| 1 | /*
|
|---|
| 2 | * Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
|
|---|
| 3 | *
|
|---|
| 4 | * The contents of this file are covered under the licence agreement in the
|
|---|
| 5 | * file "LICENCE" distributed with Cforall.
|
|---|
| 6 | *
|
|---|
| 7 | * lex.ll --
|
|---|
| 8 | *
|
|---|
| 9 | * Author : Peter A. Buhr
|
|---|
| 10 | * Created On : Sat Sep 22 08:58:10 2001
|
|---|
| 11 | * Last Modified By : Peter A. Buhr
|
|---|
| 12 | * Last Modified On : Wed Jul 12 18:04:44 2017
|
|---|
| 13 | * Update Count : 535
|
|---|
| 14 | */
|
|---|
| 15 |
|
|---|
| 16 | %option yylineno
|
|---|
| 17 | %option nounput
|
|---|
| 18 |
|
|---|
| 19 | %{
|
|---|
| 20 | // This lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
|
|---|
| 21 | // performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
|
|---|
| 22 | // line-number directives) and C/C++ style comments, which are ignored.
|
|---|
| 23 |
|
|---|
| 24 | //**************************** Includes and Defines ****************************
|
|---|
| 25 |
|
|---|
| 26 | #include <string>
|
|---|
| 27 | #include <cstdio> // FILENAME_MAX
|
|---|
| 28 |
|
|---|
| 29 | #include "ParseNode.h"
|
|---|
| 30 | #include "TypedefTable.h"
|
|---|
| 31 |
|
|---|
| 32 | char *yyfilename;
|
|---|
| 33 | std::string *strtext; // accumulate parts of character and string constant value
|
|---|
| 34 |
|
|---|
| 35 | #define RETURN_LOCN(x) yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
|
|---|
| 36 | #define RETURN_VAL(x) yylval.tok.str = new std::string( yytext ); RETURN_LOCN( x )
|
|---|
| 37 | #define RETURN_CHAR(x) yylval.tok.str = nullptr; RETURN_LOCN( x )
|
|---|
| 38 | #define RETURN_STR(x) yylval.tok.str = strtext; RETURN_LOCN( x )
|
|---|
| 39 |
|
|---|
| 40 | #define WHITE_RETURN(x) // do nothing
|
|---|
| 41 | #define NEWLINE_RETURN() WHITE_RETURN( '\n' )
|
|---|
| 42 | #define ASCIIOP_RETURN() RETURN_CHAR( (int)yytext[0] ) // single character operator
|
|---|
| 43 | #define NAMEDOP_RETURN(x) RETURN_CHAR( x ) // multichar operator, with a name
|
|---|
| 44 | #define NUMERIC_RETURN(x) rm_underscore(); RETURN_VAL( x ) // numeric constant
|
|---|
| 45 | #define KEYWORD_RETURN(x) RETURN_CHAR( x ) // keyword
|
|---|
| 46 | #define IDENTIFIER_RETURN() RETURN_VAL( typedefTable.isKind( yytext ) )
|
|---|
| 47 | #define ATTRIBUTE_RETURN() RETURN_VAL( ATTR_IDENTIFIER )
|
|---|
| 48 |
|
|---|
| 49 | void rm_underscore() {
|
|---|
| 50 | // Remove underscores in numeric constant by copying the non-underscore characters to the front of the string.
|
|---|
| 51 | yyleng = 0;
|
|---|
| 52 | for ( int i = 0; yytext[i] != '\0'; i += 1 ) {
|
|---|
| 53 | if ( yytext[i] != '_' ) {
|
|---|
| 54 | yytext[yyleng] = yytext[i];
|
|---|
| 55 | yyleng += 1;
|
|---|
| 56 | } // if
|
|---|
| 57 | } // for
|
|---|
| 58 | yytext[yyleng] = '\0';
|
|---|
| 59 | }
|
|---|
| 60 |
|
|---|
| 61 | // Stop warning due to incorrectly generated flex code.
|
|---|
| 62 | #pragma GCC diagnostic ignored "-Wsign-compare"
|
|---|
| 63 | %}
|
|---|
| 64 |
|
|---|
| 65 | octal [0-7]
|
|---|
| 66 | nonzero [1-9]
|
|---|
| 67 | decimal [0-9]
|
|---|
| 68 | hex [0-9a-fA-F]
|
|---|
| 69 | universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2}))
|
|---|
| 70 |
|
|---|
| 71 | // identifier, GCC: $ in identifier
|
|---|
| 72 | identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})*
|
|---|
| 73 |
|
|---|
| 74 | // attribute identifier, GCC: $ in identifier
|
|---|
| 75 | attr_identifier "@"{identifier}
|
|---|
| 76 |
|
|---|
| 77 | // numeric constants, CFA: '_' in constant
|
|---|
| 78 | hex_quad {hex}("_"?{hex}){3}
|
|---|
| 79 | integer_suffix "_"?(([uU](("ll"|"LL"|[lL])[iI]|[iI]?("ll"|"LL"|[lL])?))|([iI](("ll"|"LL"|[lL])[uU]|[uU]?("ll"|"LL"|[lL])?))|(("ll"|"LL"|[lL])([iI][uU]|[uU]?[iI]?)))
|
|---|
| 80 |
|
|---|
| 81 | octal_digits ({octal})|({octal}({octal}|"_")*{octal})
|
|---|
| 82 | octal_prefix "0""_"?
|
|---|
| 83 | octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix}?
|
|---|
| 84 |
|
|---|
| 85 | nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal})
|
|---|
| 86 | decimal_constant {nonzero_digits}{integer_suffix}?
|
|---|
| 87 |
|
|---|
| 88 | hex_digits ({hex})|({hex}({hex}|"_")*{hex})
|
|---|
| 89 | hex_prefix "0"[xX]"_"?
|
|---|
| 90 | hex_constant {hex_prefix}{hex_digits}{integer_suffix}?
|
|---|
| 91 |
|
|---|
| 92 | decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal})
|
|---|
| 93 | real_decimal {decimal_digits}"."{exponent}?{floating_suffix}?
|
|---|
| 94 | real_fraction "."{decimal_digits}{exponent}?{floating_suffix}?
|
|---|
| 95 | real_constant {decimal_digits}{real_fraction}
|
|---|
| 96 | exponent "_"?[eE]"_"?[+-]?{decimal_digits}
|
|---|
| 97 | // GCC: D (double) and iI (imaginary) suffixes, and DL (long double)
|
|---|
| 98 | floating_suffix "_"?([fFdDlL][iI]?|[iI][lLfFdD]?|"DL")
|
|---|
| 99 | floating_constant (({real_constant}{exponent}?)|({decimal_digits}{exponent})){floating_suffix}?
|
|---|
| 100 |
|
|---|
| 101 | binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
|
|---|
| 102 | hex_fractional_constant ({hex_digits}?"."{hex_digits})|({hex_digits}".")
|
|---|
| 103 | hex_floating_constant {hex_prefix}(({hex_fractional_constant}{binary_exponent})|({hex_digits}{binary_exponent})){floating_suffix}?
|
|---|
| 104 |
|
|---|
| 105 | // character escape sequence, GCC: \e => esc character
|
|---|
| 106 | simple_escape "\\"[abefnrtv'"?\\]
|
|---|
| 107 | // ' stop highlighting
|
|---|
| 108 | octal_escape "\\"{octal}("_"?{octal}){0,2}
|
|---|
| 109 | hex_escape "\\""x""_"?{hex_digits}
|
|---|
| 110 | escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char}
|
|---|
| 111 | cwide_prefix "L"|"U"|"u"
|
|---|
| 112 | swide_prefix {cwide_prefix}|"u8"
|
|---|
| 113 |
|
|---|
| 114 | // display/white-space characters
|
|---|
| 115 | h_tab [\011]
|
|---|
| 116 | form_feed [\014]
|
|---|
| 117 | v_tab [\013]
|
|---|
| 118 | c_return [\015]
|
|---|
| 119 | h_white [ ]|{h_tab}
|
|---|
| 120 |
|
|---|
| 121 | // overloadable operators
|
|---|
| 122 | op_unary_only "~"|"!"
|
|---|
| 123 | op_unary_binary "+"|"-"|"*"
|
|---|
| 124 | op_unary_pre_post "++"|"--"
|
|---|
| 125 | op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post}
|
|---|
| 126 |
|
|---|
| 127 | op_binary_only "/"|"%"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"&="|"|="|"^="|"<<="|">>="
|
|---|
| 128 | op_binary_over {op_unary_binary}|{op_binary_only}
|
|---|
| 129 | // op_binary_not_over "?"|"->"|"."|"&&"|"||"|"@="
|
|---|
| 130 | // operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over}
|
|---|
| 131 |
|
|---|
| 132 | %x COMMENT
|
|---|
| 133 | %x BKQUOTE
|
|---|
| 134 | %x QUOTE
|
|---|
| 135 | %x STRING
|
|---|
| 136 |
|
|---|
| 137 | %%
|
|---|
| 138 | /* line directives */
|
|---|
| 139 | ^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["].*"\n" {
|
|---|
| 140 | /* " stop highlighting */
|
|---|
| 141 | static char filename[FILENAME_MAX]; // temporarily store current source-file name
|
|---|
| 142 | char *end_num;
|
|---|
| 143 | char *begin_string, *end_string;
|
|---|
| 144 | long lineno, length;
|
|---|
| 145 | lineno = strtol( yytext + 1, &end_num, 0 );
|
|---|
| 146 | begin_string = strchr( end_num, '"' );
|
|---|
| 147 | if ( begin_string ) { // file name ?
|
|---|
| 148 | end_string = strchr( begin_string + 1, '"' ); // look for ending delimiter
|
|---|
| 149 | assert( end_string ); // closing quote ?
|
|---|
| 150 | length = end_string - begin_string - 1; // file-name length without quotes or sentinel
|
|---|
| 151 | assert( length < FILENAME_MAX ); // room for sentinel ?
|
|---|
| 152 | memcpy( &filename, begin_string + 1, length ); // copy file name from yytext
|
|---|
| 153 | filename[ length ] = '\0'; // terminate string with sentinel
|
|---|
| 154 | //std::cout << "file " << filename << " line " << lineno << std::endl;
|
|---|
| 155 | yylineno = lineno;
|
|---|
| 156 | yyfilename = filename;
|
|---|
| 157 | } // if
|
|---|
| 158 | }
|
|---|
| 159 |
|
|---|
| 160 | /* ignore preprocessor directives (for now) */
|
|---|
| 161 | ^{h_white}*"#"[^\n]*"\n" ;
|
|---|
| 162 |
|
|---|
| 163 | /* ignore C style comments (ALSO HANDLED BY CPP) */
|
|---|
| 164 | "/*" { BEGIN COMMENT; }
|
|---|
| 165 | <COMMENT>.|\n ;
|
|---|
| 166 | <COMMENT>"*/" { BEGIN 0; }
|
|---|
| 167 |
|
|---|
| 168 | /* ignore C++ style comments (ALSO HANDLED BY CPP) */
|
|---|
| 169 | "//"[^\n]*"\n" ;
|
|---|
| 170 |
|
|---|
| 171 | /* ignore whitespace */
|
|---|
| 172 | {h_white}+ { WHITE_RETURN(' '); }
|
|---|
| 173 | ({v_tab}|{c_return}|{form_feed})+ { WHITE_RETURN(' '); }
|
|---|
| 174 | ({h_white}|{v_tab}|{c_return}|{form_feed})*"\n" { NEWLINE_RETURN(); }
|
|---|
| 175 |
|
|---|
| 176 | /* keywords */
|
|---|
| 177 | _Alignas { KEYWORD_RETURN(ALIGNAS); } // C11
|
|---|
| 178 | _Alignof { KEYWORD_RETURN(ALIGNOF); } // C11
|
|---|
| 179 | __alignof { KEYWORD_RETURN(ALIGNOF); } // GCC
|
|---|
| 180 | __alignof__ { KEYWORD_RETURN(ALIGNOF); } // GCC
|
|---|
| 181 | asm { KEYWORD_RETURN(ASM); }
|
|---|
| 182 | __asm { KEYWORD_RETURN(ASM); } // GCC
|
|---|
| 183 | __asm__ { KEYWORD_RETURN(ASM); } // GCC
|
|---|
| 184 | _At { KEYWORD_RETURN(AT); } // CFA
|
|---|
| 185 | _Atomic { KEYWORD_RETURN(ATOMIC); } // C11
|
|---|
| 186 | __attribute { KEYWORD_RETURN(ATTRIBUTE); } // GCC
|
|---|
| 187 | __attribute__ { KEYWORD_RETURN(ATTRIBUTE); } // GCC
|
|---|
| 188 | auto { KEYWORD_RETURN(AUTO); }
|
|---|
| 189 | _Bool { KEYWORD_RETURN(BOOL); } // C99
|
|---|
| 190 | break { KEYWORD_RETURN(BREAK); }
|
|---|
| 191 | case { KEYWORD_RETURN(CASE); }
|
|---|
| 192 | catch { KEYWORD_RETURN(CATCH); } // CFA
|
|---|
| 193 | catchResume { KEYWORD_RETURN(CATCHRESUME); } // CFA
|
|---|
| 194 | char { KEYWORD_RETURN(CHAR); }
|
|---|
| 195 | choose { KEYWORD_RETURN(CHOOSE); } // CFA
|
|---|
| 196 | _Complex { KEYWORD_RETURN(COMPLEX); } // C99
|
|---|
| 197 | __complex { KEYWORD_RETURN(COMPLEX); } // GCC
|
|---|
| 198 | __complex__ { KEYWORD_RETURN(COMPLEX); } // GCC
|
|---|
| 199 | const { KEYWORD_RETURN(CONST); }
|
|---|
| 200 | __const { KEYWORD_RETURN(CONST); } // GCC
|
|---|
| 201 | __const__ { KEYWORD_RETURN(CONST); } // GCC
|
|---|
| 202 | continue { KEYWORD_RETURN(CONTINUE); }
|
|---|
| 203 | coroutine { KEYWORD_RETURN(COROUTINE); } // CFA
|
|---|
| 204 | default { KEYWORD_RETURN(DEFAULT); }
|
|---|
| 205 | disable { KEYWORD_RETURN(DISABLE); } // CFA
|
|---|
| 206 | do { KEYWORD_RETURN(DO); }
|
|---|
| 207 | double { KEYWORD_RETURN(DOUBLE); }
|
|---|
| 208 | dtype { KEYWORD_RETURN(DTYPE); } // CFA
|
|---|
| 209 | else { KEYWORD_RETURN(ELSE); }
|
|---|
| 210 | enable { KEYWORD_RETURN(ENABLE); } // CFA
|
|---|
| 211 | enum { KEYWORD_RETURN(ENUM); }
|
|---|
| 212 | __extension__ { KEYWORD_RETURN(EXTENSION); } // GCC
|
|---|
| 213 | extern { KEYWORD_RETURN(EXTERN); }
|
|---|
| 214 | fallthrough { KEYWORD_RETURN(FALLTHRU); } // CFA
|
|---|
| 215 | fallthru { KEYWORD_RETURN(FALLTHRU); } // CFA
|
|---|
| 216 | finally { KEYWORD_RETURN(FINALLY); } // CFA
|
|---|
| 217 | float { KEYWORD_RETURN(FLOAT); }
|
|---|
| 218 | __float128 { KEYWORD_RETURN(FLOAT); } // GCC
|
|---|
| 219 | for { KEYWORD_RETURN(FOR); }
|
|---|
| 220 | forall { KEYWORD_RETURN(FORALL); } // CFA
|
|---|
| 221 | fortran { KEYWORD_RETURN(FORTRAN); }
|
|---|
| 222 | ftype { KEYWORD_RETURN(FTYPE); } // CFA
|
|---|
| 223 | _Generic { KEYWORD_RETURN(GENERIC); } // C11
|
|---|
| 224 | goto { KEYWORD_RETURN(GOTO); }
|
|---|
| 225 | if { KEYWORD_RETURN(IF); }
|
|---|
| 226 | _Imaginary { KEYWORD_RETURN(IMAGINARY); } // C99
|
|---|
| 227 | __imag { KEYWORD_RETURN(IMAGINARY); } // GCC
|
|---|
| 228 | __imag__ { KEYWORD_RETURN(IMAGINARY); } // GCC
|
|---|
| 229 | inline { KEYWORD_RETURN(INLINE); } // C99
|
|---|
| 230 | __inline { KEYWORD_RETURN(INLINE); } // GCC
|
|---|
| 231 | __inline__ { KEYWORD_RETURN(INLINE); } // GCC
|
|---|
| 232 | int { KEYWORD_RETURN(INT); }
|
|---|
| 233 | __int128 { KEYWORD_RETURN(INT); } // GCC
|
|---|
| 234 | __label__ { KEYWORD_RETURN(LABEL); } // GCC
|
|---|
| 235 | long { KEYWORD_RETURN(LONG); }
|
|---|
| 236 | lvalue { KEYWORD_RETURN(LVALUE); } // CFA
|
|---|
| 237 | monitor { KEYWORD_RETURN(MONITOR); } // CFA
|
|---|
| 238 | mutex { KEYWORD_RETURN(MUTEX); } // CFA
|
|---|
| 239 | _Noreturn { KEYWORD_RETURN(NORETURN); } // C11
|
|---|
| 240 | __builtin_offsetof { KEYWORD_RETURN(OFFSETOF); } // GCC
|
|---|
| 241 | one_t { NUMERIC_RETURN(ONE_T); } // CFA
|
|---|
| 242 | otype { KEYWORD_RETURN(OTYPE); } // CFA
|
|---|
| 243 | register { KEYWORD_RETURN(REGISTER); }
|
|---|
| 244 | restrict { KEYWORD_RETURN(RESTRICT); } // C99
|
|---|
| 245 | __restrict { KEYWORD_RETURN(RESTRICT); } // GCC
|
|---|
| 246 | __restrict__ { KEYWORD_RETURN(RESTRICT); } // GCC
|
|---|
| 247 | return { KEYWORD_RETURN(RETURN); }
|
|---|
| 248 | short { KEYWORD_RETURN(SHORT); }
|
|---|
| 249 | signed { KEYWORD_RETURN(SIGNED); }
|
|---|
| 250 | __signed { KEYWORD_RETURN(SIGNED); } // GCC
|
|---|
| 251 | __signed__ { KEYWORD_RETURN(SIGNED); } // GCC
|
|---|
| 252 | sizeof { KEYWORD_RETURN(SIZEOF); }
|
|---|
| 253 | static { KEYWORD_RETURN(STATIC); }
|
|---|
| 254 | _Static_assert { KEYWORD_RETURN(STATICASSERT); } // C11
|
|---|
| 255 | struct { KEYWORD_RETURN(STRUCT); }
|
|---|
| 256 | switch { KEYWORD_RETURN(SWITCH); }
|
|---|
| 257 | thread { KEYWORD_RETURN(THREAD); } // C11
|
|---|
| 258 | _Thread_local { KEYWORD_RETURN(THREADLOCAL); } // C11
|
|---|
| 259 | throw { KEYWORD_RETURN(THROW); } // CFA
|
|---|
| 260 | throwResume { KEYWORD_RETURN(THROWRESUME); } // CFA
|
|---|
| 261 | trait { KEYWORD_RETURN(TRAIT); } // CFA
|
|---|
| 262 | try { KEYWORD_RETURN(TRY); } // CFA
|
|---|
| 263 | ttype { KEYWORD_RETURN(TTYPE); } // CFA
|
|---|
| 264 | typedef { KEYWORD_RETURN(TYPEDEF); }
|
|---|
| 265 | typeof { KEYWORD_RETURN(TYPEOF); } // GCC
|
|---|
| 266 | __typeof { KEYWORD_RETURN(TYPEOF); } // GCC
|
|---|
| 267 | __typeof__ { KEYWORD_RETURN(TYPEOF); } // GCC
|
|---|
| 268 | union { KEYWORD_RETURN(UNION); }
|
|---|
| 269 | unsigned { KEYWORD_RETURN(UNSIGNED); }
|
|---|
| 270 | __builtin_va_list { KEYWORD_RETURN(VALIST); } // GCC
|
|---|
| 271 | void { KEYWORD_RETURN(VOID); }
|
|---|
| 272 | volatile { KEYWORD_RETURN(VOLATILE); }
|
|---|
| 273 | __volatile { KEYWORD_RETURN(VOLATILE); } // GCC
|
|---|
| 274 | __volatile__ { KEYWORD_RETURN(VOLATILE); } // GCC
|
|---|
| 275 | while { KEYWORD_RETURN(WHILE); }
|
|---|
| 276 | with { KEYWORD_RETURN(WITH); } // CFA
|
|---|
| 277 | zero_t { NUMERIC_RETURN(ZERO_T); } // CFA
|
|---|
| 278 |
|
|---|
| 279 | /* identifier */
|
|---|
| 280 | {identifier} { IDENTIFIER_RETURN(); }
|
|---|
| 281 | {attr_identifier} { ATTRIBUTE_RETURN(); }
|
|---|
| 282 | "`" { BEGIN BKQUOTE; }
|
|---|
| 283 | <BKQUOTE>{identifier} { IDENTIFIER_RETURN(); }
|
|---|
| 284 | <BKQUOTE>"`" { BEGIN 0; }
|
|---|
| 285 |
|
|---|
| 286 | /* numeric constants */
|
|---|
| 287 | "0" { NUMERIC_RETURN(ZERO); } // CFA
|
|---|
| 288 | "1" { NUMERIC_RETURN(ONE); } // CFA
|
|---|
| 289 | {decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
|
|---|
| 290 | {octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
|
|---|
| 291 | {hex_constant} { NUMERIC_RETURN(INTEGERconstant); }
|
|---|
| 292 | {real_decimal} { NUMERIC_RETURN(REALDECIMALconstant); } // must appear before floating_constant
|
|---|
| 293 | {real_fraction} { NUMERIC_RETURN(REALFRACTIONconstant); } // must appear before floating_constant
|
|---|
| 294 | {floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
|
|---|
| 295 | {hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
|
|---|
| 296 |
|
|---|
| 297 | /* character constant, allows empty value */
|
|---|
| 298 | ({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new std::string( yytext, yyleng ); }
|
|---|
| 299 | <QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); }
|
|---|
| 300 | <QUOTE>['\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); }
|
|---|
| 301 | /* ' stop highlighting */
|
|---|
| 302 |
|
|---|
| 303 | /* string constant */
|
|---|
| 304 | ({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new std::string( yytext, yyleng ); }
|
|---|
| 305 | <STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); }
|
|---|
| 306 | <STRING>["\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); }
|
|---|
| 307 | /* " stop highlighting */
|
|---|
| 308 |
|
|---|
| 309 | /* common character/string constant */
|
|---|
| 310 | <QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); }
|
|---|
| 311 | <QUOTE,STRING>"\\"{h_white}*"\n" {} // continuation (ALSO HANDLED BY CPP)
|
|---|
| 312 | <QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character
|
|---|
| 313 |
|
|---|
| 314 | /* punctuation */
|
|---|
| 315 | "@" { ASCIIOP_RETURN(); }
|
|---|
| 316 | "[" { ASCIIOP_RETURN(); }
|
|---|
| 317 | "]" { ASCIIOP_RETURN(); }
|
|---|
| 318 | "(" { ASCIIOP_RETURN(); }
|
|---|
| 319 | ")" { ASCIIOP_RETURN(); }
|
|---|
| 320 | "{" { ASCIIOP_RETURN(); }
|
|---|
| 321 | "}" { ASCIIOP_RETURN(); }
|
|---|
| 322 | "," { ASCIIOP_RETURN(); } // also operator
|
|---|
| 323 | ":" { ASCIIOP_RETURN(); }
|
|---|
| 324 | ";" { ASCIIOP_RETURN(); }
|
|---|
| 325 | "." { ASCIIOP_RETURN(); } // also operator
|
|---|
| 326 | "..." { NAMEDOP_RETURN(ELLIPSIS); }
|
|---|
| 327 |
|
|---|
| 328 | /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
|
|---|
| 329 | "<:" { RETURN_VAL('['); }
|
|---|
| 330 | ":>" { RETURN_VAL(']'); }
|
|---|
| 331 | "<%" { RETURN_VAL('{'); }
|
|---|
| 332 | "%>" { RETURN_VAL('}'); }
|
|---|
| 333 |
|
|---|
| 334 | /* operators */
|
|---|
| 335 | "!" { ASCIIOP_RETURN(); }
|
|---|
| 336 | "+" { ASCIIOP_RETURN(); }
|
|---|
| 337 | "-" { ASCIIOP_RETURN(); }
|
|---|
| 338 | "*" { ASCIIOP_RETURN(); }
|
|---|
| 339 | "/" { ASCIIOP_RETURN(); }
|
|---|
| 340 | "%" { ASCIIOP_RETURN(); }
|
|---|
| 341 | "^" { ASCIIOP_RETURN(); }
|
|---|
| 342 | "~" { ASCIIOP_RETURN(); }
|
|---|
| 343 | "&" { ASCIIOP_RETURN(); }
|
|---|
| 344 | "|" { ASCIIOP_RETURN(); }
|
|---|
| 345 | "<" { ASCIIOP_RETURN(); }
|
|---|
| 346 | ">" { ASCIIOP_RETURN(); }
|
|---|
| 347 | "=" { ASCIIOP_RETURN(); }
|
|---|
| 348 | "?" { ASCIIOP_RETURN(); }
|
|---|
| 349 |
|
|---|
| 350 | "++" { NAMEDOP_RETURN(ICR); }
|
|---|
| 351 | "--" { NAMEDOP_RETURN(DECR); }
|
|---|
| 352 | "==" { NAMEDOP_RETURN(EQ); }
|
|---|
| 353 | "!=" { NAMEDOP_RETURN(NE); }
|
|---|
| 354 | "<<" { NAMEDOP_RETURN(LS); }
|
|---|
| 355 | ">>" { NAMEDOP_RETURN(RS); }
|
|---|
| 356 | "<=" { NAMEDOP_RETURN(LE); }
|
|---|
| 357 | ">=" { NAMEDOP_RETURN(GE); }
|
|---|
| 358 | "&&" { NAMEDOP_RETURN(ANDAND); }
|
|---|
| 359 | "||" { NAMEDOP_RETURN(OROR); }
|
|---|
| 360 | "->" { NAMEDOP_RETURN(ARROW); }
|
|---|
| 361 | "+=" { NAMEDOP_RETURN(PLUSassign); }
|
|---|
| 362 | "-=" { NAMEDOP_RETURN(MINUSassign); }
|
|---|
| 363 | "*=" { NAMEDOP_RETURN(MULTassign); }
|
|---|
| 364 | "/=" { NAMEDOP_RETURN(DIVassign); }
|
|---|
| 365 | "%=" { NAMEDOP_RETURN(MODassign); }
|
|---|
| 366 | "&=" { NAMEDOP_RETURN(ANDassign); }
|
|---|
| 367 | "|=" { NAMEDOP_RETURN(ORassign); }
|
|---|
| 368 | "^=" { NAMEDOP_RETURN(ERassign); }
|
|---|
| 369 | "<<=" { NAMEDOP_RETURN(LSassign); }
|
|---|
| 370 | ">>=" { NAMEDOP_RETURN(RSassign); }
|
|---|
| 371 |
|
|---|
| 372 | "@=" { NAMEDOP_RETURN(ATassign); } // CFA
|
|---|
| 373 |
|
|---|
| 374 | /* CFA, operator identifier */
|
|---|
| 375 | {op_unary}"?" { IDENTIFIER_RETURN(); } // unary
|
|---|
| 376 | "?"({op_unary_pre_post}|"()"|"[?]"|"{}") { IDENTIFIER_RETURN(); }
|
|---|
| 377 | "^?{}" { IDENTIFIER_RETURN(); }
|
|---|
| 378 | "?"{op_binary_over}"?" { IDENTIFIER_RETURN(); } // binary
|
|---|
| 379 | /*
|
|---|
| 380 | This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the string "*?*?" can be
|
|---|
| 381 | lexed as "*?"/"*?" or "*"/"?*?". Since it is common practise to put a unary operator juxtaposed to an identifier,
|
|---|
| 382 | e.g., "*i", users will be annoyed if they cannot do this with respect to operator identifiers. Therefore, there is
|
|---|
| 383 | a lexical look-ahead for the second case, with backtracking to return the leading unary operator and then
|
|---|
| 384 | reparsing the trailing operator identifier. Otherwise a space is needed between the unary operator and operator
|
|---|
| 385 | identifier to disambiguate this common case.
|
|---|
| 386 |
|
|---|
| 387 | A similar issue occurs with the dereference, *?(...), and routine-call, ?()(...) identifiers. The ambiguity
|
|---|
| 388 | occurs when the deference operator has no parameters, *?() and *?()(...), requiring arbitrary whitespace
|
|---|
| 389 | look-ahead for the routine-call parameter-list to disambiguate. However, the dereference operator must have a
|
|---|
| 390 | parameter/argument to dereference *?(...). Hence, always interpreting the string *?() as * ?() does not preclude
|
|---|
| 391 | any meaningful program.
|
|---|
| 392 |
|
|---|
| 393 | The remaining cases are with the increment/decrement operators and conditional expression:
|
|---|
| 394 |
|
|---|
| 395 | i++? ...(...);
|
|---|
| 396 | i?++ ...(...);
|
|---|
| 397 |
|
|---|
| 398 | requiring arbitrary whitespace look-ahead for the operator parameter-list, even though that interpretation is an
|
|---|
| 399 | incorrect expression (juxtaposed identifiers). Therefore, it is necessary to disambiguate these cases with a
|
|---|
| 400 | space:
|
|---|
| 401 |
|
|---|
| 402 | i++ ? i : 0;
|
|---|
| 403 | i? ++i : 0;
|
|---|
| 404 | */
|
|---|
| 405 | {op_unary}"?"({op_unary_pre_post}|"()"|"[?]"|{op_binary_over}"?") {
|
|---|
| 406 | // 1 or 2 character unary operator ?
|
|---|
| 407 | int i = yytext[1] == '?' ? 1 : 2;
|
|---|
| 408 | yyless( i ); // put back characters up to first '?'
|
|---|
| 409 | if ( i > 1 ) {
|
|---|
| 410 | NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
|
|---|
| 411 | } else {
|
|---|
| 412 | ASCIIOP_RETURN();
|
|---|
| 413 | } // if
|
|---|
| 414 | }
|
|---|
| 415 |
|
|---|
| 416 | /* unknown characters */
|
|---|
| 417 | . { printf("unknown character(s):\"%s\" on line %d\n", yytext, yylineno); }
|
|---|
| 418 |
|
|---|
| 419 | %%
|
|---|
| 420 |
|
|---|
| 421 | // Local Variables: //
|
|---|
| 422 | // mode: c++ //
|
|---|
| 423 | // tab-width: 4 //
|
|---|
| 424 | // compile-command: "make install" //
|
|---|
| 425 | // End: //
|
|---|
