source: src/Parser/parser.yy@ f90d10f

ADT arm-eh ast-experimental enum forall-pointer-decay jacob/cs343-translation new-ast new-ast-unique-expr pthread-emulation qualifiedEnum
Last change on this file since f90d10f was ff489bf, checked in by Peter A. Buhr <pabuhr@…>, 6 years ago

Merge branch 'master' of plg.uwaterloo.ca:software/cfa/cfa-cc
  • Property mode set to 100644
File size: 136.4 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author : Peter A. Buhr
10// Created On : Sat Sep 1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Fri Mar 6 17:26:45 2020
13// Update Count : 4474
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS. While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks. Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// 1. designation with '=' (use ':' instead)
29//
30// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32//
33// 1. designation with and without '=' (use ':' instead)
34// 2. attributes not allowed in parenthesis of declarator
35//
36// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40// grammar rule.
41
42%{
43#define YYDEBUG_LEXER_TEXT (yylval) // lexer loads this up each time
44#define YYDEBUG 1 // get the pretty debugging code to compile
45#define YYERROR_VERBOSE // more information in syntax errors
46
47#undef __GNUC_MINOR__
48
49#include <cstdio>
50#include <stack>
51using namespace std;
52
53#include "SynTree/Declaration.h"
54#include "ParseNode.h"
55#include "TypedefTable.h"
56#include "TypeData.h"
57#include "SynTree/LinkageSpec.h"
58#include "Common/SemanticError.h" // error_str
59#include "Common/utility.h" // for maybeMoveBuild, maybeBuild, CodeLo...
60
61extern DeclarationNode * parseTree;
62extern LinkageSpec::Spec linkage;
63extern TypedefTable typedefTable;
64
65stack< LinkageSpec::Spec > linkageStack;
66
67bool appendStr( string & to, string & from ) {
68 // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
69 // "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
70 // the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
71 // easier to let the C compiler handle this case.
72 //
73 // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
74 // without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
75 // i.e., u"a" U"b" L"c" is disallowed.
76
77 if ( from[0] != '"' ) { // encoding ?
78 if ( to[0] != '"' ) { // encoding ?
79 if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
80 yyerror( "non-matching string encodings for string-literal concatenation" );
81 return false; // parse error, must call YYERROR in action
82 } else if ( from[1] == '8' ) {
83 from.erase( 0, 1 ); // remove 2nd encoding
84 } // if
85 } else {
86 if ( from[1] == '8' ) { // move encoding to start
87 to = "u8" + to;
88 from.erase( 0, 1 ); // remove 2nd encoding
89 } else {
90 to = from[0] + to;
91 } // if
92 } // if
93 from.erase( 0, 1 ); // remove 2nd encoding
94 } // if
95 to += " " + from; // concatenated into single string
96 return true;
97} // appendStr
98
99DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
100 // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
101 DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
102 for ( cur = dynamic_cast<DeclarationNode *>( cur->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode *>( cur->get_next() ) ) {
103 cl->cloneBaseType( cur );
104 } // for
105 declList->addType( cl );
106 return declList;
107} // distAttr
108
109void distExt( DeclarationNode * declaration ) {
110 // distribute EXTENSION across all declarations
111 for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
112 iter->set_extension( true );
113 } // for
114} // distExt
115
116void distInl( DeclarationNode * declaration ) {
117 // distribute EXTENSION across all declarations
118 for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
119 iter->set_inLine( true );
120 } // for
121} // distInl
122
123void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
124 // distribute qualifiers across all non-variable declarations in a distribution statemement
125 for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
126 // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
127 // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
128 // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
129 // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
130 DeclarationNode * clone = qualifiers->clone();
131 if ( qualifiers->type ) { // forall clause ? (handles SC)
132 if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
133 swap( clone->type->forall, iter->type->aggregate.params );
134 iter->addQualifiers( clone );
135 } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
136 // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
137 DeclarationNode newnode;
138 swap( newnode.type, iter->type->aggInst.aggregate );
139 swap( clone->type->forall, newnode.type->aggregate.params );
140 newnode.addQualifiers( clone );
141 swap( newnode.type, iter->type->aggInst.aggregate );
142 } else if ( iter->type->kind == TypeData::Function ) { // routines ?
143 swap( clone->type->forall, iter->type->forall );
144 iter->addQualifiers( clone );
145 } // if
146 } else { // just SC qualifiers
147 iter->addQualifiers( clone );
148 } // if
149 } // for
150 delete qualifiers;
151} // distQual
152
153// There is an ambiguity for inline generic-routine return-types and generic routines.
154// forall( otype T ) struct S { int i; } bar( T ) {}
155// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
156// forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
157// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
158// forall( otype T ) struct S { int T; };
159// forall( otype W ) bar( W ) {}
160
161void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
162 if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
163 funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
164 declSpec->type->aggregate.params = nullptr;
165 } // if
166} // rebindForall
167
168string * build_postfix_name( string * name ) {
169 *name = string("__postfix_func_") + *name;
170 return name;
171} // build_postfix_name
172
173DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
174 if ( ! fieldList ) { // field declarator ?
175 if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate || typeSpec->type->kind == TypeData::Enum) ) ) {
176 stringstream ss;
177 typeSpec->type->print( ss );
178 SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
179 return nullptr;
180 } // if
181 fieldList = DeclarationNode::newName( nullptr );
182 } // if
183 return distAttr( typeSpec, fieldList ); // mark all fields in list
184} // fieldDecl
185
186ForCtrl * forCtrl( ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
187 ConstantExpr * constant = dynamic_cast<ConstantExpr *>(type->expr.get());
188 if ( constant && (constant->get_constant()->get_value() == "0" || constant->get_constant()->get_value() == "1") ) {
189 type = new ExpressionNode( new CastExpr( maybeMoveBuild< Expression >(type), new BasicType( Type::Qualifiers(), BasicType::SignedInt ) ) );
190 } // if
191 return new ForCtrl(
192 distAttr( DeclarationNode::newTypeof( type, true ), DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) ) ),
193 // NULL comp/inc => leave blank
194 comp ? new ExpressionNode( build_binary_val( compop, new ExpressionNode( build_varref( new string( *index ) ) ), comp ) ) : 0,
195 inc ? new ExpressionNode( build_binary_val( compop == OperKinds::LThan || compop == OperKinds::LEThan ? // choose += or -= for upto/downto
196 OperKinds::PlusAssn : OperKinds::MinusAssn, new ExpressionNode( build_varref( new string( *index ) ) ), inc ) ) : 0 );
197} // forCtrl
198
199ForCtrl * forCtrl( ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
200 if ( NameExpr * identifier = dynamic_cast<NameExpr *>(index->expr.get()) ) {
201 return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
202 } else if ( CommaExpr * commaExpr = dynamic_cast<CommaExpr *>(index->expr.get()) ) {
203 if ( NameExpr * identifier = dynamic_cast<NameExpr *>(commaExpr->arg1 ) ) {
204 return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
205 } else {
206 SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); return nullptr;
207 } // if
208 } else {
209 SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); return nullptr;
210 } // if
211} // forCtrl
212
213bool forall = false, yyy = false; // aggregate have one or more forall qualifiers ?
214
215// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
216#define YYLLOC_DEFAULT(Cur, Rhs, N) \
217if ( N ) { \
218 (Cur).first_line = YYRHSLOC( Rhs, 1 ).first_line; \
219 (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column; \
220 (Cur).last_line = YYRHSLOC( Rhs, N ).last_line; \
221 (Cur).last_column = YYRHSLOC( Rhs, N ).last_column; \
222 (Cur).filename = YYRHSLOC( Rhs, 1 ).filename; \
223} else { \
224 (Cur).first_line = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line; \
225 (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column; \
226 (Cur).filename = YYRHSLOC( Rhs, 0 ).filename; \
227}
228%}
229
230%define parse.error verbose
231
232// Types declaration for productions
233%union {
234 Token tok;
235 ParseNode * pn;
236 ExpressionNode * en;
237 DeclarationNode * decl;
238 AggregateDecl::Aggregate aggKey;
239 TypeDecl::Kind tclass;
240 StatementNode * sn;
241 WaitForStmt * wfs;
242 Expression * constant;
243 IfCtrl * ifctl;
244 ForCtrl * fctl;
245 enum OperKinds compop;
246 LabelNode * label;
247 InitializerNode * in;
248 OperKinds op;
249 std::string * str;
250 bool flag;
251 CatchStmt::Kind catch_kind;
252 GenericExpr * genexpr;
253}
254
255//************************* TERMINAL TOKENS ********************************
256
257// keywords
258%token TYPEDEF
259%token EXTERN STATIC AUTO REGISTER
260%token THREADLOCAL // C11
261%token INLINE FORTRAN // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
262%token NORETURN // C11
263%token CONST VOLATILE
264%token RESTRICT // C99
265%token ATOMIC // C11
266%token FORALL MUTEX VIRTUAL COERCE // CFA
267%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
268%token BOOL COMPLEX IMAGINARY // C99
269%token INT128 UINT128 uuFLOAT80 uuFLOAT128 // GCC
270%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
271%token ZERO_T ONE_T // CFA
272%token VALIST // GCC
273%token AUTO_TYPE // GCC
274%token TYPEOF BASETYPEOF LABEL // GCC
275%token ENUM STRUCT UNION
276%token EXCEPTION // CFA
277%token GENERATOR COROUTINE MONITOR THREAD // CFA
278%token OTYPE FTYPE DTYPE TTYPE TRAIT // CFA
279%token SIZEOF OFFSETOF
280// %token RESUME // CFA
281%token SUSPEND // CFA
282%token ATTRIBUTE EXTENSION // GCC
283%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
284%token CHOOSE DISABLE ENABLE FALLTHRU FALLTHROUGH TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT WITH WHEN WAITFOR // CFA
285%token ASM // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
286%token ALIGNAS ALIGNOF GENERIC STATICASSERT // C11
287
288// names and constants: lexer differentiates between identifier and typedef names
289%token<tok> IDENTIFIER QUOTED_IDENTIFIER TYPEDEFname TYPEGENname
290%token<tok> TIMEOUT WOR
291%token<tok> INTEGERconstant CHARACTERconstant STRINGliteral
292%token<tok> DIRECTIVE
293// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
294// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
295// converted into the tuple index (.)(1). e.g., 3.x
296%token<tok> FLOATING_DECIMALconstant FLOATING_FRACTIONconstant FLOATINGconstant
297
298// multi-character operators
299%token ARROW // ->
300%token ICR DECR // ++ --
301%token LS RS // << >>
302%token LE GE EQ NE // <= >= == !=
303%token ANDAND OROR // && ||
304%token ELLIPSIS // ...
305
306%token EXPassign MULTassign DIVassign MODassign // \= *= /= %=
307%token PLUSassign MINUSassign // += -=
308%token LSassign RSassign // <<= >>=
309%token ANDassign ERassign ORassign // &= ^= |=
310
311%token ErangeUpEq ErangeDown ErangeDownEq // ~= -~ -~=
312%token ATassign // @=
313
314%type<tok> identifier
315%type<tok> identifier_or_type_name attr_name
316%type<tok> quasi_keyword
317%type<constant> string_literal
318%type<str> string_literal_list
319
320// expressions
321%type<en> constant
322%type<en> tuple tuple_expression_list
323%type<op> ptrref_operator unary_operator assignment_operator
324%type<en> primary_expression postfix_expression unary_expression
325%type<en> cast_expression_list cast_expression exponential_expression multiplicative_expression additive_expression
326%type<en> shift_expression relational_expression equality_expression
327%type<en> AND_expression exclusive_OR_expression inclusive_OR_expression
328%type<en> logical_AND_expression logical_OR_expression
329%type<en> conditional_expression constant_expression assignment_expression assignment_expression_opt
330%type<en> comma_expression comma_expression_opt
331%type<en> argument_expression_list argument_expression default_initialize_opt
332%type<ifctl> if_control_expression
333%type<fctl> for_control_expression for_control_expression_list
334%type<compop> inclexcl
335%type<en> subrange
336%type<decl> asm_name_opt
337%type<en> asm_operands_opt asm_operands_list asm_operand
338%type<label> label_list
339%type<en> asm_clobbers_list_opt
340%type<flag> asm_volatile_opt
341%type<en> handler_predicate_opt
342%type<genexpr> generic_association generic_assoc_list
343
344// statements
345%type<sn> statement labeled_statement compound_statement
346%type<sn> statement_decl statement_decl_list statement_list_nodecl
347%type<sn> selection_statement if_statement
348%type<sn> switch_clause_list_opt switch_clause_list
349%type<en> case_value
350%type<sn> case_clause case_value_list case_label case_label_list
351%type<sn> iteration_statement jump_statement
352%type<sn> expression_statement asm_statement
353%type<sn> with_statement
354%type<en> with_clause_opt
355%type<sn> exception_statement handler_clause finally_clause
356%type<catch_kind> handler_key
357%type<sn> mutex_statement
358%type<en> when_clause when_clause_opt waitfor timeout
359%type<sn> waitfor_statement
360%type<wfs> waitfor_clause
361
362// declarations
363%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
364%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
365%type<decl> abstract_parameter_declaration
366
367%type<aggKey> aggregate_key aggregate_data aggregate_control
368%type<decl> aggregate_type aggregate_type_nobody
369
370%type<decl> assertion assertion_list assertion_list_opt
371
372%type<en> bit_subrange_size_opt bit_subrange_size
373
374%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
375
376%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
377
378%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
379%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
380
381%type<decl> elaborated_type elaborated_type_nobody
382
383%type<decl> enumerator_list enum_type enum_type_nobody
384%type<en> enumerator_value_opt
385
386%type<decl> external_definition external_definition_list external_definition_list_opt
387
388%type<decl> exception_declaration
389
390%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
391%type<en> field field_name_list field_name fraction_constants_opt
392
393%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
394
395%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
396%type<decl> identifier_list
397
398%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
399%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
400%type<decl> cfa_abstract_ptr cfa_abstract_tuple
401
402%type<decl> cfa_array_parameter_1st_dimension
403
404%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
405%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
406
407%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
408%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
409
410%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
411
412%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
413
414%type<decl> c_declaration static_assert
415%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
416%type<decl> KR_parameter_list KR_parameter_list_opt
417
418%type<decl> parameter_declaration parameter_list parameter_type_list_opt
419
420%type<decl> paren_identifier paren_type
421
422%type<decl> storage_class storage_class_list
423
424%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
425
426%type<tclass> type_class
427%type<decl> type_declarator type_declarator_name type_declaring_list
428
429%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
430%type<decl> typedef typedef_declaration typedef_expression
431
432%type<decl> variable_type_redeclarator type_ptr type_array type_function
433
434%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
435
436%type<decl> type type_no_function
437%type<decl> type_parameter type_parameter_list type_initializer_opt
438
439%type<en> type_parameters_opt type_list
440
441%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
442%type<decl> type_specifier type_specifier_nobody
443
444%type<decl> variable_declarator variable_ptr variable_array variable_function
445%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
446
447%type<decl> attribute_list_opt attribute_list attribute_name_list attribute attribute_name
448
449// initializers
450%type<in> initializer initializer_list_opt initializer_opt
451
452// designators
453%type<en> designator designator_list designation
454
455
456// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
457// .---------. matches IF '(' comma_expression ')' statement . (reduce)
458// if ( C ) S1 else S2
459// `-----------------' matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
460// Similar issues exit with the waitfor statement.
461
462// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
463// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
464%precedence THEN // rule precedence for IF/WAITFOR statement
465%precedence WOR // token precedence for start of WOR in WAITFOR statement
466%precedence TIMEOUT // token precedence for start of TIMEOUT in WAITFOR statement
467%precedence ELSE // token precedence for start of else clause in IF/WAITFOR statement
468
469// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
470// forall( otype T ) struct Foo { T v; };
471// .-----. matches pointer to function returning a generic (which is impossible without a type)
472// Foo ( *fp )( int );
473// `---' matches start of TYPEGENname '('
474// must be:
475// Foo( int ) ( *fp )( int );
476// The same problem occurs here:
477// forall( otype T ) struct Foo { T v; } ( *fp )( int );
478// must be:
479// forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
480
481// Order of these lines matters (low-to-high precedence).
482%precedence TYPEGENname
483%precedence '}'
484%precedence '('
485
486// %precedence RESUME
487// %precedence '{'
488// %precedence ')'
489
490%locations // support location tracking for error messages
491
492%start translation_unit // parse-tree root
493
494%%
495//************************* Namespace Management ********************************
496
497// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
498// which are lexically identical.
499//
500// typedef int foo; // identifier foo must now be scanned as TYPEDEFname
501// foo f; // to allow it to appear in this context
502//
503// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
504// between syntactic and semantic constructs. Cforall compounds this problem by introducing type names local to the
505// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
506// generators" -- parameterized types. This latter type name creates a third class of identifiers, "TYPEGENname", which
507// must be distinguished by the lexical scanner.
508//
509// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
510// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
511// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
512// each context that introduces a name scope, a new level is created in the type table and that level is popped on
513// exiting the scope. Since type names can be local to a particular declaration, each declaration is itself a scope.
514// This requires distinguishing between type names that are local to the current declaration scope and those that
515// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
516//
517// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
518// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
519// around the list separator.
520//
521// int f( forall(T) T (*f1) T , forall( S ) S (*f2)( S ) );
522// push pop push pop
523
524push:
525 { typedefTable.enterScope(); }
526 ;
527
528pop:
529 { typedefTable.leaveScope(); }
530 ;
531
532//************************* CONSTANTS ********************************
533
534constant:
535 // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
536 INTEGERconstant { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
537 | FLOATING_DECIMALconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
538 | FLOATING_FRACTIONconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
539 | FLOATINGconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
540 | CHARACTERconstant { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
541 ;
542
543quasi_keyword: // CFA
544 TIMEOUT
545 | WOR
546 ;
547
548identifier:
549 IDENTIFIER
550 | quasi_keyword
551 | '@' // CFA
552 { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
553 ;
554
555string_literal:
556 string_literal_list { $$ = build_constantStr( *$1 ); }
557 ;
558
559string_literal_list: // juxtaposed strings are concatenated
560 STRINGliteral { $$ = $1; } // conversion from tok to str
561 | string_literal_list STRINGliteral
562 {
563 if ( ! appendStr( *$1, *$2 ) ) YYERROR; // append 2nd juxtaposed string to 1st
564 delete $2; // allocated by lexer
565 $$ = $1; // conversion from tok to str
566 }
567 ;
568
569//************************* EXPRESSIONS ********************************
570
571primary_expression:
572 IDENTIFIER // typedef name cannot be used as a variable name
573 { $$ = new ExpressionNode( build_varref( $1 ) ); }
574 | quasi_keyword
575 { $$ = new ExpressionNode( build_varref( $1 ) ); }
576 | tuple
577 | '(' comma_expression ')'
578 { $$ = $2; }
579 | '(' compound_statement ')' // GCC, lambda expression
580 { $$ = new ExpressionNode( new StmtExpr( dynamic_cast< CompoundStmt * >(maybeMoveBuild< Statement >($2) ) ) ); }
581 | type_name '.' identifier // CFA, nested type
582 { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
583 | type_name '.' '[' field_name_list ']' // CFA, nested type / tuple field selector
584 { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
585 | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
586 {
587 // add the missing control expression to the GenericExpr and return it
588 $5->control = maybeMoveBuild<Expression>( $3 );
589 $$ = new ExpressionNode( $5 );
590 }
591 // | RESUME '(' comma_expression ')'
592 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
593 // | RESUME '(' comma_expression ')' compound_statement
594 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
595 ;
596
597generic_assoc_list: // C11
598 generic_association
599 | generic_assoc_list ',' generic_association
600 {
601 // steal the association node from the singleton and delete the wrapper
602 $1->associations.splice($1->associations.end(), $3->associations);
603 delete $3;
604 $$ = $1;
605 }
606 ;
607
608generic_association: // C11
609 type_no_function ':' assignment_expression
610 {
611 // create a GenericExpr wrapper with one association pair
612 $$ = new GenericExpr( nullptr, { { maybeMoveBuildType($1), maybeMoveBuild<Expression>($3) } } );
613 }
614 | DEFAULT ':' assignment_expression
615 { $$ = new GenericExpr( nullptr, { { maybeMoveBuild<Expression>($3) } } ); }
616 ;
617
618postfix_expression:
619 primary_expression
620 | postfix_expression '[' assignment_expression ']'
621 // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
622 // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
623 // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
624 // equivalent to the old x[i,j].
625 { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
626 | postfix_expression '{' argument_expression_list '}' // CFA, constructor call
627 {
628 Token fn;
629 fn.str = new std::string( "?{}" ); // location undefined - use location of '{'?
630 $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
631 }
632 | postfix_expression '(' argument_expression_list ')'
633 { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
634 | postfix_expression '`' identifier // CFA, postfix call
635 { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
636 | constant '`' identifier // CFA, postfix call
637 { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
638 | string_literal '`' identifier // CFA, postfix call
639 { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), new ExpressionNode( $1 ) ) ); }
640 | postfix_expression '.' identifier
641 { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
642 | postfix_expression '.' INTEGERconstant // CFA, tuple index
643 { $$ = new ExpressionNode( build_fieldSel( $1, build_constantInteger( *$3 ) ) ); }
644 | postfix_expression FLOATING_FRACTIONconstant // CFA, tuple index
645 { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
646 | postfix_expression '.' '[' field_name_list ']' // CFA, tuple field selector
647 { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
648 | postfix_expression '.' aggregate_control
649 { $$ = new ExpressionNode( build_keyword_cast( $3, $1 ) ); }
650 | postfix_expression ARROW identifier
651 { $$ = new ExpressionNode( build_pfieldSel( $1, build_varref( $3 ) ) ); }
652 | postfix_expression ARROW INTEGERconstant // CFA, tuple index
653 { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
654 | postfix_expression ARROW '[' field_name_list ']' // CFA, tuple field selector
655 { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
656 | postfix_expression ICR
657 { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
658 | postfix_expression DECR
659 { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
660 | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
661 { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
662 | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
663 { $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
664 | '^' primary_expression '{' argument_expression_list '}' // CFA, destructor call
665 {
666 Token fn;
667 fn.str = new string( "^?{}" ); // location undefined
668 $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
669 }
670 ;
671
672argument_expression_list:
673 // empty
674 { $$ = nullptr; }
675 | argument_expression
676 | argument_expression_list ',' argument_expression
677 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
678 ;
679
680argument_expression:
681 '@' // CFA, default parameter
682 { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
683 // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
684 | assignment_expression
685 ;
686
687field_name_list: // CFA, tuple field selector
688 field
689 | field_name_list ',' field { $$ = (ExpressionNode *)($1->set_last( $3 )); }
690 ;
691
692field: // CFA, tuple field selector
693 field_name
694 | FLOATING_DECIMALconstant field
695 { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
696 | FLOATING_DECIMALconstant '[' field_name_list ']'
697 { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $3 ) ) ); }
698 | field_name '.' field
699 { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
700 | field_name '.' '[' field_name_list ']'
701 { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
702 | field_name ARROW field
703 { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
704 | field_name ARROW '[' field_name_list ']'
705 { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
706 ;
707
708field_name:
709 INTEGERconstant fraction_constants_opt
710 { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
711 | FLOATINGconstant fraction_constants_opt
712 { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
713 | identifier fraction_constants_opt
714 {
715 $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
716 }
717 ;
718
719fraction_constants_opt:
720 // empty
721 { $$ = nullptr; }
722 | fraction_constants_opt FLOATING_FRACTIONconstant
723 {
724 Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
725 $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1, constant ) ) : new ExpressionNode( constant );
726 }
727 ;
728
729unary_expression:
730 postfix_expression
731 // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
732 // semantics checks, e.g., ++3, 3--, *3, &&3
733 | constant
734 | string_literal
735 { $$ = new ExpressionNode( $1 ); }
736 | EXTENSION cast_expression // GCC
737 { $$ = $2->set_extension( true ); }
738 // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
739 // { * X; } // dereference X
740 // { * int X; } // CFA declaration of pointer to int
741 | ptrref_operator cast_expression // CFA
742 {
743 switch ( $1 ) {
744 case OperKinds::AddressOf:
745 $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) );
746 break;
747 case OperKinds::PointTo:
748 $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
749 break;
750 case OperKinds::And:
751 $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) ) );
752 break;
753 default:
754 assert( false );
755 }
756 }
757 | unary_operator cast_expression
758 { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
759 | ICR unary_expression
760 { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
761 | DECR unary_expression
762 { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
763 | SIZEOF unary_expression
764 { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
765 | SIZEOF '(' type_no_function ')'
766 { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
767 | ALIGNOF unary_expression // GCC, variable alignment
768 { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
769 | ALIGNOF '(' type_no_function ')' // GCC, type alignment
770 { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
771 | OFFSETOF '(' type_no_function ',' identifier ')'
772 { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
773 ;
774
775ptrref_operator:
776 '*' { $$ = OperKinds::PointTo; }
777 | '&' { $$ = OperKinds::AddressOf; }
778 // GCC, address of label must be handled by semantic check for ref,ref,label
779 | ANDAND { $$ = OperKinds::And; }
780 ;
781
782unary_operator:
783 '+' { $$ = OperKinds::UnPlus; }
784 | '-' { $$ = OperKinds::UnMinus; }
785 | '!' { $$ = OperKinds::Neg; }
786 | '~' { $$ = OperKinds::BitNeg; }
787 ;
788
789cast_expression:
790 unary_expression
791 | '(' type_no_function ')' cast_expression
792 { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
793 | '(' aggregate_control '&' ')' cast_expression // CFA
794 { $$ = new ExpressionNode( build_keyword_cast( $2, $5 ) ); }
795 // VIRTUAL cannot be opt because of look ahead issues
796 | '(' VIRTUAL ')' cast_expression // CFA
797 { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $4 ), maybeMoveBuildType( nullptr ) ) ); }
798 | '(' VIRTUAL type_no_function ')' cast_expression // CFA
799 { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $5 ), maybeMoveBuildType( $3 ) ) ); }
800 | '(' RETURN type_no_function ')' cast_expression // CFA
801 { SemanticError( yylloc, "Return cast is currently unimplemented." ); $$ = nullptr; }
802 | '(' COERCE type_no_function ')' cast_expression // CFA
803 { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
804 | '(' qualifier_cast_list ')' cast_expression // CFA
805 { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
806// | '(' type_no_function ')' tuple
807// { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
808 ;
809
810qualifier_cast_list:
811 cast_modifier type_qualifier_name
812 | cast_modifier MUTEX
813 | qualifier_cast_list cast_modifier type_qualifier_name
814 | qualifier_cast_list cast_modifier MUTEX
815 ;
816
817cast_modifier:
818 '-'
819 | '+'
820 ;
821
822exponential_expression:
823 cast_expression
824 | exponential_expression '\\' cast_expression
825 { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
826 ;
827
828multiplicative_expression:
829 exponential_expression
830 | multiplicative_expression '*' exponential_expression
831 { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
832 | multiplicative_expression '/' exponential_expression
833 { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
834 | multiplicative_expression '%' exponential_expression
835 { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
836 ;
837
838additive_expression:
839 multiplicative_expression
840 | additive_expression '+' multiplicative_expression
841 { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
842 | additive_expression '-' multiplicative_expression
843 { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
844 ;
845
846shift_expression:
847 additive_expression
848 | shift_expression LS additive_expression
849 { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
850 | shift_expression RS additive_expression
851 { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
852 ;
853
854relational_expression:
855 shift_expression
856 | relational_expression '<' shift_expression
857 { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
858 | relational_expression '>' shift_expression
859 { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
860 | relational_expression LE shift_expression
861 { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
862 | relational_expression GE shift_expression
863 { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
864 ;
865
866equality_expression:
867 relational_expression
868 | equality_expression EQ relational_expression
869 { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
870 | equality_expression NE relational_expression
871 { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
872 ;
873
874AND_expression:
875 equality_expression
876 | AND_expression '&' equality_expression
877 { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
878 ;
879
880exclusive_OR_expression:
881 AND_expression
882 | exclusive_OR_expression '^' AND_expression
883 { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
884 ;
885
886inclusive_OR_expression:
887 exclusive_OR_expression
888 | inclusive_OR_expression '|' exclusive_OR_expression
889 { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
890 ;
891
892logical_AND_expression:
893 inclusive_OR_expression
894 | logical_AND_expression ANDAND inclusive_OR_expression
895 { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
896 ;
897
898logical_OR_expression:
899 logical_AND_expression
900 | logical_OR_expression OROR logical_AND_expression
901 { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
902 ;
903
904conditional_expression:
905 logical_OR_expression
906 | logical_OR_expression '?' comma_expression ':' conditional_expression
907 { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
908 // FIX ME: computes $1 twice
909 | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
910 { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
911 ;
912
913constant_expression:
914 conditional_expression
915 ;
916
917assignment_expression:
918 // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
919 conditional_expression
920 | unary_expression assignment_operator assignment_expression
921 {
922 if ( $2 == OperKinds::AtAssn ) {
923 SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
924 } else {
925 $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) );
926 } // if
927 }
928 | unary_expression '=' '{' initializer_list_opt comma_opt '}'
929 { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
930 ;
931
932assignment_expression_opt:
933 // empty
934 { $$ = nullptr; }
935 | assignment_expression
936 ;
937
938assignment_operator:
939 '=' { $$ = OperKinds::Assign; }
940 | ATassign { $$ = OperKinds::AtAssn; }
941 | EXPassign { $$ = OperKinds::ExpAssn; }
942 | MULTassign { $$ = OperKinds::MulAssn; }
943 | DIVassign { $$ = OperKinds::DivAssn; }
944 | MODassign { $$ = OperKinds::ModAssn; }
945 | PLUSassign { $$ = OperKinds::PlusAssn; }
946 | MINUSassign { $$ = OperKinds::MinusAssn; }
947 | LSassign { $$ = OperKinds::LSAssn; }
948 | RSassign { $$ = OperKinds::RSAssn; }
949 | ANDassign { $$ = OperKinds::AndAssn; }
950 | ERassign { $$ = OperKinds::ERAssn; }
951 | ORassign { $$ = OperKinds::OrAssn; }
952 ;
953
954tuple: // CFA, tuple
955 // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
956 // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
957// '[' ']'
958// { $$ = new ExpressionNode( build_tuple() ); }
959// | '[' push assignment_expression pop ']'
960// { $$ = new ExpressionNode( build_tuple( $3 ) ); }
961 '[' ',' tuple_expression_list ']'
962 { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
963 | '[' push assignment_expression pop ',' tuple_expression_list ']'
964 { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)($3->set_last( $6 ) ) )); }
965 ;
966
967tuple_expression_list:
968 assignment_expression_opt
969 | tuple_expression_list ',' assignment_expression_opt
970 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
971 ;
972
973comma_expression:
974 assignment_expression
975 | comma_expression ',' assignment_expression
976 { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
977 ;
978
979comma_expression_opt:
980 // empty
981 { $$ = nullptr; }
982 | comma_expression
983 ;
984
985//*************************** STATEMENTS *******************************
986
987statement:
988 labeled_statement
989 | compound_statement
990 | expression_statement
991 | selection_statement
992 | iteration_statement
993 | jump_statement
994 | with_statement
995 | mutex_statement
996 | waitfor_statement
997 | exception_statement
998 | enable_disable_statement
999 { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1000 | asm_statement
1001 | DIRECTIVE
1002 { $$ = new StatementNode( build_directive( $1 ) ); }
1003 ;
1004
1005labeled_statement:
1006 // labels cannot be identifiers 0 or 1
1007 identifier_or_type_name ':' attribute_list_opt statement
1008 { $$ = $4->add_label( $1, $3 ); }
1009 ;
1010
1011compound_statement:
1012 '{' '}'
1013 { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
1014 | '{' push
1015 local_label_declaration_opt // GCC, local labels
1016 statement_decl_list // C99, intermix declarations and statements
1017 pop '}'
1018 { $$ = new StatementNode( build_compound( $4 ) ); }
1019 ;
1020
1021statement_decl_list: // C99
1022 statement_decl
1023 | statement_decl_list statement_decl
1024 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1025 ;
1026
1027statement_decl:
1028 declaration // CFA, new & old style declarations
1029 { $$ = new StatementNode( $1 ); }
1030 | EXTENSION declaration // GCC
1031 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1032 | function_definition
1033 { $$ = new StatementNode( $1 ); }
1034 | EXTENSION function_definition // GCC
1035 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1036 | statement
1037 ;
1038
1039statement_list_nodecl:
1040 statement
1041 | statement_list_nodecl statement
1042 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1043 ;
1044
1045expression_statement:
1046 comma_expression_opt ';'
1047 { $$ = new StatementNode( build_expr( $1 ) ); }
1048 ;
1049
1050selection_statement:
1051 // pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1052 // the inherent S/R conflict with THEN/ELSE.
1053 push if_statement pop
1054 { $$ = $2; }
1055 | SWITCH '(' comma_expression ')' case_clause
1056 { $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
1057 | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1058 {
1059 StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
1060 // The semantics of the declaration list is changed to include associated initialization, which is performed
1061 // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1062 // statement around the switch. Statements after the initial declaration list can never be executed, and
1063 // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1064 // statement.
1065 $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1066 }
1067 | CHOOSE '(' comma_expression ')' case_clause // CFA
1068 { $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
1069 | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1070 {
1071 StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
1072 $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1073 }
1074 ;
1075
1076if_statement:
1077 IF '(' if_control_expression ')' statement %prec THEN
1078 // explicitly deal with the shift/reduce conflict on if/else
1079 { $$ = new StatementNode( build_if( $3, $5, nullptr ) ); }
1080 | IF '(' if_control_expression ')' statement ELSE statement
1081 { $$ = new StatementNode( build_if( $3, $5, $7 ) ); }
1082 ;
1083
1084if_control_expression:
1085 comma_expression
1086 { $$ = new IfCtrl( nullptr, $1 ); }
1087 | c_declaration // no semi-colon
1088 { $$ = new IfCtrl( $1, nullptr ); }
1089 | cfa_declaration // no semi-colon
1090 { $$ = new IfCtrl( $1, nullptr ); }
1091 | declaration comma_expression // semi-colon separated
1092 { $$ = new IfCtrl( $1, $2 ); }
1093 ;
1094
1095// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1096// clause allows a list of values and subranges.
1097
1098case_value: // CFA
1099 constant_expression { $$ = $1; }
1100 | constant_expression ELLIPSIS constant_expression // GCC, subrange
1101 { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
1102 | subrange // CFA, subrange
1103 ;
1104
1105case_value_list: // CFA
1106 case_value { $$ = new StatementNode( build_case( $1 ) ); }
1107 // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1108 | case_value_list ',' case_value { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
1109 ;
1110
1111case_label: // CFA
1112 CASE case_value_list ':' { $$ = $2; }
1113 | DEFAULT ':' { $$ = new StatementNode( build_default() ); }
1114 // A semantic check is required to ensure only one default clause per switch/choose statement.
1115 ;
1116
1117//label_list_opt:
1118// // empty
1119// | identifier_or_type_name ':'
1120// | label_list_opt identifier_or_type_name ':'
1121// ;
1122
1123case_label_list: // CFA
1124 case_label
1125 | case_label_list case_label { $$ = (StatementNode *)( $1->set_last( $2 )); }
1126 ;
1127
1128case_clause: // CFA
1129 case_label_list statement { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1130 ;
1131
1132switch_clause_list_opt: // CFA
1133 // empty
1134 { $$ = nullptr; }
1135 | switch_clause_list
1136 ;
1137
1138switch_clause_list: // CFA
1139 case_label_list statement_list_nodecl
1140 { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1141 | switch_clause_list case_label_list statement_list_nodecl
1142 { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1143 ;
1144
1145iteration_statement:
1146 WHILE '(' push if_control_expression ')' statement pop
1147 { $$ = new StatementNode( build_while( $4, $6 ) ); }
1148 | WHILE '(' ')' statement // CFA => while ( 1 )
1149 { $$ = new StatementNode( build_while( new IfCtrl( nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ), $4 ) ); }
1150 | DO statement WHILE '(' comma_expression ')' ';'
1151 { $$ = new StatementNode( build_do_while( $5, $2 ) ); }
1152 | DO statement WHILE '(' ')' ';' // CFA => do while( 1 )
1153 { $$ = new StatementNode( build_do_while( new ExpressionNode( build_constantInteger( *new string( "1" ) ) ), $2 ) ); }
1154 | FOR '(' push for_control_expression_list ')' statement pop
1155 { $$ = new StatementNode( build_for( $4, $6 ) ); }
1156 | FOR '(' ')' statement // CFA => for ( ;; )
1157 { $$ = new StatementNode( build_for( new ForCtrl( (ExpressionNode * )nullptr, (ExpressionNode * )nullptr, (ExpressionNode * )nullptr ), $4 ) ); }
1158 ;
1159
1160for_control_expression_list:
1161 for_control_expression
1162 | for_control_expression_list ':' for_control_expression
1163 // ForCtrl + ForCtrl:
1164 // init + init => multiple declaration statements that are hoisted
1165 // condition + condition => (expression) && (expression)
1166 // change + change => (expression), (expression)
1167 {
1168 $1->init->set_last( $3->init );
1169 if ( $1->condition ) {
1170 if ( $3->condition ) {
1171 $1->condition->expr.reset( new LogicalExpr( $1->condition->expr.release(), $3->condition->expr.release(), true ) );
1172 } // if
1173 } else $1->condition = $3->condition;
1174 if ( $1->change ) {
1175 if ( $3->change ) {
1176 $1->change->expr.reset( new CommaExpr( $1->change->expr.release(), $3->change->expr.release() ) );
1177 } // if
1178 } else $1->change = $3->change;
1179 $$ = $1;
1180 }
1181 ;
1182
1183for_control_expression:
1184 ';' comma_expression_opt ';' comma_expression_opt
1185 { $$ = new ForCtrl( (ExpressionNode * )nullptr, $2, $4 ); }
1186 | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1187 { $$ = new ForCtrl( $1, $3, $5 ); }
1188 | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1189 { $$ = new ForCtrl( $1, $2, $4 ); }
1190
1191 | comma_expression // CFA
1192 { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1193 OperKinds::LThan, $1->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1194 | '=' comma_expression // CFA
1195 { $$ = forCtrl( $2, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1196 OperKinds::LEThan, $2->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1197 | comma_expression inclexcl comma_expression // CFA
1198 { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1199 | comma_expression inclexcl comma_expression '~' comma_expression // CFA
1200 { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, $5 ); }
1201 | comma_expression ';' comma_expression // CFA
1202 { $$ = forCtrl( $3, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1203 OperKinds::LThan, $3->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1204 | comma_expression ';' '=' comma_expression // CFA
1205 { $$ = forCtrl( $4, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1206 OperKinds::LEThan, $4->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1207 | comma_expression ';' comma_expression inclexcl comma_expression // CFA
1208 { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1209 | comma_expression ';' comma_expression inclexcl comma_expression '~' comma_expression // CFA
1210 { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, $7 ); }
1211
1212 // There is a S/R conflicit if ~ and -~ are factored out.
1213 | comma_expression ';' comma_expression '~' '@' // CFA
1214 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1215 | comma_expression ';' comma_expression ErangeDown '@' // CFA
1216 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1217 | comma_expression ';' comma_expression '~' '@' '~' comma_expression // CFA
1218 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, $7 ); }
1219 | comma_expression ';' comma_expression ErangeDown '@' '~' comma_expression // CFA
1220 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, $7 ); }
1221 | comma_expression ';' comma_expression '~' '@' '~' '@' // CFA
1222 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, nullptr ); }
1223 ;
1224
1225inclexcl:
1226 '~'
1227 { $$ = OperKinds::LThan; }
1228 | ErangeUpEq
1229 { $$ = OperKinds::LEThan; }
1230 | ErangeDown
1231 { $$ = OperKinds::GThan; }
1232 | ErangeDownEq
1233 { $$ = OperKinds::GEThan; }
1234 ;
1235
1236jump_statement:
1237 GOTO identifier_or_type_name ';'
1238 { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1239 | GOTO '*' comma_expression ';' // GCC, computed goto
1240 // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1241 // whereas normal operator precedence yields goto (*i)+3;
1242 { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1243 // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1244 | fall_through_name ';' // CFA
1245 { $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1246 | fall_through_name identifier_or_type_name ';' // CFA
1247 { $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1248 | fall_through_name DEFAULT ';' // CFA
1249 { $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1250 | CONTINUE ';'
1251 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1252 { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1253 | CONTINUE identifier_or_type_name ';' // CFA, multi-level continue
1254 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1255 // the target of the transfer appears only at the start of an iteration statement.
1256 { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1257 | BREAK ';'
1258 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1259 { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1260 | BREAK identifier_or_type_name ';' // CFA, multi-level exit
1261 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1262 // the target of the transfer appears only at the start of an iteration statement.
1263 { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1264 | RETURN comma_expression_opt ';'
1265 { $$ = new StatementNode( build_return( $2 ) ); }
1266 | RETURN '{' initializer_list_opt comma_opt '}' ';'
1267 { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1268 | SUSPEND ';'
1269 { $$ = new StatementNode( build_suspend( nullptr ) ); }
1270 | SUSPEND compound_statement
1271 { $$ = new StatementNode( build_suspend( $2 ) ); }
1272 | SUSPEND COROUTINE ';'
1273 { $$ = new StatementNode( build_suspend( nullptr, SuspendStmt::Coroutine ) ); }
1274 | SUSPEND COROUTINE compound_statement
1275 { $$ = new StatementNode( build_suspend( $3, SuspendStmt::Coroutine ) ); }
1276 | SUSPEND GENERATOR ';'
1277 { $$ = new StatementNode( build_suspend( nullptr, SuspendStmt::Generator ) ); }
1278 | SUSPEND GENERATOR compound_statement
1279 { $$ = new StatementNode( build_suspend( $3, SuspendStmt::Generator ) ); }
1280 | THROW assignment_expression_opt ';' // handles rethrow
1281 { $$ = new StatementNode( build_throw( $2 ) ); }
1282 | THROWRESUME assignment_expression_opt ';' // handles reresume
1283 { $$ = new StatementNode( build_resume( $2 ) ); }
1284 | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1285 { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1286 ;
1287
1288fall_through_name: // CFA
1289 FALLTHRU
1290 | FALLTHROUGH
1291 ;
1292
1293with_statement:
1294 WITH '(' tuple_expression_list ')' statement
1295 {
1296 $$ = new StatementNode( build_with( $3, $5 ) );
1297 }
1298 ;
1299
1300// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1301mutex_statement:
1302 MUTEX '(' argument_expression_list ')' statement
1303 { SemanticError( yylloc, "Mutex statement is currently unimplemented." ); $$ = nullptr; }
1304 ;
1305
1306when_clause:
1307 WHEN '(' comma_expression ')' { $$ = $3; }
1308 ;
1309
1310when_clause_opt:
1311 // empty
1312 { $$ = nullptr; }
1313 | when_clause
1314 ;
1315
1316waitfor:
1317 WAITFOR '(' cast_expression ')'
1318 { $$ = $3; }
1319// | WAITFOR '(' cast_expression ',' argument_expression_list ')'
1320// { $$ = (ExpressionNode *)$3->set_last( $5 ); }
1321 | WAITFOR '(' cast_expression_list ':' argument_expression_list ')'
1322 { $$ = (ExpressionNode *)($3->set_last( $5 )); }
1323 ;
1324
1325cast_expression_list:
1326 cast_expression
1327 | cast_expression_list ',' cast_expression
1328 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1329 ;
1330
1331timeout:
1332 TIMEOUT '(' comma_expression ')' { $$ = $3; }
1333 ;
1334
1335waitfor_clause:
1336 when_clause_opt waitfor statement %prec THEN
1337 { $$ = build_waitfor( $2, $3, $1 ); }
1338 | when_clause_opt waitfor statement WOR waitfor_clause
1339 { $$ = build_waitfor( $2, $3, $1, $5 ); }
1340 | when_clause_opt timeout statement %prec THEN
1341 { $$ = build_waitfor_timeout( $2, $3, $1 ); }
1342 | when_clause_opt ELSE statement
1343 { $$ = build_waitfor_timeout( nullptr, $3, $1 ); }
1344 // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1345 | when_clause_opt timeout statement WOR ELSE statement
1346 { SemanticError( yylloc, "else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1347 | when_clause_opt timeout statement WOR when_clause ELSE statement
1348 { $$ = build_waitfor_timeout( $2, $3, $1, $7, $5 ); }
1349 ;
1350
1351waitfor_statement:
1352 when_clause_opt waitfor statement %prec THEN
1353 { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1354 | when_clause_opt waitfor statement WOR waitfor_clause
1355 { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1356 ;
1357
1358exception_statement:
1359 TRY compound_statement handler_clause
1360 { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1361 | TRY compound_statement finally_clause
1362 { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1363 | TRY compound_statement handler_clause finally_clause
1364 { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1365 ;
1366
1367handler_clause:
1368 handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1369 { $$ = new StatementNode( build_catch( $1, $4, $6, $8 ) ); }
1370 | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1371 { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $5, $7, $9 ) ) ); }
1372 ;
1373
1374handler_predicate_opt:
1375 // empty
1376 { $$ = nullptr; }
1377 | ';' conditional_expression { $$ = $2; }
1378 ;
1379
1380handler_key:
1381 CATCH { $$ = CatchStmt::Terminate; }
1382 | CATCHRESUME { $$ = CatchStmt::Resume; }
1383 ;
1384
1385finally_clause:
1386 FINALLY compound_statement { $$ = new StatementNode( build_finally( $2 ) ); }
1387 ;
1388
1389exception_declaration:
1390 // No SUE declaration in parameter list.
1391 type_specifier_nobody
1392 | type_specifier_nobody declarator
1393 { $$ = $2->addType( $1 ); }
1394 | type_specifier_nobody variable_abstract_declarator
1395 { $$ = $2->addType( $1 ); }
1396 | cfa_abstract_declarator_tuple identifier // CFA
1397 { $$ = $1->addName( $2 ); }
1398 | cfa_abstract_declarator_tuple // CFA
1399 ;
1400
1401enable_disable_statement:
1402 enable_disable_key identifier_list compound_statement
1403 ;
1404
1405enable_disable_key:
1406 ENABLE
1407 | DISABLE
1408 ;
1409
1410asm_statement:
1411 ASM asm_volatile_opt '(' string_literal ')' ';'
1412 { $$ = new StatementNode( build_asm( $2, $4, 0 ) ); }
1413 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1414 { $$ = new StatementNode( build_asm( $2, $4, $6 ) ); }
1415 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1416 { $$ = new StatementNode( build_asm( $2, $4, $6, $8 ) ); }
1417 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1418 { $$ = new StatementNode( build_asm( $2, $4, $6, $8, $10 ) ); }
1419 | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1420 { $$ = new StatementNode( build_asm( $2, $5, 0, $8, $10, $12 ) ); }
1421 ;
1422
1423asm_volatile_opt: // GCC
1424 // empty
1425 { $$ = false; }
1426 | VOLATILE
1427 { $$ = true; }
1428 ;
1429
1430asm_operands_opt: // GCC
1431 // empty
1432 { $$ = nullptr; } // use default argument
1433 | asm_operands_list
1434 ;
1435
1436asm_operands_list: // GCC
1437 asm_operand
1438 | asm_operands_list ',' asm_operand
1439 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1440 ;
1441
1442asm_operand: // GCC
1443 string_literal '(' constant_expression ')'
1444 { $$ = new ExpressionNode( new AsmExpr( nullptr, $1, maybeMoveBuild< Expression >( $3 ) ) ); }
1445 | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1446 { $$ = new ExpressionNode( new AsmExpr( $2, $4, maybeMoveBuild< Expression >( $6 ) ) ); }
1447 ;
1448
1449asm_clobbers_list_opt: // GCC
1450 // empty
1451 { $$ = nullptr; } // use default argument
1452 | string_literal
1453 { $$ = new ExpressionNode( $1 ); }
1454 | asm_clobbers_list_opt ',' string_literal
1455 { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( $3 ) )); }
1456 ;
1457
1458label_list:
1459 identifier
1460 {
1461 $$ = new LabelNode(); $$->labels.push_back( *$1 );
1462 delete $1; // allocated by lexer
1463 }
1464 | label_list ',' identifier
1465 {
1466 $$ = $1; $1->labels.push_back( *$3 );
1467 delete $3; // allocated by lexer
1468 }
1469 ;
1470
1471//******************************* DECLARATIONS *********************************
1472
1473declaration_list_opt: // used at beginning of switch statement
1474 // empty
1475 { $$ = nullptr; }
1476 | declaration_list
1477 ;
1478
1479declaration_list:
1480 declaration
1481 | declaration_list declaration
1482 { $$ = $1->appendList( $2 ); }
1483 ;
1484
1485KR_parameter_list_opt: // used to declare parameter types in K&R style functions
1486 // empty
1487 { $$ = nullptr; }
1488 | KR_parameter_list
1489 ;
1490
1491KR_parameter_list:
1492 push c_declaration pop ';'
1493 { $$ = $2; }
1494 | KR_parameter_list push c_declaration pop ';'
1495 { $$ = $1->appendList( $3 ); }
1496 ;
1497
1498local_label_declaration_opt: // GCC, local label
1499 // empty
1500 | local_label_declaration_list
1501 ;
1502
1503local_label_declaration_list: // GCC, local label
1504 LABEL local_label_list ';'
1505 | local_label_declaration_list LABEL local_label_list ';'
1506 ;
1507
1508local_label_list: // GCC, local label
1509 identifier_or_type_name
1510 | local_label_list ',' identifier_or_type_name
1511 ;
1512
1513declaration: // old & new style declarations
1514 c_declaration ';'
1515 | cfa_declaration ';' // CFA
1516 | static_assert // C11
1517 ;
1518
1519static_assert:
1520 STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1521 { $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1522 | STATICASSERT '(' constant_expression ')' ';' // CFA
1523 { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( *new string( "\"\"" ) ) ); }
1524
1525// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1526// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1527// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1528// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1529// the declaration list (as in Pascal). ANSI C and the new CFA declarations may appear together in the same program
1530// block, but cannot be mixed within a specific declaration.
1531//
1532// CFA C
1533// [10] int x; int x[10]; // array of 10 integers
1534// [10] * char y; char *y[10]; // array of 10 pointers to char
1535
1536cfa_declaration: // CFA
1537 cfa_variable_declaration
1538 | cfa_typedef_declaration
1539 | cfa_function_declaration
1540 | type_declaring_list
1541 | trait_specifier
1542 ;
1543
1544cfa_variable_declaration: // CFA
1545 cfa_variable_specifier initializer_opt
1546 { $$ = $1->addInitializer( $2 ); }
1547 | declaration_qualifier_list cfa_variable_specifier initializer_opt
1548 // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1549 // them as a type_qualifier cannot appear in that context.
1550 { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1551 | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1552 { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1553 ;
1554
1555cfa_variable_specifier: // CFA
1556 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1557 // storage-class
1558 cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1559 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1560 | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1561 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1562 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1563 { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1564 ;
1565
1566cfa_function_declaration: // CFA
1567 cfa_function_specifier
1568 | type_qualifier_list cfa_function_specifier
1569 { $$ = $2->addQualifiers( $1 ); }
1570 | declaration_qualifier_list cfa_function_specifier
1571 { $$ = $2->addQualifiers( $1 ); }
1572 | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1573 { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1574 | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1575 {
1576 // Append the return type at the start (left-hand-side) to each identifier in the list.
1577 DeclarationNode * ret = new DeclarationNode;
1578 ret->type = maybeClone( $1->type->base );
1579 $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1580 }
1581 ;
1582
1583cfa_function_specifier: // CFA
1584// '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1585// {
1586// $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1587// }
1588// '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1589// {
1590// typedefTable.setNextIdentifier( *$5 );
1591// $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1592// }
1593// | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1594// {
1595// typedefTable.setNextIdentifier( *$5 );
1596// $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1597// }
1598// | '[' ']' typegen_name
1599 // identifier_or_type_name must be broken apart because of the sequence:
1600 //
1601 // '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1602 // '[' ']' type_specifier
1603 //
1604 // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1605 // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1606 cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1607 // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1608 { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1609 | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1610 { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1611 ;
1612
1613cfa_function_return: // CFA
1614 '[' push cfa_parameter_list pop ']'
1615 { $$ = DeclarationNode::newTuple( $3 ); }
1616 | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1617 // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
1618 { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1619 ;
1620
1621cfa_typedef_declaration: // CFA
1622 TYPEDEF cfa_variable_specifier
1623 {
1624 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "1" );
1625 $$ = $2->addTypedef();
1626 }
1627 | TYPEDEF cfa_function_specifier
1628 {
1629 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "2" );
1630 $$ = $2->addTypedef();
1631 }
1632 | cfa_typedef_declaration pop ',' push identifier
1633 {
1634 typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "3" );
1635 $$ = $1->appendList( $1->cloneType( $5 ) );
1636 }
1637 ;
1638
1639// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1640// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1641
1642typedef_declaration:
1643 TYPEDEF type_specifier declarator
1644 {
1645 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "4" );
1646 $$ = $3->addType( $2 )->addTypedef();
1647 }
1648 | typedef_declaration pop ',' push declarator
1649 {
1650 typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname, "5" );
1651 $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1652 }
1653 | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1654 {
1655 typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "6" );
1656 $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1657 }
1658 | type_specifier TYPEDEF declarator
1659 {
1660 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "7" );
1661 $$ = $3->addType( $1 )->addTypedef();
1662 }
1663 | type_specifier TYPEDEF type_qualifier_list declarator
1664 {
1665 typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "8" );
1666 $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1667 }
1668 ;
1669
1670typedef_expression:
1671 // GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1672 TYPEDEF identifier '=' assignment_expression
1673 {
1674 // $$ = DeclarationNode::newName( 0 ); // unimplemented
1675 SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1676 }
1677 | typedef_expression pop ',' push identifier '=' assignment_expression
1678 {
1679 // $$ = DeclarationNode::newName( 0 ); // unimplemented
1680 SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1681 }
1682 ;
1683
1684//c_declaration:
1685// declaring_list pop ';'
1686// | typedef_declaration pop ';'
1687// | typedef_expression pop ';' // GCC, naming expression type
1688// | sue_declaration_specifier pop ';'
1689// ;
1690//
1691//declaring_list:
1692// // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1693// // storage-class
1694// declarator asm_name_opt initializer_opt
1695// {
1696// typedefTable.addToEnclosingScope( IDENTIFIER );
1697// $$ = ( $2->addType( $1 ))->addAsmName( $3 )->addInitializer( $4 );
1698// }
1699// | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1700// {
1701// typedefTable.addToEnclosingScope( IDENTIFIER );
1702// $$ = $1->appendList( $1->cloneBaseType( $4->addAsmName( $5 )->addInitializer( $6 ) ) );
1703// }
1704// ;
1705
1706c_declaration:
1707 declaration_specifier declaring_list
1708 { $$ = distAttr( $1, $2 ); }
1709 | typedef_declaration
1710 | typedef_expression // GCC, naming expression type
1711 | sue_declaration_specifier
1712 ;
1713
1714declaring_list:
1715 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1716 // storage-class
1717 declarator asm_name_opt initializer_opt
1718 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
1719 | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1720 { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
1721 ;
1722
1723declaration_specifier: // type specifier + storage class
1724 basic_declaration_specifier
1725 | sue_declaration_specifier
1726 | type_declaration_specifier
1727 ;
1728
1729declaration_specifier_nobody: // type specifier + storage class - {...}
1730 // Preclude SUE declarations in restricted scopes:
1731 //
1732 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1733 //
1734 // because it is impossible to call f due to name equivalence.
1735 basic_declaration_specifier
1736 | sue_declaration_specifier_nobody
1737 | type_declaration_specifier
1738 ;
1739
1740type_specifier: // type specifier
1741 basic_type_specifier
1742 | sue_type_specifier
1743 | type_type_specifier
1744 ;
1745
1746type_specifier_nobody: // type specifier - {...}
1747 // Preclude SUE declarations in restricted scopes:
1748 //
1749 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1750 //
1751 // because it is impossible to call f due to name equivalence.
1752 basic_type_specifier
1753 | sue_type_specifier_nobody
1754 | type_type_specifier
1755 ;
1756
1757type_qualifier_list_opt: // GCC, used in asm_statement
1758 // empty
1759 { $$ = nullptr; }
1760 | type_qualifier_list
1761 ;
1762
1763type_qualifier_list:
1764 // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1765 //
1766 // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1767 // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1768 // appeared only once.
1769 type_qualifier
1770 | type_qualifier_list type_qualifier
1771 { $$ = $1->addQualifiers( $2 ); }
1772 ;
1773
1774type_qualifier:
1775 type_qualifier_name
1776 | attribute
1777 ;
1778
1779type_qualifier_name:
1780 CONST
1781 { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1782 | RESTRICT
1783 { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1784 | VOLATILE
1785 { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1786 | ATOMIC
1787 { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1788 | forall
1789 ;
1790
1791forall:
1792 FORALL '(' type_parameter_list ')' // CFA
1793 { $$ = DeclarationNode::newForall( $3 ); }
1794 ;
1795
1796declaration_qualifier_list:
1797 storage_class_list
1798 | type_qualifier_list storage_class_list // remaining OBSOLESCENT (see 2 )
1799 { $$ = $1->addQualifiers( $2 ); }
1800 | declaration_qualifier_list type_qualifier_list storage_class_list
1801 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1802 ;
1803
1804storage_class_list:
1805 // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1806 // only one of each is specified, except for inline, which can appear with the others.
1807 //
1808 // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1809 // specifiers in a declaration.
1810 storage_class
1811 | storage_class_list storage_class
1812 { $$ = $1->addQualifiers( $2 ); }
1813 ;
1814
1815storage_class:
1816 EXTERN
1817 { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1818 | STATIC
1819 { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1820 | AUTO
1821 { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1822 | REGISTER
1823 { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1824 | THREADLOCAL // C11
1825 { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1826 // Put function specifiers here to simplify parsing rules, but separate them semantically.
1827 | INLINE // C99
1828 { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1829 | FORTRAN // C99
1830 { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1831 | NORETURN // C11
1832 { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1833 ;
1834
1835basic_type_name:
1836 VOID
1837 { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1838 | BOOL // C99
1839 { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1840 | CHAR
1841 { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1842 | INT
1843 { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1844 | INT128
1845 { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1846 | UINT128
1847 { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 )->addType( DeclarationNode::newSignedNess( DeclarationNode::Unsigned ) ); }
1848 | FLOAT
1849 { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1850 | DOUBLE
1851 { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1852 | uuFLOAT80
1853 { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
1854 | uuFLOAT128
1855 { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
1856 | uFLOAT16
1857 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
1858 | uFLOAT32
1859 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
1860 | uFLOAT32X
1861 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
1862 | uFLOAT64
1863 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
1864 | uFLOAT64X
1865 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
1866 | uFLOAT128
1867 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
1868 | COMPLEX // C99
1869 { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1870 | IMAGINARY // C99
1871 { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1872 | SIGNED
1873 { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1874 | UNSIGNED
1875 { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1876 | SHORT
1877 { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1878 | LONG
1879 { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1880 | VALIST // GCC, __builtin_va_list
1881 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1882 | AUTO_TYPE
1883 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::AutoType ); }
1884 ;
1885
1886basic_declaration_specifier:
1887 // A semantic check is necessary for conflicting storage classes.
1888 basic_type_specifier
1889 | declaration_qualifier_list basic_type_specifier
1890 { $$ = $2->addQualifiers( $1 ); }
1891 | basic_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1892 { $$ = $1->addQualifiers( $2 ); }
1893 | basic_declaration_specifier storage_class type_qualifier_list
1894 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1895 | basic_declaration_specifier storage_class basic_type_specifier
1896 { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1897 ;
1898
1899basic_type_specifier:
1900 direct_type
1901 // Cannot have type modifiers, e.g., short, long, etc.
1902 | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1903 { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1904 ;
1905
1906direct_type:
1907 basic_type_name
1908 | type_qualifier_list basic_type_name
1909 { $$ = $2->addQualifiers( $1 ); }
1910 | direct_type type_qualifier
1911 { $$ = $1->addQualifiers( $2 ); }
1912 | direct_type basic_type_name
1913 { $$ = $1->addType( $2 ); }
1914 ;
1915
1916indirect_type:
1917 TYPEOF '(' type ')' // GCC: typeof( x ) y;
1918 { $$ = $3; }
1919 | TYPEOF '(' comma_expression ')' // GCC: typeof( a+b ) y;
1920 { $$ = DeclarationNode::newTypeof( $3 ); }
1921 | BASETYPEOF '(' type ')' // CFA: basetypeof( x ) y;
1922 { $$ = DeclarationNode::newTypeof( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ), true ); }
1923 | BASETYPEOF '(' comma_expression ')' // CFA: basetypeof( a+b ) y;
1924 { $$ = DeclarationNode::newTypeof( $3, true ); }
1925 | ZERO_T // CFA
1926 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1927 | ONE_T // CFA
1928 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1929 ;
1930
1931sue_declaration_specifier: // struct, union, enum + storage class + type specifier
1932 sue_type_specifier
1933 | declaration_qualifier_list sue_type_specifier
1934 { $$ = $2->addQualifiers( $1 ); }
1935 | sue_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1936 { $$ = $1->addQualifiers( $2 ); }
1937 | sue_declaration_specifier storage_class type_qualifier_list
1938 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1939 ;
1940
1941sue_type_specifier: // struct, union, enum + type specifier
1942 elaborated_type
1943 | type_qualifier_list
1944 { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1945 elaborated_type
1946 { $$ = $3->addQualifiers( $1 ); }
1947 | sue_type_specifier type_qualifier
1948 {
1949 if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
1950 $$ = $1->addQualifiers( $2 );
1951 }
1952 ;
1953
1954sue_declaration_specifier_nobody: // struct, union, enum - {...} + storage class + type specifier
1955 sue_type_specifier_nobody
1956 | declaration_qualifier_list sue_type_specifier_nobody
1957 { $$ = $2->addQualifiers( $1 ); }
1958 | sue_declaration_specifier_nobody storage_class // remaining OBSOLESCENT (see 2)
1959 { $$ = $1->addQualifiers( $2 ); }
1960 | sue_declaration_specifier_nobody storage_class type_qualifier_list
1961 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1962 ;
1963
1964sue_type_specifier_nobody: // struct, union, enum - {...} + type specifier
1965 elaborated_type_nobody
1966 | type_qualifier_list elaborated_type_nobody
1967 { $$ = $2->addQualifiers( $1 ); }
1968 | sue_type_specifier_nobody type_qualifier
1969 { $$ = $1->addQualifiers( $2 ); }
1970 ;
1971
1972type_declaration_specifier:
1973 type_type_specifier
1974 | declaration_qualifier_list type_type_specifier
1975 { $$ = $2->addQualifiers( $1 ); }
1976 | type_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1977 { $$ = $1->addQualifiers( $2 ); }
1978 | type_declaration_specifier storage_class type_qualifier_list
1979 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1980 ;
1981
1982type_type_specifier: // typedef types
1983 type_name
1984 | type_qualifier_list type_name
1985 { $$ = $2->addQualifiers( $1 ); }
1986 | type_type_specifier type_qualifier
1987 { $$ = $1->addQualifiers( $2 ); }
1988 ;
1989
1990type_name:
1991 TYPEDEFname
1992 { $$ = DeclarationNode::newFromTypedef( $1 ); }
1993 | '.' TYPEDEFname
1994 { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
1995 | type_name '.' TYPEDEFname
1996 { $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
1997 | typegen_name
1998 | '.' typegen_name
1999 { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
2000 | type_name '.' typegen_name
2001 { $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
2002 ;
2003
2004typegen_name: // CFA
2005 TYPEGENname
2006 { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2007 | TYPEGENname '(' ')'
2008 { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2009 | TYPEGENname '(' type_list ')'
2010 { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
2011 ;
2012
2013elaborated_type: // struct, union, enum
2014 aggregate_type
2015 | enum_type
2016 ;
2017
2018elaborated_type_nobody: // struct, union, enum - {...}
2019 aggregate_type_nobody
2020 | enum_type_nobody
2021 ;
2022
2023fred:
2024 // empty
2025 { yyy = false; }
2026 ;
2027
2028aggregate_type: // struct, union
2029 aggregate_key attribute_list_opt
2030 { forall = false; } // reset
2031 '{' field_declaration_list_opt '}' type_parameters_opt
2032 { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2033 | aggregate_key attribute_list_opt identifier fred
2034 {
2035 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2036 forall = false; // reset
2037 }
2038 '{' field_declaration_list_opt '}' type_parameters_opt
2039 { $$ = DeclarationNode::newAggregate( $1, $3, $9, $7, true )->addQualifiers( $2 ); }
2040 | aggregate_key attribute_list_opt type_name fred
2041 {
2042 // for type_name can be a qualified type name S.T, in which case only the last name in the chain needs a typedef (other names in the chain should already have one)
2043 typedefTable.makeTypedef( *$3->type->leafName(), forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2044 forall = false; // reset
2045 }
2046 '{' field_declaration_list_opt '}' type_parameters_opt
2047 { $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $9, $7, true )->addQualifiers( $2 ); }
2048 | aggregate_type_nobody
2049 ;
2050
2051type_parameters_opt:
2052 // empty
2053 { $$ = nullptr; } %prec '}'
2054 | '(' type_list ')'
2055 { $$ = $2; }
2056 ;
2057
2058aggregate_type_nobody: // struct, union - {...}
2059 aggregate_key attribute_list_opt identifier fred
2060 {
2061 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname );
2062 forall = false; // reset
2063 $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2064 }
2065 | aggregate_key attribute_list_opt type_name fred
2066 {
2067 forall = false; // reset
2068 // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2069 // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2070 // delete newFromTypeGen.
2071 $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2072 $3->type->symbolic.name = nullptr;
2073 $3->type->symbolic.actuals = nullptr;
2074 delete $3;
2075 }
2076 ;
2077
2078aggregate_key:
2079 aggregate_data
2080 | aggregate_control
2081 ;
2082
2083aggregate_data:
2084 STRUCT
2085 { yyy = true; $$ = AggregateDecl::Struct; }
2086 | UNION
2087 { yyy = true; $$ = AggregateDecl::Union; }
2088 | EXCEPTION // CFA
2089 { yyy = true; $$ = AggregateDecl::Exception; }
2090 ;
2091
2092aggregate_control: // CFA
2093 GENERATOR
2094 { yyy = true; $$ = AggregateDecl::Generator; }
2095 | MONITOR GENERATOR
2096 { SemanticError( yylloc, "monitor generator is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2097 | COROUTINE
2098 { yyy = true; $$ = AggregateDecl::Coroutine; }
2099 | MONITOR
2100 { yyy = true; $$ = AggregateDecl::Monitor; }
2101 | MONITOR COROUTINE
2102 { SemanticError( yylloc, "monitor coroutine is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2103 | THREAD
2104 { yyy = true; $$ = AggregateDecl::Thread; }
2105 | MONITOR THREAD
2106 { SemanticError( yylloc, "monitor thread is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2107 ;
2108
2109field_declaration_list_opt:
2110 // empty
2111 { $$ = nullptr; }
2112 | field_declaration_list_opt field_declaration
2113 { $$ = $1 ? $1->appendList( $2 ) : $2; }
2114 ;
2115
2116field_declaration:
2117 type_specifier field_declaring_list_opt ';'
2118 { $$ = fieldDecl( $1, $2 ); }
2119 | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2120 { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2121 | INLINE type_specifier field_abstract_list_opt ';' // CFA
2122 {
2123 if ( ! $3 ) { // field declarator ?
2124 $3 = DeclarationNode::newName( nullptr );
2125 } // if
2126 $3->inLine = true;
2127 $$ = distAttr( $2, $3 ); // mark all fields in list
2128 distInl( $3 );
2129 }
2130 | INLINE aggregate_control ';' // CFA
2131 { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2132 | typedef_declaration ';' // CFA
2133 | cfa_field_declaring_list ';' // CFA, new style field declaration
2134 | EXTENSION cfa_field_declaring_list ';' // GCC
2135 { distExt( $2 ); $$ = $2; } // mark all fields in list
2136 | INLINE cfa_field_abstract_list ';' // CFA, new style field declaration
2137 { $$ = $2; } // mark all fields in list
2138 | cfa_typedef_declaration ';' // CFA
2139 | static_assert // C11
2140 ;
2141
2142field_declaring_list_opt:
2143 // empty
2144 { $$ = nullptr; }
2145 | field_declarator
2146 | field_declaring_list_opt ',' attribute_list_opt field_declarator
2147 { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2148 ;
2149
2150field_declarator:
2151 bit_subrange_size // C special case, no field name
2152 { $$ = DeclarationNode::newBitfield( $1 ); }
2153 | variable_declarator bit_subrange_size_opt
2154 // A semantic check is required to ensure bit_subrange only appears on integral types.
2155 { $$ = $1->addBitfield( $2 ); }
2156 | variable_type_redeclarator bit_subrange_size_opt
2157 // A semantic check is required to ensure bit_subrange only appears on integral types.
2158 { $$ = $1->addBitfield( $2 ); }
2159 ;
2160
2161field_abstract_list_opt:
2162 // empty
2163 { $$ = nullptr; }
2164 | field_abstract
2165 | field_abstract_list_opt ',' attribute_list_opt field_abstract
2166 { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2167 ;
2168
2169field_abstract:
2170 // no bit fields
2171 variable_abstract_declarator
2172 ;
2173
2174cfa_field_declaring_list: // CFA, new style field declaration
2175 // bit-fields are handled by C declarations
2176 cfa_abstract_declarator_tuple identifier_or_type_name
2177 { $$ = $1->addName( $2 ); }
2178 | cfa_field_declaring_list ',' identifier_or_type_name
2179 { $$ = $1->appendList( $1->cloneType( $3 ) ); }
2180 ;
2181
2182cfa_field_abstract_list: // CFA, new style field declaration
2183 // bit-fields are handled by C declarations
2184 cfa_abstract_declarator_tuple
2185 | cfa_field_abstract_list ','
2186 { $$ = $1->appendList( $1->cloneType( 0 ) ); }
2187 ;
2188
2189bit_subrange_size_opt:
2190 // empty
2191 { $$ = nullptr; }
2192 | bit_subrange_size
2193 ;
2194
2195bit_subrange_size:
2196 ':' assignment_expression
2197 { $$ = $2; }
2198 ;
2199
2200enum_type: // enum
2201 ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2202 { $$ = DeclarationNode::newEnum( nullptr, $4, true )->addQualifiers( $2 ); }
2203 | ENUM attribute_list_opt identifier
2204 { typedefTable.makeTypedef( *$3 ); }
2205 '{' enumerator_list comma_opt '}'
2206 { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
2207 | ENUM attribute_list_opt type_name
2208 '{' enumerator_list comma_opt '}'
2209 { $$ = DeclarationNode::newEnum( $3->type->symbolic.name, $5, true )->addQualifiers( $2 ); }
2210 | enum_type_nobody
2211 ;
2212
2213enum_type_nobody: // enum - {...}
2214 ENUM attribute_list_opt identifier
2215 {
2216 typedefTable.makeTypedef( *$3 );
2217 $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 );
2218 }
2219 | ENUM attribute_list_opt type_name
2220 {
2221 typedefTable.makeTypedef( *$3->type->symbolic.name );
2222 $$ = DeclarationNode::newEnum( $3->type->symbolic.name, 0, false )->addQualifiers( $2 );
2223 }
2224 ;
2225
2226enumerator_list:
2227 identifier_or_type_name enumerator_value_opt
2228 { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
2229 | enumerator_list ',' identifier_or_type_name enumerator_value_opt
2230 { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
2231 ;
2232
2233enumerator_value_opt:
2234 // empty
2235 { $$ = nullptr; }
2236 | '=' constant_expression
2237 { $$ = $2; }
2238 ;
2239
2240cfa_parameter_ellipsis_list_opt: // CFA, abstract + real
2241 // empty
2242 { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2243 | ELLIPSIS
2244 { $$ = nullptr; }
2245 | cfa_abstract_parameter_list
2246 | cfa_parameter_list
2247 | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2248 { $$ = $1->appendList( $5 ); }
2249 | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2250 { $$ = $1->addVarArgs(); }
2251 | cfa_parameter_list pop ',' push ELLIPSIS
2252 { $$ = $1->addVarArgs(); }
2253 ;
2254
2255cfa_parameter_list: // CFA
2256 // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2257 // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2258 cfa_parameter_declaration
2259 | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2260 { $$ = $1->appendList( $5 ); }
2261 | cfa_parameter_list pop ',' push cfa_parameter_declaration
2262 { $$ = $1->appendList( $5 ); }
2263 | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2264 { $$ = $1->appendList( $5 )->appendList( $9 ); }
2265 ;
2266
2267cfa_abstract_parameter_list: // CFA, new & old style abstract
2268 cfa_abstract_parameter_declaration
2269 | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2270 { $$ = $1->appendList( $5 ); }
2271 ;
2272
2273parameter_type_list_opt:
2274 // empty
2275 { $$ = nullptr; }
2276 | ELLIPSIS
2277 { $$ = nullptr; }
2278 | parameter_list
2279 | parameter_list pop ',' push ELLIPSIS
2280 { $$ = $1->addVarArgs(); }
2281 ;
2282
2283parameter_list: // abstract + real
2284 abstract_parameter_declaration
2285 | parameter_declaration
2286 | parameter_list pop ',' push abstract_parameter_declaration
2287 { $$ = $1->appendList( $5 ); }
2288 | parameter_list pop ',' push parameter_declaration
2289 { $$ = $1->appendList( $5 ); }
2290 ;
2291
2292// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2293// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2294
2295cfa_parameter_declaration: // CFA, new & old style parameter declaration
2296 parameter_declaration
2297 | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initialize_opt
2298 { $$ = $1->addName( $2 ); }
2299 | cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2300 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2301 { $$ = $1->addName( $2 ); }
2302 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2303 { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2304 | cfa_function_specifier
2305 ;
2306
2307cfa_abstract_parameter_declaration: // CFA, new & old style parameter declaration
2308 abstract_parameter_declaration
2309 | cfa_identifier_parameter_declarator_no_tuple
2310 | cfa_abstract_tuple
2311 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2312 | type_qualifier_list cfa_abstract_tuple
2313 { $$ = $2->addQualifiers( $1 ); }
2314 | cfa_abstract_function
2315 ;
2316
2317parameter_declaration:
2318 // No SUE declaration in parameter list.
2319 declaration_specifier_nobody identifier_parameter_declarator default_initialize_opt
2320 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2321 | declaration_specifier_nobody type_parameter_redeclarator default_initialize_opt
2322 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2323 ;
2324
2325abstract_parameter_declaration:
2326 declaration_specifier_nobody default_initialize_opt
2327 { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2328 | declaration_specifier_nobody abstract_parameter_declarator default_initialize_opt
2329 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2330 ;
2331
2332// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2333// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2334// identifiers. The ANSI-style parameter-list can redefine a typedef name.
2335
2336identifier_list: // K&R-style parameter list => no types
2337 identifier
2338 { $$ = DeclarationNode::newName( $1 ); }
2339 | identifier_list ',' identifier
2340 { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2341 ;
2342
2343identifier_or_type_name:
2344 identifier
2345 | TYPEDEFname
2346 | TYPEGENname
2347 ;
2348
2349type_no_function: // sizeof, alignof, cast (constructor)
2350 cfa_abstract_declarator_tuple // CFA
2351 | type_specifier
2352 | type_specifier abstract_declarator
2353 { $$ = $2->addType( $1 ); }
2354 ;
2355
2356type: // typeof, assertion
2357 type_no_function
2358 | cfa_abstract_function // CFA
2359 ;
2360
2361initializer_opt:
2362 // empty
2363 { $$ = nullptr; }
2364 | '=' initializer
2365 { $$ = $2; }
2366 | '=' VOID
2367 { $$ = new InitializerNode( true ); }
2368 | ATassign initializer
2369 { $$ = $2->set_maybeConstructed( false ); }
2370 ;
2371
2372initializer:
2373 assignment_expression { $$ = new InitializerNode( $1 ); }
2374 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
2375 ;
2376
2377initializer_list_opt:
2378 // empty
2379 { $$ = nullptr; }
2380 | initializer
2381 | designation initializer { $$ = $2->set_designators( $1 ); }
2382 | initializer_list_opt ',' initializer { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2383 | initializer_list_opt ',' designation initializer
2384 { $$ = (InitializerNode *)($1->set_last( $4->set_designators( $3 ) )); }
2385 ;
2386
2387// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2388// '=' to separator the designator from the initializer value, as in:
2389//
2390// int x[10] = { [1] = 3 };
2391//
2392// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment. To disambiguate this case, CFA
2393// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2394// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2395// shift/reduce conflicts
2396
2397designation:
2398 designator_list ':' // C99, CFA uses ":" instead of "="
2399 | identifier ':' // GCC, field name
2400 { $$ = new ExpressionNode( build_varref( $1 ) ); }
2401 ;
2402
2403designator_list: // C99
2404 designator
2405 | designator_list designator
2406 { $$ = (ExpressionNode *)($1->set_last( $2 )); }
2407 //| designator_list designator { $$ = new ExpressionNode( $1, $2 ); }
2408 ;
2409
2410designator:
2411 '.' identifier // C99, field name
2412 { $$ = new ExpressionNode( build_varref( $2 ) ); }
2413 | '[' push assignment_expression pop ']' // C99, single array element
2414 // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2415 { $$ = $3; }
2416 | '[' push subrange pop ']' // CFA, multiple array elements
2417 { $$ = $3; }
2418 | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2419 { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $3 ), maybeMoveBuild< Expression >( $5 ) ) ); }
2420 | '.' '[' push field_name_list pop ']' // CFA, tuple field selector
2421 { $$ = $4; }
2422 ;
2423
2424// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2425// rather than an object-oriented type system. This required four groups of extensions:
2426//
2427// Overloading: function, data, and operator identifiers may be overloaded.
2428//
2429// Type declarations: "type" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2430// and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2431// definitions of new types. Type declarations with storage class "extern" provide opaque types.
2432//
2433// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2434// site. A polymorphic function is not a template; it is a function, with an address and a type.
2435//
2436// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2437// types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2438// hierarchies. Unlike classes, they can define relationships between types. Assertions declare that a type or
2439// types provide the operations declared by a specification. Assertions are normally used to declare requirements
2440// on type arguments of polymorphic functions.
2441
2442type_parameter_list: // CFA
2443 type_parameter
2444 | type_parameter_list ',' type_parameter
2445 { $$ = $1->appendList( $3 ); }
2446 ;
2447
2448type_initializer_opt: // CFA
2449 // empty
2450 { $$ = nullptr; }
2451 | '=' type
2452 { $$ = $2; }
2453 ;
2454
2455type_parameter: // CFA
2456 type_class identifier_or_type_name
2457 { typedefTable.addToScope( *$2, TYPEDEFname, "9" ); }
2458 type_initializer_opt assertion_list_opt
2459 { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2460 | type_specifier identifier_parameter_declarator
2461 | assertion_list
2462 { $$ = DeclarationNode::newTypeParam( TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2463 ;
2464
2465type_class: // CFA
2466 OTYPE
2467 { $$ = TypeDecl::Otype; }
2468 | DTYPE
2469 { $$ = TypeDecl::Dtype; }
2470 | FTYPE
2471 { $$ = TypeDecl::Ftype; }
2472 | TTYPE
2473 { $$ = TypeDecl::Ttype; }
2474 ;
2475
2476assertion_list_opt: // CFA
2477 // empty
2478 { $$ = nullptr; }
2479 | assertion_list
2480 ;
2481
2482assertion_list: // CFA
2483 assertion
2484 | assertion_list assertion
2485 { $$ = $1 ? $1->appendList( $2 ) : $2; }
2486 ;
2487
2488assertion: // CFA
2489 '|' identifier_or_type_name '(' type_list ')'
2490 { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
2491 | '|' '{' push trait_declaration_list pop '}'
2492 { $$ = $4; }
2493 // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
2494 // { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
2495 ;
2496
2497type_list: // CFA
2498 type
2499 { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2500 | assignment_expression
2501 { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $1->build()) ); $$ = nullptr; }
2502 | type_list ',' type
2503 { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) )); }
2504 | type_list ',' assignment_expression
2505 { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $3->build()) ); $$ = nullptr; }
2506 // { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2507 ;
2508
2509type_declaring_list: // CFA
2510 OTYPE type_declarator
2511 { $$ = $2; }
2512 | storage_class_list OTYPE type_declarator
2513 { $$ = $3->addQualifiers( $1 ); }
2514 | type_declaring_list ',' type_declarator
2515 { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2516 ;
2517
2518type_declarator: // CFA
2519 type_declarator_name assertion_list_opt
2520 { $$ = $1->addAssertions( $2 ); }
2521 | type_declarator_name assertion_list_opt '=' type
2522 { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2523 ;
2524
2525type_declarator_name: // CFA
2526 identifier_or_type_name
2527 {
2528 typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "10" );
2529 $$ = DeclarationNode::newTypeDecl( $1, 0 );
2530 }
2531 | identifier_or_type_name '(' type_parameter_list ')'
2532 {
2533 typedefTable.addToEnclosingScope( *$1, TYPEGENname, "11" );
2534 $$ = DeclarationNode::newTypeDecl( $1, $3 );
2535 }
2536 ;
2537
2538trait_specifier: // CFA
2539 TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
2540 { $$ = DeclarationNode::newTrait( $2, $4, 0 ); }
2541 | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
2542 { $$ = DeclarationNode::newTrait( $2, $4, $8 ); }
2543 ;
2544
2545trait_declaration_list: // CFA
2546 trait_declaration
2547 | trait_declaration_list pop push trait_declaration
2548 { $$ = $1->appendList( $4 ); }
2549 ;
2550
2551trait_declaration: // CFA
2552 cfa_trait_declaring_list ';'
2553 | trait_declaring_list ';'
2554 ;
2555
2556cfa_trait_declaring_list: // CFA
2557 cfa_variable_specifier
2558 | cfa_function_specifier
2559 | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2560 { $$ = $1->appendList( $1->cloneType( $5 ) ); }
2561 ;
2562
2563trait_declaring_list: // CFA
2564 type_specifier declarator
2565 { $$ = $2->addType( $1 ); }
2566 | trait_declaring_list pop ',' push declarator
2567 { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
2568 ;
2569
2570//***************************** EXTERNAL DEFINITIONS *****************************
2571
2572translation_unit:
2573 // empty, input file
2574 | external_definition_list
2575 { parseTree = parseTree ? parseTree->appendList( $1 ) : $1; }
2576 ;
2577
2578external_definition_list:
2579 push external_definition pop
2580 { $$ = $2; }
2581 | external_definition_list push external_definition pop
2582 { $$ = $1 ? $1->appendList( $3 ) : $3; }
2583 ;
2584
2585external_definition_list_opt:
2586 // empty
2587 { $$ = nullptr; }
2588 | external_definition_list
2589 ;
2590
2591up:
2592 { typedefTable.up( forall ); forall = false; }
2593 ;
2594
2595down:
2596 { typedefTable.down(); }
2597 ;
2598
2599external_definition:
2600 declaration
2601 | external_function_definition
2602 | EXTENSION external_definition // GCC, multiple __extension__ allowed, meaning unknown
2603 {
2604 distExt( $2 ); // mark all fields in list
2605 $$ = $2;
2606 }
2607 | ASM '(' string_literal ')' ';' // GCC, global assembler statement
2608 {
2609 $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( false, $3, 0 ) ) );
2610 }
2611 | EXTERN STRINGliteral // C++-style linkage specifier
2612 {
2613 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
2614 linkage = LinkageSpec::update( yylloc, linkage, $2 );
2615 }
2616 '{' up external_definition_list_opt down '}'
2617 {
2618 linkage = linkageStack.top();
2619 linkageStack.pop();
2620 $$ = $6;
2621 }
2622 | type_qualifier_list
2623 {
2624 if ( $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2625 if ( $1->type->forall ) forall = true; // remember generic type
2626 }
2627 '{' up external_definition_list_opt down '}' // CFA, namespace
2628 {
2629 distQual( $5, $1 );
2630 forall = false;
2631 $$ = $5;
2632 }
2633 | declaration_qualifier_list
2634 {
2635 if ( $1->type && $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2636 if ( $1->type && $1->type->forall ) forall = true; // remember generic type
2637 }
2638 '{' up external_definition_list_opt down '}' // CFA, namespace
2639 {
2640 distQual( $5, $1 );
2641 forall = false;
2642 $$ = $5;
2643 }
2644 | declaration_qualifier_list type_qualifier_list
2645 {
2646 if ( ($1->type && $1->type->qualifiers.val) || $2->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2647 if ( ($1->type && $1->type->forall) || $2->type->forall ) forall = true; // remember generic type
2648 }
2649 '{' up external_definition_list_opt down '}' // CFA, namespace
2650 {
2651 distQual( $6, $1->addQualifiers( $2 ) );
2652 forall = false;
2653 $$ = $6;
2654 }
2655 ;
2656
2657external_function_definition:
2658 function_definition
2659 // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2660 // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2661 // Parsing is possible because function_definition does not appear in the context of an expression (nested
2662 // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2663 // declaration must still have a type_specifier. OBSOLESCENT (see 1)
2664 | function_declarator compound_statement
2665 { $$ = $1->addFunctionBody( $2 ); }
2666 | KR_function_declarator KR_parameter_list_opt compound_statement
2667 { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
2668 ;
2669
2670with_clause_opt:
2671 // empty
2672 { $$ = nullptr; forall = false; }
2673 | WITH '(' tuple_expression_list ')'
2674 { $$ = $3; forall = false; }
2675 ;
2676
2677function_definition:
2678 cfa_function_declaration with_clause_opt compound_statement // CFA
2679 {
2680 // Add the function body to the last identifier in the function definition list, i.e., foo3:
2681 // [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2682 $1->get_last()->addFunctionBody( $3, $2 );
2683 $$ = $1;
2684 }
2685 | declaration_specifier function_declarator with_clause_opt compound_statement
2686 {
2687 rebindForall( $1, $2 );
2688 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2689 }
2690 | declaration_specifier variable_type_redeclarator with_clause_opt compound_statement
2691 {
2692 rebindForall( $1, $2 );
2693 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2694 }
2695 // handles default int return type, OBSOLESCENT (see 1)
2696 | type_qualifier_list function_declarator with_clause_opt compound_statement
2697 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2698 // handles default int return type, OBSOLESCENT (see 1)
2699 | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2700 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2701 // handles default int return type, OBSOLESCENT (see 1)
2702 | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2703 { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2704
2705 // Old-style K&R function definition, OBSOLESCENT (see 4)
2706 | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2707 {
2708 rebindForall( $1, $2 );
2709 $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2710 }
2711 // handles default int return type, OBSOLESCENT (see 1)
2712 | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2713 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2714 // handles default int return type, OBSOLESCENT (see 1)
2715 | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2716 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2717 // handles default int return type, OBSOLESCENT (see 1)
2718 | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2719 { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2720 ;
2721
2722declarator:
2723 variable_declarator
2724 | variable_type_redeclarator
2725 | function_declarator
2726 ;
2727
2728subrange:
2729 constant_expression '~' constant_expression // CFA, integer subrange
2730 { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
2731 ;
2732
2733asm_name_opt: // GCC
2734 // empty
2735 { $$ = nullptr; }
2736 | ASM '(' string_literal ')' attribute_list_opt
2737 {
2738 DeclarationNode * name = new DeclarationNode();
2739 name->asmName = $3;
2740 $$ = name->addQualifiers( $5 );
2741 }
2742 ;
2743
2744attribute_list_opt: // GCC
2745 // empty
2746 { $$ = nullptr; }
2747 | attribute_list
2748 ;
2749
2750attribute_list: // GCC
2751 attribute
2752 | attribute_list attribute
2753 { $$ = $2->addQualifiers( $1 ); }
2754 ;
2755
2756attribute: // GCC
2757 ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2758 { $$ = $4; }
2759 ;
2760
2761attribute_name_list: // GCC
2762 attribute_name
2763 | attribute_name_list ',' attribute_name
2764 { $$ = $3->addQualifiers( $1 ); }
2765 ;
2766
2767attribute_name: // GCC
2768 // empty
2769 { $$ = nullptr; }
2770 | attr_name
2771 { $$ = DeclarationNode::newAttribute( $1 ); }
2772 | attr_name '(' argument_expression_list ')'
2773 { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2774 ;
2775
2776attr_name: // GCC
2777 IDENTIFIER
2778 | quasi_keyword
2779 | TYPEDEFname
2780 | TYPEGENname
2781 | FALLTHROUGH
2782 { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2783 | CONST
2784 { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2785 ;
2786
2787// ============================================================================
2788// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2789// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2790// in:
2791//
2792// int (*f())[10] { ... };
2793// ... (*f())[3] += 1; // definition mimics usage
2794//
2795// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2796// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2797// ============================================================================
2798
2799// ----------------------------------------------------------------------------
2800// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2801// to define a variable or function prototype, e.g.:
2802//
2803// valid declaration invalid definition
2804// ----------------- ------------------
2805// int f; int f {}
2806// int *f; int *f {}
2807// int f[10]; int f[10] {}
2808// int (*f)(int); int (*f)(int) {}
2809//
2810// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2811// variable_declarator and function_declarator.
2812// ----------------------------------------------------------------------------
2813
2814// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2815// declaring an array of functions versus a pointer to an array of functions.
2816
2817variable_declarator:
2818 paren_identifier attribute_list_opt
2819 { $$ = $1->addQualifiers( $2 ); }
2820 | variable_ptr
2821 | variable_array attribute_list_opt
2822 { $$ = $1->addQualifiers( $2 ); }
2823 | variable_function attribute_list_opt
2824 { $$ = $1->addQualifiers( $2 ); }
2825 ;
2826
2827paren_identifier:
2828 identifier
2829 { $$ = DeclarationNode::newName( $1 ); }
2830 | '(' paren_identifier ')' // redundant parenthesis
2831 { $$ = $2; }
2832 ;
2833
2834variable_ptr:
2835 ptrref_operator variable_declarator
2836 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2837 | ptrref_operator type_qualifier_list variable_declarator
2838 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2839 | '(' variable_ptr ')' attribute_list_opt
2840 { $$ = $2->addQualifiers( $4 ); } // redundant parenthesis
2841 ;
2842
2843variable_array:
2844 paren_identifier array_dimension
2845 { $$ = $1->addArray( $2 ); }
2846 | '(' variable_ptr ')' array_dimension
2847 { $$ = $2->addArray( $4 ); }
2848 | '(' variable_array ')' multi_array_dimension // redundant parenthesis
2849 { $$ = $2->addArray( $4 ); }
2850 | '(' variable_array ')' // redundant parenthesis
2851 { $$ = $2; }
2852 ;
2853
2854variable_function:
2855 '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2856 { $$ = $2->addParamList( $6 ); }
2857 | '(' variable_function ')' // redundant parenthesis
2858 { $$ = $2; }
2859 ;
2860
2861// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2862// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2863// is the same scope. The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2864
2865function_declarator:
2866 function_no_ptr attribute_list_opt
2867 { $$ = $1->addQualifiers( $2 ); }
2868 | function_ptr
2869 | function_array attribute_list_opt
2870 { $$ = $1->addQualifiers( $2 ); }
2871 ;
2872
2873function_no_ptr:
2874 paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2875 { $$ = $1->addParamList( $4 ); }
2876 | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2877 { $$ = $2->addParamList( $6 ); }
2878 | '(' function_no_ptr ')' // redundant parenthesis
2879 { $$ = $2; }
2880 ;
2881
2882function_ptr:
2883 ptrref_operator function_declarator
2884 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2885 | ptrref_operator type_qualifier_list function_declarator
2886 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2887 | '(' function_ptr ')'
2888 { $$ = $2; }
2889 ;
2890
2891function_array:
2892 '(' function_ptr ')' array_dimension
2893 { $$ = $2->addArray( $4 ); }
2894 | '(' function_array ')' multi_array_dimension // redundant parenthesis
2895 { $$ = $2->addArray( $4 ); }
2896 | '(' function_array ')' // redundant parenthesis
2897 { $$ = $2; }
2898 ;
2899
2900// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
2901//
2902// f( a, b, c ) int a, *b, c[]; {}
2903//
2904// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
2905// returning arrays and functions versus pointers to arrays and functions.
2906
2907KR_function_declarator:
2908 KR_function_no_ptr
2909 | KR_function_ptr
2910 | KR_function_array
2911 ;
2912
2913KR_function_no_ptr:
2914 paren_identifier '(' identifier_list ')' // function_declarator handles empty parameter
2915 { $$ = $1->addIdList( $3 ); }
2916 | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
2917 { $$ = $2->addParamList( $6 ); }
2918 | '(' KR_function_no_ptr ')' // redundant parenthesis
2919 { $$ = $2; }
2920 ;
2921
2922KR_function_ptr:
2923 ptrref_operator KR_function_declarator
2924 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2925 | ptrref_operator type_qualifier_list KR_function_declarator
2926 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2927 | '(' KR_function_ptr ')'
2928 { $$ = $2; }
2929 ;
2930
2931KR_function_array:
2932 '(' KR_function_ptr ')' array_dimension
2933 { $$ = $2->addArray( $4 ); }
2934 | '(' KR_function_array ')' multi_array_dimension // redundant parenthesis
2935 { $$ = $2->addArray( $4 ); }
2936 | '(' KR_function_array ')' // redundant parenthesis
2937 { $$ = $2; }
2938 ;
2939
2940// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2941//
2942// typedef int foo;
2943// {
2944// int foo; // redefine typedef name in new scope
2945// }
2946//
2947// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2948// and functions versus pointers to arrays and functions.
2949
2950variable_type_redeclarator:
2951 paren_type attribute_list_opt
2952 { $$ = $1->addQualifiers( $2 ); }
2953 | type_ptr
2954 | type_array attribute_list_opt
2955 { $$ = $1->addQualifiers( $2 ); }
2956 | type_function attribute_list_opt
2957 { $$ = $1->addQualifiers( $2 ); }
2958 ;
2959
2960paren_type:
2961 typedef
2962 // hide type name in enclosing scope by variable name
2963 {
2964 // if ( ! typedefTable.existsCurr( *$1->name ) ) {
2965 typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "ID" );
2966 // } else {
2967 // SemanticError( yylloc, string("'") + *$1->name + "' redeclared as different kind of symbol." ); $$ = nullptr;
2968 // } // if
2969 }
2970 | '(' paren_type ')'
2971 { $$ = $2; }
2972 ;
2973
2974type_ptr:
2975 ptrref_operator variable_type_redeclarator
2976 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2977 | ptrref_operator type_qualifier_list variable_type_redeclarator
2978 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2979 | '(' type_ptr ')' attribute_list_opt
2980 { $$ = $2->addQualifiers( $4 ); } // redundant parenthesis
2981 ;
2982
2983type_array:
2984 paren_type array_dimension
2985 { $$ = $1->addArray( $2 ); }
2986 | '(' type_ptr ')' array_dimension
2987 { $$ = $2->addArray( $4 ); }
2988 | '(' type_array ')' multi_array_dimension // redundant parenthesis
2989 { $$ = $2->addArray( $4 ); }
2990 | '(' type_array ')' // redundant parenthesis
2991 { $$ = $2; }
2992 ;
2993
2994type_function:
2995 paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2996 { $$ = $1->addParamList( $4 ); }
2997 | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2998 { $$ = $2->addParamList( $6 ); }
2999 | '(' type_function ')' // redundant parenthesis
3000 { $$ = $2; }
3001 ;
3002
3003// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
3004// typedef name and allows the C99 array options, which can only appear in a parameter list. The pattern precludes
3005// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
3006// pointers to arrays and functions.
3007
3008identifier_parameter_declarator:
3009 paren_identifier attribute_list_opt
3010 { $$ = $1->addQualifiers( $2 ); }
3011 | '&' MUTEX paren_identifier attribute_list_opt
3012 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3013 | identifier_parameter_ptr
3014 | identifier_parameter_array attribute_list_opt
3015 { $$ = $1->addQualifiers( $2 ); }
3016 | identifier_parameter_function attribute_list_opt
3017 { $$ = $1->addQualifiers( $2 ); }
3018 ;
3019
3020identifier_parameter_ptr:
3021 ptrref_operator identifier_parameter_declarator
3022 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3023 | ptrref_operator type_qualifier_list identifier_parameter_declarator
3024 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3025 | '(' identifier_parameter_ptr ')' attribute_list_opt
3026 { $$ = $2->addQualifiers( $4 ); }
3027 ;
3028
3029identifier_parameter_array:
3030 paren_identifier array_parameter_dimension
3031 { $$ = $1->addArray( $2 ); }
3032 | '(' identifier_parameter_ptr ')' array_dimension
3033 { $$ = $2->addArray( $4 ); }
3034 | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3035 { $$ = $2->addArray( $4 ); }
3036 | '(' identifier_parameter_array ')' // redundant parenthesis
3037 { $$ = $2; }
3038 ;
3039
3040identifier_parameter_function:
3041 paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3042 { $$ = $1->addParamList( $4 ); }
3043 | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3044 { $$ = $2->addParamList( $6 ); }
3045 | '(' identifier_parameter_function ')' // redundant parenthesis
3046 { $$ = $2; }
3047 ;
3048
3049// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3050// e.g.:
3051//
3052// typedef int foo;
3053// forall( otype T ) struct foo;
3054// int f( int foo ); // redefine typedef name in new scope
3055//
3056// and allows the C99 array options, which can only appear in a parameter list.
3057
3058type_parameter_redeclarator:
3059 typedef attribute_list_opt
3060 { $$ = $1->addQualifiers( $2 ); }
3061 | '&' MUTEX typedef attribute_list_opt
3062 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3063 | type_parameter_ptr
3064 | type_parameter_array attribute_list_opt
3065 { $$ = $1->addQualifiers( $2 ); }
3066 | type_parameter_function attribute_list_opt
3067 { $$ = $1->addQualifiers( $2 ); }
3068 ;
3069
3070typedef:
3071 TYPEDEFname
3072 { $$ = DeclarationNode::newName( $1 ); }
3073 | TYPEGENname
3074 { $$ = DeclarationNode::newName( $1 ); }
3075 ;
3076
3077type_parameter_ptr:
3078 ptrref_operator type_parameter_redeclarator
3079 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3080 | ptrref_operator type_qualifier_list type_parameter_redeclarator
3081 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3082 | '(' type_parameter_ptr ')' attribute_list_opt
3083 { $$ = $2->addQualifiers( $4 ); }
3084 ;
3085
3086type_parameter_array:
3087 typedef array_parameter_dimension
3088 { $$ = $1->addArray( $2 ); }
3089 | '(' type_parameter_ptr ')' array_parameter_dimension
3090 { $$ = $2->addArray( $4 ); }
3091 ;
3092
3093type_parameter_function:
3094 typedef '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3095 { $$ = $1->addParamList( $4 ); }
3096 | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3097 { $$ = $2->addParamList( $6 ); }
3098 ;
3099
3100// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3101// which the type applies, e.g.:
3102//
3103// sizeof( int );
3104// sizeof( int * );
3105// sizeof( int [10] );
3106// sizeof( int (*)() );
3107// sizeof( int () );
3108//
3109// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3110// and functions versus pointers to arrays and functions.
3111
3112abstract_declarator:
3113 abstract_ptr
3114 | abstract_array attribute_list_opt
3115 { $$ = $1->addQualifiers( $2 ); }
3116 | abstract_function attribute_list_opt
3117 { $$ = $1->addQualifiers( $2 ); }
3118 ;
3119
3120abstract_ptr:
3121 ptrref_operator
3122 { $$ = DeclarationNode::newPointer( 0, $1 ); }
3123 | ptrref_operator type_qualifier_list
3124 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3125 | ptrref_operator abstract_declarator
3126 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3127 | ptrref_operator type_qualifier_list abstract_declarator
3128 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3129 | '(' abstract_ptr ')' attribute_list_opt
3130 { $$ = $2->addQualifiers( $4 ); }
3131 ;
3132
3133abstract_array:
3134 array_dimension
3135 | '(' abstract_ptr ')' array_dimension
3136 { $$ = $2->addArray( $4 ); }
3137 | '(' abstract_array ')' multi_array_dimension // redundant parenthesis
3138 { $$ = $2->addArray( $4 ); }
3139 | '(' abstract_array ')' // redundant parenthesis
3140 { $$ = $2; }
3141 ;
3142
3143abstract_function:
3144 '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3145 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3146 | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3147 { $$ = $2->addParamList( $6 ); }
3148 | '(' abstract_function ')' // redundant parenthesis
3149 { $$ = $2; }
3150 ;
3151
3152array_dimension:
3153 // Only the first dimension can be empty.
3154 '[' ']'
3155 { $$ = DeclarationNode::newArray( 0, 0, false ); }
3156 | '[' ']' multi_array_dimension
3157 { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
3158 | multi_array_dimension
3159 ;
3160
3161multi_array_dimension:
3162 '[' push assignment_expression pop ']'
3163 { $$ = DeclarationNode::newArray( $3, 0, false ); }
3164 | '[' push '*' pop ']' // C99
3165 { $$ = DeclarationNode::newVarArray( 0 ); }
3166 | multi_array_dimension '[' push assignment_expression pop ']'
3167 { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
3168 | multi_array_dimension '[' push '*' pop ']' // C99
3169 { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3170 ;
3171
3172// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3173// identifier to which the type applies, e.g.:
3174//
3175// int f( int ); // not handled here
3176// int f( int * ); // abstract function-prototype parameter; no parameter name specified
3177// int f( int (*)() ); // abstract function-prototype parameter; no parameter name specified
3178// int f( int (int) ); // abstract function-prototype parameter; no parameter name specified
3179//
3180// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3181// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3182// special meaning of parenthesis around a typedef name:
3183//
3184// ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3185// parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3186// not as redundant parentheses around the identifier."
3187//
3188// For example:
3189//
3190// typedef float T;
3191// int f( int ( T [5] ) ); // see abstract_parameter_declarator
3192// int g( int ( T ( int ) ) ); // see abstract_parameter_declarator
3193// int f( int f1( T a[5] ) ); // see identifier_parameter_declarator
3194// int g( int g1( T g2( int p ) ) ); // see identifier_parameter_declarator
3195//
3196// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3197// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3198// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3199// functions.
3200
3201abstract_parameter_declarator:
3202 abstract_parameter_ptr
3203 | '&' MUTEX attribute_list_opt
3204 { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3205 | abstract_parameter_array attribute_list_opt
3206 { $$ = $1->addQualifiers( $2 ); }
3207 | abstract_parameter_function attribute_list_opt
3208 { $$ = $1->addQualifiers( $2 ); }
3209 ;
3210
3211abstract_parameter_ptr:
3212 ptrref_operator
3213 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3214 | ptrref_operator type_qualifier_list
3215 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3216 | ptrref_operator abstract_parameter_declarator
3217 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3218 | ptrref_operator type_qualifier_list abstract_parameter_declarator
3219 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3220 | '(' abstract_parameter_ptr ')' attribute_list_opt
3221 { $$ = $2->addQualifiers( $4 ); }
3222 ;
3223
3224abstract_parameter_array:
3225 array_parameter_dimension
3226 | '(' abstract_parameter_ptr ')' array_parameter_dimension
3227 { $$ = $2->addArray( $4 ); }
3228 | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3229 { $$ = $2->addArray( $4 ); }
3230 | '(' abstract_parameter_array ')' // redundant parenthesis
3231 { $$ = $2; }
3232 ;
3233
3234abstract_parameter_function:
3235 '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3236 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3237 | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3238 { $$ = $2->addParamList( $6 ); }
3239 | '(' abstract_parameter_function ')' // redundant parenthesis
3240 { $$ = $2; }
3241 ;
3242
3243array_parameter_dimension:
3244 // Only the first dimension can be empty or have qualifiers.
3245 array_parameter_1st_dimension
3246 | array_parameter_1st_dimension multi_array_dimension
3247 { $$ = $1->addArray( $2 ); }
3248 | multi_array_dimension
3249 ;
3250
3251// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3252//
3253// ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3254// a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3255
3256array_parameter_1st_dimension:
3257 '[' ']'
3258 { $$ = DeclarationNode::newArray( 0, 0, false ); }
3259 // multi_array_dimension handles the '[' '*' ']' case
3260 | '[' push type_qualifier_list '*' pop ']' // remaining C99
3261 { $$ = DeclarationNode::newVarArray( $3 ); }
3262 | '[' push type_qualifier_list pop ']'
3263 { $$ = DeclarationNode::newArray( 0, $3, false ); }
3264 // multi_array_dimension handles the '[' assignment_expression ']' case
3265 | '[' push type_qualifier_list assignment_expression pop ']'
3266 { $$ = DeclarationNode::newArray( $4, $3, false ); }
3267 | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3268 { $$ = DeclarationNode::newArray( $5, $4, true ); }
3269 | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3270 { $$ = DeclarationNode::newArray( $5, $3, true ); }
3271 ;
3272
3273// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3274//
3275// struct S {
3276// int;
3277// int *;
3278// int [10];
3279// int (*)();
3280// };
3281
3282variable_abstract_declarator:
3283 variable_abstract_ptr
3284 | variable_abstract_array attribute_list_opt
3285 { $$ = $1->addQualifiers( $2 ); }
3286 | variable_abstract_function attribute_list_opt
3287 { $$ = $1->addQualifiers( $2 ); }
3288 ;
3289
3290variable_abstract_ptr:
3291 ptrref_operator
3292 { $$ = DeclarationNode::newPointer( 0, $1 ); }
3293 | ptrref_operator type_qualifier_list
3294 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3295 | ptrref_operator variable_abstract_declarator
3296 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3297 | ptrref_operator type_qualifier_list variable_abstract_declarator
3298 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3299 | '(' variable_abstract_ptr ')' attribute_list_opt
3300 { $$ = $2->addQualifiers( $4 ); }
3301 ;
3302
3303variable_abstract_array:
3304 array_dimension
3305 | '(' variable_abstract_ptr ')' array_dimension
3306 { $$ = $2->addArray( $4 ); }
3307 | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3308 { $$ = $2->addArray( $4 ); }
3309 | '(' variable_abstract_array ')' // redundant parenthesis
3310 { $$ = $2; }
3311 ;
3312
3313variable_abstract_function:
3314 '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3315 { $$ = $2->addParamList( $6 ); }
3316 | '(' variable_abstract_function ')' // redundant parenthesis
3317 { $$ = $2; }
3318 ;
3319
3320// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3321// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3322
3323cfa_identifier_parameter_declarator_tuple: // CFA
3324 cfa_identifier_parameter_declarator_no_tuple
3325 | cfa_abstract_tuple
3326 | type_qualifier_list cfa_abstract_tuple
3327 { $$ = $2->addQualifiers( $1 ); }
3328 ;
3329
3330cfa_identifier_parameter_declarator_no_tuple: // CFA
3331 cfa_identifier_parameter_ptr
3332 | cfa_identifier_parameter_array
3333 ;
3334
3335cfa_identifier_parameter_ptr: // CFA
3336 // No SUE declaration in parameter list.
3337 ptrref_operator type_specifier_nobody
3338 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3339 | type_qualifier_list ptrref_operator type_specifier_nobody
3340 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3341 | ptrref_operator cfa_abstract_function
3342 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3343 | type_qualifier_list ptrref_operator cfa_abstract_function
3344 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3345 | ptrref_operator cfa_identifier_parameter_declarator_tuple
3346 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3347 | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3348 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3349 ;
3350
3351cfa_identifier_parameter_array: // CFA
3352 // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3353 // shift/reduce conflict with new-style empty (void) function return type.
3354 '[' ']' type_specifier_nobody
3355 { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3356 | cfa_array_parameter_1st_dimension type_specifier_nobody
3357 { $$ = $2->addNewArray( $1 ); }
3358 | '[' ']' multi_array_dimension type_specifier_nobody
3359 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3360 | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3361 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3362 | multi_array_dimension type_specifier_nobody
3363 { $$ = $2->addNewArray( $1 ); }
3364
3365 | '[' ']' cfa_identifier_parameter_ptr
3366 { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3367 | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3368 { $$ = $2->addNewArray( $1 ); }
3369 | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3370 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3371 | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3372 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3373 | multi_array_dimension cfa_identifier_parameter_ptr
3374 { $$ = $2->addNewArray( $1 ); }
3375 ;
3376
3377cfa_array_parameter_1st_dimension:
3378 '[' push type_qualifier_list '*' pop ']' // remaining C99
3379 { $$ = DeclarationNode::newVarArray( $3 ); }
3380 | '[' push type_qualifier_list assignment_expression pop ']'
3381 { $$ = DeclarationNode::newArray( $4, $3, false ); }
3382 | '[' push declaration_qualifier_list assignment_expression pop ']'
3383 // declaration_qualifier_list must be used because of shift/reduce conflict with
3384 // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3385 // appear in this context.
3386 { $$ = DeclarationNode::newArray( $4, $3, true ); }
3387 | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3388 { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3389 ;
3390
3391// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3392// identifier to which the type applies, e.g.:
3393//
3394// [int] f( int ); // abstract variable parameter; no parameter name specified
3395// [int] f( [int] (int) ); // abstract function-prototype parameter; no parameter name specified
3396//
3397// These rules need LR(3):
3398//
3399// cfa_abstract_tuple identifier_or_type_name
3400// '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
3401//
3402// since a function return type can be syntactically identical to a tuple type:
3403//
3404// [int, int] t;
3405// [int, int] f( int );
3406//
3407// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3408// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3409// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3410// duplicated when appearing with cfa_function_specifier.
3411
3412cfa_abstract_declarator_tuple: // CFA
3413 cfa_abstract_tuple
3414 | type_qualifier_list cfa_abstract_tuple
3415 { $$ = $2->addQualifiers( $1 ); }
3416 | cfa_abstract_declarator_no_tuple
3417 ;
3418
3419cfa_abstract_declarator_no_tuple: // CFA
3420 cfa_abstract_ptr
3421 | cfa_abstract_array
3422 ;
3423
3424cfa_abstract_ptr: // CFA
3425 ptrref_operator type_specifier
3426 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3427 | type_qualifier_list ptrref_operator type_specifier
3428 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3429 | ptrref_operator cfa_abstract_function
3430 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3431 | type_qualifier_list ptrref_operator cfa_abstract_function
3432 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3433 | ptrref_operator cfa_abstract_declarator_tuple
3434 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3435 | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3436 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3437 ;
3438
3439cfa_abstract_array: // CFA
3440 // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3441 // empty (void) function return type.
3442 '[' ']' type_specifier
3443 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3444 | '[' ']' multi_array_dimension type_specifier
3445 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3446 | multi_array_dimension type_specifier
3447 { $$ = $2->addNewArray( $1 ); }
3448 | '[' ']' cfa_abstract_ptr
3449 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3450 | '[' ']' multi_array_dimension cfa_abstract_ptr
3451 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3452 | multi_array_dimension cfa_abstract_ptr
3453 { $$ = $2->addNewArray( $1 ); }
3454 ;
3455
3456cfa_abstract_tuple: // CFA
3457 '[' push cfa_abstract_parameter_list pop ']'
3458 { $$ = DeclarationNode::newTuple( $3 ); }
3459 | '[' push type_specifier_nobody ELLIPSIS pop ']'
3460 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3461 | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
3462 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3463 ;
3464
3465cfa_abstract_function: // CFA
3466// '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
3467// { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3468 cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
3469 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3470 | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
3471 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3472 ;
3473
3474// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3475// each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3476//
3477// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3478// the declaration specifiers in a declaration is an obsolescent feature."
3479//
3480// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3481// prototype-format parameter type declarators) is an obsolescent feature."
3482//
3483// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3484// declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3485
3486//************************* MISCELLANEOUS ********************************
3487
3488comma_opt: // redundant comma
3489 // empty
3490 | ','
3491 ;
3492
3493default_initialize_opt:
3494 // empty
3495 { $$ = nullptr; }
3496 | '=' assignment_expression
3497 { $$ = $2; }
3498 ;
3499
3500%%
3501
3502// ----end of grammar----
3503
3504// Local Variables: //
3505// mode: c++ //
3506// tab-width: 4 //
3507// compile-command: "make install" //
3508// End: //
Note: See TracBrowser for help on using the repository browser.