source: src/Parser/lex.ll @ ded6c2a6

ast-experimental
Last change on this file since ded6c2a6 was 8c25760, checked in by Peter A. Buhr <pabuhr@…>, 19 months ago

put keywords in alphabetic order in lex.ll
  • Property mode set to 100644
File size: 20.7 KB
Line 
1/*
2 * Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3 *
4 * The contents of this file are covered under the licence agreement in the
5 * file "LICENCE" distributed with Cforall.
6 *
7 * lex.ll --
8 *
9 * Author           : Peter A. Buhr
10 * Created On       : Sat Sep 22 08:58:10 2001
11 * Last Modified By : Peter A. Buhr
12 * Last Modified On : Tue May  2 08:45:21 2023
13 * Update Count     : 769
14 */
15
16%option yylineno
17%option noyywrap
18%option nounput
19
20%{
21// The lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
22// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
23// line-number directives) and C/C++ style comments, which are ignored.
24
25// *************************** Includes and Defines ****************************
26
27#ifdef __clang__
28#pragma GCC diagnostic ignored "-Wnull-conversion"
29#endif
30
31// trigger before each matching rule's action
32#define YY_USER_ACTION \
33        yylloc.first_line = yylineno; \
34        yylloc.first_column = column; \
35        column += yyleng; \
36        yylloc.last_column = column; \
37        yylloc.last_line = yylineno; \
38        yylloc.filename = yyfilename ? yyfilename : "";
39unsigned int column = 0;                                                                // position of the end of the last token parsed
40
41#include <string>
42#include <cstdio>                                                                               // FILENAME_MAX
43using namespace std;
44
45#include "config.h"                                                                             // configure info
46#include "DeclarationNode.h"                            // for DeclarationNode
47#include "ExpressionNode.h"                             // for LabelNode
48#include "InitializerNode.h"                            // for InitializerNode
49#include "ParseNode.h"
50#include "ParserTypes.h"                                // for Token
51#include "StatementNode.h"                              // for CondCtl, ForCtrl
52#include "TypedefTable.h"
53// This (generated) header must come late as it is missing includes.
54#include "parser.hh"                                    // generated info
55
56string * build_postfix_name( string * name );
57
58char *yyfilename;
59string *strtext;                                                                                // accumulate parts of character and string constant value
60
61#define RETURN_LOCN(x)          yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
62#define RETURN_VAL(x)           yylval.tok.str = new string( yytext ); RETURN_LOCN( x )
63#define RETURN_CHAR(x)          yylval.tok.str = nullptr; RETURN_LOCN( x )
64#define RETURN_STR(x)           yylval.tok.str = strtext; RETURN_LOCN( x )
65
66#define WHITE_RETURN(x)         // do nothing
67#define NEWLINE_RETURN()        column = 0; WHITE_RETURN( '\n' )
68#define ASCIIOP_RETURN()        RETURN_CHAR( (int)yytext[0] ) // single character operator
69#define NAMEDOP_RETURN(x)       RETURN_CHAR( x )                        // multichar operator, with a name
70#define NUMERIC_RETURN(x)       rm_underscore(); RETURN_VAL( x ) // numeric constant
71#define KEYWORD_RETURN(x)       RETURN_CHAR( x )                        // keyword
72#define QKEYWORD_RETURN(x)      RETURN_VAL(x);                          // quasi-keyword
73#define IDENTIFIER_RETURN()     RETURN_VAL( typedefTable.isKind( yytext ) )
74
75#ifdef HAVE_KEYWORDS_FLOATXX                                                    // GCC >= 7 => keyword, otherwise typedef
76#define FLOATXX(v) KEYWORD_RETURN(v);
77#else
78#define FLOATXX(v) IDENTIFIER_RETURN();
79#endif // HAVE_KEYWORDS_FLOATXX
80
81void rm_underscore() {
82        // SKULLDUGGERY: remove underscores (ok to shorten?)
83        yyleng = 0;
84        for ( int i = 0; yytext[i] != '\0'; i += 1 ) {          // copying non-underscore characters to front of string
85                if ( yytext[i] != '_' ) {
86                        yytext[yyleng] = yytext[i];
87                        yyleng += 1;
88                } // if
89        } // for
90        yytext[yyleng] = '\0';
91} // rm_underscore
92
93// Stop warning due to incorrectly generated flex code.
94#pragma GCC diagnostic ignored "-Wsign-compare"
95%}
96
97binary [0-1]
98octal [0-7]
99nonzero [1-9]
100decimal [0-9]
101hex [0-9a-fA-F]
102universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2}))
103
104                                // identifier, GCC: $ in identifier
105identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})*
106
107                                // numeric constants, CFA: '_' in constant
108hex_quad {hex}("_"?{hex}){3}
109size_opt (8|16|32|64|128)?
110                                // CFA: explicit l8/l16/l32/l64/l128, char 'hh', short 'h', int 'n'
111length ("ll"|"LL"|[lL]{size_opt})|("hh"|"HH"|[hHnN])
112                                // CFA: size_t 'z', pointer 'p', which define a sign and length
113integer_suffix_opt ("_"?(([uU]({length}?[iI]?)|([iI]{length}))|([iI]({length}?[uU]?)|([uU]{length}))|({length}([iI]?[uU]?)|([uU][iI]))|[zZ]|[pP]))?
114
115octal_digits ({octal})|({octal}({octal}|"_")*{octal})
116octal_prefix "0""_"?
117octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix_opt}
118
119nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal})
120decimal_constant {nonzero_digits}{integer_suffix_opt}
121
122binary_digits ({binary})|({binary}({binary}|"_")*{binary})
123binary_prefix "0"[bB]"_"?
124binary_constant {binary_prefix}{binary_digits}{integer_suffix_opt}
125
126hex_digits ({hex})|({hex}({hex}|"_")*{hex})
127hex_prefix "0"[xX]"_"?
128hex_constant {hex_prefix}{hex_digits}{integer_suffix_opt}
129
130                                // GCC: floating D (double), imaginary iI, and decimal floating DF, DD, DL
131exponent "_"?[eE]"_"?[+-]?{decimal_digits}
132floating_size 16|32|32x|64|64x|80|128|128x
133floating_length ([fFdDlLwWqQ]|[fF]{floating_size})
134floating_suffix ({floating_length}?[iI]?)|([iI]{floating_length})
135decimal_floating_suffix [dD][fFdDlL]
136floating_suffix_opt ("_"?({floating_suffix}|{decimal_floating_suffix}))?
137decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal})
138floating_decimal {decimal_digits}"."{exponent}?{floating_suffix_opt}
139floating_fraction "."{decimal_digits}{exponent}?{floating_suffix_opt}
140floating_constant ({decimal_digits}{exponent}{floating_suffix_opt})|({decimal_digits}{floating_fraction})
141
142binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
143hex_floating_suffix_opt ("_"?({floating_suffix}))?
144hex_floating_fraction ({hex_digits}?"."{hex_digits})|({hex_digits}".")
145hex_floating_constant {hex_prefix}(({hex_floating_fraction}{binary_exponent})|({hex_digits}{binary_exponent})){hex_floating_suffix_opt}
146
147                                // character escape sequence, GCC: \e => esc character
148simple_escape "\\"[abefnrtv'"?\\]
149                                // ' stop editor highlighting
150octal_escape "\\"{octal}("_"?{octal}){0,2}
151hex_escape "\\""x""_"?{hex_digits}
152escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char}
153cwide_prefix "L"|"U"|"u"
154swide_prefix {cwide_prefix}|"u8"
155
156                                // display/white-space characters
157h_tab [\011]
158form_feed [\014]
159v_tab [\013]
160c_return [\015]
161h_white [ ]|{h_tab}
162
163                                // overloadable operators
164op_unary_only "~"|"!"
165op_unary_binary "+"|"-"|"*"
166op_unary_pre_post "++"|"--"
167op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post}
168
169op_binary_only "/"|"%"|"\\"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"\\="|"&="|"|="|"^="|"<<="|">>="
170op_binary_over {op_unary_binary}|{op_binary_only}
171                                // op_binary_not_over "?"|"->"|"."|"&&"|"||"|"@="
172                                // operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over}
173
174%x COMMENT
175%x BKQUOTE
176%x QUOTE
177%x STRING
178
179%%
180                                /* line directives */
181^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["].*"\n" {
182        /* " stop editor highlighting */
183        static char filename[FILENAME_MAX];                                     // temporarily store current source-file name
184        char *end_num;
185        char *begin_string, *end_string;
186        long lineno, length;
187        lineno = strtol( yytext + 1, &end_num, 0 );
188        begin_string = strchr( end_num, '"' );
189        if ( begin_string ) {                                                           // file name ?
190                end_string = strchr( begin_string + 1, '"' );   // look for ending delimiter
191                assert( end_string );                                                   // closing quote ?
192                length = end_string - begin_string - 1;                 // file-name length without quotes or sentinel
193                assert( length < FILENAME_MAX );                                // room for sentinel ?
194                memcpy( &filename, begin_string + 1, length );  // copy file name from yytext
195                filename[ length ] = '\0';                                              // terminate string with sentinel
196                //cout << "file " << filename << " line " << lineno << endl;
197                yylineno = lineno;
198                yyfilename = filename;
199        } // if
200}
201
202                                /* preprocessor-style directives */
203^{h_white}*"#"[^\n]*"\n" { RETURN_VAL( DIRECTIVE ); }
204
205                                /* ignore C style comments (ALSO HANDLED BY CPP) */
206"/*"                    { BEGIN COMMENT; }
207<COMMENT>.|\n   ;
208<COMMENT>"*/"   { BEGIN 0; }
209
210                                /* ignore C++ style comments (ALSO HANDLED BY CPP) */
211"//"[^\n]*"\n"  ;
212
213                                /* ignore whitespace */
214{h_white}+              { WHITE_RETURN(' '); }
215({v_tab}|{c_return}|{form_feed})+ { WHITE_RETURN(' '); }
216({h_white}|{v_tab}|{c_return}|{form_feed})*"\n" { NEWLINE_RETURN(); }
217
218                                /* keywords */
219_Alignas                { KEYWORD_RETURN(ALIGNAS); }                    // C11
220_Alignof                { KEYWORD_RETURN(ALIGNOF); }                    // C11
221__alignof               { KEYWORD_RETURN(ALIGNOF); }                    // GCC
222__alignof__             { KEYWORD_RETURN(ALIGNOF); }                    // GCC
223and                             { QKEYWORD_RETURN(WAND); }                              // CFA
224asm                             { KEYWORD_RETURN(ASM); }
225__asm                   { KEYWORD_RETURN(ASM); }                                // GCC
226__asm__                 { KEYWORD_RETURN(ASM); }                                // GCC
227_Atomic                 { KEYWORD_RETURN(ATOMIC); }                             // C11
228__attribute             { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
229__attribute__   { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
230auto                    { KEYWORD_RETURN(AUTO); }
231__auto_type             { KEYWORD_RETURN(AUTO_TYPE); }
232basetypeof              { KEYWORD_RETURN(BASETYPEOF); }                 // CFA
233_Bool                   { KEYWORD_RETURN(BOOL); }                               // C99
234break                   { KEYWORD_RETURN(BREAK); }
235case                    { KEYWORD_RETURN(CASE); }
236catch                   { QKEYWORD_RETURN(CATCH); }                             // CFA
237catchResume             { QKEYWORD_RETURN(CATCHRESUME); }               // CFA
238char                    { KEYWORD_RETURN(CHAR); }
239choose                  { KEYWORD_RETURN(CHOOSE); }                             // CFA
240coerce                  { KEYWORD_RETURN(COERCE); }                             // CFA
241_Complex                { KEYWORD_RETURN(COMPLEX); }                    // C99
242__complex               { KEYWORD_RETURN(COMPLEX); }                    // GCC
243__complex__             { KEYWORD_RETURN(COMPLEX); }                    // GCC
244const                   { KEYWORD_RETURN(CONST); }
245__const                 { KEYWORD_RETURN(CONST); }                              // GCC
246__const__               { KEYWORD_RETURN(CONST); }                              // GCC
247continue                { KEYWORD_RETURN(CONTINUE); }
248coroutine               { KEYWORD_RETURN(COROUTINE); }                  // CFA
249_Decimal32              { KEYWORD_RETURN(DECIMAL32); }                  // GCC
250_Decimal64              { KEYWORD_RETURN(DECIMAL64); }                  // GCC
251_Decimal128             { KEYWORD_RETURN(DECIMAL128); }                 // GCC
252default                 { KEYWORD_RETURN(DEFAULT); }
253disable                 { KEYWORD_RETURN(DISABLE); }                    // CFA
254do                              { KEYWORD_RETURN(DO); }
255double                  { KEYWORD_RETURN(DOUBLE); }
256dtype                   { KEYWORD_RETURN(DTYPE); }                              // CFA
257else                    { KEYWORD_RETURN(ELSE); }
258enable                  { KEYWORD_RETURN(ENABLE); }                             // CFA
259enum                    { KEYWORD_RETURN(ENUM); }
260exception               { KEYWORD_RETURN(EXCEPTION); }                  // CFA
261__extension__   { KEYWORD_RETURN(EXTENSION); }                  // GCC
262extern                  { KEYWORD_RETURN(EXTERN); }
263fallthrough             { KEYWORD_RETURN(FALLTHROUGH); }                // CFA
264fallthru                { KEYWORD_RETURN(FALLTHRU); }                   // CFA
265finally                 { QKEYWORD_RETURN(FINALLY); }                   // CFA
266fixup                   { QKEYWORD_RETURN(FIXUP); }                             // CFA
267float                   { KEYWORD_RETURN(FLOAT); }
268__float80               { KEYWORD_RETURN(uuFLOAT80); }                  // GCC
269float80                 { KEYWORD_RETURN(uuFLOAT80); }                  // GCC
270__float128              { KEYWORD_RETURN(uuFLOAT128); }                 // GCC
271float128                { KEYWORD_RETURN(uuFLOAT128); }                 // GCC
272_Float16                { FLOATXX(uFLOAT16); }                                  // GCC
273_Float32                { FLOATXX(uFLOAT32); }                                  // GCC
274_Float32x               { FLOATXX(uFLOAT32X); }                                 // GCC
275_Float64                { FLOATXX(uFLOAT64); }                                  // GCC
276_Float64x               { FLOATXX(uFLOAT64X); }                                 // GCC
277_Float128               { FLOATXX(uFLOAT128); }                                 // GCC
278_Float128x              { FLOATXX(uFLOAT128); }                                 // GCC
279for                             { KEYWORD_RETURN(FOR); }
280forall                  { KEYWORD_RETURN(FORALL); }                             // CFA
281fortran                 { KEYWORD_RETURN(FORTRAN); }
282ftype                   { KEYWORD_RETURN(FTYPE); }                              // CFA
283generator               { KEYWORD_RETURN(GENERATOR); }                  // CFA
284_Generic                { KEYWORD_RETURN(GENERIC); }                    // C11
285goto                    { KEYWORD_RETURN(GOTO); }
286if                              { KEYWORD_RETURN(IF); }
287_Imaginary              { KEYWORD_RETURN(IMAGINARY); }                  // C99
288__imag                  { KEYWORD_RETURN(IMAGINARY); }                  // GCC
289__imag__                { KEYWORD_RETURN(IMAGINARY); }                  // GCC
290inline                  { KEYWORD_RETURN(INLINE); }                             // C99
291__inline                { KEYWORD_RETURN(INLINE); }                             // GCC
292__inline__              { KEYWORD_RETURN(INLINE); }                             // GCC
293int                             { KEYWORD_RETURN(INT); }
294int128                  { KEYWORD_RETURN(INT128); }                             // CFA
295__int128                { KEYWORD_RETURN(INT128); }                             // GCC
296__int128_t              { KEYWORD_RETURN(INT128); }                             // GCC
297__label__               { KEYWORD_RETURN(LABEL); }                              // GCC
298long                    { KEYWORD_RETURN(LONG); }
299monitor                 { KEYWORD_RETURN(MONITOR); }                    // CFA
300mutex                   { KEYWORD_RETURN(MUTEX); }                              // CFA
301_Noreturn               { KEYWORD_RETURN(NORETURN); }                   // C11
302__builtin_offsetof { KEYWORD_RETURN(OFFSETOF); }                // GCC
303one_t                   { NUMERIC_RETURN(ONE_T); }                              // CFA
304or                              { QKEYWORD_RETURN(WOR); }                               // CFA
305otype                   { KEYWORD_RETURN(OTYPE); }                              // CFA
306recover                 { QKEYWORD_RETURN(RECOVER); }                   // CFA
307register                { KEYWORD_RETURN(REGISTER); }
308report                  { KEYWORD_RETURN(THROWRESUME); }                // CFA
309restrict                { KEYWORD_RETURN(RESTRICT); }                   // C99
310__restrict              { KEYWORD_RETURN(RESTRICT); }                   // GCC
311__restrict__    { KEYWORD_RETURN(RESTRICT); }                   // GCC
312return                  { KEYWORD_RETURN(RETURN); }
313 /* resume                      { KEYWORD_RETURN(RESUME); }                             // CFA */
314short                   { KEYWORD_RETURN(SHORT); }
315signed                  { KEYWORD_RETURN(SIGNED); }
316__signed                { KEYWORD_RETURN(SIGNED); }                             // GCC
317__signed__              { KEYWORD_RETURN(SIGNED); }                             // GCC
318sizeof                  { KEYWORD_RETURN(SIZEOF); }
319static                  { KEYWORD_RETURN(STATIC); }
320_Static_assert  { KEYWORD_RETURN(STATICASSERT); }               // C11
321struct                  { KEYWORD_RETURN(STRUCT); }
322suspend                 { KEYWORD_RETURN(SUSPEND); }                    // CFA
323switch                  { KEYWORD_RETURN(SWITCH); }
324thread                  { KEYWORD_RETURN(THREAD); }                             // C11
325__thread                { KEYWORD_RETURN(THREADLOCALGCC); }             // GCC
326_Thread_local   { KEYWORD_RETURN(THREADLOCALC11); }             // C11
327throw                   { KEYWORD_RETURN(THROW); }                              // CFA
328throwResume             { KEYWORD_RETURN(THROWRESUME); }                // CFA
329timeout                 { QKEYWORD_RETURN(TIMEOUT); }                   // CFA
330trait                   { KEYWORD_RETURN(TRAIT); }                              // CFA
331try                             { KEYWORD_RETURN(TRY); }                                // CFA
332ttype                   { KEYWORD_RETURN(TTYPE); }                              // CFA
333typedef                 { KEYWORD_RETURN(TYPEDEF); }
334typeof                  { KEYWORD_RETURN(TYPEOF); }                             // GCC
335__typeof                { KEYWORD_RETURN(TYPEOF); }                             // GCC
336__typeof__              { KEYWORD_RETURN(TYPEOF); }                             // GCC
337typeid                  { KEYWORD_RETURN(TYPEID); }                             // GCC
338union                   { KEYWORD_RETURN(UNION); }
339__uint128_t             { KEYWORD_RETURN(UINT128); }                    // GCC
340unsigned                { KEYWORD_RETURN(UNSIGNED); }
341__builtin_va_arg { KEYWORD_RETURN(VA_ARG); }                    // GCC
342__builtin_va_list { KEYWORD_RETURN(VA_LIST); }                  // GCC
343virtual                 { KEYWORD_RETURN(VIRTUAL); }                    // CFA
344void                    { KEYWORD_RETURN(VOID); }
345volatile                { KEYWORD_RETURN(VOLATILE); }
346__volatile              { KEYWORD_RETURN(VOLATILE); }                   // GCC
347__volatile__    { KEYWORD_RETURN(VOLATILE); }                   // GCC
348vtable                  { KEYWORD_RETURN(VTABLE); }                             // CFA
349waitfor                 { KEYWORD_RETURN(WAITFOR); }                    // CFA
350waituntil               { KEYWORD_RETURN(WAITUNTIL); }                  // CFA
351when                    { KEYWORD_RETURN(WHEN); }                               // CFA
352while                   { KEYWORD_RETURN(WHILE); }
353with                    { KEYWORD_RETURN(WITH); }                               // CFA
354zero_t                  { NUMERIC_RETURN(ZERO_T); }                             // CFA
355
356                                /* identifier */
357{identifier}    { IDENTIFIER_RETURN(); }
358"``"{identifier} {                                                                              // CFA
359        yytext[yyleng] = '\0'; yytext += 2;                                     // SKULLDUGGERY: remove backquotes (ok to shorten?)
360        IDENTIFIER_RETURN();
361}
362
363                                /* numeric constants */
364{binary_constant} { NUMERIC_RETURN(INTEGERconstant); }
365{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
366{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
367{hex_constant}  { NUMERIC_RETURN(INTEGERconstant); }
368{floating_decimal}      { NUMERIC_RETURN(FLOATING_DECIMALconstant); } // must appear before floating_constant
369{floating_fraction}     { NUMERIC_RETURN(FLOATING_FRACTIONconstant); } // must appear before floating_constant
370{floating_constant}     { NUMERIC_RETURN(FLOATINGconstant); }
371{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
372
373                                /* character constant, allows empty value */
374({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new string( yytext, yyleng ); }
375<QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); }
376<QUOTE>['\n]    { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); }
377                                /* ' stop editor highlighting */
378
379                                /* string constant */
380({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new string( yytext, yyleng ); }
381<STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); }
382<STRING>["\n]   { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); }
383                                /* " stop editor highlighting */
384
385                                /* common character/string constant */
386<QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); }
387<QUOTE,STRING>"\\"{h_white}*"\n" {}                                             // continuation (ALSO HANDLED BY CPP)
388<QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character
389
390                                /* punctuation */
391"@"                             { ASCIIOP_RETURN(); }
392"`"                             { ASCIIOP_RETURN(); }
393"["                             { ASCIIOP_RETURN(); }
394"]"                             { ASCIIOP_RETURN(); }
395"("                             { ASCIIOP_RETURN(); }
396")"                             { ASCIIOP_RETURN(); }
397"{"                             { ASCIIOP_RETURN(); }
398"}"                             { ASCIIOP_RETURN(); }
399","                             { ASCIIOP_RETURN(); }                                   // also operator
400":"                             { ASCIIOP_RETURN(); }
401";"                             { ASCIIOP_RETURN(); }
402"."                             { ASCIIOP_RETURN(); }                                   // also operator
403"..."                   { NAMEDOP_RETURN(ELLIPSIS); }
404
405                                /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
406"<:"                    { RETURN_VAL('['); }
407":>"                    { RETURN_VAL(']'); }
408"<%"                    { RETURN_VAL('{'); }
409"%>"                    { RETURN_VAL('}'); }
410
411                                /* operators */
412"!"                             { ASCIIOP_RETURN(); }
413"+"                             { ASCIIOP_RETURN(); }
414"-"                             { ASCIIOP_RETURN(); }
415"*"                             { ASCIIOP_RETURN(); }
416"\\"                    { ASCIIOP_RETURN(); }                                   // CFA, exponentiation
417"/"                             { ASCIIOP_RETURN(); }
418"%"                             { ASCIIOP_RETURN(); }
419"^"                             { ASCIIOP_RETURN(); }
420"~"                             { ASCIIOP_RETURN(); }
421"&"                             { ASCIIOP_RETURN(); }
422"|"                             { ASCIIOP_RETURN(); }
423"<"                             { ASCIIOP_RETURN(); }
424">"                             { ASCIIOP_RETURN(); }
425"="                             { ASCIIOP_RETURN(); }
426"?"                             { ASCIIOP_RETURN(); }
427
428"++"                    { NAMEDOP_RETURN(ICR); }
429"--"                    { NAMEDOP_RETURN(DECR); }
430"=="                    { NAMEDOP_RETURN(EQ); }
431"!="                    { NAMEDOP_RETURN(NE); }
432"<<"                    { NAMEDOP_RETURN(LS); }
433">>"                    { NAMEDOP_RETURN(RS); }
434"<="                    { NAMEDOP_RETURN(LE); }
435">="                    { NAMEDOP_RETURN(GE); }
436"&&"                    { NAMEDOP_RETURN(ANDAND); }
437"||"                    { NAMEDOP_RETURN(OROR); }
438"->"                    { NAMEDOP_RETURN(ARROW); }
439"+="                    { NAMEDOP_RETURN(PLUSassign); }
440"-="                    { NAMEDOP_RETURN(MINUSassign); }
441"\\="                   { NAMEDOP_RETURN(EXPassign); }                  // CFA, exponentiation
442"*="                    { NAMEDOP_RETURN(MULTassign); }
443"/="                    { NAMEDOP_RETURN(DIVassign); }
444"%="                    { NAMEDOP_RETURN(MODassign); }
445"&="                    { NAMEDOP_RETURN(ANDassign); }
446"|="                    { NAMEDOP_RETURN(ORassign); }
447"^="                    { NAMEDOP_RETURN(ERassign); }
448"<<="                   { NAMEDOP_RETURN(LSassign); }
449">>="                   { NAMEDOP_RETURN(RSassign); }
450
451"@="                    { NAMEDOP_RETURN(ATassign); }                   // CFA
452"~="                    { NAMEDOP_RETURN(ErangeUpEq); }                 // CFA
453"-~"                    { NAMEDOP_RETURN(ErangeDown); }                 // CFA
454"-~="                   { NAMEDOP_RETURN(ErangeDownEq); }               // CFA
455
456                                /* CFA, operator identifier */
457{op_unary}"?"   { IDENTIFIER_RETURN(); }                                // unary
458"?"({op_unary_pre_post}|"()"|"[?]"|"{}") { IDENTIFIER_RETURN(); }
459"^?{}"                  { IDENTIFIER_RETURN(); }
460"?`"{identifier} {                                                                              // postfix operator
461        yylval.tok.str = new string( &yytext[2] );                      // remove ?`
462        yylval.tok.str = build_postfix_name( yylval.tok.str ); // add prefix
463        RETURN_LOCN( typedefTable.isKind( *yylval.tok.str ) );
464}
465"?"{op_binary_over}"?"  { IDENTIFIER_RETURN(); }                // binary
466        /*
467          This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the string "*?*?"  can be
468          lexed as "*?"/"*?" or "*"/"?*?". Since it is common practise to put a unary operator juxtaposed to an identifier,
469          e.g., "*i", users will be annoyed if they cannot do this with respect to operator identifiers. Therefore, there is
470          a lexical look-ahead for the second case, with backtracking to return the leading unary operator and then
471          reparsing the trailing operator identifier.  Otherwise a space is needed between the unary operator and operator
472          identifier to disambiguate this common case.
473
474          A similar issue occurs with the dereference, *?(...), and routine-call, ?()(...) identifiers.  The ambiguity
475          occurs when the deference operator has no parameters, *?() and *?()(...), requiring arbitrary whitespace
476          look-ahead for the routine-call parameter-list to disambiguate.  However, the dereference operator must have a
477          parameter/argument to dereference *?(...).  Hence, always interpreting the string *?() as * ?() does not preclude
478          any meaningful program.
479
480          The remaining cases are with the increment/decrement operators and conditional expression:
481
482          i++? ...(...);
483          i?++ ...(...);
484
485          requiring arbitrary whitespace look-ahead for the operator parameter-list, even though that interpretation is an
486      incorrect expression (juxtaposed identifiers).  Therefore, it is necessary to disambiguate these cases with a
487      space:
488
489          i++ ? i : 0;
490          i? ++i : 0;
491        */
492{op_unary}"?"({op_unary_pre_post}|"()"|"[?]"|{op_binary_over}"?") {
493        // 1 or 2 character unary operator ?
494        int i = yytext[1] == '?' ? 1 : 2;
495        yyless( i );            // put back characters up to first '?'
496        if ( i > 1 ) {
497                NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
498        } else {
499                ASCIIOP_RETURN();
500        } // if
501}
502
503                                /* unknown character */
504.                               { yyerror( "unknown character" ); }
505
506%%
507
508// ----end of lexer----
509
510void yyerror( const char * errmsg ) {
511        SemanticErrorThrow = true;
512        cerr << (yyfilename ? yyfilename : "*unknown file*") << ':' << yylineno << ':' << column - yyleng + 1
513                 << ": " << ErrorHelpers::error_str() << errmsg << " before token \"" << (yytext[0] == '\0' ? "EOF" : yytext) << '"' << endl;
514}
515
516// Local Variables: //
517// mode: c++ //
518// tab-width: 4 //
519// compile-command: "make install" //
520// End: //
Note: See TracBrowser for help on using the repository browser.