source: src/Parser/parser.yy@ cb98d9d

Last change on this file since cb98d9d was d9bad51, checked in by Andrew Beach <ajbeach@…>, 18 months ago

Fixed memory leak in the parser.
  • Property mode set to 100644
File size: 176.2 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author : Peter A. Buhr
10// Created On : Sat Sep 1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Sat Mar 16 18:19:23 2024
13// Update Count : 6617
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS. While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks. Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// designation with '=' (use ':' instead)
29//
30// This incompatibility is discussed in detail before the "designation" grammar rule. Most of the syntactic extensions
31// from ANSI90 to ANSI11 C are marked with the comment "C99/C11".
32
33// This grammar also has two levels of extensions. The first extensions cover most of the GCC C extensions. All of the
34// syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall (CFA), which
35// fixes several of C's outstanding problems and extends C with many modern language concepts. All of the syntactic
36// extensions for CFA C are marked with the comment "CFA".
37
38%{
39#define YYDEBUG_LEXER_TEXT( yylval ) // lexer loads this up each time
40#define YYDEBUG 1 // get the pretty debugging code to compile
41#define YYERROR_VERBOSE // more information in syntax errors
42
43#undef __GNUC_MINOR__
44
45#include <cstdio>
46#include <sstream>
47#include <stack>
48using namespace std;
49
50#include "DeclarationNode.h" // for DeclarationNode, ...
51#include "ExpressionNode.h" // for ExpressionNode, ...
52#include "InitializerNode.h" // for InitializerNode, ...
53#include "ParserTypes.h"
54#include "StatementNode.h" // for build_...
55#include "TypedefTable.h"
56#include "TypeData.h"
57#include "Common/SemanticError.h" // error_str
58#include "Common/utility.h" // for maybeMoveBuild, maybeBuild, CodeLo...
59
60// lex uses __null in a boolean context, it's fine.
61#ifdef __clang__
62#pragma GCC diagnostic ignored "-Wparentheses-equality"
63#endif
64
65extern DeclarationNode * parseTree;
66extern ast::Linkage::Spec linkage;
67extern TypedefTable typedefTable;
68
69stack<ast::Linkage::Spec> linkageStack;
70
71bool appendStr( string & to, string & from ) {
72 // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
73 // "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
74 // the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
75 // easier to let the C compiler handle this case.
76 //
77 // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
78 // without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
79 // e.g., u"a" U"b" L"c" is disallowed.
80
81 if ( from[0] != '"' ) { // encoding ?
82 if ( to[0] != '"' ) { // encoding ?
83 if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
84 yyerror( "non-matching string encodings for string-literal concatenation" );
85 return false; // parse error, must call YYERROR in action
86 } else if ( from[1] == '8' ) {
87 from.erase( 0, 1 ); // remove 2nd encoding
88 } // if
89 } else {
90 if ( from[1] == '8' ) { // move encoding to start
91 to = "u8" + to;
92 from.erase( 0, 1 ); // remove 2nd encoding
93 } else {
94 to = from[0] + to;
95 } // if
96 } // if
97 from.erase( 0, 1 ); // remove 2nd encoding
98 } // if
99 to += " " + from; // concatenated into single string
100 return true;
101} // appendStr
102
103DeclarationNode * distAttr( DeclarationNode * typeSpec, DeclarationNode * declList ) {
104 // Distribute type specifier across all declared variables, e.g., static, const, __attribute__.
105 assert( declList );
106
107 // Do not distribute attributes for aggregates because the attributes surrounding the aggregate belong it not the
108 // variables in the declaration list, e.g.,
109 //
110 // struct __attribute__(( aligned(128) )) S { ...
111 // } v1 __attribute__(( aligned(64) )), v2 __attribute__(( aligned(32) )), v3;
112 // struct S v4;
113 //
114 // v1 => 64, v2 =>32, v3 => 128, v2 => 128
115 //
116 // Anonymous aggregates are a special case because there is no aggregate to bind the attribute to; hence it floats
117 // to the declaration list.
118 //
119 // struct __attribute__(( aligned(128) )) /*anonymous */ { ... } v1;
120 //
121 // v1 => 128
122
123 bool copyattr = ! (typeSpec->type && typeSpec->type->kind == TypeData::Aggregate && ! typeSpec->type->aggregate.anon );
124
125 // addType copies the type information for the aggregate instances from typeSpec into cl's aggInst.aggregate.
126 DeclarationNode * cl = (new DeclarationNode)->addType( typeSpec ); // typeSpec IS DELETED!!!
127
128 // Start at second variable in declaration list and clone the type specifiers for each variable.
129 for ( DeclarationNode * cur = declList->next ; cur != nullptr; cur = cur->next ) {
130 cl->cloneBaseType( cur, copyattr ); // cur is modified
131 } // for
132
133 // Add first variable in declaration list with hidden type information in aggInst.aggregate, which is used by
134 // extractType to recover the type for the aggregate instances.
135 declList->addType( cl, copyattr ); // cl IS DELETED!!!
136 return declList;
137} // distAttr
138
139void distExt( DeclarationNode * declaration ) {
140 // distribute EXTENSION across all declarations
141 for ( DeclarationNode *iter = declaration ; iter != nullptr ; iter = iter->next ) {
142 iter->set_extension( true );
143 } // for
144} // distExt
145
146void distInl( DeclarationNode * declaration ) {
147 // distribute INLINE across all declarations
148 for ( DeclarationNode *iter = declaration ; iter != nullptr ; iter = iter->next ) {
149 iter->set_inLine( true );
150 } // for
151} // distInl
152
153void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
154 // distribute qualifiers across all non-variable declarations in a distribution statemement
155 for ( DeclarationNode * iter = declaration ; iter != nullptr ; iter = iter->next ) {
156 // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
157 // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
158 // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
159 // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
160 DeclarationNode * clone = qualifiers->clone();
161 if ( qualifiers->type ) { // forall clause ? (handles SC)
162 if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
163 swap( clone->type->forall, iter->type->aggregate.params );
164 iter->addQualifiers( clone );
165 } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
166 // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
167 DeclarationNode newnode;
168 swap( newnode.type, iter->type->aggInst.aggregate );
169 swap( clone->type->forall, newnode.type->aggregate.params );
170 newnode.addQualifiers( clone );
171 swap( newnode.type, iter->type->aggInst.aggregate );
172 } else if ( iter->type->kind == TypeData::Function ) { // routines ?
173 swap( clone->type->forall, iter->type->forall );
174 iter->addQualifiers( clone );
175 } // if
176 } else { // just SC qualifiers
177 iter->addQualifiers( clone );
178 } // if
179 } // for
180 delete qualifiers;
181} // distQual
182
183// There is an ambiguity for inline generic-routine return-types and generic routines.
184// forall( otype T ) struct S { int i; } bar( T ) {}
185// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
186// forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
187// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
188// forall( otype T ) struct S { int T; };
189// forall( otype W ) bar( W ) {}
190
191void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
192 if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
193 funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
194 declSpec->type->aggregate.params = nullptr;
195 } // if
196} // rebindForall
197
198string * build_postfix_name( string * name ) {
199 *name = string("__postfix_func_") + *name;
200 return name;
201} // build_postfix_name
202
203DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
204 if ( nullptr == fieldList ) {
205 if ( !( typeSpec->type && typeSpec->type->kind == TypeData::Aggregate ) ) {
206 stringstream ss;
207 // printf( "fieldDecl1 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
208 SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
209 return nullptr;
210 } // if
211 // printf( "fieldDecl2 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
212 fieldList = DeclarationNode::newName( nullptr );
213 } // if
214
215 // printf( "fieldDecl3 typeSpec %p\n", typeSpec ); typeSpec->print( std::cout, 0 );
216 DeclarationNode * temp = distAttr( typeSpec, fieldList ); // mark all fields in list
217 // printf( "fieldDecl4 temp %p\n", temp ); temp->print( std::cout, 0 );
218 return temp;
219} // fieldDecl
220
221#define NEW_ZERO new ExpressionNode( build_constantInteger( yylloc, *new string( "0" ) ) )
222#define NEW_ONE new ExpressionNode( build_constantInteger( yylloc, *new string( "1" ) ) )
223#define UPDOWN( compop, left, right ) (compop == OperKinds::LThan || compop == OperKinds::LEThan ? left : right)
224#define MISSING_ANON_FIELD "syntax error, missing loop fields with an anonymous loop index is meaningless as loop index is unavailable in loop body."
225#define MISSING_LOW "syntax error, missing low value for up-to range so index is uninitialized."
226#define MISSING_HIGH "syntax error, missing high value for down-to range so index is uninitialized."
227
228static ForCtrl * makeForCtrl(
229 const CodeLocation & location,
230 DeclarationNode * init,
231 enum OperKinds compop,
232 ExpressionNode * comp,
233 ExpressionNode * inc ) {
234 // Wrap both comp/inc if they are non-null.
235 if ( comp ) comp = new ExpressionNode( build_binary_val( location,
236 compop,
237 new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
238 comp ) );
239 if ( inc ) inc = new ExpressionNode( build_binary_val( location,
240 // choose += or -= for upto/downto
241 compop == OperKinds::LThan || compop == OperKinds::LEThan ? OperKinds::PlusAssn : OperKinds::MinusAssn,
242 new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
243 inc ) );
244 // The StatementNode call frees init->name, it must happen later.
245 return new ForCtrl( new StatementNode( init ), comp, inc );
246}
247
248ForCtrl * forCtrl( const CodeLocation & location, DeclarationNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
249 if ( index->initializer ) {
250 SemanticError( yylloc, "syntax error, direct initialization disallowed. Use instead: type var; initialization ~ comparison ~ increment." );
251 } // if
252 if ( index->next ) {
253 SemanticError( yylloc, "syntax error, multiple loop indexes disallowed in for-loop declaration." );
254 } // if
255 DeclarationNode * initDecl = index->addInitializer( new InitializerNode( start ) );
256 return makeForCtrl( location, initDecl, compop, comp, inc );
257} // forCtrl
258
259ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
260 ast::ConstantExpr * constant = dynamic_cast<ast::ConstantExpr *>(type->expr.get());
261 if ( constant && (constant->rep == "0" || constant->rep == "1") ) {
262 type = new ExpressionNode( new ast::CastExpr( location, maybeMoveBuild(type), new ast::BasicType( ast::BasicType::SignedInt ) ) );
263 } // if
264 DeclarationNode * initDecl = distAttr(
265 DeclarationNode::newTypeof( type, true ),
266 DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) )
267 );
268 return makeForCtrl( location, initDecl, compop, comp, inc );
269} // forCtrl
270
271ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
272 if ( auto identifier = dynamic_cast<ast::NameExpr *>(index->expr.get()) ) {
273 return forCtrl( location, type, new string( identifier->name ), start, compop, comp, inc );
274 } else if ( auto commaExpr = dynamic_cast<ast::CommaExpr *>( index->expr.get() ) ) {
275 if ( auto identifier = commaExpr->arg1.as<ast::NameExpr>() ) {
276 return forCtrl( location, type, new string( identifier->name ), start, compop, comp, inc );
277 } else {
278 SemanticError( yylloc, "syntax error, loop-index name missing. Expression disallowed." ); return nullptr;
279 } // if
280 } else {
281 SemanticError( yylloc, "syntax error, loop-index name missing. Expression disallowed." ); return nullptr;
282 } // if
283} // forCtrl
284
285static void IdentifierBeforeIdentifier( string & identifier1, string & identifier2, const char * kind ) {
286 SemanticError( yylloc, "syntax error, adjacent identifiers \"%s\" and \"%s\" are not meaningful in an %s.\n"
287 "Possible cause is misspelled type name or missing generic parameter.",
288 identifier1.c_str(), identifier2.c_str(), kind );
289} // IdentifierBeforeIdentifier
290
291static void IdentifierBeforeType( string & identifier, const char * kind ) {
292 SemanticError( yylloc, "syntax error, identifier \"%s\" cannot appear before a %s.\n"
293 "Possible cause is misspelled storage/CV qualifier, misspelled typename, or missing generic parameter.",
294 identifier.c_str(), kind );
295} // IdentifierBeforeType
296
297bool forall = false; // aggregate have one or more forall qualifiers ?
298
299// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
300#define YYLLOC_DEFAULT(Cur, Rhs, N) \
301if ( N ) { \
302 (Cur).first_line = YYRHSLOC( Rhs, 1 ).first_line; \
303 (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column; \
304 (Cur).last_line = YYRHSLOC( Rhs, N ).last_line; \
305 (Cur).last_column = YYRHSLOC( Rhs, N ).last_column; \
306 (Cur).filename = YYRHSLOC( Rhs, 1 ).filename; \
307} else { \
308 (Cur).first_line = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line; \
309 (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column; \
310 (Cur).filename = YYRHSLOC( Rhs, 0 ).filename; \
311}
312%}
313
314%define parse.error verbose
315
316// Types declaration for productions
317
318%union {
319 // A raw token can be used.
320 Token tok;
321
322 // The general node types hold some generic node or list of nodes.
323 DeclarationNode * decl;
324 InitializerNode * init;
325 ExpressionNode * expr;
326 StatementNode * stmt;
327 ClauseNode * clause;
328 TypeData * type;
329
330 // Special "nodes" containing compound information.
331 CondCtl * ifctl;
332 ForCtrl * forctl;
333 LabelNode * labels;
334
335 // Various flags and single values that become fields later.
336 ast::AggregateDecl::Aggregate aggKey;
337 ast::TypeDecl::Kind tclass;
338 OperKinds oper;
339 bool is_volatile;
340 EnumHiding enum_hiding;
341 ast::ExceptionKind except_kind;
342 // String passes ownership with it.
343 std::string * str;
344
345 // Narrower node types are used to avoid constant unwrapping.
346 ast::WaitForStmt * wfs;
347 ast::WaitUntilStmt::ClauseNode * wucn;
348 ast::GenericExpr * genexpr;
349}
350
351// ************************ TERMINAL TOKENS ********************************
352
353// keywords
354%token TYPEDEF
355%token EXTERN STATIC AUTO REGISTER
356%token THREADLOCALGCC THREADLOCALC11 // GCC, C11
357%token INLINE FORTRAN // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
358%token NORETURN // C11
359%token CONST VOLATILE
360%token RESTRICT // C99
361%token ATOMIC // C11
362%token FORALL MUTEX VIRTUAL VTABLE COERCE // CFA
363%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
364%token BOOL COMPLEX IMAGINARY // C99
365%token INT128 UINT128 uuFLOAT80 uuFLOAT128 // GCC
366%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
367%token DECIMAL32 DECIMAL64 DECIMAL128 // GCC
368%token ZERO_T ONE_T // CFA
369%token SIZEOF TYPEOF VA_LIST VA_ARG AUTO_TYPE // GCC
370%token OFFSETOF BASETYPEOF TYPEID // CFA
371%token ENUM STRUCT UNION
372%token EXCEPTION // CFA
373%token GENERATOR COROUTINE MONITOR THREAD // CFA
374%token OTYPE FTYPE DTYPE TTYPE TRAIT // CFA
375// %token RESUME // CFA
376%token LABEL // GCC
377%token SUSPEND // CFA
378%token ATTRIBUTE EXTENSION // GCC
379%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
380%token CHOOSE FALLTHRU FALLTHROUGH WITH WHEN WAITFOR WAITUNTIL // CFA
381%token CORUN COFOR
382%token DISABLE ENABLE TRY THROW THROWRESUME AT // CFA
383%token ASM // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
384%token ALIGNAS ALIGNOF GENERIC STATICASSERT // C11
385
386// names and constants: lexer differentiates between identifier and typedef names
387%token<tok> IDENTIFIER TYPEDIMname TYPEDEFname TYPEGENname
388%token<tok> TIMEOUT WAND WOR CATCH RECOVER CATCHRESUME FIXUP FINALLY // CFA
389%token<tok> INTEGERconstant CHARACTERconstant STRINGliteral
390%token<tok> DIRECTIVE
391// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
392// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
393// converted into the tuple index (.)(1). e.g., 3.x
394%token<tok> FLOATING_DECIMALconstant FLOATING_FRACTIONconstant FLOATINGconstant
395
396// multi-character operators
397%token ARROW // ->
398%token ICR DECR // ++ --
399%token LS RS // << >>
400%token LE GE EQ NE // <= >= == !=
401%token ANDAND OROR // && ||
402%token ATTR ELLIPSIS // @@ ...
403
404%token EXPassign MULTassign DIVassign MODassign // \= *= /= %=
405%token PLUSassign MINUSassign // += -=
406%token LSassign RSassign // <<= >>=
407%token ANDassign ERassign ORassign // &= ^= |=
408
409%token ErangeUpEq ErangeDown ErangeDownEq // ~= -~ -~=
410%token ATassign // @=
411
412%type<tok> identifier identifier_at identifier_or_type_name attr_name
413%type<tok> quasi_keyword
414%type<expr> string_literal
415%type<str> string_literal_list
416
417%type<enum_hiding> hide_opt visible_hide_opt
418
419// expressions
420%type<expr> constant
421%type<expr> tuple tuple_expression_list
422%type<oper> ptrref_operator unary_operator assignment_operator simple_assignment_operator compound_assignment_operator
423%type<expr> primary_expression postfix_expression unary_expression
424%type<expr> cast_expression_list cast_expression exponential_expression multiplicative_expression additive_expression
425%type<expr> shift_expression relational_expression equality_expression
426%type<expr> AND_expression exclusive_OR_expression inclusive_OR_expression
427%type<expr> logical_AND_expression logical_OR_expression
428%type<expr> conditional_expression constant_expression assignment_expression assignment_expression_opt
429%type<expr> comma_expression comma_expression_opt
430%type<expr> argument_expression_list_opt argument_expression_list argument_expression default_initializer_opt
431%type<ifctl> conditional_declaration
432%type<forctl> for_control_expression for_control_expression_list
433%type<oper> upupeq updown updowneq downupdowneq
434%type<expr> subrange
435%type<decl> asm_name_opt
436%type<expr> asm_operands_opt asm_operands_list asm_operand
437%type<labels> label_list
438%type<expr> asm_clobbers_list_opt
439%type<is_volatile> asm_volatile_opt
440%type<expr> handler_predicate_opt
441%type<genexpr> generic_association generic_assoc_list
442
443// statements
444%type<stmt> statement labeled_statement compound_statement
445%type<stmt> statement_decl statement_decl_list statement_list_nodecl
446%type<stmt> selection_statement
447%type<clause> switch_clause_list_opt switch_clause_list
448%type<expr> case_value
449%type<clause> case_clause case_value_list case_label case_label_list
450%type<stmt> iteration_statement jump_statement
451%type<stmt> expression_statement asm_statement
452%type<stmt> with_statement
453%type<expr> with_clause_opt
454%type<stmt> corun_statement cofor_statement
455%type<stmt> exception_statement
456%type<clause> handler_clause finally_clause
457%type<except_kind> handler_key
458%type<stmt> mutex_statement
459%type<expr> when_clause when_clause_opt waitfor waituntil timeout
460%type<stmt> waitfor_statement waituntil_statement
461%type<wfs> wor_waitfor_clause
462%type<wucn> waituntil_clause wand_waituntil_clause wor_waituntil_clause
463
464// declarations
465%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
466%type<decl> abstract_parameter_declarator_opt abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
467%type<decl> abstract_parameter_declaration
468
469%type<aggKey> aggregate_key aggregate_data aggregate_control
470%type<decl> aggregate_type aggregate_type_nobody
471
472%type<decl> assertion assertion_list assertion_list_opt
473
474%type<expr> bit_subrange_size_opt bit_subrange_size
475
476%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
477%type<type> basic_type_name_type
478%type<type> vtable vtable_opt default_opt
479
480%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
481
482%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
483%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
484
485%type<decl> elaborated_type elaborated_type_nobody
486
487%type<decl> enumerator_list enum_type enum_type_nobody enumerator_type
488%type<init> enumerator_value_opt
489
490%type<decl> external_definition external_definition_list external_definition_list_opt
491
492%type<decl> exception_declaration
493
494%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
495%type<expr> field field_name_list field_name fraction_constants_opt
496
497%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
498
499%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
500%type<decl> identifier_list
501
502%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
503%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
504%type<decl> cfa_abstract_ptr cfa_abstract_tuple
505
506%type<decl> cfa_array_parameter_1st_dimension
507
508%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
509%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
510
511%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
512%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
513
514%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_list_ellipsis_opt
515
516%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
517
518%type<decl> c_declaration static_assert
519%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
520%type<decl> KR_parameter_list KR_parameter_list_opt
521
522%type<decl> parameter_declaration parameter_list parameter_list_ellipsis_opt
523
524%type<decl> paren_identifier paren_type
525
526%type<decl> storage_class storage_class_list
527
528%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
529
530%type<tclass> type_class new_type_class
531%type<decl> type_declarator type_declarator_name type_declaring_list
532
533%type<decl> type_declaration_specifier type_type_specifier
534%type<type> type_name typegen_name
535%type<decl> typedef_name typedef_declaration typedef_expression
536
537%type<decl> variable_type_redeclarator variable_type_ptr variable_type_array variable_type_function
538%type<decl> general_function_declarator function_type_redeclarator function_type_array function_type_no_ptr function_type_ptr
539
540%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
541
542%type<decl> type type_no_function
543%type<decl> type_parameter type_parameter_list type_initializer_opt
544
545%type<expr> type_parameters_opt type_list array_type_list // array_dimension_list
546
547%type<decl> type_qualifier forall type_qualifier_list_opt type_qualifier_list
548%type<type> type_qualifier_name
549%type<decl> type_specifier type_specifier_nobody
550
551%type<decl> variable_declarator variable_ptr variable_array variable_function
552%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
553
554%type<decl> attribute_list_opt attribute_list attribute attribute_name_list attribute_name
555
556// initializers
557%type<init> initializer initializer_list_opt initializer_opt
558
559// designators
560%type<expr> designator designator_list designation
561
562
563// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
564// .---------. matches IF '(' comma_expression ')' statement . (reduce)
565// if ( C ) S1 else S2
566// `-----------------' matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
567// Similar issues exit with the waitfor statement.
568
569// Order of these lines matters (low-to-high precedence). THEN is left associative over WAND/WOR/TIMEOUT/ELSE, WAND/WOR
570// is left associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
571%precedence THEN // rule precedence for IF/WAITFOR statement
572%precedence ANDAND // token precedence for start of WAND in WAITFOR statement
573%precedence WAND // token precedence for start of WAND in WAITFOR statement
574%precedence OROR // token precedence for start of WOR in WAITFOR statement
575%precedence WOR // token precedence for start of WOR in WAITFOR statement
576%precedence TIMEOUT // token precedence for start of TIMEOUT in WAITFOR statement
577%precedence CATCH // token precedence for start of TIMEOUT in WAITFOR statement
578%precedence RECOVER // token precedence for start of TIMEOUT in WAITFOR statement
579%precedence CATCHRESUME // token precedence for start of TIMEOUT in WAITFOR statement
580%precedence FIXUP // token precedence for start of TIMEOUT in WAITFOR statement
581%precedence FINALLY // token precedence for start of TIMEOUT in WAITFOR statement
582%precedence ELSE // token precedence for start of else clause in IF/WAITFOR statement
583
584
585// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
586// forall( otype T ) struct Foo { T v; };
587// .-----. matches pointer to function returning a generic (which is impossible without a type)
588// Foo ( *fp )( int );
589// `---' matches start of TYPEGENname '('
590// must be:
591// Foo( int ) ( *fp )( int );
592// The same problem occurs here:
593// forall( otype T ) struct Foo { T v; } ( *fp )( int );
594// must be:
595// forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
596
597// Order of these lines matters (low-to-high precedence).
598%precedence TYPEGENname
599%precedence '}'
600%precedence '('
601
602// %precedence RESUME
603// %precedence '{'
604// %precedence ')'
605
606%locations // support location tracking for error messages
607
608%start translation_unit // parse-tree root
609
610%%
611// ************************ Namespace Management ********************************
612
613// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
614// which are lexically identical.
615//
616// typedef int foo; // identifier foo must now be scanned as TYPEDEFname
617// foo f; // to allow it to appear in this context
618//
619// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
620// between syntactic and semantic constructs. Cforall compounds this problem by introducing type names local to the
621// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
622// generators" -- parameterized types. This latter type name creates a third class of identifiers, "TYPEGENname", which
623// must be distinguished by the lexical scanner.
624//
625// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
626// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
627// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
628// each context that introduces a name scope, a new level is created in the type table and that level is popped on
629// exiting the scope. Since type names can be local to a particular declaration, each declaration is itself a scope.
630// This requires distinguishing between type names that are local to the current declaration scope and those that
631// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
632//
633// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
634// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
635// around the list separator.
636//
637// XXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
638// push pop push pop
639
640push:
641 { typedefTable.enterScope(); }
642 ;
643
644pop:
645 { typedefTable.leaveScope(); }
646 ;
647
648// ************************ CONSTANTS ********************************
649
650constant:
651 // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
652 INTEGERconstant { $$ = new ExpressionNode( build_constantInteger( yylloc, *$1 ) ); }
653 | FLOATING_DECIMALconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
654 | FLOATING_FRACTIONconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
655 | FLOATINGconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
656 | CHARACTERconstant { $$ = new ExpressionNode( build_constantChar( yylloc, *$1 ) ); }
657 ;
658
659quasi_keyword: // CFA
660 TIMEOUT
661 | WAND
662 | WOR
663 | CATCH
664 | RECOVER
665 | CATCHRESUME
666 | FIXUP
667 | FINALLY
668 ;
669
670identifier:
671 IDENTIFIER
672 | quasi_keyword
673 ;
674
675identifier_at:
676 identifier
677 | '@' // CFA
678 { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
679 ;
680
681string_literal:
682 string_literal_list { $$ = new ExpressionNode( build_constantStr( yylloc, *$1 ) ); }
683 ;
684
685string_literal_list: // juxtaposed strings are concatenated
686 STRINGliteral { $$ = $1; } // conversion from tok to str
687 | string_literal_list STRINGliteral
688 {
689 if ( ! appendStr( *$1, *$2 ) ) YYERROR; // append 2nd juxtaposed string to 1st
690 delete $2; // allocated by lexer
691 $$ = $1; // conversion from tok to str
692 }
693 ;
694
695// ************************ EXPRESSIONS ********************************
696
697primary_expression:
698 IDENTIFIER // typedef name cannot be used as a variable name
699 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
700 | quasi_keyword
701 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
702 | TYPEDIMname // CFA, generic length argument
703 { $$ = new ExpressionNode( build_dimensionref( yylloc, $1 ) ); }
704 | tuple
705 | '(' comma_expression ')'
706 { $$ = $2; }
707 | '(' compound_statement ')' // GCC, lambda expression
708 { $$ = new ExpressionNode( new ast::StmtExpr( yylloc, dynamic_cast<ast::CompoundStmt *>( maybeMoveBuild( $2 ) ) ) ); }
709 | type_name '.' identifier // CFA, nested type
710 { $$ = new ExpressionNode( build_qualified_expr( yylloc, DeclarationNode::newFromTypeData( $1 ), build_varref( yylloc, $3 ) ) ); }
711 | type_name '.' '[' field_name_list ']' // CFA, nested type / tuple field selector
712 { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
713 | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
714 {
715 // add the missing control expression to the GenericExpr and return it
716 $5->control = maybeMoveBuild( $3 );
717 $$ = new ExpressionNode( $5 );
718 }
719 // | RESUME '(' comma_expression ')'
720 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
721 // | RESUME '(' comma_expression ')' compound_statement
722 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
723 | IDENTIFIER IDENTIFIER // invalid syntax rule
724 { IdentifierBeforeIdentifier( *$1.str, *$2.str, "expression" ); $$ = nullptr; }
725 | IDENTIFIER type_qualifier // invalid syntax rule
726 { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
727 | IDENTIFIER storage_class // invalid syntax rule
728 { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
729 | IDENTIFIER basic_type_name // invalid syntax rule
730 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
731 | IDENTIFIER TYPEDEFname // invalid syntax rule
732 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
733 | IDENTIFIER TYPEGENname // invalid syntax rule
734 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
735 ;
736
737generic_assoc_list: // C11
738 generic_association
739 | generic_assoc_list ',' generic_association
740 {
741 // steal the association node from the singleton and delete the wrapper
742 assert( 1 == $3->associations.size() );
743 $1->associations.push_back( $3->associations.front() );
744 delete $3;
745 $$ = $1;
746 }
747 ;
748
749generic_association: // C11
750 type_no_function ':' assignment_expression
751 {
752 // create a GenericExpr wrapper with one association pair
753 $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuildType( $1 ), maybeMoveBuild( $3 ) } } );
754 }
755 | DEFAULT ':' assignment_expression
756 { $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuild( $3 ) } } ); }
757 ;
758
759postfix_expression:
760 primary_expression
761 | postfix_expression '[' assignment_expression ',' tuple_expression_list ']'
762 // Historic, transitional: Disallow commas in subscripts.
763 // Switching to this behaviour may help check if a C compatibilty case uses comma-exprs in subscripts.
764 // Current: Commas in subscripts make tuples.
765 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, new ExpressionNode( build_tuple( yylloc, $3->set_last( $5 ) ) ) ) ); }
766 | postfix_expression '[' assignment_expression ']'
767 // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
768 // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
769 // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
770 // equivalent to the old x[i,j].
771 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
772 | constant '[' assignment_expression ']' // 3[a], 'a'[a], 3.5[a]
773 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
774 | string_literal '[' assignment_expression ']' // "abc"[3], 3["abc"]
775 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
776 | postfix_expression '{' argument_expression_list_opt '}' // CFA, constructor call
777 {
778 Token fn;
779 fn.str = new std::string( "?{}" ); // location undefined - use location of '{'?
780 $$ = new ExpressionNode( new ast::ConstructorExpr( yylloc, build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), $1->set_last( $3 ) ) ) );
781 }
782 | postfix_expression '(' argument_expression_list_opt ')'
783 { $$ = new ExpressionNode( build_func( yylloc, $1, $3 ) ); }
784 | VA_ARG '(' primary_expression ',' declaration_specifier_nobody abstract_parameter_declarator_opt ')'
785 // { SemanticError( yylloc, "va_arg is currently unimplemented." ); $$ = nullptr; }
786 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, new string( "__builtin_va_arg" ) ) ),
787 $3->set_last( (ExpressionNode *)($6 ? $6->addType( $5 ) : $5) ) ) ); }
788 | postfix_expression '`' identifier // CFA, postfix call
789 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
790 | constant '`' identifier // CFA, postfix call
791 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
792 | string_literal '`' identifier // CFA, postfix call
793 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
794
795 // SKULLDUGGERY: The typedef table used for parsing does not store fields in structures. To parse a qualified
796 // name, it is assumed all name-tokens after the first are identifiers, regardless of how the lexer identifies
797 // them. For example:
798 //
799 // struct S;
800 // forall(T) struct T;
801 // union U;
802 // enum E { S, T, E };
803 // struct Z { int S, T, Z, E, U; };
804 // void fred () {
805 // Z z;
806 // z.S; // lexer returns S is TYPEDEFname
807 // z.T; // lexer returns T is TYPEGENname
808 // z.Z; // lexer returns Z is TYPEDEFname
809 // z.U; // lexer returns U is TYPEDEFname
810 // z.E; // lexer returns E is TYPEDEFname
811 // }
812 | postfix_expression '.' identifier
813 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
814 | postfix_expression '.' TYPEDEFname // CFA, SKULLDUGGERY
815 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
816 | postfix_expression '.' TYPEGENname // CFA, SKULLDUGGERY
817 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
818
819 | postfix_expression '.' INTEGERconstant // CFA, tuple index
820 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
821 | postfix_expression FLOATING_FRACTIONconstant // CFA, tuple index
822 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 ) ) ); }
823 | postfix_expression '.' '[' field_name_list ']' // CFA, tuple field selector
824 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
825 | postfix_expression '.' aggregate_control
826 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $3, $1 ) ); }
827 | postfix_expression ARROW identifier
828 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
829 | postfix_expression ARROW INTEGERconstant // CFA, tuple index
830 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
831 | postfix_expression ARROW '[' field_name_list ']' // CFA, tuple field selector
832 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
833 | postfix_expression ICR
834 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::IncrPost, $1 ) ); }
835 | postfix_expression DECR
836 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::DecrPost, $1 ) ); }
837 | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
838 { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, new InitializerNode( $5, true ) ) ); }
839 | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
840 { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
841 | '^' primary_expression '{' argument_expression_list_opt '}' // CFA, destructor call
842 {
843 Token fn;
844 fn.str = new string( "^?{}" ); // location undefined
845 $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), $2->set_last( $4 ) ) );
846 }
847 ;
848
849argument_expression_list_opt:
850 // empty
851 { $$ = nullptr; }
852 | argument_expression_list
853 ;
854
855argument_expression_list:
856 argument_expression
857 | argument_expression_list_opt ',' argument_expression
858 { $$ = $1->set_last( $3 ); }
859 ;
860
861argument_expression:
862 '@' // CFA, default parameter
863 { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
864 // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
865 | assignment_expression
866 ;
867
868field_name_list: // CFA, tuple field selector
869 field
870 | field_name_list ',' field { $$ = $1->set_last( $3 ); }
871 ;
872
873field: // CFA, tuple field selector
874 field_name
875 | FLOATING_DECIMALconstant field
876 { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), maybeMoveBuild( $2 ) ) ); }
877 | FLOATING_DECIMALconstant '[' field_name_list ']'
878 { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), build_tuple( yylloc, $3 ) ) ); }
879 | field_name '.' field
880 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
881 | field_name '.' '[' field_name_list ']'
882 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
883 | field_name ARROW field
884 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
885 | field_name ARROW '[' field_name_list ']'
886 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
887 ;
888
889field_name:
890 INTEGERconstant fraction_constants_opt
891 { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_constantInteger( yylloc, *$1 ), $2 ) ); }
892 | FLOATINGconstant fraction_constants_opt
893 { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_field_name_FLOATINGconstant( yylloc, *$1 ), $2 ) ); }
894 | identifier_at fraction_constants_opt // CFA, allow anonymous fields
895 {
896 $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_varref( yylloc, $1 ), $2 ) );
897 }
898 ;
899
900fraction_constants_opt:
901 // empty
902 { $$ = nullptr; }
903 | fraction_constants_opt FLOATING_FRACTIONconstant
904 {
905 ast::Expr * constant = build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 );
906 $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( yylloc, $1, constant ) ) : new ExpressionNode( constant );
907 }
908 ;
909
910unary_expression:
911 postfix_expression
912 // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
913 // semantics checks, e.g., ++3, 3--, *3, &&3
914 | constant
915 | string_literal
916 { $$ = $1; }
917 | EXTENSION cast_expression // GCC
918 { $$ = $2->set_extension( true ); }
919 // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
920 // { * X; } // dereference X
921 // { * int X; } // CFA declaration of pointer to int
922 | ptrref_operator cast_expression // CFA
923 {
924 switch ( $1 ) {
925 case OperKinds::AddressOf:
926 $$ = new ExpressionNode( new ast::AddressExpr( maybeMoveBuild( $2 ) ) );
927 break;
928 case OperKinds::PointTo:
929 $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) );
930 break;
931 case OperKinds::And:
932 $$ = new ExpressionNode( new ast::AddressExpr( new ast::AddressExpr( maybeMoveBuild( $2 ) ) ) );
933 break;
934 default:
935 assert( false );
936 }
937 }
938 | unary_operator cast_expression
939 { $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) ); }
940 | ICR unary_expression
941 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Incr, $2 ) ); }
942 | DECR unary_expression
943 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Decr, $2 ) ); }
944 | SIZEOF unary_expression
945 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuild( $2 ) ) ); }
946 | SIZEOF '(' type_no_function ')'
947 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
948 | ALIGNOF unary_expression // GCC, variable alignment
949 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuild( $2 ) ) ); }
950 | ALIGNOF '(' type_no_function ')' // GCC, type alignment
951 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
952
953 // Cannot use rule "type", which includes cfa_abstract_function, for sizeof/alignof, because of S/R problems on
954 // look ahead, so the cfa_abstract_function is factored out.
955 | SIZEOF '(' cfa_abstract_function ')'
956 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
957 | ALIGNOF '(' cfa_abstract_function ')' // GCC, type alignment
958 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
959
960 | OFFSETOF '(' type_no_function ',' identifier ')'
961 { $$ = new ExpressionNode( build_offsetOf( yylloc, $3, build_varref( yylloc, $5 ) ) ); }
962 | TYPEID '(' type ')'
963 {
964 SemanticError( yylloc, "typeid name is currently unimplemented." ); $$ = nullptr;
965 // $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) );
966 }
967 ;
968
969ptrref_operator:
970 '*' { $$ = OperKinds::PointTo; }
971 | '&' { $$ = OperKinds::AddressOf; }
972 // GCC, address of label must be handled by semantic check for ref,ref,label
973 | ANDAND { $$ = OperKinds::And; }
974 ;
975
976unary_operator:
977 '+' { $$ = OperKinds::UnPlus; }
978 | '-' { $$ = OperKinds::UnMinus; }
979 | '!' { $$ = OperKinds::Neg; }
980 | '~' { $$ = OperKinds::BitNeg; }
981 ;
982
983cast_expression:
984 unary_expression
985 | '(' type_no_function ')' cast_expression
986 { $$ = new ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
987 | '(' aggregate_control '&' ')' cast_expression // CFA
988 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
989 | '(' aggregate_control '*' ')' cast_expression // CFA
990 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
991 | '(' VIRTUAL ')' cast_expression // CFA
992 { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $4 ), nullptr ) ); }
993 | '(' VIRTUAL type_no_function ')' cast_expression // CFA
994 { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $5 ), maybeMoveBuildType( $3 ) ) ); }
995 | '(' RETURN type_no_function ')' cast_expression // CFA
996 { $$ = new ExpressionNode( build_cast( yylloc, $3, $5, ast::CastExpr::Return ) ); }
997 | '(' COERCE type_no_function ')' cast_expression // CFA
998 { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
999 | '(' qualifier_cast_list ')' cast_expression // CFA
1000 { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
1001// | '(' type_no_function ')' tuple
1002// { $$ = new ast::ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
1003 ;
1004
1005qualifier_cast_list:
1006 cast_modifier type_qualifier_name
1007 | cast_modifier MUTEX
1008 | qualifier_cast_list cast_modifier type_qualifier_name
1009 | qualifier_cast_list cast_modifier MUTEX
1010 ;
1011
1012cast_modifier:
1013 '-'
1014 | '+'
1015 ;
1016
1017exponential_expression:
1018 cast_expression
1019 | exponential_expression '\\' cast_expression
1020 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Exp, $1, $3 ) ); }
1021 ;
1022
1023multiplicative_expression:
1024 exponential_expression
1025 | multiplicative_expression '*' exponential_expression
1026 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mul, $1, $3 ) ); }
1027 | multiplicative_expression '/' exponential_expression
1028 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Div, $1, $3 ) ); }
1029 | multiplicative_expression '%' exponential_expression
1030 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mod, $1, $3 ) ); }
1031 ;
1032
1033additive_expression:
1034 multiplicative_expression
1035 | additive_expression '+' multiplicative_expression
1036 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Plus, $1, $3 ) ); }
1037 | additive_expression '-' multiplicative_expression
1038 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Minus, $1, $3 ) ); }
1039 ;
1040
1041shift_expression:
1042 additive_expression
1043 | shift_expression LS additive_expression
1044 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LShift, $1, $3 ) ); }
1045 | shift_expression RS additive_expression
1046 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::RShift, $1, $3 ) ); }
1047 ;
1048
1049relational_expression:
1050 shift_expression
1051 | relational_expression '<' shift_expression
1052 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LThan, $1, $3 ) ); }
1053 | relational_expression '>' shift_expression
1054 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GThan, $1, $3 ) ); }
1055 | relational_expression LE shift_expression
1056 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LEThan, $1, $3 ) ); }
1057 | relational_expression GE shift_expression
1058 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GEThan, $1, $3 ) ); }
1059 ;
1060
1061equality_expression:
1062 relational_expression
1063 | equality_expression EQ relational_expression
1064 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Eq, $1, $3 ) ); }
1065 | equality_expression NE relational_expression
1066 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Neq, $1, $3 ) ); }
1067 ;
1068
1069AND_expression:
1070 equality_expression
1071 | AND_expression '&' equality_expression
1072 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitAnd, $1, $3 ) ); }
1073 ;
1074
1075exclusive_OR_expression:
1076 AND_expression
1077 | exclusive_OR_expression '^' AND_expression
1078 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Xor, $1, $3 ) ); }
1079 ;
1080
1081inclusive_OR_expression:
1082 exclusive_OR_expression
1083 | inclusive_OR_expression '|' exclusive_OR_expression
1084 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitOr, $1, $3 ) ); }
1085 ;
1086
1087logical_AND_expression:
1088 inclusive_OR_expression
1089 | logical_AND_expression ANDAND inclusive_OR_expression
1090 { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::AndExpr ) ); }
1091 ;
1092
1093logical_OR_expression:
1094 logical_AND_expression
1095 | logical_OR_expression OROR logical_AND_expression
1096 { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::OrExpr ) ); }
1097 ;
1098
1099conditional_expression:
1100 logical_OR_expression
1101 | logical_OR_expression '?' comma_expression ':' conditional_expression
1102 { $$ = new ExpressionNode( build_cond( yylloc, $1, $3, $5 ) ); }
1103 | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
1104 { $$ = new ExpressionNode( build_cond( yylloc, $1, nullptr, $4 ) ); }
1105 ;
1106
1107constant_expression:
1108 conditional_expression
1109 ;
1110
1111assignment_expression:
1112 // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
1113 conditional_expression
1114 | unary_expression assignment_operator assignment_expression
1115 {
1116// if ( $2 == OperKinds::AtAssn ) {
1117// SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
1118// } else {
1119 $$ = new ExpressionNode( build_binary_val( yylloc, $2, $1, $3 ) );
1120// } // if
1121 }
1122 | unary_expression '=' '{' initializer_list_opt comma_opt '}'
1123 { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
1124 ;
1125
1126assignment_expression_opt:
1127 // empty
1128 { $$ = nullptr; }
1129 | assignment_expression
1130 ;
1131
1132assignment_operator:
1133 simple_assignment_operator
1134 | compound_assignment_operator
1135 ;
1136
1137simple_assignment_operator:
1138 '=' { $$ = OperKinds::Assign; }
1139 | ATassign { $$ = OperKinds::AtAssn; } // CFA
1140 ;
1141
1142compound_assignment_operator:
1143 EXPassign { $$ = OperKinds::ExpAssn; }
1144 | MULTassign { $$ = OperKinds::MulAssn; }
1145 | DIVassign { $$ = OperKinds::DivAssn; }
1146 | MODassign { $$ = OperKinds::ModAssn; }
1147 | PLUSassign { $$ = OperKinds::PlusAssn; }
1148 | MINUSassign { $$ = OperKinds::MinusAssn; }
1149 | LSassign { $$ = OperKinds::LSAssn; }
1150 | RSassign { $$ = OperKinds::RSAssn; }
1151 | ANDassign { $$ = OperKinds::AndAssn; }
1152 | ERassign { $$ = OperKinds::ERAssn; }
1153 | ORassign { $$ = OperKinds::OrAssn; }
1154 ;
1155
1156tuple: // CFA, tuple
1157 // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
1158 // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
1159// '[' ']'
1160// { $$ = new ExpressionNode( build_tuple() ); }
1161// | '[' push assignment_expression pop ']'
1162// { $$ = new ExpressionNode( build_tuple( $3 ) ); }
1163 '[' ',' tuple_expression_list ']'
1164 { $$ = new ExpressionNode( build_tuple( yylloc, (new ExpressionNode( nullptr ))->set_last( $3 ) ) ); }
1165 | '[' push assignment_expression pop ',' tuple_expression_list ']'
1166 { $$ = new ExpressionNode( build_tuple( yylloc, $3->set_last( $6 ) ) ); }
1167 ;
1168
1169tuple_expression_list:
1170 assignment_expression
1171 | '@' // CFA
1172 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1173 | tuple_expression_list ',' assignment_expression
1174 { $$ = $1->set_last( $3 ); }
1175 | tuple_expression_list ',' '@'
1176 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1177 ;
1178
1179comma_expression:
1180 assignment_expression
1181 | comma_expression ',' assignment_expression
1182 { $$ = new ExpressionNode( new ast::CommaExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1183 ;
1184
1185comma_expression_opt:
1186 // empty
1187 { $$ = nullptr; }
1188 | comma_expression
1189 ;
1190
1191// ************************** STATEMENTS *******************************
1192
1193statement:
1194 labeled_statement
1195 | compound_statement
1196 | expression_statement
1197 | selection_statement
1198 | iteration_statement
1199 | jump_statement
1200 | with_statement
1201 | mutex_statement
1202 | waitfor_statement
1203 | waituntil_statement
1204 | corun_statement
1205 | cofor_statement
1206 | exception_statement
1207 | enable_disable_statement
1208 { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1209 | asm_statement
1210 | DIRECTIVE
1211 { $$ = new StatementNode( build_directive( yylloc, $1 ) ); }
1212 ;
1213
1214labeled_statement:
1215 // labels cannot be identifiers 0 or 1
1216 identifier_or_type_name ':' attribute_list_opt statement
1217 { $$ = $4->add_label( yylloc, $1, $3 ); }
1218 | identifier_or_type_name ':' attribute_list_opt error // invalid syntax rule
1219 {
1220 SemanticError( yylloc, "syntx error, label \"%s\" must be associated with a statement, "
1221 "where a declaration, case, or default is not a statement.\n"
1222 "Move the label or terminate with a semicolon.", $1.str->c_str() );
1223 $$ = nullptr;
1224 }
1225 ;
1226
1227compound_statement:
1228 '{' '}'
1229 { $$ = new StatementNode( build_compound( yylloc, (StatementNode *)0 ) ); }
1230 | '{' push
1231 local_label_declaration_opt // GCC, local labels appear at start of block
1232 statement_decl_list // C99, intermix declarations and statements
1233 pop '}'
1234 { $$ = new StatementNode( build_compound( yylloc, $4 ) ); }
1235 ;
1236
1237statement_decl_list: // C99
1238 statement_decl
1239 | statement_decl_list statement_decl
1240 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1241 ;
1242
1243statement_decl:
1244 declaration // CFA, new & old style declarations
1245 { $$ = new StatementNode( $1 ); }
1246 | EXTENSION declaration // GCC
1247 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1248 | function_definition
1249 { $$ = new StatementNode( $1 ); }
1250 | EXTENSION function_definition // GCC
1251 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1252 | statement
1253 ;
1254
1255statement_list_nodecl:
1256 statement
1257 | statement_list_nodecl statement
1258 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1259 | statement_list_nodecl error // invalid syntax rule
1260 { SemanticError( yylloc, "syntax error, declarations only allowed at the start of the switch body,"
1261 " i.e., after the '{'." ); $$ = nullptr; }
1262 ;
1263
1264expression_statement:
1265 comma_expression_opt ';'
1266 { $$ = new StatementNode( build_expr( yylloc, $1 ) ); }
1267 ;
1268
1269// "if", "switch", and "choose" require parenthesis around the conditional. See the following ambiguities without
1270// parenthesis:
1271//
1272// if x + y + z; => if ( x ) + y + z or if ( x + y ) + z
1273//
1274// switch O { }
1275//
1276// O{} => object-constructor for conditional, switch body ???
1277// O{} => O for conditional followed by switch body
1278//
1279// C++ has this problem, as it has the same constructor syntax.
1280//
1281// switch sizeof ( T ) { }
1282//
1283// sizeof ( T ) => sizeof of T for conditional followed by switch body
1284// sizeof ( T ) => sizeof of compound literal (T){ }, closing parenthesis ???
1285//
1286// Note the two grammar rules for sizeof (alignof)
1287//
1288// | SIZEOF unary_expression
1289// | SIZEOF '(' type_no_function ')'
1290//
1291// where the first DOES NOT require parenthesis! And C++ inherits this problem from C.
1292
1293selection_statement:
1294 IF '(' conditional_declaration ')' statement %prec THEN
1295 // explicitly deal with the shift/reduce conflict on if/else
1296 { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), nullptr ) ); }
1297 | IF '(' conditional_declaration ')' statement ELSE statement
1298 { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), maybe_build_compound( yylloc, $7 ) ) ); }
1299 | SWITCH '(' comma_expression ')' case_clause
1300 { $$ = new StatementNode( build_switch( yylloc, true, $3, $5 ) ); }
1301 | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1302 {
1303 StatementNode *sw = new StatementNode( build_switch( yylloc, true, $3, $8 ) );
1304 // The semantics of the declaration list is changed to include associated initialization, which is performed
1305 // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1306 // statement around the switch. Statements after the initial declaration list can never be executed, and
1307 // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1308 // statement.
1309 $$ = $7 ? new StatementNode( build_compound( yylloc, (new StatementNode( $7 ))->set_last( sw ) ) ) : sw;
1310 }
1311 | SWITCH '(' comma_expression ')' '{' error '}' // CFA, invalid syntax rule error
1312 { SemanticError( yylloc, "synatx error, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1313 | CHOOSE '(' comma_expression ')' case_clause // CFA
1314 { $$ = new StatementNode( build_switch( yylloc, false, $3, $5 ) ); }
1315 | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1316 {
1317 StatementNode *sw = new StatementNode( build_switch( yylloc, false, $3, $8 ) );
1318 $$ = $7 ? new StatementNode( build_compound( yylloc, (new StatementNode( $7 ))->set_last( sw ) ) ) : sw;
1319 }
1320 | CHOOSE '(' comma_expression ')' '{' error '}' // CFA, invalid syntax rule
1321 { SemanticError( yylloc, "syntax error, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1322 ;
1323
1324conditional_declaration:
1325 comma_expression
1326 { $$ = new CondCtl( nullptr, $1 ); }
1327 | c_declaration // no semi-colon
1328 { $$ = new CondCtl( $1, nullptr ); }
1329 | cfa_declaration // no semi-colon
1330 { $$ = new CondCtl( $1, nullptr ); }
1331 | declaration comma_expression // semi-colon separated
1332 { $$ = new CondCtl( $1, $2 ); }
1333 ;
1334
1335// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1336// clause allows a list of values and subranges.
1337
1338case_value: // CFA
1339 constant_expression { $$ = $1; }
1340 | constant_expression ELLIPSIS constant_expression // GCC, subrange
1341 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1342 | subrange // CFA, subrange
1343 ;
1344
1345case_value_list: // CFA
1346 case_value { $$ = new ClauseNode( build_case( yylloc, $1 ) ); }
1347 // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1348 | case_value_list ',' case_value { $$ = $1->set_last( new ClauseNode( build_case( yylloc, $3 ) ) ); }
1349 ;
1350
1351case_label: // CFA
1352 CASE error // invalid syntax rule
1353 { SemanticError( yylloc, "syntax error, case list missing after case." ); $$ = nullptr; }
1354 | CASE case_value_list ':' { $$ = $2; }
1355 | CASE case_value_list error // invalid syntax rule
1356 { SemanticError( yylloc, "syntax error, colon missing after case list." ); $$ = nullptr; }
1357 | DEFAULT ':' { $$ = new ClauseNode( build_default( yylloc ) ); }
1358 // A semantic check is required to ensure only one default clause per switch/choose statement.
1359 | DEFAULT error // invalid syntax rule
1360 { SemanticError( yylloc, "syntax error, colon missing after default." ); $$ = nullptr; }
1361 ;
1362
1363case_label_list: // CFA
1364 case_label
1365 | case_label_list case_label { $$ = $1->set_last( $2 ); }
1366 ;
1367
1368case_clause: // CFA
1369 case_label_list statement { $$ = $1->append_last_case( maybe_build_compound( yylloc, $2 ) ); }
1370 ;
1371
1372switch_clause_list_opt: // CFA
1373 // empty
1374 { $$ = nullptr; }
1375 | switch_clause_list
1376 ;
1377
1378switch_clause_list: // CFA
1379 case_label_list statement_list_nodecl
1380 { $$ = $1->append_last_case( new StatementNode( build_compound( yylloc, $2 ) ) ); }
1381 | switch_clause_list case_label_list statement_list_nodecl
1382 { $$ = $1->set_last( $2->append_last_case( new StatementNode( build_compound( yylloc, $3 ) ) ) ); }
1383 ;
1384
1385iteration_statement:
1386 WHILE '(' ')' statement %prec THEN // CFA => while ( 1 )
1387 { $$ = new StatementNode( build_while( yylloc, new CondCtl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) ); }
1388 | WHILE '(' ')' statement ELSE statement // CFA
1389 {
1390 $$ = new StatementNode( build_while( yylloc, new CondCtl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) );
1391 SemanticWarning( yylloc, Warning::SuperfluousElse );
1392 }
1393 | WHILE '(' conditional_declaration ')' statement %prec THEN
1394 { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1395 | WHILE '(' conditional_declaration ')' statement ELSE statement // CFA
1396 { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1397 | DO statement WHILE '(' ')' ';' // CFA => do while( 1 )
1398 { $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) ); }
1399 | DO statement WHILE '(' ')' ELSE statement // CFA
1400 {
1401 $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) );
1402 SemanticWarning( yylloc, Warning::SuperfluousElse );
1403 }
1404 | DO statement WHILE '(' comma_expression ')' ';'
1405 { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ) ) ); }
1406 | DO statement WHILE '(' comma_expression ')' ELSE statement // CFA
1407 { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ), $8 ) ); }
1408 | FOR '(' ')' statement %prec THEN // CFA => for ( ;; )
1409 { $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) ); }
1410 | FOR '(' ')' statement ELSE statement // CFA
1411 {
1412 $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) );
1413 SemanticWarning( yylloc, Warning::SuperfluousElse );
1414 }
1415 | FOR '(' for_control_expression_list ')' statement %prec THEN
1416 { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1417 | FOR '(' for_control_expression_list ')' statement ELSE statement // CFA
1418 { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1419 ;
1420
1421for_control_expression_list:
1422 for_control_expression
1423 | for_control_expression_list ':' for_control_expression
1424 // ForCtrl + ForCtrl:
1425 // init + init => multiple declaration statements that are hoisted
1426 // condition + condition => (expression) && (expression)
1427 // change + change => (expression), (expression)
1428 {
1429 $1->init->set_last( $3->init );
1430 if ( $1->condition ) {
1431 if ( $3->condition ) {
1432 $1->condition->expr.reset( new ast::LogicalExpr( yylloc, $1->condition->expr.release(), $3->condition->expr.release(), ast::AndExpr ) );
1433 } // if
1434 } else $1->condition = $3->condition;
1435 if ( $1->change ) {
1436 if ( $3->change ) {
1437 $1->change->expr.reset( new ast::CommaExpr( yylloc, $1->change->expr.release(), $3->change->expr.release() ) );
1438 } // if
1439 } else $1->change = $3->change;
1440 $$ = $1;
1441 }
1442 ;
1443
1444for_control_expression:
1445 ';' comma_expression_opt ';' comma_expression_opt
1446 { $$ = new ForCtrl( nullptr, $2, $4 ); }
1447 | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1448 {
1449 StatementNode * init = $1 ? new StatementNode( new ast::ExprStmt( yylloc, maybeMoveBuild( $1 ) ) ) : nullptr;
1450 $$ = new ForCtrl( init, $3, $5 );
1451 }
1452 | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1453 { $$ = new ForCtrl( new StatementNode( $1 ), $2, $4 ); }
1454
1455 | '@' ';' comma_expression // CFA, empty loop-index
1456 { $$ = new ForCtrl( nullptr, $3, nullptr ); }
1457 | '@' ';' comma_expression ';' comma_expression // CFA, empty loop-index
1458 { $$ = new ForCtrl( nullptr, $3, $5 ); }
1459
1460 | comma_expression // CFA, anonymous loop-index
1461 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), NEW_ZERO, OperKinds::LThan, $1->clone(), NEW_ONE ); }
1462 | downupdowneq comma_expression // CFA, anonymous loop-index
1463 { $$ = forCtrl( yylloc, $2, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $1, NEW_ZERO, $2->clone() ), $1, UPDOWN( $1, $2->clone(), NEW_ZERO ), NEW_ONE ); }
1464
1465 | comma_expression updowneq comma_expression // CFA, anonymous loop-index
1466 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), NEW_ONE ); }
1467 | '@' updowneq comma_expression // CFA, anonymous loop-index
1468 {
1469 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1470 else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, NEW_ONE );
1471 }
1472 | comma_expression updowneq '@' // CFA, anonymous loop-index
1473 {
1474 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1475 else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1476 }
1477 | comma_expression updowneq comma_expression '~' comma_expression // CFA, anonymous loop-index
1478 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), $5 ); }
1479 | '@' updowneq comma_expression '~' comma_expression // CFA, anonymous loop-index
1480 {
1481 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1482 else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, $5 );
1483 }
1484 | comma_expression updowneq '@' '~' comma_expression // CFA, anonymous loop-index
1485 {
1486 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1487 else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1488 }
1489 | comma_expression updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1490 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1491 | '@' updowneq '@' // CFA, invalid syntax rule
1492 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1493 | '@' updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1494 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1495 | comma_expression updowneq '@' '~' '@' // CFA, invalid syntax rule
1496 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1497 | '@' updowneq '@' '~' '@' // CFA, invalid syntax rule
1498 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1499
1500 | comma_expression ';' comma_expression // CFA
1501 { $$ = forCtrl( yylloc, $3, $1, NEW_ZERO, OperKinds::LThan, $3->clone(), NEW_ONE ); }
1502 | comma_expression ';' downupdowneq comma_expression // CFA
1503 { $$ = forCtrl( yylloc, $4, $1, UPDOWN( $3, NEW_ZERO, $4->clone() ), $3, UPDOWN( $3, $4->clone(), NEW_ZERO ), NEW_ONE ); }
1504
1505 | comma_expression ';' comma_expression updowneq comma_expression // CFA
1506 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), NEW_ONE ); }
1507 | comma_expression ';' '@' updowneq comma_expression // CFA
1508 {
1509 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1510 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, NEW_ONE );
1511 }
1512 | comma_expression ';' comma_expression updowneq '@' // CFA
1513 {
1514 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1515 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1516 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, NEW_ONE );
1517 }
1518 | comma_expression ';' '@' updowneq '@' // CFA, invalid syntax rule
1519 { SemanticError( yylloc, "syntax error, missing low/high value for up/down-to range so index is uninitialized." ); $$ = nullptr; }
1520
1521 | comma_expression ';' comma_expression updowneq comma_expression '~' comma_expression // CFA
1522 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), $7 ); }
1523 | comma_expression ';' '@' updowneq comma_expression '~' comma_expression // CFA, invalid syntax rule
1524 {
1525 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1526 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, $7 );
1527 }
1528 | comma_expression ';' comma_expression updowneq '@' '~' comma_expression // CFA
1529 {
1530 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1531 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1532 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, $7 );
1533 }
1534 | comma_expression ';' comma_expression updowneq comma_expression '~' '@' // CFA
1535 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), nullptr ); }
1536 | comma_expression ';' '@' updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1537 {
1538 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1539 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, nullptr );
1540 }
1541 | comma_expression ';' comma_expression updowneq '@' '~' '@' // CFA
1542 {
1543 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1544 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1545 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, nullptr );
1546 }
1547 | comma_expression ';' '@' updowneq '@' '~' '@' // CFA
1548 { SemanticError( yylloc, "syntax error, missing low/high value for up/down-to range so index is uninitialized." ); $$ = nullptr; }
1549
1550 | declaration comma_expression // CFA
1551 { $$ = forCtrl( yylloc, $1, NEW_ZERO, OperKinds::LThan, $2, NEW_ONE ); }
1552 | declaration downupdowneq comma_expression // CFA
1553 { $$ = forCtrl( yylloc, $1, UPDOWN( $2, NEW_ZERO, $3 ), $2, UPDOWN( $2, $3->clone(), NEW_ZERO ), NEW_ONE ); }
1554
1555 | declaration comma_expression updowneq comma_expression // CFA
1556 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2->clone(), $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), NEW_ONE ); }
1557 | declaration '@' updowneq comma_expression // CFA
1558 {
1559 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1560 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, NEW_ONE );
1561 }
1562 | declaration comma_expression updowneq '@' // CFA
1563 {
1564 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1565 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1566 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, NEW_ONE );
1567 }
1568
1569 | declaration comma_expression updowneq comma_expression '~' comma_expression // CFA
1570 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), $6 ); }
1571 | declaration '@' updowneq comma_expression '~' comma_expression // CFA
1572 {
1573 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1574 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, $6 );
1575 }
1576 | declaration comma_expression updowneq '@' '~' comma_expression // CFA
1577 {
1578 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1579 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1580 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, $6 );
1581 }
1582 | declaration comma_expression updowneq comma_expression '~' '@' // CFA
1583 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), nullptr ); }
1584 | declaration '@' updowneq comma_expression '~' '@' // CFA
1585 {
1586 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1587 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, nullptr );
1588 }
1589 | declaration comma_expression updowneq '@' '~' '@' // CFA
1590 {
1591 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1592 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1593 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, nullptr );
1594 }
1595 | declaration '@' updowneq '@' '~' '@' // CFA, invalid syntax rule
1596 { SemanticError( yylloc, "syntax error, missing low/high value for up/down-to range so index is uninitialized." ); $$ = nullptr; }
1597
1598 | comma_expression ';' enum_key // CFA, enum type
1599 {
1600 SemanticError( yylloc, "Type iterator is currently unimplemented." ); $$ = nullptr;
1601 //$$ = forCtrl( new ExpressionNode( build_varref( $3 ) ), $1, nullptr, OperKinds::Range, nullptr, nullptr );
1602 }
1603 | comma_expression ';' downupdowneq enum_key // CFA, enum type, reverse direction
1604 {
1605 if ( $3 == OperKinds::LEThan || $3 == OperKinds::GEThan ) {
1606 SemanticError( yylloc, "syntax error, all enumeration ranges are equal (all values). Remove \"=~\"." ); $$ = nullptr;
1607 }
1608 SemanticError( yylloc, "Type iterator is currently unimplemented." ); $$ = nullptr;
1609 }
1610 ;
1611
1612enum_key:
1613 TYPEDEFname
1614 | ENUM TYPEDEFname
1615 ;
1616
1617downupdowneq:
1618 ErangeDown
1619 { $$ = OperKinds::GThan; }
1620 | ErangeUpEq
1621 { $$ = OperKinds::LEThan; }
1622 | ErangeDownEq
1623 { $$ = OperKinds::GEThan; }
1624 ;
1625
1626updown:
1627 '~'
1628 { $$ = OperKinds::LThan; }
1629 | ErangeDown
1630 { $$ = OperKinds::GThan; }
1631 ;
1632
1633updowneq:
1634 updown
1635 | ErangeUpEq
1636 { $$ = OperKinds::LEThan; }
1637 | ErangeDownEq
1638 { $$ = OperKinds::GEThan; }
1639 ;
1640
1641jump_statement:
1642 GOTO identifier_or_type_name ';'
1643 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Goto ) ); }
1644 | GOTO '*' comma_expression ';' // GCC, computed goto
1645 // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1646 // whereas normal operator precedence yields goto (*i)+3;
1647 { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1648 // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1649 | fall_through_name ';' // CFA
1650 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThrough ) ); }
1651 | fall_through_name identifier_or_type_name ';' // CFA
1652 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::FallThrough ) ); }
1653 | fall_through_name DEFAULT ';' // CFA
1654 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThroughDefault ) ); }
1655 | CONTINUE ';'
1656 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1657 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Continue ) ); }
1658 | CONTINUE identifier_or_type_name ';' // CFA, multi-level continue
1659 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1660 // the target of the transfer appears only at the start of an iteration statement.
1661 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Continue ) ); }
1662 | BREAK ';'
1663 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1664 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Break ) ); }
1665 | BREAK identifier_or_type_name ';' // CFA, multi-level exit
1666 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1667 // the target of the transfer appears only at the start of an iteration statement.
1668 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Break ) ); }
1669 | RETURN comma_expression_opt ';'
1670 { $$ = new StatementNode( build_return( yylloc, $2 ) ); }
1671 | RETURN '{' initializer_list_opt comma_opt '}' ';'
1672 { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1673 | SUSPEND ';'
1674 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::None ) ); }
1675 | SUSPEND compound_statement
1676 { $$ = new StatementNode( build_suspend( yylloc, $2, ast::SuspendStmt::None ) ); }
1677 | SUSPEND COROUTINE ';'
1678 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Coroutine ) ); }
1679 | SUSPEND COROUTINE compound_statement
1680 { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Coroutine ) ); }
1681 | SUSPEND GENERATOR ';'
1682 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Generator ) ); }
1683 | SUSPEND GENERATOR compound_statement
1684 { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Generator ) ); }
1685 | THROW assignment_expression_opt ';' // handles rethrow
1686 { $$ = new StatementNode( build_throw( yylloc, $2 ) ); }
1687 | THROWRESUME assignment_expression_opt ';' // handles reresume
1688 { $$ = new StatementNode( build_resume( yylloc, $2 ) ); }
1689 | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1690 { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1691 ;
1692
1693fall_through_name: // CFA
1694 FALLTHRU
1695 | FALLTHROUGH
1696 ;
1697
1698with_statement:
1699 WITH '(' tuple_expression_list ')' statement
1700 { $$ = new StatementNode( build_with( yylloc, $3, $5 ) ); }
1701 ;
1702
1703// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so possibly change syntax to "with mutex".
1704mutex_statement:
1705 MUTEX '(' argument_expression_list_opt ')' statement
1706 {
1707 if ( ! $3 ) { SemanticError( yylloc, "syntax error, mutex argument list cannot be empty." ); $$ = nullptr; }
1708 $$ = new StatementNode( build_mutex( yylloc, $3, $5 ) );
1709 }
1710 ;
1711
1712when_clause:
1713 WHEN '(' comma_expression ')' { $$ = $3; }
1714 ;
1715
1716when_clause_opt:
1717 // empty
1718 { $$ = nullptr; }
1719 | when_clause
1720 ;
1721
1722cast_expression_list:
1723 cast_expression
1724 | cast_expression_list ',' cast_expression
1725 { SemanticError( yylloc, "List of mutex member is currently unimplemented." ); $$ = nullptr; }
1726 ;
1727
1728timeout:
1729 TIMEOUT '(' comma_expression ')' { $$ = $3; }
1730 ;
1731
1732wor:
1733 OROR
1734 | WOR
1735
1736waitfor:
1737 WAITFOR '(' cast_expression ')'
1738 { $$ = $3; }
1739 | WAITFOR '(' cast_expression_list ':' argument_expression_list_opt ')'
1740 { $$ = $3->set_last( $5 ); }
1741 ;
1742
1743wor_waitfor_clause:
1744 when_clause_opt waitfor statement %prec THEN
1745 // Called first: create header for WaitForStmt.
1746 { $$ = build_waitfor( yylloc, new ast::WaitForStmt( yylloc ), $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1747 | wor_waitfor_clause wor when_clause_opt waitfor statement
1748 { $$ = build_waitfor( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1749 | wor_waitfor_clause wor when_clause_opt ELSE statement
1750 { $$ = build_waitfor_else( yylloc, $1, $3, maybe_build_compound( yylloc, $5 ) ); }
1751 | wor_waitfor_clause wor when_clause_opt timeout statement %prec THEN
1752 { $$ = build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1753 // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1754 | wor_waitfor_clause wor when_clause_opt timeout statement wor ELSE statement // invalid syntax rule
1755 { SemanticError( yylloc, "syntax error, else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1756 | wor_waitfor_clause wor when_clause_opt timeout statement wor when_clause ELSE statement
1757 { $$ = build_waitfor_else( yylloc, build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ), $7, maybe_build_compound( yylloc, $9 ) ); }
1758 ;
1759
1760waitfor_statement:
1761 wor_waitfor_clause %prec THEN
1762 { $$ = new StatementNode( $1 ); }
1763 ;
1764
1765wand:
1766 ANDAND
1767 | WAND
1768 ;
1769
1770waituntil:
1771 WAITUNTIL '(' comma_expression ')'
1772 { $$ = $3; }
1773 ;
1774
1775waituntil_clause:
1776 when_clause_opt waituntil statement
1777 { $$ = build_waituntil_clause( yylloc, $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1778 | '(' wor_waituntil_clause ')'
1779 { $$ = $2; }
1780 ;
1781
1782wand_waituntil_clause:
1783 waituntil_clause %prec THEN
1784 { $$ = $1; }
1785 | waituntil_clause wand wand_waituntil_clause
1786 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::AND, $1, $3 ); }
1787 ;
1788
1789wor_waituntil_clause:
1790 wand_waituntil_clause
1791 { $$ = $1; }
1792 | wor_waituntil_clause wor wand_waituntil_clause
1793 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::OR, $1, $3 ); }
1794 | wor_waituntil_clause wor when_clause_opt ELSE statement
1795 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::LEFT_OR, $1, build_waituntil_else( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1796 ;
1797
1798waituntil_statement:
1799 wor_waituntil_clause %prec THEN
1800 { $$ = new StatementNode( build_waituntil_stmt( yylloc, $1 ) ); }
1801 ;
1802
1803corun_statement:
1804 CORUN statement
1805 { $$ = new StatementNode( build_corun( yylloc, $2 ) ); }
1806 ;
1807
1808cofor_statement:
1809 COFOR '(' for_control_expression_list ')' statement
1810 { $$ = new StatementNode( build_cofor( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1811 ;
1812
1813exception_statement:
1814 TRY compound_statement handler_clause %prec THEN
1815 { $$ = new StatementNode( build_try( yylloc, $2, $3, nullptr ) ); }
1816 | TRY compound_statement finally_clause
1817 { $$ = new StatementNode( build_try( yylloc, $2, nullptr, $3 ) ); }
1818 | TRY compound_statement handler_clause finally_clause
1819 { $$ = new StatementNode( build_try( yylloc, $2, $3, $4 ) ); }
1820 ;
1821
1822handler_clause:
1823 handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1824 { $$ = new ClauseNode( build_catch( yylloc, $1, $4, $6, $8 ) ); }
1825 | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1826 { $$ = $1->set_last( new ClauseNode( build_catch( yylloc, $2, $5, $7, $9 ) ) ); }
1827 ;
1828
1829handler_predicate_opt:
1830 // empty
1831 { $$ = nullptr; }
1832 | ';' conditional_expression { $$ = $2; }
1833 ;
1834
1835handler_key:
1836 CATCH { $$ = ast::Terminate; }
1837 | RECOVER { $$ = ast::Terminate; }
1838 | CATCHRESUME { $$ = ast::Resume; }
1839 | FIXUP { $$ = ast::Resume; }
1840 ;
1841
1842finally_clause:
1843 FINALLY compound_statement { $$ = new ClauseNode( build_finally( yylloc, $2 ) ); }
1844 ;
1845
1846exception_declaration:
1847 // No SUE declaration in parameter list.
1848 type_specifier_nobody
1849 | type_specifier_nobody declarator
1850 { $$ = $2->addType( $1 ); }
1851 | type_specifier_nobody variable_abstract_declarator
1852 { $$ = $2->addType( $1 ); }
1853 | cfa_abstract_declarator_tuple identifier // CFA
1854 { $$ = $1->addName( $2 ); }
1855 | cfa_abstract_declarator_tuple // CFA
1856 ;
1857
1858enable_disable_statement:
1859 enable_disable_key identifier_list compound_statement
1860 ;
1861
1862enable_disable_key:
1863 ENABLE
1864 | DISABLE
1865 ;
1866
1867asm_statement:
1868 ASM asm_volatile_opt '(' string_literal ')' ';'
1869 { $$ = new StatementNode( build_asm( yylloc, $2, $4, nullptr ) ); }
1870 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1871 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6 ) ); }
1872 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1873 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8 ) ); }
1874 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1875 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8, $10 ) ); }
1876 | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1877 { $$ = new StatementNode( build_asm( yylloc, $2, $5, nullptr, $8, $10, $12 ) ); }
1878 ;
1879
1880asm_volatile_opt: // GCC
1881 // empty
1882 { $$ = false; }
1883 | VOLATILE
1884 { $$ = true; }
1885 ;
1886
1887asm_operands_opt: // GCC
1888 // empty
1889 { $$ = nullptr; } // use default argument
1890 | asm_operands_list
1891 ;
1892
1893asm_operands_list: // GCC
1894 asm_operand
1895 | asm_operands_list ',' asm_operand
1896 { $$ = $1->set_last( $3 ); }
1897 ;
1898
1899asm_operand: // GCC
1900 string_literal '(' constant_expression ')'
1901 { $$ = new ExpressionNode( new ast::AsmExpr( yylloc, "", maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1902 | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1903 {
1904 $$ = new ExpressionNode( new ast::AsmExpr( yylloc, *$2.str, maybeMoveBuild( $4 ), maybeMoveBuild( $6 ) ) );
1905 delete $2.str;
1906 }
1907 ;
1908
1909asm_clobbers_list_opt: // GCC
1910 // empty
1911 { $$ = nullptr; } // use default argument
1912 | string_literal
1913 { $$ = $1; }
1914 | asm_clobbers_list_opt ',' string_literal
1915 { $$ = $1->set_last( $3 ); }
1916 ;
1917
1918label_list:
1919 identifier
1920 {
1921 $$ = new LabelNode(); $$->labels.emplace_back( yylloc, *$1 );
1922 delete $1; // allocated by lexer
1923 }
1924 | label_list ',' identifier
1925 {
1926 $$ = $1; $1->labels.emplace_back( yylloc, *$3 );
1927 delete $3; // allocated by lexer
1928 }
1929 ;
1930
1931// ****************************** DECLARATIONS *********************************
1932
1933declaration_list_opt: // used at beginning of switch statement
1934 // empty
1935 { $$ = nullptr; }
1936 | declaration_list
1937 ;
1938
1939declaration_list:
1940 declaration
1941 | declaration_list declaration
1942 { $$ = $1->set_last( $2 ); }
1943 ;
1944
1945KR_parameter_list_opt: // used to declare parameter types in K&R style functions
1946 // empty
1947 { $$ = nullptr; }
1948 | KR_parameter_list
1949 ;
1950
1951KR_parameter_list:
1952 c_declaration ';'
1953 { $$ = $1; }
1954 | KR_parameter_list c_declaration ';'
1955 { $$ = $1->set_last( $2 ); }
1956 ;
1957
1958local_label_declaration_opt: // GCC, local label
1959 // empty
1960 | local_label_declaration_list
1961 ;
1962
1963local_label_declaration_list: // GCC, local label
1964 LABEL local_label_list ';'
1965 | local_label_declaration_list LABEL local_label_list ';'
1966 ;
1967
1968local_label_list: // GCC, local label
1969 identifier_or_type_name
1970 | local_label_list ',' identifier_or_type_name
1971 ;
1972
1973declaration: // old & new style declarations
1974 c_declaration ';'
1975 | cfa_declaration ';' // CFA
1976 | static_assert // C11
1977 ;
1978
1979static_assert:
1980 STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1981 { $$ = DeclarationNode::newStaticAssert( $3, maybeMoveBuild( $5 ) ); }
1982 | STATICASSERT '(' constant_expression ')' ';' // CFA
1983 { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( yylloc, *new string( "\"\"" ) ) ); }
1984
1985// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1986// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1987// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1988// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1989// the declaration list (as in Pascal). ANSI C and the new CFA declarations may appear together in the same program
1990// block, but cannot be mixed within a specific declaration.
1991//
1992// CFA C
1993// [10] int x; int x[10]; // array of 10 integers
1994// [10] * char y; char *y[10]; // array of 10 pointers to char
1995
1996cfa_declaration: // CFA
1997 cfa_variable_declaration
1998 | cfa_typedef_declaration
1999 | cfa_function_declaration
2000 | type_declaring_list
2001 { SemanticError( yylloc, "otype declaration is currently unimplemented." ); $$ = nullptr; }
2002 | trait_specifier
2003 ;
2004
2005cfa_variable_declaration: // CFA
2006 cfa_variable_specifier initializer_opt
2007 { $$ = $1->addInitializer( $2 ); }
2008 | declaration_qualifier_list cfa_variable_specifier initializer_opt
2009 // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
2010 // them as a type_qualifier cannot appear in that context.
2011 { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
2012 | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
2013 { $$ = $1->set_last( $1->cloneType( $5 )->addInitializer( $6 ) ); }
2014 ;
2015
2016cfa_variable_specifier: // CFA
2017 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
2018 // storage-class
2019 cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
2020 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
2021 | cfa_abstract_tuple identifier_or_type_name asm_name_opt
2022 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
2023 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
2024 { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
2025 ;
2026
2027cfa_function_declaration: // CFA
2028 cfa_function_specifier
2029 | type_qualifier_list cfa_function_specifier
2030 { $$ = $2->addQualifiers( $1 ); }
2031 | declaration_qualifier_list cfa_function_specifier
2032 { $$ = $2->addQualifiers( $1 ); }
2033 | declaration_qualifier_list type_qualifier_list cfa_function_specifier
2034 { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
2035 | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')'
2036 {
2037 // Append the return type at the start (left-hand-side) to each identifier in the list.
2038 DeclarationNode * ret = new DeclarationNode;
2039 ret->type = maybeCopy( $1->type->base );
2040 $$ = $1->set_last( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
2041 }
2042 ;
2043
2044cfa_function_specifier: // CFA
2045 '[' ']' identifier '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2046 { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2047 | '[' ']' TYPEDEFname '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2048 { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2049 // | '[' ']' TYPEGENname '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2050 // { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2051
2052 // identifier_or_type_name must be broken apart because of the sequence:
2053 //
2054 // '[' ']' identifier_or_type_name '(' cfa_parameter_list_ellipsis_opt ')'
2055 // '[' ']' type_specifier
2056 //
2057 // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
2058 // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
2059 | cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2060 // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
2061 { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
2062 | cfa_function_return identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2063 { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
2064 ;
2065
2066cfa_function_return: // CFA
2067 '[' push cfa_parameter_list pop ']'
2068 { $$ = DeclarationNode::newTuple( $3 ); }
2069 | '[' push cfa_parameter_list ',' cfa_abstract_parameter_list pop ']'
2070 // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
2071 { $$ = DeclarationNode::newTuple( $3->set_last( $5 ) ); }
2072 ;
2073
2074cfa_typedef_declaration: // CFA
2075 TYPEDEF cfa_variable_specifier
2076 {
2077 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "cfa_typedef_declaration 1" );
2078 $$ = $2->addTypedef();
2079 }
2080 | TYPEDEF cfa_function_specifier
2081 {
2082 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "cfa_typedef_declaration 2" );
2083 $$ = $2->addTypedef();
2084 }
2085 | cfa_typedef_declaration ',' identifier
2086 {
2087 typedefTable.addToEnclosingScope( *$3, TYPEDEFname, "cfa_typedef_declaration 3" );
2088 $$ = $1->set_last( $1->cloneType( $3 ) );
2089 }
2090 ;
2091
2092// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
2093// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
2094
2095typedef_declaration:
2096 TYPEDEF type_specifier declarator
2097 {
2098 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "typedef_declaration 1" );
2099 if ( $2->type->forall || ($2->type->kind == TypeData::Aggregate && $2->type->aggregate.params) ) {
2100 SemanticError( yylloc, "forall qualifier in typedef is currently unimplemented." ); $$ = nullptr;
2101 } else $$ = $3->addType( $2 )->addTypedef(); // watchout frees $2 and $3
2102 }
2103 | typedef_declaration ',' declarator
2104 {
2105 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "typedef_declaration 2" );
2106 $$ = $1->set_last( $1->cloneBaseType( $3 )->addTypedef() );
2107 }
2108 | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
2109 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2110 | type_specifier TYPEDEF declarator
2111 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2112 | type_specifier TYPEDEF type_qualifier_list declarator
2113 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2114 ;
2115
2116typedef_expression:
2117 // deprecated GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
2118 TYPEDEF identifier '=' assignment_expression
2119 {
2120 SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
2121 }
2122 | typedef_expression ',' identifier '=' assignment_expression
2123 {
2124 SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
2125 }
2126 ;
2127
2128c_declaration:
2129 declaration_specifier declaring_list
2130 { $$ = distAttr( $1, $2 ); }
2131 | typedef_declaration
2132 | typedef_expression // deprecated GCC, naming expression type
2133 | sue_declaration_specifier
2134 {
2135 assert( $1->type );
2136 if ( $1->type->qualifiers.any() ) { // CV qualifiers ?
2137 SemanticError( yylloc, "syntax error, useless type qualifier(s) in empty declaration." ); $$ = nullptr;
2138 }
2139 // enums are never empty declarations because there must have at least one enumeration.
2140 if ( $1->type->kind == TypeData::AggregateInst && $1->storageClasses.any() ) { // storage class ?
2141 SemanticError( yylloc, "syntax error, useless storage qualifier(s) in empty aggregate declaration." ); $$ = nullptr;
2142 }
2143 }
2144 ;
2145
2146declaring_list:
2147 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
2148 // storage-class
2149 variable_declarator asm_name_opt initializer_opt
2150 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2151 | variable_type_redeclarator asm_name_opt initializer_opt
2152 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2153
2154 | general_function_declarator asm_name_opt
2155 { $$ = $1->addAsmName( $2 )->addInitializer( nullptr ); }
2156 | general_function_declarator asm_name_opt '=' VOID
2157 { $$ = $1->addAsmName( $2 )->addInitializer( new InitializerNode( true ) ); }
2158
2159 | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
2160 { $$ = $1->set_last( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
2161 ;
2162
2163general_function_declarator:
2164 function_type_redeclarator
2165 | function_declarator
2166 ;
2167
2168declaration_specifier: // type specifier + storage class
2169 basic_declaration_specifier
2170 | type_declaration_specifier
2171 | sue_declaration_specifier
2172 | sue_declaration_specifier invalid_types // invalid syntax rule
2173 {
2174 SemanticError( yylloc, "syntax error, expecting ';' at end of \"%s\" declaration.",
2175 ast::AggregateDecl::aggrString( $1->type->aggregate.kind ) );
2176 $$ = nullptr;
2177 }
2178 ;
2179
2180invalid_types:
2181 aggregate_key
2182 | basic_type_name
2183 | indirect_type
2184 ;
2185
2186declaration_specifier_nobody: // type specifier + storage class - {...}
2187 // Preclude SUE declarations in restricted scopes:
2188 //
2189 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2190 //
2191 // because it is impossible to call f due to name equivalence.
2192 basic_declaration_specifier
2193 | sue_declaration_specifier_nobody
2194 | type_declaration_specifier
2195 ;
2196
2197type_specifier: // type specifier
2198 basic_type_specifier
2199 | sue_type_specifier
2200 | type_type_specifier
2201 ;
2202
2203type_specifier_nobody: // type specifier - {...}
2204 // Preclude SUE declarations in restricted scopes:
2205 //
2206 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2207 //
2208 // because it is impossible to call f due to name equivalence.
2209 basic_type_specifier
2210 | sue_type_specifier_nobody
2211 | type_type_specifier
2212 ;
2213
2214type_qualifier_list_opt: // GCC, used in asm_statement
2215 // empty
2216 { $$ = nullptr; }
2217 | type_qualifier_list
2218 ;
2219
2220type_qualifier_list:
2221 // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
2222 //
2223 // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
2224 // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
2225 // appeared only once.
2226 type_qualifier
2227 | type_qualifier_list type_qualifier
2228 { $$ = $1->addQualifiers( $2 ); }
2229 ;
2230
2231type_qualifier:
2232 type_qualifier_name
2233 { $$ = DeclarationNode::newFromTypeData( $1 ); }
2234 | attribute // trick handles most attribute locations
2235 ;
2236
2237type_qualifier_name:
2238 CONST
2239 { $$ = build_type_qualifier( ast::CV::Const ); }
2240 | RESTRICT
2241 { $$ = build_type_qualifier( ast::CV::Restrict ); }
2242 | VOLATILE
2243 { $$ = build_type_qualifier( ast::CV::Volatile ); }
2244 | ATOMIC
2245 { $$ = build_type_qualifier( ast::CV::Atomic ); }
2246
2247 // forall is a CV qualifier because it can appear in places where SC qualifiers are disallowed.
2248 //
2249 // void foo( forall( T ) T (*)( T ) ); // forward declaration
2250 // void bar( static int ); // static disallowed (gcc/CFA)
2251 | forall
2252 { $$ = build_forall( $1 ); }
2253 ;
2254
2255forall:
2256 FORALL '(' type_parameter_list ')' // CFA
2257 { $$ = $3; }
2258 ;
2259
2260declaration_qualifier_list:
2261 storage_class_list
2262 | type_qualifier_list storage_class_list // remaining OBSOLESCENT (see 2 )
2263 { $$ = $1->addQualifiers( $2 ); }
2264 | declaration_qualifier_list type_qualifier_list storage_class_list
2265 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2266 ;
2267
2268storage_class_list:
2269 // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
2270 // only one of each is specified, except for inline, which can appear with the others.
2271 //
2272 // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
2273 // specifiers in a declaration.
2274 storage_class
2275 | storage_class_list storage_class
2276 { $$ = $1->addQualifiers( $2 ); }
2277 ;
2278
2279storage_class:
2280 EXTERN
2281 { $$ = DeclarationNode::newStorageClass( ast::Storage::Extern ); }
2282 | STATIC
2283 { $$ = DeclarationNode::newStorageClass( ast::Storage::Static ); }
2284 | AUTO
2285 { $$ = DeclarationNode::newStorageClass( ast::Storage::Auto ); }
2286 | REGISTER
2287 { $$ = DeclarationNode::newStorageClass( ast::Storage::Register ); }
2288 | THREADLOCALGCC // GCC
2289 { $$ = DeclarationNode::newStorageClass( ast::Storage::ThreadLocalGcc ); }
2290 | THREADLOCALC11 // C11
2291 { $$ = DeclarationNode::newStorageClass( ast::Storage::ThreadLocalC11 ); }
2292 // Put function specifiers here to simplify parsing rules, but separate them semantically.
2293 | INLINE // C99
2294 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Inline ); }
2295 | FORTRAN // C99
2296 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Fortran ); }
2297 | NORETURN // C11
2298 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Noreturn ); }
2299 ;
2300
2301basic_type_name:
2302 basic_type_name_type
2303 { $$ = DeclarationNode::newFromTypeData( $1 ); }
2304 ;
2305
2306// Just an intermediate value for conversion.
2307basic_type_name_type:
2308 VOID
2309 { $$ = build_basic_type( TypeData::Void ); }
2310 | BOOL // C99
2311 { $$ = build_basic_type( TypeData::Bool ); }
2312 | CHAR
2313 { $$ = build_basic_type( TypeData::Char ); }
2314 | INT
2315 { $$ = build_basic_type( TypeData::Int ); }
2316 | INT128
2317 { $$ = build_basic_type( TypeData::Int128 ); }
2318 | UINT128
2319 { $$ = addType( build_basic_type( TypeData::Int128 ), build_signedness( TypeData::Unsigned ) ); }
2320 | FLOAT
2321 { $$ = build_basic_type( TypeData::Float ); }
2322 | DOUBLE
2323 { $$ = build_basic_type( TypeData::Double ); }
2324 | uuFLOAT80
2325 { $$ = build_basic_type( TypeData::uuFloat80 ); }
2326 | uuFLOAT128
2327 { $$ = build_basic_type( TypeData::uuFloat128 ); }
2328 | uFLOAT16
2329 { $$ = build_basic_type( TypeData::uFloat16 ); }
2330 | uFLOAT32
2331 { $$ = build_basic_type( TypeData::uFloat32 ); }
2332 | uFLOAT32X
2333 { $$ = build_basic_type( TypeData::uFloat32x ); }
2334 | uFLOAT64
2335 { $$ = build_basic_type( TypeData::uFloat64 ); }
2336 | uFLOAT64X
2337 { $$ = build_basic_type( TypeData::uFloat64x ); }
2338 | uFLOAT128
2339 { $$ = build_basic_type( TypeData::uFloat128 ); }
2340 | DECIMAL32
2341 { SemanticError( yylloc, "_Decimal32 is currently unimplemented." ); $$ = nullptr; }
2342 | DECIMAL64
2343 { SemanticError( yylloc, "_Decimal64 is currently unimplemented." ); $$ = nullptr; }
2344 | DECIMAL128
2345 { SemanticError( yylloc, "_Decimal128 is currently unimplemented." ); $$ = nullptr; }
2346 | COMPLEX // C99
2347 { $$ = build_complex_type( TypeData::Complex ); }
2348 | IMAGINARY // C99
2349 { $$ = build_complex_type( TypeData::Imaginary ); }
2350 | SIGNED
2351 { $$ = build_signedness( TypeData::Signed ); }
2352 | UNSIGNED
2353 { $$ = build_signedness( TypeData::Unsigned ); }
2354 | SHORT
2355 { $$ = build_length( TypeData::Short ); }
2356 | LONG
2357 { $$ = build_length( TypeData::Long ); }
2358 | VA_LIST // GCC, __builtin_va_list
2359 { $$ = build_builtin_type( TypeData::Valist ); }
2360 | AUTO_TYPE
2361 { $$ = build_builtin_type( TypeData::AutoType ); }
2362 | vtable
2363 ;
2364
2365vtable_opt:
2366 // empty
2367 { $$ = nullptr; }
2368 | vtable
2369 ;
2370
2371vtable:
2372 VTABLE '(' type_name ')' default_opt
2373 { $$ = build_vtable_type( $3 ); }
2374 ;
2375
2376default_opt:
2377 // empty
2378 { $$ = nullptr; }
2379 | DEFAULT
2380 { SemanticError( yylloc, "vtable default is currently unimplemented." ); $$ = nullptr; }
2381 ;
2382
2383basic_declaration_specifier:
2384 // A semantic check is necessary for conflicting storage classes.
2385 basic_type_specifier
2386 | declaration_qualifier_list basic_type_specifier
2387 { $$ = $2->addQualifiers( $1 ); }
2388 | basic_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2389 { $$ = $1->addQualifiers( $2 ); }
2390 | basic_declaration_specifier storage_class type_qualifier_list
2391 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2392 | basic_declaration_specifier storage_class basic_type_specifier
2393 { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
2394 ;
2395
2396basic_type_specifier:
2397 direct_type
2398 // Cannot have type modifiers, e.g., short, long, etc.
2399 | type_qualifier_list_opt indirect_type type_qualifier_list_opt
2400 { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
2401 ;
2402
2403direct_type:
2404 basic_type_name
2405 | type_qualifier_list basic_type_name
2406 { $$ = $2->addQualifiers( $1 ); }
2407 | direct_type type_qualifier
2408 { $$ = $1->addQualifiers( $2 ); }
2409 | direct_type basic_type_name
2410 { $$ = $1->addType( $2 ); }
2411 ;
2412
2413indirect_type:
2414 TYPEOF '(' type ')' // GCC: typeof( x ) y;
2415 { $$ = $3; }
2416 | TYPEOF '(' comma_expression ')' // GCC: typeof( a+b ) y;
2417 { $$ = DeclarationNode::newTypeof( $3 ); }
2418 | BASETYPEOF '(' type ')' // CFA: basetypeof( x ) y;
2419 { $$ = DeclarationNode::newTypeof( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ), true ); }
2420 | BASETYPEOF '(' comma_expression ')' // CFA: basetypeof( a+b ) y;
2421 { $$ = DeclarationNode::newTypeof( $3, true ); }
2422 | ZERO_T // CFA
2423 { $$ = DeclarationNode::newFromTypeData( build_builtin_type( TypeData::Zero ) ); }
2424 | ONE_T // CFA
2425 { $$ = DeclarationNode::newFromTypeData( build_builtin_type( TypeData::One ) ); }
2426 ;
2427
2428sue_declaration_specifier: // struct, union, enum + storage class + type specifier
2429 sue_type_specifier
2430 | declaration_qualifier_list sue_type_specifier
2431 { $$ = $2->addQualifiers( $1 ); }
2432 | sue_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2433 { $$ = $1->addQualifiers( $2 ); }
2434 | sue_declaration_specifier storage_class type_qualifier_list
2435 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2436 ;
2437
2438sue_type_specifier: // struct, union, enum + type specifier
2439 elaborated_type
2440 | type_qualifier_list
2441 { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
2442 elaborated_type
2443 { $$ = $3->addQualifiers( $1 ); }
2444 | sue_type_specifier type_qualifier
2445 {
2446 if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
2447 $$ = $1->addQualifiers( $2 );
2448 }
2449 ;
2450
2451sue_declaration_specifier_nobody: // struct, union, enum - {...} + storage class + type specifier
2452 sue_type_specifier_nobody
2453 | declaration_qualifier_list sue_type_specifier_nobody
2454 { $$ = $2->addQualifiers( $1 ); }
2455 | sue_declaration_specifier_nobody storage_class // remaining OBSOLESCENT (see 2)
2456 { $$ = $1->addQualifiers( $2 ); }
2457 | sue_declaration_specifier_nobody storage_class type_qualifier_list
2458 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2459 ;
2460
2461sue_type_specifier_nobody: // struct, union, enum - {...} + type specifier
2462 elaborated_type_nobody
2463 | type_qualifier_list elaborated_type_nobody
2464 { $$ = $2->addQualifiers( $1 ); }
2465 | sue_type_specifier_nobody type_qualifier
2466 { $$ = $1->addQualifiers( $2 ); }
2467 ;
2468
2469type_declaration_specifier:
2470 type_type_specifier
2471 | declaration_qualifier_list type_type_specifier
2472 { $$ = $2->addQualifiers( $1 ); }
2473 | type_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2474 { $$ = $1->addQualifiers( $2 ); }
2475 | type_declaration_specifier storage_class type_qualifier_list
2476 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2477 ;
2478
2479type_type_specifier: // typedef types
2480 type_name
2481 { $$ = DeclarationNode::newFromTypeData( $1 ); }
2482 | type_qualifier_list type_name
2483 { $$ = DeclarationNode::newFromTypeData( $2 )->addQualifiers( $1 ); }
2484 | type_type_specifier type_qualifier
2485 { $$ = $1->addQualifiers( $2 ); }
2486 ;
2487
2488type_name:
2489 TYPEDEFname
2490 { $$ = build_typedef( $1 ); }
2491 | '.' TYPEDEFname
2492 { $$ = build_qualified_type( build_global_scope(), build_typedef( $2 ) ); }
2493 | type_name '.' TYPEDEFname
2494 { $$ = build_qualified_type( $1, build_typedef( $3 ) ); }
2495 | typegen_name
2496 | '.' typegen_name
2497 { $$ = build_qualified_type( build_global_scope(), $2 ); }
2498 | type_name '.' typegen_name
2499 { $$ = build_qualified_type( $1, $3 ); }
2500 ;
2501
2502typegen_name: // CFA
2503 TYPEGENname
2504 { $$ = build_type_gen( $1, nullptr ); }
2505 | TYPEGENname '(' ')'
2506 { $$ = build_type_gen( $1, nullptr ); }
2507 | TYPEGENname '(' type_list ')'
2508 { $$ = build_type_gen( $1, $3 ); }
2509 ;
2510
2511elaborated_type: // struct, union, enum
2512 aggregate_type
2513 | enum_type
2514 ;
2515
2516elaborated_type_nobody: // struct, union, enum - {...}
2517 aggregate_type_nobody
2518 | enum_type_nobody
2519 ;
2520
2521// ************************** AGGREGATE *******************************
2522
2523aggregate_type: // struct, union
2524 aggregate_key attribute_list_opt
2525 { forall = false; } // reset
2526 '{' field_declaration_list_opt '}' type_parameters_opt
2527 { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2528 | aggregate_key attribute_list_opt identifier
2529 {
2530 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 1" );
2531 forall = false; // reset
2532 }
2533 '{' field_declaration_list_opt '}' type_parameters_opt
2534 {
2535 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2536 }
2537 | aggregate_key attribute_list_opt TYPEDEFname // unqualified type name
2538 {
2539 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 2" );
2540 forall = false; // reset
2541 }
2542 '{' field_declaration_list_opt '}' type_parameters_opt
2543 {
2544 DeclarationNode::newFromTypeData( build_typedef( $3 ) );
2545 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2546 }
2547 | aggregate_key attribute_list_opt TYPEGENname // unqualified type name
2548 {
2549 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 3" );
2550 forall = false; // reset
2551 }
2552 '{' field_declaration_list_opt '}' type_parameters_opt
2553 {
2554 DeclarationNode::newFromTypeData( build_type_gen( $3, nullptr ) );
2555 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2556 }
2557 | aggregate_type_nobody
2558 ;
2559
2560type_parameters_opt:
2561 // empty
2562 { $$ = nullptr; } %prec '}'
2563 | '(' type_list ')'
2564 { $$ = $2; }
2565 ;
2566
2567aggregate_type_nobody: // struct, union - {...}
2568 aggregate_key attribute_list_opt identifier
2569 {
2570 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type_nobody" );
2571 forall = false; // reset
2572 $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2573 }
2574 | aggregate_key attribute_list_opt type_name
2575 {
2576 forall = false; // reset
2577 // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2578 // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2579 // delete newFromTypeGen.
2580 if ( $3->kind == TypeData::SymbolicInst && ! $3->symbolic.isTypedef ) {
2581 $$ = DeclarationNode::newFromTypeData( $3 )->addQualifiers( $2 );
2582 } else {
2583 $$ = DeclarationNode::newAggregate( $1, $3->symbolic.name, $3->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2584 $3->symbolic.name = nullptr; // copied to $$
2585 $3->symbolic.actuals = nullptr;
2586 delete $3;
2587 }
2588 }
2589 ;
2590
2591aggregate_key:
2592 aggregate_data
2593 | aggregate_control
2594 ;
2595
2596aggregate_data:
2597 STRUCT vtable_opt
2598 { $$ = ast::AggregateDecl::Struct; }
2599 | UNION
2600 { $$ = ast::AggregateDecl::Union; }
2601 | EXCEPTION // CFA
2602 { $$ = ast::AggregateDecl::Exception; }
2603 ;
2604
2605aggregate_control: // CFA
2606 MONITOR
2607 { $$ = ast::AggregateDecl::Monitor; }
2608 | MUTEX STRUCT
2609 { $$ = ast::AggregateDecl::Monitor; }
2610 | GENERATOR
2611 { $$ = ast::AggregateDecl::Generator; }
2612 | MUTEX GENERATOR
2613 {
2614 SemanticError( yylloc, "monitor generator is currently unimplemented." );
2615 $$ = ast::AggregateDecl::NoAggregate;
2616 }
2617 | COROUTINE
2618 { $$ = ast::AggregateDecl::Coroutine; }
2619 | MUTEX COROUTINE
2620 {
2621 SemanticError( yylloc, "monitor coroutine is currently unimplemented." );
2622 $$ = ast::AggregateDecl::NoAggregate;
2623 }
2624 | THREAD
2625 { $$ = ast::AggregateDecl::Thread; }
2626 | MUTEX THREAD
2627 {
2628 SemanticError( yylloc, "monitor thread is currently unimplemented." );
2629 $$ = ast::AggregateDecl::NoAggregate;
2630 }
2631 ;
2632
2633field_declaration_list_opt:
2634 // empty
2635 { $$ = nullptr; }
2636 | field_declaration_list_opt field_declaration
2637 { $$ = $1 ? $1->set_last( $2 ) : $2; }
2638 ;
2639
2640field_declaration:
2641 type_specifier field_declaring_list_opt ';'
2642 {
2643 // printf( "type_specifier1 %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2644 $$ = fieldDecl( $1, $2 );
2645 // printf( "type_specifier2 %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2646 // for ( Attribute * attr: reverseIterate( $$->attributes ) ) {
2647 // printf( "\tattr %s\n", attr->name.c_str() );
2648 // } // for
2649 }
2650 | type_specifier field_declaring_list_opt '}' // invalid syntax rule
2651 {
2652 SemanticError( yylloc, "syntax error, expecting ';' at end of previous declaration." );
2653 $$ = nullptr;
2654 }
2655 | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2656 { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2657 | STATIC type_specifier field_declaring_list_opt ';' // CFA
2658 { SemanticError( yylloc, "STATIC aggregate field qualifier currently unimplemented." ); $$ = nullptr; }
2659 | INLINE type_specifier field_abstract_list_opt ';' // CFA
2660 {
2661 if ( ! $3 ) { // field declarator ?
2662 $3 = DeclarationNode::newName( nullptr );
2663 } // if
2664 $3->inLine = true;
2665 $$ = distAttr( $2, $3 ); // mark all fields in list
2666 distInl( $3 );
2667 }
2668 | INLINE aggregate_control ';' // CFA
2669 { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2670 | typedef_declaration ';' // CFA
2671 | cfa_field_declaring_list ';' // CFA, new style field declaration
2672 | EXTENSION cfa_field_declaring_list ';' // GCC
2673 { distExt( $2 ); $$ = $2; } // mark all fields in list
2674 | INLINE cfa_field_abstract_list ';' // CFA, new style field declaration
2675 { $$ = $2; } // mark all fields in list
2676 | cfa_typedef_declaration ';' // CFA
2677 | static_assert // C11
2678 ;
2679
2680field_declaring_list_opt:
2681 // empty
2682 { $$ = nullptr; }
2683 | field_declarator
2684 | field_declaring_list_opt ',' attribute_list_opt field_declarator
2685 { $$ = $1->set_last( $4->addQualifiers( $3 ) ); }
2686 ;
2687
2688field_declarator:
2689 bit_subrange_size // C special case, no field name
2690 { $$ = DeclarationNode::newBitfield( $1 ); }
2691 | variable_declarator bit_subrange_size_opt
2692 // A semantic check is required to ensure bit_subrange only appears on integral types.
2693 { $$ = $1->addBitfield( $2 ); }
2694 | variable_type_redeclarator bit_subrange_size_opt
2695 // A semantic check is required to ensure bit_subrange only appears on integral types.
2696 { $$ = $1->addBitfield( $2 ); }
2697 | function_type_redeclarator bit_subrange_size_opt
2698 // A semantic check is required to ensure bit_subrange only appears on integral types.
2699 { $$ = $1->addBitfield( $2 ); }
2700 ;
2701
2702field_abstract_list_opt:
2703 // empty
2704 { $$ = nullptr; }
2705 | field_abstract
2706 | field_abstract_list_opt ',' attribute_list_opt field_abstract
2707 { $$ = $1->set_last( $4->addQualifiers( $3 ) ); }
2708 ;
2709
2710field_abstract:
2711 // no bit fields
2712 variable_abstract_declarator
2713 ;
2714
2715cfa_field_declaring_list: // CFA, new style field declaration
2716 // bit-fields are handled by C declarations
2717 cfa_abstract_declarator_tuple identifier_or_type_name
2718 { $$ = $1->addName( $2 ); }
2719 | cfa_field_declaring_list ',' identifier_or_type_name
2720 { $$ = $1->set_last( $1->cloneType( $3 ) ); }
2721 ;
2722
2723cfa_field_abstract_list: // CFA, new style field declaration
2724 // bit-fields are handled by C declarations
2725 cfa_abstract_declarator_tuple
2726 | cfa_field_abstract_list ','
2727 { $$ = $1->set_last( $1->cloneType( 0 ) ); }
2728 ;
2729
2730bit_subrange_size_opt:
2731 // empty
2732 { $$ = nullptr; }
2733 | bit_subrange_size
2734 ;
2735
2736bit_subrange_size:
2737 ':' assignment_expression
2738 { $$ = $2; }
2739 ;
2740
2741// ************************** ENUMERATION *******************************
2742
2743enum_type:
2744 // anonymous, no type name
2745 ENUM attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2746 {
2747 if ( $3 == EnumHiding::Hide ) {
2748 SemanticError( yylloc, "syntax error, hiding ('!') the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr;
2749 } // if
2750 $$ = DeclarationNode::newEnum( nullptr, $5, true, false )->addQualifiers( $2 );
2751 }
2752 | ENUM enumerator_type attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2753 {
2754 if ( $2 && ($2->storageClasses.val != 0 || $2->type->qualifiers.any()) ) {
2755 SemanticError( yylloc, "syntax error, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2756 }
2757 if ( $4 == EnumHiding::Hide ) {
2758 SemanticError( yylloc, "syntax error, hiding ('!') the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr;
2759 } // if
2760 $$ = DeclarationNode::newEnum( nullptr, $6, true, true, $2 )->addQualifiers( $3 );
2761 }
2762
2763 // named type
2764 | ENUM attribute_list_opt identifier
2765 { typedefTable.makeTypedef( *$3, "enum_type 1" ); }
2766 hide_opt '{' enumerator_list comma_opt '}'
2767 { $$ = DeclarationNode::newEnum( $3, $7, true, false, nullptr, $5 )->addQualifiers( $2 ); }
2768 | ENUM attribute_list_opt typedef_name hide_opt '{' enumerator_list comma_opt '}' // unqualified type name
2769 { $$ = DeclarationNode::newEnum( $3->name, $6, true, false, nullptr, $4 )->addQualifiers( $2 ); }
2770 | ENUM enumerator_type attribute_list_opt identifier attribute_list_opt
2771 {
2772 if ( $2 && ($2->storageClasses.any() || $2->type->qualifiers.val != 0) ) {
2773 SemanticError( yylloc, "syntax error, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2774 }
2775 typedefTable.makeTypedef( *$4, "enum_type 2" );
2776 }
2777 hide_opt '{' enumerator_list comma_opt '}'
2778 { $$ = DeclarationNode::newEnum( $4, $9, true, true, $2, $7 )->addQualifiers( $3 )->addQualifiers( $5 ); }
2779 | ENUM enumerator_type attribute_list_opt typedef_name attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2780 { $$ = DeclarationNode::newEnum( $4->name, $8, true, true, $2, $6 )->addQualifiers( $3 )->addQualifiers( $5 ); }
2781
2782 // forward declaration
2783 | enum_type_nobody
2784 ;
2785
2786enumerator_type:
2787 '(' ')' // pure enumeration
2788 { $$ = nullptr; }
2789 | '(' cfa_abstract_parameter_declaration ')' // typed enumeration
2790 { $$ = $2; }
2791 ;
2792
2793hide_opt:
2794 // empty
2795 { $$ = EnumHiding::Visible; }
2796 | '!'
2797 { $$ = EnumHiding::Hide; }
2798 ;
2799
2800enum_type_nobody: // enum - {...}
2801 ENUM attribute_list_opt identifier
2802 {
2803 typedefTable.makeTypedef( *$3, "enum_type_nobody 1" );
2804 $$ = DeclarationNode::newEnum( $3, nullptr, false, false )->addQualifiers( $2 );
2805 }
2806 | ENUM attribute_list_opt type_name
2807 {
2808 typedefTable.makeTypedef( *$3->symbolic.name, "enum_type_nobody 2" );
2809 $$ = DeclarationNode::newEnum( $3->symbolic.name, nullptr, false, false )->addQualifiers( $2 );
2810 }
2811 ;
2812
2813enumerator_list:
2814 visible_hide_opt identifier_or_type_name enumerator_value_opt
2815 { $$ = DeclarationNode::newEnumValueGeneric( $2, $3 ); }
2816 | INLINE type_name
2817 {
2818 $$ = DeclarationNode::newEnumInLine( $2->symbolic.name );
2819 $2->symbolic.name = nullptr;
2820 delete $2;
2821 }
2822 | enumerator_list ',' visible_hide_opt identifier_or_type_name enumerator_value_opt
2823 { $$ = $1->set_last( DeclarationNode::newEnumValueGeneric( $4, $5 ) ); }
2824 | enumerator_list ',' INLINE type_name enumerator_value_opt
2825 { $$ = $1->set_last( DeclarationNode::newEnumValueGeneric( new string("inline"), nullptr ) ); }
2826 ;
2827
2828visible_hide_opt:
2829 hide_opt
2830 | '^'
2831 { $$ = EnumHiding::Visible; }
2832 ;
2833
2834enumerator_value_opt:
2835 // empty
2836 { $$ = nullptr; }
2837 | '=' constant_expression { $$ = new InitializerNode( $2 ); }
2838 | '=' '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $3, true ); }
2839 // | simple_assignment_operator initializer
2840 // { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2841 ;
2842
2843// ************************** FUNCTION PARAMETERS *******************************
2844
2845parameter_list_ellipsis_opt:
2846 // empty
2847 { $$ = nullptr; }
2848 | ELLIPSIS
2849 { $$ = nullptr; }
2850 | parameter_list
2851 | parameter_list ',' ELLIPSIS
2852 { $$ = $1->addVarArgs(); }
2853 ;
2854
2855parameter_list: // abstract + real
2856 parameter_declaration
2857 | abstract_parameter_declaration
2858 | parameter_list ',' parameter_declaration
2859 { $$ = $1->set_last( $3 ); }
2860 | parameter_list ',' abstract_parameter_declaration
2861 { $$ = $1->set_last( $3 ); }
2862 ;
2863
2864cfa_parameter_list_ellipsis_opt: // CFA, abstract + real
2865 // empty
2866 { $$ = DeclarationNode::newFromTypeData( build_basic_type( TypeData::Void ) ); }
2867 | ELLIPSIS
2868 { $$ = nullptr; }
2869 | cfa_parameter_list
2870 | cfa_abstract_parameter_list
2871 | cfa_parameter_list ',' cfa_abstract_parameter_list
2872 { $$ = $1->set_last( $3 ); }
2873 | cfa_parameter_list ',' ELLIPSIS
2874 { $$ = $1->addVarArgs(); }
2875 | cfa_abstract_parameter_list ',' ELLIPSIS
2876 { $$ = $1->addVarArgs(); }
2877 ;
2878
2879cfa_parameter_list: // CFA
2880 // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2881 // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2882 cfa_parameter_declaration
2883 | cfa_abstract_parameter_list ',' cfa_parameter_declaration
2884 { $$ = $1->set_last( $3 ); }
2885 | cfa_parameter_list ',' cfa_parameter_declaration
2886 { $$ = $1->set_last( $3 ); }
2887 | cfa_parameter_list ',' cfa_abstract_parameter_list ',' cfa_parameter_declaration
2888 { $$ = $1->set_last( $3 )->set_last( $5 ); }
2889 ;
2890
2891cfa_abstract_parameter_list: // CFA, new & old style abstract
2892 cfa_abstract_parameter_declaration
2893 | cfa_abstract_parameter_list ',' cfa_abstract_parameter_declaration
2894 { $$ = $1->set_last( $3 ); }
2895 ;
2896
2897// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2898// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2899
2900parameter_declaration:
2901 // No SUE declaration in parameter list.
2902 declaration_specifier_nobody identifier_parameter_declarator default_initializer_opt
2903 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2904 | declaration_specifier_nobody type_parameter_redeclarator default_initializer_opt
2905 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2906 ;
2907
2908abstract_parameter_declaration:
2909 declaration_specifier_nobody default_initializer_opt
2910 { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2911 | declaration_specifier_nobody abstract_parameter_declarator default_initializer_opt
2912 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2913 ;
2914
2915cfa_parameter_declaration: // CFA, new & old style parameter declaration
2916 parameter_declaration
2917 | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initializer_opt
2918 { $$ = $1->addName( $2 ); }
2919 | cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2920 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2921 { $$ = $1->addName( $2 ); }
2922 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2923 { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2924 | cfa_function_specifier // int f( "int fp()" );
2925 ;
2926
2927cfa_abstract_parameter_declaration: // CFA, new & old style parameter declaration
2928 abstract_parameter_declaration
2929 | cfa_identifier_parameter_declarator_no_tuple
2930 | cfa_abstract_tuple
2931 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2932 | type_qualifier_list cfa_abstract_tuple
2933 { $$ = $2->addQualifiers( $1 ); }
2934 | cfa_abstract_function // int f( "int ()" );
2935 ;
2936
2937// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2938// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2939// identifiers. The ANSI-style parameter-list can redefine a typedef name.
2940
2941identifier_list: // K&R-style parameter list => no types
2942 identifier
2943 { $$ = DeclarationNode::newName( $1 ); }
2944 | identifier_list ',' identifier
2945 { $$ = $1->set_last( DeclarationNode::newName( $3 ) ); }
2946 ;
2947
2948identifier_or_type_name:
2949 identifier
2950 | TYPEDEFname
2951 | TYPEGENname
2952 ;
2953
2954type_no_function: // sizeof, alignof, cast (constructor)
2955 cfa_abstract_declarator_tuple // CFA
2956 | type_specifier // cannot be type_specifier_nobody, e.g., (struct S {}){} is a thing
2957 | type_specifier abstract_declarator
2958 { $$ = $2->addType( $1 ); }
2959 ;
2960
2961type: // typeof, assertion
2962 type_no_function
2963 | cfa_abstract_function // CFA
2964 ;
2965
2966initializer_opt:
2967 // empty
2968 { $$ = nullptr; }
2969 | simple_assignment_operator initializer { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2970 | '=' VOID { $$ = new InitializerNode( true ); }
2971 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
2972 ;
2973
2974initializer:
2975 assignment_expression { $$ = new InitializerNode( $1 ); }
2976 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
2977 ;
2978
2979initializer_list_opt:
2980 // empty
2981 { $$ = nullptr; }
2982 | initializer
2983 | designation initializer { $$ = $2->set_designators( $1 ); }
2984 | initializer_list_opt ',' initializer { $$ = $1->set_last( $3 ); }
2985 | initializer_list_opt ',' designation initializer { $$ = $1->set_last( $4->set_designators( $3 ) ); }
2986 ;
2987
2988// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2989// '=' to separator the designator from the initializer value, as in:
2990//
2991// int x[10] = { [1] = 3 };
2992//
2993// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment. To disambiguate this case, CFA
2994// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2995// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2996// shift/reduce conflicts
2997
2998designation:
2999 designator_list ':' // C99, CFA uses ":" instead of "="
3000 | identifier_at ':' // GCC, field name
3001 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
3002 ;
3003
3004designator_list: // C99
3005 designator
3006 | designator_list designator
3007 { $$ = $1->set_last( $2 ); }
3008 //| designator_list designator { $$ = new ExpressionNode( $1, $2 ); }
3009 ;
3010
3011designator:
3012 '.' identifier_at // C99, field name
3013 { $$ = new ExpressionNode( build_varref( yylloc, $2 ) ); }
3014 | '[' push assignment_expression pop ']' // C99, single array element
3015 // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
3016 { $$ = $3; }
3017 | '[' push subrange pop ']' // CFA, multiple array elements
3018 { $$ = $3; }
3019 | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
3020 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $3 ), maybeMoveBuild( $5 ) ) ); }
3021 | '.' '[' push field_name_list pop ']' // CFA, tuple field selector
3022 { $$ = $4; }
3023 ;
3024
3025// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
3026// rather than an object-oriented type system. This required four groups of extensions:
3027//
3028// Overloading: function, data, and operator identifiers may be overloaded.
3029//
3030// Type declarations: "otype" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
3031// and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
3032// definitions of new types. Type declarations with storage class "extern" provide opaque types.
3033//
3034// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
3035// site. A polymorphic function is not a template; it is a function, with an address and a type.
3036//
3037// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
3038// types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
3039// hierarchies. Unlike classes, they can define relationships between types. Assertions declare that a type or
3040// types provide the operations declared by a specification. Assertions are normally used to declare requirements
3041// on type arguments of polymorphic functions.
3042
3043type_parameter_list: // CFA
3044 type_parameter
3045 | type_parameter_list ',' type_parameter
3046 { $$ = $1->set_last( $3 ); }
3047 ;
3048
3049type_initializer_opt: // CFA
3050 // empty
3051 { $$ = nullptr; }
3052 | '=' type
3053 { $$ = $2; }
3054 ;
3055
3056type_parameter: // CFA
3057 type_class identifier_or_type_name
3058 {
3059 typedefTable.addToScope( *$2, TYPEDEFname, "type_parameter 1" );
3060 if ( $1 == ast::TypeDecl::Otype ) { SemanticError( yylloc, "otype keyword is deprecated, use T " ); }
3061 if ( $1 == ast::TypeDecl::Dtype ) { SemanticError( yylloc, "dtype keyword is deprecated, use T &" ); }
3062 if ( $1 == ast::TypeDecl::Ttype ) { SemanticError( yylloc, "ttype keyword is deprecated, use T ..." ); }
3063 }
3064 type_initializer_opt assertion_list_opt
3065 { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
3066 | identifier_or_type_name new_type_class
3067 { typedefTable.addToScope( *$1, TYPEDEFname, "type_parameter 2" ); }
3068 type_initializer_opt assertion_list_opt
3069 { $$ = DeclarationNode::newTypeParam( $2, $1 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
3070 | '[' identifier_or_type_name ']'
3071 {
3072 typedefTable.addToScope( *$2, TYPEDIMname, "type_parameter 3" );
3073 $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dimension, $2 );
3074 }
3075 // | type_specifier identifier_parameter_declarator
3076 | assertion_list
3077 { $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
3078 | ENUM '(' identifier_or_type_name ')' identifier_or_type_name new_type_class type_initializer_opt assertion_list_opt
3079 {
3080 typedefTable.addToScope( *$3, TYPEDIMname, "type_parameter 4" );
3081 typedefTable.addToScope( *$5, TYPEDIMname, "type_parameter 5" );
3082 $$ = DeclarationNode::newTypeParam( $6, $5 )->addTypeInitializer( $7 )->addAssertions( $8 );
3083 }
3084 ;
3085
3086new_type_class: // CFA
3087 // empty
3088 { $$ = ast::TypeDecl::Otype; }
3089 | '&'
3090 { $$ = ast::TypeDecl::Dtype; }
3091 | '*'
3092 { $$ = ast::TypeDecl::DStype; } // Dtype + sized
3093 // | '(' '*' ')' // Gregor made me do it
3094 // { $$ = ast::TypeDecl::Ftype; }
3095 | ELLIPSIS
3096 { $$ = ast::TypeDecl::Ttype; }
3097 ;
3098
3099type_class: // CFA
3100 OTYPE
3101 { $$ = ast::TypeDecl::Otype; }
3102 | DTYPE
3103 { $$ = ast::TypeDecl::Dtype; }
3104 | FTYPE
3105 { $$ = ast::TypeDecl::Ftype; }
3106 | TTYPE
3107 { $$ = ast::TypeDecl::Ttype; }
3108 ;
3109
3110assertion_list_opt: // CFA
3111 // empty
3112 { $$ = nullptr; }
3113 | assertion_list
3114 ;
3115
3116assertion_list: // CFA
3117 assertion
3118 | assertion_list assertion
3119 { $$ = $1->set_last( $2 ); }
3120 ;
3121
3122assertion: // CFA
3123 '|' identifier_or_type_name '(' type_list ')'
3124 { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
3125 | '|' '{' push trait_declaration_list pop '}'
3126 { $$ = $4; }
3127 // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
3128 // { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
3129 ;
3130
3131type_list: // CFA
3132 type
3133 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3134 | assignment_expression
3135 | type_list ',' type
3136 { $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
3137 | type_list ',' assignment_expression
3138 { $$ = $1->set_last( $3 ); }
3139 ;
3140
3141type_declaring_list: // CFA
3142 OTYPE type_declarator
3143 { $$ = $2; }
3144 | storage_class_list OTYPE type_declarator
3145 { $$ = $3->addQualifiers( $1 ); }
3146 | type_declaring_list ',' type_declarator
3147 { $$ = $1->set_last( $3->copySpecifiers( $1 ) ); }
3148 ;
3149
3150type_declarator: // CFA
3151 type_declarator_name assertion_list_opt
3152 { $$ = $1->addAssertions( $2 ); }
3153 | type_declarator_name assertion_list_opt '=' type
3154 { $$ = $1->addAssertions( $2 )->addType( $4 ); }
3155 ;
3156
3157type_declarator_name: // CFA
3158 identifier_or_type_name
3159 {
3160 typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "type_declarator_name 1" );
3161 $$ = DeclarationNode::newTypeDecl( $1, nullptr );
3162 }
3163 | identifier_or_type_name '(' type_parameter_list ')'
3164 {
3165 typedefTable.addToEnclosingScope( *$1, TYPEGENname, "type_declarator_name 2" );
3166 $$ = DeclarationNode::newTypeDecl( $1, $3 );
3167 }
3168 ;
3169
3170trait_specifier: // CFA
3171 TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
3172 {
3173 SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3174 $$ = DeclarationNode::newTrait( $2, $4, nullptr );
3175 }
3176 | forall TRAIT identifier_or_type_name '{' '}' // alternate
3177 { $$ = DeclarationNode::newTrait( $3, $1, nullptr ); }
3178 | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
3179 {
3180 SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3181 $$ = DeclarationNode::newTrait( $2, $4, $8 );
3182 }
3183 | forall TRAIT identifier_or_type_name '{' push trait_declaration_list pop '}' // alternate
3184 { $$ = DeclarationNode::newTrait( $3, $1, $6 ); }
3185 ;
3186
3187trait_declaration_list: // CFA
3188 trait_declaration
3189 | trait_declaration_list pop push trait_declaration
3190 { $$ = $1->set_last( $4 ); }
3191 ;
3192
3193trait_declaration: // CFA
3194 cfa_trait_declaring_list ';'
3195 | trait_declaring_list ';'
3196 ;
3197
3198cfa_trait_declaring_list: // CFA
3199 cfa_variable_specifier
3200 | cfa_function_specifier
3201 | cfa_trait_declaring_list pop ',' push identifier_or_type_name
3202 { $$ = $1->set_last( $1->cloneType( $5 ) ); }
3203 ;
3204
3205trait_declaring_list: // CFA
3206 type_specifier declarator
3207 { $$ = $2->addType( $1 ); }
3208 | trait_declaring_list pop ',' push declarator
3209 { $$ = $1->set_last( $1->cloneBaseType( $5 ) ); }
3210 ;
3211
3212// **************************** EXTERNAL DEFINITIONS *****************************
3213
3214translation_unit:
3215 // empty, input file
3216 | external_definition_list
3217 { parseTree = parseTree ? parseTree->set_last( $1 ) : $1; }
3218 ;
3219
3220external_definition_list:
3221 push external_definition pop
3222 { $$ = $2; }
3223 | external_definition_list push external_definition pop
3224 { $$ = $1 ? $1->set_last( $3 ) : $3; }
3225 ;
3226
3227external_definition_list_opt:
3228 // empty
3229 { $$ = nullptr; }
3230 | external_definition_list
3231 ;
3232
3233up:
3234 { typedefTable.up( forall ); forall = false; }
3235 ;
3236
3237down:
3238 { typedefTable.down(); }
3239 ;
3240
3241external_definition:
3242 DIRECTIVE
3243 { $$ = DeclarationNode::newDirectiveStmt( new StatementNode( build_directive( yylloc, $1 ) ) ); }
3244 | declaration
3245 {
3246 // Variable declarations of anonymous types requires creating a unique type-name across multiple translation
3247 // unit, which is a dubious task, especially because C uses name rather than structural typing; hence it is
3248 // disallowed at the moment.
3249 if ( $1->linkage == ast::Linkage::Cforall && ! $1->storageClasses.is_static &&
3250 $1->type && $1->type->kind == TypeData::AggregateInst ) {
3251 if ( $1->type->aggInst.aggregate->aggregate.anon ) {
3252 SemanticError( yylloc, "extern anonymous aggregate is currently unimplemented." ); $$ = nullptr;
3253 }
3254 }
3255 }
3256 | IDENTIFIER IDENTIFIER
3257 { IdentifierBeforeIdentifier( *$1.str, *$2.str, " declaration" ); $$ = nullptr; }
3258 | IDENTIFIER type_qualifier // invalid syntax rule
3259 { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
3260 | IDENTIFIER storage_class // invalid syntax rule
3261 { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
3262 | IDENTIFIER basic_type_name // invalid syntax rule
3263 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3264 | IDENTIFIER TYPEDEFname // invalid syntax rule
3265 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3266 | IDENTIFIER TYPEGENname // invalid syntax rule
3267 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3268 | external_function_definition
3269 | EXTENSION external_definition // GCC, multiple __extension__ allowed, meaning unknown
3270 {
3271 distExt( $2 ); // mark all fields in list
3272 $$ = $2;
3273 }
3274 | ASM '(' string_literal ')' ';' // GCC, global assembler statement
3275 { $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( yylloc, false, $3, nullptr ) ) ); }
3276 | EXTERN STRINGliteral
3277 {
3278 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
3279 linkage = ast::Linkage::update( yylloc, linkage, $2 );
3280 }
3281 up external_definition down
3282 {
3283 linkage = linkageStack.top();
3284 linkageStack.pop();
3285 $$ = $5;
3286 }
3287 | EXTERN STRINGliteral // C++-style linkage specifier
3288 {
3289 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
3290 linkage = ast::Linkage::update( yylloc, linkage, $2 );
3291 }
3292 '{' up external_definition_list_opt down '}'
3293 {
3294 linkage = linkageStack.top();
3295 linkageStack.pop();
3296 $$ = $6;
3297 }
3298 // global distribution
3299 | type_qualifier_list
3300 {
3301 if ( $1->type->qualifiers.any() ) {
3302 SemanticError( yylloc, "syntax error, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3303 }
3304 if ( $1->type->forall ) forall = true; // remember generic type
3305 }
3306 '{' up external_definition_list_opt down '}' // CFA, namespace
3307 {
3308 distQual( $5, $1 );
3309 forall = false;
3310 $$ = $5;
3311 }
3312 | declaration_qualifier_list
3313 {
3314 if ( $1->type && $1->type->qualifiers.any() ) {
3315 SemanticError( yylloc, "syntax error, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3316 }
3317 if ( $1->type && $1->type->forall ) forall = true; // remember generic type
3318 }
3319 '{' up external_definition_list_opt down '}' // CFA, namespace
3320 {
3321 distQual( $5, $1 );
3322 forall = false;
3323 $$ = $5;
3324 }
3325 | declaration_qualifier_list type_qualifier_list
3326 {
3327 if ( ($1->type && $1->type->qualifiers.any()) || ($2->type && $2->type->qualifiers.any()) ) {
3328 SemanticError( yylloc, "syntax error, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3329 }
3330 if ( ($1->type && $1->type->forall) || ($2->type && $2->type->forall) ) forall = true; // remember generic type
3331 }
3332 '{' up external_definition_list_opt down '}' // CFA, namespace
3333 {
3334 distQual( $6, $1->addQualifiers( $2 ) );
3335 forall = false;
3336 $$ = $6;
3337 }
3338 ;
3339
3340external_function_definition:
3341 function_definition
3342 // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
3343 // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
3344 // Parsing is possible because function_definition does not appear in the context of an expression (nested
3345 // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
3346 // declaration must still have a type_specifier. OBSOLESCENT (see 1)
3347 | function_declarator compound_statement
3348 { $$ = $1->addFunctionBody( $2 ); }
3349 | KR_function_declarator KR_parameter_list_opt compound_statement
3350 { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
3351 ;
3352
3353with_clause_opt:
3354 // empty
3355 { $$ = nullptr; forall = false; }
3356 | WITH '(' tuple_expression_list ')' attribute_list_opt
3357 {
3358 $$ = $3; forall = false;
3359 if ( $5 ) {
3360 SemanticError( yylloc, "syntax error, attributes cannot be associated with function body. Move attribute(s) before \"with\" clause." );
3361 $$ = nullptr;
3362 } // if
3363 }
3364 ;
3365
3366function_definition:
3367 cfa_function_declaration with_clause_opt compound_statement // CFA
3368 {
3369 // Add the function body to the last identifier in the function definition list, i.e., foo3:
3370 // [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
3371 $1->get_last()->addFunctionBody( $3, $2 );
3372 $$ = $1;
3373 }
3374 | declaration_specifier function_declarator with_clause_opt compound_statement
3375 {
3376 rebindForall( $1, $2 );
3377 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3378 }
3379 | declaration_specifier function_type_redeclarator with_clause_opt compound_statement
3380 {
3381 rebindForall( $1, $2 );
3382 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3383 }
3384 // handles default int return type, OBSOLESCENT (see 1)
3385 | type_qualifier_list function_declarator with_clause_opt compound_statement
3386 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3387 // handles default int return type, OBSOLESCENT (see 1)
3388 | declaration_qualifier_list function_declarator with_clause_opt compound_statement
3389 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3390 // handles default int return type, OBSOLESCENT (see 1)
3391 | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
3392 { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3393
3394 // Old-style K&R function definition, OBSOLESCENT (see 4)
3395 | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3396 {
3397 rebindForall( $1, $2 );
3398 $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
3399 }
3400 // handles default int return type, OBSOLESCENT (see 1)
3401 | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3402 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3403 // handles default int return type, OBSOLESCENT (see 1)
3404 | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3405 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3406 // handles default int return type, OBSOLESCENT (see 1)
3407 | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3408 { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3409 ;
3410
3411declarator:
3412 variable_declarator
3413 | variable_type_redeclarator
3414 | function_declarator
3415 | function_type_redeclarator
3416 ;
3417
3418subrange:
3419 constant_expression '~' constant_expression // CFA, integer subrange
3420 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
3421 ;
3422
3423// **************************** ASM *****************************
3424
3425asm_name_opt: // GCC
3426 // empty
3427 { $$ = nullptr; }
3428 | ASM '(' string_literal ')' attribute_list_opt
3429 {
3430 DeclarationNode * name = new DeclarationNode();
3431 name->asmName = maybeMoveBuild( $3 );
3432 $$ = name->addQualifiers( $5 );
3433 }
3434 ;
3435
3436// **************************** ATTRIBUTE *****************************
3437
3438attribute_list_opt: // GCC
3439 // empty
3440 { $$ = nullptr; }
3441 | attribute_list
3442 ;
3443
3444attribute_list: // GCC
3445 attribute
3446 | attribute_list attribute
3447 { $$ = $2->addQualifiers( $1 ); }
3448 ;
3449
3450attribute: // GCC
3451 ATTRIBUTE '(' '(' attribute_name_list ')' ')'
3452 { $$ = $4; }
3453 | ATTRIBUTE '(' attribute_name_list ')' // CFA
3454 { $$ = $3; }
3455 | ATTR '(' attribute_name_list ')' // CFA
3456 { $$ = $3; }
3457 ;
3458
3459attribute_name_list: // GCC
3460 attribute_name
3461 | attribute_name_list ',' attribute_name
3462 { $$ = $3->addQualifiers( $1 ); }
3463 ;
3464
3465attribute_name: // GCC
3466 // empty
3467 { $$ = nullptr; }
3468 | attr_name
3469 { $$ = DeclarationNode::newAttribute( $1 ); }
3470 | attr_name '(' argument_expression_list_opt ')'
3471 { $$ = DeclarationNode::newAttribute( $1, $3 ); }
3472 ;
3473
3474attr_name: // GCC
3475 IDENTIFIER
3476 | quasi_keyword
3477 | TYPEDEFname
3478 | TYPEGENname
3479 | FALLTHROUGH
3480 { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
3481 | CONST
3482 { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
3483 ;
3484
3485// ============================================================================
3486// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
3487// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
3488// in:
3489//
3490// int (*f())[10] { ... };
3491// ... (*f())[3] += 1; // definition mimics usage
3492//
3493// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
3494// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
3495// ============================================================================
3496
3497// ----------------------------------------------------------------------------
3498// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
3499// to define a variable or function prototype, e.g.:
3500//
3501// valid declaration invalid definition
3502// ----------------- ------------------
3503// int f; int f {}
3504// int *f; int *f {}
3505// int f[10]; int f[10] {}
3506// int (*f)(int); int (*f)(int) {}
3507//
3508// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
3509// variable_declarator and function_declarator.
3510// ----------------------------------------------------------------------------
3511
3512// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
3513// declaring an array of functions versus a pointer to an array of functions.
3514
3515paren_identifier:
3516 identifier_at
3517 { $$ = DeclarationNode::newName( $1 ); }
3518 | '(' paren_identifier ')' // redundant parenthesis
3519 { $$ = $2; }
3520 ;
3521
3522variable_declarator:
3523 paren_identifier attribute_list_opt
3524 { $$ = $1->addQualifiers( $2 ); }
3525 | variable_ptr
3526 | variable_array attribute_list_opt
3527 { $$ = $1->addQualifiers( $2 ); }
3528 | variable_function attribute_list_opt
3529 { $$ = $1->addQualifiers( $2 ); }
3530 ;
3531
3532variable_ptr:
3533 ptrref_operator variable_declarator
3534 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3535 | ptrref_operator type_qualifier_list variable_declarator
3536 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3537 | '(' variable_ptr ')' attribute_list_opt // redundant parenthesis
3538 { $$ = $2->addQualifiers( $4 ); }
3539 | '(' attribute_list variable_ptr ')' attribute_list_opt // redundant parenthesis
3540 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3541 ;
3542
3543variable_array:
3544 paren_identifier array_dimension
3545 { $$ = $1->addArray( $2 ); }
3546 | '(' variable_ptr ')' array_dimension
3547 { $$ = $2->addArray( $4 ); }
3548 | '(' attribute_list variable_ptr ')' array_dimension
3549 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3550 | '(' variable_array ')' multi_array_dimension // redundant parenthesis
3551 { $$ = $2->addArray( $4 ); }
3552 | '(' attribute_list variable_array ')' multi_array_dimension // redundant parenthesis
3553 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3554 | '(' variable_array ')' // redundant parenthesis
3555 { $$ = $2; }
3556 | '(' attribute_list variable_array ')' // redundant parenthesis
3557 { $$ = $3->addQualifiers( $2 ); }
3558 ;
3559
3560variable_function:
3561 '(' variable_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3562 { $$ = $2->addParamList( $5 ); }
3563 | '(' attribute_list variable_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3564 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3565 | '(' variable_function ')' // redundant parenthesis
3566 { $$ = $2; }
3567 | '(' attribute_list variable_function ')' // redundant parenthesis
3568 { $$ = $3->addQualifiers( $2 ); }
3569 ;
3570
3571// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
3572// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
3573// is the same scope. The pattern precludes returning arrays and functions versus pointers to arrays and functions.
3574
3575function_declarator:
3576 function_no_ptr attribute_list_opt
3577 { $$ = $1->addQualifiers( $2 ); }
3578 | function_ptr
3579 | function_array attribute_list_opt
3580 { $$ = $1->addQualifiers( $2 ); }
3581 ;
3582
3583function_no_ptr:
3584 paren_identifier '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3585 { $$ = $1->addParamList( $3 ); }
3586 | '(' function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3587 { $$ = $2->addParamList( $5 ); }
3588 | '(' attribute_list function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3589 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3590 | '(' function_no_ptr ')' // redundant parenthesis
3591 { $$ = $2; }
3592 | '(' attribute_list function_no_ptr ')' // redundant parenthesis
3593 { $$ = $3->addQualifiers( $2 ); }
3594 ;
3595
3596function_ptr:
3597 ptrref_operator function_declarator
3598 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3599 | ptrref_operator type_qualifier_list function_declarator
3600 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3601 | '(' function_ptr ')' attribute_list_opt
3602 { $$ = $2->addQualifiers( $4 ); }
3603 | '(' attribute_list function_ptr ')' attribute_list_opt
3604 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3605 ;
3606
3607function_array:
3608 '(' function_ptr ')' array_dimension
3609 { $$ = $2->addArray( $4 ); }
3610 | '(' attribute_list function_ptr ')' array_dimension
3611 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3612 | '(' function_array ')' multi_array_dimension // redundant parenthesis
3613 { $$ = $2->addArray( $4 ); }
3614 | '(' attribute_list function_array ')' multi_array_dimension // redundant parenthesis
3615 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3616 | '(' function_array ')' // redundant parenthesis
3617 { $$ = $2; }
3618 | '(' attribute_list function_array ')' // redundant parenthesis
3619 { $$ = $3->addQualifiers( $2 ); }
3620 ;
3621
3622// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
3623//
3624// f( a, b, c ) int a, *b, c[]; {}
3625//
3626// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
3627// returning arrays and functions versus pointers to arrays and functions.
3628
3629KR_function_declarator:
3630 KR_function_no_ptr
3631 | KR_function_ptr
3632 | KR_function_array
3633 ;
3634
3635KR_function_no_ptr:
3636 paren_identifier '(' identifier_list ')' // function_declarator handles empty parameter
3637 { $$ = $1->addIdList( $3 ); }
3638 | '(' KR_function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3639 { $$ = $2->addParamList( $5 ); }
3640 | '(' attribute_list KR_function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3641 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3642 | '(' KR_function_no_ptr ')' // redundant parenthesis
3643 { $$ = $2; }
3644 | '(' attribute_list KR_function_no_ptr ')' // redundant parenthesis
3645 { $$ = $3->addQualifiers( $2 ); }
3646 ;
3647
3648KR_function_ptr:
3649 ptrref_operator KR_function_declarator
3650 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3651 | ptrref_operator type_qualifier_list KR_function_declarator
3652 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3653 | '(' KR_function_ptr ')'
3654 { $$ = $2; }
3655 | '(' attribute_list KR_function_ptr ')'
3656 { $$ = $3->addQualifiers( $2 ); }
3657 ;
3658
3659KR_function_array:
3660 '(' KR_function_ptr ')' array_dimension
3661 { $$ = $2->addArray( $4 ); }
3662 | '(' attribute_list KR_function_ptr ')' array_dimension
3663 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3664 | '(' KR_function_array ')' multi_array_dimension // redundant parenthesis
3665 { $$ = $2->addArray( $4 ); }
3666 | '(' attribute_list KR_function_array ')' multi_array_dimension // redundant parenthesis
3667 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3668 | '(' KR_function_array ')' // redundant parenthesis
3669 { $$ = $2; }
3670 | '(' attribute_list KR_function_array ')' // redundant parenthesis
3671 { $$ = $3->addQualifiers( $2 ); }
3672 ;
3673
3674// This pattern parses a declaration for a variable that redefines a type name, e.g.:
3675//
3676// typedef int foo;
3677// {
3678// int foo; // redefine typedef name in new scope
3679// }
3680
3681paren_type:
3682 typedef_name
3683 {
3684 // hide type name in enclosing scope by variable name
3685 typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "paren_type" );
3686 }
3687 | '(' paren_type ')'
3688 { $$ = $2; }
3689 ;
3690
3691variable_type_redeclarator:
3692 paren_type attribute_list_opt
3693 { $$ = $1->addQualifiers( $2 ); }
3694 | variable_type_ptr
3695 | variable_type_array attribute_list_opt
3696 { $$ = $1->addQualifiers( $2 ); }
3697 | variable_type_function attribute_list_opt
3698 { $$ = $1->addQualifiers( $2 ); }
3699 ;
3700
3701variable_type_ptr:
3702 ptrref_operator variable_type_redeclarator
3703 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3704 | ptrref_operator type_qualifier_list variable_type_redeclarator
3705 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3706 | '(' variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3707 { $$ = $2->addQualifiers( $4 ); }
3708 | '(' attribute_list variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3709 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3710 ;
3711
3712variable_type_array:
3713 paren_type array_dimension
3714 { $$ = $1->addArray( $2 ); }
3715 | '(' variable_type_ptr ')' array_dimension
3716 { $$ = $2->addArray( $4 ); }
3717 | '(' attribute_list variable_type_ptr ')' array_dimension
3718 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3719 | '(' variable_type_array ')' multi_array_dimension // redundant parenthesis
3720 { $$ = $2->addArray( $4 ); }
3721 | '(' attribute_list variable_type_array ')' multi_array_dimension // redundant parenthesis
3722 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3723 | '(' variable_type_array ')' // redundant parenthesis
3724 { $$ = $2; }
3725 | '(' attribute_list variable_type_array ')' // redundant parenthesis
3726 { $$ = $3->addQualifiers( $2 ); }
3727 ;
3728
3729variable_type_function:
3730 '(' variable_type_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3731 { $$ = $2->addParamList( $5 ); }
3732 | '(' attribute_list variable_type_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3733 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3734 | '(' variable_type_function ')' // redundant parenthesis
3735 { $$ = $2; }
3736 | '(' attribute_list variable_type_function ')' // redundant parenthesis
3737 { $$ = $3->addQualifiers( $2 ); }
3738 ;
3739
3740// This pattern parses a declaration for a function prototype that redefines a type name. It precludes declaring an
3741// array of functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to
3742// arrays and functions.
3743
3744function_type_redeclarator:
3745 function_type_no_ptr attribute_list_opt
3746 { $$ = $1->addQualifiers( $2 ); }
3747 | function_type_ptr
3748 | function_type_array attribute_list_opt
3749 { $$ = $1->addQualifiers( $2 ); }
3750 ;
3751
3752function_type_no_ptr:
3753 paren_type '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3754 { $$ = $1->addParamList( $3 ); }
3755 | '(' function_type_ptr ')' '(' parameter_list_ellipsis_opt ')'
3756 { $$ = $2->addParamList( $5 ); }
3757 | '(' attribute_list function_type_ptr ')' '(' parameter_list_ellipsis_opt ')'
3758 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3759 | '(' function_type_no_ptr ')' // redundant parenthesis
3760 { $$ = $2; }
3761 | '(' attribute_list function_type_no_ptr ')' // redundant parenthesis
3762 { $$ = $3->addQualifiers( $2 ); }
3763 ;
3764
3765function_type_ptr:
3766 ptrref_operator function_type_redeclarator
3767 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3768 | ptrref_operator type_qualifier_list function_type_redeclarator
3769 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3770 | '(' function_type_ptr ')' attribute_list_opt
3771 { $$ = $2->addQualifiers( $4 ); }
3772 | '(' attribute_list function_type_ptr ')' attribute_list_opt
3773 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3774 ;
3775
3776function_type_array:
3777 '(' function_type_ptr ')' array_dimension
3778 { $$ = $2->addArray( $4 ); }
3779 | '(' attribute_list function_type_ptr ')' array_dimension
3780 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3781 | '(' function_type_array ')' multi_array_dimension // redundant parenthesis
3782 { $$ = $2->addArray( $4 ); }
3783 | '(' attribute_list function_type_array ')' multi_array_dimension // redundant parenthesis
3784 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3785 | '(' function_type_array ')' // redundant parenthesis
3786 { $$ = $2; }
3787 | '(' attribute_list function_type_array ')' // redundant parenthesis
3788 { $$ = $3->addQualifiers( $2 ); }
3789 ;
3790
3791// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
3792// typedef name and allows the C99 array options, which can only appear in a parameter list. The pattern precludes
3793// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
3794// pointers to arrays and functions.
3795
3796identifier_parameter_declarator:
3797 paren_identifier attribute_list_opt
3798 { $$ = $1->addQualifiers( $2 ); }
3799 | '&' MUTEX paren_identifier attribute_list_opt
3800 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
3801 OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3802 | identifier_parameter_ptr
3803 | identifier_parameter_array attribute_list_opt
3804 { $$ = $1->addQualifiers( $2 ); }
3805 | identifier_parameter_function attribute_list_opt
3806 { $$ = $1->addQualifiers( $2 ); }
3807 ;
3808
3809identifier_parameter_ptr:
3810 ptrref_operator identifier_parameter_declarator
3811 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3812 | ptrref_operator type_qualifier_list identifier_parameter_declarator
3813 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3814 | '(' identifier_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3815 { $$ = $2->addQualifiers( $4 ); }
3816 ;
3817
3818identifier_parameter_array:
3819 paren_identifier array_parameter_dimension
3820 { $$ = $1->addArray( $2 ); }
3821 | '(' identifier_parameter_ptr ')' array_dimension
3822 { $$ = $2->addArray( $4 ); }
3823 | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3824 { $$ = $2->addArray( $4 ); }
3825 | '(' identifier_parameter_array ')' // redundant parenthesis
3826 { $$ = $2; }
3827 ;
3828
3829identifier_parameter_function:
3830 paren_identifier '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3831 { $$ = $1->addParamList( $3 ); }
3832 | '(' identifier_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3833 { $$ = $2->addParamList( $5 ); }
3834 | '(' identifier_parameter_function ')' // redundant parenthesis
3835 { $$ = $2; }
3836 ;
3837
3838// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3839// e.g.:
3840//
3841// typedef int foo;
3842// forall( otype T ) struct foo;
3843// int f( int foo ); // redefine typedef name in new scope
3844//
3845// and allows the C99 array options, which can only appear in a parameter list.
3846
3847type_parameter_redeclarator:
3848 typedef_name attribute_list_opt
3849 { $$ = $1->addQualifiers( $2 ); }
3850 | '&' MUTEX typedef_name attribute_list_opt
3851 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
3852 OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3853 | type_parameter_ptr
3854 | type_parameter_array attribute_list_opt
3855 { $$ = $1->addQualifiers( $2 ); }
3856 | type_parameter_function attribute_list_opt
3857 { $$ = $1->addQualifiers( $2 ); }
3858 ;
3859
3860typedef_name:
3861 TYPEDEFname
3862 { $$ = DeclarationNode::newName( $1 ); }
3863 | TYPEGENname
3864 { $$ = DeclarationNode::newName( $1 ); }
3865 ;
3866
3867type_parameter_ptr:
3868 ptrref_operator type_parameter_redeclarator
3869 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3870 | ptrref_operator type_qualifier_list type_parameter_redeclarator
3871 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3872 | '(' type_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3873 { $$ = $2->addQualifiers( $4 ); }
3874 ;
3875
3876type_parameter_array:
3877 typedef_name array_parameter_dimension
3878 { $$ = $1->addArray( $2 ); }
3879 | '(' type_parameter_ptr ')' array_parameter_dimension
3880 { $$ = $2->addArray( $4 ); }
3881 ;
3882
3883type_parameter_function:
3884 typedef_name '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3885 { $$ = $1->addParamList( $3 ); }
3886 | '(' type_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3887 { $$ = $2->addParamList( $5 ); }
3888 ;
3889
3890// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3891// which the type applies, e.g.:
3892//
3893// sizeof( int );
3894// sizeof( int * );
3895// sizeof( int [10] );
3896// sizeof( int (*)() );
3897// sizeof( int () );
3898//
3899// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3900// and functions versus pointers to arrays and functions.
3901
3902abstract_declarator:
3903 abstract_ptr
3904 | abstract_array attribute_list_opt
3905 { $$ = $1->addQualifiers( $2 ); }
3906 | abstract_function attribute_list_opt
3907 { $$ = $1->addQualifiers( $2 ); }
3908 ;
3909
3910abstract_ptr:
3911 ptrref_operator
3912 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3913 | ptrref_operator type_qualifier_list
3914 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3915 | ptrref_operator abstract_declarator
3916 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3917 | ptrref_operator type_qualifier_list abstract_declarator
3918 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3919 | '(' abstract_ptr ')' attribute_list_opt
3920 { $$ = $2->addQualifiers( $4 ); }
3921 ;
3922
3923abstract_array:
3924 array_dimension
3925 | '(' abstract_ptr ')' array_dimension
3926 { $$ = $2->addArray( $4 ); }
3927 | '(' abstract_array ')' multi_array_dimension // redundant parenthesis
3928 { $$ = $2->addArray( $4 ); }
3929 | '(' abstract_array ')' // redundant parenthesis
3930 { $$ = $2; }
3931 ;
3932
3933abstract_function:
3934 '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3935 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
3936 | '(' abstract_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3937 { $$ = $2->addParamList( $5 ); }
3938 | '(' abstract_function ')' // redundant parenthesis
3939 { $$ = $2; }
3940 ;
3941
3942array_dimension:
3943 // Only the first dimension can be empty.
3944 '[' ']'
3945 { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
3946 | '[' ']' multi_array_dimension
3947 { $$ = DeclarationNode::newArray( nullptr, nullptr, false )->addArray( $3 ); }
3948 // Cannot use constant_expression because of tuples => semantic check
3949 | '[' push assignment_expression pop ',' comma_expression ']' // CFA
3950 { $$ = DeclarationNode::newArray( $3, nullptr, false )->addArray( DeclarationNode::newArray( $6, nullptr, false ) ); }
3951 // { SemanticError( yylloc, "New array dimension is currently unimplemented." ); $$ = nullptr; }
3952
3953 // If needed, the following parses and does not use comma_expression, so the array structure can be built.
3954 // | '[' push assignment_expression pop ',' push array_dimension_list pop ']' // CFA
3955
3956 | '[' push array_type_list pop ']' // CFA
3957 { $$ = DeclarationNode::newArray( $3, nullptr, false ); }
3958 | multi_array_dimension
3959 ;
3960
3961// array_dimension_list:
3962// assignment_expression
3963// | array_dimension_list ',' assignment_expression
3964// ;
3965
3966array_type_list:
3967 basic_type_name
3968 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3969 | type_name
3970 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3971 | assignment_expression upupeq assignment_expression
3972 | array_type_list ',' basic_type_name
3973 { $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
3974 | array_type_list ',' type_name
3975 { $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
3976 | array_type_list ',' assignment_expression upupeq assignment_expression
3977 ;
3978
3979upupeq:
3980 '~'
3981 { $$ = OperKinds::LThan; }
3982 | ErangeUpEq
3983 { $$ = OperKinds::LEThan; }
3984 ;
3985
3986multi_array_dimension:
3987 '[' push assignment_expression pop ']'
3988 { $$ = DeclarationNode::newArray( $3, nullptr, false ); }
3989 | '[' push '*' pop ']' // C99
3990 { $$ = DeclarationNode::newVarArray( 0 ); }
3991 | multi_array_dimension '[' push assignment_expression pop ']'
3992 { $$ = $1->addArray( DeclarationNode::newArray( $4, nullptr, false ) ); }
3993 | multi_array_dimension '[' push '*' pop ']' // C99
3994 { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3995 ;
3996
3997// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3998// identifier to which the type applies, e.g.:
3999//
4000// int f( int ); // not handled here
4001// int f( int * ); // abstract function-prototype parameter; no parameter name specified
4002// int f( int (*)() ); // abstract function-prototype parameter; no parameter name specified
4003// int f( int (int) ); // abstract function-prototype parameter; no parameter name specified
4004//
4005// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
4006// and functions versus pointers to arrays and functions. In addition, the pattern handles the
4007// special meaning of parenthesis around a typedef name:
4008//
4009// ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
4010// parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
4011// not as redundant parentheses around the identifier."
4012//
4013// For example:
4014//
4015// typedef float T;
4016// int f( int ( T [5] ) ); // see abstract_parameter_declarator
4017// int g( int ( T ( int ) ) ); // see abstract_parameter_declarator
4018// int f( int f1( T a[5] ) ); // see identifier_parameter_declarator
4019// int g( int g1( T g2( int p ) ) ); // see identifier_parameter_declarator
4020//
4021// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
4022// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
4023// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
4024// functions.
4025
4026abstract_parameter_declarator_opt:
4027 // empty
4028 { $$ = nullptr; }
4029 | abstract_parameter_declarator
4030 ;
4031
4032abstract_parameter_declarator:
4033 abstract_parameter_ptr
4034 | '&' MUTEX attribute_list_opt
4035 { $$ = DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
4036 OperKinds::AddressOf )->addQualifiers( $3 ); }
4037 | abstract_parameter_array attribute_list_opt
4038 { $$ = $1->addQualifiers( $2 ); }
4039 | abstract_parameter_function attribute_list_opt
4040 { $$ = $1->addQualifiers( $2 ); }
4041 ;
4042
4043abstract_parameter_ptr:
4044 ptrref_operator
4045 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
4046 | ptrref_operator type_qualifier_list
4047 { $$ = DeclarationNode::newPointer( $2, $1 ); }
4048 | ptrref_operator abstract_parameter_declarator
4049 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4050 | ptrref_operator type_qualifier_list abstract_parameter_declarator
4051 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4052 | '(' abstract_parameter_ptr ')' attribute_list_opt // redundant parenthesis
4053 { $$ = $2->addQualifiers( $4 ); }
4054 ;
4055
4056abstract_parameter_array:
4057 array_parameter_dimension
4058 | '(' abstract_parameter_ptr ')' array_parameter_dimension
4059 { $$ = $2->addArray( $4 ); }
4060 | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
4061 { $$ = $2->addArray( $4 ); }
4062 | '(' abstract_parameter_array ')' // redundant parenthesis
4063 { $$ = $2; }
4064 ;
4065
4066abstract_parameter_function:
4067 '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4068 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
4069 | '(' abstract_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4070 { $$ = $2->addParamList( $5 ); }
4071 | '(' abstract_parameter_function ')' // redundant parenthesis
4072 { $$ = $2; }
4073 ;
4074
4075array_parameter_dimension:
4076 // Only the first dimension can be empty or have qualifiers.
4077 array_parameter_1st_dimension
4078 | array_parameter_1st_dimension multi_array_dimension
4079 { $$ = $1->addArray( $2 ); }
4080 | multi_array_dimension
4081 ;
4082
4083// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
4084//
4085// ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
4086// a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
4087
4088array_parameter_1st_dimension:
4089 '[' ']'
4090 { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
4091 // multi_array_dimension handles the '[' '*' ']' case
4092 | '[' push type_qualifier_list '*' pop ']' // remaining C99
4093 { $$ = DeclarationNode::newVarArray( $3 ); }
4094 | '[' push type_qualifier_list pop ']'
4095 { $$ = DeclarationNode::newArray( nullptr, $3, false ); }
4096 // multi_array_dimension handles the '[' assignment_expression ']' case
4097 | '[' push type_qualifier_list assignment_expression pop ']'
4098 { $$ = DeclarationNode::newArray( $4, $3, false ); }
4099 | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
4100 { $$ = DeclarationNode::newArray( $5, $4, true ); }
4101 | '[' push type_qualifier_list STATIC assignment_expression pop ']'
4102 { $$ = DeclarationNode::newArray( $5, $3, true ); }
4103 ;
4104
4105// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
4106//
4107// struct S {
4108// int;
4109// int *;
4110// int [10];
4111// int (*)();
4112// };
4113
4114variable_abstract_declarator:
4115 variable_abstract_ptr
4116 | variable_abstract_array attribute_list_opt
4117 { $$ = $1->addQualifiers( $2 ); }
4118 | variable_abstract_function attribute_list_opt
4119 { $$ = $1->addQualifiers( $2 ); }
4120 ;
4121
4122variable_abstract_ptr:
4123 ptrref_operator
4124 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
4125 | ptrref_operator type_qualifier_list
4126 { $$ = DeclarationNode::newPointer( $2, $1 ); }
4127 | ptrref_operator variable_abstract_declarator
4128 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4129 | ptrref_operator type_qualifier_list variable_abstract_declarator
4130 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4131 | '(' variable_abstract_ptr ')' attribute_list_opt // redundant parenthesis
4132 { $$ = $2->addQualifiers( $4 ); }
4133 ;
4134
4135variable_abstract_array:
4136 array_dimension
4137 | '(' variable_abstract_ptr ')' array_dimension
4138 { $$ = $2->addArray( $4 ); }
4139 | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
4140 { $$ = $2->addArray( $4 ); }
4141 | '(' variable_abstract_array ')' // redundant parenthesis
4142 { $$ = $2; }
4143 ;
4144
4145variable_abstract_function:
4146 '(' variable_abstract_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4147 { $$ = $2->addParamList( $5 ); }
4148 | '(' variable_abstract_function ')' // redundant parenthesis
4149 { $$ = $2; }
4150 ;
4151
4152// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
4153// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
4154
4155cfa_identifier_parameter_declarator_tuple: // CFA
4156 cfa_identifier_parameter_declarator_no_tuple
4157 | cfa_abstract_tuple
4158 | type_qualifier_list cfa_abstract_tuple
4159 { $$ = $2->addQualifiers( $1 ); }
4160 ;
4161
4162cfa_identifier_parameter_declarator_no_tuple: // CFA
4163 cfa_identifier_parameter_ptr
4164 | cfa_identifier_parameter_array
4165 ;
4166
4167cfa_identifier_parameter_ptr: // CFA
4168 // No SUE declaration in parameter list.
4169 ptrref_operator type_specifier_nobody
4170 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4171 | type_qualifier_list ptrref_operator type_specifier_nobody
4172 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4173 | ptrref_operator cfa_abstract_function
4174 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4175 | type_qualifier_list ptrref_operator cfa_abstract_function
4176 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4177 | ptrref_operator cfa_identifier_parameter_declarator_tuple
4178 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4179 | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
4180 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4181 ;
4182
4183cfa_identifier_parameter_array: // CFA
4184 // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
4185 // shift/reduce conflict with new-style empty (void) function return type.
4186 '[' ']' type_specifier_nobody
4187 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4188 | cfa_array_parameter_1st_dimension type_specifier_nobody
4189 { $$ = $2->addNewArray( $1 ); }
4190 | '[' ']' multi_array_dimension type_specifier_nobody
4191 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4192 | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
4193 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4194 | multi_array_dimension type_specifier_nobody
4195 { $$ = $2->addNewArray( $1 ); }
4196
4197 | '[' ']' cfa_identifier_parameter_ptr
4198 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4199 | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
4200 { $$ = $2->addNewArray( $1 ); }
4201 | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
4202 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4203 | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
4204 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4205 | multi_array_dimension cfa_identifier_parameter_ptr
4206 { $$ = $2->addNewArray( $1 ); }
4207 ;
4208
4209cfa_array_parameter_1st_dimension:
4210 '[' push type_qualifier_list '*' pop ']' // remaining C99
4211 { $$ = DeclarationNode::newVarArray( $3 ); }
4212 | '[' push type_qualifier_list assignment_expression pop ']'
4213 { $$ = DeclarationNode::newArray( $4, $3, false ); }
4214 | '[' push declaration_qualifier_list assignment_expression pop ']'
4215 // declaration_qualifier_list must be used because of shift/reduce conflict with
4216 // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
4217 // appear in this context.
4218 { $$ = DeclarationNode::newArray( $4, $3, true ); }
4219 | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
4220 { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
4221 ;
4222
4223// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
4224// identifier to which the type applies, e.g.:
4225//
4226// [int] f( int ); // abstract variable parameter; no parameter name specified
4227// [int] f( [int] (int) ); // abstract function-prototype parameter; no parameter name specified
4228//
4229// These rules need LR(3):
4230//
4231// cfa_abstract_tuple identifier_or_type_name
4232// '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_list_ellipsis_opt ')'
4233//
4234// since a function return type can be syntactically identical to a tuple type:
4235//
4236// [int, int] t;
4237// [int, int] f( int );
4238//
4239// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
4240// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
4241// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
4242// duplicated when appearing with cfa_function_specifier.
4243
4244cfa_abstract_declarator_tuple: // CFA
4245 cfa_abstract_tuple
4246 | type_qualifier_list cfa_abstract_tuple
4247 { $$ = $2->addQualifiers( $1 ); }
4248 | cfa_abstract_declarator_no_tuple
4249 ;
4250
4251cfa_abstract_declarator_no_tuple: // CFA
4252 cfa_abstract_ptr
4253 | cfa_abstract_array
4254 ;
4255
4256cfa_abstract_ptr: // CFA
4257 ptrref_operator type_specifier
4258 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4259 | type_qualifier_list ptrref_operator type_specifier
4260 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4261 | ptrref_operator cfa_abstract_function
4262 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4263 | type_qualifier_list ptrref_operator cfa_abstract_function
4264 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4265 | ptrref_operator cfa_abstract_declarator_tuple
4266 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4267 | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
4268 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4269 ;
4270
4271cfa_abstract_array: // CFA
4272 // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
4273 // empty (void) function return type.
4274 '[' ']' type_specifier
4275 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4276 | '[' ']' multi_array_dimension type_specifier
4277 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4278 | multi_array_dimension type_specifier
4279 { $$ = $2->addNewArray( $1 ); }
4280 | '[' ']' cfa_abstract_ptr
4281 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4282 | '[' ']' multi_array_dimension cfa_abstract_ptr
4283 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4284 | multi_array_dimension cfa_abstract_ptr
4285 { $$ = $2->addNewArray( $1 ); }
4286 ;
4287
4288cfa_abstract_tuple: // CFA
4289 '[' push cfa_abstract_parameter_list pop ']'
4290 { $$ = DeclarationNode::newTuple( $3 ); }
4291 | '[' push type_specifier_nobody ELLIPSIS pop ']'
4292 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4293 | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
4294 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4295 ;
4296
4297cfa_abstract_function: // CFA
4298 '[' ']' '(' cfa_parameter_list_ellipsis_opt ')'
4299 { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
4300 | cfa_abstract_tuple '(' push cfa_parameter_list_ellipsis_opt pop ')'
4301 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4302 | cfa_function_return '(' push cfa_parameter_list_ellipsis_opt pop ')'
4303 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4304 ;
4305
4306// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
4307// each declaration, and in the specifier-qualifier list in each structure declaration and type name."
4308//
4309// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
4310// the declaration specifiers in a declaration is an obsolescent feature."
4311//
4312// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
4313// prototype-format parameter type declarators) is an obsolescent feature."
4314//
4315// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
4316// declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
4317
4318// ************************ MISCELLANEOUS ********************************
4319
4320comma_opt: // redundant comma
4321 // empty
4322 | ','
4323 ;
4324
4325default_initializer_opt:
4326 // empty
4327 { $$ = nullptr; }
4328 | '=' assignment_expression
4329 { $$ = $2; }
4330 ;
4331
4332%%
4333
4334// ----end of grammar----
4335
4336// Local Variables: //
4337// mode: c++ //
4338// tab-width: 4 //
4339// compile-command: "bison -Wcounterexamples parser.yy" //
4340// End: //
Note: See TracBrowser for help on using the repository browser.