source: src/Parser/parser.yy @ 332bd33

arm-ehjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-expr
Last change on this file since 332bd33 was 332bd33, checked in by Peter A. Buhr <pabuhr@…>, 2 years ago

add inclusive bound to singleton comparison

  • Property mode set to 100644
File size: 135.3 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author           : Peter A. Buhr
10// Created On       : Sat Sep  1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Thu Dec 12 17:42:08 2019
13// Update Count     : 4401
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS.  While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks.  Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// 1. designation with '=' (use ':' instead)
29//
30// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32//
33// 1. designation with and without '=' (use ':' instead)
34// 2. attributes not allowed in parenthesis of declarator
35//
36// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40// grammar rule.
41
42%{
43#define YYDEBUG_LEXER_TEXT (yylval)                                             // lexer loads this up each time
44#define YYDEBUG 1                                                                               // get the pretty debugging code to compile
45#define YYERROR_VERBOSE                                                                 // more information in syntax errors
46
47#undef __GNUC_MINOR__
48
49#include <cstdio>
50#include <stack>
51using namespace std;
52
53#include "SynTree/Declaration.h"
54#include "ParseNode.h"
55#include "TypedefTable.h"
56#include "TypeData.h"
57#include "LinkageSpec.h"
58#include "Common/SemanticError.h"                                               // error_str
59#include "Common/utility.h"                                                             // for maybeMoveBuild, maybeBuild, CodeLo...
60
61extern DeclarationNode * parseTree;
62extern LinkageSpec::Spec linkage;
63extern TypedefTable typedefTable;
64
65stack< LinkageSpec::Spec > linkageStack;
66
67bool appendStr( string & to, string & from ) {
68        // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
69        //    "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
70        //    the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
71        //    easier to let the C compiler handle this case.
72        //
73        // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
74        //    without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
75        //    i.e., u"a" U"b" L"c" is disallowed.
76
77        if ( from[0] != '"' ) {                                                         // encoding ?
78                if ( to[0] != '"' ) {                                                   // encoding ?
79                        if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
80                                yyerror( "non-matching string encodings for string-literal concatenation" );
81                                return false;                                                   // parse error, must call YYERROR in action
82                        } else if ( from[1] == '8' ) {
83                                from.erase( 0, 1 );                                             // remove 2nd encoding
84                        } // if
85                } else {
86                        if ( from[1] == '8' ) {                                         // move encoding to start
87                                to = "u8" + to;
88                                from.erase( 0, 1 );                                             // remove 2nd encoding
89                        } else {
90                                to = from[0] + to;
91                        } // if
92                } // if
93                from.erase( 0, 1 );                                                             // remove 2nd encoding
94        } // if
95        to += " " + from;                                                                       // concatenated into single string
96        return true;
97} // appendStr
98
99DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
100        // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
101        DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
102        for ( cur = dynamic_cast<DeclarationNode *>( cur->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode *>( cur->get_next() ) ) {
103                cl->cloneBaseType( cur );
104        } // for
105        declList->addType( cl );
106        return declList;
107} // distAttr
108
109void distExt( DeclarationNode * declaration ) {
110        // distribute EXTENSION across all declarations
111        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
112                iter->set_extension( true );
113        } // for
114} // distExt
115
116void distInl( DeclarationNode * declaration ) {
117        // distribute EXTENSION across all declarations
118        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
119                iter->set_inLine( true );
120        } // for
121} // distInl
122
123void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
124        // distribute qualifiers across all non-variable declarations in a distribution statemement
125        for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
126                // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
127                // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
128                // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
129                // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
130                DeclarationNode * clone = qualifiers->clone();
131                if ( qualifiers->type ) {                                               // forall clause ? (handles SC)
132                        if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
133                                swap( clone->type->forall, iter->type->aggregate.params );
134                                iter->addQualifiers( clone );
135                        } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
136                                // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
137                                DeclarationNode newnode;
138                                swap( newnode.type, iter->type->aggInst.aggregate );
139                                swap( clone->type->forall, newnode.type->aggregate.params );
140                                newnode.addQualifiers( clone );
141                                swap( newnode.type, iter->type->aggInst.aggregate );
142                        } else if ( iter->type->kind == TypeData::Function ) { // routines ?
143                                swap( clone->type->forall, iter->type->forall );
144                                iter->addQualifiers( clone );
145                        } // if
146                } else {                                                                                // just SC qualifiers
147                        iter->addQualifiers( clone );
148                } // if
149        } // for
150        delete qualifiers;
151} // distQual
152
153// There is an ambiguity for inline generic-routine return-types and generic routines.
154//   forall( otype T ) struct S { int i; } bar( T ) {}
155// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
156//   forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
157// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
158//   forall( otype T ) struct S { int T; };
159//   forall( otype W ) bar( W ) {}
160
161void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
162        if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
163                funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
164                declSpec->type->aggregate.params = nullptr;
165        } // if
166} // rebindForall
167
168NameExpr * build_postfix_name( const string * name ) {
169        NameExpr * new_name = build_varref( new string( "?`" + *name ) );
170        delete name;
171        return new_name;
172} // build_postfix_name
173
174DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
175        if ( ! fieldList ) {                                                            // field declarator ?
176                if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate || typeSpec->type->kind == TypeData::Enum) ) ) {
177                        stringstream ss;
178                        typeSpec->type->print( ss );
179                        SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
180                        return nullptr;
181                } // if
182                fieldList = DeclarationNode::newName( nullptr );
183        } // if
184        return distAttr( typeSpec, fieldList );                         // mark all fields in list
185} // fieldDecl
186
187ForCtrl * forCtrl( ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
188        ConstantExpr * constant = dynamic_cast<ConstantExpr *>(type->expr.get());
189        if ( constant && (constant->get_constant()->get_value() == "0" || constant->get_constant()->get_value() == "1") ) {
190        type = new ExpressionNode( new CastExpr( maybeMoveBuild< Expression >(type), new BasicType( Type::Qualifiers(), BasicType::SignedInt ) ) );
191        } // if
192        return new ForCtrl(
193                distAttr( DeclarationNode::newTypeof( type, true ), DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) ) ),
194                // NULL comp/inc => leave blank
195                comp ? new ExpressionNode( build_binary_val( compop, new ExpressionNode( build_varref( new string( *index ) ) ), comp ) ) : 0,
196                inc ? new ExpressionNode( build_binary_val( compop == OperKinds::LThan || compop == OperKinds::LEThan ? // choose += or -= for upto/downto
197                                                        OperKinds::PlusAssn : OperKinds::MinusAssn, new ExpressionNode( build_varref( new string( *index ) ) ), inc ) ) : 0 );
198} // forCtrl
199
200ForCtrl * forCtrl( ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
201        if ( NameExpr * identifier = dynamic_cast<NameExpr *>(index->expr.get()) ) {
202                return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
203        } else if ( CommaExpr * commaExpr = dynamic_cast<CommaExpr *>(index->expr.get()) ) {
204                if ( NameExpr * identifier = dynamic_cast<NameExpr *>(commaExpr->arg1 ) ) {
205                        return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
206                } else {
207                        SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); return nullptr;
208                } // if
209        } else {
210                SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); return nullptr;
211        } // if
212} // forCtrl
213
214bool forall = false, yyy = false;                                               // aggregate have one or more forall qualifiers ?
215
216// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
217#define YYLLOC_DEFAULT(Cur, Rhs, N)                                                                                             \
218if ( N ) {                                                                                                                                              \
219        (Cur).first_line   = YYRHSLOC( Rhs, 1 ).first_line;                                                     \
220        (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column;                                           \
221        (Cur).last_line    = YYRHSLOC( Rhs, N ).last_line;                                                      \
222        (Cur).last_column  = YYRHSLOC( Rhs, N ).last_column;                                            \
223        (Cur).filename     = YYRHSLOC( Rhs, 1 ).filename;                                                       \
224} else {                                                                                                                                                \
225        (Cur).first_line   = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line;            \
226        (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column;        \
227        (Cur).filename     = YYRHSLOC( Rhs, 0 ).filename;                                                       \
228}
229%}
230
231%define parse.error verbose
232
233// Types declaration for productions
234%union {
235        Token tok;
236        ParseNode * pn;
237        ExpressionNode * en;
238        DeclarationNode * decl;
239        AggregateDecl::Aggregate aggKey;
240        DeclarationNode::TypeClass tclass;
241        StatementNode * sn;
242        WaitForStmt * wfs;
243        Expression * constant;
244        IfCtrl * ifctl;
245        ForCtrl * fctl;
246        enum OperKinds compop;
247        LabelNode * label;
248        InitializerNode * in;
249        OperKinds op;
250        std::string * str;
251        bool flag;
252        CatchStmt::Kind catch_kind;
253        GenericExpr * genexpr;
254}
255
256//************************* TERMINAL TOKENS ********************************
257
258// keywords
259%token TYPEDEF
260%token EXTERN STATIC AUTO REGISTER
261%token THREADLOCAL                                                                              // C11
262%token INLINE FORTRAN                                                                   // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
263%token NORETURN                                                                                 // C11
264%token CONST VOLATILE
265%token RESTRICT                                                                                 // C99
266%token ATOMIC                                                                                   // C11
267%token FORALL MUTEX VIRTUAL COERCE                                              // CFA
268%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
269%token BOOL COMPLEX IMAGINARY                                                   // C99
270%token INT128 UINT128 uuFLOAT80 uuFLOAT128                              // GCC
271%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
272%token ZERO_T ONE_T                                                                             // CFA
273%token VALIST                                                                                   // GCC
274%token AUTO_TYPE                                                                                // GCC
275%token TYPEOF BASETYPEOF LABEL                                                  // GCC
276%token ENUM STRUCT UNION
277%token EXCEPTION                                                                                // CFA
278%token GENERATOR COROUTINE MONITOR THREAD                               // CFA
279%token OTYPE FTYPE DTYPE TTYPE TRAIT                                    // CFA
280%token SIZEOF OFFSETOF
281// %token SUSPEND RESUME                                                                        // CFA
282%token ATTRIBUTE EXTENSION                                                              // GCC
283%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
284%token CHOOSE DISABLE ENABLE FALLTHRU FALLTHROUGH TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT WITH WHEN WAITFOR // CFA
285%token ASM                                                                                              // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
286%token ALIGNAS ALIGNOF GENERIC STATICASSERT                             // C11
287
288// names and constants: lexer differentiates between identifier and typedef names
289%token<tok> IDENTIFIER                  QUOTED_IDENTIFIER               TYPEDEFname                             TYPEGENname
290%token<tok> TIMEOUT                             WOR
291%token<tok> INTEGERconstant             CHARACTERconstant               STRINGliteral
292%token<tok> DIRECTIVE
293// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
294// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
295// converted into the tuple index (.)(1). e.g., 3.x
296%token<tok>     FLOATING_DECIMALconstant        FLOATING_FRACTIONconstant       FLOATINGconstant
297
298// multi-character operators
299%token ARROW                                                                                    // ->
300%token ICR DECR                                                                                 // ++   --
301%token LS RS                                                                                    // <<   >>
302%token LE GE EQ NE                                                                              // <=   >=      ==      !=
303%token ANDAND OROR                                                                              // &&   ||
304%token ELLIPSIS                                                                                 // ...
305
306%token EXPassign        MULTassign      DIVassign       MODassign       // \=   *=      /=      %=
307%token PLUSassign       MINUSassign                                                     // +=   -=
308%token LSassign         RSassign                                                        // <<=  >>=
309%token ANDassign        ERassign        ORassign                                // &=   ^=      |=
310
311%token ErangeUpEq       ErangeDown      ErangeDownEq                    // ~=   -~      -~=
312%token ATassign                                                                                 // @=
313
314%type<tok> identifier
315%type<tok> identifier_or_type_name  attr_name
316%type<tok> quasi_keyword
317%type<constant> string_literal
318%type<str> string_literal_list
319
320// expressions
321%type<en> constant
322%type<en> tuple                                                 tuple_expression_list
323%type<op> ptrref_operator                               unary_operator                          assignment_operator
324%type<en> primary_expression                    postfix_expression                      unary_expression
325%type<en> cast_expression                               exponential_expression          multiplicative_expression       additive_expression
326%type<en> shift_expression                              relational_expression           equality_expression
327%type<en> AND_expression                                exclusive_OR_expression         inclusive_OR_expression
328%type<en> logical_AND_expression                logical_OR_expression
329%type<en> conditional_expression                constant_expression                     assignment_expression           assignment_expression_opt
330%type<en> comma_expression                              comma_expression_opt
331%type<en> argument_expression_list              argument_expression                     default_initialize_opt
332%type<ifctl> if_control_expression
333%type<fctl> for_control_expression              for_control_expression_list
334%type<compop> inclexcl
335%type<en> subrange
336%type<decl> asm_name_opt
337%type<en> asm_operands_opt                              asm_operands_list                       asm_operand
338%type<label> label_list
339%type<en> asm_clobbers_list_opt
340%type<flag> asm_volatile_opt
341%type<en> handler_predicate_opt
342%type<genexpr> generic_association              generic_assoc_list
343
344// statements
345%type<sn> statement                                             labeled_statement                       compound_statement
346%type<sn> statement_decl                                statement_decl_list                     statement_list_nodecl
347%type<sn> selection_statement                   if_statement
348%type<sn> switch_clause_list_opt                switch_clause_list
349%type<en> case_value
350%type<sn> case_clause                                   case_value_list                         case_label                                      case_label_list
351%type<sn> iteration_statement                   jump_statement
352%type<sn> expression_statement                  asm_statement
353%type<sn> with_statement
354%type<en> with_clause_opt
355%type<sn> exception_statement                   handler_clause                          finally_clause
356%type<catch_kind> handler_key
357%type<sn> mutex_statement
358%type<en> when_clause                                   when_clause_opt                         waitfor                                         timeout
359%type<sn> waitfor_statement
360%type<wfs> waitfor_clause
361
362// declarations
363%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
364%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
365%type<decl> abstract_parameter_declaration
366
367%type<aggKey> aggregate_key aggregate_data aggregate_control
368%type<decl> aggregate_type aggregate_type_nobody
369
370%type<decl> assertion assertion_list assertion_list_opt
371
372%type<en>   bit_subrange_size_opt bit_subrange_size
373
374%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
375
376%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
377
378%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
379%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
380
381%type<decl> elaborated_type elaborated_type_nobody
382
383%type<decl> enumerator_list enum_type enum_type_nobody
384%type<en> enumerator_value_opt
385
386%type<decl> external_definition external_definition_list external_definition_list_opt
387
388%type<decl> exception_declaration
389
390%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
391%type<en> field field_name_list field_name fraction_constants_opt
392
393%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
394
395%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
396%type<decl> identifier_list
397
398%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
399%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
400%type<decl> cfa_abstract_ptr cfa_abstract_tuple
401
402%type<decl> cfa_array_parameter_1st_dimension
403
404%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
405%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
406
407%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
408%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
409
410%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
411
412%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
413
414%type<decl> c_declaration static_assert
415%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
416%type<decl> KR_parameter_list KR_parameter_list_opt
417
418%type<decl> parameter_declaration parameter_list parameter_type_list_opt
419
420%type<decl> paren_identifier paren_type
421
422%type<decl> storage_class storage_class_list
423
424%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
425
426%type<tclass> type_class
427%type<decl> type_declarator type_declarator_name type_declaring_list
428
429%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
430%type<decl> typedef typedef_declaration typedef_expression
431
432%type<decl> variable_type_redeclarator type_ptr type_array type_function
433
434%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
435
436%type<decl> type type_no_function
437%type<decl> type_parameter type_parameter_list type_initializer_opt
438
439%type<en> type_parameters_opt type_list
440
441%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
442%type<decl> type_specifier type_specifier_nobody
443
444%type<decl> variable_declarator variable_ptr variable_array variable_function
445%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
446
447%type<decl> attribute_list_opt attribute_list attribute_name_list attribute attribute_name
448
449// initializers
450%type<in>  initializer initializer_list_opt initializer_opt
451
452// designators
453%type<en>  designator designator_list designation
454
455
456// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
457//   .---------.                                matches IF '(' comma_expression ')' statement . (reduce)
458//   if ( C ) S1 else S2
459//   `-----------------'                matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
460// Similar issues exit with the waitfor statement.
461
462// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
463// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
464%precedence THEN        // rule precedence for IF/WAITFOR statement
465%precedence WOR         // token precedence for start of WOR in WAITFOR statement
466%precedence TIMEOUT     // token precedence for start of TIMEOUT in WAITFOR statement
467%precedence ELSE        // token precedence for start of else clause in IF/WAITFOR statement
468
469// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
470//   forall( otype T ) struct Foo { T v; };
471//       .-----.                                matches pointer to function returning a generic (which is impossible without a type)
472//   Foo ( *fp )( int );
473//   `---'                                              matches start of TYPEGENname '('
474// must be:
475//   Foo( int ) ( *fp )( int );
476// The same problem occurs here:
477//   forall( otype T ) struct Foo { T v; } ( *fp )( int );
478// must be:
479//   forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
480
481// Order of these lines matters (low-to-high precedence).
482%precedence TYPEGENname
483%precedence '}'
484%precedence '('
485
486// %precedence RESUME
487// %precedence '{'
488// %precedence ')'
489
490%locations                                                                                              // support location tracking for error messages
491
492%start translation_unit                                                                 // parse-tree root
493
494%%
495//************************* Namespace Management ********************************
496
497// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
498// which are lexically identical.
499//
500//   typedef int foo; // identifier foo must now be scanned as TYPEDEFname
501//   foo f;           // to allow it to appear in this context
502//
503// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
504// between syntactic and semantic constructs.  Cforall compounds this problem by introducing type names local to the
505// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
506// generators" -- parameterized types.  This latter type name creates a third class of identifiers, "TYPEGENname", which
507// must be distinguished by the lexical scanner.
508//
509// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
510// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
511// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
512// each context that introduces a name scope, a new level is created in the type table and that level is popped on
513// exiting the scope.  Since type names can be local to a particular declaration, each declaration is itself a scope.
514// This requires distinguishing between type names that are local to the current declaration scope and those that
515// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
516//
517// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
518// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
519// around the list separator.
520//
521//  int f( forall(T) T (*f1) T , forall( S ) S (*f2)( S ) );
522//      push               pop   push                   pop
523
524push:
525                { typedefTable.enterScope(); }
526        ;
527
528pop:
529                { typedefTable.leaveScope(); }
530        ;
531
532//************************* CONSTANTS ********************************
533
534constant:
535                // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
536        INTEGERconstant                                                         { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
537        | FLOATING_DECIMALconstant                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
538        | FLOATING_FRACTIONconstant                                     { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
539        | FLOATINGconstant                                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
540        | CHARACTERconstant                                                     { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
541        ;
542
543quasi_keyword:                                                                                  // CFA
544        TIMEOUT
545        | WOR
546        ;
547
548identifier:
549        IDENTIFIER
550        | quasi_keyword
551        | '@'                                                                                           // CFA
552                { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
553        ;
554
555string_literal:
556        string_literal_list                                                     { $$ = build_constantStr( *$1 ); }
557        ;
558
559string_literal_list:                                                                    // juxtaposed strings are concatenated
560        STRINGliteral                                                           { $$ = $1; } // conversion from tok to str
561        | string_literal_list STRINGliteral
562                {
563                        if ( ! appendStr( *$1, *$2 ) ) YYERROR;         // append 2nd juxtaposed string to 1st
564                        delete $2;                                                                      // allocated by lexer
565                        $$ = $1;                                                                        // conversion from tok to str
566                }
567        ;
568
569//************************* EXPRESSIONS ********************************
570
571primary_expression:
572        IDENTIFIER                                                                                      // typedef name cannot be used as a variable name
573                { $$ = new ExpressionNode( build_varref( $1 ) ); }
574        | quasi_keyword
575                { $$ = new ExpressionNode( build_varref( $1 ) ); }
576        | tuple
577        | '(' comma_expression ')'
578                { $$ = $2; }
579        | '(' compound_statement ')'                                            // GCC, lambda expression
580                { $$ = new ExpressionNode( new StmtExpr( dynamic_cast< CompoundStmt * >(maybeMoveBuild< Statement >($2) ) ) ); }
581        | constant '`' IDENTIFIER                                                       // CFA, postfix call
582                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), $1 ) ); }
583        | string_literal '`' IDENTIFIER                                         // CFA, postfix call
584                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), new ExpressionNode( $1 ) ) ); }
585        | IDENTIFIER '`' IDENTIFIER                                                     // CFA, postfix call
586                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), new ExpressionNode( build_varref( $1 ) ) ) ); }
587        | tuple '`' IDENTIFIER                                                          // CFA, postfix call
588                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), $1 ) ); }
589        | '(' comma_expression ')' '`' IDENTIFIER                       // CFA, postfix call
590                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $5 ) ), $2 ) ); }
591        | type_name '.' identifier                                                      // CFA, nested type
592                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
593        | type_name '.' '[' field_name_list ']'                         // CFA, nested type / tuple field selector
594                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
595        | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
596                {
597                        // add the missing control expression to the GenericExpr and return it
598                        $5->control = maybeMoveBuild<Expression>( $3 );
599                        $$ = new ExpressionNode( $5 );
600                }
601        // | RESUME '(' comma_expression ')'
602        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
603        // | RESUME '(' comma_expression ')' compound_statement
604        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
605        ;
606
607generic_assoc_list:                                                                             // C11
608        generic_association
609        | generic_assoc_list ',' generic_association
610                {
611                        // steal the association node from the singleton and delete the wrapper
612                        $1->associations.splice($1->associations.end(), $3->associations);
613                        delete $3;
614                        $$ = $1;
615                }
616        ;
617
618generic_association:                                                                    // C11
619        type_no_function ':' assignment_expression
620                {
621                        // create a GenericExpr wrapper with one association pair
622                        $$ = new GenericExpr( nullptr, { { maybeMoveBuildType($1), maybeMoveBuild<Expression>($3) } } );
623                }
624        | DEFAULT ':' assignment_expression
625                { $$ = new GenericExpr( nullptr, { { maybeMoveBuild<Expression>($3) } } ); }
626        ;
627
628postfix_expression:
629        primary_expression
630        | postfix_expression '[' assignment_expression ']'
631                // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
632                // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
633                // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
634                // equivalent to the old x[i,j].
635                { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
636        | postfix_expression '{' argument_expression_list '}' // CFA, constructor call
637                {
638                        Token fn;
639                        fn.str = new std::string( "?{}" );                      // location undefined - use location of '{'?
640                        $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
641                }
642        | postfix_expression '(' argument_expression_list ')'
643                { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
644        | postfix_expression '.' identifier
645                { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
646        | postfix_expression '.' INTEGERconstant                        // CFA, tuple index
647                { $$ = new ExpressionNode( build_fieldSel( $1, build_constantInteger( *$3 ) ) ); }
648        | postfix_expression FLOATING_FRACTIONconstant          // CFA, tuple index
649                { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
650        | postfix_expression '.' '[' field_name_list ']'        // CFA, tuple field selector
651                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
652        | postfix_expression '.' aggregate_control
653                { $$ = new ExpressionNode( build_keyword_cast( $3, $1 ) ); }
654        | postfix_expression ARROW identifier
655                { $$ = new ExpressionNode( build_pfieldSel( $1, build_varref( $3 ) ) ); }
656        | postfix_expression ARROW INTEGERconstant                      // CFA, tuple index
657                { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
658        | postfix_expression ARROW '[' field_name_list ']'      // CFA, tuple field selector
659                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
660        | postfix_expression ICR
661                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
662        | postfix_expression DECR
663                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
664        | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
665                { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
666        | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
667                { $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
668        | '^' primary_expression '{' argument_expression_list '}' // CFA
669                {
670                        Token fn;
671                        fn.str = new string( "^?{}" );                          // location undefined
672                        $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
673                }
674        ;
675
676argument_expression_list:
677        // empty
678                { $$ = nullptr; }
679        | argument_expression
680        | argument_expression_list ',' argument_expression
681                { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
682        ;
683
684argument_expression:
685        '@'                                                                                                     // CFA, default parameter
686                { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
687                // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
688        | assignment_expression
689        ;
690
691field_name_list:                                                                                // CFA, tuple field selector
692        field
693        | field_name_list ',' field                                     { $$ = (ExpressionNode *)$1->set_last( $3 ); }
694        ;
695
696field:                                                                                                  // CFA, tuple field selector
697        field_name
698        | FLOATING_DECIMALconstant field
699                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
700        | FLOATING_DECIMALconstant '[' field_name_list ']'
701                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $3 ) ) ); }
702        | field_name '.' field
703                { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
704        | field_name '.' '[' field_name_list ']'
705                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
706        | field_name ARROW field
707                { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
708        | field_name ARROW '[' field_name_list ']'
709                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
710        ;
711
712field_name:
713        INTEGERconstant fraction_constants_opt
714                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
715        | FLOATINGconstant fraction_constants_opt
716                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
717        | identifier fraction_constants_opt
718                {
719                        $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
720                }
721        ;
722
723fraction_constants_opt:
724        // empty
725                { $$ = nullptr; }
726        | fraction_constants_opt FLOATING_FRACTIONconstant
727                {
728                        Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
729                        $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1,  constant ) ) : new ExpressionNode( constant );
730                }
731        ;
732
733unary_expression:
734        postfix_expression
735                // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
736                // semantics checks, e.g., ++3, 3--, *3, &&3
737        | constant
738        | string_literal
739                { $$ = new ExpressionNode( $1 ); }
740        | EXTENSION cast_expression                                                     // GCC
741                { $$ = $2->set_extension( true ); }
742                // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
743                //              { * X; }         // dereference X
744                //              { * int X; } // CFA declaration of pointer to int
745        | ptrref_operator cast_expression                                       // CFA
746                {
747                        switch ( $1 ) {
748                          case OperKinds::AddressOf:
749                                $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) );
750                                break;
751                          case OperKinds::PointTo:
752                                $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
753                                break;
754                          case OperKinds::And:
755                                $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) ) );
756                                break;
757                          default:
758                                assert( false );
759                        }
760                }
761        | unary_operator cast_expression
762                { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
763        | ICR unary_expression
764                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
765        | DECR unary_expression
766                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
767        | SIZEOF unary_expression
768                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
769        | SIZEOF '(' type_no_function ')'
770                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
771        | ALIGNOF unary_expression                                                      // GCC, variable alignment
772                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
773        | ALIGNOF '(' type_no_function ')'                                      // GCC, type alignment
774                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
775        | OFFSETOF '(' type_no_function ',' identifier ')'
776                { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
777        ;
778
779ptrref_operator:
780        '*'                                                                                     { $$ = OperKinds::PointTo; }
781        | '&'                                                                           { $$ = OperKinds::AddressOf; }
782                // GCC, address of label must be handled by semantic check for ref,ref,label
783        | ANDAND                                                                        { $$ = OperKinds::And; }
784        ;
785
786unary_operator:
787        '+'                                                                                     { $$ = OperKinds::UnPlus; }
788        | '-'                                                                           { $$ = OperKinds::UnMinus; }
789        | '!'                                                                           { $$ = OperKinds::Neg; }
790        | '~'                                                                           { $$ = OperKinds::BitNeg; }
791        ;
792
793cast_expression:
794        unary_expression
795        | '(' type_no_function ')' cast_expression
796                { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
797        | '(' aggregate_control '&' ')' cast_expression         // CFA
798                { $$ = new ExpressionNode( build_keyword_cast( $2, $5 ) ); }
799                // VIRTUAL cannot be opt because of look ahead issues
800        | '(' VIRTUAL ')' cast_expression                                       // CFA
801                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $4 ), maybeMoveBuildType( nullptr ) ) ); }
802        | '(' VIRTUAL type_no_function ')' cast_expression      // CFA
803                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $5 ), maybeMoveBuildType( $3 ) ) ); }
804        | '(' RETURN type_no_function ')' cast_expression       // CFA
805                { SemanticError( yylloc, "Return cast is currently unimplemented." ); $$ = nullptr; }
806        | '(' COERCE type_no_function ')' cast_expression       // CFA
807                { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
808        | '(' qualifier_cast_list ')' cast_expression           // CFA
809                { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
810//      | '(' type_no_function ')' tuple
811//              { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
812        ;
813
814qualifier_cast_list:
815        cast_modifier type_qualifier_name
816        | cast_modifier MUTEX
817        | qualifier_cast_list cast_modifier type_qualifier_name
818        | qualifier_cast_list cast_modifier MUTEX
819        ;
820
821cast_modifier:
822        '-'
823        | '+'
824        ;
825
826exponential_expression:
827        cast_expression
828        | exponential_expression '\\' cast_expression
829                { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
830        ;
831
832multiplicative_expression:
833        exponential_expression
834        | multiplicative_expression '*' exponential_expression
835                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
836        | multiplicative_expression '/' exponential_expression
837                { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
838        | multiplicative_expression '%' exponential_expression
839                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
840        ;
841
842additive_expression:
843        multiplicative_expression
844        | additive_expression '+' multiplicative_expression
845                { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
846        | additive_expression '-' multiplicative_expression
847                { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
848        ;
849
850shift_expression:
851        additive_expression
852        | shift_expression LS additive_expression
853                { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
854        | shift_expression RS additive_expression
855                { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
856        ;
857
858relational_expression:
859        shift_expression
860        | relational_expression '<' shift_expression
861                { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
862        | relational_expression '>' shift_expression
863                { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
864        | relational_expression LE shift_expression
865                { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
866        | relational_expression GE shift_expression
867                { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
868        ;
869
870equality_expression:
871        relational_expression
872        | equality_expression EQ relational_expression
873                { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
874        | equality_expression NE relational_expression
875                { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
876        ;
877
878AND_expression:
879        equality_expression
880        | AND_expression '&' equality_expression
881                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
882        ;
883
884exclusive_OR_expression:
885        AND_expression
886        | exclusive_OR_expression '^' AND_expression
887                { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
888        ;
889
890inclusive_OR_expression:
891        exclusive_OR_expression
892        | inclusive_OR_expression '|' exclusive_OR_expression
893                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
894        ;
895
896logical_AND_expression:
897        inclusive_OR_expression
898        | logical_AND_expression ANDAND inclusive_OR_expression
899                { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
900        ;
901
902logical_OR_expression:
903        logical_AND_expression
904        | logical_OR_expression OROR logical_AND_expression
905                { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
906        ;
907
908conditional_expression:
909        logical_OR_expression
910        | logical_OR_expression '?' comma_expression ':' conditional_expression
911                { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
912                // FIX ME: computes $1 twice
913        | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
914                { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
915        ;
916
917constant_expression:
918        conditional_expression
919        ;
920
921assignment_expression:
922                // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
923        conditional_expression
924        | unary_expression assignment_operator assignment_expression
925                { $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) ); }
926        | unary_expression '=' '{' initializer_list_opt comma_opt '}'
927                { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
928        ;
929
930assignment_expression_opt:
931        // empty
932                { $$ = nullptr; }
933        | assignment_expression
934        ;
935
936assignment_operator:
937        '='                                                                                     { $$ = OperKinds::Assign; }
938        | ATassign                                                                      { $$ = OperKinds::AtAssn; }
939        | EXPassign                                                                     { $$ = OperKinds::ExpAssn; }
940        | MULTassign                                                            { $$ = OperKinds::MulAssn; }
941        | DIVassign                                                                     { $$ = OperKinds::DivAssn; }
942        | MODassign                                                                     { $$ = OperKinds::ModAssn; }
943        | PLUSassign                                                            { $$ = OperKinds::PlusAssn; }
944        | MINUSassign                                                           { $$ = OperKinds::MinusAssn; }
945        | LSassign                                                                      { $$ = OperKinds::LSAssn; }
946        | RSassign                                                                      { $$ = OperKinds::RSAssn; }
947        | ANDassign                                                                     { $$ = OperKinds::AndAssn; }
948        | ERassign                                                                      { $$ = OperKinds::ERAssn; }
949        | ORassign                                                                      { $$ = OperKinds::OrAssn; }
950        ;
951
952tuple:                                                                                                  // CFA, tuple
953                // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
954                // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
955//      '[' ']'
956//              { $$ = new ExpressionNode( build_tuple() ); }
957//      | '[' push assignment_expression pop ']'
958//              { $$ = new ExpressionNode( build_tuple( $3 ) ); }
959        '[' ',' tuple_expression_list ']'
960                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
961        | '[' push assignment_expression pop ',' tuple_expression_list ']'
962                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)$3->set_last( $6 ) ) ); }
963        ;
964
965tuple_expression_list:
966        assignment_expression_opt
967        | tuple_expression_list ',' assignment_expression_opt
968                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
969        ;
970
971comma_expression:
972        assignment_expression
973        | comma_expression ',' assignment_expression
974                { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
975        ;
976
977comma_expression_opt:
978        // empty
979                { $$ = nullptr; }
980        | comma_expression
981        ;
982
983//*************************** STATEMENTS *******************************
984
985statement:
986        labeled_statement
987        | compound_statement
988        | expression_statement
989        | selection_statement
990        | iteration_statement
991        | jump_statement
992        | with_statement
993        | mutex_statement
994        | waitfor_statement
995        | exception_statement
996        | enable_disable_statement
997                { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
998        | asm_statement
999        | DIRECTIVE
1000                { $$ = new StatementNode( build_directive( $1 ) ); }
1001        ;
1002
1003labeled_statement:
1004                // labels cannot be identifiers 0 or 1
1005        identifier_or_type_name ':' attribute_list_opt statement
1006                { $$ = $4->add_label( $1, $3 ); }
1007        ;
1008
1009compound_statement:
1010        '{' '}'
1011                { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
1012        | '{' push
1013          local_label_declaration_opt                                           // GCC, local labels
1014          statement_decl_list                                                           // C99, intermix declarations and statements
1015          pop '}'
1016                { $$ = new StatementNode( build_compound( $4 ) ); }
1017        ;
1018
1019statement_decl_list:                                                                    // C99
1020        statement_decl
1021        | statement_decl_list statement_decl
1022                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1023        ;
1024
1025statement_decl:
1026        declaration                                                                                     // CFA, new & old style declarations
1027                { $$ = new StatementNode( $1 ); }
1028        | EXTENSION declaration                                                         // GCC
1029                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1030        | function_definition
1031                { $$ = new StatementNode( $1 ); }
1032        | EXTENSION function_definition                                         // GCC
1033                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1034        | statement
1035        ;
1036
1037statement_list_nodecl:
1038        statement
1039        | statement_list_nodecl statement
1040                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1041        ;
1042
1043expression_statement:
1044        comma_expression_opt ';'
1045                { $$ = new StatementNode( build_expr( $1 ) ); }
1046        ;
1047
1048selection_statement:
1049                        // pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1050                        // the inherent S/R conflict with THEN/ELSE.
1051        push if_statement pop
1052                { $$ = $2; }
1053        | SWITCH '(' comma_expression ')' case_clause
1054                { $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
1055        | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1056                {
1057                        StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
1058                        // The semantics of the declaration list is changed to include associated initialization, which is performed
1059                        // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1060                        // statement around the switch.  Statements after the initial declaration list can never be executed, and
1061                        // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1062                        // statement.
1063                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1064                }
1065        | CHOOSE '(' comma_expression ')' case_clause           // CFA
1066                { $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
1067        | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1068                {
1069                        StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
1070                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1071                }
1072        ;
1073
1074if_statement:
1075        IF '(' if_control_expression ')' statement                      %prec THEN
1076                // explicitly deal with the shift/reduce conflict on if/else
1077                { $$ = new StatementNode( build_if( $3, $5, nullptr ) ); }
1078        | IF '(' if_control_expression ')' statement ELSE statement
1079                { $$ = new StatementNode( build_if( $3, $5, $7 ) ); }
1080        ;
1081
1082if_control_expression:
1083        comma_expression
1084                { $$ = new IfCtrl( nullptr, $1 ); }
1085        | c_declaration                                                                         // no semi-colon
1086                { $$ = new IfCtrl( $1, nullptr ); }
1087        | cfa_declaration                                                                       // no semi-colon
1088                { $$ = new IfCtrl( $1, nullptr ); }
1089        | declaration comma_expression                                          // semi-colon separated
1090                { $$ = new IfCtrl( $1, $2 ); }
1091        ;
1092
1093// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1094// clause allows a list of values and subranges.
1095
1096case_value:                                                                                             // CFA
1097        constant_expression                                                     { $$ = $1; }
1098        | constant_expression ELLIPSIS constant_expression      // GCC, subrange
1099                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
1100        | subrange                                                                                      // CFA, subrange
1101        ;
1102
1103case_value_list:                                                                                // CFA
1104        case_value                                                                      { $$ = new StatementNode( build_case( $1 ) ); }
1105                // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1106        | case_value_list ',' case_value                        { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
1107        ;
1108
1109case_label:                                                                                             // CFA
1110        CASE case_value_list ':'                                        { $$ = $2; }
1111        | DEFAULT ':'                                                           { $$ = new StatementNode( build_default() ); }
1112                // A semantic check is required to ensure only one default clause per switch/choose statement.
1113        ;
1114
1115//label_list_opt:
1116//      // empty
1117//      | identifier_or_type_name ':'
1118//      | label_list_opt identifier_or_type_name ':'
1119//      ;
1120
1121case_label_list:                                                                                // CFA
1122        case_label
1123        | case_label_list case_label                            { $$ = (StatementNode *)( $1->set_last( $2 )); }
1124        ;
1125
1126case_clause:                                                                                    // CFA
1127        case_label_list statement                                       { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1128        ;
1129
1130switch_clause_list_opt:                                                                 // CFA
1131        // empty
1132                { $$ = nullptr; }
1133        | switch_clause_list
1134        ;
1135
1136switch_clause_list:                                                                             // CFA
1137        case_label_list statement_list_nodecl
1138                { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1139        | switch_clause_list case_label_list statement_list_nodecl
1140                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1141        ;
1142
1143iteration_statement:
1144        WHILE '(' push if_control_expression ')' statement pop
1145                { $$ = new StatementNode( build_while( $4, $6 ) ); }
1146        | WHILE '(' ')' statement                                                       // CFA => while ( 1 )
1147                { $$ = new StatementNode( build_while( new IfCtrl( nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ), $4 ) ); }
1148        | DO statement WHILE '(' comma_expression ')' ';'
1149                { $$ = new StatementNode( build_do_while( $5, $2 ) ); }
1150        | DO statement WHILE '(' ')' ';'                                        // CFA => do while( 1 )
1151                { $$ = new StatementNode( build_do_while( new ExpressionNode( build_constantInteger( *new string( "1" ) ) ), $2 ) ); }
1152        | FOR '(' push for_control_expression_list ')' statement pop
1153                { $$ = new StatementNode( build_for( $4, $6 ) ); }
1154        | FOR '(' ')' statement                                                         // CFA => for ( ;; )
1155                { $$ = new StatementNode( build_for( new ForCtrl( (ExpressionNode * )nullptr, (ExpressionNode * )nullptr, (ExpressionNode * )nullptr ), $4 ) ); }
1156        ;
1157
1158for_control_expression_list:
1159        for_control_expression
1160        | for_control_expression_list ':' for_control_expression
1161                // ForCtrl + ForCtrl:
1162                //    init + init => multiple declaration statements that are hoisted
1163                //    condition + condition => (expression) && (expression)
1164                //    change + change => (expression), (expression)
1165                {
1166                        $1->init->set_last( $3->init );
1167                        if ( $1->condition ) {
1168                                if ( $3->condition ) {
1169                                        $1->condition->expr.reset( new LogicalExpr( $1->condition->expr.release(), $3->condition->expr.release(), true ) );
1170                                } // if
1171                        } else $1->condition = $3->condition;
1172                        if ( $1->change ) {
1173                                if ( $3->change ) {
1174                                        $1->change->expr.reset( new CommaExpr( $1->change->expr.release(), $3->change->expr.release() ) );
1175                                } // if
1176                        } else $1->change = $3->change;
1177                        $$ = $1;
1178                }
1179        ;
1180
1181for_control_expression:
1182        ';' comma_expression_opt ';' comma_expression_opt
1183                { $$ = new ForCtrl( (ExpressionNode * )nullptr, $2, $4 ); }
1184        | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1185                { $$ = new ForCtrl( $1, $3, $5 ); }
1186        | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1187                { $$ = new ForCtrl( $1, $2, $4 ); }
1188
1189        | comma_expression                                                                      // CFA
1190                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1191                                                OperKinds::LThan, $1->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1192        | comma_expression inclexcl comma_expression            // CFA
1193                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1194        | comma_expression inclexcl comma_expression '~' comma_expression // CFA
1195                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, $5 ); }
1196        | comma_expression ';' comma_expression                         // CFA
1197                { $$ = forCtrl( $3, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1198                                                OperKinds::LThan, $3->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1199        | comma_expression ';' '=' comma_expression                             // CFA
1200                { $$ = forCtrl( $4, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1201                                                OperKinds::LEThan, $4->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1202        | comma_expression ';' comma_expression inclexcl comma_expression // CFA
1203                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1204        | comma_expression ';' comma_expression inclexcl comma_expression '~' comma_expression // CFA
1205                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, $7 ); }
1206
1207                // There is a S/R conflicit if ~ and -~ are factored out.
1208        | comma_expression ';' comma_expression '~' '@'         // CFA
1209                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1210        | comma_expression ';' comma_expression ErangeDown '@' // CFA
1211                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1212        | comma_expression ';' comma_expression '~' '@' '~' comma_expression // CFA
1213                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, $7 ); }
1214        | comma_expression ';' comma_expression ErangeDown '@' '~' comma_expression // CFA
1215                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, $7 ); }
1216        | comma_expression ';' comma_expression '~' '@' '~' '@' // CFA
1217                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, nullptr ); }
1218        ;
1219
1220inclexcl:
1221        '~'
1222                { $$ = OperKinds::LThan; }
1223        | ErangeUpEq
1224                { $$ = OperKinds::LEThan; }
1225        | ErangeDown
1226                { $$ = OperKinds::GThan; }
1227        | ErangeDownEq
1228                { $$ = OperKinds::GEThan; }
1229        ;
1230
1231jump_statement:
1232        GOTO identifier_or_type_name ';'
1233                { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1234        | GOTO '*' comma_expression ';'                                         // GCC, computed goto
1235                // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1236                // whereas normal operator precedence yields goto (*i)+3;
1237                { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1238                // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1239    | fall_through_name ';'                                                             // CFA
1240                { $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1241    | fall_through_name identifier_or_type_name ';'             // CFA
1242                { $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1243        | fall_through_name DEFAULT ';'                                         // CFA
1244                { $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1245        | CONTINUE ';'
1246                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1247                { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1248        | CONTINUE identifier_or_type_name ';'                          // CFA, multi-level continue
1249                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1250                // the target of the transfer appears only at the start of an iteration statement.
1251                { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1252        | BREAK ';'
1253                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1254                { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1255        | BREAK identifier_or_type_name ';'                                     // CFA, multi-level exit
1256                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1257                // the target of the transfer appears only at the start of an iteration statement.
1258                { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1259        | RETURN comma_expression_opt ';'
1260                { $$ = new StatementNode( build_return( $2 ) ); }
1261        | RETURN '{' initializer_list_opt comma_opt '}' ';'
1262                { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1263        // | SUSPEND ';'
1264        //      { SemanticError( yylloc, "Suspend expression is currently unimplemented." ); $$ = nullptr; }
1265        // | SUSPEND compound_statement ';'
1266        //      { SemanticError( yylloc, "Suspend expression is currently unimplemented." ); $$ = nullptr; }
1267        | THROW assignment_expression_opt ';'                           // handles rethrow
1268                { $$ = new StatementNode( build_throw( $2 ) ); }
1269        | THROWRESUME assignment_expression_opt ';'                     // handles reresume
1270                { $$ = new StatementNode( build_resume( $2 ) ); }
1271        | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1272                { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1273        ;
1274
1275fall_through_name:                                                                              // CFA
1276        FALLTHRU
1277        | FALLTHROUGH
1278        ;
1279
1280with_statement:
1281        WITH '(' tuple_expression_list ')' statement
1282                {
1283                        $$ = new StatementNode( build_with( $3, $5 ) );
1284                }
1285        ;
1286
1287// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1288mutex_statement:
1289        MUTEX '(' argument_expression_list ')' statement
1290                { SemanticError( yylloc, "Mutex statement is currently unimplemented." ); $$ = nullptr; }
1291        ;
1292
1293when_clause:
1294        WHEN '(' comma_expression ')'                           { $$ = $3; }
1295        ;
1296
1297when_clause_opt:
1298        // empty
1299                { $$ = nullptr; }
1300        | when_clause
1301        ;
1302
1303waitfor:
1304        WAITFOR '(' cast_expression ')'
1305                { $$ = $3; }
1306        | WAITFOR '(' cast_expression ',' argument_expression_list ')'
1307                { $$ = (ExpressionNode *)$3->set_last( $5 ); }
1308        ;
1309
1310timeout:
1311        TIMEOUT '(' comma_expression ')'                        { $$ = $3; }
1312        ;
1313
1314waitfor_clause:
1315        when_clause_opt waitfor statement                                       %prec THEN
1316                { $$ = build_waitfor( $2, $3, $1 ); }
1317        | when_clause_opt waitfor statement WOR waitfor_clause
1318                { $$ = build_waitfor( $2, $3, $1, $5 ); }
1319        | when_clause_opt timeout statement                                     %prec THEN
1320                { $$ = build_waitfor_timeout( $2, $3, $1 ); }
1321        | when_clause_opt ELSE statement
1322                { $$ = build_waitfor_timeout( nullptr, $3, $1 ); }
1323                // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1324        | when_clause_opt timeout statement WOR ELSE statement
1325                { SemanticError( yylloc, "else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1326        | when_clause_opt timeout statement WOR when_clause ELSE statement
1327                { $$ = build_waitfor_timeout( $2, $3, $1, $7, $5 ); }
1328        ;
1329
1330waitfor_statement:
1331        when_clause_opt waitfor statement                                       %prec THEN
1332                { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1333        | when_clause_opt waitfor statement WOR waitfor_clause
1334                { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1335        ;
1336
1337exception_statement:
1338        TRY compound_statement handler_clause
1339                { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1340        | TRY compound_statement finally_clause
1341                { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1342        | TRY compound_statement handler_clause finally_clause
1343                { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1344        ;
1345
1346handler_clause:
1347        handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1348                { $$ = new StatementNode( build_catch( $1, $4, $6, $8 ) ); }
1349        | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1350                { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $5, $7, $9 ) ) ); }
1351        ;
1352
1353handler_predicate_opt:
1354        // empty
1355                { $$ = nullptr; }
1356        | ';' conditional_expression                            { $$ = $2; }
1357        ;
1358
1359handler_key:
1360        CATCH                                                                           { $$ = CatchStmt::Terminate; }
1361        | CATCHRESUME                                                           { $$ = CatchStmt::Resume; }
1362        ;
1363
1364finally_clause:
1365        FINALLY compound_statement                                      { $$ = new StatementNode( build_finally( $2 ) ); }
1366        ;
1367
1368exception_declaration:
1369                // No SUE declaration in parameter list.
1370        type_specifier_nobody
1371        | type_specifier_nobody declarator
1372                { $$ = $2->addType( $1 ); }
1373        | type_specifier_nobody variable_abstract_declarator
1374                { $$ = $2->addType( $1 ); }
1375        | cfa_abstract_declarator_tuple identifier                      // CFA
1376                { $$ = $1->addName( $2 ); }
1377        | cfa_abstract_declarator_tuple                                         // CFA
1378        ;
1379
1380enable_disable_statement:
1381        enable_disable_key identifier_list compound_statement
1382        ;
1383
1384enable_disable_key:
1385        ENABLE
1386        | DISABLE
1387        ;
1388
1389asm_statement:
1390        ASM asm_volatile_opt '(' string_literal ')' ';'
1391                { $$ = new StatementNode( build_asm( $2, $4, 0 ) ); }
1392        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1393                { $$ = new StatementNode( build_asm( $2, $4, $6 ) ); }
1394        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1395                { $$ = new StatementNode( build_asm( $2, $4, $6, $8 ) ); }
1396        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1397                { $$ = new StatementNode( build_asm( $2, $4, $6, $8, $10 ) ); }
1398        | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1399                { $$ = new StatementNode( build_asm( $2, $5, 0, $8, $10, $12 ) ); }
1400        ;
1401
1402asm_volatile_opt:                                                                               // GCC
1403        // empty
1404                { $$ = false; }
1405        | VOLATILE
1406                { $$ = true; }
1407        ;
1408
1409asm_operands_opt:                                                                               // GCC
1410        // empty
1411                { $$ = nullptr; }                                                               // use default argument
1412        | asm_operands_list
1413        ;
1414
1415asm_operands_list:                                                                              // GCC
1416        asm_operand
1417        | asm_operands_list ',' asm_operand
1418                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
1419        ;
1420
1421asm_operand:                                                                                    // GCC
1422        string_literal '(' constant_expression ')'
1423                { $$ = new ExpressionNode( new AsmExpr( nullptr, $1, maybeMoveBuild< Expression >( $3 ) ) ); }
1424        | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1425                { $$ = new ExpressionNode( new AsmExpr( $2, $4, maybeMoveBuild< Expression >( $6 ) ) ); }
1426        ;
1427
1428asm_clobbers_list_opt:                                                                  // GCC
1429        // empty
1430                { $$ = nullptr; }                                                               // use default argument
1431        | string_literal
1432                { $$ = new ExpressionNode( $1 ); }
1433        | asm_clobbers_list_opt ',' string_literal
1434                // set_last returns ParseNode *
1435                { $$ = (ExpressionNode *)$1->set_last( new ExpressionNode( $3 ) ); }
1436        ;
1437
1438label_list:
1439        identifier
1440                {
1441                        $$ = new LabelNode(); $$->labels.push_back( *$1 );
1442                        delete $1;                                                                      // allocated by lexer
1443                }
1444        | label_list ',' identifier
1445                {
1446                        $$ = $1; $1->labels.push_back( *$3 );
1447                        delete $3;                                                                      // allocated by lexer
1448                }
1449        ;
1450
1451//******************************* DECLARATIONS *********************************
1452
1453declaration_list_opt:                                                                   // used at beginning of switch statement
1454        // empty
1455                { $$ = nullptr; }
1456        | declaration_list
1457        ;
1458
1459declaration_list:
1460        declaration
1461        | declaration_list declaration
1462                { $$ = $1->appendList( $2 ); }
1463        ;
1464
1465KR_parameter_list_opt:                                                                  // used to declare parameter types in K&R style functions
1466        // empty
1467                { $$ = nullptr; }
1468        | KR_parameter_list
1469        ;
1470
1471KR_parameter_list:
1472        push c_declaration pop ';'
1473                { $$ = $2; }
1474        | KR_parameter_list push c_declaration pop ';'
1475                { $$ = $1->appendList( $3 ); }
1476        ;
1477
1478local_label_declaration_opt:                                                    // GCC, local label
1479        // empty
1480        | local_label_declaration_list
1481        ;
1482
1483local_label_declaration_list:                                                   // GCC, local label
1484        LABEL local_label_list ';'
1485        | local_label_declaration_list LABEL local_label_list ';'
1486        ;
1487
1488local_label_list:                                                                               // GCC, local label
1489        identifier_or_type_name
1490        | local_label_list ',' identifier_or_type_name
1491        ;
1492
1493declaration:                                                                                    // old & new style declarations
1494        c_declaration ';'
1495        | cfa_declaration ';'                                                           // CFA
1496        | static_assert                                                                         // C11
1497        ;
1498
1499static_assert:
1500        STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1501                { $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1502        | STATICASSERT '(' constant_expression ')' ';'          // CFA
1503                { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( *new string( "\"\"" ) ) ); }
1504
1505// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1506// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1507// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1508// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1509// the declaration list (as in Pascal).  ANSI C and the new CFA declarations may appear together in the same program
1510// block, but cannot be mixed within a specific declaration.
1511//
1512//                      CFA                                     C
1513//              [10] int x;                     int x[10];              // array of 10 integers
1514//              [10] * char y;          char *y[10];    // array of 10 pointers to char
1515
1516cfa_declaration:                                                                                // CFA
1517        cfa_variable_declaration
1518        | cfa_typedef_declaration
1519        | cfa_function_declaration
1520        | type_declaring_list
1521        | trait_specifier
1522        ;
1523
1524cfa_variable_declaration:                                                               // CFA
1525        cfa_variable_specifier initializer_opt
1526                { $$ = $1->addInitializer( $2 ); }
1527        | declaration_qualifier_list cfa_variable_specifier initializer_opt
1528                // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1529                // them as a type_qualifier cannot appear in that context.
1530                { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1531        | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1532                { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1533        ;
1534
1535cfa_variable_specifier:                                                                 // CFA
1536                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1537                // storage-class
1538        cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1539                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1540        | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1541                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1542        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1543                { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1544        ;
1545
1546cfa_function_declaration:                                                               // CFA
1547        cfa_function_specifier
1548        | type_qualifier_list cfa_function_specifier
1549                { $$ = $2->addQualifiers( $1 ); }
1550        | declaration_qualifier_list cfa_function_specifier
1551                { $$ = $2->addQualifiers( $1 ); }
1552        | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1553                { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1554        | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1555                {
1556                        // Append the return type at the start (left-hand-side) to each identifier in the list.
1557                        DeclarationNode * ret = new DeclarationNode;
1558                        ret->type = maybeClone( $1->type->base );
1559                        $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1560                }
1561        ;
1562
1563cfa_function_specifier:                                                                 // CFA
1564//      '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1565//              {
1566//                      $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1567//              }
1568//      '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1569//              {
1570//                      typedefTable.setNextIdentifier( *$5 );
1571//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1572//              }
1573//      | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1574//              {
1575//                      typedefTable.setNextIdentifier( *$5 );
1576//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1577//              }
1578//      | '[' ']' typegen_name
1579                // identifier_or_type_name must be broken apart because of the sequence:
1580                //
1581                //   '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1582                //   '[' ']' type_specifier
1583                //
1584                // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1585                // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1586        cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1587                // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1588                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 ); }
1589        | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1590                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 ); }
1591        ;
1592
1593cfa_function_return:                                                                    // CFA
1594        '[' push cfa_parameter_list pop ']'
1595                { $$ = DeclarationNode::newTuple( $3 ); }
1596        | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1597                // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
1598                { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1599        ;
1600
1601cfa_typedef_declaration:                                                                // CFA
1602        TYPEDEF cfa_variable_specifier
1603                {
1604                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "1" );
1605                        $$ = $2->addTypedef();
1606                }
1607        | TYPEDEF cfa_function_specifier
1608                {
1609                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "2" );
1610                        $$ = $2->addTypedef();
1611                }
1612        | cfa_typedef_declaration pop ',' push identifier
1613                {
1614                        typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "3" );
1615                        $$ = $1->appendList( $1->cloneType( $5 ) );
1616                }
1617        ;
1618
1619// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1620// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1621
1622typedef_declaration:
1623        TYPEDEF type_specifier declarator
1624                {
1625                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "4" );
1626                        $$ = $3->addType( $2 )->addTypedef();
1627                }
1628        | typedef_declaration pop ',' push declarator
1629                {
1630                        typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname, "5" );
1631                        $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1632                }
1633        | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1634                {
1635                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "6" );
1636                        $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1637                }
1638        | type_specifier TYPEDEF declarator
1639                {
1640                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "7" );
1641                        $$ = $3->addType( $1 )->addTypedef();
1642                }
1643        | type_specifier TYPEDEF type_qualifier_list declarator
1644                {
1645                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "8" );
1646                        $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1647                }
1648        ;
1649
1650typedef_expression:
1651                // GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1652        TYPEDEF identifier '=' assignment_expression
1653                {
1654                        // $$ = DeclarationNode::newName( 0 );                  // unimplemented
1655                        SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1656                }
1657        | typedef_expression pop ',' push identifier '=' assignment_expression
1658                {
1659                        // $$ = DeclarationNode::newName( 0 );                  // unimplemented
1660                        SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1661                }
1662        ;
1663
1664//c_declaration:
1665//      declaring_list pop ';'
1666//      | typedef_declaration pop ';'
1667//      | typedef_expression pop ';'                                            // GCC, naming expression type
1668//      | sue_declaration_specifier pop ';'
1669//      ;
1670//
1671//declaring_list:
1672//              // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1673//              // storage-class
1674//       declarator asm_name_opt initializer_opt
1675//              {
1676//                      typedefTable.addToEnclosingScope( IDENTIFIER );
1677//                      $$ = ( $2->addType( $1 ))->addAsmName( $3 )->addInitializer( $4 );
1678//              }
1679//      | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1680//              {
1681//                      typedefTable.addToEnclosingScope( IDENTIFIER );
1682//                      $$ = $1->appendList( $1->cloneBaseType( $4->addAsmName( $5 )->addInitializer( $6 ) ) );
1683//              }
1684//      ;
1685
1686c_declaration:
1687        declaration_specifier declaring_list
1688                { $$ = distAttr( $1, $2 ); }
1689        | typedef_declaration
1690        | typedef_expression                                                            // GCC, naming expression type
1691        | sue_declaration_specifier
1692        ;
1693
1694declaring_list:
1695                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1696                // storage-class
1697        declarator asm_name_opt initializer_opt
1698                { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
1699        | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1700                { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
1701        ;
1702
1703declaration_specifier:                                                                  // type specifier + storage class
1704        basic_declaration_specifier
1705        | sue_declaration_specifier
1706        | type_declaration_specifier
1707        ;
1708
1709declaration_specifier_nobody:                                                   // type specifier + storage class - {...}
1710                // Preclude SUE declarations in restricted scopes:
1711                //
1712                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1713                //
1714                // because it is impossible to call f due to name equivalence.
1715        basic_declaration_specifier
1716        | sue_declaration_specifier_nobody
1717        | type_declaration_specifier
1718        ;
1719
1720type_specifier:                                                                                 // type specifier
1721        basic_type_specifier
1722        | sue_type_specifier
1723        | type_type_specifier
1724        ;
1725
1726type_specifier_nobody:                                                                  // type specifier - {...}
1727                // Preclude SUE declarations in restricted scopes:
1728                //
1729                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1730                //
1731                // because it is impossible to call f due to name equivalence.
1732        basic_type_specifier
1733        | sue_type_specifier_nobody
1734        | type_type_specifier
1735        ;
1736
1737type_qualifier_list_opt:                                                                // GCC, used in asm_statement
1738        // empty
1739                { $$ = nullptr; }
1740        | type_qualifier_list
1741        ;
1742
1743type_qualifier_list:
1744                // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1745                //
1746                // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1747                // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1748                // appeared only once.
1749        type_qualifier
1750        | type_qualifier_list type_qualifier
1751                { $$ = $1->addQualifiers( $2 ); }
1752        ;
1753
1754type_qualifier:
1755        type_qualifier_name
1756        | attribute
1757        ;
1758
1759type_qualifier_name:
1760        CONST
1761                { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1762        | RESTRICT
1763                { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1764        | VOLATILE
1765                { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1766        | ATOMIC
1767                { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1768        | forall
1769        ;
1770
1771forall:
1772        FORALL '(' type_parameter_list ')'                                      // CFA
1773                { $$ = DeclarationNode::newForall( $3 ); }
1774        ;
1775
1776declaration_qualifier_list:
1777        storage_class_list
1778        | type_qualifier_list storage_class_list                        // remaining OBSOLESCENT (see 2 )
1779                { $$ = $1->addQualifiers( $2 ); }
1780        | declaration_qualifier_list type_qualifier_list storage_class_list
1781                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1782        ;
1783
1784storage_class_list:
1785                // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1786                // only one of each is specified, except for inline, which can appear with the others.
1787                //
1788                // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1789                // specifiers in a declaration.
1790        storage_class
1791        | storage_class_list storage_class
1792                { $$ = $1->addQualifiers( $2 ); }
1793        ;
1794
1795storage_class:
1796        EXTERN
1797                { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1798        | STATIC
1799                { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1800        | AUTO
1801                { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1802        | REGISTER
1803                { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1804        | THREADLOCAL                                                                           // C11
1805                { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1806                // Put function specifiers here to simplify parsing rules, but separate them semantically.
1807        | INLINE                                                                                        // C99
1808                { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1809        | FORTRAN                                                                                       // C99
1810                { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1811        | NORETURN                                                                                      // C11
1812                { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1813        ;
1814
1815basic_type_name:
1816        VOID
1817                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1818        | BOOL                                                                                          // C99
1819                { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1820        | CHAR
1821                { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1822        | INT
1823                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1824        | INT128
1825                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1826        | UINT128
1827                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 )->addType( DeclarationNode::newSignedNess( DeclarationNode::Unsigned ) ); }
1828        | FLOAT
1829                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1830        | DOUBLE
1831                { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1832        | uuFLOAT80
1833                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
1834        | uuFLOAT128
1835                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
1836        | uFLOAT16
1837                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
1838        | uFLOAT32
1839                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
1840        | uFLOAT32X
1841                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
1842        | uFLOAT64
1843                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
1844        | uFLOAT64X
1845                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
1846        | uFLOAT128
1847                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
1848        | COMPLEX                                                                                       // C99
1849                { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1850        | IMAGINARY                                                                                     // C99
1851                { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1852        | SIGNED
1853                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1854        | UNSIGNED
1855                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1856        | SHORT
1857                { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1858        | LONG
1859                { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1860        | VALIST                                                                                        // GCC, __builtin_va_list
1861                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1862        | AUTO_TYPE
1863                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::AutoType ); }
1864        ;
1865
1866basic_declaration_specifier:
1867                // A semantic check is necessary for conflicting storage classes.
1868        basic_type_specifier
1869        | declaration_qualifier_list basic_type_specifier
1870                { $$ = $2->addQualifiers( $1 ); }
1871        | basic_declaration_specifier storage_class                     // remaining OBSOLESCENT (see 2)
1872                { $$ = $1->addQualifiers( $2 ); }
1873        | basic_declaration_specifier storage_class type_qualifier_list
1874                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1875        | basic_declaration_specifier storage_class basic_type_specifier
1876                { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1877        ;
1878
1879basic_type_specifier:
1880        direct_type
1881                // Cannot have type modifiers, e.g., short, long, etc.
1882        | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1883                { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1884        ;
1885
1886direct_type:
1887        basic_type_name
1888        | type_qualifier_list basic_type_name
1889                { $$ = $2->addQualifiers( $1 ); }
1890        | direct_type type_qualifier
1891                { $$ = $1->addQualifiers( $2 ); }
1892        | direct_type basic_type_name
1893                { $$ = $1->addType( $2 ); }
1894        ;
1895
1896indirect_type:
1897        TYPEOF '(' type ')'                                                                     // GCC: typeof( x ) y;
1898                { $$ = $3; }
1899        | TYPEOF '(' comma_expression ')'                                       // GCC: typeof( a+b ) y;
1900                { $$ = DeclarationNode::newTypeof( $3 ); }
1901        | BASETYPEOF '(' type ')'                                                       // CFA: basetypeof( x ) y;
1902                { $$ = DeclarationNode::newTypeof( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ), true ); }
1903        | BASETYPEOF '(' comma_expression ')'                           // CFA: basetypeof( a+b ) y;
1904                { $$ = DeclarationNode::newTypeof( $3, true ); }
1905        | ZERO_T                                                                                        // CFA
1906                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1907        | ONE_T                                                                                         // CFA
1908                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1909        ;
1910
1911sue_declaration_specifier:                                                              // struct, union, enum + storage class + type specifier
1912        sue_type_specifier
1913        | declaration_qualifier_list sue_type_specifier
1914                { $$ = $2->addQualifiers( $1 ); }
1915        | sue_declaration_specifier storage_class                       // remaining OBSOLESCENT (see 2)
1916                { $$ = $1->addQualifiers( $2 ); }
1917        | sue_declaration_specifier storage_class type_qualifier_list
1918                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1919        ;
1920
1921sue_type_specifier:                                                                             // struct, union, enum + type specifier
1922        elaborated_type
1923        | type_qualifier_list
1924                { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1925          elaborated_type
1926                { $$ = $3->addQualifiers( $1 ); }
1927        | sue_type_specifier type_qualifier
1928                {
1929                        if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
1930                        $$ = $1->addQualifiers( $2 );
1931                }
1932        ;
1933
1934sue_declaration_specifier_nobody:                                               // struct, union, enum - {...} + storage class + type specifier
1935        sue_type_specifier_nobody
1936        | declaration_qualifier_list sue_type_specifier_nobody
1937                { $$ = $2->addQualifiers( $1 ); }
1938        | sue_declaration_specifier_nobody storage_class        // remaining OBSOLESCENT (see 2)
1939                { $$ = $1->addQualifiers( $2 ); }
1940        | sue_declaration_specifier_nobody storage_class type_qualifier_list
1941                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1942        ;
1943
1944sue_type_specifier_nobody:                                                              // struct, union, enum - {...} + type specifier
1945        elaborated_type_nobody
1946        | type_qualifier_list elaborated_type_nobody
1947                { $$ = $2->addQualifiers( $1 ); }
1948        | sue_type_specifier_nobody type_qualifier
1949                { $$ = $1->addQualifiers( $2 ); }
1950        ;
1951
1952type_declaration_specifier:
1953        type_type_specifier
1954        | declaration_qualifier_list type_type_specifier
1955                { $$ = $2->addQualifiers( $1 ); }
1956        | type_declaration_specifier storage_class                      // remaining OBSOLESCENT (see 2)
1957                { $$ = $1->addQualifiers( $2 ); }
1958        | type_declaration_specifier storage_class type_qualifier_list
1959                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1960        ;
1961
1962type_type_specifier:                                                                    // typedef types
1963        type_name
1964        | type_qualifier_list type_name
1965                { $$ = $2->addQualifiers( $1 ); }
1966        | type_type_specifier type_qualifier
1967                { $$ = $1->addQualifiers( $2 ); }
1968        ;
1969
1970type_name:
1971        TYPEDEFname
1972                { $$ = DeclarationNode::newFromTypedef( $1 ); }
1973        | '.' TYPEDEFname
1974                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
1975        | type_name '.' TYPEDEFname
1976                { $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
1977        | typegen_name
1978        | '.' typegen_name
1979                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
1980        | type_name '.' typegen_name
1981                { $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
1982        ;
1983
1984typegen_name:                                                                                   // CFA
1985        TYPEGENname
1986                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1987        | TYPEGENname '(' ')'
1988                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1989        | TYPEGENname '(' type_list ')'
1990                { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
1991        ;
1992
1993elaborated_type:                                                                                // struct, union, enum
1994        aggregate_type
1995        | enum_type
1996        ;
1997
1998elaborated_type_nobody:                                                                 // struct, union, enum - {...}
1999        aggregate_type_nobody
2000        | enum_type_nobody
2001        ;
2002
2003fred:
2004        // empty
2005                { yyy = false; }
2006        ;
2007
2008aggregate_type:                                                                                 // struct, union
2009        aggregate_key attribute_list_opt
2010                { forall = false; }                                                             // reset
2011          '{' field_declaration_list_opt '}' type_parameters_opt
2012                { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2013        | aggregate_key attribute_list_opt identifier fred
2014                {
2015                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2016                        forall = false;                                                         // reset
2017                }
2018          '{' field_declaration_list_opt '}' type_parameters_opt
2019                { $$ = DeclarationNode::newAggregate( $1, $3, $9, $7, true )->addQualifiers( $2 ); }
2020        | aggregate_key attribute_list_opt type_name fred
2021                {
2022                        // for type_name can be a qualified type name S.T, in which case only the last name in the chain needs a typedef (other names in the chain should already have one)
2023                        typedefTable.makeTypedef( *$3->type->leafName(), forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2024                        forall = false;                                                         // reset
2025                }
2026          '{' field_declaration_list_opt '}' type_parameters_opt
2027                { $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $9, $7, true )->addQualifiers( $2 ); }
2028        | aggregate_type_nobody
2029        ;
2030
2031type_parameters_opt:
2032        // empty
2033                { $$ = nullptr; }                                                               %prec '}'
2034        | '(' type_list ')'
2035                { $$ = $2; }
2036        ;
2037
2038aggregate_type_nobody:                                                                  // struct, union - {...}
2039        aggregate_key attribute_list_opt identifier fred
2040                {
2041                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname );
2042                        forall = false;                                                         // reset
2043                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2044                }
2045        | aggregate_key attribute_list_opt type_name fred
2046                {
2047                        forall = false;                                                         // reset
2048                        // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2049                        // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2050                        // delete newFromTypeGen.
2051                        $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2052                        $3->type->symbolic.name = nullptr;
2053                        $3->type->symbolic.actuals = nullptr;
2054                        delete $3;
2055                }
2056        ;
2057
2058aggregate_key:
2059        aggregate_data
2060        | aggregate_control
2061        ;
2062
2063aggregate_data:
2064        STRUCT
2065                { yyy = true; $$ = AggregateDecl::Struct; }
2066        | UNION
2067                { yyy = true; $$ = AggregateDecl::Union; }
2068        | EXCEPTION                                                                                     // CFA
2069                { yyy = true; $$ = AggregateDecl::Exception; }
2070        ;
2071
2072aggregate_control:                                                                              // CFA
2073        GENERATOR
2074                { yyy = true; $$ = AggregateDecl::Coroutine; }
2075        | COROUTINE
2076                { yyy = true; $$ = AggregateDecl::Coroutine; }
2077        | MONITOR
2078                { yyy = true; $$ = AggregateDecl::Monitor; }
2079        | THREAD
2080                { yyy = true; $$ = AggregateDecl::Thread; }
2081        ;
2082
2083field_declaration_list_opt:
2084        // empty
2085                { $$ = nullptr; }
2086        | field_declaration_list_opt field_declaration
2087                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2088        ;
2089
2090field_declaration:
2091        type_specifier field_declaring_list_opt ';'
2092                { $$ = fieldDecl( $1, $2 ); }
2093        | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2094                { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2095        | INLINE type_specifier field_abstract_list_opt ';'     // CFA
2096                {
2097                        if ( ! $3 ) {                                                           // field declarator ?
2098                                $3 = DeclarationNode::newName( nullptr );
2099                        } // if
2100                        $3->inLine = true;
2101                        $$ = distAttr( $2, $3 );                                        // mark all fields in list
2102                        distInl( $3 );
2103                }
2104        | INLINE aggregate_control ';'                                          // CFA
2105                { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2106        | typedef_declaration ';'                                                       // CFA
2107        | cfa_field_declaring_list ';'                                          // CFA, new style field declaration
2108        | EXTENSION cfa_field_declaring_list ';'                        // GCC
2109                { distExt( $2 ); $$ = $2; }                                             // mark all fields in list
2110        | INLINE cfa_field_abstract_list ';'                            // CFA, new style field declaration
2111                { $$ = $2; }                                                                    // mark all fields in list
2112        | cfa_typedef_declaration ';'                                           // CFA
2113        | static_assert                                                                         // C11
2114        ;
2115
2116field_declaring_list_opt:
2117        // empty
2118                { $$ = nullptr; }
2119        | field_declarator
2120        | field_declaring_list_opt ',' attribute_list_opt field_declarator
2121                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2122        ;
2123
2124field_declarator:
2125        bit_subrange_size                                                                       // C special case, no field name
2126                { $$ = DeclarationNode::newBitfield( $1 ); }
2127        | variable_declarator bit_subrange_size_opt
2128                // A semantic check is required to ensure bit_subrange only appears on integral types.
2129                { $$ = $1->addBitfield( $2 ); }
2130        | variable_type_redeclarator bit_subrange_size_opt
2131                // A semantic check is required to ensure bit_subrange only appears on integral types.
2132                { $$ = $1->addBitfield( $2 ); }
2133        ;
2134
2135field_abstract_list_opt:
2136        // empty
2137                { $$ = nullptr; }
2138        | field_abstract
2139        | field_abstract_list_opt ',' attribute_list_opt field_abstract
2140                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2141        ;
2142
2143field_abstract:
2144                //      no bit fields
2145        variable_abstract_declarator
2146        ;
2147
2148cfa_field_declaring_list:                                                               // CFA, new style field declaration
2149        // bit-fields are handled by C declarations
2150        cfa_abstract_declarator_tuple identifier_or_type_name
2151                { $$ = $1->addName( $2 ); }
2152        | cfa_field_declaring_list ',' identifier_or_type_name
2153                { $$ = $1->appendList( $1->cloneType( $3 ) ); }
2154        ;
2155
2156cfa_field_abstract_list:                                                                // CFA, new style field declaration
2157        // bit-fields are handled by C declarations
2158        cfa_abstract_declarator_tuple
2159        | cfa_field_abstract_list ','
2160                { $$ = $1->appendList( $1->cloneType( 0 ) ); }
2161        ;
2162
2163bit_subrange_size_opt:
2164        // empty
2165                { $$ = nullptr; }
2166        | bit_subrange_size
2167        ;
2168
2169bit_subrange_size:
2170        ':' assignment_expression
2171                { $$ = $2; }
2172        ;
2173
2174enum_type:                                                                                              // enum
2175        ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2176                { $$ = DeclarationNode::newEnum( nullptr, $4, true )->addQualifiers( $2 ); }
2177        | ENUM attribute_list_opt identifier
2178                { typedefTable.makeTypedef( *$3 ); }
2179          '{' enumerator_list comma_opt '}'
2180                { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
2181        | ENUM attribute_list_opt type_name
2182          '{' enumerator_list comma_opt '}'
2183                { $$ = DeclarationNode::newEnum( $3->type->symbolic.name, $5, true )->addQualifiers( $2 ); }
2184        | enum_type_nobody
2185        ;
2186
2187enum_type_nobody:                                                                               // enum - {...}
2188        ENUM attribute_list_opt identifier
2189                {
2190                        typedefTable.makeTypedef( *$3 );
2191                        $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 );
2192                }
2193        | ENUM attribute_list_opt type_name
2194                {
2195                        typedefTable.makeTypedef( *$3->type->symbolic.name );
2196                        $$ = DeclarationNode::newEnum( $3->type->symbolic.name, 0, false )->addQualifiers( $2 );
2197                }
2198        ;
2199
2200enumerator_list:
2201        identifier_or_type_name enumerator_value_opt
2202                { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
2203        | enumerator_list ',' identifier_or_type_name enumerator_value_opt
2204                { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
2205        ;
2206
2207enumerator_value_opt:
2208        // empty
2209                { $$ = nullptr; }
2210        | '=' constant_expression
2211                { $$ = $2; }
2212        ;
2213
2214cfa_parameter_ellipsis_list_opt:                                                        // CFA, abstract + real
2215        // empty
2216                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2217        | ELLIPSIS
2218                { $$ = nullptr; }
2219        | cfa_abstract_parameter_list
2220        | cfa_parameter_list
2221        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2222                { $$ = $1->appendList( $5 ); }
2223        | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2224                { $$ = $1->addVarArgs(); }
2225        | cfa_parameter_list pop ',' push ELLIPSIS
2226                { $$ = $1->addVarArgs(); }
2227        ;
2228
2229cfa_parameter_list:                                                                             // CFA
2230                // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2231                // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2232        cfa_parameter_declaration
2233        | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2234                { $$ = $1->appendList( $5 ); }
2235        | cfa_parameter_list pop ',' push cfa_parameter_declaration
2236                { $$ = $1->appendList( $5 ); }
2237        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2238                { $$ = $1->appendList( $5 )->appendList( $9 ); }
2239        ;
2240
2241cfa_abstract_parameter_list:                                                    // CFA, new & old style abstract
2242        cfa_abstract_parameter_declaration
2243        | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2244                { $$ = $1->appendList( $5 ); }
2245        ;
2246
2247parameter_type_list_opt:
2248        // empty
2249                { $$ = nullptr; }
2250        | ELLIPSIS
2251                { $$ = nullptr; }
2252        | parameter_list
2253        | parameter_list pop ',' push ELLIPSIS
2254                { $$ = $1->addVarArgs(); }
2255        ;
2256
2257parameter_list:                                                                                 // abstract + real
2258        abstract_parameter_declaration
2259        | parameter_declaration
2260        | parameter_list pop ',' push abstract_parameter_declaration
2261                { $$ = $1->appendList( $5 ); }
2262        | parameter_list pop ',' push parameter_declaration
2263                { $$ = $1->appendList( $5 ); }
2264        ;
2265
2266// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2267// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2268
2269cfa_parameter_declaration:                                                              // CFA, new & old style parameter declaration
2270        parameter_declaration
2271        | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initialize_opt
2272                { $$ = $1->addName( $2 ); }
2273        | cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2274                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2275                { $$ = $1->addName( $2 ); }
2276        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2277                { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2278        | cfa_function_specifier
2279        ;
2280
2281cfa_abstract_parameter_declaration:                                             // CFA, new & old style parameter declaration
2282        abstract_parameter_declaration
2283        | cfa_identifier_parameter_declarator_no_tuple
2284        | cfa_abstract_tuple
2285                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2286        | type_qualifier_list cfa_abstract_tuple
2287                { $$ = $2->addQualifiers( $1 ); }
2288        | cfa_abstract_function
2289        ;
2290
2291parameter_declaration:
2292                // No SUE declaration in parameter list.
2293        declaration_specifier_nobody identifier_parameter_declarator default_initialize_opt
2294                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2295        | declaration_specifier_nobody type_parameter_redeclarator default_initialize_opt
2296                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2297        ;
2298
2299abstract_parameter_declaration:
2300        declaration_specifier_nobody default_initialize_opt
2301                { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2302        | declaration_specifier_nobody abstract_parameter_declarator default_initialize_opt
2303                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2304        ;
2305
2306// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2307// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2308// identifiers.  The ANSI-style parameter-list can redefine a typedef name.
2309
2310identifier_list:                                                                                // K&R-style parameter list => no types
2311        identifier
2312                { $$ = DeclarationNode::newName( $1 ); }
2313        | identifier_list ',' identifier
2314                { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2315        ;
2316
2317identifier_or_type_name:
2318        identifier
2319        | TYPEDEFname
2320        | TYPEGENname
2321        ;
2322
2323type_no_function:                                                                               // sizeof, alignof, cast (constructor)
2324        cfa_abstract_declarator_tuple                                           // CFA
2325        | type_specifier
2326        | type_specifier abstract_declarator
2327                { $$ = $2->addType( $1 ); }
2328        ;
2329
2330type:                                                                                                   // typeof, assertion
2331        type_no_function
2332        | cfa_abstract_function                                                         // CFA
2333        ;
2334
2335initializer_opt:
2336        // empty
2337                { $$ = nullptr; }
2338        | '=' initializer
2339                { $$ = $2; }
2340        | '=' VOID
2341                { $$ = new InitializerNode( true ); }
2342        | ATassign initializer
2343                { $$ = $2->set_maybeConstructed( false ); }
2344        ;
2345
2346initializer:
2347        assignment_expression                                           { $$ = new InitializerNode( $1 ); }
2348        | '{' initializer_list_opt comma_opt '}'        { $$ = new InitializerNode( $2, true ); }
2349        ;
2350
2351initializer_list_opt:
2352        // empty
2353                { $$ = nullptr; }
2354        | initializer
2355        | designation initializer                                       { $$ = $2->set_designators( $1 ); }
2356        | initializer_list_opt ',' initializer          { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2357        | initializer_list_opt ',' designation initializer
2358                { $$ = (InitializerNode *)( $1->set_last( $4->set_designators( $3 ) ) ); }
2359        ;
2360
2361// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2362// '=' to separator the designator from the initializer value, as in:
2363//
2364//              int x[10] = { [1] = 3 };
2365//
2366// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment.  To disambiguate this case, CFA
2367// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2368// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2369// shift/reduce conflicts
2370
2371designation:
2372        designator_list ':'                                                                     // C99, CFA uses ":" instead of "="
2373        | identifier ':'                                                                        // GCC, field name
2374                { $$ = new ExpressionNode( build_varref( $1 ) ); }
2375        ;
2376
2377designator_list:                                                                                // C99
2378        designator
2379        | designator_list designator
2380                { $$ = (ExpressionNode *)( $1->set_last( $2 ) ); }
2381        //| designator_list designator                                          { $$ = new ExpressionNode( $1, $2 ); }
2382        ;
2383
2384designator:
2385        '.' identifier                                                                          // C99, field name
2386                { $$ = new ExpressionNode( build_varref( $2 ) ); }
2387        | '[' push assignment_expression pop ']'                        // C99, single array element
2388                // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2389                { $$ = $3; }
2390        | '[' push subrange pop ']'                                                     // CFA, multiple array elements
2391                { $$ = $3; }
2392        | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2393                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $3 ), maybeMoveBuild< Expression >( $5 ) ) ); }
2394        | '.' '[' push field_name_list pop ']'                          // CFA, tuple field selector
2395                { $$ = $4; }
2396        ;
2397
2398// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2399// rather than an object-oriented type system. This required four groups of extensions:
2400//
2401// Overloading: function, data, and operator identifiers may be overloaded.
2402//
2403// Type declarations: "type" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2404//     and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2405//     definitions of new types. Type declarations with storage class "extern" provide opaque types.
2406//
2407// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2408//     site. A polymorphic function is not a template; it is a function, with an address and a type.
2409//
2410// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2411//     types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2412//     hierarchies. Unlike classes, they can define relationships between types.  Assertions declare that a type or
2413//     types provide the operations declared by a specification.  Assertions are normally used to declare requirements
2414//     on type arguments of polymorphic functions.
2415
2416type_parameter_list:                                                                    // CFA
2417        type_parameter
2418        | type_parameter_list ',' type_parameter
2419                { $$ = $1->appendList( $3 ); }
2420        ;
2421
2422type_initializer_opt:                                                                   // CFA
2423        // empty
2424                { $$ = nullptr; }
2425        | '=' type
2426                { $$ = $2; }
2427        ;
2428
2429type_parameter:                                                                                 // CFA
2430        type_class identifier_or_type_name
2431                { typedefTable.addToScope( *$2, TYPEDEFname, "9" ); }
2432          type_initializer_opt assertion_list_opt
2433                { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2434        | type_specifier identifier_parameter_declarator
2435        | assertion_list
2436                { $$ = DeclarationNode::newTypeParam( DeclarationNode::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2437        ;
2438
2439type_class:                                                                                             // CFA
2440        OTYPE
2441                { $$ = DeclarationNode::Otype; }
2442        | DTYPE
2443                { $$ = DeclarationNode::Dtype; }
2444        | FTYPE
2445                { $$ = DeclarationNode::Ftype; }
2446        | TTYPE
2447                { $$ = DeclarationNode::Ttype; }
2448        ;
2449
2450assertion_list_opt:                                                                             // CFA
2451        // empty
2452                { $$ = nullptr; }
2453        | assertion_list
2454        ;
2455
2456assertion_list:                                                                                 // CFA
2457        assertion
2458        | assertion_list assertion
2459                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2460        ;
2461
2462assertion:                                                                                              // CFA
2463        '|' identifier_or_type_name '(' type_list ')'
2464                { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
2465        | '|' '{' push trait_declaration_list pop '}'
2466                { $$ = $4; }
2467        // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
2468        //      { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
2469        ;
2470
2471type_list:                                                                                              // CFA
2472        type
2473                { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2474        | assignment_expression
2475                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $1->build()) ); $$ = nullptr; }
2476        | type_list ',' type
2477                { $$ = (ExpressionNode *)( $1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) ) ); }
2478        | type_list ',' assignment_expression
2479                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $3->build()) ); $$ = nullptr; }
2480                // { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2481        ;
2482
2483type_declaring_list:                                                                    // CFA
2484        OTYPE type_declarator
2485                { $$ = $2; }
2486        | storage_class_list OTYPE type_declarator
2487                { $$ = $3->addQualifiers( $1 ); }
2488        | type_declaring_list ',' type_declarator
2489                { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2490        ;
2491
2492type_declarator:                                                                                // CFA
2493        type_declarator_name assertion_list_opt
2494                { $$ = $1->addAssertions( $2 ); }
2495        | type_declarator_name assertion_list_opt '=' type
2496                { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2497        ;
2498
2499type_declarator_name:                                                                   // CFA
2500        identifier_or_type_name
2501                {
2502                        typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "10" );
2503                        $$ = DeclarationNode::newTypeDecl( $1, 0 );
2504                }
2505        | identifier_or_type_name '(' type_parameter_list ')'
2506                {
2507                        typedefTable.addToEnclosingScope( *$1, TYPEGENname, "11" );
2508                        $$ = DeclarationNode::newTypeDecl( $1, $3 );
2509                }
2510        ;
2511
2512trait_specifier:                                                                                // CFA
2513        TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
2514                { $$ = DeclarationNode::newTrait( $2, $4, 0 ); }
2515        | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
2516                { $$ = DeclarationNode::newTrait( $2, $4, $8 ); }
2517        ;
2518
2519trait_declaration_list:                                                                 // CFA
2520        trait_declaration
2521        | trait_declaration_list pop push trait_declaration
2522                { $$ = $1->appendList( $4 ); }
2523        ;
2524
2525trait_declaration:                                                                              // CFA
2526        cfa_trait_declaring_list ';'
2527        | trait_declaring_list ';'
2528        ;
2529
2530cfa_trait_declaring_list:                                                               // CFA
2531        cfa_variable_specifier
2532        | cfa_function_specifier
2533        | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2534                { $$ = $1->appendList( $1->cloneType( $5 ) ); }
2535        ;
2536
2537trait_declaring_list:                                                                   // CFA
2538        type_specifier declarator
2539                { $$ = $2->addType( $1 ); }
2540        | trait_declaring_list pop ',' push declarator
2541                { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
2542        ;
2543
2544//***************************** EXTERNAL DEFINITIONS *****************************
2545
2546translation_unit:
2547        // empty, input file
2548        | external_definition_list
2549                { parseTree = parseTree ? parseTree->appendList( $1 ) : $1;     }
2550        ;
2551
2552external_definition_list:
2553        push external_definition pop
2554                { $$ = $2; }
2555        | external_definition_list push external_definition pop
2556                { $$ = $1 ? $1->appendList( $3 ) : $3; }
2557        ;
2558
2559external_definition_list_opt:
2560        // empty
2561                { $$ = nullptr; }
2562        | external_definition_list
2563        ;
2564
2565up:
2566                { typedefTable.up( forall ); forall = false; }
2567        ;
2568
2569down:
2570                { typedefTable.down(); }
2571        ;
2572
2573external_definition:
2574        declaration
2575        | external_function_definition
2576        | EXTENSION external_definition                                         // GCC, multiple __extension__ allowed, meaning unknown
2577                {
2578                        distExt( $2 );                                                          // mark all fields in list
2579                        $$ = $2;
2580                }
2581        | ASM '(' string_literal ')' ';'                                        // GCC, global assembler statement
2582                {
2583                        $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( false, $3, 0 ) ) );
2584                }
2585        | EXTERN STRINGliteral                                                          // C++-style linkage specifier
2586                {
2587                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
2588                        linkage = LinkageSpec::linkageUpdate( yylloc, linkage, $2 );
2589                }
2590          '{' up external_definition_list_opt down '}'
2591                {
2592                        linkage = linkageStack.top();
2593                        linkageStack.pop();
2594                        $$ = $6;
2595                }
2596        | type_qualifier_list
2597                {
2598                        if ( $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2599                        if ( $1->type->forall ) forall = true;          // remember generic type
2600                }
2601          '{' up external_definition_list_opt down '}'          // CFA, namespace
2602                {
2603                        distQual( $5, $1 );
2604                        forall = false;
2605                        $$ = $5;
2606                }
2607        | declaration_qualifier_list
2608                {
2609                        if ( $1->type && $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2610                        if ( $1->type && $1->type->forall ) forall = true; // remember generic type
2611                }
2612          '{' up external_definition_list_opt down '}'          // CFA, namespace
2613                {
2614                        distQual( $5, $1 );
2615                        forall = false;
2616                        $$ = $5;
2617                }
2618        | declaration_qualifier_list type_qualifier_list
2619                {
2620                        if ( ($1->type && $1->type->qualifiers.val) || $2->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2621                        if ( ($1->type && $1->type->forall) || $2->type->forall ) forall = true; // remember generic type
2622                }
2623          '{' up external_definition_list_opt down '}'          // CFA, namespace
2624                {
2625                        distQual( $6, $1->addQualifiers( $2 ) );
2626                        forall = false;
2627                        $$ = $6;
2628                }
2629        ;
2630
2631external_function_definition:
2632        function_definition
2633                // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2634                // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2635                // Parsing is possible because function_definition does not appear in the context of an expression (nested
2636                // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2637                // declaration must still have a type_specifier.  OBSOLESCENT (see 1)
2638        | function_declarator compound_statement
2639                { $$ = $1->addFunctionBody( $2 ); }
2640        | KR_function_declarator KR_parameter_list_opt compound_statement
2641                { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
2642        ;
2643
2644with_clause_opt:
2645        // empty
2646                { $$ = nullptr; forall = false; }
2647        | WITH '(' tuple_expression_list ')'
2648                { $$ = $3; forall = false; }
2649        ;
2650
2651function_definition:
2652        cfa_function_declaration with_clause_opt compound_statement     // CFA
2653                {
2654                        // Add the function body to the last identifier in the function definition list, i.e., foo3:
2655                        //   [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2656                        $1->get_last()->addFunctionBody( $3, $2 );
2657                        $$ = $1;
2658                }
2659        | declaration_specifier function_declarator with_clause_opt compound_statement
2660                {
2661                        rebindForall( $1, $2 );
2662                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2663                }
2664        | declaration_specifier variable_type_redeclarator with_clause_opt compound_statement
2665                {
2666                        rebindForall( $1, $2 );
2667                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2668                }
2669                // handles default int return type, OBSOLESCENT (see 1)
2670        | type_qualifier_list function_declarator with_clause_opt compound_statement
2671                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2672                // handles default int return type, OBSOLESCENT (see 1)
2673        | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2674                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2675                // handles default int return type, OBSOLESCENT (see 1)
2676        | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2677                { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2678
2679                // Old-style K&R function definition, OBSOLESCENT (see 4)
2680        | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2681                {
2682                        rebindForall( $1, $2 );
2683                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2684                }
2685                // handles default int return type, OBSOLESCENT (see 1)
2686        | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2687                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2688                // handles default int return type, OBSOLESCENT (see 1)
2689        | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2690                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2691                // handles default int return type, OBSOLESCENT (see 1)
2692        | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2693                { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2694        ;
2695
2696declarator:
2697        variable_declarator
2698        | variable_type_redeclarator
2699        | function_declarator
2700        ;
2701
2702subrange:
2703        constant_expression '~' constant_expression                     // CFA, integer subrange
2704                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
2705        ;
2706
2707asm_name_opt:                                                                                   // GCC
2708        // empty
2709                { $$ = nullptr; }
2710        | ASM '(' string_literal ')' attribute_list_opt
2711                {
2712                        DeclarationNode * name = new DeclarationNode();
2713                        name->asmName = $3;
2714                        $$ = name->addQualifiers( $5 );
2715                }
2716        ;
2717
2718attribute_list_opt:                                                                             // GCC
2719        // empty
2720                { $$ = nullptr; }
2721        | attribute_list
2722        ;
2723
2724attribute_list:                                                                                 // GCC
2725        attribute
2726        | attribute_list attribute
2727                { $$ = $2->addQualifiers( $1 ); }
2728        ;
2729
2730attribute:                                                                                              // GCC
2731        ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2732                { $$ = $4; }
2733        ;
2734
2735attribute_name_list:                                                                    // GCC
2736        attribute_name
2737        | attribute_name_list ',' attribute_name
2738                { $$ = $3->addQualifiers( $1 ); }
2739        ;
2740
2741attribute_name:                                                                                 // GCC
2742        // empty
2743                { $$ = nullptr; }
2744        | attr_name
2745                { $$ = DeclarationNode::newAttribute( $1 ); }
2746        | attr_name '(' argument_expression_list ')'
2747                { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2748        ;
2749
2750attr_name:                                                                                              // GCC
2751        IDENTIFIER
2752        | quasi_keyword
2753        | TYPEDEFname
2754        | TYPEGENname
2755        | FALLTHROUGH
2756                { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2757        | CONST
2758                { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2759        ;
2760
2761// ============================================================================
2762// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2763// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2764// in:
2765//
2766//              int (*f())[10] { ... };
2767//              ... (*f())[3] += 1;             // definition mimics usage
2768//
2769// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2770// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2771// ============================================================================
2772
2773// ----------------------------------------------------------------------------
2774// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2775// to define a variable or function prototype, e.g.:
2776//
2777//              valid declaration               invalid definition
2778//              -----------------               ------------------
2779//              int f;                                  int f {}
2780//              int *f;                                 int *f {}
2781//              int f[10];                              int f[10] {}
2782//              int (*f)(int);                  int (*f)(int) {}
2783//
2784// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2785// variable_declarator and function_declarator.
2786// ----------------------------------------------------------------------------
2787
2788// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2789// declaring an array of functions versus a pointer to an array of functions.
2790
2791variable_declarator:
2792        paren_identifier attribute_list_opt
2793                { $$ = $1->addQualifiers( $2 ); }
2794        | variable_ptr
2795        | variable_array attribute_list_opt
2796                { $$ = $1->addQualifiers( $2 ); }
2797        | variable_function attribute_list_opt
2798                { $$ = $1->addQualifiers( $2 ); }
2799        ;
2800
2801paren_identifier:
2802        identifier
2803                { $$ = DeclarationNode::newName( $1 ); }
2804        | '(' paren_identifier ')'                                                      // redundant parenthesis
2805                { $$ = $2; }
2806        ;
2807
2808variable_ptr:
2809        ptrref_operator variable_declarator
2810                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2811        | ptrref_operator type_qualifier_list variable_declarator
2812                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2813        | '(' variable_ptr ')' attribute_list_opt
2814                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2815        ;
2816
2817variable_array:
2818        paren_identifier array_dimension
2819                { $$ = $1->addArray( $2 ); }
2820        | '(' variable_ptr ')' array_dimension
2821                { $$ = $2->addArray( $4 ); }
2822        | '(' variable_array ')' multi_array_dimension          // redundant parenthesis
2823                { $$ = $2->addArray( $4 ); }
2824        | '(' variable_array ')'                                                        // redundant parenthesis
2825                { $$ = $2; }
2826        ;
2827
2828variable_function:
2829        '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2830                { $$ = $2->addParamList( $6 ); }
2831        | '(' variable_function ')'                                                     // redundant parenthesis
2832                { $$ = $2; }
2833        ;
2834
2835// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2836// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2837// is the same scope.  The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2838
2839function_declarator:
2840        function_no_ptr attribute_list_opt
2841                { $$ = $1->addQualifiers( $2 ); }
2842        | function_ptr
2843        | function_array attribute_list_opt
2844                { $$ = $1->addQualifiers( $2 ); }
2845        ;
2846
2847function_no_ptr:
2848        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2849                { $$ = $1->addParamList( $4 ); }
2850        | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2851                { $$ = $2->addParamList( $6 ); }
2852        | '(' function_no_ptr ')'                                                       // redundant parenthesis
2853                { $$ = $2; }
2854        ;
2855
2856function_ptr:
2857        ptrref_operator function_declarator
2858                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2859        | ptrref_operator type_qualifier_list function_declarator
2860                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2861        | '(' function_ptr ')'
2862                { $$ = $2; }
2863        ;
2864
2865function_array:
2866        '(' function_ptr ')' array_dimension
2867                { $$ = $2->addArray( $4 ); }
2868        | '(' function_array ')' multi_array_dimension          // redundant parenthesis
2869                { $$ = $2->addArray( $4 ); }
2870        | '(' function_array ')'                                                        // redundant parenthesis
2871                { $$ = $2; }
2872        ;
2873
2874// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
2875//
2876//   f( a, b, c ) int a, *b, c[]; {}
2877//
2878// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
2879// returning arrays and functions versus pointers to arrays and functions.
2880
2881KR_function_declarator:
2882        KR_function_no_ptr
2883        | KR_function_ptr
2884        | KR_function_array
2885        ;
2886
2887KR_function_no_ptr:
2888        paren_identifier '(' identifier_list ')'                        // function_declarator handles empty parameter
2889                { $$ = $1->addIdList( $3 ); }
2890        | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
2891                { $$ = $2->addParamList( $6 ); }
2892        | '(' KR_function_no_ptr ')'                                            // redundant parenthesis
2893                { $$ = $2; }
2894        ;
2895
2896KR_function_ptr:
2897        ptrref_operator KR_function_declarator
2898                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2899        | ptrref_operator type_qualifier_list KR_function_declarator
2900                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2901        | '(' KR_function_ptr ')'
2902                { $$ = $2; }
2903        ;
2904
2905KR_function_array:
2906        '(' KR_function_ptr ')' array_dimension
2907                { $$ = $2->addArray( $4 ); }
2908        | '(' KR_function_array ')' multi_array_dimension       // redundant parenthesis
2909                { $$ = $2->addArray( $4 ); }
2910        | '(' KR_function_array ')'                                                     // redundant parenthesis
2911                { $$ = $2; }
2912        ;
2913
2914// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2915//
2916//              typedef int foo;
2917//              {
2918//                 int foo; // redefine typedef name in new scope
2919//              }
2920//
2921// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2922// and functions versus pointers to arrays and functions.
2923
2924variable_type_redeclarator:
2925        paren_type attribute_list_opt
2926                { $$ = $1->addQualifiers( $2 ); }
2927        | type_ptr
2928        | type_array attribute_list_opt
2929                { $$ = $1->addQualifiers( $2 ); }
2930        | type_function attribute_list_opt
2931                { $$ = $1->addQualifiers( $2 ); }
2932        ;
2933
2934paren_type:
2935        typedef
2936                // hide type name in enclosing scope by variable name
2937                {
2938                        // if ( ! typedefTable.existsCurr( *$1->name ) ) {
2939                                typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "ID" );
2940                        // } else {
2941                        //      SemanticError( yylloc, string("'") + *$1->name + "' redeclared as different kind of symbol." ); $$ = nullptr;
2942                        // } // if
2943                }
2944        | '(' paren_type ')'
2945                { $$ = $2; }
2946        ;
2947
2948type_ptr:
2949        ptrref_operator variable_type_redeclarator
2950                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2951        | ptrref_operator type_qualifier_list variable_type_redeclarator
2952                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2953        | '(' type_ptr ')' attribute_list_opt
2954                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2955        ;
2956
2957type_array:
2958        paren_type array_dimension
2959                { $$ = $1->addArray( $2 ); }
2960        | '(' type_ptr ')' array_dimension
2961                { $$ = $2->addArray( $4 ); }
2962        | '(' type_array ')' multi_array_dimension                      // redundant parenthesis
2963                { $$ = $2->addArray( $4 ); }
2964        | '(' type_array ')'                                                            // redundant parenthesis
2965                { $$ = $2; }
2966        ;
2967
2968type_function:
2969        paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2970                { $$ = $1->addParamList( $4 ); }
2971        | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2972                { $$ = $2->addParamList( $6 ); }
2973        | '(' type_function ')'                                                         // redundant parenthesis
2974                { $$ = $2; }
2975        ;
2976
2977// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
2978// typedef name and allows the C99 array options, which can only appear in a parameter list.  The pattern precludes
2979// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
2980// pointers to arrays and functions.
2981
2982identifier_parameter_declarator:
2983        paren_identifier attribute_list_opt
2984                { $$ = $1->addQualifiers( $2 ); }
2985        | '&' MUTEX paren_identifier attribute_list_opt
2986                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
2987        | identifier_parameter_ptr
2988        | identifier_parameter_array attribute_list_opt
2989                { $$ = $1->addQualifiers( $2 ); }
2990        | identifier_parameter_function attribute_list_opt
2991                { $$ = $1->addQualifiers( $2 ); }
2992        ;
2993
2994identifier_parameter_ptr:
2995        ptrref_operator identifier_parameter_declarator
2996                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2997        | ptrref_operator type_qualifier_list identifier_parameter_declarator
2998                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2999        | '(' identifier_parameter_ptr ')' attribute_list_opt
3000                { $$ = $2->addQualifiers( $4 ); }
3001        ;
3002
3003identifier_parameter_array:
3004        paren_identifier array_parameter_dimension
3005                { $$ = $1->addArray( $2 ); }
3006        | '(' identifier_parameter_ptr ')' array_dimension
3007                { $$ = $2->addArray( $4 ); }
3008        | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3009                { $$ = $2->addArray( $4 ); }
3010        | '(' identifier_parameter_array ')'                            // redundant parenthesis
3011                { $$ = $2; }
3012        ;
3013
3014identifier_parameter_function:
3015        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3016                { $$ = $1->addParamList( $4 ); }
3017        | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3018                { $$ = $2->addParamList( $6 ); }
3019        | '(' identifier_parameter_function ')'                         // redundant parenthesis
3020                { $$ = $2; }
3021        ;
3022
3023// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3024// e.g.:
3025//
3026//              typedef int foo;
3027//              forall( otype T ) struct foo;
3028//              int f( int foo ); // redefine typedef name in new scope
3029//
3030// and allows the C99 array options, which can only appear in a parameter list.
3031
3032type_parameter_redeclarator:
3033        typedef attribute_list_opt
3034                { $$ = $1->addQualifiers( $2 ); }
3035        | '&' MUTEX typedef attribute_list_opt
3036                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3037        | type_parameter_ptr
3038        | type_parameter_array attribute_list_opt
3039                { $$ = $1->addQualifiers( $2 ); }
3040        | type_parameter_function attribute_list_opt
3041                { $$ = $1->addQualifiers( $2 ); }
3042        ;
3043
3044typedef:
3045        TYPEDEFname
3046                { $$ = DeclarationNode::newName( $1 ); }
3047        | TYPEGENname
3048                { $$ = DeclarationNode::newName( $1 ); }
3049        ;
3050
3051type_parameter_ptr:
3052        ptrref_operator type_parameter_redeclarator
3053                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3054        | ptrref_operator type_qualifier_list type_parameter_redeclarator
3055                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3056        | '(' type_parameter_ptr ')' attribute_list_opt
3057                { $$ = $2->addQualifiers( $4 ); }
3058        ;
3059
3060type_parameter_array:
3061        typedef array_parameter_dimension
3062                { $$ = $1->addArray( $2 ); }
3063        | '(' type_parameter_ptr ')' array_parameter_dimension
3064                { $$ = $2->addArray( $4 ); }
3065        ;
3066
3067type_parameter_function:
3068        typedef '(' push parameter_type_list_opt pop ')'        // empty parameter list OBSOLESCENT (see 3)
3069                { $$ = $1->addParamList( $4 ); }
3070        | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3071                { $$ = $2->addParamList( $6 ); }
3072        ;
3073
3074// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3075// which the type applies, e.g.:
3076//
3077//              sizeof( int );
3078//              sizeof( int * );
3079//              sizeof( int [10] );
3080//              sizeof( int (*)() );
3081//              sizeof( int () );
3082//
3083// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3084// and functions versus pointers to arrays and functions.
3085
3086abstract_declarator:
3087        abstract_ptr
3088        | abstract_array attribute_list_opt
3089                { $$ = $1->addQualifiers( $2 ); }
3090        | abstract_function attribute_list_opt
3091                { $$ = $1->addQualifiers( $2 ); }
3092        ;
3093
3094abstract_ptr:
3095        ptrref_operator
3096                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3097        | ptrref_operator type_qualifier_list
3098                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3099        | ptrref_operator abstract_declarator
3100                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3101        | ptrref_operator type_qualifier_list abstract_declarator
3102                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3103        | '(' abstract_ptr ')' attribute_list_opt
3104                { $$ = $2->addQualifiers( $4 ); }
3105        ;
3106
3107abstract_array:
3108        array_dimension
3109        | '(' abstract_ptr ')' array_dimension
3110                { $$ = $2->addArray( $4 ); }
3111        | '(' abstract_array ')' multi_array_dimension          // redundant parenthesis
3112                { $$ = $2->addArray( $4 ); }
3113        | '(' abstract_array ')'                                                        // redundant parenthesis
3114                { $$ = $2; }
3115        ;
3116
3117abstract_function:
3118        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3119                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3120        | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3121                { $$ = $2->addParamList( $6 ); }
3122        | '(' abstract_function ')'                                                     // redundant parenthesis
3123                { $$ = $2; }
3124        ;
3125
3126array_dimension:
3127                // Only the first dimension can be empty.
3128        '[' ']'
3129                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3130        | '[' ']' multi_array_dimension
3131                { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
3132        | multi_array_dimension
3133        ;
3134
3135multi_array_dimension:
3136        '[' push assignment_expression pop ']'
3137                { $$ = DeclarationNode::newArray( $3, 0, false ); }
3138        | '[' push '*' pop ']'                                                          // C99
3139                { $$ = DeclarationNode::newVarArray( 0 ); }
3140        | multi_array_dimension '[' push assignment_expression pop ']'
3141                { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
3142        | multi_array_dimension '[' push '*' pop ']'            // C99
3143                { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3144        ;
3145
3146// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3147// identifier to which the type applies, e.g.:
3148//
3149//              int f( int );                   // not handled here
3150//              int f( int * );                 // abstract function-prototype parameter; no parameter name specified
3151//              int f( int (*)() );             // abstract function-prototype parameter; no parameter name specified
3152//              int f( int (int) );             // abstract function-prototype parameter; no parameter name specified
3153//
3154// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3155// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3156// special meaning of parenthesis around a typedef name:
3157//
3158//              ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3159//              parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3160//              not as redundant parentheses around the identifier."
3161//
3162// For example:
3163//
3164//              typedef float T;
3165//              int f( int ( T [5] ) );                                 // see abstract_parameter_declarator
3166//              int g( int ( T ( int ) ) );                             // see abstract_parameter_declarator
3167//              int f( int f1( T a[5] ) );                              // see identifier_parameter_declarator
3168//              int g( int g1( T g2( int p ) ) );               // see identifier_parameter_declarator
3169//
3170// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3171// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3172// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3173// functions.
3174
3175abstract_parameter_declarator:
3176        abstract_parameter_ptr
3177        | '&' MUTEX attribute_list_opt
3178                { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3179        | abstract_parameter_array attribute_list_opt
3180                { $$ = $1->addQualifiers( $2 ); }
3181        | abstract_parameter_function attribute_list_opt
3182                { $$ = $1->addQualifiers( $2 ); }
3183        ;
3184
3185abstract_parameter_ptr:
3186        ptrref_operator
3187                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3188        | ptrref_operator type_qualifier_list
3189                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3190        | ptrref_operator abstract_parameter_declarator
3191                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3192        | ptrref_operator type_qualifier_list abstract_parameter_declarator
3193                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3194        | '(' abstract_parameter_ptr ')' attribute_list_opt
3195                { $$ = $2->addQualifiers( $4 ); }
3196        ;
3197
3198abstract_parameter_array:
3199        array_parameter_dimension
3200        | '(' abstract_parameter_ptr ')' array_parameter_dimension
3201                { $$ = $2->addArray( $4 ); }
3202        | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3203                { $$ = $2->addArray( $4 ); }
3204        | '(' abstract_parameter_array ')'                                      // redundant parenthesis
3205                { $$ = $2; }
3206        ;
3207
3208abstract_parameter_function:
3209        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3210                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3211        | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3212                { $$ = $2->addParamList( $6 ); }
3213        | '(' abstract_parameter_function ')'                           // redundant parenthesis
3214                { $$ = $2; }
3215        ;
3216
3217array_parameter_dimension:
3218                // Only the first dimension can be empty or have qualifiers.
3219        array_parameter_1st_dimension
3220        | array_parameter_1st_dimension multi_array_dimension
3221                { $$ = $1->addArray( $2 ); }
3222        | multi_array_dimension
3223        ;
3224
3225// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3226//
3227//              ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3228//              a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3229
3230array_parameter_1st_dimension:
3231        '[' ']'
3232                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3233                // multi_array_dimension handles the '[' '*' ']' case
3234        | '[' push type_qualifier_list '*' pop ']'                      // remaining C99
3235                { $$ = DeclarationNode::newVarArray( $3 ); }
3236        | '[' push type_qualifier_list pop ']'
3237                { $$ = DeclarationNode::newArray( 0, $3, false ); }
3238                // multi_array_dimension handles the '[' assignment_expression ']' case
3239        | '[' push type_qualifier_list assignment_expression pop ']'
3240                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3241        | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3242                { $$ = DeclarationNode::newArray( $5, $4, true ); }
3243        | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3244                { $$ = DeclarationNode::newArray( $5, $3, true ); }
3245        ;
3246
3247// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3248//
3249//              struct S {
3250//          int;
3251//          int *;
3252//          int [10];
3253//          int (*)();
3254//      };
3255
3256variable_abstract_declarator:
3257        variable_abstract_ptr
3258        | variable_abstract_array attribute_list_opt
3259                { $$ = $1->addQualifiers( $2 ); }
3260        | variable_abstract_function attribute_list_opt
3261                { $$ = $1->addQualifiers( $2 ); }
3262        ;
3263
3264variable_abstract_ptr:
3265        ptrref_operator
3266                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3267        | ptrref_operator type_qualifier_list
3268                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3269        | ptrref_operator variable_abstract_declarator
3270                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3271        | ptrref_operator type_qualifier_list variable_abstract_declarator
3272                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3273        | '(' variable_abstract_ptr ')' attribute_list_opt
3274                { $$ = $2->addQualifiers( $4 ); }
3275        ;
3276
3277variable_abstract_array:
3278        array_dimension
3279        | '(' variable_abstract_ptr ')' array_dimension
3280                { $$ = $2->addArray( $4 ); }
3281        | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3282                { $$ = $2->addArray( $4 ); }
3283        | '(' variable_abstract_array ')'                                       // redundant parenthesis
3284                { $$ = $2; }
3285        ;
3286
3287variable_abstract_function:
3288        '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3289                { $$ = $2->addParamList( $6 ); }
3290        | '(' variable_abstract_function ')'                            // redundant parenthesis
3291                { $$ = $2; }
3292        ;
3293
3294// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3295// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3296
3297cfa_identifier_parameter_declarator_tuple:                              // CFA
3298        cfa_identifier_parameter_declarator_no_tuple
3299        | cfa_abstract_tuple
3300        | type_qualifier_list cfa_abstract_tuple
3301                { $$ = $2->addQualifiers( $1 ); }
3302        ;
3303
3304cfa_identifier_parameter_declarator_no_tuple:                   // CFA
3305        cfa_identifier_parameter_ptr
3306        | cfa_identifier_parameter_array
3307        ;
3308
3309cfa_identifier_parameter_ptr:                                                   // CFA
3310                // No SUE declaration in parameter list.
3311        ptrref_operator type_specifier_nobody
3312                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3313        | type_qualifier_list ptrref_operator type_specifier_nobody
3314                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3315        | ptrref_operator cfa_abstract_function
3316                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3317        | type_qualifier_list ptrref_operator cfa_abstract_function
3318                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3319        | ptrref_operator cfa_identifier_parameter_declarator_tuple
3320                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3321        | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3322                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3323        ;
3324
3325cfa_identifier_parameter_array:                                                 // CFA
3326                // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3327                // shift/reduce conflict with new-style empty (void) function return type.
3328        '[' ']' type_specifier_nobody
3329                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3330        | cfa_array_parameter_1st_dimension type_specifier_nobody
3331                { $$ = $2->addNewArray( $1 ); }
3332        | '[' ']' multi_array_dimension type_specifier_nobody
3333                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3334        | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3335                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3336        | multi_array_dimension type_specifier_nobody
3337                { $$ = $2->addNewArray( $1 ); }
3338
3339        | '[' ']' cfa_identifier_parameter_ptr
3340                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3341        | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3342                { $$ = $2->addNewArray( $1 ); }
3343        | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3344                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3345        | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3346                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3347        | multi_array_dimension cfa_identifier_parameter_ptr
3348                { $$ = $2->addNewArray( $1 ); }
3349        ;
3350
3351cfa_array_parameter_1st_dimension:
3352        '[' push type_qualifier_list '*' pop ']'                        // remaining C99
3353                { $$ = DeclarationNode::newVarArray( $3 ); }
3354        | '[' push type_qualifier_list assignment_expression pop ']'
3355                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3356        | '[' push declaration_qualifier_list assignment_expression pop ']'
3357                // declaration_qualifier_list must be used because of shift/reduce conflict with
3358                // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3359                // appear in this context.
3360                { $$ = DeclarationNode::newArray( $4, $3, true ); }
3361        | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3362                { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3363        ;
3364
3365// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3366// identifier to which the type applies, e.g.:
3367//
3368//              [int] f( int );                         // abstract variable parameter; no parameter name specified
3369//              [int] f( [int] (int) );         // abstract function-prototype parameter; no parameter name specified
3370//
3371// These rules need LR(3):
3372//
3373//              cfa_abstract_tuple identifier_or_type_name
3374//              '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
3375//
3376// since a function return type can be syntactically identical to a tuple type:
3377//
3378//              [int, int] t;
3379//              [int, int] f( int );
3380//
3381// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3382// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3383// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3384// duplicated when appearing with cfa_function_specifier.
3385
3386cfa_abstract_declarator_tuple:                                                  // CFA
3387        cfa_abstract_tuple
3388        | type_qualifier_list cfa_abstract_tuple
3389                { $$ = $2->addQualifiers( $1 ); }
3390        | cfa_abstract_declarator_no_tuple
3391        ;
3392
3393cfa_abstract_declarator_no_tuple:                                               // CFA
3394        cfa_abstract_ptr
3395        | cfa_abstract_array
3396        ;
3397
3398cfa_abstract_ptr:                                                                               // CFA
3399        ptrref_operator type_specifier
3400                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3401        | type_qualifier_list ptrref_operator type_specifier
3402                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3403        | ptrref_operator cfa_abstract_function
3404                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3405        | type_qualifier_list ptrref_operator cfa_abstract_function
3406                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3407        | ptrref_operator cfa_abstract_declarator_tuple
3408                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3409        | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3410                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3411        ;
3412
3413cfa_abstract_array:                                                                             // CFA
3414                // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3415                // empty (void) function return type.
3416        '[' ']' type_specifier
3417                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3418        | '[' ']' multi_array_dimension type_specifier
3419                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3420        | multi_array_dimension type_specifier
3421                { $$ = $2->addNewArray( $1 ); }
3422        | '[' ']' cfa_abstract_ptr
3423                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3424        | '[' ']' multi_array_dimension cfa_abstract_ptr
3425                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3426        | multi_array_dimension cfa_abstract_ptr
3427                { $$ = $2->addNewArray( $1 ); }
3428        ;
3429
3430cfa_abstract_tuple:                                                                             // CFA
3431        '[' push cfa_abstract_parameter_list pop ']'
3432                { $$ = DeclarationNode::newTuple( $3 ); }
3433        | '[' push type_specifier_nobody ELLIPSIS pop ']'
3434                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3435        | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
3436                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3437        ;
3438
3439cfa_abstract_function:                                                                  // CFA
3440//      '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
3441//              { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3442        cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
3443                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3444        | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
3445                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3446        ;
3447
3448// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3449//    each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3450//
3451// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3452//    the declaration specifiers in a declaration is an obsolescent feature."
3453//
3454// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3455//    prototype-format parameter type declarators) is an obsolescent feature."
3456//
3457// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3458//    declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3459
3460//************************* MISCELLANEOUS ********************************
3461
3462comma_opt:                                                                                              // redundant comma
3463        // empty
3464        | ','
3465        ;
3466
3467default_initialize_opt:
3468        // empty
3469                { $$ = nullptr; }
3470        | '=' assignment_expression
3471                { $$ = $2; }
3472        ;
3473
3474%%
3475
3476// ----end of grammar----
3477
3478// Local Variables: //
3479// mode: c++ //
3480// tab-width: 4 //
3481// compile-command: "make install" //
3482// End: //
Note: See TracBrowser for help on using the repository browser.