source: src/Parser/parser.yy@ 0e4e43d

Last change on this file since 0e4e43d was e86735ba, checked in by Peter A. Buhr <pabuhr@…>, 5 months ago

clean up current for control, first attempt at adding ==/!= to for control
  • Property mode set to 100644
File size: 184.7 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author : Peter A. Buhr
10// Created On : Sat Sep 1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Fri Apr 18 15:23:42 2025
13// Update Count : 7283
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS. While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks. Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed. Most of the syntactic extensions from
27// ANSI90 to ANSI11 C are marked with the comment "C99/C11".
28
29// This grammar also has two levels of extensions. The first extensions cover most of the GCC C extensions. All of the
30// syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall (CFA), which
31// fixes several of C's outstanding problems and extends C with many modern language concepts. All of the syntactic
32// extensions for CFA C are marked with the comment "CFA".
33
34%{
35#define YYDEBUG_LEXER_TEXT( yylval ) // lexer loads this up each time
36#define YYDEBUG 1 // get the pretty debugging code to compile
37#define YYERROR_VERBOSE // more information in syntax errors
38
39#undef __GNUC_MINOR__
40
41#include <cstdio>
42#include <sstream>
43#include <stack>
44using namespace std;
45
46#include "DeclarationNode.hpp" // for DeclarationNode, ...
47#include "ExpressionNode.hpp" // for ExpressionNode, ...
48#include "InitializerNode.hpp" // for InitializerNode, ...
49#include "ParserTypes.hpp"
50#include "StatementNode.hpp" // for build_...
51#include "TypedefTable.hpp"
52#include "TypeData.hpp"
53#include "AST/Type.hpp" // for BasicType, BasicKind
54#include "Common/SemanticError.hpp" // error_str
55#include "Common/Utility.hpp" // for maybeMoveBuild, maybeBuild, CodeLo...
56#include "AST/Attribute.hpp" // for Attribute
57#include "AST/Print.hpp" // for print
58#include "Common/Iterate.hpp" // for reverseIterate
59
60// lex uses __null in a boolean context, it's fine.
61#ifdef __clang__
62#pragma GCC diagnostic ignored "-Wparentheses-equality"
63#endif
64
65extern DeclarationNode * parseTree;
66extern ast::Linkage::Spec linkage;
67extern TypedefTable typedefTable;
68
69stack<ast::Linkage::Spec> linkageStack;
70
71bool appendStr( string & to, string & from ) {
72 // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
73 // "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
74 // the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
75 // easier to let the C compiler handle this case.
76 //
77 // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
78 // without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
79 // e.g., u"a" U"b" L"c" is disallowed.
80
81 if ( from[0] != '"' ) { // encoding ?
82 if ( to[0] != '"' ) { // encoding ?
83 if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
84 yyerror( "non-matching string encodings for string-literal concatenation" );
85 return false; // parse error, must call YYERROR in action
86 } else if ( from[1] == '8' ) {
87 from.erase( 0, 1 ); // remove 2nd encoding
88 } // if
89 } else {
90 if ( from[1] == '8' ) { // move encoding to start
91 to = "u8" + to;
92 from.erase( 0, 1 ); // remove 2nd encoding
93 } else {
94 to = from[0] + to;
95 } // if
96 } // if
97 from.erase( 0, 1 ); // remove 2nd encoding
98 } // if
99 to += " " + from; // concatenated into single string
100 return true;
101} // appendStr
102
103DeclarationNode * distTypeSpec( DeclarationNode * typeSpec, DeclarationNode * declList ) {
104 // Distribute type specifier across all declared variables, e.g., static, const, __attribute__.
105 assert( declList );
106
107 // Do not distribute attributes for aggregates because the attributes surrounding the aggregate belong it not the
108 // variables in the declaration list, e.g.,
109 //
110 // struct __attribute__(( aligned(128) )) S { ...
111 // } v1 __attribute__(( aligned(64) )), v2 __attribute__(( aligned(32) )), v3;
112 // struct S v4;
113 //
114 // v1 => 64, v2 =>32, v3 => 128, v2 => 128
115 //
116 // Anonymous aggregates are a special case because there is no aggregate to bind the attribute to; hence it floats
117 // to the declaration list.
118 //
119 // struct __attribute__(( aligned(128) )) /*anonymous */ { ... } v1;
120 //
121 // v1 => 128
122
123 bool copyattr = ! (typeSpec->type && typeSpec->type->kind == TypeData::Aggregate && ! typeSpec->type->aggregate.anon );
124
125 // addType copies the type information for the aggregate instances from typeSpec into cl's aggInst.aggregate.
126 DeclarationNode * cl = (new DeclarationNode)->addType( typeSpec ); // typeSpec IS DELETED!!!
127
128 // Start at second variable in declaration list and clone the type specifiers for each variable.
129 for ( DeclarationNode * cur = declList->next ; cur != nullptr; cur = cur->next ) {
130 cl->cloneBaseType( cur, copyattr ); // cur is modified
131 } // for
132
133 // Add first variable in declaration list with hidden type information in aggInst.aggregate, which is used by
134 // extractType to recover the type for the aggregate instances.
135 declList->addType( cl, copyattr ); // cl IS DELETED!!!
136 return declList;
137} // distTypeSpec
138
139void distAttr( DeclarationNode * attributes, DeclarationNode * declaration ) {
140 // distribute attributes across all declaring list
141 for ( DeclarationNode * attr = attributes; attr != nullptr ; attr = attr->next ) {
142 for ( DeclarationNode * decl = declaration ; decl != nullptr ; decl = decl->next ) {
143 decl->attributes.insert( decl->attributes.begin(), attr->attributes.begin(), attr->attributes.end() );
144 } // for
145 } // for
146} // distAttr
147
148void distExt( DeclarationNode * declaration ) {
149 // distribute EXTENSION across all declarations
150 for ( DeclarationNode * decl = declaration ; decl != nullptr ; decl = decl->next ) {
151 decl->set_extension( true );
152 } // for
153} // distExt
154
155void distInl( DeclarationNode * declaration ) {
156 // distribute INLINE across all declarations
157 for ( DeclarationNode *decl = declaration ; decl != nullptr ; decl = decl->next ) {
158 decl->set_inLine( true );
159 } // for
160} // distInl
161
162void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
163 // distribute qualifiers across all non-variable declarations in a distribution statemement
164 for ( DeclarationNode * decl = declaration ; decl != nullptr ; decl = decl->next ) {
165 // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
166 // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
167 // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
168 // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
169 DeclarationNode * clone = qualifiers->clone();
170 if ( qualifiers->type ) { // forall clause ? (handles SC)
171 if ( decl->type->kind == TypeData::Aggregate ) { // struct/union ?
172 swap( clone->type->forall, decl->type->aggregate.params );
173 decl->addQualifiers( clone );
174 } else if ( decl->type->kind == TypeData::AggregateInst && decl->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
175 // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
176 DeclarationNode newnode;
177 swap( newnode.type, decl->type->aggInst.aggregate );
178 swap( clone->type->forall, newnode.type->aggregate.params );
179 newnode.addQualifiers( clone );
180 swap( newnode.type, decl->type->aggInst.aggregate );
181 } else if ( decl->type->kind == TypeData::Function ) { // routines ?
182 swap( clone->type->forall, decl->type->forall );
183 decl->addQualifiers( clone );
184 } // if
185 } else { // just SC qualifiers
186 decl->addQualifiers( clone );
187 } // if
188 } // for
189 delete qualifiers;
190} // distQual
191
192// There is an ambiguity for inline generic-routine return-types and generic routines.
193// forall( otype T ) struct S { int i; } bar( T ) {}
194// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
195// forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
196// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
197// forall( otype T ) struct S { int T; };
198// forall( otype W ) bar( W ) {}
199
200void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
201 if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
202 funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
203 declSpec->type->aggregate.params = nullptr;
204 } // if
205} // rebindForall
206
207string * build_postfix_name( string * name ) {
208 *name = string("__postfix_func_") + *name;
209 return name;
210} // build_postfix_name
211
212DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
213 if ( fieldList == nullptr ) {
214 if ( !( typeSpec->type && typeSpec->type->kind == TypeData::Aggregate ) ) { // int; no fieldList
215 // printf( "fieldDecl1 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
216 SemanticWarning( yylloc, Warning::SuperfluousDecl );
217 return nullptr;
218 } // if
219 // printf( "fieldDecl2 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
220 fieldList = DeclarationNode::newName( nullptr ); // struct S { ... } no fieldList
221 } // if
222
223 // printf( "fieldDecl3 typeSpec %p\n", typeSpec ); typeSpec->print( std::cout, 0 );
224 DeclarationNode * temp = distTypeSpec( typeSpec, fieldList ); // mark all fields in list
225 // printf( "fieldDecl4 temp %p\n", temp ); temp->print( std::cout, 0 );
226 return temp;
227} // fieldDecl
228
229#define NEW_ZERO new ExpressionNode( build_constantInteger( yylloc, *new string( "0" ) ) )
230#define NEW_ONE new ExpressionNode( build_constantInteger( yylloc, *new string( "1" ) ) )
231#define UPDOWN( compop, left, right ) (compop == OperKinds::LThan || compop == OperKinds::LEThan || compop == OperKinds::Neq ? left : right)
232#define MISSING_ANON_FIELD "illegal syntax, missing loop fields with an anonymous loop index is meaningless as loop index is unavailable in loop body."
233#define MISSING_LOW "illegal syntax, missing low value for ascanding range so index is uninitialized."
234#define MISSING_HIGH "illegal syntax, missing high value for descending range so index is uninitialized."
235
236static ForCtrl * makeForCtrl( const CodeLocation & location, DeclarationNode * init, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
237 // Wrap both comp/inc if they are non-null.
238 if ( comp ) comp = new ExpressionNode( build_binary_val( location,
239 compop,
240 new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
241 comp ) );
242 if ( inc ) inc = new ExpressionNode( build_binary_val( location,
243 // choose += or -= for upto/downto
244 UPDOWN( compop, OperKinds::PlusAssn, OperKinds::MinusAssn ),
245 new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
246 inc ) );
247 // The StatementNode call frees init->name, it must happen later.
248 return new ForCtrl( new StatementNode( init ), comp, inc );
249}
250
251ForCtrl * forCtrl( const CodeLocation & location, DeclarationNode * index, ExpressionNode * start, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
252 if ( index->initializer ) {
253 SemanticError( yylloc, "illegal syntax, direct initialization disallowed. Use instead: type var; initialization ~ comparison ~ increment." );
254 } // if
255 if ( index->next ) {
256 SemanticError( yylloc, "illegal syntax, multiple loop indexes disallowed in for-loop declaration." );
257 } // if
258 DeclarationNode * initDecl = index->addInitializer( new InitializerNode( start ) );
259 return makeForCtrl( location, initDecl, compop, comp, inc );
260} // forCtrl
261
262ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, string * index, ExpressionNode * start, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
263 ast::ConstantExpr * constant = dynamic_cast<ast::ConstantExpr *>(type->expr.get());
264 if ( constant && (constant->rep == "0" || constant->rep == "1") ) {
265 type = new ExpressionNode( new ast::CastExpr( location, maybeMoveBuild(type), new ast::BasicType( ast::BasicKind::SignedInt ) ) );
266 } // if
267 DeclarationNode * initDecl = distTypeSpec(
268 DeclarationNode::newTypeof( type, true ),
269 DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) )
270 );
271 return makeForCtrl( location, initDecl, compop, comp, inc );
272} // forCtrl
273
274#define MISSING_LOOP_INDEX "illegal syntax, only a single identifier or declaration allowed in initialization, e.g., for ( i; ... ) or for ( int i; ... ). Expression disallowed."
275
276ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
277 if ( auto identifier = dynamic_cast<ast::NameExpr *>(index->expr.get()) ) {
278 return forCtrl( location, type, new string( identifier->name ), start, compop, comp, inc );
279 } else {
280 SemanticError( yylloc, MISSING_LOOP_INDEX ); return nullptr;
281 } // if
282} // forCtrl
283
284ForCtrl * enumRangeCtrl( ExpressionNode * index_expr, OperKinds compop, ExpressionNode * range_over_expr, DeclarationNode * type ) {
285 assert( compop == OperKinds::LEThan || compop == OperKinds::GEThan );
286 if ( auto identifier = dynamic_cast<ast::NameExpr *>(index_expr->expr.get()) ) {
287 DeclarationNode * indexDecl =
288 DeclarationNode::newName( new std::string(identifier->name) )->addType( type );
289 return new ForCtrl( new StatementNode( indexDecl ), range_over_expr, compop );
290 } else {
291 SemanticError( yylloc, MISSING_LOOP_INDEX ); return nullptr;
292 } // if
293} // enumRangeCtrl
294
295static void IdentifierBeforeIdentifier( string & identifier1, string & identifier2, const char * kind ) {
296 SemanticError( yylloc, "illegal syntax, adjacent identifiers \"%s\" and \"%s\" are not meaningful in an %s.\n"
297 "Possible cause is misspelled type name or missing generic parameter.",
298 identifier1.c_str(), identifier2.c_str(), kind );
299} // IdentifierBeforeIdentifier
300
301static void IdentifierBeforeType( string & identifier, const char * kind ) {
302 SemanticError( yylloc, "illegal syntax, identifier \"%s\" cannot appear before a %s.\n"
303 "Possible cause is misspelled storage/CV qualifier, misspelled typename, or missing generic parameter.",
304 identifier.c_str(), kind );
305} // IdentifierBeforeType
306
307bool forall = false; // aggregate have one or more forall qualifiers ?
308
309// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
310#define YYLLOC_DEFAULT(Cur, Rhs, N) \
311if ( N ) { \
312 (Cur).first_line = YYRHSLOC( Rhs, 1 ).first_line; \
313 (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column; \
314 (Cur).last_line = YYRHSLOC( Rhs, N ).last_line; \
315 (Cur).last_column = YYRHSLOC( Rhs, N ).last_column; \
316 (Cur).filename = YYRHSLOC( Rhs, 1 ).filename; \
317} else { \
318 (Cur).first_line = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line; \
319 (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column; \
320 (Cur).filename = YYRHSLOC( Rhs, 0 ).filename; \
321}
322%}
323
324%define parse.error verbose
325
326// Types declaration for productions
327
328%union {
329 // A raw token can be used.
330 Token tok;
331
332 // The general node types hold some generic node or list of nodes.
333 DeclarationNode * decl;
334 InitializerNode * init;
335 ExpressionNode * expr;
336 StatementNode * stmt;
337 ClauseNode * clause;
338 TypeData * type;
339
340 // Special "nodes" containing compound information.
341 CondCtrl * ifctrl;
342 ForCtrl * forctrl;
343 LabelNode * labels;
344
345 // Various flags and single values that become fields later.
346 ast::AggregateDecl::Aggregate aggKey;
347 ast::TypeDecl::Kind tclass;
348 OperKinds oper;
349 bool is_volatile;
350 EnumHiding enum_hiding;
351 ast::ExceptionKind except_kind;
352 // String passes ownership with it.
353 std::string * str;
354
355 // Narrower node types are used to avoid constant unwrapping.
356 ast::WaitForStmt * wfs;
357 ast::WaitUntilStmt::ClauseNode * wucn;
358 ast::GenericExpr * genexpr;
359}
360
361// ************************ TERMINAL TOKENS ********************************
362
363// keywords
364%token TYPEDEF
365%token EXTERN STATIC AUTO REGISTER
366%token THREADLOCALGCC THREADLOCALC11 // GCC, C11
367%token INLINE FORTRAN // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
368%token NORETURN // C11
369%token CONST VOLATILE
370%token RESTRICT // C99
371%token ATOMIC // C11
372%token FORALL MUTEX VIRTUAL VTABLE COERCE // CFA
373%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
374%token BOOL COMPLEX IMAGINARY // C99
375%token INT128 UINT128 FLOAT80 uuFLOAT128 // GCC
376%token FLOAT16 FLOAT32 FLOAT32X FLOAT64 FLOAT64X FLOAT128 FLOAT128X // GCC
377%token FLOAT32X4 FLOAT64X2 SVFLOAT32 SVFLOAT64 SVBOOL // GCC (ARM)
378%token DECIMAL32 DECIMAL64 DECIMAL128 // GCC
379%token ZERO_T ONE_T // CFA
380%token SIZEOF TYPEOF VA_LIST VA_ARG AUTO_TYPE COUNTOF // GCC
381%token OFFSETOF BASETYPEOF TYPEID // CFA
382%token ENUM STRUCT UNION
383%token EXCEPTION // CFA
384%token GENERATOR COROUTINE MONITOR THREAD // CFA
385%token OTYPE FTYPE DTYPE TTYPE TRAIT // CFA
386// %token RESUME // CFA
387%token LABEL // GCC
388%token SUSPEND // CFA
389%token ATTRIBUTE EXTENSION // GCC
390%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
391%token CHOOSE FALLTHROUGH WITH WHEN WAITFOR WAITUNTIL // CFA
392%token CORUN COFOR
393%token DISABLE ENABLE TRY THROW THROWRESUME AT // CFA
394%token ASM // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
395%token ALIGNAS ALIGNOF GENERIC STATICASSERT // C11
396
397// names and constants: lexer differentiates between identifier and typedef names
398%token<tok> IDENTIFIER TYPEDIMname TYPEDEFname TYPEGENname
399%token<tok> TIMEOUT WAND WOR CATCH RECOVER CATCHRESUME FIXUP FINALLY // CFA
400%token<tok> INTEGERconstant CHARACTERconstant STRINGliteral
401%token<tok> DIRECTIVE C23_ATTRIBUTE
402// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
403// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
404// converted into the tuple index (.)(1). e.g., 3.x
405%token<tok> FLOATING_DECIMALconstant FLOATING_FRACTIONconstant FLOATINGconstant
406
407// multi-character operators
408%token ARROW // ->
409%token ICR DECR // ++ --
410%token LS RS // << >>
411%token LE GE EQ NE // <= >= == !=
412%token ANDAND OROR // && ||
413%token ATTR ELLIPSIS // @@ ...
414
415%token EXPassign MULTassign DIVassign MODassign // \= *= /= %=
416%token PLUSassign MINUSassign // += -=
417%token LSassign RSassign // <<= >>=
418%token ANDassign ERassign ORassign // &= ^= |=
419
420%token ErangeUpLt ErangeUpLe ErangeEq ErangeNe // +~ +~=/~= ~== ~!=
421%token ErangeDownGt ErangeDownGe ErangeDownEq ErangeDownNe // -~ -~= -~== -~!=
422%token ATassign // @=
423
424%type<tok> identifier identifier_at identifier_or_type_name attr_name
425%type<tok> quasi_keyword
426%type<expr> string_literal
427%type<str> string_literal_list
428
429%type<enum_hiding> hide_opt visible_hide_opt
430
431// expressions
432%type<expr> constant
433%type<expr> tuple tuple_expression_list
434%type<oper> ptrref_operator unary_operator assignment_operator simple_assignment_operator compound_assignment_operator
435%type<expr> primary_expression postfix_expression unary_expression
436%type<expr> cast_expression_list cast_expression exponential_expression multiplicative_expression additive_expression
437%type<expr> shift_expression relational_expression equality_expression
438%type<expr> AND_expression exclusive_OR_expression inclusive_OR_expression
439%type<expr> logical_AND_expression logical_OR_expression
440%type<expr> conditional_expression constant_expression assignment_expression assignment_expression_opt
441%type<expr> comma_expression comma_expression_opt
442%type<expr> argument_expression_list_opt argument_expression_list argument_expression default_initializer_opt
443%type<ifctrl> conditional_declaration
444%type<forctrl> for_control_expression for_control_expression_list
445%type<oper> upupeq updown updownS updownEq
446%type<expr> subrange
447%type<decl> asm_name_opt
448%type<expr> asm_operands_opt asm_operands_list asm_operand
449%type<labels> asm_label_list
450%type<expr> asm_clobbers_list_opt
451%type<is_volatile> asm_volatile_opt
452%type<expr> handler_predicate_opt
453%type<genexpr> generic_association generic_assoc_list
454
455// statements
456%type<stmt> statement labelled_statement compound_statement
457%type<stmt> statement_decl statement_decl_list statement_list_nodecl
458%type<stmt> selection_statement
459%type<clause> switch_clause_list_opt switch_clause_list
460%type<expr> case_value
461%type<clause> case_clause case_value_list case_label case_label_list
462%type<stmt> iteration_statement jump_statement
463%type<stmt> expression_statement asm_statement
464%type<stmt> with_statement
465%type<expr> with_clause_opt
466%type<stmt> corun_statement cofor_statement
467%type<stmt> exception_statement
468%type<clause> handler_clause finally_clause
469%type<except_kind> handler_key
470%type<stmt> mutex_statement
471%type<expr> when_clause when_clause_opt waitfor waituntil timeout
472%type<stmt> waitfor_statement waituntil_statement
473%type<wfs> wor_waitfor_clause
474%type<wucn> waituntil_clause wand_waituntil_clause wor_waituntil_clause
475
476// declarations
477%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
478%type<decl> abstract_parameter_declarator_opt abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array
479 abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension abstract_parameter_declaration
480
481%type<aggKey> aggregate_key aggregate_data aggregate_control
482%type<decl> aggregate_type aggregate_type_nobody
483
484%type<decl> assertion assertion_list assertion_list_opt
485
486%type<expr> bit_subrange_size_opt bit_subrange_size
487
488%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
489%type<type> basic_type_name_type
490%type<type> vtable vtable_opt default_opt
491
492%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
493
494%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
495%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
496
497%type<decl> elaborated_type elaborated_type_nobody
498
499%type<decl> enumerator_list enum_type enum_type_nobody enum_key enumerator_type
500%type<init> enumerator_value_opt
501
502%type<decl> external_definition external_definition_list external_definition_list_opt
503
504%type<decl> exception_declaration
505
506%type<decl> field_declaration_list_opt field_declaration field_declaring_list field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
507%type<expr> field field_name_list field_name fraction_constants_opt
508
509%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
510
511%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
512%type<decl> identifier_list
513
514%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
515%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
516%type<decl> cfa_abstract_ptr cfa_abstract_tuple
517
518%type<decl> cfa_array_parameter_1st_dimension
519
520%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
521%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
522
523%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
524%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
525
526%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_list_ellipsis_opt
527
528%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
529
530%type<decl> c_declaration static_assert
531%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
532%type<decl> KR_parameter_list KR_parameter_list_opt
533
534%type<decl> parameter_declaration parameter_list parameter_list_ellipsis_opt
535
536%type<decl> paren_identifier paren_type
537
538%type<decl> storage_class storage_class_list
539
540%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
541
542%type<tclass> type_class new_type_class
543%type<decl> type_declarator type_declarator_name type_declaring_list
544
545%type<decl> type_declaration_specifier type_type_specifier
546%type<type> type_name typegen_name
547%type<decl> typedef_name typedef_declaration typedef_expression
548
549%type<decl> variable_type_redeclarator variable_type_ptr variable_type_array variable_type_function
550%type<decl> general_function_declarator function_type_redeclarator function_type_array function_type_no_ptr function_type_ptr
551
552%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
553
554%type<decl> type type_no_function
555%type<decl> type_parameter type_parameter_list type_initializer_opt
556
557%type<expr> type_parameters_opt type_list array_type_list // array_dimension_list
558
559%type<decl> type_qualifier forall type_qualifier_list_opt type_qualifier_list
560%type<type> type_qualifier_name
561%type<decl> type_specifier type_specifier_nobody
562
563%type<decl> variable_declarator variable_ptr variable_array variable_function
564%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
565
566%type<decl> attribute_list_opt attribute_list attribute attribute_name_list attribute_name
567
568// initializers
569%type<init> initializer initializer_list_opt initializer_opt
570
571// designators
572%type<expr> designator designator_list designation
573
574
575// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
576// .---------. matches IF '(' comma_expression ')' statement . (reduce)
577// if ( C ) S1 else S2
578// `-----------------' matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
579// Similar issues exit with the waitfor statement.
580
581// Order of these lines matters (low-to-high precedence). THEN is left associative over WAND/WOR/TIMEOUT/ELSE, WAND/WOR
582// is left associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
583%precedence THEN // rule precedence for IF/WAITFOR statement
584%precedence ANDAND // token precedence for start of WAND in WAITFOR statement
585%precedence WAND // token precedence for start of WAND in WAITFOR statement
586%precedence OROR // token precedence for start of WOR in WAITFOR statement
587%precedence WOR // token precedence for start of WOR in WAITFOR statement
588%precedence TIMEOUT // token precedence for start of TIMEOUT in WAITFOR statement
589%precedence CATCH // token precedence for start of TIMEOUT in WAITFOR statement
590%precedence RECOVER // token precedence for start of TIMEOUT in WAITFOR statement
591%precedence CATCHRESUME // token precedence for start of TIMEOUT in WAITFOR statement
592%precedence FIXUP // token precedence for start of TIMEOUT in WAITFOR statement
593%precedence FINALLY // token precedence for start of TIMEOUT in WAITFOR statement
594%precedence ELSE // token precedence for start of else clause in IF/WAITFOR statement
595
596
597// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
598// forall( otype T ) struct Foo { T v; };
599// .-----. matches pointer to function returning a generic (which is impossible without a type)
600// Foo ( *fp )( int );
601// `---' matches start of TYPEGENname '('
602// must be:
603// Foo( int ) ( *fp )( int );
604// The same problem occurs here:
605// forall( otype T ) struct Foo { T v; } ( *fp )( int );
606// must be:
607// forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
608
609// Order of these lines matters (low-to-high precedence).
610%precedence TYPEGENname
611%precedence '}'
612%precedence '('
613
614// %precedence RESUME
615// %precedence '{'
616// %precedence ')'
617
618%locations // support location tracking for error messages
619
620%start translation_unit // parse-tree root
621
622%%
623// ************************ Namespace Management ********************************
624
625// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
626// which are lexically identical.
627//
628// typedef int foo; // identifier foo must now be scanned as TYPEDEFname
629// foo f; // to allow it to appear in this context
630//
631// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
632// between syntactic and semantic constructs. Cforall compounds this problem by introducing type names local to the
633// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
634// generators" -- parameterized types. This latter type name creates a third class of identifiers, "TYPEGENname", which
635// must be distinguished by the lexical scanner.
636//
637// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
638// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
639// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
640// each context that introduces a name scope, a new level is created in the type table and that level is popped on
641// exiting the scope. Since type names can be local to a particular declaration, each declaration is itself a scope.
642// This requires distinguishing between type names that are local to the current declaration scope and those that
643// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
644//
645// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
646// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
647// around the list separator.
648//
649// XXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
650// push pop push pop
651
652push:
653 { typedefTable.enterScope(); }
654 ;
655
656pop:
657 { typedefTable.leaveScope(); }
658 ;
659
660// ************************ CONSTANTS ********************************
661
662constant:
663 // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
664 INTEGERconstant { $$ = new ExpressionNode( build_constantInteger( yylloc, *$1 ) ); }
665 | FLOATING_DECIMALconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
666 | FLOATING_FRACTIONconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
667 | FLOATINGconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
668 | CHARACTERconstant { $$ = new ExpressionNode( build_constantChar( yylloc, *$1 ) ); }
669 ;
670
671quasi_keyword: // CFA
672 TIMEOUT
673 | WAND
674 | WOR
675 | CATCH
676 | RECOVER
677 | CATCHRESUME
678 | FIXUP
679 | FINALLY
680 ;
681
682identifier:
683 IDENTIFIER
684 | quasi_keyword
685 ;
686
687identifier_at:
688 identifier
689 | '@' // CFA
690 { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
691 ;
692
693identifier_or_type_name:
694 identifier
695 | TYPEDEFname
696 | TYPEGENname
697 ;
698
699string_literal:
700 string_literal_list { $$ = new ExpressionNode( build_constantStr( yylloc, *$1 ) ); }
701 ;
702
703string_literal_list: // juxtaposed strings are concatenated
704 STRINGliteral { $$ = $1; } // conversion from tok to str
705 | string_literal_list STRINGliteral
706 {
707 if ( ! appendStr( *$1, *$2 ) ) YYERROR; // append 2nd juxtaposed string to 1st
708 delete $2; // allocated by lexer
709 $$ = $1; // conversion from tok to str
710 }
711 ;
712
713// ************************ EXPRESSIONS ********************************
714
715primary_expression:
716 IDENTIFIER // typedef name cannot be used as a variable name
717 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
718 | quasi_keyword
719 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
720 | TYPEDIMname // CFA, generic length argument
721 { $$ = new ExpressionNode( build_dimensionref( yylloc, $1 ) ); }
722 | tuple
723 | '(' comma_expression ')'
724 { $$ = $2; }
725 | '(' compound_statement ')' // GCC, lambda expression
726 { $$ = new ExpressionNode( new ast::StmtExpr( yylloc, dynamic_cast<ast::CompoundStmt *>( maybeMoveBuild( $2 ) ) ) ); }
727 | type_name '.' identifier // CFA, nested type
728 { $$ = new ExpressionNode( build_qualified_expr( yylloc, DeclarationNode::newFromTypeData( $1 ), build_varref( yylloc, $3 ) ) ); }
729 | type_name '.' '[' field_name_list ']' // CFA, nested type / tuple field selector
730 { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
731 | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
732 {
733 // add the missing control expression to the GenericExpr and return it
734 $5->control = maybeMoveBuild( $3 );
735 $$ = new ExpressionNode( $5 );
736 }
737 // | RESUME '(' comma_expression ')'
738 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
739 // | RESUME '(' comma_expression ')' compound_statement
740 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
741 | IDENTIFIER IDENTIFIER // invalid syntax rule
742 { IdentifierBeforeIdentifier( *$1.str, *$2.str, "expression" ); $$ = nullptr; }
743 | IDENTIFIER type_qualifier // invalid syntax rule
744 { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
745 | IDENTIFIER storage_class // invalid syntax rule
746 { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
747 | IDENTIFIER basic_type_name // invalid syntax rule
748 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
749 | IDENTIFIER TYPEDEFname // invalid syntax rule
750 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
751 | IDENTIFIER TYPEGENname // invalid syntax rule
752 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
753 ;
754
755generic_assoc_list: // C11
756 generic_association
757 | generic_assoc_list ',' generic_association
758 {
759 // steal the association node from the singleton and delete the wrapper
760 assert( 1 == $3->associations.size() );
761 $1->associations.push_back( $3->associations.front() );
762 delete $3;
763 $$ = $1;
764 }
765 ;
766
767generic_association: // C11
768 type_no_function ':' assignment_expression
769 {
770 // create a GenericExpr wrapper with one association pair
771 $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuildType( $1 ), maybeMoveBuild( $3 ) } } );
772 }
773 | DEFAULT ':' assignment_expression
774 { $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuild( $3 ) } } ); }
775 ;
776
777postfix_expression:
778 primary_expression
779 | postfix_expression '[' assignment_expression ',' tuple_expression_list ']'
780 // Historic, transitional: Disallow commas in subscripts.
781 // Switching to this behaviour may help check if a C compatibilty case uses comma-exprs in subscripts.
782 // Current: Commas in subscripts make tuples.
783 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, new ExpressionNode( build_tuple( yylloc, $3->set_last( $5 ) ) ) ) ); }
784 | postfix_expression '[' assignment_expression ']'
785 // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
786 // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
787 // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
788 // equivalent to the old x[i,j].
789 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
790 | constant '[' assignment_expression ']' // 3[a], 'a'[a], 3.5[a]
791 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
792 | string_literal '[' assignment_expression ']' // "abc"[3], 3["abc"]
793 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
794 | postfix_expression '{' argument_expression_list_opt '}' // CFA, constructor call
795 {
796 Token fn;
797 fn.str = new std::string( "?{}" ); // location undefined - use location of '{'?
798 $$ = new ExpressionNode( new ast::ConstructorExpr( yylloc, build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), $1->set_last( $3 ) ) ) );
799 }
800 | postfix_expression '(' argument_expression_list_opt ')'
801 { $$ = new ExpressionNode( build_func( yylloc, $1, $3 ) ); }
802 | VA_ARG '(' primary_expression ',' declaration_specifier_nobody abstract_parameter_declarator_opt ')'
803 { $$ = new ExpressionNode( build_va_arg( yylloc, $3, ( $6 ? $6->addType( $5 ) : $5 ) ) ); }
804 | postfix_expression '`' identifier // CFA, postfix call
805 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
806 | constant '`' identifier // CFA, postfix call
807 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
808 | string_literal '`' identifier // CFA, postfix call
809 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
810
811 // SKULLDUGGERY: The typedef table used for parsing does not store fields in structures. To parse a qualified
812 // name, it is assumed all name-tokens after the first are identifiers, regardless of how the lexer identifies
813 // them. For example:
814 //
815 // struct S;
816 // forall(T) struct T;
817 // union U;
818 // enum E { S, T, E };
819 // struct Z { int S, T, Z, E, U; };
820 // void fred () {
821 // Z z;
822 // z.S; // lexer returns S is TYPEDEFname
823 // z.T; // lexer returns T is TYPEGENname
824 // z.Z; // lexer returns Z is TYPEDEFname
825 // z.U; // lexer returns U is TYPEDEFname
826 // z.E; // lexer returns E is TYPEDEFname
827 // }
828 | postfix_expression '.' identifier_or_type_name
829 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
830
831 | postfix_expression '.' INTEGERconstant // CFA, tuple index
832 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
833 | postfix_expression FLOATING_FRACTIONconstant // CFA, tuple index
834 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 ) ) ); }
835 | postfix_expression '.' '[' field_name_list ']' // CFA, tuple field selector
836 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
837 | postfix_expression '.' aggregate_control
838 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $3, $1 ) ); }
839 | postfix_expression ARROW identifier
840 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
841 | postfix_expression ARROW INTEGERconstant // CFA, tuple index
842 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
843 | postfix_expression ARROW '[' field_name_list ']' // CFA, tuple field selector
844 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
845 | postfix_expression ICR
846 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::IncrPost, $1 ) ); }
847 | postfix_expression DECR
848 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::DecrPost, $1 ) ); }
849 | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
850 { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, new InitializerNode( $5, true ) ) ); }
851 | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
852 { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
853 | '^' primary_expression '{' argument_expression_list_opt '}' // CFA, destructor call
854 {
855 Token fn;
856 fn.str = new string( "^?{}" ); // location undefined
857 $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), $2->set_last( $4 ) ) );
858 }
859 ;
860
861field_name_list: // CFA, tuple field selector
862 field
863 | field_name_list ',' field { $$ = $1->set_last( $3 ); }
864 ;
865
866field: // CFA, tuple field selector
867 field_name
868 | FLOATING_DECIMALconstant field
869 { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), maybeMoveBuild( $2 ) ) ); }
870 | FLOATING_DECIMALconstant '[' field_name_list ']'
871 { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), build_tuple( yylloc, $3 ) ) ); }
872 | field_name '.' field
873 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
874 | field_name '.' '[' field_name_list ']'
875 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
876 | field_name ARROW field
877 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
878 | field_name ARROW '[' field_name_list ']'
879 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
880 ;
881
882field_name:
883 INTEGERconstant fraction_constants_opt
884 { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_constantInteger( yylloc, *$1 ), $2 ) ); }
885 | FLOATINGconstant fraction_constants_opt
886 { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_field_name_FLOATINGconstant( yylloc, *$1 ), $2 ) ); }
887 | identifier_at fraction_constants_opt // CFA, allow anonymous fields
888 {
889 $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_varref( yylloc, $1 ), $2 ) );
890 }
891 ;
892
893fraction_constants_opt:
894 // empty
895 { $$ = nullptr; }
896 | fraction_constants_opt FLOATING_FRACTIONconstant
897 {
898 ast::Expr * constant = build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 );
899 $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( yylloc, $1, constant ) ) : new ExpressionNode( constant );
900 }
901 ;
902
903unary_expression:
904 postfix_expression
905 // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
906 // semantics checks, e.g., ++3, 3--, *3, &&3
907 | constant
908 | string_literal
909 { $$ = $1; }
910 | EXTENSION cast_expression // GCC
911 { $$ = $2->set_extension( true ); }
912 // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
913 // { * X; } // dereference X
914 // { * int X; } // CFA declaration of pointer to int
915 | ptrref_operator cast_expression // CFA
916 {
917 switch ( $1 ) {
918 case OperKinds::AddressOf:
919 $$ = new ExpressionNode( new ast::AddressExpr( maybeMoveBuild( $2 ) ) );
920 break;
921 case OperKinds::PointTo:
922 $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) );
923 break;
924 case OperKinds::And:
925 $$ = new ExpressionNode( new ast::AddressExpr( new ast::AddressExpr( maybeMoveBuild( $2 ) ) ) );
926 break;
927 default:
928 assert( false );
929 }
930 }
931 | unary_operator cast_expression
932 { $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) ); }
933 | ICR unary_expression
934 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Incr, $2 ) ); }
935 | DECR unary_expression
936 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Decr, $2 ) ); }
937 | SIZEOF unary_expression
938 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, new ast::TypeofType( maybeMoveBuild( $2 ) ) ) ); }
939 | SIZEOF '(' type_no_function ')'
940 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
941 | SIZEOF '(' attribute_list type_no_function ')'
942 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $4->addQualifiers( $3 ) ) ) ); }
943 | ALIGNOF unary_expression // GCC, variable alignment
944 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, new ast::TypeofType( maybeMoveBuild( $2 ) ) ) ); }
945 | ALIGNOF '(' type_no_function ')' // GCC, type alignment
946 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
947
948 // Cannot use rule "type", which includes cfa_abstract_function, for sizeof/alignof, because of S/R problems on
949 // look ahead, so the cfa_abstract_function is factored out.
950 | SIZEOF '(' cfa_abstract_function ')'
951 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
952 | ALIGNOF '(' cfa_abstract_function ')' // GCC, type alignment
953 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
954
955 | OFFSETOF '(' type_no_function ',' identifier ')'
956 { $$ = new ExpressionNode( build_offsetOf( yylloc, $3, build_varref( yylloc, $5 ) ) ); }
957 | TYPEID '(' type ')'
958 {
959 SemanticError( yylloc, "typeid name is currently unimplemented." ); $$ = nullptr;
960 // $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) );
961 }
962 | COUNTOF unary_expression
963 { $$ = new ExpressionNode( new ast::CountofExpr( yylloc, new ast::TypeofType( maybeMoveBuild( $2 ) ) ) ); }
964 | COUNTOF '(' type_no_function ')'
965 { $$ = new ExpressionNode( new ast::CountofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
966 ;
967
968ptrref_operator:
969 '*' { $$ = OperKinds::PointTo; }
970 | '&' { $$ = OperKinds::AddressOf; }
971 // GCC, address of label must be handled by semantic check for ref,ref,label
972 | ANDAND { $$ = OperKinds::And; }
973 ;
974
975unary_operator:
976 '+' { $$ = OperKinds::UnPlus; }
977 | '-' { $$ = OperKinds::UnMinus; }
978 | '!' { $$ = OperKinds::Neg; }
979 | '~' { $$ = OperKinds::BitNeg; }
980 ;
981
982cast_expression:
983 unary_expression
984 | '(' type_no_function ')' cast_expression
985 { $$ = new ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
986 | '(' aggregate_control '&' ')' cast_expression // CFA
987 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
988 | '(' aggregate_control '*' ')' cast_expression // CFA
989 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
990 | '(' VIRTUAL ')' cast_expression // CFA
991 { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $4 ), nullptr ) ); }
992 | '(' VIRTUAL type_no_function ')' cast_expression // CFA
993 { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $5 ), maybeMoveBuildType( $3 ) ) ); }
994 | '(' RETURN type_no_function ')' cast_expression // CFA (ASCRIPTION)
995 { $$ = new ExpressionNode( build_cast( yylloc, $3, $5, ast::ReturnCast ) ); }
996 | '(' COERCE type_no_function ')' cast_expression // CFA (COERCION)
997 { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
998 | '(' qualifier_cast_list ')' cast_expression // CFA, (modify CVs of cast_expression)
999 { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
1000// | '(' type_no_function ')' tuple
1001// { $$ = new ast::ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
1002 ;
1003
1004qualifier_cast_list:
1005 cast_modifier type_qualifier_name
1006 | cast_modifier MUTEX
1007 | qualifier_cast_list cast_modifier type_qualifier_name
1008 | qualifier_cast_list cast_modifier MUTEX
1009 ;
1010
1011cast_modifier:
1012 '-'
1013 | '+'
1014 ;
1015
1016exponential_expression:
1017 cast_expression
1018 | exponential_expression '\\' cast_expression
1019 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Exp, $1, $3 ) ); }
1020 ;
1021
1022multiplicative_expression:
1023 exponential_expression
1024 | multiplicative_expression '*' exponential_expression
1025 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mul, $1, $3 ) ); }
1026 | multiplicative_expression '/' exponential_expression
1027 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Div, $1, $3 ) ); }
1028 | multiplicative_expression '%' exponential_expression
1029 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mod, $1, $3 ) ); }
1030 ;
1031
1032additive_expression:
1033 multiplicative_expression
1034 | additive_expression '+' multiplicative_expression
1035 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Plus, $1, $3 ) ); }
1036 | additive_expression '-' multiplicative_expression
1037 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Minus, $1, $3 ) ); }
1038 ;
1039
1040shift_expression:
1041 additive_expression
1042 | shift_expression LS additive_expression
1043 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LShift, $1, $3 ) ); }
1044 | shift_expression RS additive_expression
1045 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::RShift, $1, $3 ) ); }
1046 ;
1047
1048relational_expression:
1049 shift_expression
1050 | relational_expression '<' shift_expression
1051 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LThan, $1, $3 ) ); }
1052 | relational_expression '>' shift_expression
1053 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GThan, $1, $3 ) ); }
1054 | relational_expression LE shift_expression
1055 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LEThan, $1, $3 ) ); }
1056 | relational_expression GE shift_expression
1057 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GEThan, $1, $3 ) ); }
1058 ;
1059
1060equality_expression:
1061 relational_expression
1062 | equality_expression EQ relational_expression
1063 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Eq, $1, $3 ) ); }
1064 | equality_expression NE relational_expression
1065 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Neq, $1, $3 ) ); }
1066 ;
1067
1068AND_expression:
1069 equality_expression
1070 | AND_expression '&' equality_expression
1071 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitAnd, $1, $3 ) ); }
1072 ;
1073
1074exclusive_OR_expression:
1075 AND_expression
1076 | exclusive_OR_expression '^' AND_expression
1077 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Xor, $1, $3 ) ); }
1078 ;
1079
1080inclusive_OR_expression:
1081 exclusive_OR_expression
1082 | inclusive_OR_expression '|' exclusive_OR_expression
1083 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitOr, $1, $3 ) ); }
1084 ;
1085
1086logical_AND_expression:
1087 inclusive_OR_expression
1088 | logical_AND_expression ANDAND inclusive_OR_expression
1089 { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::AndExpr ) ); }
1090 ;
1091
1092logical_OR_expression:
1093 logical_AND_expression
1094 | logical_OR_expression OROR logical_AND_expression
1095 { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::OrExpr ) ); }
1096 ;
1097
1098conditional_expression:
1099 logical_OR_expression
1100 | logical_OR_expression '?' comma_expression ':' conditional_expression
1101 { $$ = new ExpressionNode( build_cond( yylloc, $1, $3, $5 ) ); }
1102 | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
1103 { $$ = new ExpressionNode( build_cond( yylloc, $1, nullptr, $4 ) ); }
1104 ;
1105
1106constant_expression:
1107 conditional_expression
1108 ;
1109
1110argument_expression_list_opt:
1111 // empty
1112 { $$ = nullptr; }
1113 | argument_expression_list
1114 ;
1115
1116argument_expression_list:
1117 argument_expression
1118 // | argument_expression_list_opt ',' argument_expression // CFA, allow empty argument
1119 | argument_expression_list ',' argument_expression // no empty argument
1120 { $$ = $1->set_last( $3 ); }
1121 ;
1122
1123argument_expression:
1124 '?' // CFA, default parameter
1125 // { SemanticError( yylloc, "Argument to default parameter is currently unimplemented." ); $$ = nullptr; }
1126 { $$ = new ExpressionNode( build_constantInteger( yylloc, *new string( "2" ) ) ); }
1127 | '?' identifier '=' assignment_expression // CFA, keyword argument
1128 // { SemanticError( yylloc, "keyword argument is currently unimplemented." ); $$ = nullptr; }
1129 { $$ = $4; }
1130 | assignment_expression
1131 ;
1132
1133assignment_expression:
1134 // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
1135 conditional_expression
1136 | unary_expression assignment_operator assignment_expression
1137 {
1138// if ( $2 == OperKinds::AtAssn ) {
1139// SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
1140// } else {
1141 $$ = new ExpressionNode( build_binary_val( yylloc, $2, $1, $3 ) );
1142// } // if
1143 }
1144 | unary_expression '=' '{' initializer_list_opt comma_opt '}'
1145 { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
1146 ;
1147
1148assignment_expression_opt:
1149 // empty
1150 { $$ = nullptr; }
1151 | assignment_expression
1152 ;
1153
1154assignment_operator:
1155 simple_assignment_operator
1156 | compound_assignment_operator
1157 ;
1158
1159simple_assignment_operator:
1160 '=' { $$ = OperKinds::Assign; }
1161 | ATassign { $$ = OperKinds::AtAssn; } // CFA
1162 ;
1163
1164compound_assignment_operator:
1165 EXPassign { $$ = OperKinds::ExpAssn; }
1166 | MULTassign { $$ = OperKinds::MulAssn; }
1167 | DIVassign { $$ = OperKinds::DivAssn; }
1168 | MODassign { $$ = OperKinds::ModAssn; }
1169 | PLUSassign { $$ = OperKinds::PlusAssn; }
1170 | MINUSassign { $$ = OperKinds::MinusAssn; }
1171 | LSassign { $$ = OperKinds::LSAssn; }
1172 | RSassign { $$ = OperKinds::RSAssn; }
1173 | ANDassign { $$ = OperKinds::AndAssn; }
1174 | ERassign { $$ = OperKinds::ERAssn; }
1175 | ORassign { $$ = OperKinds::OrAssn; }
1176 ;
1177
1178tuple: // CFA, tuple
1179 // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
1180 // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
1181 '[' ',' ']'
1182 // { $$ = new ExpressionNode( build_tuple( yylloc, nullptr ) ); }
1183 { SemanticError( yylloc, "Empty tuple is meaningless." ); $$ = nullptr; }
1184 | '[' assignment_expression ',' ']'
1185 { $$ = new ExpressionNode( build_tuple( yylloc, $2 ) ); }
1186 | '[' '@' comma_opt ']'
1187 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1188 | '[' assignment_expression ',' tuple_expression_list comma_opt ']'
1189 { $$ = new ExpressionNode( build_tuple( yylloc, $2->set_last( $4 ) ) ); }
1190 | '[' '@' ',' tuple_expression_list comma_opt ']'
1191 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1192 ;
1193
1194tuple_expression_list:
1195 assignment_expression
1196 | '@' // CFA
1197 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1198 | tuple_expression_list ',' assignment_expression
1199 { $$ = $1->set_last( $3 ); }
1200 | tuple_expression_list ',' '@'
1201 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1202 ;
1203
1204comma_expression:
1205 assignment_expression
1206 | comma_expression ',' assignment_expression
1207 { $$ = new ExpressionNode( new ast::CommaExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1208 ;
1209
1210comma_expression_opt:
1211 // empty
1212 { $$ = nullptr; }
1213 | comma_expression
1214 ;
1215
1216// ************************** STATEMENTS *******************************
1217
1218statement:
1219 labelled_statement
1220 | compound_statement
1221 | expression_statement
1222 | selection_statement
1223 | iteration_statement
1224 | jump_statement
1225 | with_statement
1226 | mutex_statement
1227 | waitfor_statement
1228 | waituntil_statement
1229 | corun_statement
1230 | cofor_statement
1231 | exception_statement
1232 | enable_disable_statement
1233 { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1234 | asm_statement
1235 | DIRECTIVE
1236 { $$ = new StatementNode( build_directive( yylloc, $1 ) ); }
1237 ;
1238
1239labelled_statement:
1240 // labels cannot be identifiers 0 or 1
1241 identifier_or_type_name ':' attribute_list_opt statement
1242 { $$ = $4->add_label( yylloc, $1, $3 ); }
1243 | identifier_or_type_name ':' attribute_list_opt error // invalid syntax rule
1244 {
1245 SemanticError( yylloc, "syntx error, label \"%s\" must be associated with a statement, "
1246 "where a declaration, case, or default is not a statement.\n"
1247 "Move the label or terminate with a semicolon.", $1.str->c_str() );
1248 $$ = nullptr;
1249 }
1250 ;
1251
1252compound_statement:
1253 '{' '}'
1254 { $$ = new StatementNode( build_compound( yylloc, (StatementNode *)0 ) ); }
1255 | '{' push
1256 local_label_declaration_opt // GCC, local labels appear at start of block
1257 statement_decl_list // C99, intermix declarations and statements
1258 pop '}'
1259 { $$ = new StatementNode( build_compound( yylloc, $4 ) ); }
1260 ;
1261
1262statement_decl_list: // C99
1263 statement_decl
1264 | statement_decl_list statement_decl
1265 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1266 ;
1267
1268statement_decl:
1269 attribute_list_opt declaration // CFA, new & old style declarations
1270 { distAttr( $1, $2 ); $$ = new StatementNode( $2 ); }
1271 | attribute_list_opt EXTENSION declaration // GCC
1272 { distAttr( $1, $3 ); distExt( $3 ); $$ = new StatementNode( $3 ); }
1273 | attribute_list_opt function_definition
1274 { distAttr( $1, $2 ); $$ = new StatementNode( $2 ); }
1275 | attribute_list_opt EXTENSION function_definition // GCC
1276 { distAttr( $1, $3 ); distExt( $3 ); $$ = new StatementNode( $3 ); }
1277 | attribute_list_opt statement // FIX ME!
1278 { $$ = $2->addQualifiers( $1 ); }
1279 ;
1280
1281statement_list_nodecl:
1282 attribute_list_opt statement
1283 { $$ = $2->addQualifiers( $1 ); } // FIX ME!
1284 | statement_list_nodecl attribute_list_opt statement
1285 { assert( $1 ); $1->set_last( $3->addQualifiers( $2 ) ); $$ = $1; } // FIX ME!
1286 | statement_list_nodecl error // invalid syntax rule
1287 { SemanticError( yylloc, "illegal syntax, declarations only allowed at the start of the switch body,"
1288 " i.e., after the '{'." ); $$ = nullptr; }
1289 ;
1290
1291expression_statement: // expression or null statement
1292 comma_expression_opt ';'
1293 { $$ = new StatementNode( build_expr( yylloc, $1 ) ); }
1294 ;
1295
1296// "if", "switch", and "choose" require parenthesis around the conditional. See the following ambiguities without
1297// parenthesis:
1298//
1299// if x + y + z; => if ( x ) + y + z or if ( x + y ) + z
1300//
1301// switch O { }
1302//
1303// O{} => object-constructor for conditional, switch body ???
1304// O{} => O for conditional followed by switch body
1305//
1306// C++ has this problem, as it has the same constructor syntax.
1307//
1308// switch sizeof ( T ) { }
1309//
1310// sizeof ( T ) => sizeof of T for conditional followed by switch body
1311// sizeof ( T ) => sizeof of compound literal (T){ }, closing parenthesis ???
1312//
1313// Note the two grammar rules for sizeof (alignof)
1314//
1315// | SIZEOF unary_expression
1316// | SIZEOF '(' type_no_function ')'
1317//
1318// where the first DOES NOT require parenthesis! And C++ inherits this problem from C.
1319
1320selection_statement:
1321 IF '(' conditional_declaration ')' statement %prec THEN
1322 // explicitly deal with the shift/reduce conflict on if/else
1323 { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), nullptr ) ); }
1324 | IF '(' conditional_declaration ')' statement ELSE statement
1325 { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), maybe_build_compound( yylloc, $7 ) ) ); }
1326 | SWITCH '(' comma_expression ')' case_clause
1327 { $$ = new StatementNode( build_switch( yylloc, true, $3, $5 ) ); }
1328 | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1329 {
1330 StatementNode *sw = new StatementNode( build_switch( yylloc, true, $3, $8 ) );
1331 // The semantics of the declaration list is changed to include associated initialization, which is performed
1332 // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1333 // statement around the switch. Statements after the initial declaration list can never be executed, and
1334 // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1335 // statement.
1336 $$ = $7 ? new StatementNode( build_compound( yylloc, (new StatementNode( $7 ))->set_last( sw ) ) ) : sw;
1337 }
1338 | SWITCH '(' comma_expression ')' '{' error '}' // CFA, invalid syntax rule error
1339 { SemanticError( yylloc, "synatx error, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1340 | CHOOSE '(' comma_expression ')' case_clause // CFA
1341 { $$ = new StatementNode( build_switch( yylloc, false, $3, $5 ) ); }
1342 | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1343 {
1344 StatementNode *sw = new StatementNode( build_switch( yylloc, false, $3, $8 ) );
1345 $$ = $7 ? new StatementNode( build_compound( yylloc, (new StatementNode( $7 ))->set_last( sw ) ) ) : sw;
1346 }
1347 | CHOOSE '(' comma_expression ')' '{' error '}' // CFA, invalid syntax rule
1348 { SemanticError( yylloc, "illegal syntax, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1349 ;
1350
1351conditional_declaration:
1352 comma_expression
1353 { $$ = new CondCtrl( nullptr, $1 ); }
1354 | c_declaration // no semi-colon
1355 { $$ = new CondCtrl( $1, nullptr ); }
1356 | cfa_declaration // no semi-colon
1357 { $$ = new CondCtrl( $1, nullptr ); }
1358 | declaration comma_expression // semi-colon separated
1359 { $$ = new CondCtrl( $1, $2 ); }
1360 ;
1361
1362// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1363// clause allows a list of values and subranges.
1364
1365case_value: // CFA
1366 constant_expression { $$ = $1; }
1367 | constant_expression ELLIPSIS constant_expression // GCC, subrange
1368 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1369 | subrange // CFA, subrange
1370 ;
1371
1372case_value_list: // CFA
1373 case_value { $$ = new ClauseNode( build_case( yylloc, $1 ) ); }
1374 // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1375 | case_value_list ',' case_value { $$ = $1->set_last( new ClauseNode( build_case( yylloc, $3 ) ) ); }
1376 ;
1377
1378case_label: // CFA
1379 CASE error // invalid syntax rule
1380 { SemanticError( yylloc, "illegal syntax, case list missing after case." ); $$ = nullptr; }
1381 | CASE case_value_list ':' { $$ = $2; }
1382 | CASE case_value_list error // invalid syntax rule
1383 { SemanticError( yylloc, "illegal syntax, colon missing after case list." ); $$ = nullptr; }
1384 | DEFAULT ':' { $$ = new ClauseNode( build_default( yylloc ) ); }
1385 // A semantic check is required to ensure only one default clause per switch/choose statement.
1386 | DEFAULT error // invalid syntax rule
1387 { SemanticError( yylloc, "illegal syntax, colon missing after default." ); $$ = nullptr; }
1388 ;
1389
1390case_label_list: // CFA
1391 case_label
1392 | case_label_list case_label { $$ = $1->set_last( $2 ); }
1393 ;
1394
1395case_clause: // CFA
1396 case_label_list statement { $$ = $1->append_last_case( maybe_build_compound( yylloc, $2 ) ); }
1397 ;
1398
1399switch_clause_list_opt: // CFA
1400 // empty
1401 { $$ = nullptr; }
1402 | switch_clause_list
1403 ;
1404
1405switch_clause_list: // CFA
1406 case_label_list statement_list_nodecl
1407 { $$ = $1->append_last_case( new StatementNode( build_compound( yylloc, $2 ) ) ); }
1408 | switch_clause_list case_label_list statement_list_nodecl
1409 { $$ = $1->set_last( $2->append_last_case( new StatementNode( build_compound( yylloc, $3 ) ) ) ); }
1410 ;
1411
1412iteration_statement:
1413 WHILE '(' ')' statement %prec THEN // CFA => while ( 1 )
1414 { $$ = new StatementNode( build_while( yylloc, new CondCtrl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) ); }
1415 | WHILE '(' ')' statement ELSE statement // CFA
1416 {
1417 $$ = new StatementNode( build_while( yylloc, new CondCtrl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) );
1418 SemanticWarning( yylloc, Warning::SuperfluousElse );
1419 }
1420 | WHILE '(' conditional_declaration ')' statement %prec THEN
1421 { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1422 | WHILE '(' conditional_declaration ')' statement ELSE statement // CFA
1423 { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1424 | DO statement WHILE '(' ')' ';' // CFA => do while( 1 )
1425 { $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) ); }
1426 | DO statement WHILE '(' ')' ELSE statement // CFA
1427 {
1428 $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) );
1429 SemanticWarning( yylloc, Warning::SuperfluousElse );
1430 }
1431 | DO statement WHILE '(' comma_expression ')' ';'
1432 { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ) ) ); }
1433 | DO statement WHILE '(' comma_expression ')' ELSE statement // CFA
1434 { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ), $8 ) ); }
1435 | FOR '(' ')' statement %prec THEN // CFA => for ( ;; )
1436 { $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) ); }
1437 | FOR '(' ')' statement ELSE statement // CFA
1438 {
1439 $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) );
1440 SemanticWarning( yylloc, Warning::SuperfluousElse );
1441 }
1442 | FOR '(' for_control_expression_list ')' statement %prec THEN
1443 { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1444 | FOR '(' for_control_expression_list ')' statement ELSE statement // CFA
1445 { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1446 ;
1447
1448for_control_expression_list:
1449 for_control_expression
1450 | for_control_expression_list ':' for_control_expression
1451 // ForCtrl + ForCtrl:
1452 // init + init => multiple declaration statements that are hoisted
1453 // condition + condition => (expression) && (expression)
1454 // change + change => (expression), (expression)
1455 {
1456 $1->init->set_last( $3->init );
1457 if ( $1->condition ) {
1458 if ( $3->condition ) {
1459 $1->condition->expr.reset( new ast::LogicalExpr( yylloc, $1->condition->expr.release(), $3->condition->expr.release(), ast::AndExpr ) );
1460 } // if
1461 } else $1->condition = $3->condition;
1462 if ( $1->change ) {
1463 if ( $3->change ) {
1464 $1->change->expr.reset( new ast::CommaExpr( yylloc, $1->change->expr.release(), $3->change->expr.release() ) );
1465 } // if
1466 } else $1->change = $3->change;
1467 $$ = $1;
1468 }
1469 ;
1470
1471for_control_expression:
1472 ';' comma_expression_opt ';' comma_expression_opt
1473 { $$ = new ForCtrl( nullptr, $2, $4 ); }
1474 | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1475 {
1476 $$ = new ForCtrl( $1 ? new StatementNode( new ast::ExprStmt( yylloc, maybeMoveBuild( $1 ) ) ) : nullptr, $3, $5 );
1477 }
1478 | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1479 { $$ = new ForCtrl( new StatementNode( $1 ), $2, $4 ); }
1480
1481 | '@' ';' comma_expression // CFA, empty loop-index
1482 { $$ = new ForCtrl( nullptr, $3, nullptr ); }
1483 | '@' ';' comma_expression ';' comma_expression // CFA, empty loop-index
1484 { $$ = new ForCtrl( nullptr, $3, $5 ); }
1485
1486 | comma_expression // CFA, anonymous loop-index
1487 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), NEW_ZERO, OperKinds::LThan, $1->clone(), NEW_ONE ); }
1488 | updown comma_expression // CFA, anonymous loop-index
1489 { $$ = forCtrl( yylloc, $2, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $1, NEW_ZERO, $2->clone() ), $1, UPDOWN( $1, $2->clone(), NEW_ZERO ), NEW_ONE ); }
1490
1491 | comma_expression updownS comma_expression // CFA, anonymous loop-index
1492 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), NEW_ONE ); }
1493 | '@' updownS comma_expression // CFA, anonymous loop-index
1494 {
1495 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1496 else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, NEW_ONE );
1497 }
1498 | comma_expression updownS '@' // CFA, anonymous loop-index
1499 {
1500 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1501 else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1502 }
1503
1504 | comma_expression updownS comma_expression '~' comma_expression // CFA, anonymous loop-index
1505 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), $5 ); }
1506 | '@' updownS comma_expression '~' comma_expression // CFA, anonymous loop-index
1507 {
1508 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1509 else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, $5 );
1510 }
1511 | comma_expression updownS '@' '~' comma_expression // CFA, anonymous loop-index
1512 {
1513 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1514 else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1515 }
1516 | comma_expression updownS comma_expression '~' '@' // CFA, invalid syntax rule
1517 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1518 | '@' updownS '@' // CFA, invalid syntax rule
1519 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1520 | '@' updownS comma_expression '~' '@' // CFA, invalid syntax rule
1521 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1522 | comma_expression updownS '@' '~' '@' // CFA, invalid syntax rule
1523 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1524 | '@' updownS '@' '~' '@' // CFA, invalid syntax rule
1525 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1526
1527 // These rules accept a comma_expression for the initialization, when only an identifier is correct. Being
1528 // permissive allows for a better error message from forCtrl.
1529 | comma_expression ';' comma_expression // CFA
1530 { $$ = forCtrl( yylloc, $3, $1, NEW_ZERO, OperKinds::LThan, $3->clone(), NEW_ONE ); }
1531 | comma_expression ';' updown comma_expression // CFA
1532 { $$ = forCtrl( yylloc, $4, $1, UPDOWN( $3, NEW_ZERO, $4->clone() ), $3, UPDOWN( $3, $4->clone(), NEW_ZERO ), NEW_ONE ); }
1533
1534 | comma_expression ';' comma_expression updownS comma_expression // CFA
1535 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), NEW_ONE ); }
1536 | comma_expression ';' '@' updownS comma_expression // CFA
1537 {
1538 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1539 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, NEW_ONE );
1540 }
1541 | comma_expression ';' comma_expression updownS '@' // CFA
1542 {
1543 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1544 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1545 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, NEW_ONE );
1546 }
1547 | comma_expression ';' '@' updownS '@' // CFA, invalid syntax rule
1548 { SemanticError( yylloc, "illegal syntax, missing low/high value for ascending/descending range so index is uninitialized." ); $$ = nullptr; }
1549
1550 | comma_expression ';' comma_expression updownEq comma_expression // CFA
1551 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), NEW_ONE ); }
1552
1553 | comma_expression ';' comma_expression updownS comma_expression '~' comma_expression // CFA
1554 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), $7 ); }
1555 | comma_expression ';' '@' updownS comma_expression '~' comma_expression // CFA, invalid syntax rule
1556 {
1557 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1558 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, $7 );
1559 }
1560 | comma_expression ';' comma_expression updownS '@' '~' comma_expression // CFA
1561 {
1562 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1563 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1564 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, $7 );
1565 }
1566 | comma_expression ';' comma_expression updownS comma_expression '~' '@' // CFA
1567 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), nullptr ); }
1568 | comma_expression ';' '@' updownS comma_expression '~' '@' // CFA, invalid syntax rule
1569 {
1570 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1571 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, nullptr );
1572 }
1573 | comma_expression ';' comma_expression updownS '@' '~' '@' // CFA
1574 {
1575 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1576 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1577 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, nullptr );
1578 }
1579 | comma_expression ';' '@' updownS '@' '~' '@' // CFA
1580 { SemanticError( yylloc, "illegal syntax, missing low/high value for ascending/descending range so index is uninitialized." ); $$ = nullptr; }
1581
1582 | declaration comma_expression // CFA
1583 { $$ = forCtrl( yylloc, $1, NEW_ZERO, OperKinds::LThan, $2, NEW_ONE ); }
1584 | declaration updown comma_expression // CFA
1585 { $$ = forCtrl( yylloc, $1, UPDOWN( $2, NEW_ZERO, $3 ), $2, UPDOWN( $2, $3->clone(), NEW_ZERO ), NEW_ONE ); }
1586
1587 | declaration comma_expression updownS comma_expression // CFA
1588 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2->clone(), $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), NEW_ONE ); }
1589 | declaration '@' updownS comma_expression // CFA
1590 {
1591 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1592 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, NEW_ONE );
1593 }
1594 | declaration comma_expression updownS '@' // CFA
1595 {
1596 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1597 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1598 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, NEW_ONE );
1599 }
1600
1601 | declaration comma_expression updownEq comma_expression // CFA
1602 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2->clone(), $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), NEW_ONE ); }
1603
1604 | declaration comma_expression updownS comma_expression '~' comma_expression // CFA
1605 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), $6 ); }
1606 | declaration '@' updownS comma_expression '~' comma_expression // CFA
1607 {
1608 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1609 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, $6 );
1610 }
1611 | declaration comma_expression updownS '@' '~' comma_expression // CFA
1612 {
1613 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1614 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1615 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, $6 );
1616 }
1617 | declaration comma_expression updownS comma_expression '~' '@' // CFA
1618 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), nullptr ); }
1619 | declaration '@' updownS comma_expression '~' '@' // CFA
1620 {
1621 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1622 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, nullptr );
1623 }
1624 | declaration comma_expression updownS '@' '~' '@' // CFA
1625 {
1626 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1627 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1628 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, nullptr );
1629 }
1630 | declaration '@' updownS '@' '~' '@' // CFA, invalid syntax rule
1631 { SemanticError( yylloc, "illegal syntax, missing low/high value for ascending/descending range so index is uninitialized." ); $$ = nullptr; }
1632
1633 | comma_expression ';' type_type_specifier // CFA, enum type
1634 {
1635 $$ = enumRangeCtrl( $1, OperKinds::LEThan, new ExpressionNode( new ast::TypeExpr( yylloc, $3->clone()->buildType() ) ), $3 );
1636 }
1637 | comma_expression ';' updown enum_key // CFA, enum type, reverse direction
1638 {
1639 if ( $3 == OperKinds::GThan ) {
1640 SemanticError( yylloc, "all enumeration ranges are equal (all values). Add an equal, e.g., ~=, -~=." ); $$ = nullptr;
1641 $3 = OperKinds::GEThan;
1642 } // if
1643 $$ = enumRangeCtrl( $1, $3, new ExpressionNode( new ast::TypeExpr( yylloc, $4->clone()->buildType() ) ), $4 );
1644 }
1645 ;
1646
1647enum_key:
1648 type_name
1649 {
1650 typedefTable.makeTypedef( *$1->symbolic.name, "enum_type_nobody 1" );
1651 $$ = DeclarationNode::newEnum( $1->symbolic.name, nullptr, false, false );
1652 }
1653 | ENUM identifier
1654 {
1655 typedefTable.makeTypedef( *$2, "enum_type_nobody 2" );
1656 $$ = DeclarationNode::newEnum( $2, nullptr, false, false );
1657 }
1658 | ENUM type_name
1659 {
1660 typedefTable.makeTypedef( *$2->symbolic.name, "enum_type_nobody 3" );
1661 $$ = DeclarationNode::newEnum( $2->symbolic.name, nullptr, false, false );
1662 }
1663 ;
1664
1665// This rule exists to handle the ambiguity with unary operator '~'. The rule is the same as updownS minus the '~'.
1666// Specifically, "for ( ~5 )" means the complement of 5, not loop 0..4. Hence, in this case "for ( ~= 5 )", i.e., 0..5,
1667// it is not possible to just remove the '='. The entire '~=' must be removed.
1668updown:
1669 ErangeUpLt
1670 { $$ = OperKinds::LThan; }
1671 | ErangeDownGt
1672 { $$ = OperKinds::GThan; }
1673 | ErangeUpLe
1674 { $$ = OperKinds::LEThan; }
1675 | ErangeDownGe
1676 { $$ = OperKinds::GEThan; }
1677 ;
1678
1679updownS:
1680 '~' // shorthand 0 ~ 10 => 0 +~ 10
1681 { $$ = OperKinds::LThan; }
1682 | updown
1683 ;
1684
1685updownEq:
1686 ErangeEq
1687 { $$ = OperKinds::Eq; }
1688 | ErangeNe
1689 { $$ = OperKinds::Neq; }
1690 | ErangeDownEq
1691 { $$ = OperKinds::Eq; }
1692 | ErangeDownNe
1693 { $$ = OperKinds::Neq; }
1694 ;
1695
1696jump_statement:
1697 GOTO identifier_or_type_name ';'
1698 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Goto ) ); }
1699 | GOTO '*' comma_expression ';' // GCC, computed goto
1700 // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1701 // whereas normal operator precedence yields goto (*i)+3;
1702 { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1703 // A semantic check is required to ensure fallthrough appears only in the body of a choose statement.
1704 | FALLTHROUGH ';' // CFA
1705 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThrough ) ); }
1706 | FALLTHROUGH identifier_or_type_name ';' // CFA
1707 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::FallThrough ) ); }
1708 | FALLTHROUGH DEFAULT ';' // CFA
1709 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThroughDefault ) ); }
1710 | CONTINUE ';'
1711 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1712 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Continue ) ); }
1713 | CONTINUE identifier_or_type_name ';' // CFA, multi-level continue
1714 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1715 // the target of the transfer appears only at the start of an iteration statement.
1716 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Continue ) ); }
1717 | BREAK ';'
1718 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1719 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Break ) ); }
1720 | BREAK identifier_or_type_name ';' // CFA, multi-level exit
1721 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1722 // the target of the transfer appears only at the start of an iteration statement.
1723 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Break ) ); }
1724 | RETURN comma_expression_opt ';'
1725 { $$ = new StatementNode( build_return( yylloc, $2 ) ); }
1726 | RETURN '{' initializer_list_opt comma_opt '}' ';'
1727 { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1728 | SUSPEND ';'
1729 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::None ) ); }
1730 | SUSPEND compound_statement
1731 { $$ = new StatementNode( build_suspend( yylloc, $2, ast::SuspendStmt::None ) ); }
1732 | SUSPEND COROUTINE ';'
1733 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Coroutine ) ); }
1734 | SUSPEND COROUTINE compound_statement
1735 { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Coroutine ) ); }
1736 | SUSPEND GENERATOR ';'
1737 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Generator ) ); }
1738 | SUSPEND GENERATOR compound_statement
1739 { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Generator ) ); }
1740 | THROW assignment_expression_opt ';' // handles rethrow
1741 { $$ = new StatementNode( build_throw( yylloc, $2 ) ); }
1742 | THROWRESUME assignment_expression_opt ';' // handles reresume
1743 { $$ = new StatementNode( build_resume( yylloc, $2 ) ); }
1744 | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1745 { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1746 ;
1747
1748with_statement:
1749 WITH '(' type_list ')' statement // support scoped enumeration
1750 { $$ = new StatementNode( build_with( yylloc, $3, $5 ) ); }
1751 ;
1752
1753// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so possibly change syntax to "with mutex".
1754mutex_statement:
1755 MUTEX '(' argument_expression_list_opt ')' statement
1756 {
1757 if ( ! $3 ) { SemanticError( yylloc, "illegal syntax, mutex argument list cannot be empty." ); $$ = nullptr; }
1758 $$ = new StatementNode( build_mutex( yylloc, $3, $5 ) );
1759 }
1760 ;
1761
1762when_clause:
1763 WHEN '(' comma_expression ')' { $$ = $3; }
1764 ;
1765
1766when_clause_opt:
1767 // empty
1768 { $$ = nullptr; }
1769 | when_clause
1770 ;
1771
1772cast_expression_list:
1773 cast_expression
1774 | cast_expression_list ',' cast_expression
1775 { SemanticError( yylloc, "List of mutex member is currently unimplemented." ); $$ = nullptr; }
1776 ;
1777
1778timeout:
1779 TIMEOUT '(' comma_expression ')' { $$ = $3; }
1780 ;
1781
1782wor:
1783 OROR
1784 | WOR
1785
1786waitfor:
1787 WAITFOR '(' cast_expression ')'
1788 { $$ = $3; }
1789 | WAITFOR '(' cast_expression_list ':' argument_expression_list_opt ')'
1790 { $$ = $3->set_last( $5 ); }
1791 ;
1792
1793wor_waitfor_clause:
1794 when_clause_opt waitfor statement %prec THEN
1795 // Called first: create header for WaitForStmt.
1796 { $$ = build_waitfor( yylloc, new ast::WaitForStmt( yylloc ), $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1797 | wor_waitfor_clause wor when_clause_opt waitfor statement
1798 { $$ = build_waitfor( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1799 | wor_waitfor_clause wor when_clause_opt ELSE statement
1800 { $$ = build_waitfor_else( yylloc, $1, $3, maybe_build_compound( yylloc, $5 ) ); }
1801 | wor_waitfor_clause wor when_clause_opt timeout statement %prec THEN
1802 { $$ = build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1803 // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1804 | wor_waitfor_clause wor when_clause_opt timeout statement wor ELSE statement // invalid syntax rule
1805 { SemanticError( yylloc, "illegal syntax, else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1806 | wor_waitfor_clause wor when_clause_opt timeout statement wor when_clause ELSE statement
1807 { $$ = build_waitfor_else( yylloc, build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ), $7, maybe_build_compound( yylloc, $9 ) ); }
1808 ;
1809
1810waitfor_statement:
1811 wor_waitfor_clause %prec THEN
1812 { $$ = new StatementNode( $1 ); }
1813 ;
1814
1815wand:
1816 ANDAND
1817 | WAND
1818 ;
1819
1820waituntil:
1821 WAITUNTIL '(' comma_expression ')'
1822 { $$ = $3; }
1823 ;
1824
1825waituntil_clause:
1826 when_clause_opt waituntil statement
1827 { $$ = build_waituntil_clause( yylloc, $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1828 | '(' wor_waituntil_clause ')'
1829 { $$ = $2; }
1830 ;
1831
1832wand_waituntil_clause:
1833 waituntil_clause %prec THEN
1834 { $$ = $1; }
1835 | waituntil_clause wand wand_waituntil_clause
1836 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::AND, $1, $3 ); }
1837 ;
1838
1839wor_waituntil_clause:
1840 wand_waituntil_clause
1841 { $$ = $1; }
1842 | wor_waituntil_clause wor wand_waituntil_clause
1843 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::OR, $1, $3 ); }
1844 | wor_waituntil_clause wor when_clause_opt ELSE statement
1845 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::LEFT_OR, $1, build_waituntil_else( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1846 ;
1847
1848waituntil_statement:
1849 wor_waituntil_clause %prec THEN
1850 { $$ = new StatementNode( build_waituntil_stmt( yylloc, $1 ) ); }
1851 ;
1852
1853corun_statement:
1854 CORUN statement
1855 { $$ = new StatementNode( build_corun( yylloc, $2 ) ); }
1856 ;
1857
1858cofor_statement:
1859 COFOR '(' for_control_expression_list ')' statement
1860 { $$ = new StatementNode( build_cofor( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1861 ;
1862
1863exception_statement:
1864 TRY compound_statement handler_clause %prec THEN
1865 { $$ = new StatementNode( build_try( yylloc, $2, $3, nullptr ) ); }
1866 | TRY compound_statement finally_clause
1867 { $$ = new StatementNode( build_try( yylloc, $2, nullptr, $3 ) ); }
1868 | TRY compound_statement handler_clause finally_clause
1869 { $$ = new StatementNode( build_try( yylloc, $2, $3, $4 ) ); }
1870 ;
1871
1872handler_clause:
1873 handler_key '(' exception_declaration handler_predicate_opt ')' compound_statement
1874 { $$ = new ClauseNode( build_catch( yylloc, $1, $3, $4, $6 ) ); }
1875 | handler_clause handler_key '(' exception_declaration handler_predicate_opt ')' compound_statement
1876 { $$ = $1->set_last( new ClauseNode( build_catch( yylloc, $2, $4, $5, $7 ) ) ); }
1877 ;
1878
1879handler_predicate_opt:
1880 // empty
1881 { $$ = nullptr; }
1882 | ';' conditional_expression { $$ = $2; }
1883 ;
1884
1885handler_key:
1886 CATCH { $$ = ast::Terminate; }
1887 | RECOVER { $$ = ast::Terminate; }
1888 | CATCHRESUME { $$ = ast::Resume; }
1889 | FIXUP { $$ = ast::Resume; }
1890 ;
1891
1892finally_clause:
1893 FINALLY compound_statement { $$ = new ClauseNode( build_finally( yylloc, $2 ) ); }
1894 ;
1895
1896exception_declaration:
1897 // No SUE declaration in parameter list.
1898 type_specifier_nobody
1899 | type_specifier_nobody declarator
1900 { $$ = $2->addType( $1 ); }
1901 | type_specifier_nobody variable_abstract_declarator
1902 { $$ = $2->addType( $1 ); }
1903 | cfa_abstract_declarator_tuple identifier // CFA
1904 { $$ = $1->addName( $2 ); }
1905 | cfa_abstract_declarator_tuple // CFA
1906 ;
1907
1908enable_disable_statement:
1909 enable_disable_key identifier_list compound_statement
1910 ;
1911
1912enable_disable_key:
1913 ENABLE
1914 | DISABLE
1915 ;
1916
1917asm_statement:
1918 ASM asm_volatile_opt '(' string_literal ')' ';'
1919 { $$ = new StatementNode( build_asm( yylloc, $2, $4, nullptr ) ); }
1920 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1921 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6 ) ); }
1922 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1923 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8 ) ); }
1924 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1925 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8, $10 ) ); }
1926 | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' asm_label_list ')' ';'
1927 { $$ = new StatementNode( build_asm( yylloc, $2, $5, nullptr, $8, $10, $12 ) ); }
1928 ;
1929
1930asm_volatile_opt: // GCC
1931 // empty
1932 { $$ = false; }
1933 | VOLATILE
1934 { $$ = true; }
1935 ;
1936
1937asm_operands_opt: // GCC
1938 // empty
1939 { $$ = nullptr; } // use default argument
1940 | asm_operands_list
1941 ;
1942
1943asm_operands_list: // GCC
1944 asm_operand
1945 | asm_operands_list ',' asm_operand
1946 { $$ = $1->set_last( $3 ); }
1947 ;
1948
1949asm_operand: // GCC
1950 string_literal '(' constant_expression ')'
1951 { $$ = new ExpressionNode( new ast::AsmExpr( yylloc, "", maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1952 | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1953 {
1954 $$ = new ExpressionNode( new ast::AsmExpr( yylloc, *$2.str, maybeMoveBuild( $4 ), maybeMoveBuild( $6 ) ) );
1955 delete $2.str;
1956 }
1957 ;
1958
1959asm_clobbers_list_opt: // GCC
1960 // empty
1961 { $$ = nullptr; } // use default argument
1962 | string_literal
1963 { $$ = $1; }
1964 | asm_clobbers_list_opt ',' string_literal
1965 { $$ = $1->set_last( $3 ); }
1966 ;
1967
1968asm_label_list:
1969 identifier_or_type_name
1970 { $$ = new LabelNode(); $$->labels.emplace_back( yylloc, *$1 ); delete $1; } // allocated by lexer
1971 | asm_label_list ',' identifier_or_type_name
1972 { $$ = $1; $1->labels.emplace_back( yylloc, *$3 ); delete $3; } // allocated by lexer
1973 ;
1974
1975// ****************************** DECLARATIONS *********************************
1976
1977declaration_list_opt: // used at beginning of switch statement
1978 // empty
1979 { $$ = nullptr; }
1980 | declaration_list
1981 ;
1982
1983declaration_list:
1984 attribute_list_opt declaration
1985 { $$ = $2->addQualifiers( $1 ); }
1986 | declaration_list declaration
1987 { $$ = $1->set_last( $2 ); }
1988 ;
1989
1990KR_parameter_list_opt: // used to declare parameter types in K&R style functions
1991 // empty
1992 { $$ = nullptr; }
1993 | KR_parameter_list
1994 ;
1995
1996KR_parameter_list:
1997 c_declaration ';'
1998 { $$ = $1; }
1999 | KR_parameter_list c_declaration ';'
2000 { $$ = $1->set_last( $2 ); }
2001 ;
2002
2003local_label_declaration_opt: // GCC, local label
2004 // empty
2005 | local_label_declaration_list
2006 ;
2007
2008local_label_declaration_list: // GCC, local label
2009 LABEL local_label_list ';'
2010 | local_label_declaration_list LABEL local_label_list ';'
2011 ;
2012
2013local_label_list: // GCC, local label
2014 identifier_or_type_name
2015 | local_label_list ',' identifier_or_type_name
2016 ;
2017
2018declaration: // old & new style declarations
2019 c_declaration ';'
2020 | cfa_declaration ';' // CFA
2021 | static_assert ';' // C11
2022 ;
2023
2024static_assert:
2025 STATICASSERT '(' constant_expression ',' string_literal ')' // C11
2026 { $$ = DeclarationNode::newStaticAssert( $3, maybeMoveBuild( $5 ) ); }
2027 | STATICASSERT '(' constant_expression ')' // CFA
2028 { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( yylloc, *new string( "\"\"" ) ) ); }
2029
2030// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
2031// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
2032// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
2033// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
2034// the declaration list (as in Pascal). ANSI C and the new CFA declarations may appear together in the same program
2035// block, but cannot be mixed within a specific declaration.
2036//
2037// CFA C
2038// [10] int x; int x[10]; // array of 10 integers
2039// [10] * char y; char *y[10]; // array of 10 pointers to char
2040
2041cfa_declaration: // CFA
2042 cfa_variable_declaration
2043 | cfa_typedef_declaration
2044 | cfa_function_declaration
2045 | type_declaring_list
2046 { SemanticError( yylloc, "otype declaration is currently unimplemented." ); $$ = nullptr; }
2047 | trait_specifier
2048 ;
2049
2050cfa_variable_declaration: // CFA
2051 cfa_variable_specifier initializer_opt
2052 { $$ = $1->addInitializer( $2 ); }
2053 | declaration_qualifier_list cfa_variable_specifier initializer_opt
2054 // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
2055 // them as a type_qualifier cannot appear in that context.
2056 { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
2057 | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
2058 { $$ = $1->set_last( $1->cloneType( $5 )->addInitializer( $6 ) ); }
2059 ;
2060
2061cfa_variable_specifier: // CFA
2062 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
2063 // storage-class
2064 cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
2065 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
2066 | cfa_abstract_tuple identifier_or_type_name asm_name_opt
2067 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
2068 | multi_array_dimension cfa_abstract_tuple identifier_or_type_name asm_name_opt
2069 { $$ = $2->addNewArray( $1 )->addName( $3 )->addAsmName( $4 ); }
2070 | multi_array_dimension type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
2071 { $$ = $3->addNewArray( $1 )->addQualifiers( $2 )->addName( $4 )->addAsmName( $5 ); }
2072
2073 // [ int s, int t ]; // declare s and t
2074 // [ int, int ] f();
2075 // [] g( int );
2076 // [ int x, int y ] = f(); // declare x and y, initialize each from f
2077 // g( x + y );
2078 | cfa_function_return asm_name_opt
2079 { SemanticError( yylloc, "tuple-element declarations is currently unimplemented." ); $$ = nullptr; }
2080 | type_qualifier_list cfa_function_return asm_name_opt
2081 { SemanticError( yylloc, "tuple variable declaration is currently unimplemented." ); $$ = nullptr; }
2082 ;
2083
2084cfa_function_declaration: // CFA
2085 cfa_function_specifier
2086 | type_qualifier_list cfa_function_specifier
2087 { $$ = $2->addQualifiers( $1 ); }
2088 | declaration_qualifier_list cfa_function_specifier
2089 { $$ = $2->addQualifiers( $1 ); }
2090 | declaration_qualifier_list type_qualifier_list cfa_function_specifier
2091 { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
2092 | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')'
2093 {
2094 // Append the return type at the start (left-hand-side) to each identifier in the list.
2095 DeclarationNode * ret = new DeclarationNode;
2096 ret->type = maybeCopy( $1->type->base );
2097 $$ = $1->set_last( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
2098 }
2099 ;
2100
2101cfa_function_specifier: // CFA
2102 '[' ']' identifier '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2103 { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2104 | '[' ']' TYPEDEFname '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2105 { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2106 // | '[' ']' TYPEGENname '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2107 // { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2108
2109 // identifier_or_type_name must be broken apart because of the sequence:
2110 //
2111 // '[' ']' identifier_or_type_name '(' cfa_parameter_list_ellipsis_opt ')'
2112 // '[' ']' type_specifier
2113 //
2114 // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
2115 // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
2116 | cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2117 // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
2118 { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
2119 | cfa_function_return identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2120 { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
2121 ;
2122
2123cfa_function_return: // CFA
2124 '[' cfa_parameter_list ']'
2125 { $$ = DeclarationNode::newTuple( $2 ); }
2126 | '[' cfa_parameter_list ',' cfa_abstract_parameter_list ']'
2127 // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
2128 { $$ = DeclarationNode::newTuple( $2->set_last( $4 ) ); }
2129 ;
2130
2131cfa_typedef_declaration: // CFA
2132 TYPEDEF attribute_list_opt cfa_variable_specifier
2133 {
2134 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "cfa_typedef_declaration 1" );
2135 $$ = $3->addTypedef()->addQualifiers( $2 );
2136 }
2137 | TYPEDEF attribute_list_opt cfa_function_specifier
2138 {
2139 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "cfa_typedef_declaration 2" );
2140 $$ = $3->addTypedef()->addQualifiers( $2 );
2141 }
2142 | cfa_typedef_declaration ',' attribute_list_opt identifier
2143 {
2144 typedefTable.addToEnclosingScope( *$4, TYPEDEFname, "cfa_typedef_declaration 3" );
2145 $$ = $1->set_last( $1->cloneType( $4 )->addQualifiers( $3 ) );
2146 }
2147 ;
2148
2149// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
2150// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
2151
2152typedef_declaration:
2153 TYPEDEF attribute_list_opt type_specifier declarator
2154 {
2155 typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "typedef_declaration 1" );
2156 if ( $3->type->forall || ($3->type->kind == TypeData::Aggregate && $3->type->aggregate.params) ) {
2157 SemanticError( yylloc, "forall qualifier in typedef is currently unimplemented." ); $$ = nullptr;
2158 } else $$ = $4->addType( $3 )->addTypedef()->addQualifiers( $2 ); // watchout frees $3 and $4
2159 }
2160 | typedef_declaration ',' attribute_list_opt declarator
2161 {
2162 typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "typedef_declaration 2" );
2163 $$ = $1->set_last( $1->cloneBaseType( $4 )->addTypedef()->addQualifiers( $3 ) );
2164 }
2165 | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
2166 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2167 | type_specifier TYPEDEF declarator
2168 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2169 | type_specifier TYPEDEF type_qualifier_list declarator
2170 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2171 ;
2172
2173typedef_expression:
2174 // deprecated GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
2175 TYPEDEF identifier '=' assignment_expression
2176 { SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr; }
2177 | typedef_expression ',' identifier '=' assignment_expression
2178 { SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr; }
2179 ;
2180
2181c_declaration:
2182 declaration_specifier declaring_list
2183 { $$ = distTypeSpec( $1, $2 ); }
2184 | typedef_declaration
2185 | typedef_expression // deprecated GCC, naming expression type
2186 | sue_declaration_specifier
2187 {
2188 assert( $1->type );
2189 if ( $1->type->qualifiers.any() ) { // CV qualifiers ?
2190 SemanticError( yylloc, "illegal syntax, useless type qualifier(s) in empty declaration." ); $$ = nullptr;
2191 }
2192 // enums are never empty declarations because there must have at least one enumeration.
2193 if ( $1->type->kind == TypeData::AggregateInst && $1->storageClasses.any() ) { // storage class ?
2194 SemanticError( yylloc, "illegal syntax, useless storage qualifier(s) in empty aggregate declaration." ); $$ = nullptr;
2195 }
2196 }
2197 ;
2198
2199declaring_list:
2200 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
2201 // storage-class
2202 variable_declarator asm_name_opt initializer_opt
2203 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2204 | variable_type_redeclarator asm_name_opt initializer_opt
2205 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2206
2207 | general_function_declarator asm_name_opt
2208 { $$ = $1->addAsmName( $2 )->addInitializer( nullptr ); }
2209 | general_function_declarator asm_name_opt '=' VOID
2210 { $$ = $1->addAsmName( $2 )->addInitializer( new InitializerNode( true ) ); }
2211
2212 | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
2213 { $$ = $1->set_last( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
2214 ;
2215
2216general_function_declarator:
2217 function_type_redeclarator
2218 | function_declarator
2219 ;
2220
2221declaration_specifier: // type specifier + storage class
2222 basic_declaration_specifier
2223 | type_declaration_specifier
2224 | sue_declaration_specifier
2225 | sue_declaration_specifier invalid_types // invalid syntax rule
2226 {
2227 SemanticError( yylloc, "illegal syntax, expecting ';' at end of \"%s\" declaration.",
2228 ast::AggregateDecl::aggrString( $1->type->aggregate.kind ) );
2229 $$ = nullptr;
2230 }
2231 ;
2232
2233invalid_types:
2234 aggregate_key
2235 | basic_type_name
2236 | indirect_type
2237 ;
2238
2239declaration_specifier_nobody: // type specifier + storage class - {...}
2240 // Preclude SUE declarations in restricted scopes:
2241 //
2242 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2243 //
2244 // because it is impossible to call f due to name equivalence.
2245 basic_declaration_specifier
2246 | sue_declaration_specifier_nobody
2247 | type_declaration_specifier
2248 ;
2249
2250type_specifier: // type specifier
2251 basic_type_specifier
2252 | sue_type_specifier
2253 | type_type_specifier attribute_list_opt
2254 ;
2255
2256type_specifier_nobody: // type specifier - {...}
2257 // Preclude SUE declarations in restricted scopes:
2258 //
2259 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2260 //
2261 // because it is impossible to call f due to name equivalence.
2262 basic_type_specifier
2263 | sue_type_specifier_nobody
2264 | type_type_specifier
2265 ;
2266
2267type_qualifier_list_opt: // GCC, used in asm_statement
2268 // empty
2269 { $$ = nullptr; }
2270 | type_qualifier_list
2271 ;
2272
2273type_qualifier_list:
2274 // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
2275 //
2276 // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
2277 // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
2278 // appeared only once.
2279 type_qualifier attribute_list_opt
2280 { $$ = $1->addQualifiers( $2 ); }
2281 | type_qualifier_list type_qualifier attribute_list_opt
2282 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2283 ;
2284
2285type_qualifier:
2286 type_qualifier_name
2287 { $$ = DeclarationNode::newFromTypeData( $1 ); }
2288 ;
2289
2290type_qualifier_name:
2291 CONST
2292 { $$ = build_type_qualifier( ast::CV::Const ); }
2293 | RESTRICT
2294 { $$ = build_type_qualifier( ast::CV::Restrict ); }
2295 | VOLATILE
2296 { $$ = build_type_qualifier( ast::CV::Volatile ); }
2297 | ATOMIC
2298 { $$ = build_type_qualifier( ast::CV::Atomic ); }
2299
2300 // forall is a CV qualifier because it can appear in places where SC qualifiers are disallowed.
2301 //
2302 // void foo( forall( T ) T (*)( T ) ); // forward declaration
2303 // void bar( static int ); // static disallowed (gcc/CFA)
2304 | forall
2305 { $$ = build_forall( $1 ); }
2306 ;
2307
2308forall:
2309 FORALL '(' type_parameter_list ')' // CFA
2310 { $$ = $3; }
2311 ;
2312
2313declaration_qualifier_list:
2314 storage_class_list
2315 | type_qualifier_list storage_class_list
2316 { $$ = $1->addQualifiers( $2 ); }
2317 | declaration_qualifier_list type_qualifier_list storage_class_list
2318 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2319 ;
2320
2321storage_class_list:
2322 // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
2323 // only one of each is specified, except for inline, which can appear with the others.
2324 //
2325 // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
2326 // specifiers in a declaration.
2327 storage_class attribute_list_opt
2328 { $$ = $1->addQualifiers( $2 ); }
2329 | storage_class_list storage_class attribute_list_opt
2330 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2331 ;
2332
2333storage_class:
2334 EXTERN
2335 { $$ = DeclarationNode::newStorageClass( ast::Storage::Extern ); }
2336 | STATIC
2337 { $$ = DeclarationNode::newStorageClass( ast::Storage::Static ); }
2338 | AUTO
2339 { $$ = DeclarationNode::newStorageClass( ast::Storage::Auto ); }
2340 | REGISTER
2341 { $$ = DeclarationNode::newStorageClass( ast::Storage::Register ); }
2342 | THREADLOCALGCC // GCC
2343 { $$ = DeclarationNode::newStorageClass( ast::Storage::ThreadLocalGcc ); }
2344 | THREADLOCALC11 // C11
2345 { $$ = DeclarationNode::newStorageClass( ast::Storage::ThreadLocalC11 ); }
2346 // Put function specifiers here to simplify parsing rules, but separate them semantically.
2347 | INLINE // C99
2348 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Inline ); }
2349 | FORTRAN // C99
2350 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Fortran ); }
2351 | NORETURN // C11
2352 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Noreturn ); }
2353 ;
2354
2355basic_type_name:
2356 basic_type_name_type
2357 { $$ = DeclarationNode::newFromTypeData( $1 ); }
2358 ;
2359
2360// Just an intermediate value for conversion.
2361basic_type_name_type:
2362 VOID
2363 { $$ = build_basic_type( TypeData::Void ); }
2364 | BOOL // C99
2365 { $$ = build_basic_type( TypeData::Bool ); }
2366 | CHAR
2367 { $$ = build_basic_type( TypeData::Char ); }
2368 | INT
2369 { $$ = build_basic_type( TypeData::Int ); }
2370 | INT128
2371 { $$ = build_basic_type( TypeData::Int128 ); }
2372 | UINT128
2373 { $$ = addType( build_basic_type( TypeData::Int128 ), build_signedness( TypeData::Unsigned ) ); }
2374 | FLOAT
2375 { $$ = build_basic_type( TypeData::Float ); }
2376 | DOUBLE
2377 { $$ = build_basic_type( TypeData::Double ); }
2378 | FLOAT80
2379 { $$ = build_basic_type( TypeData::Float80 ); }
2380 | uuFLOAT128
2381 { $$ = build_basic_type( TypeData::uuFloat128 ); }
2382 | FLOAT16
2383 { $$ = build_basic_type( TypeData::Float16 ); }
2384 | FLOAT32
2385 { $$ = build_basic_type( TypeData::Float32 ); }
2386 | FLOAT32X
2387 { $$ = build_basic_type( TypeData::Float32x ); }
2388 | FLOAT64
2389 { $$ = build_basic_type( TypeData::Float64 ); }
2390 | FLOAT64X
2391 { $$ = build_basic_type( TypeData::Float64x ); }
2392 | FLOAT128
2393 { $$ = build_basic_type( TypeData::Float128 ); }
2394 // https://developer.arm.com/documentation/den0018/a/NEON-Intrinsics/Accessing-vector-types-from-C
2395 | FLOAT128X
2396 { $$ = build_basic_type( TypeData::Float128x ); }
2397 | FLOAT32X4
2398 { $$ = build_basic_type( TypeData::Float32x4 ); }
2399 | FLOAT64X2
2400 { $$ = build_basic_type( TypeData::Float64x2 ); }
2401 | SVFLOAT32
2402 { $$ = build_basic_type( TypeData::Svfloat32 ); }
2403 | SVFLOAT64
2404 { $$ = build_basic_type( TypeData::Svfloat64 ); }
2405 | SVBOOL
2406 { $$ = build_basic_type( TypeData::Svbool ); }
2407 | DECIMAL32
2408 { SemanticError( yylloc, "_Decimal32 is currently unimplemented." ); $$ = nullptr; }
2409 | DECIMAL64
2410 { SemanticError( yylloc, "_Decimal64 is currently unimplemented." ); $$ = nullptr; }
2411 | DECIMAL128
2412 { SemanticError( yylloc, "_Decimal128 is currently unimplemented." ); $$ = nullptr; }
2413 | COMPLEX // C99
2414 { $$ = build_complex_type( TypeData::Complex ); }
2415 | IMAGINARY // C99
2416 { $$ = build_complex_type( TypeData::Imaginary ); }
2417 | SIGNED
2418 { $$ = build_signedness( TypeData::Signed ); }
2419 | UNSIGNED
2420 { $$ = build_signedness( TypeData::Unsigned ); }
2421 | SHORT
2422 { $$ = build_length( TypeData::Short ); }
2423 | LONG
2424 { $$ = build_length( TypeData::Long ); }
2425 | VA_LIST // GCC, __builtin_va_list
2426 { $$ = build_builtin_type( TypeData::Valist ); }
2427 | AUTO_TYPE
2428 { $$ = build_builtin_type( TypeData::AutoType ); }
2429 | vtable
2430 ;
2431
2432vtable_opt:
2433 // empty
2434 { $$ = nullptr; }
2435 | vtable
2436 ;
2437
2438vtable:
2439 VTABLE '(' type_name ')' default_opt
2440 { $$ = build_vtable_type( $3 ); }
2441 ;
2442
2443default_opt:
2444 // empty
2445 { $$ = nullptr; }
2446 | DEFAULT
2447 { SemanticError( yylloc, "vtable default is currently unimplemented." ); $$ = nullptr; }
2448 ;
2449
2450basic_declaration_specifier:
2451 // A semantic check is necessary for conflicting storage classes.
2452 basic_type_specifier
2453 | declaration_qualifier_list basic_type_specifier
2454 { $$ = $2->addQualifiers( $1 ); }
2455 | basic_declaration_specifier storage_class attribute_list_opt // remaining OBSOLESCENT (see 2)
2456 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2457 | basic_declaration_specifier storage_class type_qualifier_list
2458 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2459 | basic_declaration_specifier storage_class basic_type_specifier
2460 { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
2461 ;
2462
2463basic_type_specifier:
2464 direct_type attribute_list_opt
2465 { $$ = $1->addQualifiers( $2 ); }
2466 // Cannot have type modifiers, e.g., short, long, etc.
2467 | type_qualifier_list_opt indirect_type attribute_list
2468 { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
2469 | type_qualifier_list_opt indirect_type type_qualifier_list_opt
2470 { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
2471 ;
2472
2473direct_type:
2474 basic_type_name
2475 | type_qualifier_list basic_type_name
2476 { $$ = $2->addQualifiers( $1 ); }
2477 | direct_type type_qualifier
2478 { $$ = $1->addQualifiers( $2 ); }
2479 | direct_type basic_type_name
2480 { $$ = $1->addType( $2 ); }
2481 ;
2482
2483indirect_type:
2484 TYPEOF '(' type ')' // GCC: typeof( x ) y;
2485 { $$ = $3; }
2486 | TYPEOF '(' comma_expression ')' // GCC: typeof( a+b ) y;
2487 { $$ = DeclarationNode::newTypeof( $3 ); }
2488 | BASETYPEOF '(' type ')' // CFA: basetypeof( x ) y;
2489 { $$ = DeclarationNode::newTypeof( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ), true ); }
2490 | BASETYPEOF '(' comma_expression ')' // CFA: basetypeof( a+b ) y;
2491 { $$ = DeclarationNode::newTypeof( $3, true ); }
2492 | ZERO_T // CFA
2493 { $$ = DeclarationNode::newFromTypeData( build_builtin_type( TypeData::Zero ) ); }
2494 | ONE_T // CFA
2495 { $$ = DeclarationNode::newFromTypeData( build_builtin_type( TypeData::One ) ); }
2496 ;
2497
2498sue_declaration_specifier: // struct, union, enum + storage class + type specifier
2499 sue_type_specifier
2500 | declaration_qualifier_list sue_type_specifier
2501 { $$ = $2->addQualifiers( $1 ); }
2502 | sue_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2503 { $$ = $1->addQualifiers( $2 ); }
2504 | sue_declaration_specifier storage_class type_qualifier_list
2505 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2506 ;
2507
2508sue_type_specifier: // struct, union, enum + type specifier
2509 elaborated_type
2510 | type_qualifier_list
2511 { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
2512 elaborated_type
2513 { $$ = $3->addQualifiers( $1 ); }
2514 | sue_type_specifier type_qualifier
2515 {
2516 if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
2517 $$ = $1->addQualifiers( $2 );
2518 }
2519 ;
2520
2521sue_declaration_specifier_nobody: // struct, union, enum - {...} + storage class + type specifier
2522 sue_type_specifier_nobody
2523 | declaration_qualifier_list sue_type_specifier_nobody
2524 { $$ = $2->addQualifiers( $1 ); }
2525 | sue_declaration_specifier_nobody storage_class // remaining OBSOLESCENT (see 2)
2526 { $$ = $1->addQualifiers( $2 ); }
2527 | sue_declaration_specifier_nobody storage_class type_qualifier_list
2528 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2529 ;
2530
2531sue_type_specifier_nobody: // struct, union, enum - {...} + type specifier
2532 elaborated_type_nobody
2533 | type_qualifier_list elaborated_type_nobody
2534 { $$ = $2->addQualifiers( $1 ); }
2535 | sue_type_specifier_nobody type_qualifier
2536 { $$ = $1->addQualifiers( $2 ); }
2537 ;
2538
2539type_declaration_specifier:
2540 type_type_specifier attribute_list_opt
2541 { $$ = $1->addQualifiers( $2 ); }
2542 | declaration_qualifier_list type_type_specifier attribute_list_opt
2543 { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
2544 | type_declaration_specifier storage_class attribute_list_opt // remaining OBSOLESCENT (see 2)
2545 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2546 | type_declaration_specifier storage_class type_qualifier_list
2547 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2548 ;
2549
2550type_type_specifier: // typedef types
2551 type_name
2552 { $$ = DeclarationNode::newFromTypeData( $1 ); }
2553 | type_qualifier_list type_name
2554 { $$ = DeclarationNode::newFromTypeData( $2 )->addQualifiers( $1 ); }
2555 | type_type_specifier type_qualifier
2556 { $$ = $1->addQualifiers( $2 ); }
2557 ;
2558
2559type_name:
2560 TYPEDEFname
2561 { $$ = build_typedef( $1 ); }
2562 | '.' TYPEDEFname
2563 { $$ = build_qualified_type( build_global_scope(), build_typedef( $2 ) ); }
2564 | type_name '.' TYPEDEFname
2565 { $$ = build_qualified_type( $1, build_typedef( $3 ) ); }
2566 | typegen_name
2567 | '.' typegen_name
2568 { $$ = build_qualified_type( build_global_scope(), $2 ); }
2569 | type_name '.' typegen_name
2570 { $$ = build_qualified_type( $1, $3 ); }
2571 ;
2572
2573typegen_name: // CFA
2574 TYPEGENname
2575 { $$ = build_type_gen( $1, nullptr ); }
2576 | TYPEGENname '(' ')'
2577 { $$ = build_type_gen( $1, nullptr ); }
2578 | TYPEGENname '(' type_list ')'
2579 { $$ = build_type_gen( $1, $3 ); }
2580 ;
2581
2582elaborated_type: // struct, union, enum
2583 aggregate_type
2584 | enum_type
2585 ;
2586
2587elaborated_type_nobody: // struct, union, enum - {...}
2588 aggregate_type_nobody
2589 | enum_type_nobody
2590 ;
2591
2592// ************************** AGGREGATE *******************************
2593
2594aggregate_type: // struct, union
2595 aggregate_key attribute_list_opt
2596 { forall = false; } // reset
2597 '{' field_declaration_list_opt '}' type_parameters_opt attribute_list_opt
2598 { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 )->addQualifiers( $8 ); }
2599 | aggregate_key attribute_list_opt identifier attribute_list_opt
2600 {
2601 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 1" );
2602 forall = false; // reset
2603 }
2604 '{' field_declaration_list_opt '}' type_parameters_opt attribute_list_opt
2605 {
2606 $$ = DeclarationNode::newAggregate( $1, $3, $9, $7, true )->addQualifiers( $2 )->addQualifiers( $4 )->addQualifiers( $10 );
2607 }
2608 | aggregate_key attribute_list_opt TYPEDEFname attribute_list_opt // unqualified type name
2609 {
2610 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 2" );
2611 forall = false; // reset
2612 }
2613 '{' field_declaration_list_opt '}' type_parameters_opt attribute_list_opt
2614 {
2615 DeclarationNode::newFromTypeData( build_typedef( $3 ) );
2616 $$ = DeclarationNode::newAggregate( $1, $3, $9, $7, true )->addQualifiers( $2 )->addQualifiers( $4 )->addQualifiers( $10 );
2617 }
2618 | aggregate_key attribute_list_opt TYPEGENname attribute_list_opt // unqualified type name
2619 {
2620 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 3" );
2621 forall = false; // reset
2622 }
2623 '{' field_declaration_list_opt '}' type_parameters_opt attribute_list_opt
2624 {
2625 DeclarationNode::newFromTypeData( build_type_gen( $3, nullptr ) );
2626 $$ = DeclarationNode::newAggregate( $1, $3, $9, $7, true )->addQualifiers( $2 )->addQualifiers( $10 );
2627 }
2628 | aggregate_type_nobody
2629 ;
2630
2631type_parameters_opt:
2632 // empty
2633 { $$ = nullptr; } %prec '}'
2634 | '(' type_list ')'
2635 { $$ = $2; }
2636 ;
2637
2638aggregate_type_nobody: // struct, union - {...}
2639 aggregate_key attribute_list_opt identifier
2640 {
2641 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type_nobody" );
2642 forall = false; // reset
2643 $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2644 }
2645 | aggregate_key attribute_list_opt type_name
2646 {
2647 forall = false; // reset
2648 // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2649 // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2650 // delete newFromTypeGen.
2651 if ( $3->kind == TypeData::SymbolicInst && ! $3->symbolic.isTypedef ) {
2652 $$ = DeclarationNode::newFromTypeData( $3 )->addQualifiers( $2 );
2653 } else {
2654 $$ = DeclarationNode::newAggregate( $1, $3->symbolic.name, $3->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2655 $3->symbolic.name = nullptr; // copied to $$
2656 $3->symbolic.actuals = nullptr;
2657 delete $3;
2658 }
2659 }
2660 ;
2661
2662aggregate_key:
2663 aggregate_data
2664 | aggregate_control
2665 ;
2666
2667aggregate_data:
2668 STRUCT vtable_opt
2669 { $$ = ast::AggregateDecl::Struct; }
2670 | UNION
2671 { $$ = ast::AggregateDecl::Union; }
2672 | EXCEPTION // CFA
2673 { $$ = ast::AggregateDecl::Exception; }
2674 ;
2675
2676aggregate_control: // CFA
2677 MONITOR
2678 { $$ = ast::AggregateDecl::Monitor; }
2679 | MUTEX STRUCT
2680 { $$ = ast::AggregateDecl::Monitor; }
2681 | GENERATOR
2682 { $$ = ast::AggregateDecl::Generator; }
2683 | MUTEX GENERATOR
2684 {
2685 SemanticError( yylloc, "monitor generator is currently unimplemented." );
2686 $$ = ast::AggregateDecl::NoAggregate;
2687 }
2688 | COROUTINE
2689 { $$ = ast::AggregateDecl::Coroutine; }
2690 | MUTEX COROUTINE
2691 {
2692 SemanticError( yylloc, "monitor coroutine is currently unimplemented." );
2693 $$ = ast::AggregateDecl::NoAggregate;
2694 }
2695 | THREAD
2696 { $$ = ast::AggregateDecl::Thread; }
2697 | MUTEX THREAD
2698 {
2699 SemanticError( yylloc, "monitor thread is currently unimplemented." );
2700 $$ = ast::AggregateDecl::NoAggregate;
2701 }
2702 ;
2703
2704field_declaration_list_opt:
2705 // empty => struct S { /* no fields */ };
2706 { $$ = nullptr; }
2707 | field_declaration_list_opt attribute_list_opt field_declaration
2708 { distAttr( $2, $3 ); $$ = $1 ? $1->set_last( $3 ) : $3; }
2709 ;
2710
2711field_declaration:
2712 type_specifier field_declaring_list_opt ';'
2713 { $$ = fieldDecl( $1, $2 ); }
2714 | type_specifier field_declaring_list_opt '}' // invalid syntax rule
2715 {
2716 SemanticError( yylloc, "illegal syntax, expecting ';' at end of previous declaration." );
2717 $$ = nullptr;
2718 }
2719 | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2720 { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2721 | STATIC type_specifier field_declaring_list_opt ';' // CFA
2722 { SemanticError( yylloc, "STATIC aggregate field qualifier currently unimplemented." ); $$ = nullptr; }
2723 | INLINE attribute_list_opt type_specifier field_abstract_list_opt ';' // CFA
2724 {
2725 if ( ! $4 ) { // field declarator ?
2726 $4 = DeclarationNode::newName( nullptr );
2727 } // if
2728 $4->inLine = true;
2729 $$ = distTypeSpec( $3, $4 ); // mark all fields in list
2730 distInl( $4 );
2731 }
2732 | INLINE attribute_list_opt aggregate_control ';' // CFA
2733 { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2734 | typedef_declaration ';' // CFA
2735 | cfa_field_declaring_list ';' // CFA, new style field declaration
2736 | EXTENSION cfa_field_declaring_list ';' // GCC
2737 { distExt( $2 ); $$ = $2; } // mark all fields in list
2738 | INLINE attribute_list_opt cfa_field_abstract_list ';' // CFA, new style field declaration
2739 { $$ = $3->addQualifiers( $2 ); } // mark all fields in list
2740 | cfa_typedef_declaration ';' // CFA
2741 | static_assert ';' // C11
2742 ;
2743
2744field_declaring_list_opt:
2745 // empty
2746 { $$ = nullptr; }
2747 | field_declaring_list
2748 ;
2749
2750field_declaring_list:
2751 field_declarator
2752 | field_declaring_list_opt ',' attribute_list_opt field_declarator
2753 { $$ = $1->set_last( $4->addQualifiers( $3 ) ); }
2754 ;
2755
2756field_declarator:
2757 bit_subrange_size // C special case, no field name
2758 { $$ = DeclarationNode::newBitfield( $1 ); }
2759 | variable_declarator bit_subrange_size_opt
2760 // A semantic check is required to ensure bit_subrange only appears on integral types.
2761 { $$ = $1->addBitfield( $2 ); }
2762 | variable_type_redeclarator bit_subrange_size_opt
2763 // A semantic check is required to ensure bit_subrange only appears on integral types.
2764 { $$ = $1->addBitfield( $2 ); }
2765 | function_type_redeclarator bit_subrange_size_opt
2766 // A semantic check is required to ensure bit_subrange only appears on integral types.
2767 { $$ = $1->addBitfield( $2 ); }
2768 ;
2769
2770field_abstract_list_opt:
2771 // empty
2772 { $$ = nullptr; }
2773 | field_abstract
2774 | field_abstract_list_opt ',' attribute_list_opt field_abstract
2775 { $$ = $1->set_last( $4->addQualifiers( $3 ) ); }
2776 ;
2777
2778field_abstract:
2779 variable_abstract_declarator // no bit fields
2780 ;
2781
2782cfa_field_declaring_list: // CFA, new style field declaration
2783 // bit-fields are handled by C declarations
2784 cfa_abstract_declarator_tuple identifier_or_type_name
2785 { $$ = $1->addName( $2 ); }
2786 | cfa_field_declaring_list ',' identifier_or_type_name
2787 { $$ = $1->set_last( $1->cloneType( $3 ) ); }
2788 ;
2789
2790cfa_field_abstract_list: // CFA, new style field declaration
2791 // bit-fields are handled by C declarations
2792 cfa_abstract_declarator_tuple
2793 | cfa_field_abstract_list ','
2794 { $$ = $1->set_last( $1->cloneType( 0 ) ); }
2795 ;
2796
2797bit_subrange_size_opt:
2798 // empty
2799 { $$ = nullptr; }
2800 | bit_subrange_size
2801 ;
2802
2803bit_subrange_size:
2804 ':' assignment_expression
2805 { $$ = $2; }
2806 ;
2807
2808// ************************** ENUMERATION *******************************
2809
2810enum_type:
2811 // anonymous, no type name
2812 ENUM attribute_list_opt hide_opt '{' enumerator_list comma_opt '}' attribute_list_opt
2813 {
2814 if ( $3 == EnumHiding::Hide ) {
2815 SemanticError( yylloc, "illegal syntax, hiding ('!') the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr;
2816 } // if
2817 $$ = DeclarationNode::newEnum( nullptr, $5, true, false )->addQualifiers( $2 )->addQualifiers( $8 );
2818 }
2819 | ENUM enumerator_type attribute_list_opt hide_opt '{' enumerator_list comma_opt '}' attribute_list_opt
2820 {
2821 if ( $2 && ($2->storageClasses.val != 0 || $2->type->qualifiers.any()) ) {
2822 SemanticError( yylloc, "illegal syntax, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2823 }
2824 if ( $4 == EnumHiding::Hide ) {
2825 SemanticError( yylloc, "illegal syntax, hiding ('!') the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr;
2826 } // if
2827 $$ = DeclarationNode::newEnum( nullptr, $6, true, true, $2 )->addQualifiers( $3 )->addQualifiers( $9 );
2828 }
2829
2830 // named type
2831 | ENUM attribute_list_opt identifier attribute_list_opt
2832 { typedefTable.makeTypedef( *$3, "enum_type 1" ); }
2833 hide_opt '{' enumerator_list comma_opt '}' attribute_list_opt
2834 { $$ = DeclarationNode::newEnum( $3, $8, true, false, nullptr, $6 )->addQualifiers( $2 ->addQualifiers( $4 ))->addQualifiers( $11 ); }
2835 | ENUM attribute_list_opt typedef_name attribute_list_opt hide_opt '{' enumerator_list comma_opt '}' attribute_list_opt // unqualified type name
2836 { $$ = DeclarationNode::newEnum( $3->name, $7, true, false, nullptr, $5 )->addQualifiers( $2 )->addQualifiers( $4 )->addQualifiers( $10 ); }
2837 | ENUM enumerator_type attribute_list_opt identifier attribute_list_opt
2838 {
2839 if ( $2 && ($2->storageClasses.any() || $2->type->qualifiers.val != 0) ) {
2840 SemanticError( yylloc, "illegal syntax, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2841 }
2842 typedefTable.makeTypedef( *$4, "enum_type 2" );
2843 }
2844 hide_opt '{' enumerator_list comma_opt '}' attribute_list_opt
2845 { $$ = DeclarationNode::newEnum( $4, $9, true, true, $2, $7 )->addQualifiers( $3 )->addQualifiers( $5 )->addQualifiers( $12 ); }
2846 | ENUM enumerator_type attribute_list_opt typedef_name attribute_list_opt hide_opt '{' enumerator_list comma_opt '}' attribute_list_opt
2847 { $$ = DeclarationNode::newEnum( $4->name, $8, true, true, $2, $6 )->addQualifiers( $3 )->addQualifiers( $5 )->addQualifiers( $11 ); }
2848
2849 // forward declaration
2850 | enum_type_nobody
2851 ;
2852
2853enumerator_type:
2854 '(' ')' // pure enumeration
2855 { $$ = nullptr; }
2856 | '(' cfa_abstract_parameter_declaration ')' // typed enumeration
2857 { $$ = $2; }
2858 ;
2859
2860hide_opt:
2861 // empty
2862 { $$ = EnumHiding::Visible; }
2863 | '!'
2864 { $$ = EnumHiding::Hide; }
2865 ;
2866
2867enum_type_nobody: // enum - {...}
2868 ENUM attribute_list_opt identifier
2869 {
2870 typedefTable.makeTypedef( *$3, "enum_type_nobody 1" );
2871 $$ = DeclarationNode::newEnum( $3, nullptr, false, false )->addQualifiers( $2 );
2872 }
2873 | ENUM attribute_list_opt type_name
2874 {
2875 typedefTable.makeTypedef( *$3->symbolic.name, "enum_type_nobody 2" );
2876 $$ = DeclarationNode::newEnum( $3->symbolic.name, nullptr, false, false )->addQualifiers( $2 );
2877 }
2878 ;
2879
2880enumerator_list:
2881 // empty
2882 { SemanticError( yylloc, "enumeration must have a minimum of one enumerator, empty enumerator list is meaningless." ); $$ = nullptr; }
2883 | visible_hide_opt identifier_or_type_name enumerator_value_opt
2884 { $$ = DeclarationNode::newEnumValueGeneric( $2, $3 ); }
2885 | INLINE type_name
2886 {
2887 $$ = DeclarationNode::newEnumInLine( $2->symbolic.name );
2888 $2->symbolic.name = nullptr;
2889 delete $2;
2890 }
2891 | enumerator_list ',' visible_hide_opt identifier_or_type_name enumerator_value_opt
2892 { $$ = $1->set_last( DeclarationNode::newEnumValueGeneric( $4, $5 ) ); }
2893 | enumerator_list ',' INLINE type_name
2894 { $$ = $1->set_last( DeclarationNode::newEnumInLine( $4->symbolic.name ) ); }
2895 ;
2896
2897visible_hide_opt:
2898 hide_opt
2899 | '^'
2900 { $$ = EnumHiding::Visible; }
2901 ;
2902
2903enumerator_value_opt:
2904 // empty
2905 { $$ = nullptr; }
2906 | '=' constant_expression { $$ = new InitializerNode( $2 ); }
2907 | '=' '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $3, true ); }
2908 // | simple_assignment_operator initializer
2909 // { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2910 ;
2911
2912// ************************** FUNCTION PARAMETERS *******************************
2913
2914parameter_list_ellipsis_opt:
2915 // empty
2916 { $$ = DeclarationNode::newFromTypeData( build_basic_type( TypeData::Void ) ); }
2917 | ELLIPSIS
2918 { $$ = nullptr; }
2919 | parameter_list
2920 | parameter_list ',' ELLIPSIS
2921 { $$ = $1->addVarArgs(); }
2922 ;
2923
2924parameter_list: // abstract + real
2925 parameter_declaration
2926 | attribute_list parameter_declaration
2927 { $$ = $2->addQualifiers( $1 ); }
2928 | abstract_parameter_declaration
2929 | attribute_list abstract_parameter_declaration
2930 { $$ = $2->addQualifiers( $1 ); }
2931 | parameter_list ',' attribute_list_opt parameter_declaration
2932 { $4->addQualifiers( $3 ); $$ = $1->set_last( $4 ); }
2933 | parameter_list ',' attribute_list_opt abstract_parameter_declaration
2934 { $4->addQualifiers( $3 ); $$ = $1->set_last( $4 ); }
2935 ;
2936
2937cfa_parameter_list_ellipsis_opt: // CFA, abstract + real
2938 // empty
2939 { $$ = DeclarationNode::newFromTypeData( build_basic_type( TypeData::Void ) ); }
2940 | ELLIPSIS
2941 { $$ = nullptr; }
2942 | cfa_parameter_list
2943 | cfa_abstract_parameter_list
2944 | cfa_parameter_list ',' cfa_abstract_parameter_list
2945 { $$ = $1->set_last( $3 ); }
2946 | cfa_parameter_list ',' ELLIPSIS
2947 { $$ = $1->addVarArgs(); }
2948 | cfa_abstract_parameter_list ',' ELLIPSIS
2949 { $$ = $1->addVarArgs(); }
2950 ;
2951
2952cfa_parameter_list: // CFA
2953 // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2954 // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2955 cfa_parameter_declaration
2956 | cfa_abstract_parameter_list ',' cfa_parameter_declaration
2957 { $$ = $1->set_last( $3 ); }
2958 | cfa_parameter_list ',' cfa_parameter_declaration
2959 { $$ = $1->set_last( $3 ); }
2960 | cfa_parameter_list ',' cfa_abstract_parameter_list ',' cfa_parameter_declaration
2961 { $$ = $1->set_last( $3 )->set_last( $5 ); }
2962 ;
2963
2964cfa_abstract_parameter_list: // CFA, new & old style abstract
2965 cfa_abstract_parameter_declaration
2966 | cfa_abstract_parameter_list ',' cfa_abstract_parameter_declaration
2967 { $$ = $1->set_last( $3 ); }
2968 ;
2969
2970// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2971// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2972
2973parameter_declaration:
2974 // No SUE declaration in parameter list.
2975 declaration_specifier_nobody identifier_parameter_declarator default_initializer_opt
2976 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2977 | declaration_specifier_nobody type_parameter_redeclarator default_initializer_opt
2978 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2979 ;
2980
2981abstract_parameter_declaration:
2982 declaration_specifier_nobody default_initializer_opt
2983 { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2984 | declaration_specifier_nobody abstract_parameter_declarator default_initializer_opt
2985 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2986 ;
2987
2988cfa_parameter_declaration: // CFA, new & old style parameter declaration
2989 parameter_declaration
2990 | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initializer_opt
2991 { $$ = $1->addName( $2 ); }
2992 | cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2993 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2994 { $$ = $1->addName( $2 ); }
2995 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2996 { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2997 | cfa_function_specifier // int f( "int fp()" );
2998 ;
2999
3000cfa_abstract_parameter_declaration: // CFA, new & old style parameter declaration
3001 abstract_parameter_declaration
3002 | cfa_identifier_parameter_declarator_no_tuple
3003 | cfa_abstract_tuple
3004 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
3005 | type_qualifier_list cfa_abstract_tuple
3006 { $$ = $2->addQualifiers( $1 ); }
3007 | cfa_abstract_function // int f( "int ()" );
3008 ;
3009
3010// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
3011// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
3012// identifiers. The ANSI-style parameter-list can redefine a typedef name.
3013
3014identifier_list: // K&R-style parameter list => no types
3015 identifier
3016 { $$ = DeclarationNode::newName( $1 ); }
3017 | identifier_list ',' identifier
3018 { $$ = $1->set_last( DeclarationNode::newName( $3 ) ); }
3019 ;
3020
3021type_no_function: // sizeof, alignof, cast (constructor)
3022 type_specifier // cannot be type_specifier_nobody, e.g., (struct S {}){} is a thing
3023 | type_specifier abstract_declarator
3024 { $$ = $2->addType( $1 ); }
3025 | cfa_abstract_declarator_tuple // CFA
3026 ;
3027
3028type: // typeof, assertion
3029 type_no_function
3030 | attribute_list type_no_function
3031 { $$ = $2->addQualifiers( $1 ); }
3032 | cfa_abstract_function // CFA
3033 | attribute_list cfa_abstract_function // CFA
3034 { $$ = $2->addQualifiers( $1 ); }
3035 ;
3036
3037initializer_opt:
3038 // empty
3039 { $$ = nullptr; }
3040 | simple_assignment_operator initializer { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
3041 | '=' VOID { $$ = new InitializerNode( true ); }
3042 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
3043 ;
3044
3045initializer:
3046 assignment_expression { $$ = new InitializerNode( $1 ); }
3047 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
3048 ;
3049
3050initializer_list_opt:
3051 // empty
3052 { $$ = nullptr; }
3053 | initializer
3054 | designation initializer { $$ = $2->set_designators( $1 ); }
3055 | initializer_list_opt ',' initializer { $$ = $1->set_last( $3 ); }
3056 | initializer_list_opt ',' designation initializer { $$ = $1->set_last( $4->set_designators( $3 ) ); }
3057 ;
3058
3059// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
3060// '=' to separator the designator from the initializer value, as in:
3061//
3062// int x[10] = { [1] = 3 };
3063//
3064// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment. To disambiguate this case, CFA
3065// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
3066// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
3067// shift/reduce conflicts
3068
3069designation:
3070 designator_list '=' // C99, CFA uses ":" instead of "="
3071 | identifier_at ':' // GCC, field name, obsolete since GCC 2.5
3072 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
3073 ;
3074
3075designator_list: // C99
3076 designator
3077 | designator_list designator
3078 { $$ = $1->set_last( $2 ); }
3079 ;
3080
3081designator:
3082 '.' identifier_at // C99, field name
3083 { $$ = new ExpressionNode( build_varref( yylloc, $2 ) ); }
3084 | '[' constant_expression ']' // C99, single array element
3085 { $$ = $2; }
3086 | '[' subrange ']' // CFA, multiple array elements
3087 { $$ = $2; }
3088 | '[' constant_expression ELLIPSIS constant_expression ']' // GCC, multiple array elements
3089 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $2 ), maybeMoveBuild( $4 ) ) ); }
3090 | '.' '[' field_name_list ']' // CFA, tuple field selector
3091 { $$ = $3; }
3092 ;
3093
3094// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
3095// rather than an object-oriented type system. This required four groups of extensions:
3096//
3097// Overloading: function, data, and operator identifiers may be overloaded.
3098//
3099// Type declarations: "otype" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
3100// and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
3101// definitions of new types. Type declarations with storage class "extern" provide opaque types.
3102//
3103// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
3104// site. A polymorphic function is not a template; it is a function, with an address and a type.
3105//
3106// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
3107// types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
3108// hierarchies. Unlike classes, they can define relationships between types. Assertions declare that a type or
3109// types provide the operations declared by a specification. Assertions are normally used to declare requirements
3110// on type arguments of polymorphic functions.
3111
3112type_parameter_list: // CFA
3113 type_parameter
3114 | type_parameter_list ',' type_parameter
3115 { $$ = $1->set_last( $3 ); }
3116 ;
3117
3118type_initializer_opt: // CFA
3119 // empty
3120 { $$ = nullptr; }
3121 | '=' type
3122 { $$ = $2; }
3123 ;
3124
3125type_parameter: // CFA
3126 type_class identifier_or_type_name
3127 { typedefTable.addToScope( *$2, TYPEDEFname, "type_parameter 1" ); }
3128 type_initializer_opt assertion_list_opt
3129 { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
3130 | identifier_or_type_name new_type_class
3131 { typedefTable.addToScope( *$1, TYPEDEFname, "type_parameter 2" ); }
3132 type_initializer_opt assertion_list_opt
3133 { $$ = DeclarationNode::newTypeParam( $2, $1 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
3134 | '[' identifier_or_type_name ']'
3135 {
3136 typedefTable.addToScope( *$2, TYPEDIMname, "type_parameter 3" );
3137 $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dimension, $2 );
3138 }
3139 // | type_specifier identifier_parameter_declarator
3140 | assertion_list
3141 // Invent a placeholder type to wrap these bare assertions. Rely on buildFunctionDecl to remove the placeholder.
3142 { $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dtype, new string( "" ) )->addAssertions( $1 ); }
3143 | ENUM '(' identifier_or_type_name ')' identifier_or_type_name new_type_class type_initializer_opt assertion_list_opt
3144 {
3145 typedefTable.addToScope( *$3, TYPEDIMname, "type_parameter 4" );
3146 typedefTable.addToScope( *$5, TYPEDIMname, "type_parameter 5" );
3147 $$ = DeclarationNode::newTypeParam( $6, $5 )->addTypeInitializer( $7 )->addAssertions( $8 );
3148 }
3149 ;
3150
3151new_type_class: // CFA
3152 // empty
3153 { $$ = ast::TypeDecl::Otype; }
3154 | '&'
3155 { $$ = ast::TypeDecl::Dtype; }
3156 | '*'
3157 { $$ = ast::TypeDecl::DStype; } // Dtype + sized
3158 // | '(' '*' ')' // Gregor made me do it
3159 // { $$ = ast::TypeDecl::Ftype; }
3160 | ELLIPSIS
3161 { $$ = ast::TypeDecl::Ttype; }
3162 ;
3163
3164type_class: // CFA
3165 OTYPE
3166 { SemanticError( yylloc, "otype keyword is deprecated, use T " ); }
3167 | DTYPE
3168 { SemanticError( yylloc, "dtype keyword is deprecated, use T &" ); }
3169 | FTYPE
3170 { $$ = ast::TypeDecl::Ftype; }
3171 | TTYPE
3172 { SemanticError( yylloc, "ttype keyword is deprecated, use T ..." ); }
3173 ;
3174
3175assertion_list_opt: // CFA
3176 // empty
3177 { $$ = nullptr; }
3178 | assertion_list
3179 ;
3180
3181assertion_list: // CFA
3182 assertion
3183 | assertion_list assertion
3184 { $$ = $1->set_last( $2 ); }
3185 ;
3186
3187assertion: // CFA
3188 '|' identifier_or_type_name '(' type_list ')'
3189 { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
3190 | '|' '{' trait_declaration_list '}'
3191 { $$ = $3; }
3192 // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
3193 // { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
3194 ;
3195
3196type_list: // CFA
3197 type
3198 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3199 | assignment_expression
3200 | type_list ',' type
3201 { $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
3202 | type_list ',' assignment_expression
3203 { $$ = $1->set_last( $3 ); }
3204 ;
3205
3206type_declaring_list: // CFA
3207 OTYPE type_declarator
3208 { $$ = $2; }
3209 | storage_class_list OTYPE type_declarator
3210 { $$ = $3->addQualifiers( $1 ); }
3211 | type_declaring_list ',' type_declarator
3212 { $$ = $1->set_last( $3->copySpecifiers( $1 ) ); }
3213 ;
3214
3215type_declarator: // CFA
3216 type_declarator_name assertion_list_opt
3217 { $$ = $1->addAssertions( $2 ); }
3218 | type_declarator_name assertion_list_opt '=' type
3219 { $$ = $1->addAssertions( $2 )->addType( $4 ); }
3220 ;
3221
3222type_declarator_name: // CFA
3223 identifier_or_type_name
3224 {
3225 typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "type_declarator_name 1" );
3226 $$ = DeclarationNode::newTypeDecl( $1, nullptr );
3227 }
3228 | identifier_or_type_name '(' type_parameter_list ')'
3229 {
3230 typedefTable.addToEnclosingScope( *$1, TYPEGENname, "type_declarator_name 2" );
3231 $$ = DeclarationNode::newTypeDecl( $1, $3 );
3232 }
3233 ;
3234
3235trait_specifier: // CFA
3236 TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
3237 {
3238 SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3239 $$ = DeclarationNode::newTrait( $2, $4, nullptr );
3240 }
3241 | forall TRAIT identifier_or_type_name '{' '}' // new alternate
3242 { $$ = DeclarationNode::newTrait( $3, $1, nullptr ); }
3243 | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' trait_declaration_list '}'
3244 {
3245 SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3246 $$ = DeclarationNode::newTrait( $2, $4, $7 );
3247 }
3248 | forall TRAIT identifier_or_type_name '{' trait_declaration_list '}' // alternate
3249 { $$ = DeclarationNode::newTrait( $3, $1, $5 ); }
3250 ;
3251
3252trait_declaration_list: // CFA
3253 trait_declaration
3254 | trait_declaration_list trait_declaration
3255 { $$ = $1->set_last( $2 ); }
3256 ;
3257
3258trait_declaration: // CFA
3259 cfa_trait_declaring_list ';'
3260 | trait_declaring_list ';'
3261 ;
3262
3263cfa_trait_declaring_list: // CFA
3264 cfa_variable_specifier
3265 | cfa_function_specifier
3266 | cfa_trait_declaring_list ',' identifier_or_type_name
3267 { $$ = $1->set_last( $1->cloneType( $3 ) ); }
3268 ;
3269
3270trait_declaring_list: // CFA
3271 // Cannot declare an aggregate or enumeration in a trait.
3272 type_specifier_nobody declarator
3273 { $$ = $2->addType( $1 ); }
3274 | trait_declaring_list ',' declarator
3275 { $$ = $1->set_last( $1->cloneBaseType( $3 ) ); }
3276 | error
3277 { SemanticError( yylloc, "Possible cause is declaring an aggregate or enumeration type in a trait." ); $$ = nullptr; }
3278 ;
3279
3280// **************************** EXTERNAL DEFINITIONS *****************************
3281
3282translation_unit:
3283 // empty, input file
3284 | external_definition_list
3285 { parseTree = parseTree ? parseTree->set_last( $1 ) : $1; }
3286 ;
3287
3288external_definition_list_opt:
3289 // empty
3290 { $$ = nullptr; }
3291 | external_definition_list
3292 ;
3293
3294external_definition_list:
3295 attribute_list_opt push external_definition pop
3296 { distAttr( $1, $3 ); $$ = $3; }
3297 | external_definition_list attribute_list_opt push external_definition pop
3298 { distAttr( $2, $4 ); $$ = $1 ? $1->set_last( $4 ) : $4->addQualifiers( $2 ); }
3299 ;
3300
3301up:
3302 { typedefTable.up( forall ); forall = false; }
3303 ;
3304
3305down:
3306 { typedefTable.down(); }
3307 ;
3308
3309external_definition:
3310 DIRECTIVE
3311 { $$ = DeclarationNode::newDirectiveStmt( new StatementNode( build_directive( yylloc, $1 ) ) ); }
3312 | declaration
3313 {
3314 // Variable declarations of anonymous types requires creating a unique type-name across multiple translation
3315 // unit, which is a dubious task, especially because C uses name rather than structural typing; hence it is
3316 // disallowed at the moment.
3317 if ( $1->linkage == ast::Linkage::Cforall && ! $1->storageClasses.is_static &&
3318 $1->type && $1->type->kind == TypeData::AggregateInst ) {
3319 if ( $1->type->aggInst.aggregate->aggregate.anon ) {
3320 SemanticError( yylloc, "extern anonymous aggregate is currently unimplemented." ); $$ = nullptr;
3321 }
3322 }
3323 }
3324 | IDENTIFIER IDENTIFIER
3325 { IdentifierBeforeIdentifier( *$1.str, *$2.str, " declaration" ); $$ = nullptr; }
3326 | IDENTIFIER type_qualifier // invalid syntax rule
3327 { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
3328 | IDENTIFIER storage_class // invalid syntax rule
3329 { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
3330 | IDENTIFIER basic_type_name // invalid syntax rule
3331 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3332 | IDENTIFIER TYPEDEFname // invalid syntax rule
3333 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3334 | IDENTIFIER TYPEGENname // invalid syntax rule
3335 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3336 | external_function_definition
3337 | EXTENSION external_definition // GCC, multiple __extension__ allowed, meaning unknown
3338 {
3339 distExt( $2 ); // mark all fields in list
3340 $$ = $2;
3341 }
3342 | ASM '(' string_literal ')' ';' // GCC, global assembler statement
3343 { $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( yylloc, false, $3, nullptr ) ) ); }
3344 | EXTERN STRINGliteral
3345 {
3346 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
3347 linkage = ast::Linkage::update( yylloc, linkage, $2 );
3348 }
3349 up external_definition down
3350 {
3351 linkage = linkageStack.top();
3352 linkageStack.pop();
3353 $$ = $5;
3354 }
3355 | EXTERN STRINGliteral // C++-style linkage specifier
3356 {
3357 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
3358 linkage = ast::Linkage::update( yylloc, linkage, $2 );
3359 }
3360 '{' up external_definition_list_opt down '}'
3361 {
3362 linkage = linkageStack.top();
3363 linkageStack.pop();
3364 $$ = $6;
3365 }
3366 // global distribution
3367 | type_qualifier_list
3368 {
3369 if ( $1->type->qualifiers.any() ) {
3370 SemanticError( yylloc, "illegal syntax, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3371 }
3372 if ( $1->type->forall ) forall = true; // remember generic type
3373 }
3374 '{' up external_definition_list_opt down '}' // CFA, namespace
3375 {
3376 distQual( $5, $1 );
3377 forall = false;
3378 $$ = $5;
3379 }
3380 | declaration_qualifier_list
3381 {
3382 if ( $1->type && $1->type->qualifiers.any() ) {
3383 SemanticError( yylloc, "illegal syntax, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3384 }
3385 if ( $1->type && $1->type->forall ) forall = true; // remember generic type
3386 }
3387 '{' up external_definition_list_opt down '}' // CFA, namespace
3388 {
3389 distQual( $5, $1 );
3390 forall = false;
3391 $$ = $5;
3392 }
3393 | declaration_qualifier_list type_qualifier_list
3394 {
3395 if ( ($1->type && $1->type->qualifiers.any()) || ($2->type && $2->type->qualifiers.any()) ) {
3396 SemanticError( yylloc, "illegal syntax, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3397 }
3398 if ( ($1->type && $1->type->forall) || ($2->type && $2->type->forall) ) forall = true; // remember generic type
3399 }
3400 '{' up external_definition_list_opt down '}' // CFA, namespace
3401 {
3402 distQual( $6, $1->addQualifiers( $2 ) );
3403 forall = false;
3404 $$ = $6;
3405 }
3406 | ';' // empty declaration
3407 { $$ = nullptr; }
3408 ;
3409
3410external_function_definition:
3411 function_definition
3412 // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
3413 // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
3414 // Parsing is possible because function_definition does not appear in the context of an expression (nested
3415 // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
3416 // declaration must still have a type_specifier. OBSOLESCENT (see 1)
3417 | function_declarator compound_statement
3418 { $$ = $1->addFunctionBody( $2 ); }
3419 | KR_function_declarator KR_parameter_list_opt compound_statement
3420 { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
3421 ;
3422
3423with_clause_opt:
3424 // empty
3425 { $$ = nullptr; forall = false; }
3426 | WITH '(' type_list ')' attribute_list_opt // support scoped enumeration
3427 {
3428 $$ = $3; forall = false;
3429 if ( $5 ) {
3430 SemanticError( yylloc, "illegal syntax, attributes cannot be associated with function body. Move attribute(s) before \"with\" clause." );
3431 $$ = nullptr;
3432 } // if
3433 }
3434 ;
3435
3436function_definition:
3437 cfa_function_declaration with_clause_opt compound_statement // CFA
3438 {
3439 // Add the function body to the last identifier in the function definition list, i.e., foo3:
3440 // [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
3441 $1->get_last()->addFunctionBody( $3, $2 );
3442 $$ = $1;
3443 }
3444 | declaration_specifier function_declarator with_clause_opt compound_statement
3445 {
3446 rebindForall( $1, $2 );
3447 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3448 }
3449 | declaration_specifier function_type_redeclarator with_clause_opt compound_statement
3450 {
3451 rebindForall( $1, $2 );
3452 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3453 }
3454 // handles default int return type, OBSOLESCENT (see 1)
3455 | type_qualifier_list function_declarator with_clause_opt compound_statement
3456 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3457 // handles default int return type, OBSOLESCENT (see 1)
3458 | declaration_qualifier_list function_declarator with_clause_opt compound_statement
3459 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3460 // handles default int return type, OBSOLESCENT (see 1)
3461 | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
3462 { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3463
3464 // Old-style K&R function definition, OBSOLESCENT (see 4)
3465 | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3466 {
3467 rebindForall( $1, $2 );
3468 $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
3469 }
3470 // handles default int return type, OBSOLESCENT (see 1)
3471 | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3472 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3473 // handles default int return type, OBSOLESCENT (see 1)
3474 | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3475 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3476 // handles default int return type, OBSOLESCENT (see 1)
3477 | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3478 { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3479 ;
3480
3481declarator:
3482 variable_declarator
3483 | variable_type_redeclarator
3484 | function_declarator
3485 | function_type_redeclarator
3486 ;
3487
3488subrange:
3489 constant_expression '~' constant_expression // CFA, integer subrange
3490 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
3491 ;
3492
3493// **************************** ASM *****************************
3494
3495asm_name_opt: // GCC
3496 // empty
3497 { $$ = nullptr; }
3498 | ASM '(' string_literal ')' attribute_list_opt
3499 {
3500 DeclarationNode * name = new DeclarationNode();
3501 name->asmName = maybeMoveBuild( $3 );
3502 $$ = name->addQualifiers( $5 );
3503 }
3504 ;
3505
3506// **************************** ATTRIBUTE *****************************
3507
3508attribute_list_opt: // GCC
3509 // empty
3510 { $$ = nullptr; }
3511 | attribute_list
3512 ;
3513
3514attribute_list: // GCC
3515 attribute
3516 | attribute_list attribute
3517 { $$ = $2->addQualifiers( $1 ); }
3518 ;
3519
3520attribute: // GCC
3521 ATTRIBUTE '(' '(' attribute_name_list ')' ')'
3522 { $$ = $4; }
3523 | ATTRIBUTE '(' attribute_name_list ')' // CFA
3524 { $$ = $3; }
3525 | ATTR attribute_name_list ']' // CFA, @[...]
3526 { $$ = $2; }
3527 | C23_ATTRIBUTE // C23, [[...]], see lexer
3528 { $$ = DeclarationNode::newAttribute( $1 ); }
3529 ;
3530
3531attribute_name_list: // GCC
3532 attribute_name
3533 | attribute_name_list ',' attribute_name
3534 { $$ = $3->addQualifiers( $1 ); }
3535 ;
3536
3537attribute_name: // GCC
3538 // empty
3539 { $$ = nullptr; }
3540 | attr_name
3541 { $$ = DeclarationNode::newAttribute( $1 ); }
3542 | attr_name '(' argument_expression_list_opt ')'
3543 { $$ = DeclarationNode::newAttribute( $1, $3 ); }
3544 ;
3545
3546attr_name: // GCC
3547 identifier_or_type_name
3548 | FALLTHROUGH
3549 { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
3550 | CONST
3551 { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
3552 ;
3553
3554// ============================================================================
3555// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
3556// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
3557// in:
3558//
3559// int (*f())[10] { ... };
3560// ... (*f())[3] += 1; // definition mimics usage
3561//
3562// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
3563// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
3564// ============================================================================
3565
3566// ----------------------------------------------------------------------------
3567// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
3568// to define a variable or function prototype, e.g.:
3569//
3570// valid declaration invalid definition
3571// ----------------- ------------------
3572// int f; int f {}
3573// int *f; int *f {}
3574// int f[10]; int f[10] {}
3575// int (*f)(int); int (*f)(int) {}
3576//
3577// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
3578// variable_declarator and function_declarator.
3579// ----------------------------------------------------------------------------
3580
3581// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
3582// declaring an array of functions versus a pointer to an array of functions.
3583
3584paren_identifier:
3585 identifier_at
3586 { $$ = DeclarationNode::newName( $1 ); }
3587 | '?' identifier
3588 // { SemanticError( yylloc, "keyword parameter is currently unimplemented." ); $$ = nullptr; }
3589 { $$ = DeclarationNode::newName( $2 ); }
3590 | '(' paren_identifier ')' // redundant parenthesis
3591 { $$ = $2; }
3592 ;
3593
3594variable_declarator:
3595 paren_identifier attribute_list_opt
3596 { $$ = $1->addQualifiers( $2 ); }
3597 | variable_ptr
3598 | variable_array attribute_list_opt
3599 { $$ = $1->addQualifiers( $2 ); }
3600 | variable_function attribute_list_opt
3601 { $$ = $1->addQualifiers( $2 ); }
3602 ;
3603
3604variable_ptr:
3605 ptrref_operator variable_declarator
3606 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3607 | ptrref_operator attribute_list variable_declarator
3608 { $$ = $3->addPointer( DeclarationNode::newPointer( nullptr, $1 ) )->addQualifiers( $2 ); }
3609 | ptrref_operator type_qualifier_list variable_declarator
3610 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3611 | '(' variable_ptr ')' attribute_list_opt // redundant parenthesis
3612 { $$ = $2->addQualifiers( $4 ); }
3613 | '(' attribute_list variable_ptr ')' attribute_list_opt // redundant parenthesis
3614 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3615 ;
3616
3617variable_array:
3618 paren_identifier array_dimension
3619 { $$ = $1->addArray( $2 ); }
3620 | '(' variable_ptr ')' array_dimension
3621 { $$ = $2->addArray( $4 ); }
3622 | '(' attribute_list variable_ptr ')' array_dimension
3623 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3624 | '(' variable_array ')' multi_array_dimension // redundant parenthesis
3625 { $$ = $2->addArray( $4 ); }
3626 | '(' attribute_list variable_array ')' multi_array_dimension // redundant parenthesis
3627 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3628 | '(' variable_array ')' // redundant parenthesis
3629 { $$ = $2; }
3630 | '(' attribute_list variable_array ')' // redundant parenthesis
3631 { $$ = $3->addQualifiers( $2 ); }
3632 ;
3633
3634variable_function:
3635 '(' variable_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3636 { $$ = $2->addParamList( $5 ); }
3637 | '(' attribute_list variable_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3638 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3639 | '(' variable_function ')' // redundant parenthesis
3640 { $$ = $2; }
3641 | '(' attribute_list variable_function ')' // redundant parenthesis
3642 { $$ = $3->addQualifiers( $2 ); }
3643 ;
3644
3645// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
3646// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
3647// is the same scope. The pattern precludes returning arrays and functions versus pointers to arrays and functions.
3648
3649function_declarator:
3650 function_no_ptr attribute_list_opt
3651 { $$ = $1->addQualifiers( $2 ); }
3652 | function_ptr
3653 | function_array attribute_list_opt
3654 { $$ = $1->addQualifiers( $2 ); }
3655 ;
3656
3657function_no_ptr:
3658 paren_identifier '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3659 { $$ = $1->addParamList( $3 ); }
3660 | '(' function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3661 { $$ = $2->addParamList( $5 ); }
3662 | '(' attribute_list function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3663 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3664 | '(' function_no_ptr ')' // redundant parenthesis
3665 { $$ = $2; }
3666 | '(' attribute_list function_no_ptr ')' // redundant parenthesis
3667 { $$ = $3->addQualifiers( $2 ); }
3668 ;
3669
3670function_ptr:
3671 ptrref_operator function_declarator
3672 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3673 | ptrref_operator attribute_list function_declarator
3674 { $$ = $3->addPointer( DeclarationNode::newPointer( nullptr, $1 ) )->addQualifiers( $2 ); }
3675 | ptrref_operator type_qualifier_list function_declarator
3676 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3677 | '(' function_ptr ')' attribute_list_opt
3678 { $$ = $2->addQualifiers( $4 ); }
3679 | '(' attribute_list function_ptr ')' attribute_list_opt
3680 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3681 ;
3682
3683function_array:
3684 '(' function_ptr ')' array_dimension
3685 { $$ = $2->addArray( $4 ); }
3686 | '(' attribute_list function_ptr ')' array_dimension
3687 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3688 | '(' function_array ')' multi_array_dimension // redundant parenthesis
3689 { $$ = $2->addArray( $4 ); }
3690 | '(' attribute_list function_array ')' multi_array_dimension // redundant parenthesis
3691 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3692 | '(' function_array ')' // redundant parenthesis
3693 { $$ = $2; }
3694 | '(' attribute_list function_array ')' // redundant parenthesis
3695 { $$ = $3->addQualifiers( $2 ); }
3696 ;
3697
3698// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
3699//
3700// f( a, b, c ) int a, *b, c[]; {}
3701//
3702// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
3703// returning arrays and functions versus pointers to arrays and functions.
3704
3705KR_function_declarator:
3706 KR_function_no_ptr
3707 | KR_function_ptr
3708 | KR_function_array
3709 ;
3710
3711KR_function_no_ptr:
3712 paren_identifier '(' identifier_list ')' // function_declarator handles empty parameter
3713 { $$ = $1->addIdList( $3 ); }
3714 | '(' KR_function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3715 { $$ = $2->addParamList( $5 ); }
3716 | '(' attribute_list KR_function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3717 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3718 | '(' KR_function_no_ptr ')' // redundant parenthesis
3719 { $$ = $2; }
3720 | '(' attribute_list KR_function_no_ptr ')' // redundant parenthesis
3721 { $$ = $3->addQualifiers( $2 ); }
3722 ;
3723
3724KR_function_ptr:
3725 ptrref_operator KR_function_declarator
3726 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3727 | ptrref_operator attribute_list KR_function_declarator
3728 { $$ = $3->addPointer( DeclarationNode::newPointer( nullptr, $1 ) )->addQualifiers( $2 ); }
3729 | ptrref_operator type_qualifier_list KR_function_declarator
3730 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3731 | '(' KR_function_ptr ')'
3732 { $$ = $2; }
3733 | '(' attribute_list KR_function_ptr ')'
3734 { $$ = $3->addQualifiers( $2 ); }
3735 ;
3736
3737KR_function_array:
3738 '(' KR_function_ptr ')' array_dimension
3739 { $$ = $2->addArray( $4 ); }
3740 | '(' attribute_list KR_function_ptr ')' array_dimension
3741 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3742 | '(' KR_function_array ')' multi_array_dimension // redundant parenthesis
3743 { $$ = $2->addArray( $4 ); }
3744 | '(' attribute_list KR_function_array ')' multi_array_dimension // redundant parenthesis
3745 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3746 | '(' KR_function_array ')' // redundant parenthesis
3747 { $$ = $2; }
3748 | '(' attribute_list KR_function_array ')' // redundant parenthesis
3749 { $$ = $3->addQualifiers( $2 ); }
3750 ;
3751
3752// This pattern parses a declaration for a variable that redefines a type name, e.g.:
3753//
3754// typedef int foo;
3755// {
3756// int foo; // redefine typedef name in new scope
3757// }
3758
3759paren_type:
3760 typedef_name
3761 {
3762 // hide type name in enclosing scope by variable name
3763 typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "paren_type" );
3764 }
3765 | '(' paren_type ')'
3766 { $$ = $2; }
3767 ;
3768
3769variable_type_redeclarator:
3770 paren_type attribute_list_opt
3771 { $$ = $1->addQualifiers( $2 ); }
3772 | variable_type_ptr
3773 | variable_type_array attribute_list_opt
3774 { $$ = $1->addQualifiers( $2 ); }
3775 | variable_type_function attribute_list_opt
3776 { $$ = $1->addQualifiers( $2 ); }
3777 ;
3778
3779variable_type_ptr:
3780 ptrref_operator variable_type_redeclarator
3781 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3782 | ptrref_operator attribute_list variable_type_redeclarator
3783 { $$ = $3->addPointer( DeclarationNode::newPointer( nullptr, $1 ) )->addQualifiers( $2 ); }
3784 | ptrref_operator type_qualifier_list variable_type_redeclarator
3785 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3786 | '(' variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3787 { $$ = $2->addQualifiers( $4 ); }
3788 | '(' attribute_list variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3789 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3790 ;
3791
3792variable_type_array:
3793 paren_type array_dimension
3794 { $$ = $1->addArray( $2 ); }
3795 | '(' variable_type_ptr ')' array_dimension
3796 { $$ = $2->addArray( $4 ); }
3797 | '(' attribute_list variable_type_ptr ')' array_dimension
3798 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3799 | '(' variable_type_array ')' multi_array_dimension // redundant parenthesis
3800 { $$ = $2->addArray( $4 ); }
3801 | '(' attribute_list variable_type_array ')' multi_array_dimension // redundant parenthesis
3802 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3803 | '(' variable_type_array ')' // redundant parenthesis
3804 { $$ = $2; }
3805 | '(' attribute_list variable_type_array ')' // redundant parenthesis
3806 { $$ = $3->addQualifiers( $2 ); }
3807 ;
3808
3809variable_type_function:
3810 '(' variable_type_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3811 { $$ = $2->addParamList( $5 ); }
3812 | '(' attribute_list variable_type_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3813 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3814 | '(' variable_type_function ')' // redundant parenthesis
3815 { $$ = $2; }
3816 | '(' attribute_list variable_type_function ')' // redundant parenthesis
3817 { $$ = $3->addQualifiers( $2 ); }
3818 ;
3819
3820// This pattern parses a declaration for a function prototype that redefines a type name. It precludes declaring an
3821// array of functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to
3822// arrays and functions.
3823
3824function_type_redeclarator:
3825 function_type_no_ptr attribute_list_opt
3826 { $$ = $1->addQualifiers( $2 ); }
3827 | function_type_ptr
3828 | function_type_array attribute_list_opt
3829 { $$ = $1->addQualifiers( $2 ); }
3830 ;
3831
3832function_type_no_ptr:
3833 paren_type '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3834 { $$ = $1->addParamList( $3 ); }
3835 | '(' function_type_ptr ')' '(' parameter_list_ellipsis_opt ')'
3836 { $$ = $2->addParamList( $5 ); }
3837 | '(' attribute_list function_type_ptr ')' '(' parameter_list_ellipsis_opt ')'
3838 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3839 | '(' function_type_no_ptr ')' // redundant parenthesis
3840 { $$ = $2; }
3841 | '(' attribute_list function_type_no_ptr ')' // redundant parenthesis
3842 { $$ = $3->addQualifiers( $2 ); }
3843 ;
3844
3845function_type_ptr:
3846 ptrref_operator function_type_redeclarator
3847 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3848 | ptrref_operator attribute_list function_type_redeclarator
3849 { $$ = $3->addPointer( DeclarationNode::newPointer( nullptr, $1 ) )->addQualifiers( $2 ); }
3850 | ptrref_operator type_qualifier_list function_type_redeclarator
3851 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3852 | '(' function_type_ptr ')' attribute_list_opt
3853 { $$ = $2->addQualifiers( $4 ); }
3854 | '(' attribute_list function_type_ptr ')' attribute_list_opt
3855 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3856 ;
3857
3858function_type_array:
3859 '(' function_type_ptr ')' array_dimension
3860 { $$ = $2->addArray( $4 ); }
3861 | '(' attribute_list function_type_ptr ')' array_dimension
3862 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3863 | '(' function_type_array ')' multi_array_dimension // redundant parenthesis
3864 { $$ = $2->addArray( $4 ); }
3865 | '(' attribute_list function_type_array ')' multi_array_dimension // redundant parenthesis
3866 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3867 | '(' function_type_array ')' // redundant parenthesis
3868 { $$ = $2; }
3869 | '(' attribute_list function_type_array ')' // redundant parenthesis
3870 { $$ = $3->addQualifiers( $2 ); }
3871 ;
3872
3873// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
3874// typedef name and allows the C99 array options, which can only appear in a parameter list. The pattern precludes
3875// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
3876// pointers to arrays and functions.
3877
3878identifier_parameter_declarator:
3879 paren_identifier attribute_list_opt
3880 { $$ = $1->addQualifiers( $2 ); }
3881 | '&' MUTEX paren_identifier attribute_list_opt
3882 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
3883 OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3884 | identifier_parameter_ptr
3885 | identifier_parameter_array attribute_list_opt
3886 { $$ = $1->addQualifiers( $2 ); }
3887 | identifier_parameter_function attribute_list_opt
3888 { $$ = $1->addQualifiers( $2 ); }
3889 ;
3890
3891identifier_parameter_ptr:
3892 ptrref_operator identifier_parameter_declarator
3893 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3894 | ptrref_operator attribute_list identifier_parameter_declarator
3895 { $$ = $3->addPointer( DeclarationNode::newPointer( nullptr, $1 ) )->addQualifiers( $2 ); }
3896 | ptrref_operator type_qualifier_list identifier_parameter_declarator
3897 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3898 | '(' identifier_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3899 { $$ = $2->addQualifiers( $4 ); }
3900 ;
3901
3902identifier_parameter_array:
3903 paren_identifier array_parameter_dimension
3904 { $$ = $1->addArray( $2 ); }
3905 | '(' identifier_parameter_ptr ')' array_dimension
3906 { $$ = $2->addArray( $4 ); }
3907 | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3908 { $$ = $2->addArray( $4 ); }
3909 | '(' identifier_parameter_array ')' // redundant parenthesis
3910 { $$ = $2; }
3911 ;
3912
3913identifier_parameter_function:
3914 paren_identifier '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3915 { $$ = $1->addParamList( $3 ); }
3916 | '(' identifier_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3917 { $$ = $2->addParamList( $5 ); }
3918 | '(' identifier_parameter_function ')' // redundant parenthesis
3919 { $$ = $2; }
3920 ;
3921
3922// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3923// e.g.:
3924//
3925// typedef int foo;
3926// forall( otype T ) struct foo;
3927// int f( int foo ); // redefine typedef name in new scope
3928//
3929// and allows the C99 array options, which can only appear in a parameter list.
3930
3931type_parameter_redeclarator:
3932 typedef_name attribute_list_opt
3933 { $$ = $1->addQualifiers( $2 ); }
3934 | '&' MUTEX typedef_name attribute_list_opt
3935 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
3936 OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3937 | type_parameter_ptr
3938 | type_parameter_array attribute_list_opt
3939 { $$ = $1->addQualifiers( $2 ); }
3940 | type_parameter_function attribute_list_opt
3941 { $$ = $1->addQualifiers( $2 ); }
3942 ;
3943
3944typedef_name:
3945 TYPEDEFname
3946 { $$ = DeclarationNode::newName( $1 ); }
3947 | TYPEGENname
3948 { $$ = DeclarationNode::newName( $1 ); }
3949 ;
3950
3951type_parameter_ptr:
3952 ptrref_operator type_parameter_redeclarator
3953 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3954 | ptrref_operator attribute_list type_parameter_redeclarator
3955 { $$ = $3->addPointer( DeclarationNode::newPointer( nullptr, $1 ) )->addQualifiers( $2 ); }
3956 | ptrref_operator type_qualifier_list type_parameter_redeclarator
3957 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3958 | '(' type_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3959 { $$ = $2->addQualifiers( $4 ); }
3960 ;
3961
3962type_parameter_array:
3963 typedef_name array_parameter_dimension
3964 { $$ = $1->addArray( $2 ); }
3965 | '(' type_parameter_ptr ')' array_parameter_dimension
3966 { $$ = $2->addArray( $4 ); }
3967 ;
3968
3969type_parameter_function:
3970 typedef_name '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3971 { $$ = $1->addParamList( $3 ); }
3972 | '(' type_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3973 { $$ = $2->addParamList( $5 ); }
3974 ;
3975
3976// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3977// which the type applies, e.g.:
3978//
3979// sizeof( int );
3980// sizeof( int * );
3981// sizeof( int [10] );
3982// sizeof( int (*)() );
3983// sizeof( int () );
3984//
3985// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3986// and functions versus pointers to arrays and functions.
3987
3988abstract_declarator:
3989 abstract_ptr
3990 | abstract_array attribute_list_opt
3991 { $$ = $1->addQualifiers( $2 ); }
3992 | abstract_function attribute_list_opt
3993 { $$ = $1->addQualifiers( $2 ); }
3994 ;
3995
3996abstract_ptr:
3997 ptrref_operator attribute_list_opt
3998 { $$ = DeclarationNode::newPointer( nullptr, $1 )->addQualifiers( $2 ); }
3999 | ptrref_operator type_qualifier_list
4000 { $$ = DeclarationNode::newPointer( $2, $1 ); }
4001 | ptrref_operator abstract_declarator
4002 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4003 | ptrref_operator attribute_list abstract_declarator
4004 { $$ = $3->addPointer( DeclarationNode::newPointer( nullptr, $1 )->addQualifiers( $2 ) ); }
4005 | ptrref_operator type_qualifier_list abstract_declarator
4006 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4007 | '(' abstract_ptr ')' attribute_list_opt
4008 { $$ = $2->addQualifiers( $4 ); }
4009 ;
4010
4011abstract_array:
4012 array_dimension
4013 | '(' abstract_ptr ')' array_dimension
4014 { $$ = $2->addArray( $4 ); }
4015 | '(' abstract_array ')' multi_array_dimension // redundant parenthesis
4016 { $$ = $2->addArray( $4 ); }
4017 | '(' abstract_array ')' // redundant parenthesis
4018 { $$ = $2; }
4019 ;
4020
4021abstract_function:
4022 '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4023 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
4024 | '(' abstract_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4025 { $$ = $2->addParamList( $5 ); }
4026 | '(' abstract_function ')' // redundant parenthesis
4027 { $$ = $2; }
4028 ;
4029
4030array_dimension:
4031 // Only the first dimension can be empty.
4032 '[' ']'
4033 { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
4034 | '[' ']' multi_array_dimension
4035 { $$ = DeclarationNode::newArray( nullptr, nullptr, false )->addArray( $3 ); }
4036 // Cannot use constant_expression because of tuples => semantic check
4037 | '[' assignment_expression ',' comma_expression ']' // CFA
4038 { $$ = DeclarationNode::newArray( $2, nullptr, false )->addArray( DeclarationNode::newArray( $4, nullptr, false ) ); }
4039 // { SemanticError( yylloc, "New array dimension is currently unimplemented." ); $$ = nullptr; }
4040
4041 // If needed, the following parses and does not use comma_expression, so the array structure can be built.
4042 // | '[' push assignment_expression pop ',' push array_dimension_list pop ']' // CFA
4043
4044 | '[' array_type_list ']' // CFA
4045 { $$ = DeclarationNode::newArray( $2, nullptr, false ); }
4046 | multi_array_dimension
4047 ;
4048
4049// array_dimension_list:
4050// assignment_expression
4051// | array_dimension_list ',' assignment_expression
4052// ;
4053
4054array_type_list:
4055 basic_type_name
4056 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
4057 | type_name
4058 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
4059 | assignment_expression upupeq assignment_expression
4060 | array_type_list ',' basic_type_name
4061 { $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
4062 | array_type_list ',' type_name
4063 { $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
4064 | array_type_list ',' assignment_expression upupeq assignment_expression
4065 ;
4066
4067upupeq:
4068 '~'
4069 { $$ = OperKinds::LThan; }
4070 | ErangeUpLe
4071 { $$ = OperKinds::LEThan; }
4072 ;
4073
4074multi_array_dimension:
4075 '[' assignment_expression ']'
4076 { $$ = DeclarationNode::newArray( $2, nullptr, false ); }
4077 | '[' '*' ']' // C99
4078 { $$ = DeclarationNode::newVarArray( 0 ); }
4079 | multi_array_dimension '[' assignment_expression ']'
4080 { $$ = $1->addArray( DeclarationNode::newArray( $3, nullptr, false ) ); }
4081 | multi_array_dimension '[' '*' ']' // C99
4082 { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
4083 ;
4084
4085// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
4086// identifier to which the type applies, e.g.:
4087//
4088// int f( int ); // not handled here
4089// int f( int * ); // abstract function-prototype parameter; no parameter name specified
4090// int f( int (*)() ); // abstract function-prototype parameter; no parameter name specified
4091// int f( int (int) ); // abstract function-prototype parameter; no parameter name specified
4092//
4093// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
4094// and functions versus pointers to arrays and functions. In addition, the pattern handles the special meaning of
4095// parenthesis around a typedef name:
4096//
4097// ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
4098// parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
4099// not as redundant parentheses around the identifier."
4100//
4101// For example:
4102//
4103// typedef float T;
4104// int f( int ( T [5] ) ); // see abstract_parameter_declarator
4105// int g( int ( T ( int ) ) ); // see abstract_parameter_declarator
4106// int f( int f1( T a[5] ) ); // see identifier_parameter_declarator
4107// int g( int g1( T g2( int p ) ) ); // see identifier_parameter_declarator
4108//
4109// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
4110// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
4111// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
4112// functions.
4113
4114abstract_parameter_declarator_opt:
4115 // empty
4116 { $$ = nullptr; }
4117 | abstract_parameter_declarator
4118 ;
4119
4120abstract_parameter_declarator:
4121 abstract_parameter_ptr
4122 | '&' MUTEX attribute_list_opt
4123 { $$ = DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
4124 OperKinds::AddressOf )->addQualifiers( $3 ); }
4125 | abstract_parameter_array attribute_list_opt
4126 { $$ = $1->addQualifiers( $2 ); }
4127 | abstract_parameter_function attribute_list_opt
4128 { $$ = $1->addQualifiers( $2 ); }
4129 ;
4130
4131abstract_parameter_ptr:
4132 ptrref_operator attribute_list_opt
4133 { $$ = DeclarationNode::newPointer( nullptr, $1 )->addQualifiers( $2 ); }
4134 | ptrref_operator type_qualifier_list
4135 { $$ = DeclarationNode::newPointer( $2, $1 ); }
4136 | ptrref_operator abstract_parameter_declarator
4137 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4138 | ptrref_operator type_qualifier_list abstract_parameter_declarator
4139 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4140 | '(' abstract_parameter_ptr ')' attribute_list_opt // redundant parenthesis
4141 { $$ = $2->addQualifiers( $4 ); }
4142 ;
4143
4144abstract_parameter_array:
4145 array_parameter_dimension
4146 | '(' abstract_parameter_ptr ')' array_parameter_dimension
4147 { $$ = $2->addArray( $4 ); }
4148 | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
4149 { $$ = $2->addArray( $4 ); }
4150 | '(' abstract_parameter_array ')' // redundant parenthesis
4151 { $$ = $2; }
4152 ;
4153
4154abstract_parameter_function:
4155 '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4156 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
4157 | '(' abstract_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4158 { $$ = $2->addParamList( $5 ); }
4159 | '(' abstract_parameter_function ')' // redundant parenthesis
4160 { $$ = $2; }
4161 ;
4162
4163array_parameter_dimension:
4164 // Only the first dimension can be empty or have qualifiers.
4165 array_parameter_1st_dimension
4166 | array_parameter_1st_dimension multi_array_dimension
4167 { $$ = $1->addArray( $2 ); }
4168 | multi_array_dimension
4169 ;
4170
4171// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
4172//
4173// ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
4174// a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
4175
4176array_parameter_1st_dimension:
4177 '[' ']'
4178 { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
4179 // multi_array_dimension handles the '[' '*' ']' case
4180 | '[' push type_qualifier_list '*' pop ']' // remaining C99
4181 { $$ = DeclarationNode::newVarArray( $3 ); }
4182 | '[' push type_qualifier_list pop ']'
4183 { $$ = DeclarationNode::newArray( nullptr, $3, false ); }
4184 // multi_array_dimension handles the '[' assignment_expression ']' case
4185 | '[' push type_qualifier_list assignment_expression pop ']'
4186 { $$ = DeclarationNode::newArray( $4, $3, false ); }
4187 | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
4188 { $$ = DeclarationNode::newArray( $5, $4, true ); }
4189 | '[' push type_qualifier_list STATIC assignment_expression pop ']'
4190 { $$ = DeclarationNode::newArray( $5, $3, true ); }
4191 ;
4192
4193// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
4194//
4195// struct S {
4196// int;
4197// int *;
4198// int [10];
4199// int (*)();
4200// };
4201
4202variable_abstract_declarator:
4203 variable_abstract_ptr
4204 | variable_abstract_array attribute_list_opt
4205 { $$ = $1->addQualifiers( $2 ); }
4206 | variable_abstract_function attribute_list_opt
4207 { $$ = $1->addQualifiers( $2 ); }
4208 ;
4209
4210variable_abstract_ptr:
4211 ptrref_operator attribute_list_opt
4212 { $$ = DeclarationNode::newPointer( nullptr, $1 )->addQualifiers( $2 ); }
4213 | ptrref_operator type_qualifier_list
4214 { $$ = DeclarationNode::newPointer( $2, $1 ); }
4215 | ptrref_operator variable_abstract_declarator
4216 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4217 | ptrref_operator type_qualifier_list variable_abstract_declarator
4218 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4219 | '(' variable_abstract_ptr ')' attribute_list_opt // redundant parenthesis
4220 { $$ = $2->addQualifiers( $4 ); }
4221 ;
4222
4223variable_abstract_array:
4224 array_dimension
4225 | '(' variable_abstract_ptr ')' array_dimension
4226 { $$ = $2->addArray( $4 ); }
4227 | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
4228 { $$ = $2->addArray( $4 ); }
4229 | '(' variable_abstract_array ')' // redundant parenthesis
4230 { $$ = $2; }
4231 ;
4232
4233variable_abstract_function:
4234 '(' variable_abstract_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4235 { $$ = $2->addParamList( $5 ); }
4236 | '(' variable_abstract_function ')' // redundant parenthesis
4237 { $$ = $2; }
4238 ;
4239
4240// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
4241// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
4242
4243cfa_identifier_parameter_declarator_tuple: // CFA
4244 cfa_identifier_parameter_declarator_no_tuple
4245 | cfa_abstract_tuple
4246 | type_qualifier_list cfa_abstract_tuple
4247 { $$ = $2->addQualifiers( $1 ); }
4248 ;
4249
4250cfa_identifier_parameter_declarator_no_tuple: // CFA
4251 cfa_identifier_parameter_ptr
4252 | cfa_identifier_parameter_array
4253 | type_qualifier_list cfa_identifier_parameter_array
4254 { $$ = $2->addQualifiers( $1 ); }
4255 ;
4256
4257cfa_identifier_parameter_ptr: // CFA
4258 // No SUE declaration in parameter list.
4259 ptrref_operator type_specifier_nobody
4260 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4261 | ptrref_operator attribute_list type_specifier_nobody
4262 { $$ = $3->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) )->addQualifiers( $2 ); }
4263 | type_qualifier_list ptrref_operator type_specifier_nobody
4264 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4265 | ptrref_operator cfa_abstract_function
4266 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4267 | type_qualifier_list ptrref_operator cfa_abstract_function
4268 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4269 | ptrref_operator cfa_identifier_parameter_declarator_tuple
4270 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4271 | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
4272 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4273 ;
4274
4275cfa_identifier_parameter_array: // CFA
4276 // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
4277 // shift/reduce conflict with new-style empty (void) function return type.
4278 '[' ']' type_specifier_nobody
4279 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4280 | '[' ']' cfa_abstract_tuple
4281 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4282 | cfa_array_parameter_1st_dimension type_specifier_nobody
4283 { $$ = $2->addNewArray( $1 ); }
4284 | cfa_array_parameter_1st_dimension cfa_abstract_tuple
4285 { $$ = $2->addNewArray( $1 ); }
4286 | '[' ']' multi_array_dimension type_specifier_nobody
4287 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4288 | '[' ']' multi_array_dimension cfa_abstract_tuple
4289 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4290 | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
4291 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4292 | cfa_array_parameter_1st_dimension multi_array_dimension cfa_abstract_tuple
4293 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4294 | multi_array_dimension type_specifier_nobody
4295 { $$ = $2->addNewArray( $1 ); }
4296 | multi_array_dimension cfa_abstract_tuple
4297 { $$ = $2->addNewArray( $1 ); }
4298
4299 | '[' ']' cfa_identifier_parameter_ptr
4300 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4301 | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
4302 { $$ = $2->addNewArray( $1 ); }
4303 | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
4304 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4305 | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
4306 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4307 | multi_array_dimension cfa_identifier_parameter_ptr
4308 { $$ = $2->addNewArray( $1 ); }
4309 ;
4310
4311cfa_array_parameter_1st_dimension:
4312 '[' type_qualifier_list '*' ']' // remaining C99
4313 { $$ = DeclarationNode::newVarArray( $2 ); }
4314 | '[' type_qualifier_list assignment_expression ']'
4315 { $$ = DeclarationNode::newArray( $3, $2, false ); }
4316 | '[' declaration_qualifier_list assignment_expression ']'
4317 // declaration_qualifier_list must be used because of shift/reduce conflict with
4318 // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
4319 // appear in this context.
4320 { $$ = DeclarationNode::newArray( $3, $2, true ); }
4321 | '[' declaration_qualifier_list type_qualifier_list assignment_expression ']'
4322 { $$ = DeclarationNode::newArray( $4, $3->addQualifiers( $2 ), true ); }
4323 ;
4324
4325// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
4326// identifier to which the type applies, e.g.:
4327//
4328// [int] f( int ); // abstract variable parameter; no parameter name specified
4329// [int] f( [int] (int) ); // abstract function-prototype parameter; no parameter name specified
4330//
4331// These rules need LR(3):
4332//
4333// cfa_abstract_tuple identifier_or_type_name
4334// '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_list_ellipsis_opt ')'
4335//
4336// since a function return type can be syntactically identical to a tuple type:
4337//
4338// [int, int] t;
4339// [int, int] f( int );
4340//
4341// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
4342// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
4343// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
4344// duplicated when appearing with cfa_function_specifier.
4345
4346cfa_abstract_declarator_tuple: // CFA
4347 cfa_abstract_tuple
4348 | type_qualifier_list cfa_abstract_tuple
4349 { $$ = $2->addQualifiers( $1 ); }
4350 | cfa_abstract_declarator_no_tuple
4351 ;
4352
4353cfa_abstract_declarator_no_tuple: // CFA
4354 cfa_abstract_ptr
4355 | cfa_abstract_array
4356 ;
4357
4358cfa_abstract_ptr: // CFA
4359 ptrref_operator type_specifier
4360 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4361 | ptrref_operator attribute_list type_specifier
4362 { $$ = $3->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) )->addQualifiers( $2 ); }
4363 | type_qualifier_list ptrref_operator type_specifier
4364 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4365 | ptrref_operator cfa_abstract_function
4366 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4367 | type_qualifier_list ptrref_operator cfa_abstract_function
4368 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4369 | ptrref_operator cfa_abstract_declarator_tuple
4370 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4371 | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
4372 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4373 ;
4374
4375cfa_abstract_array: // CFA
4376 // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
4377 // empty (void) function return type.
4378 '[' ']' type_specifier
4379 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4380 | '[' ']' multi_array_dimension type_specifier
4381 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4382 | multi_array_dimension type_specifier
4383 { $$ = $2->addNewArray( $1 ); }
4384 | '[' ']' cfa_abstract_ptr
4385 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4386 | '[' ']' multi_array_dimension cfa_abstract_ptr
4387 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4388 | multi_array_dimension cfa_abstract_ptr
4389 { $$ = $2->addNewArray( $1 ); }
4390 ;
4391
4392cfa_abstract_tuple: // CFA
4393 '[' cfa_abstract_parameter_list ']'
4394 { $$ = DeclarationNode::newTuple( $2 ); }
4395 | '[' type_specifier_nobody ELLIPSIS ']'
4396 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4397 | '[' type_specifier_nobody ELLIPSIS constant_expression ']'
4398 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4399 ;
4400
4401cfa_abstract_function: // CFA
4402 '[' ']' '(' cfa_parameter_list_ellipsis_opt ')'
4403 { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
4404 | cfa_abstract_tuple '(' push cfa_parameter_list_ellipsis_opt pop ')'
4405 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4406 | cfa_function_return '(' push cfa_parameter_list_ellipsis_opt pop ')'
4407 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4408 ;
4409
4410// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
4411// each declaration, and in the specifier-qualifier list in each structure declaration and type name."
4412//
4413// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
4414// the declaration specifiers in a declaration is an obsolescent feature."
4415//
4416// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
4417// prototype-format parameter type declarators) is an obsolescent feature."
4418//
4419// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
4420// declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
4421
4422// ************************ MISCELLANEOUS ********************************
4423
4424comma_opt: // redundant comma
4425 // empty
4426 | ','
4427 ;
4428
4429default_initializer_opt:
4430 // empty
4431 { $$ = nullptr; }
4432 | '=' assignment_expression
4433 { $$ = $2; }
4434 ;
4435
4436%%
4437
4438// ----end of grammar----
4439
4440// Local Variables: //
4441// mode: c++ //
4442// tab-width: 4 //
4443// compile-command: "bison -Wcounterexamples parser.yy" //
4444// End: //
Note: See TracBrowser for help on using the repository browser.