Context Navigation

lex.ll @ 8a78dd3

ADTaaron-thesisarm-ehast-experimentalcleanup-dtorsdeferred_resndemanglerenumforall-pointer-decayjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-exprnew-envno_listpersistent-indexerpthread-emulationqualifiedEnumresolv-newwith_gc

Last change on this file since 8a78dd3 was bd7f401, checked in by Peter A. Buhr <pabuhr@…>, 7 years ago
formatting
Property mode set to `100644`
File size: 18.0 KB

Line
1	/*
2	* Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3	*
4	* The contents of this file are covered under the licence agreement in the
5	* file "LICENCE" distributed with Cforall.
6	*
7	* lex.ll --
8	*
9	* Author : Peter A. Buhr
10	* Created On : Sat Sep 22 08:58:10 2001
11	* Last Modified By : Peter A. Buhr
12	* Last Modified On : Wed Oct 25 13:53:56 2017
13	* Update Count : 634
14	*/
15
16	%option yylineno
17	%option noyywrap
18	%option nounput
19
20	%{
21	// The lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
22	// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
23	// line-number directives) and C/C++ style comments, which are ignored.
24
25	//************************** Includes and Defines **************************
26
27	unsigned int column = 0; // position of the end of the last token parsed
28	#define YY_USER_ACTION yylloc.first_line = yylineno; yylloc.first_column = column; column += yyleng; yylloc.last_column = column; yylloc.last_line = yylineno; yylloc.filename = yyfilename ? yyfilename : ""; // trigger before each matching rule's action
29
30	#include <string>
31	#include <cstdio> // FILENAME_MAX
32	using namespace std;
33
34	#include "ParseNode.h"
35	#include "TypedefTable.h"
36
37	char *yyfilename;
38	string *strtext; // accumulate parts of character and string constant value
39
40	#define RETURN_LOCN(x) yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
41	#define RETURN_VAL(x) yylval.tok.str = new string( yytext ); RETURN_LOCN( x )
42	#define RETURN_CHAR(x) yylval.tok.str = nullptr; RETURN_LOCN( x )
43	#define RETURN_STR(x) yylval.tok.str = strtext; RETURN_LOCN( x )
44
45	#define WHITE_RETURN(x) // do nothing
46	#define NEWLINE_RETURN() column = 0; WHITE_RETURN( '\n' )
47	#define ASCIIOP_RETURN() RETURN_CHAR( (int)yytext[0] ) // single character operator
48	#define NAMEDOP_RETURN(x) RETURN_CHAR( x ) // multichar operator, with a name
49	#define NUMERIC_RETURN(x) rm_underscore(); RETURN_VAL( x ) // numeric constant
50	#define KEYWORD_RETURN(x) RETURN_CHAR( x ) // keyword
51	#define QKEYWORD_RETURN(x) typedefTable.isKind( yytext ); RETURN_VAL(x); // quasi-keyword
52	#define IDENTIFIER_RETURN() RETURN_VAL( typedefTable.isKind( yytext ) )
53	#define ATTRIBUTE_RETURN() RETURN_VAL( ATTR_IDENTIFIER )
54
55	void rm_underscore() {
56	// Remove underscores in numeric constant by copying the non-underscore characters to the front of the string.
57	yyleng = 0;
58	for ( int i = 0; yytext[i] != '\0'; i += 1 ) {
59	if ( yytext[i] == '`' ) {
60	// copy user suffix
61	for ( ; yytext[i] != '\0'; i += 1 ) {
62	yytext[yyleng] = yytext[i];
63	yyleng += 1;
64	} // for
65	break;
66	} // if
67	if ( yytext[i] != '_' ) {
68	yytext[yyleng] = yytext[i];
69	yyleng += 1;
70	} // if
71	} // for
72	yytext[yyleng] = '\0';
73	}
74
75	// Stop warning due to incorrectly generated flex code.
76	#pragma GCC diagnostic ignored "-Wsign-compare"
77	%}
78
79	octal [0-7]
80	nonzero [1-9]
81	decimal [0-9]
82	hex [0-9a-fA-F]
83	universal_char "\\"((u"_"?{hex_quad})\|(U"_"?{hex_quad}{2}))
84
85	// identifier, GCC: $ in identifier
86	identifier ([a-zA-Z_$]\|{universal_char})([0-9a-zA-Z_$]\|{universal_char})*
87
88	// attribute identifier, GCC: $ in identifier
89	attr_identifier "@"{identifier}
90
91	user_suffix_opt ("`"{identifier})?
92
93	// numeric constants, CFA: '_' in constant
94	hex_quad {hex}("_"?{hex}){3}
95	size_opt (8\|16\|32\|64\|128)?
96	length ("ll"\|"LL"\|[lL]{size_opt})\|("hh"\|"HH"\|[hH])
97	integer_suffix_opt ("_"?(([uU]({length}?[iI]?)\|([iI]{length}))\|([iI]({length}?[uU]?)\|([uU]{length}))\|({length}([iI]?[uU]?)\|([uU][iI]))\|[zZ]))?{user_suffix_opt}
98
99	octal_digits ({octal})\|({octal}({octal}\|"_")*{octal})
100	octal_prefix "0""_"?
101	octal_constant (("0")\|({octal_prefix}{octal_digits})){integer_suffix_opt}
102
103	nonzero_digits ({nonzero})\|({nonzero}({decimal}\|"_")*{decimal})
104	decimal_constant {nonzero_digits}{integer_suffix_opt}
105
106	hex_digits ({hex})\|({hex}({hex}\|"_")*{hex})
107	hex_prefix "0"[xX]"_"?
108	hex_constant {hex_prefix}{hex_digits}{integer_suffix_opt}
109
110	// GCC: D (double) and iI (imaginary) suffixes, and DL (long double)
111	exponent "_"?[eE]"_"?[+-]?{decimal_digits}
112	floating_size 32\|64\|80\|128
113	floating_length ([fFdDlL]\|[lL]{floating_size})
114	floating_suffix ({floating_length}?[iI]?)\|([iI]{floating_length})
115	floating_suffix_opt ("_"?({floating_suffix}\|"DL"))?{user_suffix_opt}
116	decimal_digits ({decimal})\|({decimal}({decimal}\|"_")*{decimal})
117	floating_decimal {decimal_digits}"."{exponent}?{floating_suffix_opt}
118	floating_fraction "."{decimal_digits}{exponent}?{floating_suffix_opt}
119	floating_constant ({decimal_digits}{exponent}{floating_suffix_opt})\|({decimal_digits}{floating_fraction})
120
121	binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
122	hex_floating_suffix_opt ("_"?({floating_suffix}))?{user_suffix_opt}
123	hex_floating_fraction ({hex_digits}?"."{hex_digits})\|({hex_digits}".")
124	hex_floating_constant {hex_prefix}(({hex_floating_fraction}{binary_exponent})\|({hex_digits}{binary_exponent})){hex_floating_suffix_opt}
125
126	// character escape sequence, GCC: \e => esc character
127	simple_escape "\\"[abefnrtv'"?\\]
128	// ' stop editor highlighting
129	octal_escape "\\"{octal}("_"?{octal}){0,2}
130	hex_escape "\\""x""_"?{hex_digits}
131	escape_seq {simple_escape}\|{octal_escape}\|{hex_escape}\|{universal_char}
132	cwide_prefix "L"\|"U"\|"u"
133	swide_prefix {cwide_prefix}\|"u8"
134
135	// display/white-space characters
136	h_tab [\011]
137	form_feed [\014]
138	v_tab [\013]
139	c_return [\015]
140	h_white [ ]\|{h_tab}
141
142	// overloadable operators
143	op_unary_only "~"\|"!"
144	op_unary_binary "+"\|"-"\|"*"
145	op_unary_pre_post "++"\|"--"
146	op_unary {op_unary_only}\|{op_unary_binary}\|{op_unary_pre_post}
147
148	op_binary_only "/"\|"%"\|"\\"\|"^"\|"&"\|"\|"\|"<"\|">"\|"="\|"=="\|"!="\|"<<"\|">>"\|"<="\|">="\|"+="\|"-="\|"*="\|"/="\|"%="\|"\\="\|"&="\|"\|="\|"^="\|"<<="\|">>="
149	op_binary_over {op_unary_binary}\|{op_binary_only}
150	// op_binary_not_over "?"\|"->"\|"."\|"&&"\|"\|\|"\|"@="
151	// operator {op_unary_pre_post}\|{op_binary_over}\|{op_binary_not_over}
152
153	%x COMMENT
154	%x BKQUOTE
155	%x QUOTE
156	%x STRING
157
158	%%
159	/* line directives */
160	^{h_white}"#"{h_white}[0-9]+{h_white}["][^"\n]+["]."\n" {
161	/* " stop editor highlighting */
162	static char filename[FILENAME_MAX]; // temporarily store current source-file name
163	char *end_num;
164	char begin_string, end_string;
165	long lineno, length;
166	lineno = strtol( yytext + 1, &end_num, 0 );
167	begin_string = strchr( end_num, '"' );
168	if ( begin_string ) { // file name ?
169	end_string = strchr( begin_string + 1, '"' ); // look for ending delimiter
170	assert( end_string ); // closing quote ?
171	length = end_string - begin_string - 1; // file-name length without quotes or sentinel
172	assert( length < FILENAME_MAX ); // room for sentinel ?
173	memcpy( &filename, begin_string + 1, length ); // copy file name from yytext
174	filename[ length ] = '\0'; // terminate string with sentinel
175	//cout << "file " << filename << " line " << lineno << endl;
176	yylineno = lineno;
177	yyfilename = filename;
178	} // if
179	}
180
181	/* ignore preprocessor directives (for now) */
182	^{h_white}"#"[^\n]"\n" ;
183
184	/* ignore C style comments (ALSO HANDLED BY CPP) */
185	"/*" { BEGIN COMMENT; }
186	<COMMENT>.\|\n ;
187	<COMMENT>"*/" { BEGIN 0; }
188
189	/* ignore C++ style comments (ALSO HANDLED BY CPP) */
190	"//"[^\n]*"\n" ;
191
192	/* ignore whitespace */
193	{h_white}+ { WHITE_RETURN(' '); }
194	({v_tab}\|{c_return}\|{form_feed})+ { WHITE_RETURN(' '); }
195	({h_white}\|{v_tab}\|{c_return}\|{form_feed})*"\n" { NEWLINE_RETURN(); }
196
197	/* keywords */
198	_Alignas { KEYWORD_RETURN(ALIGNAS); } // C11
199	_Alignof { KEYWORD_RETURN(ALIGNOF); } // C11
200	__alignof { KEYWORD_RETURN(ALIGNOF); } // GCC
201	__alignof__ { KEYWORD_RETURN(ALIGNOF); } // GCC
202	asm { KEYWORD_RETURN(ASM); }
203	__asm { KEYWORD_RETURN(ASM); } // GCC
204	__asm__ { KEYWORD_RETURN(ASM); } // GCC
205	_At { KEYWORD_RETURN(AT); } // CFA
206	_Atomic { KEYWORD_RETURN(ATOMIC); } // C11
207	__attribute { KEYWORD_RETURN(ATTRIBUTE); } // GCC
208	__attribute__ { KEYWORD_RETURN(ATTRIBUTE); } // GCC
209	auto { KEYWORD_RETURN(AUTO); }
210	_Bool { KEYWORD_RETURN(BOOL); } // C99
211	break { KEYWORD_RETURN(BREAK); }
212	case { KEYWORD_RETURN(CASE); }
213	catch { KEYWORD_RETURN(CATCH); } // CFA
214	catchResume { KEYWORD_RETURN(CATCHRESUME); } // CFA
215	char { KEYWORD_RETURN(CHAR); }
216	choose { KEYWORD_RETURN(CHOOSE); } // CFA
217	_Complex { KEYWORD_RETURN(COMPLEX); } // C99
218	__complex { KEYWORD_RETURN(COMPLEX); } // GCC
219	__complex__ { KEYWORD_RETURN(COMPLEX); } // GCC
220	const { KEYWORD_RETURN(CONST); }
221	__const { KEYWORD_RETURN(CONST); } // GCC
222	__const__ { KEYWORD_RETURN(CONST); } // GCC
223	continue { KEYWORD_RETURN(CONTINUE); }
224	coroutine { KEYWORD_RETURN(COROUTINE); } // CFA
225	default { KEYWORD_RETURN(DEFAULT); }
226	disable { KEYWORD_RETURN(DISABLE); } // CFA
227	do { KEYWORD_RETURN(DO); }
228	double { KEYWORD_RETURN(DOUBLE); }
229	dtype { KEYWORD_RETURN(DTYPE); } // CFA
230	else { KEYWORD_RETURN(ELSE); }
231	enable { KEYWORD_RETURN(ENABLE); } // CFA
232	enum { KEYWORD_RETURN(ENUM); }
233	__extension__ { KEYWORD_RETURN(EXTENSION); } // GCC
234	extern { KEYWORD_RETURN(EXTERN); }
235	fallthru { KEYWORD_RETURN(FALLTHRU); } // CFA
236	fallthrough { KEYWORD_RETURN(FALLTHROUGH); } // CFA
237	finally { KEYWORD_RETURN(FINALLY); } // CFA
238	float { KEYWORD_RETURN(FLOAT); }
239	__float80 { KEYWORD_RETURN(FLOAT80); } // GCC
240	float80 { KEYWORD_RETURN(FLOAT80); } // GCC
241	__float128 { KEYWORD_RETURN(FLOAT128); } // GCC
242	float128 { KEYWORD_RETURN(FLOAT128); } // GCC
243	for { KEYWORD_RETURN(FOR); }
244	forall { KEYWORD_RETURN(FORALL); } // CFA
245	fortran { KEYWORD_RETURN(FORTRAN); }
246	ftype { KEYWORD_RETURN(FTYPE); } // CFA
247	_Generic { KEYWORD_RETURN(GENERIC); } // C11
248	goto { KEYWORD_RETURN(GOTO); }
249	if { KEYWORD_RETURN(IF); }
250	_Imaginary { KEYWORD_RETURN(IMAGINARY); } // C99
251	__imag { KEYWORD_RETURN(IMAGINARY); } // GCC
252	__imag__ { KEYWORD_RETURN(IMAGINARY); } // GCC
253	inline { KEYWORD_RETURN(INLINE); } // C99
254	__inline { KEYWORD_RETURN(INLINE); } // GCC
255	__inline__ { KEYWORD_RETURN(INLINE); } // GCC
256	int { KEYWORD_RETURN(INT); }
257	__int128 { KEYWORD_RETURN(INT128); } // GCC
258	int128 { KEYWORD_RETURN(INT128); } // GCC
259	__label__ { KEYWORD_RETURN(LABEL); } // GCC
260	long { KEYWORD_RETURN(LONG); }
261	monitor { KEYWORD_RETURN(MONITOR); } // CFA
262	mutex { KEYWORD_RETURN(MUTEX); } // CFA
263	_Noreturn { KEYWORD_RETURN(NORETURN); } // C11
264	__builtin_offsetof { KEYWORD_RETURN(OFFSETOF); } // GCC
265	one_t { NUMERIC_RETURN(ONE_T); } // CFA
266	otype { KEYWORD_RETURN(OTYPE); } // CFA
267	register { KEYWORD_RETURN(REGISTER); }
268	restrict { KEYWORD_RETURN(RESTRICT); } // C99
269	__restrict { KEYWORD_RETURN(RESTRICT); } // GCC
270	__restrict__ { KEYWORD_RETURN(RESTRICT); } // GCC
271	return { KEYWORD_RETURN(RETURN); }
272	short { KEYWORD_RETURN(SHORT); }
273	signed { KEYWORD_RETURN(SIGNED); }
274	__signed { KEYWORD_RETURN(SIGNED); } // GCC
275	__signed__ { KEYWORD_RETURN(SIGNED); } // GCC
276	sizeof { KEYWORD_RETURN(SIZEOF); }
277	static { KEYWORD_RETURN(STATIC); }
278	_Static_assert { KEYWORD_RETURN(STATICASSERT); } // C11
279	struct { KEYWORD_RETURN(STRUCT); }
280	switch { KEYWORD_RETURN(SWITCH); }
281	thread { KEYWORD_RETURN(THREAD); } // C11
282	_Thread_local { KEYWORD_RETURN(THREADLOCAL); } // C11
283	throw { KEYWORD_RETURN(THROW); } // CFA
284	throwResume { KEYWORD_RETURN(THROWRESUME); } // CFA
285	timeout { QKEYWORD_RETURN(TIMEOUT); } // CFA
286	trait { KEYWORD_RETURN(TRAIT); } // CFA
287	try { KEYWORD_RETURN(TRY); } // CFA
288	ttype { KEYWORD_RETURN(TTYPE); } // CFA
289	typedef { KEYWORD_RETURN(TYPEDEF); }
290	typeof { KEYWORD_RETURN(TYPEOF); } // GCC
291	__typeof { KEYWORD_RETURN(TYPEOF); } // GCC
292	__typeof__ { KEYWORD_RETURN(TYPEOF); } // GCC
293	union { KEYWORD_RETURN(UNION); }
294	unsigned { KEYWORD_RETURN(UNSIGNED); }
295	__builtin_va_list { KEYWORD_RETURN(VALIST); } // GCC
296	virtual { KEYWORD_RETURN(VIRTUAL); } // CFA
297	void { KEYWORD_RETURN(VOID); }
298	volatile { KEYWORD_RETURN(VOLATILE); }
299	__volatile { KEYWORD_RETURN(VOLATILE); } // GCC
300	__volatile__ { KEYWORD_RETURN(VOLATILE); } // GCC
301	waitfor { KEYWORD_RETURN(WAITFOR); }
302	or { QKEYWORD_RETURN(WOR); } // CFA
303	when { KEYWORD_RETURN(WHEN); }
304	while { KEYWORD_RETURN(WHILE); }
305	with { KEYWORD_RETURN(WITH); } // CFA
306	zero_t { NUMERIC_RETURN(ZERO_T); } // CFA
307
308	/* identifier */
309	{identifier} { IDENTIFIER_RETURN(); }
310	{attr_identifier} { ATTRIBUTE_RETURN(); }
311	"`" { BEGIN BKQUOTE; }
312	<BKQUOTE>{identifier} { IDENTIFIER_RETURN(); }
313	<BKQUOTE>"`" { BEGIN 0; }
314
315	/* numeric constants */
316	{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
317	{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
318	{hex_constant} { NUMERIC_RETURN(INTEGERconstant); }
319	{floating_decimal} { NUMERIC_RETURN(FLOATING_DECIMALconstant); } // must appear before floating_constant
320	{floating_fraction} { NUMERIC_RETURN(FLOATING_FRACTIONconstant); } // must appear before floating_constant
321	{floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
322	{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
323
324	/* character constant, allows empty value */
325	({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new string( yytext, yyleng ); }
326	<QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); }
327	<QUOTE>['\n]{user_suffix_opt} { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); }
328	/* ' stop editor highlighting */
329
330	/* string constant */
331	({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new string( yytext, yyleng ); }
332	<STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); }
333	<STRING>["\n]{user_suffix_opt} { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); }
334	/* " stop editor highlighting */
335
336	/* common character/string constant */
337	<QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); }
338	<QUOTE,STRING>"\\"{h_white}*"\n" {} // continuation (ALSO HANDLED BY CPP)
339	<QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character
340
341	/* punctuation */
342	"@" { ASCIIOP_RETURN(); }
343	"[" { ASCIIOP_RETURN(); }
344	"]" { ASCIIOP_RETURN(); }
345	"(" { ASCIIOP_RETURN(); }
346	")" { ASCIIOP_RETURN(); }
347	"{" { ASCIIOP_RETURN(); }
348	"}" { ASCIIOP_RETURN(); }
349	"," { ASCIIOP_RETURN(); } // also operator
350	":" { ASCIIOP_RETURN(); }
351	";" { ASCIIOP_RETURN(); }
352	"." { ASCIIOP_RETURN(); } // also operator
353	"..." { NAMEDOP_RETURN(ELLIPSIS); }
354
355	/* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
356	"<:" { RETURN_VAL('['); }
357	":>" { RETURN_VAL(']'); }
358	"<%" { RETURN_VAL('{'); }
359	"%>" { RETURN_VAL('}'); }
360
361	/* operators */
362	"!" { ASCIIOP_RETURN(); }
363	"+" { ASCIIOP_RETURN(); }
364	"-" { ASCIIOP_RETURN(); }
365	"*" { ASCIIOP_RETURN(); }
366	"\\" { ASCIIOP_RETURN(); } // CFA, exponentiation
367	"/" { ASCIIOP_RETURN(); }
368	"%" { ASCIIOP_RETURN(); }
369	"^" { ASCIIOP_RETURN(); }
370	"~" { ASCIIOP_RETURN(); }
371	"&" { ASCIIOP_RETURN(); }
372	"\|" { ASCIIOP_RETURN(); }
373	"<" { ASCIIOP_RETURN(); }
374	">" { ASCIIOP_RETURN(); }
375	"=" { ASCIIOP_RETURN(); }
376	"?" { ASCIIOP_RETURN(); }
377
378	"++" { NAMEDOP_RETURN(ICR); }
379	"--" { NAMEDOP_RETURN(DECR); }
380	"==" { NAMEDOP_RETURN(EQ); }
381	"!=" { NAMEDOP_RETURN(NE); }
382	"<<" { NAMEDOP_RETURN(LS); }
383	">>" { NAMEDOP_RETURN(RS); }
384	"<=" { NAMEDOP_RETURN(LE); }
385	">=" { NAMEDOP_RETURN(GE); }
386	"&&" { NAMEDOP_RETURN(ANDAND); }
387	"\|\|" { NAMEDOP_RETURN(OROR); }
388	"->" { NAMEDOP_RETURN(ARROW); }
389	"+=" { NAMEDOP_RETURN(PLUSassign); }
390	"-=" { NAMEDOP_RETURN(MINUSassign); }
391	"\\=" { NAMEDOP_RETURN(EXPassign); } // CFA, exponentiation
392	"*=" { NAMEDOP_RETURN(MULTassign); }
393	"/=" { NAMEDOP_RETURN(DIVassign); }
394	"%=" { NAMEDOP_RETURN(MODassign); }
395	"&=" { NAMEDOP_RETURN(ANDassign); }
396	"\|=" { NAMEDOP_RETURN(ORassign); }
397	"^=" { NAMEDOP_RETURN(ERassign); }
398	"<<=" { NAMEDOP_RETURN(LSassign); }
399	">>=" { NAMEDOP_RETURN(RSassign); }
400
401	"@=" { NAMEDOP_RETURN(ATassign); } // CFA
402
403	/* CFA, operator identifier */
404	{op_unary}"?" { IDENTIFIER_RETURN(); } // unary
405	"?"({op_unary_pre_post}\|"()"\|"[?]"\|"{}") { IDENTIFIER_RETURN(); }
406	"^?{}" { IDENTIFIER_RETURN(); }
407	"?`"{identifier} { IDENTIFIER_RETURN(); } // unit operator
408	"?"{op_binary_over}"?" { IDENTIFIER_RETURN(); } // binary
409	/*
410	This rule handles ambiguous cases with operator identifiers, e.g., "int ??()", where the string "??" can be
411	lexed as "?"/"?" or ""/"??". Since it is common practise to put a unary operator juxtaposed to an identifier,
412	e.g., "*i", users will be annoyed if they cannot do this with respect to operator identifiers. Therefore, there is
413	a lexical look-ahead for the second case, with backtracking to return the leading unary operator and then
414	reparsing the trailing operator identifier. Otherwise a space is needed between the unary operator and operator
415	identifier to disambiguate this common case.
416
417	A similar issue occurs with the dereference, *?(...), and routine-call, ?()(...) identifiers. The ambiguity
418	occurs when the deference operator has no parameters, ?() and ?()(...), requiring arbitrary whitespace
419	look-ahead for the routine-call parameter-list to disambiguate. However, the dereference operator must have a
420	parameter/argument to dereference ?(...). Hence, always interpreting the string ?() as * ?() does not preclude
421	any meaningful program.
422
423	The remaining cases are with the increment/decrement operators and conditional expression:
424
425	i++? ...(...);
426	i?++ ...(...);
427
428	requiring arbitrary whitespace look-ahead for the operator parameter-list, even though that interpretation is an
429	incorrect expression (juxtaposed identifiers). Therefore, it is necessary to disambiguate these cases with a
430	space:
431
432	i++ ? i : 0;
433	i? ++i : 0;
434	*/
435	{op_unary}"?"({op_unary_pre_post}\|"()"\|"[?]"\|{op_binary_over}"?") {
436	// 1 or 2 character unary operator ?
437	int i = yytext[1] == '?' ? 1 : 2;
438	yyless( i ); // put back characters up to first '?'
439	if ( i > 1 ) {
440	NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
441	} else {
442	ASCIIOP_RETURN();
443	} // if
444	}
445
446	/* unknown character */
447	. { yyerror( "unknown character" ); }
448
449	%%
450	// ----end of lexer----
451
452	void yyerror( const char * errmsg ) {
453	cout << (yyfilename ? yyfilename : "unknown file") << ':' << yylineno << ':' << column - yyleng + 1
454	<< ": " << SemanticError::error_str() << errmsg << " at token \"" << (yytext[0] == '\0' ? "EOF" : yytext) << '"' << endl;
455	}
456
457	// Local Variables: //
458	// mode: c++ //
459	// tab-width: 4 //
460	// compile-command: "make install" //
461	// End: //

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format