source: src/Parser/parser.yy@ f93d7fc

ADT ast-experimental enum forall-pointer-decay jacob/cs343-translation pthread-emulation qualifiedEnum
Last change on this file since f93d7fc was 8a1d95af, checked in by Peter A. Buhr <pabuhr@…>, 4 years ago

Merge branch 'master' of plg.uwaterloo.ca:software/cfa/cfa-cc
  • Property mode set to 100644
File size: 145.4 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author : Peter A. Buhr
10// Created On : Sat Sep 1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Sun Aug 8 09:14:44 2021
13// Update Count : 5038
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS. While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks. Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// designation with '=' (use ':' instead)
29//
30// This incompatibility is discussed in detail before the "designation" grammar rule. Most of the syntactic extensions
31// from ANSI90 to ANSI11 C are marked with the comment "C99/C11".
32
33// This grammar also has two levels of extensions. The first extensions cover most of the GCC C extensions All of the
34// syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall (CFA), which
35// fixes several of C's outstanding problems and extends C with many modern language concepts. All of the syntactic
36// extensions for CFA C are marked with the comment "CFA".
37
38%{
39#define YYDEBUG_LEXER_TEXT( yylval ) // lexer loads this up each time
40#define YYDEBUG 1 // get the pretty debugging code to compile
41#define YYERROR_VERBOSE // more information in syntax errors
42
43#undef __GNUC_MINOR__
44
45#include <cstdio>
46#include <stack>
47using namespace std;
48
49#include "SynTree/Declaration.h"
50#include "ParseNode.h"
51#include "TypedefTable.h"
52#include "TypeData.h"
53#include "SynTree/LinkageSpec.h"
54#include "Common/SemanticError.h" // error_str
55#include "Common/utility.h" // for maybeMoveBuild, maybeBuild, CodeLo...
56
57extern DeclarationNode * parseTree;
58extern LinkageSpec::Spec linkage;
59extern TypedefTable typedefTable;
60
61stack<LinkageSpec::Spec> linkageStack;
62
63bool appendStr( string & to, string & from ) {
64 // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
65 // "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
66 // the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
67 // easier to let the C compiler handle this case.
68 //
69 // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
70 // without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
71 // i.e., u"a" U"b" L"c" is disallowed.
72
73 if ( from[0] != '"' ) { // encoding ?
74 if ( to[0] != '"' ) { // encoding ?
75 if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
76 yyerror( "non-matching string encodings for string-literal concatenation" );
77 return false; // parse error, must call YYERROR in action
78 } else if ( from[1] == '8' ) {
79 from.erase( 0, 1 ); // remove 2nd encoding
80 } // if
81 } else {
82 if ( from[1] == '8' ) { // move encoding to start
83 to = "u8" + to;
84 from.erase( 0, 1 ); // remove 2nd encoding
85 } else {
86 to = from[0] + to;
87 } // if
88 } // if
89 from.erase( 0, 1 ); // remove 2nd encoding
90 } // if
91 to += " " + from; // concatenated into single string
92 return true;
93} // appendStr
94
95DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
96 // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
97 DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
98 for ( cur = dynamic_cast<DeclarationNode *>( cur->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode *>( cur->get_next() ) ) {
99 cl->cloneBaseType( cur );
100 } // for
101 declList->addType( cl );
102 return declList;
103} // distAttr
104
105void distExt( DeclarationNode * declaration ) {
106 // distribute EXTENSION across all declarations
107 for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
108 iter->set_extension( true );
109 } // for
110} // distExt
111
112void distInl( DeclarationNode * declaration ) {
113 // distribute EXTENSION across all declarations
114 for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
115 iter->set_inLine( true );
116 } // for
117} // distInl
118
119void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
120 // distribute qualifiers across all non-variable declarations in a distribution statemement
121 for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
122 // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
123 // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
124 // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
125 // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
126 DeclarationNode * clone = qualifiers->clone();
127 if ( qualifiers->type ) { // forall clause ? (handles SC)
128 if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
129 swap( clone->type->forall, iter->type->aggregate.params );
130 iter->addQualifiers( clone );
131 } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
132 // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
133 DeclarationNode newnode;
134 swap( newnode.type, iter->type->aggInst.aggregate );
135 swap( clone->type->forall, newnode.type->aggregate.params );
136 newnode.addQualifiers( clone );
137 swap( newnode.type, iter->type->aggInst.aggregate );
138 } else if ( iter->type->kind == TypeData::Function ) { // routines ?
139 swap( clone->type->forall, iter->type->forall );
140 iter->addQualifiers( clone );
141 } // if
142 } else { // just SC qualifiers
143 iter->addQualifiers( clone );
144 } // if
145 } // for
146 delete qualifiers;
147} // distQual
148
149// There is an ambiguity for inline generic-routine return-types and generic routines.
150// forall( otype T ) struct S { int i; } bar( T ) {}
151// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
152// forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
153// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
154// forall( otype T ) struct S { int T; };
155// forall( otype W ) bar( W ) {}
156
157void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
158 if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
159 funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
160 declSpec->type->aggregate.params = nullptr;
161 } // if
162} // rebindForall
163
164string * build_postfix_name( string * name ) {
165 *name = string("__postfix_func_") + *name;
166 return name;
167} // build_postfix_name
168
169DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
170 if ( ! fieldList ) { // field declarator ?
171 if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate || typeSpec->type->kind == TypeData::Enum) ) ) {
172 stringstream ss;
173 typeSpec->type->print( ss );
174 SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
175 return nullptr;
176 } // if
177 fieldList = DeclarationNode::newName( nullptr );
178 } // if
179 return distAttr( typeSpec, fieldList ); // mark all fields in list
180} // fieldDecl
181
182ForCtrl * forCtrl( ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
183 ConstantExpr * constant = dynamic_cast<ConstantExpr *>(type->expr.get());
184 if ( constant && (constant->get_constant()->get_value() == "0" || constant->get_constant()->get_value() == "1") ) {
185 type = new ExpressionNode( new CastExpr( maybeMoveBuild<Expression>(type), new BasicType( Type::Qualifiers(), BasicType::SignedInt ) ) );
186 } // if
187// type = new ExpressionNode( build_func( new ExpressionNode( build_varref( new string( "__for_control_index_constraints__" ) ) ), type ) );
188 return new ForCtrl(
189 distAttr( DeclarationNode::newTypeof( type, true ), DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) ) ),
190 // NULL comp/inc => leave blank
191 comp ? new ExpressionNode( build_binary_val( compop, new ExpressionNode( build_varref( new string( *index ) ) ), comp ) ) : 0,
192 inc ? new ExpressionNode( build_binary_val( compop == OperKinds::LThan || compop == OperKinds::LEThan ? // choose += or -= for upto/downto
193 OperKinds::PlusAssn : OperKinds::MinusAssn, new ExpressionNode( build_varref( new string( *index ) ) ), inc ) ) : 0 );
194} // forCtrl
195
196ForCtrl * forCtrl( ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
197 if ( NameExpr * identifier = dynamic_cast<NameExpr *>(index->expr.get()) ) {
198 return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
199 } else if ( CommaExpr * commaExpr = dynamic_cast<CommaExpr *>(index->expr.get()) ) {
200 if ( NameExpr * identifier = dynamic_cast<NameExpr *>(commaExpr->arg1 ) ) {
201 return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
202 } else {
203 SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed." ); return nullptr;
204 } // if
205 } else {
206 SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed." ); return nullptr;
207 } // if
208} // forCtrl
209
210bool forall = false; // aggregate have one or more forall qualifiers ?
211
212// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
213#define YYLLOC_DEFAULT(Cur, Rhs, N) \
214if ( N ) { \
215 (Cur).first_line = YYRHSLOC( Rhs, 1 ).first_line; \
216 (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column; \
217 (Cur).last_line = YYRHSLOC( Rhs, N ).last_line; \
218 (Cur).last_column = YYRHSLOC( Rhs, N ).last_column; \
219 (Cur).filename = YYRHSLOC( Rhs, 1 ).filename; \
220} else { \
221 (Cur).first_line = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line; \
222 (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column; \
223 (Cur).filename = YYRHSLOC( Rhs, 0 ).filename; \
224}
225%}
226
227%define parse.error verbose
228
229// Types declaration for productions
230%union {
231 Token tok;
232 ParseNode * pn;
233 ExpressionNode * en;
234 DeclarationNode * decl;
235 AggregateDecl::Aggregate aggKey;
236 TypeDecl::Kind tclass;
237 StatementNode * sn;
238 WaitForStmt * wfs;
239 Expression * constant;
240 IfCtrl * ifctl;
241 ForCtrl * fctl;
242 enum OperKinds compop;
243 LabelNode * label;
244 InitializerNode * in;
245 OperKinds op;
246 std::string * str;
247 bool flag;
248 CatchStmt::Kind catch_kind;
249 GenericExpr * genexpr;
250}
251
252//************************* TERMINAL TOKENS ********************************
253
254// keywords
255%token TYPEDEF
256%token EXTERN STATIC AUTO REGISTER
257%token THREADLOCAL // C11
258%token INLINE FORTRAN // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
259%token NORETURN // C11
260%token CONST VOLATILE
261%token RESTRICT // C99
262%token ATOMIC // C11
263%token FORALL MUTEX VIRTUAL VTABLE COERCE // CFA
264%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
265%token BOOL COMPLEX IMAGINARY // C99
266%token INT128 UINT128 uuFLOAT80 uuFLOAT128 // GCC
267%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
268%token DECIMAL32 DECIMAL64 DECIMAL128 // GCC
269%token ZERO_T ONE_T // CFA
270%token SIZEOF TYPEOF VALIST AUTO_TYPE // GCC
271%token OFFSETOF BASETYPEOF TYPEID // CFA
272%token ENUM STRUCT UNION
273%token EXCEPTION // CFA
274%token GENERATOR COROUTINE MONITOR THREAD // CFA
275%token OTYPE FTYPE DTYPE TTYPE TRAIT // CFA
276// %token RESUME // CFA
277%token LABEL // GCC
278%token SUSPEND // CFA
279%token ATTRIBUTE EXTENSION // GCC
280%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
281%token CHOOSE FALLTHRU FALLTHROUGH WITH WHEN WAITFOR // CFA
282%token DISABLE ENABLE TRY THROW THROWRESUME AT // CFA
283%token ASM // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
284%token ALIGNAS ALIGNOF GENERIC STATICASSERT // C11
285
286// names and constants: lexer differentiates between identifier and typedef names
287%token<tok> IDENTIFIER QUOTED_IDENTIFIER TYPEDIMname TYPEDEFname TYPEGENname
288%token<tok> TIMEOUT WOR CATCH RECOVER CATCHRESUME FIXUP FINALLY // CFA
289%token<tok> INTEGERconstant CHARACTERconstant STRINGliteral
290%token<tok> DIRECTIVE
291// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
292// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
293// converted into the tuple index (.)(1). e.g., 3.x
294%token<tok> FLOATING_DECIMALconstant FLOATING_FRACTIONconstant FLOATINGconstant
295
296// multi-character operators
297%token ARROW // ->
298%token ICR DECR // ++ --
299%token LS RS // << >>
300%token LE GE EQ NE // <= >= == !=
301%token ANDAND OROR // && ||
302%token ELLIPSIS // ...
303
304%token EXPassign MULTassign DIVassign MODassign // \= *= /= %=
305%token PLUSassign MINUSassign // += -=
306%token LSassign RSassign // <<= >>=
307%token ANDassign ERassign ORassign // &= ^= |=
308
309%token ErangeUpEq ErangeDown ErangeDownEq // ~= -~ -~=
310%token ATassign // @=
311
312%type<tok> identifier
313%type<tok> identifier_or_type_name attr_name
314%type<tok> quasi_keyword
315%type<constant> string_literal
316%type<str> string_literal_list
317
318// expressions
319%type<en> constant
320%type<en> tuple tuple_expression_list
321%type<op> ptrref_operator unary_operator assignment_operator simple_assignment_operator compound_assignment_operator
322%type<en> primary_expression postfix_expression unary_expression
323%type<en> cast_expression_list cast_expression exponential_expression multiplicative_expression additive_expression
324%type<en> shift_expression relational_expression equality_expression
325%type<en> AND_expression exclusive_OR_expression inclusive_OR_expression
326%type<en> logical_AND_expression logical_OR_expression
327%type<en> conditional_expression constant_expression assignment_expression assignment_expression_opt
328%type<en> comma_expression comma_expression_opt
329%type<en> argument_expression_list_opt argument_expression default_initializer_opt
330%type<ifctl> if_control_expression
331%type<fctl> for_control_expression for_control_expression_list
332%type<compop> inclexcl
333%type<en> subrange
334%type<decl> asm_name_opt
335%type<en> asm_operands_opt asm_operands_list asm_operand
336%type<label> label_list
337%type<en> asm_clobbers_list_opt
338%type<flag> asm_volatile_opt
339%type<en> handler_predicate_opt
340%type<genexpr> generic_association generic_assoc_list
341
342// statements
343%type<sn> statement labeled_statement compound_statement
344%type<sn> statement_decl statement_decl_list statement_list_nodecl
345%type<sn> selection_statement if_statement
346%type<sn> switch_clause_list_opt switch_clause_list
347%type<en> case_value
348%type<sn> case_clause case_value_list case_label case_label_list
349%type<sn> iteration_statement jump_statement
350%type<sn> expression_statement asm_statement
351%type<sn> with_statement
352%type<en> with_clause_opt
353%type<sn> exception_statement handler_clause finally_clause
354%type<catch_kind> handler_key
355%type<sn> mutex_statement
356%type<en> when_clause when_clause_opt waitfor timeout
357%type<sn> waitfor_statement
358%type<wfs> waitfor_clause
359
360// declarations
361%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
362%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
363%type<decl> abstract_parameter_declaration
364
365%type<aggKey> aggregate_key aggregate_data aggregate_control
366%type<decl> aggregate_type aggregate_type_nobody
367
368%type<decl> assertion assertion_list assertion_list_opt
369
370%type<en> bit_subrange_size_opt bit_subrange_size
371
372%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
373%type<decl> vtable vtable_opt default_opt
374
375%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
376
377%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
378%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
379
380%type<decl> elaborated_type elaborated_type_nobody
381
382%type<decl> enumerator_list enum_type enum_type_nobody
383%type<en> enumerator_value_opt
384
385%type<decl> external_definition external_definition_list external_definition_list_opt
386
387%type<decl> exception_declaration
388
389%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
390%type<en> field field_name_list field_name fraction_constants_opt
391
392%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
393
394%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
395%type<decl> identifier_list
396
397%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
398%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
399%type<decl> cfa_abstract_ptr cfa_abstract_tuple
400
401%type<decl> cfa_array_parameter_1st_dimension
402
403%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
404%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
405
406%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
407%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
408
409%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
410
411%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
412
413%type<decl> c_declaration static_assert
414%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
415%type<decl> KR_parameter_list KR_parameter_list_opt
416
417%type<decl> parameter_declaration parameter_list parameter_type_list_opt
418
419%type<decl> paren_identifier paren_type
420
421%type<decl> storage_class storage_class_list
422
423%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
424
425%type<tclass> type_class new_type_class
426%type<decl> type_declarator type_declarator_name type_declaring_list
427
428%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
429%type<decl> typedef_name typedef_declaration typedef_expression
430
431%type<decl> variable_type_redeclarator type_ptr type_array type_function
432
433%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
434
435%type<decl> type type_no_function
436%type<decl> type_parameter type_parameter_list type_initializer_opt
437
438%type<en> type_parameters_opt type_list
439
440%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
441%type<decl> type_specifier type_specifier_nobody
442
443%type<decl> variable_declarator variable_ptr variable_array variable_function
444%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
445
446%type<decl> attribute_list_opt attribute_list attribute attribute_name_list attribute_name
447
448// initializers
449%type<in> initializer initializer_list_opt initializer_opt
450
451// designators
452%type<en> designator designator_list designation
453
454
455// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
456// .---------. matches IF '(' comma_expression ')' statement . (reduce)
457// if ( C ) S1 else S2
458// `-----------------' matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
459// Similar issues exit with the waitfor statement.
460
461// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
462// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
463%precedence THEN // rule precedence for IF/WAITFOR statement
464%precedence WOR // token precedence for start of WOR in WAITFOR statement
465%precedence TIMEOUT // token precedence for start of TIMEOUT in WAITFOR statement
466%precedence CATCH // token precedence for start of TIMEOUT in WAITFOR statement
467%precedence RECOVER // token precedence for start of TIMEOUT in WAITFOR statement
468%precedence CATCHRESUME // token precedence for start of TIMEOUT in WAITFOR statement
469%precedence FIXUP // token precedence for start of TIMEOUT in WAITFOR statement
470%precedence FINALLY // token precedence for start of TIMEOUT in WAITFOR statement
471%precedence ELSE // token precedence for start of else clause in IF/WAITFOR statement
472
473
474// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
475// forall( otype T ) struct Foo { T v; };
476// .-----. matches pointer to function returning a generic (which is impossible without a type)
477// Foo ( *fp )( int );
478// `---' matches start of TYPEGENname '('
479// must be:
480// Foo( int ) ( *fp )( int );
481// The same problem occurs here:
482// forall( otype T ) struct Foo { T v; } ( *fp )( int );
483// must be:
484// forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
485
486// Order of these lines matters (low-to-high precedence).
487%precedence TYPEGENname
488%precedence '}'
489%precedence '('
490
491// %precedence RESUME
492// %precedence '{'
493// %precedence ')'
494
495%locations // support location tracking for error messages
496
497%start translation_unit // parse-tree root
498
499%%
500//************************* Namespace Management ********************************
501
502// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
503// which are lexically identical.
504//
505// typedef int foo; // identifier foo must now be scanned as TYPEDEFname
506// foo f; // to allow it to appear in this context
507//
508// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
509// between syntactic and semantic constructs. Cforall compounds this problem by introducing type names local to the
510// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
511// generators" -- parameterized types. This latter type name creates a third class of identifiers, "TYPEGENname", which
512// must be distinguished by the lexical scanner.
513//
514// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
515// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
516// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
517// each context that introduces a name scope, a new level is created in the type table and that level is popped on
518// exiting the scope. Since type names can be local to a particular declaration, each declaration is itself a scope.
519// This requires distinguishing between type names that are local to the current declaration scope and those that
520// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
521//
522// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
523// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
524// around the list separator.
525//
526// int f( forall(T) T (*f1) T , forall( S ) S (*f2)( S ) );
527// push pop push pop
528
529push:
530 { typedefTable.enterScope(); }
531 ;
532
533pop:
534 { typedefTable.leaveScope(); }
535 ;
536
537//************************* CONSTANTS ********************************
538
539constant:
540 // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
541 INTEGERconstant { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
542 | FLOATING_DECIMALconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
543 | FLOATING_FRACTIONconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
544 | FLOATINGconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
545 | CHARACTERconstant { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
546 ;
547
548quasi_keyword: // CFA
549 TIMEOUT
550 | WOR
551 | CATCH
552 | RECOVER
553 | CATCHRESUME
554 | FIXUP
555 | FINALLY
556 ;
557
558identifier:
559 IDENTIFIER
560 | quasi_keyword
561 | '@' // CFA
562 { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
563 ;
564
565string_literal:
566 string_literal_list { $$ = build_constantStr( *$1 ); }
567 ;
568
569string_literal_list: // juxtaposed strings are concatenated
570 STRINGliteral { $$ = $1; } // conversion from tok to str
571 | string_literal_list STRINGliteral
572 {
573 if ( ! appendStr( *$1, *$2 ) ) YYERROR; // append 2nd juxtaposed string to 1st
574 delete $2; // allocated by lexer
575 $$ = $1; // conversion from tok to str
576 }
577 ;
578
579//************************* EXPRESSIONS ********************************
580
581primary_expression:
582 IDENTIFIER // typedef name cannot be used as a variable name
583 { $$ = new ExpressionNode( build_varref( $1 ) ); }
584 | quasi_keyword
585 { $$ = new ExpressionNode( build_varref( $1 ) ); }
586 | TYPEDIMname // CFA, generic length argument
587 // { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( DeclarationNode::newFromTypedef( $1 ) ) ) ); }
588 // { $$ = new ExpressionNode( build_varref( $1 ) ); }
589 { $$ = new ExpressionNode( build_dimensionref( $1 ) ); }
590 | tuple
591 | '(' comma_expression ')'
592 { $$ = $2; }
593 | '(' compound_statement ')' // GCC, lambda expression
594 { $$ = new ExpressionNode( new StmtExpr( dynamic_cast<CompoundStmt *>(maybeMoveBuild<Statement>($2) ) ) ); }
595 | type_name '.' identifier // CFA, nested type
596 { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
597 | type_name '.' '[' field_name_list ']' // CFA, nested type / tuple field selector
598 { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
599 | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
600 {
601 // add the missing control expression to the GenericExpr and return it
602 $5->control = maybeMoveBuild<Expression>( $3 );
603 $$ = new ExpressionNode( $5 );
604 }
605 // | RESUME '(' comma_expression ')'
606 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
607 // | RESUME '(' comma_expression ')' compound_statement
608 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
609 ;
610
611generic_assoc_list: // C11
612 generic_association
613 | generic_assoc_list ',' generic_association
614 {
615 // steal the association node from the singleton and delete the wrapper
616 $1->associations.splice($1->associations.end(), $3->associations);
617 delete $3;
618 $$ = $1;
619 }
620 ;
621
622generic_association: // C11
623 type_no_function ':' assignment_expression
624 {
625 // create a GenericExpr wrapper with one association pair
626 $$ = new GenericExpr( nullptr, { { maybeMoveBuildType($1), maybeMoveBuild<Expression>( $3 ) } } );
627 }
628 | DEFAULT ':' assignment_expression
629 { $$ = new GenericExpr( nullptr, { { maybeMoveBuild<Expression>( $3 ) } } ); }
630 ;
631
632postfix_expression:
633 primary_expression
634 | postfix_expression '[' assignment_expression ',' tuple_expression_list ']'
635 // Historic, transitional: Disallow commas in subscripts.
636 // Switching to this behaviour may help check if a C compatibilty case uses comma-exprs in subscripts.
637 // { SemanticError( yylloc, "New array subscript is currently unimplemented." ); $$ = nullptr; }
638 // Current: Commas in subscripts make tuples.
639 { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, new ExpressionNode( build_tuple( (ExpressionNode *)($3->set_last( $5 ) ) )) ) ); }
640 | postfix_expression '[' assignment_expression ']'
641 // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
642 // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
643 // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
644 // equivalent to the old x[i,j].
645 { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
646 | postfix_expression '{' argument_expression_list_opt '}' // CFA, constructor call
647 {
648 Token fn;
649 fn.str = new std::string( "?{}" ); // location undefined - use location of '{'?
650 $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
651 }
652 | postfix_expression '(' argument_expression_list_opt ')'
653 { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
654 | postfix_expression '`' identifier // CFA, postfix call
655 { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
656 | constant '`' identifier // CFA, postfix call
657 { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
658 | string_literal '`' identifier // CFA, postfix call
659 { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), new ExpressionNode( $1 ) ) ); }
660 | postfix_expression '.' identifier
661 { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
662 | postfix_expression '.' INTEGERconstant // CFA, tuple index
663 { $$ = new ExpressionNode( build_fieldSel( $1, build_constantInteger( *$3 ) ) ); }
664 | postfix_expression FLOATING_FRACTIONconstant // CFA, tuple index
665 { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
666 | postfix_expression '.' '[' field_name_list ']' // CFA, tuple field selector
667 { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
668 | postfix_expression '.' aggregate_control
669 { $$ = new ExpressionNode( build_keyword_cast( $3, $1 ) ); }
670 | postfix_expression ARROW identifier
671 { $$ = new ExpressionNode( build_pfieldSel( $1, build_varref( $3 ) ) ); }
672 | postfix_expression ARROW INTEGERconstant // CFA, tuple index
673 { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
674 | postfix_expression ARROW '[' field_name_list ']' // CFA, tuple field selector
675 { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
676 | postfix_expression ICR
677 { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
678 | postfix_expression DECR
679 { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
680 | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
681 { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
682 | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
683 { $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
684 | '^' primary_expression '{' argument_expression_list_opt '}' // CFA, destructor call
685 {
686 Token fn;
687 fn.str = new string( "^?{}" ); // location undefined
688 $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
689 }
690 ;
691
692argument_expression_list_opt:
693 // empty
694 { $$ = nullptr; }
695 | argument_expression
696 | argument_expression_list_opt ',' argument_expression
697 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
698 ;
699
700argument_expression:
701 '@' // CFA, default parameter
702 { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
703 // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
704 | assignment_expression
705 ;
706
707field_name_list: // CFA, tuple field selector
708 field
709 | field_name_list ',' field { $$ = (ExpressionNode *)($1->set_last( $3 )); }
710 ;
711
712field: // CFA, tuple field selector
713 field_name
714 | FLOATING_DECIMALconstant field
715 { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
716 | FLOATING_DECIMALconstant '[' field_name_list ']'
717 { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $3 ) ) ); }
718 | field_name '.' field
719 { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
720 | field_name '.' '[' field_name_list ']'
721 { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
722 | field_name ARROW field
723 { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
724 | field_name ARROW '[' field_name_list ']'
725 { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
726 ;
727
728field_name:
729 INTEGERconstant fraction_constants_opt
730 { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
731 | FLOATINGconstant fraction_constants_opt
732 { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
733 | identifier fraction_constants_opt
734 {
735 $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
736 }
737 ;
738
739fraction_constants_opt:
740 // empty
741 { $$ = nullptr; }
742 | fraction_constants_opt FLOATING_FRACTIONconstant
743 {
744 Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
745 $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1, constant ) ) : new ExpressionNode( constant );
746 }
747 ;
748
749unary_expression:
750 postfix_expression
751 // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
752 // semantics checks, e.g., ++3, 3--, *3, &&3
753 | constant
754 | string_literal
755 { $$ = new ExpressionNode( $1 ); }
756 | EXTENSION cast_expression // GCC
757 { $$ = $2->set_extension( true ); }
758 // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
759 // { * X; } // dereference X
760 // { * int X; } // CFA declaration of pointer to int
761 | ptrref_operator cast_expression // CFA
762 {
763 switch ( $1 ) {
764 case OperKinds::AddressOf:
765 $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild<Expression>( $2 ) ) );
766 break;
767 case OperKinds::PointTo:
768 $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
769 break;
770 case OperKinds::And:
771 $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild<Expression>( $2 ) ) ) );
772 break;
773 default:
774 assert( false );
775 }
776 }
777 | unary_operator cast_expression
778 { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
779 | ICR unary_expression
780 { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
781 | DECR unary_expression
782 { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
783 | SIZEOF unary_expression
784 { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild<Expression>( $2 ) ) ); }
785 | SIZEOF '(' type_no_function ')'
786 { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
787 | ALIGNOF unary_expression // GCC, variable alignment
788 { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild<Expression>( $2 ) ) ); }
789 | ALIGNOF '(' type_no_function ')' // GCC, type alignment
790 { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
791 | OFFSETOF '(' type_no_function ',' identifier ')'
792 { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
793 | TYPEID '(' type_no_function ')'
794 {
795 SemanticError( yylloc, "typeid name is currently unimplemented." ); $$ = nullptr;
796 // $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) );
797 }
798 ;
799
800ptrref_operator:
801 '*' { $$ = OperKinds::PointTo; }
802 | '&' { $$ = OperKinds::AddressOf; }
803 // GCC, address of label must be handled by semantic check for ref,ref,label
804 | ANDAND { $$ = OperKinds::And; }
805 ;
806
807unary_operator:
808 '+' { $$ = OperKinds::UnPlus; }
809 | '-' { $$ = OperKinds::UnMinus; }
810 | '!' { $$ = OperKinds::Neg; }
811 | '~' { $$ = OperKinds::BitNeg; }
812 ;
813
814cast_expression:
815 unary_expression
816 | '(' type_no_function ')' cast_expression
817 { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
818 | '(' aggregate_control '&' ')' cast_expression // CFA
819 { $$ = new ExpressionNode( build_keyword_cast( $2, $5 ) ); }
820 | '(' aggregate_control '*' ')' cast_expression // CFA
821 { $$ = new ExpressionNode( build_keyword_cast( $2, $5 ) ); }
822 | '(' VIRTUAL ')' cast_expression // CFA
823 { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild<Expression>( $4 ), maybeMoveBuildType( nullptr ) ) ); }
824 | '(' VIRTUAL type_no_function ')' cast_expression // CFA
825 { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild<Expression>( $5 ), maybeMoveBuildType( $3 ) ) ); }
826 | '(' RETURN type_no_function ')' cast_expression // CFA
827 { SemanticError( yylloc, "Return cast is currently unimplemented." ); $$ = nullptr; }
828 | '(' COERCE type_no_function ')' cast_expression // CFA
829 { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
830 | '(' qualifier_cast_list ')' cast_expression // CFA
831 { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
832// | '(' type_no_function ')' tuple
833// { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
834 ;
835
836qualifier_cast_list:
837 cast_modifier type_qualifier_name
838 | cast_modifier MUTEX
839 | qualifier_cast_list cast_modifier type_qualifier_name
840 | qualifier_cast_list cast_modifier MUTEX
841 ;
842
843cast_modifier:
844 '-'
845 | '+'
846 ;
847
848exponential_expression:
849 cast_expression
850 | exponential_expression '\\' cast_expression
851 { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
852 ;
853
854multiplicative_expression:
855 exponential_expression
856 | multiplicative_expression '*' exponential_expression
857 { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
858 | multiplicative_expression '/' exponential_expression
859 { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
860 | multiplicative_expression '%' exponential_expression
861 { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
862 ;
863
864additive_expression:
865 multiplicative_expression
866 | additive_expression '+' multiplicative_expression
867 { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
868 | additive_expression '-' multiplicative_expression
869 { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
870 ;
871
872shift_expression:
873 additive_expression
874 | shift_expression LS additive_expression
875 { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
876 | shift_expression RS additive_expression
877 { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
878 ;
879
880relational_expression:
881 shift_expression
882 | relational_expression '<' shift_expression
883 { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
884 | relational_expression '>' shift_expression
885 { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
886 | relational_expression LE shift_expression
887 { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
888 | relational_expression GE shift_expression
889 { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
890 ;
891
892equality_expression:
893 relational_expression
894 | equality_expression EQ relational_expression
895 { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
896 | equality_expression NE relational_expression
897 { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
898 ;
899
900AND_expression:
901 equality_expression
902 | AND_expression '&' equality_expression
903 { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
904 ;
905
906exclusive_OR_expression:
907 AND_expression
908 | exclusive_OR_expression '^' AND_expression
909 { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
910 ;
911
912inclusive_OR_expression:
913 exclusive_OR_expression
914 | inclusive_OR_expression '|' exclusive_OR_expression
915 { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
916 ;
917
918logical_AND_expression:
919 inclusive_OR_expression
920 | logical_AND_expression ANDAND inclusive_OR_expression
921 { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
922 ;
923
924logical_OR_expression:
925 logical_AND_expression
926 | logical_OR_expression OROR logical_AND_expression
927 { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
928 ;
929
930conditional_expression:
931 logical_OR_expression
932 | logical_OR_expression '?' comma_expression ':' conditional_expression
933 { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
934 // FIX ME: computes $1 twice
935 | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
936 { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
937 ;
938
939constant_expression:
940 conditional_expression
941 ;
942
943assignment_expression:
944 // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
945 conditional_expression
946 | unary_expression assignment_operator assignment_expression
947 {
948// if ( $2 == OperKinds::AtAssn ) {
949// SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
950// } else {
951 $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) );
952// } // if
953 }
954 | unary_expression '=' '{' initializer_list_opt comma_opt '}'
955 { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
956 ;
957
958assignment_expression_opt:
959 // empty
960 { $$ = nullptr; }
961 | assignment_expression
962 ;
963
964assignment_operator:
965 simple_assignment_operator
966 | compound_assignment_operator
967 ;
968
969simple_assignment_operator:
970 '=' { $$ = OperKinds::Assign; }
971 | ATassign { $$ = OperKinds::AtAssn; } // CFA
972 ;
973
974compound_assignment_operator:
975 EXPassign { $$ = OperKinds::ExpAssn; }
976 | MULTassign { $$ = OperKinds::MulAssn; }
977 | DIVassign { $$ = OperKinds::DivAssn; }
978 | MODassign { $$ = OperKinds::ModAssn; }
979 | PLUSassign { $$ = OperKinds::PlusAssn; }
980 | MINUSassign { $$ = OperKinds::MinusAssn; }
981 | LSassign { $$ = OperKinds::LSAssn; }
982 | RSassign { $$ = OperKinds::RSAssn; }
983 | ANDassign { $$ = OperKinds::AndAssn; }
984 | ERassign { $$ = OperKinds::ERAssn; }
985 | ORassign { $$ = OperKinds::OrAssn; }
986 ;
987
988tuple: // CFA, tuple
989 // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
990 // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
991// '[' ']'
992// { $$ = new ExpressionNode( build_tuple() ); }
993// | '[' push assignment_expression pop ']'
994// { $$ = new ExpressionNode( build_tuple( $3 ) ); }
995 '[' ',' tuple_expression_list ']'
996 { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
997 | '[' push assignment_expression pop ',' tuple_expression_list ']'
998 { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)($3->set_last( $6 ) ) )); }
999 ;
1000
1001tuple_expression_list:
1002 assignment_expression
1003 | '@' // CFA
1004 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1005 | tuple_expression_list ',' assignment_expression
1006 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1007 | tuple_expression_list ',' '@'
1008 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1009 ;
1010
1011comma_expression:
1012 assignment_expression
1013 | comma_expression ',' assignment_expression
1014 { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild<Expression>( $1 ), maybeMoveBuild<Expression>( $3 ) ) ); }
1015 ;
1016
1017comma_expression_opt:
1018 // empty
1019 { $$ = nullptr; }
1020 | comma_expression
1021 ;
1022
1023//*************************** STATEMENTS *******************************
1024
1025statement:
1026 labeled_statement
1027 | compound_statement
1028 | expression_statement
1029 | selection_statement
1030 | iteration_statement
1031 | jump_statement
1032 | with_statement
1033 | mutex_statement
1034 | waitfor_statement
1035 | exception_statement
1036 | enable_disable_statement
1037 { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1038 | asm_statement
1039 | DIRECTIVE
1040 { $$ = new StatementNode( build_directive( $1 ) ); }
1041 ;
1042
1043labeled_statement:
1044 // labels cannot be identifiers 0 or 1
1045 identifier_or_type_name ':' attribute_list_opt statement
1046 { $$ = $4->add_label( $1, $3 ); }
1047 ;
1048
1049compound_statement:
1050 '{' '}'
1051 { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
1052 | '{' push
1053 local_label_declaration_opt // GCC, local labels appear at start of block
1054 statement_decl_list // C99, intermix declarations and statements
1055 pop '}'
1056 { $$ = new StatementNode( build_compound( $4 ) ); }
1057 ;
1058
1059statement_decl_list: // C99
1060 statement_decl
1061 | statement_decl_list statement_decl
1062 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1063 ;
1064
1065statement_decl:
1066 declaration // CFA, new & old style declarations
1067 { $$ = new StatementNode( $1 ); }
1068 | EXTENSION declaration // GCC
1069 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1070 | function_definition
1071 { $$ = new StatementNode( $1 ); }
1072 | EXTENSION function_definition // GCC
1073 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1074 | statement
1075 ;
1076
1077statement_list_nodecl:
1078 statement
1079 | statement_list_nodecl statement
1080 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1081 ;
1082
1083expression_statement:
1084 comma_expression_opt ';'
1085 { $$ = new StatementNode( build_expr( $1 ) ); }
1086 ;
1087
1088selection_statement:
1089 // pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1090 // the inherent S/R conflict with THEN/ELSE.
1091 push if_statement pop
1092 { $$ = $2; }
1093 | SWITCH '(' comma_expression ')' case_clause
1094 { $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
1095 | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1096 {
1097 StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
1098 // The semantics of the declaration list is changed to include associated initialization, which is performed
1099 // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1100 // statement around the switch. Statements after the initial declaration list can never be executed, and
1101 // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1102 // statement.
1103 $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1104 }
1105 | CHOOSE '(' comma_expression ')' case_clause // CFA
1106 { $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
1107 | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1108 {
1109 StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
1110 $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1111 }
1112 ;
1113
1114if_statement:
1115 IF '(' if_control_expression ')' statement %prec THEN
1116 // explicitly deal with the shift/reduce conflict on if/else
1117 { $$ = new StatementNode( build_if( $3, maybe_build_compound( $5 ), nullptr ) ); }
1118 | IF '(' if_control_expression ')' statement ELSE statement
1119 { $$ = new StatementNode( build_if( $3, maybe_build_compound( $5 ), maybe_build_compound( $7 ) ) ); }
1120 ;
1121
1122if_control_expression:
1123 comma_expression
1124 { $$ = new IfCtrl( nullptr, $1 ); }
1125 | c_declaration // no semi-colon
1126 { $$ = new IfCtrl( $1, nullptr ); }
1127 | cfa_declaration // no semi-colon
1128 { $$ = new IfCtrl( $1, nullptr ); }
1129 | declaration comma_expression // semi-colon separated
1130 { $$ = new IfCtrl( $1, $2 ); }
1131 ;
1132
1133// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1134// clause allows a list of values and subranges.
1135
1136case_value: // CFA
1137 constant_expression { $$ = $1; }
1138 | constant_expression ELLIPSIS constant_expression // GCC, subrange
1139 { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild<Expression>( $1 ), maybeMoveBuild<Expression>( $3 ) ) ); }
1140 | subrange // CFA, subrange
1141 ;
1142
1143case_value_list: // CFA
1144 case_value { $$ = new StatementNode( build_case( $1 ) ); }
1145 // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1146 | case_value_list ',' case_value { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
1147 ;
1148
1149case_label: // CFA
1150 CASE case_value_list ':' { $$ = $2; }
1151 | DEFAULT ':' { $$ = new StatementNode( build_default() ); }
1152 // A semantic check is required to ensure only one default clause per switch/choose statement.
1153 ;
1154
1155//label_list_opt:
1156// // empty
1157// | identifier_or_type_name ':'
1158// | label_list_opt identifier_or_type_name ':'
1159// ;
1160
1161case_label_list: // CFA
1162 case_label
1163 | case_label_list case_label { $$ = (StatementNode *)( $1->set_last( $2 )); }
1164 ;
1165
1166case_clause: // CFA
1167 case_label_list statement { $$ = $1->append_last_case( maybe_build_compound( $2 ) ); }
1168 ;
1169
1170switch_clause_list_opt: // CFA
1171 // empty
1172 { $$ = nullptr; }
1173 | switch_clause_list
1174 ;
1175
1176switch_clause_list: // CFA
1177 case_label_list statement_list_nodecl
1178 { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1179 | switch_clause_list case_label_list statement_list_nodecl
1180 { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1181 ;
1182
1183iteration_statement:
1184 WHILE '(' push if_control_expression ')' statement pop
1185 { $$ = new StatementNode( build_while( $4, maybe_build_compound( $6 ) ) ); }
1186 | WHILE '(' ')' statement // CFA => while ( 1 )
1187 { $$ = new StatementNode( build_while( new IfCtrl( nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ), maybe_build_compound( $4 ) ) ); }
1188 | DO statement WHILE '(' comma_expression ')' ';'
1189 { $$ = new StatementNode( build_do_while( $5, maybe_build_compound( $2 ) ) ); }
1190 | DO statement WHILE '(' ')' ';' // CFA => do while( 1 )
1191 { $$ = new StatementNode( build_do_while( new ExpressionNode( build_constantInteger( *new string( "1" ) ) ), maybe_build_compound( $2 ) ) ); }
1192 | FOR '(' push for_control_expression_list ')' statement pop
1193 { $$ = new StatementNode( build_for( $4, maybe_build_compound( $6 ) ) ); }
1194 | FOR '(' ')' statement // CFA => for ( ;; )
1195 { $$ = new StatementNode( build_for( new ForCtrl( (ExpressionNode * )nullptr, (ExpressionNode * )nullptr, (ExpressionNode * )nullptr ), maybe_build_compound( $4 ) ) ); }
1196 ;
1197
1198for_control_expression_list:
1199 for_control_expression
1200 | for_control_expression_list ':' for_control_expression
1201 // ForCtrl + ForCtrl:
1202 // init + init => multiple declaration statements that are hoisted
1203 // condition + condition => (expression) && (expression)
1204 // change + change => (expression), (expression)
1205 {
1206 $1->init->set_last( $3->init );
1207 if ( $1->condition ) {
1208 if ( $3->condition ) {
1209 $1->condition->expr.reset( new LogicalExpr( $1->condition->expr.release(), $3->condition->expr.release(), true ) );
1210 } // if
1211 } else $1->condition = $3->condition;
1212 if ( $1->change ) {
1213 if ( $3->change ) {
1214 $1->change->expr.reset( new CommaExpr( $1->change->expr.release(), $3->change->expr.release() ) );
1215 } // if
1216 } else $1->change = $3->change;
1217 $$ = $1;
1218 }
1219 ;
1220
1221for_control_expression:
1222 ';' comma_expression_opt ';' comma_expression_opt
1223 { $$ = new ForCtrl( (ExpressionNode * )nullptr, $2, $4 ); }
1224 | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1225 { $$ = new ForCtrl( $1, $3, $5 ); }
1226 | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1227 { $$ = new ForCtrl( $1, $2, $4 ); }
1228
1229 | comma_expression // CFA
1230 { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1231 OperKinds::LThan, $1->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1232 | '=' comma_expression // CFA
1233 { $$ = forCtrl( $2, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1234 OperKinds::LEThan, $2->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1235 | comma_expression inclexcl comma_expression // CFA
1236 { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1237 | comma_expression inclexcl comma_expression '~' comma_expression // CFA
1238 { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, $5 ); }
1239 | comma_expression ';' // CFA
1240 { $$ = forCtrl( new ExpressionNode( build_constantInteger( *new string( "0u" ) ) ), $1, nullptr, OperKinds::LThan, nullptr, nullptr ); }
1241 | comma_expression ';' comma_expression // CFA
1242 { $$ = forCtrl( $3, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1243 OperKinds::LThan, $3->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1244 | comma_expression ';' '=' comma_expression // CFA
1245 { $$ = forCtrl( $4, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1246 OperKinds::LEThan, $4->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1247 | comma_expression ';' comma_expression inclexcl comma_expression // CFA
1248 { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1249 | comma_expression ';' comma_expression inclexcl comma_expression '~' comma_expression // CFA
1250 { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, $7 ); }
1251
1252 | comma_expression ';' TYPEDEFname // CFA, array type
1253 {
1254 SemanticError( yylloc, "Array interator is currently unimplemented." ); $$ = nullptr;
1255 $$ = forCtrl( new ExpressionNode( build_varref( $3 ) ), $1, nullptr, OperKinds::Range, nullptr, nullptr );
1256 }
1257
1258 // There is a S/R conflicit if ~ and -~ are factored out.
1259 | comma_expression ';' comma_expression '~' '@' // CFA
1260 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1261 | comma_expression ';' comma_expression ErangeDown '@' // CFA
1262 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1263 | comma_expression ';' comma_expression '~' '@' '~' comma_expression // CFA
1264 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, $7 ); }
1265 | comma_expression ';' comma_expression ErangeDown '@' '~' comma_expression // CFA
1266 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, $7 ); }
1267 | comma_expression ';' comma_expression '~' '@' '~' '@' // CFA
1268 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, nullptr ); }
1269 ;
1270
1271inclexcl:
1272 '~'
1273 { $$ = OperKinds::LThan; }
1274 | ErangeUpEq
1275 { $$ = OperKinds::LEThan; }
1276 | ErangeDown
1277 { $$ = OperKinds::GThan; }
1278 | ErangeDownEq
1279 { $$ = OperKinds::GEThan; }
1280 ;
1281
1282jump_statement:
1283 GOTO identifier_or_type_name ';'
1284 { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1285 | GOTO '*' comma_expression ';' // GCC, computed goto
1286 // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1287 // whereas normal operator precedence yields goto (*i)+3;
1288 { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1289 // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1290 | fall_through_name ';' // CFA
1291 { $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1292 | fall_through_name identifier_or_type_name ';' // CFA
1293 { $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1294 | fall_through_name DEFAULT ';' // CFA
1295 { $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1296 | CONTINUE ';'
1297 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1298 { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1299 | CONTINUE identifier_or_type_name ';' // CFA, multi-level continue
1300 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1301 // the target of the transfer appears only at the start of an iteration statement.
1302 { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1303 | BREAK ';'
1304 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1305 { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1306 | BREAK identifier_or_type_name ';' // CFA, multi-level exit
1307 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1308 // the target of the transfer appears only at the start of an iteration statement.
1309 { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1310 | RETURN comma_expression_opt ';'
1311 { $$ = new StatementNode( build_return( $2 ) ); }
1312 | RETURN '{' initializer_list_opt comma_opt '}' ';'
1313 { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1314 | SUSPEND ';'
1315 { $$ = new StatementNode( build_suspend( nullptr ) ); }
1316 | SUSPEND compound_statement
1317 { $$ = new StatementNode( build_suspend( $2 ) ); }
1318 | SUSPEND COROUTINE ';'
1319 { $$ = new StatementNode( build_suspend( nullptr, SuspendStmt::Coroutine ) ); }
1320 | SUSPEND COROUTINE compound_statement
1321 { $$ = new StatementNode( build_suspend( $3, SuspendStmt::Coroutine ) ); }
1322 | SUSPEND GENERATOR ';'
1323 { $$ = new StatementNode( build_suspend( nullptr, SuspendStmt::Generator ) ); }
1324 | SUSPEND GENERATOR compound_statement
1325 { $$ = new StatementNode( build_suspend( $3, SuspendStmt::Generator ) ); }
1326 | THROW assignment_expression_opt ';' // handles rethrow
1327 { $$ = new StatementNode( build_throw( $2 ) ); }
1328 | THROWRESUME assignment_expression_opt ';' // handles reresume
1329 { $$ = new StatementNode( build_resume( $2 ) ); }
1330 | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1331 { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1332 ;
1333
1334fall_through_name: // CFA
1335 FALLTHRU
1336 | FALLTHROUGH
1337 ;
1338
1339with_statement:
1340 WITH '(' tuple_expression_list ')' statement
1341 {
1342 $$ = new StatementNode( build_with( $3, $5 ) );
1343 }
1344 ;
1345
1346// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1347mutex_statement:
1348 MUTEX '(' argument_expression_list_opt ')' statement
1349 { $$ = new StatementNode( build_mutex( $3, $5 ) ); }
1350 ;
1351
1352when_clause:
1353 WHEN '(' comma_expression ')' { $$ = $3; }
1354 ;
1355
1356when_clause_opt:
1357 // empty
1358 { $$ = nullptr; }
1359 | when_clause
1360 ;
1361
1362waitfor:
1363 WAITFOR '(' cast_expression ')'
1364 { $$ = $3; }
1365// | WAITFOR '(' cast_expression ',' argument_expression_list_opt ')'
1366// { $$ = (ExpressionNode *)$3->set_last( $5 ); }
1367 | WAITFOR '(' cast_expression_list ':' argument_expression_list_opt ')'
1368 { $$ = (ExpressionNode *)($3->set_last( $5 )); }
1369 ;
1370
1371cast_expression_list:
1372 cast_expression
1373 | cast_expression_list ',' cast_expression
1374 // { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1375 { SemanticError( yylloc, "List of mutex member is currently unimplemented." ); $$ = nullptr; }
1376 ;
1377
1378timeout:
1379 TIMEOUT '(' comma_expression ')' { $$ = $3; }
1380 ;
1381
1382waitfor_clause:
1383 when_clause_opt waitfor statement %prec THEN
1384 { $$ = build_waitfor( $2, maybe_build_compound( $3 ), $1 ); }
1385 | when_clause_opt waitfor statement WOR waitfor_clause
1386 { $$ = build_waitfor( $2, maybe_build_compound( $3 ), $1, $5 ); }
1387 | when_clause_opt timeout statement %prec THEN
1388 { $$ = build_waitfor_timeout( $2, maybe_build_compound( $3 ), $1 ); }
1389 | when_clause_opt ELSE statement
1390 { $$ = build_waitfor_timeout( nullptr, maybe_build_compound( $3 ), $1 ); }
1391 // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1392 | when_clause_opt timeout statement WOR ELSE statement
1393 { SemanticError( yylloc, "else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1394 | when_clause_opt timeout statement WOR when_clause ELSE statement
1395 { $$ = build_waitfor_timeout( $2, maybe_build_compound( $3 ), $1, maybe_build_compound( $7 ), $5 ); }
1396 ;
1397
1398waitfor_statement:
1399 when_clause_opt waitfor statement %prec THEN
1400 { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1401 | when_clause_opt waitfor statement WOR waitfor_clause
1402 { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1403 ;
1404
1405exception_statement:
1406 TRY compound_statement handler_clause %prec THEN
1407 { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1408 | TRY compound_statement finally_clause
1409 { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1410 | TRY compound_statement handler_clause finally_clause
1411 { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1412 ;
1413
1414handler_clause:
1415 handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1416 { $$ = new StatementNode( build_catch( $1, $4, $6, $8 ) ); }
1417 | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1418 { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $5, $7, $9 ) ) ); }
1419 ;
1420
1421handler_predicate_opt:
1422 // empty
1423 { $$ = nullptr; }
1424 | ';' conditional_expression { $$ = $2; }
1425 ;
1426
1427handler_key:
1428 CATCH { $$ = CatchStmt::Terminate; }
1429 | RECOVER { $$ = CatchStmt::Terminate; }
1430 | CATCHRESUME { $$ = CatchStmt::Resume; }
1431 | FIXUP { $$ = CatchStmt::Resume; }
1432 ;
1433
1434finally_clause:
1435 FINALLY compound_statement { $$ = new StatementNode( build_finally( $2 ) ); }
1436 ;
1437
1438exception_declaration:
1439 // No SUE declaration in parameter list.
1440 type_specifier_nobody
1441 | type_specifier_nobody declarator
1442 { $$ = $2->addType( $1 ); }
1443 | type_specifier_nobody variable_abstract_declarator
1444 { $$ = $2->addType( $1 ); }
1445 | cfa_abstract_declarator_tuple identifier // CFA
1446 { $$ = $1->addName( $2 ); }
1447 | cfa_abstract_declarator_tuple // CFA
1448 ;
1449
1450enable_disable_statement:
1451 enable_disable_key identifier_list compound_statement
1452 ;
1453
1454enable_disable_key:
1455 ENABLE
1456 | DISABLE
1457 ;
1458
1459asm_statement:
1460 ASM asm_volatile_opt '(' string_literal ')' ';'
1461 { $$ = new StatementNode( build_asm( $2, $4, 0 ) ); }
1462 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1463 { $$ = new StatementNode( build_asm( $2, $4, $6 ) ); }
1464 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1465 { $$ = new StatementNode( build_asm( $2, $4, $6, $8 ) ); }
1466 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1467 { $$ = new StatementNode( build_asm( $2, $4, $6, $8, $10 ) ); }
1468 | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1469 { $$ = new StatementNode( build_asm( $2, $5, 0, $8, $10, $12 ) ); }
1470 ;
1471
1472asm_volatile_opt: // GCC
1473 // empty
1474 { $$ = false; }
1475 | VOLATILE
1476 { $$ = true; }
1477 ;
1478
1479asm_operands_opt: // GCC
1480 // empty
1481 { $$ = nullptr; } // use default argument
1482 | asm_operands_list
1483 ;
1484
1485asm_operands_list: // GCC
1486 asm_operand
1487 | asm_operands_list ',' asm_operand
1488 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1489 ;
1490
1491asm_operand: // GCC
1492 string_literal '(' constant_expression ')'
1493 { $$ = new ExpressionNode( new AsmExpr( nullptr, $1, maybeMoveBuild<Expression>( $3 ) ) ); }
1494 | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1495 { $$ = new ExpressionNode( new AsmExpr( $2, $4, maybeMoveBuild<Expression>( $6 ) ) ); }
1496 ;
1497
1498asm_clobbers_list_opt: // GCC
1499 // empty
1500 { $$ = nullptr; } // use default argument
1501 | string_literal
1502 { $$ = new ExpressionNode( $1 ); }
1503 | asm_clobbers_list_opt ',' string_literal
1504 { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( $3 ) )); }
1505 ;
1506
1507label_list:
1508 identifier
1509 {
1510 $$ = new LabelNode(); $$->labels.push_back( *$1 );
1511 delete $1; // allocated by lexer
1512 }
1513 | label_list ',' identifier
1514 {
1515 $$ = $1; $1->labels.push_back( *$3 );
1516 delete $3; // allocated by lexer
1517 }
1518 ;
1519
1520//******************************* DECLARATIONS *********************************
1521
1522declaration_list_opt: // used at beginning of switch statement
1523 // empty
1524 { $$ = nullptr; }
1525 | declaration_list
1526 ;
1527
1528declaration_list:
1529 declaration
1530 | declaration_list declaration
1531 { $$ = $1->appendList( $2 ); }
1532 ;
1533
1534KR_parameter_list_opt: // used to declare parameter types in K&R style functions
1535 // empty
1536 { $$ = nullptr; }
1537 | KR_parameter_list
1538 ;
1539
1540KR_parameter_list:
1541 push c_declaration pop ';'
1542 { $$ = $2; }
1543 | KR_parameter_list push c_declaration pop ';'
1544 { $$ = $1->appendList( $3 ); }
1545 ;
1546
1547local_label_declaration_opt: // GCC, local label
1548 // empty
1549 | local_label_declaration_list
1550 ;
1551
1552local_label_declaration_list: // GCC, local label
1553 LABEL local_label_list ';'
1554 | local_label_declaration_list LABEL local_label_list ';'
1555 ;
1556
1557local_label_list: // GCC, local label
1558 identifier_or_type_name
1559 | local_label_list ',' identifier_or_type_name
1560 ;
1561
1562declaration: // old & new style declarations
1563 c_declaration ';'
1564 | cfa_declaration ';' // CFA
1565 | static_assert // C11
1566 ;
1567
1568static_assert:
1569 STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1570 { $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1571 | STATICASSERT '(' constant_expression ')' ';' // CFA
1572 { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( *new string( "\"\"" ) ) ); }
1573
1574// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1575// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1576// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1577// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1578// the declaration list (as in Pascal). ANSI C and the new CFA declarations may appear together in the same program
1579// block, but cannot be mixed within a specific declaration.
1580//
1581// CFA C
1582// [10] int x; int x[10]; // array of 10 integers
1583// [10] * char y; char *y[10]; // array of 10 pointers to char
1584
1585cfa_declaration: // CFA
1586 cfa_variable_declaration
1587 | cfa_typedef_declaration
1588 | cfa_function_declaration
1589 | type_declaring_list
1590 { SemanticError( yylloc, "otype declaration is currently unimplemented." ); $$ = nullptr; }
1591 | trait_specifier
1592 ;
1593
1594cfa_variable_declaration: // CFA
1595 cfa_variable_specifier initializer_opt
1596 { $$ = $1->addInitializer( $2 ); }
1597 | declaration_qualifier_list cfa_variable_specifier initializer_opt
1598 // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1599 // them as a type_qualifier cannot appear in that context.
1600 { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1601 | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1602 { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1603 ;
1604
1605cfa_variable_specifier: // CFA
1606 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1607 // storage-class
1608 cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1609 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1610 | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1611 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1612 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1613 { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1614 ;
1615
1616cfa_function_declaration: // CFA
1617 cfa_function_specifier
1618 | type_qualifier_list cfa_function_specifier
1619 { $$ = $2->addQualifiers( $1 ); }
1620 | declaration_qualifier_list cfa_function_specifier
1621 { $$ = $2->addQualifiers( $1 ); }
1622 | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1623 { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1624 | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1625 {
1626 // Append the return type at the start (left-hand-side) to each identifier in the list.
1627 DeclarationNode * ret = new DeclarationNode;
1628 ret->type = maybeClone( $1->type->base );
1629 $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1630 }
1631 ;
1632
1633cfa_function_specifier: // CFA
1634// '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1635// {
1636// $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1637// }
1638// '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1639// {
1640// typedefTable.setNextIdentifier( *$5 );
1641// $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1642// }
1643// | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1644// {
1645// typedefTable.setNextIdentifier( *$5 );
1646// $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1647// }
1648// | '[' ']' typegen_name
1649 // identifier_or_type_name must be broken apart because of the sequence:
1650 //
1651 // '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1652 // '[' ']' type_specifier
1653 //
1654 // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1655 // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1656 cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1657 // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1658 { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1659 | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1660 { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1661 ;
1662
1663cfa_function_return: // CFA
1664 '[' push cfa_parameter_list pop ']'
1665 { $$ = DeclarationNode::newTuple( $3 ); }
1666 | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1667 // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
1668 { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1669 ;
1670
1671cfa_typedef_declaration: // CFA
1672 TYPEDEF cfa_variable_specifier
1673 {
1674 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "1" );
1675 $$ = $2->addTypedef();
1676 }
1677 | TYPEDEF cfa_function_specifier
1678 {
1679 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "2" );
1680 $$ = $2->addTypedef();
1681 }
1682 | cfa_typedef_declaration pop ',' push identifier
1683 {
1684 typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "3" );
1685 $$ = $1->appendList( $1->cloneType( $5 ) );
1686 }
1687 ;
1688
1689// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1690// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1691
1692typedef_declaration:
1693 TYPEDEF type_specifier declarator
1694 {
1695 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "4" );
1696 $$ = $3->addType( $2 )->addTypedef();
1697 }
1698 | typedef_declaration pop ',' push declarator
1699 {
1700 typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname, "5" );
1701 $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1702 }
1703 | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1704 {
1705 typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "6" );
1706 $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1707 }
1708 | type_specifier TYPEDEF declarator
1709 {
1710 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "7" );
1711 $$ = $3->addType( $1 )->addTypedef();
1712 }
1713 | type_specifier TYPEDEF type_qualifier_list declarator
1714 {
1715 typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "8" );
1716 $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1717 }
1718 ;
1719
1720typedef_expression:
1721 // deprecated GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1722 TYPEDEF identifier '=' assignment_expression
1723 {
1724 SemanticError( yylloc, "Typedef expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
1725 }
1726 | typedef_expression pop ',' push identifier '=' assignment_expression
1727 {
1728 SemanticError( yylloc, "Typedef expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
1729 }
1730 ;
1731
1732c_declaration:
1733 declaration_specifier declaring_list
1734 { $$ = distAttr( $1, $2 ); }
1735 | typedef_declaration
1736 | typedef_expression // deprecated GCC, naming expression type
1737 | sue_declaration_specifier
1738 ;
1739
1740declaring_list:
1741 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1742 // storage-class
1743 declarator asm_name_opt initializer_opt
1744 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
1745 | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1746 { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
1747 ;
1748
1749declaration_specifier: // type specifier + storage class
1750 basic_declaration_specifier
1751 | sue_declaration_specifier
1752 | type_declaration_specifier
1753 ;
1754
1755declaration_specifier_nobody: // type specifier + storage class - {...}
1756 // Preclude SUE declarations in restricted scopes:
1757 //
1758 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1759 //
1760 // because it is impossible to call f due to name equivalence.
1761 basic_declaration_specifier
1762 | sue_declaration_specifier_nobody
1763 | type_declaration_specifier
1764 ;
1765
1766type_specifier: // type specifier
1767 basic_type_specifier
1768 | sue_type_specifier
1769 | type_type_specifier
1770 ;
1771
1772type_specifier_nobody: // type specifier - {...}
1773 // Preclude SUE declarations in restricted scopes:
1774 //
1775 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1776 //
1777 // because it is impossible to call f due to name equivalence.
1778 basic_type_specifier
1779 | sue_type_specifier_nobody
1780 | type_type_specifier
1781 ;
1782
1783type_qualifier_list_opt: // GCC, used in asm_statement
1784 // empty
1785 { $$ = nullptr; }
1786 | type_qualifier_list
1787 ;
1788
1789type_qualifier_list:
1790 // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1791 //
1792 // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1793 // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1794 // appeared only once.
1795 type_qualifier
1796 | type_qualifier_list type_qualifier
1797 { $$ = $1->addQualifiers( $2 ); }
1798 ;
1799
1800type_qualifier:
1801 type_qualifier_name
1802 | attribute // trick handles most atrribute locations
1803 ;
1804
1805type_qualifier_name:
1806 CONST
1807 { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1808 | RESTRICT
1809 { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1810 | VOLATILE
1811 { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1812 | ATOMIC
1813 { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1814 | forall
1815 ;
1816
1817forall:
1818 FORALL '(' type_parameter_list ')' // CFA
1819 { $$ = DeclarationNode::newForall( $3 ); }
1820 ;
1821
1822declaration_qualifier_list:
1823 storage_class_list
1824 | type_qualifier_list storage_class_list // remaining OBSOLESCENT (see 2 )
1825 { $$ = $1->addQualifiers( $2 ); }
1826 | declaration_qualifier_list type_qualifier_list storage_class_list
1827 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1828 ;
1829
1830storage_class_list:
1831 // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1832 // only one of each is specified, except for inline, which can appear with the others.
1833 //
1834 // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1835 // specifiers in a declaration.
1836 storage_class
1837 | storage_class_list storage_class
1838 { $$ = $1->addQualifiers( $2 ); }
1839 ;
1840
1841storage_class:
1842 EXTERN
1843 { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1844 | STATIC
1845 { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1846 | AUTO
1847 { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1848 | REGISTER
1849 { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1850 | THREADLOCAL // C11
1851 { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1852 // Put function specifiers here to simplify parsing rules, but separate them semantically.
1853 | INLINE // C99
1854 { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1855 | FORTRAN // C99
1856 { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1857 | NORETURN // C11
1858 { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1859 ;
1860
1861basic_type_name:
1862 VOID
1863 { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1864 | BOOL // C99
1865 { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1866 | CHAR
1867 { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1868 | INT
1869 { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1870 | INT128
1871 { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1872 | UINT128
1873 { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 )->addType( DeclarationNode::newSignedNess( DeclarationNode::Unsigned ) ); }
1874 | FLOAT
1875 { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1876 | DOUBLE
1877 { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1878 | uuFLOAT80
1879 { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
1880 | uuFLOAT128
1881 { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
1882 | uFLOAT16
1883 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
1884 | uFLOAT32
1885 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
1886 | uFLOAT32X
1887 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
1888 | uFLOAT64
1889 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
1890 | uFLOAT64X
1891 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
1892 | uFLOAT128
1893 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
1894 | DECIMAL32
1895 { SemanticError( yylloc, "_Decimal32 is currently unimplemented." ); $$ = nullptr; }
1896 | DECIMAL64
1897 { SemanticError( yylloc, "_Decimal64 is currently unimplemented." ); $$ = nullptr; }
1898 | DECIMAL128
1899 { SemanticError( yylloc, "_Decimal128 is currently unimplemented." ); $$ = nullptr; }
1900 | COMPLEX // C99
1901 { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1902 | IMAGINARY // C99
1903 { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1904 | SIGNED
1905 { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1906 | UNSIGNED
1907 { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1908 | SHORT
1909 { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1910 | LONG
1911 { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1912 | VALIST // GCC, __builtin_va_list
1913 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1914 | AUTO_TYPE
1915 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::AutoType ); }
1916 | vtable
1917 ;
1918
1919vtable_opt:
1920 // empty
1921 { $$ = nullptr; }
1922 | vtable
1923 ;
1924
1925vtable:
1926 VTABLE '(' type_name ')' default_opt
1927 { $$ = DeclarationNode::newVtableType( $3 ); }
1928 // { SemanticError( yylloc, "vtable is currently unimplemented." ); $$ = nullptr; }
1929 ;
1930
1931default_opt:
1932 // empty
1933 { $$ = nullptr; }
1934 | DEFAULT
1935 { SemanticError( yylloc, "vtable default is currently unimplemented." ); $$ = nullptr; }
1936 ;
1937
1938basic_declaration_specifier:
1939 // A semantic check is necessary for conflicting storage classes.
1940 basic_type_specifier
1941 | declaration_qualifier_list basic_type_specifier
1942 { $$ = $2->addQualifiers( $1 ); }
1943 | basic_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1944 { $$ = $1->addQualifiers( $2 ); }
1945 | basic_declaration_specifier storage_class type_qualifier_list
1946 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1947 | basic_declaration_specifier storage_class basic_type_specifier
1948 { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1949 ;
1950
1951basic_type_specifier:
1952 direct_type
1953 // Cannot have type modifiers, e.g., short, long, etc.
1954 | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1955 { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1956 ;
1957
1958direct_type:
1959 basic_type_name
1960 | type_qualifier_list basic_type_name
1961 { $$ = $2->addQualifiers( $1 ); }
1962 | direct_type type_qualifier
1963 { $$ = $1->addQualifiers( $2 ); }
1964 | direct_type basic_type_name
1965 { $$ = $1->addType( $2 ); }
1966 ;
1967
1968indirect_type:
1969 TYPEOF '(' type ')' // GCC: typeof( x ) y;
1970 { $$ = $3; }
1971 | TYPEOF '(' comma_expression ')' // GCC: typeof( a+b ) y;
1972 { $$ = DeclarationNode::newTypeof( $3 ); }
1973 | BASETYPEOF '(' type ')' // CFA: basetypeof( x ) y;
1974 { $$ = DeclarationNode::newTypeof( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ), true ); }
1975 | BASETYPEOF '(' comma_expression ')' // CFA: basetypeof( a+b ) y;
1976 { $$ = DeclarationNode::newTypeof( $3, true ); }
1977 | ZERO_T // CFA
1978 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1979 | ONE_T // CFA
1980 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1981 ;
1982
1983sue_declaration_specifier: // struct, union, enum + storage class + type specifier
1984 sue_type_specifier
1985 | declaration_qualifier_list sue_type_specifier
1986 { $$ = $2->addQualifiers( $1 ); }
1987 | sue_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1988 { $$ = $1->addQualifiers( $2 ); }
1989 | sue_declaration_specifier storage_class type_qualifier_list
1990 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1991 ;
1992
1993sue_type_specifier: // struct, union, enum + type specifier
1994 elaborated_type
1995 | type_qualifier_list
1996 { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1997 elaborated_type
1998 { $$ = $3->addQualifiers( $1 ); }
1999 | sue_type_specifier type_qualifier
2000 {
2001 if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
2002 $$ = $1->addQualifiers( $2 );
2003 }
2004 ;
2005
2006sue_declaration_specifier_nobody: // struct, union, enum - {...} + storage class + type specifier
2007 sue_type_specifier_nobody
2008 | declaration_qualifier_list sue_type_specifier_nobody
2009 { $$ = $2->addQualifiers( $1 ); }
2010 | sue_declaration_specifier_nobody storage_class // remaining OBSOLESCENT (see 2)
2011 { $$ = $1->addQualifiers( $2 ); }
2012 | sue_declaration_specifier_nobody storage_class type_qualifier_list
2013 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2014 ;
2015
2016sue_type_specifier_nobody: // struct, union, enum - {...} + type specifier
2017 elaborated_type_nobody
2018 | type_qualifier_list elaborated_type_nobody
2019 { $$ = $2->addQualifiers( $1 ); }
2020 | sue_type_specifier_nobody type_qualifier
2021 { $$ = $1->addQualifiers( $2 ); }
2022 ;
2023
2024type_declaration_specifier:
2025 type_type_specifier
2026 | declaration_qualifier_list type_type_specifier
2027 { $$ = $2->addQualifiers( $1 ); }
2028 | type_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2029 { $$ = $1->addQualifiers( $2 ); }
2030 | type_declaration_specifier storage_class type_qualifier_list
2031 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2032 ;
2033
2034type_type_specifier: // typedef types
2035 type_name
2036 | type_qualifier_list type_name
2037 { $$ = $2->addQualifiers( $1 ); }
2038 | type_type_specifier type_qualifier
2039 { $$ = $1->addQualifiers( $2 ); }
2040 ;
2041
2042type_name:
2043 TYPEDEFname
2044 { $$ = DeclarationNode::newFromTypedef( $1 ); }
2045 | '.' TYPEDEFname
2046 { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
2047 | type_name '.' TYPEDEFname
2048 { $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
2049 | typegen_name
2050 | '.' typegen_name
2051 { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
2052 | type_name '.' typegen_name
2053 { $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
2054 ;
2055
2056typegen_name: // CFA
2057 TYPEGENname
2058 { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2059 | TYPEGENname '(' ')'
2060 { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2061 | TYPEGENname '(' type_list ')'
2062 { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
2063 ;
2064
2065elaborated_type: // struct, union, enum
2066 aggregate_type
2067 | enum_type
2068 ;
2069
2070elaborated_type_nobody: // struct, union, enum - {...}
2071 aggregate_type_nobody
2072 | enum_type_nobody
2073 ;
2074
2075aggregate_type: // struct, union
2076 aggregate_key attribute_list_opt
2077 { forall = false; } // reset
2078 '{' field_declaration_list_opt '}' type_parameters_opt
2079 { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2080 | aggregate_key attribute_list_opt identifier
2081 {
2082 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2083 forall = false; // reset
2084 }
2085 '{' field_declaration_list_opt '}' type_parameters_opt
2086 { $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 ); }
2087 | aggregate_key attribute_list_opt TYPEDEFname // unqualified type name
2088 {
2089 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2090 forall = false; // reset
2091 }
2092 '{' field_declaration_list_opt '}' type_parameters_opt
2093 {
2094 DeclarationNode::newFromTypedef( $3 );
2095 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2096 }
2097 | aggregate_key attribute_list_opt TYPEGENname // unqualified type name
2098 {
2099 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2100 forall = false; // reset
2101 }
2102 '{' field_declaration_list_opt '}' type_parameters_opt
2103 {
2104 DeclarationNode::newFromTypeGen( $3, nullptr );
2105 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2106 }
2107 | aggregate_type_nobody
2108 ;
2109
2110type_parameters_opt:
2111 // empty
2112 { $$ = nullptr; } %prec '}'
2113 | '(' type_list ')'
2114 { $$ = $2; }
2115 ;
2116
2117aggregate_type_nobody: // struct, union - {...}
2118 aggregate_key attribute_list_opt identifier
2119 {
2120 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname );
2121 forall = false; // reset
2122 $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2123 }
2124 | aggregate_key attribute_list_opt type_name
2125 {
2126 forall = false; // reset
2127 // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2128 // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2129 // delete newFromTypeGen.
2130 $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2131 $3->type->symbolic.name = nullptr;
2132 $3->type->symbolic.actuals = nullptr;
2133 delete $3;
2134 }
2135 ;
2136
2137aggregate_key:
2138 aggregate_data
2139 | aggregate_control
2140 ;
2141
2142aggregate_data:
2143 STRUCT vtable_opt
2144 { $$ = AggregateDecl::Struct; }
2145 | UNION
2146 { $$ = AggregateDecl::Union; }
2147 | EXCEPTION // CFA
2148 { $$ = AggregateDecl::Exception; }
2149 // { SemanticError( yylloc, "exception aggregate is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2150 ;
2151
2152aggregate_control: // CFA
2153 MONITOR
2154 { $$ = AggregateDecl::Monitor; }
2155 | MUTEX STRUCT
2156 { $$ = AggregateDecl::Monitor; }
2157 | GENERATOR
2158 { $$ = AggregateDecl::Generator; }
2159 | MUTEX GENERATOR
2160 { SemanticError( yylloc, "monitor generator is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2161 | COROUTINE
2162 { $$ = AggregateDecl::Coroutine; }
2163 | MUTEX COROUTINE
2164 { SemanticError( yylloc, "monitor coroutine is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2165 | THREAD
2166 { $$ = AggregateDecl::Thread; }
2167 | MUTEX THREAD
2168 { SemanticError( yylloc, "monitor thread is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2169 ;
2170
2171field_declaration_list_opt:
2172 // empty
2173 { $$ = nullptr; }
2174 | field_declaration_list_opt field_declaration
2175 { $$ = $1 ? $1->appendList( $2 ) : $2; }
2176 ;
2177
2178field_declaration:
2179 type_specifier field_declaring_list_opt ';'
2180 { $$ = fieldDecl( $1, $2 ); }
2181 | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2182 { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2183 | INLINE type_specifier field_abstract_list_opt ';' // CFA
2184 {
2185 if ( ! $3 ) { // field declarator ?
2186 $3 = DeclarationNode::newName( nullptr );
2187 } // if
2188 $3->inLine = true;
2189 $$ = distAttr( $2, $3 ); // mark all fields in list
2190 distInl( $3 );
2191 }
2192 | INLINE aggregate_control ';' // CFA
2193 { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2194 | typedef_declaration ';' // CFA
2195 | cfa_field_declaring_list ';' // CFA, new style field declaration
2196 | EXTENSION cfa_field_declaring_list ';' // GCC
2197 { distExt( $2 ); $$ = $2; } // mark all fields in list
2198 | INLINE cfa_field_abstract_list ';' // CFA, new style field declaration
2199 { $$ = $2; } // mark all fields in list
2200 | cfa_typedef_declaration ';' // CFA
2201 | static_assert // C11
2202 ;
2203
2204field_declaring_list_opt:
2205 // empty
2206 { $$ = nullptr; }
2207 | field_declarator
2208 | field_declaring_list_opt ',' attribute_list_opt field_declarator
2209 { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2210 ;
2211
2212field_declarator:
2213 bit_subrange_size // C special case, no field name
2214 { $$ = DeclarationNode::newBitfield( $1 ); }
2215 | variable_declarator bit_subrange_size_opt
2216 // A semantic check is required to ensure bit_subrange only appears on integral types.
2217 { $$ = $1->addBitfield( $2 ); }
2218 | variable_type_redeclarator bit_subrange_size_opt
2219 // A semantic check is required to ensure bit_subrange only appears on integral types.
2220 { $$ = $1->addBitfield( $2 ); }
2221 ;
2222
2223field_abstract_list_opt:
2224 // empty
2225 { $$ = nullptr; }
2226 | field_abstract
2227 | field_abstract_list_opt ',' attribute_list_opt field_abstract
2228 { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2229 ;
2230
2231field_abstract:
2232 // no bit fields
2233 variable_abstract_declarator
2234 ;
2235
2236cfa_field_declaring_list: // CFA, new style field declaration
2237 // bit-fields are handled by C declarations
2238 cfa_abstract_declarator_tuple identifier_or_type_name
2239 { $$ = $1->addName( $2 ); }
2240 | cfa_field_declaring_list ',' identifier_or_type_name
2241 { $$ = $1->appendList( $1->cloneType( $3 ) ); }
2242 ;
2243
2244cfa_field_abstract_list: // CFA, new style field declaration
2245 // bit-fields are handled by C declarations
2246 cfa_abstract_declarator_tuple
2247 | cfa_field_abstract_list ','
2248 { $$ = $1->appendList( $1->cloneType( 0 ) ); }
2249 ;
2250
2251bit_subrange_size_opt:
2252 // empty
2253 { $$ = nullptr; }
2254 | bit_subrange_size
2255 ;
2256
2257bit_subrange_size:
2258 ':' assignment_expression
2259 { $$ = $2; }
2260 ;
2261
2262enum_type: // enum
2263 ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2264 { $$ = DeclarationNode::newEnum( nullptr, $4, true )->addQualifiers( $2 ); }
2265 | ENUM attribute_list_opt identifier
2266 { typedefTable.makeTypedef( *$3 ); }
2267 '{' enumerator_list comma_opt '}'
2268 { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
2269 | ENUM attribute_list_opt typedef_name // unqualified type name
2270 '{' enumerator_list comma_opt '}'
2271 { $$ = DeclarationNode::newEnum( $3->name, $5, true )->addQualifiers( $2 ); }
2272 | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt '{' enumerator_list comma_opt '}'
2273 {
2274 if ( $3->storageClasses.val != 0 || $3->type->qualifiers.val != 0 ) { SemanticError( yylloc, "storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." ); }
2275 SemanticError( yylloc, "Typed enumeration is currently unimplemented." ); $$ = nullptr;
2276 }
2277 | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt identifier attribute_list_opt
2278 {
2279 if ( $3->storageClasses.val != 0 || $3->type->qualifiers.val != 0 ) { SemanticError( yylloc, "storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." ); }
2280 typedefTable.makeTypedef( *$6 );
2281 }
2282 '{' enumerator_list comma_opt '}'
2283 {
2284 SemanticError( yylloc, "Typed enumeration is currently unimplemented." ); $$ = nullptr;
2285 }
2286 | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt typedef_name attribute_list_opt '{' enumerator_list comma_opt '}'
2287 {
2288 if ( $3->storageClasses.val != 0 || $3->type->qualifiers.val != 0 ) { SemanticError( yylloc, "storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." ); }
2289 typedefTable.makeTypedef( *$6->name );
2290 SemanticError( yylloc, "Typed enumeration is currently unimplemented." ); $$ = nullptr;
2291 }
2292 | enum_type_nobody
2293 ;
2294
2295enum_type_nobody: // enum - {...}
2296 ENUM attribute_list_opt identifier
2297 { typedefTable.makeTypedef( *$3 ); $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 ); }
2298 | ENUM attribute_list_opt type_name // qualified type name
2299 { typedefTable.makeTypedef( *$3->type->symbolic.name ); $$ = DeclarationNode::newEnum( $3->type->symbolic.name, 0, false )->addQualifiers( $2 ); }
2300 ;
2301
2302enumerator_list:
2303 identifier_or_type_name enumerator_value_opt
2304 { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
2305 | INLINE type_name
2306 { $$ = DeclarationNode::newEnumConstant( new string("inline"), nullptr ); }
2307 | enumerator_list ',' identifier_or_type_name enumerator_value_opt
2308 { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
2309 | enumerator_list ',' INLINE type_name enumerator_value_opt
2310 { $$ = $1->appendList( DeclarationNode::newEnumConstant( new string("inline"), nullptr ) ); }
2311 ;
2312
2313enumerator_value_opt:
2314 // empty
2315 { $$ = nullptr; }
2316 // | '=' constant_expression
2317 // { $$ = $2; }
2318 | simple_assignment_operator initializer
2319 { $$ = $2->get_expression(); } // FIX ME: enum only deals with constant_expression
2320 ;
2321
2322cfa_parameter_ellipsis_list_opt: // CFA, abstract + real
2323 // empty
2324 { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2325 | ELLIPSIS
2326 { $$ = nullptr; }
2327 | cfa_abstract_parameter_list
2328 | cfa_parameter_list
2329 | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2330 { $$ = $1->appendList( $5 ); }
2331 | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2332 { $$ = $1->addVarArgs(); }
2333 | cfa_parameter_list pop ',' push ELLIPSIS
2334 { $$ = $1->addVarArgs(); }
2335 ;
2336
2337cfa_parameter_list: // CFA
2338 // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2339 // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2340 cfa_parameter_declaration
2341 | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2342 { $$ = $1->appendList( $5 ); }
2343 | cfa_parameter_list pop ',' push cfa_parameter_declaration
2344 { $$ = $1->appendList( $5 ); }
2345 | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2346 { $$ = $1->appendList( $5 )->appendList( $9 ); }
2347 ;
2348
2349cfa_abstract_parameter_list: // CFA, new & old style abstract
2350 cfa_abstract_parameter_declaration
2351 | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2352 { $$ = $1->appendList( $5 ); }
2353 ;
2354
2355parameter_type_list_opt:
2356 // empty
2357 { $$ = nullptr; }
2358 | ELLIPSIS
2359 { $$ = nullptr; }
2360 | parameter_list
2361 | parameter_list pop ',' push ELLIPSIS
2362 { $$ = $1->addVarArgs(); }
2363 ;
2364
2365parameter_list: // abstract + real
2366 abstract_parameter_declaration
2367 | parameter_declaration
2368 | parameter_list pop ',' push abstract_parameter_declaration
2369 { $$ = $1->appendList( $5 ); }
2370 | parameter_list pop ',' push parameter_declaration
2371 { $$ = $1->appendList( $5 ); }
2372 ;
2373
2374// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2375// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2376
2377cfa_parameter_declaration: // CFA, new & old style parameter declaration
2378 parameter_declaration
2379 | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initializer_opt
2380 { $$ = $1->addName( $2 ); }
2381 | cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2382 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2383 { $$ = $1->addName( $2 ); }
2384 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2385 { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2386 | cfa_function_specifier
2387 ;
2388
2389cfa_abstract_parameter_declaration: // CFA, new & old style parameter declaration
2390 abstract_parameter_declaration
2391 | cfa_identifier_parameter_declarator_no_tuple
2392 | cfa_abstract_tuple
2393 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2394 | type_qualifier_list cfa_abstract_tuple
2395 { $$ = $2->addQualifiers( $1 ); }
2396 | cfa_abstract_function
2397 ;
2398
2399parameter_declaration:
2400 // No SUE declaration in parameter list.
2401 declaration_specifier_nobody identifier_parameter_declarator default_initializer_opt
2402 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2403 | declaration_specifier_nobody type_parameter_redeclarator default_initializer_opt
2404 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2405 ;
2406
2407abstract_parameter_declaration:
2408 declaration_specifier_nobody default_initializer_opt
2409 { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2410 | declaration_specifier_nobody abstract_parameter_declarator default_initializer_opt
2411 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2412 ;
2413
2414// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2415// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2416// identifiers. The ANSI-style parameter-list can redefine a typedef name.
2417
2418identifier_list: // K&R-style parameter list => no types
2419 identifier
2420 { $$ = DeclarationNode::newName( $1 ); }
2421 | identifier_list ',' identifier
2422 { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2423 ;
2424
2425identifier_or_type_name:
2426 identifier
2427 | TYPEDEFname
2428 | TYPEGENname
2429 ;
2430
2431type_no_function: // sizeof, alignof, cast (constructor)
2432 cfa_abstract_declarator_tuple // CFA
2433 | type_specifier
2434 | type_specifier abstract_declarator
2435 { $$ = $2->addType( $1 ); }
2436 ;
2437
2438type: // typeof, assertion
2439 type_no_function
2440 | cfa_abstract_function // CFA
2441 ;
2442
2443initializer_opt:
2444 // empty
2445 { $$ = nullptr; }
2446 | simple_assignment_operator initializer { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2447 | '=' VOID { $$ = new InitializerNode( true ); }
2448 ;
2449
2450initializer:
2451 assignment_expression { $$ = new InitializerNode( $1 ); }
2452 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
2453 ;
2454
2455initializer_list_opt:
2456 // empty
2457 { $$ = nullptr; }
2458 | initializer
2459 | designation initializer { $$ = $2->set_designators( $1 ); }
2460 | initializer_list_opt ',' initializer { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2461 | initializer_list_opt ',' designation initializer
2462 { $$ = (InitializerNode *)($1->set_last( $4->set_designators( $3 ) )); }
2463 ;
2464
2465// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2466// '=' to separator the designator from the initializer value, as in:
2467//
2468// int x[10] = { [1] = 3 };
2469//
2470// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment. To disambiguate this case, CFA
2471// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2472// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2473// shift/reduce conflicts
2474
2475designation:
2476 designator_list ':' // C99, CFA uses ":" instead of "="
2477 | identifier ':' // GCC, field name
2478 { $$ = new ExpressionNode( build_varref( $1 ) ); }
2479 ;
2480
2481designator_list: // C99
2482 designator
2483 | designator_list designator
2484 { $$ = (ExpressionNode *)($1->set_last( $2 )); }
2485 //| designator_list designator { $$ = new ExpressionNode( $1, $2 ); }
2486 ;
2487
2488designator:
2489 '.' identifier // C99, field name
2490 { $$ = new ExpressionNode( build_varref( $2 ) ); }
2491 | '[' push assignment_expression pop ']' // C99, single array element
2492 // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2493 { $$ = $3; }
2494 | '[' push subrange pop ']' // CFA, multiple array elements
2495 { $$ = $3; }
2496 | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2497 { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild<Expression>( $3 ), maybeMoveBuild<Expression>( $5 ) ) ); }
2498 | '.' '[' push field_name_list pop ']' // CFA, tuple field selector
2499 { $$ = $4; }
2500 ;
2501
2502// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2503// rather than an object-oriented type system. This required four groups of extensions:
2504//
2505// Overloading: function, data, and operator identifiers may be overloaded.
2506//
2507// Type declarations: "otype" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2508// and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2509// definitions of new types. Type declarations with storage class "extern" provide opaque types.
2510//
2511// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2512// site. A polymorphic function is not a template; it is a function, with an address and a type.
2513//
2514// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2515// types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2516// hierarchies. Unlike classes, they can define relationships between types. Assertions declare that a type or
2517// types provide the operations declared by a specification. Assertions are normally used to declare requirements
2518// on type arguments of polymorphic functions.
2519
2520type_parameter_list: // CFA
2521 type_parameter
2522 | type_parameter_list ',' type_parameter
2523 { $$ = $1->appendList( $3 ); }
2524 ;
2525
2526type_initializer_opt: // CFA
2527 // empty
2528 { $$ = nullptr; }
2529 | '=' type
2530 { $$ = $2; }
2531 ;
2532
2533type_parameter: // CFA
2534 type_class identifier_or_type_name
2535 {
2536 typedefTable.addToScope( *$2, TYPEDEFname, "9" );
2537 if ( $1 == TypeDecl::Otype ) { SemanticError( yylloc, "otype keyword is deprecated, use T " ); }
2538 if ( $1 == TypeDecl::Dtype ) { SemanticError( yylloc, "dtype keyword is deprecated, use T &" ); }
2539 if ( $1 == TypeDecl::Ttype ) { SemanticError( yylloc, "ttype keyword is deprecated, use T ..." ); }
2540 }
2541 type_initializer_opt assertion_list_opt
2542 { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2543 | identifier_or_type_name new_type_class
2544 { typedefTable.addToScope( *$1, TYPEDEFname, "9" ); }
2545 type_initializer_opt assertion_list_opt
2546 { $$ = DeclarationNode::newTypeParam( $2, $1 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2547 | '[' identifier_or_type_name ']'
2548 {
2549 typedefTable.addToScope( *$2, TYPEDIMname, "9" );
2550 $$ = DeclarationNode::newTypeParam( TypeDecl::Dimension, $2 );
2551 }
2552 // | type_specifier identifier_parameter_declarator
2553 | assertion_list
2554 { $$ = DeclarationNode::newTypeParam( TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2555 ;
2556
2557new_type_class: // CFA
2558 // empty
2559 { $$ = TypeDecl::Otype; }
2560 | '&'
2561 { $$ = TypeDecl::Dtype; }
2562 | '*'
2563 { $$ = TypeDecl::DStype; } // dtype + sized
2564 // | '(' '*' ')'
2565 // { $$ = TypeDecl::Ftype; }
2566 | ELLIPSIS
2567 { $$ = TypeDecl::Ttype; }
2568 ;
2569
2570type_class: // CFA
2571 OTYPE
2572 { $$ = TypeDecl::Otype; }
2573 | DTYPE
2574 { $$ = TypeDecl::Dtype; }
2575 | FTYPE
2576 { $$ = TypeDecl::Ftype; }
2577 | TTYPE
2578 { $$ = TypeDecl::Ttype; }
2579 ;
2580
2581assertion_list_opt: // CFA
2582 // empty
2583 { $$ = nullptr; }
2584 | assertion_list
2585 ;
2586
2587assertion_list: // CFA
2588 assertion
2589 | assertion_list assertion
2590 { $$ = $1->appendList( $2 ); }
2591 ;
2592
2593assertion: // CFA
2594 '|' identifier_or_type_name '(' type_list ')'
2595 { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
2596 | '|' '{' push trait_declaration_list pop '}'
2597 { $$ = $4; }
2598 // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
2599 // { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
2600 ;
2601
2602type_list: // CFA
2603 type
2604 { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2605 | assignment_expression
2606 | type_list ',' type
2607 { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) )); }
2608 | type_list ',' assignment_expression
2609 { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2610 ;
2611
2612type_declaring_list: // CFA
2613 OTYPE type_declarator
2614 { $$ = $2; }
2615 | storage_class_list OTYPE type_declarator
2616 { $$ = $3->addQualifiers( $1 ); }
2617 | type_declaring_list ',' type_declarator
2618 { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2619 ;
2620
2621type_declarator: // CFA
2622 type_declarator_name assertion_list_opt
2623 { $$ = $1->addAssertions( $2 ); }
2624 | type_declarator_name assertion_list_opt '=' type
2625 { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2626 ;
2627
2628type_declarator_name: // CFA
2629 identifier_or_type_name
2630 {
2631 typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "10" );
2632 $$ = DeclarationNode::newTypeDecl( $1, 0 );
2633 }
2634 | identifier_or_type_name '(' type_parameter_list ')'
2635 {
2636 typedefTable.addToEnclosingScope( *$1, TYPEGENname, "11" );
2637 $$ = DeclarationNode::newTypeDecl( $1, $3 );
2638 }
2639 ;
2640
2641trait_specifier: // CFA
2642 TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
2643 { $$ = DeclarationNode::newTrait( $2, $4, 0 ); }
2644 | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
2645 { $$ = DeclarationNode::newTrait( $2, $4, $8 ); }
2646 ;
2647
2648trait_declaration_list: // CFA
2649 trait_declaration
2650 | trait_declaration_list pop push trait_declaration
2651 { $$ = $1->appendList( $4 ); }
2652 ;
2653
2654trait_declaration: // CFA
2655 cfa_trait_declaring_list ';'
2656 | trait_declaring_list ';'
2657 ;
2658
2659cfa_trait_declaring_list: // CFA
2660 cfa_variable_specifier
2661 | cfa_function_specifier
2662 | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2663 { $$ = $1->appendList( $1->cloneType( $5 ) ); }
2664 ;
2665
2666trait_declaring_list: // CFA
2667 type_specifier declarator
2668 { $$ = $2->addType( $1 ); }
2669 | trait_declaring_list pop ',' push declarator
2670 { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
2671 ;
2672
2673//***************************** EXTERNAL DEFINITIONS *****************************
2674
2675translation_unit:
2676 // empty, input file
2677 | external_definition_list
2678 { parseTree = parseTree ? parseTree->appendList( $1 ) : $1; }
2679 ;
2680
2681external_definition_list:
2682 push external_definition pop
2683 { $$ = $2; }
2684 | external_definition_list push external_definition pop
2685 { $$ = $1 ? $1->appendList( $3 ) : $3; }
2686 ;
2687
2688external_definition_list_opt:
2689 // empty
2690 { $$ = nullptr; }
2691 | external_definition_list
2692 ;
2693
2694up:
2695 { typedefTable.up( forall ); forall = false; }
2696 ;
2697
2698down:
2699 { typedefTable.down(); }
2700 ;
2701
2702external_definition:
2703 DIRECTIVE
2704 { $$ = DeclarationNode::newDirectiveStmt( new StatementNode( build_directive( $1 ) ) ); }
2705 | declaration
2706 | external_function_definition
2707 | EXTENSION external_definition // GCC, multiple __extension__ allowed, meaning unknown
2708 {
2709 distExt( $2 ); // mark all fields in list
2710 $$ = $2;
2711 }
2712 | ASM '(' string_literal ')' ';' // GCC, global assembler statement
2713 { $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( false, $3, 0 ) ) ); }
2714 | EXTERN STRINGliteral // C++-style linkage specifier
2715 {
2716 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
2717 linkage = LinkageSpec::update( yylloc, linkage, $2 );
2718 }
2719 '{' up external_definition_list_opt down '}'
2720 {
2721 linkage = linkageStack.top();
2722 linkageStack.pop();
2723 $$ = $6;
2724 }
2725 | type_qualifier_list
2726 {
2727 if ( $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2728 if ( $1->type->forall ) forall = true; // remember generic type
2729 }
2730 '{' up external_definition_list_opt down '}' // CFA, namespace
2731 {
2732 distQual( $5, $1 );
2733 forall = false;
2734 $$ = $5;
2735 }
2736 | declaration_qualifier_list
2737 {
2738 if ( $1->type && $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2739 if ( $1->type && $1->type->forall ) forall = true; // remember generic type
2740 }
2741 '{' up external_definition_list_opt down '}' // CFA, namespace
2742 {
2743 distQual( $5, $1 );
2744 forall = false;
2745 $$ = $5;
2746 }
2747 | declaration_qualifier_list type_qualifier_list
2748 {
2749 if ( ($1->type && $1->type->qualifiers.val) || $2->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2750 if ( ($1->type && $1->type->forall) || $2->type->forall ) forall = true; // remember generic type
2751 }
2752 '{' up external_definition_list_opt down '}' // CFA, namespace
2753 {
2754 distQual( $6, $1->addQualifiers( $2 ) );
2755 forall = false;
2756 $$ = $6;
2757 }
2758 ;
2759
2760external_function_definition:
2761 function_definition
2762 // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2763 // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2764 // Parsing is possible because function_definition does not appear in the context of an expression (nested
2765 // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2766 // declaration must still have a type_specifier. OBSOLESCENT (see 1)
2767 | function_declarator compound_statement
2768 { $$ = $1->addFunctionBody( $2 ); }
2769 | KR_function_declarator KR_parameter_list_opt compound_statement
2770 { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
2771 ;
2772
2773with_clause_opt:
2774 // empty
2775 { $$ = nullptr; forall = false; }
2776 | WITH '(' tuple_expression_list ')'
2777 { $$ = $3; forall = false; }
2778 ;
2779
2780function_definition:
2781 cfa_function_declaration with_clause_opt compound_statement // CFA
2782 {
2783 // Add the function body to the last identifier in the function definition list, i.e., foo3:
2784 // [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2785 $1->get_last()->addFunctionBody( $3, $2 );
2786 $$ = $1;
2787 }
2788 | declaration_specifier function_declarator with_clause_opt compound_statement
2789 {
2790 rebindForall( $1, $2 );
2791 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2792 }
2793 | declaration_specifier variable_type_redeclarator with_clause_opt compound_statement
2794 {
2795 rebindForall( $1, $2 );
2796 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2797 }
2798 // handles default int return type, OBSOLESCENT (see 1)
2799 | type_qualifier_list function_declarator with_clause_opt compound_statement
2800 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2801 // handles default int return type, OBSOLESCENT (see 1)
2802 | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2803 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2804 // handles default int return type, OBSOLESCENT (see 1)
2805 | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2806 { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2807
2808 // Old-style K&R function definition, OBSOLESCENT (see 4)
2809 | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2810 {
2811 rebindForall( $1, $2 );
2812 $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2813 }
2814 // handles default int return type, OBSOLESCENT (see 1)
2815 | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2816 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2817 // handles default int return type, OBSOLESCENT (see 1)
2818 | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2819 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2820 // handles default int return type, OBSOLESCENT (see 1)
2821 | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2822 { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2823 ;
2824
2825declarator:
2826 variable_declarator
2827 | variable_type_redeclarator
2828 | function_declarator
2829 ;
2830
2831subrange:
2832 constant_expression '~' constant_expression // CFA, integer subrange
2833 { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild<Expression>( $1 ), maybeMoveBuild<Expression>( $3 ) ) ); }
2834 ;
2835
2836asm_name_opt: // GCC
2837 // empty
2838 { $$ = nullptr; }
2839 | ASM '(' string_literal ')' attribute_list_opt
2840 {
2841 DeclarationNode * name = new DeclarationNode();
2842 name->asmName = $3;
2843 $$ = name->addQualifiers( $5 );
2844 }
2845 ;
2846
2847attribute_list_opt: // GCC
2848 // empty
2849 { $$ = nullptr; }
2850 | attribute_list
2851 ;
2852
2853attribute_list: // GCC
2854 attribute
2855 | attribute_list attribute
2856 { $$ = $2->addQualifiers( $1 ); }
2857 ;
2858
2859attribute: // GCC
2860 ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2861 { $$ = $4; }
2862 ;
2863
2864attribute_name_list: // GCC
2865 attribute_name
2866 | attribute_name_list ',' attribute_name
2867 { $$ = $3->addQualifiers( $1 ); }
2868 ;
2869
2870attribute_name: // GCC
2871 // empty
2872 { $$ = nullptr; }
2873 | attr_name
2874 { $$ = DeclarationNode::newAttribute( $1 ); }
2875 | attr_name '(' argument_expression_list_opt ')'
2876 { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2877 ;
2878
2879attr_name: // GCC
2880 IDENTIFIER
2881 | quasi_keyword
2882 | TYPEDEFname
2883 | TYPEGENname
2884 | FALLTHROUGH
2885 { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2886 | CONST
2887 { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2888 ;
2889
2890// ============================================================================
2891// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2892// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2893// in:
2894//
2895// int (*f())[10] { ... };
2896// ... (*f())[3] += 1; // definition mimics usage
2897//
2898// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2899// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2900// ============================================================================
2901
2902// ----------------------------------------------------------------------------
2903// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2904// to define a variable or function prototype, e.g.:
2905//
2906// valid declaration invalid definition
2907// ----------------- ------------------
2908// int f; int f {}
2909// int *f; int *f {}
2910// int f[10]; int f[10] {}
2911// int (*f)(int); int (*f)(int) {}
2912//
2913// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2914// variable_declarator and function_declarator.
2915// ----------------------------------------------------------------------------
2916
2917// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2918// declaring an array of functions versus a pointer to an array of functions.
2919
2920paren_identifier:
2921 identifier
2922 { $$ = DeclarationNode::newName( $1 ); }
2923 | '(' paren_identifier ')' // redundant parenthesis
2924 { $$ = $2; }
2925 ;
2926
2927variable_declarator:
2928 paren_identifier attribute_list_opt
2929 { $$ = $1->addQualifiers( $2 ); }
2930 | variable_ptr
2931 | variable_array attribute_list_opt
2932 { $$ = $1->addQualifiers( $2 ); }
2933 | variable_function attribute_list_opt
2934 { $$ = $1->addQualifiers( $2 ); }
2935 ;
2936
2937variable_ptr:
2938 ptrref_operator variable_declarator
2939 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2940 | ptrref_operator type_qualifier_list variable_declarator
2941 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2942 | '(' variable_ptr ')' attribute_list_opt // redundant parenthesis
2943 { $$ = $2->addQualifiers( $4 ); }
2944 | '(' attribute_list variable_ptr ')' attribute_list_opt // redundant parenthesis
2945 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
2946 ;
2947
2948variable_array:
2949 paren_identifier array_dimension
2950 { $$ = $1->addArray( $2 ); }
2951 | '(' variable_ptr ')' array_dimension
2952 { $$ = $2->addArray( $4 ); }
2953 | '(' attribute_list variable_ptr ')' array_dimension
2954 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
2955 | '(' variable_array ')' multi_array_dimension // redundant parenthesis
2956 { $$ = $2->addArray( $4 ); }
2957 | '(' attribute_list variable_array ')' multi_array_dimension // redundant parenthesis
2958 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
2959 | '(' variable_array ')' // redundant parenthesis
2960 { $$ = $2; }
2961 | '(' attribute_list variable_array ')' // redundant parenthesis
2962 { $$ = $3->addQualifiers( $2 ); }
2963 ;
2964
2965variable_function:
2966 '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2967 { $$ = $2->addParamList( $6 ); }
2968 | '(' attribute_list variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2969 { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
2970 | '(' variable_function ')' // redundant parenthesis
2971 { $$ = $2; }
2972 | '(' attribute_list variable_function ')' // redundant parenthesis
2973 { $$ = $3->addQualifiers( $2 ); }
2974 ;
2975
2976// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2977// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2978// is the same scope. The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2979
2980function_declarator:
2981 function_no_ptr attribute_list_opt
2982 { $$ = $1->addQualifiers( $2 ); }
2983 | function_ptr
2984 | function_array attribute_list_opt
2985 { $$ = $1->addQualifiers( $2 ); }
2986 ;
2987
2988function_no_ptr:
2989 paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2990 { $$ = $1->addParamList( $4 ); }
2991 | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2992 { $$ = $2->addParamList( $6 ); }
2993 | '(' attribute_list function_ptr ')' '(' push parameter_type_list_opt pop ')'
2994 { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
2995 | '(' function_no_ptr ')' // redundant parenthesis
2996 { $$ = $2; }
2997 | '(' attribute_list function_no_ptr ')' // redundant parenthesis
2998 { $$ = $3->addQualifiers( $2 ); }
2999 ;
3000
3001function_ptr:
3002 ptrref_operator function_declarator
3003 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3004 | ptrref_operator type_qualifier_list function_declarator
3005 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3006 | '(' function_ptr ')' attribute_list_opt
3007 { $$ = $2->addQualifiers( $4 ); }
3008 | '(' attribute_list function_ptr ')' attribute_list_opt
3009 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3010 ;
3011
3012function_array:
3013 '(' function_ptr ')' array_dimension
3014 { $$ = $2->addArray( $4 ); }
3015 | '(' attribute_list function_ptr ')' array_dimension
3016 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3017 | '(' function_array ')' multi_array_dimension // redundant parenthesis
3018 { $$ = $2->addArray( $4 ); }
3019 | '(' attribute_list function_array ')' multi_array_dimension // redundant parenthesis
3020 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3021 | '(' function_array ')' // redundant parenthesis
3022 { $$ = $2; }
3023 | '(' attribute_list function_array ')' // redundant parenthesis
3024 { $$ = $3->addQualifiers( $2 ); }
3025 ;
3026
3027// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
3028//
3029// f( a, b, c ) int a, *b, c[]; {}
3030//
3031// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
3032// returning arrays and functions versus pointers to arrays and functions.
3033
3034KR_function_declarator:
3035 KR_function_no_ptr
3036 | KR_function_ptr
3037 | KR_function_array
3038 ;
3039
3040KR_function_no_ptr:
3041 paren_identifier '(' identifier_list ')' // function_declarator handles empty parameter
3042 { $$ = $1->addIdList( $3 ); }
3043 | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
3044 { $$ = $2->addParamList( $6 ); }
3045 | '(' attribute_list KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
3046 { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
3047 | '(' KR_function_no_ptr ')' // redundant parenthesis
3048 { $$ = $2; }
3049 | '(' attribute_list KR_function_no_ptr ')' // redundant parenthesis
3050 { $$ = $3->addQualifiers( $2 ); }
3051 ;
3052
3053KR_function_ptr:
3054 ptrref_operator KR_function_declarator
3055 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3056 | ptrref_operator type_qualifier_list KR_function_declarator
3057 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3058 | '(' KR_function_ptr ')'
3059 { $$ = $2; }
3060 | '(' attribute_list KR_function_ptr ')'
3061 { $$ = $3->addQualifiers( $2 ); }
3062 ;
3063
3064KR_function_array:
3065 '(' KR_function_ptr ')' array_dimension
3066 { $$ = $2->addArray( $4 ); }
3067 | '(' attribute_list KR_function_ptr ')' array_dimension
3068 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3069 | '(' KR_function_array ')' multi_array_dimension // redundant parenthesis
3070 { $$ = $2->addArray( $4 ); }
3071 | '(' attribute_list KR_function_array ')' multi_array_dimension // redundant parenthesis
3072 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3073 | '(' KR_function_array ')' // redundant parenthesis
3074 { $$ = $2; }
3075 | '(' attribute_list KR_function_array ')' // redundant parenthesis
3076 { $$ = $3->addQualifiers( $2 ); }
3077 ;
3078
3079// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
3080//
3081// typedef int foo;
3082// {
3083// int foo; // redefine typedef name in new scope
3084// }
3085//
3086// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3087// and functions versus pointers to arrays and functions.
3088
3089paren_type:
3090 typedef_name
3091 {
3092 // hide type name in enclosing scope by variable name
3093 typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "ID" );
3094 }
3095 | '(' paren_type ')'
3096 { $$ = $2; }
3097 ;
3098
3099variable_type_redeclarator:
3100 paren_type attribute_list_opt
3101 { $$ = $1->addQualifiers( $2 ); }
3102 | type_ptr
3103 | type_array attribute_list_opt
3104 { $$ = $1->addQualifiers( $2 ); }
3105 | type_function attribute_list_opt
3106 { $$ = $1->addQualifiers( $2 ); }
3107 ;
3108
3109type_ptr:
3110 ptrref_operator variable_type_redeclarator
3111 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3112 | ptrref_operator type_qualifier_list variable_type_redeclarator
3113 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3114 | '(' type_ptr ')' attribute_list_opt // redundant parenthesis
3115 { $$ = $2->addQualifiers( $4 ); }
3116 | '(' attribute_list type_ptr ')' attribute_list_opt // redundant parenthesis
3117 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3118 ;
3119
3120type_array:
3121 paren_type array_dimension
3122 { $$ = $1->addArray( $2 ); }
3123 | '(' type_ptr ')' array_dimension
3124 { $$ = $2->addArray( $4 ); }
3125 | '(' attribute_list type_ptr ')' array_dimension
3126 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3127 | '(' type_array ')' multi_array_dimension // redundant parenthesis
3128 { $$ = $2->addArray( $4 ); }
3129 | '(' attribute_list type_array ')' multi_array_dimension // redundant parenthesis
3130 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3131 | '(' type_array ')' // redundant parenthesis
3132 { $$ = $2; }
3133 | '(' attribute_list type_array ')' // redundant parenthesis
3134 { $$ = $3->addQualifiers( $2 ); }
3135 ;
3136
3137type_function:
3138 paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3139 { $$ = $1->addParamList( $4 ); }
3140 | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3141 { $$ = $2->addParamList( $6 ); }
3142 | '(' attribute_list type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3143 { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
3144 | '(' type_function ')' // redundant parenthesis
3145 { $$ = $2; }
3146 | '(' attribute_list type_function ')' // redundant parenthesis
3147 { $$ = $3->addQualifiers( $2 ); }
3148 ;
3149
3150// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
3151// typedef name and allows the C99 array options, which can only appear in a parameter list. The pattern precludes
3152// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
3153// pointers to arrays and functions.
3154
3155identifier_parameter_declarator:
3156 paren_identifier attribute_list_opt
3157 { $$ = $1->addQualifiers( $2 ); }
3158 | '&' MUTEX paren_identifier attribute_list_opt
3159 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3160 | identifier_parameter_ptr
3161 | identifier_parameter_array attribute_list_opt
3162 { $$ = $1->addQualifiers( $2 ); }
3163 | identifier_parameter_function attribute_list_opt
3164 { $$ = $1->addQualifiers( $2 ); }
3165 ;
3166
3167identifier_parameter_ptr:
3168 ptrref_operator identifier_parameter_declarator
3169 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3170 | ptrref_operator type_qualifier_list identifier_parameter_declarator
3171 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3172 | '(' identifier_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3173 { $$ = $2->addQualifiers( $4 ); }
3174 ;
3175
3176identifier_parameter_array:
3177 paren_identifier array_parameter_dimension
3178 { $$ = $1->addArray( $2 ); }
3179 | '(' identifier_parameter_ptr ')' array_dimension
3180 { $$ = $2->addArray( $4 ); }
3181 | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3182 { $$ = $2->addArray( $4 ); }
3183 | '(' identifier_parameter_array ')' // redundant parenthesis
3184 { $$ = $2; }
3185 ;
3186
3187identifier_parameter_function:
3188 paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3189 { $$ = $1->addParamList( $4 ); }
3190 | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3191 { $$ = $2->addParamList( $6 ); }
3192 | '(' identifier_parameter_function ')' // redundant parenthesis
3193 { $$ = $2; }
3194 ;
3195
3196// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3197// e.g.:
3198//
3199// typedef int foo;
3200// forall( otype T ) struct foo;
3201// int f( int foo ); // redefine typedef name in new scope
3202//
3203// and allows the C99 array options, which can only appear in a parameter list.
3204
3205type_parameter_redeclarator:
3206 typedef_name attribute_list_opt
3207 { $$ = $1->addQualifiers( $2 ); }
3208 | '&' MUTEX typedef_name attribute_list_opt
3209 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3210 | type_parameter_ptr
3211 | type_parameter_array attribute_list_opt
3212 { $$ = $1->addQualifiers( $2 ); }
3213 | type_parameter_function attribute_list_opt
3214 { $$ = $1->addQualifiers( $2 ); }
3215 ;
3216
3217typedef_name:
3218 TYPEDEFname
3219 { $$ = DeclarationNode::newName( $1 ); }
3220 | TYPEGENname
3221 { $$ = DeclarationNode::newName( $1 ); }
3222 ;
3223
3224type_parameter_ptr:
3225 ptrref_operator type_parameter_redeclarator
3226 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3227 | ptrref_operator type_qualifier_list type_parameter_redeclarator
3228 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3229 | '(' type_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3230 { $$ = $2->addQualifiers( $4 ); }
3231 ;
3232
3233type_parameter_array:
3234 typedef_name array_parameter_dimension
3235 { $$ = $1->addArray( $2 ); }
3236 | '(' type_parameter_ptr ')' array_parameter_dimension
3237 { $$ = $2->addArray( $4 ); }
3238 ;
3239
3240type_parameter_function:
3241 typedef_name '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3242 { $$ = $1->addParamList( $4 ); }
3243 | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3244 { $$ = $2->addParamList( $6 ); }
3245 ;
3246
3247// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3248// which the type applies, e.g.:
3249//
3250// sizeof( int );
3251// sizeof( int * );
3252// sizeof( int [10] );
3253// sizeof( int (*)() );
3254// sizeof( int () );
3255//
3256// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3257// and functions versus pointers to arrays and functions.
3258
3259abstract_declarator:
3260 abstract_ptr
3261 | abstract_array attribute_list_opt
3262 { $$ = $1->addQualifiers( $2 ); }
3263 | abstract_function attribute_list_opt
3264 { $$ = $1->addQualifiers( $2 ); }
3265 ;
3266
3267abstract_ptr:
3268 ptrref_operator
3269 { $$ = DeclarationNode::newPointer( 0, $1 ); }
3270 | ptrref_operator type_qualifier_list
3271 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3272 | ptrref_operator abstract_declarator
3273 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3274 | ptrref_operator type_qualifier_list abstract_declarator
3275 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3276 | '(' abstract_ptr ')' attribute_list_opt
3277 { $$ = $2->addQualifiers( $4 ); }
3278 ;
3279
3280abstract_array:
3281 array_dimension
3282 | '(' abstract_ptr ')' array_dimension
3283 { $$ = $2->addArray( $4 ); }
3284 | '(' abstract_array ')' multi_array_dimension // redundant parenthesis
3285 { $$ = $2->addArray( $4 ); }
3286 | '(' abstract_array ')' // redundant parenthesis
3287 { $$ = $2; }
3288 ;
3289
3290abstract_function:
3291 '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3292 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3293 | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3294 { $$ = $2->addParamList( $6 ); }
3295 | '(' abstract_function ')' // redundant parenthesis
3296 { $$ = $2; }
3297 ;
3298
3299array_dimension:
3300 // Only the first dimension can be empty.
3301 '[' ']'
3302 { $$ = DeclarationNode::newArray( 0, 0, false ); }
3303 | '[' ']' multi_array_dimension
3304 { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
3305 | '[' push assignment_expression pop ',' comma_expression ']'
3306 { $$ = DeclarationNode::newArray( $3, 0, false )->addArray( DeclarationNode::newArray( $6, 0, false ) ); }
3307 // { SemanticError( yylloc, "New array dimension is currently unimplemented." ); $$ = nullptr; }
3308 | multi_array_dimension
3309 ;
3310
3311multi_array_dimension:
3312 '[' push assignment_expression pop ']'
3313 { $$ = DeclarationNode::newArray( $3, 0, false ); }
3314 | '[' push '*' pop ']' // C99
3315 { $$ = DeclarationNode::newVarArray( 0 ); }
3316 | multi_array_dimension '[' push assignment_expression pop ']'
3317 { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
3318 | multi_array_dimension '[' push '*' pop ']' // C99
3319 { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3320 ;
3321
3322// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3323// identifier to which the type applies, e.g.:
3324//
3325// int f( int ); // not handled here
3326// int f( int * ); // abstract function-prototype parameter; no parameter name specified
3327// int f( int (*)() ); // abstract function-prototype parameter; no parameter name specified
3328// int f( int (int) ); // abstract function-prototype parameter; no parameter name specified
3329//
3330// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3331// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3332// special meaning of parenthesis around a typedef name:
3333//
3334// ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3335// parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3336// not as redundant parentheses around the identifier."
3337//
3338// For example:
3339//
3340// typedef float T;
3341// int f( int ( T [5] ) ); // see abstract_parameter_declarator
3342// int g( int ( T ( int ) ) ); // see abstract_parameter_declarator
3343// int f( int f1( T a[5] ) ); // see identifier_parameter_declarator
3344// int g( int g1( T g2( int p ) ) ); // see identifier_parameter_declarator
3345//
3346// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3347// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3348// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3349// functions.
3350
3351abstract_parameter_declarator:
3352 abstract_parameter_ptr
3353 | '&' MUTEX attribute_list_opt
3354 { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3355 | abstract_parameter_array attribute_list_opt
3356 { $$ = $1->addQualifiers( $2 ); }
3357 | abstract_parameter_function attribute_list_opt
3358 { $$ = $1->addQualifiers( $2 ); }
3359 ;
3360
3361abstract_parameter_ptr:
3362 ptrref_operator
3363 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3364 | ptrref_operator type_qualifier_list
3365 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3366 | ptrref_operator abstract_parameter_declarator
3367 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3368 | ptrref_operator type_qualifier_list abstract_parameter_declarator
3369 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3370 | '(' abstract_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3371 { $$ = $2->addQualifiers( $4 ); }
3372 ;
3373
3374abstract_parameter_array:
3375 array_parameter_dimension
3376 | '(' abstract_parameter_ptr ')' array_parameter_dimension
3377 { $$ = $2->addArray( $4 ); }
3378 | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3379 { $$ = $2->addArray( $4 ); }
3380 | '(' abstract_parameter_array ')' // redundant parenthesis
3381 { $$ = $2; }
3382 ;
3383
3384abstract_parameter_function:
3385 '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3386 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3387 | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3388 { $$ = $2->addParamList( $6 ); }
3389 | '(' abstract_parameter_function ')' // redundant parenthesis
3390 { $$ = $2; }
3391 ;
3392
3393array_parameter_dimension:
3394 // Only the first dimension can be empty or have qualifiers.
3395 array_parameter_1st_dimension
3396 | array_parameter_1st_dimension multi_array_dimension
3397 { $$ = $1->addArray( $2 ); }
3398 | multi_array_dimension
3399 ;
3400
3401// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3402//
3403// ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3404// a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3405
3406array_parameter_1st_dimension:
3407 '[' ']'
3408 { $$ = DeclarationNode::newArray( 0, 0, false ); }
3409 // multi_array_dimension handles the '[' '*' ']' case
3410 | '[' push type_qualifier_list '*' pop ']' // remaining C99
3411 { $$ = DeclarationNode::newVarArray( $3 ); }
3412 | '[' push type_qualifier_list pop ']'
3413 { $$ = DeclarationNode::newArray( 0, $3, false ); }
3414 // multi_array_dimension handles the '[' assignment_expression ']' case
3415 | '[' push type_qualifier_list assignment_expression pop ']'
3416 { $$ = DeclarationNode::newArray( $4, $3, false ); }
3417 | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3418 { $$ = DeclarationNode::newArray( $5, $4, true ); }
3419 | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3420 { $$ = DeclarationNode::newArray( $5, $3, true ); }
3421 ;
3422
3423// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3424//
3425// struct S {
3426// int;
3427// int *;
3428// int [10];
3429// int (*)();
3430// };
3431
3432variable_abstract_declarator:
3433 variable_abstract_ptr
3434 | variable_abstract_array attribute_list_opt
3435 { $$ = $1->addQualifiers( $2 ); }
3436 | variable_abstract_function attribute_list_opt
3437 { $$ = $1->addQualifiers( $2 ); }
3438 ;
3439
3440variable_abstract_ptr:
3441 ptrref_operator
3442 { $$ = DeclarationNode::newPointer( 0, $1 ); }
3443 | ptrref_operator type_qualifier_list
3444 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3445 | ptrref_operator variable_abstract_declarator
3446 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3447 | ptrref_operator type_qualifier_list variable_abstract_declarator
3448 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3449 | '(' variable_abstract_ptr ')' attribute_list_opt // redundant parenthesis
3450 { $$ = $2->addQualifiers( $4 ); }
3451 ;
3452
3453variable_abstract_array:
3454 array_dimension
3455 | '(' variable_abstract_ptr ')' array_dimension
3456 { $$ = $2->addArray( $4 ); }
3457 | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3458 { $$ = $2->addArray( $4 ); }
3459 | '(' variable_abstract_array ')' // redundant parenthesis
3460 { $$ = $2; }
3461 ;
3462
3463variable_abstract_function:
3464 '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3465 { $$ = $2->addParamList( $6 ); }
3466 | '(' variable_abstract_function ')' // redundant parenthesis
3467 { $$ = $2; }
3468 ;
3469
3470// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3471// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3472
3473cfa_identifier_parameter_declarator_tuple: // CFA
3474 cfa_identifier_parameter_declarator_no_tuple
3475 | cfa_abstract_tuple
3476 | type_qualifier_list cfa_abstract_tuple
3477 { $$ = $2->addQualifiers( $1 ); }
3478 ;
3479
3480cfa_identifier_parameter_declarator_no_tuple: // CFA
3481 cfa_identifier_parameter_ptr
3482 | cfa_identifier_parameter_array
3483 ;
3484
3485cfa_identifier_parameter_ptr: // CFA
3486 // No SUE declaration in parameter list.
3487 ptrref_operator type_specifier_nobody
3488 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3489 | type_qualifier_list ptrref_operator type_specifier_nobody
3490 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3491 | ptrref_operator cfa_abstract_function
3492 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3493 | type_qualifier_list ptrref_operator cfa_abstract_function
3494 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3495 | ptrref_operator cfa_identifier_parameter_declarator_tuple
3496 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3497 | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3498 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3499 ;
3500
3501cfa_identifier_parameter_array: // CFA
3502 // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3503 // shift/reduce conflict with new-style empty (void) function return type.
3504 '[' ']' type_specifier_nobody
3505 { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3506 | cfa_array_parameter_1st_dimension type_specifier_nobody
3507 { $$ = $2->addNewArray( $1 ); }
3508 | '[' ']' multi_array_dimension type_specifier_nobody
3509 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3510 | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3511 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3512 | multi_array_dimension type_specifier_nobody
3513 { $$ = $2->addNewArray( $1 ); }
3514
3515 | '[' ']' cfa_identifier_parameter_ptr
3516 { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3517 | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3518 { $$ = $2->addNewArray( $1 ); }
3519 | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3520 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3521 | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3522 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3523 | multi_array_dimension cfa_identifier_parameter_ptr
3524 { $$ = $2->addNewArray( $1 ); }
3525 ;
3526
3527cfa_array_parameter_1st_dimension:
3528 '[' push type_qualifier_list '*' pop ']' // remaining C99
3529 { $$ = DeclarationNode::newVarArray( $3 ); }
3530 | '[' push type_qualifier_list assignment_expression pop ']'
3531 { $$ = DeclarationNode::newArray( $4, $3, false ); }
3532 | '[' push declaration_qualifier_list assignment_expression pop ']'
3533 // declaration_qualifier_list must be used because of shift/reduce conflict with
3534 // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3535 // appear in this context.
3536 { $$ = DeclarationNode::newArray( $4, $3, true ); }
3537 | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3538 { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3539 ;
3540
3541// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3542// identifier to which the type applies, e.g.:
3543//
3544// [int] f( int ); // abstract variable parameter; no parameter name specified
3545// [int] f( [int] (int) ); // abstract function-prototype parameter; no parameter name specified
3546//
3547// These rules need LR(3):
3548//
3549// cfa_abstract_tuple identifier_or_type_name
3550// '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
3551//
3552// since a function return type can be syntactically identical to a tuple type:
3553//
3554// [int, int] t;
3555// [int, int] f( int );
3556//
3557// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3558// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3559// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3560// duplicated when appearing with cfa_function_specifier.
3561
3562cfa_abstract_declarator_tuple: // CFA
3563 cfa_abstract_tuple
3564 | type_qualifier_list cfa_abstract_tuple
3565 { $$ = $2->addQualifiers( $1 ); }
3566 | cfa_abstract_declarator_no_tuple
3567 ;
3568
3569cfa_abstract_declarator_no_tuple: // CFA
3570 cfa_abstract_ptr
3571 | cfa_abstract_array
3572 ;
3573
3574cfa_abstract_ptr: // CFA
3575 ptrref_operator type_specifier
3576 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3577 | type_qualifier_list ptrref_operator type_specifier
3578 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3579 | ptrref_operator cfa_abstract_function
3580 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3581 | type_qualifier_list ptrref_operator cfa_abstract_function
3582 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3583 | ptrref_operator cfa_abstract_declarator_tuple
3584 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3585 | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3586 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3587 ;
3588
3589cfa_abstract_array: // CFA
3590 // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3591 // empty (void) function return type.
3592 '[' ']' type_specifier
3593 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3594 | '[' ']' multi_array_dimension type_specifier
3595 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3596 | multi_array_dimension type_specifier
3597 { $$ = $2->addNewArray( $1 ); }
3598 | '[' ']' cfa_abstract_ptr
3599 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3600 | '[' ']' multi_array_dimension cfa_abstract_ptr
3601 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3602 | multi_array_dimension cfa_abstract_ptr
3603 { $$ = $2->addNewArray( $1 ); }
3604 ;
3605
3606cfa_abstract_tuple: // CFA
3607 '[' push cfa_abstract_parameter_list pop ']'
3608 { $$ = DeclarationNode::newTuple( $3 ); }
3609 | '[' push type_specifier_nobody ELLIPSIS pop ']'
3610 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3611 | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
3612 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3613 ;
3614
3615cfa_abstract_function: // CFA
3616// '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
3617// { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3618 cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
3619 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3620 | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
3621 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3622 ;
3623
3624// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3625// each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3626//
3627// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3628// the declaration specifiers in a declaration is an obsolescent feature."
3629//
3630// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3631// prototype-format parameter type declarators) is an obsolescent feature."
3632//
3633// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3634// declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3635
3636//************************* MISCELLANEOUS ********************************
3637
3638comma_opt: // redundant comma
3639 // empty
3640 | ','
3641 ;
3642
3643default_initializer_opt:
3644 // empty
3645 { $$ = nullptr; }
3646 | '=' assignment_expression
3647 { $$ = $2; }
3648 ;
3649
3650%%
3651
3652// ----end of grammar----
3653
3654// Local Variables: //
3655// mode: c++ //
3656// tab-width: 4 //
3657// compile-command: "make install" //
3658// End: //
Note: See TracBrowser for help on using the repository browser.