source: libcfa/src/stdlib.hfa

Last change on this file was 3770b87, checked in by Peter A. Buhr <pabuhr@…>, 5 months ago

formatting, add PRNG copy to checkpoint PRNG state, remove autogen PRNG copy constructor and assignment to prevent accidental PRNG copy

  • Property mode set to 100644
File size: 21.2 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2016 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// stdlib --
8//
9// Author           : Peter A. Buhr
10// Created On       : Thu Jan 28 17:12:35 2016
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Sun Oct  8 09:18:28 2023
13// Update Count     : 789
14//
15
16#pragma once
17
18#include "bits/defs.hfa"                                                                // OPTIONAL_THREAD
19#include "bits/align.hfa"                                                               // libAlign
20#include "bits/random.hfa"                                                              // prng
21#include <Exception.hfa>
22#include <heap.hfa>
23
24#include <stdlib.h>                                                                             // *alloc, strto*, ato*
25#include <errno.h>
26
27// Reduce includes by explicitly defining these routines.
28extern "C" {
29        void * memalign( size_t alignment, size_t size );       // malloc.h
30        void * pvalloc( size_t size );                                          // malloc.h
31        void * memset( void * dest, int fill, size_t size ); // string.h
32        void * memcpy( void * dest, const void * src, size_t size ); // string.h
33} // extern "C"
34
35//---------------------------------------
36
37#ifndef EXIT_FAILURE
38#define EXIT_FAILURE    1                                                               // failing exit status
39#define EXIT_SUCCESS    0                                                               // successful exit status
40#endif // ! EXIT_FAILURE
41
42//---------------------------------------
43
44#include "common.hfa"
45
46//---------------------------------------
47
48static inline forall( T & | sized(T) ) {
49        // CFA safe equivalents, i.e., implicit size specification
50
51        T * malloc( void ) {
52                if ( _Alignof(T) <= libAlign() ) return (T *)malloc( sizeof(T) ); // C allocation
53                else return (T *)memalign( _Alignof(T), sizeof(T) );
54        } // malloc
55
56        T * aalloc( size_t dim ) {
57                if ( _Alignof(T) <= libAlign() ) return (T *)aalloc( dim, sizeof(T) ); // C allocation
58                else return (T *)amemalign( _Alignof(T), dim, sizeof(T) );
59        } // aalloc
60
61        T * calloc( size_t dim ) {
62                if ( _Alignof(T) <= libAlign() ) return (T *)calloc( dim, sizeof(T) ); // C allocation
63                else return (T *)cmemalign( _Alignof(T), dim, sizeof(T) );
64        } // calloc
65
66        T * resize( T * ptr, size_t size ) {                            // CFA resize, eliminate return-type cast
67                if ( _Alignof(T) <= libAlign() ) return (T *)resize( (void *)ptr, size ); // CFA resize
68                else return (T *)resize( (void *)ptr, _Alignof(T), size ); // CFA resize
69        } // resize
70
71        T * realloc( T * ptr, size_t size ) {                           // CFA realloc, eliminate return-type cast
72                if ( _Alignof(T) <= libAlign() ) return (T *)realloc( (void *)ptr, size ); // C realloc
73                else return (T *)realloc( (void *)ptr, _Alignof(T), size ); // CFA realloc
74        } // realloc
75
76        T * memalign( size_t align ) {
77                return (T *)memalign( align, sizeof(T) );               // C memalign
78        } // memalign
79
80        T * amemalign( size_t align, size_t dim ) {
81                return (T *)amemalign( align, dim, sizeof(T) ); // CFA amemalign
82        } // amemalign
83
84        T * cmemalign( size_t align, size_t dim  ) {
85                return (T *)cmemalign( align, dim, sizeof(T) ); // CFA cmemalign
86        } // cmemalign
87
88        T * aligned_alloc( size_t align ) {
89                return (T *)aligned_alloc( align, sizeof(T) );  // C aligned_alloc
90        } // aligned_alloc
91
92        int posix_memalign( T ** ptr, size_t align ) {
93                return posix_memalign( (void **)ptr, align, sizeof(T) ); // C posix_memalign
94        } // posix_memalign
95
96        T * valloc( void ) {
97                return (T *)valloc( sizeof(T) );                                // C valloc
98        } // valloc
99
100        T * pvalloc( void ) {
101                return (T *)pvalloc( sizeof(T) );                               // C pvalloc
102        } // pvalloc
103} // distribution
104
105/*
106        FIX ME : fix alloc interface after Ticker Number 214 is resolved, define and add union to S_fill. Then, modify postfix-fill functions to support T * with nmemb, char, and T object of any size. Finally, change alloc_internal.
107        Or, just follow the instructions below for that.
108
109        1. Replace the current forall-block that contains defintions of S_fill and S_realloc with following:
110                forall( T & | sized(T) ) {
111                        union  U_fill           { char c; T * a; T t; };
112                        struct S_fill           { char tag; U_fill(T) fill; };
113                        struct S_realloc        { inline T *; };
114                }
115
116        2. Replace all current postfix-fill functions with following for updated S_fill:
117                S_fill(T) ?`fill( char a )                                      { S_fill(T) ret = {'c'}; ret.fill.c = a; return ret; }
118                S_fill(T) ?`fill( T    a )                                      { S_fill(T) ret = {'t'}; memcpy(&ret.fill.t, &a, sizeof(T)); return ret; }
119                S_fill(T) ?`fill( T    a[], size_t nmemb )      { S_fill(T) ret = {'a', nmemb}; ret.fill.a = a; return ret; }
120
121        3. Replace the alloc_internal$ function which is outside ttype forall-block with following function:
122                T * alloc_internal$( void * Resize, T * Realloc, size_t Align, size_t Dim, S_fill(T) Fill) {
123                        T * ptr = NULL;
124                        size_t size = sizeof(T);
125                        size_t copy_end = 0;
126
127                        if(Resize) {
128                                ptr = (T*) (void *) resize( (int *)Resize, Align, Dim * size );
129                        } else if (Realloc) {
130                                if (Fill.tag != '0') copy_end = min(malloc_size( Realloc ), Dim * size);
131                                ptr = (T*) (void *) realloc( (int *)Realloc, Align, Dim * size );
132                        } else {
133                                ptr = (T*) (void *) memalign( Align, Dim * size );
134                        }
135
136                        if(Fill.tag == 'c') {
137                                memset( (char *)ptr + copy_end, (int)Fill.fill.c, Dim * size - copy_end );
138                        } else if(Fill.tag == 't') {
139                                for ( int i = copy_end; i <= Dim * size - size ; i += size ) {
140                                        memcpy( (char *)ptr + i, &Fill.fill.t, size );
141                                }
142                        } else if(Fill.tag == 'a') {
143                                memcpy( (char *)ptr + copy_end, Fill.fill.a, min(Dim * size - copy_end, size * Fill.nmemb) );
144                        }
145
146                        return ptr;
147                } // alloc_internal$
148*/
149
150typedef struct S_align                  { inline size_t;  } T_align;
151typedef struct S_resize                 { inline void *;  }     T_resize;
152
153forall( T & ) {
154        struct S_fill           { char tag; char c; size_t size; T * at; char t[50]; };
155        struct S_realloc        { inline T *; };
156}
157
158static inline T_align   ?`align   ( size_t a )  { return (T_align){a}; }
159static inline T_resize  ?`resize  ( void * a )  { return (T_resize){a}; }
160
161static inline forall( T & | sized(T) ) {
162        S_fill(T) ?`fill ( T t ) {
163                S_fill(T) ret = { 't' };
164                size_t size = sizeof(T);
165                if ( size > sizeof(ret.t) ) {
166                        abort( "ERROR: const object of size greater than 50 bytes given for dynamic memory fill\n" );
167                } // if
168                memcpy( &ret.t, &t, size );
169                return ret;
170        }
171        S_fill(T)               ?`fill ( zero_t ) = void; // FIX ME: remove this once ticket 214 is resolved
172        S_fill(T)               ?`fill ( T * a )                                { return (S_fill(T)){ 'T', '0', 0, a }; } // FIX ME: remove this once ticket 214 is resolved
173        S_fill(T)               ?`fill ( char c )                               { return (S_fill(T)){ 'c', c }; }
174        S_fill(T)               ?`fill ( T a[], size_t nmemb )  { return (S_fill(T)){ 'a', '0', nmemb * sizeof(T), a }; }
175
176        S_realloc(T)    ?`realloc ( T * a )                             { return (S_realloc(T)){a}; }
177
178        T * alloc_internal$( void * Resize, T * Realloc, size_t Align, size_t Dim, S_fill(T) Fill ) {
179                T * ptr = NULL;
180                size_t size = sizeof(T);
181                size_t copy_end = 0;
182
183                if ( Resize ) {
184                        ptr = (T*) (void *) resize( (void *)Resize, Align, Dim * size );
185                } else if ( Realloc ) {
186                        if ( Fill.tag != '0' ) copy_end = min(malloc_size( Realloc ), Dim * size );
187                        ptr = (T *) (void *) realloc( (void *)Realloc, Align, Dim * size );
188                } else {
189                        ptr = (T *) (void *) memalign( Align, Dim * size );
190                }
191
192                if ( Fill.tag == 'c' ) {
193                        memset( (char *)ptr + copy_end, (int)Fill.c, Dim * size - copy_end );
194                } else if ( Fill.tag == 't' ) {
195                        for ( i; copy_end ~ Dim * size ~ size ) {
196                                #pragma GCC diagnostic push
197                                #pragma GCC diagnostic ignored "-Wmaybe-uninitialized"
198                                assert( size <= sizeof(Fill.t) );
199                                memcpy( (char *)ptr + i, &Fill.t, size );
200                                #pragma GCC diagnostic pop
201                        }
202                } else if ( Fill.tag == 'a' ) {
203                        memcpy( (char *)ptr + copy_end, Fill.at, min(Dim * size - copy_end, Fill.size) );
204                } else if ( Fill.tag == 'T' ) {
205                        memcpy( (char *)ptr + copy_end, Fill.at, Dim * size );
206                }
207
208                return ptr;
209        } // alloc_internal$
210
211        forall( TT... | { T * alloc_internal$( void *, T *, size_t, size_t, S_fill(T), TT ); } ) {
212                T * alloc_internal$( void *, T *, size_t Align, size_t Dim, S_fill(T) Fill, T_resize Resize, TT rest ) {
213                return alloc_internal$( Resize, (T*)0p, Align, Dim, Fill, rest);
214                }
215
216                T * alloc_internal$( void *, T *, size_t Align, size_t Dim, S_fill(T) Fill, S_realloc(T) Realloc, TT rest ) {
217                return alloc_internal$( (void*)0p, Realloc, Align, Dim, Fill, rest);
218                }
219
220                T * alloc_internal$( void * Resize, T * Realloc, size_t, size_t Dim, S_fill(T) Fill, T_align Align, TT rest ) {
221                return alloc_internal$( Resize, Realloc, Align, Dim, Fill, rest);
222                }
223
224                T * alloc_internal$( void * Resize, T * Realloc, size_t Align, size_t Dim, S_fill(T), S_fill(T) Fill, TT rest ) {
225                return alloc_internal$( Resize, Realloc, Align, Dim, Fill, rest );
226                }
227
228            T * alloc( TT all ) {
229                return alloc_internal$( (void*)0p, (T*)0p, (_Alignof(T) > libAlign() ? _Alignof(T) : libAlign()), (size_t)1, (S_fill(T)){'0'}, all );
230            }
231
232            T * alloc( size_t dim, TT all ) {
233                return alloc_internal$( (void*)0p, (T*)0p, (_Alignof(T) > libAlign() ? _Alignof(T) : libAlign()), dim, (S_fill(T)){'0'}, all );
234            }
235        } // distribution TT
236} // distribution T
237
238static inline forall( T & | sized(T) ) {
239        // CFA safe initialization/copy, i.e., implicit size specification, non-array types
240        T * memset( T * dest, char fill ) {
241                return (T *)memset( dest, fill, sizeof(T) );
242        } // memset
243
244        T * memcpy( T * dest, const T * src ) {
245                return (T *)memcpy( dest, src, sizeof(T) );
246        } // memcpy
247
248        // CFA safe initialization/copy, i.e., implicit size specification, array types
249        T * amemset( T dest[], char fill, size_t dim ) {
250                return (T *)(void *)memset( dest, fill, dim * sizeof(T) ); // C memset
251        } // amemset
252
253        T * amemcpy( T dest[], const T src[], size_t dim ) {
254                return (T *)(void *)memcpy( dest, src, dim * sizeof(T) ); // C memcpy
255        } // amemcpy
256} // distribution
257
258// CFA deallocation for multiple objects
259static inline forall( T & )                                                     // FIX ME, problems with 0p in list
260void free( T * ptr ) {
261        free( (void *)ptr );                                                            // C free
262} // free
263static inline forall( T &, TT... | { void free( TT ); } )
264void free( T * ptr, TT rest ) {
265        free( ptr );
266        free( rest );
267} // free
268
269// CFA allocation/deallocation and constructor/destructor, non-array types
270static inline forall( T & | sized(T), TT... | { void ?{}( T &, TT ); } )
271T * new( TT p ) {
272        return &(*(T *)malloc()){ p };                                          // run constructor
273} // new
274
275static inline forall( T & | { void ^?{}( T & ); } )
276void delete( T * ptr ) {
277        // special case for 0-sized object => always call destructor
278        if ( ptr || sizeof(ptr) == 0 ) {                                        // ignore null but not 0-sized objects
279                ^(*ptr){};                                                                              // run destructor
280        } // if
281        free( ptr );                                                                            // always call free
282} // delete
283static inline forall( T &, TT... | { void ^?{}( T & ); void delete( TT ); } )
284void delete( T * ptr, TT rest ) {
285        delete( ptr );
286        delete( rest );
287} // delete
288
289// CFA allocation/deallocation and constructor/destructor, array types
290forall( T & | sized(T), TT... | { void ?{}( T &, TT ); } ) T * anew( size_t dim, TT p );
291forall( T & | sized(T) | { void ^?{}( T & ); } ) void adelete( T arr[] );
292forall( T & | sized(T) | { void ^?{}( T & ); }, TT... | { void adelete( TT ); } ) void adelete( T arr[], TT rest );
293
294//---------------------------------------
295
296static inline {
297        int strto( const char sptr[], char * eptr[], int base ) { return (int)strtol( sptr, eptr, base ); }
298        unsigned int strto( const char sptr[], char * eptr[], int base ) { return (unsigned int)strtoul( sptr, eptr, base ); }
299        long int strto( const char sptr[], char * eptr[], int base ) { return strtol( sptr, eptr, base ); }
300        unsigned long int strto( const char sptr[], char * eptr[], int base ) { return strtoul( sptr, eptr, base ); }
301        long long int strto( const char sptr[], char * eptr[], int base ) { return strtoll( sptr, eptr, base ); }
302        unsigned long long int strto( const char sptr[], char * eptr[], int base ) { return strtoull( sptr, eptr, base ); }
303
304        float strto( const char sptr[], char * eptr[] ) { return strtof( sptr, eptr ); }
305        double strto( const char sptr[], char * eptr[] ) { return strtod( sptr, eptr ); }
306        long double strto( const char sptr[], char * eptr[] ) { return strtold( sptr, eptr ); }
307} // distribution
308
309float _Complex strto( const char sptr[], char * eptr[] );
310double _Complex strto( const char sptr[], char * eptr[] );
311long double _Complex strto( const char sptr[], char * eptr[] );
312
313ExceptionDecl( out_of_range );
314ExceptionDecl( invalid_argument );
315
316forall( T | { T strto( const char sptr[], char * eptr[], int ); } )
317T convert( const char sptr[] );
318
319static inline {
320        int ato( const char sptr[] ) { return (int)strtol( sptr, 0p, 10 ); }
321        unsigned int ato( const char sptr[] ) { return (unsigned int)strtoul( sptr, 0p, 10 ); }
322        long int ato( const char sptr[] ) { return strtol( sptr, 0p, 10 ); }
323        unsigned long int ato( const char sptr[] ) { return strtoul( sptr, 0p, 10 ); }
324        long long int ato( const char sptr[] ) { return strtoll( sptr, 0p, 10 ); }
325        unsigned long long int ato( const char sptr[] ) { return strtoull( sptr, 0p, 10 ); }
326
327        float ato( const char sptr[] ) { return strtof( sptr, 0p ); }
328        double ato( const char sptr[] ) { return strtod( sptr, 0p ); }
329        long double ato( const char sptr[] ) { return strtold( sptr, 0p ); }
330
331        float _Complex ato( const char sptr[] ) { return strto( sptr, 0p ); }
332        double _Complex ato( const char sptr[] ) { return strto( sptr, 0p ); }
333        long double _Complex ato( const char sptr[] ) { return strto( sptr, 0p ); }
334} // distribution
335
336//---------------------------------------
337
338forall( E | { int ?<?( E, E ); } ) {
339        E * bsearch( E key, const E * vals, size_t dim );
340        size_t bsearch( E key, const E * vals, size_t dim );
341        E * bsearchl( E key, const E * vals, size_t dim );
342        size_t bsearchl( E key, const E * vals, size_t dim );
343        E * bsearchu( E key, const E * vals, size_t dim );
344        size_t bsearchu( E key, const E * vals, size_t dim );
345} // distribution
346
347forall( K, E | { int ?<?( K, K ); K getKey( const E & ); } ) {
348        E * bsearch( K key, const E * vals, size_t dim );
349        size_t bsearch( K key, const E * vals, size_t dim );
350        E * bsearchl( K key, const E * vals, size_t dim );
351        size_t bsearchl( K key, const E * vals, size_t dim );
352        E * bsearchu( K key, const E * vals, size_t dim );
353        size_t bsearchu( K key, const E * vals, size_t dim );
354} // distribution
355
356forall( E | { int ?<?( E, E ); } ) {
357        void qsort( E * vals, size_t dim );
358} // distribution
359
360//---------------------------------------
361
362extern "C" {                                                                                    // override C version
363        void srandom( unsigned int seed );
364        long int random( void );                                                        // GENERATES POSITIVE AND NEGATIVE VALUES
365        // For positive values, use unsigned int, e.g., unsigned int r = random() % 100U;
366} // extern "C"
367
368static inline {
369        long int random( long int l, long int u ) { if ( u < l ) [u, l] = [l, u]; return lrand48() % (u - l + 1) + l; } // [l,u]
370        long int random( long int u ) { return random( 0, u - 1 ); } // [0,u)
371        unsigned long int random( void ) { return lrand48(); }
372        unsigned long int random( unsigned long int u ) { return lrand48() % u; } // [0,u)
373        unsigned long int random( unsigned long int l, unsigned long int u ) { if ( u < l ) [u, l] = [l, u]; return lrand48() % (u - l + 1) + l; } // [l,u]
374
375        char random( void ) { return (unsigned long int)random(); }
376        char random( char u ) { return (unsigned long int)random( (unsigned long int)u ); } // [0,u)
377        char random( char l, char u ) { return random( (unsigned long int)l, (unsigned long int)u ); } // [l,u)
378        int random( void ) { return (long int)random(); }
379        int random( int u ) { return (long int)random( (long int)u ); } // [0,u]
380        int random( int l, int u ) { return random( (long int)l, (long int)u ); } // [l,u)
381        unsigned int random( void ) { return (unsigned long int)random(); }
382        unsigned int random( unsigned int u ) { return (unsigned long int)random( (unsigned long int)u ); } // [0,u]
383        unsigned int random( unsigned int l, unsigned int u ) { return random( (unsigned long int)l, (unsigned long int)u ); } // [l,u)
384} // distribution
385
386float random( void );                                                                   // [0.0, 1.0)
387double random( void );                                                                  // [0.0, 1.0)
388float _Complex random( void );                                                  // [0.0, 1.0)+[0.0, 1.0)i
389double _Complex random( void );                                                 // [0.0, 1.0)+[0.0, 1.0)i
390long double _Complex random( void );                                    // [0.0, 1.0)+[0.0, 1.0)i
391
392//---------------------------------------
393
394// Sequential Pseudo Random-Number Generator : generate repeatable sequence of values that appear random.
395//
396// Declaration :
397//   PRNG sprng = { 1009 } - set starting seed versus random seed
398//
399// Interface :
400//   set_seed( sprng, 1009 ) - set starting seed for ALL kernel threads versus random seed
401//   get_seed( sprng ) - read seed
402//   prng( sprng ) - generate random value in range [0,UINT_MAX]
403//   prng( sprng, u ) - generate random value in range [0,u)
404//   prng( sprng, l, u ) - generate random value in range [l,u]
405//   calls( sprng ) - number of generated random value so far
406//
407// Examples : generate random number between 5-21
408//   prng( sprng ) % 17 + 5;    values 0-16 + 5 = 5-21
409//   prng( sprng, 16 + 1 ) + 5;
410//   prng( sprng, 5, 21 );
411//   calls( sprng );
412
413forall( PRNG &, R )
414trait basic_prng {
415        void set_seed( PRNG & prng, R seed );                           // set seed
416        R get_seed( PRNG & prng );                                                      // get seed
417        R prng( PRNG & prng );
418        void ?{}( PRNG & prng );                                                        // random seed
419        void ?{}( PRNG & prng, R seed );                                        // fixed seed
420}; // basic_prng
421
422static inline forall( PRNG &, R | basic_prng( PRNG, R ) | { R ?%?( R, R ); } ) {
423        R prng( PRNG & prng, R u ) { return prng( prng ) % u; } // [0,u)
424}
425static inline forall( PRNG &, R | basic_prng( PRNG, R ) | { R ?+?( R, R ); R ?-?( R, R ); R ?%?( R, R ); void ?{}( R &, one_t ); } ) {
426        R prng( PRNG & prng, R l, R u ) { return prng( prng, u - l + (R){1} ) + l; } // [l,u]
427}
428
429struct PRNG32 {
430        uint32_t callcnt;                                                                       // call count
431        uint32_t seed;                                                                          // current seed
432        PRNG_STATE_32_T state;                                                          // random state
433}; // PRNG32
434
435static inline {
436        void set_seed( PRNG32 & prng, uint32_t seed_ ) with( prng ) { seed = seed_; PRNG_SET_SEED_32( state, seed ); }
437        uint32_t get_seed( PRNG32 & prng ) __attribute__(( warn_unused_result )) with( prng ) { return seed; }
438        void ?{}( PRNG32 & prng, uint32_t seed ) with( prng ) { callcnt = 0; set_seed( prng, seed ); } // fixed seed
439        void ?{}( PRNG32 & prng ) with( prng ) { ?{}( prng, rdtscl() ); } // random seed
440        uint32_t prng( PRNG32 & prng ) __attribute__(( warn_unused_result )) with( prng ) { callcnt += 1; return PRNG_NAME_32( state ); } // [0,UINT_MAX]
441        uint32_t prng( PRNG32 & prng, uint32_t u ) __attribute__(( warn_unused_result )) { return prng( prng ) % u; } // [0,u)
442        uint32_t prng( PRNG32 & prng, uint32_t l, uint32_t u ) __attribute__(( warn_unused_result )) { return prng( prng, u - l + 1 ) + l; } // [l,u]
443        uint32_t calls( PRNG32 & prng ) __attribute__(( warn_unused_result )) with( prng ) { return callcnt; }
444        void copy( PRNG32 & dst, PRNG32 & src ) { dst = src; } // checkpoint PRNG state, use autogen assignment
445} // distribution
446void ?{}( PRNG32 &, PRNG32 & ) = void;                                  // no copy, remove autogen copy constructor
447PRNG32 & ?=?( PRNG32 &, const PRNG32 ) = void;                  // no assignment, remove autogen assignment
448
449struct PRNG64 {
450        uint64_t callcnt;                                                                       // call count
451        uint64_t seed;                                                                          // current seed
452        PRNG_STATE_64_T state;                                                          // random state
453}; // PRNG64
454
455static inline {
456        void set_seed( PRNG64 & prng, uint64_t seed_ ) with( prng ) { seed = seed_; PRNG_SET_SEED_64( state, seed ); }
457        uint64_t get_seed( PRNG64 & prng ) __attribute__(( warn_unused_result )) with( prng ) { return seed; }
458        void ?{}( PRNG64 & prng, uint64_t seed ) with( prng ) { callcnt = 0; set_seed( prng, seed ); } // fixed seed
459        void ?{}( PRNG64 & prng ) with( prng ) { ?{}( prng, rdtscl() ); } // random seed
460        uint64_t prng( PRNG64 & prng ) __attribute__(( warn_unused_result )) with( prng ) { callcnt += 1; return PRNG_NAME_64( state ); } // [0,UINT_MAX]
461        uint64_t prng( PRNG64 & prng, uint64_t u ) __attribute__(( warn_unused_result )) { return prng( prng ) % u; } // [0,u)
462        uint64_t prng( PRNG64 & prng, uint64_t l, uint64_t u ) __attribute__(( warn_unused_result )) { return prng( prng, u - l + 1 ) + l; } // [l,u]
463        uint64_t calls( PRNG64 & prng ) __attribute__(( warn_unused_result )) with( prng ) { return callcnt; }
464        void copy( PRNG64 & dst, PRNG64 & src ) { dst = src; } // checkpoint PRNG state, use autogen assignment
465} // distribution
466void ?{}( PRNG64 &, PRNG64 & ) = void;                                  // no copy, remove autogen copy constructor
467PRNG64 & ?=?( PRNG64 &, const PRNG64 ) = void;                  // no assignment, remove autogen assignment
468
469// Set default random-generator size.
470#if defined( __x86_64__ ) || defined( __aarch64__ )             // 64-bit architecture
471#define PRNG PRNG64
472#else                                                                                                   // 32-bit architecture
473#define PRNG PRNG32
474#endif // __x86_64__
475
476// Concurrent Pseudo Random-Number Generator : generate repeatable sequence of values that appear random.
477//
478// Interface :
479//   set_seed( 1009 ) - fixed seed for all kernel threads versus random seed
480//   get_seed() - read seed
481//   prng() - generate random value in range [0,UINT_MAX]
482//   prng( u ) - generate random value in range [0,u)
483//   prng( l, u ) - generate random value in range [l,u]
484//
485// Examples : generate random number between 5-21
486//   prng() % 17 + 5;   values 0-16 + 5 = 5-21
487//   prng( 16 + 1 ) + 5;
488//   prng( 5, 21 );
489
490// Harmonize with concurrency/thread.hfa.
491void set_seed( size_t seed_ ) OPTIONAL_THREAD;                  // set global seed
492size_t get_seed() __attribute__(( warn_unused_result )); // get global seed
493size_t prng( void ) __attribute__(( warn_unused_result )) OPTIONAL_THREAD; // [0,UINT_MAX]
494static inline {
495        size_t prng( size_t u ) __attribute__(( warn_unused_result )) { return prng() % u; } // [0,u)
496        size_t prng( size_t l, size_t u ) __attribute__(( warn_unused_result )) { return prng( u - l + 1 ) + l; } // [l,u]
497} // distribution
498
499//---------------------------------------
500
501extern bool threading_enabled( void ) OPTIONAL_THREAD;
502
503// Local Variables: //
504// mode: c //
505// tab-width: 4 //
506// End: //
Note: See TracBrowser for help on using the repository browser.