Context Navigation

parser.yy@ 68cd1ce

Visit:

ADT aaron-thesis arm-eh ast-experimental cleanup-dtors ctor deferred_resn demangler enum forall-pointer-decay gc_noraii jacob/cs343-translation jenkins-sandbox memory new-ast new-ast-unique-expr new-env no_list persistent-indexer pthread-emulation qualifiedEnum resolv-new string with_gc

Last change on this file since 68cd1ce was 68cd1ce, checked in by Peter A. Buhr <pabuhr@…>, 10 years ago
unify and fix storage class
Property mode set to `100644`
File size: 98.8 KB

Line
1	//
2	// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3	//
4	// The contents of this file are covered under the licence agreement in the
5	// file "LICENCE" distributed with Cforall.
6	//
7	// cfa.y --
8	//
9	// Author : Peter A. Buhr
10	// Created On : Sat Sep 1 20:22:55 2001
11	// Last Modified By : Peter A. Buhr
12	// Last Modified On : Sat Jun 13 07:21:45 2015
13	// Update Count : 1048
14	//
15
16	// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on
17	// the C grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS. While
18	// parts have been copied, important changes have been made in all sections; these changes are sufficient to
19	// constitute a new grammar. In particular, this grammar attempts to be more syntactically precise, i.e., it
20	// parses less incorrect language syntax that must be subsequently rejected by semantic checks. Nevertheless,
21	// there are still several semantic checks required and many are noted in the grammar. Finally, the grammar is
22	// extended with GCC and CFA language extensions.
23
24	// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got
25	// stuck with the grammar.
26
27	// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
28	//
29	// 1. designation with '=' (use ':' instead)
30	//
31	// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This
32	// grammar also has two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
33	//
34	// 1. nested functions
35	// 2. generalized lvalues
36	// 3. designation with and without '=' (use ':' instead)
37	// 4. attributes not allowed in parenthesis of declarator
38	//
39	// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for
40	// Cforall (CFA), which fixes several of C's outstanding problems and extends C with many modern language
41	// concepts. All of the syntactic extensions for CFA C are marked with the comment "CFA". As noted above,
42	// there is one unreconcileable parsing problem between C99 and CFA with respect to designators; this is
43	// discussed in detail before the "designation" grammar rule.
44
45	%{
46	#define YYDEBUG_LEXER_TEXT (yylval) // lexer loads this up each time
47	#define YYDEBUG 1 // get the pretty debugging code to compile
48	extern char *yytext;
49
50	#undef __GNUC_MINOR__
51
52	#include <cstdio>
53	#include <stack>
54	#include "TypedefTable.h"
55	#include "lex.h"
56	#include "ParseNode.h"
57	#include "LinkageSpec.h"
58
59	DeclarationNode *theTree = 0; // the resulting parse tree
60	LinkageSpec::Type linkage = LinkageSpec::Cforall;
61	std::stack< LinkageSpec::Type > linkageStack;
62	TypedefTable typedefTable;
63	%}
64
65	//*********************** TERMINAL TOKENS ******************************
66
67	// keywords
68	%token TYPEDEF
69	%token AUTO EXTERN REGISTER STATIC
70	%token INLINE // C99
71	%token FORTRAN // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
72	%token CONST VOLATILE
73	%token RESTRICT // C99
74	%token FORALL LVALUE // CFA
75	%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
76	%token BOOL COMPLEX IMAGINARY // C99
77	%token TYPEOF LABEL // GCC
78	%token ENUM STRUCT UNION
79	%token TYPE FTYPE DTYPE CONTEXT // CFA
80	%token SIZEOF
81	%token ATTRIBUTE EXTENSION // GCC
82	%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
83	%token CHOOSE FALLTHRU TRY CATCH FINALLY THROW // CFA
84	%token ASM // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
85	%token ALIGNAS ALIGNOF ATOMIC GENERIC NORETURN STATICASSERT THREADLOCAL // C11
86
87	// names and constants: lexer differentiates between identifier and typedef names
88	%token<tok> IDENTIFIER QUOTED_IDENTIFIER TYPEDEFname TYPEGENname
89	%token<tok> ATTR_IDENTIFIER ATTR_TYPEDEFname ATTR_TYPEGENname
90	%token<tok> INTEGERconstant FLOATINGconstant CHARACTERconstant STRINGliteral
91	%token<tok> ZERO ONE // CFA
92
93	// multi-character operators
94	%token ARROW // ->
95	%token ICR DECR // ++ --
96	%token LS RS // << >>
97	%token LE GE EQ NE // <= >= == !=
98	%token ANDAND OROR // && \|\|
99	%token ELLIPSIS // ...
100
101	%token MULTassign DIVassign MODassign // *= /= %=/
102	%token PLUSassign MINUSassign // += -=
103	%token LSassign RSassign // <<= >>=
104	%token ANDassign ERassign ORassign // &= ^= \|=
105
106	// Types declaration
107	%union
108	{
109	Token tok;
110	ParseNode *pn;
111	ExpressionNode *en;
112	DeclarationNode *decl;
113	DeclarationNode::Aggregate aggKey;
114	DeclarationNode::TypeClass tclass;
115	StatementNode *sn;
116	ConstantNode *constant;
117	InitializerNode *in;
118	}
119
120	%type<tok> zero_one identifier no_attr_identifier no_01_identifier
121	%type<tok> identifier_or_typedef_name no_attr_identifier_or_typedef_name no_01_identifier_or_typedef_name
122	%type<constant> string_literal_list
123
124	// expressions
125	%type<constant> constant
126	%type<en> tuple tuple_expression_list
127	%type<en> unary_operator assignment_operator
128	%type<en> primary_expression postfix_expression unary_expression
129	%type<en> cast_expression multiplicative_expression additive_expression shift_expression
130	%type<en> relational_expression equality_expression AND_expression exclusive_OR_expression
131	%type<en> inclusive_OR_expression logical_AND_expression logical_OR_expression conditional_expression
132	%type<en> constant_expression assignment_expression assignment_expression_opt
133	%type<en> comma_expression comma_expression_opt
134	%type<en> argument_expression_list argument_expression for_control_expression assignment_opt
135	%type<en> subrange
136
137	// statements
138	%type<sn> labeled_statement compound_statement expression_statement selection_statement
139	%type<sn> iteration_statement jump_statement exception_statement asm_statement
140	%type<sn> fall_through_opt fall_through
141	%type<sn> statement statement_list
142	%type<sn> block_item_list block_item
143	%type<sn> case_clause
144	%type<en> case_value case_value_list
145	%type<sn> case_label case_label_list
146	%type<sn> switch_clause_list_opt switch_clause_list choose_clause_list_opt choose_clause_list
147	%type<pn> handler_list handler_clause finally_clause
148
149	// declarations
150	%type<decl> abstract_array abstract_declarator abstract_function abstract_parameter_array
151	%type<decl> abstract_parameter_declaration abstract_parameter_declarator abstract_parameter_function
152	%type<decl> abstract_parameter_ptr abstract_ptr
153
154	%type<aggKey> aggregate_key
155	%type<decl> aggregate_name
156
157	%type<decl> array_dimension array_parameter_1st_dimension array_parameter_dimension multi_array_dimension
158
159	%type<decl> assertion assertion_list_opt
160
161	%type<en> bit_subrange_size_opt bit_subrange_size
162
163	%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type_name indirect_type_name
164
165	%type<decl> context_declaration context_declaration_list context_declaring_list context_specifier
166
167	%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
168	%type<decl> declaration_specifier declarator declaring_list
169
170	%type<decl> elaborated_type_name
171
172	%type<decl> enumerator_list enum_name
173	%type<en> enumerator_value_opt
174
175	%type<decl> exception_declaration external_definition external_definition_list external_definition_list_opt
176
177	%type<decl> field_declaration field_declaration_list field_declarator field_declaring_list
178	%type<en> field field_list
179
180	%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
181
182	%type<decl> identifier_parameter_array identifier_parameter_declarator identifier_parameter_function
183	%type<decl> identifier_parameter_ptr identifier_list
184
185	%type<decl> new_abstract_array new_abstract_declarator_no_tuple new_abstract_declarator_tuple
186	%type<decl> new_abstract_function new_abstract_parameter_declaration new_abstract_parameter_list
187	%type<decl> new_abstract_ptr new_abstract_tuple
188
189	%type<decl> new_array_parameter_1st_dimension
190
191	%type<decl> new_context_declaring_list new_declaration new_field_declaring_list
192	%type<decl> new_function_declaration new_function_return new_function_specifier
193
194	%type<decl> new_identifier_parameter_array new_identifier_parameter_declarator_no_tuple
195	%type<decl> new_identifier_parameter_declarator_tuple new_identifier_parameter_ptr
196
197	%type<decl> new_parameter_declaration new_parameter_list new_parameter_type_list new_parameter_type_list_opt
198
199	%type<decl> new_typedef_declaration new_variable_declaration new_variable_specifier
200
201	%type<decl> old_declaration old_declaration_list old_declaration_list_opt old_function_array
202	%type<decl> old_function_declarator old_function_no_ptr old_function_ptr
203
204	%type<decl> parameter_declaration parameter_list parameter_type_list
205	%type<decl> parameter_type_list_opt
206
207	%type<decl> paren_identifier paren_typedef
208
209	%type<decl> storage_class storage_class_name storage_class_list
210
211	%type<decl> sue_declaration_specifier sue_type_specifier
212
213	%type<tclass> type_class
214	%type<decl> type_declarator type_declarator_name type_declaring_list
215
216	%type<decl> typedef typedef_array typedef_declaration typedef_declaration_specifier typedef_expression
217	%type<decl> typedef_function typedef_parameter_array typedef_parameter_function typedef_parameter_ptr
218	%type<decl> typedef_parameter_redeclarator typedef_ptr typedef_redeclarator typedef_type_specifier
219	%type<decl> typegen_declaration_specifier typegen_type_specifier
220
221	%type<decl> type_name type_name_no_function
222	%type<decl> type_parameter type_parameter_list
223
224	%type<en> type_name_list
225
226	%type<decl> type_qualifier type_qualifier_name type_qualifier_list type_qualifier_list_opt type_specifier
227
228	%type<decl> variable_abstract_array variable_abstract_declarator variable_abstract_function
229	%type<decl> variable_abstract_ptr variable_array variable_declarator variable_function variable_ptr
230
231	// initializers
232	%type<in> initializer initializer_list initializer_opt
233
234	// designators
235	%type<en> designator designator_list designation
236
237
238	// Handle single shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string
239	// is ambiguous:
240	// .---------. matches IF '(' comma_expression ')' statement
241	// if ( C ) S1 else S2
242	// `-----------------' matches IF '(' comma_expression ')' statement ELSE statement */
243
244	%nonassoc THEN // rule precedence for IF '(' comma_expression ')' statement
245	%nonassoc ELSE // token precedence for start of else clause in IF statement
246
247	%start translation_unit // parse-tree root
248
249	%%
250	//*********************** Namespace Management ******************************
251
252	// The grammar in the ANSI C standard is not strictly context-free, since it relies upon the distinct terminal
253	// symbols "identifier" and "TYPEDEFname" that are lexically identical. While it is possible to write a
254	// purely context-free grammar, such a grammar would obscure the relationship between syntactic and semantic
255	// constructs. Hence, this grammar uses the ANSI style.
256	//
257	// Cforall compounds this problem by introducing type names local to the scope of a declaration (for instance,
258	// those introduced through "forall" qualifiers), and by introducing "type generators" -- parametrized types.
259	// This latter type name creates a third class of identifiers that must be distinguished by the scanner.
260	//
261	// Since the scanner cannot distinguish among the different classes of identifiers without some context
262	// information, it accesses a data structure (the TypedefTable) to allow classification of an identifier that
263	// it has just read. Semantic actions during the parser update this data structure when the class of
264	// identifiers change.
265	//
266	// Because the Cforall language is block-scoped, there is the possibility that an identifier can change its
267	// class in a local scope; it must revert to its original class at the end of the block. Since type names can
268	// be local to a particular declaration, each declaration is itself a scope. This requires distinguishing
269	// between type names that are local to the current declaration scope and those that persist past the end of
270	// the declaration (i.e., names defined in "typedef" or "type" declarations).
271	//
272	// The non-terminals "push" and "pop" derive the empty string; their only use is to denote the opening and
273	// closing of scopes. Every push must have a matching pop, although it is regrettable the matching pairs do
274	// not always occur within the same rule. These non-terminals may appear in more contexts than strictly
275	// necessary from a semantic point of view. Unfortunately, these extra rules are necessary to prevent parsing
276	// conflicts -- the parser may not have enough context and look-ahead information to decide whether a new
277	// scope is necessary, so the effect of these extra rules is to open a new scope unconditionally. As the
278	// grammar evolves, it may be neccesary to add or move around "push" and "pop" nonterminals to resolve
279	// conflicts of this sort.
280
281	push:
282	{
283	typedefTable.enterScope();
284	}
285	;
286
287	pop:
288	{
289	typedefTable.leaveScope();
290	}
291	;
292
293	//*********************** CONSTANTS ******************************
294
295	constant:
296	// ENUMERATIONconstant is not included here; it is treated as a variable with type
297	// "enumeration constant".
298	INTEGERconstant { $$ = new ConstantNode( ConstantNode::Integer, $1 ); }
299	\| FLOATINGconstant { $$ = new ConstantNode( ConstantNode::Float, $1 ); }
300	\| CHARACTERconstant { $$ = new ConstantNode( ConstantNode::Character, $1 ); }
301	;
302
303	identifier:
304	IDENTIFIER
305	\| ATTR_IDENTIFIER // CFA
306	\| zero_one // CFA
307	;
308
309	no_01_identifier:
310	IDENTIFIER
311	\| ATTR_IDENTIFIER // CFA
312	;
313
314	no_attr_identifier:
315	IDENTIFIER
316	;
317
318	zero_one: // CFA
319	ZERO
320	\| ONE
321	;
322
323	string_literal_list: // juxtaposed strings are concatenated
324	STRINGliteral { $$ = new ConstantNode( ConstantNode::String, $1 ); }
325	\| string_literal_list STRINGliteral { $$ = $1->appendstr( $2 ); }
326	;
327
328	//*********************** EXPRESSIONS ******************************
329
330	primary_expression:
331	IDENTIFIER // typedef name cannot be used as a variable name
332	{ $$ = new VarRefNode($1); }
333	\| zero_one
334	{ $$ = new VarRefNode($1); }
335	\| constant
336	{ $$ = $1; }
337	\| string_literal_list
338	{ $$ = $1; }
339	\| '(' comma_expression ')'
340	{ $$ = $2; }
341	\| '(' compound_statement ')' // GCC, lambda expression
342	{ $$ = new ValofExprNode($2); }
343	;
344
345	postfix_expression:
346	primary_expression
347	\| postfix_expression '[' push assignment_expression pop ']'
348	// CFA, comma_expression disallowed in the context because it results in a commom user error:
349	// subscripting a matrix with x[i,j] instead of x[i][j]. While this change is not backwards
350	// compatible, there seems to be little advantage to this feature and many disadvantages. It is
351	// possible to write x[(i,j)] in CFA, which is equivalent to the old x[i,j].
352	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Index), $1, $4); }
353	\| postfix_expression '(' argument_expression_list ')'
354	{ $$ = new CompositeExprNode($1, $3); }
355	\| postfix_expression '.' no_attr_identifier
356	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::FieldSel), $1, new VarRefNode($3)); }
357	\| postfix_expression '.' '[' push field_list pop ']' // CFA, tuple field selector
358	\| postfix_expression ARROW no_attr_identifier
359	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::PFieldSel), $1, new VarRefNode($3)); }
360	\| postfix_expression ARROW '[' push field_list pop ']' // CFA, tuple field selector
361	\| postfix_expression ICR
362	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::IncrPost), $1); }
363	\| postfix_expression DECR
364	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::DecrPost), $1); }
365	// GCC has priority: cast_expression
366	\| '(' type_name_no_function ')' '{' initializer_list comma_opt '}' // C99
367	{ $$ = 0; }
368	;
369
370	argument_expression_list:
371	argument_expression
372	\| argument_expression_list ',' argument_expression
373	{ $$ = (ExpressionNode *)($1->set_link($3)); }
374	;
375
376	argument_expression:
377	// empty
378	{ $$ = 0; } // use default argument
379	\| assignment_expression
380	\| no_attr_identifier ':' assignment_expression
381	{ $$ = $3->set_asArgName($1); }
382	// Only a list of no_attr_identifier_or_typedef_name is allowed in this context. However, there is
383	// insufficient look ahead to distinguish between this list of parameter names and a tuple, so the
384	// tuple form must be used with an appropriate semantic check.
385	\| '[' push assignment_expression pop ']' ':' assignment_expression
386	{ $$ = $7->set_asArgName($3); }
387	\| '[' push assignment_expression ',' tuple_expression_list pop ']' ':' assignment_expression
388	{ $$ = $9->set_asArgName( new CompositeExprNode( new OperatorNode( OperatorNode::TupleC ), (ExpressionNode *)$3->set_link( flattenCommas( $5 )))); }
389	;
390
391	field_list: // CFA, tuple field selector
392	field
393	\| field_list ',' field { $$ = (ExpressionNode *)$1->set_link( $3 ); }
394	;
395
396	field: // CFA, tuple field selector
397	no_attr_identifier
398	{ $$ = new VarRefNode( $1 ); }
399	\| no_attr_identifier '.' field
400	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::FieldSel), new VarRefNode( $1 ), $3); }
401	\| no_attr_identifier '.' '[' push field_list pop ']'
402	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::FieldSel), new VarRefNode( $1 ), $5); }
403	\| no_attr_identifier ARROW field
404	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::PFieldSel), new VarRefNode( $1 ), $3); }
405	\| no_attr_identifier ARROW '[' push field_list pop ']'
406	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::PFieldSel), new VarRefNode( $1 ), $5); }
407	;
408
409	unary_expression:
410	postfix_expression
411	\| ICR unary_expression
412	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Incr), $2); }
413	\| DECR unary_expression
414	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Decr), $2); }
415	\| EXTENSION cast_expression // GCC
416	{ $$ = $2; }
417	\| unary_operator cast_expression
418	{ $$ = new CompositeExprNode($1, $2); }
419	\| '!' cast_expression
420	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Neg), $2); }
421	\| '*' cast_expression // CFA
422	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::PointTo), $2); }
423	// '*' is is separated from unary_operator because of shift/reduce conflict in:
424	// { * X; } // dereference X
425	// { * int X; } // CFA declaration of pointer to int
426	// '&' must be moved here if C++ reference variables are supported.
427	\| SIZEOF unary_expression
428	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::SizeOf), $2); }
429	\| SIZEOF '(' type_name_no_function ')'
430	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::SizeOf), new TypeValueNode($3)); }
431	\| ATTR_IDENTIFIER
432	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Attr), new VarRefNode($1)); }
433	\| ATTR_IDENTIFIER '(' type_name ')'
434	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Attr), new VarRefNode($1), new TypeValueNode($3)); }
435	\| ATTR_IDENTIFIER '(' argument_expression ')'
436	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Attr), new VarRefNode($1), $3); }
437	\| ALIGNOF unary_expression // GCC, variable alignment
438	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::AlignOf), $2); }
439	\| ALIGNOF '(' type_name_no_function ')' // GCC, type alignment
440	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::AlignOf), new TypeValueNode($3)); }
441	\| ANDAND no_attr_identifier // GCC, address of label
442	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::LabelAddress), new VarRefNode($2, true)); }
443	;
444
445	unary_operator:
446	'&' { $$ = new OperatorNode(OperatorNode::AddressOf); }
447	\| '+' { $$ = new OperatorNode(OperatorNode::UnPlus); }
448	\| '-' { $$ = new OperatorNode(OperatorNode::UnMinus); }
449	\| '~' { $$ = new OperatorNode(OperatorNode::BitNeg); }
450	;
451
452	cast_expression:
453	unary_expression
454	\| '(' type_name_no_function ')' cast_expression
455	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Cast), new TypeValueNode($2), $4); }
456	\| '(' type_name_no_function ')' tuple
457	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Cast), new TypeValueNode($2), $4); }
458	;
459
460	multiplicative_expression:
461	cast_expression
462	\| multiplicative_expression '*' cast_expression
463	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Mul),$1,$3); }
464	\| multiplicative_expression '/' cast_expression
465	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Div),$1,$3); }
466	\| multiplicative_expression '%' cast_expression
467	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Mod),$1,$3); }
468	;
469
470	additive_expression:
471	multiplicative_expression
472	\| additive_expression '+' multiplicative_expression
473	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Plus),$1,$3); }
474	\| additive_expression '-' multiplicative_expression
475	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Minus),$1,$3); }
476	;
477
478	shift_expression:
479	additive_expression
480	\| shift_expression LS additive_expression
481	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::LShift),$1,$3); }
482	\| shift_expression RS additive_expression
483	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::RShift),$1,$3); }
484	;
485
486	relational_expression:
487	shift_expression
488	\| relational_expression '<' shift_expression
489	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::LThan),$1,$3); }
490	\| relational_expression '>' shift_expression
491	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::GThan),$1,$3); }
492	\| relational_expression LE shift_expression
493	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::LEThan),$1,$3); }
494	\| relational_expression GE shift_expression
495	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::GEThan),$1,$3); }
496	;
497
498	equality_expression:
499	relational_expression
500	\| equality_expression EQ relational_expression
501	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Eq), $1, $3); }
502	\| equality_expression NE relational_expression
503	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Neq), $1, $3); }
504	;
505
506	AND_expression:
507	equality_expression
508	\| AND_expression '&' equality_expression
509	{ $$ =new CompositeExprNode(new OperatorNode(OperatorNode::BitAnd), $1, $3); }
510	;
511
512	exclusive_OR_expression:
513	AND_expression
514	\| exclusive_OR_expression '^' AND_expression
515	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Xor), $1, $3); }
516	;
517
518	inclusive_OR_expression:
519	exclusive_OR_expression
520	\| inclusive_OR_expression '\|' exclusive_OR_expression
521	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::BitOr), $1, $3); }
522	;
523
524	logical_AND_expression:
525	inclusive_OR_expression
526	\| logical_AND_expression ANDAND inclusive_OR_expression
527	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::And), $1, $3); }
528	;
529
530	logical_OR_expression:
531	logical_AND_expression
532	\| logical_OR_expression OROR logical_AND_expression
533	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Or), $1, $3); }
534	;
535
536	conditional_expression:
537	logical_OR_expression
538	\| logical_OR_expression '?' comma_expression ':' conditional_expression
539	{ $$ = new CompositeExprNode( new OperatorNode(OperatorNode::Cond), (ExpressionNode )mkList( ($1, $3, $5) ) ); }
540	\| logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
541	{ $$=new CompositeExprNode(new OperatorNode(OperatorNode::NCond),$1,$4); }
542	\| logical_OR_expression '?' comma_expression ':' tuple // CFA, tuple expression
543	{ $$ = new CompositeExprNode( new OperatorNode(OperatorNode::Cond), (ExpressionNode )mkList( ($1, $3, $5) ) ); }
544	;
545
546	constant_expression:
547	conditional_expression
548	;
549
550	assignment_expression:
551	// CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
552	conditional_expression
553	\| unary_expression '=' assignment_expression
554	{ $$ =new CompositeExprNode(new OperatorNode(OperatorNode::Assign), $1, $3); }
555	\| unary_expression assignment_operator assignment_expression
556	{ $$ =new CompositeExprNode($2, $1, $3); }
557	\| tuple assignment_opt // CFA, tuple expression
558	{ $$ = ($2 == 0) ? $1 : new CompositeExprNode( new OperatorNode( OperatorNode::Assign ), $1, $2 ); }
559	;
560
561	assignment_expression_opt:
562	// empty
563	{ $$ = new NullExprNode; }
564	\| assignment_expression
565	;
566
567	tuple: // CFA, tuple
568	// CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce
569	// conflict with comma_expression in new_identifier_parameter_array and new_abstract_array
570	'[' push pop ']'
571	{ $$ = new CompositeExprNode( new OperatorNode( OperatorNode::TupleC ) ); }
572	\| '[' push assignment_expression pop ']'
573	{ $$ = new CompositeExprNode( new OperatorNode( OperatorNode::TupleC ), $3 ); }
574	\| '[' push ',' tuple_expression_list pop ']'
575	{ $$ = new CompositeExprNode( new OperatorNode( OperatorNode::TupleC ), (ExpressionNode *)(new NullExprNode)->set_link( $4 ) ); }
576	\| '[' push assignment_expression ',' tuple_expression_list pop ']'
577	{ $$ = new CompositeExprNode( new OperatorNode( OperatorNode::TupleC ), (ExpressionNode *)$3->set_link( flattenCommas( $5 ) ) ); }
578	;
579
580	tuple_expression_list:
581	assignment_expression_opt
582	\| tuple_expression_list ',' assignment_expression_opt
583	{ $$ = (ExpressionNode *)$1->set_link( $3 ); }
584	;
585
586	assignment_operator:
587	MULTassign { $$ = new OperatorNode(OperatorNode::MulAssn); }
588	\| DIVassign { $$ = new OperatorNode(OperatorNode::DivAssn); }
589	\| MODassign { $$ = new OperatorNode(OperatorNode::ModAssn); }
590	\| PLUSassign { $$ = new OperatorNode(OperatorNode::PlusAssn); }
591	\| MINUSassign { $$ = new OperatorNode(OperatorNode::MinusAssn); }
592	\| LSassign { $$ = new OperatorNode(OperatorNode::LSAssn); }
593	\| RSassign { $$ = new OperatorNode(OperatorNode::RSAssn); }
594	\| ANDassign { $$ = new OperatorNode(OperatorNode::AndAssn); }
595	\| ERassign { $$ = new OperatorNode(OperatorNode::ERAssn); }
596	\| ORassign { $$ = new OperatorNode(OperatorNode::OrAssn); }
597	;
598
599	comma_expression:
600	assignment_expression
601	\| comma_expression ',' assignment_expression // { $$ = (ExpressionNode *)$1->add_to_list($3); }
602	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Comma),$1,$3); }
603	;
604
605	comma_expression_opt:
606	// empty
607	{ $$ = 0; }
608	\| comma_expression
609	;
610
611	//************************* STATEMENTS *****************************
612
613	statement:
614	labeled_statement
615	\| compound_statement
616	\| expression_statement { $$ = $1; }
617	\| selection_statement
618	\| iteration_statement
619	\| jump_statement
620	\| exception_statement
621	\| asm_statement
622	;
623
624	labeled_statement:
625	no_attr_identifier ':' attribute_list_opt statement
626	{ $$ = $4->add_label($1);}
627	;
628
629	compound_statement:
630	'{' '}'
631	{ $$ = new CompoundStmtNode( (StatementNode *)0 ); }
632	\| '{'
633	// Two scopes are necessary because the block itself has a scope, but every declaration within the
634	// block also requires its own scope
635	push push
636	label_declaration_opt // GCC, local labels
637	block_item_list pop '}' // C99, intermix declarations and statements
638	{ $$ = new CompoundStmtNode( $5 ); }
639	;
640
641	block_item_list: // C99
642	block_item
643	\| block_item_list push block_item
644	{ if ($1 != 0) { $1->set_link($3); $$ = $1; } }
645	;
646
647	block_item:
648	declaration // CFA, new & old style declarations
649	{ $$ = new StatementNode( $1 ); }
650	\| EXTENSION declaration // GCC
651	{ $$ = new StatementNode( $2 ); }
652	\| function_definition
653	{ $$ = new StatementNode( $1 ); }
654	\| statement pop
655	;
656
657	statement_list:
658	statement
659	\| statement_list statement
660	{ if ($1 != 0) { $1->set_link($2); $$ = $1; } }
661	;
662
663	expression_statement:
664	comma_expression_opt ';'
665	{ $$ = new StatementNode(StatementNode::Exp, $1, 0); }
666	;
667
668	selection_statement:
669	IF '(' comma_expression ')' statement %prec THEN
670	// explicitly deal with the shift/reduce conflict on if/else
671	{ $$ = new StatementNode(StatementNode::If, $3, $5); }
672	\| IF '(' comma_expression ')' statement ELSE statement
673	{ $$ = new StatementNode(StatementNode::If, $3, (StatementNode )mkList(($5, *$7)) ); }
674	\| SWITCH '(' comma_expression ')' case_clause // CFA
675	{ $$ = new StatementNode(StatementNode::Switch, $3, $5); }
676	\| SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt '}' // CFA
677	{ $$ = new StatementNode(StatementNode::Switch, $3, $8); /* xxx */ }
678	// The semantics of the declaration list is changed to include any associated initialization, which is
679	// performed before the transfer to the appropriate case clause. Statements after the initial
680	// declaration list can never be executed, and therefore, are removed from the grammar even though C
681	// allows it.
682	\| CHOOSE '(' comma_expression ')' case_clause // CFA
683	{ $$ = new StatementNode(StatementNode::Choose, $3, $5); }
684	\| CHOOSE '(' comma_expression ')' '{' push declaration_list_opt choose_clause_list_opt '}' // CFA
685	{ $$ = new StatementNode(StatementNode::Choose, $3, $8); }
686	;
687
688	// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a
689	// case clause allows a list of values and subranges.
690
691	case_value: // CFA
692	constant_expression { $$ = $1; }
693	\| constant_expression ELLIPSIS constant_expression // GCC, subrange
694	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Range),$1,$3); }
695	\| subrange // CFA, subrange
696	;
697
698	case_value_list: // CFA
699	case_value
700	\| case_value_list ',' case_value
701	{ $$ = new CompositeExprNode(new OperatorNode( OperatorNode::TupleC ), (ExpressionNode *)(tupleContents($1))->set_link($3) ); }
702	;
703
704	case_label: // CFA
705	CASE case_value_list ':' { $$ = new StatementNode(StatementNode::Case, $2, 0); }
706	\| DEFAULT ':' { $$ = new StatementNode(StatementNode::Default); }
707	// A semantic check is required to ensure only one default clause per switch/choose statement.
708	;
709
710	case_label_list: // CFA
711	case_label
712	\| case_label_list case_label { $$ = (StatementNode *)($1->set_link($2)); }
713	;
714
715	case_clause: // CFA
716	case_label_list statement { $$ = $1->append_last_case($2); }
717	;
718
719	switch_clause_list_opt: // CFA
720	// empty
721	{ $$ = 0; }
722	\| switch_clause_list
723	;
724
725	switch_clause_list: // CFA
726	case_label_list statement_list
727	{ $$ = $1->append_last_case($2); }
728	\| switch_clause_list case_label_list statement_list
729	{ $$ = (StatementNode *)($1->set_link($2->append_last_case($3))); }
730	;
731
732	choose_clause_list_opt: // CFA
733	// empty
734	{ $$ = 0; }
735	\| choose_clause_list
736	;
737
738	choose_clause_list: // CFA
739	case_label_list fall_through
740	{ $$ = $1->append_last_case($2); }
741	\| case_label_list statement_list fall_through_opt
742	{ $$ = $1->append_last_case((StatementNode )mkList(($2,*$3))); }
743	\| choose_clause_list case_label_list fall_through
744	{ $$ = (StatementNode *)($1->set_link($2->append_last_case($3))); }
745	\| choose_clause_list case_label_list statement_list fall_through_opt
746	{ $$ = (StatementNode )($1->set_link($2->append_last_case((StatementNode )mkList(($3,$4))))); }
747	;
748
749	fall_through_opt: // CFA
750	// empty
751	{ $$ = 0; }
752	\| fall_through
753	;
754
755	fall_through: // CFA
756	FALLTHRU { $$ = new StatementNode(StatementNode::Fallthru, 0, 0); }
757	\| FALLTHRU ';' { $$ = new StatementNode(StatementNode::Fallthru, 0, 0); }
758	;
759
760	iteration_statement:
761	WHILE '(' comma_expression ')' statement
762	{ $$ = new StatementNode(StatementNode::While, $3, $5); }
763	\| DO statement WHILE '(' comma_expression ')' ';'
764	{ $$ = new StatementNode(StatementNode::Do, $5, $2); }
765	\| FOR '(' push for_control_expression ')' statement
766	{ $$ = new StatementNode(StatementNode::For, $4, $6); }
767	;
768
769	for_control_expression:
770	comma_expression_opt pop ';' comma_expression_opt ';' comma_expression_opt
771	{ $$ = new ForCtlExprNode($1, $4, $6); }
772	\| declaration comma_expression_opt ';' comma_expression_opt // C99
773	{ $$ = new ForCtlExprNode($1, $2, $4); }
774	;
775
776	jump_statement:
777	GOTO no_attr_identifier ';'
778	{ $$ = new StatementNode(StatementNode::Goto, $2); }
779	\| GOTO '*' comma_expression ';' // GCC, computed goto
780	// The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; =>
781	// goto (i+3); whereas normal operator precedence yields goto (i)+3;
782	{ $$ = new StatementNode(StatementNode::Goto, $3); }
783	\| CONTINUE ';'
784	// A semantic check is required to ensure this statement appears only in the body of an iteration
785	// statement.
786	{ $$ = new StatementNode(StatementNode::Continue, 0, 0); }
787	\| CONTINUE no_attr_identifier ';' // CFA, multi-level continue
788	// A semantic check is required to ensure this statement appears only in the body of an iteration
789	// statement, and the target of the transfer appears only at the start of an iteration statement.
790	{ $$ = new StatementNode(StatementNode::Continue, $2); }
791	\| BREAK ';'
792	// A semantic check is required to ensure this statement appears only in the body of an iteration
793	// statement.
794	{ $$ = new StatementNode(StatementNode::Break, 0, 0); }
795	\| BREAK no_attr_identifier ';' // CFA, multi-level exit
796	// A semantic check is required to ensure this statement appears only in the body of an iteration
797	// statement, and the target of the transfer appears only at the start of an iteration statement.
798	{ $$ = new StatementNode(StatementNode::Break, $2 ); }
799	\| RETURN comma_expression_opt ';'
800	{ $$ = new StatementNode(StatementNode::Return, $2, 0); }
801	\| THROW assignment_expression ';'
802	{ $$ = new StatementNode(StatementNode::Throw, $2, 0); }
803	\| THROW ';'
804	{ $$ = new StatementNode(StatementNode::Throw, 0, 0); }
805	;
806
807	exception_statement:
808	TRY compound_statement handler_list
809	{ $$ = new StatementNode(StatementNode::Try, 0,(StatementNode )(mkList(($2,*$3)))); }
810	\| TRY compound_statement finally_clause
811	{ $$ = new StatementNode(StatementNode::Try, 0,(StatementNode )(mkList(($2,*$3)))); }
812	\| TRY compound_statement handler_list finally_clause
813	{
814	$3->set_link($4);
815	$$ = new StatementNode(StatementNode::Try, 0,(StatementNode )(mkList(($2,*$3))));
816	}
817	;
818
819	handler_list:
820	// There must be at least one catch clause
821	handler_clause
822	// ISO/IEC 9899:1999 Section 15.3(6) If present, a "..." handler shall be the last handler for its try
823	// block.
824	\| CATCH '(' ELLIPSIS ')' compound_statement
825	{ $$ = StatementNode::newCatchStmt( 0, $5, true ); }
826	\| handler_clause CATCH '(' ELLIPSIS ')' compound_statement
827	{ $$ = $1->set_link( StatementNode::newCatchStmt( 0, $6, true ) ); }
828	;
829
830	handler_clause:
831	CATCH '(' push push exception_declaration pop ')' compound_statement pop
832	{ $$ = StatementNode::newCatchStmt($5, $8); }
833	\| handler_clause CATCH '(' push push exception_declaration pop ')' compound_statement pop
834	{ $$ = $1->set_link( StatementNode::newCatchStmt($6, $9) ); }
835	;
836
837	finally_clause:
838	FINALLY compound_statement
839	{
840	$$ = new StatementNode(StatementNode::Finally, 0, $2);
841	std::cout << "Just created a finally node" << std::endl;
842	}
843	;
844
845	exception_declaration:
846	// A semantic check is required to ensure type_specifier does not create a new type, e.g.:
847	//
848	// catch ( struct { int i; } x ) ...
849	//
850	// This new type cannot catch any thrown type because of name equivalence among types.
851	type_specifier
852	\| type_specifier declarator
853	{
854	typedefTable.addToEnclosingScope( TypedefTable::ID );
855	$$ = $2->addType( $1 );
856	}
857	\| type_specifier variable_abstract_declarator
858	{ $$ = $2->addType( $1 ); }
859	\| new_abstract_declarator_tuple no_attr_identifier // CFA
860	{
861	typedefTable.addToEnclosingScope( TypedefTable::ID );
862	$$ = $1->addName( $2 );
863	}
864	\| new_abstract_declarator_tuple // CFA
865	;
866
867	asm_statement:
868	ASM type_qualifier_list_opt '(' constant_expression ')' ';'
869	{ $$ = new StatementNode(StatementNode::Asm, 0, 0); }
870	\| ASM type_qualifier_list_opt '(' constant_expression ':' asm_operands_opt ')' ';' // remaining GCC
871	{ $$ = new StatementNode(StatementNode::Asm, 0, 0); }
872	\| ASM type_qualifier_list_opt '(' constant_expression ':' asm_operands_opt ':' asm_operands_opt ')' ';'
873	{ $$ = new StatementNode(StatementNode::Asm, 0, 0); }
874	\| ASM type_qualifier_list_opt '(' constant_expression ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list ')' ';'
875	{ $$ = new StatementNode(StatementNode::Asm, 0, 0); }
876	;
877
878	asm_operands_opt: // GCC
879	// empty
880	\| asm_operands_list
881	;
882
883	asm_operands_list: // GCC
884	asm_operand
885	\| asm_operands_list ',' asm_operand
886	;
887
888	asm_operand: // GCC
889	STRINGliteral '(' constant_expression ')' {}
890	;
891
892	asm_clobbers_list: // GCC
893	STRINGliteral {}
894	\| asm_clobbers_list ',' STRINGliteral
895	;
896
897	//***************************** DECLARATIONS *******************************
898
899	declaration_list_opt: // used at beginning of switch statement
900	pop
901	{ $$ = 0; }
902	\| declaration_list
903	;
904
905	declaration_list:
906	declaration
907	\| declaration_list push declaration
908	{ $$ = $1->appendList( $3 ); }
909	;
910
911	old_declaration_list_opt: // used to declare parameter types in K&R style functions
912	pop
913	{ $$ = 0; }
914	\| old_declaration_list
915	;
916
917	old_declaration_list:
918	old_declaration
919	\| old_declaration_list push old_declaration
920	{ $$ = $1->appendList( $3 ); }
921	;
922
923	label_declaration_opt: // GCC, local label
924	// empty
925	\| label_declaration_list
926	;
927
928	label_declaration_list: // GCC, local label
929	LABEL label_list ';'
930	\| label_declaration_list LABEL label_list ';'
931	;
932
933	label_list: // GCC, local label
934	no_attr_identifier_or_typedef_name {}
935	\| label_list ',' no_attr_identifier_or_typedef_name {}
936	;
937
938	declaration: // CFA, new & old style declarations
939	new_declaration
940	\| old_declaration
941	;
942
943	// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and
944	// function declarations. CFA declarations use the same declaration tokens as in C; however, CFA places
945	// declaration modifiers to the left of the base type, while C declarations place modifiers to the right of
946	// the base type. CFA declaration modifiers are interpreted from left to right and the entire type
947	// specification is distributed across all variables in the declaration list (as in Pascal). ANSI C and the
948	// new CFA declarations may appear together in the same program block, but cannot be mixed within a specific
949	// declaration.
950	//
951	// CFA C
952	// [10] int x; int x[10]; // array of 10 integers
953	// [10] * char y; char *y[10]; // array of 10 pointers to char
954
955	new_declaration: // CFA
956	new_variable_declaration pop ';'
957	\| new_typedef_declaration pop ';'
958	\| new_function_declaration pop ';'
959	\| type_declaring_list pop ';'
960	\| context_specifier pop ';'
961	;
962
963	new_variable_declaration: // CFA
964	new_variable_specifier initializer_opt
965	{
966	typedefTable.addToEnclosingScope( TypedefTable::ID );
967	$$ = $1;
968	}
969	\| declaration_qualifier_list new_variable_specifier initializer_opt
970	// declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to
971	// preclude them as a type_qualifier cannot appear in that context.
972	{
973	typedefTable.addToEnclosingScope( TypedefTable::ID );
974	$$ = $2->addQualifiers( $1 );
975	}
976	\| new_variable_declaration pop ',' push identifier_or_typedef_name initializer_opt
977	{
978	typedefTable.addToEnclosingScope( *$5, TypedefTable::ID );
979	$$ = $1->appendList( $1->cloneType( $5 ) );
980	}
981	;
982
983	new_variable_specifier: // CFA
984	// A semantic check is required to ensure asm_name only appears on declarations with implicit or
985	// explicit static storage-class
986	new_abstract_declarator_no_tuple identifier_or_typedef_name asm_name_opt
987	{
988	typedefTable.setNextIdentifier( *$2 );
989	$$ = $1->addName( $2 );
990	}
991	\| new_abstract_tuple identifier_or_typedef_name asm_name_opt
992	{
993	typedefTable.setNextIdentifier( *$2 );
994	$$ = $1->addName( $2 );
995	}
996	\| type_qualifier_list new_abstract_tuple identifier_or_typedef_name asm_name_opt
997	{
998	typedefTable.setNextIdentifier( *$3 );
999	$$ = $2->addQualifiers( $1 )->addName( $3 );
1000	}
1001	;
1002
1003	new_function_declaration: // CFA
1004	new_function_specifier
1005	{
1006	typedefTable.addToEnclosingScope( TypedefTable::ID );
1007	$$ = $1;
1008	}
1009	\| type_qualifier_list new_function_specifier
1010	{
1011	typedefTable.addToEnclosingScope( TypedefTable::ID );
1012	$$ = $2->addQualifiers( $1 );
1013	}
1014	\| declaration_qualifier_list new_function_specifier
1015	{
1016	typedefTable.addToEnclosingScope( TypedefTable::ID );
1017	$$ = $2->addQualifiers( $1 );
1018	}
1019	\| declaration_qualifier_list type_qualifier_list new_function_specifier
1020	{
1021	typedefTable.addToEnclosingScope( TypedefTable::ID );
1022	$$ = $3->addQualifiers( $1 )->addQualifiers( $2 );
1023	}
1024	\| new_function_declaration pop ',' push identifier_or_typedef_name
1025	{
1026	typedefTable.addToEnclosingScope( *$5, TypedefTable::ID );
1027	$$ = $1->appendList( $1->cloneType( $5 ) );
1028	}
1029	;
1030
1031	new_function_specifier: // CFA
1032	'[' push pop ']' identifier '(' push new_parameter_type_list_opt pop ')'
1033	{
1034	typedefTable.setNextIdentifier( *($5) );
1035	$$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1036	}
1037	\| '[' push pop ']' TYPEDEFname '(' push new_parameter_type_list_opt pop ')'
1038	{
1039	typedefTable.setNextIdentifier( *($5) );
1040	$$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1041	}
1042	// identifier_or_typedef_name must be broken apart because of the sequence:
1043	//
1044	// '[' ']' identifier_or_typedef_name '(' new_parameter_type_list_opt ')'
1045	// '[' ']' type_specifier
1046	//
1047	// type_specifier can resolve to just TYPEDEFname (e.g. typedef int T; int f( T );). Therefore this
1048	// must be flattened to allow lookahead to the '(' without having to reduce
1049	// identifier_or_typedef_name.
1050	\| new_abstract_tuple identifier_or_typedef_name '(' push new_parameter_type_list_opt pop ')'
1051	// To obtain LR(1), this rule must be factored out from function return type (see
1052	// new_abstract_declarator).
1053	{
1054	$$ = DeclarationNode::newFunction( $2, $1, $5, 0, true );
1055	}
1056	\| new_function_return identifier_or_typedef_name '(' push new_parameter_type_list_opt pop ')'
1057	{
1058	$$ = DeclarationNode::newFunction( $2, $1, $5, 0, true );
1059	}
1060	;
1061
1062	new_function_return: // CFA
1063	'[' push new_parameter_list pop ']'
1064	{ $$ = DeclarationNode::newTuple( $3 ); }
1065	\| '[' push new_parameter_list pop ',' push new_abstract_parameter_list pop ']'
1066	// To obtain LR(1), the last new_abstract_parameter_list is added into this flattened rule to
1067	// lookahead to the ']'.
1068	{ $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1069	;
1070
1071	new_typedef_declaration: // CFA
1072	TYPEDEF new_variable_specifier
1073	{
1074	typedefTable.addToEnclosingScope( TypedefTable::TD);
1075	$$ = $2->addTypedef();
1076	}
1077	\| TYPEDEF new_function_specifier
1078	{
1079	typedefTable.addToEnclosingScope( TypedefTable::TD);
1080	$$ = $2->addTypedef();
1081	}
1082	\| new_typedef_declaration pop ',' push no_attr_identifier
1083	{
1084	typedefTable.addToEnclosingScope( *$5, TypedefTable::TD);
1085	$$ = $1->appendList( $1->cloneType( $5 ) );
1086	}
1087	;
1088
1089	// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is
1090	// factored out as a separate form of declaration, which syntactically precludes storage-class specifiers and
1091	// initialization.
1092
1093	typedef_declaration:
1094	TYPEDEF type_specifier declarator
1095	{
1096	typedefTable.addToEnclosingScope( TypedefTable::TD);
1097	$$ = $3->addType( $2 )->addTypedef();
1098	}
1099	\| typedef_declaration pop ',' push declarator
1100	{
1101	typedefTable.addToEnclosingScope( TypedefTable::TD);
1102	$$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1103	}
1104	\| type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2)
1105	{
1106	typedefTable.addToEnclosingScope( TypedefTable::TD);
1107	$$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1108	}
1109	\| type_specifier TYPEDEF declarator
1110	{
1111	typedefTable.addToEnclosingScope( TypedefTable::TD);
1112	$$ = $3->addType( $1 )->addTypedef();
1113	}
1114	\| type_specifier TYPEDEF type_qualifier_list declarator
1115	{
1116	typedefTable.addToEnclosingScope( TypedefTable::TD);
1117	$$ = $4->addQualifiers($1)->addTypedef()->addType($1);
1118	}
1119	;
1120
1121	typedef_expression: // GCC, naming expression type
1122	TYPEDEF no_attr_identifier '=' assignment_expression
1123	{
1124	typedefTable.addToEnclosingScope(*($2), TypedefTable::TD);
1125	$$ = DeclarationNode::newName( 0 ); // XXX
1126	}
1127	\| typedef_expression pop ',' push no_attr_identifier '=' assignment_expression
1128	{
1129	typedefTable.addToEnclosingScope(*($5), TypedefTable::TD);
1130	$$ = DeclarationNode::newName( 0 ); // XXX
1131	}
1132	;
1133
1134	old_declaration:
1135	declaring_list pop ';'
1136	\| typedef_declaration pop ';'
1137	\| typedef_expression pop ';' // GCC, naming expression type
1138	\| sue_declaration_specifier pop ';'
1139	;
1140
1141	declaring_list:
1142	// A semantic check is required to ensure asm_name only appears on declarations with implicit or
1143	// explicit static storage-class
1144	declaration_specifier declarator asm_name_opt initializer_opt
1145	{
1146	typedefTable.addToEnclosingScope( TypedefTable::ID );
1147	$$ = ($2->addType( $1 ))->addInitializer($4);
1148	}
1149	\| declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1150	{
1151	typedefTable.addToEnclosingScope( TypedefTable::ID );
1152	$$ = $1->appendList( $1->cloneBaseType( $4->addInitializer($6) ) );
1153	}
1154	;
1155
1156	declaration_specifier: // type specifier + storage class
1157	basic_declaration_specifier
1158	\| sue_declaration_specifier
1159	\| typedef_declaration_specifier
1160	\| typegen_declaration_specifier
1161	;
1162
1163	type_specifier: // declaration specifier - storage class
1164	basic_type_specifier
1165	\| sue_type_specifier
1166	\| typedef_type_specifier
1167	\| typegen_type_specifier
1168	;
1169
1170	type_qualifier_list_opt: // GCC, used in asm_statement
1171	// empty
1172	{ $$ = 0; }
1173	\| type_qualifier_list
1174	;
1175
1176	type_qualifier_list:
1177	// A semantic check is necessary to ensure a type qualifier is appropriate for the kind of
1178	// declaration.
1179	//
1180	// ISO/IEC 9899:1999 Section 6.7.3(4) : If the same qualifier appears more than once in the same
1181	// specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as
1182	// if it appeared only once.
1183	type_qualifier
1184	\| type_qualifier_list type_qualifier
1185	{ $$ = $1->addQualifiers( $2 ); }
1186	;
1187
1188	type_qualifier:
1189	type_qualifier_name
1190	\| attribute
1191	{ $$ = DeclarationNode::newQualifier( DeclarationNode::Attribute ); }
1192	;
1193
1194	type_qualifier_name:
1195	CONST
1196	{ $$ = DeclarationNode::newQualifier( DeclarationNode::Const ); }
1197	\| RESTRICT
1198	{ $$ = DeclarationNode::newQualifier( DeclarationNode::Restrict ); }
1199	\| VOLATILE
1200	{ $$ = DeclarationNode::newQualifier( DeclarationNode::Volatile ); }
1201	\| LVALUE // CFA
1202	{ $$ = DeclarationNode::newQualifier( DeclarationNode::Lvalue ); }
1203	\| ATOMIC
1204	{ $$ = DeclarationNode::newQualifier( DeclarationNode::Atomic ); }
1205	\| FORALL '('
1206	{
1207	typedefTable.enterScope();
1208	}
1209	type_parameter_list ')' // CFA
1210	{
1211	typedefTable.leaveScope();
1212	$$ = DeclarationNode::newForall( $4 );
1213	}
1214	;
1215
1216	declaration_qualifier_list:
1217	storage_class_list
1218	\| type_qualifier_list storage_class_list // remaining OBSOLESCENT (see 2)
1219	{ $$ = $1->addQualifiers( $2 ); }
1220	\| declaration_qualifier_list type_qualifier_list storage_class_list
1221	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1222	;
1223
1224	storage_class_list:
1225	// A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration
1226	// and that only one of each is specified, except for inline, which can appear with the others.
1227	//
1228	// ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the
1229	// declaration specifiers in a declaration.
1230	storage_class
1231	\| storage_class_list storage_class
1232	{ $$ = $1->addQualifiers( $2 ); }
1233	;
1234
1235	storage_class:
1236	storage_class_name
1237	;
1238
1239	storage_class_name:
1240	EXTERN
1241	{ $$ = DeclarationNode::newStorageClass( DeclarationNode::Extern ); }
1242	\| STATIC
1243	{ $$ = DeclarationNode::newStorageClass( DeclarationNode::Static ); }
1244	\| AUTO
1245	{ $$ = DeclarationNode::newStorageClass( DeclarationNode::Auto ); }
1246	\| REGISTER
1247	{ $$ = DeclarationNode::newStorageClass( DeclarationNode::Register ); }
1248	\| INLINE // C99
1249	{ $$ = DeclarationNode::newStorageClass( DeclarationNode::Inline ); }
1250	\| FORTRAN // C99
1251	{ $$ = DeclarationNode::newStorageClass( DeclarationNode::Fortran ); }
1252	\| NORETURN // C11
1253	{ $$ = DeclarationNode::newStorageClass( DeclarationNode::Noreturn ); }
1254	\| THREADLOCAL // C11
1255	{ $$ = DeclarationNode::newStorageClass( DeclarationNode::Threadlocal ); }
1256	;
1257
1258	basic_type_name:
1259	CHAR
1260	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1261	\| DOUBLE
1262	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1263	\| FLOAT
1264	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1265	\| INT
1266	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1267	\| LONG
1268	{ $$ = DeclarationNode::newModifier( DeclarationNode::Long ); }
1269	\| SHORT
1270	{ $$ = DeclarationNode::newModifier( DeclarationNode::Short ); }
1271	\| SIGNED
1272	{ $$ = DeclarationNode::newModifier( DeclarationNode::Signed ); }
1273	\| UNSIGNED
1274	{ $$ = DeclarationNode::newModifier( DeclarationNode::Unsigned ); }
1275	\| VOID
1276	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1277	\| BOOL // C99
1278	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1279	\| COMPLEX // C99
1280	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Complex ); }
1281	\| IMAGINARY // C99
1282	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Imaginary ); }
1283	;
1284
1285	basic_declaration_specifier:
1286	// A semantic check is necessary for conflicting storage classes.
1287	basic_type_specifier
1288	\| declaration_qualifier_list basic_type_specifier
1289	{ $$ = $2->addQualifiers( $1 ); }
1290	\| basic_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1291	{ $$ = $1->addQualifiers( $2 ); }
1292	\| basic_declaration_specifier storage_class type_qualifier_list
1293	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1294	\| basic_declaration_specifier storage_class basic_type_specifier
1295	{ $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1296	;
1297
1298	basic_type_specifier:
1299	direct_type_name
1300	\| type_qualifier_list_opt indirect_type_name type_qualifier_list_opt
1301	{ $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1302	;
1303
1304	direct_type_name:
1305	// A semantic check is necessary for conflicting type qualifiers.
1306	basic_type_name
1307	\| type_qualifier_list basic_type_name
1308	{ $$ = $2->addQualifiers( $1 ); }
1309	\| direct_type_name type_qualifier
1310	{ $$ = $1->addQualifiers( $2 ); }
1311	\| direct_type_name basic_type_name
1312	{ $$ = $1->addType( $2 ); }
1313	;
1314
1315	indirect_type_name:
1316	TYPEOF '(' type_name ')' // GCC: typeof(x) y;
1317	{ $$ = $3; }
1318	\| TYPEOF '(' comma_expression ')' // GCC: typeof(a+b) y;
1319	{ $$ = DeclarationNode::newTypeof( $3 ); }
1320	\| ATTR_TYPEGENname '(' type_name ')' // CFA: e.g., @type(x) y;
1321	{ $$ = DeclarationNode::newAttr( $1, $3 ); }
1322	\| ATTR_TYPEGENname '(' comma_expression ')' // CFA: e.g., @type(a+b) y;
1323	{ $$ = DeclarationNode::newAttr( $1, $3 ); }
1324	;
1325
1326	sue_declaration_specifier:
1327	sue_type_specifier
1328	\| declaration_qualifier_list sue_type_specifier
1329	{ $$ = $2->addQualifiers( $1 ); }
1330	\| sue_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1331	{ $$ = $1->addQualifiers( $2 ); }
1332	\| sue_declaration_specifier storage_class type_qualifier_list
1333	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1334	;
1335
1336	sue_type_specifier:
1337	elaborated_type_name // struct, union, enum
1338	\| type_qualifier_list elaborated_type_name
1339	{ $$ = $2->addQualifiers( $1 ); }
1340	\| sue_type_specifier type_qualifier
1341	{ $$ = $1->addQualifiers( $2 ); }
1342	;
1343
1344	typedef_declaration_specifier:
1345	typedef_type_specifier
1346	\| declaration_qualifier_list typedef_type_specifier
1347	{ $$ = $2->addQualifiers( $1 ); }
1348	\| typedef_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1349	{ $$ = $1->addQualifiers( $2 ); }
1350	\| typedef_declaration_specifier storage_class type_qualifier_list
1351	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1352	;
1353
1354	typedef_type_specifier: // typedef types
1355	TYPEDEFname
1356	{ $$ = DeclarationNode::newFromTypedef( $1 ); }
1357	\| type_qualifier_list TYPEDEFname
1358	{ $$ = DeclarationNode::newFromTypedef( $2 )->addQualifiers( $1 ); }
1359	\| typedef_type_specifier type_qualifier
1360	{ $$ = $1->addQualifiers( $2 ); }
1361	;
1362
1363	elaborated_type_name:
1364	aggregate_name
1365	\| enum_name
1366	;
1367
1368	aggregate_name:
1369	aggregate_key '{' field_declaration_list '}'
1370	{ $$ = DeclarationNode::newAggregate( $1, 0, 0, 0, $3 ); }
1371	\| aggregate_key no_attr_identifier_or_typedef_name
1372	{ $$ = DeclarationNode::newAggregate( $1, $2, 0, 0, 0 ); }
1373	\| aggregate_key no_attr_identifier_or_typedef_name '{' field_declaration_list '}'
1374	{ $$ = DeclarationNode::newAggregate( $1, $2, 0, 0, $4 ); }
1375	\| aggregate_key '(' push type_parameter_list pop ')' '{' field_declaration_list '}' // CFA
1376	{ $$ = DeclarationNode::newAggregate( $1, 0, $4, 0, $8 ); }
1377	\| aggregate_key '(' push type_parameter_list pop ')' no_attr_identifier_or_typedef_name // CFA
1378	{ $$ = DeclarationNode::newAggregate( $1, $7, $4, 0, 0 ); }
1379	\| aggregate_key '(' push type_parameter_list pop ')' no_attr_identifier_or_typedef_name '{' field_declaration_list '}' // CFA
1380	{ $$ = DeclarationNode::newAggregate( $1, $7, $4, 0, $9 ); }
1381	\| aggregate_key '(' push type_parameter_list pop ')' '(' type_name_list ')' '{' field_declaration_list '}' // CFA
1382	{ $$ = DeclarationNode::newAggregate( $1, 0, $4, $8, $11 ); }
1383	\| aggregate_key '(' push type_name_list pop ')' no_attr_identifier_or_typedef_name // CFA
1384	// push and pop are only to prevent S/R conflicts
1385	{ $$ = DeclarationNode::newAggregate( $1, $7, 0, $4, 0 ); }
1386	\| aggregate_key '(' push type_parameter_list pop ')' '(' type_name_list ')' no_attr_identifier_or_typedef_name '{' field_declaration_list '}' // CFA
1387	{ $$ = DeclarationNode::newAggregate( $1, $10, $4, $8, $12 ); }
1388	;
1389
1390	aggregate_key:
1391	STRUCT attribute_list_opt
1392	{ $$ = DeclarationNode::Struct; }
1393	\| UNION attribute_list_opt
1394	{ $$ = DeclarationNode::Union; }
1395	;
1396
1397	field_declaration_list:
1398	field_declaration
1399	{ $$ = $1; }
1400	\| field_declaration_list field_declaration
1401	{ $$ = $1->appendList( $2 ); }
1402	;
1403
1404	field_declaration:
1405	new_field_declaring_list ';' // CFA, new style field declaration
1406	\| EXTENSION new_field_declaring_list ';' // GCC
1407	{ $$ = $2; }
1408	\| field_declaring_list ';'
1409	\| EXTENSION field_declaring_list ';' // GCC
1410	{ $$ = $2; }
1411	;
1412
1413	new_field_declaring_list: // CFA, new style field declaration
1414	new_abstract_declarator_tuple // CFA, no field name
1415	\| new_abstract_declarator_tuple no_attr_identifier_or_typedef_name
1416	{ $$ = $1->addName( $2 ); }
1417	\| new_field_declaring_list ',' no_attr_identifier_or_typedef_name
1418	{ $$ = $1->appendList( $1->cloneType( $3 ) ); }
1419	\| new_field_declaring_list ',' // CFA, no field name
1420	{ $$ = $1->appendList( $1->cloneType( 0 ) ); }
1421	;
1422
1423	field_declaring_list:
1424	type_specifier field_declarator
1425	{ $$ = $2->addType( $1 ); }
1426	\| field_declaring_list ',' attribute_list_opt field_declarator
1427	{ $$ = $1->appendList( $1->cloneBaseType( $4 ) ); }
1428	;
1429
1430	field_declarator:
1431	// empty
1432	{ $$ = DeclarationNode::newName( 0 ); /* XXX */ } // CFA, no field name
1433	\| bit_subrange_size // no field name
1434	{ $$ = DeclarationNode::newBitfield( $1 ); }
1435	\| variable_declarator bit_subrange_size_opt
1436	// A semantic check is required to ensure bit_subrange only appears on base type int.
1437	{ $$ = $1->addBitfield( $2 ); }
1438	\| typedef_redeclarator bit_subrange_size_opt
1439	// A semantic check is required to ensure bit_subrange only appears on base type int.
1440	{ $$ = $1->addBitfield( $2 ); }
1441	\| variable_abstract_declarator // CFA, no field name
1442	;
1443
1444	bit_subrange_size_opt:
1445	// empty
1446	{ $$ = 0; }
1447	\| bit_subrange_size
1448	{ $$ = $1; }
1449	;
1450
1451	bit_subrange_size:
1452	':' constant_expression
1453	{ $$ = $2; }
1454	;
1455
1456	enum_key:
1457	ENUM attribute_list_opt
1458	;
1459
1460	enum_name:
1461	enum_key '{' enumerator_list comma_opt '}'
1462	{ $$ = DeclarationNode::newEnum( 0, $3 ); }
1463	\| enum_key no_attr_identifier_or_typedef_name '{' enumerator_list comma_opt '}'
1464	{ $$ = DeclarationNode::newEnum( $2, $4 ); }
1465	\| enum_key no_attr_identifier_or_typedef_name
1466	{ $$ = DeclarationNode::newEnum( $2, 0 ); }
1467	;
1468
1469	enumerator_list:
1470	no_attr_identifier_or_typedef_name enumerator_value_opt
1471	{ $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
1472	\| enumerator_list ',' no_attr_identifier_or_typedef_name enumerator_value_opt
1473	{ $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
1474	;
1475
1476	enumerator_value_opt:
1477	// empty
1478	{ $$ = 0; }
1479	\| '=' constant_expression
1480	{ $$ = $2; }
1481	;
1482
1483	// Minimum of one parameter after which ellipsis is allowed only at the end.
1484
1485	new_parameter_type_list_opt: // CFA
1486	// empty
1487	{ $$ = 0; }
1488	\| new_parameter_type_list
1489	;
1490
1491	new_parameter_type_list: // CFA, abstract + real
1492	new_abstract_parameter_list
1493	\| new_parameter_list
1494	\| new_parameter_list pop ',' push new_abstract_parameter_list
1495	{ $$ = $1->appendList( $5 ); }
1496	\| new_abstract_parameter_list pop ',' push ELLIPSIS
1497	{ $$ = $1->addVarArgs(); }
1498	\| new_parameter_list pop ',' push ELLIPSIS
1499	{ $$ = $1->addVarArgs(); }
1500	;
1501
1502	new_parameter_list: // CFA
1503	// To obtain LR(1) between new_parameter_list and new_abstract_tuple, the last
1504	// new_abstract_parameter_list is factored out from new_parameter_list, flattening the rules to get
1505	// lookahead to the ']'.
1506	new_parameter_declaration
1507	\| new_abstract_parameter_list pop ',' push new_parameter_declaration
1508	{ $$ = $1->appendList( $5 ); }
1509	\| new_parameter_list pop ',' push new_parameter_declaration
1510	{ $$ = $1->appendList( $5 ); }
1511	\| new_parameter_list pop ',' push new_abstract_parameter_list pop ',' push new_parameter_declaration
1512	{ $$ = $1->appendList( $5 )->appendList( $9 ); }
1513	;
1514
1515	new_abstract_parameter_list: // CFA, new & old style abstract
1516	new_abstract_parameter_declaration
1517	\| new_abstract_parameter_list pop ',' push new_abstract_parameter_declaration
1518	{ $$ = $1->appendList( $5 ); }
1519	;
1520
1521	parameter_type_list_opt:
1522	// empty
1523	{ $$ = 0; }
1524	\| parameter_type_list
1525	;
1526
1527	parameter_type_list:
1528	parameter_list
1529	\| parameter_list pop ',' push ELLIPSIS
1530	{ $$ = $1->addVarArgs(); }
1531	;
1532
1533	parameter_list: // abstract + real
1534	abstract_parameter_declaration
1535	\| parameter_declaration
1536	\| parameter_list pop ',' push abstract_parameter_declaration
1537	{ $$ = $1->appendList( $5 ); }
1538	\| parameter_list pop ',' push parameter_declaration
1539	{ $$ = $1->appendList( $5 ); }
1540	;
1541
1542	// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different
1543	// semantics for typedef name by using typedef_parameter_redeclarator instead of typedef_redeclarator, and
1544	// function prototypes.
1545
1546	new_parameter_declaration: // CFA, new & old style parameter declaration
1547	parameter_declaration
1548	\| new_identifier_parameter_declarator_no_tuple identifier_or_typedef_name assignment_opt
1549	{ $$ = $1->addName( $2 ); }
1550	\| new_abstract_tuple identifier_or_typedef_name assignment_opt
1551	// To obtain LR(1), these rules must be duplicated here (see new_abstract_declarator).
1552	{ $$ = $1->addName( $2 ); }
1553	\| type_qualifier_list new_abstract_tuple identifier_or_typedef_name assignment_opt
1554	{ $$ = $2->addName( $3 )->addQualifiers( $1 ); }
1555	\| new_function_specifier
1556	;
1557
1558	new_abstract_parameter_declaration: // CFA, new & old style parameter declaration
1559	abstract_parameter_declaration
1560	\| new_identifier_parameter_declarator_no_tuple
1561	\| new_abstract_tuple
1562	// To obtain LR(1), these rules must be duplicated here (see new_abstract_declarator).
1563	\| type_qualifier_list new_abstract_tuple
1564	{ $$ = $2->addQualifiers( $1 ); }
1565	\| new_abstract_function
1566	;
1567
1568	parameter_declaration:
1569	declaration_specifier identifier_parameter_declarator assignment_opt
1570	{
1571	typedefTable.addToEnclosingScope( TypedefTable::ID );
1572	$$ = $2->addType( $1 )->addInitializer( new InitializerNode($3) );
1573	}
1574	\| declaration_specifier typedef_parameter_redeclarator assignment_opt
1575	{
1576	typedefTable.addToEnclosingScope( TypedefTable::ID );
1577	$$ = $2->addType( $1 )->addInitializer( new InitializerNode($3) );
1578	}
1579	;
1580
1581	abstract_parameter_declaration:
1582	declaration_specifier
1583	\| declaration_specifier abstract_parameter_declarator
1584	{ $$ = $2->addType( $1 ); }
1585	;
1586
1587	// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
1588	// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is
1589	// based only on identifiers. The ANSI-style parameter-list can redefine a typedef name.
1590
1591	identifier_list: // K&R-style parameter list => no types
1592	no_attr_identifier
1593	{ $$ = DeclarationNode::newName( $1 ); }
1594	\| identifier_list ',' no_attr_identifier
1595	{ $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
1596	;
1597
1598	identifier_or_typedef_name:
1599	identifier
1600	\| TYPEDEFname
1601	\| TYPEGENname
1602	;
1603
1604	no_01_identifier_or_typedef_name:
1605	no_01_identifier
1606	\| TYPEDEFname
1607	\| TYPEGENname
1608	;
1609
1610	no_attr_identifier_or_typedef_name:
1611	no_attr_identifier
1612	\| TYPEDEFname
1613	\| TYPEGENname
1614	;
1615
1616	type_name_no_function: // sizeof, alignof, cast (constructor)
1617	new_abstract_declarator_tuple // CFA
1618	\| type_specifier
1619	\| type_specifier variable_abstract_declarator
1620	{ $$ = $2->addType( $1 ); }
1621	;
1622
1623	type_name: // typeof, assertion
1624	new_abstract_declarator_tuple // CFA
1625	\| new_abstract_function // CFA
1626	\| type_specifier
1627	\| type_specifier abstract_declarator
1628	{ $$ = $2->addType( $1 ); }
1629	;
1630
1631	initializer_opt:
1632	// empty
1633	{ $$ = 0; }
1634	\| '=' initializer { $$ = $2; }
1635	;
1636
1637	initializer:
1638	assignment_expression { $$ = new InitializerNode($1); }
1639	\| '{' initializer_list comma_opt '}' { $$ = new InitializerNode($2, true); }
1640	;
1641
1642	initializer_list:
1643	initializer
1644	\| designation initializer { $$ = $2->set_designators( $1 ); }
1645	\| initializer_list ',' initializer { $$ = (InitializerNode *)( $1->set_link($3) ); }
1646	\| initializer_list ',' designation initializer
1647	{ $$ = (InitializerNode *)( $1->set_link( $4->set_designators($3) ) ); }
1648	;
1649
1650	// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is
1651	// use of '=' to separator the designator from the initializer value, as in:
1652	//
1653	// int x[10] = { [1] = 3 };
1654	//
1655	// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment. To disambiguate this
1656	// case, CFA changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC
1657	// does uses ":" for field selection. The optional use of the "=" in GCC, or in this case ":", cannot be
1658	// supported either due to shift/reduce conflicts
1659
1660	designation:
1661	designator_list ':' // C99, CFA uses ":" instead of "="
1662	\| no_attr_identifier_or_typedef_name ':' // GCC, field name
1663	{ $$ = new VarRefNode( $1 ); }
1664	;
1665
1666	designator_list: // C99
1667	designator
1668	\| designator_list designator { $$ = (ExpressionNode *)($1->set_link( $2 )); }
1669	;
1670
1671	designator:
1672	'.' no_attr_identifier_or_typedef_name // C99, field name
1673	{ $$ = new VarRefNode( $2 ); }
1674	\| '[' push assignment_expression pop ']' // C99, single array element
1675	// assignment_expression used instead of constant_expression because of shift/reduce conflicts with
1676	// tuple.
1677	{ $$ = $3; }
1678	\| '[' push subrange pop ']' // CFA, multiple array elements
1679	{ $$ = $3; }
1680	\| '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
1681	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Range), $3, $5); }
1682	\| '.' '[' push field_list pop ']' // CFA, tuple field selector
1683	{ $$ = $4; }
1684	;
1685
1686	// The CFA type system is based on parametric polymorphism, the ability to declare functions with type
1687	// parameters, rather than an object-oriented type system. This required four groups of extensions:
1688	//
1689	// Overloading: function, data, and operator identifiers may be overloaded.
1690	//
1691	// Type declarations: "type" is used to generate new types for declaring objects. Similarly, "dtype" is used
1692	// for object and incomplete types, and "ftype" is used for function types. Type declarations with
1693	// initializers provide definitions of new types. Type declarations with storage class "extern" provide
1694	// opaque types.
1695	//
1696	// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at
1697	// the call site. A polymorphic function is not a template; it is a function, with an address and a type.
1698	//
1699	// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
1700	// types. They serve many of the purposes of abstract classes, and specification hierarchies resemble
1701	// subclass hierarchies. Unlike classes, they can define relationships between types. Assertions declare
1702	// that a type or types provide the operations declared by a specification. Assertions are normally used
1703	// to declare requirements on type arguments of polymorphic functions.
1704
1705	typegen_declaration_specifier: // CFA
1706	typegen_type_specifier
1707	\| declaration_qualifier_list typegen_type_specifier
1708	{ $$ = $2->addQualifiers( $1 ); }
1709	\| typegen_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1710	{ $$ = $1->addQualifiers( $2 ); }
1711	\| typegen_declaration_specifier storage_class type_qualifier_list
1712	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1713	;
1714
1715	typegen_type_specifier: // CFA
1716	TYPEGENname '(' type_name_list ')'
1717	{ $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
1718	\| type_qualifier_list TYPEGENname '(' type_name_list ')'
1719	{ $$ = DeclarationNode::newFromTypeGen( $2, $4 )->addQualifiers( $1 ); }
1720	\| typegen_type_specifier type_qualifier
1721	{ $$ = $1->addQualifiers( $2 ); }
1722	;
1723
1724	type_parameter_list: // CFA
1725	type_parameter assignment_opt
1726	\| type_parameter_list ',' type_parameter assignment_opt
1727	{ $$ = $1->appendList( $3 ); }
1728	;
1729
1730	type_parameter: // CFA
1731	type_class no_attr_identifier_or_typedef_name
1732	{ typedefTable.addToEnclosingScope(*($2), TypedefTable::TD); }
1733	assertion_list_opt
1734	{ $$ = DeclarationNode::newTypeParam( $1, $2 )->addAssertions( $4 ); }
1735	\| type_specifier identifier_parameter_declarator
1736	;
1737
1738	type_class: // CFA
1739	TYPE
1740	{ $$ = DeclarationNode::Type; }
1741	\| DTYPE
1742	{ $$ = DeclarationNode::Ftype; }
1743	\| FTYPE
1744	{ $$ = DeclarationNode::Dtype; }
1745	;
1746
1747	assertion_list_opt: // CFA
1748	// empty
1749	{ $$ = 0; }
1750	\| assertion_list_opt assertion
1751	{ $$ = $1 == 0 ? $2 : $1->appendList( $2 ); }
1752	;
1753
1754	assertion: // CFA
1755	'\|' no_attr_identifier_or_typedef_name '(' type_name_list ')'
1756	{
1757	typedefTable.openContext( *($2) );
1758	$$ = DeclarationNode::newContextUse( $2, $4 );
1759	}
1760	\| '\|' '{' push context_declaration_list '}'
1761	{ $$ = $4; }
1762	\| '\|' '(' push type_parameter_list pop ')' '{' push context_declaration_list '}' '(' type_name_list ')'
1763	{ $$ = 0; }
1764	;
1765
1766	type_name_list: // CFA
1767	type_name
1768	{ $$ = new TypeValueNode( $1 ); }
1769	\| assignment_expression
1770	\| type_name_list ',' type_name
1771	{ $$ = (ExpressionNode *)($1->set_link(new TypeValueNode( $3 ))); }
1772	\| type_name_list ',' assignment_expression
1773	{ $$ = (ExpressionNode *)($1->set_link($3)); }
1774	;
1775
1776	type_declaring_list: // CFA
1777	TYPE type_declarator
1778	{ $$ = $2; }
1779	\| storage_class_list TYPE type_declarator
1780	{ $$ = $3->addQualifiers( $1 ); }
1781	\| type_declaring_list ',' type_declarator
1782	{ $$ = $1->appendList( $3->copyStorageClasses( $1 ) ); }
1783	;
1784
1785	type_declarator: // CFA
1786	type_declarator_name assertion_list_opt
1787	{ $$ = $1->addAssertions( $2 ); }
1788	\| type_declarator_name assertion_list_opt '=' type_name
1789	{ $$ = $1->addAssertions( $2 )->addType( $4 ); }
1790	;
1791
1792	type_declarator_name: // CFA
1793	no_attr_identifier_or_typedef_name
1794	{
1795	typedefTable.addToEnclosingScope(*($1), TypedefTable::TD);
1796	$$ = DeclarationNode::newTypeDecl( $1, 0 );
1797	}
1798	\| no_01_identifier_or_typedef_name '(' push type_parameter_list pop ')'
1799	{
1800	typedefTable.addToEnclosingScope(*($1), TypedefTable::TG);
1801	$$ = DeclarationNode::newTypeDecl( $1, $4 );
1802	}
1803	;
1804
1805	context_specifier: // CFA
1806	CONTEXT no_attr_identifier_or_typedef_name '(' push type_parameter_list pop ')' '{' '}'
1807	{
1808	typedefTable.addToEnclosingScope(*($2), TypedefTable::ID );
1809	$$ = DeclarationNode::newContext( $2, $5, 0 );
1810	}
1811	\| CONTEXT no_attr_identifier_or_typedef_name '(' push type_parameter_list pop ')' '{'
1812	{
1813	typedefTable.enterContext( *($2) );
1814	typedefTable.enterScope();
1815	}
1816	context_declaration_list '}'
1817	{
1818	typedefTable.leaveContext();
1819	typedefTable.addToEnclosingScope(*($2), TypedefTable::ID );
1820	$$ = DeclarationNode::newContext( $2, $5, $10 );
1821	}
1822	;
1823
1824	context_declaration_list: // CFA
1825	context_declaration
1826	\| context_declaration_list push context_declaration
1827	{ $$ = $1->appendList( $3 ); }
1828	;
1829
1830	context_declaration: // CFA
1831	new_context_declaring_list pop ';'
1832	\| context_declaring_list pop ';'
1833	;
1834
1835	new_context_declaring_list: // CFA
1836	new_variable_specifier
1837	{
1838	typedefTable.addToEnclosingScope2( TypedefTable::ID );
1839	$$ = $1;
1840	}
1841	\| new_function_specifier
1842	{
1843	typedefTable.addToEnclosingScope2( TypedefTable::ID );
1844	$$ = $1;
1845	}
1846	\| new_context_declaring_list pop ',' push identifier_or_typedef_name
1847	{
1848	typedefTable.addToEnclosingScope2( *($5), TypedefTable::ID );
1849	$$ = $1->appendList( $1->cloneType( $5 ) );
1850	}
1851	;
1852
1853	context_declaring_list: // CFA
1854	type_specifier declarator
1855	{
1856	typedefTable.addToEnclosingScope2( TypedefTable::ID );
1857	$$ = $2->addType( $1 );
1858	}
1859	\| context_declaring_list pop ',' push declarator
1860	{
1861	typedefTable.addToEnclosingScope2( TypedefTable::ID );
1862	$$ = $1->appendList( $1->cloneBaseType( $5 ) );
1863	}
1864	;
1865
1866	//*************************** EXTERNAL DEFINITIONS ***************************
1867
1868	translation_unit:
1869	// empty
1870	{} // empty input file
1871	\| external_definition_list
1872	{
1873	if ( theTree ) {
1874	theTree->appendList( $1 );
1875	} else {
1876	theTree = $1;
1877	}
1878	}
1879	;
1880
1881	external_definition_list:
1882	external_definition
1883	\| external_definition_list push external_definition
1884	{ $$ = ($1 != NULL ) ? $1->appendList( $3 ) : $3; }
1885	;
1886
1887	external_definition_list_opt:
1888	// empty
1889	{ $$ = 0; }
1890	\| external_definition_list
1891	;
1892
1893	external_definition:
1894	declaration
1895	\| external_function_definition
1896	\| asm_statement // GCC, global assembler statement
1897	{}
1898	\| EXTERN STRINGliteral
1899	{
1900	linkageStack.push( linkage );
1901	linkage = LinkageSpec::fromString( *$2 );
1902	}
1903	'{' external_definition_list_opt '}' // C++-style linkage specifier
1904	{
1905	linkage = linkageStack.top();
1906	linkageStack.pop();
1907	$$ = $5;
1908	}
1909	\| EXTENSION external_definition
1910	{ $$ = $2; }
1911	;
1912
1913	external_function_definition:
1914	function_definition
1915
1916	// These rules are a concession to the "implicit int" type_specifier because there is a significant
1917	// amount of code with functions missing a type-specifier on the return type. Parsing is possible
1918	// because function_definition does not appear in the context of an expression (nested functions would
1919	// preclude this concession). A function prototype declaration must still have a type_specifier.
1920	// OBSOLESCENT (see 1)
1921	\| function_declarator compound_statement
1922	{
1923	typedefTable.addToEnclosingScope( TypedefTable::ID );
1924	typedefTable.leaveScope();
1925	$$ = $1->addFunctionBody( $2 );
1926	}
1927	\| old_function_declarator push old_declaration_list_opt compound_statement
1928	{
1929	typedefTable.addToEnclosingScope( TypedefTable::ID );
1930	typedefTable.leaveScope();
1931	$$ = $1->addOldDeclList( $3 )->addFunctionBody( $4 );
1932	}
1933	;
1934
1935	function_definition:
1936	new_function_declaration compound_statement // CFA
1937	{
1938	typedefTable.addToEnclosingScope( TypedefTable::ID );
1939	typedefTable.leaveScope();
1940	$$ = $1->addFunctionBody( $2 );
1941	}
1942	\| declaration_specifier function_declarator compound_statement
1943	{
1944	typedefTable.addToEnclosingScope( TypedefTable::ID );
1945	typedefTable.leaveScope();
1946	$$ = $2->addFunctionBody( $3 )->addType( $1 );
1947	}
1948	\| type_qualifier_list function_declarator compound_statement
1949	{
1950	typedefTable.addToEnclosingScope( TypedefTable::ID );
1951	typedefTable.leaveScope();
1952	$$ = $2->addFunctionBody( $3 )->addQualifiers( $1 );
1953	}
1954	\| declaration_qualifier_list function_declarator compound_statement
1955	{
1956	typedefTable.addToEnclosingScope( TypedefTable::ID );
1957	typedefTable.leaveScope();
1958	$$ = $2->addFunctionBody( $3 )->addQualifiers( $1 );
1959	}
1960	\| declaration_qualifier_list type_qualifier_list function_declarator compound_statement
1961	{
1962	typedefTable.addToEnclosingScope( TypedefTable::ID );
1963	typedefTable.leaveScope();
1964	$$ = $3->addFunctionBody( $4 )->addQualifiers( $2 )->addQualifiers( $1 );
1965	}
1966
1967	// Old-style K&R function definition, OBSOLESCENT (see 4)
1968	\| declaration_specifier old_function_declarator push old_declaration_list_opt compound_statement
1969	{
1970	typedefTable.addToEnclosingScope( TypedefTable::ID );
1971	typedefTable.leaveScope();
1972	$$ = $2->addOldDeclList( $4 )->addFunctionBody( $5 )->addType( $1 );
1973	}
1974	\| type_qualifier_list old_function_declarator push old_declaration_list_opt compound_statement
1975	{
1976	typedefTable.addToEnclosingScope( TypedefTable::ID );
1977	typedefTable.leaveScope();
1978	$$ = $2->addOldDeclList( $4 )->addFunctionBody( $5 )->addQualifiers( $1 );
1979	}
1980
1981	// Old-style K&R function definition with "implicit int" type_specifier, OBSOLESCENT (see 4)
1982	\| declaration_qualifier_list old_function_declarator push old_declaration_list_opt compound_statement
1983	{
1984	typedefTable.addToEnclosingScope( TypedefTable::ID );
1985	typedefTable.leaveScope();
1986	$$ = $2->addOldDeclList( $4 )->addFunctionBody( $5 )->addQualifiers( $1 );
1987	}
1988	\| declaration_qualifier_list type_qualifier_list old_function_declarator push old_declaration_list_opt compound_statement
1989	{
1990	typedefTable.addToEnclosingScope( TypedefTable::ID );
1991	typedefTable.leaveScope();
1992	$$ = $3->addOldDeclList( $5 )->addFunctionBody( $6 )->addQualifiers( $2 )->addQualifiers( $1 );
1993	}
1994	;
1995
1996	declarator:
1997	variable_declarator
1998	\| function_declarator
1999	\| typedef_redeclarator
2000	;
2001
2002	subrange:
2003	constant_expression '~' constant_expression // CFA, integer subrange
2004	{ $$ = new CompositeExprNode(new OperatorNode(OperatorNode::Range), $1, $3); }
2005	;
2006
2007	asm_name_opt: // GCC
2008	// empty
2009	\| ASM '(' string_literal_list ')' attribute_list_opt
2010	;
2011
2012	attribute_list_opt: // GCC
2013	// empty
2014	\| attribute_list
2015	;
2016
2017	attribute_list: // GCC
2018	attribute
2019	\| attribute_list attribute
2020	;
2021
2022	attribute: // GCC
2023	ATTRIBUTE '(' '(' attribute_parameter_list ')' ')'
2024	;
2025
2026	attribute_parameter_list: // GCC
2027	attrib
2028	\| attribute_parameter_list ',' attrib
2029	;
2030
2031	attrib: // GCC
2032	// empty
2033	\| any_word
2034	\| any_word '(' comma_expression_opt ')'
2035	;
2036
2037	any_word: // GCC
2038	identifier_or_typedef_name {}
2039	\| storage_class_name {}
2040	\| basic_type_name {}
2041	\| type_qualifier {}
2042	;
2043
2044	// ============================================================================
2045	// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are
2046	// necessary because the type of an identifier in wrapped around the identifier in the same form as its usage
2047	// in an expression, as in:
2048	//
2049	// int (*f())[10] { ... };
2050	// ... (*f())[3] += 1; // definition mimics usage
2051	//
2052	// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some
2053	// or all of the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a
2054	// particular context.
2055	// ============================================================================
2056
2057	// ----------------------------------------------------------------------------
2058	// The set of valid declarators before a compound statement for defining a function is less than the set of
2059	// declarators to define a variable or function prototype, e.g.:
2060	//
2061	// valid declaration invalid definition
2062	// ----------------- ------------------
2063	// int f; int f {}
2064	// int f; int f {}
2065	// int f[10]; int f[10] {}
2066	// int (f)(int); int (f)(int) {}
2067	//
2068	// To preclude this syntactic anomaly requires separating the grammar rules for variable and function
2069	// declarators, hence variable_declarator and function_declarator.
2070	// ----------------------------------------------------------------------------
2071
2072	// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern
2073	// precludes declaring an array of functions versus a pointer to an array of functions.
2074
2075	variable_declarator:
2076	paren_identifier attribute_list_opt
2077	\| variable_ptr
2078	\| variable_array attribute_list_opt
2079	\| variable_function attribute_list_opt
2080	;
2081
2082	paren_identifier:
2083	identifier
2084	{
2085	typedefTable.setNextIdentifier( *($1) );
2086	$$ = DeclarationNode::newName( $1 );
2087	}
2088	\| '(' paren_identifier ')' // redundant parenthesis
2089	{ $$ = $2; }
2090	;
2091
2092	variable_ptr:
2093	'*' variable_declarator
2094	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2095	\| '*' type_qualifier_list variable_declarator
2096	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2097	\| '(' variable_ptr ')'
2098	{ $$ = $2; }
2099	;
2100
2101	variable_array:
2102	paren_identifier array_dimension
2103	{ $$ = $1->addArray( $2 ); }
2104	\| '(' variable_ptr ')' array_dimension
2105	{ $$ = $2->addArray( $4 ); }
2106	\| '(' variable_array ')' multi_array_dimension // redundant parenthesis
2107	{ $$ = $2->addArray( $4 ); }
2108	\| '(' variable_array ')' // redundant parenthesis
2109	{ $$ = $2; }
2110	;
2111
2112	variable_function:
2113	'(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2114	{ $$ = $2->addParamList( $6 ); }
2115	\| '(' variable_function ')' // redundant parenthesis
2116	{ $$ = $2; }
2117	;
2118
2119	// This pattern parses a function declarator that is not redefining a typedef name. Because functions cannot
2120	// be nested, there is no context where a function definition can redefine a typedef name. To allow nested
2121	// functions requires further separation of variable and function declarators in typedef_redeclarator. The
2122	// pattern precludes returning arrays and functions versus pointers to arrays and functions.
2123
2124	function_declarator:
2125	function_no_ptr attribute_list_opt
2126	\| function_ptr
2127	\| function_array attribute_list_opt
2128	;
2129
2130	function_no_ptr:
2131	paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2132	{ $$ = $1->addParamList( $4 ); }
2133	\| '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2134	{ $$ = $2->addParamList( $6 ); }
2135	\| '(' function_no_ptr ')' // redundant parenthesis
2136	{ $$ = $2; }
2137	;
2138
2139	function_ptr:
2140	'*' function_declarator
2141	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2142	\| '*' type_qualifier_list function_declarator
2143	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2144	\| '(' function_ptr ')'
2145	{ $$ = $2; }
2146	;
2147
2148	function_array:
2149	'(' function_ptr ')' array_dimension
2150	{ $$ = $2->addArray( $4 ); }
2151	\| '(' function_array ')' multi_array_dimension // redundant parenthesis
2152	{ $$ = $2->addArray( $4 ); }
2153	\| '(' function_array ')' // redundant parenthesis
2154	{ $$ = $2; }
2155	;
2156
2157	// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4) that is not redefining a
2158	// typedef name (see function_declarator for additional comments). The pattern precludes returning arrays and
2159	// functions versus pointers to arrays and functions.
2160
2161	old_function_declarator:
2162	old_function_no_ptr
2163	\| old_function_ptr
2164	\| old_function_array
2165	;
2166
2167	old_function_no_ptr:
2168	paren_identifier '(' identifier_list ')' // function_declarator handles empty parameter
2169	{ $$ = $1->addIdList( $3 ); }
2170	\| '(' old_function_ptr ')' '(' identifier_list ')'
2171	{ $$ = $2->addIdList( $5 ); }
2172	\| '(' old_function_no_ptr ')' // redundant parenthesis
2173	{ $$ = $2; }
2174	;
2175
2176	old_function_ptr:
2177	'*' old_function_declarator
2178	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2179	\| '*' type_qualifier_list old_function_declarator
2180	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2181	\| '(' old_function_ptr ')'
2182	{ $$ = $2; }
2183	;
2184
2185	old_function_array:
2186	'(' old_function_ptr ')' array_dimension
2187	{ $$ = $2->addArray( $4 ); }
2188	\| '(' old_function_array ')' multi_array_dimension // redundant parenthesis
2189	{ $$ = $2->addArray( $4 ); }
2190	\| '(' old_function_array ')' // redundant parenthesis
2191	{ $$ = $2; }
2192	;
2193
2194	// This pattern parses a declaration for a variable or function prototype that redefines a typedef name, e.g.:
2195	//
2196	// typedef int foo;
2197	// {
2198	// int foo; // redefine typedef name in new scope
2199	// }
2200	//
2201	// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and
2202	// returning arrays and functions versus pointers to arrays and functions.
2203
2204	typedef_redeclarator:
2205	paren_typedef attribute_list_opt
2206	\| typedef_ptr
2207	\| typedef_array attribute_list_opt
2208	\| typedef_function attribute_list_opt
2209	;
2210
2211	paren_typedef:
2212	TYPEDEFname
2213	{
2214	typedefTable.setNextIdentifier( *($1) );
2215	$$ = DeclarationNode::newName( $1 );
2216	}
2217	\| '(' paren_typedef ')'
2218	{ $$ = $2; }
2219	;
2220
2221	typedef_ptr:
2222	'*' typedef_redeclarator
2223	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2224	\| '*' type_qualifier_list typedef_redeclarator
2225	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2226	\| '(' typedef_ptr ')'
2227	{ $$ = $2; }
2228	;
2229
2230	typedef_array:
2231	paren_typedef array_dimension
2232	{ $$ = $1->addArray( $2 ); }
2233	\| '(' typedef_ptr ')' array_dimension
2234	{ $$ = $2->addArray( $4 ); }
2235	\| '(' typedef_array ')' multi_array_dimension // redundant parenthesis
2236	{ $$ = $2->addArray( $4 ); }
2237	\| '(' typedef_array ')' // redundant parenthesis
2238	{ $$ = $2; }
2239	;
2240
2241	typedef_function:
2242	paren_typedef '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2243	{ $$ = $1->addParamList( $4 ); }
2244	\| '(' typedef_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2245	{ $$ = $2->addParamList( $6 ); }
2246	\| '(' typedef_function ')' // redundant parenthesis
2247	{ $$ = $2; }
2248	;
2249
2250	// This pattern parses a declaration for a parameter variable or function prototype that is not redefining a
2251	// typedef name and allows the C99 array options, which can only appear in a parameter list. The pattern
2252	// precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2253	// and functions versus pointers to arrays and functions.
2254
2255	identifier_parameter_declarator:
2256	paren_identifier attribute_list_opt
2257	\| identifier_parameter_ptr
2258	\| identifier_parameter_array attribute_list_opt
2259	\| identifier_parameter_function attribute_list_opt
2260	;
2261
2262	identifier_parameter_ptr:
2263	'*' identifier_parameter_declarator
2264	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2265	\| '*' type_qualifier_list identifier_parameter_declarator
2266	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2267	\| '(' identifier_parameter_ptr ')'
2268	{ $$ = $2; }
2269	;
2270
2271	identifier_parameter_array:
2272	paren_identifier array_parameter_dimension
2273	{ $$ = $1->addArray( $2 ); }
2274	\| '(' identifier_parameter_ptr ')' array_dimension
2275	{ $$ = $2->addArray( $4 ); }
2276	\| '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
2277	{ $$ = $2->addArray( $4 ); }
2278	\| '(' identifier_parameter_array ')' // redundant parenthesis
2279	{ $$ = $2; }
2280	;
2281
2282	identifier_parameter_function:
2283	paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2284	{ $$ = $1->addParamList( $4 ); }
2285	\| '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2286	{ $$ = $2->addParamList( $6 ); }
2287	\| '(' identifier_parameter_function ')' // redundant parenthesis
2288	{ $$ = $2; }
2289	;
2290
2291	// This pattern parses a declaration for a parameter variable or function prototype that is redefining a
2292	// typedef name, e.g.:
2293	//
2294	// typedef int foo;
2295	// int f( int foo ); // redefine typedef name in new scope
2296	//
2297	// and allows the C99 array options, which can only appear in a parameter list. In addition, the pattern
2298	// handles the special meaning of parenthesis around a typedef name:
2299	//
2300	// ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
2301	// parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
2302	// not as redundant parentheses around the identifier."
2303	//
2304	// which precludes the following cases:
2305	//
2306	// typedef float T;
2307	// int f( int ( T [5] ) ); // see abstract_parameter_declarator
2308	// int g( int ( T ( int ) ) ); // see abstract_parameter_declarator
2309	// int f( int f1( T a[5] ) ); // see identifier_parameter_declarator
2310	// int g( int g1( T g2( int p ) ) ); // see identifier_parameter_declarator
2311	//
2312	// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type
2313	// list, and not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes
2314	// declaring an array of functions versus a pointer to an array of functions, and returning arrays and
2315	// functions versus pointers to arrays and functions.
2316
2317	typedef_parameter_redeclarator:
2318	typedef attribute_list_opt
2319	\| typedef_parameter_ptr
2320	\| typedef_parameter_array attribute_list_opt
2321	\| typedef_parameter_function attribute_list_opt
2322	;
2323
2324	typedef:
2325	TYPEDEFname
2326	{
2327	typedefTable.setNextIdentifier( *($1) );
2328	$$ = DeclarationNode::newName( $1 );
2329	}
2330	;
2331
2332	typedef_parameter_ptr:
2333	'*' typedef_parameter_redeclarator
2334	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2335	\| '*' type_qualifier_list typedef_parameter_redeclarator
2336	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2337	\| '(' typedef_parameter_ptr ')'
2338	{ $$ = $2; }
2339	;
2340
2341	typedef_parameter_array:
2342	typedef array_parameter_dimension
2343	{ $$ = $1->addArray( $2 ); }
2344	\| '(' typedef_parameter_ptr ')' array_parameter_dimension
2345	{ $$ = $2->addArray( $4 ); }
2346	;
2347
2348	typedef_parameter_function:
2349	typedef '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2350	{ $$ = $1->addParamList( $4 ); }
2351	\| '(' typedef_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2352	{ $$ = $2->addParamList( $6 ); }
2353	;
2354
2355	// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no
2356	// identifier to which the type applies, e.g.:
2357	//
2358	// sizeof( int );
2359	// sizeof( int [10] );
2360	//
2361	// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and
2362	// returning arrays and functions versus pointers to arrays and functions.
2363
2364	abstract_declarator:
2365	abstract_ptr
2366	\| abstract_array attribute_list_opt
2367	\| abstract_function attribute_list_opt
2368	;
2369
2370	abstract_ptr:
2371	'*'
2372	{ $$ = DeclarationNode::newPointer( 0 ); }
2373	\| '*' type_qualifier_list
2374	{ $$ = DeclarationNode::newPointer( $2 ); }
2375	\| '*' abstract_declarator
2376	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2377	\| '*' type_qualifier_list abstract_declarator
2378	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2379	\| '(' abstract_ptr ')'
2380	{ $$ = $2; }
2381	;
2382
2383	abstract_array:
2384	array_dimension
2385	\| '(' abstract_ptr ')' array_dimension
2386	{ $$ = $2->addArray( $4 ); }
2387	\| '(' abstract_array ')' multi_array_dimension // redundant parenthesis
2388	{ $$ = $2->addArray( $4 ); }
2389	\| '(' abstract_array ')' // redundant parenthesis
2390	{ $$ = $2; }
2391	;
2392
2393	abstract_function:
2394	'(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2395	{ $$ = DeclarationNode::newFunction( 0, 0, $3, 0 ); }
2396	\| '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2397	{ $$ = $2->addParamList( $6 ); }
2398	\| '(' abstract_function ')' // redundant parenthesis
2399	{ $$ = $2; }
2400	;
2401
2402	array_dimension:
2403	// Only the first dimension can be empty.
2404	'[' push pop ']'
2405	{ $$ = DeclarationNode::newArray( 0, 0, false ); }
2406	\| '[' push pop ']' multi_array_dimension
2407	{ $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $5 ); }
2408	\| multi_array_dimension
2409	;
2410
2411	multi_array_dimension:
2412	'[' push assignment_expression pop ']'
2413	{ $$ = DeclarationNode::newArray( $3, 0, false ); }
2414	\| '[' push '*' pop ']' // C99
2415	{ $$ = DeclarationNode::newVarArray( 0 ); }
2416	\| multi_array_dimension '[' push assignment_expression pop ']'
2417	{ $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
2418	\| multi_array_dimension '[' push '*' pop ']' // C99
2419	{ $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
2420	;
2421
2422	// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
2423	// identifier to which the type applies, e.g.:
2424	//
2425	// int f( int ); // abstract variable parameter; no parameter name specified
2426	// int f( int (int) ); // abstract function-prototype parameter; no parameter name specified
2427	//
2428	// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and
2429	// returning arrays and functions versus pointers to arrays and functions.
2430
2431	abstract_parameter_declarator:
2432	abstract_parameter_ptr
2433	\| abstract_parameter_array attribute_list_opt
2434	\| abstract_parameter_function attribute_list_opt
2435	;
2436
2437	abstract_parameter_ptr:
2438	'*'
2439	{ $$ = DeclarationNode::newPointer( 0 ); }
2440	\| '*' type_qualifier_list
2441	{ $$ = DeclarationNode::newPointer( $2 ); }
2442	\| '*' abstract_parameter_declarator
2443	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2444	\| '*' type_qualifier_list abstract_parameter_declarator
2445	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2446	\| '(' abstract_parameter_ptr ')'
2447	{ $$ = $2; }
2448	;
2449
2450	abstract_parameter_array:
2451	array_parameter_dimension
2452	\| '(' abstract_parameter_ptr ')' array_parameter_dimension
2453	{ $$ = $2->addArray( $4 ); }
2454	\| '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
2455	{ $$ = $2->addArray( $4 ); }
2456	\| '(' abstract_parameter_array ')' // redundant parenthesis
2457	{ $$ = $2; }
2458	;
2459
2460	abstract_parameter_function:
2461	'(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2462	{ $$ = DeclarationNode::newFunction( 0, 0, $3, 0 ); }
2463	\| '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2464	{ $$ = $2->addParamList( $6 ); }
2465	\| '(' abstract_parameter_function ')' // redundant parenthesis
2466	{ $$ = $2; }
2467	;
2468
2469	array_parameter_dimension:
2470	// Only the first dimension can be empty or have qualifiers.
2471	array_parameter_1st_dimension
2472	\| array_parameter_1st_dimension multi_array_dimension
2473	{ $$ = $1->addArray( $2 ); }
2474	\| multi_array_dimension
2475	;
2476
2477	// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
2478	//
2479	// ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall
2480	// appear only in a declaration of a function parameter with an array type, and then only in the
2481	// outermost array type derivation."
2482
2483	array_parameter_1st_dimension:
2484	'[' push pop ']'
2485	{ $$ = DeclarationNode::newArray( 0, 0, false ); }
2486	// multi_array_dimension handles the '[' '*' ']' case
2487	\| '[' push type_qualifier_list '*' pop ']' // remaining C99
2488	{ $$ = DeclarationNode::newVarArray( $3 ); }
2489	\| '[' push type_qualifier_list pop ']'
2490	{ $$ = DeclarationNode::newArray( 0, $3, false ); }
2491	// multi_array_dimension handles the '[' assignment_expression ']' case
2492	\| '[' push type_qualifier_list assignment_expression pop ']'
2493	{ $$ = DeclarationNode::newArray( $4, $3, false ); }
2494	\| '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
2495	{ $$ = DeclarationNode::newArray( $5, $4, true ); }
2496	\| '[' push type_qualifier_list STATIC assignment_expression pop ']'
2497	{ $$ = DeclarationNode::newArray( $5, $3, true ); }
2498	;
2499
2500	// This pattern parses a declaration of an abstract variable, i.e., there is no identifier to which the type
2501	// applies, e.g.:
2502	//
2503	// sizeof( int ); // abstract variable; no identifier name specified
2504	//
2505	// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and
2506	// returning arrays and functions versus pointers to arrays and functions.
2507
2508	variable_abstract_declarator:
2509	variable_abstract_ptr
2510	\| variable_abstract_array attribute_list_opt
2511	\| variable_abstract_function attribute_list_opt
2512	;
2513
2514	variable_abstract_ptr:
2515	'*'
2516	{ $$ = DeclarationNode::newPointer( 0 ); }
2517	\| '*' type_qualifier_list
2518	{ $$ = DeclarationNode::newPointer( $2 ); }
2519	\| '*' variable_abstract_declarator
2520	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2521	\| '*' type_qualifier_list variable_abstract_declarator
2522	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2523	\| '(' variable_abstract_ptr ')'
2524	{ $$ = $2; }
2525	;
2526
2527	variable_abstract_array:
2528	array_dimension
2529	\| '(' variable_abstract_ptr ')' array_dimension
2530	{ $$ = $2->addArray( $4 ); }
2531	\| '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
2532	{ $$ = $2->addArray( $4 ); }
2533	\| '(' variable_abstract_array ')' // redundant parenthesis
2534	{ $$ = $2; }
2535	;
2536
2537	variable_abstract_function:
2538	'(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2539	{ $$ = $2->addParamList( $6 ); }
2540	\| '(' variable_abstract_function ')' // redundant parenthesis
2541	{ $$ = $2; }
2542	;
2543
2544	// This pattern parses a new-style declaration for a parameter variable or function prototype that is either
2545	// an identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
2546
2547	new_identifier_parameter_declarator_tuple: // CFA
2548	new_identifier_parameter_declarator_no_tuple
2549	\| new_abstract_tuple
2550	\| type_qualifier_list new_abstract_tuple
2551	{ $$ = $2->addQualifiers( $1 ); }
2552	;
2553
2554	new_identifier_parameter_declarator_no_tuple: // CFA
2555	new_identifier_parameter_ptr
2556	\| new_identifier_parameter_array
2557	;
2558
2559	new_identifier_parameter_ptr: // CFA
2560	'*' type_specifier
2561	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2562	\| type_qualifier_list '*' type_specifier
2563	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2564	\| '*' new_abstract_function
2565	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2566	\| type_qualifier_list '*' new_abstract_function
2567	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2568	\| '*' new_identifier_parameter_declarator_tuple
2569	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2570	\| type_qualifier_list '*' new_identifier_parameter_declarator_tuple
2571	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2572	;
2573
2574	new_identifier_parameter_array: // CFA
2575	// Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due
2576	// to shift/reduce conflict with new-style empty (void) function return type.
2577	'[' push pop ']' type_specifier
2578	{ $$ = $5->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2579	\| new_array_parameter_1st_dimension type_specifier
2580	{ $$ = $2->addNewArray( $1 ); }
2581	\| '[' push pop ']' multi_array_dimension type_specifier
2582	{ $$ = $6->addNewArray( $5 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2583	\| new_array_parameter_1st_dimension multi_array_dimension type_specifier
2584	{ $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
2585	\| multi_array_dimension type_specifier
2586	{ $$ = $2->addNewArray( $1 ); }
2587	\| '[' push pop ']' new_identifier_parameter_ptr
2588	{ $$ = $5->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2589	\| new_array_parameter_1st_dimension new_identifier_parameter_ptr
2590	{ $$ = $2->addNewArray( $1 ); }
2591	\| '[' push pop ']' multi_array_dimension new_identifier_parameter_ptr
2592	{ $$ = $6->addNewArray( $5 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2593	\| new_array_parameter_1st_dimension multi_array_dimension new_identifier_parameter_ptr
2594	{ $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
2595	\| multi_array_dimension new_identifier_parameter_ptr
2596	{ $$ = $2->addNewArray( $1 ); }
2597	;
2598
2599	new_array_parameter_1st_dimension:
2600	'[' push type_qualifier_list '*' pop ']' // remaining C99
2601	{ $$ = DeclarationNode::newVarArray( $3 ); }
2602	\| '[' push type_qualifier_list assignment_expression pop ']'
2603	{ $$ = DeclarationNode::newArray( $4, $3, false ); }
2604	\| '[' push declaration_qualifier_list assignment_expression pop ']'
2605	// declaration_qualifier_list must be used because of shift/reduce conflict with
2606	// assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
2607	// appear in this context.
2608	{ $$ = DeclarationNode::newArray( $4, $3, true ); }
2609	\| '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
2610	{ $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
2611	;
2612
2613	// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is
2614	// no identifier to which the type applies, e.g.:
2615	//
2616	// [int] f( int ); // abstract variable parameter; no parameter name specified
2617	// [int] f( [int] (int) ); // abstract function-prototype parameter; no parameter name specified
2618	//
2619	// These rules need LR(3):
2620	//
2621	// new_abstract_tuple identifier_or_typedef_name
2622	// '[' new_parameter_list ']' identifier_or_typedef_name '(' new_parameter_type_list_opt ')'
2623	//
2624	// since a function return type can be syntactically identical to a tuple type:
2625	//
2626	// [int, int] t;
2627	// [int, int] f( int );
2628	//
2629	// Therefore, it is necessary to look at the token after identifier_or_typedef_name to know when to reduce
2630	// new_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the
2631	// necessary lookahead. To accomplish this, new_abstract_declarator has an entry point without tuple, and
2632	// tuple declarations are duplicated when appearing with new_function_specifier.
2633
2634	new_abstract_declarator_tuple: // CFA
2635	new_abstract_tuple
2636	\| type_qualifier_list new_abstract_tuple
2637	{ $$ = $2->addQualifiers( $1 ); }
2638	\| new_abstract_declarator_no_tuple
2639	;
2640
2641	new_abstract_declarator_no_tuple: // CFA
2642	new_abstract_ptr
2643	\| new_abstract_array
2644	;
2645
2646	new_abstract_ptr: // CFA
2647	'*' type_specifier
2648	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2649	\| type_qualifier_list '*' type_specifier
2650	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2651	\| '*' new_abstract_function
2652	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2653	\| type_qualifier_list '*' new_abstract_function
2654	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2655	\| '*' new_abstract_declarator_tuple
2656	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2657	\| type_qualifier_list '*' new_abstract_declarator_tuple
2658	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2659	;
2660
2661	new_abstract_array: // CFA
2662	// Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce
2663	// conflict with empty (void) function return type.
2664	'[' push pop ']' type_specifier
2665	{ $$ = $5->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2666	\| '[' push pop ']' multi_array_dimension type_specifier
2667	{ $$ = $6->addNewArray( $5 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2668	\| multi_array_dimension type_specifier
2669	{ $$ = $2->addNewArray( $1 ); }
2670	\| '[' push pop ']' new_abstract_ptr
2671	{ $$ = $5->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2672	\| '[' push pop ']' multi_array_dimension new_abstract_ptr
2673	{ $$ = $6->addNewArray( $5 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2674	\| multi_array_dimension new_abstract_ptr
2675	{ $$ = $2->addNewArray( $1 ); }
2676	;
2677
2678	new_abstract_tuple: // CFA
2679	'[' push new_abstract_parameter_list pop ']'
2680	{ $$ = DeclarationNode::newTuple( $3 ); }
2681	;
2682
2683	new_abstract_function: // CFA
2684	'[' push pop ']' '(' new_parameter_type_list_opt ')'
2685	{ $$ = DeclarationNode::newFunction( 0, DeclarationNode::newTuple( 0 ), $6, 0 ); }
2686	\| new_abstract_tuple '(' push new_parameter_type_list_opt pop ')'
2687	{ $$ = DeclarationNode::newFunction( 0, $1, $4, 0 ); }
2688	\| new_function_return '(' push new_parameter_type_list_opt pop ')'
2689	{ $$ = DeclarationNode::newFunction( 0, $1, $4, 0 ); }
2690	;
2691
2692	// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration
2693	// specifiers in each declaration, and in the specifier-qualifier list in each structure declaration and
2694	// type name."
2695	//
2696	// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the
2697	// beginning of the declaration specifiers in a declaration is an obsolescent feature."
2698	//
2699	// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
2700	// prototype-format parameter type declarators) is an obsolescent feature."
2701	//
2702	// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter
2703	// identifier and declaration lists (not prototype-format parameter type and identifier declarators) is an
2704	// obsolescent feature.
2705
2706	//*********************** MISCELLANEOUS ******************************
2707
2708	comma_opt: // redundant comma
2709	// empty
2710	\| ','
2711	;
2712
2713	assignment_opt:
2714	// empty
2715	{ $$ = 0; }
2716	\| '=' assignment_expression
2717	{ $$ = $2; }
2718	;
2719
2720	%%
2721	// ----end of grammar----
2722
2723	void yyerror( const char * ) {
2724	std::cout << "Error ";
2725	if ( yyfilename ) {
2726	std::cout << "in file " << yyfilename << " ";
2727	} // if
2728	std::cout << "at line " << yylineno << " reading token \"" << (yytext[0] == '\0' ? "EOF" : yytext) << "\"" << std::endl;
2729	}
2730
2731	// Local Variables: //
2732	// tab-width: 4 //
2733	// mode: c++ //
2734	// compile-command: "make install" //
2735	// End: //

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format