source: libcfa/src/vec/vec3.hfa @ 20cf96d

ADTast-experimental
Last change on this file since 20cf96d was fd54fef, checked in by Michael Brooks <mlbrooks@…>, 4 years ago

Converting the project to use the new syntax for otype, dtype and ttytpe.

Changed prelude (gen), libcfa and test suite to use it. Added a simple deprecation rule of the old syntax to the parser; we might wish to support both syntaxes "officially," like with an extra CLI switch, but this measure should serve as a simple reminder for our team to try the new syntax.
  • Property mode set to 100644
File size: 6.5 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2021 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// io/types.hfa --
8//
9// Author           : Dimitry Kobets
10// Created On       :
11// Last Modified By :
12// Last Modified On :
13// Update Count     :
14//
15
16#pragma once
17
18#include <iostream.hfa>
19#include "vec.hfa"
20
21forall (T) {
22    struct vec3 {
23        T x, y, z;
24    };
25}
26
27forall (T) {
28    static inline {
29
30    void ?{}(vec3(T)& v, T x, T y, T z) {
31        v.[x, y, z] = [x, y, z];
32    }
33
34    forall(| zero_assign(T))
35    void ?{}(vec3(T)& vec, zero_t) with (vec) {
36        x = y = z = 0;
37    }
38
39    void ?{}(vec3(T)& vec, T val) with (vec) {
40        x = y = z = val;
41    }
42
43    void ?{}(vec3(T)& vec, vec3(T) other) with (vec) {
44        [x,y,z] = other.[x,y,z];
45    }
46
47    void ?=?(vec3(T)& vec, vec3(T) other) with (vec) {
48        [x,y,z] = other.[x,y,z];
49    }
50    forall(| zero_assign(T))
51    void ?=?(vec3(T)& vec, zero_t) with (vec) {
52        x = y = z = 0;
53    }
54
55    // Primitive mathematical operations
56
57    // -
58    forall(| subtract(T)) {
59    vec3(T) ?-?(vec3(T) u, vec3(T) v) {
60        return [u.x - v.x, u.y - v.y, u.z - v.z];
61    }
62    vec3(T)& ?-=?(vec3(T)& u, vec3(T) v) {
63        u = u - v;
64        return u;
65    }
66    }
67    forall(| negate(T)) {
68    vec3(T) -?(vec3(T) v) with (v) {
69        return [-x, -y, -z];
70    }
71    }
72    forall(| { T --?(T&); }) {
73    vec3(T)& --?(vec3(T)& v) {
74        --v.x;
75        --v.y;
76        --v.z;
77        return v;
78    }
79    vec3(T) ?--(vec3(T)& v) {
80        vec3(T) copy = v;
81        --v;
82        return copy;
83    }
84    }
85
86    // +
87    forall(| add(T)) {
88    vec3(T) ?+?(vec3(T) u, vec3(T) v) {
89        return [u.x + v.x, u.y + v.y, u.z + v.z];
90    }
91    vec3(T)& ?+=?(vec3(T)& u, vec3(T) v) {
92        u = u + v;
93        return u;
94    }
95    }
96
97    forall(| { T ++?(T&); }) {
98    vec3(T)& ++?(vec3(T)& v) {
99        ++v.x;
100        ++v.y;
101        ++v.z;
102        return v;
103    }
104    vec3(T) ?++(vec3(T)& v) {
105        vec3(T) copy = v;
106        ++v;
107        return copy;
108    }
109    }
110
111    // *
112    forall(| multiply(T)) {
113    vec3(T) ?*?(vec3(T) v, T scalar) with (v) {
114        return [x * scalar, y * scalar, z * scalar];
115    }
116    vec3(T) ?*?(T scalar, vec3(T) v) {
117        return v * scalar;
118    }
119    vec3(T) ?*?(vec3(T) u, vec3(T) v) {
120        return [u.x * v.x, u.y * v.y, u.z * v.z];
121    }
122    vec3(T)& ?*=?(vec3(T)& v, T scalar) {
123        v = v * scalar;
124        return v;
125    }
126    vec3(T)& ?*=?(vec3(T)& u, vec3(T) v) {
127        u = u * v;
128        return u;
129    }
130    }
131
132    // /
133    forall(| divide(T)) {
134    vec3(T) ?/?(vec3(T) v, T scalar) with (v) {
135        return [x / scalar, y / scalar, z / scalar];
136    }
137    vec3(T) ?/?(vec3(T) u, vec3(T) v) {
138        return [u.x / v.x, u.y / v.y, u.z / v.z];
139    }
140    vec3(T)& ?/=?(vec3(T)& v, T scalar) {
141        v = v / scalar;
142        return v;
143    }
144    vec3(T)& ?/=?(vec3(T)& u, vec3(T) v) {
145        u = u / v;
146        return u;
147    }
148    }
149
150    // %
151    forall(| { T ?%?(T,T); }) {
152    vec3(T) ?%?(vec3(T) v, T scalar) with (v) {
153        return [x % scalar, y % scalar, z % scalar];
154    }
155    vec3(T)& ?%=?(vec3(T)& u, T scalar) {
156        u = u % scalar;
157        return u;
158    }
159    vec3(T) ?%?(vec3(T) u, vec3(T) v) {
160        return [u.x % v.x, u.y % v.y, u.z % v.z];
161    }
162    vec3(T)& ?%=?(vec3(T)& u, vec3(T) v) {
163        u = u % v;
164        return u;
165    }
166    }
167
168    // &
169    forall(| { T ?&?(T,T); }) {
170    vec3(T) ?&?(vec3(T) v, T scalar) with (v) {
171        return [x & scalar, y & scalar, z & scalar];
172    }
173    vec3(T)& ?&=?(vec3(T)& u, T scalar) {
174        u = u & scalar;
175        return u;
176    }
177    vec3(T) ?&?(vec3(T) u, vec3(T) v) {
178        return [u.x & v.x, u.y & v.y, u.z & v.z];
179    }
180    vec3(T)& ?&=?(vec3(T)& u, vec3(T) v) {
181        u = u & v;
182        return u;
183    }
184    }
185
186    // |
187    forall(| { T ?|?(T,T); }) {
188    vec3(T) ?|?(vec3(T) v, T scalar) with (v) {
189        return [x | scalar, y | scalar, z | scalar];
190    }
191    vec3(T)& ?|=?(vec3(T)& u, T scalar) {
192        u = u | scalar;
193        return u;
194    }
195    vec3(T) ?|?(vec3(T) u, vec3(T) v) {
196        return [u.x | v.x, u.y | v.y, u.z | v.z];
197    }
198    vec3(T)& ?|=?(vec3(T)& u, vec3(T) v) {
199        u = u | v;
200        return u;
201    }
202    }
203
204    // ^
205    forall(| { T ?^?(T,T); }) {
206    vec3(T) ?^?(vec3(T) v, T scalar) with (v) {
207        return [x ^ scalar, y ^ scalar, z ^ scalar];
208    }
209    vec3(T)& ?^=?(vec3(T)& u, T scalar) {
210        u = u ^ scalar;
211        return u;
212    }
213    vec3(T) ?^?(vec3(T) u, vec3(T) v) {
214        return [u.x ^ v.x, u.y ^ v.y, u.z ^ v.z];
215    }
216    vec3(T)& ?^=?(vec3(T)& u, vec3(T) v) {
217        u = u ^ v;
218        return u;
219    }
220    }
221
222    // <<
223    forall(| { T ?<<?(T,T); }) {
224    vec3(T) ?<<?(vec3(T) v, T scalar) with (v) {
225        return [x << scalar, y << scalar, z << scalar];
226    }
227    vec3(T)& ?<<=?(vec3(T)& u, T scalar) {
228        u = u << scalar;
229        return u;
230    }
231    vec3(T) ?<<?(vec3(T) u, vec3(T) v) {
232        return [u.x << v.x, u.y << v.y, u.z << v.z];
233    }
234    vec3(T)& ?<<=?(vec3(T)& u, vec3(T) v) {
235        u = u << v;
236        return u;
237    }
238    }
239
240    // >>
241    forall(| { T ?>>?(T,T); }) {
242    vec3(T) ?>>?(vec3(T) v, T scalar) with (v) {
243        return [x >> scalar, y >> scalar, z >> scalar];
244    }
245    vec3(T)& ?>>=?(vec3(T)& u, T scalar) {
246        u = u >> scalar;
247        return u;
248    }
249    vec3(T) ?>>?(vec3(T) u, vec3(T) v) {
250        return [u.x >> v.x, u.y >> v.y, u.z >> v.z];
251    }
252    vec3(T)& ?>>=?(vec3(T)& u, vec3(T) v) {
253        u = u >> v;
254        return u;
255    }
256    }
257
258    // ~
259    forall(| { T ~?(T); })
260    vec3(T) ~?(vec3(T) v) with (v) {
261        return [~v.x, ~v.y, ~v.z];
262    }
263
264    // relational
265    forall(| equality(T)) {
266    bool ?==?(vec3(T) u, vec3(T) v) with (u) {
267        return x == v.x && y == v.y && z == v.z;
268    }
269    bool ?!=?(vec3(T) u, vec3(T) v) {
270        return !(u == v);
271    }
272    }
273
274    // Geometric functions
275    forall(| add(T) | multiply(T))
276    T dot(vec3(T) u, vec3(T) v) {
277        return u.x * v.x + u.y * v.y + u.z * v.z;
278    }
279
280    forall(| subtract(T) | multiply(T))
281    vec3(T) cross(vec3(T) u, vec3(T) v) {
282        return (vec3(T)){ u.y * v.z - v.y * u.z,
283                          u.z * v.x - v.z * u.x,
284                          u.x * v.y - v.x * u.y };
285    }
286
287    } // static inline
288}
289
290forall(ostype &, T | writeable(T, ostype)) {
291    ostype & ?|?(ostype & os, vec3(T) v) with (v) {
292        return os | '<' | x | ',' | y | ',' | z | '>';
293    }
294    void ?|?(ostype & os, vec3(T) v ) with (v) {
295        (ostype &)(os | v); ends(os);
296    }
297}
Note: See TracBrowser for help on using the repository browser.