source: src/Parser/parser.yy@ bc48c0d

Last change on this file since bc48c0d was 4117761, checked in by JiadaL <j82liang@…>, 15 months ago

Merge branch 'master' of plg.uwaterloo.ca:software/cfa/cfa-cc
  • Property mode set to 100644
File size: 177.8 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author : Peter A. Buhr
10// Created On : Sat Sep 1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Thu Jun 27 14:45:57 2024
13// Update Count : 6705
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS. While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks. Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// designation with '=' (use ':' instead)
29//
30// This incompatibility is discussed in detail before the "designation" grammar rule. Most of the syntactic extensions
31// from ANSI90 to ANSI11 C are marked with the comment "C99/C11".
32
33// This grammar also has two levels of extensions. The first extensions cover most of the GCC C extensions. All of the
34// syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall (CFA), which
35// fixes several of C's outstanding problems and extends C with many modern language concepts. All of the syntactic
36// extensions for CFA C are marked with the comment "CFA".
37
38%{
39#define YYDEBUG_LEXER_TEXT( yylval ) // lexer loads this up each time
40#define YYDEBUG 1 // get the pretty debugging code to compile
41#define YYERROR_VERBOSE // more information in syntax errors
42
43#undef __GNUC_MINOR__
44
45#include <cstdio>
46#include <sstream>
47#include <stack>
48using namespace std;
49
50#include "DeclarationNode.hpp" // for DeclarationNode, ...
51#include "ExpressionNode.hpp" // for ExpressionNode, ...
52#include "InitializerNode.hpp" // for InitializerNode, ...
53#include "ParserTypes.hpp"
54#include "StatementNode.hpp" // for build_...
55#include "TypedefTable.hpp"
56#include "TypeData.hpp"
57#include "AST/Type.hpp" // for BasicType, BasicKind
58#include "Common/SemanticError.hpp" // error_str
59#include "Common/Utility.hpp" // for maybeMoveBuild, maybeBuild, CodeLo...
60
61// lex uses __null in a boolean context, it's fine.
62#ifdef __clang__
63#pragma GCC diagnostic ignored "-Wparentheses-equality"
64#endif
65
66extern DeclarationNode * parseTree;
67extern ast::Linkage::Spec linkage;
68extern TypedefTable typedefTable;
69
70stack<ast::Linkage::Spec> linkageStack;
71
72bool appendStr( string & to, string & from ) {
73 // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
74 // "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
75 // the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
76 // easier to let the C compiler handle this case.
77 //
78 // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
79 // without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
80 // e.g., u"a" U"b" L"c" is disallowed.
81
82 if ( from[0] != '"' ) { // encoding ?
83 if ( to[0] != '"' ) { // encoding ?
84 if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
85 yyerror( "non-matching string encodings for string-literal concatenation" );
86 return false; // parse error, must call YYERROR in action
87 } else if ( from[1] == '8' ) {
88 from.erase( 0, 1 ); // remove 2nd encoding
89 } // if
90 } else {
91 if ( from[1] == '8' ) { // move encoding to start
92 to = "u8" + to;
93 from.erase( 0, 1 ); // remove 2nd encoding
94 } else {
95 to = from[0] + to;
96 } // if
97 } // if
98 from.erase( 0, 1 ); // remove 2nd encoding
99 } // if
100 to += " " + from; // concatenated into single string
101 return true;
102} // appendStr
103
104DeclarationNode * distAttr( DeclarationNode * typeSpec, DeclarationNode * declList ) {
105 // Distribute type specifier across all declared variables, e.g., static, const, __attribute__.
106 assert( declList );
107
108 // Do not distribute attributes for aggregates because the attributes surrounding the aggregate belong it not the
109 // variables in the declaration list, e.g.,
110 //
111 // struct __attribute__(( aligned(128) )) S { ...
112 // } v1 __attribute__(( aligned(64) )), v2 __attribute__(( aligned(32) )), v3;
113 // struct S v4;
114 //
115 // v1 => 64, v2 =>32, v3 => 128, v2 => 128
116 //
117 // Anonymous aggregates are a special case because there is no aggregate to bind the attribute to; hence it floats
118 // to the declaration list.
119 //
120 // struct __attribute__(( aligned(128) )) /*anonymous */ { ... } v1;
121 //
122 // v1 => 128
123
124 bool copyattr = ! (typeSpec->type && typeSpec->type->kind == TypeData::Aggregate && ! typeSpec->type->aggregate.anon );
125
126 // addType copies the type information for the aggregate instances from typeSpec into cl's aggInst.aggregate.
127 DeclarationNode * cl = (new DeclarationNode)->addType( typeSpec ); // typeSpec IS DELETED!!!
128
129 // Start at second variable in declaration list and clone the type specifiers for each variable.
130 for ( DeclarationNode * cur = declList->next ; cur != nullptr; cur = cur->next ) {
131 cl->cloneBaseType( cur, copyattr ); // cur is modified
132 } // for
133
134 // Add first variable in declaration list with hidden type information in aggInst.aggregate, which is used by
135 // extractType to recover the type for the aggregate instances.
136 declList->addType( cl, copyattr ); // cl IS DELETED!!!
137 return declList;
138} // distAttr
139
140void distExt( DeclarationNode * declaration ) {
141 // distribute EXTENSION across all declarations
142 for ( DeclarationNode *iter = declaration ; iter != nullptr ; iter = iter->next ) {
143 iter->set_extension( true );
144 } // for
145} // distExt
146
147void distInl( DeclarationNode * declaration ) {
148 // distribute INLINE across all declarations
149 for ( DeclarationNode *iter = declaration ; iter != nullptr ; iter = iter->next ) {
150 iter->set_inLine( true );
151 } // for
152} // distInl
153
154void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
155 // distribute qualifiers across all non-variable declarations in a distribution statemement
156 for ( DeclarationNode * iter = declaration ; iter != nullptr ; iter = iter->next ) {
157 // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
158 // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
159 // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
160 // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
161 DeclarationNode * clone = qualifiers->clone();
162 if ( qualifiers->type ) { // forall clause ? (handles SC)
163 if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
164 swap( clone->type->forall, iter->type->aggregate.params );
165 iter->addQualifiers( clone );
166 } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
167 // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
168 DeclarationNode newnode;
169 swap( newnode.type, iter->type->aggInst.aggregate );
170 swap( clone->type->forall, newnode.type->aggregate.params );
171 newnode.addQualifiers( clone );
172 swap( newnode.type, iter->type->aggInst.aggregate );
173 } else if ( iter->type->kind == TypeData::Function ) { // routines ?
174 swap( clone->type->forall, iter->type->forall );
175 iter->addQualifiers( clone );
176 } // if
177 } else { // just SC qualifiers
178 iter->addQualifiers( clone );
179 } // if
180 } // for
181 delete qualifiers;
182} // distQual
183
184// There is an ambiguity for inline generic-routine return-types and generic routines.
185// forall( otype T ) struct S { int i; } bar( T ) {}
186// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
187// forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
188// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
189// forall( otype T ) struct S { int T; };
190// forall( otype W ) bar( W ) {}
191
192void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
193 if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
194 funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
195 declSpec->type->aggregate.params = nullptr;
196 } // if
197} // rebindForall
198
199string * build_postfix_name( string * name ) {
200 *name = string("__postfix_func_") + *name;
201 return name;
202} // build_postfix_name
203
204DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
205 if ( nullptr == fieldList ) {
206 if ( !( typeSpec->type && typeSpec->type->kind == TypeData::Aggregate ) ) {
207 stringstream ss;
208 // printf( "fieldDecl1 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
209 SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
210 return nullptr;
211 } // if
212 // printf( "fieldDecl2 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
213 fieldList = DeclarationNode::newName( nullptr );
214 } // if
215
216 // printf( "fieldDecl3 typeSpec %p\n", typeSpec ); typeSpec->print( std::cout, 0 );
217 DeclarationNode * temp = distAttr( typeSpec, fieldList ); // mark all fields in list
218 // printf( "fieldDecl4 temp %p\n", temp ); temp->print( std::cout, 0 );
219 return temp;
220} // fieldDecl
221
222#define NEW_ZERO new ExpressionNode( build_constantInteger( yylloc, *new string( "0" ) ) )
223#define NEW_ONE new ExpressionNode( build_constantInteger( yylloc, *new string( "1" ) ) )
224#define UPDOWN( compop, left, right ) (compop == OperKinds::LThan || compop == OperKinds::LEThan ? left : right)
225#define MISSING_ANON_FIELD "illegal syntax, missing loop fields with an anonymous loop index is meaningless as loop index is unavailable in loop body."
226#define MISSING_LOW "illegal syntax, missing low value for ascanding range so index is uninitialized."
227#define MISSING_HIGH "illegal syntax, missing high value for descending range so index is uninitialized."
228
229static ForCtrl * makeForCtrl( const CodeLocation & location, DeclarationNode * init, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
230 // Wrap both comp/inc if they are non-null.
231 if ( comp ) comp = new ExpressionNode( build_binary_val( location,
232 compop,
233 new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
234 comp ) );
235 if ( inc ) inc = new ExpressionNode( build_binary_val( location,
236 // choose += or -= for upto/downto
237 compop == OperKinds::LThan || compop == OperKinds::LEThan ? OperKinds::PlusAssn : OperKinds::MinusAssn,
238 new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
239 inc ) );
240 // The StatementNode call frees init->name, it must happen later.
241 return new ForCtrl( new StatementNode( init ), comp, inc );
242}
243
244ForCtrl * forCtrl( const CodeLocation & location, DeclarationNode * index, ExpressionNode * start, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
245 if ( index->initializer ) {
246 SemanticError( yylloc, "illegal syntax, direct initialization disallowed. Use instead: type var; initialization ~ comparison ~ increment." );
247 } // if
248 if ( index->next ) {
249 SemanticError( yylloc, "illegal syntax, multiple loop indexes disallowed in for-loop declaration." );
250 } // if
251 DeclarationNode * initDecl = index->addInitializer( new InitializerNode( start ) );
252 return makeForCtrl( location, initDecl, compop, comp, inc );
253} // forCtrl
254
255ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, string * index, ExpressionNode * start, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
256 ast::ConstantExpr * constant = dynamic_cast<ast::ConstantExpr *>(type->expr.get());
257 if ( constant && (constant->rep == "0" || constant->rep == "1") ) {
258 type = new ExpressionNode( new ast::CastExpr( location, maybeMoveBuild(type), new ast::BasicType( ast::BasicKind::SignedInt ) ) );
259 } // if
260 DeclarationNode * initDecl = distAttr(
261 DeclarationNode::newTypeof( type, true ),
262 DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) )
263 );
264 return makeForCtrl( location, initDecl, compop, comp, inc );
265} // forCtrl
266
267#define MISSING_LOOP_INDEX "illegal syntax, only a single identifier or declaration allowed in initialization, e.g., for ( i; ... ) or for ( int i; ... ). Expression disallowed."
268
269ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
270 if ( auto identifier = dynamic_cast<ast::NameExpr *>(index->expr.get()) ) {
271 return forCtrl( location, type, new string( identifier->name ), start, compop, comp, inc );
272 } else {
273 SemanticError( yylloc, MISSING_LOOP_INDEX ); return nullptr;
274 } // if
275} // forCtrl
276
277ForCtrl * enumRangeCtrl( ExpressionNode * index_expr, __attribute__((unused)) OperKinds compop, ExpressionNode * range_over_expr ) {
278 if ( auto identifier = dynamic_cast<ast::NameExpr *>(index_expr->expr.get()) ) {
279 DeclarationNode * indexDecl = DeclarationNode::newName( new std::string(identifier->name) );
280 assert( range_over_expr );
281 return new ForCtrl( new StatementNode( indexDecl ), range_over_expr, compop );
282 } else {
283 SemanticError( yylloc, MISSING_LOOP_INDEX ); return nullptr;
284 } // if
285} // enumRangeCtrl
286
287static void IdentifierBeforeIdentifier( string & identifier1, string & identifier2, const char * kind ) {
288 SemanticError( yylloc, "illegal syntax, adjacent identifiers \"%s\" and \"%s\" are not meaningful in an %s.\n"
289 "Possible cause is misspelled type name or missing generic parameter.",
290 identifier1.c_str(), identifier2.c_str(), kind );
291} // IdentifierBeforeIdentifier
292
293static void IdentifierBeforeType( string & identifier, const char * kind ) {
294 SemanticError( yylloc, "illegal syntax, identifier \"%s\" cannot appear before a %s.\n"
295 "Possible cause is misspelled storage/CV qualifier, misspelled typename, or missing generic parameter.",
296 identifier.c_str(), kind );
297} // IdentifierBeforeType
298
299bool forall = false; // aggregate have one or more forall qualifiers ?
300
301// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
302#define YYLLOC_DEFAULT(Cur, Rhs, N) \
303if ( N ) { \
304 (Cur).first_line = YYRHSLOC( Rhs, 1 ).first_line; \
305 (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column; \
306 (Cur).last_line = YYRHSLOC( Rhs, N ).last_line; \
307 (Cur).last_column = YYRHSLOC( Rhs, N ).last_column; \
308 (Cur).filename = YYRHSLOC( Rhs, 1 ).filename; \
309} else { \
310 (Cur).first_line = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line; \
311 (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column; \
312 (Cur).filename = YYRHSLOC( Rhs, 0 ).filename; \
313}
314%}
315
316%define parse.error verbose
317
318// Types declaration for productions
319
320%union {
321 // A raw token can be used.
322 Token tok;
323
324 // The general node types hold some generic node or list of nodes.
325 DeclarationNode * decl;
326 InitializerNode * init;
327 ExpressionNode * expr;
328 StatementNode * stmt;
329 ClauseNode * clause;
330 TypeData * type;
331
332 // Special "nodes" containing compound information.
333 CondCtl * ifctl;
334 ForCtrl * forctl;
335 LabelNode * labels;
336
337 // Various flags and single values that become fields later.
338 ast::AggregateDecl::Aggregate aggKey;
339 ast::TypeDecl::Kind tclass;
340 OperKinds oper;
341 bool is_volatile;
342 EnumHiding enum_hiding;
343 ast::ExceptionKind except_kind;
344 // String passes ownership with it.
345 std::string * str;
346
347 // Narrower node types are used to avoid constant unwrapping.
348 ast::WaitForStmt * wfs;
349 ast::WaitUntilStmt::ClauseNode * wucn;
350 ast::GenericExpr * genexpr;
351}
352
353// ************************ TERMINAL TOKENS ********************************
354
355// keywords
356%token TYPEDEF
357%token EXTERN STATIC AUTO REGISTER
358%token THREADLOCALGCC THREADLOCALC11 // GCC, C11
359%token INLINE FORTRAN // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
360%token NORETURN // C11
361%token CONST VOLATILE
362%token RESTRICT // C99
363%token ATOMIC // C11
364%token FORALL MUTEX VIRTUAL VTABLE COERCE // CFA
365%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
366%token BOOL COMPLEX IMAGINARY // C99
367%token INT128 UINT128 uuFLOAT80 uuFLOAT128 // GCC
368%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
369%token DECIMAL32 DECIMAL64 DECIMAL128 // GCC
370%token ZERO_T ONE_T // CFA
371%token SIZEOF TYPEOF VA_LIST VA_ARG AUTO_TYPE COUNTOF // GCC
372%token OFFSETOF BASETYPEOF TYPEID // CFA
373%token ENUM STRUCT UNION
374%token EXCEPTION // CFA
375%token GENERATOR COROUTINE MONITOR THREAD // CFA
376%token OTYPE FTYPE DTYPE TTYPE TRAIT // CFA
377// %token RESUME // CFA
378%token LABEL // GCC
379%token SUSPEND // CFA
380%token ATTRIBUTE EXTENSION // GCC
381%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
382%token CHOOSE FALLTHRU FALLTHROUGH WITH WHEN WAITFOR WAITUNTIL // CFA
383%token CORUN COFOR
384%token DISABLE ENABLE TRY THROW THROWRESUME AT // CFA
385%token ASM // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
386%token ALIGNAS ALIGNOF GENERIC STATICASSERT // C11
387
388// names and constants: lexer differentiates between identifier and typedef names
389%token<tok> IDENTIFIER TYPEDIMname TYPEDEFname TYPEGENname
390%token<tok> TIMEOUT WAND WOR CATCH RECOVER CATCHRESUME FIXUP FINALLY // CFA
391%token<tok> INTEGERconstant CHARACTERconstant STRINGliteral
392%token<tok> DIRECTIVE
393// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
394// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
395// converted into the tuple index (.)(1). e.g., 3.x
396%token<tok> FLOATING_DECIMALconstant FLOATING_FRACTIONconstant FLOATINGconstant
397
398// multi-character operators
399%token ARROW // ->
400%token ICR DECR // ++ --
401%token LS RS // << >>
402%token LE GE EQ NE // <= >= == !=
403%token ANDAND OROR // && ||
404%token ATTR ELLIPSIS // @@ ...
405
406%token EXPassign MULTassign DIVassign MODassign // \= *= /= %=
407%token PLUSassign MINUSassign // += -=
408%token LSassign RSassign // <<= >>=
409%token ANDassign ERassign ORassign // &= ^= |=
410
411%token ErangeUp ErangeUpEq ErangeDown ErangeDownEq // +~ +~=/~= -~ -~=
412%token ATassign // @=
413
414%type<tok> identifier identifier_at identifier_or_type_name attr_name
415%type<tok> quasi_keyword
416%type<expr> string_literal
417%type<str> string_literal_list
418
419%type<enum_hiding> hide_opt visible_hide_opt
420
421// expressions
422%type<expr> constant
423%type<expr> tuple tuple_expression_list
424%type<oper> ptrref_operator unary_operator assignment_operator simple_assignment_operator compound_assignment_operator
425%type<expr> primary_expression postfix_expression unary_expression
426%type<expr> cast_expression_list cast_expression exponential_expression multiplicative_expression additive_expression
427%type<expr> shift_expression relational_expression equality_expression
428%type<expr> AND_expression exclusive_OR_expression inclusive_OR_expression
429%type<expr> logical_AND_expression logical_OR_expression
430%type<expr> conditional_expression constant_expression assignment_expression assignment_expression_opt
431%type<expr> comma_expression comma_expression_opt
432%type<expr> argument_expression_list_opt argument_expression_list argument_expression default_initializer_opt
433%type<ifctl> conditional_declaration
434%type<forctl> for_control_expression for_control_expression_list
435%type<oper> upupeq updown updowneq downupdowneq
436%type<expr> subrange
437%type<decl> asm_name_opt
438%type<expr> asm_operands_opt asm_operands_list asm_operand
439%type<labels> label_list
440%type<expr> asm_clobbers_list_opt
441%type<is_volatile> asm_volatile_opt
442%type<expr> handler_predicate_opt
443%type<genexpr> generic_association generic_assoc_list
444
445// statements
446%type<stmt> statement labeled_statement compound_statement
447%type<stmt> statement_decl statement_decl_list statement_list_nodecl
448%type<stmt> selection_statement
449%type<clause> switch_clause_list_opt switch_clause_list
450%type<expr> case_value
451%type<clause> case_clause case_value_list case_label case_label_list
452%type<stmt> iteration_statement jump_statement
453%type<stmt> expression_statement asm_statement
454%type<stmt> with_statement
455%type<expr> with_clause_opt
456%type<stmt> corun_statement cofor_statement
457%type<stmt> exception_statement
458%type<clause> handler_clause finally_clause
459%type<except_kind> handler_key
460%type<stmt> mutex_statement
461%type<expr> when_clause when_clause_opt waitfor waituntil timeout
462%type<stmt> waitfor_statement waituntil_statement
463%type<wfs> wor_waitfor_clause
464%type<wucn> waituntil_clause wand_waituntil_clause wor_waituntil_clause
465
466// declarations
467%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
468%type<decl> abstract_parameter_declarator_opt abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
469%type<decl> abstract_parameter_declaration
470
471%type<aggKey> aggregate_key aggregate_data aggregate_control
472%type<decl> aggregate_type aggregate_type_nobody
473
474%type<decl> assertion assertion_list assertion_list_opt
475
476%type<expr> bit_subrange_size_opt bit_subrange_size
477
478%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
479%type<type> basic_type_name_type
480%type<type> vtable vtable_opt default_opt
481
482%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
483
484%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
485%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
486
487%type<decl> elaborated_type elaborated_type_nobody
488
489%type<decl> enumerator_list enum_type enum_type_nobody enum_key enumerator_type
490%type<init> enumerator_value_opt
491
492%type<decl> external_definition external_definition_list external_definition_list_opt
493
494%type<decl> exception_declaration
495
496%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
497%type<expr> field field_name_list field_name fraction_constants_opt
498
499%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
500
501%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
502%type<decl> identifier_list
503
504%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
505%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
506%type<decl> cfa_abstract_ptr cfa_abstract_tuple
507
508%type<decl> cfa_array_parameter_1st_dimension
509
510%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
511%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
512
513%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
514%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
515
516%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_list_ellipsis_opt
517
518%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
519
520%type<decl> c_declaration static_assert
521%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
522%type<decl> KR_parameter_list KR_parameter_list_opt
523
524%type<decl> parameter_declaration parameter_list parameter_list_ellipsis_opt
525
526%type<decl> paren_identifier paren_type
527
528%type<decl> storage_class storage_class_list
529
530%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
531
532%type<tclass> type_class new_type_class
533%type<decl> type_declarator type_declarator_name type_declaring_list
534
535%type<decl> type_declaration_specifier type_type_specifier
536%type<type> type_name typegen_name
537%type<decl> typedef_name typedef_declaration typedef_expression
538
539%type<decl> variable_type_redeclarator variable_type_ptr variable_type_array variable_type_function
540%type<decl> general_function_declarator function_type_redeclarator function_type_array function_type_no_ptr function_type_ptr
541
542%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
543
544%type<decl> type type_no_function
545%type<decl> type_parameter type_parameter_list type_initializer_opt
546
547%type<expr> type_parameters_opt type_list array_type_list // array_dimension_list
548
549%type<decl> type_qualifier forall type_qualifier_list_opt type_qualifier_list
550%type<type> type_qualifier_name
551%type<decl> type_specifier type_specifier_nobody
552
553%type<decl> variable_declarator variable_ptr variable_array variable_function
554%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
555
556%type<decl> attribute_list_opt attribute_list attribute attribute_name_list attribute_name
557
558// initializers
559%type<init> initializer initializer_list_opt initializer_opt
560
561// designators
562%type<expr> designator designator_list designation
563
564
565// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
566// .---------. matches IF '(' comma_expression ')' statement . (reduce)
567// if ( C ) S1 else S2
568// `-----------------' matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
569// Similar issues exit with the waitfor statement.
570
571// Order of these lines matters (low-to-high precedence). THEN is left associative over WAND/WOR/TIMEOUT/ELSE, WAND/WOR
572// is left associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
573%precedence THEN // rule precedence for IF/WAITFOR statement
574%precedence ANDAND // token precedence for start of WAND in WAITFOR statement
575%precedence WAND // token precedence for start of WAND in WAITFOR statement
576%precedence OROR // token precedence for start of WOR in WAITFOR statement
577%precedence WOR // token precedence for start of WOR in WAITFOR statement
578%precedence TIMEOUT // token precedence for start of TIMEOUT in WAITFOR statement
579%precedence CATCH // token precedence for start of TIMEOUT in WAITFOR statement
580%precedence RECOVER // token precedence for start of TIMEOUT in WAITFOR statement
581%precedence CATCHRESUME // token precedence for start of TIMEOUT in WAITFOR statement
582%precedence FIXUP // token precedence for start of TIMEOUT in WAITFOR statement
583%precedence FINALLY // token precedence for start of TIMEOUT in WAITFOR statement
584%precedence ELSE // token precedence for start of else clause in IF/WAITFOR statement
585
586
587// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
588// forall( otype T ) struct Foo { T v; };
589// .-----. matches pointer to function returning a generic (which is impossible without a type)
590// Foo ( *fp )( int );
591// `---' matches start of TYPEGENname '('
592// must be:
593// Foo( int ) ( *fp )( int );
594// The same problem occurs here:
595// forall( otype T ) struct Foo { T v; } ( *fp )( int );
596// must be:
597// forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
598
599// Order of these lines matters (low-to-high precedence).
600%precedence TYPEGENname
601%precedence '}'
602%precedence '('
603
604// %precedence RESUME
605// %precedence '{'
606// %precedence ')'
607
608%locations // support location tracking for error messages
609
610%start translation_unit // parse-tree root
611
612%%
613// ************************ Namespace Management ********************************
614
615// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
616// which are lexically identical.
617//
618// typedef int foo; // identifier foo must now be scanned as TYPEDEFname
619// foo f; // to allow it to appear in this context
620//
621// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
622// between syntactic and semantic constructs. Cforall compounds this problem by introducing type names local to the
623// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
624// generators" -- parameterized types. This latter type name creates a third class of identifiers, "TYPEGENname", which
625// must be distinguished by the lexical scanner.
626//
627// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
628// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
629// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
630// each context that introduces a name scope, a new level is created in the type table and that level is popped on
631// exiting the scope. Since type names can be local to a particular declaration, each declaration is itself a scope.
632// This requires distinguishing between type names that are local to the current declaration scope and those that
633// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
634//
635// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
636// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
637// around the list separator.
638//
639// XXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
640// push pop push pop
641
642push:
643 { typedefTable.enterScope(); }
644 ;
645
646pop:
647 { typedefTable.leaveScope(); }
648 ;
649
650// ************************ CONSTANTS ********************************
651
652constant:
653 // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
654 INTEGERconstant { $$ = new ExpressionNode( build_constantInteger( yylloc, *$1 ) ); }
655 | FLOATING_DECIMALconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
656 | FLOATING_FRACTIONconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
657 | FLOATINGconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
658 | CHARACTERconstant { $$ = new ExpressionNode( build_constantChar( yylloc, *$1 ) ); }
659 ;
660
661quasi_keyword: // CFA
662 TIMEOUT
663 | WAND
664 | WOR
665 | CATCH
666 | RECOVER
667 | CATCHRESUME
668 | FIXUP
669 | FINALLY
670 ;
671
672identifier:
673 IDENTIFIER
674 | quasi_keyword
675 ;
676
677identifier_at:
678 identifier
679 | '@' // CFA
680 { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
681 ;
682
683identifier_or_type_name:
684 identifier
685 | TYPEDEFname
686 | TYPEGENname
687 ;
688
689string_literal:
690 string_literal_list { $$ = new ExpressionNode( build_constantStr( yylloc, *$1 ) ); }
691 ;
692
693string_literal_list: // juxtaposed strings are concatenated
694 STRINGliteral { $$ = $1; } // conversion from tok to str
695 | string_literal_list STRINGliteral
696 {
697 if ( ! appendStr( *$1, *$2 ) ) YYERROR; // append 2nd juxtaposed string to 1st
698 delete $2; // allocated by lexer
699 $$ = $1; // conversion from tok to str
700 }
701 ;
702
703// ************************ EXPRESSIONS ********************************
704
705primary_expression:
706 IDENTIFIER // typedef name cannot be used as a variable name
707 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
708 | quasi_keyword
709 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
710 | TYPEDIMname // CFA, generic length argument
711 { $$ = new ExpressionNode( build_dimensionref( yylloc, $1 ) ); }
712 | tuple
713 | '(' comma_expression ')'
714 { $$ = $2; }
715 | '(' compound_statement ')' // GCC, lambda expression
716 { $$ = new ExpressionNode( new ast::StmtExpr( yylloc, dynamic_cast<ast::CompoundStmt *>( maybeMoveBuild( $2 ) ) ) ); }
717 | type_name '.' identifier // CFA, nested type
718 { $$ = new ExpressionNode( build_qualified_expr( yylloc, DeclarationNode::newFromTypeData( $1 ), build_varref( yylloc, $3 ) ) ); }
719 | type_name '.' '[' field_name_list ']' // CFA, nested type / tuple field selector
720 { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
721 | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
722 {
723 // add the missing control expression to the GenericExpr and return it
724 $5->control = maybeMoveBuild( $3 );
725 $$ = new ExpressionNode( $5 );
726 }
727 // | RESUME '(' comma_expression ')'
728 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
729 // | RESUME '(' comma_expression ')' compound_statement
730 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
731 | IDENTIFIER IDENTIFIER // invalid syntax rule
732 { IdentifierBeforeIdentifier( *$1.str, *$2.str, "expression" ); $$ = nullptr; }
733 | IDENTIFIER type_qualifier // invalid syntax rule
734 { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
735 | IDENTIFIER storage_class // invalid syntax rule
736 { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
737 | IDENTIFIER basic_type_name // invalid syntax rule
738 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
739 | IDENTIFIER TYPEDEFname // invalid syntax rule
740 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
741 | IDENTIFIER TYPEGENname // invalid syntax rule
742 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
743 ;
744
745generic_assoc_list: // C11
746 generic_association
747 | generic_assoc_list ',' generic_association
748 {
749 // steal the association node from the singleton and delete the wrapper
750 assert( 1 == $3->associations.size() );
751 $1->associations.push_back( $3->associations.front() );
752 delete $3;
753 $$ = $1;
754 }
755 ;
756
757generic_association: // C11
758 type_no_function ':' assignment_expression
759 {
760 // create a GenericExpr wrapper with one association pair
761 $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuildType( $1 ), maybeMoveBuild( $3 ) } } );
762 }
763 | DEFAULT ':' assignment_expression
764 { $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuild( $3 ) } } ); }
765 ;
766
767postfix_expression:
768 primary_expression
769 | postfix_expression '[' assignment_expression ',' tuple_expression_list ']'
770 // Historic, transitional: Disallow commas in subscripts.
771 // Switching to this behaviour may help check if a C compatibilty case uses comma-exprs in subscripts.
772 // Current: Commas in subscripts make tuples.
773 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, new ExpressionNode( build_tuple( yylloc, $3->set_last( $5 ) ) ) ) ); }
774 | postfix_expression '[' assignment_expression ']'
775 // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
776 // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
777 // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
778 // equivalent to the old x[i,j].
779 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
780 | constant '[' assignment_expression ']' // 3[a], 'a'[a], 3.5[a]
781 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
782 | string_literal '[' assignment_expression ']' // "abc"[3], 3["abc"]
783 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
784 | postfix_expression '{' argument_expression_list_opt '}' // CFA, constructor call
785 {
786 Token fn;
787 fn.str = new std::string( "?{}" ); // location undefined - use location of '{'?
788 $$ = new ExpressionNode( new ast::ConstructorExpr( yylloc, build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), $1->set_last( $3 ) ) ) );
789 }
790 | postfix_expression '(' argument_expression_list_opt ')'
791 { $$ = new ExpressionNode( build_func( yylloc, $1, $3 ) ); }
792 | VA_ARG '(' primary_expression ',' declaration_specifier_nobody abstract_parameter_declarator_opt ')'
793 // { SemanticError( yylloc, "va_arg is currently unimplemented." ); $$ = nullptr; }
794 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, new string( "__builtin_va_arg" ) ) ),
795 $3->set_last( (ExpressionNode *)($6 ? $6->addType( $5 ) : $5) ) ) ); }
796 | postfix_expression '`' identifier // CFA, postfix call
797 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
798 | constant '`' identifier // CFA, postfix call
799 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
800 | string_literal '`' identifier // CFA, postfix call
801 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
802
803 // SKULLDUGGERY: The typedef table used for parsing does not store fields in structures. To parse a qualified
804 // name, it is assumed all name-tokens after the first are identifiers, regardless of how the lexer identifies
805 // them. For example:
806 //
807 // struct S;
808 // forall(T) struct T;
809 // union U;
810 // enum E { S, T, E };
811 // struct Z { int S, T, Z, E, U; };
812 // void fred () {
813 // Z z;
814 // z.S; // lexer returns S is TYPEDEFname
815 // z.T; // lexer returns T is TYPEGENname
816 // z.Z; // lexer returns Z is TYPEDEFname
817 // z.U; // lexer returns U is TYPEDEFname
818 // z.E; // lexer returns E is TYPEDEFname
819 // }
820 | postfix_expression '.' identifier_or_type_name
821 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
822
823 | postfix_expression '.' INTEGERconstant // CFA, tuple index
824 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
825 | postfix_expression FLOATING_FRACTIONconstant // CFA, tuple index
826 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 ) ) ); }
827 | postfix_expression '.' '[' field_name_list ']' // CFA, tuple field selector
828 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
829 | postfix_expression '.' aggregate_control
830 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $3, $1 ) ); }
831 | postfix_expression ARROW identifier
832 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
833 | postfix_expression ARROW INTEGERconstant // CFA, tuple index
834 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
835 | postfix_expression ARROW '[' field_name_list ']' // CFA, tuple field selector
836 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
837 | postfix_expression ICR
838 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::IncrPost, $1 ) ); }
839 | postfix_expression DECR
840 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::DecrPost, $1 ) ); }
841 | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
842 { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, new InitializerNode( $5, true ) ) ); }
843 | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
844 { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
845 | '^' primary_expression '{' argument_expression_list_opt '}' // CFA, destructor call
846 {
847 Token fn;
848 fn.str = new string( "^?{}" ); // location undefined
849 $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), $2->set_last( $4 ) ) );
850 }
851 ;
852
853argument_expression_list_opt:
854 // empty
855 { $$ = nullptr; }
856 | argument_expression_list
857 ;
858
859argument_expression_list:
860 argument_expression
861 | argument_expression_list_opt ',' argument_expression
862 { $$ = $1->set_last( $3 ); }
863 ;
864
865argument_expression:
866 '@' // CFA, default parameter
867 { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
868 // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
869 | assignment_expression
870 ;
871
872field_name_list: // CFA, tuple field selector
873 field
874 | field_name_list ',' field { $$ = $1->set_last( $3 ); }
875 ;
876
877field: // CFA, tuple field selector
878 field_name
879 | FLOATING_DECIMALconstant field
880 { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), maybeMoveBuild( $2 ) ) ); }
881 | FLOATING_DECIMALconstant '[' field_name_list ']'
882 { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), build_tuple( yylloc, $3 ) ) ); }
883 | field_name '.' field
884 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
885 | field_name '.' '[' field_name_list ']'
886 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
887 | field_name ARROW field
888 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
889 | field_name ARROW '[' field_name_list ']'
890 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
891 ;
892
893field_name:
894 INTEGERconstant fraction_constants_opt
895 { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_constantInteger( yylloc, *$1 ), $2 ) ); }
896 | FLOATINGconstant fraction_constants_opt
897 { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_field_name_FLOATINGconstant( yylloc, *$1 ), $2 ) ); }
898 | identifier_at fraction_constants_opt // CFA, allow anonymous fields
899 {
900 $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_varref( yylloc, $1 ), $2 ) );
901 }
902 ;
903
904fraction_constants_opt:
905 // empty
906 { $$ = nullptr; }
907 | fraction_constants_opt FLOATING_FRACTIONconstant
908 {
909 ast::Expr * constant = build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 );
910 $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( yylloc, $1, constant ) ) : new ExpressionNode( constant );
911 }
912 ;
913
914unary_expression:
915 postfix_expression
916 // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
917 // semantics checks, e.g., ++3, 3--, *3, &&3
918 | constant
919 | string_literal
920 { $$ = $1; }
921 | EXTENSION cast_expression // GCC
922 { $$ = $2->set_extension( true ); }
923 // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
924 // { * X; } // dereference X
925 // { * int X; } // CFA declaration of pointer to int
926 | ptrref_operator cast_expression // CFA
927 {
928 switch ( $1 ) {
929 case OperKinds::AddressOf:
930 $$ = new ExpressionNode( new ast::AddressExpr( maybeMoveBuild( $2 ) ) );
931 break;
932 case OperKinds::PointTo:
933 $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) );
934 break;
935 case OperKinds::And:
936 $$ = new ExpressionNode( new ast::AddressExpr( new ast::AddressExpr( maybeMoveBuild( $2 ) ) ) );
937 break;
938 default:
939 assert( false );
940 }
941 }
942 | unary_operator cast_expression
943 { $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) ); }
944 | ICR unary_expression
945 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Incr, $2 ) ); }
946 | DECR unary_expression
947 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Decr, $2 ) ); }
948 | SIZEOF unary_expression
949 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuild( $2 ) ) ); }
950 | SIZEOF '(' type_no_function ')'
951 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
952 | ALIGNOF unary_expression // GCC, variable alignment
953 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuild( $2 ) ) ); }
954 | ALIGNOF '(' type_no_function ')' // GCC, type alignment
955 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
956
957 // Cannot use rule "type", which includes cfa_abstract_function, for sizeof/alignof, because of S/R problems on
958 // look ahead, so the cfa_abstract_function is factored out.
959 | SIZEOF '(' cfa_abstract_function ')'
960 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
961 | ALIGNOF '(' cfa_abstract_function ')' // GCC, type alignment
962 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
963
964 | OFFSETOF '(' type_no_function ',' identifier ')'
965 { $$ = new ExpressionNode( build_offsetOf( yylloc, $3, build_varref( yylloc, $5 ) ) ); }
966 | TYPEID '(' type ')'
967 {
968 SemanticError( yylloc, "typeid name is currently unimplemented." ); $$ = nullptr;
969 // $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) );
970 }
971 | COUNTOF '(' type_no_function ')'
972 { $$ = new ExpressionNode( new ast::CountExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
973 | COUNTOF unary_expression
974 { SemanticError( yylloc, "countof for expressions is currently unimplemented. "); $$ = nullptr; }
975 ;
976
977ptrref_operator:
978 '*' { $$ = OperKinds::PointTo; }
979 | '&' { $$ = OperKinds::AddressOf; }
980 // GCC, address of label must be handled by semantic check for ref,ref,label
981 | ANDAND { $$ = OperKinds::And; }
982 ;
983
984unary_operator:
985 '+' { $$ = OperKinds::UnPlus; }
986 | '-' { $$ = OperKinds::UnMinus; }
987 | '!' { $$ = OperKinds::Neg; }
988 | '~' { $$ = OperKinds::BitNeg; }
989 ;
990
991cast_expression:
992 unary_expression
993 | '(' type_no_function ')' cast_expression
994 { $$ = new ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
995 | '(' aggregate_control '&' ')' cast_expression // CFA
996 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
997 | '(' aggregate_control '*' ')' cast_expression // CFA
998 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
999 | '(' VIRTUAL ')' cast_expression // CFA
1000 { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $4 ), nullptr ) ); }
1001 | '(' VIRTUAL type_no_function ')' cast_expression // CFA
1002 { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $5 ), maybeMoveBuildType( $3 ) ) ); }
1003 | '(' RETURN type_no_function ')' cast_expression // CFA
1004 { $$ = new ExpressionNode( build_cast( yylloc, $3, $5, ast::CastExpr::Return ) ); }
1005 | '(' COERCE type_no_function ')' cast_expression // CFA
1006 { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
1007 | '(' qualifier_cast_list ')' cast_expression // CFA
1008 { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
1009// | '(' type_no_function ')' tuple
1010// { $$ = new ast::ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
1011 ;
1012
1013qualifier_cast_list:
1014 cast_modifier type_qualifier_name
1015 | cast_modifier MUTEX
1016 | qualifier_cast_list cast_modifier type_qualifier_name
1017 | qualifier_cast_list cast_modifier MUTEX
1018 ;
1019
1020cast_modifier:
1021 '-'
1022 | '+'
1023 ;
1024
1025exponential_expression:
1026 cast_expression
1027 | exponential_expression '\\' cast_expression
1028 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Exp, $1, $3 ) ); }
1029 ;
1030
1031multiplicative_expression:
1032 exponential_expression
1033 | multiplicative_expression '*' exponential_expression
1034 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mul, $1, $3 ) ); }
1035 | multiplicative_expression '/' exponential_expression
1036 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Div, $1, $3 ) ); }
1037 | multiplicative_expression '%' exponential_expression
1038 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mod, $1, $3 ) ); }
1039 ;
1040
1041additive_expression:
1042 multiplicative_expression
1043 | additive_expression '+' multiplicative_expression
1044 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Plus, $1, $3 ) ); }
1045 | additive_expression '-' multiplicative_expression
1046 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Minus, $1, $3 ) ); }
1047 ;
1048
1049shift_expression:
1050 additive_expression
1051 | shift_expression LS additive_expression
1052 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LShift, $1, $3 ) ); }
1053 | shift_expression RS additive_expression
1054 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::RShift, $1, $3 ) ); }
1055 ;
1056
1057relational_expression:
1058 shift_expression
1059 | relational_expression '<' shift_expression
1060 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LThan, $1, $3 ) ); }
1061 | relational_expression '>' shift_expression
1062 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GThan, $1, $3 ) ); }
1063 | relational_expression LE shift_expression
1064 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LEThan, $1, $3 ) ); }
1065 | relational_expression GE shift_expression
1066 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GEThan, $1, $3 ) ); }
1067 ;
1068
1069equality_expression:
1070 relational_expression
1071 | equality_expression EQ relational_expression
1072 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Eq, $1, $3 ) ); }
1073 | equality_expression NE relational_expression
1074 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Neq, $1, $3 ) ); }
1075 ;
1076
1077AND_expression:
1078 equality_expression
1079 | AND_expression '&' equality_expression
1080 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitAnd, $1, $3 ) ); }
1081 ;
1082
1083exclusive_OR_expression:
1084 AND_expression
1085 | exclusive_OR_expression '^' AND_expression
1086 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Xor, $1, $3 ) ); }
1087 ;
1088
1089inclusive_OR_expression:
1090 exclusive_OR_expression
1091 | inclusive_OR_expression '|' exclusive_OR_expression
1092 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitOr, $1, $3 ) ); }
1093 ;
1094
1095logical_AND_expression:
1096 inclusive_OR_expression
1097 | logical_AND_expression ANDAND inclusive_OR_expression
1098 { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::AndExpr ) ); }
1099 ;
1100
1101logical_OR_expression:
1102 logical_AND_expression
1103 | logical_OR_expression OROR logical_AND_expression
1104 { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::OrExpr ) ); }
1105 ;
1106
1107conditional_expression:
1108 logical_OR_expression
1109 | logical_OR_expression '?' comma_expression ':' conditional_expression
1110 { $$ = new ExpressionNode( build_cond( yylloc, $1, $3, $5 ) ); }
1111 | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
1112 { $$ = new ExpressionNode( build_cond( yylloc, $1, nullptr, $4 ) ); }
1113 ;
1114
1115constant_expression:
1116 conditional_expression
1117 ;
1118
1119assignment_expression:
1120 // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
1121 conditional_expression
1122 | unary_expression assignment_operator assignment_expression
1123 {
1124// if ( $2 == OperKinds::AtAssn ) {
1125// SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
1126// } else {
1127 $$ = new ExpressionNode( build_binary_val( yylloc, $2, $1, $3 ) );
1128// } // if
1129 }
1130 | unary_expression '=' '{' initializer_list_opt comma_opt '}'
1131 { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
1132 ;
1133
1134assignment_expression_opt:
1135 // empty
1136 { $$ = nullptr; }
1137 | assignment_expression
1138 ;
1139
1140assignment_operator:
1141 simple_assignment_operator
1142 | compound_assignment_operator
1143 ;
1144
1145simple_assignment_operator:
1146 '=' { $$ = OperKinds::Assign; }
1147 | ATassign { $$ = OperKinds::AtAssn; } // CFA
1148 ;
1149
1150compound_assignment_operator:
1151 EXPassign { $$ = OperKinds::ExpAssn; }
1152 | MULTassign { $$ = OperKinds::MulAssn; }
1153 | DIVassign { $$ = OperKinds::DivAssn; }
1154 | MODassign { $$ = OperKinds::ModAssn; }
1155 | PLUSassign { $$ = OperKinds::PlusAssn; }
1156 | MINUSassign { $$ = OperKinds::MinusAssn; }
1157 | LSassign { $$ = OperKinds::LSAssn; }
1158 | RSassign { $$ = OperKinds::RSAssn; }
1159 | ANDassign { $$ = OperKinds::AndAssn; }
1160 | ERassign { $$ = OperKinds::ERAssn; }
1161 | ORassign { $$ = OperKinds::OrAssn; }
1162 ;
1163
1164tuple: // CFA, tuple
1165 // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
1166 // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
1167// '[' ']'
1168// { $$ = new ExpressionNode( build_tuple() ); }
1169// | '[' push assignment_expression pop ']'
1170// { $$ = new ExpressionNode( build_tuple( $3 ) ); }
1171 '[' ',' tuple_expression_list ']'
1172 { $$ = new ExpressionNode( build_tuple( yylloc, (new ExpressionNode( nullptr ))->set_last( $3 ) ) ); }
1173 | '[' push assignment_expression pop ',' tuple_expression_list ']'
1174 { $$ = new ExpressionNode( build_tuple( yylloc, $3->set_last( $6 ) ) ); }
1175 ;
1176
1177tuple_expression_list:
1178 assignment_expression
1179 | '@' // CFA
1180 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1181 | tuple_expression_list ',' assignment_expression
1182 { $$ = $1->set_last( $3 ); }
1183 | tuple_expression_list ',' '@'
1184 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1185 ;
1186
1187comma_expression:
1188 assignment_expression
1189 | comma_expression ',' assignment_expression
1190 { $$ = new ExpressionNode( new ast::CommaExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1191 ;
1192
1193comma_expression_opt:
1194 // empty
1195 { $$ = nullptr; }
1196 | comma_expression
1197 ;
1198
1199// ************************** STATEMENTS *******************************
1200
1201statement:
1202 labeled_statement
1203 | compound_statement
1204 | expression_statement
1205 | selection_statement
1206 | iteration_statement
1207 | jump_statement
1208 | with_statement
1209 | mutex_statement
1210 | waitfor_statement
1211 | waituntil_statement
1212 | corun_statement
1213 | cofor_statement
1214 | exception_statement
1215 | enable_disable_statement
1216 { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1217 | asm_statement
1218 | DIRECTIVE
1219 { $$ = new StatementNode( build_directive( yylloc, $1 ) ); }
1220 ;
1221
1222labeled_statement:
1223 // labels cannot be identifiers 0 or 1
1224 identifier_or_type_name ':' attribute_list_opt statement
1225 { $$ = $4->add_label( yylloc, $1, $3 ); }
1226 | identifier_or_type_name ':' attribute_list_opt error // invalid syntax rule
1227 {
1228 SemanticError( yylloc, "syntx error, label \"%s\" must be associated with a statement, "
1229 "where a declaration, case, or default is not a statement.\n"
1230 "Move the label or terminate with a semicolon.", $1.str->c_str() );
1231 $$ = nullptr;
1232 }
1233 ;
1234
1235compound_statement:
1236 '{' '}'
1237 { $$ = new StatementNode( build_compound( yylloc, (StatementNode *)0 ) ); }
1238 | '{' push
1239 local_label_declaration_opt // GCC, local labels appear at start of block
1240 statement_decl_list // C99, intermix declarations and statements
1241 pop '}'
1242 { $$ = new StatementNode( build_compound( yylloc, $4 ) ); }
1243 ;
1244
1245statement_decl_list: // C99
1246 statement_decl
1247 | statement_decl_list statement_decl
1248 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1249 ;
1250
1251statement_decl:
1252 declaration // CFA, new & old style declarations
1253 { $$ = new StatementNode( $1 ); }
1254 | EXTENSION declaration // GCC
1255 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1256 | function_definition
1257 { $$ = new StatementNode( $1 ); }
1258 | EXTENSION function_definition // GCC
1259 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1260 | statement
1261 ;
1262
1263statement_list_nodecl:
1264 statement
1265 | statement_list_nodecl statement
1266 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1267 | statement_list_nodecl error // invalid syntax rule
1268 { SemanticError( yylloc, "illegal syntax, declarations only allowed at the start of the switch body,"
1269 " i.e., after the '{'." ); $$ = nullptr; }
1270 ;
1271
1272expression_statement:
1273 comma_expression_opt ';'
1274 { $$ = new StatementNode( build_expr( yylloc, $1 ) ); }
1275 ;
1276
1277// "if", "switch", and "choose" require parenthesis around the conditional. See the following ambiguities without
1278// parenthesis:
1279//
1280// if x + y + z; => if ( x ) + y + z or if ( x + y ) + z
1281//
1282// switch O { }
1283//
1284// O{} => object-constructor for conditional, switch body ???
1285// O{} => O for conditional followed by switch body
1286//
1287// C++ has this problem, as it has the same constructor syntax.
1288//
1289// switch sizeof ( T ) { }
1290//
1291// sizeof ( T ) => sizeof of T for conditional followed by switch body
1292// sizeof ( T ) => sizeof of compound literal (T){ }, closing parenthesis ???
1293//
1294// Note the two grammar rules for sizeof (alignof)
1295//
1296// | SIZEOF unary_expression
1297// | SIZEOF '(' type_no_function ')'
1298//
1299// where the first DOES NOT require parenthesis! And C++ inherits this problem from C.
1300
1301selection_statement:
1302 IF '(' conditional_declaration ')' statement %prec THEN
1303 // explicitly deal with the shift/reduce conflict on if/else
1304 { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), nullptr ) ); }
1305 | IF '(' conditional_declaration ')' statement ELSE statement
1306 { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), maybe_build_compound( yylloc, $7 ) ) ); }
1307 | SWITCH '(' comma_expression ')' case_clause
1308 { $$ = new StatementNode( build_switch( yylloc, true, $3, $5 ) ); }
1309 | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1310 {
1311 StatementNode *sw = new StatementNode( build_switch( yylloc, true, $3, $8 ) );
1312 // The semantics of the declaration list is changed to include associated initialization, which is performed
1313 // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1314 // statement around the switch. Statements after the initial declaration list can never be executed, and
1315 // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1316 // statement.
1317 $$ = $7 ? new StatementNode( build_compound( yylloc, (new StatementNode( $7 ))->set_last( sw ) ) ) : sw;
1318 }
1319 | SWITCH '(' comma_expression ')' '{' error '}' // CFA, invalid syntax rule error
1320 { SemanticError( yylloc, "synatx error, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1321 | CHOOSE '(' comma_expression ')' case_clause // CFA
1322 { $$ = new StatementNode( build_switch( yylloc, false, $3, $5 ) ); }
1323 | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1324 {
1325 StatementNode *sw = new StatementNode( build_switch( yylloc, false, $3, $8 ) );
1326 $$ = $7 ? new StatementNode( build_compound( yylloc, (new StatementNode( $7 ))->set_last( sw ) ) ) : sw;
1327 }
1328 | CHOOSE '(' comma_expression ')' '{' error '}' // CFA, invalid syntax rule
1329 { SemanticError( yylloc, "illegal syntax, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1330 ;
1331
1332conditional_declaration:
1333 comma_expression
1334 { $$ = new CondCtl( nullptr, $1 ); }
1335 | c_declaration // no semi-colon
1336 { $$ = new CondCtl( $1, nullptr ); }
1337 | cfa_declaration // no semi-colon
1338 { $$ = new CondCtl( $1, nullptr ); }
1339 | declaration comma_expression // semi-colon separated
1340 { $$ = new CondCtl( $1, $2 ); }
1341 ;
1342
1343// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1344// clause allows a list of values and subranges.
1345
1346case_value: // CFA
1347 constant_expression { $$ = $1; }
1348 | constant_expression ELLIPSIS constant_expression // GCC, subrange
1349 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1350 | subrange // CFA, subrange
1351 ;
1352
1353case_value_list: // CFA
1354 case_value { $$ = new ClauseNode( build_case( yylloc, $1 ) ); }
1355 // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1356 | case_value_list ',' case_value { $$ = $1->set_last( new ClauseNode( build_case( yylloc, $3 ) ) ); }
1357 ;
1358
1359case_label: // CFA
1360 CASE error // invalid syntax rule
1361 { SemanticError( yylloc, "illegal syntax, case list missing after case." ); $$ = nullptr; }
1362 | CASE case_value_list ':' { $$ = $2; }
1363 | CASE case_value_list error // invalid syntax rule
1364 { SemanticError( yylloc, "illegal syntax, colon missing after case list." ); $$ = nullptr; }
1365 | DEFAULT ':' { $$ = new ClauseNode( build_default( yylloc ) ); }
1366 // A semantic check is required to ensure only one default clause per switch/choose statement.
1367 | DEFAULT error // invalid syntax rule
1368 { SemanticError( yylloc, "illegal syntax, colon missing after default." ); $$ = nullptr; }
1369 ;
1370
1371case_label_list: // CFA
1372 case_label
1373 | case_label_list case_label { $$ = $1->set_last( $2 ); }
1374 ;
1375
1376case_clause: // CFA
1377 case_label_list statement { $$ = $1->append_last_case( maybe_build_compound( yylloc, $2 ) ); }
1378 ;
1379
1380switch_clause_list_opt: // CFA
1381 // empty
1382 { $$ = nullptr; }
1383 | switch_clause_list
1384 ;
1385
1386switch_clause_list: // CFA
1387 case_label_list statement_list_nodecl
1388 { $$ = $1->append_last_case( new StatementNode( build_compound( yylloc, $2 ) ) ); }
1389 | switch_clause_list case_label_list statement_list_nodecl
1390 { $$ = $1->set_last( $2->append_last_case( new StatementNode( build_compound( yylloc, $3 ) ) ) ); }
1391 ;
1392
1393iteration_statement:
1394 WHILE '(' ')' statement %prec THEN // CFA => while ( 1 )
1395 { $$ = new StatementNode( build_while( yylloc, new CondCtl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) ); }
1396 | WHILE '(' ')' statement ELSE statement // CFA
1397 {
1398 $$ = new StatementNode( build_while( yylloc, new CondCtl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) );
1399 SemanticWarning( yylloc, Warning::SuperfluousElse );
1400 }
1401 | WHILE '(' conditional_declaration ')' statement %prec THEN
1402 { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1403 | WHILE '(' conditional_declaration ')' statement ELSE statement // CFA
1404 { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1405 | DO statement WHILE '(' ')' ';' // CFA => do while( 1 )
1406 { $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) ); }
1407 | DO statement WHILE '(' ')' ELSE statement // CFA
1408 {
1409 $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) );
1410 SemanticWarning( yylloc, Warning::SuperfluousElse );
1411 }
1412 | DO statement WHILE '(' comma_expression ')' ';'
1413 { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ) ) ); }
1414 | DO statement WHILE '(' comma_expression ')' ELSE statement // CFA
1415 { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ), $8 ) ); }
1416 | FOR '(' ')' statement %prec THEN // CFA => for ( ;; )
1417 { $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) ); }
1418 | FOR '(' ')' statement ELSE statement // CFA
1419 {
1420 $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) );
1421 SemanticWarning( yylloc, Warning::SuperfluousElse );
1422 }
1423 | FOR '(' for_control_expression_list ')' statement %prec THEN
1424 { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1425 | FOR '(' for_control_expression_list ')' statement ELSE statement // CFA
1426 { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1427 ;
1428
1429for_control_expression_list:
1430 for_control_expression
1431 | for_control_expression_list ':' for_control_expression
1432 // ForCtrl + ForCtrl:
1433 // init + init => multiple declaration statements that are hoisted
1434 // condition + condition => (expression) && (expression)
1435 // change + change => (expression), (expression)
1436 {
1437 $1->init->set_last( $3->init );
1438 if ( $1->condition ) {
1439 if ( $3->condition ) {
1440 $1->condition->expr.reset( new ast::LogicalExpr( yylloc, $1->condition->expr.release(), $3->condition->expr.release(), ast::AndExpr ) );
1441 } // if
1442 } else $1->condition = $3->condition;
1443 if ( $1->change ) {
1444 if ( $3->change ) {
1445 $1->change->expr.reset( new ast::CommaExpr( yylloc, $1->change->expr.release(), $3->change->expr.release() ) );
1446 } // if
1447 } else $1->change = $3->change;
1448 $$ = $1;
1449 }
1450 ;
1451
1452for_control_expression:
1453 ';' comma_expression_opt ';' comma_expression_opt
1454 { $$ = new ForCtrl( nullptr, $2, $4 ); }
1455 | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1456 {
1457 $$ = new ForCtrl( $1 ? new StatementNode( new ast::ExprStmt( yylloc, maybeMoveBuild( $1 ) ) ) : nullptr, $3, $5 );
1458 }
1459 | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1460 { $$ = new ForCtrl( new StatementNode( $1 ), $2, $4 ); }
1461
1462 | '@' ';' comma_expression // CFA, empty loop-index
1463 { $$ = new ForCtrl( nullptr, $3, nullptr ); }
1464 | '@' ';' comma_expression ';' comma_expression // CFA, empty loop-index
1465 { $$ = new ForCtrl( nullptr, $3, $5 ); }
1466
1467 | comma_expression // CFA, anonymous loop-index
1468 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), NEW_ZERO, OperKinds::LThan, $1->clone(), NEW_ONE ); }
1469 | downupdowneq comma_expression // CFA, anonymous loop-index
1470 { $$ = forCtrl( yylloc, $2, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $1, NEW_ZERO, $2->clone() ), $1, UPDOWN( $1, $2->clone(), NEW_ZERO ), NEW_ONE ); }
1471
1472 | comma_expression updowneq comma_expression // CFA, anonymous loop-index
1473 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), NEW_ONE ); }
1474 | '@' updowneq comma_expression // CFA, anonymous loop-index
1475 {
1476 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1477 else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, NEW_ONE );
1478 }
1479 | comma_expression updowneq '@' // CFA, anonymous loop-index
1480 {
1481 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1482 else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1483 }
1484 | comma_expression updowneq comma_expression '~' comma_expression // CFA, anonymous loop-index
1485 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), $5 ); }
1486 | '@' updowneq comma_expression '~' comma_expression // CFA, anonymous loop-index
1487 {
1488 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1489 else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, $5 );
1490 }
1491 | comma_expression updowneq '@' '~' comma_expression // CFA, anonymous loop-index
1492 {
1493 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1494 else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1495 }
1496 | comma_expression updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1497 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1498 | '@' updowneq '@' // CFA, invalid syntax rule
1499 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1500 | '@' updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1501 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1502 | comma_expression updowneq '@' '~' '@' // CFA, invalid syntax rule
1503 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1504 | '@' updowneq '@' '~' '@' // CFA, invalid syntax rule
1505 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1506
1507 // These rules accept a comma_expression for the initialization, when only an identifier is correct. Being
1508 // permissive allows for a better error message from forCtrl.
1509 | comma_expression ';' comma_expression // CFA
1510 { $$ = forCtrl( yylloc, $3, $1, NEW_ZERO, OperKinds::LThan, $3->clone(), NEW_ONE ); }
1511 | comma_expression ';' downupdowneq comma_expression // CFA
1512 { $$ = forCtrl( yylloc, $4, $1, UPDOWN( $3, NEW_ZERO, $4->clone() ), $3, UPDOWN( $3, $4->clone(), NEW_ZERO ), NEW_ONE ); }
1513
1514 | comma_expression ';' comma_expression updowneq comma_expression // CFA
1515 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), NEW_ONE ); }
1516 | comma_expression ';' '@' updowneq comma_expression // CFA
1517 {
1518 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1519 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, NEW_ONE );
1520 }
1521 | comma_expression ';' comma_expression updowneq '@' // CFA
1522 {
1523 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1524 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1525 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, NEW_ONE );
1526 }
1527 | comma_expression ';' '@' updowneq '@' // CFA, invalid syntax rule
1528 { SemanticError( yylloc, "illegal syntax, missing low/high value for ascending/descending range so index is uninitialized." ); $$ = nullptr; }
1529
1530 | comma_expression ';' comma_expression updowneq comma_expression '~' comma_expression // CFA
1531 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), $7 ); }
1532 | comma_expression ';' '@' updowneq comma_expression '~' comma_expression // CFA, invalid syntax rule
1533 {
1534 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1535 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, $7 );
1536 }
1537 | comma_expression ';' comma_expression updowneq '@' '~' comma_expression // CFA
1538 {
1539 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1540 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1541 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, $7 );
1542 }
1543 | comma_expression ';' comma_expression updowneq comma_expression '~' '@' // CFA
1544 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), nullptr ); }
1545 | comma_expression ';' '@' updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1546 {
1547 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1548 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, nullptr );
1549 }
1550 | comma_expression ';' comma_expression updowneq '@' '~' '@' // CFA
1551 {
1552 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1553 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1554 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, nullptr );
1555 }
1556 | comma_expression ';' '@' updowneq '@' '~' '@' // CFA
1557 { SemanticError( yylloc, "illegal syntax, missing low/high value for ascending/descending range so index is uninitialized." ); $$ = nullptr; }
1558
1559 | declaration comma_expression // CFA
1560 { $$ = forCtrl( yylloc, $1, NEW_ZERO, OperKinds::LThan, $2, NEW_ONE ); }
1561 | declaration downupdowneq comma_expression // CFA
1562 { $$ = forCtrl( yylloc, $1, UPDOWN( $2, NEW_ZERO, $3 ), $2, UPDOWN( $2, $3->clone(), NEW_ZERO ), NEW_ONE ); }
1563
1564 | declaration comma_expression updowneq comma_expression // CFA
1565 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2->clone(), $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), NEW_ONE ); }
1566 | declaration '@' updowneq comma_expression // CFA
1567 {
1568 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1569 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, NEW_ONE );
1570 }
1571 | declaration comma_expression updowneq '@' // CFA
1572 {
1573 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1574 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1575 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, NEW_ONE );
1576 }
1577
1578 | declaration comma_expression updowneq comma_expression '~' comma_expression // CFA
1579 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), $6 ); }
1580 | declaration '@' updowneq comma_expression '~' comma_expression // CFA
1581 {
1582 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1583 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, $6 );
1584 }
1585 | declaration comma_expression updowneq '@' '~' comma_expression // CFA
1586 {
1587 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1588 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1589 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, $6 );
1590 }
1591 | declaration comma_expression updowneq comma_expression '~' '@' // CFA
1592 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), nullptr ); }
1593 | declaration '@' updowneq comma_expression '~' '@' // CFA
1594 {
1595 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1596 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, nullptr );
1597 }
1598 | declaration comma_expression updowneq '@' '~' '@' // CFA
1599 {
1600 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1601 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1602 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, nullptr );
1603 }
1604 | declaration '@' updowneq '@' '~' '@' // CFA, invalid syntax rule
1605 { SemanticError( yylloc, "illegal syntax, missing low/high value for ascending/descending range so index is uninitialized." ); $$ = nullptr; }
1606
1607 | comma_expression ';' enum_key // CFA, enum type
1608 {
1609 $$ = enumRangeCtrl( $1, OperKinds::LEThan, new ExpressionNode( new ast::TypeExpr( yylloc, $3->buildType() ) ) );
1610 }
1611 | comma_expression ';' downupdowneq enum_key // CFA, enum type, reverse direction
1612 {
1613 if ( $3 == OperKinds::GThan ) {
1614 SemanticError( yylloc, "all enumeration ranges are equal (all values). Add an equal, e.g., ~=, -~=." ); $$ = nullptr;
1615 $3 = OperKinds::GEThan;
1616 } // if
1617 $$ = enumRangeCtrl( $1, $3, new ExpressionNode( new ast::TypeExpr( yylloc, $4->buildType() ) ) );
1618 }
1619 ;
1620
1621enum_key:
1622 type_name
1623 { $$ = DeclarationNode::newEnum( $1->symbolic.name, nullptr, false, false ); }
1624 | ENUM identifier
1625 { $$ = DeclarationNode::newEnum( $2, nullptr, false, false ); }
1626 | ENUM type_name
1627 { $$ = DeclarationNode::newEnum( $2->symbolic.name, nullptr, false, false ); }
1628 ;
1629
1630// This rule exists to handle the ambiguity with unary operator '~'. The rule is the same as updowneq minus the '~'.
1631// Specifically, "for ( ~5 )" means the complement of 5, not loop 0..4. Hence, in this case "for ( ~= 5 )", i.e., 0..5,
1632// it is not possible to just remove the '='. The entire '~=' must be removed.
1633downupdowneq:
1634 ErangeUp
1635 { $$ = OperKinds::LThan; }
1636 | ErangeDown
1637 { $$ = OperKinds::GThan; }
1638 | ErangeUpEq
1639 { $$ = OperKinds::LEThan; }
1640 | ErangeDownEq
1641 { $$ = OperKinds::GEThan; }
1642 ;
1643
1644updown:
1645 '~' // shorthand 0 ~ 10 => 0 +~ 10
1646 { $$ = OperKinds::LThan; }
1647 | ErangeUp
1648 { $$ = OperKinds::LThan; }
1649 | ErangeDown
1650 { $$ = OperKinds::GThan; }
1651 ;
1652
1653updowneq:
1654 updown
1655 | ErangeUpEq
1656 { $$ = OperKinds::LEThan; }
1657 | ErangeDownEq
1658 { $$ = OperKinds::GEThan; }
1659 ;
1660
1661jump_statement:
1662 GOTO identifier_or_type_name ';'
1663 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Goto ) ); }
1664 | GOTO '*' comma_expression ';' // GCC, computed goto
1665 // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1666 // whereas normal operator precedence yields goto (*i)+3;
1667 { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1668 // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1669 | fall_through_name ';' // CFA
1670 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThrough ) ); }
1671 | fall_through_name identifier_or_type_name ';' // CFA
1672 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::FallThrough ) ); }
1673 | fall_through_name DEFAULT ';' // CFA
1674 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThroughDefault ) ); }
1675 | CONTINUE ';'
1676 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1677 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Continue ) ); }
1678 | CONTINUE identifier_or_type_name ';' // CFA, multi-level continue
1679 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1680 // the target of the transfer appears only at the start of an iteration statement.
1681 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Continue ) ); }
1682 | BREAK ';'
1683 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1684 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Break ) ); }
1685 | BREAK identifier_or_type_name ';' // CFA, multi-level exit
1686 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1687 // the target of the transfer appears only at the start of an iteration statement.
1688 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Break ) ); }
1689 | RETURN comma_expression_opt ';'
1690 { $$ = new StatementNode( build_return( yylloc, $2 ) ); }
1691 | RETURN '{' initializer_list_opt comma_opt '}' ';'
1692 { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1693 | SUSPEND ';'
1694 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::None ) ); }
1695 | SUSPEND compound_statement
1696 { $$ = new StatementNode( build_suspend( yylloc, $2, ast::SuspendStmt::None ) ); }
1697 | SUSPEND COROUTINE ';'
1698 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Coroutine ) ); }
1699 | SUSPEND COROUTINE compound_statement
1700 { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Coroutine ) ); }
1701 | SUSPEND GENERATOR ';'
1702 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Generator ) ); }
1703 | SUSPEND GENERATOR compound_statement
1704 { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Generator ) ); }
1705 | THROW assignment_expression_opt ';' // handles rethrow
1706 { $$ = new StatementNode( build_throw( yylloc, $2 ) ); }
1707 | THROWRESUME assignment_expression_opt ';' // handles reresume
1708 { $$ = new StatementNode( build_resume( yylloc, $2 ) ); }
1709 | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1710 { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1711 ;
1712
1713fall_through_name: // CFA
1714 FALLTHRU
1715 | FALLTHROUGH
1716 ;
1717
1718with_statement:
1719 WITH '(' type_list ')' statement // support scoped enumeration
1720 { $$ = new StatementNode( build_with( yylloc, $3, $5 ) ); }
1721 ;
1722
1723// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so possibly change syntax to "with mutex".
1724mutex_statement:
1725 MUTEX '(' argument_expression_list_opt ')' statement
1726 {
1727 if ( ! $3 ) { SemanticError( yylloc, "illegal syntax, mutex argument list cannot be empty." ); $$ = nullptr; }
1728 $$ = new StatementNode( build_mutex( yylloc, $3, $5 ) );
1729 }
1730 ;
1731
1732when_clause:
1733 WHEN '(' comma_expression ')' { $$ = $3; }
1734 ;
1735
1736when_clause_opt:
1737 // empty
1738 { $$ = nullptr; }
1739 | when_clause
1740 ;
1741
1742cast_expression_list:
1743 cast_expression
1744 | cast_expression_list ',' cast_expression
1745 { SemanticError( yylloc, "List of mutex member is currently unimplemented." ); $$ = nullptr; }
1746 ;
1747
1748timeout:
1749 TIMEOUT '(' comma_expression ')' { $$ = $3; }
1750 ;
1751
1752wor:
1753 OROR
1754 | WOR
1755
1756waitfor:
1757 WAITFOR '(' cast_expression ')'
1758 { $$ = $3; }
1759 | WAITFOR '(' cast_expression_list ':' argument_expression_list_opt ')'
1760 { $$ = $3->set_last( $5 ); }
1761 ;
1762
1763wor_waitfor_clause:
1764 when_clause_opt waitfor statement %prec THEN
1765 // Called first: create header for WaitForStmt.
1766 { $$ = build_waitfor( yylloc, new ast::WaitForStmt( yylloc ), $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1767 | wor_waitfor_clause wor when_clause_opt waitfor statement
1768 { $$ = build_waitfor( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1769 | wor_waitfor_clause wor when_clause_opt ELSE statement
1770 { $$ = build_waitfor_else( yylloc, $1, $3, maybe_build_compound( yylloc, $5 ) ); }
1771 | wor_waitfor_clause wor when_clause_opt timeout statement %prec THEN
1772 { $$ = build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1773 // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1774 | wor_waitfor_clause wor when_clause_opt timeout statement wor ELSE statement // invalid syntax rule
1775 { SemanticError( yylloc, "illegal syntax, else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1776 | wor_waitfor_clause wor when_clause_opt timeout statement wor when_clause ELSE statement
1777 { $$ = build_waitfor_else( yylloc, build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ), $7, maybe_build_compound( yylloc, $9 ) ); }
1778 ;
1779
1780waitfor_statement:
1781 wor_waitfor_clause %prec THEN
1782 { $$ = new StatementNode( $1 ); }
1783 ;
1784
1785wand:
1786 ANDAND
1787 | WAND
1788 ;
1789
1790waituntil:
1791 WAITUNTIL '(' comma_expression ')'
1792 { $$ = $3; }
1793 ;
1794
1795waituntil_clause:
1796 when_clause_opt waituntil statement
1797 { $$ = build_waituntil_clause( yylloc, $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1798 | '(' wor_waituntil_clause ')'
1799 { $$ = $2; }
1800 ;
1801
1802wand_waituntil_clause:
1803 waituntil_clause %prec THEN
1804 { $$ = $1; }
1805 | waituntil_clause wand wand_waituntil_clause
1806 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::AND, $1, $3 ); }
1807 ;
1808
1809wor_waituntil_clause:
1810 wand_waituntil_clause
1811 { $$ = $1; }
1812 | wor_waituntil_clause wor wand_waituntil_clause
1813 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::OR, $1, $3 ); }
1814 | wor_waituntil_clause wor when_clause_opt ELSE statement
1815 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::LEFT_OR, $1, build_waituntil_else( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1816 ;
1817
1818waituntil_statement:
1819 wor_waituntil_clause %prec THEN
1820 { $$ = new StatementNode( build_waituntil_stmt( yylloc, $1 ) ); }
1821 ;
1822
1823corun_statement:
1824 CORUN statement
1825 { $$ = new StatementNode( build_corun( yylloc, $2 ) ); }
1826 ;
1827
1828cofor_statement:
1829 COFOR '(' for_control_expression_list ')' statement
1830 { $$ = new StatementNode( build_cofor( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1831 ;
1832
1833exception_statement:
1834 TRY compound_statement handler_clause %prec THEN
1835 { $$ = new StatementNode( build_try( yylloc, $2, $3, nullptr ) ); }
1836 | TRY compound_statement finally_clause
1837 { $$ = new StatementNode( build_try( yylloc, $2, nullptr, $3 ) ); }
1838 | TRY compound_statement handler_clause finally_clause
1839 { $$ = new StatementNode( build_try( yylloc, $2, $3, $4 ) ); }
1840 ;
1841
1842handler_clause:
1843 handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1844 { $$ = new ClauseNode( build_catch( yylloc, $1, $4, $6, $8 ) ); }
1845 | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1846 { $$ = $1->set_last( new ClauseNode( build_catch( yylloc, $2, $5, $7, $9 ) ) ); }
1847 ;
1848
1849handler_predicate_opt:
1850 // empty
1851 { $$ = nullptr; }
1852 | ';' conditional_expression { $$ = $2; }
1853 ;
1854
1855handler_key:
1856 CATCH { $$ = ast::Terminate; }
1857 | RECOVER { $$ = ast::Terminate; }
1858 | CATCHRESUME { $$ = ast::Resume; }
1859 | FIXUP { $$ = ast::Resume; }
1860 ;
1861
1862finally_clause:
1863 FINALLY compound_statement { $$ = new ClauseNode( build_finally( yylloc, $2 ) ); }
1864 ;
1865
1866exception_declaration:
1867 // No SUE declaration in parameter list.
1868 type_specifier_nobody
1869 | type_specifier_nobody declarator
1870 { $$ = $2->addType( $1 ); }
1871 | type_specifier_nobody variable_abstract_declarator
1872 { $$ = $2->addType( $1 ); }
1873 | cfa_abstract_declarator_tuple identifier // CFA
1874 { $$ = $1->addName( $2 ); }
1875 | cfa_abstract_declarator_tuple // CFA
1876 ;
1877
1878enable_disable_statement:
1879 enable_disable_key identifier_list compound_statement
1880 ;
1881
1882enable_disable_key:
1883 ENABLE
1884 | DISABLE
1885 ;
1886
1887asm_statement:
1888 ASM asm_volatile_opt '(' string_literal ')' ';'
1889 { $$ = new StatementNode( build_asm( yylloc, $2, $4, nullptr ) ); }
1890 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1891 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6 ) ); }
1892 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1893 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8 ) ); }
1894 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1895 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8, $10 ) ); }
1896 | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1897 { $$ = new StatementNode( build_asm( yylloc, $2, $5, nullptr, $8, $10, $12 ) ); }
1898 ;
1899
1900asm_volatile_opt: // GCC
1901 // empty
1902 { $$ = false; }
1903 | VOLATILE
1904 { $$ = true; }
1905 ;
1906
1907asm_operands_opt: // GCC
1908 // empty
1909 { $$ = nullptr; } // use default argument
1910 | asm_operands_list
1911 ;
1912
1913asm_operands_list: // GCC
1914 asm_operand
1915 | asm_operands_list ',' asm_operand
1916 { $$ = $1->set_last( $3 ); }
1917 ;
1918
1919asm_operand: // GCC
1920 string_literal '(' constant_expression ')'
1921 { $$ = new ExpressionNode( new ast::AsmExpr( yylloc, "", maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1922 | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1923 {
1924 $$ = new ExpressionNode( new ast::AsmExpr( yylloc, *$2.str, maybeMoveBuild( $4 ), maybeMoveBuild( $6 ) ) );
1925 delete $2.str;
1926 }
1927 ;
1928
1929asm_clobbers_list_opt: // GCC
1930 // empty
1931 { $$ = nullptr; } // use default argument
1932 | string_literal
1933 { $$ = $1; }
1934 | asm_clobbers_list_opt ',' string_literal
1935 { $$ = $1->set_last( $3 ); }
1936 ;
1937
1938label_list:
1939 identifier
1940 {
1941 $$ = new LabelNode(); $$->labels.emplace_back( yylloc, *$1 );
1942 delete $1; // allocated by lexer
1943 }
1944 | label_list ',' identifier
1945 {
1946 $$ = $1; $1->labels.emplace_back( yylloc, *$3 );
1947 delete $3; // allocated by lexer
1948 }
1949 ;
1950
1951// ****************************** DECLARATIONS *********************************
1952
1953declaration_list_opt: // used at beginning of switch statement
1954 // empty
1955 { $$ = nullptr; }
1956 | declaration_list
1957 ;
1958
1959declaration_list:
1960 declaration
1961 | declaration_list declaration
1962 { $$ = $1->set_last( $2 ); }
1963 ;
1964
1965KR_parameter_list_opt: // used to declare parameter types in K&R style functions
1966 // empty
1967 { $$ = nullptr; }
1968 | KR_parameter_list
1969 ;
1970
1971KR_parameter_list:
1972 c_declaration ';'
1973 { $$ = $1; }
1974 | KR_parameter_list c_declaration ';'
1975 { $$ = $1->set_last( $2 ); }
1976 ;
1977
1978local_label_declaration_opt: // GCC, local label
1979 // empty
1980 | local_label_declaration_list
1981 ;
1982
1983local_label_declaration_list: // GCC, local label
1984 LABEL local_label_list ';'
1985 | local_label_declaration_list LABEL local_label_list ';'
1986 ;
1987
1988local_label_list: // GCC, local label
1989 identifier_or_type_name
1990 | local_label_list ',' identifier_or_type_name
1991 ;
1992
1993declaration: // old & new style declarations
1994 c_declaration ';'
1995 | cfa_declaration ';' // CFA
1996 | static_assert // C11
1997 ;
1998
1999static_assert:
2000 STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
2001 { $$ = DeclarationNode::newStaticAssert( $3, maybeMoveBuild( $5 ) ); }
2002 | STATICASSERT '(' constant_expression ')' ';' // CFA
2003 { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( yylloc, *new string( "\"\"" ) ) ); }
2004
2005// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
2006// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
2007// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
2008// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
2009// the declaration list (as in Pascal). ANSI C and the new CFA declarations may appear together in the same program
2010// block, but cannot be mixed within a specific declaration.
2011//
2012// CFA C
2013// [10] int x; int x[10]; // array of 10 integers
2014// [10] * char y; char *y[10]; // array of 10 pointers to char
2015
2016cfa_declaration: // CFA
2017 cfa_variable_declaration
2018 | cfa_typedef_declaration
2019 | cfa_function_declaration
2020 | type_declaring_list
2021 { SemanticError( yylloc, "otype declaration is currently unimplemented." ); $$ = nullptr; }
2022 | trait_specifier
2023 ;
2024
2025cfa_variable_declaration: // CFA
2026 cfa_variable_specifier initializer_opt
2027 { $$ = $1->addInitializer( $2 ); }
2028 | declaration_qualifier_list cfa_variable_specifier initializer_opt
2029 // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
2030 // them as a type_qualifier cannot appear in that context.
2031 { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
2032 | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
2033 { $$ = $1->set_last( $1->cloneType( $5 )->addInitializer( $6 ) ); }
2034 ;
2035
2036cfa_variable_specifier: // CFA
2037 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
2038 // storage-class
2039 cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
2040 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
2041 | cfa_abstract_tuple identifier_or_type_name asm_name_opt
2042 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
2043 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
2044 { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
2045
2046 // [ int s, int t ]; // declare s and t
2047 // [ int, int ] f();
2048 // [] g( int );
2049 // [ int x, int y ] = f(); // declare x and y, initialize each from f
2050 // g( x + y );
2051 | cfa_function_return asm_name_opt
2052 { SemanticError( yylloc, "tuple-element declarations is currently unimplemented." ); $$ = nullptr; }
2053 | type_qualifier_list cfa_function_return asm_name_opt
2054 { SemanticError( yylloc, "tuple variable declaration is currently unimplemented." ); $$ = nullptr; }
2055 ;
2056
2057cfa_function_declaration: // CFA
2058 cfa_function_specifier
2059 | type_qualifier_list cfa_function_specifier
2060 { $$ = $2->addQualifiers( $1 ); }
2061 | declaration_qualifier_list cfa_function_specifier
2062 { $$ = $2->addQualifiers( $1 ); }
2063 | declaration_qualifier_list type_qualifier_list cfa_function_specifier
2064 { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
2065 | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')'
2066 {
2067 // Append the return type at the start (left-hand-side) to each identifier in the list.
2068 DeclarationNode * ret = new DeclarationNode;
2069 ret->type = maybeCopy( $1->type->base );
2070 $$ = $1->set_last( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
2071 }
2072 ;
2073
2074cfa_function_specifier: // CFA
2075 '[' ']' identifier '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2076 { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2077 | '[' ']' TYPEDEFname '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2078 { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2079 // | '[' ']' TYPEGENname '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2080 // { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2081
2082 // identifier_or_type_name must be broken apart because of the sequence:
2083 //
2084 // '[' ']' identifier_or_type_name '(' cfa_parameter_list_ellipsis_opt ')'
2085 // '[' ']' type_specifier
2086 //
2087 // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
2088 // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
2089 | cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2090 // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
2091 { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
2092 | cfa_function_return identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2093 { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
2094 ;
2095
2096cfa_function_return: // CFA
2097 '[' push cfa_parameter_list pop ']'
2098 { $$ = DeclarationNode::newTuple( $3 ); }
2099 | '[' push cfa_parameter_list ',' cfa_abstract_parameter_list pop ']'
2100 // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
2101 { $$ = DeclarationNode::newTuple( $3->set_last( $5 ) ); }
2102 ;
2103
2104cfa_typedef_declaration: // CFA
2105 TYPEDEF cfa_variable_specifier
2106 {
2107 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "cfa_typedef_declaration 1" );
2108 $$ = $2->addTypedef();
2109 }
2110 | TYPEDEF cfa_function_specifier
2111 {
2112 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "cfa_typedef_declaration 2" );
2113 $$ = $2->addTypedef();
2114 }
2115 | cfa_typedef_declaration ',' identifier
2116 {
2117 typedefTable.addToEnclosingScope( *$3, TYPEDEFname, "cfa_typedef_declaration 3" );
2118 $$ = $1->set_last( $1->cloneType( $3 ) );
2119 }
2120 ;
2121
2122// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
2123// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
2124
2125typedef_declaration:
2126 TYPEDEF type_specifier declarator
2127 {
2128 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "typedef_declaration 1" );
2129 if ( $2->type->forall || ($2->type->kind == TypeData::Aggregate && $2->type->aggregate.params) ) {
2130 SemanticError( yylloc, "forall qualifier in typedef is currently unimplemented." ); $$ = nullptr;
2131 } else $$ = $3->addType( $2 )->addTypedef(); // watchout frees $2 and $3
2132 }
2133 | typedef_declaration ',' declarator
2134 {
2135 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "typedef_declaration 2" );
2136 $$ = $1->set_last( $1->cloneBaseType( $3 )->addTypedef() );
2137 }
2138 | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
2139 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2140 | type_specifier TYPEDEF declarator
2141 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2142 | type_specifier TYPEDEF type_qualifier_list declarator
2143 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2144 ;
2145
2146typedef_expression:
2147 // deprecated GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
2148 TYPEDEF identifier '=' assignment_expression
2149 {
2150 SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
2151 }
2152 | typedef_expression ',' identifier '=' assignment_expression
2153 {
2154 SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
2155 }
2156 ;
2157
2158c_declaration:
2159 declaration_specifier declaring_list
2160 { $$ = distAttr( $1, $2 ); }
2161 | typedef_declaration
2162 | typedef_expression // deprecated GCC, naming expression type
2163 | sue_declaration_specifier
2164 {
2165 assert( $1->type );
2166 if ( $1->type->qualifiers.any() ) { // CV qualifiers ?
2167 SemanticError( yylloc, "illegal syntax, useless type qualifier(s) in empty declaration." ); $$ = nullptr;
2168 }
2169 // enums are never empty declarations because there must have at least one enumeration.
2170 if ( $1->type->kind == TypeData::AggregateInst && $1->storageClasses.any() ) { // storage class ?
2171 SemanticError( yylloc, "illegal syntax, useless storage qualifier(s) in empty aggregate declaration." ); $$ = nullptr;
2172 }
2173 }
2174 ;
2175
2176declaring_list:
2177 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
2178 // storage-class
2179 variable_declarator asm_name_opt initializer_opt
2180 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2181 | variable_type_redeclarator asm_name_opt initializer_opt
2182 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2183
2184 | general_function_declarator asm_name_opt
2185 { $$ = $1->addAsmName( $2 )->addInitializer( nullptr ); }
2186 | general_function_declarator asm_name_opt '=' VOID
2187 { $$ = $1->addAsmName( $2 )->addInitializer( new InitializerNode( true ) ); }
2188
2189 | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
2190 { $$ = $1->set_last( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
2191 ;
2192
2193general_function_declarator:
2194 function_type_redeclarator
2195 | function_declarator
2196 ;
2197
2198declaration_specifier: // type specifier + storage class
2199 basic_declaration_specifier
2200 | type_declaration_specifier
2201 | sue_declaration_specifier
2202 | sue_declaration_specifier invalid_types // invalid syntax rule
2203 {
2204 SemanticError( yylloc, "illegal syntax, expecting ';' at end of \"%s\" declaration.",
2205 ast::AggregateDecl::aggrString( $1->type->aggregate.kind ) );
2206 $$ = nullptr;
2207 }
2208 ;
2209
2210invalid_types:
2211 aggregate_key
2212 | basic_type_name
2213 | indirect_type
2214 ;
2215
2216declaration_specifier_nobody: // type specifier + storage class - {...}
2217 // Preclude SUE declarations in restricted scopes:
2218 //
2219 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2220 //
2221 // because it is impossible to call f due to name equivalence.
2222 basic_declaration_specifier
2223 | sue_declaration_specifier_nobody
2224 | type_declaration_specifier
2225 ;
2226
2227type_specifier: // type specifier
2228 basic_type_specifier
2229 | sue_type_specifier
2230 | type_type_specifier
2231 ;
2232
2233type_specifier_nobody: // type specifier - {...}
2234 // Preclude SUE declarations in restricted scopes:
2235 //
2236 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2237 //
2238 // because it is impossible to call f due to name equivalence.
2239 basic_type_specifier
2240 | sue_type_specifier_nobody
2241 | type_type_specifier
2242 ;
2243
2244type_qualifier_list_opt: // GCC, used in asm_statement
2245 // empty
2246 { $$ = nullptr; }
2247 | type_qualifier_list
2248 ;
2249
2250type_qualifier_list:
2251 // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
2252 //
2253 // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
2254 // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
2255 // appeared only once.
2256 type_qualifier
2257 | type_qualifier_list type_qualifier
2258 { $$ = $1->addQualifiers( $2 ); }
2259 ;
2260
2261type_qualifier:
2262 type_qualifier_name
2263 { $$ = DeclarationNode::newFromTypeData( $1 ); }
2264 | attribute // trick handles most attribute locations
2265 ;
2266
2267type_qualifier_name:
2268 CONST
2269 { $$ = build_type_qualifier( ast::CV::Const ); }
2270 | RESTRICT
2271 { $$ = build_type_qualifier( ast::CV::Restrict ); }
2272 | VOLATILE
2273 { $$ = build_type_qualifier( ast::CV::Volatile ); }
2274 | ATOMIC
2275 { $$ = build_type_qualifier( ast::CV::Atomic ); }
2276
2277 // forall is a CV qualifier because it can appear in places where SC qualifiers are disallowed.
2278 //
2279 // void foo( forall( T ) T (*)( T ) ); // forward declaration
2280 // void bar( static int ); // static disallowed (gcc/CFA)
2281 | forall
2282 { $$ = build_forall( $1 ); }
2283 ;
2284
2285forall:
2286 FORALL '(' type_parameter_list ')' // CFA
2287 { $$ = $3; }
2288 ;
2289
2290declaration_qualifier_list:
2291 storage_class_list
2292 | type_qualifier_list storage_class_list // remaining OBSOLESCENT (see 2 )
2293 { $$ = $1->addQualifiers( $2 ); }
2294 | declaration_qualifier_list type_qualifier_list storage_class_list
2295 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2296 ;
2297
2298storage_class_list:
2299 // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
2300 // only one of each is specified, except for inline, which can appear with the others.
2301 //
2302 // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
2303 // specifiers in a declaration.
2304 storage_class
2305 | storage_class_list storage_class
2306 { $$ = $1->addQualifiers( $2 ); }
2307 ;
2308
2309storage_class:
2310 EXTERN
2311 { $$ = DeclarationNode::newStorageClass( ast::Storage::Extern ); }
2312 | STATIC
2313 { $$ = DeclarationNode::newStorageClass( ast::Storage::Static ); }
2314 | AUTO
2315 { $$ = DeclarationNode::newStorageClass( ast::Storage::Auto ); }
2316 | REGISTER
2317 { $$ = DeclarationNode::newStorageClass( ast::Storage::Register ); }
2318 | THREADLOCALGCC // GCC
2319 { $$ = DeclarationNode::newStorageClass( ast::Storage::ThreadLocalGcc ); }
2320 | THREADLOCALC11 // C11
2321 { $$ = DeclarationNode::newStorageClass( ast::Storage::ThreadLocalC11 ); }
2322 // Put function specifiers here to simplify parsing rules, but separate them semantically.
2323 | INLINE // C99
2324 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Inline ); }
2325 | FORTRAN // C99
2326 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Fortran ); }
2327 | NORETURN // C11
2328 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Noreturn ); }
2329 ;
2330
2331basic_type_name:
2332 basic_type_name_type
2333 { $$ = DeclarationNode::newFromTypeData( $1 ); }
2334 ;
2335
2336// Just an intermediate value for conversion.
2337basic_type_name_type:
2338 VOID
2339 { $$ = build_basic_type( TypeData::Void ); }
2340 | BOOL // C99
2341 { $$ = build_basic_type( TypeData::Bool ); }
2342 | CHAR
2343 { $$ = build_basic_type( TypeData::Char ); }
2344 | INT
2345 { $$ = build_basic_type( TypeData::Int ); }
2346 | INT128
2347 { $$ = build_basic_type( TypeData::Int128 ); }
2348 | UINT128
2349 { $$ = addType( build_basic_type( TypeData::Int128 ), build_signedness( TypeData::Unsigned ) ); }
2350 | FLOAT
2351 { $$ = build_basic_type( TypeData::Float ); }
2352 | DOUBLE
2353 { $$ = build_basic_type( TypeData::Double ); }
2354 | uuFLOAT80
2355 { $$ = build_basic_type( TypeData::uuFloat80 ); }
2356 | uuFLOAT128
2357 { $$ = build_basic_type( TypeData::uuFloat128 ); }
2358 | uFLOAT16
2359 { $$ = build_basic_type( TypeData::uFloat16 ); }
2360 | uFLOAT32
2361 { $$ = build_basic_type( TypeData::uFloat32 ); }
2362 | uFLOAT32X
2363 { $$ = build_basic_type( TypeData::uFloat32x ); }
2364 | uFLOAT64
2365 { $$ = build_basic_type( TypeData::uFloat64 ); }
2366 | uFLOAT64X
2367 { $$ = build_basic_type( TypeData::uFloat64x ); }
2368 | uFLOAT128
2369 { $$ = build_basic_type( TypeData::uFloat128 ); }
2370 | DECIMAL32
2371 { SemanticError( yylloc, "_Decimal32 is currently unimplemented." ); $$ = nullptr; }
2372 | DECIMAL64
2373 { SemanticError( yylloc, "_Decimal64 is currently unimplemented." ); $$ = nullptr; }
2374 | DECIMAL128
2375 { SemanticError( yylloc, "_Decimal128 is currently unimplemented." ); $$ = nullptr; }
2376 | COMPLEX // C99
2377 { $$ = build_complex_type( TypeData::Complex ); }
2378 | IMAGINARY // C99
2379 { $$ = build_complex_type( TypeData::Imaginary ); }
2380 | SIGNED
2381 { $$ = build_signedness( TypeData::Signed ); }
2382 | UNSIGNED
2383 { $$ = build_signedness( TypeData::Unsigned ); }
2384 | SHORT
2385 { $$ = build_length( TypeData::Short ); }
2386 | LONG
2387 { $$ = build_length( TypeData::Long ); }
2388 | VA_LIST // GCC, __builtin_va_list
2389 { $$ = build_builtin_type( TypeData::Valist ); }
2390 | AUTO_TYPE
2391 { $$ = build_builtin_type( TypeData::AutoType ); }
2392 | vtable
2393 ;
2394
2395vtable_opt:
2396 // empty
2397 { $$ = nullptr; }
2398 | vtable
2399 ;
2400
2401vtable:
2402 VTABLE '(' type_name ')' default_opt
2403 { $$ = build_vtable_type( $3 ); }
2404 ;
2405
2406default_opt:
2407 // empty
2408 { $$ = nullptr; }
2409 | DEFAULT
2410 { SemanticError( yylloc, "vtable default is currently unimplemented." ); $$ = nullptr; }
2411 ;
2412
2413basic_declaration_specifier:
2414 // A semantic check is necessary for conflicting storage classes.
2415 basic_type_specifier
2416 | declaration_qualifier_list basic_type_specifier
2417 { $$ = $2->addQualifiers( $1 ); }
2418 | basic_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2419 { $$ = $1->addQualifiers( $2 ); }
2420 | basic_declaration_specifier storage_class type_qualifier_list
2421 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2422 | basic_declaration_specifier storage_class basic_type_specifier
2423 { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
2424 ;
2425
2426basic_type_specifier:
2427 direct_type
2428 // Cannot have type modifiers, e.g., short, long, etc.
2429 | type_qualifier_list_opt indirect_type type_qualifier_list_opt
2430 { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
2431 ;
2432
2433direct_type:
2434 basic_type_name
2435 | type_qualifier_list basic_type_name
2436 { $$ = $2->addQualifiers( $1 ); }
2437 | direct_type type_qualifier
2438 { $$ = $1->addQualifiers( $2 ); }
2439 | direct_type basic_type_name
2440 { $$ = $1->addType( $2 ); }
2441 ;
2442
2443indirect_type:
2444 TYPEOF '(' type ')' // GCC: typeof( x ) y;
2445 { $$ = $3; }
2446 | TYPEOF '(' comma_expression ')' // GCC: typeof( a+b ) y;
2447 { $$ = DeclarationNode::newTypeof( $3 ); }
2448 | BASETYPEOF '(' type ')' // CFA: basetypeof( x ) y;
2449 { $$ = DeclarationNode::newTypeof( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ), true ); }
2450 | BASETYPEOF '(' comma_expression ')' // CFA: basetypeof( a+b ) y;
2451 { $$ = DeclarationNode::newTypeof( $3, true ); }
2452 | ZERO_T // CFA
2453 { $$ = DeclarationNode::newFromTypeData( build_builtin_type( TypeData::Zero ) ); }
2454 | ONE_T // CFA
2455 { $$ = DeclarationNode::newFromTypeData( build_builtin_type( TypeData::One ) ); }
2456 ;
2457
2458sue_declaration_specifier: // struct, union, enum + storage class + type specifier
2459 sue_type_specifier
2460 | declaration_qualifier_list sue_type_specifier
2461 { $$ = $2->addQualifiers( $1 ); }
2462 | sue_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2463 { $$ = $1->addQualifiers( $2 ); }
2464 | sue_declaration_specifier storage_class type_qualifier_list
2465 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2466 ;
2467
2468sue_type_specifier: // struct, union, enum + type specifier
2469 elaborated_type
2470 | type_qualifier_list
2471 { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
2472 elaborated_type
2473 { $$ = $3->addQualifiers( $1 ); }
2474 | sue_type_specifier type_qualifier
2475 {
2476 if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
2477 $$ = $1->addQualifiers( $2 );
2478 }
2479 ;
2480
2481sue_declaration_specifier_nobody: // struct, union, enum - {...} + storage class + type specifier
2482 sue_type_specifier_nobody
2483 | declaration_qualifier_list sue_type_specifier_nobody
2484 { $$ = $2->addQualifiers( $1 ); }
2485 | sue_declaration_specifier_nobody storage_class // remaining OBSOLESCENT (see 2)
2486 { $$ = $1->addQualifiers( $2 ); }
2487 | sue_declaration_specifier_nobody storage_class type_qualifier_list
2488 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2489 ;
2490
2491sue_type_specifier_nobody: // struct, union, enum - {...} + type specifier
2492 elaborated_type_nobody
2493 | type_qualifier_list elaborated_type_nobody
2494 { $$ = $2->addQualifiers( $1 ); }
2495 | sue_type_specifier_nobody type_qualifier
2496 { $$ = $1->addQualifiers( $2 ); }
2497 ;
2498
2499type_declaration_specifier:
2500 type_type_specifier
2501 | declaration_qualifier_list type_type_specifier
2502 { $$ = $2->addQualifiers( $1 ); }
2503 | type_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2504 { $$ = $1->addQualifiers( $2 ); }
2505 | type_declaration_specifier storage_class type_qualifier_list
2506 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2507 ;
2508
2509type_type_specifier: // typedef types
2510 type_name
2511 { $$ = DeclarationNode::newFromTypeData( $1 ); }
2512 | type_qualifier_list type_name
2513 { $$ = DeclarationNode::newFromTypeData( $2 )->addQualifiers( $1 ); }
2514 | type_type_specifier type_qualifier
2515 { $$ = $1->addQualifiers( $2 ); }
2516 ;
2517
2518type_name:
2519 TYPEDEFname
2520 { $$ = build_typedef( $1 ); }
2521 | '.' TYPEDEFname
2522 { $$ = build_qualified_type( build_global_scope(), build_typedef( $2 ) ); }
2523 | type_name '.' TYPEDEFname
2524 { $$ = build_qualified_type( $1, build_typedef( $3 ) ); }
2525 | typegen_name
2526 | '.' typegen_name
2527 { $$ = build_qualified_type( build_global_scope(), $2 ); }
2528 | type_name '.' typegen_name
2529 { $$ = build_qualified_type( $1, $3 ); }
2530 ;
2531
2532typegen_name: // CFA
2533 TYPEGENname
2534 { $$ = build_type_gen( $1, nullptr ); }
2535 | TYPEGENname '(' ')'
2536 { $$ = build_type_gen( $1, nullptr ); }
2537 | TYPEGENname '(' type_list ')'
2538 { $$ = build_type_gen( $1, $3 ); }
2539 ;
2540
2541elaborated_type: // struct, union, enum
2542 aggregate_type
2543 | enum_type
2544 ;
2545
2546elaborated_type_nobody: // struct, union, enum - {...}
2547 aggregate_type_nobody
2548 | enum_type_nobody
2549 ;
2550
2551// ************************** AGGREGATE *******************************
2552
2553aggregate_type: // struct, union
2554 aggregate_key attribute_list_opt
2555 { forall = false; } // reset
2556 '{' field_declaration_list_opt '}' type_parameters_opt
2557 { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2558 | aggregate_key attribute_list_opt identifier
2559 {
2560 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 1" );
2561 forall = false; // reset
2562 }
2563 '{' field_declaration_list_opt '}' type_parameters_opt
2564 {
2565 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2566 }
2567 | aggregate_key attribute_list_opt TYPEDEFname // unqualified type name
2568 {
2569 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 2" );
2570 forall = false; // reset
2571 }
2572 '{' field_declaration_list_opt '}' type_parameters_opt
2573 {
2574 DeclarationNode::newFromTypeData( build_typedef( $3 ) );
2575 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2576 }
2577 | aggregate_key attribute_list_opt TYPEGENname // unqualified type name
2578 {
2579 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 3" );
2580 forall = false; // reset
2581 }
2582 '{' field_declaration_list_opt '}' type_parameters_opt
2583 {
2584 DeclarationNode::newFromTypeData( build_type_gen( $3, nullptr ) );
2585 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2586 }
2587 | aggregate_type_nobody
2588 ;
2589
2590type_parameters_opt:
2591 // empty
2592 { $$ = nullptr; } %prec '}'
2593 | '(' type_list ')'
2594 { $$ = $2; }
2595 ;
2596
2597aggregate_type_nobody: // struct, union - {...}
2598 aggregate_key attribute_list_opt identifier
2599 {
2600 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type_nobody" );
2601 forall = false; // reset
2602 $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2603 }
2604 | aggregate_key attribute_list_opt type_name
2605 {
2606 forall = false; // reset
2607 // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2608 // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2609 // delete newFromTypeGen.
2610 if ( $3->kind == TypeData::SymbolicInst && ! $3->symbolic.isTypedef ) {
2611 $$ = DeclarationNode::newFromTypeData( $3 )->addQualifiers( $2 );
2612 } else {
2613 $$ = DeclarationNode::newAggregate( $1, $3->symbolic.name, $3->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2614 $3->symbolic.name = nullptr; // copied to $$
2615 $3->symbolic.actuals = nullptr;
2616 delete $3;
2617 }
2618 }
2619 ;
2620
2621aggregate_key:
2622 aggregate_data
2623 | aggregate_control
2624 ;
2625
2626aggregate_data:
2627 STRUCT vtable_opt
2628 { $$ = ast::AggregateDecl::Struct; }
2629 | UNION
2630 { $$ = ast::AggregateDecl::Union; }
2631 | EXCEPTION // CFA
2632 { $$ = ast::AggregateDecl::Exception; }
2633 ;
2634
2635aggregate_control: // CFA
2636 MONITOR
2637 { $$ = ast::AggregateDecl::Monitor; }
2638 | MUTEX STRUCT
2639 { $$ = ast::AggregateDecl::Monitor; }
2640 | GENERATOR
2641 { $$ = ast::AggregateDecl::Generator; }
2642 | MUTEX GENERATOR
2643 {
2644 SemanticError( yylloc, "monitor generator is currently unimplemented." );
2645 $$ = ast::AggregateDecl::NoAggregate;
2646 }
2647 | COROUTINE
2648 { $$ = ast::AggregateDecl::Coroutine; }
2649 | MUTEX COROUTINE
2650 {
2651 SemanticError( yylloc, "monitor coroutine is currently unimplemented." );
2652 $$ = ast::AggregateDecl::NoAggregate;
2653 }
2654 | THREAD
2655 { $$ = ast::AggregateDecl::Thread; }
2656 | MUTEX THREAD
2657 {
2658 SemanticError( yylloc, "monitor thread is currently unimplemented." );
2659 $$ = ast::AggregateDecl::NoAggregate;
2660 }
2661 ;
2662
2663field_declaration_list_opt:
2664 // empty
2665 { $$ = nullptr; }
2666 | field_declaration_list_opt field_declaration
2667 { $$ = $1 ? $1->set_last( $2 ) : $2; }
2668 ;
2669
2670field_declaration:
2671 type_specifier field_declaring_list_opt ';'
2672 {
2673 // printf( "type_specifier1 %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2674 $$ = fieldDecl( $1, $2 );
2675 // printf( "type_specifier2 %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2676 // for ( Attribute * attr: reverseIterate( $$->attributes ) ) {
2677 // printf( "\tattr %s\n", attr->name.c_str() );
2678 // } // for
2679 }
2680 | type_specifier field_declaring_list_opt '}' // invalid syntax rule
2681 {
2682 SemanticError( yylloc, "illegal syntax, expecting ';' at end of previous declaration." );
2683 $$ = nullptr;
2684 }
2685 | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2686 { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2687 | STATIC type_specifier field_declaring_list_opt ';' // CFA
2688 { SemanticError( yylloc, "STATIC aggregate field qualifier currently unimplemented." ); $$ = nullptr; }
2689 | INLINE type_specifier field_abstract_list_opt ';' // CFA
2690 {
2691 if ( ! $3 ) { // field declarator ?
2692 $3 = DeclarationNode::newName( nullptr );
2693 } // if
2694 $3->inLine = true;
2695 $$ = distAttr( $2, $3 ); // mark all fields in list
2696 distInl( $3 );
2697 }
2698 | INLINE aggregate_control ';' // CFA
2699 { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2700 | typedef_declaration ';' // CFA
2701 | cfa_field_declaring_list ';' // CFA, new style field declaration
2702 | EXTENSION cfa_field_declaring_list ';' // GCC
2703 { distExt( $2 ); $$ = $2; } // mark all fields in list
2704 | INLINE cfa_field_abstract_list ';' // CFA, new style field declaration
2705 { $$ = $2; } // mark all fields in list
2706 | cfa_typedef_declaration ';' // CFA
2707 | static_assert // C11
2708 ;
2709
2710field_declaring_list_opt:
2711 // empty
2712 { $$ = nullptr; }
2713 | field_declarator
2714 | field_declaring_list_opt ',' attribute_list_opt field_declarator
2715 { $$ = $1->set_last( $4->addQualifiers( $3 ) ); }
2716 ;
2717
2718field_declarator:
2719 bit_subrange_size // C special case, no field name
2720 { $$ = DeclarationNode::newBitfield( $1 ); }
2721 | variable_declarator bit_subrange_size_opt
2722 // A semantic check is required to ensure bit_subrange only appears on integral types.
2723 { $$ = $1->addBitfield( $2 ); }
2724 | variable_type_redeclarator bit_subrange_size_opt
2725 // A semantic check is required to ensure bit_subrange only appears on integral types.
2726 { $$ = $1->addBitfield( $2 ); }
2727 | function_type_redeclarator bit_subrange_size_opt
2728 // A semantic check is required to ensure bit_subrange only appears on integral types.
2729 { $$ = $1->addBitfield( $2 ); }
2730 ;
2731
2732field_abstract_list_opt:
2733 // empty
2734 { $$ = nullptr; }
2735 | field_abstract
2736 | field_abstract_list_opt ',' attribute_list_opt field_abstract
2737 { $$ = $1->set_last( $4->addQualifiers( $3 ) ); }
2738 ;
2739
2740field_abstract:
2741 // no bit fields
2742 variable_abstract_declarator
2743 ;
2744
2745cfa_field_declaring_list: // CFA, new style field declaration
2746 // bit-fields are handled by C declarations
2747 cfa_abstract_declarator_tuple identifier_or_type_name
2748 { $$ = $1->addName( $2 ); }
2749 | cfa_field_declaring_list ',' identifier_or_type_name
2750 { $$ = $1->set_last( $1->cloneType( $3 ) ); }
2751 ;
2752
2753cfa_field_abstract_list: // CFA, new style field declaration
2754 // bit-fields are handled by C declarations
2755 cfa_abstract_declarator_tuple
2756 | cfa_field_abstract_list ','
2757 { $$ = $1->set_last( $1->cloneType( 0 ) ); }
2758 ;
2759
2760bit_subrange_size_opt:
2761 // empty
2762 { $$ = nullptr; }
2763 | bit_subrange_size
2764 ;
2765
2766bit_subrange_size:
2767 ':' assignment_expression
2768 { $$ = $2; }
2769 ;
2770
2771// ************************** ENUMERATION *******************************
2772
2773enum_type:
2774 // anonymous, no type name
2775 ENUM attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2776 {
2777 if ( $3 == EnumHiding::Hide ) {
2778 SemanticError( yylloc, "illegal syntax, hiding ('!') the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr;
2779 } // if
2780 $$ = DeclarationNode::newEnum( nullptr, $5, true, false )->addQualifiers( $2 );
2781 }
2782 | ENUM enumerator_type attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2783 {
2784 if ( $2 && ($2->storageClasses.val != 0 || $2->type->qualifiers.any()) ) {
2785 SemanticError( yylloc, "illegal syntax, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2786 }
2787 if ( $4 == EnumHiding::Hide ) {
2788 SemanticError( yylloc, "illegal syntax, hiding ('!') the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr;
2789 } // if
2790 $$ = DeclarationNode::newEnum( nullptr, $6, true, true, $2 )->addQualifiers( $3 );
2791 }
2792
2793 // named type
2794 | ENUM attribute_list_opt identifier
2795 { typedefTable.makeTypedef( *$3, "enum_type 1" ); }
2796 hide_opt '{' enumerator_list comma_opt '}'
2797 { $$ = DeclarationNode::newEnum( $3, $7, true, false, nullptr, $5 )->addQualifiers( $2 ); }
2798 | ENUM attribute_list_opt typedef_name hide_opt '{' enumerator_list comma_opt '}' // unqualified type name
2799 { $$ = DeclarationNode::newEnum( $3->name, $6, true, false, nullptr, $4 )->addQualifiers( $2 ); }
2800 | ENUM enumerator_type attribute_list_opt identifier attribute_list_opt
2801 {
2802 if ( $2 && ($2->storageClasses.any() || $2->type->qualifiers.val != 0) ) {
2803 SemanticError( yylloc, "illegal syntax, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2804 }
2805 typedefTable.makeTypedef( *$4, "enum_type 2" );
2806 }
2807 hide_opt '{' enumerator_list comma_opt '}'
2808 { $$ = DeclarationNode::newEnum( $4, $9, true, true, $2, $7 )->addQualifiers( $3 )->addQualifiers( $5 ); }
2809 | ENUM enumerator_type attribute_list_opt typedef_name attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2810 { $$ = DeclarationNode::newEnum( $4->name, $8, true, true, $2, $6 )->addQualifiers( $3 )->addQualifiers( $5 ); }
2811
2812 // forward declaration
2813 | enum_type_nobody
2814 ;
2815
2816enumerator_type:
2817 '(' ')' // pure enumeration
2818 { $$ = nullptr; }
2819 | '(' cfa_abstract_parameter_declaration ')' // typed enumeration
2820 { $$ = $2; }
2821 ;
2822
2823hide_opt:
2824 // empty
2825 { $$ = EnumHiding::Visible; }
2826 | '!'
2827 { $$ = EnumHiding::Hide; }
2828 ;
2829
2830enum_type_nobody: // enum - {...}
2831 ENUM attribute_list_opt identifier
2832 {
2833 typedefTable.makeTypedef( *$3, "enum_type_nobody 1" );
2834 $$ = DeclarationNode::newEnum( $3, nullptr, false, false )->addQualifiers( $2 );
2835 }
2836 | ENUM attribute_list_opt type_name
2837 {
2838 typedefTable.makeTypedef( *$3->symbolic.name, "enum_type_nobody 2" );
2839 $$ = DeclarationNode::newEnum( $3->symbolic.name, nullptr, false, false )->addQualifiers( $2 );
2840 }
2841 ;
2842
2843enumerator_list:
2844 visible_hide_opt identifier_or_type_name enumerator_value_opt
2845 { $$ = DeclarationNode::newEnumValueGeneric( $2, $3 ); }
2846 | INLINE type_name
2847 {
2848 $$ = DeclarationNode::newEnumInLine( $2->symbolic.name );
2849 $2->symbolic.name = nullptr;
2850 delete $2;
2851 }
2852 | enumerator_list ',' visible_hide_opt identifier_or_type_name enumerator_value_opt
2853 { $$ = $1->set_last( DeclarationNode::newEnumValueGeneric( $4, $5 ) ); }
2854 | enumerator_list ',' INLINE type_name
2855 { $$ = $1->set_last( DeclarationNode::newEnumInLine( $4->symbolic.name ) ); }
2856 ;
2857
2858visible_hide_opt:
2859 hide_opt
2860 | '^'
2861 { $$ = EnumHiding::Visible; }
2862 ;
2863
2864enumerator_value_opt:
2865 // empty
2866 { $$ = nullptr; }
2867 | '=' constant_expression { $$ = new InitializerNode( $2 ); }
2868 | '=' '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $3, true ); }
2869 // | simple_assignment_operator initializer
2870 // { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2871 ;
2872
2873// ************************** FUNCTION PARAMETERS *******************************
2874
2875parameter_list_ellipsis_opt:
2876 // empty
2877 { $$ = nullptr; }
2878 | ELLIPSIS
2879 { $$ = nullptr; }
2880 | parameter_list
2881 | parameter_list ',' ELLIPSIS
2882 { $$ = $1->addVarArgs(); }
2883 ;
2884
2885parameter_list: // abstract + real
2886 parameter_declaration
2887 | abstract_parameter_declaration
2888 | parameter_list ',' parameter_declaration
2889 { $$ = $1->set_last( $3 ); }
2890 | parameter_list ',' abstract_parameter_declaration
2891 { $$ = $1->set_last( $3 ); }
2892 ;
2893
2894cfa_parameter_list_ellipsis_opt: // CFA, abstract + real
2895 // empty
2896 { $$ = DeclarationNode::newFromTypeData( build_basic_type( TypeData::Void ) ); }
2897 | ELLIPSIS
2898 { $$ = nullptr; }
2899 | cfa_parameter_list
2900 | cfa_abstract_parameter_list
2901 | cfa_parameter_list ',' cfa_abstract_parameter_list
2902 { $$ = $1->set_last( $3 ); }
2903 | cfa_parameter_list ',' ELLIPSIS
2904 { $$ = $1->addVarArgs(); }
2905 | cfa_abstract_parameter_list ',' ELLIPSIS
2906 { $$ = $1->addVarArgs(); }
2907 ;
2908
2909cfa_parameter_list: // CFA
2910 // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2911 // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2912 cfa_parameter_declaration
2913 | cfa_abstract_parameter_list ',' cfa_parameter_declaration
2914 { $$ = $1->set_last( $3 ); }
2915 | cfa_parameter_list ',' cfa_parameter_declaration
2916 { $$ = $1->set_last( $3 ); }
2917 | cfa_parameter_list ',' cfa_abstract_parameter_list ',' cfa_parameter_declaration
2918 { $$ = $1->set_last( $3 )->set_last( $5 ); }
2919 ;
2920
2921cfa_abstract_parameter_list: // CFA, new & old style abstract
2922 cfa_abstract_parameter_declaration
2923 | cfa_abstract_parameter_list ',' cfa_abstract_parameter_declaration
2924 { $$ = $1->set_last( $3 ); }
2925 ;
2926
2927// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2928// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2929
2930parameter_declaration:
2931 // No SUE declaration in parameter list.
2932 declaration_specifier_nobody identifier_parameter_declarator default_initializer_opt
2933 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2934 | declaration_specifier_nobody type_parameter_redeclarator default_initializer_opt
2935 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2936 ;
2937
2938abstract_parameter_declaration:
2939 declaration_specifier_nobody default_initializer_opt
2940 { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2941 | declaration_specifier_nobody abstract_parameter_declarator default_initializer_opt
2942 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2943 ;
2944
2945cfa_parameter_declaration: // CFA, new & old style parameter declaration
2946 parameter_declaration
2947 | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initializer_opt
2948 { $$ = $1->addName( $2 ); }
2949 | cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2950 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2951 { $$ = $1->addName( $2 ); }
2952 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2953 { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2954 | cfa_function_specifier // int f( "int fp()" );
2955 ;
2956
2957cfa_abstract_parameter_declaration: // CFA, new & old style parameter declaration
2958 abstract_parameter_declaration
2959 | cfa_identifier_parameter_declarator_no_tuple
2960 | cfa_abstract_tuple
2961 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2962 | type_qualifier_list cfa_abstract_tuple
2963 { $$ = $2->addQualifiers( $1 ); }
2964 | cfa_abstract_function // int f( "int ()" );
2965 ;
2966
2967// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2968// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2969// identifiers. The ANSI-style parameter-list can redefine a typedef name.
2970
2971identifier_list: // K&R-style parameter list => no types
2972 identifier
2973 { $$ = DeclarationNode::newName( $1 ); }
2974 | identifier_list ',' identifier
2975 { $$ = $1->set_last( DeclarationNode::newName( $3 ) ); }
2976 ;
2977
2978type_no_function: // sizeof, alignof, cast (constructor)
2979 cfa_abstract_declarator_tuple // CFA
2980 | type_specifier // cannot be type_specifier_nobody, e.g., (struct S {}){} is a thing
2981 | type_specifier abstract_declarator
2982 { $$ = $2->addType( $1 ); }
2983 ;
2984
2985type: // typeof, assertion
2986 type_no_function
2987 | cfa_abstract_function // CFA
2988 ;
2989
2990initializer_opt:
2991 // empty
2992 { $$ = nullptr; }
2993 | simple_assignment_operator initializer { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2994 | '=' VOID { $$ = new InitializerNode( true ); }
2995 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
2996 ;
2997
2998initializer:
2999 assignment_expression { $$ = new InitializerNode( $1 ); }
3000 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
3001 ;
3002
3003initializer_list_opt:
3004 // empty
3005 { $$ = nullptr; }
3006 | initializer
3007 | designation initializer { $$ = $2->set_designators( $1 ); }
3008 | initializer_list_opt ',' initializer { $$ = $1->set_last( $3 ); }
3009 | initializer_list_opt ',' designation initializer { $$ = $1->set_last( $4->set_designators( $3 ) ); }
3010 ;
3011
3012// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
3013// '=' to separator the designator from the initializer value, as in:
3014//
3015// int x[10] = { [1] = 3 };
3016//
3017// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment. To disambiguate this case, CFA
3018// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
3019// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
3020// shift/reduce conflicts
3021
3022designation:
3023 designator_list ':' // C99, CFA uses ":" instead of "="
3024 | identifier_at ':' // GCC, field name
3025 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
3026 ;
3027
3028designator_list: // C99
3029 designator
3030 | designator_list designator
3031 { $$ = $1->set_last( $2 ); }
3032 //| designator_list designator { $$ = new ExpressionNode( $1, $2 ); }
3033 ;
3034
3035designator:
3036 '.' identifier_at // C99, field name
3037 { $$ = new ExpressionNode( build_varref( yylloc, $2 ) ); }
3038 | '[' push assignment_expression pop ']' // C99, single array element
3039 // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
3040 { $$ = $3; }
3041 | '[' push subrange pop ']' // CFA, multiple array elements
3042 { $$ = $3; }
3043 | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
3044 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $3 ), maybeMoveBuild( $5 ) ) ); }
3045 | '.' '[' push field_name_list pop ']' // CFA, tuple field selector
3046 { $$ = $4; }
3047 ;
3048
3049// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
3050// rather than an object-oriented type system. This required four groups of extensions:
3051//
3052// Overloading: function, data, and operator identifiers may be overloaded.
3053//
3054// Type declarations: "otype" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
3055// and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
3056// definitions of new types. Type declarations with storage class "extern" provide opaque types.
3057//
3058// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
3059// site. A polymorphic function is not a template; it is a function, with an address and a type.
3060//
3061// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
3062// types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
3063// hierarchies. Unlike classes, they can define relationships between types. Assertions declare that a type or
3064// types provide the operations declared by a specification. Assertions are normally used to declare requirements
3065// on type arguments of polymorphic functions.
3066
3067type_parameter_list: // CFA
3068 type_parameter
3069 | type_parameter_list ',' type_parameter
3070 { $$ = $1->set_last( $3 ); }
3071 ;
3072
3073type_initializer_opt: // CFA
3074 // empty
3075 { $$ = nullptr; }
3076 | '=' type
3077 { $$ = $2; }
3078 ;
3079
3080type_parameter: // CFA
3081 type_class identifier_or_type_name
3082 {
3083 typedefTable.addToScope( *$2, TYPEDEFname, "type_parameter 1" );
3084 if ( $1 == ast::TypeDecl::Otype ) { SemanticError( yylloc, "otype keyword is deprecated, use T " ); }
3085 if ( $1 == ast::TypeDecl::Dtype ) { SemanticError( yylloc, "dtype keyword is deprecated, use T &" ); }
3086 if ( $1 == ast::TypeDecl::Ttype ) { SemanticError( yylloc, "ttype keyword is deprecated, use T ..." ); }
3087 }
3088 type_initializer_opt assertion_list_opt
3089 { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
3090 | identifier_or_type_name new_type_class
3091 { typedefTable.addToScope( *$1, TYPEDEFname, "type_parameter 2" ); }
3092 type_initializer_opt assertion_list_opt
3093 { $$ = DeclarationNode::newTypeParam( $2, $1 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
3094 | '[' identifier_or_type_name ']'
3095 {
3096 typedefTable.addToScope( *$2, TYPEDIMname, "type_parameter 3" );
3097 $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dimension, $2 );
3098 }
3099 // | type_specifier identifier_parameter_declarator
3100 | assertion_list
3101 { $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
3102 | ENUM '(' identifier_or_type_name ')' identifier_or_type_name new_type_class type_initializer_opt assertion_list_opt
3103 {
3104 typedefTable.addToScope( *$3, TYPEDIMname, "type_parameter 4" );
3105 typedefTable.addToScope( *$5, TYPEDIMname, "type_parameter 5" );
3106 $$ = DeclarationNode::newTypeParam( $6, $5 )->addTypeInitializer( $7 )->addAssertions( $8 );
3107 }
3108 ;
3109
3110new_type_class: // CFA
3111 // empty
3112 { $$ = ast::TypeDecl::Otype; }
3113 | '&'
3114 { $$ = ast::TypeDecl::Dtype; }
3115 | '*'
3116 { $$ = ast::TypeDecl::DStype; } // Dtype + sized
3117 // | '(' '*' ')' // Gregor made me do it
3118 // { $$ = ast::TypeDecl::Ftype; }
3119 | ELLIPSIS
3120 { $$ = ast::TypeDecl::Ttype; }
3121 ;
3122
3123type_class: // CFA
3124 OTYPE
3125 { $$ = ast::TypeDecl::Otype; }
3126 | DTYPE
3127 { $$ = ast::TypeDecl::Dtype; }
3128 | FTYPE
3129 { $$ = ast::TypeDecl::Ftype; }
3130 | TTYPE
3131 { $$ = ast::TypeDecl::Ttype; }
3132 ;
3133
3134assertion_list_opt: // CFA
3135 // empty
3136 { $$ = nullptr; }
3137 | assertion_list
3138 ;
3139
3140assertion_list: // CFA
3141 assertion
3142 | assertion_list assertion
3143 { $$ = $1->set_last( $2 ); }
3144 ;
3145
3146assertion: // CFA
3147 '|' identifier_or_type_name '(' type_list ')'
3148 { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
3149 | '|' '{' push trait_declaration_list pop '}'
3150 { $$ = $4; }
3151 // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
3152 // { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
3153 ;
3154
3155type_list: // CFA
3156 type
3157 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3158 | assignment_expression
3159 | type_list ',' type
3160 { $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
3161 | type_list ',' assignment_expression
3162 { $$ = $1->set_last( $3 ); }
3163 ;
3164
3165type_declaring_list: // CFA
3166 OTYPE type_declarator
3167 { $$ = $2; }
3168 | storage_class_list OTYPE type_declarator
3169 { $$ = $3->addQualifiers( $1 ); }
3170 | type_declaring_list ',' type_declarator
3171 { $$ = $1->set_last( $3->copySpecifiers( $1 ) ); }
3172 ;
3173
3174type_declarator: // CFA
3175 type_declarator_name assertion_list_opt
3176 { $$ = $1->addAssertions( $2 ); }
3177 | type_declarator_name assertion_list_opt '=' type
3178 { $$ = $1->addAssertions( $2 )->addType( $4 ); }
3179 ;
3180
3181type_declarator_name: // CFA
3182 identifier_or_type_name
3183 {
3184 typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "type_declarator_name 1" );
3185 $$ = DeclarationNode::newTypeDecl( $1, nullptr );
3186 }
3187 | identifier_or_type_name '(' type_parameter_list ')'
3188 {
3189 typedefTable.addToEnclosingScope( *$1, TYPEGENname, "type_declarator_name 2" );
3190 $$ = DeclarationNode::newTypeDecl( $1, $3 );
3191 }
3192 ;
3193
3194trait_specifier: // CFA
3195 TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
3196 {
3197 SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3198 $$ = DeclarationNode::newTrait( $2, $4, nullptr );
3199 }
3200 | forall TRAIT identifier_or_type_name '{' '}' // alternate
3201 { $$ = DeclarationNode::newTrait( $3, $1, nullptr ); }
3202 | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
3203 {
3204 SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3205 $$ = DeclarationNode::newTrait( $2, $4, $8 );
3206 }
3207 | forall TRAIT identifier_or_type_name '{' push trait_declaration_list pop '}' // alternate
3208 { $$ = DeclarationNode::newTrait( $3, $1, $6 ); }
3209 ;
3210
3211trait_declaration_list: // CFA
3212 trait_declaration
3213 | trait_declaration_list pop push trait_declaration
3214 { $$ = $1->set_last( $4 ); }
3215 ;
3216
3217trait_declaration: // CFA
3218 cfa_trait_declaring_list ';'
3219 | trait_declaring_list ';'
3220 ;
3221
3222cfa_trait_declaring_list: // CFA
3223 cfa_variable_specifier
3224 | cfa_function_specifier
3225 | cfa_trait_declaring_list pop ',' push identifier_or_type_name
3226 { $$ = $1->set_last( $1->cloneType( $5 ) ); }
3227 ;
3228
3229trait_declaring_list: // CFA
3230 type_specifier declarator
3231 { $$ = $2->addType( $1 ); }
3232 | trait_declaring_list pop ',' push declarator
3233 { $$ = $1->set_last( $1->cloneBaseType( $5 ) ); }
3234 ;
3235
3236// **************************** EXTERNAL DEFINITIONS *****************************
3237
3238translation_unit:
3239 // empty, input file
3240 | external_definition_list
3241 { parseTree = parseTree ? parseTree->set_last( $1 ) : $1; }
3242 ;
3243
3244external_definition_list:
3245 push external_definition pop
3246 { $$ = $2; }
3247 | external_definition_list push external_definition pop
3248 { $$ = $1 ? $1->set_last( $3 ) : $3; }
3249 ;
3250
3251external_definition_list_opt:
3252 // empty
3253 { $$ = nullptr; }
3254 | external_definition_list
3255 ;
3256
3257up:
3258 { typedefTable.up( forall ); forall = false; }
3259 ;
3260
3261down:
3262 { typedefTable.down(); }
3263 ;
3264
3265external_definition:
3266 DIRECTIVE
3267 { $$ = DeclarationNode::newDirectiveStmt( new StatementNode( build_directive( yylloc, $1 ) ) ); }
3268 | declaration
3269 {
3270 // Variable declarations of anonymous types requires creating a unique type-name across multiple translation
3271 // unit, which is a dubious task, especially because C uses name rather than structural typing; hence it is
3272 // disallowed at the moment.
3273 if ( $1->linkage == ast::Linkage::Cforall && ! $1->storageClasses.is_static &&
3274 $1->type && $1->type->kind == TypeData::AggregateInst ) {
3275 if ( $1->type->aggInst.aggregate->aggregate.anon ) {
3276 SemanticError( yylloc, "extern anonymous aggregate is currently unimplemented." ); $$ = nullptr;
3277 }
3278 }
3279 }
3280 | IDENTIFIER IDENTIFIER
3281 { IdentifierBeforeIdentifier( *$1.str, *$2.str, " declaration" ); $$ = nullptr; }
3282 | IDENTIFIER type_qualifier // invalid syntax rule
3283 { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
3284 | IDENTIFIER storage_class // invalid syntax rule
3285 { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
3286 | IDENTIFIER basic_type_name // invalid syntax rule
3287 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3288 | IDENTIFIER TYPEDEFname // invalid syntax rule
3289 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3290 | IDENTIFIER TYPEGENname // invalid syntax rule
3291 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3292 | external_function_definition
3293 | EXTENSION external_definition // GCC, multiple __extension__ allowed, meaning unknown
3294 {
3295 distExt( $2 ); // mark all fields in list
3296 $$ = $2;
3297 }
3298 | ASM '(' string_literal ')' ';' // GCC, global assembler statement
3299 { $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( yylloc, false, $3, nullptr ) ) ); }
3300 | EXTERN STRINGliteral
3301 {
3302 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
3303 linkage = ast::Linkage::update( yylloc, linkage, $2 );
3304 }
3305 up external_definition down
3306 {
3307 linkage = linkageStack.top();
3308 linkageStack.pop();
3309 $$ = $5;
3310 }
3311 | EXTERN STRINGliteral // C++-style linkage specifier
3312 {
3313 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
3314 linkage = ast::Linkage::update( yylloc, linkage, $2 );
3315 }
3316 '{' up external_definition_list_opt down '}'
3317 {
3318 linkage = linkageStack.top();
3319 linkageStack.pop();
3320 $$ = $6;
3321 }
3322 // global distribution
3323 | type_qualifier_list
3324 {
3325 if ( $1->type->qualifiers.any() ) {
3326 SemanticError( yylloc, "illegal syntax, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3327 }
3328 if ( $1->type->forall ) forall = true; // remember generic type
3329 }
3330 '{' up external_definition_list_opt down '}' // CFA, namespace
3331 {
3332 distQual( $5, $1 );
3333 forall = false;
3334 $$ = $5;
3335 }
3336 | declaration_qualifier_list
3337 {
3338 if ( $1->type && $1->type->qualifiers.any() ) {
3339 SemanticError( yylloc, "illegal syntax, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3340 }
3341 if ( $1->type && $1->type->forall ) forall = true; // remember generic type
3342 }
3343 '{' up external_definition_list_opt down '}' // CFA, namespace
3344 {
3345 distQual( $5, $1 );
3346 forall = false;
3347 $$ = $5;
3348 }
3349 | declaration_qualifier_list type_qualifier_list
3350 {
3351 if ( ($1->type && $1->type->qualifiers.any()) || ($2->type && $2->type->qualifiers.any()) ) {
3352 SemanticError( yylloc, "illegal syntax, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3353 }
3354 if ( ($1->type && $1->type->forall) || ($2->type && $2->type->forall) ) forall = true; // remember generic type
3355 }
3356 '{' up external_definition_list_opt down '}' // CFA, namespace
3357 {
3358 distQual( $6, $1->addQualifiers( $2 ) );
3359 forall = false;
3360 $$ = $6;
3361 }
3362 ;
3363
3364external_function_definition:
3365 function_definition
3366 // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
3367 // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
3368 // Parsing is possible because function_definition does not appear in the context of an expression (nested
3369 // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
3370 // declaration must still have a type_specifier. OBSOLESCENT (see 1)
3371 | function_declarator compound_statement
3372 { $$ = $1->addFunctionBody( $2 ); }
3373 | KR_function_declarator KR_parameter_list_opt compound_statement
3374 { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
3375 ;
3376
3377with_clause_opt:
3378 // empty
3379 { $$ = nullptr; forall = false; }
3380 | WITH '(' type_list ')' attribute_list_opt // support scoped enumeration
3381 {
3382 $$ = $3; forall = false;
3383 if ( $5 ) {
3384 SemanticError( yylloc, "illegal syntax, attributes cannot be associated with function body. Move attribute(s) before \"with\" clause." );
3385 $$ = nullptr;
3386 } // if
3387 }
3388 ;
3389
3390function_definition:
3391 cfa_function_declaration with_clause_opt compound_statement // CFA
3392 {
3393 // Add the function body to the last identifier in the function definition list, i.e., foo3:
3394 // [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
3395 $1->get_last()->addFunctionBody( $3, $2 );
3396 $$ = $1;
3397 }
3398 | declaration_specifier function_declarator with_clause_opt compound_statement
3399 {
3400 rebindForall( $1, $2 );
3401 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3402 }
3403 | declaration_specifier function_type_redeclarator with_clause_opt compound_statement
3404 {
3405 rebindForall( $1, $2 );
3406 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3407 }
3408 // handles default int return type, OBSOLESCENT (see 1)
3409 | type_qualifier_list function_declarator with_clause_opt compound_statement
3410 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3411 // handles default int return type, OBSOLESCENT (see 1)
3412 | declaration_qualifier_list function_declarator with_clause_opt compound_statement
3413 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3414 // handles default int return type, OBSOLESCENT (see 1)
3415 | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
3416 { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3417
3418 // Old-style K&R function definition, OBSOLESCENT (see 4)
3419 | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3420 {
3421 rebindForall( $1, $2 );
3422 $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
3423 }
3424 // handles default int return type, OBSOLESCENT (see 1)
3425 | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3426 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3427 // handles default int return type, OBSOLESCENT (see 1)
3428 | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3429 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3430 // handles default int return type, OBSOLESCENT (see 1)
3431 | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3432 { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3433 ;
3434
3435declarator:
3436 variable_declarator
3437 | variable_type_redeclarator
3438 | function_declarator
3439 | function_type_redeclarator
3440 ;
3441
3442subrange:
3443 constant_expression '~' constant_expression // CFA, integer subrange
3444 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
3445 ;
3446
3447// **************************** ASM *****************************
3448
3449asm_name_opt: // GCC
3450 // empty
3451 { $$ = nullptr; }
3452 | ASM '(' string_literal ')' attribute_list_opt
3453 {
3454 DeclarationNode * name = new DeclarationNode();
3455 name->asmName = maybeMoveBuild( $3 );
3456 $$ = name->addQualifiers( $5 );
3457 }
3458 ;
3459
3460// **************************** ATTRIBUTE *****************************
3461
3462attribute_list_opt: // GCC
3463 // empty
3464 { $$ = nullptr; }
3465 | attribute_list
3466 ;
3467
3468attribute_list: // GCC
3469 attribute
3470 | attribute_list attribute
3471 { $$ = $2->addQualifiers( $1 ); }
3472 ;
3473
3474attribute: // GCC
3475 ATTRIBUTE '(' '(' attribute_name_list ')' ')'
3476 { $$ = $4; }
3477 | ATTRIBUTE '(' attribute_name_list ')' // CFA
3478 { $$ = $3; }
3479 | ATTR '(' attribute_name_list ')' // CFA
3480 { $$ = $3; }
3481 ;
3482
3483attribute_name_list: // GCC
3484 attribute_name
3485 | attribute_name_list ',' attribute_name
3486 { $$ = $3->addQualifiers( $1 ); }
3487 ;
3488
3489attribute_name: // GCC
3490 // empty
3491 { $$ = nullptr; }
3492 | attr_name
3493 { $$ = DeclarationNode::newAttribute( $1 ); }
3494 | attr_name '(' argument_expression_list_opt ')'
3495 { $$ = DeclarationNode::newAttribute( $1, $3 ); }
3496 ;
3497
3498attr_name: // GCC
3499 identifier_or_type_name
3500 | FALLTHROUGH
3501 { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
3502 | CONST
3503 { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
3504 ;
3505
3506// ============================================================================
3507// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
3508// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
3509// in:
3510//
3511// int (*f())[10] { ... };
3512// ... (*f())[3] += 1; // definition mimics usage
3513//
3514// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
3515// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
3516// ============================================================================
3517
3518// ----------------------------------------------------------------------------
3519// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
3520// to define a variable or function prototype, e.g.:
3521//
3522// valid declaration invalid definition
3523// ----------------- ------------------
3524// int f; int f {}
3525// int *f; int *f {}
3526// int f[10]; int f[10] {}
3527// int (*f)(int); int (*f)(int) {}
3528//
3529// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
3530// variable_declarator and function_declarator.
3531// ----------------------------------------------------------------------------
3532
3533// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
3534// declaring an array of functions versus a pointer to an array of functions.
3535
3536paren_identifier:
3537 identifier_at
3538 { $$ = DeclarationNode::newName( $1 ); }
3539 | '(' paren_identifier ')' // redundant parenthesis
3540 { $$ = $2; }
3541 ;
3542
3543variable_declarator:
3544 paren_identifier attribute_list_opt
3545 { $$ = $1->addQualifiers( $2 ); }
3546 | variable_ptr
3547 | variable_array attribute_list_opt
3548 { $$ = $1->addQualifiers( $2 ); }
3549 | variable_function attribute_list_opt
3550 { $$ = $1->addQualifiers( $2 ); }
3551 ;
3552
3553variable_ptr:
3554 ptrref_operator variable_declarator
3555 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3556 | ptrref_operator type_qualifier_list variable_declarator
3557 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3558 | '(' variable_ptr ')' attribute_list_opt // redundant parenthesis
3559 { $$ = $2->addQualifiers( $4 ); }
3560 | '(' attribute_list variable_ptr ')' attribute_list_opt // redundant parenthesis
3561 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3562 ;
3563
3564variable_array:
3565 paren_identifier array_dimension
3566 { $$ = $1->addArray( $2 ); }
3567 | '(' variable_ptr ')' array_dimension
3568 { $$ = $2->addArray( $4 ); }
3569 | '(' attribute_list variable_ptr ')' array_dimension
3570 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3571 | '(' variable_array ')' multi_array_dimension // redundant parenthesis
3572 { $$ = $2->addArray( $4 ); }
3573 | '(' attribute_list variable_array ')' multi_array_dimension // redundant parenthesis
3574 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3575 | '(' variable_array ')' // redundant parenthesis
3576 { $$ = $2; }
3577 | '(' attribute_list variable_array ')' // redundant parenthesis
3578 { $$ = $3->addQualifiers( $2 ); }
3579 ;
3580
3581variable_function:
3582 '(' variable_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3583 { $$ = $2->addParamList( $5 ); }
3584 | '(' attribute_list variable_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3585 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3586 | '(' variable_function ')' // redundant parenthesis
3587 { $$ = $2; }
3588 | '(' attribute_list variable_function ')' // redundant parenthesis
3589 { $$ = $3->addQualifiers( $2 ); }
3590 ;
3591
3592// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
3593// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
3594// is the same scope. The pattern precludes returning arrays and functions versus pointers to arrays and functions.
3595
3596function_declarator:
3597 function_no_ptr attribute_list_opt
3598 { $$ = $1->addQualifiers( $2 ); }
3599 | function_ptr
3600 | function_array attribute_list_opt
3601 { $$ = $1->addQualifiers( $2 ); }
3602 ;
3603
3604function_no_ptr:
3605 paren_identifier '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3606 { $$ = $1->addParamList( $3 ); }
3607 | '(' function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3608 { $$ = $2->addParamList( $5 ); }
3609 | '(' attribute_list function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3610 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3611 | '(' function_no_ptr ')' // redundant parenthesis
3612 { $$ = $2; }
3613 | '(' attribute_list function_no_ptr ')' // redundant parenthesis
3614 { $$ = $3->addQualifiers( $2 ); }
3615 ;
3616
3617function_ptr:
3618 ptrref_operator function_declarator
3619 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3620 | ptrref_operator type_qualifier_list function_declarator
3621 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3622 | '(' function_ptr ')' attribute_list_opt
3623 { $$ = $2->addQualifiers( $4 ); }
3624 | '(' attribute_list function_ptr ')' attribute_list_opt
3625 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3626 ;
3627
3628function_array:
3629 '(' function_ptr ')' array_dimension
3630 { $$ = $2->addArray( $4 ); }
3631 | '(' attribute_list function_ptr ')' array_dimension
3632 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3633 | '(' function_array ')' multi_array_dimension // redundant parenthesis
3634 { $$ = $2->addArray( $4 ); }
3635 | '(' attribute_list function_array ')' multi_array_dimension // redundant parenthesis
3636 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3637 | '(' function_array ')' // redundant parenthesis
3638 { $$ = $2; }
3639 | '(' attribute_list function_array ')' // redundant parenthesis
3640 { $$ = $3->addQualifiers( $2 ); }
3641 ;
3642
3643// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
3644//
3645// f( a, b, c ) int a, *b, c[]; {}
3646//
3647// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
3648// returning arrays and functions versus pointers to arrays and functions.
3649
3650KR_function_declarator:
3651 KR_function_no_ptr
3652 | KR_function_ptr
3653 | KR_function_array
3654 ;
3655
3656KR_function_no_ptr:
3657 paren_identifier '(' identifier_list ')' // function_declarator handles empty parameter
3658 { $$ = $1->addIdList( $3 ); }
3659 | '(' KR_function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3660 { $$ = $2->addParamList( $5 ); }
3661 | '(' attribute_list KR_function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3662 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3663 | '(' KR_function_no_ptr ')' // redundant parenthesis
3664 { $$ = $2; }
3665 | '(' attribute_list KR_function_no_ptr ')' // redundant parenthesis
3666 { $$ = $3->addQualifiers( $2 ); }
3667 ;
3668
3669KR_function_ptr:
3670 ptrref_operator KR_function_declarator
3671 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3672 | ptrref_operator type_qualifier_list KR_function_declarator
3673 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3674 | '(' KR_function_ptr ')'
3675 { $$ = $2; }
3676 | '(' attribute_list KR_function_ptr ')'
3677 { $$ = $3->addQualifiers( $2 ); }
3678 ;
3679
3680KR_function_array:
3681 '(' KR_function_ptr ')' array_dimension
3682 { $$ = $2->addArray( $4 ); }
3683 | '(' attribute_list KR_function_ptr ')' array_dimension
3684 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3685 | '(' KR_function_array ')' multi_array_dimension // redundant parenthesis
3686 { $$ = $2->addArray( $4 ); }
3687 | '(' attribute_list KR_function_array ')' multi_array_dimension // redundant parenthesis
3688 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3689 | '(' KR_function_array ')' // redundant parenthesis
3690 { $$ = $2; }
3691 | '(' attribute_list KR_function_array ')' // redundant parenthesis
3692 { $$ = $3->addQualifiers( $2 ); }
3693 ;
3694
3695// This pattern parses a declaration for a variable that redefines a type name, e.g.:
3696//
3697// typedef int foo;
3698// {
3699// int foo; // redefine typedef name in new scope
3700// }
3701
3702paren_type:
3703 typedef_name
3704 {
3705 // hide type name in enclosing scope by variable name
3706 typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "paren_type" );
3707 }
3708 | '(' paren_type ')'
3709 { $$ = $2; }
3710 ;
3711
3712variable_type_redeclarator:
3713 paren_type attribute_list_opt
3714 { $$ = $1->addQualifiers( $2 ); }
3715 | variable_type_ptr
3716 | variable_type_array attribute_list_opt
3717 { $$ = $1->addQualifiers( $2 ); }
3718 | variable_type_function attribute_list_opt
3719 { $$ = $1->addQualifiers( $2 ); }
3720 ;
3721
3722variable_type_ptr:
3723 ptrref_operator variable_type_redeclarator
3724 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3725 | ptrref_operator type_qualifier_list variable_type_redeclarator
3726 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3727 | '(' variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3728 { $$ = $2->addQualifiers( $4 ); }
3729 | '(' attribute_list variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3730 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3731 ;
3732
3733variable_type_array:
3734 paren_type array_dimension
3735 { $$ = $1->addArray( $2 ); }
3736 | '(' variable_type_ptr ')' array_dimension
3737 { $$ = $2->addArray( $4 ); }
3738 | '(' attribute_list variable_type_ptr ')' array_dimension
3739 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3740 | '(' variable_type_array ')' multi_array_dimension // redundant parenthesis
3741 { $$ = $2->addArray( $4 ); }
3742 | '(' attribute_list variable_type_array ')' multi_array_dimension // redundant parenthesis
3743 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3744 | '(' variable_type_array ')' // redundant parenthesis
3745 { $$ = $2; }
3746 | '(' attribute_list variable_type_array ')' // redundant parenthesis
3747 { $$ = $3->addQualifiers( $2 ); }
3748 ;
3749
3750variable_type_function:
3751 '(' variable_type_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3752 { $$ = $2->addParamList( $5 ); }
3753 | '(' attribute_list variable_type_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3754 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3755 | '(' variable_type_function ')' // redundant parenthesis
3756 { $$ = $2; }
3757 | '(' attribute_list variable_type_function ')' // redundant parenthesis
3758 { $$ = $3->addQualifiers( $2 ); }
3759 ;
3760
3761// This pattern parses a declaration for a function prototype that redefines a type name. It precludes declaring an
3762// array of functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to
3763// arrays and functions.
3764
3765function_type_redeclarator:
3766 function_type_no_ptr attribute_list_opt
3767 { $$ = $1->addQualifiers( $2 ); }
3768 | function_type_ptr
3769 | function_type_array attribute_list_opt
3770 { $$ = $1->addQualifiers( $2 ); }
3771 ;
3772
3773function_type_no_ptr:
3774 paren_type '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3775 { $$ = $1->addParamList( $3 ); }
3776 | '(' function_type_ptr ')' '(' parameter_list_ellipsis_opt ')'
3777 { $$ = $2->addParamList( $5 ); }
3778 | '(' attribute_list function_type_ptr ')' '(' parameter_list_ellipsis_opt ')'
3779 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3780 | '(' function_type_no_ptr ')' // redundant parenthesis
3781 { $$ = $2; }
3782 | '(' attribute_list function_type_no_ptr ')' // redundant parenthesis
3783 { $$ = $3->addQualifiers( $2 ); }
3784 ;
3785
3786function_type_ptr:
3787 ptrref_operator function_type_redeclarator
3788 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3789 | ptrref_operator type_qualifier_list function_type_redeclarator
3790 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3791 | '(' function_type_ptr ')' attribute_list_opt
3792 { $$ = $2->addQualifiers( $4 ); }
3793 | '(' attribute_list function_type_ptr ')' attribute_list_opt
3794 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3795 ;
3796
3797function_type_array:
3798 '(' function_type_ptr ')' array_dimension
3799 { $$ = $2->addArray( $4 ); }
3800 | '(' attribute_list function_type_ptr ')' array_dimension
3801 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3802 | '(' function_type_array ')' multi_array_dimension // redundant parenthesis
3803 { $$ = $2->addArray( $4 ); }
3804 | '(' attribute_list function_type_array ')' multi_array_dimension // redundant parenthesis
3805 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3806 | '(' function_type_array ')' // redundant parenthesis
3807 { $$ = $2; }
3808 | '(' attribute_list function_type_array ')' // redundant parenthesis
3809 { $$ = $3->addQualifiers( $2 ); }
3810 ;
3811
3812// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
3813// typedef name and allows the C99 array options, which can only appear in a parameter list. The pattern precludes
3814// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
3815// pointers to arrays and functions.
3816
3817identifier_parameter_declarator:
3818 paren_identifier attribute_list_opt
3819 { $$ = $1->addQualifiers( $2 ); }
3820 | '&' MUTEX paren_identifier attribute_list_opt
3821 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
3822 OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3823 | identifier_parameter_ptr
3824 | identifier_parameter_array attribute_list_opt
3825 { $$ = $1->addQualifiers( $2 ); }
3826 | identifier_parameter_function attribute_list_opt
3827 { $$ = $1->addQualifiers( $2 ); }
3828 ;
3829
3830identifier_parameter_ptr:
3831 ptrref_operator identifier_parameter_declarator
3832 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3833 | ptrref_operator type_qualifier_list identifier_parameter_declarator
3834 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3835 | '(' identifier_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3836 { $$ = $2->addQualifiers( $4 ); }
3837 ;
3838
3839identifier_parameter_array:
3840 paren_identifier array_parameter_dimension
3841 { $$ = $1->addArray( $2 ); }
3842 | '(' identifier_parameter_ptr ')' array_dimension
3843 { $$ = $2->addArray( $4 ); }
3844 | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3845 { $$ = $2->addArray( $4 ); }
3846 | '(' identifier_parameter_array ')' // redundant parenthesis
3847 { $$ = $2; }
3848 ;
3849
3850identifier_parameter_function:
3851 paren_identifier '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3852 { $$ = $1->addParamList( $3 ); }
3853 | '(' identifier_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3854 { $$ = $2->addParamList( $5 ); }
3855 | '(' identifier_parameter_function ')' // redundant parenthesis
3856 { $$ = $2; }
3857 ;
3858
3859// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3860// e.g.:
3861//
3862// typedef int foo;
3863// forall( otype T ) struct foo;
3864// int f( int foo ); // redefine typedef name in new scope
3865//
3866// and allows the C99 array options, which can only appear in a parameter list.
3867
3868type_parameter_redeclarator:
3869 typedef_name attribute_list_opt
3870 { $$ = $1->addQualifiers( $2 ); }
3871 | '&' MUTEX typedef_name attribute_list_opt
3872 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
3873 OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3874 | type_parameter_ptr
3875 | type_parameter_array attribute_list_opt
3876 { $$ = $1->addQualifiers( $2 ); }
3877 | type_parameter_function attribute_list_opt
3878 { $$ = $1->addQualifiers( $2 ); }
3879 ;
3880
3881typedef_name:
3882 TYPEDEFname
3883 { $$ = DeclarationNode::newName( $1 ); }
3884 | TYPEGENname
3885 { $$ = DeclarationNode::newName( $1 ); }
3886 ;
3887
3888type_parameter_ptr:
3889 ptrref_operator type_parameter_redeclarator
3890 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3891 | ptrref_operator type_qualifier_list type_parameter_redeclarator
3892 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3893 | '(' type_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3894 { $$ = $2->addQualifiers( $4 ); }
3895 ;
3896
3897type_parameter_array:
3898 typedef_name array_parameter_dimension
3899 { $$ = $1->addArray( $2 ); }
3900 | '(' type_parameter_ptr ')' array_parameter_dimension
3901 { $$ = $2->addArray( $4 ); }
3902 ;
3903
3904type_parameter_function:
3905 typedef_name '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3906 { $$ = $1->addParamList( $3 ); }
3907 | '(' type_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3908 { $$ = $2->addParamList( $5 ); }
3909 ;
3910
3911// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3912// which the type applies, e.g.:
3913//
3914// sizeof( int );
3915// sizeof( int * );
3916// sizeof( int [10] );
3917// sizeof( int (*)() );
3918// sizeof( int () );
3919//
3920// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3921// and functions versus pointers to arrays and functions.
3922
3923abstract_declarator:
3924 abstract_ptr
3925 | abstract_array attribute_list_opt
3926 { $$ = $1->addQualifiers( $2 ); }
3927 | abstract_function attribute_list_opt
3928 { $$ = $1->addQualifiers( $2 ); }
3929 ;
3930
3931abstract_ptr:
3932 ptrref_operator
3933 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3934 | ptrref_operator type_qualifier_list
3935 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3936 | ptrref_operator abstract_declarator
3937 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3938 | ptrref_operator type_qualifier_list abstract_declarator
3939 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3940 | '(' abstract_ptr ')' attribute_list_opt
3941 { $$ = $2->addQualifiers( $4 ); }
3942 ;
3943
3944abstract_array:
3945 array_dimension
3946 | '(' abstract_ptr ')' array_dimension
3947 { $$ = $2->addArray( $4 ); }
3948 | '(' abstract_array ')' multi_array_dimension // redundant parenthesis
3949 { $$ = $2->addArray( $4 ); }
3950 | '(' abstract_array ')' // redundant parenthesis
3951 { $$ = $2; }
3952 ;
3953
3954abstract_function:
3955 '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3956 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
3957 | '(' abstract_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3958 { $$ = $2->addParamList( $5 ); }
3959 | '(' abstract_function ')' // redundant parenthesis
3960 { $$ = $2; }
3961 ;
3962
3963array_dimension:
3964 // Only the first dimension can be empty.
3965 '[' ']'
3966 { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
3967 | '[' ']' multi_array_dimension
3968 { $$ = DeclarationNode::newArray( nullptr, nullptr, false )->addArray( $3 ); }
3969 // Cannot use constant_expression because of tuples => semantic check
3970 | '[' push assignment_expression pop ',' comma_expression ']' // CFA
3971 { $$ = DeclarationNode::newArray( $3, nullptr, false )->addArray( DeclarationNode::newArray( $6, nullptr, false ) ); }
3972 // { SemanticError( yylloc, "New array dimension is currently unimplemented." ); $$ = nullptr; }
3973
3974 // If needed, the following parses and does not use comma_expression, so the array structure can be built.
3975 // | '[' push assignment_expression pop ',' push array_dimension_list pop ']' // CFA
3976
3977 | '[' push array_type_list pop ']' // CFA
3978 { $$ = DeclarationNode::newArray( $3, nullptr, false ); }
3979 | multi_array_dimension
3980 ;
3981
3982// array_dimension_list:
3983// assignment_expression
3984// | array_dimension_list ',' assignment_expression
3985// ;
3986
3987array_type_list:
3988 basic_type_name
3989 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3990 | type_name
3991 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3992 | assignment_expression upupeq assignment_expression
3993 | array_type_list ',' basic_type_name
3994 { $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
3995 | array_type_list ',' type_name
3996 { $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
3997 | array_type_list ',' assignment_expression upupeq assignment_expression
3998 ;
3999
4000upupeq:
4001 '~'
4002 { $$ = OperKinds::LThan; }
4003 | ErangeUpEq
4004 { $$ = OperKinds::LEThan; }
4005 ;
4006
4007multi_array_dimension:
4008 '[' push assignment_expression pop ']'
4009 { $$ = DeclarationNode::newArray( $3, nullptr, false ); }
4010 | '[' push '*' pop ']' // C99
4011 { $$ = DeclarationNode::newVarArray( 0 ); }
4012 | multi_array_dimension '[' push assignment_expression pop ']'
4013 { $$ = $1->addArray( DeclarationNode::newArray( $4, nullptr, false ) ); }
4014 | multi_array_dimension '[' push '*' pop ']' // C99
4015 { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
4016 ;
4017
4018// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
4019// identifier to which the type applies, e.g.:
4020//
4021// int f( int ); // not handled here
4022// int f( int * ); // abstract function-prototype parameter; no parameter name specified
4023// int f( int (*)() ); // abstract function-prototype parameter; no parameter name specified
4024// int f( int (int) ); // abstract function-prototype parameter; no parameter name specified
4025//
4026// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
4027// and functions versus pointers to arrays and functions. In addition, the pattern handles the special meaning of
4028// parenthesis around a typedef name:
4029//
4030// ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
4031// parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
4032// not as redundant parentheses around the identifier."
4033//
4034// For example:
4035//
4036// typedef float T;
4037// int f( int ( T [5] ) ); // see abstract_parameter_declarator
4038// int g( int ( T ( int ) ) ); // see abstract_parameter_declarator
4039// int f( int f1( T a[5] ) ); // see identifier_parameter_declarator
4040// int g( int g1( T g2( int p ) ) ); // see identifier_parameter_declarator
4041//
4042// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
4043// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
4044// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
4045// functions.
4046
4047abstract_parameter_declarator_opt:
4048 // empty
4049 { $$ = nullptr; }
4050 | abstract_parameter_declarator
4051 ;
4052
4053abstract_parameter_declarator:
4054 abstract_parameter_ptr
4055 | '&' MUTEX attribute_list_opt
4056 { $$ = DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
4057 OperKinds::AddressOf )->addQualifiers( $3 ); }
4058 | abstract_parameter_array attribute_list_opt
4059 { $$ = $1->addQualifiers( $2 ); }
4060 | abstract_parameter_function attribute_list_opt
4061 { $$ = $1->addQualifiers( $2 ); }
4062 ;
4063
4064abstract_parameter_ptr:
4065 ptrref_operator
4066 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
4067 | ptrref_operator type_qualifier_list
4068 { $$ = DeclarationNode::newPointer( $2, $1 ); }
4069 | ptrref_operator abstract_parameter_declarator
4070 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4071 | ptrref_operator type_qualifier_list abstract_parameter_declarator
4072 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4073 | '(' abstract_parameter_ptr ')' attribute_list_opt // redundant parenthesis
4074 { $$ = $2->addQualifiers( $4 ); }
4075 ;
4076
4077abstract_parameter_array:
4078 array_parameter_dimension
4079 | '(' abstract_parameter_ptr ')' array_parameter_dimension
4080 { $$ = $2->addArray( $4 ); }
4081 | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
4082 { $$ = $2->addArray( $4 ); }
4083 | '(' abstract_parameter_array ')' // redundant parenthesis
4084 { $$ = $2; }
4085 ;
4086
4087abstract_parameter_function:
4088 '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4089 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
4090 | '(' abstract_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4091 { $$ = $2->addParamList( $5 ); }
4092 | '(' abstract_parameter_function ')' // redundant parenthesis
4093 { $$ = $2; }
4094 ;
4095
4096array_parameter_dimension:
4097 // Only the first dimension can be empty or have qualifiers.
4098 array_parameter_1st_dimension
4099 | array_parameter_1st_dimension multi_array_dimension
4100 { $$ = $1->addArray( $2 ); }
4101 | multi_array_dimension
4102 ;
4103
4104// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
4105//
4106// ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
4107// a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
4108
4109array_parameter_1st_dimension:
4110 '[' ']'
4111 { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
4112 // multi_array_dimension handles the '[' '*' ']' case
4113 | '[' push type_qualifier_list '*' pop ']' // remaining C99
4114 { $$ = DeclarationNode::newVarArray( $3 ); }
4115 | '[' push type_qualifier_list pop ']'
4116 { $$ = DeclarationNode::newArray( nullptr, $3, false ); }
4117 // multi_array_dimension handles the '[' assignment_expression ']' case
4118 | '[' push type_qualifier_list assignment_expression pop ']'
4119 { $$ = DeclarationNode::newArray( $4, $3, false ); }
4120 | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
4121 { $$ = DeclarationNode::newArray( $5, $4, true ); }
4122 | '[' push type_qualifier_list STATIC assignment_expression pop ']'
4123 { $$ = DeclarationNode::newArray( $5, $3, true ); }
4124 ;
4125
4126// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
4127//
4128// struct S {
4129// int;
4130// int *;
4131// int [10];
4132// int (*)();
4133// };
4134
4135variable_abstract_declarator:
4136 variable_abstract_ptr
4137 | variable_abstract_array attribute_list_opt
4138 { $$ = $1->addQualifiers( $2 ); }
4139 | variable_abstract_function attribute_list_opt
4140 { $$ = $1->addQualifiers( $2 ); }
4141 ;
4142
4143variable_abstract_ptr:
4144 ptrref_operator
4145 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
4146 | ptrref_operator type_qualifier_list
4147 { $$ = DeclarationNode::newPointer( $2, $1 ); }
4148 | ptrref_operator variable_abstract_declarator
4149 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4150 | ptrref_operator type_qualifier_list variable_abstract_declarator
4151 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4152 | '(' variable_abstract_ptr ')' attribute_list_opt // redundant parenthesis
4153 { $$ = $2->addQualifiers( $4 ); }
4154 ;
4155
4156variable_abstract_array:
4157 array_dimension
4158 | '(' variable_abstract_ptr ')' array_dimension
4159 { $$ = $2->addArray( $4 ); }
4160 | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
4161 { $$ = $2->addArray( $4 ); }
4162 | '(' variable_abstract_array ')' // redundant parenthesis
4163 { $$ = $2; }
4164 ;
4165
4166variable_abstract_function:
4167 '(' variable_abstract_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4168 { $$ = $2->addParamList( $5 ); }
4169 | '(' variable_abstract_function ')' // redundant parenthesis
4170 { $$ = $2; }
4171 ;
4172
4173// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
4174// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
4175
4176cfa_identifier_parameter_declarator_tuple: // CFA
4177 cfa_identifier_parameter_declarator_no_tuple
4178 | cfa_abstract_tuple
4179 | type_qualifier_list cfa_abstract_tuple
4180 { $$ = $2->addQualifiers( $1 ); }
4181 ;
4182
4183cfa_identifier_parameter_declarator_no_tuple: // CFA
4184 cfa_identifier_parameter_ptr
4185 | cfa_identifier_parameter_array
4186 ;
4187
4188cfa_identifier_parameter_ptr: // CFA
4189 // No SUE declaration in parameter list.
4190 ptrref_operator type_specifier_nobody
4191 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4192 | type_qualifier_list ptrref_operator type_specifier_nobody
4193 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4194 | ptrref_operator cfa_abstract_function
4195 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4196 | type_qualifier_list ptrref_operator cfa_abstract_function
4197 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4198 | ptrref_operator cfa_identifier_parameter_declarator_tuple
4199 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4200 | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
4201 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4202 ;
4203
4204cfa_identifier_parameter_array: // CFA
4205 // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
4206 // shift/reduce conflict with new-style empty (void) function return type.
4207 '[' ']' type_specifier_nobody
4208 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4209 | cfa_array_parameter_1st_dimension type_specifier_nobody
4210 { $$ = $2->addNewArray( $1 ); }
4211 | '[' ']' multi_array_dimension type_specifier_nobody
4212 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4213 | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
4214 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4215 | multi_array_dimension type_specifier_nobody
4216 { $$ = $2->addNewArray( $1 ); }
4217
4218 | '[' ']' cfa_identifier_parameter_ptr
4219 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4220 | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
4221 { $$ = $2->addNewArray( $1 ); }
4222 | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
4223 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4224 | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
4225 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4226 | multi_array_dimension cfa_identifier_parameter_ptr
4227 { $$ = $2->addNewArray( $1 ); }
4228 ;
4229
4230cfa_array_parameter_1st_dimension:
4231 '[' push type_qualifier_list '*' pop ']' // remaining C99
4232 { $$ = DeclarationNode::newVarArray( $3 ); }
4233 | '[' push type_qualifier_list assignment_expression pop ']'
4234 { $$ = DeclarationNode::newArray( $4, $3, false ); }
4235 | '[' push declaration_qualifier_list assignment_expression pop ']'
4236 // declaration_qualifier_list must be used because of shift/reduce conflict with
4237 // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
4238 // appear in this context.
4239 { $$ = DeclarationNode::newArray( $4, $3, true ); }
4240 | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
4241 { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
4242 ;
4243
4244// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
4245// identifier to which the type applies, e.g.:
4246//
4247// [int] f( int ); // abstract variable parameter; no parameter name specified
4248// [int] f( [int] (int) ); // abstract function-prototype parameter; no parameter name specified
4249//
4250// These rules need LR(3):
4251//
4252// cfa_abstract_tuple identifier_or_type_name
4253// '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_list_ellipsis_opt ')'
4254//
4255// since a function return type can be syntactically identical to a tuple type:
4256//
4257// [int, int] t;
4258// [int, int] f( int );
4259//
4260// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
4261// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
4262// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
4263// duplicated when appearing with cfa_function_specifier.
4264
4265cfa_abstract_declarator_tuple: // CFA
4266 cfa_abstract_tuple
4267 | type_qualifier_list cfa_abstract_tuple
4268 { $$ = $2->addQualifiers( $1 ); }
4269 | cfa_abstract_declarator_no_tuple
4270 ;
4271
4272cfa_abstract_declarator_no_tuple: // CFA
4273 cfa_abstract_ptr
4274 | cfa_abstract_array
4275 ;
4276
4277cfa_abstract_ptr: // CFA
4278 ptrref_operator type_specifier
4279 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4280 | type_qualifier_list ptrref_operator type_specifier
4281 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4282 | ptrref_operator cfa_abstract_function
4283 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4284 | type_qualifier_list ptrref_operator cfa_abstract_function
4285 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4286 | ptrref_operator cfa_abstract_declarator_tuple
4287 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4288 | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
4289 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4290 ;
4291
4292cfa_abstract_array: // CFA
4293 // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
4294 // empty (void) function return type.
4295 '[' ']' type_specifier
4296 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4297 | '[' ']' multi_array_dimension type_specifier
4298 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4299 | multi_array_dimension type_specifier
4300 { $$ = $2->addNewArray( $1 ); }
4301 | '[' ']' cfa_abstract_ptr
4302 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4303 | '[' ']' multi_array_dimension cfa_abstract_ptr
4304 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4305 | multi_array_dimension cfa_abstract_ptr
4306 { $$ = $2->addNewArray( $1 ); }
4307 ;
4308
4309cfa_abstract_tuple: // CFA
4310 '[' push cfa_abstract_parameter_list pop ']'
4311 { $$ = DeclarationNode::newTuple( $3 ); }
4312 | '[' push type_specifier_nobody ELLIPSIS pop ']'
4313 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4314 | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
4315 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4316 ;
4317
4318cfa_abstract_function: // CFA
4319 '[' ']' '(' cfa_parameter_list_ellipsis_opt ')'
4320 { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
4321 | cfa_abstract_tuple '(' push cfa_parameter_list_ellipsis_opt pop ')'
4322 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4323 | cfa_function_return '(' push cfa_parameter_list_ellipsis_opt pop ')'
4324 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4325 ;
4326
4327// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
4328// each declaration, and in the specifier-qualifier list in each structure declaration and type name."
4329//
4330// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
4331// the declaration specifiers in a declaration is an obsolescent feature."
4332//
4333// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
4334// prototype-format parameter type declarators) is an obsolescent feature."
4335//
4336// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
4337// declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
4338
4339// ************************ MISCELLANEOUS ********************************
4340
4341comma_opt: // redundant comma
4342 // empty
4343 | ','
4344 ;
4345
4346default_initializer_opt:
4347 // empty
4348 { $$ = nullptr; }
4349 | '=' assignment_expression
4350 { $$ = $2; }
4351 ;
4352
4353%%
4354
4355// ----end of grammar----
4356
4357// Local Variables: //
4358// mode: c++ //
4359// tab-width: 4 //
4360// compile-command: "bison -Wcounterexamples parser.yy" //
4361// End: //
Note: See TracBrowser for help on using the repository browser.