source: src/Parser/lex.ll @ f3fc8cbe

ADTaaron-thesisarm-ehast-experimentalcleanup-dtorsctordeferred_resndemanglerenumforall-pointer-decaygc_noraiijacob/cs343-translationjenkins-sandboxmemorynew-astnew-ast-unique-exprnew-envno_listpersistent-indexerpthread-emulationqualifiedEnumresolv-newstringwith_gc
Last change on this file since f3fc8cbe was f3fc8cbe, checked in by Peter A. Buhr <pabuhr@…>, 8 years ago

dli suffixes second try
  • Property mode set to 100644
File size: 15.1 KB
Line 
1/*
2 * Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3 *
4 * The contents of this file are covered under the licence agreement in the
5 * file "LICENCE" distributed with Cforall.
6 *
7 * lex.l --
8 *
9 * Author           : Peter A. Buhr
10 * Created On       : Sat Sep 22 08:58:10 2001
11 * Last Modified By : Peter A. Buhr
12 * Last Modified On : Thu Jan 21 21:53:38 2016
13 * Update Count     : 417
14 */
15
16%option yylineno
17%option nounput
18
19%{
20// This lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
21// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
22// line-number directives) and C/C++ style comments, which are ignored.
23
24//**************************** Includes and Defines ****************************
25
26#include <string>
27
28#include "lex.h"
29#include "ParseNode.h"
30#include "parser.h"                                                                             // YACC generated definitions based on C++ grammar
31
32char *yyfilename;
33std::string *strtext;                                                                   // accumulate parts of character and string constant value
34
35#define RETURN_LOCN(x)          yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
36#define RETURN_VAL(x)           yylval.tok.str = new std::string( yytext ); RETURN_LOCN( x )
37#define RETURN_CHAR(x)          yylval.tok.str = NULL; RETURN_LOCN( x )
38#define RETURN_STR(x)           yylval.tok.str = strtext; RETURN_LOCN( x )
39
40#define WHITE_RETURN(x)                                                                 // do nothing
41#define NEWLINE_RETURN()        WHITE_RETURN( '\n' )
42#define ASCIIOP_RETURN()        RETURN_CHAR( (int)yytext[0] ) // single character operator
43#define NAMEDOP_RETURN(x)       RETURN_VAL( x )                         // multichar operator, with a name
44#define NUMERIC_RETURN(x)       rm_underscore(); RETURN_VAL( x ) // numeric constant
45#define KEYWORD_RETURN(x)       RETURN_CHAR( x )                        // keyword
46#define IDENTIFIER_RETURN()     RETURN_VAL( (typedefTable.isIdentifier( yytext ) ? IDENTIFIER : typedefTable.isTypedef( yytext ) ? TYPEDEFname : TYPEGENname ) )
47#define ATTRIBUTE_RETURN()      RETURN_VAL( ATTR_IDENTIFIER )
48
49void rm_underscore() {
50        // remove underscores in numeric constant
51        int j = 0;
52        for ( int i = 0; yytext[i] != '\0'; i += 1 ) {
53                if ( yytext[i] != '_' ) {
54                        yytext[j] = yytext[i];
55                        j += 1;
56                } // if
57        } // for
58        yyleng = j;
59        yytext[yyleng] = '\0';
60}
61
62%}
63
64octal [0-7]
65nonzero [1-9]
66decimal [0-9]
67hex [0-9a-fA-F]
68universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2}))
69
70                                // identifier, GCC: $ in identifier
71identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})*
72
73                                // quoted identifier
74quoted_identifier "`"{identifier}"`"
75
76                                // attribute identifier, GCC: $ in identifier
77attr_identifier "@"{identifier}
78
79                                // numeric constants, CFA: '_' in constant
80hex_quad {hex}("_"?{hex}){3}
81integer_suffix "_"?(([uU][lL]?)|([uU]("ll"|"LL")?)|([lL][uU]?)|("ll"|"LL")[uU]?)
82
83octal_digits ({octal})|({octal}({octal}|"_")*{octal})
84octal_prefix "0""_"?
85octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix}?
86
87nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal})
88decimal_constant {nonzero_digits}{integer_suffix}?
89
90hex_digits ({hex})|({hex}({hex}|"_")*{hex})
91hex_prefix "0"[xX]"_"?
92hex_constant {hex_prefix}{hex_digits}{integer_suffix}?
93
94decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal})
95fractional_constant ({decimal_digits}?"."{decimal_digits})|({decimal_digits}".")
96exponent "_"?[eE]"_"?[+-]?{decimal_digits}
97                                // GCC: D (double), LD (long double) and iI (imaginary) suffixes
98floating_suffix "_"?(([fFdD][lL]?)|([lL][fFdD]?)|([iI][lLfFdD]?))
99floating_constant (({fractional_constant}{exponent}?)|({decimal_digits}{exponent})){floating_suffix}?
100
101binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
102hex_fractional_constant ({hex_digits}?"."{hex_digits})|({hex_digits}".")
103hex_floating_constant {hex_prefix}(({hex_fractional_constant}{binary_exponent})|({hex_digits}{binary_exponent})){floating_suffix}?
104
105                                // character escape sequence, GCC: \e => esc character
106simple_escape "\\"[abefnrtv'"?\\]
107                                // ' stop highlighting
108octal_escape "\\"{octal}("_"?{octal}){0,2}
109hex_escape "\\""x""_"?{hex_digits}
110escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char}
111cwide_prefix "L"|"U"|"u"
112swide_prefix {cwide_prefix}|"u8"
113
114                                // display/white-space characters
115h_tab [\011]
116form_feed [\014]
117v_tab [\013]
118c_return [\015]
119h_white [ ]|{h_tab}
120
121                                // operators
122op_unary_only "~"|"!"
123op_unary_binary "+"|"-"|"*"
124op_unary_pre_post "++"|"--"
125op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post}
126
127op_binary_only "/"|"%"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"&="|"|="|"^="|"<<="|">>="
128op_binary_over {op_unary_binary}|{op_binary_only}
129op_binary_not_over "?"|"->"|"&&"|"||"
130operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over}
131
132%x COMMENT
133%x BKQUOTE
134%x QUOTE
135%x STRING
136
137%%
138                                   /* line directives */
139^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["][^\n]*"\n" {
140        /* " stop highlighting */
141        char *end_num;
142        char *begin_string, *end_string;
143        char *filename;
144        long lineno, length;
145        lineno = strtol( yytext + 1, &end_num, 0 );
146        begin_string = strchr( end_num, '"' );
147        if ( begin_string ) {
148                end_string = strchr( begin_string + 1, '"' );
149                if ( end_string ) {
150                        length = end_string - begin_string - 1;
151                        filename = new char[ length + 1 ];
152                        memcpy( filename, begin_string + 1, length );
153                        filename[ length ] = '\0';
154                        //std::cout << "file " << filename << " line " << lineno << std::endl;
155                        yylineno = lineno;
156                        yyfilename = filename;
157                } // if
158        } // if
159}
160
161                                /* ignore preprocessor directives (for now) */
162^{h_white}*"#"[^\n]*"\n" ;
163
164                                /* ignore C style comments (ALSO HANDLED BY CPP) */
165"/*"                    { BEGIN COMMENT; }
166<COMMENT>.|\n   ;
167<COMMENT>"*/"   { BEGIN 0; }
168
169                                /* ignore C++ style comments (ALSO HANDLED BY CPP) */
170"//"[^\n]*"\n"  ;
171
172                                /* ignore whitespace */
173{h_white}+              { WHITE_RETURN(' '); }
174({v_tab}|{c_return}|{form_feed})+ { WHITE_RETURN(' '); }
175({h_white}|{v_tab}|{c_return}|{form_feed})*"\n" { NEWLINE_RETURN(); }
176
177                                /* keywords */
178_Alignas                { KEYWORD_RETURN(ALIGNAS); }                    // C11
179_Alignof                { KEYWORD_RETURN(ALIGNOF); }                    // C11
180__alignof               { KEYWORD_RETURN(ALIGNOF); }                    // GCC
181__alignof__             { KEYWORD_RETURN(ALIGNOF); }                    // GCC
182asm                             { KEYWORD_RETURN(ASM); }
183__asm                   { KEYWORD_RETURN(ASM); }                                // GCC
184__asm__                 { KEYWORD_RETURN(ASM); }                                // GCC
185_At                             { KEYWORD_RETURN(AT); }                                 // CFA
186_Atomic                 { KEYWORD_RETURN(ATOMIC); }                             // C11
187__attribute             { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
188__attribute__   { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
189auto                    { KEYWORD_RETURN(AUTO); }
190_Bool                   { KEYWORD_RETURN(BOOL); }                               // C99
191break                   { KEYWORD_RETURN(BREAK); }
192case                    { KEYWORD_RETURN(CASE); }
193catch                   { KEYWORD_RETURN(CATCH); }                              // CFA
194catchResume             { KEYWORD_RETURN(CATCHRESUME); }                // CFA
195char                    { KEYWORD_RETURN(CHAR); }
196choose                  { KEYWORD_RETURN(CHOOSE); }                             // CFA
197_Complex                { KEYWORD_RETURN(COMPLEX); }                    // C99
198__complex               { KEYWORD_RETURN(COMPLEX); }                    // GCC
199__complex__             { KEYWORD_RETURN(COMPLEX); }                    // GCC
200const                   { KEYWORD_RETURN(CONST); }
201__const                 { KEYWORD_RETURN(CONST); }                              // GCC
202__const__               { KEYWORD_RETURN(CONST); }                              // GCC
203context                 { KEYWORD_RETURN(CONTEXT); }                    // CFA
204continue                { KEYWORD_RETURN(CONTINUE); }
205default                 { KEYWORD_RETURN(DEFAULT); }
206disable                 { KEYWORD_RETURN(DISABLE); }                    // CFA
207do                              { KEYWORD_RETURN(DO); }
208double                  { KEYWORD_RETURN(DOUBLE); }
209dtype                   { KEYWORD_RETURN(DTYPE); }                              // CFA
210else                    { KEYWORD_RETURN(ELSE); }
211enable                  { KEYWORD_RETURN(ENABLE); }                             // CFA
212enum                    { KEYWORD_RETURN(ENUM); }
213__extension__   { KEYWORD_RETURN(EXTENSION); }                  // GCC
214extern                  { KEYWORD_RETURN(EXTERN); }
215fallthru                { KEYWORD_RETURN(FALLTHRU); }                   // CFA
216finally                 { KEYWORD_RETURN(FINALLY); }                    // CFA
217float                   { KEYWORD_RETURN(FLOAT); }
218__float128              { KEYWORD_RETURN(FLOAT); }                              // GCC
219for                             { KEYWORD_RETURN(FOR); }
220forall                  { KEYWORD_RETURN(FORALL); }                             // CFA
221fortran                 { KEYWORD_RETURN(FORTRAN); }
222ftype                   { KEYWORD_RETURN(FTYPE); }                              // CFA
223_Generic                { KEYWORD_RETURN(GENERIC); }                    // C11
224goto                    { KEYWORD_RETURN(GOTO); }
225if                              { KEYWORD_RETURN(IF); }
226_Imaginary              { KEYWORD_RETURN(IMAGINARY); }                  // C99
227__imag                  { KEYWORD_RETURN(IMAGINARY); }                  // GCC
228__imag__                { KEYWORD_RETURN(IMAGINARY); }                  // GCC
229inline                  { KEYWORD_RETURN(INLINE); }                             // C99
230__inline                { KEYWORD_RETURN(INLINE); }                             // GCC
231__inline__              { KEYWORD_RETURN(INLINE); }                             // GCC
232int                             { KEYWORD_RETURN(INT); }
233__int128                { KEYWORD_RETURN(INT); }                                // GCC
234__label__               { KEYWORD_RETURN(LABEL); }                              // GCC
235long                    { KEYWORD_RETURN(LONG); }
236lvalue                  { KEYWORD_RETURN(LVALUE); }                             // CFA
237_Noreturn               { KEYWORD_RETURN(NORETURN); }                   // C11
238register                { KEYWORD_RETURN(REGISTER); }
239restrict                { KEYWORD_RETURN(RESTRICT); }                   // C99
240__restrict              { KEYWORD_RETURN(RESTRICT); }                   // GCC
241__restrict__    { KEYWORD_RETURN(RESTRICT); }                   // GCC
242return                  { KEYWORD_RETURN(RETURN); }
243short                   { KEYWORD_RETURN(SHORT); }
244signed                  { KEYWORD_RETURN(SIGNED); }
245__signed                { KEYWORD_RETURN(SIGNED); }                             // GCC
246__signed__              { KEYWORD_RETURN(SIGNED); }                             // GCC
247sizeof                  { KEYWORD_RETURN(SIZEOF); }
248static                  { KEYWORD_RETURN(STATIC); }
249_Static_assert  { KEYWORD_RETURN(STATICASSERT); }               // C11
250struct                  { KEYWORD_RETURN(STRUCT); }
251switch                  { KEYWORD_RETURN(SWITCH); }
252_Thread_local   { KEYWORD_RETURN(THREADLOCAL); }                // C11
253throw                   { KEYWORD_RETURN(THROW); }                              // CFA
254throwResume             { KEYWORD_RETURN(THROWRESUME); }                // CFA
255try                             { KEYWORD_RETURN(TRY); }                                // CFA
256type                    { KEYWORD_RETURN(TYPE); }                               // CFA
257typedef                 { KEYWORD_RETURN(TYPEDEF); }
258typeof                  { KEYWORD_RETURN(TYPEOF); }                             // GCC
259__typeof                { KEYWORD_RETURN(TYPEOF); }                             // GCC
260__typeof__              { KEYWORD_RETURN(TYPEOF); }                             // GCC
261union                   { KEYWORD_RETURN(UNION); }
262unsigned                { KEYWORD_RETURN(UNSIGNED); }
263void                    { KEYWORD_RETURN(VOID); }
264volatile                { KEYWORD_RETURN(VOLATILE); }
265__volatile              { KEYWORD_RETURN(VOLATILE); }                   // GCC
266__volatile__    { KEYWORD_RETURN(VOLATILE); }                   // GCC
267while                   { KEYWORD_RETURN(WHILE); }
268
269                                /* identifier */
270{identifier}    { IDENTIFIER_RETURN(); }
271{attr_identifier} { ATTRIBUTE_RETURN(); }
272"`"                     { BEGIN BKQUOTE; }
273<BKQUOTE>{identifier} { IDENTIFIER_RETURN(); }
274<BKQUOTE>"`"    { BEGIN 0; }
275
276                                /* numeric constants */
277"0"                             { NUMERIC_RETURN(ZERO); }                               // CFA
278"1"                             { NUMERIC_RETURN(ONE); }                                // CFA
279{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
280{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
281{hex_constant}  { NUMERIC_RETURN(INTEGERconstant); }
282{floating_constant}     { NUMERIC_RETURN(FLOATINGconstant); }
283{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
284
285                                /* character constant, allows empty value */
286({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new std::string; *strtext += std::string( yytext ); }
287<QUOTE>[^'\\\n]* { *strtext += std::string( yytext ); }
288<QUOTE>['\n]    { BEGIN 0; *strtext += std::string( yytext); RETURN_STR(CHARACTERconstant); }
289                                /* ' stop highlighting */
290
291                                /* string constant */
292({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new std::string; *strtext += std::string( yytext ); }
293<STRING>[^"\\\n]* { *strtext += std::string( yytext ); }
294<STRING>["\n]   { BEGIN 0; *strtext += std::string( yytext ); RETURN_STR(STRINGliteral); }
295                                /* " stop highlighting */
296
297                                /* common character/string constant */
298<QUOTE,STRING>{escape_seq} { rm_underscore(); *strtext += std::string( yytext ); }
299<QUOTE,STRING>"\\"{h_white}*"\n" {}                                             // continuation (ALSO HANDLED BY CPP)
300<QUOTE,STRING>"\\" { *strtext += std::string( yytext ); } // unknown escape character
301
302                                /* punctuation */
303"["                             { ASCIIOP_RETURN(); }
304"]"                             { ASCIIOP_RETURN(); }
305"("                             { ASCIIOP_RETURN(); }
306")"                             { ASCIIOP_RETURN(); }
307"{"                             { ASCIIOP_RETURN(); }
308"}"                             { ASCIIOP_RETURN(); }
309","                             { ASCIIOP_RETURN(); }                                   // also operator
310":"                             { ASCIIOP_RETURN(); }
311";"                             { ASCIIOP_RETURN(); }
312"."                             { ASCIIOP_RETURN(); }                                   // also operator
313"..."                   { NAMEDOP_RETURN(ELLIPSIS); }
314
315                                /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
316"<:"                    { RETURN_VAL('['); }
317":>"                    { RETURN_VAL(']'); }
318"<%"                    { RETURN_VAL('{'); }
319"%>"                    { RETURN_VAL('}'); }
320
321                                /* operators */
322"!"                             { ASCIIOP_RETURN(); }
323"+"                             { ASCIIOP_RETURN(); }
324"-"                             { ASCIIOP_RETURN(); }
325"*"                             { ASCIIOP_RETURN(); }
326"/"                             { ASCIIOP_RETURN(); }
327"%"                             { ASCIIOP_RETURN(); }
328"^"                             { ASCIIOP_RETURN(); }
329"~"                             { ASCIIOP_RETURN(); }
330"&"                             { ASCIIOP_RETURN(); }
331"|"                             { ASCIIOP_RETURN(); }
332"<"                             { ASCIIOP_RETURN(); }
333">"                             { ASCIIOP_RETURN(); }
334"="                             { ASCIIOP_RETURN(); }
335"?"                             { ASCIIOP_RETURN(); }
336
337"++"                    { NAMEDOP_RETURN(ICR); }
338"--"                    { NAMEDOP_RETURN(DECR); }
339"=="                    { NAMEDOP_RETURN(EQ); }
340"!="                    { NAMEDOP_RETURN(NE); }
341"<<"                    { NAMEDOP_RETURN(LS); }
342">>"                    { NAMEDOP_RETURN(RS); }
343"<="                    { NAMEDOP_RETURN(LE); }
344">="                    { NAMEDOP_RETURN(GE); }
345"&&"                    { NAMEDOP_RETURN(ANDAND); }
346"||"                    { NAMEDOP_RETURN(OROR); }
347"->"                    { NAMEDOP_RETURN(ARROW); }
348"+="                    { NAMEDOP_RETURN(PLUSassign); }
349"-="                    { NAMEDOP_RETURN(MINUSassign); }
350"*="                    { NAMEDOP_RETURN(MULTassign); }
351"/="                    { NAMEDOP_RETURN(DIVassign); }
352"%="                    { NAMEDOP_RETURN(MODassign); }
353"&="                    { NAMEDOP_RETURN(ANDassign); }
354"|="                    { NAMEDOP_RETURN(ORassign); }
355"^="                    { NAMEDOP_RETURN(ERassign); }
356"<<="                   { NAMEDOP_RETURN(LSassign); }
357">>="                   { NAMEDOP_RETURN(RSassign); }
358
359"@="                    { NAMEDOP_RETURN(ATassign); }
360
361                                /* CFA, operator identifier */
362{op_unary}"?"   { IDENTIFIER_RETURN(); }                                // unary
363"?"({op_unary_pre_post}|"()"|"[?]"|"{}") { IDENTIFIER_RETURN(); }
364"^?{}" { IDENTIFIER_RETURN(); }
365"?"{op_binary_over}"?"  { IDENTIFIER_RETURN(); }                // binary
366        /*
367          This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the string "*?*?"
368          can be lexed as "*"/"?*?" or "*?"/"*?". Since it is common practise to put a unary operator juxtaposed
369          to an identifier, e.g., "*i", users will be annoyed if they cannot do this with respect to operator
370          identifiers. Even with this special hack, there are 5 general cases that cannot be handled. The first
371          case is for the function-call identifier "?()":
372
373          int * ?()();  // declaration: space required after '*'
374          * ?()();      // expression: space required after '*'
375
376          Without the space, the string "*?()" is ambiguous without N character look ahead; it requires scanning
377          ahead to determine if there is a '(', which is the start of an argument/parameter list.
378
379          The 4 remaining cases occur in expressions:
380
381          i++?i:0;              // space required before '?'
382          i--?i:0;              // space required before '?'
383          i?++i:0;              // space required after '?'
384          i?--i:0;              // space required after '?'
385
386          In the first two cases, the string "i++?" is ambiguous, where this string can be lexed as "i"/"++?" or
387          "i++"/"?"; it requires scanning ahead to determine if there is a '(', which is the start of an argument
388          list.  In the second two cases, the string "?++x" is ambiguous, where this string can be lexed as
389          "?++"/"x" or "?"/"++x"; it requires scanning ahead to determine if there is a '(', which is the start of
390          an argument list.
391        */
392{op_unary}"?"({op_unary_pre_post}|"[?]"|{op_binary_over}"?") {
393        // 1 or 2 character unary operator ?
394        int i = yytext[1] == '?' ? 1 : 2;
395        yyless( i );            // put back characters up to first '?'
396        if ( i > 1 ) {
397                NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
398        } else {
399                ASCIIOP_RETURN();
400        } // if
401}
402
403                                /* unknown characters */
404.                       { printf("unknown character(s):\"%s\" on line %d\n", yytext, yylineno); }
405
406%%
407
408// Local Variables: //
409// mode: c++ //
410// tab-width: 4 //
411// compile-command: "make install" //
412// End: //
Note: See TracBrowser for help on using the repository browser.