source: src/Parser/lex.ll@ 2d59d53

ADT aaron-thesis arm-eh ast-experimental cleanup-dtors deferred_resn demangler enum forall-pointer-decay jacob/cs343-translation jenkins-sandbox new-ast new-ast-unique-expr new-env no_list persistent-indexer pthread-emulation qualifiedEnum resolv-new with_gc
Last change on this file since 2d59d53 was 3a2128f, checked in by Peter A. Buhr <pabuhr@…>, 9 years ago

add types zero_t and one_t to lexer/parser
  • Property mode set to 100644
File size: 15.9 KB
Line 
1/*
2 * Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3 *
4 * The contents of this file are covered under the licence agreement in the
5 * file "LICENCE" distributed with Cforall.
6 *
7 * lex.l --
8 *
9 * Author : Peter A. Buhr
10 * Created On : Sat Sep 22 08:58:10 2001
11 * Last Modified By : Peter A. Buhr
12 * Last Modified On : Tue Nov 29 11:32:00 2016
13 * Update Count : 501
14 */
15
16%option yylineno
17%option nounput
18
19%{
20// This lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
21// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
22// line-number directives) and C/C++ style comments, which are ignored.
23
24//**************************** Includes and Defines ****************************
25
26#include <string>
27#include <cstdio> // FILENAME_MAX
28
29#include "lex.h"
30#include "parser.h" // YACC generated definitions based on C++ grammar
31#include "ParseNode.h"
32#include "TypedefTable.h"
33
34char *yyfilename;
35std::string *strtext; // accumulate parts of character and string constant value
36
37#define RETURN_LOCN(x) yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
38#define RETURN_VAL(x) yylval.tok.str = new std::string( yytext ); RETURN_LOCN( x )
39#define RETURN_CHAR(x) yylval.tok.str = nullptr; RETURN_LOCN( x )
40#define RETURN_STR(x) yylval.tok.str = strtext; RETURN_LOCN( x )
41
42#define WHITE_RETURN(x) // do nothing
43#define NEWLINE_RETURN() WHITE_RETURN( '\n' )
44#define ASCIIOP_RETURN() RETURN_CHAR( (int)yytext[0] ) // single character operator
45#define NAMEDOP_RETURN(x) RETURN_CHAR( x ) // multichar operator, with a name
46#define NUMERIC_RETURN(x) rm_underscore(); RETURN_VAL( x ) // numeric constant
47#define KEYWORD_RETURN(x) RETURN_CHAR( x ) // keyword
48#define IDENTIFIER_RETURN() RETURN_VAL( typedefTable.isKind( yytext ) )
49#define ATTRIBUTE_RETURN() RETURN_VAL( ATTR_IDENTIFIER )
50
51void rm_underscore() {
52 // Remove underscores in numeric constant by copying the non-underscore characters to the front of the string.
53 yyleng = 0;
54 for ( int i = 0; yytext[i] != '\0'; i += 1 ) {
55 if ( yytext[i] != '_' ) {
56 yytext[yyleng] = yytext[i];
57 yyleng += 1;
58 } // if
59 } // for
60 yytext[yyleng] = '\0';
61}
62
63%}
64
65octal [0-7]
66nonzero [1-9]
67decimal [0-9]
68hex [0-9a-fA-F]
69universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2}))
70
71 // identifier, GCC: $ in identifier
72identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})*
73
74 // attribute identifier, GCC: $ in identifier
75attr_identifier "@"{identifier}
76
77 // numeric constants, CFA: '_' in constant
78hex_quad {hex}("_"?{hex}){3}
79integer_suffix "_"?(([uU][lL]?)|([uU]("ll"|"LL")?)|([lL][uU]?)|("ll"|"LL")[uU]?)
80
81octal_digits ({octal})|({octal}({octal}|"_")*{octal})
82octal_prefix "0""_"?
83octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix}?
84
85nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal})
86decimal_constant {nonzero_digits}{integer_suffix}?
87
88hex_digits ({hex})|({hex}({hex}|"_")*{hex})
89hex_prefix "0"[xX]"_"?
90hex_constant {hex_prefix}{hex_digits}{integer_suffix}?
91
92decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal})
93real_decimal {decimal_digits}"."
94real_fraction "."{decimal_digits}
95real_constant {decimal_digits}?{real_fraction}
96exponent "_"?[eE]"_"?[+-]?{decimal_digits}
97 // GCC: D (double), DL (long double) and iI (imaginary) suffixes
98floating_suffix "_"?([fFdDlL][iI]?|"DL"|[iI][lLfFdD]?)
99 //floating_suffix "_"?([fFdD]|[lL]|[D][L])|([iI][lLfFdD])|([lLfFdD][iI]))
100floating_constant (({real_constant}{exponent}?)|({decimal_digits}{exponent})){floating_suffix}?
101
102binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
103hex_fractional_constant ({hex_digits}?"."{hex_digits})|({hex_digits}".")
104hex_floating_constant {hex_prefix}(({hex_fractional_constant}{binary_exponent})|({hex_digits}{binary_exponent})){floating_suffix}?
105
106 // character escape sequence, GCC: \e => esc character
107simple_escape "\\"[abefnrtv'"?\\]
108 // ' stop highlighting
109octal_escape "\\"{octal}("_"?{octal}){0,2}
110hex_escape "\\""x""_"?{hex_digits}
111escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char}
112cwide_prefix "L"|"U"|"u"
113swide_prefix {cwide_prefix}|"u8"
114
115 // display/white-space characters
116h_tab [\011]
117form_feed [\014]
118v_tab [\013]
119c_return [\015]
120h_white [ ]|{h_tab}
121
122 // overloadable operators
123op_unary_only "~"|"!"
124op_unary_binary "+"|"-"|"*"
125op_unary_pre_post "++"|"--"
126op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post}
127
128op_binary_only "/"|"%"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"&="|"|="|"^="|"<<="|">>="
129op_binary_over {op_unary_binary}|{op_binary_only}
130 // op_binary_not_over "?"|"->"|"."|"&&"|"||"|"@="
131 // operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over}
132
133%x COMMENT
134%x BKQUOTE
135%x QUOTE
136%x STRING
137
138%%
139 /* line directives */
140^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["].*"\n" {
141 /* " stop highlighting */
142 static char filename[FILENAME_MAX]; // temporarily store current source-file name
143 char *end_num;
144 char *begin_string, *end_string;
145 long lineno, length;
146 lineno = strtol( yytext + 1, &end_num, 0 );
147 begin_string = strchr( end_num, '"' );
148 if ( begin_string ) { // file name ?
149 end_string = strchr( begin_string + 1, '"' ); // look for ending delimiter
150 assert( end_string ); // closing quote ?
151 length = end_string - begin_string - 1; // file-name length without quotes or sentinel
152 assert( length < FILENAME_MAX ); // room for sentinel ?
153 memcpy( &filename, begin_string + 1, length ); // copy file name from yytext
154 filename[ length ] = '\0'; // terminate string with sentinel
155 //std::cout << "file " << filename << " line " << lineno << std::endl;
156 yylineno = lineno;
157 yyfilename = filename;
158 } // if
159}
160
161 /* ignore preprocessor directives (for now) */
162^{h_white}*"#"[^\n]*"\n" ;
163
164 /* ignore C style comments (ALSO HANDLED BY CPP) */
165"/*" { BEGIN COMMENT; }
166<COMMENT>.|\n ;
167<COMMENT>"*/" { BEGIN 0; }
168
169 /* ignore C++ style comments (ALSO HANDLED BY CPP) */
170"//"[^\n]*"\n" ;
171
172 /* ignore whitespace */
173{h_white}+ { WHITE_RETURN(' '); }
174({v_tab}|{c_return}|{form_feed})+ { WHITE_RETURN(' '); }
175({h_white}|{v_tab}|{c_return}|{form_feed})*"\n" { NEWLINE_RETURN(); }
176
177 /* keywords */
178_Alignas { KEYWORD_RETURN(ALIGNAS); } // C11
179_Alignof { KEYWORD_RETURN(ALIGNOF); } // C11
180__alignof { KEYWORD_RETURN(ALIGNOF); } // GCC
181__alignof__ { KEYWORD_RETURN(ALIGNOF); } // GCC
182asm { KEYWORD_RETURN(ASM); }
183__asm { KEYWORD_RETURN(ASM); } // GCC
184__asm__ { KEYWORD_RETURN(ASM); } // GCC
185_At { KEYWORD_RETURN(AT); } // CFA
186_Atomic { KEYWORD_RETURN(ATOMIC); } // C11
187__attribute { KEYWORD_RETURN(ATTRIBUTE); } // GCC
188__attribute__ { KEYWORD_RETURN(ATTRIBUTE); } // GCC
189auto { KEYWORD_RETURN(AUTO); }
190_Bool { KEYWORD_RETURN(BOOL); } // C99
191break { KEYWORD_RETURN(BREAK); }
192case { KEYWORD_RETURN(CASE); }
193catch { KEYWORD_RETURN(CATCH); } // CFA
194catchResume { KEYWORD_RETURN(CATCHRESUME); } // CFA
195char { KEYWORD_RETURN(CHAR); }
196choose { KEYWORD_RETURN(CHOOSE); } // CFA
197_Complex { KEYWORD_RETURN(COMPLEX); } // C99
198__complex { KEYWORD_RETURN(COMPLEX); } // GCC
199__complex__ { KEYWORD_RETURN(COMPLEX); } // GCC
200const { KEYWORD_RETURN(CONST); }
201__const { KEYWORD_RETURN(CONST); } // GCC
202__const__ { KEYWORD_RETURN(CONST); } // GCC
203continue { KEYWORD_RETURN(CONTINUE); }
204default { KEYWORD_RETURN(DEFAULT); }
205disable { KEYWORD_RETURN(DISABLE); } // CFA
206do { KEYWORD_RETURN(DO); }
207double { KEYWORD_RETURN(DOUBLE); }
208dtype { KEYWORD_RETURN(DTYPE); } // CFA
209else { KEYWORD_RETURN(ELSE); }
210enable { KEYWORD_RETURN(ENABLE); } // CFA
211enum { KEYWORD_RETURN(ENUM); }
212__extension__ { KEYWORD_RETURN(EXTENSION); } // GCC
213extern { KEYWORD_RETURN(EXTERN); }
214fallthrough { KEYWORD_RETURN(FALLTHRU); } // CFA
215fallthru { KEYWORD_RETURN(FALLTHRU); } // CFA
216finally { KEYWORD_RETURN(FINALLY); } // CFA
217float { KEYWORD_RETURN(FLOAT); }
218__float128 { KEYWORD_RETURN(FLOAT); } // GCC
219for { KEYWORD_RETURN(FOR); }
220forall { KEYWORD_RETURN(FORALL); } // CFA
221fortran { KEYWORD_RETURN(FORTRAN); }
222ftype { KEYWORD_RETURN(FTYPE); } // CFA
223_Generic { KEYWORD_RETURN(GENERIC); } // C11
224goto { KEYWORD_RETURN(GOTO); }
225if { KEYWORD_RETURN(IF); }
226_Imaginary { KEYWORD_RETURN(IMAGINARY); } // C99
227__imag { KEYWORD_RETURN(IMAGINARY); } // GCC
228__imag__ { KEYWORD_RETURN(IMAGINARY); } // GCC
229inline { KEYWORD_RETURN(INLINE); } // C99
230__inline { KEYWORD_RETURN(INLINE); } // GCC
231__inline__ { KEYWORD_RETURN(INLINE); } // GCC
232int { KEYWORD_RETURN(INT); }
233__int128 { KEYWORD_RETURN(INT); } // GCC
234__label__ { KEYWORD_RETURN(LABEL); } // GCC
235long { KEYWORD_RETURN(LONG); }
236lvalue { KEYWORD_RETURN(LVALUE); } // CFA
237_Noreturn { KEYWORD_RETURN(NORETURN); } // C11
238__builtin_offsetof { KEYWORD_RETURN(OFFSETOF); } // GCC
239one_t { NUMERIC_RETURN(ONE_T); } // CFA
240otype { KEYWORD_RETURN(OTYPE); } // CFA
241register { KEYWORD_RETURN(REGISTER); }
242restrict { KEYWORD_RETURN(RESTRICT); } // C99
243__restrict { KEYWORD_RETURN(RESTRICT); } // GCC
244__restrict__ { KEYWORD_RETURN(RESTRICT); } // GCC
245return { KEYWORD_RETURN(RETURN); }
246short { KEYWORD_RETURN(SHORT); }
247signed { KEYWORD_RETURN(SIGNED); }
248__signed { KEYWORD_RETURN(SIGNED); } // GCC
249__signed__ { KEYWORD_RETURN(SIGNED); } // GCC
250sizeof { KEYWORD_RETURN(SIZEOF); }
251static { KEYWORD_RETURN(STATIC); }
252_Static_assert { KEYWORD_RETURN(STATICASSERT); } // C11
253struct { KEYWORD_RETURN(STRUCT); }
254switch { KEYWORD_RETURN(SWITCH); }
255_Thread_local { KEYWORD_RETURN(THREADLOCAL); } // C11
256throw { KEYWORD_RETURN(THROW); } // CFA
257throwResume { KEYWORD_RETURN(THROWRESUME); } // CFA
258trait { KEYWORD_RETURN(TRAIT); } // CFA
259try { KEYWORD_RETURN(TRY); } // CFA
260typedef { KEYWORD_RETURN(TYPEDEF); }
261typeof { KEYWORD_RETURN(TYPEOF); } // GCC
262__typeof { KEYWORD_RETURN(TYPEOF); } // GCC
263__typeof__ { KEYWORD_RETURN(TYPEOF); } // GCC
264union { KEYWORD_RETURN(UNION); }
265unsigned { KEYWORD_RETURN(UNSIGNED); }
266__builtin_va_list { KEYWORD_RETURN(VALIST); } // GCC
267void { KEYWORD_RETURN(VOID); }
268volatile { KEYWORD_RETURN(VOLATILE); }
269__volatile { KEYWORD_RETURN(VOLATILE); } // GCC
270__volatile__ { KEYWORD_RETURN(VOLATILE); } // GCC
271while { KEYWORD_RETURN(WHILE); }
272zero_t { NUMERIC_RETURN(ZERO_T); } // CFA
273
274 /* identifier */
275{identifier} { IDENTIFIER_RETURN(); }
276{attr_identifier} { ATTRIBUTE_RETURN(); }
277"`" { BEGIN BKQUOTE; }
278<BKQUOTE>{identifier} { IDENTIFIER_RETURN(); }
279<BKQUOTE>"`" { BEGIN 0; }
280
281 /* numeric constants */
282"0" { NUMERIC_RETURN(ZERO); } // CFA
283"1" { NUMERIC_RETURN(ONE); } // CFA
284{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
285{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
286{hex_constant} { NUMERIC_RETURN(INTEGERconstant); }
287{real_decimal} { NUMERIC_RETURN(REALDECIMALconstant); } // must appear before floating_constant
288{real_fraction} { NUMERIC_RETURN(REALFRACTIONconstant); } // must appear before floating_constant
289{floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
290{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
291
292 /* character constant, allows empty value */
293({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new std::string( yytext, yyleng ); }
294<QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); }
295<QUOTE>['\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); }
296 /* ' stop highlighting */
297
298 /* string constant */
299({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new std::string( yytext, yyleng ); }
300<STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); }
301<STRING>["\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); }
302 /* " stop highlighting */
303
304 /* common character/string constant */
305<QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); }
306<QUOTE,STRING>"\\"{h_white}*"\n" {} // continuation (ALSO HANDLED BY CPP)
307<QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character
308
309 /* punctuation */
310"[" { ASCIIOP_RETURN(); }
311"]" { ASCIIOP_RETURN(); }
312"(" { ASCIIOP_RETURN(); }
313")" { ASCIIOP_RETURN(); }
314"{" { ASCIIOP_RETURN(); }
315"}" { ASCIIOP_RETURN(); }
316"," { ASCIIOP_RETURN(); } // also operator
317":" { ASCIIOP_RETURN(); }
318";" { ASCIIOP_RETURN(); }
319"." { ASCIIOP_RETURN(); } // also operator
320"..." { NAMEDOP_RETURN(ELLIPSIS); }
321
322 /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
323"<:" { RETURN_VAL('['); }
324":>" { RETURN_VAL(']'); }
325"<%" { RETURN_VAL('{'); }
326"%>" { RETURN_VAL('}'); }
327
328 /* operators */
329"!" { ASCIIOP_RETURN(); }
330"+" { ASCIIOP_RETURN(); }
331"-" { ASCIIOP_RETURN(); }
332"*" { ASCIIOP_RETURN(); }
333"/" { ASCIIOP_RETURN(); }
334"%" { ASCIIOP_RETURN(); }
335"^" { ASCIIOP_RETURN(); }
336"~" { ASCIIOP_RETURN(); }
337"&" { ASCIIOP_RETURN(); }
338"|" { ASCIIOP_RETURN(); }
339"<" { ASCIIOP_RETURN(); }
340">" { ASCIIOP_RETURN(); }
341"=" { ASCIIOP_RETURN(); }
342"?" { ASCIIOP_RETURN(); }
343
344"++" { NAMEDOP_RETURN(ICR); }
345"--" { NAMEDOP_RETURN(DECR); }
346"==" { NAMEDOP_RETURN(EQ); }
347"!=" { NAMEDOP_RETURN(NE); }
348"<<" { NAMEDOP_RETURN(LS); }
349">>" { NAMEDOP_RETURN(RS); }
350"<=" { NAMEDOP_RETURN(LE); }
351">=" { NAMEDOP_RETURN(GE); }
352"&&" { NAMEDOP_RETURN(ANDAND); }
353"||" { NAMEDOP_RETURN(OROR); }
354"->" { NAMEDOP_RETURN(ARROW); }
355"+=" { NAMEDOP_RETURN(PLUSassign); }
356"-=" { NAMEDOP_RETURN(MINUSassign); }
357"*=" { NAMEDOP_RETURN(MULTassign); }
358"/=" { NAMEDOP_RETURN(DIVassign); }
359"%=" { NAMEDOP_RETURN(MODassign); }
360"&=" { NAMEDOP_RETURN(ANDassign); }
361"|=" { NAMEDOP_RETURN(ORassign); }
362"^=" { NAMEDOP_RETURN(ERassign); }
363"<<=" { NAMEDOP_RETURN(LSassign); }
364">>=" { NAMEDOP_RETURN(RSassign); }
365
366"@=" { NAMEDOP_RETURN(ATassign); } // CFA
367
368 /* CFA, operator identifier */
369{op_unary}"?" { IDENTIFIER_RETURN(); } // unary
370"?"({op_unary_pre_post}|"()"|"[?]"|"{}") { IDENTIFIER_RETURN(); }
371"^?{}" { IDENTIFIER_RETURN(); }
372"?"{op_binary_over}"?" { IDENTIFIER_RETURN(); } // binary
373 /*
374 This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the string "*?*?"
375 can be lexed as "*"/"?*?" or "*?"/"*?". Since it is common practise to put a unary operator juxtaposed
376 to an identifier, e.g., "*i", users will be annoyed if they cannot do this with respect to operator
377 identifiers. Even with this special hack, there are 5 general cases that cannot be handled. The first
378 case is for the function-call identifier "?()":
379
380 int * ?()(); // declaration: space required after '*'
381 * ?()(); // expression: space required after '*'
382
383 Without the space, the string "*?()" is ambiguous without N character look ahead; it requires scanning
384 ahead to determine if there is a '(', which is the start of an argument/parameter list.
385
386 The 4 remaining cases occur in expressions:
387
388 i++?i:0; // space required before '?'
389 i--?i:0; // space required before '?'
390 i?++i:0; // space required after '?'
391 i?--i:0; // space required after '?'
392
393 In the first two cases, the string "i++?" is ambiguous, where this string can be lexed as "i"/"++?" or
394 "i++"/"?"; it requires scanning ahead to determine if there is a '(', which is the start of an argument
395 list. In the second two cases, the string "?++x" is ambiguous, where this string can be lexed as
396 "?++"/"x" or "?"/"++x"; it requires scanning ahead to determine if there is a '(', which is the start of
397 an argument list.
398 */
399{op_unary}"?"({op_unary_pre_post}|"[?]"|{op_binary_over}"?") {
400 // 1 or 2 character unary operator ?
401 int i = yytext[1] == '?' ? 1 : 2;
402 yyless( i ); // put back characters up to first '?'
403 if ( i > 1 ) {
404 NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
405 } else {
406 ASCIIOP_RETURN();
407 } // if
408}
409
410 /* unknown characters */
411. { printf("unknown character(s):\"%s\" on line %d\n", yytext, yylineno); }
412
413%%
414
415// Local Variables: //
416// mode: c++ //
417// tab-width: 4 //
418// compile-command: "make install" //
419// End: //
Note: See TracBrowser for help on using the repository browser.