source: src/Parser/parser.yy@ 496f92ed

ADT ast-experimental enum pthread-emulation qualifiedEnum
Last change on this file since 496f92ed was afe9e45, checked in by Peter A. Buhr <pabuhr@…>, 4 years ago

add more detailed syntax-error messages
  • Property mode set to 100644
File size: 148.3 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author : Peter A. Buhr
10// Created On : Sat Sep 1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Fri Feb 25 17:54:56 2022
13// Update Count : 5262
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS. While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks. Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// designation with '=' (use ':' instead)
29//
30// This incompatibility is discussed in detail before the "designation" grammar rule. Most of the syntactic extensions
31// from ANSI90 to ANSI11 C are marked with the comment "C99/C11".
32
33// This grammar also has two levels of extensions. The first extensions cover most of the GCC C extensions. All of the
34// syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall (CFA), which
35// fixes several of C's outstanding problems and extends C with many modern language concepts. All of the syntactic
36// extensions for CFA C are marked with the comment "CFA".
37
38%{
39#define YYDEBUG_LEXER_TEXT( yylval ) // lexer loads this up each time
40#define YYDEBUG 1 // get the pretty debugging code to compile
41#define YYERROR_VERBOSE // more information in syntax errors
42
43#undef __GNUC_MINOR__
44
45#include <cstdio>
46#include <stack>
47using namespace std;
48
49#include "SynTree/Declaration.h"
50#include "ParseNode.h"
51#include "TypedefTable.h"
52#include "TypeData.h"
53#include "SynTree/LinkageSpec.h"
54#include "Common/SemanticError.h" // error_str
55#include "Common/utility.h" // for maybeMoveBuild, maybeBuild, CodeLo...
56
57extern DeclarationNode * parseTree;
58extern LinkageSpec::Spec linkage;
59extern TypedefTable typedefTable;
60
61stack<LinkageSpec::Spec> linkageStack;
62
63bool appendStr( string & to, string & from ) {
64 // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
65 // "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
66 // the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
67 // easier to let the C compiler handle this case.
68 //
69 // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
70 // without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
71 // e.g., u"a" U"b" L"c" is disallowed.
72
73 if ( from[0] != '"' ) { // encoding ?
74 if ( to[0] != '"' ) { // encoding ?
75 if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
76 yyerror( "non-matching string encodings for string-literal concatenation" );
77 return false; // parse error, must call YYERROR in action
78 } else if ( from[1] == '8' ) {
79 from.erase( 0, 1 ); // remove 2nd encoding
80 } // if
81 } else {
82 if ( from[1] == '8' ) { // move encoding to start
83 to = "u8" + to;
84 from.erase( 0, 1 ); // remove 2nd encoding
85 } else {
86 to = from[0] + to;
87 } // if
88 } // if
89 from.erase( 0, 1 ); // remove 2nd encoding
90 } // if
91 to += " " + from; // concatenated into single string
92 return true;
93} // appendStr
94
95DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
96 // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
97 DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
98 for ( cur = dynamic_cast<DeclarationNode *>( cur->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode *>( cur->get_next() ) ) {
99 cl->cloneBaseType( cur );
100 } // for
101 declList->addType( cl );
102 return declList;
103} // distAttr
104
105void distExt( DeclarationNode * declaration ) {
106 // distribute EXTENSION across all declarations
107 for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
108 iter->set_extension( true );
109 } // for
110} // distExt
111
112void distInl( DeclarationNode * declaration ) {
113 // distribute EXTENSION across all declarations
114 for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
115 iter->set_inLine( true );
116 } // for
117} // distInl
118
119void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
120 // distribute qualifiers across all non-variable declarations in a distribution statemement
121 for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
122 // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
123 // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
124 // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
125 // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
126 DeclarationNode * clone = qualifiers->clone();
127 if ( qualifiers->type ) { // forall clause ? (handles SC)
128 if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
129 swap( clone->type->forall, iter->type->aggregate.params );
130 iter->addQualifiers( clone );
131 } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
132 // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
133 DeclarationNode newnode;
134 swap( newnode.type, iter->type->aggInst.aggregate );
135 swap( clone->type->forall, newnode.type->aggregate.params );
136 newnode.addQualifiers( clone );
137 swap( newnode.type, iter->type->aggInst.aggregate );
138 } else if ( iter->type->kind == TypeData::Function ) { // routines ?
139 swap( clone->type->forall, iter->type->forall );
140 iter->addQualifiers( clone );
141 } // if
142 } else { // just SC qualifiers
143 iter->addQualifiers( clone );
144 } // if
145 } // for
146 delete qualifiers;
147} // distQual
148
149// There is an ambiguity for inline generic-routine return-types and generic routines.
150// forall( otype T ) struct S { int i; } bar( T ) {}
151// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
152// forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
153// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
154// forall( otype T ) struct S { int T; };
155// forall( otype W ) bar( W ) {}
156
157void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
158 if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
159 funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
160 declSpec->type->aggregate.params = nullptr;
161 } // if
162} // rebindForall
163
164string * build_postfix_name( string * name ) {
165 *name = string("__postfix_func_") + *name;
166 return name;
167} // build_postfix_name
168
169DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
170 if ( ! fieldList ) { // field declarator ?
171 if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate || typeSpec->type->kind == TypeData::Enum) ) ) {
172 stringstream ss;
173 typeSpec->type->print( ss );
174 SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
175 return nullptr;
176 } // if
177 fieldList = DeclarationNode::newName( nullptr );
178 } // if
179 return distAttr( typeSpec, fieldList ); // mark all fields in list
180} // fieldDecl
181
182ForCtrl * forCtrl( ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
183 ConstantExpr * constant = dynamic_cast<ConstantExpr *>(type->expr.get());
184 if ( constant && (constant->get_constant()->get_value() == "0" || constant->get_constant()->get_value() == "1") ) {
185 type = new ExpressionNode( new CastExpr( maybeMoveBuild<Expression>(type), new BasicType( Type::Qualifiers(), BasicType::SignedInt ) ) );
186 } // if
187// type = new ExpressionNode( build_func( new ExpressionNode( build_varref( new string( "__for_control_index_constraints__" ) ) ), type ) );
188 return new ForCtrl(
189 distAttr( DeclarationNode::newTypeof( type, true ), DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) ) ),
190 // NULL comp/inc => leave blank
191 comp ? new ExpressionNode( build_binary_val( compop, new ExpressionNode( build_varref( new string( *index ) ) ), comp ) ) : 0,
192 inc ? new ExpressionNode( build_binary_val( compop == OperKinds::LThan || compop == OperKinds::LEThan ? // choose += or -= for upto/downto
193 OperKinds::PlusAssn : OperKinds::MinusAssn, new ExpressionNode( build_varref( new string( *index ) ) ), inc ) ) : 0 );
194} // forCtrl
195
196ForCtrl * forCtrl( ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
197 if ( NameExpr * identifier = dynamic_cast<NameExpr *>(index->expr.get()) ) {
198 return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
199 } else if ( CommaExpr * commaExpr = dynamic_cast<CommaExpr *>(index->expr.get()) ) {
200 if ( NameExpr * identifier = dynamic_cast<NameExpr *>(commaExpr->arg1 ) ) {
201 return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
202 } else {
203 SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed." ); return nullptr;
204 } // if
205 } else {
206 SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed." ); return nullptr;
207 } // if
208} // forCtrl
209
210bool forall = false; // aggregate have one or more forall qualifiers ?
211
212// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
213#define YYLLOC_DEFAULT(Cur, Rhs, N) \
214if ( N ) { \
215 (Cur).first_line = YYRHSLOC( Rhs, 1 ).first_line; \
216 (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column; \
217 (Cur).last_line = YYRHSLOC( Rhs, N ).last_line; \
218 (Cur).last_column = YYRHSLOC( Rhs, N ).last_column; \
219 (Cur).filename = YYRHSLOC( Rhs, 1 ).filename; \
220} else { \
221 (Cur).first_line = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line; \
222 (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column; \
223 (Cur).filename = YYRHSLOC( Rhs, 0 ).filename; \
224}
225%}
226
227%define parse.error verbose
228
229// Types declaration for productions
230%union {
231 Token tok;
232 ParseNode * pn;
233 ExpressionNode * en;
234 DeclarationNode * decl;
235 AggregateDecl::Aggregate aggKey;
236 TypeDecl::Kind tclass;
237 StatementNode * sn;
238 WaitForStmt * wfs;
239 Expression * constant;
240 CondCtl * ifctl;
241 ForCtrl * fctl;
242 enum OperKinds compop;
243 LabelNode * label;
244 InitializerNode * in;
245 OperKinds op;
246 std::string * str;
247 bool flag;
248 CatchStmt::Kind catch_kind;
249 GenericExpr * genexpr;
250}
251
252//************************* TERMINAL TOKENS ********************************
253
254// keywords
255%token TYPEDEF
256%token EXTERN STATIC AUTO REGISTER
257%token THREADLOCAL // C11
258%token INLINE FORTRAN // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
259%token NORETURN // C11
260%token CONST VOLATILE
261%token RESTRICT // C99
262%token ATOMIC // C11
263%token FORALL MUTEX VIRTUAL VTABLE COERCE // CFA
264%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
265%token BOOL COMPLEX IMAGINARY // C99
266%token INT128 UINT128 uuFLOAT80 uuFLOAT128 // GCC
267%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
268%token DECIMAL32 DECIMAL64 DECIMAL128 // GCC
269%token ZERO_T ONE_T // CFA
270%token SIZEOF TYPEOF VALIST AUTO_TYPE // GCC
271%token OFFSETOF BASETYPEOF TYPEID // CFA
272%token ENUM STRUCT UNION
273%token EXCEPTION // CFA
274%token GENERATOR COROUTINE MONITOR THREAD // CFA
275%token OTYPE FTYPE DTYPE TTYPE TRAIT // CFA
276// %token RESUME // CFA
277%token LABEL // GCC
278%token SUSPEND // CFA
279%token ATTRIBUTE EXTENSION // GCC
280%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
281%token CHOOSE FALLTHRU FALLTHROUGH WITH WHEN WAITFOR // CFA
282%token DISABLE ENABLE TRY THROW THROWRESUME AT // CFA
283%token ASM // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
284%token ALIGNAS ALIGNOF GENERIC STATICASSERT // C11
285
286// names and constants: lexer differentiates between identifier and typedef names
287%token<tok> IDENTIFIER QUOTED_IDENTIFIER TYPEDIMname TYPEDEFname TYPEGENname
288%token<tok> TIMEOUT WOR CATCH RECOVER CATCHRESUME FIXUP FINALLY // CFA
289%token<tok> INTEGERconstant CHARACTERconstant STRINGliteral
290%token<tok> DIRECTIVE
291// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
292// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
293// converted into the tuple index (.)(1). e.g., 3.x
294%token<tok> FLOATING_DECIMALconstant FLOATING_FRACTIONconstant FLOATINGconstant
295
296// multi-character operators
297%token ARROW // ->
298%token ICR DECR // ++ --
299%token LS RS // << >>
300%token LE GE EQ NE // <= >= == !=
301%token ANDAND OROR // && ||
302%token ELLIPSIS // ...
303
304%token EXPassign MULTassign DIVassign MODassign // \= *= /= %=
305%token PLUSassign MINUSassign // += -=
306%token LSassign RSassign // <<= >>=
307%token ANDassign ERassign ORassign // &= ^= |=
308
309%token ErangeUpEq ErangeDown ErangeDownEq // ~= -~ -~=
310%token ATassign // @=
311
312%type<tok> identifier identifier_at identifier_or_type_name attr_name
313%type<tok> quasi_keyword
314%type<constant> string_literal
315%type<str> string_literal_list
316
317// expressions
318%type<en> constant
319%type<en> tuple tuple_expression_list
320%type<op> ptrref_operator unary_operator assignment_operator simple_assignment_operator compound_assignment_operator
321%type<en> primary_expression postfix_expression unary_expression
322%type<en> cast_expression_list cast_expression exponential_expression multiplicative_expression additive_expression
323%type<en> shift_expression relational_expression equality_expression
324%type<en> AND_expression exclusive_OR_expression inclusive_OR_expression
325%type<en> logical_AND_expression logical_OR_expression
326%type<en> conditional_expression constant_expression assignment_expression assignment_expression_opt
327%type<en> comma_expression comma_expression_opt
328%type<en> argument_expression_list_opt argument_expression_list argument_expression default_initializer_opt
329%type<ifctl> conditional_declaration
330%type<fctl> for_control_expression for_control_expression_list
331%type<compop> inclexcl
332%type<en> subrange
333%type<decl> asm_name_opt
334%type<en> asm_operands_opt asm_operands_list asm_operand
335%type<label> label_list
336%type<en> asm_clobbers_list_opt
337%type<flag> asm_volatile_opt
338%type<en> handler_predicate_opt
339%type<genexpr> generic_association generic_assoc_list
340
341// statements
342%type<sn> statement labeled_statement compound_statement
343%type<sn> statement_decl statement_decl_list statement_list_nodecl
344%type<sn> selection_statement if_statement
345%type<sn> switch_clause_list_opt switch_clause_list
346%type<en> case_value
347%type<sn> case_clause case_value_list case_label case_label_list
348%type<sn> iteration_statement jump_statement
349%type<sn> expression_statement asm_statement
350%type<sn> with_statement
351%type<en> with_clause_opt
352%type<sn> exception_statement handler_clause finally_clause
353%type<catch_kind> handler_key
354%type<sn> mutex_statement
355%type<en> when_clause when_clause_opt waitfor timeout
356%type<sn> waitfor_statement
357%type<wfs> waitfor_clause
358
359// declarations
360%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
361%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
362%type<decl> abstract_parameter_declaration
363
364%type<aggKey> aggregate_key aggregate_data aggregate_control
365%type<decl> aggregate_type aggregate_type_nobody
366
367%type<decl> assertion assertion_list assertion_list_opt
368
369%type<en> bit_subrange_size_opt bit_subrange_size
370
371%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
372%type<decl> vtable vtable_opt default_opt
373
374%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
375
376%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
377%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
378
379%type<decl> elaborated_type elaborated_type_nobody
380
381%type<decl> enumerator_list enum_type enum_type_nobody
382%type<en> enumerator_value_opt
383
384%type<decl> external_definition external_definition_list external_definition_list_opt
385
386%type<decl> exception_declaration
387
388%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
389%type<en> field field_name_list field_name fraction_constants_opt
390
391%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
392
393%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
394%type<decl> identifier_list
395
396%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
397%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
398%type<decl> cfa_abstract_ptr cfa_abstract_tuple
399
400%type<decl> cfa_array_parameter_1st_dimension
401
402%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
403%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
404
405%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
406%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
407
408%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
409
410%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
411
412%type<decl> c_declaration static_assert
413%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
414%type<decl> KR_parameter_list KR_parameter_list_opt
415
416%type<decl> parameter_declaration parameter_list parameter_type_list_opt
417
418%type<decl> paren_identifier paren_type
419
420%type<decl> storage_class storage_class_list
421
422%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
423
424%type<tclass> type_class new_type_class
425%type<decl> type_declarator type_declarator_name type_declaring_list
426
427%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
428%type<decl> typedef_name typedef_declaration typedef_expression
429
430%type<decl> variable_type_redeclarator type_ptr type_array type_function
431
432%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
433
434%type<decl> type type_no_function
435%type<decl> type_parameter type_parameter_list type_initializer_opt
436
437%type<en> type_parameters_opt type_list
438
439%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
440%type<decl> type_specifier type_specifier_nobody
441
442%type<decl> variable_declarator variable_ptr variable_array variable_function
443%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
444
445%type<decl> attribute_list_opt attribute_list attribute attribute_name_list attribute_name
446
447// initializers
448%type<in> initializer initializer_list_opt initializer_opt
449
450// designators
451%type<en> designator designator_list designation
452
453
454// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
455// .---------. matches IF '(' comma_expression ')' statement . (reduce)
456// if ( C ) S1 else S2
457// `-----------------' matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
458// Similar issues exit with the waitfor statement.
459
460// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
461// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
462%precedence THEN // rule precedence for IF/WAITFOR statement
463%precedence WOR // token precedence for start of WOR in WAITFOR statement
464%precedence TIMEOUT // token precedence for start of TIMEOUT in WAITFOR statement
465%precedence CATCH // token precedence for start of TIMEOUT in WAITFOR statement
466%precedence RECOVER // token precedence for start of TIMEOUT in WAITFOR statement
467%precedence CATCHRESUME // token precedence for start of TIMEOUT in WAITFOR statement
468%precedence FIXUP // token precedence for start of TIMEOUT in WAITFOR statement
469%precedence FINALLY // token precedence for start of TIMEOUT in WAITFOR statement
470%precedence ELSE // token precedence for start of else clause in IF/WAITFOR statement
471
472
473// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
474// forall( otype T ) struct Foo { T v; };
475// .-----. matches pointer to function returning a generic (which is impossible without a type)
476// Foo ( *fp )( int );
477// `---' matches start of TYPEGENname '('
478// must be:
479// Foo( int ) ( *fp )( int );
480// The same problem occurs here:
481// forall( otype T ) struct Foo { T v; } ( *fp )( int );
482// must be:
483// forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
484
485// Order of these lines matters (low-to-high precedence).
486%precedence TYPEGENname
487%precedence '}'
488%precedence '('
489
490// %precedence RESUME
491// %precedence '{'
492// %precedence ')'
493
494%locations // support location tracking for error messages
495
496%start translation_unit // parse-tree root
497
498%%
499//************************* Namespace Management ********************************
500
501// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
502// which are lexically identical.
503//
504// typedef int foo; // identifier foo must now be scanned as TYPEDEFname
505// foo f; // to allow it to appear in this context
506//
507// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
508// between syntactic and semantic constructs. Cforall compounds this problem by introducing type names local to the
509// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
510// generators" -- parameterized types. This latter type name creates a third class of identifiers, "TYPEGENname", which
511// must be distinguished by the lexical scanner.
512//
513// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
514// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
515// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
516// each context that introduces a name scope, a new level is created in the type table and that level is popped on
517// exiting the scope. Since type names can be local to a particular declaration, each declaration is itself a scope.
518// This requires distinguishing between type names that are local to the current declaration scope and those that
519// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
520//
521// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
522// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
523// around the list separator.
524//
525// int f( forall(T) T (*f1) T , forall( S ) S (*f2)( S ) );
526// push pop push pop
527
528push:
529 { typedefTable.enterScope(); }
530 ;
531
532pop:
533 { typedefTable.leaveScope(); }
534 ;
535
536//************************* CONSTANTS ********************************
537
538constant:
539 // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
540 INTEGERconstant { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
541 | FLOATING_DECIMALconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
542 | FLOATING_FRACTIONconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
543 | FLOATINGconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
544 | CHARACTERconstant { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
545 ;
546
547quasi_keyword: // CFA
548 TIMEOUT
549 | WOR
550 | CATCH
551 | RECOVER
552 | CATCHRESUME
553 | FIXUP
554 | FINALLY
555 ;
556
557identifier:
558 IDENTIFIER
559 | quasi_keyword
560 ;
561
562identifier_at:
563 identifier
564 | '@' // CFA
565 { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
566 ;
567
568string_literal:
569 string_literal_list { $$ = build_constantStr( *$1 ); }
570 ;
571
572string_literal_list: // juxtaposed strings are concatenated
573 STRINGliteral { $$ = $1; } // conversion from tok to str
574 | string_literal_list STRINGliteral
575 {
576 if ( ! appendStr( *$1, *$2 ) ) YYERROR; // append 2nd juxtaposed string to 1st
577 delete $2; // allocated by lexer
578 $$ = $1; // conversion from tok to str
579 }
580 ;
581
582//************************* EXPRESSIONS ********************************
583
584primary_expression:
585 IDENTIFIER // typedef name cannot be used as a variable name
586 { $$ = new ExpressionNode( build_varref( $1 ) ); }
587 | quasi_keyword
588 { $$ = new ExpressionNode( build_varref( $1 ) ); }
589 | TYPEDIMname // CFA, generic length argument
590 // { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( DeclarationNode::newFromTypedef( $1 ) ) ) ); }
591 // { $$ = new ExpressionNode( build_varref( $1 ) ); }
592 { $$ = new ExpressionNode( build_dimensionref( $1 ) ); }
593 | tuple
594 | '(' comma_expression ')'
595 { $$ = $2; }
596 | '(' compound_statement ')' // GCC, lambda expression
597 { $$ = new ExpressionNode( new StmtExpr( dynamic_cast<CompoundStmt *>(maybeMoveBuild<Statement>($2) ) ) ); }
598 | type_name '.' identifier // CFA, nested type
599 { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
600 | type_name '.' '[' field_name_list ']' // CFA, nested type / tuple field selector
601 { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
602 | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
603 {
604 // add the missing control expression to the GenericExpr and return it
605 $5->control = maybeMoveBuild<Expression>( $3 );
606 $$ = new ExpressionNode( $5 );
607 }
608 // | RESUME '(' comma_expression ')'
609 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
610 // | RESUME '(' comma_expression ')' compound_statement
611 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
612 | IDENTIFIER IDENTIFIER // syntax error
613 {
614 SemanticError( yylloc, ::toString( "Adjacent identifiers are not meaningful in an expression. "
615 "Possible problem is identifier \"", *$1.str,
616 "\" is a misspelled typename or an incorrectly specified type name, "
617 "e.g., missing generic parameter or missing struct/union/enum before typename." ) );
618 $$ = nullptr;
619 }
620 | IDENTIFIER direct_type // syntax error
621 {
622 SemanticError( yylloc, ::toString( "Identifier \"", *$1.str, "\" cannot appear before a type. "
623 "Possible problem is misspelled storage or CV qualifier." ) );
624 $$ = nullptr;
625 }
626 ;
627
628generic_assoc_list: // C11
629 generic_association
630 | generic_assoc_list ',' generic_association
631 {
632 // steal the association node from the singleton and delete the wrapper
633 $1->associations.splice($1->associations.end(), $3->associations);
634 delete $3;
635 $$ = $1;
636 }
637 ;
638
639generic_association: // C11
640 type_no_function ':' assignment_expression
641 {
642 // create a GenericExpr wrapper with one association pair
643 $$ = new GenericExpr( nullptr, { { maybeMoveBuildType($1), maybeMoveBuild<Expression>( $3 ) } } );
644 }
645 | DEFAULT ':' assignment_expression
646 { $$ = new GenericExpr( nullptr, { { maybeMoveBuild<Expression>( $3 ) } } ); }
647 ;
648
649postfix_expression:
650 primary_expression
651 | postfix_expression '[' assignment_expression ',' tuple_expression_list ']'
652 // Historic, transitional: Disallow commas in subscripts.
653 // Switching to this behaviour may help check if a C compatibilty case uses comma-exprs in subscripts.
654 // { SemanticError( yylloc, "New array subscript is currently unimplemented." ); $$ = nullptr; }
655 // Current: Commas in subscripts make tuples.
656 { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, new ExpressionNode( build_tuple( (ExpressionNode *)($3->set_last( $5 ) ) )) ) ); }
657 | postfix_expression '[' assignment_expression ']'
658 // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
659 // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
660 // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
661 // equivalent to the old x[i,j].
662 { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
663 | postfix_expression '{' argument_expression_list_opt '}' // CFA, constructor call
664 {
665 Token fn;
666 fn.str = new std::string( "?{}" ); // location undefined - use location of '{'?
667 $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
668 }
669 | postfix_expression '(' argument_expression_list_opt ')'
670 { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
671 | postfix_expression '`' identifier // CFA, postfix call
672 { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
673 | constant '`' identifier // CFA, postfix call
674 { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
675 | string_literal '`' identifier // CFA, postfix call
676 { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), new ExpressionNode( $1 ) ) ); }
677 | postfix_expression '.' identifier
678 { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
679 | postfix_expression '.' INTEGERconstant // CFA, tuple index
680 { $$ = new ExpressionNode( build_fieldSel( $1, build_constantInteger( *$3 ) ) ); }
681 | postfix_expression FLOATING_FRACTIONconstant // CFA, tuple index
682 { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
683 | postfix_expression '.' '[' field_name_list ']' // CFA, tuple field selector
684 { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
685 | postfix_expression '.' aggregate_control
686 { $$ = new ExpressionNode( build_keyword_cast( $3, $1 ) ); }
687 | postfix_expression ARROW identifier
688 { $$ = new ExpressionNode( build_pfieldSel( $1, build_varref( $3 ) ) ); }
689 | postfix_expression ARROW INTEGERconstant // CFA, tuple index
690 { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
691 | postfix_expression ARROW '[' field_name_list ']' // CFA, tuple field selector
692 { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
693 | postfix_expression ICR
694 { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
695 | postfix_expression DECR
696 { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
697 | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
698 { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
699 | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
700 { $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
701 | '^' primary_expression '{' argument_expression_list_opt '}' // CFA, destructor call
702 {
703 Token fn;
704 fn.str = new string( "^?{}" ); // location undefined
705 $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
706 }
707 ;
708
709argument_expression_list_opt:
710 // empty
711 { $$ = nullptr; }
712 | argument_expression_list
713 ;
714
715argument_expression_list:
716 argument_expression
717 | argument_expression_list_opt ',' argument_expression
718 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
719 ;
720
721argument_expression:
722 '@' // CFA, default parameter
723 { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
724 // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
725 | assignment_expression
726 ;
727
728field_name_list: // CFA, tuple field selector
729 field
730 | field_name_list ',' field { $$ = (ExpressionNode *)($1->set_last( $3 )); }
731 ;
732
733field: // CFA, tuple field selector
734 field_name
735 | FLOATING_DECIMALconstant field
736 { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
737 | FLOATING_DECIMALconstant '[' field_name_list ']'
738 { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $3 ) ) ); }
739 | field_name '.' field
740 { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
741 | field_name '.' '[' field_name_list ']'
742 { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
743 | field_name ARROW field
744 { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
745 | field_name ARROW '[' field_name_list ']'
746 { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
747 ;
748
749field_name:
750 INTEGERconstant fraction_constants_opt
751 { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
752 | FLOATINGconstant fraction_constants_opt
753 { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
754 | identifier_at fraction_constants_opt // CFA, allow anonymous fields
755 {
756 $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
757 }
758 ;
759
760fraction_constants_opt:
761 // empty
762 { $$ = nullptr; }
763 | fraction_constants_opt FLOATING_FRACTIONconstant
764 {
765 Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
766 $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1, constant ) ) : new ExpressionNode( constant );
767 }
768 ;
769
770unary_expression:
771 postfix_expression
772 // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
773 // semantics checks, e.g., ++3, 3--, *3, &&3
774 | constant
775 | string_literal
776 { $$ = new ExpressionNode( $1 ); }
777 | EXTENSION cast_expression // GCC
778 { $$ = $2->set_extension( true ); }
779 // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
780 // { * X; } // dereference X
781 // { * int X; } // CFA declaration of pointer to int
782 | ptrref_operator cast_expression // CFA
783 {
784 switch ( $1 ) {
785 case OperKinds::AddressOf:
786 $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild<Expression>( $2 ) ) );
787 break;
788 case OperKinds::PointTo:
789 $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
790 break;
791 case OperKinds::And:
792 $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild<Expression>( $2 ) ) ) );
793 break;
794 default:
795 assert( false );
796 }
797 }
798 | unary_operator cast_expression
799 { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
800 | ICR unary_expression
801 { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
802 | DECR unary_expression
803 { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
804 | SIZEOF unary_expression
805 { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild<Expression>( $2 ) ) ); }
806 | SIZEOF '(' type_no_function ')'
807 { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
808 | ALIGNOF unary_expression // GCC, variable alignment
809 { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild<Expression>( $2 ) ) ); }
810 | ALIGNOF '(' type_no_function ')' // GCC, type alignment
811 { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
812 | OFFSETOF '(' type_no_function ',' identifier ')'
813 { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
814 | TYPEID '(' type_no_function ')'
815 {
816 SemanticError( yylloc, "typeid name is currently unimplemented." ); $$ = nullptr;
817 // $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) );
818 }
819 ;
820
821ptrref_operator:
822 '*' { $$ = OperKinds::PointTo; }
823 | '&' { $$ = OperKinds::AddressOf; }
824 // GCC, address of label must be handled by semantic check for ref,ref,label
825 | ANDAND { $$ = OperKinds::And; }
826 ;
827
828unary_operator:
829 '+' { $$ = OperKinds::UnPlus; }
830 | '-' { $$ = OperKinds::UnMinus; }
831 | '!' { $$ = OperKinds::Neg; }
832 | '~' { $$ = OperKinds::BitNeg; }
833 ;
834
835cast_expression:
836 unary_expression
837 | '(' type_no_function ')' cast_expression
838 { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
839 | '(' aggregate_control '&' ')' cast_expression // CFA
840 { $$ = new ExpressionNode( build_keyword_cast( $2, $5 ) ); }
841 | '(' aggregate_control '*' ')' cast_expression // CFA
842 { $$ = new ExpressionNode( build_keyword_cast( $2, $5 ) ); }
843 | '(' VIRTUAL ')' cast_expression // CFA
844 { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild<Expression>( $4 ), maybeMoveBuildType( nullptr ) ) ); }
845 | '(' VIRTUAL type_no_function ')' cast_expression // CFA
846 { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild<Expression>( $5 ), maybeMoveBuildType( $3 ) ) ); }
847 | '(' RETURN type_no_function ')' cast_expression // CFA
848 { SemanticError( yylloc, "Return cast is currently unimplemented." ); $$ = nullptr; }
849 | '(' COERCE type_no_function ')' cast_expression // CFA
850 { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
851 | '(' qualifier_cast_list ')' cast_expression // CFA
852 { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
853// | '(' type_no_function ')' tuple
854// { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
855 ;
856
857qualifier_cast_list:
858 cast_modifier type_qualifier_name
859 | cast_modifier MUTEX
860 | qualifier_cast_list cast_modifier type_qualifier_name
861 | qualifier_cast_list cast_modifier MUTEX
862 ;
863
864cast_modifier:
865 '-'
866 | '+'
867 ;
868
869exponential_expression:
870 cast_expression
871 | exponential_expression '\\' cast_expression
872 { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
873 ;
874
875multiplicative_expression:
876 exponential_expression
877 | multiplicative_expression '*' exponential_expression
878 { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
879 | multiplicative_expression '/' exponential_expression
880 { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
881 | multiplicative_expression '%' exponential_expression
882 { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
883 ;
884
885additive_expression:
886 multiplicative_expression
887 | additive_expression '+' multiplicative_expression
888 { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
889 | additive_expression '-' multiplicative_expression
890 { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
891 ;
892
893shift_expression:
894 additive_expression
895 | shift_expression LS additive_expression
896 { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
897 | shift_expression RS additive_expression
898 { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
899 ;
900
901relational_expression:
902 shift_expression
903 | relational_expression '<' shift_expression
904 { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
905 | relational_expression '>' shift_expression
906 { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
907 | relational_expression LE shift_expression
908 { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
909 | relational_expression GE shift_expression
910 { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
911 ;
912
913equality_expression:
914 relational_expression
915 | equality_expression EQ relational_expression
916 { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
917 | equality_expression NE relational_expression
918 { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
919 ;
920
921AND_expression:
922 equality_expression
923 | AND_expression '&' equality_expression
924 { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
925 ;
926
927exclusive_OR_expression:
928 AND_expression
929 | exclusive_OR_expression '^' AND_expression
930 { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
931 ;
932
933inclusive_OR_expression:
934 exclusive_OR_expression
935 | inclusive_OR_expression '|' exclusive_OR_expression
936 { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
937 ;
938
939logical_AND_expression:
940 inclusive_OR_expression
941 | logical_AND_expression ANDAND inclusive_OR_expression
942 { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
943 ;
944
945logical_OR_expression:
946 logical_AND_expression
947 | logical_OR_expression OROR logical_AND_expression
948 { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
949 ;
950
951conditional_expression:
952 logical_OR_expression
953 | logical_OR_expression '?' comma_expression ':' conditional_expression
954 { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
955 // FIX ME: computes $1 twice
956 | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
957 { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
958 ;
959
960constant_expression:
961 conditional_expression
962 ;
963
964assignment_expression:
965 // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
966 conditional_expression
967 | unary_expression assignment_operator assignment_expression
968 {
969// if ( $2 == OperKinds::AtAssn ) {
970// SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
971// } else {
972 $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) );
973// } // if
974 }
975 | unary_expression '=' '{' initializer_list_opt comma_opt '}'
976 { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
977 ;
978
979assignment_expression_opt:
980 // empty
981 { $$ = nullptr; }
982 | assignment_expression
983 ;
984
985assignment_operator:
986 simple_assignment_operator
987 | compound_assignment_operator
988 ;
989
990simple_assignment_operator:
991 '=' { $$ = OperKinds::Assign; }
992 | ATassign { $$ = OperKinds::AtAssn; } // CFA
993 ;
994
995compound_assignment_operator:
996 EXPassign { $$ = OperKinds::ExpAssn; }
997 | MULTassign { $$ = OperKinds::MulAssn; }
998 | DIVassign { $$ = OperKinds::DivAssn; }
999 | MODassign { $$ = OperKinds::ModAssn; }
1000 | PLUSassign { $$ = OperKinds::PlusAssn; }
1001 | MINUSassign { $$ = OperKinds::MinusAssn; }
1002 | LSassign { $$ = OperKinds::LSAssn; }
1003 | RSassign { $$ = OperKinds::RSAssn; }
1004 | ANDassign { $$ = OperKinds::AndAssn; }
1005 | ERassign { $$ = OperKinds::ERAssn; }
1006 | ORassign { $$ = OperKinds::OrAssn; }
1007 ;
1008
1009tuple: // CFA, tuple
1010 // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
1011 // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
1012// '[' ']'
1013// { $$ = new ExpressionNode( build_tuple() ); }
1014// | '[' push assignment_expression pop ']'
1015// { $$ = new ExpressionNode( build_tuple( $3 ) ); }
1016 '[' ',' tuple_expression_list ']'
1017 { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
1018 | '[' push assignment_expression pop ',' tuple_expression_list ']'
1019 { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)($3->set_last( $6 ) ) )); }
1020 ;
1021
1022tuple_expression_list:
1023 assignment_expression
1024 | '@' // CFA
1025 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1026 | tuple_expression_list ',' assignment_expression
1027 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1028 | tuple_expression_list ',' '@'
1029 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1030 ;
1031
1032comma_expression:
1033 assignment_expression
1034 | comma_expression ',' assignment_expression
1035 { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild<Expression>( $1 ), maybeMoveBuild<Expression>( $3 ) ) ); }
1036 ;
1037
1038comma_expression_opt:
1039 // empty
1040 { $$ = nullptr; }
1041 | comma_expression
1042 ;
1043
1044//*************************** STATEMENTS *******************************
1045
1046statement:
1047 labeled_statement
1048 | compound_statement
1049 | expression_statement
1050 | selection_statement
1051 | iteration_statement
1052 | jump_statement
1053 | with_statement
1054 | mutex_statement
1055 | waitfor_statement
1056 | exception_statement
1057 | enable_disable_statement
1058 { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1059 | asm_statement
1060 | DIRECTIVE
1061 { $$ = new StatementNode( build_directive( $1 ) ); }
1062 ;
1063
1064labeled_statement:
1065 // labels cannot be identifiers 0 or 1
1066 identifier_or_type_name ':' attribute_list_opt statement
1067 { $$ = $4->add_label( $1, $3 ); }
1068 | identifier_or_type_name ':' attribute_list_opt error // syntax error
1069 {
1070 SemanticError( yylloc, ::toString( "Label \"", *$1.str, "\" must be associated with a statement, "
1071 "where a declaration, case, or default is not a statement. "
1072 "Move the label or terminate with a semi-colon." ) );
1073 $$ = nullptr;
1074 }
1075 ;
1076
1077compound_statement:
1078 '{' '}'
1079 { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
1080 | '{' push
1081 local_label_declaration_opt // GCC, local labels appear at start of block
1082 statement_decl_list // C99, intermix declarations and statements
1083 pop '}'
1084 { $$ = new StatementNode( build_compound( $4 ) ); }
1085 ;
1086
1087statement_decl_list: // C99
1088 statement_decl
1089 | statement_decl_list statement_decl
1090 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1091 ;
1092
1093statement_decl:
1094 declaration // CFA, new & old style declarations
1095 { $$ = new StatementNode( $1 ); }
1096 | EXTENSION declaration // GCC
1097 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1098 | function_definition
1099 { $$ = new StatementNode( $1 ); }
1100 | EXTENSION function_definition // GCC
1101 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1102 | statement
1103 ;
1104
1105statement_list_nodecl:
1106 statement
1107 | statement_list_nodecl statement
1108 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1109 | statement_list_nodecl error // syntax error
1110 { SemanticError( yylloc, "Declarations only allowed at the start of the switch body, i.e., after the '{'." ); $$ = nullptr; }
1111 ;
1112
1113expression_statement:
1114 comma_expression_opt ';'
1115 { $$ = new StatementNode( build_expr( $1 ) ); }
1116 | MUTEX '(' ')' comma_expression ';'
1117 { $$ = new StatementNode( build_mutex( nullptr, new StatementNode( build_expr( $4 ) ) ) ); }
1118 ;
1119
1120selection_statement:
1121 // pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1122 // the inherent S/R conflict with THEN/ELSE.
1123 push if_statement pop
1124 { $$ = $2; }
1125 | SWITCH '(' comma_expression ')' case_clause
1126 { $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
1127 | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1128 {
1129 StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
1130 // The semantics of the declaration list is changed to include associated initialization, which is performed
1131 // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1132 // statement around the switch. Statements after the initial declaration list can never be executed, and
1133 // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1134 // statement.
1135 $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1136 }
1137 | SWITCH '(' comma_expression ')' '{' error '}' // CFA, syntax error
1138 { SemanticError( yylloc, "Only declarations can appear before the list of case clauses." ); $$ = nullptr; }
1139 | CHOOSE '(' comma_expression ')' case_clause // CFA
1140 { $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
1141 | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1142 {
1143 StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
1144 $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1145 }
1146 | CHOOSE '(' comma_expression ')' '{' error '}' // CFA, syntax error
1147 { SemanticError( yylloc, "Only declarations can appear before the list of case clauses." ); $$ = nullptr; }
1148 ;
1149
1150if_statement:
1151 IF '(' conditional_declaration ')' statement %prec THEN
1152 // explicitly deal with the shift/reduce conflict on if/else
1153 { $$ = new StatementNode( build_if( $3, maybe_build_compound( $5 ), nullptr ) ); }
1154 | IF '(' conditional_declaration ')' statement ELSE statement
1155 { $$ = new StatementNode( build_if( $3, maybe_build_compound( $5 ), maybe_build_compound( $7 ) ) ); }
1156 ;
1157
1158conditional_declaration:
1159 comma_expression
1160 { $$ = new CondCtl( nullptr, $1 ); }
1161 | c_declaration // no semi-colon
1162 { $$ = new CondCtl( $1, nullptr ); }
1163 | cfa_declaration // no semi-colon
1164 { $$ = new CondCtl( $1, nullptr ); }
1165 | declaration comma_expression // semi-colon separated
1166 { $$ = new CondCtl( $1, $2 ); }
1167 ;
1168
1169// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1170// clause allows a list of values and subranges.
1171
1172case_value: // CFA
1173 constant_expression { $$ = $1; }
1174 | constant_expression ELLIPSIS constant_expression // GCC, subrange
1175 { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild<Expression>( $1 ), maybeMoveBuild<Expression>( $3 ) ) ); }
1176 | subrange // CFA, subrange
1177 ;
1178
1179case_value_list: // CFA
1180 case_value { $$ = new StatementNode( build_case( $1 ) ); }
1181 // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1182 | case_value_list ',' case_value { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
1183 ;
1184
1185case_label: // CFA
1186 CASE error // syntax error
1187 { SemanticError( yylloc, "Missing case list after case." ); $$ = nullptr; }
1188 | CASE case_value_list ':' { $$ = $2; }
1189 | CASE case_value_list error // syntax error
1190 { SemanticError( yylloc, "Missing colon after case list." ); $$ = nullptr; }
1191 | DEFAULT ':' { $$ = new StatementNode( build_default() ); }
1192 // A semantic check is required to ensure only one default clause per switch/choose statement.
1193 | DEFAULT error // syntax error
1194 { SemanticError( yylloc, "Missing colon after default." ); $$ = nullptr; }
1195 ;
1196
1197case_label_list: // CFA
1198 case_label
1199 | case_label_list case_label { $$ = (StatementNode *)( $1->set_last( $2 )); }
1200 ;
1201
1202case_clause: // CFA
1203 case_label_list statement { $$ = $1->append_last_case( maybe_build_compound( $2 ) ); }
1204 ;
1205
1206switch_clause_list_opt: // CFA
1207 // empty
1208 { $$ = nullptr; }
1209 | switch_clause_list
1210 ;
1211
1212switch_clause_list: // CFA
1213 case_label_list statement_list_nodecl
1214 { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1215 | switch_clause_list case_label_list statement_list_nodecl
1216 { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1217 ;
1218
1219iteration_statement:
1220 WHILE '(' ')' statement // CFA => while ( 1 )
1221 { $$ = new StatementNode( build_while( new CondCtl( nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ), maybe_build_compound( $4 ) ) ); }
1222 | WHILE '(' conditional_declaration ')' statement %prec THEN
1223 { $$ = new StatementNode( build_while( $3, maybe_build_compound( $5 ) ) ); }
1224 | WHILE '(' conditional_declaration ')' statement ELSE statement // CFA
1225 { $$ = new StatementNode( build_while( $3, maybe_build_compound( $5 ), $7 ) ); }
1226 | DO statement WHILE '(' ')' ';' // CFA => do while( 1 )
1227 { $$ = new StatementNode( build_do_while( new ExpressionNode( build_constantInteger( *new string( "1" ) ) ), maybe_build_compound( $2 ) ) ); }
1228 | DO statement WHILE '(' comma_expression ')' ';' %prec THEN
1229 { $$ = new StatementNode( build_do_while( $5, maybe_build_compound( $2 ) ) ); }
1230 | DO statement WHILE '(' comma_expression ')' ELSE statement // CFA
1231 { $$ = new StatementNode( build_do_while( $5, maybe_build_compound( $2 ), $8 ) ); }
1232 | FOR '(' ')' statement // CFA => for ( ;; )
1233 { $$ = new StatementNode( build_for( new ForCtrl( (ExpressionNode * )nullptr, (ExpressionNode * )nullptr, (ExpressionNode * )nullptr ), maybe_build_compound( $4 ) ) ); }
1234 | FOR '(' for_control_expression_list ')' statement %prec THEN
1235 { $$ = new StatementNode( build_for( $3, maybe_build_compound( $5 ) ) ); }
1236 | FOR '(' for_control_expression_list ')' statement ELSE statement // CFA
1237 { $$ = new StatementNode( build_for( $3, maybe_build_compound( $5 ), $7 ) ); }
1238 ;
1239
1240for_control_expression_list:
1241 for_control_expression
1242 | for_control_expression_list ':' for_control_expression
1243 // ForCtrl + ForCtrl:
1244 // init + init => multiple declaration statements that are hoisted
1245 // condition + condition => (expression) && (expression)
1246 // change + change => (expression), (expression)
1247 {
1248 $1->init->set_last( $3->init );
1249 if ( $1->condition ) {
1250 if ( $3->condition ) {
1251 $1->condition->expr.reset( new LogicalExpr( $1->condition->expr.release(), $3->condition->expr.release(), true ) );
1252 } // if
1253 } else $1->condition = $3->condition;
1254 if ( $1->change ) {
1255 if ( $3->change ) {
1256 $1->change->expr.reset( new CommaExpr( $1->change->expr.release(), $3->change->expr.release() ) );
1257 } // if
1258 } else $1->change = $3->change;
1259 $$ = $1;
1260 }
1261 ;
1262
1263for_control_expression:
1264 ';' comma_expression_opt ';' comma_expression_opt
1265 { $$ = new ForCtrl( (ExpressionNode * )nullptr, $2, $4 ); }
1266 | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1267 { $$ = new ForCtrl( $1, $3, $5 ); }
1268 | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1269 { $$ = new ForCtrl( $1, $2, $4 ); }
1270
1271 | comma_expression // CFA
1272 { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1273 OperKinds::LThan, $1->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1274 | '=' comma_expression // CFA
1275 { $$ = forCtrl( $2, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1276 OperKinds::LEThan, $2->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1277 | comma_expression inclexcl comma_expression // CFA
1278 { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1279 | comma_expression inclexcl comma_expression '~' comma_expression // CFA
1280 { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, $5 ); }
1281 | comma_expression ';' // CFA
1282 { $$ = forCtrl( new ExpressionNode( build_constantInteger( *new string( "0u" ) ) ), $1, nullptr, OperKinds::LThan, nullptr, nullptr ); }
1283 | comma_expression ';' comma_expression // CFA
1284 { $$ = forCtrl( $3, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1285 OperKinds::LThan, $3->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1286 | comma_expression ';' '=' comma_expression // CFA
1287 { $$ = forCtrl( $4, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1288 OperKinds::LEThan, $4->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1289 | comma_expression ';' comma_expression inclexcl comma_expression // CFA
1290 { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1291 | comma_expression ';' comma_expression inclexcl comma_expression '~' comma_expression // CFA
1292 { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, $7 ); }
1293
1294 | comma_expression ';' TYPEDEFname // CFA, array type
1295 {
1296 SemanticError( yylloc, "Array interator is currently unimplemented." ); $$ = nullptr;
1297 $$ = forCtrl( new ExpressionNode( build_varref( $3 ) ), $1, nullptr, OperKinds::Range, nullptr, nullptr );
1298 }
1299
1300 // There is a S/R conflicit if ~ and -~ are factored out.
1301 | comma_expression ';' comma_expression '~' '@' // CFA
1302 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1303 | comma_expression ';' comma_expression ErangeDown '@' // CFA
1304 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1305 | comma_expression ';' comma_expression '~' '@' '~' comma_expression // CFA
1306 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, $7 ); }
1307 | comma_expression ';' comma_expression ErangeDown '@' '~' comma_expression // CFA
1308 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, $7 ); }
1309 | comma_expression ';' comma_expression '~' '@' '~' '@' // CFA
1310 { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, nullptr ); }
1311 ;
1312
1313inclexcl:
1314 '~'
1315 { $$ = OperKinds::LThan; }
1316 | ErangeUpEq
1317 { $$ = OperKinds::LEThan; }
1318 | ErangeDown
1319 { $$ = OperKinds::GThan; }
1320 | ErangeDownEq
1321 { $$ = OperKinds::GEThan; }
1322 ;
1323
1324jump_statement:
1325 GOTO identifier_or_type_name ';'
1326 { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1327 | GOTO '*' comma_expression ';' // GCC, computed goto
1328 // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1329 // whereas normal operator precedence yields goto (*i)+3;
1330 { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1331 // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1332 | fall_through_name ';' // CFA
1333 { $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1334 | fall_through_name identifier_or_type_name ';' // CFA
1335 { $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1336 | fall_through_name DEFAULT ';' // CFA
1337 { $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1338 | CONTINUE ';'
1339 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1340 { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1341 | CONTINUE identifier_or_type_name ';' // CFA, multi-level continue
1342 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1343 // the target of the transfer appears only at the start of an iteration statement.
1344 { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1345 | BREAK ';'
1346 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1347 { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1348 | BREAK identifier_or_type_name ';' // CFA, multi-level exit
1349 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1350 // the target of the transfer appears only at the start of an iteration statement.
1351 { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1352 | RETURN comma_expression_opt ';'
1353 { $$ = new StatementNode( build_return( $2 ) ); }
1354 | RETURN '{' initializer_list_opt comma_opt '}' ';'
1355 { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1356 | SUSPEND ';'
1357 { $$ = new StatementNode( build_suspend( nullptr ) ); }
1358 | SUSPEND compound_statement
1359 { $$ = new StatementNode( build_suspend( $2 ) ); }
1360 | SUSPEND COROUTINE ';'
1361 { $$ = new StatementNode( build_suspend( nullptr, SuspendStmt::Coroutine ) ); }
1362 | SUSPEND COROUTINE compound_statement
1363 { $$ = new StatementNode( build_suspend( $3, SuspendStmt::Coroutine ) ); }
1364 | SUSPEND GENERATOR ';'
1365 { $$ = new StatementNode( build_suspend( nullptr, SuspendStmt::Generator ) ); }
1366 | SUSPEND GENERATOR compound_statement
1367 { $$ = new StatementNode( build_suspend( $3, SuspendStmt::Generator ) ); }
1368 | THROW assignment_expression_opt ';' // handles rethrow
1369 { $$ = new StatementNode( build_throw( $2 ) ); }
1370 | THROWRESUME assignment_expression_opt ';' // handles reresume
1371 { $$ = new StatementNode( build_resume( $2 ) ); }
1372 | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1373 { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1374 ;
1375
1376fall_through_name: // CFA
1377 FALLTHRU
1378 | FALLTHROUGH
1379 ;
1380
1381with_statement:
1382 WITH '(' tuple_expression_list ')' statement
1383 { $$ = new StatementNode( build_with( $3, $5 ) ); }
1384 ;
1385
1386// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1387mutex_statement:
1388 MUTEX '(' argument_expression_list ')' statement
1389 { $$ = new StatementNode( build_mutex( $3, $5 ) ); }
1390 ;
1391
1392when_clause:
1393 WHEN '(' comma_expression ')' { $$ = $3; }
1394 ;
1395
1396when_clause_opt:
1397 // empty
1398 { $$ = nullptr; }
1399 | when_clause
1400 ;
1401
1402waitfor:
1403 WAITFOR '(' cast_expression ')'
1404 { $$ = $3; }
1405// | WAITFOR '(' cast_expression ',' argument_expression_list_opt ')'
1406// { $$ = (ExpressionNode *)$3->set_last( $5 ); }
1407 | WAITFOR '(' cast_expression_list ':' argument_expression_list_opt ')'
1408 { $$ = (ExpressionNode *)($3->set_last( $5 )); }
1409 ;
1410
1411cast_expression_list:
1412 cast_expression
1413 | cast_expression_list ',' cast_expression
1414 // { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1415 { SemanticError( yylloc, "List of mutex member is currently unimplemented." ); $$ = nullptr; }
1416 ;
1417
1418timeout:
1419 TIMEOUT '(' comma_expression ')' { $$ = $3; }
1420 ;
1421
1422waitfor_clause:
1423 when_clause_opt waitfor statement %prec THEN
1424 { $$ = build_waitfor( $2, maybe_build_compound( $3 ), $1 ); }
1425 | when_clause_opt waitfor statement WOR waitfor_clause
1426 { $$ = build_waitfor( $2, maybe_build_compound( $3 ), $1, $5 ); }
1427 | when_clause_opt timeout statement %prec THEN
1428 { $$ = build_waitfor_timeout( $2, maybe_build_compound( $3 ), $1 ); }
1429 | when_clause_opt ELSE statement
1430 { $$ = build_waitfor_timeout( nullptr, maybe_build_compound( $3 ), $1 ); }
1431 // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1432 | when_clause_opt timeout statement WOR ELSE statement // syntax error
1433 { SemanticError( yylloc, "else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1434 | when_clause_opt timeout statement WOR when_clause ELSE statement
1435 { $$ = build_waitfor_timeout( $2, maybe_build_compound( $3 ), $1, maybe_build_compound( $7 ), $5 ); }
1436 ;
1437
1438waitfor_statement:
1439 when_clause_opt waitfor statement %prec THEN
1440 { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1441 | when_clause_opt waitfor statement WOR waitfor_clause
1442 { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1443 ;
1444
1445exception_statement:
1446 TRY compound_statement handler_clause %prec THEN
1447 { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1448 | TRY compound_statement finally_clause
1449 { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1450 | TRY compound_statement handler_clause finally_clause
1451 { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1452 ;
1453
1454handler_clause:
1455 handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1456 { $$ = new StatementNode( build_catch( $1, $4, $6, $8 ) ); }
1457 | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1458 { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $5, $7, $9 ) ) ); }
1459 ;
1460
1461handler_predicate_opt:
1462 // empty
1463 { $$ = nullptr; }
1464 | ';' conditional_expression { $$ = $2; }
1465 ;
1466
1467handler_key:
1468 CATCH { $$ = CatchStmt::Terminate; }
1469 | RECOVER { $$ = CatchStmt::Terminate; }
1470 | CATCHRESUME { $$ = CatchStmt::Resume; }
1471 | FIXUP { $$ = CatchStmt::Resume; }
1472 ;
1473
1474finally_clause:
1475 FINALLY compound_statement { $$ = new StatementNode( build_finally( $2 ) ); }
1476 ;
1477
1478exception_declaration:
1479 // No SUE declaration in parameter list.
1480 type_specifier_nobody
1481 | type_specifier_nobody declarator
1482 { $$ = $2->addType( $1 ); }
1483 | type_specifier_nobody variable_abstract_declarator
1484 { $$ = $2->addType( $1 ); }
1485 | cfa_abstract_declarator_tuple identifier // CFA
1486 { $$ = $1->addName( $2 ); }
1487 | cfa_abstract_declarator_tuple // CFA
1488 ;
1489
1490enable_disable_statement:
1491 enable_disable_key identifier_list compound_statement
1492 ;
1493
1494enable_disable_key:
1495 ENABLE
1496 | DISABLE
1497 ;
1498
1499asm_statement:
1500 ASM asm_volatile_opt '(' string_literal ')' ';'
1501 { $$ = new StatementNode( build_asm( $2, $4, 0 ) ); }
1502 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1503 { $$ = new StatementNode( build_asm( $2, $4, $6 ) ); }
1504 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1505 { $$ = new StatementNode( build_asm( $2, $4, $6, $8 ) ); }
1506 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1507 { $$ = new StatementNode( build_asm( $2, $4, $6, $8, $10 ) ); }
1508 | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1509 { $$ = new StatementNode( build_asm( $2, $5, 0, $8, $10, $12 ) ); }
1510 ;
1511
1512asm_volatile_opt: // GCC
1513 // empty
1514 { $$ = false; }
1515 | VOLATILE
1516 { $$ = true; }
1517 ;
1518
1519asm_operands_opt: // GCC
1520 // empty
1521 { $$ = nullptr; } // use default argument
1522 | asm_operands_list
1523 ;
1524
1525asm_operands_list: // GCC
1526 asm_operand
1527 | asm_operands_list ',' asm_operand
1528 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1529 ;
1530
1531asm_operand: // GCC
1532 string_literal '(' constant_expression ')'
1533 { $$ = new ExpressionNode( new AsmExpr( nullptr, $1, maybeMoveBuild<Expression>( $3 ) ) ); }
1534 | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1535 { $$ = new ExpressionNode( new AsmExpr( $2, $4, maybeMoveBuild<Expression>( $6 ) ) ); }
1536 ;
1537
1538asm_clobbers_list_opt: // GCC
1539 // empty
1540 { $$ = nullptr; } // use default argument
1541 | string_literal
1542 { $$ = new ExpressionNode( $1 ); }
1543 | asm_clobbers_list_opt ',' string_literal
1544 { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( $3 ) )); }
1545 ;
1546
1547label_list:
1548 identifier
1549 {
1550 $$ = new LabelNode(); $$->labels.push_back( *$1 );
1551 delete $1; // allocated by lexer
1552 }
1553 | label_list ',' identifier
1554 {
1555 $$ = $1; $1->labels.push_back( *$3 );
1556 delete $3; // allocated by lexer
1557 }
1558 ;
1559
1560//******************************* DECLARATIONS *********************************
1561
1562declaration_list_opt: // used at beginning of switch statement
1563 // empty
1564 { $$ = nullptr; }
1565 | declaration_list
1566 ;
1567
1568declaration_list:
1569 declaration
1570 | declaration_list declaration
1571 { $$ = $1->appendList( $2 ); }
1572 ;
1573
1574KR_parameter_list_opt: // used to declare parameter types in K&R style functions
1575 // empty
1576 { $$ = nullptr; }
1577 | KR_parameter_list
1578 ;
1579
1580KR_parameter_list:
1581 push c_declaration pop ';'
1582 { $$ = $2; }
1583 | KR_parameter_list push c_declaration pop ';'
1584 { $$ = $1->appendList( $3 ); }
1585 ;
1586
1587local_label_declaration_opt: // GCC, local label
1588 // empty
1589 | local_label_declaration_list
1590 ;
1591
1592local_label_declaration_list: // GCC, local label
1593 LABEL local_label_list ';'
1594 | local_label_declaration_list LABEL local_label_list ';'
1595 ;
1596
1597local_label_list: // GCC, local label
1598 identifier_or_type_name
1599 | local_label_list ',' identifier_or_type_name
1600 ;
1601
1602declaration: // old & new style declarations
1603 c_declaration ';'
1604 | cfa_declaration ';' // CFA
1605 | static_assert // C11
1606 ;
1607
1608static_assert:
1609 STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1610 { $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1611 | STATICASSERT '(' constant_expression ')' ';' // CFA
1612 { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( *new string( "\"\"" ) ) ); }
1613
1614// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1615// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1616// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1617// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1618// the declaration list (as in Pascal). ANSI C and the new CFA declarations may appear together in the same program
1619// block, but cannot be mixed within a specific declaration.
1620//
1621// CFA C
1622// [10] int x; int x[10]; // array of 10 integers
1623// [10] * char y; char *y[10]; // array of 10 pointers to char
1624
1625cfa_declaration: // CFA
1626 cfa_variable_declaration
1627 | cfa_typedef_declaration
1628 | cfa_function_declaration
1629 | type_declaring_list
1630 { SemanticError( yylloc, "otype declaration is currently unimplemented." ); $$ = nullptr; }
1631 | trait_specifier
1632 ;
1633
1634cfa_variable_declaration: // CFA
1635 cfa_variable_specifier initializer_opt
1636 { $$ = $1->addInitializer( $2 ); }
1637 | declaration_qualifier_list cfa_variable_specifier initializer_opt
1638 // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1639 // them as a type_qualifier cannot appear in that context.
1640 { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1641 | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1642 { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1643 ;
1644
1645cfa_variable_specifier: // CFA
1646 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1647 // storage-class
1648 cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1649 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1650 | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1651 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1652 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1653 { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1654 ;
1655
1656cfa_function_declaration: // CFA
1657 cfa_function_specifier
1658 | type_qualifier_list cfa_function_specifier
1659 { $$ = $2->addQualifiers( $1 ); }
1660 | declaration_qualifier_list cfa_function_specifier
1661 { $$ = $2->addQualifiers( $1 ); }
1662 | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1663 { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1664 | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1665 {
1666 // Append the return type at the start (left-hand-side) to each identifier in the list.
1667 DeclarationNode * ret = new DeclarationNode;
1668 ret->type = maybeClone( $1->type->base );
1669 $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1670 }
1671 ;
1672
1673cfa_function_specifier: // CFA
1674// '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1675// {
1676// $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1677// }
1678// '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1679// {
1680// typedefTable.setNextIdentifier( *$5 );
1681// $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1682// }
1683// | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1684// {
1685// typedefTable.setNextIdentifier( *$5 );
1686// $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1687// }
1688// | '[' ']' typegen_name
1689 // identifier_or_type_name must be broken apart because of the sequence:
1690 //
1691 // '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1692 // '[' ']' type_specifier
1693 //
1694 // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1695 // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1696 cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1697 // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1698 { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1699 | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1700 { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1701 ;
1702
1703cfa_function_return: // CFA
1704 '[' push cfa_parameter_list pop ']'
1705 { $$ = DeclarationNode::newTuple( $3 ); }
1706 | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1707 // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
1708 { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1709 ;
1710
1711cfa_typedef_declaration: // CFA
1712 TYPEDEF cfa_variable_specifier
1713 {
1714 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "1" );
1715 $$ = $2->addTypedef();
1716 }
1717 | TYPEDEF cfa_function_specifier
1718 {
1719 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "2" );
1720 $$ = $2->addTypedef();
1721 }
1722 | cfa_typedef_declaration pop ',' push identifier
1723 {
1724 typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "3" );
1725 $$ = $1->appendList( $1->cloneType( $5 ) );
1726 }
1727 ;
1728
1729// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1730// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1731
1732typedef_declaration:
1733 TYPEDEF type_specifier declarator
1734 {
1735 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "4" );
1736 $$ = $3->addType( $2 )->addTypedef();
1737 }
1738 | typedef_declaration pop ',' push declarator
1739 {
1740 typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname, "5" );
1741 $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1742 }
1743 | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1744 {
1745 typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "6" );
1746 $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1747 }
1748 | type_specifier TYPEDEF declarator
1749 {
1750 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "7" );
1751 $$ = $3->addType( $1 )->addTypedef();
1752 }
1753 | type_specifier TYPEDEF type_qualifier_list declarator
1754 {
1755 typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "8" );
1756 $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1757 }
1758 ;
1759
1760typedef_expression:
1761 // deprecated GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1762 TYPEDEF identifier '=' assignment_expression
1763 {
1764 SemanticError( yylloc, "Typedef expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
1765 }
1766 | typedef_expression pop ',' push identifier '=' assignment_expression
1767 {
1768 SemanticError( yylloc, "Typedef expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
1769 }
1770 ;
1771
1772c_declaration:
1773 declaration_specifier declaring_list
1774 { $$ = distAttr( $1, $2 ); }
1775 | typedef_declaration
1776 | typedef_expression // deprecated GCC, naming expression type
1777 | sue_declaration_specifier
1778 ;
1779
1780declaring_list:
1781 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1782 // storage-class
1783 declarator asm_name_opt initializer_opt
1784 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
1785 | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1786 { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
1787 ;
1788
1789declaration_specifier: // type specifier + storage class
1790 basic_declaration_specifier
1791 | sue_declaration_specifier
1792 | type_declaration_specifier
1793 ;
1794
1795declaration_specifier_nobody: // type specifier + storage class - {...}
1796 // Preclude SUE declarations in restricted scopes:
1797 //
1798 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1799 //
1800 // because it is impossible to call f due to name equivalence.
1801 basic_declaration_specifier
1802 | sue_declaration_specifier_nobody
1803 | type_declaration_specifier
1804 ;
1805
1806type_specifier: // type specifier
1807 basic_type_specifier
1808 | sue_type_specifier
1809 | type_type_specifier
1810 ;
1811
1812type_specifier_nobody: // type specifier - {...}
1813 // Preclude SUE declarations in restricted scopes:
1814 //
1815 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1816 //
1817 // because it is impossible to call f due to name equivalence.
1818 basic_type_specifier
1819 | sue_type_specifier_nobody
1820 | type_type_specifier
1821 ;
1822
1823type_qualifier_list_opt: // GCC, used in asm_statement
1824 // empty
1825 { $$ = nullptr; }
1826 | type_qualifier_list
1827 ;
1828
1829type_qualifier_list:
1830 // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1831 //
1832 // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1833 // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1834 // appeared only once.
1835 type_qualifier
1836 | type_qualifier_list type_qualifier
1837 { $$ = $1->addQualifiers( $2 ); }
1838 ;
1839
1840type_qualifier:
1841 type_qualifier_name
1842 | attribute // trick handles most atrribute locations
1843 ;
1844
1845type_qualifier_name:
1846 CONST
1847 { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1848 | RESTRICT
1849 { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1850 | VOLATILE
1851 { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1852 | ATOMIC
1853 { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1854 | forall
1855 ;
1856
1857forall:
1858 FORALL '(' type_parameter_list ')' // CFA
1859 { $$ = DeclarationNode::newForall( $3 ); }
1860 ;
1861
1862declaration_qualifier_list:
1863 storage_class_list
1864 | type_qualifier_list storage_class_list // remaining OBSOLESCENT (see 2 )
1865 { $$ = $1->addQualifiers( $2 ); }
1866 | declaration_qualifier_list type_qualifier_list storage_class_list
1867 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1868 ;
1869
1870storage_class_list:
1871 // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1872 // only one of each is specified, except for inline, which can appear with the others.
1873 //
1874 // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1875 // specifiers in a declaration.
1876 storage_class
1877 | storage_class_list storage_class
1878 { $$ = $1->addQualifiers( $2 ); }
1879 ;
1880
1881storage_class:
1882 EXTERN
1883 { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1884 | STATIC
1885 { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1886 | AUTO
1887 { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1888 | REGISTER
1889 { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1890 | THREADLOCAL // C11
1891 { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1892 // Put function specifiers here to simplify parsing rules, but separate them semantically.
1893 | INLINE // C99
1894 { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1895 | FORTRAN // C99
1896 { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1897 | NORETURN // C11
1898 { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1899 ;
1900
1901basic_type_name:
1902 VOID
1903 { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1904 | BOOL // C99
1905 { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1906 | CHAR
1907 { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1908 | INT
1909 { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1910 | INT128
1911 { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1912 | UINT128
1913 { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 )->addType( DeclarationNode::newSignedNess( DeclarationNode::Unsigned ) ); }
1914 | FLOAT
1915 { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1916 | DOUBLE
1917 { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1918 | uuFLOAT80
1919 { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
1920 | uuFLOAT128
1921 { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
1922 | uFLOAT16
1923 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
1924 | uFLOAT32
1925 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
1926 | uFLOAT32X
1927 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
1928 | uFLOAT64
1929 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
1930 | uFLOAT64X
1931 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
1932 | uFLOAT128
1933 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
1934 | DECIMAL32
1935 { SemanticError( yylloc, "_Decimal32 is currently unimplemented." ); $$ = nullptr; }
1936 | DECIMAL64
1937 { SemanticError( yylloc, "_Decimal64 is currently unimplemented." ); $$ = nullptr; }
1938 | DECIMAL128
1939 { SemanticError( yylloc, "_Decimal128 is currently unimplemented." ); $$ = nullptr; }
1940 | COMPLEX // C99
1941 { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1942 | IMAGINARY // C99
1943 { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1944 | SIGNED
1945 { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1946 | UNSIGNED
1947 { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1948 | SHORT
1949 { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1950 | LONG
1951 { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1952 | VALIST // GCC, __builtin_va_list
1953 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1954 | AUTO_TYPE
1955 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::AutoType ); }
1956 | vtable
1957 ;
1958
1959vtable_opt:
1960 // empty
1961 { $$ = nullptr; }
1962 | vtable
1963 ;
1964
1965vtable:
1966 VTABLE '(' type_name ')' default_opt
1967 { $$ = DeclarationNode::newVtableType( $3 ); }
1968 // { SemanticError( yylloc, "vtable is currently unimplemented." ); $$ = nullptr; }
1969 ;
1970
1971default_opt:
1972 // empty
1973 { $$ = nullptr; }
1974 | DEFAULT
1975 { SemanticError( yylloc, "vtable default is currently unimplemented." ); $$ = nullptr; }
1976 ;
1977
1978basic_declaration_specifier:
1979 // A semantic check is necessary for conflicting storage classes.
1980 basic_type_specifier
1981 | declaration_qualifier_list basic_type_specifier
1982 { $$ = $2->addQualifiers( $1 ); }
1983 | basic_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1984 { $$ = $1->addQualifiers( $2 ); }
1985 | basic_declaration_specifier storage_class type_qualifier_list
1986 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1987 | basic_declaration_specifier storage_class basic_type_specifier
1988 { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1989 ;
1990
1991basic_type_specifier:
1992 direct_type
1993 // Cannot have type modifiers, e.g., short, long, etc.
1994 | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1995 { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1996 ;
1997
1998direct_type:
1999 basic_type_name
2000 | type_qualifier_list basic_type_name
2001 { $$ = $2->addQualifiers( $1 ); }
2002 | direct_type type_qualifier
2003 { $$ = $1->addQualifiers( $2 ); }
2004 | direct_type basic_type_name
2005 { $$ = $1->addType( $2 ); }
2006 ;
2007
2008indirect_type:
2009 TYPEOF '(' type ')' // GCC: typeof( x ) y;
2010 { $$ = $3; }
2011 | TYPEOF '(' comma_expression ')' // GCC: typeof( a+b ) y;
2012 { $$ = DeclarationNode::newTypeof( $3 ); }
2013 | BASETYPEOF '(' type ')' // CFA: basetypeof( x ) y;
2014 { $$ = DeclarationNode::newTypeof( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ), true ); }
2015 | BASETYPEOF '(' comma_expression ')' // CFA: basetypeof( a+b ) y;
2016 { $$ = DeclarationNode::newTypeof( $3, true ); }
2017 | ZERO_T // CFA
2018 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
2019 | ONE_T // CFA
2020 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
2021 ;
2022
2023sue_declaration_specifier: // struct, union, enum + storage class + type specifier
2024 sue_type_specifier
2025 | declaration_qualifier_list sue_type_specifier
2026 { $$ = $2->addQualifiers( $1 ); }
2027 | sue_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2028 { $$ = $1->addQualifiers( $2 ); }
2029 | sue_declaration_specifier storage_class type_qualifier_list
2030 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2031 ;
2032
2033sue_type_specifier: // struct, union, enum + type specifier
2034 elaborated_type
2035 | type_qualifier_list
2036 { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
2037 elaborated_type
2038 { $$ = $3->addQualifiers( $1 ); }
2039 | sue_type_specifier type_qualifier
2040 {
2041 if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
2042 $$ = $1->addQualifiers( $2 );
2043 }
2044 ;
2045
2046sue_declaration_specifier_nobody: // struct, union, enum - {...} + storage class + type specifier
2047 sue_type_specifier_nobody
2048 | declaration_qualifier_list sue_type_specifier_nobody
2049 { $$ = $2->addQualifiers( $1 ); }
2050 | sue_declaration_specifier_nobody storage_class // remaining OBSOLESCENT (see 2)
2051 { $$ = $1->addQualifiers( $2 ); }
2052 | sue_declaration_specifier_nobody storage_class type_qualifier_list
2053 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2054 ;
2055
2056sue_type_specifier_nobody: // struct, union, enum - {...} + type specifier
2057 elaborated_type_nobody
2058 | type_qualifier_list elaborated_type_nobody
2059 { $$ = $2->addQualifiers( $1 ); }
2060 | sue_type_specifier_nobody type_qualifier
2061 { $$ = $1->addQualifiers( $2 ); }
2062 ;
2063
2064type_declaration_specifier:
2065 type_type_specifier
2066 | declaration_qualifier_list type_type_specifier
2067 { $$ = $2->addQualifiers( $1 ); }
2068 | type_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2069 { $$ = $1->addQualifiers( $2 ); }
2070 | type_declaration_specifier storage_class type_qualifier_list
2071 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2072 ;
2073
2074type_type_specifier: // typedef types
2075 type_name
2076 | type_qualifier_list type_name
2077 { $$ = $2->addQualifiers( $1 ); }
2078 | type_type_specifier type_qualifier
2079 { $$ = $1->addQualifiers( $2 ); }
2080 ;
2081
2082type_name:
2083 TYPEDEFname
2084 { $$ = DeclarationNode::newFromTypedef( $1 ); }
2085 | '.' TYPEDEFname
2086 { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
2087 | type_name '.' TYPEDEFname
2088 { $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
2089 | typegen_name
2090 | '.' typegen_name
2091 { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
2092 | type_name '.' typegen_name
2093 { $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
2094 ;
2095
2096typegen_name: // CFA
2097 TYPEGENname
2098 { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2099 | TYPEGENname '(' ')'
2100 { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2101 | TYPEGENname '(' type_list ')'
2102 { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
2103 ;
2104
2105elaborated_type: // struct, union, enum
2106 aggregate_type
2107 | enum_type
2108 ;
2109
2110elaborated_type_nobody: // struct, union, enum - {...}
2111 aggregate_type_nobody
2112 | enum_type_nobody
2113 ;
2114
2115aggregate_type: // struct, union
2116 aggregate_key attribute_list_opt
2117 { forall = false; } // reset
2118 '{' field_declaration_list_opt '}' type_parameters_opt
2119 { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2120 | aggregate_key attribute_list_opt identifier
2121 {
2122 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2123 forall = false; // reset
2124 }
2125 '{' field_declaration_list_opt '}' type_parameters_opt
2126 { $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 ); }
2127 | aggregate_key attribute_list_opt TYPEDEFname // unqualified type name
2128 {
2129 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2130 forall = false; // reset
2131 }
2132 '{' field_declaration_list_opt '}' type_parameters_opt
2133 {
2134 DeclarationNode::newFromTypedef( $3 );
2135 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2136 }
2137 | aggregate_key attribute_list_opt TYPEGENname // unqualified type name
2138 {
2139 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2140 forall = false; // reset
2141 }
2142 '{' field_declaration_list_opt '}' type_parameters_opt
2143 {
2144 DeclarationNode::newFromTypeGen( $3, nullptr );
2145 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2146 }
2147 | aggregate_type_nobody
2148 ;
2149
2150type_parameters_opt:
2151 // empty
2152 { $$ = nullptr; } %prec '}'
2153 | '(' type_list ')'
2154 { $$ = $2; }
2155 ;
2156
2157aggregate_type_nobody: // struct, union - {...}
2158 aggregate_key attribute_list_opt identifier
2159 {
2160 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname );
2161 forall = false; // reset
2162 $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2163 }
2164 | aggregate_key attribute_list_opt type_name
2165 {
2166 forall = false; // reset
2167 // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2168 // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2169 // delete newFromTypeGen.
2170 $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2171 $3->type->symbolic.name = nullptr;
2172 $3->type->symbolic.actuals = nullptr;
2173 delete $3;
2174 }
2175 ;
2176
2177aggregate_key:
2178 aggregate_data
2179 | aggregate_control
2180 ;
2181
2182aggregate_data:
2183 STRUCT vtable_opt
2184 { $$ = AggregateDecl::Struct; }
2185 | UNION
2186 { $$ = AggregateDecl::Union; }
2187 | EXCEPTION // CFA
2188 { $$ = AggregateDecl::Exception; }
2189 // { SemanticError( yylloc, "exception aggregate is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2190 ;
2191
2192aggregate_control: // CFA
2193 MONITOR
2194 { $$ = AggregateDecl::Monitor; }
2195 | MUTEX STRUCT
2196 { $$ = AggregateDecl::Monitor; }
2197 | GENERATOR
2198 { $$ = AggregateDecl::Generator; }
2199 | MUTEX GENERATOR
2200 { SemanticError( yylloc, "monitor generator is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2201 | COROUTINE
2202 { $$ = AggregateDecl::Coroutine; }
2203 | MUTEX COROUTINE
2204 { SemanticError( yylloc, "monitor coroutine is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2205 | THREAD
2206 { $$ = AggregateDecl::Thread; }
2207 | MUTEX THREAD
2208 { SemanticError( yylloc, "monitor thread is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2209 ;
2210
2211field_declaration_list_opt:
2212 // empty
2213 { $$ = nullptr; }
2214 | field_declaration_list_opt field_declaration
2215 { $$ = $1 ? $1->appendList( $2 ) : $2; }
2216 ;
2217
2218field_declaration:
2219 type_specifier field_declaring_list_opt ';'
2220 { $$ = fieldDecl( $1, $2 ); }
2221 | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2222 { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2223 | INLINE type_specifier field_abstract_list_opt ';' // CFA
2224 {
2225 if ( ! $3 ) { // field declarator ?
2226 $3 = DeclarationNode::newName( nullptr );
2227 } // if
2228 $3->inLine = true;
2229 $$ = distAttr( $2, $3 ); // mark all fields in list
2230 distInl( $3 );
2231 }
2232 | INLINE aggregate_control ';' // CFA
2233 { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2234 | typedef_declaration ';' // CFA
2235 | cfa_field_declaring_list ';' // CFA, new style field declaration
2236 | EXTENSION cfa_field_declaring_list ';' // GCC
2237 { distExt( $2 ); $$ = $2; } // mark all fields in list
2238 | INLINE cfa_field_abstract_list ';' // CFA, new style field declaration
2239 { $$ = $2; } // mark all fields in list
2240 | cfa_typedef_declaration ';' // CFA
2241 | static_assert // C11
2242 ;
2243
2244field_declaring_list_opt:
2245 // empty
2246 { $$ = nullptr; }
2247 | field_declarator
2248 | field_declaring_list_opt ',' attribute_list_opt field_declarator
2249 { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2250 ;
2251
2252field_declarator:
2253 bit_subrange_size // C special case, no field name
2254 { $$ = DeclarationNode::newBitfield( $1 ); }
2255 | variable_declarator bit_subrange_size_opt
2256 // A semantic check is required to ensure bit_subrange only appears on integral types.
2257 { $$ = $1->addBitfield( $2 ); }
2258 | variable_type_redeclarator bit_subrange_size_opt
2259 // A semantic check is required to ensure bit_subrange only appears on integral types.
2260 { $$ = $1->addBitfield( $2 ); }
2261 ;
2262
2263field_abstract_list_opt:
2264 // empty
2265 { $$ = nullptr; }
2266 | field_abstract
2267 | field_abstract_list_opt ',' attribute_list_opt field_abstract
2268 { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2269 ;
2270
2271field_abstract:
2272 // no bit fields
2273 variable_abstract_declarator
2274 ;
2275
2276cfa_field_declaring_list: // CFA, new style field declaration
2277 // bit-fields are handled by C declarations
2278 cfa_abstract_declarator_tuple identifier_or_type_name
2279 { $$ = $1->addName( $2 ); }
2280 | cfa_field_declaring_list ',' identifier_or_type_name
2281 { $$ = $1->appendList( $1->cloneType( $3 ) ); }
2282 ;
2283
2284cfa_field_abstract_list: // CFA, new style field declaration
2285 // bit-fields are handled by C declarations
2286 cfa_abstract_declarator_tuple
2287 | cfa_field_abstract_list ','
2288 { $$ = $1->appendList( $1->cloneType( 0 ) ); }
2289 ;
2290
2291bit_subrange_size_opt:
2292 // empty
2293 { $$ = nullptr; }
2294 | bit_subrange_size
2295 ;
2296
2297bit_subrange_size:
2298 ':' assignment_expression
2299 { $$ = $2; }
2300 ;
2301
2302enum_type: // enum
2303 ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2304 { $$ = DeclarationNode::newEnum( nullptr, $4, true )->addQualifiers( $2 ); }
2305 | ENUM attribute_list_opt identifier
2306 { typedefTable.makeTypedef( *$3 ); }
2307 '{' enumerator_list comma_opt '}'
2308 { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
2309 | ENUM attribute_list_opt typedef_name // unqualified type name
2310 '{' enumerator_list comma_opt '}'
2311 { $$ = DeclarationNode::newEnum( $3->name, $5, true )->addQualifiers( $2 ); }
2312 | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt '{' enumerator_list comma_opt '}'
2313 {
2314 if ( $3->storageClasses.val != 0 || $3->type->qualifiers.val != 0 ) { SemanticError( yylloc, "storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." ); }
2315 SemanticError( yylloc, "Typed enumeration is currently unimplemented." ); $$ = nullptr;
2316 }
2317 | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt identifier attribute_list_opt
2318 {
2319 if ( $3->storageClasses.val != 0 || $3->type->qualifiers.val != 0 ) { SemanticError( yylloc, "storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." ); }
2320 typedefTable.makeTypedef( *$6 );
2321 }
2322 '{' enumerator_list comma_opt '}'
2323 {
2324 SemanticError( yylloc, "Typed enumeration is currently unimplemented." ); $$ = nullptr;
2325 }
2326 | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt typedef_name attribute_list_opt '{' enumerator_list comma_opt '}'
2327 {
2328 if ( $3->storageClasses.val != 0 || $3->type->qualifiers.val != 0 ) { SemanticError( yylloc, "storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." ); }
2329 typedefTable.makeTypedef( *$6->name );
2330 SemanticError( yylloc, "Typed enumeration is currently unimplemented." ); $$ = nullptr;
2331 }
2332 | enum_type_nobody
2333 ;
2334
2335enum_type_nobody: // enum - {...}
2336 ENUM attribute_list_opt identifier
2337 { typedefTable.makeTypedef( *$3 ); $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 ); }
2338 | ENUM attribute_list_opt type_name // qualified type name
2339 { typedefTable.makeTypedef( *$3->type->symbolic.name ); $$ = DeclarationNode::newEnum( $3->type->symbolic.name, 0, false )->addQualifiers( $2 ); }
2340 ;
2341
2342enumerator_list:
2343 identifier_or_type_name enumerator_value_opt
2344 { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
2345 | INLINE type_name
2346 { $$ = DeclarationNode::newEnumConstant( new string("inline"), nullptr ); }
2347 | enumerator_list ',' identifier_or_type_name enumerator_value_opt
2348 { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
2349 | enumerator_list ',' INLINE type_name enumerator_value_opt
2350 { $$ = $1->appendList( DeclarationNode::newEnumConstant( new string("inline"), nullptr ) ); }
2351 ;
2352
2353enumerator_value_opt:
2354 // empty
2355 { $$ = nullptr; }
2356 // | '=' constant_expression
2357 // { $$ = $2; }
2358 | simple_assignment_operator initializer
2359 { $$ = $2->get_expression(); } // FIX ME: enum only deals with constant_expression
2360 ;
2361
2362cfa_parameter_ellipsis_list_opt: // CFA, abstract + real
2363 // empty
2364 { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2365 | ELLIPSIS
2366 { $$ = nullptr; }
2367 | cfa_abstract_parameter_list
2368 | cfa_parameter_list
2369 | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2370 { $$ = $1->appendList( $5 ); }
2371 | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2372 { $$ = $1->addVarArgs(); }
2373 | cfa_parameter_list pop ',' push ELLIPSIS
2374 { $$ = $1->addVarArgs(); }
2375 ;
2376
2377cfa_parameter_list: // CFA
2378 // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2379 // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2380 cfa_parameter_declaration
2381 | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2382 { $$ = $1->appendList( $5 ); }
2383 | cfa_parameter_list pop ',' push cfa_parameter_declaration
2384 { $$ = $1->appendList( $5 ); }
2385 | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2386 { $$ = $1->appendList( $5 )->appendList( $9 ); }
2387 ;
2388
2389cfa_abstract_parameter_list: // CFA, new & old style abstract
2390 cfa_abstract_parameter_declaration
2391 | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2392 { $$ = $1->appendList( $5 ); }
2393 ;
2394
2395parameter_type_list_opt:
2396 // empty
2397 { $$ = nullptr; }
2398 | ELLIPSIS
2399 { $$ = nullptr; }
2400 | parameter_list
2401 | parameter_list pop ',' push ELLIPSIS
2402 { $$ = $1->addVarArgs(); }
2403 ;
2404
2405parameter_list: // abstract + real
2406 abstract_parameter_declaration
2407 | parameter_declaration
2408 | parameter_list pop ',' push abstract_parameter_declaration
2409 { $$ = $1->appendList( $5 ); }
2410 | parameter_list pop ',' push parameter_declaration
2411 { $$ = $1->appendList( $5 ); }
2412 ;
2413
2414// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2415// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2416
2417cfa_parameter_declaration: // CFA, new & old style parameter declaration
2418 parameter_declaration
2419 | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initializer_opt
2420 { $$ = $1->addName( $2 ); }
2421 | cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2422 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2423 { $$ = $1->addName( $2 ); }
2424 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2425 { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2426 | cfa_function_specifier
2427 ;
2428
2429cfa_abstract_parameter_declaration: // CFA, new & old style parameter declaration
2430 abstract_parameter_declaration
2431 | cfa_identifier_parameter_declarator_no_tuple
2432 | cfa_abstract_tuple
2433 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2434 | type_qualifier_list cfa_abstract_tuple
2435 { $$ = $2->addQualifiers( $1 ); }
2436 | cfa_abstract_function
2437 ;
2438
2439parameter_declaration:
2440 // No SUE declaration in parameter list.
2441 declaration_specifier_nobody identifier_parameter_declarator default_initializer_opt
2442 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2443 | declaration_specifier_nobody type_parameter_redeclarator default_initializer_opt
2444 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2445 ;
2446
2447abstract_parameter_declaration:
2448 declaration_specifier_nobody default_initializer_opt
2449 { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2450 | declaration_specifier_nobody abstract_parameter_declarator default_initializer_opt
2451 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2452 ;
2453
2454// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2455// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2456// identifiers. The ANSI-style parameter-list can redefine a typedef name.
2457
2458identifier_list: // K&R-style parameter list => no types
2459 identifier
2460 { $$ = DeclarationNode::newName( $1 ); }
2461 | identifier_list ',' identifier
2462 { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2463 ;
2464
2465identifier_or_type_name:
2466 identifier
2467 | TYPEDEFname
2468 | TYPEGENname
2469 ;
2470
2471type_no_function: // sizeof, alignof, cast (constructor)
2472 cfa_abstract_declarator_tuple // CFA
2473 | type_specifier
2474 | type_specifier abstract_declarator
2475 { $$ = $2->addType( $1 ); }
2476 ;
2477
2478type: // typeof, assertion
2479 type_no_function
2480 | cfa_abstract_function // CFA
2481 ;
2482
2483initializer_opt:
2484 // empty
2485 { $$ = nullptr; }
2486 | simple_assignment_operator initializer { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2487 | '=' VOID { $$ = new InitializerNode( true ); }
2488 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
2489 ;
2490
2491initializer:
2492 assignment_expression { $$ = new InitializerNode( $1 ); }
2493 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
2494 ;
2495
2496initializer_list_opt:
2497 // empty
2498 { $$ = nullptr; }
2499 | initializer
2500 | designation initializer { $$ = $2->set_designators( $1 ); }
2501 | initializer_list_opt ',' initializer { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2502 | initializer_list_opt ',' designation initializer { $$ = (InitializerNode *)($1->set_last( $4->set_designators( $3 ) )); }
2503 ;
2504
2505// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2506// '=' to separator the designator from the initializer value, as in:
2507//
2508// int x[10] = { [1] = 3 };
2509//
2510// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment. To disambiguate this case, CFA
2511// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2512// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2513// shift/reduce conflicts
2514
2515designation:
2516 designator_list ':' // C99, CFA uses ":" instead of "="
2517 | identifier_at ':' // GCC, field name
2518 { $$ = new ExpressionNode( build_varref( $1 ) ); }
2519 ;
2520
2521designator_list: // C99
2522 designator
2523 | designator_list designator
2524 { $$ = (ExpressionNode *)($1->set_last( $2 )); }
2525 //| designator_list designator { $$ = new ExpressionNode( $1, $2 ); }
2526 ;
2527
2528designator:
2529 '.' identifier_at // C99, field name
2530 { $$ = new ExpressionNode( build_varref( $2 ) ); }
2531 | '[' push assignment_expression pop ']' // C99, single array element
2532 // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2533 { $$ = $3; }
2534 | '[' push subrange pop ']' // CFA, multiple array elements
2535 { $$ = $3; }
2536 | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2537 { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild<Expression>( $3 ), maybeMoveBuild<Expression>( $5 ) ) ); }
2538 | '.' '[' push field_name_list pop ']' // CFA, tuple field selector
2539 { $$ = $4; }
2540 ;
2541
2542// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2543// rather than an object-oriented type system. This required four groups of extensions:
2544//
2545// Overloading: function, data, and operator identifiers may be overloaded.
2546//
2547// Type declarations: "otype" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2548// and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2549// definitions of new types. Type declarations with storage class "extern" provide opaque types.
2550//
2551// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2552// site. A polymorphic function is not a template; it is a function, with an address and a type.
2553//
2554// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2555// types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2556// hierarchies. Unlike classes, they can define relationships between types. Assertions declare that a type or
2557// types provide the operations declared by a specification. Assertions are normally used to declare requirements
2558// on type arguments of polymorphic functions.
2559
2560type_parameter_list: // CFA
2561 type_parameter
2562 | type_parameter_list ',' type_parameter
2563 { $$ = $1->appendList( $3 ); }
2564 ;
2565
2566type_initializer_opt: // CFA
2567 // empty
2568 { $$ = nullptr; }
2569 | '=' type
2570 { $$ = $2; }
2571 ;
2572
2573type_parameter: // CFA
2574 type_class identifier_or_type_name
2575 {
2576 typedefTable.addToScope( *$2, TYPEDEFname, "9" );
2577 if ( $1 == TypeDecl::Otype ) { SemanticError( yylloc, "otype keyword is deprecated, use T " ); }
2578 if ( $1 == TypeDecl::Dtype ) { SemanticError( yylloc, "dtype keyword is deprecated, use T &" ); }
2579 if ( $1 == TypeDecl::Ttype ) { SemanticError( yylloc, "ttype keyword is deprecated, use T ..." ); }
2580 }
2581 type_initializer_opt assertion_list_opt
2582 { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2583 | identifier_or_type_name new_type_class
2584 { typedefTable.addToScope( *$1, TYPEDEFname, "9" ); }
2585 type_initializer_opt assertion_list_opt
2586 { $$ = DeclarationNode::newTypeParam( $2, $1 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2587 | '[' identifier_or_type_name ']'
2588 {
2589 typedefTable.addToScope( *$2, TYPEDIMname, "9" );
2590 $$ = DeclarationNode::newTypeParam( TypeDecl::Dimension, $2 );
2591 }
2592 // | type_specifier identifier_parameter_declarator
2593 | assertion_list
2594 { $$ = DeclarationNode::newTypeParam( TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2595 ;
2596
2597new_type_class: // CFA
2598 // empty
2599 { $$ = TypeDecl::Otype; }
2600 | '&'
2601 { $$ = TypeDecl::Dtype; }
2602 | '*'
2603 { $$ = TypeDecl::DStype; } // dtype + sized
2604 // | '(' '*' ')'
2605 // { $$ = TypeDecl::Ftype; }
2606 | ELLIPSIS
2607 { $$ = TypeDecl::Ttype; }
2608 ;
2609
2610type_class: // CFA
2611 OTYPE
2612 { $$ = TypeDecl::Otype; }
2613 | DTYPE
2614 { $$ = TypeDecl::Dtype; }
2615 | FTYPE
2616 { $$ = TypeDecl::Ftype; }
2617 | TTYPE
2618 { $$ = TypeDecl::Ttype; }
2619 ;
2620
2621assertion_list_opt: // CFA
2622 // empty
2623 { $$ = nullptr; }
2624 | assertion_list
2625 ;
2626
2627assertion_list: // CFA
2628 assertion
2629 | assertion_list assertion
2630 { $$ = $1->appendList( $2 ); }
2631 ;
2632
2633assertion: // CFA
2634 '|' identifier_or_type_name '(' type_list ')'
2635 { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
2636 | '|' '{' push trait_declaration_list pop '}'
2637 { $$ = $4; }
2638 // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
2639 // { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
2640 ;
2641
2642type_list: // CFA
2643 type
2644 { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2645 | assignment_expression
2646 | type_list ',' type
2647 { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) )); }
2648 | type_list ',' assignment_expression
2649 { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2650 ;
2651
2652type_declaring_list: // CFA
2653 OTYPE type_declarator
2654 { $$ = $2; }
2655 | storage_class_list OTYPE type_declarator
2656 { $$ = $3->addQualifiers( $1 ); }
2657 | type_declaring_list ',' type_declarator
2658 { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2659 ;
2660
2661type_declarator: // CFA
2662 type_declarator_name assertion_list_opt
2663 { $$ = $1->addAssertions( $2 ); }
2664 | type_declarator_name assertion_list_opt '=' type
2665 { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2666 ;
2667
2668type_declarator_name: // CFA
2669 identifier_or_type_name
2670 {
2671 typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "10" );
2672 $$ = DeclarationNode::newTypeDecl( $1, 0 );
2673 }
2674 | identifier_or_type_name '(' type_parameter_list ')'
2675 {
2676 typedefTable.addToEnclosingScope( *$1, TYPEGENname, "11" );
2677 $$ = DeclarationNode::newTypeDecl( $1, $3 );
2678 }
2679 ;
2680
2681trait_specifier: // CFA
2682 TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
2683 { $$ = DeclarationNode::newTrait( $2, $4, 0 ); }
2684 | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
2685 { $$ = DeclarationNode::newTrait( $2, $4, $8 ); }
2686 ;
2687
2688trait_declaration_list: // CFA
2689 trait_declaration
2690 | trait_declaration_list pop push trait_declaration
2691 { $$ = $1->appendList( $4 ); }
2692 ;
2693
2694trait_declaration: // CFA
2695 cfa_trait_declaring_list ';'
2696 | trait_declaring_list ';'
2697 ;
2698
2699cfa_trait_declaring_list: // CFA
2700 cfa_variable_specifier
2701 | cfa_function_specifier
2702 | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2703 { $$ = $1->appendList( $1->cloneType( $5 ) ); }
2704 ;
2705
2706trait_declaring_list: // CFA
2707 type_specifier declarator
2708 { $$ = $2->addType( $1 ); }
2709 | trait_declaring_list pop ',' push declarator
2710 { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
2711 ;
2712
2713//***************************** EXTERNAL DEFINITIONS *****************************
2714
2715translation_unit:
2716 // empty, input file
2717 | external_definition_list
2718 { parseTree = parseTree ? parseTree->appendList( $1 ) : $1; }
2719 ;
2720
2721external_definition_list:
2722 push external_definition pop
2723 { $$ = $2; }
2724 | external_definition_list push external_definition pop
2725 { $$ = $1 ? $1->appendList( $3 ) : $3; }
2726 ;
2727
2728external_definition_list_opt:
2729 // empty
2730 { $$ = nullptr; }
2731 | external_definition_list
2732 ;
2733
2734up:
2735 { typedefTable.up( forall ); forall = false; }
2736 ;
2737
2738down:
2739 { typedefTable.down(); }
2740 ;
2741
2742external_definition:
2743 DIRECTIVE
2744 { $$ = DeclarationNode::newDirectiveStmt( new StatementNode( build_directive( $1 ) ) ); }
2745 | declaration
2746 | external_function_definition
2747 | EXTENSION external_definition // GCC, multiple __extension__ allowed, meaning unknown
2748 {
2749 distExt( $2 ); // mark all fields in list
2750 $$ = $2;
2751 }
2752 | ASM '(' string_literal ')' ';' // GCC, global assembler statement
2753 { $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( false, $3, 0 ) ) ); }
2754 | EXTERN STRINGliteral
2755 {
2756 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
2757 linkage = LinkageSpec::update( yylloc, linkage, $2 );
2758 }
2759 up external_definition down
2760 {
2761 linkage = linkageStack.top();
2762 linkageStack.pop();
2763 $$ = $5;
2764 }
2765 | EXTERN STRINGliteral // C++-style linkage specifier
2766 {
2767 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
2768 linkage = LinkageSpec::update( yylloc, linkage, $2 );
2769 }
2770 '{' up external_definition_list_opt down '}'
2771 {
2772 linkage = linkageStack.top();
2773 linkageStack.pop();
2774 $$ = $6;
2775 }
2776 | type_qualifier_list
2777 {
2778 if ( $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2779 if ( $1->type->forall ) forall = true; // remember generic type
2780 }
2781 '{' up external_definition_list_opt down '}' // CFA, namespace
2782 {
2783 distQual( $5, $1 );
2784 forall = false;
2785 $$ = $5;
2786 }
2787 | declaration_qualifier_list
2788 {
2789 if ( $1->type && $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2790 if ( $1->type && $1->type->forall ) forall = true; // remember generic type
2791 }
2792 '{' up external_definition_list_opt down '}' // CFA, namespace
2793 {
2794 distQual( $5, $1 );
2795 forall = false;
2796 $$ = $5;
2797 }
2798 | declaration_qualifier_list type_qualifier_list
2799 {
2800 if ( ($1->type && $1->type->qualifiers.val) || $2->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2801 if ( ($1->type && $1->type->forall) || $2->type->forall ) forall = true; // remember generic type
2802 }
2803 '{' up external_definition_list_opt down '}' // CFA, namespace
2804 {
2805 distQual( $6, $1->addQualifiers( $2 ) );
2806 forall = false;
2807 $$ = $6;
2808 }
2809 ;
2810
2811external_function_definition:
2812 function_definition
2813 // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2814 // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2815 // Parsing is possible because function_definition does not appear in the context of an expression (nested
2816 // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2817 // declaration must still have a type_specifier. OBSOLESCENT (see 1)
2818 | function_declarator compound_statement
2819 { $$ = $1->addFunctionBody( $2 ); }
2820 | KR_function_declarator KR_parameter_list_opt compound_statement
2821 { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
2822 ;
2823
2824with_clause_opt:
2825 // empty
2826 { $$ = nullptr; forall = false; }
2827 | WITH '(' tuple_expression_list ')'
2828 { $$ = $3; forall = false; }
2829 ;
2830
2831function_definition:
2832 cfa_function_declaration with_clause_opt compound_statement // CFA
2833 {
2834 // Add the function body to the last identifier in the function definition list, i.e., foo3:
2835 // [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2836 $1->get_last()->addFunctionBody( $3, $2 );
2837 $$ = $1;
2838 }
2839 | declaration_specifier function_declarator with_clause_opt compound_statement
2840 {
2841 rebindForall( $1, $2 );
2842 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2843 }
2844 | declaration_specifier variable_type_redeclarator with_clause_opt compound_statement
2845 {
2846 rebindForall( $1, $2 );
2847 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2848 }
2849 // handles default int return type, OBSOLESCENT (see 1)
2850 | type_qualifier_list function_declarator with_clause_opt compound_statement
2851 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2852 // handles default int return type, OBSOLESCENT (see 1)
2853 | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2854 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2855 // handles default int return type, OBSOLESCENT (see 1)
2856 | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2857 { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2858
2859 // Old-style K&R function definition, OBSOLESCENT (see 4)
2860 | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2861 {
2862 rebindForall( $1, $2 );
2863 $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2864 }
2865 // handles default int return type, OBSOLESCENT (see 1)
2866 | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2867 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2868 // handles default int return type, OBSOLESCENT (see 1)
2869 | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2870 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2871 // handles default int return type, OBSOLESCENT (see 1)
2872 | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2873 { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2874 ;
2875
2876declarator:
2877 variable_declarator
2878 | variable_type_redeclarator
2879 | function_declarator
2880 ;
2881
2882subrange:
2883 constant_expression '~' constant_expression // CFA, integer subrange
2884 { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild<Expression>( $1 ), maybeMoveBuild<Expression>( $3 ) ) ); }
2885 ;
2886
2887asm_name_opt: // GCC
2888 // empty
2889 { $$ = nullptr; }
2890 | ASM '(' string_literal ')' attribute_list_opt
2891 {
2892 DeclarationNode * name = new DeclarationNode();
2893 name->asmName = $3;
2894 $$ = name->addQualifiers( $5 );
2895 }
2896 ;
2897
2898attribute_list_opt: // GCC
2899 // empty
2900 { $$ = nullptr; }
2901 | attribute_list
2902 ;
2903
2904attribute_list: // GCC
2905 attribute
2906 | attribute_list attribute
2907 { $$ = $2->addQualifiers( $1 ); }
2908 ;
2909
2910attribute: // GCC
2911 ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2912 { $$ = $4; }
2913 ;
2914
2915attribute_name_list: // GCC
2916 attribute_name
2917 | attribute_name_list ',' attribute_name
2918 { $$ = $3->addQualifiers( $1 ); }
2919 ;
2920
2921attribute_name: // GCC
2922 // empty
2923 { $$ = nullptr; }
2924 | attr_name
2925 { $$ = DeclarationNode::newAttribute( $1 ); }
2926 | attr_name '(' argument_expression_list_opt ')'
2927 { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2928 ;
2929
2930attr_name: // GCC
2931 IDENTIFIER
2932 | quasi_keyword
2933 | TYPEDEFname
2934 | TYPEGENname
2935 | FALLTHROUGH
2936 { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2937 | CONST
2938 { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2939 ;
2940
2941// ============================================================================
2942// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2943// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2944// in:
2945//
2946// int (*f())[10] { ... };
2947// ... (*f())[3] += 1; // definition mimics usage
2948//
2949// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2950// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2951// ============================================================================
2952
2953// ----------------------------------------------------------------------------
2954// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2955// to define a variable or function prototype, e.g.:
2956//
2957// valid declaration invalid definition
2958// ----------------- ------------------
2959// int f; int f {}
2960// int *f; int *f {}
2961// int f[10]; int f[10] {}
2962// int (*f)(int); int (*f)(int) {}
2963//
2964// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2965// variable_declarator and function_declarator.
2966// ----------------------------------------------------------------------------
2967
2968// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2969// declaring an array of functions versus a pointer to an array of functions.
2970
2971paren_identifier:
2972 identifier_at
2973 { $$ = DeclarationNode::newName( $1 ); }
2974 | '(' paren_identifier ')' // redundant parenthesis
2975 { $$ = $2; }
2976 ;
2977
2978variable_declarator:
2979 paren_identifier attribute_list_opt
2980 { $$ = $1->addQualifiers( $2 ); }
2981 | variable_ptr
2982 | variable_array attribute_list_opt
2983 { $$ = $1->addQualifiers( $2 ); }
2984 | variable_function attribute_list_opt
2985 { $$ = $1->addQualifiers( $2 ); }
2986 ;
2987
2988variable_ptr:
2989 ptrref_operator variable_declarator
2990 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2991 | ptrref_operator type_qualifier_list variable_declarator
2992 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2993 | '(' variable_ptr ')' attribute_list_opt // redundant parenthesis
2994 { $$ = $2->addQualifiers( $4 ); }
2995 | '(' attribute_list variable_ptr ')' attribute_list_opt // redundant parenthesis
2996 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
2997 ;
2998
2999variable_array:
3000 paren_identifier array_dimension
3001 { $$ = $1->addArray( $2 ); }
3002 | '(' variable_ptr ')' array_dimension
3003 { $$ = $2->addArray( $4 ); }
3004 | '(' attribute_list variable_ptr ')' array_dimension
3005 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3006 | '(' variable_array ')' multi_array_dimension // redundant parenthesis
3007 { $$ = $2->addArray( $4 ); }
3008 | '(' attribute_list variable_array ')' multi_array_dimension // redundant parenthesis
3009 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3010 | '(' variable_array ')' // redundant parenthesis
3011 { $$ = $2; }
3012 | '(' attribute_list variable_array ')' // redundant parenthesis
3013 { $$ = $3->addQualifiers( $2 ); }
3014 ;
3015
3016variable_function:
3017 '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3018 { $$ = $2->addParamList( $6 ); }
3019 | '(' attribute_list variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3020 { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
3021 | '(' variable_function ')' // redundant parenthesis
3022 { $$ = $2; }
3023 | '(' attribute_list variable_function ')' // redundant parenthesis
3024 { $$ = $3->addQualifiers( $2 ); }
3025 ;
3026
3027// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
3028// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
3029// is the same scope. The pattern precludes returning arrays and functions versus pointers to arrays and functions.
3030
3031function_declarator:
3032 function_no_ptr attribute_list_opt
3033 { $$ = $1->addQualifiers( $2 ); }
3034 | function_ptr
3035 | function_array attribute_list_opt
3036 { $$ = $1->addQualifiers( $2 ); }
3037 ;
3038
3039function_no_ptr:
3040 paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3041 { $$ = $1->addParamList( $4 ); }
3042 | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
3043 { $$ = $2->addParamList( $6 ); }
3044 | '(' attribute_list function_ptr ')' '(' push parameter_type_list_opt pop ')'
3045 { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
3046 | '(' function_no_ptr ')' // redundant parenthesis
3047 { $$ = $2; }
3048 | '(' attribute_list function_no_ptr ')' // redundant parenthesis
3049 { $$ = $3->addQualifiers( $2 ); }
3050 ;
3051
3052function_ptr:
3053 ptrref_operator function_declarator
3054 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3055 | ptrref_operator type_qualifier_list function_declarator
3056 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3057 | '(' function_ptr ')' attribute_list_opt
3058 { $$ = $2->addQualifiers( $4 ); }
3059 | '(' attribute_list function_ptr ')' attribute_list_opt
3060 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3061 ;
3062
3063function_array:
3064 '(' function_ptr ')' array_dimension
3065 { $$ = $2->addArray( $4 ); }
3066 | '(' attribute_list function_ptr ')' array_dimension
3067 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3068 | '(' function_array ')' multi_array_dimension // redundant parenthesis
3069 { $$ = $2->addArray( $4 ); }
3070 | '(' attribute_list function_array ')' multi_array_dimension // redundant parenthesis
3071 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3072 | '(' function_array ')' // redundant parenthesis
3073 { $$ = $2; }
3074 | '(' attribute_list function_array ')' // redundant parenthesis
3075 { $$ = $3->addQualifiers( $2 ); }
3076 ;
3077
3078// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
3079//
3080// f( a, b, c ) int a, *b, c[]; {}
3081//
3082// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
3083// returning arrays and functions versus pointers to arrays and functions.
3084
3085KR_function_declarator:
3086 KR_function_no_ptr
3087 | KR_function_ptr
3088 | KR_function_array
3089 ;
3090
3091KR_function_no_ptr:
3092 paren_identifier '(' identifier_list ')' // function_declarator handles empty parameter
3093 { $$ = $1->addIdList( $3 ); }
3094 | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
3095 { $$ = $2->addParamList( $6 ); }
3096 | '(' attribute_list KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
3097 { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
3098 | '(' KR_function_no_ptr ')' // redundant parenthesis
3099 { $$ = $2; }
3100 | '(' attribute_list KR_function_no_ptr ')' // redundant parenthesis
3101 { $$ = $3->addQualifiers( $2 ); }
3102 ;
3103
3104KR_function_ptr:
3105 ptrref_operator KR_function_declarator
3106 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3107 | ptrref_operator type_qualifier_list KR_function_declarator
3108 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3109 | '(' KR_function_ptr ')'
3110 { $$ = $2; }
3111 | '(' attribute_list KR_function_ptr ')'
3112 { $$ = $3->addQualifiers( $2 ); }
3113 ;
3114
3115KR_function_array:
3116 '(' KR_function_ptr ')' array_dimension
3117 { $$ = $2->addArray( $4 ); }
3118 | '(' attribute_list KR_function_ptr ')' array_dimension
3119 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3120 | '(' KR_function_array ')' multi_array_dimension // redundant parenthesis
3121 { $$ = $2->addArray( $4 ); }
3122 | '(' attribute_list KR_function_array ')' multi_array_dimension // redundant parenthesis
3123 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3124 | '(' KR_function_array ')' // redundant parenthesis
3125 { $$ = $2; }
3126 | '(' attribute_list KR_function_array ')' // redundant parenthesis
3127 { $$ = $3->addQualifiers( $2 ); }
3128 ;
3129
3130// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
3131//
3132// typedef int foo;
3133// {
3134// int foo; // redefine typedef name in new scope
3135// }
3136//
3137// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3138// and functions versus pointers to arrays and functions.
3139
3140paren_type:
3141 typedef_name
3142 {
3143 // hide type name in enclosing scope by variable name
3144 typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "ID" );
3145 }
3146 | '(' paren_type ')'
3147 { $$ = $2; }
3148 ;
3149
3150variable_type_redeclarator:
3151 paren_type attribute_list_opt
3152 { $$ = $1->addQualifiers( $2 ); }
3153 | type_ptr
3154 | type_array attribute_list_opt
3155 { $$ = $1->addQualifiers( $2 ); }
3156 | type_function attribute_list_opt
3157 { $$ = $1->addQualifiers( $2 ); }
3158 ;
3159
3160type_ptr:
3161 ptrref_operator variable_type_redeclarator
3162 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3163 | ptrref_operator type_qualifier_list variable_type_redeclarator
3164 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3165 | '(' type_ptr ')' attribute_list_opt // redundant parenthesis
3166 { $$ = $2->addQualifiers( $4 ); }
3167 | '(' attribute_list type_ptr ')' attribute_list_opt // redundant parenthesis
3168 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3169 ;
3170
3171type_array:
3172 paren_type array_dimension
3173 { $$ = $1->addArray( $2 ); }
3174 | '(' type_ptr ')' array_dimension
3175 { $$ = $2->addArray( $4 ); }
3176 | '(' attribute_list type_ptr ')' array_dimension
3177 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3178 | '(' type_array ')' multi_array_dimension // redundant parenthesis
3179 { $$ = $2->addArray( $4 ); }
3180 | '(' attribute_list type_array ')' multi_array_dimension // redundant parenthesis
3181 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3182 | '(' type_array ')' // redundant parenthesis
3183 { $$ = $2; }
3184 | '(' attribute_list type_array ')' // redundant parenthesis
3185 { $$ = $3->addQualifiers( $2 ); }
3186 ;
3187
3188type_function:
3189 paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3190 { $$ = $1->addParamList( $4 ); }
3191 | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3192 { $$ = $2->addParamList( $6 ); }
3193 | '(' attribute_list type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3194 { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
3195 | '(' type_function ')' // redundant parenthesis
3196 { $$ = $2; }
3197 | '(' attribute_list type_function ')' // redundant parenthesis
3198 { $$ = $3->addQualifiers( $2 ); }
3199 ;
3200
3201// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
3202// typedef name and allows the C99 array options, which can only appear in a parameter list. The pattern precludes
3203// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
3204// pointers to arrays and functions.
3205
3206identifier_parameter_declarator:
3207 paren_identifier attribute_list_opt
3208 { $$ = $1->addQualifiers( $2 ); }
3209 | '&' MUTEX paren_identifier attribute_list_opt
3210 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3211 | identifier_parameter_ptr
3212 | identifier_parameter_array attribute_list_opt
3213 { $$ = $1->addQualifiers( $2 ); }
3214 | identifier_parameter_function attribute_list_opt
3215 { $$ = $1->addQualifiers( $2 ); }
3216 ;
3217
3218identifier_parameter_ptr:
3219 ptrref_operator identifier_parameter_declarator
3220 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3221 | ptrref_operator type_qualifier_list identifier_parameter_declarator
3222 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3223 | '(' identifier_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3224 { $$ = $2->addQualifiers( $4 ); }
3225 ;
3226
3227identifier_parameter_array:
3228 paren_identifier array_parameter_dimension
3229 { $$ = $1->addArray( $2 ); }
3230 | '(' identifier_parameter_ptr ')' array_dimension
3231 { $$ = $2->addArray( $4 ); }
3232 | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3233 { $$ = $2->addArray( $4 ); }
3234 | '(' identifier_parameter_array ')' // redundant parenthesis
3235 { $$ = $2; }
3236 ;
3237
3238identifier_parameter_function:
3239 paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3240 { $$ = $1->addParamList( $4 ); }
3241 | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3242 { $$ = $2->addParamList( $6 ); }
3243 | '(' identifier_parameter_function ')' // redundant parenthesis
3244 { $$ = $2; }
3245 ;
3246
3247// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3248// e.g.:
3249//
3250// typedef int foo;
3251// forall( otype T ) struct foo;
3252// int f( int foo ); // redefine typedef name in new scope
3253//
3254// and allows the C99 array options, which can only appear in a parameter list.
3255
3256type_parameter_redeclarator:
3257 typedef_name attribute_list_opt
3258 { $$ = $1->addQualifiers( $2 ); }
3259 | '&' MUTEX typedef_name attribute_list_opt
3260 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3261 | type_parameter_ptr
3262 | type_parameter_array attribute_list_opt
3263 { $$ = $1->addQualifiers( $2 ); }
3264 | type_parameter_function attribute_list_opt
3265 { $$ = $1->addQualifiers( $2 ); }
3266 ;
3267
3268typedef_name:
3269 TYPEDEFname
3270 { $$ = DeclarationNode::newName( $1 ); }
3271 | TYPEGENname
3272 { $$ = DeclarationNode::newName( $1 ); }
3273 ;
3274
3275type_parameter_ptr:
3276 ptrref_operator type_parameter_redeclarator
3277 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3278 | ptrref_operator type_qualifier_list type_parameter_redeclarator
3279 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3280 | '(' type_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3281 { $$ = $2->addQualifiers( $4 ); }
3282 ;
3283
3284type_parameter_array:
3285 typedef_name array_parameter_dimension
3286 { $$ = $1->addArray( $2 ); }
3287 | '(' type_parameter_ptr ')' array_parameter_dimension
3288 { $$ = $2->addArray( $4 ); }
3289 ;
3290
3291type_parameter_function:
3292 typedef_name '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3293 { $$ = $1->addParamList( $4 ); }
3294 | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3295 { $$ = $2->addParamList( $6 ); }
3296 ;
3297
3298// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3299// which the type applies, e.g.:
3300//
3301// sizeof( int );
3302// sizeof( int * );
3303// sizeof( int [10] );
3304// sizeof( int (*)() );
3305// sizeof( int () );
3306//
3307// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3308// and functions versus pointers to arrays and functions.
3309
3310abstract_declarator:
3311 abstract_ptr
3312 | abstract_array attribute_list_opt
3313 { $$ = $1->addQualifiers( $2 ); }
3314 | abstract_function attribute_list_opt
3315 { $$ = $1->addQualifiers( $2 ); }
3316 ;
3317
3318abstract_ptr:
3319 ptrref_operator
3320 { $$ = DeclarationNode::newPointer( 0, $1 ); }
3321 | ptrref_operator type_qualifier_list
3322 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3323 | ptrref_operator abstract_declarator
3324 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3325 | ptrref_operator type_qualifier_list abstract_declarator
3326 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3327 | '(' abstract_ptr ')' attribute_list_opt
3328 { $$ = $2->addQualifiers( $4 ); }
3329 ;
3330
3331abstract_array:
3332 array_dimension
3333 | '(' abstract_ptr ')' array_dimension
3334 { $$ = $2->addArray( $4 ); }
3335 | '(' abstract_array ')' multi_array_dimension // redundant parenthesis
3336 { $$ = $2->addArray( $4 ); }
3337 | '(' abstract_array ')' // redundant parenthesis
3338 { $$ = $2; }
3339 ;
3340
3341abstract_function:
3342 '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3343 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3344 | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3345 { $$ = $2->addParamList( $6 ); }
3346 | '(' abstract_function ')' // redundant parenthesis
3347 { $$ = $2; }
3348 ;
3349
3350array_dimension:
3351 // Only the first dimension can be empty.
3352 '[' ']'
3353 { $$ = DeclarationNode::newArray( 0, 0, false ); }
3354 | '[' ']' multi_array_dimension
3355 { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
3356 | '[' push assignment_expression pop ',' comma_expression ']'
3357 { $$ = DeclarationNode::newArray( $3, 0, false )->addArray( DeclarationNode::newArray( $6, 0, false ) ); }
3358 // { SemanticError( yylloc, "New array dimension is currently unimplemented." ); $$ = nullptr; }
3359 | multi_array_dimension
3360 ;
3361
3362multi_array_dimension:
3363 '[' push assignment_expression pop ']'
3364 { $$ = DeclarationNode::newArray( $3, 0, false ); }
3365 | '[' push '*' pop ']' // C99
3366 { $$ = DeclarationNode::newVarArray( 0 ); }
3367 | multi_array_dimension '[' push assignment_expression pop ']'
3368 { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
3369 | multi_array_dimension '[' push '*' pop ']' // C99
3370 { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3371 ;
3372
3373// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3374// identifier to which the type applies, e.g.:
3375//
3376// int f( int ); // not handled here
3377// int f( int * ); // abstract function-prototype parameter; no parameter name specified
3378// int f( int (*)() ); // abstract function-prototype parameter; no parameter name specified
3379// int f( int (int) ); // abstract function-prototype parameter; no parameter name specified
3380//
3381// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3382// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3383// special meaning of parenthesis around a typedef name:
3384//
3385// ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3386// parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3387// not as redundant parentheses around the identifier."
3388//
3389// For example:
3390//
3391// typedef float T;
3392// int f( int ( T [5] ) ); // see abstract_parameter_declarator
3393// int g( int ( T ( int ) ) ); // see abstract_parameter_declarator
3394// int f( int f1( T a[5] ) ); // see identifier_parameter_declarator
3395// int g( int g1( T g2( int p ) ) ); // see identifier_parameter_declarator
3396//
3397// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3398// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3399// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3400// functions.
3401
3402abstract_parameter_declarator:
3403 abstract_parameter_ptr
3404 | '&' MUTEX attribute_list_opt
3405 { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3406 | abstract_parameter_array attribute_list_opt
3407 { $$ = $1->addQualifiers( $2 ); }
3408 | abstract_parameter_function attribute_list_opt
3409 { $$ = $1->addQualifiers( $2 ); }
3410 ;
3411
3412abstract_parameter_ptr:
3413 ptrref_operator
3414 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3415 | ptrref_operator type_qualifier_list
3416 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3417 | ptrref_operator abstract_parameter_declarator
3418 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3419 | ptrref_operator type_qualifier_list abstract_parameter_declarator
3420 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3421 | '(' abstract_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3422 { $$ = $2->addQualifiers( $4 ); }
3423 ;
3424
3425abstract_parameter_array:
3426 array_parameter_dimension
3427 | '(' abstract_parameter_ptr ')' array_parameter_dimension
3428 { $$ = $2->addArray( $4 ); }
3429 | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3430 { $$ = $2->addArray( $4 ); }
3431 | '(' abstract_parameter_array ')' // redundant parenthesis
3432 { $$ = $2; }
3433 ;
3434
3435abstract_parameter_function:
3436 '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3437 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3438 | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3439 { $$ = $2->addParamList( $6 ); }
3440 | '(' abstract_parameter_function ')' // redundant parenthesis
3441 { $$ = $2; }
3442 ;
3443
3444array_parameter_dimension:
3445 // Only the first dimension can be empty or have qualifiers.
3446 array_parameter_1st_dimension
3447 | array_parameter_1st_dimension multi_array_dimension
3448 { $$ = $1->addArray( $2 ); }
3449 | multi_array_dimension
3450 ;
3451
3452// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3453//
3454// ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3455// a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3456
3457array_parameter_1st_dimension:
3458 '[' ']'
3459 { $$ = DeclarationNode::newArray( 0, 0, false ); }
3460 // multi_array_dimension handles the '[' '*' ']' case
3461 | '[' push type_qualifier_list '*' pop ']' // remaining C99
3462 { $$ = DeclarationNode::newVarArray( $3 ); }
3463 | '[' push type_qualifier_list pop ']'
3464 { $$ = DeclarationNode::newArray( 0, $3, false ); }
3465 // multi_array_dimension handles the '[' assignment_expression ']' case
3466 | '[' push type_qualifier_list assignment_expression pop ']'
3467 { $$ = DeclarationNode::newArray( $4, $3, false ); }
3468 | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3469 { $$ = DeclarationNode::newArray( $5, $4, true ); }
3470 | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3471 { $$ = DeclarationNode::newArray( $5, $3, true ); }
3472 ;
3473
3474// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3475//
3476// struct S {
3477// int;
3478// int *;
3479// int [10];
3480// int (*)();
3481// };
3482
3483variable_abstract_declarator:
3484 variable_abstract_ptr
3485 | variable_abstract_array attribute_list_opt
3486 { $$ = $1->addQualifiers( $2 ); }
3487 | variable_abstract_function attribute_list_opt
3488 { $$ = $1->addQualifiers( $2 ); }
3489 ;
3490
3491variable_abstract_ptr:
3492 ptrref_operator
3493 { $$ = DeclarationNode::newPointer( 0, $1 ); }
3494 | ptrref_operator type_qualifier_list
3495 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3496 | ptrref_operator variable_abstract_declarator
3497 { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3498 | ptrref_operator type_qualifier_list variable_abstract_declarator
3499 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3500 | '(' variable_abstract_ptr ')' attribute_list_opt // redundant parenthesis
3501 { $$ = $2->addQualifiers( $4 ); }
3502 ;
3503
3504variable_abstract_array:
3505 array_dimension
3506 | '(' variable_abstract_ptr ')' array_dimension
3507 { $$ = $2->addArray( $4 ); }
3508 | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3509 { $$ = $2->addArray( $4 ); }
3510 | '(' variable_abstract_array ')' // redundant parenthesis
3511 { $$ = $2; }
3512 ;
3513
3514variable_abstract_function:
3515 '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3516 { $$ = $2->addParamList( $6 ); }
3517 | '(' variable_abstract_function ')' // redundant parenthesis
3518 { $$ = $2; }
3519 ;
3520
3521// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3522// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3523
3524cfa_identifier_parameter_declarator_tuple: // CFA
3525 cfa_identifier_parameter_declarator_no_tuple
3526 | cfa_abstract_tuple
3527 | type_qualifier_list cfa_abstract_tuple
3528 { $$ = $2->addQualifiers( $1 ); }
3529 ;
3530
3531cfa_identifier_parameter_declarator_no_tuple: // CFA
3532 cfa_identifier_parameter_ptr
3533 | cfa_identifier_parameter_array
3534 ;
3535
3536cfa_identifier_parameter_ptr: // CFA
3537 // No SUE declaration in parameter list.
3538 ptrref_operator type_specifier_nobody
3539 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3540 | type_qualifier_list ptrref_operator type_specifier_nobody
3541 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3542 | ptrref_operator cfa_abstract_function
3543 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3544 | type_qualifier_list ptrref_operator cfa_abstract_function
3545 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3546 | ptrref_operator cfa_identifier_parameter_declarator_tuple
3547 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3548 | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3549 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3550 ;
3551
3552cfa_identifier_parameter_array: // CFA
3553 // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3554 // shift/reduce conflict with new-style empty (void) function return type.
3555 '[' ']' type_specifier_nobody
3556 { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3557 | cfa_array_parameter_1st_dimension type_specifier_nobody
3558 { $$ = $2->addNewArray( $1 ); }
3559 | '[' ']' multi_array_dimension type_specifier_nobody
3560 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3561 | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3562 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3563 | multi_array_dimension type_specifier_nobody
3564 { $$ = $2->addNewArray( $1 ); }
3565
3566 | '[' ']' cfa_identifier_parameter_ptr
3567 { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3568 | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3569 { $$ = $2->addNewArray( $1 ); }
3570 | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3571 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3572 | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3573 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3574 | multi_array_dimension cfa_identifier_parameter_ptr
3575 { $$ = $2->addNewArray( $1 ); }
3576 ;
3577
3578cfa_array_parameter_1st_dimension:
3579 '[' push type_qualifier_list '*' pop ']' // remaining C99
3580 { $$ = DeclarationNode::newVarArray( $3 ); }
3581 | '[' push type_qualifier_list assignment_expression pop ']'
3582 { $$ = DeclarationNode::newArray( $4, $3, false ); }
3583 | '[' push declaration_qualifier_list assignment_expression pop ']'
3584 // declaration_qualifier_list must be used because of shift/reduce conflict with
3585 // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3586 // appear in this context.
3587 { $$ = DeclarationNode::newArray( $4, $3, true ); }
3588 | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3589 { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3590 ;
3591
3592// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3593// identifier to which the type applies, e.g.:
3594//
3595// [int] f( int ); // abstract variable parameter; no parameter name specified
3596// [int] f( [int] (int) ); // abstract function-prototype parameter; no parameter name specified
3597//
3598// These rules need LR(3):
3599//
3600// cfa_abstract_tuple identifier_or_type_name
3601// '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
3602//
3603// since a function return type can be syntactically identical to a tuple type:
3604//
3605// [int, int] t;
3606// [int, int] f( int );
3607//
3608// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3609// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3610// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3611// duplicated when appearing with cfa_function_specifier.
3612
3613cfa_abstract_declarator_tuple: // CFA
3614 cfa_abstract_tuple
3615 | type_qualifier_list cfa_abstract_tuple
3616 { $$ = $2->addQualifiers( $1 ); }
3617 | cfa_abstract_declarator_no_tuple
3618 ;
3619
3620cfa_abstract_declarator_no_tuple: // CFA
3621 cfa_abstract_ptr
3622 | cfa_abstract_array
3623 ;
3624
3625cfa_abstract_ptr: // CFA
3626 ptrref_operator type_specifier
3627 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3628 | type_qualifier_list ptrref_operator type_specifier
3629 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3630 | ptrref_operator cfa_abstract_function
3631 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3632 | type_qualifier_list ptrref_operator cfa_abstract_function
3633 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3634 | ptrref_operator cfa_abstract_declarator_tuple
3635 { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3636 | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3637 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3638 ;
3639
3640cfa_abstract_array: // CFA
3641 // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3642 // empty (void) function return type.
3643 '[' ']' type_specifier
3644 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3645 | '[' ']' multi_array_dimension type_specifier
3646 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3647 | multi_array_dimension type_specifier
3648 { $$ = $2->addNewArray( $1 ); }
3649 | '[' ']' cfa_abstract_ptr
3650 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3651 | '[' ']' multi_array_dimension cfa_abstract_ptr
3652 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3653 | multi_array_dimension cfa_abstract_ptr
3654 { $$ = $2->addNewArray( $1 ); }
3655 ;
3656
3657cfa_abstract_tuple: // CFA
3658 '[' push cfa_abstract_parameter_list pop ']'
3659 { $$ = DeclarationNode::newTuple( $3 ); }
3660 | '[' push type_specifier_nobody ELLIPSIS pop ']'
3661 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3662 | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
3663 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3664 ;
3665
3666cfa_abstract_function: // CFA
3667// '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
3668// { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3669 cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
3670 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3671 | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
3672 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3673 ;
3674
3675// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3676// each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3677//
3678// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3679// the declaration specifiers in a declaration is an obsolescent feature."
3680//
3681// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3682// prototype-format parameter type declarators) is an obsolescent feature."
3683//
3684// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3685// declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3686
3687//************************* MISCELLANEOUS ********************************
3688
3689comma_opt: // redundant comma
3690 // empty
3691 | ','
3692 ;
3693
3694default_initializer_opt:
3695 // empty
3696 { $$ = nullptr; }
3697 | '=' assignment_expression
3698 { $$ = $2; }
3699 ;
3700
3701%%
3702
3703// ----end of grammar----
3704
3705// Local Variables: //
3706// mode: c++ //
3707// tab-width: 4 //
3708// compile-command: "make install" //
3709// End: //
Note: See TracBrowser for help on using the repository browser.