Context Navigation

lex.ll@ b51e389c

Visit:

ADT ast-experimental enum forall-pointer-decay jacob/cs343-translation new-ast-unique-expr pthread-emulation qualifiedEnum

Last change on this file since b51e389c was 1f652a7, checked in by Peter A. Buhr <pabuhr@…>, 4 years ago
add keywords typeid and vtable, and parse new syntax for virtual tables
Property mode set to `100644`
File size: 19.7 KB

Line
1	/*
2	* Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3	*
4	* The contents of this file are covered under the licence agreement in the
5	* file "LICENCE" distributed with Cforall.
6	*
7	* lex.ll --
8	*
9	* Author : Peter A. Buhr
10	* Created On : Sat Sep 22 08:58:10 2001
11	* Last Modified By : Peter A. Buhr
12	* Last Modified On : Thu Apr 1 13:22:31 2021
13	* Update Count : 754
14	*/
15
16	%option yylineno
17	%option noyywrap
18	%option nounput
19
20	%{
21	// The lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
22	// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
23	// line-number directives) and C/C++ style comments, which are ignored.
24
25	//************************** Includes and Defines **************************
26
27	// trigger before each matching rule's action
28	#define YY_USER_ACTION \
29	yylloc.first_line = yylineno; \
30	yylloc.first_column = column; \
31	column += yyleng; \
32	yylloc.last_column = column; \
33	yylloc.last_line = yylineno; \
34	yylloc.filename = yyfilename ? yyfilename : "";
35	unsigned int column = 0; // position of the end of the last token parsed
36
37	#include <string>
38	#include <cstdio> // FILENAME_MAX
39	using namespace std;
40
41	#include "config.h" // configure info
42	#include "ParseNode.h"
43	#include "TypedefTable.h"
44
45	string * build_postfix_name( string * name );
46
47	char *yyfilename;
48	string *strtext; // accumulate parts of character and string constant value
49
50	#define RETURN_LOCN(x) yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
51	#define RETURN_VAL(x) yylval.tok.str = new string( yytext ); RETURN_LOCN( x )
52	#define RETURN_CHAR(x) yylval.tok.str = nullptr; RETURN_LOCN( x )
53	#define RETURN_STR(x) yylval.tok.str = strtext; RETURN_LOCN( x )
54
55	#define WHITE_RETURN(x) // do nothing
56	#define NEWLINE_RETURN() column = 0; WHITE_RETURN( '\n' )
57	#define ASCIIOP_RETURN() RETURN_CHAR( (int)yytext[0] ) // single character operator
58	#define NAMEDOP_RETURN(x) RETURN_CHAR( x ) // multichar operator, with a name
59	#define NUMERIC_RETURN(x) rm_underscore(); RETURN_VAL( x ) // numeric constant
60	#define KEYWORD_RETURN(x) RETURN_CHAR( x ) // keyword
61	#define QKEYWORD_RETURN(x) RETURN_VAL(x); // quasi-keyword
62	#define IDENTIFIER_RETURN() RETURN_VAL( typedefTable.isKind( yytext ) )
63
64	#ifdef HAVE_KEYWORDS_FLOATXX // GCC >= 7 => keyword, otherwise typedef
65	#define FLOATXX(v) KEYWORD_RETURN(v);
66	#else
67	#define FLOATXX(v) IDENTIFIER_RETURN();
68	#endif // HAVE_KEYWORDS_FLOATXX
69
70	void rm_underscore() {
71	// SKULLDUGGERY: remove underscores (ok to shorten?)
72	yyleng = 0;
73	for ( int i = 0; yytext[i] != '\0'; i += 1 ) { // copying non-underscore characters to front of string
74	if ( yytext[i] != '_' ) {
75	yytext[yyleng] = yytext[i];
76	yyleng += 1;
77	} // if
78	} // for
79	yytext[yyleng] = '\0';
80	} // rm_underscore
81
82	// Stop warning due to incorrectly generated flex code.
83	#pragma GCC diagnostic ignored "-Wsign-compare"
84	%}
85
86	binary [0-1]
87	octal [0-7]
88	nonzero [1-9]
89	decimal [0-9]
90	hex [0-9a-fA-F]
91	universal_char "\\"((u"_"?{hex_quad})\|(U"_"?{hex_quad}{2}))
92
93	// identifier, GCC: $ in identifier
94	identifier ([a-zA-Z_$]\|{universal_char})([0-9a-zA-Z_$]\|{universal_char})*
95
96	// numeric constants, CFA: '_' in constant
97	hex_quad {hex}("_"?{hex}){3}
98	size_opt (8\|16\|32\|64\|128)?
99	// CFA: explicit l8/l16/l32/l64/l128, char 'hh', short 'h', int 'n'
100	length ("ll"\|"LL"\|[lL]{size_opt})\|("hh"\|"HH"\|[hHnN])
101	// CFA: size_t 'z', pointer 'p', which define a sign and length
102	integer_suffix_opt ("_"?(([uU]({length}?[iI]?)\|([iI]{length}))\|([iI]({length}?[uU]?)\|([uU]{length}))\|({length}([iI]?[uU]?)\|([uU][iI]))\|[zZ]\|[pP]))?
103
104	octal_digits ({octal})\|({octal}({octal}\|"_")*{octal})
105	octal_prefix "0""_"?
106	octal_constant (("0")\|({octal_prefix}{octal_digits})){integer_suffix_opt}
107
108	nonzero_digits ({nonzero})\|({nonzero}({decimal}\|"_")*{decimal})
109	decimal_constant {nonzero_digits}{integer_suffix_opt}
110
111	binary_digits ({binary})\|({binary}({binary}\|"_")*{binary})
112	binary_prefix "0"[bB]"_"?
113	binary_constant {binary_prefix}{binary_digits}{integer_suffix_opt}
114
115	hex_digits ({hex})\|({hex}({hex}\|"_")*{hex})
116	hex_prefix "0"[xX]"_"?
117	hex_constant {hex_prefix}{hex_digits}{integer_suffix_opt}
118
119	// GCC: D (double) and iI (imaginary) suffixes, and DL (long double)
120	exponent "_"?[eE]"_"?[+-]?{decimal_digits}
121	floating_size 16\|32\|32x\|64\|64x\|80\|128\|128x
122	floating_length ([fFdDlLwWqQ]\|[fF]{floating_size})
123	floating_suffix ({floating_length}?[iI]?)\|([iI]{floating_length})
124	floating_suffix_opt ("_"?({floating_suffix}\|"DL"))?
125	decimal_digits ({decimal})\|({decimal}({decimal}\|"_")*{decimal})
126	floating_decimal {decimal_digits}"."{exponent}?{floating_suffix_opt}
127	floating_fraction "."{decimal_digits}{exponent}?{floating_suffix_opt}
128	floating_constant ({decimal_digits}{exponent}{floating_suffix_opt})\|({decimal_digits}{floating_fraction})
129
130	binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
131	hex_floating_suffix_opt ("_"?({floating_suffix}))?
132	hex_floating_fraction ({hex_digits}?"."{hex_digits})\|({hex_digits}".")
133	hex_floating_constant {hex_prefix}(({hex_floating_fraction}{binary_exponent})\|({hex_digits}{binary_exponent})){hex_floating_suffix_opt}
134
135	// character escape sequence, GCC: \e => esc character
136	simple_escape "\\"[abefnrtv'"?\\]
137	// ' stop editor highlighting
138	octal_escape "\\"{octal}("_"?{octal}){0,2}
139	hex_escape "\\""x""_"?{hex_digits}
140	escape_seq {simple_escape}\|{octal_escape}\|{hex_escape}\|{universal_char}
141	cwide_prefix "L"\|"U"\|"u"
142	swide_prefix {cwide_prefix}\|"u8"
143
144	// display/white-space characters
145	h_tab [\011]
146	form_feed [\014]
147	v_tab [\013]
148	c_return [\015]
149	h_white [ ]\|{h_tab}
150
151	// overloadable operators
152	op_unary_only "~"\|"!"
153	op_unary_binary "+"\|"-"\|"*"
154	op_unary_pre_post "++"\|"--"
155	op_unary {op_unary_only}\|{op_unary_binary}\|{op_unary_pre_post}
156
157	op_binary_only "/"\|"%"\|"\\"\|"^"\|"&"\|"\|"\|"<"\|">"\|"="\|"=="\|"!="\|"<<"\|">>"\|"<="\|">="\|"+="\|"-="\|"*="\|"/="\|"%="\|"\\="\|"&="\|"\|="\|"^="\|"<<="\|">>="
158	op_binary_over {op_unary_binary}\|{op_binary_only}
159	// op_binary_not_over "?"\|"->"\|"."\|"&&"\|"\|\|"\|"@="
160	// operator {op_unary_pre_post}\|{op_binary_over}\|{op_binary_not_over}
161
162	%x COMMENT
163	%x BKQUOTE
164	%x QUOTE
165	%x STRING
166
167	%%
168	/* line directives */
169	^{h_white}"#"{h_white}[0-9]+{h_white}["][^"\n]+["]."\n" {
170	/* " stop editor highlighting */
171	static char filename[FILENAME_MAX]; // temporarily store current source-file name
172	char *end_num;
173	char begin_string, end_string;
174	long lineno, length;
175	lineno = strtol( yytext + 1, &end_num, 0 );
176	begin_string = strchr( end_num, '"' );
177	if ( begin_string ) { // file name ?
178	end_string = strchr( begin_string + 1, '"' ); // look for ending delimiter
179	assert( end_string ); // closing quote ?
180	length = end_string - begin_string - 1; // file-name length without quotes or sentinel
181	assert( length < FILENAME_MAX ); // room for sentinel ?
182	memcpy( &filename, begin_string + 1, length ); // copy file name from yytext
183	filename[ length ] = '\0'; // terminate string with sentinel
184	//cout << "file " << filename << " line " << lineno << endl;
185	yylineno = lineno;
186	yyfilename = filename;
187	} // if
188	}
189
190	/* preprocessor-style directives */
191	^{h_white}"#"[^\n]"\n" { RETURN_VAL( DIRECTIVE ); }
192
193	/* ignore C style comments (ALSO HANDLED BY CPP) */
194	"/*" { BEGIN COMMENT; }
195	<COMMENT>.\|\n ;
196	<COMMENT>"*/" { BEGIN 0; }
197
198	/* ignore C++ style comments (ALSO HANDLED BY CPP) */
199	"//"[^\n]*"\n" ;
200
201	/* ignore whitespace */
202	{h_white}+ { WHITE_RETURN(' '); }
203	({v_tab}\|{c_return}\|{form_feed})+ { WHITE_RETURN(' '); }
204	({h_white}\|{v_tab}\|{c_return}\|{form_feed})*"\n" { NEWLINE_RETURN(); }
205
206	/* keywords */
207	_Alignas { KEYWORD_RETURN(ALIGNAS); } // C11
208	_Alignof { KEYWORD_RETURN(ALIGNOF); } // C11
209	__alignof { KEYWORD_RETURN(ALIGNOF); } // GCC
210	__alignof__ { KEYWORD_RETURN(ALIGNOF); } // GCC
211	asm { KEYWORD_RETURN(ASM); }
212	__asm { KEYWORD_RETURN(ASM); } // GCC
213	__asm__ { KEYWORD_RETURN(ASM); } // GCC
214	_Atomic { KEYWORD_RETURN(ATOMIC); } // C11
215	__attribute { KEYWORD_RETURN(ATTRIBUTE); } // GCC
216	__attribute__ { KEYWORD_RETURN(ATTRIBUTE); } // GCC
217	auto { KEYWORD_RETURN(AUTO); }
218	__auto_type { KEYWORD_RETURN(AUTO_TYPE); }
219	basetypeof { KEYWORD_RETURN(BASETYPEOF); } // CFA
220	_Bool { KEYWORD_RETURN(BOOL); } // C99
221	break { KEYWORD_RETURN(BREAK); }
222	case { KEYWORD_RETURN(CASE); }
223	catch { QKEYWORD_RETURN(CATCH); } // CFA
224	catchResume { QKEYWORD_RETURN(CATCHRESUME); } // CFA
225	char { KEYWORD_RETURN(CHAR); }
226	choose { KEYWORD_RETURN(CHOOSE); } // CFA
227	coerce { KEYWORD_RETURN(COERCE); } // CFA
228	_Complex { KEYWORD_RETURN(COMPLEX); } // C99
229	__complex { KEYWORD_RETURN(COMPLEX); } // GCC
230	__complex__ { KEYWORD_RETURN(COMPLEX); } // GCC
231	const { KEYWORD_RETURN(CONST); }
232	__const { KEYWORD_RETURN(CONST); } // GCC
233	__const__ { KEYWORD_RETURN(CONST); } // GCC
234	continue { KEYWORD_RETURN(CONTINUE); }
235	coroutine { KEYWORD_RETURN(COROUTINE); } // CFA
236	default { KEYWORD_RETURN(DEFAULT); }
237	disable { KEYWORD_RETURN(DISABLE); } // CFA
238	do { KEYWORD_RETURN(DO); }
239	double { KEYWORD_RETURN(DOUBLE); }
240	dtype { KEYWORD_RETURN(DTYPE); } // CFA
241	else { KEYWORD_RETURN(ELSE); }
242	enable { KEYWORD_RETURN(ENABLE); } // CFA
243	enum { KEYWORD_RETURN(ENUM); }
244	__extension__ { KEYWORD_RETURN(EXTENSION); } // GCC
245	exception { KEYWORD_RETURN(EXCEPTION); } // CFA
246	extern { KEYWORD_RETURN(EXTERN); }
247	fallthrough { KEYWORD_RETURN(FALLTHROUGH); } // CFA
248	fallthru { KEYWORD_RETURN(FALLTHRU); } // CFA
249	finally { QKEYWORD_RETURN(FINALLY); } // CFA
250	fixup { QKEYWORD_RETURN(FIXUP); } // CFA
251	float { KEYWORD_RETURN(FLOAT); }
252	__float80 { KEYWORD_RETURN(uuFLOAT80); } // GCC
253	float80 { KEYWORD_RETURN(uuFLOAT80); } // GCC
254	__float128 { KEYWORD_RETURN(uuFLOAT128); } // GCC
255	float128 { KEYWORD_RETURN(uuFLOAT128); } // GCC
256	_Float16 { FLOATXX(uFLOAT16); } // GCC
257	_Float32 { FLOATXX(uFLOAT32); } // GCC
258	_Float32x { FLOATXX(uFLOAT32X); } // GCC
259	_Float64 { FLOATXX(uFLOAT64); } // GCC
260	_Float64x { FLOATXX(uFLOAT64X); } // GCC
261	_Float128 { FLOATXX(uFLOAT128); } // GCC
262	_Float128x { FLOATXX(uFLOAT128); } // GCC
263	for { KEYWORD_RETURN(FOR); }
264	forall { KEYWORD_RETURN(FORALL); } // CFA
265	fortran { KEYWORD_RETURN(FORTRAN); }
266	ftype { KEYWORD_RETURN(FTYPE); } // CFA
267	generator { KEYWORD_RETURN(GENERATOR); } // CFA
268	_Generic { KEYWORD_RETURN(GENERIC); } // C11
269	goto { KEYWORD_RETURN(GOTO); }
270	if { KEYWORD_RETURN(IF); }
271	_Imaginary { KEYWORD_RETURN(IMAGINARY); } // C99
272	__imag { KEYWORD_RETURN(IMAGINARY); } // GCC
273	__imag__ { KEYWORD_RETURN(IMAGINARY); } // GCC
274	inline { KEYWORD_RETURN(INLINE); } // C99
275	__inline { KEYWORD_RETURN(INLINE); } // GCC
276	__inline__ { KEYWORD_RETURN(INLINE); } // GCC
277	int { KEYWORD_RETURN(INT); }
278	int128 { KEYWORD_RETURN(INT128); } // CFA
279	__int128 { KEYWORD_RETURN(INT128); } // GCC
280	__int128_t { KEYWORD_RETURN(INT128); } // GCC
281	__label__ { KEYWORD_RETURN(LABEL); } // GCC
282	long { KEYWORD_RETURN(LONG); }
283	monitor { KEYWORD_RETURN(MONITOR); } // CFA
284	mutex { KEYWORD_RETURN(MUTEX); } // CFA
285	_Noreturn { KEYWORD_RETURN(NORETURN); } // C11
286	__builtin_offsetof { KEYWORD_RETURN(OFFSETOF); } // GCC
287	one_t { NUMERIC_RETURN(ONE_T); } // CFA
288	or { QKEYWORD_RETURN(WOR); } // CFA
289	otype { KEYWORD_RETURN(OTYPE); } // CFA
290	recover { QKEYWORD_RETURN(RECOVER); } // CFA
291	register { KEYWORD_RETURN(REGISTER); }
292	report { KEYWORD_RETURN(THROWRESUME); } // CFA
293	restrict { KEYWORD_RETURN(RESTRICT); } // C99
294	__restrict { KEYWORD_RETURN(RESTRICT); } // GCC
295	__restrict__ { KEYWORD_RETURN(RESTRICT); } // GCC
296	return { KEYWORD_RETURN(RETURN); }
297	/* resume { KEYWORD_RETURN(RESUME); } // CFA */
298	short { KEYWORD_RETURN(SHORT); }
299	signed { KEYWORD_RETURN(SIGNED); }
300	__signed { KEYWORD_RETURN(SIGNED); } // GCC
301	__signed__ { KEYWORD_RETURN(SIGNED); } // GCC
302	sizeof { KEYWORD_RETURN(SIZEOF); }
303	static { KEYWORD_RETURN(STATIC); }
304	_Static_assert { KEYWORD_RETURN(STATICASSERT); } // C11
305	struct { KEYWORD_RETURN(STRUCT); }
306	suspend { KEYWORD_RETURN(SUSPEND); } // CFA
307	switch { KEYWORD_RETURN(SWITCH); }
308	thread { KEYWORD_RETURN(THREAD); } // C11
309	_Thread_local { KEYWORD_RETURN(THREADLOCAL); } // C11
310	throw { KEYWORD_RETURN(THROW); } // CFA
311	throwResume { KEYWORD_RETURN(THROWRESUME); } // CFA
312	timeout { QKEYWORD_RETURN(TIMEOUT); } // CFA
313	trait { KEYWORD_RETURN(TRAIT); } // CFA
314	try { KEYWORD_RETURN(TRY); } // CFA
315	ttype { KEYWORD_RETURN(TTYPE); } // CFA
316	typedef { KEYWORD_RETURN(TYPEDEF); }
317	typeof { KEYWORD_RETURN(TYPEOF); } // GCC
318	__typeof { KEYWORD_RETURN(TYPEOF); } // GCC
319	__typeof__ { KEYWORD_RETURN(TYPEOF); } // GCC
320	typeid { KEYWORD_RETURN(TYPEID); } // GCC
321	union { KEYWORD_RETURN(UNION); }
322	__uint128_t { KEYWORD_RETURN(UINT128); } // GCC
323	unsigned { KEYWORD_RETURN(UNSIGNED); }
324	__builtin_va_list { KEYWORD_RETURN(VALIST); } // GCC
325	virtual { KEYWORD_RETURN(VIRTUAL); } // CFA
326	void { KEYWORD_RETURN(VOID); }
327	volatile { KEYWORD_RETURN(VOLATILE); }
328	__volatile { KEYWORD_RETURN(VOLATILE); } // GCC
329	__volatile__ { KEYWORD_RETURN(VOLATILE); } // GCC
330	vtable { KEYWORD_RETURN(VTABLE); } // CFA
331	waitfor { KEYWORD_RETURN(WAITFOR); } // CFA
332	when { KEYWORD_RETURN(WHEN); } // CFA
333	while { KEYWORD_RETURN(WHILE); }
334	with { KEYWORD_RETURN(WITH); } // CFA
335	zero_t { NUMERIC_RETURN(ZERO_T); } // CFA
336
337	/* identifier */
338	{identifier} { IDENTIFIER_RETURN(); }
339	"``"{identifier} { // CFA
340	yytext[yyleng] = '\0'; yytext += 2; // SKULLDUGGERY: remove backquotes (ok to shorten?)
341	IDENTIFIER_RETURN();
342	}
343
344	/* numeric constants */
345	{binary_constant} { NUMERIC_RETURN(INTEGERconstant); }
346	{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
347	{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
348	{hex_constant} { NUMERIC_RETURN(INTEGERconstant); }
349	{floating_decimal} { NUMERIC_RETURN(FLOATING_DECIMALconstant); } // must appear before floating_constant
350	{floating_fraction} { NUMERIC_RETURN(FLOATING_FRACTIONconstant); } // must appear before floating_constant
351	{floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
352	{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
353
354	/* character constant, allows empty value */
355	({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new string( yytext, yyleng ); }
356	<QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); }
357	<QUOTE>['\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); }
358	/* ' stop editor highlighting */
359
360	/* string constant */
361	({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new string( yytext, yyleng ); }
362	<STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); }
363	<STRING>["\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); }
364	/* " stop editor highlighting */
365
366	/* common character/string constant */
367	<QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); }
368	<QUOTE,STRING>"\\"{h_white}*"\n" {} // continuation (ALSO HANDLED BY CPP)
369	<QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character
370
371	/* punctuation */
372	"@" { ASCIIOP_RETURN(); }
373	"`" { ASCIIOP_RETURN(); }
374	"[" { ASCIIOP_RETURN(); }
375	"]" { ASCIIOP_RETURN(); }
376	"(" { ASCIIOP_RETURN(); }
377	")" { ASCIIOP_RETURN(); }
378	"{" { ASCIIOP_RETURN(); }
379	"}" { ASCIIOP_RETURN(); }
380	"," { ASCIIOP_RETURN(); } // also operator
381	":" { ASCIIOP_RETURN(); }
382	";" { ASCIIOP_RETURN(); }
383	"." { ASCIIOP_RETURN(); } // also operator
384	"..." { NAMEDOP_RETURN(ELLIPSIS); }
385
386	/* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
387	"<:" { RETURN_VAL('['); }
388	":>" { RETURN_VAL(']'); }
389	"<%" { RETURN_VAL('{'); }
390	"%>" { RETURN_VAL('}'); }
391
392	/* operators */
393	"!" { ASCIIOP_RETURN(); }
394	"+" { ASCIIOP_RETURN(); }
395	"-" { ASCIIOP_RETURN(); }
396	"*" { ASCIIOP_RETURN(); }
397	"\\" { ASCIIOP_RETURN(); } // CFA, exponentiation
398	"/" { ASCIIOP_RETURN(); }
399	"%" { ASCIIOP_RETURN(); }
400	"^" { ASCIIOP_RETURN(); }
401	"~" { ASCIIOP_RETURN(); }
402	"&" { ASCIIOP_RETURN(); }
403	"\|" { ASCIIOP_RETURN(); }
404	"<" { ASCIIOP_RETURN(); }
405	">" { ASCIIOP_RETURN(); }
406	"=" { ASCIIOP_RETURN(); }
407	"?" { ASCIIOP_RETURN(); }
408
409	"++" { NAMEDOP_RETURN(ICR); }
410	"--" { NAMEDOP_RETURN(DECR); }
411	"==" { NAMEDOP_RETURN(EQ); }
412	"!=" { NAMEDOP_RETURN(NE); }
413	"<<" { NAMEDOP_RETURN(LS); }
414	">>" { NAMEDOP_RETURN(RS); }
415	"<=" { NAMEDOP_RETURN(LE); }
416	">=" { NAMEDOP_RETURN(GE); }
417	"&&" { NAMEDOP_RETURN(ANDAND); }
418	"\|\|" { NAMEDOP_RETURN(OROR); }
419	"->" { NAMEDOP_RETURN(ARROW); }
420	"+=" { NAMEDOP_RETURN(PLUSassign); }
421	"-=" { NAMEDOP_RETURN(MINUSassign); }
422	"\\=" { NAMEDOP_RETURN(EXPassign); } // CFA, exponentiation
423	"*=" { NAMEDOP_RETURN(MULTassign); }
424	"/=" { NAMEDOP_RETURN(DIVassign); }
425	"%=" { NAMEDOP_RETURN(MODassign); }
426	"&=" { NAMEDOP_RETURN(ANDassign); }
427	"\|=" { NAMEDOP_RETURN(ORassign); }
428	"^=" { NAMEDOP_RETURN(ERassign); }
429	"<<=" { NAMEDOP_RETURN(LSassign); }
430	">>=" { NAMEDOP_RETURN(RSassign); }
431
432	"@=" { NAMEDOP_RETURN(ATassign); } // CFA
433	"~=" { NAMEDOP_RETURN(ErangeUpEq); } // CFA
434	"-~" { NAMEDOP_RETURN(ErangeDown); } // CFA
435	"-~=" { NAMEDOP_RETURN(ErangeDownEq); } // CFA
436
437	/* CFA, operator identifier */
438	{op_unary}"?" { IDENTIFIER_RETURN(); } // unary
439	"?"({op_unary_pre_post}\|"()"\|"[?]"\|"{}") { IDENTIFIER_RETURN(); }
440	"^?{}" { IDENTIFIER_RETURN(); }
441	"?`"{identifier} { // postfix operator
442	yylval.tok.str = new string( &yytext[2] ); // remove ?`
443	yylval.tok.str = build_postfix_name( yylval.tok.str ); // add prefix
444	RETURN_LOCN( typedefTable.isKind( *yylval.tok.str ) );
445	}
446	"?"{op_binary_over}"?" { IDENTIFIER_RETURN(); } // binary
447	/*
448	This rule handles ambiguous cases with operator identifiers, e.g., "int ??()", where the string "??" can be
449	lexed as "?"/"?" or ""/"??". Since it is common practise to put a unary operator juxtaposed to an identifier,
450	e.g., "*i", users will be annoyed if they cannot do this with respect to operator identifiers. Therefore, there is
451	a lexical look-ahead for the second case, with backtracking to return the leading unary operator and then
452	reparsing the trailing operator identifier. Otherwise a space is needed between the unary operator and operator
453	identifier to disambiguate this common case.
454
455	A similar issue occurs with the dereference, *?(...), and routine-call, ?()(...) identifiers. The ambiguity
456	occurs when the deference operator has no parameters, ?() and ?()(...), requiring arbitrary whitespace
457	look-ahead for the routine-call parameter-list to disambiguate. However, the dereference operator must have a
458	parameter/argument to dereference ?(...). Hence, always interpreting the string ?() as * ?() does not preclude
459	any meaningful program.
460
461	The remaining cases are with the increment/decrement operators and conditional expression:
462
463	i++? ...(...);
464	i?++ ...(...);
465
466	requiring arbitrary whitespace look-ahead for the operator parameter-list, even though that interpretation is an
467	incorrect expression (juxtaposed identifiers). Therefore, it is necessary to disambiguate these cases with a
468	space:
469
470	i++ ? i : 0;
471	i? ++i : 0;
472	*/
473	{op_unary}"?"({op_unary_pre_post}\|"()"\|"[?]"\|{op_binary_over}"?") {
474	// 1 or 2 character unary operator ?
475	int i = yytext[1] == '?' ? 1 : 2;
476	yyless( i ); // put back characters up to first '?'
477	if ( i > 1 ) {
478	NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
479	} else {
480	ASCIIOP_RETURN();
481	} // if
482	}
483
484	/* unknown character */
485	. { yyerror( "unknown character" ); }
486
487	%%
488
489	// ----end of lexer----
490
491	void yyerror( const char * errmsg ) {
492	SemanticErrorThrow = true;
493	cerr << (yyfilename ? yyfilename : "unknown file") << ':' << yylineno << ':' << column - yyleng + 1
494	<< ": " << ErrorHelpers::error_str() << errmsg << " at token \"" << (yytext[0] == '\0' ? "EOF" : yytext) << '"' << endl;
495	}
496
497	// Local Variables: //
498	// mode: c++ //
499	// tab-width: 4 //
500	// compile-command: "make install" //
501	// End: //

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format