source: src/Parser/parser.yy @ 054514d

aaron-thesisarm-ehcleanup-dtorsdeferred_resndemanglerjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-exprnew-envno_listpersistent-indexerwith_gc
Last change on this file since 054514d was 054514d, checked in by Rob Schluntz <rschlunt@…>, 4 years ago

Merge branch 'master' of plg.uwaterloo.ca:/u/cforall/software/cfa/cfa-cc

  • Property mode set to 100644
File size: 122.7 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author           : Peter A. Buhr
10// Created On       : Sat Sep  1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Mon May 28 17:01:36 2018
13// Update Count     : 3383
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS.  While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks.  Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// 1. designation with '=' (use ':' instead)
29//
30// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32//
33// 1. designation with and without '=' (use ':' instead)
34// 2. attributes not allowed in parenthesis of declarator
35//
36// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40// grammar rule.
41
42%{
43#define YYDEBUG_LEXER_TEXT (yylval)                                             // lexer loads this up each time
44#define YYDEBUG 1                                                                               // get the pretty debugging code to compile
45#define YYERROR_VERBOSE                                                                 // more information in syntax errors
46
47#undef __GNUC_MINOR__
48
49#include <cstdio>
50#include <stack>
51using namespace std;
52
53#include "ParseNode.h"
54#include "TypedefTable.h"
55#include "TypeData.h"
56#include "LinkageSpec.h"
57#include "Common/SemanticError.h"                                               // error_str
58#include "Common/utility.h"                                                             // for maybeMoveBuild, maybeBuild, CodeLo...
59
60extern DeclarationNode * parseTree;
61extern LinkageSpec::Spec linkage;
62extern TypedefTable typedefTable;
63
64stack< LinkageSpec::Spec > linkageStack;
65
66bool appendStr( string & to, string & from ) {
67        // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
68        //    "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
69        //    the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
70        //    easier to let the C compiler handle this case.
71        //
72        // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
73        //    without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
74        //    i.e., u"a" U"b" L"c" is disallowed.
75
76        if ( from[0] != '"' ) {                                                         // encoding ?
77                if ( to[0] != '"' ) {                                                   // encoding ?
78                        if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
79                                yyerror( "non-matching string encodings for string-literal concatenation" );
80                                return false;                                                   // parse error, must call YYERROR in action
81                        } else if ( from[1] == '8' ) {
82                                from.erase( 0, 1 );                                             // remove 2nd encoding
83                        } // if
84                } else {
85                        if ( from[1] == '8' ) {                                         // move encoding to start
86                                to = "u8" + to;
87                                from.erase( 0, 1 );                                             // remove 2nd encoding
88                        } else {
89                                to = from[0] + to;
90                        } // if
91                } // if
92                from.erase( 0, 1 );                                                             // remove 2nd encoding
93        } // if
94        to += " " + from;                                                                       // concatenated into single string
95        return true;
96} // appendStr
97
98DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
99        // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
100        DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
101        //cur->addType( specifier );
102        for ( cur = dynamic_cast< DeclarationNode * >( cur->get_next() ); cur != nullptr; cur = dynamic_cast< DeclarationNode * >( cur->get_next() ) ) {
103                cl->cloneBaseType( cur );
104        } // for
105        declList->addType( cl );
106//      delete cl;
107        return declList;
108} // distAttr
109
110void distExt( DeclarationNode * declaration ) {
111        // distribute EXTENSION across all declarations
112        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
113                iter->set_extension( true );
114        } // for
115} // distExt
116
117// There is an ambiguity for inline generic-routine return-types and generic routines.
118//   forall( otype T ) struct S { int i; } bar( T ) {}
119// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
120//   forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
121// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
122//   forall( otype T ) struct S { int T; };
123//   forall( otype W ) bar( W ) {}
124
125void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
126        if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
127                funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
128                declSpec->type->aggregate.params = nullptr;
129        } // if
130} // rebindForall
131
132NameExpr * build_postfix_name( const string * name ) {
133        NameExpr * new_name = build_varref( new string( "?`" + *name ) );
134        delete name;
135        return new_name;
136} // build_postfix_name
137
138bool forall = false, xxx = false;                                               // aggregate have one or more forall qualifiers ?
139
140// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
141#define YYLLOC_DEFAULT(Cur, Rhs, N)                                                                                             \
142if ( N ) {                                                                                                                                              \
143        (Cur).first_line   = YYRHSLOC( Rhs, 1 ).first_line;                                                     \
144        (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column;                                           \
145        (Cur).last_line    = YYRHSLOC( Rhs, N ).last_line;                                                      \
146        (Cur).last_column  = YYRHSLOC( Rhs, N ).last_column;                                            \
147        (Cur).filename     = YYRHSLOC( Rhs, 1 ).filename;                                                       \
148} else {                                                                                                                                                \
149        (Cur).first_line   = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line;            \
150        (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column;        \
151        (Cur).filename     = YYRHSLOC( Rhs, 0 ).filename;                                                       \
152}
153%}
154
155%define parse.error verbose
156
157// Types declaration for productions
158%union
159{
160        Token tok;
161        ParseNode * pn;
162        ExpressionNode * en;
163        DeclarationNode * decl;
164        DeclarationNode::Aggregate aggKey;
165        DeclarationNode::TypeClass tclass;
166        StatementNode * sn;
167        WaitForStmt * wfs;
168        Expression * constant;
169        IfCtl * ifctl;
170        ForCtl * fctl;
171        LabelNode * label;
172        InitializerNode * in;
173        OperKinds op;
174        std::string * str;
175        bool flag;
176        CatchStmt::Kind catch_kind;
177        GenericExpr * genexpr;
178}
179
180//************************* TERMINAL TOKENS ********************************
181
182// keywords
183%token TYPEDEF
184%token EXTERN STATIC AUTO REGISTER
185%token THREADLOCAL                                                                              // C11
186%token INLINE FORTRAN                                                                   // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
187%token NORETURN                                                                                 // C11
188%token CONST VOLATILE
189%token RESTRICT                                                                                 // C99
190%token ATOMIC                                                                                   // C11
191%token FORALL MUTEX VIRTUAL                                                             // CFA
192%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
193%token BOOL COMPLEX IMAGINARY                                                   // C99
194%token INT128 FLOAT80 FLOAT128                                                  // GCC
195%token ZERO_T ONE_T                                                                             // CFA
196%token VALIST                                                                                   // GCC
197%token TYPEOF LABEL                                                                             // GCC
198%token ENUM STRUCT UNION
199%token EXCEPTION                                                                                // CFA
200%token COROUTINE MONITOR THREAD                                                 // CFA
201%token OTYPE FTYPE DTYPE TTYPE TRAIT                                    // CFA
202%token SIZEOF OFFSETOF
203%token ATTRIBUTE EXTENSION                                                              // GCC
204%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
205%token CHOOSE DISABLE ENABLE FALLTHRU FALLTHROUGH TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT WITH WHEN WAITFOR // CFA
206%token ASM                                                                                              // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
207%token ALIGNAS ALIGNOF GENERIC STATICASSERT                             // C11
208
209// names and constants: lexer differentiates between identifier and typedef names
210%token<tok> IDENTIFIER                  QUOTED_IDENTIFIER               TYPEDEFname                             TYPEGENname
211%token<tok> TIMEOUT                             WOR
212%token<tok> ATTR_IDENTIFIER             ATTR_TYPEDEFname                ATTR_TYPEGENname
213%token<tok> INTEGERconstant             CHARACTERconstant               STRINGliteral
214%token<tok> DIRECTIVE
215// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
216// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
217// converted into the tuple index (.)(1). e.g., 3.x
218%token<tok>     FLOATING_DECIMALconstant        FLOATING_FRACTIONconstant       FLOATINGconstant
219
220// multi-character operators
221%token ARROW                                                                                    // ->
222%token ICR DECR                                                                                 // ++   --
223%token LS RS                                                                                    // <<   >>
224%token LE GE EQ NE                                                                              // <=   >=      ==      !=
225%token ANDAND OROR                                                                              // &&   ||
226%token ELLIPSIS                                                                                 // ...
227
228%token EXPassign        MULTassign      DIVassign       MODassign       // \=   *=      /=      %=
229%token PLUSassign       MINUSassign                                                     // +=   -=
230%token LSassign         RSassign                                                        // <<=  >>=
231%token ANDassign        ERassign        ORassign                                // &=   ^=      |=
232
233%token ATassign                                                                                 // @=
234
235%type<tok> identifier  no_attr_identifier
236%type<tok> identifier_or_type_name  no_attr_identifier_or_type_name  attr_name
237%type<tok> quasi_keyword
238%type<constant> string_literal
239%type<str> string_literal_list
240
241// expressions
242%type<en> constant
243%type<en> tuple                                                 tuple_expression_list
244%type<op> ptrref_operator                               unary_operator                          assignment_operator
245%type<en> primary_expression                    postfix_expression                      unary_expression
246%type<en> cast_expression                               exponential_expression          multiplicative_expression       additive_expression
247%type<en> shift_expression                              relational_expression           equality_expression
248%type<en> AND_expression                                exclusive_OR_expression         inclusive_OR_expression
249%type<en> logical_AND_expression                logical_OR_expression
250%type<en> conditional_expression                constant_expression                     assignment_expression           assignment_expression_opt
251%type<en> comma_expression                              comma_expression_opt
252%type<en> argument_expression_list              argument_expression                     default_initialize_opt
253%type<ifctl> if_control_expression
254%type<fctl> for_control_expression
255%type<en> subrange
256%type<decl> asm_name_opt
257%type<en> asm_operands_opt asm_operands_list asm_operand
258%type<label> label_list
259%type<en> asm_clobbers_list_opt
260%type<flag> asm_volatile_opt
261%type<en> handler_predicate_opt
262%type<genexpr> generic_association generic_assoc_list
263
264// statements
265%type<sn> statement                                             labeled_statement                       compound_statement
266%type<sn> statement_decl                                statement_decl_list                     statement_list_nodecl
267%type<sn> selection_statement
268%type<sn> switch_clause_list_opt                switch_clause_list
269%type<en> case_value
270%type<sn> case_clause                                   case_value_list                         case_label                                      case_label_list
271%type<sn> iteration_statement                   jump_statement
272%type<sn> expression_statement                  asm_statement
273%type<sn> with_statement
274%type<en> with_clause_opt
275%type<sn> exception_statement                   handler_clause                          finally_clause
276%type<catch_kind> handler_key
277%type<sn> mutex_statement
278%type<en> when_clause                                   when_clause_opt                         waitfor                                         timeout
279%type<sn> waitfor_statement
280%type<wfs> waitfor_clause
281
282// declarations
283%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
284%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
285%type<decl> abstract_parameter_declaration
286
287%type<aggKey> aggregate_key
288%type<decl> aggregate_type aggregate_type_nobody
289
290%type<decl> assertion assertion_list assertion_list_opt
291
292%type<en>   bit_subrange_size_opt bit_subrange_size
293
294%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
295
296%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
297
298%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
299%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
300
301%type<decl> elaborated_type elaborated_type_nobody
302
303%type<decl> enumerator_list enum_type enum_type_nobody
304%type<en> enumerator_value_opt
305
306%type<decl> exception_declaration external_definition external_definition_list external_definition_list_opt
307
308%type<decl> field_declaration field_declaration_list_opt field_declarator_opt field_declaring_list
309%type<en> field field_list field_name fraction_constants_opt
310
311%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
312
313%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
314%type<decl> identifier_list
315
316%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
317%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
318%type<decl> cfa_abstract_ptr cfa_abstract_tuple
319
320%type<decl> cfa_array_parameter_1st_dimension
321
322%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list
323%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
324
325%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
326%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
327
328%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
329
330%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
331
332%type<decl> c_declaration static_assert
333%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
334%type<decl> KR_declaration_list KR_declaration_list_opt
335
336%type<decl> parameter_declaration parameter_list parameter_type_list_opt
337
338%type<decl> paren_identifier paren_type
339
340%type<decl> storage_class storage_class_list
341
342%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
343
344%type<tclass> type_class
345%type<decl> type_declarator type_declarator_name type_declaring_list
346
347%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
348%type<decl> typedef typedef_declaration typedef_expression
349
350%type<decl> variable_type_redeclarator type_ptr type_array type_function
351
352%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
353
354%type<decl> type type_no_function
355%type<decl> type_parameter type_parameter_list type_initializer_opt
356
357%type<en> type_list
358
359%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
360%type<decl> type_specifier type_specifier_nobody
361
362%type<decl> variable_declarator variable_ptr variable_array variable_function
363%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
364
365%type<decl> attribute_list_opt attribute_list attribute_name_list attribute attribute_name
366
367// initializers
368%type<in>  initializer initializer_list_opt initializer_opt
369
370// designators
371%type<en>  designator designator_list designation
372
373
374// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
375//   .---------.                                matches IF '(' comma_expression ')' statement . (reduce)
376//   if ( C ) S1 else S2
377//   `-----------------'                matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
378// Similar issues exit with the waitfor statement.
379
380// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
381// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
382%precedence THEN        // rule precedence for IF/WAITFOR statement
383%precedence WOR         // token precedence for start of WOR in WAITFOR statement
384%precedence TIMEOUT     // token precedence for start of TIMEOUT in WAITFOR statement
385%precedence ELSE        // token precedence for start of else clause in IF/WAITFOR statement
386
387// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
388//   forall( otype T ) struct Foo { T v; };
389//       .-----.                                matches pointer to function returning a generic (which is impossible without a type)
390//   Foo ( *fp )( int );
391//   `---'                                              matches start of TYPEGENname '('
392// Must be:
393//   Foo( int ) ( *fp )( int );
394
395// Order of these lines matters (low-to-high precedence).
396%precedence TYPEGENname
397%precedence '('
398
399%locations                                                                                              // support location tracking for error messages
400
401%start translation_unit                                                                 // parse-tree root
402
403%%
404//************************* Namespace Management ********************************
405
406// The grammar in the ANSI C standard is not strictly context-free, since it relies upon the distinct terminal symbols
407// "identifier", "TYPEDEFname", and "TYPEGENname" that are lexically identical.  While it is possible to write a purely
408// context-free grammar, such a grammar would obscure the relationship between syntactic and semantic constructs.
409// Hence, this grammar uses the ANSI style.
410//
411// Cforall compounds this problem by introducing type names local to the scope of a declaration (for instance, those
412// introduced through "forall" qualifiers), and by introducing "type generators" -- parameterized types.  This latter
413// type name creates a third class of identifiers that must be distinguished by the scanner.
414//
415// Since the scanner cannot distinguish among the different classes of identifiers without some context information, it
416// accesses a data structure (TypedefTable) to allow classification of an identifier that it has just read.  Semantic
417// actions during the parser update this data structure when the class of identifiers change.
418//
419// Because the Cforall language is block-scoped, an identifier can change its class in a local scope; it must revert to
420// its original class at the end of the block.  Since type names can be local to a particular declaration, each
421// declaration is itself a scope.  This requires distinguishing between type names that are local to the current
422// declaration scope and those that persist past the end of the declaration (i.e., names defined in "typedef" or "otype"
423// declarations).
424//
425// The non-terminals "push" and "pop" denote the opening and closing of scopes.  Every push must have a matching pop,
426// although it is regrettable the matching pairs do not always occur within the same rule.  These non-terminals may
427// appear in more contexts than strictly necessary from a semantic point of view.
428
429push:
430                { typedefTable.enterScope(); }
431        ;
432
433pop:
434                { typedefTable.leaveScope(); }
435        ;
436
437//************************* CONSTANTS ********************************
438
439constant:
440                // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
441        INTEGERconstant                                                         { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
442        | FLOATING_DECIMALconstant                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
443        | FLOATING_FRACTIONconstant                                     { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
444        | FLOATINGconstant                                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
445        | CHARACTERconstant                                                     { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
446        ;
447
448quasi_keyword:                                                                                  // CFA
449        TIMEOUT
450        | WOR
451        ;
452
453identifier:
454        IDENTIFIER
455        | ATTR_IDENTIFIER                                                                       // CFA
456        | quasi_keyword
457        ;
458
459no_attr_identifier:
460        IDENTIFIER
461        | quasi_keyword
462        ;
463
464string_literal:
465        string_literal_list                                                     { $$ = build_constantStr( *$1 ); }
466        ;
467
468string_literal_list:                                                                    // juxtaposed strings are concatenated
469        STRINGliteral                                                           { $$ = $1; } // conversion from tok to str
470        | string_literal_list STRINGliteral
471                {
472                        if ( ! appendStr( *$1, *$2 ) ) YYERROR;         // append 2nd juxtaposed string to 1st
473                        delete $2;                                                                      // allocated by lexer
474                        $$ = $1;                                                                        // conversion from tok to str
475                }
476        ;
477
478//************************* EXPRESSIONS ********************************
479
480primary_expression:
481        IDENTIFIER                                                                                      // typedef name cannot be used as a variable name
482                { $$ = new ExpressionNode( build_varref( $1 ) ); }
483        | quasi_keyword
484                { $$ = new ExpressionNode( build_varref( $1 ) ); }
485        | tuple
486        | '(' comma_expression ')'
487                { $$ = $2; }
488        | '(' compound_statement ')'                                            // GCC, lambda expression
489                { $$ = new ExpressionNode( new StmtExpr( dynamic_cast< CompoundStmt * >(maybeMoveBuild< Statement >($2) ) ) ); }
490        | constant '`' IDENTIFIER                                                       // CFA, postfix call
491                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), $1 ) ); }
492        | string_literal '`' IDENTIFIER                                         // CFA, postfix call
493                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), new ExpressionNode( $1 ) ) ); }
494        | IDENTIFIER '`' IDENTIFIER                                                     // CFA, postfix call
495                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), new ExpressionNode( build_varref( $1 ) ) ) ); }
496        | tuple '`' IDENTIFIER                                                          // CFA, postfix call
497                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), $1 ) ); }
498        | '(' comma_expression ')' '`' IDENTIFIER                       // CFA, postfix call
499                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $5 ) ), $2 ) ); }
500        | type_name '.' no_attr_identifier                                      // CFA, nested type
501                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
502        | type_name '.' '[' field_list ']'                                      // CFA, nested type / tuple field selector
503                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
504        | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
505                {
506                        // add the missing control expression to the GenericExpr and return it
507                        $5->control = maybeMoveBuild<Expression>( $3 );
508                        $$ = new ExpressionNode( $5 );
509                }
510        ;
511
512generic_assoc_list:                                                                             // C11
513        generic_association
514        | generic_assoc_list ',' generic_association
515                {
516                        // steal the association node from the singleton and delete the wrapper
517                        $1->associations.splice($1->associations.end(), $3->associations);
518                        delete $3;
519                        $$ = $1;
520                }
521        ;
522
523generic_association:                                                                    // C11
524        type_no_function ':' assignment_expression
525                {
526                        // create a GenericExpr wrapper with one association pair
527                        $$ = new GenericExpr( nullptr, { { maybeMoveBuildType($1), maybeMoveBuild<Expression>($3) } } );
528                }
529        | DEFAULT ':' assignment_expression
530                { $$ = new GenericExpr( nullptr, { { maybeMoveBuild<Expression>($3) } } ); }
531        ;
532
533postfix_expression:
534        primary_expression
535        | postfix_expression '[' assignment_expression ']'
536                // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
537                // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
538                // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
539                // equivalent to the old x[i,j].
540                { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
541        | postfix_expression '{' argument_expression_list '}' // CFA, constructor call
542                {
543                        Token fn;
544                        fn.str = new std::string( "?{}" );                      // location undefined - use location of '{'?
545                        $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
546                }
547        | postfix_expression '(' argument_expression_list ')'
548                { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
549        | postfix_expression '.' no_attr_identifier
550                { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
551        | postfix_expression '.' INTEGERconstant                        // CFA, tuple index
552                { $$ = new ExpressionNode( build_fieldSel( $1, build_constantInteger( *$3 ) ) ); }
553        | postfix_expression FLOATING_FRACTIONconstant          // CFA, tuple index
554                { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
555        | postfix_expression '.' '[' field_list ']'                     // CFA, tuple field selector
556                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
557        | postfix_expression ARROW no_attr_identifier
558                {
559                        $$ = new ExpressionNode( build_pfieldSel( $1, *$3 == "0" || *$3 == "1" ? build_constantInteger( *$3 ) : build_varref( $3 ) ) );
560                }
561        | postfix_expression ARROW INTEGERconstant                      // CFA, tuple index
562                { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
563        | postfix_expression ARROW '[' field_list ']'           // CFA, tuple field selector
564                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
565        | postfix_expression ICR
566                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
567        | postfix_expression DECR
568                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
569        | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
570                { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
571        | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
572                { $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
573        | '^' primary_expression '{' argument_expression_list '}' // CFA
574                {
575                        Token fn;
576                        fn.str = new string( "^?{}" );                          // location undefined
577                        $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
578                }
579        ;
580
581argument_expression_list:
582        argument_expression
583        | argument_expression_list ',' argument_expression
584                { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
585        ;
586
587argument_expression:
588        // empty
589                { $$ = nullptr; }
590        // | '@'                                                                                                // use default argument
591        //      { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
592        | assignment_expression
593        ;
594
595field_list:                                                                                             // CFA, tuple field selector
596        field
597        | field_list ',' field                                          { $$ = (ExpressionNode *)$1->set_last( $3 ); }
598        ;
599
600field:                                                                                                  // CFA, tuple field selector
601        field_name
602        | FLOATING_DECIMALconstant field
603                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
604        | FLOATING_DECIMALconstant '[' field_list ']'
605                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $3 ) ) ); }
606        | field_name '.' field
607                { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
608        | field_name '.' '[' field_list ']'
609                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
610        | field_name ARROW field
611                { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
612        | field_name ARROW '[' field_list ']'
613                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
614        ;
615
616field_name:
617        INTEGERconstant fraction_constants_opt
618                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
619        | FLOATINGconstant fraction_constants_opt
620                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
621        | no_attr_identifier fraction_constants_opt
622                {
623                        $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
624                }
625        ;
626
627fraction_constants_opt:
628        // empty
629                { $$ = nullptr; }
630        | fraction_constants_opt FLOATING_FRACTIONconstant
631                {
632                        Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
633                        $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1,  constant ) ) : new ExpressionNode( constant );
634                }
635        ;
636
637unary_expression:
638        postfix_expression
639                // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
640                // semantics checks, e.g., ++3, 3--, *3, &&3
641        | constant
642                { $$ = $1; }
643        | string_literal
644                { $$ = new ExpressionNode( $1 ); }
645        | EXTENSION cast_expression                                                     // GCC
646                { $$ = $2->set_extension( true ); }
647                // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
648                //              { * X; }         // dereference X
649                //              { * int X; } // CFA declaration of pointer to int
650        | ptrref_operator cast_expression                                       // CFA
651                {
652                        switch ( $1 ) {
653                          case OperKinds::AddressOf:
654                                $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) );
655                                break;
656                          case OperKinds::PointTo:
657                                $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
658                                break;
659                          case OperKinds::And:
660                                $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) ) );
661                                break;
662                          default:
663                                assert( false );
664                        }
665                }
666        | unary_operator cast_expression
667                { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
668        | ICR unary_expression
669                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
670        | DECR unary_expression
671                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
672        | SIZEOF unary_expression
673                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
674        | SIZEOF '(' type_no_function ')'
675                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
676        | ALIGNOF unary_expression                                                      // GCC, variable alignment
677                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
678        | ALIGNOF '(' type_no_function ')'                                      // GCC, type alignment
679                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
680        | OFFSETOF '(' type_no_function ',' no_attr_identifier ')'
681                { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
682        | ATTR_IDENTIFIER
683                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuild< Expression >( (ExpressionNode *)nullptr ) ) ); }
684        | ATTR_IDENTIFIER '(' argument_expression ')'
685                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
686        | ATTR_IDENTIFIER '(' type ')'
687                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuildType( $3 ) ) ); }
688        ;
689
690ptrref_operator:
691        '*'                                                                                     { $$ = OperKinds::PointTo; }
692        | '&'                                                                           { $$ = OperKinds::AddressOf; }
693                // GCC, address of label must be handled by semantic check for ref,ref,label
694        | ANDAND                                                                        { $$ = OperKinds::And; }
695        ;
696
697unary_operator:
698        '+'                                                                                     { $$ = OperKinds::UnPlus; }
699        | '-'                                                                           { $$ = OperKinds::UnMinus; }
700        | '!'                                                                           { $$ = OperKinds::Neg; }
701        | '~'                                                                           { $$ = OperKinds::BitNeg; }
702        ;
703
704cast_expression:
705        unary_expression
706        | '(' type_no_function ')' cast_expression
707                { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
708        | '(' COROUTINE '&' ')' cast_expression                         // CFA
709                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Coroutine, $5 ) ); }
710        | '(' THREAD '&' ')' cast_expression                            // CFA
711                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Thread, $5 ) ); }
712        | '(' MONITOR '&' ')' cast_expression                           // CFA
713                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Monitor, $5 ) ); }
714                // VIRTUAL cannot be opt because of look ahead issues
715        | '(' VIRTUAL ')' cast_expression                                       // CFA
716                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $4 ), maybeMoveBuildType( nullptr ) ) ); }
717        | '(' VIRTUAL type_no_function ')' cast_expression      // CFA
718                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $5 ), maybeMoveBuildType( $3 ) ) ); }
719//      | '(' type_no_function ')' tuple
720//              { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
721        ;
722
723exponential_expression:
724        cast_expression
725        | exponential_expression '\\' cast_expression
726                { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
727        ;
728
729multiplicative_expression:
730        exponential_expression
731        | multiplicative_expression '*' exponential_expression
732                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
733        | multiplicative_expression '/' exponential_expression
734                { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
735        | multiplicative_expression '%' exponential_expression
736                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
737        ;
738
739additive_expression:
740        multiplicative_expression
741        | additive_expression '+' multiplicative_expression
742                { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
743        | additive_expression '-' multiplicative_expression
744                { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
745        ;
746
747shift_expression:
748        additive_expression
749        | shift_expression LS additive_expression
750                { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
751        | shift_expression RS additive_expression
752                { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
753        ;
754
755relational_expression:
756        shift_expression
757        | relational_expression '<' shift_expression
758                { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
759        | relational_expression '>' shift_expression
760                { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
761        | relational_expression LE shift_expression
762                { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
763        | relational_expression GE shift_expression
764                { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
765        ;
766
767equality_expression:
768        relational_expression
769        | equality_expression EQ relational_expression
770                { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
771        | equality_expression NE relational_expression
772                { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
773        ;
774
775AND_expression:
776        equality_expression
777        | AND_expression '&' equality_expression
778                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
779        ;
780
781exclusive_OR_expression:
782        AND_expression
783        | exclusive_OR_expression '^' AND_expression
784                { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
785        ;
786
787inclusive_OR_expression:
788        exclusive_OR_expression
789        | inclusive_OR_expression '|' exclusive_OR_expression
790                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
791        ;
792
793logical_AND_expression:
794        inclusive_OR_expression
795        | logical_AND_expression ANDAND inclusive_OR_expression
796                { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
797        ;
798
799logical_OR_expression:
800        logical_AND_expression
801        | logical_OR_expression OROR logical_AND_expression
802                { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
803        ;
804
805conditional_expression:
806        logical_OR_expression
807        | logical_OR_expression '?' comma_expression ':' conditional_expression
808                { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
809                // FIX ME: computes $1 twice
810        | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
811                { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
812        ;
813
814constant_expression:
815        conditional_expression
816        ;
817
818assignment_expression:
819                // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
820        conditional_expression
821        | unary_expression assignment_operator assignment_expression
822                { $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) ); }
823        | unary_expression '=' '{' initializer_list_opt comma_opt '}'
824                { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
825        ;
826
827assignment_expression_opt:
828        // empty
829                { $$ = nullptr; }
830        | assignment_expression
831        ;
832
833assignment_operator:
834        '='                                                                                     { $$ = OperKinds::Assign; }
835        | ATassign                                                                      { $$ = OperKinds::AtAssn; }
836        | EXPassign                                                                     { $$ = OperKinds::ExpAssn; }
837        | MULTassign                                                            { $$ = OperKinds::MulAssn; }
838        | DIVassign                                                                     { $$ = OperKinds::DivAssn; }
839        | MODassign                                                                     { $$ = OperKinds::ModAssn; }
840        | PLUSassign                                                            { $$ = OperKinds::PlusAssn; }
841        | MINUSassign                                                           { $$ = OperKinds::MinusAssn; }
842        | LSassign                                                                      { $$ = OperKinds::LSAssn; }
843        | RSassign                                                                      { $$ = OperKinds::RSAssn; }
844        | ANDassign                                                                     { $$ = OperKinds::AndAssn; }
845        | ERassign                                                                      { $$ = OperKinds::ERAssn; }
846        | ORassign                                                                      { $$ = OperKinds::OrAssn; }
847        ;
848
849tuple:                                                                                                  // CFA, tuple
850                // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
851                // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
852//      '[' ']'
853//              { $$ = new ExpressionNode( build_tuple() ); }
854//      | '[' push assignment_expression pop ']'
855//              { $$ = new ExpressionNode( build_tuple( $3 ) ); }
856        '[' push ',' tuple_expression_list pop ']'
857                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $4 ) ) ); }
858        | '[' push assignment_expression ',' tuple_expression_list pop ']'
859                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)$3->set_last( $5 ) ) ); }
860        ;
861
862tuple_expression_list:
863        assignment_expression_opt
864        | tuple_expression_list ',' assignment_expression_opt
865                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
866        ;
867
868comma_expression:
869        assignment_expression
870        | comma_expression ',' assignment_expression
871                { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
872        ;
873
874comma_expression_opt:
875        // empty
876                { $$ = nullptr; }
877        | comma_expression
878        ;
879
880//*************************** STATEMENTS *******************************
881
882statement:
883        labeled_statement
884        | compound_statement
885        | expression_statement
886        | selection_statement
887        | iteration_statement
888        | jump_statement
889        | with_statement
890        | mutex_statement
891        | waitfor_statement
892        | exception_statement
893        | enable_disable_statement
894                { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
895        | asm_statement
896        | DIRECTIVE
897                { $$ = new StatementNode( build_directive( $1 ) ); }
898        ;
899
900labeled_statement:
901                // labels cannot be identifiers 0 or 1 or ATTR_IDENTIFIER
902        identifier_or_type_name ':' attribute_list_opt statement
903                {
904                        $$ = $4->add_label( $1, $3 );
905                }
906        ;
907
908compound_statement:
909        '{' '}'
910                { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
911        | '{'
912                // Two scopes are necessary because the block itself has a scope, but every declaration within the block also
913                // requires its own scope.
914          push push
915          local_label_declaration_opt                                           // GCC, local labels
916          statement_decl_list                                                           // C99, intermix declarations and statements
917          pop '}'
918                { $$ = new StatementNode( build_compound( $5 ) ); }
919        ;
920
921statement_decl_list:                                                                    // C99
922        statement_decl
923        | statement_decl_list push statement_decl
924                { if ( $1 != 0 ) { $1->set_last( $3 ); $$ = $1; } }
925        ;
926
927statement_decl:
928        declaration                                                                                     // CFA, new & old style declarations
929                { $$ = new StatementNode( $1 ); }
930        | EXTENSION declaration                                                         // GCC
931                {
932                        distExt( $2 );
933                        $$ = new StatementNode( $2 );
934                }
935        | function_definition
936                { $$ = new StatementNode( $1 ); }
937        | EXTENSION function_definition                                         // GCC
938                {
939                        distExt( $2 );
940                        $$ = new StatementNode( $2 );
941                }
942        | statement pop
943        ;
944
945statement_list_nodecl:
946        statement
947        | statement_list_nodecl statement
948                { if ( $1 != 0 ) { $1->set_last( $2 ); $$ = $1; } }
949        ;
950
951expression_statement:
952        comma_expression_opt ';'
953                { $$ = new StatementNode( build_expr( $1 ) ); }
954        ;
955
956selection_statement:
957        IF '(' push if_control_expression ')' statement         %prec THEN
958                // explicitly deal with the shift/reduce conflict on if/else
959                { $$ = new StatementNode( build_if( $4, $6, nullptr ) ); }
960        | IF '(' push if_control_expression ')' statement ELSE statement
961                { $$ = new StatementNode( build_if( $4, $6, $8 ) ); }
962        | SWITCH '(' comma_expression ')' case_clause
963                { $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
964        | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt '}' // CFA
965                {
966                        StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
967                        // The semantics of the declaration list is changed to include associated initialization, which is performed
968                        // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
969                        // statement around the switch.  Statements after the initial declaration list can never be executed, and
970                        // therefore, are removed from the grammar even though C allows it. The change also applies to choose
971                        // statement.
972                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
973                }
974        | CHOOSE '(' comma_expression ')' case_clause           // CFA
975                { $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
976        | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt '}' // CFA
977                {
978                        StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
979                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
980                }
981        ;
982
983if_control_expression:
984        comma_expression pop
985                { $$ = new IfCtl( nullptr, $1 ); }
986        | c_declaration pop                                                                     // no semi-colon
987                { $$ = new IfCtl( $1, nullptr ); }
988        | cfa_declaration pop                                                           // no semi-colon
989                { $$ = new IfCtl( $1, nullptr ); }
990        | declaration comma_expression                                          // semi-colon separated
991                { $$ = new IfCtl( $1, $2 ); }
992        ;
993
994// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
995// clause allows a list of values and subranges.
996
997case_value:                                                                                             // CFA
998        constant_expression                                                     { $$ = $1; }
999        | constant_expression ELLIPSIS constant_expression      // GCC, subrange
1000                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
1001        | subrange                                                                                      // CFA, subrange
1002        ;
1003
1004case_value_list:                                                                                // CFA
1005        case_value                                                                      { $$ = new StatementNode( build_case( $1 ) ); }
1006                // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1007        | case_value_list ',' case_value                        { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
1008        ;
1009
1010case_label:                                                                                             // CFA
1011        CASE case_value_list ':'                                        { $$ = $2; }
1012        | DEFAULT ':'                                                           { $$ = new StatementNode( build_default() ); }
1013                // A semantic check is required to ensure only one default clause per switch/choose statement.
1014        ;
1015
1016//label_list_opt:
1017//      // empty
1018//      | identifier_or_type_name ':'
1019//      | label_list_opt identifier_or_type_name ':'
1020//      ;
1021
1022case_label_list:                                                                                // CFA
1023        case_label
1024        | case_label_list case_label                            { $$ = (StatementNode *)( $1->set_last( $2 )); }
1025        ;
1026
1027case_clause:                                                                                    // CFA
1028        case_label_list statement                                       { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1029        ;
1030
1031switch_clause_list_opt:                                                                 // CFA
1032        // empty
1033                { $$ = nullptr; }
1034        | switch_clause_list
1035        ;
1036
1037switch_clause_list:                                                                             // CFA
1038        case_label_list statement_list_nodecl
1039                { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1040        | switch_clause_list case_label_list statement_list_nodecl
1041                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1042        ;
1043
1044iteration_statement:
1045        WHILE '(' comma_expression ')' statement
1046                { $$ = new StatementNode( build_while( $3, $5 ) ); }
1047        | DO statement WHILE '(' comma_expression ')' ';'
1048                { $$ = new StatementNode( build_while( $5, $2, true ) ); }
1049        | FOR '(' push for_control_expression ')' statement
1050                { $$ = new StatementNode( build_for( $4, $6 ) ); }
1051        ;
1052
1053for_control_expression:
1054        comma_expression_opt pop ';' comma_expression_opt ';' comma_expression_opt
1055                { $$ = new ForCtl( $1, $4, $6 ); }
1056        | declaration comma_expression_opt ';' comma_expression_opt // C99
1057                { $$ = new ForCtl( $1, $2, $4 ); }
1058        ;
1059
1060jump_statement:
1061        GOTO identifier_or_type_name ';'
1062                { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1063        | GOTO '*' comma_expression ';'                                         // GCC, computed goto
1064                // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1065                // whereas normal operator precedence yields goto (*i)+3;
1066                { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1067                // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1068    | fall_through_name ';'                                                             // CFA
1069                { $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1070    | fall_through_name identifier_or_type_name ';'             // CFA
1071                { $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1072        | fall_through_name DEFAULT ';'                                         // CFA
1073                { $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1074        | CONTINUE ';'
1075                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1076                { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1077        | CONTINUE identifier_or_type_name ';'                          // CFA, multi-level continue
1078                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1079                // the target of the transfer appears only at the start of an iteration statement.
1080                { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1081        | BREAK ';'
1082                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1083                { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1084        | BREAK identifier_or_type_name ';'                                     // CFA, multi-level exit
1085                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1086                // the target of the transfer appears only at the start of an iteration statement.
1087                { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1088        | RETURN comma_expression_opt ';'
1089                { $$ = new StatementNode( build_return( $2 ) ); }
1090        | RETURN '{' initializer_list_opt comma_opt '}'
1091                { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1092        | THROW assignment_expression_opt ';'                           // handles rethrow
1093                { $$ = new StatementNode( build_throw( $2 ) ); }
1094        | THROWRESUME assignment_expression_opt ';'                     // handles reresume
1095                { $$ = new StatementNode( build_resume( $2 ) ); }
1096        | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1097                { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1098        ;
1099
1100fall_through_name:                                                                              // CFA
1101        FALLTHRU
1102        | FALLTHROUGH
1103        ;
1104
1105with_statement:
1106        WITH '(' tuple_expression_list ')' statement
1107                {
1108                        $$ = new StatementNode( build_with( $3, $5 ) );
1109                }
1110        ;
1111
1112// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1113mutex_statement:
1114        MUTEX '(' argument_expression_list ')' statement
1115                { SemanticError( yylloc, "Mutex statement is currently unimplemented." ); $$ = nullptr; }
1116        ;
1117
1118when_clause:
1119        WHEN '(' comma_expression ')'                           { $$ = $3; }
1120        ;
1121
1122when_clause_opt:
1123        // empty
1124                { $$ = nullptr; }
1125        | when_clause
1126        ;
1127
1128waitfor:
1129        WAITFOR '(' identifier ')'
1130                {
1131                        $$ = new ExpressionNode( new NameExpr( *$3 ) );
1132                        delete $3;
1133                }
1134        | WAITFOR '(' identifier ',' argument_expression_list ')'
1135                {
1136                        $$ = new ExpressionNode( new NameExpr( *$3 ) );
1137                        $$->set_last( $5 );
1138                        delete $3;
1139                }
1140        ;
1141
1142timeout:
1143        TIMEOUT '(' comma_expression ')'                        { $$ = $3; }
1144        ;
1145
1146waitfor_clause:
1147        when_clause_opt waitfor statement                                       %prec THEN
1148                { $$ = build_waitfor( $2, $3, $1 ); }
1149        | when_clause_opt waitfor statement WOR waitfor_clause
1150                { $$ = build_waitfor( $2, $3, $1, $5 ); }
1151        | when_clause_opt timeout statement                                     %prec THEN
1152                { $$ = build_waitfor_timeout( $2, $3, $1 ); }
1153        | when_clause_opt ELSE statement
1154                { $$ = build_waitfor_timeout( nullptr, $3, $1 ); }
1155                // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1156        | when_clause_opt timeout statement WOR when_clause ELSE statement
1157                { $$ = build_waitfor_timeout( $2, $3, $1, $7, $5 ); }
1158        ;
1159
1160waitfor_statement:
1161        when_clause_opt waitfor statement                                       %prec THEN
1162                { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1163        | when_clause_opt waitfor statement WOR waitfor_clause
1164                { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1165        ;
1166
1167exception_statement:
1168        TRY compound_statement handler_clause
1169                { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1170        | TRY compound_statement finally_clause
1171                { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1172        | TRY compound_statement handler_clause finally_clause
1173                { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1174        ;
1175
1176handler_clause:
1177        handler_key '(' push push exception_declaration pop handler_predicate_opt ')' compound_statement pop
1178                { $$ = new StatementNode( build_catch( $1, $5, $7, $9 ) ); }
1179        | handler_clause handler_key '(' push push exception_declaration pop handler_predicate_opt ')' compound_statement pop
1180                { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $6, $8, $10 ) ) ); }
1181        ;
1182
1183handler_predicate_opt:
1184        // empty
1185                { $$ = nullptr; }
1186        | ';' conditional_expression                            { $$ = $2; }
1187        ;
1188
1189handler_key:
1190        CATCH                                                                           { $$ = CatchStmt::Terminate; }
1191        | CATCHRESUME                                                           { $$ = CatchStmt::Resume; }
1192        ;
1193
1194finally_clause:
1195        FINALLY compound_statement                                      { $$ = new StatementNode( build_finally( $2 ) ); }
1196        ;
1197
1198exception_declaration:
1199                // No SUE declaration in parameter list.
1200        type_specifier_nobody
1201        | type_specifier_nobody declarator
1202                { $$ = $2->addType( $1 ); }
1203        | type_specifier_nobody variable_abstract_declarator
1204                { $$ = $2->addType( $1 ); }
1205        | cfa_abstract_declarator_tuple no_attr_identifier      // CFA
1206                { $$ = $1->addName( $2 ); }
1207        | cfa_abstract_declarator_tuple                                         // CFA
1208        ;
1209
1210enable_disable_statement:
1211        enable_disable_key identifier_list compound_statement
1212        ;
1213
1214enable_disable_key:
1215        ENABLE
1216        | DISABLE
1217        ;
1218
1219asm_statement:
1220        ASM asm_volatile_opt '(' string_literal ')' ';'
1221                { $$ = new StatementNode( build_asm( $2, $4, 0 ) ); }
1222        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1223                { $$ = new StatementNode( build_asm( $2, $4, $6 ) ); }
1224        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1225                { $$ = new StatementNode( build_asm( $2, $4, $6, $8 ) ); }
1226        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1227                { $$ = new StatementNode( build_asm( $2, $4, $6, $8, $10 ) ); }
1228        | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1229                { $$ = new StatementNode( build_asm( $2, $5, 0, $8, $10, $12 ) ); }
1230        ;
1231
1232asm_volatile_opt:                                                                               // GCC
1233        // empty
1234                { $$ = false; }
1235        | VOLATILE
1236                { $$ = true; }
1237        ;
1238
1239asm_operands_opt:                                                                               // GCC
1240        // empty
1241                { $$ = nullptr; }                                                               // use default argument
1242        | asm_operands_list
1243        ;
1244
1245asm_operands_list:                                                                              // GCC
1246        asm_operand
1247        | asm_operands_list ',' asm_operand
1248                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
1249        ;
1250
1251asm_operand:                                                                                    // GCC
1252        string_literal '(' constant_expression ')'
1253                { $$ = new ExpressionNode( new AsmExpr( maybeMoveBuild< Expression >( (ExpressionNode *)nullptr ), $1, maybeMoveBuild< Expression >( $3 ) ) ); }
1254        | '[' constant_expression ']' string_literal '(' constant_expression ')'
1255                { $$ = new ExpressionNode( new AsmExpr( maybeMoveBuild< Expression >( $2 ), $4, maybeMoveBuild< Expression >( $6 ) ) ); }
1256        ;
1257
1258asm_clobbers_list_opt:                                                                  // GCC
1259        // empty
1260                { $$ = nullptr; }                                                               // use default argument
1261        | string_literal
1262                { $$ = new ExpressionNode( $1 ); }
1263        | asm_clobbers_list_opt ',' string_literal
1264                // set_last returns ParseNode *
1265                { $$ = (ExpressionNode *)$1->set_last( new ExpressionNode( $3 ) ); }
1266        ;
1267
1268label_list:
1269        no_attr_identifier
1270                {
1271                        $$ = new LabelNode(); $$->labels.push_back( *$1 );
1272                        delete $1;                                                                      // allocated by lexer
1273                }
1274        | label_list ',' no_attr_identifier
1275                {
1276                        $$ = $1; $1->labels.push_back( *$3 );
1277                        delete $3;                                                                      // allocated by lexer
1278                }
1279        ;
1280
1281//******************************* DECLARATIONS *********************************
1282
1283declaration_list_opt:                                                                   // used at beginning of switch statement
1284        pop     // empty
1285                { $$ = nullptr; }
1286        | declaration_list
1287        ;
1288
1289declaration_list:
1290        declaration
1291        | declaration_list push declaration
1292                { $$ = $1->appendList( $3 ); }
1293        ;
1294
1295KR_declaration_list_opt:                                                                // used to declare parameter types in K&R style functions
1296        // empty
1297                { $$ = nullptr; }
1298        | KR_declaration_list
1299        ;
1300
1301KR_declaration_list:
1302        push c_declaration pop ';'
1303                { $$ = $2; }
1304        | KR_declaration_list push c_declaration pop ';'
1305                { $$ = $1->appendList( $3 ); }
1306        ;
1307
1308local_label_declaration_opt:                                                    // GCC, local label
1309        // empty
1310        | local_label_declaration_list
1311        ;
1312
1313local_label_declaration_list:                                                   // GCC, local label
1314        LABEL local_label_list ';'
1315        | local_label_declaration_list LABEL local_label_list ';'
1316        ;
1317
1318local_label_list:                                                                               // GCC, local label
1319        no_attr_identifier_or_type_name
1320        | local_label_list ',' no_attr_identifier_or_type_name
1321        ;
1322
1323declaration:                                                                                    // old & new style declarations
1324        c_declaration pop ';'
1325        | cfa_declaration pop ';'                                                       // CFA
1326        | static_assert
1327        ;
1328
1329static_assert:
1330        STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1331                { $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1332
1333// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1334// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1335// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1336// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1337// the declaration list (as in Pascal).  ANSI C and the new CFA declarations may appear together in the same program
1338// block, but cannot be mixed within a specific declaration.
1339//
1340//                      CFA                                     C
1341//              [10] int x;                     int x[10];              // array of 10 integers
1342//              [10] * char y;          char *y[10];    // array of 10 pointers to char
1343
1344cfa_declaration:                                                                                // CFA
1345        cfa_variable_declaration
1346        | cfa_typedef_declaration
1347        | cfa_function_declaration
1348        | type_declaring_list
1349        | trait_specifier
1350        ;
1351
1352cfa_variable_declaration:                                                               // CFA
1353        cfa_variable_specifier initializer_opt
1354                { $$ = $1->addInitializer( $2 ); }
1355        | declaration_qualifier_list cfa_variable_specifier initializer_opt
1356                // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1357                // them as a type_qualifier cannot appear in that context.
1358                { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1359        | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1360                { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1361        ;
1362
1363cfa_variable_specifier:                                                                 // CFA
1364                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1365                // storage-class
1366        cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1367                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1368        | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1369                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1370        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1371                { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1372        ;
1373
1374cfa_function_declaration:                                                               // CFA
1375        cfa_function_specifier
1376                { $$ = $1; }
1377        | type_qualifier_list cfa_function_specifier
1378                { $$ = $2->addQualifiers( $1 ); }
1379        | declaration_qualifier_list cfa_function_specifier
1380                { $$ = $2->addQualifiers( $1 ); }
1381        | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1382                { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1383        | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1384                {
1385                        // Append the return type at the start (left-hand-side) to each identifier in the list.
1386                        DeclarationNode * ret = new DeclarationNode;
1387                        ret->type = maybeClone( $1->type->base );
1388                        $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1389                }
1390        ;
1391
1392cfa_function_specifier:                                                                 // CFA
1393//      '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1394//              {
1395//                      $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1396//              }
1397//      '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1398//              {
1399//                      typedefTable.setNextIdentifier( *$5 );
1400//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1401//              }
1402//      | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1403//              {
1404//                      typedefTable.setNextIdentifier( *$5 );
1405//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1406//              }
1407//      | '[' ']' typegen_name
1408                // identifier_or_type_name must be broken apart because of the sequence:
1409                //
1410                //   '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1411                //   '[' ']' type_specifier
1412                //
1413                // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1414                // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1415        cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1416                // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1417                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 ); }
1418        | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1419                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 ); }
1420        ;
1421
1422cfa_function_return:                                                                    // CFA
1423        '[' push cfa_parameter_list pop ']'
1424                { $$ = DeclarationNode::newTuple( $3 ); }
1425        | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1426                // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
1427                { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1428        ;
1429
1430cfa_typedef_declaration:                                                                // CFA
1431        TYPEDEF cfa_variable_specifier
1432                {
1433                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname );
1434                        $$ = $2->addTypedef();
1435                }
1436        | TYPEDEF cfa_function_specifier
1437                {
1438                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname );
1439                        $$ = $2->addTypedef();
1440                }
1441        | cfa_typedef_declaration pop ',' push no_attr_identifier
1442                {
1443                        typedefTable.addToEnclosingScope( *$5, TYPEDEFname );
1444                        $$ = $1->appendList( $1->cloneType( $5 ) );
1445                }
1446        ;
1447
1448// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1449// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1450
1451typedef_declaration:
1452        TYPEDEF type_specifier declarator
1453                {
1454                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname );
1455                        $$ = $3->addType( $2 )->addTypedef();
1456                }
1457        | typedef_declaration pop ',' push declarator
1458                {
1459                        typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname );
1460                        $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1461                }
1462        | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1463                {
1464                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname );
1465                        $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1466                }
1467        | type_specifier TYPEDEF declarator
1468                {
1469                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname );
1470                        $$ = $3->addType( $1 )->addTypedef();
1471                }
1472        | type_specifier TYPEDEF type_qualifier_list declarator
1473                {
1474                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname );
1475                        $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1476                }
1477        ;
1478
1479typedef_expression:
1480                // GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1481        TYPEDEF no_attr_identifier '=' assignment_expression
1482                {
1483                        // $$ = DeclarationNode::newName( 0 );                  // unimplemented
1484                        SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1485                }
1486        | typedef_expression pop ',' push no_attr_identifier '=' assignment_expression
1487                {
1488                        // $$ = DeclarationNode::newName( 0 );                  // unimplemented
1489                        SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1490                }
1491        ;
1492
1493//c_declaration:
1494//      declaring_list pop ';'
1495//      | typedef_declaration pop ';'
1496//      | typedef_expression pop ';'                                            // GCC, naming expression type
1497//      | sue_declaration_specifier pop ';'
1498//      ;
1499//
1500//declaring_list:
1501//              // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1502//              // storage-class
1503//       declarator asm_name_opt initializer_opt
1504//              {
1505//                      typedefTable.addToEnclosingScope( IDENTIFIER );
1506//                      $$ = ( $2->addType( $1 ))->addAsmName( $3 )->addInitializer( $4 );
1507//              }
1508//      | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1509//              {
1510//                      typedefTable.addToEnclosingScope( IDENTIFIER );
1511//                      $$ = $1->appendList( $1->cloneBaseType( $4->addAsmName( $5 )->addInitializer( $6 ) ) );
1512//              }
1513//      ;
1514
1515c_declaration:
1516        declaration_specifier declaring_list
1517                { $$ = distAttr( $1, $2 ); }
1518        | typedef_declaration
1519        | typedef_expression                                                            // GCC, naming expression type
1520        | sue_declaration_specifier
1521        ;
1522
1523declaring_list:
1524                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1525                // storage-class
1526        declarator asm_name_opt initializer_opt
1527                { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
1528        | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1529                { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
1530        ;
1531
1532declaration_specifier:                                                                  // type specifier + storage class
1533        basic_declaration_specifier
1534        | sue_declaration_specifier
1535        | type_declaration_specifier
1536        ;
1537
1538declaration_specifier_nobody:                                                   // type specifier + storage class - {...}
1539                // Preclude SUE declarations in restricted scopes:
1540                //
1541                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1542                //
1543                // because it is impossible to call f due to name equivalence.
1544        basic_declaration_specifier
1545        | sue_declaration_specifier_nobody
1546        | type_declaration_specifier
1547        ;
1548
1549type_specifier:                                                                                 // type specifier
1550        basic_type_specifier
1551        | sue_type_specifier
1552        | type_type_specifier
1553        ;
1554
1555type_specifier_nobody:                                                                  // type specifier - {...}
1556                // Preclude SUE declarations in restricted scopes:
1557                //
1558                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1559                //
1560                // because it is impossible to call f due to name equivalence.
1561        basic_type_specifier
1562        | sue_type_specifier_nobody
1563        | type_type_specifier
1564        ;
1565
1566type_qualifier_list_opt:                                                                // GCC, used in asm_statement
1567        // empty
1568                { $$ = nullptr; }
1569        | type_qualifier_list
1570        ;
1571
1572type_qualifier_list:
1573                // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1574                //
1575                // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1576                // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1577                // appeared only once.
1578        type_qualifier
1579        | type_qualifier_list type_qualifier
1580                { $$ = $1->addQualifiers( $2 ); }
1581        ;
1582
1583type_qualifier:
1584        type_qualifier_name
1585        | attribute
1586        ;
1587
1588type_qualifier_name:
1589        CONST
1590                { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1591        | RESTRICT
1592                { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1593        | VOLATILE
1594                { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1595        | ATOMIC
1596                { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1597        | forall
1598        ;
1599
1600forall:
1601        FORALL '(' push type_parameter_list pop ')'                                     // CFA
1602                { $$ = DeclarationNode::newForall( $4 ); }
1603        ;
1604
1605declaration_qualifier_list:
1606        storage_class_list
1607        | type_qualifier_list storage_class_list                        // remaining OBSOLESCENT (see 2 )
1608                { $$ = $1->addQualifiers( $2 ); }
1609        | declaration_qualifier_list type_qualifier_list storage_class_list
1610                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1611        ;
1612
1613storage_class_list:
1614                // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1615                // only one of each is specified, except for inline, which can appear with the others.
1616                //
1617                // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1618                // specifiers in a declaration.
1619        storage_class
1620        | storage_class_list storage_class
1621                { $$ = $1->addQualifiers( $2 ); }
1622        ;
1623
1624storage_class:
1625        EXTERN
1626                { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1627        | STATIC
1628                { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1629        | AUTO
1630                { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1631        | REGISTER
1632                { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1633        | THREADLOCAL                                                                           // C11
1634                { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1635                // Put function specifiers here to simplify parsing rules, but separate them semantically.
1636        | INLINE                                                                                        // C99
1637                { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1638        | FORTRAN                                                                                       // C99
1639                { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1640        | NORETURN                                                                                      // C11
1641                { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1642        ;
1643
1644basic_type_name:
1645        VOID
1646                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1647        | BOOL                                                                                          // C99
1648                { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1649        | CHAR
1650                { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1651        | INT
1652                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1653        | INT128
1654                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1655        | FLOAT
1656                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1657        | FLOAT80
1658                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float80 ); }
1659        | FLOAT128
1660                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float128 ); }
1661        | DOUBLE
1662                { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1663        | COMPLEX                                                                                       // C99
1664                { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1665        | IMAGINARY                                                                                     // C99
1666                { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1667        | SIGNED
1668                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1669        | UNSIGNED
1670                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1671        | SHORT
1672                { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1673        | LONG
1674                { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1675        | VALIST                                                                                        // GCC, __builtin_va_list
1676                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1677        ;
1678
1679basic_declaration_specifier:
1680                // A semantic check is necessary for conflicting storage classes.
1681        basic_type_specifier
1682        | declaration_qualifier_list basic_type_specifier
1683                { $$ = $2->addQualifiers( $1 ); }
1684        | basic_declaration_specifier storage_class                     // remaining OBSOLESCENT (see 2)
1685                { $$ = $1->addQualifiers( $2 ); }
1686        | basic_declaration_specifier storage_class type_qualifier_list
1687                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1688        | basic_declaration_specifier storage_class basic_type_specifier
1689                { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1690        ;
1691
1692basic_type_specifier:
1693        direct_type
1694                // Cannot have type modifiers, e.g., short, long, etc.
1695        | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1696                { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1697        ;
1698
1699direct_type:
1700        basic_type_name
1701        | type_qualifier_list basic_type_name
1702                { $$ = $2->addQualifiers( $1 ); }
1703        | direct_type type_qualifier
1704                { $$ = $1->addQualifiers( $2 ); }
1705        | direct_type basic_type_name
1706                { $$ = $1->addType( $2 ); }
1707        ;
1708
1709indirect_type:
1710        TYPEOF '(' type ')'                                                                     // GCC: typeof(x) y;
1711                { $$ = $3; }
1712        | TYPEOF '(' comma_expression ')'                                       // GCC: typeof(a+b) y;
1713                { $$ = DeclarationNode::newTypeof( $3 ); }
1714        | ATTR_TYPEGENname '(' type ')'                                         // CFA: e.g., @type(x) y;
1715                { $$ = DeclarationNode::newAttr( $1, $3 ); }
1716        | ATTR_TYPEGENname '(' comma_expression ')'                     // CFA: e.g., @type(a+b) y;
1717                { $$ = DeclarationNode::newAttr( $1, $3 ); }
1718        | ZERO_T                                                                                        // CFA
1719                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1720        | ONE_T                                                                                         // CFA
1721                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1722        ;
1723
1724sue_declaration_specifier:                                                              // struct, union, enum + storage class + type specifier
1725        sue_type_specifier
1726        | declaration_qualifier_list sue_type_specifier
1727                { $$ = $2->addQualifiers( $1 ); }
1728        | sue_declaration_specifier storage_class                       // remaining OBSOLESCENT (see 2)
1729                { $$ = $1->addQualifiers( $2 ); }
1730        | sue_declaration_specifier storage_class type_qualifier_list
1731                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1732        ;
1733
1734sue_type_specifier:                                                                             // struct, union, enum + type specifier
1735        elaborated_type
1736        | type_qualifier_list
1737                { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1738          elaborated_type
1739                { $$ = $3->addQualifiers( $1 ); }
1740        | sue_type_specifier type_qualifier
1741                { $$ = $1->addQualifiers( $2 ); }
1742        ;
1743
1744sue_declaration_specifier_nobody:                                               // struct, union, enum - {...} + storage class + type specifier
1745        sue_type_specifier_nobody
1746        | declaration_qualifier_list sue_type_specifier_nobody
1747                { $$ = $2->addQualifiers( $1 ); }
1748        | sue_declaration_specifier_nobody storage_class        // remaining OBSOLESCENT (see 2)
1749                { $$ = $1->addQualifiers( $2 ); }
1750        | sue_declaration_specifier_nobody storage_class type_qualifier_list
1751                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1752        ;
1753
1754sue_type_specifier_nobody:                                                              // struct, union, enum - {...} + type specifier
1755        elaborated_type_nobody
1756        | type_qualifier_list elaborated_type_nobody
1757                { $$ = $2->addQualifiers( $1 ); }
1758        | sue_type_specifier_nobody type_qualifier
1759                { $$ = $1->addQualifiers( $2 ); }
1760        ;
1761
1762type_declaration_specifier:
1763        type_type_specifier
1764        | declaration_qualifier_list type_type_specifier
1765                { $$ = $2->addQualifiers( $1 ); }
1766        | type_declaration_specifier storage_class                      // remaining OBSOLESCENT (see 2)
1767                { $$ = $1->addQualifiers( $2 ); }
1768        | type_declaration_specifier storage_class type_qualifier_list
1769                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1770        ;
1771
1772type_type_specifier:                                                                    // typedef types
1773        type_name
1774        | type_qualifier_list type_name
1775                { $$ = $2->addQualifiers( $1 ); }
1776        | type_type_specifier type_qualifier
1777                { $$ = $1->addQualifiers( $2 ); }
1778        ;
1779
1780type_name:
1781        TYPEDEFname
1782                { $$ = DeclarationNode::newFromTypedef( $1 ); }
1783        | '.' TYPEDEFname
1784                { $$ = DeclarationNode::newFromTypedef( $2 ); } // FIX ME
1785        | type_name '.' TYPEDEFname
1786                { $$ = DeclarationNode::newFromTypedef( $3 ); } // FIX ME
1787        | typegen_name
1788        | '.' typegen_name
1789                { $$ = $2; }                                                                    // FIX ME
1790        | type_name '.' typegen_name
1791                { $$ = $3; }                                                                    // FIX ME
1792        ;
1793
1794typegen_name:                                                                                   // CFA
1795        TYPEGENname
1796                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1797        | TYPEGENname '(' ')'
1798                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1799        | TYPEGENname '(' type_list ')'
1800                { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
1801        ;
1802
1803elaborated_type:                                                                                // struct, union, enum
1804        aggregate_type
1805        | enum_type
1806        ;
1807
1808elaborated_type_nobody:                                                                 // struct, union, enum - {...}
1809        aggregate_type_nobody
1810        | enum_type_nobody
1811        ;
1812
1813aggregate_type:                                                                                 // struct, union
1814        aggregate_key attribute_list_opt '{' field_declaration_list_opt '}'
1815                { $$ = DeclarationNode::newAggregate( $1, new string( DeclarationNode::anonymous.newName() ), nullptr, $4, true )->addQualifiers( $2 ); }
1816        | aggregate_key attribute_list_opt no_attr_identifier_or_type_name
1817                {
1818                        typedefTable.makeTypedef( *$3 );                        // create typedef
1819                        if ( forall ) typedefTable.changeKind( *$3, TYPEGENname ); // possibly update
1820                        forall = false;                                                         // reset
1821                }
1822          '{' field_declaration_list_opt '}'
1823                { $$ = DeclarationNode::newAggregate( $1, $3, nullptr, $6, true )->addQualifiers( $2 ); }
1824        | aggregate_key attribute_list_opt '(' type_list ')' '{' field_declaration_list_opt '}' // CFA
1825                { $$ = DeclarationNode::newAggregate( $1, new string( DeclarationNode::anonymous.newName() ), $4, $7, false )->addQualifiers( $2 ); }
1826        | aggregate_type_nobody
1827        ;
1828
1829aggregate_type_nobody:                                                                  // struct, union - {...}
1830        aggregate_key attribute_list_opt no_attr_identifier
1831                {
1832                        typedefTable.makeTypedef( *$3 );
1833                        if ( forall ) typedefTable.changeKind( *$3, TYPEGENname ); // possibly update
1834                        forall = false;                                                         // reset
1835                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
1836                }
1837        | aggregate_key attribute_list_opt TYPEDEFname
1838                {
1839                        typedefTable.makeTypedef( *$3 );
1840                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
1841                }
1842        | aggregate_key attribute_list_opt typegen_name         // CFA
1843                {
1844                        // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
1845                        // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
1846                        // delete newFromTypeGen.
1847                        $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
1848                        $3->type->symbolic.name = nullptr;
1849                        $3->type->symbolic.actuals = nullptr;
1850                        delete $3;
1851                }
1852        ;
1853
1854aggregate_key:
1855        STRUCT
1856                { $$ = DeclarationNode::Struct; }
1857        | UNION
1858                { $$ = DeclarationNode::Union; }
1859        | EXCEPTION
1860                { $$ = DeclarationNode::Exception; }
1861        | COROUTINE
1862                { $$ = DeclarationNode::Coroutine; }
1863        | MONITOR
1864                { $$ = DeclarationNode::Monitor; }
1865        | THREAD
1866                { $$ = DeclarationNode::Thread; }
1867        ;
1868
1869field_declaration_list_opt:
1870        // empty
1871                { $$ = nullptr; }
1872        | field_declaration_list_opt field_declaration
1873                { $$ = $1 ? $1->appendList( $2 ) : $2; }
1874        ;
1875
1876field_declaration:
1877        cfa_field_declaring_list ';'                                            // CFA, new style field declaration
1878        | EXTENSION cfa_field_declaring_list ';'                        // GCC
1879                {
1880                        distExt( $2 );                                                          // mark all fields in list
1881                        $$ = $2;
1882                }
1883        | type_specifier field_declaring_list ';'
1884                {
1885                        $$ = distAttr( $1, $2 ); }
1886        | EXTENSION type_specifier field_declaring_list ';'     // GCC
1887                {
1888                        distExt( $3 );                                                          // mark all fields in list
1889                        $$ = distAttr( $2, $3 );
1890                }
1891        | static_assert
1892        ;
1893
1894cfa_field_declaring_list:                                                               // CFA, new style field declaration
1895        cfa_abstract_declarator_tuple                                           // CFA, no field name
1896        | cfa_abstract_declarator_tuple no_attr_identifier_or_type_name
1897                { $$ = $1->addName( $2 ); }
1898        | cfa_field_declaring_list ',' no_attr_identifier_or_type_name
1899                { $$ = $1->appendList( $1->cloneType( $3 ) ); }
1900        | cfa_field_declaring_list ','                                          // CFA, no field name
1901                { $$ = $1->appendList( $1->cloneType( 0 ) ); }
1902        ;
1903
1904field_declaring_list:
1905        field_declarator_opt
1906        | field_declaring_list ',' attribute_list_opt field_declarator_opt
1907                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
1908        ;
1909
1910field_declarator_opt:
1911        // empty
1912                { $$ = DeclarationNode::newName( 0 ); /* XXX */ } // CFA, no field name
1913        // '@'
1914        //      { $$ = DeclarationNode::newName( new string( DeclarationNode::anonymous.newName() ) ); } // CFA, no field name
1915        | bit_subrange_size                                                                     // no field name
1916                { $$ = DeclarationNode::newBitfield( $1 ); }
1917        | variable_declarator bit_subrange_size_opt
1918                // A semantic check is required to ensure bit_subrange only appears on base type int.
1919                { $$ = $1->addBitfield( $2 ); }
1920        | variable_type_redeclarator bit_subrange_size_opt
1921                // A semantic check is required to ensure bit_subrange only appears on base type int.
1922                { $$ = $1->addBitfield( $2 ); }
1923        | variable_abstract_declarator                                          // CFA, no field name
1924        ;
1925
1926bit_subrange_size_opt:
1927        // empty
1928                { $$ = nullptr; }
1929        | bit_subrange_size
1930                { $$ = $1; }
1931        ;
1932
1933bit_subrange_size:
1934        ':' constant_expression
1935                { $$ = $2; }
1936        ;
1937
1938enum_type:                                                                                              // enum
1939        ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
1940                { $$ = DeclarationNode::newEnum( new string( DeclarationNode::anonymous.newName() ), $4, true )->addQualifiers( $2 ); }
1941        | ENUM attribute_list_opt no_attr_identifier_or_type_name
1942                { typedefTable.makeTypedef( *$3 ); }
1943          '{' enumerator_list comma_opt '}'
1944                { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
1945        | enum_type_nobody
1946        ;
1947
1948enum_type_nobody:                                                                               // enum - {...}
1949        ENUM attribute_list_opt no_attr_identifier_or_type_name
1950                {
1951                        typedefTable.makeTypedef( *$3 );
1952                        $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 );
1953                }
1954        ;
1955
1956enumerator_list:
1957        no_attr_identifier_or_type_name enumerator_value_opt
1958                { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
1959        | enumerator_list ',' no_attr_identifier_or_type_name enumerator_value_opt
1960                { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
1961        ;
1962
1963enumerator_value_opt:
1964        // empty
1965                { $$ = nullptr; }
1966        | '=' constant_expression
1967                { $$ = $2; }
1968        ;
1969
1970cfa_parameter_ellipsis_list_opt:                                                        // CFA, abstract + real
1971        // empty
1972                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1973        | ELLIPSIS
1974                { $$ = nullptr; }
1975        | cfa_abstract_parameter_list
1976        | cfa_parameter_list
1977        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
1978                { $$ = $1->appendList( $5 ); }
1979        | cfa_abstract_parameter_list pop ',' push ELLIPSIS
1980                { $$ = $1->addVarArgs(); }
1981        | cfa_parameter_list pop ',' push ELLIPSIS
1982                { $$ = $1->addVarArgs(); }
1983        ;
1984
1985cfa_parameter_list:                                                                             // CFA
1986                // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
1987                // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
1988        cfa_parameter_declaration
1989        | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
1990                { $$ = $1->appendList( $5 ); }
1991        | cfa_parameter_list pop ',' push cfa_parameter_declaration
1992                { $$ = $1->appendList( $5 ); }
1993        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
1994                { $$ = $1->appendList( $5 )->appendList( $9 ); }
1995        ;
1996
1997cfa_abstract_parameter_list:                                                    // CFA, new & old style abstract
1998        cfa_abstract_parameter_declaration
1999        | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2000                { $$ = $1->appendList( $5 ); }
2001        ;
2002
2003parameter_type_list_opt:
2004        // empty
2005                { $$ = nullptr; }
2006        | ELLIPSIS
2007                { $$ = nullptr; }
2008        | parameter_list
2009        | parameter_list pop ',' push ELLIPSIS
2010                { $$ = $1->addVarArgs(); }
2011        ;
2012
2013parameter_list:                                                                                 // abstract + real
2014        abstract_parameter_declaration
2015        | parameter_declaration
2016        | parameter_list pop ',' push abstract_parameter_declaration
2017                { $$ = $1->appendList( $5 ); }
2018        | parameter_list pop ',' push parameter_declaration
2019                { $$ = $1->appendList( $5 ); }
2020        ;
2021
2022// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2023// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2024
2025cfa_parameter_declaration:                                                              // CFA, new & old style parameter declaration
2026        parameter_declaration
2027        | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initialize_opt
2028                { $$ = $1->addName( $2 ); }
2029        | cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2030                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2031                { $$ = $1->addName( $2 ); }
2032        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2033                { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2034        | cfa_function_specifier
2035        ;
2036
2037cfa_abstract_parameter_declaration:                                             // CFA, new & old style parameter declaration
2038        abstract_parameter_declaration
2039        | cfa_identifier_parameter_declarator_no_tuple
2040        | cfa_abstract_tuple
2041                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2042        | type_qualifier_list cfa_abstract_tuple
2043                { $$ = $2->addQualifiers( $1 ); }
2044        | cfa_abstract_function
2045        ;
2046
2047parameter_declaration:
2048                // No SUE declaration in parameter list.
2049        declaration_specifier_nobody identifier_parameter_declarator default_initialize_opt
2050                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2051        | declaration_specifier_nobody type_parameter_redeclarator default_initialize_opt
2052                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2053        ;
2054
2055abstract_parameter_declaration:
2056        declaration_specifier_nobody default_initialize_opt
2057                { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2058        | declaration_specifier_nobody abstract_parameter_declarator default_initialize_opt
2059                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2060        ;
2061
2062// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2063// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2064// identifiers.  The ANSI-style parameter-list can redefine a typedef name.
2065
2066identifier_list:                                                                                // K&R-style parameter list => no types
2067        no_attr_identifier
2068                { $$ = DeclarationNode::newName( $1 ); }
2069        | identifier_list ',' no_attr_identifier
2070                { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2071        ;
2072
2073identifier_or_type_name:
2074        identifier
2075        | TYPEDEFname
2076        | TYPEGENname
2077        ;
2078
2079no_attr_identifier_or_type_name:
2080        no_attr_identifier
2081        | TYPEDEFname
2082        | TYPEGENname
2083        ;
2084
2085type_no_function:                                                                               // sizeof, alignof, cast (constructor)
2086        cfa_abstract_declarator_tuple                                           // CFA
2087        | type_specifier
2088        | type_specifier abstract_declarator
2089                { $$ = $2->addType( $1 ); }
2090        ;
2091
2092type:                                                                                                   // typeof, assertion
2093        type_no_function
2094        | cfa_abstract_function                                                         // CFA
2095        ;
2096
2097initializer_opt:
2098        // empty
2099                { $$ = nullptr; }
2100        | '=' initializer
2101                { $$ = $2; }
2102        | '=' VOID
2103                { $$ = new InitializerNode( true ); }
2104        | ATassign initializer
2105                { $$ = $2->set_maybeConstructed( false ); }
2106        ;
2107
2108initializer:
2109        assignment_expression                                           { $$ = new InitializerNode( $1 ); }
2110        | '{' initializer_list_opt comma_opt '}'        { $$ = new InitializerNode( $2, true ); }
2111        ;
2112
2113initializer_list_opt:
2114        // empty
2115                { $$ = nullptr; }
2116        | initializer
2117        | designation initializer                                       { $$ = $2->set_designators( $1 ); }
2118        | initializer_list_opt ',' initializer          { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2119        | initializer_list_opt ',' designation initializer
2120                { $$ = (InitializerNode *)( $1->set_last( $4->set_designators( $3 ) ) ); }
2121        ;
2122
2123// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2124// '=' to separator the designator from the initializer value, as in:
2125//
2126//              int x[10] = { [1] = 3 };
2127//
2128// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment.  To disambiguate this case, CFA
2129// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2130// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2131// shift/reduce conflicts
2132
2133designation:
2134        designator_list ':'                                                                     // C99, CFA uses ":" instead of "="
2135        | no_attr_identifier ':'                                                        // GCC, field name
2136                { $$ = new ExpressionNode( build_varref( $1 ) ); }
2137        ;
2138
2139designator_list:                                                                                // C99
2140        designator
2141        | designator_list designator
2142                { $$ = (ExpressionNode *)( $1->set_last( $2 ) ); }
2143        //| designator_list designator                                          { $$ = new ExpressionNode( $1, $2 ); }
2144        ;
2145
2146designator:
2147        '.' no_attr_identifier                                                          // C99, field name
2148                { $$ = new ExpressionNode( build_varref( $2 ) ); }
2149        | '[' push assignment_expression pop ']'                        // C99, single array element
2150                // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2151                { $$ = $3; }
2152        | '[' push subrange pop ']'                                                     // CFA, multiple array elements
2153                { $$ = $3; }
2154        | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2155                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $3 ), maybeMoveBuild< Expression >( $5 ) ) ); }
2156        | '.' '[' push field_list pop ']'                                       // CFA, tuple field selector
2157                { $$ = $4; }
2158        ;
2159
2160// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2161// rather than an object-oriented type system. This required four groups of extensions:
2162//
2163// Overloading: function, data, and operator identifiers may be overloaded.
2164//
2165// Type declarations: "type" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2166//     and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2167//     definitions of new types. Type declarations with storage class "extern" provide opaque types.
2168//
2169// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2170//     site. A polymorphic function is not a template; it is a function, with an address and a type.
2171//
2172// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2173//     types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2174//     hierarchies. Unlike classes, they can define relationships between types.  Assertions declare that a type or
2175//     types provide the operations declared by a specification.  Assertions are normally used to declare requirements
2176//     on type arguments of polymorphic functions.
2177
2178type_parameter_list:                                                                    // CFA
2179        type_parameter
2180                { $$ = $1; }
2181        | type_parameter_list ',' type_parameter
2182                { $$ = $1->appendList( $3 ); }
2183        ;
2184
2185type_initializer_opt:                                                                   // CFA
2186        // empty
2187                { $$ = nullptr; }
2188        | '=' type
2189                { $$ = $2; }
2190        ;
2191
2192type_parameter:                                                                                 // CFA
2193        type_class no_attr_identifier_or_type_name
2194                { typedefTable.addToEnclosingScope( *$2, TYPEDEFname ); }
2195          type_initializer_opt assertion_list_opt
2196                { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2197        | type_specifier identifier_parameter_declarator
2198        | assertion_list
2199                { $$ = DeclarationNode::newTypeParam( DeclarationNode::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2200        ;
2201
2202type_class:                                                                                             // CFA
2203        OTYPE
2204                { $$ = DeclarationNode::Otype; }
2205        | DTYPE
2206                { $$ = DeclarationNode::Dtype; }
2207        | FTYPE
2208                { $$ = DeclarationNode::Ftype; }
2209        | TTYPE
2210                { $$ = DeclarationNode::Ttype; }
2211        ;
2212
2213assertion_list_opt:                                                                             // CFA
2214        // empty
2215                { $$ = nullptr; }
2216        | assertion_list
2217        ;
2218
2219assertion_list:                                                                                 // CFA
2220        assertion
2221        | assertion_list assertion
2222                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2223        ;
2224
2225assertion:                                                                                              // CFA
2226        '|' no_attr_identifier_or_type_name '(' type_list ')'
2227                { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
2228        | '|' '{' push trait_declaration_list pop '}'
2229                { $$ = $4; }
2230        | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
2231                { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
2232        ;
2233
2234type_list:                                                                                              // CFA
2235        type
2236                { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2237        | assignment_expression
2238        | type_list ',' type
2239                { $$ = (ExpressionNode *)( $1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) ) ); }
2240        | type_list ',' assignment_expression
2241                { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2242        ;
2243
2244type_declaring_list:                                                                    // CFA
2245        OTYPE type_declarator
2246                { $$ = $2; }
2247        | storage_class_list OTYPE type_declarator
2248                { $$ = $3->addQualifiers( $1 ); }
2249        | type_declaring_list ',' type_declarator
2250                { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2251        ;
2252
2253type_declarator:                                                                                // CFA
2254        type_declarator_name assertion_list_opt
2255                { $$ = $1->addAssertions( $2 ); }
2256        | type_declarator_name assertion_list_opt '=' type
2257                { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2258        ;
2259
2260type_declarator_name:                                                                   // CFA
2261        no_attr_identifier_or_type_name
2262                {
2263                        typedefTable.addToEnclosingScope( *$1, TYPEDEFname );
2264                        $$ = DeclarationNode::newTypeDecl( $1, 0 );
2265                }
2266        | no_attr_identifier_or_type_name '(' push type_parameter_list pop ')'
2267                {
2268                        typedefTable.addToEnclosingScope( *$1, TYPEGENname );
2269                        $$ = DeclarationNode::newTypeDecl( $1, $4 );
2270                }
2271        ;
2272
2273trait_specifier:                                                                                // CFA
2274        TRAIT no_attr_identifier_or_type_name '(' push type_parameter_list pop ')' '{' '}'
2275                { $$ = DeclarationNode::newTrait( $2, $5, 0 ); }
2276        | TRAIT no_attr_identifier_or_type_name '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}'
2277                { $$ = DeclarationNode::newTrait( $2, $5, $10 ); }
2278        ;
2279
2280trait_declaration_list:                                                                 // CFA
2281        trait_declaration
2282        | trait_declaration_list pop push trait_declaration
2283                { $$ = $1->appendList( $4 ); }
2284        ;
2285
2286trait_declaration:                                                                              // CFA
2287        cfa_trait_declaring_list ';'
2288        | trait_declaring_list ';'
2289        ;
2290
2291cfa_trait_declaring_list:                                                               // CFA
2292        cfa_variable_specifier
2293        | cfa_function_specifier
2294        | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2295                { $$ = $1->appendList( $1->cloneType( $5 ) ); }
2296        ;
2297
2298trait_declaring_list:                                                                   // CFA
2299        type_specifier declarator
2300                { $$ = $2->addType( $1 ); }
2301        | trait_declaring_list pop ',' push declarator
2302                { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
2303        ;
2304
2305//***************************** EXTERNAL DEFINITIONS *****************************
2306
2307translation_unit:
2308        // empty
2309                {}                                                                                              // empty input file
2310        | external_definition_list
2311                { parseTree = parseTree ? parseTree->appendList( $1 ) : $1;     }
2312        ;
2313
2314external_definition_list:
2315        external_definition
2316        | external_definition_list
2317                { forall = xxx; }
2318          push external_definition
2319                { $$ = $1 ? $1->appendList( $4 ) : $4; }
2320        ;
2321
2322external_definition_list_opt:
2323        // empty
2324                { $$ = nullptr; }
2325        | external_definition_list
2326        ;
2327
2328external_definition:
2329        declaration
2330        | external_function_definition
2331        | ASM '(' string_literal ')' ';'                                        // GCC, global assembler statement
2332                {
2333                        $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( false, $3, 0 ) ) );
2334                }
2335        | EXTERN STRINGliteral                                                          // C++-style linkage specifier
2336                {
2337                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
2338                        linkage = LinkageSpec::linkageUpdate( yylloc, linkage, $2 );
2339                }
2340          '{' external_definition_list_opt '}'
2341                {
2342                        linkage = linkageStack.top();
2343                        linkageStack.pop();
2344                        $$ = $5;
2345                }
2346        | EXTENSION external_definition                                         // GCC, multiple __extension__ allowed, meaning unknown
2347                {
2348                        distExt( $2 );                                                          // mark all fields in list
2349                        $$ = $2;
2350                }
2351        | type_qualifier_list
2352                { if ( $1->type->forall ) xxx = forall = true; } // remember generic type
2353          push '{' external_definition_list '}'                         // CFA, namespace
2354                {
2355                        for ( DeclarationNode * iter = $5; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
2356                                if ( isMangled( iter->linkage ) ) {             // ignore extern "C"
2357                                        iter->addQualifiers( $1->clone() );
2358                                } // if
2359                        } // for
2360                        xxx = false;
2361                        delete $1;
2362                        $$ = $5;
2363                }
2364        | declaration_qualifier_list
2365                { if ( $1->type->forall ) xxx = forall = true; } // remember generic type
2366          push '{' external_definition_list '}'                         // CFA, namespace
2367                {
2368                        for ( DeclarationNode * iter = $5; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
2369                                if ( isMangled( iter->linkage ) ) {             // ignore extern "C"
2370                                        iter->addQualifiers( $1->clone() );
2371                                } // if
2372                        } // for
2373                        xxx = false;
2374                        delete $1;
2375                        $$ = $5;
2376                }
2377        | declaration_qualifier_list type_qualifier_list
2378                {
2379                        // forall must be in the type_qualifier_list
2380                        if ( $2->type->forall ) xxx = forall = true; // remember generic type
2381                }
2382          push '{' external_definition_list '}'                         // CFA, namespace
2383                {
2384                        for ( DeclarationNode * iter = $6; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
2385                                if ( isMangled( iter->linkage ) && isMangled( $2->linkage ) ) { // ignore extern "C"
2386                                        iter->addQualifiers( $1->clone() );
2387                                        iter->addQualifiers( $2->clone() );
2388                                } // if
2389                        } // for
2390                        xxx = false;
2391                        delete $1;
2392                        delete $2;
2393                        $$ = $6;
2394                }
2395        ;
2396
2397external_function_definition:
2398        function_definition
2399                // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2400                // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2401                // Parsing is possible because function_definition does not appear in the context of an expression (nested
2402                // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2403                // declaration must still have a type_specifier.  OBSOLESCENT (see 1)
2404        | function_declarator compound_statement
2405                { $$ = $1->addFunctionBody( $2 ); }
2406        | KR_function_declarator KR_declaration_list_opt compound_statement
2407                { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
2408        ;
2409
2410with_clause_opt:
2411        // empty
2412                { $$ = nullptr; forall = false; }
2413        | WITH '(' tuple_expression_list ')'
2414                { $$ = $3; forall = false; }
2415        ;
2416
2417function_definition:
2418        cfa_function_declaration with_clause_opt compound_statement     // CFA
2419                {
2420                        // Add the function body to the last identifier in the function definition list, i.e., foo3:
2421                        //   [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2422                        $1->get_last()->addFunctionBody( $3, $2 );
2423                        $$ = $1;
2424                }
2425        | declaration_specifier function_declarator with_clause_opt compound_statement
2426                {
2427                        rebindForall( $1, $2 );
2428                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2429                }
2430        | declaration_specifier variable_type_redeclarator with_clause_opt compound_statement
2431                {
2432                        rebindForall( $1, $2 );
2433                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2434                }
2435                // handles default int return type, OBSOLESCENT (see 1)
2436        | type_qualifier_list function_declarator with_clause_opt compound_statement
2437                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2438                // handles default int return type, OBSOLESCENT (see 1)
2439        | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2440                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2441                // handles default int return type, OBSOLESCENT (see 1)
2442        | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2443                { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2444
2445                // Old-style K&R function definition, OBSOLESCENT (see 4)
2446        | declaration_specifier KR_function_declarator KR_declaration_list_opt with_clause_opt compound_statement
2447                {
2448                        rebindForall( $1, $2 );
2449                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2450                }
2451                // handles default int return type, OBSOLESCENT (see 1)
2452        | type_qualifier_list KR_function_declarator KR_declaration_list_opt with_clause_opt compound_statement
2453                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2454                // handles default int return type, OBSOLESCENT (see 1)
2455        | declaration_qualifier_list KR_function_declarator KR_declaration_list_opt with_clause_opt compound_statement
2456                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2457                // handles default int return type, OBSOLESCENT (see 1)
2458        | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_declaration_list_opt with_clause_opt compound_statement
2459                { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2460        ;
2461
2462declarator:
2463        variable_declarator
2464        | variable_type_redeclarator
2465        | function_declarator
2466        ;
2467
2468subrange:
2469        constant_expression '~' constant_expression                     // CFA, integer subrange
2470                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
2471        ;
2472
2473asm_name_opt:                                                                                   // GCC
2474        // empty
2475                { $$ = nullptr; }
2476        | ASM '(' string_literal ')' attribute_list_opt
2477                {
2478                        DeclarationNode * name = new DeclarationNode();
2479                        name->asmName = $3;
2480                        $$ = name->addQualifiers( $5 );
2481                }
2482        ;
2483
2484attribute_list_opt:                                                                             // GCC
2485        // empty
2486                { $$ = nullptr; }
2487        | attribute_list
2488        ;
2489
2490attribute_list:                                                                                 // GCC
2491        attribute
2492        | attribute_list attribute
2493                { $$ = $2->addQualifiers( $1 ); }
2494        ;
2495
2496attribute:                                                                                              // GCC
2497        ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2498                { $$ = $4; }
2499        ;
2500
2501attribute_name_list:                                                                    // GCC
2502        attribute_name
2503        | attribute_name_list ',' attribute_name
2504                { $$ = $3->addQualifiers( $1 ); }
2505        ;
2506
2507attribute_name:                                                                                 // GCC
2508        // empty
2509                { $$ = nullptr; }
2510        | attr_name
2511                { $$ = DeclarationNode::newAttribute( $1 ); }
2512        | attr_name '(' argument_expression_list ')'
2513                { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2514        ;
2515
2516attr_name:                                                                                              // GCC
2517        IDENTIFIER
2518        | quasi_keyword
2519        | TYPEDEFname
2520        | TYPEGENname
2521        | FALLTHROUGH
2522                { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2523        | CONST
2524                { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2525        ;
2526
2527// ============================================================================
2528// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2529// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2530// in:
2531//
2532//              int (*f())[10] { ... };
2533//              ... (*f())[3] += 1;             // definition mimics usage
2534//
2535// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2536// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2537// ============================================================================
2538
2539// ----------------------------------------------------------------------------
2540// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2541// to define a variable or function prototype, e.g.:
2542//
2543//              valid declaration               invalid definition
2544//              -----------------               ------------------
2545//              int f;                                  int f {}
2546//              int *f;                                 int *f {}
2547//              int f[10];                              int f[10] {}
2548//              int (*f)(int);                  int (*f)(int) {}
2549//
2550// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2551// variable_declarator and function_declarator.
2552// ----------------------------------------------------------------------------
2553
2554// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2555// declaring an array of functions versus a pointer to an array of functions.
2556
2557variable_declarator:
2558        paren_identifier attribute_list_opt
2559                { $$ = $1->addQualifiers( $2 ); }
2560        | variable_ptr
2561        | variable_array attribute_list_opt
2562                { $$ = $1->addQualifiers( $2 ); }
2563        | variable_function attribute_list_opt
2564                { $$ = $1->addQualifiers( $2 ); }
2565        ;
2566
2567paren_identifier:
2568        identifier
2569                { $$ = DeclarationNode::newName( $1 ); }
2570        | '(' paren_identifier ')'                                                      // redundant parenthesis
2571                { $$ = $2; }
2572        ;
2573
2574variable_ptr:
2575        ptrref_operator variable_declarator
2576                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2577        | ptrref_operator type_qualifier_list variable_declarator
2578                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2579        | '(' variable_ptr ')' attribute_list_opt
2580                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2581        ;
2582
2583variable_array:
2584        paren_identifier array_dimension
2585                { $$ = $1->addArray( $2 ); }
2586        | '(' variable_ptr ')' array_dimension
2587                { $$ = $2->addArray( $4 ); }
2588        | '(' variable_array ')' multi_array_dimension          // redundant parenthesis
2589                { $$ = $2->addArray( $4 ); }
2590        | '(' variable_array ')'                                                        // redundant parenthesis
2591                { $$ = $2; }
2592        ;
2593
2594variable_function:
2595        '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2596                { $$ = $2->addParamList( $6 ); }
2597        | '(' variable_function ')'                                                     // redundant parenthesis
2598                { $$ = $2; }
2599        ;
2600
2601// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2602// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2603// is the same scope.  The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2604
2605function_declarator:
2606        function_no_ptr attribute_list_opt
2607                { $$ = $1->addQualifiers( $2 ); }
2608        | function_ptr
2609        | function_array attribute_list_opt
2610                { $$ = $1->addQualifiers( $2 ); }
2611        ;
2612
2613function_no_ptr:
2614        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2615                { $$ = $1->addParamList( $4 ); }
2616        | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2617                { $$ = $2->addParamList( $6 ); }
2618        | '(' function_no_ptr ')'                                                       // redundant parenthesis
2619                { $$ = $2; }
2620        ;
2621
2622function_ptr:
2623        ptrref_operator function_declarator
2624                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2625        | ptrref_operator type_qualifier_list function_declarator
2626                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2627        | '(' function_ptr ')'
2628                { $$ = $2; }
2629        ;
2630
2631function_array:
2632        '(' function_ptr ')' array_dimension
2633                { $$ = $2->addArray( $4 ); }
2634        | '(' function_array ')' multi_array_dimension          // redundant parenthesis
2635                { $$ = $2->addArray( $4 ); }
2636        | '(' function_array ')'                                                        // redundant parenthesis
2637                { $$ = $2; }
2638        ;
2639
2640// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
2641//
2642//   f( a, b, c ) int a, *b, c[]; {}
2643//
2644// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
2645// returning arrays and functions versus pointers to arrays and functions.
2646
2647KR_function_declarator:
2648        KR_function_no_ptr
2649        | KR_function_ptr
2650        | KR_function_array
2651        ;
2652
2653KR_function_no_ptr:
2654        paren_identifier '(' identifier_list ')'                        // function_declarator handles empty parameter
2655                { $$ = $1->addIdList( $3 ); }
2656        | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
2657                { $$ = $2->addParamList( $6 ); }
2658        | '(' KR_function_no_ptr ')'                                            // redundant parenthesis
2659                { $$ = $2; }
2660        ;
2661
2662KR_function_ptr:
2663        ptrref_operator KR_function_declarator
2664                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2665        | ptrref_operator type_qualifier_list KR_function_declarator
2666                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2667        | '(' KR_function_ptr ')'
2668                { $$ = $2; }
2669        ;
2670
2671KR_function_array:
2672        '(' KR_function_ptr ')' array_dimension
2673                { $$ = $2->addArray( $4 ); }
2674        | '(' KR_function_array ')' multi_array_dimension       // redundant parenthesis
2675                { $$ = $2->addArray( $4 ); }
2676        | '(' KR_function_array ')'                                                     // redundant parenthesis
2677                { $$ = $2; }
2678        ;
2679
2680// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2681//
2682//              typedef int foo;
2683//              {
2684//                 int foo; // redefine typedef name in new scope
2685//              }
2686//
2687// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2688// and functions versus pointers to arrays and functions.
2689
2690variable_type_redeclarator:
2691        paren_type attribute_list_opt
2692                { $$ = $1->addQualifiers( $2 ); }
2693        | type_ptr
2694        | type_array attribute_list_opt
2695                { $$ = $1->addQualifiers( $2 ); }
2696        | type_function attribute_list_opt
2697                { $$ = $1->addQualifiers( $2 ); }
2698        ;
2699
2700paren_type:
2701        typedef
2702                // hide type name in enclosing scope by variable name
2703                { typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER ); }
2704        | '(' paren_type ')'
2705                { $$ = $2; }
2706        ;
2707
2708type_ptr:
2709        ptrref_operator variable_type_redeclarator
2710                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2711        | ptrref_operator type_qualifier_list variable_type_redeclarator
2712                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2713        | '(' type_ptr ')' attribute_list_opt
2714                { $$ = $2->addQualifiers( $4 ); }
2715        ;
2716
2717type_array:
2718        paren_type array_dimension
2719                { $$ = $1->addArray( $2 ); }
2720        | '(' type_ptr ')' array_dimension
2721                { $$ = $2->addArray( $4 ); }
2722        | '(' type_array ')' multi_array_dimension                      // redundant parenthesis
2723                { $$ = $2->addArray( $4 ); }
2724        | '(' type_array ')'                                                            // redundant parenthesis
2725                { $$ = $2; }
2726        ;
2727
2728type_function:
2729        paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2730                { $$ = $1->addParamList( $4 ); }
2731        | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2732                { $$ = $2->addParamList( $6 ); }
2733        | '(' type_function ')'                                                         // redundant parenthesis
2734                { $$ = $2; }
2735        ;
2736
2737// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
2738// typedef name and allows the C99 array options, which can only appear in a parameter list.  The pattern precludes
2739// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
2740// pointers to arrays and functions.
2741
2742identifier_parameter_declarator:
2743        paren_identifier attribute_list_opt
2744                { $$ = $1->addQualifiers( $2 ); }
2745        | '&' MUTEX paren_identifier attribute_list_opt
2746                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
2747        | identifier_parameter_ptr
2748        | identifier_parameter_array attribute_list_opt
2749                { $$ = $1->addQualifiers( $2 ); }
2750        | identifier_parameter_function attribute_list_opt
2751                { $$ = $1->addQualifiers( $2 ); }
2752        ;
2753
2754identifier_parameter_ptr:
2755        ptrref_operator identifier_parameter_declarator
2756                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2757        | ptrref_operator type_qualifier_list identifier_parameter_declarator
2758                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2759        | '(' identifier_parameter_ptr ')' attribute_list_opt
2760                { $$ = $2->addQualifiers( $4 ); }
2761        ;
2762
2763identifier_parameter_array:
2764        paren_identifier array_parameter_dimension
2765                { $$ = $1->addArray( $2 ); }
2766        | '(' identifier_parameter_ptr ')' array_dimension
2767                { $$ = $2->addArray( $4 ); }
2768        | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
2769                { $$ = $2->addArray( $4 ); }
2770        | '(' identifier_parameter_array ')'                            // redundant parenthesis
2771                { $$ = $2; }
2772        ;
2773
2774identifier_parameter_function:
2775        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2776                { $$ = $1->addParamList( $4 ); }
2777        | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2778                { $$ = $2->addParamList( $6 ); }
2779        | '(' identifier_parameter_function ')'                         // redundant parenthesis
2780                { $$ = $2; }
2781        ;
2782
2783// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
2784// e.g.:
2785//
2786//              typedef int foo;
2787//              forall( otype T ) struct foo;
2788//              int f( int foo ); // redefine typedef name in new scope
2789//
2790// and allows the C99 array options, which can only appear in a parameter list.
2791
2792type_parameter_redeclarator:
2793        typedef attribute_list_opt
2794                { $$ = $1->addQualifiers( $2 ); }
2795        | '&' MUTEX typedef attribute_list_opt
2796                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
2797        | type_parameter_ptr
2798        | type_parameter_array attribute_list_opt
2799                { $$ = $1->addQualifiers( $2 ); }
2800        | type_parameter_function attribute_list_opt
2801                { $$ = $1->addQualifiers( $2 ); }
2802        ;
2803
2804typedef:
2805        TYPEDEFname
2806                { $$ = DeclarationNode::newName( $1 ); }
2807        | TYPEGENname
2808                { $$ = DeclarationNode::newName( $1 ); }
2809        ;
2810
2811type_parameter_ptr:
2812        ptrref_operator type_parameter_redeclarator
2813                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2814        | ptrref_operator type_qualifier_list type_parameter_redeclarator
2815                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2816        | '(' type_parameter_ptr ')' attribute_list_opt
2817                { $$ = $2->addQualifiers( $4 ); }
2818        ;
2819
2820type_parameter_array:
2821        typedef array_parameter_dimension
2822                { $$ = $1->addArray( $2 ); }
2823        | '(' type_parameter_ptr ')' array_parameter_dimension
2824                { $$ = $2->addArray( $4 ); }
2825        ;
2826
2827type_parameter_function:
2828        typedef '(' push parameter_type_list_opt pop ')'        // empty parameter list OBSOLESCENT (see 3)
2829                { $$ = $1->addParamList( $4 ); }
2830        | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2831                { $$ = $2->addParamList( $6 ); }
2832        ;
2833
2834// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
2835// which the type applies, e.g.:
2836//
2837//              sizeof( int );
2838//              sizeof( int * );
2839//              sizeof( int [10] );
2840//              sizeof( int (*)() );
2841//              sizeof( int () );
2842//
2843// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2844// and functions versus pointers to arrays and functions.
2845
2846abstract_declarator:
2847        abstract_ptr
2848        | abstract_array attribute_list_opt
2849                { $$ = $1->addQualifiers( $2 ); }
2850        | abstract_function attribute_list_opt
2851                { $$ = $1->addQualifiers( $2 ); }
2852        ;
2853
2854abstract_ptr:
2855        ptrref_operator
2856                { $$ = DeclarationNode::newPointer( 0, $1 ); }
2857        | ptrref_operator type_qualifier_list
2858                { $$ = DeclarationNode::newPointer( $2, $1 ); }
2859        | ptrref_operator abstract_declarator
2860                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2861        | ptrref_operator type_qualifier_list abstract_declarator
2862                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2863        | '(' abstract_ptr ')' attribute_list_opt
2864                { $$ = $2->addQualifiers( $4 ); }
2865        ;
2866
2867abstract_array:
2868        array_dimension
2869        | '(' abstract_ptr ')' array_dimension
2870                { $$ = $2->addArray( $4 ); }
2871        | '(' abstract_array ')' multi_array_dimension          // redundant parenthesis
2872                { $$ = $2->addArray( $4 ); }
2873        | '(' abstract_array ')'                                                        // redundant parenthesis
2874                { $$ = $2; }
2875        ;
2876
2877abstract_function:
2878        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
2879                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
2880        | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2881                { $$ = $2->addParamList( $6 ); }
2882        | '(' abstract_function ')'                                                     // redundant parenthesis
2883                { $$ = $2; }
2884        ;
2885
2886array_dimension:
2887                // Only the first dimension can be empty.
2888        '[' ']'
2889                { $$ = DeclarationNode::newArray( 0, 0, false ); }
2890        | '[' ']' multi_array_dimension
2891                { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
2892        | multi_array_dimension
2893        ;
2894
2895multi_array_dimension:
2896        '[' push assignment_expression pop ']'
2897                { $$ = DeclarationNode::newArray( $3, 0, false ); }
2898        | '[' push '*' pop ']'                                                          // C99
2899                { $$ = DeclarationNode::newVarArray( 0 ); }
2900        | multi_array_dimension '[' push assignment_expression pop ']'
2901                { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
2902        | multi_array_dimension '[' push '*' pop ']'            // C99
2903                { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
2904        ;
2905
2906// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
2907// identifier to which the type applies, e.g.:
2908//
2909//              int f( int );                   // not handled here
2910//              int f( int * );                 // abstract function-prototype parameter; no parameter name specified
2911//              int f( int (*)() );             // abstract function-prototype parameter; no parameter name specified
2912//              int f( int (int) );             // abstract function-prototype parameter; no parameter name specified
2913//
2914// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2915// and functions versus pointers to arrays and functions. In addition, the pattern handles the
2916// special meaning of parenthesis around a typedef name:
2917//
2918//              ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
2919//              parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
2920//              not as redundant parentheses around the identifier."
2921//
2922// For example:
2923//
2924//              typedef float T;
2925//              int f( int ( T [5] ) );                                 // see abstract_parameter_declarator
2926//              int g( int ( T ( int ) ) );                             // see abstract_parameter_declarator
2927//              int f( int f1( T a[5] ) );                              // see identifier_parameter_declarator
2928//              int g( int g1( T g2( int p ) ) );               // see identifier_parameter_declarator
2929//
2930// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
2931// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
2932// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
2933// functions.
2934
2935abstract_parameter_declarator:
2936        abstract_parameter_ptr
2937        | '&' MUTEX attribute_list_opt
2938                { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
2939        | abstract_parameter_array attribute_list_opt
2940                { $$ = $1->addQualifiers( $2 ); }
2941        | abstract_parameter_function attribute_list_opt
2942                { $$ = $1->addQualifiers( $2 ); }
2943        ;
2944
2945abstract_parameter_ptr:
2946        ptrref_operator
2947                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
2948        | ptrref_operator type_qualifier_list
2949                { $$ = DeclarationNode::newPointer( $2, $1 ); }
2950        | ptrref_operator abstract_parameter_declarator
2951                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
2952        | ptrref_operator type_qualifier_list abstract_parameter_declarator
2953                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2954        | '(' abstract_parameter_ptr ')' attribute_list_opt
2955                { $$ = $2->addQualifiers( $4 ); }
2956        ;
2957
2958abstract_parameter_array:
2959        array_parameter_dimension
2960        | '(' abstract_parameter_ptr ')' array_parameter_dimension
2961                { $$ = $2->addArray( $4 ); }
2962        | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
2963                { $$ = $2->addArray( $4 ); }
2964        | '(' abstract_parameter_array ')'                                      // redundant parenthesis
2965                { $$ = $2; }
2966        ;
2967
2968abstract_parameter_function:
2969        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
2970                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
2971        | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2972                { $$ = $2->addParamList( $6 ); }
2973        | '(' abstract_parameter_function ')'                           // redundant parenthesis
2974                { $$ = $2; }
2975        ;
2976
2977array_parameter_dimension:
2978                // Only the first dimension can be empty or have qualifiers.
2979        array_parameter_1st_dimension
2980        | array_parameter_1st_dimension multi_array_dimension
2981                { $$ = $1->addArray( $2 ); }
2982        | multi_array_dimension
2983        ;
2984
2985// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
2986//
2987//              ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
2988//              a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
2989
2990array_parameter_1st_dimension:
2991        '[' ']'
2992                { $$ = DeclarationNode::newArray( 0, 0, false ); }
2993                // multi_array_dimension handles the '[' '*' ']' case
2994        | '[' push type_qualifier_list '*' pop ']'                      // remaining C99
2995                { $$ = DeclarationNode::newVarArray( $3 ); }
2996        | '[' push type_qualifier_list pop ']'
2997                { $$ = DeclarationNode::newArray( 0, $3, false ); }
2998                // multi_array_dimension handles the '[' assignment_expression ']' case
2999        | '[' push type_qualifier_list assignment_expression pop ']'
3000                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3001        | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3002                { $$ = DeclarationNode::newArray( $5, $4, true ); }
3003        | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3004                { $$ = DeclarationNode::newArray( $5, $3, true ); }
3005        ;
3006
3007// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3008//
3009//              struct S {
3010//          int;
3011//          int *;
3012//          int [10];
3013//          int (*)();
3014//      };
3015
3016variable_abstract_declarator:
3017        variable_abstract_ptr
3018        | variable_abstract_array attribute_list_opt
3019                { $$ = $1->addQualifiers( $2 ); }
3020        | variable_abstract_function attribute_list_opt
3021                { $$ = $1->addQualifiers( $2 ); }
3022        ;
3023
3024variable_abstract_ptr:
3025        ptrref_operator
3026                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3027        | ptrref_operator type_qualifier_list
3028                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3029        | ptrref_operator variable_abstract_declarator
3030                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3031        | ptrref_operator type_qualifier_list variable_abstract_declarator
3032                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3033        | '(' variable_abstract_ptr ')' attribute_list_opt
3034                { $$ = $2->addQualifiers( $4 ); }
3035        ;
3036
3037variable_abstract_array:
3038        array_dimension
3039        | '(' variable_abstract_ptr ')' array_dimension
3040                { $$ = $2->addArray( $4 ); }
3041        | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3042                { $$ = $2->addArray( $4 ); }
3043        | '(' variable_abstract_array ')'                                       // redundant parenthesis
3044                { $$ = $2; }
3045        ;
3046
3047variable_abstract_function:
3048        '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3049                { $$ = $2->addParamList( $6 ); }
3050        | '(' variable_abstract_function ')'                            // redundant parenthesis
3051                { $$ = $2; }
3052        ;
3053
3054// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3055// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3056
3057cfa_identifier_parameter_declarator_tuple:                              // CFA
3058        cfa_identifier_parameter_declarator_no_tuple
3059        | cfa_abstract_tuple
3060        | type_qualifier_list cfa_abstract_tuple
3061                { $$ = $2->addQualifiers( $1 ); }
3062        ;
3063
3064cfa_identifier_parameter_declarator_no_tuple:                   // CFA
3065        cfa_identifier_parameter_ptr
3066        | cfa_identifier_parameter_array
3067        ;
3068
3069cfa_identifier_parameter_ptr:                                                   // CFA
3070                // No SUE declaration in parameter list.
3071        ptrref_operator type_specifier_nobody
3072                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3073        | type_qualifier_list ptrref_operator type_specifier_nobody
3074                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3075        | ptrref_operator cfa_abstract_function
3076                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3077        | type_qualifier_list ptrref_operator cfa_abstract_function
3078                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3079        | ptrref_operator cfa_identifier_parameter_declarator_tuple
3080                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3081        | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3082                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3083        ;
3084
3085cfa_identifier_parameter_array:                                                 // CFA
3086                // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3087                // shift/reduce conflict with new-style empty (void) function return type.
3088        '[' ']' type_specifier_nobody
3089                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3090        | cfa_array_parameter_1st_dimension type_specifier_nobody
3091                { $$ = $2->addNewArray( $1 ); }
3092        | '[' ']' multi_array_dimension type_specifier_nobody
3093                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3094        | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3095                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3096        | multi_array_dimension type_specifier_nobody
3097                { $$ = $2->addNewArray( $1 ); }
3098
3099        | '[' ']' cfa_identifier_parameter_ptr
3100                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3101        | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3102                { $$ = $2->addNewArray( $1 ); }
3103        | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3104                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3105        | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3106                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3107        | multi_array_dimension cfa_identifier_parameter_ptr
3108                { $$ = $2->addNewArray( $1 ); }
3109        ;
3110
3111cfa_array_parameter_1st_dimension:
3112        '[' push type_qualifier_list '*' pop ']'                        // remaining C99
3113                { $$ = DeclarationNode::newVarArray( $3 ); }
3114        | '[' push type_qualifier_list assignment_expression pop ']'
3115                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3116        | '[' push declaration_qualifier_list assignment_expression pop ']'
3117                // declaration_qualifier_list must be used because of shift/reduce conflict with
3118                // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3119                // appear in this context.
3120                { $$ = DeclarationNode::newArray( $4, $3, true ); }
3121        | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3122                { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3123        ;
3124
3125// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3126// identifier to which the type applies, e.g.:
3127//
3128//              [int] f( int );                         // abstract variable parameter; no parameter name specified
3129//              [int] f( [int] (int) );         // abstract function-prototype parameter; no parameter name specified
3130//
3131// These rules need LR(3):
3132//
3133//              cfa_abstract_tuple identifier_or_type_name
3134//              '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
3135//
3136// since a function return type can be syntactically identical to a tuple type:
3137//
3138//              [int, int] t;
3139//              [int, int] f( int );
3140//
3141// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3142// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3143// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3144// duplicated when appearing with cfa_function_specifier.
3145
3146cfa_abstract_declarator_tuple:                                                  // CFA
3147        cfa_abstract_tuple
3148        | type_qualifier_list cfa_abstract_tuple
3149                { $$ = $2->addQualifiers( $1 ); }
3150        | cfa_abstract_declarator_no_tuple
3151        ;
3152
3153cfa_abstract_declarator_no_tuple:                                               // CFA
3154        cfa_abstract_ptr
3155        | cfa_abstract_array
3156        ;
3157
3158cfa_abstract_ptr:                                                                               // CFA
3159        ptrref_operator type_specifier
3160                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3161        | type_qualifier_list ptrref_operator type_specifier
3162                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3163        | ptrref_operator cfa_abstract_function
3164                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3165        | type_qualifier_list ptrref_operator cfa_abstract_function
3166                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3167        | ptrref_operator cfa_abstract_declarator_tuple
3168                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3169        | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3170                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3171        ;
3172
3173cfa_abstract_array:                                                                             // CFA
3174                // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3175                // empty (void) function return type.
3176        '[' ']' type_specifier
3177                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3178        | '[' ']' multi_array_dimension type_specifier
3179                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3180        | multi_array_dimension type_specifier
3181                { $$ = $2->addNewArray( $1 ); }
3182        | '[' ']' cfa_abstract_ptr
3183                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3184        | '[' ']' multi_array_dimension cfa_abstract_ptr
3185                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3186        | multi_array_dimension cfa_abstract_ptr
3187                { $$ = $2->addNewArray( $1 ); }
3188        ;
3189
3190cfa_abstract_tuple:                                                                             // CFA
3191        '[' push cfa_abstract_parameter_list pop ']'
3192                { $$ = DeclarationNode::newTuple( $3 ); }
3193        | '[' push type_specifier_nobody ELLIPSIS ']'
3194                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3195        | '[' push type_specifier_nobody ELLIPSIS constant_expression ']'
3196                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3197        ;
3198
3199cfa_abstract_function:                                                                  // CFA
3200//      '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
3201//              { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3202        cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
3203                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3204        | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
3205                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3206        ;
3207
3208// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3209//    each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3210//
3211// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3212//    the declaration specifiers in a declaration is an obsolescent feature."
3213//
3214// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3215//    prototype-format parameter type declarators) is an obsolescent feature."
3216//
3217// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3218//    declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3219
3220//************************* MISCELLANEOUS ********************************
3221
3222comma_opt:                                                                                              // redundant comma
3223        // empty
3224        | ','
3225        ;
3226
3227default_initialize_opt:
3228        // empty
3229                { $$ = nullptr; }
3230        | '=' assignment_expression
3231                { $$ = $2; }
3232        ;
3233
3234%%
3235// ----end of grammar----
3236
3237// Local Variables: //
3238// mode: c++ //
3239// tab-width: 4 //
3240// compile-command: "make install" //
3241// End: //
Note: See TracBrowser for help on using the repository browser.