source: libcfa/src/concurrency/locks.cfa @ 55422cf

ADTast-experimentalpthread-emulationqualifiedEnum
Last change on this file since 55422cf was ae06e0b, checked in by caparsons <caparson@…>, 22 months ago

added pthread_cond_var

  • Property mode set to 100644
File size: 16.9 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2021 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// locks.hfa -- LIBCFATHREAD
8// Runtime locks that used with the runtime thread system.
9//
10// Author           : Colby Alexander Parsons
11// Created On       : Thu Jan 21 19:46:50 2021
12// Last Modified By :
13// Last Modified On :
14// Update Count     :
15//
16
17#define __cforall_thread__
18#define _GNU_SOURCE
19
20#include "locks.hfa"
21#include "kernel/private.hfa"
22
23#include <kernel.hfa>
24#include <stdlib.hfa>
25
26#pragma GCC visibility push(default)
27
28//-----------------------------------------------------------------------------
29// info_thread
30forall(L & | is_blocking_lock(L)) {
31        struct info_thread {
32                // used to put info_thread on a dl queue
33                inline dlink(info_thread(L));
34
35                // waiting thread
36                struct thread$ * t;
37
38                // shadow field
39                uintptr_t info;
40
41                // lock that is passed to wait() (if one is passed)
42                L * lock;
43
44                // true when signalled and false when timeout wakes thread
45                bool signalled;
46        };
47        P9_EMBEDDED( info_thread(L), dlink(info_thread(L)) )
48
49        void ?{}( info_thread(L) & this, thread$ * t, uintptr_t info, L * l ) {
50                this.t = t;
51                this.info = info;
52                this.lock = l;
53        }
54
55        void ^?{}( info_thread(L) & this ) {}
56}
57
58//-----------------------------------------------------------------------------
59// Blocking Locks
60void ?{}( blocking_lock & this, bool multi_acquisition, bool strict_owner ) {
61        this.lock{};
62        this.blocked_threads{};
63        this.wait_count = 0;
64        this.multi_acquisition = multi_acquisition;
65        this.strict_owner = strict_owner;
66        this.owner = 0p;
67        this.recursion_count = 0;
68}
69
70void ^?{}( blocking_lock & this ) {}
71
72
73void lock( blocking_lock & this ) with( this ) {
74        lock( lock __cfaabi_dbg_ctx2 );
75        thread$ * thrd = active_thread();
76
77        // single acquisition lock is held by current thread
78        /* paranoid */ verifyf( owner != thrd || multi_acquisition, "Single acquisition lock holder (%p) attempted to reacquire the lock %p resulting in a deadlock.", owner, &this );
79
80        // lock is held by some other thread
81        if ( owner != 0p && owner != thrd ) {
82                insert_last( blocked_threads, *thrd );
83                wait_count++;
84                unlock( lock );
85                park( );
86        }
87        // multi acquisition lock is held by current thread
88        else if ( owner == thrd && multi_acquisition ) {
89                recursion_count++;
90                unlock( lock );
91        }
92        // lock isn't held
93        else {
94                owner = thrd;
95                recursion_count = 1;
96                unlock( lock );
97        }
98}
99
100bool try_lock( blocking_lock & this ) with( this ) {
101        bool ret = false;
102        lock( lock __cfaabi_dbg_ctx2 );
103
104        // lock isn't held
105        if ( owner == 0p ) {
106                owner = active_thread();
107                recursion_count = 1;
108                ret = true;
109        }
110        // multi acquisition lock is held by current thread
111        else if ( owner == active_thread() && multi_acquisition ) {
112                recursion_count++;
113                ret = true;
114        }
115
116        unlock( lock );
117        return ret;
118}
119
120static void pop_and_set_new_owner( blocking_lock & this ) with( this ) {
121        thread$ * t = &try_pop_front( blocked_threads );
122        owner = t;
123        recursion_count = ( t ? 1 : 0 );
124        if ( t ) wait_count--;
125        unpark( t );
126}
127
128void unlock( blocking_lock & this ) with( this ) {
129        lock( lock __cfaabi_dbg_ctx2 );
130        /* paranoid */ verifyf( owner != 0p, "Attempt to release lock %p that isn't held", &this );
131        /* paranoid */ verifyf( owner == active_thread() || !strict_owner , "Thread %p other than the owner %p attempted to release owner lock %p", owner, active_thread(), &this );
132        /* paranoid */ verifyf( recursion_count == 1 || multi_acquisition, "Thread %p attempted to release owner lock %p which is not recursive but has a recursive count of %zu", active_thread(), &this, recursion_count );
133
134        // if recursion count is zero release lock and set new owner if one is waiting
135        recursion_count--;
136        if ( recursion_count == 0 ) {
137                pop_and_set_new_owner( this );
138        }
139        unlock( lock );
140}
141
142size_t wait_count( blocking_lock & this ) with( this ) {
143        return wait_count;
144}
145
146void on_notify( blocking_lock & this, thread$ * t ) with( this ) {
147        lock( lock __cfaabi_dbg_ctx2 );
148        // lock held
149        if ( owner != 0p ) {
150                insert_last( blocked_threads, *t );
151                wait_count++;
152                unlock( lock );
153        }
154        // lock not held
155        else {
156                owner = t;
157                recursion_count = 1;
158                unpark( t );
159                unlock( lock );
160        }
161}
162
163size_t on_wait( blocking_lock & this ) with( this ) {
164        lock( lock __cfaabi_dbg_ctx2 );
165        /* paranoid */ verifyf( owner != 0p, "Attempt to release lock %p that isn't held", &this );
166        /* paranoid */ verifyf( owner == active_thread() || !strict_owner, "Thread %p other than the owner %p attempted to release owner lock %p", owner, active_thread(), &this );
167
168        size_t ret = recursion_count;
169
170        pop_and_set_new_owner( this );
171        unlock( lock );
172        return ret;
173}
174
175void on_wakeup( blocking_lock & this, size_t recursion ) with( this ) {
176        recursion_count = recursion;
177}
178
179//-----------------------------------------------------------------------------
180// alarm node wrapper
181forall(L & | is_blocking_lock(L)) {
182        struct alarm_node_wrap {
183                alarm_node_t alarm_node;
184                condition_variable(L) * cond;
185                info_thread(L) * info_thd;
186        };
187
188        void ?{}( alarm_node_wrap(L) & this, Duration alarm, Duration period, Alarm_Callback callback, condition_variable(L) * c, info_thread(L) * i ) {
189                this.alarm_node{ callback, alarm, period };
190                this.cond = c;
191                this.info_thd = i;
192        }
193
194        void ^?{}( alarm_node_wrap(L) & this ) { }
195
196        static void timeout_handler ( alarm_node_wrap(L) & this ) with( this ) {
197                // This condition_variable member is called from the kernel, and therefore, cannot block, but it can spin.
198                lock( cond->lock __cfaabi_dbg_ctx2 );
199
200                // this check is necessary to avoid a race condition since this timeout handler
201                //      may still be called after a thread has been removed from the queue but
202                //      before the alarm is unregistered
203                if ( (*info_thd)`isListed ) {   // is thread on queue
204                        info_thd->signalled = false;
205                        // remove this thread O(1)
206                        remove( *info_thd );
207                        cond->count--;
208                        if( info_thd->lock ) {
209                                // call lock's on_notify if a lock was passed
210                                on_notify(*info_thd->lock, info_thd->t);
211                        } else {
212                                // otherwise wake thread
213                                unpark( info_thd->t );
214                        }
215                }
216                unlock( cond->lock );
217        }
218
219        // this casts the alarm node to our wrapped type since we used type erasure
220        static void alarm_node_wrap_cast( alarm_node_t & a ) { timeout_handler( (alarm_node_wrap(L) &)a ); }
221
222        struct pthread_alarm_node_wrap {
223                alarm_node_t alarm_node;
224                pthread_cond_var(L) * cond;
225                info_thread(L) * info_thd;
226        };
227
228        void ?{}( pthread_alarm_node_wrap(L) & this, Duration alarm, Duration period, Alarm_Callback callback, pthread_cond_var(L) * c, info_thread(L) * i ) {
229                this.alarm_node{ callback, alarm, period };
230                this.cond = c;
231                this.info_thd = i;
232        }
233
234        void ^?{}( pthread_alarm_node_wrap(L) & this ) { }
235
236        static void timeout_handler ( pthread_alarm_node_wrap(L) & this ) with( this ) {
237                // This pthread_cond_var member is called from the kernel, and therefore, cannot block, but it can spin.
238                lock( cond->lock __cfaabi_dbg_ctx2 );
239
240                // this check is necessary to avoid a race condition since this timeout handler
241                //      may still be called after a thread has been removed from the queue but
242                //      before the alarm is unregistered
243                if ( (*info_thd)`isListed ) {   // is thread on queue
244                        info_thd->signalled = false;
245                        // remove this thread O(1)
246                        remove( *info_thd );
247                        on_notify(*info_thd->lock, info_thd->t);
248                }
249                unlock( cond->lock );
250        }
251
252        // this casts the alarm node to our wrapped type since we used type erasure
253        static void pthread_alarm_node_wrap_cast( alarm_node_t & a ) { timeout_handler( (pthread_alarm_node_wrap(L) &)a ); }
254}
255
256//-----------------------------------------------------------------------------
257// Synchronization Locks
258forall(L & | is_blocking_lock(L)) {
259
260        //-----------------------------------------------------------------------------
261        // condition variable
262        void ?{}( condition_variable(L) & this ){
263                this.lock{};
264                this.blocked_threads{};
265                this.count = 0;
266        }
267
268        void ^?{}( condition_variable(L) & this ){ }
269
270        static void process_popped( condition_variable(L) & this, info_thread(L) & popped ) with( this ) {
271                if(&popped != 0p) {
272                        popped.signalled = true;
273                        count--;
274                        if (popped.lock) {
275                                // if lock passed call on_notify
276                                on_notify(*popped.lock, popped.t);
277                        } else {
278                                // otherwise wake thread
279                                unpark(popped.t);
280                        }
281                }
282        }
283
284        bool notify_one( condition_variable(L) & this ) with( this ) {
285                lock( lock __cfaabi_dbg_ctx2 );
286                bool ret = ! blocked_threads`isEmpty;
287                process_popped(this, try_pop_front( blocked_threads ));
288                unlock( lock );
289                return ret;
290        }
291
292        bool notify_all( condition_variable(L) & this ) with(this) {
293                lock( lock __cfaabi_dbg_ctx2 );
294                bool ret = ! blocked_threads`isEmpty;
295                while( ! blocked_threads`isEmpty ) {
296                        process_popped(this, try_pop_front( blocked_threads ));
297                }
298                unlock( lock );
299                return ret;
300        }
301
302        uintptr_t front( condition_variable(L) & this ) with(this) {
303                return blocked_threads`isEmpty ? NULL : blocked_threads`first.info;
304        }
305
306        bool empty( condition_variable(L) & this ) with(this) {
307                lock( lock __cfaabi_dbg_ctx2 );
308                bool ret = blocked_threads`isEmpty;
309                unlock( lock );
310                return ret;
311        }
312
313        int counter( condition_variable(L) & this ) with(this) { return count; }
314
315        static size_t queue_and_get_recursion( condition_variable(L) & this, info_thread(L) * i ) with(this) {
316                // add info_thread to waiting queue
317                insert_last( blocked_threads, *i );
318                count++;
319                size_t recursion_count = 0;
320                if (i->lock) {
321                        // if lock was passed get recursion count to reset to after waking thread
322                        recursion_count = on_wait( *i->lock );
323                }
324                return recursion_count;
325        }
326
327        // helper for wait()'s' with no timeout
328        static void queue_info_thread( condition_variable(L) & this, info_thread(L) & i ) with(this) {
329                lock( lock __cfaabi_dbg_ctx2 );
330                size_t recursion_count = queue_and_get_recursion(this, &i);
331                unlock( lock );
332
333                // blocks here
334                park( );
335
336                // resets recursion count here after waking
337                if (i.lock) on_wakeup(*i.lock, recursion_count);
338        }
339
340        #define WAIT( u, l ) \
341                info_thread( L ) i = { active_thread(), u, l }; \
342                queue_info_thread( this, i );
343
344        // helper for wait()'s' with a timeout
345        static void queue_info_thread_timeout( condition_variable(L) & this, info_thread(L) & info, Duration t, Alarm_Callback callback ) with(this) {
346                lock( lock __cfaabi_dbg_ctx2 );
347                size_t recursion_count = queue_and_get_recursion(this, &info);
348                alarm_node_wrap(L) node_wrap = { t, 0`s, callback, &this, &info };
349                register_self( &node_wrap.alarm_node );
350                unlock( lock );
351
352                // blocks here
353                park();
354
355                // unregisters alarm so it doesn't go off if this happens first
356                unregister_self( &node_wrap.alarm_node );
357
358                // resets recursion count here after waking
359                if (info.lock) on_wakeup(*info.lock, recursion_count);
360        }
361
362        #define WAIT_TIME( u, l, t ) \
363                info_thread( L ) i = { active_thread(), u, l }; \
364                queue_info_thread_timeout(this, i, t, alarm_node_wrap_cast ); \
365                return i.signalled;
366
367        void wait( condition_variable(L) & this                        ) with(this) { WAIT( 0, 0p    ) }
368        void wait( condition_variable(L) & this, uintptr_t info        ) with(this) { WAIT( info, 0p ) }
369        void wait( condition_variable(L) & this, L & l                 ) with(this) { WAIT( 0, &l    ) }
370        void wait( condition_variable(L) & this, L & l, uintptr_t info ) with(this) { WAIT( info, &l ) }
371
372        bool wait( condition_variable(L) & this, Duration duration                        ) with(this) { WAIT_TIME( 0   , 0p , duration ) }
373        bool wait( condition_variable(L) & this, uintptr_t info, Duration duration        ) with(this) { WAIT_TIME( info, 0p , duration ) }
374        bool wait( condition_variable(L) & this, L & l, Duration duration                 ) with(this) { WAIT_TIME( 0   , &l , duration ) }
375        bool wait( condition_variable(L) & this, L & l, uintptr_t info, Duration duration ) with(this) { WAIT_TIME( info, &l , duration ) }
376
377        //-----------------------------------------------------------------------------
378        // fast_cond_var
379        void  ?{}( fast_cond_var(L) & this ){
380                this.blocked_threads{};
381                #ifdef __CFA_DEBUG__
382                this.lock_used = 0p;
383                #endif
384        }
385        void ^?{}( fast_cond_var(L) & this ){ }
386
387        bool notify_one( fast_cond_var(L) & this ) with(this) {
388                bool ret = ! blocked_threads`isEmpty;
389                if ( ret ) {
390                        info_thread(L) & popped = try_pop_front( blocked_threads );
391                        on_notify(*popped.lock, popped.t);
392                }
393                return ret;
394        }
395        bool notify_all( fast_cond_var(L) & this ) with(this) {
396                bool ret = ! blocked_threads`isEmpty;
397                while( ! blocked_threads`isEmpty ) {
398                        info_thread(L) & popped = try_pop_front( blocked_threads );
399                        on_notify(*popped.lock, popped.t);
400                }
401                return ret;
402        }
403
404        uintptr_t front( fast_cond_var(L) & this ) with(this) { return blocked_threads`isEmpty ? NULL : blocked_threads`first.info; }
405        bool empty ( fast_cond_var(L) & this ) with(this) { return blocked_threads`isEmpty; }
406
407        void wait( fast_cond_var(L) & this, L & l ) {
408                wait( this, l, 0 );
409        }
410
411        void wait( fast_cond_var(L) & this, L & l, uintptr_t info ) with(this) {
412                // brand cond lock with lock
413                #ifdef __CFA_DEBUG__
414                        if ( lock_used == 0p ) lock_used = &l;
415                        else { assert(lock_used == &l); }
416                #endif
417                info_thread( L ) i = { active_thread(), info, &l };
418                insert_last( blocked_threads, i );
419                size_t recursion_count = on_wait( *i.lock );
420                park( );
421                on_wakeup(*i.lock, recursion_count);
422        }
423
424        //-----------------------------------------------------------------------------
425        // pthread_cond_var
426
427        void  ?{}( pthread_cond_var(L) & this ) with(this) {
428                blocked_threads{};
429                lock{};
430        }
431
432        void ^?{}( pthread_cond_var(L) & this ) { }
433
434        bool notify_one( pthread_cond_var(L) & this ) with(this) {
435                lock( lock __cfaabi_dbg_ctx2 );
436                bool ret = ! blocked_threads`isEmpty;
437                if ( ret ) {
438                        info_thread(L) & popped = try_pop_front( blocked_threads );
439                        on_notify(*popped.lock, popped.t);
440                }
441                unlock( lock );
442                return ret;
443        }
444
445        bool notify_all( pthread_cond_var(L) & this ) with(this) {
446                lock( lock __cfaabi_dbg_ctx2 );
447                bool ret = ! blocked_threads`isEmpty;
448                while( ! blocked_threads`isEmpty ) {
449                        info_thread(L) & popped = try_pop_front( blocked_threads );
450                        on_notify(*popped.lock, popped.t);
451                }
452                unlock( lock );
453                return ret;
454        }
455
456        uintptr_t front( pthread_cond_var(L) & this ) with(this) { return blocked_threads`isEmpty ? NULL : blocked_threads`first.info; }
457        bool empty ( pthread_cond_var(L) & this ) with(this) { return blocked_threads`isEmpty; }
458
459        static size_t queue_and_get_recursion( pthread_cond_var(L) & this, info_thread(L) * i ) with(this) {
460                // add info_thread to waiting queue
461                insert_last( blocked_threads, *i );
462                size_t recursion_count = 0;
463                recursion_count = on_wait( *i->lock );
464                return recursion_count;
465        }
466       
467        static void queue_info_thread_timeout( pthread_cond_var(L) & this, info_thread(L) & info, Duration t, Alarm_Callback callback ) with(this) {
468                lock( lock __cfaabi_dbg_ctx2 );
469                size_t recursion_count = queue_and_get_recursion(this, &info);
470                pthread_alarm_node_wrap(L) node_wrap = { t, 0`s, callback, &this, &info };
471                register_self( &node_wrap.alarm_node );
472                unlock( lock );
473
474                // blocks here
475                park();
476
477                // unregisters alarm so it doesn't go off if this happens first
478                unregister_self( &node_wrap.alarm_node );
479
480                // resets recursion count here after waking
481                if (info.lock) on_wakeup(*info.lock, recursion_count);
482        }
483
484        void wait( pthread_cond_var(L) & this, L & l ) with(this) {
485                wait( this, l, 0 );
486        }
487
488        void wait( pthread_cond_var(L) & this, L & l, uintptr_t info ) with(this) {
489                lock( lock __cfaabi_dbg_ctx2 );
490                info_thread( L ) i = { active_thread(), info, &l };
491                size_t recursion_count = queue_and_get_recursion(this, &i);
492                unlock( lock );
493                park( );
494                on_wakeup(*i.lock, recursion_count);
495        }
496
497        #define PTHREAD_WAIT_TIME( u, l, t ) \
498                info_thread( L ) i = { active_thread(), u, l }; \
499                queue_info_thread_timeout(this, i, t, pthread_alarm_node_wrap_cast ); \
500                return i.signalled;
501
502        bool wait( pthread_cond_var(L) & this, L & l, timespec t ) {
503                Duration d = { t };
504                WAIT_TIME( 0, &l , d )
505        }
506       
507        bool wait( pthread_cond_var(L) & this, L & l, uintptr_t info, timespec t  ) {
508                Duration d = { t };
509                WAIT_TIME( info, &l , d )
510        }
511}
512//-----------------------------------------------------------------------------
513// Semaphore
514void  ?{}( semaphore & this, int count = 1 ) {
515        (this.lock){};
516        this.count = count;
517        (this.waiting){};
518}
519void ^?{}(semaphore & this) {}
520
521bool P(semaphore & this) with( this ){
522        lock( lock __cfaabi_dbg_ctx2 );
523        count -= 1;
524        if ( count < 0 ) {
525                // queue current task
526                append( waiting, active_thread() );
527
528                // atomically release spin lock and block
529                unlock( lock );
530                park();
531                return true;
532        }
533        else {
534            unlock( lock );
535            return false;
536        }
537}
538
539thread$ * V (semaphore & this, const bool doUnpark ) with( this ) {
540        thread$ * thrd = 0p;
541        lock( lock __cfaabi_dbg_ctx2 );
542        count += 1;
543        if ( count <= 0 ) {
544                // remove task at head of waiting list
545                thrd = pop_head( waiting );
546        }
547
548        unlock( lock );
549
550        // make new owner
551        if( doUnpark ) unpark( thrd );
552
553        return thrd;
554}
555
556bool V(semaphore & this) with( this ) {
557        thread$ * thrd = V(this, true);
558        return thrd != 0p;
559}
560
561bool V(semaphore & this, unsigned diff) with( this ) {
562        thread$ * thrd = 0p;
563        lock( lock __cfaabi_dbg_ctx2 );
564        int release = max(-count, (int)diff);
565        count += diff;
566        for(release) {
567                unpark( pop_head( waiting ) );
568        }
569
570        unlock( lock );
571
572        return thrd != 0p;
573}
Note: See TracBrowser for help on using the repository browser.