source: src/Parser/lex.ll@ efe4d730

ADT aaron-thesis arm-eh ast-experimental cleanup-dtors deferred_resn demangler enum forall-pointer-decay jacob/cs343-translation jenkins-sandbox new-ast new-ast-unique-expr new-env no_list persistent-indexer pthread-emulation qualifiedEnum resolv-new with_gc
Last change on this file since efe4d730 was 9059213, checked in by Peter A. Buhr <pabuhr@…>, 9 years ago

small changes to bring me up to date
  • Property mode set to 100644
File size: 15.6 KB
Line 
1/*
2 * Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3 *
4 * The contents of this file are covered under the licence agreement in the
5 * file "LICENCE" distributed with Cforall.
6 *
7 * lex.l --
8 *
9 * Author : Peter A. Buhr
10 * Created On : Sat Sep 22 08:58:10 2001
11 * Last Modified By : Peter A. Buhr
12 * Last Modified On : Tue Oct 18 22:19:37 2016
13 * Update Count : 488
14 */
15
16%option yylineno
17%option nounput
18
19%{
20// This lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
21// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
22// line-number directives) and C/C++ style comments, which are ignored.
23
24//**************************** Includes and Defines ****************************
25
26#include <string>
27#include <cstdio> // FILENAME_MAX
28
29#include "lex.h"
30#include "parser.h" // YACC generated definitions based on C++ grammar
31#include "ParseNode.h"
32#include "TypedefTable.h"
33
34char *yyfilename;
35std::string *strtext; // accumulate parts of character and string constant value
36
37#define RETURN_LOCN(x) yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
38#define RETURN_VAL(x) yylval.tok.str = new std::string( yytext ); RETURN_LOCN( x )
39#define RETURN_CHAR(x) yylval.tok.str = nullptr; RETURN_LOCN( x )
40#define RETURN_STR(x) yylval.tok.str = strtext; RETURN_LOCN( x )
41
42#define WHITE_RETURN(x) // do nothing
43#define NEWLINE_RETURN() WHITE_RETURN( '\n' )
44#define ASCIIOP_RETURN() RETURN_CHAR( (int)yytext[0] ) // single character operator
45#define NAMEDOP_RETURN(x) RETURN_CHAR( x ) // multichar operator, with a name
46#define NUMERIC_RETURN(x) rm_underscore(); RETURN_VAL( x ) // numeric constant
47#define KEYWORD_RETURN(x) RETURN_CHAR( x ) // keyword
48#define IDENTIFIER_RETURN() RETURN_VAL( typedefTable.isKind( yytext ) )
49#define ATTRIBUTE_RETURN() RETURN_VAL( ATTR_IDENTIFIER )
50
51void rm_underscore() {
52 // Remove underscores in numeric constant by copying the non-underscore characters to the front of the string.
53 yyleng = 0;
54 for ( int i = 0; yytext[i] != '\0'; i += 1 ) {
55 if ( yytext[i] != '_' ) {
56 yytext[yyleng] = yytext[i];
57 yyleng += 1;
58 } // if
59 } // for
60 yytext[yyleng] = '\0';
61}
62
63%}
64
65octal [0-7]
66nonzero [1-9]
67decimal [0-9]
68hex [0-9a-fA-F]
69universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2}))
70
71 // identifier, GCC: $ in identifier
72identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})*
73
74 // attribute identifier, GCC: $ in identifier
75attr_identifier "@"{identifier}
76
77 // numeric constants, CFA: '_' in constant
78hex_quad {hex}("_"?{hex}){3}
79integer_suffix "_"?(([uU][lL]?)|([uU]("ll"|"LL")?)|([lL][uU]?)|("ll"|"LL")[uU]?)
80
81octal_digits ({octal})|({octal}({octal}|"_")*{octal})
82octal_prefix "0""_"?
83octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix}?
84
85nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal})
86decimal_constant {nonzero_digits}{integer_suffix}?
87
88hex_digits ({hex})|({hex}({hex}|"_")*{hex})
89hex_prefix "0"[xX]"_"?
90hex_constant {hex_prefix}{hex_digits}{integer_suffix}?
91
92decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal})
93fractional_constant ({decimal_digits}?"."{decimal_digits})|({decimal_digits}".")
94exponent "_"?[eE]"_"?[+-]?{decimal_digits}
95 // GCC: D (double), DL (long double) and iI (imaginary) suffixes
96floating_suffix "_"?([fFdDlL][iI]?|"DL"|[iI][lLfFdD]?)
97 //floating_suffix "_"?([fFdD]|[lL]|[D][L])|([iI][lLfFdD])|([lLfFdD][iI]))
98floating_constant (({fractional_constant}{exponent}?)|({decimal_digits}{exponent})){floating_suffix}?
99
100binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
101hex_fractional_constant ({hex_digits}?"."{hex_digits})|({hex_digits}".")
102hex_floating_constant {hex_prefix}(({hex_fractional_constant}{binary_exponent})|({hex_digits}{binary_exponent})){floating_suffix}?
103
104 // character escape sequence, GCC: \e => esc character
105simple_escape "\\"[abefnrtv'"?\\]
106 // ' stop highlighting
107octal_escape "\\"{octal}("_"?{octal}){0,2}
108hex_escape "\\""x""_"?{hex_digits}
109escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char}
110cwide_prefix "L"|"U"|"u"
111swide_prefix {cwide_prefix}|"u8"
112
113 // display/white-space characters
114h_tab [\011]
115form_feed [\014]
116v_tab [\013]
117c_return [\015]
118h_white [ ]|{h_tab}
119
120 // overloadable operators
121op_unary_only "~"|"!"
122op_unary_binary "+"|"-"|"*"
123op_unary_pre_post "++"|"--"
124op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post}
125
126op_binary_only "/"|"%"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"&="|"|="|"^="|"<<="|">>="
127op_binary_over {op_unary_binary}|{op_binary_only}
128 // op_binary_not_over "?"|"->"|"."|"&&"|"||"|"@="
129 // operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over}
130
131%x COMMENT
132%x BKQUOTE
133%x QUOTE
134%x STRING
135
136%%
137 /* line directives */
138^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["].*"\n" {
139 /* " stop highlighting */
140 static char filename[FILENAME_MAX]; // temporarily store current source-file name
141 char *end_num;
142 char *begin_string, *end_string;
143 long lineno, length;
144 lineno = strtol( yytext + 1, &end_num, 0 );
145 begin_string = strchr( end_num, '"' );
146 if ( begin_string ) { // file name ?
147 end_string = strchr( begin_string + 1, '"' ); // look for ending delimiter
148 assert( end_string ); // closing quote ?
149 length = end_string - begin_string - 1; // file-name length without quotes or sentinel
150 assert( length < FILENAME_MAX ); // room for sentinel ?
151 memcpy( &filename, begin_string + 1, length ); // copy file name from yytext
152 filename[ length ] = '\0'; // terminate string with sentinel
153 //std::cout << "file " << filename << " line " << lineno << std::endl;
154 yylineno = lineno;
155 yyfilename = filename;
156 } // if
157}
158
159 /* ignore preprocessor directives (for now) */
160^{h_white}*"#"[^\n]*"\n" ;
161
162 /* ignore C style comments (ALSO HANDLED BY CPP) */
163"/*" { BEGIN COMMENT; }
164<COMMENT>.|\n ;
165<COMMENT>"*/" { BEGIN 0; }
166
167 /* ignore C++ style comments (ALSO HANDLED BY CPP) */
168"//"[^\n]*"\n" ;
169
170 /* ignore whitespace */
171{h_white}+ { WHITE_RETURN(' '); }
172({v_tab}|{c_return}|{form_feed})+ { WHITE_RETURN(' '); }
173({h_white}|{v_tab}|{c_return}|{form_feed})*"\n" { NEWLINE_RETURN(); }
174
175 /* keywords */
176_Alignas { KEYWORD_RETURN(ALIGNAS); } // C11
177_Alignof { KEYWORD_RETURN(ALIGNOF); } // C11
178__alignof { KEYWORD_RETURN(ALIGNOF); } // GCC
179__alignof__ { KEYWORD_RETURN(ALIGNOF); } // GCC
180asm { KEYWORD_RETURN(ASM); }
181__asm { KEYWORD_RETURN(ASM); } // GCC
182__asm__ { KEYWORD_RETURN(ASM); } // GCC
183_At { KEYWORD_RETURN(AT); } // CFA
184_Atomic { KEYWORD_RETURN(ATOMIC); } // C11
185__attribute { KEYWORD_RETURN(ATTRIBUTE); } // GCC
186__attribute__ { KEYWORD_RETURN(ATTRIBUTE); } // GCC
187auto { KEYWORD_RETURN(AUTO); }
188_Bool { KEYWORD_RETURN(BOOL); } // C99
189break { KEYWORD_RETURN(BREAK); }
190case { KEYWORD_RETURN(CASE); }
191catch { KEYWORD_RETURN(CATCH); } // CFA
192catchResume { KEYWORD_RETURN(CATCHRESUME); } // CFA
193char { KEYWORD_RETURN(CHAR); }
194choose { KEYWORD_RETURN(CHOOSE); } // CFA
195_Complex { KEYWORD_RETURN(COMPLEX); } // C99
196__complex { KEYWORD_RETURN(COMPLEX); } // GCC
197__complex__ { KEYWORD_RETURN(COMPLEX); } // GCC
198const { KEYWORD_RETURN(CONST); }
199__const { KEYWORD_RETURN(CONST); } // GCC
200__const__ { KEYWORD_RETURN(CONST); } // GCC
201continue { KEYWORD_RETURN(CONTINUE); }
202default { KEYWORD_RETURN(DEFAULT); }
203disable { KEYWORD_RETURN(DISABLE); } // CFA
204do { KEYWORD_RETURN(DO); }
205double { KEYWORD_RETURN(DOUBLE); }
206dtype { KEYWORD_RETURN(DTYPE); } // CFA
207else { KEYWORD_RETURN(ELSE); }
208enable { KEYWORD_RETURN(ENABLE); } // CFA
209enum { KEYWORD_RETURN(ENUM); }
210__extension__ { KEYWORD_RETURN(EXTENSION); } // GCC
211extern { KEYWORD_RETURN(EXTERN); }
212fallthrough { KEYWORD_RETURN(FALLTHRU); } // CFA
213fallthru { KEYWORD_RETURN(FALLTHRU); } // CFA
214finally { KEYWORD_RETURN(FINALLY); } // CFA
215float { KEYWORD_RETURN(FLOAT); }
216__float128 { KEYWORD_RETURN(FLOAT); } // GCC
217for { KEYWORD_RETURN(FOR); }
218forall { KEYWORD_RETURN(FORALL); } // CFA
219fortran { KEYWORD_RETURN(FORTRAN); }
220ftype { KEYWORD_RETURN(FTYPE); } // CFA
221_Generic { KEYWORD_RETURN(GENERIC); } // C11
222goto { KEYWORD_RETURN(GOTO); }
223if { KEYWORD_RETURN(IF); }
224_Imaginary { KEYWORD_RETURN(IMAGINARY); } // C99
225__imag { KEYWORD_RETURN(IMAGINARY); } // GCC
226__imag__ { KEYWORD_RETURN(IMAGINARY); } // GCC
227inline { KEYWORD_RETURN(INLINE); } // C99
228__inline { KEYWORD_RETURN(INLINE); } // GCC
229__inline__ { KEYWORD_RETURN(INLINE); } // GCC
230int { KEYWORD_RETURN(INT); }
231__int128 { KEYWORD_RETURN(INT); } // GCC
232__label__ { KEYWORD_RETURN(LABEL); } // GCC
233long { KEYWORD_RETURN(LONG); }
234lvalue { KEYWORD_RETURN(LVALUE); } // CFA
235_Noreturn { KEYWORD_RETURN(NORETURN); } // C11
236__builtin_offsetof { KEYWORD_RETURN(OFFSETOF); } // GCC
237otype { KEYWORD_RETURN(OTYPE); } // CFA
238register { KEYWORD_RETURN(REGISTER); }
239restrict { KEYWORD_RETURN(RESTRICT); } // C99
240__restrict { KEYWORD_RETURN(RESTRICT); } // GCC
241__restrict__ { KEYWORD_RETURN(RESTRICT); } // GCC
242return { KEYWORD_RETURN(RETURN); }
243short { KEYWORD_RETURN(SHORT); }
244signed { KEYWORD_RETURN(SIGNED); }
245__signed { KEYWORD_RETURN(SIGNED); } // GCC
246__signed__ { KEYWORD_RETURN(SIGNED); } // GCC
247sizeof { KEYWORD_RETURN(SIZEOF); }
248static { KEYWORD_RETURN(STATIC); }
249_Static_assert { KEYWORD_RETURN(STATICASSERT); } // C11
250struct { KEYWORD_RETURN(STRUCT); }
251switch { KEYWORD_RETURN(SWITCH); }
252_Thread_local { KEYWORD_RETURN(THREADLOCAL); } // C11
253throw { KEYWORD_RETURN(THROW); } // CFA
254throwResume { KEYWORD_RETURN(THROWRESUME); } // CFA
255trait { KEYWORD_RETURN(TRAIT); } // CFA
256try { KEYWORD_RETURN(TRY); } // CFA
257typedef { KEYWORD_RETURN(TYPEDEF); }
258typeof { KEYWORD_RETURN(TYPEOF); } // GCC
259__typeof { KEYWORD_RETURN(TYPEOF); } // GCC
260__typeof__ { KEYWORD_RETURN(TYPEOF); } // GCC
261union { KEYWORD_RETURN(UNION); }
262unsigned { KEYWORD_RETURN(UNSIGNED); }
263__builtin_va_list { KEYWORD_RETURN(VALIST); } // GCC
264void { KEYWORD_RETURN(VOID); }
265volatile { KEYWORD_RETURN(VOLATILE); }
266__volatile { KEYWORD_RETURN(VOLATILE); } // GCC
267__volatile__ { KEYWORD_RETURN(VOLATILE); } // GCC
268while { KEYWORD_RETURN(WHILE); }
269
270 /* identifier */
271{identifier} { IDENTIFIER_RETURN(); }
272{attr_identifier} { ATTRIBUTE_RETURN(); }
273"`" { BEGIN BKQUOTE; }
274<BKQUOTE>{identifier} { IDENTIFIER_RETURN(); }
275<BKQUOTE>"`" { BEGIN 0; }
276
277 /* numeric constants */
278"0" { NUMERIC_RETURN(ZERO); } // CFA
279"1" { NUMERIC_RETURN(ONE); } // CFA
280{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
281{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
282{hex_constant} { NUMERIC_RETURN(INTEGERconstant); }
283{floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
284{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
285
286 /* character constant, allows empty value */
287({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new std::string( yytext, yyleng ); }
288<QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); }
289<QUOTE>['\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); }
290 /* ' stop highlighting */
291
292 /* string constant */
293({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new std::string( yytext, yyleng ); }
294<STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); }
295<STRING>["\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); }
296 /* " stop highlighting */
297
298 /* common character/string constant */
299<QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); }
300<QUOTE,STRING>"\\"{h_white}*"\n" {} // continuation (ALSO HANDLED BY CPP)
301<QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character
302
303 /* punctuation */
304"[" { ASCIIOP_RETURN(); }
305"]" { ASCIIOP_RETURN(); }
306"(" { ASCIIOP_RETURN(); }
307")" { ASCIIOP_RETURN(); }
308"{" { ASCIIOP_RETURN(); }
309"}" { ASCIIOP_RETURN(); }
310"," { ASCIIOP_RETURN(); } // also operator
311":" { ASCIIOP_RETURN(); }
312";" { ASCIIOP_RETURN(); }
313"." { ASCIIOP_RETURN(); } // also operator
314"..." { NAMEDOP_RETURN(ELLIPSIS); }
315
316 /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
317"<:" { RETURN_VAL('['); }
318":>" { RETURN_VAL(']'); }
319"<%" { RETURN_VAL('{'); }
320"%>" { RETURN_VAL('}'); }
321
322 /* operators */
323"!" { ASCIIOP_RETURN(); }
324"+" { ASCIIOP_RETURN(); }
325"-" { ASCIIOP_RETURN(); }
326"*" { ASCIIOP_RETURN(); }
327"/" { ASCIIOP_RETURN(); }
328"%" { ASCIIOP_RETURN(); }
329"^" { ASCIIOP_RETURN(); }
330"~" { ASCIIOP_RETURN(); }
331"&" { ASCIIOP_RETURN(); }
332"|" { ASCIIOP_RETURN(); }
333"<" { ASCIIOP_RETURN(); }
334">" { ASCIIOP_RETURN(); }
335"=" { ASCIIOP_RETURN(); }
336"?" { ASCIIOP_RETURN(); }
337
338"++" { NAMEDOP_RETURN(ICR); }
339"--" { NAMEDOP_RETURN(DECR); }
340"==" { NAMEDOP_RETURN(EQ); }
341"!=" { NAMEDOP_RETURN(NE); }
342"<<" { NAMEDOP_RETURN(LS); }
343">>" { NAMEDOP_RETURN(RS); }
344"<=" { NAMEDOP_RETURN(LE); }
345">=" { NAMEDOP_RETURN(GE); }
346"&&" { NAMEDOP_RETURN(ANDAND); }
347"||" { NAMEDOP_RETURN(OROR); }
348"->" { NAMEDOP_RETURN(ARROW); }
349"+=" { NAMEDOP_RETURN(PLUSassign); }
350"-=" { NAMEDOP_RETURN(MINUSassign); }
351"*=" { NAMEDOP_RETURN(MULTassign); }
352"/=" { NAMEDOP_RETURN(DIVassign); }
353"%=" { NAMEDOP_RETURN(MODassign); }
354"&=" { NAMEDOP_RETURN(ANDassign); }
355"|=" { NAMEDOP_RETURN(ORassign); }
356"^=" { NAMEDOP_RETURN(ERassign); }
357"<<=" { NAMEDOP_RETURN(LSassign); }
358">>=" { NAMEDOP_RETURN(RSassign); }
359
360"@=" { NAMEDOP_RETURN(ATassign); } // CFA
361
362 /* CFA, operator identifier */
363{op_unary}"?" { IDENTIFIER_RETURN(); } // unary
364"?"({op_unary_pre_post}|"()"|"[?]"|"{}") { IDENTIFIER_RETURN(); }
365"^?{}" { IDENTIFIER_RETURN(); }
366"?"{op_binary_over}"?" { IDENTIFIER_RETURN(); } // binary
367 /*
368 This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the string "*?*?"
369 can be lexed as "*"/"?*?" or "*?"/"*?". Since it is common practise to put a unary operator juxtaposed
370 to an identifier, e.g., "*i", users will be annoyed if they cannot do this with respect to operator
371 identifiers. Even with this special hack, there are 5 general cases that cannot be handled. The first
372 case is for the function-call identifier "?()":
373
374 int * ?()(); // declaration: space required after '*'
375 * ?()(); // expression: space required after '*'
376
377 Without the space, the string "*?()" is ambiguous without N character look ahead; it requires scanning
378 ahead to determine if there is a '(', which is the start of an argument/parameter list.
379
380 The 4 remaining cases occur in expressions:
381
382 i++?i:0; // space required before '?'
383 i--?i:0; // space required before '?'
384 i?++i:0; // space required after '?'
385 i?--i:0; // space required after '?'
386
387 In the first two cases, the string "i++?" is ambiguous, where this string can be lexed as "i"/"++?" or
388 "i++"/"?"; it requires scanning ahead to determine if there is a '(', which is the start of an argument
389 list. In the second two cases, the string "?++x" is ambiguous, where this string can be lexed as
390 "?++"/"x" or "?"/"++x"; it requires scanning ahead to determine if there is a '(', which is the start of
391 an argument list.
392 */
393{op_unary}"?"({op_unary_pre_post}|"[?]"|{op_binary_over}"?") {
394 // 1 or 2 character unary operator ?
395 int i = yytext[1] == '?' ? 1 : 2;
396 yyless( i ); // put back characters up to first '?'
397 if ( i > 1 ) {
398 NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
399 } else {
400 ASCIIOP_RETURN();
401 } // if
402}
403
404 /* unknown characters */
405. { printf("unknown character(s):\"%s\" on line %d\n", yytext, yylineno); }
406
407%%
408
409// Local Variables: //
410// mode: c++ //
411// tab-width: 4 //
412// compile-command: "make install" //
413// End: //
Note: See TracBrowser for help on using the repository browser.