source: src/Parser/lex.ll @ e72fc60

Last change on this file since e72fc60 was 647e2ea, checked in by Peter A. Buhr <pabuhr@…>, 8 months ago

try @@(...) for attributes, rename and reorder grammar rules, remove apparently unnecessary push/pop rules, first attempt at [] => [void] return type
  • Property mode set to 100644
File size: 21.0 KB
Line 
1/*
2 * Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3 *
4 * The contents of this file are covered under the licence agreement in the
5 * file "LICENCE" distributed with Cforall.
6 *
7 * lex.ll --
8 *
9 * Author           : Peter A. Buhr
10 * Created On       : Sat Sep 22 08:58:10 2001
11 * Last Modified By : Peter A. Buhr
12 * Last Modified On : Sat Feb 24 11:47:24 2024
13 * Update Count     : 777
14 */
15
16%option yylineno
17%option noyywrap
18%option nounput
19
20%{
21// The lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
22// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
23// line-number directives) and C/C++ style comments, which are ignored.
24
25// *************************** Includes and Defines ****************************
26
27#ifdef __clang__
28#pragma GCC diagnostic ignored "-Wnull-conversion"
29#endif
30
31// trigger before each matching rule's action
32#define YY_USER_ACTION \
33        yylloc.first_line = yylineno; \
34        yylloc.first_column = column; \
35        column += yyleng; \
36        yylloc.last_column = column; \
37        yylloc.last_line = yylineno; \
38        yylloc.filename = yyfilename ? yyfilename : "";
39unsigned int column = 0;                                                                // position of the end of the last token parsed
40
41#include <string>
42#include <cstdio>                                                                               // FILENAME_MAX
43using namespace std;
44
45#include "config.h"                                                                             // configure info
46#include "DeclarationNode.h"                            // for DeclarationNode
47#include "ExpressionNode.h"                             // for LabelNode
48#include "InitializerNode.h"                            // for InitializerNode
49#include "ParseNode.h"
50#include "ParserTypes.h"                                // for Token
51#include "StatementNode.h"                              // for CondCtl, ForCtrl
52#include "TypedefTable.h"
53// This (generated) header must come late as it is missing includes.
54#include "parser.hh"                                    // generated info
55
56string * build_postfix_name( string * name );
57
58char *yyfilename;
59string *strtext;                                                                                // accumulate parts of character and string constant value
60
61#define RETURN_LOCN(x)          yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
62#define RETURN_VAL(x)           yylval.tok.str = new string( yytext ); RETURN_LOCN( x )
63#define RETURN_CHAR(x)          yylval.tok.str = nullptr; RETURN_LOCN( x )
64#define RETURN_STR(x)           yylval.tok.str = strtext; RETURN_LOCN( x )
65
66#define WHITE_RETURN(x)         // do nothing
67#define NEWLINE_RETURN()        column = 0; WHITE_RETURN( '\n' )
68#define ASCIIOP_RETURN()        RETURN_CHAR( (int)yytext[0] ) // single character operator
69#define NAMEDOP_RETURN(x)       RETURN_CHAR( x )                        // multichar operator, with a name
70#define NUMERIC_RETURN(x)       rm_underscore(); RETURN_VAL( x ) // numeric constant
71#define KEYWORD_RETURN(x)       RETURN_CHAR( x )                        // keyword
72#define QKEYWORD_RETURN(x)      RETURN_VAL(x);                          // quasi-keyword
73#define IDENTIFIER_RETURN()     RETURN_VAL( typedefTable.isKind( yytext ) )
74
75#ifdef HAVE_KEYWORDS_FLOATXX                                                    // GCC >= 7 => keyword, otherwise typedef
76#define FLOATXX(v) KEYWORD_RETURN(v);
77#else
78#define FLOATXX(v) IDENTIFIER_RETURN();
79#endif // HAVE_KEYWORDS_FLOATXX
80
81void rm_underscore() {
82        // SKULLDUGGERY: remove underscores (ok to shorten?)
83        yyleng = 0;
84        for ( int i = 0; yytext[i] != '\0'; i += 1 ) {          // copying non-underscore characters to front of string
85                if ( yytext[i] != '_' ) {
86                        yytext[yyleng] = yytext[i];
87                        yyleng += 1;
88                } // if
89        } // for
90        yytext[yyleng] = '\0';
91} // rm_underscore
92
93// Stop warning due to incorrectly generated flex code.
94#pragma GCC diagnostic ignored "-Wsign-compare"
95%}
96
97binary [0-1]
98octal [0-7]
99nonzero [1-9]
100decimal [0-9]
101hex [0-9a-fA-F]
102universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2}))
103
104                                // identifier, GCC: $ in identifier
105identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})*
106
107                                // numeric constants, CFA: '_' in constant
108hex_quad {hex}("_"?{hex}){3}
109size_opt (8|16|32|64|128)?
110                                // CFA: explicit l8/l16/l32/l64/l128, char 'hh', short 'h', int 'n'
111length ("ll"|"LL"|[lL]{size_opt})|("hh"|"HH"|[hHnN])
112                                // CFA: size_t 'z', pointer 'p', which define a sign and length
113integer_suffix_opt ("_"?(([uU]({length}?[iI]?)|([iI]{length}))|([iI]({length}?[uU]?)|([uU]{length}))|({length}([iI]?[uU]?)|([uU][iI]))|[zZ]|[pP]))?
114
115octal_digits ({octal})|({octal}({octal}|"_")*{octal})
116octal_prefix "0""_"?
117octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix_opt}
118
119nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal})
120decimal_constant {nonzero_digits}{integer_suffix_opt}
121
122binary_digits ({binary})|({binary}({binary}|"_")*{binary})
123binary_prefix "0"[bB]"_"?
124binary_constant {binary_prefix}{binary_digits}{integer_suffix_opt}
125
126hex_digits ({hex})|({hex}({hex}|"_")*{hex})
127hex_prefix "0"[xX]"_"?
128hex_constant {hex_prefix}{hex_digits}{integer_suffix_opt}
129
130                                // GCC: floating D (double), imaginary iI, and decimal floating DF, DD, DL
131exponent "_"?[eE]"_"?[+-]?{decimal_digits}
132floating_size 16|32|32x|64|64x|80|128|128x
133floating_length ([fFdDlLwWqQ]|[fF]{floating_size})
134floating_suffix ({floating_length}?[iI]?)|([iI]{floating_length})
135decimal_floating_suffix [dD][fFdDlL]
136floating_suffix_opt ("_"?({floating_suffix}|{decimal_floating_suffix}))?
137decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal})
138floating_decimal {decimal_digits}"."{exponent}?{floating_suffix_opt}
139floating_fraction "."{decimal_digits}{exponent}?{floating_suffix_opt}
140floating_constant ({decimal_digits}{exponent}{floating_suffix_opt})|({decimal_digits}{floating_fraction})
141
142binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
143hex_floating_suffix_opt ("_"?({floating_suffix}))?
144hex_floating_fraction ({hex_digits}?"."{hex_digits})|({hex_digits}".")
145hex_floating_constant {hex_prefix}(({hex_floating_fraction}{binary_exponent})|({hex_digits}{binary_exponent})){hex_floating_suffix_opt}
146
147                                // character escape sequence, GCC: \e => esc character
148simple_escape "\\"[abefnrtv'"?\\]
149                                // ' stop editor highlighting
150octal_escape "\\"{octal}("_"?{octal}){0,2}
151hex_escape "\\""x""_"?{hex_digits}
152escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char}
153cwide_prefix "L"|"U"|"u"
154swide_prefix {cwide_prefix}|"u8"
155
156                                // display/white-space characters
157h_tab [\011]
158form_feed [\014]
159v_tab [\013]
160c_return [\015]
161h_white [ ]|{h_tab}
162
163                                // overloadable operators
164op_unary_only "~"|"!"
165op_unary_binary "+"|"-"|"*"
166op_unary_pre_post "++"|"--"
167op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post}
168
169op_binary_only "/"|"%"|"\\"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"\\="|"&="|"|="|"^="|"<<="|">>="
170op_binary_over {op_unary_binary}|{op_binary_only}
171                                // op_binary_not_over "?"|"->"|"."|"&&"|"||"|"@="
172                                // operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over}
173
174%x COMMENT
175%x BKQUOTE
176%x QUOTE
177%x STRING
178
179%%
180                                /* line directives */
181^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["].*"\n" {
182        /* " stop editor highlighting */
183        static char filename[FILENAME_MAX];                                     // temporarily store current source-file name
184        char *end_num;
185        char *begin_string, *end_string;
186        long lineno, length;
187        lineno = strtol( yytext + 1, &end_num, 0 );
188        begin_string = strchr( end_num, '"' );
189        if ( begin_string ) {                                                           // file name ?
190                end_string = strchr( begin_string + 1, '"' );   // look for ending delimiter
191                assert( end_string );                                                   // closing quote ?
192                length = end_string - begin_string - 1;                 // file-name length without quotes or sentinel
193                assert( length < FILENAME_MAX );                                // room for sentinel ?
194                memcpy( &filename, begin_string + 1, length );  // copy file name from yytext
195                filename[ length ] = '\0';                                              // terminate string with sentinel
196                //cout << "file " << filename << " line " << lineno << endl;
197                yylineno = lineno;
198                yyfilename = filename;
199        } // if
200}
201
202                                /* preprocessor-style directives */
203^{h_white}*"#"[^\n]*"\n" { RETURN_VAL( DIRECTIVE ); }
204
205                                /* ignore C style comments (ALSO HANDLED BY CPP) */
206"/*"                    { BEGIN COMMENT; }
207<COMMENT>.|\n   ;
208<COMMENT>"*/"   { BEGIN 0; }
209
210                                /* ignore C++ style comments (ALSO HANDLED BY CPP) */
211"//"[^\n]*"\n"  ;
212
213                                /* ignore whitespace */
214{h_white}+              { WHITE_RETURN(' '); }
215({v_tab}|{c_return}|{form_feed})+ { WHITE_RETURN(' '); }
216({h_white}|{v_tab}|{c_return}|{form_feed})*"\n" { NEWLINE_RETURN(); }
217
218                                /* keywords */
219alignas                 { KEYWORD_RETURN(ALIGNAS); }                    // CFA
220_Alignas                { KEYWORD_RETURN(ALIGNAS); }                    // C11
221alignof                 { KEYWORD_RETURN(ALIGNOF); }                    // CFA
222_Alignof                { KEYWORD_RETURN(ALIGNOF); }                    // C11
223__alignof               { KEYWORD_RETURN(ALIGNOF); }                    // GCC
224__alignof__             { KEYWORD_RETURN(ALIGNOF); }                    // GCC
225and                             { QKEYWORD_RETURN(WAND); }                              // CFA
226asm                             { KEYWORD_RETURN(ASM); }
227__asm                   { KEYWORD_RETURN(ASM); }                                // GCC
228__asm__                 { KEYWORD_RETURN(ASM); }                                // GCC
229_Atomic                 { KEYWORD_RETURN(ATOMIC); }                             // C11
230__attribute             { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
231__attribute__   { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
232auto                    { KEYWORD_RETURN(AUTO); }
233__auto_type             { KEYWORD_RETURN(AUTO_TYPE); }
234basetypeof              { KEYWORD_RETURN(BASETYPEOF); }                 // CFA
235_Bool                   { KEYWORD_RETURN(BOOL); }                               // C99
236break                   { KEYWORD_RETURN(BREAK); }
237case                    { KEYWORD_RETURN(CASE); }
238catch                   { QKEYWORD_RETURN(CATCH); }                             // CFA
239catchResume             { QKEYWORD_RETURN(CATCHRESUME); }               // CFA
240char                    { KEYWORD_RETURN(CHAR); }
241choose                  { KEYWORD_RETURN(CHOOSE); }                             // CFA
242coerce                  { KEYWORD_RETURN(COERCE); }                             // CFA
243corun                   { KEYWORD_RETURN(CORUN); }                              // CFA
244cofor                   { KEYWORD_RETURN(COFOR); }                              // CFA
245_Complex                { KEYWORD_RETURN(COMPLEX); }                    // C99
246__complex               { KEYWORD_RETURN(COMPLEX); }                    // GCC
247__complex__             { KEYWORD_RETURN(COMPLEX); }                    // GCC
248const                   { KEYWORD_RETURN(CONST); }
249__const                 { KEYWORD_RETURN(CONST); }                              // GCC
250__const__               { KEYWORD_RETURN(CONST); }                              // GCC
251continue                { KEYWORD_RETURN(CONTINUE); }
252coroutine               { KEYWORD_RETURN(COROUTINE); }                  // CFA
253_Decimal32              { KEYWORD_RETURN(DECIMAL32); }                  // GCC
254_Decimal64              { KEYWORD_RETURN(DECIMAL64); }                  // GCC
255_Decimal128             { KEYWORD_RETURN(DECIMAL128); }                 // GCC
256default                 { KEYWORD_RETURN(DEFAULT); }
257disable                 { KEYWORD_RETURN(DISABLE); }                    // CFA
258do                              { KEYWORD_RETURN(DO); }
259double                  { KEYWORD_RETURN(DOUBLE); }
260dtype                   { KEYWORD_RETURN(DTYPE); }                              // CFA
261else                    { KEYWORD_RETURN(ELSE); }
262enable                  { KEYWORD_RETURN(ENABLE); }                             // CFA
263enum                    { KEYWORD_RETURN(ENUM); }
264exception               { KEYWORD_RETURN(EXCEPTION); }                  // CFA
265__extension__   { KEYWORD_RETURN(EXTENSION); }                  // GCC
266extern                  { KEYWORD_RETURN(EXTERN); }
267fallthrough             { KEYWORD_RETURN(FALLTHROUGH); }                // CFA
268fallthru                { KEYWORD_RETURN(FALLTHRU); }                   // CFA
269finally                 { QKEYWORD_RETURN(FINALLY); }                   // CFA
270fixup                   { QKEYWORD_RETURN(FIXUP); }                             // CFA
271float                   { KEYWORD_RETURN(FLOAT); }
272__float80               { KEYWORD_RETURN(uuFLOAT80); }                  // GCC
273float80                 { KEYWORD_RETURN(uuFLOAT80); }                  // GCC
274__float128              { KEYWORD_RETURN(uuFLOAT128); }                 // GCC
275float128                { KEYWORD_RETURN(uuFLOAT128); }                 // GCC
276_Float16                { FLOATXX(uFLOAT16); }                                  // GCC
277_Float32                { FLOATXX(uFLOAT32); }                                  // GCC
278_Float32x               { FLOATXX(uFLOAT32X); }                                 // GCC
279_Float64                { FLOATXX(uFLOAT64); }                                  // GCC
280_Float64x               { FLOATXX(uFLOAT64X); }                                 // GCC
281_Float128               { FLOATXX(uFLOAT128); }                                 // GCC
282_Float128x              { FLOATXX(uFLOAT128); }                                 // GCC
283for                             { KEYWORD_RETURN(FOR); }
284forall                  { KEYWORD_RETURN(FORALL); }                             // CFA
285fortran                 { KEYWORD_RETURN(FORTRAN); }
286ftype                   { KEYWORD_RETURN(FTYPE); }                              // CFA
287generator               { KEYWORD_RETURN(GENERATOR); }                  // CFA
288_Generic                { KEYWORD_RETURN(GENERIC); }                    // C11
289goto                    { KEYWORD_RETURN(GOTO); }
290if                              { KEYWORD_RETURN(IF); }
291_Imaginary              { KEYWORD_RETURN(IMAGINARY); }                  // C99
292__imag                  { KEYWORD_RETURN(IMAGINARY); }                  // GCC
293__imag__                { KEYWORD_RETURN(IMAGINARY); }                  // GCC
294inline                  { KEYWORD_RETURN(INLINE); }                             // C99
295__inline                { KEYWORD_RETURN(INLINE); }                             // GCC
296__inline__              { KEYWORD_RETURN(INLINE); }                             // GCC
297int                             { KEYWORD_RETURN(INT); }
298int128                  { KEYWORD_RETURN(INT128); }                             // CFA
299__int128                { KEYWORD_RETURN(INT128); }                             // GCC
300__int128_t              { KEYWORD_RETURN(INT128); }                             // GCC
301__label__               { KEYWORD_RETURN(LABEL); }                              // GCC
302long                    { KEYWORD_RETURN(LONG); }
303monitor                 { KEYWORD_RETURN(MONITOR); }                    // CFA
304mutex                   { KEYWORD_RETURN(MUTEX); }                              // CFA
305_Noreturn               { KEYWORD_RETURN(NORETURN); }                   // C11
306__builtin_offsetof { KEYWORD_RETURN(OFFSETOF); }                // GCC
307one_t                   { NUMERIC_RETURN(ONE_T); }                              // CFA
308or                              { QKEYWORD_RETURN(WOR); }                               // CFA
309otype                   { KEYWORD_RETURN(OTYPE); }                              // CFA
310recover                 { QKEYWORD_RETURN(RECOVER); }                   // CFA
311register                { KEYWORD_RETURN(REGISTER); }
312report                  { KEYWORD_RETURN(THROWRESUME); }                // CFA
313restrict                { KEYWORD_RETURN(RESTRICT); }                   // C99
314__restrict              { KEYWORD_RETURN(RESTRICT); }                   // GCC
315__restrict__    { KEYWORD_RETURN(RESTRICT); }                   // GCC
316return                  { KEYWORD_RETURN(RETURN); }
317 /* resume                      { KEYWORD_RETURN(RESUME); }                             // CFA */
318short                   { KEYWORD_RETURN(SHORT); }
319signed                  { KEYWORD_RETURN(SIGNED); }
320__signed                { KEYWORD_RETURN(SIGNED); }                             // GCC
321__signed__              { KEYWORD_RETURN(SIGNED); }                             // GCC
322sizeof                  { KEYWORD_RETURN(SIZEOF); }
323static                  { KEYWORD_RETURN(STATIC); }
324_Static_assert  { KEYWORD_RETURN(STATICASSERT); }               // C11
325static_assert   { KEYWORD_RETURN(STATICASSERT); }               // C23
326struct                  { KEYWORD_RETURN(STRUCT); }
327suspend                 { KEYWORD_RETURN(SUSPEND); }                    // CFA
328switch                  { KEYWORD_RETURN(SWITCH); }
329thread                  { KEYWORD_RETURN(THREAD); }                             // C11
330__thread                { KEYWORD_RETURN(THREADLOCALGCC); }             // GCC
331_Thread_local   { KEYWORD_RETURN(THREADLOCALC11); }             // C11
332thread_local    { KEYWORD_RETURN(THREADLOCALC11); }             // C23
333throw                   { KEYWORD_RETURN(THROW); }                              // CFA
334throwResume             { KEYWORD_RETURN(THROWRESUME); }                // CFA
335timeout                 { QKEYWORD_RETURN(TIMEOUT); }                   // CFA
336trait                   { KEYWORD_RETURN(TRAIT); }                              // CFA
337try                             { KEYWORD_RETURN(TRY); }                                // CFA
338ttype                   { KEYWORD_RETURN(TTYPE); }                              // CFA
339typedef                 { KEYWORD_RETURN(TYPEDEF); }
340typeof                  { KEYWORD_RETURN(TYPEOF); }                             // GCC
341__typeof                { KEYWORD_RETURN(TYPEOF); }                             // GCC
342__typeof__              { KEYWORD_RETURN(TYPEOF); }                             // GCC
343typeid                  { KEYWORD_RETURN(TYPEID); }                             // GCC
344union                   { KEYWORD_RETURN(UNION); }
345__uint128_t             { KEYWORD_RETURN(UINT128); }                    // GCC
346unsigned                { KEYWORD_RETURN(UNSIGNED); }
347__builtin_va_arg { KEYWORD_RETURN(VA_ARG); }                    // GCC
348__builtin_va_list { KEYWORD_RETURN(VA_LIST); }                  // GCC
349virtual                 { KEYWORD_RETURN(VIRTUAL); }                    // CFA
350void                    { KEYWORD_RETURN(VOID); }
351volatile                { KEYWORD_RETURN(VOLATILE); }
352__volatile              { KEYWORD_RETURN(VOLATILE); }                   // GCC
353__volatile__    { KEYWORD_RETURN(VOLATILE); }                   // GCC
354vtable                  { KEYWORD_RETURN(VTABLE); }                             // CFA
355waitfor                 { KEYWORD_RETURN(WAITFOR); }                    // CFA
356waituntil               { KEYWORD_RETURN(WAITUNTIL); }                  // CFA
357when                    { KEYWORD_RETURN(WHEN); }                               // CFA
358while                   { KEYWORD_RETURN(WHILE); }
359with                    { KEYWORD_RETURN(WITH); }                               // CFA
360zero_t                  { NUMERIC_RETURN(ZERO_T); }                             // CFA
361
362                                /* identifier */
363{identifier}    { IDENTIFIER_RETURN(); }
364"``"{identifier} {                                                                              // CFA
365        yytext[yyleng] = '\0'; yytext += 2;                                     // SKULLDUGGERY: remove backquotes (ok to shorten?)
366        IDENTIFIER_RETURN();
367}
368
369                                /* numeric constants */
370{binary_constant} { NUMERIC_RETURN(INTEGERconstant); }
371{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
372{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
373{hex_constant}  { NUMERIC_RETURN(INTEGERconstant); }
374{floating_decimal}      { NUMERIC_RETURN(FLOATING_DECIMALconstant); } // must appear before floating_constant
375{floating_fraction}     { NUMERIC_RETURN(FLOATING_FRACTIONconstant); } // must appear before floating_constant
376{floating_constant}     { NUMERIC_RETURN(FLOATINGconstant); }
377{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
378
379                                /* character constant, allows empty value */
380({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new string( yytext, yyleng ); }
381<QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); }
382<QUOTE>['\n]    { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); }
383                                /* ' stop editor highlighting */
384
385                                /* string constant */
386({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new string( yytext, yyleng ); }
387<STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); }
388<STRING>["\n]   { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); }
389                                /* " stop editor highlighting */
390
391                                /* common character/string constant */
392<QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); }
393<QUOTE,STRING>"\\"{h_white}*"\n" {}                                             // continuation (ALSO HANDLED BY CPP)
394<QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character
395
396                                /* punctuation */
397"@"                             { ASCIIOP_RETURN(); }
398"`"                             { ASCIIOP_RETURN(); }
399"["                             { ASCIIOP_RETURN(); }
400"]"                             { ASCIIOP_RETURN(); }
401"("                             { ASCIIOP_RETURN(); }
402")"                             { ASCIIOP_RETURN(); }
403"{"                             { ASCIIOP_RETURN(); }
404"}"                             { ASCIIOP_RETURN(); }
405","                             { ASCIIOP_RETURN(); }                                   // also operator
406":"                             { ASCIIOP_RETURN(); }
407";"                             { ASCIIOP_RETURN(); }
408"."                             { ASCIIOP_RETURN(); }                                   // also operator
409"@@"                    { NAMEDOP_RETURN(ATTR); }                               // CFA, attribute shorthand
410"..."                   { NAMEDOP_RETURN(ELLIPSIS); }
411
412                                /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
413"<:"                    { RETURN_VAL('['); }
414":>"                    { RETURN_VAL(']'); }
415"<%"                    { RETURN_VAL('{'); }
416"%>"                    { RETURN_VAL('}'); }
417
418                                /* operators */
419"!"                             { ASCIIOP_RETURN(); }
420"+"                             { ASCIIOP_RETURN(); }
421"-"                             { ASCIIOP_RETURN(); }
422"*"                             { ASCIIOP_RETURN(); }
423"\\"                    { ASCIIOP_RETURN(); }                                   // CFA, exponentiation
424"/"                             { ASCIIOP_RETURN(); }
425"%"                             { ASCIIOP_RETURN(); }
426"^"                             { ASCIIOP_RETURN(); }
427"~"                             { ASCIIOP_RETURN(); }
428"&"                             { ASCIIOP_RETURN(); }
429"|"                             { ASCIIOP_RETURN(); }
430"<"                             { ASCIIOP_RETURN(); }
431">"                             { ASCIIOP_RETURN(); }
432"="                             { ASCIIOP_RETURN(); }
433"?"                             { ASCIIOP_RETURN(); }
434
435"++"                    { NAMEDOP_RETURN(ICR); }
436"--"                    { NAMEDOP_RETURN(DECR); }
437"=="                    { NAMEDOP_RETURN(EQ); }
438"!="                    { NAMEDOP_RETURN(NE); }
439"<<"                    { NAMEDOP_RETURN(LS); }
440">>"                    { NAMEDOP_RETURN(RS); }
441"<="                    { NAMEDOP_RETURN(LE); }
442">="                    { NAMEDOP_RETURN(GE); }
443"&&"                    { NAMEDOP_RETURN(ANDAND); }
444"||"                    { NAMEDOP_RETURN(OROR); }
445"->"                    { NAMEDOP_RETURN(ARROW); }
446"+="                    { NAMEDOP_RETURN(PLUSassign); }
447"-="                    { NAMEDOP_RETURN(MINUSassign); }
448"\\="                   { NAMEDOP_RETURN(EXPassign); }                  // CFA, exponentiation
449"*="                    { NAMEDOP_RETURN(MULTassign); }
450"/="                    { NAMEDOP_RETURN(DIVassign); }
451"%="                    { NAMEDOP_RETURN(MODassign); }
452"&="                    { NAMEDOP_RETURN(ANDassign); }
453"|="                    { NAMEDOP_RETURN(ORassign); }
454"^="                    { NAMEDOP_RETURN(ERassign); }
455"<<="                   { NAMEDOP_RETURN(LSassign); }
456">>="                   { NAMEDOP_RETURN(RSassign); }
457
458"@="                    { NAMEDOP_RETURN(ATassign); }                   // CFA
459"~="                    { NAMEDOP_RETURN(ErangeUpEq); }                 // CFA
460"-~"                    { NAMEDOP_RETURN(ErangeDown); }                 // CFA
461"-~="                   { NAMEDOP_RETURN(ErangeDownEq); }               // CFA
462
463                                /* CFA, operator identifier */
464{op_unary}"?"   { IDENTIFIER_RETURN(); }                                // unary
465"?"({op_unary_pre_post}|"()"|"[?]"|"{}") { IDENTIFIER_RETURN(); }
466"^?{}"                  { IDENTIFIER_RETURN(); }
467"?`"{identifier} {                                                                              // postfix operator
468        yylval.tok.str = new string( &yytext[2] );                      // remove ?`
469        yylval.tok.str = build_postfix_name( yylval.tok.str ); // add prefix
470        RETURN_LOCN( typedefTable.isKind( *yylval.tok.str ) );
471}
472"?"{op_binary_over}"?"  { IDENTIFIER_RETURN(); }                // binary
473        /*
474          This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the string "*?*?"  can be
475          lexed as "*?"/"*?" or "*"/"?*?". Since it is common practise to put a unary operator juxtaposed to an identifier,
476          e.g., "*i", users will be annoyed if they cannot do this with respect to operator identifiers. Therefore, there is
477          a lexical look-ahead for the second case, with backtracking to return the leading unary operator and then
478          reparsing the trailing operator identifier.  Otherwise a space is needed between the unary operator and operator
479          identifier to disambiguate this common case.
480
481          A similar issue occurs with the dereference, *?(...), and routine-call, ?()(...) identifiers.  The ambiguity
482          occurs when the deference operator has no parameters, *?() and *?()(...), requiring arbitrary whitespace
483          look-ahead for the routine-call parameter-list to disambiguate.  However, the dereference operator must have a
484          parameter/argument to dereference *?(...).  Hence, always interpreting the string *?() as * ?() does not preclude
485          any meaningful program.
486
487          The remaining cases are with the increment/decrement operators and conditional expression:
488
489          i++? ...(...);
490          i?++ ...(...);
491
492          requiring arbitrary whitespace look-ahead for the operator parameter-list, even though that interpretation is an
493      incorrect expression (juxtaposed identifiers).  Therefore, it is necessary to disambiguate these cases with a
494      space:
495
496          i++ ? i : 0;
497          i? ++i : 0;
498        */
499{op_unary}"?"({op_unary_pre_post}|"()"|"[?]"|{op_binary_over}"?") {
500        // 1 or 2 character unary operator ?
501        int i = yytext[1] == '?' ? 1 : 2;
502        yyless( i );            // put back characters up to first '?'
503        if ( i > 1 ) {
504                NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
505        } else {
506                ASCIIOP_RETURN();
507        } // if
508}
509
510                                /* unknown character */
511.                               { yyerror( "unknown character" ); }
512
513%%
514
515// ----end of lexer----
516
517void yyerror( const char * errmsg ) {
518        SemanticErrorThrow = true;
519        cerr << (yyfilename ? yyfilename : "*unknown file*") << ':' << yylineno << ':' << column - yyleng + 1
520                 << ": " << ErrorHelpers::error_str() << errmsg << " before token \"" << (yytext[0] == '\0' ? "EOF" : yytext) << '"' << endl;
521}
522
523// Local Variables: //
524// mode: c++ //
525// tab-width: 4 //
526// compile-command: "make install" //
527// End: //
Note: See TracBrowser for help on using the repository browser.