Context Navigation

lex.ll@ 46c4dea

Visit:

Last change on this file since 46c4dea was 4e0168a, checked in by Peter A. Buhr <pabuhr@…>, 12 months ago
documentation, update C23 attribute lexing
Property mode set to `100644`
File size: 22.2 KB

Rev	Line
[b87a5ed]	1	/*
	2	* Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
	3	*
	4	* The contents of this file are covered under the licence agreement in the
	5	* file "LICENCE" distributed with Cforall.
[8f60f0b]	6	*
[6016c87]	7	* lex.ll --
[8f60f0b]	8	*
[51b73452]	9	* Author : Peter A. Buhr
	10	* Created On : Sat Sep 22 08:58:10 2001
[926af74]	11	* Last Modified By : Peter A. Buhr
[4e0168a]	12	* Last Modified On : Sun Oct 13 16:49:47 2024
	13	* Update Count : 876
[51b73452]	14	*/
	15
	16	%option yylineno
[4e9c7c1]	17	%option noyywrap
[5f2f2d7]	18	%option nounput
[51b73452]	19
	20	%{
[9ed4f94]	21	// The lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
[de62360d]	22	// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
	23	// line-number directives) and C/C++ style comments, which are ignored.
[51b73452]	24
[bb7422a]	25	// ************************* Includes and Defines **************************
[51b73452]	26
[0bd46fd]	27	#ifdef __clang__
	28	#pragma GCC diagnostic ignored "-Wnull-conversion"
	29	#endif
	30
[4439008]	31	// trigger before each matching rule's action
	32	#define YY_USER_ACTION \
	33	yylloc.first_line = yylineno; \
	34	yylloc.first_column = column; \
	35	column += yyleng; \
	36	yylloc.last_column = column; \
	37	yylloc.last_line = yylineno; \
	38	yylloc.filename = yyfilename ? yyfilename : "";
[9ed4f94]	39	unsigned int column = 0; // position of the end of the last token parsed
	40
[51b73452]	41	#include <string>
[f487962]	42	#include <cstdio> // FILENAME_MAX
[9ed4f94]	43	using namespace std;
[51b73452]	44
[ba01b14]	45	#include "config.h" // configure info
[c92bdcc]	46	#include "DeclarationNode.hpp" // for DeclarationNode
	47	#include "ExpressionNode.hpp" // for LabelNode
	48	#include "InitializerNode.hpp" // for InitializerNode
	49	#include "ParseNode.hpp"
	50	#include "ParserTypes.hpp" // for Token
[738a9b4]	51	#include "StatementNode.hpp" // for CondCtrl, ForCtrl
[c92bdcc]	52	#include "TypedefTable.hpp"
[c468150]	53	// This (generated) header must come late as it is missing includes.
	54	#include "parser.hh" // generated info
[51b73452]	55
[60a8062]	56	string * build_postfix_name( string * name );
	57
[51b73452]	58	char *yyfilename;
[9ed4f94]	59	string *strtext; // accumulate parts of character and string constant value
[51b73452]	60
[de62360d]	61	#define RETURN_LOCN(x) yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
[9ed4f94]	62	#define RETURN_VAL(x) yylval.tok.str = new string( yytext ); RETURN_LOCN( x )
[926af74]	63	#define RETURN_CHAR(x) yylval.tok.str = nullptr; RETURN_LOCN( x )
[de62360d]	64	#define RETURN_STR(x) yylval.tok.str = strtext; RETURN_LOCN( x )
[5f2f2d7]	65
[f487962]	66	#define WHITE_RETURN(x) // do nothing
[9ed4f94]	67	#define NEWLINE_RETURN() column = 0; WHITE_RETURN( '\n' )
[de62360d]	68	#define ASCIIOP_RETURN() RETURN_CHAR( (int)yytext[0] ) // single character operator
[f487962]	69	#define NAMEDOP_RETURN(x) RETURN_CHAR( x ) // multichar operator, with a name
[de62360d]	70	#define NUMERIC_RETURN(x) rm_underscore(); RETURN_VAL( x ) // numeric constant
	71	#define KEYWORD_RETURN(x) RETURN_CHAR( x ) // keyword
[4439008]	72	#define QKEYWORD_RETURN(x) RETURN_VAL(x); // quasi-keyword
[984dce6]	73	#define IDENTIFIER_RETURN() RETURN_VAL( typedefTable.isKind( yytext ) )
[51b73452]	74
[25744d2]	75	#ifdef HAVE_KEYWORDS_FLOATXX // GCC >= 7 => keyword, otherwise typedef
[ba01b14]	76	#define FLOATXX(v) KEYWORD_RETURN(v);
	77	#else
[37cdd97]	78	#define FLOATXX(v) IDENTIFIER_RETURN();
[ba01b14]	79	#endif // HAVE_KEYWORDS_FLOATXX
	80
[3848e0e]	81	void rm_underscore() {
[7e419e7]	82	// SKULLDUGGERY: remove underscores (ok to shorten?)
[e7aed49]	83	yyleng = 0;
[7e419e7]	84	for ( int i = 0; yytext[i] != '\0'; i += 1 ) { // copying non-underscore characters to front of string
[b87a5ed]	85	if ( yytext[i] != '_' ) {
[e7aed49]	86	yytext[yyleng] = yytext[i];
	87	yyleng += 1;
[b87a5ed]	88	} // if
	89	} // for
	90	yytext[yyleng] = '\0';
[7e419e7]	91	} // rm_underscore
[51b73452]	92
[7812f1d1]	93	// Stop warning due to incorrectly generated flex code.
	94	#pragma GCC diagnostic ignored "-Wsign-compare"
[51b73452]	95	%}
	96
[0a2168f]	97	binary [0-1]
[51b73452]	98	octal [0-7]
	99	nonzero [1-9]
	100	decimal [0-9]
	101	hex [0-9a-fA-F]
[3848e0e]	102	universal_char "\\"((u"_"?{hex_quad})\|(U"_"?{hex_quad}{2}))
[51b73452]	103
[b87a5ed]	104	// identifier, GCC: $ in identifier
[51b73452]	105	identifier ([a-zA-Z_$]\|{universal_char})([0-9a-zA-Z_$]\|{universal_char})*
	106
[b87a5ed]	107	// numeric constants, CFA: '_' in constant
[3848e0e]	108	hex_quad {hex}("_"?{hex}){3}
[201aeb9]	109	size_opt (8\|16\|32\|64\|128)?
[0a616e0]	110	// CFA: explicit l8/l16/l32/l64/l128, char 'hh', short 'h', int 'n'
[f56c32e]	111	length ("ll"\|"LL"\|[lL]{size_opt})\|("hh"\|"HH"\|[hHnN])
[0a616e0]	112	// CFA: size_t 'z', pointer 'p', which define a sign and length
	113	integer_suffix_opt ("_"?(([uU]({length}?[iI]?)\|([iI]{length}))\|([iI]({length}?[uU]?)\|([uU]{length}))\|({length}([iI]?[uU]?)\|([uU][iI]))\|[zZ]\|[pP]))?
[51b73452]	114
	115	octal_digits ({octal})\|({octal}({octal}\|"_")*{octal})
	116	octal_prefix "0""_"?
[930f69e]	117	octal_constant (("0")\|({octal_prefix}{octal_digits})){integer_suffix_opt}
[51b73452]	118
	119	nonzero_digits ({nonzero})\|({nonzero}({decimal}\|"_")*{decimal})
[930f69e]	120	decimal_constant {nonzero_digits}{integer_suffix_opt}
[51b73452]	121
[0a2168f]	122	binary_digits ({binary})\|({binary}({binary}\|"_")*{binary})
	123	binary_prefix "0"[bB]"_"?
	124	binary_constant {binary_prefix}{binary_digits}{integer_suffix_opt}
	125
[51b73452]	126	hex_digits ({hex})\|({hex}({hex}\|"_")*{hex})
	127	hex_prefix "0"[xX]"_"?
[930f69e]	128	hex_constant {hex_prefix}{hex_digits}{integer_suffix_opt}
[51b73452]	129
[d3b5a14]	130	// GCC: floating D (double), imaginary iI, and decimal floating DF, DD, DL
[51b73452]	131	exponent "_"?[eE]"_"?[+-]?{decimal_digits}
[ba01b14]	132	floating_size 16\|32\|32x\|64\|64x\|80\|128\|128x
	133	floating_length ([fFdDlLwWqQ]\|[fF]{floating_size})
[201aeb9]	134	floating_suffix ({floating_length}?[iI]?)\|([iI]{floating_length})
[d3b5a14]	135	decimal_floating_suffix [dD][fFdDlL]
	136	floating_suffix_opt ("_"?({floating_suffix}\|{decimal_floating_suffix}))?
[f4b77f2]	137	decimal_digits ({decimal})\|({decimal}({decimal}\|"_")*{decimal})
[930f69e]	138	floating_decimal {decimal_digits}"."{exponent}?{floating_suffix_opt}
	139	floating_fraction "."{decimal_digits}{exponent}?{floating_suffix_opt}
	140	floating_constant ({decimal_digits}{exponent}{floating_suffix_opt})\|({decimal_digits}{floating_fraction})
[51b73452]	141
	142	binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
[dc7db63]	143	hex_floating_suffix_opt ("_"?({floating_suffix}))?
[930f69e]	144	hex_floating_fraction ({hex_digits}?"."{hex_digits})\|({hex_digits}".")
[f4b77f2]	145	hex_floating_constant {hex_prefix}(({hex_floating_fraction}{binary_exponent})\|({hex_digits}{binary_exponent})){hex_floating_suffix_opt}
[51b73452]	146
[b87a5ed]	147	// character escape sequence, GCC: \e => esc character
[51b73452]	148	simple_escape "\\"[abefnrtv'"?\\]
[1a8b17a]	149	// " stop editor highlighting
[3848e0e]	150	octal_escape "\\"{octal}("_"?{octal}){0,2}
	151	hex_escape "\\""x""_"?{hex_digits}
[51b73452]	152	escape_seq {simple_escape}\|{octal_escape}\|{hex_escape}\|{universal_char}
[59db689]	153	cwide_prefix "L"\|"U"\|"u"
	154	swide_prefix {cwide_prefix}\|"u8"
[51b73452]	155
[b87a5ed]	156	// display/white-space characters
[1a8b17a]	157	h_tab "\t"
	158	form_feed "\f"
	159	v_tab "\v"
	160	new_line "\n"
	161	c_return "\r"
	162	h_white " "\|{h_tab}
	163	v_white {v_tab}\|{c_return}\|{form_feed}
	164	hv_white {h_white}\|{v_tab}\|{new_line}\|{c_return}\|{form_feed}
[51b73452]	165
[e7aed49]	166	// overloadable operators
[51b73452]	167	op_unary_only "~"\|"!"
	168	op_unary_binary "+"\|"-"\|"*"
	169	op_unary_pre_post "++"\|"--"
	170	op_unary {op_unary_only}\|{op_unary_binary}\|{op_unary_pre_post}
	171
[994d080]	172	op_binary_only "/"\|"%"\|"\\"\|"^"\|"&"\|"\|"\|"<"\|">"\|"="\|"=="\|"!="\|"<<"\|">>"\|"<="\|">="\|"+="\|"-="\|"*="\|"/="\|"%="\|"\\="\|"&="\|"\|="\|"^="\|"<<="\|">>="
[51b73452]	173	op_binary_over {op_unary_binary}\|{op_binary_only}
[e7aed49]	174	// op_binary_not_over "?"\|"->"\|"."\|"&&"\|"\|\|"\|"@="
	175	// operator {op_unary_pre_post}\|{op_binary_over}\|{op_binary_not_over}
[51b73452]	176
[4e0168a]	177	// C23 attributes, CPP also handles missing quote delimiter
	178	attr_string "\""([^\"\\\n]\|{escape_seq})*["\n]
	179	attr_arg_opt ({hv_white}"("({hv_white}{attr_string}{hv_white}*)+")")?
[1a8b17a]	180	attributes "deprecated"{attr_arg_opt}\|"fallthrough"\|"nodiscard"{attr_arg_opt}\|"maybe_unused"\|"noreturn"\|"_Noreturn"\|"unsequenced"\|"unused"\|"reproducible"\|{identifier}{hv_white}"::"{hv_white}{identifier}
	181
[51b73452]	182	%x COMMENT
[3848e0e]	183	%x QUOTE
	184	%x STRING
[51b73452]	185
	186	%%
[994d080]	187	/* line directives */
[4040425]	188	^{h_white}"#"{h_white}[0-9]+{h_white}["][^"\n]+["]."\n" {
[930f69e]	189	/* " stop editor highlighting */
[c1c1112]	190	static char filename[FILENAME_MAX]; // temporarily store current source-file name
[51b73452]	191	char *end_num;
	192	char begin_string, end_string;
	193	long lineno, length;
	194	lineno = strtol( yytext + 1, &end_num, 0 );
	195	begin_string = strchr( end_num, '"' );
[f487962]	196	if ( begin_string ) { // file name ?
	197	end_string = strchr( begin_string + 1, '"' ); // look for ending delimiter
	198	assert( end_string ); // closing quote ?
	199	length = end_string - begin_string - 1; // file-name length without quotes or sentinel
	200	assert( length < FILENAME_MAX ); // room for sentinel ?
	201	memcpy( &filename, begin_string + 1, length ); // copy file name from yytext
	202	filename[ length ] = '\0'; // terminate string with sentinel
[9ed4f94]	203	//cout << "file " << filename << " line " << lineno << endl;
[f487962]	204	yylineno = lineno;
[c1c1112]	205	yyfilename = filename;
[b87a5ed]	206	} // if
[51b73452]	207	}
	208
[637dd9c]	209	/* preprocessor-style directives */
[61fc4f6]	210	^{h_white}"#"[^\n]"\n" { RETURN_VAL( DIRECTIVE ); }
[51b73452]	211
[cd623a4]	212	/* ignore C style comments (ALSO HANDLED BY CPP) */
[3848e0e]	213	"/*" { BEGIN COMMENT; }
[cd623a4]	214	<COMMENT>.\|\n ;
	215	<COMMENT>"*/" { BEGIN 0; }
[51b73452]	216
[cd623a4]	217	/* ignore C++ style comments (ALSO HANDLED BY CPP) */
	218	"//"[^\n]*"\n" ;
[51b73452]	219
[b87a5ed]	220	/* ignore whitespace */
[1a8b17a]	221	({h_white}\|{v_white})+ { WHITE_RETURN(' '); } // do nothing
	222	"\n" { NEWLINE_RETURN(); } // reset column counter
[51b73452]	223
[b87a5ed]	224	/* keywords */
[46f9f02]	225	alignas { KEYWORD_RETURN(ALIGNAS); } // CFA
[b87a5ed]	226	_Alignas { KEYWORD_RETURN(ALIGNAS); } // C11
[46f9f02]	227	alignof { KEYWORD_RETURN(ALIGNOF); } // CFA
[b87a5ed]	228	_Alignof { KEYWORD_RETURN(ALIGNOF); } // C11
	229	__alignof { KEYWORD_RETURN(ALIGNOF); } // GCC
	230	__alignof__ { KEYWORD_RETURN(ALIGNOF); } // GCC
[9fd9d015]	231	and { QKEYWORD_RETURN(WAND); } // CFA
[b87a5ed]	232	asm { KEYWORD_RETURN(ASM); }
	233	__asm { KEYWORD_RETURN(ASM); } // GCC
	234	__asm__ { KEYWORD_RETURN(ASM); } // GCC
	235	_Atomic { KEYWORD_RETURN(ATOMIC); } // C11
	236	__attribute { KEYWORD_RETURN(ATTRIBUTE); } // GCC
	237	__attribute__ { KEYWORD_RETURN(ATTRIBUTE); } // GCC
[3848e0e]	238	auto { KEYWORD_RETURN(AUTO); }
[f673c13c]	239	__auto_type { KEYWORD_RETURN(AUTO_TYPE); }
[b6ad601]	240	basetypeof { KEYWORD_RETURN(BASETYPEOF); } // CFA
[b87a5ed]	241	_Bool { KEYWORD_RETURN(BOOL); } // C99
[c5f69fd]	242	__SVBool_t { KEYWORD_RETURN(SVBOOL); } // gcc (ARM)
[3848e0e]	243	break { KEYWORD_RETURN(BREAK); }
	244	case { KEYWORD_RETURN(CASE); }
[9fb1367]	245	catch { QKEYWORD_RETURN(CATCH); } // CFA
	246	catchResume { QKEYWORD_RETURN(CATCHRESUME); } // CFA
[3848e0e]	247	char { KEYWORD_RETURN(CHAR); }
[b87a5ed]	248	choose { KEYWORD_RETURN(CHOOSE); } // CFA
[1528a2c]	249	coerce { KEYWORD_RETURN(COERCE); } // CFA
[11ab0b4a]	250	corun { KEYWORD_RETURN(CORUN); } // CFA
	251	cofor { KEYWORD_RETURN(COFOR); } // CFA
[b87a5ed]	252	_Complex { KEYWORD_RETURN(COMPLEX); } // C99
	253	__complex { KEYWORD_RETURN(COMPLEX); } // GCC
	254	__complex__ { KEYWORD_RETURN(COMPLEX); } // GCC
[3848e0e]	255	const { KEYWORD_RETURN(CONST); }
[b87a5ed]	256	__const { KEYWORD_RETURN(CONST); } // GCC
	257	__const__ { KEYWORD_RETURN(CONST); } // GCC
[3848e0e]	258	continue { KEYWORD_RETURN(CONTINUE); }
[e04b636]	259	coroutine { KEYWORD_RETURN(COROUTINE); } // CFA
[15f769c]	260	_Decimal32 { KEYWORD_RETURN(DECIMAL32); } // GCC
	261	_Decimal64 { KEYWORD_RETURN(DECIMAL64); } // GCC
	262	_Decimal128 { KEYWORD_RETURN(DECIMAL128); } // GCC
[3848e0e]	263	default { KEYWORD_RETURN(DEFAULT); }
[02e5ab6]	264	disable { KEYWORD_RETURN(DISABLE); } // CFA
[b87a5ed]	265	do { KEYWORD_RETURN(DO); }
[3848e0e]	266	double { KEYWORD_RETURN(DOUBLE); }
[b87a5ed]	267	dtype { KEYWORD_RETURN(DTYPE); } // CFA
[3848e0e]	268	else { KEYWORD_RETURN(ELSE); }
[02e5ab6]	269	enable { KEYWORD_RETURN(ENABLE); } // CFA
[3848e0e]	270	enum { KEYWORD_RETURN(ENUM); }
[c27fb59]	271	exception { KEYWORD_RETURN(EXCEPTION); } // CFA
[8c25760]	272	__extension__ { KEYWORD_RETURN(EXTENSION); } // GCC
[3848e0e]	273	extern { KEYWORD_RETURN(EXTERN); }
[bd7f401]	274	fallthrough { KEYWORD_RETURN(FALLTHROUGH); } // CFA
[35f730f]	275	fallthru { KEYWORD_RETURN(FALLTHRU); } // CFA
[9fb1367]	276	finally { QKEYWORD_RETURN(FINALLY); } // CFA
	277	fixup { QKEYWORD_RETURN(FIXUP); } // CFA
[3848e0e]	278	float { KEYWORD_RETURN(FLOAT); }
[c5f69fd]	279	__float80 { KEYWORD_RETURN(FLOAT80); } // GCC
	280	float80 { KEYWORD_RETURN(FLOAT80); } // GCC
[e15853c]	281	__float128 { KEYWORD_RETURN(uuFLOAT128); } // GCC
	282	float128 { KEYWORD_RETURN(uuFLOAT128); } // GCC
[c5f69fd]	283	_Float16 { FLOATXX(FLOAT16); } // GCC
	284	_Float32 { FLOATXX(FLOAT32); } // GCC
	285	_Float32x { FLOATXX(FLOAT32X); } // GCC
	286	_Float64 { FLOATXX(FLOAT64); } // GCC
	287	_Float64x { FLOATXX(FLOAT64X); } // GCC
	288	_Float128 { FLOATXX(FLOAT128); } // GCC
	289	_Float128x { FLOATXX(FLOAT128X); } // GCC
	290	__Float32x4_t { FLOATXX(FLOAT32X4); } // GCC (ARM)
	291	__Float64x2_t { FLOATXX(FLOAT64X2); } // GCC (ARM)
	292	__SVFloat32_t { FLOATXX(SVFLOAT32); } // GCC (ARM)
	293	__SVFloat64_t { FLOATXX(SVFLOAT64); } // GCC (ARM)
[b87a5ed]	294	for { KEYWORD_RETURN(FOR); }
	295	forall { KEYWORD_RETURN(FORALL); } // CFA
[3848e0e]	296	fortran { KEYWORD_RETURN(FORTRAN); }
[b87a5ed]	297	ftype { KEYWORD_RETURN(FTYPE); } // CFA
[553772b]	298	generator { KEYWORD_RETURN(GENERATOR); } // CFA
[b87a5ed]	299	_Generic { KEYWORD_RETURN(GENERIC); } // C11
[3848e0e]	300	goto { KEYWORD_RETURN(GOTO); }
[b87a5ed]	301	if { KEYWORD_RETURN(IF); }
	302	_Imaginary { KEYWORD_RETURN(IMAGINARY); } // C99
	303	__imag { KEYWORD_RETURN(IMAGINARY); } // GCC
	304	__imag__ { KEYWORD_RETURN(IMAGINARY); } // GCC
	305	inline { KEYWORD_RETURN(INLINE); } // C99
	306	__inline { KEYWORD_RETURN(INLINE); } // GCC
	307	__inline__ { KEYWORD_RETURN(INLINE); } // GCC
	308	int { KEYWORD_RETURN(INT); }
[f1da02c]	309	int128 { KEYWORD_RETURN(INT128); } // CFA
[201aeb9]	310	__int128 { KEYWORD_RETURN(INT128); } // GCC
[f1da02c]	311	__int128_t { KEYWORD_RETURN(INT128); } // GCC
[b87a5ed]	312	__label__ { KEYWORD_RETURN(LABEL); } // GCC
[3848e0e]	313	long { KEYWORD_RETURN(LONG); }
[6016c87]	314	monitor { KEYWORD_RETURN(MONITOR); } // CFA
[a7c90d4]	315	mutex { KEYWORD_RETURN(MUTEX); } // CFA
[b87a5ed]	316	_Noreturn { KEYWORD_RETURN(NORETURN); } // C11
[5721a6d]	317	__builtin_offsetof { KEYWORD_RETURN(OFFSETOF); } // GCC
[3a2128f]	318	one_t { NUMERIC_RETURN(ONE_T); } // CFA
[ce28c7b]	319	or { QKEYWORD_RETURN(WOR); } // CFA
[4040425]	320	otype { KEYWORD_RETURN(OTYPE); } // CFA
[9fb1367]	321	recover { QKEYWORD_RETURN(RECOVER); } // CFA
[3848e0e]	322	register { KEYWORD_RETURN(REGISTER); }
[9fb1367]	323	report { KEYWORD_RETURN(THROWRESUME); } // CFA
[b87a5ed]	324	restrict { KEYWORD_RETURN(RESTRICT); } // C99
	325	__restrict { KEYWORD_RETURN(RESTRICT); } // GCC
	326	__restrict__ { KEYWORD_RETURN(RESTRICT); } // GCC
[3848e0e]	327	return { KEYWORD_RETURN(RETURN); }
[25744d2]	328	/* resume { KEYWORD_RETURN(RESUME); } // CFA */
[3848e0e]	329	short { KEYWORD_RETURN(SHORT); }
	330	signed { KEYWORD_RETURN(SIGNED); }
[b87a5ed]	331	__signed { KEYWORD_RETURN(SIGNED); } // GCC
	332	__signed__ { KEYWORD_RETURN(SIGNED); } // GCC
[3848e0e]	333	sizeof { KEYWORD_RETURN(SIZEOF); }
[07771bc]	334	countof { KEYWORD_RETURN(COUNTOF); } // GCC
[3848e0e]	335	static { KEYWORD_RETURN(STATIC); }
[b87a5ed]	336	_Static_assert { KEYWORD_RETURN(STATICASSERT); } // C11
[46f9f02]	337	static_assert { KEYWORD_RETURN(STATICASSERT); } // C23
[3848e0e]	338	struct { KEYWORD_RETURN(STRUCT); }
[37cdd97]	339	suspend { KEYWORD_RETURN(SUSPEND); } // CFA
[3848e0e]	340	switch { KEYWORD_RETURN(SWITCH); }
[bd4d011]	341	thread { KEYWORD_RETURN(THREAD); } // C11
[ed9a1ae]	342	__thread { KEYWORD_RETURN(THREADLOCALGCC); } // GCC
	343	_Thread_local { KEYWORD_RETURN(THREADLOCALC11); } // C11
[46f9f02]	344	thread_local { KEYWORD_RETURN(THREADLOCALC11); } // C23
[b87a5ed]	345	throw { KEYWORD_RETURN(THROW); } // CFA
[02e5ab6]	346	throwResume { KEYWORD_RETURN(THROWRESUME); } // CFA
[5b2edbc]	347	timeout { QKEYWORD_RETURN(TIMEOUT); } // CFA
[4040425]	348	trait { KEYWORD_RETURN(TRAIT); } // CFA
[b87a5ed]	349	try { KEYWORD_RETURN(TRY); } // CFA
[8f60f0b]	350	ttype { KEYWORD_RETURN(TTYPE); } // CFA
[3848e0e]	351	typedef { KEYWORD_RETURN(TYPEDEF); }
[b87a5ed]	352	typeof { KEYWORD_RETURN(TYPEOF); } // GCC
	353	__typeof { KEYWORD_RETURN(TYPEOF); } // GCC
	354	__typeof__ { KEYWORD_RETURN(TYPEOF); } // GCC
[1f652a7]	355	typeid { KEYWORD_RETURN(TYPEID); } // GCC
[3848e0e]	356	union { KEYWORD_RETURN(UNION); }
[f1da02c]	357	__uint128_t { KEYWORD_RETURN(UINT128); } // GCC
[3848e0e]	358	unsigned { KEYWORD_RETURN(UNSIGNED); }
[59c7e3e]	359	__builtin_va_arg { KEYWORD_RETURN(VA_ARG); } // GCC
	360	__builtin_va_list { KEYWORD_RETURN(VA_LIST); } // GCC
[72457b6]	361	virtual { KEYWORD_RETURN(VIRTUAL); } // CFA
[3848e0e]	362	void { KEYWORD_RETURN(VOID); }
	363	volatile { KEYWORD_RETURN(VOLATILE); }
[b87a5ed]	364	__volatile { KEYWORD_RETURN(VOLATILE); } // GCC
	365	__volatile__ { KEYWORD_RETURN(VOLATILE); } // GCC
[1f652a7]	366	vtable { KEYWORD_RETURN(VTABLE); } // CFA
[9fb1367]	367	waitfor { KEYWORD_RETURN(WAITFOR); } // CFA
[466787a]	368	waituntil { KEYWORD_RETURN(WAITUNTIL); } // CFA
[9fb1367]	369	when { KEYWORD_RETURN(WHEN); } // CFA
[3848e0e]	370	while { KEYWORD_RETURN(WHILE); }
[8b47e50]	371	with { KEYWORD_RETURN(WITH); } // CFA
[3a2128f]	372	zero_t { NUMERIC_RETURN(ZERO_T); } // CFA
[51b73452]	373
[b87a5ed]	374	/* identifier */
	375	{identifier} { IDENTIFIER_RETURN(); }
[095ac99]	376	"``"{identifier} { // CFA
	377	yytext[yyleng] = '\0'; yytext += 2; // SKULLDUGGERY: remove backquotes (ok to shorten?)
[dc7db63]	378	IDENTIFIER_RETURN();
	379	}
[51b73452]	380
[1a8b17a]	381	/* C23 attributes */
	382	"[["{hv_white}{attributes}({hv_white}","{hv_white}{attributes}){hv_white}*"]]" {
[4e0168a]	383	strtext = new string( &yytext[2], yyleng - 4 ); // remove delimiters "[[" and "]]"
[1a8b17a]	384	RETURN_STR(C23_ATTRIBUTE);
	385	}
	386
[b87a5ed]	387	/* numeric constants */
[0a2168f]	388	{binary_constant} { NUMERIC_RETURN(INTEGERconstant); }
[59db689]	389	{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
[0a2168f]	390	{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
[1a8b17a]	391	{hex_constant} { NUMERIC_RETURN(INTEGERconstant); }
	392	{floating_decimal} { NUMERIC_RETURN(FLOATING_DECIMALconstant); } // must appear before floating_constant
[930f69e]	393	{floating_fraction} { NUMERIC_RETURN(FLOATING_FRACTIONconstant); } // must appear before floating_constant
[3848e0e]	394	{floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
	395	{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
[51b73452]	396
[4e0168a]	397	/* character constant, allows empty value, CPP also handles missing quote delimiter */
[9ed4f94]	398	({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new string( yytext, yyleng ); }
[c1c1112]	399	<QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); }
[dc7db63]	400	<QUOTE>['\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); }
[930f69e]	401	/* ' stop editor highlighting */
[51b73452]	402
[4e0168a]	403	/* string constant, CPP also handles missing quote delimiter */
[9ed4f94]	404	({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new string( yytext, yyleng ); }
[c1c1112]	405	<STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); }
[dc7db63]	406	<STRING>["\n] { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); }
[930f69e]	407	/* " stop editor highlighting */
[51b73452]	408
[59db689]	409	/* common character/string constant */
[c1c1112]	410	<QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); }
[cd623a4]	411	<QUOTE,STRING>"\\"{h_white}*"\n" {} // continuation (ALSO HANDLED BY CPP)
[c1c1112]	412	<QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character
[3848e0e]	413
[b87a5ed]	414	/* punctuation */
[615a096]	415	"@" { ASCIIOP_RETURN(); }
[dc7db63]	416	"`" { ASCIIOP_RETURN(); }
[b87a5ed]	417	"[" { ASCIIOP_RETURN(); }
	418	"]" { ASCIIOP_RETURN(); }
	419	"(" { ASCIIOP_RETURN(); }
	420	")" { ASCIIOP_RETURN(); }
	421	"{" { ASCIIOP_RETURN(); }
	422	"}" { ASCIIOP_RETURN(); }
	423	"," { ASCIIOP_RETURN(); } // also operator
	424	":" { ASCIIOP_RETURN(); }
	425	";" { ASCIIOP_RETURN(); }
	426	"." { ASCIIOP_RETURN(); } // also operator
[647e2ea]	427	"@@" { NAMEDOP_RETURN(ATTR); } // CFA, attribute shorthand
[3848e0e]	428	"..." { NAMEDOP_RETURN(ELLIPSIS); }
	429
[b87a5ed]	430	/* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
[3848e0e]	431	"<:" { RETURN_VAL('['); }
	432	":>" { RETURN_VAL(']'); }
	433	"<%" { RETURN_VAL('{'); }
	434	"%>" { RETURN_VAL('}'); }
[51b73452]	435
[b87a5ed]	436	/* operators */
	437	"!" { ASCIIOP_RETURN(); }
	438	"+" { ASCIIOP_RETURN(); }
	439	"-" { ASCIIOP_RETURN(); }
	440	"*" { ASCIIOP_RETURN(); }
[e5f2a67]	441	"\\" { ASCIIOP_RETURN(); } // CFA, exponentiation
[b87a5ed]	442	"/" { ASCIIOP_RETURN(); }
	443	"%" { ASCIIOP_RETURN(); }
	444	"^" { ASCIIOP_RETURN(); }
	445	"~" { ASCIIOP_RETURN(); }
	446	"&" { ASCIIOP_RETURN(); }
	447	"\|" { ASCIIOP_RETURN(); }
	448	"<" { ASCIIOP_RETURN(); }
	449	">" { ASCIIOP_RETURN(); }
	450	"=" { ASCIIOP_RETURN(); }
	451	"?" { ASCIIOP_RETURN(); }
[3848e0e]	452
	453	"++" { NAMEDOP_RETURN(ICR); }
	454	"--" { NAMEDOP_RETURN(DECR); }
	455	"==" { NAMEDOP_RETURN(EQ); }
	456	"!=" { NAMEDOP_RETURN(NE); }
	457	"<<" { NAMEDOP_RETURN(LS); }
	458	">>" { NAMEDOP_RETURN(RS); }
	459	"<=" { NAMEDOP_RETURN(LE); }
	460	">=" { NAMEDOP_RETURN(GE); }
	461	"&&" { NAMEDOP_RETURN(ANDAND); }
	462	"\|\|" { NAMEDOP_RETURN(OROR); }
	463	"->" { NAMEDOP_RETURN(ARROW); }
	464	"+=" { NAMEDOP_RETURN(PLUSassign); }
	465	"-=" { NAMEDOP_RETURN(MINUSassign); }
[e5f2a67]	466	"\\=" { NAMEDOP_RETURN(EXPassign); } // CFA, exponentiation
[3848e0e]	467	"*=" { NAMEDOP_RETURN(MULTassign); }
	468	"/=" { NAMEDOP_RETURN(DIVassign); }
	469	"%=" { NAMEDOP_RETURN(MODassign); }
	470	"&=" { NAMEDOP_RETURN(ANDassign); }
	471	"\|=" { NAMEDOP_RETURN(ORassign); }
	472	"^=" { NAMEDOP_RETURN(ERassign); }
	473	"<<=" { NAMEDOP_RETURN(LSassign); }
	474	">>=" { NAMEDOP_RETURN(RSassign); }
[51b73452]	475
[08061589]	476	"@=" { NAMEDOP_RETURN(ATassign); } // CFA
[01afd8d]	477	"+~" { NAMEDOP_RETURN(ErangeUp); } // CFA
[d69f4bb4]	478	"~=" { NAMEDOP_RETURN(ErangeUpEq); } // CFA
[01afd8d]	479	"+~=" { NAMEDOP_RETURN(ErangeUpEq); } // CFA
[d69f4bb4]	480	"-~" { NAMEDOP_RETURN(ErangeDown); } // CFA
	481	"-~=" { NAMEDOP_RETURN(ErangeDownEq); } // CFA
[097e2b0]	482
[b87a5ed]	483	/* CFA, operator identifier */
	484	{op_unary}"?" { IDENTIFIER_RETURN(); } // unary
[a61fea9a]	485	"?"({op_unary_pre_post}\|"()"\|"[?]"\|"{}") { IDENTIFIER_RETURN(); }
[76c62b2]	486	"^?{}" { IDENTIFIER_RETURN(); }
[60a8062]	487	"?`"{identifier} { // postfix operator
	488	yylval.tok.str = new string( &yytext[2] ); // remove ?`
	489	yylval.tok.str = build_postfix_name( yylval.tok.str ); // add prefix
	490	RETURN_LOCN( typedefTable.isKind( *yylval.tok.str ) );
	491	}
[b87a5ed]	492	"?"{op_binary_over}"?" { IDENTIFIER_RETURN(); } // binary
[51b73452]	493	/*
[daf9671]	494	This rule handles ambiguous cases with operator identifiers, e.g., "int ??()", where the string "??" can be
	495	lexed as "?"/"?" or ""/"??". Since it is common practise to put a unary operator juxtaposed to an identifier,
	496	e.g., "*i", users will be annoyed if they cannot do this with respect to operator identifiers. Therefore, there is
	497	a lexical look-ahead for the second case, with backtracking to return the leading unary operator and then
	498	reparsing the trailing operator identifier. Otherwise a space is needed between the unary operator and operator
	499	identifier to disambiguate this common case.
	500
	501	A similar issue occurs with the dereference, *?(...), and routine-call, ?()(...) identifiers. The ambiguity
	502	occurs when the deference operator has no parameters, ?() and ?()(...), requiring arbitrary whitespace
	503	look-ahead for the routine-call parameter-list to disambiguate. However, the dereference operator must have a
	504	parameter/argument to dereference ?(...). Hence, always interpreting the string ?() as * ?() does not preclude
	505	any meaningful program.
	506
	507	The remaining cases are with the increment/decrement operators and conditional expression:
	508
	509	i++? ...(...);
	510	i?++ ...(...);
	511
	512	requiring arbitrary whitespace look-ahead for the operator parameter-list, even though that interpretation is an
	513	incorrect expression (juxtaposed identifiers). Therefore, it is necessary to disambiguate these cases with a
	514	space:
	515
	516	i++ ? i : 0;
	517	i? ++i : 0;
[51b73452]	518	*/
[daf9671]	519	{op_unary}"?"({op_unary_pre_post}\|"()"\|"[?]"\|{op_binary_over}"?") {
[b87a5ed]	520	// 1 or 2 character unary operator ?
	521	int i = yytext[1] == '?' ? 1 : 2;
	522	yyless( i ); // put back characters up to first '?'
	523	if ( i > 1 ) {
	524	NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
	525	} else {
	526	ASCIIOP_RETURN();
	527	} // if
	528	}
	529
[9ed4f94]	530	/* unknown character */
	531	. { yyerror( "unknown character" ); }
[51b73452]	532
	533	%%
[8551b859]	534
[9ed4f94]	535	// ----end of lexer----
	536
	537	void yyerror( const char * errmsg ) {
[8551b859]	538	SemanticErrorThrow = true;
[a8615fd1]	539	cerr << (yyfilename ? yyfilename : "unknown file") << ':' << yylineno << ':' << column - yyleng + 1
[79a6b17]	540	<< ": " << ErrorHelpers::error_str() << errmsg << " before token \"" << (yytext[0] == '\0' ? "EOF" : yytext) << '"' << endl;
[9ed4f94]	541	}
[51b73452]	542
[b87a5ed]	543	// Local Variables: //
	544	// mode: c++ //
[de62360d]	545	// tab-width: 4 //
[b87a5ed]	546	// compile-command: "make install" //
	547	// End: //

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format