source: src/Parser/lex.ll@ 1a8b17a

Last change on this file since 1a8b17a was 1a8b17a, checked in by Peter A. Buhr <pabuhr@…>, 14 months ago

add C23 attributes, require comma terminator for nullary and unary tuple (optional terminator for Nary tuples), change designator to C syntax using equal rather than colon
  • Property mode set to 100644
File size: 22.0 KB
Line 
1/*
2 * Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3 *
4 * The contents of this file are covered under the licence agreement in the
5 * file "LICENCE" distributed with Cforall.
6 *
7 * lex.ll --
8 *
9 * Author : Peter A. Buhr
10 * Created On : Sat Sep 22 08:58:10 2001
11 * Last Modified By : Peter A. Buhr
12 * Last Modified On : Sun Oct 13 10:03:28 2024
13 * Update Count : 869
14 */
15
16%option yylineno
17%option noyywrap
18%option nounput
19
20%{
21// The lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
22// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
23// line-number directives) and C/C++ style comments, which are ignored.
24
25// *************************** Includes and Defines ****************************
26
27#ifdef __clang__
28#pragma GCC diagnostic ignored "-Wnull-conversion"
29#endif
30
31// trigger before each matching rule's action
32#define YY_USER_ACTION \
33 yylloc.first_line = yylineno; \
34 yylloc.first_column = column; \
35 column += yyleng; \
36 yylloc.last_column = column; \
37 yylloc.last_line = yylineno; \
38 yylloc.filename = yyfilename ? yyfilename : "";
39unsigned int column = 0; // position of the end of the last token parsed
40
41#include <string>
42#include <cstdio> // FILENAME_MAX
43using namespace std;
44
45#include "config.h" // configure info
46#include "DeclarationNode.hpp" // for DeclarationNode
47#include "ExpressionNode.hpp" // for LabelNode
48#include "InitializerNode.hpp" // for InitializerNode
49#include "ParseNode.hpp"
50#include "ParserTypes.hpp" // for Token
51#include "StatementNode.hpp" // for CondCtrl, ForCtrl
52#include "TypedefTable.hpp"
53// This (generated) header must come late as it is missing includes.
54#include "parser.hh" // generated info
55
56string * build_postfix_name( string * name );
57
58char *yyfilename;
59string *strtext; // accumulate parts of character and string constant value
60
61#define RETURN_LOCN(x) yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
62#define RETURN_VAL(x) yylval.tok.str = new string( yytext ); RETURN_LOCN( x )
63#define RETURN_CHAR(x) yylval.tok.str = nullptr; RETURN_LOCN( x )
64#define RETURN_STR(x) yylval.tok.str = strtext; RETURN_LOCN( x )
65
66#define WHITE_RETURN(x) // do nothing
67#define NEWLINE_RETURN() column = 0; WHITE_RETURN( '\n' )
68#define ASCIIOP_RETURN() RETURN_CHAR( (int)yytext[0] ) // single character operator
69#define NAMEDOP_RETURN(x) RETURN_CHAR( x ) // multichar operator, with a name
70#define NUMERIC_RETURN(x) rm_underscore(); RETURN_VAL( x ) // numeric constant
71#define KEYWORD_RETURN(x) RETURN_CHAR( x ) // keyword
72#define QKEYWORD_RETURN(x) RETURN_VAL(x); // quasi-keyword
73#define IDENTIFIER_RETURN() RETURN_VAL( typedefTable.isKind( yytext ) )
74
75#ifdef HAVE_KEYWORDS_FLOATXX // GCC >= 7 => keyword, otherwise typedef
76#define FLOATXX(v) KEYWORD_RETURN(v);
77#else
78#define FLOATXX(v) IDENTIFIER_RETURN();
79#endif // HAVE_KEYWORDS_FLOATXX
80
81void rm_underscore() {
82 // SKULLDUGGERY: remove underscores (ok to shorten?)
83 yyleng = 0;
84 for ( int i = 0; yytext[i] != '\0'; i += 1 ) { // copying non-underscore characters to front of string
85 if ( yytext[i] != '_' ) {
86 yytext[yyleng] = yytext[i];
87 yyleng += 1;
88 } // if
89 } // for
90 yytext[yyleng] = '\0';
91} // rm_underscore
92
93// Stop warning due to incorrectly generated flex code.
94#pragma GCC diagnostic ignored "-Wsign-compare"
95%}
96
97binary [0-1]
98octal [0-7]
99nonzero [1-9]
100decimal [0-9]
101hex [0-9a-fA-F]
102universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2}))
103
104 // identifier, GCC: $ in identifier
105identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})*
106
107 // numeric constants, CFA: '_' in constant
108hex_quad {hex}("_"?{hex}){3}
109size_opt (8|16|32|64|128)?
110 // CFA: explicit l8/l16/l32/l64/l128, char 'hh', short 'h', int 'n'
111length ("ll"|"LL"|[lL]{size_opt})|("hh"|"HH"|[hHnN])
112 // CFA: size_t 'z', pointer 'p', which define a sign and length
113integer_suffix_opt ("_"?(([uU]({length}?[iI]?)|([iI]{length}))|([iI]({length}?[uU]?)|([uU]{length}))|({length}([iI]?[uU]?)|([uU][iI]))|[zZ]|[pP]))?
114
115octal_digits ({octal})|({octal}({octal}|"_")*{octal})
116octal_prefix "0""_"?
117octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix_opt}
118
119nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal})
120decimal_constant {nonzero_digits}{integer_suffix_opt}
121
122binary_digits ({binary})|({binary}({binary}|"_")*{binary})
123binary_prefix "0"[bB]"_"?
124binary_constant {binary_prefix}{binary_digits}{integer_suffix_opt}
125
126hex_digits ({hex})|({hex}({hex}|"_")*{hex})
127hex_prefix "0"[xX]"_"?
128hex_constant {hex_prefix}{hex_digits}{integer_suffix_opt}
129
130 // GCC: floating D (double), imaginary iI, and decimal floating DF, DD, DL
131exponent "_"?[eE]"_"?[+-]?{decimal_digits}
132floating_size 16|32|32x|64|64x|80|128|128x
133floating_length ([fFdDlLwWqQ]|[fF]{floating_size})
134floating_suffix ({floating_length}?[iI]?)|([iI]{floating_length})
135decimal_floating_suffix [dD][fFdDlL]
136floating_suffix_opt ("_"?({floating_suffix}|{decimal_floating_suffix}))?
137decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal})
138floating_decimal {decimal_digits}"."{exponent}?{floating_suffix_opt}
139floating_fraction "."{decimal_digits}{exponent}?{floating_suffix_opt}
140floating_constant ({decimal_digits}{exponent}{floating_suffix_opt})|({decimal_digits}{floating_fraction})
141
142binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
143hex_floating_suffix_opt ("_"?({floating_suffix}))?
144hex_floating_fraction ({hex_digits}?"."{hex_digits})|({hex_digits}".")
145hex_floating_constant {hex_prefix}(({hex_floating_fraction}{binary_exponent})|({hex_digits}{binary_exponent})){hex_floating_suffix_opt}
146
147 // character escape sequence, GCC: \e => esc character
148simple_escape "\\"[abefnrtv'"?\\]
149 // " stop editor highlighting
150octal_escape "\\"{octal}("_"?{octal}){0,2}
151hex_escape "\\""x""_"?{hex_digits}
152escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char}
153cwide_prefix "L"|"U"|"u"
154swide_prefix {cwide_prefix}|"u8"
155
156 // display/white-space characters
157h_tab "\t"
158form_feed "\f"
159v_tab "\v"
160new_line "\n"
161c_return "\r"
162h_white " "|{h_tab}
163v_white {v_tab}|{c_return}|{form_feed}
164hv_white {h_white}|{v_tab}|{new_line}|{c_return}|{form_feed}
165
166 // overloadable operators
167op_unary_only "~"|"!"
168op_unary_binary "+"|"-"|"*"
169op_unary_pre_post "++"|"--"
170op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post}
171
172op_binary_only "/"|"%"|"\\"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"\\="|"&="|"|="|"^="|"<<="|">>="
173op_binary_over {op_unary_binary}|{op_binary_only}
174 // op_binary_not_over "?"|"->"|"."|"&&"|"||"|"@="
175 // operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over}
176
177 // C23 attributes
178attr_string "\""[^\"]*"\""
179attr_arg_opt ({hv_white}*"("{hv_white}*{attr_string}{hv_white}*")")?
180attributes "deprecated"{attr_arg_opt}|"fallthrough"|"nodiscard"{attr_arg_opt}|"maybe_unused"|"noreturn"|"_Noreturn"|"unsequenced"|"unused"|"reproducible"|{identifier}{hv_white}*"::"{hv_white}*{identifier}
181
182%x COMMENT
183%x BKQUOTE
184%x QUOTE
185%x STRING
186
187%%
188 /* line directives */
189^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["].*"\n" {
190 /* " stop editor highlighting */
191 static char filename[FILENAME_MAX]; // temporarily store current source-file name
192 char *end_num;
193 char *begin_string, *end_string;
194 long lineno, length;
195 lineno = strtol( yytext + 1, &end_num, 0 );
196 begin_string = strchr( end_num, '"' );
197 if ( begin_string ) { // file name ?
198 end_string = strchr( begin_string + 1, '"' ); // look for ending delimiter
199 assert( end_string ); // closing quote ?
200 length = end_string - begin_string - 1; // file-name length without quotes or sentinel
201 assert( length < FILENAME_MAX ); // room for sentinel ?
202 memcpy( &filename, begin_string + 1, length ); // copy file name from yytext
203 filename[ length ] = '\0'; // terminate string with sentinel
204 //cout << "file " << filename << " line " << lineno << endl;
205 yylineno = lineno;
206 yyfilename = filename;
207 } // if
208}
209
210 /* preprocessor-style directives */
211^{h_white}*"#"[^\n]*"\n" { RETURN_VAL( DIRECTIVE ); }
212
213 /* ignore C style comments (ALSO HANDLED BY CPP) */
214"/*" { BEGIN COMMENT; }
215<COMMENT>.|\n ;
216<COMMENT>"*/" { BEGIN 0; }
217
218 /* ignore C++ style comments (ALSO HANDLED BY CPP) */
219"//"[^\n]*"\n" ;
220
221 /* ignore whitespace */
222({h_white}|{v_white})+ { WHITE_RETURN(' '); } // do nothing
223"\n" { NEWLINE_RETURN(); } // reset column counter
224
225 /* keywords */
226alignas { KEYWORD_RETURN(ALIGNAS); } // CFA
227_Alignas { KEYWORD_RETURN(ALIGNAS); } // C11
228alignof { KEYWORD_RETURN(ALIGNOF); } // CFA
229_Alignof { KEYWORD_RETURN(ALIGNOF); } // C11
230__alignof { KEYWORD_RETURN(ALIGNOF); } // GCC
231__alignof__ { KEYWORD_RETURN(ALIGNOF); } // GCC
232and { QKEYWORD_RETURN(WAND); } // CFA
233asm { KEYWORD_RETURN(ASM); }
234__asm { KEYWORD_RETURN(ASM); } // GCC
235__asm__ { KEYWORD_RETURN(ASM); } // GCC
236_Atomic { KEYWORD_RETURN(ATOMIC); } // C11
237__attribute { KEYWORD_RETURN(ATTRIBUTE); } // GCC
238__attribute__ { KEYWORD_RETURN(ATTRIBUTE); } // GCC
239auto { KEYWORD_RETURN(AUTO); }
240__auto_type { KEYWORD_RETURN(AUTO_TYPE); }
241basetypeof { KEYWORD_RETURN(BASETYPEOF); } // CFA
242_Bool { KEYWORD_RETURN(BOOL); } // C99
243__SVBool_t { KEYWORD_RETURN(SVBOOL); } // gcc (ARM)
244break { KEYWORD_RETURN(BREAK); }
245case { KEYWORD_RETURN(CASE); }
246catch { QKEYWORD_RETURN(CATCH); } // CFA
247catchResume { QKEYWORD_RETURN(CATCHRESUME); } // CFA
248char { KEYWORD_RETURN(CHAR); }
249choose { KEYWORD_RETURN(CHOOSE); } // CFA
250coerce { KEYWORD_RETURN(COERCE); } // CFA
251corun { KEYWORD_RETURN(CORUN); } // CFA
252cofor { KEYWORD_RETURN(COFOR); } // CFA
253_Complex { KEYWORD_RETURN(COMPLEX); } // C99
254__complex { KEYWORD_RETURN(COMPLEX); } // GCC
255__complex__ { KEYWORD_RETURN(COMPLEX); } // GCC
256const { KEYWORD_RETURN(CONST); }
257__const { KEYWORD_RETURN(CONST); } // GCC
258__const__ { KEYWORD_RETURN(CONST); } // GCC
259continue { KEYWORD_RETURN(CONTINUE); }
260coroutine { KEYWORD_RETURN(COROUTINE); } // CFA
261_Decimal32 { KEYWORD_RETURN(DECIMAL32); } // GCC
262_Decimal64 { KEYWORD_RETURN(DECIMAL64); } // GCC
263_Decimal128 { KEYWORD_RETURN(DECIMAL128); } // GCC
264default { KEYWORD_RETURN(DEFAULT); }
265disable { KEYWORD_RETURN(DISABLE); } // CFA
266do { KEYWORD_RETURN(DO); }
267double { KEYWORD_RETURN(DOUBLE); }
268dtype { KEYWORD_RETURN(DTYPE); } // CFA
269else { KEYWORD_RETURN(ELSE); }
270enable { KEYWORD_RETURN(ENABLE); } // CFA
271enum { KEYWORD_RETURN(ENUM); }
272exception { KEYWORD_RETURN(EXCEPTION); } // CFA
273__extension__ { KEYWORD_RETURN(EXTENSION); } // GCC
274extern { KEYWORD_RETURN(EXTERN); }
275fallthrough { KEYWORD_RETURN(FALLTHROUGH); } // CFA
276fallthru { KEYWORD_RETURN(FALLTHRU); } // CFA
277finally { QKEYWORD_RETURN(FINALLY); } // CFA
278fixup { QKEYWORD_RETURN(FIXUP); } // CFA
279float { KEYWORD_RETURN(FLOAT); }
280__float80 { KEYWORD_RETURN(FLOAT80); } // GCC
281float80 { KEYWORD_RETURN(FLOAT80); } // GCC
282__float128 { KEYWORD_RETURN(uuFLOAT128); } // GCC
283float128 { KEYWORD_RETURN(uuFLOAT128); } // GCC
284_Float16 { FLOATXX(FLOAT16); } // GCC
285_Float32 { FLOATXX(FLOAT32); } // GCC
286_Float32x { FLOATXX(FLOAT32X); } // GCC
287_Float64 { FLOATXX(FLOAT64); } // GCC
288_Float64x { FLOATXX(FLOAT64X); } // GCC
289_Float128 { FLOATXX(FLOAT128); } // GCC
290_Float128x { FLOATXX(FLOAT128X); } // GCC
291__Float32x4_t { FLOATXX(FLOAT32X4); } // GCC (ARM)
292__Float64x2_t { FLOATXX(FLOAT64X2); } // GCC (ARM)
293__SVFloat32_t { FLOATXX(SVFLOAT32); } // GCC (ARM)
294__SVFloat64_t { FLOATXX(SVFLOAT64); } // GCC (ARM)
295for { KEYWORD_RETURN(FOR); }
296forall { KEYWORD_RETURN(FORALL); } // CFA
297fortran { KEYWORD_RETURN(FORTRAN); }
298ftype { KEYWORD_RETURN(FTYPE); } // CFA
299generator { KEYWORD_RETURN(GENERATOR); } // CFA
300_Generic { KEYWORD_RETURN(GENERIC); } // C11
301goto { KEYWORD_RETURN(GOTO); }
302if { KEYWORD_RETURN(IF); }
303_Imaginary { KEYWORD_RETURN(IMAGINARY); } // C99
304__imag { KEYWORD_RETURN(IMAGINARY); } // GCC
305__imag__ { KEYWORD_RETURN(IMAGINARY); } // GCC
306inline { KEYWORD_RETURN(INLINE); } // C99
307__inline { KEYWORD_RETURN(INLINE); } // GCC
308__inline__ { KEYWORD_RETURN(INLINE); } // GCC
309int { KEYWORD_RETURN(INT); }
310int128 { KEYWORD_RETURN(INT128); } // CFA
311__int128 { KEYWORD_RETURN(INT128); } // GCC
312__int128_t { KEYWORD_RETURN(INT128); } // GCC
313__label__ { KEYWORD_RETURN(LABEL); } // GCC
314long { KEYWORD_RETURN(LONG); }
315monitor { KEYWORD_RETURN(MONITOR); } // CFA
316mutex { KEYWORD_RETURN(MUTEX); } // CFA
317_Noreturn { KEYWORD_RETURN(NORETURN); } // C11
318__builtin_offsetof { KEYWORD_RETURN(OFFSETOF); } // GCC
319one_t { NUMERIC_RETURN(ONE_T); } // CFA
320or { QKEYWORD_RETURN(WOR); } // CFA
321otype { KEYWORD_RETURN(OTYPE); } // CFA
322recover { QKEYWORD_RETURN(RECOVER); } // CFA
323register { KEYWORD_RETURN(REGISTER); }
324report { KEYWORD_RETURN(THROWRESUME); } // CFA
325restrict { KEYWORD_RETURN(RESTRICT); } // C99
326__restrict { KEYWORD_RETURN(RESTRICT); } // GCC
327__restrict__ { KEYWORD_RETURN(RESTRICT); } // GCC
328return { KEYWORD_RETURN(RETURN); }
329 /* resume { KEYWORD_RETURN(RESUME); } // CFA */
330short { KEYWORD_RETURN(SHORT); }
331signed { KEYWORD_RETURN(SIGNED); }
332__signed { KEYWORD_RETURN(SIGNED); } // GCC
333__signed__ { KEYWORD_RETURN(SIGNED); } // GCC
334sizeof { KEYWORD_RETURN(SIZEOF); }
335countof { KEYWORD_RETURN(COUNTOF); } // GCC
336static { KEYWORD_RETURN(STATIC); }
337_Static_assert { KEYWORD_RETURN(STATICASSERT); } // C11
338static_assert { KEYWORD_RETURN(STATICASSERT); } // C23
339struct { KEYWORD_RETURN(STRUCT); }
340suspend { KEYWORD_RETURN(SUSPEND); } // CFA
341switch { KEYWORD_RETURN(SWITCH); }
342thread { KEYWORD_RETURN(THREAD); } // C11
343__thread { KEYWORD_RETURN(THREADLOCALGCC); } // GCC
344_Thread_local { KEYWORD_RETURN(THREADLOCALC11); } // C11
345thread_local { KEYWORD_RETURN(THREADLOCALC11); } // C23
346throw { KEYWORD_RETURN(THROW); } // CFA
347throwResume { KEYWORD_RETURN(THROWRESUME); } // CFA
348timeout { QKEYWORD_RETURN(TIMEOUT); } // CFA
349trait { KEYWORD_RETURN(TRAIT); } // CFA
350try { KEYWORD_RETURN(TRY); } // CFA
351ttype { KEYWORD_RETURN(TTYPE); } // CFA
352typedef { KEYWORD_RETURN(TYPEDEF); }
353typeof { KEYWORD_RETURN(TYPEOF); } // GCC
354__typeof { KEYWORD_RETURN(TYPEOF); } // GCC
355__typeof__ { KEYWORD_RETURN(TYPEOF); } // GCC
356typeid { KEYWORD_RETURN(TYPEID); } // GCC
357union { KEYWORD_RETURN(UNION); }
358__uint128_t { KEYWORD_RETURN(UINT128); } // GCC
359unsigned { KEYWORD_RETURN(UNSIGNED); }
360__builtin_va_arg { KEYWORD_RETURN(VA_ARG); } // GCC
361__builtin_va_list { KEYWORD_RETURN(VA_LIST); } // GCC
362virtual { KEYWORD_RETURN(VIRTUAL); } // CFA
363void { KEYWORD_RETURN(VOID); }
364volatile { KEYWORD_RETURN(VOLATILE); }
365__volatile { KEYWORD_RETURN(VOLATILE); } // GCC
366__volatile__ { KEYWORD_RETURN(VOLATILE); } // GCC
367vtable { KEYWORD_RETURN(VTABLE); } // CFA
368waitfor { KEYWORD_RETURN(WAITFOR); } // CFA
369waituntil { KEYWORD_RETURN(WAITUNTIL); } // CFA
370when { KEYWORD_RETURN(WHEN); } // CFA
371while { KEYWORD_RETURN(WHILE); }
372with { KEYWORD_RETURN(WITH); } // CFA
373zero_t { NUMERIC_RETURN(ZERO_T); } // CFA
374
375 /* identifier */
376{identifier} { IDENTIFIER_RETURN(); }
377"``"{identifier} { // CFA
378 yytext[yyleng] = '\0'; yytext += 2; // SKULLDUGGERY: remove backquotes (ok to shorten?)
379 IDENTIFIER_RETURN();
380}
381
382 /* C23 attributes */
383"[["{hv_white}*{attributes}({hv_white}*","{hv_white}*{attributes})*{hv_white}*"]]" {
384 strtext = new string( &yytext[2], yyleng - 4 ); // remove [[]]
385 RETURN_STR(C23_ATTRIBUTE);
386}
387
388 /* numeric constants */
389{binary_constant} { NUMERIC_RETURN(INTEGERconstant); }
390{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
391{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
392{hex_constant} { NUMERIC_RETURN(INTEGERconstant); }
393{floating_decimal} { NUMERIC_RETURN(FLOATING_DECIMALconstant); } // must appear before floating_constant
394{floating_fraction} { NUMERIC_RETURN(FLOATING_FRACTIONconstant); } // must appear before floating_constant
395{floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
396{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
397
398 /* character constant, allows empty value */
399({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new string( yytext, yyleng ); }
400<QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); }
401<QUOTE>['\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); }
402 /* ' stop editor highlighting */
403
404 /* string constant */
405({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new string( yytext, yyleng ); }
406<STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); }
407<STRING>["\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); }
408 /* " stop editor highlighting */
409
410 /* common character/string constant */
411<QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); }
412<QUOTE,STRING>"\\"{h_white}*"\n" {} // continuation (ALSO HANDLED BY CPP)
413<QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character
414
415 /* punctuation */
416"@" { ASCIIOP_RETURN(); }
417"`" { ASCIIOP_RETURN(); }
418"[" { ASCIIOP_RETURN(); }
419"]" { ASCIIOP_RETURN(); }
420"(" { ASCIIOP_RETURN(); }
421")" { ASCIIOP_RETURN(); }
422"{" { ASCIIOP_RETURN(); }
423"}" { ASCIIOP_RETURN(); }
424"," { ASCIIOP_RETURN(); } // also operator
425":" { ASCIIOP_RETURN(); }
426";" { ASCIIOP_RETURN(); }
427"." { ASCIIOP_RETURN(); } // also operator
428"@@" { NAMEDOP_RETURN(ATTR); } // CFA, attribute shorthand
429"..." { NAMEDOP_RETURN(ELLIPSIS); }
430
431 /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
432"<:" { RETURN_VAL('['); }
433":>" { RETURN_VAL(']'); }
434"<%" { RETURN_VAL('{'); }
435"%>" { RETURN_VAL('}'); }
436
437 /* operators */
438"!" { ASCIIOP_RETURN(); }
439"+" { ASCIIOP_RETURN(); }
440"-" { ASCIIOP_RETURN(); }
441"*" { ASCIIOP_RETURN(); }
442"\\" { ASCIIOP_RETURN(); } // CFA, exponentiation
443"/" { ASCIIOP_RETURN(); }
444"%" { ASCIIOP_RETURN(); }
445"^" { ASCIIOP_RETURN(); }
446"~" { ASCIIOP_RETURN(); }
447"&" { ASCIIOP_RETURN(); }
448"|" { ASCIIOP_RETURN(); }
449"<" { ASCIIOP_RETURN(); }
450">" { ASCIIOP_RETURN(); }
451"=" { ASCIIOP_RETURN(); }
452"?" { ASCIIOP_RETURN(); }
453
454"++" { NAMEDOP_RETURN(ICR); }
455"--" { NAMEDOP_RETURN(DECR); }
456"==" { NAMEDOP_RETURN(EQ); }
457"!=" { NAMEDOP_RETURN(NE); }
458"<<" { NAMEDOP_RETURN(LS); }
459">>" { NAMEDOP_RETURN(RS); }
460"<=" { NAMEDOP_RETURN(LE); }
461">=" { NAMEDOP_RETURN(GE); }
462"&&" { NAMEDOP_RETURN(ANDAND); }
463"||" { NAMEDOP_RETURN(OROR); }
464"->" { NAMEDOP_RETURN(ARROW); }
465"+=" { NAMEDOP_RETURN(PLUSassign); }
466"-=" { NAMEDOP_RETURN(MINUSassign); }
467"\\=" { NAMEDOP_RETURN(EXPassign); } // CFA, exponentiation
468"*=" { NAMEDOP_RETURN(MULTassign); }
469"/=" { NAMEDOP_RETURN(DIVassign); }
470"%=" { NAMEDOP_RETURN(MODassign); }
471"&=" { NAMEDOP_RETURN(ANDassign); }
472"|=" { NAMEDOP_RETURN(ORassign); }
473"^=" { NAMEDOP_RETURN(ERassign); }
474"<<=" { NAMEDOP_RETURN(LSassign); }
475">>=" { NAMEDOP_RETURN(RSassign); }
476
477"@=" { NAMEDOP_RETURN(ATassign); } // CFA
478"+~" { NAMEDOP_RETURN(ErangeUp); } // CFA
479"~=" { NAMEDOP_RETURN(ErangeUpEq); } // CFA
480"+~=" { NAMEDOP_RETURN(ErangeUpEq); } // CFA
481"-~" { NAMEDOP_RETURN(ErangeDown); } // CFA
482"-~=" { NAMEDOP_RETURN(ErangeDownEq); } // CFA
483
484 /* CFA, operator identifier */
485{op_unary}"?" { IDENTIFIER_RETURN(); } // unary
486"?"({op_unary_pre_post}|"()"|"[?]"|"{}") { IDENTIFIER_RETURN(); }
487"^?{}" { IDENTIFIER_RETURN(); }
488"?`"{identifier} { // postfix operator
489 yylval.tok.str = new string( &yytext[2] ); // remove ?`
490 yylval.tok.str = build_postfix_name( yylval.tok.str ); // add prefix
491 RETURN_LOCN( typedefTable.isKind( *yylval.tok.str ) );
492}
493"?"{op_binary_over}"?" { IDENTIFIER_RETURN(); } // binary
494 /*
495 This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the string "*?*?" can be
496 lexed as "*?"/"*?" or "*"/"?*?". Since it is common practise to put a unary operator juxtaposed to an identifier,
497 e.g., "*i", users will be annoyed if they cannot do this with respect to operator identifiers. Therefore, there is
498 a lexical look-ahead for the second case, with backtracking to return the leading unary operator and then
499 reparsing the trailing operator identifier. Otherwise a space is needed between the unary operator and operator
500 identifier to disambiguate this common case.
501
502 A similar issue occurs with the dereference, *?(...), and routine-call, ?()(...) identifiers. The ambiguity
503 occurs when the deference operator has no parameters, *?() and *?()(...), requiring arbitrary whitespace
504 look-ahead for the routine-call parameter-list to disambiguate. However, the dereference operator must have a
505 parameter/argument to dereference *?(...). Hence, always interpreting the string *?() as * ?() does not preclude
506 any meaningful program.
507
508 The remaining cases are with the increment/decrement operators and conditional expression:
509
510 i++? ...(...);
511 i?++ ...(...);
512
513 requiring arbitrary whitespace look-ahead for the operator parameter-list, even though that interpretation is an
514 incorrect expression (juxtaposed identifiers). Therefore, it is necessary to disambiguate these cases with a
515 space:
516
517 i++ ? i : 0;
518 i? ++i : 0;
519 */
520{op_unary}"?"({op_unary_pre_post}|"()"|"[?]"|{op_binary_over}"?") {
521 // 1 or 2 character unary operator ?
522 int i = yytext[1] == '?' ? 1 : 2;
523 yyless( i ); // put back characters up to first '?'
524 if ( i > 1 ) {
525 NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
526 } else {
527 ASCIIOP_RETURN();
528 } // if
529}
530
531 /* unknown character */
532. { yyerror( "unknown character" ); }
533
534%%
535
536// ----end of lexer----
537
538void yyerror( const char * errmsg ) {
539 SemanticErrorThrow = true;
540 cerr << (yyfilename ? yyfilename : "*unknown file*") << ':' << yylineno << ':' << column - yyleng + 1
541 << ": " << ErrorHelpers::error_str() << errmsg << " before token \"" << (yytext[0] == '\0' ? "EOF" : yytext) << '"' << endl;
542}
543
544// Local Variables: //
545// mode: c++ //
546// tab-width: 4 //
547// compile-command: "make install" //
548// End: //
Note: See TracBrowser for help on using the repository browser.