Context Navigation

parser.yy @ dbff8ec

Last change on this file since dbff8ec was b9f6791f, checked in by Peter A. Buhr <pabuhr@…>, 4 months ago
allow empty global declaration ';', adjust semi-colon rules after static_assert
Property mode set to `100644`
File size: 178.2 KB

Line
1	//
2	// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3	//
4	// The contents of this file are covered under the licence agreement in the
5	// file "LICENCE" distributed with Cforall.
6	//
7	// parser.yy --
8	//
9	// Author : Peter A. Buhr
10	// Created On : Sat Sep 1 20:22:55 2001
11	// Last Modified By : Peter A. Buhr
12	// Last Modified On : Tue Jul 9 10:29:01 2024
13	// Update Count : 6713
14	//
15
16	// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17	// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS. While parts have been
18	// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19	// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20	// that must be subsequently rejected by semantic checks. Nevertheless, there are still several semantic checks
21	// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23	// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24	// the grammar.
25
26	// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27	//
28	// designation with '=' (use ':' instead)
29	//
30	// This incompatibility is discussed in detail before the "designation" grammar rule. Most of the syntactic extensions
31	// from ANSI90 to ANSI11 C are marked with the comment "C99/C11".
32
33	// This grammar also has two levels of extensions. The first extensions cover most of the GCC C extensions. All of the
34	// syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall (CFA), which
35	// fixes several of C's outstanding problems and extends C with many modern language concepts. All of the syntactic
36	// extensions for CFA C are marked with the comment "CFA".
37
38	%{
39	#define YYDEBUG_LEXER_TEXT( yylval ) // lexer loads this up each time
40	#define YYDEBUG 1 // get the pretty debugging code to compile
41	#define YYERROR_VERBOSE // more information in syntax errors
42
43	#undef __GNUC_MINOR__
44
45	#include <cstdio>
46	#include <sstream>
47	#include <stack>
48	using namespace std;
49
50	#include "DeclarationNode.hpp" // for DeclarationNode, ...
51	#include "ExpressionNode.hpp" // for ExpressionNode, ...
52	#include "InitializerNode.hpp" // for InitializerNode, ...
53	#include "ParserTypes.hpp"
54	#include "StatementNode.hpp" // for build_...
55	#include "TypedefTable.hpp"
56	#include "TypeData.hpp"
57	#include "AST/Type.hpp" // for BasicType, BasicKind
58	#include "Common/SemanticError.hpp" // error_str
59	#include "Common/Utility.hpp" // for maybeMoveBuild, maybeBuild, CodeLo...
60
61	// lex uses __null in a boolean context, it's fine.
62	#ifdef __clang__
63	#pragma GCC diagnostic ignored "-Wparentheses-equality"
64	#endif
65
66	extern DeclarationNode * parseTree;
67	extern ast::Linkage::Spec linkage;
68	extern TypedefTable typedefTable;
69
70	stack<ast::Linkage::Spec> linkageStack;
71
72	bool appendStr( string & to, string & from ) {
73	// 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
74	// "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
75	// the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
76	// easier to let the C compiler handle this case.
77	//
78	// 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
79	// without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
80	// e.g., u"a" U"b" L"c" is disallowed.
81
82	if ( from[0] != '"' ) { // encoding ?
83	if ( to[0] != '"' ) { // encoding ?
84	if ( to[0] != from[0] \|\| to[1] != from[1] ) { // different encodings ?
85	yyerror( "non-matching string encodings for string-literal concatenation" );
86	return false; // parse error, must call YYERROR in action
87	} else if ( from[1] == '8' ) {
88	from.erase( 0, 1 ); // remove 2nd encoding
89	} // if
90	} else {
91	if ( from[1] == '8' ) { // move encoding to start
92	to = "u8" + to;
93	from.erase( 0, 1 ); // remove 2nd encoding
94	} else {
95	to = from[0] + to;
96	} // if
97	} // if
98	from.erase( 0, 1 ); // remove 2nd encoding
99	} // if
100	to += " " + from; // concatenated into single string
101	return true;
102	} // appendStr
103
104	DeclarationNode * distAttr( DeclarationNode * typeSpec, DeclarationNode * declList ) {
105	// Distribute type specifier across all declared variables, e.g., static, const, __attribute__.
106	assert( declList );
107
108	// Do not distribute attributes for aggregates because the attributes surrounding the aggregate belong it not the
109	// variables in the declaration list, e.g.,
110	//
111	// struct __attribute__(( aligned(128) )) S { ...
112	// } v1 __attribute__(( aligned(64) )), v2 __attribute__(( aligned(32) )), v3;
113	// struct S v4;
114	//
115	// v1 => 64, v2 =>32, v3 => 128, v2 => 128
116	//
117	// Anonymous aggregates are a special case because there is no aggregate to bind the attribute to; hence it floats
118	// to the declaration list.
119	//
120	// struct __attribute__(( aligned(128) )) /anonymous / { ... } v1;
121	//
122	// v1 => 128
123
124	bool copyattr = ! (typeSpec->type && typeSpec->type->kind == TypeData::Aggregate && ! typeSpec->type->aggregate.anon );
125
126	// addType copies the type information for the aggregate instances from typeSpec into cl's aggInst.aggregate.
127	DeclarationNode * cl = (new DeclarationNode)->addType( typeSpec ); // typeSpec IS DELETED!!!
128
129	// Start at second variable in declaration list and clone the type specifiers for each variable.
130	for ( DeclarationNode * cur = declList->next ; cur != nullptr; cur = cur->next ) {
131	cl->cloneBaseType( cur, copyattr ); // cur is modified
132	} // for
133
134	// Add first variable in declaration list with hidden type information in aggInst.aggregate, which is used by
135	// extractType to recover the type for the aggregate instances.
136	declList->addType( cl, copyattr ); // cl IS DELETED!!!
137	return declList;
138	} // distAttr
139
140	void distExt( DeclarationNode * declaration ) {
141	// distribute EXTENSION across all declarations
142	for ( DeclarationNode *iter = declaration ; iter != nullptr ; iter = iter->next ) {
143	iter->set_extension( true );
144	} // for
145	} // distExt
146
147	void distInl( DeclarationNode * declaration ) {
148	// distribute INLINE across all declarations
149	for ( DeclarationNode *iter = declaration ; iter != nullptr ; iter = iter->next ) {
150	iter->set_inLine( true );
151	} // for
152	} // distInl
153
154	void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
155	// distribute qualifiers across all non-variable declarations in a distribution statemement
156	for ( DeclarationNode * iter = declaration ; iter != nullptr ; iter = iter->next ) {
157	// SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
158	// addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
159	// get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
160	// be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
161	DeclarationNode * clone = qualifiers->clone();
162	if ( qualifiers->type ) { // forall clause ? (handles SC)
163	if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
164	swap( clone->type->forall, iter->type->aggregate.params );
165	iter->addQualifiers( clone );
166	} else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
167	// Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
168	DeclarationNode newnode;
169	swap( newnode.type, iter->type->aggInst.aggregate );
170	swap( clone->type->forall, newnode.type->aggregate.params );
171	newnode.addQualifiers( clone );
172	swap( newnode.type, iter->type->aggInst.aggregate );
173	} else if ( iter->type->kind == TypeData::Function ) { // routines ?
174	swap( clone->type->forall, iter->type->forall );
175	iter->addQualifiers( clone );
176	} // if
177	} else { // just SC qualifiers
178	iter->addQualifiers( clone );
179	} // if
180	} // for
181	delete qualifiers;
182	} // distQual
183
184	// There is an ambiguity for inline generic-routine return-types and generic routines.
185	// forall( otype T ) struct S { int i; } bar( T ) {}
186	// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
187	// forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
188	// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
189	// forall( otype T ) struct S { int T; };
190	// forall( otype W ) bar( W ) {}
191
192	void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
193	if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
194	funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
195	declSpec->type->aggregate.params = nullptr;
196	} // if
197	} // rebindForall
198
199	string * build_postfix_name( string * name ) {
200	name = string("__postfix_func_") + name;
201	return name;
202	} // build_postfix_name
203
204	DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
205	if ( nullptr == fieldList ) {
206	if ( !( typeSpec->type && typeSpec->type->kind == TypeData::Aggregate ) ) {
207	stringstream ss;
208	// printf( "fieldDecl1 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
209	SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
210	return nullptr;
211	} // if
212	// printf( "fieldDecl2 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
213	fieldList = DeclarationNode::newName( nullptr );
214	} // if
215
216	// printf( "fieldDecl3 typeSpec %p\n", typeSpec ); typeSpec->print( std::cout, 0 );
217	DeclarationNode * temp = distAttr( typeSpec, fieldList ); // mark all fields in list
218	// printf( "fieldDecl4 temp %p\n", temp ); temp->print( std::cout, 0 );
219	return temp;
220	} // fieldDecl
221
222	#define NEW_ZERO new ExpressionNode( build_constantInteger( yylloc, *new string( "0" ) ) )
223	#define NEW_ONE new ExpressionNode( build_constantInteger( yylloc, *new string( "1" ) ) )
224	#define UPDOWN( compop, left, right ) (compop == OperKinds::LThan \|\| compop == OperKinds::LEThan ? left : right)
225	#define MISSING_ANON_FIELD "illegal syntax, missing loop fields with an anonymous loop index is meaningless as loop index is unavailable in loop body."
226	#define MISSING_LOW "illegal syntax, missing low value for ascanding range so index is uninitialized."
227	#define MISSING_HIGH "illegal syntax, missing high value for descending range so index is uninitialized."
228
229	static ForCtrl * makeForCtrl( const CodeLocation & location, DeclarationNode * init, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
230	// Wrap both comp/inc if they are non-null.
231	if ( comp ) comp = new ExpressionNode( build_binary_val( location,
232	compop,
233	new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
234	comp ) );
235	if ( inc ) inc = new ExpressionNode( build_binary_val( location,
236	// choose += or -= for upto/downto
237	compop == OperKinds::LThan \|\| compop == OperKinds::LEThan ? OperKinds::PlusAssn : OperKinds::MinusAssn,
238	new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
239	inc ) );
240	// The StatementNode call frees init->name, it must happen later.
241	return new ForCtrl( new StatementNode( init ), comp, inc );
242	}
243
244	ForCtrl * forCtrl( const CodeLocation & location, DeclarationNode * index, ExpressionNode * start, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
245	if ( index->initializer ) {
246	SemanticError( yylloc, "illegal syntax, direct initialization disallowed. Use instead: type var; initialization ~ comparison ~ increment." );
247	} // if
248	if ( index->next ) {
249	SemanticError( yylloc, "illegal syntax, multiple loop indexes disallowed in for-loop declaration." );
250	} // if
251	DeclarationNode * initDecl = index->addInitializer( new InitializerNode( start ) );
252	return makeForCtrl( location, initDecl, compop, comp, inc );
253	} // forCtrl
254
255	ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, string * index, ExpressionNode * start, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
256	ast::ConstantExpr * constant = dynamic_cast<ast::ConstantExpr *>(type->expr.get());
257	if ( constant && (constant->rep == "0" \|\| constant->rep == "1") ) {
258	type = new ExpressionNode( new ast::CastExpr( location, maybeMoveBuild(type), new ast::BasicType( ast::BasicKind::SignedInt ) ) );
259	} // if
260	DeclarationNode * initDecl = distAttr(
261	DeclarationNode::newTypeof( type, true ),
262	DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) )
263	);
264	return makeForCtrl( location, initDecl, compop, comp, inc );
265	} // forCtrl
266
267	#define MISSING_LOOP_INDEX "illegal syntax, only a single identifier or declaration allowed in initialization, e.g., for ( i; ... ) or for ( int i; ... ). Expression disallowed."
268
269	ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
270	if ( auto identifier = dynamic_cast<ast::NameExpr *>(index->expr.get()) ) {
271	return forCtrl( location, type, new string( identifier->name ), start, compop, comp, inc );
272	} else {
273	SemanticError( yylloc, MISSING_LOOP_INDEX ); return nullptr;
274	} // if
275	} // forCtrl
276
277	ForCtrl * enumRangeCtrl( ExpressionNode * index_expr, OperKinds compop, ExpressionNode * range_over_expr, DeclarationNode * type ) {
278	assert( compop == OperKinds::LEThan \|\| compop == OperKinds::GEThan );
279	if ( auto identifier = dynamic_cast<ast::NameExpr *>(index_expr->expr.get()) ) {
280	DeclarationNode * indexDecl =
281	DeclarationNode::newName( new std::string(identifier->name) )->addType( type );
282	return new ForCtrl( new StatementNode( indexDecl ), range_over_expr, compop );
283	} else {
284	SemanticError( yylloc, MISSING_LOOP_INDEX ); return nullptr;
285	} // if
286	} // enumRangeCtrl
287
288	static void IdentifierBeforeIdentifier( string & identifier1, string & identifier2, const char * kind ) {
289	SemanticError( yylloc, "illegal syntax, adjacent identifiers \"%s\" and \"%s\" are not meaningful in an %s.\n"
290	"Possible cause is misspelled type name or missing generic parameter.",
291	identifier1.c_str(), identifier2.c_str(), kind );
292	} // IdentifierBeforeIdentifier
293
294	static void IdentifierBeforeType( string & identifier, const char * kind ) {
295	SemanticError( yylloc, "illegal syntax, identifier \"%s\" cannot appear before a %s.\n"
296	"Possible cause is misspelled storage/CV qualifier, misspelled typename, or missing generic parameter.",
297	identifier.c_str(), kind );
298	} // IdentifierBeforeType
299
300	bool forall = false; // aggregate have one or more forall qualifiers ?
301
302	// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
303	#define YYLLOC_DEFAULT(Cur, Rhs, N) \
304	if ( N ) { \
305	(Cur).first_line = YYRHSLOC( Rhs, 1 ).first_line; \
306	(Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column; \
307	(Cur).last_line = YYRHSLOC( Rhs, N ).last_line; \
308	(Cur).last_column = YYRHSLOC( Rhs, N ).last_column; \
309	(Cur).filename = YYRHSLOC( Rhs, 1 ).filename; \
310	} else { \
311	(Cur).first_line = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line; \
312	(Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column; \
313	(Cur).filename = YYRHSLOC( Rhs, 0 ).filename; \
314	}
315	%}
316
317	%define parse.error verbose
318
319	// Types declaration for productions
320
321	%union {
322	// A raw token can be used.
323	Token tok;
324
325	// The general node types hold some generic node or list of nodes.
326	DeclarationNode * decl;
327	InitializerNode * init;
328	ExpressionNode * expr;
329	StatementNode * stmt;
330	ClauseNode * clause;
331	TypeData * type;
332
333	// Special "nodes" containing compound information.
334	CondCtl * ifctl;
335	ForCtrl * forctl;
336	LabelNode * labels;
337
338	// Various flags and single values that become fields later.
339	ast::AggregateDecl::Aggregate aggKey;
340	ast::TypeDecl::Kind tclass;
341	OperKinds oper;
342	bool is_volatile;
343	EnumHiding enum_hiding;
344	ast::ExceptionKind except_kind;
345	// String passes ownership with it.
346	std::string * str;
347
348	// Narrower node types are used to avoid constant unwrapping.
349	ast::WaitForStmt * wfs;
350	ast::WaitUntilStmt::ClauseNode * wucn;
351	ast::GenericExpr * genexpr;
352	}
353
354	// ********************** TERMINAL TOKENS ******************************
355
356	// keywords
357	%token TYPEDEF
358	%token EXTERN STATIC AUTO REGISTER
359	%token THREADLOCALGCC THREADLOCALC11 // GCC, C11
360	%token INLINE FORTRAN // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
361	%token NORETURN // C11
362	%token CONST VOLATILE
363	%token RESTRICT // C99
364	%token ATOMIC // C11
365	%token FORALL MUTEX VIRTUAL VTABLE COERCE // CFA
366	%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
367	%token BOOL COMPLEX IMAGINARY // C99
368	%token INT128 UINT128 uuFLOAT80 uuFLOAT128 // GCC
369	%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
370	%token DECIMAL32 DECIMAL64 DECIMAL128 // GCC
371	%token ZERO_T ONE_T // CFA
372	%token SIZEOF TYPEOF VA_LIST VA_ARG AUTO_TYPE COUNTOF // GCC
373	%token OFFSETOF BASETYPEOF TYPEID // CFA
374	%token ENUM STRUCT UNION
375	%token EXCEPTION // CFA
376	%token GENERATOR COROUTINE MONITOR THREAD // CFA
377	%token OTYPE FTYPE DTYPE TTYPE TRAIT // CFA
378	// %token RESUME // CFA
379	%token LABEL // GCC
380	%token SUSPEND // CFA
381	%token ATTRIBUTE EXTENSION // GCC
382	%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
383	%token CHOOSE FALLTHRU FALLTHROUGH WITH WHEN WAITFOR WAITUNTIL // CFA
384	%token CORUN COFOR
385	%token DISABLE ENABLE TRY THROW THROWRESUME AT // CFA
386	%token ASM // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
387	%token ALIGNAS ALIGNOF GENERIC STATICASSERT // C11
388
389	// names and constants: lexer differentiates between identifier and typedef names
390	%token<tok> IDENTIFIER TYPEDIMname TYPEDEFname TYPEGENname
391	%token<tok> TIMEOUT WAND WOR CATCH RECOVER CATCHRESUME FIXUP FINALLY // CFA
392	%token<tok> INTEGERconstant CHARACTERconstant STRINGliteral
393	%token<tok> DIRECTIVE
394	// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
395	// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
396	// converted into the tuple index (.)(1). e.g., 3.x
397	%token<tok> FLOATING_DECIMALconstant FLOATING_FRACTIONconstant FLOATINGconstant
398
399	// multi-character operators
400	%token ARROW // ->
401	%token ICR DECR // ++ --
402	%token LS RS // << >>
403	%token LE GE EQ NE // <= >= == !=
404	%token ANDAND OROR // && \|\|
405	%token ATTR ELLIPSIS // @@ ...
406
407	%token EXPassign MULTassign DIVassign MODassign // \= *= /= %=
408	%token PLUSassign MINUSassign // += -=
409	%token LSassign RSassign // <<= >>=
410	%token ANDassign ERassign ORassign // &= ^= \|=
411
412	%token ErangeUp ErangeUpEq ErangeDown ErangeDownEq // +~ +~=/~= -~ -~=
413	%token ATassign // @=
414
415	%type<tok> identifier identifier_at identifier_or_type_name attr_name
416	%type<tok> quasi_keyword
417	%type<expr> string_literal
418	%type<str> string_literal_list
419
420	%type<enum_hiding> hide_opt visible_hide_opt
421
422	// expressions
423	%type<expr> constant
424	%type<expr> tuple tuple_expression_list
425	%type<oper> ptrref_operator unary_operator assignment_operator simple_assignment_operator compound_assignment_operator
426	%type<expr> primary_expression postfix_expression unary_expression
427	%type<expr> cast_expression_list cast_expression exponential_expression multiplicative_expression additive_expression
428	%type<expr> shift_expression relational_expression equality_expression
429	%type<expr> AND_expression exclusive_OR_expression inclusive_OR_expression
430	%type<expr> logical_AND_expression logical_OR_expression
431	%type<expr> conditional_expression constant_expression assignment_expression assignment_expression_opt
432	%type<expr> comma_expression comma_expression_opt
433	%type<expr> argument_expression_list_opt argument_expression_list argument_expression default_initializer_opt
434	%type<ifctl> conditional_declaration
435	%type<forctl> for_control_expression for_control_expression_list
436	%type<oper> upupeq updown updowneq downupdowneq
437	%type<expr> subrange
438	%type<decl> asm_name_opt
439	%type<expr> asm_operands_opt asm_operands_list asm_operand
440	%type<labels> label_list
441	%type<expr> asm_clobbers_list_opt
442	%type<is_volatile> asm_volatile_opt
443	%type<expr> handler_predicate_opt
444	%type<genexpr> generic_association generic_assoc_list
445
446	// statements
447	%type<stmt> statement labeled_statement compound_statement
448	%type<stmt> statement_decl statement_decl_list statement_list_nodecl
449	%type<stmt> selection_statement
450	%type<clause> switch_clause_list_opt switch_clause_list
451	%type<expr> case_value
452	%type<clause> case_clause case_value_list case_label case_label_list
453	%type<stmt> iteration_statement jump_statement
454	%type<stmt> expression_statement asm_statement
455	%type<stmt> with_statement
456	%type<expr> with_clause_opt
457	%type<stmt> corun_statement cofor_statement
458	%type<stmt> exception_statement
459	%type<clause> handler_clause finally_clause
460	%type<except_kind> handler_key
461	%type<stmt> mutex_statement
462	%type<expr> when_clause when_clause_opt waitfor waituntil timeout
463	%type<stmt> waitfor_statement waituntil_statement
464	%type<wfs> wor_waitfor_clause
465	%type<wucn> waituntil_clause wand_waituntil_clause wor_waituntil_clause
466
467	// declarations
468	%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
469	%type<decl> abstract_parameter_declarator_opt abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
470	%type<decl> abstract_parameter_declaration
471
472	%type<aggKey> aggregate_key aggregate_data aggregate_control
473	%type<decl> aggregate_type aggregate_type_nobody
474
475	%type<decl> assertion assertion_list assertion_list_opt
476
477	%type<expr> bit_subrange_size_opt bit_subrange_size
478
479	%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
480	%type<type> basic_type_name_type
481	%type<type> vtable vtable_opt default_opt
482
483	%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
484
485	%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
486	%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
487
488	%type<decl> elaborated_type elaborated_type_nobody
489
490	%type<decl> enumerator_list enum_type enum_type_nobody enum_key enumerator_type
491	%type<init> enumerator_value_opt
492
493	%type<decl> external_definition external_definition_list external_definition_list_opt
494
495	%type<decl> exception_declaration
496
497	%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
498	%type<expr> field field_name_list field_name fraction_constants_opt
499
500	%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
501
502	%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
503	%type<decl> identifier_list
504
505	%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
506	%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
507	%type<decl> cfa_abstract_ptr cfa_abstract_tuple
508
509	%type<decl> cfa_array_parameter_1st_dimension
510
511	%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
512	%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
513
514	%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
515	%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
516
517	%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_list_ellipsis_opt
518
519	%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
520
521	%type<decl> c_declaration static_assert
522	%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
523	%type<decl> KR_parameter_list KR_parameter_list_opt
524
525	%type<decl> parameter_declaration parameter_list parameter_list_ellipsis_opt
526
527	%type<decl> paren_identifier paren_type
528
529	%type<decl> storage_class storage_class_list
530
531	%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
532
533	%type<tclass> type_class new_type_class
534	%type<decl> type_declarator type_declarator_name type_declaring_list
535
536	%type<decl> type_declaration_specifier type_type_specifier
537	%type<type> type_name typegen_name
538	%type<decl> typedef_name typedef_declaration typedef_expression
539
540	%type<decl> variable_type_redeclarator variable_type_ptr variable_type_array variable_type_function
541	%type<decl> general_function_declarator function_type_redeclarator function_type_array function_type_no_ptr function_type_ptr
542
543	%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
544
545	%type<decl> type type_no_function
546	%type<decl> type_parameter type_parameter_list type_initializer_opt
547
548	%type<expr> type_parameters_opt type_list array_type_list // array_dimension_list
549
550	%type<decl> type_qualifier forall type_qualifier_list_opt type_qualifier_list
551	%type<type> type_qualifier_name
552	%type<decl> type_specifier type_specifier_nobody
553
554	%type<decl> variable_declarator variable_ptr variable_array variable_function
555	%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
556
557	%type<decl> attribute_list_opt attribute_list attribute attribute_name_list attribute_name
558
559	// initializers
560	%type<init> initializer initializer_list_opt initializer_opt
561
562	// designators
563	%type<expr> designator designator_list designation
564
565
566	// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
567	// .---------. matches IF '(' comma_expression ')' statement . (reduce)
568	// if ( C ) S1 else S2
569	// `-----------------' matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
570	// Similar issues exit with the waitfor statement.
571
572	// Order of these lines matters (low-to-high precedence). THEN is left associative over WAND/WOR/TIMEOUT/ELSE, WAND/WOR
573	// is left associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
574	%precedence THEN // rule precedence for IF/WAITFOR statement
575	%precedence ANDAND // token precedence for start of WAND in WAITFOR statement
576	%precedence WAND // token precedence for start of WAND in WAITFOR statement
577	%precedence OROR // token precedence for start of WOR in WAITFOR statement
578	%precedence WOR // token precedence for start of WOR in WAITFOR statement
579	%precedence TIMEOUT // token precedence for start of TIMEOUT in WAITFOR statement
580	%precedence CATCH // token precedence for start of TIMEOUT in WAITFOR statement
581	%precedence RECOVER // token precedence for start of TIMEOUT in WAITFOR statement
582	%precedence CATCHRESUME // token precedence for start of TIMEOUT in WAITFOR statement
583	%precedence FIXUP // token precedence for start of TIMEOUT in WAITFOR statement
584	%precedence FINALLY // token precedence for start of TIMEOUT in WAITFOR statement
585	%precedence ELSE // token precedence for start of else clause in IF/WAITFOR statement
586
587
588	// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
589	// forall( otype T ) struct Foo { T v; };
590	// .-----. matches pointer to function returning a generic (which is impossible without a type)
591	// Foo ( *fp )( int );
592	// `---' matches start of TYPEGENname '('
593	// must be:
594	// Foo( int ) ( *fp )( int );
595	// The same problem occurs here:
596	// forall( otype T ) struct Foo { T v; } ( *fp )( int );
597	// must be:
598	// forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
599
600	// Order of these lines matters (low-to-high precedence).
601	%precedence TYPEGENname
602	%precedence '}'
603	%precedence '('
604
605	// %precedence RESUME
606	// %precedence '{'
607	// %precedence ')'
608
609	%locations // support location tracking for error messages
610
611	%start translation_unit // parse-tree root
612
613	%%
614	// ********************** Namespace Management ******************************
615
616	// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
617	// which are lexically identical.
618	//
619	// typedef int foo; // identifier foo must now be scanned as TYPEDEFname
620	// foo f; // to allow it to appear in this context
621	//
622	// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
623	// between syntactic and semantic constructs. Cforall compounds this problem by introducing type names local to the
624	// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
625	// generators" -- parameterized types. This latter type name creates a third class of identifiers, "TYPEGENname", which
626	// must be distinguished by the lexical scanner.
627	//
628	// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
629	// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
630	// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
631	// each context that introduces a name scope, a new level is created in the type table and that level is popped on
632	// exiting the scope. Since type names can be local to a particular declaration, each declaration is itself a scope.
633	// This requires distinguishing between type names that are local to the current declaration scope and those that
634	// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
635	//
636	// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
637	// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
638	// around the list separator.
639	//
640	// XXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
641	// push pop push pop
642
643	push:
644	{ typedefTable.enterScope(); }
645	;
646
647	pop:
648	{ typedefTable.leaveScope(); }
649	;
650
651	// ********************** CONSTANTS ******************************
652
653	constant:
654	// ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
655	INTEGERconstant { $$ = new ExpressionNode( build_constantInteger( yylloc, *$1 ) ); }
656	\| FLOATING_DECIMALconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
657	\| FLOATING_FRACTIONconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
658	\| FLOATINGconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
659	\| CHARACTERconstant { $$ = new ExpressionNode( build_constantChar( yylloc, *$1 ) ); }
660	;
661
662	quasi_keyword: // CFA
663	TIMEOUT
664	\| WAND
665	\| WOR
666	\| CATCH
667	\| RECOVER
668	\| CATCHRESUME
669	\| FIXUP
670	\| FINALLY
671	;
672
673	identifier:
674	IDENTIFIER
675	\| quasi_keyword
676	;
677
678	identifier_at:
679	identifier
680	\| '@' // CFA
681	{ Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
682	;
683
684	identifier_or_type_name:
685	identifier
686	\| TYPEDEFname
687	\| TYPEGENname
688	;
689
690	string_literal:
691	string_literal_list { $$ = new ExpressionNode( build_constantStr( yylloc, *$1 ) ); }
692	;
693
694	string_literal_list: // juxtaposed strings are concatenated
695	STRINGliteral { $$ = $1; } // conversion from tok to str
696	\| string_literal_list STRINGliteral
697	{
698	if ( ! appendStr( $1, $2 ) ) YYERROR; // append 2nd juxtaposed string to 1st
699	delete $2; // allocated by lexer
700	$$ = $1; // conversion from tok to str
701	}
702	;
703
704	// ********************** EXPRESSIONS ******************************
705
706	primary_expression:
707	IDENTIFIER // typedef name cannot be used as a variable name
708	{ $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
709	\| quasi_keyword
710	{ $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
711	\| TYPEDIMname // CFA, generic length argument
712	{ $$ = new ExpressionNode( build_dimensionref( yylloc, $1 ) ); }
713	\| tuple
714	\| '(' comma_expression ')'
715	{ $$ = $2; }
716	\| '(' compound_statement ')' // GCC, lambda expression
717	{ $$ = new ExpressionNode( new ast::StmtExpr( yylloc, dynamic_cast<ast::CompoundStmt *>( maybeMoveBuild( $2 ) ) ) ); }
718	\| type_name '.' identifier // CFA, nested type
719	{ $$ = new ExpressionNode( build_qualified_expr( yylloc, DeclarationNode::newFromTypeData( $1 ), build_varref( yylloc, $3 ) ) ); }
720	\| type_name '.' '[' field_name_list ']' // CFA, nested type / tuple field selector
721	{ SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
722	\| GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
723	{
724	// add the missing control expression to the GenericExpr and return it
725	$5->control = maybeMoveBuild( $3 );
726	$$ = new ExpressionNode( $5 );
727	}
728	// \| RESUME '(' comma_expression ')'
729	// { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
730	// \| RESUME '(' comma_expression ')' compound_statement
731	// { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
732	\| IDENTIFIER IDENTIFIER // invalid syntax rule
733	{ IdentifierBeforeIdentifier( $1.str, $2.str, "expression" ); $$ = nullptr; }
734	\| IDENTIFIER type_qualifier // invalid syntax rule
735	{ IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
736	\| IDENTIFIER storage_class // invalid syntax rule
737	{ IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
738	\| IDENTIFIER basic_type_name // invalid syntax rule
739	{ IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
740	\| IDENTIFIER TYPEDEFname // invalid syntax rule
741	{ IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
742	\| IDENTIFIER TYPEGENname // invalid syntax rule
743	{ IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
744	;
745
746	generic_assoc_list: // C11
747	generic_association
748	\| generic_assoc_list ',' generic_association
749	{
750	// steal the association node from the singleton and delete the wrapper
751	assert( 1 == $3->associations.size() );
752	$1->associations.push_back( $3->associations.front() );
753	delete $3;
754	$$ = $1;
755	}
756	;
757
758	generic_association: // C11
759	type_no_function ':' assignment_expression
760	{
761	// create a GenericExpr wrapper with one association pair
762	$$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuildType( $1 ), maybeMoveBuild( $3 ) } } );
763	}
764	\| DEFAULT ':' assignment_expression
765	{ $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuild( $3 ) } } ); }
766	;
767
768	postfix_expression:
769	primary_expression
770	\| postfix_expression '[' assignment_expression ',' tuple_expression_list ']'
771	// Historic, transitional: Disallow commas in subscripts.
772	// Switching to this behaviour may help check if a C compatibilty case uses comma-exprs in subscripts.
773	// Current: Commas in subscripts make tuples.
774	{ $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, new ExpressionNode( build_tuple( yylloc, $3->set_last( $5 ) ) ) ) ); }
775	\| postfix_expression '[' assignment_expression ']'
776	// CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
777	// matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
778	// little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
779	// equivalent to the old x[i,j].
780	{ $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
781	\| constant '[' assignment_expression ']' // 3[a], 'a'[a], 3.5[a]
782	{ $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
783	\| string_literal '[' assignment_expression ']' // "abc"[3], 3["abc"]
784	{ $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
785	\| postfix_expression '{' argument_expression_list_opt '}' // CFA, constructor call
786	{
787	Token fn;
788	fn.str = new std::string( "?{}" ); // location undefined - use location of '{'?
789	$$ = new ExpressionNode( new ast::ConstructorExpr( yylloc, build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), $1->set_last( $3 ) ) ) );
790	}
791	\| postfix_expression '(' argument_expression_list_opt ')'
792	{ $$ = new ExpressionNode( build_func( yylloc, $1, $3 ) ); }
793	\| VA_ARG '(' primary_expression ',' declaration_specifier_nobody abstract_parameter_declarator_opt ')'
794	// { SemanticError( yylloc, "va_arg is currently unimplemented." ); $$ = nullptr; }
795	{ $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, new string( "__builtin_va_arg" ) ) ),
796	$3->set_last( (ExpressionNode *)($6 ? $6->addType( $5 ) : $5) ) ) ); }
797	\| postfix_expression '`' identifier // CFA, postfix call
798	{ $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
799	\| constant '`' identifier // CFA, postfix call
800	{ $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
801	\| string_literal '`' identifier // CFA, postfix call
802	{ $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
803
804	// SKULLDUGGERY: The typedef table used for parsing does not store fields in structures. To parse a qualified
805	// name, it is assumed all name-tokens after the first are identifiers, regardless of how the lexer identifies
806	// them. For example:
807	//
808	// struct S;
809	// forall(T) struct T;
810	// union U;
811	// enum E { S, T, E };
812	// struct Z { int S, T, Z, E, U; };
813	// void fred () {
814	// Z z;
815	// z.S; // lexer returns S is TYPEDEFname
816	// z.T; // lexer returns T is TYPEGENname
817	// z.Z; // lexer returns Z is TYPEDEFname
818	// z.U; // lexer returns U is TYPEDEFname
819	// z.E; // lexer returns E is TYPEDEFname
820	// }
821	\| postfix_expression '.' identifier_or_type_name
822	{ $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
823
824	\| postfix_expression '.' INTEGERconstant // CFA, tuple index
825	{ $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
826	\| postfix_expression FLOATING_FRACTIONconstant // CFA, tuple index
827	{ $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 ) ) ); }
828	\| postfix_expression '.' '[' field_name_list ']' // CFA, tuple field selector
829	{ $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
830	\| postfix_expression '.' aggregate_control
831	{ $$ = new ExpressionNode( build_keyword_cast( yylloc, $3, $1 ) ); }
832	\| postfix_expression ARROW identifier
833	{ $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
834	\| postfix_expression ARROW INTEGERconstant // CFA, tuple index
835	{ $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
836	\| postfix_expression ARROW '[' field_name_list ']' // CFA, tuple field selector
837	{ $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
838	\| postfix_expression ICR
839	{ $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::IncrPost, $1 ) ); }
840	\| postfix_expression DECR
841	{ $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::DecrPost, $1 ) ); }
842	\| '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
843	{ $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, new InitializerNode( $5, true ) ) ); }
844	\| '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
845	{ $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
846	\| '^' primary_expression '{' argument_expression_list_opt '}' // CFA, destructor call
847	{
848	Token fn;
849	fn.str = new string( "^?{}" ); // location undefined
850	$$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), $2->set_last( $4 ) ) );
851	}
852	;
853
854	argument_expression_list_opt:
855	// empty
856	{ $$ = nullptr; }
857	\| argument_expression_list
858	;
859
860	argument_expression_list:
861	argument_expression
862	\| argument_expression_list_opt ',' argument_expression
863	{ $$ = $1->set_last( $3 ); }
864	;
865
866	argument_expression:
867	'@' // CFA, default parameter
868	{ SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
869	// { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
870	\| assignment_expression
871	;
872
873	field_name_list: // CFA, tuple field selector
874	field
875	\| field_name_list ',' field { $$ = $1->set_last( $3 ); }
876	;
877
878	field: // CFA, tuple field selector
879	field_name
880	\| FLOATING_DECIMALconstant field
881	{ $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), maybeMoveBuild( $2 ) ) ); }
882	\| FLOATING_DECIMALconstant '[' field_name_list ']'
883	{ $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), build_tuple( yylloc, $3 ) ) ); }
884	\| field_name '.' field
885	{ $$ = new ExpressionNode( build_fieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
886	\| field_name '.' '[' field_name_list ']'
887	{ $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
888	\| field_name ARROW field
889	{ $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
890	\| field_name ARROW '[' field_name_list ']'
891	{ $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
892	;
893
894	field_name:
895	INTEGERconstant fraction_constants_opt
896	{ $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_constantInteger( yylloc, *$1 ), $2 ) ); }
897	\| FLOATINGconstant fraction_constants_opt
898	{ $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_field_name_FLOATINGconstant( yylloc, *$1 ), $2 ) ); }
899	\| identifier_at fraction_constants_opt // CFA, allow anonymous fields
900	{
901	$$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_varref( yylloc, $1 ), $2 ) );
902	}
903	;
904
905	fraction_constants_opt:
906	// empty
907	{ $$ = nullptr; }
908	\| fraction_constants_opt FLOATING_FRACTIONconstant
909	{
910	ast::Expr * constant = build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 );
911	$$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( yylloc, $1, constant ) ) : new ExpressionNode( constant );
912	}
913	;
914
915	unary_expression:
916	postfix_expression
917	// first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
918	// semantics checks, e.g., ++3, 3--, *3, &&3
919	\| constant
920	\| string_literal
921	{ $$ = $1; }
922	\| EXTENSION cast_expression // GCC
923	{ $$ = $2->set_extension( true ); }
924	// '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
925	// { * X; } // dereference X
926	// { * int X; } // CFA declaration of pointer to int
927	\| ptrref_operator cast_expression // CFA
928	{
929	switch ( $1 ) {
930	case OperKinds::AddressOf:
931	$$ = new ExpressionNode( new ast::AddressExpr( maybeMoveBuild( $2 ) ) );
932	break;
933	case OperKinds::PointTo:
934	$$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) );
935	break;
936	case OperKinds::And:
937	$$ = new ExpressionNode( new ast::AddressExpr( new ast::AddressExpr( maybeMoveBuild( $2 ) ) ) );
938	break;
939	default:
940	assert( false );
941	}
942	}
943	\| unary_operator cast_expression
944	{ $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) ); }
945	\| ICR unary_expression
946	{ $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Incr, $2 ) ); }
947	\| DECR unary_expression
948	{ $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Decr, $2 ) ); }
949	\| SIZEOF unary_expression
950	{ $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuild( $2 ) ) ); }
951	\| SIZEOF '(' type_no_function ')'
952	{ $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
953	\| ALIGNOF unary_expression // GCC, variable alignment
954	{ $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuild( $2 ) ) ); }
955	\| ALIGNOF '(' type_no_function ')' // GCC, type alignment
956	{ $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
957
958	// Cannot use rule "type", which includes cfa_abstract_function, for sizeof/alignof, because of S/R problems on
959	// look ahead, so the cfa_abstract_function is factored out.
960	\| SIZEOF '(' cfa_abstract_function ')'
961	{ $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
962	\| ALIGNOF '(' cfa_abstract_function ')' // GCC, type alignment
963	{ $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
964
965	\| OFFSETOF '(' type_no_function ',' identifier ')'
966	{ $$ = new ExpressionNode( build_offsetOf( yylloc, $3, build_varref( yylloc, $5 ) ) ); }
967	\| TYPEID '(' type ')'
968	{
969	SemanticError( yylloc, "typeid name is currently unimplemented." ); $$ = nullptr;
970	// $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) );
971	}
972	\| COUNTOF '(' type_no_function ')'
973	{ $$ = new ExpressionNode( new ast::CountExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
974	\| COUNTOF unary_expression
975	{ SemanticError( yylloc, "countof for expressions is currently unimplemented. "); $$ = nullptr; }
976	;
977
978	ptrref_operator:
979	'*' { $$ = OperKinds::PointTo; }
980	\| '&' { $$ = OperKinds::AddressOf; }
981	// GCC, address of label must be handled by semantic check for ref,ref,label
982	\| ANDAND { $$ = OperKinds::And; }
983	;
984
985	unary_operator:
986	'+' { $$ = OperKinds::UnPlus; }
987	\| '-' { $$ = OperKinds::UnMinus; }
988	\| '!' { $$ = OperKinds::Neg; }
989	\| '~' { $$ = OperKinds::BitNeg; }
990	;
991
992	cast_expression:
993	unary_expression
994	\| '(' type_no_function ')' cast_expression
995	{ $$ = new ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
996	\| '(' aggregate_control '&' ')' cast_expression // CFA
997	{ $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
998	\| '(' aggregate_control '*' ')' cast_expression // CFA
999	{ $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
1000	\| '(' VIRTUAL ')' cast_expression // CFA
1001	{ $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $4 ), nullptr ) ); }
1002	\| '(' VIRTUAL type_no_function ')' cast_expression // CFA
1003	{ $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $5 ), maybeMoveBuildType( $3 ) ) ); }
1004	\| '(' RETURN type_no_function ')' cast_expression // CFA
1005	{ $$ = new ExpressionNode( build_cast( yylloc, $3, $5, ast::CastExpr::Return ) ); }
1006	\| '(' COERCE type_no_function ')' cast_expression // CFA
1007	{ SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
1008	\| '(' qualifier_cast_list ')' cast_expression // CFA
1009	{ SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
1010	// \| '(' type_no_function ')' tuple
1011	// { $$ = new ast::ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
1012	;
1013
1014	qualifier_cast_list:
1015	cast_modifier type_qualifier_name
1016	\| cast_modifier MUTEX
1017	\| qualifier_cast_list cast_modifier type_qualifier_name
1018	\| qualifier_cast_list cast_modifier MUTEX
1019	;
1020
1021	cast_modifier:
1022	'-'
1023	\| '+'
1024	;
1025
1026	exponential_expression:
1027	cast_expression
1028	\| exponential_expression '\\' cast_expression
1029	{ $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Exp, $1, $3 ) ); }
1030	;
1031
1032	multiplicative_expression:
1033	exponential_expression
1034	\| multiplicative_expression '*' exponential_expression
1035	{ $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mul, $1, $3 ) ); }
1036	\| multiplicative_expression '/' exponential_expression
1037	{ $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Div, $1, $3 ) ); }
1038	\| multiplicative_expression '%' exponential_expression
1039	{ $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mod, $1, $3 ) ); }
1040	;
1041
1042	additive_expression:
1043	multiplicative_expression
1044	\| additive_expression '+' multiplicative_expression
1045	{ $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Plus, $1, $3 ) ); }
1046	\| additive_expression '-' multiplicative_expression
1047	{ $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Minus, $1, $3 ) ); }
1048	;
1049
1050	shift_expression:
1051	additive_expression
1052	\| shift_expression LS additive_expression
1053	{ $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LShift, $1, $3 ) ); }
1054	\| shift_expression RS additive_expression
1055	{ $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::RShift, $1, $3 ) ); }
1056	;
1057
1058	relational_expression:
1059	shift_expression
1060	\| relational_expression '<' shift_expression
1061	{ $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LThan, $1, $3 ) ); }
1062	\| relational_expression '>' shift_expression
1063	{ $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GThan, $1, $3 ) ); }
1064	\| relational_expression LE shift_expression
1065	{ $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LEThan, $1, $3 ) ); }
1066	\| relational_expression GE shift_expression
1067	{ $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GEThan, $1, $3 ) ); }
1068	;
1069
1070	equality_expression:
1071	relational_expression
1072	\| equality_expression EQ relational_expression
1073	{ $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Eq, $1, $3 ) ); }
1074	\| equality_expression NE relational_expression
1075	{ $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Neq, $1, $3 ) ); }
1076	;
1077
1078	AND_expression:
1079	equality_expression
1080	\| AND_expression '&' equality_expression
1081	{ $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitAnd, $1, $3 ) ); }
1082	;
1083
1084	exclusive_OR_expression:
1085	AND_expression
1086	\| exclusive_OR_expression '^' AND_expression
1087	{ $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Xor, $1, $3 ) ); }
1088	;
1089
1090	inclusive_OR_expression:
1091	exclusive_OR_expression
1092	\| inclusive_OR_expression '\|' exclusive_OR_expression
1093	{ $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitOr, $1, $3 ) ); }
1094	;
1095
1096	logical_AND_expression:
1097	inclusive_OR_expression
1098	\| logical_AND_expression ANDAND inclusive_OR_expression
1099	{ $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::AndExpr ) ); }
1100	;
1101
1102	logical_OR_expression:
1103	logical_AND_expression
1104	\| logical_OR_expression OROR logical_AND_expression
1105	{ $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::OrExpr ) ); }
1106	;
1107
1108	conditional_expression:
1109	logical_OR_expression
1110	\| logical_OR_expression '?' comma_expression ':' conditional_expression
1111	{ $$ = new ExpressionNode( build_cond( yylloc, $1, $3, $5 ) ); }
1112	\| logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
1113	{ $$ = new ExpressionNode( build_cond( yylloc, $1, nullptr, $4 ) ); }
1114	;
1115
1116	constant_expression:
1117	conditional_expression
1118	;
1119
1120	assignment_expression:
1121	// CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
1122	conditional_expression
1123	\| unary_expression assignment_operator assignment_expression
1124	{
1125	// if ( $2 == OperKinds::AtAssn ) {
1126	// SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
1127	// } else {
1128	$$ = new ExpressionNode( build_binary_val( yylloc, $2, $1, $3 ) );
1129	// } // if
1130	}
1131	\| unary_expression '=' '{' initializer_list_opt comma_opt '}'
1132	{ SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
1133	;
1134
1135	assignment_expression_opt:
1136	// empty
1137	{ $$ = nullptr; }
1138	\| assignment_expression
1139	;
1140
1141	assignment_operator:
1142	simple_assignment_operator
1143	\| compound_assignment_operator
1144	;
1145
1146	simple_assignment_operator:
1147	'=' { $$ = OperKinds::Assign; }
1148	\| ATassign { $$ = OperKinds::AtAssn; } // CFA
1149	;
1150
1151	compound_assignment_operator:
1152	EXPassign { $$ = OperKinds::ExpAssn; }
1153	\| MULTassign { $$ = OperKinds::MulAssn; }
1154	\| DIVassign { $$ = OperKinds::DivAssn; }
1155	\| MODassign { $$ = OperKinds::ModAssn; }
1156	\| PLUSassign { $$ = OperKinds::PlusAssn; }
1157	\| MINUSassign { $$ = OperKinds::MinusAssn; }
1158	\| LSassign { $$ = OperKinds::LSAssn; }
1159	\| RSassign { $$ = OperKinds::RSAssn; }
1160	\| ANDassign { $$ = OperKinds::AndAssn; }
1161	\| ERassign { $$ = OperKinds::ERAssn; }
1162	\| ORassign { $$ = OperKinds::OrAssn; }
1163	;
1164
1165	tuple: // CFA, tuple
1166	// CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
1167	// comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
1168	// '[' ']'
1169	// { $$ = new ExpressionNode( build_tuple() ); }
1170	// \| '[' push assignment_expression pop ']'
1171	// { $$ = new ExpressionNode( build_tuple( $3 ) ); }
1172	'[' ',' tuple_expression_list ']'
1173	{ $$ = new ExpressionNode( build_tuple( yylloc, (new ExpressionNode( nullptr ))->set_last( $3 ) ) ); }
1174	\| '[' push assignment_expression pop ',' tuple_expression_list ']'
1175	{ $$ = new ExpressionNode( build_tuple( yylloc, $3->set_last( $6 ) ) ); }
1176	;
1177
1178	tuple_expression_list:
1179	assignment_expression
1180	\| '@' // CFA
1181	{ SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1182	\| tuple_expression_list ',' assignment_expression
1183	{ $$ = $1->set_last( $3 ); }
1184	\| tuple_expression_list ',' '@'
1185	{ SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1186	;
1187
1188	comma_expression:
1189	assignment_expression
1190	\| comma_expression ',' assignment_expression
1191	{ $$ = new ExpressionNode( new ast::CommaExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1192	;
1193
1194	comma_expression_opt:
1195	// empty
1196	{ $$ = nullptr; }
1197	\| comma_expression
1198	;
1199
1200	// ************************ STATEMENTS *****************************
1201
1202	statement:
1203	labeled_statement
1204	\| compound_statement
1205	\| expression_statement
1206	\| selection_statement
1207	\| iteration_statement
1208	\| jump_statement
1209	\| with_statement
1210	\| mutex_statement
1211	\| waitfor_statement
1212	\| waituntil_statement
1213	\| corun_statement
1214	\| cofor_statement
1215	\| exception_statement
1216	\| enable_disable_statement
1217	{ SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1218	\| asm_statement
1219	\| DIRECTIVE
1220	{ $$ = new StatementNode( build_directive( yylloc, $1 ) ); }
1221	;
1222
1223	labeled_statement:
1224	// labels cannot be identifiers 0 or 1
1225	identifier_or_type_name ':' attribute_list_opt statement
1226	{ $$ = $4->add_label( yylloc, $1, $3 ); }
1227	\| identifier_or_type_name ':' attribute_list_opt error // invalid syntax rule
1228	{
1229	SemanticError( yylloc, "syntx error, label \"%s\" must be associated with a statement, "
1230	"where a declaration, case, or default is not a statement.\n"
1231	"Move the label or terminate with a semicolon.", $1.str->c_str() );
1232	$$ = nullptr;
1233	}
1234	;
1235
1236	compound_statement:
1237	'{' '}'
1238	{ $$ = new StatementNode( build_compound( yylloc, (StatementNode *)0 ) ); }
1239	\| '{' push
1240	local_label_declaration_opt // GCC, local labels appear at start of block
1241	statement_decl_list // C99, intermix declarations and statements
1242	pop '}'
1243	{ $$ = new StatementNode( build_compound( yylloc, $4 ) ); }
1244	;
1245
1246	statement_decl_list: // C99
1247	statement_decl
1248	\| statement_decl_list statement_decl
1249	{ assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1250	;
1251
1252	statement_decl:
1253	declaration // CFA, new & old style declarations
1254	{ $$ = new StatementNode( $1 ); }
1255	\| EXTENSION declaration // GCC
1256	{ distExt( $2 ); $$ = new StatementNode( $2 ); }
1257	\| function_definition
1258	{ $$ = new StatementNode( $1 ); }
1259	\| EXTENSION function_definition // GCC
1260	{ distExt( $2 ); $$ = new StatementNode( $2 ); }
1261	\| statement
1262	;
1263
1264	statement_list_nodecl:
1265	statement
1266	\| statement_list_nodecl statement
1267	{ assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1268	\| statement_list_nodecl error // invalid syntax rule
1269	{ SemanticError( yylloc, "illegal syntax, declarations only allowed at the start of the switch body,"
1270	" i.e., after the '{'." ); $$ = nullptr; }
1271	;
1272
1273	expression_statement:
1274	comma_expression_opt ';'
1275	{ $$ = new StatementNode( build_expr( yylloc, $1 ) ); }
1276	;
1277
1278	// "if", "switch", and "choose" require parenthesis around the conditional. See the following ambiguities without
1279	// parenthesis:
1280	//
1281	// if x + y + z; => if ( x ) + y + z or if ( x + y ) + z
1282	//
1283	// switch O { }
1284	//
1285	// O{} => object-constructor for conditional, switch body ???
1286	// O{} => O for conditional followed by switch body
1287	//
1288	// C++ has this problem, as it has the same constructor syntax.
1289	//
1290	// switch sizeof ( T ) { }
1291	//
1292	// sizeof ( T ) => sizeof of T for conditional followed by switch body
1293	// sizeof ( T ) => sizeof of compound literal (T){ }, closing parenthesis ???
1294	//
1295	// Note the two grammar rules for sizeof (alignof)
1296	//
1297	// \| SIZEOF unary_expression
1298	// \| SIZEOF '(' type_no_function ')'
1299	//
1300	// where the first DOES NOT require parenthesis! And C++ inherits this problem from C.
1301
1302	selection_statement:
1303	IF '(' conditional_declaration ')' statement %prec THEN
1304	// explicitly deal with the shift/reduce conflict on if/else
1305	{ $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), nullptr ) ); }
1306	\| IF '(' conditional_declaration ')' statement ELSE statement
1307	{ $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), maybe_build_compound( yylloc, $7 ) ) ); }
1308	\| SWITCH '(' comma_expression ')' case_clause
1309	{ $$ = new StatementNode( build_switch( yylloc, true, $3, $5 ) ); }
1310	\| SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1311	{
1312	StatementNode *sw = new StatementNode( build_switch( yylloc, true, $3, $8 ) );
1313	// The semantics of the declaration list is changed to include associated initialization, which is performed
1314	// before the transfer to the appropriate case clause by hoisting the declarations into a compound
1315	// statement around the switch. Statements after the initial declaration list can never be executed, and
1316	// therefore, are removed from the grammar even though C allows it. The change also applies to choose
1317	// statement.
1318	$$ = $7 ? new StatementNode( build_compound( yylloc, (new StatementNode( $7 ))->set_last( sw ) ) ) : sw;
1319	}
1320	\| SWITCH '(' comma_expression ')' '{' error '}' // CFA, invalid syntax rule error
1321	{ SemanticError( yylloc, "synatx error, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1322	\| CHOOSE '(' comma_expression ')' case_clause // CFA
1323	{ $$ = new StatementNode( build_switch( yylloc, false, $3, $5 ) ); }
1324	\| CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1325	{
1326	StatementNode *sw = new StatementNode( build_switch( yylloc, false, $3, $8 ) );
1327	$$ = $7 ? new StatementNode( build_compound( yylloc, (new StatementNode( $7 ))->set_last( sw ) ) ) : sw;
1328	}
1329	\| CHOOSE '(' comma_expression ')' '{' error '}' // CFA, invalid syntax rule
1330	{ SemanticError( yylloc, "illegal syntax, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1331	;
1332
1333	conditional_declaration:
1334	comma_expression
1335	{ $$ = new CondCtl( nullptr, $1 ); }
1336	\| c_declaration // no semi-colon
1337	{ $$ = new CondCtl( $1, nullptr ); }
1338	\| cfa_declaration // no semi-colon
1339	{ $$ = new CondCtl( $1, nullptr ); }
1340	\| declaration comma_expression // semi-colon separated
1341	{ $$ = new CondCtl( $1, $2 ); }
1342	;
1343
1344	// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1345	// clause allows a list of values and subranges.
1346
1347	case_value: // CFA
1348	constant_expression { $$ = $1; }
1349	\| constant_expression ELLIPSIS constant_expression // GCC, subrange
1350	{ $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1351	\| subrange // CFA, subrange
1352	;
1353
1354	case_value_list: // CFA
1355	case_value { $$ = new ClauseNode( build_case( yylloc, $1 ) ); }
1356	// convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1357	\| case_value_list ',' case_value { $$ = $1->set_last( new ClauseNode( build_case( yylloc, $3 ) ) ); }
1358	;
1359
1360	case_label: // CFA
1361	CASE error // invalid syntax rule
1362	{ SemanticError( yylloc, "illegal syntax, case list missing after case." ); $$ = nullptr; }
1363	\| CASE case_value_list ':' { $$ = $2; }
1364	\| CASE case_value_list error // invalid syntax rule
1365	{ SemanticError( yylloc, "illegal syntax, colon missing after case list." ); $$ = nullptr; }
1366	\| DEFAULT ':' { $$ = new ClauseNode( build_default( yylloc ) ); }
1367	// A semantic check is required to ensure only one default clause per switch/choose statement.
1368	\| DEFAULT error // invalid syntax rule
1369	{ SemanticError( yylloc, "illegal syntax, colon missing after default." ); $$ = nullptr; }
1370	;
1371
1372	case_label_list: // CFA
1373	case_label
1374	\| case_label_list case_label { $$ = $1->set_last( $2 ); }
1375	;
1376
1377	case_clause: // CFA
1378	case_label_list statement { $$ = $1->append_last_case( maybe_build_compound( yylloc, $2 ) ); }
1379	;
1380
1381	switch_clause_list_opt: // CFA
1382	// empty
1383	{ $$ = nullptr; }
1384	\| switch_clause_list
1385	;
1386
1387	switch_clause_list: // CFA
1388	case_label_list statement_list_nodecl
1389	{ $$ = $1->append_last_case( new StatementNode( build_compound( yylloc, $2 ) ) ); }
1390	\| switch_clause_list case_label_list statement_list_nodecl
1391	{ $$ = $1->set_last( $2->append_last_case( new StatementNode( build_compound( yylloc, $3 ) ) ) ); }
1392	;
1393
1394	iteration_statement:
1395	WHILE '(' ')' statement %prec THEN // CFA => while ( 1 )
1396	{ $$ = new StatementNode( build_while( yylloc, new CondCtl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) ); }
1397	\| WHILE '(' ')' statement ELSE statement // CFA
1398	{
1399	$$ = new StatementNode( build_while( yylloc, new CondCtl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) );
1400	SemanticWarning( yylloc, Warning::SuperfluousElse );
1401	}
1402	\| WHILE '(' conditional_declaration ')' statement %prec THEN
1403	{ $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1404	\| WHILE '(' conditional_declaration ')' statement ELSE statement // CFA
1405	{ $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1406	\| DO statement WHILE '(' ')' ';' // CFA => do while( 1 )
1407	{ $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) ); }
1408	\| DO statement WHILE '(' ')' ELSE statement // CFA
1409	{
1410	$$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) );
1411	SemanticWarning( yylloc, Warning::SuperfluousElse );
1412	}
1413	\| DO statement WHILE '(' comma_expression ')' ';'
1414	{ $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ) ) ); }
1415	\| DO statement WHILE '(' comma_expression ')' ELSE statement // CFA
1416	{ $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ), $8 ) ); }
1417	\| FOR '(' ')' statement %prec THEN // CFA => for ( ;; )
1418	{ $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) ); }
1419	\| FOR '(' ')' statement ELSE statement // CFA
1420	{
1421	$$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) );
1422	SemanticWarning( yylloc, Warning::SuperfluousElse );
1423	}
1424	\| FOR '(' for_control_expression_list ')' statement %prec THEN
1425	{ $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1426	\| FOR '(' for_control_expression_list ')' statement ELSE statement // CFA
1427	{ $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1428	;
1429
1430	for_control_expression_list:
1431	for_control_expression
1432	\| for_control_expression_list ':' for_control_expression
1433	// ForCtrl + ForCtrl:
1434	// init + init => multiple declaration statements that are hoisted
1435	// condition + condition => (expression) && (expression)
1436	// change + change => (expression), (expression)
1437	{
1438	$1->init->set_last( $3->init );
1439	if ( $1->condition ) {
1440	if ( $3->condition ) {
1441	$1->condition->expr.reset( new ast::LogicalExpr( yylloc, $1->condition->expr.release(), $3->condition->expr.release(), ast::AndExpr ) );
1442	} // if
1443	} else $1->condition = $3->condition;
1444	if ( $1->change ) {
1445	if ( $3->change ) {
1446	$1->change->expr.reset( new ast::CommaExpr( yylloc, $1->change->expr.release(), $3->change->expr.release() ) );
1447	} // if
1448	} else $1->change = $3->change;
1449	$$ = $1;
1450	}
1451	;
1452
1453	for_control_expression:
1454	';' comma_expression_opt ';' comma_expression_opt
1455	{ $$ = new ForCtrl( nullptr, $2, $4 ); }
1456	\| comma_expression ';' comma_expression_opt ';' comma_expression_opt
1457	{
1458	$$ = new ForCtrl( $1 ? new StatementNode( new ast::ExprStmt( yylloc, maybeMoveBuild( $1 ) ) ) : nullptr, $3, $5 );
1459	}
1460	\| declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1461	{ $$ = new ForCtrl( new StatementNode( $1 ), $2, $4 ); }
1462
1463	\| '@' ';' comma_expression // CFA, empty loop-index
1464	{ $$ = new ForCtrl( nullptr, $3, nullptr ); }
1465	\| '@' ';' comma_expression ';' comma_expression // CFA, empty loop-index
1466	{ $$ = new ForCtrl( nullptr, $3, $5 ); }
1467
1468	\| comma_expression // CFA, anonymous loop-index
1469	{ $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), NEW_ZERO, OperKinds::LThan, $1->clone(), NEW_ONE ); }
1470	\| downupdowneq comma_expression // CFA, anonymous loop-index
1471	{ $$ = forCtrl( yylloc, $2, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $1, NEW_ZERO, $2->clone() ), $1, UPDOWN( $1, $2->clone(), NEW_ZERO ), NEW_ONE ); }
1472
1473	\| comma_expression updowneq comma_expression // CFA, anonymous loop-index
1474	{ $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), NEW_ONE ); }
1475	\| '@' updowneq comma_expression // CFA, anonymous loop-index
1476	{
1477	if ( $2 == OperKinds::LThan \|\| $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1478	else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, NEW_ONE );
1479	}
1480	\| comma_expression updowneq '@' // CFA, anonymous loop-index
1481	{
1482	if ( $2 == OperKinds::LThan \|\| $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1483	else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1484	}
1485	\| comma_expression updowneq comma_expression '~' comma_expression // CFA, anonymous loop-index
1486	{ $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), $5 ); }
1487	\| '@' updowneq comma_expression '~' comma_expression // CFA, anonymous loop-index
1488	{
1489	if ( $2 == OperKinds::LThan \|\| $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1490	else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, $5 );
1491	}
1492	\| comma_expression updowneq '@' '~' comma_expression // CFA, anonymous loop-index
1493	{
1494	if ( $2 == OperKinds::LThan \|\| $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1495	else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1496	}
1497	\| comma_expression updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1498	{ SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1499	\| '@' updowneq '@' // CFA, invalid syntax rule
1500	{ SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1501	\| '@' updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1502	{ SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1503	\| comma_expression updowneq '@' '~' '@' // CFA, invalid syntax rule
1504	{ SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1505	\| '@' updowneq '@' '~' '@' // CFA, invalid syntax rule
1506	{ SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1507
1508	// These rules accept a comma_expression for the initialization, when only an identifier is correct. Being
1509	// permissive allows for a better error message from forCtrl.
1510	\| comma_expression ';' comma_expression // CFA
1511	{ $$ = forCtrl( yylloc, $3, $1, NEW_ZERO, OperKinds::LThan, $3->clone(), NEW_ONE ); }
1512	\| comma_expression ';' downupdowneq comma_expression // CFA
1513	{ $$ = forCtrl( yylloc, $4, $1, UPDOWN( $3, NEW_ZERO, $4->clone() ), $3, UPDOWN( $3, $4->clone(), NEW_ZERO ), NEW_ONE ); }
1514
1515	\| comma_expression ';' comma_expression updowneq comma_expression // CFA
1516	{ $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), NEW_ONE ); }
1517	\| comma_expression ';' '@' updowneq comma_expression // CFA
1518	{
1519	if ( $4 == OperKinds::LThan \|\| $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1520	else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, NEW_ONE );
1521	}
1522	\| comma_expression ';' comma_expression updowneq '@' // CFA
1523	{
1524	if ( $4 == OperKinds::GThan \|\| $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1525	else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1526	else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, NEW_ONE );
1527	}
1528	\| comma_expression ';' '@' updowneq '@' // CFA, invalid syntax rule
1529	{ SemanticError( yylloc, "illegal syntax, missing low/high value for ascending/descending range so index is uninitialized." ); $$ = nullptr; }
1530
1531	\| comma_expression ';' comma_expression updowneq comma_expression '~' comma_expression // CFA
1532	{ $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), $7 ); }
1533	\| comma_expression ';' '@' updowneq comma_expression '~' comma_expression // CFA, invalid syntax rule
1534	{
1535	if ( $4 == OperKinds::LThan \|\| $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1536	else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, $7 );
1537	}
1538	\| comma_expression ';' comma_expression updowneq '@' '~' comma_expression // CFA
1539	{
1540	if ( $4 == OperKinds::GThan \|\| $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1541	else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1542	else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, $7 );
1543	}
1544	\| comma_expression ';' comma_expression updowneq comma_expression '~' '@' // CFA
1545	{ $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), nullptr ); }
1546	\| comma_expression ';' '@' updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1547	{
1548	if ( $4 == OperKinds::LThan \|\| $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1549	else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, nullptr );
1550	}
1551	\| comma_expression ';' comma_expression updowneq '@' '~' '@' // CFA
1552	{
1553	if ( $4 == OperKinds::GThan \|\| $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1554	else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1555	else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, nullptr );
1556	}
1557	\| comma_expression ';' '@' updowneq '@' '~' '@' // CFA
1558	{ SemanticError( yylloc, "illegal syntax, missing low/high value for ascending/descending range so index is uninitialized." ); $$ = nullptr; }
1559
1560	\| declaration comma_expression // CFA
1561	{ $$ = forCtrl( yylloc, $1, NEW_ZERO, OperKinds::LThan, $2, NEW_ONE ); }
1562	\| declaration downupdowneq comma_expression // CFA
1563	{ $$ = forCtrl( yylloc, $1, UPDOWN( $2, NEW_ZERO, $3 ), $2, UPDOWN( $2, $3->clone(), NEW_ZERO ), NEW_ONE ); }
1564
1565	\| declaration comma_expression updowneq comma_expression // CFA
1566	{ $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2->clone(), $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), NEW_ONE ); }
1567	\| declaration '@' updowneq comma_expression // CFA
1568	{
1569	if ( $3 == OperKinds::LThan \|\| $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1570	else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, NEW_ONE );
1571	}
1572	\| declaration comma_expression updowneq '@' // CFA
1573	{
1574	if ( $3 == OperKinds::GThan \|\| $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1575	else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1576	else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, NEW_ONE );
1577	}
1578
1579	\| declaration comma_expression updowneq comma_expression '~' comma_expression // CFA
1580	{ $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), $6 ); }
1581	\| declaration '@' updowneq comma_expression '~' comma_expression // CFA
1582	{
1583	if ( $3 == OperKinds::LThan \|\| $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1584	else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, $6 );
1585	}
1586	\| declaration comma_expression updowneq '@' '~' comma_expression // CFA
1587	{
1588	if ( $3 == OperKinds::GThan \|\| $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1589	else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1590	else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, $6 );
1591	}
1592	\| declaration comma_expression updowneq comma_expression '~' '@' // CFA
1593	{ $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), nullptr ); }
1594	\| declaration '@' updowneq comma_expression '~' '@' // CFA
1595	{
1596	if ( $3 == OperKinds::LThan \|\| $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1597	else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, nullptr );
1598	}
1599	\| declaration comma_expression updowneq '@' '~' '@' // CFA
1600	{
1601	if ( $3 == OperKinds::GThan \|\| $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1602	else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1603	else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, nullptr );
1604	}
1605	\| declaration '@' updowneq '@' '~' '@' // CFA, invalid syntax rule
1606	{ SemanticError( yylloc, "illegal syntax, missing low/high value for ascending/descending range so index is uninitialized." ); $$ = nullptr; }
1607
1608	\| comma_expression ';' type_type_specifier // CFA, enum type
1609	{
1610	$$ = enumRangeCtrl( $1, OperKinds::LEThan, new ExpressionNode( new ast::TypeExpr( yylloc, $3->clone()->buildType() ) ), $3 );
1611	}
1612	\| comma_expression ';' downupdowneq enum_key // CFA, enum type, reverse direction
1613	{
1614	if ( $3 == OperKinds::GThan ) {
1615	SemanticError( yylloc, "all enumeration ranges are equal (all values). Add an equal, e.g., ~=, -~=." ); $$ = nullptr;
1616	$3 = OperKinds::GEThan;
1617	} // if
1618	$$ = enumRangeCtrl( $1, $3, new ExpressionNode( new ast::TypeExpr( yylloc, $4->clone()->buildType() ) ), $4 );
1619	}
1620	;
1621
1622	enum_key:
1623	type_name
1624	{ typedefTable.makeTypedef( *$1->symbolic.name, "enum_type_nobody 1" );
1625	$$ = DeclarationNode::newEnum( $1->symbolic.name, nullptr, false, false ); }
1626	\| ENUM identifier
1627	{ typedefTable.makeTypedef( *$2, "enum_type_nobody 2" );
1628	$$ = DeclarationNode::newEnum( $2, nullptr, false, false ); }
1629	\| ENUM type_name
1630	{ typedefTable.makeTypedef( *$2->symbolic.name, "enum_type_nobody 3" );
1631	$$ = DeclarationNode::newEnum( $2->symbolic.name, nullptr, false, false ); }
1632	;
1633
1634	// This rule exists to handle the ambiguity with unary operator '~'. The rule is the same as updowneq minus the '~'.
1635	// Specifically, "for ( ~5 )" means the complement of 5, not loop 0..4. Hence, in this case "for ( ~= 5 )", i.e., 0..5,
1636	// it is not possible to just remove the '='. The entire '~=' must be removed.
1637	downupdowneq:
1638	ErangeUp
1639	{ $$ = OperKinds::LThan; }
1640	\| ErangeDown
1641	{ $$ = OperKinds::GThan; }
1642	\| ErangeUpEq
1643	{ $$ = OperKinds::LEThan; }
1644	\| ErangeDownEq
1645	{ $$ = OperKinds::GEThan; }
1646	;
1647
1648	updown:
1649	'~' // shorthand 0 ~ 10 => 0 +~ 10
1650	{ $$ = OperKinds::LThan; }
1651	\| ErangeUp
1652	{ $$ = OperKinds::LThan; }
1653	\| ErangeDown
1654	{ $$ = OperKinds::GThan; }
1655	;
1656
1657	updowneq:
1658	updown
1659	\| ErangeUpEq
1660	{ $$ = OperKinds::LEThan; }
1661	\| ErangeDownEq
1662	{ $$ = OperKinds::GEThan; }
1663	;
1664
1665	jump_statement:
1666	GOTO identifier_or_type_name ';'
1667	{ $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Goto ) ); }
1668	\| GOTO '*' comma_expression ';' // GCC, computed goto
1669	// The syntax for the GCC computed goto violates normal expression precedence, e.g., goto i+3; => goto (i+3);
1670	// whereas normal operator precedence yields goto (*i)+3;
1671	{ $$ = new StatementNode( build_computedgoto( $3 ) ); }
1672	// A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1673	\| fall_through_name ';' // CFA
1674	{ $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThrough ) ); }
1675	\| fall_through_name identifier_or_type_name ';' // CFA
1676	{ $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::FallThrough ) ); }
1677	\| fall_through_name DEFAULT ';' // CFA
1678	{ $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThroughDefault ) ); }
1679	\| CONTINUE ';'
1680	// A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1681	{ $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Continue ) ); }
1682	\| CONTINUE identifier_or_type_name ';' // CFA, multi-level continue
1683	// A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1684	// the target of the transfer appears only at the start of an iteration statement.
1685	{ $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Continue ) ); }
1686	\| BREAK ';'
1687	// A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1688	{ $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Break ) ); }
1689	\| BREAK identifier_or_type_name ';' // CFA, multi-level exit
1690	// A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1691	// the target of the transfer appears only at the start of an iteration statement.
1692	{ $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Break ) ); }
1693	\| RETURN comma_expression_opt ';'
1694	{ $$ = new StatementNode( build_return( yylloc, $2 ) ); }
1695	\| RETURN '{' initializer_list_opt comma_opt '}' ';'
1696	{ SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1697	\| SUSPEND ';'
1698	{ $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::None ) ); }
1699	\| SUSPEND compound_statement
1700	{ $$ = new StatementNode( build_suspend( yylloc, $2, ast::SuspendStmt::None ) ); }
1701	\| SUSPEND COROUTINE ';'
1702	{ $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Coroutine ) ); }
1703	\| SUSPEND COROUTINE compound_statement
1704	{ $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Coroutine ) ); }
1705	\| SUSPEND GENERATOR ';'
1706	{ $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Generator ) ); }
1707	\| SUSPEND GENERATOR compound_statement
1708	{ $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Generator ) ); }
1709	\| THROW assignment_expression_opt ';' // handles rethrow
1710	{ $$ = new StatementNode( build_throw( yylloc, $2 ) ); }
1711	\| THROWRESUME assignment_expression_opt ';' // handles reresume
1712	{ $$ = new StatementNode( build_resume( yylloc, $2 ) ); }
1713	\| THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1714	{ $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1715	;
1716
1717	fall_through_name: // CFA
1718	FALLTHRU
1719	\| FALLTHROUGH
1720	;
1721
1722	with_statement:
1723	WITH '(' type_list ')' statement // support scoped enumeration
1724	{ $$ = new StatementNode( build_with( yylloc, $3, $5 ) ); }
1725	;
1726
1727	// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so possibly change syntax to "with mutex".
1728	mutex_statement:
1729	MUTEX '(' argument_expression_list_opt ')' statement
1730	{
1731	if ( ! $3 ) { SemanticError( yylloc, "illegal syntax, mutex argument list cannot be empty." ); $$ = nullptr; }
1732	$$ = new StatementNode( build_mutex( yylloc, $3, $5 ) );
1733	}
1734	;
1735
1736	when_clause:
1737	WHEN '(' comma_expression ')' { $$ = $3; }
1738	;
1739
1740	when_clause_opt:
1741	// empty
1742	{ $$ = nullptr; }
1743	\| when_clause
1744	;
1745
1746	cast_expression_list:
1747	cast_expression
1748	\| cast_expression_list ',' cast_expression
1749	{ SemanticError( yylloc, "List of mutex member is currently unimplemented." ); $$ = nullptr; }
1750	;
1751
1752	timeout:
1753	TIMEOUT '(' comma_expression ')' { $$ = $3; }
1754	;
1755
1756	wor:
1757	OROR
1758	\| WOR
1759
1760	waitfor:
1761	WAITFOR '(' cast_expression ')'
1762	{ $$ = $3; }
1763	\| WAITFOR '(' cast_expression_list ':' argument_expression_list_opt ')'
1764	{ $$ = $3->set_last( $5 ); }
1765	;
1766
1767	wor_waitfor_clause:
1768	when_clause_opt waitfor statement %prec THEN
1769	// Called first: create header for WaitForStmt.
1770	{ $$ = build_waitfor( yylloc, new ast::WaitForStmt( yylloc ), $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1771	\| wor_waitfor_clause wor when_clause_opt waitfor statement
1772	{ $$ = build_waitfor( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1773	\| wor_waitfor_clause wor when_clause_opt ELSE statement
1774	{ $$ = build_waitfor_else( yylloc, $1, $3, maybe_build_compound( yylloc, $5 ) ); }
1775	\| wor_waitfor_clause wor when_clause_opt timeout statement %prec THEN
1776	{ $$ = build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1777	// "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1778	\| wor_waitfor_clause wor when_clause_opt timeout statement wor ELSE statement // invalid syntax rule
1779	{ SemanticError( yylloc, "illegal syntax, else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1780	\| wor_waitfor_clause wor when_clause_opt timeout statement wor when_clause ELSE statement
1781	{ $$ = build_waitfor_else( yylloc, build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ), $7, maybe_build_compound( yylloc, $9 ) ); }
1782	;
1783
1784	waitfor_statement:
1785	wor_waitfor_clause %prec THEN
1786	{ $$ = new StatementNode( $1 ); }
1787	;
1788
1789	wand:
1790	ANDAND
1791	\| WAND
1792	;
1793
1794	waituntil:
1795	WAITUNTIL '(' comma_expression ')'
1796	{ $$ = $3; }
1797	;
1798
1799	waituntil_clause:
1800	when_clause_opt waituntil statement
1801	{ $$ = build_waituntil_clause( yylloc, $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1802	\| '(' wor_waituntil_clause ')'
1803	{ $$ = $2; }
1804	;
1805
1806	wand_waituntil_clause:
1807	waituntil_clause %prec THEN
1808	{ $$ = $1; }
1809	\| waituntil_clause wand wand_waituntil_clause
1810	{ $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::AND, $1, $3 ); }
1811	;
1812
1813	wor_waituntil_clause:
1814	wand_waituntil_clause
1815	{ $$ = $1; }
1816	\| wor_waituntil_clause wor wand_waituntil_clause
1817	{ $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::OR, $1, $3 ); }
1818	\| wor_waituntil_clause wor when_clause_opt ELSE statement
1819	{ $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::LEFT_OR, $1, build_waituntil_else( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1820	;
1821
1822	waituntil_statement:
1823	wor_waituntil_clause %prec THEN
1824	{ $$ = new StatementNode( build_waituntil_stmt( yylloc, $1 ) ); }
1825	;
1826
1827	corun_statement:
1828	CORUN statement
1829	{ $$ = new StatementNode( build_corun( yylloc, $2 ) ); }
1830	;
1831
1832	cofor_statement:
1833	COFOR '(' for_control_expression_list ')' statement
1834	{ $$ = new StatementNode( build_cofor( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1835	;
1836
1837	exception_statement:
1838	TRY compound_statement handler_clause %prec THEN
1839	{ $$ = new StatementNode( build_try( yylloc, $2, $3, nullptr ) ); }
1840	\| TRY compound_statement finally_clause
1841	{ $$ = new StatementNode( build_try( yylloc, $2, nullptr, $3 ) ); }
1842	\| TRY compound_statement handler_clause finally_clause
1843	{ $$ = new StatementNode( build_try( yylloc, $2, $3, $4 ) ); }
1844	;
1845
1846	handler_clause:
1847	handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1848	{ $$ = new ClauseNode( build_catch( yylloc, $1, $4, $6, $8 ) ); }
1849	\| handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1850	{ $$ = $1->set_last( new ClauseNode( build_catch( yylloc, $2, $5, $7, $9 ) ) ); }
1851	;
1852
1853	handler_predicate_opt:
1854	// empty
1855	{ $$ = nullptr; }
1856	\| ';' conditional_expression { $$ = $2; }
1857	;
1858
1859	handler_key:
1860	CATCH { $$ = ast::Terminate; }
1861	\| RECOVER { $$ = ast::Terminate; }
1862	\| CATCHRESUME { $$ = ast::Resume; }
1863	\| FIXUP { $$ = ast::Resume; }
1864	;
1865
1866	finally_clause:
1867	FINALLY compound_statement { $$ = new ClauseNode( build_finally( yylloc, $2 ) ); }
1868	;
1869
1870	exception_declaration:
1871	// No SUE declaration in parameter list.
1872	type_specifier_nobody
1873	\| type_specifier_nobody declarator
1874	{ $$ = $2->addType( $1 ); }
1875	\| type_specifier_nobody variable_abstract_declarator
1876	{ $$ = $2->addType( $1 ); }
1877	\| cfa_abstract_declarator_tuple identifier // CFA
1878	{ $$ = $1->addName( $2 ); }
1879	\| cfa_abstract_declarator_tuple // CFA
1880	;
1881
1882	enable_disable_statement:
1883	enable_disable_key identifier_list compound_statement
1884	;
1885
1886	enable_disable_key:
1887	ENABLE
1888	\| DISABLE
1889	;
1890
1891	asm_statement:
1892	ASM asm_volatile_opt '(' string_literal ')' ';'
1893	{ $$ = new StatementNode( build_asm( yylloc, $2, $4, nullptr ) ); }
1894	\| ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1895	{ $$ = new StatementNode( build_asm( yylloc, $2, $4, $6 ) ); }
1896	\| ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1897	{ $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8 ) ); }
1898	\| ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1899	{ $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8, $10 ) ); }
1900	\| ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1901	{ $$ = new StatementNode( build_asm( yylloc, $2, $5, nullptr, $8, $10, $12 ) ); }
1902	;
1903
1904	asm_volatile_opt: // GCC
1905	// empty
1906	{ $$ = false; }
1907	\| VOLATILE
1908	{ $$ = true; }
1909	;
1910
1911	asm_operands_opt: // GCC
1912	// empty
1913	{ $$ = nullptr; } // use default argument
1914	\| asm_operands_list
1915	;
1916
1917	asm_operands_list: // GCC
1918	asm_operand
1919	\| asm_operands_list ',' asm_operand
1920	{ $$ = $1->set_last( $3 ); }
1921	;
1922
1923	asm_operand: // GCC
1924	string_literal '(' constant_expression ')'
1925	{ $$ = new ExpressionNode( new ast::AsmExpr( yylloc, "", maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1926	\| '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1927	{
1928	$$ = new ExpressionNode( new ast::AsmExpr( yylloc, *$2.str, maybeMoveBuild( $4 ), maybeMoveBuild( $6 ) ) );
1929	delete $2.str;
1930	}
1931	;
1932
1933	asm_clobbers_list_opt: // GCC
1934	// empty
1935	{ $$ = nullptr; } // use default argument
1936	\| string_literal
1937	{ $$ = $1; }
1938	\| asm_clobbers_list_opt ',' string_literal
1939	{ $$ = $1->set_last( $3 ); }
1940	;
1941
1942	label_list:
1943	identifier
1944	{
1945	$$ = new LabelNode(); $$->labels.emplace_back( yylloc, *$1 );
1946	delete $1; // allocated by lexer
1947	}
1948	\| label_list ',' identifier
1949	{
1950	$$ = $1; $1->labels.emplace_back( yylloc, *$3 );
1951	delete $3; // allocated by lexer
1952	}
1953	;
1954
1955	// **************************** DECLARATIONS *******************************
1956
1957	declaration_list_opt: // used at beginning of switch statement
1958	// empty
1959	{ $$ = nullptr; }
1960	\| declaration_list
1961	;
1962
1963	declaration_list:
1964	declaration
1965	\| declaration_list declaration
1966	{ $$ = $1->set_last( $2 ); }
1967	;
1968
1969	KR_parameter_list_opt: // used to declare parameter types in K&R style functions
1970	// empty
1971	{ $$ = nullptr; }
1972	\| KR_parameter_list
1973	;
1974
1975	KR_parameter_list:
1976	c_declaration ';'
1977	{ $$ = $1; }
1978	\| KR_parameter_list c_declaration ';'
1979	{ $$ = $1->set_last( $2 ); }
1980	;
1981
1982	local_label_declaration_opt: // GCC, local label
1983	// empty
1984	\| local_label_declaration_list
1985	;
1986
1987	local_label_declaration_list: // GCC, local label
1988	LABEL local_label_list ';'
1989	\| local_label_declaration_list LABEL local_label_list ';'
1990	;
1991
1992	local_label_list: // GCC, local label
1993	identifier_or_type_name
1994	\| local_label_list ',' identifier_or_type_name
1995	;
1996
1997	declaration: // old & new style declarations
1998	c_declaration ';'
1999	\| cfa_declaration ';' // CFA
2000	\| static_assert ';' // C11
2001	;
2002
2003	static_assert:
2004	STATICASSERT '(' constant_expression ',' string_literal ')' // C11
2005	{ $$ = DeclarationNode::newStaticAssert( $3, maybeMoveBuild( $5 ) ); }
2006	\| STATICASSERT '(' constant_expression ')' // CFA
2007	{ $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( yylloc, *new string( "\"\"" ) ) ); }
2008
2009	// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
2010	// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
2011	// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
2012	// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
2013	// the declaration list (as in Pascal). ANSI C and the new CFA declarations may appear together in the same program
2014	// block, but cannot be mixed within a specific declaration.
2015	//
2016	// CFA C
2017	// [10] int x; int x[10]; // array of 10 integers
2018	// [10] * char y; char *y[10]; // array of 10 pointers to char
2019
2020	cfa_declaration: // CFA
2021	cfa_variable_declaration
2022	\| cfa_typedef_declaration
2023	\| cfa_function_declaration
2024	\| type_declaring_list
2025	{ SemanticError( yylloc, "otype declaration is currently unimplemented." ); $$ = nullptr; }
2026	\| trait_specifier
2027	;
2028
2029	cfa_variable_declaration: // CFA
2030	cfa_variable_specifier initializer_opt
2031	{ $$ = $1->addInitializer( $2 ); }
2032	\| declaration_qualifier_list cfa_variable_specifier initializer_opt
2033	// declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
2034	// them as a type_qualifier cannot appear in that context.
2035	{ $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
2036	\| cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
2037	{ $$ = $1->set_last( $1->cloneType( $5 )->addInitializer( $6 ) ); }
2038	;
2039
2040	cfa_variable_specifier: // CFA
2041	// A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
2042	// storage-class
2043	cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
2044	{ $$ = $1->addName( $2 )->addAsmName( $3 ); }
2045	\| cfa_abstract_tuple identifier_or_type_name asm_name_opt
2046	{ $$ = $1->addName( $2 )->addAsmName( $3 ); }
2047	\| type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
2048	{ $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
2049
2050	// [ int s, int t ]; // declare s and t
2051	// [ int, int ] f();
2052	// [] g( int );
2053	// [ int x, int y ] = f(); // declare x and y, initialize each from f
2054	// g( x + y );
2055	\| cfa_function_return asm_name_opt
2056	{ SemanticError( yylloc, "tuple-element declarations is currently unimplemented." ); $$ = nullptr; }
2057	\| type_qualifier_list cfa_function_return asm_name_opt
2058	{ SemanticError( yylloc, "tuple variable declaration is currently unimplemented." ); $$ = nullptr; }
2059	;
2060
2061	cfa_function_declaration: // CFA
2062	cfa_function_specifier
2063	\| type_qualifier_list cfa_function_specifier
2064	{ $$ = $2->addQualifiers( $1 ); }
2065	\| declaration_qualifier_list cfa_function_specifier
2066	{ $$ = $2->addQualifiers( $1 ); }
2067	\| declaration_qualifier_list type_qualifier_list cfa_function_specifier
2068	{ $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
2069	\| cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')'
2070	{
2071	// Append the return type at the start (left-hand-side) to each identifier in the list.
2072	DeclarationNode * ret = new DeclarationNode;
2073	ret->type = maybeCopy( $1->type->base );
2074	$$ = $1->set_last( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
2075	}
2076	;
2077
2078	cfa_function_specifier: // CFA
2079	'[' ']' identifier '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2080	{ $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2081	\| '[' ']' TYPEDEFname '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2082	{ $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2083	// \| '[' ']' TYPEGENname '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2084	// { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2085
2086	// identifier_or_type_name must be broken apart because of the sequence:
2087	//
2088	// '[' ']' identifier_or_type_name '(' cfa_parameter_list_ellipsis_opt ')'
2089	// '[' ']' type_specifier
2090	//
2091	// type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
2092	// flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
2093	\| cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2094	// To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
2095	{ $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
2096	\| cfa_function_return identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2097	{ $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
2098	;
2099
2100	cfa_function_return: // CFA
2101	'[' push cfa_parameter_list pop ']'
2102	{ $$ = DeclarationNode::newTuple( $3 ); }
2103	\| '[' push cfa_parameter_list ',' cfa_abstract_parameter_list pop ']'
2104	// To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
2105	{ $$ = DeclarationNode::newTuple( $3->set_last( $5 ) ); }
2106	;
2107
2108	cfa_typedef_declaration: // CFA
2109	TYPEDEF cfa_variable_specifier
2110	{
2111	typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "cfa_typedef_declaration 1" );
2112	$$ = $2->addTypedef();
2113	}
2114	\| TYPEDEF cfa_function_specifier
2115	{
2116	typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "cfa_typedef_declaration 2" );
2117	$$ = $2->addTypedef();
2118	}
2119	\| cfa_typedef_declaration ',' identifier
2120	{
2121	typedefTable.addToEnclosingScope( *$3, TYPEDEFname, "cfa_typedef_declaration 3" );
2122	$$ = $1->set_last( $1->cloneType( $3 ) );
2123	}
2124	;
2125
2126	// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
2127	// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
2128
2129	typedef_declaration:
2130	TYPEDEF type_specifier declarator
2131	{
2132	typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "typedef_declaration 1" );
2133	if ( $2->type->forall \|\| ($2->type->kind == TypeData::Aggregate && $2->type->aggregate.params) ) {
2134	SemanticError( yylloc, "forall qualifier in typedef is currently unimplemented." ); $$ = nullptr;
2135	} else $$ = $3->addType( $2 )->addTypedef(); // watchout frees $2 and $3
2136	}
2137	\| typedef_declaration ',' declarator
2138	{
2139	typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "typedef_declaration 2" );
2140	$$ = $1->set_last( $1->cloneBaseType( $3 )->addTypedef() );
2141	}
2142	\| type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
2143	{ SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2144	\| type_specifier TYPEDEF declarator
2145	{ SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2146	\| type_specifier TYPEDEF type_qualifier_list declarator
2147	{ SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2148	;
2149
2150	typedef_expression:
2151	// deprecated GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
2152	TYPEDEF identifier '=' assignment_expression
2153	{
2154	SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
2155	}
2156	\| typedef_expression ',' identifier '=' assignment_expression
2157	{
2158	SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
2159	}
2160	;
2161
2162	c_declaration:
2163	declaration_specifier declaring_list
2164	{ $$ = distAttr( $1, $2 ); }
2165	\| typedef_declaration
2166	\| typedef_expression // deprecated GCC, naming expression type
2167	\| sue_declaration_specifier
2168	{
2169	assert( $1->type );
2170	if ( $1->type->qualifiers.any() ) { // CV qualifiers ?
2171	SemanticError( yylloc, "illegal syntax, useless type qualifier(s) in empty declaration." ); $$ = nullptr;
2172	}
2173	// enums are never empty declarations because there must have at least one enumeration.
2174	if ( $1->type->kind == TypeData::AggregateInst && $1->storageClasses.any() ) { // storage class ?
2175	SemanticError( yylloc, "illegal syntax, useless storage qualifier(s) in empty aggregate declaration." ); $$ = nullptr;
2176	}
2177	}
2178	;
2179
2180	declaring_list:
2181	// A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
2182	// storage-class
2183	variable_declarator asm_name_opt initializer_opt
2184	{ $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2185	\| variable_type_redeclarator asm_name_opt initializer_opt
2186	{ $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2187
2188	\| general_function_declarator asm_name_opt
2189	{ $$ = $1->addAsmName( $2 )->addInitializer( nullptr ); }
2190	\| general_function_declarator asm_name_opt '=' VOID
2191	{ $$ = $1->addAsmName( $2 )->addInitializer( new InitializerNode( true ) ); }
2192
2193	\| declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
2194	{ $$ = $1->set_last( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
2195	;
2196
2197	general_function_declarator:
2198	function_type_redeclarator
2199	\| function_declarator
2200	;
2201
2202	declaration_specifier: // type specifier + storage class
2203	basic_declaration_specifier
2204	\| type_declaration_specifier
2205	\| sue_declaration_specifier
2206	\| sue_declaration_specifier invalid_types // invalid syntax rule
2207	{
2208	SemanticError( yylloc, "illegal syntax, expecting ';' at end of \"%s\" declaration.",
2209	ast::AggregateDecl::aggrString( $1->type->aggregate.kind ) );
2210	$$ = nullptr;
2211	}
2212	;
2213
2214	invalid_types:
2215	aggregate_key
2216	\| basic_type_name
2217	\| indirect_type
2218	;
2219
2220	declaration_specifier_nobody: // type specifier + storage class - {...}
2221	// Preclude SUE declarations in restricted scopes:
2222	//
2223	// int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2224	//
2225	// because it is impossible to call f due to name equivalence.
2226	basic_declaration_specifier
2227	\| sue_declaration_specifier_nobody
2228	\| type_declaration_specifier
2229	;
2230
2231	type_specifier: // type specifier
2232	basic_type_specifier
2233	\| sue_type_specifier
2234	\| type_type_specifier
2235	;
2236
2237	type_specifier_nobody: // type specifier - {...}
2238	// Preclude SUE declarations in restricted scopes:
2239	//
2240	// int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2241	//
2242	// because it is impossible to call f due to name equivalence.
2243	basic_type_specifier
2244	\| sue_type_specifier_nobody
2245	\| type_type_specifier
2246	;
2247
2248	type_qualifier_list_opt: // GCC, used in asm_statement
2249	// empty
2250	{ $$ = nullptr; }
2251	\| type_qualifier_list
2252	;
2253
2254	type_qualifier_list:
2255	// A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
2256	//
2257	// ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
2258	// specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
2259	// appeared only once.
2260	type_qualifier
2261	\| type_qualifier_list type_qualifier
2262	{ $$ = $1->addQualifiers( $2 ); }
2263	;
2264
2265	type_qualifier:
2266	type_qualifier_name
2267	{ $$ = DeclarationNode::newFromTypeData( $1 ); }
2268	\| attribute // trick handles most attribute locations
2269	;
2270
2271	type_qualifier_name:
2272	CONST
2273	{ $$ = build_type_qualifier( ast::CV::Const ); }
2274	\| RESTRICT
2275	{ $$ = build_type_qualifier( ast::CV::Restrict ); }
2276	\| VOLATILE
2277	{ $$ = build_type_qualifier( ast::CV::Volatile ); }
2278	\| ATOMIC
2279	{ $$ = build_type_qualifier( ast::CV::Atomic ); }
2280
2281	// forall is a CV qualifier because it can appear in places where SC qualifiers are disallowed.
2282	//
2283	// void foo( forall( T ) T (*)( T ) ); // forward declaration
2284	// void bar( static int ); // static disallowed (gcc/CFA)
2285	\| forall
2286	{ $$ = build_forall( $1 ); }
2287	;
2288
2289	forall:
2290	FORALL '(' type_parameter_list ')' // CFA
2291	{ $$ = $3; }
2292	;
2293
2294	declaration_qualifier_list:
2295	storage_class_list
2296	\| type_qualifier_list storage_class_list // remaining OBSOLESCENT (see 2 )
2297	{ $$ = $1->addQualifiers( $2 ); }
2298	\| declaration_qualifier_list type_qualifier_list storage_class_list
2299	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2300	;
2301
2302	storage_class_list:
2303	// A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
2304	// only one of each is specified, except for inline, which can appear with the others.
2305	//
2306	// ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
2307	// specifiers in a declaration.
2308	storage_class
2309	\| storage_class_list storage_class
2310	{ $$ = $1->addQualifiers( $2 ); }
2311	;
2312
2313	storage_class:
2314	EXTERN
2315	{ $$ = DeclarationNode::newStorageClass( ast::Storage::Extern ); }
2316	\| STATIC
2317	{ $$ = DeclarationNode::newStorageClass( ast::Storage::Static ); }
2318	\| AUTO
2319	{ $$ = DeclarationNode::newStorageClass( ast::Storage::Auto ); }
2320	\| REGISTER
2321	{ $$ = DeclarationNode::newStorageClass( ast::Storage::Register ); }
2322	\| THREADLOCALGCC // GCC
2323	{ $$ = DeclarationNode::newStorageClass( ast::Storage::ThreadLocalGcc ); }
2324	\| THREADLOCALC11 // C11
2325	{ $$ = DeclarationNode::newStorageClass( ast::Storage::ThreadLocalC11 ); }
2326	// Put function specifiers here to simplify parsing rules, but separate them semantically.
2327	\| INLINE // C99
2328	{ $$ = DeclarationNode::newFuncSpecifier( ast::Function::Inline ); }
2329	\| FORTRAN // C99
2330	{ $$ = DeclarationNode::newFuncSpecifier( ast::Function::Fortran ); }
2331	\| NORETURN // C11
2332	{ $$ = DeclarationNode::newFuncSpecifier( ast::Function::Noreturn ); }
2333	;
2334
2335	basic_type_name:
2336	basic_type_name_type
2337	{ $$ = DeclarationNode::newFromTypeData( $1 ); }
2338	;
2339
2340	// Just an intermediate value for conversion.
2341	basic_type_name_type:
2342	VOID
2343	{ $$ = build_basic_type( TypeData::Void ); }
2344	\| BOOL // C99
2345	{ $$ = build_basic_type( TypeData::Bool ); }
2346	\| CHAR
2347	{ $$ = build_basic_type( TypeData::Char ); }
2348	\| INT
2349	{ $$ = build_basic_type( TypeData::Int ); }
2350	\| INT128
2351	{ $$ = build_basic_type( TypeData::Int128 ); }
2352	\| UINT128
2353	{ $$ = addType( build_basic_type( TypeData::Int128 ), build_signedness( TypeData::Unsigned ) ); }
2354	\| FLOAT
2355	{ $$ = build_basic_type( TypeData::Float ); }
2356	\| DOUBLE
2357	{ $$ = build_basic_type( TypeData::Double ); }
2358	\| uuFLOAT80
2359	{ $$ = build_basic_type( TypeData::uuFloat80 ); }
2360	\| uuFLOAT128
2361	{ $$ = build_basic_type( TypeData::uuFloat128 ); }
2362	\| uFLOAT16
2363	{ $$ = build_basic_type( TypeData::uFloat16 ); }
2364	\| uFLOAT32
2365	{ $$ = build_basic_type( TypeData::uFloat32 ); }
2366	\| uFLOAT32X
2367	{ $$ = build_basic_type( TypeData::uFloat32x ); }
2368	\| uFLOAT64
2369	{ $$ = build_basic_type( TypeData::uFloat64 ); }
2370	\| uFLOAT64X
2371	{ $$ = build_basic_type( TypeData::uFloat64x ); }
2372	\| uFLOAT128
2373	{ $$ = build_basic_type( TypeData::uFloat128 ); }
2374	\| DECIMAL32
2375	{ SemanticError( yylloc, "_Decimal32 is currently unimplemented." ); $$ = nullptr; }
2376	\| DECIMAL64
2377	{ SemanticError( yylloc, "_Decimal64 is currently unimplemented." ); $$ = nullptr; }
2378	\| DECIMAL128
2379	{ SemanticError( yylloc, "_Decimal128 is currently unimplemented." ); $$ = nullptr; }
2380	\| COMPLEX // C99
2381	{ $$ = build_complex_type( TypeData::Complex ); }
2382	\| IMAGINARY // C99
2383	{ $$ = build_complex_type( TypeData::Imaginary ); }
2384	\| SIGNED
2385	{ $$ = build_signedness( TypeData::Signed ); }
2386	\| UNSIGNED
2387	{ $$ = build_signedness( TypeData::Unsigned ); }
2388	\| SHORT
2389	{ $$ = build_length( TypeData::Short ); }
2390	\| LONG
2391	{ $$ = build_length( TypeData::Long ); }
2392	\| VA_LIST // GCC, __builtin_va_list
2393	{ $$ = build_builtin_type( TypeData::Valist ); }
2394	\| AUTO_TYPE
2395	{ $$ = build_builtin_type( TypeData::AutoType ); }
2396	\| vtable
2397	;
2398
2399	vtable_opt:
2400	// empty
2401	{ $$ = nullptr; }
2402	\| vtable
2403	;
2404
2405	vtable:
2406	VTABLE '(' type_name ')' default_opt
2407	{ $$ = build_vtable_type( $3 ); }
2408	;
2409
2410	default_opt:
2411	// empty
2412	{ $$ = nullptr; }
2413	\| DEFAULT
2414	{ SemanticError( yylloc, "vtable default is currently unimplemented." ); $$ = nullptr; }
2415	;
2416
2417	basic_declaration_specifier:
2418	// A semantic check is necessary for conflicting storage classes.
2419	basic_type_specifier
2420	\| declaration_qualifier_list basic_type_specifier
2421	{ $$ = $2->addQualifiers( $1 ); }
2422	\| basic_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2423	{ $$ = $1->addQualifiers( $2 ); }
2424	\| basic_declaration_specifier storage_class type_qualifier_list
2425	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2426	\| basic_declaration_specifier storage_class basic_type_specifier
2427	{ $$ = $3->addQualifiers( $2 )->addType( $1 ); }
2428	;
2429
2430	basic_type_specifier:
2431	direct_type
2432	// Cannot have type modifiers, e.g., short, long, etc.
2433	\| type_qualifier_list_opt indirect_type type_qualifier_list_opt
2434	{ $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
2435	;
2436
2437	direct_type:
2438	basic_type_name
2439	\| type_qualifier_list basic_type_name
2440	{ $$ = $2->addQualifiers( $1 ); }
2441	\| direct_type type_qualifier
2442	{ $$ = $1->addQualifiers( $2 ); }
2443	\| direct_type basic_type_name
2444	{ $$ = $1->addType( $2 ); }
2445	;
2446
2447	indirect_type:
2448	TYPEOF '(' type ')' // GCC: typeof( x ) y;
2449	{ $$ = $3; }
2450	\| TYPEOF '(' comma_expression ')' // GCC: typeof( a+b ) y;
2451	{ $$ = DeclarationNode::newTypeof( $3 ); }
2452	\| BASETYPEOF '(' type ')' // CFA: basetypeof( x ) y;
2453	{ $$ = DeclarationNode::newTypeof( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ), true ); }
2454	\| BASETYPEOF '(' comma_expression ')' // CFA: basetypeof( a+b ) y;
2455	{ $$ = DeclarationNode::newTypeof( $3, true ); }
2456	\| ZERO_T // CFA
2457	{ $$ = DeclarationNode::newFromTypeData( build_builtin_type( TypeData::Zero ) ); }
2458	\| ONE_T // CFA
2459	{ $$ = DeclarationNode::newFromTypeData( build_builtin_type( TypeData::One ) ); }
2460	;
2461
2462	sue_declaration_specifier: // struct, union, enum + storage class + type specifier
2463	sue_type_specifier
2464	\| declaration_qualifier_list sue_type_specifier
2465	{ $$ = $2->addQualifiers( $1 ); }
2466	\| sue_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2467	{ $$ = $1->addQualifiers( $2 ); }
2468	\| sue_declaration_specifier storage_class type_qualifier_list
2469	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2470	;
2471
2472	sue_type_specifier: // struct, union, enum + type specifier
2473	elaborated_type
2474	\| type_qualifier_list
2475	{ if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
2476	elaborated_type
2477	{ $$ = $3->addQualifiers( $1 ); }
2478	\| sue_type_specifier type_qualifier
2479	{
2480	if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
2481	$$ = $1->addQualifiers( $2 );
2482	}
2483	;
2484
2485	sue_declaration_specifier_nobody: // struct, union, enum - {...} + storage class + type specifier
2486	sue_type_specifier_nobody
2487	\| declaration_qualifier_list sue_type_specifier_nobody
2488	{ $$ = $2->addQualifiers( $1 ); }
2489	\| sue_declaration_specifier_nobody storage_class // remaining OBSOLESCENT (see 2)
2490	{ $$ = $1->addQualifiers( $2 ); }
2491	\| sue_declaration_specifier_nobody storage_class type_qualifier_list
2492	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2493	;
2494
2495	sue_type_specifier_nobody: // struct, union, enum - {...} + type specifier
2496	elaborated_type_nobody
2497	\| type_qualifier_list elaborated_type_nobody
2498	{ $$ = $2->addQualifiers( $1 ); }
2499	\| sue_type_specifier_nobody type_qualifier
2500	{ $$ = $1->addQualifiers( $2 ); }
2501	;
2502
2503	type_declaration_specifier:
2504	type_type_specifier
2505	\| declaration_qualifier_list type_type_specifier
2506	{ $$ = $2->addQualifiers( $1 ); }
2507	\| type_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2508	{ $$ = $1->addQualifiers( $2 ); }
2509	\| type_declaration_specifier storage_class type_qualifier_list
2510	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2511	;
2512
2513	type_type_specifier: // typedef types
2514	type_name
2515	{ $$ = DeclarationNode::newFromTypeData( $1 ); }
2516	\| type_qualifier_list type_name
2517	{ $$ = DeclarationNode::newFromTypeData( $2 )->addQualifiers( $1 ); }
2518	\| type_type_specifier type_qualifier
2519	{ $$ = $1->addQualifiers( $2 ); }
2520	;
2521
2522	type_name:
2523	TYPEDEFname
2524	{ $$ = build_typedef( $1 ); }
2525	\| '.' TYPEDEFname
2526	{ $$ = build_qualified_type( build_global_scope(), build_typedef( $2 ) ); }
2527	\| type_name '.' TYPEDEFname
2528	{ $$ = build_qualified_type( $1, build_typedef( $3 ) ); }
2529	\| typegen_name
2530	\| '.' typegen_name
2531	{ $$ = build_qualified_type( build_global_scope(), $2 ); }
2532	\| type_name '.' typegen_name
2533	{ $$ = build_qualified_type( $1, $3 ); }
2534	;
2535
2536	typegen_name: // CFA
2537	TYPEGENname
2538	{ $$ = build_type_gen( $1, nullptr ); }
2539	\| TYPEGENname '(' ')'
2540	{ $$ = build_type_gen( $1, nullptr ); }
2541	\| TYPEGENname '(' type_list ')'
2542	{ $$ = build_type_gen( $1, $3 ); }
2543	;
2544
2545	elaborated_type: // struct, union, enum
2546	aggregate_type
2547	\| enum_type
2548	;
2549
2550	elaborated_type_nobody: // struct, union, enum - {...}
2551	aggregate_type_nobody
2552	\| enum_type_nobody
2553	;
2554
2555	// ************************ AGGREGATE *****************************
2556
2557	aggregate_type: // struct, union
2558	aggregate_key attribute_list_opt
2559	{ forall = false; } // reset
2560	'{' field_declaration_list_opt '}' type_parameters_opt
2561	{ $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2562	\| aggregate_key attribute_list_opt identifier
2563	{
2564	typedefTable.makeTypedef( *$3, forall \|\| typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 1" );
2565	forall = false; // reset
2566	}
2567	'{' field_declaration_list_opt '}' type_parameters_opt
2568	{
2569	$$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2570	}
2571	\| aggregate_key attribute_list_opt TYPEDEFname // unqualified type name
2572	{
2573	typedefTable.makeTypedef( *$3, forall \|\| typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 2" );
2574	forall = false; // reset
2575	}
2576	'{' field_declaration_list_opt '}' type_parameters_opt
2577	{
2578	DeclarationNode::newFromTypeData( build_typedef( $3 ) );
2579	$$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2580	}
2581	\| aggregate_key attribute_list_opt TYPEGENname // unqualified type name
2582	{
2583	typedefTable.makeTypedef( *$3, forall \|\| typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 3" );
2584	forall = false; // reset
2585	}
2586	'{' field_declaration_list_opt '}' type_parameters_opt
2587	{
2588	DeclarationNode::newFromTypeData( build_type_gen( $3, nullptr ) );
2589	$$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2590	}
2591	\| aggregate_type_nobody
2592	;
2593
2594	type_parameters_opt:
2595	// empty
2596	{ $$ = nullptr; } %prec '}'
2597	\| '(' type_list ')'
2598	{ $$ = $2; }
2599	;
2600
2601	aggregate_type_nobody: // struct, union - {...}
2602	aggregate_key attribute_list_opt identifier
2603	{
2604	typedefTable.makeTypedef( *$3, forall \|\| typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type_nobody" );
2605	forall = false; // reset
2606	$$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2607	}
2608	\| aggregate_key attribute_list_opt type_name
2609	{
2610	forall = false; // reset
2611	// Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2612	// switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2613	// delete newFromTypeGen.
2614	if ( $3->kind == TypeData::SymbolicInst && ! $3->symbolic.isTypedef ) {
2615	$$ = DeclarationNode::newFromTypeData( $3 )->addQualifiers( $2 );
2616	} else {
2617	$$ = DeclarationNode::newAggregate( $1, $3->symbolic.name, $3->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2618	$3->symbolic.name = nullptr; // copied to $$
2619	$3->symbolic.actuals = nullptr;
2620	delete $3;
2621	}
2622	}
2623	;
2624
2625	aggregate_key:
2626	aggregate_data
2627	\| aggregate_control
2628	;
2629
2630	aggregate_data:
2631	STRUCT vtable_opt
2632	{ $$ = ast::AggregateDecl::Struct; }
2633	\| UNION
2634	{ $$ = ast::AggregateDecl::Union; }
2635	\| EXCEPTION // CFA
2636	{ $$ = ast::AggregateDecl::Exception; }
2637	;
2638
2639	aggregate_control: // CFA
2640	MONITOR
2641	{ $$ = ast::AggregateDecl::Monitor; }
2642	\| MUTEX STRUCT
2643	{ $$ = ast::AggregateDecl::Monitor; }
2644	\| GENERATOR
2645	{ $$ = ast::AggregateDecl::Generator; }
2646	\| MUTEX GENERATOR
2647	{
2648	SemanticError( yylloc, "monitor generator is currently unimplemented." );
2649	$$ = ast::AggregateDecl::NoAggregate;
2650	}
2651	\| COROUTINE
2652	{ $$ = ast::AggregateDecl::Coroutine; }
2653	\| MUTEX COROUTINE
2654	{
2655	SemanticError( yylloc, "monitor coroutine is currently unimplemented." );
2656	$$ = ast::AggregateDecl::NoAggregate;
2657	}
2658	\| THREAD
2659	{ $$ = ast::AggregateDecl::Thread; }
2660	\| MUTEX THREAD
2661	{
2662	SemanticError( yylloc, "monitor thread is currently unimplemented." );
2663	$$ = ast::AggregateDecl::NoAggregate;
2664	}
2665	;
2666
2667	field_declaration_list_opt:
2668	// empty
2669	{ $$ = nullptr; }
2670	\| field_declaration_list_opt field_declaration
2671	{ $$ = $1 ? $1->set_last( $2 ) : $2; }
2672	;
2673
2674	field_declaration:
2675	type_specifier field_declaring_list_opt ';'
2676	{
2677	// printf( "type_specifier1 %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2678	$$ = fieldDecl( $1, $2 );
2679	// printf( "type_specifier2 %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2680	// for ( Attribute * attr: reverseIterate( $$->attributes ) ) {
2681	// printf( "\tattr %s\n", attr->name.c_str() );
2682	// } // for
2683	}
2684	\| type_specifier field_declaring_list_opt '}' // invalid syntax rule
2685	{
2686	SemanticError( yylloc, "illegal syntax, expecting ';' at end of previous declaration." );
2687	$$ = nullptr;
2688	}
2689	\| EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2690	{ $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2691	\| STATIC type_specifier field_declaring_list_opt ';' // CFA
2692	{ SemanticError( yylloc, "STATIC aggregate field qualifier currently unimplemented." ); $$ = nullptr; }
2693	\| INLINE type_specifier field_abstract_list_opt ';' // CFA
2694	{
2695	if ( ! $3 ) { // field declarator ?
2696	$3 = DeclarationNode::newName( nullptr );
2697	} // if
2698	$3->inLine = true;
2699	$$ = distAttr( $2, $3 ); // mark all fields in list
2700	distInl( $3 );
2701	}
2702	\| INLINE aggregate_control ';' // CFA
2703	{ SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2704	\| typedef_declaration ';' // CFA
2705	\| cfa_field_declaring_list ';' // CFA, new style field declaration
2706	\| EXTENSION cfa_field_declaring_list ';' // GCC
2707	{ distExt( $2 ); $$ = $2; } // mark all fields in list
2708	\| INLINE cfa_field_abstract_list ';' // CFA, new style field declaration
2709	{ $$ = $2; } // mark all fields in list
2710	\| cfa_typedef_declaration ';' // CFA
2711	\| static_assert ';' // C11
2712	;
2713
2714	field_declaring_list_opt:
2715	// empty
2716	{ $$ = nullptr; }
2717	\| field_declarator
2718	\| field_declaring_list_opt ',' attribute_list_opt field_declarator
2719	{ $$ = $1->set_last( $4->addQualifiers( $3 ) ); }
2720	;
2721
2722	field_declarator:
2723	bit_subrange_size // C special case, no field name
2724	{ $$ = DeclarationNode::newBitfield( $1 ); }
2725	\| variable_declarator bit_subrange_size_opt
2726	// A semantic check is required to ensure bit_subrange only appears on integral types.
2727	{ $$ = $1->addBitfield( $2 ); }
2728	\| variable_type_redeclarator bit_subrange_size_opt
2729	// A semantic check is required to ensure bit_subrange only appears on integral types.
2730	{ $$ = $1->addBitfield( $2 ); }
2731	\| function_type_redeclarator bit_subrange_size_opt
2732	// A semantic check is required to ensure bit_subrange only appears on integral types.
2733	{ $$ = $1->addBitfield( $2 ); }
2734	;
2735
2736	field_abstract_list_opt:
2737	// empty
2738	{ $$ = nullptr; }
2739	\| field_abstract
2740	\| field_abstract_list_opt ',' attribute_list_opt field_abstract
2741	{ $$ = $1->set_last( $4->addQualifiers( $3 ) ); }
2742	;
2743
2744	field_abstract:
2745	// no bit fields
2746	variable_abstract_declarator
2747	;
2748
2749	cfa_field_declaring_list: // CFA, new style field declaration
2750	// bit-fields are handled by C declarations
2751	cfa_abstract_declarator_tuple identifier_or_type_name
2752	{ $$ = $1->addName( $2 ); }
2753	\| cfa_field_declaring_list ',' identifier_or_type_name
2754	{ $$ = $1->set_last( $1->cloneType( $3 ) ); }
2755	;
2756
2757	cfa_field_abstract_list: // CFA, new style field declaration
2758	// bit-fields are handled by C declarations
2759	cfa_abstract_declarator_tuple
2760	\| cfa_field_abstract_list ','
2761	{ $$ = $1->set_last( $1->cloneType( 0 ) ); }
2762	;
2763
2764	bit_subrange_size_opt:
2765	// empty
2766	{ $$ = nullptr; }
2767	\| bit_subrange_size
2768	;
2769
2770	bit_subrange_size:
2771	':' assignment_expression
2772	{ $$ = $2; }
2773	;
2774
2775	// ************************ ENUMERATION *****************************
2776
2777	enum_type:
2778	// anonymous, no type name
2779	ENUM attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2780	{
2781	if ( $3 == EnumHiding::Hide ) {
2782	SemanticError( yylloc, "illegal syntax, hiding ('!') the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr;
2783	} // if
2784	$$ = DeclarationNode::newEnum( nullptr, $5, true, false )->addQualifiers( $2 );
2785	}
2786	\| ENUM enumerator_type attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2787	{
2788	if ( $2 && ($2->storageClasses.val != 0 \|\| $2->type->qualifiers.any()) ) {
2789	SemanticError( yylloc, "illegal syntax, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2790	}
2791	if ( $4 == EnumHiding::Hide ) {
2792	SemanticError( yylloc, "illegal syntax, hiding ('!') the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr;
2793	} // if
2794	$$ = DeclarationNode::newEnum( nullptr, $6, true, true, $2 )->addQualifiers( $3 );
2795	}
2796
2797	// named type
2798	\| ENUM attribute_list_opt identifier
2799	{ typedefTable.makeTypedef( *$3, "enum_type 1" ); }
2800	hide_opt '{' enumerator_list comma_opt '}'
2801	{ $$ = DeclarationNode::newEnum( $3, $7, true, false, nullptr, $5 )->addQualifiers( $2 ); }
2802	\| ENUM attribute_list_opt typedef_name hide_opt '{' enumerator_list comma_opt '}' // unqualified type name
2803	{ $$ = DeclarationNode::newEnum( $3->name, $6, true, false, nullptr, $4 )->addQualifiers( $2 ); }
2804	\| ENUM enumerator_type attribute_list_opt identifier attribute_list_opt
2805	{
2806	if ( $2 && ($2->storageClasses.any() \|\| $2->type->qualifiers.val != 0) ) {
2807	SemanticError( yylloc, "illegal syntax, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2808	}
2809	typedefTable.makeTypedef( *$4, "enum_type 2" );
2810	}
2811	hide_opt '{' enumerator_list comma_opt '}'
2812	{ $$ = DeclarationNode::newEnum( $4, $9, true, true, $2, $7 )->addQualifiers( $3 )->addQualifiers( $5 ); }
2813	\| ENUM enumerator_type attribute_list_opt typedef_name attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2814	{ $$ = DeclarationNode::newEnum( $4->name, $8, true, true, $2, $6 )->addQualifiers( $3 )->addQualifiers( $5 ); }
2815
2816	// forward declaration
2817	\| enum_type_nobody
2818	;
2819
2820	enumerator_type:
2821	'(' ')' // pure enumeration
2822	{ $$ = nullptr; }
2823	\| '(' cfa_abstract_parameter_declaration ')' // typed enumeration
2824	{ $$ = $2; }
2825	;
2826
2827	hide_opt:
2828	// empty
2829	{ $$ = EnumHiding::Visible; }
2830	\| '!'
2831	{ $$ = EnumHiding::Hide; }
2832	;
2833
2834	enum_type_nobody: // enum - {...}
2835	ENUM attribute_list_opt identifier
2836	{
2837	typedefTable.makeTypedef( *$3, "enum_type_nobody 1" );
2838	$$ = DeclarationNode::newEnum( $3, nullptr, false, false )->addQualifiers( $2 );
2839	}
2840	\| ENUM attribute_list_opt type_name
2841	{
2842	typedefTable.makeTypedef( *$3->symbolic.name, "enum_type_nobody 2" );
2843	$$ = DeclarationNode::newEnum( $3->symbolic.name, nullptr, false, false )->addQualifiers( $2 );
2844	}
2845	;
2846
2847	enumerator_list:
2848	visible_hide_opt identifier_or_type_name enumerator_value_opt
2849	{ $$ = DeclarationNode::newEnumValueGeneric( $2, $3 ); }
2850	\| INLINE type_name
2851	{
2852	$$ = DeclarationNode::newEnumInLine( $2->symbolic.name );
2853	$2->symbolic.name = nullptr;
2854	delete $2;
2855	}
2856	\| enumerator_list ',' visible_hide_opt identifier_or_type_name enumerator_value_opt
2857	{ $$ = $1->set_last( DeclarationNode::newEnumValueGeneric( $4, $5 ) ); }
2858	\| enumerator_list ',' INLINE type_name
2859	{ $$ = $1->set_last( DeclarationNode::newEnumInLine( $4->symbolic.name ) ); }
2860	;
2861
2862	visible_hide_opt:
2863	hide_opt
2864	\| '^'
2865	{ $$ = EnumHiding::Visible; }
2866	;
2867
2868	enumerator_value_opt:
2869	// empty
2870	{ $$ = nullptr; }
2871	\| '=' constant_expression { $$ = new InitializerNode( $2 ); }
2872	\| '=' '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $3, true ); }
2873	// \| simple_assignment_operator initializer
2874	// { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2875	;
2876
2877	// ************************ FUNCTION PARAMETERS *****************************
2878
2879	parameter_list_ellipsis_opt:
2880	// empty
2881	{ $$ = nullptr; }
2882	\| ELLIPSIS
2883	{ $$ = nullptr; }
2884	\| parameter_list
2885	\| parameter_list ',' ELLIPSIS
2886	{ $$ = $1->addVarArgs(); }
2887	;
2888
2889	parameter_list: // abstract + real
2890	parameter_declaration
2891	\| abstract_parameter_declaration
2892	\| parameter_list ',' parameter_declaration
2893	{ $$ = $1->set_last( $3 ); }
2894	\| parameter_list ',' abstract_parameter_declaration
2895	{ $$ = $1->set_last( $3 ); }
2896	;
2897
2898	cfa_parameter_list_ellipsis_opt: // CFA, abstract + real
2899	// empty
2900	{ $$ = DeclarationNode::newFromTypeData( build_basic_type( TypeData::Void ) ); }
2901	\| ELLIPSIS
2902	{ $$ = nullptr; }
2903	\| cfa_parameter_list
2904	\| cfa_abstract_parameter_list
2905	\| cfa_parameter_list ',' cfa_abstract_parameter_list
2906	{ $$ = $1->set_last( $3 ); }
2907	\| cfa_parameter_list ',' ELLIPSIS
2908	{ $$ = $1->addVarArgs(); }
2909	\| cfa_abstract_parameter_list ',' ELLIPSIS
2910	{ $$ = $1->addVarArgs(); }
2911	;
2912
2913	cfa_parameter_list: // CFA
2914	// To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2915	// factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2916	cfa_parameter_declaration
2917	\| cfa_abstract_parameter_list ',' cfa_parameter_declaration
2918	{ $$ = $1->set_last( $3 ); }
2919	\| cfa_parameter_list ',' cfa_parameter_declaration
2920	{ $$ = $1->set_last( $3 ); }
2921	\| cfa_parameter_list ',' cfa_abstract_parameter_list ',' cfa_parameter_declaration
2922	{ $$ = $1->set_last( $3 )->set_last( $5 ); }
2923	;
2924
2925	cfa_abstract_parameter_list: // CFA, new & old style abstract
2926	cfa_abstract_parameter_declaration
2927	\| cfa_abstract_parameter_list ',' cfa_abstract_parameter_declaration
2928	{ $$ = $1->set_last( $3 ); }
2929	;
2930
2931	// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2932	// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2933
2934	parameter_declaration:
2935	// No SUE declaration in parameter list.
2936	declaration_specifier_nobody identifier_parameter_declarator default_initializer_opt
2937	{ $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2938	\| declaration_specifier_nobody type_parameter_redeclarator default_initializer_opt
2939	{ $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2940	;
2941
2942	abstract_parameter_declaration:
2943	declaration_specifier_nobody default_initializer_opt
2944	{ $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2945	\| declaration_specifier_nobody abstract_parameter_declarator default_initializer_opt
2946	{ $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2947	;
2948
2949	cfa_parameter_declaration: // CFA, new & old style parameter declaration
2950	parameter_declaration
2951	\| cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initializer_opt
2952	{ $$ = $1->addName( $2 ); }
2953	\| cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2954	// To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2955	{ $$ = $1->addName( $2 ); }
2956	\| type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2957	{ $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2958	\| cfa_function_specifier // int f( "int fp()" );
2959	;
2960
2961	cfa_abstract_parameter_declaration: // CFA, new & old style parameter declaration
2962	abstract_parameter_declaration
2963	\| cfa_identifier_parameter_declarator_no_tuple
2964	\| cfa_abstract_tuple
2965	// To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2966	\| type_qualifier_list cfa_abstract_tuple
2967	{ $$ = $2->addQualifiers( $1 ); }
2968	\| cfa_abstract_function // int f( "int ()" );
2969	;
2970
2971	// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2972	// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2973	// identifiers. The ANSI-style parameter-list can redefine a typedef name.
2974
2975	identifier_list: // K&R-style parameter list => no types
2976	identifier
2977	{ $$ = DeclarationNode::newName( $1 ); }
2978	\| identifier_list ',' identifier
2979	{ $$ = $1->set_last( DeclarationNode::newName( $3 ) ); }
2980	;
2981
2982	type_no_function: // sizeof, alignof, cast (constructor)
2983	cfa_abstract_declarator_tuple // CFA
2984	\| type_specifier // cannot be type_specifier_nobody, e.g., (struct S {}){} is a thing
2985	\| type_specifier abstract_declarator
2986	{ $$ = $2->addType( $1 ); }
2987	;
2988
2989	type: // typeof, assertion
2990	type_no_function
2991	\| cfa_abstract_function // CFA
2992	;
2993
2994	initializer_opt:
2995	// empty
2996	{ $$ = nullptr; }
2997	\| simple_assignment_operator initializer { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2998	\| '=' VOID { $$ = new InitializerNode( true ); }
2999	\| '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
3000	;
3001
3002	initializer:
3003	assignment_expression { $$ = new InitializerNode( $1 ); }
3004	\| '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
3005	;
3006
3007	initializer_list_opt:
3008	// empty
3009	{ $$ = nullptr; }
3010	\| initializer
3011	\| designation initializer { $$ = $2->set_designators( $1 ); }
3012	\| initializer_list_opt ',' initializer { $$ = $1->set_last( $3 ); }
3013	\| initializer_list_opt ',' designation initializer { $$ = $1->set_last( $4->set_designators( $3 ) ); }
3014	;
3015
3016	// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
3017	// '=' to separator the designator from the initializer value, as in:
3018	//
3019	// int x[10] = { [1] = 3 };
3020	//
3021	// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment. To disambiguate this case, CFA
3022	// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
3023	// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
3024	// shift/reduce conflicts
3025
3026	designation:
3027	designator_list ':' // C99, CFA uses ":" instead of "="
3028	\| identifier_at ':' // GCC, field name
3029	{ $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
3030	;
3031
3032	designator_list: // C99
3033	designator
3034	\| designator_list designator
3035	{ $$ = $1->set_last( $2 ); }
3036	//\| designator_list designator { $$ = new ExpressionNode( $1, $2 ); }
3037	;
3038
3039	designator:
3040	'.' identifier_at // C99, field name
3041	{ $$ = new ExpressionNode( build_varref( yylloc, $2 ) ); }
3042	\| '[' push assignment_expression pop ']' // C99, single array element
3043	// assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
3044	{ $$ = $3; }
3045	\| '[' push subrange pop ']' // CFA, multiple array elements
3046	{ $$ = $3; }
3047	\| '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
3048	{ $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $3 ), maybeMoveBuild( $5 ) ) ); }
3049	\| '.' '[' push field_name_list pop ']' // CFA, tuple field selector
3050	{ $$ = $4; }
3051	;
3052
3053	// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
3054	// rather than an object-oriented type system. This required four groups of extensions:
3055	//
3056	// Overloading: function, data, and operator identifiers may be overloaded.
3057	//
3058	// Type declarations: "otype" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
3059	// and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
3060	// definitions of new types. Type declarations with storage class "extern" provide opaque types.
3061	//
3062	// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
3063	// site. A polymorphic function is not a template; it is a function, with an address and a type.
3064	//
3065	// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
3066	// types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
3067	// hierarchies. Unlike classes, they can define relationships between types. Assertions declare that a type or
3068	// types provide the operations declared by a specification. Assertions are normally used to declare requirements
3069	// on type arguments of polymorphic functions.
3070
3071	type_parameter_list: // CFA
3072	type_parameter
3073	\| type_parameter_list ',' type_parameter
3074	{ $$ = $1->set_last( $3 ); }
3075	;
3076
3077	type_initializer_opt: // CFA
3078	// empty
3079	{ $$ = nullptr; }
3080	\| '=' type
3081	{ $$ = $2; }
3082	;
3083
3084	type_parameter: // CFA
3085	type_class identifier_or_type_name
3086	{
3087	typedefTable.addToScope( *$2, TYPEDEFname, "type_parameter 1" );
3088	if ( $1 == ast::TypeDecl::Otype ) { SemanticError( yylloc, "otype keyword is deprecated, use T " ); }
3089	if ( $1 == ast::TypeDecl::Dtype ) { SemanticError( yylloc, "dtype keyword is deprecated, use T &" ); }
3090	if ( $1 == ast::TypeDecl::Ttype ) { SemanticError( yylloc, "ttype keyword is deprecated, use T ..." ); }
3091	}
3092	type_initializer_opt assertion_list_opt
3093	{ $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
3094	\| identifier_or_type_name new_type_class
3095	{ typedefTable.addToScope( *$1, TYPEDEFname, "type_parameter 2" ); }
3096	type_initializer_opt assertion_list_opt
3097	{ $$ = DeclarationNode::newTypeParam( $2, $1 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
3098	\| '[' identifier_or_type_name ']'
3099	{
3100	typedefTable.addToScope( *$2, TYPEDIMname, "type_parameter 3" );
3101	$$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dimension, $2 );
3102	}
3103	// \| type_specifier identifier_parameter_declarator
3104	\| assertion_list
3105	{ $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
3106	\| ENUM '(' identifier_or_type_name ')' identifier_or_type_name new_type_class type_initializer_opt assertion_list_opt
3107	{
3108	typedefTable.addToScope( *$3, TYPEDIMname, "type_parameter 4" );
3109	typedefTable.addToScope( *$5, TYPEDIMname, "type_parameter 5" );
3110	$$ = DeclarationNode::newTypeParam( $6, $5 )->addTypeInitializer( $7 )->addAssertions( $8 );
3111	}
3112	;
3113
3114	new_type_class: // CFA
3115	// empty
3116	{ $$ = ast::TypeDecl::Otype; }
3117	\| '&'
3118	{ $$ = ast::TypeDecl::Dtype; }
3119	\| '*'
3120	{ $$ = ast::TypeDecl::DStype; } // Dtype + sized
3121	// \| '(' '*' ')' // Gregor made me do it
3122	// { $$ = ast::TypeDecl::Ftype; }
3123	\| ELLIPSIS
3124	{ $$ = ast::TypeDecl::Ttype; }
3125	;
3126
3127	type_class: // CFA
3128	OTYPE
3129	{ $$ = ast::TypeDecl::Otype; }
3130	\| DTYPE
3131	{ $$ = ast::TypeDecl::Dtype; }
3132	\| FTYPE
3133	{ $$ = ast::TypeDecl::Ftype; }
3134	\| TTYPE
3135	{ $$ = ast::TypeDecl::Ttype; }
3136	;
3137
3138	assertion_list_opt: // CFA
3139	// empty
3140	{ $$ = nullptr; }
3141	\| assertion_list
3142	;
3143
3144	assertion_list: // CFA
3145	assertion
3146	\| assertion_list assertion
3147	{ $$ = $1->set_last( $2 ); }
3148	;
3149
3150	assertion: // CFA
3151	'\|' identifier_or_type_name '(' type_list ')'
3152	{ $$ = DeclarationNode::newTraitUse( $2, $4 ); }
3153	\| '\|' '{' push trait_declaration_list pop '}'
3154	{ $$ = $4; }
3155	// \| '\|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
3156	// { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
3157	;
3158
3159	type_list: // CFA
3160	type
3161	{ $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3162	\| assignment_expression
3163	\| type_list ',' type
3164	{ $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
3165	\| type_list ',' assignment_expression
3166	{ $$ = $1->set_last( $3 ); }
3167	;
3168
3169	type_declaring_list: // CFA
3170	OTYPE type_declarator
3171	{ $$ = $2; }
3172	\| storage_class_list OTYPE type_declarator
3173	{ $$ = $3->addQualifiers( $1 ); }
3174	\| type_declaring_list ',' type_declarator
3175	{ $$ = $1->set_last( $3->copySpecifiers( $1 ) ); }
3176	;
3177
3178	type_declarator: // CFA
3179	type_declarator_name assertion_list_opt
3180	{ $$ = $1->addAssertions( $2 ); }
3181	\| type_declarator_name assertion_list_opt '=' type
3182	{ $$ = $1->addAssertions( $2 )->addType( $4 ); }
3183	;
3184
3185	type_declarator_name: // CFA
3186	identifier_or_type_name
3187	{
3188	typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "type_declarator_name 1" );
3189	$$ = DeclarationNode::newTypeDecl( $1, nullptr );
3190	}
3191	\| identifier_or_type_name '(' type_parameter_list ')'
3192	{
3193	typedefTable.addToEnclosingScope( *$1, TYPEGENname, "type_declarator_name 2" );
3194	$$ = DeclarationNode::newTypeDecl( $1, $3 );
3195	}
3196	;
3197
3198	trait_specifier: // CFA
3199	TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
3200	{
3201	SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3202	$$ = DeclarationNode::newTrait( $2, $4, nullptr );
3203	}
3204	\| forall TRAIT identifier_or_type_name '{' '}' // alternate
3205	{ $$ = DeclarationNode::newTrait( $3, $1, nullptr ); }
3206	\| TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
3207	{
3208	SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3209	$$ = DeclarationNode::newTrait( $2, $4, $8 );
3210	}
3211	\| forall TRAIT identifier_or_type_name '{' push trait_declaration_list pop '}' // alternate
3212	{ $$ = DeclarationNode::newTrait( $3, $1, $6 ); }
3213	;
3214
3215	trait_declaration_list: // CFA
3216	trait_declaration
3217	\| trait_declaration_list pop push trait_declaration
3218	{ $$ = $1->set_last( $4 ); }
3219	;
3220
3221	trait_declaration: // CFA
3222	cfa_trait_declaring_list ';'
3223	\| trait_declaring_list ';'
3224	;
3225
3226	cfa_trait_declaring_list: // CFA
3227	cfa_variable_specifier
3228	\| cfa_function_specifier
3229	\| cfa_trait_declaring_list pop ',' push identifier_or_type_name
3230	{ $$ = $1->set_last( $1->cloneType( $5 ) ); }
3231	;
3232
3233	trait_declaring_list: // CFA
3234	type_specifier declarator
3235	{ $$ = $2->addType( $1 ); }
3236	\| trait_declaring_list pop ',' push declarator
3237	{ $$ = $1->set_last( $1->cloneBaseType( $5 ) ); }
3238	;
3239
3240	// ************************** EXTERNAL DEFINITIONS ***************************
3241
3242	translation_unit:
3243	// empty, input file
3244	\| external_definition_list
3245	{ parseTree = parseTree ? parseTree->set_last( $1 ) : $1; }
3246	;
3247
3248	external_definition_list:
3249	push external_definition pop
3250	{ $$ = $2; }
3251	\| external_definition_list push external_definition pop
3252	{ $$ = $1 ? $1->set_last( $3 ) : $3; }
3253	;
3254
3255	external_definition_list_opt:
3256	// empty
3257	{ $$ = nullptr; }
3258	\| external_definition_list
3259	;
3260
3261	up:
3262	{ typedefTable.up( forall ); forall = false; }
3263	;
3264
3265	down:
3266	{ typedefTable.down(); }
3267	;
3268
3269	external_definition:
3270	DIRECTIVE
3271	{ $$ = DeclarationNode::newDirectiveStmt( new StatementNode( build_directive( yylloc, $1 ) ) ); }
3272	\| declaration
3273	{
3274	// Variable declarations of anonymous types requires creating a unique type-name across multiple translation
3275	// unit, which is a dubious task, especially because C uses name rather than structural typing; hence it is
3276	// disallowed at the moment.
3277	if ( $1->linkage == ast::Linkage::Cforall && ! $1->storageClasses.is_static &&
3278	$1->type && $1->type->kind == TypeData::AggregateInst ) {
3279	if ( $1->type->aggInst.aggregate->aggregate.anon ) {
3280	SemanticError( yylloc, "extern anonymous aggregate is currently unimplemented." ); $$ = nullptr;
3281	}
3282	}
3283	}
3284	\| IDENTIFIER IDENTIFIER
3285	{ IdentifierBeforeIdentifier( $1.str, $2.str, " declaration" ); $$ = nullptr; }
3286	\| IDENTIFIER type_qualifier // invalid syntax rule
3287	{ IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
3288	\| IDENTIFIER storage_class // invalid syntax rule
3289	{ IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
3290	\| IDENTIFIER basic_type_name // invalid syntax rule
3291	{ IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3292	\| IDENTIFIER TYPEDEFname // invalid syntax rule
3293	{ IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3294	\| IDENTIFIER TYPEGENname // invalid syntax rule
3295	{ IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3296	\| external_function_definition
3297	\| EXTENSION external_definition // GCC, multiple __extension__ allowed, meaning unknown
3298	{
3299	distExt( $2 ); // mark all fields in list
3300	$$ = $2;
3301	}
3302	\| ASM '(' string_literal ')' ';' // GCC, global assembler statement
3303	{ $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( yylloc, false, $3, nullptr ) ) ); }
3304	\| EXTERN STRINGliteral
3305	{
3306	linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
3307	linkage = ast::Linkage::update( yylloc, linkage, $2 );
3308	}
3309	up external_definition down
3310	{
3311	linkage = linkageStack.top();
3312	linkageStack.pop();
3313	$$ = $5;
3314	}
3315	\| EXTERN STRINGliteral // C++-style linkage specifier
3316	{
3317	linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
3318	linkage = ast::Linkage::update( yylloc, linkage, $2 );
3319	}
3320	'{' up external_definition_list_opt down '}'
3321	{
3322	linkage = linkageStack.top();
3323	linkageStack.pop();
3324	$$ = $6;
3325	}
3326	// global distribution
3327	\| type_qualifier_list
3328	{
3329	if ( $1->type->qualifiers.any() ) {
3330	SemanticError( yylloc, "illegal syntax, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3331	}
3332	if ( $1->type->forall ) forall = true; // remember generic type
3333	}
3334	'{' up external_definition_list_opt down '}' // CFA, namespace
3335	{
3336	distQual( $5, $1 );
3337	forall = false;
3338	$$ = $5;
3339	}
3340	\| declaration_qualifier_list
3341	{
3342	if ( $1->type && $1->type->qualifiers.any() ) {
3343	SemanticError( yylloc, "illegal syntax, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3344	}
3345	if ( $1->type && $1->type->forall ) forall = true; // remember generic type
3346	}
3347	'{' up external_definition_list_opt down '}' // CFA, namespace
3348	{
3349	distQual( $5, $1 );
3350	forall = false;
3351	$$ = $5;
3352	}
3353	\| declaration_qualifier_list type_qualifier_list
3354	{
3355	if ( ($1->type && $1->type->qualifiers.any()) \|\| ($2->type && $2->type->qualifiers.any()) ) {
3356	SemanticError( yylloc, "illegal syntax, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3357	}
3358	if ( ($1->type && $1->type->forall) \|\| ($2->type && $2->type->forall) ) forall = true; // remember generic type
3359	}
3360	'{' up external_definition_list_opt down '}' // CFA, namespace
3361	{
3362	distQual( $6, $1->addQualifiers( $2 ) );
3363	forall = false;
3364	$$ = $6;
3365	}
3366	\| ';' // empty declaration
3367	{ $$ = nullptr; }
3368	;
3369
3370	external_function_definition:
3371	function_definition
3372	// These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
3373	// legacy code with global functions missing the type-specifier for the return type, and assuming "int".
3374	// Parsing is possible because function_definition does not appear in the context of an expression (nested
3375	// functions preclude this concession, i.e., all nested function must have a return type). A function prototype
3376	// declaration must still have a type_specifier. OBSOLESCENT (see 1)
3377	\| function_declarator compound_statement
3378	{ $$ = $1->addFunctionBody( $2 ); }
3379	\| KR_function_declarator KR_parameter_list_opt compound_statement
3380	{ $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
3381	;
3382
3383	with_clause_opt:
3384	// empty
3385	{ $$ = nullptr; forall = false; }
3386	\| WITH '(' type_list ')' attribute_list_opt // support scoped enumeration
3387	{
3388	$$ = $3; forall = false;
3389	if ( $5 ) {
3390	SemanticError( yylloc, "illegal syntax, attributes cannot be associated with function body. Move attribute(s) before \"with\" clause." );
3391	$$ = nullptr;
3392	} // if
3393	}
3394	;
3395
3396	function_definition:
3397	cfa_function_declaration with_clause_opt compound_statement // CFA
3398	{
3399	// Add the function body to the last identifier in the function definition list, i.e., foo3:
3400	// [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
3401	$1->get_last()->addFunctionBody( $3, $2 );
3402	$$ = $1;
3403	}
3404	\| declaration_specifier function_declarator with_clause_opt compound_statement
3405	{
3406	rebindForall( $1, $2 );
3407	$$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3408	}
3409	\| declaration_specifier function_type_redeclarator with_clause_opt compound_statement
3410	{
3411	rebindForall( $1, $2 );
3412	$$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3413	}
3414	// handles default int return type, OBSOLESCENT (see 1)
3415	\| type_qualifier_list function_declarator with_clause_opt compound_statement
3416	{ $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3417	// handles default int return type, OBSOLESCENT (see 1)
3418	\| declaration_qualifier_list function_declarator with_clause_opt compound_statement
3419	{ $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3420	// handles default int return type, OBSOLESCENT (see 1)
3421	\| declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
3422	{ $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3423
3424	// Old-style K&R function definition, OBSOLESCENT (see 4)
3425	\| declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3426	{
3427	rebindForall( $1, $2 );
3428	$$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
3429	}
3430	// handles default int return type, OBSOLESCENT (see 1)
3431	\| type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3432	{ $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3433	// handles default int return type, OBSOLESCENT (see 1)
3434	\| declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3435	{ $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3436	// handles default int return type, OBSOLESCENT (see 1)
3437	\| declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3438	{ $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3439	;
3440
3441	declarator:
3442	variable_declarator
3443	\| variable_type_redeclarator
3444	\| function_declarator
3445	\| function_type_redeclarator
3446	;
3447
3448	subrange:
3449	constant_expression '~' constant_expression // CFA, integer subrange
3450	{ $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
3451	;
3452
3453	// ************************** ASM ***************************
3454
3455	asm_name_opt: // GCC
3456	// empty
3457	{ $$ = nullptr; }
3458	\| ASM '(' string_literal ')' attribute_list_opt
3459	{
3460	DeclarationNode * name = new DeclarationNode();
3461	name->asmName = maybeMoveBuild( $3 );
3462	$$ = name->addQualifiers( $5 );
3463	}
3464	;
3465
3466	// ************************** ATTRIBUTE ***************************
3467
3468	attribute_list_opt: // GCC
3469	// empty
3470	{ $$ = nullptr; }
3471	\| attribute_list
3472	;
3473
3474	attribute_list: // GCC
3475	attribute
3476	\| attribute_list attribute
3477	{ $$ = $2->addQualifiers( $1 ); }
3478	;
3479
3480	attribute: // GCC
3481	ATTRIBUTE '(' '(' attribute_name_list ')' ')'
3482	{ $$ = $4; }
3483	\| ATTRIBUTE '(' attribute_name_list ')' // CFA
3484	{ $$ = $3; }
3485	\| ATTR '(' attribute_name_list ')' // CFA
3486	{ $$ = $3; }
3487	;
3488
3489	attribute_name_list: // GCC
3490	attribute_name
3491	\| attribute_name_list ',' attribute_name
3492	{ $$ = $3->addQualifiers( $1 ); }
3493	;
3494
3495	attribute_name: // GCC
3496	// empty
3497	{ $$ = nullptr; }
3498	\| attr_name
3499	{ $$ = DeclarationNode::newAttribute( $1 ); }
3500	\| attr_name '(' argument_expression_list_opt ')'
3501	{ $$ = DeclarationNode::newAttribute( $1, $3 ); }
3502	;
3503
3504	attr_name: // GCC
3505	identifier_or_type_name
3506	\| FALLTHROUGH
3507	{ $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
3508	\| CONST
3509	{ $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
3510	;
3511
3512	// ============================================================================
3513	// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
3514	// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
3515	// in:
3516	//
3517	// int (*f())[10] { ... };
3518	// ... (*f())[3] += 1; // definition mimics usage
3519	//
3520	// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
3521	// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
3522	// ============================================================================
3523
3524	// ----------------------------------------------------------------------------
3525	// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
3526	// to define a variable or function prototype, e.g.:
3527	//
3528	// valid declaration invalid definition
3529	// ----------------- ------------------
3530	// int f; int f {}
3531	// int f; int f {}
3532	// int f[10]; int f[10] {}
3533	// int (f)(int); int (f)(int) {}
3534	//
3535	// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
3536	// variable_declarator and function_declarator.
3537	// ----------------------------------------------------------------------------
3538
3539	// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
3540	// declaring an array of functions versus a pointer to an array of functions.
3541
3542	paren_identifier:
3543	identifier_at
3544	{ $$ = DeclarationNode::newName( $1 ); }
3545	\| '(' paren_identifier ')' // redundant parenthesis
3546	{ $$ = $2; }
3547	;
3548
3549	variable_declarator:
3550	paren_identifier attribute_list_opt
3551	{ $$ = $1->addQualifiers( $2 ); }
3552	\| variable_ptr
3553	\| variable_array attribute_list_opt
3554	{ $$ = $1->addQualifiers( $2 ); }
3555	\| variable_function attribute_list_opt
3556	{ $$ = $1->addQualifiers( $2 ); }
3557	;
3558
3559	variable_ptr:
3560	ptrref_operator variable_declarator
3561	{ $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3562	\| ptrref_operator type_qualifier_list variable_declarator
3563	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3564	\| '(' variable_ptr ')' attribute_list_opt // redundant parenthesis
3565	{ $$ = $2->addQualifiers( $4 ); }
3566	\| '(' attribute_list variable_ptr ')' attribute_list_opt // redundant parenthesis
3567	{ $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3568	;
3569
3570	variable_array:
3571	paren_identifier array_dimension
3572	{ $$ = $1->addArray( $2 ); }
3573	\| '(' variable_ptr ')' array_dimension
3574	{ $$ = $2->addArray( $4 ); }
3575	\| '(' attribute_list variable_ptr ')' array_dimension
3576	{ $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3577	\| '(' variable_array ')' multi_array_dimension // redundant parenthesis
3578	{ $$ = $2->addArray( $4 ); }
3579	\| '(' attribute_list variable_array ')' multi_array_dimension // redundant parenthesis
3580	{ $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3581	\| '(' variable_array ')' // redundant parenthesis
3582	{ $$ = $2; }
3583	\| '(' attribute_list variable_array ')' // redundant parenthesis
3584	{ $$ = $3->addQualifiers( $2 ); }
3585	;
3586
3587	variable_function:
3588	'(' variable_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3589	{ $$ = $2->addParamList( $5 ); }
3590	\| '(' attribute_list variable_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3591	{ $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3592	\| '(' variable_function ')' // redundant parenthesis
3593	{ $$ = $2; }
3594	\| '(' attribute_list variable_function ')' // redundant parenthesis
3595	{ $$ = $3->addQualifiers( $2 ); }
3596	;
3597
3598	// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
3599	// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
3600	// is the same scope. The pattern precludes returning arrays and functions versus pointers to arrays and functions.
3601
3602	function_declarator:
3603	function_no_ptr attribute_list_opt
3604	{ $$ = $1->addQualifiers( $2 ); }
3605	\| function_ptr
3606	\| function_array attribute_list_opt
3607	{ $$ = $1->addQualifiers( $2 ); }
3608	;
3609
3610	function_no_ptr:
3611	paren_identifier '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3612	{ $$ = $1->addParamList( $3 ); }
3613	\| '(' function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3614	{ $$ = $2->addParamList( $5 ); }
3615	\| '(' attribute_list function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3616	{ $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3617	\| '(' function_no_ptr ')' // redundant parenthesis
3618	{ $$ = $2; }
3619	\| '(' attribute_list function_no_ptr ')' // redundant parenthesis
3620	{ $$ = $3->addQualifiers( $2 ); }
3621	;
3622
3623	function_ptr:
3624	ptrref_operator function_declarator
3625	{ $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3626	\| ptrref_operator type_qualifier_list function_declarator
3627	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3628	\| '(' function_ptr ')' attribute_list_opt
3629	{ $$ = $2->addQualifiers( $4 ); }
3630	\| '(' attribute_list function_ptr ')' attribute_list_opt
3631	{ $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3632	;
3633
3634	function_array:
3635	'(' function_ptr ')' array_dimension
3636	{ $$ = $2->addArray( $4 ); }
3637	\| '(' attribute_list function_ptr ')' array_dimension
3638	{ $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3639	\| '(' function_array ')' multi_array_dimension // redundant parenthesis
3640	{ $$ = $2->addArray( $4 ); }
3641	\| '(' attribute_list function_array ')' multi_array_dimension // redundant parenthesis
3642	{ $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3643	\| '(' function_array ')' // redundant parenthesis
3644	{ $$ = $2; }
3645	\| '(' attribute_list function_array ')' // redundant parenthesis
3646	{ $$ = $3->addQualifiers( $2 ); }
3647	;
3648
3649	// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
3650	//
3651	// f( a, b, c ) int a, *b, c[]; {}
3652	//
3653	// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
3654	// returning arrays and functions versus pointers to arrays and functions.
3655
3656	KR_function_declarator:
3657	KR_function_no_ptr
3658	\| KR_function_ptr
3659	\| KR_function_array
3660	;
3661
3662	KR_function_no_ptr:
3663	paren_identifier '(' identifier_list ')' // function_declarator handles empty parameter
3664	{ $$ = $1->addIdList( $3 ); }
3665	\| '(' KR_function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3666	{ $$ = $2->addParamList( $5 ); }
3667	\| '(' attribute_list KR_function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3668	{ $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3669	\| '(' KR_function_no_ptr ')' // redundant parenthesis
3670	{ $$ = $2; }
3671	\| '(' attribute_list KR_function_no_ptr ')' // redundant parenthesis
3672	{ $$ = $3->addQualifiers( $2 ); }
3673	;
3674
3675	KR_function_ptr:
3676	ptrref_operator KR_function_declarator
3677	{ $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3678	\| ptrref_operator type_qualifier_list KR_function_declarator
3679	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3680	\| '(' KR_function_ptr ')'
3681	{ $$ = $2; }
3682	\| '(' attribute_list KR_function_ptr ')'
3683	{ $$ = $3->addQualifiers( $2 ); }
3684	;
3685
3686	KR_function_array:
3687	'(' KR_function_ptr ')' array_dimension
3688	{ $$ = $2->addArray( $4 ); }
3689	\| '(' attribute_list KR_function_ptr ')' array_dimension
3690	{ $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3691	\| '(' KR_function_array ')' multi_array_dimension // redundant parenthesis
3692	{ $$ = $2->addArray( $4 ); }
3693	\| '(' attribute_list KR_function_array ')' multi_array_dimension // redundant parenthesis
3694	{ $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3695	\| '(' KR_function_array ')' // redundant parenthesis
3696	{ $$ = $2; }
3697	\| '(' attribute_list KR_function_array ')' // redundant parenthesis
3698	{ $$ = $3->addQualifiers( $2 ); }
3699	;
3700
3701	// This pattern parses a declaration for a variable that redefines a type name, e.g.:
3702	//
3703	// typedef int foo;
3704	// {
3705	// int foo; // redefine typedef name in new scope
3706	// }
3707
3708	paren_type:
3709	typedef_name
3710	{
3711	// hide type name in enclosing scope by variable name
3712	typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "paren_type" );
3713	}
3714	\| '(' paren_type ')'
3715	{ $$ = $2; }
3716	;
3717
3718	variable_type_redeclarator:
3719	paren_type attribute_list_opt
3720	{ $$ = $1->addQualifiers( $2 ); }
3721	\| variable_type_ptr
3722	\| variable_type_array attribute_list_opt
3723	{ $$ = $1->addQualifiers( $2 ); }
3724	\| variable_type_function attribute_list_opt
3725	{ $$ = $1->addQualifiers( $2 ); }
3726	;
3727
3728	variable_type_ptr:
3729	ptrref_operator variable_type_redeclarator
3730	{ $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3731	\| ptrref_operator type_qualifier_list variable_type_redeclarator
3732	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3733	\| '(' variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3734	{ $$ = $2->addQualifiers( $4 ); }
3735	\| '(' attribute_list variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3736	{ $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3737	;
3738
3739	variable_type_array:
3740	paren_type array_dimension
3741	{ $$ = $1->addArray( $2 ); }
3742	\| '(' variable_type_ptr ')' array_dimension
3743	{ $$ = $2->addArray( $4 ); }
3744	\| '(' attribute_list variable_type_ptr ')' array_dimension
3745	{ $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3746	\| '(' variable_type_array ')' multi_array_dimension // redundant parenthesis
3747	{ $$ = $2->addArray( $4 ); }
3748	\| '(' attribute_list variable_type_array ')' multi_array_dimension // redundant parenthesis
3749	{ $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3750	\| '(' variable_type_array ')' // redundant parenthesis
3751	{ $$ = $2; }
3752	\| '(' attribute_list variable_type_array ')' // redundant parenthesis
3753	{ $$ = $3->addQualifiers( $2 ); }
3754	;
3755
3756	variable_type_function:
3757	'(' variable_type_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3758	{ $$ = $2->addParamList( $5 ); }
3759	\| '(' attribute_list variable_type_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3760	{ $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3761	\| '(' variable_type_function ')' // redundant parenthesis
3762	{ $$ = $2; }
3763	\| '(' attribute_list variable_type_function ')' // redundant parenthesis
3764	{ $$ = $3->addQualifiers( $2 ); }
3765	;
3766
3767	// This pattern parses a declaration for a function prototype that redefines a type name. It precludes declaring an
3768	// array of functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to
3769	// arrays and functions.
3770
3771	function_type_redeclarator:
3772	function_type_no_ptr attribute_list_opt
3773	{ $$ = $1->addQualifiers( $2 ); }
3774	\| function_type_ptr
3775	\| function_type_array attribute_list_opt
3776	{ $$ = $1->addQualifiers( $2 ); }
3777	;
3778
3779	function_type_no_ptr:
3780	paren_type '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3781	{ $$ = $1->addParamList( $3 ); }
3782	\| '(' function_type_ptr ')' '(' parameter_list_ellipsis_opt ')'
3783	{ $$ = $2->addParamList( $5 ); }
3784	\| '(' attribute_list function_type_ptr ')' '(' parameter_list_ellipsis_opt ')'
3785	{ $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3786	\| '(' function_type_no_ptr ')' // redundant parenthesis
3787	{ $$ = $2; }
3788	\| '(' attribute_list function_type_no_ptr ')' // redundant parenthesis
3789	{ $$ = $3->addQualifiers( $2 ); }
3790	;
3791
3792	function_type_ptr:
3793	ptrref_operator function_type_redeclarator
3794	{ $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3795	\| ptrref_operator type_qualifier_list function_type_redeclarator
3796	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3797	\| '(' function_type_ptr ')' attribute_list_opt
3798	{ $$ = $2->addQualifiers( $4 ); }
3799	\| '(' attribute_list function_type_ptr ')' attribute_list_opt
3800	{ $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3801	;
3802
3803	function_type_array:
3804	'(' function_type_ptr ')' array_dimension
3805	{ $$ = $2->addArray( $4 ); }
3806	\| '(' attribute_list function_type_ptr ')' array_dimension
3807	{ $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3808	\| '(' function_type_array ')' multi_array_dimension // redundant parenthesis
3809	{ $$ = $2->addArray( $4 ); }
3810	\| '(' attribute_list function_type_array ')' multi_array_dimension // redundant parenthesis
3811	{ $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3812	\| '(' function_type_array ')' // redundant parenthesis
3813	{ $$ = $2; }
3814	\| '(' attribute_list function_type_array ')' // redundant parenthesis
3815	{ $$ = $3->addQualifiers( $2 ); }
3816	;
3817
3818	// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
3819	// typedef name and allows the C99 array options, which can only appear in a parameter list. The pattern precludes
3820	// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
3821	// pointers to arrays and functions.
3822
3823	identifier_parameter_declarator:
3824	paren_identifier attribute_list_opt
3825	{ $$ = $1->addQualifiers( $2 ); }
3826	\| '&' MUTEX paren_identifier attribute_list_opt
3827	{ $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
3828	OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3829	\| identifier_parameter_ptr
3830	\| identifier_parameter_array attribute_list_opt
3831	{ $$ = $1->addQualifiers( $2 ); }
3832	\| identifier_parameter_function attribute_list_opt
3833	{ $$ = $1->addQualifiers( $2 ); }
3834	;
3835
3836	identifier_parameter_ptr:
3837	ptrref_operator identifier_parameter_declarator
3838	{ $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3839	\| ptrref_operator type_qualifier_list identifier_parameter_declarator
3840	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3841	\| '(' identifier_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3842	{ $$ = $2->addQualifiers( $4 ); }
3843	;
3844
3845	identifier_parameter_array:
3846	paren_identifier array_parameter_dimension
3847	{ $$ = $1->addArray( $2 ); }
3848	\| '(' identifier_parameter_ptr ')' array_dimension
3849	{ $$ = $2->addArray( $4 ); }
3850	\| '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3851	{ $$ = $2->addArray( $4 ); }
3852	\| '(' identifier_parameter_array ')' // redundant parenthesis
3853	{ $$ = $2; }
3854	;
3855
3856	identifier_parameter_function:
3857	paren_identifier '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3858	{ $$ = $1->addParamList( $3 ); }
3859	\| '(' identifier_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3860	{ $$ = $2->addParamList( $5 ); }
3861	\| '(' identifier_parameter_function ')' // redundant parenthesis
3862	{ $$ = $2; }
3863	;
3864
3865	// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3866	// e.g.:
3867	//
3868	// typedef int foo;
3869	// forall( otype T ) struct foo;
3870	// int f( int foo ); // redefine typedef name in new scope
3871	//
3872	// and allows the C99 array options, which can only appear in a parameter list.
3873
3874	type_parameter_redeclarator:
3875	typedef_name attribute_list_opt
3876	{ $$ = $1->addQualifiers( $2 ); }
3877	\| '&' MUTEX typedef_name attribute_list_opt
3878	{ $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
3879	OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3880	\| type_parameter_ptr
3881	\| type_parameter_array attribute_list_opt
3882	{ $$ = $1->addQualifiers( $2 ); }
3883	\| type_parameter_function attribute_list_opt
3884	{ $$ = $1->addQualifiers( $2 ); }
3885	;
3886
3887	typedef_name:
3888	TYPEDEFname
3889	{ $$ = DeclarationNode::newName( $1 ); }
3890	\| TYPEGENname
3891	{ $$ = DeclarationNode::newName( $1 ); }
3892	;
3893
3894	type_parameter_ptr:
3895	ptrref_operator type_parameter_redeclarator
3896	{ $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3897	\| ptrref_operator type_qualifier_list type_parameter_redeclarator
3898	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3899	\| '(' type_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3900	{ $$ = $2->addQualifiers( $4 ); }
3901	;
3902
3903	type_parameter_array:
3904	typedef_name array_parameter_dimension
3905	{ $$ = $1->addArray( $2 ); }
3906	\| '(' type_parameter_ptr ')' array_parameter_dimension
3907	{ $$ = $2->addArray( $4 ); }
3908	;
3909
3910	type_parameter_function:
3911	typedef_name '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3912	{ $$ = $1->addParamList( $3 ); }
3913	\| '(' type_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3914	{ $$ = $2->addParamList( $5 ); }
3915	;
3916
3917	// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3918	// which the type applies, e.g.:
3919	//
3920	// sizeof( int );
3921	// sizeof( int * );
3922	// sizeof( int [10] );
3923	// sizeof( int (*)() );
3924	// sizeof( int () );
3925	//
3926	// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3927	// and functions versus pointers to arrays and functions.
3928
3929	abstract_declarator:
3930	abstract_ptr
3931	\| abstract_array attribute_list_opt
3932	{ $$ = $1->addQualifiers( $2 ); }
3933	\| abstract_function attribute_list_opt
3934	{ $$ = $1->addQualifiers( $2 ); }
3935	;
3936
3937	abstract_ptr:
3938	ptrref_operator
3939	{ $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3940	\| ptrref_operator type_qualifier_list
3941	{ $$ = DeclarationNode::newPointer( $2, $1 ); }
3942	\| ptrref_operator abstract_declarator
3943	{ $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3944	\| ptrref_operator type_qualifier_list abstract_declarator
3945	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3946	\| '(' abstract_ptr ')' attribute_list_opt
3947	{ $$ = $2->addQualifiers( $4 ); }
3948	;
3949
3950	abstract_array:
3951	array_dimension
3952	\| '(' abstract_ptr ')' array_dimension
3953	{ $$ = $2->addArray( $4 ); }
3954	\| '(' abstract_array ')' multi_array_dimension // redundant parenthesis
3955	{ $$ = $2->addArray( $4 ); }
3956	\| '(' abstract_array ')' // redundant parenthesis
3957	{ $$ = $2; }
3958	;
3959
3960	abstract_function:
3961	'(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3962	{ $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
3963	\| '(' abstract_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3964	{ $$ = $2->addParamList( $5 ); }
3965	\| '(' abstract_function ')' // redundant parenthesis
3966	{ $$ = $2; }
3967	;
3968
3969	array_dimension:
3970	// Only the first dimension can be empty.
3971	'[' ']'
3972	{ $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
3973	\| '[' ']' multi_array_dimension
3974	{ $$ = DeclarationNode::newArray( nullptr, nullptr, false )->addArray( $3 ); }
3975	// Cannot use constant_expression because of tuples => semantic check
3976	\| '[' push assignment_expression pop ',' comma_expression ']' // CFA
3977	{ $$ = DeclarationNode::newArray( $3, nullptr, false )->addArray( DeclarationNode::newArray( $6, nullptr, false ) ); }
3978	// { SemanticError( yylloc, "New array dimension is currently unimplemented." ); $$ = nullptr; }
3979
3980	// If needed, the following parses and does not use comma_expression, so the array structure can be built.
3981	// \| '[' push assignment_expression pop ',' push array_dimension_list pop ']' // CFA
3982
3983	\| '[' push array_type_list pop ']' // CFA
3984	{ $$ = DeclarationNode::newArray( $3, nullptr, false ); }
3985	\| multi_array_dimension
3986	;
3987
3988	// array_dimension_list:
3989	// assignment_expression
3990	// \| array_dimension_list ',' assignment_expression
3991	// ;
3992
3993	array_type_list:
3994	basic_type_name
3995	{ $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3996	\| type_name
3997	{ $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3998	\| assignment_expression upupeq assignment_expression
3999	\| array_type_list ',' basic_type_name
4000	{ $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
4001	\| array_type_list ',' type_name
4002	{ $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
4003	\| array_type_list ',' assignment_expression upupeq assignment_expression
4004	;
4005
4006	upupeq:
4007	'~'
4008	{ $$ = OperKinds::LThan; }
4009	\| ErangeUpEq
4010	{ $$ = OperKinds::LEThan; }
4011	;
4012
4013	multi_array_dimension:
4014	'[' push assignment_expression pop ']'
4015	{ $$ = DeclarationNode::newArray( $3, nullptr, false ); }
4016	\| '[' push '*' pop ']' // C99
4017	{ $$ = DeclarationNode::newVarArray( 0 ); }
4018	\| multi_array_dimension '[' push assignment_expression pop ']'
4019	{ $$ = $1->addArray( DeclarationNode::newArray( $4, nullptr, false ) ); }
4020	\| multi_array_dimension '[' push '*' pop ']' // C99
4021	{ $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
4022	;
4023
4024	// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
4025	// identifier to which the type applies, e.g.:
4026	//
4027	// int f( int ); // not handled here
4028	// int f( int * ); // abstract function-prototype parameter; no parameter name specified
4029	// int f( int (*)() ); // abstract function-prototype parameter; no parameter name specified
4030	// int f( int (int) ); // abstract function-prototype parameter; no parameter name specified
4031	//
4032	// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
4033	// and functions versus pointers to arrays and functions. In addition, the pattern handles the special meaning of
4034	// parenthesis around a typedef name:
4035	//
4036	// ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
4037	// parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
4038	// not as redundant parentheses around the identifier."
4039	//
4040	// For example:
4041	//
4042	// typedef float T;
4043	// int f( int ( T [5] ) ); // see abstract_parameter_declarator
4044	// int g( int ( T ( int ) ) ); // see abstract_parameter_declarator
4045	// int f( int f1( T a[5] ) ); // see identifier_parameter_declarator
4046	// int g( int g1( T g2( int p ) ) ); // see identifier_parameter_declarator
4047	//
4048	// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
4049	// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
4050	// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
4051	// functions.
4052
4053	abstract_parameter_declarator_opt:
4054	// empty
4055	{ $$ = nullptr; }
4056	\| abstract_parameter_declarator
4057	;
4058
4059	abstract_parameter_declarator:
4060	abstract_parameter_ptr
4061	\| '&' MUTEX attribute_list_opt
4062	{ $$ = DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
4063	OperKinds::AddressOf )->addQualifiers( $3 ); }
4064	\| abstract_parameter_array attribute_list_opt
4065	{ $$ = $1->addQualifiers( $2 ); }
4066	\| abstract_parameter_function attribute_list_opt
4067	{ $$ = $1->addQualifiers( $2 ); }
4068	;
4069
4070	abstract_parameter_ptr:
4071	ptrref_operator
4072	{ $$ = DeclarationNode::newPointer( nullptr, $1 ); }
4073	\| ptrref_operator type_qualifier_list
4074	{ $$ = DeclarationNode::newPointer( $2, $1 ); }
4075	\| ptrref_operator abstract_parameter_declarator
4076	{ $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4077	\| ptrref_operator type_qualifier_list abstract_parameter_declarator
4078	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4079	\| '(' abstract_parameter_ptr ')' attribute_list_opt // redundant parenthesis
4080	{ $$ = $2->addQualifiers( $4 ); }
4081	;
4082
4083	abstract_parameter_array:
4084	array_parameter_dimension
4085	\| '(' abstract_parameter_ptr ')' array_parameter_dimension
4086	{ $$ = $2->addArray( $4 ); }
4087	\| '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
4088	{ $$ = $2->addArray( $4 ); }
4089	\| '(' abstract_parameter_array ')' // redundant parenthesis
4090	{ $$ = $2; }
4091	;
4092
4093	abstract_parameter_function:
4094	'(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4095	{ $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
4096	\| '(' abstract_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4097	{ $$ = $2->addParamList( $5 ); }
4098	\| '(' abstract_parameter_function ')' // redundant parenthesis
4099	{ $$ = $2; }
4100	;
4101
4102	array_parameter_dimension:
4103	// Only the first dimension can be empty or have qualifiers.
4104	array_parameter_1st_dimension
4105	\| array_parameter_1st_dimension multi_array_dimension
4106	{ $$ = $1->addArray( $2 ); }
4107	\| multi_array_dimension
4108	;
4109
4110	// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
4111	//
4112	// ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
4113	// a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
4114
4115	array_parameter_1st_dimension:
4116	'[' ']'
4117	{ $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
4118	// multi_array_dimension handles the '[' '*' ']' case
4119	\| '[' push type_qualifier_list '*' pop ']' // remaining C99
4120	{ $$ = DeclarationNode::newVarArray( $3 ); }
4121	\| '[' push type_qualifier_list pop ']'
4122	{ $$ = DeclarationNode::newArray( nullptr, $3, false ); }
4123	// multi_array_dimension handles the '[' assignment_expression ']' case
4124	\| '[' push type_qualifier_list assignment_expression pop ']'
4125	{ $$ = DeclarationNode::newArray( $4, $3, false ); }
4126	\| '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
4127	{ $$ = DeclarationNode::newArray( $5, $4, true ); }
4128	\| '[' push type_qualifier_list STATIC assignment_expression pop ']'
4129	{ $$ = DeclarationNode::newArray( $5, $3, true ); }
4130	;
4131
4132	// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
4133	//
4134	// struct S {
4135	// int;
4136	// int *;
4137	// int [10];
4138	// int (*)();
4139	// };
4140
4141	variable_abstract_declarator:
4142	variable_abstract_ptr
4143	\| variable_abstract_array attribute_list_opt
4144	{ $$ = $1->addQualifiers( $2 ); }
4145	\| variable_abstract_function attribute_list_opt
4146	{ $$ = $1->addQualifiers( $2 ); }
4147	;
4148
4149	variable_abstract_ptr:
4150	ptrref_operator
4151	{ $$ = DeclarationNode::newPointer( nullptr, $1 ); }
4152	\| ptrref_operator type_qualifier_list
4153	{ $$ = DeclarationNode::newPointer( $2, $1 ); }
4154	\| ptrref_operator variable_abstract_declarator
4155	{ $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4156	\| ptrref_operator type_qualifier_list variable_abstract_declarator
4157	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4158	\| '(' variable_abstract_ptr ')' attribute_list_opt // redundant parenthesis
4159	{ $$ = $2->addQualifiers( $4 ); }
4160	;
4161
4162	variable_abstract_array:
4163	array_dimension
4164	\| '(' variable_abstract_ptr ')' array_dimension
4165	{ $$ = $2->addArray( $4 ); }
4166	\| '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
4167	{ $$ = $2->addArray( $4 ); }
4168	\| '(' variable_abstract_array ')' // redundant parenthesis
4169	{ $$ = $2; }
4170	;
4171
4172	variable_abstract_function:
4173	'(' variable_abstract_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4174	{ $$ = $2->addParamList( $5 ); }
4175	\| '(' variable_abstract_function ')' // redundant parenthesis
4176	{ $$ = $2; }
4177	;
4178
4179	// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
4180	// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
4181
4182	cfa_identifier_parameter_declarator_tuple: // CFA
4183	cfa_identifier_parameter_declarator_no_tuple
4184	\| cfa_abstract_tuple
4185	\| type_qualifier_list cfa_abstract_tuple
4186	{ $$ = $2->addQualifiers( $1 ); }
4187	;
4188
4189	cfa_identifier_parameter_declarator_no_tuple: // CFA
4190	cfa_identifier_parameter_ptr
4191	\| cfa_identifier_parameter_array
4192	;
4193
4194	cfa_identifier_parameter_ptr: // CFA
4195	// No SUE declaration in parameter list.
4196	ptrref_operator type_specifier_nobody
4197	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4198	\| type_qualifier_list ptrref_operator type_specifier_nobody
4199	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4200	\| ptrref_operator cfa_abstract_function
4201	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4202	\| type_qualifier_list ptrref_operator cfa_abstract_function
4203	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4204	\| ptrref_operator cfa_identifier_parameter_declarator_tuple
4205	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4206	\| type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
4207	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4208	;
4209
4210	cfa_identifier_parameter_array: // CFA
4211	// Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
4212	// shift/reduce conflict with new-style empty (void) function return type.
4213	'[' ']' type_specifier_nobody
4214	{ $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4215	\| cfa_array_parameter_1st_dimension type_specifier_nobody
4216	{ $$ = $2->addNewArray( $1 ); }
4217	\| '[' ']' multi_array_dimension type_specifier_nobody
4218	{ $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4219	\| cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
4220	{ $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4221	\| multi_array_dimension type_specifier_nobody
4222	{ $$ = $2->addNewArray( $1 ); }
4223
4224	\| '[' ']' cfa_identifier_parameter_ptr
4225	{ $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4226	\| cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
4227	{ $$ = $2->addNewArray( $1 ); }
4228	\| '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
4229	{ $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4230	\| cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
4231	{ $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4232	\| multi_array_dimension cfa_identifier_parameter_ptr
4233	{ $$ = $2->addNewArray( $1 ); }
4234	;
4235
4236	cfa_array_parameter_1st_dimension:
4237	'[' push type_qualifier_list '*' pop ']' // remaining C99
4238	{ $$ = DeclarationNode::newVarArray( $3 ); }
4239	\| '[' push type_qualifier_list assignment_expression pop ']'
4240	{ $$ = DeclarationNode::newArray( $4, $3, false ); }
4241	\| '[' push declaration_qualifier_list assignment_expression pop ']'
4242	// declaration_qualifier_list must be used because of shift/reduce conflict with
4243	// assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
4244	// appear in this context.
4245	{ $$ = DeclarationNode::newArray( $4, $3, true ); }
4246	\| '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
4247	{ $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
4248	;
4249
4250	// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
4251	// identifier to which the type applies, e.g.:
4252	//
4253	// [int] f( int ); // abstract variable parameter; no parameter name specified
4254	// [int] f( [int] (int) ); // abstract function-prototype parameter; no parameter name specified
4255	//
4256	// These rules need LR(3):
4257	//
4258	// cfa_abstract_tuple identifier_or_type_name
4259	// '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_list_ellipsis_opt ')'
4260	//
4261	// since a function return type can be syntactically identical to a tuple type:
4262	//
4263	// [int, int] t;
4264	// [int, int] f( int );
4265	//
4266	// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
4267	// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
4268	// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
4269	// duplicated when appearing with cfa_function_specifier.
4270
4271	cfa_abstract_declarator_tuple: // CFA
4272	cfa_abstract_tuple
4273	\| type_qualifier_list cfa_abstract_tuple
4274	{ $$ = $2->addQualifiers( $1 ); }
4275	\| cfa_abstract_declarator_no_tuple
4276	;
4277
4278	cfa_abstract_declarator_no_tuple: // CFA
4279	cfa_abstract_ptr
4280	\| cfa_abstract_array
4281	;
4282
4283	cfa_abstract_ptr: // CFA
4284	ptrref_operator type_specifier
4285	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4286	\| type_qualifier_list ptrref_operator type_specifier
4287	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4288	\| ptrref_operator cfa_abstract_function
4289	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4290	\| type_qualifier_list ptrref_operator cfa_abstract_function
4291	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4292	\| ptrref_operator cfa_abstract_declarator_tuple
4293	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4294	\| type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
4295	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4296	;
4297
4298	cfa_abstract_array: // CFA
4299	// Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
4300	// empty (void) function return type.
4301	'[' ']' type_specifier
4302	{ $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4303	\| '[' ']' multi_array_dimension type_specifier
4304	{ $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4305	\| multi_array_dimension type_specifier
4306	{ $$ = $2->addNewArray( $1 ); }
4307	\| '[' ']' cfa_abstract_ptr
4308	{ $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4309	\| '[' ']' multi_array_dimension cfa_abstract_ptr
4310	{ $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4311	\| multi_array_dimension cfa_abstract_ptr
4312	{ $$ = $2->addNewArray( $1 ); }
4313	;
4314
4315	cfa_abstract_tuple: // CFA
4316	'[' push cfa_abstract_parameter_list pop ']'
4317	{ $$ = DeclarationNode::newTuple( $3 ); }
4318	\| '[' push type_specifier_nobody ELLIPSIS pop ']'
4319	{ SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4320	\| '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
4321	{ SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4322	;
4323
4324	cfa_abstract_function: // CFA
4325	'[' ']' '(' cfa_parameter_list_ellipsis_opt ')'
4326	{ $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
4327	\| cfa_abstract_tuple '(' push cfa_parameter_list_ellipsis_opt pop ')'
4328	{ $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4329	\| cfa_function_return '(' push cfa_parameter_list_ellipsis_opt pop ')'
4330	{ $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4331	;
4332
4333	// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
4334	// each declaration, and in the specifier-qualifier list in each structure declaration and type name."
4335	//
4336	// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
4337	// the declaration specifiers in a declaration is an obsolescent feature."
4338	//
4339	// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
4340	// prototype-format parameter type declarators) is an obsolescent feature."
4341	//
4342	// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
4343	// declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
4344
4345	// ********************** MISCELLANEOUS ******************************
4346
4347	comma_opt: // redundant comma
4348	// empty
4349	\| ','
4350	;
4351
4352	default_initializer_opt:
4353	// empty
4354	{ $$ = nullptr; }
4355	\| '=' assignment_expression
4356	{ $$ = $2; }
4357	;
4358
4359	%%
4360
4361	// ----end of grammar----
4362
4363	// Local Variables: //
4364	// mode: c++ //
4365	// tab-width: 4 //
4366	// compile-command: "bison -Wcounterexamples parser.yy" //
4367	// End: //

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format