source: src/Parser/parser.yy@ 71ca5b9

Last change on this file since 71ca5b9 was 857b5f9, checked in by Andrew Beach <ajbeach@…>, 8 months ago

CountExpr -> CountofExpr. Actually the main fix was making countof use the same pattern as sizeof/alignof, using a typeof to combine the two cases and have one field instead of two.
  • Property mode set to 100644
File size: 179.9 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author : Peter A. Buhr
10// Created On : Sat Sep 1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Fri Jan 17 14:35:08 2025
13// Update Count : 6935
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS. While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks. Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed. Most of the syntactic extensions from
27// ANSI90 to ANSI11 C are marked with the comment "C99/C11".
28
29// This grammar also has two levels of extensions. The first extensions cover most of the GCC C extensions. All of the
30// syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall (CFA), which
31// fixes several of C's outstanding problems and extends C with many modern language concepts. All of the syntactic
32// extensions for CFA C are marked with the comment "CFA".
33
34%{
35#define YYDEBUG_LEXER_TEXT( yylval ) // lexer loads this up each time
36#define YYDEBUG 1 // get the pretty debugging code to compile
37#define YYERROR_VERBOSE // more information in syntax errors
38
39#undef __GNUC_MINOR__
40
41#include <cstdio>
42#include <sstream>
43#include <stack>
44using namespace std;
45
46#include "DeclarationNode.hpp" // for DeclarationNode, ...
47#include "ExpressionNode.hpp" // for ExpressionNode, ...
48#include "InitializerNode.hpp" // for InitializerNode, ...
49#include "ParserTypes.hpp"
50#include "StatementNode.hpp" // for build_...
51#include "TypedefTable.hpp"
52#include "TypeData.hpp"
53#include "AST/Type.hpp" // for BasicType, BasicKind
54#include "Common/SemanticError.hpp" // error_str
55#include "Common/Utility.hpp" // for maybeMoveBuild, maybeBuild, CodeLo...
56
57// lex uses __null in a boolean context, it's fine.
58#ifdef __clang__
59#pragma GCC diagnostic ignored "-Wparentheses-equality"
60#endif
61
62extern DeclarationNode * parseTree;
63extern ast::Linkage::Spec linkage;
64extern TypedefTable typedefTable;
65
66stack<ast::Linkage::Spec> linkageStack;
67
68bool appendStr( string & to, string & from ) {
69 // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
70 // "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
71 // the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
72 // easier to let the C compiler handle this case.
73 //
74 // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
75 // without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
76 // e.g., u"a" U"b" L"c" is disallowed.
77
78 if ( from[0] != '"' ) { // encoding ?
79 if ( to[0] != '"' ) { // encoding ?
80 if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
81 yyerror( "non-matching string encodings for string-literal concatenation" );
82 return false; // parse error, must call YYERROR in action
83 } else if ( from[1] == '8' ) {
84 from.erase( 0, 1 ); // remove 2nd encoding
85 } // if
86 } else {
87 if ( from[1] == '8' ) { // move encoding to start
88 to = "u8" + to;
89 from.erase( 0, 1 ); // remove 2nd encoding
90 } else {
91 to = from[0] + to;
92 } // if
93 } // if
94 from.erase( 0, 1 ); // remove 2nd encoding
95 } // if
96 to += " " + from; // concatenated into single string
97 return true;
98} // appendStr
99
100DeclarationNode * distAttr( DeclarationNode * typeSpec, DeclarationNode * declList ) {
101 // Distribute type specifier across all declared variables, e.g., static, const, __attribute__.
102 assert( declList );
103
104 // Do not distribute attributes for aggregates because the attributes surrounding the aggregate belong it not the
105 // variables in the declaration list, e.g.,
106 //
107 // struct __attribute__(( aligned(128) )) S { ...
108 // } v1 __attribute__(( aligned(64) )), v2 __attribute__(( aligned(32) )), v3;
109 // struct S v4;
110 //
111 // v1 => 64, v2 =>32, v3 => 128, v2 => 128
112 //
113 // Anonymous aggregates are a special case because there is no aggregate to bind the attribute to; hence it floats
114 // to the declaration list.
115 //
116 // struct __attribute__(( aligned(128) )) /*anonymous */ { ... } v1;
117 //
118 // v1 => 128
119
120 bool copyattr = ! (typeSpec->type && typeSpec->type->kind == TypeData::Aggregate && ! typeSpec->type->aggregate.anon );
121
122 // addType copies the type information for the aggregate instances from typeSpec into cl's aggInst.aggregate.
123 DeclarationNode * cl = (new DeclarationNode)->addType( typeSpec ); // typeSpec IS DELETED!!!
124
125 // Start at second variable in declaration list and clone the type specifiers for each variable.
126 for ( DeclarationNode * cur = declList->next ; cur != nullptr; cur = cur->next ) {
127 cl->cloneBaseType( cur, copyattr ); // cur is modified
128 } // for
129
130 // Add first variable in declaration list with hidden type information in aggInst.aggregate, which is used by
131 // extractType to recover the type for the aggregate instances.
132 declList->addType( cl, copyattr ); // cl IS DELETED!!!
133 return declList;
134} // distAttr
135
136void distExt( DeclarationNode * declaration ) {
137 // distribute EXTENSION across all declarations
138 for ( DeclarationNode *iter = declaration ; iter != nullptr ; iter = iter->next ) {
139 iter->set_extension( true );
140 } // for
141} // distExt
142
143void distInl( DeclarationNode * declaration ) {
144 // distribute INLINE across all declarations
145 for ( DeclarationNode *iter = declaration ; iter != nullptr ; iter = iter->next ) {
146 iter->set_inLine( true );
147 } // for
148} // distInl
149
150void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
151 // distribute qualifiers across all non-variable declarations in a distribution statemement
152 for ( DeclarationNode * iter = declaration ; iter != nullptr ; iter = iter->next ) {
153 // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
154 // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
155 // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
156 // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
157 DeclarationNode * clone = qualifiers->clone();
158 if ( qualifiers->type ) { // forall clause ? (handles SC)
159 if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
160 swap( clone->type->forall, iter->type->aggregate.params );
161 iter->addQualifiers( clone );
162 } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
163 // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
164 DeclarationNode newnode;
165 swap( newnode.type, iter->type->aggInst.aggregate );
166 swap( clone->type->forall, newnode.type->aggregate.params );
167 newnode.addQualifiers( clone );
168 swap( newnode.type, iter->type->aggInst.aggregate );
169 } else if ( iter->type->kind == TypeData::Function ) { // routines ?
170 swap( clone->type->forall, iter->type->forall );
171 iter->addQualifiers( clone );
172 } // if
173 } else { // just SC qualifiers
174 iter->addQualifiers( clone );
175 } // if
176 } // for
177 delete qualifiers;
178} // distQual
179
180// There is an ambiguity for inline generic-routine return-types and generic routines.
181// forall( otype T ) struct S { int i; } bar( T ) {}
182// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
183// forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
184// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
185// forall( otype T ) struct S { int T; };
186// forall( otype W ) bar( W ) {}
187
188void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
189 if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
190 funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
191 declSpec->type->aggregate.params = nullptr;
192 } // if
193} // rebindForall
194
195string * build_postfix_name( string * name ) {
196 *name = string("__postfix_func_") + *name;
197 return name;
198} // build_postfix_name
199
200DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
201 if ( fieldList == nullptr ) {
202 if ( !( typeSpec->type && typeSpec->type->kind == TypeData::Aggregate ) ) { // int; no fieldList
203 // printf( "fieldDecl1 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
204 SemanticWarning( yylloc, Warning::SuperfluousDecl );
205 return nullptr;
206 } // if
207 // printf( "fieldDecl2 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
208 fieldList = DeclarationNode::newName( nullptr ); // struct S { ... } no fieldList
209 } // if
210
211 // printf( "fieldDecl3 typeSpec %p\n", typeSpec ); typeSpec->print( std::cout, 0 );
212 DeclarationNode * temp = distAttr( typeSpec, fieldList ); // mark all fields in list
213 // printf( "fieldDecl4 temp %p\n", temp ); temp->print( std::cout, 0 );
214 return temp;
215} // fieldDecl
216
217#define NEW_ZERO new ExpressionNode( build_constantInteger( yylloc, *new string( "0" ) ) )
218#define NEW_ONE new ExpressionNode( build_constantInteger( yylloc, *new string( "1" ) ) )
219#define UPDOWN( compop, left, right ) (compop == OperKinds::LThan || compop == OperKinds::LEThan ? left : right)
220#define MISSING_ANON_FIELD "illegal syntax, missing loop fields with an anonymous loop index is meaningless as loop index is unavailable in loop body."
221#define MISSING_LOW "illegal syntax, missing low value for ascanding range so index is uninitialized."
222#define MISSING_HIGH "illegal syntax, missing high value for descending range so index is uninitialized."
223
224static ForCtrl * makeForCtrl( const CodeLocation & location, DeclarationNode * init, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
225 // Wrap both comp/inc if they are non-null.
226 if ( comp ) comp = new ExpressionNode( build_binary_val( location,
227 compop,
228 new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
229 comp ) );
230 if ( inc ) inc = new ExpressionNode( build_binary_val( location,
231 // choose += or -= for upto/downto
232 compop == OperKinds::LThan || compop == OperKinds::LEThan ? OperKinds::PlusAssn : OperKinds::MinusAssn,
233 new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
234 inc ) );
235 // The StatementNode call frees init->name, it must happen later.
236 return new ForCtrl( new StatementNode( init ), comp, inc );
237}
238
239ForCtrl * forCtrl( const CodeLocation & location, DeclarationNode * index, ExpressionNode * start, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
240 if ( index->initializer ) {
241 SemanticError( yylloc, "illegal syntax, direct initialization disallowed. Use instead: type var; initialization ~ comparison ~ increment." );
242 } // if
243 if ( index->next ) {
244 SemanticError( yylloc, "illegal syntax, multiple loop indexes disallowed in for-loop declaration." );
245 } // if
246 DeclarationNode * initDecl = index->addInitializer( new InitializerNode( start ) );
247 return makeForCtrl( location, initDecl, compop, comp, inc );
248} // forCtrl
249
250ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, string * index, ExpressionNode * start, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
251 ast::ConstantExpr * constant = dynamic_cast<ast::ConstantExpr *>(type->expr.get());
252 if ( constant && (constant->rep == "0" || constant->rep == "1") ) {
253 type = new ExpressionNode( new ast::CastExpr( location, maybeMoveBuild(type), new ast::BasicType( ast::BasicKind::SignedInt ) ) );
254 } // if
255 DeclarationNode * initDecl = distAttr(
256 DeclarationNode::newTypeof( type, true ),
257 DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) )
258 );
259 return makeForCtrl( location, initDecl, compop, comp, inc );
260} // forCtrl
261
262#define MISSING_LOOP_INDEX "illegal syntax, only a single identifier or declaration allowed in initialization, e.g., for ( i; ... ) or for ( int i; ... ). Expression disallowed."
263
264ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
265 if ( auto identifier = dynamic_cast<ast::NameExpr *>(index->expr.get()) ) {
266 return forCtrl( location, type, new string( identifier->name ), start, compop, comp, inc );
267 } else {
268 SemanticError( yylloc, MISSING_LOOP_INDEX ); return nullptr;
269 } // if
270} // forCtrl
271
272ForCtrl * enumRangeCtrl( ExpressionNode * index_expr, OperKinds compop, ExpressionNode * range_over_expr, DeclarationNode * type ) {
273 assert( compop == OperKinds::LEThan || compop == OperKinds::GEThan );
274 if ( auto identifier = dynamic_cast<ast::NameExpr *>(index_expr->expr.get()) ) {
275 DeclarationNode * indexDecl =
276 DeclarationNode::newName( new std::string(identifier->name) )->addType( type );
277 return new ForCtrl( new StatementNode( indexDecl ), range_over_expr, compop );
278 } else {
279 SemanticError( yylloc, MISSING_LOOP_INDEX ); return nullptr;
280 } // if
281} // enumRangeCtrl
282
283static void IdentifierBeforeIdentifier( string & identifier1, string & identifier2, const char * kind ) {
284 SemanticError( yylloc, "illegal syntax, adjacent identifiers \"%s\" and \"%s\" are not meaningful in an %s.\n"
285 "Possible cause is misspelled type name or missing generic parameter.",
286 identifier1.c_str(), identifier2.c_str(), kind );
287} // IdentifierBeforeIdentifier
288
289static void IdentifierBeforeType( string & identifier, const char * kind ) {
290 SemanticError( yylloc, "illegal syntax, identifier \"%s\" cannot appear before a %s.\n"
291 "Possible cause is misspelled storage/CV qualifier, misspelled typename, or missing generic parameter.",
292 identifier.c_str(), kind );
293} // IdentifierBeforeType
294
295bool forall = false; // aggregate have one or more forall qualifiers ?
296
297// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
298#define YYLLOC_DEFAULT(Cur, Rhs, N) \
299if ( N ) { \
300 (Cur).first_line = YYRHSLOC( Rhs, 1 ).first_line; \
301 (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column; \
302 (Cur).last_line = YYRHSLOC( Rhs, N ).last_line; \
303 (Cur).last_column = YYRHSLOC( Rhs, N ).last_column; \
304 (Cur).filename = YYRHSLOC( Rhs, 1 ).filename; \
305} else { \
306 (Cur).first_line = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line; \
307 (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column; \
308 (Cur).filename = YYRHSLOC( Rhs, 0 ).filename; \
309}
310%}
311
312%define parse.error verbose
313
314// Types declaration for productions
315
316%union {
317 // A raw token can be used.
318 Token tok;
319
320 // The general node types hold some generic node or list of nodes.
321 DeclarationNode * decl;
322 InitializerNode * init;
323 ExpressionNode * expr;
324 StatementNode * stmt;
325 ClauseNode * clause;
326 TypeData * type;
327
328 // Special "nodes" containing compound information.
329 CondCtrl * ifctrl;
330 ForCtrl * forctrl;
331 LabelNode * labels;
332
333 // Various flags and single values that become fields later.
334 ast::AggregateDecl::Aggregate aggKey;
335 ast::TypeDecl::Kind tclass;
336 OperKinds oper;
337 bool is_volatile;
338 EnumHiding enum_hiding;
339 ast::ExceptionKind except_kind;
340 // String passes ownership with it.
341 std::string * str;
342
343 // Narrower node types are used to avoid constant unwrapping.
344 ast::WaitForStmt * wfs;
345 ast::WaitUntilStmt::ClauseNode * wucn;
346 ast::GenericExpr * genexpr;
347}
348
349// ************************ TERMINAL TOKENS ********************************
350
351// keywords
352%token TYPEDEF
353%token EXTERN STATIC AUTO REGISTER
354%token THREADLOCALGCC THREADLOCALC11 // GCC, C11
355%token INLINE FORTRAN // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
356%token NORETURN // C11
357%token CONST VOLATILE
358%token RESTRICT // C99
359%token ATOMIC // C11
360%token FORALL MUTEX VIRTUAL VTABLE COERCE // CFA
361%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
362%token BOOL COMPLEX IMAGINARY // C99
363%token INT128 UINT128 FLOAT80 uuFLOAT128 // GCC
364%token FLOAT16 FLOAT32 FLOAT32X FLOAT64 FLOAT64X FLOAT128 FLOAT128X // GCC
365%token FLOAT32X4 FLOAT64X2 SVFLOAT32 SVFLOAT64 SVBOOL // GCC (ARM)
366%token DECIMAL32 DECIMAL64 DECIMAL128 // GCC
367%token ZERO_T ONE_T // CFA
368%token SIZEOF TYPEOF VA_LIST VA_ARG AUTO_TYPE COUNTOF // GCC
369%token OFFSETOF BASETYPEOF TYPEID // CFA
370%token ENUM STRUCT UNION
371%token EXCEPTION // CFA
372%token GENERATOR COROUTINE MONITOR THREAD // CFA
373%token OTYPE FTYPE DTYPE TTYPE TRAIT // CFA
374// %token RESUME // CFA
375%token LABEL // GCC
376%token SUSPEND // CFA
377%token ATTRIBUTE EXTENSION // GCC
378%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
379%token CHOOSE FALLTHROUGH WITH WHEN WAITFOR WAITUNTIL // CFA
380%token CORUN COFOR
381%token DISABLE ENABLE TRY THROW THROWRESUME AT // CFA
382%token ASM // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
383%token ALIGNAS ALIGNOF GENERIC STATICASSERT // C11
384
385// names and constants: lexer differentiates between identifier and typedef names
386%token<tok> IDENTIFIER TYPEDIMname TYPEDEFname TYPEGENname
387%token<tok> TIMEOUT WAND WOR CATCH RECOVER CATCHRESUME FIXUP FINALLY // CFA
388%token<tok> INTEGERconstant CHARACTERconstant STRINGliteral
389%token<tok> DIRECTIVE C23_ATTRIBUTE
390// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
391// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
392// converted into the tuple index (.)(1). e.g., 3.x
393%token<tok> FLOATING_DECIMALconstant FLOATING_FRACTIONconstant FLOATINGconstant
394
395// multi-character operators
396%token ARROW // ->
397%token ICR DECR // ++ --
398%token LS RS // << >>
399%token LE GE EQ NE // <= >= == !=
400%token ANDAND OROR // && ||
401%token ATTR ELLIPSIS // @@ ...
402
403%token EXPassign MULTassign DIVassign MODassign // \= *= /= %=
404%token PLUSassign MINUSassign // += -=
405%token LSassign RSassign // <<= >>=
406%token ANDassign ERassign ORassign // &= ^= |=
407
408%token ErangeUp ErangeUpEq ErangeDown ErangeDownEq // +~ +~=/~= -~ -~=
409%token ATassign // @=
410
411%type<tok> identifier identifier_at identifier_or_type_name attr_name
412%type<tok> quasi_keyword
413%type<expr> string_literal
414%type<str> string_literal_list
415
416%type<enum_hiding> hide_opt visible_hide_opt
417
418// expressions
419%type<expr> constant
420%type<expr> tuple tuple_expression_list
421%type<oper> ptrref_operator unary_operator assignment_operator simple_assignment_operator compound_assignment_operator
422%type<expr> primary_expression postfix_expression unary_expression
423%type<expr> cast_expression_list cast_expression exponential_expression multiplicative_expression additive_expression
424%type<expr> shift_expression relational_expression equality_expression
425%type<expr> AND_expression exclusive_OR_expression inclusive_OR_expression
426%type<expr> logical_AND_expression logical_OR_expression
427%type<expr> conditional_expression constant_expression assignment_expression assignment_expression_opt
428%type<expr> comma_expression comma_expression_opt
429%type<expr> argument_expression_list_opt argument_expression_list argument_expression default_initializer_opt
430%type<ifctrl> conditional_declaration
431%type<forctrl> for_control_expression for_control_expression_list
432%type<oper> upupeq updown updowneq downupdowneq
433%type<expr> subrange
434%type<decl> asm_name_opt
435%type<expr> asm_operands_opt asm_operands_list asm_operand
436%type<labels> label_list
437%type<expr> asm_clobbers_list_opt
438%type<is_volatile> asm_volatile_opt
439%type<expr> handler_predicate_opt
440%type<genexpr> generic_association generic_assoc_list
441
442// statements
443%type<stmt> statement labeled_statement compound_statement
444%type<stmt> statement_decl statement_decl_list statement_list_nodecl
445%type<stmt> selection_statement
446%type<clause> switch_clause_list_opt switch_clause_list
447%type<expr> case_value
448%type<clause> case_clause case_value_list case_label case_label_list
449%type<stmt> iteration_statement jump_statement
450%type<stmt> expression_statement asm_statement
451%type<stmt> with_statement
452%type<expr> with_clause_opt
453%type<stmt> corun_statement cofor_statement
454%type<stmt> exception_statement
455%type<clause> handler_clause finally_clause
456%type<except_kind> handler_key
457%type<stmt> mutex_statement
458%type<expr> when_clause when_clause_opt waitfor waituntil timeout
459%type<stmt> waitfor_statement waituntil_statement
460%type<wfs> wor_waitfor_clause
461%type<wucn> waituntil_clause wand_waituntil_clause wor_waituntil_clause
462
463// declarations
464%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
465%type<decl> abstract_parameter_declarator_opt abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array
466 abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension abstract_parameter_declaration
467
468%type<aggKey> aggregate_key aggregate_data aggregate_control
469%type<decl> aggregate_type aggregate_type_nobody
470
471%type<decl> assertion assertion_list assertion_list_opt
472
473%type<expr> bit_subrange_size_opt bit_subrange_size
474
475%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
476%type<type> basic_type_name_type
477%type<type> vtable vtable_opt default_opt
478
479%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
480
481%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
482%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
483
484%type<decl> elaborated_type elaborated_type_nobody
485
486%type<decl> enumerator_list enum_type enum_type_nobody enum_key enumerator_type
487%type<init> enumerator_value_opt
488
489%type<decl> external_definition external_definition_list external_definition_list_opt
490
491%type<decl> exception_declaration
492
493%type<decl> field_declaration_list_opt field_declaration field_declaring_list field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
494%type<expr> field field_name_list field_name fraction_constants_opt
495
496%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
497
498%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
499%type<decl> identifier_list
500
501%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
502%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
503%type<decl> cfa_abstract_ptr cfa_abstract_tuple
504
505%type<decl> cfa_array_parameter_1st_dimension
506
507%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
508%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
509
510%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
511%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
512
513%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_list_ellipsis_opt
514
515%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
516
517%type<decl> c_declaration static_assert
518%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
519%type<decl> KR_parameter_list KR_parameter_list_opt
520
521%type<decl> parameter_declaration parameter_list parameter_list_ellipsis_opt
522
523%type<decl> paren_identifier paren_type
524
525%type<decl> storage_class storage_class_list
526
527%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
528
529%type<tclass> type_class new_type_class
530%type<decl> type_declarator type_declarator_name type_declaring_list
531
532%type<decl> type_declaration_specifier type_type_specifier
533%type<type> type_name typegen_name
534%type<decl> typedef_name typedef_declaration typedef_expression
535
536%type<decl> variable_type_redeclarator variable_type_ptr variable_type_array variable_type_function
537%type<decl> general_function_declarator function_type_redeclarator function_type_array function_type_no_ptr function_type_ptr
538
539%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
540
541%type<decl> type type_no_function
542%type<decl> type_parameter type_parameter_list type_initializer_opt
543
544%type<expr> type_parameters_opt type_list array_type_list // array_dimension_list
545
546%type<decl> type_qualifier forall type_qualifier_list_opt type_qualifier_list
547%type<type> type_qualifier_name
548%type<decl> type_specifier type_specifier_nobody
549
550%type<decl> variable_declarator variable_ptr variable_array variable_function
551%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
552
553%type<decl> attribute_list_opt attribute_list attribute attribute_name_list attribute_name
554
555// initializers
556%type<init> initializer initializer_list_opt initializer_opt
557
558// designators
559%type<expr> designator designator_list designation
560
561
562// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
563// .---------. matches IF '(' comma_expression ')' statement . (reduce)
564// if ( C ) S1 else S2
565// `-----------------' matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
566// Similar issues exit with the waitfor statement.
567
568// Order of these lines matters (low-to-high precedence). THEN is left associative over WAND/WOR/TIMEOUT/ELSE, WAND/WOR
569// is left associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
570%precedence THEN // rule precedence for IF/WAITFOR statement
571%precedence ANDAND // token precedence for start of WAND in WAITFOR statement
572%precedence WAND // token precedence for start of WAND in WAITFOR statement
573%precedence OROR // token precedence for start of WOR in WAITFOR statement
574%precedence WOR // token precedence for start of WOR in WAITFOR statement
575%precedence TIMEOUT // token precedence for start of TIMEOUT in WAITFOR statement
576%precedence CATCH // token precedence for start of TIMEOUT in WAITFOR statement
577%precedence RECOVER // token precedence for start of TIMEOUT in WAITFOR statement
578%precedence CATCHRESUME // token precedence for start of TIMEOUT in WAITFOR statement
579%precedence FIXUP // token precedence for start of TIMEOUT in WAITFOR statement
580%precedence FINALLY // token precedence for start of TIMEOUT in WAITFOR statement
581%precedence ELSE // token precedence for start of else clause in IF/WAITFOR statement
582
583
584// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
585// forall( otype T ) struct Foo { T v; };
586// .-----. matches pointer to function returning a generic (which is impossible without a type)
587// Foo ( *fp )( int );
588// `---' matches start of TYPEGENname '('
589// must be:
590// Foo( int ) ( *fp )( int );
591// The same problem occurs here:
592// forall( otype T ) struct Foo { T v; } ( *fp )( int );
593// must be:
594// forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
595
596// Order of these lines matters (low-to-high precedence).
597%precedence TYPEGENname
598%precedence '}'
599%precedence '('
600
601// %precedence RESUME
602// %precedence '{'
603// %precedence ')'
604
605%locations // support location tracking for error messages
606
607%start translation_unit // parse-tree root
608
609%%
610// ************************ Namespace Management ********************************
611
612// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
613// which are lexically identical.
614//
615// typedef int foo; // identifier foo must now be scanned as TYPEDEFname
616// foo f; // to allow it to appear in this context
617//
618// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
619// between syntactic and semantic constructs. Cforall compounds this problem by introducing type names local to the
620// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
621// generators" -- parameterized types. This latter type name creates a third class of identifiers, "TYPEGENname", which
622// must be distinguished by the lexical scanner.
623//
624// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
625// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
626// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
627// each context that introduces a name scope, a new level is created in the type table and that level is popped on
628// exiting the scope. Since type names can be local to a particular declaration, each declaration is itself a scope.
629// This requires distinguishing between type names that are local to the current declaration scope and those that
630// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
631//
632// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
633// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
634// around the list separator.
635//
636// XXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
637// push pop push pop
638
639push:
640 { typedefTable.enterScope(); }
641 ;
642
643pop:
644 { typedefTable.leaveScope(); }
645 ;
646
647// ************************ CONSTANTS ********************************
648
649constant:
650 // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
651 INTEGERconstant { $$ = new ExpressionNode( build_constantInteger( yylloc, *$1 ) ); }
652 | FLOATING_DECIMALconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
653 | FLOATING_FRACTIONconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
654 | FLOATINGconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
655 | CHARACTERconstant { $$ = new ExpressionNode( build_constantChar( yylloc, *$1 ) ); }
656 ;
657
658quasi_keyword: // CFA
659 TIMEOUT
660 | WAND
661 | WOR
662 | CATCH
663 | RECOVER
664 | CATCHRESUME
665 | FIXUP
666 | FINALLY
667 ;
668
669identifier:
670 IDENTIFIER
671 | quasi_keyword
672 ;
673
674identifier_at:
675 identifier
676 | '@' // CFA
677 { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
678 ;
679
680identifier_or_type_name:
681 identifier
682 | TYPEDEFname
683 | TYPEGENname
684 ;
685
686string_literal:
687 string_literal_list { $$ = new ExpressionNode( build_constantStr( yylloc, *$1 ) ); }
688 ;
689
690string_literal_list: // juxtaposed strings are concatenated
691 STRINGliteral { $$ = $1; } // conversion from tok to str
692 | string_literal_list STRINGliteral
693 {
694 if ( ! appendStr( *$1, *$2 ) ) YYERROR; // append 2nd juxtaposed string to 1st
695 delete $2; // allocated by lexer
696 $$ = $1; // conversion from tok to str
697 }
698 ;
699
700// ************************ EXPRESSIONS ********************************
701
702primary_expression:
703 IDENTIFIER // typedef name cannot be used as a variable name
704 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
705 | quasi_keyword
706 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
707 | TYPEDIMname // CFA, generic length argument
708 { $$ = new ExpressionNode( build_dimensionref( yylloc, $1 ) ); }
709 | tuple
710 | '(' comma_expression ')'
711 { $$ = $2; }
712 | '(' compound_statement ')' // GCC, lambda expression
713 { $$ = new ExpressionNode( new ast::StmtExpr( yylloc, dynamic_cast<ast::CompoundStmt *>( maybeMoveBuild( $2 ) ) ) ); }
714 | type_name '.' identifier // CFA, nested type
715 { $$ = new ExpressionNode( build_qualified_expr( yylloc, DeclarationNode::newFromTypeData( $1 ), build_varref( yylloc, $3 ) ) ); }
716 | type_name '.' '[' field_name_list ']' // CFA, nested type / tuple field selector
717 { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
718 | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
719 {
720 // add the missing control expression to the GenericExpr and return it
721 $5->control = maybeMoveBuild( $3 );
722 $$ = new ExpressionNode( $5 );
723 }
724 // | RESUME '(' comma_expression ')'
725 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
726 // | RESUME '(' comma_expression ')' compound_statement
727 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
728 | IDENTIFIER IDENTIFIER // invalid syntax rule
729 { IdentifierBeforeIdentifier( *$1.str, *$2.str, "expression" ); $$ = nullptr; }
730 | IDENTIFIER type_qualifier // invalid syntax rule
731 { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
732 | IDENTIFIER storage_class // invalid syntax rule
733 { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
734 | IDENTIFIER basic_type_name // invalid syntax rule
735 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
736 | IDENTIFIER TYPEDEFname // invalid syntax rule
737 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
738 | IDENTIFIER TYPEGENname // invalid syntax rule
739 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
740 ;
741
742generic_assoc_list: // C11
743 generic_association
744 | generic_assoc_list ',' generic_association
745 {
746 // steal the association node from the singleton and delete the wrapper
747 assert( 1 == $3->associations.size() );
748 $1->associations.push_back( $3->associations.front() );
749 delete $3;
750 $$ = $1;
751 }
752 ;
753
754generic_association: // C11
755 type_no_function ':' assignment_expression
756 {
757 // create a GenericExpr wrapper with one association pair
758 $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuildType( $1 ), maybeMoveBuild( $3 ) } } );
759 }
760 | DEFAULT ':' assignment_expression
761 { $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuild( $3 ) } } ); }
762 ;
763
764postfix_expression:
765 primary_expression
766 | postfix_expression '[' assignment_expression ',' tuple_expression_list ']'
767 // Historic, transitional: Disallow commas in subscripts.
768 // Switching to this behaviour may help check if a C compatibilty case uses comma-exprs in subscripts.
769 // Current: Commas in subscripts make tuples.
770 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, new ExpressionNode( build_tuple( yylloc, $3->set_last( $5 ) ) ) ) ); }
771 | postfix_expression '[' assignment_expression ']'
772 // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
773 // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
774 // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
775 // equivalent to the old x[i,j].
776 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
777 | constant '[' assignment_expression ']' // 3[a], 'a'[a], 3.5[a]
778 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
779 | string_literal '[' assignment_expression ']' // "abc"[3], 3["abc"]
780 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
781 | postfix_expression '{' argument_expression_list_opt '}' // CFA, constructor call
782 {
783 Token fn;
784 fn.str = new std::string( "?{}" ); // location undefined - use location of '{'?
785 $$ = new ExpressionNode( new ast::ConstructorExpr( yylloc, build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), $1->set_last( $3 ) ) ) );
786 }
787 | postfix_expression '(' argument_expression_list_opt ')'
788 { $$ = new ExpressionNode( build_func( yylloc, $1, $3 ) ); }
789 | VA_ARG '(' primary_expression ',' declaration_specifier_nobody abstract_parameter_declarator_opt ')'
790 { $$ = new ExpressionNode( build_va_arg( yylloc, $3, ( $6 ? $6->addType( $5 ) : $5 ) ) ); }
791 | postfix_expression '`' identifier // CFA, postfix call
792 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
793 | constant '`' identifier // CFA, postfix call
794 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
795 | string_literal '`' identifier // CFA, postfix call
796 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
797
798 // SKULLDUGGERY: The typedef table used for parsing does not store fields in structures. To parse a qualified
799 // name, it is assumed all name-tokens after the first are identifiers, regardless of how the lexer identifies
800 // them. For example:
801 //
802 // struct S;
803 // forall(T) struct T;
804 // union U;
805 // enum E { S, T, E };
806 // struct Z { int S, T, Z, E, U; };
807 // void fred () {
808 // Z z;
809 // z.S; // lexer returns S is TYPEDEFname
810 // z.T; // lexer returns T is TYPEGENname
811 // z.Z; // lexer returns Z is TYPEDEFname
812 // z.U; // lexer returns U is TYPEDEFname
813 // z.E; // lexer returns E is TYPEDEFname
814 // }
815 | postfix_expression '.' identifier_or_type_name
816 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
817
818 | postfix_expression '.' INTEGERconstant // CFA, tuple index
819 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
820 | postfix_expression FLOATING_FRACTIONconstant // CFA, tuple index
821 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 ) ) ); }
822 | postfix_expression '.' '[' field_name_list ']' // CFA, tuple field selector
823 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
824 | postfix_expression '.' aggregate_control
825 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $3, $1 ) ); }
826 | postfix_expression ARROW identifier
827 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
828 | postfix_expression ARROW INTEGERconstant // CFA, tuple index
829 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
830 | postfix_expression ARROW '[' field_name_list ']' // CFA, tuple field selector
831 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
832 | postfix_expression ICR
833 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::IncrPost, $1 ) ); }
834 | postfix_expression DECR
835 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::DecrPost, $1 ) ); }
836 | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
837 { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, new InitializerNode( $5, true ) ) ); }
838 | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
839 { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
840 | '^' primary_expression '{' argument_expression_list_opt '}' // CFA, destructor call
841 {
842 Token fn;
843 fn.str = new string( "^?{}" ); // location undefined
844 $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), $2->set_last( $4 ) ) );
845 }
846 ;
847
848field_name_list: // CFA, tuple field selector
849 field
850 | field_name_list ',' field { $$ = $1->set_last( $3 ); }
851 ;
852
853field: // CFA, tuple field selector
854 field_name
855 | FLOATING_DECIMALconstant field
856 { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), maybeMoveBuild( $2 ) ) ); }
857 | FLOATING_DECIMALconstant '[' field_name_list ']'
858 { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), build_tuple( yylloc, $3 ) ) ); }
859 | field_name '.' field
860 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
861 | field_name '.' '[' field_name_list ']'
862 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
863 | field_name ARROW field
864 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
865 | field_name ARROW '[' field_name_list ']'
866 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
867 ;
868
869field_name:
870 INTEGERconstant fraction_constants_opt
871 { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_constantInteger( yylloc, *$1 ), $2 ) ); }
872 | FLOATINGconstant fraction_constants_opt
873 { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_field_name_FLOATINGconstant( yylloc, *$1 ), $2 ) ); }
874 | identifier_at fraction_constants_opt // CFA, allow anonymous fields
875 {
876 $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_varref( yylloc, $1 ), $2 ) );
877 }
878 ;
879
880fraction_constants_opt:
881 // empty
882 { $$ = nullptr; }
883 | fraction_constants_opt FLOATING_FRACTIONconstant
884 {
885 ast::Expr * constant = build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 );
886 $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( yylloc, $1, constant ) ) : new ExpressionNode( constant );
887 }
888 ;
889
890unary_expression:
891 postfix_expression
892 // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
893 // semantics checks, e.g., ++3, 3--, *3, &&3
894 | constant
895 | string_literal
896 { $$ = $1; }
897 | EXTENSION cast_expression // GCC
898 { $$ = $2->set_extension( true ); }
899 // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
900 // { * X; } // dereference X
901 // { * int X; } // CFA declaration of pointer to int
902 | ptrref_operator cast_expression // CFA
903 {
904 switch ( $1 ) {
905 case OperKinds::AddressOf:
906 $$ = new ExpressionNode( new ast::AddressExpr( maybeMoveBuild( $2 ) ) );
907 break;
908 case OperKinds::PointTo:
909 $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) );
910 break;
911 case OperKinds::And:
912 $$ = new ExpressionNode( new ast::AddressExpr( new ast::AddressExpr( maybeMoveBuild( $2 ) ) ) );
913 break;
914 default:
915 assert( false );
916 }
917 }
918 | unary_operator cast_expression
919 { $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) ); }
920 | ICR unary_expression
921 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Incr, $2 ) ); }
922 | DECR unary_expression
923 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Decr, $2 ) ); }
924 | SIZEOF unary_expression
925 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, new ast::TypeofType( maybeMoveBuild( $2 ) ) ) ); }
926 | SIZEOF '(' type_no_function ')'
927 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
928 | ALIGNOF unary_expression // GCC, variable alignment
929 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, new ast::TypeofType( maybeMoveBuild( $2 ) ) ) ); }
930 | ALIGNOF '(' type_no_function ')' // GCC, type alignment
931 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
932
933 // Cannot use rule "type", which includes cfa_abstract_function, for sizeof/alignof, because of S/R problems on
934 // look ahead, so the cfa_abstract_function is factored out.
935 | SIZEOF '(' cfa_abstract_function ')'
936 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
937 | ALIGNOF '(' cfa_abstract_function ')' // GCC, type alignment
938 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
939
940 | OFFSETOF '(' type_no_function ',' identifier ')'
941 { $$ = new ExpressionNode( build_offsetOf( yylloc, $3, build_varref( yylloc, $5 ) ) ); }
942 | TYPEID '(' type ')'
943 {
944 SemanticError( yylloc, "typeid name is currently unimplemented." ); $$ = nullptr;
945 // $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) );
946 }
947 | COUNTOF unary_expression
948 { $$ = new ExpressionNode( new ast::CountofExpr( yylloc, new ast::TypeofType( maybeMoveBuild( $2 ) ) ) ); }
949 | COUNTOF '(' type_no_function ')'
950 { $$ = new ExpressionNode( new ast::CountofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
951 ;
952
953ptrref_operator:
954 '*' { $$ = OperKinds::PointTo; }
955 | '&' { $$ = OperKinds::AddressOf; }
956 // GCC, address of label must be handled by semantic check for ref,ref,label
957 | ANDAND { $$ = OperKinds::And; }
958 ;
959
960unary_operator:
961 '+' { $$ = OperKinds::UnPlus; }
962 | '-' { $$ = OperKinds::UnMinus; }
963 | '!' { $$ = OperKinds::Neg; }
964 | '~' { $$ = OperKinds::BitNeg; }
965 ;
966
967cast_expression:
968 unary_expression
969 | '(' type_no_function ')' cast_expression
970 { $$ = new ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
971 | '(' aggregate_control '&' ')' cast_expression // CFA
972 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
973 | '(' aggregate_control '*' ')' cast_expression // CFA
974 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
975 | '(' VIRTUAL ')' cast_expression // CFA
976 { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $4 ), nullptr ) ); }
977 | '(' VIRTUAL type_no_function ')' cast_expression // CFA
978 { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $5 ), maybeMoveBuildType( $3 ) ) ); }
979 | '(' RETURN type_no_function ')' cast_expression // CFA (ASCRIPTION)
980 { $$ = new ExpressionNode( build_cast( yylloc, $3, $5, ast::ReturnCast ) ); }
981 | '(' COERCE type_no_function ')' cast_expression // CFA (COERCION)
982 { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
983 | '(' qualifier_cast_list ')' cast_expression // CFA, (modify CVs of cast_expression)
984 { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
985// | '(' type_no_function ')' tuple
986// { $$ = new ast::ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
987 ;
988
989qualifier_cast_list:
990 cast_modifier type_qualifier_name
991 | cast_modifier MUTEX
992 | qualifier_cast_list cast_modifier type_qualifier_name
993 | qualifier_cast_list cast_modifier MUTEX
994 ;
995
996cast_modifier:
997 '-'
998 | '+'
999 ;
1000
1001exponential_expression:
1002 cast_expression
1003 | exponential_expression '\\' cast_expression
1004 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Exp, $1, $3 ) ); }
1005 ;
1006
1007multiplicative_expression:
1008 exponential_expression
1009 | multiplicative_expression '*' exponential_expression
1010 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mul, $1, $3 ) ); }
1011 | multiplicative_expression '/' exponential_expression
1012 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Div, $1, $3 ) ); }
1013 | multiplicative_expression '%' exponential_expression
1014 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mod, $1, $3 ) ); }
1015 ;
1016
1017additive_expression:
1018 multiplicative_expression
1019 | additive_expression '+' multiplicative_expression
1020 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Plus, $1, $3 ) ); }
1021 | additive_expression '-' multiplicative_expression
1022 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Minus, $1, $3 ) ); }
1023 ;
1024
1025shift_expression:
1026 additive_expression
1027 | shift_expression LS additive_expression
1028 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LShift, $1, $3 ) ); }
1029 | shift_expression RS additive_expression
1030 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::RShift, $1, $3 ) ); }
1031 ;
1032
1033relational_expression:
1034 shift_expression
1035 | relational_expression '<' shift_expression
1036 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LThan, $1, $3 ) ); }
1037 | relational_expression '>' shift_expression
1038 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GThan, $1, $3 ) ); }
1039 | relational_expression LE shift_expression
1040 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LEThan, $1, $3 ) ); }
1041 | relational_expression GE shift_expression
1042 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GEThan, $1, $3 ) ); }
1043 ;
1044
1045equality_expression:
1046 relational_expression
1047 | equality_expression EQ relational_expression
1048 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Eq, $1, $3 ) ); }
1049 | equality_expression NE relational_expression
1050 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Neq, $1, $3 ) ); }
1051 ;
1052
1053AND_expression:
1054 equality_expression
1055 | AND_expression '&' equality_expression
1056 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitAnd, $1, $3 ) ); }
1057 ;
1058
1059exclusive_OR_expression:
1060 AND_expression
1061 | exclusive_OR_expression '^' AND_expression
1062 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Xor, $1, $3 ) ); }
1063 ;
1064
1065inclusive_OR_expression:
1066 exclusive_OR_expression
1067 | inclusive_OR_expression '|' exclusive_OR_expression
1068 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitOr, $1, $3 ) ); }
1069 ;
1070
1071logical_AND_expression:
1072 inclusive_OR_expression
1073 | logical_AND_expression ANDAND inclusive_OR_expression
1074 { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::AndExpr ) ); }
1075 ;
1076
1077logical_OR_expression:
1078 logical_AND_expression
1079 | logical_OR_expression OROR logical_AND_expression
1080 { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::OrExpr ) ); }
1081 ;
1082
1083conditional_expression:
1084 logical_OR_expression
1085 | logical_OR_expression '?' comma_expression ':' conditional_expression
1086 { $$ = new ExpressionNode( build_cond( yylloc, $1, $3, $5 ) ); }
1087 | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
1088 { $$ = new ExpressionNode( build_cond( yylloc, $1, nullptr, $4 ) ); }
1089 ;
1090
1091constant_expression:
1092 conditional_expression
1093 ;
1094
1095argument_expression_list_opt:
1096 // empty
1097 { $$ = nullptr; }
1098 | argument_expression_list
1099 ;
1100
1101argument_expression_list:
1102 argument_expression
1103 // | argument_expression_list_opt ',' argument_expression // CFA, allow empty argument
1104 | argument_expression_list ',' argument_expression // no empty argument
1105 { $$ = $1->set_last( $3 ); }
1106 ;
1107
1108argument_expression:
1109 '?' // CFA, default parameter
1110 // { SemanticError( yylloc, "Argument to default parameter is currently unimplemented." ); $$ = nullptr; }
1111 { $$ = new ExpressionNode( build_constantInteger( yylloc, *new string( "2" ) ) ); }
1112 | '?' identifier '=' assignment_expression // CFA, keyword argument
1113 // { SemanticError( yylloc, "keyword argument is currently unimplemented." ); $$ = nullptr; }
1114 { $$ = $4; }
1115 | assignment_expression
1116 ;
1117
1118assignment_expression:
1119 // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
1120 conditional_expression
1121 | unary_expression assignment_operator assignment_expression
1122 {
1123// if ( $2 == OperKinds::AtAssn ) {
1124// SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
1125// } else {
1126 $$ = new ExpressionNode( build_binary_val( yylloc, $2, $1, $3 ) );
1127// } // if
1128 }
1129 | unary_expression '=' '{' initializer_list_opt comma_opt '}'
1130 { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
1131 ;
1132
1133assignment_expression_opt:
1134 // empty
1135 { $$ = nullptr; }
1136 | assignment_expression
1137 ;
1138
1139assignment_operator:
1140 simple_assignment_operator
1141 | compound_assignment_operator
1142 ;
1143
1144simple_assignment_operator:
1145 '=' { $$ = OperKinds::Assign; }
1146 | ATassign { $$ = OperKinds::AtAssn; } // CFA
1147 ;
1148
1149compound_assignment_operator:
1150 EXPassign { $$ = OperKinds::ExpAssn; }
1151 | MULTassign { $$ = OperKinds::MulAssn; }
1152 | DIVassign { $$ = OperKinds::DivAssn; }
1153 | MODassign { $$ = OperKinds::ModAssn; }
1154 | PLUSassign { $$ = OperKinds::PlusAssn; }
1155 | MINUSassign { $$ = OperKinds::MinusAssn; }
1156 | LSassign { $$ = OperKinds::LSAssn; }
1157 | RSassign { $$ = OperKinds::RSAssn; }
1158 | ANDassign { $$ = OperKinds::AndAssn; }
1159 | ERassign { $$ = OperKinds::ERAssn; }
1160 | ORassign { $$ = OperKinds::OrAssn; }
1161 ;
1162
1163tuple: // CFA, tuple
1164 // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
1165 // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
1166 '[' ',' ']'
1167 // { $$ = new ExpressionNode( build_tuple( yylloc, nullptr ) ); }
1168 { SemanticError( yylloc, "Empty tuple is meaningless." ); $$ = nullptr; }
1169 | '[' assignment_expression ',' ']'
1170 { $$ = new ExpressionNode( build_tuple( yylloc, $2 ) ); }
1171 | '[' '@' comma_opt ']'
1172 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1173 | '[' assignment_expression ',' tuple_expression_list comma_opt ']'
1174 { $$ = new ExpressionNode( build_tuple( yylloc, $2->set_last( $4 ) ) ); }
1175 | '[' '@' ',' tuple_expression_list comma_opt ']'
1176 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1177 ;
1178
1179tuple_expression_list:
1180 assignment_expression
1181 | '@' // CFA
1182 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1183 | tuple_expression_list ',' assignment_expression
1184 { $$ = $1->set_last( $3 ); }
1185 | tuple_expression_list ',' '@'
1186 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1187 ;
1188
1189comma_expression:
1190 assignment_expression
1191 | comma_expression ',' assignment_expression
1192 { $$ = new ExpressionNode( new ast::CommaExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1193 ;
1194
1195comma_expression_opt:
1196 // empty
1197 { $$ = nullptr; }
1198 | comma_expression
1199 ;
1200
1201// ************************** STATEMENTS *******************************
1202
1203statement:
1204 labeled_statement
1205 | compound_statement
1206 | expression_statement
1207 | selection_statement
1208 | iteration_statement
1209 | jump_statement
1210 | with_statement
1211 | mutex_statement
1212 | waitfor_statement
1213 | waituntil_statement
1214 | corun_statement
1215 | cofor_statement
1216 | exception_statement
1217 | enable_disable_statement
1218 { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1219 | asm_statement
1220 | DIRECTIVE
1221 { $$ = new StatementNode( build_directive( yylloc, $1 ) ); }
1222// | attribute ';'
1223// { $$ = new StatementNode( $1 ); }
1224 ;
1225
1226labeled_statement:
1227 // labels cannot be identifiers 0 or 1
1228 identifier_or_type_name ':' attribute_list_opt statement
1229 { $$ = $4->add_label( yylloc, $1, $3 ); }
1230 | identifier_or_type_name ':' attribute_list_opt error // invalid syntax rule
1231 {
1232 SemanticError( yylloc, "syntx error, label \"%s\" must be associated with a statement, "
1233 "where a declaration, case, or default is not a statement.\n"
1234 "Move the label or terminate with a semicolon.", $1.str->c_str() );
1235 $$ = nullptr;
1236 }
1237 ;
1238
1239compound_statement:
1240 '{' '}'
1241 { $$ = new StatementNode( build_compound( yylloc, (StatementNode *)0 ) ); }
1242 | '{' push
1243 local_label_declaration_opt // GCC, local labels appear at start of block
1244 statement_decl_list // C99, intermix declarations and statements
1245 pop '}'
1246 { $$ = new StatementNode( build_compound( yylloc, $4 ) ); }
1247 ;
1248
1249statement_decl_list: // C99
1250 statement_decl
1251 | statement_decl_list statement_decl
1252 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1253 ;
1254
1255statement_decl:
1256 declaration // CFA, new & old style declarations
1257 { $$ = new StatementNode( $1 ); }
1258 | EXTENSION declaration // GCC
1259 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1260 | function_definition
1261 { $$ = new StatementNode( $1 ); }
1262 | EXTENSION function_definition // GCC
1263 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1264 | statement
1265 ;
1266
1267statement_list_nodecl:
1268 statement
1269 | statement_list_nodecl statement
1270 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1271 | statement_list_nodecl error // invalid syntax rule
1272 { SemanticError( yylloc, "illegal syntax, declarations only allowed at the start of the switch body,"
1273 " i.e., after the '{'." ); $$ = nullptr; }
1274 ;
1275
1276expression_statement:
1277 comma_expression_opt ';'
1278 { $$ = new StatementNode( build_expr( yylloc, $1 ) ); }
1279 ;
1280
1281// "if", "switch", and "choose" require parenthesis around the conditional. See the following ambiguities without
1282// parenthesis:
1283//
1284// if x + y + z; => if ( x ) + y + z or if ( x + y ) + z
1285//
1286// switch O { }
1287//
1288// O{} => object-constructor for conditional, switch body ???
1289// O{} => O for conditional followed by switch body
1290//
1291// C++ has this problem, as it has the same constructor syntax.
1292//
1293// switch sizeof ( T ) { }
1294//
1295// sizeof ( T ) => sizeof of T for conditional followed by switch body
1296// sizeof ( T ) => sizeof of compound literal (T){ }, closing parenthesis ???
1297//
1298// Note the two grammar rules for sizeof (alignof)
1299//
1300// | SIZEOF unary_expression
1301// | SIZEOF '(' type_no_function ')'
1302//
1303// where the first DOES NOT require parenthesis! And C++ inherits this problem from C.
1304
1305selection_statement:
1306 IF '(' conditional_declaration ')' statement %prec THEN
1307 // explicitly deal with the shift/reduce conflict on if/else
1308 { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), nullptr ) ); }
1309 | IF '(' conditional_declaration ')' statement ELSE statement
1310 { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), maybe_build_compound( yylloc, $7 ) ) ); }
1311 | SWITCH '(' comma_expression ')' case_clause
1312 { $$ = new StatementNode( build_switch( yylloc, true, $3, $5 ) ); }
1313 | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1314 {
1315 StatementNode *sw = new StatementNode( build_switch( yylloc, true, $3, $8 ) );
1316 // The semantics of the declaration list is changed to include associated initialization, which is performed
1317 // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1318 // statement around the switch. Statements after the initial declaration list can never be executed, and
1319 // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1320 // statement.
1321 $$ = $7 ? new StatementNode( build_compound( yylloc, (new StatementNode( $7 ))->set_last( sw ) ) ) : sw;
1322 }
1323 | SWITCH '(' comma_expression ')' '{' error '}' // CFA, invalid syntax rule error
1324 { SemanticError( yylloc, "synatx error, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1325 | CHOOSE '(' comma_expression ')' case_clause // CFA
1326 { $$ = new StatementNode( build_switch( yylloc, false, $3, $5 ) ); }
1327 | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1328 {
1329 StatementNode *sw = new StatementNode( build_switch( yylloc, false, $3, $8 ) );
1330 $$ = $7 ? new StatementNode( build_compound( yylloc, (new StatementNode( $7 ))->set_last( sw ) ) ) : sw;
1331 }
1332 | CHOOSE '(' comma_expression ')' '{' error '}' // CFA, invalid syntax rule
1333 { SemanticError( yylloc, "illegal syntax, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1334 ;
1335
1336conditional_declaration:
1337 comma_expression
1338 { $$ = new CondCtrl( nullptr, $1 ); }
1339 | c_declaration // no semi-colon
1340 { $$ = new CondCtrl( $1, nullptr ); }
1341 | cfa_declaration // no semi-colon
1342 { $$ = new CondCtrl( $1, nullptr ); }
1343 | declaration comma_expression // semi-colon separated
1344 { $$ = new CondCtrl( $1, $2 ); }
1345 ;
1346
1347// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1348// clause allows a list of values and subranges.
1349
1350case_value: // CFA
1351 constant_expression { $$ = $1; }
1352 | constant_expression ELLIPSIS constant_expression // GCC, subrange
1353 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1354 | subrange // CFA, subrange
1355 ;
1356
1357case_value_list: // CFA
1358 case_value { $$ = new ClauseNode( build_case( yylloc, $1 ) ); }
1359 // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1360 | case_value_list ',' case_value { $$ = $1->set_last( new ClauseNode( build_case( yylloc, $3 ) ) ); }
1361 ;
1362
1363case_label: // CFA
1364 CASE error // invalid syntax rule
1365 { SemanticError( yylloc, "illegal syntax, case list missing after case." ); $$ = nullptr; }
1366 | CASE case_value_list ':' { $$ = $2; }
1367 | CASE case_value_list error // invalid syntax rule
1368 { SemanticError( yylloc, "illegal syntax, colon missing after case list." ); $$ = nullptr; }
1369 | DEFAULT ':' { $$ = new ClauseNode( build_default( yylloc ) ); }
1370 // A semantic check is required to ensure only one default clause per switch/choose statement.
1371 | DEFAULT error // invalid syntax rule
1372 { SemanticError( yylloc, "illegal syntax, colon missing after default." ); $$ = nullptr; }
1373 ;
1374
1375case_label_list: // CFA
1376 case_label
1377 | case_label_list case_label { $$ = $1->set_last( $2 ); }
1378 ;
1379
1380case_clause: // CFA
1381 case_label_list statement { $$ = $1->append_last_case( maybe_build_compound( yylloc, $2 ) ); }
1382 ;
1383
1384switch_clause_list_opt: // CFA
1385 // empty
1386 { $$ = nullptr; }
1387 | switch_clause_list
1388 ;
1389
1390switch_clause_list: // CFA
1391 case_label_list statement_list_nodecl
1392 { $$ = $1->append_last_case( new StatementNode( build_compound( yylloc, $2 ) ) ); }
1393 | switch_clause_list case_label_list statement_list_nodecl
1394 { $$ = $1->set_last( $2->append_last_case( new StatementNode( build_compound( yylloc, $3 ) ) ) ); }
1395 ;
1396
1397iteration_statement:
1398 WHILE '(' ')' statement %prec THEN // CFA => while ( 1 )
1399 { $$ = new StatementNode( build_while( yylloc, new CondCtrl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) ); }
1400 | WHILE '(' ')' statement ELSE statement // CFA
1401 {
1402 $$ = new StatementNode( build_while( yylloc, new CondCtrl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) );
1403 SemanticWarning( yylloc, Warning::SuperfluousElse );
1404 }
1405 | WHILE '(' conditional_declaration ')' statement %prec THEN
1406 { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1407 | WHILE '(' conditional_declaration ')' statement ELSE statement // CFA
1408 { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1409 | DO statement WHILE '(' ')' ';' // CFA => do while( 1 )
1410 { $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) ); }
1411 | DO statement WHILE '(' ')' ELSE statement // CFA
1412 {
1413 $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) );
1414 SemanticWarning( yylloc, Warning::SuperfluousElse );
1415 }
1416 | DO statement WHILE '(' comma_expression ')' ';'
1417 { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ) ) ); }
1418 | DO statement WHILE '(' comma_expression ')' ELSE statement // CFA
1419 { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ), $8 ) ); }
1420 | FOR '(' ')' statement %prec THEN // CFA => for ( ;; )
1421 { $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) ); }
1422 | FOR '(' ')' statement ELSE statement // CFA
1423 {
1424 $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) );
1425 SemanticWarning( yylloc, Warning::SuperfluousElse );
1426 }
1427 | FOR '(' for_control_expression_list ')' statement %prec THEN
1428 { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1429 | FOR '(' for_control_expression_list ')' statement ELSE statement // CFA
1430 { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1431 ;
1432
1433for_control_expression_list:
1434 for_control_expression
1435 | for_control_expression_list ':' for_control_expression
1436 // ForCtrl + ForCtrl:
1437 // init + init => multiple declaration statements that are hoisted
1438 // condition + condition => (expression) && (expression)
1439 // change + change => (expression), (expression)
1440 {
1441 $1->init->set_last( $3->init );
1442 if ( $1->condition ) {
1443 if ( $3->condition ) {
1444 $1->condition->expr.reset( new ast::LogicalExpr( yylloc, $1->condition->expr.release(), $3->condition->expr.release(), ast::AndExpr ) );
1445 } // if
1446 } else $1->condition = $3->condition;
1447 if ( $1->change ) {
1448 if ( $3->change ) {
1449 $1->change->expr.reset( new ast::CommaExpr( yylloc, $1->change->expr.release(), $3->change->expr.release() ) );
1450 } // if
1451 } else $1->change = $3->change;
1452 $$ = $1;
1453 }
1454 ;
1455
1456for_control_expression:
1457 ';' comma_expression_opt ';' comma_expression_opt
1458 { $$ = new ForCtrl( nullptr, $2, $4 ); }
1459 | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1460 {
1461 $$ = new ForCtrl( $1 ? new StatementNode( new ast::ExprStmt( yylloc, maybeMoveBuild( $1 ) ) ) : nullptr, $3, $5 );
1462 }
1463 | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1464 { $$ = new ForCtrl( new StatementNode( $1 ), $2, $4 ); }
1465
1466 | '@' ';' comma_expression // CFA, empty loop-index
1467 { $$ = new ForCtrl( nullptr, $3, nullptr ); }
1468 | '@' ';' comma_expression ';' comma_expression // CFA, empty loop-index
1469 { $$ = new ForCtrl( nullptr, $3, $5 ); }
1470
1471 | comma_expression // CFA, anonymous loop-index
1472 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), NEW_ZERO, OperKinds::LThan, $1->clone(), NEW_ONE ); }
1473 | downupdowneq comma_expression // CFA, anonymous loop-index
1474 { $$ = forCtrl( yylloc, $2, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $1, NEW_ZERO, $2->clone() ), $1, UPDOWN( $1, $2->clone(), NEW_ZERO ), NEW_ONE ); }
1475
1476 | comma_expression updowneq comma_expression // CFA, anonymous loop-index
1477 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), NEW_ONE ); }
1478 | '@' updowneq comma_expression // CFA, anonymous loop-index
1479 {
1480 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1481 else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, NEW_ONE );
1482 }
1483 | comma_expression updowneq '@' // CFA, anonymous loop-index
1484 {
1485 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1486 else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1487 }
1488 | comma_expression updowneq comma_expression '~' comma_expression // CFA, anonymous loop-index
1489 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), $5 ); }
1490 | '@' updowneq comma_expression '~' comma_expression // CFA, anonymous loop-index
1491 {
1492 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1493 else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, $5 );
1494 }
1495 | comma_expression updowneq '@' '~' comma_expression // CFA, anonymous loop-index
1496 {
1497 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1498 else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1499 }
1500 | comma_expression updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1501 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1502 | '@' updowneq '@' // CFA, invalid syntax rule
1503 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1504 | '@' updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1505 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1506 | comma_expression updowneq '@' '~' '@' // CFA, invalid syntax rule
1507 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1508 | '@' updowneq '@' '~' '@' // CFA, invalid syntax rule
1509 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1510
1511 // These rules accept a comma_expression for the initialization, when only an identifier is correct. Being
1512 // permissive allows for a better error message from forCtrl.
1513 | comma_expression ';' comma_expression // CFA
1514 { $$ = forCtrl( yylloc, $3, $1, NEW_ZERO, OperKinds::LThan, $3->clone(), NEW_ONE ); }
1515 | comma_expression ';' downupdowneq comma_expression // CFA
1516 { $$ = forCtrl( yylloc, $4, $1, UPDOWN( $3, NEW_ZERO, $4->clone() ), $3, UPDOWN( $3, $4->clone(), NEW_ZERO ), NEW_ONE ); }
1517
1518 | comma_expression ';' comma_expression updowneq comma_expression // CFA
1519 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), NEW_ONE ); }
1520 | comma_expression ';' '@' updowneq comma_expression // CFA
1521 {
1522 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1523 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, NEW_ONE );
1524 }
1525 | comma_expression ';' comma_expression updowneq '@' // CFA
1526 {
1527 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1528 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1529 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, NEW_ONE );
1530 }
1531 | comma_expression ';' '@' updowneq '@' // CFA, invalid syntax rule
1532 { SemanticError( yylloc, "illegal syntax, missing low/high value for ascending/descending range so index is uninitialized." ); $$ = nullptr; }
1533
1534 | comma_expression ';' comma_expression updowneq comma_expression '~' comma_expression // CFA
1535 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), $7 ); }
1536 | comma_expression ';' '@' updowneq comma_expression '~' comma_expression // CFA, invalid syntax rule
1537 {
1538 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1539 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, $7 );
1540 }
1541 | comma_expression ';' comma_expression updowneq '@' '~' comma_expression // CFA
1542 {
1543 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1544 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1545 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, $7 );
1546 }
1547 | comma_expression ';' comma_expression updowneq comma_expression '~' '@' // CFA
1548 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), nullptr ); }
1549 | comma_expression ';' '@' updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1550 {
1551 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1552 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, nullptr );
1553 }
1554 | comma_expression ';' comma_expression updowneq '@' '~' '@' // CFA
1555 {
1556 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1557 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1558 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, nullptr );
1559 }
1560 | comma_expression ';' '@' updowneq '@' '~' '@' // CFA
1561 { SemanticError( yylloc, "illegal syntax, missing low/high value for ascending/descending range so index is uninitialized." ); $$ = nullptr; }
1562
1563// | '@' identifier ';' comma_expression // CFA
1564 | declaration comma_expression // CFA
1565 { $$ = forCtrl( yylloc, $1, NEW_ZERO, OperKinds::LThan, $2, NEW_ONE ); }
1566 | declaration downupdowneq comma_expression // CFA
1567 { $$ = forCtrl( yylloc, $1, UPDOWN( $2, NEW_ZERO, $3 ), $2, UPDOWN( $2, $3->clone(), NEW_ZERO ), NEW_ONE ); }
1568
1569 | declaration comma_expression updowneq comma_expression // CFA
1570 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2->clone(), $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), NEW_ONE ); }
1571 | declaration '@' updowneq comma_expression // CFA
1572 {
1573 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1574 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, NEW_ONE );
1575 }
1576 | declaration comma_expression updowneq '@' // CFA
1577 {
1578 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1579 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1580 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, NEW_ONE );
1581 }
1582
1583 | declaration comma_expression updowneq comma_expression '~' comma_expression // CFA
1584 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), $6 ); }
1585 | declaration '@' updowneq comma_expression '~' comma_expression // CFA
1586 {
1587 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1588 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, $6 );
1589 }
1590 | declaration comma_expression updowneq '@' '~' comma_expression // CFA
1591 {
1592 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1593 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1594 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, $6 );
1595 }
1596 | declaration comma_expression updowneq comma_expression '~' '@' // CFA
1597 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), nullptr ); }
1598 | declaration '@' updowneq comma_expression '~' '@' // CFA
1599 {
1600 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1601 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, nullptr );
1602 }
1603 | declaration comma_expression updowneq '@' '~' '@' // CFA
1604 {
1605 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1606 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1607 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, nullptr );
1608 }
1609 | declaration '@' updowneq '@' '~' '@' // CFA, invalid syntax rule
1610 { SemanticError( yylloc, "illegal syntax, missing low/high value for ascending/descending range so index is uninitialized." ); $$ = nullptr; }
1611
1612 | comma_expression ';' type_type_specifier // CFA, enum type
1613 {
1614 $$ = enumRangeCtrl( $1, OperKinds::LEThan, new ExpressionNode( new ast::TypeExpr( yylloc, $3->clone()->buildType() ) ), $3 );
1615 }
1616 | comma_expression ';' downupdowneq enum_key // CFA, enum type, reverse direction
1617 {
1618 if ( $3 == OperKinds::GThan ) {
1619 SemanticError( yylloc, "all enumeration ranges are equal (all values). Add an equal, e.g., ~=, -~=." ); $$ = nullptr;
1620 $3 = OperKinds::GEThan;
1621 } // if
1622 $$ = enumRangeCtrl( $1, $3, new ExpressionNode( new ast::TypeExpr( yylloc, $4->clone()->buildType() ) ), $4 );
1623 }
1624 ;
1625
1626enum_key:
1627 type_name
1628 {
1629 typedefTable.makeTypedef( *$1->symbolic.name, "enum_type_nobody 1" );
1630 $$ = DeclarationNode::newEnum( $1->symbolic.name, nullptr, false, false );
1631 }
1632 | ENUM identifier
1633 {
1634 typedefTable.makeTypedef( *$2, "enum_type_nobody 2" );
1635 $$ = DeclarationNode::newEnum( $2, nullptr, false, false );
1636 }
1637 | ENUM type_name
1638 {
1639 typedefTable.makeTypedef( *$2->symbolic.name, "enum_type_nobody 3" );
1640 $$ = DeclarationNode::newEnum( $2->symbolic.name, nullptr, false, false );
1641 }
1642 ;
1643
1644// This rule exists to handle the ambiguity with unary operator '~'. The rule is the same as updowneq minus the '~'.
1645// Specifically, "for ( ~5 )" means the complement of 5, not loop 0..4. Hence, in this case "for ( ~= 5 )", i.e., 0..5,
1646// it is not possible to just remove the '='. The entire '~=' must be removed.
1647downupdowneq:
1648 ErangeUp
1649 { $$ = OperKinds::LThan; }
1650 | ErangeDown
1651 { $$ = OperKinds::GThan; }
1652 | ErangeUpEq
1653 { $$ = OperKinds::LEThan; }
1654 | ErangeDownEq
1655 { $$ = OperKinds::GEThan; }
1656 ;
1657
1658updown:
1659 '~' // shorthand 0 ~ 10 => 0 +~ 10
1660 { $$ = OperKinds::LThan; }
1661 | ErangeUp
1662 { $$ = OperKinds::LThan; }
1663 | ErangeDown
1664 { $$ = OperKinds::GThan; }
1665 ;
1666
1667updowneq:
1668 updown
1669 | ErangeUpEq
1670 { $$ = OperKinds::LEThan; }
1671 | ErangeDownEq
1672 { $$ = OperKinds::GEThan; }
1673 ;
1674
1675jump_statement:
1676 GOTO identifier_or_type_name ';'
1677 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Goto ) ); }
1678 | GOTO '*' comma_expression ';' // GCC, computed goto
1679 // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1680 // whereas normal operator precedence yields goto (*i)+3;
1681 { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1682 // A semantic check is required to ensure fallthrough appears only in the body of a choose statement.
1683 | FALLTHROUGH ';' // CFA
1684 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThrough ) ); }
1685 | FALLTHROUGH identifier_or_type_name ';' // CFA
1686 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::FallThrough ) ); }
1687 | FALLTHROUGH DEFAULT ';' // CFA
1688 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThroughDefault ) ); }
1689 | CONTINUE ';'
1690 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1691 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Continue ) ); }
1692 | CONTINUE identifier_or_type_name ';' // CFA, multi-level continue
1693 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1694 // the target of the transfer appears only at the start of an iteration statement.
1695 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Continue ) ); }
1696 | BREAK ';'
1697 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1698 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Break ) ); }
1699 | BREAK identifier_or_type_name ';' // CFA, multi-level exit
1700 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1701 // the target of the transfer appears only at the start of an iteration statement.
1702 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Break ) ); }
1703 | RETURN comma_expression_opt ';'
1704 { $$ = new StatementNode( build_return( yylloc, $2 ) ); }
1705 | RETURN '{' initializer_list_opt comma_opt '}' ';'
1706 { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1707 | SUSPEND ';'
1708 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::None ) ); }
1709 | SUSPEND compound_statement
1710 { $$ = new StatementNode( build_suspend( yylloc, $2, ast::SuspendStmt::None ) ); }
1711 | SUSPEND COROUTINE ';'
1712 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Coroutine ) ); }
1713 | SUSPEND COROUTINE compound_statement
1714 { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Coroutine ) ); }
1715 | SUSPEND GENERATOR ';'
1716 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Generator ) ); }
1717 | SUSPEND GENERATOR compound_statement
1718 { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Generator ) ); }
1719 | THROW assignment_expression_opt ';' // handles rethrow
1720 { $$ = new StatementNode( build_throw( yylloc, $2 ) ); }
1721 | THROWRESUME assignment_expression_opt ';' // handles reresume
1722 { $$ = new StatementNode( build_resume( yylloc, $2 ) ); }
1723 | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1724 { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1725 ;
1726
1727with_statement:
1728 WITH '(' type_list ')' statement // support scoped enumeration
1729 { $$ = new StatementNode( build_with( yylloc, $3, $5 ) ); }
1730 ;
1731
1732// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so possibly change syntax to "with mutex".
1733mutex_statement:
1734 MUTEX '(' argument_expression_list_opt ')' statement
1735 {
1736 if ( ! $3 ) { SemanticError( yylloc, "illegal syntax, mutex argument list cannot be empty." ); $$ = nullptr; }
1737 $$ = new StatementNode( build_mutex( yylloc, $3, $5 ) );
1738 }
1739 ;
1740
1741when_clause:
1742 WHEN '(' comma_expression ')' { $$ = $3; }
1743 ;
1744
1745when_clause_opt:
1746 // empty
1747 { $$ = nullptr; }
1748 | when_clause
1749 ;
1750
1751cast_expression_list:
1752 cast_expression
1753 | cast_expression_list ',' cast_expression
1754 { SemanticError( yylloc, "List of mutex member is currently unimplemented." ); $$ = nullptr; }
1755 ;
1756
1757timeout:
1758 TIMEOUT '(' comma_expression ')' { $$ = $3; }
1759 ;
1760
1761wor:
1762 OROR
1763 | WOR
1764
1765waitfor:
1766 WAITFOR '(' cast_expression ')'
1767 { $$ = $3; }
1768 | WAITFOR '(' cast_expression_list ':' argument_expression_list_opt ')'
1769 { $$ = $3->set_last( $5 ); }
1770 ;
1771
1772wor_waitfor_clause:
1773 when_clause_opt waitfor statement %prec THEN
1774 // Called first: create header for WaitForStmt.
1775 { $$ = build_waitfor( yylloc, new ast::WaitForStmt( yylloc ), $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1776 | wor_waitfor_clause wor when_clause_opt waitfor statement
1777 { $$ = build_waitfor( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1778 | wor_waitfor_clause wor when_clause_opt ELSE statement
1779 { $$ = build_waitfor_else( yylloc, $1, $3, maybe_build_compound( yylloc, $5 ) ); }
1780 | wor_waitfor_clause wor when_clause_opt timeout statement %prec THEN
1781 { $$ = build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1782 // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1783 | wor_waitfor_clause wor when_clause_opt timeout statement wor ELSE statement // invalid syntax rule
1784 { SemanticError( yylloc, "illegal syntax, else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1785 | wor_waitfor_clause wor when_clause_opt timeout statement wor when_clause ELSE statement
1786 { $$ = build_waitfor_else( yylloc, build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ), $7, maybe_build_compound( yylloc, $9 ) ); }
1787 ;
1788
1789waitfor_statement:
1790 wor_waitfor_clause %prec THEN
1791 { $$ = new StatementNode( $1 ); }
1792 ;
1793
1794wand:
1795 ANDAND
1796 | WAND
1797 ;
1798
1799waituntil:
1800 WAITUNTIL '(' comma_expression ')'
1801 { $$ = $3; }
1802 ;
1803
1804waituntil_clause:
1805 when_clause_opt waituntil statement
1806 { $$ = build_waituntil_clause( yylloc, $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1807 | '(' wor_waituntil_clause ')'
1808 { $$ = $2; }
1809 ;
1810
1811wand_waituntil_clause:
1812 waituntil_clause %prec THEN
1813 { $$ = $1; }
1814 | waituntil_clause wand wand_waituntil_clause
1815 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::AND, $1, $3 ); }
1816 ;
1817
1818wor_waituntil_clause:
1819 wand_waituntil_clause
1820 { $$ = $1; }
1821 | wor_waituntil_clause wor wand_waituntil_clause
1822 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::OR, $1, $3 ); }
1823 | wor_waituntil_clause wor when_clause_opt ELSE statement
1824 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::LEFT_OR, $1, build_waituntil_else( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1825 ;
1826
1827waituntil_statement:
1828 wor_waituntil_clause %prec THEN
1829 { $$ = new StatementNode( build_waituntil_stmt( yylloc, $1 ) ); }
1830 ;
1831
1832corun_statement:
1833 CORUN statement
1834 { $$ = new StatementNode( build_corun( yylloc, $2 ) ); }
1835 ;
1836
1837cofor_statement:
1838 COFOR '(' for_control_expression_list ')' statement
1839 { $$ = new StatementNode( build_cofor( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1840 ;
1841
1842exception_statement:
1843 TRY compound_statement handler_clause %prec THEN
1844 { $$ = new StatementNode( build_try( yylloc, $2, $3, nullptr ) ); }
1845 | TRY compound_statement finally_clause
1846 { $$ = new StatementNode( build_try( yylloc, $2, nullptr, $3 ) ); }
1847 | TRY compound_statement handler_clause finally_clause
1848 { $$ = new StatementNode( build_try( yylloc, $2, $3, $4 ) ); }
1849 ;
1850
1851handler_clause:
1852 handler_key '(' exception_declaration handler_predicate_opt ')' compound_statement
1853 { $$ = new ClauseNode( build_catch( yylloc, $1, $3, $4, $6 ) ); }
1854 | handler_clause handler_key '(' exception_declaration handler_predicate_opt ')' compound_statement
1855 { $$ = $1->set_last( new ClauseNode( build_catch( yylloc, $2, $4, $5, $7 ) ) ); }
1856 ;
1857
1858handler_predicate_opt:
1859 // empty
1860 { $$ = nullptr; }
1861 | ';' conditional_expression { $$ = $2; }
1862 ;
1863
1864handler_key:
1865 CATCH { $$ = ast::Terminate; }
1866 | RECOVER { $$ = ast::Terminate; }
1867 | CATCHRESUME { $$ = ast::Resume; }
1868 | FIXUP { $$ = ast::Resume; }
1869 ;
1870
1871finally_clause:
1872 FINALLY compound_statement { $$ = new ClauseNode( build_finally( yylloc, $2 ) ); }
1873 ;
1874
1875exception_declaration:
1876 // No SUE declaration in parameter list.
1877 type_specifier_nobody
1878 | type_specifier_nobody declarator
1879 { $$ = $2->addType( $1 ); }
1880 | type_specifier_nobody variable_abstract_declarator
1881 { $$ = $2->addType( $1 ); }
1882 | cfa_abstract_declarator_tuple identifier // CFA
1883 { $$ = $1->addName( $2 ); }
1884 | cfa_abstract_declarator_tuple // CFA
1885 ;
1886
1887enable_disable_statement:
1888 enable_disable_key identifier_list compound_statement
1889 ;
1890
1891enable_disable_key:
1892 ENABLE
1893 | DISABLE
1894 ;
1895
1896asm_statement:
1897 ASM asm_volatile_opt '(' string_literal ')' ';'
1898 { $$ = new StatementNode( build_asm( yylloc, $2, $4, nullptr ) ); }
1899 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1900 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6 ) ); }
1901 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1902 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8 ) ); }
1903 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1904 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8, $10 ) ); }
1905 | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1906 { $$ = new StatementNode( build_asm( yylloc, $2, $5, nullptr, $8, $10, $12 ) ); }
1907 ;
1908
1909asm_volatile_opt: // GCC
1910 // empty
1911 { $$ = false; }
1912 | VOLATILE
1913 { $$ = true; }
1914 ;
1915
1916asm_operands_opt: // GCC
1917 // empty
1918 { $$ = nullptr; } // use default argument
1919 | asm_operands_list
1920 ;
1921
1922asm_operands_list: // GCC
1923 asm_operand
1924 | asm_operands_list ',' asm_operand
1925 { $$ = $1->set_last( $3 ); }
1926 ;
1927
1928asm_operand: // GCC
1929 string_literal '(' constant_expression ')'
1930 { $$ = new ExpressionNode( new ast::AsmExpr( yylloc, "", maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1931 | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1932 {
1933 $$ = new ExpressionNode( new ast::AsmExpr( yylloc, *$2.str, maybeMoveBuild( $4 ), maybeMoveBuild( $6 ) ) );
1934 delete $2.str;
1935 }
1936 ;
1937
1938asm_clobbers_list_opt: // GCC
1939 // empty
1940 { $$ = nullptr; } // use default argument
1941 | string_literal
1942 { $$ = $1; }
1943 | asm_clobbers_list_opt ',' string_literal
1944 { $$ = $1->set_last( $3 ); }
1945 ;
1946
1947label_list:
1948 identifier
1949 {
1950 $$ = new LabelNode(); $$->labels.emplace_back( yylloc, *$1 );
1951 delete $1; // allocated by lexer
1952 }
1953 | label_list ',' identifier
1954 {
1955 $$ = $1; $1->labels.emplace_back( yylloc, *$3 );
1956 delete $3; // allocated by lexer
1957 }
1958 ;
1959
1960// ****************************** DECLARATIONS *********************************
1961
1962declaration_list_opt: // used at beginning of switch statement
1963 // empty
1964 { $$ = nullptr; }
1965 | declaration_list
1966 ;
1967
1968declaration_list:
1969 declaration
1970 | declaration_list declaration
1971 { $$ = $1->set_last( $2 ); }
1972 ;
1973
1974KR_parameter_list_opt: // used to declare parameter types in K&R style functions
1975 // empty
1976 { $$ = nullptr; }
1977 | KR_parameter_list
1978 ;
1979
1980KR_parameter_list:
1981 c_declaration ';'
1982 { $$ = $1; }
1983 | KR_parameter_list c_declaration ';'
1984 { $$ = $1->set_last( $2 ); }
1985 ;
1986
1987local_label_declaration_opt: // GCC, local label
1988 // empty
1989 | local_label_declaration_list
1990 ;
1991
1992local_label_declaration_list: // GCC, local label
1993 LABEL local_label_list ';'
1994 | local_label_declaration_list LABEL local_label_list ';'
1995 ;
1996
1997local_label_list: // GCC, local label
1998 identifier_or_type_name
1999 | local_label_list ',' identifier_or_type_name
2000 ;
2001
2002declaration: // old & new style declarations
2003 c_declaration ';'
2004 | cfa_declaration ';' // CFA
2005 | static_assert ';' // C11
2006 ;
2007
2008static_assert:
2009 STATICASSERT '(' constant_expression ',' string_literal ')' // C11
2010 { $$ = DeclarationNode::newStaticAssert( $3, maybeMoveBuild( $5 ) ); }
2011 | STATICASSERT '(' constant_expression ')' // CFA
2012 { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( yylloc, *new string( "\"\"" ) ) ); }
2013
2014// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
2015// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
2016// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
2017// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
2018// the declaration list (as in Pascal). ANSI C and the new CFA declarations may appear together in the same program
2019// block, but cannot be mixed within a specific declaration.
2020//
2021// CFA C
2022// [10] int x; int x[10]; // array of 10 integers
2023// [10] * char y; char *y[10]; // array of 10 pointers to char
2024
2025cfa_declaration: // CFA
2026 cfa_variable_declaration
2027 | cfa_typedef_declaration
2028 | cfa_function_declaration
2029 | type_declaring_list
2030 { SemanticError( yylloc, "otype declaration is currently unimplemented." ); $$ = nullptr; }
2031 | trait_specifier
2032 ;
2033
2034cfa_variable_declaration: // CFA
2035 cfa_variable_specifier initializer_opt
2036 { $$ = $1->addInitializer( $2 ); }
2037 | declaration_qualifier_list cfa_variable_specifier initializer_opt
2038 // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
2039 // them as a type_qualifier cannot appear in that context.
2040 { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
2041 | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
2042 { $$ = $1->set_last( $1->cloneType( $5 )->addInitializer( $6 ) ); }
2043 ;
2044
2045cfa_variable_specifier: // CFA
2046 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
2047 // storage-class
2048 cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
2049 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
2050 | cfa_abstract_tuple identifier_or_type_name asm_name_opt
2051 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
2052 | multi_array_dimension cfa_abstract_tuple identifier_or_type_name asm_name_opt
2053 { $$ = $2->addNewArray( $1 )->addName( $3 )->addAsmName( $4 ); }
2054 | multi_array_dimension type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
2055 { $$ = $3->addNewArray( $1 )->addQualifiers( $2 )->addName( $4 )->addAsmName( $5 ); }
2056
2057 // [ int s, int t ]; // declare s and t
2058 // [ int, int ] f();
2059 // [] g( int );
2060 // [ int x, int y ] = f(); // declare x and y, initialize each from f
2061 // g( x + y );
2062 | cfa_function_return asm_name_opt
2063 { SemanticError( yylloc, "tuple-element declarations is currently unimplemented." ); $$ = nullptr; }
2064 | type_qualifier_list cfa_function_return asm_name_opt
2065 { SemanticError( yylloc, "tuple variable declaration is currently unimplemented." ); $$ = nullptr; }
2066 ;
2067
2068cfa_function_declaration: // CFA
2069 cfa_function_specifier
2070 | type_qualifier_list cfa_function_specifier
2071 { $$ = $2->addQualifiers( $1 ); }
2072 | declaration_qualifier_list cfa_function_specifier
2073 { $$ = $2->addQualifiers( $1 ); }
2074 | declaration_qualifier_list type_qualifier_list cfa_function_specifier
2075 { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
2076 | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')'
2077 {
2078 // Append the return type at the start (left-hand-side) to each identifier in the list.
2079 DeclarationNode * ret = new DeclarationNode;
2080 ret->type = maybeCopy( $1->type->base );
2081 $$ = $1->set_last( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
2082 }
2083 ;
2084
2085cfa_function_specifier: // CFA
2086 '[' ']' identifier '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2087 { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2088 | '[' ']' TYPEDEFname '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2089 { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2090 // | '[' ']' TYPEGENname '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2091 // { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2092
2093 // identifier_or_type_name must be broken apart because of the sequence:
2094 //
2095 // '[' ']' identifier_or_type_name '(' cfa_parameter_list_ellipsis_opt ')'
2096 // '[' ']' type_specifier
2097 //
2098 // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
2099 // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
2100 | cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2101 // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
2102 { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
2103 | cfa_function_return identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2104 { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
2105 ;
2106
2107cfa_function_return: // CFA
2108 '[' cfa_parameter_list ']'
2109 { $$ = DeclarationNode::newTuple( $2 ); }
2110 | '[' cfa_parameter_list ',' cfa_abstract_parameter_list ']'
2111 // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
2112 { $$ = DeclarationNode::newTuple( $2->set_last( $4 ) ); }
2113 ;
2114
2115cfa_typedef_declaration: // CFA
2116 TYPEDEF cfa_variable_specifier
2117 {
2118 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "cfa_typedef_declaration 1" );
2119 $$ = $2->addTypedef();
2120 }
2121 | TYPEDEF cfa_function_specifier
2122 {
2123 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "cfa_typedef_declaration 2" );
2124 $$ = $2->addTypedef();
2125 }
2126 | cfa_typedef_declaration ',' identifier
2127 {
2128 typedefTable.addToEnclosingScope( *$3, TYPEDEFname, "cfa_typedef_declaration 3" );
2129 $$ = $1->set_last( $1->cloneType( $3 ) );
2130 }
2131 ;
2132
2133// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
2134// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
2135
2136typedef_declaration:
2137 TYPEDEF type_specifier declarator
2138 {
2139 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "typedef_declaration 1" );
2140 if ( $2->type->forall || ($2->type->kind == TypeData::Aggregate && $2->type->aggregate.params) ) {
2141 SemanticError( yylloc, "forall qualifier in typedef is currently unimplemented." ); $$ = nullptr;
2142 } else $$ = $3->addType( $2 )->addTypedef(); // watchout frees $2 and $3
2143 }
2144 | typedef_declaration ',' declarator
2145 {
2146 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "typedef_declaration 2" );
2147 $$ = $1->set_last( $1->cloneBaseType( $3 )->addTypedef() );
2148 }
2149 | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
2150 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2151 | type_specifier TYPEDEF declarator
2152 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2153 | type_specifier TYPEDEF type_qualifier_list declarator
2154 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2155 ;
2156
2157typedef_expression:
2158 // deprecated GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
2159 TYPEDEF identifier '=' assignment_expression
2160 {
2161 SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
2162 }
2163 | typedef_expression ',' identifier '=' assignment_expression
2164 {
2165 SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
2166 }
2167 ;
2168
2169c_declaration:
2170 declaration_specifier declaring_list
2171 { $$ = distAttr( $1, $2 ); }
2172 | typedef_declaration
2173 | typedef_expression // deprecated GCC, naming expression type
2174 | sue_declaration_specifier
2175 {
2176 assert( $1->type );
2177 if ( $1->type->qualifiers.any() ) { // CV qualifiers ?
2178 SemanticError( yylloc, "illegal syntax, useless type qualifier(s) in empty declaration." ); $$ = nullptr;
2179 }
2180 // enums are never empty declarations because there must have at least one enumeration.
2181 if ( $1->type->kind == TypeData::AggregateInst && $1->storageClasses.any() ) { // storage class ?
2182 SemanticError( yylloc, "illegal syntax, useless storage qualifier(s) in empty aggregate declaration." ); $$ = nullptr;
2183 }
2184 }
2185 ;
2186
2187declaring_list:
2188 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
2189 // storage-class
2190 variable_declarator asm_name_opt initializer_opt
2191 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2192 | variable_type_redeclarator asm_name_opt initializer_opt
2193 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2194
2195 | general_function_declarator asm_name_opt
2196 { $$ = $1->addAsmName( $2 )->addInitializer( nullptr ); }
2197 | general_function_declarator asm_name_opt '=' VOID
2198 { $$ = $1->addAsmName( $2 )->addInitializer( new InitializerNode( true ) ); }
2199
2200 | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
2201 { $$ = $1->set_last( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
2202 ;
2203
2204general_function_declarator:
2205 function_type_redeclarator
2206 | function_declarator
2207 ;
2208
2209declaration_specifier: // type specifier + storage class
2210 basic_declaration_specifier
2211 | type_declaration_specifier
2212 | sue_declaration_specifier
2213 | sue_declaration_specifier invalid_types // invalid syntax rule
2214 {
2215 SemanticError( yylloc, "illegal syntax, expecting ';' at end of \"%s\" declaration.",
2216 ast::AggregateDecl::aggrString( $1->type->aggregate.kind ) );
2217 $$ = nullptr;
2218 }
2219 ;
2220
2221invalid_types:
2222 aggregate_key
2223 | basic_type_name
2224 | indirect_type
2225 ;
2226
2227declaration_specifier_nobody: // type specifier + storage class - {...}
2228 // Preclude SUE declarations in restricted scopes:
2229 //
2230 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2231 //
2232 // because it is impossible to call f due to name equivalence.
2233 basic_declaration_specifier
2234 | sue_declaration_specifier_nobody
2235 | type_declaration_specifier
2236 ;
2237
2238type_specifier: // type specifier
2239 basic_type_specifier
2240 | sue_type_specifier
2241 | type_type_specifier
2242 ;
2243
2244type_specifier_nobody: // type specifier - {...}
2245 // Preclude SUE declarations in restricted scopes:
2246 //
2247 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2248 //
2249 // because it is impossible to call f due to name equivalence.
2250 basic_type_specifier
2251 | sue_type_specifier_nobody
2252 | type_type_specifier
2253 ;
2254
2255type_qualifier_list_opt: // GCC, used in asm_statement
2256 // empty
2257 { $$ = nullptr; }
2258 | type_qualifier_list
2259 ;
2260
2261type_qualifier_list:
2262 // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
2263 //
2264 // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
2265 // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
2266 // appeared only once.
2267 type_qualifier
2268 | type_qualifier_list type_qualifier
2269 { $$ = $1->addQualifiers( $2 ); }
2270 ;
2271
2272type_qualifier:
2273 type_qualifier_name
2274 { $$ = DeclarationNode::newFromTypeData( $1 ); }
2275 | attribute // trick handles most attribute locations
2276 ;
2277
2278type_qualifier_name:
2279 CONST
2280 { $$ = build_type_qualifier( ast::CV::Const ); }
2281 | RESTRICT
2282 { $$ = build_type_qualifier( ast::CV::Restrict ); }
2283 | VOLATILE
2284 { $$ = build_type_qualifier( ast::CV::Volatile ); }
2285 | ATOMIC
2286 { $$ = build_type_qualifier( ast::CV::Atomic ); }
2287
2288 // forall is a CV qualifier because it can appear in places where SC qualifiers are disallowed.
2289 //
2290 // void foo( forall( T ) T (*)( T ) ); // forward declaration
2291 // void bar( static int ); // static disallowed (gcc/CFA)
2292 | forall
2293 { $$ = build_forall( $1 ); }
2294 ;
2295
2296forall:
2297 FORALL '(' type_parameter_list ')' // CFA
2298 { $$ = $3; }
2299 ;
2300
2301declaration_qualifier_list:
2302 storage_class_list
2303 | type_qualifier_list storage_class_list // remaining OBSOLESCENT (see 2 )
2304 { $$ = $1->addQualifiers( $2 ); }
2305 | declaration_qualifier_list type_qualifier_list storage_class_list
2306 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2307 ;
2308
2309storage_class_list:
2310 // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
2311 // only one of each is specified, except for inline, which can appear with the others.
2312 //
2313 // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
2314 // specifiers in a declaration.
2315 storage_class
2316 | storage_class_list storage_class
2317 { $$ = $1->addQualifiers( $2 ); }
2318 ;
2319
2320storage_class:
2321 EXTERN
2322 { $$ = DeclarationNode::newStorageClass( ast::Storage::Extern ); }
2323 | STATIC
2324 { $$ = DeclarationNode::newStorageClass( ast::Storage::Static ); }
2325 | AUTO
2326 { $$ = DeclarationNode::newStorageClass( ast::Storage::Auto ); }
2327 | REGISTER
2328 { $$ = DeclarationNode::newStorageClass( ast::Storage::Register ); }
2329 | THREADLOCALGCC // GCC
2330 { $$ = DeclarationNode::newStorageClass( ast::Storage::ThreadLocalGcc ); }
2331 | THREADLOCALC11 // C11
2332 { $$ = DeclarationNode::newStorageClass( ast::Storage::ThreadLocalC11 ); }
2333 // Put function specifiers here to simplify parsing rules, but separate them semantically.
2334 | INLINE // C99
2335 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Inline ); }
2336 | FORTRAN // C99
2337 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Fortran ); }
2338 | NORETURN // C11
2339 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Noreturn ); }
2340 ;
2341
2342basic_type_name:
2343 basic_type_name_type
2344 { $$ = DeclarationNode::newFromTypeData( $1 ); }
2345 ;
2346
2347// Just an intermediate value for conversion.
2348basic_type_name_type:
2349 VOID
2350 { $$ = build_basic_type( TypeData::Void ); }
2351 | BOOL // C99
2352 { $$ = build_basic_type( TypeData::Bool ); }
2353 | CHAR
2354 { $$ = build_basic_type( TypeData::Char ); }
2355 | INT
2356 { $$ = build_basic_type( TypeData::Int ); }
2357 | INT128
2358 { $$ = build_basic_type( TypeData::Int128 ); }
2359 | UINT128
2360 { $$ = addType( build_basic_type( TypeData::Int128 ), build_signedness( TypeData::Unsigned ) ); }
2361 | FLOAT
2362 { $$ = build_basic_type( TypeData::Float ); }
2363 | DOUBLE
2364 { $$ = build_basic_type( TypeData::Double ); }
2365 | FLOAT80
2366 { $$ = build_basic_type( TypeData::Float80 ); }
2367 | uuFLOAT128
2368 { $$ = build_basic_type( TypeData::uuFloat128 ); }
2369 | FLOAT16
2370 { $$ = build_basic_type( TypeData::Float16 ); }
2371 | FLOAT32
2372 { $$ = build_basic_type( TypeData::Float32 ); }
2373 | FLOAT32X
2374 { $$ = build_basic_type( TypeData::Float32x ); }
2375 | FLOAT64
2376 { $$ = build_basic_type( TypeData::Float64 ); }
2377 | FLOAT64X
2378 { $$ = build_basic_type( TypeData::Float64x ); }
2379 | FLOAT128
2380 { $$ = build_basic_type( TypeData::Float128 ); }
2381 // https://developer.arm.com/documentation/den0018/a/NEON-Intrinsics/Accessing-vector-types-from-C
2382 | FLOAT128X
2383 { $$ = build_basic_type( TypeData::Float128x ); }
2384 | FLOAT32X4
2385 { $$ = build_basic_type( TypeData::Float32x4 ); }
2386 | FLOAT64X2
2387 { $$ = build_basic_type( TypeData::Float64x2 ); }
2388 | SVFLOAT32
2389 { $$ = build_basic_type( TypeData::Svfloat32 ); }
2390 | SVFLOAT64
2391 { $$ = build_basic_type( TypeData::Svfloat64 ); }
2392 | SVBOOL
2393 { $$ = build_basic_type( TypeData::Svbool ); }
2394 | DECIMAL32
2395 { SemanticError( yylloc, "_Decimal32 is currently unimplemented." ); $$ = nullptr; }
2396 | DECIMAL64
2397 { SemanticError( yylloc, "_Decimal64 is currently unimplemented." ); $$ = nullptr; }
2398 | DECIMAL128
2399 { SemanticError( yylloc, "_Decimal128 is currently unimplemented." ); $$ = nullptr; }
2400 | COMPLEX // C99
2401 { $$ = build_complex_type( TypeData::Complex ); }
2402 | IMAGINARY // C99
2403 { $$ = build_complex_type( TypeData::Imaginary ); }
2404 | SIGNED
2405 { $$ = build_signedness( TypeData::Signed ); }
2406 | UNSIGNED
2407 { $$ = build_signedness( TypeData::Unsigned ); }
2408 | SHORT
2409 { $$ = build_length( TypeData::Short ); }
2410 | LONG
2411 { $$ = build_length( TypeData::Long ); }
2412 | VA_LIST // GCC, __builtin_va_list
2413 { $$ = build_builtin_type( TypeData::Valist ); }
2414 | AUTO_TYPE
2415 { $$ = build_builtin_type( TypeData::AutoType ); }
2416 | vtable
2417 ;
2418
2419vtable_opt:
2420 // empty
2421 { $$ = nullptr; }
2422 | vtable
2423 ;
2424
2425vtable:
2426 VTABLE '(' type_name ')' default_opt
2427 { $$ = build_vtable_type( $3 ); }
2428 ;
2429
2430default_opt:
2431 // empty
2432 { $$ = nullptr; }
2433 | DEFAULT
2434 { SemanticError( yylloc, "vtable default is currently unimplemented." ); $$ = nullptr; }
2435 ;
2436
2437basic_declaration_specifier:
2438 // A semantic check is necessary for conflicting storage classes.
2439 basic_type_specifier
2440 | declaration_qualifier_list basic_type_specifier
2441 { $$ = $2->addQualifiers( $1 ); }
2442 | basic_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2443 { $$ = $1->addQualifiers( $2 ); }
2444 | basic_declaration_specifier storage_class type_qualifier_list
2445 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2446 | basic_declaration_specifier storage_class basic_type_specifier
2447 { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
2448 ;
2449
2450basic_type_specifier:
2451 direct_type
2452 // Cannot have type modifiers, e.g., short, long, etc.
2453 | type_qualifier_list_opt indirect_type type_qualifier_list_opt
2454 { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
2455 ;
2456
2457direct_type:
2458 basic_type_name
2459 | type_qualifier_list basic_type_name
2460 { $$ = $2->addQualifiers( $1 ); }
2461 | direct_type type_qualifier
2462 { $$ = $1->addQualifiers( $2 ); }
2463 | direct_type basic_type_name
2464 { $$ = $1->addType( $2 ); }
2465 ;
2466
2467indirect_type:
2468 TYPEOF '(' type ')' // GCC: typeof( x ) y;
2469 { $$ = $3; }
2470 | TYPEOF '(' comma_expression ')' // GCC: typeof( a+b ) y;
2471 { $$ = DeclarationNode::newTypeof( $3 ); }
2472 | BASETYPEOF '(' type ')' // CFA: basetypeof( x ) y;
2473 { $$ = DeclarationNode::newTypeof( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ), true ); }
2474 | BASETYPEOF '(' comma_expression ')' // CFA: basetypeof( a+b ) y;
2475 { $$ = DeclarationNode::newTypeof( $3, true ); }
2476 | ZERO_T // CFA
2477 { $$ = DeclarationNode::newFromTypeData( build_builtin_type( TypeData::Zero ) ); }
2478 | ONE_T // CFA
2479 { $$ = DeclarationNode::newFromTypeData( build_builtin_type( TypeData::One ) ); }
2480 ;
2481
2482sue_declaration_specifier: // struct, union, enum + storage class + type specifier
2483 sue_type_specifier
2484 | declaration_qualifier_list sue_type_specifier
2485 { $$ = $2->addQualifiers( $1 ); }
2486 | sue_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2487 { $$ = $1->addQualifiers( $2 ); }
2488 | sue_declaration_specifier storage_class type_qualifier_list
2489 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2490 ;
2491
2492sue_type_specifier: // struct, union, enum + type specifier
2493 elaborated_type
2494 | type_qualifier_list
2495 { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
2496 elaborated_type
2497 { $$ = $3->addQualifiers( $1 ); }
2498 | sue_type_specifier type_qualifier
2499 {
2500 if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
2501 $$ = $1->addQualifiers( $2 );
2502 }
2503 ;
2504
2505sue_declaration_specifier_nobody: // struct, union, enum - {...} + storage class + type specifier
2506 sue_type_specifier_nobody
2507 | declaration_qualifier_list sue_type_specifier_nobody
2508 { $$ = $2->addQualifiers( $1 ); }
2509 | sue_declaration_specifier_nobody storage_class // remaining OBSOLESCENT (see 2)
2510 { $$ = $1->addQualifiers( $2 ); }
2511 | sue_declaration_specifier_nobody storage_class type_qualifier_list
2512 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2513 ;
2514
2515sue_type_specifier_nobody: // struct, union, enum - {...} + type specifier
2516 elaborated_type_nobody
2517 | type_qualifier_list elaborated_type_nobody
2518 { $$ = $2->addQualifiers( $1 ); }
2519 | sue_type_specifier_nobody type_qualifier
2520 { $$ = $1->addQualifiers( $2 ); }
2521 ;
2522
2523type_declaration_specifier:
2524 type_type_specifier
2525 | declaration_qualifier_list type_type_specifier
2526 { $$ = $2->addQualifiers( $1 ); }
2527 | type_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2528 { $$ = $1->addQualifiers( $2 ); }
2529 | type_declaration_specifier storage_class type_qualifier_list
2530 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2531 ;
2532
2533type_type_specifier: // typedef types
2534 type_name
2535 { $$ = DeclarationNode::newFromTypeData( $1 ); }
2536 | type_qualifier_list type_name
2537 { $$ = DeclarationNode::newFromTypeData( $2 )->addQualifiers( $1 ); }
2538 | type_type_specifier type_qualifier
2539 { $$ = $1->addQualifiers( $2 ); }
2540 ;
2541
2542type_name:
2543 TYPEDEFname
2544 { $$ = build_typedef( $1 ); }
2545 | '.' TYPEDEFname
2546 { $$ = build_qualified_type( build_global_scope(), build_typedef( $2 ) ); }
2547 | type_name '.' TYPEDEFname
2548 { $$ = build_qualified_type( $1, build_typedef( $3 ) ); }
2549 | typegen_name
2550 | '.' typegen_name
2551 { $$ = build_qualified_type( build_global_scope(), $2 ); }
2552 | type_name '.' typegen_name
2553 { $$ = build_qualified_type( $1, $3 ); }
2554 ;
2555
2556typegen_name: // CFA
2557 TYPEGENname
2558 { $$ = build_type_gen( $1, nullptr ); }
2559 | TYPEGENname '(' ')'
2560 { $$ = build_type_gen( $1, nullptr ); }
2561 | TYPEGENname '(' type_list ')'
2562 { $$ = build_type_gen( $1, $3 ); }
2563 ;
2564
2565elaborated_type: // struct, union, enum
2566 aggregate_type
2567 | enum_type
2568 ;
2569
2570elaborated_type_nobody: // struct, union, enum - {...}
2571 aggregate_type_nobody
2572 | enum_type_nobody
2573 ;
2574
2575// ************************** AGGREGATE *******************************
2576
2577aggregate_type: // struct, union
2578 aggregate_key attribute_list_opt
2579 { forall = false; } // reset
2580 '{' field_declaration_list_opt '}' type_parameters_opt
2581 { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2582 | aggregate_key attribute_list_opt identifier
2583 {
2584 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 1" );
2585 forall = false; // reset
2586 }
2587 '{' field_declaration_list_opt '}' type_parameters_opt
2588 {
2589 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2590 }
2591 | aggregate_key attribute_list_opt TYPEDEFname // unqualified type name
2592 {
2593 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 2" );
2594 forall = false; // reset
2595 }
2596 '{' field_declaration_list_opt '}' type_parameters_opt
2597 {
2598 DeclarationNode::newFromTypeData( build_typedef( $3 ) );
2599 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2600 }
2601 | aggregate_key attribute_list_opt TYPEGENname // unqualified type name
2602 {
2603 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 3" );
2604 forall = false; // reset
2605 }
2606 '{' field_declaration_list_opt '}' type_parameters_opt
2607 {
2608 DeclarationNode::newFromTypeData( build_type_gen( $3, nullptr ) );
2609 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2610 }
2611 | aggregate_type_nobody
2612 ;
2613
2614type_parameters_opt:
2615 // empty
2616 { $$ = nullptr; } %prec '}'
2617 | '(' type_list ')'
2618 { $$ = $2; }
2619 ;
2620
2621aggregate_type_nobody: // struct, union - {...}
2622 aggregate_key attribute_list_opt identifier
2623 {
2624 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type_nobody" );
2625 forall = false; // reset
2626 $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2627 }
2628 | aggregate_key attribute_list_opt type_name
2629 {
2630 forall = false; // reset
2631 // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2632 // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2633 // delete newFromTypeGen.
2634 if ( $3->kind == TypeData::SymbolicInst && ! $3->symbolic.isTypedef ) {
2635 $$ = DeclarationNode::newFromTypeData( $3 )->addQualifiers( $2 );
2636 } else {
2637 $$ = DeclarationNode::newAggregate( $1, $3->symbolic.name, $3->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2638 $3->symbolic.name = nullptr; // copied to $$
2639 $3->symbolic.actuals = nullptr;
2640 delete $3;
2641 }
2642 }
2643 ;
2644
2645aggregate_key:
2646 aggregate_data
2647 | aggregate_control
2648 ;
2649
2650aggregate_data:
2651 STRUCT vtable_opt
2652 { $$ = ast::AggregateDecl::Struct; }
2653 | UNION
2654 { $$ = ast::AggregateDecl::Union; }
2655 | EXCEPTION // CFA
2656 { $$ = ast::AggregateDecl::Exception; }
2657 ;
2658
2659aggregate_control: // CFA
2660 MONITOR
2661 { $$ = ast::AggregateDecl::Monitor; }
2662 | MUTEX STRUCT
2663 { $$ = ast::AggregateDecl::Monitor; }
2664 | GENERATOR
2665 { $$ = ast::AggregateDecl::Generator; }
2666 | MUTEX GENERATOR
2667 {
2668 SemanticError( yylloc, "monitor generator is currently unimplemented." );
2669 $$ = ast::AggregateDecl::NoAggregate;
2670 }
2671 | COROUTINE
2672 { $$ = ast::AggregateDecl::Coroutine; }
2673 | MUTEX COROUTINE
2674 {
2675 SemanticError( yylloc, "monitor coroutine is currently unimplemented." );
2676 $$ = ast::AggregateDecl::NoAggregate;
2677 }
2678 | THREAD
2679 { $$ = ast::AggregateDecl::Thread; }
2680 | MUTEX THREAD
2681 {
2682 SemanticError( yylloc, "monitor thread is currently unimplemented." );
2683 $$ = ast::AggregateDecl::NoAggregate;
2684 }
2685 ;
2686
2687field_declaration_list_opt:
2688 // empty
2689 { $$ = nullptr; }
2690 | field_declaration_list_opt field_declaration
2691 { $$ = $1 ? $1->set_last( $2 ) : $2; }
2692 ;
2693
2694field_declaration:
2695 type_specifier field_declaring_list_opt ';'
2696 {
2697 $$ = fieldDecl( $1, $2 );
2698 }
2699 | type_specifier field_declaring_list_opt '}' // invalid syntax rule
2700 {
2701 SemanticError( yylloc, "illegal syntax, expecting ';' at end of previous declaration." );
2702 $$ = nullptr;
2703 }
2704 | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2705 { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2706 | STATIC type_specifier field_declaring_list_opt ';' // CFA
2707 { SemanticError( yylloc, "STATIC aggregate field qualifier currently unimplemented." ); $$ = nullptr; }
2708 | INLINE type_specifier field_abstract_list_opt ';' // CFA
2709 {
2710 if ( ! $3 ) { // field declarator ?
2711 $3 = DeclarationNode::newName( nullptr );
2712 } // if
2713 $3->inLine = true;
2714 $$ = distAttr( $2, $3 ); // mark all fields in list
2715 distInl( $3 );
2716 }
2717 | INLINE aggregate_control ';' // CFA
2718 { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2719 | typedef_declaration ';' // CFA
2720 | cfa_field_declaring_list ';' // CFA, new style field declaration
2721 | EXTENSION cfa_field_declaring_list ';' // GCC
2722 { distExt( $2 ); $$ = $2; } // mark all fields in list
2723 | INLINE cfa_field_abstract_list ';' // CFA, new style field declaration
2724 { $$ = $2; } // mark all fields in list
2725 | cfa_typedef_declaration ';' // CFA
2726 | static_assert ';' // C11
2727 ;
2728
2729field_declaring_list_opt:
2730 // empty
2731 { $$ = nullptr; }
2732 | field_declaring_list
2733 ;
2734
2735field_declaring_list:
2736 field_declarator
2737 | field_declaring_list_opt ',' attribute_list_opt field_declarator
2738 { $$ = $1->set_last( $4->addQualifiers( $3 ) ); }
2739 ;
2740
2741field_declarator:
2742 bit_subrange_size // C special case, no field name
2743 { $$ = DeclarationNode::newBitfield( $1 ); }
2744 | variable_declarator bit_subrange_size_opt
2745 // A semantic check is required to ensure bit_subrange only appears on integral types.
2746 { $$ = $1->addBitfield( $2 ); }
2747 | variable_type_redeclarator bit_subrange_size_opt
2748 // A semantic check is required to ensure bit_subrange only appears on integral types.
2749 { $$ = $1->addBitfield( $2 ); }
2750 | function_type_redeclarator bit_subrange_size_opt
2751 // A semantic check is required to ensure bit_subrange only appears on integral types.
2752 { $$ = $1->addBitfield( $2 ); }
2753 ;
2754
2755field_abstract_list_opt:
2756 // empty
2757 { $$ = nullptr; }
2758 | field_abstract
2759 | field_abstract_list_opt ',' attribute_list_opt field_abstract
2760 { $$ = $1->set_last( $4->addQualifiers( $3 ) ); }
2761 ;
2762
2763field_abstract:
2764 // no bit fields
2765 variable_abstract_declarator
2766 ;
2767
2768cfa_field_declaring_list: // CFA, new style field declaration
2769 // bit-fields are handled by C declarations
2770 cfa_abstract_declarator_tuple identifier_or_type_name
2771 { $$ = $1->addName( $2 ); }
2772 | cfa_field_declaring_list ',' identifier_or_type_name
2773 { $$ = $1->set_last( $1->cloneType( $3 ) ); }
2774 ;
2775
2776cfa_field_abstract_list: // CFA, new style field declaration
2777 // bit-fields are handled by C declarations
2778 cfa_abstract_declarator_tuple
2779 | cfa_field_abstract_list ','
2780 { $$ = $1->set_last( $1->cloneType( 0 ) ); }
2781 ;
2782
2783bit_subrange_size_opt:
2784 // empty
2785 { $$ = nullptr; }
2786 | bit_subrange_size
2787 ;
2788
2789bit_subrange_size:
2790 ':' assignment_expression
2791 { $$ = $2; }
2792 ;
2793
2794// ************************** ENUMERATION *******************************
2795
2796enum_type:
2797 // anonymous, no type name
2798 ENUM attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2799 {
2800 if ( $3 == EnumHiding::Hide ) {
2801 SemanticError( yylloc, "illegal syntax, hiding ('!') the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr;
2802 } // if
2803 $$ = DeclarationNode::newEnum( nullptr, $5, true, false )->addQualifiers( $2 );
2804 }
2805 | ENUM enumerator_type attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2806 {
2807 if ( $2 && ($2->storageClasses.val != 0 || $2->type->qualifiers.any()) ) {
2808 SemanticError( yylloc, "illegal syntax, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2809 }
2810 if ( $4 == EnumHiding::Hide ) {
2811 SemanticError( yylloc, "illegal syntax, hiding ('!') the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr;
2812 } // if
2813 $$ = DeclarationNode::newEnum( nullptr, $6, true, true, $2 )->addQualifiers( $3 );
2814 }
2815
2816 // named type
2817 | ENUM attribute_list_opt identifier
2818 { typedefTable.makeTypedef( *$3, "enum_type 1" ); }
2819 hide_opt '{' enumerator_list comma_opt '}'
2820 { $$ = DeclarationNode::newEnum( $3, $7, true, false, nullptr, $5 )->addQualifiers( $2 ); }
2821 | ENUM attribute_list_opt typedef_name hide_opt '{' enumerator_list comma_opt '}' // unqualified type name
2822 { $$ = DeclarationNode::newEnum( $3->name, $6, true, false, nullptr, $4 )->addQualifiers( $2 ); }
2823 | ENUM enumerator_type attribute_list_opt identifier attribute_list_opt
2824 {
2825 if ( $2 && ($2->storageClasses.any() || $2->type->qualifiers.val != 0) ) {
2826 SemanticError( yylloc, "illegal syntax, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2827 }
2828 typedefTable.makeTypedef( *$4, "enum_type 2" );
2829 }
2830 hide_opt '{' enumerator_list comma_opt '}'
2831 { $$ = DeclarationNode::newEnum( $4, $9, true, true, $2, $7 )->addQualifiers( $3 )->addQualifiers( $5 ); }
2832 | ENUM enumerator_type attribute_list_opt typedef_name attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2833 { $$ = DeclarationNode::newEnum( $4->name, $8, true, true, $2, $6 )->addQualifiers( $3 )->addQualifiers( $5 ); }
2834
2835 // forward declaration
2836 | enum_type_nobody
2837 ;
2838
2839enumerator_type:
2840 '(' ')' // pure enumeration
2841 { $$ = nullptr; }
2842 | '(' cfa_abstract_parameter_declaration ')' // typed enumeration
2843 { $$ = $2; }
2844 ;
2845
2846hide_opt:
2847 // empty
2848 { $$ = EnumHiding::Visible; }
2849 | '!'
2850 { $$ = EnumHiding::Hide; }
2851 ;
2852
2853enum_type_nobody: // enum - {...}
2854 ENUM attribute_list_opt identifier
2855 {
2856 typedefTable.makeTypedef( *$3, "enum_type_nobody 1" );
2857 $$ = DeclarationNode::newEnum( $3, nullptr, false, false )->addQualifiers( $2 );
2858 }
2859 | ENUM attribute_list_opt type_name
2860 {
2861 typedefTable.makeTypedef( *$3->symbolic.name, "enum_type_nobody 2" );
2862 $$ = DeclarationNode::newEnum( $3->symbolic.name, nullptr, false, false )->addQualifiers( $2 );
2863 }
2864 ;
2865
2866enumerator_list:
2867 // empty
2868 { SemanticError( yylloc, "enumeration must have a minimum of one enumerator, empty enumerator list is meaningless." ); $$ = nullptr; }
2869 | visible_hide_opt identifier_or_type_name enumerator_value_opt
2870 { $$ = DeclarationNode::newEnumValueGeneric( $2, $3 ); }
2871 | INLINE type_name
2872 {
2873 $$ = DeclarationNode::newEnumInLine( $2->symbolic.name );
2874 $2->symbolic.name = nullptr;
2875 delete $2;
2876 }
2877 | enumerator_list ',' visible_hide_opt identifier_or_type_name enumerator_value_opt
2878 { $$ = $1->set_last( DeclarationNode::newEnumValueGeneric( $4, $5 ) ); }
2879 | enumerator_list ',' INLINE type_name
2880 { $$ = $1->set_last( DeclarationNode::newEnumInLine( $4->symbolic.name ) ); }
2881 ;
2882
2883visible_hide_opt:
2884 hide_opt
2885 | '^'
2886 { $$ = EnumHiding::Visible; }
2887 ;
2888
2889enumerator_value_opt:
2890 // empty
2891 { $$ = nullptr; }
2892 | '=' constant_expression { $$ = new InitializerNode( $2 ); }
2893 | '=' '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $3, true ); }
2894 // | simple_assignment_operator initializer
2895 // { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2896 ;
2897
2898// ************************** FUNCTION PARAMETERS *******************************
2899
2900parameter_list_ellipsis_opt:
2901 // empty
2902 { $$ = DeclarationNode::newFromTypeData( build_basic_type( TypeData::Void ) ); }
2903 | ELLIPSIS
2904 { $$ = nullptr; }
2905 | parameter_list
2906 | parameter_list ',' ELLIPSIS
2907 { $$ = $1->addVarArgs(); }
2908 ;
2909
2910parameter_list: // abstract + real
2911 parameter_declaration
2912 | abstract_parameter_declaration
2913 | parameter_list ',' parameter_declaration
2914 { $$ = $1->set_last( $3 ); }
2915 | parameter_list ',' abstract_parameter_declaration
2916 { $$ = $1->set_last( $3 ); }
2917 ;
2918
2919cfa_parameter_list_ellipsis_opt: // CFA, abstract + real
2920 // empty
2921 { $$ = DeclarationNode::newFromTypeData( build_basic_type( TypeData::Void ) ); }
2922 | ELLIPSIS
2923 { $$ = nullptr; }
2924 | cfa_parameter_list
2925 | cfa_abstract_parameter_list
2926 | cfa_parameter_list ',' cfa_abstract_parameter_list
2927 { $$ = $1->set_last( $3 ); }
2928 | cfa_parameter_list ',' ELLIPSIS
2929 { $$ = $1->addVarArgs(); }
2930 | cfa_abstract_parameter_list ',' ELLIPSIS
2931 { $$ = $1->addVarArgs(); }
2932 ;
2933
2934cfa_parameter_list: // CFA
2935 // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2936 // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2937 cfa_parameter_declaration
2938 | cfa_abstract_parameter_list ',' cfa_parameter_declaration
2939 { $$ = $1->set_last( $3 ); }
2940 | cfa_parameter_list ',' cfa_parameter_declaration
2941 { $$ = $1->set_last( $3 ); }
2942 | cfa_parameter_list ',' cfa_abstract_parameter_list ',' cfa_parameter_declaration
2943 { $$ = $1->set_last( $3 )->set_last( $5 ); }
2944 ;
2945
2946cfa_abstract_parameter_list: // CFA, new & old style abstract
2947 cfa_abstract_parameter_declaration
2948 | cfa_abstract_parameter_list ',' cfa_abstract_parameter_declaration
2949 { $$ = $1->set_last( $3 ); }
2950 ;
2951
2952// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2953// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2954
2955parameter_declaration:
2956 // No SUE declaration in parameter list.
2957 declaration_specifier_nobody identifier_parameter_declarator default_initializer_opt
2958 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2959 | declaration_specifier_nobody type_parameter_redeclarator default_initializer_opt
2960 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2961 ;
2962
2963abstract_parameter_declaration:
2964 declaration_specifier_nobody default_initializer_opt
2965 { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2966 | declaration_specifier_nobody abstract_parameter_declarator default_initializer_opt
2967 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2968 ;
2969
2970cfa_parameter_declaration: // CFA, new & old style parameter declaration
2971 parameter_declaration
2972 | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initializer_opt
2973 { $$ = $1->addName( $2 ); }
2974 | cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2975 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2976 { $$ = $1->addName( $2 ); }
2977 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2978 { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2979 | cfa_function_specifier // int f( "int fp()" );
2980 ;
2981
2982cfa_abstract_parameter_declaration: // CFA, new & old style parameter declaration
2983 abstract_parameter_declaration
2984 | cfa_identifier_parameter_declarator_no_tuple
2985 | cfa_abstract_tuple
2986 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2987 | type_qualifier_list cfa_abstract_tuple
2988 { $$ = $2->addQualifiers( $1 ); }
2989 | cfa_abstract_function // int f( "int ()" );
2990 ;
2991
2992// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2993// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2994// identifiers. The ANSI-style parameter-list can redefine a typedef name.
2995
2996identifier_list: // K&R-style parameter list => no types
2997 identifier
2998 { $$ = DeclarationNode::newName( $1 ); }
2999 | identifier_list ',' identifier
3000 { $$ = $1->set_last( DeclarationNode::newName( $3 ) ); }
3001 ;
3002
3003type_no_function: // sizeof, alignof, cast (constructor)
3004 cfa_abstract_declarator_tuple // CFA
3005 | type_specifier // cannot be type_specifier_nobody, e.g., (struct S {}){} is a thing
3006 | type_specifier abstract_declarator
3007 { $$ = $2->addType( $1 ); }
3008 ;
3009
3010type: // typeof, assertion
3011 type_no_function
3012 | cfa_abstract_function // CFA
3013 ;
3014
3015initializer_opt:
3016 // empty
3017 { $$ = nullptr; }
3018 | simple_assignment_operator initializer { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
3019 | '=' VOID { $$ = new InitializerNode( true ); }
3020 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
3021 ;
3022
3023initializer:
3024 assignment_expression { $$ = new InitializerNode( $1 ); }
3025 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
3026 ;
3027
3028initializer_list_opt:
3029 // empty
3030 { $$ = nullptr; }
3031 | initializer
3032 | designation initializer { $$ = $2->set_designators( $1 ); }
3033 | initializer_list_opt ',' initializer { $$ = $1->set_last( $3 ); }
3034 | initializer_list_opt ',' designation initializer { $$ = $1->set_last( $4->set_designators( $3 ) ); }
3035 ;
3036
3037// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
3038// '=' to separator the designator from the initializer value, as in:
3039//
3040// int x[10] = { [1] = 3 };
3041//
3042// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment. To disambiguate this case, CFA
3043// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
3044// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
3045// shift/reduce conflicts
3046
3047designation:
3048 designator_list '=' // C99, CFA uses ":" instead of "="
3049 | identifier_at ':' // GCC, field name, obsolete since GCC 2.5
3050 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
3051 ;
3052
3053designator_list: // C99
3054 designator
3055 | designator_list designator
3056 { $$ = $1->set_last( $2 ); }
3057 ;
3058
3059designator:
3060 '.' identifier_at // C99, field name
3061 { $$ = new ExpressionNode( build_varref( yylloc, $2 ) ); }
3062 | '[' constant_expression ']' // C99, single array element
3063 { $$ = $2; }
3064 | '[' subrange ']' // CFA, multiple array elements
3065 { $$ = $2; }
3066 | '[' constant_expression ELLIPSIS constant_expression ']' // GCC, multiple array elements
3067 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $2 ), maybeMoveBuild( $4 ) ) ); }
3068 | '.' '[' field_name_list ']' // CFA, tuple field selector
3069 { $$ = $3; }
3070 ;
3071
3072// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
3073// rather than an object-oriented type system. This required four groups of extensions:
3074//
3075// Overloading: function, data, and operator identifiers may be overloaded.
3076//
3077// Type declarations: "otype" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
3078// and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
3079// definitions of new types. Type declarations with storage class "extern" provide opaque types.
3080//
3081// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
3082// site. A polymorphic function is not a template; it is a function, with an address and a type.
3083//
3084// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
3085// types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
3086// hierarchies. Unlike classes, they can define relationships between types. Assertions declare that a type or
3087// types provide the operations declared by a specification. Assertions are normally used to declare requirements
3088// on type arguments of polymorphic functions.
3089
3090type_parameter_list: // CFA
3091 type_parameter
3092 | type_parameter_list ',' type_parameter
3093 { $$ = $1->set_last( $3 ); }
3094 ;
3095
3096type_initializer_opt: // CFA
3097 // empty
3098 { $$ = nullptr; }
3099 | '=' type
3100 { $$ = $2; }
3101 ;
3102
3103type_parameter: // CFA
3104 type_class identifier_or_type_name
3105 {
3106 typedefTable.addToScope( *$2, TYPEDEFname, "type_parameter 1" );
3107 if ( $1 == ast::TypeDecl::Otype ) { SemanticError( yylloc, "otype keyword is deprecated, use T " ); }
3108 if ( $1 == ast::TypeDecl::Dtype ) { SemanticError( yylloc, "dtype keyword is deprecated, use T &" ); }
3109 if ( $1 == ast::TypeDecl::Ttype ) { SemanticError( yylloc, "ttype keyword is deprecated, use T ..." ); }
3110 }
3111 type_initializer_opt assertion_list_opt
3112 { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
3113 | identifier_or_type_name new_type_class
3114 { typedefTable.addToScope( *$1, TYPEDEFname, "type_parameter 2" ); }
3115 type_initializer_opt assertion_list_opt
3116 { $$ = DeclarationNode::newTypeParam( $2, $1 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
3117 | '[' identifier_or_type_name ']'
3118 {
3119 typedefTable.addToScope( *$2, TYPEDIMname, "type_parameter 3" );
3120 $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dimension, $2 );
3121 }
3122 // | type_specifier identifier_parameter_declarator
3123 | assertion_list
3124 { $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
3125 | ENUM '(' identifier_or_type_name ')' identifier_or_type_name new_type_class type_initializer_opt assertion_list_opt
3126 {
3127 typedefTable.addToScope( *$3, TYPEDIMname, "type_parameter 4" );
3128 typedefTable.addToScope( *$5, TYPEDIMname, "type_parameter 5" );
3129 $$ = DeclarationNode::newTypeParam( $6, $5 )->addTypeInitializer( $7 )->addAssertions( $8 );
3130 }
3131 ;
3132
3133new_type_class: // CFA
3134 // empty
3135 { $$ = ast::TypeDecl::Otype; }
3136 | '&'
3137 { $$ = ast::TypeDecl::Dtype; }
3138 | '*'
3139 { $$ = ast::TypeDecl::DStype; } // Dtype + sized
3140 // | '(' '*' ')' // Gregor made me do it
3141 // { $$ = ast::TypeDecl::Ftype; }
3142 | ELLIPSIS
3143 { $$ = ast::TypeDecl::Ttype; }
3144 ;
3145
3146type_class: // CFA
3147 OTYPE
3148 { $$ = ast::TypeDecl::Otype; }
3149 | DTYPE
3150 { $$ = ast::TypeDecl::Dtype; }
3151 | FTYPE
3152 { $$ = ast::TypeDecl::Ftype; }
3153 | TTYPE
3154 { $$ = ast::TypeDecl::Ttype; }
3155 ;
3156
3157assertion_list_opt: // CFA
3158 // empty
3159 { $$ = nullptr; }
3160 | assertion_list
3161 ;
3162
3163assertion_list: // CFA
3164 assertion
3165 | assertion_list assertion
3166 { $$ = $1->set_last( $2 ); }
3167 ;
3168
3169assertion: // CFA
3170 '|' identifier_or_type_name '(' type_list ')'
3171 { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
3172 | '|' '{' trait_declaration_list '}'
3173 { $$ = $3; }
3174 // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
3175 // { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
3176 ;
3177
3178type_list: // CFA
3179 type
3180 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3181 | assignment_expression
3182 | type_list ',' type
3183 { $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
3184 | type_list ',' assignment_expression
3185 { $$ = $1->set_last( $3 ); }
3186 ;
3187
3188type_declaring_list: // CFA
3189 OTYPE type_declarator
3190 { $$ = $2; }
3191 | storage_class_list OTYPE type_declarator
3192 { $$ = $3->addQualifiers( $1 ); }
3193 | type_declaring_list ',' type_declarator
3194 { $$ = $1->set_last( $3->copySpecifiers( $1 ) ); }
3195 ;
3196
3197type_declarator: // CFA
3198 type_declarator_name assertion_list_opt
3199 { $$ = $1->addAssertions( $2 ); }
3200 | type_declarator_name assertion_list_opt '=' type
3201 { $$ = $1->addAssertions( $2 )->addType( $4 ); }
3202 ;
3203
3204type_declarator_name: // CFA
3205 identifier_or_type_name
3206 {
3207 typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "type_declarator_name 1" );
3208 $$ = DeclarationNode::newTypeDecl( $1, nullptr );
3209 }
3210 | identifier_or_type_name '(' type_parameter_list ')'
3211 {
3212 typedefTable.addToEnclosingScope( *$1, TYPEGENname, "type_declarator_name 2" );
3213 $$ = DeclarationNode::newTypeDecl( $1, $3 );
3214 }
3215 ;
3216
3217trait_specifier: // CFA
3218 TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
3219 {
3220 SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3221 $$ = DeclarationNode::newTrait( $2, $4, nullptr );
3222 }
3223 | forall TRAIT identifier_or_type_name '{' '}' // alternate
3224 { $$ = DeclarationNode::newTrait( $3, $1, nullptr ); }
3225 | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' trait_declaration_list '}'
3226 {
3227 SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3228 $$ = DeclarationNode::newTrait( $2, $4, $7 );
3229 }
3230 | forall TRAIT identifier_or_type_name '{' trait_declaration_list '}' // alternate
3231 { $$ = DeclarationNode::newTrait( $3, $1, $5 ); }
3232 ;
3233
3234trait_declaration_list: // CFA
3235 trait_declaration
3236 | trait_declaration_list trait_declaration
3237 { $$ = $1->set_last( $2 ); }
3238 ;
3239
3240trait_declaration: // CFA
3241 cfa_trait_declaring_list ';'
3242 | trait_declaring_list ';'
3243 ;
3244
3245cfa_trait_declaring_list: // CFA
3246 cfa_variable_specifier
3247 | cfa_function_specifier
3248 | cfa_trait_declaring_list ',' identifier_or_type_name
3249 { $$ = $1->set_last( $1->cloneType( $3 ) ); }
3250 ;
3251
3252trait_declaring_list: // CFA
3253 // Cannot declare an aggregate or enumeration in a trait.
3254 type_specifier_nobody declarator
3255 { $$ = $2->addType( $1 ); }
3256 | trait_declaring_list ',' declarator
3257 { $$ = $1->set_last( $1->cloneBaseType( $3 ) ); }
3258 | error
3259 { SemanticError( yylloc, "Possible cause is declaring an aggregate or enumeration type in a trait." ); $$ = nullptr; }
3260 ;
3261
3262// **************************** EXTERNAL DEFINITIONS *****************************
3263
3264translation_unit:
3265 // empty, input file
3266 | external_definition_list
3267 { parseTree = parseTree ? parseTree->set_last( $1 ) : $1; }
3268 ;
3269
3270external_definition_list:
3271 push external_definition pop
3272 { $$ = $2; }
3273 | external_definition_list push external_definition pop
3274 { $$ = $1 ? $1->set_last( $3 ) : $3; }
3275 ;
3276
3277external_definition_list_opt:
3278 // empty
3279 { $$ = nullptr; }
3280 | external_definition_list
3281 ;
3282
3283up:
3284 { typedefTable.up( forall ); forall = false; }
3285 ;
3286
3287down:
3288 { typedefTable.down(); }
3289 ;
3290
3291external_definition:
3292 DIRECTIVE
3293 { $$ = DeclarationNode::newDirectiveStmt( new StatementNode( build_directive( yylloc, $1 ) ) ); }
3294 | declaration
3295 {
3296 // Variable declarations of anonymous types requires creating a unique type-name across multiple translation
3297 // unit, which is a dubious task, especially because C uses name rather than structural typing; hence it is
3298 // disallowed at the moment.
3299 if ( $1->linkage == ast::Linkage::Cforall && ! $1->storageClasses.is_static &&
3300 $1->type && $1->type->kind == TypeData::AggregateInst ) {
3301 if ( $1->type->aggInst.aggregate->aggregate.anon ) {
3302 SemanticError( yylloc, "extern anonymous aggregate is currently unimplemented." ); $$ = nullptr;
3303 }
3304 }
3305 }
3306 | IDENTIFIER IDENTIFIER
3307 { IdentifierBeforeIdentifier( *$1.str, *$2.str, " declaration" ); $$ = nullptr; }
3308 | IDENTIFIER type_qualifier // invalid syntax rule
3309 { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
3310 | IDENTIFIER storage_class // invalid syntax rule
3311 { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
3312 | IDENTIFIER basic_type_name // invalid syntax rule
3313 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3314 | IDENTIFIER TYPEDEFname // invalid syntax rule
3315 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3316 | IDENTIFIER TYPEGENname // invalid syntax rule
3317 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3318 | external_function_definition
3319 | EXTENSION external_definition // GCC, multiple __extension__ allowed, meaning unknown
3320 {
3321 distExt( $2 ); // mark all fields in list
3322 $$ = $2;
3323 }
3324 | ASM '(' string_literal ')' ';' // GCC, global assembler statement
3325 { $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( yylloc, false, $3, nullptr ) ) ); }
3326 | EXTERN STRINGliteral
3327 {
3328 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
3329 linkage = ast::Linkage::update( yylloc, linkage, $2 );
3330 }
3331 up external_definition down
3332 {
3333 linkage = linkageStack.top();
3334 linkageStack.pop();
3335 $$ = $5;
3336 }
3337 | EXTERN STRINGliteral // C++-style linkage specifier
3338 {
3339 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
3340 linkage = ast::Linkage::update( yylloc, linkage, $2 );
3341 }
3342 '{' up external_definition_list_opt down '}'
3343 {
3344 linkage = linkageStack.top();
3345 linkageStack.pop();
3346 $$ = $6;
3347 }
3348 // global distribution
3349 | type_qualifier_list
3350 {
3351 if ( $1->type->qualifiers.any() ) {
3352 SemanticError( yylloc, "illegal syntax, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3353 }
3354 if ( $1->type->forall ) forall = true; // remember generic type
3355 }
3356 '{' up external_definition_list_opt down '}' // CFA, namespace
3357 {
3358 distQual( $5, $1 );
3359 forall = false;
3360 $$ = $5;
3361 }
3362 | declaration_qualifier_list
3363 {
3364 if ( $1->type && $1->type->qualifiers.any() ) {
3365 SemanticError( yylloc, "illegal syntax, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3366 }
3367 if ( $1->type && $1->type->forall ) forall = true; // remember generic type
3368 }
3369 '{' up external_definition_list_opt down '}' // CFA, namespace
3370 {
3371 distQual( $5, $1 );
3372 forall = false;
3373 $$ = $5;
3374 }
3375 | declaration_qualifier_list type_qualifier_list
3376 {
3377 if ( ($1->type && $1->type->qualifiers.any()) || ($2->type && $2->type->qualifiers.any()) ) {
3378 SemanticError( yylloc, "illegal syntax, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3379 }
3380 if ( ($1->type && $1->type->forall) || ($2->type && $2->type->forall) ) forall = true; // remember generic type
3381 }
3382 '{' up external_definition_list_opt down '}' // CFA, namespace
3383 {
3384 distQual( $6, $1->addQualifiers( $2 ) );
3385 forall = false;
3386 $$ = $6;
3387 }
3388 | ';' // empty declaration
3389 { $$ = nullptr; }
3390 ;
3391
3392external_function_definition:
3393 function_definition
3394 // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
3395 // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
3396 // Parsing is possible because function_definition does not appear in the context of an expression (nested
3397 // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
3398 // declaration must still have a type_specifier. OBSOLESCENT (see 1)
3399 | function_declarator compound_statement
3400 { $$ = $1->addFunctionBody( $2 ); }
3401 | KR_function_declarator KR_parameter_list_opt compound_statement
3402 { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
3403 ;
3404
3405with_clause_opt:
3406 // empty
3407 { $$ = nullptr; forall = false; }
3408 | WITH '(' type_list ')' attribute_list_opt // support scoped enumeration
3409 {
3410 $$ = $3; forall = false;
3411 if ( $5 ) {
3412 SemanticError( yylloc, "illegal syntax, attributes cannot be associated with function body. Move attribute(s) before \"with\" clause." );
3413 $$ = nullptr;
3414 } // if
3415 }
3416 ;
3417
3418function_definition:
3419 cfa_function_declaration with_clause_opt compound_statement // CFA
3420 {
3421 // Add the function body to the last identifier in the function definition list, i.e., foo3:
3422 // [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
3423 $1->get_last()->addFunctionBody( $3, $2 );
3424 $$ = $1;
3425 }
3426 | declaration_specifier function_declarator with_clause_opt compound_statement
3427 {
3428 rebindForall( $1, $2 );
3429 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3430 }
3431 | declaration_specifier function_type_redeclarator with_clause_opt compound_statement
3432 {
3433 rebindForall( $1, $2 );
3434 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3435 }
3436 // handles default int return type, OBSOLESCENT (see 1)
3437 | type_qualifier_list function_declarator with_clause_opt compound_statement
3438 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3439 // handles default int return type, OBSOLESCENT (see 1)
3440 | declaration_qualifier_list function_declarator with_clause_opt compound_statement
3441 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3442 // handles default int return type, OBSOLESCENT (see 1)
3443 | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
3444 { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3445
3446 // Old-style K&R function definition, OBSOLESCENT (see 4)
3447 | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3448 {
3449 rebindForall( $1, $2 );
3450 $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
3451 }
3452 // handles default int return type, OBSOLESCENT (see 1)
3453 | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3454 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3455 // handles default int return type, OBSOLESCENT (see 1)
3456 | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3457 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3458 // handles default int return type, OBSOLESCENT (see 1)
3459 | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3460 { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3461 ;
3462
3463declarator:
3464 variable_declarator
3465 | variable_type_redeclarator
3466 | function_declarator
3467 | function_type_redeclarator
3468 ;
3469
3470subrange:
3471 constant_expression '~' constant_expression // CFA, integer subrange
3472 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
3473 ;
3474
3475// **************************** ASM *****************************
3476
3477asm_name_opt: // GCC
3478 // empty
3479 { $$ = nullptr; }
3480 | ASM '(' string_literal ')' attribute_list_opt
3481 {
3482 DeclarationNode * name = new DeclarationNode();
3483 name->asmName = maybeMoveBuild( $3 );
3484 $$ = name->addQualifiers( $5 );
3485 }
3486 ;
3487
3488// **************************** ATTRIBUTE *****************************
3489
3490attribute_list_opt: // GCC
3491 // empty
3492 { $$ = nullptr; }
3493 | attribute_list
3494 ;
3495
3496attribute_list: // GCC
3497 attribute
3498 | attribute_list attribute
3499 { $$ = $2->addQualifiers( $1 ); }
3500 ;
3501
3502attribute: // GCC
3503 ATTRIBUTE '(' '(' attribute_name_list ')' ')'
3504 { $$ = $4; }
3505 | ATTRIBUTE '(' attribute_name_list ')' // CFA
3506 { $$ = $3; }
3507 | ATTR attribute_name_list ']' // CFA, @[...]
3508 { $$ = $2; }
3509 | C23_ATTRIBUTE // C23, [[...]], see lexer
3510 { $$ = DeclarationNode::newAttribute( $1 ); }
3511 ;
3512
3513attribute_name_list: // GCC
3514 attribute_name
3515 | attribute_name_list ',' attribute_name
3516 { $$ = $3->addQualifiers( $1 ); }
3517 ;
3518
3519attribute_name: // GCC
3520 // empty
3521 { $$ = nullptr; }
3522 | attr_name
3523 { $$ = DeclarationNode::newAttribute( $1 ); }
3524 | attr_name '(' argument_expression_list_opt ')'
3525 { $$ = DeclarationNode::newAttribute( $1, $3 ); }
3526 ;
3527
3528attr_name: // GCC
3529 identifier_or_type_name
3530 | FALLTHROUGH
3531 { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
3532 | CONST
3533 { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
3534 ;
3535
3536// ============================================================================
3537// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
3538// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
3539// in:
3540//
3541// int (*f())[10] { ... };
3542// ... (*f())[3] += 1; // definition mimics usage
3543//
3544// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
3545// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
3546// ============================================================================
3547
3548// ----------------------------------------------------------------------------
3549// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
3550// to define a variable or function prototype, e.g.:
3551//
3552// valid declaration invalid definition
3553// ----------------- ------------------
3554// int f; int f {}
3555// int *f; int *f {}
3556// int f[10]; int f[10] {}
3557// int (*f)(int); int (*f)(int) {}
3558//
3559// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
3560// variable_declarator and function_declarator.
3561// ----------------------------------------------------------------------------
3562
3563// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
3564// declaring an array of functions versus a pointer to an array of functions.
3565
3566paren_identifier:
3567 identifier_at
3568 { $$ = DeclarationNode::newName( $1 ); }
3569 | '?' identifier
3570 // { SemanticError( yylloc, "keyword parameter is currently unimplemented." ); $$ = nullptr; }
3571 { $$ = DeclarationNode::newName( $2 ); }
3572 | '(' paren_identifier ')' // redundant parenthesis
3573 { $$ = $2; }
3574 ;
3575
3576variable_declarator:
3577 paren_identifier attribute_list_opt
3578 { $$ = $1->addQualifiers( $2 ); }
3579 | variable_ptr
3580 | variable_array attribute_list_opt
3581 { $$ = $1->addQualifiers( $2 ); }
3582 | variable_function attribute_list_opt
3583 { $$ = $1->addQualifiers( $2 ); }
3584 ;
3585
3586variable_ptr:
3587 ptrref_operator variable_declarator
3588 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3589 | ptrref_operator type_qualifier_list variable_declarator
3590 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3591 | '(' variable_ptr ')' attribute_list_opt // redundant parenthesis
3592 { $$ = $2->addQualifiers( $4 ); }
3593 | '(' attribute_list variable_ptr ')' attribute_list_opt // redundant parenthesis
3594 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3595 ;
3596
3597variable_array:
3598 paren_identifier array_dimension
3599 { $$ = $1->addArray( $2 ); }
3600 | '(' variable_ptr ')' array_dimension
3601 { $$ = $2->addArray( $4 ); }
3602 | '(' attribute_list variable_ptr ')' array_dimension
3603 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3604 | '(' variable_array ')' multi_array_dimension // redundant parenthesis
3605 { $$ = $2->addArray( $4 ); }
3606 | '(' attribute_list variable_array ')' multi_array_dimension // redundant parenthesis
3607 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3608 | '(' variable_array ')' // redundant parenthesis
3609 { $$ = $2; }
3610 | '(' attribute_list variable_array ')' // redundant parenthesis
3611 { $$ = $3->addQualifiers( $2 ); }
3612 ;
3613
3614variable_function:
3615 '(' variable_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3616 { $$ = $2->addParamList( $5 ); }
3617 | '(' attribute_list variable_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3618 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3619 | '(' variable_function ')' // redundant parenthesis
3620 { $$ = $2; }
3621 | '(' attribute_list variable_function ')' // redundant parenthesis
3622 { $$ = $3->addQualifiers( $2 ); }
3623 ;
3624
3625// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
3626// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
3627// is the same scope. The pattern precludes returning arrays and functions versus pointers to arrays and functions.
3628
3629function_declarator:
3630 function_no_ptr attribute_list_opt
3631 { $$ = $1->addQualifiers( $2 ); }
3632 | function_ptr
3633 | function_array attribute_list_opt
3634 { $$ = $1->addQualifiers( $2 ); }
3635 ;
3636
3637function_no_ptr:
3638 paren_identifier '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3639 { $$ = $1->addParamList( $3 ); }
3640 | '(' function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3641 { $$ = $2->addParamList( $5 ); }
3642 | '(' attribute_list function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3643 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3644 | '(' function_no_ptr ')' // redundant parenthesis
3645 { $$ = $2; }
3646 | '(' attribute_list function_no_ptr ')' // redundant parenthesis
3647 { $$ = $3->addQualifiers( $2 ); }
3648 ;
3649
3650function_ptr:
3651 ptrref_operator function_declarator
3652 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3653 | ptrref_operator type_qualifier_list function_declarator
3654 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3655 | '(' function_ptr ')' attribute_list_opt
3656 { $$ = $2->addQualifiers( $4 ); }
3657 | '(' attribute_list function_ptr ')' attribute_list_opt
3658 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3659 ;
3660
3661function_array:
3662 '(' function_ptr ')' array_dimension
3663 { $$ = $2->addArray( $4 ); }
3664 | '(' attribute_list function_ptr ')' array_dimension
3665 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3666 | '(' function_array ')' multi_array_dimension // redundant parenthesis
3667 { $$ = $2->addArray( $4 ); }
3668 | '(' attribute_list function_array ')' multi_array_dimension // redundant parenthesis
3669 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3670 | '(' function_array ')' // redundant parenthesis
3671 { $$ = $2; }
3672 | '(' attribute_list function_array ')' // redundant parenthesis
3673 { $$ = $3->addQualifiers( $2 ); }
3674 ;
3675
3676// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
3677//
3678// f( a, b, c ) int a, *b, c[]; {}
3679//
3680// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
3681// returning arrays and functions versus pointers to arrays and functions.
3682
3683KR_function_declarator:
3684 KR_function_no_ptr
3685 | KR_function_ptr
3686 | KR_function_array
3687 ;
3688
3689KR_function_no_ptr:
3690 paren_identifier '(' identifier_list ')' // function_declarator handles empty parameter
3691 { $$ = $1->addIdList( $3 ); }
3692 | '(' KR_function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3693 { $$ = $2->addParamList( $5 ); }
3694 | '(' attribute_list KR_function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3695 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3696 | '(' KR_function_no_ptr ')' // redundant parenthesis
3697 { $$ = $2; }
3698 | '(' attribute_list KR_function_no_ptr ')' // redundant parenthesis
3699 { $$ = $3->addQualifiers( $2 ); }
3700 ;
3701
3702KR_function_ptr:
3703 ptrref_operator KR_function_declarator
3704 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3705 | ptrref_operator type_qualifier_list KR_function_declarator
3706 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3707 | '(' KR_function_ptr ')'
3708 { $$ = $2; }
3709 | '(' attribute_list KR_function_ptr ')'
3710 { $$ = $3->addQualifiers( $2 ); }
3711 ;
3712
3713KR_function_array:
3714 '(' KR_function_ptr ')' array_dimension
3715 { $$ = $2->addArray( $4 ); }
3716 | '(' attribute_list KR_function_ptr ')' array_dimension
3717 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3718 | '(' KR_function_array ')' multi_array_dimension // redundant parenthesis
3719 { $$ = $2->addArray( $4 ); }
3720 | '(' attribute_list KR_function_array ')' multi_array_dimension // redundant parenthesis
3721 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3722 | '(' KR_function_array ')' // redundant parenthesis
3723 { $$ = $2; }
3724 | '(' attribute_list KR_function_array ')' // redundant parenthesis
3725 { $$ = $3->addQualifiers( $2 ); }
3726 ;
3727
3728// This pattern parses a declaration for a variable that redefines a type name, e.g.:
3729//
3730// typedef int foo;
3731// {
3732// int foo; // redefine typedef name in new scope
3733// }
3734
3735paren_type:
3736 typedef_name
3737 {
3738 // hide type name in enclosing scope by variable name
3739 typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "paren_type" );
3740 }
3741 | '(' paren_type ')'
3742 { $$ = $2; }
3743 ;
3744
3745variable_type_redeclarator:
3746 paren_type attribute_list_opt
3747 { $$ = $1->addQualifiers( $2 ); }
3748 | variable_type_ptr
3749 | variable_type_array attribute_list_opt
3750 { $$ = $1->addQualifiers( $2 ); }
3751 | variable_type_function attribute_list_opt
3752 { $$ = $1->addQualifiers( $2 ); }
3753 ;
3754
3755variable_type_ptr:
3756 ptrref_operator variable_type_redeclarator
3757 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3758 | ptrref_operator type_qualifier_list variable_type_redeclarator
3759 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3760 | '(' variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3761 { $$ = $2->addQualifiers( $4 ); }
3762 | '(' attribute_list variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3763 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3764 ;
3765
3766variable_type_array:
3767 paren_type array_dimension
3768 { $$ = $1->addArray( $2 ); }
3769 | '(' variable_type_ptr ')' array_dimension
3770 { $$ = $2->addArray( $4 ); }
3771 | '(' attribute_list variable_type_ptr ')' array_dimension
3772 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3773 | '(' variable_type_array ')' multi_array_dimension // redundant parenthesis
3774 { $$ = $2->addArray( $4 ); }
3775 | '(' attribute_list variable_type_array ')' multi_array_dimension // redundant parenthesis
3776 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3777 | '(' variable_type_array ')' // redundant parenthesis
3778 { $$ = $2; }
3779 | '(' attribute_list variable_type_array ')' // redundant parenthesis
3780 { $$ = $3->addQualifiers( $2 ); }
3781 ;
3782
3783variable_type_function:
3784 '(' variable_type_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3785 { $$ = $2->addParamList( $5 ); }
3786 | '(' attribute_list variable_type_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3787 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3788 | '(' variable_type_function ')' // redundant parenthesis
3789 { $$ = $2; }
3790 | '(' attribute_list variable_type_function ')' // redundant parenthesis
3791 { $$ = $3->addQualifiers( $2 ); }
3792 ;
3793
3794// This pattern parses a declaration for a function prototype that redefines a type name. It precludes declaring an
3795// array of functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to
3796// arrays and functions.
3797
3798function_type_redeclarator:
3799 function_type_no_ptr attribute_list_opt
3800 { $$ = $1->addQualifiers( $2 ); }
3801 | function_type_ptr
3802 | function_type_array attribute_list_opt
3803 { $$ = $1->addQualifiers( $2 ); }
3804 ;
3805
3806function_type_no_ptr:
3807 paren_type '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3808 { $$ = $1->addParamList( $3 ); }
3809 | '(' function_type_ptr ')' '(' parameter_list_ellipsis_opt ')'
3810 { $$ = $2->addParamList( $5 ); }
3811 | '(' attribute_list function_type_ptr ')' '(' parameter_list_ellipsis_opt ')'
3812 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3813 | '(' function_type_no_ptr ')' // redundant parenthesis
3814 { $$ = $2; }
3815 | '(' attribute_list function_type_no_ptr ')' // redundant parenthesis
3816 { $$ = $3->addQualifiers( $2 ); }
3817 ;
3818
3819function_type_ptr:
3820 ptrref_operator function_type_redeclarator
3821 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3822 | ptrref_operator type_qualifier_list function_type_redeclarator
3823 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3824 | '(' function_type_ptr ')' attribute_list_opt
3825 { $$ = $2->addQualifiers( $4 ); }
3826 | '(' attribute_list function_type_ptr ')' attribute_list_opt
3827 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3828 ;
3829
3830function_type_array:
3831 '(' function_type_ptr ')' array_dimension
3832 { $$ = $2->addArray( $4 ); }
3833 | '(' attribute_list function_type_ptr ')' array_dimension
3834 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3835 | '(' function_type_array ')' multi_array_dimension // redundant parenthesis
3836 { $$ = $2->addArray( $4 ); }
3837 | '(' attribute_list function_type_array ')' multi_array_dimension // redundant parenthesis
3838 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3839 | '(' function_type_array ')' // redundant parenthesis
3840 { $$ = $2; }
3841 | '(' attribute_list function_type_array ')' // redundant parenthesis
3842 { $$ = $3->addQualifiers( $2 ); }
3843 ;
3844
3845// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
3846// typedef name and allows the C99 array options, which can only appear in a parameter list. The pattern precludes
3847// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
3848// pointers to arrays and functions.
3849
3850identifier_parameter_declarator:
3851 paren_identifier attribute_list_opt
3852 { $$ = $1->addQualifiers( $2 ); }
3853 | '&' MUTEX paren_identifier attribute_list_opt
3854 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
3855 OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3856 | identifier_parameter_ptr
3857 | identifier_parameter_array attribute_list_opt
3858 { $$ = $1->addQualifiers( $2 ); }
3859 | identifier_parameter_function attribute_list_opt
3860 { $$ = $1->addQualifiers( $2 ); }
3861 ;
3862
3863identifier_parameter_ptr:
3864 ptrref_operator identifier_parameter_declarator
3865 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3866 | ptrref_operator type_qualifier_list identifier_parameter_declarator
3867 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3868 | '(' identifier_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3869 { $$ = $2->addQualifiers( $4 ); }
3870 ;
3871
3872identifier_parameter_array:
3873 paren_identifier array_parameter_dimension
3874 { $$ = $1->addArray( $2 ); }
3875 | '(' identifier_parameter_ptr ')' array_dimension
3876 { $$ = $2->addArray( $4 ); }
3877 | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3878 { $$ = $2->addArray( $4 ); }
3879 | '(' identifier_parameter_array ')' // redundant parenthesis
3880 { $$ = $2; }
3881 ;
3882
3883identifier_parameter_function:
3884 paren_identifier '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3885 { $$ = $1->addParamList( $3 ); }
3886 | '(' identifier_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3887 { $$ = $2->addParamList( $5 ); }
3888 | '(' identifier_parameter_function ')' // redundant parenthesis
3889 { $$ = $2; }
3890 ;
3891
3892// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3893// e.g.:
3894//
3895// typedef int foo;
3896// forall( otype T ) struct foo;
3897// int f( int foo ); // redefine typedef name in new scope
3898//
3899// and allows the C99 array options, which can only appear in a parameter list.
3900
3901type_parameter_redeclarator:
3902 typedef_name attribute_list_opt
3903 { $$ = $1->addQualifiers( $2 ); }
3904 | '&' MUTEX typedef_name attribute_list_opt
3905 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
3906 OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3907 | type_parameter_ptr
3908 | type_parameter_array attribute_list_opt
3909 { $$ = $1->addQualifiers( $2 ); }
3910 | type_parameter_function attribute_list_opt
3911 { $$ = $1->addQualifiers( $2 ); }
3912 ;
3913
3914typedef_name:
3915 TYPEDEFname
3916 { $$ = DeclarationNode::newName( $1 ); }
3917 | TYPEGENname
3918 { $$ = DeclarationNode::newName( $1 ); }
3919 ;
3920
3921type_parameter_ptr:
3922 ptrref_operator type_parameter_redeclarator
3923 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3924 | ptrref_operator type_qualifier_list type_parameter_redeclarator
3925 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3926 | '(' type_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3927 { $$ = $2->addQualifiers( $4 ); }
3928 ;
3929
3930type_parameter_array:
3931 typedef_name array_parameter_dimension
3932 { $$ = $1->addArray( $2 ); }
3933 | '(' type_parameter_ptr ')' array_parameter_dimension
3934 { $$ = $2->addArray( $4 ); }
3935 ;
3936
3937type_parameter_function:
3938 typedef_name '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3939 { $$ = $1->addParamList( $3 ); }
3940 | '(' type_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3941 { $$ = $2->addParamList( $5 ); }
3942 ;
3943
3944// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3945// which the type applies, e.g.:
3946//
3947// sizeof( int );
3948// sizeof( int * );
3949// sizeof( int [10] );
3950// sizeof( int (*)() );
3951// sizeof( int () );
3952//
3953// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3954// and functions versus pointers to arrays and functions.
3955
3956abstract_declarator:
3957 abstract_ptr
3958 | abstract_array attribute_list_opt
3959 { $$ = $1->addQualifiers( $2 ); }
3960 | abstract_function attribute_list_opt
3961 { $$ = $1->addQualifiers( $2 ); }
3962 ;
3963
3964abstract_ptr:
3965 ptrref_operator
3966 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3967 | ptrref_operator type_qualifier_list
3968 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3969 | ptrref_operator abstract_declarator
3970 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3971 | ptrref_operator type_qualifier_list abstract_declarator
3972 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3973 | '(' abstract_ptr ')' attribute_list_opt
3974 { $$ = $2->addQualifiers( $4 ); }
3975 ;
3976
3977abstract_array:
3978 array_dimension
3979 | '(' abstract_ptr ')' array_dimension
3980 { $$ = $2->addArray( $4 ); }
3981 | '(' abstract_array ')' multi_array_dimension // redundant parenthesis
3982 { $$ = $2->addArray( $4 ); }
3983 | '(' abstract_array ')' // redundant parenthesis
3984 { $$ = $2; }
3985 ;
3986
3987abstract_function:
3988 '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3989 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
3990 | '(' abstract_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3991 { $$ = $2->addParamList( $5 ); }
3992 | '(' abstract_function ')' // redundant parenthesis
3993 { $$ = $2; }
3994 ;
3995
3996array_dimension:
3997 // Only the first dimension can be empty.
3998 '[' ']'
3999 { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
4000 | '[' ']' multi_array_dimension
4001 { $$ = DeclarationNode::newArray( nullptr, nullptr, false )->addArray( $3 ); }
4002 // Cannot use constant_expression because of tuples => semantic check
4003 | '[' assignment_expression ',' comma_expression ']' // CFA
4004 { $$ = DeclarationNode::newArray( $2, nullptr, false )->addArray( DeclarationNode::newArray( $4, nullptr, false ) ); }
4005 // { SemanticError( yylloc, "New array dimension is currently unimplemented." ); $$ = nullptr; }
4006
4007 // If needed, the following parses and does not use comma_expression, so the array structure can be built.
4008 // | '[' push assignment_expression pop ',' push array_dimension_list pop ']' // CFA
4009
4010 | '[' array_type_list ']' // CFA
4011 { $$ = DeclarationNode::newArray( $2, nullptr, false ); }
4012 | multi_array_dimension
4013 ;
4014
4015// array_dimension_list:
4016// assignment_expression
4017// | array_dimension_list ',' assignment_expression
4018// ;
4019
4020array_type_list:
4021 basic_type_name
4022 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
4023 | type_name
4024 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
4025 | assignment_expression upupeq assignment_expression
4026 | array_type_list ',' basic_type_name
4027 { $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
4028 | array_type_list ',' type_name
4029 { $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
4030 | array_type_list ',' assignment_expression upupeq assignment_expression
4031 ;
4032
4033upupeq:
4034 '~'
4035 { $$ = OperKinds::LThan; }
4036 | ErangeUpEq
4037 { $$ = OperKinds::LEThan; }
4038 ;
4039
4040multi_array_dimension:
4041 '[' assignment_expression ']'
4042 { $$ = DeclarationNode::newArray( $2, nullptr, false ); }
4043 | '[' '*' ']' // C99
4044 { $$ = DeclarationNode::newVarArray( 0 ); }
4045 | multi_array_dimension '[' assignment_expression ']'
4046 { $$ = $1->addArray( DeclarationNode::newArray( $3, nullptr, false ) ); }
4047 | multi_array_dimension '[' '*' ']' // C99
4048 { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
4049 ;
4050
4051// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
4052// identifier to which the type applies, e.g.:
4053//
4054// int f( int ); // not handled here
4055// int f( int * ); // abstract function-prototype parameter; no parameter name specified
4056// int f( int (*)() ); // abstract function-prototype parameter; no parameter name specified
4057// int f( int (int) ); // abstract function-prototype parameter; no parameter name specified
4058//
4059// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
4060// and functions versus pointers to arrays and functions. In addition, the pattern handles the special meaning of
4061// parenthesis around a typedef name:
4062//
4063// ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
4064// parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
4065// not as redundant parentheses around the identifier."
4066//
4067// For example:
4068//
4069// typedef float T;
4070// int f( int ( T [5] ) ); // see abstract_parameter_declarator
4071// int g( int ( T ( int ) ) ); // see abstract_parameter_declarator
4072// int f( int f1( T a[5] ) ); // see identifier_parameter_declarator
4073// int g( int g1( T g2( int p ) ) ); // see identifier_parameter_declarator
4074//
4075// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
4076// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
4077// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
4078// functions.
4079
4080abstract_parameter_declarator_opt:
4081 // empty
4082 { $$ = nullptr; }
4083 | abstract_parameter_declarator
4084 ;
4085
4086abstract_parameter_declarator:
4087 abstract_parameter_ptr
4088 | '&' MUTEX attribute_list_opt
4089 { $$ = DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
4090 OperKinds::AddressOf )->addQualifiers( $3 ); }
4091 | abstract_parameter_array attribute_list_opt
4092 { $$ = $1->addQualifiers( $2 ); }
4093 | abstract_parameter_function attribute_list_opt
4094 { $$ = $1->addQualifiers( $2 ); }
4095 ;
4096
4097abstract_parameter_ptr:
4098 ptrref_operator
4099 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
4100 | ptrref_operator type_qualifier_list
4101 { $$ = DeclarationNode::newPointer( $2, $1 ); }
4102 | ptrref_operator abstract_parameter_declarator
4103 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4104 | ptrref_operator type_qualifier_list abstract_parameter_declarator
4105 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4106 | '(' abstract_parameter_ptr ')' attribute_list_opt // redundant parenthesis
4107 { $$ = $2->addQualifiers( $4 ); }
4108 ;
4109
4110abstract_parameter_array:
4111 array_parameter_dimension
4112 | '(' abstract_parameter_ptr ')' array_parameter_dimension
4113 { $$ = $2->addArray( $4 ); }
4114 | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
4115 { $$ = $2->addArray( $4 ); }
4116 | '(' abstract_parameter_array ')' // redundant parenthesis
4117 { $$ = $2; }
4118 ;
4119
4120abstract_parameter_function:
4121 '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4122 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
4123 | '(' abstract_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4124 { $$ = $2->addParamList( $5 ); }
4125 | '(' abstract_parameter_function ')' // redundant parenthesis
4126 { $$ = $2; }
4127 ;
4128
4129array_parameter_dimension:
4130 // Only the first dimension can be empty or have qualifiers.
4131 array_parameter_1st_dimension
4132 | array_parameter_1st_dimension multi_array_dimension
4133 { $$ = $1->addArray( $2 ); }
4134 | multi_array_dimension
4135 ;
4136
4137// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
4138//
4139// ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
4140// a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
4141
4142array_parameter_1st_dimension:
4143 '[' ']'
4144 { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
4145 // multi_array_dimension handles the '[' '*' ']' case
4146 | '[' push type_qualifier_list '*' pop ']' // remaining C99
4147 { $$ = DeclarationNode::newVarArray( $3 ); }
4148 | '[' push type_qualifier_list pop ']'
4149 { $$ = DeclarationNode::newArray( nullptr, $3, false ); }
4150 // multi_array_dimension handles the '[' assignment_expression ']' case
4151 | '[' push type_qualifier_list assignment_expression pop ']'
4152 { $$ = DeclarationNode::newArray( $4, $3, false ); }
4153 | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
4154 { $$ = DeclarationNode::newArray( $5, $4, true ); }
4155 | '[' push type_qualifier_list STATIC assignment_expression pop ']'
4156 { $$ = DeclarationNode::newArray( $5, $3, true ); }
4157 ;
4158
4159// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
4160//
4161// struct S {
4162// int;
4163// int *;
4164// int [10];
4165// int (*)();
4166// };
4167
4168variable_abstract_declarator:
4169 variable_abstract_ptr
4170 | variable_abstract_array attribute_list_opt
4171 { $$ = $1->addQualifiers( $2 ); }
4172 | variable_abstract_function attribute_list_opt
4173 { $$ = $1->addQualifiers( $2 ); }
4174 ;
4175
4176variable_abstract_ptr:
4177 ptrref_operator
4178 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
4179 | ptrref_operator type_qualifier_list
4180 { $$ = DeclarationNode::newPointer( $2, $1 ); }
4181 | ptrref_operator variable_abstract_declarator
4182 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4183 | ptrref_operator type_qualifier_list variable_abstract_declarator
4184 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4185 | '(' variable_abstract_ptr ')' attribute_list_opt // redundant parenthesis
4186 { $$ = $2->addQualifiers( $4 ); }
4187 ;
4188
4189variable_abstract_array:
4190 array_dimension
4191 | '(' variable_abstract_ptr ')' array_dimension
4192 { $$ = $2->addArray( $4 ); }
4193 | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
4194 { $$ = $2->addArray( $4 ); }
4195 | '(' variable_abstract_array ')' // redundant parenthesis
4196 { $$ = $2; }
4197 ;
4198
4199variable_abstract_function:
4200 '(' variable_abstract_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4201 { $$ = $2->addParamList( $5 ); }
4202 | '(' variable_abstract_function ')' // redundant parenthesis
4203 { $$ = $2; }
4204 ;
4205
4206// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
4207// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
4208
4209cfa_identifier_parameter_declarator_tuple: // CFA
4210 cfa_identifier_parameter_declarator_no_tuple
4211 | cfa_abstract_tuple
4212 | type_qualifier_list cfa_abstract_tuple
4213 { $$ = $2->addQualifiers( $1 ); }
4214 ;
4215
4216cfa_identifier_parameter_declarator_no_tuple: // CFA
4217 cfa_identifier_parameter_ptr
4218 | cfa_identifier_parameter_array
4219 | type_qualifier_list cfa_identifier_parameter_array
4220 { $$ = $2->addQualifiers( $1 ); }
4221 ;
4222
4223cfa_identifier_parameter_ptr: // CFA
4224 // No SUE declaration in parameter list.
4225 ptrref_operator type_specifier_nobody
4226 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4227 | type_qualifier_list ptrref_operator type_specifier_nobody
4228 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4229 | ptrref_operator cfa_abstract_function
4230 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4231 | type_qualifier_list ptrref_operator cfa_abstract_function
4232 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4233 | ptrref_operator cfa_identifier_parameter_declarator_tuple
4234 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4235 | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
4236 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4237 ;
4238
4239cfa_identifier_parameter_array: // CFA
4240 // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
4241 // shift/reduce conflict with new-style empty (void) function return type.
4242 '[' ']' type_specifier_nobody
4243 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4244 | '[' ']' cfa_abstract_tuple
4245 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4246 | cfa_array_parameter_1st_dimension type_specifier_nobody
4247 { $$ = $2->addNewArray( $1 ); }
4248 | cfa_array_parameter_1st_dimension cfa_abstract_tuple
4249 { $$ = $2->addNewArray( $1 ); }
4250 | '[' ']' multi_array_dimension type_specifier_nobody
4251 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4252 | '[' ']' multi_array_dimension cfa_abstract_tuple
4253 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4254 | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
4255 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4256 | cfa_array_parameter_1st_dimension multi_array_dimension cfa_abstract_tuple
4257 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4258 | multi_array_dimension type_specifier_nobody
4259 { $$ = $2->addNewArray( $1 ); }
4260 | multi_array_dimension cfa_abstract_tuple
4261 { $$ = $2->addNewArray( $1 ); }
4262
4263 | '[' ']' cfa_identifier_parameter_ptr
4264 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4265 | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
4266 { $$ = $2->addNewArray( $1 ); }
4267 | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
4268 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4269 | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
4270 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4271 | multi_array_dimension cfa_identifier_parameter_ptr
4272 { $$ = $2->addNewArray( $1 ); }
4273 ;
4274
4275cfa_array_parameter_1st_dimension:
4276 '[' type_qualifier_list '*' ']' // remaining C99
4277 { $$ = DeclarationNode::newVarArray( $2 ); }
4278 | '[' type_qualifier_list assignment_expression ']'
4279 { $$ = DeclarationNode::newArray( $3, $2, false ); }
4280 | '[' declaration_qualifier_list assignment_expression ']'
4281 // declaration_qualifier_list must be used because of shift/reduce conflict with
4282 // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
4283 // appear in this context.
4284 { $$ = DeclarationNode::newArray( $3, $2, true ); }
4285 | '[' declaration_qualifier_list type_qualifier_list assignment_expression ']'
4286 { $$ = DeclarationNode::newArray( $4, $3->addQualifiers( $2 ), true ); }
4287 ;
4288
4289// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
4290// identifier to which the type applies, e.g.:
4291//
4292// [int] f( int ); // abstract variable parameter; no parameter name specified
4293// [int] f( [int] (int) ); // abstract function-prototype parameter; no parameter name specified
4294//
4295// These rules need LR(3):
4296//
4297// cfa_abstract_tuple identifier_or_type_name
4298// '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_list_ellipsis_opt ')'
4299//
4300// since a function return type can be syntactically identical to a tuple type:
4301//
4302// [int, int] t;
4303// [int, int] f( int );
4304//
4305// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
4306// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
4307// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
4308// duplicated when appearing with cfa_function_specifier.
4309
4310cfa_abstract_declarator_tuple: // CFA
4311 cfa_abstract_tuple
4312 | type_qualifier_list cfa_abstract_tuple
4313 { $$ = $2->addQualifiers( $1 ); }
4314 | cfa_abstract_declarator_no_tuple
4315 ;
4316
4317cfa_abstract_declarator_no_tuple: // CFA
4318 cfa_abstract_ptr
4319 | cfa_abstract_array
4320 ;
4321
4322cfa_abstract_ptr: // CFA
4323 ptrref_operator type_specifier
4324 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4325 | type_qualifier_list ptrref_operator type_specifier
4326 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4327 | ptrref_operator cfa_abstract_function
4328 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4329 | type_qualifier_list ptrref_operator cfa_abstract_function
4330 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4331 | ptrref_operator cfa_abstract_declarator_tuple
4332 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4333 | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
4334 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4335 ;
4336
4337cfa_abstract_array: // CFA
4338 // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
4339 // empty (void) function return type.
4340 '[' ']' type_specifier
4341 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4342 | '[' ']' multi_array_dimension type_specifier
4343 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4344 | multi_array_dimension type_specifier
4345 { $$ = $2->addNewArray( $1 ); }
4346 | '[' ']' cfa_abstract_ptr
4347 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4348 | '[' ']' multi_array_dimension cfa_abstract_ptr
4349 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4350 | multi_array_dimension cfa_abstract_ptr
4351 { $$ = $2->addNewArray( $1 ); }
4352 ;
4353
4354cfa_abstract_tuple: // CFA
4355 '[' cfa_abstract_parameter_list ']'
4356 { $$ = DeclarationNode::newTuple( $2 ); }
4357 | '[' type_specifier_nobody ELLIPSIS ']'
4358 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4359 | '[' type_specifier_nobody ELLIPSIS constant_expression ']'
4360 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4361 ;
4362
4363cfa_abstract_function: // CFA
4364 '[' ']' '(' cfa_parameter_list_ellipsis_opt ')'
4365 { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
4366 | cfa_abstract_tuple '(' push cfa_parameter_list_ellipsis_opt pop ')'
4367 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4368 | cfa_function_return '(' push cfa_parameter_list_ellipsis_opt pop ')'
4369 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4370 ;
4371
4372// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
4373// each declaration, and in the specifier-qualifier list in each structure declaration and type name."
4374//
4375// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
4376// the declaration specifiers in a declaration is an obsolescent feature."
4377//
4378// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
4379// prototype-format parameter type declarators) is an obsolescent feature."
4380//
4381// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
4382// declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
4383
4384// ************************ MISCELLANEOUS ********************************
4385
4386comma_opt: // redundant comma
4387 // empty
4388 | ','
4389 ;
4390
4391default_initializer_opt:
4392 // empty
4393 { $$ = nullptr; }
4394 | '=' assignment_expression
4395 { $$ = $2; }
4396 ;
4397
4398%%
4399
4400// ----end of grammar----
4401
4402// Local Variables: //
4403// mode: c++ //
4404// tab-width: 4 //
4405// compile-command: "bison -Wcounterexamples parser.yy" //
4406// End: //
Note: See TracBrowser for help on using the repository browser.