Context Navigation

lex.ll@ 84b08d4

Visit:

ADT aaron-thesis arm-eh ast-experimental cleanup-dtors ctor deferred_resn demangler enum forall-pointer-decay gc_noraii jacob/cs343-translation jenkins-sandbox memory new-ast new-ast-unique-expr new-env no_list persistent-indexer pthread-emulation qualifiedEnum resolv-new with_gc

Last change on this file since 84b08d4 was 097e2b0, checked in by Peter A. Buhr <pabuhr@…>, 10 years ago
constructor/destructor, more example programs
Property mode set to `100644`
File size: 15.0 KB

Rev	Line
[b87a5ed]	1	/*
	2	* Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
	3	*
	4	* The contents of this file are covered under the licence agreement in the
	5	* file "LICENCE" distributed with Cforall.
[51b73452]	6	*
	7	* lex.l --
	8	*
	9	* Author : Peter A. Buhr
	10	* Created On : Sat Sep 22 08:58:10 2001
	11	* Last Modified By : Peter A. Buhr
[097e2b0]	12	* Last Modified On : Thu Oct 8 16:13:07 2015
	13	* Update Count : 404
[51b73452]	14	*/
	15
	16	%option yylineno
[5f2f2d7]	17	%option nounput
[51b73452]	18
	19	%{
[de62360d]	20	// This lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
	21	// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
	22	// line-number directives) and C/C++ style comments, which are ignored.
[51b73452]	23
[8c17ab0]	24	//************************** Includes and Defines **************************
[51b73452]	25
	26	#include <string>
	27
	28	#include "lex.h"
	29	#include "ParseNode.h"
[59db689]	30	#include "parser.h" // YACC generated definitions based on C++ grammar
[51b73452]	31
	32	char *yyfilename;
[b87a5ed]	33	std::string *strtext; // accumulate parts of character and string constant value
[51b73452]	34
[de62360d]	35	#define RETURN_LOCN(x) yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
	36	#define RETURN_VAL(x) yylval.tok.str = new std::string( yytext ); RETURN_LOCN( x )
	37	#define RETURN_CHAR(x) yylval.tok.str = NULL; RETURN_LOCN( x )
	38	#define RETURN_STR(x) yylval.tok.str = strtext; RETURN_LOCN( x )
[5f2f2d7]	39
[b87a5ed]	40	#define WHITE_RETURN(x) // do nothing
[de62360d]	41	#define NEWLINE_RETURN() WHITE_RETURN( '\n' )
	42	#define ASCIIOP_RETURN() RETURN_CHAR( (int)yytext[0] ) // single character operator
	43	#define NAMEDOP_RETURN(x) RETURN_VAL( x ) // multichar operator, with a name
	44	#define NUMERIC_RETURN(x) rm_underscore(); RETURN_VAL( x ) // numeric constant
	45	#define KEYWORD_RETURN(x) RETURN_CHAR( x ) // keyword
	46	#define IDENTIFIER_RETURN() RETURN_VAL( (typedefTable.isIdentifier( yytext ) ? IDENTIFIER : typedefTable.isTypedef( yytext ) ? TYPEDEFname : TYPEGENname ) )
	47	#define ATTRIBUTE_RETURN() RETURN_VAL( ATTR_IDENTIFIER )
[51b73452]	48
[3848e0e]	49	void rm_underscore() {
[b87a5ed]	50	// remove underscores in numeric constant
	51	int j = 0;
	52	for ( int i = 0; yytext[i] != '\0'; i += 1 ) {
	53	if ( yytext[i] != '_' ) {
	54	yytext[j] = yytext[i];
	55	j += 1;
	56	} // if
	57	} // for
	58	yyleng = j;
	59	yytext[yyleng] = '\0';
[51b73452]	60	}
	61
	62	%}
	63
	64	octal [0-7]
	65	nonzero [1-9]
	66	decimal [0-9]
	67	hex [0-9a-fA-F]
[3848e0e]	68	universal_char "\\"((u"_"?{hex_quad})\|(U"_"?{hex_quad}{2}))
[51b73452]	69
[b87a5ed]	70	// identifier, GCC: $ in identifier
[51b73452]	71	identifier ([a-zA-Z_$]\|{universal_char})([0-9a-zA-Z_$]\|{universal_char})*
	72
[b87a5ed]	73	// quoted identifier
[8c17ab0]	74	quoted_identifier "`"{identifier}"`"
	75
[b87a5ed]	76	// attribute identifier, GCC: $ in identifier
[51b73452]	77	attr_identifier "@"{identifier}
	78
[b87a5ed]	79	// numeric constants, CFA: '_' in constant
[3848e0e]	80	hex_quad {hex}("_"?{hex}){3}
[51b73452]	81	integer_suffix "_"?(([uU][lL]?)\|([uU]("ll"\|"LL")?)\|([lL][uU]?)\|("ll"\|"LL")[uU]?)
	82
	83	octal_digits ({octal})\|({octal}({octal}\|"_")*{octal})
	84	octal_prefix "0""_"?
	85	octal_constant (("0")\|({octal_prefix}{octal_digits})){integer_suffix}?
	86
	87	nonzero_digits ({nonzero})\|({nonzero}({decimal}\|"_")*{decimal})
	88	decimal_constant {nonzero_digits}{integer_suffix}?
	89
	90	hex_digits ({hex})\|({hex}({hex}\|"_")*{hex})
	91	hex_prefix "0"[xX]"_"?
	92	hex_constant {hex_prefix}{hex_digits}{integer_suffix}?
	93
	94	decimal_digits ({decimal})\|({decimal}({decimal}\|"_")*{decimal})
	95	fractional_constant ({decimal_digits}?"."{decimal_digits})\|({decimal_digits}".")
	96	exponent "_"?[eE]"_"?[+-]?{decimal_digits}
	97	floating_suffix "_"?[flFL]
	98	floating_constant (({fractional_constant}{exponent}?)\|({decimal_digits}{exponent})){floating_suffix}?
	99
	100	binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
	101	hex_fractional_constant ({hex_digits}?"."{hex_digits})\|({hex_digits}".")
	102	hex_floating_constant {hex_prefix}(({hex_fractional_constant}{binary_exponent})\|({hex_digits}{binary_exponent})){floating_suffix}?
	103
[b87a5ed]	104	// character escape sequence, GCC: \e => esc character
[51b73452]	105	simple_escape "\\"[abefnrtv'"?\\]
[b87a5ed]	106	// ' stop highlighting
[3848e0e]	107	octal_escape "\\"{octal}("_"?{octal}){0,2}
	108	hex_escape "\\""x""_"?{hex_digits}
[51b73452]	109	escape_seq {simple_escape}\|{octal_escape}\|{hex_escape}\|{universal_char}
[59db689]	110	cwide_prefix "L"\|"U"\|"u"
	111	swide_prefix {cwide_prefix}\|"u8"
[51b73452]	112
[b87a5ed]	113	// display/white-space characters
[51b73452]	114	h_tab [\011]
	115	form_feed [\014]
	116	v_tab [\013]
	117	c_return [\015]
	118	h_white [ ]\|{h_tab}
	119
[b87a5ed]	120	// operators
[51b73452]	121	op_unary_only "~"\|"!"
	122	op_unary_binary "+"\|"-"\|"*"
	123	op_unary_pre_post "++"\|"--"
	124	op_unary {op_unary_only}\|{op_unary_binary}\|{op_unary_pre_post}
	125
	126	op_binary_only "/"\|"%"\|"^"\|"&"\|"\|"\|"<"\|">"\|"="\|"=="\|"!="\|"<<"\|">>"\|"<="\|">="\|"+="\|"-="\|"*="\|"/="\|"%="\|"&="\|"\|="\|"^="\|"<<="\|">>="
	127	op_binary_over {op_unary_binary}\|{op_binary_only}
	128	op_binary_not_over "?"\|"->"\|"&&"\|"\|\|"
	129	operator {op_unary_pre_post}\|{op_binary_over}\|{op_binary_not_over}
	130
	131	%x COMMENT
[3848e0e]	132	%x BKQUOTE
	133	%x QUOTE
	134	%x STRING
[51b73452]	135
	136	%%
[b87a5ed]	137	/* line directives */
[51b73452]	138	^{h_white}"#"{h_white}[0-9]+{h_white}["][^"\n]+["][^\n]"\n" {
[8c17ab0]	139	/* " stop highlighting */
[51b73452]	140	char *end_num;
	141	char begin_string, end_string;
	142	char *filename;
	143	long lineno, length;
	144	lineno = strtol( yytext + 1, &end_num, 0 );
	145	begin_string = strchr( end_num, '"' );
[3848e0e]	146	if ( begin_string ) {
[b87a5ed]	147	end_string = strchr( begin_string + 1, '"' );
	148	if ( end_string ) {
	149	length = end_string - begin_string - 1;
	150	filename = new char[ length + 1 ];
	151	memcpy( filename, begin_string + 1, length );
	152	filename[ length ] = '\0';
	153	//std::cout << "file " << filename << " line " << lineno << std::endl;
	154	yylineno = lineno;
	155	yyfilename = filename;
	156	} // if
	157	} // if
[51b73452]	158	}
	159
[b87a5ed]	160	/* ignore preprocessor directives (for now) */
[51b73452]	161	^{h_white}"#"[^\n]"\n" ;
	162
[cd623a4]	163	/* ignore C style comments (ALSO HANDLED BY CPP) */
[3848e0e]	164	"/*" { BEGIN COMMENT; }
[cd623a4]	165	<COMMENT>.\|\n ;
	166	<COMMENT>"*/" { BEGIN 0; }
[51b73452]	167
[cd623a4]	168	/* ignore C++ style comments (ALSO HANDLED BY CPP) */
	169	"//"[^\n]*"\n" ;
[51b73452]	170
[b87a5ed]	171	/* ignore whitespace */
[3848e0e]	172	{h_white}+ { WHITE_RETURN(' '); }
	173	({v_tab}\|{c_return}\|{form_feed})+ { WHITE_RETURN(' '); }
	174	({h_white}\|{v_tab}\|{c_return}\|{form_feed})*"\n" { NEWLINE_RETURN(); }
[51b73452]	175
[b87a5ed]	176	/* keywords */
	177	_Alignas { KEYWORD_RETURN(ALIGNAS); } // C11
	178	_Alignof { KEYWORD_RETURN(ALIGNOF); } // C11
	179	__alignof { KEYWORD_RETURN(ALIGNOF); } // GCC
	180	__alignof__ { KEYWORD_RETURN(ALIGNOF); } // GCC
	181	asm { KEYWORD_RETURN(ASM); }
	182	__asm { KEYWORD_RETURN(ASM); } // GCC
	183	__asm__ { KEYWORD_RETURN(ASM); } // GCC
[02e5ab6]	184	_At { KEYWORD_RETURN(AT); } // CFA
[b87a5ed]	185	_Atomic { KEYWORD_RETURN(ATOMIC); } // C11
	186	__attribute { KEYWORD_RETURN(ATTRIBUTE); } // GCC
	187	__attribute__ { KEYWORD_RETURN(ATTRIBUTE); } // GCC
[3848e0e]	188	auto { KEYWORD_RETURN(AUTO); }
[b87a5ed]	189	_Bool { KEYWORD_RETURN(BOOL); } // C99
[3848e0e]	190	break { KEYWORD_RETURN(BREAK); }
	191	case { KEYWORD_RETURN(CASE); }
[b87a5ed]	192	catch { KEYWORD_RETURN(CATCH); } // CFA
[02e5ab6]	193	catchResume { KEYWORD_RETURN(CATCHRESUME); } // CFA
[3848e0e]	194	char { KEYWORD_RETURN(CHAR); }
[b87a5ed]	195	choose { KEYWORD_RETURN(CHOOSE); } // CFA
	196	_Complex { KEYWORD_RETURN(COMPLEX); } // C99
	197	__complex { KEYWORD_RETURN(COMPLEX); } // GCC
	198	__complex__ { KEYWORD_RETURN(COMPLEX); } // GCC
[3848e0e]	199	const { KEYWORD_RETURN(CONST); }
[b87a5ed]	200	__const { KEYWORD_RETURN(CONST); } // GCC
	201	__const__ { KEYWORD_RETURN(CONST); } // GCC
	202	context { KEYWORD_RETURN(CONTEXT); } // CFA
[3848e0e]	203	continue { KEYWORD_RETURN(CONTINUE); }
	204	default { KEYWORD_RETURN(DEFAULT); }
[02e5ab6]	205	disable { KEYWORD_RETURN(DISABLE); } // CFA
[b87a5ed]	206	do { KEYWORD_RETURN(DO); }
[3848e0e]	207	double { KEYWORD_RETURN(DOUBLE); }
[b87a5ed]	208	dtype { KEYWORD_RETURN(DTYPE); } // CFA
[3848e0e]	209	else { KEYWORD_RETURN(ELSE); }
[02e5ab6]	210	enable { KEYWORD_RETURN(ENABLE); } // CFA
[3848e0e]	211	enum { KEYWORD_RETURN(ENUM); }
[b87a5ed]	212	__extension__ { KEYWORD_RETURN(EXTENSION); } // GCC
[3848e0e]	213	extern { KEYWORD_RETURN(EXTERN); }
[b87a5ed]	214	fallthru { KEYWORD_RETURN(FALLTHRU); } // CFA
	215	finally { KEYWORD_RETURN(FINALLY); } // CFA
[3848e0e]	216	float { KEYWORD_RETURN(FLOAT); }
[b87a5ed]	217	__float128 { KEYWORD_RETURN(FLOAT); } // GCC
	218	for { KEYWORD_RETURN(FOR); }
	219	forall { KEYWORD_RETURN(FORALL); } // CFA
[3848e0e]	220	fortran { KEYWORD_RETURN(FORTRAN); }
[b87a5ed]	221	ftype { KEYWORD_RETURN(FTYPE); } // CFA
	222	_Generic { KEYWORD_RETURN(GENERIC); } // C11
[3848e0e]	223	goto { KEYWORD_RETURN(GOTO); }
[b87a5ed]	224	if { KEYWORD_RETURN(IF); }
	225	_Imaginary { KEYWORD_RETURN(IMAGINARY); } // C99
	226	__imag { KEYWORD_RETURN(IMAGINARY); } // GCC
	227	__imag__ { KEYWORD_RETURN(IMAGINARY); } // GCC
	228	inline { KEYWORD_RETURN(INLINE); } // C99
	229	__inline { KEYWORD_RETURN(INLINE); } // GCC
	230	__inline__ { KEYWORD_RETURN(INLINE); } // GCC
	231	int { KEYWORD_RETURN(INT); }
	232	__int128 { KEYWORD_RETURN(INT); } // GCC
	233	__label__ { KEYWORD_RETURN(LABEL); } // GCC
[3848e0e]	234	long { KEYWORD_RETURN(LONG); }
[b87a5ed]	235	lvalue { KEYWORD_RETURN(LVALUE); } // CFA
	236	_Noreturn { KEYWORD_RETURN(NORETURN); } // C11
[3848e0e]	237	register { KEYWORD_RETURN(REGISTER); }
[b87a5ed]	238	restrict { KEYWORD_RETURN(RESTRICT); } // C99
	239	__restrict { KEYWORD_RETURN(RESTRICT); } // GCC
	240	__restrict__ { KEYWORD_RETURN(RESTRICT); } // GCC
[3848e0e]	241	return { KEYWORD_RETURN(RETURN); }
	242	short { KEYWORD_RETURN(SHORT); }
	243	signed { KEYWORD_RETURN(SIGNED); }
[b87a5ed]	244	__signed { KEYWORD_RETURN(SIGNED); } // GCC
	245	__signed__ { KEYWORD_RETURN(SIGNED); } // GCC
[3848e0e]	246	sizeof { KEYWORD_RETURN(SIZEOF); }
	247	static { KEYWORD_RETURN(STATIC); }
[b87a5ed]	248	_Static_assert { KEYWORD_RETURN(STATICASSERT); } // C11
[3848e0e]	249	struct { KEYWORD_RETURN(STRUCT); }
	250	switch { KEYWORD_RETURN(SWITCH); }
[b87a5ed]	251	_Thread_local { KEYWORD_RETURN(THREADLOCAL); } // C11
	252	throw { KEYWORD_RETURN(THROW); } // CFA
[02e5ab6]	253	throwResume { KEYWORD_RETURN(THROWRESUME); } // CFA
[b87a5ed]	254	try { KEYWORD_RETURN(TRY); } // CFA
	255	type { KEYWORD_RETURN(TYPE); } // CFA
[3848e0e]	256	typedef { KEYWORD_RETURN(TYPEDEF); }
[b87a5ed]	257	typeof { KEYWORD_RETURN(TYPEOF); } // GCC
	258	__typeof { KEYWORD_RETURN(TYPEOF); } // GCC
	259	__typeof__ { KEYWORD_RETURN(TYPEOF); } // GCC
[3848e0e]	260	union { KEYWORD_RETURN(UNION); }
	261	unsigned { KEYWORD_RETURN(UNSIGNED); }
	262	void { KEYWORD_RETURN(VOID); }
	263	volatile { KEYWORD_RETURN(VOLATILE); }
[b87a5ed]	264	__volatile { KEYWORD_RETURN(VOLATILE); } // GCC
	265	__volatile__ { KEYWORD_RETURN(VOLATILE); } // GCC
[3848e0e]	266	while { KEYWORD_RETURN(WHILE); }
[51b73452]	267
[b87a5ed]	268	/* identifier */
	269	{identifier} { IDENTIFIER_RETURN(); }
	270	{attr_identifier} { ATTRIBUTE_RETURN(); }
[3848e0e]	271	"`" { BEGIN BKQUOTE; }
[b87a5ed]	272	<BKQUOTE>{identifier} { IDENTIFIER_RETURN(); }
	273	<BKQUOTE>"`" { BEGIN 0; }
[51b73452]	274
[b87a5ed]	275	/* numeric constants */
	276	"0" { NUMERIC_RETURN(ZERO); } // CFA
	277	"1" { NUMERIC_RETURN(ONE); } // CFA
[59db689]	278	{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
	279	{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
	280	{hex_constant} { NUMERIC_RETURN(INTEGERconstant); }
[3848e0e]	281	{floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
	282	{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
[51b73452]	283
[b87a5ed]	284	/* character constant, allows empty value */
[59db689]	285	({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new std::string; *strtext += std::string( yytext ); }
[b87a5ed]	286	<QUOTE>[^'\\\n]* { *strtext += std::string( yytext ); }
	287	<QUOTE>['\n] { BEGIN 0; *strtext += std::string( yytext); RETURN_STR(CHARACTERconstant); }
	288	/* ' stop highlighting */
[51b73452]	289
[b87a5ed]	290	/* string constant */
[59db689]	291	({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new std::string; *strtext += std::string( yytext ); }
[b87a5ed]	292	<STRING>[^"\\\n]* { *strtext += std::string( yytext ); }
[59db689]	293	<STRING>["\n] { BEGIN 0; *strtext += std::string( yytext ); RETURN_STR(STRINGliteral); }
[b87a5ed]	294	/* " stop highlighting */
[51b73452]	295
[59db689]	296	/* common character/string constant */
[3848e0e]	297	<QUOTE,STRING>{escape_seq} { rm_underscore(); *strtext += std::string( yytext ); }
[cd623a4]	298	<QUOTE,STRING>"\\"{h_white}*"\n" {} // continuation (ALSO HANDLED BY CPP)
[59db689]	299	<QUOTE,STRING>"\\" { *strtext += std::string( yytext ); } // unknown escape character
[3848e0e]	300
[b87a5ed]	301	/* punctuation */
	302	"[" { ASCIIOP_RETURN(); }
	303	"]" { ASCIIOP_RETURN(); }
	304	"(" { ASCIIOP_RETURN(); }
	305	")" { ASCIIOP_RETURN(); }
	306	"{" { ASCIIOP_RETURN(); }
	307	"}" { ASCIIOP_RETURN(); }
	308	"," { ASCIIOP_RETURN(); } // also operator
	309	":" { ASCIIOP_RETURN(); }
	310	";" { ASCIIOP_RETURN(); }
	311	"." { ASCIIOP_RETURN(); } // also operator
[3848e0e]	312	"..." { NAMEDOP_RETURN(ELLIPSIS); }
	313
[b87a5ed]	314	/* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
[3848e0e]	315	"<:" { RETURN_VAL('['); }
	316	":>" { RETURN_VAL(']'); }
	317	"<%" { RETURN_VAL('{'); }
	318	"%>" { RETURN_VAL('}'); }
[51b73452]	319
[b87a5ed]	320	/* operators */
	321	"!" { ASCIIOP_RETURN(); }
	322	"+" { ASCIIOP_RETURN(); }
	323	"-" { ASCIIOP_RETURN(); }
	324	"*" { ASCIIOP_RETURN(); }
	325	"/" { ASCIIOP_RETURN(); }
	326	"%" { ASCIIOP_RETURN(); }
	327	"^" { ASCIIOP_RETURN(); }
	328	"~" { ASCIIOP_RETURN(); }
	329	"&" { ASCIIOP_RETURN(); }
	330	"\|" { ASCIIOP_RETURN(); }
	331	"<" { ASCIIOP_RETURN(); }
	332	">" { ASCIIOP_RETURN(); }
	333	"=" { ASCIIOP_RETURN(); }
	334	"?" { ASCIIOP_RETURN(); }
[3848e0e]	335
	336	"++" { NAMEDOP_RETURN(ICR); }
	337	"--" { NAMEDOP_RETURN(DECR); }
	338	"==" { NAMEDOP_RETURN(EQ); }
	339	"!=" { NAMEDOP_RETURN(NE); }
	340	"<<" { NAMEDOP_RETURN(LS); }
	341	">>" { NAMEDOP_RETURN(RS); }
	342	"<=" { NAMEDOP_RETURN(LE); }
	343	">=" { NAMEDOP_RETURN(GE); }
	344	"&&" { NAMEDOP_RETURN(ANDAND); }
	345	"\|\|" { NAMEDOP_RETURN(OROR); }
	346	"->" { NAMEDOP_RETURN(ARROW); }
	347	"+=" { NAMEDOP_RETURN(PLUSassign); }
	348	"-=" { NAMEDOP_RETURN(MINUSassign); }
	349	"*=" { NAMEDOP_RETURN(MULTassign); }
	350	"/=" { NAMEDOP_RETURN(DIVassign); }
	351	"%=" { NAMEDOP_RETURN(MODassign); }
	352	"&=" { NAMEDOP_RETURN(ANDassign); }
	353	"\|=" { NAMEDOP_RETURN(ORassign); }
	354	"^=" { NAMEDOP_RETURN(ERassign); }
	355	"<<=" { NAMEDOP_RETURN(LSassign); }
	356	">>=" { NAMEDOP_RETURN(RSassign); }
[51b73452]	357
[097e2b0]	358	"@=" { NAMEDOP_RETURN(ATassign); }
	359
[b87a5ed]	360	/* CFA, operator identifier */
	361	{op_unary}"?" { IDENTIFIER_RETURN(); } // unary
[a61fea9a]	362	"?"({op_unary_pre_post}\|"()"\|"[?]"\|"{}") { IDENTIFIER_RETURN(); }
[02e5ab6]	363	"^?{}" { IDENTIFIER_RETURN(); }
[b87a5ed]	364	"?"{op_binary_over}"?" { IDENTIFIER_RETURN(); } // binary
[51b73452]	365	/*
[b87a5ed]	366	This rule handles ambiguous cases with operator identifiers, e.g., "int ??()", where the string "??"
	367	can be lexed as ""/"??" or "?"/"?". Since it is common practise to put a unary operator juxtaposed
	368	to an identifier, e.g., "*i", users will be annoyed if they cannot do this with respect to operator
	369	identifiers. Even with this special hack, there are 5 general cases that cannot be handled. The first
	370	case is for the function-call identifier "?()":
[51b73452]	371
	372	int * ?()(); // declaration: space required after '*'
	373	* ?()(); // expression: space required after '*'
	374
[b87a5ed]	375	Without the space, the string "*?()" is ambiguous without N character look ahead; it requires scanning
	376	ahead to determine if there is a '(', which is the start of an argument/parameter list.
[51b73452]	377
	378	The 4 remaining cases occur in expressions:
	379
	380	i++?i:0; // space required before '?'
	381	i--?i:0; // space required before '?'
	382	i?++i:0; // space required after '?'
	383	i?--i:0; // space required after '?'
	384
[b87a5ed]	385	In the first two cases, the string "i++?" is ambiguous, where this string can be lexed as "i"/"++?" or
	386	"i++"/"?"; it requires scanning ahead to determine if there is a '(', which is the start of an argument
	387	list. In the second two cases, the string "?++x" is ambiguous, where this string can be lexed as
	388	"?++"/"x" or "?"/"++x"; it requires scanning ahead to determine if there is a '(', which is the start of
	389	an argument list.
[51b73452]	390	*/
[02e5ab6]	391	{op_unary}"?"({op_unary_pre_post}\|"[?]"\|{op_binary_over}"?") {
[b87a5ed]	392	// 1 or 2 character unary operator ?
	393	int i = yytext[1] == '?' ? 1 : 2;
	394	yyless( i ); // put back characters up to first '?'
	395	if ( i > 1 ) {
	396	NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
	397	} else {
	398	ASCIIOP_RETURN();
	399	} // if
	400	}
	401
	402	/* unknown characters */
[3848e0e]	403	. { printf("unknown character(s):\"%s\" on line %d\n", yytext, yylineno); }
[51b73452]	404
	405	%%
	406
[b87a5ed]	407	// Local Variables: //
	408	// mode: c++ //
[de62360d]	409	// tab-width: 4 //
[b87a5ed]	410	// compile-command: "make install" //
	411	// End: //

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format