source: tests/collections/sequence.cfa @ 4c19647

#include <fstream.hfa>
#include <stdlib.hfa>                                                                   // new, delete
#include <bits/sequence.hfa>

int main() {
        // Fred test

        struct Fred {
                inline Seqable;                                                                 // Plan 9 inheritance
                int i;
        };
        void ?{}( Fred & fred ) { abort(); }
        void ?{}( Fred & fred, int p ) with( fred ) {
                i = p;
        }

        Fred *& Back( Fred * n ) {
                return (Fred *)Back( (Seqable *)n );
        }

        Fred *& Next( Fred * n ) {
                return (Fred *)Next( (Colable *)n );
        }

        Sequence(Fred) fred;
        SeqIter(Fred) fredIter = { fred };
        Fred & f;

        sout | nlOff;                                                                           // turn off auto newline

        for ( ; fredIter >> f; ) {                                                      // empty list
                sout | f.i | ' ';
        }
        sout | "empty" | nl;
        
        for ( i; 10 ) {
                add( fred, *new( 2 * i ) );
        }

        for ( SeqIter(Fred) iter = { fred }; iter >> f; ) {
                sout | f.i | ' ';
        }
        sout | nl;

        for ( i; 9 ) {
                delete( &dropHead( fred ) );
        }

        for ( over( fredIter, fred ); fredIter >> f; ) {
                sout | f.i | ' ';
        }
        sout | nl;
        
        for ( i; 10 ) {
                addTail( fred, *new( 2 * i + 1 ) );
        }
        for ( over( fredIter, fred ); fredIter >> f; ) {
                sout | f.i | ' ';
        }
        sout | nl;

        for ( i; 9 ) {
                delete( &dropTail( fred ) );
        }
        for ( over( fredIter, fred ); fredIter >> f; ) {
                sout | f.i | ' ';
        }
        sout | nl;

        for ( over( fredIter, fred ); fredIter >> f; ) {
                delete( &f );
        }

        Sequence(Fred) fred0;
        Fred * middle;
        for ( i; 10 ) {
                if( i == 5) {
                        middle = new( i );
                        addHead( fred0, *middle );
                        continue;
                }
                addHead( fred0, *new( i ) );
        }

        for ( SeqIterRev(Fred) iter = { fred0 }; iter >> f; ) {
                sout | f.i | ' ';
        }
        sout | nl;

        Fred * front = new( -1 );
        insertBef( fred0, *front, tail(fred0));
        insertAft( fred0, *front, *new( -2 ) );
        remove( fred0, *front );
        delete( front );

        sout | head(fred0).i | nl;
        Fred & end = dropTail( fred );
        delete( &end );

        for ( over( fredIter, fred0 ); fredIter >> f; ) {
                sout | f.i | ' ';
        }
        sout | nl;

        Sequence(Fred) fred2;

        split( fred2, fred0, *middle);

        for ( over( fredIter, fred0 ); fredIter >> f; ) {
                sout | f.i | ' ';
        }
        sout | nl;

        for ( over( fredIter, fred2 ); fredIter >> f; ) {
                sout | f.i | ' ';
        }
        sout | nl;

        transfer( fred0, fred2);

        for ( over( fredIter, fred0 ); fredIter >> f; ) {
                sout | f.i | ' ';
        }
        sout | nl;

        for ( over( fredIter, fred0 ); fredIter >> f; ) {
                delete( &f );
        }

        // Mary test

        struct Mary {
                inline Fred;                                                                    // Plan 9 inheritance
                int j;
        };
        void ?{}( Mary & mary ) { abort(); }
        void ?{}( Mary & mary, int p ) with( mary ) {
                ((Fred &)mary){ p };
                j = p;
        }

        Mary *& Back( Mary * n ) {
                return (Mary *)Back( (Fred *)n );
        }

        Mary *& Next( Mary * n ) {
                return (Mary *)Next( (Fred *)n );
        }

        Sequence(Mary) mary;
        Sequence(Mary) baz;
        SeqIter(Mary) maryIter = { mary };
        Mary & m;

        for ( ; maryIter >> m; ) {                                                      // empty list
                sout | m.i | m.j | ' ';
        }
        sout | "empty" | nl;
        
        for ( i; 10 ) {
                add( mary, *new( 2 * i ) );
                add( baz, *new( 2 * i ) );
        }

        for ( SeqIter(Mary) iter = { mary }; iter >> m; ) {
                sout | m.i | m.j | ' ';
        }
        sout | nl;
        
        for ( i; 9 ) {
                delete( &dropHead( mary ) );
        }

        for ( over( maryIter, mary ); maryIter >> m; ) {
                sout | m.i | m.j | ' ';
        }
        sout | nl;
        
        for ( i; 10 ) {
                addTail( mary, *new( 2 * i + 1 ) );
        }
        for ( over( maryIter, mary ); maryIter >> m; ) {
                sout | m.i | m.j | ' ';
        }
        sout | nl;

        for ( i; 9 ) {
                delete( &dropTail( mary ) );
        }
        for ( over( maryIter, mary ); maryIter >> m; ) {
                sout | m.i | m.j | ' ';
        }
        sout | nl;

        transfer( mary, baz );

        for ( over( maryIter, baz ); maryIter >> m; ) {
                sout | m.i | m.j | ' ';
        }
        sout | "empty" | nl;

        for ( over( maryIter, mary ); maryIter >> m; ) {
                sout | m.i | m.j | ' ';
        }
        sout | nl;

        for ( over( maryIter, mary ); maryIter >> m; ) {
                delete( &m );
        }
}