| 1 | /*
|
|---|
| 2 | * Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
|
|---|
| 3 | *
|
|---|
| 4 | * The contents of this file are covered under the licence agreement in the
|
|---|
| 5 | * file "LICENCE" distributed with Cforall.
|
|---|
| 6 | *
|
|---|
| 7 | * lex.l --
|
|---|
| 8 | *
|
|---|
| 9 | * Author : Peter A. Buhr
|
|---|
| 10 | * Created On : Sat Sep 22 08:58:10 2001
|
|---|
| 11 | * Last Modified By : Peter A. Buhr
|
|---|
| 12 | * Last Modified On : Wed Oct 26 17:32:30 2016
|
|---|
| 13 | * Update Count : 499
|
|---|
| 14 | */
|
|---|
| 15 |
|
|---|
| 16 | %option yylineno
|
|---|
| 17 | %option nounput
|
|---|
| 18 |
|
|---|
| 19 | %{
|
|---|
| 20 | // This lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
|
|---|
| 21 | // performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
|
|---|
| 22 | // line-number directives) and C/C++ style comments, which are ignored.
|
|---|
| 23 |
|
|---|
| 24 | //**************************** Includes and Defines ****************************
|
|---|
| 25 |
|
|---|
| 26 | #include <string>
|
|---|
| 27 | #include <cstdio> // FILENAME_MAX
|
|---|
| 28 |
|
|---|
| 29 | #include "lex.h"
|
|---|
| 30 | #include "parser.h" // YACC generated definitions based on C++ grammar
|
|---|
| 31 | #include "ParseNode.h"
|
|---|
| 32 | #include "TypedefTable.h"
|
|---|
| 33 |
|
|---|
| 34 | char *yyfilename;
|
|---|
| 35 | std::string *strtext; // accumulate parts of character and string constant value
|
|---|
| 36 |
|
|---|
| 37 | #define RETURN_LOCN(x) yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
|
|---|
| 38 | #define RETURN_VAL(x) yylval.tok.str = new std::string( yytext ); RETURN_LOCN( x )
|
|---|
| 39 | #define RETURN_CHAR(x) yylval.tok.str = nullptr; RETURN_LOCN( x )
|
|---|
| 40 | #define RETURN_STR(x) yylval.tok.str = strtext; RETURN_LOCN( x )
|
|---|
| 41 |
|
|---|
| 42 | #define WHITE_RETURN(x) // do nothing
|
|---|
| 43 | #define NEWLINE_RETURN() WHITE_RETURN( '\n' )
|
|---|
| 44 | #define ASCIIOP_RETURN() RETURN_CHAR( (int)yytext[0] ) // single character operator
|
|---|
| 45 | #define NAMEDOP_RETURN(x) RETURN_CHAR( x ) // multichar operator, with a name
|
|---|
| 46 | #define NUMERIC_RETURN(x) rm_underscore(); RETURN_VAL( x ) // numeric constant
|
|---|
| 47 | #define KEYWORD_RETURN(x) RETURN_CHAR( x ) // keyword
|
|---|
| 48 | #define IDENTIFIER_RETURN() RETURN_VAL( typedefTable.isKind( yytext ) )
|
|---|
| 49 | #define ATTRIBUTE_RETURN() RETURN_VAL( ATTR_IDENTIFIER )
|
|---|
| 50 |
|
|---|
| 51 | void rm_underscore() {
|
|---|
| 52 | // Remove underscores in numeric constant by copying the non-underscore characters to the front of the string.
|
|---|
| 53 | yyleng = 0;
|
|---|
| 54 | for ( int i = 0; yytext[i] != '\0'; i += 1 ) {
|
|---|
| 55 | if ( yytext[i] != '_' ) {
|
|---|
| 56 | yytext[yyleng] = yytext[i];
|
|---|
| 57 | yyleng += 1;
|
|---|
| 58 | } // if
|
|---|
| 59 | } // for
|
|---|
| 60 | yytext[yyleng] = '\0';
|
|---|
| 61 | }
|
|---|
| 62 |
|
|---|
| 63 | %}
|
|---|
| 64 |
|
|---|
| 65 | octal [0-7]
|
|---|
| 66 | nonzero [1-9]
|
|---|
| 67 | decimal [0-9]
|
|---|
| 68 | hex [0-9a-fA-F]
|
|---|
| 69 | universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2}))
|
|---|
| 70 |
|
|---|
| 71 | // identifier, GCC: $ in identifier
|
|---|
| 72 | identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})*
|
|---|
| 73 |
|
|---|
| 74 | // attribute identifier, GCC: $ in identifier
|
|---|
| 75 | attr_identifier "@"{identifier}
|
|---|
| 76 |
|
|---|
| 77 | // numeric constants, CFA: '_' in constant
|
|---|
| 78 | hex_quad {hex}("_"?{hex}){3}
|
|---|
| 79 | integer_suffix "_"?(([uU][lL]?)|([uU]("ll"|"LL")?)|([lL][uU]?)|("ll"|"LL")[uU]?)
|
|---|
| 80 |
|
|---|
| 81 | octal_digits ({octal})|({octal}({octal}|"_")*{octal})
|
|---|
| 82 | octal_prefix "0""_"?
|
|---|
| 83 | octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix}?
|
|---|
| 84 |
|
|---|
| 85 | nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal})
|
|---|
| 86 | decimal_constant {nonzero_digits}{integer_suffix}?
|
|---|
| 87 |
|
|---|
| 88 | hex_digits ({hex})|({hex}({hex}|"_")*{hex})
|
|---|
| 89 | hex_prefix "0"[xX]"_"?
|
|---|
| 90 | hex_constant {hex_prefix}{hex_digits}{integer_suffix}?
|
|---|
| 91 |
|
|---|
| 92 | decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal})
|
|---|
| 93 | real_decimal {decimal_digits}"."
|
|---|
| 94 | real_fraction "."{decimal_digits}
|
|---|
| 95 | real_constant {decimal_digits}?{real_fraction}
|
|---|
| 96 | exponent "_"?[eE]"_"?[+-]?{decimal_digits}
|
|---|
| 97 | // GCC: D (double), DL (long double) and iI (imaginary) suffixes
|
|---|
| 98 | floating_suffix "_"?([fFdDlL][iI]?|"DL"|[iI][lLfFdD]?)
|
|---|
| 99 | //floating_suffix "_"?([fFdD]|[lL]|[D][L])|([iI][lLfFdD])|([lLfFdD][iI]))
|
|---|
| 100 | floating_constant (({real_constant}{exponent}?)|({decimal_digits}{exponent})){floating_suffix}?
|
|---|
| 101 |
|
|---|
| 102 | binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
|
|---|
| 103 | hex_fractional_constant ({hex_digits}?"."{hex_digits})|({hex_digits}".")
|
|---|
| 104 | hex_floating_constant {hex_prefix}(({hex_fractional_constant}{binary_exponent})|({hex_digits}{binary_exponent})){floating_suffix}?
|
|---|
| 105 |
|
|---|
| 106 | // character escape sequence, GCC: \e => esc character
|
|---|
| 107 | simple_escape "\\"[abefnrtv'"?\\]
|
|---|
| 108 | // ' stop highlighting
|
|---|
| 109 | octal_escape "\\"{octal}("_"?{octal}){0,2}
|
|---|
| 110 | hex_escape "\\""x""_"?{hex_digits}
|
|---|
| 111 | escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char}
|
|---|
| 112 | cwide_prefix "L"|"U"|"u"
|
|---|
| 113 | swide_prefix {cwide_prefix}|"u8"
|
|---|
| 114 |
|
|---|
| 115 | // display/white-space characters
|
|---|
| 116 | h_tab [\011]
|
|---|
| 117 | form_feed [\014]
|
|---|
| 118 | v_tab [\013]
|
|---|
| 119 | c_return [\015]
|
|---|
| 120 | h_white [ ]|{h_tab}
|
|---|
| 121 |
|
|---|
| 122 | // overloadable operators
|
|---|
| 123 | op_unary_only "~"|"!"
|
|---|
| 124 | op_unary_binary "+"|"-"|"*"
|
|---|
| 125 | op_unary_pre_post "++"|"--"
|
|---|
| 126 | op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post}
|
|---|
| 127 |
|
|---|
| 128 | op_binary_only "/"|"%"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"&="|"|="|"^="|"<<="|">>="
|
|---|
| 129 | op_binary_over {op_unary_binary}|{op_binary_only}
|
|---|
| 130 | // op_binary_not_over "?"|"->"|"."|"&&"|"||"|"@="
|
|---|
| 131 | // operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over}
|
|---|
| 132 |
|
|---|
| 133 | %x COMMENT
|
|---|
| 134 | %x BKQUOTE
|
|---|
| 135 | %x QUOTE
|
|---|
| 136 | %x STRING
|
|---|
| 137 |
|
|---|
| 138 | %%
|
|---|
| 139 | /* line directives */
|
|---|
| 140 | ^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["].*"\n" {
|
|---|
| 141 | /* " stop highlighting */
|
|---|
| 142 | static char filename[FILENAME_MAX]; // temporarily store current source-file name
|
|---|
| 143 | char *end_num;
|
|---|
| 144 | char *begin_string, *end_string;
|
|---|
| 145 | long lineno, length;
|
|---|
| 146 | lineno = strtol( yytext + 1, &end_num, 0 );
|
|---|
| 147 | begin_string = strchr( end_num, '"' );
|
|---|
| 148 | if ( begin_string ) { // file name ?
|
|---|
| 149 | end_string = strchr( begin_string + 1, '"' ); // look for ending delimiter
|
|---|
| 150 | assert( end_string ); // closing quote ?
|
|---|
| 151 | length = end_string - begin_string - 1; // file-name length without quotes or sentinel
|
|---|
| 152 | assert( length < FILENAME_MAX ); // room for sentinel ?
|
|---|
| 153 | memcpy( &filename, begin_string + 1, length ); // copy file name from yytext
|
|---|
| 154 | filename[ length ] = '\0'; // terminate string with sentinel
|
|---|
| 155 | //std::cout << "file " << filename << " line " << lineno << std::endl;
|
|---|
| 156 | yylineno = lineno;
|
|---|
| 157 | yyfilename = filename;
|
|---|
| 158 | } // if
|
|---|
| 159 | }
|
|---|
| 160 |
|
|---|
| 161 | /* ignore preprocessor directives (for now) */
|
|---|
| 162 | ^{h_white}*"#"[^\n]*"\n" ;
|
|---|
| 163 |
|
|---|
| 164 | /* ignore C style comments (ALSO HANDLED BY CPP) */
|
|---|
| 165 | "/*" { BEGIN COMMENT; }
|
|---|
| 166 | <COMMENT>.|\n ;
|
|---|
| 167 | <COMMENT>"*/" { BEGIN 0; }
|
|---|
| 168 |
|
|---|
| 169 | /* ignore C++ style comments (ALSO HANDLED BY CPP) */
|
|---|
| 170 | "//"[^\n]*"\n" ;
|
|---|
| 171 |
|
|---|
| 172 | /* ignore whitespace */
|
|---|
| 173 | {h_white}+ { WHITE_RETURN(' '); }
|
|---|
| 174 | ({v_tab}|{c_return}|{form_feed})+ { WHITE_RETURN(' '); }
|
|---|
| 175 | ({h_white}|{v_tab}|{c_return}|{form_feed})*"\n" { NEWLINE_RETURN(); }
|
|---|
| 176 |
|
|---|
| 177 | /* keywords */
|
|---|
| 178 | _Alignas { KEYWORD_RETURN(ALIGNAS); } // C11
|
|---|
| 179 | _Alignof { KEYWORD_RETURN(ALIGNOF); } // C11
|
|---|
| 180 | __alignof { KEYWORD_RETURN(ALIGNOF); } // GCC
|
|---|
| 181 | __alignof__ { KEYWORD_RETURN(ALIGNOF); } // GCC
|
|---|
| 182 | asm { KEYWORD_RETURN(ASM); }
|
|---|
| 183 | __asm { KEYWORD_RETURN(ASM); } // GCC
|
|---|
| 184 | __asm__ { KEYWORD_RETURN(ASM); } // GCC
|
|---|
| 185 | _At { KEYWORD_RETURN(AT); } // CFA
|
|---|
| 186 | _Atomic { KEYWORD_RETURN(ATOMIC); } // C11
|
|---|
| 187 | __attribute { KEYWORD_RETURN(ATTRIBUTE); } // GCC
|
|---|
| 188 | __attribute__ { KEYWORD_RETURN(ATTRIBUTE); } // GCC
|
|---|
| 189 | auto { KEYWORD_RETURN(AUTO); }
|
|---|
| 190 | _Bool { KEYWORD_RETURN(BOOL); } // C99
|
|---|
| 191 | break { KEYWORD_RETURN(BREAK); }
|
|---|
| 192 | case { KEYWORD_RETURN(CASE); }
|
|---|
| 193 | catch { KEYWORD_RETURN(CATCH); } // CFA
|
|---|
| 194 | catchResume { KEYWORD_RETURN(CATCHRESUME); } // CFA
|
|---|
| 195 | char { KEYWORD_RETURN(CHAR); }
|
|---|
| 196 | choose { KEYWORD_RETURN(CHOOSE); } // CFA
|
|---|
| 197 | _Complex { KEYWORD_RETURN(COMPLEX); } // C99
|
|---|
| 198 | __complex { KEYWORD_RETURN(COMPLEX); } // GCC
|
|---|
| 199 | __complex__ { KEYWORD_RETURN(COMPLEX); } // GCC
|
|---|
| 200 | const { KEYWORD_RETURN(CONST); }
|
|---|
| 201 | __const { KEYWORD_RETURN(CONST); } // GCC
|
|---|
| 202 | __const__ { KEYWORD_RETURN(CONST); } // GCC
|
|---|
| 203 | continue { KEYWORD_RETURN(CONTINUE); }
|
|---|
| 204 | default { KEYWORD_RETURN(DEFAULT); }
|
|---|
| 205 | disable { KEYWORD_RETURN(DISABLE); } // CFA
|
|---|
| 206 | do { KEYWORD_RETURN(DO); }
|
|---|
| 207 | double { KEYWORD_RETURN(DOUBLE); }
|
|---|
| 208 | dtype { KEYWORD_RETURN(DTYPE); } // CFA
|
|---|
| 209 | else { KEYWORD_RETURN(ELSE); }
|
|---|
| 210 | enable { KEYWORD_RETURN(ENABLE); } // CFA
|
|---|
| 211 | enum { KEYWORD_RETURN(ENUM); }
|
|---|
| 212 | __extension__ { KEYWORD_RETURN(EXTENSION); } // GCC
|
|---|
| 213 | extern { KEYWORD_RETURN(EXTERN); }
|
|---|
| 214 | fallthrough { KEYWORD_RETURN(FALLTHRU); } // CFA
|
|---|
| 215 | fallthru { KEYWORD_RETURN(FALLTHRU); } // CFA
|
|---|
| 216 | finally { KEYWORD_RETURN(FINALLY); } // CFA
|
|---|
| 217 | float { KEYWORD_RETURN(FLOAT); }
|
|---|
| 218 | __float128 { KEYWORD_RETURN(FLOAT); } // GCC
|
|---|
| 219 | for { KEYWORD_RETURN(FOR); }
|
|---|
| 220 | forall { KEYWORD_RETURN(FORALL); } // CFA
|
|---|
| 221 | fortran { KEYWORD_RETURN(FORTRAN); }
|
|---|
| 222 | ftype { KEYWORD_RETURN(FTYPE); } // CFA
|
|---|
| 223 | _Generic { KEYWORD_RETURN(GENERIC); } // C11
|
|---|
| 224 | goto { KEYWORD_RETURN(GOTO); }
|
|---|
| 225 | if { KEYWORD_RETURN(IF); }
|
|---|
| 226 | _Imaginary { KEYWORD_RETURN(IMAGINARY); } // C99
|
|---|
| 227 | __imag { KEYWORD_RETURN(IMAGINARY); } // GCC
|
|---|
| 228 | __imag__ { KEYWORD_RETURN(IMAGINARY); } // GCC
|
|---|
| 229 | inline { KEYWORD_RETURN(INLINE); } // C99
|
|---|
| 230 | __inline { KEYWORD_RETURN(INLINE); } // GCC
|
|---|
| 231 | __inline__ { KEYWORD_RETURN(INLINE); } // GCC
|
|---|
| 232 | int { KEYWORD_RETURN(INT); }
|
|---|
| 233 | __int128 { KEYWORD_RETURN(INT); } // GCC
|
|---|
| 234 | __label__ { KEYWORD_RETURN(LABEL); } // GCC
|
|---|
| 235 | long { KEYWORD_RETURN(LONG); }
|
|---|
| 236 | lvalue { KEYWORD_RETURN(LVALUE); } // CFA
|
|---|
| 237 | _Noreturn { KEYWORD_RETURN(NORETURN); } // C11
|
|---|
| 238 | __builtin_offsetof { KEYWORD_RETURN(OFFSETOF); } // GCC
|
|---|
| 239 | otype { KEYWORD_RETURN(OTYPE); } // CFA
|
|---|
| 240 | register { KEYWORD_RETURN(REGISTER); }
|
|---|
| 241 | restrict { KEYWORD_RETURN(RESTRICT); } // C99
|
|---|
| 242 | __restrict { KEYWORD_RETURN(RESTRICT); } // GCC
|
|---|
| 243 | __restrict__ { KEYWORD_RETURN(RESTRICT); } // GCC
|
|---|
| 244 | return { KEYWORD_RETURN(RETURN); }
|
|---|
| 245 | short { KEYWORD_RETURN(SHORT); }
|
|---|
| 246 | signed { KEYWORD_RETURN(SIGNED); }
|
|---|
| 247 | __signed { KEYWORD_RETURN(SIGNED); } // GCC
|
|---|
| 248 | __signed__ { KEYWORD_RETURN(SIGNED); } // GCC
|
|---|
| 249 | sizeof { KEYWORD_RETURN(SIZEOF); }
|
|---|
| 250 | static { KEYWORD_RETURN(STATIC); }
|
|---|
| 251 | _Static_assert { KEYWORD_RETURN(STATICASSERT); } // C11
|
|---|
| 252 | struct { KEYWORD_RETURN(STRUCT); }
|
|---|
| 253 | switch { KEYWORD_RETURN(SWITCH); }
|
|---|
| 254 | _Thread_local { KEYWORD_RETURN(THREADLOCAL); } // C11
|
|---|
| 255 | throw { KEYWORD_RETURN(THROW); } // CFA
|
|---|
| 256 | throwResume { KEYWORD_RETURN(THROWRESUME); } // CFA
|
|---|
| 257 | trait { KEYWORD_RETURN(TRAIT); } // CFA
|
|---|
| 258 | try { KEYWORD_RETURN(TRY); } // CFA
|
|---|
| 259 | typedef { KEYWORD_RETURN(TYPEDEF); }
|
|---|
| 260 | typeof { KEYWORD_RETURN(TYPEOF); } // GCC
|
|---|
| 261 | __typeof { KEYWORD_RETURN(TYPEOF); } // GCC
|
|---|
| 262 | __typeof__ { KEYWORD_RETURN(TYPEOF); } // GCC
|
|---|
| 263 | union { KEYWORD_RETURN(UNION); }
|
|---|
| 264 | unsigned { KEYWORD_RETURN(UNSIGNED); }
|
|---|
| 265 | __builtin_va_list { KEYWORD_RETURN(VALIST); } // GCC
|
|---|
| 266 | void { KEYWORD_RETURN(VOID); }
|
|---|
| 267 | volatile { KEYWORD_RETURN(VOLATILE); }
|
|---|
| 268 | __volatile { KEYWORD_RETURN(VOLATILE); } // GCC
|
|---|
| 269 | __volatile__ { KEYWORD_RETURN(VOLATILE); } // GCC
|
|---|
| 270 | while { KEYWORD_RETURN(WHILE); }
|
|---|
| 271 |
|
|---|
| 272 | /* identifier */
|
|---|
| 273 | {identifier} { IDENTIFIER_RETURN(); }
|
|---|
| 274 | {attr_identifier} { ATTRIBUTE_RETURN(); }
|
|---|
| 275 | "`" { BEGIN BKQUOTE; }
|
|---|
| 276 | <BKQUOTE>{identifier} { IDENTIFIER_RETURN(); }
|
|---|
| 277 | <BKQUOTE>"`" { BEGIN 0; }
|
|---|
| 278 |
|
|---|
| 279 | /* numeric constants */
|
|---|
| 280 | "0" { NUMERIC_RETURN(ZERO); } // CFA
|
|---|
| 281 | "1" { NUMERIC_RETURN(ONE); } // CFA
|
|---|
| 282 | {decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
|
|---|
| 283 | {octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
|
|---|
| 284 | {hex_constant} { NUMERIC_RETURN(INTEGERconstant); }
|
|---|
| 285 | {real_decimal} { NUMERIC_RETURN(REALDECIMALconstant); } // must appear before floating_constant
|
|---|
| 286 | {real_fraction} { NUMERIC_RETURN(REALFRACTIONconstant); } // must appear before floating_constant
|
|---|
| 287 | {floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
|
|---|
| 288 | {hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
|
|---|
| 289 |
|
|---|
| 290 | /* character constant, allows empty value */
|
|---|
| 291 | ({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new std::string( yytext, yyleng ); }
|
|---|
| 292 | <QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); }
|
|---|
| 293 | <QUOTE>['\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); }
|
|---|
| 294 | /* ' stop highlighting */
|
|---|
| 295 |
|
|---|
| 296 | /* string constant */
|
|---|
| 297 | ({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new std::string( yytext, yyleng ); }
|
|---|
| 298 | <STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); }
|
|---|
| 299 | <STRING>["\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); }
|
|---|
| 300 | /* " stop highlighting */
|
|---|
| 301 |
|
|---|
| 302 | /* common character/string constant */
|
|---|
| 303 | <QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); }
|
|---|
| 304 | <QUOTE,STRING>"\\"{h_white}*"\n" {} // continuation (ALSO HANDLED BY CPP)
|
|---|
| 305 | <QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character
|
|---|
| 306 |
|
|---|
| 307 | /* punctuation */
|
|---|
| 308 | "[" { ASCIIOP_RETURN(); }
|
|---|
| 309 | "]" { ASCIIOP_RETURN(); }
|
|---|
| 310 | "(" { ASCIIOP_RETURN(); }
|
|---|
| 311 | ")" { ASCIIOP_RETURN(); }
|
|---|
| 312 | "{" { ASCIIOP_RETURN(); }
|
|---|
| 313 | "}" { ASCIIOP_RETURN(); }
|
|---|
| 314 | "," { ASCIIOP_RETURN(); } // also operator
|
|---|
| 315 | ":" { ASCIIOP_RETURN(); }
|
|---|
| 316 | ";" { ASCIIOP_RETURN(); }
|
|---|
| 317 | "." { ASCIIOP_RETURN(); } // also operator
|
|---|
| 318 | "..." { NAMEDOP_RETURN(ELLIPSIS); }
|
|---|
| 319 |
|
|---|
| 320 | /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
|
|---|
| 321 | "<:" { RETURN_VAL('['); }
|
|---|
| 322 | ":>" { RETURN_VAL(']'); }
|
|---|
| 323 | "<%" { RETURN_VAL('{'); }
|
|---|
| 324 | "%>" { RETURN_VAL('}'); }
|
|---|
| 325 |
|
|---|
| 326 | /* operators */
|
|---|
| 327 | "!" { ASCIIOP_RETURN(); }
|
|---|
| 328 | "+" { ASCIIOP_RETURN(); }
|
|---|
| 329 | "-" { ASCIIOP_RETURN(); }
|
|---|
| 330 | "*" { ASCIIOP_RETURN(); }
|
|---|
| 331 | "/" { ASCIIOP_RETURN(); }
|
|---|
| 332 | "%" { ASCIIOP_RETURN(); }
|
|---|
| 333 | "^" { ASCIIOP_RETURN(); }
|
|---|
| 334 | "~" { ASCIIOP_RETURN(); }
|
|---|
| 335 | "&" { ASCIIOP_RETURN(); }
|
|---|
| 336 | "|" { ASCIIOP_RETURN(); }
|
|---|
| 337 | "<" { ASCIIOP_RETURN(); }
|
|---|
| 338 | ">" { ASCIIOP_RETURN(); }
|
|---|
| 339 | "=" { ASCIIOP_RETURN(); }
|
|---|
| 340 | "?" { ASCIIOP_RETURN(); }
|
|---|
| 341 |
|
|---|
| 342 | "++" { NAMEDOP_RETURN(ICR); }
|
|---|
| 343 | "--" { NAMEDOP_RETURN(DECR); }
|
|---|
| 344 | "==" { NAMEDOP_RETURN(EQ); }
|
|---|
| 345 | "!=" { NAMEDOP_RETURN(NE); }
|
|---|
| 346 | "<<" { NAMEDOP_RETURN(LS); }
|
|---|
| 347 | ">>" { NAMEDOP_RETURN(RS); }
|
|---|
| 348 | "<=" { NAMEDOP_RETURN(LE); }
|
|---|
| 349 | ">=" { NAMEDOP_RETURN(GE); }
|
|---|
| 350 | "&&" { NAMEDOP_RETURN(ANDAND); }
|
|---|
| 351 | "||" { NAMEDOP_RETURN(OROR); }
|
|---|
| 352 | "->" { NAMEDOP_RETURN(ARROW); }
|
|---|
| 353 | "+=" { NAMEDOP_RETURN(PLUSassign); }
|
|---|
| 354 | "-=" { NAMEDOP_RETURN(MINUSassign); }
|
|---|
| 355 | "*=" { NAMEDOP_RETURN(MULTassign); }
|
|---|
| 356 | "/=" { NAMEDOP_RETURN(DIVassign); }
|
|---|
| 357 | "%=" { NAMEDOP_RETURN(MODassign); }
|
|---|
| 358 | "&=" { NAMEDOP_RETURN(ANDassign); }
|
|---|
| 359 | "|=" { NAMEDOP_RETURN(ORassign); }
|
|---|
| 360 | "^=" { NAMEDOP_RETURN(ERassign); }
|
|---|
| 361 | "<<=" { NAMEDOP_RETURN(LSassign); }
|
|---|
| 362 | ">>=" { NAMEDOP_RETURN(RSassign); }
|
|---|
| 363 |
|
|---|
| 364 | "@=" { NAMEDOP_RETURN(ATassign); } // CFA
|
|---|
| 365 |
|
|---|
| 366 | /* CFA, operator identifier */
|
|---|
| 367 | {op_unary}"?" { IDENTIFIER_RETURN(); } // unary
|
|---|
| 368 | "?"({op_unary_pre_post}|"()"|"[?]"|"{}") { IDENTIFIER_RETURN(); }
|
|---|
| 369 | "^?{}" { IDENTIFIER_RETURN(); }
|
|---|
| 370 | "?"{op_binary_over}"?" { IDENTIFIER_RETURN(); } // binary
|
|---|
| 371 | /*
|
|---|
| 372 | This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the string "*?*?"
|
|---|
| 373 | can be lexed as "*"/"?*?" or "*?"/"*?". Since it is common practise to put a unary operator juxtaposed
|
|---|
| 374 | to an identifier, e.g., "*i", users will be annoyed if they cannot do this with respect to operator
|
|---|
| 375 | identifiers. Even with this special hack, there are 5 general cases that cannot be handled. The first
|
|---|
| 376 | case is for the function-call identifier "?()":
|
|---|
| 377 |
|
|---|
| 378 | int * ?()(); // declaration: space required after '*'
|
|---|
| 379 | * ?()(); // expression: space required after '*'
|
|---|
| 380 |
|
|---|
| 381 | Without the space, the string "*?()" is ambiguous without N character look ahead; it requires scanning
|
|---|
| 382 | ahead to determine if there is a '(', which is the start of an argument/parameter list.
|
|---|
| 383 |
|
|---|
| 384 | The 4 remaining cases occur in expressions:
|
|---|
| 385 |
|
|---|
| 386 | i++?i:0; // space required before '?'
|
|---|
| 387 | i--?i:0; // space required before '?'
|
|---|
| 388 | i?++i:0; // space required after '?'
|
|---|
| 389 | i?--i:0; // space required after '?'
|
|---|
| 390 |
|
|---|
| 391 | In the first two cases, the string "i++?" is ambiguous, where this string can be lexed as "i"/"++?" or
|
|---|
| 392 | "i++"/"?"; it requires scanning ahead to determine if there is a '(', which is the start of an argument
|
|---|
| 393 | list. In the second two cases, the string "?++x" is ambiguous, where this string can be lexed as
|
|---|
| 394 | "?++"/"x" or "?"/"++x"; it requires scanning ahead to determine if there is a '(', which is the start of
|
|---|
| 395 | an argument list.
|
|---|
| 396 | */
|
|---|
| 397 | {op_unary}"?"({op_unary_pre_post}|"[?]"|{op_binary_over}"?") {
|
|---|
| 398 | // 1 or 2 character unary operator ?
|
|---|
| 399 | int i = yytext[1] == '?' ? 1 : 2;
|
|---|
| 400 | yyless( i ); // put back characters up to first '?'
|
|---|
| 401 | if ( i > 1 ) {
|
|---|
| 402 | NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
|
|---|
| 403 | } else {
|
|---|
| 404 | ASCIIOP_RETURN();
|
|---|
| 405 | } // if
|
|---|
| 406 | }
|
|---|
| 407 |
|
|---|
| 408 | /* unknown characters */
|
|---|
| 409 | . { printf("unknown character(s):\"%s\" on line %d\n", yytext, yylineno); }
|
|---|
| 410 |
|
|---|
| 411 | %%
|
|---|
| 412 |
|
|---|
| 413 | // Local Variables: //
|
|---|
| 414 | // mode: c++ //
|
|---|
| 415 | // tab-width: 4 //
|
|---|
| 416 | // compile-command: "make install" //
|
|---|
| 417 | // End: //
|
|---|
