source: src/Parser/lex.ll@ 3c1e432

Last change on this file since 3c1e432 was 98a5ee7, checked in by Peter A. Buhr <pabuhr@…>, 8 months ago

temporary fix for ARM vector types
  • Property mode set to 100644
File size: 22.1 KB
Line 
1/*
2 * Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3 *
4 * The contents of this file are covered under the licence agreement in the
5 * file "LICENCE" distributed with Cforall.
6 *
7 * lex.ll --
8 *
9 * Author : Peter A. Buhr
10 * Created On : Sat Sep 22 08:58:10 2001
11 * Last Modified By : Peter A. Buhr
12 * Last Modified On : Mon Mar 3 09:21:33 2025
13 * Update Count : 880
14 */
15
16%option yylineno
17%option noyywrap
18%option nounput
19
20%{
21// The lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
22// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
23// line-number directives) and C/C++ style comments, which are ignored.
24
25// *************************** Includes and Defines ****************************
26
27#ifdef __clang__
28#pragma GCC diagnostic ignored "-Wnull-conversion"
29#endif
30
31// trigger before each matching rule's action
32#define YY_USER_ACTION \
33 yylloc.first_line = yylineno; \
34 yylloc.first_column = column; \
35 column += yyleng; \
36 yylloc.last_column = column; \
37 yylloc.last_line = yylineno; \
38 yylloc.filename = yyfilename ? yyfilename : "";
39unsigned int column = 0; // position of the end of the last token parsed
40
41#include <string>
42#include <cstdio> // FILENAME_MAX
43using namespace std;
44
45#include "config.h" // configure info
46#include "DeclarationNode.hpp" // for DeclarationNode
47#include "ExpressionNode.hpp" // for LabelNode
48#include "InitializerNode.hpp" // for InitializerNode
49#include "ParseNode.hpp"
50#include "ParserTypes.hpp" // for Token
51#include "StatementNode.hpp" // for CondCtrl, ForCtrl
52#include "TypedefTable.hpp"
53// This (generated) header must come late as it is missing includes.
54#include "parser.hh" // generated info
55
56string * build_postfix_name( string * name );
57
58char *yyfilename;
59string *strtext; // accumulate parts of character and string constant value
60
61#define RETURN_LOCN(x) yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
62#define RETURN_VAL(x) yylval.tok.str = new string( yytext ); RETURN_LOCN( x )
63#define RETURN_CHAR(x) yylval.tok.str = nullptr; RETURN_LOCN( x )
64#define RETURN_STR(x) yylval.tok.str = strtext; RETURN_LOCN( x )
65
66#define WHITE_RETURN(x) // do nothing
67#define NEWLINE_RETURN() column = 0; WHITE_RETURN( '\n' )
68#define ASCIIOP_RETURN() RETURN_CHAR( (int)yytext[0] ) // single character operator
69#define NAMEDOP_RETURN(x) RETURN_CHAR( x ) // multichar operator, with a name
70#define NUMERIC_RETURN(x) rm_underscore(); RETURN_VAL( x ) // numeric constant
71#define KEYWORD_RETURN(x) RETURN_CHAR( x ) // keyword
72#define QKEYWORD_RETURN(x) RETURN_VAL(x); // quasi-keyword
73#define IDENTIFIER_RETURN() RETURN_VAL( typedefTable.isKind( yytext ) )
74
75#ifdef HAVE_KEYWORDS_FLOATXX // GCC >= 7 => keyword, otherwise typedef
76#define FLOATXX(v) KEYWORD_RETURN(v);
77#else
78#define FLOATXX(v) IDENTIFIER_RETURN();
79#endif // HAVE_KEYWORDS_FLOATXX
80
81void rm_underscore() {
82 // SKULLDUGGERY: remove underscores (ok to shorten?)
83 yyleng = 0;
84 for ( int i = 0; yytext[i] != '\0'; i += 1 ) { // copying non-underscore characters to front of string
85 if ( yytext[i] != '_' ) {
86 yytext[yyleng] = yytext[i];
87 yyleng += 1;
88 } // if
89 } // for
90 yytext[yyleng] = '\0';
91} // rm_underscore
92
93// Stop warning due to incorrectly generated flex code.
94#pragma GCC diagnostic ignored "-Wsign-compare"
95%}
96
97binary [0-1]
98octal [0-7]
99nonzero [1-9]
100decimal [0-9]
101hex [0-9a-fA-F]
102universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2}))
103
104 // identifier, GCC: $ in identifier
105identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})*
106
107 // numeric constants, CFA: '_' in constant
108hex_quad {hex}("_"?{hex}){3}
109size_opt (8|16|32|64|128)?
110 // CFA: explicit l8/l16/l32/l64/l128, char 'hh', short 'h', int 'n'
111length ("ll"|"LL"|[lL]{size_opt})|("hh"|"HH"|[hHnN])
112 // CFA: size_t 'z', pointer 'p', which define a sign and length
113integer_suffix_opt ("_"?(([uU]({length}?[iI]?)|([iI]{length}))|([iI]({length}?[uU]?)|([uU]{length}))|({length}([iI]?[uU]?)|([uU][iI]))|[zZ]|[pP]))?
114
115octal_digits ({octal})|({octal}({octal}|"_")*{octal})
116octal_prefix "0""_"?
117octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix_opt}
118
119nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal})
120decimal_constant {nonzero_digits}{integer_suffix_opt}
121
122binary_digits ({binary})|({binary}({binary}|"_")*{binary})
123binary_prefix "0"[bB]"_"?
124binary_constant {binary_prefix}{binary_digits}{integer_suffix_opt}
125
126hex_digits ({hex})|({hex}({hex}|"_")*{hex})
127hex_prefix "0"[xX]"_"?
128hex_constant {hex_prefix}{hex_digits}{integer_suffix_opt}
129
130 // GCC: floating D (double), imaginary iI, and decimal floating DF, DD, DL
131exponent "_"?[eE]"_"?[+-]?{decimal_digits}
132floating_size 16|32|32x|64|64x|80|128|128x
133floating_length ([fFdDlLwWqQ]|[fF]{floating_size})
134floating_suffix ({floating_length}?[iI]?)|([iI]{floating_length})
135decimal_floating_suffix [dD][fFdDlL]
136floating_suffix_opt ("_"?({floating_suffix}|{decimal_floating_suffix}))?
137decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal})
138floating_decimal {decimal_digits}"."{exponent}?{floating_suffix_opt}
139floating_fraction "."{decimal_digits}{exponent}?{floating_suffix_opt}
140floating_constant ({decimal_digits}{exponent}{floating_suffix_opt})|({decimal_digits}{floating_fraction})
141
142binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
143hex_floating_suffix_opt ("_"?({floating_suffix}))?
144hex_floating_fraction ({hex_digits}?"."{hex_digits})|({hex_digits}".")
145hex_floating_constant {hex_prefix}(({hex_floating_fraction}{binary_exponent})|({hex_digits}{binary_exponent})){hex_floating_suffix_opt}
146
147 // character escape sequence, GCC: \e => esc character
148simple_escape "\\"[abefnrtv'"?\\]
149 // " stop editor highlighting
150octal_escape "\\"{octal}("_"?{octal}){0,2}
151hex_escape "\\""x""_"?{hex_digits}
152escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char}
153cwide_prefix "L"|"U"|"u"
154swide_prefix {cwide_prefix}|"u8"
155
156 // display/white-space characters
157h_tab "\t"
158form_feed "\f"
159v_tab "\v"
160new_line "\n"
161c_return "\r"
162h_white " "|{h_tab}
163v_white {v_tab}|{c_return}|{form_feed}
164hv_white {h_white}|{v_tab}|{new_line}|{c_return}|{form_feed}
165
166 // overloadable operators
167op_unary_only "~"|"!"
168op_unary_binary "+"|"-"|"*"
169op_unary_pre_post "++"|"--"
170op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post}
171
172op_binary_only "/"|"%"|"\\"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"\\="|"&="|"|="|"^="|"<<="|">>="
173op_binary_over {op_unary_binary}|{op_binary_only}
174 // op_binary_not_over "?"|"->"|"."|"&&"|"||"|"@="
175 // operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over}
176
177 // C23 attributes, CPP also handles missing quote delimiter
178attr_string "\""([^\"\\\n]|{escape_seq})*["\n]
179attr_arg_opt ({hv_white}*"("({hv_white}*{attr_string}{hv_white}*)+")")?
180attributes "deprecated"{attr_arg_opt}|"fallthrough"|"nodiscard"{attr_arg_opt}|"maybe_unused"|"noreturn"|"_Noreturn"|"unsequenced"|"unused"|"reproducible"|{identifier}{hv_white}*"::"{hv_white}*{identifier}
181
182%x COMMENT
183%x QUOTE
184%x STRING
185
186%%
187 /* line directives */
188^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["].*"\n" {
189 /* " stop editor highlighting */
190 static char filename[FILENAME_MAX]; // temporarily store current source-file name
191 char *end_num;
192 char *begin_string, *end_string;
193 long lineno, length;
194 lineno = strtol( yytext + 1, &end_num, 0 );
195 begin_string = strchr( end_num, '"' );
196 if ( begin_string ) { // file name ?
197 end_string = strchr( begin_string + 1, '"' ); // look for ending delimiter
198 assert( end_string ); // closing quote ?
199 length = end_string - begin_string - 1; // file-name length without quotes or sentinel
200 assert( length < FILENAME_MAX ); // room for sentinel ?
201 memcpy( &filename, begin_string + 1, length ); // copy file name from yytext
202 filename[ length ] = '\0'; // terminate string with sentinel
203 //cout << "file " << filename << " line " << lineno << endl;
204 yylineno = lineno;
205 yyfilename = filename;
206 } // if
207}
208
209 /* preprocessor-style directives */
210^{h_white}*"#"[^\n]*"\n" { RETURN_VAL( DIRECTIVE ); }
211
212 /* ignore C style comments (ALSO HANDLED BY CPP) */
213"/*" { BEGIN COMMENT; }
214<COMMENT>.|\n ;
215<COMMENT>"*/" { BEGIN 0; }
216
217 /* ignore C++ style comments (ALSO HANDLED BY CPP) */
218"//"[^\n]*"\n" ;
219
220 /* ignore whitespace */
221({h_white}|{v_white})+ { WHITE_RETURN(' '); } // do nothing
222"\n" { NEWLINE_RETURN(); } // reset column counter
223
224 /* keywords */
225alignas { KEYWORD_RETURN(ALIGNAS); } // CFA
226_Alignas { KEYWORD_RETURN(ALIGNAS); } // C11
227alignof { KEYWORD_RETURN(ALIGNOF); } // CFA
228_Alignof { KEYWORD_RETURN(ALIGNOF); } // C11
229__alignof { KEYWORD_RETURN(ALIGNOF); } // GCC
230__alignof__ { KEYWORD_RETURN(ALIGNOF); } // GCC
231and { QKEYWORD_RETURN(WAND); } // CFA
232asm { KEYWORD_RETURN(ASM); }
233__asm { KEYWORD_RETURN(ASM); } // GCC
234__asm__ { KEYWORD_RETURN(ASM); } // GCC
235_Atomic { KEYWORD_RETURN(ATOMIC); } // C11
236__attribute { KEYWORD_RETURN(ATTRIBUTE); } // GCC
237__attribute__ { KEYWORD_RETURN(ATTRIBUTE); } // GCC
238auto { KEYWORD_RETURN(AUTO); }
239__auto_type { KEYWORD_RETURN(AUTO_TYPE); }
240basetypeof { KEYWORD_RETURN(BASETYPEOF); } // CFA
241_Bool { KEYWORD_RETURN(BOOL); } // C99
242__SVBool_t { KEYWORD_RETURN(BOOL); } // gcc (ARM)
243break { KEYWORD_RETURN(BREAK); }
244case { KEYWORD_RETURN(CASE); }
245catch { QKEYWORD_RETURN(CATCH); } // CFA
246catchResume { QKEYWORD_RETURN(CATCHRESUME); } // CFA
247char { KEYWORD_RETURN(CHAR); }
248choose { KEYWORD_RETURN(CHOOSE); } // CFA
249coerce { KEYWORD_RETURN(COERCE); } // CFA
250corun { KEYWORD_RETURN(CORUN); } // CFA
251cofor { KEYWORD_RETURN(COFOR); } // CFA
252_Complex { KEYWORD_RETURN(COMPLEX); } // C99
253__complex { KEYWORD_RETURN(COMPLEX); } // GCC
254__complex__ { KEYWORD_RETURN(COMPLEX); } // GCC
255const { KEYWORD_RETURN(CONST); }
256__const { KEYWORD_RETURN(CONST); } // GCC
257__const__ { KEYWORD_RETURN(CONST); } // GCC
258continue { KEYWORD_RETURN(CONTINUE); }
259coroutine { KEYWORD_RETURN(COROUTINE); } // CFA
260_Decimal32 { KEYWORD_RETURN(DECIMAL32); } // GCC
261_Decimal64 { KEYWORD_RETURN(DECIMAL64); } // GCC
262_Decimal128 { KEYWORD_RETURN(DECIMAL128); } // GCC
263default { KEYWORD_RETURN(DEFAULT); }
264disable { KEYWORD_RETURN(DISABLE); } // CFA
265do { KEYWORD_RETURN(DO); }
266double { KEYWORD_RETURN(DOUBLE); }
267dtype { KEYWORD_RETURN(DTYPE); } // CFA
268else { KEYWORD_RETURN(ELSE); }
269enable { KEYWORD_RETURN(ENABLE); } // CFA
270enum { KEYWORD_RETURN(ENUM); }
271exception { KEYWORD_RETURN(EXCEPTION); } // CFA
272__extension__ { KEYWORD_RETURN(EXTENSION); } // GCC
273extern { KEYWORD_RETURN(EXTERN); }
274fallthrough { KEYWORD_RETURN(FALLTHROUGH); } // CFA
275finally { QKEYWORD_RETURN(FINALLY); } // CFA
276fixup { QKEYWORD_RETURN(FIXUP); } // CFA
277float { KEYWORD_RETURN(FLOAT); }
278__float80 { KEYWORD_RETURN(FLOAT80); } // GCC
279float80 { KEYWORD_RETURN(FLOAT80); } // GCC
280__float128 { KEYWORD_RETURN(uuFLOAT128); } // GCC
281float128 { KEYWORD_RETURN(uuFLOAT128); } // GCC
282_Float16 { FLOATXX(FLOAT16); } // GCC
283_Float32 { FLOATXX(FLOAT32); } // GCC
284_Float32x { FLOATXX(FLOAT32X); } // GCC
285_Float64 { FLOATXX(FLOAT64); } // GCC
286_Float64x { FLOATXX(FLOAT64X); } // GCC
287_Float128 { FLOATXX(FLOAT128); } // GCC
288_Float128x { FLOATXX(FLOAT128X); } // GCC
289__Float32x4_t { FLOATXX(FLOAT128); } // GCC (ARM)
290__Float64x2_t { FLOATXX(FLOAT128); } // GCC (ARM)
291__SVFloat32_t { FLOATXX(FLOAT128); } // GCC (ARM)
292__SVFloat64_t { FLOATXX(FLOAT128); } // GCC (ARM)
293for { KEYWORD_RETURN(FOR); }
294forall { KEYWORD_RETURN(FORALL); } // CFA
295fortran { KEYWORD_RETURN(FORTRAN); }
296ftype { KEYWORD_RETURN(FTYPE); } // CFA
297generator { KEYWORD_RETURN(GENERATOR); } // CFA
298_Generic { KEYWORD_RETURN(GENERIC); } // C11
299goto { KEYWORD_RETURN(GOTO); }
300if { KEYWORD_RETURN(IF); }
301_Imaginary { KEYWORD_RETURN(IMAGINARY); } // C99
302__imag { KEYWORD_RETURN(IMAGINARY); } // GCC
303__imag__ { KEYWORD_RETURN(IMAGINARY); } // GCC
304inline { KEYWORD_RETURN(INLINE); } // C99
305__inline { KEYWORD_RETURN(INLINE); } // GCC
306__inline__ { KEYWORD_RETURN(INLINE); } // GCC
307int { KEYWORD_RETURN(INT); }
308int128 { KEYWORD_RETURN(INT128); } // CFA
309__int128 { KEYWORD_RETURN(INT128); } // GCC
310__int128_t { KEYWORD_RETURN(INT128); } // GCC
311__label__ { KEYWORD_RETURN(LABEL); } // GCC
312long { KEYWORD_RETURN(LONG); }
313monitor { KEYWORD_RETURN(MONITOR); } // CFA
314mutex { KEYWORD_RETURN(MUTEX); } // CFA
315_Noreturn { KEYWORD_RETURN(NORETURN); } // C11
316__builtin_offsetof { KEYWORD_RETURN(OFFSETOF); } // GCC
317one_t { NUMERIC_RETURN(ONE_T); } // CFA
318or { QKEYWORD_RETURN(WOR); } // CFA
319otype { KEYWORD_RETURN(OTYPE); } // CFA
320recover { QKEYWORD_RETURN(RECOVER); } // CFA
321register { KEYWORD_RETURN(REGISTER); }
322report { KEYWORD_RETURN(THROWRESUME); } // CFA
323restrict { KEYWORD_RETURN(RESTRICT); } // C99
324__restrict { KEYWORD_RETURN(RESTRICT); } // GCC
325__restrict__ { KEYWORD_RETURN(RESTRICT); } // GCC
326return { KEYWORD_RETURN(RETURN); }
327 /* resume { KEYWORD_RETURN(RESUME); } // CFA */
328short { KEYWORD_RETURN(SHORT); }
329signed { KEYWORD_RETURN(SIGNED); }
330__signed { KEYWORD_RETURN(SIGNED); } // GCC
331__signed__ { KEYWORD_RETURN(SIGNED); } // GCC
332sizeof { KEYWORD_RETURN(SIZEOF); }
333countof { KEYWORD_RETURN(COUNTOF); } // GCC
334static { KEYWORD_RETURN(STATIC); }
335_Static_assert { KEYWORD_RETURN(STATICASSERT); } // C11
336static_assert { KEYWORD_RETURN(STATICASSERT); } // C23
337struct { KEYWORD_RETURN(STRUCT); }
338suspend { KEYWORD_RETURN(SUSPEND); } // CFA
339switch { KEYWORD_RETURN(SWITCH); }
340thread { KEYWORD_RETURN(THREAD); } // C11
341__thread { KEYWORD_RETURN(THREADLOCALGCC); } // GCC
342_Thread_local { KEYWORD_RETURN(THREADLOCALC11); } // C11
343thread_local { KEYWORD_RETURN(THREADLOCALC11); } // C23
344throw { KEYWORD_RETURN(THROW); } // CFA
345throwResume { KEYWORD_RETURN(THROWRESUME); } // CFA
346timeout { QKEYWORD_RETURN(TIMEOUT); } // CFA
347trait { KEYWORD_RETURN(TRAIT); } // CFA
348try { KEYWORD_RETURN(TRY); } // CFA
349ttype { KEYWORD_RETURN(TTYPE); } // CFA
350typedef { KEYWORD_RETURN(TYPEDEF); }
351typeof { KEYWORD_RETURN(TYPEOF); } // GCC
352__typeof { KEYWORD_RETURN(TYPEOF); } // GCC
353__typeof__ { KEYWORD_RETURN(TYPEOF); } // GCC
354typeid { KEYWORD_RETURN(TYPEID); } // GCC
355union { KEYWORD_RETURN(UNION); }
356__uint128_t { KEYWORD_RETURN(UINT128); } // GCC
357unsigned { KEYWORD_RETURN(UNSIGNED); }
358__builtin_va_arg { KEYWORD_RETURN(VA_ARG); } // GCC
359__builtin_va_list { KEYWORD_RETURN(VA_LIST); } // GCC
360virtual { KEYWORD_RETURN(VIRTUAL); } // CFA
361void { KEYWORD_RETURN(VOID); }
362volatile { KEYWORD_RETURN(VOLATILE); }
363__volatile { KEYWORD_RETURN(VOLATILE); } // GCC
364__volatile__ { KEYWORD_RETURN(VOLATILE); } // GCC
365vtable { KEYWORD_RETURN(VTABLE); } // CFA
366waitfor { KEYWORD_RETURN(WAITFOR); } // CFA
367waituntil { KEYWORD_RETURN(WAITUNTIL); } // CFA
368when { KEYWORD_RETURN(WHEN); } // CFA
369while { KEYWORD_RETURN(WHILE); }
370with { KEYWORD_RETURN(WITH); } // CFA
371zero_t { NUMERIC_RETURN(ZERO_T); } // CFA
372
373 /* identifier */
374{identifier} { IDENTIFIER_RETURN(); }
375"``"{identifier} { // CFA
376 yytext[yyleng] = '\0'; yytext += 2; // SKULLDUGGERY: remove backquotes (ok to shorten?)
377 IDENTIFIER_RETURN();
378}
379
380 /* C23 attributes */
381"[["{hv_white}*{attributes}({hv_white}*","{hv_white}*{attributes})*{hv_white}*"]]" {
382 strtext = new string( &yytext[2], yyleng - 4 ); // remove delimiters "[[" and "]]"
383 RETURN_STR(C23_ATTRIBUTE);
384}
385
386 /* numeric constants */
387{binary_constant} { NUMERIC_RETURN(INTEGERconstant); }
388{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
389{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
390{hex_constant} { NUMERIC_RETURN(INTEGERconstant); }
391{floating_decimal} { NUMERIC_RETURN(FLOATING_DECIMALconstant); } // must appear before floating_constant
392{floating_fraction} { NUMERIC_RETURN(FLOATING_FRACTIONconstant); } // must appear before floating_constant
393{floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
394{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
395
396 /* character constant, allows empty value, CPP also handles missing quote delimiter */
397({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new string( yytext, yyleng ); }
398<QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); }
399<QUOTE>['\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); }
400 /* ' stop editor highlighting */
401
402 /* string constant, CPP also handles missing quote delimiter */
403({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new string( yytext, yyleng ); }
404<STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); }
405<STRING>["\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); }
406 /* " stop editor highlighting */
407
408 /* common character/string constant */
409<QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); }
410<QUOTE,STRING>"\\"{h_white}*"\n" {} // continuation (ALSO HANDLED BY CPP)
411<QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character
412
413 /* punctuation */
414"@" { ASCIIOP_RETURN(); }
415"`" { ASCIIOP_RETURN(); }
416"[" { ASCIIOP_RETURN(); }
417"]" { ASCIIOP_RETURN(); }
418"(" { ASCIIOP_RETURN(); }
419")" { ASCIIOP_RETURN(); }
420"{" { ASCIIOP_RETURN(); }
421"}" { ASCIIOP_RETURN(); }
422"," { ASCIIOP_RETURN(); } // also operator
423":" { ASCIIOP_RETURN(); }
424";" { ASCIIOP_RETURN(); }
425"." { ASCIIOP_RETURN(); } // also operator
426"@[" { NAMEDOP_RETURN(ATTR); } // CFA, attribute shorthand
427"..." { NAMEDOP_RETURN(ELLIPSIS); }
428
429 /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
430"<:" { RETURN_VAL('['); }
431":>" { RETURN_VAL(']'); }
432"<%" { RETURN_VAL('{'); }
433"%>" { RETURN_VAL('}'); }
434
435 /* operators */
436"!" { ASCIIOP_RETURN(); }
437"+" { ASCIIOP_RETURN(); }
438"-" { ASCIIOP_RETURN(); }
439"*" { ASCIIOP_RETURN(); }
440"\\" { ASCIIOP_RETURN(); } // CFA, exponentiation
441"/" { ASCIIOP_RETURN(); }
442"%" { ASCIIOP_RETURN(); }
443"^" { ASCIIOP_RETURN(); }
444"~" { ASCIIOP_RETURN(); }
445"&" { ASCIIOP_RETURN(); }
446"|" { ASCIIOP_RETURN(); }
447"<" { ASCIIOP_RETURN(); }
448">" { ASCIIOP_RETURN(); }
449"=" { ASCIIOP_RETURN(); }
450"?" { ASCIIOP_RETURN(); }
451
452"++" { NAMEDOP_RETURN(ICR); }
453"--" { NAMEDOP_RETURN(DECR); }
454"==" { NAMEDOP_RETURN(EQ); }
455"!=" { NAMEDOP_RETURN(NE); }
456"<<" { NAMEDOP_RETURN(LS); }
457">>" { NAMEDOP_RETURN(RS); }
458"<=" { NAMEDOP_RETURN(LE); }
459">=" { NAMEDOP_RETURN(GE); }
460"&&" { NAMEDOP_RETURN(ANDAND); }
461"||" { NAMEDOP_RETURN(OROR); }
462"->" { NAMEDOP_RETURN(ARROW); }
463"+=" { NAMEDOP_RETURN(PLUSassign); }
464"-=" { NAMEDOP_RETURN(MINUSassign); }
465"\\=" { NAMEDOP_RETURN(EXPassign); } // CFA, exponentiation
466"*=" { NAMEDOP_RETURN(MULTassign); }
467"/=" { NAMEDOP_RETURN(DIVassign); }
468"%=" { NAMEDOP_RETURN(MODassign); }
469"&=" { NAMEDOP_RETURN(ANDassign); }
470"|=" { NAMEDOP_RETURN(ORassign); }
471"^=" { NAMEDOP_RETURN(ERassign); }
472"<<=" { NAMEDOP_RETURN(LSassign); }
473">>=" { NAMEDOP_RETURN(RSassign); }
474
475"@=" { NAMEDOP_RETURN(ATassign); } // CFA
476"+~" { NAMEDOP_RETURN(ErangeUp); } // CFA
477"~=" { NAMEDOP_RETURN(ErangeUpEq); } // CFA
478"+~=" { NAMEDOP_RETURN(ErangeUpEq); } // CFA
479"-~" { NAMEDOP_RETURN(ErangeDown); } // CFA
480"-~=" { NAMEDOP_RETURN(ErangeDownEq); } // CFA
481
482 /* CFA, operator identifier */
483{op_unary}"?" { IDENTIFIER_RETURN(); } // unary
484"?"({op_unary_pre_post}|"()"|"[?]"|"{}") { IDENTIFIER_RETURN(); }
485"^?{}" { IDENTIFIER_RETURN(); }
486"?`"{identifier} { // postfix operator
487 yylval.tok.str = new string( &yytext[2] ); // remove ?`
488 yylval.tok.str = build_postfix_name( yylval.tok.str ); // add prefix
489 RETURN_LOCN( typedefTable.isKind( *yylval.tok.str ) );
490}
491"?"{op_binary_over}"?" { IDENTIFIER_RETURN(); } // binary
492 /*
493 This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the string "*?*?" can be
494 lexed as "*?"/"*?" or "*"/"?*?". Since it is common practise to put a unary operator juxtaposed to an identifier,
495 e.g., "*i", users will be annoyed if they cannot do this with respect to operator identifiers. Therefore, there is
496 a lexical look-ahead for the second case, with backtracking to return the leading unary operator and then
497 reparsing the trailing operator identifier. Otherwise a space is needed between the unary operator and operator
498 identifier to disambiguate this common case.
499
500 A similar issue occurs with the dereference, *?(...), and routine-call, ?()(...) identifiers. The ambiguity
501 occurs when the deference operator has no parameters, *?() and *?()(...), requiring arbitrary whitespace
502 look-ahead for the routine-call parameter-list to disambiguate. However, the dereference operator must have a
503 parameter/argument to dereference *?(...). Hence, always interpreting the string *?() as * ?() does not preclude
504 any meaningful program.
505
506 The remaining cases are with the increment/decrement operators and conditional expression:
507
508 i++? ...(...);
509 i?++ ...(...);
510
511 requiring arbitrary whitespace look-ahead for the operator parameter-list, even though that interpretation is an
512 incorrect expression (juxtaposed identifiers). Therefore, it is necessary to disambiguate these cases with a
513 space:
514
515 i++ ? i : 0;
516 i? ++i : 0;
517 */
518{op_unary}"?"({op_unary_pre_post}|"()"|"[?]"|{op_binary_over}"?") {
519 // 1 or 2 character unary operator ?
520 int i = yytext[1] == '?' ? 1 : 2;
521 yyless( i ); // put back characters up to first '?'
522 if ( i > 1 ) {
523 NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
524 } else {
525 ASCIIOP_RETURN();
526 } // if
527}
528
529 /* unknown character */
530. { yyerror( "unknown character" ); }
531
532%%
533
534// ----end of lexer----
535
536void yyerror( const char * errmsg ) {
537 SemanticErrorThrow = true;
538 cerr << (yyfilename ? yyfilename : "*unknown file*") << ':' << yylineno << ':' << column - yyleng + 1
539 << ": " << ErrorHelpers::error_str() << errmsg << " before token \"" << (yytext[0] == '\0' ? "EOF" : yytext) << '"' << endl;
540}
541
542// Local Variables: //
543// mode: c++ //
544// tab-width: 4 //
545// compile-command: "make install" //
546// End: //
Note: See TracBrowser for help on using the repository browser.