source: doc/theses/mike_brooks_MMath/plots/list-zoomin-rel-i-swift.gp@ 8501107

set terminal pdfcairo color enhanced size 2.75in,2.0in font "Times,17"

set size 1.0, 1.0    # scale of plot area inside terminal
set origin 0.0, 0.0  # bottom-left corner

INDIR="build"
OUTDIR="build"

set macros
set output OUTDIR."/plot-list-zoomin-rel-i-swift.pdf"

# Draw fake x axis at y=1.0; use vertical-only bounding 'H'
unset border
set arrow from graph 0, first 1 to graph 1, first 1 nohead lt -1 lw 2
set arrow 100 from graph 0, graph 0 to graph 0, graph 1 nohead lw 1 front

set grid
unset key

set logscale x 2
set xrange [0.75:250];
set xlabel "List length (item count)"


#set bmargin 0
set tmargin 0.1
set lmargin 10
set rmargin 0.1

set ylabel "Duration (relative)" offset -1.0,0
set logscale y (2**0.2)
set yrange [0.47:2.1];
set format y "%.1f {/Symbol \264}"
set ytics (0.5, 0.6, 0.7, 0.8, 0.9, 1.0, 1.2, 1.4, 1.6, 1.8, 2.0) nomirror

# labelled boxes around size zones
set object rect  from first  6, first 0.6 to first  23,  first 2.0 fc rgb "black"       fs empty         lw 2.0
set object rect  from first 45, first 0.6 to first 181, first 1.8 fc rgb "black"       fs empty         lw 2.0
set label "small"                         at first  23,  first (0.6 * 0.9) right
set label "medium"                        at first 181, first (0.6 * 0.9) right

set errorbars 2.0
set pointintervalbox 0

plot INDIR."/plot-list-zoomin-rel-i-swift.dat" \
       i 0 using ($1 * 0.98):8:4:5 title columnheader(1) with yerrorbars lt rgb "blue"        pt  6  ps 0.85 lw 1, \
    '' i 4 using ($1 * 0.94):8:4:5 title columnheader(1) with yerrorbars lt rgb "dark-orange"   pt  8  ps 0.75 lw 1, \
    '' i 3 using ($1 * 1.02):8:4:5 title columnheader(1) with yerrorbars lt rgb "magenta"             pt  10 ps 0.85 lw 1, \
    '' i 2 using ($1 * 1.06):8:4:5 title columnheader(1) with yerrorbars lt rgb "purple"              pt  12 ps 1.0  lw 1