Context Navigation

lex.ll@ ffaedcd

Visit:

ADT arm-eh ast-experimental cleanup-dtors enum forall-pointer-decay jacob/cs343-translation jenkins-sandbox new-ast new-ast-unique-expr pthread-emulation qualifiedEnum

Last change on this file since ffaedcd was 1528a2c, checked in by Peter A. Buhr <pabuhr@…>, 7 years ago
parse new casts
Property mode set to `100644`
File size: 19.1 KB

Line
1	/*
2	* Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3	*
4	* The contents of this file are covered under the licence agreement in the
5	* file "LICENCE" distributed with Cforall.
6	*
7	* lex.ll --
8	*
9	* Author : Peter A. Buhr
10	* Created On : Sat Sep 22 08:58:10 2001
11	* Last Modified By : Peter A. Buhr
12	* Last Modified On : Wed Mar 13 14:54:30 2019
13	* Update Count : 707
14	*/
15
16	%option yylineno
17	%option noyywrap
18	%option nounput
19
20	%{
21	// The lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
22	// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
23	// line-number directives) and C/C++ style comments, which are ignored.
24
25	//************************** Includes and Defines **************************
26
27	// trigger before each matching rule's action
28	#define YY_USER_ACTION \
29	yylloc.first_line = yylineno; \
30	yylloc.first_column = column; \
31	column += yyleng; \
32	yylloc.last_column = column; \
33	yylloc.last_line = yylineno; \
34	yylloc.filename = yyfilename ? yyfilename : "";
35	unsigned int column = 0; // position of the end of the last token parsed
36
37	#include <string>
38	#include <cstdio> // FILENAME_MAX
39	using namespace std;
40
41	#include "config.h" // configure info
42	#include "ParseNode.h"
43	#include "TypedefTable.h"
44
45	char *yyfilename;
46	string *strtext; // accumulate parts of character and string constant value
47
48	#define RETURN_LOCN(x) yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
49	#define RETURN_VAL(x) yylval.tok.str = new string( yytext ); RETURN_LOCN( x )
50	#define RETURN_CHAR(x) yylval.tok.str = nullptr; RETURN_LOCN( x )
51	#define RETURN_STR(x) yylval.tok.str = strtext; RETURN_LOCN( x )
52
53	#define WHITE_RETURN(x) // do nothing
54	#define NEWLINE_RETURN() column = 0; WHITE_RETURN( '\n' )
55	#define ASCIIOP_RETURN() RETURN_CHAR( (int)yytext[0] ) // single character operator
56	#define NAMEDOP_RETURN(x) RETURN_CHAR( x ) // multichar operator, with a name
57	#define NUMERIC_RETURN(x) rm_underscore(); RETURN_VAL( x ) // numeric constant
58	#define KEYWORD_RETURN(x) RETURN_CHAR( x ) // keyword
59	#define QKEYWORD_RETURN(x) RETURN_VAL(x); // quasi-keyword
60	#define IDENTIFIER_RETURN() RETURN_VAL( typedefTable.isKind( yytext ) )
61	#define ATTRIBUTE_RETURN() RETURN_VAL( ATTR_IDENTIFIER )
62
63	#ifdef HAVE_KEYWORDS_FLOATXX // GCC >= 7 => keyword, otherwise typedef
64	#define FLOATXX(v) KEYWORD_RETURN(v);
65	#else
66	#define FLOATXX(v) IDENTIFIER_RETURN();
67	#endif // HAVE_KEYWORDS_FLOATXX
68
69	void rm_underscore() {
70	// SKULLDUGGERY: remove underscores (ok to shorten?)
71	yyleng = 0;
72	for ( int i = 0; yytext[i] != '\0'; i += 1 ) { // copying non-underscore characters to front of string
73	if ( yytext[i] != '_' ) {
74	yytext[yyleng] = yytext[i];
75	yyleng += 1;
76	} // if
77	} // for
78	yytext[yyleng] = '\0';
79	} // rm_underscore
80
81	// Stop warning due to incorrectly generated flex code.
82	#pragma GCC diagnostic ignored "-Wsign-compare"
83	%}
84
85	binary [0-1]
86	octal [0-7]
87	nonzero [1-9]
88	decimal [0-9]
89	hex [0-9a-fA-F]
90	universal_char "\\"((u"_"?{hex_quad})\|(U"_"?{hex_quad}{2}))
91
92	// identifier, GCC: $ in identifier
93	identifier ([a-zA-Z_$]\|{universal_char})([0-9a-zA-Z_$]\|{universal_char})*
94
95	// attribute identifier, GCC: $ in identifier
96	attr_identifier "@"{identifier}
97
98	// numeric constants, CFA: '_' in constant
99	hex_quad {hex}("_"?{hex}){3}
100	size_opt (8\|16\|32\|64\|128)?
101	// CFA: explicit l8/l16/l32/l64/l128, char 'hh', short 'h', int 'n'
102	length ("ll"\|"LL"\|[lL]{size_opt})\|("hh"\|"HH"\|[hHnN])
103	// CFA: size_t 'z', pointer 'p', which define a sign and length
104	integer_suffix_opt ("_"?(([uU]({length}?[iI]?)\|([iI]{length}))\|([iI]({length}?[uU]?)\|([uU]{length}))\|({length}([iI]?[uU]?)\|([uU][iI]))\|[zZ]\|[pP]))?
105
106	octal_digits ({octal})\|({octal}({octal}\|"_")*{octal})
107	octal_prefix "0""_"?
108	octal_constant (("0")\|({octal_prefix}{octal_digits})){integer_suffix_opt}
109
110	nonzero_digits ({nonzero})\|({nonzero}({decimal}\|"_")*{decimal})
111	decimal_constant {nonzero_digits}{integer_suffix_opt}
112
113	binary_digits ({binary})\|({binary}({binary}\|"_")*{binary})
114	binary_prefix "0"[bB]"_"?
115	binary_constant {binary_prefix}{binary_digits}{integer_suffix_opt}
116
117	hex_digits ({hex})\|({hex}({hex}\|"_")*{hex})
118	hex_prefix "0"[xX]"_"?
119	hex_constant {hex_prefix}{hex_digits}{integer_suffix_opt}
120
121	// GCC: D (double) and iI (imaginary) suffixes, and DL (long double)
122	exponent "_"?[eE]"_"?[+-]?{decimal_digits}
123	floating_size 16\|32\|32x\|64\|64x\|80\|128\|128x
124	floating_length ([fFdDlLwWqQ]\|[fF]{floating_size})
125	floating_suffix ({floating_length}?[iI]?)\|([iI]{floating_length})
126	floating_suffix_opt ("_"?({floating_suffix}\|"DL"))?
127	decimal_digits ({decimal})\|({decimal}({decimal}\|"_")*{decimal})
128	floating_decimal {decimal_digits}"."{exponent}?{floating_suffix_opt}
129	floating_fraction "."{decimal_digits}{exponent}?{floating_suffix_opt}
130	floating_constant ({decimal_digits}{exponent}{floating_suffix_opt})\|({decimal_digits}{floating_fraction})
131
132	binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
133	hex_floating_suffix_opt ("_"?({floating_suffix}))?
134	hex_floating_fraction ({hex_digits}?"."{hex_digits})\|({hex_digits}".")
135	hex_floating_constant {hex_prefix}(({hex_floating_fraction}{binary_exponent})\|({hex_digits}{binary_exponent})){hex_floating_suffix_opt}
136
137	// character escape sequence, GCC: \e => esc character
138	simple_escape "\\"[abefnrtv'"?\\]
139	// ' stop editor highlighting
140	octal_escape "\\"{octal}("_"?{octal}){0,2}
141	hex_escape "\\""x""_"?{hex_digits}
142	escape_seq {simple_escape}\|{octal_escape}\|{hex_escape}\|{universal_char}
143	cwide_prefix "L"\|"U"\|"u"
144	swide_prefix {cwide_prefix}\|"u8"
145
146	// display/white-space characters
147	h_tab [\011]
148	form_feed [\014]
149	v_tab [\013]
150	c_return [\015]
151	h_white [ ]\|{h_tab}
152
153	// overloadable operators
154	op_unary_only "~"\|"!"
155	op_unary_binary "+"\|"-"\|"*"
156	op_unary_pre_post "++"\|"--"
157	op_unary {op_unary_only}\|{op_unary_binary}\|{op_unary_pre_post}
158
159	op_binary_only "/"\|"%"\|"\\"\|"^"\|"&"\|"\|"\|"<"\|">"\|"="\|"=="\|"!="\|"<<"\|">>"\|"<="\|">="\|"+="\|"-="\|"*="\|"/="\|"%="\|"\\="\|"&="\|"\|="\|"^="\|"<<="\|">>="
160	op_binary_over {op_unary_binary}\|{op_binary_only}
161	// op_binary_not_over "?"\|"->"\|"."\|"&&"\|"\|\|"\|"@="
162	// operator {op_unary_pre_post}\|{op_binary_over}\|{op_binary_not_over}
163
164	%x COMMENT
165	%x BKQUOTE
166	%x QUOTE
167	%x STRING
168
169	%%
170	/* line directives */
171	^{h_white}"#"{h_white}[0-9]+{h_white}["][^"\n]+["]."\n" {
172	/* " stop editor highlighting */
173	static char filename[FILENAME_MAX]; // temporarily store current source-file name
174	char *end_num;
175	char begin_string, end_string;
176	long lineno, length;
177	lineno = strtol( yytext + 1, &end_num, 0 );
178	begin_string = strchr( end_num, '"' );
179	if ( begin_string ) { // file name ?
180	end_string = strchr( begin_string + 1, '"' ); // look for ending delimiter
181	assert( end_string ); // closing quote ?
182	length = end_string - begin_string - 1; // file-name length without quotes or sentinel
183	assert( length < FILENAME_MAX ); // room for sentinel ?
184	memcpy( &filename, begin_string + 1, length ); // copy file name from yytext
185	filename[ length ] = '\0'; // terminate string with sentinel
186	//cout << "file " << filename << " line " << lineno << endl;
187	yylineno = lineno;
188	yyfilename = filename;
189	} // if
190	}
191
192	/* preprocessor-style directives */
193	^{h_white}"#"[^\n]"\n" { RETURN_VAL( DIRECTIVE ); }
194
195	/* ignore C style comments (ALSO HANDLED BY CPP) */
196	"/*" { BEGIN COMMENT; }
197	<COMMENT>.\|\n ;
198	<COMMENT>"*/" { BEGIN 0; }
199
200	/* ignore C++ style comments (ALSO HANDLED BY CPP) */
201	"//"[^\n]*"\n" ;
202
203	/* ignore whitespace */
204	{h_white}+ { WHITE_RETURN(' '); }
205	({v_tab}\|{c_return}\|{form_feed})+ { WHITE_RETURN(' '); }
206	({h_white}\|{v_tab}\|{c_return}\|{form_feed})*"\n" { NEWLINE_RETURN(); }
207
208	/* keywords */
209	_Alignas { KEYWORD_RETURN(ALIGNAS); } // C11
210	_Alignof { KEYWORD_RETURN(ALIGNOF); } // C11
211	__alignof { KEYWORD_RETURN(ALIGNOF); } // GCC
212	__alignof__ { KEYWORD_RETURN(ALIGNOF); } // GCC
213	asm { KEYWORD_RETURN(ASM); }
214	__asm { KEYWORD_RETURN(ASM); } // GCC
215	__asm__ { KEYWORD_RETURN(ASM); } // GCC
216	_Atomic { KEYWORD_RETURN(ATOMIC); } // C11
217	__attribute { KEYWORD_RETURN(ATTRIBUTE); } // GCC
218	__attribute__ { KEYWORD_RETURN(ATTRIBUTE); } // GCC
219	auto { KEYWORD_RETURN(AUTO); }
220	basetypeof { KEYWORD_RETURN(BASETYPEOF); } // CFA
221	_Bool { KEYWORD_RETURN(BOOL); } // C99
222	break { KEYWORD_RETURN(BREAK); }
223	case { KEYWORD_RETURN(CASE); }
224	catch { KEYWORD_RETURN(CATCH); } // CFA
225	catchResume { KEYWORD_RETURN(CATCHRESUME); } // CFA
226	char { KEYWORD_RETURN(CHAR); }
227	choose { KEYWORD_RETURN(CHOOSE); } // CFA
228	coerce { KEYWORD_RETURN(COERCE); } // CFA
229	_Complex { KEYWORD_RETURN(COMPLEX); } // C99
230	__complex { KEYWORD_RETURN(COMPLEX); } // GCC
231	__complex__ { KEYWORD_RETURN(COMPLEX); } // GCC
232	const { KEYWORD_RETURN(CONST); }
233	__const { KEYWORD_RETURN(CONST); } // GCC
234	__const__ { KEYWORD_RETURN(CONST); } // GCC
235	continue { KEYWORD_RETURN(CONTINUE); }
236	coroutine { KEYWORD_RETURN(COROUTINE); } // CFA
237	default { KEYWORD_RETURN(DEFAULT); }
238	disable { KEYWORD_RETURN(DISABLE); } // CFA
239	do { KEYWORD_RETURN(DO); }
240	double { KEYWORD_RETURN(DOUBLE); }
241	dtype { KEYWORD_RETURN(DTYPE); } // CFA
242	else { KEYWORD_RETURN(ELSE); }
243	enable { KEYWORD_RETURN(ENABLE); } // CFA
244	enum { KEYWORD_RETURN(ENUM); }
245	__extension__ { KEYWORD_RETURN(EXTENSION); } // GCC
246	exception { KEYWORD_RETURN(EXCEPTION); } // CFA
247	extern { KEYWORD_RETURN(EXTERN); }
248	fallthrough { KEYWORD_RETURN(FALLTHROUGH); } // CFA
249	fallthru { KEYWORD_RETURN(FALLTHRU); } // CFA
250	finally { KEYWORD_RETURN(FINALLY); } // CFA
251	float { KEYWORD_RETURN(FLOAT); }
252	__float80 { KEYWORD_RETURN(uuFLOAT80); } // GCC
253	float80 { KEYWORD_RETURN(uuFLOAT80); } // GCC
254	__float128 { KEYWORD_RETURN(uuFLOAT128); } // GCC
255	float128 { KEYWORD_RETURN(uuFLOAT128); } // GCC
256	_Float16 { FLOATXX(uFLOAT16); } // GCC
257	_Float32 { FLOATXX(uFLOAT32); } // GCC
258	_Float32x { FLOATXX(uFLOAT32X); } // GCC
259	_Float64 { FLOATXX(uFLOAT64); } // GCC
260	_Float64x { FLOATXX(uFLOAT64X); } // GCC
261	_Float128 { FLOATXX(uFLOAT128); } // GCC
262	_Float128x { FLOATXX(uFLOAT128); } // GCC
263	for { KEYWORD_RETURN(FOR); }
264	forall { KEYWORD_RETURN(FORALL); } // CFA
265	fortran { KEYWORD_RETURN(FORTRAN); }
266	ftype { KEYWORD_RETURN(FTYPE); } // CFA
267	_Generic { KEYWORD_RETURN(GENERIC); } // C11
268	goto { KEYWORD_RETURN(GOTO); }
269	if { KEYWORD_RETURN(IF); }
270	_Imaginary { KEYWORD_RETURN(IMAGINARY); } // C99
271	__imag { KEYWORD_RETURN(IMAGINARY); } // GCC
272	__imag__ { KEYWORD_RETURN(IMAGINARY); } // GCC
273	inline { KEYWORD_RETURN(INLINE); } // C99
274	__inline { KEYWORD_RETURN(INLINE); } // GCC
275	__inline__ { KEYWORD_RETURN(INLINE); } // GCC
276	int { KEYWORD_RETURN(INT); }
277	__int128 { KEYWORD_RETURN(INT128); } // GCC
278	int128 { KEYWORD_RETURN(INT128); } // GCC
279	__label__ { KEYWORD_RETURN(LABEL); } // GCC
280	long { KEYWORD_RETURN(LONG); }
281	monitor { KEYWORD_RETURN(MONITOR); } // CFA
282	mutex { KEYWORD_RETURN(MUTEX); } // CFA
283	_Noreturn { KEYWORD_RETURN(NORETURN); } // C11
284	__builtin_offsetof { KEYWORD_RETURN(OFFSETOF); } // GCC
285	one_t { NUMERIC_RETURN(ONE_T); } // CFA
286	or { QKEYWORD_RETURN(WOR); } // CFA
287	otype { KEYWORD_RETURN(OTYPE); } // CFA
288	register { KEYWORD_RETURN(REGISTER); }
289	restrict { KEYWORD_RETURN(RESTRICT); } // C99
290	__restrict { KEYWORD_RETURN(RESTRICT); } // GCC
291	__restrict__ { KEYWORD_RETURN(RESTRICT); } // GCC
292	return { KEYWORD_RETURN(RETURN); }
293	short { KEYWORD_RETURN(SHORT); }
294	signed { KEYWORD_RETURN(SIGNED); }
295	__signed { KEYWORD_RETURN(SIGNED); } // GCC
296	__signed__ { KEYWORD_RETURN(SIGNED); } // GCC
297	sizeof { KEYWORD_RETURN(SIZEOF); }
298	static { KEYWORD_RETURN(STATIC); }
299	_Static_assert { KEYWORD_RETURN(STATICASSERT); } // C11
300	struct { KEYWORD_RETURN(STRUCT); }
301	switch { KEYWORD_RETURN(SWITCH); }
302	thread { KEYWORD_RETURN(THREAD); } // C11
303	_Thread_local { KEYWORD_RETURN(THREADLOCAL); } // C11
304	throw { KEYWORD_RETURN(THROW); } // CFA
305	throwResume { KEYWORD_RETURN(THROWRESUME); } // CFA
306	timeout { QKEYWORD_RETURN(TIMEOUT); } // CFA
307	trait { KEYWORD_RETURN(TRAIT); } // CFA
308	try { KEYWORD_RETURN(TRY); } // CFA
309	ttype { KEYWORD_RETURN(TTYPE); } // CFA
310	typedef { KEYWORD_RETURN(TYPEDEF); }
311	typeof { KEYWORD_RETURN(TYPEOF); } // GCC
312	__typeof { KEYWORD_RETURN(TYPEOF); } // GCC
313	__typeof__ { KEYWORD_RETURN(TYPEOF); } // GCC
314	union { KEYWORD_RETURN(UNION); }
315	unsigned { KEYWORD_RETURN(UNSIGNED); }
316	__builtin_va_list { KEYWORD_RETURN(VALIST); } // GCC
317	virtual { KEYWORD_RETURN(VIRTUAL); } // CFA
318	void { KEYWORD_RETURN(VOID); }
319	volatile { KEYWORD_RETURN(VOLATILE); }
320	__volatile { KEYWORD_RETURN(VOLATILE); } // GCC
321	__volatile__ { KEYWORD_RETURN(VOLATILE); } // GCC
322	waitfor { KEYWORD_RETURN(WAITFOR); }
323	when { KEYWORD_RETURN(WHEN); }
324	while { KEYWORD_RETURN(WHILE); }
325	with { KEYWORD_RETURN(WITH); } // CFA
326	zero_t { NUMERIC_RETURN(ZERO_T); } // CFA
327
328	/* identifier */
329	{identifier} { IDENTIFIER_RETURN(); }
330	"`"{identifier}"`" { // CFA
331	yytext[yyleng - 1] = '\0'; yytext += 1; // SKULLDUGGERY: remove backquotes (ok to shorten?)
332	IDENTIFIER_RETURN();
333	}
334	{attr_identifier} { ATTRIBUTE_RETURN(); }
335
336	/* numeric constants */
337	{binary_constant} { NUMERIC_RETURN(INTEGERconstant); }
338	{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
339	{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
340	{hex_constant} { NUMERIC_RETURN(INTEGERconstant); }
341	{floating_decimal} { NUMERIC_RETURN(FLOATING_DECIMALconstant); } // must appear before floating_constant
342	{floating_fraction} { NUMERIC_RETURN(FLOATING_FRACTIONconstant); } // must appear before floating_constant
343	{floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
344	{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
345
346	/* character constant, allows empty value */
347	({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new string( yytext, yyleng ); }
348	<QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); }
349	<QUOTE>['\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); }
350	/* ' stop editor highlighting */
351
352	/* string constant */
353	({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new string( yytext, yyleng ); }
354	<STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); }
355	<STRING>["\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); }
356	/* " stop editor highlighting */
357
358	/* common character/string constant */
359	<QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); }
360	<QUOTE,STRING>"\\"{h_white}*"\n" {} // continuation (ALSO HANDLED BY CPP)
361	<QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character
362
363	/* punctuation */
364	"@" { ASCIIOP_RETURN(); }
365	"`" { ASCIIOP_RETURN(); }
366	"[" { ASCIIOP_RETURN(); }
367	"]" { ASCIIOP_RETURN(); }
368	"(" { ASCIIOP_RETURN(); }
369	")" { ASCIIOP_RETURN(); }
370	"{" { ASCIIOP_RETURN(); }
371	"}" { ASCIIOP_RETURN(); }
372	"," { ASCIIOP_RETURN(); } // also operator
373	":" { ASCIIOP_RETURN(); }
374	";" { ASCIIOP_RETURN(); }
375	"." { ASCIIOP_RETURN(); } // also operator
376	"..." { NAMEDOP_RETURN(ELLIPSIS); }
377
378	/* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
379	"<:" { RETURN_VAL('['); }
380	":>" { RETURN_VAL(']'); }
381	"<%" { RETURN_VAL('{'); }
382	"%>" { RETURN_VAL('}'); }
383
384	/* operators */
385	"!" { ASCIIOP_RETURN(); }
386	"+" { ASCIIOP_RETURN(); }
387	"-" { ASCIIOP_RETURN(); }
388	"*" { ASCIIOP_RETURN(); }
389	"\\" { ASCIIOP_RETURN(); } // CFA, exponentiation
390	"/" { ASCIIOP_RETURN(); }
391	"%" { ASCIIOP_RETURN(); }
392	"^" { ASCIIOP_RETURN(); }
393	"~" { ASCIIOP_RETURN(); }
394	"&" { ASCIIOP_RETURN(); }
395	"\|" { ASCIIOP_RETURN(); }
396	"<" { ASCIIOP_RETURN(); }
397	">" { ASCIIOP_RETURN(); }
398	"=" { ASCIIOP_RETURN(); }
399	"?" { ASCIIOP_RETURN(); }
400
401	"++" { NAMEDOP_RETURN(ICR); }
402	"--" { NAMEDOP_RETURN(DECR); }
403	"==" { NAMEDOP_RETURN(EQ); }
404	"!=" { NAMEDOP_RETURN(NE); }
405	"<<" { NAMEDOP_RETURN(LS); }
406	">>" { NAMEDOP_RETURN(RS); }
407	"<=" { NAMEDOP_RETURN(LE); }
408	">=" { NAMEDOP_RETURN(GE); }
409	"&&" { NAMEDOP_RETURN(ANDAND); }
410	"\|\|" { NAMEDOP_RETURN(OROR); }
411	"->" { NAMEDOP_RETURN(ARROW); }
412	"+=" { NAMEDOP_RETURN(PLUSassign); }
413	"-=" { NAMEDOP_RETURN(MINUSassign); }
414	"\\=" { NAMEDOP_RETURN(EXPassign); } // CFA, exponentiation
415	"*=" { NAMEDOP_RETURN(MULTassign); }
416	"/=" { NAMEDOP_RETURN(DIVassign); }
417	"%=" { NAMEDOP_RETURN(MODassign); }
418	"&=" { NAMEDOP_RETURN(ANDassign); }
419	"\|=" { NAMEDOP_RETURN(ORassign); }
420	"^=" { NAMEDOP_RETURN(ERassign); }
421	"<<=" { NAMEDOP_RETURN(LSassign); }
422	">>=" { NAMEDOP_RETURN(RSassign); }
423
424	"@=" { NAMEDOP_RETURN(ATassign); } // CFA
425	"~=" { NAMEDOP_RETURN(ErangeUpEq); } // CFA
426	"-~" { NAMEDOP_RETURN(ErangeDown); } // CFA
427	"-~=" { NAMEDOP_RETURN(ErangeDownEq); } // CFA
428
429	/* CFA, operator identifier */
430	{op_unary}"?" { IDENTIFIER_RETURN(); } // unary
431	"?"({op_unary_pre_post}\|"()"\|"[?]"\|"{}") { IDENTIFIER_RETURN(); }
432	"^?{}" { IDENTIFIER_RETURN(); }
433	"?`"{identifier} { IDENTIFIER_RETURN(); } // postfix operator
434	"?"{op_binary_over}"?" { IDENTIFIER_RETURN(); } // binary
435	/*
436	This rule handles ambiguous cases with operator identifiers, e.g., "int ??()", where the string "??" can be
437	lexed as "?"/"?" or ""/"??". Since it is common practise to put a unary operator juxtaposed to an identifier,
438	e.g., "*i", users will be annoyed if they cannot do this with respect to operator identifiers. Therefore, there is
439	a lexical look-ahead for the second case, with backtracking to return the leading unary operator and then
440	reparsing the trailing operator identifier. Otherwise a space is needed between the unary operator and operator
441	identifier to disambiguate this common case.
442
443	A similar issue occurs with the dereference, *?(...), and routine-call, ?()(...) identifiers. The ambiguity
444	occurs when the deference operator has no parameters, ?() and ?()(...), requiring arbitrary whitespace
445	look-ahead for the routine-call parameter-list to disambiguate. However, the dereference operator must have a
446	parameter/argument to dereference ?(...). Hence, always interpreting the string ?() as * ?() does not preclude
447	any meaningful program.
448
449	The remaining cases are with the increment/decrement operators and conditional expression:
450
451	i++? ...(...);
452	i?++ ...(...);
453
454	requiring arbitrary whitespace look-ahead for the operator parameter-list, even though that interpretation is an
455	incorrect expression (juxtaposed identifiers). Therefore, it is necessary to disambiguate these cases with a
456	space:
457
458	i++ ? i : 0;
459	i? ++i : 0;
460	*/
461	{op_unary}"?"({op_unary_pre_post}\|"()"\|"[?]"\|{op_binary_over}"?") {
462	// 1 or 2 character unary operator ?
463	int i = yytext[1] == '?' ? 1 : 2;
464	yyless( i ); // put back characters up to first '?'
465	if ( i > 1 ) {
466	NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
467	} else {
468	ASCIIOP_RETURN();
469	} // if
470	}
471
472	/* unknown character */
473	. { yyerror( "unknown character" ); }
474
475	%%
476
477	// ----end of lexer----
478
479	void yyerror( const char * errmsg ) {
480	SemanticErrorThrow = true;
481	cerr << (yyfilename ? yyfilename : "unknown file") << ':' << yylineno << ':' << column - yyleng + 1
482	<< ": " << ErrorHelpers::error_str() << errmsg << " at token \"" << (yytext[0] == '\0' ? "EOF" : yytext) << '"' << endl;
483	}
484
485	// Local Variables: //
486	// mode: c++ //
487	// tab-width: 4 //
488	// compile-command: "make install" //
489	// End: //

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format