Context Navigation

lex.ll @ d3c3261

Last change on this file since d3c3261 was 01fac29, checked in by Peter A. Buhr <pabuhr@…>, 13 months ago
lex _static_assert from C23
Property mode set to `100644`
File size: 20.7 KB

Rev	Line
[b87a5ed]	1	/*
	2	* Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
	3	*
	4	* The contents of this file are covered under the licence agreement in the
	5	* file "LICENCE" distributed with Cforall.
[8f60f0b]	6	*
[6016c87]	7	* lex.ll --
[8f60f0b]	8	*
[51b7345]	9	* Author : Peter A. Buhr
	10	* Created On : Sat Sep 22 08:58:10 2001
[926af74]	11	* Last Modified By : Peter A. Buhr
[01fac29]	12	* Last Modified On : Fri Jun 9 10:04:00 2023
	13	* Update Count : 770
[51b7345]	14	*/
	15
	16	%option yylineno
[4e9c7c1]	17	%option noyywrap
[5f2f2d7]	18	%option nounput
[51b7345]	19
	20	%{
[9ed4f94]	21	// The lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
[de62360d]	22	// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
	23	// line-number directives) and C/C++ style comments, which are ignored.
[51b7345]	24
[bb7422a]	25	// ************************* Includes and Defines **************************
[51b7345]	26
[0bd46fd]	27	#ifdef __clang__
	28	#pragma GCC diagnostic ignored "-Wnull-conversion"
	29	#endif
	30
[4439008]	31	// trigger before each matching rule's action
	32	#define YY_USER_ACTION \
	33	yylloc.first_line = yylineno; \
	34	yylloc.first_column = column; \
	35	column += yyleng; \
	36	yylloc.last_column = column; \
	37	yylloc.last_line = yylineno; \
	38	yylloc.filename = yyfilename ? yyfilename : "";
[9ed4f94]	39	unsigned int column = 0; // position of the end of the last token parsed
	40
[51b7345]	41	#include <string>
[f487962]	42	#include <cstdio> // FILENAME_MAX
[9ed4f94]	43	using namespace std;
[51b7345]	44
[ba01b14]	45	#include "config.h" // configure info
[c468150]	46	#include "DeclarationNode.h" // for DeclarationNode
	47	#include "ExpressionNode.h" // for LabelNode
	48	#include "InitializerNode.h" // for InitializerNode
[984dce6]	49	#include "ParseNode.h"
[c468150]	50	#include "ParserTypes.h" // for Token
	51	#include "StatementNode.h" // for CondCtl, ForCtrl
[984dce6]	52	#include "TypedefTable.h"
[c468150]	53	// This (generated) header must come late as it is missing includes.
	54	#include "parser.hh" // generated info
[51b7345]	55
[60a8062]	56	string * build_postfix_name( string * name );
	57
[51b7345]	58	char *yyfilename;
[9ed4f94]	59	string *strtext; // accumulate parts of character and string constant value
[51b7345]	60
[de62360d]	61	#define RETURN_LOCN(x) yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
[9ed4f94]	62	#define RETURN_VAL(x) yylval.tok.str = new string( yytext ); RETURN_LOCN( x )
[926af74]	63	#define RETURN_CHAR(x) yylval.tok.str = nullptr; RETURN_LOCN( x )
[de62360d]	64	#define RETURN_STR(x) yylval.tok.str = strtext; RETURN_LOCN( x )
[5f2f2d7]	65
[f487962]	66	#define WHITE_RETURN(x) // do nothing
[9ed4f94]	67	#define NEWLINE_RETURN() column = 0; WHITE_RETURN( '\n' )
[de62360d]	68	#define ASCIIOP_RETURN() RETURN_CHAR( (int)yytext[0] ) // single character operator
[f487962]	69	#define NAMEDOP_RETURN(x) RETURN_CHAR( x ) // multichar operator, with a name
[de62360d]	70	#define NUMERIC_RETURN(x) rm_underscore(); RETURN_VAL( x ) // numeric constant
	71	#define KEYWORD_RETURN(x) RETURN_CHAR( x ) // keyword
[4439008]	72	#define QKEYWORD_RETURN(x) RETURN_VAL(x); // quasi-keyword
[984dce6]	73	#define IDENTIFIER_RETURN() RETURN_VAL( typedefTable.isKind( yytext ) )
[51b7345]	74
[25744d2]	75	#ifdef HAVE_KEYWORDS_FLOATXX // GCC >= 7 => keyword, otherwise typedef
[ba01b14]	76	#define FLOATXX(v) KEYWORD_RETURN(v);
	77	#else
[37cdd97]	78	#define FLOATXX(v) IDENTIFIER_RETURN();
[ba01b14]	79	#endif // HAVE_KEYWORDS_FLOATXX
	80
[3848e0e]	81	void rm_underscore() {
[7e419e7]	82	// SKULLDUGGERY: remove underscores (ok to shorten?)
[e7aed49]	83	yyleng = 0;
[7e419e7]	84	for ( int i = 0; yytext[i] != '\0'; i += 1 ) { // copying non-underscore characters to front of string
[b87a5ed]	85	if ( yytext[i] != '_' ) {
[e7aed49]	86	yytext[yyleng] = yytext[i];
	87	yyleng += 1;
[b87a5ed]	88	} // if
	89	} // for
	90	yytext[yyleng] = '\0';
[7e419e7]	91	} // rm_underscore
[51b7345]	92
[7812f1d1]	93	// Stop warning due to incorrectly generated flex code.
	94	#pragma GCC diagnostic ignored "-Wsign-compare"
[51b7345]	95	%}
	96
[0a2168f]	97	binary [0-1]
[51b7345]	98	octal [0-7]
	99	nonzero [1-9]
	100	decimal [0-9]
	101	hex [0-9a-fA-F]
[3848e0e]	102	universal_char "\\"((u"_"?{hex_quad})\|(U"_"?{hex_quad}{2}))
[51b7345]	103
[b87a5ed]	104	// identifier, GCC: $ in identifier
[51b7345]	105	identifier ([a-zA-Z_$]\|{universal_char})([0-9a-zA-Z_$]\|{universal_char})*
	106
[b87a5ed]	107	// numeric constants, CFA: '_' in constant
[3848e0e]	108	hex_quad {hex}("_"?{hex}){3}
[201aeb9]	109	size_opt (8\|16\|32\|64\|128)?
[0a616e0]	110	// CFA: explicit l8/l16/l32/l64/l128, char 'hh', short 'h', int 'n'
[f56c32e]	111	length ("ll"\|"LL"\|[lL]{size_opt})\|("hh"\|"HH"\|[hHnN])
[0a616e0]	112	// CFA: size_t 'z', pointer 'p', which define a sign and length
	113	integer_suffix_opt ("_"?(([uU]({length}?[iI]?)\|([iI]{length}))\|([iI]({length}?[uU]?)\|([uU]{length}))\|({length}([iI]?[uU]?)\|([uU][iI]))\|[zZ]\|[pP]))?
[51b7345]	114
	115	octal_digits ({octal})\|({octal}({octal}\|"_")*{octal})
	116	octal_prefix "0""_"?
[930f69e]	117	octal_constant (("0")\|({octal_prefix}{octal_digits})){integer_suffix_opt}
[51b7345]	118
	119	nonzero_digits ({nonzero})\|({nonzero}({decimal}\|"_")*{decimal})
[930f69e]	120	decimal_constant {nonzero_digits}{integer_suffix_opt}
[51b7345]	121
[0a2168f]	122	binary_digits ({binary})\|({binary}({binary}\|"_")*{binary})
	123	binary_prefix "0"[bB]"_"?
	124	binary_constant {binary_prefix}{binary_digits}{integer_suffix_opt}
	125
[51b7345]	126	hex_digits ({hex})\|({hex}({hex}\|"_")*{hex})
	127	hex_prefix "0"[xX]"_"?
[930f69e]	128	hex_constant {hex_prefix}{hex_digits}{integer_suffix_opt}
[51b7345]	129
[d3b5a14]	130	// GCC: floating D (double), imaginary iI, and decimal floating DF, DD, DL
[51b7345]	131	exponent "_"?[eE]"_"?[+-]?{decimal_digits}
[ba01b14]	132	floating_size 16\|32\|32x\|64\|64x\|80\|128\|128x
	133	floating_length ([fFdDlLwWqQ]\|[fF]{floating_size})
[201aeb9]	134	floating_suffix ({floating_length}?[iI]?)\|([iI]{floating_length})
[d3b5a14]	135	decimal_floating_suffix [dD][fFdDlL]
	136	floating_suffix_opt ("_"?({floating_suffix}\|{decimal_floating_suffix}))?
[f4b77f2]	137	decimal_digits ({decimal})\|({decimal}({decimal}\|"_")*{decimal})
[930f69e]	138	floating_decimal {decimal_digits}"."{exponent}?{floating_suffix_opt}
	139	floating_fraction "."{decimal_digits}{exponent}?{floating_suffix_opt}
	140	floating_constant ({decimal_digits}{exponent}{floating_suffix_opt})\|({decimal_digits}{floating_fraction})
[51b7345]	141
	142	binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
[dc7db63]	143	hex_floating_suffix_opt ("_"?({floating_suffix}))?
[930f69e]	144	hex_floating_fraction ({hex_digits}?"."{hex_digits})\|({hex_digits}".")
[f4b77f2]	145	hex_floating_constant {hex_prefix}(({hex_floating_fraction}{binary_exponent})\|({hex_digits}{binary_exponent})){hex_floating_suffix_opt}
[51b7345]	146
[b87a5ed]	147	// character escape sequence, GCC: \e => esc character
[51b7345]	148	simple_escape "\\"[abefnrtv'"?\\]
[930f69e]	149	// ' stop editor highlighting
[3848e0e]	150	octal_escape "\\"{octal}("_"?{octal}){0,2}
	151	hex_escape "\\""x""_"?{hex_digits}
[51b7345]	152	escape_seq {simple_escape}\|{octal_escape}\|{hex_escape}\|{universal_char}
[59db689]	153	cwide_prefix "L"\|"U"\|"u"
	154	swide_prefix {cwide_prefix}\|"u8"
[51b7345]	155
[b87a5ed]	156	// display/white-space characters
[51b7345]	157	h_tab [\011]
	158	form_feed [\014]
	159	v_tab [\013]
	160	c_return [\015]
	161	h_white [ ]\|{h_tab}
	162
[e7aed49]	163	// overloadable operators
[51b7345]	164	op_unary_only "~"\|"!"
	165	op_unary_binary "+"\|"-"\|"*"
	166	op_unary_pre_post "++"\|"--"
	167	op_unary {op_unary_only}\|{op_unary_binary}\|{op_unary_pre_post}
	168
[994d080]	169	op_binary_only "/"\|"%"\|"\\"\|"^"\|"&"\|"\|"\|"<"\|">"\|"="\|"=="\|"!="\|"<<"\|">>"\|"<="\|">="\|"+="\|"-="\|"*="\|"/="\|"%="\|"\\="\|"&="\|"\|="\|"^="\|"<<="\|">>="
[51b7345]	170	op_binary_over {op_unary_binary}\|{op_binary_only}
[e7aed49]	171	// op_binary_not_over "?"\|"->"\|"."\|"&&"\|"\|\|"\|"@="
	172	// operator {op_unary_pre_post}\|{op_binary_over}\|{op_binary_not_over}
[51b7345]	173
	174	%x COMMENT
[3848e0e]	175	%x BKQUOTE
	176	%x QUOTE
	177	%x STRING
[51b7345]	178
	179	%%
[994d080]	180	/* line directives */
[4040425]	181	^{h_white}"#"{h_white}[0-9]+{h_white}["][^"\n]+["]."\n" {
[930f69e]	182	/* " stop editor highlighting */
[c1c1112]	183	static char filename[FILENAME_MAX]; // temporarily store current source-file name
[51b7345]	184	char *end_num;
	185	char begin_string, end_string;
	186	long lineno, length;
	187	lineno = strtol( yytext + 1, &end_num, 0 );
	188	begin_string = strchr( end_num, '"' );
[f487962]	189	if ( begin_string ) { // file name ?
	190	end_string = strchr( begin_string + 1, '"' ); // look for ending delimiter
	191	assert( end_string ); // closing quote ?
	192	length = end_string - begin_string - 1; // file-name length without quotes or sentinel
	193	assert( length < FILENAME_MAX ); // room for sentinel ?
	194	memcpy( &filename, begin_string + 1, length ); // copy file name from yytext
	195	filename[ length ] = '\0'; // terminate string with sentinel
[9ed4f94]	196	//cout << "file " << filename << " line " << lineno << endl;
[f487962]	197	yylineno = lineno;
[c1c1112]	198	yyfilename = filename;
[b87a5ed]	199	} // if
[51b7345]	200	}
	201
[637dd9c]	202	/* preprocessor-style directives */
[61fc4f6]	203	^{h_white}"#"[^\n]"\n" { RETURN_VAL( DIRECTIVE ); }
[51b7345]	204
[cd623a4]	205	/* ignore C style comments (ALSO HANDLED BY CPP) */
[3848e0e]	206	"/*" { BEGIN COMMENT; }
[cd623a4]	207	<COMMENT>.\|\n ;
	208	<COMMENT>"*/" { BEGIN 0; }
[51b7345]	209
[cd623a4]	210	/* ignore C++ style comments (ALSO HANDLED BY CPP) */
	211	"//"[^\n]*"\n" ;
[51b7345]	212
[b87a5ed]	213	/* ignore whitespace */
[3848e0e]	214	{h_white}+ { WHITE_RETURN(' '); }
	215	({v_tab}\|{c_return}\|{form_feed})+ { WHITE_RETURN(' '); }
	216	({h_white}\|{v_tab}\|{c_return}\|{form_feed})*"\n" { NEWLINE_RETURN(); }
[51b7345]	217
[b87a5ed]	218	/* keywords */
	219	_Alignas { KEYWORD_RETURN(ALIGNAS); } // C11
	220	_Alignof { KEYWORD_RETURN(ALIGNOF); } // C11
	221	__alignof { KEYWORD_RETURN(ALIGNOF); } // GCC
	222	__alignof__ { KEYWORD_RETURN(ALIGNOF); } // GCC
[9fd9d015]	223	and { QKEYWORD_RETURN(WAND); } // CFA
[b87a5ed]	224	asm { KEYWORD_RETURN(ASM); }
	225	__asm { KEYWORD_RETURN(ASM); } // GCC
	226	__asm__ { KEYWORD_RETURN(ASM); } // GCC
	227	_Atomic { KEYWORD_RETURN(ATOMIC); } // C11
	228	__attribute { KEYWORD_RETURN(ATTRIBUTE); } // GCC
	229	__attribute__ { KEYWORD_RETURN(ATTRIBUTE); } // GCC
[3848e0e]	230	auto { KEYWORD_RETURN(AUTO); }
[f673c13c]	231	__auto_type { KEYWORD_RETURN(AUTO_TYPE); }
[b6ad601]	232	basetypeof { KEYWORD_RETURN(BASETYPEOF); } // CFA
[b87a5ed]	233	_Bool { KEYWORD_RETURN(BOOL); } // C99
[3848e0e]	234	break { KEYWORD_RETURN(BREAK); }
	235	case { KEYWORD_RETURN(CASE); }
[9fb1367]	236	catch { QKEYWORD_RETURN(CATCH); } // CFA
	237	catchResume { QKEYWORD_RETURN(CATCHRESUME); } // CFA
[3848e0e]	238	char { KEYWORD_RETURN(CHAR); }
[b87a5ed]	239	choose { KEYWORD_RETURN(CHOOSE); } // CFA
[1528a2c]	240	coerce { KEYWORD_RETURN(COERCE); } // CFA
[b87a5ed]	241	_Complex { KEYWORD_RETURN(COMPLEX); } // C99
	242	__complex { KEYWORD_RETURN(COMPLEX); } // GCC
	243	__complex__ { KEYWORD_RETURN(COMPLEX); } // GCC
[3848e0e]	244	const { KEYWORD_RETURN(CONST); }
[b87a5ed]	245	__const { KEYWORD_RETURN(CONST); } // GCC
	246	__const__ { KEYWORD_RETURN(CONST); } // GCC
[3848e0e]	247	continue { KEYWORD_RETURN(CONTINUE); }
[e04b636]	248	coroutine { KEYWORD_RETURN(COROUTINE); } // CFA
[15f769c]	249	_Decimal32 { KEYWORD_RETURN(DECIMAL32); } // GCC
	250	_Decimal64 { KEYWORD_RETURN(DECIMAL64); } // GCC
	251	_Decimal128 { KEYWORD_RETURN(DECIMAL128); } // GCC
[3848e0e]	252	default { KEYWORD_RETURN(DEFAULT); }
[02e5ab6]	253	disable { KEYWORD_RETURN(DISABLE); } // CFA
[b87a5ed]	254	do { KEYWORD_RETURN(DO); }
[3848e0e]	255	double { KEYWORD_RETURN(DOUBLE); }
[b87a5ed]	256	dtype { KEYWORD_RETURN(DTYPE); } // CFA
[3848e0e]	257	else { KEYWORD_RETURN(ELSE); }
[02e5ab6]	258	enable { KEYWORD_RETURN(ENABLE); } // CFA
[3848e0e]	259	enum { KEYWORD_RETURN(ENUM); }
[c27fb59]	260	exception { KEYWORD_RETURN(EXCEPTION); } // CFA
[8c25760]	261	__extension__ { KEYWORD_RETURN(EXTENSION); } // GCC
[3848e0e]	262	extern { KEYWORD_RETURN(EXTERN); }
[bd7f401]	263	fallthrough { KEYWORD_RETURN(FALLTHROUGH); } // CFA
[35f730f]	264	fallthru { KEYWORD_RETURN(FALLTHRU); } // CFA
[9fb1367]	265	finally { QKEYWORD_RETURN(FINALLY); } // CFA
	266	fixup { QKEYWORD_RETURN(FIXUP); } // CFA
[3848e0e]	267	float { KEYWORD_RETURN(FLOAT); }
[e15853c]	268	__float80 { KEYWORD_RETURN(uuFLOAT80); } // GCC
	269	float80 { KEYWORD_RETURN(uuFLOAT80); } // GCC
	270	__float128 { KEYWORD_RETURN(uuFLOAT128); } // GCC
	271	float128 { KEYWORD_RETURN(uuFLOAT128); } // GCC
	272	_Float16 { FLOATXX(uFLOAT16); } // GCC
	273	_Float32 { FLOATXX(uFLOAT32); } // GCC
	274	_Float32x { FLOATXX(uFLOAT32X); } // GCC
	275	_Float64 { FLOATXX(uFLOAT64); } // GCC
	276	_Float64x { FLOATXX(uFLOAT64X); } // GCC
	277	_Float128 { FLOATXX(uFLOAT128); } // GCC
	278	_Float128x { FLOATXX(uFLOAT128); } // GCC
[b87a5ed]	279	for { KEYWORD_RETURN(FOR); }
	280	forall { KEYWORD_RETURN(FORALL); } // CFA
[3848e0e]	281	fortran { KEYWORD_RETURN(FORTRAN); }
[b87a5ed]	282	ftype { KEYWORD_RETURN(FTYPE); } // CFA
[553772b]	283	generator { KEYWORD_RETURN(GENERATOR); } // CFA
[b87a5ed]	284	_Generic { KEYWORD_RETURN(GENERIC); } // C11
[3848e0e]	285	goto { KEYWORD_RETURN(GOTO); }
[b87a5ed]	286	if { KEYWORD_RETURN(IF); }
	287	_Imaginary { KEYWORD_RETURN(IMAGINARY); } // C99
	288	__imag { KEYWORD_RETURN(IMAGINARY); } // GCC
	289	__imag__ { KEYWORD_RETURN(IMAGINARY); } // GCC
	290	inline { KEYWORD_RETURN(INLINE); } // C99
	291	__inline { KEYWORD_RETURN(INLINE); } // GCC
	292	__inline__ { KEYWORD_RETURN(INLINE); } // GCC
	293	int { KEYWORD_RETURN(INT); }
[f1da02c]	294	int128 { KEYWORD_RETURN(INT128); } // CFA
[201aeb9]	295	__int128 { KEYWORD_RETURN(INT128); } // GCC
[f1da02c]	296	__int128_t { KEYWORD_RETURN(INT128); } // GCC
[b87a5ed]	297	__label__ { KEYWORD_RETURN(LABEL); } // GCC
[3848e0e]	298	long { KEYWORD_RETURN(LONG); }
[6016c87]	299	monitor { KEYWORD_RETURN(MONITOR); } // CFA
[a7c90d4]	300	mutex { KEYWORD_RETURN(MUTEX); } // CFA
[b87a5ed]	301	_Noreturn { KEYWORD_RETURN(NORETURN); } // C11
[5721a6d]	302	__builtin_offsetof { KEYWORD_RETURN(OFFSETOF); } // GCC
[3a2128f]	303	one_t { NUMERIC_RETURN(ONE_T); } // CFA
[ce28c7b]	304	or { QKEYWORD_RETURN(WOR); } // CFA
[4040425]	305	otype { KEYWORD_RETURN(OTYPE); } // CFA
[9fb1367]	306	recover { QKEYWORD_RETURN(RECOVER); } // CFA
[3848e0e]	307	register { KEYWORD_RETURN(REGISTER); }
[9fb1367]	308	report { KEYWORD_RETURN(THROWRESUME); } // CFA
[b87a5ed]	309	restrict { KEYWORD_RETURN(RESTRICT); } // C99
	310	__restrict { KEYWORD_RETURN(RESTRICT); } // GCC
	311	__restrict__ { KEYWORD_RETURN(RESTRICT); } // GCC
[3848e0e]	312	return { KEYWORD_RETURN(RETURN); }
[25744d2]	313	/* resume { KEYWORD_RETURN(RESUME); } // CFA */
[3848e0e]	314	short { KEYWORD_RETURN(SHORT); }
	315	signed { KEYWORD_RETURN(SIGNED); }
[b87a5ed]	316	__signed { KEYWORD_RETURN(SIGNED); } // GCC
	317	__signed__ { KEYWORD_RETURN(SIGNED); } // GCC
[3848e0e]	318	sizeof { KEYWORD_RETURN(SIZEOF); }
	319	static { KEYWORD_RETURN(STATIC); }
[b87a5ed]	320	_Static_assert { KEYWORD_RETURN(STATICASSERT); } // C11
[01fac29]	321	_static_assert { KEYWORD_RETURN(STATICASSERT); } // C23
[3848e0e]	322	struct { KEYWORD_RETURN(STRUCT); }
[37cdd97]	323	suspend { KEYWORD_RETURN(SUSPEND); } // CFA
[3848e0e]	324	switch { KEYWORD_RETURN(SWITCH); }
[bd4d011]	325	thread { KEYWORD_RETURN(THREAD); } // C11
[ed9a1ae]	326	__thread { KEYWORD_RETURN(THREADLOCALGCC); } // GCC
	327	_Thread_local { KEYWORD_RETURN(THREADLOCALC11); } // C11
[b87a5ed]	328	throw { KEYWORD_RETURN(THROW); } // CFA
[02e5ab6]	329	throwResume { KEYWORD_RETURN(THROWRESUME); } // CFA
[5b2edbc]	330	timeout { QKEYWORD_RETURN(TIMEOUT); } // CFA
[4040425]	331	trait { KEYWORD_RETURN(TRAIT); } // CFA
[b87a5ed]	332	try { KEYWORD_RETURN(TRY); } // CFA
[8f60f0b]	333	ttype { KEYWORD_RETURN(TTYPE); } // CFA
[3848e0e]	334	typedef { KEYWORD_RETURN(TYPEDEF); }
[b87a5ed]	335	typeof { KEYWORD_RETURN(TYPEOF); } // GCC
	336	__typeof { KEYWORD_RETURN(TYPEOF); } // GCC
	337	__typeof__ { KEYWORD_RETURN(TYPEOF); } // GCC
[1f652a7]	338	typeid { KEYWORD_RETURN(TYPEID); } // GCC
[3848e0e]	339	union { KEYWORD_RETURN(UNION); }
[f1da02c]	340	__uint128_t { KEYWORD_RETURN(UINT128); } // GCC
[3848e0e]	341	unsigned { KEYWORD_RETURN(UNSIGNED); }
[59c7e3e]	342	__builtin_va_arg { KEYWORD_RETURN(VA_ARG); } // GCC
	343	__builtin_va_list { KEYWORD_RETURN(VA_LIST); } // GCC
[72457b6]	344	virtual { KEYWORD_RETURN(VIRTUAL); } // CFA
[3848e0e]	345	void { KEYWORD_RETURN(VOID); }
	346	volatile { KEYWORD_RETURN(VOLATILE); }
[b87a5ed]	347	__volatile { KEYWORD_RETURN(VOLATILE); } // GCC
	348	__volatile__ { KEYWORD_RETURN(VOLATILE); } // GCC
[1f652a7]	349	vtable { KEYWORD_RETURN(VTABLE); } // CFA
[9fb1367]	350	waitfor { KEYWORD_RETURN(WAITFOR); } // CFA
[466787a]	351	waituntil { KEYWORD_RETURN(WAITUNTIL); } // CFA
[9fb1367]	352	when { KEYWORD_RETURN(WHEN); } // CFA
[3848e0e]	353	while { KEYWORD_RETURN(WHILE); }
[8b47e50]	354	with { KEYWORD_RETURN(WITH); } // CFA
[3a2128f]	355	zero_t { NUMERIC_RETURN(ZERO_T); } // CFA
[51b7345]	356
[b87a5ed]	357	/* identifier */
	358	{identifier} { IDENTIFIER_RETURN(); }
[095ac99]	359	"``"{identifier} { // CFA
	360	yytext[yyleng] = '\0'; yytext += 2; // SKULLDUGGERY: remove backquotes (ok to shorten?)
[dc7db63]	361	IDENTIFIER_RETURN();
	362	}
[51b7345]	363
[b87a5ed]	364	/* numeric constants */
[0a2168f]	365	{binary_constant} { NUMERIC_RETURN(INTEGERconstant); }
[59db689]	366	{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
[0a2168f]	367	{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
[59db689]	368	{hex_constant} { NUMERIC_RETURN(INTEGERconstant); }
[930f69e]	369	{floating_decimal} { NUMERIC_RETURN(FLOATING_DECIMALconstant); } // must appear before floating_constant
	370	{floating_fraction} { NUMERIC_RETURN(FLOATING_FRACTIONconstant); } // must appear before floating_constant
[3848e0e]	371	{floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
	372	{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
[51b7345]	373
[b87a5ed]	374	/* character constant, allows empty value */
[9ed4f94]	375	({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new string( yytext, yyleng ); }
[c1c1112]	376	<QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); }
[dc7db63]	377	<QUOTE>['\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); }
[930f69e]	378	/* ' stop editor highlighting */
[51b7345]	379
[b87a5ed]	380	/* string constant */
[9ed4f94]	381	({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new string( yytext, yyleng ); }
[c1c1112]	382	<STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); }
[dc7db63]	383	<STRING>["\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); }
[930f69e]	384	/* " stop editor highlighting */
[51b7345]	385
[59db689]	386	/* common character/string constant */
[c1c1112]	387	<QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); }
[cd623a4]	388	<QUOTE,STRING>"\\"{h_white}*"\n" {} // continuation (ALSO HANDLED BY CPP)
[c1c1112]	389	<QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character
[3848e0e]	390
[b87a5ed]	391	/* punctuation */
[615a096]	392	"@" { ASCIIOP_RETURN(); }
[dc7db63]	393	"`" { ASCIIOP_RETURN(); }
[b87a5ed]	394	"[" { ASCIIOP_RETURN(); }
	395	"]" { ASCIIOP_RETURN(); }
	396	"(" { ASCIIOP_RETURN(); }
	397	")" { ASCIIOP_RETURN(); }
	398	"{" { ASCIIOP_RETURN(); }
	399	"}" { ASCIIOP_RETURN(); }
	400	"," { ASCIIOP_RETURN(); } // also operator
	401	":" { ASCIIOP_RETURN(); }
	402	";" { ASCIIOP_RETURN(); }
	403	"." { ASCIIOP_RETURN(); } // also operator
[3848e0e]	404	"..." { NAMEDOP_RETURN(ELLIPSIS); }
	405
[b87a5ed]	406	/* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
[3848e0e]	407	"<:" { RETURN_VAL('['); }
	408	":>" { RETURN_VAL(']'); }
	409	"<%" { RETURN_VAL('{'); }
	410	"%>" { RETURN_VAL('}'); }
[51b7345]	411
[b87a5ed]	412	/* operators */
	413	"!" { ASCIIOP_RETURN(); }
	414	"+" { ASCIIOP_RETURN(); }
	415	"-" { ASCIIOP_RETURN(); }
	416	"*" { ASCIIOP_RETURN(); }
[e5f2a67]	417	"\\" { ASCIIOP_RETURN(); } // CFA, exponentiation
[b87a5ed]	418	"/" { ASCIIOP_RETURN(); }
	419	"%" { ASCIIOP_RETURN(); }
	420	"^" { ASCIIOP_RETURN(); }
	421	"~" { ASCIIOP_RETURN(); }
	422	"&" { ASCIIOP_RETURN(); }
	423	"\|" { ASCIIOP_RETURN(); }
	424	"<" { ASCIIOP_RETURN(); }
	425	">" { ASCIIOP_RETURN(); }
	426	"=" { ASCIIOP_RETURN(); }
	427	"?" { ASCIIOP_RETURN(); }
[3848e0e]	428
	429	"++" { NAMEDOP_RETURN(ICR); }
	430	"--" { NAMEDOP_RETURN(DECR); }
	431	"==" { NAMEDOP_RETURN(EQ); }
	432	"!=" { NAMEDOP_RETURN(NE); }
	433	"<<" { NAMEDOP_RETURN(LS); }
	434	">>" { NAMEDOP_RETURN(RS); }
	435	"<=" { NAMEDOP_RETURN(LE); }
	436	">=" { NAMEDOP_RETURN(GE); }
	437	"&&" { NAMEDOP_RETURN(ANDAND); }
	438	"\|\|" { NAMEDOP_RETURN(OROR); }
	439	"->" { NAMEDOP_RETURN(ARROW); }
	440	"+=" { NAMEDOP_RETURN(PLUSassign); }
	441	"-=" { NAMEDOP_RETURN(MINUSassign); }
[e5f2a67]	442	"\\=" { NAMEDOP_RETURN(EXPassign); } // CFA, exponentiation
[3848e0e]	443	"*=" { NAMEDOP_RETURN(MULTassign); }
	444	"/=" { NAMEDOP_RETURN(DIVassign); }
	445	"%=" { NAMEDOP_RETURN(MODassign); }
	446	"&=" { NAMEDOP_RETURN(ANDassign); }
	447	"\|=" { NAMEDOP_RETURN(ORassign); }
	448	"^=" { NAMEDOP_RETURN(ERassign); }
	449	"<<=" { NAMEDOP_RETURN(LSassign); }
	450	">>=" { NAMEDOP_RETURN(RSassign); }
[51b7345]	451
[08061589]	452	"@=" { NAMEDOP_RETURN(ATassign); } // CFA
[d69f4bb4]	453	"~=" { NAMEDOP_RETURN(ErangeUpEq); } // CFA
	454	"-~" { NAMEDOP_RETURN(ErangeDown); } // CFA
	455	"-~=" { NAMEDOP_RETURN(ErangeDownEq); } // CFA
[097e2b0]	456
[b87a5ed]	457	/* CFA, operator identifier */
	458	{op_unary}"?" { IDENTIFIER_RETURN(); } // unary
[a61fea9a]	459	"?"({op_unary_pre_post}\|"()"\|"[?]"\|"{}") { IDENTIFIER_RETURN(); }
[76c62b2]	460	"^?{}" { IDENTIFIER_RETURN(); }
[60a8062]	461	"?`"{identifier} { // postfix operator
	462	yylval.tok.str = new string( &yytext[2] ); // remove ?`
	463	yylval.tok.str = build_postfix_name( yylval.tok.str ); // add prefix
	464	RETURN_LOCN( typedefTable.isKind( *yylval.tok.str ) );
	465	}
[b87a5ed]	466	"?"{op_binary_over}"?" { IDENTIFIER_RETURN(); } // binary
[51b7345]	467	/*
[daf9671]	468	This rule handles ambiguous cases with operator identifiers, e.g., "int ??()", where the string "??" can be
	469	lexed as "?"/"?" or ""/"??". Since it is common practise to put a unary operator juxtaposed to an identifier,
	470	e.g., "*i", users will be annoyed if they cannot do this with respect to operator identifiers. Therefore, there is
	471	a lexical look-ahead for the second case, with backtracking to return the leading unary operator and then
	472	reparsing the trailing operator identifier. Otherwise a space is needed between the unary operator and operator
	473	identifier to disambiguate this common case.
	474
	475	A similar issue occurs with the dereference, *?(...), and routine-call, ?()(...) identifiers. The ambiguity
	476	occurs when the deference operator has no parameters, ?() and ?()(...), requiring arbitrary whitespace
	477	look-ahead for the routine-call parameter-list to disambiguate. However, the dereference operator must have a
	478	parameter/argument to dereference ?(...). Hence, always interpreting the string ?() as * ?() does not preclude
	479	any meaningful program.
	480
	481	The remaining cases are with the increment/decrement operators and conditional expression:
	482
	483	i++? ...(...);
	484	i?++ ...(...);
	485
	486	requiring arbitrary whitespace look-ahead for the operator parameter-list, even though that interpretation is an
	487	incorrect expression (juxtaposed identifiers). Therefore, it is necessary to disambiguate these cases with a
	488	space:
	489
	490	i++ ? i : 0;
	491	i? ++i : 0;
[51b7345]	492	*/
[daf9671]	493	{op_unary}"?"({op_unary_pre_post}\|"()"\|"[?]"\|{op_binary_over}"?") {
[b87a5ed]	494	// 1 or 2 character unary operator ?
	495	int i = yytext[1] == '?' ? 1 : 2;
	496	yyless( i ); // put back characters up to first '?'
	497	if ( i > 1 ) {
	498	NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
	499	} else {
	500	ASCIIOP_RETURN();
	501	} // if
	502	}
	503
[9ed4f94]	504	/* unknown character */
	505	. { yyerror( "unknown character" ); }
[51b7345]	506
	507	%%
[8551b859]	508
[9ed4f94]	509	// ----end of lexer----
	510
	511	void yyerror( const char * errmsg ) {
[8551b859]	512	SemanticErrorThrow = true;
[a8615fd1]	513	cerr << (yyfilename ? yyfilename : "unknown file") << ':' << yylineno << ':' << column - yyleng + 1
[79a6b17]	514	<< ": " << ErrorHelpers::error_str() << errmsg << " before token \"" << (yytext[0] == '\0' ? "EOF" : yytext) << '"' << endl;
[9ed4f94]	515	}
[51b7345]	516
[b87a5ed]	517	// Local Variables: //
	518	// mode: c++ //
[de62360d]	519	// tab-width: 4 //
[b87a5ed]	520	// compile-command: "make install" //
	521	// End: //

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format