source: src/Parser/lex.ll@ 2e60a1a

ADT aaron-thesis arm-eh ast-experimental cleanup-dtors ctor deferred_resn demangler enum forall-pointer-decay gc_noraii jacob/cs343-translation jenkins-sandbox memory new-ast new-ast-unique-expr new-env no_list persistent-indexer pthread-emulation qualifiedEnum resolv-new string with_gc
Last change on this file since 2e60a1a was 4040425, checked in by Peter A. Buhr <pabuhr@…>, 10 years ago

change keyword type to otype and context to trait
  • Property mode set to 100644
File size: 15.2 KB
Line 
1/*
2 * Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3 *
4 * The contents of this file are covered under the licence agreement in the
5 * file "LICENCE" distributed with Cforall.
6 *
7 * lex.l --
8 *
9 * Author : Peter A. Buhr
10 * Created On : Sat Sep 22 08:58:10 2001
11 * Last Modified By : Peter A. Buhr
12 * Last Modified On : Wed Mar 2 18:07:20 2016
13 * Update Count : 434
14 */
15
16%option yylineno
17%option nounput
18
19%{
20// This lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
21// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
22// line-number directives) and C/C++ style comments, which are ignored.
23
24//**************************** Includes and Defines ****************************
25
26#include <string>
27
28#include "lex.h"
29#include "ParseNode.h"
30#include "parser.h" // YACC generated definitions based on C++ grammar
31
32char *yyfilename;
33std::string *strtext; // accumulate parts of character and string constant value
34
35#define RETURN_LOCN(x) yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
36#define RETURN_VAL(x) yylval.tok.str = new std::string( yytext ); RETURN_LOCN( x )
37#define RETURN_CHAR(x) yylval.tok.str = NULL; RETURN_LOCN( x )
38#define RETURN_STR(x) yylval.tok.str = strtext; RETURN_LOCN( x )
39
40#define WHITE_RETURN(x) // do nothing
41#define NEWLINE_RETURN() WHITE_RETURN( '\n' )
42#define ASCIIOP_RETURN() RETURN_CHAR( (int)yytext[0] ) // single character operator
43#define NAMEDOP_RETURN(x) RETURN_VAL( x ) // multichar operator, with a name
44#define NUMERIC_RETURN(x) rm_underscore(); RETURN_VAL( x ) // numeric constant
45#define KEYWORD_RETURN(x) RETURN_CHAR( x ) // keyword
46#define IDENTIFIER_RETURN() RETURN_VAL( (typedefTable.isIdentifier( yytext ) ? IDENTIFIER : typedefTable.isTypedef( yytext ) ? TYPEDEFname : TYPEGENname ) )
47#define ATTRIBUTE_RETURN() RETURN_VAL( ATTR_IDENTIFIER )
48
49void rm_underscore() {
50 // remove underscores in numeric constant
51 int j = 0;
52 for ( int i = 0; yytext[i] != '\0'; i += 1 ) {
53 if ( yytext[i] != '_' ) {
54 yytext[j] = yytext[i];
55 j += 1;
56 } // if
57 } // for
58 yyleng = j;
59 yytext[yyleng] = '\0';
60}
61
62%}
63
64octal [0-7]
65nonzero [1-9]
66decimal [0-9]
67hex [0-9a-fA-F]
68universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2}))
69
70 // identifier, GCC: $ in identifier
71identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})*
72
73 // quoted identifier
74quoted_identifier "`"{identifier}"`"
75
76 // attribute identifier, GCC: $ in identifier
77attr_identifier "@"{identifier}
78
79 // numeric constants, CFA: '_' in constant
80hex_quad {hex}("_"?{hex}){3}
81integer_suffix "_"?(([uU][lL]?)|([uU]("ll"|"LL")?)|([lL][uU]?)|("ll"|"LL")[uU]?)
82
83octal_digits ({octal})|({octal}({octal}|"_")*{octal})
84octal_prefix "0""_"?
85octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix}?
86
87nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal})
88decimal_constant {nonzero_digits}{integer_suffix}?
89
90hex_digits ({hex})|({hex}({hex}|"_")*{hex})
91hex_prefix "0"[xX]"_"?
92hex_constant {hex_prefix}{hex_digits}{integer_suffix}?
93
94decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal})
95fractional_constant ({decimal_digits}?"."{decimal_digits})|({decimal_digits}".")
96exponent "_"?[eE]"_"?[+-]?{decimal_digits}
97 // GCC: D (double), LD (long double) and iI (imaginary) suffixes
98floating_suffix "_"?([fFdD]?|([lL]?)|([iI][lLfFdD]?)|([lLfFdD][iI]))
99floating_constant (({fractional_constant}{exponent}?)|({decimal_digits}{exponent})){floating_suffix}?
100
101binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
102hex_fractional_constant ({hex_digits}?"."{hex_digits})|({hex_digits}".")
103hex_floating_constant {hex_prefix}(({hex_fractional_constant}{binary_exponent})|({hex_digits}{binary_exponent})){floating_suffix}?
104
105 // character escape sequence, GCC: \e => esc character
106simple_escape "\\"[abefnrtv'"?\\]
107 // ' stop highlighting
108octal_escape "\\"{octal}("_"?{octal}){0,2}
109hex_escape "\\""x""_"?{hex_digits}
110escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char}
111cwide_prefix "L"|"U"|"u"
112swide_prefix {cwide_prefix}|"u8"
113
114 // display/white-space characters
115h_tab [\011]
116form_feed [\014]
117v_tab [\013]
118c_return [\015]
119h_white [ ]|{h_tab}
120
121 // operators
122op_unary_only "~"|"!"
123op_unary_binary "+"|"-"|"*"
124op_unary_pre_post "++"|"--"
125op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post}
126
127op_binary_only "/"|"%"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"&="|"|="|"^="|"<<="|">>="
128op_binary_over {op_unary_binary}|{op_binary_only}
129op_binary_not_over "?"|"->"|"&&"|"||"
130operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over}
131
132%x COMMENT
133%x BKQUOTE
134%x QUOTE
135%x STRING
136
137%%
138 /* line directives */
139^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["].*"\n" {
140 /* " stop highlighting */
141 char *end_num;
142 char *begin_string, *end_string;
143 char *filename;
144 long lineno, length;
145 lineno = strtol( yytext + 1, &end_num, 0 );
146 begin_string = strchr( end_num, '"' );
147 if ( begin_string ) {
148 end_string = strchr( begin_string + 1, '"' );
149 if ( end_string ) {
150 length = end_string - begin_string - 1;
151 filename = new char[ length + 1 ];
152 memcpy( filename, begin_string + 1, length );
153 filename[ length ] = '\0';
154 //std::cout << "file " << filename << " line " << lineno << std::endl;
155 yylineno = lineno;
156 yyfilename = filename;
157 } // if
158 } // if
159}
160
161 /* ignore preprocessor directives (for now) */
162^{h_white}*"#"[^\n]*"\n" ;
163
164 /* ignore C style comments (ALSO HANDLED BY CPP) */
165"/*" { BEGIN COMMENT; }
166<COMMENT>.|\n ;
167<COMMENT>"*/" { BEGIN 0; }
168
169 /* ignore C++ style comments (ALSO HANDLED BY CPP) */
170"//"[^\n]*"\n" ;
171
172 /* ignore whitespace */
173{h_white}+ { WHITE_RETURN(' '); }
174({v_tab}|{c_return}|{form_feed})+ { WHITE_RETURN(' '); }
175({h_white}|{v_tab}|{c_return}|{form_feed})*"\n" { NEWLINE_RETURN(); }
176
177 /* keywords */
178_Alignas { KEYWORD_RETURN(ALIGNAS); } // C11
179_Alignof { KEYWORD_RETURN(ALIGNOF); } // C11
180__alignof { KEYWORD_RETURN(ALIGNOF); } // GCC
181__alignof__ { KEYWORD_RETURN(ALIGNOF); } // GCC
182asm { KEYWORD_RETURN(ASM); }
183__asm { KEYWORD_RETURN(ASM); } // GCC
184__asm__ { KEYWORD_RETURN(ASM); } // GCC
185_At { KEYWORD_RETURN(AT); } // CFA
186_Atomic { KEYWORD_RETURN(ATOMIC); } // C11
187__attribute { KEYWORD_RETURN(ATTRIBUTE); } // GCC
188__attribute__ { KEYWORD_RETURN(ATTRIBUTE); } // GCC
189auto { KEYWORD_RETURN(AUTO); }
190_Bool { KEYWORD_RETURN(BOOL); } // C99
191break { KEYWORD_RETURN(BREAK); }
192case { KEYWORD_RETURN(CASE); }
193catch { KEYWORD_RETURN(CATCH); } // CFA
194catchResume { KEYWORD_RETURN(CATCHRESUME); } // CFA
195char { KEYWORD_RETURN(CHAR); }
196choose { KEYWORD_RETURN(CHOOSE); } // CFA
197_Complex { KEYWORD_RETURN(COMPLEX); } // C99
198__complex { KEYWORD_RETURN(COMPLEX); } // GCC
199__complex__ { KEYWORD_RETURN(COMPLEX); } // GCC
200const { KEYWORD_RETURN(CONST); }
201__const { KEYWORD_RETURN(CONST); } // GCC
202__const__ { KEYWORD_RETURN(CONST); } // GCC
203continue { KEYWORD_RETURN(CONTINUE); }
204default { KEYWORD_RETURN(DEFAULT); }
205disable { KEYWORD_RETURN(DISABLE); } // CFA
206do { KEYWORD_RETURN(DO); }
207double { KEYWORD_RETURN(DOUBLE); }
208dtype { KEYWORD_RETURN(DTYPE); } // CFA
209else { KEYWORD_RETURN(ELSE); }
210enable { KEYWORD_RETURN(ENABLE); } // CFA
211enum { KEYWORD_RETURN(ENUM); }
212__extension__ { KEYWORD_RETURN(EXTENSION); } // GCC
213extern { KEYWORD_RETURN(EXTERN); }
214fallthru { KEYWORD_RETURN(FALLTHRU); } // CFA
215finally { KEYWORD_RETURN(FINALLY); } // CFA
216float { KEYWORD_RETURN(FLOAT); }
217__float128 { KEYWORD_RETURN(FLOAT); } // GCC
218for { KEYWORD_RETURN(FOR); }
219forall { KEYWORD_RETURN(FORALL); } // CFA
220fortran { KEYWORD_RETURN(FORTRAN); }
221ftype { KEYWORD_RETURN(FTYPE); } // CFA
222_Generic { KEYWORD_RETURN(GENERIC); } // C11
223goto { KEYWORD_RETURN(GOTO); }
224if { KEYWORD_RETURN(IF); }
225_Imaginary { KEYWORD_RETURN(IMAGINARY); } // C99
226__imag { KEYWORD_RETURN(IMAGINARY); } // GCC
227__imag__ { KEYWORD_RETURN(IMAGINARY); } // GCC
228inline { KEYWORD_RETURN(INLINE); } // C99
229__inline { KEYWORD_RETURN(INLINE); } // GCC
230__inline__ { KEYWORD_RETURN(INLINE); } // GCC
231int { KEYWORD_RETURN(INT); }
232__int128 { KEYWORD_RETURN(INT); } // GCC
233__label__ { KEYWORD_RETURN(LABEL); } // GCC
234long { KEYWORD_RETURN(LONG); }
235lvalue { KEYWORD_RETURN(LVALUE); } // CFA
236_Noreturn { KEYWORD_RETURN(NORETURN); } // C11
237__builtin_offsetof { KEYWORD_RETURN(OFFSETOF); } // GCC
238otype { KEYWORD_RETURN(OTYPE); } // CFA
239register { KEYWORD_RETURN(REGISTER); }
240restrict { KEYWORD_RETURN(RESTRICT); } // C99
241__restrict { KEYWORD_RETURN(RESTRICT); } // GCC
242__restrict__ { KEYWORD_RETURN(RESTRICT); } // GCC
243return { KEYWORD_RETURN(RETURN); }
244short { KEYWORD_RETURN(SHORT); }
245signed { KEYWORD_RETURN(SIGNED); }
246__signed { KEYWORD_RETURN(SIGNED); } // GCC
247__signed__ { KEYWORD_RETURN(SIGNED); } // GCC
248sizeof { KEYWORD_RETURN(SIZEOF); }
249static { KEYWORD_RETURN(STATIC); }
250_Static_assert { KEYWORD_RETURN(STATICASSERT); } // C11
251struct { KEYWORD_RETURN(STRUCT); }
252switch { KEYWORD_RETURN(SWITCH); }
253_Thread_local { KEYWORD_RETURN(THREADLOCAL); } // C11
254throw { KEYWORD_RETURN(THROW); } // CFA
255throwResume { KEYWORD_RETURN(THROWRESUME); } // CFA
256trait { KEYWORD_RETURN(TRAIT); } // CFA
257try { KEYWORD_RETURN(TRY); } // CFA
258typedef { KEYWORD_RETURN(TYPEDEF); }
259typeof { KEYWORD_RETURN(TYPEOF); } // GCC
260__typeof { KEYWORD_RETURN(TYPEOF); } // GCC
261__typeof__ { KEYWORD_RETURN(TYPEOF); } // GCC
262union { KEYWORD_RETURN(UNION); }
263unsigned { KEYWORD_RETURN(UNSIGNED); }
264__builtin_va_list { KEYWORD_RETURN(VALIST); } // GCC
265void { KEYWORD_RETURN(VOID); }
266volatile { KEYWORD_RETURN(VOLATILE); }
267__volatile { KEYWORD_RETURN(VOLATILE); } // GCC
268__volatile__ { KEYWORD_RETURN(VOLATILE); } // GCC
269while { KEYWORD_RETURN(WHILE); }
270
271 /* identifier */
272{identifier} { IDENTIFIER_RETURN(); }
273{attr_identifier} { ATTRIBUTE_RETURN(); }
274"`" { BEGIN BKQUOTE; }
275<BKQUOTE>{identifier} { IDENTIFIER_RETURN(); }
276<BKQUOTE>"`" { BEGIN 0; }
277
278 /* numeric constants */
279"0" { NUMERIC_RETURN(ZERO); } // CFA
280"1" { NUMERIC_RETURN(ONE); } // CFA
281{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
282{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
283{hex_constant} { NUMERIC_RETURN(INTEGERconstant); }
284{floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
285{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
286
287 /* character constant, allows empty value */
288({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new std::string; *strtext += std::string( yytext ); }
289<QUOTE>[^'\\\n]* { *strtext += std::string( yytext ); }
290<QUOTE>['\n] { BEGIN 0; *strtext += std::string( yytext); RETURN_STR(CHARACTERconstant); }
291 /* ' stop highlighting */
292
293 /* string constant */
294({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new std::string; *strtext += std::string( yytext ); }
295<STRING>[^"\\\n]* { *strtext += std::string( yytext ); }
296<STRING>["\n] { BEGIN 0; *strtext += std::string( yytext ); RETURN_STR(STRINGliteral); }
297 /* " stop highlighting */
298
299 /* common character/string constant */
300<QUOTE,STRING>{escape_seq} { rm_underscore(); *strtext += std::string( yytext ); }
301<QUOTE,STRING>"\\"{h_white}*"\n" {} // continuation (ALSO HANDLED BY CPP)
302<QUOTE,STRING>"\\" { *strtext += std::string( yytext ); } // unknown escape character
303
304 /* punctuation */
305"[" { ASCIIOP_RETURN(); }
306"]" { ASCIIOP_RETURN(); }
307"(" { ASCIIOP_RETURN(); }
308")" { ASCIIOP_RETURN(); }
309"{" { ASCIIOP_RETURN(); }
310"}" { ASCIIOP_RETURN(); }
311"," { ASCIIOP_RETURN(); } // also operator
312":" { ASCIIOP_RETURN(); }
313";" { ASCIIOP_RETURN(); }
314"." { ASCIIOP_RETURN(); } // also operator
315"..." { NAMEDOP_RETURN(ELLIPSIS); }
316
317 /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
318"<:" { RETURN_VAL('['); }
319":>" { RETURN_VAL(']'); }
320"<%" { RETURN_VAL('{'); }
321"%>" { RETURN_VAL('}'); }
322
323 /* operators */
324"!" { ASCIIOP_RETURN(); }
325"+" { ASCIIOP_RETURN(); }
326"-" { ASCIIOP_RETURN(); }
327"*" { ASCIIOP_RETURN(); }
328"/" { ASCIIOP_RETURN(); }
329"%" { ASCIIOP_RETURN(); }
330"^" { ASCIIOP_RETURN(); }
331"~" { ASCIIOP_RETURN(); }
332"&" { ASCIIOP_RETURN(); }
333"|" { ASCIIOP_RETURN(); }
334"<" { ASCIIOP_RETURN(); }
335">" { ASCIIOP_RETURN(); }
336"=" { ASCIIOP_RETURN(); }
337"?" { ASCIIOP_RETURN(); }
338
339"++" { NAMEDOP_RETURN(ICR); }
340"--" { NAMEDOP_RETURN(DECR); }
341"==" { NAMEDOP_RETURN(EQ); }
342"!=" { NAMEDOP_RETURN(NE); }
343"<<" { NAMEDOP_RETURN(LS); }
344">>" { NAMEDOP_RETURN(RS); }
345"<=" { NAMEDOP_RETURN(LE); }
346">=" { NAMEDOP_RETURN(GE); }
347"&&" { NAMEDOP_RETURN(ANDAND); }
348"||" { NAMEDOP_RETURN(OROR); }
349"->" { NAMEDOP_RETURN(ARROW); }
350"+=" { NAMEDOP_RETURN(PLUSassign); }
351"-=" { NAMEDOP_RETURN(MINUSassign); }
352"*=" { NAMEDOP_RETURN(MULTassign); }
353"/=" { NAMEDOP_RETURN(DIVassign); }
354"%=" { NAMEDOP_RETURN(MODassign); }
355"&=" { NAMEDOP_RETURN(ANDassign); }
356"|=" { NAMEDOP_RETURN(ORassign); }
357"^=" { NAMEDOP_RETURN(ERassign); }
358"<<=" { NAMEDOP_RETURN(LSassign); }
359">>=" { NAMEDOP_RETURN(RSassign); }
360
361"@=" { NAMEDOP_RETURN(ATassign); }
362
363 /* CFA, operator identifier */
364{op_unary}"?" { IDENTIFIER_RETURN(); } // unary
365"?"({op_unary_pre_post}|"()"|"[?]"|"{}") { IDENTIFIER_RETURN(); }
366"^?{}" { IDENTIFIER_RETURN(); }
367"?"{op_binary_over}"?" { IDENTIFIER_RETURN(); } // binary
368 /*
369 This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the string "*?*?"
370 can be lexed as "*"/"?*?" or "*?"/"*?". Since it is common practise to put a unary operator juxtaposed
371 to an identifier, e.g., "*i", users will be annoyed if they cannot do this with respect to operator
372 identifiers. Even with this special hack, there are 5 general cases that cannot be handled. The first
373 case is for the function-call identifier "?()":
374
375 int * ?()(); // declaration: space required after '*'
376 * ?()(); // expression: space required after '*'
377
378 Without the space, the string "*?()" is ambiguous without N character look ahead; it requires scanning
379 ahead to determine if there is a '(', which is the start of an argument/parameter list.
380
381 The 4 remaining cases occur in expressions:
382
383 i++?i:0; // space required before '?'
384 i--?i:0; // space required before '?'
385 i?++i:0; // space required after '?'
386 i?--i:0; // space required after '?'
387
388 In the first two cases, the string "i++?" is ambiguous, where this string can be lexed as "i"/"++?" or
389 "i++"/"?"; it requires scanning ahead to determine if there is a '(', which is the start of an argument
390 list. In the second two cases, the string "?++x" is ambiguous, where this string can be lexed as
391 "?++"/"x" or "?"/"++x"; it requires scanning ahead to determine if there is a '(', which is the start of
392 an argument list.
393 */
394{op_unary}"?"({op_unary_pre_post}|"[?]"|{op_binary_over}"?") {
395 // 1 or 2 character unary operator ?
396 int i = yytext[1] == '?' ? 1 : 2;
397 yyless( i ); // put back characters up to first '?'
398 if ( i > 1 ) {
399 NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
400 } else {
401 ASCIIOP_RETURN();
402 } // if
403}
404
405 /* unknown characters */
406. { printf("unknown character(s):\"%s\" on line %d\n", yytext, yylineno); }
407
408%%
409
410// Local Variables: //
411// mode: c++ //
412// tab-width: 4 //
413// compile-command: "make install" //
414// End: //
Note: See TracBrowser for help on using the repository browser.