source: tests/concurrent/waituntil/chan-and.cfa@ 2d831a1

#include <select.hfa>
#include <thread.hfa>
#include <channel.hfa>

channel(long long int) A, B, C;

volatile bool done = false;
long long int globalTotal = 0;

thread Server1 {};
void main( Server1 & this ) {
    long long int a, b, c, i = 0, myTotal = 0;
    bool isDone = false;
    for( ; !isDone; i++ ) {
        waituntil( a << A ) { myTotal += a; }
        and waituntil( b << B ) { myTotal += b; }
        and waituntil( c << C ) { if ( c == -1 ) { isDone = true; } else myTotal += c; } // C_TODO fix breaks inside waituntils
        or else {}
    }
    __atomic_fetch_add( &globalTotal, myTotal, __ATOMIC_SEQ_CST );
}

size_t numtimes = 100000;
size_t numServers = 1;
int main( int argc, char * argv[] ) {
    if ( argc == 2 )
        numtimes = atoi( argv[1] );

    processor p[numServers];
    A{5};
    B{5};
    C{5};

    long long int total = 0;
    printf("start\n");
    {
        Server1 s[numServers];
        for( long long int j = 0; j < numtimes; j++ ) {
            waituntil( j >> A ) { total += j; }
            and waituntil( j >> B ) { total += j; }
            and waituntil( j >> C ) { total += j; }
        }
        printf("waiting for empty channels\n");
        size_t A_count = get_count( A );
        size_t B_count = get_count( B );
        size_t C_count = get_count( C );
        while( A_count > 0 || B_count > 0 || C_count > 0 ) { 
            A_count = get_count( A );
            B_count = get_count( B );
            C_count = get_count( C );
        }
        printf("sending sentinels\n");
        for ( i; numServers ) {
            insert( A, 0 );
            insert( B, 0 );
            insert( C, -1 );
        }
        printf("joining servers\n");
    }
    if ( total != globalTotal ) 
        printf("CHECKSUM MISMATCH!! Main thread got %lld, server sum is %lld\n", total, globalTotal);
    printf("done\n");
}