| 1 | /* |
|---|
| 2 | * Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo |
|---|
| 3 | * |
|---|
| 4 | * The contents of this file are covered under the licence agreement in the |
|---|
| 5 | * file "LICENCE" distributed with Cforall. |
|---|
| 6 | * |
|---|
| 7 | * lex.l -- |
|---|
| 8 | * |
|---|
| 9 | * Author : Peter A. Buhr |
|---|
| 10 | * Created On : Sat Sep 22 08:58:10 2001 |
|---|
| 11 | * Last Modified By : Peter A. Buhr |
|---|
| 12 | * Last Modified On : Fri Mar 3 22:18:00 2017 |
|---|
| 13 | * Update Count : 502 |
|---|
| 14 | */ |
|---|
| 15 | |
|---|
| 16 | %option yylineno |
|---|
| 17 | %option nounput |
|---|
| 18 | |
|---|
| 19 | %{ |
|---|
| 20 | // This lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been |
|---|
| 21 | // performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g., |
|---|
| 22 | // line-number directives) and C/C++ style comments, which are ignored. |
|---|
| 23 | |
|---|
| 24 | //**************************** Includes and Defines **************************** |
|---|
| 25 | |
|---|
| 26 | #include <string> |
|---|
| 27 | #include <cstdio> // FILENAME_MAX |
|---|
| 28 | |
|---|
| 29 | #include "lex.h" |
|---|
| 30 | #include "parser.h" // YACC generated definitions based on C++ grammar |
|---|
| 31 | #include "ParseNode.h" |
|---|
| 32 | #include "TypedefTable.h" |
|---|
| 33 | |
|---|
| 34 | char *yyfilename; |
|---|
| 35 | std::string *strtext; // accumulate parts of character and string constant value |
|---|
| 36 | |
|---|
| 37 | #define RETURN_LOCN(x) yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x ) |
|---|
| 38 | #define RETURN_VAL(x) yylval.tok.str = new std::string( yytext ); RETURN_LOCN( x ) |
|---|
| 39 | #define RETURN_CHAR(x) yylval.tok.str = nullptr; RETURN_LOCN( x ) |
|---|
| 40 | #define RETURN_STR(x) yylval.tok.str = strtext; RETURN_LOCN( x ) |
|---|
| 41 | |
|---|
| 42 | #define WHITE_RETURN(x) // do nothing |
|---|
| 43 | #define NEWLINE_RETURN() WHITE_RETURN( '\n' ) |
|---|
| 44 | #define ASCIIOP_RETURN() RETURN_CHAR( (int)yytext[0] ) // single character operator |
|---|
| 45 | #define NAMEDOP_RETURN(x) RETURN_CHAR( x ) // multichar operator, with a name |
|---|
| 46 | #define NUMERIC_RETURN(x) rm_underscore(); RETURN_VAL( x ) // numeric constant |
|---|
| 47 | #define KEYWORD_RETURN(x) RETURN_CHAR( x ) // keyword |
|---|
| 48 | #define IDENTIFIER_RETURN() RETURN_VAL( typedefTable.isKind( yytext ) ) |
|---|
| 49 | #define ATTRIBUTE_RETURN() RETURN_VAL( ATTR_IDENTIFIER ) |
|---|
| 50 | |
|---|
| 51 | void rm_underscore() { |
|---|
| 52 | // Remove underscores in numeric constant by copying the non-underscore characters to the front of the string. |
|---|
| 53 | yyleng = 0; |
|---|
| 54 | for ( int i = 0; yytext[i] != '\0'; i += 1 ) { |
|---|
| 55 | if ( yytext[i] != '_' ) { |
|---|
| 56 | yytext[yyleng] = yytext[i]; |
|---|
| 57 | yyleng += 1; |
|---|
| 58 | } // if |
|---|
| 59 | } // for |
|---|
| 60 | yytext[yyleng] = '\0'; |
|---|
| 61 | } |
|---|
| 62 | |
|---|
| 63 | %} |
|---|
| 64 | |
|---|
| 65 | octal [0-7] |
|---|
| 66 | nonzero [1-9] |
|---|
| 67 | decimal [0-9] |
|---|
| 68 | hex [0-9a-fA-F] |
|---|
| 69 | universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2})) |
|---|
| 70 | |
|---|
| 71 | // identifier, GCC: $ in identifier |
|---|
| 72 | identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})* |
|---|
| 73 | |
|---|
| 74 | // attribute identifier, GCC: $ in identifier |
|---|
| 75 | attr_identifier "@"{identifier} |
|---|
| 76 | |
|---|
| 77 | // numeric constants, CFA: '_' in constant |
|---|
| 78 | hex_quad {hex}("_"?{hex}){3} |
|---|
| 79 | integer_suffix "_"?(([uU][lL]?)|([uU]("ll"|"LL")?)|([lL][uU]?)|("ll"|"LL")[uU]?) |
|---|
| 80 | |
|---|
| 81 | octal_digits ({octal})|({octal}({octal}|"_")*{octal}) |
|---|
| 82 | octal_prefix "0""_"? |
|---|
| 83 | octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix}? |
|---|
| 84 | |
|---|
| 85 | nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal}) |
|---|
| 86 | decimal_constant {nonzero_digits}{integer_suffix}? |
|---|
| 87 | |
|---|
| 88 | hex_digits ({hex})|({hex}({hex}|"_")*{hex}) |
|---|
| 89 | hex_prefix "0"[xX]"_"? |
|---|
| 90 | hex_constant {hex_prefix}{hex_digits}{integer_suffix}? |
|---|
| 91 | |
|---|
| 92 | decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal}) |
|---|
| 93 | real_decimal {decimal_digits}"." |
|---|
| 94 | real_fraction "."{decimal_digits} |
|---|
| 95 | real_constant {decimal_digits}?{real_fraction} |
|---|
| 96 | exponent "_"?[eE]"_"?[+-]?{decimal_digits} |
|---|
| 97 | // GCC: D (double), DL (long double) and iI (imaginary) suffixes |
|---|
| 98 | floating_suffix "_"?([fFdDlL][iI]?|"DL"|[iI][lLfFdD]?) |
|---|
| 99 | //floating_suffix "_"?([fFdD]|[lL]|[D][L])|([iI][lLfFdD])|([lLfFdD][iI])) |
|---|
| 100 | floating_constant (({real_constant}{exponent}?)|({decimal_digits}{exponent})){floating_suffix}? |
|---|
| 101 | |
|---|
| 102 | binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits} |
|---|
| 103 | hex_fractional_constant ({hex_digits}?"."{hex_digits})|({hex_digits}".") |
|---|
| 104 | hex_floating_constant {hex_prefix}(({hex_fractional_constant}{binary_exponent})|({hex_digits}{binary_exponent})){floating_suffix}? |
|---|
| 105 | |
|---|
| 106 | // character escape sequence, GCC: \e => esc character |
|---|
| 107 | simple_escape "\\"[abefnrtv'"?\\] |
|---|
| 108 | // ' stop highlighting |
|---|
| 109 | octal_escape "\\"{octal}("_"?{octal}){0,2} |
|---|
| 110 | hex_escape "\\""x""_"?{hex_digits} |
|---|
| 111 | escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char} |
|---|
| 112 | cwide_prefix "L"|"U"|"u" |
|---|
| 113 | swide_prefix {cwide_prefix}|"u8" |
|---|
| 114 | |
|---|
| 115 | // display/white-space characters |
|---|
| 116 | h_tab [\011] |
|---|
| 117 | form_feed [\014] |
|---|
| 118 | v_tab [\013] |
|---|
| 119 | c_return [\015] |
|---|
| 120 | h_white [ ]|{h_tab} |
|---|
| 121 | |
|---|
| 122 | // overloadable operators |
|---|
| 123 | op_unary_only "~"|"!" |
|---|
| 124 | op_unary_binary "+"|"-"|"*" |
|---|
| 125 | op_unary_pre_post "++"|"--" |
|---|
| 126 | op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post} |
|---|
| 127 | |
|---|
| 128 | op_binary_only "/"|"%"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"&="|"|="|"^="|"<<="|">>=" |
|---|
| 129 | op_binary_over {op_unary_binary}|{op_binary_only} |
|---|
| 130 | // op_binary_not_over "?"|"->"|"."|"&&"|"||"|"@=" |
|---|
| 131 | // operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over} |
|---|
| 132 | |
|---|
| 133 | %x COMMENT |
|---|
| 134 | %x BKQUOTE |
|---|
| 135 | %x QUOTE |
|---|
| 136 | %x STRING |
|---|
| 137 | |
|---|
| 138 | %% |
|---|
| 139 | /* line directives */ |
|---|
| 140 | ^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["].*"\n" { |
|---|
| 141 | /* " stop highlighting */ |
|---|
| 142 | static char filename[FILENAME_MAX]; // temporarily store current source-file name |
|---|
| 143 | char *end_num; |
|---|
| 144 | char *begin_string, *end_string; |
|---|
| 145 | long lineno, length; |
|---|
| 146 | lineno = strtol( yytext + 1, &end_num, 0 ); |
|---|
| 147 | begin_string = strchr( end_num, '"' ); |
|---|
| 148 | if ( begin_string ) { // file name ? |
|---|
| 149 | end_string = strchr( begin_string + 1, '"' ); // look for ending delimiter |
|---|
| 150 | assert( end_string ); // closing quote ? |
|---|
| 151 | length = end_string - begin_string - 1; // file-name length without quotes or sentinel |
|---|
| 152 | assert( length < FILENAME_MAX ); // room for sentinel ? |
|---|
| 153 | memcpy( &filename, begin_string + 1, length ); // copy file name from yytext |
|---|
| 154 | filename[ length ] = '\0'; // terminate string with sentinel |
|---|
| 155 | //std::cout << "file " << filename << " line " << lineno << std::endl; |
|---|
| 156 | yylineno = lineno; |
|---|
| 157 | yyfilename = filename; |
|---|
| 158 | } // if |
|---|
| 159 | } |
|---|
| 160 | |
|---|
| 161 | /* ignore preprocessor directives (for now) */ |
|---|
| 162 | ^{h_white}*"#"[^\n]*"\n" ; |
|---|
| 163 | |
|---|
| 164 | /* ignore C style comments (ALSO HANDLED BY CPP) */ |
|---|
| 165 | "/*" { BEGIN COMMENT; } |
|---|
| 166 | <COMMENT>.|\n ; |
|---|
| 167 | <COMMENT>"*/" { BEGIN 0; } |
|---|
| 168 | |
|---|
| 169 | /* ignore C++ style comments (ALSO HANDLED BY CPP) */ |
|---|
| 170 | "//"[^\n]*"\n" ; |
|---|
| 171 | |
|---|
| 172 | /* ignore whitespace */ |
|---|
| 173 | {h_white}+ { WHITE_RETURN(' '); } |
|---|
| 174 | ({v_tab}|{c_return}|{form_feed})+ { WHITE_RETURN(' '); } |
|---|
| 175 | ({h_white}|{v_tab}|{c_return}|{form_feed})*"\n" { NEWLINE_RETURN(); } |
|---|
| 176 | |
|---|
| 177 | /* keywords */ |
|---|
| 178 | _Alignas { KEYWORD_RETURN(ALIGNAS); } // C11 |
|---|
| 179 | _Alignof { KEYWORD_RETURN(ALIGNOF); } // C11 |
|---|
| 180 | __alignof { KEYWORD_RETURN(ALIGNOF); } // GCC |
|---|
| 181 | __alignof__ { KEYWORD_RETURN(ALIGNOF); } // GCC |
|---|
| 182 | asm { KEYWORD_RETURN(ASM); } |
|---|
| 183 | __asm { KEYWORD_RETURN(ASM); } // GCC |
|---|
| 184 | __asm__ { KEYWORD_RETURN(ASM); } // GCC |
|---|
| 185 | _At { KEYWORD_RETURN(AT); } // CFA |
|---|
| 186 | _Atomic { KEYWORD_RETURN(ATOMIC); } // C11 |
|---|
| 187 | __attribute { KEYWORD_RETURN(ATTRIBUTE); } // GCC |
|---|
| 188 | __attribute__ { KEYWORD_RETURN(ATTRIBUTE); } // GCC |
|---|
| 189 | auto { KEYWORD_RETURN(AUTO); } |
|---|
| 190 | _Bool { KEYWORD_RETURN(BOOL); } // C99 |
|---|
| 191 | break { KEYWORD_RETURN(BREAK); } |
|---|
| 192 | case { KEYWORD_RETURN(CASE); } |
|---|
| 193 | catch { KEYWORD_RETURN(CATCH); } // CFA |
|---|
| 194 | catchResume { KEYWORD_RETURN(CATCHRESUME); } // CFA |
|---|
| 195 | char { KEYWORD_RETURN(CHAR); } |
|---|
| 196 | choose { KEYWORD_RETURN(CHOOSE); } // CFA |
|---|
| 197 | _Complex { KEYWORD_RETURN(COMPLEX); } // C99 |
|---|
| 198 | __complex { KEYWORD_RETURN(COMPLEX); } // GCC |
|---|
| 199 | __complex__ { KEYWORD_RETURN(COMPLEX); } // GCC |
|---|
| 200 | const { KEYWORD_RETURN(CONST); } |
|---|
| 201 | __const { KEYWORD_RETURN(CONST); } // GCC |
|---|
| 202 | __const__ { KEYWORD_RETURN(CONST); } // GCC |
|---|
| 203 | continue { KEYWORD_RETURN(CONTINUE); } |
|---|
| 204 | default { KEYWORD_RETURN(DEFAULT); } |
|---|
| 205 | disable { KEYWORD_RETURN(DISABLE); } // CFA |
|---|
| 206 | do { KEYWORD_RETURN(DO); } |
|---|
| 207 | double { KEYWORD_RETURN(DOUBLE); } |
|---|
| 208 | dtype { KEYWORD_RETURN(DTYPE); } // CFA |
|---|
| 209 | else { KEYWORD_RETURN(ELSE); } |
|---|
| 210 | enable { KEYWORD_RETURN(ENABLE); } // CFA |
|---|
| 211 | enum { KEYWORD_RETURN(ENUM); } |
|---|
| 212 | __extension__ { KEYWORD_RETURN(EXTENSION); } // GCC |
|---|
| 213 | extern { KEYWORD_RETURN(EXTERN); } |
|---|
| 214 | fallthrough { KEYWORD_RETURN(FALLTHRU); } // CFA |
|---|
| 215 | fallthru { KEYWORD_RETURN(FALLTHRU); } // CFA |
|---|
| 216 | finally { KEYWORD_RETURN(FINALLY); } // CFA |
|---|
| 217 | float { KEYWORD_RETURN(FLOAT); } |
|---|
| 218 | __float128 { KEYWORD_RETURN(FLOAT); } // GCC |
|---|
| 219 | for { KEYWORD_RETURN(FOR); } |
|---|
| 220 | forall { KEYWORD_RETURN(FORALL); } // CFA |
|---|
| 221 | fortran { KEYWORD_RETURN(FORTRAN); } |
|---|
| 222 | ftype { KEYWORD_RETURN(FTYPE); } // CFA |
|---|
| 223 | _Generic { KEYWORD_RETURN(GENERIC); } // C11 |
|---|
| 224 | goto { KEYWORD_RETURN(GOTO); } |
|---|
| 225 | if { KEYWORD_RETURN(IF); } |
|---|
| 226 | _Imaginary { KEYWORD_RETURN(IMAGINARY); } // C99 |
|---|
| 227 | __imag { KEYWORD_RETURN(IMAGINARY); } // GCC |
|---|
| 228 | __imag__ { KEYWORD_RETURN(IMAGINARY); } // GCC |
|---|
| 229 | inline { KEYWORD_RETURN(INLINE); } // C99 |
|---|
| 230 | __inline { KEYWORD_RETURN(INLINE); } // GCC |
|---|
| 231 | __inline__ { KEYWORD_RETURN(INLINE); } // GCC |
|---|
| 232 | int { KEYWORD_RETURN(INT); } |
|---|
| 233 | __int128 { KEYWORD_RETURN(INT); } // GCC |
|---|
| 234 | __label__ { KEYWORD_RETURN(LABEL); } // GCC |
|---|
| 235 | long { KEYWORD_RETURN(LONG); } |
|---|
| 236 | lvalue { KEYWORD_RETURN(LVALUE); } // CFA |
|---|
| 237 | mutex { KEYWORD_RETURN(MUTEX); } // CFA |
|---|
| 238 | _Noreturn { KEYWORD_RETURN(NORETURN); } // C11 |
|---|
| 239 | __builtin_offsetof { KEYWORD_RETURN(OFFSETOF); } // GCC |
|---|
| 240 | one_t { NUMERIC_RETURN(ONE_T); } // CFA |
|---|
| 241 | otype { KEYWORD_RETURN(OTYPE); } // CFA |
|---|
| 242 | register { KEYWORD_RETURN(REGISTER); } |
|---|
| 243 | restrict { KEYWORD_RETURN(RESTRICT); } // C99 |
|---|
| 244 | __restrict { KEYWORD_RETURN(RESTRICT); } // GCC |
|---|
| 245 | __restrict__ { KEYWORD_RETURN(RESTRICT); } // GCC |
|---|
| 246 | return { KEYWORD_RETURN(RETURN); } |
|---|
| 247 | short { KEYWORD_RETURN(SHORT); } |
|---|
| 248 | signed { KEYWORD_RETURN(SIGNED); } |
|---|
| 249 | __signed { KEYWORD_RETURN(SIGNED); } // GCC |
|---|
| 250 | __signed__ { KEYWORD_RETURN(SIGNED); } // GCC |
|---|
| 251 | sizeof { KEYWORD_RETURN(SIZEOF); } |
|---|
| 252 | static { KEYWORD_RETURN(STATIC); } |
|---|
| 253 | _Static_assert { KEYWORD_RETURN(STATICASSERT); } // C11 |
|---|
| 254 | struct { KEYWORD_RETURN(STRUCT); } |
|---|
| 255 | switch { KEYWORD_RETURN(SWITCH); } |
|---|
| 256 | _Thread_local { KEYWORD_RETURN(THREADLOCAL); } // C11 |
|---|
| 257 | throw { KEYWORD_RETURN(THROW); } // CFA |
|---|
| 258 | throwResume { KEYWORD_RETURN(THROWRESUME); } // CFA |
|---|
| 259 | trait { KEYWORD_RETURN(TRAIT); } // CFA |
|---|
| 260 | try { KEYWORD_RETURN(TRY); } // CFA |
|---|
| 261 | ttype { KEYWORD_RETURN(TTYPE); } // CFA |
|---|
| 262 | typedef { KEYWORD_RETURN(TYPEDEF); } |
|---|
| 263 | typeof { KEYWORD_RETURN(TYPEOF); } // GCC |
|---|
| 264 | __typeof { KEYWORD_RETURN(TYPEOF); } // GCC |
|---|
| 265 | __typeof__ { KEYWORD_RETURN(TYPEOF); } // GCC |
|---|
| 266 | union { KEYWORD_RETURN(UNION); } |
|---|
| 267 | unsigned { KEYWORD_RETURN(UNSIGNED); } |
|---|
| 268 | __builtin_va_list { KEYWORD_RETURN(VALIST); } // GCC |
|---|
| 269 | void { KEYWORD_RETURN(VOID); } |
|---|
| 270 | volatile { KEYWORD_RETURN(VOLATILE); } |
|---|
| 271 | __volatile { KEYWORD_RETURN(VOLATILE); } // GCC |
|---|
| 272 | __volatile__ { KEYWORD_RETURN(VOLATILE); } // GCC |
|---|
| 273 | while { KEYWORD_RETURN(WHILE); } |
|---|
| 274 | zero_t { NUMERIC_RETURN(ZERO_T); } // CFA |
|---|
| 275 | |
|---|
| 276 | /* identifier */ |
|---|
| 277 | {identifier} { IDENTIFIER_RETURN(); } |
|---|
| 278 | {attr_identifier} { ATTRIBUTE_RETURN(); } |
|---|
| 279 | "`" { BEGIN BKQUOTE; } |
|---|
| 280 | <BKQUOTE>{identifier} { IDENTIFIER_RETURN(); } |
|---|
| 281 | <BKQUOTE>"`" { BEGIN 0; } |
|---|
| 282 | |
|---|
| 283 | /* numeric constants */ |
|---|
| 284 | "0" { NUMERIC_RETURN(ZERO); } // CFA |
|---|
| 285 | "1" { NUMERIC_RETURN(ONE); } // CFA |
|---|
| 286 | {decimal_constant} { NUMERIC_RETURN(INTEGERconstant); } |
|---|
| 287 | {octal_constant} { NUMERIC_RETURN(INTEGERconstant); } |
|---|
| 288 | {hex_constant} { NUMERIC_RETURN(INTEGERconstant); } |
|---|
| 289 | {real_decimal} { NUMERIC_RETURN(REALDECIMALconstant); } // must appear before floating_constant |
|---|
| 290 | {real_fraction} { NUMERIC_RETURN(REALFRACTIONconstant); } // must appear before floating_constant |
|---|
| 291 | {floating_constant} { NUMERIC_RETURN(FLOATINGconstant); } |
|---|
| 292 | {hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); } |
|---|
| 293 | |
|---|
| 294 | /* character constant, allows empty value */ |
|---|
| 295 | ({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new std::string( yytext, yyleng ); } |
|---|
| 296 | <QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); } |
|---|
| 297 | <QUOTE>['\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); } |
|---|
| 298 | /* ' stop highlighting */ |
|---|
| 299 | |
|---|
| 300 | /* string constant */ |
|---|
| 301 | ({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new std::string( yytext, yyleng ); } |
|---|
| 302 | <STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); } |
|---|
| 303 | <STRING>["\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); } |
|---|
| 304 | /* " stop highlighting */ |
|---|
| 305 | |
|---|
| 306 | /* common character/string constant */ |
|---|
| 307 | <QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); } |
|---|
| 308 | <QUOTE,STRING>"\\"{h_white}*"\n" {} // continuation (ALSO HANDLED BY CPP) |
|---|
| 309 | <QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character |
|---|
| 310 | |
|---|
| 311 | /* punctuation */ |
|---|
| 312 | "[" { ASCIIOP_RETURN(); } |
|---|
| 313 | "]" { ASCIIOP_RETURN(); } |
|---|
| 314 | "(" { ASCIIOP_RETURN(); } |
|---|
| 315 | ")" { ASCIIOP_RETURN(); } |
|---|
| 316 | "{" { ASCIIOP_RETURN(); } |
|---|
| 317 | "}" { ASCIIOP_RETURN(); } |
|---|
| 318 | "," { ASCIIOP_RETURN(); } // also operator |
|---|
| 319 | ":" { ASCIIOP_RETURN(); } |
|---|
| 320 | ";" { ASCIIOP_RETURN(); } |
|---|
| 321 | "." { ASCIIOP_RETURN(); } // also operator |
|---|
| 322 | "..." { NAMEDOP_RETURN(ELLIPSIS); } |
|---|
| 323 | |
|---|
| 324 | /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */ |
|---|
| 325 | "<:" { RETURN_VAL('['); } |
|---|
| 326 | ":>" { RETURN_VAL(']'); } |
|---|
| 327 | "<%" { RETURN_VAL('{'); } |
|---|
| 328 | "%>" { RETURN_VAL('}'); } |
|---|
| 329 | |
|---|
| 330 | /* operators */ |
|---|
| 331 | "!" { ASCIIOP_RETURN(); } |
|---|
| 332 | "+" { ASCIIOP_RETURN(); } |
|---|
| 333 | "-" { ASCIIOP_RETURN(); } |
|---|
| 334 | "*" { ASCIIOP_RETURN(); } |
|---|
| 335 | "/" { ASCIIOP_RETURN(); } |
|---|
| 336 | "%" { ASCIIOP_RETURN(); } |
|---|
| 337 | "^" { ASCIIOP_RETURN(); } |
|---|
| 338 | "~" { ASCIIOP_RETURN(); } |
|---|
| 339 | "&" { ASCIIOP_RETURN(); } |
|---|
| 340 | "|" { ASCIIOP_RETURN(); } |
|---|
| 341 | "<" { ASCIIOP_RETURN(); } |
|---|
| 342 | ">" { ASCIIOP_RETURN(); } |
|---|
| 343 | "=" { ASCIIOP_RETURN(); } |
|---|
| 344 | "?" { ASCIIOP_RETURN(); } |
|---|
| 345 | |
|---|
| 346 | "++" { NAMEDOP_RETURN(ICR); } |
|---|
| 347 | "--" { NAMEDOP_RETURN(DECR); } |
|---|
| 348 | "==" { NAMEDOP_RETURN(EQ); } |
|---|
| 349 | "!=" { NAMEDOP_RETURN(NE); } |
|---|
| 350 | "<<" { NAMEDOP_RETURN(LS); } |
|---|
| 351 | ">>" { NAMEDOP_RETURN(RS); } |
|---|
| 352 | "<=" { NAMEDOP_RETURN(LE); } |
|---|
| 353 | ">=" { NAMEDOP_RETURN(GE); } |
|---|
| 354 | "&&" { NAMEDOP_RETURN(ANDAND); } |
|---|
| 355 | "||" { NAMEDOP_RETURN(OROR); } |
|---|
| 356 | "->" { NAMEDOP_RETURN(ARROW); } |
|---|
| 357 | "+=" { NAMEDOP_RETURN(PLUSassign); } |
|---|
| 358 | "-=" { NAMEDOP_RETURN(MINUSassign); } |
|---|
| 359 | "*=" { NAMEDOP_RETURN(MULTassign); } |
|---|
| 360 | "/=" { NAMEDOP_RETURN(DIVassign); } |
|---|
| 361 | "%=" { NAMEDOP_RETURN(MODassign); } |
|---|
| 362 | "&=" { NAMEDOP_RETURN(ANDassign); } |
|---|
| 363 | "|=" { NAMEDOP_RETURN(ORassign); } |
|---|
| 364 | "^=" { NAMEDOP_RETURN(ERassign); } |
|---|
| 365 | "<<=" { NAMEDOP_RETURN(LSassign); } |
|---|
| 366 | ">>=" { NAMEDOP_RETURN(RSassign); } |
|---|
| 367 | |
|---|
| 368 | "@=" { NAMEDOP_RETURN(ATassign); } // CFA |
|---|
| 369 | |
|---|
| 370 | /* CFA, operator identifier */ |
|---|
| 371 | {op_unary}"?" { IDENTIFIER_RETURN(); } // unary |
|---|
| 372 | "?"({op_unary_pre_post}|"()"|"[?]"|"{}") { IDENTIFIER_RETURN(); } |
|---|
| 373 | "^?{}" { IDENTIFIER_RETURN(); } |
|---|
| 374 | "?"{op_binary_over}"?" { IDENTIFIER_RETURN(); } // binary |
|---|
| 375 | /* |
|---|
| 376 | This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the string "*?*?" |
|---|
| 377 | can be lexed as "*"/"?*?" or "*?"/"*?". Since it is common practise to put a unary operator juxtaposed |
|---|
| 378 | to an identifier, e.g., "*i", users will be annoyed if they cannot do this with respect to operator |
|---|
| 379 | identifiers. Even with this special hack, there are 5 general cases that cannot be handled. The first |
|---|
| 380 | case is for the function-call identifier "?()": |
|---|
| 381 | |
|---|
| 382 | int * ?()(); // declaration: space required after '*' |
|---|
| 383 | * ?()(); // expression: space required after '*' |
|---|
| 384 | |
|---|
| 385 | Without the space, the string "*?()" is ambiguous without N character look ahead; it requires scanning |
|---|
| 386 | ahead to determine if there is a '(', which is the start of an argument/parameter list. |
|---|
| 387 | |
|---|
| 388 | The 4 remaining cases occur in expressions: |
|---|
| 389 | |
|---|
| 390 | i++?i:0; // space required before '?' |
|---|
| 391 | i--?i:0; // space required before '?' |
|---|
| 392 | i?++i:0; // space required after '?' |
|---|
| 393 | i?--i:0; // space required after '?' |
|---|
| 394 | |
|---|
| 395 | In the first two cases, the string "i++?" is ambiguous, where this string can be lexed as "i"/"++?" or |
|---|
| 396 | "i++"/"?"; it requires scanning ahead to determine if there is a '(', which is the start of an argument |
|---|
| 397 | list. In the second two cases, the string "?++x" is ambiguous, where this string can be lexed as |
|---|
| 398 | "?++"/"x" or "?"/"++x"; it requires scanning ahead to determine if there is a '(', which is the start of |
|---|
| 399 | an argument list. |
|---|
| 400 | */ |
|---|
| 401 | {op_unary}"?"({op_unary_pre_post}|"[?]"|{op_binary_over}"?") { |
|---|
| 402 | // 1 or 2 character unary operator ? |
|---|
| 403 | int i = yytext[1] == '?' ? 1 : 2; |
|---|
| 404 | yyless( i ); // put back characters up to first '?' |
|---|
| 405 | if ( i > 1 ) { |
|---|
| 406 | NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR ); |
|---|
| 407 | } else { |
|---|
| 408 | ASCIIOP_RETURN(); |
|---|
| 409 | } // if |
|---|
| 410 | } |
|---|
| 411 | |
|---|
| 412 | /* unknown characters */ |
|---|
| 413 | . { printf("unknown character(s):\"%s\" on line %d\n", yytext, yylineno); } |
|---|
| 414 | |
|---|
| 415 | %% |
|---|
| 416 | |
|---|
| 417 | // Local Variables: // |
|---|
| 418 | // mode: c++ // |
|---|
| 419 | // tab-width: 4 // |
|---|
| 420 | // compile-command: "make install" // |
|---|
| 421 | // End: // |
|---|
