Context Navigation

parser.yy @ c45d2fa

ADTarm-ehast-experimentalenumforall-pointer-decayjacob/cs343-translationnew-astnew-ast-unique-exprpthread-emulationqualifiedEnum

Last change on this file since c45d2fa was a491a3c, checked in by Peter A. Buhr <pabuhr@…>, 4 years ago
parser prints "List of mutex member is currently unimplemented" error
Property mode set to `100644`
File size: 137.1 KB

Line
1	//
2	// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3	//
4	// The contents of this file are covered under the licence agreement in the
5	// file "LICENCE" distributed with Cforall.
6	//
7	// parser.yy --
8	//
9	// Author : Peter A. Buhr
10	// Created On : Sat Sep 1 20:22:55 2001
11	// Last Modified By : Peter A. Buhr
12	// Last Modified On : Thu May 28 12:11:45 2020
13	// Update Count : 4500
14	//
15
16	// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17	// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS. While parts have been
18	// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19	// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20	// that must be subsequently rejected by semantic checks. Nevertheless, there are still several semantic checks
21	// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23	// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24	// the grammar.
25
26	// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27	//
28	// 1. designation with '=' (use ':' instead)
29	//
30	// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31	// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32	//
33	// 1. designation with and without '=' (use ':' instead)
34	// 2. attributes not allowed in parenthesis of declarator
35	//
36	// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37	// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38	// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39	// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40	// grammar rule.
41
42	%{
43	#define YYDEBUG_LEXER_TEXT (yylval) // lexer loads this up each time
44	#define YYDEBUG 1 // get the pretty debugging code to compile
45	#define YYERROR_VERBOSE // more information in syntax errors
46
47	#undef __GNUC_MINOR__
48
49	#include <cstdio>
50	#include <stack>
51	using namespace std;
52
53	#include "SynTree/Declaration.h"
54	#include "ParseNode.h"
55	#include "TypedefTable.h"
56	#include "TypeData.h"
57	#include "SynTree/LinkageSpec.h"
58	#include "Common/SemanticError.h" // error_str
59	#include "Common/utility.h" // for maybeMoveBuild, maybeBuild, CodeLo...
60
61	extern DeclarationNode * parseTree;
62	extern LinkageSpec::Spec linkage;
63	extern TypedefTable typedefTable;
64
65	stack< LinkageSpec::Spec > linkageStack;
66
67	bool appendStr( string & to, string & from ) {
68	// 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
69	// "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
70	// the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
71	// easier to let the C compiler handle this case.
72	//
73	// 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
74	// without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
75	// i.e., u"a" U"b" L"c" is disallowed.
76
77	if ( from[0] != '"' ) { // encoding ?
78	if ( to[0] != '"' ) { // encoding ?
79	if ( to[0] != from[0] \|\| to[1] != from[1] ) { // different encodings ?
80	yyerror( "non-matching string encodings for string-literal concatenation" );
81	return false; // parse error, must call YYERROR in action
82	} else if ( from[1] == '8' ) {
83	from.erase( 0, 1 ); // remove 2nd encoding
84	} // if
85	} else {
86	if ( from[1] == '8' ) { // move encoding to start
87	to = "u8" + to;
88	from.erase( 0, 1 ); // remove 2nd encoding
89	} else {
90	to = from[0] + to;
91	} // if
92	} // if
93	from.erase( 0, 1 ); // remove 2nd encoding
94	} // if
95	to += " " + from; // concatenated into single string
96	return true;
97	} // appendStr
98
99	DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
100	// distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
101	DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
102	for ( cur = dynamic_cast<DeclarationNode >( cur->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode >( cur->get_next() ) ) {
103	cl->cloneBaseType( cur );
104	} // for
105	declList->addType( cl );
106	return declList;
107	} // distAttr
108
109	void distExt( DeclarationNode * declaration ) {
110	// distribute EXTENSION across all declarations
111	for ( DeclarationNode iter = declaration; iter != nullptr; iter = (DeclarationNode )iter->get_next() ) {
112	iter->set_extension( true );
113	} // for
114	} // distExt
115
116	void distInl( DeclarationNode * declaration ) {
117	// distribute EXTENSION across all declarations
118	for ( DeclarationNode iter = declaration; iter != nullptr; iter = (DeclarationNode )iter->get_next() ) {
119	iter->set_inLine( true );
120	} // for
121	} // distInl
122
123	void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
124	// distribute qualifiers across all non-variable declarations in a distribution statemement
125	for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
126	// SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
127	// addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
128	// get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
129	// be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
130	DeclarationNode * clone = qualifiers->clone();
131	if ( qualifiers->type ) { // forall clause ? (handles SC)
132	if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
133	swap( clone->type->forall, iter->type->aggregate.params );
134	iter->addQualifiers( clone );
135	} else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
136	// Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
137	DeclarationNode newnode;
138	swap( newnode.type, iter->type->aggInst.aggregate );
139	swap( clone->type->forall, newnode.type->aggregate.params );
140	newnode.addQualifiers( clone );
141	swap( newnode.type, iter->type->aggInst.aggregate );
142	} else if ( iter->type->kind == TypeData::Function ) { // routines ?
143	swap( clone->type->forall, iter->type->forall );
144	iter->addQualifiers( clone );
145	} // if
146	} else { // just SC qualifiers
147	iter->addQualifiers( clone );
148	} // if
149	} // for
150	delete qualifiers;
151	} // distQual
152
153	// There is an ambiguity for inline generic-routine return-types and generic routines.
154	// forall( otype T ) struct S { int i; } bar( T ) {}
155	// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
156	// forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
157	// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
158	// forall( otype T ) struct S { int T; };
159	// forall( otype W ) bar( W ) {}
160
161	void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
162	if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
163	funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
164	declSpec->type->aggregate.params = nullptr;
165	} // if
166	} // rebindForall
167
168	string * build_postfix_name( string * name ) {
169	name = string("__postfix_func_") + name;
170	return name;
171	} // build_postfix_name
172
173	DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
174	if ( ! fieldList ) { // field declarator ?
175	if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate \|\| typeSpec->type->kind == TypeData::Enum) ) ) {
176	stringstream ss;
177	typeSpec->type->print( ss );
178	SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
179	return nullptr;
180	} // if
181	fieldList = DeclarationNode::newName( nullptr );
182	} // if
183	return distAttr( typeSpec, fieldList ); // mark all fields in list
184	} // fieldDecl
185
186	ForCtrl * forCtrl( ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
187	ConstantExpr * constant = dynamic_cast<ConstantExpr *>(type->expr.get());
188	if ( constant && (constant->get_constant()->get_value() == "0" \|\| constant->get_constant()->get_value() == "1") ) {
189	type = new ExpressionNode( new CastExpr( maybeMoveBuild< Expression >(type), new BasicType( Type::Qualifiers(), BasicType::SignedInt ) ) );
190	} // if
191	return new ForCtrl(
192	distAttr( DeclarationNode::newTypeof( type, true ), DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) ) ),
193	// NULL comp/inc => leave blank
194	comp ? new ExpressionNode( build_binary_val( compop, new ExpressionNode( build_varref( new string( *index ) ) ), comp ) ) : 0,
195	inc ? new ExpressionNode( build_binary_val( compop == OperKinds::LThan \|\| compop == OperKinds::LEThan ? // choose += or -= for upto/downto
196	OperKinds::PlusAssn : OperKinds::MinusAssn, new ExpressionNode( build_varref( new string( *index ) ) ), inc ) ) : 0 );
197	} // forCtrl
198
199	ForCtrl * forCtrl( ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
200	if ( NameExpr * identifier = dynamic_cast<NameExpr *>(index->expr.get()) ) {
201	return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
202	} else if ( CommaExpr * commaExpr = dynamic_cast<CommaExpr *>(index->expr.get()) ) {
203	if ( NameExpr * identifier = dynamic_cast<NameExpr *>(commaExpr->arg1 ) ) {
204	return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
205	} else {
206	SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); return nullptr;
207	} // if
208	} else {
209	SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); return nullptr;
210	} // if
211	} // forCtrl
212
213	bool forall = false, yyy = false; // aggregate have one or more forall qualifiers ?
214
215	// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
216	#define YYLLOC_DEFAULT(Cur, Rhs, N) \
217	if ( N ) { \
218	(Cur).first_line = YYRHSLOC( Rhs, 1 ).first_line; \
219	(Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column; \
220	(Cur).last_line = YYRHSLOC( Rhs, N ).last_line; \
221	(Cur).last_column = YYRHSLOC( Rhs, N ).last_column; \
222	(Cur).filename = YYRHSLOC( Rhs, 1 ).filename; \
223	} else { \
224	(Cur).first_line = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line; \
225	(Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column; \
226	(Cur).filename = YYRHSLOC( Rhs, 0 ).filename; \
227	}
228	%}
229
230	%define parse.error verbose
231
232	// Types declaration for productions
233	%union {
234	Token tok;
235	ParseNode * pn;
236	ExpressionNode * en;
237	DeclarationNode * decl;
238	AggregateDecl::Aggregate aggKey;
239	TypeDecl::Kind tclass;
240	StatementNode * sn;
241	WaitForStmt * wfs;
242	Expression * constant;
243	IfCtrl * ifctl;
244	ForCtrl * fctl;
245	enum OperKinds compop;
246	LabelNode * label;
247	InitializerNode * in;
248	OperKinds op;
249	std::string * str;
250	bool flag;
251	CatchStmt::Kind catch_kind;
252	GenericExpr * genexpr;
253	}
254
255	//*********************** TERMINAL TOKENS ******************************
256
257	// keywords
258	%token TYPEDEF
259	%token EXTERN STATIC AUTO REGISTER
260	%token THREADLOCAL // C11
261	%token INLINE FORTRAN // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
262	%token NORETURN // C11
263	%token CONST VOLATILE
264	%token RESTRICT // C99
265	%token ATOMIC // C11
266	%token FORALL MUTEX VIRTUAL COERCE // CFA
267	%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
268	%token BOOL COMPLEX IMAGINARY // C99
269	%token INT128 UINT128 uuFLOAT80 uuFLOAT128 // GCC
270	%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
271	%token ZERO_T ONE_T // CFA
272	%token VALIST // GCC
273	%token AUTO_TYPE // GCC
274	%token TYPEOF BASETYPEOF LABEL // GCC
275	%token ENUM STRUCT UNION
276	%token EXCEPTION // CFA
277	%token GENERATOR COROUTINE MONITOR THREAD // CFA
278	%token OTYPE FTYPE DTYPE TTYPE TRAIT // CFA
279	%token SIZEOF OFFSETOF
280	// %token RESUME // CFA
281	%token SUSPEND // CFA
282	%token ATTRIBUTE EXTENSION // GCC
283	%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
284	%token CHOOSE DISABLE ENABLE FALLTHRU FALLTHROUGH TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT WITH WHEN WAITFOR // CFA
285	%token ASM // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
286	%token ALIGNAS ALIGNOF GENERIC STATICASSERT // C11
287
288	// names and constants: lexer differentiates between identifier and typedef names
289	%token<tok> IDENTIFIER QUOTED_IDENTIFIER TYPEDEFname TYPEGENname
290	%token<tok> TIMEOUT WOR
291	%token<tok> INTEGERconstant CHARACTERconstant STRINGliteral
292	%token<tok> DIRECTIVE
293	// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
294	// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
295	// converted into the tuple index (.)(1). e.g., 3.x
296	%token<tok> FLOATING_DECIMALconstant FLOATING_FRACTIONconstant FLOATINGconstant
297
298	// multi-character operators
299	%token ARROW // ->
300	%token ICR DECR // ++ --
301	%token LS RS // << >>
302	%token LE GE EQ NE // <= >= == !=
303	%token ANDAND OROR // && \|\|
304	%token ELLIPSIS // ...
305
306	%token EXPassign MULTassign DIVassign MODassign // \= *= /= %=
307	%token PLUSassign MINUSassign // += -=
308	%token LSassign RSassign // <<= >>=
309	%token ANDassign ERassign ORassign // &= ^= \|=
310
311	%token ErangeUpEq ErangeDown ErangeDownEq // ~= -~ -~=
312	%token ATassign // @=
313
314	%type<tok> identifier
315	%type<tok> identifier_or_type_name attr_name
316	%type<tok> quasi_keyword
317	%type<constant> string_literal
318	%type<str> string_literal_list
319
320	// expressions
321	%type<en> constant
322	%type<en> tuple tuple_expression_list
323	%type<op> ptrref_operator unary_operator assignment_operator
324	%type<en> primary_expression postfix_expression unary_expression
325	%type<en> cast_expression_list cast_expression exponential_expression multiplicative_expression additive_expression
326	%type<en> shift_expression relational_expression equality_expression
327	%type<en> AND_expression exclusive_OR_expression inclusive_OR_expression
328	%type<en> logical_AND_expression logical_OR_expression
329	%type<en> conditional_expression constant_expression assignment_expression assignment_expression_opt
330	%type<en> comma_expression comma_expression_opt
331	%type<en> argument_expression_list_opt argument_expression default_initialize_opt
332	%type<ifctl> if_control_expression
333	%type<fctl> for_control_expression for_control_expression_list
334	%type<compop> inclexcl
335	%type<en> subrange
336	%type<decl> asm_name_opt
337	%type<en> asm_operands_opt asm_operands_list asm_operand
338	%type<label> label_list
339	%type<en> asm_clobbers_list_opt
340	%type<flag> asm_volatile_opt
341	%type<en> handler_predicate_opt
342	%type<genexpr> generic_association generic_assoc_list
343
344	// statements
345	%type<sn> statement labeled_statement compound_statement
346	%type<sn> statement_decl statement_decl_list statement_list_nodecl
347	%type<sn> selection_statement if_statement
348	%type<sn> switch_clause_list_opt switch_clause_list
349	%type<en> case_value
350	%type<sn> case_clause case_value_list case_label case_label_list
351	%type<sn> iteration_statement jump_statement
352	%type<sn> expression_statement asm_statement
353	%type<sn> with_statement
354	%type<en> with_clause_opt
355	%type<sn> exception_statement handler_clause finally_clause
356	%type<catch_kind> handler_key
357	%type<sn> mutex_statement
358	%type<en> when_clause when_clause_opt waitfor timeout
359	%type<sn> waitfor_statement
360	%type<wfs> waitfor_clause
361
362	// declarations
363	%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
364	%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
365	%type<decl> abstract_parameter_declaration
366
367	%type<aggKey> aggregate_key aggregate_data aggregate_control
368	%type<decl> aggregate_type aggregate_type_nobody
369
370	%type<decl> assertion assertion_list assertion_list_opt
371
372	%type<en> bit_subrange_size_opt bit_subrange_size
373
374	%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
375
376	%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
377
378	%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
379	%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
380
381	%type<decl> elaborated_type elaborated_type_nobody
382
383	%type<decl> enumerator_list enum_type enum_type_nobody
384	%type<en> enumerator_value_opt
385
386	%type<decl> external_definition external_definition_list external_definition_list_opt
387
388	%type<decl> exception_declaration
389
390	%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
391	%type<en> field field_name_list field_name fraction_constants_opt
392
393	%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
394
395	%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
396	%type<decl> identifier_list
397
398	%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
399	%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
400	%type<decl> cfa_abstract_ptr cfa_abstract_tuple
401
402	%type<decl> cfa_array_parameter_1st_dimension
403
404	%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
405	%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
406
407	%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
408	%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
409
410	%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
411
412	%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
413
414	%type<decl> c_declaration static_assert
415	%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
416	%type<decl> KR_parameter_list KR_parameter_list_opt
417
418	%type<decl> parameter_declaration parameter_list parameter_type_list_opt
419
420	%type<decl> paren_identifier paren_type
421
422	%type<decl> storage_class storage_class_list
423
424	%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
425
426	%type<tclass> type_class
427	%type<decl> type_declarator type_declarator_name type_declaring_list
428
429	%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
430	%type<decl> typedef typedef_declaration typedef_expression
431
432	%type<decl> variable_type_redeclarator type_ptr type_array type_function
433
434	%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
435
436	%type<decl> type type_no_function
437	%type<decl> type_parameter type_parameter_list type_initializer_opt
438
439	%type<en> type_parameters_opt type_list
440
441	%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
442	%type<decl> type_specifier type_specifier_nobody
443
444	%type<decl> variable_declarator variable_ptr variable_array variable_function
445	%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
446
447	%type<decl> attribute_list_opt attribute_list attribute_name_list attribute attribute_name
448
449	// initializers
450	%type<in> initializer initializer_list_opt initializer_opt
451
452	// designators
453	%type<en> designator designator_list designation
454
455
456	// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
457	// .---------. matches IF '(' comma_expression ')' statement . (reduce)
458	// if ( C ) S1 else S2
459	// `-----------------' matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
460	// Similar issues exit with the waitfor statement.
461
462	// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
463	// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
464	%precedence THEN // rule precedence for IF/WAITFOR statement
465	%precedence WOR // token precedence for start of WOR in WAITFOR statement
466	%precedence TIMEOUT // token precedence for start of TIMEOUT in WAITFOR statement
467	%precedence ELSE // token precedence for start of else clause in IF/WAITFOR statement
468
469	// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
470	// forall( otype T ) struct Foo { T v; };
471	// .-----. matches pointer to function returning a generic (which is impossible without a type)
472	// Foo ( *fp )( int );
473	// `---' matches start of TYPEGENname '('
474	// must be:
475	// Foo( int ) ( *fp )( int );
476	// The same problem occurs here:
477	// forall( otype T ) struct Foo { T v; } ( *fp )( int );
478	// must be:
479	// forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
480
481	// Order of these lines matters (low-to-high precedence).
482	%precedence TYPEGENname
483	%precedence '}'
484	%precedence '('
485
486	// %precedence RESUME
487	// %precedence '{'
488	// %precedence ')'
489
490	%locations // support location tracking for error messages
491
492	%start translation_unit // parse-tree root
493
494	%%
495	//*********************** Namespace Management ******************************
496
497	// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
498	// which are lexically identical.
499	//
500	// typedef int foo; // identifier foo must now be scanned as TYPEDEFname
501	// foo f; // to allow it to appear in this context
502	//
503	// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
504	// between syntactic and semantic constructs. Cforall compounds this problem by introducing type names local to the
505	// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
506	// generators" -- parameterized types. This latter type name creates a third class of identifiers, "TYPEGENname", which
507	// must be distinguished by the lexical scanner.
508	//
509	// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
510	// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
511	// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
512	// each context that introduces a name scope, a new level is created in the type table and that level is popped on
513	// exiting the scope. Since type names can be local to a particular declaration, each declaration is itself a scope.
514	// This requires distinguishing between type names that are local to the current declaration scope and those that
515	// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
516	//
517	// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
518	// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
519	// around the list separator.
520	//
521	// int f( forall(T) T (f1) T , forall( S ) S (f2)( S ) );
522	// push pop push pop
523
524	push:
525	{ typedefTable.enterScope(); }
526	;
527
528	pop:
529	{ typedefTable.leaveScope(); }
530	;
531
532	//*********************** CONSTANTS ******************************
533
534	constant:
535	// ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
536	INTEGERconstant { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
537	\| FLOATING_DECIMALconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
538	\| FLOATING_FRACTIONconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
539	\| FLOATINGconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
540	\| CHARACTERconstant { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
541	;
542
543	quasi_keyword: // CFA
544	TIMEOUT
545	\| WOR
546	;
547
548	identifier:
549	IDENTIFIER
550	\| quasi_keyword
551	\| '@' // CFA
552	{ Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
553	;
554
555	string_literal:
556	string_literal_list { $$ = build_constantStr( *$1 ); }
557	;
558
559	string_literal_list: // juxtaposed strings are concatenated
560	STRINGliteral { $$ = $1; } // conversion from tok to str
561	\| string_literal_list STRINGliteral
562	{
563	if ( ! appendStr( $1, $2 ) ) YYERROR; // append 2nd juxtaposed string to 1st
564	delete $2; // allocated by lexer
565	$$ = $1; // conversion from tok to str
566	}
567	;
568
569	//*********************** EXPRESSIONS ******************************
570
571	primary_expression:
572	IDENTIFIER // typedef name cannot be used as a variable name
573	{ $$ = new ExpressionNode( build_varref( $1 ) ); }
574	\| quasi_keyword
575	{ $$ = new ExpressionNode( build_varref( $1 ) ); }
576	\| tuple
577	\| '(' comma_expression ')'
578	{ $$ = $2; }
579	\| '(' compound_statement ')' // GCC, lambda expression
580	{ $$ = new ExpressionNode( new StmtExpr( dynamic_cast< CompoundStmt * >(maybeMoveBuild< Statement >($2) ) ) ); }
581	\| type_name '.' identifier // CFA, nested type
582	{ SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
583	\| type_name '.' '[' field_name_list ']' // CFA, nested type / tuple field selector
584	{ SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
585	\| GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
586	{
587	// add the missing control expression to the GenericExpr and return it
588	$5->control = maybeMoveBuild<Expression>( $3 );
589	$$ = new ExpressionNode( $5 );
590	}
591	// \| RESUME '(' comma_expression ')'
592	// { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
593	// \| RESUME '(' comma_expression ')' compound_statement
594	// { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
595	;
596
597	generic_assoc_list: // C11
598	generic_association
599	\| generic_assoc_list ',' generic_association
600	{
601	// steal the association node from the singleton and delete the wrapper
602	$1->associations.splice($1->associations.end(), $3->associations);
603	delete $3;
604	$$ = $1;
605	}
606	;
607
608	generic_association: // C11
609	type_no_function ':' assignment_expression
610	{
611	// create a GenericExpr wrapper with one association pair
612	$$ = new GenericExpr( nullptr, { { maybeMoveBuildType($1), maybeMoveBuild<Expression>($3) } } );
613	}
614	\| DEFAULT ':' assignment_expression
615	{ $$ = new GenericExpr( nullptr, { { maybeMoveBuild<Expression>($3) } } ); }
616	;
617
618	postfix_expression:
619	primary_expression
620	\| postfix_expression '[' assignment_expression ']'
621	// CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
622	// matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
623	// little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
624	// equivalent to the old x[i,j].
625	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
626	\| postfix_expression '{' argument_expression_list_opt '}' // CFA, constructor call
627	{
628	Token fn;
629	fn.str = new std::string( "?{}" ); // location undefined - use location of '{'?
630	$$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
631	}
632	\| postfix_expression '(' argument_expression_list_opt ')'
633	{ $$ = new ExpressionNode( build_func( $1, $3 ) ); }
634	\| postfix_expression '`' identifier // CFA, postfix call
635	{ $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
636	\| constant '`' identifier // CFA, postfix call
637	{ $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
638	\| string_literal '`' identifier // CFA, postfix call
639	{ $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), new ExpressionNode( $1 ) ) ); }
640	\| postfix_expression '.' identifier
641	{ $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
642	\| postfix_expression '.' INTEGERconstant // CFA, tuple index
643	{ $$ = new ExpressionNode( build_fieldSel( $1, build_constantInteger( *$3 ) ) ); }
644	\| postfix_expression FLOATING_FRACTIONconstant // CFA, tuple index
645	{ $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
646	\| postfix_expression '.' '[' field_name_list ']' // CFA, tuple field selector
647	{ $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
648	\| postfix_expression '.' aggregate_control
649	{ $$ = new ExpressionNode( build_keyword_cast( $3, $1 ) ); }
650	\| postfix_expression ARROW identifier
651	{ $$ = new ExpressionNode( build_pfieldSel( $1, build_varref( $3 ) ) ); }
652	\| postfix_expression ARROW INTEGERconstant // CFA, tuple index
653	{ $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
654	\| postfix_expression ARROW '[' field_name_list ']' // CFA, tuple field selector
655	{ $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
656	\| postfix_expression ICR
657	{ $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
658	\| postfix_expression DECR
659	{ $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
660	\| '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
661	{ $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
662	\| '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
663	{ $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
664	\| '^' primary_expression '{' argument_expression_list_opt '}' // CFA, destructor call
665	{
666	Token fn;
667	fn.str = new string( "^?{}" ); // location undefined
668	$$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
669	}
670	;
671
672	argument_expression_list_opt:
673	// empty
674	{ $$ = nullptr; }
675	\| argument_expression
676	\| argument_expression_list_opt ',' argument_expression
677	{ $$ = (ExpressionNode *)($1->set_last( $3 )); }
678	;
679
680	argument_expression:
681	'@' // CFA, default parameter
682	{ SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
683	// { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
684	\| assignment_expression
685	;
686
687	field_name_list: // CFA, tuple field selector
688	field
689	\| field_name_list ',' field { $$ = (ExpressionNode *)($1->set_last( $3 )); }
690	;
691
692	field: // CFA, tuple field selector
693	field_name
694	\| FLOATING_DECIMALconstant field
695	{ $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
696	\| FLOATING_DECIMALconstant '[' field_name_list ']'
697	{ $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $3 ) ) ); }
698	\| field_name '.' field
699	{ $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
700	\| field_name '.' '[' field_name_list ']'
701	{ $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
702	\| field_name ARROW field
703	{ $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
704	\| field_name ARROW '[' field_name_list ']'
705	{ $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
706	;
707
708	field_name:
709	INTEGERconstant fraction_constants_opt
710	{ $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
711	\| FLOATINGconstant fraction_constants_opt
712	{ $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
713	\| identifier fraction_constants_opt
714	{
715	$$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
716	}
717	;
718
719	fraction_constants_opt:
720	// empty
721	{ $$ = nullptr; }
722	\| fraction_constants_opt FLOATING_FRACTIONconstant
723	{
724	Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
725	$$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1, constant ) ) : new ExpressionNode( constant );
726	}
727	;
728
729	unary_expression:
730	postfix_expression
731	// first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
732	// semantics checks, e.g., ++3, 3--, *3, &&3
733	\| constant
734	\| string_literal
735	{ $$ = new ExpressionNode( $1 ); }
736	\| EXTENSION cast_expression // GCC
737	{ $$ = $2->set_extension( true ); }
738	// '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
739	// { * X; } // dereference X
740	// { * int X; } // CFA declaration of pointer to int
741	\| ptrref_operator cast_expression // CFA
742	{
743	switch ( $1 ) {
744	case OperKinds::AddressOf:
745	$$ = new ExpressionNode( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) );
746	break;
747	case OperKinds::PointTo:
748	$$ = new ExpressionNode( build_unary_val( $1, $2 ) );
749	break;
750	case OperKinds::And:
751	$$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) ) );
752	break;
753	default:
754	assert( false );
755	}
756	}
757	\| unary_operator cast_expression
758	{ $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
759	\| ICR unary_expression
760	{ $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
761	\| DECR unary_expression
762	{ $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
763	\| SIZEOF unary_expression
764	{ $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
765	\| SIZEOF '(' type_no_function ')'
766	{ $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
767	\| ALIGNOF unary_expression // GCC, variable alignment
768	{ $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
769	\| ALIGNOF '(' type_no_function ')' // GCC, type alignment
770	{ $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
771	\| OFFSETOF '(' type_no_function ',' identifier ')'
772	{ $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
773	;
774
775	ptrref_operator:
776	'*' { $$ = OperKinds::PointTo; }
777	\| '&' { $$ = OperKinds::AddressOf; }
778	// GCC, address of label must be handled by semantic check for ref,ref,label
779	\| ANDAND { $$ = OperKinds::And; }
780	;
781
782	unary_operator:
783	'+' { $$ = OperKinds::UnPlus; }
784	\| '-' { $$ = OperKinds::UnMinus; }
785	\| '!' { $$ = OperKinds::Neg; }
786	\| '~' { $$ = OperKinds::BitNeg; }
787	;
788
789	cast_expression:
790	unary_expression
791	\| '(' type_no_function ')' cast_expression
792	{ $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
793	\| '(' aggregate_control '&' ')' cast_expression // CFA
794	{ $$ = new ExpressionNode( build_keyword_cast( $2, $5 ) ); }
795	// VIRTUAL cannot be opt because of look ahead issues
796	\| '(' VIRTUAL ')' cast_expression // CFA
797	{ $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $4 ), maybeMoveBuildType( nullptr ) ) ); }
798	\| '(' VIRTUAL type_no_function ')' cast_expression // CFA
799	{ $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $5 ), maybeMoveBuildType( $3 ) ) ); }
800	\| '(' RETURN type_no_function ')' cast_expression // CFA
801	{ SemanticError( yylloc, "Return cast is currently unimplemented." ); $$ = nullptr; }
802	\| '(' COERCE type_no_function ')' cast_expression // CFA
803	{ SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
804	\| '(' qualifier_cast_list ')' cast_expression // CFA
805	{ SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
806	// \| '(' type_no_function ')' tuple
807	// { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
808	;
809
810	qualifier_cast_list:
811	cast_modifier type_qualifier_name
812	\| cast_modifier MUTEX
813	\| qualifier_cast_list cast_modifier type_qualifier_name
814	\| qualifier_cast_list cast_modifier MUTEX
815	;
816
817	cast_modifier:
818	'-'
819	\| '+'
820	;
821
822	exponential_expression:
823	cast_expression
824	\| exponential_expression '\\' cast_expression
825	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
826	;
827
828	multiplicative_expression:
829	exponential_expression
830	\| multiplicative_expression '*' exponential_expression
831	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
832	\| multiplicative_expression '/' exponential_expression
833	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
834	\| multiplicative_expression '%' exponential_expression
835	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
836	;
837
838	additive_expression:
839	multiplicative_expression
840	\| additive_expression '+' multiplicative_expression
841	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
842	\| additive_expression '-' multiplicative_expression
843	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
844	;
845
846	shift_expression:
847	additive_expression
848	\| shift_expression LS additive_expression
849	{ $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
850	\| shift_expression RS additive_expression
851	{ $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
852	;
853
854	relational_expression:
855	shift_expression
856	\| relational_expression '<' shift_expression
857	{ $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
858	\| relational_expression '>' shift_expression
859	{ $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
860	\| relational_expression LE shift_expression
861	{ $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
862	\| relational_expression GE shift_expression
863	{ $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
864	;
865
866	equality_expression:
867	relational_expression
868	\| equality_expression EQ relational_expression
869	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
870	\| equality_expression NE relational_expression
871	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
872	;
873
874	AND_expression:
875	equality_expression
876	\| AND_expression '&' equality_expression
877	{ $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
878	;
879
880	exclusive_OR_expression:
881	AND_expression
882	\| exclusive_OR_expression '^' AND_expression
883	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
884	;
885
886	inclusive_OR_expression:
887	exclusive_OR_expression
888	\| inclusive_OR_expression '\|' exclusive_OR_expression
889	{ $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
890	;
891
892	logical_AND_expression:
893	inclusive_OR_expression
894	\| logical_AND_expression ANDAND inclusive_OR_expression
895	{ $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
896	;
897
898	logical_OR_expression:
899	logical_AND_expression
900	\| logical_OR_expression OROR logical_AND_expression
901	{ $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
902	;
903
904	conditional_expression:
905	logical_OR_expression
906	\| logical_OR_expression '?' comma_expression ':' conditional_expression
907	{ $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
908	// FIX ME: computes $1 twice
909	\| logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
910	{ $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
911	;
912
913	constant_expression:
914	conditional_expression
915	;
916
917	assignment_expression:
918	// CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
919	conditional_expression
920	\| unary_expression assignment_operator assignment_expression
921	{
922	if ( $2 == OperKinds::AtAssn ) {
923	SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
924	} else {
925	$$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) );
926	} // if
927	}
928	\| unary_expression '=' '{' initializer_list_opt comma_opt '}'
929	{ SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
930	;
931
932	assignment_expression_opt:
933	// empty
934	{ $$ = nullptr; }
935	\| assignment_expression
936	;
937
938	assignment_operator:
939	'=' { $$ = OperKinds::Assign; }
940	\| ATassign { $$ = OperKinds::AtAssn; }
941	\| EXPassign { $$ = OperKinds::ExpAssn; }
942	\| MULTassign { $$ = OperKinds::MulAssn; }
943	\| DIVassign { $$ = OperKinds::DivAssn; }
944	\| MODassign { $$ = OperKinds::ModAssn; }
945	\| PLUSassign { $$ = OperKinds::PlusAssn; }
946	\| MINUSassign { $$ = OperKinds::MinusAssn; }
947	\| LSassign { $$ = OperKinds::LSAssn; }
948	\| RSassign { $$ = OperKinds::RSAssn; }
949	\| ANDassign { $$ = OperKinds::AndAssn; }
950	\| ERassign { $$ = OperKinds::ERAssn; }
951	\| ORassign { $$ = OperKinds::OrAssn; }
952	;
953
954	tuple: // CFA, tuple
955	// CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
956	// comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
957	// '[' ']'
958	// { $$ = new ExpressionNode( build_tuple() ); }
959	// \| '[' push assignment_expression pop ']'
960	// { $$ = new ExpressionNode( build_tuple( $3 ) ); }
961	'[' ',' tuple_expression_list ']'
962	{ $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
963	\| '[' push assignment_expression pop ',' tuple_expression_list ']'
964	{ $$ = new ExpressionNode( build_tuple( (ExpressionNode *)($3->set_last( $6 ) ) )); }
965	;
966
967	tuple_expression_list:
968	assignment_expression
969	\| '@' // CFA
970	{ SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
971	\| tuple_expression_list ',' assignment_expression
972	{ $$ = (ExpressionNode *)($1->set_last( $3 )); }
973	\| tuple_expression_list ',' '@'
974	{ SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
975	;
976
977	comma_expression:
978	assignment_expression
979	\| comma_expression ',' assignment_expression
980	{ $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
981	;
982
983	comma_expression_opt:
984	// empty
985	{ $$ = nullptr; }
986	\| comma_expression
987	;
988
989	//************************* STATEMENTS *****************************
990
991	statement:
992	labeled_statement
993	\| compound_statement
994	\| expression_statement
995	\| selection_statement
996	\| iteration_statement
997	\| jump_statement
998	\| with_statement
999	\| mutex_statement
1000	\| waitfor_statement
1001	\| exception_statement
1002	\| enable_disable_statement
1003	{ SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1004	\| asm_statement
1005	\| DIRECTIVE
1006	{ $$ = new StatementNode( build_directive( $1 ) ); }
1007	;
1008
1009	labeled_statement:
1010	// labels cannot be identifiers 0 or 1
1011	identifier_or_type_name ':' attribute_list_opt statement
1012	{ $$ = $4->add_label( $1, $3 ); }
1013	;
1014
1015	compound_statement:
1016	'{' '}'
1017	{ $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
1018	\| '{' push
1019	local_label_declaration_opt // GCC, local labels
1020	statement_decl_list // C99, intermix declarations and statements
1021	pop '}'
1022	{ $$ = new StatementNode( build_compound( $4 ) ); }
1023	;
1024
1025	statement_decl_list: // C99
1026	statement_decl
1027	\| statement_decl_list statement_decl
1028	{ assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1029	;
1030
1031	statement_decl:
1032	declaration // CFA, new & old style declarations
1033	{ $$ = new StatementNode( $1 ); }
1034	\| EXTENSION declaration // GCC
1035	{ distExt( $2 ); $$ = new StatementNode( $2 ); }
1036	\| function_definition
1037	{ $$ = new StatementNode( $1 ); }
1038	\| EXTENSION function_definition // GCC
1039	{ distExt( $2 ); $$ = new StatementNode( $2 ); }
1040	\| statement
1041	;
1042
1043	statement_list_nodecl:
1044	statement
1045	\| statement_list_nodecl statement
1046	{ assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1047	;
1048
1049	expression_statement:
1050	comma_expression_opt ';'
1051	{ $$ = new StatementNode( build_expr( $1 ) ); }
1052	;
1053
1054	selection_statement:
1055	// pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1056	// the inherent S/R conflict with THEN/ELSE.
1057	push if_statement pop
1058	{ $$ = $2; }
1059	\| SWITCH '(' comma_expression ')' case_clause
1060	{ $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
1061	\| SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1062	{
1063	StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
1064	// The semantics of the declaration list is changed to include associated initialization, which is performed
1065	// before the transfer to the appropriate case clause by hoisting the declarations into a compound
1066	// statement around the switch. Statements after the initial declaration list can never be executed, and
1067	// therefore, are removed from the grammar even though C allows it. The change also applies to choose
1068	// statement.
1069	$$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1070	}
1071	\| CHOOSE '(' comma_expression ')' case_clause // CFA
1072	{ $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
1073	\| CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1074	{
1075	StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
1076	$$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1077	}
1078	;
1079
1080	if_statement:
1081	IF '(' if_control_expression ')' statement %prec THEN
1082	// explicitly deal with the shift/reduce conflict on if/else
1083	{ $$ = new StatementNode( build_if( $3, $5, nullptr ) ); }
1084	\| IF '(' if_control_expression ')' statement ELSE statement
1085	{ $$ = new StatementNode( build_if( $3, $5, $7 ) ); }
1086	;
1087
1088	if_control_expression:
1089	comma_expression
1090	{ $$ = new IfCtrl( nullptr, $1 ); }
1091	\| c_declaration // no semi-colon
1092	{ $$ = new IfCtrl( $1, nullptr ); }
1093	\| cfa_declaration // no semi-colon
1094	{ $$ = new IfCtrl( $1, nullptr ); }
1095	\| declaration comma_expression // semi-colon separated
1096	{ $$ = new IfCtrl( $1, $2 ); }
1097	;
1098
1099	// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1100	// clause allows a list of values and subranges.
1101
1102	case_value: // CFA
1103	constant_expression { $$ = $1; }
1104	\| constant_expression ELLIPSIS constant_expression // GCC, subrange
1105	{ $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
1106	\| subrange // CFA, subrange
1107	;
1108
1109	case_value_list: // CFA
1110	case_value { $$ = new StatementNode( build_case( $1 ) ); }
1111	// convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1112	\| case_value_list ',' case_value { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
1113	;
1114
1115	case_label: // CFA
1116	CASE case_value_list ':' { $$ = $2; }
1117	\| DEFAULT ':' { $$ = new StatementNode( build_default() ); }
1118	// A semantic check is required to ensure only one default clause per switch/choose statement.
1119	;
1120
1121	//label_list_opt:
1122	// // empty
1123	// \| identifier_or_type_name ':'
1124	// \| label_list_opt identifier_or_type_name ':'
1125	// ;
1126
1127	case_label_list: // CFA
1128	case_label
1129	\| case_label_list case_label { $$ = (StatementNode *)( $1->set_last( $2 )); }
1130	;
1131
1132	case_clause: // CFA
1133	case_label_list statement { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1134	;
1135
1136	switch_clause_list_opt: // CFA
1137	// empty
1138	{ $$ = nullptr; }
1139	\| switch_clause_list
1140	;
1141
1142	switch_clause_list: // CFA
1143	case_label_list statement_list_nodecl
1144	{ $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1145	\| switch_clause_list case_label_list statement_list_nodecl
1146	{ $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1147	;
1148
1149	iteration_statement:
1150	WHILE '(' push if_control_expression ')' statement pop
1151	{ $$ = new StatementNode( build_while( $4, $6 ) ); }
1152	\| WHILE '(' ')' statement // CFA => while ( 1 )
1153	{ $$ = new StatementNode( build_while( new IfCtrl( nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ), $4 ) ); }
1154	\| DO statement WHILE '(' comma_expression ')' ';'
1155	{ $$ = new StatementNode( build_do_while( $5, $2 ) ); }
1156	\| DO statement WHILE '(' ')' ';' // CFA => do while( 1 )
1157	{ $$ = new StatementNode( build_do_while( new ExpressionNode( build_constantInteger( *new string( "1" ) ) ), $2 ) ); }
1158	\| FOR '(' push for_control_expression_list ')' statement pop
1159	{ $$ = new StatementNode( build_for( $4, $6 ) ); }
1160	\| FOR '(' ')' statement // CFA => for ( ;; )
1161	{ $$ = new StatementNode( build_for( new ForCtrl( (ExpressionNode * )nullptr, (ExpressionNode * )nullptr, (ExpressionNode * )nullptr ), $4 ) ); }
1162	;
1163
1164	for_control_expression_list:
1165	for_control_expression
1166	\| for_control_expression_list ':' for_control_expression
1167	// ForCtrl + ForCtrl:
1168	// init + init => multiple declaration statements that are hoisted
1169	// condition + condition => (expression) && (expression)
1170	// change + change => (expression), (expression)
1171	{
1172	$1->init->set_last( $3->init );
1173	if ( $1->condition ) {
1174	if ( $3->condition ) {
1175	$1->condition->expr.reset( new LogicalExpr( $1->condition->expr.release(), $3->condition->expr.release(), true ) );
1176	} // if
1177	} else $1->condition = $3->condition;
1178	if ( $1->change ) {
1179	if ( $3->change ) {
1180	$1->change->expr.reset( new CommaExpr( $1->change->expr.release(), $3->change->expr.release() ) );
1181	} // if
1182	} else $1->change = $3->change;
1183	$$ = $1;
1184	}
1185	;
1186
1187	for_control_expression:
1188	';' comma_expression_opt ';' comma_expression_opt
1189	{ $$ = new ForCtrl( (ExpressionNode * )nullptr, $2, $4 ); }
1190	\| comma_expression ';' comma_expression_opt ';' comma_expression_opt
1191	{ $$ = new ForCtrl( $1, $3, $5 ); }
1192	\| declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1193	{ $$ = new ForCtrl( $1, $2, $4 ); }
1194
1195	\| comma_expression // CFA
1196	{ $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1197	OperKinds::LThan, $1->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1198	\| '=' comma_expression // CFA
1199	{ $$ = forCtrl( $2, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1200	OperKinds::LEThan, $2->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1201	\| comma_expression inclexcl comma_expression // CFA
1202	{ $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1203	\| comma_expression inclexcl comma_expression '~' comma_expression // CFA
1204	{ $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, $5 ); }
1205	\| comma_expression ';' // CFA
1206	{ $$ = forCtrl( new ExpressionNode( build_constantInteger( *new string( "0u" ) ) ), $1, nullptr, OperKinds::LThan, nullptr, nullptr ); }
1207	\| comma_expression ';' comma_expression // CFA
1208	{ $$ = forCtrl( $3, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1209	OperKinds::LThan, $3->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1210	\| comma_expression ';' '=' comma_expression // CFA
1211	{ $$ = forCtrl( $4, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1212	OperKinds::LEThan, $4->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1213	\| comma_expression ';' comma_expression inclexcl comma_expression // CFA
1214	{ $$ = forCtrl( $3, $1, $3->clone(), $4, $5, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1215	\| comma_expression ';' comma_expression inclexcl comma_expression '~' comma_expression // CFA
1216	{ $$ = forCtrl( $3, $1, $3->clone(), $4, $5, $7 ); }
1217
1218	// There is a S/R conflicit if ~ and -~ are factored out.
1219	\| comma_expression ';' comma_expression '~' '@' // CFA
1220	{ $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1221	\| comma_expression ';' comma_expression ErangeDown '@' // CFA
1222	{ $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1223	\| comma_expression ';' comma_expression '~' '@' '~' comma_expression // CFA
1224	{ $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, $7 ); }
1225	\| comma_expression ';' comma_expression ErangeDown '@' '~' comma_expression // CFA
1226	{ $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, $7 ); }
1227	\| comma_expression ';' comma_expression '~' '@' '~' '@' // CFA
1228	{ $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, nullptr ); }
1229	;
1230
1231	inclexcl:
1232	'~'
1233	{ $$ = OperKinds::LThan; }
1234	\| ErangeUpEq
1235	{ $$ = OperKinds::LEThan; }
1236	\| ErangeDown
1237	{ $$ = OperKinds::GThan; }
1238	\| ErangeDownEq
1239	{ $$ = OperKinds::GEThan; }
1240	;
1241
1242	jump_statement:
1243	GOTO identifier_or_type_name ';'
1244	{ $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1245	\| GOTO '*' comma_expression ';' // GCC, computed goto
1246	// The syntax for the GCC computed goto violates normal expression precedence, e.g., goto i+3; => goto (i+3);
1247	// whereas normal operator precedence yields goto (*i)+3;
1248	{ $$ = new StatementNode( build_computedgoto( $3 ) ); }
1249	// A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1250	\| fall_through_name ';' // CFA
1251	{ $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1252	\| fall_through_name identifier_or_type_name ';' // CFA
1253	{ $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1254	\| fall_through_name DEFAULT ';' // CFA
1255	{ $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1256	\| CONTINUE ';'
1257	// A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1258	{ $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1259	\| CONTINUE identifier_or_type_name ';' // CFA, multi-level continue
1260	// A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1261	// the target of the transfer appears only at the start of an iteration statement.
1262	{ $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1263	\| BREAK ';'
1264	// A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1265	{ $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1266	\| BREAK identifier_or_type_name ';' // CFA, multi-level exit
1267	// A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1268	// the target of the transfer appears only at the start of an iteration statement.
1269	{ $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1270	\| RETURN comma_expression_opt ';'
1271	{ $$ = new StatementNode( build_return( $2 ) ); }
1272	\| RETURN '{' initializer_list_opt comma_opt '}' ';'
1273	{ SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1274	\| SUSPEND ';'
1275	{ $$ = new StatementNode( build_suspend( nullptr ) ); }
1276	\| SUSPEND compound_statement
1277	{ $$ = new StatementNode( build_suspend( $2 ) ); }
1278	\| SUSPEND COROUTINE ';'
1279	{ $$ = new StatementNode( build_suspend( nullptr, SuspendStmt::Coroutine ) ); }
1280	\| SUSPEND COROUTINE compound_statement
1281	{ $$ = new StatementNode( build_suspend( $3, SuspendStmt::Coroutine ) ); }
1282	\| SUSPEND GENERATOR ';'
1283	{ $$ = new StatementNode( build_suspend( nullptr, SuspendStmt::Generator ) ); }
1284	\| SUSPEND GENERATOR compound_statement
1285	{ $$ = new StatementNode( build_suspend( $3, SuspendStmt::Generator ) ); }
1286	\| THROW assignment_expression_opt ';' // handles rethrow
1287	{ $$ = new StatementNode( build_throw( $2 ) ); }
1288	\| THROWRESUME assignment_expression_opt ';' // handles reresume
1289	{ $$ = new StatementNode( build_resume( $2 ) ); }
1290	\| THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1291	{ $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1292	;
1293
1294	fall_through_name: // CFA
1295	FALLTHRU
1296	\| FALLTHROUGH
1297	;
1298
1299	with_statement:
1300	WITH '(' tuple_expression_list ')' statement
1301	{
1302	$$ = new StatementNode( build_with( $3, $5 ) );
1303	}
1304	;
1305
1306	// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1307	mutex_statement:
1308	MUTEX '(' argument_expression_list_opt ')' statement
1309	{ SemanticError( yylloc, "Mutex statement is currently unimplemented." ); $$ = nullptr; }
1310	;
1311
1312	when_clause:
1313	WHEN '(' comma_expression ')' { $$ = $3; }
1314	;
1315
1316	when_clause_opt:
1317	// empty
1318	{ $$ = nullptr; }
1319	\| when_clause
1320	;
1321
1322	waitfor:
1323	WAITFOR '(' cast_expression ')'
1324	{ $$ = $3; }
1325	// \| WAITFOR '(' cast_expression ',' argument_expression_list_opt ')'
1326	// { $$ = (ExpressionNode *)$3->set_last( $5 ); }
1327	\| WAITFOR '(' cast_expression_list ':' argument_expression_list_opt ')'
1328	{ $$ = (ExpressionNode *)($3->set_last( $5 )); }
1329	;
1330
1331	cast_expression_list:
1332	cast_expression
1333	\| cast_expression_list ',' cast_expression
1334	// { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1335	{ SemanticError( yylloc, "List of mutex member is currently unimplemented." ); $$ = nullptr; }
1336	;
1337
1338	timeout:
1339	TIMEOUT '(' comma_expression ')' { $$ = $3; }
1340	;
1341
1342	waitfor_clause:
1343	when_clause_opt waitfor statement %prec THEN
1344	{ $$ = build_waitfor( $2, $3, $1 ); }
1345	\| when_clause_opt waitfor statement WOR waitfor_clause
1346	{ $$ = build_waitfor( $2, $3, $1, $5 ); }
1347	\| when_clause_opt timeout statement %prec THEN
1348	{ $$ = build_waitfor_timeout( $2, $3, $1 ); }
1349	\| when_clause_opt ELSE statement
1350	{ $$ = build_waitfor_timeout( nullptr, $3, $1 ); }
1351	// "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1352	\| when_clause_opt timeout statement WOR ELSE statement
1353	{ SemanticError( yylloc, "else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1354	\| when_clause_opt timeout statement WOR when_clause ELSE statement
1355	{ $$ = build_waitfor_timeout( $2, $3, $1, $7, $5 ); }
1356	;
1357
1358	waitfor_statement:
1359	when_clause_opt waitfor statement %prec THEN
1360	{ $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1361	\| when_clause_opt waitfor statement WOR waitfor_clause
1362	{ $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1363	;
1364
1365	exception_statement:
1366	TRY compound_statement handler_clause
1367	{ $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1368	\| TRY compound_statement finally_clause
1369	{ $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1370	\| TRY compound_statement handler_clause finally_clause
1371	{ $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1372	;
1373
1374	handler_clause:
1375	handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1376	{ $$ = new StatementNode( build_catch( $1, $4, $6, $8 ) ); }
1377	\| handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1378	{ $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $5, $7, $9 ) ) ); }
1379	;
1380
1381	handler_predicate_opt:
1382	// empty
1383	{ $$ = nullptr; }
1384	\| ';' conditional_expression { $$ = $2; }
1385	;
1386
1387	handler_key:
1388	CATCH { $$ = CatchStmt::Terminate; }
1389	\| CATCHRESUME { $$ = CatchStmt::Resume; }
1390	;
1391
1392	finally_clause:
1393	FINALLY compound_statement { $$ = new StatementNode( build_finally( $2 ) ); }
1394	;
1395
1396	exception_declaration:
1397	// No SUE declaration in parameter list.
1398	type_specifier_nobody
1399	\| type_specifier_nobody declarator
1400	{ $$ = $2->addType( $1 ); }
1401	\| type_specifier_nobody variable_abstract_declarator
1402	{ $$ = $2->addType( $1 ); }
1403	\| cfa_abstract_declarator_tuple identifier // CFA
1404	{ $$ = $1->addName( $2 ); }
1405	\| cfa_abstract_declarator_tuple // CFA
1406	;
1407
1408	enable_disable_statement:
1409	enable_disable_key identifier_list compound_statement
1410	;
1411
1412	enable_disable_key:
1413	ENABLE
1414	\| DISABLE
1415	;
1416
1417	asm_statement:
1418	ASM asm_volatile_opt '(' string_literal ')' ';'
1419	{ $$ = new StatementNode( build_asm( $2, $4, 0 ) ); }
1420	\| ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1421	{ $$ = new StatementNode( build_asm( $2, $4, $6 ) ); }
1422	\| ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1423	{ $$ = new StatementNode( build_asm( $2, $4, $6, $8 ) ); }
1424	\| ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1425	{ $$ = new StatementNode( build_asm( $2, $4, $6, $8, $10 ) ); }
1426	\| ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1427	{ $$ = new StatementNode( build_asm( $2, $5, 0, $8, $10, $12 ) ); }
1428	;
1429
1430	asm_volatile_opt: // GCC
1431	// empty
1432	{ $$ = false; }
1433	\| VOLATILE
1434	{ $$ = true; }
1435	;
1436
1437	asm_operands_opt: // GCC
1438	// empty
1439	{ $$ = nullptr; } // use default argument
1440	\| asm_operands_list
1441	;
1442
1443	asm_operands_list: // GCC
1444	asm_operand
1445	\| asm_operands_list ',' asm_operand
1446	{ $$ = (ExpressionNode *)($1->set_last( $3 )); }
1447	;
1448
1449	asm_operand: // GCC
1450	string_literal '(' constant_expression ')'
1451	{ $$ = new ExpressionNode( new AsmExpr( nullptr, $1, maybeMoveBuild< Expression >( $3 ) ) ); }
1452	\| '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1453	{ $$ = new ExpressionNode( new AsmExpr( $2, $4, maybeMoveBuild< Expression >( $6 ) ) ); }
1454	;
1455
1456	asm_clobbers_list_opt: // GCC
1457	// empty
1458	{ $$ = nullptr; } // use default argument
1459	\| string_literal
1460	{ $$ = new ExpressionNode( $1 ); }
1461	\| asm_clobbers_list_opt ',' string_literal
1462	{ $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( $3 ) )); }
1463	;
1464
1465	label_list:
1466	identifier
1467	{
1468	$$ = new LabelNode(); $$->labels.push_back( *$1 );
1469	delete $1; // allocated by lexer
1470	}
1471	\| label_list ',' identifier
1472	{
1473	$$ = $1; $1->labels.push_back( *$3 );
1474	delete $3; // allocated by lexer
1475	}
1476	;
1477
1478	//***************************** DECLARATIONS *******************************
1479
1480	declaration_list_opt: // used at beginning of switch statement
1481	// empty
1482	{ $$ = nullptr; }
1483	\| declaration_list
1484	;
1485
1486	declaration_list:
1487	declaration
1488	\| declaration_list declaration
1489	{ $$ = $1->appendList( $2 ); }
1490	;
1491
1492	KR_parameter_list_opt: // used to declare parameter types in K&R style functions
1493	// empty
1494	{ $$ = nullptr; }
1495	\| KR_parameter_list
1496	;
1497
1498	KR_parameter_list:
1499	push c_declaration pop ';'
1500	{ $$ = $2; }
1501	\| KR_parameter_list push c_declaration pop ';'
1502	{ $$ = $1->appendList( $3 ); }
1503	;
1504
1505	local_label_declaration_opt: // GCC, local label
1506	// empty
1507	\| local_label_declaration_list
1508	;
1509
1510	local_label_declaration_list: // GCC, local label
1511	LABEL local_label_list ';'
1512	\| local_label_declaration_list LABEL local_label_list ';'
1513	;
1514
1515	local_label_list: // GCC, local label
1516	identifier_or_type_name
1517	\| local_label_list ',' identifier_or_type_name
1518	;
1519
1520	declaration: // old & new style declarations
1521	c_declaration ';'
1522	\| cfa_declaration ';' // CFA
1523	\| static_assert // C11
1524	;
1525
1526	static_assert:
1527	STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1528	{ $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1529	\| STATICASSERT '(' constant_expression ')' ';' // CFA
1530	{ $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( *new string( "\"\"" ) ) ); }
1531
1532	// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1533	// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1534	// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1535	// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1536	// the declaration list (as in Pascal). ANSI C and the new CFA declarations may appear together in the same program
1537	// block, but cannot be mixed within a specific declaration.
1538	//
1539	// CFA C
1540	// [10] int x; int x[10]; // array of 10 integers
1541	// [10] * char y; char *y[10]; // array of 10 pointers to char
1542
1543	cfa_declaration: // CFA
1544	cfa_variable_declaration
1545	\| cfa_typedef_declaration
1546	\| cfa_function_declaration
1547	\| type_declaring_list
1548	\| trait_specifier
1549	;
1550
1551	cfa_variable_declaration: // CFA
1552	cfa_variable_specifier initializer_opt
1553	{ $$ = $1->addInitializer( $2 ); }
1554	\| declaration_qualifier_list cfa_variable_specifier initializer_opt
1555	// declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1556	// them as a type_qualifier cannot appear in that context.
1557	{ $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1558	\| cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1559	{ $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1560	;
1561
1562	cfa_variable_specifier: // CFA
1563	// A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1564	// storage-class
1565	cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1566	{ $$ = $1->addName( $2 )->addAsmName( $3 ); }
1567	\| cfa_abstract_tuple identifier_or_type_name asm_name_opt
1568	{ $$ = $1->addName( $2 )->addAsmName( $3 ); }
1569	\| type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1570	{ $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1571	;
1572
1573	cfa_function_declaration: // CFA
1574	cfa_function_specifier
1575	\| type_qualifier_list cfa_function_specifier
1576	{ $$ = $2->addQualifiers( $1 ); }
1577	\| declaration_qualifier_list cfa_function_specifier
1578	{ $$ = $2->addQualifiers( $1 ); }
1579	\| declaration_qualifier_list type_qualifier_list cfa_function_specifier
1580	{ $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1581	\| cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1582	{
1583	// Append the return type at the start (left-hand-side) to each identifier in the list.
1584	DeclarationNode * ret = new DeclarationNode;
1585	ret->type = maybeClone( $1->type->base );
1586	$$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1587	}
1588	;
1589
1590	cfa_function_specifier: // CFA
1591	// '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1592	// {
1593	// $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1594	// }
1595	// '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1596	// {
1597	// typedefTable.setNextIdentifier( *$5 );
1598	// $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1599	// }
1600	// \| '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1601	// {
1602	// typedefTable.setNextIdentifier( *$5 );
1603	// $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1604	// }
1605	// \| '[' ']' typegen_name
1606	// identifier_or_type_name must be broken apart because of the sequence:
1607	//
1608	// '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1609	// '[' ']' type_specifier
1610	//
1611	// type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1612	// flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1613	cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1614	// To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1615	{ $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1616	\| cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1617	{ $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1618	;
1619
1620	cfa_function_return: // CFA
1621	'[' push cfa_parameter_list pop ']'
1622	{ $$ = DeclarationNode::newTuple( $3 ); }
1623	\| '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1624	// To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
1625	{ $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1626	;
1627
1628	cfa_typedef_declaration: // CFA
1629	TYPEDEF cfa_variable_specifier
1630	{
1631	typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "1" );
1632	$$ = $2->addTypedef();
1633	}
1634	\| TYPEDEF cfa_function_specifier
1635	{
1636	typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "2" );
1637	$$ = $2->addTypedef();
1638	}
1639	\| cfa_typedef_declaration pop ',' push identifier
1640	{
1641	typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "3" );
1642	$$ = $1->appendList( $1->cloneType( $5 ) );
1643	}
1644	;
1645
1646	// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1647	// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1648
1649	typedef_declaration:
1650	TYPEDEF type_specifier declarator
1651	{
1652	typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "4" );
1653	$$ = $3->addType( $2 )->addTypedef();
1654	}
1655	\| typedef_declaration pop ',' push declarator
1656	{
1657	typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname, "5" );
1658	$$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1659	}
1660	\| type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1661	{
1662	typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "6" );
1663	$$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1664	}
1665	\| type_specifier TYPEDEF declarator
1666	{
1667	typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "7" );
1668	$$ = $3->addType( $1 )->addTypedef();
1669	}
1670	\| type_specifier TYPEDEF type_qualifier_list declarator
1671	{
1672	typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "8" );
1673	$$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1674	}
1675	;
1676
1677	typedef_expression:
1678	// GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1679	TYPEDEF identifier '=' assignment_expression
1680	{
1681	// $$ = DeclarationNode::newName( 0 ); // unimplemented
1682	SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1683	}
1684	\| typedef_expression pop ',' push identifier '=' assignment_expression
1685	{
1686	// $$ = DeclarationNode::newName( 0 ); // unimplemented
1687	SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1688	}
1689	;
1690
1691	//c_declaration:
1692	// declaring_list pop ';'
1693	// \| typedef_declaration pop ';'
1694	// \| typedef_expression pop ';' // GCC, naming expression type
1695	// \| sue_declaration_specifier pop ';'
1696	// ;
1697	//
1698	//declaring_list:
1699	// // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1700	// // storage-class
1701	// declarator asm_name_opt initializer_opt
1702	// {
1703	// typedefTable.addToEnclosingScope( IDENTIFIER );
1704	// $$ = ( $2->addType( $1 ))->addAsmName( $3 )->addInitializer( $4 );
1705	// }
1706	// \| declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1707	// {
1708	// typedefTable.addToEnclosingScope( IDENTIFIER );
1709	// $$ = $1->appendList( $1->cloneBaseType( $4->addAsmName( $5 )->addInitializer( $6 ) ) );
1710	// }
1711	// ;
1712
1713	c_declaration:
1714	declaration_specifier declaring_list
1715	{ $$ = distAttr( $1, $2 ); }
1716	\| typedef_declaration
1717	\| typedef_expression // GCC, naming expression type
1718	\| sue_declaration_specifier
1719	;
1720
1721	declaring_list:
1722	// A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1723	// storage-class
1724	declarator asm_name_opt initializer_opt
1725	{ $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
1726	\| declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1727	{ $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
1728	;
1729
1730	declaration_specifier: // type specifier + storage class
1731	basic_declaration_specifier
1732	\| sue_declaration_specifier
1733	\| type_declaration_specifier
1734	;
1735
1736	declaration_specifier_nobody: // type specifier + storage class - {...}
1737	// Preclude SUE declarations in restricted scopes:
1738	//
1739	// int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1740	//
1741	// because it is impossible to call f due to name equivalence.
1742	basic_declaration_specifier
1743	\| sue_declaration_specifier_nobody
1744	\| type_declaration_specifier
1745	;
1746
1747	type_specifier: // type specifier
1748	basic_type_specifier
1749	\| sue_type_specifier
1750	\| type_type_specifier
1751	;
1752
1753	type_specifier_nobody: // type specifier - {...}
1754	// Preclude SUE declarations in restricted scopes:
1755	//
1756	// int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1757	//
1758	// because it is impossible to call f due to name equivalence.
1759	basic_type_specifier
1760	\| sue_type_specifier_nobody
1761	\| type_type_specifier
1762	;
1763
1764	type_qualifier_list_opt: // GCC, used in asm_statement
1765	// empty
1766	{ $$ = nullptr; }
1767	\| type_qualifier_list
1768	;
1769
1770	type_qualifier_list:
1771	// A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1772	//
1773	// ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1774	// specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1775	// appeared only once.
1776	type_qualifier
1777	\| type_qualifier_list type_qualifier
1778	{ $$ = $1->addQualifiers( $2 ); }
1779	;
1780
1781	type_qualifier:
1782	type_qualifier_name
1783	\| attribute
1784	;
1785
1786	type_qualifier_name:
1787	CONST
1788	{ $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1789	\| RESTRICT
1790	{ $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1791	\| VOLATILE
1792	{ $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1793	\| ATOMIC
1794	{ $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1795	\| forall
1796	;
1797
1798	forall:
1799	FORALL '(' type_parameter_list ')' // CFA
1800	{ $$ = DeclarationNode::newForall( $3 ); }
1801	;
1802
1803	declaration_qualifier_list:
1804	storage_class_list
1805	\| type_qualifier_list storage_class_list // remaining OBSOLESCENT (see 2 )
1806	{ $$ = $1->addQualifiers( $2 ); }
1807	\| declaration_qualifier_list type_qualifier_list storage_class_list
1808	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1809	;
1810
1811	storage_class_list:
1812	// A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1813	// only one of each is specified, except for inline, which can appear with the others.
1814	//
1815	// ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1816	// specifiers in a declaration.
1817	storage_class
1818	\| storage_class_list storage_class
1819	{ $$ = $1->addQualifiers( $2 ); }
1820	;
1821
1822	storage_class:
1823	EXTERN
1824	{ $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1825	\| STATIC
1826	{ $$ = DeclarationNode::newStorageClass( Type::Static ); }
1827	\| AUTO
1828	{ $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1829	\| REGISTER
1830	{ $$ = DeclarationNode::newStorageClass( Type::Register ); }
1831	\| THREADLOCAL // C11
1832	{ $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1833	// Put function specifiers here to simplify parsing rules, but separate them semantically.
1834	\| INLINE // C99
1835	{ $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1836	\| FORTRAN // C99
1837	{ $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1838	\| NORETURN // C11
1839	{ $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1840	;
1841
1842	basic_type_name:
1843	VOID
1844	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1845	\| BOOL // C99
1846	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1847	\| CHAR
1848	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1849	\| INT
1850	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1851	\| INT128
1852	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1853	\| UINT128
1854	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 )->addType( DeclarationNode::newSignedNess( DeclarationNode::Unsigned ) ); }
1855	\| FLOAT
1856	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1857	\| DOUBLE
1858	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1859	\| uuFLOAT80
1860	{ $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
1861	\| uuFLOAT128
1862	{ $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
1863	\| uFLOAT16
1864	{ $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
1865	\| uFLOAT32
1866	{ $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
1867	\| uFLOAT32X
1868	{ $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
1869	\| uFLOAT64
1870	{ $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
1871	\| uFLOAT64X
1872	{ $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
1873	\| uFLOAT128
1874	{ $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
1875	\| COMPLEX // C99
1876	{ $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1877	\| IMAGINARY // C99
1878	{ $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1879	\| SIGNED
1880	{ $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1881	\| UNSIGNED
1882	{ $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1883	\| SHORT
1884	{ $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1885	\| LONG
1886	{ $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1887	\| VALIST // GCC, __builtin_va_list
1888	{ $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1889	\| AUTO_TYPE
1890	{ $$ = DeclarationNode::newBuiltinType( DeclarationNode::AutoType ); }
1891	;
1892
1893	basic_declaration_specifier:
1894	// A semantic check is necessary for conflicting storage classes.
1895	basic_type_specifier
1896	\| declaration_qualifier_list basic_type_specifier
1897	{ $$ = $2->addQualifiers( $1 ); }
1898	\| basic_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1899	{ $$ = $1->addQualifiers( $2 ); }
1900	\| basic_declaration_specifier storage_class type_qualifier_list
1901	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1902	\| basic_declaration_specifier storage_class basic_type_specifier
1903	{ $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1904	;
1905
1906	basic_type_specifier:
1907	direct_type
1908	// Cannot have type modifiers, e.g., short, long, etc.
1909	\| type_qualifier_list_opt indirect_type type_qualifier_list_opt
1910	{ $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1911	;
1912
1913	direct_type:
1914	basic_type_name
1915	\| type_qualifier_list basic_type_name
1916	{ $$ = $2->addQualifiers( $1 ); }
1917	\| direct_type type_qualifier
1918	{ $$ = $1->addQualifiers( $2 ); }
1919	\| direct_type basic_type_name
1920	{ $$ = $1->addType( $2 ); }
1921	;
1922
1923	indirect_type:
1924	TYPEOF '(' type ')' // GCC: typeof( x ) y;
1925	{ $$ = $3; }
1926	\| TYPEOF '(' comma_expression ')' // GCC: typeof( a+b ) y;
1927	{ $$ = DeclarationNode::newTypeof( $3 ); }
1928	\| BASETYPEOF '(' type ')' // CFA: basetypeof( x ) y;
1929	{ $$ = DeclarationNode::newTypeof( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ), true ); }
1930	\| BASETYPEOF '(' comma_expression ')' // CFA: basetypeof( a+b ) y;
1931	{ $$ = DeclarationNode::newTypeof( $3, true ); }
1932	\| ZERO_T // CFA
1933	{ $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1934	\| ONE_T // CFA
1935	{ $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1936	;
1937
1938	sue_declaration_specifier: // struct, union, enum + storage class + type specifier
1939	sue_type_specifier
1940	\| declaration_qualifier_list sue_type_specifier
1941	{ $$ = $2->addQualifiers( $1 ); }
1942	\| sue_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1943	{ $$ = $1->addQualifiers( $2 ); }
1944	\| sue_declaration_specifier storage_class type_qualifier_list
1945	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1946	;
1947
1948	sue_type_specifier: // struct, union, enum + type specifier
1949	elaborated_type
1950	\| type_qualifier_list
1951	{ if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1952	elaborated_type
1953	{ $$ = $3->addQualifiers( $1 ); }
1954	\| sue_type_specifier type_qualifier
1955	{
1956	if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
1957	$$ = $1->addQualifiers( $2 );
1958	}
1959	;
1960
1961	sue_declaration_specifier_nobody: // struct, union, enum - {...} + storage class + type specifier
1962	sue_type_specifier_nobody
1963	\| declaration_qualifier_list sue_type_specifier_nobody
1964	{ $$ = $2->addQualifiers( $1 ); }
1965	\| sue_declaration_specifier_nobody storage_class // remaining OBSOLESCENT (see 2)
1966	{ $$ = $1->addQualifiers( $2 ); }
1967	\| sue_declaration_specifier_nobody storage_class type_qualifier_list
1968	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1969	;
1970
1971	sue_type_specifier_nobody: // struct, union, enum - {...} + type specifier
1972	elaborated_type_nobody
1973	\| type_qualifier_list elaborated_type_nobody
1974	{ $$ = $2->addQualifiers( $1 ); }
1975	\| sue_type_specifier_nobody type_qualifier
1976	{ $$ = $1->addQualifiers( $2 ); }
1977	;
1978
1979	type_declaration_specifier:
1980	type_type_specifier
1981	\| declaration_qualifier_list type_type_specifier
1982	{ $$ = $2->addQualifiers( $1 ); }
1983	\| type_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1984	{ $$ = $1->addQualifiers( $2 ); }
1985	\| type_declaration_specifier storage_class type_qualifier_list
1986	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1987	;
1988
1989	type_type_specifier: // typedef types
1990	type_name
1991	\| type_qualifier_list type_name
1992	{ $$ = $2->addQualifiers( $1 ); }
1993	\| type_type_specifier type_qualifier
1994	{ $$ = $1->addQualifiers( $2 ); }
1995	;
1996
1997	type_name:
1998	TYPEDEFname
1999	{ $$ = DeclarationNode::newFromTypedef( $1 ); }
2000	\| '.' TYPEDEFname
2001	{ $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
2002	\| type_name '.' TYPEDEFname
2003	{ $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
2004	\| typegen_name
2005	\| '.' typegen_name
2006	{ $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
2007	\| type_name '.' typegen_name
2008	{ $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
2009	;
2010
2011	typegen_name: // CFA
2012	TYPEGENname
2013	{ $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2014	\| TYPEGENname '(' ')'
2015	{ $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2016	\| TYPEGENname '(' type_list ')'
2017	{ $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
2018	;
2019
2020	elaborated_type: // struct, union, enum
2021	aggregate_type
2022	\| enum_type
2023	;
2024
2025	elaborated_type_nobody: // struct, union, enum - {...}
2026	aggregate_type_nobody
2027	\| enum_type_nobody
2028	;
2029
2030	fred:
2031	// empty
2032	{ yyy = false; }
2033	;
2034
2035	aggregate_type: // struct, union
2036	aggregate_key attribute_list_opt
2037	{ forall = false; } // reset
2038	'{' field_declaration_list_opt '}' type_parameters_opt
2039	{ $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2040	\| aggregate_key attribute_list_opt identifier fred
2041	{
2042	typedefTable.makeTypedef( *$3, forall \|\| typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2043	forall = false; // reset
2044	}
2045	'{' field_declaration_list_opt '}' type_parameters_opt
2046	{ $$ = DeclarationNode::newAggregate( $1, $3, $9, $7, true )->addQualifiers( $2 ); }
2047	\| aggregate_key attribute_list_opt type_name fred
2048	{
2049	// for type_name can be a qualified type name S.T, in which case only the last name in the chain needs a typedef (other names in the chain should already have one)
2050	typedefTable.makeTypedef( *$3->type->leafName(), forall \|\| typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2051	forall = false; // reset
2052	}
2053	'{' field_declaration_list_opt '}' type_parameters_opt
2054	{ $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $9, $7, true )->addQualifiers( $2 ); }
2055	\| aggregate_type_nobody
2056	;
2057
2058	type_parameters_opt:
2059	// empty
2060	{ $$ = nullptr; } %prec '}'
2061	\| '(' type_list ')'
2062	{ $$ = $2; }
2063	;
2064
2065	aggregate_type_nobody: // struct, union - {...}
2066	aggregate_key attribute_list_opt identifier fred
2067	{
2068	typedefTable.makeTypedef( *$3, forall \|\| typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname );
2069	forall = false; // reset
2070	$$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2071	}
2072	\| aggregate_key attribute_list_opt type_name fred
2073	{
2074	forall = false; // reset
2075	// Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2076	// switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2077	// delete newFromTypeGen.
2078	$$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2079	$3->type->symbolic.name = nullptr;
2080	$3->type->symbolic.actuals = nullptr;
2081	delete $3;
2082	}
2083	;
2084
2085	aggregate_key:
2086	aggregate_data
2087	\| aggregate_control
2088	;
2089
2090	aggregate_data:
2091	STRUCT
2092	{ yyy = true; $$ = AggregateDecl::Struct; }
2093	\| UNION
2094	{ yyy = true; $$ = AggregateDecl::Union; }
2095	\| EXCEPTION // CFA
2096	{ yyy = true; $$ = AggregateDecl::Exception; }
2097	;
2098
2099	aggregate_control: // CFA
2100	MONITOR
2101	{ yyy = true; $$ = AggregateDecl::Monitor; }
2102	\| MUTEX STRUCT
2103	{ yyy = true; $$ = AggregateDecl::Monitor; }
2104	\| GENERATOR
2105	{ yyy = true; $$ = AggregateDecl::Generator; }
2106	\| MUTEX GENERATOR
2107	{ SemanticError( yylloc, "monitor generator is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2108	\| COROUTINE
2109	{ yyy = true; $$ = AggregateDecl::Coroutine; }
2110	\| MUTEX COROUTINE
2111	{ SemanticError( yylloc, "monitor coroutine is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2112	\| THREAD
2113	{ yyy = true; $$ = AggregateDecl::Thread; }
2114	\| MUTEX THREAD
2115	{ SemanticError( yylloc, "monitor thread is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2116	;
2117
2118	field_declaration_list_opt:
2119	// empty
2120	{ $$ = nullptr; }
2121	\| field_declaration_list_opt field_declaration
2122	{ $$ = $1 ? $1->appendList( $2 ) : $2; }
2123	;
2124
2125	field_declaration:
2126	type_specifier field_declaring_list_opt ';'
2127	{ $$ = fieldDecl( $1, $2 ); }
2128	\| EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2129	{ $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2130	\| INLINE type_specifier field_abstract_list_opt ';' // CFA
2131	{
2132	if ( ! $3 ) { // field declarator ?
2133	$3 = DeclarationNode::newName( nullptr );
2134	} // if
2135	$3->inLine = true;
2136	$$ = distAttr( $2, $3 ); // mark all fields in list
2137	distInl( $3 );
2138	}
2139	\| INLINE aggregate_control ';' // CFA
2140	{ SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2141	\| typedef_declaration ';' // CFA
2142	\| cfa_field_declaring_list ';' // CFA, new style field declaration
2143	\| EXTENSION cfa_field_declaring_list ';' // GCC
2144	{ distExt( $2 ); $$ = $2; } // mark all fields in list
2145	\| INLINE cfa_field_abstract_list ';' // CFA, new style field declaration
2146	{ $$ = $2; } // mark all fields in list
2147	\| cfa_typedef_declaration ';' // CFA
2148	\| static_assert // C11
2149	;
2150
2151	field_declaring_list_opt:
2152	// empty
2153	{ $$ = nullptr; }
2154	\| field_declarator
2155	\| field_declaring_list_opt ',' attribute_list_opt field_declarator
2156	{ $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2157	;
2158
2159	field_declarator:
2160	bit_subrange_size // C special case, no field name
2161	{ $$ = DeclarationNode::newBitfield( $1 ); }
2162	\| variable_declarator bit_subrange_size_opt
2163	// A semantic check is required to ensure bit_subrange only appears on integral types.
2164	{ $$ = $1->addBitfield( $2 ); }
2165	\| variable_type_redeclarator bit_subrange_size_opt
2166	// A semantic check is required to ensure bit_subrange only appears on integral types.
2167	{ $$ = $1->addBitfield( $2 ); }
2168	;
2169
2170	field_abstract_list_opt:
2171	// empty
2172	{ $$ = nullptr; }
2173	\| field_abstract
2174	\| field_abstract_list_opt ',' attribute_list_opt field_abstract
2175	{ $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2176	;
2177
2178	field_abstract:
2179	// no bit fields
2180	variable_abstract_declarator
2181	;
2182
2183	cfa_field_declaring_list: // CFA, new style field declaration
2184	// bit-fields are handled by C declarations
2185	cfa_abstract_declarator_tuple identifier_or_type_name
2186	{ $$ = $1->addName( $2 ); }
2187	\| cfa_field_declaring_list ',' identifier_or_type_name
2188	{ $$ = $1->appendList( $1->cloneType( $3 ) ); }
2189	;
2190
2191	cfa_field_abstract_list: // CFA, new style field declaration
2192	// bit-fields are handled by C declarations
2193	cfa_abstract_declarator_tuple
2194	\| cfa_field_abstract_list ','
2195	{ $$ = $1->appendList( $1->cloneType( 0 ) ); }
2196	;
2197
2198	bit_subrange_size_opt:
2199	// empty
2200	{ $$ = nullptr; }
2201	\| bit_subrange_size
2202	;
2203
2204	bit_subrange_size:
2205	':' assignment_expression
2206	{ $$ = $2; }
2207	;
2208
2209	enum_type: // enum
2210	ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2211	{ $$ = DeclarationNode::newEnum( nullptr, $4, true )->addQualifiers( $2 ); }
2212	\| ENUM attribute_list_opt identifier
2213	{ typedefTable.makeTypedef( *$3 ); }
2214	'{' enumerator_list comma_opt '}'
2215	{ $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
2216	\| ENUM attribute_list_opt type_name
2217	'{' enumerator_list comma_opt '}'
2218	{ $$ = DeclarationNode::newEnum( $3->type->symbolic.name, $5, true )->addQualifiers( $2 ); }
2219	\| enum_type_nobody
2220	;
2221
2222	enum_type_nobody: // enum - {...}
2223	ENUM attribute_list_opt identifier
2224	{
2225	typedefTable.makeTypedef( *$3 );
2226	$$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 );
2227	}
2228	\| ENUM attribute_list_opt type_name
2229	{
2230	typedefTable.makeTypedef( *$3->type->symbolic.name );
2231	$$ = DeclarationNode::newEnum( $3->type->symbolic.name, 0, false )->addQualifiers( $2 );
2232	}
2233	;
2234
2235	enumerator_list:
2236	identifier_or_type_name enumerator_value_opt
2237	{ $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
2238	\| enumerator_list ',' identifier_or_type_name enumerator_value_opt
2239	{ $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
2240	;
2241
2242	enumerator_value_opt:
2243	// empty
2244	{ $$ = nullptr; }
2245	\| '=' constant_expression
2246	{ $$ = $2; }
2247	;
2248
2249	cfa_parameter_ellipsis_list_opt: // CFA, abstract + real
2250	// empty
2251	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2252	\| ELLIPSIS
2253	{ $$ = nullptr; }
2254	\| cfa_abstract_parameter_list
2255	\| cfa_parameter_list
2256	\| cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2257	{ $$ = $1->appendList( $5 ); }
2258	\| cfa_abstract_parameter_list pop ',' push ELLIPSIS
2259	{ $$ = $1->addVarArgs(); }
2260	\| cfa_parameter_list pop ',' push ELLIPSIS
2261	{ $$ = $1->addVarArgs(); }
2262	;
2263
2264	cfa_parameter_list: // CFA
2265	// To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2266	// factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2267	cfa_parameter_declaration
2268	\| cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2269	{ $$ = $1->appendList( $5 ); }
2270	\| cfa_parameter_list pop ',' push cfa_parameter_declaration
2271	{ $$ = $1->appendList( $5 ); }
2272	\| cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2273	{ $$ = $1->appendList( $5 )->appendList( $9 ); }
2274	;
2275
2276	cfa_abstract_parameter_list: // CFA, new & old style abstract
2277	cfa_abstract_parameter_declaration
2278	\| cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2279	{ $$ = $1->appendList( $5 ); }
2280	;
2281
2282	parameter_type_list_opt:
2283	// empty
2284	{ $$ = nullptr; }
2285	\| ELLIPSIS
2286	{ $$ = nullptr; }
2287	\| parameter_list
2288	\| parameter_list pop ',' push ELLIPSIS
2289	{ $$ = $1->addVarArgs(); }
2290	;
2291
2292	parameter_list: // abstract + real
2293	abstract_parameter_declaration
2294	\| parameter_declaration
2295	\| parameter_list pop ',' push abstract_parameter_declaration
2296	{ $$ = $1->appendList( $5 ); }
2297	\| parameter_list pop ',' push parameter_declaration
2298	{ $$ = $1->appendList( $5 ); }
2299	;
2300
2301	// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2302	// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2303
2304	cfa_parameter_declaration: // CFA, new & old style parameter declaration
2305	parameter_declaration
2306	\| cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initialize_opt
2307	{ $$ = $1->addName( $2 ); }
2308	\| cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2309	// To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2310	{ $$ = $1->addName( $2 ); }
2311	\| type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2312	{ $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2313	\| cfa_function_specifier
2314	;
2315
2316	cfa_abstract_parameter_declaration: // CFA, new & old style parameter declaration
2317	abstract_parameter_declaration
2318	\| cfa_identifier_parameter_declarator_no_tuple
2319	\| cfa_abstract_tuple
2320	// To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2321	\| type_qualifier_list cfa_abstract_tuple
2322	{ $$ = $2->addQualifiers( $1 ); }
2323	\| cfa_abstract_function
2324	;
2325
2326	parameter_declaration:
2327	// No SUE declaration in parameter list.
2328	declaration_specifier_nobody identifier_parameter_declarator default_initialize_opt
2329	{ $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2330	\| declaration_specifier_nobody type_parameter_redeclarator default_initialize_opt
2331	{ $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2332	;
2333
2334	abstract_parameter_declaration:
2335	declaration_specifier_nobody default_initialize_opt
2336	{ $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2337	\| declaration_specifier_nobody abstract_parameter_declarator default_initialize_opt
2338	{ $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2339	;
2340
2341	// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2342	// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2343	// identifiers. The ANSI-style parameter-list can redefine a typedef name.
2344
2345	identifier_list: // K&R-style parameter list => no types
2346	identifier
2347	{ $$ = DeclarationNode::newName( $1 ); }
2348	\| identifier_list ',' identifier
2349	{ $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2350	;
2351
2352	identifier_or_type_name:
2353	identifier
2354	\| TYPEDEFname
2355	\| TYPEGENname
2356	;
2357
2358	type_no_function: // sizeof, alignof, cast (constructor)
2359	cfa_abstract_declarator_tuple // CFA
2360	\| type_specifier
2361	\| type_specifier abstract_declarator
2362	{ $$ = $2->addType( $1 ); }
2363	;
2364
2365	type: // typeof, assertion
2366	type_no_function
2367	\| cfa_abstract_function // CFA
2368	;
2369
2370	initializer_opt:
2371	// empty
2372	{ $$ = nullptr; }
2373	\| '=' initializer
2374	{ $$ = $2; }
2375	\| '=' VOID
2376	{ $$ = new InitializerNode( true ); }
2377	\| ATassign initializer
2378	{ $$ = $2->set_maybeConstructed( false ); }
2379	;
2380
2381	initializer:
2382	assignment_expression { $$ = new InitializerNode( $1 ); }
2383	\| '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
2384	;
2385
2386	initializer_list_opt:
2387	// empty
2388	{ $$ = nullptr; }
2389	\| initializer
2390	\| designation initializer { $$ = $2->set_designators( $1 ); }
2391	\| initializer_list_opt ',' initializer { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2392	\| initializer_list_opt ',' designation initializer
2393	{ $$ = (InitializerNode *)($1->set_last( $4->set_designators( $3 ) )); }
2394	;
2395
2396	// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2397	// '=' to separator the designator from the initializer value, as in:
2398	//
2399	// int x[10] = { [1] = 3 };
2400	//
2401	// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment. To disambiguate this case, CFA
2402	// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2403	// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2404	// shift/reduce conflicts
2405
2406	designation:
2407	designator_list ':' // C99, CFA uses ":" instead of "="
2408	\| identifier ':' // GCC, field name
2409	{ $$ = new ExpressionNode( build_varref( $1 ) ); }
2410	;
2411
2412	designator_list: // C99
2413	designator
2414	\| designator_list designator
2415	{ $$ = (ExpressionNode *)($1->set_last( $2 )); }
2416	//\| designator_list designator { $$ = new ExpressionNode( $1, $2 ); }
2417	;
2418
2419	designator:
2420	'.' identifier // C99, field name
2421	{ $$ = new ExpressionNode( build_varref( $2 ) ); }
2422	\| '[' push assignment_expression pop ']' // C99, single array element
2423	// assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2424	{ $$ = $3; }
2425	\| '[' push subrange pop ']' // CFA, multiple array elements
2426	{ $$ = $3; }
2427	\| '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2428	{ $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $3 ), maybeMoveBuild< Expression >( $5 ) ) ); }
2429	\| '.' '[' push field_name_list pop ']' // CFA, tuple field selector
2430	{ $$ = $4; }
2431	;
2432
2433	// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2434	// rather than an object-oriented type system. This required four groups of extensions:
2435	//
2436	// Overloading: function, data, and operator identifiers may be overloaded.
2437	//
2438	// Type declarations: "type" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2439	// and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2440	// definitions of new types. Type declarations with storage class "extern" provide opaque types.
2441	//
2442	// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2443	// site. A polymorphic function is not a template; it is a function, with an address and a type.
2444	//
2445	// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2446	// types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2447	// hierarchies. Unlike classes, they can define relationships between types. Assertions declare that a type or
2448	// types provide the operations declared by a specification. Assertions are normally used to declare requirements
2449	// on type arguments of polymorphic functions.
2450
2451	type_parameter_list: // CFA
2452	type_parameter
2453	\| type_parameter_list ',' type_parameter
2454	{ $$ = $1->appendList( $3 ); }
2455	;
2456
2457	type_initializer_opt: // CFA
2458	// empty
2459	{ $$ = nullptr; }
2460	\| '=' type
2461	{ $$ = $2; }
2462	;
2463
2464	type_parameter: // CFA
2465	type_class identifier_or_type_name
2466	{ typedefTable.addToScope( *$2, TYPEDEFname, "9" ); }
2467	type_initializer_opt assertion_list_opt
2468	{ $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2469	\| type_specifier identifier_parameter_declarator
2470	\| assertion_list
2471	{ $$ = DeclarationNode::newTypeParam( TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2472	;
2473
2474	type_class: // CFA
2475	OTYPE
2476	{ $$ = TypeDecl::Otype; }
2477	\| DTYPE
2478	{ $$ = TypeDecl::Dtype; }
2479	\| FTYPE
2480	{ $$ = TypeDecl::Ftype; }
2481	\| TTYPE
2482	{ $$ = TypeDecl::Ttype; }
2483	;
2484
2485	assertion_list_opt: // CFA
2486	// empty
2487	{ $$ = nullptr; }
2488	\| assertion_list
2489	;
2490
2491	assertion_list: // CFA
2492	assertion
2493	\| assertion_list assertion
2494	{ $$ = $1 ? $1->appendList( $2 ) : $2; }
2495	;
2496
2497	assertion: // CFA
2498	'\|' identifier_or_type_name '(' type_list ')'
2499	{ $$ = DeclarationNode::newTraitUse( $2, $4 ); }
2500	\| '\|' '{' push trait_declaration_list pop '}'
2501	{ $$ = $4; }
2502	// \| '\|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
2503	// { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
2504	;
2505
2506	type_list: // CFA
2507	type
2508	{ $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2509	\| assignment_expression
2510	{ SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $1->build()) ); $$ = nullptr; }
2511	\| type_list ',' type
2512	{ $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) )); }
2513	\| type_list ',' assignment_expression
2514	{ SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $3->build()) ); $$ = nullptr; }
2515	// { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2516	;
2517
2518	type_declaring_list: // CFA
2519	OTYPE type_declarator
2520	{ $$ = $2; }
2521	\| storage_class_list OTYPE type_declarator
2522	{ $$ = $3->addQualifiers( $1 ); }
2523	\| type_declaring_list ',' type_declarator
2524	{ $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2525	;
2526
2527	type_declarator: // CFA
2528	type_declarator_name assertion_list_opt
2529	{ $$ = $1->addAssertions( $2 ); }
2530	\| type_declarator_name assertion_list_opt '=' type
2531	{ $$ = $1->addAssertions( $2 )->addType( $4 ); }
2532	;
2533
2534	type_declarator_name: // CFA
2535	identifier_or_type_name
2536	{
2537	typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "10" );
2538	$$ = DeclarationNode::newTypeDecl( $1, 0 );
2539	}
2540	\| identifier_or_type_name '(' type_parameter_list ')'
2541	{
2542	typedefTable.addToEnclosingScope( *$1, TYPEGENname, "11" );
2543	$$ = DeclarationNode::newTypeDecl( $1, $3 );
2544	}
2545	;
2546
2547	trait_specifier: // CFA
2548	TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
2549	{ $$ = DeclarationNode::newTrait( $2, $4, 0 ); }
2550	\| TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
2551	{ $$ = DeclarationNode::newTrait( $2, $4, $8 ); }
2552	;
2553
2554	trait_declaration_list: // CFA
2555	trait_declaration
2556	\| trait_declaration_list pop push trait_declaration
2557	{ $$ = $1->appendList( $4 ); }
2558	;
2559
2560	trait_declaration: // CFA
2561	cfa_trait_declaring_list ';'
2562	\| trait_declaring_list ';'
2563	;
2564
2565	cfa_trait_declaring_list: // CFA
2566	cfa_variable_specifier
2567	\| cfa_function_specifier
2568	\| cfa_trait_declaring_list pop ',' push identifier_or_type_name
2569	{ $$ = $1->appendList( $1->cloneType( $5 ) ); }
2570	;
2571
2572	trait_declaring_list: // CFA
2573	type_specifier declarator
2574	{ $$ = $2->addType( $1 ); }
2575	\| trait_declaring_list pop ',' push declarator
2576	{ $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
2577	;
2578
2579	//*************************** EXTERNAL DEFINITIONS ***************************
2580
2581	translation_unit:
2582	// empty, input file
2583	\| external_definition_list
2584	{ parseTree = parseTree ? parseTree->appendList( $1 ) : $1; }
2585	;
2586
2587	external_definition_list:
2588	push external_definition pop
2589	{ $$ = $2; }
2590	\| external_definition_list push external_definition pop
2591	{ $$ = $1 ? $1->appendList( $3 ) : $3; }
2592	;
2593
2594	external_definition_list_opt:
2595	// empty
2596	{ $$ = nullptr; }
2597	\| external_definition_list
2598	;
2599
2600	up:
2601	{ typedefTable.up( forall ); forall = false; }
2602	;
2603
2604	down:
2605	{ typedefTable.down(); }
2606	;
2607
2608	external_definition:
2609	declaration
2610	\| external_function_definition
2611	\| EXTENSION external_definition // GCC, multiple __extension__ allowed, meaning unknown
2612	{
2613	distExt( $2 ); // mark all fields in list
2614	$$ = $2;
2615	}
2616	\| ASM '(' string_literal ')' ';' // GCC, global assembler statement
2617	{
2618	$$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( false, $3, 0 ) ) );
2619	}
2620	\| EXTERN STRINGliteral // C++-style linkage specifier
2621	{
2622	linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
2623	linkage = LinkageSpec::update( yylloc, linkage, $2 );
2624	}
2625	'{' up external_definition_list_opt down '}'
2626	{
2627	linkage = linkageStack.top();
2628	linkageStack.pop();
2629	$$ = $6;
2630	}
2631	\| type_qualifier_list
2632	{
2633	if ( $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2634	if ( $1->type->forall ) forall = true; // remember generic type
2635	}
2636	'{' up external_definition_list_opt down '}' // CFA, namespace
2637	{
2638	distQual( $5, $1 );
2639	forall = false;
2640	$$ = $5;
2641	}
2642	\| declaration_qualifier_list
2643	{
2644	if ( $1->type && $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2645	if ( $1->type && $1->type->forall ) forall = true; // remember generic type
2646	}
2647	'{' up external_definition_list_opt down '}' // CFA, namespace
2648	{
2649	distQual( $5, $1 );
2650	forall = false;
2651	$$ = $5;
2652	}
2653	\| declaration_qualifier_list type_qualifier_list
2654	{
2655	if ( ($1->type && $1->type->qualifiers.val) \|\| $2->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2656	if ( ($1->type && $1->type->forall) \|\| $2->type->forall ) forall = true; // remember generic type
2657	}
2658	'{' up external_definition_list_opt down '}' // CFA, namespace
2659	{
2660	distQual( $6, $1->addQualifiers( $2 ) );
2661	forall = false;
2662	$$ = $6;
2663	}
2664	;
2665
2666	external_function_definition:
2667	function_definition
2668	// These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2669	// legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2670	// Parsing is possible because function_definition does not appear in the context of an expression (nested
2671	// functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2672	// declaration must still have a type_specifier. OBSOLESCENT (see 1)
2673	\| function_declarator compound_statement
2674	{ $$ = $1->addFunctionBody( $2 ); }
2675	\| KR_function_declarator KR_parameter_list_opt compound_statement
2676	{ $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
2677	;
2678
2679	with_clause_opt:
2680	// empty
2681	{ $$ = nullptr; forall = false; }
2682	\| WITH '(' tuple_expression_list ')'
2683	{ $$ = $3; forall = false; }
2684	;
2685
2686	function_definition:
2687	cfa_function_declaration with_clause_opt compound_statement // CFA
2688	{
2689	// Add the function body to the last identifier in the function definition list, i.e., foo3:
2690	// [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2691	$1->get_last()->addFunctionBody( $3, $2 );
2692	$$ = $1;
2693	}
2694	\| declaration_specifier function_declarator with_clause_opt compound_statement
2695	{
2696	rebindForall( $1, $2 );
2697	$$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2698	}
2699	\| declaration_specifier variable_type_redeclarator with_clause_opt compound_statement
2700	{
2701	rebindForall( $1, $2 );
2702	$$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2703	}
2704	// handles default int return type, OBSOLESCENT (see 1)
2705	\| type_qualifier_list function_declarator with_clause_opt compound_statement
2706	{ $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2707	// handles default int return type, OBSOLESCENT (see 1)
2708	\| declaration_qualifier_list function_declarator with_clause_opt compound_statement
2709	{ $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2710	// handles default int return type, OBSOLESCENT (see 1)
2711	\| declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2712	{ $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2713
2714	// Old-style K&R function definition, OBSOLESCENT (see 4)
2715	\| declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2716	{
2717	rebindForall( $1, $2 );
2718	$$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2719	}
2720	// handles default int return type, OBSOLESCENT (see 1)
2721	\| type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2722	{ $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2723	// handles default int return type, OBSOLESCENT (see 1)
2724	\| declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2725	{ $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2726	// handles default int return type, OBSOLESCENT (see 1)
2727	\| declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2728	{ $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2729	;
2730
2731	declarator:
2732	variable_declarator
2733	\| variable_type_redeclarator
2734	\| function_declarator
2735	;
2736
2737	subrange:
2738	constant_expression '~' constant_expression // CFA, integer subrange
2739	{ $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
2740	;
2741
2742	asm_name_opt: // GCC
2743	// empty
2744	{ $$ = nullptr; }
2745	\| ASM '(' string_literal ')' attribute_list_opt
2746	{
2747	DeclarationNode * name = new DeclarationNode();
2748	name->asmName = $3;
2749	$$ = name->addQualifiers( $5 );
2750	}
2751	;
2752
2753	attribute_list_opt: // GCC
2754	// empty
2755	{ $$ = nullptr; }
2756	\| attribute_list
2757	;
2758
2759	attribute_list: // GCC
2760	attribute
2761	\| attribute_list attribute
2762	{ $$ = $2->addQualifiers( $1 ); }
2763	;
2764
2765	attribute: // GCC
2766	ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2767	{ $$ = $4; }
2768	;
2769
2770	attribute_name_list: // GCC
2771	attribute_name
2772	\| attribute_name_list ',' attribute_name
2773	{ $$ = $3->addQualifiers( $1 ); }
2774	;
2775
2776	attribute_name: // GCC
2777	// empty
2778	{ $$ = nullptr; }
2779	\| attr_name
2780	{ $$ = DeclarationNode::newAttribute( $1 ); }
2781	\| attr_name '(' argument_expression_list_opt ')'
2782	{ $$ = DeclarationNode::newAttribute( $1, $3 ); }
2783	;
2784
2785	attr_name: // GCC
2786	IDENTIFIER
2787	\| quasi_keyword
2788	\| TYPEDEFname
2789	\| TYPEGENname
2790	\| FALLTHROUGH
2791	{ $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2792	\| CONST
2793	{ $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2794	;
2795
2796	// ============================================================================
2797	// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2798	// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2799	// in:
2800	//
2801	// int (*f())[10] { ... };
2802	// ... (*f())[3] += 1; // definition mimics usage
2803	//
2804	// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2805	// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2806	// ============================================================================
2807
2808	// ----------------------------------------------------------------------------
2809	// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2810	// to define a variable or function prototype, e.g.:
2811	//
2812	// valid declaration invalid definition
2813	// ----------------- ------------------
2814	// int f; int f {}
2815	// int f; int f {}
2816	// int f[10]; int f[10] {}
2817	// int (f)(int); int (f)(int) {}
2818	//
2819	// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2820	// variable_declarator and function_declarator.
2821	// ----------------------------------------------------------------------------
2822
2823	// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2824	// declaring an array of functions versus a pointer to an array of functions.
2825
2826	variable_declarator:
2827	paren_identifier attribute_list_opt
2828	{ $$ = $1->addQualifiers( $2 ); }
2829	\| variable_ptr
2830	\| variable_array attribute_list_opt
2831	{ $$ = $1->addQualifiers( $2 ); }
2832	\| variable_function attribute_list_opt
2833	{ $$ = $1->addQualifiers( $2 ); }
2834	;
2835
2836	paren_identifier:
2837	identifier
2838	{ $$ = DeclarationNode::newName( $1 ); }
2839	\| '(' paren_identifier ')' // redundant parenthesis
2840	{ $$ = $2; }
2841	;
2842
2843	variable_ptr:
2844	ptrref_operator variable_declarator
2845	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2846	\| ptrref_operator type_qualifier_list variable_declarator
2847	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2848	\| '(' variable_ptr ')' attribute_list_opt
2849	{ $$ = $2->addQualifiers( $4 ); } // redundant parenthesis
2850	;
2851
2852	variable_array:
2853	paren_identifier array_dimension
2854	{ $$ = $1->addArray( $2 ); }
2855	\| '(' variable_ptr ')' array_dimension
2856	{ $$ = $2->addArray( $4 ); }
2857	\| '(' variable_array ')' multi_array_dimension // redundant parenthesis
2858	{ $$ = $2->addArray( $4 ); }
2859	\| '(' variable_array ')' // redundant parenthesis
2860	{ $$ = $2; }
2861	;
2862
2863	variable_function:
2864	'(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2865	{ $$ = $2->addParamList( $6 ); }
2866	\| '(' variable_function ')' // redundant parenthesis
2867	{ $$ = $2; }
2868	;
2869
2870	// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2871	// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2872	// is the same scope. The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2873
2874	function_declarator:
2875	function_no_ptr attribute_list_opt
2876	{ $$ = $1->addQualifiers( $2 ); }
2877	\| function_ptr
2878	\| function_array attribute_list_opt
2879	{ $$ = $1->addQualifiers( $2 ); }
2880	;
2881
2882	function_no_ptr:
2883	paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2884	{ $$ = $1->addParamList( $4 ); }
2885	\| '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2886	{ $$ = $2->addParamList( $6 ); }
2887	\| '(' function_no_ptr ')' // redundant parenthesis
2888	{ $$ = $2; }
2889	;
2890
2891	function_ptr:
2892	ptrref_operator function_declarator
2893	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2894	\| ptrref_operator type_qualifier_list function_declarator
2895	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2896	\| '(' function_ptr ')'
2897	{ $$ = $2; }
2898	;
2899
2900	function_array:
2901	'(' function_ptr ')' array_dimension
2902	{ $$ = $2->addArray( $4 ); }
2903	\| '(' function_array ')' multi_array_dimension // redundant parenthesis
2904	{ $$ = $2->addArray( $4 ); }
2905	\| '(' function_array ')' // redundant parenthesis
2906	{ $$ = $2; }
2907	;
2908
2909	// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
2910	//
2911	// f( a, b, c ) int a, *b, c[]; {}
2912	//
2913	// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
2914	// returning arrays and functions versus pointers to arrays and functions.
2915
2916	KR_function_declarator:
2917	KR_function_no_ptr
2918	\| KR_function_ptr
2919	\| KR_function_array
2920	;
2921
2922	KR_function_no_ptr:
2923	paren_identifier '(' identifier_list ')' // function_declarator handles empty parameter
2924	{ $$ = $1->addIdList( $3 ); }
2925	\| '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
2926	{ $$ = $2->addParamList( $6 ); }
2927	\| '(' KR_function_no_ptr ')' // redundant parenthesis
2928	{ $$ = $2; }
2929	;
2930
2931	KR_function_ptr:
2932	ptrref_operator KR_function_declarator
2933	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2934	\| ptrref_operator type_qualifier_list KR_function_declarator
2935	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2936	\| '(' KR_function_ptr ')'
2937	{ $$ = $2; }
2938	;
2939
2940	KR_function_array:
2941	'(' KR_function_ptr ')' array_dimension
2942	{ $$ = $2->addArray( $4 ); }
2943	\| '(' KR_function_array ')' multi_array_dimension // redundant parenthesis
2944	{ $$ = $2->addArray( $4 ); }
2945	\| '(' KR_function_array ')' // redundant parenthesis
2946	{ $$ = $2; }
2947	;
2948
2949	// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2950	//
2951	// typedef int foo;
2952	// {
2953	// int foo; // redefine typedef name in new scope
2954	// }
2955	//
2956	// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2957	// and functions versus pointers to arrays and functions.
2958
2959	variable_type_redeclarator:
2960	paren_type attribute_list_opt
2961	{ $$ = $1->addQualifiers( $2 ); }
2962	\| type_ptr
2963	\| type_array attribute_list_opt
2964	{ $$ = $1->addQualifiers( $2 ); }
2965	\| type_function attribute_list_opt
2966	{ $$ = $1->addQualifiers( $2 ); }
2967	;
2968
2969	paren_type:
2970	typedef
2971	// hide type name in enclosing scope by variable name
2972	{
2973	// if ( ! typedefTable.existsCurr( *$1->name ) ) {
2974	typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "ID" );
2975	// } else {
2976	// SemanticError( yylloc, string("'") + *$1->name + "' redeclared as different kind of symbol." ); $$ = nullptr;
2977	// } // if
2978	}
2979	\| '(' paren_type ')'
2980	{ $$ = $2; }
2981	;
2982
2983	type_ptr:
2984	ptrref_operator variable_type_redeclarator
2985	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2986	\| ptrref_operator type_qualifier_list variable_type_redeclarator
2987	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2988	\| '(' type_ptr ')' attribute_list_opt
2989	{ $$ = $2->addQualifiers( $4 ); } // redundant parenthesis
2990	;
2991
2992	type_array:
2993	paren_type array_dimension
2994	{ $$ = $1->addArray( $2 ); }
2995	\| '(' type_ptr ')' array_dimension
2996	{ $$ = $2->addArray( $4 ); }
2997	\| '(' type_array ')' multi_array_dimension // redundant parenthesis
2998	{ $$ = $2->addArray( $4 ); }
2999	\| '(' type_array ')' // redundant parenthesis
3000	{ $$ = $2; }
3001	;
3002
3003	type_function:
3004	paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3005	{ $$ = $1->addParamList( $4 ); }
3006	\| '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3007	{ $$ = $2->addParamList( $6 ); }
3008	\| '(' type_function ')' // redundant parenthesis
3009	{ $$ = $2; }
3010	;
3011
3012	// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
3013	// typedef name and allows the C99 array options, which can only appear in a parameter list. The pattern precludes
3014	// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
3015	// pointers to arrays and functions.
3016
3017	identifier_parameter_declarator:
3018	paren_identifier attribute_list_opt
3019	{ $$ = $1->addQualifiers( $2 ); }
3020	\| '&' MUTEX paren_identifier attribute_list_opt
3021	{ $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3022	\| identifier_parameter_ptr
3023	\| identifier_parameter_array attribute_list_opt
3024	{ $$ = $1->addQualifiers( $2 ); }
3025	\| identifier_parameter_function attribute_list_opt
3026	{ $$ = $1->addQualifiers( $2 ); }
3027	;
3028
3029	identifier_parameter_ptr:
3030	ptrref_operator identifier_parameter_declarator
3031	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3032	\| ptrref_operator type_qualifier_list identifier_parameter_declarator
3033	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3034	\| '(' identifier_parameter_ptr ')' attribute_list_opt
3035	{ $$ = $2->addQualifiers( $4 ); }
3036	;
3037
3038	identifier_parameter_array:
3039	paren_identifier array_parameter_dimension
3040	{ $$ = $1->addArray( $2 ); }
3041	\| '(' identifier_parameter_ptr ')' array_dimension
3042	{ $$ = $2->addArray( $4 ); }
3043	\| '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3044	{ $$ = $2->addArray( $4 ); }
3045	\| '(' identifier_parameter_array ')' // redundant parenthesis
3046	{ $$ = $2; }
3047	;
3048
3049	identifier_parameter_function:
3050	paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3051	{ $$ = $1->addParamList( $4 ); }
3052	\| '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3053	{ $$ = $2->addParamList( $6 ); }
3054	\| '(' identifier_parameter_function ')' // redundant parenthesis
3055	{ $$ = $2; }
3056	;
3057
3058	// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3059	// e.g.:
3060	//
3061	// typedef int foo;
3062	// forall( otype T ) struct foo;
3063	// int f( int foo ); // redefine typedef name in new scope
3064	//
3065	// and allows the C99 array options, which can only appear in a parameter list.
3066
3067	type_parameter_redeclarator:
3068	typedef attribute_list_opt
3069	{ $$ = $1->addQualifiers( $2 ); }
3070	\| '&' MUTEX typedef attribute_list_opt
3071	{ $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3072	\| type_parameter_ptr
3073	\| type_parameter_array attribute_list_opt
3074	{ $$ = $1->addQualifiers( $2 ); }
3075	\| type_parameter_function attribute_list_opt
3076	{ $$ = $1->addQualifiers( $2 ); }
3077	;
3078
3079	typedef:
3080	TYPEDEFname
3081	{ $$ = DeclarationNode::newName( $1 ); }
3082	\| TYPEGENname
3083	{ $$ = DeclarationNode::newName( $1 ); }
3084	;
3085
3086	type_parameter_ptr:
3087	ptrref_operator type_parameter_redeclarator
3088	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3089	\| ptrref_operator type_qualifier_list type_parameter_redeclarator
3090	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3091	\| '(' type_parameter_ptr ')' attribute_list_opt
3092	{ $$ = $2->addQualifiers( $4 ); }
3093	;
3094
3095	type_parameter_array:
3096	typedef array_parameter_dimension
3097	{ $$ = $1->addArray( $2 ); }
3098	\| '(' type_parameter_ptr ')' array_parameter_dimension
3099	{ $$ = $2->addArray( $4 ); }
3100	;
3101
3102	type_parameter_function:
3103	typedef '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3104	{ $$ = $1->addParamList( $4 ); }
3105	\| '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3106	{ $$ = $2->addParamList( $6 ); }
3107	;
3108
3109	// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3110	// which the type applies, e.g.:
3111	//
3112	// sizeof( int );
3113	// sizeof( int * );
3114	// sizeof( int [10] );
3115	// sizeof( int (*)() );
3116	// sizeof( int () );
3117	//
3118	// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3119	// and functions versus pointers to arrays and functions.
3120
3121	abstract_declarator:
3122	abstract_ptr
3123	\| abstract_array attribute_list_opt
3124	{ $$ = $1->addQualifiers( $2 ); }
3125	\| abstract_function attribute_list_opt
3126	{ $$ = $1->addQualifiers( $2 ); }
3127	;
3128
3129	abstract_ptr:
3130	ptrref_operator
3131	{ $$ = DeclarationNode::newPointer( 0, $1 ); }
3132	\| ptrref_operator type_qualifier_list
3133	{ $$ = DeclarationNode::newPointer( $2, $1 ); }
3134	\| ptrref_operator abstract_declarator
3135	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3136	\| ptrref_operator type_qualifier_list abstract_declarator
3137	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3138	\| '(' abstract_ptr ')' attribute_list_opt
3139	{ $$ = $2->addQualifiers( $4 ); }
3140	;
3141
3142	abstract_array:
3143	array_dimension
3144	\| '(' abstract_ptr ')' array_dimension
3145	{ $$ = $2->addArray( $4 ); }
3146	\| '(' abstract_array ')' multi_array_dimension // redundant parenthesis
3147	{ $$ = $2->addArray( $4 ); }
3148	\| '(' abstract_array ')' // redundant parenthesis
3149	{ $$ = $2; }
3150	;
3151
3152	abstract_function:
3153	'(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3154	{ $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3155	\| '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3156	{ $$ = $2->addParamList( $6 ); }
3157	\| '(' abstract_function ')' // redundant parenthesis
3158	{ $$ = $2; }
3159	;
3160
3161	array_dimension:
3162	// Only the first dimension can be empty.
3163	'[' ']'
3164	{ $$ = DeclarationNode::newArray( 0, 0, false ); }
3165	\| '[' ']' multi_array_dimension
3166	{ $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
3167	\| multi_array_dimension
3168	;
3169
3170	multi_array_dimension:
3171	'[' push assignment_expression pop ']'
3172	{ $$ = DeclarationNode::newArray( $3, 0, false ); }
3173	\| '[' push '*' pop ']' // C99
3174	{ $$ = DeclarationNode::newVarArray( 0 ); }
3175	\| multi_array_dimension '[' push assignment_expression pop ']'
3176	{ $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
3177	\| multi_array_dimension '[' push '*' pop ']' // C99
3178	{ $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3179	;
3180
3181	// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3182	// identifier to which the type applies, e.g.:
3183	//
3184	// int f( int ); // not handled here
3185	// int f( int * ); // abstract function-prototype parameter; no parameter name specified
3186	// int f( int (*)() ); // abstract function-prototype parameter; no parameter name specified
3187	// int f( int (int) ); // abstract function-prototype parameter; no parameter name specified
3188	//
3189	// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3190	// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3191	// special meaning of parenthesis around a typedef name:
3192	//
3193	// ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3194	// parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3195	// not as redundant parentheses around the identifier."
3196	//
3197	// For example:
3198	//
3199	// typedef float T;
3200	// int f( int ( T [5] ) ); // see abstract_parameter_declarator
3201	// int g( int ( T ( int ) ) ); // see abstract_parameter_declarator
3202	// int f( int f1( T a[5] ) ); // see identifier_parameter_declarator
3203	// int g( int g1( T g2( int p ) ) ); // see identifier_parameter_declarator
3204	//
3205	// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3206	// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3207	// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3208	// functions.
3209
3210	abstract_parameter_declarator:
3211	abstract_parameter_ptr
3212	\| '&' MUTEX attribute_list_opt
3213	{ $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3214	\| abstract_parameter_array attribute_list_opt
3215	{ $$ = $1->addQualifiers( $2 ); }
3216	\| abstract_parameter_function attribute_list_opt
3217	{ $$ = $1->addQualifiers( $2 ); }
3218	;
3219
3220	abstract_parameter_ptr:
3221	ptrref_operator
3222	{ $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3223	\| ptrref_operator type_qualifier_list
3224	{ $$ = DeclarationNode::newPointer( $2, $1 ); }
3225	\| ptrref_operator abstract_parameter_declarator
3226	{ $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3227	\| ptrref_operator type_qualifier_list abstract_parameter_declarator
3228	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3229	\| '(' abstract_parameter_ptr ')' attribute_list_opt
3230	{ $$ = $2->addQualifiers( $4 ); }
3231	;
3232
3233	abstract_parameter_array:
3234	array_parameter_dimension
3235	\| '(' abstract_parameter_ptr ')' array_parameter_dimension
3236	{ $$ = $2->addArray( $4 ); }
3237	\| '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3238	{ $$ = $2->addArray( $4 ); }
3239	\| '(' abstract_parameter_array ')' // redundant parenthesis
3240	{ $$ = $2; }
3241	;
3242
3243	abstract_parameter_function:
3244	'(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3245	{ $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3246	\| '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3247	{ $$ = $2->addParamList( $6 ); }
3248	\| '(' abstract_parameter_function ')' // redundant parenthesis
3249	{ $$ = $2; }
3250	;
3251
3252	array_parameter_dimension:
3253	// Only the first dimension can be empty or have qualifiers.
3254	array_parameter_1st_dimension
3255	\| array_parameter_1st_dimension multi_array_dimension
3256	{ $$ = $1->addArray( $2 ); }
3257	\| multi_array_dimension
3258	;
3259
3260	// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3261	//
3262	// ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3263	// a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3264
3265	array_parameter_1st_dimension:
3266	'[' ']'
3267	{ $$ = DeclarationNode::newArray( 0, 0, false ); }
3268	// multi_array_dimension handles the '[' '*' ']' case
3269	\| '[' push type_qualifier_list '*' pop ']' // remaining C99
3270	{ $$ = DeclarationNode::newVarArray( $3 ); }
3271	\| '[' push type_qualifier_list pop ']'
3272	{ $$ = DeclarationNode::newArray( 0, $3, false ); }
3273	// multi_array_dimension handles the '[' assignment_expression ']' case
3274	\| '[' push type_qualifier_list assignment_expression pop ']'
3275	{ $$ = DeclarationNode::newArray( $4, $3, false ); }
3276	\| '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3277	{ $$ = DeclarationNode::newArray( $5, $4, true ); }
3278	\| '[' push type_qualifier_list STATIC assignment_expression pop ']'
3279	{ $$ = DeclarationNode::newArray( $5, $3, true ); }
3280	;
3281
3282	// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3283	//
3284	// struct S {
3285	// int;
3286	// int *;
3287	// int [10];
3288	// int (*)();
3289	// };
3290
3291	variable_abstract_declarator:
3292	variable_abstract_ptr
3293	\| variable_abstract_array attribute_list_opt
3294	{ $$ = $1->addQualifiers( $2 ); }
3295	\| variable_abstract_function attribute_list_opt
3296	{ $$ = $1->addQualifiers( $2 ); }
3297	;
3298
3299	variable_abstract_ptr:
3300	ptrref_operator
3301	{ $$ = DeclarationNode::newPointer( 0, $1 ); }
3302	\| ptrref_operator type_qualifier_list
3303	{ $$ = DeclarationNode::newPointer( $2, $1 ); }
3304	\| ptrref_operator variable_abstract_declarator
3305	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3306	\| ptrref_operator type_qualifier_list variable_abstract_declarator
3307	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3308	\| '(' variable_abstract_ptr ')' attribute_list_opt
3309	{ $$ = $2->addQualifiers( $4 ); }
3310	;
3311
3312	variable_abstract_array:
3313	array_dimension
3314	\| '(' variable_abstract_ptr ')' array_dimension
3315	{ $$ = $2->addArray( $4 ); }
3316	\| '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3317	{ $$ = $2->addArray( $4 ); }
3318	\| '(' variable_abstract_array ')' // redundant parenthesis
3319	{ $$ = $2; }
3320	;
3321
3322	variable_abstract_function:
3323	'(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3324	{ $$ = $2->addParamList( $6 ); }
3325	\| '(' variable_abstract_function ')' // redundant parenthesis
3326	{ $$ = $2; }
3327	;
3328
3329	// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3330	// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3331
3332	cfa_identifier_parameter_declarator_tuple: // CFA
3333	cfa_identifier_parameter_declarator_no_tuple
3334	\| cfa_abstract_tuple
3335	\| type_qualifier_list cfa_abstract_tuple
3336	{ $$ = $2->addQualifiers( $1 ); }
3337	;
3338
3339	cfa_identifier_parameter_declarator_no_tuple: // CFA
3340	cfa_identifier_parameter_ptr
3341	\| cfa_identifier_parameter_array
3342	;
3343
3344	cfa_identifier_parameter_ptr: // CFA
3345	// No SUE declaration in parameter list.
3346	ptrref_operator type_specifier_nobody
3347	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3348	\| type_qualifier_list ptrref_operator type_specifier_nobody
3349	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3350	\| ptrref_operator cfa_abstract_function
3351	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3352	\| type_qualifier_list ptrref_operator cfa_abstract_function
3353	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3354	\| ptrref_operator cfa_identifier_parameter_declarator_tuple
3355	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3356	\| type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3357	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3358	;
3359
3360	cfa_identifier_parameter_array: // CFA
3361	// Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3362	// shift/reduce conflict with new-style empty (void) function return type.
3363	'[' ']' type_specifier_nobody
3364	{ $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3365	\| cfa_array_parameter_1st_dimension type_specifier_nobody
3366	{ $$ = $2->addNewArray( $1 ); }
3367	\| '[' ']' multi_array_dimension type_specifier_nobody
3368	{ $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3369	\| cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3370	{ $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3371	\| multi_array_dimension type_specifier_nobody
3372	{ $$ = $2->addNewArray( $1 ); }
3373
3374	\| '[' ']' cfa_identifier_parameter_ptr
3375	{ $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3376	\| cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3377	{ $$ = $2->addNewArray( $1 ); }
3378	\| '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3379	{ $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3380	\| cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3381	{ $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3382	\| multi_array_dimension cfa_identifier_parameter_ptr
3383	{ $$ = $2->addNewArray( $1 ); }
3384	;
3385
3386	cfa_array_parameter_1st_dimension:
3387	'[' push type_qualifier_list '*' pop ']' // remaining C99
3388	{ $$ = DeclarationNode::newVarArray( $3 ); }
3389	\| '[' push type_qualifier_list assignment_expression pop ']'
3390	{ $$ = DeclarationNode::newArray( $4, $3, false ); }
3391	\| '[' push declaration_qualifier_list assignment_expression pop ']'
3392	// declaration_qualifier_list must be used because of shift/reduce conflict with
3393	// assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3394	// appear in this context.
3395	{ $$ = DeclarationNode::newArray( $4, $3, true ); }
3396	\| '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3397	{ $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3398	;
3399
3400	// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3401	// identifier to which the type applies, e.g.:
3402	//
3403	// [int] f( int ); // abstract variable parameter; no parameter name specified
3404	// [int] f( [int] (int) ); // abstract function-prototype parameter; no parameter name specified
3405	//
3406	// These rules need LR(3):
3407	//
3408	// cfa_abstract_tuple identifier_or_type_name
3409	// '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
3410	//
3411	// since a function return type can be syntactically identical to a tuple type:
3412	//
3413	// [int, int] t;
3414	// [int, int] f( int );
3415	//
3416	// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3417	// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3418	// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3419	// duplicated when appearing with cfa_function_specifier.
3420
3421	cfa_abstract_declarator_tuple: // CFA
3422	cfa_abstract_tuple
3423	\| type_qualifier_list cfa_abstract_tuple
3424	{ $$ = $2->addQualifiers( $1 ); }
3425	\| cfa_abstract_declarator_no_tuple
3426	;
3427
3428	cfa_abstract_declarator_no_tuple: // CFA
3429	cfa_abstract_ptr
3430	\| cfa_abstract_array
3431	;
3432
3433	cfa_abstract_ptr: // CFA
3434	ptrref_operator type_specifier
3435	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3436	\| type_qualifier_list ptrref_operator type_specifier
3437	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3438	\| ptrref_operator cfa_abstract_function
3439	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3440	\| type_qualifier_list ptrref_operator cfa_abstract_function
3441	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3442	\| ptrref_operator cfa_abstract_declarator_tuple
3443	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3444	\| type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3445	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3446	;
3447
3448	cfa_abstract_array: // CFA
3449	// Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3450	// empty (void) function return type.
3451	'[' ']' type_specifier
3452	{ $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3453	\| '[' ']' multi_array_dimension type_specifier
3454	{ $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3455	\| multi_array_dimension type_specifier
3456	{ $$ = $2->addNewArray( $1 ); }
3457	\| '[' ']' cfa_abstract_ptr
3458	{ $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3459	\| '[' ']' multi_array_dimension cfa_abstract_ptr
3460	{ $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3461	\| multi_array_dimension cfa_abstract_ptr
3462	{ $$ = $2->addNewArray( $1 ); }
3463	;
3464
3465	cfa_abstract_tuple: // CFA
3466	'[' push cfa_abstract_parameter_list pop ']'
3467	{ $$ = DeclarationNode::newTuple( $3 ); }
3468	\| '[' push type_specifier_nobody ELLIPSIS pop ']'
3469	{ SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3470	\| '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
3471	{ SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3472	;
3473
3474	cfa_abstract_function: // CFA
3475	// '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
3476	// { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3477	cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
3478	{ $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3479	\| cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
3480	{ $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3481	;
3482
3483	// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3484	// each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3485	//
3486	// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3487	// the declaration specifiers in a declaration is an obsolescent feature."
3488	//
3489	// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3490	// prototype-format parameter type declarators) is an obsolescent feature."
3491	//
3492	// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3493	// declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3494
3495	//*********************** MISCELLANEOUS ******************************
3496
3497	comma_opt: // redundant comma
3498	// empty
3499	\| ','
3500	;
3501
3502	default_initialize_opt:
3503	// empty
3504	{ $$ = nullptr; }
3505	\| '=' assignment_expression
3506	{ $$ = $2; }
3507	;
3508
3509	%%
3510
3511	// ----end of grammar----
3512
3513	// Local Variables: //
3514	// mode: c++ //
3515	// tab-width: 4 //
3516	// compile-command: "make install" //
3517	// End: //

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format