source: translator/Parser/lex.l @ 3848e0e

ADTaaron-thesisarm-ehast-experimentalcleanup-dtorsctordeferred_resndemanglerenumforall-pointer-decaygc_noraiijacob/cs343-translationjenkins-sandboxmemorynew-astnew-ast-unique-exprnew-envno_listpersistent-indexerpthread-emulationqualifiedEnumresolv-newstringwith_gc
Last change on this file since 3848e0e was 3848e0e, checked in by Peter A. Buhr <pabuhr@…>, 9 years ago

underscore changes, ptrdiff_t changes, formating, _Bool prelude
  • Property mode set to 100644
File size: 14.2 KB
Line 
1/*                               -*- Mode: C -*-
2 *
3 * CForall Lexer Version 1.0, Copyright (C) Peter A. Buhr 2001 -- Permission is granted to copy this
4 *      grammar and to use it within software systems.  THIS GRAMMAR IS PROVIDED "AS IS" AND WITHOUT
5 *      ANY EXPRESS OR IMPLIED WARRANTIES.
6 *
7 * lex.l --
8 *
9 * Author           : Peter A. Buhr
10 * Created On       : Sat Sep 22 08:58:10 2001
11 * Last Modified By : Peter A. Buhr
12 * Last Modified On : Wed Dec  3 13:37:52 2014
13 * Update Count     : 317
14 */
15
16%option yylineno
17
18%{
19// This lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor
20// directive have been performed and removed from the source. The only exceptions are preprocessor
21// directives passed to the compiler (e.g., line-number directives) and C/C++ style comments, which
22// are ignored.
23
24//**************************** Includes and Defines ****************************
25
26#include <string>
27
28#include "lex.h"
29#include "ParseNode.h"
30#include "cfa.tab.h" // YACC generated definitions based on C++ grammar
31
32char *yyfilename;
33std::string *strtext;                                   // accumulate parts of character and string constant value
34
35#define WHITE_RETURN(x)                                 // do nothing
36#define NEWLINE_RETURN()        WHITE_RETURN('\n')
37#define RETURN_VAL(x)           yylval.tok.str = new std::string(yytext); \
38                                yylval.tok.loc.file = yyfilename; \
39                                yylval.tok.loc.line = yylineno; \
40                                return(x)
41#define RETURN_STR(x)           yylval.tok.str = strtext; \
42                                yylval.tok.loc.file = yyfilename; \
43                                yylval.tok.loc.line = yylineno; \
44                                return(x)
45
46#define KEYWORD_RETURN(x)       RETURN_VAL(x)           // keyword
47#define IDENTIFIER_RETURN()     RETURN_VAL((typedefTable.isIdentifier(yytext) ? IDENTIFIER : typedefTable.isTypedef(yytext) ? TYPEDEFname : TYPEGENname))
48//#define ATTRIBUTE_RETURN()    RETURN_VAL((typedefTable.isIdentifier(yytext) ? ATTR_IDENTIFIER : typedefTable.isTypedef(yytext) ? ATTR_TYPEDEFname : ATTR_TYPEGENname))
49#define ATTRIBUTE_RETURN()      RETURN_VAL(ATTR_IDENTIFIER)
50
51#define ASCIIOP_RETURN()        RETURN_VAL((int)yytext[0]) // single character operator
52#define NAMEDOP_RETURN(x)       RETURN_VAL(x)           // multichar operator, with a name
53
54#define NUMERIC_RETURN(x)       rm_underscore(); RETURN_VAL(x) // numeric constant
55
56void rm_underscore() {
57    // remove underscores in numeric constant
58    int j = 0;
59    for ( int i = 0; yytext[i] != '\0'; i += 1 ) {
60        if ( yytext[i] != '_' ) {
61            yytext[j] = yytext[i];
62            j += 1;
63        } // if
64    } // for
65    yyleng = j;
66    yytext[yyleng] = '\0';
67}
68
69%}
70
71octal [0-7]
72nonzero [1-9]
73decimal [0-9]
74hex [0-9a-fA-F]
75universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2}))
76
77        // identifier, GCC: $ in identifier
78identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})*
79
80        // quoted identifier
81quoted_identifier "`"{identifier}"`"
82
83        // attribute identifier, GCC: $ in identifier
84attr_identifier "@"{identifier}
85
86        // numeric constants, CFA: '_' in constant
87hex_quad {hex}("_"?{hex}){3}
88integer_suffix "_"?(([uU][lL]?)|([uU]("ll"|"LL")?)|([lL][uU]?)|("ll"|"LL")[uU]?)
89
90octal_digits ({octal})|({octal}({octal}|"_")*{octal})
91octal_prefix "0""_"?
92octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix}?
93
94nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal})
95decimal_constant {nonzero_digits}{integer_suffix}?
96
97hex_digits ({hex})|({hex}({hex}|"_")*{hex})
98hex_prefix "0"[xX]"_"?
99hex_constant {hex_prefix}{hex_digits}{integer_suffix}?
100
101decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal})
102fractional_constant ({decimal_digits}?"."{decimal_digits})|({decimal_digits}".")
103exponent "_"?[eE]"_"?[+-]?{decimal_digits}
104floating_suffix "_"?[flFL]
105floating_constant (({fractional_constant}{exponent}?)|({decimal_digits}{exponent})){floating_suffix}?
106
107binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
108hex_fractional_constant ({hex_digits}?"."{hex_digits})|({hex_digits}".")
109hex_floating_constant {hex_prefix}(({hex_fractional_constant}{binary_exponent})|({hex_digits}{binary_exponent})){floating_suffix}?
110
111        // character escape sequence, GCC: \e => esc character
112simple_escape "\\"[abefnrtv'"?\\]
113        // ' stop highlighting
114octal_escape "\\"{octal}("_"?{octal}){0,2}
115hex_escape "\\""x""_"?{hex_digits}
116escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char}
117
118        // display/white-space characters
119h_tab [\011]
120form_feed [\014]
121v_tab [\013]
122c_return [\015]
123h_white [ ]|{h_tab}
124
125        // operators
126op_unary_only "~"|"!"
127op_unary_binary "+"|"-"|"*"
128op_unary_pre_post "++"|"--"
129op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post}
130
131op_binary_only "/"|"%"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"&="|"|="|"^="|"<<="|">>="
132op_binary_over {op_unary_binary}|{op_binary_only}
133op_binary_not_over "?"|"->"|"&&"|"||"
134operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over}
135
136%x COMMENT
137%x BKQUOTE
138%x QUOTE
139%x STRING
140
141%%
142        /* line directives */
143^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["][^\n]*"\n" {
144        /* " stop highlighting */
145        char *end_num;
146        char *begin_string, *end_string;
147        char *filename;
148        long lineno, length;
149        lineno = strtol( yytext + 1, &end_num, 0 );
150        begin_string = strchr( end_num, '"' );
151        if ( begin_string ) {
152            end_string = strchr( begin_string + 1, '"' );
153            if ( end_string ) {
154                length = end_string - begin_string - 1;
155                filename = new char[ length + 1 ];
156                memcpy( filename, begin_string + 1, length );
157                filename[ length ] = '\0';
158                //std::cout << "file " << filename << " line " << lineno << std::endl;
159                yylineno = lineno;
160                yyfilename = filename;
161            }
162        }
163}
164
165        /* ignore preprocessor directives (for now) */
166^{h_white}*"#"[^\n]*"\n" ;
167
168        /* ignore C style comments */
169"/*"                    { BEGIN COMMENT; }
170<COMMENT>.|\n           ;
171<COMMENT>"*/"           { BEGIN 0; }
172
173        /* ignore C++ style comments */
174"//"[^\n]*"\n"          ;
175
176        /* ignore whitespace */
177{h_white}+              { WHITE_RETURN(' '); }
178({v_tab}|{c_return}|{form_feed})+ { WHITE_RETURN(' '); }
179({h_white}|{v_tab}|{c_return}|{form_feed})*"\n" { NEWLINE_RETURN(); }
180
181        /* keywords */
182__alignof               { KEYWORD_RETURN(ALIGNOF); }    // GCC
183__alignof__             { KEYWORD_RETURN(ALIGNOF); }    // GCC
184asm                     { KEYWORD_RETURN(ASM); }
185__asm                   { KEYWORD_RETURN(ASM); }        // GCC
186__asm__                 { KEYWORD_RETURN(ASM); }        // GCC
187__attribute             { KEYWORD_RETURN(ATTRIBUTE); }  // GCC
188__attribute__           { KEYWORD_RETURN(ATTRIBUTE); }  // GCC
189auto                    { KEYWORD_RETURN(AUTO); }
190_Bool                   { KEYWORD_RETURN(BOOL); }       // C99
191break                   { KEYWORD_RETURN(BREAK); }
192case                    { KEYWORD_RETURN(CASE); }
193catch                   { KEYWORD_RETURN(CATCH); }      // CFA
194char                    { KEYWORD_RETURN(CHAR); }
195choose                  { KEYWORD_RETURN(CHOOSE); }     // CFA
196_Complex                { KEYWORD_RETURN(COMPLEX); }    // C99
197__complex               { KEYWORD_RETURN(COMPLEX); }    // GCC
198__complex__             { KEYWORD_RETURN(COMPLEX); }    // GCC
199const                   { KEYWORD_RETURN(CONST); }
200__const                 { KEYWORD_RETURN(CONST); }      // GCC
201__const__               { KEYWORD_RETURN(CONST); }      // GCC
202context                 { KEYWORD_RETURN(CONTEXT); }    // CFA
203continue                { KEYWORD_RETURN(CONTINUE); }
204default                 { KEYWORD_RETURN(DEFAULT); }
205do                      { KEYWORD_RETURN(DO); }
206double                  { KEYWORD_RETURN(DOUBLE); }
207dtype                   { KEYWORD_RETURN(DTYPE); }      // CFA
208else                    { KEYWORD_RETURN(ELSE); }
209enum                    { KEYWORD_RETURN(ENUM); }
210__extension__           { KEYWORD_RETURN(EXTENSION); }  // GCC
211extern                  { KEYWORD_RETURN(EXTERN); }
212fallthru                { KEYWORD_RETURN(FALLTHRU); }   // CFA
213finally                 { KEYWORD_RETURN(FINALLY); }    // CFA
214float                   { KEYWORD_RETURN(FLOAT); }
215for                     { KEYWORD_RETURN(FOR); }
216forall                  { KEYWORD_RETURN(FORALL); }     // CFA
217fortran                 { KEYWORD_RETURN(FORTRAN); }
218ftype                   { KEYWORD_RETURN(FTYPE); }      // CFA
219goto                    { KEYWORD_RETURN(GOTO); }
220if                      { KEYWORD_RETURN(IF); }
221_Imaginary              { KEYWORD_RETURN(IMAGINARY); }  // C99
222__imag                  { KEYWORD_RETURN(IMAGINARY); }  // GCC
223__imag__                { KEYWORD_RETURN(IMAGINARY); }  // GCC
224inline                  { KEYWORD_RETURN(INLINE); }     // C99
225__inline                { KEYWORD_RETURN(INLINE); }     // GCC
226__inline__              { KEYWORD_RETURN(INLINE); }     // GCC
227int                     { KEYWORD_RETURN(INT); }
228__label__               { KEYWORD_RETURN(LABEL); }      // GCC
229long                    { KEYWORD_RETURN(LONG); }
230lvalue                  { KEYWORD_RETURN(LVALUE); }     // CFA
231register                { KEYWORD_RETURN(REGISTER); }
232restrict                { KEYWORD_RETURN(RESTRICT); }   // C99
233__restrict              { KEYWORD_RETURN(RESTRICT); }   // GCC
234__restrict__            { KEYWORD_RETURN(RESTRICT); }   // GCC
235return                  { KEYWORD_RETURN(RETURN); }
236short                   { KEYWORD_RETURN(SHORT); }
237signed                  { KEYWORD_RETURN(SIGNED); }
238__signed                { KEYWORD_RETURN(SIGNED); }     // GCC
239__signed__              { KEYWORD_RETURN(SIGNED); }     // GCC
240sizeof                  { KEYWORD_RETURN(SIZEOF); }
241static                  { KEYWORD_RETURN(STATIC); }
242struct                  { KEYWORD_RETURN(STRUCT); }
243switch                  { KEYWORD_RETURN(SWITCH); }
244throw                   { KEYWORD_RETURN(THROW); }      // CFA
245try                     { KEYWORD_RETURN(TRY); }        // CFA
246type                    { KEYWORD_RETURN(TYPE); }       // CFA
247typedef                 { KEYWORD_RETURN(TYPEDEF); }
248typeof                  { KEYWORD_RETURN(TYPEOF); }     // GCC
249__typeof                { KEYWORD_RETURN(TYPEOF); }     // GCC
250__typeof__              { KEYWORD_RETURN(TYPEOF); }     // GCC
251union                   { KEYWORD_RETURN(UNION); }
252unsigned                { KEYWORD_RETURN(UNSIGNED); }
253void                    { KEYWORD_RETURN(VOID); }
254volatile                { KEYWORD_RETURN(VOLATILE); }
255__volatile              { KEYWORD_RETURN(VOLATILE); }   // GCC
256__volatile__            { KEYWORD_RETURN(VOLATILE); }   // GCC
257while                   { KEYWORD_RETURN(WHILE); }
258
259        /* identifier */
260{identifier}            { IDENTIFIER_RETURN(); }
261{attr_identifier}       { ATTRIBUTE_RETURN(); }
262"`"                     { BEGIN BKQUOTE; }
263<BKQUOTE>{identifier}   { IDENTIFIER_RETURN(); }
264<BKQUOTE>"`"            { BEGIN 0; }
265
266        /* numeric constants */
267"0"                     { NUMERIC_RETURN(ZERO); }       // CFA
268"1"                     { NUMERIC_RETURN(ONE); }        // CFA
269{decimal_constant}      { NUMERIC_RETURN(INTEGERconstant); }
270{octal_constant}        { NUMERIC_RETURN(INTEGERconstant); }
271{hex_constant}          { NUMERIC_RETURN(INTEGERconstant); }
272{floating_constant}     { NUMERIC_RETURN(FLOATINGconstant); }
273{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
274
275        /* character constant, allows empty value */
276"L"?"_"?[']             { BEGIN QUOTE; rm_underscore(); strtext = new std::string; *strtext += std::string( yytext ); }
277<QUOTE>[^'\\\n]*        { *strtext += std::string( yytext ); }
278<QUOTE>['\n]            { BEGIN 0; *strtext += std::string( yytext); RETURN_STR(CHARACTERconstant); }
279        /* ' stop highlighting */
280
281        /* string constant */
282"L"?"_"?["]             { BEGIN STRING; rm_underscore(); strtext = new std::string; *strtext += std::string( yytext ); }
283<STRING>[^"\\\n]*       { *strtext += std::string( yytext ); }
284<STRING>["\n]           { BEGIN 0; *strtext += std::string( yytext); RETURN_STR(STRINGliteral); }
285        /* " stop highlighting */
286
287<QUOTE,STRING>{escape_seq} { rm_underscore(); *strtext += std::string( yytext ); }
288<QUOTE,STRING>[\\]      { *strtext += std::string( yytext ); } // unknown escape character
289
290        /* punctuation */
291"["                     { ASCIIOP_RETURN(); }
292"]"                     { ASCIIOP_RETURN(); }
293"("                     { ASCIIOP_RETURN(); }
294")"                     { ASCIIOP_RETURN(); }
295"{"                     { ASCIIOP_RETURN(); }
296"}"                     { ASCIIOP_RETURN(); }
297","                     { ASCIIOP_RETURN(); }           // also operator
298":"                     { ASCIIOP_RETURN(); }
299";"                     { ASCIIOP_RETURN(); }
300"."                     { ASCIIOP_RETURN(); }           // also operator
301"..."                   { NAMEDOP_RETURN(ELLIPSIS); }
302
303        /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
304"<:"                    { RETURN_VAL('['); }
305":>"                    { RETURN_VAL(']'); }
306"<%"                    { RETURN_VAL('{'); }
307"%>"                    { RETURN_VAL('}'); }
308
309        /* operators */
310"!"                     { ASCIIOP_RETURN(); }
311"+"                     { ASCIIOP_RETURN(); }
312"-"                     { ASCIIOP_RETURN(); }
313"*"                     { ASCIIOP_RETURN(); }
314"/"                     { ASCIIOP_RETURN(); }
315"%"                     { ASCIIOP_RETURN(); }
316"^"                     { ASCIIOP_RETURN(); }
317"~"                     { ASCIIOP_RETURN(); }
318"&"                     { ASCIIOP_RETURN(); }
319"|"                     { ASCIIOP_RETURN(); }
320"<"                     { ASCIIOP_RETURN(); }
321">"                     { ASCIIOP_RETURN(); }
322"="                     { ASCIIOP_RETURN(); }
323"?"                     { ASCIIOP_RETURN(); }
324
325"++"                    { NAMEDOP_RETURN(ICR); }
326"--"                    { NAMEDOP_RETURN(DECR); }
327"=="                    { NAMEDOP_RETURN(EQ); }
328"!="                    { NAMEDOP_RETURN(NE); }
329"<<"                    { NAMEDOP_RETURN(LS); }
330">>"                    { NAMEDOP_RETURN(RS); }
331"<="                    { NAMEDOP_RETURN(LE); }
332">="                    { NAMEDOP_RETURN(GE); }
333"&&"                    { NAMEDOP_RETURN(ANDAND); }
334"||"                    { NAMEDOP_RETURN(OROR); }
335"->"                    { NAMEDOP_RETURN(ARROW); }
336"+="                    { NAMEDOP_RETURN(PLUSassign); }
337"-="                    { NAMEDOP_RETURN(MINUSassign); }
338"*="                    { NAMEDOP_RETURN(MULTassign); }
339"/="                    { NAMEDOP_RETURN(DIVassign); }
340"%="                    { NAMEDOP_RETURN(MODassign); }
341"&="                    { NAMEDOP_RETURN(ANDassign); }
342"|="                    { NAMEDOP_RETURN(ORassign); }
343"^="                    { NAMEDOP_RETURN(ERassign); }
344"<<="                   { NAMEDOP_RETURN(LSassign); }
345">>="                   { NAMEDOP_RETURN(RSassign); }
346
347        /* CFA, operator identifier */
348{op_unary}"?"           { IDENTIFIER_RETURN(); }        // unary
349"?"({op_unary_pre_post}|"()"|"[?]") { IDENTIFIER_RETURN(); }
350"?"{op_binary_over}"?"  { IDENTIFIER_RETURN(); }        // binary
351        /*
352          This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the
353          string "*?*?"  can be lexed as "*"/"?*?" or "*?"/"*?". Since it is common practise to put
354          a unary operator juxtaposed to an identifier, e.g., "*i", users will be annoyed if they
355          cannot do this with respect to operator identifiers. Even with this special hack, there
356          are 5 general cases that cannot be handled. The first case is for the function-call
357          identifier "?()":
358
359          int * ?()();  // declaration: space required after '*'
360          * ?()();      // expression: space required after '*'
361
362          Without the space, the string "*?()" is ambiguous without N character look ahead; it
363          requires scanning ahead to determine if there is a '(', which is the start of an
364          argument/parameter list.
365
366          The 4 remaining cases occur in expressions:
367
368          i++?i:0;              // space required before '?'
369          i--?i:0;              // space required before '?'
370          i?++i:0;              // space required after '?'
371          i?--i:0;              // space required after '?'
372
373          In the first two cases, the string "i++?" is ambiguous, where this string can be lexed as
374          "i"/"++?" or "i++"/"?"; it requires scanning ahead to determine if there is a '(', which
375          is the start of an argument list.  In the second two cases, the string "?++x" is
376          ambiguous, where this string can be lexed as "?++"/"x" or "?"/"++x"; it requires scanning
377          ahead to determine if there is a '(', which is the start of an argument list.
378        */
379{op_unary}"?"(({op_unary_pre_post}|"[?]")|({op_binary_over}"?")) {
380                            // 1 or 2 character unary operator ?
381                            int i = yytext[1] == '?' ? 1 : 2;
382                            yyless( i );                // put back characters up to first '?'
383                            if ( i > 1 ) {
384                                NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
385                            } else {
386                                ASCIIOP_RETURN();
387                            } // if
388                        }
389
390        /* unknown characters */
391.                       { printf("unknown character(s):\"%s\" on line %d\n", yytext, yylineno); }
392
393%%
394
395
396// Local Variables:
397// fill-column: 100
398// compile-command: "make"
399// End:
Note: See TracBrowser for help on using the repository browser.