source: src/Parser/lex.ll @ de62360d

aaron-thesisarm-ehcleanup-dtorsctordeferred_resndemanglerenumforall-pointer-decaygc_noraiijacob/cs343-translationjenkins-sandboxmemorynew-astnew-ast-unique-exprnew-envno_listpersistent-indexerresolv-newstringwith_gc
Last change on this file since de62360d was de62360d, checked in by Peter A. Buhr <pabuhr@…>, 7 years ago

fix computed goto, fixed -std=, implicit typedefs for enum and aggregates, add _Noreturn _Thread_local

  • Property mode set to 100644
File size: 14.7 KB
Line 
1/*
2 * Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3 *
4 * The contents of this file are covered under the licence agreement in the
5 * file "LICENCE" distributed with Cforall.
6 *
7 * lex.l --
8 *
9 * Author           : Peter A. Buhr
10 * Created On       : Sat Sep 22 08:58:10 2001
11 * Last Modified By : Peter A. Buhr
12 * Last Modified On : Fri Jun 19 11:10:14 2015
13 * Update Count     : 392
14 */
15
16%option yylineno
17%option nounput
18
19%{
20// This lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
21// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
22// line-number directives) and C/C++ style comments, which are ignored.
23
24//**************************** Includes and Defines ****************************
25
26#include <string>
27
28#include "lex.h"
29#include "ParseNode.h"
30#include "parser.h"                                                                             // YACC generated definitions based on C++ grammar
31
32char *yyfilename;
33std::string *strtext;                                                                   // accumulate parts of character and string constant value
34
35#define RETURN_LOCN(x)          yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
36#define RETURN_VAL(x)           yylval.tok.str = new std::string( yytext ); RETURN_LOCN( x )
37#define RETURN_CHAR(x)          yylval.tok.str = NULL; RETURN_LOCN( x )
38#define RETURN_STR(x)           yylval.tok.str = strtext; RETURN_LOCN( x )
39
40#define WHITE_RETURN(x)                                                                 // do nothing
41#define NEWLINE_RETURN()        WHITE_RETURN( '\n' )
42#define ASCIIOP_RETURN()        RETURN_CHAR( (int)yytext[0] ) // single character operator
43#define NAMEDOP_RETURN(x)       RETURN_VAL( x )                         // multichar operator, with a name
44#define NUMERIC_RETURN(x)       rm_underscore(); RETURN_VAL( x ) // numeric constant
45#define KEYWORD_RETURN(x)       RETURN_CHAR( x )                        // keyword
46#define IDENTIFIER_RETURN()     RETURN_VAL( (typedefTable.isIdentifier( yytext ) ? IDENTIFIER : typedefTable.isTypedef( yytext ) ? TYPEDEFname : TYPEGENname ) )
47#define ATTRIBUTE_RETURN()      RETURN_VAL( ATTR_IDENTIFIER )
48
49void rm_underscore() {
50        // remove underscores in numeric constant
51        int j = 0;
52        for ( int i = 0; yytext[i] != '\0'; i += 1 ) {
53                if ( yytext[i] != '_' ) {
54                        yytext[j] = yytext[i];
55                        j += 1;
56                } // if
57        } // for
58        yyleng = j;
59        yytext[yyleng] = '\0';
60}
61
62%}
63
64octal [0-7]
65nonzero [1-9]
66decimal [0-9]
67hex [0-9a-fA-F]
68universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2}))
69
70                                // identifier, GCC: $ in identifier
71identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})*
72
73                                // quoted identifier
74quoted_identifier "`"{identifier}"`"
75
76                                // attribute identifier, GCC: $ in identifier
77attr_identifier "@"{identifier}
78
79                                // numeric constants, CFA: '_' in constant
80hex_quad {hex}("_"?{hex}){3}
81integer_suffix "_"?(([uU][lL]?)|([uU]("ll"|"LL")?)|([lL][uU]?)|("ll"|"LL")[uU]?)
82
83octal_digits ({octal})|({octal}({octal}|"_")*{octal})
84octal_prefix "0""_"?
85octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix}?
86
87nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal})
88decimal_constant {nonzero_digits}{integer_suffix}?
89
90hex_digits ({hex})|({hex}({hex}|"_")*{hex})
91hex_prefix "0"[xX]"_"?
92hex_constant {hex_prefix}{hex_digits}{integer_suffix}?
93
94decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal})
95fractional_constant ({decimal_digits}?"."{decimal_digits})|({decimal_digits}".")
96exponent "_"?[eE]"_"?[+-]?{decimal_digits}
97floating_suffix "_"?[flFL]
98floating_constant (({fractional_constant}{exponent}?)|({decimal_digits}{exponent})){floating_suffix}?
99
100binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
101hex_fractional_constant ({hex_digits}?"."{hex_digits})|({hex_digits}".")
102hex_floating_constant {hex_prefix}(({hex_fractional_constant}{binary_exponent})|({hex_digits}{binary_exponent})){floating_suffix}?
103
104                                // character escape sequence, GCC: \e => esc character
105simple_escape "\\"[abefnrtv'"?\\]
106                                // ' stop highlighting
107octal_escape "\\"{octal}("_"?{octal}){0,2}
108hex_escape "\\""x""_"?{hex_digits}
109escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char}
110cwide_prefix "L"|"U"|"u"
111swide_prefix {cwide_prefix}|"u8"
112
113                                // display/white-space characters
114h_tab [\011]
115form_feed [\014]
116v_tab [\013]
117c_return [\015]
118h_white [ ]|{h_tab}
119
120                                // operators
121op_unary_only "~"|"!"
122op_unary_binary "+"|"-"|"*"
123op_unary_pre_post "++"|"--"
124op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post}
125
126op_binary_only "/"|"%"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"&="|"|="|"^="|"<<="|">>="
127op_binary_over {op_unary_binary}|{op_binary_only}
128op_binary_not_over "?"|"->"|"&&"|"||"
129operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over}
130
131%x COMMENT
132%x BKQUOTE
133%x QUOTE
134%x STRING
135
136%%
137                                   /* line directives */
138^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["][^\n]*"\n" {
139        /* " stop highlighting */
140        char *end_num;
141        char *begin_string, *end_string;
142        char *filename;
143        long lineno, length;
144        lineno = strtol( yytext + 1, &end_num, 0 );
145        begin_string = strchr( end_num, '"' );
146        if ( begin_string ) {
147                end_string = strchr( begin_string + 1, '"' );
148                if ( end_string ) {
149                        length = end_string - begin_string - 1;
150                        filename = new char[ length + 1 ];
151                        memcpy( filename, begin_string + 1, length );
152                        filename[ length ] = '\0';
153                        //std::cout << "file " << filename << " line " << lineno << std::endl;
154                        yylineno = lineno;
155                        yyfilename = filename;
156                } // if
157        } // if
158}
159
160                                /* ignore preprocessor directives (for now) */
161^{h_white}*"#"[^\n]*"\n" ;
162
163                                /* ignore C style comments (ALSO HANDLED BY CPP) */
164"/*"                    { BEGIN COMMENT; }
165<COMMENT>.|\n   ;
166<COMMENT>"*/"   { BEGIN 0; }
167
168                                /* ignore C++ style comments (ALSO HANDLED BY CPP) */
169"//"[^\n]*"\n"  ;
170
171                                /* ignore whitespace */
172{h_white}+              { WHITE_RETURN(' '); }
173({v_tab}|{c_return}|{form_feed})+ { WHITE_RETURN(' '); }
174({h_white}|{v_tab}|{c_return}|{form_feed})*"\n" { NEWLINE_RETURN(); }
175
176                                /* keywords */
177_Alignas                { KEYWORD_RETURN(ALIGNAS); }                    // C11
178_Alignof                { KEYWORD_RETURN(ALIGNOF); }                    // C11
179__alignof               { KEYWORD_RETURN(ALIGNOF); }                    // GCC
180__alignof__             { KEYWORD_RETURN(ALIGNOF); }                    // GCC
181asm                             { KEYWORD_RETURN(ASM); }
182__asm                   { KEYWORD_RETURN(ASM); }                                // GCC
183__asm__                 { KEYWORD_RETURN(ASM); }                                // GCC
184_Atomic                 { KEYWORD_RETURN(ATOMIC); }                             // C11
185__attribute             { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
186__attribute__   { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
187auto                    { KEYWORD_RETURN(AUTO); }
188_Bool                   { KEYWORD_RETURN(BOOL); }                               // C99
189break                   { KEYWORD_RETURN(BREAK); }
190case                    { KEYWORD_RETURN(CASE); }
191catch                   { KEYWORD_RETURN(CATCH); }                              // CFA
192char                    { KEYWORD_RETURN(CHAR); }
193choose                  { KEYWORD_RETURN(CHOOSE); }                             // CFA
194_Complex                { KEYWORD_RETURN(COMPLEX); }                    // C99
195__complex               { KEYWORD_RETURN(COMPLEX); }                    // GCC
196__complex__             { KEYWORD_RETURN(COMPLEX); }                    // GCC
197const                   { KEYWORD_RETURN(CONST); }
198__const                 { KEYWORD_RETURN(CONST); }                              // GCC
199__const__               { KEYWORD_RETURN(CONST); }                              // GCC
200context                 { KEYWORD_RETURN(CONTEXT); }                    // CFA
201continue                { KEYWORD_RETURN(CONTINUE); }
202default                 { KEYWORD_RETURN(DEFAULT); }
203do                              { KEYWORD_RETURN(DO); }
204double                  { KEYWORD_RETURN(DOUBLE); }
205dtype                   { KEYWORD_RETURN(DTYPE); }                              // CFA
206else                    { KEYWORD_RETURN(ELSE); }
207enum                    { KEYWORD_RETURN(ENUM); }
208__extension__   { KEYWORD_RETURN(EXTENSION); }                  // GCC
209extern                  { KEYWORD_RETURN(EXTERN); }
210fallthru                { KEYWORD_RETURN(FALLTHRU); }                   // CFA
211finally                 { KEYWORD_RETURN(FINALLY); }                    // CFA
212float                   { KEYWORD_RETURN(FLOAT); }
213__float128              { KEYWORD_RETURN(FLOAT); }                              // GCC
214for                             { KEYWORD_RETURN(FOR); }
215forall                  { KEYWORD_RETURN(FORALL); }                             // CFA
216fortran                 { KEYWORD_RETURN(FORTRAN); }
217ftype                   { KEYWORD_RETURN(FTYPE); }                              // CFA
218_Generic                { KEYWORD_RETURN(GENERIC); }                    // C11
219goto                    { KEYWORD_RETURN(GOTO); }
220if                              { KEYWORD_RETURN(IF); }
221_Imaginary              { KEYWORD_RETURN(IMAGINARY); }                  // C99
222__imag                  { KEYWORD_RETURN(IMAGINARY); }                  // GCC
223__imag__                { KEYWORD_RETURN(IMAGINARY); }                  // GCC
224inline                  { KEYWORD_RETURN(INLINE); }                             // C99
225__inline                { KEYWORD_RETURN(INLINE); }                             // GCC
226__inline__              { KEYWORD_RETURN(INLINE); }                             // GCC
227int                             { KEYWORD_RETURN(INT); }
228__int128                { KEYWORD_RETURN(INT); }                                // GCC
229__label__               { KEYWORD_RETURN(LABEL); }                              // GCC
230long                    { KEYWORD_RETURN(LONG); }
231lvalue                  { KEYWORD_RETURN(LVALUE); }                             // CFA
232_Noreturn               { KEYWORD_RETURN(NORETURN); }                   // C11
233register                { KEYWORD_RETURN(REGISTER); }
234restrict                { KEYWORD_RETURN(RESTRICT); }                   // C99
235__restrict              { KEYWORD_RETURN(RESTRICT); }                   // GCC
236__restrict__    { KEYWORD_RETURN(RESTRICT); }                   // GCC
237return                  { KEYWORD_RETURN(RETURN); }
238short                   { KEYWORD_RETURN(SHORT); }
239signed                  { KEYWORD_RETURN(SIGNED); }
240__signed                { KEYWORD_RETURN(SIGNED); }                             // GCC
241__signed__              { KEYWORD_RETURN(SIGNED); }                             // GCC
242sizeof                  { KEYWORD_RETURN(SIZEOF); }
243static                  { KEYWORD_RETURN(STATIC); }
244_Static_assert  { KEYWORD_RETURN(STATICASSERT); }               // C11
245struct                  { KEYWORD_RETURN(STRUCT); }
246switch                  { KEYWORD_RETURN(SWITCH); }
247_Thread_local   { KEYWORD_RETURN(THREADLOCAL); }                // C11
248throw                   { KEYWORD_RETURN(THROW); }                              // CFA
249try                             { KEYWORD_RETURN(TRY); }                                // CFA
250type                    { KEYWORD_RETURN(TYPE); }                               // CFA
251typedef                 { KEYWORD_RETURN(TYPEDEF); }
252typeof                  { KEYWORD_RETURN(TYPEOF); }                             // GCC
253__typeof                { KEYWORD_RETURN(TYPEOF); }                             // GCC
254__typeof__              { KEYWORD_RETURN(TYPEOF); }                             // GCC
255union                   { KEYWORD_RETURN(UNION); }
256unsigned                { KEYWORD_RETURN(UNSIGNED); }
257void                    { KEYWORD_RETURN(VOID); }
258volatile                { KEYWORD_RETURN(VOLATILE); }
259__volatile              { KEYWORD_RETURN(VOLATILE); }                   // GCC
260__volatile__    { KEYWORD_RETURN(VOLATILE); }                   // GCC
261while                   { KEYWORD_RETURN(WHILE); }
262
263                                /* identifier */
264{identifier}    { IDENTIFIER_RETURN(); }
265{attr_identifier} { ATTRIBUTE_RETURN(); }
266"`"                     { BEGIN BKQUOTE; }
267<BKQUOTE>{identifier} { IDENTIFIER_RETURN(); }
268<BKQUOTE>"`"    { BEGIN 0; }
269
270                                /* numeric constants */
271"0"                             { NUMERIC_RETURN(ZERO); }                               // CFA
272"1"                             { NUMERIC_RETURN(ONE); }                                // CFA
273{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
274{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
275{hex_constant}  { NUMERIC_RETURN(INTEGERconstant); }
276{floating_constant}     { NUMERIC_RETURN(FLOATINGconstant); }
277{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
278
279                                /* character constant, allows empty value */
280({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new std::string; *strtext += std::string( yytext ); }
281<QUOTE>[^'\\\n]* { *strtext += std::string( yytext ); }
282<QUOTE>['\n]    { BEGIN 0; *strtext += std::string( yytext); RETURN_STR(CHARACTERconstant); }
283                                /* ' stop highlighting */
284
285                                /* string constant */
286({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new std::string; *strtext += std::string( yytext ); }
287<STRING>[^"\\\n]* { *strtext += std::string( yytext ); }
288<STRING>["\n]   { BEGIN 0; *strtext += std::string( yytext ); RETURN_STR(STRINGliteral); }
289                                /* " stop highlighting */
290
291                                /* common character/string constant */
292<QUOTE,STRING>{escape_seq} { rm_underscore(); *strtext += std::string( yytext ); }
293<QUOTE,STRING>"\\"{h_white}*"\n" {}                                             // continuation (ALSO HANDLED BY CPP)
294<QUOTE,STRING>"\\" { *strtext += std::string( yytext ); } // unknown escape character
295
296                                /* punctuation */
297"["                             { ASCIIOP_RETURN(); }
298"]"                             { ASCIIOP_RETURN(); }
299"("                             { ASCIIOP_RETURN(); }
300")"                             { ASCIIOP_RETURN(); }
301"{"                             { ASCIIOP_RETURN(); }
302"}"                             { ASCIIOP_RETURN(); }
303","                             { ASCIIOP_RETURN(); }                                   // also operator
304":"                             { ASCIIOP_RETURN(); }
305";"                             { ASCIIOP_RETURN(); }
306"."                             { ASCIIOP_RETURN(); }                                   // also operator
307"..."                   { NAMEDOP_RETURN(ELLIPSIS); }
308
309                                /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
310"<:"                    { RETURN_VAL('['); }
311":>"                    { RETURN_VAL(']'); }
312"<%"                    { RETURN_VAL('{'); }
313"%>"                    { RETURN_VAL('}'); }
314
315                                /* operators */
316"!"                             { ASCIIOP_RETURN(); }
317"+"                             { ASCIIOP_RETURN(); }
318"-"                             { ASCIIOP_RETURN(); }
319"*"                             { ASCIIOP_RETURN(); }
320"/"                             { ASCIIOP_RETURN(); }
321"%"                             { ASCIIOP_RETURN(); }
322"^"                             { ASCIIOP_RETURN(); }
323"~"                             { ASCIIOP_RETURN(); }
324"&"                             { ASCIIOP_RETURN(); }
325"|"                             { ASCIIOP_RETURN(); }
326"<"                             { ASCIIOP_RETURN(); }
327">"                             { ASCIIOP_RETURN(); }
328"="                             { ASCIIOP_RETURN(); }
329"?"                             { ASCIIOP_RETURN(); }
330
331"++"                    { NAMEDOP_RETURN(ICR); }
332"--"                    { NAMEDOP_RETURN(DECR); }
333"=="                    { NAMEDOP_RETURN(EQ); }
334"!="                    { NAMEDOP_RETURN(NE); }
335"<<"                    { NAMEDOP_RETURN(LS); }
336">>"                    { NAMEDOP_RETURN(RS); }
337"<="                    { NAMEDOP_RETURN(LE); }
338">="                    { NAMEDOP_RETURN(GE); }
339"&&"                    { NAMEDOP_RETURN(ANDAND); }
340"||"                    { NAMEDOP_RETURN(OROR); }
341"->"                    { NAMEDOP_RETURN(ARROW); }
342"+="                    { NAMEDOP_RETURN(PLUSassign); }
343"-="                    { NAMEDOP_RETURN(MINUSassign); }
344"*="                    { NAMEDOP_RETURN(MULTassign); }
345"/="                    { NAMEDOP_RETURN(DIVassign); }
346"%="                    { NAMEDOP_RETURN(MODassign); }
347"&="                    { NAMEDOP_RETURN(ANDassign); }
348"|="                    { NAMEDOP_RETURN(ORassign); }
349"^="                    { NAMEDOP_RETURN(ERassign); }
350"<<="                   { NAMEDOP_RETURN(LSassign); }
351">>="                   { NAMEDOP_RETURN(RSassign); }
352
353                                /* CFA, operator identifier */
354{op_unary}"?"   { IDENTIFIER_RETURN(); }                                // unary
355"?"({op_unary_pre_post}|"()"|"[?]"|"{}") { IDENTIFIER_RETURN(); }
356"?"{op_binary_over}"?"  { IDENTIFIER_RETURN(); }                // binary
357        /*
358          This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the string "*?*?"
359          can be lexed as "*"/"?*?" or "*?"/"*?". Since it is common practise to put a unary operator juxtaposed
360          to an identifier, e.g., "*i", users will be annoyed if they cannot do this with respect to operator
361          identifiers. Even with this special hack, there are 5 general cases that cannot be handled. The first
362          case is for the function-call identifier "?()":
363
364          int * ?()();  // declaration: space required after '*'
365          * ?()();      // expression: space required after '*'
366
367          Without the space, the string "*?()" is ambiguous without N character look ahead; it requires scanning
368          ahead to determine if there is a '(', which is the start of an argument/parameter list.
369
370          The 4 remaining cases occur in expressions:
371
372          i++?i:0;              // space required before '?'
373          i--?i:0;              // space required before '?'
374          i?++i:0;              // space required after '?'
375          i?--i:0;              // space required after '?'
376
377          In the first two cases, the string "i++?" is ambiguous, where this string can be lexed as "i"/"++?" or
378          "i++"/"?"; it requires scanning ahead to determine if there is a '(', which is the start of an argument
379          list.  In the second two cases, the string "?++x" is ambiguous, where this string can be lexed as
380          "?++"/"x" or "?"/"++x"; it requires scanning ahead to determine if there is a '(', which is the start of
381          an argument list.
382        */
383{op_unary}"?"(({op_unary_pre_post}|"[?]")|({op_binary_over}"?")) {
384        // 1 or 2 character unary operator ?
385        int i = yytext[1] == '?' ? 1 : 2;
386        yyless( i );            // put back characters up to first '?'
387        if ( i > 1 ) {
388                NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
389        } else {
390                ASCIIOP_RETURN();
391        } // if
392}
393
394                                /* unknown characters */
395.                       { printf("unknown character(s):\"%s\" on line %d\n", yytext, yylineno); }
396
397%%
398
399// Local Variables: //
400// mode: c++ //
401// tab-width: 4 //
402// compile-command: "make install" //
403// End: //
Note: See TracBrowser for help on using the repository browser.