source: src/Parser/parser.yy @ c0a33d2

aaron-thesisarm-ehcleanup-dtorsdeferred_resndemanglerjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-exprnew-envno_listpersistent-indexerwith_gc
Last change on this file since c0a33d2 was c0a33d2, checked in by Peter A. Buhr <pabuhr@…>, 4 years ago

intermediate updates

  • Property mode set to 100644
File size: 121.8 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author           : Peter A. Buhr
10// Created On       : Sat Sep  1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Thu May 24 16:49:58 2018
13// Update Count     : 3367
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS.  While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks.  Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// 1. designation with '=' (use ':' instead)
29//
30// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32//
33// 1. designation with and without '=' (use ':' instead)
34// 2. attributes not allowed in parenthesis of declarator
35//
36// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40// grammar rule.
41
42%{
43#define YYDEBUG_LEXER_TEXT (yylval)                                             // lexer loads this up each time
44#define YYDEBUG 1                                                                               // get the pretty debugging code to compile
45#define YYERROR_VERBOSE                                                                 // more information in syntax errors
46
47#undef __GNUC_MINOR__
48
49#include <cstdio>
50#include <stack>
51using namespace std;
52
53#include "ParseNode.h"
54#include "TypedefTable.h"
55#include "TypeData.h"
56#include "LinkageSpec.h"
57#include "Common/SemanticError.h"                                               // error_str
58#include "Common/utility.h"                                                             // for maybeMoveBuild, maybeBuild, CodeLo...
59
60extern DeclarationNode * parseTree;
61extern LinkageSpec::Spec linkage;
62extern TypedefTable typedefTable;
63
64stack< LinkageSpec::Spec > linkageStack;
65
66bool appendStr( string & to, string & from ) {
67        // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
68        //    "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
69        //    the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
70        //    easier to let the C compiler handle this case.
71        //
72        // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
73        //    without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
74        //    i.e., u"a" U"b" L"c" is disallowed.
75
76        if ( from[0] != '"' ) {                                                         // encoding ?
77                if ( to[0] != '"' ) {                                                   // encoding ?
78                        if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
79                                yyerror( "non-matching string encodings for string-literal concatenation" );
80                                return false;                                                   // parse error, must call YYERROR in action
81                        } else if ( from[1] == '8' ) {
82                                from.erase( 0, 1 );                                             // remove 2nd encoding
83                        } // if
84                } else {
85                        if ( from[1] == '8' ) {                                         // move encoding to start
86                                to = "u8" + to;
87                                from.erase( 0, 1 );                                             // remove 2nd encoding
88                        } else {
89                                to = from[0] + to;
90                        } // if
91                } // if
92                from.erase( 0, 1 );                                                             // remove 2nd encoding
93        } // if
94        to += " " + from;                                                                       // concatenated into single string
95        return true;
96} // appendStr
97
98DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
99        // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
100        DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
101        //cur->addType( specifier );
102        for ( cur = dynamic_cast< DeclarationNode * >( cur->get_next() ); cur != nullptr; cur = dynamic_cast< DeclarationNode * >( cur->get_next() ) ) {
103                cl->cloneBaseType( cur );
104        } // for
105        declList->addType( cl );
106//      delete cl;
107        return declList;
108} // distAttr
109
110void distExt( DeclarationNode * declaration ) {
111        // distribute EXTENSION across all declarations
112        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
113                iter->set_extension( true );
114        } // for
115} // distExt
116
117// There is an ambiguity for inline generic-routine return-types and generic routines.
118//   forall( otype T ) struct S { int i; } bar( T ) {}
119// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
120//   forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
121// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
122//   forall( otype T ) struct S { int T; };
123//   forall( otype W ) bar( W ) {}
124
125void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
126        if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
127                funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
128                declSpec->type->aggregate.params = nullptr;
129        } // if
130} // rebindForall
131
132NameExpr * build_postfix_name( const string * name ) {
133        NameExpr * new_name = build_varref( new string( "?`" + *name ) );
134        delete name;
135        return new_name;
136} // build_postfix_name
137
138bool forall = false, xxx = false;                                               // aggregate have one or more forall qualifiers ?
139
140// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
141#define YYLLOC_DEFAULT(Cur, Rhs, N)                                                                                             \
142if ( N ) {                                                                                                                                              \
143        (Cur).first_line   = YYRHSLOC( Rhs, 1 ).first_line;                                                     \
144        (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column;                                           \
145        (Cur).last_line    = YYRHSLOC( Rhs, N ).last_line;                                                      \
146        (Cur).last_column  = YYRHSLOC( Rhs, N ).last_column;                                            \
147        (Cur).filename     = YYRHSLOC( Rhs, 1 ).filename;                                                       \
148} else {                                                                                                                                                \
149        (Cur).first_line   = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line;            \
150        (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column;        \
151        (Cur).filename     = YYRHSLOC( Rhs, 0 ).filename;                                                       \
152}
153%}
154
155%define parse.error verbose
156
157// Types declaration for productions
158%union
159{
160        Token tok;
161        ParseNode * pn;
162        ExpressionNode * en;
163        DeclarationNode * decl;
164        DeclarationNode::Aggregate aggKey;
165        DeclarationNode::TypeClass tclass;
166        StatementNode * sn;
167        WaitForStmt * wfs;
168        Expression * constant;
169        IfCtl * ifctl;
170        ForCtl * fctl;
171        LabelNode * label;
172        InitializerNode * in;
173        OperKinds op;
174        std::string * str;
175        bool flag;
176        CatchStmt::Kind catch_kind;
177}
178
179//************************* TERMINAL TOKENS ********************************
180
181// keywords
182%token TYPEDEF
183%token EXTERN STATIC AUTO REGISTER
184%token THREADLOCAL                                                                              // C11
185%token INLINE FORTRAN                                                                   // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
186%token NORETURN                                                                                 // C11
187%token CONST VOLATILE
188%token RESTRICT                                                                                 // C99
189%token ATOMIC                                                                                   // C11
190%token FORALL MUTEX VIRTUAL                                                             // CFA
191%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
192%token BOOL COMPLEX IMAGINARY                                                   // C99
193%token INT128 FLOAT80 FLOAT128                                                  // GCC
194%token ZERO_T ONE_T                                                                             // CFA
195%token VALIST                                                                                   // GCC
196%token TYPEOF LABEL                                                                             // GCC
197%token ENUM STRUCT UNION
198%token EXCEPTION                                                                                // CFA
199%token COROUTINE MONITOR THREAD                                                 // CFA
200%token OTYPE FTYPE DTYPE TTYPE TRAIT                                    // CFA
201%token SIZEOF OFFSETOF
202%token ATTRIBUTE EXTENSION                                                              // GCC
203%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
204%token CHOOSE DISABLE ENABLE FALLTHRU FALLTHROUGH TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT WITH WHEN WAITFOR // CFA
205%token ASM                                                                                              // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
206%token ALIGNAS ALIGNOF GENERIC STATICASSERT                             // C11
207
208// names and constants: lexer differentiates between identifier and typedef names
209%token<tok> IDENTIFIER                  QUOTED_IDENTIFIER               TYPEDEFname                             TYPEGENname
210%token<tok> TIMEOUT                             WOR
211%token<tok> ATTR_IDENTIFIER             ATTR_TYPEDEFname                ATTR_TYPEGENname
212%token<tok> INTEGERconstant             CHARACTERconstant               STRINGliteral
213%token<tok> DIRECTIVE
214// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
215// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
216// converted into the tuple index (.)(1). e.g., 3.x
217%token<tok>     FLOATING_DECIMALconstant        FLOATING_FRACTIONconstant       FLOATINGconstant
218
219// multi-character operators
220%token ARROW                                                                                    // ->
221%token ICR DECR                                                                                 // ++   --
222%token LS RS                                                                                    // <<   >>
223%token LE GE EQ NE                                                                              // <=   >=      ==      !=
224%token ANDAND OROR                                                                              // &&   ||
225%token ELLIPSIS                                                                                 // ...
226
227%token EXPassign        MULTassign      DIVassign       MODassign       // \=   *=      /=      %=
228%token PLUSassign       MINUSassign                                                     // +=   -=
229%token LSassign         RSassign                                                        // <<=  >>=
230%token ANDassign        ERassign        ORassign                                // &=   ^=      |=
231
232%token ATassign                                                                                 // @=
233
234%type<tok> identifier  no_attr_identifier
235%type<tok> identifier_or_type_name  no_attr_identifier_or_type_name  attr_name
236%type<tok> quasi_keyword
237%type<constant> string_literal
238%type<str> string_literal_list
239
240// expressions
241%type<en> constant
242%type<en> tuple                                                 tuple_expression_list
243%type<op> ptrref_operator                               unary_operator                          assignment_operator
244%type<en> primary_expression                    postfix_expression                      unary_expression
245%type<en> cast_expression                               exponential_expression          multiplicative_expression       additive_expression
246%type<en> shift_expression                              relational_expression           equality_expression
247%type<en> AND_expression                                exclusive_OR_expression         inclusive_OR_expression
248%type<en> logical_AND_expression                logical_OR_expression
249%type<en> conditional_expression                constant_expression                     assignment_expression           assignment_expression_opt
250%type<en> comma_expression                              comma_expression_opt
251%type<en> argument_expression_list              argument_expression                     default_initialize_opt
252%type<ifctl> if_control_expression
253%type<fctl> for_control_expression
254%type<en> subrange
255%type<decl> asm_name_opt
256%type<en> asm_operands_opt asm_operands_list asm_operand
257%type<label> label_list
258%type<en> asm_clobbers_list_opt
259%type<flag> asm_volatile_opt
260%type<en> handler_predicate_opt
261
262// statements
263%type<sn> statement                                             labeled_statement                       compound_statement
264%type<sn> statement_decl                                statement_decl_list                     statement_list_nodecl
265%type<sn> selection_statement
266%type<sn> switch_clause_list_opt                switch_clause_list
267%type<en> case_value
268%type<sn> case_clause                                   case_value_list                         case_label                                      case_label_list
269%type<sn> iteration_statement                   jump_statement
270%type<sn> expression_statement                  asm_statement
271%type<sn> with_statement
272%type<en> with_clause_opt
273%type<sn> exception_statement                   handler_clause                          finally_clause
274%type<catch_kind> handler_key
275%type<sn> mutex_statement
276%type<en> when_clause                                   when_clause_opt                         waitfor                                         timeout
277%type<sn> waitfor_statement
278%type<wfs> waitfor_clause
279
280// declarations
281%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
282%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
283%type<decl> abstract_parameter_declaration
284
285%type<aggKey> aggregate_key
286%type<decl> aggregate_type aggregate_type_nobody
287
288%type<decl> assertion assertion_list assertion_list_opt
289
290%type<en>   bit_subrange_size_opt bit_subrange_size
291
292%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
293
294%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
295
296%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
297%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
298
299%type<decl> elaborated_type elaborated_type_nobody
300
301%type<decl> enumerator_list enum_type enum_type_nobody
302%type<en> enumerator_value_opt
303
304%type<decl> exception_declaration external_definition external_definition_list external_definition_list_opt
305
306%type<decl> field_declaration field_declaration_list_opt field_declarator_opt field_declaring_list
307%type<en> field field_list field_name fraction_constants_opt
308
309%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
310
311%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
312%type<decl> identifier_list
313
314%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
315%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
316%type<decl> cfa_abstract_ptr cfa_abstract_tuple
317
318%type<decl> cfa_array_parameter_1st_dimension
319
320%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list
321%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
322
323%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
324%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
325
326%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_type_list_opt
327
328%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
329
330%type<decl> c_declaration static_assert
331%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
332%type<decl> KR_declaration_list KR_declaration_list_opt
333
334%type<decl> parameter_declaration parameter_list parameter_type_list_opt
335
336%type<decl> paren_identifier paren_type
337
338%type<decl> storage_class storage_class_list
339
340%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
341
342%type<tclass> type_class
343%type<decl> type_declarator type_declarator_name type_declaring_list
344
345%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
346%type<decl> typedef typedef_declaration typedef_expression
347
348%type<decl> variable_type_redeclarator type_ptr type_array type_function
349
350%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
351
352%type<decl> type type_no_function
353%type<decl> type_parameter type_parameter_list type_initializer_opt
354
355%type<en> type_list
356
357%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
358%type<decl> type_specifier type_specifier_nobody
359
360%type<decl> variable_declarator variable_ptr variable_array variable_function
361%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
362
363%type<decl> attribute_list_opt attribute_list attribute_name_list attribute attribute_name
364
365// initializers
366%type<in>  initializer initializer_list_opt initializer_opt
367
368// designators
369%type<en>  designator designator_list designation
370
371
372// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
373//   .---------.                                matches IF '(' comma_expression ')' statement . (reduce)
374//   if ( C ) S1 else S2
375//   `-----------------'                matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
376// Similar issues exit with the waitfor statement.
377
378// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
379// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
380%precedence THEN        // rule precedence for IF/WAITFOR statement
381%precedence WOR         // token precedence for start of WOR in WAITFOR statement
382%precedence TIMEOUT     // token precedence for start of TIMEOUT in WAITFOR statement
383%precedence ELSE        // token precedence for start of else clause in IF/WAITFOR statement
384
385// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
386//   forall( otype T ) struct Foo { T v; };
387//       .-----.                                matches pointer to function returning a generic (which is impossible without a type)
388//   Foo ( *fp )( int );
389//   `---'                                              matches start of TYPEGENname '('
390// Must be:
391//   Foo( int ) ( *fp )( int );
392
393// Order of these lines matters (low-to-high precedence).
394%precedence TYPEGENname
395%precedence '('
396
397%locations                                                                                              // support location tracking for error messages
398
399%start translation_unit                                                                 // parse-tree root
400
401%%
402//************************* Namespace Management ********************************
403
404// The grammar in the ANSI C standard is not strictly context-free, since it relies upon the distinct terminal symbols
405// "identifier", "TYPEDEFname", and "TYPEGENname" that are lexically identical.  While it is possible to write a purely
406// context-free grammar, such a grammar would obscure the relationship between syntactic and semantic constructs.
407// Hence, this grammar uses the ANSI style.
408//
409// Cforall compounds this problem by introducing type names local to the scope of a declaration (for instance, those
410// introduced through "forall" qualifiers), and by introducing "type generators" -- parameterized types.  This latter
411// type name creates a third class of identifiers that must be distinguished by the scanner.
412//
413// Since the scanner cannot distinguish among the different classes of identifiers without some context information, it
414// accesses a data structure (TypedefTable) to allow classification of an identifier that it has just read.  Semantic
415// actions during the parser update this data structure when the class of identifiers change.
416//
417// Because the Cforall language is block-scoped, an identifier can change its class in a local scope; it must revert to
418// its original class at the end of the block.  Since type names can be local to a particular declaration, each
419// declaration is itself a scope.  This requires distinguishing between type names that are local to the current
420// declaration scope and those that persist past the end of the declaration (i.e., names defined in "typedef" or "otype"
421// declarations).
422//
423// The non-terminals "push" and "pop" denote the opening and closing of scopes.  Every push must have a matching pop,
424// although it is regrettable the matching pairs do not always occur within the same rule.  These non-terminals may
425// appear in more contexts than strictly necessary from a semantic point of view.
426
427push:
428                { typedefTable.enterScope(); }
429        ;
430
431pop:
432                { typedefTable.leaveScope(); }
433        ;
434
435//************************* CONSTANTS ********************************
436
437constant:
438                // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
439        INTEGERconstant                                                         { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
440        | FLOATING_DECIMALconstant                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
441        | FLOATING_FRACTIONconstant                                     { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
442        | FLOATINGconstant                                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
443        | CHARACTERconstant                                                     { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
444        ;
445
446quasi_keyword:                                                                                  // CFA
447        TIMEOUT
448        | WOR
449        ;
450
451identifier:
452        IDENTIFIER
453        | ATTR_IDENTIFIER                                                                       // CFA
454        | quasi_keyword
455        ;
456
457no_attr_identifier:
458        IDENTIFIER
459        | quasi_keyword
460        ;
461
462string_literal:
463        string_literal_list                                                     { $$ = build_constantStr( *$1 ); }
464        ;
465
466string_literal_list:                                                                    // juxtaposed strings are concatenated
467        STRINGliteral                                                           { $$ = $1; } // conversion from tok to str
468        | string_literal_list STRINGliteral
469                {
470                        if ( ! appendStr( *$1, *$2 ) ) YYERROR;         // append 2nd juxtaposed string to 1st
471                        delete $2;                                                                      // allocated by lexer
472                        $$ = $1;                                                                        // conversion from tok to str
473                }
474        ;
475
476//************************* EXPRESSIONS ********************************
477
478primary_expression:
479        IDENTIFIER                                                                                      // typedef name cannot be used as a variable name
480                { $$ = new ExpressionNode( build_varref( $1 ) ); }
481        | quasi_keyword
482                { $$ = new ExpressionNode( build_varref( $1 ) ); }
483        | tuple
484        | '(' comma_expression ')'
485                { $$ = $2; }
486        | '(' compound_statement ')'                                            // GCC, lambda expression
487                { $$ = new ExpressionNode( new StmtExpr( dynamic_cast< CompoundStmt * >(maybeMoveBuild< Statement >($2) ) ) ); }
488        | constant '`' IDENTIFIER                                                       // CFA, postfix call
489                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), $1 ) ); }
490        | string_literal '`' IDENTIFIER                                         // CFA, postfix call
491                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), new ExpressionNode( $1 ) ) ); }
492        | IDENTIFIER '`' IDENTIFIER                                                     // CFA, postfix call
493                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), new ExpressionNode( build_varref( $1 ) ) ) ); }
494        | tuple '`' IDENTIFIER                                                          // CFA, postfix call
495                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), $1 ) ); }
496        | '(' comma_expression ')' '`' IDENTIFIER                       // CFA, postfix call
497                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $5 ) ), $2 ) ); }
498        | type_name '.' no_attr_identifier                                      // CFA, nested type
499                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
500        | type_name '.' '[' field_list ']'                                      // CFA, nested type / tuple field selector
501                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
502        | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
503                { SemanticError( yylloc, "_Generic is currently unimplemented." ); $$ = nullptr; }
504        ;
505
506generic_assoc_list:                                                                             // C11
507        | generic_association
508        | generic_assoc_list ',' generic_association
509        ;
510
511generic_association:                                                                    // C11
512        type_no_function ':' assignment_expression
513        | DEFAULT ':' assignment_expression
514        ;
515
516postfix_expression:
517        primary_expression
518        | postfix_expression '[' assignment_expression ']'
519                // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
520                // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
521                // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
522                // equivalent to the old x[i,j].
523                { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
524        | postfix_expression '{' argument_expression_list '}' // CFA, constructor call
525                {
526                        Token fn;
527                        fn.str = new std::string( "?{}" );                      // location undefined - use location of '{'?
528                        $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
529                }
530        | postfix_expression '(' argument_expression_list ')'
531                { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
532        | postfix_expression '.' no_attr_identifier
533                { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
534        | postfix_expression '.' INTEGERconstant                        // CFA, tuple index
535                { $$ = new ExpressionNode( build_fieldSel( $1, build_constantInteger( *$3 ) ) ); }
536        | postfix_expression FLOATING_FRACTIONconstant          // CFA, tuple index
537                { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
538        | postfix_expression '.' '[' field_list ']'                     // CFA, tuple field selector
539                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
540        | postfix_expression ARROW no_attr_identifier
541                {
542                        $$ = new ExpressionNode( build_pfieldSel( $1, *$3 == "0" || *$3 == "1" ? build_constantInteger( *$3 ) : build_varref( $3 ) ) );
543                }
544        | postfix_expression ARROW INTEGERconstant                      // CFA, tuple index
545                { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
546        | postfix_expression ARROW '[' field_list ']'           // CFA, tuple field selector
547                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
548        | postfix_expression ICR
549                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
550        | postfix_expression DECR
551                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
552        | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
553                { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
554        | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
555                { $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
556        | '^' primary_expression '{' argument_expression_list '}' // CFA
557                {
558                        Token fn;
559                        fn.str = new string( "^?{}" );                          // location undefined
560                        $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
561                }
562        ;
563
564argument_expression_list:
565        argument_expression
566        | argument_expression_list ',' argument_expression
567                { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
568        ;
569
570argument_expression:
571        // empty
572                { $$ = nullptr; }
573        // | '@'                                                                                                // use default argument
574        //      { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
575        | assignment_expression
576        ;
577
578field_list:                                                                                             // CFA, tuple field selector
579        field
580        | field_list ',' field                                          { $$ = (ExpressionNode *)$1->set_last( $3 ); }
581        ;
582
583field:                                                                                                  // CFA, tuple field selector
584        field_name
585        | FLOATING_DECIMALconstant field
586                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
587        | FLOATING_DECIMALconstant '[' field_list ']'
588                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $3 ) ) ); }
589        | field_name '.' field
590                { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
591        | field_name '.' '[' field_list ']'
592                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
593        | field_name ARROW field
594                { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
595        | field_name ARROW '[' field_list ']'
596                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
597        ;
598
599field_name:
600        INTEGERconstant fraction_constants_opt
601                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
602        | FLOATINGconstant fraction_constants_opt
603                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
604        | no_attr_identifier fraction_constants_opt
605                {
606                        $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
607                }
608        ;
609
610fraction_constants_opt:
611        // empty
612                { $$ = nullptr; }
613        | fraction_constants_opt FLOATING_FRACTIONconstant
614                {
615                        Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
616                        $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1,  constant ) ) : new ExpressionNode( constant );
617                }
618        ;
619
620unary_expression:
621        postfix_expression
622                // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
623                // semantics checks, e.g., ++3, 3--, *3, &&3
624        | constant
625                { $$ = $1; }
626        | string_literal
627                { $$ = new ExpressionNode( $1 ); }
628        | EXTENSION cast_expression                                                     // GCC
629                { $$ = $2->set_extension( true ); }
630                // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
631                //              { * X; }         // dereference X
632                //              { * int X; } // CFA declaration of pointer to int
633        | ptrref_operator cast_expression                                       // CFA
634                {
635                        switch ( $1 ) {
636                          case OperKinds::AddressOf:
637                                $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) );
638                                break;
639                          case OperKinds::PointTo:
640                                $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
641                                break;
642                          case OperKinds::And:
643                                $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) ) );
644                                break;
645                          default:
646                                assert( false );
647                        }
648                }
649        | unary_operator cast_expression
650                { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
651        | ICR unary_expression
652                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
653        | DECR unary_expression
654                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
655        | SIZEOF unary_expression
656                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
657        | SIZEOF '(' type_no_function ')'
658                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
659        | ALIGNOF unary_expression                                                      // GCC, variable alignment
660                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
661        | ALIGNOF '(' type_no_function ')'                                      // GCC, type alignment
662                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
663        | OFFSETOF '(' type_no_function ',' no_attr_identifier ')'
664                { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
665        | ATTR_IDENTIFIER
666                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuild< Expression >( (ExpressionNode *)nullptr ) ) ); }
667        | ATTR_IDENTIFIER '(' argument_expression ')'
668                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
669        | ATTR_IDENTIFIER '(' type ')'
670                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuildType( $3 ) ) ); }
671        ;
672
673ptrref_operator:
674        '*'                                                                                     { $$ = OperKinds::PointTo; }
675        | '&'                                                                           { $$ = OperKinds::AddressOf; }
676                // GCC, address of label must be handled by semantic check for ref,ref,label
677        | ANDAND                                                                        { $$ = OperKinds::And; }
678        ;
679
680unary_operator:
681        '+'                                                                                     { $$ = OperKinds::UnPlus; }
682        | '-'                                                                           { $$ = OperKinds::UnMinus; }
683        | '!'                                                                           { $$ = OperKinds::Neg; }
684        | '~'                                                                           { $$ = OperKinds::BitNeg; }
685        ;
686
687cast_expression:
688        unary_expression
689        | '(' type_no_function ')' cast_expression
690                { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
691        | '(' COROUTINE '&' ')' cast_expression                         // CFA
692                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Coroutine, $5 ) ); }
693        | '(' THREAD '&' ')' cast_expression                            // CFA
694                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Thread, $5 ) ); }
695        | '(' MONITOR '&' ')' cast_expression                           // CFA
696                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Monitor, $5 ) ); }
697                // VIRTUAL cannot be opt because of look ahead issues
698        | '(' VIRTUAL ')' cast_expression                                       // CFA
699                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $4 ), maybeMoveBuildType( nullptr ) ) ); }
700        | '(' VIRTUAL type_no_function ')' cast_expression      // CFA
701                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $5 ), maybeMoveBuildType( $3 ) ) ); }
702//      | '(' type_no_function ')' tuple
703//              { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
704        ;
705
706exponential_expression:
707        cast_expression
708        | exponential_expression '\\' cast_expression
709                { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
710        ;
711
712multiplicative_expression:
713        exponential_expression
714        | multiplicative_expression '*' exponential_expression
715                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
716        | multiplicative_expression '/' exponential_expression
717                { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
718        | multiplicative_expression '%' exponential_expression
719                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
720        ;
721
722additive_expression:
723        multiplicative_expression
724        | additive_expression '+' multiplicative_expression
725                { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
726        | additive_expression '-' multiplicative_expression
727                { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
728        ;
729
730shift_expression:
731        additive_expression
732        | shift_expression LS additive_expression
733                { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
734        | shift_expression RS additive_expression
735                { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
736        ;
737
738relational_expression:
739        shift_expression
740        | relational_expression '<' shift_expression
741                { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
742        | relational_expression '>' shift_expression
743                { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
744        | relational_expression LE shift_expression
745                { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
746        | relational_expression GE shift_expression
747                { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
748        ;
749
750equality_expression:
751        relational_expression
752        | equality_expression EQ relational_expression
753                { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
754        | equality_expression NE relational_expression
755                { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
756        ;
757
758AND_expression:
759        equality_expression
760        | AND_expression '&' equality_expression
761                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
762        ;
763
764exclusive_OR_expression:
765        AND_expression
766        | exclusive_OR_expression '^' AND_expression
767                { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
768        ;
769
770inclusive_OR_expression:
771        exclusive_OR_expression
772        | inclusive_OR_expression '|' exclusive_OR_expression
773                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
774        ;
775
776logical_AND_expression:
777        inclusive_OR_expression
778        | logical_AND_expression ANDAND inclusive_OR_expression
779                { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
780        ;
781
782logical_OR_expression:
783        logical_AND_expression
784        | logical_OR_expression OROR logical_AND_expression
785                { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
786        ;
787
788conditional_expression:
789        logical_OR_expression
790        | logical_OR_expression '?' comma_expression ':' conditional_expression
791                { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
792                // FIX ME: computes $1 twice
793        | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
794                { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
795        ;
796
797constant_expression:
798        conditional_expression
799        ;
800
801assignment_expression:
802                // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
803        conditional_expression
804        | unary_expression assignment_operator assignment_expression
805                { $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) ); }
806        | unary_expression '=' '{' initializer_list_opt comma_opt '}'
807                { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
808        ;
809
810assignment_expression_opt:
811        // empty
812                { $$ = nullptr; }
813        | assignment_expression
814        ;
815
816assignment_operator:
817        '='                                                                                     { $$ = OperKinds::Assign; }
818        | ATassign                                                                      { $$ = OperKinds::AtAssn; }
819        | EXPassign                                                                     { $$ = OperKinds::ExpAssn; }
820        | MULTassign                                                            { $$ = OperKinds::MulAssn; }
821        | DIVassign                                                                     { $$ = OperKinds::DivAssn; }
822        | MODassign                                                                     { $$ = OperKinds::ModAssn; }
823        | PLUSassign                                                            { $$ = OperKinds::PlusAssn; }
824        | MINUSassign                                                           { $$ = OperKinds::MinusAssn; }
825        | LSassign                                                                      { $$ = OperKinds::LSAssn; }
826        | RSassign                                                                      { $$ = OperKinds::RSAssn; }
827        | ANDassign                                                                     { $$ = OperKinds::AndAssn; }
828        | ERassign                                                                      { $$ = OperKinds::ERAssn; }
829        | ORassign                                                                      { $$ = OperKinds::OrAssn; }
830        ;
831
832tuple:                                                                                                  // CFA, tuple
833                // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
834                // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
835//      '[' ']'
836//              { $$ = new ExpressionNode( build_tuple() ); }
837//      '[' push assignment_expression pop ']'
838//              { $$ = new ExpressionNode( build_tuple( $3 ) ); }
839        '[' push ',' tuple_expression_list pop ']'
840                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $4 ) ) ); }
841        | '[' push assignment_expression ',' tuple_expression_list pop ']'
842                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)$3->set_last( $5 ) ) ); }
843        ;
844
845tuple_expression_list:
846        assignment_expression_opt
847        | tuple_expression_list ',' assignment_expression_opt
848                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
849        ;
850
851comma_expression:
852        assignment_expression
853        | comma_expression ',' assignment_expression
854                { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
855        ;
856
857comma_expression_opt:
858        // empty
859                { $$ = nullptr; }
860        | comma_expression
861        ;
862
863//*************************** STATEMENTS *******************************
864
865statement:
866        labeled_statement
867        | compound_statement
868        | expression_statement
869        | selection_statement
870        | iteration_statement
871        | jump_statement
872        | with_statement
873        | mutex_statement
874        | waitfor_statement
875        | exception_statement
876        | enable_disable_statement
877                { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
878        | asm_statement
879        | DIRECTIVE
880                { $$ = new StatementNode( build_directive( $1 ) ); }
881        ;
882
883labeled_statement:
884                // labels cannot be identifiers 0 or 1 or ATTR_IDENTIFIER
885        identifier_or_type_name ':' attribute_list_opt statement
886                {
887                        $$ = $4->add_label( $1, $3 );
888                }
889        ;
890
891compound_statement:
892        '{' '}'
893                { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
894        | '{'
895                // Two scopes are necessary because the block itself has a scope, but every declaration within the block also
896                // requires its own scope.
897          push push
898          local_label_declaration_opt                                           // GCC, local labels
899          statement_decl_list                                                           // C99, intermix declarations and statements
900          pop '}'
901                { $$ = new StatementNode( build_compound( $5 ) ); }
902        ;
903
904statement_decl_list:                                                                    // C99
905        statement_decl
906        | statement_decl_list push statement_decl
907                { if ( $1 != 0 ) { $1->set_last( $3 ); $$ = $1; } }
908        ;
909
910statement_decl:
911        declaration                                                                                     // CFA, new & old style declarations
912                { $$ = new StatementNode( $1 ); }
913        | EXTENSION declaration                                                         // GCC
914                {
915                        distExt( $2 );
916                        $$ = new StatementNode( $2 );
917                }
918        | function_definition
919                { $$ = new StatementNode( $1 ); }
920        | EXTENSION function_definition                                         // GCC
921                {
922                        distExt( $2 );
923                        $$ = new StatementNode( $2 );
924                }
925        | statement pop
926        ;
927
928statement_list_nodecl:
929        statement
930        | statement_list_nodecl statement
931                { if ( $1 != 0 ) { $1->set_last( $2 ); $$ = $1; } }
932        ;
933
934expression_statement:
935        comma_expression_opt ';'
936                { $$ = new StatementNode( build_expr( $1 ) ); }
937        ;
938
939selection_statement:
940        IF '(' push if_control_expression ')' statement         %prec THEN
941                // explicitly deal with the shift/reduce conflict on if/else
942                { $$ = new StatementNode( build_if( $4, $6, nullptr ) ); }
943        | IF '(' push if_control_expression ')' statement ELSE statement
944                { $$ = new StatementNode( build_if( $4, $6, $8 ) ); }
945        | SWITCH '(' comma_expression ')' case_clause
946                { $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
947        | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt '}' // CFA
948                {
949                        StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
950                        // The semantics of the declaration list is changed to include associated initialization, which is performed
951                        // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
952                        // statement around the switch.  Statements after the initial declaration list can never be executed, and
953                        // therefore, are removed from the grammar even though C allows it. The change also applies to choose
954                        // statement.
955                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
956                }
957        | CHOOSE '(' comma_expression ')' case_clause           // CFA
958                { $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
959        | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt '}' // CFA
960                {
961                        StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
962                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
963                }
964        ;
965
966if_control_expression:
967        comma_expression pop
968                { $$ = new IfCtl( nullptr, $1 ); }
969        | c_declaration pop                                                                     // no semi-colon
970                { $$ = new IfCtl( $1, nullptr ); }
971        | cfa_declaration pop                                                           // no semi-colon
972                { $$ = new IfCtl( $1, nullptr ); }
973        | declaration comma_expression                                          // semi-colon separated
974                { $$ = new IfCtl( $1, $2 ); }
975        ;
976
977// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
978// clause allows a list of values and subranges.
979
980case_value:                                                                                             // CFA
981        constant_expression                                                     { $$ = $1; }
982        | constant_expression ELLIPSIS constant_expression      // GCC, subrange
983                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
984        | subrange                                                                                      // CFA, subrange
985        ;
986
987case_value_list:                                                                                // CFA
988        case_value                                                                      { $$ = new StatementNode( build_case( $1 ) ); }
989                // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
990        | case_value_list ',' case_value                        { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
991        ;
992
993case_label:                                                                                             // CFA
994        CASE case_value_list ':'                                        { $$ = $2; }
995        | DEFAULT ':'                                                           { $$ = new StatementNode( build_default() ); }
996                // A semantic check is required to ensure only one default clause per switch/choose statement.
997        ;
998
999//label_list_opt:
1000//      // empty
1001//      | identifier_or_type_name ':'
1002//      | label_list_opt identifier_or_type_name ':'
1003//      ;
1004
1005case_label_list:                                                                                // CFA
1006        case_label
1007        | case_label_list case_label                            { $$ = (StatementNode *)( $1->set_last( $2 )); }
1008        ;
1009
1010case_clause:                                                                                    // CFA
1011        case_label_list statement                                       { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1012        ;
1013
1014switch_clause_list_opt:                                                                 // CFA
1015        // empty
1016                { $$ = nullptr; }
1017        | switch_clause_list
1018        ;
1019
1020switch_clause_list:                                                                             // CFA
1021        case_label_list statement_list_nodecl
1022                { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1023        | switch_clause_list case_label_list statement_list_nodecl
1024                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1025        ;
1026
1027iteration_statement:
1028        WHILE '(' comma_expression ')' statement
1029                { $$ = new StatementNode( build_while( $3, $5 ) ); }
1030        | DO statement WHILE '(' comma_expression ')' ';'
1031                { $$ = new StatementNode( build_while( $5, $2, true ) ); }
1032        | FOR '(' push for_control_expression ')' statement
1033                { $$ = new StatementNode( build_for( $4, $6 ) ); }
1034        ;
1035
1036for_control_expression:
1037        comma_expression_opt pop ';' comma_expression_opt ';' comma_expression_opt
1038                { $$ = new ForCtl( $1, $4, $6 ); }
1039        | declaration comma_expression_opt ';' comma_expression_opt // C99
1040                { $$ = new ForCtl( $1, $2, $4 ); }
1041        ;
1042
1043jump_statement:
1044        GOTO identifier_or_type_name ';'
1045                { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1046        | GOTO '*' comma_expression ';'                                         // GCC, computed goto
1047                // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1048                // whereas normal operator precedence yields goto (*i)+3;
1049                { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1050                // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1051    | fall_through_name ';'                                                             // CFA
1052                { $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1053    | fall_through_name identifier_or_type_name ';'             // CFA
1054                { $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1055        | fall_through_name DEFAULT ';'                                         // CFA
1056                { $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1057        | CONTINUE ';'
1058                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1059                { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1060        | CONTINUE identifier_or_type_name ';'                          // CFA, multi-level continue
1061                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1062                // the target of the transfer appears only at the start of an iteration statement.
1063                { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1064        | BREAK ';'
1065                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1066                { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1067        | BREAK identifier_or_type_name ';'                                     // CFA, multi-level exit
1068                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1069                // the target of the transfer appears only at the start of an iteration statement.
1070                { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1071        | RETURN comma_expression_opt ';'
1072                { $$ = new StatementNode( build_return( $2 ) ); }
1073        | RETURN '{' initializer_list_opt comma_opt '}'
1074                { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1075        | THROW assignment_expression_opt ';'                           // handles rethrow
1076                { $$ = new StatementNode( build_throw( $2 ) ); }
1077        | THROWRESUME assignment_expression_opt ';'                     // handles reresume
1078                { $$ = new StatementNode( build_resume( $2 ) ); }
1079        | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1080                { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1081        ;
1082
1083fall_through_name:                                                                              // CFA
1084        FALLTHRU
1085        | FALLTHROUGH
1086        ;
1087
1088with_statement:
1089        WITH '(' tuple_expression_list ')' statement
1090                {
1091                        $$ = new StatementNode( build_with( $3, $5 ) );
1092                }
1093        ;
1094
1095// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1096mutex_statement:
1097        MUTEX '(' argument_expression_list ')' statement
1098                { SemanticError( yylloc, "Mutex statement is currently unimplemented." ); $$ = nullptr; }
1099        ;
1100
1101when_clause:
1102        WHEN '(' comma_expression ')'                           { $$ = $3; }
1103        ;
1104
1105when_clause_opt:
1106        // empty
1107                { $$ = nullptr; }
1108        | when_clause
1109        ;
1110
1111waitfor:
1112        WAITFOR '(' identifier ')'
1113                {
1114                        $$ = new ExpressionNode( new NameExpr( *$3 ) );
1115                        delete $3;
1116                }
1117        | WAITFOR '(' identifier ',' argument_expression_list ')'
1118                {
1119                        $$ = new ExpressionNode( new NameExpr( *$3 ) );
1120                        $$->set_last( $5 );
1121                        delete $3;
1122                }
1123        ;
1124
1125timeout:
1126        TIMEOUT '(' comma_expression ')'                        { $$ = $3; }
1127        ;
1128
1129waitfor_clause:
1130        when_clause_opt waitfor statement                                       %prec THEN
1131                { $$ = build_waitfor( $2, $3, $1 ); }
1132        | when_clause_opt waitfor statement WOR waitfor_clause
1133                { $$ = build_waitfor( $2, $3, $1, $5 ); }
1134        | when_clause_opt timeout statement                                     %prec THEN
1135                { $$ = build_waitfor_timeout( $2, $3, $1 ); }
1136        | when_clause_opt ELSE statement
1137                { $$ = build_waitfor_timeout( nullptr, $3, $1 ); }
1138                // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1139        | when_clause_opt timeout statement WOR when_clause ELSE statement
1140                { $$ = build_waitfor_timeout( $2, $3, $1, $7, $5 ); }
1141        ;
1142
1143waitfor_statement:
1144        when_clause_opt waitfor statement                                       %prec THEN
1145                { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1146        | when_clause_opt waitfor statement WOR waitfor_clause
1147                { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1148        ;
1149
1150exception_statement:
1151        TRY compound_statement handler_clause
1152                { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1153        | TRY compound_statement finally_clause
1154                { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1155        | TRY compound_statement handler_clause finally_clause
1156                { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1157        ;
1158
1159handler_clause:
1160        handler_key '(' push push exception_declaration pop handler_predicate_opt ')' compound_statement pop
1161                { $$ = new StatementNode( build_catch( $1, $5, $7, $9 ) ); }
1162        | handler_clause handler_key '(' push push exception_declaration pop handler_predicate_opt ')' compound_statement pop
1163                { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $6, $8, $10 ) ) ); }
1164        ;
1165
1166handler_predicate_opt:
1167        // empty
1168                { $$ = nullptr; }
1169        | ';' conditional_expression                            { $$ = $2; }
1170        ;
1171
1172handler_key:
1173        CATCH                                                                           { $$ = CatchStmt::Terminate; }
1174        | CATCHRESUME                                                           { $$ = CatchStmt::Resume; }
1175        ;
1176
1177finally_clause:
1178        FINALLY compound_statement                                      { $$ = new StatementNode( build_finally( $2 ) ); }
1179        ;
1180
1181exception_declaration:
1182                // No SUE declaration in parameter list.
1183        type_specifier_nobody
1184        | type_specifier_nobody declarator
1185                { $$ = $2->addType( $1 ); }
1186        | type_specifier_nobody variable_abstract_declarator
1187                { $$ = $2->addType( $1 ); }
1188        | cfa_abstract_declarator_tuple no_attr_identifier      // CFA
1189                { $$ = $1->addName( $2 ); }
1190        | cfa_abstract_declarator_tuple                                         // CFA
1191        ;
1192
1193enable_disable_statement:
1194        enable_disable_key identifier_list compound_statement
1195        ;
1196
1197enable_disable_key:
1198        ENABLE
1199        | DISABLE
1200        ;
1201
1202asm_statement:
1203        ASM asm_volatile_opt '(' string_literal ')' ';'
1204                { $$ = new StatementNode( build_asm( $2, $4, 0 ) ); }
1205        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1206                { $$ = new StatementNode( build_asm( $2, $4, $6 ) ); }
1207        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1208                { $$ = new StatementNode( build_asm( $2, $4, $6, $8 ) ); }
1209        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1210                { $$ = new StatementNode( build_asm( $2, $4, $6, $8, $10 ) ); }
1211        | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1212                { $$ = new StatementNode( build_asm( $2, $5, 0, $8, $10, $12 ) ); }
1213        ;
1214
1215asm_volatile_opt:                                                                               // GCC
1216        // empty
1217                { $$ = false; }
1218        | VOLATILE
1219                { $$ = true; }
1220        ;
1221
1222asm_operands_opt:                                                                               // GCC
1223        // empty
1224                { $$ = nullptr; }                                                               // use default argument
1225        | asm_operands_list
1226        ;
1227
1228asm_operands_list:                                                                              // GCC
1229        asm_operand
1230        | asm_operands_list ',' asm_operand
1231                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
1232        ;
1233
1234asm_operand:                                                                                    // GCC
1235        string_literal '(' constant_expression ')'
1236                { $$ = new ExpressionNode( new AsmExpr( maybeMoveBuild< Expression >( (ExpressionNode *)nullptr ), $1, maybeMoveBuild< Expression >( $3 ) ) ); }
1237        | '[' constant_expression ']' string_literal '(' constant_expression ')'
1238                { $$ = new ExpressionNode( new AsmExpr( maybeMoveBuild< Expression >( $2 ), $4, maybeMoveBuild< Expression >( $6 ) ) ); }
1239        ;
1240
1241asm_clobbers_list_opt:                                                                  // GCC
1242        // empty
1243                { $$ = nullptr; }                                                               // use default argument
1244        | string_literal
1245                { $$ = new ExpressionNode( $1 ); }
1246        | asm_clobbers_list_opt ',' string_literal
1247                // set_last returns ParseNode *
1248                { $$ = (ExpressionNode *)$1->set_last( new ExpressionNode( $3 ) ); }
1249        ;
1250
1251label_list:
1252        no_attr_identifier
1253                {
1254                        $$ = new LabelNode(); $$->labels.push_back( *$1 );
1255                        delete $1;                                                                      // allocated by lexer
1256                }
1257        | label_list ',' no_attr_identifier
1258                {
1259                        $$ = $1; $1->labels.push_back( *$3 );
1260                        delete $3;                                                                      // allocated by lexer
1261                }
1262        ;
1263
1264//******************************* DECLARATIONS *********************************
1265
1266declaration_list_opt:                                                                   // used at beginning of switch statement
1267        pop
1268                { $$ = nullptr; }
1269        | declaration_list
1270        ;
1271
1272declaration_list:
1273        declaration
1274        | declaration_list push declaration
1275                { $$ = $1->appendList( $3 ); }
1276        ;
1277
1278KR_declaration_list_opt:                                                                // used to declare parameter types in K&R style functions
1279        // empty
1280                { $$ = nullptr; }
1281        | KR_declaration_list
1282        ;
1283
1284KR_declaration_list:
1285        push c_declaration pop ';'
1286                { $$ = $2; }
1287        | KR_declaration_list push c_declaration pop ';'
1288                { $$ = $1->appendList( $3 ); }
1289        ;
1290
1291local_label_declaration_opt:                                                    // GCC, local label
1292        // empty
1293        | local_label_declaration_list
1294        ;
1295
1296local_label_declaration_list:                                                   // GCC, local label
1297        LABEL local_label_list ';'
1298        | local_label_declaration_list LABEL local_label_list ';'
1299        ;
1300
1301local_label_list:                                                                               // GCC, local label
1302        no_attr_identifier_or_type_name
1303        | local_label_list ',' no_attr_identifier_or_type_name
1304        ;
1305
1306declaration:                                                                                    // old & new style declarations
1307        c_declaration pop ';'
1308        | cfa_declaration pop ';'                                                       // CFA
1309        | static_assert
1310        ;
1311
1312static_assert:
1313        STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1314                { $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1315
1316// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1317// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1318// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1319// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1320// the declaration list (as in Pascal).  ANSI C and the new CFA declarations may appear together in the same program
1321// block, but cannot be mixed within a specific declaration.
1322//
1323//                      CFA                                     C
1324//              [10] int x;                     int x[10];              // array of 10 integers
1325//              [10] * char y;          char *y[10];    // array of 10 pointers to char
1326
1327cfa_declaration:                                                                                // CFA
1328        cfa_variable_declaration
1329        | cfa_typedef_declaration
1330        | cfa_function_declaration
1331        | type_declaring_list
1332        | trait_specifier
1333        ;
1334
1335cfa_variable_declaration:                                                               // CFA
1336        cfa_variable_specifier initializer_opt
1337                { $$ = $1->addInitializer( $2 ); }
1338        | declaration_qualifier_list cfa_variable_specifier initializer_opt
1339                // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1340                // them as a type_qualifier cannot appear in that context.
1341                { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1342        | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1343                { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1344        ;
1345
1346cfa_variable_specifier:                                                                 // CFA
1347                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1348                // storage-class
1349        cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1350                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1351        | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1352                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1353        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1354                { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1355        ;
1356
1357cfa_function_declaration:                                                               // CFA
1358        cfa_function_specifier
1359                { $$ = $1; }
1360        | type_qualifier_list cfa_function_specifier
1361                { $$ = $2->addQualifiers( $1 ); }
1362        | declaration_qualifier_list cfa_function_specifier
1363                { $$ = $2->addQualifiers( $1 ); }
1364        | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1365                { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1366        | cfa_function_declaration ',' identifier_or_type_name '(' cfa_parameter_type_list_opt ')'
1367                {
1368                        // Append the return type at the start (left-hand-side) to each identifier in the list.
1369                        DeclarationNode * ret = new DeclarationNode;
1370                        ret->type = maybeClone( $1->type->base );
1371                        $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $5, nullptr ) );
1372                }
1373        ;
1374
1375cfa_function_specifier:                                                                 // CFA
1376//      '[' ']' identifier_or_type_name '(' push cfa_parameter_type_list_opt pop ')' // S/R conflict
1377//              {
1378//                      $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1379//              }
1380//      '[' ']' identifier '(' push cfa_parameter_type_list_opt pop ')'
1381//              {
1382//                      typedefTable.setNextIdentifier( *$5 );
1383//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1384//              }
1385//      | '[' ']' TYPEDEFname '(' push cfa_parameter_type_list_opt pop ')'
1386//              {
1387//                      typedefTable.setNextIdentifier( *$5 );
1388//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1389//              }
1390//      | '[' ']' typegen_name
1391                // identifier_or_type_name must be broken apart because of the sequence:
1392                //
1393                //   '[' ']' identifier_or_type_name '(' cfa_parameter_type_list_opt ')'
1394                //   '[' ']' type_specifier
1395                //
1396                // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1397                // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1398        cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_type_list_opt pop ')'
1399                // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1400                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 ); }
1401        | cfa_function_return identifier_or_type_name '(' push cfa_parameter_type_list_opt pop ')'
1402                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 ); }
1403        ;
1404
1405cfa_function_return:                                                                    // CFA
1406        '[' push cfa_parameter_list pop ']'
1407                { $$ = DeclarationNode::newTuple( $3 ); }
1408        | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1409                // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the
1410                // ']'.
1411                { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1412        ;
1413
1414cfa_typedef_declaration:                                                                // CFA
1415        TYPEDEF cfa_variable_specifier
1416                {
1417                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname );
1418                        $$ = $2->addTypedef();
1419                }
1420        | TYPEDEF cfa_function_specifier
1421                {
1422                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname );
1423                        $$ = $2->addTypedef();
1424                }
1425        | cfa_typedef_declaration pop ',' push no_attr_identifier
1426                {
1427                        typedefTable.addToEnclosingScope( *$5, TYPEDEFname );
1428                        $$ = $1->appendList( $1->cloneType( $5 ) );
1429                }
1430        ;
1431
1432// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1433// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1434
1435typedef_declaration:
1436        TYPEDEF type_specifier declarator
1437                {
1438                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname );
1439                        $$ = $3->addType( $2 )->addTypedef();
1440                }
1441        | typedef_declaration pop ',' push declarator
1442                {
1443                        typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname );
1444                        $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1445                }
1446        | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1447                {
1448                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname );
1449                        $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1450                }
1451        | type_specifier TYPEDEF declarator
1452                {
1453                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname );
1454                        $$ = $3->addType( $1 )->addTypedef();
1455                }
1456        | type_specifier TYPEDEF type_qualifier_list declarator
1457                {
1458                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname );
1459                        $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1460                }
1461        ;
1462
1463typedef_expression:
1464                // GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1465        TYPEDEF no_attr_identifier '=' assignment_expression
1466                {
1467                        // $$ = DeclarationNode::newName( 0 );                  // unimplemented
1468                        SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1469                }
1470        | typedef_expression pop ',' push no_attr_identifier '=' assignment_expression
1471                {
1472                        // $$ = DeclarationNode::newName( 0 );                  // unimplemented
1473                        SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1474                }
1475        ;
1476
1477//c_declaration:
1478//      declaring_list pop ';'
1479//      | typedef_declaration pop ';'
1480//      | typedef_expression pop ';'                                            // GCC, naming expression type
1481//      | sue_declaration_specifier pop ';'
1482//      ;
1483//
1484//declaring_list:
1485//              // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1486//              // storage-class
1487//       declarator asm_name_opt initializer_opt
1488//              {
1489//                      typedefTable.addToEnclosingScope( IDENTIFIER );
1490//                      $$ = ( $2->addType( $1 ))->addAsmName( $3 )->addInitializer( $4 );
1491//              }
1492//      | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1493//              {
1494//                      typedefTable.addToEnclosingScope( IDENTIFIER );
1495//                      $$ = $1->appendList( $1->cloneBaseType( $4->addAsmName( $5 )->addInitializer( $6 ) ) );
1496//              }
1497//      ;
1498
1499c_declaration:
1500        declaration_specifier declaring_list
1501                { $$ = distAttr( $1, $2 ); }
1502        | typedef_declaration
1503        | typedef_expression                                                            // GCC, naming expression type
1504        | sue_declaration_specifier
1505        ;
1506
1507declaring_list:
1508                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1509                // storage-class
1510        declarator asm_name_opt initializer_opt
1511                { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
1512        | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1513                { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
1514        ;
1515
1516declaration_specifier:                                                                  // type specifier + storage class
1517        basic_declaration_specifier
1518        | sue_declaration_specifier
1519        | type_declaration_specifier
1520        ;
1521
1522declaration_specifier_nobody:                                                   // type specifier + storage class - {...}
1523                // Preclude SUE declarations in restricted scopes:
1524                //
1525                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1526                //
1527                // because it is impossible to call f due to name equivalence.
1528        basic_declaration_specifier
1529        | sue_declaration_specifier_nobody
1530        | type_declaration_specifier
1531        ;
1532
1533type_specifier:                                                                                 // type specifier
1534        basic_type_specifier
1535        | sue_type_specifier
1536        | type_type_specifier
1537        ;
1538
1539type_specifier_nobody:                                                                  // type specifier - {...}
1540                // Preclude SUE declarations in restricted scopes:
1541                //
1542                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1543                //
1544                // because it is impossible to call f due to name equivalence.
1545        basic_type_specifier
1546        | sue_type_specifier_nobody
1547        | type_type_specifier
1548        ;
1549
1550type_qualifier_list_opt:                                                                // GCC, used in asm_statement
1551        // empty
1552                { $$ = nullptr; }
1553        | type_qualifier_list
1554        ;
1555
1556type_qualifier_list:
1557                // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1558                //
1559                // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1560                // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1561                // appeared only once.
1562        type_qualifier
1563        | type_qualifier_list type_qualifier
1564                { $$ = $1->addQualifiers( $2 ); }
1565        ;
1566
1567type_qualifier:
1568        type_qualifier_name
1569        | attribute
1570        ;
1571
1572type_qualifier_name:
1573        CONST
1574                { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1575        | RESTRICT
1576                { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1577        | VOLATILE
1578                { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1579        | ATOMIC
1580                { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1581        | forall
1582        ;
1583
1584forall:
1585        FORALL '(' push type_parameter_list pop ')'                                     // CFA
1586                { $$ = DeclarationNode::newForall( $4 ); }
1587        ;
1588
1589declaration_qualifier_list:
1590        storage_class_list
1591        | type_qualifier_list storage_class_list                        // remaining OBSOLESCENT (see 2 )
1592                { $$ = $1->addQualifiers( $2 ); }
1593        | declaration_qualifier_list type_qualifier_list storage_class_list
1594                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1595        ;
1596
1597storage_class_list:
1598                // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1599                // only one of each is specified, except for inline, which can appear with the others.
1600                //
1601                // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1602                // specifiers in a declaration.
1603        storage_class
1604        | storage_class_list storage_class
1605                { $$ = $1->addQualifiers( $2 ); }
1606        ;
1607
1608storage_class:
1609        EXTERN
1610                { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1611        | STATIC
1612                { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1613        | AUTO
1614                { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1615        | REGISTER
1616                { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1617        | THREADLOCAL                                                                           // C11
1618                { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1619                // Put function specifiers here to simplify parsing rules, but separate them semantically.
1620        | INLINE                                                                                        // C99
1621                { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1622        | FORTRAN                                                                                       // C99
1623                { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1624        | NORETURN                                                                                      // C11
1625                { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1626        ;
1627
1628basic_type_name:
1629        VOID
1630                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1631        | BOOL                                                                                          // C99
1632                { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1633        | CHAR
1634                { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1635        | INT
1636                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1637        | INT128
1638                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1639        | FLOAT
1640                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1641        | FLOAT80
1642                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float80 ); }
1643        | FLOAT128
1644                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float128 ); }
1645        | DOUBLE
1646                { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1647        | COMPLEX                                                                                       // C99
1648                { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1649        | IMAGINARY                                                                                     // C99
1650                { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1651        | SIGNED
1652                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1653        | UNSIGNED
1654                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1655        | SHORT
1656                { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1657        | LONG
1658                { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1659        | VALIST                                                                                        // GCC, __builtin_va_list
1660                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1661        ;
1662
1663basic_declaration_specifier:
1664                // A semantic check is necessary for conflicting storage classes.
1665        basic_type_specifier
1666        | declaration_qualifier_list basic_type_specifier
1667                { $$ = $2->addQualifiers( $1 ); }
1668        | basic_declaration_specifier storage_class                     // remaining OBSOLESCENT (see 2)
1669                { $$ = $1->addQualifiers( $2 ); }
1670        | basic_declaration_specifier storage_class type_qualifier_list
1671                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1672        | basic_declaration_specifier storage_class basic_type_specifier
1673                { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1674        ;
1675
1676basic_type_specifier:
1677        direct_type
1678                // Cannot have type modifiers, e.g., short, long, etc.
1679        | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1680                { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1681        ;
1682
1683direct_type:
1684        basic_type_name
1685        | type_qualifier_list basic_type_name
1686                { $$ = $2->addQualifiers( $1 ); }
1687        | direct_type type_qualifier
1688                { $$ = $1->addQualifiers( $2 ); }
1689        | direct_type basic_type_name
1690                { $$ = $1->addType( $2 ); }
1691        ;
1692
1693indirect_type:
1694        TYPEOF '(' type ')'                                                                     // GCC: typeof(x) y;
1695                { $$ = $3; }
1696        | TYPEOF '(' comma_expression ')'                                       // GCC: typeof(a+b) y;
1697                { $$ = DeclarationNode::newTypeof( $3 ); }
1698        | ATTR_TYPEGENname '(' type ')'                                         // CFA: e.g., @type(x) y;
1699                { $$ = DeclarationNode::newAttr( $1, $3 ); }
1700        | ATTR_TYPEGENname '(' comma_expression ')'                     // CFA: e.g., @type(a+b) y;
1701                { $$ = DeclarationNode::newAttr( $1, $3 ); }
1702        | ZERO_T                                                                                        // CFA
1703                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1704        | ONE_T                                                                                         // CFA
1705                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1706        ;
1707
1708sue_declaration_specifier:                                                              // struct, union, enum + storage class + type specifier
1709        sue_type_specifier
1710        | declaration_qualifier_list sue_type_specifier
1711                { $$ = $2->addQualifiers( $1 ); }
1712        | sue_declaration_specifier storage_class                       // remaining OBSOLESCENT (see 2)
1713                { $$ = $1->addQualifiers( $2 ); }
1714        | sue_declaration_specifier storage_class type_qualifier_list
1715                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1716        ;
1717
1718sue_type_specifier:                                                                             // struct, union, enum + type specifier
1719        elaborated_type
1720        | type_qualifier_list
1721                { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1722          elaborated_type
1723                { $$ = $3->addQualifiers( $1 ); }
1724        | sue_type_specifier type_qualifier
1725                { $$ = $1->addQualifiers( $2 ); }
1726        ;
1727
1728sue_declaration_specifier_nobody:                                               // struct, union, enum - {...} + storage class + type specifier
1729        sue_type_specifier_nobody
1730        | declaration_qualifier_list sue_type_specifier_nobody
1731                { $$ = $2->addQualifiers( $1 ); }
1732        | sue_declaration_specifier_nobody storage_class        // remaining OBSOLESCENT (see 2)
1733                { $$ = $1->addQualifiers( $2 ); }
1734        | sue_declaration_specifier_nobody storage_class type_qualifier_list
1735                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1736        ;
1737
1738sue_type_specifier_nobody:                                                              // struct, union, enum - {...} + type specifier
1739        elaborated_type_nobody
1740        | type_qualifier_list elaborated_type_nobody
1741                { $$ = $2->addQualifiers( $1 ); }
1742        | sue_type_specifier_nobody type_qualifier
1743                { $$ = $1->addQualifiers( $2 ); }
1744        ;
1745
1746type_declaration_specifier:
1747        type_type_specifier
1748        | declaration_qualifier_list type_type_specifier
1749                { $$ = $2->addQualifiers( $1 ); }
1750        | type_declaration_specifier storage_class                      // remaining OBSOLESCENT (see 2)
1751                { $$ = $1->addQualifiers( $2 ); }
1752        | type_declaration_specifier storage_class type_qualifier_list
1753                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1754        ;
1755
1756type_type_specifier:                                                                    // typedef types
1757        type_name
1758        | type_qualifier_list type_name
1759                { $$ = $2->addQualifiers( $1 ); }
1760        | type_type_specifier type_qualifier
1761                { $$ = $1->addQualifiers( $2 ); }
1762        ;
1763
1764type_name:
1765        TYPEDEFname
1766                { $$ = DeclarationNode::newFromTypedef( $1 ); }
1767        | '.' TYPEDEFname
1768                { $$ = DeclarationNode::newFromTypedef( $2 ); } // FIX ME
1769        | type_name '.' TYPEDEFname
1770                { $$ = DeclarationNode::newFromTypedef( $3 ); } // FIX ME
1771        | typegen_name
1772        | '.' typegen_name
1773                { $$ = $2; }                                                                    // FIX ME
1774        | type_name '.' typegen_name
1775                { $$ = $3; }                                                                    // FIX ME
1776        ;
1777
1778typegen_name:                                                                                   // CFA
1779        TYPEGENname
1780                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1781        | TYPEGENname '(' ')'
1782                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1783        | TYPEGENname '(' type_list ')'
1784                { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
1785        ;
1786
1787elaborated_type:                                                                                // struct, union, enum
1788        aggregate_type
1789        | enum_type
1790        ;
1791
1792elaborated_type_nobody:                                                                 // struct, union, enum - {...}
1793        aggregate_type_nobody
1794        | enum_type_nobody
1795        ;
1796
1797aggregate_type:                                                                                 // struct, union
1798        aggregate_key attribute_list_opt '{' field_declaration_list_opt '}'
1799                { $$ = DeclarationNode::newAggregate( $1, new string( DeclarationNode::anonymous.newName() ), nullptr, $4, true )->addQualifiers( $2 ); }
1800        | aggregate_key attribute_list_opt no_attr_identifier_or_type_name
1801                {
1802                        typedefTable.makeTypedef( *$3 );                        // create typedef
1803                        if ( forall ) typedefTable.changeKind( *$3, TYPEGENname ); // possibly update
1804                        forall = false;                                                         // reset
1805                }
1806          '{' field_declaration_list_opt '}'
1807                { $$ = DeclarationNode::newAggregate( $1, $3, nullptr, $6, true )->addQualifiers( $2 ); }
1808        | aggregate_key attribute_list_opt '(' type_list ')' '{' field_declaration_list_opt '}' // CFA
1809                { $$ = DeclarationNode::newAggregate( $1, new string( DeclarationNode::anonymous.newName() ), $4, $7, false )->addQualifiers( $2 ); }
1810        | aggregate_type_nobody
1811        ;
1812
1813aggregate_type_nobody:                                                                  // struct, union - {...}
1814        aggregate_key attribute_list_opt no_attr_identifier
1815                {
1816                        typedefTable.makeTypedef( *$3 );
1817                        if ( forall ) typedefTable.changeKind( *$3, TYPEGENname ); // possibly update
1818                        forall = false;                                                         // reset
1819                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
1820                }
1821        | aggregate_key attribute_list_opt TYPEDEFname
1822                {
1823                        typedefTable.makeTypedef( *$3 );
1824                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
1825                }
1826        | aggregate_key attribute_list_opt typegen_name         // CFA
1827                {
1828                        // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
1829                        // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
1830                        // delete newFromTypeGen.
1831                        $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
1832                        $3->type->symbolic.name = nullptr;
1833                        $3->type->symbolic.actuals = nullptr;
1834                        delete $3;
1835                }
1836        ;
1837
1838aggregate_key:
1839        STRUCT
1840                { $$ = DeclarationNode::Struct; }
1841        | UNION
1842                { $$ = DeclarationNode::Union; }
1843        | EXCEPTION
1844                { $$ = DeclarationNode::Exception; }
1845        | COROUTINE
1846                { $$ = DeclarationNode::Coroutine; }
1847        | MONITOR
1848                { $$ = DeclarationNode::Monitor; }
1849        | THREAD
1850                { $$ = DeclarationNode::Thread; }
1851        ;
1852
1853field_declaration_list_opt:
1854        // empty
1855                { $$ = nullptr; }
1856        | field_declaration_list_opt field_declaration
1857                { $$ = $1 ? $1->appendList( $2 ) : $2; }
1858        ;
1859
1860field_declaration:
1861        cfa_field_declaring_list ';'                                            // CFA, new style field declaration
1862        | EXTENSION cfa_field_declaring_list ';'                        // GCC
1863                {
1864                        distExt( $2 );                                                          // mark all fields in list
1865                        $$ = $2;
1866                }
1867        | type_specifier field_declaring_list ';'
1868                {
1869                        $$ = distAttr( $1, $2 ); }
1870        | EXTENSION type_specifier field_declaring_list ';'     // GCC
1871                {
1872                        distExt( $3 );                                                          // mark all fields in list
1873                        $$ = distAttr( $2, $3 );
1874                }
1875        | static_assert
1876        ;
1877
1878cfa_field_declaring_list:                                                               // CFA, new style field declaration
1879        cfa_abstract_declarator_tuple                                           // CFA, no field name
1880        | cfa_abstract_declarator_tuple no_attr_identifier_or_type_name
1881                { $$ = $1->addName( $2 ); }
1882        | cfa_field_declaring_list ',' no_attr_identifier_or_type_name
1883                { $$ = $1->appendList( $1->cloneType( $3 ) ); }
1884        | cfa_field_declaring_list ','                                          // CFA, no field name
1885                { $$ = $1->appendList( $1->cloneType( 0 ) ); }
1886        ;
1887
1888field_declaring_list:
1889        field_declarator_opt
1890        | field_declaring_list ',' attribute_list_opt field_declarator_opt
1891                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
1892        ;
1893
1894field_declarator_opt:
1895        // empty
1896                { $$ = DeclarationNode::newName( 0 ); /* XXX */ } // CFA, no field name
1897        // '@'
1898        //      { $$ = DeclarationNode::newName( new string( DeclarationNode::anonymous.newName() ) ); } // CFA, no field name
1899        | bit_subrange_size                                                                     // no field name
1900                { $$ = DeclarationNode::newBitfield( $1 ); }
1901        | variable_declarator bit_subrange_size_opt
1902                // A semantic check is required to ensure bit_subrange only appears on base type int.
1903                { $$ = $1->addBitfield( $2 ); }
1904        | variable_type_redeclarator bit_subrange_size_opt
1905                // A semantic check is required to ensure bit_subrange only appears on base type int.
1906                { $$ = $1->addBitfield( $2 ); }
1907        | variable_abstract_declarator                                          // CFA, no field name
1908        ;
1909
1910bit_subrange_size_opt:
1911        // empty
1912                { $$ = nullptr; }
1913        | bit_subrange_size
1914                { $$ = $1; }
1915        ;
1916
1917bit_subrange_size:
1918        ':' constant_expression
1919                { $$ = $2; }
1920        ;
1921
1922enum_type:                                                                                              // enum
1923        ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
1924                { $$ = DeclarationNode::newEnum( new string( DeclarationNode::anonymous.newName() ), $4, true )->addQualifiers( $2 ); }
1925        | ENUM attribute_list_opt no_attr_identifier_or_type_name
1926                { typedefTable.makeTypedef( *$3 ); }
1927          '{' enumerator_list comma_opt '}'
1928                { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
1929        | enum_type_nobody
1930        ;
1931
1932enum_type_nobody:                                                                               // enum - {...}
1933        ENUM attribute_list_opt no_attr_identifier_or_type_name
1934                {
1935                        typedefTable.makeTypedef( *$3 );
1936                        $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 );
1937                }
1938        ;
1939
1940enumerator_list:
1941        no_attr_identifier_or_type_name enumerator_value_opt
1942                { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
1943        | enumerator_list ',' no_attr_identifier_or_type_name enumerator_value_opt
1944                { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
1945        ;
1946
1947enumerator_value_opt:
1948        // empty
1949                { $$ = nullptr; }
1950        | '=' constant_expression
1951                { $$ = $2; }
1952        ;
1953
1954cfa_parameter_type_list_opt:                                                    // CFA, abstract + real
1955        // empty
1956                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1957        | ELLIPSIS
1958                { $$ = nullptr; }
1959        | cfa_abstract_parameter_list
1960        | cfa_parameter_list
1961        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
1962                { $$ = $1->appendList( $5 ); }
1963        | cfa_abstract_parameter_list pop ',' push ELLIPSIS
1964                { $$ = $1->addVarArgs(); }
1965        | cfa_parameter_list pop ',' push ELLIPSIS
1966                { $$ = $1->addVarArgs(); }
1967        ;
1968
1969cfa_parameter_list:                                                                             // CFA
1970                // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
1971                // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
1972        cfa_parameter_declaration
1973        | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
1974                { $$ = $1->appendList( $5 ); }
1975        | cfa_parameter_list pop ',' push cfa_parameter_declaration
1976                { $$ = $1->appendList( $5 ); }
1977        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
1978                { $$ = $1->appendList( $5 )->appendList( $9 ); }
1979        ;
1980
1981cfa_abstract_parameter_list:                                                    // CFA, new & old style abstract
1982        cfa_abstract_parameter_declaration
1983        | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
1984                { $$ = $1->appendList( $5 ); }
1985        ;
1986
1987parameter_type_list_opt:
1988        // empty
1989                { $$ = nullptr; }
1990        | ELLIPSIS
1991                { $$ = nullptr; }
1992        | parameter_list
1993        | parameter_list pop ',' push ELLIPSIS
1994                { $$ = $1->addVarArgs(); }
1995        ;
1996
1997parameter_list:                                                                                 // abstract + real
1998        abstract_parameter_declaration
1999        | parameter_declaration
2000        | parameter_list pop ',' push abstract_parameter_declaration
2001                { $$ = $1->appendList( $5 ); }
2002        | parameter_list pop ',' push parameter_declaration
2003                { $$ = $1->appendList( $5 ); }
2004        ;
2005
2006// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2007// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2008
2009cfa_parameter_declaration:                                                              // CFA, new & old style parameter declaration
2010        parameter_declaration
2011        | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initialize_opt
2012                { $$ = $1->addName( $2 ); }
2013        | cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2014                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2015                { $$ = $1->addName( $2 ); }
2016        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2017                { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2018        | cfa_function_specifier
2019        ;
2020
2021cfa_abstract_parameter_declaration:                                             // CFA, new & old style parameter declaration
2022        abstract_parameter_declaration
2023        | cfa_identifier_parameter_declarator_no_tuple
2024        | cfa_abstract_tuple
2025                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2026        | type_qualifier_list cfa_abstract_tuple
2027                { $$ = $2->addQualifiers( $1 ); }
2028        | cfa_abstract_function
2029        ;
2030
2031parameter_declaration:
2032                // No SUE declaration in parameter list.
2033        declaration_specifier_nobody identifier_parameter_declarator default_initialize_opt
2034                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2035        | declaration_specifier_nobody type_parameter_redeclarator default_initialize_opt
2036                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2037        ;
2038
2039abstract_parameter_declaration:
2040        declaration_specifier_nobody default_initialize_opt
2041                { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2042        | declaration_specifier_nobody abstract_parameter_declarator default_initialize_opt
2043                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2044        ;
2045
2046// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2047// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2048// identifiers.  The ANSI-style parameter-list can redefine a typedef name.
2049
2050identifier_list:                                                                                // K&R-style parameter list => no types
2051        no_attr_identifier
2052                { $$ = DeclarationNode::newName( $1 ); }
2053        | identifier_list ',' no_attr_identifier
2054                { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2055        ;
2056
2057identifier_or_type_name:
2058        identifier
2059        | TYPEDEFname
2060        | TYPEGENname
2061        ;
2062
2063no_attr_identifier_or_type_name:
2064        no_attr_identifier
2065        | TYPEDEFname
2066        | TYPEGENname
2067        ;
2068
2069type_no_function:                                                                               // sizeof, alignof, cast (constructor)
2070        cfa_abstract_declarator_tuple                                           // CFA
2071        | type_specifier
2072        | type_specifier abstract_declarator
2073                { $$ = $2->addType( $1 ); }
2074        ;
2075
2076type:                                                                                                   // typeof, assertion
2077        type_no_function
2078        | cfa_abstract_function                                                         // CFA
2079        ;
2080
2081initializer_opt:
2082        // empty
2083                { $$ = nullptr; }
2084        | '=' initializer
2085                { $$ = $2; }
2086        | '=' VOID
2087                { $$ = nullptr; }
2088        | ATassign initializer
2089                { $$ = $2->set_maybeConstructed( false ); }
2090        ;
2091
2092initializer:
2093        assignment_expression                                           { $$ = new InitializerNode( $1 ); }
2094        | '{' initializer_list_opt comma_opt '}'        { $$ = new InitializerNode( $2, true ); }
2095        ;
2096
2097initializer_list_opt:
2098        // empty
2099                { $$ = nullptr; }
2100        | initializer
2101        | designation initializer                                       { $$ = $2->set_designators( $1 ); }
2102        | initializer_list_opt ',' initializer          { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2103        | initializer_list_opt ',' designation initializer
2104                { $$ = (InitializerNode *)( $1->set_last( $4->set_designators( $3 ) ) ); }
2105        ;
2106
2107// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2108// '=' to separator the designator from the initializer value, as in:
2109//
2110//              int x[10] = { [1] = 3 };
2111//
2112// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment.  To disambiguate this case, CFA
2113// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2114// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2115// shift/reduce conflicts
2116
2117designation:
2118        designator_list ':'                                                                     // C99, CFA uses ":" instead of "="
2119        | no_attr_identifier ':'                                                        // GCC, field name
2120                { $$ = new ExpressionNode( build_varref( $1 ) ); }
2121        ;
2122
2123designator_list:                                                                                // C99
2124        designator
2125        | designator_list designator
2126                { $$ = (ExpressionNode *)( $1->set_last( $2 ) ); }
2127        //| designator_list designator                                          { $$ = new ExpressionNode( $1, $2 ); }
2128        ;
2129
2130designator:
2131        '.' no_attr_identifier                                                          // C99, field name
2132                { $$ = new ExpressionNode( build_varref( $2 ) ); }
2133        | '[' push assignment_expression pop ']'                        // C99, single array element
2134                // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2135                { $$ = $3; }
2136        | '[' push subrange pop ']'                                                     // CFA, multiple array elements
2137                { $$ = $3; }
2138        | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2139                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $3 ), maybeMoveBuild< Expression >( $5 ) ) ); }
2140        | '.' '[' push field_list pop ']'                                       // CFA, tuple field selector
2141                { $$ = $4; }
2142        ;
2143
2144// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2145// rather than an object-oriented type system. This required four groups of extensions:
2146//
2147// Overloading: function, data, and operator identifiers may be overloaded.
2148//
2149// Type declarations: "type" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2150//     and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2151//     definitions of new types. Type declarations with storage class "extern" provide opaque types.
2152//
2153// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2154//     site. A polymorphic function is not a template; it is a function, with an address and a type.
2155//
2156// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2157//     types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2158//     hierarchies. Unlike classes, they can define relationships between types.  Assertions declare that a type or
2159//     types provide the operations declared by a specification.  Assertions are normally used to declare requirements
2160//     on type arguments of polymorphic functions.
2161
2162type_parameter_list:                                                                    // CFA
2163        type_parameter
2164                { $$ = $1; }
2165        | type_parameter_list ',' type_parameter
2166                { $$ = $1->appendList( $3 ); }
2167        ;
2168
2169type_initializer_opt:                                                                   // CFA
2170        // empty
2171                { $$ = nullptr; }
2172        | '=' type
2173                { $$ = $2; }
2174        ;
2175
2176type_parameter:                                                                                 // CFA
2177        type_class no_attr_identifier_or_type_name
2178                { typedefTable.addToEnclosingScope( *$2, TYPEDEFname ); }
2179          type_initializer_opt assertion_list_opt
2180                { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2181        | type_specifier identifier_parameter_declarator
2182        | assertion_list
2183                { $$ = DeclarationNode::newTypeParam( DeclarationNode::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2184        ;
2185
2186type_class:                                                                                             // CFA
2187        OTYPE
2188                { $$ = DeclarationNode::Otype; }
2189        | DTYPE
2190                { $$ = DeclarationNode::Dtype; }
2191        | FTYPE
2192                { $$ = DeclarationNode::Ftype; }
2193        | TTYPE
2194                { $$ = DeclarationNode::Ttype; }
2195        ;
2196
2197assertion_list_opt:                                                                             // CFA
2198        // empty
2199                { $$ = nullptr; }
2200        | assertion_list
2201        ;
2202
2203assertion_list:                                                                                 // CFA
2204        assertion
2205        | assertion_list assertion
2206                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2207        ;
2208
2209assertion:                                                                                              // CFA
2210        '|' no_attr_identifier_or_type_name '(' type_list ')'
2211                { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
2212        | '|' '{' push trait_declaration_list '}'
2213                { $$ = $4; }
2214        | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list '}' '(' type_list ')'
2215                { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
2216        ;
2217
2218type_list:                                                                                              // CFA
2219        type
2220                { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2221        | assignment_expression
2222        | type_list ',' type
2223                { $$ = (ExpressionNode *)( $1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) ) ); }
2224        | type_list ',' assignment_expression
2225                { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2226        ;
2227
2228type_declaring_list:                                                                    // CFA
2229        OTYPE type_declarator
2230                { $$ = $2; }
2231        | storage_class_list OTYPE type_declarator
2232                { $$ = $3->addQualifiers( $1 ); }
2233        | type_declaring_list ',' type_declarator
2234                { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2235        ;
2236
2237type_declarator:                                                                                // CFA
2238        type_declarator_name assertion_list_opt
2239                { $$ = $1->addAssertions( $2 ); }
2240        | type_declarator_name assertion_list_opt '=' type
2241                { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2242        ;
2243
2244type_declarator_name:                                                                   // CFA
2245        no_attr_identifier_or_type_name
2246                {
2247                        typedefTable.addToEnclosingScope( *$1, TYPEDEFname );
2248                        $$ = DeclarationNode::newTypeDecl( $1, 0 );
2249                }
2250        | no_attr_identifier_or_type_name '(' push type_parameter_list pop ')'
2251                {
2252                        typedefTable.addToEnclosingScope( *$1, TYPEGENname );
2253                        $$ = DeclarationNode::newTypeDecl( $1, $4 );
2254                }
2255        ;
2256
2257trait_specifier:                                                                                // CFA
2258        TRAIT no_attr_identifier_or_type_name '(' push type_parameter_list pop ')' '{' '}'
2259                { $$ = DeclarationNode::newTrait( $2, $5, 0 ); }
2260        | TRAIT no_attr_identifier_or_type_name '(' push type_parameter_list pop ')' '{'
2261                { typedefTable.enterScope(); }
2262          trait_declaration_list '}'
2263                { $$ = DeclarationNode::newTrait( $2, $5, $10 ); }
2264        ;
2265
2266trait_declaration_list:                                                                 // CFA
2267        trait_declaration
2268        | trait_declaration_list push trait_declaration
2269                { $$ = $1->appendList( $3 ); }
2270        ;
2271
2272trait_declaration:                                                                              // CFA
2273        cfa_trait_declaring_list pop ';'
2274        | trait_declaring_list pop ';'
2275        ;
2276
2277cfa_trait_declaring_list:                                                               // CFA
2278        cfa_variable_specifier
2279        | cfa_function_specifier
2280        | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2281                { $$ = $1->appendList( $1->cloneType( $5 ) ); }
2282        ;
2283
2284trait_declaring_list:                                                                   // CFA
2285        type_specifier declarator
2286                { $$ = $2->addType( $1 ); }
2287        | trait_declaring_list pop ',' push declarator
2288                { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
2289        ;
2290
2291//***************************** EXTERNAL DEFINITIONS *****************************
2292
2293translation_unit:
2294        // empty
2295                {}                                                                                              // empty input file
2296        | external_definition_list
2297                { parseTree = parseTree ? parseTree->appendList( $1 ) : $1;     }
2298        ;
2299
2300external_definition_list:
2301        external_definition
2302        | external_definition_list
2303                { forall = xxx; }
2304          push external_definition
2305                { $$ = $1 ? $1->appendList( $4 ) : $4; }
2306        ;
2307
2308external_definition_list_opt:
2309        // empty
2310                { $$ = nullptr; }
2311        | external_definition_list
2312        ;
2313
2314external_definition:
2315        declaration
2316        | external_function_definition
2317        | ASM '(' string_literal ')' ';'                                        // GCC, global assembler statement
2318                {
2319                        $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( false, $3, 0 ) ) );
2320                }
2321        | EXTERN STRINGliteral                                                          // C++-style linkage specifier
2322                {
2323                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
2324                        linkage = LinkageSpec::linkageUpdate( yylloc, linkage, $2 );
2325                }
2326          '{' external_definition_list_opt '}'
2327                {
2328                        linkage = linkageStack.top();
2329                        linkageStack.pop();
2330                        $$ = $5;
2331                }
2332        | EXTENSION external_definition                                         // GCC, multiple __extension__ allowed, meaning unknown
2333                {
2334                        distExt( $2 );                                                          // mark all fields in list
2335                        $$ = $2;
2336                }
2337        | type_qualifier_list
2338                { if ( $1->type->forall ) xxx = forall = true; } // remember generic type
2339          push '{' external_definition_list '}'                         // CFA, namespace
2340                {
2341                        for ( DeclarationNode * iter = $5; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
2342                                if ( isMangled( iter->linkage ) ) {             // ignore extern "C"
2343                                        iter->addQualifiers( $1->clone() );
2344                                } // if
2345                        } // for
2346                        xxx = false;
2347                        delete $1;
2348                        $$ = $5;
2349                }
2350        | declaration_qualifier_list
2351                { if ( $1->type->forall ) xxx = forall = true; } // remember generic type
2352          push '{' external_definition_list '}'                         // CFA, namespace
2353                {
2354                        for ( DeclarationNode * iter = $5; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
2355                                if ( isMangled( iter->linkage ) ) {             // ignore extern "C"
2356                                        iter->addQualifiers( $1->clone() );
2357                                } // if
2358                        } // for
2359                        xxx = false;
2360                        delete $1;
2361                        $$ = $5;
2362                }
2363        | declaration_qualifier_list type_qualifier_list
2364                {
2365                        // forall must be in the type_qualifier_list
2366                        if ( $2->type->forall ) xxx = forall = true; // remember generic type
2367                }
2368          push '{' external_definition_list '}'                         // CFA, namespace
2369                {
2370                        for ( DeclarationNode * iter = $6; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
2371                                if ( isMangled( iter->linkage ) && isMangled( $2->linkage ) ) { // ignore extern "C"
2372                                        iter->addQualifiers( $1->clone() );
2373                                        iter->addQualifiers( $2->clone() );
2374                                } // if
2375                        } // for
2376                        xxx = false;
2377                        delete $1;
2378                        delete $2;
2379                        $$ = $6;
2380                }
2381        ;
2382
2383external_function_definition:
2384        function_definition
2385                // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2386                // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2387                // Parsing is possible because function_definition does not appear in the context of an expression (nested
2388                // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2389                // declaration must still have a type_specifier.  OBSOLESCENT (see 1)
2390        | function_declarator compound_statement
2391                { $$ = $1->addFunctionBody( $2 ); }
2392        | KR_function_declarator KR_declaration_list_opt compound_statement
2393                { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
2394        ;
2395
2396with_clause_opt:
2397        // empty
2398                { $$ = nullptr; forall = false; }
2399        | WITH '(' tuple_expression_list ')'
2400                { $$ = $3; forall = false; }
2401        ;
2402
2403function_definition:
2404        cfa_function_declaration with_clause_opt compound_statement     // CFA
2405                {
2406                        // Add the function body to the last identifier in the function definition list, i.e., foo3:
2407                        //   [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2408                        $1->get_last()->addFunctionBody( $3, $2 );
2409                        $$ = $1;
2410                }
2411        | declaration_specifier function_declarator with_clause_opt compound_statement
2412                {
2413                        rebindForall( $1, $2 );
2414                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2415                }
2416        | declaration_specifier variable_type_redeclarator with_clause_opt compound_statement
2417                {
2418                        rebindForall( $1, $2 );
2419                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2420                }
2421                // handles default int return type, OBSOLESCENT (see 1)
2422        | type_qualifier_list function_declarator with_clause_opt compound_statement
2423                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2424                // handles default int return type, OBSOLESCENT (see 1)
2425        | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2426                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2427                // handles default int return type, OBSOLESCENT (see 1)
2428        | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2429                { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2430
2431                // Old-style K&R function definition, OBSOLESCENT (see 4)
2432        | declaration_specifier KR_function_declarator KR_declaration_list_opt with_clause_opt compound_statement
2433                {
2434                        rebindForall( $1, $2 );
2435                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2436                }
2437                // handles default int return type, OBSOLESCENT (see 1)
2438        | type_qualifier_list KR_function_declarator KR_declaration_list_opt with_clause_opt compound_statement
2439                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2440                // handles default int return type, OBSOLESCENT (see 1)
2441        | declaration_qualifier_list KR_function_declarator KR_declaration_list_opt with_clause_opt compound_statement
2442                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2443                // handles default int return type, OBSOLESCENT (see 1)
2444        | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_declaration_list_opt with_clause_opt compound_statement
2445                { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2446        ;
2447
2448declarator:
2449        variable_declarator
2450        | variable_type_redeclarator
2451        | function_declarator
2452        ;
2453
2454subrange:
2455        constant_expression '~' constant_expression                     // CFA, integer subrange
2456                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
2457        ;
2458
2459asm_name_opt:                                                                                   // GCC
2460        // empty
2461                { $$ = nullptr; }
2462        | ASM '(' string_literal ')' attribute_list_opt
2463                {
2464                        DeclarationNode * name = new DeclarationNode();
2465                        name->asmName = $3;
2466                        $$ = name->addQualifiers( $5 );
2467                }
2468        ;
2469
2470attribute_list_opt:                                                                             // GCC
2471        // empty
2472                { $$ = nullptr; }
2473        | attribute_list
2474        ;
2475
2476attribute_list:                                                                                 // GCC
2477        attribute
2478        | attribute_list attribute
2479                { $$ = $2->addQualifiers( $1 ); }
2480        ;
2481
2482attribute:                                                                                              // GCC
2483        ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2484                { $$ = $4; }
2485        ;
2486
2487attribute_name_list:                                                                    // GCC
2488        attribute_name
2489        | attribute_name_list ',' attribute_name
2490                { $$ = $3->addQualifiers( $1 ); }
2491        ;
2492
2493attribute_name:                                                                                 // GCC
2494        // empty
2495                { $$ = nullptr; }
2496        | attr_name
2497                { $$ = DeclarationNode::newAttribute( $1 ); }
2498        | attr_name '(' argument_expression_list ')'
2499                { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2500        ;
2501
2502attr_name:                                                                                              // GCC
2503        IDENTIFIER
2504        | quasi_keyword
2505        | TYPEDEFname
2506        | TYPEGENname
2507        | FALLTHROUGH
2508                { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2509        | CONST
2510                { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2511        ;
2512
2513// ============================================================================
2514// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2515// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2516// in:
2517//
2518//              int (*f())[10] { ... };
2519//              ... (*f())[3] += 1;             // definition mimics usage
2520//
2521// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2522// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2523// ============================================================================
2524
2525// ----------------------------------------------------------------------------
2526// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2527// to define a variable or function prototype, e.g.:
2528//
2529//              valid declaration               invalid definition
2530//              -----------------               ------------------
2531//              int f;                                  int f {}
2532//              int *f;                                 int *f {}
2533//              int f[10];                              int f[10] {}
2534//              int (*f)(int);                  int (*f)(int) {}
2535//
2536// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2537// variable_declarator and function_declarator.
2538// ----------------------------------------------------------------------------
2539
2540// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2541// declaring an array of functions versus a pointer to an array of functions.
2542
2543variable_declarator:
2544        paren_identifier attribute_list_opt
2545                { $$ = $1->addQualifiers( $2 ); }
2546        | variable_ptr
2547        | variable_array attribute_list_opt
2548                { $$ = $1->addQualifiers( $2 ); }
2549        | variable_function attribute_list_opt
2550                { $$ = $1->addQualifiers( $2 ); }
2551        ;
2552
2553paren_identifier:
2554        identifier
2555                { $$ = DeclarationNode::newName( $1 ); }
2556        | '(' paren_identifier ')'                                                      // redundant parenthesis
2557                { $$ = $2; }
2558        ;
2559
2560variable_ptr:
2561        ptrref_operator variable_declarator
2562                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2563        | ptrref_operator type_qualifier_list variable_declarator
2564                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2565        | '(' variable_ptr ')' attribute_list_opt
2566                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2567        ;
2568
2569variable_array:
2570        paren_identifier array_dimension
2571                { $$ = $1->addArray( $2 ); }
2572        | '(' variable_ptr ')' array_dimension
2573                { $$ = $2->addArray( $4 ); }
2574        | '(' variable_array ')' multi_array_dimension          // redundant parenthesis
2575                { $$ = $2->addArray( $4 ); }
2576        | '(' variable_array ')'                                                        // redundant parenthesis
2577                { $$ = $2; }
2578        ;
2579
2580variable_function:
2581        '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2582                { $$ = $2->addParamList( $6 ); }
2583        | '(' variable_function ')'                                                     // redundant parenthesis
2584                { $$ = $2; }
2585        ;
2586
2587// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2588// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2589// is the same scope.  The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2590
2591function_declarator:
2592        function_no_ptr attribute_list_opt
2593                { $$ = $1->addQualifiers( $2 ); }
2594        | function_ptr
2595        | function_array attribute_list_opt
2596                { $$ = $1->addQualifiers( $2 ); }
2597        ;
2598
2599function_no_ptr:
2600        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2601                { $$ = $1->addParamList( $4 ); }
2602        | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2603                { $$ = $2->addParamList( $6 ); }
2604        | '(' function_no_ptr ')'                                                       // redundant parenthesis
2605                { $$ = $2; }
2606        ;
2607
2608function_ptr:
2609        ptrref_operator function_declarator
2610                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2611        | ptrref_operator type_qualifier_list function_declarator
2612                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2613        | '(' function_ptr ')'
2614                { $$ = $2; }
2615        ;
2616
2617function_array:
2618        '(' function_ptr ')' array_dimension
2619                { $$ = $2->addArray( $4 ); }
2620        | '(' function_array ')' multi_array_dimension          // redundant parenthesis
2621                { $$ = $2->addArray( $4 ); }
2622        | '(' function_array ')'                                                        // redundant parenthesis
2623                { $$ = $2; }
2624        ;
2625
2626// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
2627//
2628//   f( a, b, c ) int a, *b, c[]; {}
2629//
2630// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
2631// returning arrays and functions versus pointers to arrays and functions.
2632
2633KR_function_declarator:
2634        KR_function_no_ptr
2635        | KR_function_ptr
2636        | KR_function_array
2637        ;
2638
2639KR_function_no_ptr:
2640        paren_identifier '(' identifier_list ')'                        // function_declarator handles empty parameter
2641                { $$ = $1->addIdList( $3 ); }
2642        | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
2643                { $$ = $2->addParamList( $6 ); }
2644        | '(' KR_function_no_ptr ')'                                            // redundant parenthesis
2645                { $$ = $2; }
2646        ;
2647
2648KR_function_ptr:
2649        ptrref_operator KR_function_declarator
2650                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2651        | ptrref_operator type_qualifier_list KR_function_declarator
2652                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2653        | '(' KR_function_ptr ')'
2654                { $$ = $2; }
2655        ;
2656
2657KR_function_array:
2658        '(' KR_function_ptr ')' array_dimension
2659                { $$ = $2->addArray( $4 ); }
2660        | '(' KR_function_array ')' multi_array_dimension       // redundant parenthesis
2661                { $$ = $2->addArray( $4 ); }
2662        | '(' KR_function_array ')'                                                     // redundant parenthesis
2663                { $$ = $2; }
2664        ;
2665
2666// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2667//
2668//              typedef int foo;
2669//              {
2670//                 int foo; // redefine typedef name in new scope
2671//              }
2672//
2673// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2674// and functions versus pointers to arrays and functions.
2675
2676variable_type_redeclarator:
2677        paren_type attribute_list_opt
2678                { $$ = $1->addQualifiers( $2 ); }
2679        | type_ptr
2680        | type_array attribute_list_opt
2681                { $$ = $1->addQualifiers( $2 ); }
2682        | type_function attribute_list_opt
2683                { $$ = $1->addQualifiers( $2 ); }
2684        ;
2685
2686paren_type:
2687        typedef
2688                // hide type name in enclosing scope by variable name
2689                { typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER ); }
2690        | '(' paren_type ')'
2691                { $$ = $2; }
2692        ;
2693
2694type_ptr:
2695        ptrref_operator variable_type_redeclarator
2696                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2697        | ptrref_operator type_qualifier_list variable_type_redeclarator
2698                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2699        | '(' type_ptr ')' attribute_list_opt
2700                { $$ = $2->addQualifiers( $4 ); }
2701        ;
2702
2703type_array:
2704        paren_type array_dimension
2705                { $$ = $1->addArray( $2 ); }
2706        | '(' type_ptr ')' array_dimension
2707                { $$ = $2->addArray( $4 ); }
2708        | '(' type_array ')' multi_array_dimension                      // redundant parenthesis
2709                { $$ = $2->addArray( $4 ); }
2710        | '(' type_array ')'                                                            // redundant parenthesis
2711                { $$ = $2; }
2712        ;
2713
2714type_function:
2715        paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2716                { $$ = $1->addParamList( $4 ); }
2717        | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2718                { $$ = $2->addParamList( $6 ); }
2719        | '(' type_function ')'                                                         // redundant parenthesis
2720                { $$ = $2; }
2721        ;
2722
2723// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
2724// typedef name and allows the C99 array options, which can only appear in a parameter list.  The pattern precludes
2725// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
2726// pointers to arrays and functions.
2727
2728identifier_parameter_declarator:
2729        paren_identifier attribute_list_opt
2730                { $$ = $1->addQualifiers( $2 ); }
2731        | '&' MUTEX paren_identifier attribute_list_opt
2732                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
2733        | identifier_parameter_ptr
2734        | identifier_parameter_array attribute_list_opt
2735                { $$ = $1->addQualifiers( $2 ); }
2736        | identifier_parameter_function attribute_list_opt
2737                { $$ = $1->addQualifiers( $2 ); }
2738        ;
2739
2740identifier_parameter_ptr:
2741        ptrref_operator identifier_parameter_declarator
2742                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2743        | ptrref_operator type_qualifier_list identifier_parameter_declarator
2744                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2745        | '(' identifier_parameter_ptr ')' attribute_list_opt
2746                { $$ = $2->addQualifiers( $4 ); }
2747        ;
2748
2749identifier_parameter_array:
2750        paren_identifier array_parameter_dimension
2751                { $$ = $1->addArray( $2 ); }
2752        | '(' identifier_parameter_ptr ')' array_dimension
2753                { $$ = $2->addArray( $4 ); }
2754        | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
2755                { $$ = $2->addArray( $4 ); }
2756        | '(' identifier_parameter_array ')'                            // redundant parenthesis
2757                { $$ = $2; }
2758        ;
2759
2760identifier_parameter_function:
2761        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2762                { $$ = $1->addParamList( $4 ); }
2763        | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2764                { $$ = $2->addParamList( $6 ); }
2765        | '(' identifier_parameter_function ')'                         // redundant parenthesis
2766                { $$ = $2; }
2767        ;
2768
2769// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
2770// e.g.:
2771//
2772//              typedef int foo;
2773//              forall( otype T ) struct foo;
2774//              int f( int foo ); // redefine typedef name in new scope
2775//
2776// and allows the C99 array options, which can only appear in a parameter list.
2777
2778type_parameter_redeclarator:
2779        typedef attribute_list_opt
2780                { $$ = $1->addQualifiers( $2 ); }
2781        | '&' MUTEX typedef attribute_list_opt
2782                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
2783        | type_parameter_ptr
2784        | type_parameter_array attribute_list_opt
2785                { $$ = $1->addQualifiers( $2 ); }
2786        | type_parameter_function attribute_list_opt
2787                { $$ = $1->addQualifiers( $2 ); }
2788        ;
2789
2790typedef:
2791        TYPEDEFname
2792                { $$ = DeclarationNode::newName( $1 ); }
2793        | TYPEGENname
2794                { $$ = DeclarationNode::newName( $1 ); }
2795        ;
2796
2797type_parameter_ptr:
2798        ptrref_operator type_parameter_redeclarator
2799                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2800        | ptrref_operator type_qualifier_list type_parameter_redeclarator
2801                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2802        | '(' type_parameter_ptr ')' attribute_list_opt
2803                { $$ = $2->addQualifiers( $4 ); }
2804        ;
2805
2806type_parameter_array:
2807        typedef array_parameter_dimension
2808                { $$ = $1->addArray( $2 ); }
2809        | '(' type_parameter_ptr ')' array_parameter_dimension
2810                { $$ = $2->addArray( $4 ); }
2811        ;
2812
2813type_parameter_function:
2814        typedef '(' push parameter_type_list_opt pop ')'        // empty parameter list OBSOLESCENT (see 3)
2815                { $$ = $1->addParamList( $4 ); }
2816        | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2817                { $$ = $2->addParamList( $6 ); }
2818        ;
2819
2820// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
2821// which the type applies, e.g.:
2822//
2823//              sizeof( int );
2824//              sizeof( int * );
2825//              sizeof( int [10] );
2826//              sizeof( int (*)() );
2827//              sizeof( int () );
2828//
2829// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2830// and functions versus pointers to arrays and functions.
2831
2832abstract_declarator:
2833        abstract_ptr
2834        | abstract_array attribute_list_opt
2835                { $$ = $1->addQualifiers( $2 ); }
2836        | abstract_function attribute_list_opt
2837                { $$ = $1->addQualifiers( $2 ); }
2838        ;
2839
2840abstract_ptr:
2841        ptrref_operator
2842                { $$ = DeclarationNode::newPointer( 0, $1 ); }
2843        | ptrref_operator type_qualifier_list
2844                { $$ = DeclarationNode::newPointer( $2, $1 ); }
2845        | ptrref_operator abstract_declarator
2846                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2847        | ptrref_operator type_qualifier_list abstract_declarator
2848                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2849        | '(' abstract_ptr ')' attribute_list_opt
2850                { $$ = $2->addQualifiers( $4 ); }
2851        ;
2852
2853abstract_array:
2854        array_dimension
2855        | '(' abstract_ptr ')' array_dimension
2856                { $$ = $2->addArray( $4 ); }
2857        | '(' abstract_array ')' multi_array_dimension          // redundant parenthesis
2858                { $$ = $2->addArray( $4 ); }
2859        | '(' abstract_array ')'                                                        // redundant parenthesis
2860                { $$ = $2; }
2861        ;
2862
2863abstract_function:
2864        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
2865                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
2866        | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2867                { $$ = $2->addParamList( $6 ); }
2868        | '(' abstract_function ')'                                                     // redundant parenthesis
2869                { $$ = $2; }
2870        ;
2871
2872array_dimension:
2873                // Only the first dimension can be empty.
2874        '[' ']'
2875                { $$ = DeclarationNode::newArray( 0, 0, false ); }
2876        | '[' ']' multi_array_dimension
2877                { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
2878        | multi_array_dimension
2879        ;
2880
2881multi_array_dimension:
2882        '[' push assignment_expression pop ']'
2883                { $$ = DeclarationNode::newArray( $3, 0, false ); }
2884        | '[' push '*' pop ']'                                                          // C99
2885                { $$ = DeclarationNode::newVarArray( 0 ); }
2886        | multi_array_dimension '[' push assignment_expression pop ']'
2887                { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
2888        | multi_array_dimension '[' push '*' pop ']'            // C99
2889                { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
2890        ;
2891
2892// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
2893// identifier to which the type applies, e.g.:
2894//
2895//              int f( int );                   // not handled here
2896//              int f( int * );                 // abstract function-prototype parameter; no parameter name specified
2897//              int f( int (*)() );             // abstract function-prototype parameter; no parameter name specified
2898//              int f( int (int) );             // abstract function-prototype parameter; no parameter name specified
2899//
2900// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2901// and functions versus pointers to arrays and functions. In addition, the pattern handles the
2902// special meaning of parenthesis around a typedef name:
2903//
2904//              ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
2905//              parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
2906//              not as redundant parentheses around the identifier."
2907//
2908// For example:
2909//
2910//              typedef float T;
2911//              int f( int ( T [5] ) );                                 // see abstract_parameter_declarator
2912//              int g( int ( T ( int ) ) );                             // see abstract_parameter_declarator
2913//              int f( int f1( T a[5] ) );                              // see identifier_parameter_declarator
2914//              int g( int g1( T g2( int p ) ) );               // see identifier_parameter_declarator
2915//
2916// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
2917// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
2918// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
2919// functions.
2920
2921abstract_parameter_declarator:
2922        abstract_parameter_ptr
2923        | '&' MUTEX attribute_list_opt
2924                { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
2925        | abstract_parameter_array attribute_list_opt
2926                { $$ = $1->addQualifiers( $2 ); }
2927        | abstract_parameter_function attribute_list_opt
2928                { $$ = $1->addQualifiers( $2 ); }
2929        ;
2930
2931abstract_parameter_ptr:
2932        ptrref_operator
2933                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
2934        | ptrref_operator type_qualifier_list
2935                { $$ = DeclarationNode::newPointer( $2, $1 ); }
2936        | ptrref_operator abstract_parameter_declarator
2937                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
2938        | ptrref_operator type_qualifier_list abstract_parameter_declarator
2939                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2940        | '(' abstract_parameter_ptr ')' attribute_list_opt
2941                { $$ = $2->addQualifiers( $4 ); }
2942        ;
2943
2944abstract_parameter_array:
2945        array_parameter_dimension
2946        | '(' abstract_parameter_ptr ')' array_parameter_dimension
2947                { $$ = $2->addArray( $4 ); }
2948        | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
2949                { $$ = $2->addArray( $4 ); }
2950        | '(' abstract_parameter_array ')'                                      // redundant parenthesis
2951                { $$ = $2; }
2952        ;
2953
2954abstract_parameter_function:
2955        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
2956                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
2957        | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2958                { $$ = $2->addParamList( $6 ); }
2959        | '(' abstract_parameter_function ')'                           // redundant parenthesis
2960                { $$ = $2; }
2961        ;
2962
2963array_parameter_dimension:
2964                // Only the first dimension can be empty or have qualifiers.
2965        array_parameter_1st_dimension
2966        | array_parameter_1st_dimension multi_array_dimension
2967                { $$ = $1->addArray( $2 ); }
2968        | multi_array_dimension
2969        ;
2970
2971// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
2972//
2973//              ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
2974//              a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
2975
2976array_parameter_1st_dimension:
2977        '[' ']'
2978                { $$ = DeclarationNode::newArray( 0, 0, false ); }
2979        // multi_array_dimension handles the '[' '*' ']' case
2980        | '[' push type_qualifier_list '*' pop ']'                      // remaining C99
2981                { $$ = DeclarationNode::newVarArray( $3 ); }
2982        | '[' push type_qualifier_list pop ']'
2983                { $$ = DeclarationNode::newArray( 0, $3, false ); }
2984        // multi_array_dimension handles the '[' assignment_expression ']' case
2985        | '[' push type_qualifier_list assignment_expression pop ']'
2986                { $$ = DeclarationNode::newArray( $4, $3, false ); }
2987        | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
2988                { $$ = DeclarationNode::newArray( $5, $4, true ); }
2989        | '[' push type_qualifier_list STATIC assignment_expression pop ']'
2990                { $$ = DeclarationNode::newArray( $5, $3, true ); }
2991        ;
2992
2993// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
2994//
2995//              struct S {
2996//          int;
2997//          int *;
2998//          int [10];
2999//          int (*)();
3000//      };
3001
3002variable_abstract_declarator:
3003        variable_abstract_ptr
3004        | variable_abstract_array attribute_list_opt
3005                { $$ = $1->addQualifiers( $2 ); }
3006        | variable_abstract_function attribute_list_opt
3007                { $$ = $1->addQualifiers( $2 ); }
3008        ;
3009
3010variable_abstract_ptr:
3011        ptrref_operator
3012                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3013        | ptrref_operator type_qualifier_list
3014                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3015        | ptrref_operator variable_abstract_declarator
3016                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3017        | ptrref_operator type_qualifier_list variable_abstract_declarator
3018                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3019        | '(' variable_abstract_ptr ')' attribute_list_opt
3020                { $$ = $2->addQualifiers( $4 ); }
3021        ;
3022
3023variable_abstract_array:
3024        array_dimension
3025        | '(' variable_abstract_ptr ')' array_dimension
3026                { $$ = $2->addArray( $4 ); }
3027        | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3028                { $$ = $2->addArray( $4 ); }
3029        | '(' variable_abstract_array ')'                                       // redundant parenthesis
3030                { $$ = $2; }
3031        ;
3032
3033variable_abstract_function:
3034        '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3035                { $$ = $2->addParamList( $6 ); }
3036        | '(' variable_abstract_function ')'                            // redundant parenthesis
3037                { $$ = $2; }
3038        ;
3039
3040// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3041// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3042
3043cfa_identifier_parameter_declarator_tuple:                              // CFA
3044        cfa_identifier_parameter_declarator_no_tuple
3045        | cfa_abstract_tuple
3046        | type_qualifier_list cfa_abstract_tuple
3047                { $$ = $2->addQualifiers( $1 ); }
3048        ;
3049
3050cfa_identifier_parameter_declarator_no_tuple:                   // CFA
3051        cfa_identifier_parameter_ptr
3052        | cfa_identifier_parameter_array
3053        ;
3054
3055cfa_identifier_parameter_ptr:                                                   // CFA
3056                // No SUE declaration in parameter list.
3057        ptrref_operator type_specifier_nobody
3058                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3059        | type_qualifier_list ptrref_operator type_specifier_nobody
3060                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3061        | ptrref_operator cfa_abstract_function
3062                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3063        | type_qualifier_list ptrref_operator cfa_abstract_function
3064                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3065        | ptrref_operator cfa_identifier_parameter_declarator_tuple
3066                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3067        | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3068                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3069        ;
3070
3071cfa_identifier_parameter_array:                                                 // CFA
3072                // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3073                // shift/reduce conflict with new-style empty (void) function return type.
3074        '[' ']' type_specifier_nobody
3075                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3076        | cfa_array_parameter_1st_dimension type_specifier_nobody
3077                { $$ = $2->addNewArray( $1 ); }
3078        | '[' ']' multi_array_dimension type_specifier_nobody
3079                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3080        | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3081                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3082        | multi_array_dimension type_specifier_nobody
3083                { $$ = $2->addNewArray( $1 ); }
3084
3085        | '[' ']' cfa_identifier_parameter_ptr
3086                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3087        | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3088                { $$ = $2->addNewArray( $1 ); }
3089        | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3090                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3091        | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3092                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3093        | multi_array_dimension cfa_identifier_parameter_ptr
3094                { $$ = $2->addNewArray( $1 ); }
3095        ;
3096
3097cfa_array_parameter_1st_dimension:
3098        '[' push type_qualifier_list '*' pop ']'                        // remaining C99
3099                { $$ = DeclarationNode::newVarArray( $3 ); }
3100        | '[' push type_qualifier_list assignment_expression pop ']'
3101                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3102        | '[' push declaration_qualifier_list assignment_expression pop ']'
3103                // declaration_qualifier_list must be used because of shift/reduce conflict with
3104                // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3105                // appear in this context.
3106                { $$ = DeclarationNode::newArray( $4, $3, true ); }
3107        | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3108                { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3109        ;
3110
3111// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3112// identifier to which the type applies, e.g.:
3113//
3114//              [int] f( int );                         // abstract variable parameter; no parameter name specified
3115//              [int] f( [int] (int) );         // abstract function-prototype parameter; no parameter name specified
3116//
3117// These rules need LR(3):
3118//
3119//              cfa_abstract_tuple identifier_or_type_name
3120//              '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_type_list_opt ')'
3121//
3122// since a function return type can be syntactically identical to a tuple type:
3123//
3124//              [int, int] t;
3125//              [int, int] f( int );
3126//
3127// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3128// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3129// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3130// duplicated when appearing with cfa_function_specifier.
3131
3132cfa_abstract_declarator_tuple:                                                  // CFA
3133        cfa_abstract_tuple
3134        | type_qualifier_list cfa_abstract_tuple
3135                { $$ = $2->addQualifiers( $1 ); }
3136        | cfa_abstract_declarator_no_tuple
3137        ;
3138
3139cfa_abstract_declarator_no_tuple:                                               // CFA
3140        cfa_abstract_ptr
3141        | cfa_abstract_array
3142        ;
3143
3144cfa_abstract_ptr:                                                                               // CFA
3145        ptrref_operator type_specifier
3146                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3147        | type_qualifier_list ptrref_operator type_specifier
3148                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3149        | ptrref_operator cfa_abstract_function
3150                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3151        | type_qualifier_list ptrref_operator cfa_abstract_function
3152                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3153        | ptrref_operator cfa_abstract_declarator_tuple
3154                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3155        | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3156                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3157        ;
3158
3159cfa_abstract_array:                                                                             // CFA
3160                // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3161                // empty (void) function return type.
3162        '[' ']' type_specifier
3163                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3164        | '[' ']' multi_array_dimension type_specifier
3165                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3166        | multi_array_dimension type_specifier
3167                { $$ = $2->addNewArray( $1 ); }
3168        | '[' ']' cfa_abstract_ptr
3169                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3170        | '[' ']' multi_array_dimension cfa_abstract_ptr
3171                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3172        | multi_array_dimension cfa_abstract_ptr
3173                { $$ = $2->addNewArray( $1 ); }
3174        ;
3175
3176cfa_abstract_tuple:                                                                             // CFA
3177        '[' push cfa_abstract_parameter_list pop ']'
3178                { $$ = DeclarationNode::newTuple( $3 ); }
3179        ;
3180
3181cfa_abstract_function:                                                                  // CFA
3182//      '[' ']' '(' cfa_parameter_type_list_opt ')'
3183//              { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3184        cfa_abstract_tuple '(' push cfa_parameter_type_list_opt pop ')'
3185                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3186        | cfa_function_return '(' push cfa_parameter_type_list_opt pop ')'
3187                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3188        ;
3189
3190// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3191//    each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3192//
3193// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3194//    the declaration specifiers in a declaration is an obsolescent feature."
3195//
3196// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3197//    prototype-format parameter type declarators) is an obsolescent feature."
3198//
3199// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3200//    declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3201
3202//************************* MISCELLANEOUS ********************************
3203
3204comma_opt:                                                                                              // redundant comma
3205        // empty
3206        | ','
3207        ;
3208
3209default_initialize_opt:
3210        // empty
3211                { $$ = nullptr; }
3212        | '=' assignment_expression
3213                { $$ = $2; }
3214        ;
3215
3216%%
3217// ----end of grammar----
3218
3219// Local Variables: //
3220// mode: c++ //
3221// tab-width: 4 //
3222// compile-command: "make install" //
3223// End: //
Note: See TracBrowser for help on using the repository browser.