source: libcfa/src/stdlib.hfa @ 69addb4

ADTarm-ehast-experimentalenumforall-pointer-decayjacob/cs343-translationnew-ast-unique-exprpthread-emulationqualifiedEnum
Last change on this file since 69addb4 was f76ff0b, checked in by m3zulfiq <m3zulfiq@…>, 4 years ago

alloc2.txt: added expected output file for test alloc2.cfa. heap.cfa: removed alignment bugs from realloc and resize with alignment. stdlib.hfa: removed debug prints from alloc interface. alloc2.cfa, malloc.cfa: uncommented tests that were previously commented because of a bug in realloc and resize.
  • Property mode set to 100644
File size: 14.9 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2016 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// stdlib --
8//
9// Author           : Peter A. Buhr
10// Created On       : Thu Jan 28 17:12:35 2016
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Tue Sep  1 20:32:34 2020
13// Update Count     : 505
14//
15
16#pragma once
17
18#include "bits/defs.hfa"
19#include "bits/align.hfa"
20
21#include <stdlib.h>                                                                             // *alloc, strto*, ato*
22#include <heap.hfa>
23
24// Reduce includes by explicitly defining these routines.
25extern "C" {
26        void * memalign( size_t alignment, size_t size );       // malloc.h
27        void * pvalloc( size_t size );                                          // malloc.h
28        void * memset( void * dest, int fill, size_t size ); // string.h
29        void * memcpy( void * dest, const void * src, size_t size ); // string.h
30} // extern "C"
31
32//---------------------------------------
33
34#ifndef EXIT_FAILURE
35#define EXIT_FAILURE    1                                                               // failing exit status
36#define EXIT_SUCCESS    0                                                               // successful exit status
37#endif // ! EXIT_FAILURE
38
39//---------------------------------------
40
41#include "common.hfa"
42
43//---------------------------------------
44
45// Macro because of returns
46#define $ARRAY_ALLOC( allocation, alignment, dim ) \
47        if ( _Alignof(T) <= libAlign() ) return (T *)(void *)allocation( dim, (size_t)sizeof(T) ); /* C allocation */ \
48        else return (T *)alignment( _Alignof(T), dim, sizeof(T) )
49
50static inline forall( dtype T | sized(T) ) {
51        // Cforall safe equivalents, i.e., implicit size specification
52
53        T * malloc( void ) {
54                if ( _Alignof(T) <= libAlign() ) return (T *)(void *)malloc( (size_t)sizeof(T) ); // C allocation
55                else return (T *)memalign( _Alignof(T), sizeof(T) );
56        } // malloc
57
58        T * aalloc( size_t dim ) {
59                $ARRAY_ALLOC( aalloc, amemalign, dim );
60        } // aalloc
61
62        T * calloc( size_t dim ) {
63                $ARRAY_ALLOC( calloc, cmemalign, dim );
64        } // calloc
65
66        T * resize( T * ptr, size_t size ) {                            // CFA resize, eliminate return-type cast
67                if ( _Alignof(T) <= libAlign() ) return (T *)(void *)resize( (void *)ptr, size ); // CFA resize
68                else return (T *)(void *)resize( (void *)ptr, _Alignof(T), size ); // CFA resize
69        } // resize
70
71        T * realloc( T * ptr, size_t size ) {                           // CFA realloc, eliminate return-type cast
72                if ( _Alignof(T) <= libAlign() ) return (T *)(void *)realloc( (void *)ptr, size ); // C realloc
73                else return (T *)(void *)realloc( (void *)ptr, _Alignof(T), size ); // CFA realloc
74        } // realloc
75
76        T * memalign( size_t align ) {
77                return (T *)memalign( align, sizeof(T) );               // C memalign
78        } // memalign
79
80        T * amemalign( size_t align, size_t dim ) {
81                return (T *)amemalign( align, dim, sizeof(T) ); // CFA amemalign
82        } // amemalign
83
84        T * cmemalign( size_t align, size_t dim  ) {
85                return (T *)cmemalign( align, dim, sizeof(T) ); // CFA cmemalign
86        } // cmemalign
87
88        T * aligned_alloc( size_t align ) {
89                return (T *)aligned_alloc( align, sizeof(T) );  // C aligned_alloc
90        } // aligned_alloc
91
92        int posix_memalign( T ** ptr, size_t align ) {
93                return posix_memalign( (void **)ptr, align, sizeof(T) ); // C posix_memalign
94        } // posix_memalign
95
96        T * valloc( void ) {
97                return (T *)valloc( sizeof(T) );                                // C valloc
98        } // valloc
99
100        T * pvalloc( void ) {
101                return (T *)pvalloc( sizeof(T) );                               // C pvalloc
102        } // pvalloc
103} // distribution
104
105/*
106        FIX ME : fix alloc interface after Ticker Number 214 is resolved, define and add union to S_fill. Then, modify postfix-fill functions to support T * with nmemb, char, and T object of any size. Finally, change alloc_internal.
107        Or, just follow the instructions below for that.
108
109        1. Replace the current forall-block that contains defintions of S_fill and S_realloc with following:
110                forall( dtype T | sized(T) ) {
111                        union  U_fill           { char c; T * a; T t; };
112                        struct S_fill           { char tag; char c; size_t size; T * at; char t[50]; };
113                        struct S_realloc        { inline T *; };
114                }
115
116        2. Replace all current postfix-fill functions with following for updated S_fill:
117                S_fill(T) ?`fill( char a )                                      { S_fill(T) ret = {'c'}; ret.fill.c = a; return ret; }
118                S_fill(T) ?`fill( T    a )                                      { S_fill(T) ret = {'t'}; memcpy(&ret.fill.t, &a, sizeof(T)); return ret; }
119                S_fill(T) ?`fill( T    a[], size_t nmemb )      { S_fill(T) ret = {'a', nmemb}; ret.fill.a = a; return ret; }
120
121        3. Replace the $alloc_internal function which is outside ttype forall-block with following function:
122                T * $alloc_internal( void * Resize, T * Realloc, size_t Align, size_t Dim, S_fill(T) Fill) {
123                        T * ptr = NULL;
124                        size_t size = sizeof(T);
125                        size_t copy_end = 0;
126
127                        if(Resize) {
128                                ptr = (T*) (void *) resize( (int *)Resize, Align, Dim * size );
129                        } else if (Realloc) {
130                                if (Fill.tag != '0') copy_end = min(malloc_size( Realloc ), Dim * size);
131                                ptr = (T*) (void *) realloc( (int *)Realloc, Align, Dim * size );
132                        } else {
133                                ptr = (T*) (void *) memalign( Align, Dim * size );
134                        }
135
136                        if(Fill.tag == 'c') {
137                                memset( (char *)ptr + copy_end, (int)Fill.fill.c, Dim * size - copy_end );
138                        } else if(Fill.tag == 't') {
139                                for ( int i = copy_end; i <= Dim * size - size ; i += size ) {
140                                        memcpy( (char *)ptr + i, &Fill.fill.t, size );
141                                }
142                        } else if(Fill.tag == 'a') {
143                                memcpy( (char *)ptr + copy_end, Fill.fill.a, min(Dim * size - copy_end, size * Fill.nmemb) );
144                        }
145
146                        return ptr;
147                } // $alloc_internal
148*/
149
150typedef struct S_align                  { inline size_t;  } T_align;
151typedef struct S_resize                 { inline void *;  }     T_resize;
152
153forall( dtype T ) {
154        struct S_fill           { char tag; char c; size_t size; T * at; char t[50]; };
155        struct S_realloc        { inline T *; };
156}
157
158static inline T_align   ?`align   ( size_t a )  { return (T_align){a}; }
159static inline T_resize  ?`resize  ( void * a )  { return (T_resize){a}; }
160static inline forall( dtype T | sized(T) ) {
161
162        S_fill(T) ?`fill ( T t ) {
163                S_fill(T) ret = { 't' };
164                size_t size = sizeof(T);
165                if(size > sizeof(ret.t)) { printf("ERROR: const object of size greater than 50 bytes given for dynamic memory fill\n"); exit(1); }
166                memcpy( &ret.t, &t, size );
167                return ret;
168        }
169        S_fill(T)               ?`fill ( char c )                               { return (S_fill(T)){ 'c', c }; }
170        S_fill(T)               ?`fill ( T * a )                                { return (S_fill(T)){ 'T', '0', 0, a }; }
171        S_fill(T)               ?`fill ( T a[], size_t nmemb )  { return (S_fill(T)){ 'a', '0', nmemb * sizeof(T), a }; }
172
173        S_realloc(T)    ?`realloc ( T * a )                             { return (S_realloc(T)){a}; }
174
175        T * $alloc_internal( void * Resize, T * Realloc, size_t Align, size_t Dim, S_fill(T) Fill) {
176                T * ptr = NULL;
177                size_t size = sizeof(T);
178                size_t copy_end = 0;
179
180                if ( Resize ) {
181                        ptr = (T*) (void *) resize( (void *)Resize, Align, Dim * size );
182                } else if ( Realloc ) {
183                        if (Fill.tag != '0') copy_end = min(malloc_size( Realloc ), Dim * size);
184                        ptr = (T*) (void *) realloc( (void *)Realloc, Align, Dim * size );
185                } else {
186                        ptr = (T*) (void *) memalign( Align, Dim * size );
187                }
188
189                if(Fill.tag == 'c') {
190                        memset( (char *)ptr + copy_end, (int)Fill.c, Dim * size - copy_end );
191                } else if(Fill.tag == 't') {
192                        for ( int i = copy_end; i < Dim * size; i += size ) {
193                                memcpy( (char *)ptr + i, &Fill.t, size );
194                        }
195                } else if(Fill.tag == 'a') {
196                        memcpy( (char *)ptr + copy_end, Fill.at, min(Dim * size - copy_end, Fill.size) );
197                } else if(Fill.tag == 'T') {
198                        for ( int i = copy_end; i < Dim * size; i += size ) {
199                                memcpy( (char *)ptr + i, Fill.at, size );
200                        }
201                }
202
203                return ptr;
204        } // $alloc_internal
205
206        forall( ttype TT | { T * $alloc_internal( void *, T *, size_t, size_t, S_fill(T), TT ); } ) {
207
208                T * $alloc_internal( void *       , T * Realloc, size_t Align, size_t Dim, S_fill(T) Fill, T_resize Resize, TT rest) {
209                return $alloc_internal( Resize, (T*)0p, Align, Dim, Fill, rest);
210                }
211
212                T * $alloc_internal( void * Resize, T *        , size_t Align, size_t Dim, S_fill(T) Fill, S_realloc(T) Realloc, TT rest) {
213                return $alloc_internal( (void*)0p, Realloc, Align, Dim, Fill, rest);
214                }
215
216                T * $alloc_internal( void * Resize, T * Realloc, size_t      , size_t Dim, S_fill(T) Fill, T_align Align, TT rest) {
217                return $alloc_internal( Resize, Realloc, Align, Dim, Fill, rest);
218                }
219
220                T * $alloc_internal( void * Resize, T * Realloc, size_t Align, size_t Dim, S_fill(T)     , S_fill(T) Fill, TT rest) {
221                return $alloc_internal( Resize, Realloc, Align, Dim, Fill, rest);
222                }
223
224            T * alloc( TT all ) {
225                return $alloc_internal( (void*)0p, (T*)0p, (_Alignof(T) > libAlign() ? _Alignof(T) : libAlign()), (size_t)1, (S_fill(T)){'0'}, all);
226            }
227
228            T * alloc( size_t dim, TT all ) {
229                return $alloc_internal( (void*)0p, (T*)0p, (_Alignof(T) > libAlign() ? _Alignof(T) : libAlign()), dim, (S_fill(T)){'0'}, all);
230            }
231
232        } // distribution TT
233
234} // distribution T
235
236static inline forall( dtype T | sized(T) ) {
237        // Cforall safe initialization/copy, i.e., implicit size specification, non-array types
238        T * memset( T * dest, char fill ) {
239                return (T *)memset( dest, fill, sizeof(T) );
240        } // memset
241
242        T * memcpy( T * dest, const T * src ) {
243                return (T *)memcpy( dest, src, sizeof(T) );
244        } // memcpy
245} // distribution
246
247static inline forall( dtype T | sized(T) ) {
248        // Cforall safe initialization/copy, i.e., implicit size specification, array types
249        T * amemset( T dest[], char fill, size_t dim ) {
250                return (T *)(void *)memset( dest, fill, dim * sizeof(T) ); // C memset
251        } // amemset
252
253        T * amemcpy( T dest[], const T src[], size_t dim ) {
254                return (T *)(void *)memcpy( dest, src, dim * sizeof(T) ); // C memcpy
255        } // amemcpy
256} // distribution
257
258// Cforall allocation/deallocation and constructor/destructor, non-array types
259forall( dtype T | sized(T), ttype Params | { void ?{}( T &, Params ); } ) T * new( Params p );
260forall( dtype T | { void ^?{}( T & ); } ) void delete( T * ptr );
261forall( dtype T, ttype Params | { void ^?{}( T & ); void delete( Params ); } ) void delete( T * ptr, Params rest );
262
263// Cforall allocation/deallocation and constructor/destructor, array types
264forall( dtype T | sized(T), ttype Params | { void ?{}( T &, Params ); } ) T * anew( size_t dim, Params p );
265forall( dtype T | sized(T) | { void ^?{}( T & ); } ) void adelete( size_t dim, T arr[] );
266forall( dtype T | sized(T) | { void ^?{}( T & ); }, ttype Params | { void adelete( Params ); } ) void adelete( size_t dim, T arr[], Params rest );
267
268//---------------------------------------
269
270static inline {
271        int strto( const char sptr[], char ** eptr, int base ) { return (int)strtol( sptr, eptr, base ); }
272        unsigned int strto( const char sptr[], char ** eptr, int base ) { return (unsigned int)strtoul( sptr, eptr, base ); }
273        long int strto( const char sptr[], char ** eptr, int base ) { return strtol( sptr, eptr, base ); }
274        unsigned long int strto( const char sptr[], char ** eptr, int base ) { return strtoul( sptr, eptr, base ); }
275        long long int strto( const char sptr[], char ** eptr, int base ) { return strtoll( sptr, eptr, base ); }
276        unsigned long long int strto( const char sptr[], char ** eptr, int base ) { return strtoull( sptr, eptr, base ); }
277
278        float strto( const char sptr[], char ** eptr ) { return strtof( sptr, eptr ); }
279        double strto( const char sptr[], char ** eptr ) { return strtod( sptr, eptr ); }
280        long double strto( const char sptr[], char ** eptr ) { return strtold( sptr, eptr ); }
281} // distribution
282
283float _Complex strto( const char sptr[], char ** eptr );
284double _Complex strto( const char sptr[], char ** eptr );
285long double _Complex strto( const char sptr[], char ** eptr );
286
287static inline {
288        int ato( const char sptr[] ) { return (int)strtol( sptr, 0p, 10 ); }
289        unsigned int ato( const char sptr[] ) { return (unsigned int)strtoul( sptr, 0p, 10 ); }
290        long int ato( const char sptr[] ) { return strtol( sptr, 0p, 10 ); }
291        unsigned long int ato( const char sptr[] ) { return strtoul( sptr, 0p, 10 ); }
292        long long int ato( const char sptr[] ) { return strtoll( sptr, 0p, 10 ); }
293        unsigned long long int ato( const char sptr[] ) { return strtoull( sptr, 0p, 10 ); }
294
295        float ato( const char sptr[] ) { return strtof( sptr, 0p ); }
296        double ato( const char sptr[] ) { return strtod( sptr, 0p ); }
297        long double ato( const char sptr[] ) { return strtold( sptr, 0p ); }
298
299        float _Complex ato( const char sptr[] ) { return strto( sptr, 0p ); }
300        double _Complex ato( const char sptr[] ) { return strto( sptr, 0p ); }
301        long double _Complex ato( const char sptr[] ) { return strto( sptr, 0p ); }
302} // distribution
303
304//---------------------------------------
305
306forall( otype E | { int ?<?( E, E ); } ) {
307        E * bsearch( E key, const E * vals, size_t dim );
308        size_t bsearch( E key, const E * vals, size_t dim );
309        E * bsearchl( E key, const E * vals, size_t dim );
310        size_t bsearchl( E key, const E * vals, size_t dim );
311        E * bsearchu( E key, const E * vals, size_t dim );
312        size_t bsearchu( E key, const E * vals, size_t dim );
313} // distribution
314
315forall( otype K, otype E | { int ?<?( K, K ); K getKey( const E & ); } ) {
316        E * bsearch( K key, const E * vals, size_t dim );
317        size_t bsearch( K key, const E * vals, size_t dim );
318        E * bsearchl( K key, const E * vals, size_t dim );
319        size_t bsearchl( K key, const E * vals, size_t dim );
320        E * bsearchu( K key, const E * vals, size_t dim );
321        size_t bsearchu( K key, const E * vals, size_t dim );
322} // distribution
323
324forall( otype E | { int ?<?( E, E ); } ) {
325        void qsort( E * vals, size_t dim );
326} // distribution
327
328//---------------------------------------
329
330extern "C" {                                                                                    // override C version
331        void srandom( unsigned int seed );
332        long int random( void );                                                        // GENERATES POSITIVE AND NEGATIVE VALUES
333        // For positive values, use unsigned int, e.g., unsigned int r = random() % 100U;
334} // extern "C"
335
336static inline {
337        long int random( long int l, long int u ) { if ( u < l ) [u, l] = [l, u]; return lrand48() % (u - l) + l; } // [l,u)
338        long int random( long int u ) { if ( u < 0 ) return random( u, 0 ); else return random( 0, u ); } // [0,u)
339        unsigned long int random( void ) { return lrand48(); }
340        unsigned long int random( unsigned long int u ) { return lrand48() % u; } // [0,u)
341        unsigned long int random( unsigned long int l, unsigned long int u ) { if ( u < l ) [u, l] = [l, u]; return lrand48() % (u - l) + l; } // [l,u)
342
343        char random( void ) { return (unsigned long int)random(); }
344        char random( char u ) { return random( (unsigned long int)u ); } // [0,u)
345        char random( char l, char u ) { return random( (unsigned long int)l, (unsigned long int)u ); } // [l,u)
346        int random( void ) { return (long int)random(); }
347        int random( int u ) { return random( (long int)u ); } // [0,u]
348        int random( int l, int u ) { return random( (long int)l, (long int)u ); } // [l,u)
349        unsigned int random( void ) { return (unsigned long int)random(); }
350        unsigned int random( unsigned int u ) { return random( (unsigned long int)u ); } // [0,u]
351        unsigned int random( unsigned int l, unsigned int u ) { return random( (unsigned long int)l, (unsigned long int)u ); } // [l,u)
352} // distribution
353
354float random( void );                                                                   // [0.0, 1.0)
355double random( void );                                                                  // [0.0, 1.0)
356float _Complex random( void );                                                  // [0.0, 1.0)+[0.0, 1.0)i
357double _Complex random( void );                                                 // [0.0, 1.0)+[0.0, 1.0)i
358long double _Complex random( void );                                    // [0.0, 1.0)+[0.0, 1.0)i
359
360//---------------------------------------
361
362extern bool threading_enabled(void) OPTIONAL_THREAD;
363
364// Local Variables: //
365// mode: c //
366// tab-width: 4 //
367// End: //
Note: See TracBrowser for help on using the repository browser.