source: src/Parser/parser.yy@ 2b78949

ADT
Last change on this file since 2b78949 was 3982384, checked in by JiadaL <j82liang@…>, 2 years ago

Merge branch 'master' of plg.uwaterloo.ca:software/cfa/cfa-cc
  • Property mode set to 100644
File size: 173.5 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author : Peter A. Buhr
10// Created On : Sat Sep 1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Wed Apr 26 16:45:37 2023
13// Update Count : 6330
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS. While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks. Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// designation with '=' (use ':' instead)
29//
30// This incompatibility is discussed in detail before the "designation" grammar rule. Most of the syntactic extensions
31// from ANSI90 to ANSI11 C are marked with the comment "C99/C11".
32
33// This grammar also has two levels of extensions. The first extensions cover most of the GCC C extensions. All of the
34// syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall (CFA), which
35// fixes several of C's outstanding problems and extends C with many modern language concepts. All of the syntactic
36// extensions for CFA C are marked with the comment "CFA".
37
38%{
39#define YYDEBUG_LEXER_TEXT( yylval ) // lexer loads this up each time
40#define YYDEBUG 1 // get the pretty debugging code to compile
41#define YYERROR_VERBOSE // more information in syntax errors
42
43#undef __GNUC_MINOR__
44
45#include <cstdio>
46#include <sstream>
47#include <stack>
48using namespace std;
49
50#include "SynTree/Type.h" // for Type
51#include "DeclarationNode.h" // for DeclarationNode, ...
52#include "ExpressionNode.h" // for ExpressionNode, ...
53#include "InitializerNode.h" // for InitializerNode, ...
54#include "ParserTypes.h"
55#include "StatementNode.h" // for build_...
56#include "TypedefTable.h"
57#include "TypeData.h"
58#include "Common/SemanticError.h" // error_str
59#include "Common/utility.h" // for maybeMoveBuild, maybeBuild, CodeLo...
60
61#include "SynTree/Attribute.h" // for Attribute
62
63// lex uses __null in a boolean context, it's fine.
64#ifdef __clang__
65#pragma GCC diagnostic ignored "-Wparentheses-equality"
66#endif
67
68extern DeclarationNode * parseTree;
69extern ast::Linkage::Spec linkage;
70extern TypedefTable typedefTable;
71
72stack<ast::Linkage::Spec> linkageStack;
73
74bool appendStr( string & to, string & from ) {
75 // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
76 // "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
77 // the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
78 // easier to let the C compiler handle this case.
79 //
80 // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
81 // without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
82 // e.g., u"a" U"b" L"c" is disallowed.
83
84 if ( from[0] != '"' ) { // encoding ?
85 if ( to[0] != '"' ) { // encoding ?
86 if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
87 yyerror( "non-matching string encodings for string-literal concatenation" );
88 return false; // parse error, must call YYERROR in action
89 } else if ( from[1] == '8' ) {
90 from.erase( 0, 1 ); // remove 2nd encoding
91 } // if
92 } else {
93 if ( from[1] == '8' ) { // move encoding to start
94 to = "u8" + to;
95 from.erase( 0, 1 ); // remove 2nd encoding
96 } else {
97 to = from[0] + to;
98 } // if
99 } // if
100 from.erase( 0, 1 ); // remove 2nd encoding
101 } // if
102 to += " " + from; // concatenated into single string
103 return true;
104} // appendStr
105
106DeclarationNode * distAttr( DeclarationNode * typeSpec, DeclarationNode * declList ) {
107 // distribute declaration_specifier across all declared variables, e.g., static, const, but not __attribute__.
108 assert( declList );
109 // printf( "distAttr1 typeSpec %p\n", typeSpec ); typeSpec->print( std::cout );
110 DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( typeSpec );
111 // printf( "distAttr2 cl %p\n", cl ); cl->type->print( std::cout );
112 // cl->type->aggregate.name = cl->type->aggInst.aggregate->aggregate.name;
113
114 for ( cur = dynamic_cast<DeclarationNode *>( cur->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode *>( cur->get_next() ) ) {
115 cl->cloneBaseType( cur );
116 } // for
117 declList->addType( cl );
118 // printf( "distAttr3 declList %p\n", declList ); declList->print( std::cout, 0 );
119 return declList;
120} // distAttr
121
122void distExt( DeclarationNode * declaration ) {
123 // distribute EXTENSION across all declarations
124 for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
125 iter->set_extension( true );
126 } // for
127} // distExt
128
129void distInl( DeclarationNode * declaration ) {
130 // distribute INLINE across all declarations
131 for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
132 iter->set_inLine( true );
133 } // for
134} // distInl
135
136void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
137 // distribute qualifiers across all non-variable declarations in a distribution statemement
138 for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
139 // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
140 // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
141 // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
142 // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
143 DeclarationNode * clone = qualifiers->clone();
144 if ( qualifiers->type ) { // forall clause ? (handles SC)
145 if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
146 swap( clone->type->forall, iter->type->aggregate.params );
147 iter->addQualifiers( clone );
148 } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
149 // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
150 DeclarationNode newnode;
151 swap( newnode.type, iter->type->aggInst.aggregate );
152 swap( clone->type->forall, newnode.type->aggregate.params );
153 newnode.addQualifiers( clone );
154 swap( newnode.type, iter->type->aggInst.aggregate );
155 } else if ( iter->type->kind == TypeData::Function ) { // routines ?
156 swap( clone->type->forall, iter->type->forall );
157 iter->addQualifiers( clone );
158 } // if
159 } else { // just SC qualifiers
160 iter->addQualifiers( clone );
161 } // if
162 } // for
163 delete qualifiers;
164} // distQual
165
166// There is an ambiguity for inline generic-routine return-types and generic routines.
167// forall( otype T ) struct S { int i; } bar( T ) {}
168// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
169// forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
170// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
171// forall( otype T ) struct S { int T; };
172// forall( otype W ) bar( W ) {}
173
174void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
175 if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
176 funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
177 declSpec->type->aggregate.params = nullptr;
178 } // if
179} // rebindForall
180
181string * build_postfix_name( string * name ) {
182 *name = string("__postfix_func_") + *name;
183 return name;
184} // build_postfix_name
185
186DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
187 if ( ! fieldList ) { // field declarator ?
188 if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate || typeSpec->type->kind == TypeData::Enum) ) ) {
189 stringstream ss;
190 // printf( "fieldDecl1 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
191 SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
192 return nullptr;
193 } // if
194 // printf( "fieldDecl2 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
195 fieldList = DeclarationNode::newName( nullptr );
196 } // if
197// return distAttr( typeSpec, fieldList ); // mark all fields in list
198
199 // printf( "fieldDecl3 typeSpec %p\n", typeSpec ); typeSpec->print( std::cout, 0 );
200 DeclarationNode * temp = distAttr( typeSpec, fieldList ); // mark all fields in list
201 // printf( "fieldDecl4 temp %p\n", temp ); temp->print( std::cout, 0 );
202 return temp;
203} // fieldDecl
204
205#define NEW_ZERO new ExpressionNode( build_constantInteger( yylloc, *new string( "0" ) ) )
206#define NEW_ONE new ExpressionNode( build_constantInteger( yylloc, *new string( "1" ) ) )
207#define UPDOWN( compop, left, right ) (compop == OperKinds::LThan || compop == OperKinds::LEThan ? left : right)
208#define MISSING_ANON_FIELD "Missing loop fields with an anonymous loop index is meaningless as loop index is unavailable in loop body."
209#define MISSING_LOW "Missing low value for up-to range so index is uninitialized."
210#define MISSING_HIGH "Missing high value for down-to range so index is uninitialized."
211
212static ForCtrl * makeForCtrl(
213 const CodeLocation & location,
214 DeclarationNode * init,
215 enum OperKinds compop,
216 ExpressionNode * comp,
217 ExpressionNode * inc ) {
218 // Wrap both comp/inc if they are non-null.
219 if ( comp ) comp = new ExpressionNode( build_binary_val( location,
220 compop,
221 new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
222 comp ) );
223 if ( inc ) inc = new ExpressionNode( build_binary_val( location,
224 // choose += or -= for upto/downto
225 compop == OperKinds::LThan || compop == OperKinds::LEThan ? OperKinds::PlusAssn : OperKinds::MinusAssn,
226 new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
227 inc ) );
228 // The StatementNode call frees init->name, it must happen later.
229 return new ForCtrl( new StatementNode( init ), comp, inc );
230}
231
232ForCtrl * forCtrl( const CodeLocation & location, DeclarationNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
233 if ( index->initializer ) {
234 SemanticError( yylloc, "Direct initialization disallowed. Use instead: type var; initialization ~ comparison ~ increment." );
235 } // if
236 if ( index->next ) {
237 SemanticError( yylloc, "Multiple loop indexes disallowed in for-loop declaration." );
238 } // if
239 DeclarationNode * initDecl = index->addInitializer( new InitializerNode( start ) );
240 return makeForCtrl( location, initDecl, compop, comp, inc );
241} // forCtrl
242
243ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
244 ast::ConstantExpr * constant = dynamic_cast<ast::ConstantExpr *>(type->expr.get());
245 if ( constant && (constant->rep == "0" || constant->rep == "1") ) {
246 type = new ExpressionNode( new ast::CastExpr( location, maybeMoveBuild(type), new ast::BasicType( ast::BasicType::SignedInt ) ) );
247 } // if
248 DeclarationNode * initDecl = distAttr(
249 DeclarationNode::newTypeof( type, true ),
250 DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) )
251 );
252 return makeForCtrl( location, initDecl, compop, comp, inc );
253} // forCtrl
254
255ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
256 if ( auto identifier = dynamic_cast<ast::NameExpr *>(index->expr.get()) ) {
257 return forCtrl( location, type, new string( identifier->name ), start, compop, comp, inc );
258 } else if ( auto commaExpr = dynamic_cast<ast::CommaExpr *>( index->expr.get() ) ) {
259 if ( auto identifier = commaExpr->arg1.as<ast::NameExpr>() ) {
260 return forCtrl( location, type, new string( identifier->name ), start, compop, comp, inc );
261 } else {
262 SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed." ); return nullptr;
263 } // if
264 } else {
265 SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed." ); return nullptr;
266 } // if
267} // forCtrl
268
269static void IdentifierBeforeIdentifier( string & identifier1, string & identifier2, const char * kind ) {
270 SemanticError( yylloc, ::toString( "Adjacent identifiers \"", identifier1, "\" and \"", identifier2, "\" are not meaningful in a", kind, ".\n"
271 "Possible cause is misspelled type name or missing generic parameter." ) );
272} // IdentifierBeforeIdentifier
273
274static void IdentifierBeforeType( string & identifier, const char * kind ) {
275 SemanticError( yylloc, ::toString( "Identifier \"", identifier, "\" cannot appear before a ", kind, ".\n"
276 "Possible cause is misspelled storage/CV qualifier, misspelled typename, or missing generic parameter." ) );
277} // IdentifierBeforeType
278
279bool forall = false; // aggregate have one or more forall qualifiers ?
280
281// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
282#define YYLLOC_DEFAULT(Cur, Rhs, N) \
283if ( N ) { \
284 (Cur).first_line = YYRHSLOC( Rhs, 1 ).first_line; \
285 (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column; \
286 (Cur).last_line = YYRHSLOC( Rhs, N ).last_line; \
287 (Cur).last_column = YYRHSLOC( Rhs, N ).last_column; \
288 (Cur).filename = YYRHSLOC( Rhs, 1 ).filename; \
289} else { \
290 (Cur).first_line = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line; \
291 (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column; \
292 (Cur).filename = YYRHSLOC( Rhs, 0 ).filename; \
293}
294%}
295
296%define parse.error verbose
297
298// Types declaration for productions
299
300%union {
301 Token tok;
302 ExpressionNode * expr;
303 DeclarationNode * decl;
304 ast::AggregateDecl::Aggregate aggKey;
305 ast::TypeDecl::Kind tclass;
306 StatementNode * stmt;
307 ClauseNode * clause;
308 ast::WaitForStmt * wfs;
309 ast::WaitUntilStmt::ClauseNode * wucn;
310 CondCtl * ifctl;
311 ForCtrl * forctl;
312 LabelNode * labels;
313 InitializerNode * init;
314 OperKinds oper;
315 std::string * str;
316 bool is_volatile;
317 EnumHiding enum_hiding;
318 ast::ExceptionKind except_kind;
319 ast::GenericExpr * genexpr;
320}
321
322// ************************ TERMINAL TOKENS ********************************
323
324// keywords
325%token TYPEDEF
326%token EXTERN STATIC AUTO REGISTER
327%token THREADLOCALGCC THREADLOCALC11 // GCC, C11
328%token INLINE FORTRAN // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
329%token NORETURN // C11
330%token CONST VOLATILE
331%token RESTRICT // C99
332%token ATOMIC // C11
333%token FORALL MUTEX VIRTUAL VTABLE COERCE // CFA
334%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
335%token BOOL COMPLEX IMAGINARY // C99
336%token INT128 UINT128 uuFLOAT80 uuFLOAT128 // GCC
337%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
338%token DECIMAL32 DECIMAL64 DECIMAL128 // GCC
339%token ZERO_T ONE_T // CFA
340%token SIZEOF TYPEOF VA_LIST VA_ARG AUTO_TYPE // GCC
341%token OFFSETOF BASETYPEOF TYPEID // CFA
342%token ENUM STRUCT UNION
343%token EXCEPTION // CFA
344%token GENERATOR COROUTINE MONITOR THREAD // CFA
345%token OTYPE FTYPE DTYPE TTYPE TRAIT // CFA
346// %token RESUME // CFA
347%token LABEL // GCC
348%token SUSPEND // CFA
349%token ATTRIBUTE EXTENSION // GCC
350%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
351%token CHOOSE FALLTHRU FALLTHROUGH WITH WHEN WAITFOR WAITUNTIL // CFA
352%token DISABLE ENABLE TRY THROW THROWRESUME AT // CFA
353%token ASM // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
354%token ALIGNAS ALIGNOF GENERIC STATICASSERT // C11
355
356// names and constants: lexer differentiates between identifier and typedef names
357%token<tok> IDENTIFIER TYPEDIMname TYPEDEFname TYPEGENname
358%token<tok> TIMEOUT WAND WOR CATCH RECOVER CATCHRESUME FIXUP FINALLY // CFA
359%token<tok> INTEGERconstant CHARACTERconstant STRINGliteral
360%token<tok> DIRECTIVE
361// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
362// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
363// converted into the tuple index (.)(1). e.g., 3.x
364%token<tok> FLOATING_DECIMALconstant FLOATING_FRACTIONconstant FLOATINGconstant
365
366// multi-character operators
367%token ARROW // ->
368%token ICR DECR // ++ --
369%token LS RS // << >>
370%token LE GE EQ NE // <= >= == !=
371%token ANDAND OROR // && ||
372%token ELLIPSIS // ...
373
374%token EXPassign MULTassign DIVassign MODassign // \= *= /= %=
375%token PLUSassign MINUSassign // += -=
376%token LSassign RSassign // <<= >>=
377%token ANDassign ERassign ORassign // &= ^= |=
378
379%token ErangeUpEq ErangeDown ErangeDownEq // ~= -~ -~=
380%token ATassign // @=
381
382%type<tok> identifier identifier_at identifier_or_type_name attr_name
383%type<tok> quasi_keyword
384%type<expr> string_literal
385%type<str> string_literal_list
386
387%type<enum_hiding> hide_opt visible_hide_opt
388
389// expressions
390%type<expr> constant
391%type<expr> tuple tuple_expression_list
392%type<oper> ptrref_operator unary_operator assignment_operator simple_assignment_operator compound_assignment_operator
393%type<expr> primary_expression postfix_expression unary_expression
394%type<expr> cast_expression_list cast_expression exponential_expression multiplicative_expression additive_expression
395%type<expr> shift_expression relational_expression equality_expression
396%type<expr> AND_expression exclusive_OR_expression inclusive_OR_expression
397%type<expr> logical_AND_expression logical_OR_expression
398%type<expr> conditional_expression constant_expression assignment_expression assignment_expression_opt
399%type<expr> comma_expression comma_expression_opt
400%type<expr> argument_expression_list_opt argument_expression_list argument_expression default_initializer_opt
401%type<ifctl> conditional_declaration
402%type<forctl> for_control_expression for_control_expression_list
403%type<oper> upupeq updown updowneq downupdowneq
404%type<expr> subrange
405%type<decl> asm_name_opt
406%type<expr> asm_operands_opt asm_operands_list asm_operand
407%type<labels> label_list
408%type<expr> asm_clobbers_list_opt
409%type<is_volatile> asm_volatile_opt
410%type<expr> handler_predicate_opt
411%type<genexpr> generic_association generic_assoc_list
412
413// statements
414%type<stmt> statement labeled_statement compound_statement
415%type<stmt> statement_decl statement_decl_list statement_list_nodecl
416%type<stmt> selection_statement if_statement
417%type<clause> switch_clause_list_opt switch_clause_list
418%type<expr> case_value
419%type<clause> case_clause case_value_list case_label case_label_list
420%type<stmt> iteration_statement jump_statement
421%type<stmt> expression_statement asm_statement
422%type<stmt> with_statement
423%type<expr> with_clause_opt
424%type<stmt> exception_statement
425%type<clause> handler_clause finally_clause
426%type<except_kind> handler_key
427%type<stmt> mutex_statement
428%type<expr> when_clause when_clause_opt waitfor waituntil timeout
429%type<stmt> waitfor_statement waituntil_statement
430%type<wfs> wor_waitfor_clause
431%type<wucn> waituntil_clause wand_waituntil_clause wor_waituntil_clause
432
433// declarations
434%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
435%type<decl> abstract_parameter_declarator_opt abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
436%type<decl> abstract_parameter_declaration
437
438%type<aggKey> aggregate_key aggregate_data aggregate_control
439%type<decl> aggregate_type aggregate_type_nobody
440
441%type<decl> assertion assertion_list assertion_list_opt
442
443%type<expr> bit_subrange_size_opt bit_subrange_size
444
445%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
446%type<decl> vtable vtable_opt default_opt
447
448%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
449
450%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
451%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
452
453%type<decl> elaborated_type elaborated_type_nobody
454
455%type<decl> enumerator_list enum_type enum_type_nobody
456%type<init> enumerator_value_opt
457
458%type<decl> external_definition external_definition_list external_definition_list_opt
459
460%type<decl> exception_declaration
461
462%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
463%type<expr> field field_name_list field_name fraction_constants_opt
464
465%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
466
467%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
468%type<decl> identifier_list
469
470%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
471%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
472%type<decl> cfa_abstract_ptr cfa_abstract_tuple
473
474%type<decl> cfa_array_parameter_1st_dimension
475
476%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
477%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
478
479%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
480%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
481
482%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
483
484%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
485
486%type<decl> c_declaration static_assert
487%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
488%type<decl> KR_parameter_list KR_parameter_list_opt
489
490%type<decl> parameter_declaration parameter_list parameter_type_list_opt
491
492%type<decl> paren_identifier paren_type
493
494%type<decl> storage_class storage_class_list
495
496%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
497
498%type<tclass> type_class new_type_class
499%type<decl> type_declarator type_declarator_name type_declaring_list
500
501%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
502%type<decl> typedef_name typedef_declaration typedef_expression
503
504%type<decl> variable_type_redeclarator variable_type_ptr variable_type_array variable_type_function
505%type<decl> general_function_declarator function_type_redeclarator function_type_array function_type_no_ptr function_type_ptr
506
507%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
508
509%type<decl> type type_no_function
510%type<decl> type_parameter type_parameter_list type_initializer_opt
511
512%type<expr> type_parameters_opt type_list array_type_list
513
514%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
515%type<decl> type_specifier type_specifier_nobody
516
517%type<decl> variable_declarator variable_ptr variable_array variable_function
518%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
519
520%type<decl> attribute_list_opt attribute_list attribute attribute_name_list attribute_name
521
522// initializers
523%type<init> initializer initializer_list_opt initializer_opt
524
525// designators
526%type<expr> designator designator_list designation
527
528
529// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
530// .---------. matches IF '(' comma_expression ')' statement . (reduce)
531// if ( C ) S1 else S2
532// `-----------------' matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
533// Similar issues exit with the waitfor statement.
534
535// Order of these lines matters (low-to-high precedence). THEN is left associative over WAND/WOR/TIMEOUT/ELSE, WAND/WOR
536// is left associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
537%precedence THEN // rule precedence for IF/WAITFOR statement
538%precedence ANDAND // token precedence for start of WAND in WAITFOR statement
539%precedence WAND // token precedence for start of WAND in WAITFOR statement
540%precedence OROR // token precedence for start of WOR in WAITFOR statement
541%precedence WOR // token precedence for start of WOR in WAITFOR statement
542%precedence TIMEOUT // token precedence for start of TIMEOUT in WAITFOR statement
543%precedence CATCH // token precedence for start of TIMEOUT in WAITFOR statement
544%precedence RECOVER // token precedence for start of TIMEOUT in WAITFOR statement
545%precedence CATCHRESUME // token precedence for start of TIMEOUT in WAITFOR statement
546%precedence FIXUP // token precedence for start of TIMEOUT in WAITFOR statement
547%precedence FINALLY // token precedence for start of TIMEOUT in WAITFOR statement
548%precedence ELSE // token precedence for start of else clause in IF/WAITFOR statement
549
550
551// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
552// forall( otype T ) struct Foo { T v; };
553// .-----. matches pointer to function returning a generic (which is impossible without a type)
554// Foo ( *fp )( int );
555// `---' matches start of TYPEGENname '('
556// must be:
557// Foo( int ) ( *fp )( int );
558// The same problem occurs here:
559// forall( otype T ) struct Foo { T v; } ( *fp )( int );
560// must be:
561// forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
562
563// Order of these lines matters (low-to-high precedence).
564%precedence TYPEGENname
565%precedence '}'
566%precedence '('
567
568// %precedence RESUME
569// %precedence '{'
570// %precedence ')'
571
572%locations // support location tracking for error messages
573
574%start translation_unit // parse-tree root
575
576%%
577// ************************ Namespace Management ********************************
578
579// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
580// which are lexically identical.
581//
582// typedef int foo; // identifier foo must now be scanned as TYPEDEFname
583// foo f; // to allow it to appear in this context
584//
585// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
586// between syntactic and semantic constructs. Cforall compounds this problem by introducing type names local to the
587// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
588// generators" -- parameterized types. This latter type name creates a third class of identifiers, "TYPEGENname", which
589// must be distinguished by the lexical scanner.
590//
591// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
592// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
593// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
594// each context that introduces a name scope, a new level is created in the type table and that level is popped on
595// exiting the scope. Since type names can be local to a particular declaration, each declaration is itself a scope.
596// This requires distinguishing between type names that are local to the current declaration scope and those that
597// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
598//
599// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
600// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
601// around the list separator.
602//
603// int f( forall(T) T (*f1) T , forall( S ) S (*f2)( S ) );
604// push pop push pop
605
606push:
607 { typedefTable.enterScope(); }
608 ;
609
610pop:
611 { typedefTable.leaveScope(); }
612 ;
613
614// ************************ CONSTANTS ********************************
615
616constant:
617 // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
618 INTEGERconstant { $$ = new ExpressionNode( build_constantInteger( yylloc, *$1 ) ); }
619 | FLOATING_DECIMALconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
620 | FLOATING_FRACTIONconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
621 | FLOATINGconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
622 | CHARACTERconstant { $$ = new ExpressionNode( build_constantChar( yylloc, *$1 ) ); }
623 ;
624
625quasi_keyword: // CFA
626 TIMEOUT
627 | WAND
628 | WOR
629 | CATCH
630 | RECOVER
631 | CATCHRESUME
632 | FIXUP
633 | FINALLY
634 ;
635
636identifier:
637 IDENTIFIER
638 | quasi_keyword
639 ;
640
641identifier_at:
642 identifier
643 | '@' // CFA
644 { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
645 ;
646
647string_literal:
648 string_literal_list { $$ = new ExpressionNode( build_constantStr( yylloc, *$1 ) ); }
649 ;
650
651string_literal_list: // juxtaposed strings are concatenated
652 STRINGliteral { $$ = $1; } // conversion from tok to str
653 | string_literal_list STRINGliteral
654 {
655 if ( ! appendStr( *$1, *$2 ) ) YYERROR; // append 2nd juxtaposed string to 1st
656 delete $2; // allocated by lexer
657 $$ = $1; // conversion from tok to str
658 }
659 ;
660
661// ************************ EXPRESSIONS ********************************
662
663primary_expression:
664 IDENTIFIER // typedef name cannot be used as a variable name
665 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
666 | quasi_keyword
667 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
668 | TYPEDIMname // CFA, generic length argument
669 // { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( DeclarationNode::newFromTypedef( $1 ) ) ) ); }
670 // { $$ = new ExpressionNode( build_varref( $1 ) ); }
671 { $$ = new ExpressionNode( build_dimensionref( yylloc, $1 ) ); }
672 | tuple
673 | '(' comma_expression ')'
674 { $$ = $2; }
675 | '(' compound_statement ')' // GCC, lambda expression
676 { $$ = new ExpressionNode( new ast::StmtExpr( yylloc, dynamic_cast<ast::CompoundStmt *>( maybeMoveBuild( $2 ) ) ) ); }
677 | type_name '.' identifier // CFA, nested type
678 { $$ = new ExpressionNode( build_qualified_expr( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
679 | type_name '.' '[' field_name_list ']' // CFA, nested type / tuple field selector
680 { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
681 | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
682 {
683 // add the missing control expression to the GenericExpr and return it
684 $5->control = maybeMoveBuild( $3 );
685 $$ = new ExpressionNode( $5 );
686 }
687 // | RESUME '(' comma_expression ')'
688 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
689 // | RESUME '(' comma_expression ')' compound_statement
690 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
691 | IDENTIFIER IDENTIFIER // syntax error
692 { IdentifierBeforeIdentifier( *$1.str, *$2.str, "n expression" ); $$ = nullptr; }
693 | IDENTIFIER type_qualifier // syntax error
694 { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
695 | IDENTIFIER storage_class // syntax error
696 { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
697 | IDENTIFIER basic_type_name // syntax error
698 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
699 | IDENTIFIER TYPEDEFname // syntax error
700 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
701 | IDENTIFIER TYPEGENname // syntax error
702 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
703 ;
704
705generic_assoc_list: // C11
706 generic_association
707 | generic_assoc_list ',' generic_association
708 {
709 // steal the association node from the singleton and delete the wrapper
710 assert( 1 == $3->associations.size() );
711 $1->associations.push_back( $3->associations.front() );
712 delete $3;
713 $$ = $1;
714 }
715 ;
716
717generic_association: // C11
718 type_no_function ':' assignment_expression
719 {
720 // create a GenericExpr wrapper with one association pair
721 $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuildType( $1 ), maybeMoveBuild( $3 ) } } );
722 }
723 | DEFAULT ':' assignment_expression
724 { $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuild( $3 ) } } ); }
725 ;
726
727postfix_expression:
728 primary_expression
729 | postfix_expression '[' assignment_expression ',' tuple_expression_list ']'
730 // Historic, transitional: Disallow commas in subscripts.
731 // Switching to this behaviour may help check if a C compatibilty case uses comma-exprs in subscripts.
732 // Current: Commas in subscripts make tuples.
733 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, new ExpressionNode( build_tuple( yylloc, (ExpressionNode *)($3->set_last( $5 ) ) )) ) ); }
734 | postfix_expression '[' assignment_expression ']'
735 // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
736 // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
737 // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
738 // equivalent to the old x[i,j].
739 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
740 | constant '[' assignment_expression ']' // 3[a], 'a'[a], 3.5[a]
741 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
742 | string_literal '[' assignment_expression ']' // "abc"[3], 3["abc"]
743 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
744 | postfix_expression '{' argument_expression_list_opt '}' // CFA, constructor call
745 {
746 Token fn;
747 fn.str = new std::string( "?{}" ); // location undefined - use location of '{'?
748 $$ = new ExpressionNode( new ast::ConstructorExpr( yylloc, build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
749 }
750 | postfix_expression '(' argument_expression_list_opt ')'
751 { $$ = new ExpressionNode( build_func( yylloc, $1, $3 ) ); }
752 | VA_ARG '(' primary_expression ',' declaration_specifier_nobody abstract_parameter_declarator_opt ')'
753 // { SemanticError( yylloc, "va_arg is currently unimplemented." ); $$ = nullptr; }
754 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, new string( "__builtin_va_arg") ) ),
755 (ExpressionNode *)($3->set_last( (ExpressionNode *)($6 ? $6->addType( $5 ) : $5) )) ) ); }
756 | postfix_expression '`' identifier // CFA, postfix call
757 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
758 | constant '`' identifier // CFA, postfix call
759 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
760 | string_literal '`' identifier // CFA, postfix call
761 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
762 | postfix_expression '.' identifier
763 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
764 | postfix_expression '.' INTEGERconstant // CFA, tuple index
765 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
766 | postfix_expression FLOATING_FRACTIONconstant // CFA, tuple index
767 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 ) ) ); }
768 | postfix_expression '.' '[' field_name_list ']' // CFA, tuple field selector
769 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
770 | postfix_expression '.' aggregate_control
771 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $3, $1 ) ); }
772 | postfix_expression ARROW identifier
773 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
774 | postfix_expression ARROW INTEGERconstant // CFA, tuple index
775 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
776 | postfix_expression ARROW '[' field_name_list ']' // CFA, tuple field selector
777 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
778 | postfix_expression ICR
779 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::IncrPost, $1 ) ); }
780 | postfix_expression DECR
781 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::DecrPost, $1 ) ); }
782 | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
783 { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, new InitializerNode( $5, true ) ) ); }
784 | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
785 { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
786 | '^' primary_expression '{' argument_expression_list_opt '}' // CFA, destructor call
787 {
788 Token fn;
789 fn.str = new string( "^?{}" ); // location undefined
790 $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
791 }
792 ;
793
794argument_expression_list_opt:
795 // empty
796 { $$ = nullptr; }
797 | argument_expression_list
798 ;
799
800argument_expression_list:
801 argument_expression
802 | argument_expression_list_opt ',' argument_expression
803 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
804 ;
805
806argument_expression:
807 '@' // CFA, default parameter
808 { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
809 // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
810 | assignment_expression
811 ;
812
813field_name_list: // CFA, tuple field selector
814 field
815 | field_name_list ',' field { $$ = (ExpressionNode *)($1->set_last( $3 )); }
816 ;
817
818field: // CFA, tuple field selector
819 field_name
820 | FLOATING_DECIMALconstant field
821 { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), maybeMoveBuild( $2 ) ) ); }
822 | FLOATING_DECIMALconstant '[' field_name_list ']'
823 { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), build_tuple( yylloc, $3 ) ) ); }
824 | field_name '.' field
825 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
826 | field_name '.' '[' field_name_list ']'
827 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
828 | field_name ARROW field
829 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
830 | field_name ARROW '[' field_name_list ']'
831 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
832 ;
833
834field_name:
835 INTEGERconstant fraction_constants_opt
836 { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_constantInteger( yylloc, *$1 ), $2 ) ); }
837 | FLOATINGconstant fraction_constants_opt
838 { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_field_name_FLOATINGconstant( yylloc, *$1 ), $2 ) ); }
839 | identifier_at fraction_constants_opt // CFA, allow anonymous fields
840 {
841 $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_varref( yylloc, $1 ), $2 ) );
842 }
843 ;
844
845fraction_constants_opt:
846 // empty
847 { $$ = nullptr; }
848 | fraction_constants_opt FLOATING_FRACTIONconstant
849 {
850 ast::Expr * constant = build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 );
851 $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( yylloc, $1, constant ) ) : new ExpressionNode( constant );
852 }
853 ;
854
855unary_expression:
856 postfix_expression
857 // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
858 // semantics checks, e.g., ++3, 3--, *3, &&3
859 | constant
860 | string_literal
861 { $$ = $1; }
862 | EXTENSION cast_expression // GCC
863 { $$ = $2->set_extension( true ); }
864 // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
865 // { * X; } // dereference X
866 // { * int X; } // CFA declaration of pointer to int
867 | ptrref_operator cast_expression // CFA
868 {
869 switch ( $1 ) {
870 case OperKinds::AddressOf:
871 $$ = new ExpressionNode( new ast::AddressExpr( maybeMoveBuild( $2 ) ) );
872 break;
873 case OperKinds::PointTo:
874 $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) );
875 break;
876 case OperKinds::And:
877 $$ = new ExpressionNode( new ast::AddressExpr( new ast::AddressExpr( maybeMoveBuild( $2 ) ) ) );
878 break;
879 default:
880 assert( false );
881 }
882 }
883 | unary_operator cast_expression
884 { $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) ); }
885 | ICR unary_expression
886 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Incr, $2 ) ); }
887 | DECR unary_expression
888 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Decr, $2 ) ); }
889 | SIZEOF unary_expression
890 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuild( $2 ) ) ); }
891 | SIZEOF '(' type_no_function ')'
892 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
893 | ALIGNOF unary_expression // GCC, variable alignment
894 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuild( $2 ) ) ); }
895 | ALIGNOF '(' type_no_function ')' // GCC, type alignment
896 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
897 | OFFSETOF '(' type_no_function ',' identifier ')'
898 { $$ = new ExpressionNode( build_offsetOf( yylloc, $3, build_varref( yylloc, $5 ) ) ); }
899 | TYPEID '(' type_no_function ')'
900 {
901 SemanticError( yylloc, "typeid name is currently unimplemented." ); $$ = nullptr;
902 // $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) );
903 }
904 ;
905
906ptrref_operator:
907 '*' { $$ = OperKinds::PointTo; }
908 | '&' { $$ = OperKinds::AddressOf; }
909 // GCC, address of label must be handled by semantic check for ref,ref,label
910 | ANDAND { $$ = OperKinds::And; }
911 ;
912
913unary_operator:
914 '+' { $$ = OperKinds::UnPlus; }
915 | '-' { $$ = OperKinds::UnMinus; }
916 | '!' { $$ = OperKinds::Neg; }
917 | '~' { $$ = OperKinds::BitNeg; }
918 ;
919
920cast_expression:
921 unary_expression
922 | '(' type_no_function ')' cast_expression
923 { $$ = new ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
924 | '(' aggregate_control '&' ')' cast_expression // CFA
925 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
926 | '(' aggregate_control '*' ')' cast_expression // CFA
927 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
928 | '(' VIRTUAL ')' cast_expression // CFA
929 { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $4 ), maybeMoveBuildType( nullptr ) ) ); }
930 | '(' VIRTUAL type_no_function ')' cast_expression // CFA
931 { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $5 ), maybeMoveBuildType( $3 ) ) ); }
932 | '(' RETURN type_no_function ')' cast_expression // CFA
933 { SemanticError( yylloc, "Return cast is currently unimplemented." ); $$ = nullptr; }
934 | '(' COERCE type_no_function ')' cast_expression // CFA
935 { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
936 | '(' qualifier_cast_list ')' cast_expression // CFA
937 { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
938// | '(' type_no_function ')' tuple
939// { $$ = new ast::ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
940 ;
941
942qualifier_cast_list:
943 cast_modifier type_qualifier_name
944 | cast_modifier MUTEX
945 | qualifier_cast_list cast_modifier type_qualifier_name
946 | qualifier_cast_list cast_modifier MUTEX
947 ;
948
949cast_modifier:
950 '-'
951 | '+'
952 ;
953
954exponential_expression:
955 cast_expression
956 | exponential_expression '\\' cast_expression
957 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Exp, $1, $3 ) ); }
958 ;
959
960multiplicative_expression:
961 exponential_expression
962 | multiplicative_expression '*' exponential_expression
963 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mul, $1, $3 ) ); }
964 | multiplicative_expression '/' exponential_expression
965 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Div, $1, $3 ) ); }
966 | multiplicative_expression '%' exponential_expression
967 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mod, $1, $3 ) ); }
968 ;
969
970additive_expression:
971 multiplicative_expression
972 | additive_expression '+' multiplicative_expression
973 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Plus, $1, $3 ) ); }
974 | additive_expression '-' multiplicative_expression
975 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Minus, $1, $3 ) ); }
976 ;
977
978shift_expression:
979 additive_expression
980 | shift_expression LS additive_expression
981 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LShift, $1, $3 ) ); }
982 | shift_expression RS additive_expression
983 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::RShift, $1, $3 ) ); }
984 ;
985
986relational_expression:
987 shift_expression
988 | relational_expression '<' shift_expression
989 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LThan, $1, $3 ) ); }
990 | relational_expression '>' shift_expression
991 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GThan, $1, $3 ) ); }
992 | relational_expression LE shift_expression
993 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LEThan, $1, $3 ) ); }
994 | relational_expression GE shift_expression
995 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GEThan, $1, $3 ) ); }
996 ;
997
998equality_expression:
999 relational_expression
1000 | equality_expression EQ relational_expression
1001 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Eq, $1, $3 ) ); }
1002 | equality_expression NE relational_expression
1003 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Neq, $1, $3 ) ); }
1004 ;
1005
1006AND_expression:
1007 equality_expression
1008 | AND_expression '&' equality_expression
1009 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitAnd, $1, $3 ) ); }
1010 ;
1011
1012exclusive_OR_expression:
1013 AND_expression
1014 | exclusive_OR_expression '^' AND_expression
1015 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Xor, $1, $3 ) ); }
1016 ;
1017
1018inclusive_OR_expression:
1019 exclusive_OR_expression
1020 | inclusive_OR_expression '|' exclusive_OR_expression
1021 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitOr, $1, $3 ) ); }
1022 ;
1023
1024logical_AND_expression:
1025 inclusive_OR_expression
1026 | logical_AND_expression ANDAND inclusive_OR_expression
1027 { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::AndExpr ) ); }
1028 ;
1029
1030logical_OR_expression:
1031 logical_AND_expression
1032 | logical_OR_expression OROR logical_AND_expression
1033 { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::OrExpr ) ); }
1034 ;
1035
1036conditional_expression:
1037 logical_OR_expression
1038 | logical_OR_expression '?' comma_expression ':' conditional_expression
1039 { $$ = new ExpressionNode( build_cond( yylloc, $1, $3, $5 ) ); }
1040 // FIX ME: computes $1 twice
1041 | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
1042 { $$ = new ExpressionNode( build_cond( yylloc, $1, $1, $4 ) ); }
1043 ;
1044
1045constant_expression:
1046 conditional_expression
1047 ;
1048
1049assignment_expression:
1050 // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
1051 conditional_expression
1052 | unary_expression assignment_operator assignment_expression
1053 {
1054// if ( $2 == OperKinds::AtAssn ) {
1055// SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
1056// } else {
1057 $$ = new ExpressionNode( build_binary_val( yylloc, $2, $1, $3 ) );
1058// } // if
1059 }
1060 | unary_expression '=' '{' initializer_list_opt comma_opt '}'
1061 { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
1062 ;
1063
1064assignment_expression_opt:
1065 // empty
1066 { $$ = nullptr; }
1067 | assignment_expression
1068 ;
1069
1070assignment_operator:
1071 simple_assignment_operator
1072 | compound_assignment_operator
1073 ;
1074
1075simple_assignment_operator:
1076 '=' { $$ = OperKinds::Assign; }
1077 | ATassign { $$ = OperKinds::AtAssn; } // CFA
1078 ;
1079
1080compound_assignment_operator:
1081 EXPassign { $$ = OperKinds::ExpAssn; }
1082 | MULTassign { $$ = OperKinds::MulAssn; }
1083 | DIVassign { $$ = OperKinds::DivAssn; }
1084 | MODassign { $$ = OperKinds::ModAssn; }
1085 | PLUSassign { $$ = OperKinds::PlusAssn; }
1086 | MINUSassign { $$ = OperKinds::MinusAssn; }
1087 | LSassign { $$ = OperKinds::LSAssn; }
1088 | RSassign { $$ = OperKinds::RSAssn; }
1089 | ANDassign { $$ = OperKinds::AndAssn; }
1090 | ERassign { $$ = OperKinds::ERAssn; }
1091 | ORassign { $$ = OperKinds::OrAssn; }
1092 ;
1093
1094tuple: // CFA, tuple
1095 // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
1096 // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
1097// '[' ']'
1098// { $$ = new ExpressionNode( build_tuple() ); }
1099// | '[' push assignment_expression pop ']'
1100// { $$ = new ExpressionNode( build_tuple( $3 ) ); }
1101 '[' ',' tuple_expression_list ']'
1102 { $$ = new ExpressionNode( build_tuple( yylloc, (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
1103 | '[' push assignment_expression pop ',' tuple_expression_list ']'
1104 { $$ = new ExpressionNode( build_tuple( yylloc, (ExpressionNode *)($3->set_last( $6 ) ) )); }
1105 ;
1106
1107tuple_expression_list:
1108 assignment_expression
1109 | '@' // CFA
1110 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1111 | tuple_expression_list ',' assignment_expression
1112 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1113 | tuple_expression_list ',' '@'
1114 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1115 ;
1116
1117comma_expression:
1118 assignment_expression
1119 | comma_expression ',' assignment_expression
1120 { $$ = new ExpressionNode( new ast::CommaExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1121 ;
1122
1123comma_expression_opt:
1124 // empty
1125 { $$ = nullptr; }
1126 | comma_expression
1127 ;
1128
1129// ************************** STATEMENTS *******************************
1130
1131statement:
1132 labeled_statement
1133 | compound_statement
1134 | expression_statement
1135 | selection_statement
1136 | iteration_statement
1137 | jump_statement
1138 | with_statement
1139 | mutex_statement
1140 | waitfor_statement
1141 | waituntil_statement
1142 | exception_statement
1143 | enable_disable_statement
1144 { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1145 | asm_statement
1146 | DIRECTIVE
1147 { $$ = new StatementNode( build_directive( yylloc, $1 ) ); }
1148 ;
1149
1150labeled_statement:
1151 // labels cannot be identifiers 0 or 1
1152 identifier_or_type_name ':' attribute_list_opt statement
1153 { $$ = $4->add_label( yylloc, $1, $3 ); }
1154 | identifier_or_type_name ':' attribute_list_opt error // syntax error
1155 {
1156 SemanticError( yylloc, ::toString( "Label \"", *$1.str, "\" must be associated with a statement, "
1157 "where a declaration, case, or default is not a statement. "
1158 "Move the label or terminate with a semi-colon." ) );
1159 $$ = nullptr;
1160 }
1161 ;
1162
1163compound_statement:
1164 '{' '}'
1165 { $$ = new StatementNode( build_compound( yylloc, (StatementNode *)0 ) ); }
1166 | '{' push
1167 local_label_declaration_opt // GCC, local labels appear at start of block
1168 statement_decl_list // C99, intermix declarations and statements
1169 pop '}'
1170 { $$ = new StatementNode( build_compound( yylloc, $4 ) ); }
1171 ;
1172
1173statement_decl_list: // C99
1174 statement_decl
1175 | statement_decl_list statement_decl
1176 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1177 ;
1178
1179statement_decl:
1180 declaration // CFA, new & old style declarations
1181 { $$ = new StatementNode( $1 ); }
1182 | EXTENSION declaration // GCC
1183 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1184 | function_definition
1185 { $$ = new StatementNode( $1 ); }
1186 | EXTENSION function_definition // GCC
1187 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1188 | statement
1189 ;
1190
1191statement_list_nodecl:
1192 statement
1193 | statement_list_nodecl statement
1194 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1195 | statement_list_nodecl error // syntax error
1196 { SemanticError( yylloc, "Declarations only allowed at the start of the switch body, i.e., after the '{'." ); $$ = nullptr; }
1197 ;
1198
1199expression_statement:
1200 comma_expression_opt ';'
1201 { $$ = new StatementNode( build_expr( yylloc, $1 ) ); }
1202 ;
1203
1204selection_statement:
1205 // pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1206 // the inherent S/R conflict with THEN/ELSE.
1207 push if_statement pop
1208 { $$ = $2; }
1209 | SWITCH '(' comma_expression ')' case_clause
1210 { $$ = new StatementNode( build_switch( yylloc, true, $3, $5 ) ); }
1211 | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1212 {
1213 StatementNode *sw = new StatementNode( build_switch( yylloc, true, $3, $8 ) );
1214 // The semantics of the declaration list is changed to include associated initialization, which is performed
1215 // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1216 // statement around the switch. Statements after the initial declaration list can never be executed, and
1217 // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1218 // statement.
1219 $$ = $7 ? new StatementNode( build_compound( yylloc, (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1220 }
1221 | SWITCH '(' comma_expression ')' '{' error '}' // CFA, syntax error
1222 { SemanticError( yylloc, "Only declarations can appear before the list of case clauses." ); $$ = nullptr; }
1223 | CHOOSE '(' comma_expression ')' case_clause // CFA
1224 { $$ = new StatementNode( build_switch( yylloc, false, $3, $5 ) ); }
1225 | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1226 {
1227 StatementNode *sw = new StatementNode( build_switch( yylloc, false, $3, $8 ) );
1228 $$ = $7 ? new StatementNode( build_compound( yylloc, (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1229 }
1230 | CHOOSE '(' comma_expression ')' '{' error '}' // CFA, syntax error
1231 { SemanticError( yylloc, "Only declarations can appear before the list of case clauses." ); $$ = nullptr; }
1232 ;
1233
1234if_statement:
1235 IF '(' conditional_declaration ')' statement %prec THEN
1236 // explicitly deal with the shift/reduce conflict on if/else
1237 { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), nullptr ) ); }
1238 | IF '(' conditional_declaration ')' statement ELSE statement
1239 { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), maybe_build_compound( yylloc, $7 ) ) ); }
1240 ;
1241
1242conditional_declaration:
1243 comma_expression
1244 { $$ = new CondCtl( nullptr, $1 ); }
1245 | c_declaration // no semi-colon
1246 { $$ = new CondCtl( $1, nullptr ); }
1247 | cfa_declaration // no semi-colon
1248 { $$ = new CondCtl( $1, nullptr ); }
1249 | declaration comma_expression // semi-colon separated
1250 { $$ = new CondCtl( $1, $2 ); }
1251 ;
1252
1253// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1254// clause allows a list of values and subranges.
1255
1256case_value: // CFA
1257 constant_expression { $$ = $1; }
1258 | constant_expression ELLIPSIS constant_expression // GCC, subrange
1259 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1260 | subrange // CFA, subrange
1261 ;
1262
1263case_value_list: // CFA
1264 case_value { $$ = new ClauseNode( build_case( yylloc, $1 ) ); }
1265 // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1266 | case_value_list ',' case_value { $$ = $1->set_last( new ClauseNode( build_case( yylloc, $3 ) ) ); }
1267 ;
1268
1269case_label: // CFA
1270 CASE error // syntax error
1271 { SemanticError( yylloc, "Missing case list after case." ); $$ = nullptr; }
1272 | CASE case_value_list ':' { $$ = $2; }
1273 | CASE case_value_list error // syntax error
1274 { SemanticError( yylloc, "Missing colon after case list." ); $$ = nullptr; }
1275 | DEFAULT ':' { $$ = new ClauseNode( build_default( yylloc ) ); }
1276 // A semantic check is required to ensure only one default clause per switch/choose statement.
1277 | DEFAULT error // syntax error
1278 { SemanticError( yylloc, "Missing colon after default." ); $$ = nullptr; }
1279 ;
1280
1281case_label_list: // CFA
1282 case_label
1283 | case_label_list case_label { $$ = $1->set_last( $2 ); }
1284 ;
1285
1286case_clause: // CFA
1287 case_label_list statement { $$ = $1->append_last_case( maybe_build_compound( yylloc, $2 ) ); }
1288 ;
1289
1290switch_clause_list_opt: // CFA
1291 // empty
1292 { $$ = nullptr; }
1293 | switch_clause_list
1294 ;
1295
1296switch_clause_list: // CFA
1297 case_label_list statement_list_nodecl
1298 { $$ = $1->append_last_case( new StatementNode( build_compound( yylloc, $2 ) ) ); }
1299 | switch_clause_list case_label_list statement_list_nodecl
1300 { $$ = $1->set_last( $2->append_last_case( new StatementNode( build_compound( yylloc, $3 ) ) ) ); }
1301 ;
1302
1303iteration_statement:
1304 WHILE '(' ')' statement %prec THEN // CFA => while ( 1 )
1305 { $$ = new StatementNode( build_while( yylloc, new CondCtl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) ); }
1306 | WHILE '(' ')' statement ELSE statement // CFA
1307 {
1308 $$ = new StatementNode( build_while( yylloc, new CondCtl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) );
1309 SemanticWarning( yylloc, Warning::SuperfluousElse );
1310 }
1311 | WHILE '(' conditional_declaration ')' statement %prec THEN
1312 { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1313 | WHILE '(' conditional_declaration ')' statement ELSE statement // CFA
1314 { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1315 | DO statement WHILE '(' ')' ';' // CFA => do while( 1 )
1316 { $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) ); }
1317 | DO statement WHILE '(' ')' ELSE statement // CFA
1318 {
1319 $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) );
1320 SemanticWarning( yylloc, Warning::SuperfluousElse );
1321 }
1322 | DO statement WHILE '(' comma_expression ')' ';'
1323 { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ) ) ); }
1324 | DO statement WHILE '(' comma_expression ')' ELSE statement // CFA
1325 { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ), $8 ) ); }
1326 | FOR '(' ')' statement %prec THEN // CFA => for ( ;; )
1327 { $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) ); }
1328 | FOR '(' ')' statement ELSE statement // CFA
1329 {
1330 $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) );
1331 SemanticWarning( yylloc, Warning::SuperfluousElse );
1332 }
1333 | FOR '(' for_control_expression_list ')' statement %prec THEN
1334 { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1335 | FOR '(' for_control_expression_list ')' statement ELSE statement // CFA
1336 { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1337 ;
1338
1339for_control_expression_list:
1340 for_control_expression
1341 | for_control_expression_list ':' for_control_expression
1342 // ForCtrl + ForCtrl:
1343 // init + init => multiple declaration statements that are hoisted
1344 // condition + condition => (expression) && (expression)
1345 // change + change => (expression), (expression)
1346 {
1347 $1->init->set_last( $3->init );
1348 if ( $1->condition ) {
1349 if ( $3->condition ) {
1350 $1->condition->expr.reset( new ast::LogicalExpr( yylloc, $1->condition->expr.release(), $3->condition->expr.release(), ast::AndExpr ) );
1351 } // if
1352 } else $1->condition = $3->condition;
1353 if ( $1->change ) {
1354 if ( $3->change ) {
1355 $1->change->expr.reset( new ast::CommaExpr( yylloc, $1->change->expr.release(), $3->change->expr.release() ) );
1356 } // if
1357 } else $1->change = $3->change;
1358 $$ = $1;
1359 }
1360 ;
1361
1362for_control_expression:
1363 ';' comma_expression_opt ';' comma_expression_opt
1364 { $$ = new ForCtrl( nullptr, $2, $4 ); }
1365 | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1366 {
1367 StatementNode * init = $1 ? new StatementNode( new ast::ExprStmt( yylloc, maybeMoveBuild( $1 ) ) ) : nullptr;
1368 $$ = new ForCtrl( init, $3, $5 );
1369 }
1370 | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1371 { $$ = new ForCtrl( new StatementNode( $1 ), $2, $4 ); }
1372
1373 | '@' ';' comma_expression // CFA, empty loop-index
1374 { $$ = new ForCtrl( nullptr, $3, nullptr ); }
1375 | '@' ';' comma_expression ';' comma_expression // CFA, empty loop-index
1376 { $$ = new ForCtrl( nullptr, $3, $5 ); }
1377
1378 | comma_expression // CFA, anonymous loop-index
1379 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), NEW_ZERO, OperKinds::LThan, $1->clone(), NEW_ONE ); }
1380 | downupdowneq comma_expression // CFA, anonymous loop-index
1381 { $$ = forCtrl( yylloc, $2, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $1, NEW_ZERO, $2->clone() ), $1, UPDOWN( $1, $2->clone(), NEW_ZERO ), NEW_ONE ); }
1382
1383 | comma_expression updowneq comma_expression // CFA, anonymous loop-index
1384 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), NEW_ONE ); }
1385 | '@' updowneq comma_expression // CFA, anonymous loop-index
1386 {
1387 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1388 else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, NEW_ONE );
1389 }
1390 | comma_expression updowneq '@' // CFA, anonymous loop-index
1391 {
1392 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1393 else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1394 }
1395 | comma_expression updowneq comma_expression '~' comma_expression // CFA, anonymous loop-index
1396 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), $5 ); }
1397 | '@' updowneq comma_expression '~' comma_expression // CFA, anonymous loop-index
1398 {
1399 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1400 else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, $5 );
1401 }
1402 | comma_expression updowneq '@' '~' comma_expression // CFA, anonymous loop-index
1403 {
1404 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1405 else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1406 }
1407 | comma_expression updowneq comma_expression '~' '@' // CFA, error
1408 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1409 | '@' updowneq '@' // CFA, error
1410 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1411 | '@' updowneq comma_expression '~' '@' // CFA, error
1412 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1413 | comma_expression updowneq '@' '~' '@' // CFA, error
1414 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1415 | '@' updowneq '@' '~' '@' // CFA, error
1416 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1417
1418 | comma_expression ';' comma_expression // CFA
1419 { $$ = forCtrl( yylloc, $3, $1, NEW_ZERO, OperKinds::LThan, $3->clone(), NEW_ONE ); }
1420 | comma_expression ';' downupdowneq comma_expression // CFA
1421 { $$ = forCtrl( yylloc, $4, $1, UPDOWN( $3, NEW_ZERO, $4->clone() ), $3, UPDOWN( $3, $4->clone(), NEW_ZERO ), NEW_ONE ); }
1422
1423 | comma_expression ';' comma_expression updowneq comma_expression // CFA
1424 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), NEW_ONE ); }
1425 | comma_expression ';' '@' updowneq comma_expression // CFA
1426 {
1427 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1428 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, NEW_ONE );
1429 }
1430 | comma_expression ';' comma_expression updowneq '@' // CFA
1431 {
1432 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1433 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "Equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1434 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, NEW_ONE );
1435 }
1436 | comma_expression ';' '@' updowneq '@' // CFA, error
1437 { SemanticError( yylloc, "Missing low/high value for up/down-to range so index is uninitialized." ); $$ = nullptr; }
1438
1439 | comma_expression ';' comma_expression updowneq comma_expression '~' comma_expression // CFA
1440 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), $7 ); }
1441 | comma_expression ';' '@' updowneq comma_expression '~' comma_expression // CFA, error
1442 {
1443 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1444 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, $7 );
1445 }
1446 | comma_expression ';' comma_expression updowneq '@' '~' comma_expression // CFA
1447 {
1448 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1449 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "Equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1450 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, $7 );
1451 }
1452 | comma_expression ';' comma_expression updowneq comma_expression '~' '@' // CFA
1453 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), nullptr ); }
1454 | comma_expression ';' '@' updowneq comma_expression '~' '@' // CFA, error
1455 {
1456 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1457 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, nullptr );
1458 }
1459 | comma_expression ';' comma_expression updowneq '@' '~' '@' // CFA
1460 {
1461 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1462 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "Equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1463 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, nullptr );
1464 }
1465 | comma_expression ';' '@' updowneq '@' '~' '@' // CFA
1466 { SemanticError( yylloc, "Missing low/high value for up/down-to range so index is uninitialized." ); $$ = nullptr; }
1467
1468 | declaration comma_expression // CFA
1469 { $$ = forCtrl( yylloc, $1, NEW_ZERO, OperKinds::LThan, $2, NEW_ONE ); }
1470 | declaration downupdowneq comma_expression // CFA
1471 { $$ = forCtrl( yylloc, $1, UPDOWN( $2, NEW_ZERO, $3 ), $2, UPDOWN( $2, $3->clone(), NEW_ZERO ), NEW_ONE ); }
1472
1473 | declaration comma_expression updowneq comma_expression // CFA
1474 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2->clone(), $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), NEW_ONE ); }
1475 | declaration '@' updowneq comma_expression // CFA
1476 {
1477 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1478 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, NEW_ONE );
1479 }
1480 | declaration comma_expression updowneq '@' // CFA
1481 {
1482 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1483 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "Equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1484 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, NEW_ONE );
1485 }
1486
1487 | declaration comma_expression updowneq comma_expression '~' comma_expression // CFA
1488 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), $6 ); }
1489 | declaration '@' updowneq comma_expression '~' comma_expression // CFA
1490 {
1491 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1492 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, $6 );
1493 }
1494 | declaration comma_expression updowneq '@' '~' comma_expression // CFA
1495 {
1496 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1497 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "Equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1498 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, $6 );
1499 }
1500 | declaration comma_expression updowneq comma_expression '~' '@' // CFA
1501 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), nullptr ); }
1502 | declaration '@' updowneq comma_expression '~' '@' // CFA
1503 {
1504 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1505 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, nullptr );
1506 }
1507 | declaration comma_expression updowneq '@' '~' '@' // CFA
1508 {
1509 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1510 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "Equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1511 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, nullptr );
1512 }
1513 | declaration '@' updowneq '@' '~' '@' // CFA, error
1514 { SemanticError( yylloc, "Missing low/high value for up/down-to range so index is uninitialized." ); $$ = nullptr; }
1515
1516 | comma_expression ';' TYPEDEFname // CFA, array type
1517 {
1518 SemanticError( yylloc, "Type iterator is currently unimplemented." ); $$ = nullptr;
1519 //$$ = forCtrl( new ExpressionNode( build_varref( $3 ) ), $1, nullptr, OperKinds::Range, nullptr, nullptr );
1520 }
1521 | comma_expression ';' downupdowneq TYPEDEFname // CFA, array type
1522 {
1523 if ( $3 == OperKinds::LEThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, "All enumation ranges are equal (all values). Remove \"=~\"." ); $$ = nullptr; }
1524 SemanticError( yylloc, "Type iterator is currently unimplemented." ); $$ = nullptr;
1525 }
1526 ;
1527
1528downupdowneq:
1529 ErangeDown
1530 { $$ = OperKinds::GThan; }
1531 | ErangeUpEq
1532 { $$ = OperKinds::LEThan; }
1533 | ErangeDownEq
1534 { $$ = OperKinds::GEThan; }
1535 ;
1536
1537updown:
1538 '~'
1539 { $$ = OperKinds::LThan; }
1540 | ErangeDown
1541 { $$ = OperKinds::GThan; }
1542 ;
1543
1544updowneq:
1545 updown
1546 | ErangeUpEq
1547 { $$ = OperKinds::LEThan; }
1548 | ErangeDownEq
1549 { $$ = OperKinds::GEThan; }
1550 ;
1551
1552jump_statement:
1553 GOTO identifier_or_type_name ';'
1554 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Goto ) ); }
1555 | GOTO '*' comma_expression ';' // GCC, computed goto
1556 // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1557 // whereas normal operator precedence yields goto (*i)+3;
1558 { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1559 // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1560 | fall_through_name ';' // CFA
1561 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThrough ) ); }
1562 | fall_through_name identifier_or_type_name ';' // CFA
1563 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::FallThrough ) ); }
1564 | fall_through_name DEFAULT ';' // CFA
1565 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThroughDefault ) ); }
1566 | CONTINUE ';'
1567 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1568 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Continue ) ); }
1569 | CONTINUE identifier_or_type_name ';' // CFA, multi-level continue
1570 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1571 // the target of the transfer appears only at the start of an iteration statement.
1572 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Continue ) ); }
1573 | BREAK ';'
1574 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1575 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Break ) ); }
1576 | BREAK identifier_or_type_name ';' // CFA, multi-level exit
1577 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1578 // the target of the transfer appears only at the start of an iteration statement.
1579 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Break ) ); }
1580 | RETURN comma_expression_opt ';'
1581 { $$ = new StatementNode( build_return( yylloc, $2 ) ); }
1582 | RETURN '{' initializer_list_opt comma_opt '}' ';'
1583 { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1584 | SUSPEND ';'
1585 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::None ) ); }
1586 | SUSPEND compound_statement
1587 { $$ = new StatementNode( build_suspend( yylloc, $2, ast::SuspendStmt::None ) ); }
1588 | SUSPEND COROUTINE ';'
1589 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Coroutine ) ); }
1590 | SUSPEND COROUTINE compound_statement
1591 { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Coroutine ) ); }
1592 | SUSPEND GENERATOR ';'
1593 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Generator ) ); }
1594 | SUSPEND GENERATOR compound_statement
1595 { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Generator ) ); }
1596 | THROW assignment_expression_opt ';' // handles rethrow
1597 { $$ = new StatementNode( build_throw( yylloc, $2 ) ); }
1598 | THROWRESUME assignment_expression_opt ';' // handles reresume
1599 { $$ = new StatementNode( build_resume( yylloc, $2 ) ); }
1600 | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1601 { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1602 ;
1603
1604fall_through_name: // CFA
1605 FALLTHRU
1606 | FALLTHROUGH
1607 ;
1608
1609with_statement:
1610 WITH '(' tuple_expression_list ')' statement
1611 { $$ = new StatementNode( build_with( yylloc, $3, $5 ) ); }
1612 ;
1613
1614// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so possibly change syntax to "with mutex".
1615mutex_statement:
1616 MUTEX '(' argument_expression_list_opt ')' statement
1617 {
1618 if ( ! $3 ) { SemanticError( yylloc, "mutex argument list cannot be empty." ); $$ = nullptr; }
1619 $$ = new StatementNode( build_mutex( yylloc, $3, $5 ) );
1620 }
1621 ;
1622
1623when_clause:
1624 WHEN '(' comma_expression ')' { $$ = $3; }
1625 ;
1626
1627when_clause_opt:
1628 // empty
1629 { $$ = nullptr; }
1630 | when_clause
1631 ;
1632
1633cast_expression_list:
1634 cast_expression
1635 | cast_expression_list ',' cast_expression
1636 // { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1637 { SemanticError( yylloc, "List of mutex member is currently unimplemented." ); $$ = nullptr; }
1638 ;
1639
1640timeout:
1641 TIMEOUT '(' comma_expression ')' { $$ = $3; }
1642 ;
1643
1644wor:
1645 OROR
1646 | WOR
1647
1648waitfor:
1649 WAITFOR '(' cast_expression ')'
1650 { $$ = $3; }
1651 | WAITFOR '(' cast_expression_list ':' argument_expression_list_opt ')'
1652 { $$ = (ExpressionNode *)($3->set_last( $5 )); }
1653 ;
1654
1655wor_waitfor_clause:
1656 when_clause_opt waitfor statement %prec THEN
1657 // Called first: create header for WaitForStmt.
1658 { $$ = build_waitfor( yylloc, new ast::WaitForStmt( yylloc ), $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1659 | wor_waitfor_clause wor when_clause_opt waitfor statement
1660 { $$ = build_waitfor( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1661 | wor_waitfor_clause wor when_clause_opt ELSE statement
1662 { $$ = build_waitfor_else( yylloc, $1, $3, maybe_build_compound( yylloc, $5 ) ); }
1663 | wor_waitfor_clause wor when_clause_opt timeout statement %prec THEN
1664 { $$ = build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1665 // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1666 | wor_waitfor_clause wor when_clause_opt timeout statement wor ELSE statement // syntax error
1667 { SemanticError( yylloc, "else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1668 | wor_waitfor_clause wor when_clause_opt timeout statement wor when_clause ELSE statement
1669 { $$ = build_waitfor_else( yylloc, build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ), $7, maybe_build_compound( yylloc, $9 ) ); }
1670 ;
1671
1672waitfor_statement:
1673 wor_waitfor_clause %prec THEN
1674 { $$ = new StatementNode( $1 ); }
1675 ;
1676
1677wand:
1678 ANDAND
1679 | WAND
1680 ;
1681
1682waituntil:
1683 WAITUNTIL '(' comma_expression ')'
1684 { $$ = $3; }
1685 ;
1686
1687waituntil_clause:
1688 when_clause_opt waituntil statement
1689 { $$ = build_waituntil_clause( yylloc, $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1690 | '(' wor_waituntil_clause ')'
1691 { $$ = $2; }
1692 ;
1693
1694wand_waituntil_clause:
1695 waituntil_clause %prec THEN
1696 { $$ = $1; }
1697 | waituntil_clause wand wand_waituntil_clause
1698 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::AND, $1, $3 ); }
1699 ;
1700
1701wor_waituntil_clause:
1702 wand_waituntil_clause
1703 { $$ = $1; }
1704 | wor_waituntil_clause wor wand_waituntil_clause
1705 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::OR, $1, $3 ); }
1706 | wor_waituntil_clause wor when_clause_opt ELSE statement
1707 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::LEFT_OR, $1, build_waituntil_else( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1708 | wor_waituntil_clause wor when_clause_opt timeout statement %prec THEN
1709 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::LEFT_OR, $1, build_waituntil_timeout( yylloc, $3, $4, maybe_build_compound( yylloc, $5 ) ) ); }
1710 // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1711 | wor_waituntil_clause wor when_clause_opt timeout statement wor ELSE statement // syntax error
1712 { SemanticError( yylloc, "else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1713 | wor_waituntil_clause wor when_clause_opt timeout statement wor when_clause ELSE statement
1714 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::LEFT_OR, $1,
1715 new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::OR,
1716 build_waituntil_timeout( yylloc, $3, $4, maybe_build_compound( yylloc, $5 ) ),
1717 build_waituntil_else( yylloc, $7, maybe_build_compound( yylloc, $9 ) ) ) ); }
1718 ;
1719
1720waituntil_statement:
1721 wor_waituntil_clause %prec THEN
1722 // SKULLDUGGERY: create an empty compound statement to test parsing of waituntil statement.
1723 {
1724 $$ = new StatementNode( build_waituntil_stmt( yylloc, $1 ) );
1725 // $$ = new StatementNode( build_compound( yylloc, nullptr ) );
1726 }
1727 ;
1728
1729exception_statement:
1730 TRY compound_statement handler_clause %prec THEN
1731 { $$ = new StatementNode( build_try( yylloc, $2, $3, nullptr ) ); }
1732 | TRY compound_statement finally_clause
1733 { $$ = new StatementNode( build_try( yylloc, $2, nullptr, $3 ) ); }
1734 | TRY compound_statement handler_clause finally_clause
1735 { $$ = new StatementNode( build_try( yylloc, $2, $3, $4 ) ); }
1736 ;
1737
1738handler_clause:
1739 handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1740 { $$ = new ClauseNode( build_catch( yylloc, $1, $4, $6, $8 ) ); }
1741 | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1742 { $$ = $1->set_last( new ClauseNode( build_catch( yylloc, $2, $5, $7, $9 ) ) ); }
1743 ;
1744
1745handler_predicate_opt:
1746 // empty
1747 { $$ = nullptr; }
1748 | ';' conditional_expression { $$ = $2; }
1749 ;
1750
1751handler_key:
1752 CATCH { $$ = ast::Terminate; }
1753 | RECOVER { $$ = ast::Terminate; }
1754 | CATCHRESUME { $$ = ast::Resume; }
1755 | FIXUP { $$ = ast::Resume; }
1756 ;
1757
1758finally_clause:
1759 FINALLY compound_statement { $$ = new ClauseNode( build_finally( yylloc, $2 ) ); }
1760 ;
1761
1762exception_declaration:
1763 // No SUE declaration in parameter list.
1764 type_specifier_nobody
1765 | type_specifier_nobody declarator
1766 { $$ = $2->addType( $1 ); }
1767 | type_specifier_nobody variable_abstract_declarator
1768 { $$ = $2->addType( $1 ); }
1769 | cfa_abstract_declarator_tuple identifier // CFA
1770 { $$ = $1->addName( $2 ); }
1771 | cfa_abstract_declarator_tuple // CFA
1772 ;
1773
1774enable_disable_statement:
1775 enable_disable_key identifier_list compound_statement
1776 ;
1777
1778enable_disable_key:
1779 ENABLE
1780 | DISABLE
1781 ;
1782
1783asm_statement:
1784 ASM asm_volatile_opt '(' string_literal ')' ';'
1785 { $$ = new StatementNode( build_asm( yylloc, $2, $4, nullptr ) ); }
1786 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1787 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6 ) ); }
1788 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1789 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8 ) ); }
1790 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1791 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8, $10 ) ); }
1792 | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1793 { $$ = new StatementNode( build_asm( yylloc, $2, $5, nullptr, $8, $10, $12 ) ); }
1794 ;
1795
1796asm_volatile_opt: // GCC
1797 // empty
1798 { $$ = false; }
1799 | VOLATILE
1800 { $$ = true; }
1801 ;
1802
1803asm_operands_opt: // GCC
1804 // empty
1805 { $$ = nullptr; } // use default argument
1806 | asm_operands_list
1807 ;
1808
1809asm_operands_list: // GCC
1810 asm_operand
1811 | asm_operands_list ',' asm_operand
1812 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1813 ;
1814
1815asm_operand: // GCC
1816 string_literal '(' constant_expression ')'
1817 { $$ = new ExpressionNode( new ast::AsmExpr( yylloc, "", maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1818 | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1819 {
1820 $$ = new ExpressionNode( new ast::AsmExpr( yylloc, *$2.str, maybeMoveBuild( $4 ), maybeMoveBuild( $6 ) ) );
1821 delete $2.str;
1822 }
1823 ;
1824
1825asm_clobbers_list_opt: // GCC
1826 // empty
1827 { $$ = nullptr; } // use default argument
1828 | string_literal
1829 { $$ = $1; }
1830 | asm_clobbers_list_opt ',' string_literal
1831 { $$ = (ExpressionNode *)( $1->set_last( $3 ) ); }
1832 ;
1833
1834label_list:
1835 identifier
1836 {
1837 $$ = new LabelNode(); $$->labels.emplace_back( yylloc, *$1 );
1838 delete $1; // allocated by lexer
1839 }
1840 | label_list ',' identifier
1841 {
1842 $$ = $1; $1->labels.emplace_back( yylloc, *$3 );
1843 delete $3; // allocated by lexer
1844 }
1845 ;
1846
1847// ****************************** DECLARATIONS *********************************
1848
1849declaration_list_opt: // used at beginning of switch statement
1850 // empty
1851 { $$ = nullptr; }
1852 | declaration_list
1853 ;
1854
1855declaration_list:
1856 declaration
1857 | declaration_list declaration
1858 { $$ = $1->appendList( $2 ); }
1859 ;
1860
1861KR_parameter_list_opt: // used to declare parameter types in K&R style functions
1862 // empty
1863 { $$ = nullptr; }
1864 | KR_parameter_list
1865 ;
1866
1867KR_parameter_list:
1868 push c_declaration pop ';'
1869 { $$ = $2; }
1870 | KR_parameter_list push c_declaration pop ';'
1871 { $$ = $1->appendList( $3 ); }
1872 ;
1873
1874local_label_declaration_opt: // GCC, local label
1875 // empty
1876 | local_label_declaration_list
1877 ;
1878
1879local_label_declaration_list: // GCC, local label
1880 LABEL local_label_list ';'
1881 | local_label_declaration_list LABEL local_label_list ';'
1882 ;
1883
1884local_label_list: // GCC, local label
1885 identifier_or_type_name
1886 | local_label_list ',' identifier_or_type_name
1887 ;
1888
1889declaration: // old & new style declarations
1890 c_declaration ';'
1891 {
1892 // printf( "C_DECLARATION1 %p %s\n", $$, $$->name ? $$->name->c_str() : "(nil)" );
1893 // for ( Attribute * attr: reverseIterate( $$->attributes ) ) {
1894 // printf( "\tattr %s\n", attr->name.c_str() );
1895 // } // for
1896 }
1897 | cfa_declaration ';' // CFA
1898 | static_assert // C11
1899 ;
1900
1901static_assert:
1902 STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1903 { $$ = DeclarationNode::newStaticAssert( $3, maybeMoveBuild( $5 ) ); }
1904 | STATICASSERT '(' constant_expression ')' ';' // CFA
1905 { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( yylloc, *new string( "\"\"" ) ) ); }
1906
1907// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1908// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1909// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1910// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1911// the declaration list (as in Pascal). ANSI C and the new CFA declarations may appear together in the same program
1912// block, but cannot be mixed within a specific declaration.
1913//
1914// CFA C
1915// [10] int x; int x[10]; // array of 10 integers
1916// [10] * char y; char *y[10]; // array of 10 pointers to char
1917
1918cfa_declaration: // CFA
1919 cfa_variable_declaration
1920 | cfa_typedef_declaration
1921 | cfa_function_declaration
1922 | type_declaring_list
1923 { SemanticError( yylloc, "otype declaration is currently unimplemented." ); $$ = nullptr; }
1924 | trait_specifier
1925 ;
1926
1927cfa_variable_declaration: // CFA
1928 cfa_variable_specifier initializer_opt
1929 { $$ = $1->addInitializer( $2 ); }
1930 | declaration_qualifier_list cfa_variable_specifier initializer_opt
1931 // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1932 // them as a type_qualifier cannot appear in that context.
1933 { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1934 | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1935 { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1936 ;
1937
1938cfa_variable_specifier: // CFA
1939 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1940 // storage-class
1941 cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1942 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1943 | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1944 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1945 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1946 { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1947 ;
1948
1949cfa_function_declaration: // CFA
1950 cfa_function_specifier
1951 | type_qualifier_list cfa_function_specifier
1952 { $$ = $2->addQualifiers( $1 ); }
1953 | declaration_qualifier_list cfa_function_specifier
1954 { $$ = $2->addQualifiers( $1 ); }
1955 | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1956 { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1957 | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1958 {
1959 // Append the return type at the start (left-hand-side) to each identifier in the list.
1960 DeclarationNode * ret = new DeclarationNode;
1961 ret->type = maybeClone( $1->type->base );
1962 $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1963 }
1964 ;
1965
1966cfa_function_specifier: // CFA
1967// '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1968// {
1969// $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, nullptr, true );
1970// }
1971// '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1972// {
1973// typedefTable.setNextIdentifier( *$5 );
1974// $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, nullptr, true );
1975// }
1976// | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1977// {
1978// typedefTable.setNextIdentifier( *$5 );
1979// $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, nullptr, true );
1980// }
1981// | '[' ']' typegen_name
1982 // identifier_or_type_name must be broken apart because of the sequence:
1983 //
1984 // '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1985 // '[' ']' type_specifier
1986 //
1987 // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1988 // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1989 cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1990 // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1991 { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
1992 | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1993 { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
1994 ;
1995
1996cfa_function_return: // CFA
1997 '[' push cfa_parameter_list pop ']'
1998 { $$ = DeclarationNode::newTuple( $3 ); }
1999 | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
2000 // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
2001 { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
2002 ;
2003
2004cfa_typedef_declaration: // CFA
2005 TYPEDEF cfa_variable_specifier
2006 {
2007 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "1" );
2008 $$ = $2->addTypedef();
2009 }
2010 | TYPEDEF cfa_function_specifier
2011 {
2012 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "2" );
2013 $$ = $2->addTypedef();
2014 }
2015 | cfa_typedef_declaration pop ',' push identifier
2016 {
2017 typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "3" );
2018 $$ = $1->appendList( $1->cloneType( $5 ) );
2019 }
2020 ;
2021
2022// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
2023// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
2024
2025typedef_declaration:
2026 TYPEDEF type_specifier declarator
2027 {
2028 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "4" );
2029 if ( $2->type->forall || ($2->type->kind == TypeData::Aggregate && $2->type->aggregate.params) ) {
2030 SemanticError( yylloc, "forall qualifier in typedef is currently unimplemented." ); $$ = nullptr;
2031 } else $$ = $3->addType( $2 )->addTypedef(); // watchout frees $2 and $3
2032 }
2033 | typedef_declaration pop ',' push declarator
2034 {
2035 typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname, "5" );
2036 $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
2037 }
2038 | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
2039 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2040 | type_specifier TYPEDEF declarator
2041 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2042 | type_specifier TYPEDEF type_qualifier_list declarator
2043 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2044 ;
2045
2046typedef_expression:
2047 // deprecated GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
2048 TYPEDEF identifier '=' assignment_expression
2049 {
2050 SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
2051 }
2052 | typedef_expression pop ',' push identifier '=' assignment_expression
2053 {
2054 SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
2055 }
2056 ;
2057
2058c_declaration:
2059 declaration_specifier declaring_list
2060 { $$ = distAttr( $1, $2 ); }
2061 | typedef_declaration
2062 | typedef_expression // deprecated GCC, naming expression type
2063 | sue_declaration_specifier
2064 {
2065 assert( $1->type );
2066 if ( $1->type->qualifiers.any() ) { // CV qualifiers ?
2067 SemanticError( yylloc, "Useless type qualifier(s) in empty declaration." ); $$ = nullptr;
2068 }
2069 // enums are never empty declarations because there must have at least one enumeration.
2070 if ( $1->type->kind == TypeData::AggregateInst && $1->storageClasses.any() ) { // storage class ?
2071 SemanticError( yylloc, "Useless storage qualifier(s) in empty aggregate declaration." ); $$ = nullptr;
2072 }
2073 }
2074 ;
2075
2076declaring_list:
2077 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
2078 // storage-class
2079 variable_declarator asm_name_opt initializer_opt
2080 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2081 | variable_type_redeclarator asm_name_opt initializer_opt
2082 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2083
2084 | general_function_declarator asm_name_opt
2085 { $$ = $1->addAsmName( $2 )->addInitializer( nullptr ); }
2086 | general_function_declarator asm_name_opt '=' VOID
2087 { $$ = $1->addAsmName( $2 )->addInitializer( new InitializerNode( true ) ); }
2088
2089 | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
2090 { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
2091 ;
2092
2093general_function_declarator:
2094 function_type_redeclarator
2095 | function_declarator
2096 ;
2097
2098declaration_specifier: // type specifier + storage class
2099 basic_declaration_specifier
2100 | type_declaration_specifier
2101 | sue_declaration_specifier
2102 | sue_declaration_specifier invalid_types
2103 {
2104 SemanticError( yylloc, ::toString( "Missing ';' after end of ",
2105 $1->type->enumeration.name ? "enum" : ast::AggregateDecl::aggrString( $1->type->aggregate.kind ),
2106 " declaration" ) );
2107 $$ = nullptr;
2108 }
2109 ;
2110
2111invalid_types:
2112 aggregate_key
2113 | basic_type_name
2114 | indirect_type
2115 ;
2116
2117declaration_specifier_nobody: // type specifier + storage class - {...}
2118 // Preclude SUE declarations in restricted scopes:
2119 //
2120 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2121 //
2122 // because it is impossible to call f due to name equivalence.
2123 basic_declaration_specifier
2124 | sue_declaration_specifier_nobody
2125 | type_declaration_specifier
2126 ;
2127
2128type_specifier: // type specifier
2129 basic_type_specifier
2130 | sue_type_specifier
2131 | type_type_specifier
2132 ;
2133
2134type_specifier_nobody: // type specifier - {...}
2135 // Preclude SUE declarations in restricted scopes:
2136 //
2137 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2138 //
2139 // because it is impossible to call f due to name equivalence.
2140 basic_type_specifier
2141 | sue_type_specifier_nobody
2142 | type_type_specifier
2143 ;
2144
2145type_qualifier_list_opt: // GCC, used in asm_statement
2146 // empty
2147 { $$ = nullptr; }
2148 | type_qualifier_list
2149 ;
2150
2151type_qualifier_list:
2152 // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
2153 //
2154 // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
2155 // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
2156 // appeared only once.
2157 type_qualifier
2158 | type_qualifier_list type_qualifier
2159 { $$ = $1->addQualifiers( $2 ); }
2160 ;
2161
2162type_qualifier:
2163 type_qualifier_name
2164 | attribute // trick handles most atrribute locations
2165 ;
2166
2167type_qualifier_name:
2168 CONST
2169 { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
2170 | RESTRICT
2171 { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
2172 | VOLATILE
2173 { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
2174 | ATOMIC
2175 { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
2176 | forall
2177 { $$ = DeclarationNode::newForall( $1 ); }
2178 ;
2179
2180forall:
2181 FORALL '(' type_parameter_list ')' // CFA
2182 { $$ = $3; }
2183 ;
2184
2185declaration_qualifier_list:
2186 storage_class_list
2187 | type_qualifier_list storage_class_list // remaining OBSOLESCENT (see 2 )
2188 { $$ = $1->addQualifiers( $2 ); }
2189 | declaration_qualifier_list type_qualifier_list storage_class_list
2190 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2191 ;
2192
2193storage_class_list:
2194 // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
2195 // only one of each is specified, except for inline, which can appear with the others.
2196 //
2197 // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
2198 // specifiers in a declaration.
2199 storage_class
2200 | storage_class_list storage_class
2201 { $$ = $1->addQualifiers( $2 ); }
2202 ;
2203
2204storage_class:
2205 EXTERN
2206 { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
2207 | STATIC
2208 { $$ = DeclarationNode::newStorageClass( Type::Static ); }
2209 | AUTO
2210 { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
2211 | REGISTER
2212 { $$ = DeclarationNode::newStorageClass( Type::Register ); }
2213 | THREADLOCALGCC // GCC
2214 { $$ = DeclarationNode::newStorageClass( Type::ThreadlocalGcc ); }
2215 | THREADLOCALC11 // C11
2216 { $$ = DeclarationNode::newStorageClass( Type::ThreadlocalC11 ); }
2217 // Put function specifiers here to simplify parsing rules, but separate them semantically.
2218 | INLINE // C99
2219 { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
2220 | FORTRAN // C99
2221 { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
2222 | NORETURN // C11
2223 { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
2224 ;
2225
2226basic_type_name:
2227 VOID
2228 { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2229 | BOOL // C99
2230 { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
2231 | CHAR
2232 { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
2233 | INT
2234 { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
2235 | INT128
2236 { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
2237 | UINT128
2238 { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 )->addType( DeclarationNode::newSignedNess( DeclarationNode::Unsigned ) ); }
2239 | FLOAT
2240 { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
2241 | DOUBLE
2242 { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
2243 | uuFLOAT80
2244 { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
2245 | uuFLOAT128
2246 { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
2247 | uFLOAT16
2248 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
2249 | uFLOAT32
2250 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
2251 | uFLOAT32X
2252 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
2253 | uFLOAT64
2254 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
2255 | uFLOAT64X
2256 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
2257 | uFLOAT128
2258 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
2259 | DECIMAL32
2260 { SemanticError( yylloc, "_Decimal32 is currently unimplemented." ); $$ = nullptr; }
2261 | DECIMAL64
2262 { SemanticError( yylloc, "_Decimal64 is currently unimplemented." ); $$ = nullptr; }
2263 | DECIMAL128
2264 { SemanticError( yylloc, "_Decimal128 is currently unimplemented." ); $$ = nullptr; }
2265 | COMPLEX // C99
2266 { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
2267 | IMAGINARY // C99
2268 { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
2269 | SIGNED
2270 { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
2271 | UNSIGNED
2272 { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
2273 | SHORT
2274 { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
2275 | LONG
2276 { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
2277 | VA_LIST // GCC, __builtin_va_list
2278 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
2279 | AUTO_TYPE
2280 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::AutoType ); }
2281 | vtable
2282 ;
2283
2284vtable_opt:
2285 // empty
2286 { $$ = nullptr; }
2287 | vtable
2288 ;
2289
2290vtable:
2291 VTABLE '(' type_name ')' default_opt
2292 { $$ = DeclarationNode::newVtableType( $3 ); }
2293 // { SemanticError( yylloc, "vtable is currently unimplemented." ); $$ = nullptr; }
2294 ;
2295
2296default_opt:
2297 // empty
2298 { $$ = nullptr; }
2299 | DEFAULT
2300 { SemanticError( yylloc, "vtable default is currently unimplemented." ); $$ = nullptr; }
2301 ;
2302
2303basic_declaration_specifier:
2304 // A semantic check is necessary for conflicting storage classes.
2305 basic_type_specifier
2306 | declaration_qualifier_list basic_type_specifier
2307 { $$ = $2->addQualifiers( $1 ); }
2308 | basic_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2309 { $$ = $1->addQualifiers( $2 ); }
2310 | basic_declaration_specifier storage_class type_qualifier_list
2311 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2312 | basic_declaration_specifier storage_class basic_type_specifier
2313 { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
2314 ;
2315
2316basic_type_specifier:
2317 direct_type
2318 // Cannot have type modifiers, e.g., short, long, etc.
2319 | type_qualifier_list_opt indirect_type type_qualifier_list_opt
2320 { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
2321 ;
2322
2323direct_type:
2324 basic_type_name
2325 | type_qualifier_list basic_type_name
2326 { $$ = $2->addQualifiers( $1 ); }
2327 | direct_type type_qualifier
2328 { $$ = $1->addQualifiers( $2 ); }
2329 | direct_type basic_type_name
2330 { $$ = $1->addType( $2 ); }
2331 ;
2332
2333indirect_type:
2334 TYPEOF '(' type ')' // GCC: typeof( x ) y;
2335 { $$ = $3; }
2336 | TYPEOF '(' comma_expression ')' // GCC: typeof( a+b ) y;
2337 { $$ = DeclarationNode::newTypeof( $3 ); }
2338 | BASETYPEOF '(' type ')' // CFA: basetypeof( x ) y;
2339 { $$ = DeclarationNode::newTypeof( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ), true ); }
2340 | BASETYPEOF '(' comma_expression ')' // CFA: basetypeof( a+b ) y;
2341 { $$ = DeclarationNode::newTypeof( $3, true ); }
2342 | ZERO_T // CFA
2343 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
2344 | ONE_T // CFA
2345 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
2346 ;
2347
2348sue_declaration_specifier: // struct, union, enum + storage class + type specifier
2349 sue_type_specifier
2350 {
2351 // printf( "sue_declaration_specifier %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2352 // for ( Attribute * attr: reverseIterate( $$->attributes ) ) {
2353 // printf( "\tattr %s\n", attr->name.c_str() );
2354 // } // for
2355 }
2356 | declaration_qualifier_list sue_type_specifier
2357 { $$ = $2->addQualifiers( $1 ); }
2358 | sue_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2359 { $$ = $1->addQualifiers( $2 ); }
2360 | sue_declaration_specifier storage_class type_qualifier_list
2361 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2362 ;
2363
2364sue_type_specifier: // struct, union, enum + type specifier
2365 elaborated_type
2366 {
2367 // printf( "sue_type_specifier %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2368 // for ( Attribute * attr: reverseIterate( $$->attributes ) ) {
2369 // printf( "\tattr %s\n", attr->name.c_str() );
2370 // } // for
2371 }
2372 | type_qualifier_list
2373 { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
2374 elaborated_type
2375 { $$ = $3->addQualifiers( $1 ); }
2376 | sue_type_specifier type_qualifier
2377 {
2378 if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
2379 $$ = $1->addQualifiers( $2 );
2380 }
2381 ;
2382
2383sue_declaration_specifier_nobody: // struct, union, enum - {...} + storage class + type specifier
2384 sue_type_specifier_nobody
2385 | declaration_qualifier_list sue_type_specifier_nobody
2386 { $$ = $2->addQualifiers( $1 ); }
2387 | sue_declaration_specifier_nobody storage_class // remaining OBSOLESCENT (see 2)
2388 { $$ = $1->addQualifiers( $2 ); }
2389 | sue_declaration_specifier_nobody storage_class type_qualifier_list
2390 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2391 ;
2392
2393sue_type_specifier_nobody: // struct, union, enum - {...} + type specifier
2394 elaborated_type_nobody
2395 | type_qualifier_list elaborated_type_nobody
2396 { $$ = $2->addQualifiers( $1 ); }
2397 | sue_type_specifier_nobody type_qualifier
2398 { $$ = $1->addQualifiers( $2 ); }
2399 ;
2400
2401type_declaration_specifier:
2402 type_type_specifier
2403 | declaration_qualifier_list type_type_specifier
2404 { $$ = $2->addQualifiers( $1 ); }
2405 | type_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2406 { $$ = $1->addQualifiers( $2 ); }
2407 | type_declaration_specifier storage_class type_qualifier_list
2408 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2409 ;
2410
2411type_type_specifier: // typedef types
2412 type_name
2413 | type_qualifier_list type_name
2414 { $$ = $2->addQualifiers( $1 ); }
2415 | type_type_specifier type_qualifier
2416 { $$ = $1->addQualifiers( $2 ); }
2417 ;
2418
2419type_name:
2420 TYPEDEFname
2421 { $$ = DeclarationNode::newFromTypedef( $1 ); }
2422 | '.' TYPEDEFname
2423 { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
2424 | type_name '.' TYPEDEFname
2425 { $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
2426 | typegen_name
2427 | '.' typegen_name
2428 { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
2429 | type_name '.' typegen_name
2430 { $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
2431 ;
2432
2433typegen_name: // CFA
2434 TYPEGENname
2435 { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2436 | TYPEGENname '(' ')'
2437 { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2438 | TYPEGENname '(' type_list ')'
2439 { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
2440 ;
2441
2442elaborated_type: // struct, union, enum
2443 aggregate_type
2444 {
2445 // printf( "elaborated_type %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2446 // for ( Attribute * attr: reverseIterate( $$->attributes ) ) {
2447 // printf( "\tattr %s\n", attr->name.c_str() );
2448 // } // for
2449 }
2450 | enum_type
2451 ;
2452
2453elaborated_type_nobody: // struct, union, enum - {...}
2454 aggregate_type_nobody
2455 | enum_type_nobody
2456 ;
2457
2458aggregate_type: // struct, union
2459 aggregate_key attribute_list_opt
2460 { forall = false; } // reset
2461 '{' field_declaration_list_opt '}' type_parameters_opt
2462 { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2463 | aggregate_key attribute_list_opt identifier
2464 {
2465 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2466 forall = false; // reset
2467 }
2468 '{' field_declaration_list_opt '}' type_parameters_opt
2469 {
2470 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2471 }
2472 | aggregate_key attribute_list_opt TYPEDEFname // unqualified type name
2473 {
2474 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2475 forall = false; // reset
2476 }
2477 '{' field_declaration_list_opt '}' type_parameters_opt
2478 {
2479 DeclarationNode::newFromTypedef( $3 );
2480 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2481 }
2482 | aggregate_key attribute_list_opt TYPEGENname // unqualified type name
2483 {
2484 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2485 forall = false; // reset
2486 }
2487 '{' field_declaration_list_opt '}' type_parameters_opt
2488 {
2489 DeclarationNode::newFromTypeGen( $3, nullptr );
2490 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2491 }
2492 | aggregate_type_nobody
2493 ;
2494
2495type_parameters_opt:
2496 // empty
2497 { $$ = nullptr; } %prec '}'
2498 | '(' type_list ')'
2499 { $$ = $2; }
2500 ;
2501
2502aggregate_type_nobody: // struct, union - {...}
2503 aggregate_key attribute_list_opt identifier
2504 {
2505 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname );
2506 forall = false; // reset
2507 $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2508 }
2509 | aggregate_key attribute_list_opt type_name
2510 {
2511 forall = false; // reset
2512 // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2513 // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2514 // delete newFromTypeGen.
2515 if ( $3->type->kind == TypeData::SymbolicInst && ! $3->type->symbolic.isTypedef ) {
2516 $$ = $3->addQualifiers( $2 );
2517 } else {
2518 $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2519 $3->type->symbolic.name = nullptr; // copied to $$
2520 $3->type->symbolic.actuals = nullptr;
2521 delete $3;
2522 }
2523 }
2524 ;
2525
2526aggregate_key:
2527 aggregate_data
2528 | aggregate_control
2529 ;
2530
2531aggregate_data:
2532 STRUCT vtable_opt
2533 { $$ = ast::AggregateDecl::Struct; }
2534 | UNION
2535 { $$ = ast::AggregateDecl::Union; }
2536 | EXCEPTION // CFA
2537 { $$ = ast::AggregateDecl::Exception; }
2538 // { SemanticError( yylloc, "exception aggregate is currently unimplemented." ); $$ = ast::AggregateDecl::NoAggregate; }
2539 ;
2540
2541aggregate_control: // CFA
2542 MONITOR
2543 { $$ = ast::AggregateDecl::Monitor; }
2544 | MUTEX STRUCT
2545 { $$ = ast::AggregateDecl::Monitor; }
2546 | GENERATOR
2547 { $$ = ast::AggregateDecl::Generator; }
2548 | MUTEX GENERATOR
2549 {
2550 SemanticError( yylloc, "monitor generator is currently unimplemented." );
2551 $$ = ast::AggregateDecl::NoAggregate;
2552 }
2553 | COROUTINE
2554 { $$ = ast::AggregateDecl::Coroutine; }
2555 | MUTEX COROUTINE
2556 {
2557 SemanticError( yylloc, "monitor coroutine is currently unimplemented." );
2558 $$ = ast::AggregateDecl::NoAggregate;
2559 }
2560 | THREAD
2561 { $$ = ast::AggregateDecl::Thread; }
2562 | MUTEX THREAD
2563 {
2564 SemanticError( yylloc, "monitor thread is currently unimplemented." );
2565 $$ = ast::AggregateDecl::NoAggregate;
2566 }
2567 ;
2568
2569field_declaration_list_opt:
2570 // empty
2571 { $$ = nullptr; }
2572 | field_declaration_list_opt field_declaration
2573 { $$ = $1 ? $1->appendList( $2 ) : $2; }
2574 ;
2575
2576field_declaration:
2577 type_specifier field_declaring_list_opt ';'
2578 {
2579 // printf( "type_specifier1 %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2580 $$ = fieldDecl( $1, $2 );
2581 // printf( "type_specifier2 %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2582 // for ( Attribute * attr: reverseIterate( $$->attributes ) ) {
2583 // printf( "\tattr %s\n", attr->name.c_str() );
2584 // } // for
2585 }
2586 | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2587 { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2588 | STATIC type_specifier field_declaring_list_opt ';' // CFA
2589 { SemanticError( yylloc, "STATIC aggregate field qualifier currently unimplemented." ); $$ = nullptr; }
2590 | INLINE type_specifier field_abstract_list_opt ';' // CFA
2591 {
2592 if ( ! $3 ) { // field declarator ?
2593 $3 = DeclarationNode::newName( nullptr );
2594 } // if
2595 $3->inLine = true;
2596 $$ = distAttr( $2, $3 ); // mark all fields in list
2597 distInl( $3 );
2598 }
2599 | INLINE aggregate_control ';' // CFA
2600 { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2601 | typedef_declaration ';' // CFA
2602 | cfa_field_declaring_list ';' // CFA, new style field declaration
2603 | EXTENSION cfa_field_declaring_list ';' // GCC
2604 { distExt( $2 ); $$ = $2; } // mark all fields in list
2605 | INLINE cfa_field_abstract_list ';' // CFA, new style field declaration
2606 { $$ = $2; } // mark all fields in list
2607 | cfa_typedef_declaration ';' // CFA
2608 | static_assert // C11
2609 ;
2610
2611field_declaring_list_opt:
2612 // empty
2613 { $$ = nullptr; }
2614 | field_declarator
2615 | field_declaring_list_opt ',' attribute_list_opt field_declarator
2616 { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2617 ;
2618
2619field_declarator:
2620 bit_subrange_size // C special case, no field name
2621 { $$ = DeclarationNode::newBitfield( $1 ); }
2622 | variable_declarator bit_subrange_size_opt
2623 // A semantic check is required to ensure bit_subrange only appears on integral types.
2624 { $$ = $1->addBitfield( $2 ); }
2625 | variable_type_redeclarator bit_subrange_size_opt
2626 // A semantic check is required to ensure bit_subrange only appears on integral types.
2627 { $$ = $1->addBitfield( $2 ); }
2628 | function_type_redeclarator bit_subrange_size_opt
2629 // A semantic check is required to ensure bit_subrange only appears on integral types.
2630 { $$ = $1->addBitfield( $2 ); }
2631 ;
2632
2633field_abstract_list_opt:
2634 // empty
2635 { $$ = nullptr; }
2636 | field_abstract
2637 | field_abstract_list_opt ',' attribute_list_opt field_abstract
2638 { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2639 ;
2640
2641field_abstract:
2642 // no bit fields
2643 variable_abstract_declarator
2644 ;
2645
2646cfa_field_declaring_list: // CFA, new style field declaration
2647 // bit-fields are handled by C declarations
2648 cfa_abstract_declarator_tuple identifier_or_type_name
2649 { $$ = $1->addName( $2 ); }
2650 | cfa_field_declaring_list ',' identifier_or_type_name
2651 { $$ = $1->appendList( $1->cloneType( $3 ) ); }
2652 ;
2653
2654cfa_field_abstract_list: // CFA, new style field declaration
2655 // bit-fields are handled by C declarations
2656 cfa_abstract_declarator_tuple
2657 | cfa_field_abstract_list ','
2658 { $$ = $1->appendList( $1->cloneType( 0 ) ); }
2659 ;
2660
2661bit_subrange_size_opt:
2662 // empty
2663 { $$ = nullptr; }
2664 | bit_subrange_size
2665 ;
2666
2667bit_subrange_size:
2668 ':' assignment_expression
2669 { $$ = $2; }
2670 ;
2671
2672enum_type:
2673 ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2674 { $$ = DeclarationNode::newEnum( nullptr, $4, true, false )->addQualifiers( $2 ); }
2675 | ENUM attribute_list_opt identifier
2676 { typedefTable.makeTypedef( *$3 ); }
2677 hide_opt '{' enumerator_list comma_opt '}'
2678 { $$ = DeclarationNode::newEnum( $3, $7, true, false, nullptr, $5 )->addQualifiers( $2 ); }
2679 | ENUM attribute_list_opt typedef_name // unqualified type name
2680 hide_opt '{' enumerator_list comma_opt '}'
2681 { $$ = DeclarationNode::newEnum( $3->name, $6, true, false, nullptr, $4 )->addQualifiers( $2 ); }
2682 | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt '{' enumerator_list comma_opt '}'
2683 {
2684 if ( $3->storageClasses.val != 0 || $3->type->qualifiers.any() )
2685 { SemanticError( yylloc, "storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." ); }
2686
2687 $$ = DeclarationNode::newEnum( nullptr, $7, true, true, $3 )->addQualifiers( $5 );
2688 }
2689 | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt identifier attribute_list_opt
2690 {
2691 if ( $3->storageClasses.any() || $3->type->qualifiers.val != 0 ) { SemanticError( yylloc, "storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." ); }
2692 typedefTable.makeTypedef( *$6 );
2693 }
2694 hide_opt '{' enumerator_list comma_opt '}'
2695 {
2696 $$ = DeclarationNode::newEnum( $6, $11, true, true, $3, $9 )->addQualifiers( $5 )->addQualifiers( $7 );
2697 }
2698 | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt typedef_name attribute_list_opt
2699 hide_opt '{' enumerator_list comma_opt '}'
2700 {
2701 $$ = DeclarationNode::newEnum( $6->name, $10, true, true, $3, $8 )->addQualifiers( $5 )->addQualifiers( $7 );
2702 }
2703 | enum_type_nobody
2704 ;
2705
2706hide_opt:
2707 // empty
2708 { $$ = EnumHiding::Visible; }
2709 | '!'
2710 { $$ = EnumHiding::Hide; }
2711 ;
2712
2713enum_type_nobody: // enum - {...}
2714 ENUM attribute_list_opt identifier
2715 { typedefTable.makeTypedef( *$3 ); $$ = DeclarationNode::newEnum( $3, nullptr, false, false )->addQualifiers( $2 ); }
2716 | ENUM attribute_list_opt type_name
2717 { typedefTable.makeTypedef( *$3->type->symbolic.name ); $$ = DeclarationNode::newEnum( $3->type->symbolic.name, nullptr, false, false )->addQualifiers( $2 ); }
2718 ;
2719
2720enumerator_list:
2721 visible_hide_opt identifier_or_type_name enumerator_value_opt
2722 { $$ = DeclarationNode::newEnumValueGeneric( $2, $3 ); }
2723 | INLINE type_name
2724 { $$ = DeclarationNode::newEnumInLine( *$2->type->symbolic.name ); }
2725 | enumerator_list ',' visible_hide_opt identifier_or_type_name enumerator_value_opt
2726 { $$ = $1->appendList( DeclarationNode::newEnumValueGeneric( $4, $5 ) ); }
2727 | enumerator_list ',' INLINE type_name enumerator_value_opt
2728 { $$ = $1->appendList( DeclarationNode::newEnumValueGeneric( new string("inline"), nullptr ) ); }
2729 ;
2730
2731visible_hide_opt:
2732 hide_opt
2733 | '^'
2734 { $$ = EnumHiding::Visible; }
2735 ;
2736
2737enumerator_value_opt:
2738 // empty
2739 { $$ = nullptr; }
2740 | '=' constant_expression { $$ = new InitializerNode( $2 ); }
2741 | '=' '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $3, true ); }
2742 // | simple_assignment_operator initializer
2743 // { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2744 ;
2745
2746cfa_parameter_ellipsis_list_opt: // CFA, abstract + real
2747 // empty
2748 { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2749 | ELLIPSIS
2750 { $$ = nullptr; }
2751 | cfa_abstract_parameter_list
2752 | cfa_parameter_list
2753 | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2754 { $$ = $1->appendList( $5 ); }
2755 | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2756 { $$ = $1->addVarArgs(); }
2757 | cfa_parameter_list pop ',' push ELLIPSIS
2758 { $$ = $1->addVarArgs(); }
2759 ;
2760
2761cfa_parameter_list: // CFA
2762 // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2763 // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2764 cfa_parameter_declaration
2765 | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2766 { $$ = $1->appendList( $5 ); }
2767 | cfa_parameter_list pop ',' push cfa_parameter_declaration
2768 { $$ = $1->appendList( $5 ); }
2769 | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2770 { $$ = $1->appendList( $5 )->appendList( $9 ); }
2771 ;
2772
2773cfa_abstract_parameter_list: // CFA, new & old style abstract
2774 cfa_abstract_parameter_declaration
2775 | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2776 { $$ = $1->appendList( $5 ); }
2777 ;
2778
2779parameter_type_list_opt:
2780 // empty
2781 { $$ = nullptr; }
2782 | ELLIPSIS
2783 { $$ = nullptr; }
2784 | parameter_list
2785 | parameter_list pop ',' push ELLIPSIS
2786 { $$ = $1->addVarArgs(); }
2787 ;
2788
2789parameter_list: // abstract + real
2790 abstract_parameter_declaration
2791 | parameter_declaration
2792 | parameter_list pop ',' push abstract_parameter_declaration
2793 { $$ = $1->appendList( $5 ); }
2794 | parameter_list pop ',' push parameter_declaration
2795 { $$ = $1->appendList( $5 ); }
2796 ;
2797
2798// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2799// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2800
2801cfa_parameter_declaration: // CFA, new & old style parameter declaration
2802 parameter_declaration
2803 | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initializer_opt
2804 { $$ = $1->addName( $2 ); }
2805 | cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2806 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2807 { $$ = $1->addName( $2 ); }
2808 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2809 { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2810 | cfa_function_specifier
2811 ;
2812
2813cfa_abstract_parameter_declaration: // CFA, new & old style parameter declaration
2814 // empty
2815 { $$ = nullptr; }
2816 | abstract_parameter_declaration
2817 | cfa_identifier_parameter_declarator_no_tuple
2818 | cfa_abstract_tuple
2819 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2820 | type_qualifier_list cfa_abstract_tuple
2821 { $$ = $2->addQualifiers( $1 ); }
2822 | cfa_abstract_function
2823 ;
2824
2825parameter_declaration:
2826 // No SUE declaration in parameter list.
2827 declaration_specifier_nobody identifier_parameter_declarator default_initializer_opt
2828 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2829 | declaration_specifier_nobody type_parameter_redeclarator default_initializer_opt
2830 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2831 ;
2832
2833abstract_parameter_declaration:
2834 declaration_specifier_nobody default_initializer_opt
2835 { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2836 | declaration_specifier_nobody abstract_parameter_declarator default_initializer_opt
2837 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2838 ;
2839
2840// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2841// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2842// identifiers. The ANSI-style parameter-list can redefine a typedef name.
2843
2844identifier_list: // K&R-style parameter list => no types
2845 identifier
2846 { $$ = DeclarationNode::newName( $1 ); }
2847 | identifier_list ',' identifier
2848 { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2849 ;
2850
2851identifier_or_type_name:
2852 identifier
2853 | TYPEDEFname
2854 | TYPEGENname
2855 ;
2856
2857type_no_function: // sizeof, alignof, cast (constructor)
2858 cfa_abstract_declarator_tuple // CFA
2859 | type_specifier // cannot be type_specifier_nobody, e.g., (struct S {}){} is a thing
2860 | type_specifier abstract_declarator
2861 { $$ = $2->addType( $1 ); }
2862 ;
2863
2864type: // typeof, assertion
2865 type_no_function
2866 | cfa_abstract_function // CFA
2867 ;
2868
2869initializer_opt:
2870 // empty
2871 { $$ = nullptr; }
2872 | simple_assignment_operator initializer { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2873 | '=' VOID { $$ = new InitializerNode( true ); }
2874 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
2875 ;
2876
2877initializer:
2878 assignment_expression { $$ = new InitializerNode( $1 ); }
2879 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
2880 ;
2881
2882initializer_list_opt:
2883 // empty
2884 { $$ = nullptr; }
2885 | initializer
2886 | designation initializer { $$ = $2->set_designators( $1 ); }
2887 | initializer_list_opt ',' initializer { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2888 | initializer_list_opt ',' designation initializer { $$ = (InitializerNode *)($1->set_last( $4->set_designators( $3 ) )); }
2889 ;
2890
2891// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2892// '=' to separator the designator from the initializer value, as in:
2893//
2894// int x[10] = { [1] = 3 };
2895//
2896// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment. To disambiguate this case, CFA
2897// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2898// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2899// shift/reduce conflicts
2900
2901designation:
2902 designator_list ':' // C99, CFA uses ":" instead of "="
2903 | identifier_at ':' // GCC, field name
2904 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
2905 ;
2906
2907designator_list: // C99
2908 designator
2909 | designator_list designator
2910 { $$ = (ExpressionNode *)($1->set_last( $2 )); }
2911 //| designator_list designator { $$ = new ExpressionNode( $1, $2 ); }
2912 ;
2913
2914designator:
2915 '.' identifier_at // C99, field name
2916 { $$ = new ExpressionNode( build_varref( yylloc, $2 ) ); }
2917 | '[' push assignment_expression pop ']' // C99, single array element
2918 // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2919 { $$ = $3; }
2920 | '[' push subrange pop ']' // CFA, multiple array elements
2921 { $$ = $3; }
2922 | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2923 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $3 ), maybeMoveBuild( $5 ) ) ); }
2924 | '.' '[' push field_name_list pop ']' // CFA, tuple field selector
2925 { $$ = $4; }
2926 ;
2927
2928// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2929// rather than an object-oriented type system. This required four groups of extensions:
2930//
2931// Overloading: function, data, and operator identifiers may be overloaded.
2932//
2933// Type declarations: "otype" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2934// and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2935// definitions of new types. Type declarations with storage class "extern" provide opaque types.
2936//
2937// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2938// site. A polymorphic function is not a template; it is a function, with an address and a type.
2939//
2940// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2941// types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2942// hierarchies. Unlike classes, they can define relationships between types. Assertions declare that a type or
2943// types provide the operations declared by a specification. Assertions are normally used to declare requirements
2944// on type arguments of polymorphic functions.
2945
2946type_parameter_list: // CFA
2947 type_parameter
2948 | type_parameter_list ',' type_parameter
2949 { $$ = $1->appendList( $3 ); }
2950 ;
2951
2952type_initializer_opt: // CFA
2953 // empty
2954 { $$ = nullptr; }
2955 | '=' type
2956 { $$ = $2; }
2957 ;
2958
2959type_parameter: // CFA
2960 type_class identifier_or_type_name
2961 {
2962 typedefTable.addToScope( *$2, TYPEDEFname, "9" );
2963 if ( $1 == ast::TypeDecl::Otype ) { SemanticError( yylloc, "otype keyword is deprecated, use T " ); }
2964 if ( $1 == ast::TypeDecl::Dtype ) { SemanticError( yylloc, "dtype keyword is deprecated, use T &" ); }
2965 if ( $1 == ast::TypeDecl::Ttype ) { SemanticError( yylloc, "ttype keyword is deprecated, use T ..." ); }
2966 }
2967 type_initializer_opt assertion_list_opt
2968 { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2969 | identifier_or_type_name new_type_class
2970 { typedefTable.addToScope( *$1, TYPEDEFname, "9" ); }
2971 type_initializer_opt assertion_list_opt
2972 { $$ = DeclarationNode::newTypeParam( $2, $1 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2973 | '[' identifier_or_type_name ']'
2974 {
2975 typedefTable.addToScope( *$2, TYPEDIMname, "9" );
2976 $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dimension, $2 );
2977 }
2978 // | type_specifier identifier_parameter_declarator
2979 | assertion_list
2980 { $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2981 ;
2982
2983new_type_class: // CFA
2984 // empty
2985 { $$ = ast::TypeDecl::Otype; }
2986 | '&'
2987 { $$ = ast::TypeDecl::Dtype; }
2988 | '*'
2989 { $$ = ast::TypeDecl::DStype; } // dtype + sized
2990 // | '(' '*' ')'
2991 // { $$ = ast::TypeDecl::Ftype; }
2992 | ELLIPSIS
2993 { $$ = ast::TypeDecl::Ttype; }
2994 ;
2995
2996type_class: // CFA
2997 OTYPE
2998 { $$ = ast::TypeDecl::Otype; }
2999 | DTYPE
3000 { $$ = ast::TypeDecl::Dtype; }
3001 | FTYPE
3002 { $$ = ast::TypeDecl::Ftype; }
3003 | TTYPE
3004 { $$ = ast::TypeDecl::Ttype; }
3005 ;
3006
3007assertion_list_opt: // CFA
3008 // empty
3009 { $$ = nullptr; }
3010 | assertion_list
3011 ;
3012
3013assertion_list: // CFA
3014 assertion
3015 | assertion_list assertion
3016 { $$ = $1->appendList( $2 ); }
3017 ;
3018
3019assertion: // CFA
3020 '|' identifier_or_type_name '(' type_list ')'
3021 { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
3022 | '|' '{' push trait_declaration_list pop '}'
3023 { $$ = $4; }
3024 // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
3025 // { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
3026 ;
3027
3028type_list: // CFA
3029 type
3030 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3031 | assignment_expression
3032 | type_list ',' type
3033 { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) )); }
3034 | type_list ',' assignment_expression
3035 { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
3036 ;
3037
3038type_declaring_list: // CFA
3039 OTYPE type_declarator
3040 { $$ = $2; }
3041 | storage_class_list OTYPE type_declarator
3042 { $$ = $3->addQualifiers( $1 ); }
3043 | type_declaring_list ',' type_declarator
3044 { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
3045 ;
3046
3047type_declarator: // CFA
3048 type_declarator_name assertion_list_opt
3049 { $$ = $1->addAssertions( $2 ); }
3050 | type_declarator_name assertion_list_opt '=' type
3051 { $$ = $1->addAssertions( $2 )->addType( $4 ); }
3052 ;
3053
3054type_declarator_name: // CFA
3055 identifier_or_type_name
3056 {
3057 typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "10" );
3058 $$ = DeclarationNode::newTypeDecl( $1, nullptr );
3059 }
3060 | identifier_or_type_name '(' type_parameter_list ')'
3061 {
3062 typedefTable.addToEnclosingScope( *$1, TYPEGENname, "11" );
3063 $$ = DeclarationNode::newTypeDecl( $1, $3 );
3064 }
3065 ;
3066
3067trait_specifier: // CFA
3068 TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
3069 {
3070 SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3071 $$ = DeclarationNode::newTrait( $2, $4, nullptr );
3072 }
3073 | forall TRAIT identifier_or_type_name '{' '}' // alternate
3074 { $$ = DeclarationNode::newTrait( $3, $1, nullptr ); }
3075 | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
3076 {
3077 SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3078 $$ = DeclarationNode::newTrait( $2, $4, $8 );
3079 }
3080 | forall TRAIT identifier_or_type_name '{' push trait_declaration_list pop '}' // alternate
3081 { $$ = DeclarationNode::newTrait( $3, $1, $6 ); }
3082 ;
3083
3084trait_declaration_list: // CFA
3085 trait_declaration
3086 | trait_declaration_list pop push trait_declaration
3087 { $$ = $1->appendList( $4 ); }
3088 ;
3089
3090trait_declaration: // CFA
3091 cfa_trait_declaring_list ';'
3092 | trait_declaring_list ';'
3093 ;
3094
3095cfa_trait_declaring_list: // CFA
3096 cfa_variable_specifier
3097 | cfa_function_specifier
3098 | cfa_trait_declaring_list pop ',' push identifier_or_type_name
3099 { $$ = $1->appendList( $1->cloneType( $5 ) ); }
3100 ;
3101
3102trait_declaring_list: // CFA
3103 type_specifier declarator
3104 { $$ = $2->addType( $1 ); }
3105 | trait_declaring_list pop ',' push declarator
3106 { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
3107 ;
3108
3109// **************************** EXTERNAL DEFINITIONS *****************************
3110
3111translation_unit:
3112 // empty, input file
3113 | external_definition_list
3114 { parseTree = parseTree ? parseTree->appendList( $1 ) : $1; }
3115 ;
3116
3117external_definition_list:
3118 push external_definition pop
3119 { $$ = $2; }
3120 | external_definition_list push external_definition pop
3121 { $$ = $1 ? $1->appendList( $3 ) : $3; }
3122 ;
3123
3124external_definition_list_opt:
3125 // empty
3126 { $$ = nullptr; }
3127 | external_definition_list
3128 ;
3129
3130up:
3131 { typedefTable.up( forall ); forall = false; }
3132 ;
3133
3134down:
3135 { typedefTable.down(); }
3136 ;
3137
3138external_definition:
3139 DIRECTIVE
3140 { $$ = DeclarationNode::newDirectiveStmt( new StatementNode( build_directive( yylloc, $1 ) ) ); }
3141 | declaration
3142 {
3143 // Variable declarations of anonymous types requires creating a unique type-name across multiple translation
3144 // unit, which is a dubious task, especially because C uses name rather than structural typing; hence it is
3145 // disallowed at the moment.
3146 if ( $1->linkage == ast::Linkage::Cforall && ! $1->storageClasses.is_static && $1->type && $1->type->kind == TypeData::AggregateInst ) {
3147 if ( $1->type->aggInst.aggregate->kind == TypeData::Enum && $1->type->aggInst.aggregate->enumeration.anon ) {
3148 SemanticError( yylloc, "extern anonymous enumeration is currently unimplemented." ); $$ = nullptr;
3149 } else if ( $1->type->aggInst.aggregate->aggregate.anon ) { // handles struct or union
3150 SemanticError( yylloc, "extern anonymous struct/union is currently unimplemented." ); $$ = nullptr;
3151 }
3152 }
3153 }
3154 | IDENTIFIER IDENTIFIER
3155 { IdentifierBeforeIdentifier( *$1.str, *$2.str, " declaration" ); $$ = nullptr; }
3156 | IDENTIFIER type_qualifier // syntax error
3157 { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
3158 | IDENTIFIER storage_class // syntax error
3159 { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
3160 | IDENTIFIER basic_type_name // syntax error
3161 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3162 | IDENTIFIER TYPEDEFname // syntax error
3163 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3164 | IDENTIFIER TYPEGENname // syntax error
3165 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3166 | external_function_definition
3167 | EXTENSION external_definition // GCC, multiple __extension__ allowed, meaning unknown
3168 {
3169 distExt( $2 ); // mark all fields in list
3170 $$ = $2;
3171 }
3172 | ASM '(' string_literal ')' ';' // GCC, global assembler statement
3173 { $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( yylloc, false, $3, nullptr ) ) ); }
3174 | EXTERN STRINGliteral
3175 {
3176 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
3177 linkage = ast::Linkage::update( yylloc, linkage, $2 );
3178 }
3179 up external_definition down
3180 {
3181 linkage = linkageStack.top();
3182 linkageStack.pop();
3183 $$ = $5;
3184 }
3185 | EXTERN STRINGliteral // C++-style linkage specifier
3186 {
3187 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
3188 linkage = ast::Linkage::update( yylloc, linkage, $2 );
3189 }
3190 '{' up external_definition_list_opt down '}'
3191 {
3192 linkage = linkageStack.top();
3193 linkageStack.pop();
3194 $$ = $6;
3195 }
3196 // global distribution
3197 | type_qualifier_list
3198 {
3199 if ( $1->type->qualifiers.any() ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
3200 if ( $1->type->forall ) forall = true; // remember generic type
3201 }
3202 '{' up external_definition_list_opt down '}' // CFA, namespace
3203 {
3204 distQual( $5, $1 );
3205 forall = false;
3206 $$ = $5;
3207 }
3208 | declaration_qualifier_list
3209 {
3210 if ( $1->type && $1->type->qualifiers.any() ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
3211 if ( $1->type && $1->type->forall ) forall = true; // remember generic type
3212 }
3213 '{' up external_definition_list_opt down '}' // CFA, namespace
3214 {
3215 distQual( $5, $1 );
3216 forall = false;
3217 $$ = $5;
3218 }
3219 | declaration_qualifier_list type_qualifier_list
3220 {
3221 if ( ($1->type && $1->type->qualifiers.any()) || ($2->type && $2->type->qualifiers.any()) ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
3222 if ( ($1->type && $1->type->forall) || ($2->type && $2->type->forall) ) forall = true; // remember generic type
3223 }
3224 '{' up external_definition_list_opt down '}' // CFA, namespace
3225 {
3226 distQual( $6, $1->addQualifiers( $2 ) );
3227 forall = false;
3228 $$ = $6;
3229 }
3230 ;
3231
3232external_function_definition:
3233 function_definition
3234 // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
3235 // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
3236 // Parsing is possible because function_definition does not appear in the context of an expression (nested
3237 // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
3238 // declaration must still have a type_specifier. OBSOLESCENT (see 1)
3239 | function_declarator compound_statement
3240 { $$ = $1->addFunctionBody( $2 ); }
3241 | KR_function_declarator KR_parameter_list_opt compound_statement
3242 { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
3243 ;
3244
3245with_clause_opt:
3246 // empty
3247 { $$ = nullptr; forall = false; }
3248 | WITH '(' tuple_expression_list ')' attribute_list_opt
3249 {
3250 $$ = $3; forall = false;
3251 if ( $5 ) {
3252 SemanticError( yylloc, "Attributes cannot be associated with function body. Move attribute(s) before \"with\" clause." );
3253 $$ = nullptr;
3254 } // if
3255 }
3256 ;
3257
3258function_definition:
3259 cfa_function_declaration with_clause_opt compound_statement // CFA
3260 {
3261 // Add the function body to the last identifier in the function definition list, i.e., foo3:
3262 // [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
3263 $1->get_last()->addFunctionBody( $3, $2 );
3264 $$ = $1;
3265 }
3266 | declaration_specifier function_declarator with_clause_opt compound_statement
3267 {
3268 rebindForall( $1, $2 );
3269 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3270 }
3271 | declaration_specifier function_type_redeclarator with_clause_opt compound_statement
3272 {
3273 rebindForall( $1, $2 );
3274 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3275 }
3276 // handles default int return type, OBSOLESCENT (see 1)
3277 | type_qualifier_list function_declarator with_clause_opt compound_statement
3278 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3279 // handles default int return type, OBSOLESCENT (see 1)
3280 | declaration_qualifier_list function_declarator with_clause_opt compound_statement
3281 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3282 // handles default int return type, OBSOLESCENT (see 1)
3283 | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
3284 { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3285
3286 // Old-style K&R function definition, OBSOLESCENT (see 4)
3287 | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3288 {
3289 rebindForall( $1, $2 );
3290 $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
3291 }
3292 // handles default int return type, OBSOLESCENT (see 1)
3293 | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3294 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3295 // handles default int return type, OBSOLESCENT (see 1)
3296 | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3297 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3298 // handles default int return type, OBSOLESCENT (see 1)
3299 | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3300 { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3301 ;
3302
3303declarator:
3304 variable_declarator
3305 | variable_type_redeclarator
3306 | function_declarator
3307 | function_type_redeclarator
3308 ;
3309
3310subrange:
3311 constant_expression '~' constant_expression // CFA, integer subrange
3312 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
3313 ;
3314
3315asm_name_opt: // GCC
3316 // empty
3317 { $$ = nullptr; }
3318 | ASM '(' string_literal ')' attribute_list_opt
3319 {
3320 DeclarationNode * name = new DeclarationNode();
3321 name->asmName = maybeMoveBuild( $3 );
3322 $$ = name->addQualifiers( $5 );
3323 }
3324 ;
3325
3326attribute_list_opt: // GCC
3327 // empty
3328 { $$ = nullptr; }
3329 | attribute_list
3330 ;
3331
3332attribute_list: // GCC
3333 attribute
3334 | attribute_list attribute
3335 { $$ = $2->addQualifiers( $1 ); }
3336 ;
3337
3338attribute: // GCC
3339 ATTRIBUTE '(' '(' attribute_name_list ')' ')'
3340 { $$ = $4; }
3341 ;
3342
3343attribute_name_list: // GCC
3344 attribute_name
3345 | attribute_name_list ',' attribute_name
3346 { $$ = $3->addQualifiers( $1 ); }
3347 ;
3348
3349attribute_name: // GCC
3350 // empty
3351 { $$ = nullptr; }
3352 | attr_name
3353 { $$ = DeclarationNode::newAttribute( $1 ); }
3354 | attr_name '(' argument_expression_list_opt ')'
3355 { $$ = DeclarationNode::newAttribute( $1, $3 ); }
3356 ;
3357
3358attr_name: // GCC
3359 IDENTIFIER
3360 | quasi_keyword
3361 | TYPEDEFname
3362 | TYPEGENname
3363 | FALLTHROUGH
3364 { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
3365 | CONST
3366 { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
3367 ;
3368
3369// ============================================================================
3370// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
3371// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
3372// in:
3373//
3374// int (*f())[10] { ... };
3375// ... (*f())[3] += 1; // definition mimics usage
3376//
3377// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
3378// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
3379// ============================================================================
3380
3381// ----------------------------------------------------------------------------
3382// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
3383// to define a variable or function prototype, e.g.:
3384//
3385// valid declaration invalid definition
3386// ----------------- ------------------
3387// int f; int f {}
3388// int *f; int *f {}
3389// int f[10]; int f[10] {}
3390// int (*f)(int); int (*f)(int) {}
3391//
3392// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
3393// variable_declarator and function_declarator.
3394// ----------------------------------------------------------------------------
3395
3396// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
3397// declaring an array of functions versus a pointer to an array of functions.
3398
3399paren_identifier:
3400 identifier_at
3401 { $$ = DeclarationNode::newName( $1 ); }
3402 | '(' paren_identifier ')' // redundant parenthesis
3403 { $$ = $2; }
3404 ;
3405
3406variable_declarator:
3407 paren_identifier attribute_list_opt
3408 { $$ = $1->addQualifiers( $2 ); }
3409 | variable_ptr
3410 | variable_array attribute_list_opt
3411 { $$ = $1->addQualifiers( $2 ); }
3412 | variable_function attribute_list_opt
3413 { $$ = $1->addQualifiers( $2 ); }
3414 ;
3415
3416variable_ptr:
3417 ptrref_operator variable_declarator
3418 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3419 | ptrref_operator type_qualifier_list variable_declarator
3420 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3421 | '(' variable_ptr ')' attribute_list_opt // redundant parenthesis
3422 { $$ = $2->addQualifiers( $4 ); }
3423 | '(' attribute_list variable_ptr ')' attribute_list_opt // redundant parenthesis
3424 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3425 ;
3426
3427variable_array:
3428 paren_identifier array_dimension
3429 { $$ = $1->addArray( $2 ); }
3430 | '(' variable_ptr ')' array_dimension
3431 { $$ = $2->addArray( $4 ); }
3432 | '(' attribute_list variable_ptr ')' array_dimension
3433 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3434 | '(' variable_array ')' multi_array_dimension // redundant parenthesis
3435 { $$ = $2->addArray( $4 ); }
3436 | '(' attribute_list variable_array ')' multi_array_dimension // redundant parenthesis
3437 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3438 | '(' variable_array ')' // redundant parenthesis
3439 { $$ = $2; }
3440 | '(' attribute_list variable_array ')' // redundant parenthesis
3441 { $$ = $3->addQualifiers( $2 ); }
3442 ;
3443
3444variable_function:
3445 '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3446 { $$ = $2->addParamList( $6 ); }
3447 | '(' attribute_list variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3448 { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
3449 | '(' variable_function ')' // redundant parenthesis
3450 { $$ = $2; }
3451 | '(' attribute_list variable_function ')' // redundant parenthesis
3452 { $$ = $3->addQualifiers( $2 ); }
3453 ;
3454
3455// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
3456// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
3457// is the same scope. The pattern precludes returning arrays and functions versus pointers to arrays and functions.
3458
3459function_declarator:
3460 function_no_ptr attribute_list_opt
3461 { $$ = $1->addQualifiers( $2 ); }
3462 | function_ptr
3463 | function_array attribute_list_opt
3464 { $$ = $1->addQualifiers( $2 ); }
3465 ;
3466
3467function_no_ptr:
3468 paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3469 { $$ = $1->addParamList( $4 ); }
3470 | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
3471 { $$ = $2->addParamList( $6 ); }
3472 | '(' attribute_list function_ptr ')' '(' push parameter_type_list_opt pop ')'
3473 { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
3474 | '(' function_no_ptr ')' // redundant parenthesis
3475 { $$ = $2; }
3476 | '(' attribute_list function_no_ptr ')' // redundant parenthesis
3477 { $$ = $3->addQualifiers( $2 ); }
3478 ;
3479
3480function_ptr:
3481 ptrref_operator function_declarator
3482 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3483 | ptrref_operator type_qualifier_list function_declarator
3484 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3485 | '(' function_ptr ')' attribute_list_opt
3486 { $$ = $2->addQualifiers( $4 ); }
3487 | '(' attribute_list function_ptr ')' attribute_list_opt
3488 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3489 ;
3490
3491function_array:
3492 '(' function_ptr ')' array_dimension
3493 { $$ = $2->addArray( $4 ); }
3494 | '(' attribute_list function_ptr ')' array_dimension
3495 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3496 | '(' function_array ')' multi_array_dimension // redundant parenthesis
3497 { $$ = $2->addArray( $4 ); }
3498 | '(' attribute_list function_array ')' multi_array_dimension // redundant parenthesis
3499 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3500 | '(' function_array ')' // redundant parenthesis
3501 { $$ = $2; }
3502 | '(' attribute_list function_array ')' // redundant parenthesis
3503 { $$ = $3->addQualifiers( $2 ); }
3504 ;
3505
3506// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
3507//
3508// f( a, b, c ) int a, *b, c[]; {}
3509//
3510// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
3511// returning arrays and functions versus pointers to arrays and functions.
3512
3513KR_function_declarator:
3514 KR_function_no_ptr
3515 | KR_function_ptr
3516 | KR_function_array
3517 ;
3518
3519KR_function_no_ptr:
3520 paren_identifier '(' identifier_list ')' // function_declarator handles empty parameter
3521 { $$ = $1->addIdList( $3 ); }
3522 | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
3523 { $$ = $2->addParamList( $6 ); }
3524 | '(' attribute_list KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
3525 { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
3526 | '(' KR_function_no_ptr ')' // redundant parenthesis
3527 { $$ = $2; }
3528 | '(' attribute_list KR_function_no_ptr ')' // redundant parenthesis
3529 { $$ = $3->addQualifiers( $2 ); }
3530 ;
3531
3532KR_function_ptr:
3533 ptrref_operator KR_function_declarator
3534 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3535 | ptrref_operator type_qualifier_list KR_function_declarator
3536 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3537 | '(' KR_function_ptr ')'
3538 { $$ = $2; }
3539 | '(' attribute_list KR_function_ptr ')'
3540 { $$ = $3->addQualifiers( $2 ); }
3541 ;
3542
3543KR_function_array:
3544 '(' KR_function_ptr ')' array_dimension
3545 { $$ = $2->addArray( $4 ); }
3546 | '(' attribute_list KR_function_ptr ')' array_dimension
3547 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3548 | '(' KR_function_array ')' multi_array_dimension // redundant parenthesis
3549 { $$ = $2->addArray( $4 ); }
3550 | '(' attribute_list KR_function_array ')' multi_array_dimension // redundant parenthesis
3551 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3552 | '(' KR_function_array ')' // redundant parenthesis
3553 { $$ = $2; }
3554 | '(' attribute_list KR_function_array ')' // redundant parenthesis
3555 { $$ = $3->addQualifiers( $2 ); }
3556 ;
3557
3558// This pattern parses a declaration for a variable that redefines a type name, e.g.:
3559//
3560// typedef int foo;
3561// {
3562// int foo; // redefine typedef name in new scope
3563// }
3564
3565paren_type:
3566 typedef_name
3567 {
3568 // hide type name in enclosing scope by variable name
3569 typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "ID" );
3570 }
3571 | '(' paren_type ')'
3572 { $$ = $2; }
3573 ;
3574
3575variable_type_redeclarator:
3576 paren_type attribute_list_opt
3577 { $$ = $1->addQualifiers( $2 ); }
3578 | variable_type_ptr
3579 | variable_type_array attribute_list_opt
3580 { $$ = $1->addQualifiers( $2 ); }
3581 | variable_type_function attribute_list_opt
3582 { $$ = $1->addQualifiers( $2 ); }
3583 ;
3584
3585variable_type_ptr:
3586 ptrref_operator variable_type_redeclarator
3587 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3588 | ptrref_operator type_qualifier_list variable_type_redeclarator
3589 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3590 | '(' variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3591 { $$ = $2->addQualifiers( $4 ); }
3592 | '(' attribute_list variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3593 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3594 ;
3595
3596variable_type_array:
3597 paren_type array_dimension
3598 { $$ = $1->addArray( $2 ); }
3599 | '(' variable_type_ptr ')' array_dimension
3600 { $$ = $2->addArray( $4 ); }
3601 | '(' attribute_list variable_type_ptr ')' array_dimension
3602 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3603 | '(' variable_type_array ')' multi_array_dimension // redundant parenthesis
3604 { $$ = $2->addArray( $4 ); }
3605 | '(' attribute_list variable_type_array ')' multi_array_dimension // redundant parenthesis
3606 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3607 | '(' variable_type_array ')' // redundant parenthesis
3608 { $$ = $2; }
3609 | '(' attribute_list variable_type_array ')' // redundant parenthesis
3610 { $$ = $3->addQualifiers( $2 ); }
3611 ;
3612
3613variable_type_function:
3614 '(' variable_type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3615 { $$ = $2->addParamList( $6 ); }
3616 | '(' attribute_list variable_type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3617 { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
3618 | '(' variable_type_function ')' // redundant parenthesis
3619 { $$ = $2; }
3620 | '(' attribute_list variable_type_function ')' // redundant parenthesis
3621 { $$ = $3->addQualifiers( $2 ); }
3622 ;
3623
3624// This pattern parses a declaration for a function prototype that redefines a type name. It precludes declaring an
3625// array of functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to
3626// arrays and functions.
3627
3628function_type_redeclarator:
3629 function_type_no_ptr attribute_list_opt
3630 { $$ = $1->addQualifiers( $2 ); }
3631 | function_type_ptr
3632 | function_type_array attribute_list_opt
3633 { $$ = $1->addQualifiers( $2 ); }
3634 ;
3635
3636function_type_no_ptr:
3637 paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3638 { $$ = $1->addParamList( $4 ); }
3639 | '(' function_type_ptr ')' '(' push parameter_type_list_opt pop ')'
3640 { $$ = $2->addParamList( $6 ); }
3641 | '(' attribute_list function_type_ptr ')' '(' push parameter_type_list_opt pop ')'
3642 { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
3643 | '(' function_type_no_ptr ')' // redundant parenthesis
3644 { $$ = $2; }
3645 | '(' attribute_list function_type_no_ptr ')' // redundant parenthesis
3646 { $$ = $3->addQualifiers( $2 ); }
3647 ;
3648
3649function_type_ptr:
3650 ptrref_operator function_type_redeclarator
3651 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3652 | ptrref_operator type_qualifier_list function_type_redeclarator
3653 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3654 | '(' function_type_ptr ')' attribute_list_opt
3655 { $$ = $2->addQualifiers( $4 ); }
3656 | '(' attribute_list function_type_ptr ')' attribute_list_opt
3657 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3658 ;
3659
3660function_type_array:
3661 '(' function_type_ptr ')' array_dimension
3662 { $$ = $2->addArray( $4 ); }
3663 | '(' attribute_list function_type_ptr ')' array_dimension
3664 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3665 | '(' function_type_array ')' multi_array_dimension // redundant parenthesis
3666 { $$ = $2->addArray( $4 ); }
3667 | '(' attribute_list function_type_array ')' multi_array_dimension // redundant parenthesis
3668 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3669 | '(' function_type_array ')' // redundant parenthesis
3670 { $$ = $2; }
3671 | '(' attribute_list function_type_array ')' // redundant parenthesis
3672 { $$ = $3->addQualifiers( $2 ); }
3673 ;
3674
3675// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
3676// typedef name and allows the C99 array options, which can only appear in a parameter list. The pattern precludes
3677// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
3678// pointers to arrays and functions.
3679
3680identifier_parameter_declarator:
3681 paren_identifier attribute_list_opt
3682 { $$ = $1->addQualifiers( $2 ); }
3683 | '&' MUTEX paren_identifier attribute_list_opt
3684 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3685 | identifier_parameter_ptr
3686 | identifier_parameter_array attribute_list_opt
3687 { $$ = $1->addQualifiers( $2 ); }
3688 | identifier_parameter_function attribute_list_opt
3689 { $$ = $1->addQualifiers( $2 ); }
3690 ;
3691
3692identifier_parameter_ptr:
3693 ptrref_operator identifier_parameter_declarator
3694 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3695 | ptrref_operator type_qualifier_list identifier_parameter_declarator
3696 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3697 | '(' identifier_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3698 { $$ = $2->addQualifiers( $4 ); }
3699 ;
3700
3701identifier_parameter_array:
3702 paren_identifier array_parameter_dimension
3703 { $$ = $1->addArray( $2 ); }
3704 | '(' identifier_parameter_ptr ')' array_dimension
3705 { $$ = $2->addArray( $4 ); }
3706 | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3707 { $$ = $2->addArray( $4 ); }
3708 | '(' identifier_parameter_array ')' // redundant parenthesis
3709 { $$ = $2; }
3710 ;
3711
3712identifier_parameter_function:
3713 paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3714 { $$ = $1->addParamList( $4 ); }
3715 | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3716 { $$ = $2->addParamList( $6 ); }
3717 | '(' identifier_parameter_function ')' // redundant parenthesis
3718 { $$ = $2; }
3719 ;
3720
3721// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3722// e.g.:
3723//
3724// typedef int foo;
3725// forall( otype T ) struct foo;
3726// int f( int foo ); // redefine typedef name in new scope
3727//
3728// and allows the C99 array options, which can only appear in a parameter list.
3729
3730type_parameter_redeclarator:
3731 typedef_name attribute_list_opt
3732 { $$ = $1->addQualifiers( $2 ); }
3733 | '&' MUTEX typedef_name attribute_list_opt
3734 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3735 | type_parameter_ptr
3736 | type_parameter_array attribute_list_opt
3737 { $$ = $1->addQualifiers( $2 ); }
3738 | type_parameter_function attribute_list_opt
3739 { $$ = $1->addQualifiers( $2 ); }
3740 ;
3741
3742typedef_name:
3743 TYPEDEFname
3744 { $$ = DeclarationNode::newName( $1 ); }
3745 | TYPEGENname
3746 { $$ = DeclarationNode::newName( $1 ); }
3747 ;
3748
3749type_parameter_ptr:
3750 ptrref_operator type_parameter_redeclarator
3751 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3752 | ptrref_operator type_qualifier_list type_parameter_redeclarator
3753 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3754 | '(' type_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3755 { $$ = $2->addQualifiers( $4 ); }
3756 ;
3757
3758type_parameter_array:
3759 typedef_name array_parameter_dimension
3760 { $$ = $1->addArray( $2 ); }
3761 | '(' type_parameter_ptr ')' array_parameter_dimension
3762 { $$ = $2->addArray( $4 ); }
3763 ;
3764
3765type_parameter_function:
3766 typedef_name '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3767 { $$ = $1->addParamList( $4 ); }
3768 | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3769 { $$ = $2->addParamList( $6 ); }
3770 ;
3771
3772// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3773// which the type applies, e.g.:
3774//
3775// sizeof( int );
3776// sizeof( int * );
3777// sizeof( int [10] );
3778// sizeof( int (*)() );
3779// sizeof( int () );
3780//
3781// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3782// and functions versus pointers to arrays and functions.
3783
3784abstract_declarator:
3785 abstract_ptr
3786 | abstract_array attribute_list_opt
3787 { $$ = $1->addQualifiers( $2 ); }
3788 | abstract_function attribute_list_opt
3789 { $$ = $1->addQualifiers( $2 ); }
3790 ;
3791
3792abstract_ptr:
3793 ptrref_operator
3794 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3795 | ptrref_operator type_qualifier_list
3796 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3797 | ptrref_operator abstract_declarator
3798 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3799 | ptrref_operator type_qualifier_list abstract_declarator
3800 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3801 | '(' abstract_ptr ')' attribute_list_opt
3802 { $$ = $2->addQualifiers( $4 ); }
3803 ;
3804
3805abstract_array:
3806 array_dimension
3807 | '(' abstract_ptr ')' array_dimension
3808 { $$ = $2->addArray( $4 ); }
3809 | '(' abstract_array ')' multi_array_dimension // redundant parenthesis
3810 { $$ = $2->addArray( $4 ); }
3811 | '(' abstract_array ')' // redundant parenthesis
3812 { $$ = $2; }
3813 ;
3814
3815abstract_function:
3816 '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3817 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3818 | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3819 { $$ = $2->addParamList( $6 ); }
3820 | '(' abstract_function ')' // redundant parenthesis
3821 { $$ = $2; }
3822 ;
3823
3824array_dimension:
3825 // Only the first dimension can be empty.
3826 '[' ']'
3827 { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
3828 | '[' ']' multi_array_dimension
3829 { $$ = DeclarationNode::newArray( nullptr, nullptr, false )->addArray( $3 ); }
3830 // Cannot use constant_expression because of tuples => semantic check
3831 | '[' push assignment_expression pop ',' comma_expression ']' // CFA
3832 { $$ = DeclarationNode::newArray( $3, nullptr, false )->addArray( DeclarationNode::newArray( $6, nullptr, false ) ); }
3833 // { SemanticError( yylloc, "New array dimension is currently unimplemented." ); $$ = nullptr; }
3834 | '[' push array_type_list pop ']' // CFA
3835 { SemanticError( yylloc, "Type array dimension is currently unimplemented." ); $$ = nullptr; }
3836 | multi_array_dimension
3837 ;
3838
3839array_type_list:
3840 basic_type_name
3841 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3842 | type_name
3843 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3844 | assignment_expression upupeq assignment_expression
3845 | array_type_list ',' basic_type_name
3846 { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) )); }
3847 | array_type_list ',' type_name
3848 { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) )); }
3849 | array_type_list ',' assignment_expression upupeq assignment_expression
3850 ;
3851
3852upupeq:
3853 '~'
3854 { $$ = OperKinds::LThan; }
3855 | ErangeUpEq
3856 { $$ = OperKinds::LEThan; }
3857 ;
3858
3859multi_array_dimension:
3860 '[' push assignment_expression pop ']'
3861 { $$ = DeclarationNode::newArray( $3, nullptr, false ); }
3862 | '[' push '*' pop ']' // C99
3863 { $$ = DeclarationNode::newVarArray( 0 ); }
3864 | multi_array_dimension '[' push assignment_expression pop ']'
3865 { $$ = $1->addArray( DeclarationNode::newArray( $4, nullptr, false ) ); }
3866 | multi_array_dimension '[' push '*' pop ']' // C99
3867 { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3868 ;
3869
3870// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3871// identifier to which the type applies, e.g.:
3872//
3873// int f( int ); // not handled here
3874// int f( int * ); // abstract function-prototype parameter; no parameter name specified
3875// int f( int (*)() ); // abstract function-prototype parameter; no parameter name specified
3876// int f( int (int) ); // abstract function-prototype parameter; no parameter name specified
3877//
3878// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3879// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3880// special meaning of parenthesis around a typedef name:
3881//
3882// ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3883// parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3884// not as redundant parentheses around the identifier."
3885//
3886// For example:
3887//
3888// typedef float T;
3889// int f( int ( T [5] ) ); // see abstract_parameter_declarator
3890// int g( int ( T ( int ) ) ); // see abstract_parameter_declarator
3891// int f( int f1( T a[5] ) ); // see identifier_parameter_declarator
3892// int g( int g1( T g2( int p ) ) ); // see identifier_parameter_declarator
3893//
3894// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3895// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3896// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3897// functions.
3898
3899abstract_parameter_declarator_opt:
3900 // empty
3901 { $$ = nullptr; }
3902 | abstract_parameter_declarator
3903 ;
3904
3905abstract_parameter_declarator:
3906 abstract_parameter_ptr
3907 | '&' MUTEX attribute_list_opt
3908 { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3909 | abstract_parameter_array attribute_list_opt
3910 { $$ = $1->addQualifiers( $2 ); }
3911 | abstract_parameter_function attribute_list_opt
3912 { $$ = $1->addQualifiers( $2 ); }
3913 ;
3914
3915abstract_parameter_ptr:
3916 ptrref_operator
3917 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3918 | ptrref_operator type_qualifier_list
3919 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3920 | ptrref_operator abstract_parameter_declarator
3921 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3922 | ptrref_operator type_qualifier_list abstract_parameter_declarator
3923 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3924 | '(' abstract_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3925 { $$ = $2->addQualifiers( $4 ); }
3926 ;
3927
3928abstract_parameter_array:
3929 array_parameter_dimension
3930 | '(' abstract_parameter_ptr ')' array_parameter_dimension
3931 { $$ = $2->addArray( $4 ); }
3932 | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3933 { $$ = $2->addArray( $4 ); }
3934 | '(' abstract_parameter_array ')' // redundant parenthesis
3935 { $$ = $2; }
3936 ;
3937
3938abstract_parameter_function:
3939 '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3940 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3941 | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3942 { $$ = $2->addParamList( $6 ); }
3943 | '(' abstract_parameter_function ')' // redundant parenthesis
3944 { $$ = $2; }
3945 ;
3946
3947array_parameter_dimension:
3948 // Only the first dimension can be empty or have qualifiers.
3949 array_parameter_1st_dimension
3950 | array_parameter_1st_dimension multi_array_dimension
3951 { $$ = $1->addArray( $2 ); }
3952 | multi_array_dimension
3953 ;
3954
3955// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3956//
3957// ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3958// a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3959
3960array_parameter_1st_dimension:
3961 '[' ']'
3962 { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
3963 // multi_array_dimension handles the '[' '*' ']' case
3964 | '[' push type_qualifier_list '*' pop ']' // remaining C99
3965 { $$ = DeclarationNode::newVarArray( $3 ); }
3966 | '[' push type_qualifier_list pop ']'
3967 { $$ = DeclarationNode::newArray( nullptr, $3, false ); }
3968 // multi_array_dimension handles the '[' assignment_expression ']' case
3969 | '[' push type_qualifier_list assignment_expression pop ']'
3970 { $$ = DeclarationNode::newArray( $4, $3, false ); }
3971 | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3972 { $$ = DeclarationNode::newArray( $5, $4, true ); }
3973 | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3974 { $$ = DeclarationNode::newArray( $5, $3, true ); }
3975 ;
3976
3977// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3978//
3979// struct S {
3980// int;
3981// int *;
3982// int [10];
3983// int (*)();
3984// };
3985
3986variable_abstract_declarator:
3987 variable_abstract_ptr
3988 | variable_abstract_array attribute_list_opt
3989 { $$ = $1->addQualifiers( $2 ); }
3990 | variable_abstract_function attribute_list_opt
3991 { $$ = $1->addQualifiers( $2 ); }
3992 ;
3993
3994variable_abstract_ptr:
3995 ptrref_operator
3996 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3997 | ptrref_operator type_qualifier_list
3998 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3999 | ptrref_operator variable_abstract_declarator
4000 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4001 | ptrref_operator type_qualifier_list variable_abstract_declarator
4002 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4003 | '(' variable_abstract_ptr ')' attribute_list_opt // redundant parenthesis
4004 { $$ = $2->addQualifiers( $4 ); }
4005 ;
4006
4007variable_abstract_array:
4008 array_dimension
4009 | '(' variable_abstract_ptr ')' array_dimension
4010 { $$ = $2->addArray( $4 ); }
4011 | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
4012 { $$ = $2->addArray( $4 ); }
4013 | '(' variable_abstract_array ')' // redundant parenthesis
4014 { $$ = $2; }
4015 ;
4016
4017variable_abstract_function:
4018 '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
4019 { $$ = $2->addParamList( $6 ); }
4020 | '(' variable_abstract_function ')' // redundant parenthesis
4021 { $$ = $2; }
4022 ;
4023
4024// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
4025// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
4026
4027cfa_identifier_parameter_declarator_tuple: // CFA
4028 cfa_identifier_parameter_declarator_no_tuple
4029 | cfa_abstract_tuple
4030 | type_qualifier_list cfa_abstract_tuple
4031 { $$ = $2->addQualifiers( $1 ); }
4032 ;
4033
4034cfa_identifier_parameter_declarator_no_tuple: // CFA
4035 cfa_identifier_parameter_ptr
4036 | cfa_identifier_parameter_array
4037 ;
4038
4039cfa_identifier_parameter_ptr: // CFA
4040 // No SUE declaration in parameter list.
4041 ptrref_operator type_specifier_nobody
4042 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4043 | type_qualifier_list ptrref_operator type_specifier_nobody
4044 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4045 | ptrref_operator cfa_abstract_function
4046 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4047 | type_qualifier_list ptrref_operator cfa_abstract_function
4048 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4049 | ptrref_operator cfa_identifier_parameter_declarator_tuple
4050 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4051 | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
4052 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4053 ;
4054
4055cfa_identifier_parameter_array: // CFA
4056 // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
4057 // shift/reduce conflict with new-style empty (void) function return type.
4058 '[' ']' type_specifier_nobody
4059 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4060 | cfa_array_parameter_1st_dimension type_specifier_nobody
4061 { $$ = $2->addNewArray( $1 ); }
4062 | '[' ']' multi_array_dimension type_specifier_nobody
4063 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4064 | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
4065 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4066 | multi_array_dimension type_specifier_nobody
4067 { $$ = $2->addNewArray( $1 ); }
4068
4069 | '[' ']' cfa_identifier_parameter_ptr
4070 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4071 | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
4072 { $$ = $2->addNewArray( $1 ); }
4073 | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
4074 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4075 | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
4076 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4077 | multi_array_dimension cfa_identifier_parameter_ptr
4078 { $$ = $2->addNewArray( $1 ); }
4079 ;
4080
4081cfa_array_parameter_1st_dimension:
4082 '[' push type_qualifier_list '*' pop ']' // remaining C99
4083 { $$ = DeclarationNode::newVarArray( $3 ); }
4084 | '[' push type_qualifier_list assignment_expression pop ']'
4085 { $$ = DeclarationNode::newArray( $4, $3, false ); }
4086 | '[' push declaration_qualifier_list assignment_expression pop ']'
4087 // declaration_qualifier_list must be used because of shift/reduce conflict with
4088 // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
4089 // appear in this context.
4090 { $$ = DeclarationNode::newArray( $4, $3, true ); }
4091 | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
4092 { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
4093 ;
4094
4095// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
4096// identifier to which the type applies, e.g.:
4097//
4098// [int] f( int ); // abstract variable parameter; no parameter name specified
4099// [int] f( [int] (int) ); // abstract function-prototype parameter; no parameter name specified
4100//
4101// These rules need LR(3):
4102//
4103// cfa_abstract_tuple identifier_or_type_name
4104// '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
4105//
4106// since a function return type can be syntactically identical to a tuple type:
4107//
4108// [int, int] t;
4109// [int, int] f( int );
4110//
4111// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
4112// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
4113// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
4114// duplicated when appearing with cfa_function_specifier.
4115
4116cfa_abstract_declarator_tuple: // CFA
4117 cfa_abstract_tuple
4118 | type_qualifier_list cfa_abstract_tuple
4119 { $$ = $2->addQualifiers( $1 ); }
4120 | cfa_abstract_declarator_no_tuple
4121 ;
4122
4123cfa_abstract_declarator_no_tuple: // CFA
4124 cfa_abstract_ptr
4125 | cfa_abstract_array
4126 ;
4127
4128cfa_abstract_ptr: // CFA
4129 ptrref_operator type_specifier
4130 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4131 | type_qualifier_list ptrref_operator type_specifier
4132 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4133 | ptrref_operator cfa_abstract_function
4134 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4135 | type_qualifier_list ptrref_operator cfa_abstract_function
4136 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4137 | ptrref_operator cfa_abstract_declarator_tuple
4138 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4139 | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
4140 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4141 ;
4142
4143cfa_abstract_array: // CFA
4144 // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
4145 // empty (void) function return type.
4146 '[' ']' type_specifier
4147 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4148 | '[' ']' multi_array_dimension type_specifier
4149 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4150 | multi_array_dimension type_specifier
4151 { $$ = $2->addNewArray( $1 ); }
4152 | '[' ']' cfa_abstract_ptr
4153 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4154 | '[' ']' multi_array_dimension cfa_abstract_ptr
4155 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4156 | multi_array_dimension cfa_abstract_ptr
4157 { $$ = $2->addNewArray( $1 ); }
4158 ;
4159
4160cfa_abstract_tuple: // CFA
4161 '[' push cfa_abstract_parameter_list pop ']'
4162 { $$ = DeclarationNode::newTuple( $3 ); }
4163 | '[' push type_specifier_nobody ELLIPSIS pop ']'
4164 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4165 | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
4166 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4167 ;
4168
4169cfa_abstract_function: // CFA
4170// '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
4171// { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
4172 cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
4173 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4174 | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
4175 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4176 ;
4177
4178// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
4179// each declaration, and in the specifier-qualifier list in each structure declaration and type name."
4180//
4181// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
4182// the declaration specifiers in a declaration is an obsolescent feature."
4183//
4184// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
4185// prototype-format parameter type declarators) is an obsolescent feature."
4186//
4187// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
4188// declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
4189
4190// ************************ MISCELLANEOUS ********************************
4191
4192comma_opt: // redundant comma
4193 // empty
4194 | ','
4195 ;
4196
4197default_initializer_opt:
4198 // empty
4199 { $$ = nullptr; }
4200 | '=' assignment_expression
4201 { $$ = $2; }
4202 ;
4203
4204%%
4205
4206// ----end of grammar----
4207
4208// Local Variables: //
4209// mode: c++ //
4210// tab-width: 4 //
4211// compile-command: "make install" //
4212// End: //
Note: See TracBrowser for help on using the repository browser.