| 1 | /*
|
|---|
| 2 | * Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
|
|---|
| 3 | *
|
|---|
| 4 | * The contents of this file are covered under the licence agreement in the
|
|---|
| 5 | * file "LICENCE" distributed with Cforall.
|
|---|
| 6 | *
|
|---|
| 7 | * lex.l --
|
|---|
| 8 | *
|
|---|
| 9 | * Author : Peter A. Buhr
|
|---|
| 10 | * Created On : Sat Sep 22 08:58:10 2001
|
|---|
| 11 | * Last Modified By : Peter A. Buhr
|
|---|
| 12 | * Last Modified On : Mon Mar 13 08:36:17 2017
|
|---|
| 13 | * Update Count : 506
|
|---|
| 14 | */
|
|---|
| 15 |
|
|---|
| 16 | %option yylineno
|
|---|
| 17 | %option nounput
|
|---|
| 18 |
|
|---|
| 19 | %{
|
|---|
| 20 | // This lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
|
|---|
| 21 | // performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
|
|---|
| 22 | // line-number directives) and C/C++ style comments, which are ignored.
|
|---|
| 23 |
|
|---|
| 24 | //**************************** Includes and Defines ****************************
|
|---|
| 25 |
|
|---|
| 26 | #include <string>
|
|---|
| 27 | #include <cstdio> // FILENAME_MAX
|
|---|
| 28 |
|
|---|
| 29 | #include "lex.h"
|
|---|
| 30 | #include "parser.h" // YACC generated definitions based on C++ grammar
|
|---|
| 31 | #include "ParseNode.h"
|
|---|
| 32 | #include "TypedefTable.h"
|
|---|
| 33 |
|
|---|
| 34 | char *yyfilename;
|
|---|
| 35 | std::string *strtext; // accumulate parts of character and string constant value
|
|---|
| 36 |
|
|---|
| 37 | #define RETURN_LOCN(x) yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
|
|---|
| 38 | #define RETURN_VAL(x) yylval.tok.str = new std::string( yytext ); RETURN_LOCN( x )
|
|---|
| 39 | #define RETURN_CHAR(x) yylval.tok.str = nullptr; RETURN_LOCN( x )
|
|---|
| 40 | #define RETURN_STR(x) yylval.tok.str = strtext; RETURN_LOCN( x )
|
|---|
| 41 |
|
|---|
| 42 | #define WHITE_RETURN(x) // do nothing
|
|---|
| 43 | #define NEWLINE_RETURN() WHITE_RETURN( '\n' )
|
|---|
| 44 | #define ASCIIOP_RETURN() RETURN_CHAR( (int)yytext[0] ) // single character operator
|
|---|
| 45 | #define NAMEDOP_RETURN(x) RETURN_CHAR( x ) // multichar operator, with a name
|
|---|
| 46 | #define NUMERIC_RETURN(x) rm_underscore(); RETURN_VAL( x ) // numeric constant
|
|---|
| 47 | #define KEYWORD_RETURN(x) RETURN_CHAR( x ) // keyword
|
|---|
| 48 | #define IDENTIFIER_RETURN() RETURN_VAL( typedefTable.isKind( yytext ) )
|
|---|
| 49 | #define ATTRIBUTE_RETURN() RETURN_VAL( ATTR_IDENTIFIER )
|
|---|
| 50 |
|
|---|
| 51 | void rm_underscore() {
|
|---|
| 52 | // Remove underscores in numeric constant by copying the non-underscore characters to the front of the string.
|
|---|
| 53 | yyleng = 0;
|
|---|
| 54 | for ( int i = 0; yytext[i] != '\0'; i += 1 ) {
|
|---|
| 55 | if ( yytext[i] != '_' ) {
|
|---|
| 56 | yytext[yyleng] = yytext[i];
|
|---|
| 57 | yyleng += 1;
|
|---|
| 58 | } // if
|
|---|
| 59 | } // for
|
|---|
| 60 | yytext[yyleng] = '\0';
|
|---|
| 61 | }
|
|---|
| 62 |
|
|---|
| 63 | %}
|
|---|
| 64 |
|
|---|
| 65 | octal [0-7]
|
|---|
| 66 | nonzero [1-9]
|
|---|
| 67 | decimal [0-9]
|
|---|
| 68 | hex [0-9a-fA-F]
|
|---|
| 69 | universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2}))
|
|---|
| 70 |
|
|---|
| 71 | // identifier, GCC: $ in identifier
|
|---|
| 72 | identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})*
|
|---|
| 73 |
|
|---|
| 74 | // attribute identifier, GCC: $ in identifier
|
|---|
| 75 | attr_identifier "@"{identifier}
|
|---|
| 76 |
|
|---|
| 77 | // numeric constants, CFA: '_' in constant
|
|---|
| 78 | hex_quad {hex}("_"?{hex}){3}
|
|---|
| 79 | integer_suffix "_"?(([uU][lL]?)|([uU]("ll"|"LL")?)|([lL][uU]?)|("ll"|"LL")[uU]?)
|
|---|
| 80 |
|
|---|
| 81 | octal_digits ({octal})|({octal}({octal}|"_")*{octal})
|
|---|
| 82 | octal_prefix "0""_"?
|
|---|
| 83 | octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix}?
|
|---|
| 84 |
|
|---|
| 85 | nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal})
|
|---|
| 86 | decimal_constant {nonzero_digits}{integer_suffix}?
|
|---|
| 87 |
|
|---|
| 88 | hex_digits ({hex})|({hex}({hex}|"_")*{hex})
|
|---|
| 89 | hex_prefix "0"[xX]"_"?
|
|---|
| 90 | hex_constant {hex_prefix}{hex_digits}{integer_suffix}?
|
|---|
| 91 |
|
|---|
| 92 | decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal})
|
|---|
| 93 | real_decimal {decimal_digits}"."
|
|---|
| 94 | real_fraction "."{decimal_digits}
|
|---|
| 95 | real_constant {decimal_digits}?{real_fraction}
|
|---|
| 96 | exponent "_"?[eE]"_"?[+-]?{decimal_digits}
|
|---|
| 97 | // GCC: D (double), DL (long double) and iI (imaginary) suffixes
|
|---|
| 98 | floating_suffix "_"?([fFdDlL][iI]?|"DL"|[iI][lLfFdD]?)
|
|---|
| 99 | //floating_suffix "_"?([fFdD]|[lL]|[D][L])|([iI][lLfFdD])|([lLfFdD][iI]))
|
|---|
| 100 | floating_constant (({real_constant}{exponent}?)|({decimal_digits}{exponent})){floating_suffix}?
|
|---|
| 101 |
|
|---|
| 102 | binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
|
|---|
| 103 | hex_fractional_constant ({hex_digits}?"."{hex_digits})|({hex_digits}".")
|
|---|
| 104 | hex_floating_constant {hex_prefix}(({hex_fractional_constant}{binary_exponent})|({hex_digits}{binary_exponent})){floating_suffix}?
|
|---|
| 105 |
|
|---|
| 106 | // character escape sequence, GCC: \e => esc character
|
|---|
| 107 | simple_escape "\\"[abefnrtv'"?\\]
|
|---|
| 108 | // ' stop highlighting
|
|---|
| 109 | octal_escape "\\"{octal}("_"?{octal}){0,2}
|
|---|
| 110 | hex_escape "\\""x""_"?{hex_digits}
|
|---|
| 111 | escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char}
|
|---|
| 112 | cwide_prefix "L"|"U"|"u"
|
|---|
| 113 | swide_prefix {cwide_prefix}|"u8"
|
|---|
| 114 |
|
|---|
| 115 | // display/white-space characters
|
|---|
| 116 | h_tab [\011]
|
|---|
| 117 | form_feed [\014]
|
|---|
| 118 | v_tab [\013]
|
|---|
| 119 | c_return [\015]
|
|---|
| 120 | h_white [ ]|{h_tab}
|
|---|
| 121 |
|
|---|
| 122 | // overloadable operators
|
|---|
| 123 | op_unary_only "~"|"!"
|
|---|
| 124 | op_unary_binary "+"|"-"|"*"
|
|---|
| 125 | op_unary_pre_post "++"|"--"
|
|---|
| 126 | op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post}
|
|---|
| 127 |
|
|---|
| 128 | op_binary_only "/"|"%"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"&="|"|="|"^="|"<<="|">>="
|
|---|
| 129 | op_binary_over {op_unary_binary}|{op_binary_only}
|
|---|
| 130 | // op_binary_not_over "?"|"->"|"."|"&&"|"||"|"@="
|
|---|
| 131 | // operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over}
|
|---|
| 132 |
|
|---|
| 133 | %x COMMENT
|
|---|
| 134 | %x BKQUOTE
|
|---|
| 135 | %x QUOTE
|
|---|
| 136 | %x STRING
|
|---|
| 137 |
|
|---|
| 138 | %%
|
|---|
| 139 | /* line directives */
|
|---|
| 140 | ^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["].*"\n" {
|
|---|
| 141 | /* " stop highlighting */
|
|---|
| 142 | static char filename[FILENAME_MAX]; // temporarily store current source-file name
|
|---|
| 143 | char *end_num;
|
|---|
| 144 | char *begin_string, *end_string;
|
|---|
| 145 | long lineno, length;
|
|---|
| 146 | lineno = strtol( yytext + 1, &end_num, 0 );
|
|---|
| 147 | begin_string = strchr( end_num, '"' );
|
|---|
| 148 | if ( begin_string ) { // file name ?
|
|---|
| 149 | end_string = strchr( begin_string + 1, '"' ); // look for ending delimiter
|
|---|
| 150 | assert( end_string ); // closing quote ?
|
|---|
| 151 | length = end_string - begin_string - 1; // file-name length without quotes or sentinel
|
|---|
| 152 | assert( length < FILENAME_MAX ); // room for sentinel ?
|
|---|
| 153 | memcpy( &filename, begin_string + 1, length ); // copy file name from yytext
|
|---|
| 154 | filename[ length ] = '\0'; // terminate string with sentinel
|
|---|
| 155 | //std::cout << "file " << filename << " line " << lineno << std::endl;
|
|---|
| 156 | yylineno = lineno;
|
|---|
| 157 | yyfilename = filename;
|
|---|
| 158 | } // if
|
|---|
| 159 | }
|
|---|
| 160 |
|
|---|
| 161 | /* ignore preprocessor directives (for now) */
|
|---|
| 162 | ^{h_white}*"#"[^\n]*"\n" ;
|
|---|
| 163 |
|
|---|
| 164 | /* ignore C style comments (ALSO HANDLED BY CPP) */
|
|---|
| 165 | "/*" { BEGIN COMMENT; }
|
|---|
| 166 | <COMMENT>.|\n ;
|
|---|
| 167 | <COMMENT>"*/" { BEGIN 0; }
|
|---|
| 168 |
|
|---|
| 169 | /* ignore C++ style comments (ALSO HANDLED BY CPP) */
|
|---|
| 170 | "//"[^\n]*"\n" ;
|
|---|
| 171 |
|
|---|
| 172 | /* ignore whitespace */
|
|---|
| 173 | {h_white}+ { WHITE_RETURN(' '); }
|
|---|
| 174 | ({v_tab}|{c_return}|{form_feed})+ { WHITE_RETURN(' '); }
|
|---|
| 175 | ({h_white}|{v_tab}|{c_return}|{form_feed})*"\n" { NEWLINE_RETURN(); }
|
|---|
| 176 |
|
|---|
| 177 | /* keywords */
|
|---|
| 178 | _Alignas { KEYWORD_RETURN(ALIGNAS); } // C11
|
|---|
| 179 | _Alignof { KEYWORD_RETURN(ALIGNOF); } // C11
|
|---|
| 180 | __alignof { KEYWORD_RETURN(ALIGNOF); } // GCC
|
|---|
| 181 | __alignof__ { KEYWORD_RETURN(ALIGNOF); } // GCC
|
|---|
| 182 | asm { KEYWORD_RETURN(ASM); }
|
|---|
| 183 | __asm { KEYWORD_RETURN(ASM); } // GCC
|
|---|
| 184 | __asm__ { KEYWORD_RETURN(ASM); } // GCC
|
|---|
| 185 | _At { KEYWORD_RETURN(AT); } // CFA
|
|---|
| 186 | _Atomic { KEYWORD_RETURN(ATOMIC); } // C11
|
|---|
| 187 | __attribute { KEYWORD_RETURN(ATTRIBUTE); } // GCC
|
|---|
| 188 | __attribute__ { KEYWORD_RETURN(ATTRIBUTE); } // GCC
|
|---|
| 189 | auto { KEYWORD_RETURN(AUTO); }
|
|---|
| 190 | _Bool { KEYWORD_RETURN(BOOL); } // C99
|
|---|
| 191 | break { KEYWORD_RETURN(BREAK); }
|
|---|
| 192 | case { KEYWORD_RETURN(CASE); }
|
|---|
| 193 | catch { KEYWORD_RETURN(CATCH); } // CFA
|
|---|
| 194 | catchResume { KEYWORD_RETURN(CATCHRESUME); } // CFA
|
|---|
| 195 | char { KEYWORD_RETURN(CHAR); }
|
|---|
| 196 | choose { KEYWORD_RETURN(CHOOSE); } // CFA
|
|---|
| 197 | _Complex { KEYWORD_RETURN(COMPLEX); } // C99
|
|---|
| 198 | __complex { KEYWORD_RETURN(COMPLEX); } // GCC
|
|---|
| 199 | __complex__ { KEYWORD_RETURN(COMPLEX); } // GCC
|
|---|
| 200 | const { KEYWORD_RETURN(CONST); }
|
|---|
| 201 | __const { KEYWORD_RETURN(CONST); } // GCC
|
|---|
| 202 | __const__ { KEYWORD_RETURN(CONST); } // GCC
|
|---|
| 203 | continue { KEYWORD_RETURN(CONTINUE); }
|
|---|
| 204 | coroutine { KEYWORD_RETURN(COROUTINE); } // CFA
|
|---|
| 205 | default { KEYWORD_RETURN(DEFAULT); }
|
|---|
| 206 | disable { KEYWORD_RETURN(DISABLE); } // CFA
|
|---|
| 207 | do { KEYWORD_RETURN(DO); }
|
|---|
| 208 | double { KEYWORD_RETURN(DOUBLE); }
|
|---|
| 209 | dtype { KEYWORD_RETURN(DTYPE); } // CFA
|
|---|
| 210 | else { KEYWORD_RETURN(ELSE); }
|
|---|
| 211 | enable { KEYWORD_RETURN(ENABLE); } // CFA
|
|---|
| 212 | enum { KEYWORD_RETURN(ENUM); }
|
|---|
| 213 | __extension__ { KEYWORD_RETURN(EXTENSION); } // GCC
|
|---|
| 214 | extern { KEYWORD_RETURN(EXTERN); }
|
|---|
| 215 | fallthrough { KEYWORD_RETURN(FALLTHRU); } // CFA
|
|---|
| 216 | fallthru { KEYWORD_RETURN(FALLTHRU); } // CFA
|
|---|
| 217 | finally { KEYWORD_RETURN(FINALLY); } // CFA
|
|---|
| 218 | float { KEYWORD_RETURN(FLOAT); }
|
|---|
| 219 | __float128 { KEYWORD_RETURN(FLOAT); } // GCC
|
|---|
| 220 | for { KEYWORD_RETURN(FOR); }
|
|---|
| 221 | forall { KEYWORD_RETURN(FORALL); } // CFA
|
|---|
| 222 | fortran { KEYWORD_RETURN(FORTRAN); }
|
|---|
| 223 | ftype { KEYWORD_RETURN(FTYPE); } // CFA
|
|---|
| 224 | _Generic { KEYWORD_RETURN(GENERIC); } // C11
|
|---|
| 225 | goto { KEYWORD_RETURN(GOTO); }
|
|---|
| 226 | if { KEYWORD_RETURN(IF); }
|
|---|
| 227 | _Imaginary { KEYWORD_RETURN(IMAGINARY); } // C99
|
|---|
| 228 | __imag { KEYWORD_RETURN(IMAGINARY); } // GCC
|
|---|
| 229 | __imag__ { KEYWORD_RETURN(IMAGINARY); } // GCC
|
|---|
| 230 | inline { KEYWORD_RETURN(INLINE); } // C99
|
|---|
| 231 | __inline { KEYWORD_RETURN(INLINE); } // GCC
|
|---|
| 232 | __inline__ { KEYWORD_RETURN(INLINE); } // GCC
|
|---|
| 233 | int { KEYWORD_RETURN(INT); }
|
|---|
| 234 | __int128 { KEYWORD_RETURN(INT); } // GCC
|
|---|
| 235 | __label__ { KEYWORD_RETURN(LABEL); } // GCC
|
|---|
| 236 | long { KEYWORD_RETURN(LONG); }
|
|---|
| 237 | lvalue { KEYWORD_RETURN(LVALUE); } // CFA
|
|---|
| 238 | monitor { KEYWORD_RETURN(MONITOR); } // CFA
|
|---|
| 239 | mutex { KEYWORD_RETURN(MUTEX); } // CFA
|
|---|
| 240 | _Noreturn { KEYWORD_RETURN(NORETURN); } // C11
|
|---|
| 241 | __builtin_offsetof { KEYWORD_RETURN(OFFSETOF); } // GCC
|
|---|
| 242 | one_t { NUMERIC_RETURN(ONE_T); } // CFA
|
|---|
| 243 | otype { KEYWORD_RETURN(OTYPE); } // CFA
|
|---|
| 244 | register { KEYWORD_RETURN(REGISTER); }
|
|---|
| 245 | restrict { KEYWORD_RETURN(RESTRICT); } // C99
|
|---|
| 246 | __restrict { KEYWORD_RETURN(RESTRICT); } // GCC
|
|---|
| 247 | __restrict__ { KEYWORD_RETURN(RESTRICT); } // GCC
|
|---|
| 248 | return { KEYWORD_RETURN(RETURN); }
|
|---|
| 249 | short { KEYWORD_RETURN(SHORT); }
|
|---|
| 250 | signed { KEYWORD_RETURN(SIGNED); }
|
|---|
| 251 | __signed { KEYWORD_RETURN(SIGNED); } // GCC
|
|---|
| 252 | __signed__ { KEYWORD_RETURN(SIGNED); } // GCC
|
|---|
| 253 | sizeof { KEYWORD_RETURN(SIZEOF); }
|
|---|
| 254 | static { KEYWORD_RETURN(STATIC); }
|
|---|
| 255 | _Static_assert { KEYWORD_RETURN(STATICASSERT); } // C11
|
|---|
| 256 | struct { KEYWORD_RETURN(STRUCT); }
|
|---|
| 257 | switch { KEYWORD_RETURN(SWITCH); }
|
|---|
| 258 | thread { KEYWORD_RETURN(THREAD); } // C11
|
|---|
| 259 | _Thread_local { KEYWORD_RETURN(THREADLOCAL); } // C11
|
|---|
| 260 | throw { KEYWORD_RETURN(THROW); } // CFA
|
|---|
| 261 | throwResume { KEYWORD_RETURN(THROWRESUME); } // CFA
|
|---|
| 262 | trait { KEYWORD_RETURN(TRAIT); } // CFA
|
|---|
| 263 | try { KEYWORD_RETURN(TRY); } // CFA
|
|---|
| 264 | ttype { KEYWORD_RETURN(TTYPE); } // CFA
|
|---|
| 265 | typedef { KEYWORD_RETURN(TYPEDEF); }
|
|---|
| 266 | typeof { KEYWORD_RETURN(TYPEOF); } // GCC
|
|---|
| 267 | __typeof { KEYWORD_RETURN(TYPEOF); } // GCC
|
|---|
| 268 | __typeof__ { KEYWORD_RETURN(TYPEOF); } // GCC
|
|---|
| 269 | union { KEYWORD_RETURN(UNION); }
|
|---|
| 270 | unsigned { KEYWORD_RETURN(UNSIGNED); }
|
|---|
| 271 | __builtin_va_list { KEYWORD_RETURN(VALIST); } // GCC
|
|---|
| 272 | void { KEYWORD_RETURN(VOID); }
|
|---|
| 273 | volatile { KEYWORD_RETURN(VOLATILE); }
|
|---|
| 274 | __volatile { KEYWORD_RETURN(VOLATILE); } // GCC
|
|---|
| 275 | __volatile__ { KEYWORD_RETURN(VOLATILE); } // GCC
|
|---|
| 276 | while { KEYWORD_RETURN(WHILE); }
|
|---|
| 277 | zero_t { NUMERIC_RETURN(ZERO_T); } // CFA
|
|---|
| 278 |
|
|---|
| 279 | /* identifier */
|
|---|
| 280 | {identifier} { IDENTIFIER_RETURN(); }
|
|---|
| 281 | {attr_identifier} { ATTRIBUTE_RETURN(); }
|
|---|
| 282 | "`" { BEGIN BKQUOTE; }
|
|---|
| 283 | <BKQUOTE>{identifier} { IDENTIFIER_RETURN(); }
|
|---|
| 284 | <BKQUOTE>"`" { BEGIN 0; }
|
|---|
| 285 |
|
|---|
| 286 | /* numeric constants */
|
|---|
| 287 | "0" { NUMERIC_RETURN(ZERO); } // CFA
|
|---|
| 288 | "1" { NUMERIC_RETURN(ONE); } // CFA
|
|---|
| 289 | {decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
|
|---|
| 290 | {octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
|
|---|
| 291 | {hex_constant} { NUMERIC_RETURN(INTEGERconstant); }
|
|---|
| 292 | {real_decimal} { NUMERIC_RETURN(REALDECIMALconstant); } // must appear before floating_constant
|
|---|
| 293 | {real_fraction} { NUMERIC_RETURN(REALFRACTIONconstant); } // must appear before floating_constant
|
|---|
| 294 | {floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
|
|---|
| 295 | {hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
|
|---|
| 296 |
|
|---|
| 297 | /* character constant, allows empty value */
|
|---|
| 298 | ({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new std::string( yytext, yyleng ); }
|
|---|
| 299 | <QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); }
|
|---|
| 300 | <QUOTE>['\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); }
|
|---|
| 301 | /* ' stop highlighting */
|
|---|
| 302 |
|
|---|
| 303 | /* string constant */
|
|---|
| 304 | ({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new std::string( yytext, yyleng ); }
|
|---|
| 305 | <STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); }
|
|---|
| 306 | <STRING>["\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); }
|
|---|
| 307 | /* " stop highlighting */
|
|---|
| 308 |
|
|---|
| 309 | /* common character/string constant */
|
|---|
| 310 | <QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); }
|
|---|
| 311 | <QUOTE,STRING>"\\"{h_white}*"\n" {} // continuation (ALSO HANDLED BY CPP)
|
|---|
| 312 | <QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character
|
|---|
| 313 |
|
|---|
| 314 | /* punctuation */
|
|---|
| 315 | "@" { ASCIIOP_RETURN(); }
|
|---|
| 316 | "[" { ASCIIOP_RETURN(); }
|
|---|
| 317 | "]" { ASCIIOP_RETURN(); }
|
|---|
| 318 | "(" { ASCIIOP_RETURN(); }
|
|---|
| 319 | ")" { ASCIIOP_RETURN(); }
|
|---|
| 320 | "{" { ASCIIOP_RETURN(); }
|
|---|
| 321 | "}" { ASCIIOP_RETURN(); }
|
|---|
| 322 | "," { ASCIIOP_RETURN(); } // also operator
|
|---|
| 323 | ":" { ASCIIOP_RETURN(); }
|
|---|
| 324 | ";" { ASCIIOP_RETURN(); }
|
|---|
| 325 | "." { ASCIIOP_RETURN(); } // also operator
|
|---|
| 326 | "..." { NAMEDOP_RETURN(ELLIPSIS); }
|
|---|
| 327 |
|
|---|
| 328 | /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
|
|---|
| 329 | "<:" { RETURN_VAL('['); }
|
|---|
| 330 | ":>" { RETURN_VAL(']'); }
|
|---|
| 331 | "<%" { RETURN_VAL('{'); }
|
|---|
| 332 | "%>" { RETURN_VAL('}'); }
|
|---|
| 333 |
|
|---|
| 334 | /* operators */
|
|---|
| 335 | "!" { ASCIIOP_RETURN(); }
|
|---|
| 336 | "+" { ASCIIOP_RETURN(); }
|
|---|
| 337 | "-" { ASCIIOP_RETURN(); }
|
|---|
| 338 | "*" { ASCIIOP_RETURN(); }
|
|---|
| 339 | "/" { ASCIIOP_RETURN(); }
|
|---|
| 340 | "%" { ASCIIOP_RETURN(); }
|
|---|
| 341 | "^" { ASCIIOP_RETURN(); }
|
|---|
| 342 | "~" { ASCIIOP_RETURN(); }
|
|---|
| 343 | "&" { ASCIIOP_RETURN(); }
|
|---|
| 344 | "|" { ASCIIOP_RETURN(); }
|
|---|
| 345 | "<" { ASCIIOP_RETURN(); }
|
|---|
| 346 | ">" { ASCIIOP_RETURN(); }
|
|---|
| 347 | "=" { ASCIIOP_RETURN(); }
|
|---|
| 348 | "?" { ASCIIOP_RETURN(); }
|
|---|
| 349 |
|
|---|
| 350 | "++" { NAMEDOP_RETURN(ICR); }
|
|---|
| 351 | "--" { NAMEDOP_RETURN(DECR); }
|
|---|
| 352 | "==" { NAMEDOP_RETURN(EQ); }
|
|---|
| 353 | "!=" { NAMEDOP_RETURN(NE); }
|
|---|
| 354 | "<<" { NAMEDOP_RETURN(LS); }
|
|---|
| 355 | ">>" { NAMEDOP_RETURN(RS); }
|
|---|
| 356 | "<=" { NAMEDOP_RETURN(LE); }
|
|---|
| 357 | ">=" { NAMEDOP_RETURN(GE); }
|
|---|
| 358 | "&&" { NAMEDOP_RETURN(ANDAND); }
|
|---|
| 359 | "||" { NAMEDOP_RETURN(OROR); }
|
|---|
| 360 | "->" { NAMEDOP_RETURN(ARROW); }
|
|---|
| 361 | "+=" { NAMEDOP_RETURN(PLUSassign); }
|
|---|
| 362 | "-=" { NAMEDOP_RETURN(MINUSassign); }
|
|---|
| 363 | "*=" { NAMEDOP_RETURN(MULTassign); }
|
|---|
| 364 | "/=" { NAMEDOP_RETURN(DIVassign); }
|
|---|
| 365 | "%=" { NAMEDOP_RETURN(MODassign); }
|
|---|
| 366 | "&=" { NAMEDOP_RETURN(ANDassign); }
|
|---|
| 367 | "|=" { NAMEDOP_RETURN(ORassign); }
|
|---|
| 368 | "^=" { NAMEDOP_RETURN(ERassign); }
|
|---|
| 369 | "<<=" { NAMEDOP_RETURN(LSassign); }
|
|---|
| 370 | ">>=" { NAMEDOP_RETURN(RSassign); }
|
|---|
| 371 |
|
|---|
| 372 | "@=" { NAMEDOP_RETURN(ATassign); } // CFA
|
|---|
| 373 |
|
|---|
| 374 | /* CFA, operator identifier */
|
|---|
| 375 | {op_unary}"?" { IDENTIFIER_RETURN(); } // unary
|
|---|
| 376 | "?"({op_unary_pre_post}|"()"|"[?]"|"{}") { IDENTIFIER_RETURN(); }
|
|---|
| 377 | "^?{}" { IDENTIFIER_RETURN(); }
|
|---|
| 378 | "?"{op_binary_over}"?" { IDENTIFIER_RETURN(); } // binary
|
|---|
| 379 | /*
|
|---|
| 380 | This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the string "*?*?"
|
|---|
| 381 | can be lexed as "*"/"?*?" or "*?"/"*?". Since it is common practise to put a unary operator juxtaposed
|
|---|
| 382 | to an identifier, e.g., "*i", users will be annoyed if they cannot do this with respect to operator
|
|---|
| 383 | identifiers. Even with this special hack, there are 5 general cases that cannot be handled. The first
|
|---|
| 384 | case is for the function-call identifier "?()":
|
|---|
| 385 |
|
|---|
| 386 | int * ?()(); // declaration: space required after '*'
|
|---|
| 387 | * ?()(); // expression: space required after '*'
|
|---|
| 388 |
|
|---|
| 389 | Without the space, the string "*?()" is ambiguous without N character look ahead; it requires scanning
|
|---|
| 390 | ahead to determine if there is a '(', which is the start of an argument/parameter list.
|
|---|
| 391 |
|
|---|
| 392 | The 4 remaining cases occur in expressions:
|
|---|
| 393 |
|
|---|
| 394 | i++?i:0; // space required before '?'
|
|---|
| 395 | i--?i:0; // space required before '?'
|
|---|
| 396 | i?++i:0; // space required after '?'
|
|---|
| 397 | i?--i:0; // space required after '?'
|
|---|
| 398 |
|
|---|
| 399 | In the first two cases, the string "i++?" is ambiguous, where this string can be lexed as "i"/"++?" or
|
|---|
| 400 | "i++"/"?"; it requires scanning ahead to determine if there is a '(', which is the start of an argument
|
|---|
| 401 | list. In the second two cases, the string "?++x" is ambiguous, where this string can be lexed as
|
|---|
| 402 | "?++"/"x" or "?"/"++x"; it requires scanning ahead to determine if there is a '(', which is the start of
|
|---|
| 403 | an argument list.
|
|---|
| 404 | */
|
|---|
| 405 | {op_unary}"?"({op_unary_pre_post}|"[?]"|{op_binary_over}"?") {
|
|---|
| 406 | // 1 or 2 character unary operator ?
|
|---|
| 407 | int i = yytext[1] == '?' ? 1 : 2;
|
|---|
| 408 | yyless( i ); // put back characters up to first '?'
|
|---|
| 409 | if ( i > 1 ) {
|
|---|
| 410 | NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
|
|---|
| 411 | } else {
|
|---|
| 412 | ASCIIOP_RETURN();
|
|---|
| 413 | } // if
|
|---|
| 414 | }
|
|---|
| 415 |
|
|---|
| 416 | /* unknown characters */
|
|---|
| 417 | . { printf("unknown character(s):\"%s\" on line %d\n", yytext, yylineno); }
|
|---|
| 418 |
|
|---|
| 419 | %%
|
|---|
| 420 |
|
|---|
| 421 | // Local Variables: //
|
|---|
| 422 | // mode: c++ //
|
|---|
| 423 | // tab-width: 4 //
|
|---|
| 424 | // compile-command: "make install" //
|
|---|
| 425 | // End: //
|
|---|
