source: src/Parser/parser.yy@ 91aa5ab

ADT arm-eh ast-experimental enum forall-pointer-decay jacob/cs343-translation new-ast-unique-expr pthread-emulation qualifiedEnum
Last change on this file since 91aa5ab was a025ea8, checked in by Peter A. Buhr <pabuhr@…>, 5 years ago

add maybe_build_compound to always build a compound statement for control structures with a single statement
  • Property mode set to 100644
File size: 136.6 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author : Peter A. Buhr
10// Created On : Sat Sep 1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Sat Oct 24 08:21:14 2020
13// Update Count : 4624
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS. While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks. Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// 1. designation with '=' (use ':' instead)
29//
30// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32//
33// 1. designation with and without '=' (use ':' instead)
34// 2. attributes not allowed in parenthesis of declarator
35//
36// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40// grammar rule.
41
42%{
43#define YYDEBUG_LEXER_TEXT (yylval) // lexer loads this up each time
44#define YYDEBUG 1 // get the pretty debugging code to compile
45#define YYERROR_VERBOSE // more information in syntax errors
46
47#undef __GNUC_MINOR__
48
49#include <cstdio>
50#include <stack>
51using namespace std;
52
53#include "SynTree/Declaration.h"
54#include "ParseNode.h"
55#include "TypedefTable.h"
56#include "TypeData.h"
57#include "SynTree/LinkageSpec.h"
58#include "Common/SemanticError.h" // error_str
59#include "Common/utility.h" // for maybeMoveBuild, maybeBuild, CodeLo...
60
61extern DeclarationNode * parseTree;
62extern LinkageSpec::Spec linkage;
63extern TypedefTable typedefTable;
64
65stack< LinkageSpec::Spec > linkageStack;
66
67bool appendStr( string & to, string & from ) {
68 // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
69 // "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
70 // the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
71 // easier to let the C compiler handle this case.
72 //
73 // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
74 // without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
75 // i.e., u"a" U"b" L"c" is disallowed.
76
77 if ( from[0] != '"' ) { // encoding ?
78 if ( to[0] != '"' ) { // encoding ?
79 if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
80 yyerror( "non-matching string encodings for string-literal concatenation" );
81 return false; // parse error, must call YYERROR in action
82 } else if ( from[1] == '8' ) {
83 from.erase( 0, 1 ); // remove 2nd encoding
84 } // if
85 } else {
86 if ( from[1] == '8' ) { // move encoding to start
87 to = "u8" + to;
88 from.erase( 0, 1 ); // remove 2nd encoding
89 } else {
90 to = from[0] + to;
91 } // if
92 } // if
93 from.erase( 0, 1 ); // remove 2nd encoding
94 } // if
95 to += " " + from; // concatenated into single string
96 return true;
97} // appendStr
98
99DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
100 // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
101 DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
102 for ( cur = dynamic_cast<DeclarationNode *>( cur->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode *>( cur->get_next() ) ) {
103 cl->cloneBaseType( cur );
104 } // for
105 declList->addType( cl );
106 return declList;
107} // distAttr
108
109void distExt( DeclarationNode * declaration ) {
110 // distribute EXTENSION across all declarations
111 for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
112 iter->set_extension( true );
113 } // for
114} // distExt
115
116void distInl( DeclarationNode * declaration ) {
117 // distribute EXTENSION across all declarations
118 for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
119 iter->set_inLine( true );
120 } // for
121} // distInl
122
123void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
124 // distribute qualifiers across all non-variable declarations in a distribution statemement
125 for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
126 // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
127 // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
128 // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
129 // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
130 DeclarationNode * clone = qualifiers->clone();
131 if ( qualifiers->type ) { // forall clause ? (handles SC)
132 if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
133 swap( clone->type->forall, iter->type->aggregate.params );
134 iter->addQualifiers( clone );
135 } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
136 // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
137 DeclarationNode newnode;
138 swap( newnode.type, iter->type->aggInst.aggregate );
139 swap( clone->type->forall, newnode.type->aggregate.params );
140 newnode.addQualifiers( clone );
141 swap( newnode.type, iter->type->aggInst.aggregate );
142 } else if ( iter->type->kind == TypeData::Function ) { // routines ?
143 swap( clone->type->forall, iter->type->forall );
144 iter->addQualifiers( clone );
145 } // if
146 } else { // just SC qualifiers
147 iter->addQualifiers( clone );
148 } // if
149 } // for
150 delete qualifiers;
151} // distQual
152
153// There is an ambiguity for inline generic-routine return-types and generic routines.
154// forall( otype T ) struct S { int i; } bar( T ) {}
155// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
156// forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
157// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
158// forall( otype T ) struct S { int T; };
159// forall( otype W ) bar( W ) {}
160
161void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
162 if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
163 funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
164 declSpec->type->aggregate.params = nullptr;
165 } // if
166} // rebindForall
167
168string * build_postfix_name( string * name ) {
169 *name = string("__postfix_func_") + *name;
170 return name;
171} // build_postfix_name
172
173DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
174 if ( ! fieldList ) { // field declarator ?
175 if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate || typeSpec->type->kind == TypeData::Enum) ) ) {
176 stringstream ss;
177 typeSpec->type->print( ss );
178 SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
179 return nullptr;
180 } // if
181 fieldList = DeclarationNode::newName( nullptr );
182 } // if
183 return distAttr( typeSpec, fieldList ); // mark all fields in list
184} // fieldDecl
185
186ForCtrl * forCtrl( ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
187 ConstantExpr * constant = dynamic_cast<ConstantExpr *>(type->expr.get());
188 if ( constant && (constant->get_constant()->get_value() == "0" || constant->get_constant()->get_value() == "1") ) {
189 type = new ExpressionNode( new CastExpr( maybeMoveBuild< Expression >(type), new BasicType( Type::Qualifiers(), BasicType::SignedInt ) ) );
190 } // if
191 return new ForCtrl(
192 distAttr( DeclarationNode::newTypeof( type, true ), DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) ) ),
193 // NULL comp/inc => leave blank
194 comp ? new ExpressionNode( build_binary_val( compop, new ExpressionNode( build_varref( new string( *index ) ) ), comp ) ) : 0,
195 inc ? new ExpressionNode( build_binary_val( compop == OperKinds::LThan || compop == OperKinds::LEThan ? // choose += or -= for upto/downto
196 OperKinds::PlusAssn : OperKinds::MinusAssn, new ExpressionNode( build_varref( new string( *index ) ) ), inc ) ) : 0 );
197} // forCtrl
198
199ForCtrl * forCtrl( ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
200 if ( NameExpr * identifier = dynamic_cast<NameExpr *>(index->expr.get()) ) {
201 return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
202 } else if ( CommaExpr * commaExpr = dynamic_cast<CommaExpr *>(index->expr.get()) ) {
203 if ( NameExpr * identifier = dynamic_cast<NameExpr *>(commaExpr->arg1 ) ) {
204 return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
205 } else {
206 SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed." ); return nullptr;
207 } // if
208 } else {
209 SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed." ); return nullptr;
210 } // if
211} // forCtrl
212
213bool forall = false, yyy = false; // aggregate have one or more forall qualifiers ?
214
215// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
216#define YYLLOC_DEFAULT(Cur, Rhs, N) \
217if ( N ) { \
218 (Cur).first_line = YYRHSLOC( Rhs, 1 ).first_line; \
219 (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column; \
220 (Cur).last_line = YYRHSLOC( Rhs, N ).last_line; \
221 (Cur).last_column = YYRHSLOC( Rhs, N ).last_column; \
222 (Cur).filename = YYRHSLOC( Rhs, 1 ).filename; \
223} else { \
224 (Cur).first_line = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line; \
225 (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column; \
226 (Cur).filename = YYRHSLOC( Rhs, 0 ).filename; \
227}
228%}
229
230%define parse.error verbose
231
232// Types declaration for productions
233%union {
234 Token tok;
235 ParseNode * pn;
236 ExpressionNode * en;
237 DeclarationNode * decl;
238 AggregateDecl::Aggregate aggKey;
239 TypeDecl::Kind tclass;
240 StatementNode * sn;
241 WaitForStmt * wfs;
242 Expression * constant;
243 IfCtrl * ifctl;
244 ForCtrl * fctl;
245 enum OperKinds compop;
246 LabelNode * label;
247 InitializerNode * in;
248 OperKinds op;
249 std::string * str;
250 bool flag;
251 CatchStmt::Kind catch_kind;
252 GenericExpr * genexpr;
253}
254
255//************************* TERMINAL TOKENS ********************************
256
257// keywords
258%token TYPEDEF
259%token EXTERN STATIC AUTO REGISTER
260%token THREADLOCAL // C11
261%token INLINE FORTRAN // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
262%token NORETURN // C11
263%token CONST VOLATILE
264%token RESTRICT // C99
265%token ATOMIC // C11
266%token FORALL MUTEX VIRTUAL COERCE // CFA
267%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
268%token BOOL COMPLEX IMAGINARY // C99
269%token INT128 UINT128 uuFLOAT80 uuFLOAT128 // GCC
270%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
271%token ZERO_T ONE_T // CFA
272%token VALIST // GCC
273%token AUTO_TYPE // GCC
274%token TYPEOF BASETYPEOF LABEL // GCC
275%token ENUM STRUCT UNION
276%token EXCEPTION // CFA
277%token GENERATOR COROUTINE MONITOR THREAD // CFA
278%token OTYPE FTYPE DTYPE TTYPE TRAIT // CFA
279%token SIZEOF OFFSETOF
280// %token RESUME // CFA
281%token SUSPEND // CFA
282%token ATTRIBUTE EXTENSION // GCC
283%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
284%token CHOOSE DISABLE ENABLE FALLTHRU FALLTHROUGH TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT WITH WHEN WAITFOR // CFA
285%token ASM // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
286%token ALIGNAS ALIGNOF GENERIC STATICASSERT // C11
287
288// names and constants: lexer differentiates between identifier and typedef names
289%token<tok> IDENTIFIER QUOTED_IDENTIFIER TYPEDEFname TYPEGENname
290%token<tok> TIMEOUT WOR
291%token<tok> INTEGERconstant CHARACTERconstant STRINGliteral
292%token<tok> DIRECTIVE
293// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
294// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
295// converted into the tuple index (.)(1). e.g., 3.x
296%token<tok> FLOATING_DECIMALconstant FLOATING_FRACTIONconstant FLOATINGconstant
297
298// multi-character operators
299%token ARROW // ->
300%token ICR DECR // ++ --
301%token LS RS // << >>
302%token LE GE EQ NE // <= >= == !=
303%token ANDAND OROR // && ||
304%token ELLIPSIS // ...
305
306%token EXPassign MULTassign DIVassign MODassign // \= *= /= %=
307%token PLUSassign MINUSassign // += -=
308%token LSassign RSassign // <<= >>=
309%token ANDassign ERassign ORassign // &= ^= |=
310
311%token ErangeUpEq ErangeDown ErangeDownEq // ~= -~ -~=
312%token ATassign // @=
313
314%type<tok> identifier
315%type<tok> identifier_or_type_name attr_name
316%type<tok> quasi_keyword
317%type<constant> string_literal
318%type<str> string_literal_list
319
320// expressions
321%type<en> constant
322%type<en> tuple tuple_expression_list
323%type<op> ptrref_operator unary_operator assignment_operator
324%type<en> primary_expression postfix_expression unary_expression
325%type<en> cast_expression_list cast_expression exponential_expression multiplicative_expression additive_expression
326%type<en> shift_expression relational_expression equality_expression
327%type<en> AND_expression exclusive_OR_expression inclusive_OR_expression
328%type<en> logical_AND_expression logical_OR_expression
329%type<en> conditional_expression constant_expression assignment_expression assignment_expression_opt
330%type<en> comma_expression comma_expression_opt
331%type<en> argument_expression_list_opt argument_expression default_initialize_opt
332%type<ifctl> if_control_expression
333%type<fctl> for_control_expression for_control_expression_list
334%type<compop> inclexcl
335%type<en> subrange
336%type<decl> asm_name_opt
337%type<en> asm_operands_opt asm_operands_list asm_operand
338%type<label> label_list
339%type<en> asm_clobbers_list_opt
340%type<flag> asm_volatile_opt
341%type<en> handler_predicate_opt
342%type<genexpr> generic_association generic_assoc_list
343
344// statements
345%type<sn> statement labeled_statement compound_statement
346%type<sn> statement_decl statement_decl_list statement_list_nodecl
347%type<sn> selection_statement if_statement
348%type<sn> switch_clause_list_opt switch_clause_list
349%type<en> case_value
350%type<sn> case_clause case_value_list case_label case_label_list
351%type<sn> iteration_statement jump_statement
352%type<sn> expression_statement asm_statement
353%type<sn> with_statement
354%type<en> with_clause_opt
355%type<sn> exception_statement handler_clause finally_clause
356%type<catch_kind> handler_key
357%type<sn> mutex_statement
358%type<en> when_clause when_clause_opt waitfor timeout
359%type<sn> waitfor_statement
360%type<wfs> waitfor_clause
361
362// declarations
363%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
364%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
365%type<decl> abstract_parameter_declaration
366
367%type<aggKey> aggregate_key aggregate_data aggregate_control
368%type<decl> aggregate_type aggregate_type_nobody
369
370%type<decl> assertion assertion_list assertion_list_opt
371
372%type<en> bit_subrange_size_opt bit_subrange_size
373
374%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
375
376%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
377
378%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
379%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
380
381%type<decl> elaborated_type elaborated_type_nobody
382
383%type<decl> enumerator_list enum_type enum_type_nobody
384%type<en> enumerator_value_opt
385
386%type<decl> external_definition external_definition_list external_definition_list_opt
387
388%type<decl> exception_declaration
389
390%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
391%type<en> field field_name_list field_name fraction_constants_opt
392
393%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
394
395%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
396%type<decl> identifier_list
397
398%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
399%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
400%type<decl> cfa_abstract_ptr cfa_abstract_tuple
401
402%type<decl> cfa_array_parameter_1st_dimension
403
404%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
405%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
406
407%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
408%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
409
410%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
411
412%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
413
414%type<decl> c_declaration static_assert
415%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
416%type<decl> KR_parameter_list KR_parameter_list_opt
417
418%type<decl> parameter_declaration parameter_list parameter_type_list_opt
419
420%type<decl> paren_identifier paren_type
421
422%type<decl> storage_class storage_class_list
423
424%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
425
426%type<tclass> type_class
427%type<decl> type_declarator type_declarator_name type_declaring_list
428
429%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
430%type<decl> typedef typedef_declaration typedef_expression
431
432%type<decl> variable_type_redeclarator type_ptr type_array type_function
433
434%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
435
436%type<decl> type type_no_function
437%type<decl> type_parameter type_parameter_list type_initializer_opt
438
439%type<en> type_parameters_opt type_list
440
441%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
442%type<decl> type_specifier type_specifier_nobody
443
444%type<decl> variable_declarator variable_ptr variable_array variable_function
445%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
446
447%type<decl> attribute_list_opt attribute_list attribute_name_list attribute attribute_name
448
449// initializers
450%type<in> initializer initializer_list_opt initializer_opt
451
452// designators
453%type<en> designator designator_list designation
454
455
456// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
457// .---------. matches IF '(' comma_expression ')' statement . (reduce)
458// if ( C ) S1 else S2
459// `-----------------' matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
460// Similar issues exit with the waitfor statement.
461
462// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
463// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
464%precedence THEN // rule precedence for IF/WAITFOR statement
465%precedence WOR // token precedence for start of WOR in WAITFOR statement
466%precedence TIMEOUT // token precedence for start of TIMEOUT in WAITFOR statement
467%precedence ELSE // token precedence for start of else clause in IF/WAITFOR statement
468
469// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
470// forall( otype T ) struct Foo { T v; };
471// .-----. matches pointer to function returning a generic (which is impossible without a type)
472// Foo ( *fp )( int );
473// `---' matches start of TYPEGENname '('
474// must be:
475// Foo( int ) ( *fp )( int );
476// The same problem occurs here:
477// forall( otype T ) struct Foo { T v; } ( *fp )( int );
478// must be:
479// forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
480
481// Order of these lines matters (low-to-high precedence).
482%precedence TYPEGENname
483%precedence '}'
484%precedence '('
485
486// %precedence RESUME
487// %precedence '{'
488// %precedence ')'
489
490%locations // support location tracking for error messages
491
492%start translation_unit // parse-tree root
493
494%%
495//************************* Namespace Management ********************************
496
497// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
498// which are lexically identical.
499//
500// typedef int foo; // identifier foo must now be scanned as TYPEDEFname
501// foo f; // to allow it to appear in this context
502//
503// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
504// between syntactic and semantic constructs. Cforall compounds this problem by introducing type names local to the
505// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
506// generators" -- parameterized types. This latter type name creates a third class of identifiers, "TYPEGENname", which
507// must be distinguished by the lexical scanner.
508//
509// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
510// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
511// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
512// each context that introduces a name scope, a new level is created in the type table and that level is popped on
513// exiting the scope. Since type names can be local to a particular declaration, each declaration is itself a scope.
514// This requires distinguishing between type names that are local to the current declaration scope and those that
515// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
516//
517// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
518// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
519// around the list separator.
520//
521// int f( forall(T) T (*f1) T , forall( S ) S (*f2)( S ) );
522// push pop push pop
523
524push:
525 { typedefTable.enterScope(); }
526 ;
527
528pop:
529 { typedefTable.leaveScope(); }
530 ;
531
532//************************* CONSTANTS ********************************
533
534constant:
535 // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
536 INTEGERconstant { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
537 | FLOATING_DECIMALconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
538 | FLOATING_FRACTIONconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
539 | FLOATINGconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
540 | CHARACTERconstant { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
541 ;
542
543quasi_keyword: // CFA
544 TIMEOUT
545 | WOR
546 ;
547
548identifier:
549 IDENTIFIER
550 | quasi_keyword
551 | '@' // CFA
552 { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
553 ;
554
555string_literal:
556 string_literal_list { $$ = build_constantStr( *$1 ); }
557 ;
558
559string_literal_list: // juxtaposed strings are concatenated
560 STRINGliteral { $$ = $1; } // conversion from tok to str
561 | string_literal_list STRINGliteral
562 {
563 if ( ! appendStr( *$1, *$2 ) ) YYERROR; // append 2nd juxtaposed string to 1st
564 delete $2; // allocated by lexer
565 $$ = $1; // conversion from tok to str
566 }
567 ;
568
569//************************* EXPRESSIONS ********************************
570
571primary_expression:
572 IDENTIFIER // typedef name cannot be used as a variable name
573 { $$ = new ExpressionNode( build_varref( $1 ) ); }
574 | quasi_keyword
575 { $$ = new ExpressionNode( build_varref( $1 ) ); }
576 | tuple
577 | '(' comma_expression ')'
578 { $$ = $2; }
579 | '(' compound_statement ')' // GCC, lambda expression
580 { $$ = new ExpressionNode( new StmtExpr( dynamic_cast< CompoundStmt * >(maybeMoveBuild< Statement >($2) ) ) ); }
581 | type_name '.' identifier // CFA, nested type
582 { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
583 | type_name '.' '[' field_name_list ']' // CFA, nested type / tuple field selector
584 { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
585 | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
586 {
587 // add the missing control expression to the GenericExpr and return it
588 $5->control = maybeMoveBuild<Expression>( $3 );
589 $$ = new ExpressionNode( $5 );
590 }
591 // | RESUME '(' comma_expression ')'
592 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
593 // | RESUME '(' comma_expression ')' compound_statement
594 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
595 ;
596
597generic_assoc_list: // C11
598 generic_association
599 | generic_assoc_list ',' generic_association
600 {
601 // steal the association node from the singleton and delete the wrapper
602 $1->associations.splice($1->associations.end(), $3->associations);
603 delete $3;
604 $$ = $1;
605 }
606 ;
607
608generic_association: // C11
609 type_no_function ':' assignment_expression
610 {
611 // create a GenericExpr wrapper with one association pair
612 $$ = new GenericExpr( nullptr, { { maybeMoveBuildType($1), maybeMoveBuild<Expression>($3) } } );
613 }
614 | DEFAULT ':' assignment_expression
615 { $$ = new GenericExpr( nullptr, { { maybeMoveBuild<Expression>($3) } } ); }
616 ;
617
618postfix_expression:
619 primary_expression
620 | postfix_expression '[' assignment_expression ']'
621 // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
622 // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
623 // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
624 // equivalent to the old x[i,j].
625 { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
626 | postfix_expression '{' argument_expression_list_opt '}' // CFA, constructor call
627 {
628 Token fn;
629 fn.str = new std::string( "?{}" ); // location undefined - use location of '{'?
630 $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
631 }
632 | postfix_expression '(' argument_expression_list_opt ')'
633 { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
634 | postfix_expression '`' identifier // CFA, postfix call
635 { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
636 | constant '`' identifier // CFA, postfix call
637 { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
638 | string_literal '`' identifier // CFA, postfix call
639 { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), new ExpressionNode( $1 ) ) ); }
640 | postfix_expression '.' identifier
641 { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
642 | postfix_expression '.' INTEGERconstant // CFA, tuple index
643 { $$ = new ExpressionNode( build_fieldSel( $1, build_constantInteger( *$3 ) ) ); }
644 | postfix_expression FLOATING_FRACTIONconstant // CFA, tuple index
645 { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
646 | postfix_expression '.' '[' field_name_list ']' // CFA, tuple field selector
647 { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
648 | postfix_expression '.' aggregate_control
649 { $$ = new ExpressionNode( build_keyword_cast( $3, $1 ) ); }
650 | postfix_expression ARROW identifier
651 { $$ = new ExpressionNode( build_pfieldSel( $1, build_varref( $3 ) ) ); }
652 | postfix_expression ARROW INTEGERconstant // CFA, tuple index
653 { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
654 | postfix_expression ARROW '[' field_name_list ']' // CFA, tuple field selector
655 { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
656 | postfix_expression ICR
657 { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
658 | postfix_expression DECR
659 { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
660 | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
661 { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
662 | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
663 { $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
664 | '^' primary_expression '{' argument_expression_list_opt '}' // CFA, destructor call
665 {
666 Token fn;
667 fn.str = new string( "^?{}" ); // location undefined
668 $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
669 }
670 ;
671
672argument_expression_list_opt:
673 // empty
674 { $$ = nullptr; }
675 | argument_expression
676 | argument_expression_list_opt ',' argument_expression
677 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
678 ;
679
680argument_expression:
681 '@' // CFA, default parameter
682 { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
683 // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
684 | assignment_expression
685 ;
686
687field_name_list: // CFA, tuple field selector
688 field
689 | field_name_list ',' field { $$ = (ExpressionNode *)($1->set_last( $3 )); }
690 ;
691
692field: // CFA, tuple field selector
693 field_name
694 | FLOATING_DECIMALconstant field
695 { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
696 | FLOATING_DECIMALconstant '[' field_name_list ']'
697 { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $3 ) ) ); }
698 | field_name '.' field
699 { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
700 | field_name '.' '[' field_name_list ']'
701 { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
702 | field_name ARROW field
703 { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
704 | field_name ARROW '[' field_name_list ']'
705 { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
706 ;
707
708field_name:
709 INTEGERconstant fraction_constants_opt
710 { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
711 | FLOATINGconstant fraction_constants_opt
712 { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
713 | identifier fraction_constants_opt
714 {
715 $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
716 }
717 ;
718
719fraction_constants_opt:
720 // empty
721 { $$ = nullptr; }
722 | fraction_constants_opt FLOATING_FRACTIONconstant
723 {
724 Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
725 $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1, constant ) ) : new ExpressionNode( constant );
726 }
727 ;
728
729unary_expression:
730 postfix_expression
731 // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
732 // semantics checks, e.g., ++3, 3--, *3, &&3
733 | constant
734 | string_literal
735 { $$ = new ExpressionNode( $1 ); }
736 | EXTENSION cast_expression // GCC
737 { $$ = $2->set_extension( true ); }
738 // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
739 // { * X; } // dereference X
740 // { * int X; } // CFA declaration of pointer to int
741 | ptrref_operator cast_expression // CFA
742 {
743 switch ( $1 ) {
744 case OperKinds::AddressOf:
745 $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) );
746 break;
747 case OperKinds::PointTo:
748 $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
749 break;
750 case OperKinds::And:
751 $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) ) );
752 break;
753 default:
754 assert( false );
755 }
756 }
757 | unary_operator cast_expression
758 { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
759 | ICR unary_expression
760 { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
761 | DECR unary_expression
762 { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
763 | SIZEOF unary_expression
764 { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
765 | SIZEOF '(' type_no_function ')'
766 { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
767 | ALIGNOF unary_expression // GCC, variable alignment
768 { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
769 | ALIGNOF '(' type_no_function ')' // GCC, type alignment
770 { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
771 | OFFSETOF '(' type_no_function ',' identifier ')'
772 { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
773 ;
774
775ptrref_operator:
776 '*' { $$ = OperKinds::PointTo; }
777 | '&' { $$ = OperKinds::AddressOf; }
778 // GCC, address of label must be handled by semantic check for ref,ref,label
779 | ANDAND { $$ = OperKinds::And; }
780 ;
781
782unary_operator:
783 '+' { $$ = OperKinds::UnPlus; }
784 | '-' { $$ = OperKinds::UnMinus; }
785 | '!' { $$ = OperKinds::Neg; }
786 | '~' { $$ = OperKinds::BitNeg; }
787 ;
788
789cast_expression:
790 unary_expression
791 | '(' type_no_function ')' cast_expression
792 { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
793 | '(' aggregate_control '&' ')' cast_expression // CFA
794 { $$ = new ExpressionNode( build_keyword_cast( $2, $5 ) ); }
795 | '(' VIRTUAL ')' cast_expression // CFA
796 { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $4 ), maybeMoveBuildType( nullptr ) ) ); }
797 | '(' VIRTUAL type_no_function ')' cast_expression // CFA
798 { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $5 ), maybeMoveBuildType( $3 ) ) ); }
799 | '(' RETURN type_no_function ')' cast_expression // CFA
800 { SemanticError( yylloc, "Return cast is currently unimplemented." ); $$ = nullptr; }
801 | '(' COERCE type_no_function ')' cast_expression // CFA
802 { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
803 | '(' qualifier_cast_list ')' cast_expression // CFA
804 { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
805// | '(' type_no_function ')' tuple
806// { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
807 ;
808
809qualifier_cast_list:
810 cast_modifier type_qualifier_name
811 | cast_modifier MUTEX
812 | qualifier_cast_list cast_modifier type_qualifier_name
813 | qualifier_cast_list cast_modifier MUTEX
814 ;
815
816cast_modifier:
817 '-'
818 | '+'
819 ;
820
821exponential_expression:
822 cast_expression
823 | exponential_expression '\\' cast_expression
824 { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
825 ;
826
827multiplicative_expression:
828 exponential_expression
829 | multiplicative_expression '*' exponential_expression
830 { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
831 | multiplicative_expression '/' exponential_expression
832 { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
833 | multiplicative_expression '%' exponential_expression
834 { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
835 ;
836
837additive_expression:
838 multiplicative_expression
839 | additive_expression '+' multiplicative_expression
840 { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
841 | additive_expression '-' multiplicative_expression
842 { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
843 ;
844
845shift_expression:
846 additive_expression
847 | shift_expression LS additive_expression
848 { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
849 | shift_expression RS additive_expression
850 { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
851 ;
852
853relational_expression:
854 shift_expression
855 | relational_expression '<' shift_expression
856 { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
857 | relational_expression '>' shift_expression
858 { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
859 | relational_expression LE shift_expression
860 { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
861 | relational_expression GE shift_expression
862 { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
863 ;
864
865equality_expression:
866 relational_expression
867 | equality_expression EQ relational_expression
868 { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
869 | equality_expression NE relational_expression
870 { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
871 ;
872
873AND_expression:
874 equality_expression
875 | AND_expression '&' equality_expression
876 { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
877 ;
878
879exclusive_OR_expression:
880 AND_expression
881 | exclusive_OR_expression '^' AND_expression
882 { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
883 ;
884
885inclusive_OR_expression:
886 exclusive_OR_expression
887 | inclusive_OR_expression '|' exclusive_OR_expression
888 { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
889 ;
890
891logical_AND_expression:
892 inclusive_OR_expression
893 | logical_AND_expression ANDAND inclusive_OR_expression
894 { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
895 ;
896
897logical_OR_expression:
898 logical_AND_expression
899 | logical_OR_expression OROR logical_AND_expression
900 { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
901 ;
902
903conditional_expression:
904 logical_OR_expression
905 | logical_OR_expression '?' comma_expression ':' conditional_expression
906 { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
907 // FIX ME: computes $1 twice
908 | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
909 { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
910 ;
911
912constant_expression:
913 conditional_expression
914 ;
915
916assignment_expression:
917 // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
918 conditional_expression
919 | unary_expression assignment_operator assignment_expression
920 {
921// if ( $2 == OperKinds::AtAssn ) {
922// SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
923// } else {
924 $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) );
925// } // if
926 }
927 | unary_expression '=' '{' initializer_list_opt comma_opt '}'
928 { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
929 ;
930
931assignment_expression_opt:
932 // empty
933 { $$ = nullptr; }
934 | assignment_expression
935 ;
936
937assignment_operator:
938 '=' { $$ = OperKinds::Assign; }
939 | ATassign { $$ = OperKinds::AtAssn; }
940 | EXPassign { $$ = OperKinds::ExpAssn; }
941 | MULTassign { $$ = OperKinds::MulAssn; }
942 | DIVassign { $$ = OperKinds::DivAssn; }
943 | MODassign { $$ = OperKinds::ModAssn; }
944 | PLUSassign { $$ = OperKinds::PlusAssn; }
945 | MINUSassign { $$ = OperKinds::MinusAssn; }
946 | LSassign { $$ = OperKinds::LSAssn; }
947 | RSassign { $$ = OperKinds::RSAssn; }
948 | ANDassign { $$ = OperKinds::AndAssn; }
949 | ERassign { $$ = OperKinds::ERAssn; }
950 | ORassign { $$ = OperKinds::OrAssn; }
951 ;
952
953tuple: // CFA, tuple
954 // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
955 // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
956// '[' ']'
957// { $$ = new ExpressionNode( build_tuple() ); }
958// | '[' push assignment_expression pop ']'
959// { $$ = new ExpressionNode( build_tuple( $3 ) ); }
960 '[' ',' tuple_expression_list ']'
961 { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
962 | '[' push assignment_expression pop ',' tuple_expression_list ']'
963 { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)($3->set_last( $6 ) ) )); }
964 ;
965
966tuple_expression_list:
967 assignment_expression
968 | '@' // CFA
969 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
970 | tuple_expression_list ',' assignment_expression
971 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
972 | tuple_expression_list ',' '@'
973 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
974 ;
975
976comma_expression:
977 assignment_expression
978 | comma_expression ',' assignment_expression
979 { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
980 ;
981
982comma_expression_opt:
983 // empty
984 { $$ = nullptr; }
985 | comma_expression
986 ;
987
988//*************************** STATEMENTS *******************************
989
990statement:
991 labeled_statement
992 | compound_statement
993 | expression_statement
994 | selection_statement
995 | iteration_statement
996 | jump_statement
997 | with_statement
998 | mutex_statement
999 | waitfor_statement
1000 | exception_statement
1001 | enable_disable_statement
1002 { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1003 | asm_statement
1004 | DIRECTIVE
1005 { $$ = new StatementNode( build_directive( $1 ) ); }
1006 ;
1007
1008labeled_statement:
1009 // labels cannot be identifiers 0 or 1
1010 identifier_or_type_name ':' attribute_list_opt statement
1011 { $$ = $4->add_label( $1, $3 ); }
1012 ;
1013
1014compound_statement:
1015 '{' '}'
1016 { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
1017 | '{' push
1018 local_label_declaration_opt // GCC, local labels
1019 statement_decl_list // C99, intermix declarations and statements
1020 pop '}'
1021 { $$ = new StatementNode( build_compound( $4 ) ); }
1022 ;
1023
1024statement_decl_list: // C99
1025 statement_decl
1026 | statement_decl_list statement_decl
1027 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1028 ;
1029
1030statement_decl:
1031 declaration // CFA, new & old style declarations
1032 { $$ = new StatementNode( $1 ); }
1033 | EXTENSION declaration // GCC
1034 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1035 | function_definition
1036 { $$ = new StatementNode( $1 ); }
1037 | EXTENSION function_definition // GCC
1038 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1039 | statement
1040 ;
1041
1042statement_list_nodecl:
1043 statement
1044 | statement_list_nodecl statement
1045 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1046 ;
1047
1048expression_statement:
1049 comma_expression_opt ';'
1050 { $$ = new StatementNode( build_expr( $1 ) ); }
1051 ;
1052
1053selection_statement:
1054 // pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1055 // the inherent S/R conflict with THEN/ELSE.
1056 push if_statement pop
1057 { $$ = $2; }
1058 | SWITCH '(' comma_expression ')' case_clause
1059 { $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
1060 | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1061 {
1062 StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
1063 // The semantics of the declaration list is changed to include associated initialization, which is performed
1064 // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1065 // statement around the switch. Statements after the initial declaration list can never be executed, and
1066 // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1067 // statement.
1068 $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1069 }
1070 | CHOOSE '(' comma_expression ')' case_clause // CFA
1071 { $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
1072 | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1073 {
1074 StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
1075 $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1076 }
1077 ;
1078
1079if_statement:
1080 IF '(' if_control_expression ')' statement %prec THEN
1081 // explicitly deal with the shift/reduce conflict on if/else
1082 { $$ = new StatementNode( build_if( $3, maybe_build_compound( $5 ), nullptr ) ); }
1083 | IF '(' if_control_expression ')' statement ELSE statement
1084 { $$ = new StatementNode( build_if( $3, maybe_build_compound( $5 ), maybe_build_compound( $7 ) ) ); }
1085 ;
1086
1087if_control_expression:
1088 comma_expression
1089 { $$ = new IfCtrl( nullptr, $1 ); }
1090 | c_declaration // no semi-colon
1091 { $$ = new IfCtrl( $1, nullptr ); }
1092 | cfa_declaration // no semi-colon
1093 { $$ = new IfCtrl( $1, nullptr ); }
1094 | declaration comma_expression // semi-colon separated
1095 { $$ = new IfCtrl( $1, $2 ); }
1096 ;
1097
1098// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1099// clause allows a list of values and subranges.
1100
1101case_value: // CFA
1102 constant_expression { $$ = $1; }
1103 | constant_expression ELLIPSIS constant_expression // GCC, subrange
1104 { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
1105 | subrange // CFA, subrange
1106 ;
1107
1108case_value_list: // CFA
1109 case_value { $$ = new StatementNode( build_case( $1 ) ); }
1110 // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1111 | case_value_list ',' case_value { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
1112 ;
1113
1114case_label: // CFA
1115 CASE case_value_list ':' { $$ = $2; }
1116 | DEFAULT ':' { $$ = new StatementNode( build_default() ); }
1117 // A semantic check is required to ensure only one default clause per switch/choose statement.
1118 ;
1119
1120//label_list_opt:
1121// // empty
1122// | identifier_or_type_name ':'
1123// | label_list_opt identifier_or_type_name ':'
1124// ;
1125
1126case_label_list: // CFA
1127 case_label
1128 | case_label_list case_label { $$ = (StatementNode *)( $1->set_last( $2 )); }
1129 ;
1130
1131case_clause: // CFA
1132 case_label_list statement { $$ = $1->append_last_case( maybe_build_compound( $2 ) ); }
1133 ;
1134
1135switch_clause_list_opt: // CFA
1136 // empty
1137 { $$ = nullptr; }
1138 | switch_clause_list
1139 ;
1140
1141switch_clause_list: // CFA
1142 case_label_list statement_list_nodecl
1143 { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1144 | switch_clause_list case_label_list statement_list_nodecl
1145 { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1146 ;
1147
1148iteration_statement:
1149 WHILE '(' push if_control_expression ')' statement pop
1150 { $$ = new StatementNode( build_while( $4, maybe_build_compound( $6 ) ) ); }
1151 | WHILE '(' ')' statement // CFA => while ( 1 )
1152 { $$ = new StatementNode( build_while( new IfCtrl( nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ), maybe_build_compound( $4 ) ) ); }
1153 | DO statement WHILE '(' comma_expression ')' ';'
1154 { $$ = new StatementNode( build_do_while( $5, maybe_build_compound( $2 ) ) ); }
1155 | DO statement WHILE '(' ')' ';' // CFA => do while( 1 )
1156 { $$ = new StatementNode( build_do_while( new ExpressionNode( build_constantInteger( *new string( "1" ) ) ), maybe_build_compound( $2 ) ) ); }
1157 | FOR '(' push for_control_expression_list ')' statement pop
1158 { $$ = new StatementNode( build_for( $4, maybe_build_compound( $6 ) ) ); }
1159 | FOR '(' ')' statement // CFA => for ( ;; )
1160 { $$ = new StatementNode( build_for( new ForCtrl( (ExpressionNode * )nullptr, (ExpressionNode * )nullptr, (ExpressionNode * )nullptr ), maybe_build_compound( $4 ) ) ); }
1161 ;
1162
1163for_control_expression_list:
1164 for_control_expression
1165 | for_control_expression_list ':' for_control_expression
1166 // ForCtrl + ForCtrl:
1167 // init + init => multiple declaration statements that are hoisted
1168 // condition + condition => (expression) && (expression)
1169 // change + change => (expression), (expression)
1170 {
1171 $1->init->set_last( $3->init );
1172 if ( $1->condition ) {
1173 if ( $3->condition ) {
1174 $1->condition->expr.reset( new LogicalExpr( $1->condition->expr.release(), $3->condition->expr.release(), true ) );
1175 } // if
1176 } else $1->condition = $3->condition;
1177 if ( $1->change ) {
1178 if ( $3->change ) {
1179 $1->change->expr.reset( new CommaExpr( $1->change->expr.release(), $3->change->expr.release() ) );
1180 } // if
1181 } else $1->change = $3->change;
1182 $$ = $1;
1183 }
1184 ;
1185
1186for_control_expression:
1187 ';' comma_expression_opt ';' comma_expression_opt
1188 { $$ = new ForCtrl( (ExpressionNode * )nullptr, $2, $4 ); }
1189 | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1190 { $$ = new ForCtrl( $1, $3, $5 ); }
1191 | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1192 { $$ = new ForCtrl( $1, $2, $4 ); }
1193
1194 | comma_expression // CFA
1195 { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1196 OperKinds::LThan, $1->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1197 | '=' comma_expression // CFA
1198 { $$ = forCtrl( $2, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1199 OperKinds::LEThan, $2->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1200 | comma_expression inclexcl comma_expression // CFA
1201 { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1202 | comma_expression inclexcl comma_expression '~' comma_expression // CFA
1203 { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, $5 ); }
1204 | comma_expression ';' // CFA
1205 { $$ = forCtrl( new ExpressionNode( build_constantInteger( *new string( "0u" ) ) ), $1, nullptr, OperKinds::LThan, nullptr, nullptr ); }
1206 | comma_expression ';' comma_expression // CFA
1207 { $$ = forCtrl( $3, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1208 OperKinds::LThan, $3->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1209 | comma_expression ';' '=' comma_expression // CFA
1210 { $$ = forCtrl( $4, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1211 OperKinds::LEThan, $4->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1212 | comma_expression ';' comma_expression inclexcl comma_expression // CFA
1213 { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1214 | comma_expression ';' comma_expression inclexcl comma_expression '~' comma_expression // CFA
1215 { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, $7 ); }
1216
1217 // There is a S/R conflicit if ~ and -~ are factored out.
1218 | comma_expression ';' comma_expression '~' '@' // CFA
1219 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1220 | comma_expression ';' comma_expression ErangeDown '@' // CFA
1221 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1222 | comma_expression ';' comma_expression '~' '@' '~' comma_expression // CFA
1223 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, $7 ); }
1224 | comma_expression ';' comma_expression ErangeDown '@' '~' comma_expression // CFA
1225 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, $7 ); }
1226 | comma_expression ';' comma_expression '~' '@' '~' '@' // CFA
1227 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, nullptr ); }
1228 ;
1229
1230inclexcl:
1231 '~'
1232 { $$ = OperKinds::LThan; }
1233 | ErangeUpEq
1234 { $$ = OperKinds::LEThan; }
1235 | ErangeDown
1236 { $$ = OperKinds::GThan; }
1237 | ErangeDownEq
1238 { $$ = OperKinds::GEThan; }
1239 ;
1240
1241jump_statement:
1242 GOTO identifier_or_type_name ';'
1243 { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1244 | GOTO '*' comma_expression ';' // GCC, computed goto
1245 // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1246 // whereas normal operator precedence yields goto (*i)+3;
1247 { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1248 // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1249 | fall_through_name ';' // CFA
1250 { $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1251 | fall_through_name identifier_or_type_name ';' // CFA
1252 { $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1253 | fall_through_name DEFAULT ';' // CFA
1254 { $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1255 | CONTINUE ';'
1256 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1257 { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1258 | CONTINUE identifier_or_type_name ';' // CFA, multi-level continue
1259 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1260 // the target of the transfer appears only at the start of an iteration statement.
1261 { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1262 | BREAK ';'
1263 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1264 { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1265 | BREAK identifier_or_type_name ';' // CFA, multi-level exit
1266 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1267 // the target of the transfer appears only at the start of an iteration statement.
1268 { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1269 | RETURN comma_expression_opt ';'
1270 { $$ = new StatementNode( build_return( $2 ) ); }
1271 | RETURN '{' initializer_list_opt comma_opt '}' ';'
1272 { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1273 | SUSPEND ';'
1274 { $$ = new StatementNode( build_suspend( nullptr ) ); }
1275 | SUSPEND compound_statement
1276 { $$ = new StatementNode( build_suspend( $2 ) ); }
1277 | SUSPEND COROUTINE ';'
1278 { $$ = new StatementNode( build_suspend( nullptr, SuspendStmt::Coroutine ) ); }
1279 | SUSPEND COROUTINE compound_statement
1280 { $$ = new StatementNode( build_suspend( $3, SuspendStmt::Coroutine ) ); }
1281 | SUSPEND GENERATOR ';'
1282 { $$ = new StatementNode( build_suspend( nullptr, SuspendStmt::Generator ) ); }
1283 | SUSPEND GENERATOR compound_statement
1284 { $$ = new StatementNode( build_suspend( $3, SuspendStmt::Generator ) ); }
1285 | THROW assignment_expression_opt ';' // handles rethrow
1286 { $$ = new StatementNode( build_throw( $2 ) ); }
1287 | THROWRESUME assignment_expression_opt ';' // handles reresume
1288 { $$ = new StatementNode( build_resume( $2 ) ); }
1289 | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1290 { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1291 ;
1292
1293fall_through_name: // CFA
1294 FALLTHRU
1295 | FALLTHROUGH
1296 ;
1297
1298with_statement:
1299 WITH '(' tuple_expression_list ')' statement
1300 {
1301 $$ = new StatementNode( build_with( $3, $5 ) );
1302 }
1303 ;
1304
1305// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1306mutex_statement:
1307 MUTEX '(' argument_expression_list_opt ')' statement
1308 { SemanticError( yylloc, "Mutex statement is currently unimplemented." ); $$ = nullptr; }
1309 ;
1310
1311when_clause:
1312 WHEN '(' comma_expression ')' { $$ = $3; }
1313 ;
1314
1315when_clause_opt:
1316 // empty
1317 { $$ = nullptr; }
1318 | when_clause
1319 ;
1320
1321waitfor:
1322 WAITFOR '(' cast_expression ')'
1323 { $$ = $3; }
1324// | WAITFOR '(' cast_expression ',' argument_expression_list_opt ')'
1325// { $$ = (ExpressionNode *)$3->set_last( $5 ); }
1326 | WAITFOR '(' cast_expression_list ':' argument_expression_list_opt ')'
1327 { $$ = (ExpressionNode *)($3->set_last( $5 )); }
1328 ;
1329
1330cast_expression_list:
1331 cast_expression
1332 | cast_expression_list ',' cast_expression
1333 // { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1334 { SemanticError( yylloc, "List of mutex member is currently unimplemented." ); $$ = nullptr; }
1335 ;
1336
1337timeout:
1338 TIMEOUT '(' comma_expression ')' { $$ = $3; }
1339 ;
1340
1341waitfor_clause:
1342 when_clause_opt waitfor statement %prec THEN
1343 { $$ = build_waitfor( $2, maybe_build_compound( $3 ), $1 ); }
1344 | when_clause_opt waitfor statement WOR waitfor_clause
1345 { $$ = build_waitfor( $2, maybe_build_compound( $3 ), $1, $5 ); }
1346 | when_clause_opt timeout statement %prec THEN
1347 { $$ = build_waitfor_timeout( $2, maybe_build_compound( $3 ), $1 ); }
1348 | when_clause_opt ELSE statement
1349 { $$ = build_waitfor_timeout( nullptr, maybe_build_compound( $3 ), $1 ); }
1350 // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1351 | when_clause_opt timeout statement WOR ELSE statement
1352 { SemanticError( yylloc, "else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1353 | when_clause_opt timeout statement WOR when_clause ELSE statement
1354 { $$ = build_waitfor_timeout( $2, maybe_build_compound( $3 ), $1, maybe_build_compound( $7 ), $5 ); }
1355 ;
1356
1357waitfor_statement:
1358 when_clause_opt waitfor statement %prec THEN
1359 { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1360 | when_clause_opt waitfor statement WOR waitfor_clause
1361 { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1362 ;
1363
1364exception_statement:
1365 TRY compound_statement handler_clause
1366 { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1367 | TRY compound_statement finally_clause
1368 { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1369 | TRY compound_statement handler_clause finally_clause
1370 { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1371 ;
1372
1373handler_clause:
1374 handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1375 { $$ = new StatementNode( build_catch( $1, $4, $6, $8 ) ); }
1376 | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1377 { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $5, $7, $9 ) ) ); }
1378 ;
1379
1380handler_predicate_opt:
1381 // empty
1382 { $$ = nullptr; }
1383 | ';' conditional_expression { $$ = $2; }
1384 ;
1385
1386handler_key:
1387 CATCH { $$ = CatchStmt::Terminate; }
1388 | CATCHRESUME { $$ = CatchStmt::Resume; }
1389 ;
1390
1391finally_clause:
1392 FINALLY compound_statement { $$ = new StatementNode( build_finally( $2 ) ); }
1393 ;
1394
1395exception_declaration:
1396 // No SUE declaration in parameter list.
1397 type_specifier_nobody
1398 | type_specifier_nobody declarator
1399 { $$ = $2->addType( $1 ); }
1400 | type_specifier_nobody variable_abstract_declarator
1401 { $$ = $2->addType( $1 ); }
1402 | cfa_abstract_declarator_tuple identifier // CFA
1403 { $$ = $1->addName( $2 ); }
1404 | cfa_abstract_declarator_tuple // CFA
1405 ;
1406
1407enable_disable_statement:
1408 enable_disable_key identifier_list compound_statement
1409 ;
1410
1411enable_disable_key:
1412 ENABLE
1413 | DISABLE
1414 ;
1415
1416asm_statement:
1417 ASM asm_volatile_opt '(' string_literal ')' ';'
1418 { $$ = new StatementNode( build_asm( $2, $4, 0 ) ); }
1419 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1420 { $$ = new StatementNode( build_asm( $2, $4, $6 ) ); }
1421 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1422 { $$ = new StatementNode( build_asm( $2, $4, $6, $8 ) ); }
1423 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1424 { $$ = new StatementNode( build_asm( $2, $4, $6, $8, $10 ) ); }
1425 | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1426 { $$ = new StatementNode( build_asm( $2, $5, 0, $8, $10, $12 ) ); }
1427 ;
1428
1429asm_volatile_opt: // GCC
1430 // empty
1431 { $$ = false; }
1432 | VOLATILE
1433 { $$ = true; }
1434 ;
1435
1436asm_operands_opt: // GCC
1437 // empty
1438 { $$ = nullptr; } // use default argument
1439 | asm_operands_list
1440 ;
1441
1442asm_operands_list: // GCC
1443 asm_operand
1444 | asm_operands_list ',' asm_operand
1445 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1446 ;
1447
1448asm_operand: // GCC
1449 string_literal '(' constant_expression ')'
1450 { $$ = new ExpressionNode( new AsmExpr( nullptr, $1, maybeMoveBuild< Expression >( $3 ) ) ); }
1451 | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1452 { $$ = new ExpressionNode( new AsmExpr( $2, $4, maybeMoveBuild< Expression >( $6 ) ) ); }
1453 ;
1454
1455asm_clobbers_list_opt: // GCC
1456 // empty
1457 { $$ = nullptr; } // use default argument
1458 | string_literal
1459 { $$ = new ExpressionNode( $1 ); }
1460 | asm_clobbers_list_opt ',' string_literal
1461 { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( $3 ) )); }
1462 ;
1463
1464label_list:
1465 identifier
1466 {
1467 $$ = new LabelNode(); $$->labels.push_back( *$1 );
1468 delete $1; // allocated by lexer
1469 }
1470 | label_list ',' identifier
1471 {
1472 $$ = $1; $1->labels.push_back( *$3 );
1473 delete $3; // allocated by lexer
1474 }
1475 ;
1476
1477//******************************* DECLARATIONS *********************************
1478
1479declaration_list_opt: // used at beginning of switch statement
1480 // empty
1481 { $$ = nullptr; }
1482 | declaration_list
1483 ;
1484
1485declaration_list:
1486 declaration
1487 | declaration_list declaration
1488 { $$ = $1->appendList( $2 ); }
1489 ;
1490
1491KR_parameter_list_opt: // used to declare parameter types in K&R style functions
1492 // empty
1493 { $$ = nullptr; }
1494 | KR_parameter_list
1495 ;
1496
1497KR_parameter_list:
1498 push c_declaration pop ';'
1499 { $$ = $2; }
1500 | KR_parameter_list push c_declaration pop ';'
1501 { $$ = $1->appendList( $3 ); }
1502 ;
1503
1504local_label_declaration_opt: // GCC, local label
1505 // empty
1506 | local_label_declaration_list
1507 ;
1508
1509local_label_declaration_list: // GCC, local label
1510 LABEL local_label_list ';'
1511 | local_label_declaration_list LABEL local_label_list ';'
1512 ;
1513
1514local_label_list: // GCC, local label
1515 identifier_or_type_name
1516 | local_label_list ',' identifier_or_type_name
1517 ;
1518
1519declaration: // old & new style declarations
1520 c_declaration ';'
1521 | cfa_declaration ';' // CFA
1522 | static_assert // C11
1523 ;
1524
1525static_assert:
1526 STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1527 { $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1528 | STATICASSERT '(' constant_expression ')' ';' // CFA
1529 { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( *new string( "\"\"" ) ) ); }
1530
1531// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1532// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1533// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1534// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1535// the declaration list (as in Pascal). ANSI C and the new CFA declarations may appear together in the same program
1536// block, but cannot be mixed within a specific declaration.
1537//
1538// CFA C
1539// [10] int x; int x[10]; // array of 10 integers
1540// [10] * char y; char *y[10]; // array of 10 pointers to char
1541
1542cfa_declaration: // CFA
1543 cfa_variable_declaration
1544 | cfa_typedef_declaration
1545 | cfa_function_declaration
1546 | type_declaring_list
1547 | trait_specifier
1548 ;
1549
1550cfa_variable_declaration: // CFA
1551 cfa_variable_specifier initializer_opt
1552 { $$ = $1->addInitializer( $2 ); }
1553 | declaration_qualifier_list cfa_variable_specifier initializer_opt
1554 // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1555 // them as a type_qualifier cannot appear in that context.
1556 { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1557 | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1558 { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1559 ;
1560
1561cfa_variable_specifier: // CFA
1562 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1563 // storage-class
1564 cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1565 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1566 | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1567 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1568 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1569 { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1570 ;
1571
1572cfa_function_declaration: // CFA
1573 cfa_function_specifier
1574 | type_qualifier_list cfa_function_specifier
1575 { $$ = $2->addQualifiers( $1 ); }
1576 | declaration_qualifier_list cfa_function_specifier
1577 { $$ = $2->addQualifiers( $1 ); }
1578 | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1579 { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1580 | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1581 {
1582 // Append the return type at the start (left-hand-side) to each identifier in the list.
1583 DeclarationNode * ret = new DeclarationNode;
1584 ret->type = maybeClone( $1->type->base );
1585 $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1586 }
1587 ;
1588
1589cfa_function_specifier: // CFA
1590// '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1591// {
1592// $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1593// }
1594// '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1595// {
1596// typedefTable.setNextIdentifier( *$5 );
1597// $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1598// }
1599// | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1600// {
1601// typedefTable.setNextIdentifier( *$5 );
1602// $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1603// }
1604// | '[' ']' typegen_name
1605 // identifier_or_type_name must be broken apart because of the sequence:
1606 //
1607 // '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1608 // '[' ']' type_specifier
1609 //
1610 // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1611 // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1612 cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1613 // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1614 { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1615 | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1616 { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1617 ;
1618
1619cfa_function_return: // CFA
1620 '[' push cfa_parameter_list pop ']'
1621 { $$ = DeclarationNode::newTuple( $3 ); }
1622 | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1623 // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
1624 { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1625 ;
1626
1627cfa_typedef_declaration: // CFA
1628 TYPEDEF cfa_variable_specifier
1629 {
1630 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "1" );
1631 $$ = $2->addTypedef();
1632 }
1633 | TYPEDEF cfa_function_specifier
1634 {
1635 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "2" );
1636 $$ = $2->addTypedef();
1637 }
1638 | cfa_typedef_declaration pop ',' push identifier
1639 {
1640 typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "3" );
1641 $$ = $1->appendList( $1->cloneType( $5 ) );
1642 }
1643 ;
1644
1645// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1646// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1647
1648typedef_declaration:
1649 TYPEDEF type_specifier declarator
1650 {
1651 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "4" );
1652 $$ = $3->addType( $2 )->addTypedef();
1653 }
1654 | typedef_declaration pop ',' push declarator
1655 {
1656 typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname, "5" );
1657 $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1658 }
1659 | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1660 {
1661 typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "6" );
1662 $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1663 }
1664 | type_specifier TYPEDEF declarator
1665 {
1666 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "7" );
1667 $$ = $3->addType( $1 )->addTypedef();
1668 }
1669 | type_specifier TYPEDEF type_qualifier_list declarator
1670 {
1671 typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "8" );
1672 $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1673 }
1674 ;
1675
1676typedef_expression:
1677 // deprecated GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1678 TYPEDEF identifier '=' assignment_expression
1679 {
1680 SemanticError( yylloc, "Typedef expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
1681 }
1682 | typedef_expression pop ',' push identifier '=' assignment_expression
1683 {
1684 SemanticError( yylloc, "Typedef expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
1685 }
1686 ;
1687
1688c_declaration:
1689 declaration_specifier declaring_list
1690 { $$ = distAttr( $1, $2 ); }
1691 | typedef_declaration
1692 | typedef_expression // deprecated GCC, naming expression type
1693 | sue_declaration_specifier
1694 ;
1695
1696declaring_list:
1697 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1698 // storage-class
1699 declarator asm_name_opt initializer_opt
1700 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
1701 | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1702 { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
1703 ;
1704
1705declaration_specifier: // type specifier + storage class
1706 basic_declaration_specifier
1707 | sue_declaration_specifier
1708 | type_declaration_specifier
1709 ;
1710
1711declaration_specifier_nobody: // type specifier + storage class - {...}
1712 // Preclude SUE declarations in restricted scopes:
1713 //
1714 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1715 //
1716 // because it is impossible to call f due to name equivalence.
1717 basic_declaration_specifier
1718 | sue_declaration_specifier_nobody
1719 | type_declaration_specifier
1720 ;
1721
1722type_specifier: // type specifier
1723 basic_type_specifier
1724 | sue_type_specifier
1725 | type_type_specifier
1726 ;
1727
1728type_specifier_nobody: // type specifier - {...}
1729 // Preclude SUE declarations in restricted scopes:
1730 //
1731 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1732 //
1733 // because it is impossible to call f due to name equivalence.
1734 basic_type_specifier
1735 | sue_type_specifier_nobody
1736 | type_type_specifier
1737 ;
1738
1739type_qualifier_list_opt: // GCC, used in asm_statement
1740 // empty
1741 { $$ = nullptr; }
1742 | type_qualifier_list
1743 ;
1744
1745type_qualifier_list:
1746 // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1747 //
1748 // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1749 // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1750 // appeared only once.
1751 type_qualifier
1752 | type_qualifier_list type_qualifier
1753 { $$ = $1->addQualifiers( $2 ); }
1754 ;
1755
1756type_qualifier:
1757 type_qualifier_name
1758 | attribute
1759 ;
1760
1761type_qualifier_name:
1762 CONST
1763 { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1764 | RESTRICT
1765 { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1766 | VOLATILE
1767 { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1768 | ATOMIC
1769 { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1770 | forall
1771 ;
1772
1773forall:
1774 FORALL '(' type_parameter_list ')' // CFA
1775 { $$ = DeclarationNode::newForall( $3 ); }
1776 ;
1777
1778declaration_qualifier_list:
1779 storage_class_list
1780 | type_qualifier_list storage_class_list // remaining OBSOLESCENT (see 2 )
1781 { $$ = $1->addQualifiers( $2 ); }
1782 | declaration_qualifier_list type_qualifier_list storage_class_list
1783 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1784 ;
1785
1786storage_class_list:
1787 // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1788 // only one of each is specified, except for inline, which can appear with the others.
1789 //
1790 // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1791 // specifiers in a declaration.
1792 storage_class
1793 | storage_class_list storage_class
1794 { $$ = $1->addQualifiers( $2 ); }
1795 ;
1796
1797storage_class:
1798 EXTERN
1799 { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1800 | STATIC
1801 { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1802 | AUTO
1803 { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1804 | REGISTER
1805 { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1806 | THREADLOCAL // C11
1807 { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1808 // Put function specifiers here to simplify parsing rules, but separate them semantically.
1809 | INLINE // C99
1810 { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1811 | FORTRAN // C99
1812 { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1813 | NORETURN // C11
1814 { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1815 ;
1816
1817basic_type_name:
1818 VOID
1819 { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1820 | BOOL // C99
1821 { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1822 | CHAR
1823 { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1824 | INT
1825 { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1826 | INT128
1827 { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1828 | UINT128
1829 { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 )->addType( DeclarationNode::newSignedNess( DeclarationNode::Unsigned ) ); }
1830 | FLOAT
1831 { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1832 | DOUBLE
1833 { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1834 | uuFLOAT80
1835 { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
1836 | uuFLOAT128
1837 { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
1838 | uFLOAT16
1839 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
1840 | uFLOAT32
1841 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
1842 | uFLOAT32X
1843 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
1844 | uFLOAT64
1845 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
1846 | uFLOAT64X
1847 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
1848 | uFLOAT128
1849 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
1850 | COMPLEX // C99
1851 { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1852 | IMAGINARY // C99
1853 { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1854 | SIGNED
1855 { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1856 | UNSIGNED
1857 { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1858 | SHORT
1859 { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1860 | LONG
1861 { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1862 | VALIST // GCC, __builtin_va_list
1863 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1864 | AUTO_TYPE
1865 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::AutoType ); }
1866 ;
1867
1868basic_declaration_specifier:
1869 // A semantic check is necessary for conflicting storage classes.
1870 basic_type_specifier
1871 | declaration_qualifier_list basic_type_specifier
1872 { $$ = $2->addQualifiers( $1 ); }
1873 | basic_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1874 { $$ = $1->addQualifiers( $2 ); }
1875 | basic_declaration_specifier storage_class type_qualifier_list
1876 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1877 | basic_declaration_specifier storage_class basic_type_specifier
1878 { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1879 ;
1880
1881basic_type_specifier:
1882 direct_type
1883 // Cannot have type modifiers, e.g., short, long, etc.
1884 | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1885 { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1886 ;
1887
1888direct_type:
1889 basic_type_name
1890 | type_qualifier_list basic_type_name
1891 { $$ = $2->addQualifiers( $1 ); }
1892 | direct_type type_qualifier
1893 { $$ = $1->addQualifiers( $2 ); }
1894 | direct_type basic_type_name
1895 { $$ = $1->addType( $2 ); }
1896 ;
1897
1898indirect_type:
1899 TYPEOF '(' type ')' // GCC: typeof( x ) y;
1900 { $$ = $3; }
1901 | TYPEOF '(' comma_expression ')' // GCC: typeof( a+b ) y;
1902 { $$ = DeclarationNode::newTypeof( $3 ); }
1903 | BASETYPEOF '(' type ')' // CFA: basetypeof( x ) y;
1904 { $$ = DeclarationNode::newTypeof( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ), true ); }
1905 | BASETYPEOF '(' comma_expression ')' // CFA: basetypeof( a+b ) y;
1906 { $$ = DeclarationNode::newTypeof( $3, true ); }
1907 | ZERO_T // CFA
1908 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1909 | ONE_T // CFA
1910 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1911 ;
1912
1913sue_declaration_specifier: // struct, union, enum + storage class + type specifier
1914 sue_type_specifier
1915 | declaration_qualifier_list sue_type_specifier
1916 { $$ = $2->addQualifiers( $1 ); }
1917 | sue_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1918 { $$ = $1->addQualifiers( $2 ); }
1919 | sue_declaration_specifier storage_class type_qualifier_list
1920 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1921 ;
1922
1923sue_type_specifier: // struct, union, enum + type specifier
1924 elaborated_type
1925 | type_qualifier_list
1926 { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1927 elaborated_type
1928 { $$ = $3->addQualifiers( $1 ); }
1929 | sue_type_specifier type_qualifier
1930 {
1931 if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
1932 $$ = $1->addQualifiers( $2 );
1933 }
1934 ;
1935
1936sue_declaration_specifier_nobody: // struct, union, enum - {...} + storage class + type specifier
1937 sue_type_specifier_nobody
1938 | declaration_qualifier_list sue_type_specifier_nobody
1939 { $$ = $2->addQualifiers( $1 ); }
1940 | sue_declaration_specifier_nobody storage_class // remaining OBSOLESCENT (see 2)
1941 { $$ = $1->addQualifiers( $2 ); }
1942 | sue_declaration_specifier_nobody storage_class type_qualifier_list
1943 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1944 ;
1945
1946sue_type_specifier_nobody: // struct, union, enum - {...} + type specifier
1947 elaborated_type_nobody
1948 | type_qualifier_list elaborated_type_nobody
1949 { $$ = $2->addQualifiers( $1 ); }
1950 | sue_type_specifier_nobody type_qualifier
1951 { $$ = $1->addQualifiers( $2 ); }
1952 ;
1953
1954type_declaration_specifier:
1955 type_type_specifier
1956 | declaration_qualifier_list type_type_specifier
1957 { $$ = $2->addQualifiers( $1 ); }
1958 | type_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1959 { $$ = $1->addQualifiers( $2 ); }
1960 | type_declaration_specifier storage_class type_qualifier_list
1961 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1962 ;
1963
1964type_type_specifier: // typedef types
1965 type_name
1966 | type_qualifier_list type_name
1967 { $$ = $2->addQualifiers( $1 ); }
1968 | type_type_specifier type_qualifier
1969 { $$ = $1->addQualifiers( $2 ); }
1970 ;
1971
1972type_name:
1973 TYPEDEFname
1974 { $$ = DeclarationNode::newFromTypedef( $1 ); }
1975 | '.' TYPEDEFname
1976 { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
1977 | type_name '.' TYPEDEFname
1978 { $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
1979 | typegen_name
1980 | '.' typegen_name
1981 { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
1982 | type_name '.' typegen_name
1983 { $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
1984 ;
1985
1986typegen_name: // CFA
1987 TYPEGENname
1988 { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1989 | TYPEGENname '(' ')'
1990 { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1991 | TYPEGENname '(' type_list ')'
1992 { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
1993 ;
1994
1995elaborated_type: // struct, union, enum
1996 aggregate_type
1997 | enum_type
1998 ;
1999
2000elaborated_type_nobody: // struct, union, enum - {...}
2001 aggregate_type_nobody
2002 | enum_type_nobody
2003 ;
2004
2005fred:
2006 // empty
2007 { yyy = false; }
2008 ;
2009
2010aggregate_type: // struct, union
2011 aggregate_key attribute_list_opt
2012 { forall = false; } // reset
2013 '{' field_declaration_list_opt '}' type_parameters_opt
2014 { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2015 | aggregate_key attribute_list_opt identifier fred
2016 {
2017 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2018 forall = false; // reset
2019 }
2020 '{' field_declaration_list_opt '}' type_parameters_opt
2021 { $$ = DeclarationNode::newAggregate( $1, $3, $9, $7, true )->addQualifiers( $2 ); }
2022 | aggregate_key attribute_list_opt type_name fred
2023 {
2024 // for type_name can be a qualified type name S.T, in which case only the last name in the chain needs a typedef (other names in the chain should already have one)
2025 typedefTable.makeTypedef( *$3->type->leafName(), forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2026 forall = false; // reset
2027 }
2028 '{' field_declaration_list_opt '}' type_parameters_opt
2029 { $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $9, $7, true )->addQualifiers( $2 ); }
2030 | aggregate_type_nobody
2031 ;
2032
2033type_parameters_opt:
2034 // empty
2035 { $$ = nullptr; } %prec '}'
2036 | '(' type_list ')'
2037 { $$ = $2; }
2038 ;
2039
2040aggregate_type_nobody: // struct, union - {...}
2041 aggregate_key attribute_list_opt identifier fred
2042 {
2043 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname );
2044 forall = false; // reset
2045 $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2046 }
2047 | aggregate_key attribute_list_opt type_name fred
2048 {
2049 forall = false; // reset
2050 // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2051 // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2052 // delete newFromTypeGen.
2053 $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2054 $3->type->symbolic.name = nullptr;
2055 $3->type->symbolic.actuals = nullptr;
2056 delete $3;
2057 }
2058 ;
2059
2060aggregate_key:
2061 aggregate_data
2062 | aggregate_control
2063 ;
2064
2065aggregate_data:
2066 STRUCT
2067 { yyy = true; $$ = AggregateDecl::Struct; }
2068 | UNION
2069 { yyy = true; $$ = AggregateDecl::Union; }
2070 | EXCEPTION // CFA
2071 // { yyy = true; $$ = AggregateDecl::Exception; }
2072 { SemanticError( yylloc, "exception aggregate is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2073 ;
2074
2075aggregate_control: // CFA
2076 MONITOR
2077 { yyy = true; $$ = AggregateDecl::Monitor; }
2078 | MUTEX STRUCT
2079 { yyy = true; $$ = AggregateDecl::Monitor; }
2080 | GENERATOR
2081 { yyy = true; $$ = AggregateDecl::Generator; }
2082 | MUTEX GENERATOR
2083 { SemanticError( yylloc, "monitor generator is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2084 | COROUTINE
2085 { yyy = true; $$ = AggregateDecl::Coroutine; }
2086 | MUTEX COROUTINE
2087 { SemanticError( yylloc, "monitor coroutine is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2088 | THREAD
2089 { yyy = true; $$ = AggregateDecl::Thread; }
2090 | MUTEX THREAD
2091 { SemanticError( yylloc, "monitor thread is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2092 ;
2093
2094field_declaration_list_opt:
2095 // empty
2096 { $$ = nullptr; }
2097 | field_declaration_list_opt field_declaration
2098 { $$ = $1 ? $1->appendList( $2 ) : $2; }
2099 ;
2100
2101field_declaration:
2102 type_specifier field_declaring_list_opt ';'
2103 { $$ = fieldDecl( $1, $2 ); }
2104 | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2105 { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2106 | INLINE type_specifier field_abstract_list_opt ';' // CFA
2107 {
2108 if ( ! $3 ) { // field declarator ?
2109 $3 = DeclarationNode::newName( nullptr );
2110 } // if
2111 $3->inLine = true;
2112 $$ = distAttr( $2, $3 ); // mark all fields in list
2113 distInl( $3 );
2114 }
2115 | INLINE aggregate_control ';' // CFA
2116 { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2117 | typedef_declaration ';' // CFA
2118 | cfa_field_declaring_list ';' // CFA, new style field declaration
2119 | EXTENSION cfa_field_declaring_list ';' // GCC
2120 { distExt( $2 ); $$ = $2; } // mark all fields in list
2121 | INLINE cfa_field_abstract_list ';' // CFA, new style field declaration
2122 { $$ = $2; } // mark all fields in list
2123 | cfa_typedef_declaration ';' // CFA
2124 | static_assert // C11
2125 ;
2126
2127field_declaring_list_opt:
2128 // empty
2129 { $$ = nullptr; }
2130 | field_declarator
2131 | field_declaring_list_opt ',' attribute_list_opt field_declarator
2132 { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2133 ;
2134
2135field_declarator:
2136 bit_subrange_size // C special case, no field name
2137 { $$ = DeclarationNode::newBitfield( $1 ); }
2138 | variable_declarator bit_subrange_size_opt
2139 // A semantic check is required to ensure bit_subrange only appears on integral types.
2140 { $$ = $1->addBitfield( $2 ); }
2141 | variable_type_redeclarator bit_subrange_size_opt
2142 // A semantic check is required to ensure bit_subrange only appears on integral types.
2143 { $$ = $1->addBitfield( $2 ); }
2144 ;
2145
2146field_abstract_list_opt:
2147 // empty
2148 { $$ = nullptr; }
2149 | field_abstract
2150 | field_abstract_list_opt ',' attribute_list_opt field_abstract
2151 { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2152 ;
2153
2154field_abstract:
2155 // no bit fields
2156 variable_abstract_declarator
2157 ;
2158
2159cfa_field_declaring_list: // CFA, new style field declaration
2160 // bit-fields are handled by C declarations
2161 cfa_abstract_declarator_tuple identifier_or_type_name
2162 { $$ = $1->addName( $2 ); }
2163 | cfa_field_declaring_list ',' identifier_or_type_name
2164 { $$ = $1->appendList( $1->cloneType( $3 ) ); }
2165 ;
2166
2167cfa_field_abstract_list: // CFA, new style field declaration
2168 // bit-fields are handled by C declarations
2169 cfa_abstract_declarator_tuple
2170 | cfa_field_abstract_list ','
2171 { $$ = $1->appendList( $1->cloneType( 0 ) ); }
2172 ;
2173
2174bit_subrange_size_opt:
2175 // empty
2176 { $$ = nullptr; }
2177 | bit_subrange_size
2178 ;
2179
2180bit_subrange_size:
2181 ':' assignment_expression
2182 { $$ = $2; }
2183 ;
2184
2185enum_type: // enum
2186 ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2187 { $$ = DeclarationNode::newEnum( nullptr, $4, true )->addQualifiers( $2 ); }
2188 | ENUM attribute_list_opt identifier
2189 { typedefTable.makeTypedef( *$3 ); }
2190 '{' enumerator_list comma_opt '}'
2191 { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
2192 | ENUM attribute_list_opt type_name
2193 '{' enumerator_list comma_opt '}'
2194 { $$ = DeclarationNode::newEnum( $3->type->symbolic.name, $5, true )->addQualifiers( $2 ); }
2195 | enum_type_nobody
2196 ;
2197
2198enum_type_nobody: // enum - {...}
2199 ENUM attribute_list_opt identifier
2200 {
2201 typedefTable.makeTypedef( *$3 );
2202 $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 );
2203 }
2204 | ENUM attribute_list_opt type_name
2205 {
2206 typedefTable.makeTypedef( *$3->type->symbolic.name );
2207 $$ = DeclarationNode::newEnum( $3->type->symbolic.name, 0, false )->addQualifiers( $2 );
2208 }
2209 ;
2210
2211enumerator_list:
2212 identifier_or_type_name enumerator_value_opt
2213 { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
2214 | enumerator_list ',' identifier_or_type_name enumerator_value_opt
2215 { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
2216 ;
2217
2218enumerator_value_opt:
2219 // empty
2220 { $$ = nullptr; }
2221 | '=' constant_expression
2222 { $$ = $2; }
2223 ;
2224
2225cfa_parameter_ellipsis_list_opt: // CFA, abstract + real
2226 // empty
2227 { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2228 | ELLIPSIS
2229 { $$ = nullptr; }
2230 | cfa_abstract_parameter_list
2231 | cfa_parameter_list
2232 | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2233 { $$ = $1->appendList( $5 ); }
2234 | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2235 { $$ = $1->addVarArgs(); }
2236 | cfa_parameter_list pop ',' push ELLIPSIS
2237 { $$ = $1->addVarArgs(); }
2238 ;
2239
2240cfa_parameter_list: // CFA
2241 // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2242 // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2243 cfa_parameter_declaration
2244 | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2245 { $$ = $1->appendList( $5 ); }
2246 | cfa_parameter_list pop ',' push cfa_parameter_declaration
2247 { $$ = $1->appendList( $5 ); }
2248 | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2249 { $$ = $1->appendList( $5 )->appendList( $9 ); }
2250 ;
2251
2252cfa_abstract_parameter_list: // CFA, new & old style abstract
2253 cfa_abstract_parameter_declaration
2254 | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2255 { $$ = $1->appendList( $5 ); }
2256 ;
2257
2258parameter_type_list_opt:
2259 // empty
2260 { $$ = nullptr; }
2261 | ELLIPSIS
2262 { $$ = nullptr; }
2263 | parameter_list
2264 | parameter_list pop ',' push ELLIPSIS
2265 { $$ = $1->addVarArgs(); }
2266 ;
2267
2268parameter_list: // abstract + real
2269 abstract_parameter_declaration
2270 | parameter_declaration
2271 | parameter_list pop ',' push abstract_parameter_declaration
2272 { $$ = $1->appendList( $5 ); }
2273 | parameter_list pop ',' push parameter_declaration
2274 { $$ = $1->appendList( $5 ); }
2275 ;
2276
2277// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2278// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2279
2280cfa_parameter_declaration: // CFA, new & old style parameter declaration
2281 parameter_declaration
2282 | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initialize_opt
2283 { $$ = $1->addName( $2 ); }
2284 | cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2285 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2286 { $$ = $1->addName( $2 ); }
2287 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2288 { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2289 | cfa_function_specifier
2290 ;
2291
2292cfa_abstract_parameter_declaration: // CFA, new & old style parameter declaration
2293 abstract_parameter_declaration
2294 | cfa_identifier_parameter_declarator_no_tuple
2295 | cfa_abstract_tuple
2296 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2297 | type_qualifier_list cfa_abstract_tuple
2298 { $$ = $2->addQualifiers( $1 ); }
2299 | cfa_abstract_function
2300 ;
2301
2302parameter_declaration:
2303 // No SUE declaration in parameter list.
2304 declaration_specifier_nobody identifier_parameter_declarator default_initialize_opt
2305 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2306 | declaration_specifier_nobody type_parameter_redeclarator default_initialize_opt
2307 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2308 ;
2309
2310abstract_parameter_declaration:
2311 declaration_specifier_nobody default_initialize_opt
2312 { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2313 | declaration_specifier_nobody abstract_parameter_declarator default_initialize_opt
2314 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2315 ;
2316
2317// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2318// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2319// identifiers. The ANSI-style parameter-list can redefine a typedef name.
2320
2321identifier_list: // K&R-style parameter list => no types
2322 identifier
2323 { $$ = DeclarationNode::newName( $1 ); }
2324 | identifier_list ',' identifier
2325 { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2326 ;
2327
2328identifier_or_type_name:
2329 identifier
2330 | TYPEDEFname
2331 | TYPEGENname
2332 ;
2333
2334type_no_function: // sizeof, alignof, cast (constructor)
2335 cfa_abstract_declarator_tuple // CFA
2336 | type_specifier
2337 | type_specifier abstract_declarator
2338 { $$ = $2->addType( $1 ); }
2339 ;
2340
2341type: // typeof, assertion
2342 type_no_function
2343 | cfa_abstract_function // CFA
2344 ;
2345
2346initializer_opt:
2347 // empty
2348 { $$ = nullptr; }
2349 | '=' initializer
2350 { $$ = $2; }
2351 | '=' VOID
2352 { $$ = new InitializerNode( true ); }
2353 | ATassign initializer
2354 { $$ = $2->set_maybeConstructed( false ); }
2355 ;
2356
2357initializer:
2358 assignment_expression { $$ = new InitializerNode( $1 ); }
2359 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
2360 ;
2361
2362initializer_list_opt:
2363 // empty
2364 { $$ = nullptr; }
2365 | initializer
2366 | designation initializer { $$ = $2->set_designators( $1 ); }
2367 | initializer_list_opt ',' initializer { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2368 | initializer_list_opt ',' designation initializer
2369 { $$ = (InitializerNode *)($1->set_last( $4->set_designators( $3 ) )); }
2370 ;
2371
2372// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2373// '=' to separator the designator from the initializer value, as in:
2374//
2375// int x[10] = { [1] = 3 };
2376//
2377// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment. To disambiguate this case, CFA
2378// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2379// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2380// shift/reduce conflicts
2381
2382designation:
2383 designator_list ':' // C99, CFA uses ":" instead of "="
2384 | identifier ':' // GCC, field name
2385 { $$ = new ExpressionNode( build_varref( $1 ) ); }
2386 ;
2387
2388designator_list: // C99
2389 designator
2390 | designator_list designator
2391 { $$ = (ExpressionNode *)($1->set_last( $2 )); }
2392 //| designator_list designator { $$ = new ExpressionNode( $1, $2 ); }
2393 ;
2394
2395designator:
2396 '.' identifier // C99, field name
2397 { $$ = new ExpressionNode( build_varref( $2 ) ); }
2398 | '[' push assignment_expression pop ']' // C99, single array element
2399 // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2400 { $$ = $3; }
2401 | '[' push subrange pop ']' // CFA, multiple array elements
2402 { $$ = $3; }
2403 | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2404 { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $3 ), maybeMoveBuild< Expression >( $5 ) ) ); }
2405 | '.' '[' push field_name_list pop ']' // CFA, tuple field selector
2406 { $$ = $4; }
2407 ;
2408
2409// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2410// rather than an object-oriented type system. This required four groups of extensions:
2411//
2412// Overloading: function, data, and operator identifiers may be overloaded.
2413//
2414// Type declarations: "otype" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2415// and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2416// definitions of new types. Type declarations with storage class "extern" provide opaque types.
2417//
2418// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2419// site. A polymorphic function is not a template; it is a function, with an address and a type.
2420//
2421// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2422// types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2423// hierarchies. Unlike classes, they can define relationships between types. Assertions declare that a type or
2424// types provide the operations declared by a specification. Assertions are normally used to declare requirements
2425// on type arguments of polymorphic functions.
2426
2427type_parameter_list: // CFA
2428 type_parameter
2429 | type_parameter_list ',' type_parameter
2430 { $$ = $1->appendList( $3 ); }
2431 ;
2432
2433type_initializer_opt: // CFA
2434 // empty
2435 { $$ = nullptr; }
2436 | '=' type
2437 { $$ = $2; }
2438 ;
2439
2440type_parameter: // CFA
2441 type_class identifier_or_type_name
2442 { typedefTable.addToScope( *$2, TYPEDEFname, "9" ); }
2443 type_initializer_opt assertion_list_opt
2444 { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2445 | type_specifier identifier_parameter_declarator
2446 | assertion_list
2447 { $$ = DeclarationNode::newTypeParam( TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2448 ;
2449
2450type_class: // CFA
2451 OTYPE
2452 { $$ = TypeDecl::Otype; }
2453 | DTYPE
2454 { $$ = TypeDecl::Dtype; }
2455 | FTYPE
2456 { $$ = TypeDecl::Ftype; }
2457 | TTYPE
2458 { $$ = TypeDecl::Ttype; }
2459 ;
2460
2461assertion_list_opt: // CFA
2462 // empty
2463 { $$ = nullptr; }
2464 | assertion_list
2465 ;
2466
2467assertion_list: // CFA
2468 assertion
2469 | assertion_list assertion
2470 { $$ = $1->appendList( $2 ); }
2471 ;
2472
2473assertion: // CFA
2474 '|' identifier_or_type_name '(' type_list ')'
2475 { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
2476 | '|' '{' push trait_declaration_list pop '}'
2477 { $$ = $4; }
2478 // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
2479 // { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
2480 ;
2481
2482type_list: // CFA
2483 type
2484 { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2485 | assignment_expression
2486 { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $1->build()) ); $$ = nullptr; }
2487 | type_list ',' type
2488 { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) )); }
2489 | type_list ',' assignment_expression
2490 { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $3->build()) ); $$ = nullptr; }
2491 // { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2492 ;
2493
2494type_declaring_list: // CFA
2495 OTYPE type_declarator
2496 { $$ = $2; }
2497 | storage_class_list OTYPE type_declarator
2498 { $$ = $3->addQualifiers( $1 ); }
2499 | type_declaring_list ',' type_declarator
2500 { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2501 ;
2502
2503type_declarator: // CFA
2504 type_declarator_name assertion_list_opt
2505 { $$ = $1->addAssertions( $2 ); }
2506 | type_declarator_name assertion_list_opt '=' type
2507 { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2508 ;
2509
2510type_declarator_name: // CFA
2511 identifier_or_type_name
2512 {
2513 typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "10" );
2514 $$ = DeclarationNode::newTypeDecl( $1, 0 );
2515 }
2516 | identifier_or_type_name '(' type_parameter_list ')'
2517 {
2518 typedefTable.addToEnclosingScope( *$1, TYPEGENname, "11" );
2519 $$ = DeclarationNode::newTypeDecl( $1, $3 );
2520 }
2521 ;
2522
2523trait_specifier: // CFA
2524 TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
2525 { $$ = DeclarationNode::newTrait( $2, $4, 0 ); }
2526 | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
2527 { $$ = DeclarationNode::newTrait( $2, $4, $8 ); }
2528 ;
2529
2530trait_declaration_list: // CFA
2531 trait_declaration
2532 | trait_declaration_list pop push trait_declaration
2533 { $$ = $1->appendList( $4 ); }
2534 ;
2535
2536trait_declaration: // CFA
2537 cfa_trait_declaring_list ';'
2538 | trait_declaring_list ';'
2539 ;
2540
2541cfa_trait_declaring_list: // CFA
2542 cfa_variable_specifier
2543 | cfa_function_specifier
2544 | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2545 { $$ = $1->appendList( $1->cloneType( $5 ) ); }
2546 ;
2547
2548trait_declaring_list: // CFA
2549 type_specifier declarator
2550 { $$ = $2->addType( $1 ); }
2551 | trait_declaring_list pop ',' push declarator
2552 { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
2553 ;
2554
2555//***************************** EXTERNAL DEFINITIONS *****************************
2556
2557translation_unit:
2558 // empty, input file
2559 | external_definition_list
2560 { parseTree = parseTree ? parseTree->appendList( $1 ) : $1; }
2561 ;
2562
2563external_definition_list:
2564 push external_definition pop
2565 { $$ = $2; }
2566 | external_definition_list push external_definition pop
2567 { $$ = $1 ? $1->appendList( $3 ) : $3; }
2568 ;
2569
2570external_definition_list_opt:
2571 // empty
2572 { $$ = nullptr; }
2573 | external_definition_list
2574 ;
2575
2576up:
2577 { typedefTable.up( forall ); forall = false; }
2578 ;
2579
2580down:
2581 { typedefTable.down(); }
2582 ;
2583
2584external_definition:
2585 declaration
2586 | external_function_definition
2587 | EXTENSION external_definition // GCC, multiple __extension__ allowed, meaning unknown
2588 {
2589 distExt( $2 ); // mark all fields in list
2590 $$ = $2;
2591 }
2592 | ASM '(' string_literal ')' ';' // GCC, global assembler statement
2593 {
2594 $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( false, $3, 0 ) ) );
2595 }
2596 | EXTERN STRINGliteral // C++-style linkage specifier
2597 {
2598 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
2599 linkage = LinkageSpec::update( yylloc, linkage, $2 );
2600 }
2601 '{' up external_definition_list_opt down '}'
2602 {
2603 linkage = linkageStack.top();
2604 linkageStack.pop();
2605 $$ = $6;
2606 }
2607 | type_qualifier_list
2608 {
2609 if ( $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2610 if ( $1->type->forall ) forall = true; // remember generic type
2611 }
2612 '{' up external_definition_list_opt down '}' // CFA, namespace
2613 {
2614 distQual( $5, $1 );
2615 forall = false;
2616 $$ = $5;
2617 }
2618 | declaration_qualifier_list
2619 {
2620 if ( $1->type && $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2621 if ( $1->type && $1->type->forall ) forall = true; // remember generic type
2622 }
2623 '{' up external_definition_list_opt down '}' // CFA, namespace
2624 {
2625 distQual( $5, $1 );
2626 forall = false;
2627 $$ = $5;
2628 }
2629 | declaration_qualifier_list type_qualifier_list
2630 {
2631 if ( ($1->type && $1->type->qualifiers.val) || $2->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2632 if ( ($1->type && $1->type->forall) || $2->type->forall ) forall = true; // remember generic type
2633 }
2634 '{' up external_definition_list_opt down '}' // CFA, namespace
2635 {
2636 distQual( $6, $1->addQualifiers( $2 ) );
2637 forall = false;
2638 $$ = $6;
2639 }
2640 ;
2641
2642external_function_definition:
2643 function_definition
2644 // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2645 // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2646 // Parsing is possible because function_definition does not appear in the context of an expression (nested
2647 // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2648 // declaration must still have a type_specifier. OBSOLESCENT (see 1)
2649 | function_declarator compound_statement
2650 { $$ = $1->addFunctionBody( $2 ); }
2651 | KR_function_declarator KR_parameter_list_opt compound_statement
2652 { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
2653 ;
2654
2655with_clause_opt:
2656 // empty
2657 { $$ = nullptr; forall = false; }
2658 | WITH '(' tuple_expression_list ')'
2659 { $$ = $3; forall = false; }
2660 ;
2661
2662function_definition:
2663 cfa_function_declaration with_clause_opt compound_statement // CFA
2664 {
2665 // Add the function body to the last identifier in the function definition list, i.e., foo3:
2666 // [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2667 $1->get_last()->addFunctionBody( $3, $2 );
2668 $$ = $1;
2669 }
2670 | declaration_specifier function_declarator with_clause_opt compound_statement
2671 {
2672 rebindForall( $1, $2 );
2673 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2674 }
2675 | declaration_specifier variable_type_redeclarator with_clause_opt compound_statement
2676 {
2677 rebindForall( $1, $2 );
2678 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2679 }
2680 // handles default int return type, OBSOLESCENT (see 1)
2681 | type_qualifier_list function_declarator with_clause_opt compound_statement
2682 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2683 // handles default int return type, OBSOLESCENT (see 1)
2684 | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2685 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2686 // handles default int return type, OBSOLESCENT (see 1)
2687 | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2688 { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2689
2690 // Old-style K&R function definition, OBSOLESCENT (see 4)
2691 | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2692 {
2693 rebindForall( $1, $2 );
2694 $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2695 }
2696 // handles default int return type, OBSOLESCENT (see 1)
2697 | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2698 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2699 // handles default int return type, OBSOLESCENT (see 1)
2700 | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2701 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2702 // handles default int return type, OBSOLESCENT (see 1)
2703 | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2704 { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2705 ;
2706
2707declarator:
2708 variable_declarator
2709 | variable_type_redeclarator
2710 | function_declarator
2711 ;
2712
2713subrange:
2714 constant_expression '~' constant_expression // CFA, integer subrange
2715 { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
2716 ;
2717
2718asm_name_opt: // GCC
2719 // empty
2720 { $$ = nullptr; }
2721 | ASM '(' string_literal ')' attribute_list_opt
2722 {
2723 DeclarationNode * name = new DeclarationNode();
2724 name->asmName = $3;
2725 $$ = name->addQualifiers( $5 );
2726 }
2727 ;
2728
2729attribute_list_opt: // GCC
2730 // empty
2731 { $$ = nullptr; }
2732 | attribute_list
2733 ;
2734
2735attribute_list: // GCC
2736 attribute
2737 | attribute_list attribute
2738 { $$ = $2->addQualifiers( $1 ); }
2739 ;
2740
2741attribute: // GCC
2742 ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2743 { $$ = $4; }
2744 ;
2745
2746attribute_name_list: // GCC
2747 attribute_name
2748 | attribute_name_list ',' attribute_name
2749 { $$ = $3->addQualifiers( $1 ); }
2750 ;
2751
2752attribute_name: // GCC
2753 // empty
2754 { $$ = nullptr; }
2755 | attr_name
2756 { $$ = DeclarationNode::newAttribute( $1 ); }
2757 | attr_name '(' argument_expression_list_opt ')'
2758 { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2759 ;
2760
2761attr_name: // GCC
2762 IDENTIFIER
2763 | quasi_keyword
2764 | TYPEDEFname
2765 | TYPEGENname
2766 | FALLTHROUGH
2767 { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2768 | CONST
2769 { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2770 ;
2771
2772// ============================================================================
2773// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2774// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2775// in:
2776//
2777// int (*f())[10] { ... };
2778// ... (*f())[3] += 1; // definition mimics usage
2779//
2780// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2781// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2782// ============================================================================
2783
2784// ----------------------------------------------------------------------------
2785// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2786// to define a variable or function prototype, e.g.:
2787//
2788// valid declaration invalid definition
2789// ----------------- ------------------
2790// int f; int f {}
2791// int *f; int *f {}
2792// int f[10]; int f[10] {}
2793// int (*f)(int); int (*f)(int) {}
2794//
2795// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2796// variable_declarator and function_declarator.
2797// ----------------------------------------------------------------------------
2798
2799// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2800// declaring an array of functions versus a pointer to an array of functions.
2801
2802variable_declarator:
2803 paren_identifier attribute_list_opt
2804 { $$ = $1->addQualifiers( $2 ); }
2805 | variable_ptr
2806 | variable_array attribute_list_opt
2807 { $$ = $1->addQualifiers( $2 ); }
2808 | variable_function attribute_list_opt
2809 { $$ = $1->addQualifiers( $2 ); }
2810 ;
2811
2812paren_identifier:
2813 identifier
2814 { $$ = DeclarationNode::newName( $1 ); }
2815 | '(' paren_identifier ')' // redundant parenthesis
2816 { $$ = $2; }
2817 ;
2818
2819variable_ptr:
2820 ptrref_operator variable_declarator
2821 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2822 | ptrref_operator type_qualifier_list variable_declarator
2823 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2824 | '(' variable_ptr ')' attribute_list_opt
2825 { $$ = $2->addQualifiers( $4 ); } // redundant parenthesis
2826 ;
2827
2828variable_array:
2829 paren_identifier array_dimension
2830 { $$ = $1->addArray( $2 ); }
2831 | '(' variable_ptr ')' array_dimension
2832 { $$ = $2->addArray( $4 ); }
2833 | '(' variable_array ')' multi_array_dimension // redundant parenthesis
2834 { $$ = $2->addArray( $4 ); }
2835 | '(' variable_array ')' // redundant parenthesis
2836 { $$ = $2; }
2837 ;
2838
2839variable_function:
2840 '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2841 { $$ = $2->addParamList( $6 ); }
2842 | '(' variable_function ')' // redundant parenthesis
2843 { $$ = $2; }
2844 ;
2845
2846// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2847// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2848// is the same scope. The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2849
2850function_declarator:
2851 function_no_ptr attribute_list_opt
2852 { $$ = $1->addQualifiers( $2 ); }
2853 | function_ptr
2854 | function_array attribute_list_opt
2855 { $$ = $1->addQualifiers( $2 ); }
2856 ;
2857
2858function_no_ptr:
2859 paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2860 { $$ = $1->addParamList( $4 ); }
2861 | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2862 { $$ = $2->addParamList( $6 ); }
2863 | '(' function_no_ptr ')' // redundant parenthesis
2864 { $$ = $2; }
2865 ;
2866
2867function_ptr:
2868 ptrref_operator function_declarator
2869 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2870 | ptrref_operator type_qualifier_list function_declarator
2871 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2872 | '(' function_ptr ')'
2873 { $$ = $2; }
2874 ;
2875
2876function_array:
2877 '(' function_ptr ')' array_dimension
2878 { $$ = $2->addArray( $4 ); }
2879 | '(' function_array ')' multi_array_dimension // redundant parenthesis
2880 { $$ = $2->addArray( $4 ); }
2881 | '(' function_array ')' // redundant parenthesis
2882 { $$ = $2; }
2883 ;
2884
2885// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
2886//
2887// f( a, b, c ) int a, *b, c[]; {}
2888//
2889// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
2890// returning arrays and functions versus pointers to arrays and functions.
2891
2892KR_function_declarator:
2893 KR_function_no_ptr
2894 | KR_function_ptr
2895 | KR_function_array
2896 ;
2897
2898KR_function_no_ptr:
2899 paren_identifier '(' identifier_list ')' // function_declarator handles empty parameter
2900 { $$ = $1->addIdList( $3 ); }
2901 | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
2902 { $$ = $2->addParamList( $6 ); }
2903 | '(' KR_function_no_ptr ')' // redundant parenthesis
2904 { $$ = $2; }
2905 ;
2906
2907KR_function_ptr:
2908 ptrref_operator KR_function_declarator
2909 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2910 | ptrref_operator type_qualifier_list KR_function_declarator
2911 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2912 | '(' KR_function_ptr ')'
2913 { $$ = $2; }
2914 ;
2915
2916KR_function_array:
2917 '(' KR_function_ptr ')' array_dimension
2918 { $$ = $2->addArray( $4 ); }
2919 | '(' KR_function_array ')' multi_array_dimension // redundant parenthesis
2920 { $$ = $2->addArray( $4 ); }
2921 | '(' KR_function_array ')' // redundant parenthesis
2922 { $$ = $2; }
2923 ;
2924
2925// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2926//
2927// typedef int foo;
2928// {
2929// int foo; // redefine typedef name in new scope
2930// }
2931//
2932// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2933// and functions versus pointers to arrays and functions.
2934
2935variable_type_redeclarator:
2936 paren_type attribute_list_opt
2937 { $$ = $1->addQualifiers( $2 ); }
2938 | type_ptr
2939 | type_array attribute_list_opt
2940 { $$ = $1->addQualifiers( $2 ); }
2941 | type_function attribute_list_opt
2942 { $$ = $1->addQualifiers( $2 ); }
2943 ;
2944
2945paren_type:
2946 typedef
2947 // hide type name in enclosing scope by variable name
2948 {
2949 // if ( ! typedefTable.existsCurr( *$1->name ) ) {
2950 typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "ID" );
2951 // } else {
2952 // SemanticError( yylloc, string("'") + *$1->name + "' redeclared as different kind of symbol." ); $$ = nullptr;
2953 // } // if
2954 }
2955 | '(' paren_type ')'
2956 { $$ = $2; }
2957 ;
2958
2959type_ptr:
2960 ptrref_operator variable_type_redeclarator
2961 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2962 | ptrref_operator type_qualifier_list variable_type_redeclarator
2963 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2964 | '(' type_ptr ')' attribute_list_opt
2965 { $$ = $2->addQualifiers( $4 ); } // redundant parenthesis
2966 ;
2967
2968type_array:
2969 paren_type array_dimension
2970 { $$ = $1->addArray( $2 ); }
2971 | '(' type_ptr ')' array_dimension
2972 { $$ = $2->addArray( $4 ); }
2973 | '(' type_array ')' multi_array_dimension // redundant parenthesis
2974 { $$ = $2->addArray( $4 ); }
2975 | '(' type_array ')' // redundant parenthesis
2976 { $$ = $2; }
2977 ;
2978
2979type_function:
2980 paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2981 { $$ = $1->addParamList( $4 ); }
2982 | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2983 { $$ = $2->addParamList( $6 ); }
2984 | '(' type_function ')' // redundant parenthesis
2985 { $$ = $2; }
2986 ;
2987
2988// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
2989// typedef name and allows the C99 array options, which can only appear in a parameter list. The pattern precludes
2990// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
2991// pointers to arrays and functions.
2992
2993identifier_parameter_declarator:
2994 paren_identifier attribute_list_opt
2995 { $$ = $1->addQualifiers( $2 ); }
2996 | '&' MUTEX paren_identifier attribute_list_opt
2997 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
2998 | identifier_parameter_ptr
2999 | identifier_parameter_array attribute_list_opt
3000 { $$ = $1->addQualifiers( $2 ); }
3001 | identifier_parameter_function attribute_list_opt
3002 { $$ = $1->addQualifiers( $2 ); }
3003 ;
3004
3005identifier_parameter_ptr:
3006 ptrref_operator identifier_parameter_declarator
3007 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3008 | ptrref_operator type_qualifier_list identifier_parameter_declarator
3009 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3010 | '(' identifier_parameter_ptr ')' attribute_list_opt
3011 { $$ = $2->addQualifiers( $4 ); }
3012 ;
3013
3014identifier_parameter_array:
3015 paren_identifier array_parameter_dimension
3016 { $$ = $1->addArray( $2 ); }
3017 | '(' identifier_parameter_ptr ')' array_dimension
3018 { $$ = $2->addArray( $4 ); }
3019 | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3020 { $$ = $2->addArray( $4 ); }
3021 | '(' identifier_parameter_array ')' // redundant parenthesis
3022 { $$ = $2; }
3023 ;
3024
3025identifier_parameter_function:
3026 paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3027 { $$ = $1->addParamList( $4 ); }
3028 | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3029 { $$ = $2->addParamList( $6 ); }
3030 | '(' identifier_parameter_function ')' // redundant parenthesis
3031 { $$ = $2; }
3032 ;
3033
3034// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3035// e.g.:
3036//
3037// typedef int foo;
3038// forall( otype T ) struct foo;
3039// int f( int foo ); // redefine typedef name in new scope
3040//
3041// and allows the C99 array options, which can only appear in a parameter list.
3042
3043type_parameter_redeclarator:
3044 typedef attribute_list_opt
3045 { $$ = $1->addQualifiers( $2 ); }
3046 | '&' MUTEX typedef attribute_list_opt
3047 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3048 | type_parameter_ptr
3049 | type_parameter_array attribute_list_opt
3050 { $$ = $1->addQualifiers( $2 ); }
3051 | type_parameter_function attribute_list_opt
3052 { $$ = $1->addQualifiers( $2 ); }
3053 ;
3054
3055typedef:
3056 TYPEDEFname
3057 { $$ = DeclarationNode::newName( $1 ); }
3058 | TYPEGENname
3059 { $$ = DeclarationNode::newName( $1 ); }
3060 ;
3061
3062type_parameter_ptr:
3063 ptrref_operator type_parameter_redeclarator
3064 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3065 | ptrref_operator type_qualifier_list type_parameter_redeclarator
3066 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3067 | '(' type_parameter_ptr ')' attribute_list_opt
3068 { $$ = $2->addQualifiers( $4 ); }
3069 ;
3070
3071type_parameter_array:
3072 typedef array_parameter_dimension
3073 { $$ = $1->addArray( $2 ); }
3074 | '(' type_parameter_ptr ')' array_parameter_dimension
3075 { $$ = $2->addArray( $4 ); }
3076 ;
3077
3078type_parameter_function:
3079 typedef '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3080 { $$ = $1->addParamList( $4 ); }
3081 | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3082 { $$ = $2->addParamList( $6 ); }
3083 ;
3084
3085// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3086// which the type applies, e.g.:
3087//
3088// sizeof( int );
3089// sizeof( int * );
3090// sizeof( int [10] );
3091// sizeof( int (*)() );
3092// sizeof( int () );
3093//
3094// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3095// and functions versus pointers to arrays and functions.
3096
3097abstract_declarator:
3098 abstract_ptr
3099 | abstract_array attribute_list_opt
3100 { $$ = $1->addQualifiers( $2 ); }
3101 | abstract_function attribute_list_opt
3102 { $$ = $1->addQualifiers( $2 ); }
3103 ;
3104
3105abstract_ptr:
3106 ptrref_operator
3107 { $$ = DeclarationNode::newPointer( 0, $1 ); }
3108 | ptrref_operator type_qualifier_list
3109 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3110 | ptrref_operator abstract_declarator
3111 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3112 | ptrref_operator type_qualifier_list abstract_declarator
3113 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3114 | '(' abstract_ptr ')' attribute_list_opt
3115 { $$ = $2->addQualifiers( $4 ); }
3116 ;
3117
3118abstract_array:
3119 array_dimension
3120 | '(' abstract_ptr ')' array_dimension
3121 { $$ = $2->addArray( $4 ); }
3122 | '(' abstract_array ')' multi_array_dimension // redundant parenthesis
3123 { $$ = $2->addArray( $4 ); }
3124 | '(' abstract_array ')' // redundant parenthesis
3125 { $$ = $2; }
3126 ;
3127
3128abstract_function:
3129 '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3130 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3131 | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3132 { $$ = $2->addParamList( $6 ); }
3133 | '(' abstract_function ')' // redundant parenthesis
3134 { $$ = $2; }
3135 ;
3136
3137array_dimension:
3138 // Only the first dimension can be empty.
3139 '[' ']'
3140 { $$ = DeclarationNode::newArray( 0, 0, false ); }
3141 | '[' ']' multi_array_dimension
3142 { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
3143 | multi_array_dimension
3144 ;
3145
3146multi_array_dimension:
3147 '[' push assignment_expression pop ']'
3148 { $$ = DeclarationNode::newArray( $3, 0, false ); }
3149 | '[' push '*' pop ']' // C99
3150 { $$ = DeclarationNode::newVarArray( 0 ); }
3151 | multi_array_dimension '[' push assignment_expression pop ']'
3152 { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
3153 | multi_array_dimension '[' push '*' pop ']' // C99
3154 { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3155 ;
3156
3157// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3158// identifier to which the type applies, e.g.:
3159//
3160// int f( int ); // not handled here
3161// int f( int * ); // abstract function-prototype parameter; no parameter name specified
3162// int f( int (*)() ); // abstract function-prototype parameter; no parameter name specified
3163// int f( int (int) ); // abstract function-prototype parameter; no parameter name specified
3164//
3165// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3166// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3167// special meaning of parenthesis around a typedef name:
3168//
3169// ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3170// parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3171// not as redundant parentheses around the identifier."
3172//
3173// For example:
3174//
3175// typedef float T;
3176// int f( int ( T [5] ) ); // see abstract_parameter_declarator
3177// int g( int ( T ( int ) ) ); // see abstract_parameter_declarator
3178// int f( int f1( T a[5] ) ); // see identifier_parameter_declarator
3179// int g( int g1( T g2( int p ) ) ); // see identifier_parameter_declarator
3180//
3181// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3182// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3183// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3184// functions.
3185
3186abstract_parameter_declarator:
3187 abstract_parameter_ptr
3188 | '&' MUTEX attribute_list_opt
3189 { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3190 | abstract_parameter_array attribute_list_opt
3191 { $$ = $1->addQualifiers( $2 ); }
3192 | abstract_parameter_function attribute_list_opt
3193 { $$ = $1->addQualifiers( $2 ); }
3194 ;
3195
3196abstract_parameter_ptr:
3197 ptrref_operator
3198 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3199 | ptrref_operator type_qualifier_list
3200 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3201 | ptrref_operator abstract_parameter_declarator
3202 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3203 | ptrref_operator type_qualifier_list abstract_parameter_declarator
3204 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3205 | '(' abstract_parameter_ptr ')' attribute_list_opt
3206 { $$ = $2->addQualifiers( $4 ); }
3207 ;
3208
3209abstract_parameter_array:
3210 array_parameter_dimension
3211 | '(' abstract_parameter_ptr ')' array_parameter_dimension
3212 { $$ = $2->addArray( $4 ); }
3213 | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3214 { $$ = $2->addArray( $4 ); }
3215 | '(' abstract_parameter_array ')' // redundant parenthesis
3216 { $$ = $2; }
3217 ;
3218
3219abstract_parameter_function:
3220 '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3221 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3222 | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3223 { $$ = $2->addParamList( $6 ); }
3224 | '(' abstract_parameter_function ')' // redundant parenthesis
3225 { $$ = $2; }
3226 ;
3227
3228array_parameter_dimension:
3229 // Only the first dimension can be empty or have qualifiers.
3230 array_parameter_1st_dimension
3231 | array_parameter_1st_dimension multi_array_dimension
3232 { $$ = $1->addArray( $2 ); }
3233 | multi_array_dimension
3234 ;
3235
3236// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3237//
3238// ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3239// a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3240
3241array_parameter_1st_dimension:
3242 '[' ']'
3243 { $$ = DeclarationNode::newArray( 0, 0, false ); }
3244 // multi_array_dimension handles the '[' '*' ']' case
3245 | '[' push type_qualifier_list '*' pop ']' // remaining C99
3246 { $$ = DeclarationNode::newVarArray( $3 ); }
3247 | '[' push type_qualifier_list pop ']'
3248 { $$ = DeclarationNode::newArray( 0, $3, false ); }
3249 // multi_array_dimension handles the '[' assignment_expression ']' case
3250 | '[' push type_qualifier_list assignment_expression pop ']'
3251 { $$ = DeclarationNode::newArray( $4, $3, false ); }
3252 | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3253 { $$ = DeclarationNode::newArray( $5, $4, true ); }
3254 | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3255 { $$ = DeclarationNode::newArray( $5, $3, true ); }
3256 ;
3257
3258// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3259//
3260// struct S {
3261// int;
3262// int *;
3263// int [10];
3264// int (*)();
3265// };
3266
3267variable_abstract_declarator:
3268 variable_abstract_ptr
3269 | variable_abstract_array attribute_list_opt
3270 { $$ = $1->addQualifiers( $2 ); }
3271 | variable_abstract_function attribute_list_opt
3272 { $$ = $1->addQualifiers( $2 ); }
3273 ;
3274
3275variable_abstract_ptr:
3276 ptrref_operator
3277 { $$ = DeclarationNode::newPointer( 0, $1 ); }
3278 | ptrref_operator type_qualifier_list
3279 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3280 | ptrref_operator variable_abstract_declarator
3281 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3282 | ptrref_operator type_qualifier_list variable_abstract_declarator
3283 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3284 | '(' variable_abstract_ptr ')' attribute_list_opt
3285 { $$ = $2->addQualifiers( $4 ); }
3286 ;
3287
3288variable_abstract_array:
3289 array_dimension
3290 | '(' variable_abstract_ptr ')' array_dimension
3291 { $$ = $2->addArray( $4 ); }
3292 | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3293 { $$ = $2->addArray( $4 ); }
3294 | '(' variable_abstract_array ')' // redundant parenthesis
3295 { $$ = $2; }
3296 ;
3297
3298variable_abstract_function:
3299 '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3300 { $$ = $2->addParamList( $6 ); }
3301 | '(' variable_abstract_function ')' // redundant parenthesis
3302 { $$ = $2; }
3303 ;
3304
3305// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3306// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3307
3308cfa_identifier_parameter_declarator_tuple: // CFA
3309 cfa_identifier_parameter_declarator_no_tuple
3310 | cfa_abstract_tuple
3311 | type_qualifier_list cfa_abstract_tuple
3312 { $$ = $2->addQualifiers( $1 ); }
3313 ;
3314
3315cfa_identifier_parameter_declarator_no_tuple: // CFA
3316 cfa_identifier_parameter_ptr
3317 | cfa_identifier_parameter_array
3318 ;
3319
3320cfa_identifier_parameter_ptr: // CFA
3321 // No SUE declaration in parameter list.
3322 ptrref_operator type_specifier_nobody
3323 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3324 | type_qualifier_list ptrref_operator type_specifier_nobody
3325 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3326 | ptrref_operator cfa_abstract_function
3327 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3328 | type_qualifier_list ptrref_operator cfa_abstract_function
3329 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3330 | ptrref_operator cfa_identifier_parameter_declarator_tuple
3331 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3332 | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3333 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3334 ;
3335
3336cfa_identifier_parameter_array: // CFA
3337 // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3338 // shift/reduce conflict with new-style empty (void) function return type.
3339 '[' ']' type_specifier_nobody
3340 { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3341 | cfa_array_parameter_1st_dimension type_specifier_nobody
3342 { $$ = $2->addNewArray( $1 ); }
3343 | '[' ']' multi_array_dimension type_specifier_nobody
3344 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3345 | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3346 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3347 | multi_array_dimension type_specifier_nobody
3348 { $$ = $2->addNewArray( $1 ); }
3349
3350 | '[' ']' cfa_identifier_parameter_ptr
3351 { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3352 | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3353 { $$ = $2->addNewArray( $1 ); }
3354 | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3355 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3356 | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3357 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3358 | multi_array_dimension cfa_identifier_parameter_ptr
3359 { $$ = $2->addNewArray( $1 ); }
3360 ;
3361
3362cfa_array_parameter_1st_dimension:
3363 '[' push type_qualifier_list '*' pop ']' // remaining C99
3364 { $$ = DeclarationNode::newVarArray( $3 ); }
3365 | '[' push type_qualifier_list assignment_expression pop ']'
3366 { $$ = DeclarationNode::newArray( $4, $3, false ); }
3367 | '[' push declaration_qualifier_list assignment_expression pop ']'
3368 // declaration_qualifier_list must be used because of shift/reduce conflict with
3369 // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3370 // appear in this context.
3371 { $$ = DeclarationNode::newArray( $4, $3, true ); }
3372 | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3373 { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3374 ;
3375
3376// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3377// identifier to which the type applies, e.g.:
3378//
3379// [int] f( int ); // abstract variable parameter; no parameter name specified
3380// [int] f( [int] (int) ); // abstract function-prototype parameter; no parameter name specified
3381//
3382// These rules need LR(3):
3383//
3384// cfa_abstract_tuple identifier_or_type_name
3385// '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
3386//
3387// since a function return type can be syntactically identical to a tuple type:
3388//
3389// [int, int] t;
3390// [int, int] f( int );
3391//
3392// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3393// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3394// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3395// duplicated when appearing with cfa_function_specifier.
3396
3397cfa_abstract_declarator_tuple: // CFA
3398 cfa_abstract_tuple
3399 | type_qualifier_list cfa_abstract_tuple
3400 { $$ = $2->addQualifiers( $1 ); }
3401 | cfa_abstract_declarator_no_tuple
3402 ;
3403
3404cfa_abstract_declarator_no_tuple: // CFA
3405 cfa_abstract_ptr
3406 | cfa_abstract_array
3407 ;
3408
3409cfa_abstract_ptr: // CFA
3410 ptrref_operator type_specifier
3411 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3412 | type_qualifier_list ptrref_operator type_specifier
3413 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3414 | ptrref_operator cfa_abstract_function
3415 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3416 | type_qualifier_list ptrref_operator cfa_abstract_function
3417 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3418 | ptrref_operator cfa_abstract_declarator_tuple
3419 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3420 | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3421 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3422 ;
3423
3424cfa_abstract_array: // CFA
3425 // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3426 // empty (void) function return type.
3427 '[' ']' type_specifier
3428 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3429 | '[' ']' multi_array_dimension type_specifier
3430 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3431 | multi_array_dimension type_specifier
3432 { $$ = $2->addNewArray( $1 ); }
3433 | '[' ']' cfa_abstract_ptr
3434 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3435 | '[' ']' multi_array_dimension cfa_abstract_ptr
3436 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3437 | multi_array_dimension cfa_abstract_ptr
3438 { $$ = $2->addNewArray( $1 ); }
3439 ;
3440
3441cfa_abstract_tuple: // CFA
3442 '[' push cfa_abstract_parameter_list pop ']'
3443 { $$ = DeclarationNode::newTuple( $3 ); }
3444 | '[' push type_specifier_nobody ELLIPSIS pop ']'
3445 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3446 | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
3447 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3448 ;
3449
3450cfa_abstract_function: // CFA
3451// '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
3452// { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3453 cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
3454 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3455 | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
3456 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3457 ;
3458
3459// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3460// each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3461//
3462// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3463// the declaration specifiers in a declaration is an obsolescent feature."
3464//
3465// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3466// prototype-format parameter type declarators) is an obsolescent feature."
3467//
3468// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3469// declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3470
3471//************************* MISCELLANEOUS ********************************
3472
3473comma_opt: // redundant comma
3474 // empty
3475 | ','
3476 ;
3477
3478default_initialize_opt:
3479 // empty
3480 { $$ = nullptr; }
3481 | '=' assignment_expression
3482 { $$ = $2; }
3483 ;
3484
3485%%
3486
3487// ----end of grammar----
3488
3489// Local Variables: //
3490// mode: c++ //
3491// tab-width: 4 //
3492// compile-command: "make install" //
3493// End: //
Note: See TracBrowser for help on using the repository browser.