Changeset cf85f96

Timestamp:

Jun 17, 2021, 10:31:39 PM (3 years ago)

Author:

Thierry Delisle <tdelisle@…>

Branches:

ADT, ast-experimental, enum, forall-pointer-decay, jacob/cs343-translation, master, new-ast-unique-expr, pthread-emulation, qualifiedEnum

Children:

df7597e0

Parents:

12daa43

Message:

Cpu map now has aself pointer to figure out where between start and start + count each cpu belong.
Added way more testing to the device/cpu test.

Files:

• libcfa/src/device/cpu.cfa (modified) (6 diffs)
• libcfa/src/device/cpu.hfa (modified) (1 diff)
• tests/device/cpu.cfa (modified) (2 diffs)

libcfa/src/device/cpu.cfa

@@ -256 +256 @@
 }
 
+struct llc_map_t {
+        raw_cache_instance * raw;
+        unsigned count;
+        unsigned start;
+};
+
 // returns an allocate list of all the different distinct last level caches
-static [*idx_range_t, size_t cnt] distinct_llcs(unsigned cpus, unsigned llc_idx, raw_cache_instance ** raw) {
+static [*llc_map_t, size_t cnt] distinct_llcs(unsigned cpus, unsigned llc_idx, raw_cache_instance ** raw) {
         // Allocate at least one element
-        idx_range_t * ranges = alloc();
+        llc_map_t* ranges = alloc();
         size_t range_cnt = 1;
 
         // Initialize with element 0
-        *ranges = raw[0][llc_idx].range;
+        ranges->raw = &raw[0][llc_idx];
+        ranges->count = 0;
+        ranges->start = -1u;
 
         // Go over all other cpus
         CPU_LOOP: for(i; 1~cpus) {
                 // Check if the range is already there
-                idx_range_t candidate = raw[i][llc_idx].range;
+                raw_cache_instance * candidate = &raw[i][llc_idx];
                 for(j; range_cnt) {
-                        idx_range_t exist = ranges[j];
+                        llc_map_t & exist = ranges[j];
                         // If the range is already there just jump to the next cpu
-                        if(0 == strcmp(candidate, exist)) continue CPU_LOOP;
+                        if(0 == strcmp(candidate->range, exist.raw->range)) continue CPU_LOOP;
                 }
 
                 // The range wasn't there, added to the list
                 ranges = alloc(range_cnt + 1, ranges`realloc);
-                ranges[range_cnt] = candidate;
+                ranges[range_cnt].raw = candidate;
+                ranges[range_cnt].count = 0;
+                ranges[range_cnt].start = -1u;
                 range_cnt++;
         }
@@ -287 +297 @@
 struct cpu_pairing_t {
         unsigned cpu;
-        unsigned llc_id;
+        unsigned id;
 };
 
 int ?<?( cpu_pairing_t lhs, cpu_pairing_t rhs ) {
-        return lhs.llc_id < rhs.llc_id;
-}
-
-static [[]cpu_pairing_t] get_cpu_pairings(unsigned cpus, raw_cache_instance ** raw, idx_range_t * maps, size_t map_cnt) {
+        return lhs.id < rhs.id;
+}
+
+static [[]cpu_pairing_t] get_cpu_pairings(unsigned cpus, raw_cache_instance ** raw, llc_map_t * maps, size_t map_cnt) {
         cpu_pairing_t * pairings = alloc(cpus);
 
@@ -301 +311 @@
                 idx_range_t want = raw[i][0].range;
                 MAP_LOOP: for(j; map_cnt) {
-                        if(0 != strcmp(want, maps[j])) continue MAP_LOOP;
-
-                        pairings[i].llc_id = j;
+                        if(0 != strcmp(want, maps[j].raw->range)) continue MAP_LOOP;
+
+                        pairings[i].id = j;
                         continue CPU_LOOP;
                 }
@@ -312 +322 @@
         return pairings;
 }
+
+#include <fstream.hfa>
 
 extern "C" {
@@ -336 +348 @@
 
                 // Find number of distinct cache instances
-                idx_range_t * maps;
+                llc_map_t * maps;
                 size_t map_cnt;
                 [maps, map_cnt] =  distinct_llcs(cpus, cache_levels - llc, raw);
 
                 #if defined(__CFA_WITH_VERIFY__)
+                // Verify that the caches cover the all the cpus
                 {
-                        unsigned width = 0;
+                        unsigned width1 = 0;
+                        unsigned width2 = 0;
                         for(i; map_cnt) {
                                 const char * _;
-                                width += read_width(maps[i], strlen(maps[i]), &_);
+                                width1 += read_width(maps[i].raw->range, strlen(maps[i].raw->range), &_);
+                                width2 += maps[i].raw->width;
                         }
-                        verify(width == cpus);
+                        verify(width1 == cpus);
+                        verify(width2 == cpus);
                 }
                 #endif
@@ -357 +373 @@
                 qsort(pairings, cpus);
 
-                unsigned llc_width = raw[0][cache_levels - llc].width;
-
-                // From the mappins build the actual cpu map we want
+                {
+                        unsigned it = 0;
+                        for(i; cpus) {
+                                unsigned llc_id = pairings[i].id;
+                                if(maps[llc_id].start == -1u) {
+                                        maps[llc_id].start = it;
+                                        it += maps[llc_id].raw->width;
+                                        /* paranoid */ verify(maps[llc_id].start < it);
+                                        /* paranoid */ verify(it != -1u);
+                                }
+                        }
+                        /* paranoid */ verify(it == cpus);
+                }
+
+                // From the mappings build the actual cpu map we want
                 struct cpu_map_entry_t * entries = alloc(cpus);
                 for(i; cpus) { entries[i].count = 0; }
                 for(i; cpus) {
+                        /* paranoid */ verify(pairings[i].id < map_cnt);
                         unsigned c = pairings[i].cpu;
-                        entries[c].start = pairings[i].llc_id * llc_width;
-                        entries[c].count = llc_width;
+                        unsigned llc_id = pairings[i].id;
+                        unsigned width = maps[llc_id].raw->width;
+                        unsigned start = maps[llc_id].start;
+                        unsigned self  = start + (maps[llc_id].count++);
+                        entries[c].count = width;
+                        entries[c].start = start;
+                        entries[c].self  = self;
                 }
 

libcfa/src/device/cpu.hfa

@@ -17 +17 @@
 
 struct cpu_map_entry_t {
+        unsigned self;
         unsigned start;
         unsigned count;

tests/device/cpu.cfa

@@ -17 +17 @@
 #include <fstream.hfa>
 #include <device/cpu.hfa>
+#include <stdlib.hfa>
+
+#include <errno.h>
+#include <stdio.h>
+#include <string.h>
+#include <unistd.h>
+
 extern "C" {
+        #include <dirent.h>
+        #include <sys/types.h>
+        #include <sys/stat.h>
         #include <sys/sysinfo.h>
+        #include <fcntl.h>
+}
+
+// go through a directory calling fn on each file
+static int iterate_dir( const char * path, void (*fn)(struct dirent * ent) ) {
+        // open the directory
+        DIR *dir = opendir(path);
+        if(dir == 0p) { return ENOTDIR; }
+
+        // call fn for each
+        struct dirent * ent;
+        while ((ent = readdir(dir)) != 0p) {
+                fn( ent );
+        }
+
+        // no longer need this
+        closedir(dir);
+        return 0;
+}
+
+// count the number of directories with the specified prefix
+// the directories counted have the form '[prefix]N' where prefix is the parameter
+// and N is an base 10 integer.
+static int count_prefix_dirs(const char * path, const char * prefix) {
+        // read the directory and find the cpu count
+        // and make sure everything is as expected
+        int max = -1;
+        int count = 0;
+        void lambda(struct dirent * ent) {
+                // were are looking for prefixX, where X is a number
+                // check that it starts with 'cpu
+                char * s = strstr(ent->d_name, prefix);
+                if(s == 0p) { return; }
+                if(s != ent->d_name) { return; }
+
+                // check that the next part is a number
+                s += strlen(prefix);
+                char * end;
+                long int val = strtol(s, &end, 10);
+                if(*end != '\0' || val < 0) { return; }
+
+                // check that it's a directory
+                if(ent->d_type != DT_DIR) { return; }
+
+                // it's a match!
+                max = max(val, max);
+                count++;
+        }
+        iterate_dir(path, lambda);
+
+        /* paranoid */ verifyf(count == max + 1, "Inconsistent %s count, counted %d, but max %s was %d", prefix, count, prefix, (int)max);
+
+        return count;
+}
+
+// Count number of cache *indexes* in the system
+// cache indexes are distinct from cache level as Data or Instruction cache
+// can share a level but not an index
+// PITFALL: assumes all cpus have the same indexes as cpu0
+static int count_cache_indexes(void) {
+        return count_prefix_dirs("/sys/devices/system/cpu/cpu0/cache", "index");
+}
+
+// read information about a spcficic cache index/cpu file into the output buffer
+static size_t read_cpuidxinfo_into(unsigned cpu, unsigned idx, const char * file, char * out, size_t out_len) {
+        // Pick the file we want and read it
+        char buf[128];
+        /* paranoid */ __attribute__((unused)) int len =
+        snprintf(buf, 128, "/sys/devices/system/cpu/cpu%u/cache/index%u/%s", cpu, idx, file);
+        /* paranoid */ verifyf(len > 0, "Could not generate '%s' filename for cpu %u, index %u", file, cpu, idx);
+
+        int fd = open(buf, 0, O_RDONLY);
+        /* paranoid */ verifyf(fd > 0, "Could not open file '%s'", buf);
+
+        ssize_t r = read(fd, out, out_len);
+        /* paranoid */ verifyf(r > 0, "Could not read file '%s'", buf);
+
+        /* paranoid */ __attribute__((unused)) int ret =
+        close(fd);
+        /* paranoid */ verifyf(ret == 0, "Could not close file '%s'", buf);
+
+        out[r-1] = '\0';
+        return r-1;
+}
+
+unsigned find_idx() {
+        int idxs = count_cache_indexes();
+
+        unsigned found_level = 0;
+        unsigned found = -1u;
+        for(i; idxs) {
+                unsigned idx = idxs - 1 - i;
+                char buf[32];
+
+                // Level is the cache level: higher means bigger and slower
+                read_cpuidxinfo_into(0, idx, "level", buf, 32);
+                char * end;
+                unsigned long level = strtoul(buf, &end, 10);
+                /* paranoid */ verifyf(level <= 250, "Cpu %u has more than 250 levels of cache, that doesn't sound right", 0);
+                /* paranoid */ verify(*end == '\0');
+
+                if(found_level < level) {
+                        found_level = level;
+                        found = idx;
+                }
+        }
+
+        /* paranoid */ verify(found != -1u);
+        return found;
 }
 
 int main() {
+        //-----------------------------------------------------------------------
         int ret1 = get_nprocs();
         int ret2 = cpu_info.hthrd_count;
@@ -31 +151 @@
         }
 
+        //-----------------------------------------------------------------------
+        // Make sure no one has the same self
+        for(ime; cpu_info.hthrd_count) {
+                unsigned me = cpu_info.llc_map[ime].self;
+                {
+                        unsigned s = cpu_info.llc_map[ime].start;
+                        unsigned e = s + cpu_info.llc_map[ime].count;
+                        if(me < s || me >= e) {
+                                sout | "CPU" | ime | "outside of it's own map: " | s | "<=" | me | "<" | e;
+                        }
+                }
+
+
+                for(ithem; cpu_info.hthrd_count) {
+                        if(ime == ithem) continue;
+
+                        unsigned them = cpu_info.llc_map[ithem].self;
+                        if(me == them) {
+                                sout | "CPU" | ime | "has conflicting self id with" | ithem | "(" | me | ")";
+                        }
+                }
+        }
+
+
+        //-----------------------------------------------------------------------
+        unsigned idx = find_idx();
+        // For all procs check mapping is consistent
+        for(cpu_me; cpu_info.hthrd_count) {
+                char buf_me[32];
+                size_t len_me = read_cpuidxinfo_into(cpu_me, idx, "shared_cpu_list", buf_me, 32);
+                for(cpu_them; cpu_info.hthrd_count) {
+                        if(cpu_me == cpu_them) continue;
+                        char buf_them[32];
+                        size_t len_them = read_cpuidxinfo_into(cpu_them, idx, "shared_cpu_list", buf_them, 32);
+
+                        bool match_file = len_them == len_me && 0 == strncmp(buf_them, buf_me, len_me);
+                        bool match_info = cpu_info.llc_map[cpu_me].start == cpu_info.llc_map[cpu_them].start && cpu_info.llc_map[cpu_me].count == cpu_info.llc_map[cpu_them].count;
+
+                        if(match_file != match_info) {
+                                sout | "CPU" | cpu_me | "and" | cpu_them | "have inconsitent file and cpu_info";
+                                sout | cpu_me | ": <" | cpu_info.llc_map[cpu_me  ].start | "," | cpu_info.llc_map[cpu_me  ].count | "> '" | buf_me   | "'";
+                                sout | cpu_me | ": <" | cpu_info.llc_map[cpu_them].start | "," | cpu_info.llc_map[cpu_them].count | "> '" | buf_them | "'";
+                        }
+                }
+        }
 }