source: src/Parser/parser.yy@ b64d0f4

Last change on this file since b64d0f4 was b93c544, checked in by Andrew Beach <ajbeach@…>, 23 months ago

Removed casts no longer needed on the result of set_last.
  • Property mode set to 100644
File size: 177.4 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author : Peter A. Buhr
10// Created On : Sat Sep 1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Wed Mar 6 10:51:55 2024
13// Update Count : 6588
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS. While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks. Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// designation with '=' (use ':' instead)
29//
30// This incompatibility is discussed in detail before the "designation" grammar rule. Most of the syntactic extensions
31// from ANSI90 to ANSI11 C are marked with the comment "C99/C11".
32
33// This grammar also has two levels of extensions. The first extensions cover most of the GCC C extensions. All of the
34// syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall (CFA), which
35// fixes several of C's outstanding problems and extends C with many modern language concepts. All of the syntactic
36// extensions for CFA C are marked with the comment "CFA".
37
38%{
39#define YYDEBUG_LEXER_TEXT( yylval ) // lexer loads this up each time
40#define YYDEBUG 1 // get the pretty debugging code to compile
41#define YYERROR_VERBOSE // more information in syntax errors
42
43#undef __GNUC_MINOR__
44
45#include <cstdio>
46#include <sstream>
47#include <stack>
48using namespace std;
49
50#include "DeclarationNode.h" // for DeclarationNode, ...
51#include "ExpressionNode.h" // for ExpressionNode, ...
52#include "InitializerNode.h" // for InitializerNode, ...
53#include "ParserTypes.h"
54#include "StatementNode.h" // for build_...
55#include "TypedefTable.h"
56#include "TypeData.h"
57#include "Common/SemanticError.h" // error_str
58#include "Common/utility.h" // for maybeMoveBuild, maybeBuild, CodeLo...
59
60// lex uses __null in a boolean context, it's fine.
61#ifdef __clang__
62#pragma GCC diagnostic ignored "-Wparentheses-equality"
63#endif
64
65extern DeclarationNode * parseTree;
66extern ast::Linkage::Spec linkage;
67extern TypedefTable typedefTable;
68
69stack<ast::Linkage::Spec> linkageStack;
70
71bool appendStr( string & to, string & from ) {
72 // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
73 // "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
74 // the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
75 // easier to let the C compiler handle this case.
76 //
77 // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
78 // without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
79 // e.g., u"a" U"b" L"c" is disallowed.
80
81 if ( from[0] != '"' ) { // encoding ?
82 if ( to[0] != '"' ) { // encoding ?
83 if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
84 yyerror( "non-matching string encodings for string-literal concatenation" );
85 return false; // parse error, must call YYERROR in action
86 } else if ( from[1] == '8' ) {
87 from.erase( 0, 1 ); // remove 2nd encoding
88 } // if
89 } else {
90 if ( from[1] == '8' ) { // move encoding to start
91 to = "u8" + to;
92 from.erase( 0, 1 ); // remove 2nd encoding
93 } else {
94 to = from[0] + to;
95 } // if
96 } // if
97 from.erase( 0, 1 ); // remove 2nd encoding
98 } // if
99 to += " " + from; // concatenated into single string
100 return true;
101} // appendStr
102
103DeclarationNode * distAttr( DeclarationNode * typeSpec, DeclarationNode * declList ) {
104 // Distribute type specifier across all declared variables, e.g., static, const, __attribute__.
105 assert( declList );
106
107 // Do not distribute attributes for aggregates because the attributes surrounding the aggregate belong it not the
108 // variables in the declaration list, e.g.,
109 //
110 // struct __attribute__(( aligned(128) )) S { ...
111 // } v1 __attribute__(( aligned(64) )), v2 __attribute__(( aligned(32) )), v3;
112 // struct S v4;
113 //
114 // v1 => 64, v2 =>32, v3 => 128, v2 => 128
115 //
116 // Anonymous aggregates are a special case because there is no aggregate to bind the attribute to; hence it floats
117 // to the declaration list.
118 //
119 // struct __attribute__(( aligned(128) )) /*anonymous */ { ... } v1;
120 //
121 // v1 => 128
122
123 bool copyattr = ! (typeSpec->type && typeSpec->type->kind == TypeData::Aggregate && ! typeSpec->type->aggregate.anon );
124
125 // addType copies the type information for the aggregate instances from typeSpec into cl's aggInst.aggregate.
126 DeclarationNode * cl = (new DeclarationNode)->addType( typeSpec ); // typeSpec IS DELETED!!!
127
128 // Start at second variable in declaration list and clone the type specifiers for each variable.
129 for ( DeclarationNode * cur = declList->next ; cur != nullptr; cur = cur->next ) {
130 cl->cloneBaseType( cur, copyattr ); // cur is modified
131 } // for
132
133 // Add first variable in declaration list with hidden type information in aggInst.aggregate, which is used by
134 // extractType to recover the type for the aggregate instances.
135 declList->addType( cl, copyattr ); // cl IS DELETED!!!
136 return declList;
137} // distAttr
138
139void distExt( DeclarationNode * declaration ) {
140 // distribute EXTENSION across all declarations
141 for ( DeclarationNode *iter = declaration ; iter != nullptr ; iter = iter->next ) {
142 iter->set_extension( true );
143 } // for
144} // distExt
145
146void distInl( DeclarationNode * declaration ) {
147 // distribute INLINE across all declarations
148 for ( DeclarationNode *iter = declaration ; iter != nullptr ; iter = iter->next ) {
149 iter->set_inLine( true );
150 } // for
151} // distInl
152
153void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
154 // distribute qualifiers across all non-variable declarations in a distribution statemement
155 for ( DeclarationNode * iter = declaration ; iter != nullptr ; iter = iter->next ) {
156 // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
157 // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
158 // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
159 // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
160 DeclarationNode * clone = qualifiers->clone();
161 if ( qualifiers->type ) { // forall clause ? (handles SC)
162 if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
163 swap( clone->type->forall, iter->type->aggregate.params );
164 iter->addQualifiers( clone );
165 } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
166 // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
167 DeclarationNode newnode;
168 swap( newnode.type, iter->type->aggInst.aggregate );
169 swap( clone->type->forall, newnode.type->aggregate.params );
170 newnode.addQualifiers( clone );
171 swap( newnode.type, iter->type->aggInst.aggregate );
172 } else if ( iter->type->kind == TypeData::Function ) { // routines ?
173 swap( clone->type->forall, iter->type->forall );
174 iter->addQualifiers( clone );
175 } // if
176 } else { // just SC qualifiers
177 iter->addQualifiers( clone );
178 } // if
179 } // for
180 delete qualifiers;
181} // distQual
182
183// There is an ambiguity for inline generic-routine return-types and generic routines.
184// forall( otype T ) struct S { int i; } bar( T ) {}
185// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
186// forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
187// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
188// forall( otype T ) struct S { int T; };
189// forall( otype W ) bar( W ) {}
190
191void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
192 if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
193 funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
194 declSpec->type->aggregate.params = nullptr;
195 } // if
196} // rebindForall
197
198string * build_postfix_name( string * name ) {
199 *name = string("__postfix_func_") + *name;
200 return name;
201} // build_postfix_name
202
203DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
204 if ( ! fieldList ) { // field declarator ?
205 if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate || typeSpec->type->kind == TypeData::Enum) ) ) {
206 stringstream ss;
207 // printf( "fieldDecl1 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
208 SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
209 return nullptr;
210 } // if
211 // printf( "fieldDecl2 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
212 fieldList = DeclarationNode::newName( nullptr );
213 } // if
214
215 // printf( "fieldDecl3 typeSpec %p\n", typeSpec ); typeSpec->print( std::cout, 0 );
216 DeclarationNode * temp = distAttr( typeSpec, fieldList ); // mark all fields in list
217 // printf( "fieldDecl4 temp %p\n", temp ); temp->print( std::cout, 0 );
218 return temp;
219} // fieldDecl
220
221#define NEW_ZERO new ExpressionNode( build_constantInteger( yylloc, *new string( "0" ) ) )
222#define NEW_ONE new ExpressionNode( build_constantInteger( yylloc, *new string( "1" ) ) )
223#define UPDOWN( compop, left, right ) (compop == OperKinds::LThan || compop == OperKinds::LEThan ? left : right)
224#define MISSING_ANON_FIELD "syntax error, missing loop fields with an anonymous loop index is meaningless as loop index is unavailable in loop body."
225#define MISSING_LOW "syntax error, missing low value for up-to range so index is uninitialized."
226#define MISSING_HIGH "syntax error, missing high value for down-to range so index is uninitialized."
227
228static ForCtrl * makeForCtrl(
229 const CodeLocation & location,
230 DeclarationNode * init,
231 enum OperKinds compop,
232 ExpressionNode * comp,
233 ExpressionNode * inc ) {
234 // Wrap both comp/inc if they are non-null.
235 if ( comp ) comp = new ExpressionNode( build_binary_val( location,
236 compop,
237 new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
238 comp ) );
239 if ( inc ) inc = new ExpressionNode( build_binary_val( location,
240 // choose += or -= for upto/downto
241 compop == OperKinds::LThan || compop == OperKinds::LEThan ? OperKinds::PlusAssn : OperKinds::MinusAssn,
242 new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
243 inc ) );
244 // The StatementNode call frees init->name, it must happen later.
245 return new ForCtrl( new StatementNode( init ), comp, inc );
246}
247
248ForCtrl * forCtrl( const CodeLocation & location, DeclarationNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
249 if ( index->initializer ) {
250 SemanticError( yylloc, "syntax error, direct initialization disallowed. Use instead: type var; initialization ~ comparison ~ increment." );
251 } // if
252 if ( index->next ) {
253 SemanticError( yylloc, "syntax error, multiple loop indexes disallowed in for-loop declaration." );
254 } // if
255 DeclarationNode * initDecl = index->addInitializer( new InitializerNode( start ) );
256 return makeForCtrl( location, initDecl, compop, comp, inc );
257} // forCtrl
258
259ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
260 ast::ConstantExpr * constant = dynamic_cast<ast::ConstantExpr *>(type->expr.get());
261 if ( constant && (constant->rep == "0" || constant->rep == "1") ) {
262 type = new ExpressionNode( new ast::CastExpr( location, maybeMoveBuild(type), new ast::BasicType( ast::BasicType::SignedInt ) ) );
263 } // if
264 DeclarationNode * initDecl = distAttr(
265 DeclarationNode::newTypeof( type, true ),
266 DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) )
267 );
268 return makeForCtrl( location, initDecl, compop, comp, inc );
269} // forCtrl
270
271ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
272 if ( auto identifier = dynamic_cast<ast::NameExpr *>(index->expr.get()) ) {
273 return forCtrl( location, type, new string( identifier->name ), start, compop, comp, inc );
274 } else if ( auto commaExpr = dynamic_cast<ast::CommaExpr *>( index->expr.get() ) ) {
275 if ( auto identifier = commaExpr->arg1.as<ast::NameExpr>() ) {
276 return forCtrl( location, type, new string( identifier->name ), start, compop, comp, inc );
277 } else {
278 SemanticError( yylloc, "syntax error, loop-index name missing. Expression disallowed." ); return nullptr;
279 } // if
280 } else {
281 SemanticError( yylloc, "syntax error, loop-index name missing. Expression disallowed." ); return nullptr;
282 } // if
283} // forCtrl
284
285static void IdentifierBeforeIdentifier( string & identifier1, string & identifier2, const char * kind ) {
286 SemanticError( yylloc, "syntax error, adjacent identifiers \"%s\" and \"%s\" are not meaningful in an %s.\n"
287 "Possible cause is misspelled type name or missing generic parameter.",
288 identifier1.c_str(), identifier2.c_str(), kind );
289} // IdentifierBeforeIdentifier
290
291static void IdentifierBeforeType( string & identifier, const char * kind ) {
292 SemanticError( yylloc, "syntax error, identifier \"%s\" cannot appear before a %s.\n"
293 "Possible cause is misspelled storage/CV qualifier, misspelled typename, or missing generic parameter.",
294 identifier.c_str(), kind );
295} // IdentifierBeforeType
296
297bool forall = false; // aggregate have one or more forall qualifiers ?
298
299// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
300#define YYLLOC_DEFAULT(Cur, Rhs, N) \
301if ( N ) { \
302 (Cur).first_line = YYRHSLOC( Rhs, 1 ).first_line; \
303 (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column; \
304 (Cur).last_line = YYRHSLOC( Rhs, N ).last_line; \
305 (Cur).last_column = YYRHSLOC( Rhs, N ).last_column; \
306 (Cur).filename = YYRHSLOC( Rhs, 1 ).filename; \
307} else { \
308 (Cur).first_line = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line; \
309 (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column; \
310 (Cur).filename = YYRHSLOC( Rhs, 0 ).filename; \
311}
312%}
313
314%define parse.error verbose
315
316// Types declaration for productions
317
318%union {
319 // A raw token can be used.
320 Token tok;
321
322 // The general node types hold some generic node or list of nodes.
323 DeclarationNode * decl;
324 InitializerNode * init;
325 ExpressionNode * expr;
326 StatementNode * stmt;
327 ClauseNode * clause;
328 TypeData * type;
329
330 // Special "nodes" containing compound information.
331 CondCtl * ifctl;
332 ForCtrl * forctl;
333 LabelNode * labels;
334
335 // Various flags and single values that become fields later.
336 ast::AggregateDecl::Aggregate aggKey;
337 ast::TypeDecl::Kind tclass;
338 OperKinds oper;
339 bool is_volatile;
340 EnumHiding enum_hiding;
341 ast::ExceptionKind except_kind;
342 // String passes ownership with it.
343 std::string * str;
344
345 // Narrower node types are used to avoid constant unwrapping.
346 ast::WaitForStmt * wfs;
347 ast::WaitUntilStmt::ClauseNode * wucn;
348 ast::GenericExpr * genexpr;
349}
350
351// ************************ TERMINAL TOKENS ********************************
352
353// keywords
354%token TYPEDEF
355%token EXTERN STATIC AUTO REGISTER
356%token THREADLOCALGCC THREADLOCALC11 // GCC, C11
357%token INLINE FORTRAN // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
358%token NORETURN // C11
359%token CONST VOLATILE
360%token RESTRICT // C99
361%token ATOMIC // C11
362%token FORALL MUTEX VIRTUAL VTABLE COERCE // CFA
363%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
364%token BOOL COMPLEX IMAGINARY // C99
365%token INT128 UINT128 uuFLOAT80 uuFLOAT128 // GCC
366%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
367%token DECIMAL32 DECIMAL64 DECIMAL128 // GCC
368%token ZERO_T ONE_T // CFA
369%token SIZEOF TYPEOF VA_LIST VA_ARG AUTO_TYPE // GCC
370%token OFFSETOF BASETYPEOF TYPEID // CFA
371%token ENUM STRUCT UNION
372%token EXCEPTION // CFA
373%token GENERATOR COROUTINE MONITOR THREAD // CFA
374%token OTYPE FTYPE DTYPE TTYPE TRAIT // CFA
375// %token RESUME // CFA
376%token LABEL // GCC
377%token SUSPEND // CFA
378%token ATTRIBUTE EXTENSION // GCC
379%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
380%token CHOOSE FALLTHRU FALLTHROUGH WITH WHEN WAITFOR WAITUNTIL // CFA
381%token CORUN COFOR
382%token DISABLE ENABLE TRY THROW THROWRESUME AT // CFA
383%token ASM // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
384%token ALIGNAS ALIGNOF GENERIC STATICASSERT // C11
385
386// names and constants: lexer differentiates between identifier and typedef names
387%token<tok> IDENTIFIER TYPEDIMname TYPEDEFname TYPEGENname
388%token<tok> TIMEOUT WAND WOR CATCH RECOVER CATCHRESUME FIXUP FINALLY // CFA
389%token<tok> INTEGERconstant CHARACTERconstant STRINGliteral
390%token<tok> DIRECTIVE
391// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
392// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
393// converted into the tuple index (.)(1). e.g., 3.x
394%token<tok> FLOATING_DECIMALconstant FLOATING_FRACTIONconstant FLOATINGconstant
395
396// multi-character operators
397%token ARROW // ->
398%token ICR DECR // ++ --
399%token LS RS // << >>
400%token LE GE EQ NE // <= >= == !=
401%token ANDAND OROR // && ||
402%token ATTR ELLIPSIS // @@ ...
403
404%token EXPassign MULTassign DIVassign MODassign // \= *= /= %=
405%token PLUSassign MINUSassign // += -=
406%token LSassign RSassign // <<= >>=
407%token ANDassign ERassign ORassign // &= ^= |=
408
409%token ErangeUpEq ErangeDown ErangeDownEq // ~= -~ -~=
410%token ATassign // @=
411
412%type<tok> identifier identifier_at identifier_or_type_name attr_name
413%type<tok> quasi_keyword
414%type<expr> string_literal
415%type<str> string_literal_list
416
417%type<enum_hiding> hide_opt visible_hide_opt
418
419// expressions
420%type<expr> constant
421%type<expr> tuple tuple_expression_list
422%type<oper> ptrref_operator unary_operator assignment_operator simple_assignment_operator compound_assignment_operator
423%type<expr> primary_expression postfix_expression unary_expression
424%type<expr> cast_expression_list cast_expression exponential_expression multiplicative_expression additive_expression
425%type<expr> shift_expression relational_expression equality_expression
426%type<expr> AND_expression exclusive_OR_expression inclusive_OR_expression
427%type<expr> logical_AND_expression logical_OR_expression
428%type<expr> conditional_expression constant_expression assignment_expression assignment_expression_opt
429%type<expr> comma_expression comma_expression_opt
430%type<expr> argument_expression_list_opt argument_expression_list argument_expression default_initializer_opt
431%type<ifctl> conditional_declaration
432%type<forctl> for_control_expression for_control_expression_list
433%type<oper> upupeq updown updowneq downupdowneq
434%type<expr> subrange
435%type<decl> asm_name_opt
436%type<expr> asm_operands_opt asm_operands_list asm_operand
437%type<labels> label_list
438%type<expr> asm_clobbers_list_opt
439%type<is_volatile> asm_volatile_opt
440%type<expr> handler_predicate_opt
441%type<genexpr> generic_association generic_assoc_list
442
443// statements
444%type<stmt> statement labeled_statement compound_statement
445%type<stmt> statement_decl statement_decl_list statement_list_nodecl
446%type<stmt> selection_statement
447%type<clause> switch_clause_list_opt switch_clause_list
448%type<expr> case_value
449%type<clause> case_clause case_value_list case_label case_label_list
450%type<stmt> iteration_statement jump_statement
451%type<stmt> expression_statement asm_statement
452%type<stmt> with_statement
453%type<expr> with_clause_opt
454%type<stmt> corun_statement cofor_statement
455%type<stmt> exception_statement
456%type<clause> handler_clause finally_clause
457%type<except_kind> handler_key
458%type<stmt> mutex_statement
459%type<expr> when_clause when_clause_opt waitfor waituntil timeout
460%type<stmt> waitfor_statement waituntil_statement
461%type<wfs> wor_waitfor_clause
462%type<wucn> waituntil_clause wand_waituntil_clause wor_waituntil_clause
463
464// declarations
465%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
466%type<decl> abstract_parameter_declarator_opt abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
467%type<decl> abstract_parameter_declaration
468
469%type<aggKey> aggregate_key aggregate_data aggregate_control
470%type<decl> aggregate_type aggregate_type_nobody
471
472%type<decl> assertion assertion_list assertion_list_opt
473
474%type<expr> bit_subrange_size_opt bit_subrange_size
475
476%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
477%type<type> basic_type_name_type
478%type<type> vtable vtable_opt default_opt
479
480%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
481
482%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
483%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
484
485%type<decl> elaborated_type elaborated_type_nobody
486
487%type<decl> enumerator_list enum_type enum_type_nobody
488%type<init> enumerator_value_opt
489
490%type<decl> external_definition external_definition_list external_definition_list_opt
491
492%type<decl> exception_declaration
493
494%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
495%type<expr> field field_name_list field_name fraction_constants_opt
496
497%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
498
499%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
500%type<decl> identifier_list
501
502%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
503%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
504%type<decl> cfa_abstract_ptr cfa_abstract_tuple
505
506%type<decl> cfa_array_parameter_1st_dimension
507
508%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
509%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
510
511%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
512%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
513
514%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_list_ellipsis_opt
515
516%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
517
518%type<decl> c_declaration static_assert
519%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
520%type<decl> KR_parameter_list KR_parameter_list_opt
521
522%type<decl> parameter_declaration parameter_list parameter_list_ellipsis_opt
523
524%type<decl> paren_identifier paren_type
525
526%type<decl> storage_class storage_class_list
527
528%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
529
530%type<tclass> type_class new_type_class
531%type<decl> type_declarator type_declarator_name type_declaring_list
532
533%type<decl> type_declaration_specifier type_type_specifier
534%type<type> type_name typegen_name
535%type<decl> typedef_name typedef_declaration typedef_expression
536
537%type<decl> variable_type_redeclarator variable_type_ptr variable_type_array variable_type_function
538%type<decl> general_function_declarator function_type_redeclarator function_type_array function_type_no_ptr function_type_ptr
539
540%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
541
542%type<decl> type type_no_function
543%type<decl> type_parameter type_parameter_list type_initializer_opt
544
545%type<expr> type_parameters_opt type_list array_type_list // array_dimension_list
546
547%type<decl> type_qualifier forall type_qualifier_list_opt type_qualifier_list
548%type<type> type_qualifier_name
549%type<decl> type_specifier type_specifier_nobody
550
551%type<decl> variable_declarator variable_ptr variable_array variable_function
552%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
553
554%type<decl> attribute_list_opt attribute_list attribute attribute_name_list attribute_name
555
556// initializers
557%type<init> initializer initializer_list_opt initializer_opt
558
559// designators
560%type<expr> designator designator_list designation
561
562
563// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
564// .---------. matches IF '(' comma_expression ')' statement . (reduce)
565// if ( C ) S1 else S2
566// `-----------------' matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
567// Similar issues exit with the waitfor statement.
568
569// Order of these lines matters (low-to-high precedence). THEN is left associative over WAND/WOR/TIMEOUT/ELSE, WAND/WOR
570// is left associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
571%precedence THEN // rule precedence for IF/WAITFOR statement
572%precedence ANDAND // token precedence for start of WAND in WAITFOR statement
573%precedence WAND // token precedence for start of WAND in WAITFOR statement
574%precedence OROR // token precedence for start of WOR in WAITFOR statement
575%precedence WOR // token precedence for start of WOR in WAITFOR statement
576%precedence TIMEOUT // token precedence for start of TIMEOUT in WAITFOR statement
577%precedence CATCH // token precedence for start of TIMEOUT in WAITFOR statement
578%precedence RECOVER // token precedence for start of TIMEOUT in WAITFOR statement
579%precedence CATCHRESUME // token precedence for start of TIMEOUT in WAITFOR statement
580%precedence FIXUP // token precedence for start of TIMEOUT in WAITFOR statement
581%precedence FINALLY // token precedence for start of TIMEOUT in WAITFOR statement
582%precedence ELSE // token precedence for start of else clause in IF/WAITFOR statement
583
584
585// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
586// forall( otype T ) struct Foo { T v; };
587// .-----. matches pointer to function returning a generic (which is impossible without a type)
588// Foo ( *fp )( int );
589// `---' matches start of TYPEGENname '('
590// must be:
591// Foo( int ) ( *fp )( int );
592// The same problem occurs here:
593// forall( otype T ) struct Foo { T v; } ( *fp )( int );
594// must be:
595// forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
596
597// Order of these lines matters (low-to-high precedence).
598%precedence TYPEGENname
599%precedence '}'
600%precedence '('
601
602// %precedence RESUME
603// %precedence '{'
604// %precedence ')'
605
606%locations // support location tracking for error messages
607
608%start translation_unit // parse-tree root
609
610%%
611// ************************ Namespace Management ********************************
612
613// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
614// which are lexically identical.
615//
616// typedef int foo; // identifier foo must now be scanned as TYPEDEFname
617// foo f; // to allow it to appear in this context
618//
619// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
620// between syntactic and semantic constructs. Cforall compounds this problem by introducing type names local to the
621// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
622// generators" -- parameterized types. This latter type name creates a third class of identifiers, "TYPEGENname", which
623// must be distinguished by the lexical scanner.
624//
625// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
626// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
627// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
628// each context that introduces a name scope, a new level is created in the type table and that level is popped on
629// exiting the scope. Since type names can be local to a particular declaration, each declaration is itself a scope.
630// This requires distinguishing between type names that are local to the current declaration scope and those that
631// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
632//
633// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
634// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
635// around the list separator.
636//
637// XXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
638// push pop push pop
639
640push:
641 { typedefTable.enterScope(); }
642 ;
643
644pop:
645 { typedefTable.leaveScope(); }
646 ;
647
648// ************************ CONSTANTS ********************************
649
650constant:
651 // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
652 INTEGERconstant { $$ = new ExpressionNode( build_constantInteger( yylloc, *$1 ) ); }
653 | FLOATING_DECIMALconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
654 | FLOATING_FRACTIONconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
655 | FLOATINGconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
656 | CHARACTERconstant { $$ = new ExpressionNode( build_constantChar( yylloc, *$1 ) ); }
657 ;
658
659quasi_keyword: // CFA
660 TIMEOUT
661 | WAND
662 | WOR
663 | CATCH
664 | RECOVER
665 | CATCHRESUME
666 | FIXUP
667 | FINALLY
668 ;
669
670identifier:
671 IDENTIFIER
672 | quasi_keyword
673 ;
674
675identifier_at:
676 identifier
677 | '@' // CFA
678 { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
679 ;
680
681string_literal:
682 string_literal_list { $$ = new ExpressionNode( build_constantStr( yylloc, *$1 ) ); }
683 ;
684
685string_literal_list: // juxtaposed strings are concatenated
686 STRINGliteral { $$ = $1; } // conversion from tok to str
687 | string_literal_list STRINGliteral
688 {
689 if ( ! appendStr( *$1, *$2 ) ) YYERROR; // append 2nd juxtaposed string to 1st
690 delete $2; // allocated by lexer
691 $$ = $1; // conversion from tok to str
692 }
693 ;
694
695// ************************ EXPRESSIONS ********************************
696
697primary_expression:
698 IDENTIFIER // typedef name cannot be used as a variable name
699 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
700 | quasi_keyword
701 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
702 | TYPEDIMname // CFA, generic length argument
703 { $$ = new ExpressionNode( build_dimensionref( yylloc, $1 ) ); }
704 | tuple
705 | '(' comma_expression ')'
706 { $$ = $2; }
707 | '(' compound_statement ')' // GCC, lambda expression
708 { $$ = new ExpressionNode( new ast::StmtExpr( yylloc, dynamic_cast<ast::CompoundStmt *>( maybeMoveBuild( $2 ) ) ) ); }
709 | type_name '.' identifier // CFA, nested type
710 { $$ = new ExpressionNode( build_qualified_expr( yylloc, DeclarationNode::newFromTypeData( $1 ), build_varref( yylloc, $3 ) ) ); }
711 | type_name '.' '[' field_name_list ']' // CFA, nested type / tuple field selector
712 { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
713 | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
714 {
715 // add the missing control expression to the GenericExpr and return it
716 $5->control = maybeMoveBuild( $3 );
717 $$ = new ExpressionNode( $5 );
718 }
719 // | RESUME '(' comma_expression ')'
720 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
721 // | RESUME '(' comma_expression ')' compound_statement
722 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
723 | IDENTIFIER IDENTIFIER // invalid syntax rule
724 { IdentifierBeforeIdentifier( *$1.str, *$2.str, "expression" ); $$ = nullptr; }
725 | IDENTIFIER type_qualifier // invalid syntax rule
726 { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
727 | IDENTIFIER storage_class // invalid syntax rule
728 { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
729 | IDENTIFIER basic_type_name // invalid syntax rule
730 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
731 | IDENTIFIER TYPEDEFname // invalid syntax rule
732 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
733 | IDENTIFIER TYPEGENname // invalid syntax rule
734 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
735 ;
736
737generic_assoc_list: // C11
738 generic_association
739 | generic_assoc_list ',' generic_association
740 {
741 // steal the association node from the singleton and delete the wrapper
742 assert( 1 == $3->associations.size() );
743 $1->associations.push_back( $3->associations.front() );
744 delete $3;
745 $$ = $1;
746 }
747 ;
748
749generic_association: // C11
750 type_no_function ':' assignment_expression
751 {
752 // create a GenericExpr wrapper with one association pair
753 $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuildType( $1 ), maybeMoveBuild( $3 ) } } );
754 }
755 | DEFAULT ':' assignment_expression
756 { $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuild( $3 ) } } ); }
757 ;
758
759postfix_expression:
760 primary_expression
761 | postfix_expression '[' assignment_expression ',' tuple_expression_list ']'
762 // Historic, transitional: Disallow commas in subscripts.
763 // Switching to this behaviour may help check if a C compatibilty case uses comma-exprs in subscripts.
764 // Current: Commas in subscripts make tuples.
765 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, new ExpressionNode( build_tuple( yylloc, $3->set_last( $5 ) ) ) ) ); }
766 | postfix_expression '[' assignment_expression ']'
767 // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
768 // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
769 // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
770 // equivalent to the old x[i,j].
771 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
772 | constant '[' assignment_expression ']' // 3[a], 'a'[a], 3.5[a]
773 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
774 | string_literal '[' assignment_expression ']' // "abc"[3], 3["abc"]
775 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
776 | postfix_expression '{' argument_expression_list_opt '}' // CFA, constructor call
777 {
778 Token fn;
779 fn.str = new std::string( "?{}" ); // location undefined - use location of '{'?
780 $$ = new ExpressionNode( new ast::ConstructorExpr( yylloc, build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), $1->set_last( $3 ) ) ) );
781 }
782 | postfix_expression '(' argument_expression_list_opt ')'
783 { $$ = new ExpressionNode( build_func( yylloc, $1, $3 ) ); }
784 | VA_ARG '(' primary_expression ',' declaration_specifier_nobody abstract_parameter_declarator_opt ')'
785 // { SemanticError( yylloc, "va_arg is currently unimplemented." ); $$ = nullptr; }
786 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, new string( "__builtin_va_arg" ) ) ),
787 $3->set_last( (ExpressionNode *)($6 ? $6->addType( $5 ) : $5) ) ) ); }
788 | postfix_expression '`' identifier // CFA, postfix call
789 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
790 | constant '`' identifier // CFA, postfix call
791 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
792 | string_literal '`' identifier // CFA, postfix call
793 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
794
795 // SKULLDUGGERY: The typedef table used for parsing does not store fields in structures. To parse a qualified
796 // name, it is assumed all name-tokens after the first are identifiers, regardless of how the lexer identifies
797 // them. For example:
798 //
799 // struct S;
800 // forall(T) struct T;
801 // union U;
802 // enum E { S, T, E };
803 // struct Z { int S, T, Z, E, U; };
804 // void fred () {
805 // Z z;
806 // z.S; // lexer returns S is TYPEDEFname
807 // z.T; // lexer returns T is TYPEGENname
808 // z.Z; // lexer returns Z is TYPEDEFname
809 // z.U; // lexer returns U is TYPEDEFname
810 // z.E; // lexer returns E is TYPEDEFname
811 // }
812 | postfix_expression '.' identifier
813 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
814 | postfix_expression '.' TYPEDEFname // CFA, SKULLDUGGERY
815 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
816 | postfix_expression '.' TYPEGENname // CFA, SKULLDUGGERY
817 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
818
819 | postfix_expression '.' INTEGERconstant // CFA, tuple index
820 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
821 | postfix_expression FLOATING_FRACTIONconstant // CFA, tuple index
822 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 ) ) ); }
823 | postfix_expression '.' '[' field_name_list ']' // CFA, tuple field selector
824 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
825 | postfix_expression '.' aggregate_control
826 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $3, $1 ) ); }
827 | postfix_expression ARROW identifier
828 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
829 | postfix_expression ARROW INTEGERconstant // CFA, tuple index
830 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
831 | postfix_expression ARROW '[' field_name_list ']' // CFA, tuple field selector
832 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
833 | postfix_expression ICR
834 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::IncrPost, $1 ) ); }
835 | postfix_expression DECR
836 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::DecrPost, $1 ) ); }
837 | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
838 { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, new InitializerNode( $5, true ) ) ); }
839 | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
840 { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
841 | '^' primary_expression '{' argument_expression_list_opt '}' // CFA, destructor call
842 {
843 Token fn;
844 fn.str = new string( "^?{}" ); // location undefined
845 $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), $2->set_last( $4 ) ) );
846 }
847 ;
848
849argument_expression_list_opt:
850 // empty
851 { $$ = nullptr; }
852 | argument_expression_list
853 ;
854
855argument_expression_list:
856 argument_expression
857 | argument_expression_list_opt ',' argument_expression
858 { $$ = $1->set_last( $3 ); }
859 ;
860
861argument_expression:
862 '@' // CFA, default parameter
863 { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
864 // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
865 | assignment_expression
866 ;
867
868field_name_list: // CFA, tuple field selector
869 field
870 | field_name_list ',' field { $$ = $1->set_last( $3 ); }
871 ;
872
873field: // CFA, tuple field selector
874 field_name
875 | FLOATING_DECIMALconstant field
876 { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), maybeMoveBuild( $2 ) ) ); }
877 | FLOATING_DECIMALconstant '[' field_name_list ']'
878 { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), build_tuple( yylloc, $3 ) ) ); }
879 | field_name '.' field
880 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
881 | field_name '.' '[' field_name_list ']'
882 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
883 | field_name ARROW field
884 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
885 | field_name ARROW '[' field_name_list ']'
886 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
887 ;
888
889field_name:
890 INTEGERconstant fraction_constants_opt
891 { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_constantInteger( yylloc, *$1 ), $2 ) ); }
892 | FLOATINGconstant fraction_constants_opt
893 { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_field_name_FLOATINGconstant( yylloc, *$1 ), $2 ) ); }
894 | identifier_at fraction_constants_opt // CFA, allow anonymous fields
895 {
896 $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_varref( yylloc, $1 ), $2 ) );
897 }
898 ;
899
900fraction_constants_opt:
901 // empty
902 { $$ = nullptr; }
903 | fraction_constants_opt FLOATING_FRACTIONconstant
904 {
905 ast::Expr * constant = build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 );
906 $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( yylloc, $1, constant ) ) : new ExpressionNode( constant );
907 }
908 ;
909
910unary_expression:
911 postfix_expression
912 // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
913 // semantics checks, e.g., ++3, 3--, *3, &&3
914 | constant
915 | string_literal
916 { $$ = $1; }
917 | EXTENSION cast_expression // GCC
918 { $$ = $2->set_extension( true ); }
919 // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
920 // { * X; } // dereference X
921 // { * int X; } // CFA declaration of pointer to int
922 | ptrref_operator cast_expression // CFA
923 {
924 switch ( $1 ) {
925 case OperKinds::AddressOf:
926 $$ = new ExpressionNode( new ast::AddressExpr( maybeMoveBuild( $2 ) ) );
927 break;
928 case OperKinds::PointTo:
929 $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) );
930 break;
931 case OperKinds::And:
932 $$ = new ExpressionNode( new ast::AddressExpr( new ast::AddressExpr( maybeMoveBuild( $2 ) ) ) );
933 break;
934 default:
935 assert( false );
936 }
937 }
938 | unary_operator cast_expression
939 { $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) ); }
940 | ICR unary_expression
941 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Incr, $2 ) ); }
942 | DECR unary_expression
943 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Decr, $2 ) ); }
944 | SIZEOF unary_expression
945 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuild( $2 ) ) ); }
946 | SIZEOF '(' type_no_function ')'
947 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
948 | ALIGNOF unary_expression // GCC, variable alignment
949 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuild( $2 ) ) ); }
950 | ALIGNOF '(' type_no_function ')' // GCC, type alignment
951 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
952
953 // Cannot use rule "type", which includes cfa_abstract_function, for sizeof/alignof, because of S/R problems on
954 // look ahead, so the cfa_abstract_function is factored out.
955 | SIZEOF '(' cfa_abstract_function ')'
956 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
957 | ALIGNOF '(' cfa_abstract_function ')' // GCC, type alignment
958 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
959
960 | OFFSETOF '(' type_no_function ',' identifier ')'
961 { $$ = new ExpressionNode( build_offsetOf( yylloc, $3, build_varref( yylloc, $5 ) ) ); }
962 | TYPEID '(' type ')'
963 {
964 SemanticError( yylloc, "typeid name is currently unimplemented." ); $$ = nullptr;
965 // $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) );
966 }
967 ;
968
969ptrref_operator:
970 '*' { $$ = OperKinds::PointTo; }
971 | '&' { $$ = OperKinds::AddressOf; }
972 // GCC, address of label must be handled by semantic check for ref,ref,label
973 | ANDAND { $$ = OperKinds::And; }
974 ;
975
976unary_operator:
977 '+' { $$ = OperKinds::UnPlus; }
978 | '-' { $$ = OperKinds::UnMinus; }
979 | '!' { $$ = OperKinds::Neg; }
980 | '~' { $$ = OperKinds::BitNeg; }
981 ;
982
983cast_expression:
984 unary_expression
985 | '(' type_no_function ')' cast_expression
986 { $$ = new ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
987 | '(' aggregate_control '&' ')' cast_expression // CFA
988 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
989 | '(' aggregate_control '*' ')' cast_expression // CFA
990 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
991 | '(' VIRTUAL ')' cast_expression // CFA
992 { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $4 ), nullptr ) ); }
993 | '(' VIRTUAL type_no_function ')' cast_expression // CFA
994 { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $5 ), maybeMoveBuildType( $3 ) ) ); }
995 | '(' RETURN type_no_function ')' cast_expression // CFA
996 { $$ = new ExpressionNode( build_cast( yylloc, $3, $5, ast::CastExpr::Return ) ); }
997 | '(' COERCE type_no_function ')' cast_expression // CFA
998 { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
999 | '(' qualifier_cast_list ')' cast_expression // CFA
1000 { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
1001// | '(' type_no_function ')' tuple
1002// { $$ = new ast::ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
1003 ;
1004
1005qualifier_cast_list:
1006 cast_modifier type_qualifier_name
1007 | cast_modifier MUTEX
1008 | qualifier_cast_list cast_modifier type_qualifier_name
1009 | qualifier_cast_list cast_modifier MUTEX
1010 ;
1011
1012cast_modifier:
1013 '-'
1014 | '+'
1015 ;
1016
1017exponential_expression:
1018 cast_expression
1019 | exponential_expression '\\' cast_expression
1020 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Exp, $1, $3 ) ); }
1021 ;
1022
1023multiplicative_expression:
1024 exponential_expression
1025 | multiplicative_expression '*' exponential_expression
1026 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mul, $1, $3 ) ); }
1027 | multiplicative_expression '/' exponential_expression
1028 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Div, $1, $3 ) ); }
1029 | multiplicative_expression '%' exponential_expression
1030 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mod, $1, $3 ) ); }
1031 ;
1032
1033additive_expression:
1034 multiplicative_expression
1035 | additive_expression '+' multiplicative_expression
1036 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Plus, $1, $3 ) ); }
1037 | additive_expression '-' multiplicative_expression
1038 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Minus, $1, $3 ) ); }
1039 ;
1040
1041shift_expression:
1042 additive_expression
1043 | shift_expression LS additive_expression
1044 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LShift, $1, $3 ) ); }
1045 | shift_expression RS additive_expression
1046 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::RShift, $1, $3 ) ); }
1047 ;
1048
1049relational_expression:
1050 shift_expression
1051 | relational_expression '<' shift_expression
1052 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LThan, $1, $3 ) ); }
1053 | relational_expression '>' shift_expression
1054 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GThan, $1, $3 ) ); }
1055 | relational_expression LE shift_expression
1056 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LEThan, $1, $3 ) ); }
1057 | relational_expression GE shift_expression
1058 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GEThan, $1, $3 ) ); }
1059 ;
1060
1061equality_expression:
1062 relational_expression
1063 | equality_expression EQ relational_expression
1064 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Eq, $1, $3 ) ); }
1065 | equality_expression NE relational_expression
1066 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Neq, $1, $3 ) ); }
1067 ;
1068
1069AND_expression:
1070 equality_expression
1071 | AND_expression '&' equality_expression
1072 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitAnd, $1, $3 ) ); }
1073 ;
1074
1075exclusive_OR_expression:
1076 AND_expression
1077 | exclusive_OR_expression '^' AND_expression
1078 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Xor, $1, $3 ) ); }
1079 ;
1080
1081inclusive_OR_expression:
1082 exclusive_OR_expression
1083 | inclusive_OR_expression '|' exclusive_OR_expression
1084 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitOr, $1, $3 ) ); }
1085 ;
1086
1087logical_AND_expression:
1088 inclusive_OR_expression
1089 | logical_AND_expression ANDAND inclusive_OR_expression
1090 { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::AndExpr ) ); }
1091 ;
1092
1093logical_OR_expression:
1094 logical_AND_expression
1095 | logical_OR_expression OROR logical_AND_expression
1096 { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::OrExpr ) ); }
1097 ;
1098
1099conditional_expression:
1100 logical_OR_expression
1101 | logical_OR_expression '?' comma_expression ':' conditional_expression
1102 { $$ = new ExpressionNode( build_cond( yylloc, $1, $3, $5 ) ); }
1103 | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
1104 { $$ = new ExpressionNode( build_cond( yylloc, $1, nullptr, $4 ) ); }
1105 ;
1106
1107constant_expression:
1108 conditional_expression
1109 ;
1110
1111assignment_expression:
1112 // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
1113 conditional_expression
1114 | unary_expression assignment_operator assignment_expression
1115 {
1116// if ( $2 == OperKinds::AtAssn ) {
1117// SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
1118// } else {
1119 $$ = new ExpressionNode( build_binary_val( yylloc, $2, $1, $3 ) );
1120// } // if
1121 }
1122 | unary_expression '=' '{' initializer_list_opt comma_opt '}'
1123 { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
1124 ;
1125
1126assignment_expression_opt:
1127 // empty
1128 { $$ = nullptr; }
1129 | assignment_expression
1130 ;
1131
1132assignment_operator:
1133 simple_assignment_operator
1134 | compound_assignment_operator
1135 ;
1136
1137simple_assignment_operator:
1138 '=' { $$ = OperKinds::Assign; }
1139 | ATassign { $$ = OperKinds::AtAssn; } // CFA
1140 ;
1141
1142compound_assignment_operator:
1143 EXPassign { $$ = OperKinds::ExpAssn; }
1144 | MULTassign { $$ = OperKinds::MulAssn; }
1145 | DIVassign { $$ = OperKinds::DivAssn; }
1146 | MODassign { $$ = OperKinds::ModAssn; }
1147 | PLUSassign { $$ = OperKinds::PlusAssn; }
1148 | MINUSassign { $$ = OperKinds::MinusAssn; }
1149 | LSassign { $$ = OperKinds::LSAssn; }
1150 | RSassign { $$ = OperKinds::RSAssn; }
1151 | ANDassign { $$ = OperKinds::AndAssn; }
1152 | ERassign { $$ = OperKinds::ERAssn; }
1153 | ORassign { $$ = OperKinds::OrAssn; }
1154 ;
1155
1156tuple: // CFA, tuple
1157 // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
1158 // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
1159// '[' ']'
1160// { $$ = new ExpressionNode( build_tuple() ); }
1161// | '[' push assignment_expression pop ']'
1162// { $$ = new ExpressionNode( build_tuple( $3 ) ); }
1163 '[' ',' tuple_expression_list ']'
1164 { $$ = new ExpressionNode( build_tuple( yylloc, (new ExpressionNode( nullptr ))->set_last( $3 ) ) ); }
1165 | '[' push assignment_expression pop ',' tuple_expression_list ']'
1166 { $$ = new ExpressionNode( build_tuple( yylloc, $3->set_last( $6 ) ) ); }
1167 ;
1168
1169tuple_expression_list:
1170 assignment_expression
1171 | '@' // CFA
1172 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1173 | tuple_expression_list ',' assignment_expression
1174 { $$ = $1->set_last( $3 ); }
1175 | tuple_expression_list ',' '@'
1176 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1177 ;
1178
1179comma_expression:
1180 assignment_expression
1181 | comma_expression ',' assignment_expression
1182 { $$ = new ExpressionNode( new ast::CommaExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1183 ;
1184
1185comma_expression_opt:
1186 // empty
1187 { $$ = nullptr; }
1188 | comma_expression
1189 ;
1190
1191// ************************** STATEMENTS *******************************
1192
1193statement:
1194 labeled_statement
1195 | compound_statement
1196 | expression_statement
1197 | selection_statement
1198 | iteration_statement
1199 | jump_statement
1200 | with_statement
1201 | mutex_statement
1202 | waitfor_statement
1203 | waituntil_statement
1204 | corun_statement
1205 | cofor_statement
1206 | exception_statement
1207 | enable_disable_statement
1208 { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1209 | asm_statement
1210 | DIRECTIVE
1211 { $$ = new StatementNode( build_directive( yylloc, $1 ) ); }
1212 ;
1213
1214labeled_statement:
1215 // labels cannot be identifiers 0 or 1
1216 identifier_or_type_name ':' attribute_list_opt statement
1217 { $$ = $4->add_label( yylloc, $1, $3 ); }
1218 | identifier_or_type_name ':' attribute_list_opt error // invalid syntax rule
1219 {
1220 SemanticError( yylloc, "syntx error, label \"%s\" must be associated with a statement, "
1221 "where a declaration, case, or default is not a statement.\n"
1222 "Move the label or terminate with a semicolon.", $1.str->c_str() );
1223 $$ = nullptr;
1224 }
1225 ;
1226
1227compound_statement:
1228 '{' '}'
1229 { $$ = new StatementNode( build_compound( yylloc, (StatementNode *)0 ) ); }
1230 | '{' push
1231 local_label_declaration_opt // GCC, local labels appear at start of block
1232 statement_decl_list // C99, intermix declarations and statements
1233 pop '}'
1234 { $$ = new StatementNode( build_compound( yylloc, $4 ) ); }
1235 ;
1236
1237statement_decl_list: // C99
1238 statement_decl
1239 | statement_decl_list statement_decl
1240 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1241 ;
1242
1243statement_decl:
1244 declaration // CFA, new & old style declarations
1245 { $$ = new StatementNode( $1 ); }
1246 | EXTENSION declaration // GCC
1247 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1248 | function_definition
1249 { $$ = new StatementNode( $1 ); }
1250 | EXTENSION function_definition // GCC
1251 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1252 | statement
1253 ;
1254
1255statement_list_nodecl:
1256 statement
1257 | statement_list_nodecl statement
1258 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1259 | statement_list_nodecl error // invalid syntax rule
1260 { SemanticError( yylloc, "syntax error, declarations only allowed at the start of the switch body,"
1261 " i.e., after the '{'." ); $$ = nullptr; }
1262 ;
1263
1264expression_statement:
1265 comma_expression_opt ';'
1266 { $$ = new StatementNode( build_expr( yylloc, $1 ) ); }
1267 ;
1268
1269// "if", "switch", and "choose" require parenthesis around the conditional. See the following ambiguities without
1270// parenthesis:
1271//
1272// if x + y + z; => "if ( x + y ) + z" or "if ( x ) + y + z"
1273//
1274// switch O { }
1275//
1276// O{} => object-constructor for conditional, switch body ???
1277// O{} => O for conditional followed by switch body
1278//
1279// C++ has this problem, as it has the same constructor syntax.
1280//
1281// switch sizeof ( T ) { }
1282//
1283// sizeof ( T ) => sizeof of T for conditional followed by switch body
1284// sizeof ( T ) => sizeof of compound literal (T){ }, closing parenthesis ???
1285//
1286// Note the two grammar rules for sizeof (alignof)
1287//
1288// | SIZEOF unary_expression
1289// | SIZEOF '(' type_no_function ')'
1290//
1291// where the first DOES NOT require parenthesis! And C++ inherits this problem from C.
1292
1293selection_statement:
1294 IF '(' conditional_declaration ')' statement %prec THEN
1295 // explicitly deal with the shift/reduce conflict on if/else
1296 { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), nullptr ) ); }
1297 | IF '(' conditional_declaration ')' statement ELSE statement
1298 { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), maybe_build_compound( yylloc, $7 ) ) ); }
1299 | SWITCH '(' comma_expression ')' case_clause
1300 { $$ = new StatementNode( build_switch( yylloc, true, $3, $5 ) ); }
1301 | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1302 {
1303 StatementNode *sw = new StatementNode( build_switch( yylloc, true, $3, $8 ) );
1304 // The semantics of the declaration list is changed to include associated initialization, which is performed
1305 // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1306 // statement around the switch. Statements after the initial declaration list can never be executed, and
1307 // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1308 // statement.
1309 $$ = $7 ? new StatementNode( build_compound( yylloc, (new StatementNode( $7 ))->set_last( sw ) ) ) : sw;
1310 }
1311 | SWITCH '(' comma_expression ')' '{' error '}' // CFA, invalid syntax rule error
1312 { SemanticError( yylloc, "synatx error, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1313 | CHOOSE '(' comma_expression ')' case_clause // CFA
1314 { $$ = new StatementNode( build_switch( yylloc, false, $3, $5 ) ); }
1315 | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1316 {
1317 StatementNode *sw = new StatementNode( build_switch( yylloc, false, $3, $8 ) );
1318 $$ = $7 ? new StatementNode( build_compound( yylloc, (new StatementNode( $7 ))->set_last( sw ) ) ) : sw;
1319 }
1320 | CHOOSE '(' comma_expression ')' '{' error '}' // CFA, invalid syntax rule
1321 { SemanticError( yylloc, "syntax error, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1322 ;
1323
1324conditional_declaration:
1325 comma_expression
1326 { $$ = new CondCtl( nullptr, $1 ); }
1327 | c_declaration // no semi-colon
1328 { $$ = new CondCtl( $1, nullptr ); }
1329 | cfa_declaration // no semi-colon
1330 { $$ = new CondCtl( $1, nullptr ); }
1331 | declaration comma_expression // semi-colon separated
1332 { $$ = new CondCtl( $1, $2 ); }
1333 ;
1334
1335// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1336// clause allows a list of values and subranges.
1337
1338case_value: // CFA
1339 constant_expression { $$ = $1; }
1340 | constant_expression ELLIPSIS constant_expression // GCC, subrange
1341 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1342 | subrange // CFA, subrange
1343 ;
1344
1345case_value_list: // CFA
1346 case_value { $$ = new ClauseNode( build_case( yylloc, $1 ) ); }
1347 // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1348 | case_value_list ',' case_value { $$ = $1->set_last( new ClauseNode( build_case( yylloc, $3 ) ) ); }
1349 ;
1350
1351case_label: // CFA
1352 CASE error // invalid syntax rule
1353 { SemanticError( yylloc, "syntax error, case list missing after case." ); $$ = nullptr; }
1354 | CASE case_value_list ':' { $$ = $2; }
1355 | CASE case_value_list error // invalid syntax rule
1356 { SemanticError( yylloc, "syntax error, colon missing after case list." ); $$ = nullptr; }
1357 | DEFAULT ':' { $$ = new ClauseNode( build_default( yylloc ) ); }
1358 // A semantic check is required to ensure only one default clause per switch/choose statement.
1359 | DEFAULT error // invalid syntax rule
1360 { SemanticError( yylloc, "syntax error, colon missing after default." ); $$ = nullptr; }
1361 ;
1362
1363case_label_list: // CFA
1364 case_label
1365 | case_label_list case_label { $$ = $1->set_last( $2 ); }
1366 ;
1367
1368case_clause: // CFA
1369 case_label_list statement { $$ = $1->append_last_case( maybe_build_compound( yylloc, $2 ) ); }
1370 ;
1371
1372switch_clause_list_opt: // CFA
1373 // empty
1374 { $$ = nullptr; }
1375 | switch_clause_list
1376 ;
1377
1378switch_clause_list: // CFA
1379 case_label_list statement_list_nodecl
1380 { $$ = $1->append_last_case( new StatementNode( build_compound( yylloc, $2 ) ) ); }
1381 | switch_clause_list case_label_list statement_list_nodecl
1382 { $$ = $1->set_last( $2->append_last_case( new StatementNode( build_compound( yylloc, $3 ) ) ) ); }
1383 ;
1384
1385iteration_statement:
1386 WHILE '(' ')' statement %prec THEN // CFA => while ( 1 )
1387 { $$ = new StatementNode( build_while( yylloc, new CondCtl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) ); }
1388 | WHILE '(' ')' statement ELSE statement // CFA
1389 {
1390 $$ = new StatementNode( build_while( yylloc, new CondCtl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) );
1391 SemanticWarning( yylloc, Warning::SuperfluousElse );
1392 }
1393 | WHILE '(' conditional_declaration ')' statement %prec THEN
1394 { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1395 | WHILE '(' conditional_declaration ')' statement ELSE statement // CFA
1396 { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1397 | DO statement WHILE '(' ')' ';' // CFA => do while( 1 )
1398 { $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) ); }
1399 | DO statement WHILE '(' ')' ELSE statement // CFA
1400 {
1401 $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) );
1402 SemanticWarning( yylloc, Warning::SuperfluousElse );
1403 }
1404 | DO statement WHILE '(' comma_expression ')' ';'
1405 { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ) ) ); }
1406 | DO statement WHILE '(' comma_expression ')' ELSE statement // CFA
1407 { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ), $8 ) ); }
1408 | FOR '(' ')' statement %prec THEN // CFA => for ( ;; )
1409 { $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) ); }
1410 | FOR '(' ')' statement ELSE statement // CFA
1411 {
1412 $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) );
1413 SemanticWarning( yylloc, Warning::SuperfluousElse );
1414 }
1415 | FOR '(' for_control_expression_list ')' statement %prec THEN
1416 { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1417 | FOR '(' for_control_expression_list ')' statement ELSE statement // CFA
1418 { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1419 ;
1420
1421for_control_expression_list:
1422 for_control_expression
1423 | for_control_expression_list ':' for_control_expression
1424 // ForCtrl + ForCtrl:
1425 // init + init => multiple declaration statements that are hoisted
1426 // condition + condition => (expression) && (expression)
1427 // change + change => (expression), (expression)
1428 {
1429 $1->init->set_last( $3->init );
1430 if ( $1->condition ) {
1431 if ( $3->condition ) {
1432 $1->condition->expr.reset( new ast::LogicalExpr( yylloc, $1->condition->expr.release(), $3->condition->expr.release(), ast::AndExpr ) );
1433 } // if
1434 } else $1->condition = $3->condition;
1435 if ( $1->change ) {
1436 if ( $3->change ) {
1437 $1->change->expr.reset( new ast::CommaExpr( yylloc, $1->change->expr.release(), $3->change->expr.release() ) );
1438 } // if
1439 } else $1->change = $3->change;
1440 $$ = $1;
1441 }
1442 ;
1443
1444for_control_expression:
1445 ';' comma_expression_opt ';' comma_expression_opt
1446 { $$ = new ForCtrl( nullptr, $2, $4 ); }
1447 | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1448 {
1449 StatementNode * init = $1 ? new StatementNode( new ast::ExprStmt( yylloc, maybeMoveBuild( $1 ) ) ) : nullptr;
1450 $$ = new ForCtrl( init, $3, $5 );
1451 }
1452 | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1453 { $$ = new ForCtrl( new StatementNode( $1 ), $2, $4 ); }
1454
1455 | '@' ';' comma_expression // CFA, empty loop-index
1456 { $$ = new ForCtrl( nullptr, $3, nullptr ); }
1457 | '@' ';' comma_expression ';' comma_expression // CFA, empty loop-index
1458 { $$ = new ForCtrl( nullptr, $3, $5 ); }
1459
1460 | comma_expression // CFA, anonymous loop-index
1461 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), NEW_ZERO, OperKinds::LThan, $1->clone(), NEW_ONE ); }
1462 | downupdowneq comma_expression // CFA, anonymous loop-index
1463 { $$ = forCtrl( yylloc, $2, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $1, NEW_ZERO, $2->clone() ), $1, UPDOWN( $1, $2->clone(), NEW_ZERO ), NEW_ONE ); }
1464
1465 | comma_expression updowneq comma_expression // CFA, anonymous loop-index
1466 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), NEW_ONE ); }
1467 | '@' updowneq comma_expression // CFA, anonymous loop-index
1468 {
1469 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1470 else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, NEW_ONE );
1471 }
1472 | comma_expression updowneq '@' // CFA, anonymous loop-index
1473 {
1474 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1475 else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1476 }
1477 | comma_expression updowneq comma_expression '~' comma_expression // CFA, anonymous loop-index
1478 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), $5 ); }
1479 | '@' updowneq comma_expression '~' comma_expression // CFA, anonymous loop-index
1480 {
1481 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1482 else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, $5 );
1483 }
1484 | comma_expression updowneq '@' '~' comma_expression // CFA, anonymous loop-index
1485 {
1486 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1487 else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1488 }
1489 | comma_expression updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1490 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1491 | '@' updowneq '@' // CFA, invalid syntax rule
1492 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1493 | '@' updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1494 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1495 | comma_expression updowneq '@' '~' '@' // CFA, invalid syntax rule
1496 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1497 | '@' updowneq '@' '~' '@' // CFA, invalid syntax rule
1498 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1499
1500 | comma_expression ';' comma_expression // CFA
1501 { $$ = forCtrl( yylloc, $3, $1, NEW_ZERO, OperKinds::LThan, $3->clone(), NEW_ONE ); }
1502 | comma_expression ';' downupdowneq comma_expression // CFA
1503 { $$ = forCtrl( yylloc, $4, $1, UPDOWN( $3, NEW_ZERO, $4->clone() ), $3, UPDOWN( $3, $4->clone(), NEW_ZERO ), NEW_ONE ); }
1504
1505 | comma_expression ';' comma_expression updowneq comma_expression // CFA
1506 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), NEW_ONE ); }
1507 | comma_expression ';' '@' updowneq comma_expression // CFA
1508 {
1509 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1510 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, NEW_ONE );
1511 }
1512 | comma_expression ';' comma_expression updowneq '@' // CFA
1513 {
1514 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1515 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1516 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, NEW_ONE );
1517 }
1518 | comma_expression ';' '@' updowneq '@' // CFA, invalid syntax rule
1519 { SemanticError( yylloc, "syntax error, missing low/high value for up/down-to range so index is uninitialized." ); $$ = nullptr; }
1520
1521 | comma_expression ';' comma_expression updowneq comma_expression '~' comma_expression // CFA
1522 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), $7 ); }
1523 | comma_expression ';' '@' updowneq comma_expression '~' comma_expression // CFA, invalid syntax rule
1524 {
1525 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1526 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, $7 );
1527 }
1528 | comma_expression ';' comma_expression updowneq '@' '~' comma_expression // CFA
1529 {
1530 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1531 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1532 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, $7 );
1533 }
1534 | comma_expression ';' comma_expression updowneq comma_expression '~' '@' // CFA
1535 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), nullptr ); }
1536 | comma_expression ';' '@' updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1537 {
1538 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1539 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, nullptr );
1540 }
1541 | comma_expression ';' comma_expression updowneq '@' '~' '@' // CFA
1542 {
1543 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1544 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1545 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, nullptr );
1546 }
1547 | comma_expression ';' '@' updowneq '@' '~' '@' // CFA
1548 { SemanticError( yylloc, "syntax error, missing low/high value for up/down-to range so index is uninitialized." ); $$ = nullptr; }
1549
1550 | declaration comma_expression // CFA
1551 { $$ = forCtrl( yylloc, $1, NEW_ZERO, OperKinds::LThan, $2, NEW_ONE ); }
1552 | declaration downupdowneq comma_expression // CFA
1553 { $$ = forCtrl( yylloc, $1, UPDOWN( $2, NEW_ZERO, $3 ), $2, UPDOWN( $2, $3->clone(), NEW_ZERO ), NEW_ONE ); }
1554
1555 | declaration comma_expression updowneq comma_expression // CFA
1556 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2->clone(), $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), NEW_ONE ); }
1557 | declaration '@' updowneq comma_expression // CFA
1558 {
1559 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1560 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, NEW_ONE );
1561 }
1562 | declaration comma_expression updowneq '@' // CFA
1563 {
1564 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1565 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1566 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, NEW_ONE );
1567 }
1568
1569 | declaration comma_expression updowneq comma_expression '~' comma_expression // CFA
1570 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), $6 ); }
1571 | declaration '@' updowneq comma_expression '~' comma_expression // CFA
1572 {
1573 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1574 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, $6 );
1575 }
1576 | declaration comma_expression updowneq '@' '~' comma_expression // CFA
1577 {
1578 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1579 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1580 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, $6 );
1581 }
1582 | declaration comma_expression updowneq comma_expression '~' '@' // CFA
1583 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), nullptr ); }
1584 | declaration '@' updowneq comma_expression '~' '@' // CFA
1585 {
1586 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1587 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, nullptr );
1588 }
1589 | declaration comma_expression updowneq '@' '~' '@' // CFA
1590 {
1591 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1592 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1593 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, nullptr );
1594 }
1595 | declaration '@' updowneq '@' '~' '@' // CFA, invalid syntax rule
1596 { SemanticError( yylloc, "syntax error, missing low/high value for up/down-to range so index is uninitialized." ); $$ = nullptr; }
1597
1598 | comma_expression ';' TYPEDEFname // CFA, array type
1599 {
1600 SemanticError( yylloc, "Type iterator is currently unimplemented." ); $$ = nullptr;
1601 //$$ = forCtrl( new ExpressionNode( build_varref( $3 ) ), $1, nullptr, OperKinds::Range, nullptr, nullptr );
1602 }
1603 | comma_expression ';' downupdowneq TYPEDEFname // CFA, array type
1604 {
1605 if ( $3 == OperKinds::LEThan || $3 == OperKinds::GEThan ) {
1606 SemanticError( yylloc, "syntax error, all enumeration ranges are equal (all values). Remove \"=~\"." ); $$ = nullptr;
1607 }
1608 SemanticError( yylloc, "Type iterator is currently unimplemented." ); $$ = nullptr;
1609 }
1610 ;
1611
1612downupdowneq:
1613 ErangeDown
1614 { $$ = OperKinds::GThan; }
1615 | ErangeUpEq
1616 { $$ = OperKinds::LEThan; }
1617 | ErangeDownEq
1618 { $$ = OperKinds::GEThan; }
1619 ;
1620
1621updown:
1622 '~'
1623 { $$ = OperKinds::LThan; }
1624 | ErangeDown
1625 { $$ = OperKinds::GThan; }
1626 ;
1627
1628updowneq:
1629 updown
1630 | ErangeUpEq
1631 { $$ = OperKinds::LEThan; }
1632 | ErangeDownEq
1633 { $$ = OperKinds::GEThan; }
1634 ;
1635
1636jump_statement:
1637 GOTO identifier_or_type_name ';'
1638 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Goto ) ); }
1639 | GOTO '*' comma_expression ';' // GCC, computed goto
1640 // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1641 // whereas normal operator precedence yields goto (*i)+3;
1642 { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1643 // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1644 | fall_through_name ';' // CFA
1645 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThrough ) ); }
1646 | fall_through_name identifier_or_type_name ';' // CFA
1647 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::FallThrough ) ); }
1648 | fall_through_name DEFAULT ';' // CFA
1649 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThroughDefault ) ); }
1650 | CONTINUE ';'
1651 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1652 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Continue ) ); }
1653 | CONTINUE identifier_or_type_name ';' // CFA, multi-level continue
1654 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1655 // the target of the transfer appears only at the start of an iteration statement.
1656 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Continue ) ); }
1657 | BREAK ';'
1658 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1659 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Break ) ); }
1660 | BREAK identifier_or_type_name ';' // CFA, multi-level exit
1661 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1662 // the target of the transfer appears only at the start of an iteration statement.
1663 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Break ) ); }
1664 | RETURN comma_expression_opt ';'
1665 { $$ = new StatementNode( build_return( yylloc, $2 ) ); }
1666 | RETURN '{' initializer_list_opt comma_opt '}' ';'
1667 { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1668 | SUSPEND ';'
1669 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::None ) ); }
1670 | SUSPEND compound_statement
1671 { $$ = new StatementNode( build_suspend( yylloc, $2, ast::SuspendStmt::None ) ); }
1672 | SUSPEND COROUTINE ';'
1673 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Coroutine ) ); }
1674 | SUSPEND COROUTINE compound_statement
1675 { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Coroutine ) ); }
1676 | SUSPEND GENERATOR ';'
1677 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Generator ) ); }
1678 | SUSPEND GENERATOR compound_statement
1679 { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Generator ) ); }
1680 | THROW assignment_expression_opt ';' // handles rethrow
1681 { $$ = new StatementNode( build_throw( yylloc, $2 ) ); }
1682 | THROWRESUME assignment_expression_opt ';' // handles reresume
1683 { $$ = new StatementNode( build_resume( yylloc, $2 ) ); }
1684 | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1685 { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1686 ;
1687
1688fall_through_name: // CFA
1689 FALLTHRU
1690 | FALLTHROUGH
1691 ;
1692
1693with_statement:
1694 WITH '(' tuple_expression_list ')' statement
1695 { $$ = new StatementNode( build_with( yylloc, $3, $5 ) ); }
1696 ;
1697
1698// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so possibly change syntax to "with mutex".
1699mutex_statement:
1700 MUTEX '(' argument_expression_list_opt ')' statement
1701 {
1702 if ( ! $3 ) { SemanticError( yylloc, "syntax error, mutex argument list cannot be empty." ); $$ = nullptr; }
1703 $$ = new StatementNode( build_mutex( yylloc, $3, $5 ) );
1704 }
1705 ;
1706
1707when_clause:
1708 WHEN '(' comma_expression ')' { $$ = $3; }
1709 ;
1710
1711when_clause_opt:
1712 // empty
1713 { $$ = nullptr; }
1714 | when_clause
1715 ;
1716
1717cast_expression_list:
1718 cast_expression
1719 | cast_expression_list ',' cast_expression
1720 { SemanticError( yylloc, "List of mutex member is currently unimplemented." ); $$ = nullptr; }
1721 ;
1722
1723timeout:
1724 TIMEOUT '(' comma_expression ')' { $$ = $3; }
1725 ;
1726
1727wor:
1728 OROR
1729 | WOR
1730
1731waitfor:
1732 WAITFOR '(' cast_expression ')'
1733 { $$ = $3; }
1734 | WAITFOR '(' cast_expression_list ':' argument_expression_list_opt ')'
1735 { $$ = $3->set_last( $5 ); }
1736 ;
1737
1738wor_waitfor_clause:
1739 when_clause_opt waitfor statement %prec THEN
1740 // Called first: create header for WaitForStmt.
1741 { $$ = build_waitfor( yylloc, new ast::WaitForStmt( yylloc ), $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1742 | wor_waitfor_clause wor when_clause_opt waitfor statement
1743 { $$ = build_waitfor( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1744 | wor_waitfor_clause wor when_clause_opt ELSE statement
1745 { $$ = build_waitfor_else( yylloc, $1, $3, maybe_build_compound( yylloc, $5 ) ); }
1746 | wor_waitfor_clause wor when_clause_opt timeout statement %prec THEN
1747 { $$ = build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1748 // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1749 | wor_waitfor_clause wor when_clause_opt timeout statement wor ELSE statement // invalid syntax rule
1750 { SemanticError( yylloc, "syntax error, else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1751 | wor_waitfor_clause wor when_clause_opt timeout statement wor when_clause ELSE statement
1752 { $$ = build_waitfor_else( yylloc, build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ), $7, maybe_build_compound( yylloc, $9 ) ); }
1753 ;
1754
1755waitfor_statement:
1756 wor_waitfor_clause %prec THEN
1757 { $$ = new StatementNode( $1 ); }
1758 ;
1759
1760wand:
1761 ANDAND
1762 | WAND
1763 ;
1764
1765waituntil:
1766 WAITUNTIL '(' comma_expression ')'
1767 { $$ = $3; }
1768 ;
1769
1770waituntil_clause:
1771 when_clause_opt waituntil statement
1772 { $$ = build_waituntil_clause( yylloc, $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1773 | '(' wor_waituntil_clause ')'
1774 { $$ = $2; }
1775 ;
1776
1777wand_waituntil_clause:
1778 waituntil_clause %prec THEN
1779 { $$ = $1; }
1780 | waituntil_clause wand wand_waituntil_clause
1781 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::AND, $1, $3 ); }
1782 ;
1783
1784wor_waituntil_clause:
1785 wand_waituntil_clause
1786 { $$ = $1; }
1787 | wor_waituntil_clause wor wand_waituntil_clause
1788 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::OR, $1, $3 ); }
1789 | wor_waituntil_clause wor when_clause_opt ELSE statement
1790 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::LEFT_OR, $1, build_waituntil_else( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1791 ;
1792
1793waituntil_statement:
1794 wor_waituntil_clause %prec THEN
1795 { $$ = new StatementNode( build_waituntil_stmt( yylloc, $1 ) ); }
1796 ;
1797
1798corun_statement:
1799 CORUN statement
1800 { $$ = new StatementNode( build_corun( yylloc, $2 ) ); }
1801 ;
1802
1803cofor_statement:
1804 COFOR '(' for_control_expression_list ')' statement
1805 { $$ = new StatementNode( build_cofor( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1806 ;
1807
1808exception_statement:
1809 TRY compound_statement handler_clause %prec THEN
1810 { $$ = new StatementNode( build_try( yylloc, $2, $3, nullptr ) ); }
1811 | TRY compound_statement finally_clause
1812 { $$ = new StatementNode( build_try( yylloc, $2, nullptr, $3 ) ); }
1813 | TRY compound_statement handler_clause finally_clause
1814 { $$ = new StatementNode( build_try( yylloc, $2, $3, $4 ) ); }
1815 ;
1816
1817handler_clause:
1818 handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1819 { $$ = new ClauseNode( build_catch( yylloc, $1, $4, $6, $8 ) ); }
1820 | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1821 { $$ = $1->set_last( new ClauseNode( build_catch( yylloc, $2, $5, $7, $9 ) ) ); }
1822 ;
1823
1824handler_predicate_opt:
1825 // empty
1826 { $$ = nullptr; }
1827 | ';' conditional_expression { $$ = $2; }
1828 ;
1829
1830handler_key:
1831 CATCH { $$ = ast::Terminate; }
1832 | RECOVER { $$ = ast::Terminate; }
1833 | CATCHRESUME { $$ = ast::Resume; }
1834 | FIXUP { $$ = ast::Resume; }
1835 ;
1836
1837finally_clause:
1838 FINALLY compound_statement { $$ = new ClauseNode( build_finally( yylloc, $2 ) ); }
1839 ;
1840
1841exception_declaration:
1842 // No SUE declaration in parameter list.
1843 type_specifier_nobody
1844 | type_specifier_nobody declarator
1845 { $$ = $2->addType( $1 ); }
1846 | type_specifier_nobody variable_abstract_declarator
1847 { $$ = $2->addType( $1 ); }
1848 | cfa_abstract_declarator_tuple identifier // CFA
1849 { $$ = $1->addName( $2 ); }
1850 | cfa_abstract_declarator_tuple // CFA
1851 ;
1852
1853enable_disable_statement:
1854 enable_disable_key identifier_list compound_statement
1855 ;
1856
1857enable_disable_key:
1858 ENABLE
1859 | DISABLE
1860 ;
1861
1862asm_statement:
1863 ASM asm_volatile_opt '(' string_literal ')' ';'
1864 { $$ = new StatementNode( build_asm( yylloc, $2, $4, nullptr ) ); }
1865 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1866 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6 ) ); }
1867 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1868 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8 ) ); }
1869 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1870 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8, $10 ) ); }
1871 | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1872 { $$ = new StatementNode( build_asm( yylloc, $2, $5, nullptr, $8, $10, $12 ) ); }
1873 ;
1874
1875asm_volatile_opt: // GCC
1876 // empty
1877 { $$ = false; }
1878 | VOLATILE
1879 { $$ = true; }
1880 ;
1881
1882asm_operands_opt: // GCC
1883 // empty
1884 { $$ = nullptr; } // use default argument
1885 | asm_operands_list
1886 ;
1887
1888asm_operands_list: // GCC
1889 asm_operand
1890 | asm_operands_list ',' asm_operand
1891 { $$ = $1->set_last( $3 ); }
1892 ;
1893
1894asm_operand: // GCC
1895 string_literal '(' constant_expression ')'
1896 { $$ = new ExpressionNode( new ast::AsmExpr( yylloc, "", maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1897 | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1898 {
1899 $$ = new ExpressionNode( new ast::AsmExpr( yylloc, *$2.str, maybeMoveBuild( $4 ), maybeMoveBuild( $6 ) ) );
1900 delete $2.str;
1901 }
1902 ;
1903
1904asm_clobbers_list_opt: // GCC
1905 // empty
1906 { $$ = nullptr; } // use default argument
1907 | string_literal
1908 { $$ = $1; }
1909 | asm_clobbers_list_opt ',' string_literal
1910 { $$ = $1->set_last( $3 ); }
1911 ;
1912
1913label_list:
1914 identifier
1915 {
1916 $$ = new LabelNode(); $$->labels.emplace_back( yylloc, *$1 );
1917 delete $1; // allocated by lexer
1918 }
1919 | label_list ',' identifier
1920 {
1921 $$ = $1; $1->labels.emplace_back( yylloc, *$3 );
1922 delete $3; // allocated by lexer
1923 }
1924 ;
1925
1926// ****************************** DECLARATIONS *********************************
1927
1928declaration_list_opt: // used at beginning of switch statement
1929 // empty
1930 { $$ = nullptr; }
1931 | declaration_list
1932 ;
1933
1934declaration_list:
1935 declaration
1936 | declaration_list declaration
1937 { $$ = $1->set_last( $2 ); }
1938 ;
1939
1940KR_parameter_list_opt: // used to declare parameter types in K&R style functions
1941 // empty
1942 { $$ = nullptr; }
1943 | KR_parameter_list
1944 ;
1945
1946KR_parameter_list:
1947 c_declaration ';'
1948 { $$ = $1; }
1949 | KR_parameter_list c_declaration ';'
1950 { $$ = $1->set_last( $2 ); }
1951 ;
1952
1953local_label_declaration_opt: // GCC, local label
1954 // empty
1955 | local_label_declaration_list
1956 ;
1957
1958local_label_declaration_list: // GCC, local label
1959 LABEL local_label_list ';'
1960 | local_label_declaration_list LABEL local_label_list ';'
1961 ;
1962
1963local_label_list: // GCC, local label
1964 identifier_or_type_name
1965 | local_label_list ',' identifier_or_type_name
1966 ;
1967
1968declaration: // old & new style declarations
1969 c_declaration ';'
1970 | cfa_declaration ';' // CFA
1971 | static_assert // C11
1972 ;
1973
1974static_assert:
1975 STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1976 { $$ = DeclarationNode::newStaticAssert( $3, maybeMoveBuild( $5 ) ); }
1977 | STATICASSERT '(' constant_expression ')' ';' // CFA
1978 { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( yylloc, *new string( "\"\"" ) ) ); }
1979
1980// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1981// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1982// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1983// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1984// the declaration list (as in Pascal). ANSI C and the new CFA declarations may appear together in the same program
1985// block, but cannot be mixed within a specific declaration.
1986//
1987// CFA C
1988// [10] int x; int x[10]; // array of 10 integers
1989// [10] * char y; char *y[10]; // array of 10 pointers to char
1990
1991cfa_declaration: // CFA
1992 cfa_variable_declaration
1993 | cfa_typedef_declaration
1994 | cfa_function_declaration
1995 | type_declaring_list
1996 { SemanticError( yylloc, "otype declaration is currently unimplemented." ); $$ = nullptr; }
1997 | trait_specifier
1998 ;
1999
2000cfa_variable_declaration: // CFA
2001 cfa_variable_specifier initializer_opt
2002 { $$ = $1->addInitializer( $2 ); }
2003 | declaration_qualifier_list cfa_variable_specifier initializer_opt
2004 // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
2005 // them as a type_qualifier cannot appear in that context.
2006 { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
2007 | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
2008 { $$ = $1->set_last( $1->cloneType( $5 )->addInitializer( $6 ) ); }
2009 ;
2010
2011cfa_variable_specifier: // CFA
2012 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
2013 // storage-class
2014 cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
2015 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
2016 | cfa_abstract_tuple identifier_or_type_name asm_name_opt
2017 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
2018 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
2019 { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
2020 ;
2021
2022cfa_function_declaration: // CFA
2023 cfa_function_specifier
2024 | type_qualifier_list cfa_function_specifier
2025 { $$ = $2->addQualifiers( $1 ); }
2026 | declaration_qualifier_list cfa_function_specifier
2027 { $$ = $2->addQualifiers( $1 ); }
2028 | declaration_qualifier_list type_qualifier_list cfa_function_specifier
2029 { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
2030 | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')'
2031 {
2032 // Append the return type at the start (left-hand-side) to each identifier in the list.
2033 DeclarationNode * ret = new DeclarationNode;
2034 ret->type = maybeCopy( $1->type->base );
2035 $$ = $1->set_last( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
2036 }
2037 ;
2038
2039cfa_function_specifier: // CFA
2040 '[' ']' identifier '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2041 { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2042 | '[' ']' TYPEDEFname '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2043 { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2044 // | '[' ']' TYPEGENname '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2045 // { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2046
2047 // identifier_or_type_name must be broken apart because of the sequence:
2048 //
2049 // '[' ']' identifier_or_type_name '(' cfa_parameter_list_ellipsis_opt ')'
2050 // '[' ']' type_specifier
2051 //
2052 // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
2053 // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
2054 | cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2055 // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
2056 { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
2057 | cfa_function_return identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2058 { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
2059 ;
2060
2061cfa_function_return: // CFA
2062 '[' push cfa_parameter_list pop ']'
2063 { $$ = DeclarationNode::newTuple( $3 ); }
2064 | '[' push cfa_parameter_list ',' cfa_abstract_parameter_list pop ']'
2065 // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
2066 { $$ = DeclarationNode::newTuple( $3->set_last( $5 ) ); }
2067 ;
2068
2069cfa_typedef_declaration: // CFA
2070 TYPEDEF cfa_variable_specifier
2071 {
2072 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "cfa_typedef_declaration 1" );
2073 $$ = $2->addTypedef();
2074 }
2075 | TYPEDEF cfa_function_specifier
2076 {
2077 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "cfa_typedef_declaration 2" );
2078 $$ = $2->addTypedef();
2079 }
2080 | cfa_typedef_declaration ',' identifier
2081 {
2082 typedefTable.addToEnclosingScope( *$3, TYPEDEFname, "cfa_typedef_declaration 3" );
2083 $$ = $1->set_last( $1->cloneType( $3 ) );
2084 }
2085 ;
2086
2087// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
2088// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
2089
2090typedef_declaration:
2091 TYPEDEF type_specifier declarator
2092 {
2093 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "typedef_declaration 1" );
2094 if ( $2->type->forall || ($2->type->kind == TypeData::Aggregate && $2->type->aggregate.params) ) {
2095 SemanticError( yylloc, "forall qualifier in typedef is currently unimplemented." ); $$ = nullptr;
2096 } else $$ = $3->addType( $2 )->addTypedef(); // watchout frees $2 and $3
2097 }
2098 | typedef_declaration ',' declarator
2099 {
2100 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "typedef_declaration 2" );
2101 $$ = $1->set_last( $1->cloneBaseType( $3 )->addTypedef() );
2102 }
2103 | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
2104 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2105 | type_specifier TYPEDEF declarator
2106 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2107 | type_specifier TYPEDEF type_qualifier_list declarator
2108 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2109 ;
2110
2111typedef_expression:
2112 // deprecated GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
2113 TYPEDEF identifier '=' assignment_expression
2114 {
2115 SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
2116 }
2117 | typedef_expression ',' identifier '=' assignment_expression
2118 {
2119 SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
2120 }
2121 ;
2122
2123c_declaration:
2124 declaration_specifier declaring_list
2125 { $$ = distAttr( $1, $2 ); }
2126 | typedef_declaration
2127 | typedef_expression // deprecated GCC, naming expression type
2128 | sue_declaration_specifier
2129 {
2130 assert( $1->type );
2131 if ( $1->type->qualifiers.any() ) { // CV qualifiers ?
2132 SemanticError( yylloc, "syntax error, useless type qualifier(s) in empty declaration." ); $$ = nullptr;
2133 }
2134 // enums are never empty declarations because there must have at least one enumeration.
2135 if ( $1->type->kind == TypeData::AggregateInst && $1->storageClasses.any() ) { // storage class ?
2136 SemanticError( yylloc, "syntax error, useless storage qualifier(s) in empty aggregate declaration." ); $$ = nullptr;
2137 }
2138 }
2139 ;
2140
2141declaring_list:
2142 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
2143 // storage-class
2144 variable_declarator asm_name_opt initializer_opt
2145 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2146 | variable_type_redeclarator asm_name_opt initializer_opt
2147 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2148
2149 | general_function_declarator asm_name_opt
2150 { $$ = $1->addAsmName( $2 )->addInitializer( nullptr ); }
2151 | general_function_declarator asm_name_opt '=' VOID
2152 { $$ = $1->addAsmName( $2 )->addInitializer( new InitializerNode( true ) ); }
2153
2154 | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
2155 { $$ = $1->set_last( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
2156 ;
2157
2158general_function_declarator:
2159 function_type_redeclarator
2160 | function_declarator
2161 ;
2162
2163declaration_specifier: // type specifier + storage class
2164 basic_declaration_specifier
2165 | type_declaration_specifier
2166 | sue_declaration_specifier
2167 | sue_declaration_specifier invalid_types // invalid syntax rule
2168 {
2169 SemanticError( yylloc, "syntax error, expecting ';' at end of \"%s\" declaration.",
2170 $1->type->enumeration.name ? "enum" : ast::AggregateDecl::aggrString( $1->type->aggregate.kind ) );
2171 $$ = nullptr;
2172 }
2173 ;
2174
2175invalid_types:
2176 aggregate_key
2177 | basic_type_name
2178 | indirect_type
2179 ;
2180
2181declaration_specifier_nobody: // type specifier + storage class - {...}
2182 // Preclude SUE declarations in restricted scopes:
2183 //
2184 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2185 //
2186 // because it is impossible to call f due to name equivalence.
2187 basic_declaration_specifier
2188 | sue_declaration_specifier_nobody
2189 | type_declaration_specifier
2190 ;
2191
2192type_specifier: // type specifier
2193 basic_type_specifier
2194 | sue_type_specifier
2195 | type_type_specifier
2196 ;
2197
2198type_specifier_nobody: // type specifier - {...}
2199 // Preclude SUE declarations in restricted scopes:
2200 //
2201 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2202 //
2203 // because it is impossible to call f due to name equivalence.
2204 basic_type_specifier
2205 | sue_type_specifier_nobody
2206 | type_type_specifier
2207 ;
2208
2209type_qualifier_list_opt: // GCC, used in asm_statement
2210 // empty
2211 { $$ = nullptr; }
2212 | type_qualifier_list
2213 ;
2214
2215type_qualifier_list:
2216 // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
2217 //
2218 // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
2219 // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
2220 // appeared only once.
2221 type_qualifier
2222 | type_qualifier_list type_qualifier
2223 { $$ = $1->addQualifiers( $2 ); }
2224 ;
2225
2226type_qualifier:
2227 type_qualifier_name
2228 { $$ = DeclarationNode::newFromTypeData( $1 ); }
2229 | attribute // trick handles most attribute locations
2230 ;
2231
2232type_qualifier_name:
2233 CONST
2234 { $$ = build_type_qualifier( ast::CV::Const ); }
2235 | RESTRICT
2236 { $$ = build_type_qualifier( ast::CV::Restrict ); }
2237 | VOLATILE
2238 { $$ = build_type_qualifier( ast::CV::Volatile ); }
2239 | ATOMIC
2240 { $$ = build_type_qualifier( ast::CV::Atomic ); }
2241
2242 // forall must be a CV qualifier because it can appear in places where SC qualifiers are disallowed.
2243 //
2244 // void foo( forall( T ) T (*)( T ) ); // forward declaration
2245 // void bar( static int ); // static disallowed (gcc/CFA)
2246 | forall
2247 { $$ = build_forall( $1 ); }
2248 ;
2249
2250forall:
2251 FORALL '(' type_parameter_list ')' // CFA
2252 { $$ = $3; }
2253 ;
2254
2255declaration_qualifier_list:
2256 storage_class_list
2257 | type_qualifier_list storage_class_list // remaining OBSOLESCENT (see 2 )
2258 { $$ = $1->addQualifiers( $2 ); }
2259 | declaration_qualifier_list type_qualifier_list storage_class_list
2260 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2261 ;
2262
2263storage_class_list:
2264 // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
2265 // only one of each is specified, except for inline, which can appear with the others.
2266 //
2267 // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
2268 // specifiers in a declaration.
2269 storage_class
2270 | storage_class_list storage_class
2271 { $$ = $1->addQualifiers( $2 ); }
2272 ;
2273
2274storage_class:
2275 EXTERN
2276 { $$ = DeclarationNode::newStorageClass( ast::Storage::Extern ); }
2277 | STATIC
2278 { $$ = DeclarationNode::newStorageClass( ast::Storage::Static ); }
2279 | AUTO
2280 { $$ = DeclarationNode::newStorageClass( ast::Storage::Auto ); }
2281 | REGISTER
2282 { $$ = DeclarationNode::newStorageClass( ast::Storage::Register ); }
2283 | THREADLOCALGCC // GCC
2284 { $$ = DeclarationNode::newStorageClass( ast::Storage::ThreadLocalGcc ); }
2285 | THREADLOCALC11 // C11
2286 { $$ = DeclarationNode::newStorageClass( ast::Storage::ThreadLocalC11 ); }
2287 // Put function specifiers here to simplify parsing rules, but separate them semantically.
2288 | INLINE // C99
2289 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Inline ); }
2290 | FORTRAN // C99
2291 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Fortran ); }
2292 | NORETURN // C11
2293 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Noreturn ); }
2294 ;
2295
2296basic_type_name:
2297 basic_type_name_type
2298 { $$ = DeclarationNode::newFromTypeData( $1 ); }
2299 ;
2300
2301// Just an intermediate value for conversion.
2302basic_type_name_type:
2303 VOID
2304 { $$ = build_basic_type( DeclarationNode::Void ); }
2305 | BOOL // C99
2306 { $$ = build_basic_type( DeclarationNode::Bool ); }
2307 | CHAR
2308 { $$ = build_basic_type( DeclarationNode::Char ); }
2309 | INT
2310 { $$ = build_basic_type( DeclarationNode::Int ); }
2311 | INT128
2312 { $$ = build_basic_type( DeclarationNode::Int128 ); }
2313 | UINT128
2314 { $$ = addType( build_basic_type( DeclarationNode::Int128 ), build_signedness( DeclarationNode::Unsigned ) ); }
2315 | FLOAT
2316 { $$ = build_basic_type( DeclarationNode::Float ); }
2317 | DOUBLE
2318 { $$ = build_basic_type( DeclarationNode::Double ); }
2319 | uuFLOAT80
2320 { $$ = build_basic_type( DeclarationNode::uuFloat80 ); }
2321 | uuFLOAT128
2322 { $$ = build_basic_type( DeclarationNode::uuFloat128 ); }
2323 | uFLOAT16
2324 { $$ = build_basic_type( DeclarationNode::uFloat16 ); }
2325 | uFLOAT32
2326 { $$ = build_basic_type( DeclarationNode::uFloat32 ); }
2327 | uFLOAT32X
2328 { $$ = build_basic_type( DeclarationNode::uFloat32x ); }
2329 | uFLOAT64
2330 { $$ = build_basic_type( DeclarationNode::uFloat64 ); }
2331 | uFLOAT64X
2332 { $$ = build_basic_type( DeclarationNode::uFloat64x ); }
2333 | uFLOAT128
2334 { $$ = build_basic_type( DeclarationNode::uFloat128 ); }
2335 | DECIMAL32
2336 { SemanticError( yylloc, "_Decimal32 is currently unimplemented." ); $$ = nullptr; }
2337 | DECIMAL64
2338 { SemanticError( yylloc, "_Decimal64 is currently unimplemented." ); $$ = nullptr; }
2339 | DECIMAL128
2340 { SemanticError( yylloc, "_Decimal128 is currently unimplemented." ); $$ = nullptr; }
2341 | COMPLEX // C99
2342 { $$ = build_complex_type( DeclarationNode::Complex ); }
2343 | IMAGINARY // C99
2344 { $$ = build_complex_type( DeclarationNode::Imaginary ); }
2345 | SIGNED
2346 { $$ = build_signedness( DeclarationNode::Signed ); }
2347 | UNSIGNED
2348 { $$ = build_signedness( DeclarationNode::Unsigned ); }
2349 | SHORT
2350 { $$ = build_length( DeclarationNode::Short ); }
2351 | LONG
2352 { $$ = build_length( DeclarationNode::Long ); }
2353 | VA_LIST // GCC, __builtin_va_list
2354 { $$ = build_builtin_type( DeclarationNode::Valist ); }
2355 | AUTO_TYPE
2356 { $$ = build_builtin_type( DeclarationNode::AutoType ); }
2357 | vtable
2358 ;
2359
2360vtable_opt:
2361 // empty
2362 { $$ = nullptr; }
2363 | vtable
2364 ;
2365
2366vtable:
2367 VTABLE '(' type_name ')' default_opt
2368 { $$ = build_vtable_type( $3 ); }
2369 ;
2370
2371default_opt:
2372 // empty
2373 { $$ = nullptr; }
2374 | DEFAULT
2375 { SemanticError( yylloc, "vtable default is currently unimplemented." ); $$ = nullptr; }
2376 ;
2377
2378basic_declaration_specifier:
2379 // A semantic check is necessary for conflicting storage classes.
2380 basic_type_specifier
2381 | declaration_qualifier_list basic_type_specifier
2382 { $$ = $2->addQualifiers( $1 ); }
2383 | basic_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2384 { $$ = $1->addQualifiers( $2 ); }
2385 | basic_declaration_specifier storage_class type_qualifier_list
2386 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2387 | basic_declaration_specifier storage_class basic_type_specifier
2388 { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
2389 ;
2390
2391basic_type_specifier:
2392 direct_type
2393 // Cannot have type modifiers, e.g., short, long, etc.
2394 | type_qualifier_list_opt indirect_type type_qualifier_list_opt
2395 { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
2396 ;
2397
2398direct_type:
2399 basic_type_name
2400 | type_qualifier_list basic_type_name
2401 { $$ = $2->addQualifiers( $1 ); }
2402 | direct_type type_qualifier
2403 { $$ = $1->addQualifiers( $2 ); }
2404 | direct_type basic_type_name
2405 { $$ = $1->addType( $2 ); }
2406 ;
2407
2408indirect_type:
2409 TYPEOF '(' type ')' // GCC: typeof( x ) y;
2410 { $$ = $3; }
2411 | TYPEOF '(' comma_expression ')' // GCC: typeof( a+b ) y;
2412 { $$ = DeclarationNode::newTypeof( $3 ); }
2413 | BASETYPEOF '(' type ')' // CFA: basetypeof( x ) y;
2414 { $$ = DeclarationNode::newTypeof( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ), true ); }
2415 | BASETYPEOF '(' comma_expression ')' // CFA: basetypeof( a+b ) y;
2416 { $$ = DeclarationNode::newTypeof( $3, true ); }
2417 | ZERO_T // CFA
2418 { $$ = DeclarationNode::newFromTypeData( build_builtin_type( DeclarationNode::Zero ) ); }
2419 | ONE_T // CFA
2420 { $$ = DeclarationNode::newFromTypeData( build_builtin_type( DeclarationNode::One ) ); }
2421 ;
2422
2423sue_declaration_specifier: // struct, union, enum + storage class + type specifier
2424 sue_type_specifier
2425 | declaration_qualifier_list sue_type_specifier
2426 { $$ = $2->addQualifiers( $1 ); }
2427 | sue_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2428 { $$ = $1->addQualifiers( $2 ); }
2429 | sue_declaration_specifier storage_class type_qualifier_list
2430 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2431 ;
2432
2433sue_type_specifier: // struct, union, enum + type specifier
2434 elaborated_type
2435 | type_qualifier_list
2436 { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
2437 elaborated_type
2438 { $$ = $3->addQualifiers( $1 ); }
2439 | sue_type_specifier type_qualifier
2440 {
2441 if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
2442 $$ = $1->addQualifiers( $2 );
2443 }
2444 ;
2445
2446sue_declaration_specifier_nobody: // struct, union, enum - {...} + storage class + type specifier
2447 sue_type_specifier_nobody
2448 | declaration_qualifier_list sue_type_specifier_nobody
2449 { $$ = $2->addQualifiers( $1 ); }
2450 | sue_declaration_specifier_nobody storage_class // remaining OBSOLESCENT (see 2)
2451 { $$ = $1->addQualifiers( $2 ); }
2452 | sue_declaration_specifier_nobody storage_class type_qualifier_list
2453 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2454 ;
2455
2456sue_type_specifier_nobody: // struct, union, enum - {...} + type specifier
2457 elaborated_type_nobody
2458 | type_qualifier_list elaborated_type_nobody
2459 { $$ = $2->addQualifiers( $1 ); }
2460 | sue_type_specifier_nobody type_qualifier
2461 { $$ = $1->addQualifiers( $2 ); }
2462 ;
2463
2464type_declaration_specifier:
2465 type_type_specifier
2466 | declaration_qualifier_list type_type_specifier
2467 { $$ = $2->addQualifiers( $1 ); }
2468 | type_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2469 { $$ = $1->addQualifiers( $2 ); }
2470 | type_declaration_specifier storage_class type_qualifier_list
2471 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2472 ;
2473
2474type_type_specifier: // typedef types
2475 type_name
2476 { $$ = DeclarationNode::newFromTypeData( $1 ); }
2477 | type_qualifier_list type_name
2478 { $$ = DeclarationNode::newFromTypeData( $2 )->addQualifiers( $1 ); }
2479 | type_type_specifier type_qualifier
2480 { $$ = $1->addQualifiers( $2 ); }
2481 ;
2482
2483type_name:
2484 TYPEDEFname
2485 { $$ = build_typedef( $1 ); }
2486 | '.' TYPEDEFname
2487 { $$ = build_qualified_type( build_global_scope(), build_typedef( $2 ) ); }
2488 | type_name '.' TYPEDEFname
2489 { $$ = build_qualified_type( $1, build_typedef( $3 ) ); }
2490 | typegen_name
2491 | '.' typegen_name
2492 { $$ = build_qualified_type( build_global_scope(), $2 ); }
2493 | type_name '.' typegen_name
2494 { $$ = build_qualified_type( $1, $3 ); }
2495 ;
2496
2497typegen_name: // CFA
2498 TYPEGENname
2499 { $$ = build_type_gen( $1, nullptr ); }
2500 | TYPEGENname '(' ')'
2501 { $$ = build_type_gen( $1, nullptr ); }
2502 | TYPEGENname '(' type_list ')'
2503 { $$ = build_type_gen( $1, $3 ); }
2504 ;
2505
2506elaborated_type: // struct, union, enum
2507 aggregate_type
2508 | enum_type
2509 ;
2510
2511elaborated_type_nobody: // struct, union, enum - {...}
2512 aggregate_type_nobody
2513 | enum_type_nobody
2514 ;
2515
2516// ************************** AGGREGATE *******************************
2517
2518aggregate_type: // struct, union
2519 aggregate_key attribute_list_opt
2520 { forall = false; } // reset
2521 '{' field_declaration_list_opt '}' type_parameters_opt
2522 { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2523 | aggregate_key attribute_list_opt identifier
2524 {
2525 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 1" );
2526 forall = false; // reset
2527 }
2528 '{' field_declaration_list_opt '}' type_parameters_opt
2529 {
2530 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2531 }
2532 | aggregate_key attribute_list_opt TYPEDEFname // unqualified type name
2533 {
2534 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 2" );
2535 forall = false; // reset
2536 }
2537 '{' field_declaration_list_opt '}' type_parameters_opt
2538 {
2539 DeclarationNode::newFromTypeData( build_typedef( $3 ) );
2540 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2541 }
2542 | aggregate_key attribute_list_opt TYPEGENname // unqualified type name
2543 {
2544 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 3" );
2545 forall = false; // reset
2546 }
2547 '{' field_declaration_list_opt '}' type_parameters_opt
2548 {
2549 DeclarationNode::newFromTypeData( build_type_gen( $3, nullptr ) );
2550 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2551 }
2552 | aggregate_type_nobody
2553 ;
2554
2555type_parameters_opt:
2556 // empty
2557 { $$ = nullptr; } %prec '}'
2558 | '(' type_list ')'
2559 { $$ = $2; }
2560 ;
2561
2562aggregate_type_nobody: // struct, union - {...}
2563 aggregate_key attribute_list_opt identifier
2564 {
2565 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type_nobody" );
2566 forall = false; // reset
2567 $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2568 }
2569 | aggregate_key attribute_list_opt type_name
2570 {
2571 forall = false; // reset
2572 // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2573 // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2574 if ( $3->kind == TypeData::SymbolicInst && ! $3->symbolic.isTypedef ) {
2575 $$ = DeclarationNode::newFromTypeData( $3 )->addQualifiers( $2 );
2576 } else {
2577 $$ = DeclarationNode::newAggregate( $1, $3->symbolic.name, $3->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2578 $3->symbolic.name = nullptr; // copied to $$
2579 $3->symbolic.actuals = nullptr;
2580 delete $3;
2581 }
2582 }
2583 ;
2584
2585aggregate_key:
2586 aggregate_data
2587 | aggregate_control
2588 ;
2589
2590aggregate_data:
2591 STRUCT vtable_opt
2592 { $$ = ast::AggregateDecl::Struct; }
2593 | UNION
2594 { $$ = ast::AggregateDecl::Union; }
2595 | EXCEPTION // CFA
2596 { $$ = ast::AggregateDecl::Exception; }
2597 ;
2598
2599aggregate_control: // CFA
2600 MONITOR
2601 { $$ = ast::AggregateDecl::Monitor; }
2602 | MUTEX STRUCT
2603 { $$ = ast::AggregateDecl::Monitor; }
2604 | GENERATOR
2605 { $$ = ast::AggregateDecl::Generator; }
2606 | MUTEX GENERATOR
2607 {
2608 SemanticError( yylloc, "monitor generator is currently unimplemented." );
2609 $$ = ast::AggregateDecl::NoAggregate;
2610 }
2611 | COROUTINE
2612 { $$ = ast::AggregateDecl::Coroutine; }
2613 | MUTEX COROUTINE
2614 {
2615 SemanticError( yylloc, "monitor coroutine is currently unimplemented." );
2616 $$ = ast::AggregateDecl::NoAggregate;
2617 }
2618 | THREAD
2619 { $$ = ast::AggregateDecl::Thread; }
2620 | MUTEX THREAD
2621 {
2622 SemanticError( yylloc, "monitor thread is currently unimplemented." );
2623 $$ = ast::AggregateDecl::NoAggregate;
2624 }
2625 ;
2626
2627field_declaration_list_opt:
2628 // empty
2629 { $$ = nullptr; }
2630 | field_declaration_list_opt field_declaration
2631 { $$ = $1 ? $1->set_last( $2 ) : $2; }
2632 ;
2633
2634field_declaration:
2635 type_specifier field_declaring_list_opt ';'
2636 {
2637 // printf( "type_specifier1 %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2638 $$ = fieldDecl( $1, $2 );
2639 // printf( "type_specifier2 %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2640 // for ( Attribute * attr: reverseIterate( $$->attributes ) ) {
2641 // printf( "\tattr %s\n", attr->name.c_str() );
2642 // } // for
2643 }
2644 | type_specifier field_declaring_list_opt '}' // invalid syntax rule
2645 {
2646 SemanticError( yylloc, "syntax error, expecting ';' at end of previous declaration." );
2647 $$ = nullptr;
2648 }
2649 | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2650 { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2651 | STATIC type_specifier field_declaring_list_opt ';' // CFA
2652 { SemanticError( yylloc, "STATIC aggregate field qualifier currently unimplemented." ); $$ = nullptr; }
2653 | INLINE type_specifier field_abstract_list_opt ';' // CFA
2654 {
2655 if ( ! $3 ) { // field declarator ?
2656 $3 = DeclarationNode::newName( nullptr );
2657 } // if
2658 $3->inLine = true;
2659 $$ = distAttr( $2, $3 ); // mark all fields in list
2660 distInl( $3 );
2661 }
2662 | INLINE aggregate_control ';' // CFA
2663 { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2664 | typedef_declaration ';' // CFA
2665 | cfa_field_declaring_list ';' // CFA, new style field declaration
2666 | EXTENSION cfa_field_declaring_list ';' // GCC
2667 { distExt( $2 ); $$ = $2; } // mark all fields in list
2668 | INLINE cfa_field_abstract_list ';' // CFA, new style field declaration
2669 { $$ = $2; } // mark all fields in list
2670 | cfa_typedef_declaration ';' // CFA
2671 | static_assert // C11
2672 ;
2673
2674field_declaring_list_opt:
2675 // empty
2676 { $$ = nullptr; }
2677 | field_declarator
2678 | field_declaring_list_opt ',' attribute_list_opt field_declarator
2679 { $$ = $1->set_last( $4->addQualifiers( $3 ) ); }
2680 ;
2681
2682field_declarator:
2683 bit_subrange_size // C special case, no field name
2684 { $$ = DeclarationNode::newBitfield( $1 ); }
2685 | variable_declarator bit_subrange_size_opt
2686 // A semantic check is required to ensure bit_subrange only appears on integral types.
2687 { $$ = $1->addBitfield( $2 ); }
2688 | variable_type_redeclarator bit_subrange_size_opt
2689 // A semantic check is required to ensure bit_subrange only appears on integral types.
2690 { $$ = $1->addBitfield( $2 ); }
2691 | function_type_redeclarator bit_subrange_size_opt
2692 // A semantic check is required to ensure bit_subrange only appears on integral types.
2693 { $$ = $1->addBitfield( $2 ); }
2694 ;
2695
2696field_abstract_list_opt:
2697 // empty
2698 { $$ = nullptr; }
2699 | field_abstract
2700 | field_abstract_list_opt ',' attribute_list_opt field_abstract
2701 { $$ = $1->set_last( $4->addQualifiers( $3 ) ); }
2702 ;
2703
2704field_abstract:
2705 // no bit fields
2706 variable_abstract_declarator
2707 ;
2708
2709cfa_field_declaring_list: // CFA, new style field declaration
2710 // bit-fields are handled by C declarations
2711 cfa_abstract_declarator_tuple identifier_or_type_name
2712 { $$ = $1->addName( $2 ); }
2713 | cfa_field_declaring_list ',' identifier_or_type_name
2714 { $$ = $1->set_last( $1->cloneType( $3 ) ); }
2715 ;
2716
2717cfa_field_abstract_list: // CFA, new style field declaration
2718 // bit-fields are handled by C declarations
2719 cfa_abstract_declarator_tuple
2720 | cfa_field_abstract_list ','
2721 { $$ = $1->set_last( $1->cloneType( 0 ) ); }
2722 ;
2723
2724bit_subrange_size_opt:
2725 // empty
2726 { $$ = nullptr; }
2727 | bit_subrange_size
2728 ;
2729
2730bit_subrange_size:
2731 ':' assignment_expression
2732 { $$ = $2; }
2733 ;
2734
2735// ************************** ENUMERATION *******************************
2736
2737enum_type:
2738 ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2739 { $$ = DeclarationNode::newEnum( nullptr, $4, true, false )->addQualifiers( $2 ); }
2740 | ENUM attribute_list_opt '!' '{' enumerator_list comma_opt '}' // invalid syntax rule
2741 { SemanticError( yylloc, "syntax error, hiding ('!') the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr; }
2742 | ENUM attribute_list_opt identifier
2743 { typedefTable.makeTypedef( *$3, "enum_type 1" ); }
2744 hide_opt '{' enumerator_list comma_opt '}'
2745 { $$ = DeclarationNode::newEnum( $3, $7, true, false, nullptr, $5 )->addQualifiers( $2 ); }
2746 | ENUM attribute_list_opt typedef_name hide_opt '{' enumerator_list comma_opt '}' // unqualified type name
2747 { $$ = DeclarationNode::newEnum( $3->name, $6, true, false, nullptr, $4 )->addQualifiers( $2 ); }
2748 | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt '{' enumerator_list comma_opt '}'
2749 {
2750 if ( $3->storageClasses.val != 0 || $3->type->qualifiers.any() ) {
2751 SemanticError( yylloc, "syntax error, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2752 }
2753 $$ = DeclarationNode::newEnum( nullptr, $7, true, true, $3 )->addQualifiers( $5 );
2754 }
2755 | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt '!' '{' enumerator_list comma_opt '}' // unqualified type name
2756 { SemanticError( yylloc, "syntax error, hiding ('!') the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr; }
2757 | ENUM '(' ')' attribute_list_opt '{' enumerator_list comma_opt '}'
2758 {
2759 $$ = DeclarationNode::newEnum( nullptr, $6, true, true )->addQualifiers( $4 );
2760 }
2761 | ENUM '(' ')' attribute_list_opt '!' '{' enumerator_list comma_opt '}' // invalid syntax rule
2762 { SemanticError( yylloc, "syntax error, hiding ('!') the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr; }
2763 | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt identifier attribute_list_opt
2764 {
2765 if ( $3 && ($3->storageClasses.any() || $3->type->qualifiers.val != 0) ) {
2766 SemanticError( yylloc, "syntax error, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2767 }
2768 typedefTable.makeTypedef( *$6, "enum_type 2" );
2769 }
2770 hide_opt '{' enumerator_list comma_opt '}'
2771 {
2772 $$ = DeclarationNode::newEnum( $6, $11, true, true, $3, $9 )->addQualifiers( $5 )->addQualifiers( $7 );
2773 }
2774 | ENUM '(' ')' attribute_list_opt identifier attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2775 {
2776 $$ = DeclarationNode::newEnum( $5, $9, true, true, nullptr, $7 )->addQualifiers( $4 )->addQualifiers( $6 );
2777 }
2778 | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt typedef_name attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2779 {
2780 $$ = DeclarationNode::newEnum( $6->name, $10, true, true, $3, $8 )->addQualifiers( $5 )->addQualifiers( $7 );
2781 }
2782 | ENUM '(' ')' attribute_list_opt typedef_name attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2783 {
2784 $$ = DeclarationNode::newEnum( $5->name, $9, true, true, nullptr, $7 )->addQualifiers( $4 )->addQualifiers( $6 );
2785 }
2786 | enum_type_nobody
2787 ;
2788
2789hide_opt:
2790 // empty
2791 { $$ = EnumHiding::Visible; }
2792 | '!'
2793 { $$ = EnumHiding::Hide; }
2794 ;
2795
2796enum_type_nobody: // enum - {...}
2797 ENUM attribute_list_opt identifier
2798 {
2799 typedefTable.makeTypedef( *$3, "enum_type_nobody 1" );
2800 $$ = DeclarationNode::newEnum( $3, nullptr, false, false )->addQualifiers( $2 );
2801 }
2802 | ENUM attribute_list_opt type_name
2803 {
2804 typedefTable.makeTypedef( *$3->symbolic.name, "enum_type_nobody 2" );
2805 $$ = DeclarationNode::newEnum( $3->symbolic.name, nullptr, false, false )->addQualifiers( $2 );
2806 }
2807 ;
2808
2809enumerator_list:
2810 visible_hide_opt identifier_or_type_name enumerator_value_opt
2811 { $$ = DeclarationNode::newEnumValueGeneric( $2, $3 ); }
2812 | INLINE type_name
2813 { $$ = DeclarationNode::newEnumInLine( *$2->symbolic.name ); }
2814 | enumerator_list ',' visible_hide_opt identifier_or_type_name enumerator_value_opt
2815 { $$ = $1->set_last( DeclarationNode::newEnumValueGeneric( $4, $5 ) ); }
2816 | enumerator_list ',' INLINE type_name enumerator_value_opt
2817 { $$ = $1->set_last( DeclarationNode::newEnumValueGeneric( new string("inline"), nullptr ) ); }
2818 ;
2819
2820visible_hide_opt:
2821 hide_opt
2822 | '^'
2823 { $$ = EnumHiding::Visible; }
2824 ;
2825
2826enumerator_value_opt:
2827 // empty
2828 { $$ = nullptr; }
2829 | '=' constant_expression { $$ = new InitializerNode( $2 ); }
2830 | '=' '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $3, true ); }
2831 // | simple_assignment_operator initializer
2832 // { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2833 ;
2834
2835// ************************** FUNCTION PARAMETERS *******************************
2836
2837parameter_list_ellipsis_opt:
2838 // empty
2839 { $$ = nullptr; }
2840 | ELLIPSIS
2841 { $$ = nullptr; }
2842 | parameter_list
2843 | parameter_list ',' ELLIPSIS
2844 { $$ = $1->addVarArgs(); }
2845 ;
2846
2847parameter_list: // abstract + real
2848 parameter_declaration
2849 | abstract_parameter_declaration
2850 | parameter_list ',' parameter_declaration
2851 { $$ = $1->set_last( $3 ); }
2852 | parameter_list ',' abstract_parameter_declaration
2853 { $$ = $1->set_last( $3 ); }
2854 ;
2855
2856cfa_parameter_list_ellipsis_opt: // CFA, abstract + real
2857 // empty
2858 { $$ = DeclarationNode::newFromTypeData( build_basic_type( DeclarationNode::Void ) ); }
2859 | ELLIPSIS
2860 { $$ = nullptr; }
2861 | cfa_parameter_list
2862 | cfa_abstract_parameter_list
2863 | cfa_parameter_list ',' cfa_abstract_parameter_list
2864 { $$ = $1->set_last( $3 ); }
2865 | cfa_parameter_list ',' ELLIPSIS
2866 { $$ = $1->addVarArgs(); }
2867 | cfa_abstract_parameter_list ',' ELLIPSIS
2868 { $$ = $1->addVarArgs(); }
2869 ;
2870
2871cfa_parameter_list: // CFA
2872 // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2873 // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2874 cfa_parameter_declaration
2875 | cfa_abstract_parameter_list ',' cfa_parameter_declaration
2876 { $$ = $1->set_last( $3 ); }
2877 | cfa_parameter_list ',' cfa_parameter_declaration
2878 { $$ = $1->set_last( $3 ); }
2879 | cfa_parameter_list ',' cfa_abstract_parameter_list ',' cfa_parameter_declaration
2880 { $$ = $1->set_last( $3 )->set_last( $5 ); }
2881 ;
2882
2883cfa_abstract_parameter_list: // CFA, new & old style abstract
2884 cfa_abstract_parameter_declaration
2885 | cfa_abstract_parameter_list ',' cfa_abstract_parameter_declaration
2886 { $$ = $1->set_last( $3 ); }
2887 ;
2888
2889// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2890// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2891
2892parameter_declaration:
2893 // No SUE declaration in parameter list.
2894 declaration_specifier_nobody identifier_parameter_declarator default_initializer_opt
2895 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2896 | declaration_specifier_nobody type_parameter_redeclarator default_initializer_opt
2897 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2898 ;
2899
2900abstract_parameter_declaration:
2901 declaration_specifier_nobody default_initializer_opt
2902 { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2903 | declaration_specifier_nobody abstract_parameter_declarator default_initializer_opt
2904 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2905 ;
2906
2907cfa_parameter_declaration: // CFA, new & old style parameter declaration
2908 parameter_declaration
2909 | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initializer_opt
2910 { $$ = $1->addName( $2 ); }
2911 | cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2912 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2913 { $$ = $1->addName( $2 ); }
2914 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2915 { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2916 | cfa_function_specifier // int f( "int fp()" );
2917 ;
2918
2919cfa_abstract_parameter_declaration: // CFA, new & old style parameter declaration
2920 abstract_parameter_declaration
2921 | cfa_identifier_parameter_declarator_no_tuple
2922 | cfa_abstract_tuple
2923 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2924 | type_qualifier_list cfa_abstract_tuple
2925 { $$ = $2->addQualifiers( $1 ); }
2926 | cfa_abstract_function // int f( "int ()" );
2927 ;
2928
2929// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2930// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2931// identifiers. The ANSI-style parameter-list can redefine a typedef name.
2932
2933identifier_list: // K&R-style parameter list => no types
2934 identifier
2935 { $$ = DeclarationNode::newName( $1 ); }
2936 | identifier_list ',' identifier
2937 { $$ = $1->set_last( DeclarationNode::newName( $3 ) ); }
2938 ;
2939
2940identifier_or_type_name:
2941 identifier
2942 | TYPEDEFname
2943 | TYPEGENname
2944 ;
2945
2946type_no_function: // sizeof, alignof, cast (constructor)
2947 cfa_abstract_declarator_tuple // CFA
2948 | type_specifier // cannot be type_specifier_nobody, e.g., (struct S {}){} is a thing
2949 | type_specifier abstract_declarator
2950 { $$ = $2->addType( $1 ); }
2951 ;
2952
2953type: // typeof, assertion
2954 type_no_function
2955 | cfa_abstract_function // CFA
2956 ;
2957
2958initializer_opt:
2959 // empty
2960 { $$ = nullptr; }
2961 | simple_assignment_operator initializer { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2962 | '=' VOID { $$ = new InitializerNode( true ); }
2963 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
2964 ;
2965
2966initializer:
2967 assignment_expression { $$ = new InitializerNode( $1 ); }
2968 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
2969 ;
2970
2971initializer_list_opt:
2972 // empty
2973 { $$ = nullptr; }
2974 | initializer
2975 | designation initializer { $$ = $2->set_designators( $1 ); }
2976 | initializer_list_opt ',' initializer { $$ = $1->set_last( $3 ); }
2977 | initializer_list_opt ',' designation initializer { $$ = $1->set_last( $4->set_designators( $3 ) ); }
2978 ;
2979
2980// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2981// '=' to separator the designator from the initializer value, as in:
2982//
2983// int x[10] = { [1] = 3 };
2984//
2985// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment. To disambiguate this case, CFA
2986// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2987// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2988// shift/reduce conflicts
2989
2990designation:
2991 designator_list ':' // C99, CFA uses ":" instead of "="
2992 | identifier_at ':' // GCC, field name
2993 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
2994 ;
2995
2996designator_list: // C99
2997 designator
2998 | designator_list designator
2999 { $$ = $1->set_last( $2 ); }
3000 //| designator_list designator { $$ = new ExpressionNode( $1, $2 ); }
3001 ;
3002
3003designator:
3004 '.' identifier_at // C99, field name
3005 { $$ = new ExpressionNode( build_varref( yylloc, $2 ) ); }
3006 | '[' push assignment_expression pop ']' // C99, single array element
3007 // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
3008 { $$ = $3; }
3009 | '[' push subrange pop ']' // CFA, multiple array elements
3010 { $$ = $3; }
3011 | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
3012 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $3 ), maybeMoveBuild( $5 ) ) ); }
3013 | '.' '[' push field_name_list pop ']' // CFA, tuple field selector
3014 { $$ = $4; }
3015 ;
3016
3017// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
3018// rather than an object-oriented type system. This required four groups of extensions:
3019//
3020// Overloading: function, data, and operator identifiers may be overloaded.
3021//
3022// Type declarations: "otype" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
3023// and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
3024// definitions of new types. Type declarations with storage class "extern" provide opaque types.
3025//
3026// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
3027// site. A polymorphic function is not a template; it is a function, with an address and a type.
3028//
3029// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
3030// types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
3031// hierarchies. Unlike classes, they can define relationships between types. Assertions declare that a type or
3032// types provide the operations declared by a specification. Assertions are normally used to declare requirements
3033// on type arguments of polymorphic functions.
3034
3035type_parameter_list: // CFA
3036 type_parameter
3037 | type_parameter_list ',' type_parameter
3038 { $$ = $1->set_last( $3 ); }
3039 ;
3040
3041type_initializer_opt: // CFA
3042 // empty
3043 { $$ = nullptr; }
3044 | '=' type
3045 { $$ = $2; }
3046 ;
3047
3048type_parameter: // CFA
3049 type_class identifier_or_type_name
3050 {
3051 typedefTable.addToScope( *$2, TYPEDEFname, "type_parameter 1" );
3052 if ( $1 == ast::TypeDecl::Otype ) { SemanticError( yylloc, "otype keyword is deprecated, use T " ); }
3053 if ( $1 == ast::TypeDecl::Dtype ) { SemanticError( yylloc, "dtype keyword is deprecated, use T &" ); }
3054 if ( $1 == ast::TypeDecl::Ttype ) { SemanticError( yylloc, "ttype keyword is deprecated, use T ..." ); }
3055 }
3056 type_initializer_opt assertion_list_opt
3057 { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
3058 | identifier_or_type_name new_type_class
3059 { typedefTable.addToScope( *$1, TYPEDEFname, "type_parameter 2" ); }
3060 type_initializer_opt assertion_list_opt
3061 { $$ = DeclarationNode::newTypeParam( $2, $1 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
3062 | '[' identifier_or_type_name ']'
3063 {
3064 typedefTable.addToScope( *$2, TYPEDIMname, "type_parameter 3" );
3065 $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dimension, $2 );
3066 }
3067 // | type_specifier identifier_parameter_declarator
3068 | assertion_list
3069 { $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
3070 | ENUM '(' identifier_or_type_name ')' identifier_or_type_name new_type_class type_initializer_opt assertion_list_opt
3071 {
3072 typedefTable.addToScope( *$3, TYPEDIMname, "type_parameter 4" );
3073 typedefTable.addToScope( *$5, TYPEDIMname, "type_parameter 5" );
3074 $$ = DeclarationNode::newTypeParam( $6, $5 )->addTypeInitializer( $7 )->addAssertions( $8 );
3075 }
3076 ;
3077
3078new_type_class: // CFA
3079 // empty
3080 { $$ = ast::TypeDecl::Otype; }
3081 | '&'
3082 { $$ = ast::TypeDecl::Dtype; }
3083 | '*'
3084 { $$ = ast::TypeDecl::DStype; } // Dtype + sized
3085 // | '(' '*' ')' // Gregor made me do it
3086 // { $$ = ast::TypeDecl::Ftype; }
3087 | ELLIPSIS
3088 { $$ = ast::TypeDecl::Ttype; }
3089 ;
3090
3091type_class: // CFA
3092 OTYPE
3093 { $$ = ast::TypeDecl::Otype; }
3094 | DTYPE
3095 { $$ = ast::TypeDecl::Dtype; }
3096 | FTYPE
3097 { $$ = ast::TypeDecl::Ftype; }
3098 | TTYPE
3099 { $$ = ast::TypeDecl::Ttype; }
3100 ;
3101
3102assertion_list_opt: // CFA
3103 // empty
3104 { $$ = nullptr; }
3105 | assertion_list
3106 ;
3107
3108assertion_list: // CFA
3109 assertion
3110 | assertion_list assertion
3111 { $$ = $1->set_last( $2 ); }
3112 ;
3113
3114assertion: // CFA
3115 '|' identifier_or_type_name '(' type_list ')'
3116 { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
3117 | '|' '{' push trait_declaration_list pop '}'
3118 { $$ = $4; }
3119 // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
3120 // { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
3121 ;
3122
3123type_list: // CFA
3124 type
3125 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3126 | assignment_expression
3127 | type_list ',' type
3128 { $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
3129 | type_list ',' assignment_expression
3130 { $$ = $1->set_last( $3 ); }
3131 ;
3132
3133type_declaring_list: // CFA
3134 OTYPE type_declarator
3135 { $$ = $2; }
3136 | storage_class_list OTYPE type_declarator
3137 { $$ = $3->addQualifiers( $1 ); }
3138 | type_declaring_list ',' type_declarator
3139 { $$ = $1->set_last( $3->copySpecifiers( $1 ) ); }
3140 ;
3141
3142type_declarator: // CFA
3143 type_declarator_name assertion_list_opt
3144 { $$ = $1->addAssertions( $2 ); }
3145 | type_declarator_name assertion_list_opt '=' type
3146 { $$ = $1->addAssertions( $2 )->addType( $4 ); }
3147 ;
3148
3149type_declarator_name: // CFA
3150 identifier_or_type_name
3151 {
3152 typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "type_declarator_name 1" );
3153 $$ = DeclarationNode::newTypeDecl( $1, nullptr );
3154 }
3155 | identifier_or_type_name '(' type_parameter_list ')'
3156 {
3157 typedefTable.addToEnclosingScope( *$1, TYPEGENname, "type_declarator_name 2" );
3158 $$ = DeclarationNode::newTypeDecl( $1, $3 );
3159 }
3160 ;
3161
3162trait_specifier: // CFA
3163 TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
3164 {
3165 SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3166 $$ = DeclarationNode::newTrait( $2, $4, nullptr );
3167 }
3168 | forall TRAIT identifier_or_type_name '{' '}' // alternate
3169 { $$ = DeclarationNode::newTrait( $3, $1, nullptr ); }
3170 | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
3171 {
3172 SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3173 $$ = DeclarationNode::newTrait( $2, $4, $8 );
3174 }
3175 | forall TRAIT identifier_or_type_name '{' push trait_declaration_list pop '}' // alternate
3176 { $$ = DeclarationNode::newTrait( $3, $1, $6 ); }
3177 ;
3178
3179trait_declaration_list: // CFA
3180 trait_declaration
3181 | trait_declaration_list pop push trait_declaration
3182 { $$ = $1->set_last( $4 ); }
3183 ;
3184
3185trait_declaration: // CFA
3186 cfa_trait_declaring_list ';'
3187 | trait_declaring_list ';'
3188 ;
3189
3190cfa_trait_declaring_list: // CFA
3191 cfa_variable_specifier
3192 | cfa_function_specifier
3193 | cfa_trait_declaring_list pop ',' push identifier_or_type_name
3194 { $$ = $1->set_last( $1->cloneType( $5 ) ); }
3195 ;
3196
3197trait_declaring_list: // CFA
3198 type_specifier declarator
3199 { $$ = $2->addType( $1 ); }
3200 | trait_declaring_list pop ',' push declarator
3201 { $$ = $1->set_last( $1->cloneBaseType( $5 ) ); }
3202 ;
3203
3204// **************************** EXTERNAL DEFINITIONS *****************************
3205
3206translation_unit:
3207 // empty, input file
3208 | external_definition_list
3209 { parseTree = parseTree ? parseTree->set_last( $1 ) : $1; }
3210 ;
3211
3212external_definition_list:
3213 push external_definition pop
3214 { $$ = $2; }
3215 | external_definition_list push external_definition pop
3216 { $$ = $1 ? $1->set_last( $3 ) : $3; }
3217 ;
3218
3219external_definition_list_opt:
3220 // empty
3221 { $$ = nullptr; }
3222 | external_definition_list
3223 ;
3224
3225up:
3226 { typedefTable.up( forall ); forall = false; }
3227 ;
3228
3229down:
3230 { typedefTable.down(); }
3231 ;
3232
3233external_definition:
3234 DIRECTIVE
3235 { $$ = DeclarationNode::newDirectiveStmt( new StatementNode( build_directive( yylloc, $1 ) ) ); }
3236 | declaration
3237 {
3238 // Variable declarations of anonymous types requires creating a unique type-name across multiple translation
3239 // unit, which is a dubious task, especially because C uses name rather than structural typing; hence it is
3240 // disallowed at the moment.
3241 if ( $1->linkage == ast::Linkage::Cforall && ! $1->storageClasses.is_static &&
3242 $1->type && $1->type->kind == TypeData::AggregateInst ) {
3243 if ( $1->type->aggInst.aggregate->kind == TypeData::Enum && $1->type->aggInst.aggregate->enumeration.anon ) {
3244 SemanticError( yylloc, "extern anonymous enumeration is currently unimplemented." ); $$ = nullptr;
3245 } else if ( $1->type->aggInst.aggregate->aggregate.anon ) { // handles struct or union
3246 SemanticError( yylloc, "extern anonymous struct/union is currently unimplemented." ); $$ = nullptr;
3247 }
3248 }
3249 }
3250 | IDENTIFIER IDENTIFIER
3251 { IdentifierBeforeIdentifier( *$1.str, *$2.str, " declaration" ); $$ = nullptr; }
3252 | IDENTIFIER type_qualifier // invalid syntax rule
3253 { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
3254 | IDENTIFIER storage_class // invalid syntax rule
3255 { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
3256 | IDENTIFIER basic_type_name // invalid syntax rule
3257 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3258 | IDENTIFIER TYPEDEFname // invalid syntax rule
3259 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3260 | IDENTIFIER TYPEGENname // invalid syntax rule
3261 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3262 | external_function_definition
3263 | EXTENSION external_definition // GCC, multiple __extension__ allowed, meaning unknown
3264 {
3265 distExt( $2 ); // mark all fields in list
3266 $$ = $2;
3267 }
3268 | ASM '(' string_literal ')' ';' // GCC, global assembler statement
3269 { $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( yylloc, false, $3, nullptr ) ) ); }
3270 | EXTERN STRINGliteral
3271 {
3272 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
3273 linkage = ast::Linkage::update( yylloc, linkage, $2 );
3274 }
3275 up external_definition down
3276 {
3277 linkage = linkageStack.top();
3278 linkageStack.pop();
3279 $$ = $5;
3280 }
3281 | EXTERN STRINGliteral // C++-style linkage specifier
3282 {
3283 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
3284 linkage = ast::Linkage::update( yylloc, linkage, $2 );
3285 }
3286 '{' up external_definition_list_opt down '}'
3287 {
3288 linkage = linkageStack.top();
3289 linkageStack.pop();
3290 $$ = $6;
3291 }
3292 // global distribution
3293 | type_qualifier_list
3294 {
3295 if ( $1->type->qualifiers.any() ) {
3296 SemanticError( yylloc, "syntax error, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3297 }
3298 if ( $1->type->forall ) forall = true; // remember generic type
3299 }
3300 '{' up external_definition_list_opt down '}' // CFA, namespace
3301 {
3302 distQual( $5, $1 );
3303 forall = false;
3304 $$ = $5;
3305 }
3306 | declaration_qualifier_list
3307 {
3308 if ( $1->type && $1->type->qualifiers.any() ) {
3309 SemanticError( yylloc, "syntax error, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3310 }
3311 if ( $1->type && $1->type->forall ) forall = true; // remember generic type
3312 }
3313 '{' up external_definition_list_opt down '}' // CFA, namespace
3314 {
3315 distQual( $5, $1 );
3316 forall = false;
3317 $$ = $5;
3318 }
3319 | declaration_qualifier_list type_qualifier_list
3320 {
3321 if ( ($1->type && $1->type->qualifiers.any()) || ($2->type && $2->type->qualifiers.any()) ) {
3322 SemanticError( yylloc, "syntax error, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3323 }
3324 if ( ($1->type && $1->type->forall) || ($2->type && $2->type->forall) ) forall = true; // remember generic type
3325 }
3326 '{' up external_definition_list_opt down '}' // CFA, namespace
3327 {
3328 distQual( $6, $1->addQualifiers( $2 ) );
3329 forall = false;
3330 $$ = $6;
3331 }
3332 ;
3333
3334external_function_definition:
3335 function_definition
3336 // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
3337 // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
3338 // Parsing is possible because function_definition does not appear in the context of an expression (nested
3339 // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
3340 // declaration must still have a type_specifier. OBSOLESCENT (see 1)
3341 | function_declarator compound_statement
3342 { $$ = $1->addFunctionBody( $2 ); }
3343 | KR_function_declarator KR_parameter_list_opt compound_statement
3344 { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
3345 ;
3346
3347with_clause_opt:
3348 // empty
3349 { $$ = nullptr; forall = false; }
3350 | WITH '(' tuple_expression_list ')' attribute_list_opt
3351 {
3352 $$ = $3; forall = false;
3353 if ( $5 ) {
3354 SemanticError( yylloc, "syntax error, attributes cannot be associated with function body. Move attribute(s) before \"with\" clause." );
3355 $$ = nullptr;
3356 } // if
3357 }
3358 ;
3359
3360function_definition:
3361 cfa_function_declaration with_clause_opt compound_statement // CFA
3362 {
3363 // Add the function body to the last identifier in the function definition list, i.e., foo3:
3364 // [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
3365 $1->get_last()->addFunctionBody( $3, $2 );
3366 $$ = $1;
3367 }
3368 | declaration_specifier function_declarator with_clause_opt compound_statement
3369 {
3370 rebindForall( $1, $2 );
3371 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3372 }
3373 | declaration_specifier function_type_redeclarator with_clause_opt compound_statement
3374 {
3375 rebindForall( $1, $2 );
3376 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3377 }
3378 // handles default int return type, OBSOLESCENT (see 1)
3379 | type_qualifier_list function_declarator with_clause_opt compound_statement
3380 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3381 // handles default int return type, OBSOLESCENT (see 1)
3382 | declaration_qualifier_list function_declarator with_clause_opt compound_statement
3383 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3384 // handles default int return type, OBSOLESCENT (see 1)
3385 | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
3386 { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3387
3388 // Old-style K&R function definition, OBSOLESCENT (see 4)
3389 | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3390 {
3391 rebindForall( $1, $2 );
3392 $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
3393 }
3394 // handles default int return type, OBSOLESCENT (see 1)
3395 | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3396 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3397 // handles default int return type, OBSOLESCENT (see 1)
3398 | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3399 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3400 // handles default int return type, OBSOLESCENT (see 1)
3401 | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3402 { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3403 ;
3404
3405declarator:
3406 variable_declarator
3407 | variable_type_redeclarator
3408 | function_declarator
3409 | function_type_redeclarator
3410 ;
3411
3412subrange:
3413 constant_expression '~' constant_expression // CFA, integer subrange
3414 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
3415 ;
3416
3417// **************************** ASM *****************************
3418
3419asm_name_opt: // GCC
3420 // empty
3421 { $$ = nullptr; }
3422 | ASM '(' string_literal ')' attribute_list_opt
3423 {
3424 DeclarationNode * name = new DeclarationNode();
3425 name->asmName = maybeMoveBuild( $3 );
3426 $$ = name->addQualifiers( $5 );
3427 }
3428 ;
3429
3430// **************************** ATTRIBUTE *****************************
3431
3432attribute_list_opt: // GCC
3433 // empty
3434 { $$ = nullptr; }
3435 | attribute_list
3436 ;
3437
3438attribute_list: // GCC
3439 attribute
3440 | attribute_list attribute
3441 { $$ = $2->addQualifiers( $1 ); }
3442 ;
3443
3444attribute: // GCC
3445 ATTRIBUTE '(' '(' attribute_name_list ')' ')'
3446 { $$ = $4; }
3447 | ATTRIBUTE '(' attribute_name_list ')' // CFA
3448 { $$ = $3; }
3449 | ATTR '(' attribute_name_list ')' // CFA
3450 { $$ = $3; }
3451 ;
3452
3453attribute_name_list: // GCC
3454 attribute_name
3455 | attribute_name_list ',' attribute_name
3456 { $$ = $3->addQualifiers( $1 ); }
3457 ;
3458
3459attribute_name: // GCC
3460 // empty
3461 { $$ = nullptr; }
3462 | attr_name
3463 { $$ = DeclarationNode::newAttribute( $1 ); }
3464 | attr_name '(' argument_expression_list_opt ')'
3465 { $$ = DeclarationNode::newAttribute( $1, $3 ); }
3466 ;
3467
3468attr_name: // GCC
3469 IDENTIFIER
3470 | quasi_keyword
3471 | TYPEDEFname
3472 | TYPEGENname
3473 | FALLTHROUGH
3474 { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
3475 | CONST
3476 { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
3477 ;
3478
3479// ============================================================================
3480// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
3481// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
3482// in:
3483//
3484// int (*f())[10] { ... };
3485// ... (*f())[3] += 1; // definition mimics usage
3486//
3487// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
3488// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
3489// ============================================================================
3490
3491// ----------------------------------------------------------------------------
3492// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
3493// to define a variable or function prototype, e.g.:
3494//
3495// valid declaration invalid definition
3496// ----------------- ------------------
3497// int f; int f {}
3498// int *f; int *f {}
3499// int f[10]; int f[10] {}
3500// int (*f)(int); int (*f)(int) {}
3501//
3502// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
3503// variable_declarator and function_declarator.
3504// ----------------------------------------------------------------------------
3505
3506// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
3507// declaring an array of functions versus a pointer to an array of functions.
3508
3509paren_identifier:
3510 identifier_at
3511 { $$ = DeclarationNode::newName( $1 ); }
3512 | '(' paren_identifier ')' // redundant parenthesis
3513 { $$ = $2; }
3514 ;
3515
3516variable_declarator:
3517 paren_identifier attribute_list_opt
3518 { $$ = $1->addQualifiers( $2 ); }
3519 | variable_ptr
3520 | variable_array attribute_list_opt
3521 { $$ = $1->addQualifiers( $2 ); }
3522 | variable_function attribute_list_opt
3523 { $$ = $1->addQualifiers( $2 ); }
3524 ;
3525
3526variable_ptr:
3527 ptrref_operator variable_declarator
3528 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3529 | ptrref_operator type_qualifier_list variable_declarator
3530 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3531 | '(' variable_ptr ')' attribute_list_opt // redundant parenthesis
3532 { $$ = $2->addQualifiers( $4 ); }
3533 | '(' attribute_list variable_ptr ')' attribute_list_opt // redundant parenthesis
3534 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3535 ;
3536
3537variable_array:
3538 paren_identifier array_dimension
3539 { $$ = $1->addArray( $2 ); }
3540 | '(' variable_ptr ')' array_dimension
3541 { $$ = $2->addArray( $4 ); }
3542 | '(' attribute_list variable_ptr ')' array_dimension
3543 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3544 | '(' variable_array ')' multi_array_dimension // redundant parenthesis
3545 { $$ = $2->addArray( $4 ); }
3546 | '(' attribute_list variable_array ')' multi_array_dimension // redundant parenthesis
3547 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3548 | '(' variable_array ')' // redundant parenthesis
3549 { $$ = $2; }
3550 | '(' attribute_list variable_array ')' // redundant parenthesis
3551 { $$ = $3->addQualifiers( $2 ); }
3552 ;
3553
3554variable_function:
3555 '(' variable_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3556 { $$ = $2->addParamList( $5 ); }
3557 | '(' attribute_list variable_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3558 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3559 | '(' variable_function ')' // redundant parenthesis
3560 { $$ = $2; }
3561 | '(' attribute_list variable_function ')' // redundant parenthesis
3562 { $$ = $3->addQualifiers( $2 ); }
3563 ;
3564
3565// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
3566// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
3567// is the same scope. The pattern precludes returning arrays and functions versus pointers to arrays and functions.
3568
3569function_declarator:
3570 function_no_ptr attribute_list_opt
3571 { $$ = $1->addQualifiers( $2 ); }
3572 | function_ptr
3573 | function_array attribute_list_opt
3574 { $$ = $1->addQualifiers( $2 ); }
3575 ;
3576
3577function_no_ptr:
3578 paren_identifier '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3579 { $$ = $1->addParamList( $3 ); }
3580 | '(' function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3581 { $$ = $2->addParamList( $5 ); }
3582 | '(' attribute_list function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3583 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3584 | '(' function_no_ptr ')' // redundant parenthesis
3585 { $$ = $2; }
3586 | '(' attribute_list function_no_ptr ')' // redundant parenthesis
3587 { $$ = $3->addQualifiers( $2 ); }
3588 ;
3589
3590function_ptr:
3591 ptrref_operator function_declarator
3592 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3593 | ptrref_operator type_qualifier_list function_declarator
3594 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3595 | '(' function_ptr ')' attribute_list_opt
3596 { $$ = $2->addQualifiers( $4 ); }
3597 | '(' attribute_list function_ptr ')' attribute_list_opt
3598 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3599 ;
3600
3601function_array:
3602 '(' function_ptr ')' array_dimension
3603 { $$ = $2->addArray( $4 ); }
3604 | '(' attribute_list function_ptr ')' array_dimension
3605 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3606 | '(' function_array ')' multi_array_dimension // redundant parenthesis
3607 { $$ = $2->addArray( $4 ); }
3608 | '(' attribute_list function_array ')' multi_array_dimension // redundant parenthesis
3609 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3610 | '(' function_array ')' // redundant parenthesis
3611 { $$ = $2; }
3612 | '(' attribute_list function_array ')' // redundant parenthesis
3613 { $$ = $3->addQualifiers( $2 ); }
3614 ;
3615
3616// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
3617//
3618// f( a, b, c ) int a, *b, c[]; {}
3619//
3620// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
3621// returning arrays and functions versus pointers to arrays and functions.
3622
3623KR_function_declarator:
3624 KR_function_no_ptr
3625 | KR_function_ptr
3626 | KR_function_array
3627 ;
3628
3629KR_function_no_ptr:
3630 paren_identifier '(' identifier_list ')' // function_declarator handles empty parameter
3631 { $$ = $1->addIdList( $3 ); }
3632 | '(' KR_function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3633 { $$ = $2->addParamList( $5 ); }
3634 | '(' attribute_list KR_function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3635 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3636 | '(' KR_function_no_ptr ')' // redundant parenthesis
3637 { $$ = $2; }
3638 | '(' attribute_list KR_function_no_ptr ')' // redundant parenthesis
3639 { $$ = $3->addQualifiers( $2 ); }
3640 ;
3641
3642KR_function_ptr:
3643 ptrref_operator KR_function_declarator
3644 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3645 | ptrref_operator type_qualifier_list KR_function_declarator
3646 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3647 | '(' KR_function_ptr ')'
3648 { $$ = $2; }
3649 | '(' attribute_list KR_function_ptr ')'
3650 { $$ = $3->addQualifiers( $2 ); }
3651 ;
3652
3653KR_function_array:
3654 '(' KR_function_ptr ')' array_dimension
3655 { $$ = $2->addArray( $4 ); }
3656 | '(' attribute_list KR_function_ptr ')' array_dimension
3657 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3658 | '(' KR_function_array ')' multi_array_dimension // redundant parenthesis
3659 { $$ = $2->addArray( $4 ); }
3660 | '(' attribute_list KR_function_array ')' multi_array_dimension // redundant parenthesis
3661 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3662 | '(' KR_function_array ')' // redundant parenthesis
3663 { $$ = $2; }
3664 | '(' attribute_list KR_function_array ')' // redundant parenthesis
3665 { $$ = $3->addQualifiers( $2 ); }
3666 ;
3667
3668// This pattern parses a declaration for a variable that redefines a type name, e.g.:
3669//
3670// typedef int foo;
3671// {
3672// int foo; // redefine typedef name in new scope
3673// }
3674
3675paren_type:
3676 typedef_name
3677 {
3678 // hide type name in enclosing scope by variable name
3679 typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "paren_type" );
3680 }
3681 | '(' paren_type ')'
3682 { $$ = $2; }
3683 ;
3684
3685variable_type_redeclarator:
3686 paren_type attribute_list_opt
3687 { $$ = $1->addQualifiers( $2 ); }
3688 | variable_type_ptr
3689 | variable_type_array attribute_list_opt
3690 { $$ = $1->addQualifiers( $2 ); }
3691 | variable_type_function attribute_list_opt
3692 { $$ = $1->addQualifiers( $2 ); }
3693 ;
3694
3695variable_type_ptr:
3696 ptrref_operator variable_type_redeclarator
3697 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3698 | ptrref_operator type_qualifier_list variable_type_redeclarator
3699 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3700 | '(' variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3701 { $$ = $2->addQualifiers( $4 ); }
3702 | '(' attribute_list variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3703 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3704 ;
3705
3706variable_type_array:
3707 paren_type array_dimension
3708 { $$ = $1->addArray( $2 ); }
3709 | '(' variable_type_ptr ')' array_dimension
3710 { $$ = $2->addArray( $4 ); }
3711 | '(' attribute_list variable_type_ptr ')' array_dimension
3712 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3713 | '(' variable_type_array ')' multi_array_dimension // redundant parenthesis
3714 { $$ = $2->addArray( $4 ); }
3715 | '(' attribute_list variable_type_array ')' multi_array_dimension // redundant parenthesis
3716 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3717 | '(' variable_type_array ')' // redundant parenthesis
3718 { $$ = $2; }
3719 | '(' attribute_list variable_type_array ')' // redundant parenthesis
3720 { $$ = $3->addQualifiers( $2 ); }
3721 ;
3722
3723variable_type_function:
3724 '(' variable_type_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3725 { $$ = $2->addParamList( $5 ); }
3726 | '(' attribute_list variable_type_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3727 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3728 | '(' variable_type_function ')' // redundant parenthesis
3729 { $$ = $2; }
3730 | '(' attribute_list variable_type_function ')' // redundant parenthesis
3731 { $$ = $3->addQualifiers( $2 ); }
3732 ;
3733
3734// This pattern parses a declaration for a function prototype that redefines a type name. It precludes declaring an
3735// array of functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to
3736// arrays and functions.
3737
3738function_type_redeclarator:
3739 function_type_no_ptr attribute_list_opt
3740 { $$ = $1->addQualifiers( $2 ); }
3741 | function_type_ptr
3742 | function_type_array attribute_list_opt
3743 { $$ = $1->addQualifiers( $2 ); }
3744 ;
3745
3746function_type_no_ptr:
3747 paren_type '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3748 { $$ = $1->addParamList( $3 ); }
3749 | '(' function_type_ptr ')' '(' parameter_list_ellipsis_opt ')'
3750 { $$ = $2->addParamList( $5 ); }
3751 | '(' attribute_list function_type_ptr ')' '(' parameter_list_ellipsis_opt ')'
3752 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3753 | '(' function_type_no_ptr ')' // redundant parenthesis
3754 { $$ = $2; }
3755 | '(' attribute_list function_type_no_ptr ')' // redundant parenthesis
3756 { $$ = $3->addQualifiers( $2 ); }
3757 ;
3758
3759function_type_ptr:
3760 ptrref_operator function_type_redeclarator
3761 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3762 | ptrref_operator type_qualifier_list function_type_redeclarator
3763 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3764 | '(' function_type_ptr ')' attribute_list_opt
3765 { $$ = $2->addQualifiers( $4 ); }
3766 | '(' attribute_list function_type_ptr ')' attribute_list_opt
3767 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3768 ;
3769
3770function_type_array:
3771 '(' function_type_ptr ')' array_dimension
3772 { $$ = $2->addArray( $4 ); }
3773 | '(' attribute_list function_type_ptr ')' array_dimension
3774 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3775 | '(' function_type_array ')' multi_array_dimension // redundant parenthesis
3776 { $$ = $2->addArray( $4 ); }
3777 | '(' attribute_list function_type_array ')' multi_array_dimension // redundant parenthesis
3778 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3779 | '(' function_type_array ')' // redundant parenthesis
3780 { $$ = $2; }
3781 | '(' attribute_list function_type_array ')' // redundant parenthesis
3782 { $$ = $3->addQualifiers( $2 ); }
3783 ;
3784
3785// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
3786// typedef name and allows the C99 array options, which can only appear in a parameter list. The pattern precludes
3787// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
3788// pointers to arrays and functions.
3789
3790identifier_parameter_declarator:
3791 paren_identifier attribute_list_opt
3792 { $$ = $1->addQualifiers( $2 ); }
3793 | '&' MUTEX paren_identifier attribute_list_opt
3794 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
3795 OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3796 | identifier_parameter_ptr
3797 | identifier_parameter_array attribute_list_opt
3798 { $$ = $1->addQualifiers( $2 ); }
3799 | identifier_parameter_function attribute_list_opt
3800 { $$ = $1->addQualifiers( $2 ); }
3801 ;
3802
3803identifier_parameter_ptr:
3804 ptrref_operator identifier_parameter_declarator
3805 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3806 | ptrref_operator type_qualifier_list identifier_parameter_declarator
3807 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3808 | '(' identifier_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3809 { $$ = $2->addQualifiers( $4 ); }
3810 ;
3811
3812identifier_parameter_array:
3813 paren_identifier array_parameter_dimension
3814 { $$ = $1->addArray( $2 ); }
3815 | '(' identifier_parameter_ptr ')' array_dimension
3816 { $$ = $2->addArray( $4 ); }
3817 | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3818 { $$ = $2->addArray( $4 ); }
3819 | '(' identifier_parameter_array ')' // redundant parenthesis
3820 { $$ = $2; }
3821 ;
3822
3823identifier_parameter_function:
3824 paren_identifier '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3825 { $$ = $1->addParamList( $3 ); }
3826 | '(' identifier_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3827 { $$ = $2->addParamList( $5 ); }
3828 | '(' identifier_parameter_function ')' // redundant parenthesis
3829 { $$ = $2; }
3830 ;
3831
3832// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3833// e.g.:
3834//
3835// typedef int foo;
3836// forall( otype T ) struct foo;
3837// int f( int foo ); // redefine typedef name in new scope
3838//
3839// and allows the C99 array options, which can only appear in a parameter list.
3840
3841type_parameter_redeclarator:
3842 typedef_name attribute_list_opt
3843 { $$ = $1->addQualifiers( $2 ); }
3844 | '&' MUTEX typedef_name attribute_list_opt
3845 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
3846 OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3847 | type_parameter_ptr
3848 | type_parameter_array attribute_list_opt
3849 { $$ = $1->addQualifiers( $2 ); }
3850 | type_parameter_function attribute_list_opt
3851 { $$ = $1->addQualifiers( $2 ); }
3852 ;
3853
3854typedef_name:
3855 TYPEDEFname
3856 { $$ = DeclarationNode::newName( $1 ); }
3857 | TYPEGENname
3858 { $$ = DeclarationNode::newName( $1 ); }
3859 ;
3860
3861type_parameter_ptr:
3862 ptrref_operator type_parameter_redeclarator
3863 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3864 | ptrref_operator type_qualifier_list type_parameter_redeclarator
3865 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3866 | '(' type_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3867 { $$ = $2->addQualifiers( $4 ); }
3868 ;
3869
3870type_parameter_array:
3871 typedef_name array_parameter_dimension
3872 { $$ = $1->addArray( $2 ); }
3873 | '(' type_parameter_ptr ')' array_parameter_dimension
3874 { $$ = $2->addArray( $4 ); }
3875 ;
3876
3877type_parameter_function:
3878 typedef_name '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3879 { $$ = $1->addParamList( $3 ); }
3880 | '(' type_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3881 { $$ = $2->addParamList( $5 ); }
3882 ;
3883
3884// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3885// which the type applies, e.g.:
3886//
3887// sizeof( int );
3888// sizeof( int * );
3889// sizeof( int [10] );
3890// sizeof( int (*)() );
3891// sizeof( int () );
3892//
3893// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3894// and functions versus pointers to arrays and functions.
3895
3896abstract_declarator:
3897 abstract_ptr
3898 | abstract_array attribute_list_opt
3899 { $$ = $1->addQualifiers( $2 ); }
3900 | abstract_function attribute_list_opt
3901 { $$ = $1->addQualifiers( $2 ); }
3902 ;
3903
3904abstract_ptr:
3905 ptrref_operator
3906 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3907 | ptrref_operator type_qualifier_list
3908 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3909 | ptrref_operator abstract_declarator
3910 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3911 | ptrref_operator type_qualifier_list abstract_declarator
3912 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3913 | '(' abstract_ptr ')' attribute_list_opt
3914 { $$ = $2->addQualifiers( $4 ); }
3915 ;
3916
3917abstract_array:
3918 array_dimension
3919 | '(' abstract_ptr ')' array_dimension
3920 { $$ = $2->addArray( $4 ); }
3921 | '(' abstract_array ')' multi_array_dimension // redundant parenthesis
3922 { $$ = $2->addArray( $4 ); }
3923 | '(' abstract_array ')' // redundant parenthesis
3924 { $$ = $2; }
3925 ;
3926
3927abstract_function:
3928 '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3929 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
3930 | '(' abstract_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3931 { $$ = $2->addParamList( $5 ); }
3932 | '(' abstract_function ')' // redundant parenthesis
3933 { $$ = $2; }
3934 ;
3935
3936array_dimension:
3937 // Only the first dimension can be empty.
3938 '[' ']'
3939 { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
3940 | '[' ']' multi_array_dimension
3941 { $$ = DeclarationNode::newArray( nullptr, nullptr, false )->addArray( $3 ); }
3942 // Cannot use constant_expression because of tuples => semantic check
3943 | '[' push assignment_expression pop ',' comma_expression ']' // CFA
3944 { $$ = DeclarationNode::newArray( $3, nullptr, false )->addArray( DeclarationNode::newArray( $6, nullptr, false ) ); }
3945 // { SemanticError( yylloc, "New array dimension is currently unimplemented." ); $$ = nullptr; }
3946
3947 // If needed, the following parses and does not use comma_expression, so the array structure can be built.
3948 // | '[' push assignment_expression pop ',' push array_dimension_list pop ']' // CFA
3949
3950 | '[' push array_type_list pop ']' // CFA
3951 { $$ = DeclarationNode::newArray( $3, nullptr, false ); }
3952 | multi_array_dimension
3953 ;
3954
3955// array_dimension_list:
3956// assignment_expression
3957// | array_dimension_list ',' assignment_expression
3958// ;
3959
3960array_type_list:
3961 basic_type_name
3962 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3963 | type_name
3964 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3965 | assignment_expression upupeq assignment_expression
3966 | array_type_list ',' basic_type_name
3967 { $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
3968 | array_type_list ',' type_name
3969 { $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
3970 | array_type_list ',' assignment_expression upupeq assignment_expression
3971 ;
3972
3973upupeq:
3974 '~'
3975 { $$ = OperKinds::LThan; }
3976 | ErangeUpEq
3977 { $$ = OperKinds::LEThan; }
3978 ;
3979
3980multi_array_dimension:
3981 '[' push assignment_expression pop ']'
3982 { $$ = DeclarationNode::newArray( $3, nullptr, false ); }
3983 | '[' push '*' pop ']' // C99
3984 { $$ = DeclarationNode::newVarArray( 0 ); }
3985 | multi_array_dimension '[' push assignment_expression pop ']'
3986 { $$ = $1->addArray( DeclarationNode::newArray( $4, nullptr, false ) ); }
3987 | multi_array_dimension '[' push '*' pop ']' // C99
3988 { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3989 ;
3990
3991// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3992// identifier to which the type applies, e.g.:
3993//
3994// int f( int ); // not handled here
3995// int f( int * ); // abstract function-prototype parameter; no parameter name specified
3996// int f( int (*)() ); // abstract function-prototype parameter; no parameter name specified
3997// int f( int (int) ); // abstract function-prototype parameter; no parameter name specified
3998//
3999// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
4000// and functions versus pointers to arrays and functions. In addition, the pattern handles the
4001// special meaning of parenthesis around a typedef name:
4002//
4003// ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
4004// parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
4005// not as redundant parentheses around the identifier."
4006//
4007// For example:
4008//
4009// typedef float T;
4010// int f( int ( T [5] ) ); // see abstract_parameter_declarator
4011// int g( int ( T ( int ) ) ); // see abstract_parameter_declarator
4012// int f( int f1( T a[5] ) ); // see identifier_parameter_declarator
4013// int g( int g1( T g2( int p ) ) ); // see identifier_parameter_declarator
4014//
4015// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
4016// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
4017// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
4018// functions.
4019
4020abstract_parameter_declarator_opt:
4021 // empty
4022 { $$ = nullptr; }
4023 | abstract_parameter_declarator
4024 ;
4025
4026abstract_parameter_declarator:
4027 abstract_parameter_ptr
4028 | '&' MUTEX attribute_list_opt
4029 { $$ = DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ), OperKinds::AddressOf )->addQualifiers( $3 ); }
4030 | abstract_parameter_array attribute_list_opt
4031 { $$ = $1->addQualifiers( $2 ); }
4032 | abstract_parameter_function attribute_list_opt
4033 { $$ = $1->addQualifiers( $2 ); }
4034 ;
4035
4036abstract_parameter_ptr:
4037 ptrref_operator
4038 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
4039 | ptrref_operator type_qualifier_list
4040 { $$ = DeclarationNode::newPointer( $2, $1 ); }
4041 | ptrref_operator abstract_parameter_declarator
4042 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4043 | ptrref_operator type_qualifier_list abstract_parameter_declarator
4044 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4045 | '(' abstract_parameter_ptr ')' attribute_list_opt // redundant parenthesis
4046 { $$ = $2->addQualifiers( $4 ); }
4047 ;
4048
4049abstract_parameter_array:
4050 array_parameter_dimension
4051 | '(' abstract_parameter_ptr ')' array_parameter_dimension
4052 { $$ = $2->addArray( $4 ); }
4053 | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
4054 { $$ = $2->addArray( $4 ); }
4055 | '(' abstract_parameter_array ')' // redundant parenthesis
4056 { $$ = $2; }
4057 ;
4058
4059abstract_parameter_function:
4060 '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4061 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
4062 | '(' abstract_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4063 { $$ = $2->addParamList( $5 ); }
4064 | '(' abstract_parameter_function ')' // redundant parenthesis
4065 { $$ = $2; }
4066 ;
4067
4068array_parameter_dimension:
4069 // Only the first dimension can be empty or have qualifiers.
4070 array_parameter_1st_dimension
4071 | array_parameter_1st_dimension multi_array_dimension
4072 { $$ = $1->addArray( $2 ); }
4073 | multi_array_dimension
4074 ;
4075
4076// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
4077//
4078// ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
4079// a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
4080
4081array_parameter_1st_dimension:
4082 '[' ']'
4083 { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
4084 // multi_array_dimension handles the '[' '*' ']' case
4085 | '[' push type_qualifier_list '*' pop ']' // remaining C99
4086 { $$ = DeclarationNode::newVarArray( $3 ); }
4087 | '[' push type_qualifier_list pop ']'
4088 { $$ = DeclarationNode::newArray( nullptr, $3, false ); }
4089 // multi_array_dimension handles the '[' assignment_expression ']' case
4090 | '[' push type_qualifier_list assignment_expression pop ']'
4091 { $$ = DeclarationNode::newArray( $4, $3, false ); }
4092 | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
4093 { $$ = DeclarationNode::newArray( $5, $4, true ); }
4094 | '[' push type_qualifier_list STATIC assignment_expression pop ']'
4095 { $$ = DeclarationNode::newArray( $5, $3, true ); }
4096 ;
4097
4098// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
4099//
4100// struct S {
4101// int;
4102// int *;
4103// int [10];
4104// int (*)();
4105// };
4106
4107variable_abstract_declarator:
4108 variable_abstract_ptr
4109 | variable_abstract_array attribute_list_opt
4110 { $$ = $1->addQualifiers( $2 ); }
4111 | variable_abstract_function attribute_list_opt
4112 { $$ = $1->addQualifiers( $2 ); }
4113 ;
4114
4115variable_abstract_ptr:
4116 ptrref_operator
4117 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
4118 | ptrref_operator type_qualifier_list
4119 { $$ = DeclarationNode::newPointer( $2, $1 ); }
4120 | ptrref_operator variable_abstract_declarator
4121 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4122 | ptrref_operator type_qualifier_list variable_abstract_declarator
4123 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4124 | '(' variable_abstract_ptr ')' attribute_list_opt // redundant parenthesis
4125 { $$ = $2->addQualifiers( $4 ); }
4126 ;
4127
4128variable_abstract_array:
4129 array_dimension
4130 | '(' variable_abstract_ptr ')' array_dimension
4131 { $$ = $2->addArray( $4 ); }
4132 | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
4133 { $$ = $2->addArray( $4 ); }
4134 | '(' variable_abstract_array ')' // redundant parenthesis
4135 { $$ = $2; }
4136 ;
4137
4138variable_abstract_function:
4139 '(' variable_abstract_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4140 { $$ = $2->addParamList( $5 ); }
4141 | '(' variable_abstract_function ')' // redundant parenthesis
4142 { $$ = $2; }
4143 ;
4144
4145// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
4146// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
4147
4148cfa_identifier_parameter_declarator_tuple: // CFA
4149 cfa_identifier_parameter_declarator_no_tuple
4150 | cfa_abstract_tuple
4151 | type_qualifier_list cfa_abstract_tuple
4152 { $$ = $2->addQualifiers( $1 ); }
4153 ;
4154
4155cfa_identifier_parameter_declarator_no_tuple: // CFA
4156 cfa_identifier_parameter_ptr
4157 | cfa_identifier_parameter_array
4158 ;
4159
4160cfa_identifier_parameter_ptr: // CFA
4161 // No SUE declaration in parameter list.
4162 ptrref_operator type_specifier_nobody
4163 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4164 | type_qualifier_list ptrref_operator type_specifier_nobody
4165 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4166 | ptrref_operator cfa_abstract_function
4167 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4168 | type_qualifier_list ptrref_operator cfa_abstract_function
4169 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4170 | ptrref_operator cfa_identifier_parameter_declarator_tuple
4171 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4172 | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
4173 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4174 ;
4175
4176cfa_identifier_parameter_array: // CFA
4177 // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
4178 // shift/reduce conflict with new-style empty (void) function return type.
4179 '[' ']' type_specifier_nobody
4180 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4181 | cfa_array_parameter_1st_dimension type_specifier_nobody
4182 { $$ = $2->addNewArray( $1 ); }
4183 | '[' ']' multi_array_dimension type_specifier_nobody
4184 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4185 | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
4186 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4187 | multi_array_dimension type_specifier_nobody
4188 { $$ = $2->addNewArray( $1 ); }
4189
4190 | '[' ']' cfa_identifier_parameter_ptr
4191 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4192 | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
4193 { $$ = $2->addNewArray( $1 ); }
4194 | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
4195 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4196 | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
4197 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4198 | multi_array_dimension cfa_identifier_parameter_ptr
4199 { $$ = $2->addNewArray( $1 ); }
4200 ;
4201
4202cfa_array_parameter_1st_dimension:
4203 '[' push type_qualifier_list '*' pop ']' // remaining C99
4204 { $$ = DeclarationNode::newVarArray( $3 ); }
4205 | '[' push type_qualifier_list assignment_expression pop ']'
4206 { $$ = DeclarationNode::newArray( $4, $3, false ); }
4207 | '[' push declaration_qualifier_list assignment_expression pop ']'
4208 // declaration_qualifier_list must be used because of shift/reduce conflict with
4209 // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
4210 // appear in this context.
4211 { $$ = DeclarationNode::newArray( $4, $3, true ); }
4212 | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
4213 { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
4214 ;
4215
4216// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
4217// identifier to which the type applies, e.g.:
4218//
4219// [int] f( int ); // abstract variable parameter; no parameter name specified
4220// [int] f( [int] (int) ); // abstract function-prototype parameter; no parameter name specified
4221//
4222// These rules need LR(3):
4223//
4224// cfa_abstract_tuple identifier_or_type_name
4225// '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_list_ellipsis_opt ')'
4226//
4227// since a function return type can be syntactically identical to a tuple type:
4228//
4229// [int, int] t;
4230// [int, int] f( int );
4231//
4232// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
4233// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
4234// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
4235// duplicated when appearing with cfa_function_specifier.
4236
4237cfa_abstract_declarator_tuple: // CFA
4238 cfa_abstract_tuple
4239 | type_qualifier_list cfa_abstract_tuple
4240 { $$ = $2->addQualifiers( $1 ); }
4241 | cfa_abstract_declarator_no_tuple
4242 ;
4243
4244cfa_abstract_declarator_no_tuple: // CFA
4245 cfa_abstract_ptr
4246 | cfa_abstract_array
4247 ;
4248
4249cfa_abstract_ptr: // CFA
4250 ptrref_operator type_specifier
4251 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4252 | type_qualifier_list ptrref_operator type_specifier
4253 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4254 | ptrref_operator cfa_abstract_function
4255 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4256 | type_qualifier_list ptrref_operator cfa_abstract_function
4257 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4258 | ptrref_operator cfa_abstract_declarator_tuple
4259 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4260 | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
4261 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4262 ;
4263
4264cfa_abstract_array: // CFA
4265 // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
4266 // empty (void) function return type.
4267 '[' ']' type_specifier
4268 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4269 | '[' ']' multi_array_dimension type_specifier
4270 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4271 | multi_array_dimension type_specifier
4272 { $$ = $2->addNewArray( $1 ); }
4273 | '[' ']' cfa_abstract_ptr
4274 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4275 | '[' ']' multi_array_dimension cfa_abstract_ptr
4276 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4277 | multi_array_dimension cfa_abstract_ptr
4278 { $$ = $2->addNewArray( $1 ); }
4279 ;
4280
4281cfa_abstract_tuple: // CFA
4282 '[' push cfa_abstract_parameter_list pop ']'
4283 { $$ = DeclarationNode::newTuple( $3 ); }
4284 | '[' push type_specifier_nobody ELLIPSIS pop ']'
4285 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4286 | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
4287 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4288 ;
4289
4290cfa_abstract_function: // CFA
4291 '[' ']' '(' cfa_parameter_list_ellipsis_opt ')'
4292 { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
4293 | cfa_abstract_tuple '(' push cfa_parameter_list_ellipsis_opt pop ')'
4294 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4295 | cfa_function_return '(' push cfa_parameter_list_ellipsis_opt pop ')'
4296 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4297 ;
4298
4299// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
4300// each declaration, and in the specifier-qualifier list in each structure declaration and type name."
4301//
4302// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
4303// the declaration specifiers in a declaration is an obsolescent feature."
4304//
4305// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
4306// prototype-format parameter type declarators) is an obsolescent feature."
4307//
4308// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
4309// declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
4310
4311// ************************ MISCELLANEOUS ********************************
4312
4313comma_opt: // redundant comma
4314 // empty
4315 | ','
4316 ;
4317
4318default_initializer_opt:
4319 // empty
4320 { $$ = nullptr; }
4321 | '=' assignment_expression
4322 { $$ = $2; }
4323 ;
4324
4325%%
4326
4327// ----end of grammar----
4328
4329// Local Variables: //
4330// mode: c++ //
4331// tab-width: 4 //
4332// compile-command: "bison -Wcounterexamples parser.yy" //
4333// End: //
Note: See TracBrowser for help on using the repository browser.