source: src/Parser/parser.yy@ 5f53cc3

ADT ast-experimental enum pthread-emulation qualifiedEnum
Last change on this file since 5f53cc3 was d824715, checked in by Peter A. Buhr <pabuhr@…>, 4 years ago

support reverse array subscript, 3[a] => a[3], 3abc => "abc"[3]
  • Property mode set to 100644
File size: 148.5 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author : Peter A. Buhr
10// Created On : Sat Sep 1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Mon Mar 14 16:35:29 2022
13// Update Count : 5276
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS. While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks. Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// designation with '=' (use ':' instead)
29//
30// This incompatibility is discussed in detail before the "designation" grammar rule. Most of the syntactic extensions
31// from ANSI90 to ANSI11 C are marked with the comment "C99/C11".
32
33// This grammar also has two levels of extensions. The first extensions cover most of the GCC C extensions. All of the
34// syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall (CFA), which
35// fixes several of C's outstanding problems and extends C with many modern language concepts. All of the syntactic
36// extensions for CFA C are marked with the comment "CFA".
37
38%{
39#define YYDEBUG_LEXER_TEXT( yylval ) // lexer loads this up each time
40#define YYDEBUG 1 // get the pretty debugging code to compile
41#define YYERROR_VERBOSE // more information in syntax errors
42
43#undef __GNUC_MINOR__
44
45#include <cstdio>
46#include <stack>
47using namespace std;
48
49#include "SynTree/Declaration.h"
50#include "ParseNode.h"
51#include "TypedefTable.h"
52#include "TypeData.h"
53#include "SynTree/LinkageSpec.h"
54#include "Common/SemanticError.h" // error_str
55#include "Common/utility.h" // for maybeMoveBuild, maybeBuild, CodeLo...
56
57extern DeclarationNode * parseTree;
58extern LinkageSpec::Spec linkage;
59extern TypedefTable typedefTable;
60
61stack<LinkageSpec::Spec> linkageStack;
62
63bool appendStr( string & to, string & from ) {
64 // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
65 // "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
66 // the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
67 // easier to let the C compiler handle this case.
68 //
69 // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
70 // without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
71 // e.g., u"a" U"b" L"c" is disallowed.
72
73 if ( from[0] != '"' ) { // encoding ?
74 if ( to[0] != '"' ) { // encoding ?
75 if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
76 yyerror( "non-matching string encodings for string-literal concatenation" );
77 return false; // parse error, must call YYERROR in action
78 } else if ( from[1] == '8' ) {
79 from.erase( 0, 1 ); // remove 2nd encoding
80 } // if
81 } else {
82 if ( from[1] == '8' ) { // move encoding to start
83 to = "u8" + to;
84 from.erase( 0, 1 ); // remove 2nd encoding
85 } else {
86 to = from[0] + to;
87 } // if
88 } // if
89 from.erase( 0, 1 ); // remove 2nd encoding
90 } // if
91 to += " " + from; // concatenated into single string
92 return true;
93} // appendStr
94
95DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
96 // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
97 DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
98 for ( cur = dynamic_cast<DeclarationNode *>( cur->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode *>( cur->get_next() ) ) {
99 cl->cloneBaseType( cur );
100 } // for
101 declList->addType( cl );
102 return declList;
103} // distAttr
104
105void distExt( DeclarationNode * declaration ) {
106 // distribute EXTENSION across all declarations
107 for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
108 iter->set_extension( true );
109 } // for
110} // distExt
111
112void distInl( DeclarationNode * declaration ) {
113 // distribute EXTENSION across all declarations
114 for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
115 iter->set_inLine( true );
116 } // for
117} // distInl
118
119void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
120 // distribute qualifiers across all non-variable declarations in a distribution statemement
121 for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
122 // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
123 // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
124 // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
125 // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
126 DeclarationNode * clone = qualifiers->clone();
127 if ( qualifiers->type ) { // forall clause ? (handles SC)
128 if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
129 swap( clone->type->forall, iter->type->aggregate.params );
130 iter->addQualifiers( clone );
131 } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
132 // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
133 DeclarationNode newnode;
134 swap( newnode.type, iter->type->aggInst.aggregate );
135 swap( clone->type->forall, newnode.type->aggregate.params );
136 newnode.addQualifiers( clone );
137 swap( newnode.type, iter->type->aggInst.aggregate );
138 } else if ( iter->type->kind == TypeData::Function ) { // routines ?
139 swap( clone->type->forall, iter->type->forall );
140 iter->addQualifiers( clone );
141 } // if
142 } else { // just SC qualifiers
143 iter->addQualifiers( clone );
144 } // if
145 } // for
146 delete qualifiers;
147} // distQual
148
149// There is an ambiguity for inline generic-routine return-types and generic routines.
150// forall( otype T ) struct S { int i; } bar( T ) {}
151// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
152// forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
153// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
154// forall( otype T ) struct S { int T; };
155// forall( otype W ) bar( W ) {}
156
157void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
158 if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
159 funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
160 declSpec->type->aggregate.params = nullptr;
161 } // if
162} // rebindForall
163
164string * build_postfix_name( string * name ) {
165 *name = string("__postfix_func_") + *name;
166 return name;
167} // build_postfix_name
168
169DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
170 if ( ! fieldList ) { // field declarator ?
171 if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate || typeSpec->type->kind == TypeData::Enum) ) ) {
172 stringstream ss;
173 typeSpec->type->print( ss );
174 SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
175 return nullptr;
176 } // if
177 fieldList = DeclarationNode::newName( nullptr );
178 } // if
179 return distAttr( typeSpec, fieldList ); // mark all fields in list
180} // fieldDecl
181
182ForCtrl * forCtrl( ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
183 ConstantExpr * constant = dynamic_cast<ConstantExpr *>(type->expr.get());
184 if ( constant && (constant->get_constant()->get_value() == "0" || constant->get_constant()->get_value() == "1") ) {
185 type = new ExpressionNode( new CastExpr( maybeMoveBuild<Expression>(type), new BasicType( Type::Qualifiers(), BasicType::SignedInt ) ) );
186 } // if
187// type = new ExpressionNode( build_func( new ExpressionNode( build_varref( new string( "__for_control_index_constraints__" ) ) ), type ) );
188 return new ForCtrl(
189 distAttr( DeclarationNode::newTypeof( type, true ), DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) ) ),
190 // NULL comp/inc => leave blank
191 comp ? new ExpressionNode( build_binary_val( compop, new ExpressionNode( build_varref( new string( *index ) ) ), comp ) ) : 0,
192 inc ? new ExpressionNode( build_binary_val( compop == OperKinds::LThan || compop == OperKinds::LEThan ? // choose += or -= for upto/downto
193 OperKinds::PlusAssn : OperKinds::MinusAssn, new ExpressionNode( build_varref( new string( *index ) ) ), inc ) ) : 0 );
194} // forCtrl
195
196ForCtrl * forCtrl( ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
197 if ( NameExpr * identifier = dynamic_cast<NameExpr *>(index->expr.get()) ) {
198 return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
199 } else if ( CommaExpr * commaExpr = dynamic_cast<CommaExpr *>(index->expr.get()) ) {
200 if ( NameExpr * identifier = dynamic_cast<NameExpr *>(commaExpr->arg1 ) ) {
201 return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
202 } else {
203 SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed." ); return nullptr;
204 } // if
205 } else {
206 SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed." ); return nullptr;
207 } // if
208} // forCtrl
209
210bool forall = false; // aggregate have one or more forall qualifiers ?
211
212// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
213#define YYLLOC_DEFAULT(Cur, Rhs, N) \
214if ( N ) { \
215 (Cur).first_line = YYRHSLOC( Rhs, 1 ).first_line; \
216 (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column; \
217 (Cur).last_line = YYRHSLOC( Rhs, N ).last_line; \
218 (Cur).last_column = YYRHSLOC( Rhs, N ).last_column; \
219 (Cur).filename = YYRHSLOC( Rhs, 1 ).filename; \
220} else { \
221 (Cur).first_line = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line; \
222 (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column; \
223 (Cur).filename = YYRHSLOC( Rhs, 0 ).filename; \
224}
225%}
226
227%define parse.error verbose
228
229// Types declaration for productions
230%union {
231 Token tok;
232 ParseNode * pn;
233 ExpressionNode * en;
234 DeclarationNode * decl;
235 AggregateDecl::Aggregate aggKey;
236 TypeDecl::Kind tclass;
237 StatementNode * sn;
238 WaitForStmt * wfs;
239 Expression * constant;
240 CondCtl * ifctl;
241 ForCtrl * fctl;
242 enum OperKinds compop;
243 LabelNode * label;
244 InitializerNode * in;
245 OperKinds op;
246 std::string * str;
247 bool flag;
248 CatchStmt::Kind catch_kind;
249 GenericExpr * genexpr;
250}
251
252//************************* TERMINAL TOKENS ********************************
253
254// keywords
255%token TYPEDEF
256%token EXTERN STATIC AUTO REGISTER
257%token THREADLOCAL // C11
258%token INLINE FORTRAN // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
259%token NORETURN // C11
260%token CONST VOLATILE
261%token RESTRICT // C99
262%token ATOMIC // C11
263%token FORALL MUTEX VIRTUAL VTABLE COERCE // CFA
264%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
265%token BOOL COMPLEX IMAGINARY // C99
266%token INT128 UINT128 uuFLOAT80 uuFLOAT128 // GCC
267%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
268%token DECIMAL32 DECIMAL64 DECIMAL128 // GCC
269%token ZERO_T ONE_T // CFA
270%token SIZEOF TYPEOF VALIST AUTO_TYPE // GCC
271%token OFFSETOF BASETYPEOF TYPEID // CFA
272%token ENUM STRUCT UNION
273%token EXCEPTION // CFA
274%token GENERATOR COROUTINE MONITOR THREAD // CFA
275%token OTYPE FTYPE DTYPE TTYPE TRAIT // CFA
276// %token RESUME // CFA
277%token LABEL // GCC
278%token SUSPEND // CFA
279%token ATTRIBUTE EXTENSION // GCC
280%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
281%token CHOOSE FALLTHRU FALLTHROUGH WITH WHEN WAITFOR // CFA
282%token DISABLE ENABLE TRY THROW THROWRESUME AT // CFA
283%token ASM // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
284%token ALIGNAS ALIGNOF GENERIC STATICASSERT // C11
285
286// names and constants: lexer differentiates between identifier and typedef names
287%token<tok> IDENTIFIER QUOTED_IDENTIFIER TYPEDIMname TYPEDEFname TYPEGENname
288%token<tok> TIMEOUT WOR CATCH RECOVER CATCHRESUME FIXUP FINALLY // CFA
289%token<tok> INTEGERconstant CHARACTERconstant STRINGliteral
290%token<tok> DIRECTIVE
291// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
292// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
293// converted into the tuple index (.)(1). e.g., 3.x
294%token<tok> FLOATING_DECIMALconstant FLOATING_FRACTIONconstant FLOATINGconstant
295
296// multi-character operators
297%token ARROW // ->
298%token ICR DECR // ++ --
299%token LS RS // << >>
300%token LE GE EQ NE // <= >= == !=
301%token ANDAND OROR // && ||
302%token ELLIPSIS // ...
303
304%token EXPassign MULTassign DIVassign MODassign // \= *= /= %=
305%token PLUSassign MINUSassign // += -=
306%token LSassign RSassign // <<= >>=
307%token ANDassign ERassign ORassign // &= ^= |=
308
309%token ErangeUpEq ErangeDown ErangeDownEq // ~= -~ -~=
310%token ATassign // @=
311
312%type<tok> identifier identifier_at identifier_or_type_name attr_name
313%type<tok> quasi_keyword
314%type<constant> string_literal
315%type<str> string_literal_list
316
317// expressions
318%type<en> constant
319%type<en> tuple tuple_expression_list
320%type<op> ptrref_operator unary_operator assignment_operator simple_assignment_operator compound_assignment_operator
321%type<en> primary_expression postfix_expression unary_expression
322%type<en> cast_expression_list cast_expression exponential_expression multiplicative_expression additive_expression
323%type<en> shift_expression relational_expression equality_expression
324%type<en> AND_expression exclusive_OR_expression inclusive_OR_expression
325%type<en> logical_AND_expression logical_OR_expression
326%type<en> conditional_expression constant_expression assignment_expression assignment_expression_opt
327%type<en> comma_expression comma_expression_opt
328%type<en> argument_expression_list_opt argument_expression_list argument_expression default_initializer_opt
329%type<ifctl> conditional_declaration
330%type<fctl> for_control_expression for_control_expression_list
331%type<compop> inclexcl
332%type<en> subrange
333%type<decl> asm_name_opt
334%type<en> asm_operands_opt asm_operands_list asm_operand
335%type<label> label_list
336%type<en> asm_clobbers_list_opt
337%type<flag> asm_volatile_opt
338%type<en> handler_predicate_opt
339%type<genexpr> generic_association generic_assoc_list
340
341// statements
342%type<sn> statement labeled_statement compound_statement
343%type<sn> statement_decl statement_decl_list statement_list_nodecl
344%type<sn> selection_statement if_statement
345%type<sn> switch_clause_list_opt switch_clause_list
346%type<en> case_value
347%type<sn> case_clause case_value_list case_label case_label_list
348%type<sn> iteration_statement jump_statement
349%type<sn> expression_statement asm_statement
350%type<sn> with_statement
351%type<en> with_clause_opt
352%type<sn> exception_statement handler_clause finally_clause
353%type<catch_kind> handler_key
354%type<sn> mutex_statement
355%type<en> when_clause when_clause_opt waitfor timeout
356%type<sn> waitfor_statement
357%type<wfs> waitfor_clause
358
359// declarations
360%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
361%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
362%type<decl> abstract_parameter_declaration
363
364%type<aggKey> aggregate_key aggregate_data aggregate_control
365%type<decl> aggregate_type aggregate_type_nobody
366
367%type<decl> assertion assertion_list assertion_list_opt
368
369%type<en> bit_subrange_size_opt bit_subrange_size
370
371%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
372%type<decl> vtable vtable_opt default_opt
373
374%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
375
376%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
377%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
378
379%type<decl> elaborated_type elaborated_type_nobody
380
381%type<decl> enumerator_list enum_type enum_type_nobody
382%type<en> enumerator_value_opt
383
384%type<decl> external_definition external_definition_list external_definition_list_opt
385
386%type<decl> exception_declaration
387
388%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
389%type<en> field field_name_list field_name fraction_constants_opt
390
391%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
392
393%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
394%type<decl> identifier_list
395
396%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
397%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
398%type<decl> cfa_abstract_ptr cfa_abstract_tuple
399
400%type<decl> cfa_array_parameter_1st_dimension
401
402%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
403%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
404
405%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
406%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
407
408%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
409
410%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
411
412%type<decl> c_declaration static_assert
413%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
414%type<decl> KR_parameter_list KR_parameter_list_opt
415
416%type<decl> parameter_declaration parameter_list parameter_type_list_opt
417
418%type<decl> paren_identifier paren_type
419
420%type<decl> storage_class storage_class_list
421
422%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
423
424%type<tclass> type_class new_type_class
425%type<decl> type_declarator type_declarator_name type_declaring_list
426
427%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
428%type<decl> typedef_name typedef_declaration typedef_expression
429
430%type<decl> variable_type_redeclarator type_ptr type_array type_function
431
432%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
433
434%type<decl> type type_no_function
435%type<decl> type_parameter type_parameter_list type_initializer_opt
436
437%type<en> type_parameters_opt type_list
438
439%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
440%type<decl> type_specifier type_specifier_nobody
441
442%type<decl> variable_declarator variable_ptr variable_array variable_function
443%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
444
445%type<decl> attribute_list_opt attribute_list attribute attribute_name_list attribute_name
446
447// initializers
448%type<in> initializer initializer_list_opt initializer_opt
449
450// designators
451%type<en> designator designator_list designation
452
453
454// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
455// .---------. matches IF '(' comma_expression ')' statement . (reduce)
456// if ( C ) S1 else S2
457// `-----------------' matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
458// Similar issues exit with the waitfor statement.
459
460// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
461// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
462%precedence THEN // rule precedence for IF/WAITFOR statement
463%precedence WOR // token precedence for start of WOR in WAITFOR statement
464%precedence TIMEOUT // token precedence for start of TIMEOUT in WAITFOR statement
465%precedence CATCH // token precedence for start of TIMEOUT in WAITFOR statement
466%precedence RECOVER // token precedence for start of TIMEOUT in WAITFOR statement
467%precedence CATCHRESUME // token precedence for start of TIMEOUT in WAITFOR statement
468%precedence FIXUP // token precedence for start of TIMEOUT in WAITFOR statement
469%precedence FINALLY // token precedence for start of TIMEOUT in WAITFOR statement
470%precedence ELSE // token precedence for start of else clause in IF/WAITFOR statement
471
472
473// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
474// forall( otype T ) struct Foo { T v; };
475// .-----. matches pointer to function returning a generic (which is impossible without a type)
476// Foo ( *fp )( int );
477// `---' matches start of TYPEGENname '('
478// must be:
479// Foo( int ) ( *fp )( int );
480// The same problem occurs here:
481// forall( otype T ) struct Foo { T v; } ( *fp )( int );
482// must be:
483// forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
484
485// Order of these lines matters (low-to-high precedence).
486%precedence TYPEGENname
487%precedence '}'
488%precedence '('
489
490// %precedence RESUME
491// %precedence '{'
492// %precedence ')'
493
494%locations // support location tracking for error messages
495
496%start translation_unit // parse-tree root
497
498%%
499//************************* Namespace Management ********************************
500
501// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
502// which are lexically identical.
503//
504// typedef int foo; // identifier foo must now be scanned as TYPEDEFname
505// foo f; // to allow it to appear in this context
506//
507// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
508// between syntactic and semantic constructs. Cforall compounds this problem by introducing type names local to the
509// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
510// generators" -- parameterized types. This latter type name creates a third class of identifiers, "TYPEGENname", which
511// must be distinguished by the lexical scanner.
512//
513// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
514// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
515// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
516// each context that introduces a name scope, a new level is created in the type table and that level is popped on
517// exiting the scope. Since type names can be local to a particular declaration, each declaration is itself a scope.
518// This requires distinguishing between type names that are local to the current declaration scope and those that
519// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
520//
521// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
522// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
523// around the list separator.
524//
525// int f( forall(T) T (*f1) T , forall( S ) S (*f2)( S ) );
526// push pop push pop
527
528push:
529 { typedefTable.enterScope(); }
530 ;
531
532pop:
533 { typedefTable.leaveScope(); }
534 ;
535
536//************************* CONSTANTS ********************************
537
538constant:
539 // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
540 INTEGERconstant { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
541 | FLOATING_DECIMALconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
542 | FLOATING_FRACTIONconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
543 | FLOATINGconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
544 | CHARACTERconstant { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
545 ;
546
547quasi_keyword: // CFA
548 TIMEOUT
549 | WOR
550 | CATCH
551 | RECOVER
552 | CATCHRESUME
553 | FIXUP
554 | FINALLY
555 ;
556
557identifier:
558 IDENTIFIER
559 | quasi_keyword
560 ;
561
562identifier_at:
563 identifier
564 | '@' // CFA
565 { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
566 ;
567
568string_literal:
569 string_literal_list { $$ = build_constantStr( *$1 ); }
570 ;
571
572string_literal_list: // juxtaposed strings are concatenated
573 STRINGliteral { $$ = $1; } // conversion from tok to str
574 | string_literal_list STRINGliteral
575 {
576 if ( ! appendStr( *$1, *$2 ) ) YYERROR; // append 2nd juxtaposed string to 1st
577 delete $2; // allocated by lexer
578 $$ = $1; // conversion from tok to str
579 }
580 ;
581
582//************************* EXPRESSIONS ********************************
583
584primary_expression:
585 IDENTIFIER // typedef name cannot be used as a variable name
586 { $$ = new ExpressionNode( build_varref( $1 ) ); }
587 | quasi_keyword
588 { $$ = new ExpressionNode( build_varref( $1 ) ); }
589 | TYPEDIMname // CFA, generic length argument
590 // { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( DeclarationNode::newFromTypedef( $1 ) ) ) ); }
591 // { $$ = new ExpressionNode( build_varref( $1 ) ); }
592 { $$ = new ExpressionNode( build_dimensionref( $1 ) ); }
593 | tuple
594 | '(' comma_expression ')'
595 { $$ = $2; }
596 | '(' compound_statement ')' // GCC, lambda expression
597 { $$ = new ExpressionNode( new StmtExpr( dynamic_cast<CompoundStmt *>(maybeMoveBuild<Statement>($2) ) ) ); }
598 | type_name '.' identifier // CFA, nested type
599 { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
600 | type_name '.' '[' field_name_list ']' // CFA, nested type / tuple field selector
601 { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
602 | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
603 {
604 // add the missing control expression to the GenericExpr and return it
605 $5->control = maybeMoveBuild<Expression>( $3 );
606 $$ = new ExpressionNode( $5 );
607 }
608 // | RESUME '(' comma_expression ')'
609 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
610 // | RESUME '(' comma_expression ')' compound_statement
611 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
612 | IDENTIFIER IDENTIFIER // syntax error
613 {
614 SemanticError( yylloc, ::toString( "Adjacent identifiers are not meaningful in an expression. "
615 "Possible problem is identifier \"", *$1.str,
616 "\" is a misspelled typename or an incorrectly specified type name, "
617 "e.g., missing generic parameter or missing struct/union/enum before typename." ) );
618 $$ = nullptr;
619 }
620 | IDENTIFIER direct_type // syntax error
621 {
622 SemanticError( yylloc, ::toString( "Identifier \"", *$1.str, "\" cannot appear before a type. "
623 "Possible problem is misspelled storage or CV qualifier." ) );
624 $$ = nullptr;
625 }
626 ;
627
628generic_assoc_list: // C11
629 generic_association
630 | generic_assoc_list ',' generic_association
631 {
632 // steal the association node from the singleton and delete the wrapper
633 $1->associations.splice($1->associations.end(), $3->associations);
634 delete $3;
635 $$ = $1;
636 }
637 ;
638
639generic_association: // C11
640 type_no_function ':' assignment_expression
641 {
642 // create a GenericExpr wrapper with one association pair
643 $$ = new GenericExpr( nullptr, { { maybeMoveBuildType($1), maybeMoveBuild<Expression>( $3 ) } } );
644 }
645 | DEFAULT ':' assignment_expression
646 { $$ = new GenericExpr( nullptr, { { maybeMoveBuild<Expression>( $3 ) } } ); }
647 ;
648
649postfix_expression:
650 primary_expression
651 | postfix_expression '[' assignment_expression ',' tuple_expression_list ']'
652 // Historic, transitional: Disallow commas in subscripts.
653 // Switching to this behaviour may help check if a C compatibilty case uses comma-exprs in subscripts.
654 // Current: Commas in subscripts make tuples.
655 { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, new ExpressionNode( build_tuple( (ExpressionNode *)($3->set_last( $5 ) ) )) ) ); }
656 | postfix_expression '[' assignment_expression ']'
657 // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
658 // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
659 // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
660 // equivalent to the old x[i,j].
661 { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
662 | constant '[' assignment_expression ']' // 3[a], 'a'[a], 3.5[a]
663 { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
664 | string_literal '[' assignment_expression ']' // "abc"[3], 3["abc"]
665 { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, new ExpressionNode( $1 ), $3 ) ); }
666 | postfix_expression '{' argument_expression_list_opt '}' // CFA, constructor call
667 {
668 Token fn;
669 fn.str = new std::string( "?{}" ); // location undefined - use location of '{'?
670 $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
671 }
672 | postfix_expression '(' argument_expression_list_opt ')'
673 { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
674 | postfix_expression '`' identifier // CFA, postfix call
675 { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
676 | constant '`' identifier // CFA, postfix call
677 { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
678 | string_literal '`' identifier // CFA, postfix call
679 { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), new ExpressionNode( $1 ) ) ); }
680 | postfix_expression '.' identifier
681 { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
682 | postfix_expression '.' INTEGERconstant // CFA, tuple index
683 { $$ = new ExpressionNode( build_fieldSel( $1, build_constantInteger( *$3 ) ) ); }
684 | postfix_expression FLOATING_FRACTIONconstant // CFA, tuple index
685 { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
686 | postfix_expression '.' '[' field_name_list ']' // CFA, tuple field selector
687 { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
688 | postfix_expression '.' aggregate_control
689 { $$ = new ExpressionNode( build_keyword_cast( $3, $1 ) ); }
690 | postfix_expression ARROW identifier
691 { $$ = new ExpressionNode( build_pfieldSel( $1, build_varref( $3 ) ) ); }
692 | postfix_expression ARROW INTEGERconstant // CFA, tuple index
693 { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
694 | postfix_expression ARROW '[' field_name_list ']' // CFA, tuple field selector
695 { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
696 | postfix_expression ICR
697 { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
698 | postfix_expression DECR
699 { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
700 | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
701 { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
702 | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
703 { $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
704 | '^' primary_expression '{' argument_expression_list_opt '}' // CFA, destructor call
705 {
706 Token fn;
707 fn.str = new string( "^?{}" ); // location undefined
708 $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
709 }
710 ;
711
712argument_expression_list_opt:
713 // empty
714 { $$ = nullptr; }
715 | argument_expression_list
716 ;
717
718argument_expression_list:
719 argument_expression
720 | argument_expression_list_opt ',' argument_expression
721 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
722 ;
723
724argument_expression:
725 '@' // CFA, default parameter
726 { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
727 // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
728 | assignment_expression
729 ;
730
731field_name_list: // CFA, tuple field selector
732 field
733 | field_name_list ',' field { $$ = (ExpressionNode *)($1->set_last( $3 )); }
734 ;
735
736field: // CFA, tuple field selector
737 field_name
738 | FLOATING_DECIMALconstant field
739 { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
740 | FLOATING_DECIMALconstant '[' field_name_list ']'
741 { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $3 ) ) ); }
742 | field_name '.' field
743 { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
744 | field_name '.' '[' field_name_list ']'
745 { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
746 | field_name ARROW field
747 { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
748 | field_name ARROW '[' field_name_list ']'
749 { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
750 ;
751
752field_name:
753 INTEGERconstant fraction_constants_opt
754 { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
755 | FLOATINGconstant fraction_constants_opt
756 { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
757 | identifier_at fraction_constants_opt // CFA, allow anonymous fields
758 {
759 $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
760 }
761 ;
762
763fraction_constants_opt:
764 // empty
765 { $$ = nullptr; }
766 | fraction_constants_opt FLOATING_FRACTIONconstant
767 {
768 Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
769 $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1, constant ) ) : new ExpressionNode( constant );
770 }
771 ;
772
773unary_expression:
774 postfix_expression
775 // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
776 // semantics checks, e.g., ++3, 3--, *3, &&3
777 | constant
778 | string_literal
779 { $$ = new ExpressionNode( $1 ); }
780 | EXTENSION cast_expression // GCC
781 { $$ = $2->set_extension( true ); }
782 // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
783 // { * X; } // dereference X
784 // { * int X; } // CFA declaration of pointer to int
785 | ptrref_operator cast_expression // CFA
786 {
787 switch ( $1 ) {
788 case OperKinds::AddressOf:
789 $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild<Expression>( $2 ) ) );
790 break;
791 case OperKinds::PointTo:
792 $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
793 break;
794 case OperKinds::And:
795 $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild<Expression>( $2 ) ) ) );
796 break;
797 default:
798 assert( false );
799 }
800 }
801 | unary_operator cast_expression
802 { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
803 | ICR unary_expression
804 { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
805 | DECR unary_expression
806 { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
807 | SIZEOF unary_expression
808 { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild<Expression>( $2 ) ) ); }
809 | SIZEOF '(' type_no_function ')'
810 { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
811 | ALIGNOF unary_expression // GCC, variable alignment
812 { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild<Expression>( $2 ) ) ); }
813 | ALIGNOF '(' type_no_function ')' // GCC, type alignment
814 { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
815 | OFFSETOF '(' type_no_function ',' identifier ')'
816 { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
817 | TYPEID '(' type_no_function ')'
818 {
819 SemanticError( yylloc, "typeid name is currently unimplemented." ); $$ = nullptr;
820 // $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) );
821 }
822 ;
823
824ptrref_operator:
825 '*' { $$ = OperKinds::PointTo; }
826 | '&' { $$ = OperKinds::AddressOf; }
827 // GCC, address of label must be handled by semantic check for ref,ref,label
828 | ANDAND { $$ = OperKinds::And; }
829 ;
830
831unary_operator:
832 '+' { $$ = OperKinds::UnPlus; }
833 | '-' { $$ = OperKinds::UnMinus; }
834 | '!' { $$ = OperKinds::Neg; }
835 | '~' { $$ = OperKinds::BitNeg; }
836 ;
837
838cast_expression:
839 unary_expression
840 | '(' type_no_function ')' cast_expression
841 { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
842 | '(' aggregate_control '&' ')' cast_expression // CFA
843 { $$ = new ExpressionNode( build_keyword_cast( $2, $5 ) ); }
844 | '(' aggregate_control '*' ')' cast_expression // CFA
845 { $$ = new ExpressionNode( build_keyword_cast( $2, $5 ) ); }
846 | '(' VIRTUAL ')' cast_expression // CFA
847 { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild<Expression>( $4 ), maybeMoveBuildType( nullptr ) ) ); }
848 | '(' VIRTUAL type_no_function ')' cast_expression // CFA
849 { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild<Expression>( $5 ), maybeMoveBuildType( $3 ) ) ); }
850 | '(' RETURN type_no_function ')' cast_expression // CFA
851 { SemanticError( yylloc, "Return cast is currently unimplemented." ); $$ = nullptr; }
852 | '(' COERCE type_no_function ')' cast_expression // CFA
853 { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
854 | '(' qualifier_cast_list ')' cast_expression // CFA
855 { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
856// | '(' type_no_function ')' tuple
857// { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
858 ;
859
860qualifier_cast_list:
861 cast_modifier type_qualifier_name
862 | cast_modifier MUTEX
863 | qualifier_cast_list cast_modifier type_qualifier_name
864 | qualifier_cast_list cast_modifier MUTEX
865 ;
866
867cast_modifier:
868 '-'
869 | '+'
870 ;
871
872exponential_expression:
873 cast_expression
874 | exponential_expression '\\' cast_expression
875 { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
876 ;
877
878multiplicative_expression:
879 exponential_expression
880 | multiplicative_expression '*' exponential_expression
881 { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
882 | multiplicative_expression '/' exponential_expression
883 { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
884 | multiplicative_expression '%' exponential_expression
885 { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
886 ;
887
888additive_expression:
889 multiplicative_expression
890 | additive_expression '+' multiplicative_expression
891 { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
892 | additive_expression '-' multiplicative_expression
893 { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
894 ;
895
896shift_expression:
897 additive_expression
898 | shift_expression LS additive_expression
899 { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
900 | shift_expression RS additive_expression
901 { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
902 ;
903
904relational_expression:
905 shift_expression
906 | relational_expression '<' shift_expression
907 { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
908 | relational_expression '>' shift_expression
909 { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
910 | relational_expression LE shift_expression
911 { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
912 | relational_expression GE shift_expression
913 { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
914 ;
915
916equality_expression:
917 relational_expression
918 | equality_expression EQ relational_expression
919 { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
920 | equality_expression NE relational_expression
921 { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
922 ;
923
924AND_expression:
925 equality_expression
926 | AND_expression '&' equality_expression
927 { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
928 ;
929
930exclusive_OR_expression:
931 AND_expression
932 | exclusive_OR_expression '^' AND_expression
933 { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
934 ;
935
936inclusive_OR_expression:
937 exclusive_OR_expression
938 | inclusive_OR_expression '|' exclusive_OR_expression
939 { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
940 ;
941
942logical_AND_expression:
943 inclusive_OR_expression
944 | logical_AND_expression ANDAND inclusive_OR_expression
945 { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
946 ;
947
948logical_OR_expression:
949 logical_AND_expression
950 | logical_OR_expression OROR logical_AND_expression
951 { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
952 ;
953
954conditional_expression:
955 logical_OR_expression
956 | logical_OR_expression '?' comma_expression ':' conditional_expression
957 { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
958 // FIX ME: computes $1 twice
959 | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
960 { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
961 ;
962
963constant_expression:
964 conditional_expression
965 ;
966
967assignment_expression:
968 // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
969 conditional_expression
970 | unary_expression assignment_operator assignment_expression
971 {
972// if ( $2 == OperKinds::AtAssn ) {
973// SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
974// } else {
975 $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) );
976// } // if
977 }
978 | unary_expression '=' '{' initializer_list_opt comma_opt '}'
979 { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
980 ;
981
982assignment_expression_opt:
983 // empty
984 { $$ = nullptr; }
985 | assignment_expression
986 ;
987
988assignment_operator:
989 simple_assignment_operator
990 | compound_assignment_operator
991 ;
992
993simple_assignment_operator:
994 '=' { $$ = OperKinds::Assign; }
995 | ATassign { $$ = OperKinds::AtAssn; } // CFA
996 ;
997
998compound_assignment_operator:
999 EXPassign { $$ = OperKinds::ExpAssn; }
1000 | MULTassign { $$ = OperKinds::MulAssn; }
1001 | DIVassign { $$ = OperKinds::DivAssn; }
1002 | MODassign { $$ = OperKinds::ModAssn; }
1003 | PLUSassign { $$ = OperKinds::PlusAssn; }
1004 | MINUSassign { $$ = OperKinds::MinusAssn; }
1005 | LSassign { $$ = OperKinds::LSAssn; }
1006 | RSassign { $$ = OperKinds::RSAssn; }
1007 | ANDassign { $$ = OperKinds::AndAssn; }
1008 | ERassign { $$ = OperKinds::ERAssn; }
1009 | ORassign { $$ = OperKinds::OrAssn; }
1010 ;
1011
1012tuple: // CFA, tuple
1013 // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
1014 // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
1015// '[' ']'
1016// { $$ = new ExpressionNode( build_tuple() ); }
1017// | '[' push assignment_expression pop ']'
1018// { $$ = new ExpressionNode( build_tuple( $3 ) ); }
1019 '[' ',' tuple_expression_list ']'
1020 { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
1021 | '[' push assignment_expression pop ',' tuple_expression_list ']'
1022 { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)($3->set_last( $6 ) ) )); }
1023 ;
1024
1025tuple_expression_list:
1026 assignment_expression
1027 | '@' // CFA
1028 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1029 | tuple_expression_list ',' assignment_expression
1030 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1031 | tuple_expression_list ',' '@'
1032 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1033 ;
1034
1035comma_expression:
1036 assignment_expression
1037 | comma_expression ',' assignment_expression
1038 { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild<Expression>( $1 ), maybeMoveBuild<Expression>( $3 ) ) ); }
1039 ;
1040
1041comma_expression_opt:
1042 // empty
1043 { $$ = nullptr; }
1044 | comma_expression
1045 ;
1046
1047//*************************** STATEMENTS *******************************
1048
1049statement:
1050 labeled_statement
1051 | compound_statement
1052 | expression_statement
1053 | selection_statement
1054 | iteration_statement
1055 | jump_statement
1056 | with_statement
1057 | mutex_statement
1058 | waitfor_statement
1059 | exception_statement
1060 | enable_disable_statement
1061 { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1062 | asm_statement
1063 | DIRECTIVE
1064 { $$ = new StatementNode( build_directive( $1 ) ); }
1065 ;
1066
1067labeled_statement:
1068 // labels cannot be identifiers 0 or 1
1069 identifier_or_type_name ':' attribute_list_opt statement
1070 { $$ = $4->add_label( $1, $3 ); }
1071 | identifier_or_type_name ':' attribute_list_opt error // syntax error
1072 {
1073 SemanticError( yylloc, ::toString( "Label \"", *$1.str, "\" must be associated with a statement, "
1074 "where a declaration, case, or default is not a statement. "
1075 "Move the label or terminate with a semi-colon." ) );
1076 $$ = nullptr;
1077 }
1078 ;
1079
1080compound_statement:
1081 '{' '}'
1082 { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
1083 | '{' push
1084 local_label_declaration_opt // GCC, local labels appear at start of block
1085 statement_decl_list // C99, intermix declarations and statements
1086 pop '}'
1087 { $$ = new StatementNode( build_compound( $4 ) ); }
1088 ;
1089
1090statement_decl_list: // C99
1091 statement_decl
1092 | statement_decl_list statement_decl
1093 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1094 ;
1095
1096statement_decl:
1097 declaration // CFA, new & old style declarations
1098 { $$ = new StatementNode( $1 ); }
1099 | EXTENSION declaration // GCC
1100 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1101 | function_definition
1102 { $$ = new StatementNode( $1 ); }
1103 | EXTENSION function_definition // GCC
1104 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1105 | statement
1106 ;
1107
1108statement_list_nodecl:
1109 statement
1110 | statement_list_nodecl statement
1111 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1112 | statement_list_nodecl error // syntax error
1113 { SemanticError( yylloc, "Declarations only allowed at the start of the switch body, i.e., after the '{'." ); $$ = nullptr; }
1114 ;
1115
1116expression_statement:
1117 comma_expression_opt ';'
1118 { $$ = new StatementNode( build_expr( $1 ) ); }
1119 | MUTEX '(' ')' comma_expression ';'
1120 { $$ = new StatementNode( build_mutex( nullptr, new StatementNode( build_expr( $4 ) ) ) ); }
1121 ;
1122
1123selection_statement:
1124 // pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1125 // the inherent S/R conflict with THEN/ELSE.
1126 push if_statement pop
1127 { $$ = $2; }
1128 | SWITCH '(' comma_expression ')' case_clause
1129 { $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
1130 | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1131 {
1132 StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
1133 // The semantics of the declaration list is changed to include associated initialization, which is performed
1134 // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1135 // statement around the switch. Statements after the initial declaration list can never be executed, and
1136 // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1137 // statement.
1138 $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1139 }
1140 | SWITCH '(' comma_expression ')' '{' error '}' // CFA, syntax error
1141 { SemanticError( yylloc, "Only declarations can appear before the list of case clauses." ); $$ = nullptr; }
1142 | CHOOSE '(' comma_expression ')' case_clause // CFA
1143 { $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
1144 | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1145 {
1146 StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
1147 $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1148 }
1149 | CHOOSE '(' comma_expression ')' '{' error '}' // CFA, syntax error
1150 { SemanticError( yylloc, "Only declarations can appear before the list of case clauses." ); $$ = nullptr; }
1151 ;
1152
1153if_statement:
1154 IF '(' conditional_declaration ')' statement %prec THEN
1155 // explicitly deal with the shift/reduce conflict on if/else
1156 { $$ = new StatementNode( build_if( $3, maybe_build_compound( $5 ), nullptr ) ); }
1157 | IF '(' conditional_declaration ')' statement ELSE statement
1158 { $$ = new StatementNode( build_if( $3, maybe_build_compound( $5 ), maybe_build_compound( $7 ) ) ); }
1159 ;
1160
1161conditional_declaration:
1162 comma_expression
1163 { $$ = new CondCtl( nullptr, $1 ); }
1164 | c_declaration // no semi-colon
1165 { $$ = new CondCtl( $1, nullptr ); }
1166 | cfa_declaration // no semi-colon
1167 { $$ = new CondCtl( $1, nullptr ); }
1168 | declaration comma_expression // semi-colon separated
1169 { $$ = new CondCtl( $1, $2 ); }
1170 ;
1171
1172// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1173// clause allows a list of values and subranges.
1174
1175case_value: // CFA
1176 constant_expression { $$ = $1; }
1177 | constant_expression ELLIPSIS constant_expression // GCC, subrange
1178 { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild<Expression>( $1 ), maybeMoveBuild<Expression>( $3 ) ) ); }
1179 | subrange // CFA, subrange
1180 ;
1181
1182case_value_list: // CFA
1183 case_value { $$ = new StatementNode( build_case( $1 ) ); }
1184 // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1185 | case_value_list ',' case_value { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
1186 ;
1187
1188case_label: // CFA
1189 CASE error // syntax error
1190 { SemanticError( yylloc, "Missing case list after case." ); $$ = nullptr; }
1191 | CASE case_value_list ':' { $$ = $2; }
1192 | CASE case_value_list error // syntax error
1193 { SemanticError( yylloc, "Missing colon after case list." ); $$ = nullptr; }
1194 | DEFAULT ':' { $$ = new StatementNode( build_default() ); }
1195 // A semantic check is required to ensure only one default clause per switch/choose statement.
1196 | DEFAULT error // syntax error
1197 { SemanticError( yylloc, "Missing colon after default." ); $$ = nullptr; }
1198 ;
1199
1200case_label_list: // CFA
1201 case_label
1202 | case_label_list case_label { $$ = (StatementNode *)( $1->set_last( $2 )); }
1203 ;
1204
1205case_clause: // CFA
1206 case_label_list statement { $$ = $1->append_last_case( maybe_build_compound( $2 ) ); }
1207 ;
1208
1209switch_clause_list_opt: // CFA
1210 // empty
1211 { $$ = nullptr; }
1212 | switch_clause_list
1213 ;
1214
1215switch_clause_list: // CFA
1216 case_label_list statement_list_nodecl
1217 { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1218 | switch_clause_list case_label_list statement_list_nodecl
1219 { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1220 ;
1221
1222iteration_statement:
1223 WHILE '(' ')' statement // CFA => while ( 1 )
1224 { $$ = new StatementNode( build_while( new CondCtl( nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ), maybe_build_compound( $4 ) ) ); }
1225 | WHILE '(' conditional_declaration ')' statement %prec THEN
1226 { $$ = new StatementNode( build_while( $3, maybe_build_compound( $5 ) ) ); }
1227 | WHILE '(' conditional_declaration ')' statement ELSE statement // CFA
1228 { $$ = new StatementNode( build_while( $3, maybe_build_compound( $5 ), $7 ) ); }
1229 | DO statement WHILE '(' ')' ';' // CFA => do while( 1 )
1230 { $$ = new StatementNode( build_do_while( new ExpressionNode( build_constantInteger( *new string( "1" ) ) ), maybe_build_compound( $2 ) ) ); }
1231 | DO statement WHILE '(' comma_expression ')' ';' %prec THEN
1232 { $$ = new StatementNode( build_do_while( $5, maybe_build_compound( $2 ) ) ); }
1233 | DO statement WHILE '(' comma_expression ')' ELSE statement // CFA
1234 { $$ = new StatementNode( build_do_while( $5, maybe_build_compound( $2 ), $8 ) ); }
1235 | FOR '(' ')' statement // CFA => for ( ;; )
1236 { $$ = new StatementNode( build_for( new ForCtrl( (ExpressionNode * )nullptr, (ExpressionNode * )nullptr, (ExpressionNode * )nullptr ), maybe_build_compound( $4 ) ) ); }
1237 | FOR '(' for_control_expression_list ')' statement %prec THEN
1238 { $$ = new StatementNode( build_for( $3, maybe_build_compound( $5 ) ) ); }
1239 | FOR '(' for_control_expression_list ')' statement ELSE statement // CFA
1240 { $$ = new StatementNode( build_for( $3, maybe_build_compound( $5 ), $7 ) ); }
1241 ;
1242
1243for_control_expression_list:
1244 for_control_expression
1245 | for_control_expression_list ':' for_control_expression
1246 // ForCtrl + ForCtrl:
1247 // init + init => multiple declaration statements that are hoisted
1248 // condition + condition => (expression) && (expression)
1249 // change + change => (expression), (expression)
1250 {
1251 $1->init->set_last( $3->init );
1252 if ( $1->condition ) {
1253 if ( $3->condition ) {
1254 $1->condition->expr.reset( new LogicalExpr( $1->condition->expr.release(), $3->condition->expr.release(), true ) );
1255 } // if
1256 } else $1->condition = $3->condition;
1257 if ( $1->change ) {
1258 if ( $3->change ) {
1259 $1->change->expr.reset( new CommaExpr( $1->change->expr.release(), $3->change->expr.release() ) );
1260 } // if
1261 } else $1->change = $3->change;
1262 $$ = $1;
1263 }
1264 ;
1265
1266for_control_expression:
1267 ';' comma_expression_opt ';' comma_expression_opt
1268 { $$ = new ForCtrl( (ExpressionNode * )nullptr, $2, $4 ); }
1269 | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1270 { $$ = new ForCtrl( $1, $3, $5 ); }
1271 | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1272 { $$ = new ForCtrl( $1, $2, $4 ); }
1273
1274 | comma_expression // CFA
1275 { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1276 OperKinds::LThan, $1->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1277 | '=' comma_expression // CFA
1278 { $$ = forCtrl( $2, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1279 OperKinds::LEThan, $2->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1280 | comma_expression inclexcl comma_expression // CFA
1281 { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1282 | comma_expression inclexcl comma_expression '~' comma_expression // CFA
1283 { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, $5 ); }
1284 | comma_expression ';' // CFA
1285 { $$ = forCtrl( new ExpressionNode( build_constantInteger( *new string( "0u" ) ) ), $1, nullptr, OperKinds::LThan, nullptr, nullptr ); }
1286 | comma_expression ';' comma_expression // CFA
1287 { $$ = forCtrl( $3, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1288 OperKinds::LThan, $3->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1289 | comma_expression ';' '=' comma_expression // CFA
1290 { $$ = forCtrl( $4, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1291 OperKinds::LEThan, $4->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1292 | comma_expression ';' comma_expression inclexcl comma_expression // CFA
1293 { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1294 | comma_expression ';' comma_expression inclexcl comma_expression '~' comma_expression // CFA
1295 { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, $7 ); }
1296
1297 | comma_expression ';' TYPEDEFname // CFA, array type
1298 {
1299 SemanticError( yylloc, "Array interator is currently unimplemented." ); $$ = nullptr;
1300 $$ = forCtrl( new ExpressionNode( build_varref( $3 ) ), $1, nullptr, OperKinds::Range, nullptr, nullptr );
1301 }
1302
1303 // There is a S/R conflicit if ~ and -~ are factored out.
1304 | comma_expression ';' comma_expression '~' '@' // CFA
1305 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1306 | comma_expression ';' comma_expression ErangeDown '@' // CFA
1307 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1308 | comma_expression ';' comma_expression '~' '@' '~' comma_expression // CFA
1309 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, $7 ); }
1310 | comma_expression ';' comma_expression ErangeDown '@' '~' comma_expression // CFA
1311 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, $7 ); }
1312 | comma_expression ';' comma_expression '~' '@' '~' '@' // CFA
1313 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, nullptr ); }
1314 ;
1315
1316inclexcl:
1317 '~'
1318 { $$ = OperKinds::LThan; }
1319 | ErangeUpEq
1320 { $$ = OperKinds::LEThan; }
1321 | ErangeDown
1322 { $$ = OperKinds::GThan; }
1323 | ErangeDownEq
1324 { $$ = OperKinds::GEThan; }
1325 ;
1326
1327jump_statement:
1328 GOTO identifier_or_type_name ';'
1329 { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1330 | GOTO '*' comma_expression ';' // GCC, computed goto
1331 // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1332 // whereas normal operator precedence yields goto (*i)+3;
1333 { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1334 // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1335 | fall_through_name ';' // CFA
1336 { $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1337 | fall_through_name identifier_or_type_name ';' // CFA
1338 { $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1339 | fall_through_name DEFAULT ';' // CFA
1340 { $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1341 | CONTINUE ';'
1342 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1343 { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1344 | CONTINUE identifier_or_type_name ';' // CFA, multi-level continue
1345 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1346 // the target of the transfer appears only at the start of an iteration statement.
1347 { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1348 | BREAK ';'
1349 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1350 { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1351 | BREAK identifier_or_type_name ';' // CFA, multi-level exit
1352 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1353 // the target of the transfer appears only at the start of an iteration statement.
1354 { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1355 | RETURN comma_expression_opt ';'
1356 { $$ = new StatementNode( build_return( $2 ) ); }
1357 | RETURN '{' initializer_list_opt comma_opt '}' ';'
1358 { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1359 | SUSPEND ';'
1360 { $$ = new StatementNode( build_suspend( nullptr ) ); }
1361 | SUSPEND compound_statement
1362 { $$ = new StatementNode( build_suspend( $2 ) ); }
1363 | SUSPEND COROUTINE ';'
1364 { $$ = new StatementNode( build_suspend( nullptr, SuspendStmt::Coroutine ) ); }
1365 | SUSPEND COROUTINE compound_statement
1366 { $$ = new StatementNode( build_suspend( $3, SuspendStmt::Coroutine ) ); }
1367 | SUSPEND GENERATOR ';'
1368 { $$ = new StatementNode( build_suspend( nullptr, SuspendStmt::Generator ) ); }
1369 | SUSPEND GENERATOR compound_statement
1370 { $$ = new StatementNode( build_suspend( $3, SuspendStmt::Generator ) ); }
1371 | THROW assignment_expression_opt ';' // handles rethrow
1372 { $$ = new StatementNode( build_throw( $2 ) ); }
1373 | THROWRESUME assignment_expression_opt ';' // handles reresume
1374 { $$ = new StatementNode( build_resume( $2 ) ); }
1375 | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1376 { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1377 ;
1378
1379fall_through_name: // CFA
1380 FALLTHRU
1381 | FALLTHROUGH
1382 ;
1383
1384with_statement:
1385 WITH '(' tuple_expression_list ')' statement
1386 { $$ = new StatementNode( build_with( $3, $5 ) ); }
1387 ;
1388
1389// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1390mutex_statement:
1391 MUTEX '(' argument_expression_list ')' statement
1392 { $$ = new StatementNode( build_mutex( $3, $5 ) ); }
1393 ;
1394
1395when_clause:
1396 WHEN '(' comma_expression ')' { $$ = $3; }
1397 ;
1398
1399when_clause_opt:
1400 // empty
1401 { $$ = nullptr; }
1402 | when_clause
1403 ;
1404
1405waitfor:
1406 WAITFOR '(' cast_expression ')'
1407 { $$ = $3; }
1408// | WAITFOR '(' cast_expression ',' argument_expression_list_opt ')'
1409// { $$ = (ExpressionNode *)$3->set_last( $5 ); }
1410 | WAITFOR '(' cast_expression_list ':' argument_expression_list_opt ')'
1411 { $$ = (ExpressionNode *)($3->set_last( $5 )); }
1412 ;
1413
1414cast_expression_list:
1415 cast_expression
1416 | cast_expression_list ',' cast_expression
1417 // { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1418 { SemanticError( yylloc, "List of mutex member is currently unimplemented." ); $$ = nullptr; }
1419 ;
1420
1421timeout:
1422 TIMEOUT '(' comma_expression ')' { $$ = $3; }
1423 ;
1424
1425waitfor_clause:
1426 when_clause_opt waitfor statement %prec THEN
1427 { $$ = build_waitfor( $2, maybe_build_compound( $3 ), $1 ); }
1428 | when_clause_opt waitfor statement WOR waitfor_clause
1429 { $$ = build_waitfor( $2, maybe_build_compound( $3 ), $1, $5 ); }
1430 | when_clause_opt timeout statement %prec THEN
1431 { $$ = build_waitfor_timeout( $2, maybe_build_compound( $3 ), $1 ); }
1432 | when_clause_opt ELSE statement
1433 { $$ = build_waitfor_timeout( nullptr, maybe_build_compound( $3 ), $1 ); }
1434 // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1435 | when_clause_opt timeout statement WOR ELSE statement // syntax error
1436 { SemanticError( yylloc, "else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1437 | when_clause_opt timeout statement WOR when_clause ELSE statement
1438 { $$ = build_waitfor_timeout( $2, maybe_build_compound( $3 ), $1, maybe_build_compound( $7 ), $5 ); }
1439 ;
1440
1441waitfor_statement:
1442 when_clause_opt waitfor statement %prec THEN
1443 { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1444 | when_clause_opt waitfor statement WOR waitfor_clause
1445 { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1446 ;
1447
1448exception_statement:
1449 TRY compound_statement handler_clause %prec THEN
1450 { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1451 | TRY compound_statement finally_clause
1452 { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1453 | TRY compound_statement handler_clause finally_clause
1454 { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1455 ;
1456
1457handler_clause:
1458 handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1459 { $$ = new StatementNode( build_catch( $1, $4, $6, $8 ) ); }
1460 | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1461 { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $5, $7, $9 ) ) ); }
1462 ;
1463
1464handler_predicate_opt:
1465 // empty
1466 { $$ = nullptr; }
1467 | ';' conditional_expression { $$ = $2; }
1468 ;
1469
1470handler_key:
1471 CATCH { $$ = CatchStmt::Terminate; }
1472 | RECOVER { $$ = CatchStmt::Terminate; }
1473 | CATCHRESUME { $$ = CatchStmt::Resume; }
1474 | FIXUP { $$ = CatchStmt::Resume; }
1475 ;
1476
1477finally_clause:
1478 FINALLY compound_statement { $$ = new StatementNode( build_finally( $2 ) ); }
1479 ;
1480
1481exception_declaration:
1482 // No SUE declaration in parameter list.
1483 type_specifier_nobody
1484 | type_specifier_nobody declarator
1485 { $$ = $2->addType( $1 ); }
1486 | type_specifier_nobody variable_abstract_declarator
1487 { $$ = $2->addType( $1 ); }
1488 | cfa_abstract_declarator_tuple identifier // CFA
1489 { $$ = $1->addName( $2 ); }
1490 | cfa_abstract_declarator_tuple // CFA
1491 ;
1492
1493enable_disable_statement:
1494 enable_disable_key identifier_list compound_statement
1495 ;
1496
1497enable_disable_key:
1498 ENABLE
1499 | DISABLE
1500 ;
1501
1502asm_statement:
1503 ASM asm_volatile_opt '(' string_literal ')' ';'
1504 { $$ = new StatementNode( build_asm( $2, $4, 0 ) ); }
1505 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1506 { $$ = new StatementNode( build_asm( $2, $4, $6 ) ); }
1507 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1508 { $$ = new StatementNode( build_asm( $2, $4, $6, $8 ) ); }
1509 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1510 { $$ = new StatementNode( build_asm( $2, $4, $6, $8, $10 ) ); }
1511 | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1512 { $$ = new StatementNode( build_asm( $2, $5, 0, $8, $10, $12 ) ); }
1513 ;
1514
1515asm_volatile_opt: // GCC
1516 // empty
1517 { $$ = false; }
1518 | VOLATILE
1519 { $$ = true; }
1520 ;
1521
1522asm_operands_opt: // GCC
1523 // empty
1524 { $$ = nullptr; } // use default argument
1525 | asm_operands_list
1526 ;
1527
1528asm_operands_list: // GCC
1529 asm_operand
1530 | asm_operands_list ',' asm_operand
1531 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1532 ;
1533
1534asm_operand: // GCC
1535 string_literal '(' constant_expression ')'
1536 { $$ = new ExpressionNode( new AsmExpr( nullptr, $1, maybeMoveBuild<Expression>( $3 ) ) ); }
1537 | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1538 { $$ = new ExpressionNode( new AsmExpr( $2, $4, maybeMoveBuild<Expression>( $6 ) ) ); }
1539 ;
1540
1541asm_clobbers_list_opt: // GCC
1542 // empty
1543 { $$ = nullptr; } // use default argument
1544 | string_literal
1545 { $$ = new ExpressionNode( $1 ); }
1546 | asm_clobbers_list_opt ',' string_literal
1547 { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( $3 ) )); }
1548 ;
1549
1550label_list:
1551 identifier
1552 {
1553 $$ = new LabelNode(); $$->labels.push_back( *$1 );
1554 delete $1; // allocated by lexer
1555 }
1556 | label_list ',' identifier
1557 {
1558 $$ = $1; $1->labels.push_back( *$3 );
1559 delete $3; // allocated by lexer
1560 }
1561 ;
1562
1563//******************************* DECLARATIONS *********************************
1564
1565declaration_list_opt: // used at beginning of switch statement
1566 // empty
1567 { $$ = nullptr; }
1568 | declaration_list
1569 ;
1570
1571declaration_list:
1572 declaration
1573 | declaration_list declaration
1574 { $$ = $1->appendList( $2 ); }
1575 ;
1576
1577KR_parameter_list_opt: // used to declare parameter types in K&R style functions
1578 // empty
1579 { $$ = nullptr; }
1580 | KR_parameter_list
1581 ;
1582
1583KR_parameter_list:
1584 push c_declaration pop ';'
1585 { $$ = $2; }
1586 | KR_parameter_list push c_declaration pop ';'
1587 { $$ = $1->appendList( $3 ); }
1588 ;
1589
1590local_label_declaration_opt: // GCC, local label
1591 // empty
1592 | local_label_declaration_list
1593 ;
1594
1595local_label_declaration_list: // GCC, local label
1596 LABEL local_label_list ';'
1597 | local_label_declaration_list LABEL local_label_list ';'
1598 ;
1599
1600local_label_list: // GCC, local label
1601 identifier_or_type_name
1602 | local_label_list ',' identifier_or_type_name
1603 ;
1604
1605declaration: // old & new style declarations
1606 c_declaration ';'
1607 | cfa_declaration ';' // CFA
1608 | static_assert // C11
1609 ;
1610
1611static_assert:
1612 STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1613 { $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1614 | STATICASSERT '(' constant_expression ')' ';' // CFA
1615 { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( *new string( "\"\"" ) ) ); }
1616
1617// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1618// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1619// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1620// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1621// the declaration list (as in Pascal). ANSI C and the new CFA declarations may appear together in the same program
1622// block, but cannot be mixed within a specific declaration.
1623//
1624// CFA C
1625// [10] int x; int x[10]; // array of 10 integers
1626// [10] * char y; char *y[10]; // array of 10 pointers to char
1627
1628cfa_declaration: // CFA
1629 cfa_variable_declaration
1630 | cfa_typedef_declaration
1631 | cfa_function_declaration
1632 | type_declaring_list
1633 { SemanticError( yylloc, "otype declaration is currently unimplemented." ); $$ = nullptr; }
1634 | trait_specifier
1635 ;
1636
1637cfa_variable_declaration: // CFA
1638 cfa_variable_specifier initializer_opt
1639 { $$ = $1->addInitializer( $2 ); }
1640 | declaration_qualifier_list cfa_variable_specifier initializer_opt
1641 // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1642 // them as a type_qualifier cannot appear in that context.
1643 { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1644 | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1645 { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1646 ;
1647
1648cfa_variable_specifier: // CFA
1649 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1650 // storage-class
1651 cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1652 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1653 | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1654 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1655 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1656 { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1657 ;
1658
1659cfa_function_declaration: // CFA
1660 cfa_function_specifier
1661 | type_qualifier_list cfa_function_specifier
1662 { $$ = $2->addQualifiers( $1 ); }
1663 | declaration_qualifier_list cfa_function_specifier
1664 { $$ = $2->addQualifiers( $1 ); }
1665 | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1666 { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1667 | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1668 {
1669 // Append the return type at the start (left-hand-side) to each identifier in the list.
1670 DeclarationNode * ret = new DeclarationNode;
1671 ret->type = maybeClone( $1->type->base );
1672 $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1673 }
1674 ;
1675
1676cfa_function_specifier: // CFA
1677// '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1678// {
1679// $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1680// }
1681// '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1682// {
1683// typedefTable.setNextIdentifier( *$5 );
1684// $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1685// }
1686// | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1687// {
1688// typedefTable.setNextIdentifier( *$5 );
1689// $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1690// }
1691// | '[' ']' typegen_name
1692 // identifier_or_type_name must be broken apart because of the sequence:
1693 //
1694 // '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1695 // '[' ']' type_specifier
1696 //
1697 // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1698 // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1699 cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1700 // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1701 { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1702 | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1703 { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1704 ;
1705
1706cfa_function_return: // CFA
1707 '[' push cfa_parameter_list pop ']'
1708 { $$ = DeclarationNode::newTuple( $3 ); }
1709 | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1710 // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
1711 { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1712 ;
1713
1714cfa_typedef_declaration: // CFA
1715 TYPEDEF cfa_variable_specifier
1716 {
1717 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "1" );
1718 $$ = $2->addTypedef();
1719 }
1720 | TYPEDEF cfa_function_specifier
1721 {
1722 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "2" );
1723 $$ = $2->addTypedef();
1724 }
1725 | cfa_typedef_declaration pop ',' push identifier
1726 {
1727 typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "3" );
1728 $$ = $1->appendList( $1->cloneType( $5 ) );
1729 }
1730 ;
1731
1732// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1733// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1734
1735typedef_declaration:
1736 TYPEDEF type_specifier declarator
1737 {
1738 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "4" );
1739 $$ = $3->addType( $2 )->addTypedef();
1740 }
1741 | typedef_declaration pop ',' push declarator
1742 {
1743 typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname, "5" );
1744 $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1745 }
1746 | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1747 {
1748 typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "6" );
1749 $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1750 }
1751 | type_specifier TYPEDEF declarator
1752 {
1753 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "7" );
1754 $$ = $3->addType( $1 )->addTypedef();
1755 }
1756 | type_specifier TYPEDEF type_qualifier_list declarator
1757 {
1758 typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "8" );
1759 $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1760 }
1761 ;
1762
1763typedef_expression:
1764 // deprecated GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1765 TYPEDEF identifier '=' assignment_expression
1766 {
1767 SemanticError( yylloc, "Typedef expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
1768 }
1769 | typedef_expression pop ',' push identifier '=' assignment_expression
1770 {
1771 SemanticError( yylloc, "Typedef expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
1772 }
1773 ;
1774
1775c_declaration:
1776 declaration_specifier declaring_list
1777 { $$ = distAttr( $1, $2 ); }
1778 | typedef_declaration
1779 | typedef_expression // deprecated GCC, naming expression type
1780 | sue_declaration_specifier
1781 ;
1782
1783declaring_list:
1784 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1785 // storage-class
1786 declarator asm_name_opt initializer_opt
1787 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
1788 | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1789 { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
1790 ;
1791
1792declaration_specifier: // type specifier + storage class
1793 basic_declaration_specifier
1794 | sue_declaration_specifier
1795 | type_declaration_specifier
1796 ;
1797
1798declaration_specifier_nobody: // type specifier + storage class - {...}
1799 // Preclude SUE declarations in restricted scopes:
1800 //
1801 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1802 //
1803 // because it is impossible to call f due to name equivalence.
1804 basic_declaration_specifier
1805 | sue_declaration_specifier_nobody
1806 | type_declaration_specifier
1807 ;
1808
1809type_specifier: // type specifier
1810 basic_type_specifier
1811 | sue_type_specifier
1812 | type_type_specifier
1813 ;
1814
1815type_specifier_nobody: // type specifier - {...}
1816 // Preclude SUE declarations in restricted scopes:
1817 //
1818 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1819 //
1820 // because it is impossible to call f due to name equivalence.
1821 basic_type_specifier
1822 | sue_type_specifier_nobody
1823 | type_type_specifier
1824 ;
1825
1826type_qualifier_list_opt: // GCC, used in asm_statement
1827 // empty
1828 { $$ = nullptr; }
1829 | type_qualifier_list
1830 ;
1831
1832type_qualifier_list:
1833 // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1834 //
1835 // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1836 // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1837 // appeared only once.
1838 type_qualifier
1839 | type_qualifier_list type_qualifier
1840 { $$ = $1->addQualifiers( $2 ); }
1841 ;
1842
1843type_qualifier:
1844 type_qualifier_name
1845 | attribute // trick handles most atrribute locations
1846 ;
1847
1848type_qualifier_name:
1849 CONST
1850 { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1851 | RESTRICT
1852 { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1853 | VOLATILE
1854 { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1855 | ATOMIC
1856 { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1857 | forall
1858 ;
1859
1860forall:
1861 FORALL '(' type_parameter_list ')' // CFA
1862 { $$ = DeclarationNode::newForall( $3 ); }
1863 ;
1864
1865declaration_qualifier_list:
1866 storage_class_list
1867 | type_qualifier_list storage_class_list // remaining OBSOLESCENT (see 2 )
1868 { $$ = $1->addQualifiers( $2 ); }
1869 | declaration_qualifier_list type_qualifier_list storage_class_list
1870 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1871 ;
1872
1873storage_class_list:
1874 // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1875 // only one of each is specified, except for inline, which can appear with the others.
1876 //
1877 // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1878 // specifiers in a declaration.
1879 storage_class
1880 | storage_class_list storage_class
1881 { $$ = $1->addQualifiers( $2 ); }
1882 ;
1883
1884storage_class:
1885 EXTERN
1886 { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1887 | STATIC
1888 { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1889 | AUTO
1890 { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1891 | REGISTER
1892 { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1893 | THREADLOCAL // C11
1894 { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1895 // Put function specifiers here to simplify parsing rules, but separate them semantically.
1896 | INLINE // C99
1897 { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1898 | FORTRAN // C99
1899 { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1900 | NORETURN // C11
1901 { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1902 ;
1903
1904basic_type_name:
1905 VOID
1906 { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1907 | BOOL // C99
1908 { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1909 | CHAR
1910 { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1911 | INT
1912 { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1913 | INT128
1914 { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1915 | UINT128
1916 { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 )->addType( DeclarationNode::newSignedNess( DeclarationNode::Unsigned ) ); }
1917 | FLOAT
1918 { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1919 | DOUBLE
1920 { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1921 | uuFLOAT80
1922 { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
1923 | uuFLOAT128
1924 { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
1925 | uFLOAT16
1926 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
1927 | uFLOAT32
1928 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
1929 | uFLOAT32X
1930 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
1931 | uFLOAT64
1932 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
1933 | uFLOAT64X
1934 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
1935 | uFLOAT128
1936 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
1937 | DECIMAL32
1938 { SemanticError( yylloc, "_Decimal32 is currently unimplemented." ); $$ = nullptr; }
1939 | DECIMAL64
1940 { SemanticError( yylloc, "_Decimal64 is currently unimplemented." ); $$ = nullptr; }
1941 | DECIMAL128
1942 { SemanticError( yylloc, "_Decimal128 is currently unimplemented." ); $$ = nullptr; }
1943 | COMPLEX // C99
1944 { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1945 | IMAGINARY // C99
1946 { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1947 | SIGNED
1948 { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1949 | UNSIGNED
1950 { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1951 | SHORT
1952 { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1953 | LONG
1954 { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1955 | VALIST // GCC, __builtin_va_list
1956 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1957 | AUTO_TYPE
1958 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::AutoType ); }
1959 | vtable
1960 ;
1961
1962vtable_opt:
1963 // empty
1964 { $$ = nullptr; }
1965 | vtable
1966 ;
1967
1968vtable:
1969 VTABLE '(' type_name ')' default_opt
1970 { $$ = DeclarationNode::newVtableType( $3 ); }
1971 // { SemanticError( yylloc, "vtable is currently unimplemented." ); $$ = nullptr; }
1972 ;
1973
1974default_opt:
1975 // empty
1976 { $$ = nullptr; }
1977 | DEFAULT
1978 { SemanticError( yylloc, "vtable default is currently unimplemented." ); $$ = nullptr; }
1979 ;
1980
1981basic_declaration_specifier:
1982 // A semantic check is necessary for conflicting storage classes.
1983 basic_type_specifier
1984 | declaration_qualifier_list basic_type_specifier
1985 { $$ = $2->addQualifiers( $1 ); }
1986 | basic_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1987 { $$ = $1->addQualifiers( $2 ); }
1988 | basic_declaration_specifier storage_class type_qualifier_list
1989 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1990 | basic_declaration_specifier storage_class basic_type_specifier
1991 { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1992 ;
1993
1994basic_type_specifier:
1995 direct_type
1996 // Cannot have type modifiers, e.g., short, long, etc.
1997 | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1998 { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1999 ;
2000
2001direct_type:
2002 basic_type_name
2003 | type_qualifier_list basic_type_name
2004 { $$ = $2->addQualifiers( $1 ); }
2005 | direct_type type_qualifier
2006 { $$ = $1->addQualifiers( $2 ); }
2007 | direct_type basic_type_name
2008 { $$ = $1->addType( $2 ); }
2009 ;
2010
2011indirect_type:
2012 TYPEOF '(' type ')' // GCC: typeof( x ) y;
2013 { $$ = $3; }
2014 | TYPEOF '(' comma_expression ')' // GCC: typeof( a+b ) y;
2015 { $$ = DeclarationNode::newTypeof( $3 ); }
2016 | BASETYPEOF '(' type ')' // CFA: basetypeof( x ) y;
2017 { $$ = DeclarationNode::newTypeof( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ), true ); }
2018 | BASETYPEOF '(' comma_expression ')' // CFA: basetypeof( a+b ) y;
2019 { $$ = DeclarationNode::newTypeof( $3, true ); }
2020 | ZERO_T // CFA
2021 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
2022 | ONE_T // CFA
2023 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
2024 ;
2025
2026sue_declaration_specifier: // struct, union, enum + storage class + type specifier
2027 sue_type_specifier
2028 | declaration_qualifier_list sue_type_specifier
2029 { $$ = $2->addQualifiers( $1 ); }
2030 | sue_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2031 { $$ = $1->addQualifiers( $2 ); }
2032 | sue_declaration_specifier storage_class type_qualifier_list
2033 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2034 ;
2035
2036sue_type_specifier: // struct, union, enum + type specifier
2037 elaborated_type
2038 | type_qualifier_list
2039 { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
2040 elaborated_type
2041 { $$ = $3->addQualifiers( $1 ); }
2042 | sue_type_specifier type_qualifier
2043 {
2044 if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
2045 $$ = $1->addQualifiers( $2 );
2046 }
2047 ;
2048
2049sue_declaration_specifier_nobody: // struct, union, enum - {...} + storage class + type specifier
2050 sue_type_specifier_nobody
2051 | declaration_qualifier_list sue_type_specifier_nobody
2052 { $$ = $2->addQualifiers( $1 ); }
2053 | sue_declaration_specifier_nobody storage_class // remaining OBSOLESCENT (see 2)
2054 { $$ = $1->addQualifiers( $2 ); }
2055 | sue_declaration_specifier_nobody storage_class type_qualifier_list
2056 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2057 ;
2058
2059sue_type_specifier_nobody: // struct, union, enum - {...} + type specifier
2060 elaborated_type_nobody
2061 | type_qualifier_list elaborated_type_nobody
2062 { $$ = $2->addQualifiers( $1 ); }
2063 | sue_type_specifier_nobody type_qualifier
2064 { $$ = $1->addQualifiers( $2 ); }
2065 ;
2066
2067type_declaration_specifier:
2068 type_type_specifier
2069 | declaration_qualifier_list type_type_specifier
2070 { $$ = $2->addQualifiers( $1 ); }
2071 | type_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2072 { $$ = $1->addQualifiers( $2 ); }
2073 | type_declaration_specifier storage_class type_qualifier_list
2074 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2075 ;
2076
2077type_type_specifier: // typedef types
2078 type_name
2079 | type_qualifier_list type_name
2080 { $$ = $2->addQualifiers( $1 ); }
2081 | type_type_specifier type_qualifier
2082 { $$ = $1->addQualifiers( $2 ); }
2083 ;
2084
2085type_name:
2086 TYPEDEFname
2087 { $$ = DeclarationNode::newFromTypedef( $1 ); }
2088 | '.' TYPEDEFname
2089 { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
2090 | type_name '.' TYPEDEFname
2091 { $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
2092 | typegen_name
2093 | '.' typegen_name
2094 { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
2095 | type_name '.' typegen_name
2096 { $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
2097 ;
2098
2099typegen_name: // CFA
2100 TYPEGENname
2101 { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2102 | TYPEGENname '(' ')'
2103 { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2104 | TYPEGENname '(' type_list ')'
2105 { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
2106 ;
2107
2108elaborated_type: // struct, union, enum
2109 aggregate_type
2110 | enum_type
2111 ;
2112
2113elaborated_type_nobody: // struct, union, enum - {...}
2114 aggregate_type_nobody
2115 | enum_type_nobody
2116 ;
2117
2118aggregate_type: // struct, union
2119 aggregate_key attribute_list_opt
2120 { forall = false; } // reset
2121 '{' field_declaration_list_opt '}' type_parameters_opt
2122 { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2123 | aggregate_key attribute_list_opt identifier
2124 {
2125 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2126 forall = false; // reset
2127 }
2128 '{' field_declaration_list_opt '}' type_parameters_opt
2129 { $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 ); }
2130 | aggregate_key attribute_list_opt TYPEDEFname // unqualified type name
2131 {
2132 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2133 forall = false; // reset
2134 }
2135 '{' field_declaration_list_opt '}' type_parameters_opt
2136 {
2137 DeclarationNode::newFromTypedef( $3 );
2138 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2139 }
2140 | aggregate_key attribute_list_opt TYPEGENname // unqualified type name
2141 {
2142 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2143 forall = false; // reset
2144 }
2145 '{' field_declaration_list_opt '}' type_parameters_opt
2146 {
2147 DeclarationNode::newFromTypeGen( $3, nullptr );
2148 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2149 }
2150 | aggregate_type_nobody
2151 ;
2152
2153type_parameters_opt:
2154 // empty
2155 { $$ = nullptr; } %prec '}'
2156 | '(' type_list ')'
2157 { $$ = $2; }
2158 ;
2159
2160aggregate_type_nobody: // struct, union - {...}
2161 aggregate_key attribute_list_opt identifier
2162 {
2163 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname );
2164 forall = false; // reset
2165 $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2166 }
2167 | aggregate_key attribute_list_opt type_name
2168 {
2169 forall = false; // reset
2170 // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2171 // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2172 // delete newFromTypeGen.
2173 $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2174 $3->type->symbolic.name = nullptr;
2175 $3->type->symbolic.actuals = nullptr;
2176 delete $3;
2177 }
2178 ;
2179
2180aggregate_key:
2181 aggregate_data
2182 | aggregate_control
2183 ;
2184
2185aggregate_data:
2186 STRUCT vtable_opt
2187 { $$ = AggregateDecl::Struct; }
2188 | UNION
2189 { $$ = AggregateDecl::Union; }
2190 | EXCEPTION // CFA
2191 { $$ = AggregateDecl::Exception; }
2192 // { SemanticError( yylloc, "exception aggregate is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2193 ;
2194
2195aggregate_control: // CFA
2196 MONITOR
2197 { $$ = AggregateDecl::Monitor; }
2198 | MUTEX STRUCT
2199 { $$ = AggregateDecl::Monitor; }
2200 | GENERATOR
2201 { $$ = AggregateDecl::Generator; }
2202 | MUTEX GENERATOR
2203 { SemanticError( yylloc, "monitor generator is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2204 | COROUTINE
2205 { $$ = AggregateDecl::Coroutine; }
2206 | MUTEX COROUTINE
2207 { SemanticError( yylloc, "monitor coroutine is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2208 | THREAD
2209 { $$ = AggregateDecl::Thread; }
2210 | MUTEX THREAD
2211 { SemanticError( yylloc, "monitor thread is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2212 ;
2213
2214field_declaration_list_opt:
2215 // empty
2216 { $$ = nullptr; }
2217 | field_declaration_list_opt field_declaration
2218 { $$ = $1 ? $1->appendList( $2 ) : $2; }
2219 ;
2220
2221field_declaration:
2222 type_specifier field_declaring_list_opt ';'
2223 { $$ = fieldDecl( $1, $2 ); }
2224 | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2225 { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2226 | INLINE type_specifier field_abstract_list_opt ';' // CFA
2227 {
2228 if ( ! $3 ) { // field declarator ?
2229 $3 = DeclarationNode::newName( nullptr );
2230 } // if
2231 $3->inLine = true;
2232 $$ = distAttr( $2, $3 ); // mark all fields in list
2233 distInl( $3 );
2234 }
2235 | INLINE aggregate_control ';' // CFA
2236 { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2237 | typedef_declaration ';' // CFA
2238 | cfa_field_declaring_list ';' // CFA, new style field declaration
2239 | EXTENSION cfa_field_declaring_list ';' // GCC
2240 { distExt( $2 ); $$ = $2; } // mark all fields in list
2241 | INLINE cfa_field_abstract_list ';' // CFA, new style field declaration
2242 { $$ = $2; } // mark all fields in list
2243 | cfa_typedef_declaration ';' // CFA
2244 | static_assert // C11
2245 ;
2246
2247field_declaring_list_opt:
2248 // empty
2249 { $$ = nullptr; }
2250 | field_declarator
2251 | field_declaring_list_opt ',' attribute_list_opt field_declarator
2252 { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2253 ;
2254
2255field_declarator:
2256 bit_subrange_size // C special case, no field name
2257 { $$ = DeclarationNode::newBitfield( $1 ); }
2258 | variable_declarator bit_subrange_size_opt
2259 // A semantic check is required to ensure bit_subrange only appears on integral types.
2260 { $$ = $1->addBitfield( $2 ); }
2261 | variable_type_redeclarator bit_subrange_size_opt
2262 // A semantic check is required to ensure bit_subrange only appears on integral types.
2263 { $$ = $1->addBitfield( $2 ); }
2264 ;
2265
2266field_abstract_list_opt:
2267 // empty
2268 { $$ = nullptr; }
2269 | field_abstract
2270 | field_abstract_list_opt ',' attribute_list_opt field_abstract
2271 { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2272 ;
2273
2274field_abstract:
2275 // no bit fields
2276 variable_abstract_declarator
2277 ;
2278
2279cfa_field_declaring_list: // CFA, new style field declaration
2280 // bit-fields are handled by C declarations
2281 cfa_abstract_declarator_tuple identifier_or_type_name
2282 { $$ = $1->addName( $2 ); }
2283 | cfa_field_declaring_list ',' identifier_or_type_name
2284 { $$ = $1->appendList( $1->cloneType( $3 ) ); }
2285 ;
2286
2287cfa_field_abstract_list: // CFA, new style field declaration
2288 // bit-fields are handled by C declarations
2289 cfa_abstract_declarator_tuple
2290 | cfa_field_abstract_list ','
2291 { $$ = $1->appendList( $1->cloneType( 0 ) ); }
2292 ;
2293
2294bit_subrange_size_opt:
2295 // empty
2296 { $$ = nullptr; }
2297 | bit_subrange_size
2298 ;
2299
2300bit_subrange_size:
2301 ':' assignment_expression
2302 { $$ = $2; }
2303 ;
2304
2305enum_type: // enum
2306 ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2307 { $$ = DeclarationNode::newEnum( nullptr, $4, true )->addQualifiers( $2 ); }
2308 | ENUM attribute_list_opt identifier
2309 { typedefTable.makeTypedef( *$3 ); }
2310 '{' enumerator_list comma_opt '}'
2311 { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
2312 | ENUM attribute_list_opt typedef_name // unqualified type name
2313 '{' enumerator_list comma_opt '}'
2314 { $$ = DeclarationNode::newEnum( $3->name, $5, true )->addQualifiers( $2 ); }
2315 | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt '{' enumerator_list comma_opt '}'
2316 {
2317 if ( $3->storageClasses.val != 0 || $3->type->qualifiers.val != 0 ) { SemanticError( yylloc, "storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." ); }
2318 SemanticError( yylloc, "Typed enumeration is currently unimplemented." ); $$ = nullptr;
2319 }
2320 | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt identifier attribute_list_opt
2321 {
2322 if ( $3->storageClasses.val != 0 || $3->type->qualifiers.val != 0 ) { SemanticError( yylloc, "storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." ); }
2323 typedefTable.makeTypedef( *$6 );
2324 }
2325 '{' enumerator_list comma_opt '}'
2326 {
2327 SemanticError( yylloc, "Typed enumeration is currently unimplemented." ); $$ = nullptr;
2328 }
2329 | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt typedef_name attribute_list_opt '{' enumerator_list comma_opt '}'
2330 {
2331 if ( $3->storageClasses.val != 0 || $3->type->qualifiers.val != 0 ) { SemanticError( yylloc, "storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." ); }
2332 typedefTable.makeTypedef( *$6->name );
2333 SemanticError( yylloc, "Typed enumeration is currently unimplemented." ); $$ = nullptr;
2334 }
2335 | enum_type_nobody
2336 ;
2337
2338enum_type_nobody: // enum - {...}
2339 ENUM attribute_list_opt identifier
2340 { typedefTable.makeTypedef( *$3 ); $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 ); }
2341 | ENUM attribute_list_opt type_name // qualified type name
2342 { typedefTable.makeTypedef( *$3->type->symbolic.name ); $$ = DeclarationNode::newEnum( $3->type->symbolic.name, 0, false )->addQualifiers( $2 ); }
2343 ;
2344
2345enumerator_list:
2346 identifier_or_type_name enumerator_value_opt
2347 { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
2348 | INLINE type_name
2349 { $$ = DeclarationNode::newEnumConstant( new string("inline"), nullptr ); }
2350 | enumerator_list ',' identifier_or_type_name enumerator_value_opt
2351 { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
2352 | enumerator_list ',' INLINE type_name enumerator_value_opt
2353 { $$ = $1->appendList( DeclarationNode::newEnumConstant( new string("inline"), nullptr ) ); }
2354 ;
2355
2356enumerator_value_opt:
2357 // empty
2358 { $$ = nullptr; }
2359 // | '=' constant_expression
2360 // { $$ = $2; }
2361 | simple_assignment_operator initializer
2362 { $$ = $2->get_expression(); } // FIX ME: enum only deals with constant_expression
2363 ;
2364
2365cfa_parameter_ellipsis_list_opt: // CFA, abstract + real
2366 // empty
2367 { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2368 | ELLIPSIS
2369 { $$ = nullptr; }
2370 | cfa_abstract_parameter_list
2371 | cfa_parameter_list
2372 | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2373 { $$ = $1->appendList( $5 ); }
2374 | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2375 { $$ = $1->addVarArgs(); }
2376 | cfa_parameter_list pop ',' push ELLIPSIS
2377 { $$ = $1->addVarArgs(); }
2378 ;
2379
2380cfa_parameter_list: // CFA
2381 // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2382 // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2383 cfa_parameter_declaration
2384 | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2385 { $$ = $1->appendList( $5 ); }
2386 | cfa_parameter_list pop ',' push cfa_parameter_declaration
2387 { $$ = $1->appendList( $5 ); }
2388 | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2389 { $$ = $1->appendList( $5 )->appendList( $9 ); }
2390 ;
2391
2392cfa_abstract_parameter_list: // CFA, new & old style abstract
2393 cfa_abstract_parameter_declaration
2394 | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2395 { $$ = $1->appendList( $5 ); }
2396 ;
2397
2398parameter_type_list_opt:
2399 // empty
2400 { $$ = nullptr; }
2401 | ELLIPSIS
2402 { $$ = nullptr; }
2403 | parameter_list
2404 | parameter_list pop ',' push ELLIPSIS
2405 { $$ = $1->addVarArgs(); }
2406 ;
2407
2408parameter_list: // abstract + real
2409 abstract_parameter_declaration
2410 | parameter_declaration
2411 | parameter_list pop ',' push abstract_parameter_declaration
2412 { $$ = $1->appendList( $5 ); }
2413 | parameter_list pop ',' push parameter_declaration
2414 { $$ = $1->appendList( $5 ); }
2415 ;
2416
2417// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2418// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2419
2420cfa_parameter_declaration: // CFA, new & old style parameter declaration
2421 parameter_declaration
2422 | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initializer_opt
2423 { $$ = $1->addName( $2 ); }
2424 | cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2425 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2426 { $$ = $1->addName( $2 ); }
2427 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2428 { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2429 | cfa_function_specifier
2430 ;
2431
2432cfa_abstract_parameter_declaration: // CFA, new & old style parameter declaration
2433 abstract_parameter_declaration
2434 | cfa_identifier_parameter_declarator_no_tuple
2435 | cfa_abstract_tuple
2436 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2437 | type_qualifier_list cfa_abstract_tuple
2438 { $$ = $2->addQualifiers( $1 ); }
2439 | cfa_abstract_function
2440 ;
2441
2442parameter_declaration:
2443 // No SUE declaration in parameter list.
2444 declaration_specifier_nobody identifier_parameter_declarator default_initializer_opt
2445 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2446 | declaration_specifier_nobody type_parameter_redeclarator default_initializer_opt
2447 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2448 ;
2449
2450abstract_parameter_declaration:
2451 declaration_specifier_nobody default_initializer_opt
2452 { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2453 | declaration_specifier_nobody abstract_parameter_declarator default_initializer_opt
2454 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2455 ;
2456
2457// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2458// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2459// identifiers. The ANSI-style parameter-list can redefine a typedef name.
2460
2461identifier_list: // K&R-style parameter list => no types
2462 identifier
2463 { $$ = DeclarationNode::newName( $1 ); }
2464 | identifier_list ',' identifier
2465 { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2466 ;
2467
2468identifier_or_type_name:
2469 identifier
2470 | TYPEDEFname
2471 | TYPEGENname
2472 ;
2473
2474type_no_function: // sizeof, alignof, cast (constructor)
2475 cfa_abstract_declarator_tuple // CFA
2476 | type_specifier
2477 | type_specifier abstract_declarator
2478 { $$ = $2->addType( $1 ); }
2479 ;
2480
2481type: // typeof, assertion
2482 type_no_function
2483 | cfa_abstract_function // CFA
2484 ;
2485
2486initializer_opt:
2487 // empty
2488 { $$ = nullptr; }
2489 | simple_assignment_operator initializer { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2490 | '=' VOID { $$ = new InitializerNode( true ); }
2491 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
2492 ;
2493
2494initializer:
2495 assignment_expression { $$ = new InitializerNode( $1 ); }
2496 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
2497 ;
2498
2499initializer_list_opt:
2500 // empty
2501 { $$ = nullptr; }
2502 | initializer
2503 | designation initializer { $$ = $2->set_designators( $1 ); }
2504 | initializer_list_opt ',' initializer { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2505 | initializer_list_opt ',' designation initializer { $$ = (InitializerNode *)($1->set_last( $4->set_designators( $3 ) )); }
2506 ;
2507
2508// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2509// '=' to separator the designator from the initializer value, as in:
2510//
2511// int x[10] = { [1] = 3 };
2512//
2513// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment. To disambiguate this case, CFA
2514// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2515// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2516// shift/reduce conflicts
2517
2518designation:
2519 designator_list ':' // C99, CFA uses ":" instead of "="
2520 | identifier_at ':' // GCC, field name
2521 { $$ = new ExpressionNode( build_varref( $1 ) ); }
2522 ;
2523
2524designator_list: // C99
2525 designator
2526 | designator_list designator
2527 { $$ = (ExpressionNode *)($1->set_last( $2 )); }
2528 //| designator_list designator { $$ = new ExpressionNode( $1, $2 ); }
2529 ;
2530
2531designator:
2532 '.' identifier_at // C99, field name
2533 { $$ = new ExpressionNode( build_varref( $2 ) ); }
2534 | '[' push assignment_expression pop ']' // C99, single array element
2535 // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2536 { $$ = $3; }
2537 | '[' push subrange pop ']' // CFA, multiple array elements
2538 { $$ = $3; }
2539 | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2540 { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild<Expression>( $3 ), maybeMoveBuild<Expression>( $5 ) ) ); }
2541 | '.' '[' push field_name_list pop ']' // CFA, tuple field selector
2542 { $$ = $4; }
2543 ;
2544
2545// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2546// rather than an object-oriented type system. This required four groups of extensions:
2547//
2548// Overloading: function, data, and operator identifiers may be overloaded.
2549//
2550// Type declarations: "otype" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2551// and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2552// definitions of new types. Type declarations with storage class "extern" provide opaque types.
2553//
2554// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2555// site. A polymorphic function is not a template; it is a function, with an address and a type.
2556//
2557// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2558// types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2559// hierarchies. Unlike classes, they can define relationships between types. Assertions declare that a type or
2560// types provide the operations declared by a specification. Assertions are normally used to declare requirements
2561// on type arguments of polymorphic functions.
2562
2563type_parameter_list: // CFA
2564 type_parameter
2565 | type_parameter_list ',' type_parameter
2566 { $$ = $1->appendList( $3 ); }
2567 ;
2568
2569type_initializer_opt: // CFA
2570 // empty
2571 { $$ = nullptr; }
2572 | '=' type
2573 { $$ = $2; }
2574 ;
2575
2576type_parameter: // CFA
2577 type_class identifier_or_type_name
2578 {
2579 typedefTable.addToScope( *$2, TYPEDEFname, "9" );
2580 if ( $1 == TypeDecl::Otype ) { SemanticError( yylloc, "otype keyword is deprecated, use T " ); }
2581 if ( $1 == TypeDecl::Dtype ) { SemanticError( yylloc, "dtype keyword is deprecated, use T &" ); }
2582 if ( $1 == TypeDecl::Ttype ) { SemanticError( yylloc, "ttype keyword is deprecated, use T ..." ); }
2583 }
2584 type_initializer_opt assertion_list_opt
2585 { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2586 | identifier_or_type_name new_type_class
2587 { typedefTable.addToScope( *$1, TYPEDEFname, "9" ); }
2588 type_initializer_opt assertion_list_opt
2589 { $$ = DeclarationNode::newTypeParam( $2, $1 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2590 | '[' identifier_or_type_name ']'
2591 {
2592 typedefTable.addToScope( *$2, TYPEDIMname, "9" );
2593 $$ = DeclarationNode::newTypeParam( TypeDecl::Dimension, $2 );
2594 }
2595 // | type_specifier identifier_parameter_declarator
2596 | assertion_list
2597 { $$ = DeclarationNode::newTypeParam( TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2598 ;
2599
2600new_type_class: // CFA
2601 // empty
2602 { $$ = TypeDecl::Otype; }
2603 | '&'
2604 { $$ = TypeDecl::Dtype; }
2605 | '*'
2606 { $$ = TypeDecl::DStype; } // dtype + sized
2607 // | '(' '*' ')'
2608 // { $$ = TypeDecl::Ftype; }
2609 | ELLIPSIS
2610 { $$ = TypeDecl::Ttype; }
2611 ;
2612
2613type_class: // CFA
2614 OTYPE
2615 { $$ = TypeDecl::Otype; }
2616 | DTYPE
2617 { $$ = TypeDecl::Dtype; }
2618 | FTYPE
2619 { $$ = TypeDecl::Ftype; }
2620 | TTYPE
2621 { $$ = TypeDecl::Ttype; }
2622 ;
2623
2624assertion_list_opt: // CFA
2625 // empty
2626 { $$ = nullptr; }
2627 | assertion_list
2628 ;
2629
2630assertion_list: // CFA
2631 assertion
2632 | assertion_list assertion
2633 { $$ = $1->appendList( $2 ); }
2634 ;
2635
2636assertion: // CFA
2637 '|' identifier_or_type_name '(' type_list ')'
2638 { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
2639 | '|' '{' push trait_declaration_list pop '}'
2640 { $$ = $4; }
2641 // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
2642 // { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
2643 ;
2644
2645type_list: // CFA
2646 type
2647 { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2648 | assignment_expression
2649 | type_list ',' type
2650 { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) )); }
2651 | type_list ',' assignment_expression
2652 { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2653 ;
2654
2655type_declaring_list: // CFA
2656 OTYPE type_declarator
2657 { $$ = $2; }
2658 | storage_class_list OTYPE type_declarator
2659 { $$ = $3->addQualifiers( $1 ); }
2660 | type_declaring_list ',' type_declarator
2661 { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2662 ;
2663
2664type_declarator: // CFA
2665 type_declarator_name assertion_list_opt
2666 { $$ = $1->addAssertions( $2 ); }
2667 | type_declarator_name assertion_list_opt '=' type
2668 { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2669 ;
2670
2671type_declarator_name: // CFA
2672 identifier_or_type_name
2673 {
2674 typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "10" );
2675 $$ = DeclarationNode::newTypeDecl( $1, 0 );
2676 }
2677 | identifier_or_type_name '(' type_parameter_list ')'
2678 {
2679 typedefTable.addToEnclosingScope( *$1, TYPEGENname, "11" );
2680 $$ = DeclarationNode::newTypeDecl( $1, $3 );
2681 }
2682 ;
2683
2684trait_specifier: // CFA
2685 TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
2686 { $$ = DeclarationNode::newTrait( $2, $4, 0 ); }
2687 | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
2688 { $$ = DeclarationNode::newTrait( $2, $4, $8 ); }
2689 ;
2690
2691trait_declaration_list: // CFA
2692 trait_declaration
2693 | trait_declaration_list pop push trait_declaration
2694 { $$ = $1->appendList( $4 ); }
2695 ;
2696
2697trait_declaration: // CFA
2698 cfa_trait_declaring_list ';'
2699 | trait_declaring_list ';'
2700 ;
2701
2702cfa_trait_declaring_list: // CFA
2703 cfa_variable_specifier
2704 | cfa_function_specifier
2705 | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2706 { $$ = $1->appendList( $1->cloneType( $5 ) ); }
2707 ;
2708
2709trait_declaring_list: // CFA
2710 type_specifier declarator
2711 { $$ = $2->addType( $1 ); }
2712 | trait_declaring_list pop ',' push declarator
2713 { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
2714 ;
2715
2716//***************************** EXTERNAL DEFINITIONS *****************************
2717
2718translation_unit:
2719 // empty, input file
2720 | external_definition_list
2721 { parseTree = parseTree ? parseTree->appendList( $1 ) : $1; }
2722 ;
2723
2724external_definition_list:
2725 push external_definition pop
2726 { $$ = $2; }
2727 | external_definition_list push external_definition pop
2728 { $$ = $1 ? $1->appendList( $3 ) : $3; }
2729 ;
2730
2731external_definition_list_opt:
2732 // empty
2733 { $$ = nullptr; }
2734 | external_definition_list
2735 ;
2736
2737up:
2738 { typedefTable.up( forall ); forall = false; }
2739 ;
2740
2741down:
2742 { typedefTable.down(); }
2743 ;
2744
2745external_definition:
2746 DIRECTIVE
2747 { $$ = DeclarationNode::newDirectiveStmt( new StatementNode( build_directive( $1 ) ) ); }
2748 | declaration
2749 | external_function_definition
2750 | EXTENSION external_definition // GCC, multiple __extension__ allowed, meaning unknown
2751 {
2752 distExt( $2 ); // mark all fields in list
2753 $$ = $2;
2754 }
2755 | ASM '(' string_literal ')' ';' // GCC, global assembler statement
2756 { $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( false, $3, 0 ) ) ); }
2757 | EXTERN STRINGliteral
2758 {
2759 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
2760 linkage = LinkageSpec::update( yylloc, linkage, $2 );
2761 }
2762 up external_definition down
2763 {
2764 linkage = linkageStack.top();
2765 linkageStack.pop();
2766 $$ = $5;
2767 }
2768 | EXTERN STRINGliteral // C++-style linkage specifier
2769 {
2770 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
2771 linkage = LinkageSpec::update( yylloc, linkage, $2 );
2772 }
2773 '{' up external_definition_list_opt down '}'
2774 {
2775 linkage = linkageStack.top();
2776 linkageStack.pop();
2777 $$ = $6;
2778 }
2779 | type_qualifier_list
2780 {
2781 if ( $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2782 if ( $1->type->forall ) forall = true; // remember generic type
2783 }
2784 '{' up external_definition_list_opt down '}' // CFA, namespace
2785 {
2786 distQual( $5, $1 );
2787 forall = false;
2788 $$ = $5;
2789 }
2790 | declaration_qualifier_list
2791 {
2792 if ( $1->type && $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2793 if ( $1->type && $1->type->forall ) forall = true; // remember generic type
2794 }
2795 '{' up external_definition_list_opt down '}' // CFA, namespace
2796 {
2797 distQual( $5, $1 );
2798 forall = false;
2799 $$ = $5;
2800 }
2801 | declaration_qualifier_list type_qualifier_list
2802 {
2803 if ( ($1->type && $1->type->qualifiers.val) || $2->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2804 if ( ($1->type && $1->type->forall) || $2->type->forall ) forall = true; // remember generic type
2805 }
2806 '{' up external_definition_list_opt down '}' // CFA, namespace
2807 {
2808 distQual( $6, $1->addQualifiers( $2 ) );
2809 forall = false;
2810 $$ = $6;
2811 }
2812 ;
2813
2814external_function_definition:
2815 function_definition
2816 // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2817 // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2818 // Parsing is possible because function_definition does not appear in the context of an expression (nested
2819 // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2820 // declaration must still have a type_specifier. OBSOLESCENT (see 1)
2821 | function_declarator compound_statement
2822 { $$ = $1->addFunctionBody( $2 ); }
2823 | KR_function_declarator KR_parameter_list_opt compound_statement
2824 { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
2825 ;
2826
2827with_clause_opt:
2828 // empty
2829 { $$ = nullptr; forall = false; }
2830 | WITH '(' tuple_expression_list ')'
2831 { $$ = $3; forall = false; }
2832 ;
2833
2834function_definition:
2835 cfa_function_declaration with_clause_opt compound_statement // CFA
2836 {
2837 // Add the function body to the last identifier in the function definition list, i.e., foo3:
2838 // [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2839 $1->get_last()->addFunctionBody( $3, $2 );
2840 $$ = $1;
2841 }
2842 | declaration_specifier function_declarator with_clause_opt compound_statement
2843 {
2844 rebindForall( $1, $2 );
2845 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2846 }
2847 | declaration_specifier variable_type_redeclarator with_clause_opt compound_statement
2848 {
2849 rebindForall( $1, $2 );
2850 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2851 }
2852 // handles default int return type, OBSOLESCENT (see 1)
2853 | type_qualifier_list function_declarator with_clause_opt compound_statement
2854 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2855 // handles default int return type, OBSOLESCENT (see 1)
2856 | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2857 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2858 // handles default int return type, OBSOLESCENT (see 1)
2859 | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2860 { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2861
2862 // Old-style K&R function definition, OBSOLESCENT (see 4)
2863 | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2864 {
2865 rebindForall( $1, $2 );
2866 $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2867 }
2868 // handles default int return type, OBSOLESCENT (see 1)
2869 | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2870 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2871 // handles default int return type, OBSOLESCENT (see 1)
2872 | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2873 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2874 // handles default int return type, OBSOLESCENT (see 1)
2875 | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2876 { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2877 ;
2878
2879declarator:
2880 variable_declarator
2881 | variable_type_redeclarator
2882 | function_declarator
2883 ;
2884
2885subrange:
2886 constant_expression '~' constant_expression // CFA, integer subrange
2887 { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild<Expression>( $1 ), maybeMoveBuild<Expression>( $3 ) ) ); }
2888 ;
2889
2890asm_name_opt: // GCC
2891 // empty
2892 { $$ = nullptr; }
2893 | ASM '(' string_literal ')' attribute_list_opt
2894 {
2895 DeclarationNode * name = new DeclarationNode();
2896 name->asmName = $3;
2897 $$ = name->addQualifiers( $5 );
2898 }
2899 ;
2900
2901attribute_list_opt: // GCC
2902 // empty
2903 { $$ = nullptr; }
2904 | attribute_list
2905 ;
2906
2907attribute_list: // GCC
2908 attribute
2909 | attribute_list attribute
2910 { $$ = $2->addQualifiers( $1 ); }
2911 ;
2912
2913attribute: // GCC
2914 ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2915 { $$ = $4; }
2916 ;
2917
2918attribute_name_list: // GCC
2919 attribute_name
2920 | attribute_name_list ',' attribute_name
2921 { $$ = $3->addQualifiers( $1 ); }
2922 ;
2923
2924attribute_name: // GCC
2925 // empty
2926 { $$ = nullptr; }
2927 | attr_name
2928 { $$ = DeclarationNode::newAttribute( $1 ); }
2929 | attr_name '(' argument_expression_list_opt ')'
2930 { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2931 ;
2932
2933attr_name: // GCC
2934 IDENTIFIER
2935 | quasi_keyword
2936 | TYPEDEFname
2937 | TYPEGENname
2938 | FALLTHROUGH
2939 { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2940 | CONST
2941 { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2942 ;
2943
2944// ============================================================================
2945// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2946// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2947// in:
2948//
2949// int (*f())[10] { ... };
2950// ... (*f())[3] += 1; // definition mimics usage
2951//
2952// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2953// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2954// ============================================================================
2955
2956// ----------------------------------------------------------------------------
2957// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2958// to define a variable or function prototype, e.g.:
2959//
2960// valid declaration invalid definition
2961// ----------------- ------------------
2962// int f; int f {}
2963// int *f; int *f {}
2964// int f[10]; int f[10] {}
2965// int (*f)(int); int (*f)(int) {}
2966//
2967// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2968// variable_declarator and function_declarator.
2969// ----------------------------------------------------------------------------
2970
2971// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2972// declaring an array of functions versus a pointer to an array of functions.
2973
2974paren_identifier:
2975 identifier_at
2976 { $$ = DeclarationNode::newName( $1 ); }
2977 | '(' paren_identifier ')' // redundant parenthesis
2978 { $$ = $2; }
2979 ;
2980
2981variable_declarator:
2982 paren_identifier attribute_list_opt
2983 { $$ = $1->addQualifiers( $2 ); }
2984 | variable_ptr
2985 | variable_array attribute_list_opt
2986 { $$ = $1->addQualifiers( $2 ); }
2987 | variable_function attribute_list_opt
2988 { $$ = $1->addQualifiers( $2 ); }
2989 ;
2990
2991variable_ptr:
2992 ptrref_operator variable_declarator
2993 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2994 | ptrref_operator type_qualifier_list variable_declarator
2995 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2996 | '(' variable_ptr ')' attribute_list_opt // redundant parenthesis
2997 { $$ = $2->addQualifiers( $4 ); }
2998 | '(' attribute_list variable_ptr ')' attribute_list_opt // redundant parenthesis
2999 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3000 ;
3001
3002variable_array:
3003 paren_identifier array_dimension
3004 { $$ = $1->addArray( $2 ); }
3005 | '(' variable_ptr ')' array_dimension
3006 { $$ = $2->addArray( $4 ); }
3007 | '(' attribute_list variable_ptr ')' array_dimension
3008 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3009 | '(' variable_array ')' multi_array_dimension // redundant parenthesis
3010 { $$ = $2->addArray( $4 ); }
3011 | '(' attribute_list variable_array ')' multi_array_dimension // redundant parenthesis
3012 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3013 | '(' variable_array ')' // redundant parenthesis
3014 { $$ = $2; }
3015 | '(' attribute_list variable_array ')' // redundant parenthesis
3016 { $$ = $3->addQualifiers( $2 ); }
3017 ;
3018
3019variable_function:
3020 '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3021 { $$ = $2->addParamList( $6 ); }
3022 | '(' attribute_list variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3023 { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
3024 | '(' variable_function ')' // redundant parenthesis
3025 { $$ = $2; }
3026 | '(' attribute_list variable_function ')' // redundant parenthesis
3027 { $$ = $3->addQualifiers( $2 ); }
3028 ;
3029
3030// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
3031// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
3032// is the same scope. The pattern precludes returning arrays and functions versus pointers to arrays and functions.
3033
3034function_declarator:
3035 function_no_ptr attribute_list_opt
3036 { $$ = $1->addQualifiers( $2 ); }
3037 | function_ptr
3038 | function_array attribute_list_opt
3039 { $$ = $1->addQualifiers( $2 ); }
3040 ;
3041
3042function_no_ptr:
3043 paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3044 { $$ = $1->addParamList( $4 ); }
3045 | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
3046 { $$ = $2->addParamList( $6 ); }
3047 | '(' attribute_list function_ptr ')' '(' push parameter_type_list_opt pop ')'
3048 { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
3049 | '(' function_no_ptr ')' // redundant parenthesis
3050 { $$ = $2; }
3051 | '(' attribute_list function_no_ptr ')' // redundant parenthesis
3052 { $$ = $3->addQualifiers( $2 ); }
3053 ;
3054
3055function_ptr:
3056 ptrref_operator function_declarator
3057 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3058 | ptrref_operator type_qualifier_list function_declarator
3059 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3060 | '(' function_ptr ')' attribute_list_opt
3061 { $$ = $2->addQualifiers( $4 ); }
3062 | '(' attribute_list function_ptr ')' attribute_list_opt
3063 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3064 ;
3065
3066function_array:
3067 '(' function_ptr ')' array_dimension
3068 { $$ = $2->addArray( $4 ); }
3069 | '(' attribute_list function_ptr ')' array_dimension
3070 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3071 | '(' function_array ')' multi_array_dimension // redundant parenthesis
3072 { $$ = $2->addArray( $4 ); }
3073 | '(' attribute_list function_array ')' multi_array_dimension // redundant parenthesis
3074 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3075 | '(' function_array ')' // redundant parenthesis
3076 { $$ = $2; }
3077 | '(' attribute_list function_array ')' // redundant parenthesis
3078 { $$ = $3->addQualifiers( $2 ); }
3079 ;
3080
3081// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
3082//
3083// f( a, b, c ) int a, *b, c[]; {}
3084//
3085// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
3086// returning arrays and functions versus pointers to arrays and functions.
3087
3088KR_function_declarator:
3089 KR_function_no_ptr
3090 | KR_function_ptr
3091 | KR_function_array
3092 ;
3093
3094KR_function_no_ptr:
3095 paren_identifier '(' identifier_list ')' // function_declarator handles empty parameter
3096 { $$ = $1->addIdList( $3 ); }
3097 | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
3098 { $$ = $2->addParamList( $6 ); }
3099 | '(' attribute_list KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
3100 { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
3101 | '(' KR_function_no_ptr ')' // redundant parenthesis
3102 { $$ = $2; }
3103 | '(' attribute_list KR_function_no_ptr ')' // redundant parenthesis
3104 { $$ = $3->addQualifiers( $2 ); }
3105 ;
3106
3107KR_function_ptr:
3108 ptrref_operator KR_function_declarator
3109 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3110 | ptrref_operator type_qualifier_list KR_function_declarator
3111 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3112 | '(' KR_function_ptr ')'
3113 { $$ = $2; }
3114 | '(' attribute_list KR_function_ptr ')'
3115 { $$ = $3->addQualifiers( $2 ); }
3116 ;
3117
3118KR_function_array:
3119 '(' KR_function_ptr ')' array_dimension
3120 { $$ = $2->addArray( $4 ); }
3121 | '(' attribute_list KR_function_ptr ')' array_dimension
3122 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3123 | '(' KR_function_array ')' multi_array_dimension // redundant parenthesis
3124 { $$ = $2->addArray( $4 ); }
3125 | '(' attribute_list KR_function_array ')' multi_array_dimension // redundant parenthesis
3126 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3127 | '(' KR_function_array ')' // redundant parenthesis
3128 { $$ = $2; }
3129 | '(' attribute_list KR_function_array ')' // redundant parenthesis
3130 { $$ = $3->addQualifiers( $2 ); }
3131 ;
3132
3133// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
3134//
3135// typedef int foo;
3136// {
3137// int foo; // redefine typedef name in new scope
3138// }
3139//
3140// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3141// and functions versus pointers to arrays and functions.
3142
3143paren_type:
3144 typedef_name
3145 {
3146 // hide type name in enclosing scope by variable name
3147 typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "ID" );
3148 }
3149 | '(' paren_type ')'
3150 { $$ = $2; }
3151 ;
3152
3153variable_type_redeclarator:
3154 paren_type attribute_list_opt
3155 { $$ = $1->addQualifiers( $2 ); }
3156 | type_ptr
3157 | type_array attribute_list_opt
3158 { $$ = $1->addQualifiers( $2 ); }
3159 | type_function attribute_list_opt
3160 { $$ = $1->addQualifiers( $2 ); }
3161 ;
3162
3163type_ptr:
3164 ptrref_operator variable_type_redeclarator
3165 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3166 | ptrref_operator type_qualifier_list variable_type_redeclarator
3167 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3168 | '(' type_ptr ')' attribute_list_opt // redundant parenthesis
3169 { $$ = $2->addQualifiers( $4 ); }
3170 | '(' attribute_list type_ptr ')' attribute_list_opt // redundant parenthesis
3171 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3172 ;
3173
3174type_array:
3175 paren_type array_dimension
3176 { $$ = $1->addArray( $2 ); }
3177 | '(' type_ptr ')' array_dimension
3178 { $$ = $2->addArray( $4 ); }
3179 | '(' attribute_list type_ptr ')' array_dimension
3180 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3181 | '(' type_array ')' multi_array_dimension // redundant parenthesis
3182 { $$ = $2->addArray( $4 ); }
3183 | '(' attribute_list type_array ')' multi_array_dimension // redundant parenthesis
3184 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3185 | '(' type_array ')' // redundant parenthesis
3186 { $$ = $2; }
3187 | '(' attribute_list type_array ')' // redundant parenthesis
3188 { $$ = $3->addQualifiers( $2 ); }
3189 ;
3190
3191type_function:
3192 paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3193 { $$ = $1->addParamList( $4 ); }
3194 | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3195 { $$ = $2->addParamList( $6 ); }
3196 | '(' attribute_list type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3197 { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
3198 | '(' type_function ')' // redundant parenthesis
3199 { $$ = $2; }
3200 | '(' attribute_list type_function ')' // redundant parenthesis
3201 { $$ = $3->addQualifiers( $2 ); }
3202 ;
3203
3204// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
3205// typedef name and allows the C99 array options, which can only appear in a parameter list. The pattern precludes
3206// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
3207// pointers to arrays and functions.
3208
3209identifier_parameter_declarator:
3210 paren_identifier attribute_list_opt
3211 { $$ = $1->addQualifiers( $2 ); }
3212 | '&' MUTEX paren_identifier attribute_list_opt
3213 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3214 | identifier_parameter_ptr
3215 | identifier_parameter_array attribute_list_opt
3216 { $$ = $1->addQualifiers( $2 ); }
3217 | identifier_parameter_function attribute_list_opt
3218 { $$ = $1->addQualifiers( $2 ); }
3219 ;
3220
3221identifier_parameter_ptr:
3222 ptrref_operator identifier_parameter_declarator
3223 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3224 | ptrref_operator type_qualifier_list identifier_parameter_declarator
3225 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3226 | '(' identifier_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3227 { $$ = $2->addQualifiers( $4 ); }
3228 ;
3229
3230identifier_parameter_array:
3231 paren_identifier array_parameter_dimension
3232 { $$ = $1->addArray( $2 ); }
3233 | '(' identifier_parameter_ptr ')' array_dimension
3234 { $$ = $2->addArray( $4 ); }
3235 | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3236 { $$ = $2->addArray( $4 ); }
3237 | '(' identifier_parameter_array ')' // redundant parenthesis
3238 { $$ = $2; }
3239 ;
3240
3241identifier_parameter_function:
3242 paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3243 { $$ = $1->addParamList( $4 ); }
3244 | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3245 { $$ = $2->addParamList( $6 ); }
3246 | '(' identifier_parameter_function ')' // redundant parenthesis
3247 { $$ = $2; }
3248 ;
3249
3250// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3251// e.g.:
3252//
3253// typedef int foo;
3254// forall( otype T ) struct foo;
3255// int f( int foo ); // redefine typedef name in new scope
3256//
3257// and allows the C99 array options, which can only appear in a parameter list.
3258
3259type_parameter_redeclarator:
3260 typedef_name attribute_list_opt
3261 { $$ = $1->addQualifiers( $2 ); }
3262 | '&' MUTEX typedef_name attribute_list_opt
3263 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3264 | type_parameter_ptr
3265 | type_parameter_array attribute_list_opt
3266 { $$ = $1->addQualifiers( $2 ); }
3267 | type_parameter_function attribute_list_opt
3268 { $$ = $1->addQualifiers( $2 ); }
3269 ;
3270
3271typedef_name:
3272 TYPEDEFname
3273 { $$ = DeclarationNode::newName( $1 ); }
3274 | TYPEGENname
3275 { $$ = DeclarationNode::newName( $1 ); }
3276 ;
3277
3278type_parameter_ptr:
3279 ptrref_operator type_parameter_redeclarator
3280 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3281 | ptrref_operator type_qualifier_list type_parameter_redeclarator
3282 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3283 | '(' type_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3284 { $$ = $2->addQualifiers( $4 ); }
3285 ;
3286
3287type_parameter_array:
3288 typedef_name array_parameter_dimension
3289 { $$ = $1->addArray( $2 ); }
3290 | '(' type_parameter_ptr ')' array_parameter_dimension
3291 { $$ = $2->addArray( $4 ); }
3292 ;
3293
3294type_parameter_function:
3295 typedef_name '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3296 { $$ = $1->addParamList( $4 ); }
3297 | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3298 { $$ = $2->addParamList( $6 ); }
3299 ;
3300
3301// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3302// which the type applies, e.g.:
3303//
3304// sizeof( int );
3305// sizeof( int * );
3306// sizeof( int [10] );
3307// sizeof( int (*)() );
3308// sizeof( int () );
3309//
3310// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3311// and functions versus pointers to arrays and functions.
3312
3313abstract_declarator:
3314 abstract_ptr
3315 | abstract_array attribute_list_opt
3316 { $$ = $1->addQualifiers( $2 ); }
3317 | abstract_function attribute_list_opt
3318 { $$ = $1->addQualifiers( $2 ); }
3319 ;
3320
3321abstract_ptr:
3322 ptrref_operator
3323 { $$ = DeclarationNode::newPointer( 0, $1 ); }
3324 | ptrref_operator type_qualifier_list
3325 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3326 | ptrref_operator abstract_declarator
3327 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3328 | ptrref_operator type_qualifier_list abstract_declarator
3329 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3330 | '(' abstract_ptr ')' attribute_list_opt
3331 { $$ = $2->addQualifiers( $4 ); }
3332 ;
3333
3334abstract_array:
3335 array_dimension
3336 | '(' abstract_ptr ')' array_dimension
3337 { $$ = $2->addArray( $4 ); }
3338 | '(' abstract_array ')' multi_array_dimension // redundant parenthesis
3339 { $$ = $2->addArray( $4 ); }
3340 | '(' abstract_array ')' // redundant parenthesis
3341 { $$ = $2; }
3342 ;
3343
3344abstract_function:
3345 '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3346 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3347 | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3348 { $$ = $2->addParamList( $6 ); }
3349 | '(' abstract_function ')' // redundant parenthesis
3350 { $$ = $2; }
3351 ;
3352
3353array_dimension:
3354 // Only the first dimension can be empty.
3355 '[' ']'
3356 { $$ = DeclarationNode::newArray( 0, 0, false ); }
3357 | '[' ']' multi_array_dimension
3358 { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
3359 | '[' push assignment_expression pop ',' comma_expression ']'
3360 { $$ = DeclarationNode::newArray( $3, 0, false )->addArray( DeclarationNode::newArray( $6, 0, false ) ); }
3361 // { SemanticError( yylloc, "New array dimension is currently unimplemented." ); $$ = nullptr; }
3362 | multi_array_dimension
3363 ;
3364
3365multi_array_dimension:
3366 '[' push assignment_expression pop ']'
3367 { $$ = DeclarationNode::newArray( $3, 0, false ); }
3368 | '[' push '*' pop ']' // C99
3369 { $$ = DeclarationNode::newVarArray( 0 ); }
3370 | multi_array_dimension '[' push assignment_expression pop ']'
3371 { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
3372 | multi_array_dimension '[' push '*' pop ']' // C99
3373 { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3374 ;
3375
3376// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3377// identifier to which the type applies, e.g.:
3378//
3379// int f( int ); // not handled here
3380// int f( int * ); // abstract function-prototype parameter; no parameter name specified
3381// int f( int (*)() ); // abstract function-prototype parameter; no parameter name specified
3382// int f( int (int) ); // abstract function-prototype parameter; no parameter name specified
3383//
3384// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3385// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3386// special meaning of parenthesis around a typedef name:
3387//
3388// ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3389// parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3390// not as redundant parentheses around the identifier."
3391//
3392// For example:
3393//
3394// typedef float T;
3395// int f( int ( T [5] ) ); // see abstract_parameter_declarator
3396// int g( int ( T ( int ) ) ); // see abstract_parameter_declarator
3397// int f( int f1( T a[5] ) ); // see identifier_parameter_declarator
3398// int g( int g1( T g2( int p ) ) ); // see identifier_parameter_declarator
3399//
3400// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3401// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3402// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3403// functions.
3404
3405abstract_parameter_declarator:
3406 abstract_parameter_ptr
3407 | '&' MUTEX attribute_list_opt
3408 { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3409 | abstract_parameter_array attribute_list_opt
3410 { $$ = $1->addQualifiers( $2 ); }
3411 | abstract_parameter_function attribute_list_opt
3412 { $$ = $1->addQualifiers( $2 ); }
3413 ;
3414
3415abstract_parameter_ptr:
3416 ptrref_operator
3417 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3418 | ptrref_operator type_qualifier_list
3419 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3420 | ptrref_operator abstract_parameter_declarator
3421 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3422 | ptrref_operator type_qualifier_list abstract_parameter_declarator
3423 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3424 | '(' abstract_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3425 { $$ = $2->addQualifiers( $4 ); }
3426 ;
3427
3428abstract_parameter_array:
3429 array_parameter_dimension
3430 | '(' abstract_parameter_ptr ')' array_parameter_dimension
3431 { $$ = $2->addArray( $4 ); }
3432 | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3433 { $$ = $2->addArray( $4 ); }
3434 | '(' abstract_parameter_array ')' // redundant parenthesis
3435 { $$ = $2; }
3436 ;
3437
3438abstract_parameter_function:
3439 '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3440 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3441 | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3442 { $$ = $2->addParamList( $6 ); }
3443 | '(' abstract_parameter_function ')' // redundant parenthesis
3444 { $$ = $2; }
3445 ;
3446
3447array_parameter_dimension:
3448 // Only the first dimension can be empty or have qualifiers.
3449 array_parameter_1st_dimension
3450 | array_parameter_1st_dimension multi_array_dimension
3451 { $$ = $1->addArray( $2 ); }
3452 | multi_array_dimension
3453 ;
3454
3455// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3456//
3457// ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3458// a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3459
3460array_parameter_1st_dimension:
3461 '[' ']'
3462 { $$ = DeclarationNode::newArray( 0, 0, false ); }
3463 // multi_array_dimension handles the '[' '*' ']' case
3464 | '[' push type_qualifier_list '*' pop ']' // remaining C99
3465 { $$ = DeclarationNode::newVarArray( $3 ); }
3466 | '[' push type_qualifier_list pop ']'
3467 { $$ = DeclarationNode::newArray( 0, $3, false ); }
3468 // multi_array_dimension handles the '[' assignment_expression ']' case
3469 | '[' push type_qualifier_list assignment_expression pop ']'
3470 { $$ = DeclarationNode::newArray( $4, $3, false ); }
3471 | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3472 { $$ = DeclarationNode::newArray( $5, $4, true ); }
3473 | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3474 { $$ = DeclarationNode::newArray( $5, $3, true ); }
3475 ;
3476
3477// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3478//
3479// struct S {
3480// int;
3481// int *;
3482// int [10];
3483// int (*)();
3484// };
3485
3486variable_abstract_declarator:
3487 variable_abstract_ptr
3488 | variable_abstract_array attribute_list_opt
3489 { $$ = $1->addQualifiers( $2 ); }
3490 | variable_abstract_function attribute_list_opt
3491 { $$ = $1->addQualifiers( $2 ); }
3492 ;
3493
3494variable_abstract_ptr:
3495 ptrref_operator
3496 { $$ = DeclarationNode::newPointer( 0, $1 ); }
3497 | ptrref_operator type_qualifier_list
3498 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3499 | ptrref_operator variable_abstract_declarator
3500 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3501 | ptrref_operator type_qualifier_list variable_abstract_declarator
3502 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3503 | '(' variable_abstract_ptr ')' attribute_list_opt // redundant parenthesis
3504 { $$ = $2->addQualifiers( $4 ); }
3505 ;
3506
3507variable_abstract_array:
3508 array_dimension
3509 | '(' variable_abstract_ptr ')' array_dimension
3510 { $$ = $2->addArray( $4 ); }
3511 | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3512 { $$ = $2->addArray( $4 ); }
3513 | '(' variable_abstract_array ')' // redundant parenthesis
3514 { $$ = $2; }
3515 ;
3516
3517variable_abstract_function:
3518 '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3519 { $$ = $2->addParamList( $6 ); }
3520 | '(' variable_abstract_function ')' // redundant parenthesis
3521 { $$ = $2; }
3522 ;
3523
3524// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3525// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3526
3527cfa_identifier_parameter_declarator_tuple: // CFA
3528 cfa_identifier_parameter_declarator_no_tuple
3529 | cfa_abstract_tuple
3530 | type_qualifier_list cfa_abstract_tuple
3531 { $$ = $2->addQualifiers( $1 ); }
3532 ;
3533
3534cfa_identifier_parameter_declarator_no_tuple: // CFA
3535 cfa_identifier_parameter_ptr
3536 | cfa_identifier_parameter_array
3537 ;
3538
3539cfa_identifier_parameter_ptr: // CFA
3540 // No SUE declaration in parameter list.
3541 ptrref_operator type_specifier_nobody
3542 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3543 | type_qualifier_list ptrref_operator type_specifier_nobody
3544 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3545 | ptrref_operator cfa_abstract_function
3546 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3547 | type_qualifier_list ptrref_operator cfa_abstract_function
3548 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3549 | ptrref_operator cfa_identifier_parameter_declarator_tuple
3550 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3551 | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3552 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3553 ;
3554
3555cfa_identifier_parameter_array: // CFA
3556 // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3557 // shift/reduce conflict with new-style empty (void) function return type.
3558 '[' ']' type_specifier_nobody
3559 { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3560 | cfa_array_parameter_1st_dimension type_specifier_nobody
3561 { $$ = $2->addNewArray( $1 ); }
3562 | '[' ']' multi_array_dimension type_specifier_nobody
3563 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3564 | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3565 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3566 | multi_array_dimension type_specifier_nobody
3567 { $$ = $2->addNewArray( $1 ); }
3568
3569 | '[' ']' cfa_identifier_parameter_ptr
3570 { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3571 | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3572 { $$ = $2->addNewArray( $1 ); }
3573 | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3574 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3575 | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3576 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3577 | multi_array_dimension cfa_identifier_parameter_ptr
3578 { $$ = $2->addNewArray( $1 ); }
3579 ;
3580
3581cfa_array_parameter_1st_dimension:
3582 '[' push type_qualifier_list '*' pop ']' // remaining C99
3583 { $$ = DeclarationNode::newVarArray( $3 ); }
3584 | '[' push type_qualifier_list assignment_expression pop ']'
3585 { $$ = DeclarationNode::newArray( $4, $3, false ); }
3586 | '[' push declaration_qualifier_list assignment_expression pop ']'
3587 // declaration_qualifier_list must be used because of shift/reduce conflict with
3588 // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3589 // appear in this context.
3590 { $$ = DeclarationNode::newArray( $4, $3, true ); }
3591 | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3592 { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3593 ;
3594
3595// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3596// identifier to which the type applies, e.g.:
3597//
3598// [int] f( int ); // abstract variable parameter; no parameter name specified
3599// [int] f( [int] (int) ); // abstract function-prototype parameter; no parameter name specified
3600//
3601// These rules need LR(3):
3602//
3603// cfa_abstract_tuple identifier_or_type_name
3604// '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
3605//
3606// since a function return type can be syntactically identical to a tuple type:
3607//
3608// [int, int] t;
3609// [int, int] f( int );
3610//
3611// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3612// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3613// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3614// duplicated when appearing with cfa_function_specifier.
3615
3616cfa_abstract_declarator_tuple: // CFA
3617 cfa_abstract_tuple
3618 | type_qualifier_list cfa_abstract_tuple
3619 { $$ = $2->addQualifiers( $1 ); }
3620 | cfa_abstract_declarator_no_tuple
3621 ;
3622
3623cfa_abstract_declarator_no_tuple: // CFA
3624 cfa_abstract_ptr
3625 | cfa_abstract_array
3626 ;
3627
3628cfa_abstract_ptr: // CFA
3629 ptrref_operator type_specifier
3630 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3631 | type_qualifier_list ptrref_operator type_specifier
3632 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3633 | ptrref_operator cfa_abstract_function
3634 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3635 | type_qualifier_list ptrref_operator cfa_abstract_function
3636 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3637 | ptrref_operator cfa_abstract_declarator_tuple
3638 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3639 | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3640 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3641 ;
3642
3643cfa_abstract_array: // CFA
3644 // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3645 // empty (void) function return type.
3646 '[' ']' type_specifier
3647 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3648 | '[' ']' multi_array_dimension type_specifier
3649 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3650 | multi_array_dimension type_specifier
3651 { $$ = $2->addNewArray( $1 ); }
3652 | '[' ']' cfa_abstract_ptr
3653 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3654 | '[' ']' multi_array_dimension cfa_abstract_ptr
3655 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3656 | multi_array_dimension cfa_abstract_ptr
3657 { $$ = $2->addNewArray( $1 ); }
3658 ;
3659
3660cfa_abstract_tuple: // CFA
3661 '[' push cfa_abstract_parameter_list pop ']'
3662 { $$ = DeclarationNode::newTuple( $3 ); }
3663 | '[' push type_specifier_nobody ELLIPSIS pop ']'
3664 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3665 | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
3666 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3667 ;
3668
3669cfa_abstract_function: // CFA
3670// '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
3671// { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3672 cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
3673 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3674 | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
3675 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3676 ;
3677
3678// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3679// each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3680//
3681// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3682// the declaration specifiers in a declaration is an obsolescent feature."
3683//
3684// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3685// prototype-format parameter type declarators) is an obsolescent feature."
3686//
3687// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3688// declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3689
3690//************************* MISCELLANEOUS ********************************
3691
3692comma_opt: // redundant comma
3693 // empty
3694 | ','
3695 ;
3696
3697default_initializer_opt:
3698 // empty
3699 { $$ = nullptr; }
3700 | '=' assignment_expression
3701 { $$ = $2; }
3702 ;
3703
3704%%
3705
3706// ----end of grammar----
3707
3708// Local Variables: //
3709// mode: c++ //
3710// tab-width: 4 //
3711// compile-command: "make install" //
3712// End: //
Note: See TracBrowser for help on using the repository browser.