source: src/Parser/parser.yy@ b28ce93

Last change on this file since b28ce93 was 1a40870, checked in by Peter A. Buhr <pabuhr@…>, 4 months ago

formatting
  • Property mode set to 100644
File size: 184.4 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author : Peter A. Buhr
10// Created On : Sat Sep 1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Wed May 21 18:44:44 2025
13// Update Count : 7296
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS. While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks. Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed. Most of the syntactic extensions from
27// ANSI90 to ANSI11 C are marked with the comment "C99/C11".
28
29// This grammar also has two levels of extensions. The first extensions cover most of the GCC C extensions. All of the
30// syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall (CFA), which
31// fixes several of C's outstanding problems and extends C with many modern language concepts. All of the syntactic
32// extensions for CFA C are marked with the comment "CFA".
33
34%{
35#define YYDEBUG_LEXER_TEXT( yylval ) // lexer loads this up each time
36#define YYDEBUG 1 // get the pretty debugging code to compile
37#define YYERROR_VERBOSE // more information in syntax errors
38
39#undef __GNUC_MINOR__
40
41#include <cstdio>
42#include <sstream>
43#include <stack>
44using namespace std;
45
46#include "DeclarationNode.hpp" // for DeclarationNode, ...
47#include "ExpressionNode.hpp" // for ExpressionNode, ...
48#include "InitializerNode.hpp" // for InitializerNode, ...
49#include "ParserTypes.hpp"
50#include "StatementNode.hpp" // for build_...
51#include "TypedefTable.hpp"
52#include "TypeData.hpp"
53#include "AST/Type.hpp" // for BasicType, BasicKind
54#include "Common/SemanticError.hpp" // error_str
55#include "Common/Utility.hpp" // for maybeMoveBuild, maybeBuild, CodeLo...
56#include "AST/Attribute.hpp" // for Attribute
57#include "AST/Print.hpp" // for print
58#include "Common/Iterate.hpp" // for reverseIterate
59
60// lex uses __null in a boolean context, it's fine.
61#ifdef __clang__
62#pragma GCC diagnostic ignored "-Wparentheses-equality"
63#endif
64
65extern DeclarationNode * parseTree;
66extern ast::Linkage::Spec linkage;
67extern TypedefTable typedefTable;
68
69stack<ast::Linkage::Spec> linkageStack;
70
71bool appendStr( string & to, string & from ) {
72 // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
73 // "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
74 // the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
75 // easier to let the C compiler handle this case.
76 //
77 // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
78 // without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
79 // e.g., u"a" U"b" L"c" is disallowed.
80
81 if ( from[0] != '"' ) { // encoding ?
82 if ( to[0] != '"' ) { // encoding ?
83 if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
84 yyerror( "non-matching string encodings for string-literal concatenation" );
85 return false; // parse error, must call YYERROR in action
86 } else if ( from[1] == '8' ) {
87 from.erase( 0, 1 ); // remove 2nd encoding
88 } // if
89 } else {
90 if ( from[1] == '8' ) { // move encoding to start
91 to = "u8" + to;
92 from.erase( 0, 1 ); // remove 2nd encoding
93 } else {
94 to = from[0] + to;
95 } // if
96 } // if
97 from.erase( 0, 1 ); // remove 2nd encoding
98 } // if
99 to += " " + from; // concatenated into single string
100 return true;
101} // appendStr
102
103DeclarationNode * distTypeSpec( DeclarationNode * typeSpec, DeclarationNode * declList ) {
104 // Distribute type specifier across all declared variables, e.g., static, const, __attribute__.
105 assert( declList );
106
107 // Do not distribute attributes for aggregates because the attributes surrounding the aggregate belong it not the
108 // variables in the declaration list, e.g.,
109 //
110 // struct __attribute__(( aligned(128) )) S { ...
111 // } v1 __attribute__(( aligned(64) )), v2 __attribute__(( aligned(32) )), v3;
112 // struct S v4;
113 //
114 // v1 => 64, v2 =>32, v3 => 128, v2 => 128
115 //
116 // Anonymous aggregates are a special case because there is no aggregate to bind the attribute to; hence it floats
117 // to the declaration list.
118 //
119 // struct __attribute__(( aligned(128) )) /*anonymous */ { ... } v1;
120 //
121 // v1 => 128
122
123 bool copyattr = ! (typeSpec->type && typeSpec->type->kind == TypeData::Aggregate && ! typeSpec->type->aggregate.anon );
124
125 // addType copies the type information for the aggregate instances from typeSpec into cl's aggInst.aggregate.
126 DeclarationNode * cl = (new DeclarationNode)->addType( typeSpec ); // typeSpec IS DELETED!!!
127
128 // Start at second variable in declaration list and clone the type specifiers for each variable.
129 for ( DeclarationNode * cur = declList->next ; cur != nullptr; cur = cur->next ) {
130 cl->cloneBaseType( cur, copyattr ); // cur is modified
131 } // for
132
133 // Add first variable in declaration list with hidden type information in aggInst.aggregate, which is used by
134 // extractType to recover the type for the aggregate instances.
135 declList->addType( cl, copyattr ); // cl IS DELETED!!!
136 return declList;
137} // distTypeSpec
138
139void distAttr( DeclarationNode * attributes, DeclarationNode * declaration ) {
140 // distribute attributes across all declaring list
141 for ( DeclarationNode * attr = attributes; attr != nullptr ; attr = attr->next ) {
142 for ( DeclarationNode * decl = declaration ; decl != nullptr ; decl = decl->next ) {
143 decl->attributes.insert( decl->attributes.begin(), attr->attributes.begin(), attr->attributes.end() );
144 } // for
145 } // for
146} // distAttr
147
148void distExt( DeclarationNode * declaration ) {
149 // distribute EXTENSION across all declarations
150 for ( DeclarationNode * decl = declaration ; decl != nullptr ; decl = decl->next ) {
151 decl->set_extension( true );
152 } // for
153} // distExt
154
155void distInl( DeclarationNode * declaration ) {
156 // distribute INLINE across all declarations
157 for ( DeclarationNode * decl = declaration ; decl != nullptr ; decl = decl->next ) {
158 decl->set_inLine( true );
159 } // for
160} // distInl
161
162void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
163 // distribute qualifiers across all non-variable declarations in a distribution statemement
164 for ( DeclarationNode * decl = declaration ; decl != nullptr ; decl = decl->next ) {
165 // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
166 // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
167 // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
168 // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
169 DeclarationNode * clone = qualifiers->clone();
170 if ( qualifiers->type ) { // forall clause ? (handles SC)
171 if ( decl->type->kind == TypeData::Aggregate ) { // struct/union ?
172 swap( clone->type->forall, decl->type->aggregate.params );
173 decl->addQualifiers( clone );
174 } else if ( decl->type->kind == TypeData::AggregateInst && decl->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
175 // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
176 DeclarationNode newnode;
177 swap( newnode.type, decl->type->aggInst.aggregate );
178 swap( clone->type->forall, newnode.type->aggregate.params );
179 newnode.addQualifiers( clone );
180 swap( newnode.type, decl->type->aggInst.aggregate );
181 } else if ( decl->type->kind == TypeData::Function ) { // routines ?
182 swap( clone->type->forall, decl->type->forall );
183 decl->addQualifiers( clone );
184 } // if
185 } else { // just SC qualifiers
186 decl->addQualifiers( clone );
187 } // if
188 } // for
189 delete qualifiers;
190} // distQual
191
192// There is an ambiguity for inline generic-routine return-types and generic routines.
193// forall( otype T ) struct S { int i; } bar( T ) {}
194// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
195// forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
196// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
197// forall( otype T ) struct S { int T; };
198// forall( otype W ) bar( W ) {}
199
200void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
201 if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
202 funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
203 declSpec->type->aggregate.params = nullptr;
204 } // if
205} // rebindForall
206
207string * build_postfix_name( string * name ) {
208 *name = string("__postfix_func_") + *name;
209 return name;
210} // build_postfix_name
211
212DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
213 if ( fieldList == nullptr ) {
214 if ( !( typeSpec->type && typeSpec->type->kind == TypeData::Aggregate ) ) { // int; no fieldList
215 // printf( "fieldDecl1 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
216 SemanticWarning( yylloc, Warning::SuperfluousDecl );
217 return nullptr;
218 } // if
219 // printf( "fieldDecl2 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
220 fieldList = DeclarationNode::newName( nullptr ); // struct S { ... } no fieldList
221 } // if
222
223 // printf( "fieldDecl3 typeSpec %p\n", typeSpec ); typeSpec->print( std::cout, 0 );
224 DeclarationNode * temp = distTypeSpec( typeSpec, fieldList ); // mark all fields in list
225 // printf( "fieldDecl4 temp %p\n", temp ); temp->print( std::cout, 0 );
226 return temp;
227} // fieldDecl
228
229#define NEW_ZERO new ExpressionNode( build_constantInteger( yylloc, *new string( "0" ) ) )
230#define NEW_ONE new ExpressionNode( build_constantInteger( yylloc, *new string( "1" ) ) )
231#define UPDOWN( compop, left, right ) (compop == OperKinds::LThan || compop == OperKinds::LEThan || compop == OperKinds::Neq ? left : right)
232#define MISSING_ANON_FIELD "illegal syntax, missing loop fields with an anonymous loop index is meaningless as loop index is unavailable in loop body."
233#define MISSING_LOW "illegal syntax, missing low value for ascanding range so index is uninitialized."
234#define MISSING_HIGH "illegal syntax, missing high value for descending range so index is uninitialized."
235
236static ForCtrl * makeForCtrl( const CodeLocation & location, DeclarationNode * init, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
237 // Wrap both comp/inc if they are non-null.
238 if ( comp ) comp = new ExpressionNode( build_binary_val( location,
239 compop,
240 new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
241 comp ) );
242 if ( inc ) inc = new ExpressionNode( build_binary_val( location,
243 // choose += or -= for upto/downto
244 UPDOWN( compop, OperKinds::PlusAssn, OperKinds::MinusAssn ),
245 new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
246 inc ) );
247 // The StatementNode call frees init->name, it must happen later.
248 return new ForCtrl( new StatementNode( init ), comp, inc );
249}
250
251ForCtrl * forCtrl( const CodeLocation & location, DeclarationNode * index, ExpressionNode * start, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
252 if ( index->initializer ) {
253 SemanticError( yylloc, "illegal syntax, direct initialization disallowed. Use instead: type var; initialization ~ comparison ~ increment." );
254 } // if
255 if ( index->next ) {
256 SemanticError( yylloc, "illegal syntax, multiple loop indexes disallowed in for-loop declaration." );
257 } // if
258 DeclarationNode * initDecl = index->addInitializer( new InitializerNode( start ) );
259 return makeForCtrl( location, initDecl, compop, comp, inc );
260} // forCtrl
261
262ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, string * index, ExpressionNode * start, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
263 ast::ConstantExpr * constant = dynamic_cast<ast::ConstantExpr *>(type->expr.get());
264 if ( constant && (constant->rep == "0" || constant->rep == "1") ) {
265 type = new ExpressionNode( new ast::CastExpr( location, maybeMoveBuild(type), new ast::BasicType( ast::BasicKind::SignedInt ) ) );
266 } // if
267 DeclarationNode * initDecl = distTypeSpec(
268 DeclarationNode::newTypeof( type, true ),
269 DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) )
270 );
271 return makeForCtrl( location, initDecl, compop, comp, inc );
272} // forCtrl
273
274#define MISSING_LOOP_INDEX "illegal syntax, only a single identifier or declaration allowed in initialization, e.g., for ( i; ... ) or for ( int i; ... ). Expression disallowed."
275
276ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
277 if ( auto identifier = dynamic_cast<ast::NameExpr *>(index->expr.get()) ) {
278 return forCtrl( location, type, new string( identifier->name ), start, compop, comp, inc );
279 } else {
280 SemanticError( yylloc, MISSING_LOOP_INDEX ); return nullptr;
281 } // if
282} // forCtrl
283
284ForCtrl * enumRangeCtrl( ExpressionNode * index_expr, OperKinds compop, ExpressionNode * range_over_expr, DeclarationNode * type ) {
285 assert( compop == OperKinds::LEThan || compop == OperKinds::GEThan );
286 if ( auto identifier = dynamic_cast<ast::NameExpr *>(index_expr->expr.get()) ) {
287 DeclarationNode * indexDecl =
288 DeclarationNode::newName( new std::string(identifier->name) )->addType( type );
289 return new ForCtrl( new StatementNode( indexDecl ), range_over_expr, compop );
290 } else {
291 SemanticError( yylloc, MISSING_LOOP_INDEX ); return nullptr;
292 } // if
293} // enumRangeCtrl
294
295static void IdentifierBeforeIdentifier( string & identifier1, string & identifier2, const char * kind ) {
296 SemanticError( yylloc, "illegal syntax, adjacent identifiers \"%s\" and \"%s\" are not meaningful in an %s.\n"
297 "Possible cause is misspelled type name or missing generic parameter.",
298 identifier1.c_str(), identifier2.c_str(), kind );
299} // IdentifierBeforeIdentifier
300
301static void IdentifierBeforeType( string & identifier, const char * kind ) {
302 SemanticError( yylloc, "illegal syntax, identifier \"%s\" cannot appear before a %s.\n"
303 "Possible cause is misspelled storage/CV qualifier, misspelled typename, or missing generic parameter.",
304 identifier.c_str(), kind );
305} // IdentifierBeforeType
306
307bool forall = false; // aggregate have one or more forall qualifiers ?
308
309// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
310#define YYLLOC_DEFAULT(Cur, Rhs, N) \
311if ( N ) { \
312 (Cur).first_line = YYRHSLOC( Rhs, 1 ).first_line; \
313 (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column; \
314 (Cur).last_line = YYRHSLOC( Rhs, N ).last_line; \
315 (Cur).last_column = YYRHSLOC( Rhs, N ).last_column; \
316 (Cur).filename = YYRHSLOC( Rhs, 1 ).filename; \
317} else { \
318 (Cur).first_line = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line; \
319 (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column; \
320 (Cur).filename = YYRHSLOC( Rhs, 0 ).filename; \
321}
322%}
323
324%define parse.error verbose
325
326// Types declaration for productions
327
328%union {
329 // A raw token can be used.
330 Token tok;
331
332 // The general node types hold some generic node or list of nodes.
333 DeclarationNode * decl;
334 InitializerNode * init;
335 ExpressionNode * expr;
336 StatementNode * stmt;
337 ClauseNode * clause;
338 TypeData * type;
339
340 // Special "nodes" containing compound information.
341 CondCtrl * ifctrl;
342 ForCtrl * forctrl;
343 LabelNode * labels;
344
345 // Various flags and single values that become fields later.
346 ast::AggregateDecl::Aggregate aggKey;
347 ast::TypeDecl::Kind tclass;
348 OperKinds oper;
349 bool is_volatile;
350 EnumHiding enum_hiding;
351 ast::ExceptionKind except_kind;
352 // String passes ownership with it.
353 std::string * str;
354
355 // Narrower node types are used to avoid constant unwrapping.
356 ast::WaitForStmt * wfs;
357 ast::WaitUntilStmt::ClauseNode * wucn;
358 ast::GenericExpr * genexpr;
359}
360
361// ************************ TERMINAL TOKENS ********************************
362
363// keywords
364%token TYPEDEF
365%token EXTERN STATIC AUTO REGISTER
366%token THREADLOCALGCC THREADLOCALC11 // GCC, C11
367%token INLINE FORTRAN // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
368%token NORETURN // C11
369%token CONST VOLATILE
370%token RESTRICT // C99
371%token ATOMIC // C11
372%token FORALL MUTEX VIRTUAL VTABLE COERCE // CFA
373%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
374%token BOOL COMPLEX IMAGINARY // C99
375%token INT128 UINT128 FLOAT80 uuFLOAT128 // GCC
376%token FLOAT16 FLOAT32 FLOAT32X FLOAT64 FLOAT64X FLOAT128 FLOAT128X // GCC
377%token FLOAT32X4 FLOAT64X2 SVFLOAT32 SVFLOAT64 SVBOOL // GCC (ARM)
378%token DECIMAL32 DECIMAL64 DECIMAL128 // GCC
379%token ZERO_T ONE_T // CFA
380%token SIZEOF TYPEOF VA_LIST VA_ARG AUTO_TYPE COUNTOF // GCC
381%token OFFSETOF BASETYPEOF TYPEID // CFA
382%token ENUM STRUCT UNION
383%token EXCEPTION // CFA
384%token GENERATOR COROUTINE MONITOR THREAD // CFA
385%token OTYPE FTYPE DTYPE TTYPE TRAIT // CFA
386// %token RESUME // CFA
387%token LABEL // GCC
388%token SUSPEND // CFA
389%token ATTRIBUTE EXTENSION // GCC
390%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
391%token CHOOSE FALLTHROUGH WITH WHEN WAITFOR WAITUNTIL // CFA
392%token CORUN COFOR
393%token DISABLE ENABLE TRY THROW THROWRESUME AT // CFA
394%token ASM // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
395%token ALIGNAS ALIGNOF GENERIC STATICASSERT // C11
396
397// names and constants: lexer differentiates between identifier and typedef names
398%token<tok> IDENTIFIER TYPEDIMname TYPEDEFname TYPEGENname
399%token<tok> TIMEOUT WAND WOR CATCH RECOVER CATCHRESUME FIXUP FINALLY // CFA
400%token<tok> INTEGERconstant CHARACTERconstant STRINGliteral
401%token<tok> DIRECTIVE C23_ATTRIBUTE
402// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
403// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
404// converted into the tuple index (.)(1). e.g., 3.x
405%token<tok> FLOATING_DECIMALconstant FLOATING_FRACTIONconstant FLOATINGconstant
406
407// multi-character operators
408%token ARROW // ->
409%token ICR DECR // ++ --
410%token LS RS // << >>
411%token LE GE EQ NE // <= >= == !=
412%token ANDAND OROR // && ||
413%token ATTR ELLIPSIS // @@ ...
414
415%token EXPassign MULTassign DIVassign MODassign // \= *= /= %=
416%token PLUSassign MINUSassign // += -=
417%token LSassign RSassign // <<= >>=
418%token ANDassign ERassign ORassign // &= ^= |=
419
420%token ErangeUpLt ErangeUpLe ErangeEq ErangeNe // +~ +~=/~= ~== ~!=
421%token ErangeDownGt ErangeDownGe ErangeDownEq ErangeDownNe // -~ -~= -~== -~!=
422%token ATassign // @=
423
424%type<tok> identifier identifier_at identifier_or_type_name attr_name
425%type<tok> quasi_keyword
426%type<expr> string_literal
427%type<str> string_literal_list
428
429%type<enum_hiding> hide_opt visible_hide_opt
430
431// expressions
432%type<expr> constant
433%type<expr> tuple tuple_expression_list
434%type<oper> ptrref_operator unary_operator assignment_operator simple_assignment_operator compound_assignment_operator
435%type<expr> primary_expression postfix_expression unary_expression
436%type<expr> cast_expression_list cast_expression exponential_expression multiplicative_expression additive_expression
437%type<expr> shift_expression relational_expression equality_expression
438%type<expr> AND_expression exclusive_OR_expression inclusive_OR_expression
439%type<expr> logical_AND_expression logical_OR_expression
440%type<expr> conditional_expression constant_expression assignment_expression assignment_expression_opt
441%type<expr> comma_expression comma_expression_opt
442%type<expr> argument_expression_list_opt argument_expression_list argument_expression default_initializer_opt
443%type<ifctrl> conditional_declaration
444%type<forctrl> for_control_expression for_control_expression_list
445%type<oper> upupeq updown updownS updownEq
446%type<expr> subrange
447%type<decl> asm_name_opt
448%type<expr> asm_operands_opt asm_operands_list asm_operand
449%type<labels> asm_label_list
450%type<expr> asm_clobbers_list_opt
451%type<is_volatile> asm_volatile_opt
452%type<expr> handler_predicate_opt
453%type<genexpr> generic_association generic_assoc_list
454
455// statements
456%type<stmt> statement labelled_statement compound_statement
457%type<stmt> statement_decl statement_decl_list statement_list_nodecl
458%type<stmt> selection_statement
459%type<clause> switch_clause_list_opt switch_clause_list
460%type<expr> case_value
461%type<clause> case_clause case_value_list case_label case_label_list
462%type<stmt> iteration_statement jump_statement
463%type<stmt> expression_statement asm_statement
464%type<stmt> with_statement
465%type<expr> with_clause_opt
466%type<stmt> corun_statement cofor_statement
467%type<stmt> exception_statement
468%type<clause> handler_clause finally_clause
469%type<except_kind> handler_key
470%type<stmt> mutex_statement
471%type<expr> when_clause when_clause_opt waitfor waituntil timeout
472%type<stmt> waitfor_statement waituntil_statement
473%type<wfs> wor_waitfor_clause
474%type<wucn> waituntil_clause wand_waituntil_clause wor_waituntil_clause
475
476// declarations
477%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
478%type<decl> abstract_parameter_declarator_opt abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array
479 abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension abstract_parameter_declaration
480
481%type<aggKey> aggregate_key aggregate_data aggregate_control
482%type<decl> aggregate_type aggregate_type_nobody
483
484%type<decl> assertion assertion_list assertion_list_opt
485
486%type<expr> bit_subrange_size_opt bit_subrange_size
487
488%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
489%type<type> basic_type_name_type
490%type<type> vtable vtable_opt default_opt
491
492%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
493
494%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
495%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
496
497%type<decl> elaborated_type elaborated_type_nobody
498
499%type<decl> enumerator_list enum_type enum_type_nobody enum_key enumerator_type
500%type<init> enumerator_value_opt
501
502%type<decl> external_definition external_definition_list external_definition_list_opt
503
504%type<decl> exception_declaration
505
506%type<decl> field_declaration_list_opt field_declaration field_declaring_list field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
507%type<expr> field field_name_list field_name fraction_constants_opt
508
509%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
510
511%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
512%type<decl> identifier_list
513
514%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
515%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
516%type<decl> cfa_abstract_ptr cfa_abstract_tuple
517
518%type<decl> cfa_array_parameter_1st_dimension
519
520%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
521%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
522
523%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
524%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
525
526%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_list_ellipsis_opt
527
528%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
529
530%type<decl> c_declaration static_assert
531%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
532%type<decl> KR_parameter_list KR_parameter_list_opt
533
534%type<decl> parameter_declaration parameter_list parameter_list_ellipsis_opt
535
536%type<decl> paren_identifier paren_type
537
538%type<decl> storage_class storage_class_list
539
540%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
541
542%type<tclass> type_class new_type_class
543%type<decl> type_declarator type_declarator_name type_declaring_list
544
545%type<decl> type_declaration_specifier type_type_specifier
546%type<type> type_name typegen_name
547%type<decl> typedef_name typedef_declaration typedef_expression
548
549%type<decl> variable_type_redeclarator variable_type_ptr variable_type_array variable_type_function
550%type<decl> general_function_declarator function_type_redeclarator function_type_array function_type_no_ptr function_type_ptr
551
552%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
553
554%type<decl> type type_no_function
555%type<decl> type_parameter type_parameter_list type_initializer_opt
556
557%type<expr> type_parameters_opt type_list array_type_list // array_dimension_list
558
559%type<decl> type_qualifier forall type_qualifier_list_opt type_qualifier_list
560%type<type> type_qualifier_name
561%type<decl> type_specifier type_specifier_nobody
562
563%type<decl> variable_declarator variable_ptr variable_array variable_function
564%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
565
566%type<decl> attribute_list_opt attribute_list attribute attribute_name_list attribute_name
567
568// initializers
569%type<init> initializer initializer_list_opt initializer_opt
570
571// designators
572%type<expr> designator designator_list designation
573
574
575// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
576// .---------. matches IF '(' comma_expression ')' statement . (reduce)
577// if ( C ) S1 else S2
578// `-----------------' matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
579// Similar issues exit with the waitfor statement.
580
581// Order of these lines matters (low-to-high precedence). THEN is left associative over WAND/WOR/TIMEOUT/ELSE, WAND/WOR
582// is left associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
583%precedence THEN // rule precedence for IF/WAITFOR statement
584%precedence ANDAND // token precedence for start of WAND in WAITFOR statement
585%precedence WAND // token precedence for start of WAND in WAITFOR statement
586%precedence OROR // token precedence for start of WOR in WAITFOR statement
587%precedence WOR // token precedence for start of WOR in WAITFOR statement
588%precedence TIMEOUT // token precedence for start of TIMEOUT in WAITFOR statement
589%precedence CATCH // token precedence for start of TIMEOUT in WAITFOR statement
590%precedence RECOVER // token precedence for start of TIMEOUT in WAITFOR statement
591%precedence CATCHRESUME // token precedence for start of TIMEOUT in WAITFOR statement
592%precedence FIXUP // token precedence for start of TIMEOUT in WAITFOR statement
593%precedence FINALLY // token precedence for start of TIMEOUT in WAITFOR statement
594%precedence ELSE // token precedence for start of else clause in IF/WAITFOR statement
595
596
597// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
598// forall( otype T ) struct Foo { T v; };
599// .-----. matches pointer to function returning a generic (which is impossible without a type)
600// Foo ( *fp )( int );
601// `---' matches start of TYPEGENname '('
602// must be:
603// Foo( int ) ( *fp )( int );
604// The same problem occurs here:
605// forall( otype T ) struct Foo { T v; } ( *fp )( int );
606// must be:
607// forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
608
609// Order of these lines matters (low-to-high precedence).
610%precedence TYPEGENname
611%precedence '}'
612%precedence '('
613
614// %precedence RESUME
615// %precedence '{'
616// %precedence ')'
617
618%locations // support location tracking for error messages
619
620%start translation_unit // parse-tree root
621
622%%
623// ************************ Namespace Management ********************************
624
625// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
626// which are lexically identical.
627//
628// typedef int foo; // identifier foo must now be scanned as TYPEDEFname
629// foo f; // to allow it to appear in this context
630//
631// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
632// between syntactic and semantic constructs. Cforall compounds this problem by introducing type names local to the
633// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
634// generators" -- parameterized types. This latter type name creates a third class of identifiers, "TYPEGENname", which
635// must be distinguished by the lexical scanner.
636//
637// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
638// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
639// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
640// each context that introduces a name scope, a new level is created in the type table and that level is popped on
641// exiting the scope. Since type names can be local to a particular declaration, each declaration is itself a scope.
642// This requires distinguishing between type names that are local to the current declaration scope and those that
643// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
644//
645// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
646// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
647// around the list separator.
648//
649// XXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
650// push pop push pop
651
652push:
653 { typedefTable.enterScope(); }
654 ;
655
656pop:
657 { typedefTable.leaveScope(); }
658 ;
659
660// ************************ CONSTANTS ********************************
661
662constant:
663 // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
664 INTEGERconstant { $$ = new ExpressionNode( build_constantInteger( yylloc, *$1 ) ); }
665 | FLOATING_DECIMALconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
666 | FLOATING_FRACTIONconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
667 | FLOATINGconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
668 | CHARACTERconstant { $$ = new ExpressionNode( build_constantChar( yylloc, *$1 ) ); }
669 ;
670
671quasi_keyword: // CFA
672 TIMEOUT
673 | WAND
674 | WOR
675 | CATCH
676 | RECOVER
677 | CATCHRESUME
678 | FIXUP
679 | FINALLY
680 ;
681
682identifier:
683 IDENTIFIER
684 | quasi_keyword
685 ;
686
687identifier_at:
688 identifier
689 | '@' // CFA
690 { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
691 ;
692
693identifier_or_type_name:
694 identifier
695 | TYPEDEFname
696 | TYPEGENname
697 ;
698
699string_literal:
700 string_literal_list { $$ = new ExpressionNode( build_constantStr( yylloc, *$1 ) ); }
701 ;
702
703string_literal_list: // juxtaposed strings are concatenated
704 STRINGliteral { $$ = $1; } // conversion from tok to str
705 | string_literal_list STRINGliteral
706 {
707 if ( ! appendStr( *$1, *$2 ) ) YYERROR; // append 2nd juxtaposed string to 1st
708 delete $2; // allocated by lexer
709 $$ = $1; // conversion from tok to str
710 }
711 ;
712
713// ************************ EXPRESSIONS ********************************
714
715primary_expression:
716 IDENTIFIER // typedef name cannot be used as a variable name
717 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
718 | quasi_keyword
719 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
720 | TYPEDIMname // CFA, generic length argument
721 { $$ = new ExpressionNode( build_dimensionref( yylloc, $1 ) ); }
722 | tuple
723 | '(' comma_expression ')'
724 { $$ = $2; }
725 | '(' compound_statement ')' // GCC, lambda expression
726 { $$ = new ExpressionNode( new ast::StmtExpr( yylloc, dynamic_cast<ast::CompoundStmt *>( maybeMoveBuild( $2 ) ) ) ); }
727 | type_name '.' identifier // CFA, nested type
728 { $$ = new ExpressionNode( build_qualified_expr( yylloc, DeclarationNode::newFromTypeData( $1 ), build_varref( yylloc, $3 ) ) ); }
729 | type_name '.' '[' field_name_list ']' // CFA, nested type / tuple field selector
730 { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
731 | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
732 {
733 // add the missing control expression to the GenericExpr and return it
734 $5->control = maybeMoveBuild( $3 );
735 $$ = new ExpressionNode( $5 );
736 }
737 // | RESUME '(' comma_expression ')'
738 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
739 // | RESUME '(' comma_expression ')' compound_statement
740 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
741 | IDENTIFIER IDENTIFIER // invalid syntax rule
742 { IdentifierBeforeIdentifier( *$1.str, *$2.str, "expression" ); $$ = nullptr; }
743 | IDENTIFIER type_qualifier // invalid syntax rule
744 { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
745 | IDENTIFIER storage_class // invalid syntax rule
746 { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
747 | IDENTIFIER basic_type_name // invalid syntax rule
748 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
749 | IDENTIFIER TYPEDEFname // invalid syntax rule
750 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
751 | IDENTIFIER TYPEGENname // invalid syntax rule
752 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
753 ;
754
755generic_assoc_list: // C11
756 generic_association
757 | generic_assoc_list ',' generic_association
758 {
759 // steal the association node from the singleton and delete the wrapper
760 assert( 1 == $3->associations.size() );
761 $1->associations.push_back( $3->associations.front() );
762 delete $3;
763 $$ = $1;
764 }
765 ;
766
767generic_association: // C11
768 type_no_function ':' assignment_expression
769 {
770 // create a GenericExpr wrapper with one association pair
771 $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuildType( $1 ), maybeMoveBuild( $3 ) } } );
772 }
773 | DEFAULT ':' assignment_expression
774 { $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuild( $3 ) } } ); }
775 ;
776
777postfix_expression:
778 primary_expression
779 | postfix_expression '[' tuple_expression_list ']' // CFA
780 // Historic, transitional: Disallow commas in subscripts.
781 // Switching to this behaviour may help check if a C compatibilty case uses comma-exprs in subscripts.
782 // Current: Commas in subscripts make tuples.
783 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, new ExpressionNode( build_tuple( yylloc, $3 ) ) ) ); }
784 | constant '[' assignment_expression ']' // 3[a], 'a'[a], 3.5[a]
785 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
786 | string_literal '[' assignment_expression ']' // "abc"[3], 3["abc"]
787 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
788 | postfix_expression '{' argument_expression_list_opt '}' // CFA, constructor call
789 {
790 Token fn;
791 fn.str = new std::string( "?{}" ); // location undefined - use location of '{'?
792 $$ = new ExpressionNode( new ast::ConstructorExpr( yylloc, build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), $1->set_last( $3 ) ) ) );
793 }
794 | postfix_expression '(' argument_expression_list_opt ')'
795 { $$ = new ExpressionNode( build_func( yylloc, $1, $3 ) ); }
796 | VA_ARG '(' primary_expression ',' declaration_specifier_nobody abstract_parameter_declarator_opt ')'
797 { $$ = new ExpressionNode( build_va_arg( yylloc, $3, ( $6 ? $6->addType( $5 ) : $5 ) ) ); }
798 | postfix_expression '`' identifier // CFA, postfix call
799 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
800 | constant '`' identifier // CFA, postfix call
801 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
802 | string_literal '`' identifier // CFA, postfix call
803 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
804
805 // SKULLDUGGERY: The typedef table used for parsing does not store fields in structures. To parse a qualified
806 // name, it is assumed all name-tokens after the first are identifiers, regardless of how the lexer identifies
807 // them. For example:
808 //
809 // struct S;
810 // forall(T) struct T;
811 // union U;
812 // enum E { S, T, E };
813 // struct Z { int S, T, Z, E, U; };
814 // void fred () {
815 // Z z;
816 // z.S; // lexer returns S is TYPEDEFname
817 // z.T; // lexer returns T is TYPEGENname
818 // z.Z; // lexer returns Z is TYPEDEFname
819 // z.U; // lexer returns U is TYPEDEFname
820 // z.E; // lexer returns E is TYPEDEFname
821 // }
822 | postfix_expression '.' identifier_or_type_name
823 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
824
825 | postfix_expression '.' INTEGERconstant // CFA, tuple index
826 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
827 | postfix_expression FLOATING_FRACTIONconstant // CFA, tuple index
828 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 ) ) ); }
829 | postfix_expression '.' '[' field_name_list ']' // CFA, tuple field selector
830 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
831 | postfix_expression '.' aggregate_control
832 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $3, $1 ) ); }
833 | postfix_expression ARROW identifier
834 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
835 | postfix_expression ARROW INTEGERconstant // CFA, tuple index
836 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
837 | postfix_expression ARROW '[' field_name_list ']' // CFA, tuple field selector
838 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
839 | postfix_expression ICR
840 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::IncrPost, $1 ) ); }
841 | postfix_expression DECR
842 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::DecrPost, $1 ) ); }
843 | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
844 { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, new InitializerNode( $5, true ) ) ); }
845 | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
846 { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
847 | '^' primary_expression '{' argument_expression_list_opt '}' // CFA, destructor call
848 {
849 Token fn;
850 fn.str = new string( "^?{}" ); // location undefined
851 $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), $2->set_last( $4 ) ) );
852 }
853 ;
854
855field_name_list: // CFA, tuple field selector
856 field
857 | field_name_list ',' field { $$ = $1->set_last( $3 ); }
858 ;
859
860field: // CFA, tuple field selector
861 field_name
862 | FLOATING_DECIMALconstant field
863 { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), maybeMoveBuild( $2 ) ) ); }
864 | FLOATING_DECIMALconstant '[' field_name_list ']'
865 { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), build_tuple( yylloc, $3 ) ) ); }
866 | field_name '.' field
867 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
868 | field_name '.' '[' field_name_list ']'
869 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
870 | field_name ARROW field
871 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
872 | field_name ARROW '[' field_name_list ']'
873 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
874 ;
875
876field_name:
877 INTEGERconstant fraction_constants_opt
878 { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_constantInteger( yylloc, *$1 ), $2 ) ); }
879 | FLOATINGconstant fraction_constants_opt
880 { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_field_name_FLOATINGconstant( yylloc, *$1 ), $2 ) ); }
881 | identifier_at fraction_constants_opt // CFA, allow anonymous fields
882 {
883 $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_varref( yylloc, $1 ), $2 ) );
884 }
885 ;
886
887fraction_constants_opt:
888 // empty
889 { $$ = nullptr; }
890 | fraction_constants_opt FLOATING_FRACTIONconstant
891 {
892 ast::Expr * constant = build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 );
893 $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( yylloc, $1, constant ) ) : new ExpressionNode( constant );
894 }
895 ;
896
897unary_expression:
898 postfix_expression
899 // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
900 // semantics checks, e.g., ++3, 3--, *3, &&3
901 | constant
902 | string_literal
903 { $$ = $1; }
904 | EXTENSION cast_expression // GCC
905 { $$ = $2->set_extension( true ); }
906 // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
907 // { * X; } // dereference X
908 // { * int X; } // CFA declaration of pointer to int
909 | ptrref_operator cast_expression // CFA
910 {
911 switch ( $1 ) {
912 case OperKinds::AddressOf:
913 $$ = new ExpressionNode( new ast::AddressExpr( maybeMoveBuild( $2 ) ) );
914 break;
915 case OperKinds::PointTo:
916 $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) );
917 break;
918 case OperKinds::And:
919 $$ = new ExpressionNode( new ast::AddressExpr( new ast::AddressExpr( maybeMoveBuild( $2 ) ) ) );
920 break;
921 default:
922 assert( false );
923 }
924 }
925 | unary_operator cast_expression
926 { $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) ); }
927 | ICR unary_expression
928 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Incr, $2 ) ); }
929 | DECR unary_expression
930 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Decr, $2 ) ); }
931 | SIZEOF unary_expression
932 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, new ast::TypeofType( maybeMoveBuild( $2 ) ) ) ); }
933 | SIZEOF '(' type_no_function ')'
934 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
935 | SIZEOF '(' attribute_list type_no_function ')'
936 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $4->addQualifiers( $3 ) ) ) ); }
937 | ALIGNOF unary_expression // GCC, variable alignment
938 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, new ast::TypeofType( maybeMoveBuild( $2 ) ) ) ); }
939 | ALIGNOF '(' type_no_function ')' // GCC, type alignment
940 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
941
942 // Cannot use rule "type", which includes cfa_abstract_function, for sizeof/alignof, because of S/R problems on
943 // look ahead, so the cfa_abstract_function is factored out.
944 | SIZEOF '(' cfa_abstract_function ')'
945 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
946 | ALIGNOF '(' cfa_abstract_function ')' // GCC, type alignment
947 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
948
949 | OFFSETOF '(' type_no_function ',' identifier ')'
950 { $$ = new ExpressionNode( build_offsetOf( yylloc, $3, build_varref( yylloc, $5 ) ) ); }
951 | TYPEID '(' type ')'
952 {
953 SemanticError( yylloc, "typeid name is currently unimplemented." ); $$ = nullptr;
954 // $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) );
955 }
956 | COUNTOF unary_expression
957 { $$ = new ExpressionNode( new ast::CountofExpr( yylloc, new ast::TypeofType( maybeMoveBuild( $2 ) ) ) ); }
958 | COUNTOF '(' type_no_function ')'
959 { $$ = new ExpressionNode( new ast::CountofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
960 ;
961
962ptrref_operator:
963 '*' { $$ = OperKinds::PointTo; }
964 | '&' { $$ = OperKinds::AddressOf; }
965 // GCC, address of label must be handled by semantic check for ref,ref,label
966 | ANDAND { $$ = OperKinds::And; }
967 ;
968
969unary_operator:
970 '+' { $$ = OperKinds::UnPlus; }
971 | '-' { $$ = OperKinds::UnMinus; }
972 | '!' { $$ = OperKinds::Neg; }
973 | '~' { $$ = OperKinds::BitNeg; }
974 ;
975
976cast_expression:
977 unary_expression
978 | '(' type_no_function ')' cast_expression
979 { $$ = new ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
980 | '(' aggregate_control '&' ')' cast_expression // CFA
981 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
982 | '(' aggregate_control '*' ')' cast_expression // CFA
983 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
984 | '(' VIRTUAL ')' cast_expression // CFA
985 { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $4 ), nullptr ) ); }
986 | '(' VIRTUAL type_no_function ')' cast_expression // CFA
987 { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $5 ), maybeMoveBuildType( $3 ) ) ); }
988 | '(' RETURN type_no_function ')' cast_expression // CFA (ASCRIPTION)
989 { $$ = new ExpressionNode( build_cast( yylloc, $3, $5, ast::ReturnCast ) ); }
990 | '(' COERCE type_no_function ')' cast_expression // CFA (COERCION)
991 { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
992 | '(' qualifier_cast_list ')' cast_expression // CFA, (modify CVs of cast_expression)
993 { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
994// | '(' type_no_function ')' tuple
995// { $$ = new ast::ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
996 ;
997
998qualifier_cast_list:
999 cast_modifier type_qualifier_name
1000 | cast_modifier MUTEX
1001 | qualifier_cast_list cast_modifier type_qualifier_name
1002 | qualifier_cast_list cast_modifier MUTEX
1003 ;
1004
1005cast_modifier:
1006 '-'
1007 | '+'
1008 ;
1009
1010exponential_expression:
1011 cast_expression
1012 | exponential_expression '\\' cast_expression
1013 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Exp, $1, $3 ) ); }
1014 ;
1015
1016multiplicative_expression:
1017 exponential_expression
1018 | multiplicative_expression '*' exponential_expression
1019 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mul, $1, $3 ) ); }
1020 | multiplicative_expression '/' exponential_expression
1021 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Div, $1, $3 ) ); }
1022 | multiplicative_expression '%' exponential_expression
1023 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mod, $1, $3 ) ); }
1024 ;
1025
1026additive_expression:
1027 multiplicative_expression
1028 | additive_expression '+' multiplicative_expression
1029 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Plus, $1, $3 ) ); }
1030 | additive_expression '-' multiplicative_expression
1031 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Minus, $1, $3 ) ); }
1032 ;
1033
1034shift_expression:
1035 additive_expression
1036 | shift_expression LS additive_expression
1037 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LShift, $1, $3 ) ); }
1038 | shift_expression RS additive_expression
1039 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::RShift, $1, $3 ) ); }
1040 ;
1041
1042relational_expression:
1043 shift_expression
1044 | relational_expression '<' shift_expression
1045 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LThan, $1, $3 ) ); }
1046 | relational_expression '>' shift_expression
1047 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GThan, $1, $3 ) ); }
1048 | relational_expression LE shift_expression
1049 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LEThan, $1, $3 ) ); }
1050 | relational_expression GE shift_expression
1051 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GEThan, $1, $3 ) ); }
1052 ;
1053
1054equality_expression:
1055 relational_expression
1056 | equality_expression EQ relational_expression
1057 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Eq, $1, $3 ) ); }
1058 | equality_expression NE relational_expression
1059 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Neq, $1, $3 ) ); }
1060 ;
1061
1062AND_expression:
1063 equality_expression
1064 | AND_expression '&' equality_expression
1065 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitAnd, $1, $3 ) ); }
1066 ;
1067
1068exclusive_OR_expression:
1069 AND_expression
1070 | exclusive_OR_expression '^' AND_expression
1071 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Xor, $1, $3 ) ); }
1072 ;
1073
1074inclusive_OR_expression:
1075 exclusive_OR_expression
1076 | inclusive_OR_expression '|' exclusive_OR_expression
1077 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitOr, $1, $3 ) ); }
1078 ;
1079
1080logical_AND_expression:
1081 inclusive_OR_expression
1082 | logical_AND_expression ANDAND inclusive_OR_expression
1083 { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::AndExpr ) ); }
1084 ;
1085
1086logical_OR_expression:
1087 logical_AND_expression
1088 | logical_OR_expression OROR logical_AND_expression
1089 { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::OrExpr ) ); }
1090 ;
1091
1092conditional_expression:
1093 logical_OR_expression
1094 | logical_OR_expression '?' comma_expression ':' conditional_expression
1095 { $$ = new ExpressionNode( build_cond( yylloc, $1, $3, $5 ) ); }
1096 | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
1097 { $$ = new ExpressionNode( build_cond( yylloc, $1, nullptr, $4 ) ); }
1098 ;
1099
1100constant_expression:
1101 conditional_expression
1102 ;
1103
1104argument_expression_list_opt:
1105 // empty
1106 { $$ = nullptr; }
1107 | argument_expression_list
1108 ;
1109
1110argument_expression_list:
1111 argument_expression
1112 // | argument_expression_list_opt ',' argument_expression // CFA, allow empty argument
1113 | argument_expression_list ',' argument_expression // no empty argument
1114 { $$ = $1->set_last( $3 ); }
1115 ;
1116
1117argument_expression:
1118 '?' // CFA, default parameter
1119 // { SemanticError( yylloc, "Argument to default parameter is currently unimplemented." ); $$ = nullptr; }
1120 { $$ = new ExpressionNode( build_constantInteger( yylloc, *new string( "2" ) ) ); }
1121 | '?' identifier '=' assignment_expression // CFA, keyword argument
1122 // { SemanticError( yylloc, "keyword argument is currently unimplemented." ); $$ = nullptr; }
1123 { $$ = $4; }
1124 | assignment_expression
1125 ;
1126
1127assignment_expression:
1128 // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
1129 conditional_expression
1130 | unary_expression assignment_operator assignment_expression
1131 {
1132// if ( $2 == OperKinds::AtAssn ) {
1133// SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
1134// } else {
1135 $$ = new ExpressionNode( build_binary_val( yylloc, $2, $1, $3 ) );
1136// } // if
1137 }
1138 | unary_expression '=' '{' initializer_list_opt comma_opt '}'
1139 { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
1140 ;
1141
1142assignment_expression_opt:
1143 // empty
1144 { $$ = nullptr; }
1145 | assignment_expression
1146 ;
1147
1148assignment_operator:
1149 simple_assignment_operator
1150 | compound_assignment_operator
1151 ;
1152
1153simple_assignment_operator:
1154 '=' { $$ = OperKinds::Assign; }
1155 | ATassign { $$ = OperKinds::AtAssn; } // CFA
1156 ;
1157
1158compound_assignment_operator:
1159 EXPassign { $$ = OperKinds::ExpAssn; }
1160 | MULTassign { $$ = OperKinds::MulAssn; }
1161 | DIVassign { $$ = OperKinds::DivAssn; }
1162 | MODassign { $$ = OperKinds::ModAssn; }
1163 | PLUSassign { $$ = OperKinds::PlusAssn; }
1164 | MINUSassign { $$ = OperKinds::MinusAssn; }
1165 | LSassign { $$ = OperKinds::LSAssn; }
1166 | RSassign { $$ = OperKinds::RSAssn; }
1167 | ANDassign { $$ = OperKinds::AndAssn; }
1168 | ERassign { $$ = OperKinds::ERAssn; }
1169 | ORassign { $$ = OperKinds::OrAssn; }
1170 ;
1171
1172tuple: // CFA, tuple
1173 // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
1174 // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
1175 '[' ',' ']'
1176 // { $$ = new ExpressionNode( build_tuple( yylloc, nullptr ) ); }
1177 { SemanticError( yylloc, "Empty tuple is meaningless." ); $$ = nullptr; }
1178 | '[' assignment_expression ',' ']'
1179 { $$ = new ExpressionNode( build_tuple( yylloc, $2 ) ); }
1180 | '[' '@' comma_opt ']'
1181 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1182 | '[' assignment_expression ',' tuple_expression_list comma_opt ']'
1183 { $$ = new ExpressionNode( build_tuple( yylloc, $2->set_last( $4 ) ) ); }
1184 | '[' '@' ',' tuple_expression_list comma_opt ']'
1185 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1186 ;
1187
1188tuple_expression_list:
1189 assignment_expression
1190 | '@' // CFA
1191 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1192 | tuple_expression_list ',' assignment_expression
1193 { $$ = $1->set_last( $3 ); }
1194 | tuple_expression_list ',' '@'
1195 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1196 ;
1197
1198comma_expression:
1199 assignment_expression
1200 | comma_expression ',' assignment_expression
1201 { $$ = new ExpressionNode( new ast::CommaExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1202 ;
1203
1204comma_expression_opt:
1205 // empty
1206 { $$ = nullptr; }
1207 | comma_expression
1208 ;
1209
1210// ************************** STATEMENTS *******************************
1211
1212statement:
1213 labelled_statement
1214 | compound_statement
1215 | expression_statement
1216 | selection_statement
1217 | iteration_statement
1218 | jump_statement
1219 | with_statement
1220 | mutex_statement
1221 | waitfor_statement
1222 | waituntil_statement
1223 | corun_statement
1224 | cofor_statement
1225 | exception_statement
1226 | enable_disable_statement
1227 { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1228 | asm_statement
1229 | DIRECTIVE
1230 { $$ = new StatementNode( build_directive( yylloc, $1 ) ); }
1231 ;
1232
1233labelled_statement:
1234 // labels cannot be identifiers 0 or 1
1235 identifier_or_type_name ':' attribute_list_opt statement
1236 { $$ = $4->add_label( yylloc, $1, $3 ); }
1237 | identifier_or_type_name ':' attribute_list_opt error // invalid syntax rule
1238 {
1239 SemanticError( yylloc, "syntx error, label \"%s\" must be associated with a statement, "
1240 "where a declaration, case, or default is not a statement.\n"
1241 "Move the label or terminate with a semicolon.", $1.str->c_str() );
1242 $$ = nullptr;
1243 }
1244 ;
1245
1246compound_statement:
1247 '{' '}'
1248 { $$ = new StatementNode( build_compound( yylloc, (StatementNode *)0 ) ); }
1249 | '{' push
1250 local_label_declaration_opt // GCC, local labels appear at start of block
1251 statement_decl_list // C99, intermix declarations and statements
1252 pop '}'
1253 { $$ = new StatementNode( build_compound( yylloc, $4 ) ); }
1254 ;
1255
1256statement_decl_list: // C99
1257 statement_decl
1258 | statement_decl_list statement_decl
1259 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1260 ;
1261
1262statement_decl:
1263 attribute_list_opt declaration // CFA, new & old style declarations
1264 { distAttr( $1, $2 ); $$ = new StatementNode( $2 ); }
1265 | attribute_list_opt EXTENSION declaration // GCC
1266 { distAttr( $1, $3 ); distExt( $3 ); $$ = new StatementNode( $3 ); }
1267 | attribute_list_opt function_definition
1268 { distAttr( $1, $2 ); $$ = new StatementNode( $2 ); }
1269 | attribute_list_opt EXTENSION function_definition // GCC
1270 { distAttr( $1, $3 ); distExt( $3 ); $$ = new StatementNode( $3 ); }
1271 | attribute_list_opt statement // FIX ME!
1272 { $$ = $2->addQualifiers( $1 ); }
1273 ;
1274
1275statement_list_nodecl:
1276 attribute_list_opt statement
1277 { $$ = $2->addQualifiers( $1 ); } // FIX ME!
1278 | statement_list_nodecl attribute_list_opt statement
1279 { assert( $1 ); $1->set_last( $3->addQualifiers( $2 ) ); $$ = $1; } // FIX ME!
1280 | statement_list_nodecl error // invalid syntax rule
1281 { SemanticError( yylloc, "illegal syntax, declarations only allowed at the start of the switch body,"
1282 " i.e., after the '{'." ); $$ = nullptr; }
1283 ;
1284
1285expression_statement: // expression or null statement
1286 comma_expression_opt ';'
1287 { $$ = new StatementNode( build_expr( yylloc, $1 ) ); }
1288 ;
1289
1290// "if", "switch", and "choose" require parenthesis around the conditional. See the following ambiguities without
1291// parenthesis:
1292//
1293// if x + y + z; => if ( x ) + y + z or if ( x + y ) + z
1294//
1295// switch O { }
1296//
1297// O{} => object-constructor for conditional, switch body ???
1298// O{} => O for conditional followed by switch body
1299//
1300// C++ has this problem, as it has the same constructor syntax.
1301//
1302// switch sizeof ( T ) { }
1303//
1304// sizeof ( T ) => sizeof of T for conditional followed by switch body
1305// sizeof ( T ) => sizeof of compound literal (T){ }, closing parenthesis ???
1306//
1307// Note the two grammar rules for sizeof (alignof)
1308//
1309// | SIZEOF unary_expression
1310// | SIZEOF '(' type_no_function ')'
1311//
1312// where the first DOES NOT require parenthesis! And C++ inherits this problem from C.
1313
1314selection_statement:
1315 IF '(' conditional_declaration ')' statement %prec THEN
1316 // explicitly deal with the shift/reduce conflict on if/else
1317 { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), nullptr ) ); }
1318 | IF '(' conditional_declaration ')' statement ELSE statement
1319 { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), maybe_build_compound( yylloc, $7 ) ) ); }
1320 | SWITCH '(' comma_expression ')' case_clause
1321 { $$ = new StatementNode( build_switch( yylloc, true, $3, $5 ) ); }
1322 | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1323 {
1324 StatementNode *sw = new StatementNode( build_switch( yylloc, true, $3, $8 ) );
1325 // The semantics of the declaration list is changed to include associated initialization, which is performed
1326 // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1327 // statement around the switch. Statements after the initial declaration list can never be executed, and
1328 // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1329 // statement.
1330 $$ = $7 ? new StatementNode( build_compound( yylloc, (new StatementNode( $7 ))->set_last( sw ) ) ) : sw;
1331 }
1332 | SWITCH '(' comma_expression ')' '{' error '}' // CFA, invalid syntax rule error
1333 { SemanticError( yylloc, "synatx error, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1334 | CHOOSE '(' comma_expression ')' case_clause // CFA
1335 { $$ = new StatementNode( build_switch( yylloc, false, $3, $5 ) ); }
1336 | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1337 {
1338 StatementNode *sw = new StatementNode( build_switch( yylloc, false, $3, $8 ) );
1339 $$ = $7 ? new StatementNode( build_compound( yylloc, (new StatementNode( $7 ))->set_last( sw ) ) ) : sw;
1340 }
1341 | CHOOSE '(' comma_expression ')' '{' error '}' // CFA, invalid syntax rule
1342 { SemanticError( yylloc, "illegal syntax, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1343 ;
1344
1345conditional_declaration:
1346 comma_expression
1347 { $$ = new CondCtrl( nullptr, $1 ); }
1348 | c_declaration // no semi-colon
1349 { $$ = new CondCtrl( $1, nullptr ); }
1350 | cfa_declaration // no semi-colon
1351 { $$ = new CondCtrl( $1, nullptr ); }
1352 | declaration comma_expression // semi-colon separated
1353 { $$ = new CondCtrl( $1, $2 ); }
1354 ;
1355
1356// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1357// clause allows a list of values and subranges.
1358
1359case_value: // CFA
1360 constant_expression { $$ = $1; }
1361 | constant_expression ELLIPSIS constant_expression // GCC, subrange
1362 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1363 | subrange // CFA, subrange
1364 ;
1365
1366case_value_list: // CFA
1367 case_value { $$ = new ClauseNode( build_case( yylloc, $1 ) ); }
1368 // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1369 | case_value_list ',' case_value { $$ = $1->set_last( new ClauseNode( build_case( yylloc, $3 ) ) ); }
1370 ;
1371
1372case_label: // CFA
1373 CASE error // invalid syntax rule
1374 { SemanticError( yylloc, "illegal syntax, case list missing after case." ); $$ = nullptr; }
1375 | CASE case_value_list ':' { $$ = $2; }
1376 | CASE case_value_list error // invalid syntax rule
1377 { SemanticError( yylloc, "illegal syntax, colon missing after case list." ); $$ = nullptr; }
1378 | DEFAULT ':' { $$ = new ClauseNode( build_default( yylloc ) ); }
1379 // A semantic check is required to ensure only one default clause per switch/choose statement.
1380 | DEFAULT error // invalid syntax rule
1381 { SemanticError( yylloc, "illegal syntax, colon missing after default." ); $$ = nullptr; }
1382 ;
1383
1384case_label_list: // CFA
1385 case_label
1386 | case_label_list case_label { $$ = $1->set_last( $2 ); }
1387 ;
1388
1389case_clause: // CFA
1390 case_label_list statement { $$ = $1->append_last_case( maybe_build_compound( yylloc, $2 ) ); }
1391 ;
1392
1393switch_clause_list_opt: // CFA
1394 // empty
1395 { $$ = nullptr; }
1396 | switch_clause_list
1397 ;
1398
1399switch_clause_list: // CFA
1400 case_label_list statement_list_nodecl
1401 { $$ = $1->append_last_case( new StatementNode( build_compound( yylloc, $2 ) ) ); }
1402 | switch_clause_list case_label_list statement_list_nodecl
1403 { $$ = $1->set_last( $2->append_last_case( new StatementNode( build_compound( yylloc, $3 ) ) ) ); }
1404 ;
1405
1406iteration_statement:
1407 WHILE '(' ')' statement %prec THEN // CFA => while ( 1 )
1408 { $$ = new StatementNode( build_while( yylloc, new CondCtrl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) ); }
1409 | WHILE '(' ')' statement ELSE statement // CFA
1410 {
1411 $$ = new StatementNode( build_while( yylloc, new CondCtrl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) );
1412 SemanticWarning( yylloc, Warning::SuperfluousElse );
1413 }
1414 | WHILE '(' conditional_declaration ')' statement %prec THEN
1415 { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1416 | WHILE '(' conditional_declaration ')' statement ELSE statement // CFA
1417 { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1418 | DO statement WHILE '(' ')' ';' // CFA => do while( 1 )
1419 { $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) ); }
1420 | DO statement WHILE '(' ')' ELSE statement // CFA
1421 {
1422 $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) );
1423 SemanticWarning( yylloc, Warning::SuperfluousElse );
1424 }
1425 | DO statement WHILE '(' comma_expression ')' ';'
1426 { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ) ) ); }
1427 | DO statement WHILE '(' comma_expression ')' ELSE statement // CFA
1428 { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ), $8 ) ); }
1429 | FOR '(' ')' statement %prec THEN // CFA => for ( ;; )
1430 { $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) ); }
1431 | FOR '(' ')' statement ELSE statement // CFA
1432 {
1433 $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) );
1434 SemanticWarning( yylloc, Warning::SuperfluousElse );
1435 }
1436 | FOR '(' for_control_expression_list ')' statement %prec THEN
1437 { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1438 | FOR '(' for_control_expression_list ')' statement ELSE statement // CFA
1439 { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1440 ;
1441
1442for_control_expression_list:
1443 for_control_expression
1444 | for_control_expression_list ':' for_control_expression
1445 // ForCtrl + ForCtrl:
1446 // init + init => multiple declaration statements that are hoisted
1447 // condition + condition => (expression) && (expression)
1448 // change + change => (expression), (expression)
1449 {
1450 $1->init->set_last( $3->init );
1451 if ( $1->condition ) {
1452 if ( $3->condition ) {
1453 $1->condition->expr.reset( new ast::LogicalExpr( yylloc, $1->condition->expr.release(), $3->condition->expr.release(), ast::AndExpr ) );
1454 } // if
1455 } else $1->condition = $3->condition;
1456 if ( $1->change ) {
1457 if ( $3->change ) {
1458 $1->change->expr.reset( new ast::CommaExpr( yylloc, $1->change->expr.release(), $3->change->expr.release() ) );
1459 } // if
1460 } else $1->change = $3->change;
1461 $$ = $1;
1462 }
1463 ;
1464
1465for_control_expression:
1466 ';' comma_expression_opt ';' comma_expression_opt
1467 { $$ = new ForCtrl( nullptr, $2, $4 ); }
1468 | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1469 {
1470 $$ = new ForCtrl( $1 ? new StatementNode( new ast::ExprStmt( yylloc, maybeMoveBuild( $1 ) ) ) : nullptr, $3, $5 );
1471 }
1472 | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1473 { $$ = new ForCtrl( new StatementNode( $1 ), $2, $4 ); }
1474
1475 | '@' ';' comma_expression // CFA, empty loop-index
1476 { $$ = new ForCtrl( nullptr, $3, nullptr ); }
1477 | '@' ';' comma_expression ';' comma_expression // CFA, empty loop-index
1478 { $$ = new ForCtrl( nullptr, $3, $5 ); }
1479
1480 | comma_expression // CFA, anonymous loop-index
1481 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), NEW_ZERO, OperKinds::LThan, $1->clone(), NEW_ONE ); }
1482 | updown comma_expression // CFA, anonymous loop-index
1483 { $$ = forCtrl( yylloc, $2, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $1, NEW_ZERO, $2->clone() ), $1, UPDOWN( $1, $2->clone(), NEW_ZERO ), NEW_ONE ); }
1484
1485 | comma_expression updownS comma_expression // CFA, anonymous loop-index
1486 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), NEW_ONE ); }
1487 | '@' updownS comma_expression // CFA, anonymous loop-index
1488 {
1489 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1490 else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, NEW_ONE );
1491 }
1492 | comma_expression updownS '@' // CFA, anonymous loop-index
1493 {
1494 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1495 else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1496 }
1497
1498 | comma_expression updownS comma_expression '~' comma_expression // CFA, anonymous loop-index
1499 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), $5 ); }
1500 | '@' updownS comma_expression '~' comma_expression // CFA, anonymous loop-index
1501 {
1502 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1503 else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, $5 );
1504 }
1505 | comma_expression updownS '@' '~' comma_expression // CFA, anonymous loop-index
1506 {
1507 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1508 else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1509 }
1510 | comma_expression updownS comma_expression '~' '@' // CFA, invalid syntax rule
1511 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1512 | '@' updownS '@' // CFA, invalid syntax rule
1513 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1514 | '@' updownS comma_expression '~' '@' // CFA, invalid syntax rule
1515 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1516 | comma_expression updownS '@' '~' '@' // CFA, invalid syntax rule
1517 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1518 | '@' updownS '@' '~' '@' // CFA, invalid syntax rule
1519 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1520
1521 // These rules accept a comma_expression for the initialization, when only an identifier is correct. Being
1522 // permissive allows for a better error message from forCtrl.
1523 | comma_expression ';' comma_expression // CFA
1524 { $$ = forCtrl( yylloc, $3, $1, NEW_ZERO, OperKinds::LThan, $3->clone(), NEW_ONE ); }
1525 | comma_expression ';' updown comma_expression // CFA
1526 { $$ = forCtrl( yylloc, $4, $1, UPDOWN( $3, NEW_ZERO, $4->clone() ), $3, UPDOWN( $3, $4->clone(), NEW_ZERO ), NEW_ONE ); }
1527
1528 | comma_expression ';' comma_expression updownS comma_expression // CFA
1529 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), NEW_ONE ); }
1530 | comma_expression ';' '@' updownS comma_expression // CFA
1531 {
1532 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1533 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, NEW_ONE );
1534 }
1535 | comma_expression ';' comma_expression updownS '@' // CFA
1536 {
1537 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1538 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1539 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, NEW_ONE );
1540 }
1541 | comma_expression ';' '@' updownS '@' // CFA, invalid syntax rule
1542 { SemanticError( yylloc, "illegal syntax, missing low/high value for ascending/descending range so index is uninitialized." ); $$ = nullptr; }
1543
1544 | comma_expression ';' comma_expression updownEq comma_expression // CFA
1545 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), NEW_ONE ); }
1546
1547 | comma_expression ';' comma_expression updownS comma_expression '~' comma_expression // CFA
1548 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), $7 ); }
1549 | comma_expression ';' '@' updownS comma_expression '~' comma_expression // CFA, invalid syntax rule
1550 {
1551 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1552 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, $7 );
1553 }
1554 | comma_expression ';' comma_expression updownS '@' '~' comma_expression // CFA
1555 {
1556 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1557 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1558 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, $7 );
1559 }
1560 | comma_expression ';' comma_expression updownS comma_expression '~' '@' // CFA
1561 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), nullptr ); }
1562 | comma_expression ';' '@' updownS comma_expression '~' '@' // CFA, invalid syntax rule
1563 {
1564 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1565 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, nullptr );
1566 }
1567 | comma_expression ';' comma_expression updownS '@' '~' '@' // CFA
1568 {
1569 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1570 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1571 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, nullptr );
1572 }
1573 | comma_expression ';' '@' updownS '@' '~' '@' // CFA
1574 { SemanticError( yylloc, "illegal syntax, missing low/high value for ascending/descending range so index is uninitialized." ); $$ = nullptr; }
1575
1576 | declaration comma_expression // CFA
1577 { $$ = forCtrl( yylloc, $1, NEW_ZERO, OperKinds::LThan, $2, NEW_ONE ); }
1578 | declaration updown comma_expression // CFA
1579 { $$ = forCtrl( yylloc, $1, UPDOWN( $2, NEW_ZERO, $3 ), $2, UPDOWN( $2, $3->clone(), NEW_ZERO ), NEW_ONE ); }
1580
1581 | declaration comma_expression updownS comma_expression // CFA
1582 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2->clone(), $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), NEW_ONE ); }
1583 | declaration '@' updownS comma_expression // CFA
1584 {
1585 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1586 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, NEW_ONE );
1587 }
1588 | declaration comma_expression updownS '@' // CFA
1589 {
1590 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1591 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1592 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, NEW_ONE );
1593 }
1594
1595 | declaration comma_expression updownEq comma_expression // CFA
1596 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2->clone(), $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), NEW_ONE ); }
1597
1598 | declaration comma_expression updownS comma_expression '~' comma_expression // CFA
1599 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), $6 ); }
1600 | declaration '@' updownS comma_expression '~' comma_expression // CFA
1601 {
1602 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1603 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, $6 );
1604 }
1605 | declaration comma_expression updownS '@' '~' comma_expression // CFA
1606 {
1607 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1608 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1609 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, $6 );
1610 }
1611 | declaration comma_expression updownS comma_expression '~' '@' // CFA
1612 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), nullptr ); }
1613 | declaration '@' updownS comma_expression '~' '@' // CFA
1614 {
1615 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1616 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, nullptr );
1617 }
1618 | declaration comma_expression updownS '@' '~' '@' // CFA
1619 {
1620 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1621 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1622 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, nullptr );
1623 }
1624 | declaration '@' updownS '@' '~' '@' // CFA, invalid syntax rule
1625 { SemanticError( yylloc, "illegal syntax, missing low/high value for ascending/descending range so index is uninitialized." ); $$ = nullptr; }
1626
1627 | comma_expression ';' type_type_specifier // CFA, enum type
1628 {
1629 $$ = enumRangeCtrl( $1, OperKinds::LEThan, new ExpressionNode( new ast::TypeExpr( yylloc, $3->clone()->buildType() ) ), $3 );
1630 }
1631 | comma_expression ';' updown enum_key // CFA, enum type, reverse direction
1632 {
1633 if ( $3 == OperKinds::GThan ) {
1634 SemanticError( yylloc, "all enumeration ranges are equal (all values). Add an equal, e.g., ~=, -~=." ); $$ = nullptr;
1635 $3 = OperKinds::GEThan;
1636 } // if
1637 $$ = enumRangeCtrl( $1, $3, new ExpressionNode( new ast::TypeExpr( yylloc, $4->clone()->buildType() ) ), $4 );
1638 }
1639 ;
1640
1641enum_key:
1642 type_name
1643 {
1644 typedefTable.makeTypedef( *$1->symbolic.name, "enum_type_nobody 1" );
1645 $$ = DeclarationNode::newEnum( $1->symbolic.name, nullptr, false, false );
1646 }
1647 | ENUM identifier
1648 {
1649 typedefTable.makeTypedef( *$2, "enum_type_nobody 2" );
1650 $$ = DeclarationNode::newEnum( $2, nullptr, false, false );
1651 }
1652 | ENUM type_name
1653 {
1654 typedefTable.makeTypedef( *$2->symbolic.name, "enum_type_nobody 3" );
1655 $$ = DeclarationNode::newEnum( $2->symbolic.name, nullptr, false, false );
1656 }
1657 ;
1658
1659// This rule exists to handle the ambiguity with unary operator '~'. The rule is the same as updownS minus the '~'.
1660// Specifically, "for ( ~5 )" means the complement of 5, not loop 0..4. Hence, in this case "for ( ~= 5 )", i.e., 0..5,
1661// it is not possible to just remove the '='. The entire '~=' must be removed.
1662updown:
1663 ErangeUpLt
1664 { $$ = OperKinds::LThan; }
1665 | ErangeDownGt
1666 { $$ = OperKinds::GThan; }
1667 | ErangeUpLe
1668 { $$ = OperKinds::LEThan; }
1669 | ErangeDownGe
1670 { $$ = OperKinds::GEThan; }
1671 ;
1672
1673updownS:
1674 '~' // shorthand 0 ~ 10 => 0 +~ 10
1675 { $$ = OperKinds::LThan; }
1676 | updown
1677 ;
1678
1679updownEq:
1680 ErangeEq
1681 { $$ = OperKinds::Eq; }
1682 | ErangeNe
1683 { $$ = OperKinds::Neq; }
1684 | ErangeDownEq
1685 { $$ = OperKinds::Eq; }
1686 | ErangeDownNe
1687 { $$ = OperKinds::Neq; }
1688 ;
1689
1690jump_statement:
1691 GOTO identifier_or_type_name ';'
1692 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Goto ) ); }
1693 | GOTO '*' comma_expression ';' // GCC, computed goto
1694 // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1695 // whereas normal operator precedence yields goto (*i)+3;
1696 { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1697 // A semantic check is required to ensure fallthrough appears only in the body of a choose statement.
1698 | FALLTHROUGH ';' // CFA
1699 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThrough ) ); }
1700 | FALLTHROUGH identifier_or_type_name ';' // CFA
1701 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::FallThrough ) ); }
1702 | FALLTHROUGH DEFAULT ';' // CFA
1703 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThroughDefault ) ); }
1704 | CONTINUE ';'
1705 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1706 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Continue ) ); }
1707 | CONTINUE identifier_or_type_name ';' // CFA, multi-level continue
1708 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1709 // the target of the transfer appears only at the start of an iteration statement.
1710 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Continue ) ); }
1711 | BREAK ';'
1712 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1713 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Break ) ); }
1714 | BREAK identifier_or_type_name ';' // CFA, multi-level exit
1715 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1716 // the target of the transfer appears only at the start of an iteration statement.
1717 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Break ) ); }
1718 | RETURN comma_expression_opt ';'
1719 { $$ = new StatementNode( build_return( yylloc, $2 ) ); }
1720 | RETURN '{' initializer_list_opt comma_opt '}' ';'
1721 { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1722 | SUSPEND ';'
1723 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::None ) ); }
1724 | SUSPEND compound_statement
1725 { $$ = new StatementNode( build_suspend( yylloc, $2, ast::SuspendStmt::None ) ); }
1726 | SUSPEND COROUTINE ';'
1727 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Coroutine ) ); }
1728 | SUSPEND COROUTINE compound_statement
1729 { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Coroutine ) ); }
1730 | SUSPEND GENERATOR ';'
1731 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Generator ) ); }
1732 | SUSPEND GENERATOR compound_statement
1733 { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Generator ) ); }
1734 | THROW assignment_expression_opt ';' // handles rethrow
1735 { $$ = new StatementNode( build_throw( yylloc, $2 ) ); }
1736 | THROWRESUME assignment_expression_opt ';' // handles reresume
1737 { $$ = new StatementNode( build_resume( yylloc, $2 ) ); }
1738 | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1739 { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1740 ;
1741
1742with_statement:
1743 WITH '(' type_list ')' statement // support scoped enumeration
1744 { $$ = new StatementNode( build_with( yylloc, $3, $5 ) ); }
1745 ;
1746
1747// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so possibly change syntax to "with mutex".
1748mutex_statement:
1749 MUTEX '(' argument_expression_list_opt ')' statement
1750 {
1751 if ( ! $3 ) { SemanticError( yylloc, "illegal syntax, mutex argument list cannot be empty." ); $$ = nullptr; }
1752 $$ = new StatementNode( build_mutex( yylloc, $3, $5 ) );
1753 }
1754 ;
1755
1756when_clause:
1757 WHEN '(' comma_expression ')' { $$ = $3; }
1758 ;
1759
1760when_clause_opt:
1761 // empty
1762 { $$ = nullptr; }
1763 | when_clause
1764 ;
1765
1766cast_expression_list:
1767 cast_expression
1768 | cast_expression_list ',' cast_expression
1769 { SemanticError( yylloc, "List of mutex member is currently unimplemented." ); $$ = nullptr; }
1770 ;
1771
1772timeout:
1773 TIMEOUT '(' comma_expression ')' { $$ = $3; }
1774 ;
1775
1776wor:
1777 OROR
1778 | WOR
1779
1780waitfor:
1781 WAITFOR '(' cast_expression ')'
1782 { $$ = $3; }
1783 | WAITFOR '(' cast_expression_list ':' argument_expression_list_opt ')'
1784 { $$ = $3->set_last( $5 ); }
1785 ;
1786
1787wor_waitfor_clause:
1788 when_clause_opt waitfor statement %prec THEN
1789 // Called first: create header for WaitForStmt.
1790 { $$ = build_waitfor( yylloc, new ast::WaitForStmt( yylloc ), $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1791 | wor_waitfor_clause wor when_clause_opt waitfor statement
1792 { $$ = build_waitfor( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1793 | wor_waitfor_clause wor when_clause_opt ELSE statement
1794 { $$ = build_waitfor_else( yylloc, $1, $3, maybe_build_compound( yylloc, $5 ) ); }
1795 | wor_waitfor_clause wor when_clause_opt timeout statement %prec THEN
1796 { $$ = build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1797 // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1798 | wor_waitfor_clause wor when_clause_opt timeout statement wor ELSE statement // invalid syntax rule
1799 { SemanticError( yylloc, "illegal syntax, else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1800 | wor_waitfor_clause wor when_clause_opt timeout statement wor when_clause ELSE statement
1801 { $$ = build_waitfor_else( yylloc, build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ), $7, maybe_build_compound( yylloc, $9 ) ); }
1802 ;
1803
1804waitfor_statement:
1805 wor_waitfor_clause %prec THEN
1806 { $$ = new StatementNode( $1 ); }
1807 ;
1808
1809wand:
1810 ANDAND
1811 | WAND
1812 ;
1813
1814waituntil:
1815 WAITUNTIL '(' comma_expression ')'
1816 { $$ = $3; }
1817 ;
1818
1819waituntil_clause:
1820 when_clause_opt waituntil statement
1821 { $$ = build_waituntil_clause( yylloc, $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1822 | '(' wor_waituntil_clause ')'
1823 { $$ = $2; }
1824 ;
1825
1826wand_waituntil_clause:
1827 waituntil_clause %prec THEN
1828 { $$ = $1; }
1829 | waituntil_clause wand wand_waituntil_clause
1830 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::AND, $1, $3 ); }
1831 ;
1832
1833wor_waituntil_clause:
1834 wand_waituntil_clause
1835 { $$ = $1; }
1836 | wor_waituntil_clause wor wand_waituntil_clause
1837 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::OR, $1, $3 ); }
1838 | wor_waituntil_clause wor when_clause_opt ELSE statement
1839 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::LEFT_OR, $1, build_waituntil_else( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1840 ;
1841
1842waituntil_statement:
1843 wor_waituntil_clause %prec THEN
1844 { $$ = new StatementNode( build_waituntil_stmt( yylloc, $1 ) ); }
1845 ;
1846
1847corun_statement:
1848 CORUN statement
1849 { $$ = new StatementNode( build_corun( yylloc, $2 ) ); }
1850 ;
1851
1852cofor_statement:
1853 COFOR '(' for_control_expression_list ')' statement
1854 { $$ = new StatementNode( build_cofor( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1855 ;
1856
1857exception_statement:
1858 TRY compound_statement handler_clause %prec THEN
1859 { $$ = new StatementNode( build_try( yylloc, $2, $3, nullptr ) ); }
1860 | TRY compound_statement finally_clause
1861 { $$ = new StatementNode( build_try( yylloc, $2, nullptr, $3 ) ); }
1862 | TRY compound_statement handler_clause finally_clause
1863 { $$ = new StatementNode( build_try( yylloc, $2, $3, $4 ) ); }
1864 ;
1865
1866handler_clause:
1867 handler_key '(' exception_declaration handler_predicate_opt ')' compound_statement
1868 { $$ = new ClauseNode( build_catch( yylloc, $1, $3, $4, $6 ) ); }
1869 | handler_clause handler_key '(' exception_declaration handler_predicate_opt ')' compound_statement
1870 { $$ = $1->set_last( new ClauseNode( build_catch( yylloc, $2, $4, $5, $7 ) ) ); }
1871 ;
1872
1873handler_predicate_opt:
1874 // empty
1875 { $$ = nullptr; }
1876 | ';' conditional_expression { $$ = $2; }
1877 ;
1878
1879handler_key:
1880 CATCH { $$ = ast::Terminate; }
1881 | RECOVER { $$ = ast::Terminate; }
1882 | CATCHRESUME { $$ = ast::Resume; }
1883 | FIXUP { $$ = ast::Resume; }
1884 ;
1885
1886finally_clause:
1887 FINALLY compound_statement { $$ = new ClauseNode( build_finally( yylloc, $2 ) ); }
1888 ;
1889
1890exception_declaration:
1891 // No SUE declaration in parameter list.
1892 type_specifier_nobody
1893 | type_specifier_nobody declarator
1894 { $$ = $2->addType( $1 ); }
1895 | type_specifier_nobody variable_abstract_declarator
1896 { $$ = $2->addType( $1 ); }
1897 | cfa_abstract_declarator_tuple identifier // CFA
1898 { $$ = $1->addName( $2 ); }
1899 | cfa_abstract_declarator_tuple // CFA
1900 ;
1901
1902enable_disable_statement:
1903 enable_disable_key identifier_list compound_statement
1904 ;
1905
1906enable_disable_key:
1907 ENABLE
1908 | DISABLE
1909 ;
1910
1911asm_statement:
1912 ASM asm_volatile_opt '(' string_literal ')' ';'
1913 { $$ = new StatementNode( build_asm( yylloc, $2, $4, nullptr ) ); }
1914 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1915 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6 ) ); }
1916 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1917 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8 ) ); }
1918 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1919 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8, $10 ) ); }
1920 | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' asm_label_list ')' ';'
1921 { $$ = new StatementNode( build_asm( yylloc, $2, $5, nullptr, $8, $10, $12 ) ); }
1922 ;
1923
1924asm_volatile_opt: // GCC
1925 // empty
1926 { $$ = false; }
1927 | VOLATILE
1928 { $$ = true; }
1929 ;
1930
1931asm_operands_opt: // GCC
1932 // empty
1933 { $$ = nullptr; } // use default argument
1934 | asm_operands_list
1935 ;
1936
1937asm_operands_list: // GCC
1938 asm_operand
1939 | asm_operands_list ',' asm_operand
1940 { $$ = $1->set_last( $3 ); }
1941 ;
1942
1943asm_operand: // GCC
1944 string_literal '(' constant_expression ')'
1945 { $$ = new ExpressionNode( new ast::AsmExpr( yylloc, "", maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1946 | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1947 {
1948 $$ = new ExpressionNode( new ast::AsmExpr( yylloc, *$2.str, maybeMoveBuild( $4 ), maybeMoveBuild( $6 ) ) );
1949 delete $2.str;
1950 }
1951 ;
1952
1953asm_clobbers_list_opt: // GCC
1954 // empty
1955 { $$ = nullptr; } // use default argument
1956 | string_literal
1957 { $$ = $1; }
1958 | asm_clobbers_list_opt ',' string_literal
1959 { $$ = $1->set_last( $3 ); }
1960 ;
1961
1962asm_label_list:
1963 identifier_or_type_name
1964 { $$ = new LabelNode(); $$->labels.emplace_back( yylloc, *$1 ); delete $1; } // allocated by lexer
1965 | asm_label_list ',' identifier_or_type_name
1966 { $$ = $1; $1->labels.emplace_back( yylloc, *$3 ); delete $3; } // allocated by lexer
1967 ;
1968
1969// ****************************** DECLARATIONS *********************************
1970
1971declaration_list_opt: // used at beginning of switch statement
1972 // empty
1973 { $$ = nullptr; }
1974 | declaration_list
1975 ;
1976
1977declaration_list:
1978 attribute_list_opt declaration
1979 { $$ = $2->addQualifiers( $1 ); }
1980 | declaration_list declaration
1981 { $$ = $1->set_last( $2 ); }
1982 ;
1983
1984KR_parameter_list_opt: // used to declare parameter types in K&R style functions
1985 // empty
1986 { $$ = nullptr; }
1987 | KR_parameter_list
1988 ;
1989
1990KR_parameter_list:
1991 c_declaration ';'
1992 { $$ = $1; }
1993 | KR_parameter_list c_declaration ';'
1994 { $$ = $1->set_last( $2 ); }
1995 ;
1996
1997local_label_declaration_opt: // GCC, local label
1998 // empty
1999 | local_label_declaration_list
2000 ;
2001
2002local_label_declaration_list: // GCC, local label
2003 LABEL local_label_list ';'
2004 | local_label_declaration_list LABEL local_label_list ';'
2005 ;
2006
2007local_label_list: // GCC, local label
2008 identifier_or_type_name
2009 | local_label_list ',' identifier_or_type_name
2010 ;
2011
2012declaration: // old & new style declarations
2013 c_declaration ';'
2014 | cfa_declaration ';' // CFA
2015 | static_assert ';' // C11
2016 ;
2017
2018static_assert:
2019 STATICASSERT '(' constant_expression ',' string_literal ')' // C11
2020 { $$ = DeclarationNode::newStaticAssert( $3, maybeMoveBuild( $5 ) ); }
2021 | STATICASSERT '(' constant_expression ')' // CFA
2022 { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( yylloc, *new string( "\"\"" ) ) ); }
2023
2024// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
2025// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
2026// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
2027// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
2028// the declaration list (as in Pascal). ANSI C and the new CFA declarations may appear together in the same program
2029// block, but cannot be mixed within a specific declaration.
2030//
2031// CFA C
2032// [10] int x; int x[10]; // array of 10 integers
2033// [10] * char y; char *y[10]; // array of 10 pointers to char
2034
2035cfa_declaration: // CFA
2036 cfa_variable_declaration
2037 | cfa_typedef_declaration
2038 | cfa_function_declaration
2039 | type_declaring_list
2040 { SemanticError( yylloc, "otype declaration is currently unimplemented." ); $$ = nullptr; }
2041 | trait_specifier
2042 ;
2043
2044cfa_variable_declaration: // CFA
2045 cfa_variable_specifier initializer_opt
2046 { $$ = $1->addInitializer( $2 ); }
2047 | declaration_qualifier_list cfa_variable_specifier initializer_opt
2048 // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
2049 // them as a type_qualifier cannot appear in that context.
2050 { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
2051 | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
2052 { $$ = $1->set_last( $1->cloneType( $5 )->addInitializer( $6 ) ); }
2053 ;
2054
2055cfa_variable_specifier: // CFA
2056 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
2057 // storage-class
2058 cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
2059 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
2060 | cfa_abstract_tuple identifier_or_type_name asm_name_opt
2061 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
2062 | multi_array_dimension cfa_abstract_tuple identifier_or_type_name asm_name_opt
2063 { $$ = $2->addNewArray( $1 )->addName( $3 )->addAsmName( $4 ); }
2064 | multi_array_dimension type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
2065 { $$ = $3->addNewArray( $1 )->addQualifiers( $2 )->addName( $4 )->addAsmName( $5 ); }
2066
2067 // [ int s, int t ]; // declare s and t
2068 // [ int, int ] f();
2069 // [] g( int );
2070 // [ int x, int y ] = f(); // declare x and y, initialize each from f
2071 // g( x + y );
2072 | cfa_function_return asm_name_opt
2073 { SemanticError( yylloc, "tuple-element declarations is currently unimplemented." ); $$ = nullptr; }
2074 | type_qualifier_list cfa_function_return asm_name_opt
2075 { SemanticError( yylloc, "tuple variable declaration is currently unimplemented." ); $$ = nullptr; }
2076 ;
2077
2078cfa_function_declaration: // CFA
2079 cfa_function_specifier
2080 | type_qualifier_list cfa_function_specifier
2081 { $$ = $2->addQualifiers( $1 ); }
2082 | declaration_qualifier_list cfa_function_specifier
2083 { $$ = $2->addQualifiers( $1 ); }
2084 | declaration_qualifier_list type_qualifier_list cfa_function_specifier
2085 { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
2086 | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')'
2087 {
2088 // Append the return type at the start (left-hand-side) to each identifier in the list.
2089 DeclarationNode * ret = new DeclarationNode;
2090 ret->type = maybeCopy( $1->type->base );
2091 $$ = $1->set_last( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
2092 }
2093 ;
2094
2095cfa_function_specifier: // CFA
2096 '[' ']' identifier '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2097 { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2098 | '[' ']' TYPEDEFname '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2099 { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2100 // | '[' ']' TYPEGENname '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2101 // { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2102
2103 // identifier_or_type_name must be broken apart because of the sequence:
2104 //
2105 // '[' ']' identifier_or_type_name '(' cfa_parameter_list_ellipsis_opt ')'
2106 // '[' ']' type_specifier
2107 //
2108 // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
2109 // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
2110 | cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2111 // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
2112 { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
2113 | cfa_function_return identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2114 { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
2115 ;
2116
2117cfa_function_return: // CFA
2118 '[' cfa_parameter_list ']'
2119 { $$ = DeclarationNode::newTuple( $2 ); }
2120 | '[' cfa_parameter_list ',' cfa_abstract_parameter_list ']'
2121 // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
2122 { $$ = DeclarationNode::newTuple( $2->set_last( $4 ) ); }
2123 ;
2124
2125cfa_typedef_declaration: // CFA
2126 TYPEDEF attribute_list_opt cfa_variable_specifier
2127 {
2128 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "cfa_typedef_declaration 1" );
2129 $$ = $3->addTypedef()->addQualifiers( $2 );
2130 }
2131 | TYPEDEF attribute_list_opt cfa_function_specifier
2132 {
2133 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "cfa_typedef_declaration 2" );
2134 $$ = $3->addTypedef()->addQualifiers( $2 );
2135 }
2136 | cfa_typedef_declaration ',' attribute_list_opt identifier
2137 {
2138 typedefTable.addToEnclosingScope( *$4, TYPEDEFname, "cfa_typedef_declaration 3" );
2139 $$ = $1->set_last( $1->cloneType( $4 )->addQualifiers( $3 ) );
2140 }
2141 ;
2142
2143// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
2144// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
2145
2146typedef_declaration:
2147 TYPEDEF attribute_list_opt type_specifier declarator
2148 {
2149 typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "typedef_declaration 1" );
2150 if ( $3->type->forall || ($3->type->kind == TypeData::Aggregate && $3->type->aggregate.params) ) {
2151 SemanticError( yylloc, "forall qualifier in typedef is currently unimplemented." ); $$ = nullptr;
2152 } else $$ = $4->addType( $3 )->addTypedef()->addQualifiers( $2 ); // watchout frees $3 and $4
2153 }
2154 | typedef_declaration ',' attribute_list_opt declarator
2155 {
2156 typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "typedef_declaration 2" );
2157 $$ = $1->set_last( $1->cloneBaseType( $4 )->addTypedef()->addQualifiers( $3 ) );
2158 }
2159 | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
2160 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2161 | type_specifier TYPEDEF declarator
2162 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2163 | type_specifier TYPEDEF type_qualifier_list declarator
2164 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2165 ;
2166
2167typedef_expression:
2168 // deprecated GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
2169 TYPEDEF identifier '=' assignment_expression
2170 { SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr; }
2171 | typedef_expression ',' identifier '=' assignment_expression
2172 { SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr; }
2173 ;
2174
2175c_declaration:
2176 declaration_specifier declaring_list
2177 { $$ = distTypeSpec( $1, $2 ); }
2178 | typedef_declaration
2179 | typedef_expression // deprecated GCC, naming expression type
2180 | sue_declaration_specifier
2181 {
2182 assert( $1->type );
2183 if ( $1->type->qualifiers.any() ) { // CV qualifiers ?
2184 SemanticError( yylloc, "illegal syntax, useless type qualifier(s) in empty declaration." ); $$ = nullptr;
2185 }
2186 // enums are never empty declarations because there must have at least one enumeration.
2187 if ( $1->type->kind == TypeData::AggregateInst && $1->storageClasses.any() ) { // storage class ?
2188 SemanticError( yylloc, "illegal syntax, useless storage qualifier(s) in empty aggregate declaration." ); $$ = nullptr;
2189 }
2190 }
2191 ;
2192
2193declaring_list:
2194 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
2195 // storage-class
2196 variable_declarator asm_name_opt initializer_opt
2197 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2198 | variable_type_redeclarator asm_name_opt initializer_opt
2199 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2200
2201 | general_function_declarator asm_name_opt
2202 { $$ = $1->addAsmName( $2 )->addInitializer( nullptr ); }
2203 | general_function_declarator asm_name_opt '=' VOID
2204 { $$ = $1->addAsmName( $2 )->addInitializer( new InitializerNode( true ) ); }
2205
2206 | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
2207 { $$ = $1->set_last( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
2208 ;
2209
2210general_function_declarator:
2211 function_type_redeclarator
2212 | function_declarator
2213 ;
2214
2215declaration_specifier: // type specifier + storage class
2216 basic_declaration_specifier
2217 | type_declaration_specifier
2218 | sue_declaration_specifier
2219 | sue_declaration_specifier invalid_types // invalid syntax rule
2220 {
2221 SemanticError( yylloc, "illegal syntax, expecting ';' at end of \"%s\" declaration.",
2222 ast::AggregateDecl::aggrString( $1->type->aggregate.kind ) );
2223 $$ = nullptr;
2224 }
2225 ;
2226
2227invalid_types:
2228 aggregate_key
2229 | basic_type_name
2230 | indirect_type
2231 ;
2232
2233declaration_specifier_nobody: // type specifier + storage class - {...}
2234 // Preclude SUE declarations in restricted scopes:
2235 //
2236 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2237 //
2238 // because it is impossible to call f due to name equivalence.
2239 basic_declaration_specifier
2240 | sue_declaration_specifier_nobody
2241 | type_declaration_specifier
2242 ;
2243
2244type_specifier: // type specifier
2245 basic_type_specifier
2246 | sue_type_specifier
2247 | type_type_specifier attribute_list_opt
2248 ;
2249
2250type_specifier_nobody: // type specifier - {...}
2251 // Preclude SUE declarations in restricted scopes:
2252 //
2253 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2254 //
2255 // because it is impossible to call f due to name equivalence.
2256 basic_type_specifier
2257 | sue_type_specifier_nobody
2258 | type_type_specifier
2259 ;
2260
2261type_qualifier_list_opt: // GCC, used in asm_statement
2262 // empty
2263 { $$ = nullptr; }
2264 | type_qualifier_list
2265 ;
2266
2267type_qualifier_list:
2268 // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
2269 //
2270 // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
2271 // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
2272 // appeared only once.
2273 type_qualifier attribute_list_opt
2274 { $$ = $1->addQualifiers( $2 ); }
2275 | type_qualifier_list type_qualifier attribute_list_opt
2276 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2277 ;
2278
2279type_qualifier:
2280 type_qualifier_name
2281 { $$ = DeclarationNode::newFromTypeData( $1 ); }
2282 ;
2283
2284type_qualifier_name:
2285 CONST
2286 { $$ = build_type_qualifier( ast::CV::Const ); }
2287 | RESTRICT
2288 { $$ = build_type_qualifier( ast::CV::Restrict ); }
2289 | VOLATILE
2290 { $$ = build_type_qualifier( ast::CV::Volatile ); }
2291 | ATOMIC
2292 { $$ = build_type_qualifier( ast::CV::Atomic ); }
2293
2294 // forall is a CV qualifier because it can appear in places where SC qualifiers are disallowed.
2295 //
2296 // void foo( forall( T ) T (*)( T ) ); // forward declaration
2297 // void bar( static int ); // static disallowed (gcc/CFA)
2298 | forall
2299 { $$ = build_forall( $1 ); }
2300 ;
2301
2302forall:
2303 FORALL '(' type_parameter_list ')' // CFA
2304 { $$ = $3; }
2305 ;
2306
2307declaration_qualifier_list:
2308 storage_class_list
2309 | type_qualifier_list storage_class_list
2310 { $$ = $1->addQualifiers( $2 ); }
2311 | declaration_qualifier_list type_qualifier_list storage_class_list
2312 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2313 ;
2314
2315storage_class_list:
2316 // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
2317 // only one of each is specified, except for inline, which can appear with the others.
2318 //
2319 // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
2320 // specifiers in a declaration.
2321 storage_class attribute_list_opt
2322 { $$ = $1->addQualifiers( $2 ); }
2323 | storage_class_list storage_class attribute_list_opt
2324 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2325 ;
2326
2327storage_class:
2328 EXTERN
2329 { $$ = DeclarationNode::newStorageClass( ast::Storage::Extern ); }
2330 | STATIC
2331 { $$ = DeclarationNode::newStorageClass( ast::Storage::Static ); }
2332 | AUTO
2333 { $$ = DeclarationNode::newStorageClass( ast::Storage::Auto ); }
2334 | REGISTER
2335 { $$ = DeclarationNode::newStorageClass( ast::Storage::Register ); }
2336 | THREADLOCALGCC // GCC
2337 { $$ = DeclarationNode::newStorageClass( ast::Storage::ThreadLocalGcc ); }
2338 | THREADLOCALC11 // C11
2339 { $$ = DeclarationNode::newStorageClass( ast::Storage::ThreadLocalC11 ); }
2340 // Put function specifiers here to simplify parsing rules, but separate them semantically.
2341 | INLINE // C99
2342 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Inline ); }
2343 | FORTRAN // C99
2344 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Fortran ); }
2345 | NORETURN // C11
2346 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Noreturn ); }
2347 ;
2348
2349basic_type_name:
2350 basic_type_name_type
2351 { $$ = DeclarationNode::newFromTypeData( $1 ); }
2352 ;
2353
2354// Just an intermediate value for conversion.
2355basic_type_name_type:
2356 VOID
2357 { $$ = build_basic_type( TypeData::Void ); }
2358 | BOOL // C99
2359 { $$ = build_basic_type( TypeData::Bool ); }
2360 | CHAR
2361 { $$ = build_basic_type( TypeData::Char ); }
2362 | INT
2363 { $$ = build_basic_type( TypeData::Int ); }
2364 | INT128
2365 { $$ = build_basic_type( TypeData::Int128 ); }
2366 | UINT128
2367 { $$ = addType( build_basic_type( TypeData::Int128 ), build_signedness( TypeData::Unsigned ) ); }
2368 | FLOAT
2369 { $$ = build_basic_type( TypeData::Float ); }
2370 | DOUBLE
2371 { $$ = build_basic_type( TypeData::Double ); }
2372 | FLOAT80
2373 { $$ = build_basic_type( TypeData::Float80 ); }
2374 | uuFLOAT128
2375 { $$ = build_basic_type( TypeData::uuFloat128 ); }
2376 | FLOAT16
2377 { $$ = build_basic_type( TypeData::Float16 ); }
2378 | FLOAT32
2379 { $$ = build_basic_type( TypeData::Float32 ); }
2380 | FLOAT32X
2381 { $$ = build_basic_type( TypeData::Float32x ); }
2382 | FLOAT64
2383 { $$ = build_basic_type( TypeData::Float64 ); }
2384 | FLOAT64X
2385 { $$ = build_basic_type( TypeData::Float64x ); }
2386 | FLOAT128
2387 { $$ = build_basic_type( TypeData::Float128 ); }
2388 // https://developer.arm.com/documentation/den0018/a/NEON-Intrinsics/Accessing-vector-types-from-C
2389 | FLOAT128X
2390 { $$ = build_basic_type( TypeData::Float128x ); }
2391 | FLOAT32X4
2392 { $$ = build_basic_type( TypeData::Float32x4 ); }
2393 | FLOAT64X2
2394 { $$ = build_basic_type( TypeData::Float64x2 ); }
2395 | SVFLOAT32
2396 { $$ = build_basic_type( TypeData::Svfloat32 ); }
2397 | SVFLOAT64
2398 { $$ = build_basic_type( TypeData::Svfloat64 ); }
2399 | SVBOOL
2400 { $$ = build_basic_type( TypeData::Svbool ); }
2401 | DECIMAL32
2402 { SemanticError( yylloc, "_Decimal32 is currently unimplemented." ); $$ = nullptr; }
2403 | DECIMAL64
2404 { SemanticError( yylloc, "_Decimal64 is currently unimplemented." ); $$ = nullptr; }
2405 | DECIMAL128
2406 { SemanticError( yylloc, "_Decimal128 is currently unimplemented." ); $$ = nullptr; }
2407 | COMPLEX // C99
2408 { $$ = build_complex_type( TypeData::Complex ); }
2409 | IMAGINARY // C99
2410 { $$ = build_complex_type( TypeData::Imaginary ); }
2411 | SIGNED
2412 { $$ = build_signedness( TypeData::Signed ); }
2413 | UNSIGNED
2414 { $$ = build_signedness( TypeData::Unsigned ); }
2415 | SHORT
2416 { $$ = build_length( TypeData::Short ); }
2417 | LONG
2418 { $$ = build_length( TypeData::Long ); }
2419 | VA_LIST // GCC, __builtin_va_list
2420 { $$ = build_builtin_type( TypeData::Valist ); }
2421 | AUTO_TYPE
2422 { $$ = build_builtin_type( TypeData::AutoType ); }
2423 | vtable
2424 ;
2425
2426vtable_opt:
2427 // empty
2428 { $$ = nullptr; }
2429 | vtable
2430 ;
2431
2432vtable:
2433 VTABLE '(' type_name ')' default_opt
2434 { $$ = build_vtable_type( $3 ); }
2435 ;
2436
2437default_opt:
2438 // empty
2439 { $$ = nullptr; }
2440 | DEFAULT
2441 { SemanticError( yylloc, "vtable default is currently unimplemented." ); $$ = nullptr; }
2442 ;
2443
2444basic_declaration_specifier:
2445 // A semantic check is necessary for conflicting storage classes.
2446 basic_type_specifier
2447 | declaration_qualifier_list basic_type_specifier
2448 { $$ = $2->addQualifiers( $1 ); }
2449 | basic_declaration_specifier storage_class attribute_list_opt // remaining OBSOLESCENT (see 2)
2450 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2451 | basic_declaration_specifier storage_class type_qualifier_list
2452 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2453 | basic_declaration_specifier storage_class basic_type_specifier
2454 { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
2455 ;
2456
2457basic_type_specifier:
2458 direct_type attribute_list_opt
2459 { $$ = $1->addQualifiers( $2 ); }
2460 // Cannot have type modifiers, e.g., short, long, etc.
2461 | type_qualifier_list_opt indirect_type attribute_list
2462 { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
2463 | type_qualifier_list_opt indirect_type type_qualifier_list_opt
2464 { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
2465 ;
2466
2467direct_type:
2468 basic_type_name
2469 | type_qualifier_list basic_type_name
2470 { $$ = $2->addQualifiers( $1 ); }
2471 | direct_type type_qualifier
2472 { $$ = $1->addQualifiers( $2 ); }
2473 | direct_type basic_type_name
2474 { $$ = $1->addType( $2 ); }
2475 ;
2476
2477indirect_type:
2478 TYPEOF '(' type ')' // GCC: typeof( x ) y;
2479 { $$ = $3; }
2480 | TYPEOF '(' comma_expression ')' // GCC: typeof( a+b ) y;
2481 { $$ = DeclarationNode::newTypeof( $3 ); }
2482 | BASETYPEOF '(' type ')' // CFA: basetypeof( x ) y;
2483 { $$ = DeclarationNode::newTypeof( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ), true ); }
2484 | BASETYPEOF '(' comma_expression ')' // CFA: basetypeof( a+b ) y;
2485 { $$ = DeclarationNode::newTypeof( $3, true ); }
2486 | ZERO_T // CFA
2487 { $$ = DeclarationNode::newFromTypeData( build_builtin_type( TypeData::Zero ) ); }
2488 | ONE_T // CFA
2489 { $$ = DeclarationNode::newFromTypeData( build_builtin_type( TypeData::One ) ); }
2490 ;
2491
2492sue_declaration_specifier: // struct, union, enum + storage class + type specifier
2493 sue_type_specifier
2494 | declaration_qualifier_list sue_type_specifier
2495 { $$ = $2->addQualifiers( $1 ); }
2496 | sue_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2497 { $$ = $1->addQualifiers( $2 ); }
2498 | sue_declaration_specifier storage_class type_qualifier_list
2499 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2500 ;
2501
2502sue_type_specifier: // struct, union, enum + type specifier
2503 elaborated_type
2504 | type_qualifier_list
2505 { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
2506 elaborated_type
2507 { $$ = $3->addQualifiers( $1 ); }
2508 | sue_type_specifier type_qualifier
2509 {
2510 if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
2511 $$ = $1->addQualifiers( $2 );
2512 }
2513 ;
2514
2515sue_declaration_specifier_nobody: // struct, union, enum - {...} + storage class + type specifier
2516 sue_type_specifier_nobody
2517 | declaration_qualifier_list sue_type_specifier_nobody
2518 { $$ = $2->addQualifiers( $1 ); }
2519 | sue_declaration_specifier_nobody storage_class // remaining OBSOLESCENT (see 2)
2520 { $$ = $1->addQualifiers( $2 ); }
2521 | sue_declaration_specifier_nobody storage_class type_qualifier_list
2522 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2523 ;
2524
2525sue_type_specifier_nobody: // struct, union, enum - {...} + type specifier
2526 elaborated_type_nobody
2527 | type_qualifier_list elaborated_type_nobody
2528 { $$ = $2->addQualifiers( $1 ); }
2529 | sue_type_specifier_nobody type_qualifier
2530 { $$ = $1->addQualifiers( $2 ); }
2531 ;
2532
2533type_declaration_specifier:
2534 type_type_specifier attribute_list_opt
2535 { $$ = $1->addQualifiers( $2 ); }
2536 | declaration_qualifier_list type_type_specifier attribute_list_opt
2537 { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
2538 | type_declaration_specifier storage_class attribute_list_opt // remaining OBSOLESCENT (see 2)
2539 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2540 | type_declaration_specifier storage_class type_qualifier_list
2541 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2542 ;
2543
2544type_type_specifier: // typedef types
2545 type_name
2546 { $$ = DeclarationNode::newFromTypeData( $1 ); }
2547 | type_qualifier_list type_name
2548 { $$ = DeclarationNode::newFromTypeData( $2 )->addQualifiers( $1 ); }
2549 | type_type_specifier type_qualifier
2550 { $$ = $1->addQualifiers( $2 ); }
2551 ;
2552
2553type_name:
2554 TYPEDEFname
2555 { $$ = build_typedef( $1 ); }
2556 | '.' TYPEDEFname
2557 { $$ = build_qualified_type( build_global_scope(), build_typedef( $2 ) ); }
2558 | type_name '.' TYPEDEFname
2559 { $$ = build_qualified_type( $1, build_typedef( $3 ) ); }
2560 | typegen_name
2561 | '.' typegen_name
2562 { $$ = build_qualified_type( build_global_scope(), $2 ); }
2563 | type_name '.' typegen_name
2564 { $$ = build_qualified_type( $1, $3 ); }
2565 ;
2566
2567typegen_name: // CFA
2568 TYPEGENname
2569 { $$ = build_type_gen( $1, nullptr ); }
2570 | TYPEGENname '(' ')'
2571 { $$ = build_type_gen( $1, nullptr ); }
2572 | TYPEGENname '(' type_list ')'
2573 { $$ = build_type_gen( $1, $3 ); }
2574 ;
2575
2576elaborated_type: // struct, union, enum
2577 aggregate_type
2578 | enum_type
2579 ;
2580
2581elaborated_type_nobody: // struct, union, enum - {...}
2582 aggregate_type_nobody
2583 | enum_type_nobody
2584 ;
2585
2586// ************************** AGGREGATE *******************************
2587
2588aggregate_type: // struct, union
2589 aggregate_key attribute_list_opt
2590 { forall = false; } // reset
2591 '{' field_declaration_list_opt '}' type_parameters_opt attribute_list_opt
2592 { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 )->addQualifiers( $8 ); }
2593 | aggregate_key attribute_list_opt identifier attribute_list_opt
2594 {
2595 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 1" );
2596 forall = false; // reset
2597 }
2598 '{' field_declaration_list_opt '}' type_parameters_opt attribute_list_opt
2599 {
2600 $$ = DeclarationNode::newAggregate( $1, $3, $9, $7, true )->addQualifiers( $2 )->addQualifiers( $4 )->addQualifiers( $10 );
2601 }
2602 | aggregate_key attribute_list_opt TYPEDEFname attribute_list_opt // unqualified type name
2603 {
2604 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 2" );
2605 forall = false; // reset
2606 }
2607 '{' field_declaration_list_opt '}' type_parameters_opt attribute_list_opt
2608 {
2609 DeclarationNode::newFromTypeData( build_typedef( $3 ) );
2610 $$ = DeclarationNode::newAggregate( $1, $3, $9, $7, true )->addQualifiers( $2 )->addQualifiers( $4 )->addQualifiers( $10 );
2611 }
2612 | aggregate_key attribute_list_opt TYPEGENname attribute_list_opt // unqualified type name
2613 {
2614 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 3" );
2615 forall = false; // reset
2616 }
2617 '{' field_declaration_list_opt '}' type_parameters_opt attribute_list_opt
2618 {
2619 DeclarationNode::newFromTypeData( build_type_gen( $3, nullptr ) );
2620 $$ = DeclarationNode::newAggregate( $1, $3, $9, $7, true )->addQualifiers( $2 )->addQualifiers( $10 );
2621 }
2622 | aggregate_type_nobody
2623 ;
2624
2625type_parameters_opt:
2626 // empty
2627 { $$ = nullptr; } %prec '}'
2628 | '(' type_list ')'
2629 { $$ = $2; }
2630 ;
2631
2632aggregate_type_nobody: // struct, union - {...}
2633 aggregate_key attribute_list_opt identifier
2634 {
2635 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type_nobody" );
2636 forall = false; // reset
2637 $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2638 }
2639 | aggregate_key attribute_list_opt type_name
2640 {
2641 forall = false; // reset
2642 // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2643 // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2644 // delete newFromTypeGen.
2645 if ( $3->kind == TypeData::SymbolicInst && ! $3->symbolic.isTypedef ) {
2646 $$ = DeclarationNode::newFromTypeData( $3 )->addQualifiers( $2 );
2647 } else {
2648 $$ = DeclarationNode::newAggregate( $1, $3->symbolic.name, $3->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2649 $3->symbolic.name = nullptr; // copied to $$
2650 $3->symbolic.actuals = nullptr;
2651 delete $3;
2652 }
2653 }
2654 ;
2655
2656aggregate_key:
2657 aggregate_data
2658 | aggregate_control
2659 ;
2660
2661aggregate_data:
2662 STRUCT vtable_opt
2663 { $$ = ast::AggregateDecl::Struct; }
2664 | UNION
2665 { $$ = ast::AggregateDecl::Union; }
2666 | EXCEPTION // CFA
2667 { $$ = ast::AggregateDecl::Exception; }
2668 ;
2669
2670aggregate_control: // CFA
2671 MONITOR
2672 { $$ = ast::AggregateDecl::Monitor; }
2673 | MUTEX STRUCT
2674 { $$ = ast::AggregateDecl::Monitor; }
2675 | GENERATOR
2676 { $$ = ast::AggregateDecl::Generator; }
2677 | MUTEX GENERATOR
2678 {
2679 SemanticError( yylloc, "monitor generator is currently unimplemented." );
2680 $$ = ast::AggregateDecl::NoAggregate;
2681 }
2682 | COROUTINE
2683 { $$ = ast::AggregateDecl::Coroutine; }
2684 | MUTEX COROUTINE
2685 {
2686 SemanticError( yylloc, "monitor coroutine is currently unimplemented." );
2687 $$ = ast::AggregateDecl::NoAggregate;
2688 }
2689 | THREAD
2690 { $$ = ast::AggregateDecl::Thread; }
2691 | MUTEX THREAD
2692 {
2693 SemanticError( yylloc, "monitor thread is currently unimplemented." );
2694 $$ = ast::AggregateDecl::NoAggregate;
2695 }
2696 ;
2697
2698field_declaration_list_opt:
2699 // empty => struct S { /* no fields */ };
2700 { $$ = nullptr; }
2701 | field_declaration_list_opt attribute_list_opt field_declaration
2702 { distAttr( $2, $3 ); $$ = $1 ? $1->set_last( $3 ) : $3; }
2703 ;
2704
2705field_declaration:
2706 type_specifier field_declaring_list_opt ';'
2707 { $$ = fieldDecl( $1, $2 ); }
2708 | type_specifier field_declaring_list_opt '}' // invalid syntax rule
2709 {
2710 SemanticError( yylloc, "illegal syntax, expecting ';' at end of previous declaration." );
2711 $$ = nullptr;
2712 }
2713 | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2714 { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2715 | STATIC type_specifier field_declaring_list_opt ';' // CFA
2716 { SemanticError( yylloc, "STATIC aggregate field qualifier currently unimplemented." ); $$ = nullptr; }
2717 | INLINE attribute_list_opt type_specifier field_abstract_list_opt ';' // CFA
2718 {
2719 if ( ! $4 ) { // field declarator ?
2720 $4 = DeclarationNode::newName( nullptr );
2721 } // if
2722 $4->inLine = true;
2723 $$ = distTypeSpec( $3, $4 ); // mark all fields in list
2724 distInl( $4 );
2725 }
2726 | INLINE attribute_list_opt aggregate_control ';' // CFA
2727 { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2728 | typedef_declaration ';' // CFA
2729 | cfa_field_declaring_list ';' // CFA, new style field declaration
2730 | EXTENSION cfa_field_declaring_list ';' // GCC
2731 { distExt( $2 ); $$ = $2; } // mark all fields in list
2732 | INLINE attribute_list_opt cfa_field_abstract_list ';' // CFA, new style field declaration
2733 { $$ = $3->addQualifiers( $2 ); } // mark all fields in list
2734 | cfa_typedef_declaration ';' // CFA
2735 | static_assert ';' // C11
2736 ;
2737
2738field_declaring_list_opt:
2739 // empty
2740 { $$ = nullptr; }
2741 | field_declaring_list
2742 ;
2743
2744field_declaring_list:
2745 field_declarator
2746 | field_declaring_list_opt ',' attribute_list_opt field_declarator
2747 { $$ = $1->set_last( $4->addQualifiers( $3 ) ); }
2748 ;
2749
2750field_declarator:
2751 bit_subrange_size // C special case, no field name
2752 { $$ = DeclarationNode::newBitfield( $1 ); }
2753 | variable_declarator bit_subrange_size_opt
2754 // A semantic check is required to ensure bit_subrange only appears on integral types.
2755 { $$ = $1->addBitfield( $2 ); }
2756 | variable_type_redeclarator bit_subrange_size_opt
2757 // A semantic check is required to ensure bit_subrange only appears on integral types.
2758 { $$ = $1->addBitfield( $2 ); }
2759 | function_type_redeclarator bit_subrange_size_opt
2760 // A semantic check is required to ensure bit_subrange only appears on integral types.
2761 { $$ = $1->addBitfield( $2 ); }
2762 ;
2763
2764field_abstract_list_opt:
2765 // empty
2766 { $$ = nullptr; }
2767 | field_abstract
2768 | field_abstract_list_opt ',' attribute_list_opt field_abstract
2769 { $$ = $1->set_last( $4->addQualifiers( $3 ) ); }
2770 ;
2771
2772field_abstract:
2773 variable_abstract_declarator // no bit fields
2774 ;
2775
2776cfa_field_declaring_list: // CFA, new style field declaration
2777 // bit-fields are handled by C declarations
2778 cfa_abstract_declarator_tuple identifier_or_type_name
2779 { $$ = $1->addName( $2 ); }
2780 | cfa_field_declaring_list ',' identifier_or_type_name
2781 { $$ = $1->set_last( $1->cloneType( $3 ) ); }
2782 ;
2783
2784cfa_field_abstract_list: // CFA, new style field declaration
2785 // bit-fields are handled by C declarations
2786 cfa_abstract_declarator_tuple
2787 | cfa_field_abstract_list ','
2788 { $$ = $1->set_last( $1->cloneType( 0 ) ); }
2789 ;
2790
2791bit_subrange_size_opt:
2792 // empty
2793 { $$ = nullptr; }
2794 | bit_subrange_size
2795 ;
2796
2797bit_subrange_size:
2798 ':' assignment_expression
2799 { $$ = $2; }
2800 ;
2801
2802// ************************** ENUMERATION *******************************
2803
2804enum_type:
2805 // anonymous, no type name
2806 ENUM attribute_list_opt hide_opt '{' enumerator_list comma_opt '}' attribute_list_opt
2807 {
2808 if ( $3 == EnumHiding::Hide ) {
2809 SemanticError( yylloc, "illegal syntax, hiding ('!') the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr;
2810 } // if
2811 $$ = DeclarationNode::newEnum( nullptr, $5, true, false )->addQualifiers( $2 )->addQualifiers( $8 );
2812 }
2813 | ENUM enumerator_type attribute_list_opt hide_opt '{' enumerator_list comma_opt '}' attribute_list_opt
2814 {
2815 if ( $2 && ($2->storageClasses.val != 0 || $2->type->qualifiers.any()) ) {
2816 SemanticError( yylloc, "illegal syntax, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2817 }
2818 if ( $4 == EnumHiding::Hide ) {
2819 SemanticError( yylloc, "illegal syntax, hiding ('!') the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr;
2820 } // if
2821 $$ = DeclarationNode::newEnum( nullptr, $6, true, true, $2 )->addQualifiers( $3 )->addQualifiers( $9 );
2822 }
2823
2824 // named type
2825 | ENUM attribute_list_opt identifier attribute_list_opt
2826 { typedefTable.makeTypedef( *$3, "enum_type 1" ); }
2827 hide_opt '{' enumerator_list comma_opt '}' attribute_list_opt
2828 { $$ = DeclarationNode::newEnum( $3, $8, true, false, nullptr, $6 )->addQualifiers( $2 ->addQualifiers( $4 ))->addQualifiers( $11 ); }
2829 | ENUM attribute_list_opt typedef_name attribute_list_opt hide_opt '{' enumerator_list comma_opt '}' attribute_list_opt // unqualified type name
2830 { $$ = DeclarationNode::newEnum( $3->name, $7, true, false, nullptr, $5 )->addQualifiers( $2 )->addQualifiers( $4 )->addQualifiers( $10 ); }
2831 | ENUM enumerator_type attribute_list_opt identifier attribute_list_opt
2832 {
2833 if ( $2 && ($2->storageClasses.any() || $2->type->qualifiers.val != 0) ) {
2834 SemanticError( yylloc, "illegal syntax, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2835 }
2836 typedefTable.makeTypedef( *$4, "enum_type 2" );
2837 }
2838 hide_opt '{' enumerator_list comma_opt '}' attribute_list_opt
2839 { $$ = DeclarationNode::newEnum( $4, $9, true, true, $2, $7 )->addQualifiers( $3 )->addQualifiers( $5 )->addQualifiers( $12 ); }
2840 | ENUM enumerator_type attribute_list_opt typedef_name attribute_list_opt hide_opt '{' enumerator_list comma_opt '}' attribute_list_opt
2841 { $$ = DeclarationNode::newEnum( $4->name, $8, true, true, $2, $6 )->addQualifiers( $3 )->addQualifiers( $5 )->addQualifiers( $11 ); }
2842
2843 // forward declaration
2844 | enum_type_nobody
2845 ;
2846
2847enumerator_type:
2848 '(' ')' // pure enumeration
2849 { $$ = nullptr; }
2850 | '(' cfa_abstract_parameter_declaration ')' // typed enumeration
2851 { $$ = $2; }
2852 ;
2853
2854hide_opt:
2855 // empty
2856 { $$ = EnumHiding::Visible; }
2857 | '!'
2858 { $$ = EnumHiding::Hide; }
2859 ;
2860
2861enum_type_nobody: // enum - {...}
2862 ENUM attribute_list_opt identifier
2863 {
2864 typedefTable.makeTypedef( *$3, "enum_type_nobody 1" );
2865 $$ = DeclarationNode::newEnum( $3, nullptr, false, false )->addQualifiers( $2 );
2866 }
2867 | ENUM attribute_list_opt type_name
2868 {
2869 typedefTable.makeTypedef( *$3->symbolic.name, "enum_type_nobody 2" );
2870 $$ = DeclarationNode::newEnum( $3->symbolic.name, nullptr, false, false )->addQualifiers( $2 );
2871 }
2872 ;
2873
2874enumerator_list:
2875 // empty
2876 { SemanticError( yylloc, "enumeration must have a minimum of one enumerator, empty enumerator list is meaningless." ); $$ = nullptr; }
2877 | visible_hide_opt identifier_or_type_name enumerator_value_opt
2878 { $$ = DeclarationNode::newEnumValueGeneric( $2, $3 ); }
2879 | INLINE type_name
2880 {
2881 $$ = DeclarationNode::newEnumInLine( $2->symbolic.name );
2882 $2->symbolic.name = nullptr;
2883 delete $2;
2884 }
2885 | enumerator_list ',' visible_hide_opt identifier_or_type_name enumerator_value_opt
2886 { $$ = $1->set_last( DeclarationNode::newEnumValueGeneric( $4, $5 ) ); }
2887 | enumerator_list ',' INLINE type_name
2888 { $$ = $1->set_last( DeclarationNode::newEnumInLine( $4->symbolic.name ) ); }
2889 ;
2890
2891visible_hide_opt:
2892 hide_opt
2893 | '^'
2894 { $$ = EnumHiding::Visible; }
2895 ;
2896
2897enumerator_value_opt:
2898 // empty
2899 { $$ = nullptr; }
2900 | '=' constant_expression { $$ = new InitializerNode( $2 ); }
2901 | '=' '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $3, true ); }
2902 // | simple_assignment_operator initializer
2903 // { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2904 ;
2905
2906// ************************** FUNCTION PARAMETERS *******************************
2907
2908parameter_list_ellipsis_opt:
2909 // empty
2910 { $$ = DeclarationNode::newFromTypeData( build_basic_type( TypeData::Void ) ); }
2911 | ELLIPSIS
2912 { $$ = nullptr; }
2913 | parameter_list
2914 | parameter_list ',' ELLIPSIS
2915 { $$ = $1->addVarArgs(); }
2916 ;
2917
2918parameter_list: // abstract + real
2919 parameter_declaration
2920 | attribute_list parameter_declaration
2921 { $$ = $2->addQualifiers( $1 ); }
2922 | abstract_parameter_declaration
2923 | attribute_list abstract_parameter_declaration
2924 { $$ = $2->addQualifiers( $1 ); }
2925 | parameter_list ',' attribute_list_opt parameter_declaration
2926 { $4->addQualifiers( $3 ); $$ = $1->set_last( $4 ); }
2927 | parameter_list ',' attribute_list_opt abstract_parameter_declaration
2928 { $4->addQualifiers( $3 ); $$ = $1->set_last( $4 ); }
2929 ;
2930
2931cfa_parameter_list_ellipsis_opt: // CFA, abstract + real
2932 // empty
2933 { $$ = DeclarationNode::newFromTypeData( build_basic_type( TypeData::Void ) ); }
2934 | ELLIPSIS
2935 { $$ = nullptr; }
2936 | cfa_parameter_list
2937 | cfa_abstract_parameter_list
2938 | cfa_parameter_list ',' cfa_abstract_parameter_list
2939 { $$ = $1->set_last( $3 ); }
2940 | cfa_parameter_list ',' ELLIPSIS
2941 { $$ = $1->addVarArgs(); }
2942 | cfa_abstract_parameter_list ',' ELLIPSIS
2943 { $$ = $1->addVarArgs(); }
2944 ;
2945
2946cfa_parameter_list: // CFA
2947 // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2948 // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2949 cfa_parameter_declaration
2950 | cfa_abstract_parameter_list ',' cfa_parameter_declaration
2951 { $$ = $1->set_last( $3 ); }
2952 | cfa_parameter_list ',' cfa_parameter_declaration
2953 { $$ = $1->set_last( $3 ); }
2954 | cfa_parameter_list ',' cfa_abstract_parameter_list ',' cfa_parameter_declaration
2955 { $$ = $1->set_last( $3 )->set_last( $5 ); }
2956 ;
2957
2958cfa_abstract_parameter_list: // CFA, new & old style abstract
2959 cfa_abstract_parameter_declaration
2960 | cfa_abstract_parameter_list ',' cfa_abstract_parameter_declaration
2961 { $$ = $1->set_last( $3 ); }
2962 ;
2963
2964// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2965// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2966
2967parameter_declaration:
2968 // No SUE declaration in parameter list.
2969 declaration_specifier_nobody identifier_parameter_declarator default_initializer_opt
2970 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2971 | declaration_specifier_nobody type_parameter_redeclarator default_initializer_opt
2972 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2973 ;
2974
2975abstract_parameter_declaration:
2976 declaration_specifier_nobody default_initializer_opt
2977 { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2978 | declaration_specifier_nobody abstract_parameter_declarator default_initializer_opt
2979 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2980 ;
2981
2982cfa_parameter_declaration: // CFA, new & old style parameter declaration
2983 parameter_declaration
2984 | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initializer_opt
2985 { $$ = $1->addName( $2 ); }
2986 | cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2987 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2988 { $$ = $1->addName( $2 ); }
2989 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2990 { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2991 | cfa_function_specifier // int f( "int fp()" );
2992 ;
2993
2994cfa_abstract_parameter_declaration: // CFA, new & old style parameter declaration
2995 abstract_parameter_declaration
2996 | cfa_identifier_parameter_declarator_no_tuple
2997 | cfa_abstract_tuple
2998 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2999 | type_qualifier_list cfa_abstract_tuple
3000 { $$ = $2->addQualifiers( $1 ); }
3001 | cfa_abstract_function // int f( "int ()" );
3002 ;
3003
3004// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
3005// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
3006// identifiers. The ANSI-style parameter-list can redefine a typedef name.
3007
3008identifier_list: // K&R-style parameter list => no types
3009 identifier
3010 { $$ = DeclarationNode::newName( $1 ); }
3011 | identifier_list ',' identifier
3012 { $$ = $1->set_last( DeclarationNode::newName( $3 ) ); }
3013 ;
3014
3015type_no_function: // sizeof, alignof, cast (constructor)
3016 type_specifier // cannot be type_specifier_nobody, e.g., (struct S {}){} is a thing
3017 | type_specifier abstract_declarator
3018 { $$ = $2->addType( $1 ); }
3019 | cfa_abstract_declarator_tuple // CFA
3020 ;
3021
3022type: // typeof, assertion
3023 type_no_function
3024 | attribute_list type_no_function
3025 { $$ = $2->addQualifiers( $1 ); }
3026 | cfa_abstract_function // CFA
3027 | attribute_list cfa_abstract_function // CFA
3028 { $$ = $2->addQualifiers( $1 ); }
3029 ;
3030
3031initializer_opt:
3032 // empty
3033 { $$ = nullptr; }
3034 | simple_assignment_operator initializer { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
3035 | '=' VOID { $$ = new InitializerNode( true ); }
3036 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
3037 ;
3038
3039initializer:
3040 assignment_expression { $$ = new InitializerNode( $1 ); }
3041 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
3042 ;
3043
3044initializer_list_opt:
3045 // empty
3046 { $$ = nullptr; }
3047 | initializer
3048 | designation initializer { $$ = $2->set_designators( $1 ); }
3049 | initializer_list_opt ',' initializer { $$ = $1->set_last( $3 ); }
3050 | initializer_list_opt ',' designation initializer { $$ = $1->set_last( $4->set_designators( $3 ) ); }
3051 ;
3052
3053// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
3054// '=' to separator the designator from the initializer value, as in:
3055//
3056// int x[10] = { [1] = 3 };
3057//
3058// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment. To disambiguate this case, CFA
3059// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
3060// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
3061// shift/reduce conflicts
3062
3063designation:
3064 designator_list '=' // C99, CFA uses ":" instead of "="
3065 | identifier_at ':' // GCC, field name, obsolete since GCC 2.5
3066 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
3067 ;
3068
3069designator_list: // C99
3070 designator
3071 | designator_list designator
3072 { $$ = $1->set_last( $2 ); }
3073 ;
3074
3075designator:
3076 '.' identifier_at // C99, field name
3077 { $$ = new ExpressionNode( build_varref( yylloc, $2 ) ); }
3078 | '[' constant_expression ']' // C99, single array element
3079 { $$ = $2; }
3080 | '[' subrange ']' // CFA, multiple array elements
3081 { $$ = $2; }
3082 | '[' constant_expression ELLIPSIS constant_expression ']' // GCC, multiple array elements
3083 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $2 ), maybeMoveBuild( $4 ) ) ); }
3084 | '.' '[' field_name_list ']' // CFA, tuple field selector
3085 { $$ = $3; }
3086 ;
3087
3088// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
3089// rather than an object-oriented type system. This required four groups of extensions:
3090//
3091// Overloading: function, data, and operator identifiers may be overloaded.
3092//
3093// Type declarations: "otype" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
3094// and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
3095// definitions of new types. Type declarations with storage class "extern" provide opaque types.
3096//
3097// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
3098// site. A polymorphic function is not a template; it is a function, with an address and a type.
3099//
3100// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
3101// types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
3102// hierarchies. Unlike classes, they can define relationships between types. Assertions declare that a type or
3103// types provide the operations declared by a specification. Assertions are normally used to declare requirements
3104// on type arguments of polymorphic functions.
3105
3106type_parameter_list: // CFA
3107 type_parameter
3108 | type_parameter_list ',' type_parameter
3109 { $$ = $1->set_last( $3 ); }
3110 ;
3111
3112type_initializer_opt: // CFA
3113 // empty
3114 { $$ = nullptr; }
3115 | '=' type
3116 { $$ = $2; }
3117 ;
3118
3119type_parameter: // CFA
3120 type_class identifier_or_type_name
3121 { typedefTable.addToScope( *$2, TYPEDEFname, "type_parameter 1" ); }
3122 type_initializer_opt assertion_list_opt
3123 { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
3124 | identifier_or_type_name new_type_class
3125 { typedefTable.addToScope( *$1, TYPEDEFname, "type_parameter 2" ); }
3126 type_initializer_opt assertion_list_opt
3127 { $$ = DeclarationNode::newTypeParam( $2, $1 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
3128 | '[' identifier_or_type_name ']' assertion_list_opt
3129 {
3130 typedefTable.addToScope( *$2, TYPEDIMname, "type_parameter 3" );
3131 $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dimension, $2 )->addAssertions( $4 );
3132 }
3133 // | type_specifier identifier_parameter_declarator
3134 | assertion_list
3135 // Invent a placeholder type to wrap these bare assertions. Rely on buildFunctionDecl to remove the placeholder.
3136 { $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dtype, new string( "" ) )->addAssertions( $1 ); }
3137 | ENUM '(' identifier_or_type_name ')' identifier_or_type_name new_type_class type_initializer_opt assertion_list_opt
3138 {
3139 typedefTable.addToScope( *$3, TYPEDIMname, "type_parameter 4" );
3140 typedefTable.addToScope( *$5, TYPEDIMname, "type_parameter 5" );
3141 $$ = DeclarationNode::newTypeParam( $6, $5 )->addTypeInitializer( $7 )->addAssertions( $8 );
3142 }
3143 ;
3144
3145new_type_class: // CFA
3146 // empty
3147 { $$ = ast::TypeDecl::Otype; }
3148 | '&'
3149 { $$ = ast::TypeDecl::Dtype; }
3150 | '*'
3151 { $$ = ast::TypeDecl::DStype; } // Dtype + sized
3152 // | '(' '*' ')' // Gregor made me do it
3153 // { $$ = ast::TypeDecl::Ftype; }
3154 | ELLIPSIS
3155 { $$ = ast::TypeDecl::Ttype; }
3156 ;
3157
3158type_class: // CFA
3159 OTYPE
3160 { SemanticError( yylloc, "otype keyword is deprecated, use T " ); }
3161 | DTYPE
3162 { SemanticError( yylloc, "dtype keyword is deprecated, use T &" ); }
3163 | FTYPE
3164 { $$ = ast::TypeDecl::Ftype; }
3165 | TTYPE
3166 { SemanticError( yylloc, "ttype keyword is deprecated, use T ..." ); }
3167 ;
3168
3169assertion_list_opt: // CFA
3170 // empty
3171 { $$ = nullptr; }
3172 | assertion_list
3173 ;
3174
3175assertion_list: // CFA
3176 assertion
3177 | assertion_list assertion
3178 { $$ = $1->set_last( $2 ); }
3179 ;
3180
3181assertion: // CFA
3182 '|' identifier_or_type_name '(' type_list ')'
3183 { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
3184 | '|' '{' trait_declaration_list '}'
3185 { $$ = $3; }
3186 // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
3187 // { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
3188 ;
3189
3190type_list: // CFA
3191 type
3192 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3193 | assignment_expression
3194 | type_list ',' type
3195 { $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
3196 | type_list ',' assignment_expression
3197 { $$ = $1->set_last( $3 ); }
3198 ;
3199
3200type_declaring_list: // CFA
3201 OTYPE type_declarator
3202 { $$ = $2; }
3203 | storage_class_list OTYPE type_declarator
3204 { $$ = $3->addQualifiers( $1 ); }
3205 | type_declaring_list ',' type_declarator
3206 { $$ = $1->set_last( $3->copySpecifiers( $1 ) ); }
3207 ;
3208
3209type_declarator: // CFA
3210 type_declarator_name assertion_list_opt
3211 { $$ = $1->addAssertions( $2 ); }
3212 | type_declarator_name assertion_list_opt '=' type
3213 { $$ = $1->addAssertions( $2 )->addType( $4 ); }
3214 ;
3215
3216type_declarator_name: // CFA
3217 identifier_or_type_name
3218 {
3219 typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "type_declarator_name 1" );
3220 $$ = DeclarationNode::newTypeDecl( $1, nullptr );
3221 }
3222 | identifier_or_type_name '(' type_parameter_list ')'
3223 {
3224 typedefTable.addToEnclosingScope( *$1, TYPEGENname, "type_declarator_name 2" );
3225 $$ = DeclarationNode::newTypeDecl( $1, $3 );
3226 }
3227 ;
3228
3229trait_specifier: // CFA
3230 TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
3231 {
3232 SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3233 $$ = DeclarationNode::newTrait( $2, $4, nullptr );
3234 }
3235 | forall TRAIT identifier_or_type_name '{' '}' // new alternate
3236 { $$ = DeclarationNode::newTrait( $3, $1, nullptr ); }
3237 | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' trait_declaration_list '}'
3238 {
3239 SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3240 $$ = DeclarationNode::newTrait( $2, $4, $7 );
3241 }
3242 | forall TRAIT identifier_or_type_name '{' trait_declaration_list '}' // alternate
3243 { $$ = DeclarationNode::newTrait( $3, $1, $5 ); }
3244 ;
3245
3246trait_declaration_list: // CFA
3247 trait_declaration
3248 | trait_declaration_list trait_declaration
3249 { $$ = $1->set_last( $2 ); }
3250 ;
3251
3252trait_declaration: // CFA
3253 cfa_trait_declaring_list ';'
3254 | trait_declaring_list ';'
3255 ;
3256
3257cfa_trait_declaring_list: // CFA
3258 cfa_variable_specifier
3259 | cfa_function_specifier
3260 | cfa_trait_declaring_list ',' identifier_or_type_name
3261 { $$ = $1->set_last( $1->cloneType( $3 ) ); }
3262 ;
3263
3264trait_declaring_list: // CFA
3265 // Cannot declare an aggregate or enumeration in a trait.
3266 type_specifier_nobody declarator
3267 { $$ = $2->addType( $1 ); }
3268 | trait_declaring_list ',' declarator
3269 { $$ = $1->set_last( $1->cloneBaseType( $3 ) ); }
3270 | error
3271 { SemanticError( yylloc, "Possible cause is declaring an aggregate or enumeration type in a trait." ); $$ = nullptr; }
3272 ;
3273
3274// **************************** EXTERNAL DEFINITIONS *****************************
3275
3276translation_unit:
3277 // empty, input file
3278 | external_definition_list
3279 { parseTree = parseTree ? parseTree->set_last( $1 ) : $1; }
3280 ;
3281
3282external_definition_list_opt:
3283 // empty
3284 { $$ = nullptr; }
3285 | external_definition_list
3286 ;
3287
3288external_definition_list:
3289 attribute_list_opt push external_definition pop
3290 { distAttr( $1, $3 ); $$ = $3; }
3291 | external_definition_list attribute_list_opt push external_definition pop
3292 { distAttr( $2, $4 ); $$ = $1 ? $1->set_last( $4 ) : $4->addQualifiers( $2 ); }
3293 ;
3294
3295up:
3296 { typedefTable.up( forall ); forall = false; }
3297 ;
3298
3299down:
3300 { typedefTable.down(); }
3301 ;
3302
3303external_definition:
3304 DIRECTIVE
3305 { $$ = DeclarationNode::newDirectiveStmt( new StatementNode( build_directive( yylloc, $1 ) ) ); }
3306 | declaration
3307 {
3308 // Variable declarations of anonymous types requires creating a unique type-name across multiple translation
3309 // unit, which is a dubious task, especially because C uses name rather than structural typing; hence it is
3310 // disallowed at the moment.
3311 if ( $1->linkage == ast::Linkage::Cforall && ! $1->storageClasses.is_static &&
3312 $1->type && $1->type->kind == TypeData::AggregateInst ) {
3313 if ( $1->type->aggInst.aggregate->aggregate.anon ) {
3314 SemanticError( yylloc, "extern anonymous aggregate is currently unimplemented." ); $$ = nullptr;
3315 }
3316 }
3317 }
3318 | IDENTIFIER IDENTIFIER
3319 { IdentifierBeforeIdentifier( *$1.str, *$2.str, " declaration" ); $$ = nullptr; }
3320 | IDENTIFIER type_qualifier // invalid syntax rule
3321 { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
3322 | IDENTIFIER storage_class // invalid syntax rule
3323 { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
3324 | IDENTIFIER basic_type_name // invalid syntax rule
3325 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3326 | IDENTIFIER TYPEDEFname // invalid syntax rule
3327 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3328 | IDENTIFIER TYPEGENname // invalid syntax rule
3329 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3330 | external_function_definition
3331 | EXTENSION external_definition // GCC, multiple __extension__ allowed, meaning unknown
3332 {
3333 distExt( $2 ); // mark all fields in list
3334 $$ = $2;
3335 }
3336 | ASM '(' string_literal ')' ';' // GCC, global assembler statement
3337 { $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( yylloc, false, $3, nullptr ) ) ); }
3338 | EXTERN STRINGliteral
3339 {
3340 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
3341 linkage = ast::Linkage::update( yylloc, linkage, $2 );
3342 }
3343 up external_definition down
3344 {
3345 linkage = linkageStack.top();
3346 linkageStack.pop();
3347 $$ = $5;
3348 }
3349 | EXTERN STRINGliteral // C++-style linkage specifier
3350 {
3351 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
3352 linkage = ast::Linkage::update( yylloc, linkage, $2 );
3353 }
3354 '{' up external_definition_list_opt down '}'
3355 {
3356 linkage = linkageStack.top();
3357 linkageStack.pop();
3358 $$ = $6;
3359 }
3360 // global distribution
3361 | type_qualifier_list
3362 {
3363 if ( $1->type->qualifiers.any() ) {
3364 SemanticError( yylloc, "illegal syntax, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3365 }
3366 if ( $1->type->forall ) forall = true; // remember generic type
3367 }
3368 '{' up external_definition_list_opt down '}' // CFA, namespace
3369 {
3370 distQual( $5, $1 );
3371 forall = false;
3372 $$ = $5;
3373 }
3374 | declaration_qualifier_list
3375 {
3376 if ( $1->type && $1->type->qualifiers.any() ) {
3377 SemanticError( yylloc, "illegal syntax, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3378 }
3379 if ( $1->type && $1->type->forall ) forall = true; // remember generic type
3380 }
3381 '{' up external_definition_list_opt down '}' // CFA, namespace
3382 {
3383 distQual( $5, $1 );
3384 forall = false;
3385 $$ = $5;
3386 }
3387 | declaration_qualifier_list type_qualifier_list
3388 {
3389 if ( ($1->type && $1->type->qualifiers.any()) || ($2->type && $2->type->qualifiers.any()) ) {
3390 SemanticError( yylloc, "illegal syntax, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3391 }
3392 if ( ($1->type && $1->type->forall) || ($2->type && $2->type->forall) ) forall = true; // remember generic type
3393 }
3394 '{' up external_definition_list_opt down '}' // CFA, namespace
3395 {
3396 distQual( $6, $1->addQualifiers( $2 ) );
3397 forall = false;
3398 $$ = $6;
3399 }
3400 | ';' // empty declaration
3401 { $$ = nullptr; }
3402 ;
3403
3404external_function_definition:
3405 function_definition
3406 // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
3407 // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
3408 // Parsing is possible because function_definition does not appear in the context of an expression (nested
3409 // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
3410 // declaration must still have a type_specifier. OBSOLESCENT (see 1)
3411 | function_declarator compound_statement
3412 { $$ = $1->addFunctionBody( $2 ); }
3413 | KR_function_declarator KR_parameter_list_opt compound_statement
3414 { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
3415 ;
3416
3417with_clause_opt:
3418 // empty
3419 { $$ = nullptr; forall = false; }
3420 | WITH '(' type_list ')' attribute_list_opt // support scoped enumeration
3421 {
3422 $$ = $3; forall = false;
3423 if ( $5 ) {
3424 SemanticError( yylloc, "illegal syntax, attributes cannot be associated with function body. Move attribute(s) before \"with\" clause." );
3425 $$ = nullptr;
3426 } // if
3427 }
3428 ;
3429
3430function_definition:
3431 cfa_function_declaration with_clause_opt compound_statement // CFA
3432 {
3433 // Add the function body to the last identifier in the function definition list, i.e., foo3:
3434 // [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
3435 $1->get_last()->addFunctionBody( $3, $2 );
3436 $$ = $1;
3437 }
3438 | declaration_specifier function_declarator with_clause_opt compound_statement
3439 {
3440 rebindForall( $1, $2 );
3441 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3442 }
3443 | declaration_specifier function_type_redeclarator with_clause_opt compound_statement
3444 {
3445 rebindForall( $1, $2 );
3446 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3447 }
3448 // handles default int return type, OBSOLESCENT (see 1)
3449 | type_qualifier_list function_declarator with_clause_opt compound_statement
3450 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3451 // handles default int return type, OBSOLESCENT (see 1)
3452 | declaration_qualifier_list function_declarator with_clause_opt compound_statement
3453 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3454 // handles default int return type, OBSOLESCENT (see 1)
3455 | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
3456 { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3457
3458 // Old-style K&R function definition, OBSOLESCENT (see 4)
3459 | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3460 {
3461 rebindForall( $1, $2 );
3462 $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
3463 }
3464 // handles default int return type, OBSOLESCENT (see 1)
3465 | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3466 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3467 // handles default int return type, OBSOLESCENT (see 1)
3468 | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3469 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3470 // handles default int return type, OBSOLESCENT (see 1)
3471 | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3472 { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3473 ;
3474
3475declarator:
3476 variable_declarator
3477 | variable_type_redeclarator
3478 | function_declarator
3479 | function_type_redeclarator
3480 ;
3481
3482subrange:
3483 constant_expression '~' constant_expression // CFA, integer subrange
3484 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
3485 ;
3486
3487// **************************** ASM *****************************
3488
3489asm_name_opt: // GCC
3490 // empty
3491 { $$ = nullptr; }
3492 | ASM '(' string_literal ')' attribute_list_opt
3493 {
3494 DeclarationNode * name = new DeclarationNode();
3495 name->asmName = maybeMoveBuild( $3 );
3496 $$ = name->addQualifiers( $5 );
3497 }
3498 ;
3499
3500// **************************** ATTRIBUTE *****************************
3501
3502attribute_list_opt: // GCC
3503 // empty
3504 { $$ = nullptr; }
3505 | attribute_list
3506 ;
3507
3508attribute_list: // GCC
3509 attribute
3510 | attribute_list attribute
3511 { $$ = $2->addQualifiers( $1 ); }
3512 ;
3513
3514attribute: // GCC
3515 ATTRIBUTE '(' '(' attribute_name_list ')' ')'
3516 { $$ = $4; }
3517 | ATTRIBUTE '(' attribute_name_list ')' // CFA
3518 { $$ = $3; }
3519 | ATTR attribute_name_list ']' // CFA, @[...]
3520 { $$ = $2; }
3521 | C23_ATTRIBUTE // C23, [[...]], see lexer
3522 { $$ = DeclarationNode::newAttribute( $1 ); }
3523 ;
3524
3525attribute_name_list: // GCC
3526 attribute_name
3527 | attribute_name_list ',' attribute_name
3528 { $$ = $3->addQualifiers( $1 ); }
3529 ;
3530
3531attribute_name: // GCC
3532 // empty
3533 { $$ = nullptr; }
3534 | attr_name
3535 { $$ = DeclarationNode::newAttribute( $1 ); }
3536 | attr_name '(' argument_expression_list_opt ')'
3537 { $$ = DeclarationNode::newAttribute( $1, $3 ); }
3538 ;
3539
3540attr_name: // GCC
3541 identifier_or_type_name
3542 | FALLTHROUGH
3543 { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
3544 | CONST
3545 { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
3546 ;
3547
3548// ============================================================================
3549// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
3550// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
3551// in:
3552//
3553// int (*f())[10] { ... };
3554// ... (*f())[3] += 1; // definition mimics usage
3555//
3556// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
3557// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
3558// ============================================================================
3559
3560// ----------------------------------------------------------------------------
3561// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
3562// to define a variable or function prototype, e.g.:
3563//
3564// valid declaration invalid definition
3565// ----------------- ------------------
3566// int f; int f {}
3567// int *f; int *f {}
3568// int f[10]; int f[10] {}
3569// int (*f)(int); int (*f)(int) {}
3570//
3571// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
3572// variable_declarator and function_declarator.
3573// ----------------------------------------------------------------------------
3574
3575// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
3576// declaring an array of functions versus a pointer to an array of functions.
3577
3578paren_identifier:
3579 identifier_at
3580 { $$ = DeclarationNode::newName( $1 ); }
3581 | '?' identifier
3582 // { SemanticError( yylloc, "keyword parameter is currently unimplemented." ); $$ = nullptr; }
3583 { $$ = DeclarationNode::newName( $2 ); }
3584 | '(' paren_identifier ')' // redundant parenthesis
3585 { $$ = $2; }
3586 ;
3587
3588variable_declarator:
3589 paren_identifier attribute_list_opt
3590 { $$ = $1->addQualifiers( $2 ); }
3591 | variable_ptr
3592 | variable_array attribute_list_opt
3593 { $$ = $1->addQualifiers( $2 ); }
3594 | variable_function attribute_list_opt
3595 { $$ = $1->addQualifiers( $2 ); }
3596 ;
3597
3598variable_ptr:
3599 ptrref_operator variable_declarator
3600 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3601 | ptrref_operator attribute_list variable_declarator
3602 { $$ = $3->addPointer( DeclarationNode::newPointer( nullptr, $1 ) )->addQualifiers( $2 ); }
3603 | ptrref_operator type_qualifier_list variable_declarator
3604 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3605 | '(' variable_ptr ')' attribute_list_opt // redundant parenthesis
3606 { $$ = $2->addQualifiers( $4 ); }
3607 | '(' attribute_list variable_ptr ')' attribute_list_opt // redundant parenthesis
3608 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3609 ;
3610
3611variable_array:
3612 paren_identifier array_dimension
3613 { $$ = $1->addArray( $2 ); }
3614 | '(' variable_ptr ')' array_dimension
3615 { $$ = $2->addArray( $4 ); }
3616 | '(' attribute_list variable_ptr ')' array_dimension
3617 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3618 | '(' variable_array ')' multi_array_dimension // redundant parenthesis
3619 { $$ = $2->addArray( $4 ); }
3620 | '(' attribute_list variable_array ')' multi_array_dimension // redundant parenthesis
3621 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3622 | '(' variable_array ')' // redundant parenthesis
3623 { $$ = $2; }
3624 | '(' attribute_list variable_array ')' // redundant parenthesis
3625 { $$ = $3->addQualifiers( $2 ); }
3626 ;
3627
3628variable_function:
3629 '(' variable_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3630 { $$ = $2->addParamList( $5 ); }
3631 | '(' attribute_list variable_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3632 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3633 | '(' variable_function ')' // redundant parenthesis
3634 { $$ = $2; }
3635 | '(' attribute_list variable_function ')' // redundant parenthesis
3636 { $$ = $3->addQualifiers( $2 ); }
3637 ;
3638
3639// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
3640// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
3641// is the same scope. The pattern precludes returning arrays and functions versus pointers to arrays and functions.
3642
3643function_declarator:
3644 function_no_ptr attribute_list_opt
3645 { $$ = $1->addQualifiers( $2 ); }
3646 | function_ptr
3647 | function_array attribute_list_opt
3648 { $$ = $1->addQualifiers( $2 ); }
3649 ;
3650
3651function_no_ptr:
3652 paren_identifier '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3653 { $$ = $1->addParamList( $3 ); }
3654 | '(' function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3655 { $$ = $2->addParamList( $5 ); }
3656 | '(' attribute_list function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3657 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3658 | '(' function_no_ptr ')' // redundant parenthesis
3659 { $$ = $2; }
3660 | '(' attribute_list function_no_ptr ')' // redundant parenthesis
3661 { $$ = $3->addQualifiers( $2 ); }
3662 ;
3663
3664function_ptr:
3665 ptrref_operator function_declarator
3666 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3667 | ptrref_operator attribute_list function_declarator
3668 { $$ = $3->addPointer( DeclarationNode::newPointer( nullptr, $1 ) )->addQualifiers( $2 ); }
3669 | ptrref_operator type_qualifier_list function_declarator
3670 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3671 | '(' function_ptr ')' attribute_list_opt
3672 { $$ = $2->addQualifiers( $4 ); }
3673 | '(' attribute_list function_ptr ')' attribute_list_opt
3674 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3675 ;
3676
3677function_array:
3678 '(' function_ptr ')' array_dimension
3679 { $$ = $2->addArray( $4 ); }
3680 | '(' attribute_list function_ptr ')' array_dimension
3681 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3682 | '(' function_array ')' multi_array_dimension // redundant parenthesis
3683 { $$ = $2->addArray( $4 ); }
3684 | '(' attribute_list function_array ')' multi_array_dimension // redundant parenthesis
3685 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3686 | '(' function_array ')' // redundant parenthesis
3687 { $$ = $2; }
3688 | '(' attribute_list function_array ')' // redundant parenthesis
3689 { $$ = $3->addQualifiers( $2 ); }
3690 ;
3691
3692// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
3693//
3694// f( a, b, c ) int a, *b, c[]; {}
3695//
3696// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
3697// returning arrays and functions versus pointers to arrays and functions.
3698
3699KR_function_declarator:
3700 KR_function_no_ptr
3701 | KR_function_ptr
3702 | KR_function_array
3703 ;
3704
3705KR_function_no_ptr:
3706 paren_identifier '(' identifier_list ')' // function_declarator handles empty parameter
3707 { $$ = $1->addIdList( $3 ); }
3708 | '(' KR_function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3709 { $$ = $2->addParamList( $5 ); }
3710 | '(' attribute_list KR_function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3711 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3712 | '(' KR_function_no_ptr ')' // redundant parenthesis
3713 { $$ = $2; }
3714 | '(' attribute_list KR_function_no_ptr ')' // redundant parenthesis
3715 { $$ = $3->addQualifiers( $2 ); }
3716 ;
3717
3718KR_function_ptr:
3719 ptrref_operator KR_function_declarator
3720 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3721 | ptrref_operator attribute_list KR_function_declarator
3722 { $$ = $3->addPointer( DeclarationNode::newPointer( nullptr, $1 ) )->addQualifiers( $2 ); }
3723 | ptrref_operator type_qualifier_list KR_function_declarator
3724 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3725 | '(' KR_function_ptr ')'
3726 { $$ = $2; }
3727 | '(' attribute_list KR_function_ptr ')'
3728 { $$ = $3->addQualifiers( $2 ); }
3729 ;
3730
3731KR_function_array:
3732 '(' KR_function_ptr ')' array_dimension
3733 { $$ = $2->addArray( $4 ); }
3734 | '(' attribute_list KR_function_ptr ')' array_dimension
3735 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3736 | '(' KR_function_array ')' multi_array_dimension // redundant parenthesis
3737 { $$ = $2->addArray( $4 ); }
3738 | '(' attribute_list KR_function_array ')' multi_array_dimension // redundant parenthesis
3739 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3740 | '(' KR_function_array ')' // redundant parenthesis
3741 { $$ = $2; }
3742 | '(' attribute_list KR_function_array ')' // redundant parenthesis
3743 { $$ = $3->addQualifiers( $2 ); }
3744 ;
3745
3746// This pattern parses a declaration for a variable that redefines a type name, e.g.:
3747//
3748// typedef int foo;
3749// {
3750// int foo; // redefine typedef name in new scope
3751// }
3752
3753paren_type:
3754 typedef_name
3755 {
3756 // hide type name in enclosing scope by variable name
3757 typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "paren_type" );
3758 }
3759 | '(' paren_type ')'
3760 { $$ = $2; }
3761 ;
3762
3763variable_type_redeclarator:
3764 paren_type attribute_list_opt
3765 { $$ = $1->addQualifiers( $2 ); }
3766 | variable_type_ptr
3767 | variable_type_array attribute_list_opt
3768 { $$ = $1->addQualifiers( $2 ); }
3769 | variable_type_function attribute_list_opt
3770 { $$ = $1->addQualifiers( $2 ); }
3771 ;
3772
3773variable_type_ptr:
3774 ptrref_operator variable_type_redeclarator
3775 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3776 | ptrref_operator attribute_list variable_type_redeclarator
3777 { $$ = $3->addPointer( DeclarationNode::newPointer( nullptr, $1 ) )->addQualifiers( $2 ); }
3778 | ptrref_operator type_qualifier_list variable_type_redeclarator
3779 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3780 | '(' variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3781 { $$ = $2->addQualifiers( $4 ); }
3782 | '(' attribute_list variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3783 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3784 ;
3785
3786variable_type_array:
3787 paren_type array_dimension
3788 { $$ = $1->addArray( $2 ); }
3789 | '(' variable_type_ptr ')' array_dimension
3790 { $$ = $2->addArray( $4 ); }
3791 | '(' attribute_list variable_type_ptr ')' array_dimension
3792 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3793 | '(' variable_type_array ')' multi_array_dimension // redundant parenthesis
3794 { $$ = $2->addArray( $4 ); }
3795 | '(' attribute_list variable_type_array ')' multi_array_dimension // redundant parenthesis
3796 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3797 | '(' variable_type_array ')' // redundant parenthesis
3798 { $$ = $2; }
3799 | '(' attribute_list variable_type_array ')' // redundant parenthesis
3800 { $$ = $3->addQualifiers( $2 ); }
3801 ;
3802
3803variable_type_function:
3804 '(' variable_type_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3805 { $$ = $2->addParamList( $5 ); }
3806 | '(' attribute_list variable_type_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3807 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3808 | '(' variable_type_function ')' // redundant parenthesis
3809 { $$ = $2; }
3810 | '(' attribute_list variable_type_function ')' // redundant parenthesis
3811 { $$ = $3->addQualifiers( $2 ); }
3812 ;
3813
3814// This pattern parses a declaration for a function prototype that redefines a type name. It precludes declaring an
3815// array of functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to
3816// arrays and functions.
3817
3818function_type_redeclarator:
3819 function_type_no_ptr attribute_list_opt
3820 { $$ = $1->addQualifiers( $2 ); }
3821 | function_type_ptr
3822 | function_type_array attribute_list_opt
3823 { $$ = $1->addQualifiers( $2 ); }
3824 ;
3825
3826function_type_no_ptr:
3827 paren_type '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3828 { $$ = $1->addParamList( $3 ); }
3829 | '(' function_type_ptr ')' '(' parameter_list_ellipsis_opt ')'
3830 { $$ = $2->addParamList( $5 ); }
3831 | '(' attribute_list function_type_ptr ')' '(' parameter_list_ellipsis_opt ')'
3832 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3833 | '(' function_type_no_ptr ')' // redundant parenthesis
3834 { $$ = $2; }
3835 | '(' attribute_list function_type_no_ptr ')' // redundant parenthesis
3836 { $$ = $3->addQualifiers( $2 ); }
3837 ;
3838
3839function_type_ptr:
3840 ptrref_operator function_type_redeclarator
3841 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3842 | ptrref_operator attribute_list function_type_redeclarator
3843 { $$ = $3->addPointer( DeclarationNode::newPointer( nullptr, $1 ) )->addQualifiers( $2 ); }
3844 | ptrref_operator type_qualifier_list function_type_redeclarator
3845 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3846 | '(' function_type_ptr ')' attribute_list_opt
3847 { $$ = $2->addQualifiers( $4 ); }
3848 | '(' attribute_list function_type_ptr ')' attribute_list_opt
3849 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3850 ;
3851
3852function_type_array:
3853 '(' function_type_ptr ')' array_dimension
3854 { $$ = $2->addArray( $4 ); }
3855 | '(' attribute_list function_type_ptr ')' array_dimension
3856 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3857 | '(' function_type_array ')' multi_array_dimension // redundant parenthesis
3858 { $$ = $2->addArray( $4 ); }
3859 | '(' attribute_list function_type_array ')' multi_array_dimension // redundant parenthesis
3860 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3861 | '(' function_type_array ')' // redundant parenthesis
3862 { $$ = $2; }
3863 | '(' attribute_list function_type_array ')' // redundant parenthesis
3864 { $$ = $3->addQualifiers( $2 ); }
3865 ;
3866
3867// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
3868// typedef name and allows the C99 array options, which can only appear in a parameter list. The pattern precludes
3869// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
3870// pointers to arrays and functions.
3871
3872identifier_parameter_declarator:
3873 paren_identifier attribute_list_opt
3874 { $$ = $1->addQualifiers( $2 ); }
3875 | '&' MUTEX paren_identifier attribute_list_opt
3876 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
3877 OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3878 | identifier_parameter_ptr
3879 | identifier_parameter_array attribute_list_opt
3880 { $$ = $1->addQualifiers( $2 ); }
3881 | identifier_parameter_function attribute_list_opt
3882 { $$ = $1->addQualifiers( $2 ); }
3883 ;
3884
3885identifier_parameter_ptr:
3886 ptrref_operator identifier_parameter_declarator
3887 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3888 | ptrref_operator attribute_list identifier_parameter_declarator
3889 { $$ = $3->addPointer( DeclarationNode::newPointer( nullptr, $1 ) )->addQualifiers( $2 ); }
3890 | ptrref_operator type_qualifier_list identifier_parameter_declarator
3891 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3892 | '(' identifier_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3893 { $$ = $2->addQualifiers( $4 ); }
3894 ;
3895
3896identifier_parameter_array:
3897 paren_identifier array_parameter_dimension
3898 { $$ = $1->addArray( $2 ); }
3899 | '(' identifier_parameter_ptr ')' array_dimension
3900 { $$ = $2->addArray( $4 ); }
3901 | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3902 { $$ = $2->addArray( $4 ); }
3903 | '(' identifier_parameter_array ')' // redundant parenthesis
3904 { $$ = $2; }
3905 ;
3906
3907identifier_parameter_function:
3908 paren_identifier '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3909 { $$ = $1->addParamList( $3 ); }
3910 | '(' identifier_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3911 { $$ = $2->addParamList( $5 ); }
3912 | '(' identifier_parameter_function ')' // redundant parenthesis
3913 { $$ = $2; }
3914 ;
3915
3916// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3917// e.g.:
3918//
3919// typedef int foo;
3920// forall( otype T ) struct foo;
3921// int f( int foo ); // redefine typedef name in new scope
3922//
3923// and allows the C99 array options, which can only appear in a parameter list.
3924
3925type_parameter_redeclarator:
3926 typedef_name attribute_list_opt
3927 { $$ = $1->addQualifiers( $2 ); }
3928 | '&' MUTEX typedef_name attribute_list_opt
3929 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
3930 OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3931 | type_parameter_ptr
3932 | type_parameter_array attribute_list_opt
3933 { $$ = $1->addQualifiers( $2 ); }
3934 | type_parameter_function attribute_list_opt
3935 { $$ = $1->addQualifiers( $2 ); }
3936 ;
3937
3938typedef_name:
3939 TYPEDEFname
3940 { $$ = DeclarationNode::newName( $1 ); }
3941 | TYPEGENname
3942 { $$ = DeclarationNode::newName( $1 ); }
3943 ;
3944
3945type_parameter_ptr:
3946 ptrref_operator type_parameter_redeclarator
3947 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3948 | ptrref_operator attribute_list type_parameter_redeclarator
3949 { $$ = $3->addPointer( DeclarationNode::newPointer( nullptr, $1 ) )->addQualifiers( $2 ); }
3950 | ptrref_operator type_qualifier_list type_parameter_redeclarator
3951 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3952 | '(' type_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3953 { $$ = $2->addQualifiers( $4 ); }
3954 ;
3955
3956type_parameter_array:
3957 typedef_name array_parameter_dimension
3958 { $$ = $1->addArray( $2 ); }
3959 | '(' type_parameter_ptr ')' array_parameter_dimension
3960 { $$ = $2->addArray( $4 ); }
3961 ;
3962
3963type_parameter_function:
3964 typedef_name '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3965 { $$ = $1->addParamList( $3 ); }
3966 | '(' type_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3967 { $$ = $2->addParamList( $5 ); }
3968 ;
3969
3970// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3971// which the type applies, e.g.:
3972//
3973// sizeof( int );
3974// sizeof( int * );
3975// sizeof( int [10] );
3976// sizeof( int (*)() );
3977// sizeof( int () );
3978//
3979// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3980// and functions versus pointers to arrays and functions.
3981
3982abstract_declarator:
3983 abstract_ptr
3984 | abstract_array attribute_list_opt
3985 { $$ = $1->addQualifiers( $2 ); }
3986 | abstract_function attribute_list_opt
3987 { $$ = $1->addQualifiers( $2 ); }
3988 ;
3989
3990abstract_ptr:
3991 ptrref_operator attribute_list_opt
3992 { $$ = DeclarationNode::newPointer( nullptr, $1 )->addQualifiers( $2 ); }
3993 | ptrref_operator type_qualifier_list
3994 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3995 | ptrref_operator abstract_declarator
3996 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3997 | ptrref_operator attribute_list abstract_declarator
3998 { $$ = $3->addPointer( DeclarationNode::newPointer( nullptr, $1 )->addQualifiers( $2 ) ); }
3999 | ptrref_operator type_qualifier_list abstract_declarator
4000 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4001 | '(' abstract_ptr ')' attribute_list_opt
4002 { $$ = $2->addQualifiers( $4 ); }
4003 ;
4004
4005abstract_array:
4006 array_dimension
4007 | '(' abstract_ptr ')' array_dimension
4008 { $$ = $2->addArray( $4 ); }
4009 | '(' abstract_array ')' multi_array_dimension // redundant parenthesis
4010 { $$ = $2->addArray( $4 ); }
4011 | '(' abstract_array ')' // redundant parenthesis
4012 { $$ = $2; }
4013 ;
4014
4015abstract_function:
4016 '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4017 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
4018 | '(' abstract_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4019 { $$ = $2->addParamList( $5 ); }
4020 | '(' abstract_function ')' // redundant parenthesis
4021 { $$ = $2; }
4022 ;
4023
4024array_dimension:
4025 // Only the first dimension can be empty.
4026 '[' ']'
4027 { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
4028 | '[' ']' multi_array_dimension
4029 { $$ = DeclarationNode::newArray( nullptr, nullptr, false )->addArray( $3 ); }
4030 // Cannot use constant_expression because of tuples => semantic check
4031 | '[' assignment_expression ',' ']' // CFA
4032 { SemanticError( yylloc, "New array dimension is currently unimplemented." ); $$ = nullptr; }
4033 // { $$ = DeclarationNode::newArray( $2, nullptr, false ); }
4034 | '[' assignment_expression ',' comma_expression ']' // CFA
4035 { SemanticError( yylloc, "New array dimension is currently unimplemented." ); $$ = nullptr; }
4036 // { $$ = DeclarationNode::newArray( $2, nullptr, false )->addArray( DeclarationNode::newArray( $4, nullptr, false ) ); }
4037
4038 // If needed, the following parses and does not use comma_expression, so the array structure can be built.
4039 // | '[' push assignment_expression pop ',' push array_dimension_list pop ']' // CFA
4040
4041 | '[' array_type_list ']' // CFA
4042 { $$ = DeclarationNode::newArray( $2, nullptr, false ); }
4043 | multi_array_dimension
4044 ;
4045
4046// array_dimension_list:
4047// assignment_expression
4048// | array_dimension_list ',' assignment_expression
4049// ;
4050
4051array_type_list:
4052 basic_type_name
4053 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
4054 | type_name
4055 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
4056 | assignment_expression upupeq assignment_expression
4057 | array_type_list ',' basic_type_name
4058 { $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
4059 | array_type_list ',' type_name
4060 { $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
4061 | array_type_list ',' assignment_expression upupeq assignment_expression
4062 ;
4063
4064upupeq:
4065 '~'
4066 { $$ = OperKinds::LThan; }
4067 | ErangeUpLe
4068 { $$ = OperKinds::LEThan; }
4069 ;
4070
4071multi_array_dimension:
4072 '[' assignment_expression ']'
4073 { $$ = DeclarationNode::newArray( $2, nullptr, false ); }
4074 | '[' '*' ']' // C99
4075 { $$ = DeclarationNode::newVarArray( 0 ); }
4076 | multi_array_dimension '[' assignment_expression ']'
4077 { $$ = $1->addArray( DeclarationNode::newArray( $3, nullptr, false ) ); }
4078 | multi_array_dimension '[' '*' ']' // C99
4079 { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
4080 ;
4081
4082// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
4083// identifier to which the type applies, e.g.:
4084//
4085// int f( int ); // not handled here
4086// int f( int * ); // abstract function-prototype parameter; no parameter name specified
4087// int f( int (*)() ); // abstract function-prototype parameter; no parameter name specified
4088// int f( int (int) ); // abstract function-prototype parameter; no parameter name specified
4089//
4090// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
4091// and functions versus pointers to arrays and functions. In addition, the pattern handles the special meaning of
4092// parenthesis around a typedef name:
4093//
4094// ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
4095// parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
4096// not as redundant parentheses around the identifier."
4097//
4098// For example:
4099//
4100// typedef float T;
4101// int f( int ( T [5] ) ); // see abstract_parameter_declarator
4102// int g( int ( T ( int ) ) ); // see abstract_parameter_declarator
4103// int f( int f1( T a[5] ) ); // see identifier_parameter_declarator
4104// int g( int g1( T g2( int p ) ) ); // see identifier_parameter_declarator
4105//
4106// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
4107// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
4108// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
4109// functions.
4110
4111abstract_parameter_declarator_opt:
4112 // empty
4113 { $$ = nullptr; }
4114 | abstract_parameter_declarator
4115 ;
4116
4117abstract_parameter_declarator:
4118 abstract_parameter_ptr
4119 | '&' MUTEX attribute_list_opt
4120 { $$ = DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
4121 OperKinds::AddressOf )->addQualifiers( $3 ); }
4122 | abstract_parameter_array attribute_list_opt
4123 { $$ = $1->addQualifiers( $2 ); }
4124 | abstract_parameter_function attribute_list_opt
4125 { $$ = $1->addQualifiers( $2 ); }
4126 ;
4127
4128abstract_parameter_ptr:
4129 ptrref_operator attribute_list_opt
4130 { $$ = DeclarationNode::newPointer( nullptr, $1 )->addQualifiers( $2 ); }
4131 | ptrref_operator type_qualifier_list
4132 { $$ = DeclarationNode::newPointer( $2, $1 ); }
4133 | ptrref_operator abstract_parameter_declarator
4134 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4135 | ptrref_operator type_qualifier_list abstract_parameter_declarator
4136 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4137 | '(' abstract_parameter_ptr ')' attribute_list_opt // redundant parenthesis
4138 { $$ = $2->addQualifiers( $4 ); }
4139 ;
4140
4141abstract_parameter_array:
4142 array_parameter_dimension
4143 | '(' abstract_parameter_ptr ')' array_parameter_dimension
4144 { $$ = $2->addArray( $4 ); }
4145 | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
4146 { $$ = $2->addArray( $4 ); }
4147 | '(' abstract_parameter_array ')' // redundant parenthesis
4148 { $$ = $2; }
4149 ;
4150
4151abstract_parameter_function:
4152 '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4153 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
4154 | '(' abstract_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4155 { $$ = $2->addParamList( $5 ); }
4156 | '(' abstract_parameter_function ')' // redundant parenthesis
4157 { $$ = $2; }
4158 ;
4159
4160array_parameter_dimension:
4161 // Only the first dimension can be empty or have qualifiers.
4162 array_parameter_1st_dimension
4163 | array_parameter_1st_dimension multi_array_dimension
4164 { $$ = $1->addArray( $2 ); }
4165 | multi_array_dimension
4166 ;
4167
4168// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
4169//
4170// ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
4171// a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
4172
4173array_parameter_1st_dimension:
4174 '[' ']'
4175 { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
4176 // multi_array_dimension handles the '[' '*' ']' case
4177 | '[' push type_qualifier_list '*' pop ']' // remaining C99
4178 { $$ = DeclarationNode::newVarArray( $3 ); }
4179 | '[' push type_qualifier_list pop ']'
4180 { $$ = DeclarationNode::newArray( nullptr, $3, false ); }
4181 // multi_array_dimension handles the '[' assignment_expression ']' case
4182 | '[' push type_qualifier_list assignment_expression pop ']'
4183 { $$ = DeclarationNode::newArray( $4, $3, false ); }
4184 | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
4185 { $$ = DeclarationNode::newArray( $5, $4, true ); }
4186 | '[' push type_qualifier_list STATIC assignment_expression pop ']'
4187 { $$ = DeclarationNode::newArray( $5, $3, true ); }
4188 ;
4189
4190// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
4191//
4192// struct S {
4193// int;
4194// int *;
4195// int [10];
4196// int (*)();
4197// };
4198
4199variable_abstract_declarator:
4200 variable_abstract_ptr
4201 | variable_abstract_array attribute_list_opt
4202 { $$ = $1->addQualifiers( $2 ); }
4203 | variable_abstract_function attribute_list_opt
4204 { $$ = $1->addQualifiers( $2 ); }
4205 ;
4206
4207variable_abstract_ptr:
4208 ptrref_operator attribute_list_opt
4209 { $$ = DeclarationNode::newPointer( nullptr, $1 )->addQualifiers( $2 ); }
4210 | ptrref_operator type_qualifier_list
4211 { $$ = DeclarationNode::newPointer( $2, $1 ); }
4212 | ptrref_operator variable_abstract_declarator
4213 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4214 | ptrref_operator type_qualifier_list variable_abstract_declarator
4215 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4216 | '(' variable_abstract_ptr ')' attribute_list_opt // redundant parenthesis
4217 { $$ = $2->addQualifiers( $4 ); }
4218 ;
4219
4220variable_abstract_array:
4221 array_dimension
4222 | '(' variable_abstract_ptr ')' array_dimension
4223 { $$ = $2->addArray( $4 ); }
4224 | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
4225 { $$ = $2->addArray( $4 ); }
4226 | '(' variable_abstract_array ')' // redundant parenthesis
4227 { $$ = $2; }
4228 ;
4229
4230variable_abstract_function:
4231 '(' variable_abstract_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4232 { $$ = $2->addParamList( $5 ); }
4233 | '(' variable_abstract_function ')' // redundant parenthesis
4234 { $$ = $2; }
4235 ;
4236
4237// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
4238// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
4239
4240cfa_identifier_parameter_declarator_tuple: // CFA
4241 cfa_identifier_parameter_declarator_no_tuple
4242 | cfa_abstract_tuple
4243 | type_qualifier_list cfa_abstract_tuple
4244 { $$ = $2->addQualifiers( $1 ); }
4245 ;
4246
4247cfa_identifier_parameter_declarator_no_tuple: // CFA
4248 cfa_identifier_parameter_ptr
4249 | cfa_identifier_parameter_array
4250 | type_qualifier_list cfa_identifier_parameter_array
4251 { $$ = $2->addQualifiers( $1 ); }
4252 ;
4253
4254cfa_identifier_parameter_ptr: // CFA
4255 // No SUE declaration in parameter list.
4256 ptrref_operator type_specifier_nobody
4257 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4258 | ptrref_operator attribute_list type_specifier_nobody
4259 { $$ = $3->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) )->addQualifiers( $2 ); }
4260 | type_qualifier_list ptrref_operator type_specifier_nobody
4261 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4262 | ptrref_operator cfa_abstract_function
4263 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4264 | type_qualifier_list ptrref_operator cfa_abstract_function
4265 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4266 | ptrref_operator cfa_identifier_parameter_declarator_tuple
4267 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4268 | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
4269 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4270 ;
4271
4272cfa_identifier_parameter_array: // CFA
4273 // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
4274 // shift/reduce conflict with new-style empty (void) function return type.
4275 '[' ']' type_specifier_nobody
4276 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4277 | '[' ']' cfa_abstract_tuple
4278 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4279 | cfa_array_parameter_1st_dimension type_specifier_nobody
4280 { $$ = $2->addNewArray( $1 ); }
4281 | cfa_array_parameter_1st_dimension cfa_abstract_tuple
4282 { $$ = $2->addNewArray( $1 ); }
4283 | '[' ']' multi_array_dimension type_specifier_nobody
4284 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4285 | '[' ']' multi_array_dimension cfa_abstract_tuple
4286 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4287 | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
4288 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4289 | cfa_array_parameter_1st_dimension multi_array_dimension cfa_abstract_tuple
4290 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4291 | multi_array_dimension type_specifier_nobody
4292 { $$ = $2->addNewArray( $1 ); }
4293 | multi_array_dimension cfa_abstract_tuple
4294 { $$ = $2->addNewArray( $1 ); }
4295
4296 | '[' ']' cfa_identifier_parameter_ptr
4297 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4298 | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
4299 { $$ = $2->addNewArray( $1 ); }
4300 | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
4301 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4302 | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
4303 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4304 | multi_array_dimension cfa_identifier_parameter_ptr
4305 { $$ = $2->addNewArray( $1 ); }
4306 ;
4307
4308cfa_array_parameter_1st_dimension:
4309 '[' type_qualifier_list '*' ']' // remaining C99
4310 { $$ = DeclarationNode::newVarArray( $2 ); }
4311 | '[' type_qualifier_list assignment_expression ']'
4312 { $$ = DeclarationNode::newArray( $3, $2, false ); }
4313 | '[' declaration_qualifier_list assignment_expression ']'
4314 // declaration_qualifier_list must be used because of shift/reduce conflict with
4315 // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
4316 // appear in this context.
4317 { $$ = DeclarationNode::newArray( $3, $2, true ); }
4318 | '[' declaration_qualifier_list type_qualifier_list assignment_expression ']'
4319 { $$ = DeclarationNode::newArray( $4, $3->addQualifiers( $2 ), true ); }
4320 ;
4321
4322// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
4323// identifier to which the type applies, e.g.:
4324//
4325// [int] f( int ); // abstract variable parameter; no parameter name specified
4326// [int] f( [int] (int) ); // abstract function-prototype parameter; no parameter name specified
4327//
4328// These rules need LR(3):
4329//
4330// cfa_abstract_tuple identifier_or_type_name
4331// '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_list_ellipsis_opt ')'
4332//
4333// since a function return type can be syntactically identical to a tuple type:
4334//
4335// [int, int] t;
4336// [int, int] f( int );
4337//
4338// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
4339// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
4340// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
4341// duplicated when appearing with cfa_function_specifier.
4342
4343cfa_abstract_declarator_tuple: // CFA
4344 cfa_abstract_tuple
4345 | type_qualifier_list cfa_abstract_tuple
4346 { $$ = $2->addQualifiers( $1 ); }
4347 | cfa_abstract_declarator_no_tuple
4348 ;
4349
4350cfa_abstract_declarator_no_tuple: // CFA
4351 cfa_abstract_ptr
4352 | cfa_abstract_array
4353 ;
4354
4355cfa_abstract_ptr: // CFA
4356 ptrref_operator type_specifier
4357 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4358 | ptrref_operator attribute_list type_specifier
4359 { $$ = $3->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) )->addQualifiers( $2 ); }
4360 | type_qualifier_list ptrref_operator type_specifier
4361 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4362 | ptrref_operator cfa_abstract_function
4363 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4364 | type_qualifier_list ptrref_operator cfa_abstract_function
4365 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4366 | ptrref_operator cfa_abstract_declarator_tuple
4367 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4368 | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
4369 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4370 ;
4371
4372cfa_abstract_array: // CFA
4373 // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
4374 // empty (void) function return type.
4375 '[' ']' type_specifier
4376 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4377 | '[' ']' multi_array_dimension type_specifier
4378 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4379 | multi_array_dimension type_specifier
4380 { $$ = $2->addNewArray( $1 ); }
4381 | '[' ']' cfa_abstract_ptr
4382 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4383 | '[' ']' multi_array_dimension cfa_abstract_ptr
4384 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4385 | multi_array_dimension cfa_abstract_ptr
4386 { $$ = $2->addNewArray( $1 ); }
4387 ;
4388
4389cfa_abstract_tuple: // CFA
4390 '[' cfa_abstract_parameter_list ']'
4391 { $$ = DeclarationNode::newTuple( $2 ); }
4392 | '[' type_specifier_nobody ELLIPSIS ']'
4393 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4394 | '[' type_specifier_nobody ELLIPSIS constant_expression ']'
4395 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4396 ;
4397
4398cfa_abstract_function: // CFA
4399 '[' ']' '(' cfa_parameter_list_ellipsis_opt ')'
4400 { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
4401 | cfa_abstract_tuple '(' push cfa_parameter_list_ellipsis_opt pop ')'
4402 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4403 | cfa_function_return '(' push cfa_parameter_list_ellipsis_opt pop ')'
4404 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4405 ;
4406
4407// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
4408// each declaration, and in the specifier-qualifier list in each structure declaration and type name."
4409//
4410// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
4411// the declaration specifiers in a declaration is an obsolescent feature."
4412//
4413// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
4414// prototype-format parameter type declarators) is an obsolescent feature."
4415//
4416// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
4417// declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
4418
4419// ************************ MISCELLANEOUS ********************************
4420
4421comma_opt: // redundant comma
4422 // empty
4423 | ','
4424 ;
4425
4426default_initializer_opt:
4427 // empty
4428 { $$ = nullptr; }
4429 | '=' assignment_expression
4430 { $$ = $2; }
4431 ;
4432
4433%%
4434
4435// ----end of grammar----
4436
4437// Local Variables: //
4438// mode: c++ //
4439// tab-width: 4 //
4440// compile-command: "bison -Wcounterexamples parser.yy" //
4441// End: //
Note: See TracBrowser for help on using the repository browser.