| 1 | /*
|
|---|
| 2 | * Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
|
|---|
| 3 | *
|
|---|
| 4 | * The contents of this file are covered under the licence agreement in the
|
|---|
| 5 | * file "LICENCE" distributed with Cforall.
|
|---|
| 6 | *
|
|---|
| 7 | * lex.ll --
|
|---|
| 8 | *
|
|---|
| 9 | * Author : Peter A. Buhr
|
|---|
| 10 | * Created On : Sat Sep 22 08:58:10 2001
|
|---|
| 11 | * Last Modified By : Peter A. Buhr
|
|---|
| 12 | * Last Modified On : Thu Jul 27 21:46:06 2017
|
|---|
| 13 | * Update Count : 550
|
|---|
| 14 | */
|
|---|
| 15 |
|
|---|
| 16 | %option yylineno
|
|---|
| 17 | %option noyywrap
|
|---|
| 18 | %option nounput
|
|---|
| 19 |
|
|---|
| 20 | %{
|
|---|
| 21 | // This lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
|
|---|
| 22 | // performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
|
|---|
| 23 | // line-number directives) and C/C++ style comments, which are ignored.
|
|---|
| 24 |
|
|---|
| 25 | //**************************** Includes and Defines ****************************
|
|---|
| 26 |
|
|---|
| 27 | #include <string>
|
|---|
| 28 | #include <cstdio> // FILENAME_MAX
|
|---|
| 29 |
|
|---|
| 30 | #include "ParseNode.h"
|
|---|
| 31 | #include "TypedefTable.h"
|
|---|
| 32 |
|
|---|
| 33 | char *yyfilename;
|
|---|
| 34 | std::string *strtext; // accumulate parts of character and string constant value
|
|---|
| 35 |
|
|---|
| 36 | #define RETURN_LOCN(x) yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
|
|---|
| 37 | #define RETURN_VAL(x) yylval.tok.str = new std::string( yytext ); RETURN_LOCN( x )
|
|---|
| 38 | #define RETURN_CHAR(x) yylval.tok.str = nullptr; RETURN_LOCN( x )
|
|---|
| 39 | #define RETURN_STR(x) yylval.tok.str = strtext; RETURN_LOCN( x )
|
|---|
| 40 |
|
|---|
| 41 | #define WHITE_RETURN(x) // do nothing
|
|---|
| 42 | #define NEWLINE_RETURN() WHITE_RETURN( '\n' )
|
|---|
| 43 | #define ASCIIOP_RETURN() RETURN_CHAR( (int)yytext[0] ) // single character operator
|
|---|
| 44 | #define NAMEDOP_RETURN(x) RETURN_CHAR( x ) // multichar operator, with a name
|
|---|
| 45 | #define NUMERIC_RETURN(x) rm_underscore(); RETURN_VAL( x ) // numeric constant
|
|---|
| 46 | #define KEYWORD_RETURN(x) RETURN_CHAR( x ) // keyword
|
|---|
| 47 | #define IDENTIFIER_RETURN() RETURN_VAL( typedefTable.isKind( yytext ) )
|
|---|
| 48 | #define ATTRIBUTE_RETURN() RETURN_VAL( ATTR_IDENTIFIER )
|
|---|
| 49 |
|
|---|
| 50 | void rm_underscore() {
|
|---|
| 51 | // Remove underscores in numeric constant by copying the non-underscore characters to the front of the string.
|
|---|
| 52 | yyleng = 0;
|
|---|
| 53 | for ( int i = 0; yytext[i] != '\0'; i += 1 ) {
|
|---|
| 54 | if ( yytext[i] != '_' ) {
|
|---|
| 55 | yytext[yyleng] = yytext[i];
|
|---|
| 56 | yyleng += 1;
|
|---|
| 57 | } // if
|
|---|
| 58 | } // for
|
|---|
| 59 | yytext[yyleng] = '\0';
|
|---|
| 60 | }
|
|---|
| 61 |
|
|---|
| 62 | // Stop warning due to incorrectly generated flex code.
|
|---|
| 63 | #pragma GCC diagnostic ignored "-Wsign-compare"
|
|---|
| 64 | %}
|
|---|
| 65 |
|
|---|
| 66 | octal [0-7]
|
|---|
| 67 | nonzero [1-9]
|
|---|
| 68 | decimal [0-9]
|
|---|
| 69 | hex [0-9a-fA-F]
|
|---|
| 70 | universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2}))
|
|---|
| 71 |
|
|---|
| 72 | // identifier, GCC: $ in identifier
|
|---|
| 73 | identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})*
|
|---|
| 74 |
|
|---|
| 75 | // attribute identifier, GCC: $ in identifier
|
|---|
| 76 | attr_identifier "@"{identifier}
|
|---|
| 77 |
|
|---|
| 78 | // numeric constants, CFA: '_' in constant
|
|---|
| 79 | hex_quad {hex}("_"?{hex}){3}
|
|---|
| 80 | integer_suffix "_"?(([uU](("ll"|"LL"|[lL])[iI]|[iI]?("ll"|"LL"|[lL])?))|([iI](("ll"|"LL"|[lL])[uU]|[uU]?("ll"|"LL"|[lL])?))|(("ll"|"LL"|[lL])([iI][uU]|[uU]?[iI]?)))
|
|---|
| 81 |
|
|---|
| 82 | octal_digits ({octal})|({octal}({octal}|"_")*{octal})
|
|---|
| 83 | octal_prefix "0""_"?
|
|---|
| 84 | octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix}?
|
|---|
| 85 |
|
|---|
| 86 | nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal})
|
|---|
| 87 | decimal_constant {nonzero_digits}{integer_suffix}?
|
|---|
| 88 |
|
|---|
| 89 | hex_digits ({hex})|({hex}({hex}|"_")*{hex})
|
|---|
| 90 | hex_prefix "0"[xX]"_"?
|
|---|
| 91 | hex_constant {hex_prefix}{hex_digits}{integer_suffix}?
|
|---|
| 92 |
|
|---|
| 93 | decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal})
|
|---|
| 94 | real_decimal {decimal_digits}"."{exponent}?{floating_suffix}?
|
|---|
| 95 | real_fraction "."{decimal_digits}{exponent}?{floating_suffix}?
|
|---|
| 96 | real_constant {decimal_digits}{real_fraction}
|
|---|
| 97 | exponent "_"?[eE]"_"?[+-]?{decimal_digits}
|
|---|
| 98 | // GCC: D (double) and iI (imaginary) suffixes, and DL (long double)
|
|---|
| 99 | floating_suffix "_"?([fFdDlL][iI]?|[iI][lLfFdD]?|"DL")
|
|---|
| 100 | floating_constant (({real_constant}{exponent}?)|({decimal_digits}{exponent})){floating_suffix}?
|
|---|
| 101 |
|
|---|
| 102 | binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
|
|---|
| 103 | hex_fractional_constant ({hex_digits}?"."{hex_digits})|({hex_digits}".")
|
|---|
| 104 | hex_floating_constant {hex_prefix}(({hex_fractional_constant}{binary_exponent})|({hex_digits}{binary_exponent})){floating_suffix}?
|
|---|
| 105 |
|
|---|
| 106 | // character escape sequence, GCC: \e => esc character
|
|---|
| 107 | simple_escape "\\"[abefnrtv'"?\\]
|
|---|
| 108 | // ' stop highlighting
|
|---|
| 109 | octal_escape "\\"{octal}("_"?{octal}){0,2}
|
|---|
| 110 | hex_escape "\\""x""_"?{hex_digits}
|
|---|
| 111 | escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char}
|
|---|
| 112 | cwide_prefix "L"|"U"|"u"
|
|---|
| 113 | swide_prefix {cwide_prefix}|"u8"
|
|---|
| 114 |
|
|---|
| 115 | // display/white-space characters
|
|---|
| 116 | h_tab [\011]
|
|---|
| 117 | form_feed [\014]
|
|---|
| 118 | v_tab [\013]
|
|---|
| 119 | c_return [\015]
|
|---|
| 120 | h_white [ ]|{h_tab}
|
|---|
| 121 |
|
|---|
| 122 | // overloadable operators
|
|---|
| 123 | op_unary_only "~"|"!"
|
|---|
| 124 | op_unary_binary "+"|"-"|"*"
|
|---|
| 125 | op_unary_pre_post "++"|"--"
|
|---|
| 126 | op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post}
|
|---|
| 127 |
|
|---|
| 128 | op_binary_only "/"|"%"|"\\"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"\\="|"&="|"|="|"^="|"<<="|">>="
|
|---|
| 129 | op_binary_over {op_unary_binary}|{op_binary_only}
|
|---|
| 130 | // op_binary_not_over "?"|"->"|"."|"&&"|"||"|"@="
|
|---|
| 131 | // operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over}
|
|---|
| 132 |
|
|---|
| 133 | %x COMMENT
|
|---|
| 134 | %x BKQUOTE
|
|---|
| 135 | %x QUOTE
|
|---|
| 136 | %x STRING
|
|---|
| 137 |
|
|---|
| 138 | %%
|
|---|
| 139 | /* line directives */
|
|---|
| 140 | ^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["].*"\n" {
|
|---|
| 141 | /* " stop highlighting */
|
|---|
| 142 | static char filename[FILENAME_MAX]; // temporarily store current source-file name
|
|---|
| 143 | char *end_num;
|
|---|
| 144 | char *begin_string, *end_string;
|
|---|
| 145 | long lineno, length;
|
|---|
| 146 | lineno = strtol( yytext + 1, &end_num, 0 );
|
|---|
| 147 | begin_string = strchr( end_num, '"' );
|
|---|
| 148 | if ( begin_string ) { // file name ?
|
|---|
| 149 | end_string = strchr( begin_string + 1, '"' ); // look for ending delimiter
|
|---|
| 150 | assert( end_string ); // closing quote ?
|
|---|
| 151 | length = end_string - begin_string - 1; // file-name length without quotes or sentinel
|
|---|
| 152 | assert( length < FILENAME_MAX ); // room for sentinel ?
|
|---|
| 153 | memcpy( &filename, begin_string + 1, length ); // copy file name from yytext
|
|---|
| 154 | filename[ length ] = '\0'; // terminate string with sentinel
|
|---|
| 155 | //std::cout << "file " << filename << " line " << lineno << std::endl;
|
|---|
| 156 | yylineno = lineno;
|
|---|
| 157 | yyfilename = filename;
|
|---|
| 158 | } // if
|
|---|
| 159 | }
|
|---|
| 160 |
|
|---|
| 161 | /* ignore preprocessor directives (for now) */
|
|---|
| 162 | ^{h_white}*"#"[^\n]*"\n" ;
|
|---|
| 163 |
|
|---|
| 164 | /* ignore C style comments (ALSO HANDLED BY CPP) */
|
|---|
| 165 | "/*" { BEGIN COMMENT; }
|
|---|
| 166 | <COMMENT>.|\n ;
|
|---|
| 167 | <COMMENT>"*/" { BEGIN 0; }
|
|---|
| 168 |
|
|---|
| 169 | /* ignore C++ style comments (ALSO HANDLED BY CPP) */
|
|---|
| 170 | "//"[^\n]*"\n" ;
|
|---|
| 171 |
|
|---|
| 172 | /* ignore whitespace */
|
|---|
| 173 | {h_white}+ { WHITE_RETURN(' '); }
|
|---|
| 174 | ({v_tab}|{c_return}|{form_feed})+ { WHITE_RETURN(' '); }
|
|---|
| 175 | ({h_white}|{v_tab}|{c_return}|{form_feed})*"\n" { NEWLINE_RETURN(); }
|
|---|
| 176 |
|
|---|
| 177 | /* keywords */
|
|---|
| 178 | _Alignas { KEYWORD_RETURN(ALIGNAS); } // C11
|
|---|
| 179 | _Alignof { KEYWORD_RETURN(ALIGNOF); } // C11
|
|---|
| 180 | __alignof { KEYWORD_RETURN(ALIGNOF); } // GCC
|
|---|
| 181 | __alignof__ { KEYWORD_RETURN(ALIGNOF); } // GCC
|
|---|
| 182 | asm { KEYWORD_RETURN(ASM); }
|
|---|
| 183 | __asm { KEYWORD_RETURN(ASM); } // GCC
|
|---|
| 184 | __asm__ { KEYWORD_RETURN(ASM); } // GCC
|
|---|
| 185 | _At { KEYWORD_RETURN(AT); } // CFA
|
|---|
| 186 | _Atomic { KEYWORD_RETURN(ATOMIC); } // C11
|
|---|
| 187 | __attribute { KEYWORD_RETURN(ATTRIBUTE); } // GCC
|
|---|
| 188 | __attribute__ { KEYWORD_RETURN(ATTRIBUTE); } // GCC
|
|---|
| 189 | auto { KEYWORD_RETURN(AUTO); }
|
|---|
| 190 | _Bool { KEYWORD_RETURN(BOOL); } // C99
|
|---|
| 191 | break { KEYWORD_RETURN(BREAK); }
|
|---|
| 192 | case { KEYWORD_RETURN(CASE); }
|
|---|
| 193 | catch { KEYWORD_RETURN(CATCH); } // CFA
|
|---|
| 194 | catchResume { KEYWORD_RETURN(CATCHRESUME); } // CFA
|
|---|
| 195 | char { KEYWORD_RETURN(CHAR); }
|
|---|
| 196 | choose { KEYWORD_RETURN(CHOOSE); } // CFA
|
|---|
| 197 | _Complex { KEYWORD_RETURN(COMPLEX); } // C99
|
|---|
| 198 | __complex { KEYWORD_RETURN(COMPLEX); } // GCC
|
|---|
| 199 | __complex__ { KEYWORD_RETURN(COMPLEX); } // GCC
|
|---|
| 200 | const { KEYWORD_RETURN(CONST); }
|
|---|
| 201 | __const { KEYWORD_RETURN(CONST); } // GCC
|
|---|
| 202 | __const__ { KEYWORD_RETURN(CONST); } // GCC
|
|---|
| 203 | continue { KEYWORD_RETURN(CONTINUE); }
|
|---|
| 204 | coroutine { KEYWORD_RETURN(COROUTINE); } // CFA
|
|---|
| 205 | default { KEYWORD_RETURN(DEFAULT); }
|
|---|
| 206 | disable { KEYWORD_RETURN(DISABLE); } // CFA
|
|---|
| 207 | do { KEYWORD_RETURN(DO); }
|
|---|
| 208 | double { KEYWORD_RETURN(DOUBLE); }
|
|---|
| 209 | dtype { KEYWORD_RETURN(DTYPE); } // CFA
|
|---|
| 210 | else { KEYWORD_RETURN(ELSE); }
|
|---|
| 211 | enable { KEYWORD_RETURN(ENABLE); } // CFA
|
|---|
| 212 | enum { KEYWORD_RETURN(ENUM); }
|
|---|
| 213 | __extension__ { KEYWORD_RETURN(EXTENSION); } // GCC
|
|---|
| 214 | extern { KEYWORD_RETURN(EXTERN); }
|
|---|
| 215 | fallthrough { KEYWORD_RETURN(FALLTHRU); } // CFA
|
|---|
| 216 | fallthru { KEYWORD_RETURN(FALLTHRU); } // CFA
|
|---|
| 217 | finally { KEYWORD_RETURN(FINALLY); } // CFA
|
|---|
| 218 | float { KEYWORD_RETURN(FLOAT); }
|
|---|
| 219 | __float128 { KEYWORD_RETURN(FLOAT); } // GCC
|
|---|
| 220 | for { KEYWORD_RETURN(FOR); }
|
|---|
| 221 | forall { KEYWORD_RETURN(FORALL); } // CFA
|
|---|
| 222 | fortran { KEYWORD_RETURN(FORTRAN); }
|
|---|
| 223 | ftype { KEYWORD_RETURN(FTYPE); } // CFA
|
|---|
| 224 | _Generic { KEYWORD_RETURN(GENERIC); } // C11
|
|---|
| 225 | goto { KEYWORD_RETURN(GOTO); }
|
|---|
| 226 | if { KEYWORD_RETURN(IF); }
|
|---|
| 227 | _Imaginary { KEYWORD_RETURN(IMAGINARY); } // C99
|
|---|
| 228 | __imag { KEYWORD_RETURN(IMAGINARY); } // GCC
|
|---|
| 229 | __imag__ { KEYWORD_RETURN(IMAGINARY); } // GCC
|
|---|
| 230 | inline { KEYWORD_RETURN(INLINE); } // C99
|
|---|
| 231 | __inline { KEYWORD_RETURN(INLINE); } // GCC
|
|---|
| 232 | __inline__ { KEYWORD_RETURN(INLINE); } // GCC
|
|---|
| 233 | int { KEYWORD_RETURN(INT); }
|
|---|
| 234 | __int128 { KEYWORD_RETURN(INT); } // GCC
|
|---|
| 235 | __int128_t { KEYWORD_RETURN(INT); } // GCC
|
|---|
| 236 | __label__ { KEYWORD_RETURN(LABEL); } // GCC
|
|---|
| 237 | long { KEYWORD_RETURN(LONG); }
|
|---|
| 238 | lvalue { KEYWORD_RETURN(LVALUE); } // CFA
|
|---|
| 239 | monitor { KEYWORD_RETURN(MONITOR); } // CFA
|
|---|
| 240 | mutex { KEYWORD_RETURN(MUTEX); } // CFA
|
|---|
| 241 | _Noreturn { KEYWORD_RETURN(NORETURN); } // C11
|
|---|
| 242 | __builtin_offsetof { KEYWORD_RETURN(OFFSETOF); } // GCC
|
|---|
| 243 | one_t { NUMERIC_RETURN(ONE_T); } // CFA
|
|---|
| 244 | otype { KEYWORD_RETURN(OTYPE); } // CFA
|
|---|
| 245 | register { KEYWORD_RETURN(REGISTER); }
|
|---|
| 246 | restrict { KEYWORD_RETURN(RESTRICT); } // C99
|
|---|
| 247 | __restrict { KEYWORD_RETURN(RESTRICT); } // GCC
|
|---|
| 248 | __restrict__ { KEYWORD_RETURN(RESTRICT); } // GCC
|
|---|
| 249 | return { KEYWORD_RETURN(RETURN); }
|
|---|
| 250 | short { KEYWORD_RETURN(SHORT); }
|
|---|
| 251 | signed { KEYWORD_RETURN(SIGNED); }
|
|---|
| 252 | __signed { KEYWORD_RETURN(SIGNED); } // GCC
|
|---|
| 253 | __signed__ { KEYWORD_RETURN(SIGNED); } // GCC
|
|---|
| 254 | sizeof { KEYWORD_RETURN(SIZEOF); }
|
|---|
| 255 | static { KEYWORD_RETURN(STATIC); }
|
|---|
| 256 | _Static_assert { KEYWORD_RETURN(STATICASSERT); } // C11
|
|---|
| 257 | struct { KEYWORD_RETURN(STRUCT); }
|
|---|
| 258 | switch { KEYWORD_RETURN(SWITCH); }
|
|---|
| 259 | thread { KEYWORD_RETURN(THREAD); } // C11
|
|---|
| 260 | _Thread_local { KEYWORD_RETURN(THREADLOCAL); } // C11
|
|---|
| 261 | throw { KEYWORD_RETURN(THROW); } // CFA
|
|---|
| 262 | throwResume { KEYWORD_RETURN(THROWRESUME); } // CFA
|
|---|
| 263 | trait { KEYWORD_RETURN(TRAIT); } // CFA
|
|---|
| 264 | try { KEYWORD_RETURN(TRY); } // CFA
|
|---|
| 265 | ttype { KEYWORD_RETURN(TTYPE); } // CFA
|
|---|
| 266 | typedef { KEYWORD_RETURN(TYPEDEF); }
|
|---|
| 267 | typeof { KEYWORD_RETURN(TYPEOF); } // GCC
|
|---|
| 268 | __typeof { KEYWORD_RETURN(TYPEOF); } // GCC
|
|---|
| 269 | __typeof__ { KEYWORD_RETURN(TYPEOF); } // GCC
|
|---|
| 270 | __uint128_t { KEYWORD_RETURN(INT); } // GCC
|
|---|
| 271 | union { KEYWORD_RETURN(UNION); }
|
|---|
| 272 | unsigned { KEYWORD_RETURN(UNSIGNED); }
|
|---|
| 273 | __builtin_va_list { KEYWORD_RETURN(VALIST); } // GCC
|
|---|
| 274 | virtual { KEYWORD_RETURN(VIRTUAL); } // CFA
|
|---|
| 275 | void { KEYWORD_RETURN(VOID); }
|
|---|
| 276 | volatile { KEYWORD_RETURN(VOLATILE); }
|
|---|
| 277 | __volatile { KEYWORD_RETURN(VOLATILE); } // GCC
|
|---|
| 278 | __volatile__ { KEYWORD_RETURN(VOLATILE); } // GCC
|
|---|
| 279 | while { KEYWORD_RETURN(WHILE); }
|
|---|
| 280 | with { KEYWORD_RETURN(WITH); } // CFA
|
|---|
| 281 | zero_t { NUMERIC_RETURN(ZERO_T); } // CFA
|
|---|
| 282 |
|
|---|
| 283 | /* identifier */
|
|---|
| 284 | {identifier} { IDENTIFIER_RETURN(); }
|
|---|
| 285 | {attr_identifier} { ATTRIBUTE_RETURN(); }
|
|---|
| 286 | "`" { BEGIN BKQUOTE; }
|
|---|
| 287 | <BKQUOTE>{identifier} { IDENTIFIER_RETURN(); }
|
|---|
| 288 | <BKQUOTE>"`" { BEGIN 0; }
|
|---|
| 289 |
|
|---|
| 290 | /* numeric constants */
|
|---|
| 291 | {decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
|
|---|
| 292 | {octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
|
|---|
| 293 | {hex_constant} { NUMERIC_RETURN(INTEGERconstant); }
|
|---|
| 294 | {real_decimal} { NUMERIC_RETURN(REALDECIMALconstant); } // must appear before floating_constant
|
|---|
| 295 | {real_fraction} { NUMERIC_RETURN(REALFRACTIONconstant); } // must appear before floating_constant
|
|---|
| 296 | {floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
|
|---|
| 297 | {hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
|
|---|
| 298 |
|
|---|
| 299 | /* character constant, allows empty value */
|
|---|
| 300 | ({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new std::string( yytext, yyleng ); }
|
|---|
| 301 | <QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); }
|
|---|
| 302 | <QUOTE>['\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); }
|
|---|
| 303 | /* ' stop highlighting */
|
|---|
| 304 |
|
|---|
| 305 | /* string constant */
|
|---|
| 306 | ({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new std::string( yytext, yyleng ); }
|
|---|
| 307 | <STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); }
|
|---|
| 308 | <STRING>["\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); }
|
|---|
| 309 | /* " stop highlighting */
|
|---|
| 310 |
|
|---|
| 311 | /* common character/string constant */
|
|---|
| 312 | <QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); }
|
|---|
| 313 | <QUOTE,STRING>"\\"{h_white}*"\n" {} // continuation (ALSO HANDLED BY CPP)
|
|---|
| 314 | <QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character
|
|---|
| 315 |
|
|---|
| 316 | /* punctuation */
|
|---|
| 317 | "@" { ASCIIOP_RETURN(); }
|
|---|
| 318 | "[" { ASCIIOP_RETURN(); }
|
|---|
| 319 | "]" { ASCIIOP_RETURN(); }
|
|---|
| 320 | "(" { ASCIIOP_RETURN(); }
|
|---|
| 321 | ")" { ASCIIOP_RETURN(); }
|
|---|
| 322 | "{" { ASCIIOP_RETURN(); }
|
|---|
| 323 | "}" { ASCIIOP_RETURN(); }
|
|---|
| 324 | "," { ASCIIOP_RETURN(); } // also operator
|
|---|
| 325 | ":" { ASCIIOP_RETURN(); }
|
|---|
| 326 | ";" { ASCIIOP_RETURN(); }
|
|---|
| 327 | "." { ASCIIOP_RETURN(); } // also operator
|
|---|
| 328 | "..." { NAMEDOP_RETURN(ELLIPSIS); }
|
|---|
| 329 |
|
|---|
| 330 | /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
|
|---|
| 331 | "<:" { RETURN_VAL('['); }
|
|---|
| 332 | ":>" { RETURN_VAL(']'); }
|
|---|
| 333 | "<%" { RETURN_VAL('{'); }
|
|---|
| 334 | "%>" { RETURN_VAL('}'); }
|
|---|
| 335 |
|
|---|
| 336 | /* operators */
|
|---|
| 337 | "!" { ASCIIOP_RETURN(); }
|
|---|
| 338 | "+" { ASCIIOP_RETURN(); }
|
|---|
| 339 | "-" { ASCIIOP_RETURN(); }
|
|---|
| 340 | "*" { ASCIIOP_RETURN(); }
|
|---|
| 341 | "\\" { ASCIIOP_RETURN(); } // CFA, exponentiation
|
|---|
| 342 | "/" { ASCIIOP_RETURN(); }
|
|---|
| 343 | "%" { ASCIIOP_RETURN(); }
|
|---|
| 344 | "^" { ASCIIOP_RETURN(); }
|
|---|
| 345 | "~" { ASCIIOP_RETURN(); }
|
|---|
| 346 | "&" { ASCIIOP_RETURN(); }
|
|---|
| 347 | "|" { ASCIIOP_RETURN(); }
|
|---|
| 348 | "<" { ASCIIOP_RETURN(); }
|
|---|
| 349 | ">" { ASCIIOP_RETURN(); }
|
|---|
| 350 | "=" { ASCIIOP_RETURN(); }
|
|---|
| 351 | "?" { ASCIIOP_RETURN(); }
|
|---|
| 352 |
|
|---|
| 353 | "++" { NAMEDOP_RETURN(ICR); }
|
|---|
| 354 | "--" { NAMEDOP_RETURN(DECR); }
|
|---|
| 355 | "==" { NAMEDOP_RETURN(EQ); }
|
|---|
| 356 | "!=" { NAMEDOP_RETURN(NE); }
|
|---|
| 357 | "<<" { NAMEDOP_RETURN(LS); }
|
|---|
| 358 | ">>" { NAMEDOP_RETURN(RS); }
|
|---|
| 359 | "<=" { NAMEDOP_RETURN(LE); }
|
|---|
| 360 | ">=" { NAMEDOP_RETURN(GE); }
|
|---|
| 361 | "&&" { NAMEDOP_RETURN(ANDAND); }
|
|---|
| 362 | "||" { NAMEDOP_RETURN(OROR); }
|
|---|
| 363 | "->" { NAMEDOP_RETURN(ARROW); }
|
|---|
| 364 | "+=" { NAMEDOP_RETURN(PLUSassign); }
|
|---|
| 365 | "-=" { NAMEDOP_RETURN(MINUSassign); }
|
|---|
| 366 | "\\=" { NAMEDOP_RETURN(EXPassign); } // CFA, exponentiation
|
|---|
| 367 | "*=" { NAMEDOP_RETURN(MULTassign); }
|
|---|
| 368 | "/=" { NAMEDOP_RETURN(DIVassign); }
|
|---|
| 369 | "%=" { NAMEDOP_RETURN(MODassign); }
|
|---|
| 370 | "&=" { NAMEDOP_RETURN(ANDassign); }
|
|---|
| 371 | "|=" { NAMEDOP_RETURN(ORassign); }
|
|---|
| 372 | "^=" { NAMEDOP_RETURN(ERassign); }
|
|---|
| 373 | "<<=" { NAMEDOP_RETURN(LSassign); }
|
|---|
| 374 | ">>=" { NAMEDOP_RETURN(RSassign); }
|
|---|
| 375 |
|
|---|
| 376 | "@=" { NAMEDOP_RETURN(ATassign); } // CFA
|
|---|
| 377 |
|
|---|
| 378 | /* CFA, operator identifier */
|
|---|
| 379 | {op_unary}"?" { IDENTIFIER_RETURN(); } // unary
|
|---|
| 380 | "?"({op_unary_pre_post}|"()"|"[?]"|"{}") { IDENTIFIER_RETURN(); }
|
|---|
| 381 | "^?{}" { IDENTIFIER_RETURN(); }
|
|---|
| 382 | "?"{op_binary_over}"?" { IDENTIFIER_RETURN(); } // binary
|
|---|
| 383 | /*
|
|---|
| 384 | This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the string "*?*?" can be
|
|---|
| 385 | lexed as "*?"/"*?" or "*"/"?*?". Since it is common practise to put a unary operator juxtaposed to an identifier,
|
|---|
| 386 | e.g., "*i", users will be annoyed if they cannot do this with respect to operator identifiers. Therefore, there is
|
|---|
| 387 | a lexical look-ahead for the second case, with backtracking to return the leading unary operator and then
|
|---|
| 388 | reparsing the trailing operator identifier. Otherwise a space is needed between the unary operator and operator
|
|---|
| 389 | identifier to disambiguate this common case.
|
|---|
| 390 |
|
|---|
| 391 | A similar issue occurs with the dereference, *?(...), and routine-call, ?()(...) identifiers. The ambiguity
|
|---|
| 392 | occurs when the deference operator has no parameters, *?() and *?()(...), requiring arbitrary whitespace
|
|---|
| 393 | look-ahead for the routine-call parameter-list to disambiguate. However, the dereference operator must have a
|
|---|
| 394 | parameter/argument to dereference *?(...). Hence, always interpreting the string *?() as * ?() does not preclude
|
|---|
| 395 | any meaningful program.
|
|---|
| 396 |
|
|---|
| 397 | The remaining cases are with the increment/decrement operators and conditional expression:
|
|---|
| 398 |
|
|---|
| 399 | i++? ...(...);
|
|---|
| 400 | i?++ ...(...);
|
|---|
| 401 |
|
|---|
| 402 | requiring arbitrary whitespace look-ahead for the operator parameter-list, even though that interpretation is an
|
|---|
| 403 | incorrect expression (juxtaposed identifiers). Therefore, it is necessary to disambiguate these cases with a
|
|---|
| 404 | space:
|
|---|
| 405 |
|
|---|
| 406 | i++ ? i : 0;
|
|---|
| 407 | i? ++i : 0;
|
|---|
| 408 | */
|
|---|
| 409 | {op_unary}"?"({op_unary_pre_post}|"()"|"[?]"|{op_binary_over}"?") {
|
|---|
| 410 | // 1 or 2 character unary operator ?
|
|---|
| 411 | int i = yytext[1] == '?' ? 1 : 2;
|
|---|
| 412 | yyless( i ); // put back characters up to first '?'
|
|---|
| 413 | if ( i > 1 ) {
|
|---|
| 414 | NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
|
|---|
| 415 | } else {
|
|---|
| 416 | ASCIIOP_RETURN();
|
|---|
| 417 | } // if
|
|---|
| 418 | }
|
|---|
| 419 |
|
|---|
| 420 | /* unknown characters */
|
|---|
| 421 | . { printf("unknown character(s):\"%s\" on line %d\n", yytext, yylineno); }
|
|---|
| 422 |
|
|---|
| 423 | %%
|
|---|
| 424 |
|
|---|
| 425 | // Local Variables: //
|
|---|
| 426 | // mode: c++ //
|
|---|
| 427 | // tab-width: 4 //
|
|---|
| 428 | // compile-command: "make install" //
|
|---|
| 429 | // End: //
|
|---|
