source: libcfa/src/concurrency/kernel.hfa@ 29c9b23

//
// Cforall Version 1.0.0 Copyright (C) 2016 University of Waterloo
//
// The contents of this file are covered under the licence agreement in the
// file "LICENCE" distributed with Cforall.
//
// kernel -- Header containing the core of the kernel API
//
// Author           : Thierry Delisle
// Created On       : Tue Jan 17 12:27:26 2017
// Last Modified By : Peter A. Buhr
// Last Modified On : Tue Feb  4 12:29:26 2020
// Update Count     : 22
//

#pragma once

#include "invoke.h"
#include "time_t.hfa"
#include "coroutine.hfa"

#include "containers/list.hfa"

extern "C" {
        #include <bits/pthreadtypes.h>
        #include <pthread.h>
        #include <linux/types.h>
}

//-----------------------------------------------------------------------------
// Underlying Locks
#ifdef __CFA_WITH_VERIFY__
        extern bool __cfaabi_dbg_in_kernel();
#endif

extern "C" {
        char * strerror(int);
}
#define CHECKED(x) { int err = x; if( err != 0 ) abort("KERNEL ERROR: Operation \"" #x "\" return error %d - %s\n", err, strerror(err)); }

struct __bin_sem_t {
        pthread_mutex_t         lock;
        pthread_cond_t          cond;
        int                     val;
};

static inline void ?{}(__bin_sem_t & this) with( this ) {
        // Create the mutex with error checking
        pthread_mutexattr_t mattr;
        pthread_mutexattr_init( &mattr );
        pthread_mutexattr_settype( &mattr, PTHREAD_MUTEX_ERRORCHECK_NP);
        pthread_mutex_init(&lock, &mattr);

        pthread_cond_init (&cond, (const pthread_condattr_t *)0p);  // workaround trac#208: cast should not be required
        val = 0;
}

static inline void ^?{}(__bin_sem_t & this) with( this ) {
        CHECKED( pthread_mutex_destroy(&lock) );
        CHECKED( pthread_cond_destroy (&cond) );
}

static inline void wait(__bin_sem_t & this) with( this ) {
        verify(__cfaabi_dbg_in_kernel());
        CHECKED( pthread_mutex_lock(&lock) );
                while(val < 1) {
                        pthread_cond_wait(&cond, &lock);
                }
                val -= 1;
        CHECKED( pthread_mutex_unlock(&lock) );
}

static inline bool post(__bin_sem_t & this) with( this ) {
        bool needs_signal = false;

        CHECKED( pthread_mutex_lock(&lock) );
                if(val < 1) {
                        val += 1;
                        pthread_cond_signal(&cond);
                        needs_signal = true;
                }
        CHECKED( pthread_mutex_unlock(&lock) );

        return needs_signal;
}

#undef CHECKED


//-----------------------------------------------------------------------------
// Processor
extern struct cluster * mainCluster;

// Processor id, required for scheduling threads
struct __processor_id_t {
        unsigned id:24;
        bool full_proc:1;

        #if !defined(__CFA_NO_STATISTICS__)
                struct __stats_t * stats;
        #endif
};

coroutine processorCtx_t {
        struct processor * proc;
};

// Wrapper around kernel threads
struct __attribute__((aligned(128))) processor {
        // Main state
        inline __processor_id_t;

        // Cluster from which to get threads
        struct cluster * cltr;

        // Set to true to notify the processor should terminate
        volatile bool do_terminate;

        // Coroutine ctx who does keeps the state of the processor
        struct processorCtx_t runner;

        // Name of the processor
        const char * name;

        // Handle to pthreads
        pthread_t kernel_thread;

        // Preemption data
        // Node which is added in the discrete event simulaiton
        struct alarm_node_t * preemption_alarm;

        // If true, a preemption was triggered in an unsafe region, the processor must preempt as soon as possible
        bool pending_preemption;

        // Idle lock (kernel semaphore)
        __bin_sem_t idle;

        // Termination synchronisation (user semaphore)
        oneshot terminated;

        // pthread Stack
        void * stack;

        // Link lists fields
        DLISTED_MGD_IMPL_IN(processor)

        #if !defined(__CFA_NO_STATISTICS__)
                int print_stats;
                bool print_halts;
        #endif

#ifdef __CFA_DEBUG__
        // Last function to enable preemption on this processor
        const char * last_enable;
#endif
};

void  ?{}(processor & this, const char name[], struct cluster & cltr);
void ^?{}(processor & this);

static inline void  ?{}(processor & this)                    { this{ "Anonymous Processor", *mainCluster}; }
static inline void  ?{}(processor & this, struct cluster & cltr)    { this{ "Anonymous Processor", cltr}; }
static inline void  ?{}(processor & this, const char name[]) { this{name, *mainCluster }; }

DLISTED_MGD_IMPL_OUT(processor)

//-----------------------------------------------------------------------------
// I/O
struct __io_data;

// IO poller user-thread
// Not using the "thread" keyword because we want to control
// more carefully when to start/stop it
struct $io_ctx_thread {
        struct __io_data * ring;
        single_sem sem;
        volatile bool done;
        $thread self;
};


struct io_context {
        $io_ctx_thread thrd;
};

struct io_context_params {
        int num_entries;
        int num_ready;
        int submit_aff;
        bool eager_submits:1;
        bool poller_submits:1;
        bool poll_submit:1;
        bool poll_complete:1;
};

void  ?{}(io_context_params & this);

void  ?{}(io_context & this, struct cluster & cl);
void  ?{}(io_context & this, struct cluster & cl, const io_context_params & params);
void ^?{}(io_context & this);

struct io_cancellation {
        __u64 target;
};

static inline void  ?{}(io_cancellation & this) { this.target = -1u; }
static inline void ^?{}(io_cancellation &) {}
bool cancel(io_cancellation & this);

//-----------------------------------------------------------------------------
// Cluster Tools

// Intrusives lanes which are used by the relaxed ready queue
struct __attribute__((aligned(128))) __intrusive_lane_t;
void  ?{}(__intrusive_lane_t & this);
void ^?{}(__intrusive_lane_t & this);

// Counter used for wether or not the lanes are all empty
struct __attribute__((aligned(128))) __snzi_node_t;
struct __snzi_t {
        unsigned mask;
        int root;
        __snzi_node_t * nodes;
};

void  ?{}( __snzi_t & this, unsigned depth );
void ^?{}( __snzi_t & this );

//TODO adjust cache size to ARCHITECTURE
// Structure holding the relaxed ready queue
struct __ready_queue_t {
        // Data tracking how many/which lanes are used
        // Aligned to 128 for cache locality
        __snzi_t snzi;

        // Data tracking the actual lanes
        // On a seperate cacheline from the used struct since
        // used can change on each push/pop but this data
        // only changes on shrink/grow
        struct {
                // Arary of lanes
                __intrusive_lane_t * volatile data;

                // Number of lanes (empty or not)
                volatile size_t count;
        } lanes;
};

void  ?{}(__ready_queue_t & this);
void ^?{}(__ready_queue_t & this);

// Idle Sleep
struct __cluster_idles {
        // Spin lock protecting the queue
        volatile uint64_t lock;

        // Total number of processors
        unsigned total;

        // Total number of idle processors
        unsigned idle;

        // List of idle processors
        dlist(processor, processor) list;
};

//-----------------------------------------------------------------------------
// Cluster
struct __attribute__((aligned(128))) cluster {
        // Ready queue for threads
        __ready_queue_t ready_queue;

        // Name of the cluster
        const char * name;

        // Preemption rate on this cluster
        Duration preemption_rate;

        // List of idle processors
        __cluster_idles idles;

        // List of threads
        __spinlock_t thread_list_lock;
        __dllist_t(struct $thread) threads;
        unsigned int nthreads;

        // Link lists fields
        struct __dbg_node_cltr {
                cluster * next;
                cluster * prev;
        } node;

        struct {
                io_context * ctxs;
                unsigned cnt;
        } io;

        #if !defined(__CFA_NO_STATISTICS__)
                struct __stats_t * stats;
                int print_stats;
        #endif
};
extern Duration default_preemption();

void ?{} (cluster & this, const char name[], Duration preemption_rate, unsigned num_io, const io_context_params & io_params);
void ^?{}(cluster & this);

static inline void ?{} (cluster & this)                                            { io_context_params default_params;    this{"Anonymous Cluster", default_preemption(), 1, default_params}; }
static inline void ?{} (cluster & this, Duration preemption_rate)                  { io_context_params default_params;    this{"Anonymous Cluster", preemption_rate, 1, default_params}; }
static inline void ?{} (cluster & this, const char name[])                         { io_context_params default_params;    this{name, default_preemption(), 1, default_params}; }
static inline void ?{} (cluster & this, unsigned num_io)                           { io_context_params default_params;    this{"Anonymous Cluster", default_preemption(), num_io, default_params}; }
static inline void ?{} (cluster & this, Duration preemption_rate, unsigned num_io) { io_context_params default_params;    this{"Anonymous Cluster", preemption_rate, num_io, default_params}; }
static inline void ?{} (cluster & this, const char name[], unsigned num_io)        { io_context_params default_params;    this{name, default_preemption(), num_io, default_params}; }
static inline void ?{} (cluster & this, const io_context_params & io_params)                                            { this{"Anonymous Cluster", default_preemption(), 1, io_params}; }
static inline void ?{} (cluster & this, Duration preemption_rate, const io_context_params & io_params)                  { this{"Anonymous Cluster", preemption_rate, 1, io_params}; }
static inline void ?{} (cluster & this, const char name[], const io_context_params & io_params)                         { this{name, default_preemption(), 1, io_params}; }
static inline void ?{} (cluster & this, unsigned num_io, const io_context_params & io_params)                           { this{"Anonymous Cluster", default_preemption(), num_io, io_params}; }
static inline void ?{} (cluster & this, Duration preemption_rate, unsigned num_io, const io_context_params & io_params) { this{"Anonymous Cluster", preemption_rate, num_io, io_params}; }
static inline void ?{} (cluster & this, const char name[], unsigned num_io, const io_context_params & io_params)        { this{name, default_preemption(), num_io, io_params}; }

static inline [cluster *&, cluster *& ] __get( cluster & this ) __attribute__((const)) { return this.node.[next, prev]; }

static inline struct processor * active_processor() { return publicTLS_get( this_processor ); } // UNSAFE
static inline struct cluster   * active_cluster  () { return publicTLS_get( this_processor )->cltr; }

#if !defined(__CFA_NO_STATISTICS__)
        void print_stats_now( cluster & this, int flags );

        static inline void print_stats_at_exit( cluster & this, int flags ) {
                this.print_stats |= flags;
        }

        static inline void print_stats_at_exit( processor & this, int flags ) {
                this.print_stats |= flags;
        }

        void print_halts( processor & this );
#endif

// Local Variables: //
// mode: c //
// tab-width: 4 //
// End: //