Context Navigation

lex.ll@ 08b5a7e

Visit:

ADT aaron-thesis arm-eh ast-experimental cleanup-dtors deferred_resn demangler enum forall-pointer-decay jacob/cs343-translation jenkins-sandbox new-ast new-ast-unique-expr new-env no_list persistent-indexer pthread-emulation qualifiedEnum with_gc

Last change on this file since 08b5a7e was 8551b859, checked in by Peter A. Buhr <pabuhr@…>, 7 years ago
set SemanticErrorThrow for parse error
Property mode set to `100644`
File size: 18.4 KB

Line
1	/*
2	* Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3	*
4	* The contents of this file are covered under the licence agreement in the
5	* file "LICENCE" distributed with Cforall.
6	*
7	* lex.ll --
8	*
9	* Author : Peter A. Buhr
10	* Created On : Sat Sep 22 08:58:10 2001
11	* Last Modified By : Peter A. Buhr
12	* Last Modified On : Thu Jun 7 08:27:40 2018
13	* Update Count : 679
14	*/
15
16	%option yylineno
17	%option noyywrap
18	%option nounput
19
20	%{
21	// The lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
22	// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
23	// line-number directives) and C/C++ style comments, which are ignored.
24
25	//************************** Includes and Defines **************************
26
27	unsigned int column = 0; // position of the end of the last token parsed
28	#define YY_USER_ACTION yylloc.first_line = yylineno; yylloc.first_column = column; column += yyleng; yylloc.last_column = column; yylloc.last_line = yylineno; yylloc.filename = yyfilename ? yyfilename : ""; // trigger before each matching rule's action
29
30	#include <string>
31	#include <cstdio> // FILENAME_MAX
32	using namespace std;
33
34	#include "ParseNode.h"
35	#include "TypedefTable.h"
36
37	char *yyfilename;
38	string *strtext; // accumulate parts of character and string constant value
39
40	#define RETURN_LOCN(x) yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
41	#define RETURN_VAL(x) yylval.tok.str = new string( yytext ); RETURN_LOCN( x )
42	#define RETURN_CHAR(x) yylval.tok.str = nullptr; RETURN_LOCN( x )
43	#define RETURN_STR(x) yylval.tok.str = strtext; RETURN_LOCN( x )
44
45	#define WHITE_RETURN(x) // do nothing
46	#define NEWLINE_RETURN() column = 0; WHITE_RETURN( '\n' )
47	#define ASCIIOP_RETURN() RETURN_CHAR( (int)yytext[0] ) // single character operator
48	#define NAMEDOP_RETURN(x) RETURN_CHAR( x ) // multichar operator, with a name
49	#define NUMERIC_RETURN(x) rm_underscore(); RETURN_VAL( x ) // numeric constant
50	#define KEYWORD_RETURN(x) RETURN_CHAR( x ) // keyword
51	#define QKEYWORD_RETURN(x) typedefTable.isKind( yytext ); RETURN_VAL(x); // quasi-keyword
52	#define IDENTIFIER_RETURN() RETURN_VAL( typedefTable.isKind( yytext ) )
53	#define ATTRIBUTE_RETURN() RETURN_VAL( ATTR_IDENTIFIER )
54
55	void rm_underscore() {
56	// SKULLDUGGERY: remove underscores (ok to shorten?)
57	yyleng = 0;
58	for ( int i = 0; yytext[i] != '\0'; i += 1 ) { // copying non-underscore characters to front of string
59	if ( yytext[i] != '_' ) {
60	yytext[yyleng] = yytext[i];
61	yyleng += 1;
62	} // if
63	} // for
64	yytext[yyleng] = '\0';
65	} // rm_underscore
66
67	// Stop warning due to incorrectly generated flex code.
68	#pragma GCC diagnostic ignored "-Wsign-compare"
69	%}
70
71	binary [0-1]
72	octal [0-7]
73	nonzero [1-9]
74	decimal [0-9]
75	hex [0-9a-fA-F]
76	universal_char "\\"((u"_"?{hex_quad})\|(U"_"?{hex_quad}{2}))
77
78	// identifier, GCC: $ in identifier
79	identifier ([a-zA-Z_$]\|{universal_char})([0-9a-zA-Z_$]\|{universal_char})*
80
81	// attribute identifier, GCC: $ in identifier
82	attr_identifier "@"{identifier}
83
84	// numeric constants, CFA: '_' in constant
85	hex_quad {hex}("_"?{hex}){3}
86	size_opt (8\|16\|32\|64\|128)?
87	length ("ll"\|"LL"\|[lL]{size_opt})\|("hh"\|"HH"\|[hH])
88	integer_suffix_opt ("_"?(([uU]({length}?[iI]?)\|([iI]{length}))\|([iI]({length}?[uU]?)\|([uU]{length}))\|({length}([iI]?[uU]?)\|([uU][iI]))\|[zZ]))?
89
90	octal_digits ({octal})\|({octal}({octal}\|"_")*{octal})
91	octal_prefix "0""_"?
92	octal_constant (("0")\|({octal_prefix}{octal_digits})){integer_suffix_opt}
93
94	nonzero_digits ({nonzero})\|({nonzero}({decimal}\|"_")*{decimal})
95	decimal_constant {nonzero_digits}{integer_suffix_opt}
96
97	binary_digits ({binary})\|({binary}({binary}\|"_")*{binary})
98	binary_prefix "0"[bB]"_"?
99	binary_constant {binary_prefix}{binary_digits}{integer_suffix_opt}
100
101	hex_digits ({hex})\|({hex}({hex}\|"_")*{hex})
102	hex_prefix "0"[xX]"_"?
103	hex_constant {hex_prefix}{hex_digits}{integer_suffix_opt}
104
105	// GCC: D (double) and iI (imaginary) suffixes, and DL (long double)
106	exponent "_"?[eE]"_"?[+-]?{decimal_digits}
107	floating_size 32\|64\|80\|128
108	floating_length ([fFdDlL]\|[lL]{floating_size})
109	floating_suffix ({floating_length}?[iI]?)\|([iI]{floating_length})
110	floating_suffix_opt ("_"?({floating_suffix}\|"DL"))?
111	decimal_digits ({decimal})\|({decimal}({decimal}\|"_")*{decimal})
112	floating_decimal {decimal_digits}"."{exponent}?{floating_suffix_opt}
113	floating_fraction "."{decimal_digits}{exponent}?{floating_suffix_opt}
114	floating_constant ({decimal_digits}{exponent}{floating_suffix_opt})\|({decimal_digits}{floating_fraction})
115
116	binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
117	hex_floating_suffix_opt ("_"?({floating_suffix}))?
118	hex_floating_fraction ({hex_digits}?"."{hex_digits})\|({hex_digits}".")
119	hex_floating_constant {hex_prefix}(({hex_floating_fraction}{binary_exponent})\|({hex_digits}{binary_exponent})){hex_floating_suffix_opt}
120
121	// character escape sequence, GCC: \e => esc character
122	simple_escape "\\"[abefnrtv'"?\\]
123	// ' stop editor highlighting
124	octal_escape "\\"{octal}("_"?{octal}){0,2}
125	hex_escape "\\""x""_"?{hex_digits}
126	escape_seq {simple_escape}\|{octal_escape}\|{hex_escape}\|{universal_char}
127	cwide_prefix "L"\|"U"\|"u"
128	swide_prefix {cwide_prefix}\|"u8"
129
130	// display/white-space characters
131	h_tab [\011]
132	form_feed [\014]
133	v_tab [\013]
134	c_return [\015]
135	h_white [ ]\|{h_tab}
136
137	// overloadable operators
138	op_unary_only "~"\|"!"
139	op_unary_binary "+"\|"-"\|"*"
140	op_unary_pre_post "++"\|"--"
141	op_unary {op_unary_only}\|{op_unary_binary}\|{op_unary_pre_post}
142
143	op_binary_only "/"\|"%"\|"\\"\|"^"\|"&"\|"\|"\|"<"\|">"\|"="\|"=="\|"!="\|"<<"\|">>"\|"<="\|">="\|"+="\|"-="\|"*="\|"/="\|"%="\|"\\="\|"&="\|"\|="\|"^="\|"<<="\|">>="
144	op_binary_over {op_unary_binary}\|{op_binary_only}
145	// op_binary_not_over "?"\|"->"\|"."\|"&&"\|"\|\|"\|"@="
146	// operator {op_unary_pre_post}\|{op_binary_over}\|{op_binary_not_over}
147
148	%x COMMENT
149	%x BKQUOTE
150	%x QUOTE
151	%x STRING
152
153	%%
154	/* line directives */
155	^{h_white}"#"{h_white}[0-9]+{h_white}["][^"\n]+["]."\n" {
156	/* " stop editor highlighting */
157	static char filename[FILENAME_MAX]; // temporarily store current source-file name
158	char *end_num;
159	char begin_string, end_string;
160	long lineno, length;
161	lineno = strtol( yytext + 1, &end_num, 0 );
162	begin_string = strchr( end_num, '"' );
163	if ( begin_string ) { // file name ?
164	end_string = strchr( begin_string + 1, '"' ); // look for ending delimiter
165	assert( end_string ); // closing quote ?
166	length = end_string - begin_string - 1; // file-name length without quotes or sentinel
167	assert( length < FILENAME_MAX ); // room for sentinel ?
168	memcpy( &filename, begin_string + 1, length ); // copy file name from yytext
169	filename[ length ] = '\0'; // terminate string with sentinel
170	//cout << "file " << filename << " line " << lineno << endl;
171	yylineno = lineno;
172	yyfilename = filename;
173	} // if
174	}
175
176	/* preprocessor-style directives */
177	^{h_white}"#"[^\n]"\n" { RETURN_VAL( DIRECTIVE ); }
178
179	/* ignore C style comments (ALSO HANDLED BY CPP) */
180	"/*" { BEGIN COMMENT; }
181	<COMMENT>.\|\n ;
182	<COMMENT>"*/" { BEGIN 0; }
183
184	/* ignore C++ style comments (ALSO HANDLED BY CPP) */
185	"//"[^\n]*"\n" ;
186
187	/* ignore whitespace */
188	{h_white}+ { WHITE_RETURN(' '); }
189	({v_tab}\|{c_return}\|{form_feed})+ { WHITE_RETURN(' '); }
190	({h_white}\|{v_tab}\|{c_return}\|{form_feed})*"\n" { NEWLINE_RETURN(); }
191
192	/* keywords */
193	_Alignas { KEYWORD_RETURN(ALIGNAS); } // C11
194	_Alignof { KEYWORD_RETURN(ALIGNOF); } // C11
195	__alignof { KEYWORD_RETURN(ALIGNOF); } // GCC
196	__alignof__ { KEYWORD_RETURN(ALIGNOF); } // GCC
197	asm { KEYWORD_RETURN(ASM); }
198	__asm { KEYWORD_RETURN(ASM); } // GCC
199	__asm__ { KEYWORD_RETURN(ASM); } // GCC
200	_Atomic { KEYWORD_RETURN(ATOMIC); } // C11
201	__attribute { KEYWORD_RETURN(ATTRIBUTE); } // GCC
202	__attribute__ { KEYWORD_RETURN(ATTRIBUTE); } // GCC
203	auto { KEYWORD_RETURN(AUTO); }
204	_Bool { KEYWORD_RETURN(BOOL); } // C99
205	break { KEYWORD_RETURN(BREAK); }
206	case { KEYWORD_RETURN(CASE); }
207	catch { KEYWORD_RETURN(CATCH); } // CFA
208	catchResume { KEYWORD_RETURN(CATCHRESUME); } // CFA
209	char { KEYWORD_RETURN(CHAR); }
210	choose { KEYWORD_RETURN(CHOOSE); } // CFA
211	_Complex { KEYWORD_RETURN(COMPLEX); } // C99
212	__complex { KEYWORD_RETURN(COMPLEX); } // GCC
213	__complex__ { KEYWORD_RETURN(COMPLEX); } // GCC
214	const { KEYWORD_RETURN(CONST); }
215	__const { KEYWORD_RETURN(CONST); } // GCC
216	__const__ { KEYWORD_RETURN(CONST); } // GCC
217	continue { KEYWORD_RETURN(CONTINUE); }
218	coroutine { KEYWORD_RETURN(COROUTINE); } // CFA
219	default { KEYWORD_RETURN(DEFAULT); }
220	disable { KEYWORD_RETURN(DISABLE); } // CFA
221	do { KEYWORD_RETURN(DO); }
222	double { KEYWORD_RETURN(DOUBLE); }
223	dtype { KEYWORD_RETURN(DTYPE); } // CFA
224	else { KEYWORD_RETURN(ELSE); }
225	enable { KEYWORD_RETURN(ENABLE); } // CFA
226	enum { KEYWORD_RETURN(ENUM); }
227	__extension__ { KEYWORD_RETURN(EXTENSION); } // GCC
228	exception { KEYWORD_RETURN(EXCEPTION); } // CFA
229	extern { KEYWORD_RETURN(EXTERN); }
230	fallthrough { KEYWORD_RETURN(FALLTHROUGH); } // CFA
231	fallthru { KEYWORD_RETURN(FALLTHRU); } // CFA
232	finally { KEYWORD_RETURN(FINALLY); } // CFA
233	float { KEYWORD_RETURN(FLOAT); }
234	_Float32 { KEYWORD_RETURN(FLOAT); } // GCC
235	_Float32x { KEYWORD_RETURN(FLOAT); } // GCC
236	_Float64 { KEYWORD_RETURN(DOUBLE); } // GCC
237	_Float64x { KEYWORD_RETURN(DOUBLE); } // GCC
238	__float80 { KEYWORD_RETURN(FLOAT80); } // GCC
239	float80 { KEYWORD_RETURN(FLOAT80); } // GCC
240	_Float128 { KEYWORD_RETURN(FLOAT128); } // GCC
241	_Float128x { KEYWORD_RETURN(FLOAT128); } // GCC
242	__float128 { KEYWORD_RETURN(FLOAT128); } // GCC
243	float128 { KEYWORD_RETURN(FLOAT128); } // GCC
244	for { KEYWORD_RETURN(FOR); }
245	forall { KEYWORD_RETURN(FORALL); } // CFA
246	fortran { KEYWORD_RETURN(FORTRAN); }
247	ftype { KEYWORD_RETURN(FTYPE); } // CFA
248	_Generic { KEYWORD_RETURN(GENERIC); } // C11
249	goto { KEYWORD_RETURN(GOTO); }
250	if { KEYWORD_RETURN(IF); }
251	_Imaginary { KEYWORD_RETURN(IMAGINARY); } // C99
252	__imag { KEYWORD_RETURN(IMAGINARY); } // GCC
253	__imag__ { KEYWORD_RETURN(IMAGINARY); } // GCC
254	inline { KEYWORD_RETURN(INLINE); } // C99
255	__inline { KEYWORD_RETURN(INLINE); } // GCC
256	__inline__ { KEYWORD_RETURN(INLINE); } // GCC
257	int { KEYWORD_RETURN(INT); }
258	__int128 { KEYWORD_RETURN(INT128); } // GCC
259	int128 { KEYWORD_RETURN(INT128); } // GCC
260	__label__ { KEYWORD_RETURN(LABEL); } // GCC
261	long { KEYWORD_RETURN(LONG); }
262	monitor { KEYWORD_RETURN(MONITOR); } // CFA
263	mutex { KEYWORD_RETURN(MUTEX); } // CFA
264	_Noreturn { KEYWORD_RETURN(NORETURN); } // C11
265	__builtin_offsetof { KEYWORD_RETURN(OFFSETOF); } // GCC
266	one_t { NUMERIC_RETURN(ONE_T); } // CFA
267	or { QKEYWORD_RETURN(WOR); } // CFA
268	otype { KEYWORD_RETURN(OTYPE); } // CFA
269	register { KEYWORD_RETURN(REGISTER); }
270	restrict { KEYWORD_RETURN(RESTRICT); } // C99
271	__restrict { KEYWORD_RETURN(RESTRICT); } // GCC
272	__restrict__ { KEYWORD_RETURN(RESTRICT); } // GCC
273	return { KEYWORD_RETURN(RETURN); }
274	short { KEYWORD_RETURN(SHORT); }
275	signed { KEYWORD_RETURN(SIGNED); }
276	__signed { KEYWORD_RETURN(SIGNED); } // GCC
277	__signed__ { KEYWORD_RETURN(SIGNED); } // GCC
278	sizeof { KEYWORD_RETURN(SIZEOF); }
279	static { KEYWORD_RETURN(STATIC); }
280	_Static_assert { KEYWORD_RETURN(STATICASSERT); } // C11
281	struct { KEYWORD_RETURN(STRUCT); }
282	switch { KEYWORD_RETURN(SWITCH); }
283	thread { KEYWORD_RETURN(THREAD); } // C11
284	_Thread_local { KEYWORD_RETURN(THREADLOCAL); } // C11
285	throw { KEYWORD_RETURN(THROW); } // CFA
286	throwResume { KEYWORD_RETURN(THROWRESUME); } // CFA
287	timeout { QKEYWORD_RETURN(TIMEOUT); } // CFA
288	trait { KEYWORD_RETURN(TRAIT); } // CFA
289	try { KEYWORD_RETURN(TRY); } // CFA
290	ttype { KEYWORD_RETURN(TTYPE); } // CFA
291	typedef { KEYWORD_RETURN(TYPEDEF); }
292	typeof { KEYWORD_RETURN(TYPEOF); } // GCC
293	__typeof { KEYWORD_RETURN(TYPEOF); } // GCC
294	__typeof__ { KEYWORD_RETURN(TYPEOF); } // GCC
295	union { KEYWORD_RETURN(UNION); }
296	unsigned { KEYWORD_RETURN(UNSIGNED); }
297	__builtin_va_list { KEYWORD_RETURN(VALIST); } // GCC
298	virtual { KEYWORD_RETURN(VIRTUAL); } // CFA
299	void { KEYWORD_RETURN(VOID); }
300	volatile { KEYWORD_RETURN(VOLATILE); }
301	__volatile { KEYWORD_RETURN(VOLATILE); } // GCC
302	__volatile__ { KEYWORD_RETURN(VOLATILE); } // GCC
303	waitfor { KEYWORD_RETURN(WAITFOR); }
304	when { KEYWORD_RETURN(WHEN); }
305	while { KEYWORD_RETURN(WHILE); }
306	with { KEYWORD_RETURN(WITH); } // CFA
307	zero_t { NUMERIC_RETURN(ZERO_T); } // CFA
308
309	/* identifier */
310	{identifier} { IDENTIFIER_RETURN(); }
311	"`"{identifier}"`" { // CFA
312	yytext[yyleng - 1] = '\0'; yytext += 1; // SKULLDUGGERY: remove backquotes (ok to shorten?)
313	IDENTIFIER_RETURN();
314	}
315	{attr_identifier} { ATTRIBUTE_RETURN(); }
316
317	/* numeric constants */
318	{binary_constant} { NUMERIC_RETURN(INTEGERconstant); }
319	{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
320	{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
321	{hex_constant} { NUMERIC_RETURN(INTEGERconstant); }
322	{floating_decimal} { NUMERIC_RETURN(FLOATING_DECIMALconstant); } // must appear before floating_constant
323	{floating_fraction} { NUMERIC_RETURN(FLOATING_FRACTIONconstant); } // must appear before floating_constant
324	{floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
325	{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
326
327	/* character constant, allows empty value */
328	({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new string( yytext, yyleng ); }
329	<QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); }
330	<QUOTE>['\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); }
331	/* ' stop editor highlighting */
332
333	/* string constant */
334	({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new string( yytext, yyleng ); }
335	<STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); }
336	<STRING>["\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); }
337	/* " stop editor highlighting */
338
339	/* common character/string constant */
340	<QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); }
341	<QUOTE,STRING>"\\"{h_white}*"\n" {} // continuation (ALSO HANDLED BY CPP)
342	<QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character
343
344	/* punctuation */
345	"@" { ASCIIOP_RETURN(); }
346	"`" { ASCIIOP_RETURN(); }
347	"[" { ASCIIOP_RETURN(); }
348	"]" { ASCIIOP_RETURN(); }
349	"(" { ASCIIOP_RETURN(); }
350	")" { ASCIIOP_RETURN(); }
351	"{" { ASCIIOP_RETURN(); }
352	"}" { ASCIIOP_RETURN(); }
353	"," { ASCIIOP_RETURN(); } // also operator
354	":" { ASCIIOP_RETURN(); }
355	";" { ASCIIOP_RETURN(); }
356	"." { ASCIIOP_RETURN(); } // also operator
357	"..." { NAMEDOP_RETURN(ELLIPSIS); }
358
359	/* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
360	"<:" { RETURN_VAL('['); }
361	":>" { RETURN_VAL(']'); }
362	"<%" { RETURN_VAL('{'); }
363	"%>" { RETURN_VAL('}'); }
364
365	/* operators */
366	"!" { ASCIIOP_RETURN(); }
367	"+" { ASCIIOP_RETURN(); }
368	"-" { ASCIIOP_RETURN(); }
369	"*" { ASCIIOP_RETURN(); }
370	"\\" { ASCIIOP_RETURN(); } // CFA, exponentiation
371	"/" { ASCIIOP_RETURN(); }
372	"%" { ASCIIOP_RETURN(); }
373	"^" { ASCIIOP_RETURN(); }
374	"~" { ASCIIOP_RETURN(); }
375	"&" { ASCIIOP_RETURN(); }
376	"\|" { ASCIIOP_RETURN(); }
377	"<" { ASCIIOP_RETURN(); }
378	">" { ASCIIOP_RETURN(); }
379	"=" { ASCIIOP_RETURN(); }
380	"?" { ASCIIOP_RETURN(); }
381
382	"++" { NAMEDOP_RETURN(ICR); }
383	"--" { NAMEDOP_RETURN(DECR); }
384	"==" { NAMEDOP_RETURN(EQ); }
385	"!=" { NAMEDOP_RETURN(NE); }
386	"<<" { NAMEDOP_RETURN(LS); }
387	">>" { NAMEDOP_RETURN(RS); }
388	"<=" { NAMEDOP_RETURN(LE); }
389	">=" { NAMEDOP_RETURN(GE); }
390	"&&" { NAMEDOP_RETURN(ANDAND); }
391	"\|\|" { NAMEDOP_RETURN(OROR); }
392	"->" { NAMEDOP_RETURN(ARROW); }
393	"+=" { NAMEDOP_RETURN(PLUSassign); }
394	"-=" { NAMEDOP_RETURN(MINUSassign); }
395	"\\=" { NAMEDOP_RETURN(EXPassign); } // CFA, exponentiation
396	"*=" { NAMEDOP_RETURN(MULTassign); }
397	"/=" { NAMEDOP_RETURN(DIVassign); }
398	"%=" { NAMEDOP_RETURN(MODassign); }
399	"&=" { NAMEDOP_RETURN(ANDassign); }
400	"\|=" { NAMEDOP_RETURN(ORassign); }
401	"^=" { NAMEDOP_RETURN(ERassign); }
402	"<<=" { NAMEDOP_RETURN(LSassign); }
403	">>=" { NAMEDOP_RETURN(RSassign); }
404
405	"@=" { NAMEDOP_RETURN(ATassign); } // CFA
406
407	/* CFA, operator identifier */
408	{op_unary}"?" { IDENTIFIER_RETURN(); } // unary
409	"?"({op_unary_pre_post}\|"()"\|"[?]"\|"{}") { IDENTIFIER_RETURN(); }
410	"^?{}" { IDENTIFIER_RETURN(); }
411	"?`"{identifier} { IDENTIFIER_RETURN(); } // postfix operator
412	"?"{op_binary_over}"?" { IDENTIFIER_RETURN(); } // binary
413	/*
414	This rule handles ambiguous cases with operator identifiers, e.g., "int ??()", where the string "??" can be
415	lexed as "?"/"?" or ""/"??". Since it is common practise to put a unary operator juxtaposed to an identifier,
416	e.g., "*i", users will be annoyed if they cannot do this with respect to operator identifiers. Therefore, there is
417	a lexical look-ahead for the second case, with backtracking to return the leading unary operator and then
418	reparsing the trailing operator identifier. Otherwise a space is needed between the unary operator and operator
419	identifier to disambiguate this common case.
420
421	A similar issue occurs with the dereference, *?(...), and routine-call, ?()(...) identifiers. The ambiguity
422	occurs when the deference operator has no parameters, ?() and ?()(...), requiring arbitrary whitespace
423	look-ahead for the routine-call parameter-list to disambiguate. However, the dereference operator must have a
424	parameter/argument to dereference ?(...). Hence, always interpreting the string ?() as * ?() does not preclude
425	any meaningful program.
426
427	The remaining cases are with the increment/decrement operators and conditional expression:
428
429	i++? ...(...);
430	i?++ ...(...);
431
432	requiring arbitrary whitespace look-ahead for the operator parameter-list, even though that interpretation is an
433	incorrect expression (juxtaposed identifiers). Therefore, it is necessary to disambiguate these cases with a
434	space:
435
436	i++ ? i : 0;
437	i? ++i : 0;
438	*/
439	{op_unary}"?"({op_unary_pre_post}\|"()"\|"[?]"\|{op_binary_over}"?") {
440	// 1 or 2 character unary operator ?
441	int i = yytext[1] == '?' ? 1 : 2;
442	yyless( i ); // put back characters up to first '?'
443	if ( i > 1 ) {
444	NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
445	} else {
446	ASCIIOP_RETURN();
447	} // if
448	}
449
450	/* unknown character */
451	. { yyerror( "unknown character" ); }
452
453	%%
454
455	// ----end of lexer----
456
457	void yyerror( const char * errmsg ) {
458	SemanticErrorThrow = true;
459	cout << (yyfilename ? yyfilename : "unknown file") << ':' << yylineno << ':' << column - yyleng + 1
460	<< ": " << ErrorHelpers::error_str() << errmsg << " at token \"" << (yytext[0] == '\0' ? "EOF" : yytext) << '"' << endl;
461	}
462
463	// Local Variables: //
464	// mode: c++ //
465	// tab-width: 4 //
466	// compile-command: "make install" //
467	// End: //

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format