Context Navigation

parser.yy @ 9867cdb

ADTarm-ehast-experimentalenumforall-pointer-decayjacob/cs343-translationnew-astnew-ast-unique-exprpthread-emulationqualifiedEnum

Last change on this file since 9867cdb was 9867cdb, checked in by Peter A. Buhr <pabuhr@…>, 4 years ago
print parser error "C @= assignment is currently unimplemented"
Property mode set to `100644`
File size: 136.1 KB

Line
1	//
2	// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3	//
4	// The contents of this file are covered under the licence agreement in the
5	// file "LICENCE" distributed with Cforall.
6	//
7	// parser.yy --
8	//
9	// Author : Peter A. Buhr
10	// Created On : Sat Sep 1 20:22:55 2001
11	// Last Modified By : Peter A. Buhr
12	// Last Modified On : Fri Mar 6 17:26:45 2020
13	// Update Count : 4474
14	//
15
16	// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17	// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS. While parts have been
18	// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19	// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20	// that must be subsequently rejected by semantic checks. Nevertheless, there are still several semantic checks
21	// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23	// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24	// the grammar.
25
26	// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27	//
28	// 1. designation with '=' (use ':' instead)
29	//
30	// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31	// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32	//
33	// 1. designation with and without '=' (use ':' instead)
34	// 2. attributes not allowed in parenthesis of declarator
35	//
36	// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37	// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38	// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39	// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40	// grammar rule.
41
42	%{
43	#define YYDEBUG_LEXER_TEXT (yylval) // lexer loads this up each time
44	#define YYDEBUG 1 // get the pretty debugging code to compile
45	#define YYERROR_VERBOSE // more information in syntax errors
46
47	#undef __GNUC_MINOR__
48
49	#include <cstdio>
50	#include <stack>
51	using namespace std;
52
53	#include "SynTree/Declaration.h"
54	#include "ParseNode.h"
55	#include "TypedefTable.h"
56	#include "TypeData.h"
57	#include "SynTree/LinkageSpec.h"
58	#include "Common/SemanticError.h" // error_str
59	#include "Common/utility.h" // for maybeMoveBuild, maybeBuild, CodeLo...
60
61	extern DeclarationNode * parseTree;
62	extern LinkageSpec::Spec linkage;
63	extern TypedefTable typedefTable;
64
65	stack< LinkageSpec::Spec > linkageStack;
66
67	bool appendStr( string & to, string & from ) {
68	// 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
69	// "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
70	// the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
71	// easier to let the C compiler handle this case.
72	//
73	// 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
74	// without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
75	// i.e., u"a" U"b" L"c" is disallowed.
76
77	if ( from[0] != '"' ) { // encoding ?
78	if ( to[0] != '"' ) { // encoding ?
79	if ( to[0] != from[0] \|\| to[1] != from[1] ) { // different encodings ?
80	yyerror( "non-matching string encodings for string-literal concatenation" );
81	return false; // parse error, must call YYERROR in action
82	} else if ( from[1] == '8' ) {
83	from.erase( 0, 1 ); // remove 2nd encoding
84	} // if
85	} else {
86	if ( from[1] == '8' ) { // move encoding to start
87	to = "u8" + to;
88	from.erase( 0, 1 ); // remove 2nd encoding
89	} else {
90	to = from[0] + to;
91	} // if
92	} // if
93	from.erase( 0, 1 ); // remove 2nd encoding
94	} // if
95	to += " " + from; // concatenated into single string
96	return true;
97	} // appendStr
98
99	DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
100	// distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
101	DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
102	for ( cur = dynamic_cast<DeclarationNode >( cur->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode >( cur->get_next() ) ) {
103	cl->cloneBaseType( cur );
104	} // for
105	declList->addType( cl );
106	return declList;
107	} // distAttr
108
109	void distExt( DeclarationNode * declaration ) {
110	// distribute EXTENSION across all declarations
111	for ( DeclarationNode iter = declaration; iter != nullptr; iter = (DeclarationNode )iter->get_next() ) {
112	iter->set_extension( true );
113	} // for
114	} // distExt
115
116	void distInl( DeclarationNode * declaration ) {
117	// distribute EXTENSION across all declarations
118	for ( DeclarationNode iter = declaration; iter != nullptr; iter = (DeclarationNode )iter->get_next() ) {
119	iter->set_inLine( true );
120	} // for
121	} // distInl
122
123	void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
124	// distribute qualifiers across all non-variable declarations in a distribution statemement
125	for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
126	// SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
127	// addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
128	// get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
129	// be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
130	DeclarationNode * clone = qualifiers->clone();
131	if ( qualifiers->type ) { // forall clause ? (handles SC)
132	if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
133	swap( clone->type->forall, iter->type->aggregate.params );
134	iter->addQualifiers( clone );
135	} else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
136	// Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
137	DeclarationNode newnode;
138	swap( newnode.type, iter->type->aggInst.aggregate );
139	swap( clone->type->forall, newnode.type->aggregate.params );
140	newnode.addQualifiers( clone );
141	swap( newnode.type, iter->type->aggInst.aggregate );
142	} else if ( iter->type->kind == TypeData::Function ) { // routines ?
143	swap( clone->type->forall, iter->type->forall );
144	iter->addQualifiers( clone );
145	} // if
146	} else { // just SC qualifiers
147	iter->addQualifiers( clone );
148	} // if
149	} // for
150	delete qualifiers;
151	} // distQual
152
153	// There is an ambiguity for inline generic-routine return-types and generic routines.
154	// forall( otype T ) struct S { int i; } bar( T ) {}
155	// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
156	// forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
157	// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
158	// forall( otype T ) struct S { int T; };
159	// forall( otype W ) bar( W ) {}
160
161	void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
162	if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
163	funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
164	declSpec->type->aggregate.params = nullptr;
165	} // if
166	} // rebindForall
167
168	string * build_postfix_name( string * name ) {
169	name = string("__postfix_func_") + name;
170	return name;
171	} // build_postfix_name
172
173	DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
174	if ( ! fieldList ) { // field declarator ?
175	if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate \|\| typeSpec->type->kind == TypeData::Enum) ) ) {
176	stringstream ss;
177	typeSpec->type->print( ss );
178	SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
179	return nullptr;
180	} // if
181	fieldList = DeclarationNode::newName( nullptr );
182	} // if
183	return distAttr( typeSpec, fieldList ); // mark all fields in list
184	} // fieldDecl
185
186	ForCtrl * forCtrl( ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
187	ConstantExpr * constant = dynamic_cast<ConstantExpr *>(type->expr.get());
188	if ( constant && (constant->get_constant()->get_value() == "0" \|\| constant->get_constant()->get_value() == "1") ) {
189	type = new ExpressionNode( new CastExpr( maybeMoveBuild< Expression >(type), new BasicType( Type::Qualifiers(), BasicType::SignedInt ) ) );
190	} // if
191	return new ForCtrl(
192	distAttr( DeclarationNode::newTypeof( type, true ), DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) ) ),
193	// NULL comp/inc => leave blank
194	comp ? new ExpressionNode( build_binary_val( compop, new ExpressionNode( build_varref( new string( *index ) ) ), comp ) ) : 0,
195	inc ? new ExpressionNode( build_binary_val( compop == OperKinds::LThan \|\| compop == OperKinds::LEThan ? // choose += or -= for upto/downto
196	OperKinds::PlusAssn : OperKinds::MinusAssn, new ExpressionNode( build_varref( new string( *index ) ) ), inc ) ) : 0 );
197	} // forCtrl
198
199	ForCtrl * forCtrl( ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
200	if ( NameExpr * identifier = dynamic_cast<NameExpr *>(index->expr.get()) ) {
201	return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
202	} else if ( CommaExpr * commaExpr = dynamic_cast<CommaExpr *>(index->expr.get()) ) {
203	if ( NameExpr * identifier = dynamic_cast<NameExpr *>(commaExpr->arg1 ) ) {
204	return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
205	} else {
206	SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); return nullptr;
207	} // if
208	} else {
209	SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); return nullptr;
210	} // if
211	} // forCtrl
212
213	bool forall = false, yyy = false; // aggregate have one or more forall qualifiers ?
214
215	// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
216	#define YYLLOC_DEFAULT(Cur, Rhs, N) \
217	if ( N ) { \
218	(Cur).first_line = YYRHSLOC( Rhs, 1 ).first_line; \
219	(Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column; \
220	(Cur).last_line = YYRHSLOC( Rhs, N ).last_line; \
221	(Cur).last_column = YYRHSLOC( Rhs, N ).last_column; \
222	(Cur).filename = YYRHSLOC( Rhs, 1 ).filename; \
223	} else { \
224	(Cur).first_line = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line; \
225	(Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column; \
226	(Cur).filename = YYRHSLOC( Rhs, 0 ).filename; \
227	}
228	%}
229
230	%define parse.error verbose
231
232	// Types declaration for productions
233	%union {
234	Token tok;
235	ParseNode * pn;
236	ExpressionNode * en;
237	DeclarationNode * decl;
238	AggregateDecl::Aggregate aggKey;
239	TypeDecl::Kind tclass;
240	StatementNode * sn;
241	WaitForStmt * wfs;
242	Expression * constant;
243	IfCtrl * ifctl;
244	ForCtrl * fctl;
245	enum OperKinds compop;
246	LabelNode * label;
247	InitializerNode * in;
248	OperKinds op;
249	std::string * str;
250	bool flag;
251	CatchStmt::Kind catch_kind;
252	GenericExpr * genexpr;
253	}
254
255	//*********************** TERMINAL TOKENS ******************************
256
257	// keywords
258	%token TYPEDEF
259	%token EXTERN STATIC AUTO REGISTER
260	%token THREADLOCAL // C11
261	%token INLINE FORTRAN // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
262	%token NORETURN // C11
263	%token CONST VOLATILE
264	%token RESTRICT // C99
265	%token ATOMIC // C11
266	%token FORALL MUTEX VIRTUAL COERCE // CFA
267	%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
268	%token BOOL COMPLEX IMAGINARY // C99
269	%token INT128 UINT128 uuFLOAT80 uuFLOAT128 // GCC
270	%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
271	%token ZERO_T ONE_T // CFA
272	%token VALIST // GCC
273	%token AUTO_TYPE // GCC
274	%token TYPEOF BASETYPEOF LABEL // GCC
275	%token ENUM STRUCT UNION
276	%token EXCEPTION // CFA
277	%token GENERATOR COROUTINE MONITOR THREAD // CFA
278	%token OTYPE FTYPE DTYPE TTYPE TRAIT // CFA
279	%token SIZEOF OFFSETOF
280	// %token SUSPEND RESUME // CFA
281	%token ATTRIBUTE EXTENSION // GCC
282	%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
283	%token CHOOSE DISABLE ENABLE FALLTHRU FALLTHROUGH TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT WITH WHEN WAITFOR // CFA
284	%token ASM // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
285	%token ALIGNAS ALIGNOF GENERIC STATICASSERT // C11
286
287	// names and constants: lexer differentiates between identifier and typedef names
288	%token<tok> IDENTIFIER QUOTED_IDENTIFIER TYPEDEFname TYPEGENname
289	%token<tok> TIMEOUT WOR
290	%token<tok> INTEGERconstant CHARACTERconstant STRINGliteral
291	%token<tok> DIRECTIVE
292	// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
293	// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
294	// converted into the tuple index (.)(1). e.g., 3.x
295	%token<tok> FLOATING_DECIMALconstant FLOATING_FRACTIONconstant FLOATINGconstant
296
297	// multi-character operators
298	%token ARROW // ->
299	%token ICR DECR // ++ --
300	%token LS RS // << >>
301	%token LE GE EQ NE // <= >= == !=
302	%token ANDAND OROR // && \|\|
303	%token ELLIPSIS // ...
304
305	%token EXPassign MULTassign DIVassign MODassign // \= *= /= %=
306	%token PLUSassign MINUSassign // += -=
307	%token LSassign RSassign // <<= >>=
308	%token ANDassign ERassign ORassign // &= ^= \|=
309
310	%token ErangeUpEq ErangeDown ErangeDownEq // ~= -~ -~=
311	%token ATassign // @=
312
313	%type<tok> identifier
314	%type<tok> identifier_or_type_name attr_name
315	%type<tok> quasi_keyword
316	%type<constant> string_literal
317	%type<str> string_literal_list
318
319	// expressions
320	%type<en> constant
321	%type<en> tuple tuple_expression_list
322	%type<op> ptrref_operator unary_operator assignment_operator
323	%type<en> primary_expression postfix_expression unary_expression
324	%type<en> cast_expression_list cast_expression exponential_expression multiplicative_expression additive_expression
325	%type<en> shift_expression relational_expression equality_expression
326	%type<en> AND_expression exclusive_OR_expression inclusive_OR_expression
327	%type<en> logical_AND_expression logical_OR_expression
328	%type<en> conditional_expression constant_expression assignment_expression assignment_expression_opt
329	%type<en> comma_expression comma_expression_opt
330	%type<en> argument_expression_list argument_expression default_initialize_opt
331	%type<ifctl> if_control_expression
332	%type<fctl> for_control_expression for_control_expression_list
333	%type<compop> inclexcl
334	%type<en> subrange
335	%type<decl> asm_name_opt
336	%type<en> asm_operands_opt asm_operands_list asm_operand
337	%type<label> label_list
338	%type<en> asm_clobbers_list_opt
339	%type<flag> asm_volatile_opt
340	%type<en> handler_predicate_opt
341	%type<genexpr> generic_association generic_assoc_list
342
343	// statements
344	%type<sn> statement labeled_statement compound_statement
345	%type<sn> statement_decl statement_decl_list statement_list_nodecl
346	%type<sn> selection_statement if_statement
347	%type<sn> switch_clause_list_opt switch_clause_list
348	%type<en> case_value
349	%type<sn> case_clause case_value_list case_label case_label_list
350	%type<sn> iteration_statement jump_statement
351	%type<sn> expression_statement asm_statement
352	%type<sn> with_statement
353	%type<en> with_clause_opt
354	%type<sn> exception_statement handler_clause finally_clause
355	%type<catch_kind> handler_key
356	%type<sn> mutex_statement
357	%type<en> when_clause when_clause_opt waitfor timeout
358	%type<sn> waitfor_statement
359	%type<wfs> waitfor_clause
360
361	// declarations
362	%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
363	%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
364	%type<decl> abstract_parameter_declaration
365
366	%type<aggKey> aggregate_key aggregate_data aggregate_control
367	%type<decl> aggregate_type aggregate_type_nobody
368
369	%type<decl> assertion assertion_list assertion_list_opt
370
371	%type<en> bit_subrange_size_opt bit_subrange_size
372
373	%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
374
375	%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
376
377	%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
378	%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
379
380	%type<decl> elaborated_type elaborated_type_nobody
381
382	%type<decl> enumerator_list enum_type enum_type_nobody
383	%type<en> enumerator_value_opt
384
385	%type<decl> external_definition external_definition_list external_definition_list_opt
386
387	%type<decl> exception_declaration
388
389	%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
390	%type<en> field field_name_list field_name fraction_constants_opt
391
392	%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
393
394	%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
395	%type<decl> identifier_list
396
397	%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
398	%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
399	%type<decl> cfa_abstract_ptr cfa_abstract_tuple
400
401	%type<decl> cfa_array_parameter_1st_dimension
402
403	%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
404	%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
405
406	%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
407	%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
408
409	%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
410
411	%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
412
413	%type<decl> c_declaration static_assert
414	%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
415	%type<decl> KR_parameter_list KR_parameter_list_opt
416
417	%type<decl> parameter_declaration parameter_list parameter_type_list_opt
418
419	%type<decl> paren_identifier paren_type
420
421	%type<decl> storage_class storage_class_list
422
423	%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
424
425	%type<tclass> type_class
426	%type<decl> type_declarator type_declarator_name type_declaring_list
427
428	%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
429	%type<decl> typedef typedef_declaration typedef_expression
430
431	%type<decl> variable_type_redeclarator type_ptr type_array type_function
432
433	%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
434
435	%type<decl> type type_no_function
436	%type<decl> type_parameter type_parameter_list type_initializer_opt
437
438	%type<en> type_parameters_opt type_list
439
440	%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
441	%type<decl> type_specifier type_specifier_nobody
442
443	%type<decl> variable_declarator variable_ptr variable_array variable_function
444	%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
445
446	%type<decl> attribute_list_opt attribute_list attribute_name_list attribute attribute_name
447
448	// initializers
449	%type<in> initializer initializer_list_opt initializer_opt
450
451	// designators
452	%type<en> designator designator_list designation
453
454
455	// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
456	// .---------. matches IF '(' comma_expression ')' statement . (reduce)
457	// if ( C ) S1 else S2
458	// `-----------------' matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
459	// Similar issues exit with the waitfor statement.
460
461	// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
462	// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
463	%precedence THEN // rule precedence for IF/WAITFOR statement
464	%precedence WOR // token precedence for start of WOR in WAITFOR statement
465	%precedence TIMEOUT // token precedence for start of TIMEOUT in WAITFOR statement
466	%precedence ELSE // token precedence for start of else clause in IF/WAITFOR statement
467
468	// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
469	// forall( otype T ) struct Foo { T v; };
470	// .-----. matches pointer to function returning a generic (which is impossible without a type)
471	// Foo ( *fp )( int );
472	// `---' matches start of TYPEGENname '('
473	// must be:
474	// Foo( int ) ( *fp )( int );
475	// The same problem occurs here:
476	// forall( otype T ) struct Foo { T v; } ( *fp )( int );
477	// must be:
478	// forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
479
480	// Order of these lines matters (low-to-high precedence).
481	%precedence TYPEGENname
482	%precedence '}'
483	%precedence '('
484
485	// %precedence RESUME
486	// %precedence '{'
487	// %precedence ')'
488
489	%locations // support location tracking for error messages
490
491	%start translation_unit // parse-tree root
492
493	%%
494	//*********************** Namespace Management ******************************
495
496	// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
497	// which are lexically identical.
498	//
499	// typedef int foo; // identifier foo must now be scanned as TYPEDEFname
500	// foo f; // to allow it to appear in this context
501	//
502	// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
503	// between syntactic and semantic constructs. Cforall compounds this problem by introducing type names local to the
504	// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
505	// generators" -- parameterized types. This latter type name creates a third class of identifiers, "TYPEGENname", which
506	// must be distinguished by the lexical scanner.
507	//
508	// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
509	// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
510	// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
511	// each context that introduces a name scope, a new level is created in the type table and that level is popped on
512	// exiting the scope. Since type names can be local to a particular declaration, each declaration is itself a scope.
513	// This requires distinguishing between type names that are local to the current declaration scope and those that
514	// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
515	//
516	// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
517	// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
518	// around the list separator.
519	//
520	// int f( forall(T) T (f1) T , forall( S ) S (f2)( S ) );
521	// push pop push pop
522
523	push:
524	{ typedefTable.enterScope(); }
525	;
526
527	pop:
528	{ typedefTable.leaveScope(); }
529	;
530
531	//*********************** CONSTANTS ******************************
532
533	constant:
534	// ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
535	INTEGERconstant { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
536	\| FLOATING_DECIMALconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
537	\| FLOATING_FRACTIONconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
538	\| FLOATINGconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
539	\| CHARACTERconstant { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
540	;
541
542	quasi_keyword: // CFA
543	TIMEOUT
544	\| WOR
545	;
546
547	identifier:
548	IDENTIFIER
549	\| quasi_keyword
550	\| '@' // CFA
551	{ Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
552	;
553
554	string_literal:
555	string_literal_list { $$ = build_constantStr( *$1 ); }
556	;
557
558	string_literal_list: // juxtaposed strings are concatenated
559	STRINGliteral { $$ = $1; } // conversion from tok to str
560	\| string_literal_list STRINGliteral
561	{
562	if ( ! appendStr( $1, $2 ) ) YYERROR; // append 2nd juxtaposed string to 1st
563	delete $2; // allocated by lexer
564	$$ = $1; // conversion from tok to str
565	}
566	;
567
568	//*********************** EXPRESSIONS ******************************
569
570	primary_expression:
571	IDENTIFIER // typedef name cannot be used as a variable name
572	{ $$ = new ExpressionNode( build_varref( $1 ) ); }
573	\| quasi_keyword
574	{ $$ = new ExpressionNode( build_varref( $1 ) ); }
575	\| tuple
576	\| '(' comma_expression ')'
577	{ $$ = $2; }
578	\| '(' compound_statement ')' // GCC, lambda expression
579	{ $$ = new ExpressionNode( new StmtExpr( dynamic_cast< CompoundStmt * >(maybeMoveBuild< Statement >($2) ) ) ); }
580	\| type_name '.' identifier // CFA, nested type
581	{ SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
582	\| type_name '.' '[' field_name_list ']' // CFA, nested type / tuple field selector
583	{ SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
584	\| GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
585	{
586	// add the missing control expression to the GenericExpr and return it
587	$5->control = maybeMoveBuild<Expression>( $3 );
588	$$ = new ExpressionNode( $5 );
589	}
590	// \| RESUME '(' comma_expression ')'
591	// { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
592	// \| RESUME '(' comma_expression ')' compound_statement
593	// { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
594	;
595
596	generic_assoc_list: // C11
597	generic_association
598	\| generic_assoc_list ',' generic_association
599	{
600	// steal the association node from the singleton and delete the wrapper
601	$1->associations.splice($1->associations.end(), $3->associations);
602	delete $3;
603	$$ = $1;
604	}
605	;
606
607	generic_association: // C11
608	type_no_function ':' assignment_expression
609	{
610	// create a GenericExpr wrapper with one association pair
611	$$ = new GenericExpr( nullptr, { { maybeMoveBuildType($1), maybeMoveBuild<Expression>($3) } } );
612	}
613	\| DEFAULT ':' assignment_expression
614	{ $$ = new GenericExpr( nullptr, { { maybeMoveBuild<Expression>($3) } } ); }
615	;
616
617	postfix_expression:
618	primary_expression
619	\| postfix_expression '[' assignment_expression ']'
620	// CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
621	// matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
622	// little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
623	// equivalent to the old x[i,j].
624	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
625	\| postfix_expression '{' argument_expression_list '}' // CFA, constructor call
626	{
627	Token fn;
628	fn.str = new std::string( "?{}" ); // location undefined - use location of '{'?
629	$$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
630	}
631	\| postfix_expression '(' argument_expression_list ')'
632	{ $$ = new ExpressionNode( build_func( $1, $3 ) ); }
633	\| postfix_expression '`' identifier // CFA, postfix call
634	{ $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
635	\| constant '`' identifier // CFA, postfix call
636	{ $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
637	\| string_literal '`' identifier // CFA, postfix call
638	{ $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), new ExpressionNode( $1 ) ) ); }
639	\| postfix_expression '.' identifier
640	{ $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
641	\| postfix_expression '.' INTEGERconstant // CFA, tuple index
642	{ $$ = new ExpressionNode( build_fieldSel( $1, build_constantInteger( *$3 ) ) ); }
643	\| postfix_expression FLOATING_FRACTIONconstant // CFA, tuple index
644	{ $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
645	\| postfix_expression '.' '[' field_name_list ']' // CFA, tuple field selector
646	{ $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
647	\| postfix_expression '.' aggregate_control
648	{ $$ = new ExpressionNode( build_keyword_cast( $3, $1 ) ); }
649	\| postfix_expression ARROW identifier
650	{ $$ = new ExpressionNode( build_pfieldSel( $1, build_varref( $3 ) ) ); }
651	\| postfix_expression ARROW INTEGERconstant // CFA, tuple index
652	{ $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
653	\| postfix_expression ARROW '[' field_name_list ']' // CFA, tuple field selector
654	{ $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
655	\| postfix_expression ICR
656	{ $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
657	\| postfix_expression DECR
658	{ $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
659	\| '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
660	{ $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
661	\| '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
662	{ $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
663	\| '^' primary_expression '{' argument_expression_list '}' // CFA, destructor call
664	{
665	Token fn;
666	fn.str = new string( "^?{}" ); // location undefined
667	$$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
668	}
669	;
670
671	argument_expression_list:
672	// empty
673	{ $$ = nullptr; }
674	\| argument_expression
675	\| argument_expression_list ',' argument_expression
676	{ $$ = (ExpressionNode *)($1->set_last( $3 )); }
677	;
678
679	argument_expression:
680	'@' // CFA, default parameter
681	{ SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
682	// { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
683	\| assignment_expression
684	;
685
686	field_name_list: // CFA, tuple field selector
687	field
688	\| field_name_list ',' field { $$ = (ExpressionNode *)($1->set_last( $3 )); }
689	;
690
691	field: // CFA, tuple field selector
692	field_name
693	\| FLOATING_DECIMALconstant field
694	{ $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
695	\| FLOATING_DECIMALconstant '[' field_name_list ']'
696	{ $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $3 ) ) ); }
697	\| field_name '.' field
698	{ $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
699	\| field_name '.' '[' field_name_list ']'
700	{ $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
701	\| field_name ARROW field
702	{ $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
703	\| field_name ARROW '[' field_name_list ']'
704	{ $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
705	;
706
707	field_name:
708	INTEGERconstant fraction_constants_opt
709	{ $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
710	\| FLOATINGconstant fraction_constants_opt
711	{ $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
712	\| identifier fraction_constants_opt
713	{
714	$$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
715	}
716	;
717
718	fraction_constants_opt:
719	// empty
720	{ $$ = nullptr; }
721	\| fraction_constants_opt FLOATING_FRACTIONconstant
722	{
723	Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
724	$$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1, constant ) ) : new ExpressionNode( constant );
725	}
726	;
727
728	unary_expression:
729	postfix_expression
730	// first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
731	// semantics checks, e.g., ++3, 3--, *3, &&3
732	\| constant
733	\| string_literal
734	{ $$ = new ExpressionNode( $1 ); }
735	\| EXTENSION cast_expression // GCC
736	{ $$ = $2->set_extension( true ); }
737	// '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
738	// { * X; } // dereference X
739	// { * int X; } // CFA declaration of pointer to int
740	\| ptrref_operator cast_expression // CFA
741	{
742	switch ( $1 ) {
743	case OperKinds::AddressOf:
744	$$ = new ExpressionNode( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) );
745	break;
746	case OperKinds::PointTo:
747	$$ = new ExpressionNode( build_unary_val( $1, $2 ) );
748	break;
749	case OperKinds::And:
750	$$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) ) );
751	break;
752	default:
753	assert( false );
754	}
755	}
756	\| unary_operator cast_expression
757	{ $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
758	\| ICR unary_expression
759	{ $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
760	\| DECR unary_expression
761	{ $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
762	\| SIZEOF unary_expression
763	{ $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
764	\| SIZEOF '(' type_no_function ')'
765	{ $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
766	\| ALIGNOF unary_expression // GCC, variable alignment
767	{ $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
768	\| ALIGNOF '(' type_no_function ')' // GCC, type alignment
769	{ $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
770	\| OFFSETOF '(' type_no_function ',' identifier ')'
771	{ $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
772	;
773
774	ptrref_operator:
775	'*' { $$ = OperKinds::PointTo; }
776	\| '&' { $$ = OperKinds::AddressOf; }
777	// GCC, address of label must be handled by semantic check for ref,ref,label
778	\| ANDAND { $$ = OperKinds::And; }
779	;
780
781	unary_operator:
782	'+' { $$ = OperKinds::UnPlus; }
783	\| '-' { $$ = OperKinds::UnMinus; }
784	\| '!' { $$ = OperKinds::Neg; }
785	\| '~' { $$ = OperKinds::BitNeg; }
786	;
787
788	cast_expression:
789	unary_expression
790	\| '(' type_no_function ')' cast_expression
791	{ $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
792	\| '(' aggregate_control '&' ')' cast_expression // CFA
793	{ $$ = new ExpressionNode( build_keyword_cast( $2, $5 ) ); }
794	// VIRTUAL cannot be opt because of look ahead issues
795	\| '(' VIRTUAL ')' cast_expression // CFA
796	{ $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $4 ), maybeMoveBuildType( nullptr ) ) ); }
797	\| '(' VIRTUAL type_no_function ')' cast_expression // CFA
798	{ $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $5 ), maybeMoveBuildType( $3 ) ) ); }
799	\| '(' RETURN type_no_function ')' cast_expression // CFA
800	{ SemanticError( yylloc, "Return cast is currently unimplemented." ); $$ = nullptr; }
801	\| '(' COERCE type_no_function ')' cast_expression // CFA
802	{ SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
803	\| '(' qualifier_cast_list ')' cast_expression // CFA
804	{ SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
805	// \| '(' type_no_function ')' tuple
806	// { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
807	;
808
809	qualifier_cast_list:
810	cast_modifier type_qualifier_name
811	\| cast_modifier MUTEX
812	\| qualifier_cast_list cast_modifier type_qualifier_name
813	\| qualifier_cast_list cast_modifier MUTEX
814	;
815
816	cast_modifier:
817	'-'
818	\| '+'
819	;
820
821	exponential_expression:
822	cast_expression
823	\| exponential_expression '\\' cast_expression
824	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
825	;
826
827	multiplicative_expression:
828	exponential_expression
829	\| multiplicative_expression '*' exponential_expression
830	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
831	\| multiplicative_expression '/' exponential_expression
832	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
833	\| multiplicative_expression '%' exponential_expression
834	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
835	;
836
837	additive_expression:
838	multiplicative_expression
839	\| additive_expression '+' multiplicative_expression
840	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
841	\| additive_expression '-' multiplicative_expression
842	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
843	;
844
845	shift_expression:
846	additive_expression
847	\| shift_expression LS additive_expression
848	{ $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
849	\| shift_expression RS additive_expression
850	{ $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
851	;
852
853	relational_expression:
854	shift_expression
855	\| relational_expression '<' shift_expression
856	{ $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
857	\| relational_expression '>' shift_expression
858	{ $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
859	\| relational_expression LE shift_expression
860	{ $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
861	\| relational_expression GE shift_expression
862	{ $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
863	;
864
865	equality_expression:
866	relational_expression
867	\| equality_expression EQ relational_expression
868	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
869	\| equality_expression NE relational_expression
870	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
871	;
872
873	AND_expression:
874	equality_expression
875	\| AND_expression '&' equality_expression
876	{ $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
877	;
878
879	exclusive_OR_expression:
880	AND_expression
881	\| exclusive_OR_expression '^' AND_expression
882	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
883	;
884
885	inclusive_OR_expression:
886	exclusive_OR_expression
887	\| inclusive_OR_expression '\|' exclusive_OR_expression
888	{ $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
889	;
890
891	logical_AND_expression:
892	inclusive_OR_expression
893	\| logical_AND_expression ANDAND inclusive_OR_expression
894	{ $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
895	;
896
897	logical_OR_expression:
898	logical_AND_expression
899	\| logical_OR_expression OROR logical_AND_expression
900	{ $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
901	;
902
903	conditional_expression:
904	logical_OR_expression
905	\| logical_OR_expression '?' comma_expression ':' conditional_expression
906	{ $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
907	// FIX ME: computes $1 twice
908	\| logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
909	{ $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
910	;
911
912	constant_expression:
913	conditional_expression
914	;
915
916	assignment_expression:
917	// CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
918	conditional_expression
919	\| unary_expression assignment_operator assignment_expression
920	{
921	if ( $2 == OperKinds::AtAssn ) {
922	SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
923	} else {
924	$$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) );
925	} // if
926	}
927	\| unary_expression '=' '{' initializer_list_opt comma_opt '}'
928	{ SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
929	;
930
931	assignment_expression_opt:
932	// empty
933	{ $$ = nullptr; }
934	\| assignment_expression
935	;
936
937	assignment_operator:
938	'=' { $$ = OperKinds::Assign; }
939	\| ATassign { $$ = OperKinds::AtAssn; }
940	\| EXPassign { $$ = OperKinds::ExpAssn; }
941	\| MULTassign { $$ = OperKinds::MulAssn; }
942	\| DIVassign { $$ = OperKinds::DivAssn; }
943	\| MODassign { $$ = OperKinds::ModAssn; }
944	\| PLUSassign { $$ = OperKinds::PlusAssn; }
945	\| MINUSassign { $$ = OperKinds::MinusAssn; }
946	\| LSassign { $$ = OperKinds::LSAssn; }
947	\| RSassign { $$ = OperKinds::RSAssn; }
948	\| ANDassign { $$ = OperKinds::AndAssn; }
949	\| ERassign { $$ = OperKinds::ERAssn; }
950	\| ORassign { $$ = OperKinds::OrAssn; }
951	;
952
953	tuple: // CFA, tuple
954	// CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
955	// comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
956	// '[' ']'
957	// { $$ = new ExpressionNode( build_tuple() ); }
958	// \| '[' push assignment_expression pop ']'
959	// { $$ = new ExpressionNode( build_tuple( $3 ) ); }
960	'[' ',' tuple_expression_list ']'
961	{ $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
962	\| '[' push assignment_expression pop ',' tuple_expression_list ']'
963	{ $$ = new ExpressionNode( build_tuple( (ExpressionNode *)($3->set_last( $6 ) ) )); }
964	;
965
966	tuple_expression_list:
967	assignment_expression_opt
968	\| tuple_expression_list ',' assignment_expression_opt
969	{ $$ = (ExpressionNode *)($1->set_last( $3 )); }
970	;
971
972	comma_expression:
973	assignment_expression
974	\| comma_expression ',' assignment_expression
975	{ $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
976	;
977
978	comma_expression_opt:
979	// empty
980	{ $$ = nullptr; }
981	\| comma_expression
982	;
983
984	//************************* STATEMENTS *****************************
985
986	statement:
987	labeled_statement
988	\| compound_statement
989	\| expression_statement
990	\| selection_statement
991	\| iteration_statement
992	\| jump_statement
993	\| with_statement
994	\| mutex_statement
995	\| waitfor_statement
996	\| exception_statement
997	\| enable_disable_statement
998	{ SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
999	\| asm_statement
1000	\| DIRECTIVE
1001	{ $$ = new StatementNode( build_directive( $1 ) ); }
1002	;
1003
1004	labeled_statement:
1005	// labels cannot be identifiers 0 or 1
1006	identifier_or_type_name ':' attribute_list_opt statement
1007	{ $$ = $4->add_label( $1, $3 ); }
1008	;
1009
1010	compound_statement:
1011	'{' '}'
1012	{ $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
1013	\| '{' push
1014	local_label_declaration_opt // GCC, local labels
1015	statement_decl_list // C99, intermix declarations and statements
1016	pop '}'
1017	{ $$ = new StatementNode( build_compound( $4 ) ); }
1018	;
1019
1020	statement_decl_list: // C99
1021	statement_decl
1022	\| statement_decl_list statement_decl
1023	{ assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1024	;
1025
1026	statement_decl:
1027	declaration // CFA, new & old style declarations
1028	{ $$ = new StatementNode( $1 ); }
1029	\| EXTENSION declaration // GCC
1030	{ distExt( $2 ); $$ = new StatementNode( $2 ); }
1031	\| function_definition
1032	{ $$ = new StatementNode( $1 ); }
1033	\| EXTENSION function_definition // GCC
1034	{ distExt( $2 ); $$ = new StatementNode( $2 ); }
1035	\| statement
1036	;
1037
1038	statement_list_nodecl:
1039	statement
1040	\| statement_list_nodecl statement
1041	{ assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1042	;
1043
1044	expression_statement:
1045	comma_expression_opt ';'
1046	{ $$ = new StatementNode( build_expr( $1 ) ); }
1047	;
1048
1049	selection_statement:
1050	// pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1051	// the inherent S/R conflict with THEN/ELSE.
1052	push if_statement pop
1053	{ $$ = $2; }
1054	\| SWITCH '(' comma_expression ')' case_clause
1055	{ $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
1056	\| SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1057	{
1058	StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
1059	// The semantics of the declaration list is changed to include associated initialization, which is performed
1060	// before the transfer to the appropriate case clause by hoisting the declarations into a compound
1061	// statement around the switch. Statements after the initial declaration list can never be executed, and
1062	// therefore, are removed from the grammar even though C allows it. The change also applies to choose
1063	// statement.
1064	$$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1065	}
1066	\| CHOOSE '(' comma_expression ')' case_clause // CFA
1067	{ $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
1068	\| CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1069	{
1070	StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
1071	$$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1072	}
1073	;
1074
1075	if_statement:
1076	IF '(' if_control_expression ')' statement %prec THEN
1077	// explicitly deal with the shift/reduce conflict on if/else
1078	{ $$ = new StatementNode( build_if( $3, $5, nullptr ) ); }
1079	\| IF '(' if_control_expression ')' statement ELSE statement
1080	{ $$ = new StatementNode( build_if( $3, $5, $7 ) ); }
1081	;
1082
1083	if_control_expression:
1084	comma_expression
1085	{ $$ = new IfCtrl( nullptr, $1 ); }
1086	\| c_declaration // no semi-colon
1087	{ $$ = new IfCtrl( $1, nullptr ); }
1088	\| cfa_declaration // no semi-colon
1089	{ $$ = new IfCtrl( $1, nullptr ); }
1090	\| declaration comma_expression // semi-colon separated
1091	{ $$ = new IfCtrl( $1, $2 ); }
1092	;
1093
1094	// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1095	// clause allows a list of values and subranges.
1096
1097	case_value: // CFA
1098	constant_expression { $$ = $1; }
1099	\| constant_expression ELLIPSIS constant_expression // GCC, subrange
1100	{ $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
1101	\| subrange // CFA, subrange
1102	;
1103
1104	case_value_list: // CFA
1105	case_value { $$ = new StatementNode( build_case( $1 ) ); }
1106	// convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1107	\| case_value_list ',' case_value { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
1108	;
1109
1110	case_label: // CFA
1111	CASE case_value_list ':' { $$ = $2; }
1112	\| DEFAULT ':' { $$ = new StatementNode( build_default() ); }
1113	// A semantic check is required to ensure only one default clause per switch/choose statement.
1114	;
1115
1116	//label_list_opt:
1117	// // empty
1118	// \| identifier_or_type_name ':'
1119	// \| label_list_opt identifier_or_type_name ':'
1120	// ;
1121
1122	case_label_list: // CFA
1123	case_label
1124	\| case_label_list case_label { $$ = (StatementNode *)( $1->set_last( $2 )); }
1125	;
1126
1127	case_clause: // CFA
1128	case_label_list statement { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1129	;
1130
1131	switch_clause_list_opt: // CFA
1132	// empty
1133	{ $$ = nullptr; }
1134	\| switch_clause_list
1135	;
1136
1137	switch_clause_list: // CFA
1138	case_label_list statement_list_nodecl
1139	{ $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1140	\| switch_clause_list case_label_list statement_list_nodecl
1141	{ $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1142	;
1143
1144	iteration_statement:
1145	WHILE '(' push if_control_expression ')' statement pop
1146	{ $$ = new StatementNode( build_while( $4, $6 ) ); }
1147	\| WHILE '(' ')' statement // CFA => while ( 1 )
1148	{ $$ = new StatementNode( build_while( new IfCtrl( nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ), $4 ) ); }
1149	\| DO statement WHILE '(' comma_expression ')' ';'
1150	{ $$ = new StatementNode( build_do_while( $5, $2 ) ); }
1151	\| DO statement WHILE '(' ')' ';' // CFA => do while( 1 )
1152	{ $$ = new StatementNode( build_do_while( new ExpressionNode( build_constantInteger( *new string( "1" ) ) ), $2 ) ); }
1153	\| FOR '(' push for_control_expression_list ')' statement pop
1154	{ $$ = new StatementNode( build_for( $4, $6 ) ); }
1155	\| FOR '(' ')' statement // CFA => for ( ;; )
1156	{ $$ = new StatementNode( build_for( new ForCtrl( (ExpressionNode * )nullptr, (ExpressionNode * )nullptr, (ExpressionNode * )nullptr ), $4 ) ); }
1157	;
1158
1159	for_control_expression_list:
1160	for_control_expression
1161	\| for_control_expression_list ':' for_control_expression
1162	// ForCtrl + ForCtrl:
1163	// init + init => multiple declaration statements that are hoisted
1164	// condition + condition => (expression) && (expression)
1165	// change + change => (expression), (expression)
1166	{
1167	$1->init->set_last( $3->init );
1168	if ( $1->condition ) {
1169	if ( $3->condition ) {
1170	$1->condition->expr.reset( new LogicalExpr( $1->condition->expr.release(), $3->condition->expr.release(), true ) );
1171	} // if
1172	} else $1->condition = $3->condition;
1173	if ( $1->change ) {
1174	if ( $3->change ) {
1175	$1->change->expr.reset( new CommaExpr( $1->change->expr.release(), $3->change->expr.release() ) );
1176	} // if
1177	} else $1->change = $3->change;
1178	$$ = $1;
1179	}
1180	;
1181
1182	for_control_expression:
1183	';' comma_expression_opt ';' comma_expression_opt
1184	{ $$ = new ForCtrl( (ExpressionNode * )nullptr, $2, $4 ); }
1185	\| comma_expression ';' comma_expression_opt ';' comma_expression_opt
1186	{ $$ = new ForCtrl( $1, $3, $5 ); }
1187	\| declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1188	{ $$ = new ForCtrl( $1, $2, $4 ); }
1189
1190	\| comma_expression // CFA
1191	{ $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1192	OperKinds::LThan, $1->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1193	\| '=' comma_expression // CFA
1194	{ $$ = forCtrl( $2, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1195	OperKinds::LEThan, $2->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1196	\| comma_expression inclexcl comma_expression // CFA
1197	{ $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1198	\| comma_expression inclexcl comma_expression '~' comma_expression // CFA
1199	{ $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, $5 ); }
1200	\| comma_expression ';' comma_expression // CFA
1201	{ $$ = forCtrl( $3, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1202	OperKinds::LThan, $3->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1203	\| comma_expression ';' '=' comma_expression // CFA
1204	{ $$ = forCtrl( $4, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1205	OperKinds::LEThan, $4->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1206	\| comma_expression ';' comma_expression inclexcl comma_expression // CFA
1207	{ $$ = forCtrl( $3, $1, $3->clone(), $4, $5, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1208	\| comma_expression ';' comma_expression inclexcl comma_expression '~' comma_expression // CFA
1209	{ $$ = forCtrl( $3, $1, $3->clone(), $4, $5, $7 ); }
1210
1211	// There is a S/R conflicit if ~ and -~ are factored out.
1212	\| comma_expression ';' comma_expression '~' '@' // CFA
1213	{ $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1214	\| comma_expression ';' comma_expression ErangeDown '@' // CFA
1215	{ $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1216	\| comma_expression ';' comma_expression '~' '@' '~' comma_expression // CFA
1217	{ $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, $7 ); }
1218	\| comma_expression ';' comma_expression ErangeDown '@' '~' comma_expression // CFA
1219	{ $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, $7 ); }
1220	\| comma_expression ';' comma_expression '~' '@' '~' '@' // CFA
1221	{ $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, nullptr ); }
1222	;
1223
1224	inclexcl:
1225	'~'
1226	{ $$ = OperKinds::LThan; }
1227	\| ErangeUpEq
1228	{ $$ = OperKinds::LEThan; }
1229	\| ErangeDown
1230	{ $$ = OperKinds::GThan; }
1231	\| ErangeDownEq
1232	{ $$ = OperKinds::GEThan; }
1233	;
1234
1235	jump_statement:
1236	GOTO identifier_or_type_name ';'
1237	{ $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1238	\| GOTO '*' comma_expression ';' // GCC, computed goto
1239	// The syntax for the GCC computed goto violates normal expression precedence, e.g., goto i+3; => goto (i+3);
1240	// whereas normal operator precedence yields goto (*i)+3;
1241	{ $$ = new StatementNode( build_computedgoto( $3 ) ); }
1242	// A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1243	\| fall_through_name ';' // CFA
1244	{ $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1245	\| fall_through_name identifier_or_type_name ';' // CFA
1246	{ $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1247	\| fall_through_name DEFAULT ';' // CFA
1248	{ $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1249	\| CONTINUE ';'
1250	// A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1251	{ $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1252	\| CONTINUE identifier_or_type_name ';' // CFA, multi-level continue
1253	// A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1254	// the target of the transfer appears only at the start of an iteration statement.
1255	{ $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1256	\| BREAK ';'
1257	// A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1258	{ $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1259	\| BREAK identifier_or_type_name ';' // CFA, multi-level exit
1260	// A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1261	// the target of the transfer appears only at the start of an iteration statement.
1262	{ $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1263	\| RETURN comma_expression_opt ';'
1264	{ $$ = new StatementNode( build_return( $2 ) ); }
1265	\| RETURN '{' initializer_list_opt comma_opt '}' ';'
1266	{ SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1267	// \| SUSPEND ';'
1268	// { SemanticError( yylloc, "Suspend expression is currently unimplemented." ); $$ = nullptr; }
1269	// \| SUSPEND compound_statement ';'
1270	// { SemanticError( yylloc, "Suspend expression is currently unimplemented." ); $$ = nullptr; }
1271	\| THROW assignment_expression_opt ';' // handles rethrow
1272	{ $$ = new StatementNode( build_throw( $2 ) ); }
1273	\| THROWRESUME assignment_expression_opt ';' // handles reresume
1274	{ $$ = new StatementNode( build_resume( $2 ) ); }
1275	\| THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1276	{ $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1277	;
1278
1279	fall_through_name: // CFA
1280	FALLTHRU
1281	\| FALLTHROUGH
1282	;
1283
1284	with_statement:
1285	WITH '(' tuple_expression_list ')' statement
1286	{
1287	$$ = new StatementNode( build_with( $3, $5 ) );
1288	}
1289	;
1290
1291	// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1292	mutex_statement:
1293	MUTEX '(' argument_expression_list ')' statement
1294	{ SemanticError( yylloc, "Mutex statement is currently unimplemented." ); $$ = nullptr; }
1295	;
1296
1297	when_clause:
1298	WHEN '(' comma_expression ')' { $$ = $3; }
1299	;
1300
1301	when_clause_opt:
1302	// empty
1303	{ $$ = nullptr; }
1304	\| when_clause
1305	;
1306
1307	waitfor:
1308	WAITFOR '(' cast_expression ')'
1309	{ $$ = $3; }
1310	// \| WAITFOR '(' cast_expression ',' argument_expression_list ')'
1311	// { $$ = (ExpressionNode *)$3->set_last( $5 ); }
1312	\| WAITFOR '(' cast_expression_list ':' argument_expression_list ')'
1313	{ $$ = (ExpressionNode *)($3->set_last( $5 )); }
1314	;
1315
1316	cast_expression_list:
1317	cast_expression
1318	\| cast_expression_list ',' cast_expression
1319	{ $$ = (ExpressionNode *)($1->set_last( $3 )); }
1320	;
1321
1322	timeout:
1323	TIMEOUT '(' comma_expression ')' { $$ = $3; }
1324	;
1325
1326	waitfor_clause:
1327	when_clause_opt waitfor statement %prec THEN
1328	{ $$ = build_waitfor( $2, $3, $1 ); }
1329	\| when_clause_opt waitfor statement WOR waitfor_clause
1330	{ $$ = build_waitfor( $2, $3, $1, $5 ); }
1331	\| when_clause_opt timeout statement %prec THEN
1332	{ $$ = build_waitfor_timeout( $2, $3, $1 ); }
1333	\| when_clause_opt ELSE statement
1334	{ $$ = build_waitfor_timeout( nullptr, $3, $1 ); }
1335	// "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1336	\| when_clause_opt timeout statement WOR ELSE statement
1337	{ SemanticError( yylloc, "else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1338	\| when_clause_opt timeout statement WOR when_clause ELSE statement
1339	{ $$ = build_waitfor_timeout( $2, $3, $1, $7, $5 ); }
1340	;
1341
1342	waitfor_statement:
1343	when_clause_opt waitfor statement %prec THEN
1344	{ $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1345	\| when_clause_opt waitfor statement WOR waitfor_clause
1346	{ $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1347	;
1348
1349	exception_statement:
1350	TRY compound_statement handler_clause
1351	{ $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1352	\| TRY compound_statement finally_clause
1353	{ $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1354	\| TRY compound_statement handler_clause finally_clause
1355	{ $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1356	;
1357
1358	handler_clause:
1359	handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1360	{ $$ = new StatementNode( build_catch( $1, $4, $6, $8 ) ); }
1361	\| handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1362	{ $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $5, $7, $9 ) ) ); }
1363	;
1364
1365	handler_predicate_opt:
1366	// empty
1367	{ $$ = nullptr; }
1368	\| ';' conditional_expression { $$ = $2; }
1369	;
1370
1371	handler_key:
1372	CATCH { $$ = CatchStmt::Terminate; }
1373	\| CATCHRESUME { $$ = CatchStmt::Resume; }
1374	;
1375
1376	finally_clause:
1377	FINALLY compound_statement { $$ = new StatementNode( build_finally( $2 ) ); }
1378	;
1379
1380	exception_declaration:
1381	// No SUE declaration in parameter list.
1382	type_specifier_nobody
1383	\| type_specifier_nobody declarator
1384	{ $$ = $2->addType( $1 ); }
1385	\| type_specifier_nobody variable_abstract_declarator
1386	{ $$ = $2->addType( $1 ); }
1387	\| cfa_abstract_declarator_tuple identifier // CFA
1388	{ $$ = $1->addName( $2 ); }
1389	\| cfa_abstract_declarator_tuple // CFA
1390	;
1391
1392	enable_disable_statement:
1393	enable_disable_key identifier_list compound_statement
1394	;
1395
1396	enable_disable_key:
1397	ENABLE
1398	\| DISABLE
1399	;
1400
1401	asm_statement:
1402	ASM asm_volatile_opt '(' string_literal ')' ';'
1403	{ $$ = new StatementNode( build_asm( $2, $4, 0 ) ); }
1404	\| ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1405	{ $$ = new StatementNode( build_asm( $2, $4, $6 ) ); }
1406	\| ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1407	{ $$ = new StatementNode( build_asm( $2, $4, $6, $8 ) ); }
1408	\| ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1409	{ $$ = new StatementNode( build_asm( $2, $4, $6, $8, $10 ) ); }
1410	\| ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1411	{ $$ = new StatementNode( build_asm( $2, $5, 0, $8, $10, $12 ) ); }
1412	;
1413
1414	asm_volatile_opt: // GCC
1415	// empty
1416	{ $$ = false; }
1417	\| VOLATILE
1418	{ $$ = true; }
1419	;
1420
1421	asm_operands_opt: // GCC
1422	// empty
1423	{ $$ = nullptr; } // use default argument
1424	\| asm_operands_list
1425	;
1426
1427	asm_operands_list: // GCC
1428	asm_operand
1429	\| asm_operands_list ',' asm_operand
1430	{ $$ = (ExpressionNode *)($1->set_last( $3 )); }
1431	;
1432
1433	asm_operand: // GCC
1434	string_literal '(' constant_expression ')'
1435	{ $$ = new ExpressionNode( new AsmExpr( nullptr, $1, maybeMoveBuild< Expression >( $3 ) ) ); }
1436	\| '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1437	{ $$ = new ExpressionNode( new AsmExpr( $2, $4, maybeMoveBuild< Expression >( $6 ) ) ); }
1438	;
1439
1440	asm_clobbers_list_opt: // GCC
1441	// empty
1442	{ $$ = nullptr; } // use default argument
1443	\| string_literal
1444	{ $$ = new ExpressionNode( $1 ); }
1445	\| asm_clobbers_list_opt ',' string_literal
1446	{ $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( $3 ) )); }
1447	;
1448
1449	label_list:
1450	identifier
1451	{
1452	$$ = new LabelNode(); $$->labels.push_back( *$1 );
1453	delete $1; // allocated by lexer
1454	}
1455	\| label_list ',' identifier
1456	{
1457	$$ = $1; $1->labels.push_back( *$3 );
1458	delete $3; // allocated by lexer
1459	}
1460	;
1461
1462	//***************************** DECLARATIONS *******************************
1463
1464	declaration_list_opt: // used at beginning of switch statement
1465	// empty
1466	{ $$ = nullptr; }
1467	\| declaration_list
1468	;
1469
1470	declaration_list:
1471	declaration
1472	\| declaration_list declaration
1473	{ $$ = $1->appendList( $2 ); }
1474	;
1475
1476	KR_parameter_list_opt: // used to declare parameter types in K&R style functions
1477	// empty
1478	{ $$ = nullptr; }
1479	\| KR_parameter_list
1480	;
1481
1482	KR_parameter_list:
1483	push c_declaration pop ';'
1484	{ $$ = $2; }
1485	\| KR_parameter_list push c_declaration pop ';'
1486	{ $$ = $1->appendList( $3 ); }
1487	;
1488
1489	local_label_declaration_opt: // GCC, local label
1490	// empty
1491	\| local_label_declaration_list
1492	;
1493
1494	local_label_declaration_list: // GCC, local label
1495	LABEL local_label_list ';'
1496	\| local_label_declaration_list LABEL local_label_list ';'
1497	;
1498
1499	local_label_list: // GCC, local label
1500	identifier_or_type_name
1501	\| local_label_list ',' identifier_or_type_name
1502	;
1503
1504	declaration: // old & new style declarations
1505	c_declaration ';'
1506	\| cfa_declaration ';' // CFA
1507	\| static_assert // C11
1508	;
1509
1510	static_assert:
1511	STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1512	{ $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1513	\| STATICASSERT '(' constant_expression ')' ';' // CFA
1514	{ $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( *new string( "\"\"" ) ) ); }
1515
1516	// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1517	// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1518	// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1519	// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1520	// the declaration list (as in Pascal). ANSI C and the new CFA declarations may appear together in the same program
1521	// block, but cannot be mixed within a specific declaration.
1522	//
1523	// CFA C
1524	// [10] int x; int x[10]; // array of 10 integers
1525	// [10] * char y; char *y[10]; // array of 10 pointers to char
1526
1527	cfa_declaration: // CFA
1528	cfa_variable_declaration
1529	\| cfa_typedef_declaration
1530	\| cfa_function_declaration
1531	\| type_declaring_list
1532	\| trait_specifier
1533	;
1534
1535	cfa_variable_declaration: // CFA
1536	cfa_variable_specifier initializer_opt
1537	{ $$ = $1->addInitializer( $2 ); }
1538	\| declaration_qualifier_list cfa_variable_specifier initializer_opt
1539	// declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1540	// them as a type_qualifier cannot appear in that context.
1541	{ $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1542	\| cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1543	{ $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1544	;
1545
1546	cfa_variable_specifier: // CFA
1547	// A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1548	// storage-class
1549	cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1550	{ $$ = $1->addName( $2 )->addAsmName( $3 ); }
1551	\| cfa_abstract_tuple identifier_or_type_name asm_name_opt
1552	{ $$ = $1->addName( $2 )->addAsmName( $3 ); }
1553	\| type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1554	{ $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1555	;
1556
1557	cfa_function_declaration: // CFA
1558	cfa_function_specifier
1559	\| type_qualifier_list cfa_function_specifier
1560	{ $$ = $2->addQualifiers( $1 ); }
1561	\| declaration_qualifier_list cfa_function_specifier
1562	{ $$ = $2->addQualifiers( $1 ); }
1563	\| declaration_qualifier_list type_qualifier_list cfa_function_specifier
1564	{ $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1565	\| cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1566	{
1567	// Append the return type at the start (left-hand-side) to each identifier in the list.
1568	DeclarationNode * ret = new DeclarationNode;
1569	ret->type = maybeClone( $1->type->base );
1570	$$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1571	}
1572	;
1573
1574	cfa_function_specifier: // CFA
1575	// '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1576	// {
1577	// $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1578	// }
1579	// '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1580	// {
1581	// typedefTable.setNextIdentifier( *$5 );
1582	// $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1583	// }
1584	// \| '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1585	// {
1586	// typedefTable.setNextIdentifier( *$5 );
1587	// $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1588	// }
1589	// \| '[' ']' typegen_name
1590	// identifier_or_type_name must be broken apart because of the sequence:
1591	//
1592	// '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1593	// '[' ']' type_specifier
1594	//
1595	// type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1596	// flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1597	cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1598	// To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1599	{ $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1600	\| cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1601	{ $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1602	;
1603
1604	cfa_function_return: // CFA
1605	'[' push cfa_parameter_list pop ']'
1606	{ $$ = DeclarationNode::newTuple( $3 ); }
1607	\| '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1608	// To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
1609	{ $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1610	;
1611
1612	cfa_typedef_declaration: // CFA
1613	TYPEDEF cfa_variable_specifier
1614	{
1615	typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "1" );
1616	$$ = $2->addTypedef();
1617	}
1618	\| TYPEDEF cfa_function_specifier
1619	{
1620	typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "2" );
1621	$$ = $2->addTypedef();
1622	}
1623	\| cfa_typedef_declaration pop ',' push identifier
1624	{
1625	typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "3" );
1626	$$ = $1->appendList( $1->cloneType( $5 ) );
1627	}
1628	;
1629
1630	// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1631	// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1632
1633	typedef_declaration:
1634	TYPEDEF type_specifier declarator
1635	{
1636	typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "4" );
1637	$$ = $3->addType( $2 )->addTypedef();
1638	}
1639	\| typedef_declaration pop ',' push declarator
1640	{
1641	typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname, "5" );
1642	$$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1643	}
1644	\| type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1645	{
1646	typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "6" );
1647	$$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1648	}
1649	\| type_specifier TYPEDEF declarator
1650	{
1651	typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "7" );
1652	$$ = $3->addType( $1 )->addTypedef();
1653	}
1654	\| type_specifier TYPEDEF type_qualifier_list declarator
1655	{
1656	typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "8" );
1657	$$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1658	}
1659	;
1660
1661	typedef_expression:
1662	// GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1663	TYPEDEF identifier '=' assignment_expression
1664	{
1665	// $$ = DeclarationNode::newName( 0 ); // unimplemented
1666	SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1667	}
1668	\| typedef_expression pop ',' push identifier '=' assignment_expression
1669	{
1670	// $$ = DeclarationNode::newName( 0 ); // unimplemented
1671	SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1672	}
1673	;
1674
1675	//c_declaration:
1676	// declaring_list pop ';'
1677	// \| typedef_declaration pop ';'
1678	// \| typedef_expression pop ';' // GCC, naming expression type
1679	// \| sue_declaration_specifier pop ';'
1680	// ;
1681	//
1682	//declaring_list:
1683	// // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1684	// // storage-class
1685	// declarator asm_name_opt initializer_opt
1686	// {
1687	// typedefTable.addToEnclosingScope( IDENTIFIER );
1688	// $$ = ( $2->addType( $1 ))->addAsmName( $3 )->addInitializer( $4 );
1689	// }
1690	// \| declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1691	// {
1692	// typedefTable.addToEnclosingScope( IDENTIFIER );
1693	// $$ = $1->appendList( $1->cloneBaseType( $4->addAsmName( $5 )->addInitializer( $6 ) ) );
1694	// }
1695	// ;
1696
1697	c_declaration:
1698	declaration_specifier declaring_list
1699	{ $$ = distAttr( $1, $2 ); }
1700	\| typedef_declaration
1701	\| typedef_expression // GCC, naming expression type
1702	\| sue_declaration_specifier
1703	;
1704
1705	declaring_list:
1706	// A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1707	// storage-class
1708	declarator asm_name_opt initializer_opt
1709	{ $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
1710	\| declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1711	{ $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
1712	;
1713
1714	declaration_specifier: // type specifier + storage class
1715	basic_declaration_specifier
1716	\| sue_declaration_specifier
1717	\| type_declaration_specifier
1718	;
1719
1720	declaration_specifier_nobody: // type specifier + storage class - {...}
1721	// Preclude SUE declarations in restricted scopes:
1722	//
1723	// int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1724	//
1725	// because it is impossible to call f due to name equivalence.
1726	basic_declaration_specifier
1727	\| sue_declaration_specifier_nobody
1728	\| type_declaration_specifier
1729	;
1730
1731	type_specifier: // type specifier
1732	basic_type_specifier
1733	\| sue_type_specifier
1734	\| type_type_specifier
1735	;
1736
1737	type_specifier_nobody: // type specifier - {...}
1738	// Preclude SUE declarations in restricted scopes:
1739	//
1740	// int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1741	//
1742	// because it is impossible to call f due to name equivalence.
1743	basic_type_specifier
1744	\| sue_type_specifier_nobody
1745	\| type_type_specifier
1746	;
1747
1748	type_qualifier_list_opt: // GCC, used in asm_statement
1749	// empty
1750	{ $$ = nullptr; }
1751	\| type_qualifier_list
1752	;
1753
1754	type_qualifier_list:
1755	// A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1756	//
1757	// ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1758	// specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1759	// appeared only once.
1760	type_qualifier
1761	\| type_qualifier_list type_qualifier
1762	{ $$ = $1->addQualifiers( $2 ); }
1763	;
1764
1765	type_qualifier:
1766	type_qualifier_name
1767	\| attribute
1768	;
1769
1770	type_qualifier_name:
1771	CONST
1772	{ $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1773	\| RESTRICT
1774	{ $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1775	\| VOLATILE
1776	{ $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1777	\| ATOMIC
1778	{ $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1779	\| forall
1780	;
1781
1782	forall:
1783	FORALL '(' type_parameter_list ')' // CFA
1784	{ $$ = DeclarationNode::newForall( $3 ); }
1785	;
1786
1787	declaration_qualifier_list:
1788	storage_class_list
1789	\| type_qualifier_list storage_class_list // remaining OBSOLESCENT (see 2 )
1790	{ $$ = $1->addQualifiers( $2 ); }
1791	\| declaration_qualifier_list type_qualifier_list storage_class_list
1792	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1793	;
1794
1795	storage_class_list:
1796	// A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1797	// only one of each is specified, except for inline, which can appear with the others.
1798	//
1799	// ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1800	// specifiers in a declaration.
1801	storage_class
1802	\| storage_class_list storage_class
1803	{ $$ = $1->addQualifiers( $2 ); }
1804	;
1805
1806	storage_class:
1807	EXTERN
1808	{ $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1809	\| STATIC
1810	{ $$ = DeclarationNode::newStorageClass( Type::Static ); }
1811	\| AUTO
1812	{ $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1813	\| REGISTER
1814	{ $$ = DeclarationNode::newStorageClass( Type::Register ); }
1815	\| THREADLOCAL // C11
1816	{ $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1817	// Put function specifiers here to simplify parsing rules, but separate them semantically.
1818	\| INLINE // C99
1819	{ $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1820	\| FORTRAN // C99
1821	{ $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1822	\| NORETURN // C11
1823	{ $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1824	;
1825
1826	basic_type_name:
1827	VOID
1828	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1829	\| BOOL // C99
1830	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1831	\| CHAR
1832	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1833	\| INT
1834	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1835	\| INT128
1836	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1837	\| UINT128
1838	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 )->addType( DeclarationNode::newSignedNess( DeclarationNode::Unsigned ) ); }
1839	\| FLOAT
1840	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1841	\| DOUBLE
1842	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1843	\| uuFLOAT80
1844	{ $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
1845	\| uuFLOAT128
1846	{ $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
1847	\| uFLOAT16
1848	{ $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
1849	\| uFLOAT32
1850	{ $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
1851	\| uFLOAT32X
1852	{ $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
1853	\| uFLOAT64
1854	{ $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
1855	\| uFLOAT64X
1856	{ $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
1857	\| uFLOAT128
1858	{ $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
1859	\| COMPLEX // C99
1860	{ $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1861	\| IMAGINARY // C99
1862	{ $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1863	\| SIGNED
1864	{ $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1865	\| UNSIGNED
1866	{ $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1867	\| SHORT
1868	{ $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1869	\| LONG
1870	{ $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1871	\| VALIST // GCC, __builtin_va_list
1872	{ $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1873	\| AUTO_TYPE
1874	{ $$ = DeclarationNode::newBuiltinType( DeclarationNode::AutoType ); }
1875	;
1876
1877	basic_declaration_specifier:
1878	// A semantic check is necessary for conflicting storage classes.
1879	basic_type_specifier
1880	\| declaration_qualifier_list basic_type_specifier
1881	{ $$ = $2->addQualifiers( $1 ); }
1882	\| basic_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1883	{ $$ = $1->addQualifiers( $2 ); }
1884	\| basic_declaration_specifier storage_class type_qualifier_list
1885	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1886	\| basic_declaration_specifier storage_class basic_type_specifier
1887	{ $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1888	;
1889
1890	basic_type_specifier:
1891	direct_type
1892	// Cannot have type modifiers, e.g., short, long, etc.
1893	\| type_qualifier_list_opt indirect_type type_qualifier_list_opt
1894	{ $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1895	;
1896
1897	direct_type:
1898	basic_type_name
1899	\| type_qualifier_list basic_type_name
1900	{ $$ = $2->addQualifiers( $1 ); }
1901	\| direct_type type_qualifier
1902	{ $$ = $1->addQualifiers( $2 ); }
1903	\| direct_type basic_type_name
1904	{ $$ = $1->addType( $2 ); }
1905	;
1906
1907	indirect_type:
1908	TYPEOF '(' type ')' // GCC: typeof( x ) y;
1909	{ $$ = $3; }
1910	\| TYPEOF '(' comma_expression ')' // GCC: typeof( a+b ) y;
1911	{ $$ = DeclarationNode::newTypeof( $3 ); }
1912	\| BASETYPEOF '(' type ')' // CFA: basetypeof( x ) y;
1913	{ $$ = DeclarationNode::newTypeof( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ), true ); }
1914	\| BASETYPEOF '(' comma_expression ')' // CFA: basetypeof( a+b ) y;
1915	{ $$ = DeclarationNode::newTypeof( $3, true ); }
1916	\| ZERO_T // CFA
1917	{ $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1918	\| ONE_T // CFA
1919	{ $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1920	;
1921
1922	sue_declaration_specifier: // struct, union, enum + storage class + type specifier
1923	sue_type_specifier
1924	\| declaration_qualifier_list sue_type_specifier
1925	{ $$ = $2->addQualifiers( $1 ); }
1926	\| sue_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1927	{ $$ = $1->addQualifiers( $2 ); }
1928	\| sue_declaration_specifier storage_class type_qualifier_list
1929	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1930	;
1931
1932	sue_type_specifier: // struct, union, enum + type specifier
1933	elaborated_type
1934	\| type_qualifier_list
1935	{ if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1936	elaborated_type
1937	{ $$ = $3->addQualifiers( $1 ); }
1938	\| sue_type_specifier type_qualifier
1939	{
1940	if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
1941	$$ = $1->addQualifiers( $2 );
1942	}
1943	;
1944
1945	sue_declaration_specifier_nobody: // struct, union, enum - {...} + storage class + type specifier
1946	sue_type_specifier_nobody
1947	\| declaration_qualifier_list sue_type_specifier_nobody
1948	{ $$ = $2->addQualifiers( $1 ); }
1949	\| sue_declaration_specifier_nobody storage_class // remaining OBSOLESCENT (see 2)
1950	{ $$ = $1->addQualifiers( $2 ); }
1951	\| sue_declaration_specifier_nobody storage_class type_qualifier_list
1952	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1953	;
1954
1955	sue_type_specifier_nobody: // struct, union, enum - {...} + type specifier
1956	elaborated_type_nobody
1957	\| type_qualifier_list elaborated_type_nobody
1958	{ $$ = $2->addQualifiers( $1 ); }
1959	\| sue_type_specifier_nobody type_qualifier
1960	{ $$ = $1->addQualifiers( $2 ); }
1961	;
1962
1963	type_declaration_specifier:
1964	type_type_specifier
1965	\| declaration_qualifier_list type_type_specifier
1966	{ $$ = $2->addQualifiers( $1 ); }
1967	\| type_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1968	{ $$ = $1->addQualifiers( $2 ); }
1969	\| type_declaration_specifier storage_class type_qualifier_list
1970	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1971	;
1972
1973	type_type_specifier: // typedef types
1974	type_name
1975	\| type_qualifier_list type_name
1976	{ $$ = $2->addQualifiers( $1 ); }
1977	\| type_type_specifier type_qualifier
1978	{ $$ = $1->addQualifiers( $2 ); }
1979	;
1980
1981	type_name:
1982	TYPEDEFname
1983	{ $$ = DeclarationNode::newFromTypedef( $1 ); }
1984	\| '.' TYPEDEFname
1985	{ $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
1986	\| type_name '.' TYPEDEFname
1987	{ $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
1988	\| typegen_name
1989	\| '.' typegen_name
1990	{ $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
1991	\| type_name '.' typegen_name
1992	{ $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
1993	;
1994
1995	typegen_name: // CFA
1996	TYPEGENname
1997	{ $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1998	\| TYPEGENname '(' ')'
1999	{ $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2000	\| TYPEGENname '(' type_list ')'
2001	{ $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
2002	;
2003
2004	elaborated_type: // struct, union, enum
2005	aggregate_type
2006	\| enum_type
2007	;
2008
2009	elaborated_type_nobody: // struct, union, enum - {...}
2010	aggregate_type_nobody
2011	\| enum_type_nobody
2012	;
2013
2014	fred:
2015	// empty
2016	{ yyy = false; }
2017	;
2018
2019	aggregate_type: // struct, union
2020	aggregate_key attribute_list_opt
2021	{ forall = false; } // reset
2022	'{' field_declaration_list_opt '}' type_parameters_opt
2023	{ $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2024	\| aggregate_key attribute_list_opt identifier fred
2025	{
2026	typedefTable.makeTypedef( *$3, forall \|\| typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2027	forall = false; // reset
2028	}
2029	'{' field_declaration_list_opt '}' type_parameters_opt
2030	{ $$ = DeclarationNode::newAggregate( $1, $3, $9, $7, true )->addQualifiers( $2 ); }
2031	\| aggregate_key attribute_list_opt type_name fred
2032	{
2033	// for type_name can be a qualified type name S.T, in which case only the last name in the chain needs a typedef (other names in the chain should already have one)
2034	typedefTable.makeTypedef( *$3->type->leafName(), forall \|\| typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2035	forall = false; // reset
2036	}
2037	'{' field_declaration_list_opt '}' type_parameters_opt
2038	{ $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $9, $7, true )->addQualifiers( $2 ); }
2039	\| aggregate_type_nobody
2040	;
2041
2042	type_parameters_opt:
2043	// empty
2044	{ $$ = nullptr; } %prec '}'
2045	\| '(' type_list ')'
2046	{ $$ = $2; }
2047	;
2048
2049	aggregate_type_nobody: // struct, union - {...}
2050	aggregate_key attribute_list_opt identifier fred
2051	{
2052	typedefTable.makeTypedef( *$3, forall \|\| typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname );
2053	forall = false; // reset
2054	$$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2055	}
2056	\| aggregate_key attribute_list_opt type_name fred
2057	{
2058	forall = false; // reset
2059	// Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2060	// switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2061	// delete newFromTypeGen.
2062	$$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2063	$3->type->symbolic.name = nullptr;
2064	$3->type->symbolic.actuals = nullptr;
2065	delete $3;
2066	}
2067	;
2068
2069	aggregate_key:
2070	aggregate_data
2071	\| aggregate_control
2072	;
2073
2074	aggregate_data:
2075	STRUCT
2076	{ yyy = true; $$ = AggregateDecl::Struct; }
2077	\| UNION
2078	{ yyy = true; $$ = AggregateDecl::Union; }
2079	\| EXCEPTION // CFA
2080	{ yyy = true; $$ = AggregateDecl::Exception; }
2081	;
2082
2083	aggregate_control: // CFA
2084	GENERATOR
2085	{ SemanticError( yylloc, "generator is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2086	\| MONITOR GENERATOR
2087	{ SemanticError( yylloc, "monitor generator is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2088	\| COROUTINE
2089	{ yyy = true; $$ = AggregateDecl::Coroutine; }
2090	\| MONITOR
2091	{ yyy = true; $$ = AggregateDecl::Monitor; }
2092	\| MONITOR COROUTINE
2093	{ SemanticError( yylloc, "monitor coroutine is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2094	\| THREAD
2095	{ yyy = true; $$ = AggregateDecl::Thread; }
2096	\| MONITOR THREAD
2097	{ SemanticError( yylloc, "monitor thread is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2098	;
2099
2100	field_declaration_list_opt:
2101	// empty
2102	{ $$ = nullptr; }
2103	\| field_declaration_list_opt field_declaration
2104	{ $$ = $1 ? $1->appendList( $2 ) : $2; }
2105	;
2106
2107	field_declaration:
2108	type_specifier field_declaring_list_opt ';'
2109	{ $$ = fieldDecl( $1, $2 ); }
2110	\| EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2111	{ $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2112	\| INLINE type_specifier field_abstract_list_opt ';' // CFA
2113	{
2114	if ( ! $3 ) { // field declarator ?
2115	$3 = DeclarationNode::newName( nullptr );
2116	} // if
2117	$3->inLine = true;
2118	$$ = distAttr( $2, $3 ); // mark all fields in list
2119	distInl( $3 );
2120	}
2121	\| INLINE aggregate_control ';' // CFA
2122	{ SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2123	\| typedef_declaration ';' // CFA
2124	\| cfa_field_declaring_list ';' // CFA, new style field declaration
2125	\| EXTENSION cfa_field_declaring_list ';' // GCC
2126	{ distExt( $2 ); $$ = $2; } // mark all fields in list
2127	\| INLINE cfa_field_abstract_list ';' // CFA, new style field declaration
2128	{ $$ = $2; } // mark all fields in list
2129	\| cfa_typedef_declaration ';' // CFA
2130	\| static_assert // C11
2131	;
2132
2133	field_declaring_list_opt:
2134	// empty
2135	{ $$ = nullptr; }
2136	\| field_declarator
2137	\| field_declaring_list_opt ',' attribute_list_opt field_declarator
2138	{ $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2139	;
2140
2141	field_declarator:
2142	bit_subrange_size // C special case, no field name
2143	{ $$ = DeclarationNode::newBitfield( $1 ); }
2144	\| variable_declarator bit_subrange_size_opt
2145	// A semantic check is required to ensure bit_subrange only appears on integral types.
2146	{ $$ = $1->addBitfield( $2 ); }
2147	\| variable_type_redeclarator bit_subrange_size_opt
2148	// A semantic check is required to ensure bit_subrange only appears on integral types.
2149	{ $$ = $1->addBitfield( $2 ); }
2150	;
2151
2152	field_abstract_list_opt:
2153	// empty
2154	{ $$ = nullptr; }
2155	\| field_abstract
2156	\| field_abstract_list_opt ',' attribute_list_opt field_abstract
2157	{ $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2158	;
2159
2160	field_abstract:
2161	// no bit fields
2162	variable_abstract_declarator
2163	;
2164
2165	cfa_field_declaring_list: // CFA, new style field declaration
2166	// bit-fields are handled by C declarations
2167	cfa_abstract_declarator_tuple identifier_or_type_name
2168	{ $$ = $1->addName( $2 ); }
2169	\| cfa_field_declaring_list ',' identifier_or_type_name
2170	{ $$ = $1->appendList( $1->cloneType( $3 ) ); }
2171	;
2172
2173	cfa_field_abstract_list: // CFA, new style field declaration
2174	// bit-fields are handled by C declarations
2175	cfa_abstract_declarator_tuple
2176	\| cfa_field_abstract_list ','
2177	{ $$ = $1->appendList( $1->cloneType( 0 ) ); }
2178	;
2179
2180	bit_subrange_size_opt:
2181	// empty
2182	{ $$ = nullptr; }
2183	\| bit_subrange_size
2184	;
2185
2186	bit_subrange_size:
2187	':' assignment_expression
2188	{ $$ = $2; }
2189	;
2190
2191	enum_type: // enum
2192	ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2193	{ $$ = DeclarationNode::newEnum( nullptr, $4, true )->addQualifiers( $2 ); }
2194	\| ENUM attribute_list_opt identifier
2195	{ typedefTable.makeTypedef( *$3 ); }
2196	'{' enumerator_list comma_opt '}'
2197	{ $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
2198	\| ENUM attribute_list_opt type_name
2199	'{' enumerator_list comma_opt '}'
2200	{ $$ = DeclarationNode::newEnum( $3->type->symbolic.name, $5, true )->addQualifiers( $2 ); }
2201	\| enum_type_nobody
2202	;
2203
2204	enum_type_nobody: // enum - {...}
2205	ENUM attribute_list_opt identifier
2206	{
2207	typedefTable.makeTypedef( *$3 );
2208	$$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 );
2209	}
2210	\| ENUM attribute_list_opt type_name
2211	{
2212	typedefTable.makeTypedef( *$3->type->symbolic.name );
2213	$$ = DeclarationNode::newEnum( $3->type->symbolic.name, 0, false )->addQualifiers( $2 );
2214	}
2215	;
2216
2217	enumerator_list:
2218	identifier_or_type_name enumerator_value_opt
2219	{ $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
2220	\| enumerator_list ',' identifier_or_type_name enumerator_value_opt
2221	{ $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
2222	;
2223
2224	enumerator_value_opt:
2225	// empty
2226	{ $$ = nullptr; }
2227	\| '=' constant_expression
2228	{ $$ = $2; }
2229	;
2230
2231	cfa_parameter_ellipsis_list_opt: // CFA, abstract + real
2232	// empty
2233	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2234	\| ELLIPSIS
2235	{ $$ = nullptr; }
2236	\| cfa_abstract_parameter_list
2237	\| cfa_parameter_list
2238	\| cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2239	{ $$ = $1->appendList( $5 ); }
2240	\| cfa_abstract_parameter_list pop ',' push ELLIPSIS
2241	{ $$ = $1->addVarArgs(); }
2242	\| cfa_parameter_list pop ',' push ELLIPSIS
2243	{ $$ = $1->addVarArgs(); }
2244	;
2245
2246	cfa_parameter_list: // CFA
2247	// To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2248	// factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2249	cfa_parameter_declaration
2250	\| cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2251	{ $$ = $1->appendList( $5 ); }
2252	\| cfa_parameter_list pop ',' push cfa_parameter_declaration
2253	{ $$ = $1->appendList( $5 ); }
2254	\| cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2255	{ $$ = $1->appendList( $5 )->appendList( $9 ); }
2256	;
2257
2258	cfa_abstract_parameter_list: // CFA, new & old style abstract
2259	cfa_abstract_parameter_declaration
2260	\| cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2261	{ $$ = $1->appendList( $5 ); }
2262	;
2263
2264	parameter_type_list_opt:
2265	// empty
2266	{ $$ = nullptr; }
2267	\| ELLIPSIS
2268	{ $$ = nullptr; }
2269	\| parameter_list
2270	\| parameter_list pop ',' push ELLIPSIS
2271	{ $$ = $1->addVarArgs(); }
2272	;
2273
2274	parameter_list: // abstract + real
2275	abstract_parameter_declaration
2276	\| parameter_declaration
2277	\| parameter_list pop ',' push abstract_parameter_declaration
2278	{ $$ = $1->appendList( $5 ); }
2279	\| parameter_list pop ',' push parameter_declaration
2280	{ $$ = $1->appendList( $5 ); }
2281	;
2282
2283	// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2284	// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2285
2286	cfa_parameter_declaration: // CFA, new & old style parameter declaration
2287	parameter_declaration
2288	\| cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initialize_opt
2289	{ $$ = $1->addName( $2 ); }
2290	\| cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2291	// To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2292	{ $$ = $1->addName( $2 ); }
2293	\| type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2294	{ $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2295	\| cfa_function_specifier
2296	;
2297
2298	cfa_abstract_parameter_declaration: // CFA, new & old style parameter declaration
2299	abstract_parameter_declaration
2300	\| cfa_identifier_parameter_declarator_no_tuple
2301	\| cfa_abstract_tuple
2302	// To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2303	\| type_qualifier_list cfa_abstract_tuple
2304	{ $$ = $2->addQualifiers( $1 ); }
2305	\| cfa_abstract_function
2306	;
2307
2308	parameter_declaration:
2309	// No SUE declaration in parameter list.
2310	declaration_specifier_nobody identifier_parameter_declarator default_initialize_opt
2311	{ $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2312	\| declaration_specifier_nobody type_parameter_redeclarator default_initialize_opt
2313	{ $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2314	;
2315
2316	abstract_parameter_declaration:
2317	declaration_specifier_nobody default_initialize_opt
2318	{ $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2319	\| declaration_specifier_nobody abstract_parameter_declarator default_initialize_opt
2320	{ $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2321	;
2322
2323	// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2324	// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2325	// identifiers. The ANSI-style parameter-list can redefine a typedef name.
2326
2327	identifier_list: // K&R-style parameter list => no types
2328	identifier
2329	{ $$ = DeclarationNode::newName( $1 ); }
2330	\| identifier_list ',' identifier
2331	{ $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2332	;
2333
2334	identifier_or_type_name:
2335	identifier
2336	\| TYPEDEFname
2337	\| TYPEGENname
2338	;
2339
2340	type_no_function: // sizeof, alignof, cast (constructor)
2341	cfa_abstract_declarator_tuple // CFA
2342	\| type_specifier
2343	\| type_specifier abstract_declarator
2344	{ $$ = $2->addType( $1 ); }
2345	;
2346
2347	type: // typeof, assertion
2348	type_no_function
2349	\| cfa_abstract_function // CFA
2350	;
2351
2352	initializer_opt:
2353	// empty
2354	{ $$ = nullptr; }
2355	\| '=' initializer
2356	{ $$ = $2; }
2357	\| '=' VOID
2358	{ $$ = new InitializerNode( true ); }
2359	\| ATassign initializer
2360	{ $$ = $2->set_maybeConstructed( false ); }
2361	;
2362
2363	initializer:
2364	assignment_expression { $$ = new InitializerNode( $1 ); }
2365	\| '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
2366	;
2367
2368	initializer_list_opt:
2369	// empty
2370	{ $$ = nullptr; }
2371	\| initializer
2372	\| designation initializer { $$ = $2->set_designators( $1 ); }
2373	\| initializer_list_opt ',' initializer { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2374	\| initializer_list_opt ',' designation initializer
2375	{ $$ = (InitializerNode *)($1->set_last( $4->set_designators( $3 ) )); }
2376	;
2377
2378	// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2379	// '=' to separator the designator from the initializer value, as in:
2380	//
2381	// int x[10] = { [1] = 3 };
2382	//
2383	// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment. To disambiguate this case, CFA
2384	// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2385	// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2386	// shift/reduce conflicts
2387
2388	designation:
2389	designator_list ':' // C99, CFA uses ":" instead of "="
2390	\| identifier ':' // GCC, field name
2391	{ $$ = new ExpressionNode( build_varref( $1 ) ); }
2392	;
2393
2394	designator_list: // C99
2395	designator
2396	\| designator_list designator
2397	{ $$ = (ExpressionNode *)($1->set_last( $2 )); }
2398	//\| designator_list designator { $$ = new ExpressionNode( $1, $2 ); }
2399	;
2400
2401	designator:
2402	'.' identifier // C99, field name
2403	{ $$ = new ExpressionNode( build_varref( $2 ) ); }
2404	\| '[' push assignment_expression pop ']' // C99, single array element
2405	// assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2406	{ $$ = $3; }
2407	\| '[' push subrange pop ']' // CFA, multiple array elements
2408	{ $$ = $3; }
2409	\| '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2410	{ $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $3 ), maybeMoveBuild< Expression >( $5 ) ) ); }
2411	\| '.' '[' push field_name_list pop ']' // CFA, tuple field selector
2412	{ $$ = $4; }
2413	;
2414
2415	// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2416	// rather than an object-oriented type system. This required four groups of extensions:
2417	//
2418	// Overloading: function, data, and operator identifiers may be overloaded.
2419	//
2420	// Type declarations: "type" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2421	// and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2422	// definitions of new types. Type declarations with storage class "extern" provide opaque types.
2423	//
2424	// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2425	// site. A polymorphic function is not a template; it is a function, with an address and a type.
2426	//
2427	// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2428	// types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2429	// hierarchies. Unlike classes, they can define relationships between types. Assertions declare that a type or
2430	// types provide the operations declared by a specification. Assertions are normally used to declare requirements
2431	// on type arguments of polymorphic functions.
2432
2433	type_parameter_list: // CFA
2434	type_parameter
2435	\| type_parameter_list ',' type_parameter
2436	{ $$ = $1->appendList( $3 ); }
2437	;
2438
2439	type_initializer_opt: // CFA
2440	// empty
2441	{ $$ = nullptr; }
2442	\| '=' type
2443	{ $$ = $2; }
2444	;
2445
2446	type_parameter: // CFA
2447	type_class identifier_or_type_name
2448	{ typedefTable.addToScope( *$2, TYPEDEFname, "9" ); }
2449	type_initializer_opt assertion_list_opt
2450	{ $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2451	\| type_specifier identifier_parameter_declarator
2452	\| assertion_list
2453	{ $$ = DeclarationNode::newTypeParam( TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2454	;
2455
2456	type_class: // CFA
2457	OTYPE
2458	{ $$ = TypeDecl::Otype; }
2459	\| DTYPE
2460	{ $$ = TypeDecl::Dtype; }
2461	\| FTYPE
2462	{ $$ = TypeDecl::Ftype; }
2463	\| TTYPE
2464	{ $$ = TypeDecl::Ttype; }
2465	;
2466
2467	assertion_list_opt: // CFA
2468	// empty
2469	{ $$ = nullptr; }
2470	\| assertion_list
2471	;
2472
2473	assertion_list: // CFA
2474	assertion
2475	\| assertion_list assertion
2476	{ $$ = $1 ? $1->appendList( $2 ) : $2; }
2477	;
2478
2479	assertion: // CFA
2480	'\|' identifier_or_type_name '(' type_list ')'
2481	{ $$ = DeclarationNode::newTraitUse( $2, $4 ); }
2482	\| '\|' '{' push trait_declaration_list pop '}'
2483	{ $$ = $4; }
2484	// \| '\|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
2485	// { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
2486	;
2487
2488	type_list: // CFA
2489	type
2490	{ $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2491	\| assignment_expression
2492	{ SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $1->build()) ); $$ = nullptr; }
2493	\| type_list ',' type
2494	{ $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) )); }
2495	\| type_list ',' assignment_expression
2496	{ SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $3->build()) ); $$ = nullptr; }
2497	// { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2498	;
2499
2500	type_declaring_list: // CFA
2501	OTYPE type_declarator
2502	{ $$ = $2; }
2503	\| storage_class_list OTYPE type_declarator
2504	{ $$ = $3->addQualifiers( $1 ); }
2505	\| type_declaring_list ',' type_declarator
2506	{ $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2507	;
2508
2509	type_declarator: // CFA
2510	type_declarator_name assertion_list_opt
2511	{ $$ = $1->addAssertions( $2 ); }
2512	\| type_declarator_name assertion_list_opt '=' type
2513	{ $$ = $1->addAssertions( $2 )->addType( $4 ); }
2514	;
2515
2516	type_declarator_name: // CFA
2517	identifier_or_type_name
2518	{
2519	typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "10" );
2520	$$ = DeclarationNode::newTypeDecl( $1, 0 );
2521	}
2522	\| identifier_or_type_name '(' type_parameter_list ')'
2523	{
2524	typedefTable.addToEnclosingScope( *$1, TYPEGENname, "11" );
2525	$$ = DeclarationNode::newTypeDecl( $1, $3 );
2526	}
2527	;
2528
2529	trait_specifier: // CFA
2530	TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
2531	{ $$ = DeclarationNode::newTrait( $2, $4, 0 ); }
2532	\| TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
2533	{ $$ = DeclarationNode::newTrait( $2, $4, $8 ); }
2534	;
2535
2536	trait_declaration_list: // CFA
2537	trait_declaration
2538	\| trait_declaration_list pop push trait_declaration
2539	{ $$ = $1->appendList( $4 ); }
2540	;
2541
2542	trait_declaration: // CFA
2543	cfa_trait_declaring_list ';'
2544	\| trait_declaring_list ';'
2545	;
2546
2547	cfa_trait_declaring_list: // CFA
2548	cfa_variable_specifier
2549	\| cfa_function_specifier
2550	\| cfa_trait_declaring_list pop ',' push identifier_or_type_name
2551	{ $$ = $1->appendList( $1->cloneType( $5 ) ); }
2552	;
2553
2554	trait_declaring_list: // CFA
2555	type_specifier declarator
2556	{ $$ = $2->addType( $1 ); }
2557	\| trait_declaring_list pop ',' push declarator
2558	{ $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
2559	;
2560
2561	//*************************** EXTERNAL DEFINITIONS ***************************
2562
2563	translation_unit:
2564	// empty, input file
2565	\| external_definition_list
2566	{ parseTree = parseTree ? parseTree->appendList( $1 ) : $1; }
2567	;
2568
2569	external_definition_list:
2570	push external_definition pop
2571	{ $$ = $2; }
2572	\| external_definition_list push external_definition pop
2573	{ $$ = $1 ? $1->appendList( $3 ) : $3; }
2574	;
2575
2576	external_definition_list_opt:
2577	// empty
2578	{ $$ = nullptr; }
2579	\| external_definition_list
2580	;
2581
2582	up:
2583	{ typedefTable.up( forall ); forall = false; }
2584	;
2585
2586	down:
2587	{ typedefTable.down(); }
2588	;
2589
2590	external_definition:
2591	declaration
2592	\| external_function_definition
2593	\| EXTENSION external_definition // GCC, multiple __extension__ allowed, meaning unknown
2594	{
2595	distExt( $2 ); // mark all fields in list
2596	$$ = $2;
2597	}
2598	\| ASM '(' string_literal ')' ';' // GCC, global assembler statement
2599	{
2600	$$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( false, $3, 0 ) ) );
2601	}
2602	\| EXTERN STRINGliteral // C++-style linkage specifier
2603	{
2604	linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
2605	linkage = LinkageSpec::update( yylloc, linkage, $2 );
2606	}
2607	'{' up external_definition_list_opt down '}'
2608	{
2609	linkage = linkageStack.top();
2610	linkageStack.pop();
2611	$$ = $6;
2612	}
2613	\| type_qualifier_list
2614	{
2615	if ( $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2616	if ( $1->type->forall ) forall = true; // remember generic type
2617	}
2618	'{' up external_definition_list_opt down '}' // CFA, namespace
2619	{
2620	distQual( $5, $1 );
2621	forall = false;
2622	$$ = $5;
2623	}
2624	\| declaration_qualifier_list
2625	{
2626	if ( $1->type && $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2627	if ( $1->type && $1->type->forall ) forall = true; // remember generic type
2628	}
2629	'{' up external_definition_list_opt down '}' // CFA, namespace
2630	{
2631	distQual( $5, $1 );
2632	forall = false;
2633	$$ = $5;
2634	}
2635	\| declaration_qualifier_list type_qualifier_list
2636	{
2637	if ( ($1->type && $1->type->qualifiers.val) \|\| $2->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2638	if ( ($1->type && $1->type->forall) \|\| $2->type->forall ) forall = true; // remember generic type
2639	}
2640	'{' up external_definition_list_opt down '}' // CFA, namespace
2641	{
2642	distQual( $6, $1->addQualifiers( $2 ) );
2643	forall = false;
2644	$$ = $6;
2645	}
2646	;
2647
2648	external_function_definition:
2649	function_definition
2650	// These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2651	// legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2652	// Parsing is possible because function_definition does not appear in the context of an expression (nested
2653	// functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2654	// declaration must still have a type_specifier. OBSOLESCENT (see 1)
2655	\| function_declarator compound_statement
2656	{ $$ = $1->addFunctionBody( $2 ); }
2657	\| KR_function_declarator KR_parameter_list_opt compound_statement
2658	{ $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
2659	;
2660
2661	with_clause_opt:
2662	// empty
2663	{ $$ = nullptr; forall = false; }
2664	\| WITH '(' tuple_expression_list ')'
2665	{ $$ = $3; forall = false; }
2666	;
2667
2668	function_definition:
2669	cfa_function_declaration with_clause_opt compound_statement // CFA
2670	{
2671	// Add the function body to the last identifier in the function definition list, i.e., foo3:
2672	// [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2673	$1->get_last()->addFunctionBody( $3, $2 );
2674	$$ = $1;
2675	}
2676	\| declaration_specifier function_declarator with_clause_opt compound_statement
2677	{
2678	rebindForall( $1, $2 );
2679	$$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2680	}
2681	\| declaration_specifier variable_type_redeclarator with_clause_opt compound_statement
2682	{
2683	rebindForall( $1, $2 );
2684	$$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2685	}
2686	// handles default int return type, OBSOLESCENT (see 1)
2687	\| type_qualifier_list function_declarator with_clause_opt compound_statement
2688	{ $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2689	// handles default int return type, OBSOLESCENT (see 1)
2690	\| declaration_qualifier_list function_declarator with_clause_opt compound_statement
2691	{ $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2692	// handles default int return type, OBSOLESCENT (see 1)
2693	\| declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2694	{ $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2695
2696	// Old-style K&R function definition, OBSOLESCENT (see 4)
2697	\| declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2698	{
2699	rebindForall( $1, $2 );
2700	$$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2701	}
2702	// handles default int return type, OBSOLESCENT (see 1)
2703	\| type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2704	{ $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2705	// handles default int return type, OBSOLESCENT (see 1)
2706	\| declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2707	{ $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2708	// handles default int return type, OBSOLESCENT (see 1)
2709	\| declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2710	{ $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2711	;
2712
2713	declarator:
2714	variable_declarator
2715	\| variable_type_redeclarator
2716	\| function_declarator
2717	;
2718
2719	subrange:
2720	constant_expression '~' constant_expression // CFA, integer subrange
2721	{ $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
2722	;
2723
2724	asm_name_opt: // GCC
2725	// empty
2726	{ $$ = nullptr; }
2727	\| ASM '(' string_literal ')' attribute_list_opt
2728	{
2729	DeclarationNode * name = new DeclarationNode();
2730	name->asmName = $3;
2731	$$ = name->addQualifiers( $5 );
2732	}
2733	;
2734
2735	attribute_list_opt: // GCC
2736	// empty
2737	{ $$ = nullptr; }
2738	\| attribute_list
2739	;
2740
2741	attribute_list: // GCC
2742	attribute
2743	\| attribute_list attribute
2744	{ $$ = $2->addQualifiers( $1 ); }
2745	;
2746
2747	attribute: // GCC
2748	ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2749	{ $$ = $4; }
2750	;
2751
2752	attribute_name_list: // GCC
2753	attribute_name
2754	\| attribute_name_list ',' attribute_name
2755	{ $$ = $3->addQualifiers( $1 ); }
2756	;
2757
2758	attribute_name: // GCC
2759	// empty
2760	{ $$ = nullptr; }
2761	\| attr_name
2762	{ $$ = DeclarationNode::newAttribute( $1 ); }
2763	\| attr_name '(' argument_expression_list ')'
2764	{ $$ = DeclarationNode::newAttribute( $1, $3 ); }
2765	;
2766
2767	attr_name: // GCC
2768	IDENTIFIER
2769	\| quasi_keyword
2770	\| TYPEDEFname
2771	\| TYPEGENname
2772	\| FALLTHROUGH
2773	{ $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2774	\| CONST
2775	{ $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2776	;
2777
2778	// ============================================================================
2779	// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2780	// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2781	// in:
2782	//
2783	// int (*f())[10] { ... };
2784	// ... (*f())[3] += 1; // definition mimics usage
2785	//
2786	// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2787	// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2788	// ============================================================================
2789
2790	// ----------------------------------------------------------------------------
2791	// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2792	// to define a variable or function prototype, e.g.:
2793	//
2794	// valid declaration invalid definition
2795	// ----------------- ------------------
2796	// int f; int f {}
2797	// int f; int f {}
2798	// int f[10]; int f[10] {}
2799	// int (f)(int); int (f)(int) {}
2800	//
2801	// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2802	// variable_declarator and function_declarator.
2803	// ----------------------------------------------------------------------------
2804
2805	// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2806	// declaring an array of functions versus a pointer to an array of functions.
2807
2808	variable_declarator:
2809	paren_identifier attribute_list_opt
2810	{ $$ = $1->addQualifiers( $2 ); }
2811	\| variable_ptr
2812	\| variable_array attribute_list_opt
2813	{ $$ = $1->addQualifiers( $2 ); }
2814	\| variable_function attribute_list_opt
2815	{ $$ = $1->addQualifiers( $2 ); }
2816	;
2817
2818	paren_identifier:
2819	identifier
2820	{ $$ = DeclarationNode::newName( $1 ); }
2821	\| '(' paren_identifier ')' // redundant parenthesis
2822	{ $$ = $2; }
2823	;
2824
2825	variable_ptr:
2826	ptrref_operator variable_declarator
2827	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2828	\| ptrref_operator type_qualifier_list variable_declarator
2829	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2830	\| '(' variable_ptr ')' attribute_list_opt
2831	{ $$ = $2->addQualifiers( $4 ); } // redundant parenthesis
2832	;
2833
2834	variable_array:
2835	paren_identifier array_dimension
2836	{ $$ = $1->addArray( $2 ); }
2837	\| '(' variable_ptr ')' array_dimension
2838	{ $$ = $2->addArray( $4 ); }
2839	\| '(' variable_array ')' multi_array_dimension // redundant parenthesis
2840	{ $$ = $2->addArray( $4 ); }
2841	\| '(' variable_array ')' // redundant parenthesis
2842	{ $$ = $2; }
2843	;
2844
2845	variable_function:
2846	'(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2847	{ $$ = $2->addParamList( $6 ); }
2848	\| '(' variable_function ')' // redundant parenthesis
2849	{ $$ = $2; }
2850	;
2851
2852	// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2853	// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2854	// is the same scope. The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2855
2856	function_declarator:
2857	function_no_ptr attribute_list_opt
2858	{ $$ = $1->addQualifiers( $2 ); }
2859	\| function_ptr
2860	\| function_array attribute_list_opt
2861	{ $$ = $1->addQualifiers( $2 ); }
2862	;
2863
2864	function_no_ptr:
2865	paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2866	{ $$ = $1->addParamList( $4 ); }
2867	\| '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2868	{ $$ = $2->addParamList( $6 ); }
2869	\| '(' function_no_ptr ')' // redundant parenthesis
2870	{ $$ = $2; }
2871	;
2872
2873	function_ptr:
2874	ptrref_operator function_declarator
2875	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2876	\| ptrref_operator type_qualifier_list function_declarator
2877	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2878	\| '(' function_ptr ')'
2879	{ $$ = $2; }
2880	;
2881
2882	function_array:
2883	'(' function_ptr ')' array_dimension
2884	{ $$ = $2->addArray( $4 ); }
2885	\| '(' function_array ')' multi_array_dimension // redundant parenthesis
2886	{ $$ = $2->addArray( $4 ); }
2887	\| '(' function_array ')' // redundant parenthesis
2888	{ $$ = $2; }
2889	;
2890
2891	// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
2892	//
2893	// f( a, b, c ) int a, *b, c[]; {}
2894	//
2895	// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
2896	// returning arrays and functions versus pointers to arrays and functions.
2897
2898	KR_function_declarator:
2899	KR_function_no_ptr
2900	\| KR_function_ptr
2901	\| KR_function_array
2902	;
2903
2904	KR_function_no_ptr:
2905	paren_identifier '(' identifier_list ')' // function_declarator handles empty parameter
2906	{ $$ = $1->addIdList( $3 ); }
2907	\| '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
2908	{ $$ = $2->addParamList( $6 ); }
2909	\| '(' KR_function_no_ptr ')' // redundant parenthesis
2910	{ $$ = $2; }
2911	;
2912
2913	KR_function_ptr:
2914	ptrref_operator KR_function_declarator
2915	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2916	\| ptrref_operator type_qualifier_list KR_function_declarator
2917	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2918	\| '(' KR_function_ptr ')'
2919	{ $$ = $2; }
2920	;
2921
2922	KR_function_array:
2923	'(' KR_function_ptr ')' array_dimension
2924	{ $$ = $2->addArray( $4 ); }
2925	\| '(' KR_function_array ')' multi_array_dimension // redundant parenthesis
2926	{ $$ = $2->addArray( $4 ); }
2927	\| '(' KR_function_array ')' // redundant parenthesis
2928	{ $$ = $2; }
2929	;
2930
2931	// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2932	//
2933	// typedef int foo;
2934	// {
2935	// int foo; // redefine typedef name in new scope
2936	// }
2937	//
2938	// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2939	// and functions versus pointers to arrays and functions.
2940
2941	variable_type_redeclarator:
2942	paren_type attribute_list_opt
2943	{ $$ = $1->addQualifiers( $2 ); }
2944	\| type_ptr
2945	\| type_array attribute_list_opt
2946	{ $$ = $1->addQualifiers( $2 ); }
2947	\| type_function attribute_list_opt
2948	{ $$ = $1->addQualifiers( $2 ); }
2949	;
2950
2951	paren_type:
2952	typedef
2953	// hide type name in enclosing scope by variable name
2954	{
2955	// if ( ! typedefTable.existsCurr( *$1->name ) ) {
2956	typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "ID" );
2957	// } else {
2958	// SemanticError( yylloc, string("'") + *$1->name + "' redeclared as different kind of symbol." ); $$ = nullptr;
2959	// } // if
2960	}
2961	\| '(' paren_type ')'
2962	{ $$ = $2; }
2963	;
2964
2965	type_ptr:
2966	ptrref_operator variable_type_redeclarator
2967	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2968	\| ptrref_operator type_qualifier_list variable_type_redeclarator
2969	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2970	\| '(' type_ptr ')' attribute_list_opt
2971	{ $$ = $2->addQualifiers( $4 ); } // redundant parenthesis
2972	;
2973
2974	type_array:
2975	paren_type array_dimension
2976	{ $$ = $1->addArray( $2 ); }
2977	\| '(' type_ptr ')' array_dimension
2978	{ $$ = $2->addArray( $4 ); }
2979	\| '(' type_array ')' multi_array_dimension // redundant parenthesis
2980	{ $$ = $2->addArray( $4 ); }
2981	\| '(' type_array ')' // redundant parenthesis
2982	{ $$ = $2; }
2983	;
2984
2985	type_function:
2986	paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2987	{ $$ = $1->addParamList( $4 ); }
2988	\| '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2989	{ $$ = $2->addParamList( $6 ); }
2990	\| '(' type_function ')' // redundant parenthesis
2991	{ $$ = $2; }
2992	;
2993
2994	// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
2995	// typedef name and allows the C99 array options, which can only appear in a parameter list. The pattern precludes
2996	// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
2997	// pointers to arrays and functions.
2998
2999	identifier_parameter_declarator:
3000	paren_identifier attribute_list_opt
3001	{ $$ = $1->addQualifiers( $2 ); }
3002	\| '&' MUTEX paren_identifier attribute_list_opt
3003	{ $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3004	\| identifier_parameter_ptr
3005	\| identifier_parameter_array attribute_list_opt
3006	{ $$ = $1->addQualifiers( $2 ); }
3007	\| identifier_parameter_function attribute_list_opt
3008	{ $$ = $1->addQualifiers( $2 ); }
3009	;
3010
3011	identifier_parameter_ptr:
3012	ptrref_operator identifier_parameter_declarator
3013	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3014	\| ptrref_operator type_qualifier_list identifier_parameter_declarator
3015	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3016	\| '(' identifier_parameter_ptr ')' attribute_list_opt
3017	{ $$ = $2->addQualifiers( $4 ); }
3018	;
3019
3020	identifier_parameter_array:
3021	paren_identifier array_parameter_dimension
3022	{ $$ = $1->addArray( $2 ); }
3023	\| '(' identifier_parameter_ptr ')' array_dimension
3024	{ $$ = $2->addArray( $4 ); }
3025	\| '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3026	{ $$ = $2->addArray( $4 ); }
3027	\| '(' identifier_parameter_array ')' // redundant parenthesis
3028	{ $$ = $2; }
3029	;
3030
3031	identifier_parameter_function:
3032	paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3033	{ $$ = $1->addParamList( $4 ); }
3034	\| '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3035	{ $$ = $2->addParamList( $6 ); }
3036	\| '(' identifier_parameter_function ')' // redundant parenthesis
3037	{ $$ = $2; }
3038	;
3039
3040	// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3041	// e.g.:
3042	//
3043	// typedef int foo;
3044	// forall( otype T ) struct foo;
3045	// int f( int foo ); // redefine typedef name in new scope
3046	//
3047	// and allows the C99 array options, which can only appear in a parameter list.
3048
3049	type_parameter_redeclarator:
3050	typedef attribute_list_opt
3051	{ $$ = $1->addQualifiers( $2 ); }
3052	\| '&' MUTEX typedef attribute_list_opt
3053	{ $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3054	\| type_parameter_ptr
3055	\| type_parameter_array attribute_list_opt
3056	{ $$ = $1->addQualifiers( $2 ); }
3057	\| type_parameter_function attribute_list_opt
3058	{ $$ = $1->addQualifiers( $2 ); }
3059	;
3060
3061	typedef:
3062	TYPEDEFname
3063	{ $$ = DeclarationNode::newName( $1 ); }
3064	\| TYPEGENname
3065	{ $$ = DeclarationNode::newName( $1 ); }
3066	;
3067
3068	type_parameter_ptr:
3069	ptrref_operator type_parameter_redeclarator
3070	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3071	\| ptrref_operator type_qualifier_list type_parameter_redeclarator
3072	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3073	\| '(' type_parameter_ptr ')' attribute_list_opt
3074	{ $$ = $2->addQualifiers( $4 ); }
3075	;
3076
3077	type_parameter_array:
3078	typedef array_parameter_dimension
3079	{ $$ = $1->addArray( $2 ); }
3080	\| '(' type_parameter_ptr ')' array_parameter_dimension
3081	{ $$ = $2->addArray( $4 ); }
3082	;
3083
3084	type_parameter_function:
3085	typedef '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3086	{ $$ = $1->addParamList( $4 ); }
3087	\| '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3088	{ $$ = $2->addParamList( $6 ); }
3089	;
3090
3091	// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3092	// which the type applies, e.g.:
3093	//
3094	// sizeof( int );
3095	// sizeof( int * );
3096	// sizeof( int [10] );
3097	// sizeof( int (*)() );
3098	// sizeof( int () );
3099	//
3100	// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3101	// and functions versus pointers to arrays and functions.
3102
3103	abstract_declarator:
3104	abstract_ptr
3105	\| abstract_array attribute_list_opt
3106	{ $$ = $1->addQualifiers( $2 ); }
3107	\| abstract_function attribute_list_opt
3108	{ $$ = $1->addQualifiers( $2 ); }
3109	;
3110
3111	abstract_ptr:
3112	ptrref_operator
3113	{ $$ = DeclarationNode::newPointer( 0, $1 ); }
3114	\| ptrref_operator type_qualifier_list
3115	{ $$ = DeclarationNode::newPointer( $2, $1 ); }
3116	\| ptrref_operator abstract_declarator
3117	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3118	\| ptrref_operator type_qualifier_list abstract_declarator
3119	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3120	\| '(' abstract_ptr ')' attribute_list_opt
3121	{ $$ = $2->addQualifiers( $4 ); }
3122	;
3123
3124	abstract_array:
3125	array_dimension
3126	\| '(' abstract_ptr ')' array_dimension
3127	{ $$ = $2->addArray( $4 ); }
3128	\| '(' abstract_array ')' multi_array_dimension // redundant parenthesis
3129	{ $$ = $2->addArray( $4 ); }
3130	\| '(' abstract_array ')' // redundant parenthesis
3131	{ $$ = $2; }
3132	;
3133
3134	abstract_function:
3135	'(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3136	{ $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3137	\| '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3138	{ $$ = $2->addParamList( $6 ); }
3139	\| '(' abstract_function ')' // redundant parenthesis
3140	{ $$ = $2; }
3141	;
3142
3143	array_dimension:
3144	// Only the first dimension can be empty.
3145	'[' ']'
3146	{ $$ = DeclarationNode::newArray( 0, 0, false ); }
3147	\| '[' ']' multi_array_dimension
3148	{ $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
3149	\| multi_array_dimension
3150	;
3151
3152	multi_array_dimension:
3153	'[' push assignment_expression pop ']'
3154	{ $$ = DeclarationNode::newArray( $3, 0, false ); }
3155	\| '[' push '*' pop ']' // C99
3156	{ $$ = DeclarationNode::newVarArray( 0 ); }
3157	\| multi_array_dimension '[' push assignment_expression pop ']'
3158	{ $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
3159	\| multi_array_dimension '[' push '*' pop ']' // C99
3160	{ $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3161	;
3162
3163	// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3164	// identifier to which the type applies, e.g.:
3165	//
3166	// int f( int ); // not handled here
3167	// int f( int * ); // abstract function-prototype parameter; no parameter name specified
3168	// int f( int (*)() ); // abstract function-prototype parameter; no parameter name specified
3169	// int f( int (int) ); // abstract function-prototype parameter; no parameter name specified
3170	//
3171	// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3172	// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3173	// special meaning of parenthesis around a typedef name:
3174	//
3175	// ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3176	// parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3177	// not as redundant parentheses around the identifier."
3178	//
3179	// For example:
3180	//
3181	// typedef float T;
3182	// int f( int ( T [5] ) ); // see abstract_parameter_declarator
3183	// int g( int ( T ( int ) ) ); // see abstract_parameter_declarator
3184	// int f( int f1( T a[5] ) ); // see identifier_parameter_declarator
3185	// int g( int g1( T g2( int p ) ) ); // see identifier_parameter_declarator
3186	//
3187	// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3188	// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3189	// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3190	// functions.
3191
3192	abstract_parameter_declarator:
3193	abstract_parameter_ptr
3194	\| '&' MUTEX attribute_list_opt
3195	{ $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3196	\| abstract_parameter_array attribute_list_opt
3197	{ $$ = $1->addQualifiers( $2 ); }
3198	\| abstract_parameter_function attribute_list_opt
3199	{ $$ = $1->addQualifiers( $2 ); }
3200	;
3201
3202	abstract_parameter_ptr:
3203	ptrref_operator
3204	{ $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3205	\| ptrref_operator type_qualifier_list
3206	{ $$ = DeclarationNode::newPointer( $2, $1 ); }
3207	\| ptrref_operator abstract_parameter_declarator
3208	{ $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3209	\| ptrref_operator type_qualifier_list abstract_parameter_declarator
3210	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3211	\| '(' abstract_parameter_ptr ')' attribute_list_opt
3212	{ $$ = $2->addQualifiers( $4 ); }
3213	;
3214
3215	abstract_parameter_array:
3216	array_parameter_dimension
3217	\| '(' abstract_parameter_ptr ')' array_parameter_dimension
3218	{ $$ = $2->addArray( $4 ); }
3219	\| '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3220	{ $$ = $2->addArray( $4 ); }
3221	\| '(' abstract_parameter_array ')' // redundant parenthesis
3222	{ $$ = $2; }
3223	;
3224
3225	abstract_parameter_function:
3226	'(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3227	{ $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3228	\| '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3229	{ $$ = $2->addParamList( $6 ); }
3230	\| '(' abstract_parameter_function ')' // redundant parenthesis
3231	{ $$ = $2; }
3232	;
3233
3234	array_parameter_dimension:
3235	// Only the first dimension can be empty or have qualifiers.
3236	array_parameter_1st_dimension
3237	\| array_parameter_1st_dimension multi_array_dimension
3238	{ $$ = $1->addArray( $2 ); }
3239	\| multi_array_dimension
3240	;
3241
3242	// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3243	//
3244	// ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3245	// a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3246
3247	array_parameter_1st_dimension:
3248	'[' ']'
3249	{ $$ = DeclarationNode::newArray( 0, 0, false ); }
3250	// multi_array_dimension handles the '[' '*' ']' case
3251	\| '[' push type_qualifier_list '*' pop ']' // remaining C99
3252	{ $$ = DeclarationNode::newVarArray( $3 ); }
3253	\| '[' push type_qualifier_list pop ']'
3254	{ $$ = DeclarationNode::newArray( 0, $3, false ); }
3255	// multi_array_dimension handles the '[' assignment_expression ']' case
3256	\| '[' push type_qualifier_list assignment_expression pop ']'
3257	{ $$ = DeclarationNode::newArray( $4, $3, false ); }
3258	\| '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3259	{ $$ = DeclarationNode::newArray( $5, $4, true ); }
3260	\| '[' push type_qualifier_list STATIC assignment_expression pop ']'
3261	{ $$ = DeclarationNode::newArray( $5, $3, true ); }
3262	;
3263
3264	// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3265	//
3266	// struct S {
3267	// int;
3268	// int *;
3269	// int [10];
3270	// int (*)();
3271	// };
3272
3273	variable_abstract_declarator:
3274	variable_abstract_ptr
3275	\| variable_abstract_array attribute_list_opt
3276	{ $$ = $1->addQualifiers( $2 ); }
3277	\| variable_abstract_function attribute_list_opt
3278	{ $$ = $1->addQualifiers( $2 ); }
3279	;
3280
3281	variable_abstract_ptr:
3282	ptrref_operator
3283	{ $$ = DeclarationNode::newPointer( 0, $1 ); }
3284	\| ptrref_operator type_qualifier_list
3285	{ $$ = DeclarationNode::newPointer( $2, $1 ); }
3286	\| ptrref_operator variable_abstract_declarator
3287	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3288	\| ptrref_operator type_qualifier_list variable_abstract_declarator
3289	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3290	\| '(' variable_abstract_ptr ')' attribute_list_opt
3291	{ $$ = $2->addQualifiers( $4 ); }
3292	;
3293
3294	variable_abstract_array:
3295	array_dimension
3296	\| '(' variable_abstract_ptr ')' array_dimension
3297	{ $$ = $2->addArray( $4 ); }
3298	\| '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3299	{ $$ = $2->addArray( $4 ); }
3300	\| '(' variable_abstract_array ')' // redundant parenthesis
3301	{ $$ = $2; }
3302	;
3303
3304	variable_abstract_function:
3305	'(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3306	{ $$ = $2->addParamList( $6 ); }
3307	\| '(' variable_abstract_function ')' // redundant parenthesis
3308	{ $$ = $2; }
3309	;
3310
3311	// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3312	// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3313
3314	cfa_identifier_parameter_declarator_tuple: // CFA
3315	cfa_identifier_parameter_declarator_no_tuple
3316	\| cfa_abstract_tuple
3317	\| type_qualifier_list cfa_abstract_tuple
3318	{ $$ = $2->addQualifiers( $1 ); }
3319	;
3320
3321	cfa_identifier_parameter_declarator_no_tuple: // CFA
3322	cfa_identifier_parameter_ptr
3323	\| cfa_identifier_parameter_array
3324	;
3325
3326	cfa_identifier_parameter_ptr: // CFA
3327	// No SUE declaration in parameter list.
3328	ptrref_operator type_specifier_nobody
3329	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3330	\| type_qualifier_list ptrref_operator type_specifier_nobody
3331	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3332	\| ptrref_operator cfa_abstract_function
3333	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3334	\| type_qualifier_list ptrref_operator cfa_abstract_function
3335	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3336	\| ptrref_operator cfa_identifier_parameter_declarator_tuple
3337	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3338	\| type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3339	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3340	;
3341
3342	cfa_identifier_parameter_array: // CFA
3343	// Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3344	// shift/reduce conflict with new-style empty (void) function return type.
3345	'[' ']' type_specifier_nobody
3346	{ $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3347	\| cfa_array_parameter_1st_dimension type_specifier_nobody
3348	{ $$ = $2->addNewArray( $1 ); }
3349	\| '[' ']' multi_array_dimension type_specifier_nobody
3350	{ $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3351	\| cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3352	{ $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3353	\| multi_array_dimension type_specifier_nobody
3354	{ $$ = $2->addNewArray( $1 ); }
3355
3356	\| '[' ']' cfa_identifier_parameter_ptr
3357	{ $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3358	\| cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3359	{ $$ = $2->addNewArray( $1 ); }
3360	\| '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3361	{ $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3362	\| cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3363	{ $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3364	\| multi_array_dimension cfa_identifier_parameter_ptr
3365	{ $$ = $2->addNewArray( $1 ); }
3366	;
3367
3368	cfa_array_parameter_1st_dimension:
3369	'[' push type_qualifier_list '*' pop ']' // remaining C99
3370	{ $$ = DeclarationNode::newVarArray( $3 ); }
3371	\| '[' push type_qualifier_list assignment_expression pop ']'
3372	{ $$ = DeclarationNode::newArray( $4, $3, false ); }
3373	\| '[' push declaration_qualifier_list assignment_expression pop ']'
3374	// declaration_qualifier_list must be used because of shift/reduce conflict with
3375	// assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3376	// appear in this context.
3377	{ $$ = DeclarationNode::newArray( $4, $3, true ); }
3378	\| '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3379	{ $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3380	;
3381
3382	// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3383	// identifier to which the type applies, e.g.:
3384	//
3385	// [int] f( int ); // abstract variable parameter; no parameter name specified
3386	// [int] f( [int] (int) ); // abstract function-prototype parameter; no parameter name specified
3387	//
3388	// These rules need LR(3):
3389	//
3390	// cfa_abstract_tuple identifier_or_type_name
3391	// '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
3392	//
3393	// since a function return type can be syntactically identical to a tuple type:
3394	//
3395	// [int, int] t;
3396	// [int, int] f( int );
3397	//
3398	// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3399	// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3400	// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3401	// duplicated when appearing with cfa_function_specifier.
3402
3403	cfa_abstract_declarator_tuple: // CFA
3404	cfa_abstract_tuple
3405	\| type_qualifier_list cfa_abstract_tuple
3406	{ $$ = $2->addQualifiers( $1 ); }
3407	\| cfa_abstract_declarator_no_tuple
3408	;
3409
3410	cfa_abstract_declarator_no_tuple: // CFA
3411	cfa_abstract_ptr
3412	\| cfa_abstract_array
3413	;
3414
3415	cfa_abstract_ptr: // CFA
3416	ptrref_operator type_specifier
3417	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3418	\| type_qualifier_list ptrref_operator type_specifier
3419	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3420	\| ptrref_operator cfa_abstract_function
3421	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3422	\| type_qualifier_list ptrref_operator cfa_abstract_function
3423	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3424	\| ptrref_operator cfa_abstract_declarator_tuple
3425	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3426	\| type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3427	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3428	;
3429
3430	cfa_abstract_array: // CFA
3431	// Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3432	// empty (void) function return type.
3433	'[' ']' type_specifier
3434	{ $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3435	\| '[' ']' multi_array_dimension type_specifier
3436	{ $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3437	\| multi_array_dimension type_specifier
3438	{ $$ = $2->addNewArray( $1 ); }
3439	\| '[' ']' cfa_abstract_ptr
3440	{ $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3441	\| '[' ']' multi_array_dimension cfa_abstract_ptr
3442	{ $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3443	\| multi_array_dimension cfa_abstract_ptr
3444	{ $$ = $2->addNewArray( $1 ); }
3445	;
3446
3447	cfa_abstract_tuple: // CFA
3448	'[' push cfa_abstract_parameter_list pop ']'
3449	{ $$ = DeclarationNode::newTuple( $3 ); }
3450	\| '[' push type_specifier_nobody ELLIPSIS pop ']'
3451	{ SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3452	\| '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
3453	{ SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3454	;
3455
3456	cfa_abstract_function: // CFA
3457	// '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
3458	// { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3459	cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
3460	{ $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3461	\| cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
3462	{ $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3463	;
3464
3465	// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3466	// each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3467	//
3468	// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3469	// the declaration specifiers in a declaration is an obsolescent feature."
3470	//
3471	// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3472	// prototype-format parameter type declarators) is an obsolescent feature."
3473	//
3474	// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3475	// declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3476
3477	//*********************** MISCELLANEOUS ******************************
3478
3479	comma_opt: // redundant comma
3480	// empty
3481	\| ','
3482	;
3483
3484	default_initialize_opt:
3485	// empty
3486	{ $$ = nullptr; }
3487	\| '=' assignment_expression
3488	{ $$ = $2; }
3489	;
3490
3491	%%
3492
3493	// ----end of grammar----
3494
3495	// Local Variables: //
3496	// mode: c++ //
3497	// tab-width: 4 //
3498	// compile-command: "make install" //
3499	// End: //

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format